aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl WINE_CHECK_HOST_TOOL(VARIABLE, PROG-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND], [PATH])
  26 dnl
  27 dnl Like AC_CHECK_TOOL but without the broken fallback to non-prefixed name
  28 dnl
  29 AC_DEFUN([WINE_CHECK_HOST_TOOL],
  30 [AS_VAR_SET_IF([ac_tool_prefix],
  31   [AC_CHECK_PROG([$1],[${ac_tool_prefix}$2],[${ac_tool_prefix}$2],,[$4])])
  32 AS_VAR_IF([ac_cv_prog_$1],[],
  33   [AS_VAR_IF([cross_compiling],[yes],[],
  34     [AS_UNSET([ac_cv_prog_$1])
  35      AC_CHECK_PROG([$1],[$2],[$2],[$3],[$4])])],
  36 [AS_VAR_COPY([$1],[ac_cv_prog_$1])])])
  37
  38 dnl WINE_HEADER_MAJOR()
  39 dnl
  40 dnl Same as AC_HEADER_MAJOR but fixed to handle the glibc 2.25 sys/types.h breakage
  41 dnl
  42 AC_DEFUN([WINE_HEADER_MAJOR],
  43 [AC_CHECK_HEADER(sys/mkdev.h,
  44                 [AC_DEFINE(MAJOR_IN_MKDEV, 1,
  45                            [Define to 1 if `major', `minor', and `makedev' are
  46                             declared in <mkdev.h>.])])
  47 if test $ac_cv_header_sys_mkdev_h = no; then
  48   AC_CHECK_HEADER(sys/sysmacros.h,
  49                   [AC_DEFINE(MAJOR_IN_SYSMACROS, 1,
  50                              [Define to 1 if `major', `minor', and `makedev'
  51                               are declared in <sysmacros.h>.])])
  52 fi])
  53
  54 dnl **** Initialize the programs used by other checks ****
  55 dnl
  56 dnl Usage: WINE_PATH_SONAME_TOOLS
  57 dnl Usage: WINE_PATH_PKG_CONFIG
  58 dnl
  59 AC_DEFUN([WINE_PATH_SONAME_TOOLS],
  60 [AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)
  61 AC_CHECK_TOOL(OTOOL,otool,otool)
  62 AC_CHECK_TOOL(READELF,[readelf],true)])
  63
  64 AC_DEFUN([WINE_PATH_PKG_CONFIG],
  65 [WINE_CHECK_HOST_TOOL(PKG_CONFIG,[pkg-config])])
  66
  67 AC_DEFUN([WINE_PATH_MINGW_PKG_CONFIG],
  68 [case "$host_cpu" in
  69   i[[3456789]]86*)
  70     ac_prefix_list="m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-w64-mingw32-pkg-config ])" ;;
  71   *)
  72     ac_prefix_list="$host_cpu-w64-mingw32-pkg-config" ;;
  73 esac
  74 AC_CHECK_PROGS(MINGW_PKG_CONFIG,[$ac_prefix_list],false)])
  75
  76 dnl **** Extract the soname of a library ****
  77 dnl
  78 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  79 dnl
  80 AC_DEFUN([WINE_CHECK_SONAME],
  81 [AC_REQUIRE([WINE_PATH_SONAME_TOOLS])dnl
  82 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  83 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  84 AC_MSG_CHECKING([for -l$1])
  85 AC_CACHE_VAL(ac_Lib,
  86 [ac_check_soname_save_LIBS=$LIBS
  87 LIBS="-l$1 $5 $LIBS"
  88   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  89   [case "$LIBEXT" in
  90     dll) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest.exe | grep "$1" | sed -e "s/dll.*/dll/"';2,$d'`]) ;;
  91     dylib) AS_VAR_SET(ac_Lib,[`$OTOOL -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  92     *) AS_VAR_SET(ac_Lib,[`$READELF -d conftest$ac_exeext | grep "NEEDED.*ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\\m4_dquote(\\(ac_lib_pattern\\.$LIBEXT[[^    ]]*\\)\\).*$/\1/"';2,$d'`])
  93        AS_VAR_IF([ac_Lib],[],
  94              [AS_VAR_SET(ac_Lib,[`$LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^  ]]*\).*$/\1/"';2,$d'`])]) ;;
  95   esac],
  96   [AS_VAR_SET(ac_Lib,[])])
  97   LIBS=$ac_check_soname_save_LIBS])dnl
  98 AS_VAR_IF([ac_Lib],[],
  99       [AC_MSG_RESULT([not found])
 100        $4],
 101       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
 102        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
 103                           [Define to the soname of the lib$1 library.])
 104        $3])dnl
 105 m4_popdef([ac_lib_pattern])dnl
 106 AS_VAR_POPDEF([ac_Lib])])
 107
 108 dnl **** Get flags from pkg-config or alternate xxx-config program ****
 109 dnl
 110 dnl Usage: WINE_PACKAGE_FLAGS(var,pkg-name,[default-lib,[cflags-alternate,libs-alternate,[checks]]])
 111 dnl
 112 AC_DEFUN([WINE_PACKAGE_FLAGS],
 113 [AC_REQUIRE([WINE_PATH_PKG_CONFIG])dnl
 114 AS_VAR_PUSHDEF([ac_cflags],[[$1]_CFLAGS])dnl
 115 AS_VAR_PUSHDEF([ac_libs],[[$1]_LIBS])dnl
 116 AC_ARG_VAR(ac_cflags, [C compiler flags for $2, overriding pkg-config])dnl
 117 AS_VAR_IF([ac_cflags],[],
 118       [AS_VAR_SET_IF([PKG_CONFIG],
 119       [ac_cflags=`$PKG_CONFIG --cflags [$2] 2>/dev/null`])])
 120 m4_ifval([$4],[test "$cross_compiling" = yes || ac_cflags=[$]{ac_cflags:-[$4]}])
 121 AC_ARG_VAR(ac_libs, [Linker flags for $2, overriding pkg-config])dnl
 122 AS_VAR_IF([ac_libs],[],
 123       [AS_VAR_SET_IF([PKG_CONFIG],
 124       [ac_libs=`$PKG_CONFIG --libs [$2] 2>/dev/null`])])
 125 m4_ifval([$5],[test "$cross_compiling" = yes || ac_libs=[$]{ac_libs:-[$5]}])
 126 m4_ifval([$3],[ac_libs=[$]{ac_libs:-"$3"}])
 127 AS_ECHO(["$as_me:${as_lineno-$LINENO}: $2 cflags: $ac_cflags"]) >&AS_MESSAGE_LOG_FD
 128 AS_ECHO(["$as_me:${as_lineno-$LINENO}: $2 libs: $ac_libs"]) >&AS_MESSAGE_LOG_FD
 129 ac_save_CPPFLAGS=$CPPFLAGS
 130 CPPFLAGS="$CPPFLAGS $ac_cflags"
 131 $6
 132 CPPFLAGS=$ac_save_CPPFLAGS
 133 AS_VAR_POPDEF([ac_libs])dnl
 134 AS_VAR_POPDEF([ac_cflags])])dnl
 135
 136 dnl **** Get flags from MinGW pkg-config or alternate xxx-config program ****
 137 dnl
 138 dnl Usage: WINE_MINGW_PACKAGE_FLAGS(var,pkg-name,[default-lib,[checks]])
 139 dnl
 140 AC_DEFUN([WINE_MINGW_PACKAGE_FLAGS],
 141 [AC_REQUIRE([WINE_PATH_MINGW_PKG_CONFIG])dnl
 142 AS_VAR_PUSHDEF([ac_cflags],[[$1]_PE_CFLAGS])dnl
 143 AS_VAR_PUSHDEF([ac_libs],[[$1]_PE_LIBS])dnl
 144 AS_VAR_IF([ac_cflags],[],
 145       [AS_VAR_SET_IF([MINGW_PKG_CONFIG],
 146       [ac_cflags=`$MINGW_PKG_CONFIG --cflags [$2] 2>/dev/null`])])
 147 AS_VAR_IF([ac_libs],[],
 148       [AS_VAR_SET_IF([MINGW_PKG_CONFIG],
 149       [ac_libs=`$MINGW_PKG_CONFIG --libs [$2] 2>/dev/null`])])
 150 m4_ifval([$3],[ac_libs=[$]{ac_libs:-"$3"}])
 151 ac_save_CPPFLAGS=$CPPFLAGS
 152 CPPFLAGS="$CPPFLAGS $ac_cflags"
 153 $4
 154 CPPFLAGS=$ac_save_CPPFLAGS
 155 AS_VAR_POPDEF([ac_libs])dnl
 156 AS_VAR_POPDEF([ac_cflags])])dnl
 157
 158 dnl **** Get flags for an external lib program ****
 159 dnl
 160 dnl Usage: WINE_EXTLIB_FLAGS(var,pkg-name,default-libs,default-cflags)
 161 dnl
 162 AC_DEFUN([WINE_EXTLIB_FLAGS],
 163 [AS_VAR_PUSHDEF([ac_cflags],[[$1]_PE_CFLAGS])dnl
 164 AS_VAR_PUSHDEF([ac_libs],[[$1]_PE_LIBS])dnl
 165 AC_ARG_VAR(ac_cflags, [C compiler flags for the PE $2, overriding the bundled version])dnl
 166 AC_ARG_VAR(ac_libs, [Linker flags for the PE $2, overriding the bundled version])dnl
 167 AS_VAR_IF([ac_libs],[],
 168   [ac_libs=$3
 169    AS_VAR_IF([ac_cflags],[],[ac_cflags=$4],[enable_$2=no])],
 170   [enable_$2=no])
 171 AS_ECHO(["$as_me:${as_lineno-$LINENO}: $2 cflags: $ac_cflags"]) >&AS_MESSAGE_LOG_FD
 172 AS_ECHO(["$as_me:${as_lineno-$LINENO}: $2 libs: $ac_libs"]) >&AS_MESSAGE_LOG_FD
 173 AS_VAR_POPDEF([ac_libs])dnl
 174 AS_VAR_POPDEF([ac_cflags])])dnl
 175
 176 dnl **** Link C code with an assembly file ****
 177 dnl
 178 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
 179 dnl
 180 AC_DEFUN([WINE_TRY_ASM_LINK],
 181 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[$2]],[[asm($1); $3]])],[$4],[$5])])
 182
 183 dnl **** Check if we can link an empty program with special CFLAGS ****
 184 dnl
 185 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
 186 dnl
 187 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
 188 dnl
 189 AC_DEFUN([WINE_TRY_CFLAGS],
 190 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
 191 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
 192 [ac_wine_try_cflags_saved=$CFLAGS
 193 CFLAGS="$CFLAGS $1"
 194 AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv) { return 0; }]])],
 195                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
 196 CFLAGS=$ac_wine_try_cflags_saved])
 197 AS_VAR_IF([ac_var],[yes],[m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
 198 AS_VAR_POPDEF([ac_var])])
 199
 200 dnl **** Check if we can link an empty program with special CFLAGS ****
 201 dnl
 202 dnl Usage: WINE_TRY_PE_CFLAGS(flags,[action-if-yes,[action-if-no]])
 203 dnl
 204 dnl The default action-if-yes is to append the flags to the arch-specific EXTRACFLAGS.
 205 dnl
 206 AC_DEFUN([WINE_TRY_PE_CFLAGS],
 207 [{ AS_VAR_PUSHDEF([ac_var], ac_cv_${wine_arch}_cflags_[[$1]])dnl
 208 AC_CACHE_CHECK([whether $CC supports $1], ac_var,
 209 [ac_wine_try_cflags_saved=$CFLAGS
 210 ac_wine_try_cflags_saved_exeext=$ac_exeext
 211 CFLAGS="$CFLAGS -nostdlib -nodefaultlibs $1"
 212 ac_exeext=".exe"
 213 AC_LINK_IFELSE([AC_LANG_SOURCE([[int __cdecl mainCRTStartup(void) { return 0; }]])],
 214                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
 215 CFLAGS=$ac_wine_try_cflags_saved
 216 ac_exeext=$ac_wine_try_cflags_saved_exeext])
 217 AS_VAR_IF([ac_var],[yes],[m4_default([$2], [AS_VAR_APPEND([${wine_arch}_EXTRACFLAGS],[" $1"])], [$3])])dnl
 218 AS_VAR_POPDEF([ac_var]) }])
 219
 220 dnl **** Check whether the given MinGW header is available ****
 221 dnl
 222 dnl Usage: WINE_CHECK_MINGW_HEADER(header,[action-if-found],[action-if-not-found],[other-includes])
 223 dnl
 224 AC_DEFUN([WINE_CHECK_MINGW_HEADER],
 225 [AS_VAR_PUSHDEF([ac_var],[ac_cv_mingw_header_$1])dnl
 226 AC_CACHE_CHECK([for MinGW $1], ac_var,
 227 [ac_wine_check_headers_saved_cc=$CC
 228 ac_wine_check_headers_saved_exeext=$ac_exeext
 229 AS_VAR_COPY([CC],[${wine_arch}_CC])
 230 ac_exeext=".exe"
 231 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[$4
 232 #include <$1>]])],[AS_VAR_SET([ac_var],[yes])],[AS_VAR_SET([ac_var],[no])])
 233 CC=$ac_wine_check_headers_saved_cc
 234 ac_exeext=$ac_wine_check_headers_saved_exeext])
 235 AS_VAR_IF([ac_var],[yes],[$2],[$3])dnl
 236 AS_VAR_POPDEF([ac_var])])
 237
 238 dnl **** Check whether the given MinGW library is available ****
 239 dnl
 240 dnl Usage: WINE_CHECK_MINGW_LIB(library,function,[action-if-found],[action-if-not-found],[other-libraries])
 241 dnl
 242 AC_DEFUN([WINE_CHECK_MINGW_LIB],
 243 [AS_VAR_PUSHDEF([ac_var],[ac_cv_mingw_lib_$1])dnl
 244 AC_CACHE_CHECK([for $2 in MinGW -l$1], ac_var,
 245 [ac_wine_check_headers_saved_cc=$CC
 246 ac_wine_check_headers_saved_exeext=$ac_exeext
 247 ac_wine_check_headers_saved_libs=$LIBS
 248 AS_VAR_COPY([CC],[${wine_arch}_CC])
 249 ac_exeext=".exe"
 250 LIBS="-l$1 $5 $LIBS"
 251 AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],[AS_VAR_SET([ac_var],[yes])],[AS_VAR_SET([ac_var],[no])])
 252 CC=$ac_wine_check_headers_saved_cc
 253 ac_exeext=$ac_wine_check_headers_saved_exeext
 254 LIBS=$ac_wine_check_headers_saved_libs])
 255 AS_VAR_IF([ac_var],[yes],[$3],[$4])dnl
 256 AS_VAR_POPDEF([ac_var])])
 257
 258 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
 259 dnl
 260 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
 261 dnl
 262 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
 263 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
 264 ac_wine_try_cflags_saved=$CFLAGS
 265 CFLAGS="$CFLAGS $1"
 266 AC_LINK_IFELSE([AC_LANG_SOURCE([[void myfunc() {}]])],
 267                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
 268 CFLAGS=$ac_wine_try_cflags_saved
 269 AS_VAR_IF([ac_var],[yes], [$2], [$3])dnl
 270 AS_VAR_POPDEF([ac_var])])
 271
 272 dnl **** Check whether we need to define a symbol on the compiler command line ****
 273 dnl
 274 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
 275 dnl
 276 AC_DEFUN([WINE_CHECK_DEFINE],
 277 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 278 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 279     AC_EGREP_CPP(yes,[#ifndef $1
 280 yes
 281 #endif],
 282     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 283 AS_VAR_IF([ac_var],[yes],
 284       [CFLAGS="$CFLAGS -D$1"
 285   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 286 AS_VAR_POPDEF([ac_var])])
 287
 288 dnl **** Check for functions with some extra libraries ****
 289 dnl
 290 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 291 dnl
 292 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 293 [ac_wine_check_funcs_save_LIBS="$LIBS"
 294 LIBS="$LIBS $2"
 295 AC_CHECK_FUNCS([$1],[$3],[$4])
 296 LIBS="$ac_wine_check_funcs_save_LIBS"])
 297
 298 dnl **** Define helper functions for creating config.status files ****
 299 dnl
 300 dnl Usage: AC_REQUIRE([WINE_CONFIG_HELPERS])
 301 dnl
 302 AC_DEFUN([WINE_CONFIG_HELPERS],
 303 [AS_VAR_SET([wine_rules],["all:"])
 304 AC_SUBST(SUBDIRS,"")
 305 AC_SUBST(DISABLED_SUBDIRS,"")
 306 AC_SUBST(CONFIGURE_TARGETS,"")
 307
 308 wine_fn_config_makefile ()
 309 {
 310     AS_VAR_APPEND([SUBDIRS],[" \\$as_nl $[1]"])
 311     AS_VAR_COPY([enable],[$[2]])
 312     case "$enable" in
 313       no) AS_VAR_APPEND([DISABLED_SUBDIRS],[" $[1]"]) ;;
 314       *aarch64*|*arm*|*i386*|*x86_64*)
 315         if test -n "$PE_ARCHS"
 316         then
 317             for i in $PE_ARCHS
 318             do
 319                 test $(expr ",$enable," : ".*,$i,") -gt 0 || AS_VAR_APPEND([${i}_DISABLED_SUBDIRS],[" $[1]"])
 320             done
 321         else
 322             test $(expr ",$enable," : ".*,$HOST_ARCH,") -gt 0 || AS_VAR_APPEND([DISABLED_SUBDIRS],[" $[1]"])
 323         fi;;
 324     esac
 325 }
 326
 327 wine_fn_config_symlink ()
 328 {
 329     ac_links=$[@]
 330     AS_VAR_APPEND([wine_rules],["
 331 $ac_links:
 332         @./config.status \$[@]"])
 333     for f in $ac_links; do AS_VAR_APPEND([CONFIGURE_TARGETS],[" $f"]); done
 334 }])
 335
 336 dnl **** Define helper function to append a rule to a makefile command list ****
 337 dnl
 338 dnl Usage: WINE_APPEND_RULE(rule)
 339 dnl
 340 AC_DEFUN([WINE_APPEND_RULE],[AC_REQUIRE([WINE_CONFIG_HELPERS])AS_VAR_APPEND([wine_rules],["
 341 $1"])])
 342
 343 dnl **** Create symlinks from config.status ****
 344 dnl
 345 dnl Usage: WINE_CONFIG_SYMLINK(target,src,enable)
 346 dnl
 347 AC_DEFUN([WINE_CONFIG_SYMLINK],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 348 m4_ifval([$3],[if test $3; then
 349 ])AC_CONFIG_LINKS([$1:$2])dnl
 350 wine_fn_config_symlink[ $1]m4_ifval([$3],[
 351 fi])[]dnl
 352 ])])
 353
 354 dnl **** Create a makefile from config.status ****
 355 dnl
 356 dnl Usage: WINE_CONFIG_MAKEFILE(file,enable,condition)
 357 dnl
 358 AC_DEFUN([WINE_CONFIG_MAKEFILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 359 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]m4_bpatsubst([$1],[.*/\([^/]*\)$],[\1])))dnl
 360 m4_append_uniq([_AC_USER_OPTS],ac_enable,[
 361 ])dnl
 362 m4_ifval([$3],[$3 || ])wine_fn_config_makefile [$1] ac_enable[]dnl
 363 AS_VAR_POPDEF([ac_enable])])
 364
 365 dnl **** Append a file to the .gitignore list ****
 366 dnl
 367 dnl Usage: WINE_IGNORE_FILE(file,enable)
 368 dnl
 369 AC_DEFUN([WINE_IGNORE_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 370 m4_ifval([$2],[test "x$[$2]" = xno || ])AS_VAR_APPEND([CONFIGURE_TARGETS],[" $1"])])
 371
 372 dnl **** Add a message to the list displayed at the end ****
 373 dnl
 374 dnl Usage: WINE_NOTICE(notice)
 375 dnl Usage: WINE_WARNING(warning)
 376 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice, enable)
 377 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning, enable)
 378 dnl Usage: WINE_ERROR_WITH(with_flag, test, error, enable)
 379 dnl Usage: WINE_PRINT_MESSAGES
 380 dnl
 381 AC_DEFUN([WINE_NOTICE],[AS_VAR_APPEND([wine_notices],["|$1"])])
 382 AC_DEFUN([WINE_WARNING],[AS_VAR_APPEND([wine_warnings],["|$1"])])
 383
 384 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 385   x)   WINE_NOTICE([$3]) ;;
 386   xno) ;;
 387   *)   AC_MSG_ERROR([$3
 388 This is an error since --with-$1 was requested.]) ;;
 389 esac
 390 m4_ifval([$4],[$4=${$4:-no}])])])
 391
 392 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 393   x)   WINE_WARNING([$3]) ;;
 394   xno) ;;
 395   *)   AC_MSG_ERROR([$3
 396 This is an error since --with-$1 was requested.]) ;;
 397 esac
 398 m4_ifval([$4],[$4=${$4:-no}])])])
 399
 400 AC_DEFUN([WINE_ERROR_WITH],[AS_IF([$2],[case "x$with_$1" in
 401   xno) ;;
 402   *)   AC_MSG_ERROR([$3
 403 Use the --without-$1 option if you really want this.]) ;;
 404 esac
 405 m4_ifval([$4],[$4=${$4:-no}])])])
 406
 407 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 408 if test "x$wine_notices" != x; then
 409     echo >&AS_MESSAGE_FD
 410     IFS="|"
 411     for msg in $wine_notices; do
 412         IFS="$ac_save_IFS"
 413         AS_VAR_IF([msg],[],,[AC_MSG_NOTICE([$msg])])
 414     done
 415 fi
 416 IFS="|"
 417 for msg in $wine_warnings; do
 418     IFS="$ac_save_IFS"
 419     AS_VAR_IF([msg],[],,[echo >&2
 420         AC_MSG_WARN([$msg])])
 421 done
 422 IFS="$ac_save_IFS"])
 423
 424 dnl Local Variables:
 425 dnl compile-command: "autoreconf --warnings=all"
 426 dnl End: