configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 # We want these before the checks, so the checks can modify their values.
  10
  11 test -z "$PROGEXT" && PROGEXT="" AC_SUBST(PROGEXT)
  12
  13 dnl **** Command-line arguments ****
  14
  15 dnl Default values
  16 MAIN_TARGET=emu
  17 LIB_TARGET=libwine.a
  18 ALT_LINK="-L\$(TOPOBJDIR) -lwine"
  19 TRACE_MSGS=yes  # the TRACE() macro
  20 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  21
  22 AC_ARG_ENABLE(emulator,
  23 [  --disable-emulator      build only the Wine library, not the emulator],
  24 [if test "$enableval" = "no"; then MAIN_TARGET="lib"; fi])
  25
  26 AC_ARG_ENABLE(dll,
  27 [  --enable-dll            build the Wine library as a DLL],
  28 [if test "$enableval" = "no"; then : ; else LIB_TARGET="libwine.so.1.0"; fi])
  29
  30 AC_ARG_ENABLE(lib,
  31 [  --disable-lib           build the Wine without building libwine.a],
  32 [if test "$enableval" = "no"; then ALT_LINK="\$(LIBOBJS) \$(X11OBJS)"; LIB_TARGET=""; fi])
  33
  34 AC_ARG_ENABLE(debug,
  35 [  --disable-debug         compile out all debugging messages],
  36 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  37
  38 AC_ARG_ENABLE(trace,
  39 [  --disable-trace         compile out TRACE messages],
  40 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  41
  42 AC_ARG_WITH(reentrant-x,
  43 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  44
  45 AC_SUBST(MAIN_TARGET)
  46 AC_SUBST(LIB_TARGET)
  47 AC_SUBST(ALT_LINK)
  48 AC_SUBST(OPTIONS)
  49
  50 if test "$DEBUG_MSGS" = "no"
  51 then
  52     AC_DEFINE(NO_DEBUG_MSGS)
  53     AC_DEFINE(NO_TRACE_MSGS)
  54 else
  55     if test "$TRACE_MSGS" = "no"
  56     then
  57         AC_DEFINE(NO_TRACE_MSGS)
  58     fi
  59 fi
  60
  61 dnl **** Check for some programs ****
  62
  63 AC_PROG_MAKE_SET
  64 AC_PROG_CC
  65 AC_PROG_CPP
  66 AC_PATH_XTRA
  67 AC_PROG_YACC
  68 AC_PROG_LEX
  69 AC_PROG_RANLIB
  70 AC_PROG_INSTALL
  71 AC_PROG_LN_S
  72 AC_CHECK_PROG(C2MAN,c2man,c2man,true)
  73 AC_PATH_PROG(LDCONFIG, ldconfig, false, /sbin:/usr/sbin:$PATH)
  74
  75 dnl Check for lint
  76 AC_CHECK_PROGS(LINT, lclint lint)
  77 if test "$LINT" = "lint"
  78 then
  79   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  80   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  81 fi
  82 AC_SUBST(LINT)
  83 AC_SUBST(LINTFLAGS)
  84
  85 dnl **** Check for some libraries ****
  86
  87 dnl Check for -lm for BeOS
  88 AC_CHECK_LIB(m,sqrt)
  89 dnl Check for -li386 for NetBSD and OpenBSD
  90 AC_CHECK_LIB(i386,i386_set_ldt)
  91 dnl Check for -lossaudio for NetBSD
  92 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  93 dnl Check for -lw for Solaris
  94 AC_CHECK_LIB(w,iswalnum)
  95 dnl Check for -lnsl for Solaris
  96 AC_CHECK_FUNCS(gethostbyname,, AC_CHECK_LIB(nsl, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl", AC_CHECK_LIB(socket, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl", , -lnsl), -lsocket))
  97 dnl Check for -lsocket for Solaris
  98 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
  99 dnl Check for -lxpg4 for FreeBSD
 100 AC_CHECK_LIB(xpg4,setrunelocale)
 101 dnl Check for -lmmap for OS/2
 102 AC_CHECK_LIB(mmap,mmap)
 103
 104 AC_CHECK_HEADERS(dlfcn.h,
 105         AC_CHECK_FUNCS(dlopen,
 106                 AC_DEFINE(HAVE_DL_API),
 107                 AC_CHECK_LIB(dl,dlopen,
 108                         AC_DEFINE(HAVE_DL_API)
 109                         LIBS="$LIBS -ldl"
 110                 )
 111         )
 112 )
 113 AC_SUBST(XLIB)
 114 if test "$have_x" = "yes"
 115 then
 116     XLIB="-lXext -lX11"
 117     ac_save_CPPFLAGS="$CPPFLAGS"
 118     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 119
 120     dnl Check for -lXpm
 121     AC_CHECK_HEADERS(X11/xpm.h)
 122     if test "$ac_cv_header_X11_xpm_h" = "yes"
 123     then
 124         AC_CHECK_LIB(Xpm,XpmCreatePixmapFromData,AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm",,$X_LIBS -lXext -lX11)
 125     fi
 126
 127     dnl Check for X Shm extension
 128     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/XShm.h)
 129     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 130     then
 131         AC_CHECK_LIB(Xext,XShmQueryExtension,AC_DEFINE(HAVE_LIBXXSHM),,$X_LIBS -lXext -lX11)
 132     fi
 133     dnl Check for XFree86 DGA / DGA 2.0 extension
 134     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/xf86dga.h)
 135     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 136     then
 137          AC_CHECK_LIB(Xxf86dga,XDGAQueryExtension,AC_DEFINE(HAVE_LIBXXF86DGA2) X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga",,$X_LIBS -lXext -lX11)
 138          AC_CHECK_LIB(Xxf86dga,XF86DGAQueryExtension,AC_DEFINE(HAVE_LIBXXF86DGA) X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga",,$X_LIBS -lXext -lX11)
 139     fi
 140
 141     dnl Check for XFree86 VMODE extension
 142     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/xf86vmode.h)
 143     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 144     then
 145         AC_CHECK_LIB(Xxf86vm,XF86VidModeQueryExtension,AC_DEFINE(HAVE_LIBXXF86VM) X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm",,$X_LIBS -lXext -lX11)
 146     fi
 147
 148     dnl Check for the presence of Mesa
 149     AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/osmesa.h)
 150     if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 151     then
 152         dnl Check for some problems due to old Mesa versions
 153         AC_CACHE_CHECK("for up-to-date Mesa version", wine_cv_mesa_version_OK,
 154           AC_TRY_COMPILE(
 155             [#include <GL/gl.h>],
 156             [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 157             [wine_cv_mesa_version_OK="yes"],
 158             [wine_cv_mesa_version_OK="no"]
 159           )
 160         )
 161
 162         if test "$wine_cv_mesa_version_OK" = "yes"
 163         then
 164             dnl Check for the presense of the library
 165             AC_CHECK_LIB(GL,glXCreateContext,AC_DEFINE(HAVE_LIBMESAGL) X_PRE_LIBS="$X_PRE_LIBS -lGL",,$X_LIBS -lXext -lX11 -lm)
 166             if test "$ac_cv_lib_GL_glXCreateContext" = "no"
 167             then
 168                 AC_CHECK_LIB(MesaGL,glXCreateContext,AC_DEFINE(HAVE_LIBMESAGL) X_PRE_LIBS="$X_PRE_LIBS -lMesaGL",,$X_LIBS -lXext -lX11 -lm)
 169             fi
 170         fi
 171     fi
 172
 173     CPPFLAGS="$ac_save_CPPFLAGS"
 174 else
 175     XLIB=""
 176     X_CFLAGS=""
 177     X_LIBS=""
 178 fi
 179
 180 dnl **** Check which curses lib to use ***
 181 AC_CHECK_HEADERS(ncurses.h)
 182 if test "$ac_cv_header_ncurses_h" = "yes"
 183 then
 184     AC_CHECK_LIB(ncurses,waddch)
 185 fi
 186 if test "$ac_cv_lib_ncurses_waddch" = "yes"
 187 then
 188     AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 189     AC_CHECK_LIB(ncurses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 190 else
 191     AC_CHECK_HEADERS(curses.h)
 192     if test "$ac_cv_header_curses_h" = "yes"
 193     then
 194        AC_CHECK_LIB(curses,waddch)
 195        AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 196        AC_CHECK_LIB(curses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 197     fi
 198 fi
 199
 200 dnl **** Check for IPX (currently Linux only) ****
 201 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 202  AC_TRY_COMPILE(
 203    [#include <sys/socket.h>
 204     #include <netipx/ipx.h>],
 205    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 206    [AC_DEFINE(HAVE_IPX_GNU)
 207     ac_cv_c_ipx_gnu="yes"],
 208    [ac_cv_c_ipx_gnu="no"])
 209  )
 210
 211 if test "$ac_cv_c_ipx_gnu" = "no"
 212 then
 213  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 214   AC_TRY_COMPILE(
 215     [#include <sys/socket.h>
 216      #include <asm/types.h>
 217      #include <linux/ipx.h>],
 218     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 219     [AC_DEFINE(HAVE_IPX_LINUX)
 220      ac_cv_c_ipx_linux="yes"],
 221     [ac_cv_c_ipx_linux="no"])
 222   )
 223 fi
 224
 225 dnl **** Check for Open Sound System ****
 226 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 227
 228 AC_CACHE_CHECK("for Open Sound System",
 229         ac_cv_c_opensoundsystem,
 230         AC_TRY_COMPILE([
 231         #if defined(HAVE_SYS_SOUNDCARD_H)
 232                 #include <sys/soundcard.h>
 233         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 234                 #include <machine/soundcard.h>
 235         #elif defined(HAVE_SOUNDCARD_H)
 236                 #include <soundcard.h>
 237         #endif
 238         ],[
 239
 240 /* check for one of the Open Sound System specific SNDCTL_ defines */
 241 #if !defined(SNDCTL_DSP_STEREO)
 242 #error No open sound system
 243 #endif
 244 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 245
 246 if test "$ac_cv_c_opensoundsystem" = "yes"
 247 then
 248     AC_DEFINE(HAVE_OSS)
 249 fi
 250
 251 AC_CACHE_CHECK("for Open Sound System/MIDI interface",
 252         ac_cv_c_opensoundsystem_midi,
 253         AC_TRY_COMPILE([
 254         #if defined(HAVE_SYS_SOUNDCARD_H)
 255                 #include <sys/soundcard.h>
 256         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 257                 #include <machine/soundcard.h>
 258         #elif defined(HAVE_SOUNDCARD_H)
 259                 #include <soundcard.h>
 260         #endif
 261         ],[
 262
 263 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 264 #if !defined(SNDCTL_SEQ_SYNC)
 265 #error No open sound system MIDI interface
 266 #endif
 267 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 268
 269 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 270 then
 271     AC_DEFINE(HAVE_OSS_MIDI)
 272 fi
 273
 274 dnl **** If ln -s doesn't work, use cp instead ****
 275 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 276
 277 dnl **** Check for gcc strength-reduce bug ****
 278
 279 if test "x${GCC}" = "xyes"
 280 then
 281   CFLAGS="$CFLAGS -Wall"
 282   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 283                   AC_TRY_RUN([
 284 int main(void) {
 285   static int Array[[3]];
 286   unsigned int B = 3;
 287   int i;
 288   for(i=0; i<B; i++) Array[[i]] = i - 3;
 289   exit( Array[[1]] != -2 );
 290 }],
 291     ac_cv_c_gcc_strength_bug="no",
 292     ac_cv_c_gcc_strength_bug="yes",
 293     ac_cv_c_gcc_strength_bug="yes") )
 294   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 295   then
 296     CFLAGS="$CFLAGS -fno-strength-reduce"
 297   fi
 298 fi
 299
 300 dnl **** Check for underscore on external symbols ****
 301
 302 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 303                ac_cv_c_extern_prefix,
 304 [saved_libs=$LIBS
 305 LIBS="conftest_asm.s $LIBS"
 306 cat > conftest_asm.s <<EOF
 307         .globl _ac_test
 308 _ac_test:
 309         .long 0
 310 EOF
 311 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 312             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 313 LIBS=$saved_libs])
 314 if test "$ac_cv_c_extern_prefix" = "yes"
 315 then
 316   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 317 fi
 318
 319 dnl **** Check for .string in assembler ****
 320
 321 AC_CACHE_CHECK("whether assembler accepts .string",
 322                ac_cv_c_asm_string,
 323 [saved_libs=$LIBS
 324 LIBS="conftest_asm.s $LIBS"
 325 cat > conftest_asm.s <<EOF
 326         .string "test"
 327 EOF
 328 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 329 LIBS=$saved_libs])
 330 if test "$ac_cv_c_asm_string" = "yes"
 331 then
 332   AC_DEFINE(HAVE_ASM_STRING)
 333 fi
 334
 335 dnl **** Check for working dll ****
 336
 337 DLLFLAGS=""
 338 BUILDFLAGS=""
 339 LDSHARED=""
 340 if test "$LIB_TARGET" = "libwine.so.1.0"
 341 then
 342   AC_CACHE_CHECK("whether we can build a Linux dll",
 343                  ac_cv_c_dll_linux,
 344   [saved_cflags=$CFLAGS
 345   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0"
 346   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 347   CFLAGS=$saved_cflags
 348   ])
 349   if test "$ac_cv_c_dll_linux" = "yes"
 350   then
 351     BUILDFLAGS="-pic"
 352     DLLFLAGS="-fPIC"
 353     LDSHARED="\$(CC) -shared -Wl,-soname,libwine.so"
 354   else
 355     AC_CACHE_CHECK("whether we can build a UnixWare dll",
 356                  ac_cv_c_dll_unixware,
 357     [saved_cflags=$CFLAGS
 358     CFLAGS="$CFLAGS -fPIC -Wl,-G,conftest.so.1.0"
 359     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 360     CFLAGS=$saved_cflags
 361     ])
 362     if test "$ac_cv_c_dll_unixware" = "yes"
 363     then
 364       BUILDFLAGS="-pic"
 365       DLLFLAGS="-fPIC"
 366       LDSHARED="\$(CC) -Wl,-G,-h,/usr/local/lib/libwine.so"
 367     else
 368       AC_CACHE_CHECK("whether we can build a NetBSD dll",
 369                    ac_cv_c_dll_netbsd,
 370       [saved_cflags=$CFLAGS
 371       CFLAGS="$CFLAGS -fPIC -Bshareable -Bforcearchive"
 372       AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 373       CFLAGS=$saved_cflags
 374       ])
 375       if test "$ac_cv_c_dll_netbsd" = "yes"
 376       then
 377         BUILDFLAGS="-pic"
 378         DLLFLAGS="-fPIC"
 379         LDSHARED="ld -Bshareable -Bforcearchive"
 380       fi
 381     fi
 382   fi
 383   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_unixware" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 384   then
 385     LIB_TARGET="libwine.a"
 386   fi
 387 fi
 388 AC_SUBST(BUILDFLAGS)
 389 AC_SUBST(DLLFLAGS)
 390 AC_SUBST(LDSHARED)
 391
 392 dnl **** Check for reentrant libc ****
 393 dnl
 394 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 395 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 396
 397 wine_cv_libc_reentrant=no
 398 dnl
 399 dnl Linux style errno location
 400 dnl
 401 AC_CACHE_CHECK("for reentrant libc: __errno_location", wine_cv_libc_r__errno_location,
 402   [AC_TRY_RUN([int myerrno = 0;
 403 char buf[256];
 404 int *__errno_location(){return &myerrno;}
 405 main(){connect(0,buf,255); exit(!myerrno);}],
 406   wine_cv_libc_r__errno_location=yes, wine_cv_libc_r__errno_location=no,
 407   wine_cv_libc_r__errno_location=yes )
 408 ])
 409 if test "$wine_cv_libc_r__errno_location" = "yes"
 410 then
 411     AC_DEFINE(HAVE__ERRNO_LOCATION)
 412     wine_cv_libc_reentrant=__errno_location
 413 fi
 414 dnl
 415 dnl FreeBSD style errno location
 416 dnl
 417 AC_CACHE_CHECK("for reentrant libc: __error", wine_cv_libc_r__error,
 418   [AC_TRY_RUN([int myerrno = 0;
 419 char buf[256];
 420 int *__error(){return &myerrno;}
 421 main(){connect(0,buf,255); exit(!myerrno);}],
 422     wine_cv_libc_r__error=yes, wine_cv_libc_r__error=no,
 423     wine_cv_libc_r__error=yes )
 424 ])
 425 if test "$wine_cv_libc_r__error" = "yes"
 426 then
 427     AC_DEFINE(HAVE__ERROR)
 428     wine_cv_libc_reentrant=__error
 429 fi
 430 dnl
 431 dnl Solaris style errno location
 432 dnl
 433 AC_CACHE_CHECK("for reentrant libc: ___errno", wine_cv_libc_r___errno,
 434   [AC_TRY_RUN([int myerrno = 0;
 435 char buf[256];
 436 int *___errno(){return &myerrno;}
 437 main(){connect(0,buf,255); exit(!myerrno);}],
 438     wine_cv_libc_r___errno=yes, wine_cv_libc_r___errno=no,
 439     wine_cv_libc_r___errno=yes )
 440 ])
 441 if test "$wine_cv_libc_r___errno" = "yes"
 442 then
 443     AC_DEFINE(HAVE___ERRNO)
 444     wine_cv_libc_reentrant=___errno
 445 fi
 446 dnl
 447 dnl UnixWare style errno location
 448 dnl
 449 AC_CACHE_CHECK("for reentrant libc: __thr_errno", wine_cv_libc_r__thr_errno,
 450   [AC_TRY_RUN([int myerrno = 0;
 451 char buf[256];
 452 int *__thr_errno(){return &myerrno;}
 453 main(){connect(0,buf,255); exit(!myerrno);}],
 454     wine_cv_libc_r__thr_errno=yes, wine_cv_libc_r__thr_errno=no,
 455     wine_cv_libc_r__thr_errno=yes )
 456 ])
 457 if test "$wine_cv_libc_r__thr_errno" = "yes"
 458 then
 459     AC_DEFINE(HAVE__THR_ERRNO)
 460     wine_cv_libc_reentrant=__thr_errno
 461 fi
 462 if test "$wine_cv_libc_reentrant" = "no"
 463 then
 464   AC_DEFINE(NO_REENTRANT_LIBC)
 465 fi
 466
 467 dnl **** Check for reentrant X libraries ****
 468 dnl
 469 dnl This may fail to determine whether X libraries are reentrant if
 470 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 471 dnl is possible with the --without-reentrant-x option.
 472
 473 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 474 then
 475 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 476   [ if test "x$with_reentrant_x" = "xno"
 477     then
 478         wine_cv_x_reentrant=no
 479     else
 480         libX11_check=none
 481         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 482             if test -r $dir/libX11.so; then
 483                 libX11_check="-D $dir/libX11.so"
 484                 break 1
 485             fi
 486             if test -r $dir/libX11.a; then
 487                 libX11_check="$dir/libX11.a"
 488                 break 1
 489             fi
 490         done
 491         if test "$libX11_check" != "none"; then
 492             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 493             then
 494                 wine_cv_x_reentrant=yes
 495             else
 496                 wine_cv_x_reentrant=no
 497             fi
 498         else
 499             wine_cv_x_reentrant=unknown
 500         fi
 501     fi ] )
 502 else
 503     wine_cv_x_reentrant=no
 504 fi
 505 if test "$wine_cv_x_reentrant" = "no"
 506 then
 507   AC_DEFINE(NO_REENTRANT_X11)
 508 fi
 509
 510 dnl **** Check for functions ****
 511
 512 AC_FUNC_ALLOCA()
 513 AC_CHECK_FUNCS(\
 514         _lwp_create \
 515         clone \
 516         getpagesize \
 517         memmove \
 518         rfork \
 519         sendmsg \
 520         sigaltstack \
 521         strcasecmp \
 522         strerror \
 523         strncasecmp \
 524         tcgetattr \
 525         timegm \
 526         usleep \
 527         vfscanf \
 528         wait4 \
 529         waitpid \
 530 )
 531
 532 dnl **** Check for header files ****
 533
 534 AC_CHECK_HEADERS(\
 535         arpa/nameser.h \
 536         curses.h \
 537         elf.h \
 538         float.h \
 539         libio.h \
 540         linux/cdrom.h \
 541         linux/joystick.h \
 542         linux/ucdrom.h \
 543         ncurses.h \
 544         net/if.h \
 545         netinet/in.h \
 546         resolv.h \
 547         strings.h \
 548         sys/cdio.h \
 549         sys/errno.h \
 550         sys/file.h \
 551         sys/filio.h \
 552         sys/lwp.h \
 553         sys/mman.h \
 554         sys/modem.h \
 555         sys/mount.h \
 556         sys/param.h \
 557         sys/signal.h \
 558         sys/sockio.h \
 559         sys/statfs.h \
 560         sys/strtio.h \
 561         sys/syscall.h \
 562         sys/vfs.h \
 563         syscall.h \
 564         ucontext.h \
 565         unistd.h \
 566         wctype.h \
 567 )
 568 AC_HEADER_STAT()
 569
 570 dnl **** Check for types ****
 571
 572 AC_C_CONST()
 573 AC_C_INLINE()
 574 AC_TYPE_SIZE_T()
 575 AC_CHECK_SIZEOF(long long,0)
 576
 577 if test "$ac_cv_header_linux_joystick_h" = "yes"
 578 then
 579    AC_CACHE_CHECK("whether linux/joystick.h uses the Linux 2.2+ API",
 580         wine_cv_linux_joystick_22_api,
 581         AC_TRY_COMPILE([
 582         #include <sys/ioctl.h>
 583         #include <linux/joystick.h>
 584
 585         struct js_event blub;
 586         ],/*empty*/,
 587         wine_cv_linux_joystick_22_api=yes,
 588         wine_cv_linux_joystick_22_api=no,
 589         wine_cv_linux_joystick_22_api=no
 590         )
 591    )
 592    if test "$wine_cv_linux_joystick_22_api"
 593    then
 594       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API)
 595    fi
 596 fi
 597
 598 dnl **** statfs checks ****
 599
 600 if test "$ac_cv_header_sys_vfs_h" = "yes"
 601 then
 602     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 603                     wine_cv_sys_vfs_has_statfs,
 604         AC_TRY_COMPILE([
 605         #include <sys/types.h>
 606         #ifdef HAVE_SYS_PARAM_H
 607         # include <sys/param.h>
 608         #endif
 609         #include <sys/vfs.h>
 610         ],[
 611                 struct statfs stfs;
 612
 613                 memset(&stfs,0,sizeof(stfs));
 614         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 615         )
 616     )
 617     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 618     then
 619       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 620     fi
 621 fi
 622
 623 if test "$ac_cv_header_sys_statfs_h" = "yes"
 624 then
 625     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 626                     wine_cv_sys_statfs_has_statfs,
 627         AC_TRY_COMPILE([
 628         #include <sys/types.h>
 629         #ifdef HAVE_SYS_PARAM_H
 630         # include <sys/param.h>
 631         #endif
 632         #include <sys/statfs.h>
 633         ],[
 634                 struct statfs stfs;
 635         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 636         )
 637     )
 638     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 639     then
 640       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 641     fi
 642 fi
 643
 644 if test "$ac_cv_header_sys_mount_h" = "yes"
 645 then
 646     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 647                     wine_cv_sys_mount_has_statfs,
 648         AC_TRY_COMPILE([
 649         #include <sys/types.h>
 650         #ifdef HAVE_SYS_PARAM_H
 651         # include <sys/param.h>
 652         #endif
 653         #include <sys/mount.h>
 654         ],[
 655                 struct statfs stfs;
 656         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 657         )
 658     )
 659     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 660     then
 661       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 662     fi
 663 fi
 664
 665 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 666
 667 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 668   [ if test "x$statfs_bfree" = "xno"
 669     then
 670         wine_cv_statfs_bfree=no
 671     else
 672         AC_TRY_COMPILE([
 673         #include <sys/types.h>
 674         #ifdef HAVE_SYS_PARAM_H
 675         # include <sys/param.h>
 676         #endif
 677         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 678         # include <sys/mount.h>
 679         #else
 680         # ifdef STATFS_DEFINED_BY_SYS_VFS
 681         #  include <sys/vfs.h>
 682         # else
 683         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 684         #   include <sys/statfs.h>
 685         #  endif
 686         # endif
 687         #endif
 688         ],[
 689                 struct statfs stfs;
 690
 691                 stfs.f_bfree++;
 692         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
 693         )
 694     fi ] )
 695 if test "$wine_cv_statfs_bfree" = "yes"
 696 then
 697   AC_DEFINE(STATFS_HAS_BFREE)
 698 fi
 699
 700 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
 701   [ if test "x$statfs_bavail" = "xno"
 702     then
 703         wine_cv_statfs_bavail=no
 704     else
 705         AC_TRY_COMPILE([
 706         #include <sys/types.h>
 707         #ifdef HAVE_SYS_PARAM_H
 708         # include <sys/param.h>
 709         #endif
 710         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 711         # include <sys/mount.h>
 712         #else
 713         # ifdef STATFS_DEFINED_BY_SYS_VFS
 714         #  include <sys/vfs.h>
 715         # else
 716         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 717         #   include <sys/statfs.h>
 718         #  endif
 719         # endif
 720         #endif
 721         ],[
 722                 struct statfs stfs;
 723
 724                 stfs.f_bavail++;
 725         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
 726         )
 727     fi ] )
 728 if test "$wine_cv_statfs_bavail" = "yes"
 729 then
 730   AC_DEFINE(STATFS_HAS_BAVAIL)
 731 fi
 732
 733 dnl *** check for working sigaltstack
 734 dnl glibc 2.0x defines it, but it always fails... so it is useless for us.
 735
 736 AC_CACHE_CHECK("for working sigaltstack",
 737         ac_cv_c_working_sigaltstack,
 738         AC_TRY_RUN([
 739         #include <stdio.h>
 740         #include <time.h> /* <sys/time.h> ? bad magic without end */
 741         #include <sys/types.h>
 742         #include <sys/signal.h>
 743         #ifdef HAVE_SYS_PARAM_H
 744         # include <sys/param.h>
 745         #endif
 746         #ifdef HAVE_SYSCALL_H
 747         # include <syscall.h>
 748         #else
 749         # ifdef HAVE_SYS_SYSCALL_H
 750         #  include <sys/syscall.h>
 751         # endif
 752         #endif
 753
 754         unsigned char *xaltstack;
 755
 756         int
 757         main(int argc,char **argv) {
 758             struct sigaltstack  ss;
 759
 760             xaltstack = malloc(16384);
 761             ss.ss_sp    = xaltstack;
 762             ss.ss_size  = 16384;
 763             ss.ss_flags = 0;
 764             if (sigaltstack(&ss, NULL) < 0) {
 765                 /* this catches the glibc case */
 766                 perror("sigaltstack");
 767                 return (1); /* aka exit(1) aka fail */
 768             }
 769             /* assume it works. */
 770             return 0; /* OK */
 771         }
 772         ],
 773         ac_cv_c_working_sigaltstack="yes",
 774         ac_cv_c_working_sigaltstack="no",
 775         ac_cv_c_working_sigaltstack="no"
 776 ))
 777
 778 if test "$ac_cv_c_working_sigaltstack" = "yes"
 779 then
 780     AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 781 fi
 782
 783
 784 dnl *** check for file descriptor passing with msg_accrights
 785
 786 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
 787  AC_TRY_COMPILE([#include <sys/types.h>
 788 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
 789                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
 790 if test "$ac_cv_c_msg_accrights" = "yes"
 791 then
 792     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
 793 fi
 794
 795 dnl *** check for the need to define __i386__
 796
 797 AC_CACHE_CHECK("whether we need to define __i386__",ac_cv_cpp_def_i386,
 798  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
 799 yes
 800 #endif],
 801  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
 802 if test "$ac_cv_cpp_def_i386" = "yes"
 803 then
 804     CFLAGS="$CFLAGS -D__i386__"
 805     LINTFLAGS="$LINTFLAGS -D__i386__"
 806 fi
 807
 808 dnl $GCC is set by autoconf
 809 GCC_NO_BUILTIN=""
 810 if test "$GCC" = "yes"
 811 then
 812     GCC_NO_BUILTIN="-fno-builtin"
 813 fi
 814 AC_SUBST(GCC_NO_BUILTIN)
 815
 816 dnl **** Generate output files ****
 817
 818 MAKE_RULES=Make.rules
 819 AC_SUBST_FILE(MAKE_RULES)
 820
 821 AC_OUTPUT([
 822 Make.rules
 823 Makefile
 824 console/Makefile
 825 controls/Makefile
 826 debugger/Makefile
 827 dlls/Makefile
 828 dlls/advapi32/Makefile
 829 dlls/avifil32/Makefile
 830 dlls/comctl32/Makefile
 831 dlls/commdlg/Makefile
 832 dlls/crtdll/Makefile
 833 dlls/dciman32/Makefile
 834 dlls/dplayx/Makefile
 835 dlls/imagehlp/Makefile
 836 dlls/imm32/Makefile
 837 dlls/lzexpand/Makefile
 838 dlls/mpr/Makefile
 839 dlls/msacm/Makefile
 840 dlls/msacm32/Makefile
 841 dlls/msnet32/Makefile
 842 dlls/msvideo/Makefile
 843 dlls/ntdll/Makefile
 844 dlls/ole32/Makefile
 845 dlls/oleaut32/Makefile
 846 dlls/olecli/Makefile
 847 dlls/oledlg/Makefile
 848 dlls/olesvr/Makefile
 849 dlls/psapi/Makefile
 850 dlls/rasapi32/Makefile
 851 dlls/shell32/Makefile
 852 dlls/sound/Makefile
 853 dlls/stress/Makefile
 854 dlls/tapi32/Makefile
 855 dlls/ver/Makefile
 856 dlls/version/Makefile
 857 dlls/win32s/Makefile
 858 dlls/win87em/Makefile
 859 dlls/winaspi/Makefile
 860 dlls/windebug/Makefile
 861 dlls/winmm/Makefile
 862 dlls/winmm/wineoss/Makefile
 863 dlls/wing/Makefile
 864 dlls/winspool/Makefile
 865 dlls/wnaspi32/Makefile
 866 documentation/Makefile
 867 documentation/wine.conf.man
 868 documentation/wine.man
 869 files/Makefile
 870 graphics/Makefile
 871 graphics/enhmetafiledrv/Makefile
 872 graphics/metafiledrv/Makefile
 873 graphics/psdrv/Makefile
 874 graphics/ttydrv/Makefile
 875 graphics/win16drv/Makefile
 876 graphics/x11drv/Makefile
 877 if1632/Makefile
 878 include/Makefile
 879 library/Makefile
 880 libtest/Makefile
 881 loader/Makefile
 882 loader/ne/Makefile
 883 loader/dos/Makefile
 884 memory/Makefile
 885 misc/Makefile
 886 miscemu/Makefile
 887 msdos/Makefile
 888 multimedia/Makefile
 889 objects/Makefile
 890 ole/Makefile
 891 programs/Makefile
 892 programs/clock/Makefile
 893 programs/cmdlgtst/Makefile
 894 programs/control/Makefile
 895 programs/avitools/Makefile
 896 programs/osversioncheck/Makefile
 897 programs/notepad/Makefile
 898 programs/progman/Makefile
 899 programs/regtest/Makefile
 900 programs/regapi/Makefile
 901 programs/view/Makefile
 902 programs/wcmd/Makefile
 903 programs/winhelp/Makefile
 904 programs/winver/Makefile
 905 rc/Makefile
 906 relay32/Makefile
 907 resources/Makefile
 908 scheduler/Makefile
 909 server/Makefile
 910 tools/Makefile
 911 tools/wrc/Makefile
 912 tsx11/Makefile
 913 win32/Makefile
 914 windows/Makefile
 915 windows/ttydrv/Makefile
 916 windows/x11drv/Makefile ])
 917
 918 if test "$have_x" = "no"
 919 then
 920   echo
 921   echo "*** Warning: X development files not found. Wine will be built without"
 922   echo "*** X support, which currently does not work, and would probably not be"
 923   echo "*** what you want anyway. You will need to install devel packages of"
 924   echo "*** Xlib/Xfree86 and Xpm at the very least."
 925 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
 926 then
 927   echo
 928   echo "*** Warning: Xpm development files not found. Wine will be built without"
 929   echo "*** Xpm support, which currently does not work. You will need to install"
 930   echo "*** devel packages of Xpm."
 931 fi
 932
 933 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
 934 then
 935   echo
 936   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
 937   echo "*** terminal resize support. Consider upgrading ncurses."
 938 fi
 939
 940 if test "$wine_cv_libc_reentrant" = "no"
 941 then
 942   echo
 943   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
 944   echo "*** thread support. Consider upgrading libc to a more recent"
 945   echo "*** reentrant version of libc."
 946 fi
 947
 948 if test "$wine_cv_mesa_version_OK" = "no"
 949 then
 950   echo
 951   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
 952   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)"
 953 fi
 954
 955 echo
 956 echo "Configure finished.  Do 'make depend && make' to compile Wine."
 957 echo
 958
 959 dnl Local Variables:
 960 dnl comment-start: "dnl "
 961 dnl comment-end: ""
 962 dnl comment-start-skip: "\\bdnl\\b\\s *"
 963 dnl compile-command: "autoconf"
 964 dnl End: