| blob | cda784cf6aa3e1b68c8cf6736c8577d1caec226d |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Author: Michael Patra <micky@marie.physik.tu-berlin.de>
3 dnl <patra@itp1.physik.tu-berlin.de>
4 AC_REVISION([configure.in 1.00])
5 AC_INIT(controls/edit.c)
6 AC_CONFIG_HEADER(include/config.h)
7 AC_CONFIG_AUX_DIR(tools)
9 dnl **** Command-line arguments ****
11 dnl Default values
12 LIBEXT=so # library type .so or .a
13 TRACE_MSGS=yes # the TRACE() macro
14 DEBUG_MSGS=yes # the TRACE(), WARN(), and FIXME() macros.
15 CURSES=yes
16 OPENGL=normal
18 AC_ARG_ENABLE(debug,
19 [ --disable-debug compile out all debugging messages],
20 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
22 AC_ARG_ENABLE(opengl,
23 [ --enable-opengl force usage of OpenGL even if the latter is thread-safe via pthread],
24 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
26 AC_ARG_ENABLE(trace,
27 [ --disable-trace compile out TRACE messages],
28 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
30 AC_ARG_WITH(curses,
31 [ --without-curses do not use curses],
32 [if test "$withval" = "no"; then CURSES="no"; fi])
34 AC_ARG_WITH(reentrant-x,
35 [ --without-reentrant-x compile for use with non-reentrant X libraries])
37 AC_SUBST(OPTIONS)
39 if test "$DEBUG_MSGS" = "no"
40 then
41 AC_DEFINE(NO_DEBUG_MSGS, 1, [Define if all debug messages are to be compiled out])
42 fi
44 if test "$TRACE_MSGS" = "no" -o "$DEBUG_MSGS" = "no"
45 then
46 AC_DEFINE(NO_TRACE_MSGS, 1, [Define if TRACE messages are to be compiled out])
47 fi
49 dnl **** Check for some programs ****
51 AC_PROG_MAKE_SET
52 AC_PROG_CC
53 AC_PROG_CPP
54 AC_PATH_XTRA
55 AC_PROG_YACC
56 AC_PROG_LEX
57 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
58 if test "$XLEX" = "none"
59 then
60 echo "*** Error: No suitable lex found. ***"
61 echo " Please install the 'flex' package."
62 exit 1
63 fi
64 AC_PROG_RANLIB
65 AC_PROG_INSTALL
66 AC_PROG_LN_S
67 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
68 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
69 AC_CYGWIN
70 AC_CHECK_PROG(DLLWRAP,dllwrap,dllwrap,false)
72 dnl Check for lint
73 AC_CHECK_PROGS(LINT, lclint lint)
74 if test "$LINT" = "lint"
75 then
76 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
77 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
78 fi
79 AC_SUBST(LINT)
80 AC_SUBST(LINTFLAGS)
82 if test "$CYGWIN" = "yes"
83 then
84 LDCOMBINE="ld -r --enable-stdcall-fixup"
85 else
86 LDCOMBINE="ld -r"
87 fi
88 AC_SUBST(LDCOMBINE)
90 dnl **** Check for some libraries ****
92 dnl Check for -lm
93 AC_CHECK_LIB(m,sqrt)
94 dnl Check for -li386 for NetBSD and OpenBSD
95 AC_CHECK_LIB(i386,i386_set_ldt)
96 dnl Check for -lossaudio for NetBSD
97 AC_CHECK_LIB(ossaudio,_oss_ioctl)
98 dnl Check for -lw for Solaris
99 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
100 dnl Check for -lnsl for Solaris
101 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
102 dnl Check for -lsocket for Solaris
103 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
104 dnl Check for -lxpg4 for FreeBSD
105 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
106 dnl Check for -lmmap for OS/2
107 AC_CHECK_LIB(mmap,mmap)
108 dnl Check for openpty
109 AC_CHECK_FUNCS(openpty,,
110 AC_CHECK_LIB(util,openpty,
111 AC_DEFINE(HAVE_OPENPTY)
112 LIBS="$LIBS -lutil"
113 ))
115 AC_CHECK_HEADERS(dlfcn.h,
116 AC_CHECK_FUNCS(dlopen,,
117 AC_CHECK_LIB(dl,dlopen,
118 AC_DEFINE(HAVE_DLOPEN)
119 LIBS="$LIBS -ldl",
120 LIBEXT="a")
121 ),
122 LIBEXT="a"
123 )
125 JPEGLIB=""
126 AC_SUBST(JPEGLIB)
127 AC_CHECK_HEADERS(jpeglib.h,
128 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
129 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
130 JPEGLIB="-ljpeg"
131 )
132 )
135 AC_SUBST(XLIB)
136 AC_SUBST(X_DLLS)
137 X_DLLS=""
138 AC_SUBST(XFILES)
139 XFILES=""
140 AC_SUBST(OPENGLFILES)
141 OPENGLFILES=""
142 AC_SUBST(OPENGL32_DLL)
143 OPENGL32_DLL=""
144 GLU32FILES=""
145 AC_SUBST(GLU32FILES)
146 GLU32_DLL=""
147 AC_SUBST(GLU32_DLL)
148 if test "$have_x" = "yes"
149 then
150 XLIB="-lXext -lX11"
151 ac_save_CPPFLAGS="$CPPFLAGS"
152 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
154 dnl *** Check for -lXpm
155 AC_CHECK_HEADERS(X11/xpm.h,
156 [ dnl *** If X11/xpm.h exists...
157 AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
158 [ AC_DEFINE(HAVE_LIBXXPM, 1, [Define if you have the Xpm library])
159 X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
160 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
161 )
162 ],
163 [ dnl *** If X11/xpm.h does not exist...
164 dnl NOTE: autoconf does not allow commas inside the third
165 dnl parameter to AC_CHECK_HEADERS, due to some quoting
166 dnl magic it does.
167 echo "Redhat : xpm xpm-devel"
168 echo "Caldera OpenLinux : xpm xpm-devel xpm-devel-static"
169 echo "SuSE : xpm"
170 echo "Debian/Corel Linux: xpm4g xpm4g-dev"
171 echo
172 echo "Or get the sources from ftp.x.org and all its mirror sites from "
173 echo "the directory /contrib/libraries."
174 echo
175 exit 1
176 ]
177 )
179 dnl *** All of the following tests require X11/Xlib.h
180 AC_CHECK_HEADERS(X11/Xlib.h,
181 [
182 dnl *** Check for X keyboard extension
183 AC_CHECK_HEADERS(X11/XKBlib.h,
184 [ dnl *** If X11/XKBlib.h exists...
185 AC_CHECK_LIB(X11, XkbQueryExtension,
186 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
187 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
188 ],
189 AC_MSG_WARN([XKB extension not found!!])
190 )
192 dnl *** Check for X Shm extension
193 AC_CHECK_HEADERS(X11/extensions/XShm.h,
194 [ dnl *** If X11/extensions/XShm.h exists...
195 AC_CHECK_LIB(Xext, XShmQueryExtension,
196 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
197 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
198 ],
199 AC_MSG_WARN([Xshm extension not found!!])
200 )
202 dnl *** Check for X shape extension
203 AC_CHECK_HEADERS(X11/extensions/shape.h,
204 [ dnl *** If X11/extensions/shape.h exists...
205 AC_CHECK_LIB(Xext,XShapeQueryExtension,
206 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
207 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
208 ],
209 AC_MSG_WARN([XShape extension not found!!])
210 )
212 dnl *** Check for XFree86 DGA / DGA 2.0 extension
213 AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
214 [ dnl *** If X11/extensions/xf86dga.h exists, check
215 dnl *** for XDGAQueryExtension()...
216 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
217 [ dnl *** If found...
218 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
219 [Define if you have the Xxf86dga library version 2])
220 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
221 ],
222 [ dnl *** If not found, look for XF86DGAQueryExtension()
223 dnl *** instead (DGA 2.0 not found)...
224 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
225 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
226 [Define if you have the Xxf86dga library version 1])
227 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
228 ],,
229 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
230 )
231 ],
232 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
233 )
234 ],
235 AC_MSG_WARN([DGA extension not found!!])
236 )
238 dnl *** Check for XFree86 VMODE extension
239 AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
240 [ dnl *** If X11/extensions/xf86vmode.h exists...
241 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
242 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
243 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
244 ],,
245 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
246 )
247 ],
248 AC_MSG_WARN([XFree86 VMODE extension not found!!])
249 )
251 dnl *** Check for XVideo extension supporting XvImages
252 AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
253 [ dnl *** If X11/extensions/Xvlib.h exists...
254 AC_CHECK_LIB(Xv, XvShmCreateImage,
255 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
256 X_PRE_LIBS="$X_PRE_LIBS -lXv"
257 ],,
258 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
259 )
260 ],
261 AC_MSG_WARN([XVideo extension not found !!])
262 )
264 dnl *** Check for XRender extension
265 AC_CHECK_HEADERS(X11/extensions/Xrender.h,
266 [ dnl *** If X11/extensions/Xrender.h exists...
267 AC_CHECK_LIB(Xrender, XRenderQueryExtension,
268 [ AC_DEFINE(HAVE_LIBXRENDER, 1, [Define if you have the XRender extension library])
269 X_PRE_LIBS="$X_PRE_LIBS -lXrender"
270 ],,
271 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
272 )
273 ],
274 AC_MSG_WARN([XRender extension not found !!])
275 )
277 ]
278 ) dnl *** End of X11/Xlib.h check
280 dnl Check for the presence of OpenGL
281 if test $OPENGL = "yes" -o $OPENGL = "normal"
282 then
283 AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
284 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
285 then
286 dnl Check for some problems due to old Mesa versions
287 AC_CACHE_CHECK("for up-to-date OpenGL version", wine_cv_opengl_version_OK,
288 AC_TRY_COMPILE(
289 [#include <GL/gl.h>],
290 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
291 [wine_cv_opengl_version_OK="yes"],
292 [wine_cv_opengl_version_OK="no"]
293 )
294 )
296 dnl Check for the thread-safety of the OpenGL library
297 AC_CACHE_CHECK("for thread-safe OpenGL version",
298 wine_cv_opengl_version_threadsafe,
299 [saved_libs=$LIBS
300 LIBS="$X_LIBS -lGL"
301 AC_TRY_LINK([],[pthread_getspecific();],
302 [wine_cv_opengl_version_threadsafe="yes"],
303 [wine_cv_opengl_version_threadsafe="no"])
304 LIBS=$saved_libs]
305 )
307 if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
308 then
309 dnl Check for the presence of the library
310 AC_CHECK_LIB(GL,glXCreateContext,
311 X_PRE_LIBS="$X_PRE_LIBS -lGL"
312 ,,
313 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
315 if test $ac_cv_lib_GL_glXCreateContext = "yes"
316 then
318 OPENGLFILES='$(OPENGLFILES)'
319 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
321 AC_CHECK_LIB(GL,glXGetProcAddressARB,
322 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
323 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
324 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
326 if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
327 then
328 AC_CACHE_CHECK("for OpenGL extension functions prototypes", wine_cv_extension_prototypes,
329 AC_TRY_COMPILE([#include <GL/gl.h>
330 #ifdef HAVE_GL_GLEXT_H
331 # include <GL/glext.h>
332 #endif
333 ],
334 [PFNGLCOLORTABLEEXTPROC test_proc;],
335 [wine_cv_extension_prototypes="yes"],
336 [wine_cv_extension_prototypes="no"]
337 )
338 )
339 if test $wine_cv_extension_prototypes = "yes"
340 then
341 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
342 [Define if the OpenGL headers define extension typedefs])
343 fi
345 OPENGL32_DLL=opengl32
346 fi
348 fi
349 dnl Check for GLU32 library.
350 AC_CHECK_LIB(GLU,gluLookAt,
351 X_PRE_LIBS="$X_PRE_LIBS -lGLU"
352 GLU32FILES='$(GLU32FILES)'
353 GLU32_DLL=glu32
354 ,,
355 $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
356 )
357 fi
358 fi
359 fi
361 CPPFLAGS="$ac_save_CPPFLAGS"
362 X_DLLS='$(X_DLLS)'
363 XFILES='$(XFILES)'
364 else
365 XLIB=""
366 X_CFLAGS=""
367 X_LIBS=""
368 fi
370 dnl **** Check which curses lib to use ***
371 if test "$CURSES" = "yes"
372 then
373 AC_CHECK_HEADERS(ncurses.h,
374 AC_CHECK_LIB(ncurses,waddch),
375 AC_CHECK_HEADERS(curses.h,AC_CHECK_LIB(curses,waddch)))
376 AC_CHECK_FUNCS(getbkgd resizeterm)
377 fi
379 CUPSLIBS=""
380 dnl **** Check for CUPS ****
381 wine_cv_warn_cups_h=no
382 AC_CHECK_LIB(cups,cupsGetPPD,
383 AC_CHECK_HEADER(cups/cups.h,
384 AC_DEFINE(HAVE_CUPS, 1, [Define if we have CUPS])
385 CUPSLIBS="-lcups",
386 wine_cv_warn_cups_h=yes)
387 )
388 AC_SUBST(CUPSLIBS)
390 dnl **** Check for FreeType 2 ****
391 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no)
392 if test "$ft_lib" = "no"
393 then
394 FREETYPELIBS=""
395 FREETYPEINCL=""
396 wine_cv_msg_freetype=no
397 else
398 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
399 if test "$ft_devel" = "no"
400 then
401 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
402 if test "$ft_devel2" = "freetype2-config"
403 then
404 ft_devel=$ft_devel2
405 fi
406 fi
407 if test "$ft_devel" = "no"
408 then
409 FREETYPELIBS=""
410 FREETYPEINCL=""
411 wine_cv_msg_freetype=yes
412 else
413 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
414 FREETYPELIBS=`$ft_devel --libs`
415 FREETYPEINCL=`$ft_devel --cflags`
416 ac_save_CPPFLAGS="$CPPFLAGS"
417 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
418 AC_CHECK_HEADERS(freetype/freetype.h \
419 freetype/ftglyph.h \
420 freetype/tttables.h \
421 freetype/ftnames.h \
422 freetype/ftsnames.h \
423 freetype/ttnameid.h \
424 freetype/ftoutln.h)
425 CPPFLAGS="$ac_save_CPPFLAGS"
426 wine_cv_msg_freetype=no
427 fi
428 fi
429 AC_SUBST(FREETYPELIBS)
430 AC_SUBST(FREETYPEINCL)
432 dnl **** Check for parport (currently Linux only) ****
433 AC_CACHE_CHECK("for parport header/ppdev.h", ac_cv_c_ppdev,
434 AC_TRY_COMPILE(
435 [#include <linux/ppdev.h>],
436 [ioctl (1,PPCLAIM,0)],
437 [ac_cv_c_ppdev="yes"],
438 [ac_cv_c_ppdev="no"])
439 )
440 if test "$ac_cv_c_ppdev" = "yes"
441 then
442 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
443 fi
445 dnl **** Check for IPX (currently Linux only) ****
446 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
447 AC_TRY_COMPILE(
448 [#include <sys/socket.h>
449 #include <netipx/ipx.h>],
450 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
451 [ac_cv_c_ipx_gnu="yes"],
452 [ac_cv_c_ipx_gnu="no"])
453 )
454 if test "$ac_cv_c_ipx_gnu" = "yes"
455 then
456 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
457 fi
459 if test "$ac_cv_c_ipx_gnu" = "no"
460 then
461 AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
462 AC_TRY_COMPILE(
463 [#include <sys/socket.h>
464 #include <asm/types.h>
465 #include <linux/ipx.h>],
466 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
467 [ac_cv_c_ipx_linux="yes"],
468 [ac_cv_c_ipx_linux="no"])
469 )
470 if test "$ac_cv_c_ipx_linux" = "yes"
471 then
472 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
473 fi
474 fi
476 dnl **** Check for Open Sound System ****
477 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
479 AC_CACHE_CHECK("for Open Sound System",
480 ac_cv_c_opensoundsystem,
481 AC_TRY_COMPILE([
482 #if defined(HAVE_SYS_SOUNDCARD_H)
483 #include <sys/soundcard.h>
484 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
485 #include <machine/soundcard.h>
486 #elif defined(HAVE_SOUNDCARD_H)
487 #include <soundcard.h>
488 #endif
489 ],[
491 /* check for one of the Open Sound System specific SNDCTL_ defines */
492 #if !defined(SNDCTL_DSP_STEREO)
493 #error No open sound system
494 #endif
495 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
497 if test "$ac_cv_c_opensoundsystem" = "yes"
498 then
499 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
500 fi
502 AC_CACHE_CHECK("for Open Sound System/MIDI interface",
503 ac_cv_c_opensoundsystem_midi,
504 AC_TRY_COMPILE([
505 #if defined(HAVE_SYS_SOUNDCARD_H)
506 #include <sys/soundcard.h>
507 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
508 #include <machine/soundcard.h>
509 #elif defined(HAVE_SOUNDCARD_H)
510 #include <soundcard.h>
511 #endif
512 ],[
514 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
515 #if !defined(SNDCTL_SEQ_SYNC)
516 #error No open sound system MIDI interface
517 #endif
518 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
520 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
521 then
522 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
523 fi
525 dnl **** If ln -s doesn't work, use cp instead ****
526 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
528 dnl **** Check for broken glibc mmap64 ****
530 AC_CACHE_CHECK( "whether mmap64 works defined as mmap", ac_cv_mmap64_works,
531 AC_TRY_RUN([
532 #define _FILE_OFFSET_BITS 64
533 #include <stdio.h>
534 #include <unistd.h>
535 #include <fcntl.h>
536 #include <sys/mman.h>
537 #include <errno.h>
539 int main(int argc,char **argv) {
540 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
541 if (fd == -1) exit(1);
543 unlink("conftest.map");
545 write(fd,"test",4);
547 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
548 (errno == EINVAL)
549 ) {
550 exit(1);
551 }
552 close(fd);
553 fprintf(stderr,"success!\n");
554 exit(0);
555 }
557 ],
558 ac_cv_mmap64_works="yes",
559 ac_cv_mmap64_works="no",
560 ac_cv_mmap64_works="no") )
562 if test "$ac_cv_mmap64_works" = "yes"
563 then
564 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
565 fi
567 dnl **** Check for gcc strength-reduce bug ****
569 if test "x${GCC}" = "xyes"
570 then
571 CFLAGS="$CFLAGS -Wall"
572 AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
573 AC_TRY_RUN([
574 int L[[4]] = {0,1,2,3};
575 int main(void) {
576 static int Array[[3]];
577 unsigned int B = 3;
578 int i;
579 for(i=0; i<B; i++) Array[[i]] = i - 3;
580 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
581 L[[i]] = 4;
583 exit( Array[[1]] != -2 || L[[2]] != 3);
584 }],
585 ac_cv_c_gcc_strength_bug="no",
586 ac_cv_c_gcc_strength_bug="yes",
587 ac_cv_c_gcc_strength_bug="yes") )
588 if test "$ac_cv_c_gcc_strength_bug" = "yes"
589 then
590 CFLAGS="$CFLAGS -fno-strength-reduce"
591 fi
593 dnl Check for -mpreferred-stack-boundary
594 AC_CACHE_CHECK("for gcc -mpreferred-stack-boundary=2 support",
595 ac_cv_c_gcc_stack_boundary,
596 [saved_cflags=$CFLAGS
597 CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
598 AC_TRY_COMPILE(,[return 0],ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")
599 CFLAGS=$saved_cflags
600 ])
601 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
602 then
603 CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
604 fi
605 fi
607 dnl **** Check if we need to place .type inside a .def directive ****
609 AC_CACHE_CHECK("whether .type must sit inside a .def directive",
610 ac_cv_c_type_in_def,
611 [saved_libs=$LIBS
612 LIBS="conftest_asm.s $LIBS"
613 cat > conftest_asm.s <<EOF
614 .globl _ac_test
615 .def _ac_test; .scl 2; .type 32; .endef
616 _ac_test:
617 .long 0
618 EOF
619 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
620 LIBS=$saved_libs])
621 if test "$ac_cv_c_type_in_def" = "yes"
622 then
623 AC_DEFINE(NEED_TYPE_IN_DEF, 1, [Define if .type asm directive must be inside a .def directive])
624 fi
626 dnl **** Check for underscore on external symbols ****
628 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
629 ac_cv_c_extern_prefix,
630 [saved_libs=$LIBS
631 LIBS="conftest_asm.s $LIBS"
632 cat > conftest_asm.s <<EOF
633 .globl _ac_test
634 _ac_test:
635 .long 0
636 EOF
637 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
638 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
639 LIBS=$saved_libs])
640 if test "$ac_cv_c_extern_prefix" = "yes"
641 then
642 AC_DEFINE(NEED_UNDERSCORE_PREFIX, 1,
643 [Define if symbols declared in assembly code need an underscore prefix])
644 fi
646 dnl **** Check for .string in assembler ****
648 AC_CACHE_CHECK("whether assembler accepts .string",
649 ac_cv_c_asm_string,
650 [saved_libs=$LIBS
651 LIBS="conftest_asm.s $LIBS"
652 cat > conftest_asm.s <<EOF
653 .string "test"
654 EOF
655 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
656 LIBS=$saved_libs])
657 if test "$ac_cv_c_asm_string" = "yes"
658 then
659 AC_DEFINE(HAVE_ASM_STRING, 1, [Define to use .string instead of .ascii])
660 fi
662 dnl **** Check for working dll ****
664 LDSHARED=""
665 LDDLLFLAGS=""
666 if test "$LIBEXT" = "so"
667 then
668 AC_CACHE_CHECK("whether we can build a GNU style ELF dll",
669 ac_cv_c_dll_gnuelf,
670 [saved_cflags=$CFLAGS
671 CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
672 AC_TRY_LINK(,[return 1],ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")
673 CFLAGS=$saved_cflags
674 ])
675 if test "$ac_cv_c_dll_gnuelf" = "yes"
676 then
677 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
678 LDDLLFLAGS="-Wl,-Bsymbolic"
679 else
680 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
681 ac_cv_c_dll_unixware,
682 [saved_cflags=$CFLAGS
683 CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
684 AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
685 CFLAGS=$saved_cflags
686 ])
687 if test "$ac_cv_c_dll_unixware" = "yes"
688 then
689 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
690 LDDLLFLAGS="-Wl,-B,symbolic"
691 fi
692 fi
693 if test "$ac_cv_c_dll_gnuelf" = "no" -a "$ac_cv_c_dll_unixware" = "no"
694 then
695 LIBEXT="a"
696 if test "$DLLWRAP" = "dllwrap"; then
697 dnl FIXME - check whether dllwrap works correctly...
698 if test "$CYGWIN" = "yes"; then
699 echo "*** use dllwrap for building shared library."
700 LIBEXT="dll"
701 fi
702 fi
703 fi
704 fi
706 if test "$LIBEXT" = "a"; then
707 echo "*** It is currently not possible to build WINE without shared"
708 echo "*** library (.so) support to allow transparent switch between .so"
709 echo "*** and .dll files."
710 echo "*** If you are using Linux, you will need a newer binutils."
711 exit 1
712 fi
714 DLLFLAGS=""
715 LDPATH=""
717 if test "$LIBEXT" = "so"; then
718 DLLFLAGS="-fPIC"
719 DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
720 LDPATH="LD_LIBRARY_PATH=\"\$(TOPOBJDIR)/unicode:\$\$LD_LIBRARY_PATH\""
721 elif test "$LIBEXT" = "dll"; then
722 #DLLFLAGS="-fPIC" # -fPIC doesn't work(at least in cygwin-b20) - FIXME
723 DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
724 LDPATH="PATH=\"\$(TOPOBJDIR)/unicode:\$\$PATH\""
725 else
726 DLL_LINK="-L\$(DLLDIR) \$(DLLS:%=-l%) \$(LIBWINE) \$(LIBUNICODE) \$(X_LIBS) \$(XLIB)"
727 AC_CACHE_CHECK([whether the linker supports --[[no]]-whole-archive (Linux)],
728 ac_cv_c_whole_archive,
729 [saved_cflags=$CFLAGS
730 CFLAGS="$CFLAGS -Wl,--whole-archive -Wl,--no-whole-archive"
731 AC_TRY_LINK(,[return 1],ac_cv_c_whole_archive="yes",ac_cv_c_whole_archive="no")
732 CFLAGS=$saved_cflags
733 ])
734 if test "$ac_cv_c_whole_archive" = "yes"
735 then
736 DLL_LINK="-Wl,--whole-archive $DLL_LINK -Wl,--no-whole-archive"
737 else
738 AC_CACHE_CHECK([whether the linker supports -z {all,default}extract (Linux)],
739 ac_cv_c_allextract,
740 [saved_cflags=$CFLAGS
741 CFLAGS="$CFLAGS -Wl,-z,allextract -Wl,-z,defaultextract"
742 AC_TRY_LINK(,[return 1],ac_cv_c_allextract="yes",ac_cv_c_allextract="no")
743 CFLAGS=$saved_cflags
744 ])
745 if test "$ac_cv_c_allextract" = "yes"
746 then
747 DLL_LINK="-Wl,-z,allextract $DLL_LINK -Wl,-z,defaultextract"
748 fi
749 fi
750 fi
752 AC_SUBST(DLL_LINK)
753 AC_SUBST(DLLFLAGS)
754 AC_SUBST(LDSHARED)
755 AC_SUBST(LDDLLFLAGS)
756 AC_SUBST(LIBEXT)
757 AC_SUBST(LDPATH)
759 dnl **** Check for reentrant libc ****
760 dnl
761 dnl For cross-compiling we blindly assume that libc is reentrant. This is
762 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
764 AC_DEFUN(WINE_CHECK_ERRNO,
765 [
766 AC_CACHE_CHECK(for reentrant libc: $1, wine_cv_libc_r_$1,
767 [AC_TRY_RUN([int myerrno = 0;
768 char buf[256];
769 int *$1(){return &myerrno;}
770 main(){connect(0,buf,255); exit(!myerrno);}],
771 wine_cv_libc_r_$1=yes, wine_cv_libc_r_$1=no,
772 wine_cv_libc_r_$1=yes )
773 ])
774 if test "$wine_cv_libc_r_$1" = "yes"
775 then
776 wine_cv_libc_reentrant=$1
777 fi
778 ])
780 wine_cv_libc_reentrant=no
781 dnl Linux style errno location
782 WINE_CHECK_ERRNO(__errno_location)
783 dnl FreeBSD style errno location
784 WINE_CHECK_ERRNO(__error)
785 dnl Solaris style errno location
786 WINE_CHECK_ERRNO(___errno)
787 dnl UnixWare style errno location
788 WINE_CHECK_ERRNO(__thr_errno)
789 dnl NetBSD style errno location
790 WINE_CHECK_ERRNO(__errno)
792 if test "$wine_cv_libc_reentrant" != "no"
793 then
794 AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant,
795 [Define to the name of the function returning errno for reentrant libc])
796 fi
798 dnl **** Check for reentrant X libraries ****
799 dnl
800 dnl This may fail to determine whether X libraries are reentrant if
801 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
802 dnl is possible with the --without-reentrant-x option.
804 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
805 then
806 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
807 [ if test "x$with_reentrant_x" = "xno"
808 then
809 wine_cv_x_reentrant=no
810 else
811 libX11_check=none
812 for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
813 if test -r $dir/libX11.so; then
814 libX11_check="-D $dir/libX11.so"
815 break 1
816 fi
817 if test -r $dir/libX11.a; then
818 libX11_check="$dir/libX11.a"
819 break 1
820 fi
821 done
822 if test "$libX11_check" != "none"; then
823 if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
824 then
825 wine_cv_x_reentrant=yes
826 else
827 wine_cv_x_reentrant=no
828 fi
829 else
830 wine_cv_x_reentrant=unknown
831 fi
832 fi ] )
833 else
834 wine_cv_x_reentrant=no
835 fi
836 if test "$wine_cv_x_reentrant" = "no"
837 then
838 AC_DEFINE(NO_REENTRANT_X11, 1,
839 [Define if X libraries are not reentrant (compiled without -D_REENTRANT)])
840 fi
843 dnl **** Check for functions ****
845 AC_FUNC_ALLOCA()
846 AC_CHECK_FUNCS(\
847 __libc_fork \
848 _lwp_create \
849 clone \
850 ecvt \
851 finite \
852 fpclass \
853 ftruncate64 \
854 getnetbyaddr \
855 getnetbyname \
856 getpagesize \
857 getprotobyname \
858 getprotobynumber \
859 getrlimit \
860 getservbyport \
861 getsockopt \
862 inet_network \
863 lseek64 \
864 lstat \
865 memmove \
866 mmap \
867 rfork \
868 select \
869 sendmsg \
870 settimeofday \
871 sigaltstack \
872 statfs \
873 strcasecmp \
874 strerror \
875 strncasecmp \
876 tcgetattr \
877 timegm \
878 usleep \
879 vfscanf \
880 wait4 \
881 waitpid \
882 )
884 dnl **** Check for header files ****
886 AC_CHECK_HEADERS(\
887 arpa/inet.h \
888 arpa/nameser.h \
889 elf.h \
890 float.h \
891 ieeefp.h \
892 libio.h \
893 libutil.h \
894 link.h \
895 linux/cdrom.h \
896 linux/input.h \
897 linux/joystick.h \
898 linux/ucdrom.h \
899 net/if.h \
900 netdb.h \
901 netinet/in.h \
902 netinet/in_systm.h \
903 netinet/ip.h \
904 netinet/tcp.h \
905 pty.h \
906 resolv.h \
907 sched.h \
908 socket.h \
909 strings.h \
910 sys/cdio.h \
911 sys/errno.h \
912 sys/file.h \
913 sys/filio.h \
914 sys/ipc.h \
915 sys/link.h \
916 sys/lwp.h \
917 sys/mman.h \
918 sys/modem.h \
919 sys/mount.h \
920 sys/msg.h \
921 sys/param.h \
922 sys/ptrace.h \
923 sys/reg.h \
924 sys/signal.h \
925 sys/shm.h \
926 sys/socket.h \
927 sys/sockio.h \
928 sys/statfs.h \
929 sys/strtio.h \
930 sys/syscall.h \
931 sys/user.h \
932 sys/wait.h \
933 sys/v86.h \
934 sys/v86intr.h \
935 sys/vfs.h \
936 sys/vm86.h \
937 syscall.h \
938 ucontext.h \
939 )
940 AC_HEADER_STAT()
942 dnl **** Check for types ****
944 AC_C_CONST()
945 AC_C_INLINE()
946 AC_TYPE_SIZE_T()
947 AC_CHECK_SIZEOF(long long,0)
949 AC_CACHE_CHECK("whether linux/input.h is for real",
950 wine_cv_linux_input_h,
951 AC_TRY_COMPILE([
952 #include <linux/input.h>
953 ] , [
954 int foo = EVIOCGBIT(EV_ABS,42);
955 int bar = BTN_PINKIE;
956 int fortytwo = 42;
957 ],
958 wine_cv_linux_input_h=yes,
959 wine_cv_linux_input_h=no,
960 no
961 )
962 )
963 if test "$wine_cv_linux_input_h" = "yes"
964 then
965 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
966 [Define if we have linux/input.h AND it contains the INPUT event API])
967 fi
970 AC_CACHE_CHECK("whether we can use re-entrant gethostbyname_r Linux style",
971 wine_cv_linux_gethostbyname_r_6,
972 AC_TRY_COMPILE([
973 #include <netdb.h>
974 ], [
975 char *name=NULL;
976 struct hostent he;
977 struct hostent *result;
978 char *buf=NULL;
979 int bufsize=0;
980 int res,errnr;
981 char *addr=NULL;
982 int addrlen=0;
983 int addrtype=0;
984 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
985 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
986 ],
987 wine_cv_linux_gethostbyname_r_6=yes,
988 wine_cv_linux_gethostbyname_r_6=no
989 )
990 )
991 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
992 then
993 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
994 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
995 fi
997 if test "$ac_cv_header_linux_joystick_h" = "yes"
998 then
999 AC_CACHE_CHECK("whether linux/joystick.h uses the Linux 2.2+ API",
1000 wine_cv_linux_joystick_22_api,
1001 AC_TRY_COMPILE([
1002 #include <sys/ioctl.h>
1003 #include <linux/joystick.h>
1005 struct js_event blub;
1006 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1007 #error "no 2.2 header"
1008 #endif
1009 ],/*empty*/,
1010 wine_cv_linux_joystick_22_api=yes,
1011 wine_cv_linux_joystick_22_api=no,
1012 wine_cv_linux_joystick_22_api=no
1013 )
1014 )
1015 if test "$wine_cv_linux_joystick_22_api" = "yes"
1016 then
1017 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1018 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1019 fi
1020 fi
1022 dnl **** statfs checks ****
1024 if test "$ac_cv_header_sys_vfs_h" = "yes"
1025 then
1026 AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
1027 wine_cv_sys_vfs_has_statfs,
1028 AC_TRY_COMPILE([
1029 #include <sys/types.h>
1030 #ifdef HAVE_SYS_PARAM_H
1031 # include <sys/param.h>
1032 #endif
1033 #include <sys/vfs.h>
1034 ],[
1035 struct statfs stfs;
1037 memset(&stfs,0,sizeof(stfs));
1038 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1039 )
1040 )
1041 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1042 then
1043 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1044 [Define if the struct statfs is defined by <sys/vfs.h>])
1045 fi
1046 fi
1048 if test "$ac_cv_header_sys_statfs_h" = "yes"
1049 then
1050 AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
1051 wine_cv_sys_statfs_has_statfs,
1052 AC_TRY_COMPILE([
1053 #include <sys/types.h>
1054 #ifdef HAVE_SYS_PARAM_H
1055 # include <sys/param.h>
1056 #endif
1057 #include <sys/statfs.h>
1058 ],[
1059 struct statfs stfs;
1060 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1061 )
1062 )
1063 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1064 then
1065 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1066 [Define if the struct statfs is defined by <sys/statfs.h>])
1067 fi
1068 fi
1070 if test "$ac_cv_header_sys_mount_h" = "yes"
1071 then
1072 AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
1073 wine_cv_sys_mount_has_statfs,
1074 AC_TRY_COMPILE([
1075 #include <sys/types.h>
1076 #ifdef HAVE_SYS_PARAM_H
1077 # include <sys/param.h>
1078 #endif
1079 #include <sys/mount.h>
1080 ],[
1081 struct statfs stfs;
1082 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1083 )
1084 )
1085 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1086 then
1087 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1088 [Define if the struct statfs is defined by <sys/mount.h>])
1089 fi
1090 fi
1092 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1094 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
1095 [ if test "x$statfs_bfree" = "xno"
1096 then
1097 wine_cv_statfs_bfree=no
1098 else
1099 AC_TRY_COMPILE([
1100 #include <sys/types.h>
1101 #ifdef HAVE_SYS_PARAM_H
1102 # include <sys/param.h>
1103 #endif
1104 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1105 # include <sys/mount.h>
1106 #else
1107 # ifdef STATFS_DEFINED_BY_SYS_VFS
1108 # include <sys/vfs.h>
1109 # else
1110 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1111 # include <sys/statfs.h>
1112 # endif
1113 # endif
1114 #endif
1115 ],[
1116 struct statfs stfs;
1118 stfs.f_bfree++;
1119 ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
1120 )
1121 fi ] )
1122 if test "$wine_cv_statfs_bfree" = "yes"
1123 then
1124 AC_DEFINE(STATFS_HAS_BFREE, 1, [Define if the struct statfs has the member bfree])
1125 fi
1127 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
1128 [ if test "x$statfs_bavail" = "xno"
1129 then
1130 wine_cv_statfs_bavail=no
1131 else
1132 AC_TRY_COMPILE([
1133 #include <sys/types.h>
1134 #ifdef HAVE_SYS_PARAM_H
1135 # include <sys/param.h>
1136 #endif
1137 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1138 # include <sys/mount.h>
1139 #else
1140 # ifdef STATFS_DEFINED_BY_SYS_VFS
1141 # include <sys/vfs.h>
1142 # else
1143 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1144 # include <sys/statfs.h>
1145 # endif
1146 # endif
1147 #endif
1148 ],[
1149 struct statfs stfs;
1151 stfs.f_bavail++;
1152 ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1153 )
1154 fi ] )
1155 if test "$wine_cv_statfs_bavail" = "yes"
1156 then
1157 AC_DEFINE(STATFS_HAS_BAVAIL, 1, [Define if the struct statfs has the member bavail])
1158 fi
1160 dnl *** check for file descriptor passing with msg_accrights
1162 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
1163 AC_TRY_COMPILE([#include <sys/types.h>
1164 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1165 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1166 if test "$ac_cv_c_msg_accrights" = "yes"
1167 then
1168 AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS, 1, [Define if struct msghdr contains msg_accrights])
1169 fi
1171 dnl *** Check for the sa_len member in struct sockaddr
1173 AC_CACHE_CHECK("for sa_len in struct sockaddr", ac_cv_c_sockaddr_sa_len,
1174 AC_TRY_COMPILE([#include <sys/types.h>
1175 #include <sys/socket.h>
1176 ], [static struct sockaddr addr; addr.sa_len = 1],
1177 ac_cv_c_sockaddr_sa_len="yes", ac_cv_c_sockaddr_sa_len="no"))
1178 if test "$ac_cv_c_sockaddr_sa_len" = "yes"
1179 then
1180 AC_DEFINE(HAVE_SOCKADDR_SA_LEN, 1, [Define if struct sockaddr contains sa_len])
1181 fi
1183 dnl *** Check for the sun_len member in struct sockaddr_un
1185 AC_CACHE_CHECK("for sun_len in struct sockaddr_un", ac_cv_c_sockaddr_sun_len,
1186 AC_TRY_COMPILE([#include <sys/types.h>
1187 #include <sys/socket.h>
1188 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1189 ac_cv_c_sockaddr_sun_len="yes", ac_cv_c_sockaddr_sun_len="no"))
1190 if test "$ac_cv_c_sockaddr_sun_len" = "yes"
1191 then
1192 AC_DEFINE(HAVE_SOCKADDR_SUN_LEN, 1, [Define if struct sockaddr_un contains sun_len])
1193 fi
1195 dnl *** check for the need to define __i386__
1197 AC_CACHE_CHECK("whether we need to define __i386__",ac_cv_cpp_def_i386,
1198 AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1199 yes
1200 #endif],
1201 ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1202 if test "$ac_cv_cpp_def_i386" = "yes"
1203 then
1204 CFLAGS="$CFLAGS -D__i386__"
1205 LINTFLAGS="$LINTFLAGS -D__i386__"
1206 fi
1208 dnl $GCC is set by autoconf
1209 GCC_NO_BUILTIN=""
1210 if test "$GCC" = "yes"
1211 then
1212 GCC_NO_BUILTIN="-fno-builtin"
1213 fi
1214 AC_SUBST(GCC_NO_BUILTIN)
1216 dnl **** Generate output files ****
1218 AC_OUTPUT_COMMANDS([
1219 extra_subdirs="\
1220 dlls/ddraw/d3ddevice \
1221 dlls/ddraw/dclipper \
1222 dlls/ddraw/ddraw \
1223 dlls/ddraw/direct3d \
1224 dlls/ddraw/dpalette \
1225 dlls/ddraw/dsurface \
1226 dlls/dinput/joystick \
1227 dlls/dinput/keyboard \
1228 dlls/dinput/mouse \
1229 dlls/kernel/messages \
1230 dlls/user/dde \
1231 dlls/user/resources \
1232 dlls/wineps/data \
1233 "
1234 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1236 MAKE_RULES=Make.rules
1237 AC_SUBST_FILE(MAKE_RULES)
1239 MAKE_DLL_RULES=dlls/Makedll.rules
1240 AC_SUBST_FILE(MAKE_DLL_RULES)
1242 MAKE_PROG_RULES=programs/Makeprog.rules
1243 AC_SUBST_FILE(MAKE_PROG_RULES)
1245 AC_OUTPUT([
1246 Make.rules
1247 dlls/Makedll.rules
1248 programs/Makeprog.rules
1249 Makefile
1250 console/Makefile
1251 controls/Makefile
1252 debugger/Makefile
1253 dlls/Makefile
1254 dlls/advapi32/Makefile
1255 dlls/avifil32/Makefile
1256 dlls/comctl32/Makefile
1257 dlls/commdlg/Makefile
1258 dlls/crtdll/Makefile
1259 dlls/dciman32/Makefile
1260 dlls/ddraw/Makefile
1261 dlls/dinput/Makefile
1262 dlls/dplay/Makefile
1263 dlls/dplayx/Makefile
1264 dlls/dsound/Makefile
1265 dlls/gdi/Makefile
1266 dlls/glu32/Makefile
1267 dlls/icmp/Makefile
1268 dlls/imagehlp/Makefile
1269 dlls/imm32/Makefile
1270 dlls/kernel/Makefile
1271 dlls/lzexpand/Makefile
1272 dlls/mapi32/Makefile
1273 dlls/mpr/Makefile
1274 dlls/msacm/Makefile
1275 dlls/msimg32/Makefile
1276 dlls/msnet32/Makefile
1277 dlls/msvcrt/Makefile
1278 dlls/msvideo/Makefile
1279 dlls/ntdll/Makefile
1280 dlls/odbc32/Makefile
1281 dlls/ole32/Makefile
1282 dlls/oleaut32/Makefile
1283 dlls/olecli/Makefile
1284 dlls/oledlg/Makefile
1285 dlls/olepro32/Makefile
1286 dlls/olesvr/Makefile
1287 dlls/opengl32/Makefile
1288 dlls/psapi/Makefile
1289 dlls/quartz/Makefile
1290 dlls/rasapi32/Makefile
1291 dlls/richedit/Makefile
1292 dlls/rpcrt4/Makefile
1293 dlls/serialui/Makefile
1294 dlls/setupapi/Makefile
1295 dlls/shdocvw/Makefile
1296 dlls/shell32/Makefile
1297 dlls/shfolder/Makefile
1298 dlls/shlwapi/Makefile
1299 dlls/sti/Makefile
1300 dlls/tapi32/Makefile
1301 dlls/ttydrv/Makefile
1302 dlls/url/Makefile
1303 dlls/urlmon/Makefile
1304 dlls/user/Makefile
1305 dlls/version/Makefile
1306 dlls/win32s/Makefile
1307 dlls/winaspi/Makefile
1308 dlls/winedos/Makefile
1309 dlls/wineps/Makefile
1310 dlls/wininet/Makefile
1311 dlls/winmm/Makefile
1312 dlls/winmm/joystick/Makefile
1313 dlls/winmm/mcianim/Makefile
1314 dlls/winmm/mciavi/Makefile
1315 dlls/winmm/mcicda/Makefile
1316 dlls/winmm/mciseq/Makefile
1317 dlls/winmm/mciwave/Makefile
1318 dlls/winmm/midimap/Makefile
1319 dlls/winmm/wavemap/Makefile
1320 dlls/winmm/wineoss/Makefile
1321 dlls/winnls/Makefile
1322 dlls/winsock/Makefile
1323 dlls/winspool/Makefile
1324 dlls/wintrust/Makefile
1325 dlls/wow32/Makefile
1326 dlls/wsock32/Makefile
1327 dlls/x11drv/Makefile
1328 documentation/Makefile
1329 documentation/wine.conf.man
1330 documentation/wine.man
1331 files/Makefile
1332 graphics/Makefile
1333 graphics/enhmetafiledrv/Makefile
1334 graphics/metafiledrv/Makefile
1335 graphics/win16drv/Makefile
1336 graphics/x11drv/Makefile
1337 if1632/Makefile
1338 include/Makefile
1339 library/Makefile
1340 libtest/Makefile
1341 loader/Makefile
1342 loader/dos/Makefile
1343 loader/ne/Makefile
1344 memory/Makefile
1345 misc/Makefile
1346 miscemu/Makefile
1347 msdos/Makefile
1348 objects/Makefile
1349 ole/Makefile
1350 programs/Makefile
1351 programs/avitools/Makefile
1352 programs/clock/Makefile
1353 programs/cmdlgtst/Makefile
1354 programs/control/Makefile
1355 programs/notepad/Makefile
1356 programs/osversioncheck/Makefile
1357 programs/progman/Makefile
1358 programs/regapi/Makefile
1359 programs/regtest/Makefile
1360 programs/uninstaller/Makefile
1361 programs/view/Makefile
1362 programs/wcmd/Makefile
1363 programs/winemine/Makefile
1364 programs/winetest/Makefile
1365 programs/winhelp/Makefile
1366 programs/winver/Makefile
1367 relay32/Makefile
1368 scheduler/Makefile
1369 server/Makefile
1370 tools/Makefile
1371 tools/winapi/Makefile
1372 tools/winebuild/Makefile
1373 tools/winedump/Makefile
1374 tools/winelauncher
1375 tools/wmc/Makefile
1376 tools/wrc/Makefile
1377 tsx11/Makefile
1378 unicode/Makefile
1379 win32/Makefile
1380 windows/Makefile
1381 windows/x11drv/Makefile ])
1383 if test "$have_x" = "no"
1384 then
1385 echo
1386 echo "*** Warning: X development files not found. Wine will be built without"
1387 echo "*** X support, which currently does not work, and would probably not be"
1388 echo "*** what you want anyway. You will need to install devel packages of"
1389 echo "*** Xlib/Xfree86 and Xpm at the very least."
1390 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1391 then
1392 echo
1393 echo "*** Warning: Xpm development files not found. Wine will be built without"
1394 echo "*** Xpm support, which currently does not work. You will need to install"
1395 echo "*** devel packages of Xpm."
1396 fi
1398 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1399 then
1400 echo
1401 echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1402 echo "*** terminal resize support. Consider upgrading ncurses."
1403 fi
1405 if test "$wine_cv_libc_reentrant" = "no"
1406 then
1407 echo
1408 echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1409 echo "*** thread support. Consider upgrading libc to a more recent"
1410 echo "*** reentrant version of libc."
1411 fi
1413 if test "$wine_cv_opengl_version_OK" = "no"
1414 then
1415 echo
1416 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1417 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1418 fi
1420 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1421 then
1422 echo
1423 echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1424 echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1425 echo "*** A fix for glibc 2.1.3 that seems to work is included in this version of Wine,"
1426 echo "*** start configure with '--enable-opengl' to force OpenGL support."
1427 fi
1429 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1430 then
1431 echo
1432 echo "*** Warning: you explicitly linked in a thread-safe OpenGL version. If you"
1433 echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1434 echo "*** support before reporting bugs."
1435 fi
1437 if test "$wine_cv_warn_cups_h" = "yes"
1438 then
1439 echo
1440 echo "*** Note: You have cups runtime libraries, but no development"
1441 echo "*** libraries. Install the cups-devel package or whichever package"
1442 echo "*** contains cups.h to enable CUPS support in WINE."
1443 fi
1445 if test "$wine_cv_msg_freetype" = "yes"
1446 then
1447 echo
1448 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1449 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1450 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1451 echo "*** enable Wine to use TrueType fonts."
1452 fi
1454 echo
1455 echo "Configure finished. Do 'make depend && make' to compile Wine."
1456 echo
1458 dnl Local Variables:
1459 dnl comment-start: "dnl "
1460 dnl comment-end: ""
1461 dnl comment-start-skip: "\\bdnl\\b\\s *"
1462 dnl compile-command: "autoconf"
1463 dnl End: