aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  34 dnl
  35 AC_DEFUN([WINE_CHECK_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])dnl
  37 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  38 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  39 AC_MSG_CHECKING([for -l$1])
  40 AC_CACHE_VAL(ac_Lib,
  41 [ac_check_soname_save_LIBS=$LIBS
  42 LIBS="-l$1 $5 $LIBS"
  43   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  44   [case "$LIBEXT" in
  45     dll) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest.exe | grep "$1" | sed -e "s/dll.*/dll/"';2,$d'`]) ;;
  46     dylib) AS_VAR_SET(ac_Lib,[`otool -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  47     *) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^      ]]*\).*$/\1/"';2,$d'`]) ;;
  48   esac])
  49   LIBS=$ac_check_soname_save_LIBS])dnl
  50 AS_IF([test "x]AS_VAR_GET(ac_Lib)[" = "x"],
  51       [AC_MSG_RESULT([not found])
  52        $4],
  53       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
  54        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
  55                           [Define to the soname of the lib$1 library.])
  56        $3])dnl
  57 m4_popdef([ac_lib_pattern])dnl
  58 AS_VAR_POPDEF([ac_Lib])])
  59
  60 dnl **** Link C code with an assembly file ****
  61 dnl
  62 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  63 dnl
  64 AC_DEFUN([WINE_TRY_ASM_LINK],
  65 [AC_LINK_IFELSE(AC_LANG_PROGRAM([[$2]],[[asm($1); $3]]),[$4],[$5])])
  66
  67 dnl **** Check if we can link an empty program with special CFLAGS ****
  68 dnl
  69 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  70 dnl
  71 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
  72 dnl
  73 AC_DEFUN([WINE_TRY_CFLAGS],
  74 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
  75 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
  76 [ac_wine_try_cflags_saved=$CFLAGS
  77 CFLAGS="$CFLAGS $1"
  78 AC_LINK_IFELSE(AC_LANG_SOURCE([[int main(int argc, char **argv) { return 0; }]]),
  79                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
  80 CFLAGS=$ac_wine_try_cflags_saved])
  81 AS_IF([test AS_VAR_GET(ac_var) = yes],
  82       [m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
  83 AS_VAR_POPDEF([ac_var])])
  84
  85 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
  86 dnl
  87 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
  88 dnl
  89 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
  90 [ac_wine_try_cflags_saved=$CFLAGS
  91 CFLAGS="$CFLAGS $1"
  92 AC_LINK_IFELSE([void myfunc() {}],[$2],[$3])
  93 CFLAGS=$ac_wine_try_cflags_saved])
  94
  95 dnl **** Check whether we need to define a symbol on the compiler command line ****
  96 dnl
  97 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
  98 dnl
  99 AC_DEFUN([WINE_CHECK_DEFINE],
 100 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 101 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 102     AC_EGREP_CPP(yes,[#ifndef $1
 103 yes
 104 #endif],
 105     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 106 AS_IF([test AS_VAR_GET(ac_var) = yes],
 107       [CFLAGS="$CFLAGS -D$1"
 108   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 109 AS_VAR_POPDEF([ac_var])])
 110
 111 dnl **** Check for functions with some extra libraries ****
 112 dnl
 113 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 114 dnl
 115 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 116 [ac_wine_check_funcs_save_LIBS="$LIBS"
 117 LIBS="$LIBS $2"
 118 AC_CHECK_FUNCS([$1],[$3],[$4])
 119 LIBS="$ac_wine_check_funcs_save_LIBS"])
 120
 121 dnl **** Check for a mingw program, trying the various mingw prefixes ****
 122 dnl
 123 dnl Usage: WINE_CHECK_MINGW_PROG(variable,prog,[value-if-not-found],[path])
 124 dnl
 125 AC_DEFUN([WINE_CHECK_MINGW_PROG],
 126 [case "$host_cpu" in
 127   i[[3456789]]86*)
 128     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32, mingw32msvc, mingw32],
 129                         m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-ac_wine_prefix-$2 ]))" ;;
 130   x86_64)
 131     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32,w64-mingw32],[x86_64-ac_wine_prefix-$2 ])" ;;
 132   *)
 133     ac_prefix_list="" ;;
 134 esac
 135 AC_CHECK_PROGS([$1],[$ac_prefix_list],[$3],[$4])])
 136
 137
 138 dnl **** Define helper functions for creating config.status files ****
 139 dnl
 140 dnl Usage: AC_REQUIRE([WINE_CONFIG_HELPERS])
 141 dnl
 142 AC_DEFUN([WINE_CONFIG_HELPERS],
 143 [ALL_MAKEFILE_DEPENDS="
 144 # Rules automatically generated by configure
 145
 146 .INIT: Makefile
 147 .MAKEFILEDEPS:
 148 all: Makefile
 149 Makefile: Makefile.in Make.vars.in Make.rules config.status
 150         @./config.status Make.tmp Makefile"
 151
 152 AC_SUBST(ALL_WINETEST_DEPENDS,["# Test binaries"])
 153 AC_SUBST(ALL_TEST_BINARIES,"")
 154
 155 wine_fn_append_file ()
 156 {
 157     AS_VAR_APPEND($[1]," \\$as_nl       $[2]")
 158 }
 159
 160 wine_fn_append_rule ()
 161 {
 162     AS_VAR_APPEND($[1],"$as_nl$[2]")
 163 }
 164
 165 wine_fn_all_dir_rules ()
 166 {
 167     ac_makedep=""
 168     if test "$[1]" != tools
 169     then
 170         dnl makedep is in tools so tools makefile cannot depend on it
 171         ac_makedep=" \$(MAKEDEP)"
 172     fi
 173
 174     wine_fn_append_file ALL_DIRS $[1]
 175     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 176 "__clean__: $[1]/__clean__
 177 .PHONY: $[1]/__clean__
 178 $[1]/__clean__: $[1]/Makefile
 179         @cd $[1] && \$(MAKE) clean
 180         \$(RM) $[1]/Makefile
 181 $[1]/Makefile: $[1]/Makefile.in Make.vars.in config.status $[2]$ac_makedep
 182         @./config.status --file $[1]/Makefile:Make.vars.in:$[1]/Makefile.in && cd $[1] && \$(MAKE) depend
 183 depend: $[1]/__depend__
 184 .PHONY: $[1]/__depend__
 185 $[1]/__depend__: $[2] \$(MAKEDEP) dummy
 186         @./config.status --file $[1]/Makefile:Make.vars.in:$[1]/Makefile.in && cd $[1] && \$(MAKE) depend"
 187 }
 188
 189 wine_fn_config_makefile ()
 190 {
 191     ac_dir=$[1]
 192     ac_enable=$[2]
 193     AS_VAR_IF([$ac_enable],[no],[return 0])
 194
 195     wine_fn_all_dir_rules $ac_dir Make.rules
 196     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 197 "all: $ac_dir
 198 .PHONY: $ac_dir
 199 $ac_dir: $ac_dir/Makefile dummy
 200         @cd $ac_dir && \$(MAKE)
 201 install:: $ac_dir
 202         @cd $ac_dir && \$(MAKE) install
 203 install-lib:: $ac_dir
 204         @cd $ac_dir && \$(MAKE) install-lib
 205 install-dev:: $ac_dir
 206         @cd $ac_dir && \$(MAKE) install-dev
 207 uninstall:: $ac_dir/Makefile
 208         @cd $ac_dir && \$(MAKE) uninstall"
 209 }
 210
 211 wine_fn_config_lib ()
 212 {
 213     ac_name=$[1]
 214     ac_dir=dlls/$ac_name
 215     wine_fn_all_dir_rules $ac_dir dlls/Makeimplib.rules
 216     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 217 "all __builddeps__: $ac_dir
 218 $ac_dir: $ac_dir/Makefile tools/widl tools/winebuild tools/winegcc include dummy
 219         @cd $ac_dir && \$(MAKE)
 220 install install-dev:: $ac_dir
 221         @cd $ac_dir && \$(MAKE) install
 222 uninstall:: $ac_dir/Makefile
 223         @cd $ac_dir && \$(MAKE) uninstall"
 224 }
 225
 226 wine_fn_config_dll ()
 227 {
 228     ac_dir=$[1]
 229     ac_enable=$[2]
 230     ac_implib=$[3]
 231     ac_implibsrc=$[4]
 232     ac_file="dlls/$ac_dir/lib$ac_implib"
 233     ac_deps="tools/widl tools/winebuild tools/winegcc include"
 234     ac_implibflags=""
 235
 236     case $ac_dir in
 237       *16) ac_implibflags=" -m16" ;;
 238     esac
 239
 240     wine_fn_all_dir_rules dlls/$ac_dir dlls/Makedll.rules
 241
 242     AS_VAR_IF([$ac_enable],[no],
 243               dnl enable_win16 is special in that it disables import libs too
 244               [test "$ac_enable" != enable_win16 || return 0],
 245               [wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 246 "all: dlls/$ac_dir
 247 .PHONY: dlls/$ac_dir
 248 dlls/$ac_dir: dlls/$ac_dir/Makefile __builddeps__ dummy
 249         @cd dlls/$ac_dir && \$(MAKE)
 250 install:: dlls/$ac_dir/Makefile __builddeps__
 251         @cd dlls/$ac_dir && \$(MAKE) install
 252 install-lib:: dlls/$ac_dir/Makefile __builddeps__
 253         @cd dlls/$ac_dir && \$(MAKE) install-lib
 254 uninstall manpages htmlpages sgmlpages xmlpages:: dlls/$ac_dir/Makefile
 255         @cd dlls/$ac_dir && \$(MAKE) \$[@]"])
 256
 257     if test -n "$ac_implibsrc"
 258     then
 259         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 260 "__builddeps__: $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT
 261 $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: $ac_deps
 262 $ac_file.def: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile
 263         @cd dlls/$ac_dir && \$(MAKE) lib$ac_implib.def
 264 $ac_file.$STATIC_IMPLIBEXT: dlls/$ac_dir/Makefile dummy
 265         @cd dlls/$ac_dir && \$(MAKE) lib$ac_implib.$STATIC_IMPLIBEXT
 266 install-dev:: dlls/$ac_dir/Makefile __builddeps__
 267         @cd dlls/$ac_dir && \$(MAKE) install-dev"
 268         if test "x$CROSSTEST_DISABLE" = x
 269         then
 270             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 271 "__builddeps__: $ac_file.cross.a
 272 $ac_file.cross.a: dlls/$ac_dir/Makefile dummy
 273         @cd dlls/$ac_dir && \$(MAKE) lib$ac_implib.cross.a"
 274         fi
 275
 276     elif test -n "$ac_implib"
 277     then
 278         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 279 "__builddeps__: $ac_file.$IMPLIBEXT
 280 $ac_file.def: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile \$(WINEBUILD)
 281         \$(WINEBUILD) \$(TARGETFLAGS)$ac_implibflags -w --def -o \$[@] --export \$(srcdir)/dlls/$ac_dir/$ac_dir.spec
 282 $ac_file.a: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile \$(WINEBUILD)
 283         \$(WINEBUILD) \$(TARGETFLAGS)$ac_implibflags -w --implib -o \$[@] --export \$(srcdir)/dlls/$ac_dir/$ac_dir.spec
 284 install-dev:: dlls/$ac_dir/Makefile __builddeps__
 285         @cd dlls/$ac_dir && \$(MAKE) install-dev"
 286         if test "x$CROSSTEST_DISABLE" = x
 287         then
 288             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 289 "__builddeps__: $ac_file.cross.a
 290 $ac_file.cross.a: dlls/$ac_dir/$ac_dir.spec dlls/$ac_dir/Makefile \$(WINEBUILD)
 291         \$(WINEBUILD) \$(CROSSTARGET:%=-b %)$ac_implibflags -w --implib -o \$[@] --export \$(srcdir)/dlls/$ac_dir/$ac_dir.spec"
 292         fi
 293
 294         if test "$ac_dir" != "$ac_implib"
 295         then
 296             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 297 "__builddeps__: dlls/lib$ac_implib.$IMPLIBEXT
 298 dlls/lib$ac_implib.$IMPLIBEXT: $ac_file.$IMPLIBEXT
 299         \$(RM) \$[@] && \$(LN_S) $ac_dir/lib$ac_implib.$IMPLIBEXT \$[@]
 300 clean::
 301         \$(RM) dlls/lib$ac_implib.$IMPLIBEXT"
 302             if test "x$CROSSTEST_DISABLE" = x
 303             then
 304                 wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 305 "__builddeps__: dlls/lib$ac_implib.cross.a
 306 dlls/lib$ac_implib.cross.a: $ac_file.cross.a
 307         \$(RM) \$[@] && \$(LN_S) $ac_dir/lib$ac_implib.cross.a \$[@]"
 308             fi
 309         fi
 310     fi
 311 }
 312
 313 wine_fn_config_program ()
 314 {
 315     ac_dir=$[1]
 316     ac_enable=$[2]
 317     ac_install=$[3]
 318     wine_fn_all_dir_rules programs/$ac_dir programs/Makeprog.rules
 319
 320     AS_VAR_IF([$ac_enable],[no],,[wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 321 "all: programs/$ac_dir
 322 .PHONY: programs/$ac_dir
 323 programs/$ac_dir: programs/$ac_dir/Makefile __builddeps__ dummy
 324         @cd programs/$ac_dir && \$(MAKE)"
 325
 326     test -n "$ac_install" || return
 327     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 328 "install install-lib:: programs/$ac_dir/Makefile __builddeps__
 329         @cd programs/$ac_dir && \$(MAKE) install
 330 uninstall:: programs/$ac_dir/Makefile
 331         @cd programs/$ac_dir && \$(MAKE) uninstall"
 332     if test "$ac_install" = installbin -a -n "$DLLEXT" -a "x$enable_tools" != xno
 333     then
 334         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 335 "install install-lib:: tools \$(DESTDIR)\$(bindir)
 336         \$(INSTALL_SCRIPT) tools/wineapploader \$(DESTDIR)\$(bindir)/$ac_dir
 337 uninstall::
 338         \$(RM) \$(DESTDIR)\$(bindir)/$ac_dir"
 339     fi])
 340 }
 341
 342 wine_fn_config_test ()
 343 {
 344     ac_dir=$[1]
 345     ac_name=$[2]
 346     wine_fn_append_file ALL_TEST_BINARIES $ac_name.exe
 347     wine_fn_append_rule ALL_WINETEST_DEPENDS \
 348 "$ac_name.exe: \$(top_builddir)/$ac_dir/$ac_name.exe$DLLEXT
 349         cp \$(top_builddir)/$ac_dir/$ac_name.exe$DLLEXT \$[@] && \$(STRIP) \$[@]
 350 $ac_name.rc:
 351         echo \"$ac_name.exe TESTRES \\\"$ac_name.exe\\\"\" >\$[@] || (\$(RM) \$[@] && false)
 352 $ac_name.res: $ac_name.rc $ac_name.exe"
 353     wine_fn_all_dir_rules $ac_dir Maketest.rules
 354
 355     AS_VAR_IF([enable_tests],[no],,[wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 356 "all programs/winetest: $ac_dir
 357 .PHONY: $ac_dir
 358 $ac_dir: $ac_dir/Makefile __builddeps__ dummy
 359         @cd $ac_dir && \$(MAKE)
 360 test: $ac_dir/__test__
 361 .PHONY: $ac_dir/__test__
 362 $ac_dir/__test__: dummy
 363         @cd $ac_dir && \$(MAKE) test
 364 testclean::
 365         \$(RM) $ac_dir/*.ok"
 366
 367         if test "x$CROSSTEST_DISABLE" = x
 368         then
 369             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 370 "crosstest: $ac_dir/__crosstest__
 371 .PHONY: $ac_dir/__crosstest__
 372 $ac_dir/__crosstest__: $ac_dir/Makefile __builddeps__ dummy
 373         @cd $ac_dir && \$(MAKE) crosstest"
 374         fi])
 375 }
 376
 377 wine_fn_config_tool ()
 378 {
 379     ac_dir=$[1]
 380     wine_fn_all_dir_rules $ac_dir Make.rules
 381
 382     AS_VAR_IF([enable_tools],[no],,[case $ac_dir in
 383       dnl tools directory has both install-lib and install-dev
 384       tools) wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 385 "install:: $ac_dir
 386         @cd $ac_dir && \$(MAKE) install
 387 install-lib:: $ac_dir
 388         @cd $ac_dir && \$(MAKE) install-lib
 389 install-dev:: $ac_dir
 390         @cd $ac_dir && \$(MAKE) install-dev" ;;
 391       *)     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 392 "install install-dev:: $ac_dir
 393         @cd $ac_dir && \$(MAKE) install" ;;
 394       esac
 395       wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 396 "uninstall:: $ac_dir/Makefile
 397         @cd $ac_dir && \$(MAKE) uninstall
 398 all __tooldeps__: $ac_dir
 399 .PHONY: $ac_dir
 400 $ac_dir: $ac_dir/Makefile libs/port dummy
 401         @cd $ac_dir && \$(MAKE)"
 402       case $ac_dir in
 403         tools/winebuild) wine_fn_append_rule ALL_MAKEFILE_DEPENDS "\$(WINEBUILD): $ac_dir" ;;
 404       esac])
 405 }
 406
 407 wine_fn_config_makerules ()
 408 {
 409     ac_rules=$[1]
 410     ac_deps=$[2]
 411     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 412 "$ac_rules: $ac_rules.in $ac_deps config.status
 413         @./config.status $ac_rules
 414 distclean::
 415         \$(RM) $ac_rules"
 416 }
 417
 418 wine_fn_config_symlink ()
 419 {
 420     ac_link=$[1]
 421     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 422 "$ac_link:
 423         @./config.status $ac_link
 424 distclean::
 425         \$(RM) $ac_link"
 426 }
 427
 428 if test "x$CROSSTEST_DISABLE" != x
 429 then
 430     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 431 "crosstest:
 432         @echo \"crosstest is not supported (mingw not installed?)\" && false"
 433 fi])
 434
 435 dnl **** Define helper function to append a file to a makefile file list ****
 436 dnl
 437 dnl Usage: WINE_APPEND_FILE(var,file)
 438 dnl
 439 AC_DEFUN([WINE_APPEND_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_file $1 "$2"])
 440
 441 dnl **** Define helper function to append a rule to a makefile command list ****
 442 dnl
 443 dnl Usage: WINE_APPEND_RULE(var,rule)
 444 dnl
 445 AC_DEFUN([WINE_APPEND_RULE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_rule $1 "$2"])
 446
 447 dnl **** Create nonexistent directories from config.status ****
 448 dnl
 449 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 450 dnl
 451 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 452 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || { AC_MSG_NOTICE([creating $1]); AS_MKDIR_P("$1"); }])])
 453
 454 dnl **** Create symlinks from config.status ****
 455 dnl
 456 dnl Usage: WINE_CONFIG_SYMLINK(name,target,enable)
 457 dnl
 458 AC_DEFUN([WINE_CONFIG_SYMLINK],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 459 m4_ifval([$3],[if test "x$[$3]" != xno; then
 460 ])AC_CONFIG_LINKS([$1:]m4_default([$2],[$1]))dnl
 461 m4_if([$2],,[test "$srcdir" = "." || ])wine_fn_config_symlink $1[]m4_ifval([$3],[
 462 fi])])
 463
 464 dnl **** Create a make rules file from config.status ****
 465 dnl
 466 dnl Usage: WINE_CONFIG_MAKERULES(file,var,deps)
 467 dnl
 468 AC_DEFUN([WINE_CONFIG_MAKERULES],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 469 wine_fn_config_makerules $1 $3
 470 $2=$1
 471 AC_SUBST_FILE([$2])dnl
 472 AC_CONFIG_FILES([$1])])
 473
 474 dnl **** Create a makefile from config.status ****
 475 dnl
 476 dnl Usage: WINE_CONFIG_MAKEFILE(file,enable)
 477 dnl
 478 AC_DEFUN([WINE_CONFIG_MAKEFILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 479 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 480 wine_fn_config_makefile [$1] ac_enable[]dnl
 481 AS_VAR_POPDEF([ac_enable])])
 482
 483 dnl **** Create a dll makefile from config.status ****
 484 dnl
 485 dnl Usage: WINE_CONFIG_DLL(name,enable,implib,implibsrc)
 486 dnl
 487 AC_DEFUN([WINE_CONFIG_DLL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 488 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 489 wine_fn_config_dll [$1] ac_enable [$3] m4_ifval([$4],["$4"])dnl
 490 AS_VAR_POPDEF([ac_enable])])
 491
 492 dnl **** Create a program makefile from config.status ****
 493 dnl
 494 dnl Usage: WINE_CONFIG_PROGRAM(name,install,enable)
 495 dnl
 496 AC_DEFUN([WINE_CONFIG_PROGRAM],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 497 AS_VAR_PUSHDEF([ac_enable],m4_default([$3],[enable_]$1))dnl
 498 wine_fn_config_program [$1] ac_enable [$2]dnl
 499 AS_VAR_POPDEF([ac_enable])])
 500
 501 dnl **** Create a test makefile from config.status ****
 502 dnl
 503 dnl Usage: WINE_CONFIG_TEST(dir)
 504 dnl
 505 AC_DEFUN([WINE_CONFIG_TEST],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 506 m4_pushdef([ac_suffix],m4_if(m4_substr([$1],0,9),[programs/],[.exe_test],[_test]))dnl
 507 m4_pushdef([ac_name],[m4_bpatsubst([$1],[.*/\(.*\)/tests$],[\1])])dnl
 508 wine_fn_config_test $1 ac_name[]ac_suffix[]dnl
 509 m4_popdef([ac_suffix])dnl
 510 m4_popdef([ac_name])])
 511
 512 dnl **** Create a static lib makefile from config.status ****
 513 dnl
 514 dnl Usage: WINE_CONFIG_LIB(name)
 515 dnl
 516 AC_DEFUN([WINE_CONFIG_LIB],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 517 wine_fn_config_lib $1])
 518
 519 dnl **** Create a tool makefile from config.status ****
 520 dnl
 521 dnl Usage: WINE_CONFIG_TOOL(name)
 522 dnl
 523 AC_DEFUN([WINE_CONFIG_TOOL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 524 wine_fn_config_tool $1])
 525
 526 dnl **** Add a message to the list displayed at the end ****
 527 dnl
 528 dnl Usage: WINE_NOTICE(notice)
 529 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice)
 530 dnl Usage: WINE_WARNING(warning)
 531 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning)
 532 dnl Usage: WINE_PRINT_MESSAGES
 533 dnl
 534 AC_DEFUN([WINE_NOTICE],[AS_VAR_APPEND([wine_notices],["|$1"])])
 535 AC_DEFUN([WINE_WARNING],[AS_VAR_APPEND([wine_warnings],["|$1"])])
 536
 537 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 538   x)   WINE_NOTICE([$3]) ;;
 539   xno) ;;
 540   *)   AC_MSG_ERROR([$3
 541 This is an error since --with-$1 was requested.]) ;;
 542 esac])])
 543
 544 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 545   x)   WINE_WARNING([$3]) ;;
 546   xno) ;;
 547   *)   AC_MSG_ERROR([$3
 548 This is an error since --with-$1 was requested.]) ;;
 549 esac])])
 550
 551 AC_DEFUN([WINE_ERROR_WITH],[AS_IF([$2],[case "x$with_$1" in
 552   xno) ;;
 553   *)   AC_MSG_ERROR([$3
 554 Use the --without-$1 option if you really want this.]) ;;
 555 esac])])
 556
 557 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 558 if test "x$wine_notices != "x; then
 559     echo >&AS_MESSAGE_FD
 560     IFS="|"
 561     for msg in $wine_notices; do
 562         IFS="$ac_save_IFS"
 563         if test -n "$msg"; then
 564             AC_MSG_NOTICE([$msg])
 565         fi
 566     done
 567 fi
 568 IFS="|"
 569 for msg in $wine_warnings; do
 570     IFS="$ac_save_IFS"
 571     if test -n "$msg"; then
 572         echo >&2
 573         AC_MSG_WARN([$msg])
 574     fi
 575 done
 576 IFS="$ac_save_IFS"])
 577
 578 dnl Local Variables:
 579 dnl compile-command: "autoreconf --warnings=all"
 580 dnl End: