configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl For detailed change history, see the git commit logs.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 dnl autoconf versions before 2.62 don't handle source dir symlinks correctly
   8 AC_PREREQ(2.62)
   9 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org],[wine],[http://www.winehq.org])
  10 AC_CONFIG_SRCDIR(server/atom.c)
  11 AC_CONFIG_HEADERS(include/config.h)
  12 AC_CONFIG_AUX_DIR(tools)
  13
  14 dnl autoconf versions before 2.63b don't have AS_VAR_APPEND or AS_VAR_IF
  15 m4_ifdef([AS_VAR_APPEND],,[as_fn_append () { eval $[1]=\$$[1]\$[2]; }
  16 AC_DEFUN([AS_VAR_APPEND],[as_fn_append $1 $2])])dnl
  17 m4_ifdef([AS_VAR_IF],,[AC_DEFUN([AS_VAR_IF],
  18 [AS_LITERAL_IF([$1],
  19   [AS_IF([test "x$$1" = x""$2], [$3], [$4])],
  20   [eval as_val=\$$1
  21    AS_IF([test "x$as_val" = x""$2], [$3], [$4])])])])dnl
  22 dnl autoconf versions before 2.64 don't have AC_PACKAGE_URL
  23 m4_ifdef([AC_PACKAGE_URL],,
  24   [AC_DEFINE([PACKAGE_URL], ["http://www.winehq.org"], [Define to the home page for this package.])
  25    AC_SUBST([PACKAGE_URL], ["http://www.winehq.org"])])dnl
  26
  27 dnl **** Command-line arguments ****
  28
  29 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  30 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  31 AC_ARG_ENABLE(tests, AS_HELP_STRING([--disable-tests],[do not build the regression tests]))
  32 AC_ARG_ENABLE(maintainer-mode, AS_HELP_STRING([--enable-maintainer-mode],[enable maintainer-specific build rules]))
  33
  34 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  35             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  36 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]))
  37 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]))
  38 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  39             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  40 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]))
  41 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  42             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  43 AC_ARG_WITH(dbus,      AS_HELP_STRING([--without-dbus],[do not use DBus (dynamic device support)]))
  44 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]))
  45 AC_ARG_WITH(freetype,  AS_HELP_STRING([--without-freetype],[do not use the FreeType library]))
  46 AC_ARG_WITH(gettext,   AS_HELP_STRING([--without-gettext],[do not use gettext]))
  47 AC_ARG_WITH(gettextpo, AS_HELP_STRING([--with-gettextpo],[use the GetTextPO library to rebuild po files]),
  48             [if test "x$withval" = "xno"; then ac_cv_header_gettext_po_h=no; fi])
  49 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  50 AC_ARG_WITH(glu,       AS_HELP_STRING([--without-glu],[do not use the GLU library]))
  51 AC_ARG_WITH(gnutls,    AS_HELP_STRING([--without-gnutls],[do not use GnuTLS (schannel support)]))
  52 AC_ARG_WITH(gsm,       AS_HELP_STRING([--without-gsm],[do not use libgsm (GSM 06.10 codec support)]),
  53             [if test "x$withval" = "xno"; then ac_cv_header_gsm_h=no; ac_cv_header_gsm_gsm_h=no; fi])
  54 AC_ARG_WITH(gstreamer, AS_HELP_STRING([--without-gstreamer],[do not use GStreamer (codecs support)]))
  55 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  56 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]))
  57 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  58             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  59 AC_ARG_WITH(mpg123,    AS_HELP_STRING([--without-mpg123],[do not use the mpg123 library]))
  60 AC_ARG_WITH(netapi,    AS_HELP_STRING([--without-netapi],[do not use the Samba NetAPI library]))
  61 AC_ARG_WITH(openal,    AS_HELP_STRING([--without-openal],[do not use OpenAL]),
  62             [if test "x$withval" = "xno"; then ac_cv_header_AL_al_h=no; ac_cv_header_OpenAL_al_h=no; fi])
  63 AC_ARG_WITH(opencl,    AS_HELP_STRING([--without-opencl],[do not use OpenCL]),
  64             [if test "x$withval" = "xno"; then ac_cv_header_CL_cl_h=no; ac_cv_header_OpenCL_opencl_h=no; fi])
  65 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  66 AC_ARG_WITH(osmesa,     AS_HELP_STRING([--without-osmesa],[do not use the OSMesa library]))
  67 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]))
  68 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]))
  69 AC_ARG_WITH(pthread,   AS_HELP_STRING([--without-pthread],[do not use the pthread library]),
  70             [if test "x$withval" = "xno"; then ac_cv_header_pthread_h=no; fi])
  71 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  72 AC_ARG_WITH(tiff,      AS_HELP_STRING([--without-tiff],[do not use TIFF]))
  73 AC_ARG_WITH(v4l,       AS_HELP_STRING([--without-v4l],[do not use v4l1 (v4l support)]))
  74 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  75             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  76 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  77             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  78 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  79             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  80 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  81             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  82 AC_ARG_WITH(xinput2,   AS_HELP_STRING([--without-xinput2],[do not use the Xinput 2 extension]),
  83             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput2_h=no; fi])
  84 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  85 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  86             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  87 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
  88             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
  89 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
  90             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
  91 AC_ARG_WITH(xshm,      AS_HELP_STRING([--without-xshm],[do not use XShm (shared memory extension)]),
  92             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XShm_h=no; fi])
  93 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
  94 AC_ARG_WITH(xxf86vm,   AS_HELP_STRING([--without-xxf86vm],[do not use XFree video mode extension]),
  95             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; ac_cv_header_X11_extensions_xf86vmproto_h=no; fi])
  96 AC_ARG_WITH(zlib,      AS_HELP_STRING([--without-zlib],[do not use Zlib (data compression)]),
  97             [if test "x$withval" = "xno"; then ac_cv_header_zlib_h=no; fi])
  98
  99 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
 100 AC_ARG_WITH(wine64,    AS_HELP_STRING([--with-wine64=DIR],[use the 64-bit Wine in DIR for a Wow64 build]))
 101
 102 AC_CANONICAL_HOST
 103
 104 dnl check for out of tree build with unclean source tree
 105 case "$srcdir" in
 106  .) ;;
 107  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 108       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 109 You need to run 'make distclean' in the source tree first.])
 110     fi ;;
 111 esac
 112
 113 dnl **** Check for some programs ****
 114
 115 AC_PROG_MAKE_SET
 116 AC_PROG_CC
 117 AC_PROG_CXX
 118 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 119 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 120 AC_DEFINE_UNQUOTED(EXEEXT,["$ac_exeext"],[Define to the file extension for executables.])
 121
 122 case $host in
 123   *-darwin*)
 124     if test "x$enable_win64" = "xyes"
 125     then
 126       CC="$CC -m64"
 127       CXX="$CXX -m64"
 128       host_cpu="x86_64"
 129       notice_platform="64-bit "
 130       AC_SUBST(TARGETFLAGS,"-m64")
 131     else
 132       CC="$CC -m32"
 133       CXX="$CXX -m32"
 134       host_cpu="i386"
 135       notice_platform="32-bit "
 136       AC_SUBST(TARGETFLAGS,"-m32")
 137       enable_win16=${enable_win16:-yes}
 138     fi
 139     with_fontconfig=${with_fontconfig:-no}
 140     ;;
 141   x86_64*)
 142     if test "x$enable_win64" != "xyes" -a "$cross_compiling" != "yes"
 143     then
 144       CC="$CC -m32"
 145       CXX="$CXX -m32"
 146       AC_MSG_CHECKING([whether $CC works])
 147       AC_LINK_IFELSE([AC_LANG_PROGRAM()],AC_MSG_RESULT([yes]),
 148                      [AC_MSG_RESULT([no])
 149                       AC_MSG_ERROR([Cannot build a 32-bit program, you need to install 32-bit development libraries.])])
 150       host_cpu="i386"
 151       notice_platform="32-bit "
 152       AC_SUBST(TARGETFLAGS,"-m32")
 153       enable_win16=${enable_win16:-yes}
 154     else
 155       if test "x${GCC}" = "xyes"
 156       then
 157         AC_MSG_CHECKING([whether $CC supports __builtin_ms_va_list])
 158         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[void func(__builtin_ms_va_list *args);]])],
 159                           [AC_MSG_RESULT([yes])],
 160                           [AC_MSG_RESULT([no])
 161                            AC_MSG_ERROR([You need gcc >= 4.4 to build Wine as 64-bit.])])
 162       fi
 163       AC_SUBST(TARGETFLAGS,"-m64")
 164     fi
 165     ;;
 166   arm*)
 167     AC_MSG_CHECKING([whether $CC supports Thumb])
 168     WINE_TRY_ASM_LINK([".thumb\nblx ac_test\n.arm"],[int ac_test(int i) { return i; }], [if (ac_test(1)) return 1],
 169                       [AC_MSG_RESULT([yes])],
 170                       [AC_MSG_RESULT([no])
 171                        AC_MSG_ERROR([You need a target with Thumb support to build Wine for ARM.])])
 172     CFLAGS="$CFLAGS -marm"
 173     ;;
 174   *-mingw32*|*-cygwin*)
 175     enable_win16=${enable_win16:-no}
 176     CFLAGS="$CFLAGS -D_WIN32"
 177     ;;
 178   i[[3456789]]86*)
 179     enable_win16=${enable_win16:-yes}
 180     ;;
 181 esac
 182
 183 dnl enable_win16 defaults to yes on x86, to no on other CPUs
 184 enable_win16=${enable_win16:-no}
 185 enable_win64=${enable_win64:-no}
 186
 187 dnl Disable winetest too if tests are disabled
 188 enable_winetest=${enable_winetest:-$enable_tests}
 189
 190 dnl Some special cases for the wow64 build
 191 if test -n "$with_wine64"
 192 then
 193     if test "x$enable_win64" = "xyes"
 194     then
 195         AC_MSG_ERROR([--enable-win64 and --with-wine64 are mutually exclusive.
 196 --enable-win64 should be used in the 64-bit build tree, --with-wine64 in the 32-bit Wow64 build tree.])
 197     fi
 198     enable_fonts=${enable_fonts:-no}
 199     enable_server=${enable_server:-no}
 200 elif test "x$enable_win64" = "xyes"
 201 then
 202     test "x$libdir" != "x\${exec_prefix}/lib" || libdir="\${exec_prefix}/lib64"
 203 fi
 204
 205 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 206   [wine_cv_toolsdir="$with_wine_tools"
 207    if test -z "$with_wine_tools"; then
 208      if test "$cross_compiling" = "yes"; then
 209        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 210      elif test -n "$with_wine64"; then
 211        wine_cv_toolsdir="$with_wine64"
 212      fi
 213    fi
 214    if test -z "$wine_cv_toolsdir"; then
 215      wine_cv_toolsdir="\$(top_builddir)"
 216    elif test -d "$wine_cv_toolsdir/tools/winebuild"; then
 217      case "$wine_cv_toolsdir" in
 218        /*) ;;
 219        *)  wine_cv_toolsdir="\$(top_builddir)/$wine_cv_toolsdir" ;;
 220      esac
 221      enable_tools=${enable_tools:-no}
 222    else
 223      AC_MSG_ERROR([could not find Wine tools in $wine_cv_toolsdir])
 224    fi])
 225 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 226 if test -n "$host_alias" -a "$host_alias" != "$build_alias"
 227 then
 228     AC_SUBST(TARGETFLAGS,"-b $host_alias $TARGETFLAGS")
 229 fi
 230
 231 dnl Check for flex
 232 AC_CHECK_PROGS(FLEX,flex,none)
 233 if test "$FLEX" = "none"
 234 then
 235   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 236 fi
 237 AC_MSG_CHECKING([whether flex is recent enough])
 238 cat >conftest.l <<EOF
 239 %top{
 240 #include "prediluvian.h"
 241 }
 242 %%
 243 EOF
 244 if $FLEX -t conftest.l >/dev/null 2>&AS_MESSAGE_LOG_FD
 245 then
 246   AC_MSG_RESULT([yes])
 247 else
 248   AC_MSG_RESULT([no])
 249   AC_MSG_ERROR([Your flex version is too old. Please install flex version 2.5.33 or newer.])
 250 fi
 251
 252 dnl Check for bison
 253 AC_CHECK_PROGS(BISON,bison,none)
 254 if test "$BISON" = "none"
 255 then
 256   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 257 fi
 258
 259 AC_CHECK_TOOLS(AR,[ar gar],ar)
 260 AC_CHECK_TOOL(STRIP,strip,strip)
 261 AC_SUBST(ARFLAGS,rc)
 262 AC_PROG_RANLIB
 263 AC_PROG_LN_S
 264 AC_PROG_EGREP
 265 AC_PROG_MKDIR_P
 266 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 267
 268 dnl Use the correct strip to install programs
 269 test -z "$INSTALL_PROGRAM" && INSTALL_PROGRAM="STRIPPROG=\"\$(STRIP)\" \$(top_srcdir)/tools/install-sh"
 270 AC_PROG_INSTALL
 271
 272 dnl Check for various programs
 273 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 274 AC_CHECK_PROGS(RSVG, rsvg, false)
 275 AC_CHECK_PROGS(CONVERT, convert, false)
 276 AC_CHECK_PROGS(ICOTOOL, icotool, false)
 277 AC_CHECK_PROGS(MSGFMT, msgfmt, false)
 278 WINE_PATH_PKG_CONFIG
 279
 280 if test "x$enable_maintainer_mode" != "xyes"
 281 then
 282   AC_SUBST([MAINTAINER_MODE],[\#])
 283 else
 284   test "$srcdir" = . || AC_MSG_ERROR([Maintainer mode cannot work out of tree.])
 285   if test "$FONTFORGE" = "false"; then AC_MSG_ERROR([You need fontforge to rebuild fonts in maintainer mode.]); fi
 286   if test "$RSVG" = "false"; then AC_MSG_ERROR([You need rsvg to rebuild icons in maintainer mode.]); fi
 287
 288   dnl Check the imagemagick version
 289   if test "$CONVERT" = false
 290   then
 291     AC_MSG_ERROR([You need imagemagick to rebuild icons in maintainer mode.])
 292   else
 293     AC_MSG_CHECKING([for recent enough imagemagick])
 294     convert_version=`convert --version | head -n1`
 295     if test "x$convert_version" != "x"
 296     then
 297       convert_version_major=`expr "$convert_version" : '.* \([[0-9]]*\)\.[[0-9]]*'`
 298       convert_version_minor=`expr "$convert_version" : '.* [[0-9]]*\.\([[0-9]]*\)'`
 299       if test "$convert_version_major" -eq 6 -a "$convert_version_minor" -lt 6
 300       then
 301         CONVERT=false
 302       fi
 303     fi
 304     if test "$CONVERT" = false
 305     then
 306       AC_MSG_RESULT([no ($convert_version_major.$convert_version_minor)])
 307       AC_MSG_ERROR([You need imagemagick version 6.6 or newer to rebuild icons in maintainer mode.])
 308     else
 309       AC_MSG_RESULT([yes ($convert_version_major.$convert_version_minor)])
 310     fi
 311   fi
 312
 313   dnl Check the icotool version
 314   if test "$ICOTOOL" = false
 315   then
 316     AC_MSG_ERROR([You need icotool to rebuild icons in maintainer mode.])
 317   else
 318     AC_MSG_CHECKING([for recent enough icotool])
 319     icotool_version=`icotool --version | head -n1`
 320     if test "x$icotool_version" != "x"
 321     then
 322       icotool_version_major=`expr "$icotool_version" : '.* \([[0-9]]*\)\.[[0-9]]*'`
 323       icotool_version_minor=`expr "$icotool_version" : '.* [[0-9]]*\.\([[0-9]]*\)'`
 324       if test "$icotool_version_major" -eq 0 -a "$icotool_version_minor" -lt 29
 325       then
 326         ICOTOOL=false
 327         WINE_WARNING([icotool version 0.29.0 or newer is needed to rebuild icons.])
 328       fi
 329     fi
 330     if test "$ICOTOOL" = false
 331     then
 332       AC_MSG_RESULT([no ($icotool_version_major.$icotool_version_minor)])
 333       AC_MSG_ERROR([You need icotool version 0.29.0 or newer to rebuild icons in maintainer mode.])
 334     else
 335       AC_MSG_RESULT([yes ($icotool_version_major.$icotool_version_minor)])
 336     fi
 337   fi
 338
 339   dnl Maintainer mode requires gettext
 340   with_gettext=yes
 341   with_gettextpo=yes
 342   AS_UNSET(ac_cv_header_gettext_po_h)
 343 fi
 344
 345 test "x$with_gettext" != xno || MSGFMT=false
 346 if test "$MSGFMT" != "false"
 347 then
 348   AC_MSG_CHECKING([whether msgfmt supports contexts])
 349   cat >conftest.po <<EOF
 350 # comment
 351 msgctxt "ctxt"
 352 msgid "id"
 353 msgstr "str"
 354 EOF
 355   if $MSGFMT -o /dev/null conftest.po 2>&AS_MESSAGE_LOG_FD
 356   then
 357     AC_MSG_RESULT([yes])
 358   else
 359     AC_MSG_RESULT([no])
 360     MSGFMT=false
 361   fi
 362 fi
 363 WINE_WARNING_WITH(gettext,[test "$MSGFMT" = false],
 364                   [gettext tools not found (or too old), translations won't be built.])
 365
 366 dnl **** Check for some libraries ****
 367
 368 dnl Check for -li386 for NetBSD and OpenBSD
 369 AC_CHECK_LIB(i386,i386_set_ldt)
 370 dnl Check for -lossaudio for NetBSD
 371 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 372
 373 AC_SUBST(XLIB,"")
 374 AC_SUBST(OPENGL_LIBS,"")
 375
 376 dnl **** Check for header files ****
 377
 378 test "x$with_fontconfig" != "xno" || ac_cv_header_fontconfig_fontconfig_h=no
 379
 380 AC_SYS_LARGEFILE()
 381
 382 AC_CHECK_HEADERS(\
 383         AL/al.h \
 384         ApplicationServices/ApplicationServices.h \
 385         AudioToolbox/AudioConverter.h \
 386         AudioUnit/AudioUnit.h \
 387         AudioUnit/AudioComponent.h \
 388         CL/cl.h \
 389         Carbon/Carbon.h \
 390         CoreAudio/CoreAudio.h \
 391         CoreServices/CoreServices.h \
 392         DiskArbitration/DiskArbitration.h \
 393         IOKit/IOKitLib.h \
 394         IOKit/hid/IOHIDLib.h \
 395         OpenAL/al.h \
 396         OpenCL/opencl.h \
 397         QuickTime/ImageCompression.h \
 398         Security/Security.h \
 399         alias.h \
 400         alsa/asoundlib.h \
 401         arpa/inet.h \
 402         arpa/nameser.h \
 403         asm/types.h \
 404         asm/user.h \
 405         curses.h \
 406         direct.h \
 407         dirent.h \
 408         dlfcn.h \
 409         elf.h \
 410         float.h \
 411         fnmatch.h \
 412         fontconfig/fontconfig.h \
 413         getopt.h \
 414         gettext-po.h \
 415         grp.h \
 416         gsm.h \
 417         gsm/gsm.h \
 418         ieeefp.h \
 419         inet/mib2.h \
 420         io.h \
 421         kstat.h \
 422         lber.h \
 423         ldap.h \
 424         libproc.h \
 425         link.h \
 426         linux/cdrom.h \
 427         linux/compiler.h \
 428         linux/filter.h \
 429         linux/hdreg.h \
 430         linux/input.h \
 431         linux/ioctl.h \
 432         linux/joystick.h \
 433         linux/major.h \
 434         linux/param.h \
 435         linux/serial.h \
 436         linux/types.h \
 437         linux/ucdrom.h \
 438         lwp.h \
 439         mach-o/nlist.h \
 440         mach-o/loader.h \
 441         mach/mach.h \
 442         mach/machine.h \
 443         machine/cpu.h \
 444         machine/limits.h \
 445         machine/sysarch.h \
 446         mntent.h \
 447         ncurses.h \
 448         netdb.h \
 449         netinet/in.h \
 450         netinet/in_systm.h \
 451         netinet/tcp.h \
 452         netinet/tcp_fsm.h \
 453         poll.h \
 454         port.h \
 455         process.h \
 456         pthread.h \
 457         pwd.h \
 458         sched.h \
 459         scsi/scsi.h \
 460         scsi/scsi_ioctl.h \
 461         scsi/sg.h \
 462         stdbool.h \
 463         stdint.h \
 464         stropts.h \
 465         sys/asoundlib.h \
 466         sys/attr.h \
 467         sys/cdio.h \
 468         sys/elf32.h \
 469         sys/epoll.h \
 470         sys/event.h \
 471         sys/exec_elf.h \
 472         sys/filio.h \
 473         sys/inotify.h \
 474         sys/ioctl.h \
 475         sys/ipc.h \
 476         sys/limits.h \
 477         sys/link.h \
 478         sys/mman.h \
 479         sys/modem.h \
 480         sys/msg.h \
 481         sys/mtio.h \
 482         sys/param.h \
 483         sys/poll.h \
 484         sys/prctl.h \
 485         sys/protosw.h \
 486         sys/ptrace.h \
 487         sys/queue.h \
 488         sys/resource.h \
 489         sys/scsiio.h \
 490         sys/shm.h \
 491         sys/signal.h \
 492         sys/socket.h \
 493         sys/socketvar.h \
 494         sys/sockio.h \
 495         sys/statvfs.h \
 496         sys/strtio.h \
 497         sys/syscall.h \
 498         sys/tihdr.h \
 499         sys/time.h \
 500         sys/timeout.h \
 501         sys/times.h \
 502         sys/uio.h \
 503         sys/user.h \
 504         sys/utsname.h \
 505         sys/vm86.h \
 506         sys/wait.h \
 507         syscall.h \
 508         termios.h \
 509         unistd.h \
 510         utime.h \
 511         valgrind/memcheck.h \
 512         valgrind/valgrind.h \
 513         zlib.h
 514 )
 515 AC_HEADER_STAT()
 516
 517 dnl **** Checks for headers that depend on other ones ****
 518
 519 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/sysctl.h sys/user.h sys/vfs.h],,,
 520     [#include <sys/types.h>
 521      #ifdef HAVE_SYS_PARAM_H
 522      # include <sys/param.h>
 523      #endif])
 524
 525 AC_CHECK_HEADERS(\
 526         netinet/ip.h \
 527         net/if.h \
 528         net/if_arp.h \
 529         net/if_dl.h \
 530         net/if_types.h \
 531         net/route.h \
 532         netinet/if_ether.h \
 533         netinet/if_inarp.h \
 534         netinet/in_pcb.h \
 535         netinet/ip_icmp.h \
 536         netinet/ip_var.h \
 537         netinet/udp.h \
 538         netipx/ipx.h \
 539         sys/un.h \
 540 ,,,[#include <sys/types.h>
 541      #ifdef HAVE_SYS_SOCKET_H
 542      # include <sys/socket.h>
 543      #endif
 544      #ifdef HAVE_SYS_SOCKETVAR_H
 545      # include <sys/socketvar.h>
 546      #endif
 547      #ifdef HAVE_NET_ROUTE_H
 548      # include <net/route.h>
 549      #endif
 550      #ifdef HAVE_NETINET_IN_H
 551      # include <netinet/in.h>
 552      #endif
 553      #ifdef HAVE_NETINET_IN_SYSTM_H
 554      # include <netinet/in_systm.h>
 555      #endif
 556      #ifdef HAVE_NET_IF_H
 557      # include <net/if.h>
 558      #endif
 559      #ifdef HAVE_NETINET_IP_H
 560      # include <netinet/ip.h>
 561      #endif])
 562
 563 AC_CHECK_HEADERS([netinet/tcp_timer.h netinet/udp_var.h netinet/icmp_var.h netinet/tcp_var.h ],,,
 564     [#include <sys/types.h>
 565      #ifdef HAVE_ALIAS_H
 566      # include <alias.h>
 567      #endif
 568      #ifdef HAVE_SYS_SOCKET_H
 569      # include <sys/socket.h>
 570      #endif
 571      #ifdef HAVE_SYS_SOCKETVAR_H
 572      # include <sys/socketvar.h>
 573      #endif
 574      #ifdef HAVE_SYS_TIMEOUT_H
 575      # include <sys/timeout.h>
 576      #endif
 577      #ifdef HAVE_NETINET_IN_H
 578      # include <netinet/in.h>
 579      #endif
 580      #ifdef HAVE_NETINET_IN_SYSTM_H
 581      # include <netinet/in_systm.h>
 582      #endif
 583      #ifdef HAVE_NETINET_IP_H
 584      # include <netinet/ip.h>
 585      #endif
 586      #ifdef HAVE_NETINET_IP_VAR_H
 587      # include <netinet/ip_var.h>
 588      #endif
 589      #ifdef HAVE_NETINET_IP_ICMP_H
 590      # include <netinet/ip_icmp.h>
 591      #endif
 592      #ifdef HAVE_NETINET_UDP_H
 593      # include <netinet/udp.h>
 594      #endif
 595      #ifdef HAVE_NETINET_TCP_H
 596      # include <netinet/tcp.h>
 597      #endif
 598      #ifdef HAVE_NETINET_TCP_TIMER_H
 599      #include <netinet/tcp_timer.h>
 600      #endif])
 601
 602 AC_CHECK_HEADERS([linux/ipx.h linux/irda.h linux/rtnetlink.h],,,
 603     [#include <sys/types.h>
 604      #ifdef HAVE_ASM_TYPES_H
 605      # include <asm/types.h>
 606      #endif
 607      #ifdef HAVE_SYS_SOCKET_H
 608      # include <sys/socket.h>
 609      #endif
 610      #ifdef HAVE_LINUX_TYPES_H
 611      # include <linux/types.h>
 612      #endif])
 613
 614 AC_CHECK_HEADERS([mach-o/dyld_images.h],,,
 615     [#ifdef HAVE_STDBOOL_H
 616      # include <stdbool.h>
 617      #endif
 618      #ifdef HAVE_STDINT_H
 619      # include <stdint.h>
 620      #endif])
 621
 622 AC_CHECK_HEADERS([resolv.h],,,
 623     [#include <sys/types.h>
 624      #ifdef HAVE_SYS_SOCKET_H
 625      # include <sys/socket.h>
 626      #endif
 627      #ifdef HAVE_NETINET_IN_H
 628      # include <netinet/in.h>
 629      #endif
 630      #ifdef HAVE_ARPA_NAMESER_H
 631      # include <arpa/nameser.h>
 632      #endif])
 633
 634 AC_CHECK_HEADERS([ifaddrs.h],,,[#include <sys/types.h>])
 635
 636 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 637
 638 AC_CHECK_HEADERS([sys/thr.h],,,
 639 [#include <sys/types.h>
 640 #ifdef HAVE_UCONTEXT_H
 641 #include <ucontext.h>
 642 #endif])
 643
 644 AC_CHECK_HEADERS([pthread_np.h],,,
 645 [#ifdef HAVE_PTHREAD_H
 646 #include <pthread.h>
 647 #endif])
 648
 649 AC_CHECK_HEADERS([linux/videodev.h linux/videodev2.h libv4l1.h],,,
 650 [#ifdef HAVE_SYS_TIME_H
 651 #include <sys/time.h>
 652 #endif
 653 #include <sys/types.h>
 654 #ifdef HAVE_ASM_TYPES_H
 655 #include <asm/types.h>
 656 #endif])
 657
 658 AC_CHECK_HEADERS([libprocstat.h],,,
 659 [#ifdef HAVE_SYS_PARAM_H
 660 #include <sys/param.h>
 661 #endif
 662 #ifdef HAVE_SYS_QUEUE_H
 663 #include <sys/queue.h>
 664 #endif
 665 #ifdef HAVE_SYS_SOCKET_H
 666 #include <sys/socket.h>
 667 #endif])
 668
 669 dnl **** Check for working dll ****
 670
 671 AC_SUBST(dlldir,"\${libdir}/wine")
 672 AC_SUBST(DLLPREFIX,"")
 673 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 674 AC_SUBST(IMPLIBEXT,"def")
 675 AC_SUBST(LDRPATH_INSTALL,"")
 676 AC_SUBST(LDRPATH_LOCAL,"")
 677 LIBEXT="so"
 678 DLLEXT=".so"
 679 STATIC_IMPLIBEXT="def.a"
 680 WINE_PATH_SONAME_TOOLS
 681
 682 wine_binary="wine"
 683 test "x$enable_win64" != "xyes" || wine_binary="wine64"
 684
 685 AC_SUBST(LOADER_RULES,["
 686 all: $wine_binary wine-installed
 687
 688 install install-lib:: wine-installed \$(DESTDIR)\$(bindir)
 689         \$(INSTALL_PROGRAM) wine-installed \$(DESTDIR)\$(bindir)/$wine_binary
 690
 691 uninstall::
 692         \$(RM) \$(DESTDIR)\$(bindir)/$wine_binary
 693 "])
 694
 695 case $host_os in
 696   cygwin*|mingw32*)
 697     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 698     LIBEXT="dll"
 699     DLLEXT=""
 700     IMPLIBEXT="a"
 701     STATIC_IMPLIBEXT="a"
 702     dnl Disable modules that can't be used on Windows
 703     enable_iphlpapi=${enable_iphlpapi:-no}
 704     enable_kernel32=${enable_kernel32:-no}
 705     enable_msvcrt=${enable_msvcrt:-no}
 706     enable_ntdll=${enable_ntdll:-no}
 707     enable_ws2_32=${enable_ws2_32:-no}
 708     enable_loader=${enable_loader:-no}
 709     enable_server=${enable_server:-no}
 710     dnl Disable dependencies that are not useful on Windows
 711     with_x=${with_x:-no}
 712     with_pthread=${with_pthread:-no}
 713
 714     dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
 715     crtlibs=""
 716     case $host_os in
 717         mingw32*)
 718           crtlibs="-lmsvcrt"
 719           AC_SUBST(SOCKETLIBS,"-L\$(top_builddir)/dlls/ws2_32 -lws2_32") ;;
 720     esac
 721
 722     AC_SUBST(LIBWINE_RULES,["
 723 all: libwine.dll libwine.a
 724
 725 libwine.a: wine.def
 726         \$(DLLTOOL) -l \$@ -d \$(srcdir)/wine.def
 727
 728 libwine.dll: \$(OBJS) wine.def
 729         \$(CC) -shared \$(srcdir)/wine.def -o \$@ \$(OBJS) $crtlibs \$(EXTRALIBS)
 730
 731 install install-lib:: libwine.dll \$(DESTDIR)\$(libdir) dummy
 732         \$(INSTALL_DATA) libwine.dll \$(DESTDIR)\$(libdir)/libwine.dll
 733
 734 install install-dev:: libwine.a \$(DESTDIR)\$(libdir) dummy
 735         \$(INSTALL_DATA) libwine.a \$(DESTDIR)\$(libdir)/libwine.a
 736
 737 uninstall::
 738         -cd \$(DESTDIR)\$(libdir) && \$(RM) libwine.a libwine.dll
 739
 740 clean::
 741         \$(RM) libwine.dll version.c
 742 "])
 743     ;;
 744
 745   darwin*|macosx*)
 746     LIBEXT="dylib"
 747     DLLFLAGS="$DLLFLAGS -fPIC"
 748     LIBWINE_LDFLAGS="-multiply_defined suppress"
 749     LDRPATH_INSTALL="-Wl,-rpath,@loader_path/\`\$(MAKEDEP) -R \$(bindir) \$(libdir)\`"
 750     LDRPATH_LOCAL="-Wl,-rpath,@loader_path/\$(top_builddir)/libs/wine"
 751     dnl declare needed frameworks
 752     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 753     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 754     AC_SUBST(FORCEFEEDBACKLIB,"-framework ForceFeedback -framework CoreFoundation")
 755     AC_SUBST(APPLICATIONSERVICESLIB,"-framework ApplicationServices")
 756     AC_SUBST(CORESERVICESLIB,"-framework CoreServices")
 757     AC_SUBST(APPKITLIB,"-framework AppKit")
 758     LDEXECFLAGS="-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00001000,-segaddr,WINE_SHAREDHEAP,0x7f000000,-sectcreate,__TEXT,__info_plist,wine_info.plist"
 759     case $host_os in
 760       darwin11*) LDEXECFLAGS="-Wl,-macosx_version_min,10.6 $LDEXECFLAGS" ;;
 761     esac
 762     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 763     then
 764         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 765         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 766     fi
 767     if test "$ac_cv_header_Security_Security_h" = "yes"
 768     then
 769         AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 770         dnl Check for the SSLCopyPeerCertificates function
 771         ac_save_LIBS="$LIBS"
 772         LIBS="$LIBS $SECURITYLIB"
 773         AC_CHECK_FUNCS(SSLCopyPeerCertificates)
 774         LIBS="$ac_save_LIBS"
 775         with_gnutls=${with_gnutls:-no}
 776     fi
 777     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 778     then
 779         if test "$ac_cv_header_AudioUnit_AudioComponent_h" = "yes"
 780         then
 781             AC_SUBST(COREAUDIO,"-framework CoreFoundation -framework CoreAudio -framework AudioUnit -framework AudioToolbox -framework CoreMIDI")
 782         else
 783             dnl CoreServices needed by AudioUnit
 784             AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 785         fi
 786         dnl Check for the AUGraphAddNode function
 787         ac_save_LIBS="$LIBS"
 788         LIBS="$LIBS $COREAUDIO"
 789         AC_CHECK_FUNCS(AUGraphAddNode)
 790         LIBS="$ac_save_LIBS"
 791     fi
 792     if test "$ac_cv_header_OpenAL_al_h" = "yes"
 793     then
 794         AC_SUBST(FRAMEWORK_OPENAL,"-framework OpenAL")
 795         AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])
 796         ac_cv_lib_openal=yes
 797     fi
 798     if test "$ac_cv_header_OpenCL_opencl_h" = "yes"
 799     then
 800         AC_SUBST(LIBOPENCL,"-framework OpenCL")
 801         ac_cv_lib_OpenCL_clGetPlatformInfo=yes
 802     fi
 803     if test "$ac_cv_header_IOKit_hid_IOHIDLib_h" = "yes"
 804     then
 805         ac_save_LIBS="$LIBS"
 806         LIBS="$LIBS $IOKITLIB"
 807         AC_CHECK_FUNCS(IOHIDManagerCreate)
 808         LIBS="$ac_save_LIBS"
 809     fi
 810     if test "$ac_cv_header_QuickTime_ImageCompression_h" = "yes"
 811     then
 812         AC_SUBST(QUICKTIMELIB,"-framework QuickTime -framework ApplicationServices -framework CoreVideo")
 813         enable_wineqtdecoder=${enable_wineqtdecoder:-yes}
 814     else
 815         WINE_NOTICE([QuickTime ${notice_platform}development files not found, video decoding won't be supported.])
 816     fi
 817     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 818     then
 819         AC_SUBST(CARBONLIB,"-framework Carbon")
 820     fi
 821
 822     dnl Enable Mac driver on Mac OS X 10.6 or later
 823     if test "$ac_cv_header_ApplicationServices_ApplicationServices_h" = "yes"
 824     then
 825         ac_save_LIBS="$LIBS"
 826         LIBS="$LIBS $APPLICATIONSERVICESLIB"
 827         AC_CHECK_FUNC(CGDisplayModeGetWidth,enable_winemac_drv=${enable_winemac_drv:-yes})
 828         LIBS="$ac_save_LIBS"
 829     fi
 830
 831     dnl Check for Xcode 3.x broken 16-bit support
 832     if test "x$enable_win16" = "xyes"
 833     then
 834         AC_MSG_CHECKING([whether 16-bit code can be built correctly])
 835         AC_RUN_IFELSE([AC_LANG_PROGRAM([[asm(".text\n"
 836                                             "bad:\tnop;nop\n"
 837                                             "good:\tnop;nop\n\t"
 838                                             ".globl _testfunc\n"
 839                                             "_testfunc:\tcallw good");
 840                                         extern void testfunc();]],
 841                                       [[unsigned short *p = (unsigned short *)testfunc;
 842                                         return p[0] != 0xe866 || p[1] != 0xfffa]])],
 843                                       AC_MSG_RESULT(yes),
 844                                       [AC_MSG_RESULT(no)
 845                                        AC_MSG_ERROR([Xcode 3.x cannot build 16-bit code correctly. Use --disable-win16 if you don't need 16-bit support.])],
 846                                        AC_MSG_RESULT([[cross-compiling, assuming yes]]))
 847     fi
 848
 849     AC_SUBST(LIBWINE_RULES,["
 850 all: libwine.dylib
 851
 852 libwine.\$(VERSION).dylib: \$(OBJS)
 853         \$(CC) -dynamiclib -install_name @rpath/libwine.\$(SOVERSION).dylib -Wl,-rpath,@loader_path/ -compatibility_version \$(SOVERSION) -current_version \$(VERSION) \$(OBJS) \$(EXTRALIBS) \$(LDFLAGS) \$(LIBS) -o \$@
 854
 855 libwine.\$(SOVERSION).dylib: libwine.\$(VERSION).dylib
 856         \$(RM) \$@ && \$(LN_S) libwine.\$(VERSION).dylib \$@
 857
 858 libwine.dylib: libwine.\$(SOVERSION).dylib
 859         \$(RM) \$@ && \$(LN_S) libwine.\$(SOVERSION).dylib \$@
 860
 861 install install-lib:: libwine.\$(VERSION).dylib \$(DESTDIR)\$(libdir) dummy
 862         \$(INSTALL_PROGRAM) libwine.\$(VERSION).dylib \$(DESTDIR)\$(libdir)/libwine.\$(VERSION).dylib
 863         cd \$(DESTDIR)\$(libdir) && \$(RM) libwine.\$(SOVERSION).dylib && \$(LN_S) libwine.\$(VERSION).dylib libwine.\$(SOVERSION).dylib
 864
 865 install install-dev:: \$(DESTDIR)\$(libdir) dummy
 866         cd \$(DESTDIR)\$(libdir) && \$(RM) libwine.dylib && \$(LN_S) libwine.\$(VERSION).dylib libwine.dylib
 867
 868 uninstall::
 869         -cd \$(DESTDIR)\$(libdir) && \$(RM) libwine.dylib libwine.\$(VERSION).dylib libwine.\$(SOVERSION).dylib
 870
 871 clean::
 872         \$(RM) libwine.dylib libwine.\$(VERSION).dylib libwine.\$(SOVERSION).dylib version.c
 873 "])
 874
 875     AS_VAR_APPEND([LOADER_RULES],["
 876 $wine_binary: main.o wine_info.plist
 877         \$(CC) -o \$@ $LDEXECFLAGS main.o \$(LIBWINE) \$(LIBPORT) \$(EXTRALIBS) \$(LDFLAGS) \$(LDRPATH_LOCAL)
 878
 879 wine-installed: main.o wine_info.plist
 880         \$(CC) -o \$@ $LDEXECFLAGS main.o \$(LIBWINE) \$(LIBPORT) \$(EXTRALIBS) \$(LDFLAGS) \$(LDRPATH_INSTALL)
 881
 882 wine_info.plist: wine_info.plist.in \$(top_builddir)/include/config.h
 883         LC_ALL=C sed -e 's,@PACKAGE_VERSION@,$PACKAGE_VERSION,g' \$(srcdir)/wine_info.plist.in >\$@ || (\$(RM) \$@ && false)
 884 "])
 885     ;;
 886
 887   linux-android*)
 888     DLLFLAGS="$DLLFLAGS -fPIC"
 889     DLLPREFIX="lib"
 890     LDEXECFLAGS=""
 891     dlldir="\${libdir}"
 892     WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 893                     [LDEXECFLAGS="-Wl,--export-dynamic"])
 894     WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 895                     [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(MAKEDEP) -R \$(bindir) \$(libdir)\`"
 896                      LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"],
 897         [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 898                          [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(MAKEDEP) -R \$(bindir) \$(libdir)\`"
 899                           LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"])])
 900
 901     WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 902                     [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 903
 904     case $host_cpu in
 905       *i[[3456789]]86* | x86_64)
 906         WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 907                         [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 908         ;;
 909     esac
 910
 911     AC_SUBST(LIBWINE_RULES,["
 912 all: libwine.so
 913
 914 libwine.so: \$(OBJS)
 915         \$(CC) -shared \$(OBJS) \$(EXTRALIBS) \$(LDFLAGS) \$(LIBS) -o \$@
 916
 917 install install-lib:: libwine.so \$(DESTDIR)\$(libdir) dummy
 918         \$(INSTALL_PROGRAM) libwine.so \$(DESTDIR)\$(libdir)/libwine.so
 919
 920 uninstall::
 921         \$(RM) \$(DESTDIR)\$(libdir)/libwine.so
 922
 923 clean::
 924         \$(RM) libwine.so version.c
 925 "])
 926
 927     AS_VAR_APPEND([LOADER_RULES],["
 928 $wine_binary: main.o
 929         \$(CC) -o \$@ $LDEXECFLAGS main.o \$(LIBWINE) \$(LIBPORT) \$(EXTRALIBS) \$(LDFLAGS) \$(LDRPATH_LOCAL)
 930
 931 wine-installed: main.o
 932         \$(CC) -o \$@ $LDEXECFLAGS main.o \$(LIBWINE) \$(LIBPORT) \$(EXTRALIBS) \$(LDFLAGS) \$(LDRPATH_INSTALL)
 933 "])
 934     ;;
 935
 936   *)
 937     DLLFLAGS="$DLLFLAGS -fPIC"
 938     LDEXECFLAGS=""
 939     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 940         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 941                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 942     if test "$ac_cv_c_dll_gnuelf" = "yes"
 943     then
 944       LDSHARED="\$(CC) -shared"
 945       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 946                       [LDSHARED="\$(CC) -shared -Wl,-soname,libwine.so.\$(SOVERSION)"],
 947                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 948                                        [LDSHARED="\$(CC) -shared -Wl,-h,libwine.so.\$(SOVERSION)"])])
 949
 950       echo '{ global: *; };' >conftest.map
 951       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 952                       [LDSHARED="$LDSHARED -Wl,--version-script=\$(srcdir)/wine.map"])
 953       rm -f conftest.map
 954
 955       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 956                       [LDEXECFLAGS="-Wl,--export-dynamic"])
 957
 958       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 959                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(MAKEDEP) -R \$(bindir) \$(libdir)\`"
 960                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"],
 961           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 962                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(MAKEDEP) -R \$(bindir) \$(libdir)\`"
 963                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"])])
 964
 965       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 966                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 967
 968       case $host_cpu in
 969         *i[[3456789]]86* | x86_64)
 970           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 971                           [case $host_os in
 972                            freebsd* | kfreebsd*-gnu) LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x60000400" ;;
 973                            *) LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400" ;;
 974                            esac
 975                           ])
 976           AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 977           if test "x$PRELINK" = xfalse
 978           then
 979               WINE_WARNING([prelink not found, base address of core dlls won't be set correctly.])
 980           fi
 981           ;;
 982       esac
 983
 984     else
 985       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 986           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 987                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 988       if test "$ac_cv_c_dll_unixware" = "yes"
 989       then
 990         LDSHARED="\$(CC) -Wl,-G,-h,libwine.so.\$(SOVERSION)"
 991       fi
 992     fi
 993     AC_SUBST(LIBWINE_RULES,["
 994 all: libwine.so
 995
 996 libwine.so.\$(VERSION): \$(OBJS) wine.map
 997         $LDSHARED \$(OBJS) \$(EXTRALIBS) \$(LDFLAGS) \$(LIBS) -o \$@
 998
 999 libwine.so.\$(SOVERSION): libwine.so.\$(VERSION)
1000         \$(RM) \$@ && \$(LN_S) libwine.so.\$(VERSION) \$@
1001
1002 libwine.so: libwine.so.\$(SOVERSION)
1003         \$(RM) \$@ && \$(LN_S) libwine.so.\$(SOVERSION) \$@
1004
1005 install install-lib:: libwine.so.\$(VERSION) \$(DESTDIR)\$(libdir) dummy
1006         \$(INSTALL_PROGRAM) libwine.so.\$(VERSION) \$(DESTDIR)\$(libdir)/libwine.so.\$(VERSION)
1007         cd \$(DESTDIR)\$(libdir) && \$(RM) libwine.so.\$(SOVERSION) && \$(LN_S) libwine.so.\$(VERSION) libwine.so.\$(SOVERSION)
1008
1009 install install-dev:: \$(DESTDIR)\$(libdir) dummy
1010         cd \$(DESTDIR)\$(libdir) && \$(RM) libwine.so && \$(LN_S) libwine.so.\$(VERSION) libwine.so
1011
1012 uninstall::
1013         -cd \$(DESTDIR)\$(libdir) && \$(RM) libwine.so libwine.so.\$(VERSION) libwine.so.\$(SOVERSION)
1014
1015 clean::
1016         \$(RM) libwine.so.\$(SOVERSION) libwine.so.\$(VERSION) version.c
1017 "])
1018
1019     AS_VAR_APPEND([LOADER_RULES],["
1020 $wine_binary: main.o
1021         \$(CC) -o \$@ $LDEXECFLAGS main.o \$(LIBWINE) \$(LIBPORT) \$(EXTRALIBS) \$(LDFLAGS) \$(LDRPATH_LOCAL)
1022
1023 wine-installed: main.o
1024         \$(CC) -o \$@ $LDEXECFLAGS main.o \$(LIBWINE) \$(LIBPORT) \$(EXTRALIBS) \$(LDFLAGS) \$(LDRPATH_INSTALL)
1025 "])
1026     ;;
1027 esac
1028
1029 enable_wineqtdecoder=${enable_wineqtdecoder:-no}
1030 enable_winemac_drv=${enable_winemac_drv:-no}
1031
1032 dnl Check for cross compiler to build test programs
1033 AC_SUBST(CROSSTARGET,"")
1034 if test "$cross_compiling" = "no" -a "x$enable_tests" != xno -a "$LIBEXT" != "dll"
1035 then
1036     WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
1037     if test "$CROSSCC" != "false"
1038     then
1039         ac_save_CC="$CC"
1040         CC="$CROSSCC"
1041         AC_MSG_CHECKING([whether $CROSSCC works])
1042         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
1043                           [AC_MSG_RESULT([yes])
1044                            set x $CROSSCC
1045                            shift
1046                            while test $# -ge 1
1047                            do
1048                                case "$1" in
1049                                  *-gcc) CROSSTARGET=`expr "$1" : '\(.*\)-gcc'` ;;
1050                                esac
1051                                shift
1052                            done],
1053                           [AC_MSG_RESULT([no])])
1054         CC="$ac_save_CC"
1055     fi
1056 fi
1057
1058 dnl **** Check for pthread ****
1059
1060 if test "$ac_cv_header_pthread_h" = "yes"
1061 then
1062     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,[AC_SUBST(LIBPTHREAD,"-lpthread")])])
1063 fi
1064 WINE_ERROR_WITH(pthread,[test "x$ac_cv_func_pthread_create" != xyes -a "x$LIBPTHREAD" = x],
1065 [pthread ${notice_platform}development files not found.
1066 Wine cannot support threads without libpthread.])
1067
1068 dnl **** Check for X11 ****
1069
1070 AC_PATH_XTRA
1071
1072 if test "$have_x" = "yes"
1073 then
1074     XLIB="-lX11"
1075     ac_save_CPPFLAGS="$CPPFLAGS"
1076     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1077
1078     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
1079     WINE_CHECK_SONAME(Xext,XextCreateExtension,[XLIB="-lXext $XLIB"],,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1080
1081     dnl *** All of the following tests require X11/Xlib.h
1082     AC_CHECK_HEADERS([X11/Xlib.h \
1083                       X11/XKBlib.h \
1084                       X11/Xutil.h \
1085                       X11/Xcursor/Xcursor.h \
1086                       X11/extensions/shape.h \
1087                       X11/extensions/XInput.h \
1088                       X11/extensions/XInput2.h \
1089                       X11/extensions/XShm.h \
1090                       X11/extensions/Xcomposite.h \
1091                       X11/extensions/Xinerama.h \
1092                       X11/extensions/Xrandr.h \
1093                       X11/extensions/Xrender.h \
1094                       X11/extensions/xf86vmode.h \
1095                       X11/extensions/xf86vmproto.h],,,
1096 [#ifdef HAVE_X11_XLIB_H
1097 # include <X11/Xlib.h>
1098 #endif
1099 #ifdef HAVE_X11_XUTIL_H
1100 # include <X11/Xutil.h>
1101 #endif])
1102
1103         dnl *** Check for X keyboard extension
1104         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
1105         then
1106               AC_CHECK_LIB(X11, XkbQueryExtension,
1107               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
1108               $X_LIBS $XLIB $X_EXTRA_LIBS)
1109         fi
1110
1111         dnl *** Check for X cursor
1112         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
1113         then
1114             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1115         fi
1116         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
1117                          [libxcursor ${notice_platform}development files not found, the Xcursor extension won't be supported.])
1118
1119         dnl *** Check for X input extension
1120         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
1121         then
1122             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1123         fi
1124         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
1125                          [libxi ${notice_platform}development files not found, the Xinput extension won't be supported.])
1126
1127         dnl *** Check for X input 2 extension
1128         if test "x$ac_cv_lib_soname_Xi" != x
1129         then
1130             WINE_NOTICE_WITH(xinput2,[test "$ac_cv_header_X11_extensions_XInput2_h" != "yes"],
1131                              [XInput2 headers not found, the XInput 2 extension won't be supported.])
1132         fi
1133
1134         dnl *** Check for X Shm extension
1135         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
1136         then
1137               AC_CHECK_LIB(Xext, XShmQueryExtension,
1138               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
1139               $X_LIBS $XLIB $X_EXTRA_LIBS)
1140         fi
1141         WINE_NOTICE_WITH(xshm,[test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],
1142                          [XShm ${notice_platform}development files not found, X Shared Memory won't be supported.])
1143
1144         dnl *** Check for X shape extension
1145         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
1146         then
1147               AC_CHECK_LIB(Xext,XShapeQueryExtension,
1148               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
1149               $X_LIBS $XLIB $X_EXTRA_LIBS)
1150         fi
1151         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
1152                          [XShape ${notice_platform}development files not found, XShape won't be supported.])
1153
1154         dnl *** Check for XFree86 VMODE extension
1155         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes" -o "$ac_cv_header_X11_extensions_xf86vmproto_h" = "yes"
1156         then
1157             WINE_CHECK_SONAME(Xxf86vm,XF86VidModeQueryExtension,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1158         fi
1159         WINE_NOTICE_WITH(xxf86vm,[test "x$ac_cv_lib_soname_Xxf86vm" = "x"],
1160                          [libXxf86vm ${notice_platform}development files not found, XFree86 Vidmode won't be supported.])
1161
1162         dnl *** Check for Transform functions in Xrender
1163         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
1164         then
1165             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
1166               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
1167                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
1168                  [Define if Xrender has the XRenderSetPictureTransform function])],,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1169                AC_CHECK_LIB(Xrender,XRenderCreateLinearGradient,
1170                 [AC_DEFINE(HAVE_XRENDERCREATELINEARGRADIENT, 1,
1171                  [Define if Xrender has the XRenderCreateLinearGradient function])],,[$X_LIBS $XLIB $X_EXTRA_LIBS])],,
1172               [$X_LIBS $XLIB $X_EXTRA_LIBS])
1173
1174         fi
1175         WINE_WARNING_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
1176                          [libxrender ${notice_platform}development files not found, XRender won't be supported.])
1177
1178         dnl *** Check for X RandR extension
1179         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
1180         then
1181                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1182 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func; if (func) return 0;]])],
1183                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,
1184                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1185 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRGetScreenResources) *f; if (f) return 0;]])],
1186                       [AC_DEFINE(HAVE_XRRGETSCREENRESOURCES, 1,
1187                         [Define if Xrandr has the XRRGetScreenResources function])])],,
1188                     [$X_LIBS $XLIB $X_EXTRA_LIBS])])
1189         fi
1190         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
1191                          [libxrandr ${notice_platform}development files not found, XRandr won't be supported.])
1192
1193         dnl *** Check for Xinerama extension
1194         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
1195         then
1196                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1197 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func; if (func) return 0;]])],
1198                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])])
1199         fi
1200         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
1201                          [libxinerama ${notice_platform}development files not found, multi-monitor setups won't be supported.])
1202
1203         dnl *** Check for X Composite extension
1204         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
1205         then
1206             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1207         fi
1208         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
1209                          [libxcomposite ${notice_platform}development files not found, Xcomposite won't be supported.])
1210
1211         dnl *** Check for XICCallback struct
1212         AC_CHECK_MEMBERS([XICCallback.callback, XEvent.xcookie],,,
1213 [#ifdef HAVE_X11_XLIB_H
1214 #include <X11/Xlib.h>
1215 #endif])
1216
1217     dnl *** End of X11/Xlib.h check
1218
1219     dnl Check for the presence of OpenGL
1220     opengl_msg=""
1221     if test "x$with_opengl" != "xno"
1222     then
1223         WINE_CHECK_SONAME(GL,glXCreateContext,
1224                      [OPENGL_LIBS="-lGL"],
1225                      [WINE_CHECK_SONAME(GL,glXCreateContext,
1226                             [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"],
1227                             [if test -f /usr/X11R6/lib/libGL.a
1228                             then
1229                                 opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
1230 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
1231                             else
1232                                 opengl_msg="No OpenGL library found on this system."
1233                             fi],
1234                             $X_LIBS $XLIB -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
1235                      $X_LIBS $XLIB -lm $X_EXTRA_LIBS)
1236         if test "x$with_glu" != "xno"
1237         then
1238             AC_CHECK_LIB(GLU,gluLookAt,[:],,[$OPENGL_LIBS $X_LIBS $XLIB -lm $X_EXTRA_LIBS])
1239             WINE_NOTICE_WITH(glu,[test "x$ac_cv_lib_GLU_gluLookAt" != xyes],
1240                              [libGLU ${notice_platform}development files not found, GLU won't be supported.])
1241         fi
1242
1243         if test "x$with_osmesa" != "xno"
1244         then
1245             WINE_CHECK_SONAME(OSMesa,glAccum,,,[$X_LIBS $XLIB -lm $X_EXTRA_LIBS])
1246             WINE_NOTICE_WITH(osmesa,[test "x$ac_cv_lib_soname_OSMesa" = "x"],
1247                              [libOSMesa ${notice_platform}development files not found (or too old), OpenGL rendering in bitmaps won't be supported.])
1248         fi
1249     fi
1250     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
1251 OpenGL and Direct3D won't be supported.])
1252
1253     CPPFLAGS="$ac_save_CPPFLAGS"
1254 else
1255     XLIB=""
1256     X_CFLAGS=""
1257     X_LIBS=""
1258     enable_winex11_drv=${enable_winex11_drv:-no}
1259 fi
1260 WINE_ERROR_WITH(x,[test "x$XLIB" = "x"],[X ${notice_platform}development files not found. Wine will be built
1261 without X support, which probably isn't what you want. You will need
1262 to install ${notice_platform}development packages of Xlib/Xfree86 at the very least.])
1263
1264 test "x$ac_cv_lib_GLU_gluLookAt" != xyes && enable_glu32=${enable_glu32:-no}
1265
1266 dnl **** Check for OpenCL ****
1267 if test "$ac_cv_header_CL_cl_h" = "yes"
1268 then
1269     AC_CHECK_LIB(OpenCL,clGetPlatformInfo,[AC_SUBST(LIBOPENCL,["-lOpenCL"])])
1270 fi
1271 WINE_NOTICE_WITH(opencl,[test "x$ac_cv_lib_OpenCL_clGetPlatformInfo" != xyes],
1272                  [OpenCL ${notice_platform}development files not found, OpenCL won't be supported.])
1273 test "x$ac_cv_lib_OpenCL_clGetPlatformInfo" != xyes && enable_opencl=${enable_opencl:-no}
1274
1275 dnl **** Check for libxml2 ****
1276
1277 if test "x$with_xml" != "xno"
1278 then
1279     WINE_PACKAGE_FLAGS(XML2,[libxml-2.0],[-lxml2],
1280                        [`xml2-config --cflags 2>/dev/null`],[`xml2-config --libs 2>/dev/null`],
1281         [AC_CHECK_HEADERS([libxml/parser.h libxml/xmlsave.h libxml/SAX2.h])
1282         if test "$ac_cv_header_libxml_parser_h" = "yes" -a "$ac_cv_header_libxml_xmlsave_h" = "yes" -a "$ac_cv_header_libxml_SAX2_h" = "yes"
1283         then
1284             AC_CHECK_LIB(xml2, xmlParseMemory,
1285                 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])],[XML2_LIBS=""],[$XML2_LIBS])
1286             AC_CHECK_LIB(xml2, xmlReadMemory,
1287                 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,[$XML2_LIBS])
1288             AC_CHECK_LIB(xml2, xmlNewDocPI,
1289                 [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,[$XML2_LIBS])
1290             AC_CHECK_LIB(xml2, xmlSchemaSetParserStructuredErrors,
1291                 [AC_DEFINE(HAVE_XMLSCHEMASSETPARSERSTRUCTUREDERRORS,1,[Define if libxml2 has the xmlSchemaSetParserStructuredErrors function])],,[$XML2_LIBS])
1292             AC_CHECK_LIB(xml2, xmlSchemaSetValidStructuredErrors,
1293                 [AC_DEFINE(HAVE_XMLSCHEMASSETVALIDSTRUCTUREDERRORS,1,[Define if libxml2 has the xmlSchemaSetValidStructuredErrors function])],,[$XML2_LIBS])
1294             AC_CHECK_LIB(xml2, xmlFirstElementChild,
1295                 [AC_DEFINE(HAVE_XMLFIRSTELEMENTCHILD,1,[Define if libxml2 has the xmlFirstElementChild function])],,[$XML2_LIBS])
1296             AC_CHECK_TYPE([xmlDocProperties],
1297                 [AC_DEFINE(HAVE_XMLDOC_PROPERTIES,1,[Define if libxml2 has the xmlDocProperties enum])],,[[#include <libxml/tree.h>]])
1298         else
1299             XML2_CFLAGS=""
1300             XML2_LIBS=""
1301         fi])
1302 fi
1303 WINE_WARNING_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
1304                  [libxml2 ${notice_platform}development files not found (or too old), XML won't be supported.])
1305
1306 if test "x$with_xslt" != "xno"
1307 then
1308     WINE_PACKAGE_FLAGS(XSLT,[libxslt],[-lxml2],
1309                        [`xslt-config --cflags 2>/dev/null`],[`xslt-config --libs 2>/dev/null`],
1310         [AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],,,
1311         [#ifdef HAVE_LIBXSLT_PATTERN_H
1312 # include <libxslt/pattern.h>
1313 #endif])
1314         if test "$ac_cv_header_libxslt_transform_h" = "yes"
1315         then
1316             WINE_CHECK_SONAME(xslt,xsltCompilePattern,,,[$XSLT_LIBS])
1317         else
1318             XSLT_CFLAGS=""
1319         fi])
1320 fi
1321 WINE_WARNING_WITH(xslt,[test "x$ac_cv_lib_soname_xslt" = "x"],
1322                  [libxslt ${notice_platform}development files not found, xslt won't be supported.])
1323
1324 dnl **** Check for libdbus ****
1325 if test "x$with_dbus" != "xno"
1326 then
1327     WINE_PACKAGE_FLAGS(DBUS,[dbus-1],,,,
1328         [AC_CHECK_HEADER([dbus/dbus.h],
1329             [WINE_CHECK_SONAME(dbus-1, dbus_connection_close,,[DBUS_CFLAGS=""],[$DBUS_LIBS])],
1330             [DBUS_CFLAGS=""])])
1331 fi
1332 WINE_NOTICE_WITH(dbus,[test "x$ac_cv_lib_soname_dbus_1" = "x" -a \
1333                             "x$ac_cv_header_DiskArbitration_DiskArbitration_h" != "xyes"],
1334                  [libdbus ${notice_platform}development files not found, no dynamic device support.])
1335
1336 dnl **** Check for libhal ****
1337 if test "x$with_hal" != "xno" -a "x$ac_cv_lib_soname_dbus_1" != x
1338 then
1339     WINE_PACKAGE_FLAGS(HAL,[hal],[-ldbus-1],,,
1340         [AC_CHECK_HEADER([hal/libhal.h],
1341             [WINE_CHECK_SONAME(hal, libhal_ctx_new,,[HAL_CFLAGS=""],[$HAL_LIBS])],
1342             [HAL_CFLAGS=""])])
1343     WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x" -a \
1344                                "x$ac_cv_header_DiskArbitration_DiskArbitration_h" != "xyes"],
1345                      [libhal ${notice_platform}development files not found, no legacy dynamic device support.])
1346 fi
1347
1348 dnl **** Check for libgnutls ****
1349 if test "x$with_gnutls" != "xno"
1350 then
1351     WINE_PACKAGE_FLAGS(GNUTLS,[gnutls],,,,
1352         [AC_CHECK_HEADER(gnutls/gnutls.h,
1353             [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>
1354 #include <gnutls/crypto.h>]], [[static typeof(gnutls_mac_get_key_size) *func; if (func) return 0;]])],
1355                 [WINE_CHECK_SONAME(gnutls,gnutls_global_init,,[GNUTLS_CFLAGS=""],[$GNUTLS_LIBS])])],
1356             [GNUTLS_CFLAGS=""])])
1357 fi
1358 WINE_NOTICE_WITH(gnutls,[test "x$ac_cv_lib_soname_gnutls" = "x"],
1359                  [libgnutls ${notice_platform}development files not found, no schannel support.])
1360
1361 dnl **** Check which curses lib to use ***
1362 CURSESLIBS=""
1363 if test "$ac_cv_header_ncurses_h" = "yes"
1364 then
1365     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
1366 elif test "$ac_cv_header_curses_h" = "yes"
1367 then
1368     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
1369 fi
1370 ac_save_LIBS="$LIBS"
1371 LIBS="$LIBS $CURSESLIBS"
1372 AC_CHECK_FUNCS(mousemask)
1373 LIBS="$ac_save_LIBS"
1374 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
1375                  [lib(n)curses ${notice_platform}development files not found, curses won't be supported.])
1376
1377 dnl **** Check for SANE ****
1378 if test "x$with_sane" != "xno"
1379 then
1380     WINE_PACKAGE_FLAGS(SANE,[libsane],,[`sane-config --cflags 2>/dev/null`],[`sane-config --ldflags 2>/dev/null`],
1381         [AC_CHECK_HEADER(sane/sane.h,
1382             [WINE_CHECK_SONAME(sane,sane_init,,[SANE_CFLAGS=""],[$SANE_LIBS])],
1383             [SANE_CFLAGS=""])])
1384 fi
1385 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
1386                  [libsane ${notice_platform}development files not found, scanners won't be supported.])
1387
1388 dnl **** Check for libv4l1 ****
1389 if test "x$with_v4l" != "xno"
1390 then
1391     WINE_CHECK_SONAME(v4l1,v4l1_open,,,)
1392 fi
1393 WINE_NOTICE_WITH(v4l,[test "x$ac_cv_lib_soname_v4l1" = "x"],
1394                  [libv4l ${notice_platform}development files not found.])
1395
1396 dnl **** Check for libgphoto2 ****
1397 if test "x$with_gphoto" != "xno"
1398 then
1399     WINE_PACKAGE_FLAGS(GPHOTO2,[libgphoto2],[-lgphoto2],
1400                        [`gphoto2-config --cflags 2>/dev/null`],[`gphoto2-config --libs 2>/dev/null`],
1401         [AC_CHECK_HEADER(gphoto2-camera.h,
1402                         [AC_CHECK_LIB(gphoto2,gp_camera_new,
1403                                       [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have the libgphoto2 development environment])],
1404                                       [GPHOTO2_LIBS=""; GPHOTO2_CFLAGS=""],
1405                                       [$GPHOTO2_LIBS])],
1406                         [GPHOTO2_LIBS=""; GPHOTO2_CFLAGS=""])])
1407     WINE_PACKAGE_FLAGS(GPHOTO2_PORT,[libgphoto2_port],[-lgphoto2_port],
1408                        [`gphoto2-port-config --cflags 2>/dev/null`],
1409                        [`gphoto2-port-config --libs 2>/dev/null`],
1410         [AC_CHECK_HEADER(gphoto2-port.h,
1411                         [AC_CHECK_LIB(gphoto2_port,gp_port_info_list_new,
1412                                       [AC_DEFINE(HAVE_GPHOTO2_PORT, 1, [Define if we have the libgphoto2_port development environment])],
1413                                       [GPHOTO2_PORT_LIBS=""; GPHOTO2_PORT_CFLAGS=""],
1414                                       [$GPHOTO2_PORT_LIBS])],
1415                         [GPHOTO2_PORT_LIBS=""; GPHOTO2_PORT_CFLAGS=""])])
1416 fi
1417 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
1418                  [libgphoto2 ${notice_platform}development files not found, digital cameras won't be supported.])
1419 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_port_gp_port_info_list_new" != "yes"],
1420                  [libgphoto2_port ${notice_platform}development files not found, digital cameras won't be auto-detected.])
1421
1422
1423 dnl **** Check for resolver library ***
1424 if test "$ac_cv_header_resolv_h" = "yes"
1425 then
1426     ac_save_LIBS="$LIBS"
1427     for lib in '' -lresolv
1428     do
1429       LIBS="$lib $ac_save_LIBS"
1430       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_NETINET_IN_H
1431 #include <netinet/in.h>
1432 #endif
1433 #include <resolv.h>]],[[res_query("foo",ns_c_in,0,0,0);]])],
1434         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
1435          AC_SUBST(RESOLVLIBS,"$lib")])
1436       if test "${RESOLVLIBS+set}" = set; then
1437         break
1438       fi
1439     done
1440     LIBS="$ac_save_LIBS"
1441 fi
1442
1443 dnl **** Check for LittleCMS ***
1444 if test "x$with_lcms2" != "xno"
1445 then
1446     WINE_PACKAGE_FLAGS(LCMS2,[lcms2],[-llcms2],,,
1447         [AC_CHECK_HEADERS([lcms2.h])
1448         if test "$ac_cv_header_lcms2_h" = "yes"
1449         then
1450             AC_CHECK_LIB(lcms2, cmsOpenProfileFromFile,
1451                 [AC_DEFINE(HAVE_LCMS2, 1, [Define if you have the LittleCMS development environment])],[LCMS2_LIBS=""])
1452         else
1453             LCMS2_CFLAGS=""
1454             LCMS2_LIBS=""
1455         fi])
1456 fi
1457 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms2_cmsOpenProfileFromFile" != "yes"],
1458                  [liblcms2 ${notice_platform}development files not found, Color Management won't be supported.])
1459
1460 dnl **** Check for FreeType 2 ****
1461 if test "x$with_freetype" != "xno"
1462 then
1463     WINE_PACKAGE_FLAGS(FREETYPE,[freetype2],[-lfreetype],
1464                        [`(freetype-config --cflags || freetype2-config --cflags) 2>/dev/null`],
1465                        [`(freetype-config --libs || freetype2-config --libs) 2>/dev/null`],
1466         [AC_CHECK_HEADERS([ft2build.h])
1467         if test "$ac_cv_header_ft2build_h" = "yes"
1468         then
1469             WINE_CHECK_SONAME(freetype,FT_Init_FreeType,
1470                 [AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
1471                  AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <ft2build.h>
1472 #include FT_MODULE_H])],
1473                 [FREETYPE_LIBS=""],[$FREETYPE_LIBS])
1474         else
1475             FREETYPE_CFLAGS=""
1476             FREETYPE_LIBS=""
1477         fi])
1478 fi
1479 WINE_ERROR_WITH(freetype,[test "x$ac_cv_lib_soname_freetype" = x],
1480                 [FreeType ${notice_platform}development files not found. Fonts will not be built.])
1481 test "x$ac_cv_lib_soname_freetype" = x && enable_fonts=${enable_fonts:-no}
1482
1483 dnl **** Check for parport (currently Linux only) ****
1484 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1485  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_SYS_IOCTL_H
1486 # include <sys/ioctl.h>
1487 #endif
1488 #include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1489     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1490 if test "$ac_cv_c_ppdev" = "yes"
1491 then
1492     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1493 fi
1494
1495 dnl **** Check for pthread functions ****
1496 WINE_CHECK_LIB_FUNCS(\
1497         pthread_attr_get_np \
1498         pthread_getattr_np \
1499         pthread_getthreadid_np \
1500         pthread_get_stackaddr_np \
1501         pthread_get_stacksize_np,
1502         [$LIBPTHREAD])
1503
1504 dnl **** Check for zlib ****
1505 if test "$ac_cv_header_zlib_h" = "yes"
1506 then
1507     AC_CHECK_LIB(z,inflate,[AC_DEFINE(HAVE_ZLIB,1,[Define to 1 if you have the `z' library (-lz).])
1508                             AC_SUBST(ZLIB,"-lz")])
1509 fi
1510 WINE_NOTICE_WITH(zlib,[test "x$ZLIB" = "x"],[libz ${notice_platform}development files not found, data compression won't be supported.])
1511
1512 dnl **** Check for gettextpo ****
1513 if test "x$enable_tools" != xno
1514 then
1515     if test "$ac_cv_header_gettext_po_h" = "yes"
1516     then
1517         AC_CHECK_LIB(gettextpo,po_message_msgctxt,
1518                      [AC_DEFINE(HAVE_LIBGETTEXTPO,1,[Define to 1 if you have the `gettextpo' library (-lgettextpo).])
1519                       AC_SUBST(LIBGETTEXTPO,"-lgettextpo")])
1520     fi
1521     test "x$with_gettextpo" != xyes || WINE_NOTICE_WITH(gettextpo,[test "x$LIBGETTEXTPO" = "x"],
1522           [GetText ${notice_platform}development files not found (or too old), po files can't be rebuilt.])
1523 fi
1524
1525 dnl **** Check for gstreamer ****
1526 if test "x$with_gstreamer" != "xno"
1527 then
1528     WINE_PACKAGE_FLAGS(GSTREAMER,[gstreamer-app-0.10],,,,
1529         [ac_gst_incl=""
1530         for i in $GSTREAMER_CFLAGS
1531         do
1532             case "$i" in
1533                 -I*) ac_gst_incl="$ac_gst_incl $i";;
1534             esac
1535         done
1536         GSTREAMER_CFLAGS=$ac_gst_incl
1537         CPPFLAGS="$ac_save_CPPFLAGS $GSTREAMER_CFLAGS"
1538         AC_CHECK_HEADER([gst/gstpad.h],
1539             [AC_CHECK_HEADER([gst/app/gstappsink.h],
1540                  [AC_MSG_CHECKING([whether gint64 defined by gst/app/gstappsink.h is indeed 64-bit])
1541                   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gst/app/gstappsink.h>]],
1542                                                      [[static int a[sizeof(gint64) > 4 ? 1 : -1]; if (a[0]) return 0;]])],
1543                     [AC_MSG_RESULT([yes])
1544                      AC_CHECK_LIB(gstreamer-0.10,gst_pad_get_caps_reffed,
1545                        [AC_CHECK_LIB(gstapp-0.10,gst_app_buffer_new,[:],,[$GSTREAMER_LIBS])])],
1546                     [AC_MSG_RESULT([no])])])],
1547             [GSTREAMER_CFLAGS=""])])
1548 fi
1549 WINE_NOTICE_WITH(gstreamer,[test "x$ac_cv_lib_gstapp_0_10_gst_app_buffer_new" != xyes -a "x$ac_cv_header_QuickTime_ImageCompression_h" != xyes],
1550                  [gstreamer-0.10 base plugins ${notice_platform}development files not found, gstreamer support disabled])
1551 test "x$ac_cv_lib_gstapp_0_10_gst_app_buffer_new" = xyes || enable_winegstreamer=${enable_winegstreamer:-no}
1552
1553 dnl **** Check for ALSA 1.x ****
1554 AC_SUBST(ALSALIBS,"")
1555 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1556 then
1557     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access_mask,
1558         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1559 #include <alsa/asoundlib.h>
1560 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1561 #include <sys/asoundlib.h>
1562 #endif]], [[snd_pcm_hw_params_get_access_mask(NULL, NULL)]])],
1563                         [ALSALIBS="-lasound"])])
1564 fi
1565
1566 dnl **** Check for OSSv4 ****
1567 if test "x$with_oss" != xno
1568 then
1569     ac_save_CPPFLAGS="$CPPFLAGS"
1570     if test -f /etc/oss.conf
1571     then
1572         . /etc/oss.conf
1573     fi
1574     ac_oss_incl="-I${OSSLIBDIR:-/usr/lib/oss}/include"
1575     CPPFLAGS="$CPPFLAGS $ac_oss_incl"
1576     AC_CHECK_HEADER([sys/soundcard.h],
1577         [AC_CHECK_MEMBERS([oss_sysinfo.numaudioengines],
1578                           [AC_SUBST(OSS4INCL,"$ac_oss_incl")],,
1579                           [#include <sys/soundcard.h>])])
1580     CPPFLAGS="$ac_save_CPPFLAGS"
1581     if test "x$ac_cv_member_oss_sysinfo_numaudioengines" != xyes
1582     then
1583         WINE_NOTICE([OSS sound system found but too old (OSSv4 needed), OSS won't be supported.])
1584     fi
1585 fi
1586
1587 dnl **** Check for capi4linux ****
1588 if test "x$with_capi" != "xno"
1589 then
1590     WINE_PACKAGE_FLAGS(CAPI20,[capi20],,,,
1591      dnl Check for broken kernel header that doesn't define __user
1592     [AC_CHECK_HEADERS([capi20.h linux/capi.h],,,[#define __user])
1593     if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1594     then
1595         WINE_CHECK_SONAME(capi20,capi20_register,,,[$CAPI20_LIBS])
1596     fi])
1597 fi
1598 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1599                  [libcapi20 ${notice_platform}development files not found, ISDN won't be supported.])
1600
1601 dnl **** Check for cups ****
1602 AC_SUBST(CUPSINCL,"")
1603 if test "x$with_cups" != "xno"
1604 then
1605     ac_save_CPPFLAGS="$CPPFLAGS"
1606     ac_cups_cflags=`cups-config --cflags 2>/dev/null`
1607     ac_cups_libs=`cups-config --ldflags 2>/dev/null`
1608     CPPFLAGS="$CPPFLAGS $ac_cups_cflags"
1609     AC_CHECK_HEADERS(cups/cups.h,
1610             [WINE_CHECK_SONAME(cups,cupsGetDefault,
1611                        [CUPSINCL="$ac_cups_cflags"],,
1612                        [$ac_cups_libs])])
1613     CPPFLAGS="$ac_save_CPPFLAGS"
1614 fi
1615 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1616                  [libcups ${notice_platform}development files not found, CUPS won't be supported.])
1617
1618 dnl **** Check for fontconfig ****
1619 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1620 then
1621     WINE_CHECK_SONAME(fontconfig,FcInit)
1622 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1623 then
1624     dnl fontconfig is in the X directory on Mac OS X
1625     ac_save_CPPFLAGS="$CPPFLAGS"
1626     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1627     $as_unset ac_cv_header_fontconfig_fontconfig_h
1628     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1629     CPPFLAGS="$ac_save_CPPFLAGS"
1630     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1631     then
1632         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1633         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1634     fi
1635 fi
1636 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1637                  [fontconfig ${notice_platform}development files not found, fontconfig won't be supported.])
1638
1639 dnl **** Check for gsm codec ****
1640 if test "$ac_cv_header_gsm_h" = "yes" -o "$ac_cv_header_gsm_gsm_h" = "yes"
1641 then
1642     WINE_CHECK_SONAME(gsm,gsm_create)
1643 fi
1644 WINE_NOTICE_WITH(gsm,[test "x$ac_cv_lib_soname_gsm" = "x"],
1645                  [libgsm ${notice_platform}development files not found, gsm 06.10 codec won't be supported.])
1646
1647 dnl **** Check for libjpeg ****
1648 if test "x$with_jpeg" != "xno"
1649 then
1650     WINE_PACKAGE_FLAGS(JPEG,[libjpeg],,,,
1651         [AC_CHECK_HEADERS([jpeglib.h])
1652         if test "$ac_cv_header_jpeglib_h" = "yes"
1653         then
1654             WINE_CHECK_SONAME(jpeg,jpeg_start_decompress,,[JPEG_CFLAGS=""],[$JPEG_LIBS])
1655         else
1656             JPEG_CFLAGS=""
1657         fi])
1658 fi
1659 WINE_WARNING_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1660                  [libjpeg ${notice_platform}development files not found, JPEG won't be supported.])
1661
1662 dnl **** Check for libpng ****
1663 if test "x$with_png" != "xno"
1664 then
1665     WINE_PACKAGE_FLAGS(PNG,[libpng],,[$X_CFLAGS],[$X_LIBS],
1666         [AC_CHECK_HEADERS([png.h])
1667         if test "$ac_cv_header_png_h" = "yes"
1668         then
1669             WINE_CHECK_SONAME(png,png_create_read_struct,
1670                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <png.h>]],[[typeof(png_set_expand_gray_1_2_4_to_8) *p]])],
1671                     [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1,[Define to 1 if libpng has the png_set_expand_gray_1_2_4_to_8 function.])])],
1672                 [PNG_CFLAGS=""],[$PNG_LIBS -lm -lz],[[libpng[[0-9]]*]])
1673         else
1674             PNG_CFLAGS=""
1675         fi])
1676 fi
1677 WINE_WARNING_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1678                  [libpng ${notice_platform}development files not found, PNG won't be supported.])
1679
1680 dnl **** Check for libtiff ****
1681 if test "x$with_tiff" != "xno"
1682 then
1683     WINE_PACKAGE_FLAGS(TIFF,[libtiff],,,,
1684         [AC_CHECK_HEADERS([tiffio.h])
1685         if test "$ac_cv_header_tiffio_h" = "yes"
1686         then
1687             WINE_CHECK_SONAME(tiff,TIFFClientOpen,,,[$TIFF_LIBS])
1688         fi])
1689 fi
1690 WINE_NOTICE_WITH(tiff,[test "x$ac_cv_lib_soname_tiff" = "x"],
1691                  [libtiff ${notice_platform}development files not found, TIFF won't be supported.])
1692
1693 dnl **** Check for mpg123 ****
1694 if test "x$with_mpg123" != "xno"
1695 then
1696     WINE_PACKAGE_FLAGS(MPG123,[libmpg123],[-lmpg123],,,
1697         [AC_CHECK_HEADERS([mpg123.h])
1698         if test "$ac_cv_header_mpg123_h" = "yes"
1699         then
1700             AC_CHECK_LIB(mpg123,mpg123_feed,[:],[MPG123_LIBS=""],[$MPG123_LIBS])
1701         else
1702             MPG123_CFLAGS=""
1703             MPG123_LIBS=""
1704         fi])
1705 fi
1706 WINE_NOTICE_WITH(mpg123,[test "x$ac_cv_lib_mpg123_mpg123_feed" != xyes -a x"$ac_cv_header_CoreAudio_CoreAudio_h" != xyes],
1707                  [libmpg123 ${notice_platform}development files not found (or too old), mp3 codec won't be supported.])
1708 test "x$ac_cv_lib_mpg123_mpg123_feed" = xyes -o "x$ac_cv_header_AudioToolbox_AudioConverter_h" = xyes || enable_winemp3_acm=${enable_winemp3_acm:-no}
1709
1710 dnl **** Check for OpenAL 1.1 ****
1711 if test "$ac_cv_header_AL_al_h" = "yes"
1712 then
1713     WINE_CHECK_SONAME(openal,alGetSource3i,[AC_SUBST(LIBOPENAL,"-lopenal")
1714                       ac_cv_lib_openal=yes
1715                       AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])],,)
1716 fi
1717 WINE_NOTICE_WITH(openal,[test "x$ac_cv_lib_openal" != xyes],
1718                  [libopenal ${notice_platform}development files not found (or too old), OpenAL won't be supported.])
1719 test "x$ac_cv_lib_openal" = xyes || enable_openal32=${enable_openal32:-no}
1720
1721 dnl **** Check for libkstat ****
1722 if test "$ac_cv_header_kstat_h" = "yes"
1723 then
1724     AC_CHECK_LIB(kstat,kstat_open,
1725                  [AC_DEFINE(HAVE_LIBKSTAT, 1, [Define to 1 if you have the `kstat' library (-lkstat).])
1726                   AC_SUBST(LIBKSTAT,"-lkstat")])
1727 fi
1728
1729 dnl **** Check for libprocstat ****
1730 if test "$ac_cv_header_libprocstat_h" = "yes"
1731 then
1732     AC_CHECK_LIB(procstat,procstat_open_sysctl,
1733                  [AC_DEFINE(HAVE_LIBPROCSTAT, 1, [Define to 1 if you have the `procstat' library (-lprocstat).])
1734                   AC_SUBST(LIBPROCSTAT,"-lprocstat")])
1735 fi
1736
1737 dnl **** Check for libodbc ****
1738 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1739
1740 dnl **** Check for libnetapi ****
1741 if test "x$with_netapi" != "xno"
1742 then
1743     WINE_CHECK_SONAME(netapi,libnetapi_init,,[AC_DEFINE_UNQUOTED(SONAME_LIBNETAPI,["libnetapi.$LIBEXT"])])
1744 fi
1745
1746 dnl **** Disable unsupported winmm drivers ****
1747 test -n "$ALSALIBS" || enable_winealsa_drv=${enable_winealsa_drv:-no}
1748 test -n "$COREAUDIO" || enable_winecoreaudio_drv=${enable_winecoreaudio_drv:-no}
1749 test "x$ac_cv_member_oss_sysinfo_numaudioengines" = xyes || enable_wineoss_drv=${enable_wineoss_drv:-no}
1750 test "$ac_cv_header_linux_joystick_h" = "yes" || enable_winejoystick_drv=${enable_winejoystick_drv:-no}
1751
1752 dnl **** Check for any sound system ****
1753 if test "x$ALSALIBS$COREAUDIO" = "x" -a \
1754         "x$ac_cv_member_oss_sysinfo_numaudioengines" != xyes -a \
1755         "x$with_alsa$with_coreaudio$with_oss" != xnonono
1756 then
1757     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1758 fi
1759
1760 dnl **** Check for gcc specific options ****
1761
1762 AC_SUBST(EXTRACFLAGS,"")
1763 if test "x${GCC}" = "xyes"
1764 then
1765   EXTRACFLAGS="-Wall -pipe"
1766
1767   dnl Check for strength-reduce bug
1768   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1769                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1770 [[static int Array[[3]];
1771   unsigned int B = 3;
1772   int i;
1773   for(i=0; i<B; i++) Array[[i]] = i - 3;
1774   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1775   L[[i]] = 4;
1776   return (Array[[1]] != -2 || L[[2]] != 3)]])],
1777     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1778   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1779   then
1780     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1781   fi
1782
1783   dnl Check for some compiler flags
1784   WINE_TRY_CFLAGS([-fno-builtin],[AC_SUBST(BUILTINFLAG,"-fno-builtin")])
1785   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1786   dnl clang needs to be told to fail on unknown options
1787   saved_CFLAGS=$CFLAGS
1788   WINE_TRY_CFLAGS([-Werror=unknown-warning-option],[CFLAGS="$CFLAGS -Werror=unknown-warning-option"])
1789   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1790   WINE_TRY_CFLAGS([-Wempty-body])
1791   WINE_TRY_CFLAGS([-Wignored-qualifiers])
1792   WINE_TRY_CFLAGS([-Wstrict-prototypes])
1793   WINE_TRY_CFLAGS([-Wtype-limits])
1794   WINE_TRY_CFLAGS([-Wunused-but-set-parameter])
1795   WINE_TRY_CFLAGS([-Wwrite-strings])
1796
1797   dnl Check for noisy string.h
1798   WINE_TRY_CFLAGS([-Wpointer-arith],
1799      [saved_string_h_CFLAGS=$CFLAGS
1800       CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1801       AC_CACHE_CHECK([for broken string.h that generates warnings with -Wpointer-arith], ac_cv_c_string_h_warnings,
1802           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1803       test "$ac_cv_c_string_h_warnings" = yes || EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1804       CFLAGS=$saved_string_h_CFLAGS])
1805
1806   dnl Check for noisy string.h on logical ops
1807   WINE_TRY_CFLAGS([-Wlogical-op],
1808      [saved_string_h_CFLAGS=$CFLAGS
1809       CFLAGS="$CFLAGS -Wlogical-op -Werror"
1810       AC_CACHE_CHECK([for broken string.h that generates warnings with -Wlogical-op], ac_cv_c_logicalop_noisy,
1811           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>
1812 char*f(const char *h,char n) {return strchr(h,n);}]])],[ac_cv_c_logicalop_noisy=no],[ac_cv_c_logicalop_noisy=yes]))
1813       CFLAGS=$saved_string_h_CFLAGS
1814       test "$ac_cv_c_logicalop_noisy" = yes || EXTRACFLAGS="$EXTRACFLAGS -Wlogical-op"])
1815
1816   CFLAGS=$saved_CFLAGS
1817
1818   dnl On Darwin, prefer stabs; everywhere else, default to dwarf-2 debug info
1819   for ac_flag in $CFLAGS; do
1820     case $ac_flag in
1821       -g) case $host_os in
1822             darwin*) WINE_TRY_CFLAGS([-gstabs+]) ;;
1823             *) WINE_TRY_CFLAGS([-gdwarf-2])
1824                WINE_TRY_CFLAGS([-gstrict-dwarf]) ;;
1825           esac ;;
1826     esac
1827   done
1828
1829   dnl gcc-4.6+ omits frame pointers by default, breaking some copy protections
1830   case $host_cpu in
1831     *i[[3456789]]86*) WINE_TRY_CFLAGS([-fno-omit-frame-pointer]) ;;
1832   esac
1833
1834   dnl mingw uses Windows 64-bit types, not Unix ones
1835   case $host in
1836     x86_64-*mingw32*|x86_64-*cygwin*) WINE_TRY_CFLAGS([-Wno-format]) ;;
1837   esac
1838
1839   dnl Enable -Werror for maintainer mode
1840   if test "x$enable_maintainer_mode" = "xyes"
1841   then
1842       WINE_TRY_CFLAGS([-Werror])
1843   fi
1844
1845   dnl Check for ms_hook_prologue support
1846   saved_CFLAGS="$CFLAGS"
1847   CFLAGS="$CFLAGS -Werror"
1848   AC_CACHE_CHECK([for ms_hook_prologue attribute], ac_cv_have_ms_hook_prologue,
1849                  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[int __attribute__((__ms_hook_prologue__)) test(void) { return 0; }]])],
1850                                    [ac_cv_have_ms_hook_prologue="yes"],[ac_cv_have_ms_hook_prologue="no"]))
1851   CFLAGS="$saved_CFLAGS"
1852   if test "$ac_cv_have_ms_hook_prologue" = "yes"
1853   then
1854       AC_DEFINE(DECLSPEC_HOTPATCH, [__attribute__((__ms_hook_prologue__))],
1855                 [Define to a function attribute for Microsoft hotpatch assembly prefix.])
1856   else
1857       AC_DEFINE(DECLSPEC_HOTPATCH, [/* */])
1858   fi
1859 fi
1860
1861 dnl **** Disable Fortify, it has too many false positives
1862
1863 AC_CACHE_CHECK([for the need to disable Fortify], ac_cv_c_fortify_enabled,
1864     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]],
1865 [[#if defined(__USE_FORTIFY_LEVEL) && __USE_FORTIFY_LEVEL > 0
1866 #error Fortify enabled
1867 #endif]])],
1868         [ac_cv_c_fortify_enabled=no],[ac_cv_c_fortify_enabled=yes]))
1869 if test "$ac_cv_c_fortify_enabled" = yes
1870 then
1871     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=0"
1872 fi
1873
1874 dnl **** Check for underscore on external symbols ****
1875
1876 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1877     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1878                       [extern int ac_test;],
1879                       [if (ac_test) return 1],
1880                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1881
1882 case $host_cpu in
1883   *i[[3456789]]86*)
1884     AC_CACHE_CHECK([whether external symbols need stdcall decoration], ac_cv_c_stdcall_suffix,
1885         WINE_TRY_ASM_LINK(["jmp _ac_test@4"],
1886 [#ifndef _MSC_VER
1887 #define __stdcall __attribute__((__stdcall__))
1888 #endif
1889 int __stdcall ac_test(int i) { return i; }],
1890                           [if (ac_test(1)) return 1],
1891                           ac_cv_c_stdcall_suffix="yes",ac_cv_c_stdcall_suffix="no")) ;;
1892   *) ac_cv_c_stdcall_suffix="no" ;;
1893 esac
1894
1895 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1896 if test "$ac_cv_c_extern_prefix" = "yes"
1897 then
1898     AC_DEFINE([__ASM_NAME(name)], ["_" name])
1899     asm_name_prefix="_"
1900 else
1901     AC_DEFINE([__ASM_NAME(name)], [name])
1902     asm_name_prefix=""
1903 fi
1904
1905 AH_TEMPLATE(__ASM_STDCALL,[Define to a macro to generate an stdcall suffix])
1906 if test "$ac_cv_c_stdcall_suffix" = "yes"
1907 then
1908     AC_DEFINE([__ASM_STDCALL(args)],["@" #args])
1909 else
1910     AC_DEFINE([__ASM_STDCALL(args)],[""])
1911 fi
1912
1913 dnl **** Check how to define a function in assembly code ****
1914
1915 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1916   WINE_TRY_ASM_LINK(
1917       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1918       ac_cv_asm_func_def=".def",
1919     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1920       ac_cv_asm_func_def=".type @function",
1921     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1922       ac_cv_asm_func_def=".type 2",
1923       ac_cv_asm_func_def="unknown")])]))
1924
1925 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1926 case "$ac_cv_asm_func_def" in
1927   ".def")
1928      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"])
1929      asm_func_header=".def $asm_name_prefix\" #name suffix \"; .scl 2; .type 32; .endef" ;;
1930   ".type @function")
1931      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"])
1932      asm_func_header=".type $asm_name_prefix\" #name suffix \",@function" ;;
1933   ".type 2")
1934      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"])
1935      asm_func_header=".type $asm_name_prefix\" #name suffix \",2" ;;
1936   *)
1937      AC_DEFINE([__ASM_FUNC(name)], [""])
1938      asm_func_header="" ;;
1939 esac
1940
1941 AC_CACHE_CHECK([whether asm() works outside of functions], ac_cv_c_asm_outside_funcs,
1942     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\n\t.long 0");]],)],
1943                       ac_cv_c_asm_outside_funcs="yes",ac_cv_c_asm_outside_funcs="no"))
1944
1945 AC_CACHE_CHECK([whether .previous is supported in assembly code], ac_cv_c_dot_previous,
1946     WINE_TRY_ASM_LINK([".text\nac_test:\t.long 0\n\t.previous"],,,
1947                       ac_cv_c_dot_previous="yes",ac_cv_c_dot_previous="no"))
1948
1949 AC_CACHE_CHECK([whether CFI directives are supported in assembly code], ac_cv_c_cfi_support,
1950     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\nac_test:\t.cfi_startproc\n\t.long 0\n\t.cfi_endproc");]])],
1951                       ac_cv_c_cfi_support="yes",ac_cv_c_cfi_support="no"))
1952
1953 asm_func_header=".globl $asm_name_prefix\" #name suffix \"\\n\\t$asm_func_header\\n$asm_name_prefix\" #name suffix \":\\n\\t"
1954 asm_func_trailer=""
1955 if test "$ac_cv_c_dot_previous" = "yes"
1956 then
1957    asm_func_trailer="\\n\\t.previous"
1958 fi
1959 if test "$ac_cv_c_cfi_support" = "yes"
1960 then
1961    asm_func_header="$asm_func_header.cfi_startproc\\n\\t"
1962    asm_func_trailer="\\n\\t.cfi_endproc$asm_func_trailer"
1963    AC_DEFINE([__ASM_CFI(str)],[str],[Define to a macro to output a .cfi assembly pseudo-op])
1964    AC_SUBST([UNWINDFLAGS],[-fasynchronous-unwind-tables])
1965 else
1966    AC_DEFINE([__ASM_CFI(str)],[""])
1967 fi
1968
1969 asm_func_code="$asm_func_header\" code \"$asm_func_trailer"
1970
1971 AH_TEMPLATE(__ASM_DEFINE_FUNC,[Define to a macro to define an assembly function])
1972 if test "$ac_cv_c_asm_outside_funcs" = "yes"
1973 then
1974     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[asm(".text\n\t.align 4\n\t$asm_func_code");])
1975 else
1976     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[void __asm_dummy_##name(void) { asm(".text\n\t.align 4\n\t$asm_func_code"); }])
1977 fi
1978 AC_DEFINE([__ASM_GLOBAL_FUNC(name,code)],[__ASM_DEFINE_FUNC(name,"",code)],
1979           [Define to a macro to generate an assembly function with C calling convention])
1980 AC_DEFINE([__ASM_STDCALL_FUNC(name,args,code)],[__ASM_DEFINE_FUNC(name,__ASM_STDCALL(args),code)],
1981           [Define to a macro to generate an assembly function with stdcall calling convention])
1982
1983 dnl **** Platform-specific checks ****
1984
1985 case $build_os in
1986   cygwin*|mingw32*) AC_SUBST(TOOLSEXT,".exe") ;;
1987 esac
1988
1989 case $host_os in
1990   linux*)
1991     case $host_cpu in
1992       *i[[3456789]]86*|x86_64*)
1993         AS_VAR_APPEND([LOADER_RULES],["
1994 all: $wine_binary-preloader
1995
1996 $wine_binary-preloader: preloader.o
1997         \$(CC) -o \$@ -static -nostartfiles -nodefaultlibs -Wl,-Ttext=0x7c400000 preloader.o \$(LIBPORT) \$(LDFLAGS)
1998
1999 install install-lib:: $wine_binary-preloader \$(DESTDIR)\$(bindir)
2000         \$(INSTALL_PROGRAM) $wine_binary-preloader \$(DESTDIR)\$(bindir)/$wine_binary-preloader
2001
2002 uninstall::
2003         \$(RM) \$(DESTDIR)\$(bindir)/$wine_binary-preloader
2004 "]) ;;
2005     esac
2006     ;;
2007 esac
2008
2009 dnl **** Check for functions ****
2010
2011 ac_save_CFLAGS="$CFLAGS"
2012 CFLAGS="$CFLAGS $BUILTINFLAG"
2013 AC_CHECK_FUNCS(\
2014         __res_get_state \
2015         __res_getservers \
2016         _finite \
2017         _isnan \
2018         _pclose \
2019         _popen \
2020         _snprintf \
2021         _spawnvp \
2022         _strdup \
2023         _stricmp \
2024         _strnicmp \
2025         _strtoi64 \
2026         _strtoui64 \
2027         _vsnprintf \
2028         asctime_r \
2029         chsize \
2030         dlopen \
2031         epoll_create \
2032         ffs \
2033         fnmatch \
2034         fork \
2035         fpclass \
2036         fstatfs \
2037         fstatvfs \
2038         ftruncate \
2039         futimens \
2040         futimes \
2041         futimesat \
2042         getattrlist \
2043         getdirentries \
2044         getopt_long_only \
2045         getpwuid \
2046         gettimeofday \
2047         getuid \
2048         if_nameindex \
2049         kqueue \
2050         lstat \
2051         memmove \
2052         mmap \
2053         pclose \
2054         pipe2 \
2055         poll \
2056         popen \
2057         port_create \
2058         prctl \
2059         pread \
2060         proc_pidinfo \
2061         pwrite \
2062         readdir \
2063         readlink \
2064         sched_yield \
2065         select \
2066         setproctitle \
2067         setrlimit \
2068         settimeofday \
2069         sigaltstack \
2070         sigprocmask \
2071         snprintf \
2072         statfs \
2073         statvfs \
2074         strcasecmp \
2075         strdup \
2076         strerror \
2077         strncasecmp \
2078         strtold \
2079         strtoll \
2080         strtoull \
2081         symlink \
2082         tcdrain \
2083         thr_kill2 \
2084         timegm \
2085         usleep \
2086         vsnprintf
2087 )
2088 CFLAGS="$ac_save_CFLAGS"
2089
2090 dnl Check for -ldl
2091 if test "$ac_cv_func_dlopen" = no
2092 then
2093     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
2094 fi
2095 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
2096
2097 dnl Check for -lpoll for Mac OS X/Darwin
2098 if test "$ac_cv_func_poll" = no
2099 then
2100     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
2101 fi
2102
2103 dnl Check for -lnsl for Solaris
2104 AC_SEARCH_LIBS(gethostbyname, nsl)
2105
2106 dnl Check for -lsocket for Solaris
2107 AC_SEARCH_LIBS(connect, socket)
2108
2109 dnl Check for -lresolv for Solaris
2110 AC_SEARCH_LIBS(inet_aton, resolv)
2111
2112 dnl **** Check for functions which may rely on -lsocket on Solaris.
2113 AC_CHECK_FUNCS(\
2114         getaddrinfo \
2115         getnameinfo \
2116         getnetbyname \
2117         getprotobyname \
2118         getprotobynumber \
2119         getservbyport \
2120         inet_addr \
2121         inet_network \
2122         inet_ntop \
2123         inet_pton \
2124         sendmsg \
2125         socketpair \
2126 )
2127
2128 dnl Check for clock_gettime which may be in -lrt
2129 ac_save_LIBS=$LIBS
2130 AC_SEARCH_LIBS(clock_gettime, rt,
2131                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define to 1 if you have the `clock_gettime' function.])
2132                 test "$ac_res" = "none required" || AC_SUBST(LIBRT,"$ac_res")])
2133 LIBS=$ac_save_LIBS
2134
2135 dnl **** Check for OpenLDAP ***
2136 AC_SUBST(LDAPLIBS,"")
2137 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
2138 then
2139     AC_CHECK_TYPE(LDAPSortKey,
2140         [AC_CHECK_LIB(ldap_r, ldap_initialize,
2141             [AC_CHECK_LIB(lber, ber_init,
2142                 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
2143                  LDAPLIBS="-lldap_r -llber"],,
2144                  [$LIBPTHREAD])],,
2145                  [$LIBPTHREAD])],,
2146         [#include <ldap.h>])
2147     WINE_CHECK_LIB_FUNCS(\
2148         ldap_count_references \
2149         ldap_first_reference \
2150         ldap_next_reference \
2151         ldap_parse_reference \
2152         ldap_parse_sort_control \
2153         ldap_parse_sortresponse_control \
2154         ldap_parse_vlv_control \
2155         ldap_parse_vlvresponse_control,
2156         [$LDAPLIBS $LIBPTHREAD])
2157 fi
2158 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
2159                  [libldap (OpenLDAP) ${notice_platform}development files not found, LDAP won't be supported.])
2160
2161 AC_CACHE_CHECK([whether mkdir takes only one argument],
2162         wine_cv_one_arg_mkdir,
2163         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/stat.h>]],[[mkdir("foo");]])],
2164                           [wine_cv_one_arg_mkdir=yes],[wine_cv_one_arg_mkdir=no]))
2165 if test "$wine_cv_one_arg_mkdir" = "yes"
2166 then
2167   AC_DEFINE(HAVE_ONE_ARG_MKDIR, 1, [Define if mkdir takes only one argument])
2168 fi
2169
2170 AC_CACHE_CHECK([for sched_setaffinity],wine_cv_have_sched_setaffinity,
2171                 AC_LINK_IFELSE([AC_LANG_PROGRAM(
2172 [[#define _GNU_SOURCE
2173 #include <sched.h>]], [[sched_setaffinity(0, 0, 0);]])],[wine_cv_have_sched_setaffinity=yes],[wine_cv_have_sched_setaffinity=no]))
2174 if test "$wine_cv_have_sched_setaffinity" = "yes"
2175 then
2176   AC_DEFINE(HAVE_SCHED_SETAFFINITY, 1, [Define to 1 if you have the `sched_setaffinity' function.])
2177 fi
2178
2179 AC_CACHE_CHECK([for fallocate],wine_cv_have_fallocate,
2180                 AC_LINK_IFELSE([AC_LANG_PROGRAM(
2181 [[#define _GNU_SOURCE
2182 #include <fcntl.h>]], [[fallocate(-1, 0, 0, 0);]])],[wine_cv_have_fallocate=yes],[wine_cv_have_fallocate=no]))
2183 if test "$wine_cv_have_fallocate" = "yes"
2184 then
2185   AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the `fallocate' function.])
2186 fi
2187
2188 dnl **** Check for types ****
2189
2190 AC_C_INLINE
2191 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
2192 AC_CHECK_TYPES([sigset_t],,,[#include <sys/types.h>
2193 #include <signal.h>])
2194 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
2195
2196 AC_CHECK_TYPES([struct xinpgen],,,
2197 [#include <sys/types.h>
2198 #ifdef HAVE_SYS_SOCKET_H
2199 #include <sys/socket.h>
2200 #endif
2201 #ifdef HAVE_SYS_SOCKETVAR_H
2202 #include <sys/socketvar.h>
2203 #endif
2204 #ifdef HAVE_NET_ROUTE_H
2205 #include <net/route.h>
2206 #endif
2207 #ifdef HAVE_NETINET_IN_H
2208 #include <netinet/in.h>
2209 #endif
2210 #ifdef HAVE_NETINET_IN_SYSTM_H
2211 #include <netinet/in_systm.h>
2212 #endif
2213 #ifdef HAVE_NETINET_IP_H
2214 #include <netinet/ip.h>
2215 #endif
2216 #ifdef HAVE_NETINET_IN_PCB_H
2217 #include <netinet/in_pcb.h>
2218 #endif])
2219
2220 AC_CHECK_TYPES([struct r_debug, struct link_map],,,
2221 [#ifdef HAVE_LINK_H
2222 #include <link.h>
2223 #endif
2224 #ifdef HAVE_SYS_LINK_H
2225 #include <sys/link.h>
2226 #endif])
2227
2228 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
2229 [#ifdef HAVE_LINUX_INPUT_H
2230 #include <linux/input.h>
2231 #endif])
2232
2233 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
2234                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
2235 if test "$wine_cv_have_sigaddset" = "yes"
2236 then
2237   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
2238 fi
2239
2240
2241 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
2242         wine_cv_linux_gethostbyname_r_6,
2243         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
2244     char *name=0;
2245     struct hostent he;
2246     struct hostent *result;
2247     char *buf=0;
2248     int bufsize=0;
2249     int errnr;
2250     char *addr=0;
2251     int addrlen=0;
2252     int addrtype=0;
2253     gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
2254     gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
2255     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
2256         ])
2257    )
2258    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
2259    then
2260       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
2261                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
2262    fi
2263
2264 if test "$ac_cv_header_linux_joystick_h" = "yes"
2265 then
2266    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
2267         wine_cv_linux_joystick_22_api,
2268         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2269         #include <sys/ioctl.h>
2270         #include <sys/types.h>
2271         #include <linux/joystick.h>
2272
2273         struct js_event blub;
2274         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
2275         #error "no 2.2 header"
2276         #endif
2277         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
2278    )
2279    if test "$wine_cv_linux_joystick_22_api" = "yes"
2280    then
2281       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
2282                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
2283    fi
2284 fi
2285
2286 dnl **** FIXME: what about mixed cases, where we need two of them? ***
2287
2288 dnl Check for statfs members
2289 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
2290 [#include <sys/types.h>
2291 #ifdef HAVE_SYS_PARAM_H
2292 # include <sys/param.h>
2293 #endif
2294 #ifdef HAVE_SYS_MOUNT_H
2295 # include <sys/mount.h>
2296 #endif
2297 #ifdef HAVE_SYS_VFS_H
2298 # include <sys/vfs.h>
2299 #endif
2300 #ifdef HAVE_SYS_STATFS_H
2301 # include <sys/statfs.h>
2302 #endif])
2303
2304 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
2305 [#ifdef HAVE_SYS_STATVFS_H
2306 #include <sys/statvfs.h>
2307 #endif])
2308
2309 dnl Check for dirent.d_reclen
2310 AC_CHECK_MEMBERS([struct dirent.d_reclen],,,
2311 [#ifdef HAVE_DIRENT_H
2312 #include <dirent.h>
2313 #endif])
2314
2315 dnl Check for socket structure members
2316 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
2317 [#include <sys/types.h>
2318 #ifdef HAVE_SYS_SOCKET_H
2319 # include <sys/socket.h>
2320 #endif
2321 #ifdef HAVE_SYS_UN_H
2322 # include <sys/un.h>
2323 #endif])
2324
2325 dnl Check for scsireq_t and sg_io_hdr_t members
2326 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
2327 [#include <sys/types.h>
2328 #ifdef HAVE_SCSI_SG_H
2329 #include <scsi/sg.h>
2330 #endif])
2331
2332 dnl Check for siginfo_t members
2333 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
2334
2335 dnl Check for struct mtget members
2336 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
2337 [#include <sys/types.h>
2338 #ifdef HAVE_SYS_MTIO_H
2339 #include <sys/mtio.h>
2340 #endif])
2341
2342 dnl Check for struct option
2343 AC_CHECK_MEMBERS([struct option.name],,,
2344 [#ifdef HAVE_GETOPT_H
2345 #include <getopt.h>
2346 #endif])
2347
2348 dnl Check for stat.st_blocks and ns-resolved times
2349 AC_CHECK_MEMBERS([
2350         struct stat.st_blocks,
2351         struct stat.st_mtim,
2352         struct stat.st_mtimespec,
2353         struct stat.st_ctim,
2354         struct stat.st_ctimespec,
2355         struct stat.st_atim,
2356         struct stat.st_atimespec,
2357         struct stat.st_birthtime,
2358         struct stat.st_birthtim,
2359         struct stat.st_birthtimespec,
2360         struct stat.__st_birthtime,
2361         struct stat.__st_birthtim])
2362
2363 dnl Check for sin6_scope_id
2364 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
2365 [#ifdef HAVE_SYS_TYPES_H
2366 #include <sys/types.h>
2367 #endif
2368 #ifdef HAVE_NETINET_IN_H
2369 #include <netinet/in.h>
2370 #endif])
2371
2372 dnl Check for struct __res_state
2373 AC_CHECK_TYPES([struct __res_state],,,
2374 [#ifdef HAVE_RESOLV_H
2375 #include <resolv.h>
2376 #endif])
2377
2378 dnl Check for _u._ext.nscount6
2379 AC_CHECK_MEMBERS([struct __res_state._u._ext.nscount6],,,
2380 [#ifdef HAVE_RESOLV_H
2381 #include <resolv.h>
2382 #endif])
2383
2384 dnl Check for ns_msg ptr member
2385 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
2386 [#ifdef HAVE_SYS_TYPES_H
2387 #include <sys/types.h>
2388 #endif
2389 #ifdef HAVE_NETINET_IN_H
2390 # include <netinet/in.h>
2391 #endif
2392 #ifdef HAVE_ARPA_NAMESER_H
2393 # include <arpa/nameser.h>
2394 #endif])
2395
2396 dnl Check for struct icmpstat
2397 AC_CHECK_MEMBERS([struct icmpstat.icps_inhist],,,
2398 [#ifdef HAVE_SYS_TYPES_H
2399 #include <sys/types.h>
2400 #endif
2401 #ifdef HAVE_NETINET_IP_H
2402 #include <netinet/ip.h>
2403 #endif
2404 #ifdef HAVE_NETINET_IP_ICMP_H
2405 #include <netinet/ip_icmp.h>
2406 #endif
2407 #ifdef HAVE_NETINET_ICMP_VAR_H
2408 #include <netinet/icmp_var.h>
2409 #endif])
2410
2411 dnl Check for struct icmpstat.icps_outhist
2412 AC_CHECK_MEMBERS([struct icmpstat.icps_outhist],,,
2413 [#ifdef HAVE_SYS_TYPES_H
2414 #include <sys/types.h>
2415 #endif
2416 #ifdef HAVE_ALIAS_H
2417 #include <alias.h>
2418 #endif
2419 #ifdef HAVE_SYS_SOCKET_H
2420 #include <sys/socket.h>
2421 #endif
2422 #ifdef HAVE_SYS_SOCKETVAR_H
2423 #include <sys/socketvar.h>
2424 #endif
2425 #ifdef HAVE_SYS_TIMEOUT_H
2426 #include <sys/timeout.h>
2427 #endif
2428 #ifdef HAVE_NETINET_IN_H
2429 #include <netinet/in.h>
2430 #endif
2431 #ifdef HAVE_NETINET_IN_SYSTM_H
2432 #include <netinet/in_systm.h>
2433 #endif
2434 #ifdef HAVE_NETINET_IP_H
2435 #include <netinet/ip.h>
2436 #endif
2437 #ifdef HAVE_NETINET_IP_VAR_H
2438 #include <netinet/ip_var.h>
2439 #endif
2440 #ifdef HAVE_NETINET_IP_ICMP_H
2441 #include <netinet/ip_icmp.h>
2442 #endif
2443 #ifdef HAVE_NETINET_ICMP_VAR_H
2444 #include <netinet/icmp_var.h>
2445 #endif])
2446
2447 dnl Check for struct ipstat
2448 AC_CHECK_MEMBERS([struct ipstat.ips_total],,,
2449 [#ifdef HAVE_SYS_TYPES_H
2450 #include <sys/types.h>
2451 #endif
2452 #ifdef HAVE_SYS_SOCKETVAR_H
2453 #include <sys/socketvar.h>
2454 #endif
2455 #ifdef HAVE_NETINET_IN_H
2456 #include <netinet/in.h>
2457 #endif
2458 #ifdef HAVE_NETINET_IP_VAR_H
2459 #include <netinet/ip_var.h>
2460 #endif])
2461
2462 dnl Check for struct ip_stats
2463 AC_CHECK_MEMBERS([struct ip_stats.ips_total],,,
2464 [#ifdef HAVE_NETINET_IP_VAR_H
2465 #include <netinet/ip_var.h>
2466 #endif])
2467
2468 dnl Check for struct tcpstat
2469 AC_CHECK_MEMBERS([struct tcpstat.tcps_connattempt],,,
2470 [#ifdef HAVE_SYS_TYPES_H
2471 #include <sys/types.h>
2472 #endif
2473 #ifdef HAVE_SYS_SOCKETVAR_H
2474 #include <sys/socketvar.h>
2475 #endif
2476 #ifdef HAVE_NETINET_IN_H
2477 #include <netinet/in.h>
2478 #endif
2479 #ifdef HAVE_NETINET_TCP_H
2480 #include <netinet/tcp.h>
2481 #endif
2482 #ifdef HAVE_NETINET_TCP_VAR_H
2483 #include <netinet/tcp_var.h>
2484 #endif])
2485
2486 dnl Check for struct tcp_stats
2487 AC_CHECK_MEMBERS([struct tcp_stats.tcps_connattempt],,,
2488 [#ifdef HAVE_NETINET_TCP_VAR_H
2489 #include <netinet/tcp_var.h>
2490 #endif])
2491
2492 dnl Check for struct udpstat
2493 AC_CHECK_MEMBERS([struct udpstat.udps_ipackets],,,
2494 [#ifdef HAVE_SYS_TYPES_H
2495 #include <sys/types.h>
2496 #endif
2497 #ifdef HAVE_NETINET_IN_H
2498 #include <netinet/in.h>
2499 #endif
2500 #ifdef HAVE_NETINET_IP_VAR_H
2501 #include <netinet/ip_var.h>
2502 #endif
2503 #ifdef HAVE_NETINET_UDP_H
2504 #include <netinet/udp.h>
2505 #endif
2506 #ifdef HAVE_NETINET_UDP_VAR_H
2507 #include <netinet/udp_var.h>
2508 #endif])
2509
2510 dnl Check for struct ifreq.ifr_hwaddr
2511 AC_CHECK_MEMBERS([struct ifreq.ifr_hwaddr],,,
2512 [#ifdef HAVE_SYS_TYPES_H
2513 #include <sys/types.h>
2514 #endif
2515 #ifdef HAVE_NET_IF_H
2516 # include <net/if.h>
2517 #endif])
2518
2519 dnl Check for the external timezone variables timezone and daylight
2520 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
2521                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
2522 if test "$ac_cv_have_timezone" = "yes"
2523 then
2524     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
2525 fi
2526 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
2527                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
2528 if test "$ac_cv_have_daylight" = "yes"
2529 then
2530     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
2531 fi
2532
2533 dnl Check for isfinite
2534 ac_save_LIBS="$LIBS"
2535 LIBS="$LIBS -lm"
2536 AC_CACHE_CHECK([for isfinite], ac_cv_have_isfinite,
2537                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define _GNU_SOURCE
2538 #include <math.h>]], [[float f = 0.0; return isfinite(f)]])],[ac_cv_have_isfinite="yes"],[ac_cv_have_isfinite="no"]))
2539 if test "$ac_cv_have_isfinite" = "yes"
2540 then
2541     AC_DEFINE(HAVE_ISFINITE, 1, [Define to 1 if you have the `isfinite' function.])
2542 fi
2543
2544 dnl Check for isinf
2545 ac_save_LIBS="$LIBS"
2546 LIBS="$LIBS -lm"
2547 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
2548                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; return isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
2549 if test "$ac_cv_have_isinf" = "yes"
2550 then
2551     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
2552 fi
2553
2554 dnl Check for isnan
2555 AC_CACHE_CHECK([for isnan], ac_cv_have_isnan,
2556                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; return isnan(f)]])],[ac_cv_have_isnan="yes"],[ac_cv_have_isnan="no"]))
2557 if test "$ac_cv_have_isnan" = "yes"
2558 then
2559     AC_DEFINE(HAVE_ISNAN, 1, [Define to 1 if you have the `isnan' function.])
2560 fi
2561 LIBS="$ac_save_LIBS"
2562
2563 dnl *** check for the need to define platform-specific symbols
2564
2565 case $host_cpu in
2566   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
2567   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
2568   *sparc64*)        WINE_CHECK_DEFINE([__sparc64__]) ;;
2569   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
2570   *powerpc64*)      WINE_CHECK_DEFINE([__powerpc64__]) ;;
2571   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
2572   *aarch64*)        WINE_CHECK_DEFINE([__aarch64__]) ;;
2573   *arm*)            WINE_CHECK_DEFINE([__arm__]) ;;
2574 esac
2575
2576 case $host_vendor in
2577   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
2578 esac
2579
2580 dnl **** Generate output files ****
2581
2582 AH_TOP([#ifndef __WINE_CONFIG_H
2583 #define __WINE_CONFIG_H
2584 #ifndef WINE_CROSSTEST])
2585 AH_BOTTOM([#endif /* WINE_CROSSTEST */
2586 #endif /* __WINE_CONFIG_H */])
2587
2588 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
2589 AS_ECHO_N("creating Makefile rules...") >&AS_MESSAGE_FD
2590
2591 dnl Import library rules
2592
2593 AC_SUBST(MAKE_IMPLIB_RULES,"DLLFLAGS = $DLLFLAGS
2594 ")
2595 if test -n "$CROSSTARGET"
2596 then
2597     AS_VAR_APPEND([MAKE_IMPLIB_RULES],"MAKEDEPFLAGS = -xo -xcross.o
2598 all: \$(STATICLIB:.a=.cross.a)
2599 ")
2600 fi
2601
2602 dnl Dll and program rules
2603
2604 if test -n "$DLLEXT"
2605 then
2606     deps="\$(MODULE)$DLLEXT \$(MODULE).fake"
2607 else
2608     deps="\$(MODULE)"
2609 fi
2610
2611 AC_SUBST(MAKE_DLL_RULES,"
2612 DLLFLAGS    = $DLLFLAGS
2613 MAINSPEC    = \$(MODULE:%.dll=%).spec
2614 IDL_TLB_RES = \$(IDL_TLB_SRCS:.idl=_t.res)
2615 MODULEFLAGS = -shared \$(srcdir)/\$(MAINSPEC) \$(EXTRADLLFLAGS)
2616
2617 all: $deps
2618
2619 manpages:: dummy
2620         \$(C2MAN) -o \$(top_builddir)/documentation/man\$(api_manext) -R\$(top_builddir) -C\$(srcdir) \$(PARENTSRC:%=-P%) -I\$(top_srcdir)/include \$(MAINSPEC:%=-w %) \$(C_SRCS)
2621 htmlpages:: dummy
2622         \$(C2MAN) -o \$(top_builddir)/documentation/html -R\$(top_builddir) -C\$(srcdir) \$(PARENTSRC:%=-P%) -I\$(top_srcdir)/include -Th \$(MAINSPEC:%=-w %) \$(C_SRCS)
2623 sgmlpages:: dummy
2624         \$(C2MAN) -o \$(top_builddir)/documentation/api-guide -R\$(top_builddir) -C\$(srcdir) \$(PARENTSRC:%=-P%) -I\$(top_srcdir)/include -Ts \$(MAINSPEC:%=-w %) \$(C_SRCS)
2625 xmlpages:: dummy
2626         \$(C2MAN) -o \$(top_builddir)/documentation/api-guide-xml -R\$(top_builddir) -C\$(srcdir) \$(PARENTSRC:%=-P%) -I\$(top_srcdir)/include -Tx \$(MAINSPEC:%=-w %) \$(C_SRCS)
2627 .PHONY: manpages htmlpages sgmlpages xmlpages
2628 ")
2629
2630 AC_SUBST(MAKE_PROG_RULES,"
2631 DLLFLAGS    = $DLLFLAGS
2632
2633 all: $deps
2634 ")
2635
2636 dnl Test rules
2637
2638 AC_SUBST(MAKE_TEST_RULES,"
2639 DLLFLAGS     = $DLLFLAGS
2640 TESTMODULE   = \$(TESTDLL:%.dll=%)_test.exe
2641 TESTMODULE_STRIPPED = \$(TESTDLL:%.dll=%)_test-stripped.exe$DLLEXT
2642 WINETEST_RES = \$(top_builddir)/programs/winetest/\$(TESTDLL:%.dll=%)_test.res
2643 RUNTESTFLAGS = -q -P wine -T \$(top_builddir) -M \$(TESTDLL) -p \$(TESTMODULE)$DLLEXT
2644 EXTRA_OBJS   = testlist.o
2645
2646 all: \$(TESTMODULE)$DLLEXT \$(WINETEST_RES)
2647
2648 \$(C_SRCS:.c=.ok): \$(TESTMODULE)$DLLEXT \$(TESTDLL:%=../%$DLLEXT)
2649
2650 .PHONY: check test testclean crosstest
2651 ")
2652 if test -n "$CROSSTARGET"
2653 then
2654     AS_VAR_APPEND([MAKE_TEST_RULES],"
2655 MAKEDEPFLAGS    = -xo -xcross.o
2656 CROSSTESTMODULE = \$(TESTDLL:%.dll=%)_crosstest.exe
2657
2658 crosstest: \$(CROSSTESTMODULE)
2659 ")
2660 fi
2661
2662 dnl Main makefile
2663
2664 WINE_APPEND_RULE([
2665 # Rules automatically generated by configure
2666
2667 .INIT: Makefile
2668 .MAKEFILEDEPS:
2669 all: Makefile
2670 Makefile: Makefile.in Make.vars.in Make.rules config.status
2671         @./config.status Make.tmp Makefile])
2672
2673 WINE_CONFIG_SYMLINK(fonts,fonts,[marlett.ttf,symbol.ttf,tahoma.ttf,tahomabd.ttf],enable_fonts)
2674 WINE_CONFIG_SYMLINK(loader,loader,[l_intl.nls])
2675 WINE_CONFIG_SYMLINK(po,po,[LINGUAS])
2676 WINE_CONFIG_SYMLINK(,tools,[wine],,winewrapper)
2677 WINE_CONFIG_SYMLINK(,tools,[wine64],enable_win64,winewrapper)
2678
2679 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/dibdrv)
2680 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
2681 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
2682 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
2683 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
2684 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
2685 WINE_CONFIG_EXTRA_DIR(include/wine)
2686
2687 WINE_CONFIG_MAKERULES([Make.rules],[MAKE_RULES])
2688
2689 WINE_CONFIG_DLL(acledit)
2690 WINE_CONFIG_DLL(aclui,,[implib])
2691 WINE_CONFIG_DLL(activeds,,[implib])
2692 WINE_CONFIG_DLL(actxprxy,,[clean])
2693 WINE_CONFIG_LIB(adsiid)
2694 WINE_CONFIG_DLL(advapi32,,[clean,implib])
2695 WINE_CONFIG_TEST(dlls/advapi32/tests)
2696 WINE_CONFIG_DLL(advpack,,[implib])
2697 WINE_CONFIG_TEST(dlls/advpack/tests)
2698 WINE_CONFIG_DLL(amstream,,[clean])
2699 WINE_CONFIG_TEST(dlls/amstream/tests)
2700 WINE_CONFIG_DLL(api-ms-win-core-localregistry-l1-1-0)
2701 WINE_CONFIG_DLL(api-ms-win-core-processthreads-l1-1-0)
2702 WINE_CONFIG_DLL(api-ms-win-core-winrt-error-l1-1-0)
2703 WINE_CONFIG_DLL(api-ms-win-core-winrt-string-l1-1-0)
2704 WINE_CONFIG_DLL(api-ms-win-downlevel-advapi32-l1-1-0)
2705 WINE_CONFIG_DLL(api-ms-win-downlevel-advapi32-l2-1-0)
2706 WINE_CONFIG_DLL(api-ms-win-downlevel-normaliz-l1-1-0)
2707 WINE_CONFIG_DLL(api-ms-win-downlevel-ole32-l1-1-0)
2708 WINE_CONFIG_DLL(api-ms-win-downlevel-shell32-l1-1-0)
2709 WINE_CONFIG_DLL(api-ms-win-downlevel-shlwapi-l1-1-0)
2710 WINE_CONFIG_DLL(api-ms-win-downlevel-shlwapi-l2-1-0)
2711 WINE_CONFIG_DLL(api-ms-win-downlevel-user32-l1-1-0)
2712 WINE_CONFIG_DLL(api-ms-win-downlevel-version-l1-1-0)
2713 WINE_CONFIG_DLL(api-ms-win-security-base-l1-1-0)
2714 WINE_CONFIG_DLL(apphelp)
2715 WINE_CONFIG_TEST(dlls/apphelp/tests)
2716 WINE_CONFIG_DLL(appwiz.cpl,,[po])
2717 WINE_CONFIG_DLL(atl,,[clean,implib])
2718 WINE_CONFIG_TEST(dlls/atl/tests)
2719 WINE_CONFIG_DLL(atl100,,[implib])
2720 WINE_CONFIG_TEST(dlls/atl100/tests)
2721 WINE_CONFIG_DLL(atl110)
2722 WINE_CONFIG_DLL(atl80,,[implib])
2723 WINE_CONFIG_TEST(dlls/atl80/tests)
2724 WINE_CONFIG_DLL(atl90)
2725 WINE_CONFIG_DLL(authz)
2726 WINE_CONFIG_DLL(avicap32,,[implib])
2727 WINE_CONFIG_DLL(avifil32,,[clean,implib,po])
2728 WINE_CONFIG_TEST(dlls/avifil32/tests)
2729 WINE_CONFIG_DLL(avifile.dll16,enable_win16)
2730 WINE_CONFIG_DLL(avrt,,[implib])
2731 WINE_CONFIG_DLL(bcrypt)
2732 WINE_CONFIG_DLL(browseui,,[clean,po])
2733 WINE_CONFIG_TEST(dlls/browseui/tests)
2734 WINE_CONFIG_DLL(cabinet,,[implib])
2735 WINE_CONFIG_TEST(dlls/cabinet/tests)
2736 WINE_CONFIG_DLL(capi2032,,[implib])
2737 WINE_CONFIG_DLL(cards,,[implib])
2738 WINE_CONFIG_DLL(cfgmgr32,,[implib])
2739 WINE_CONFIG_DLL(clusapi,,[implib])
2740 WINE_CONFIG_DLL(comcat)
2741 WINE_CONFIG_TEST(dlls/comcat/tests)
2742 WINE_CONFIG_DLL(comctl32,,[implib,po])
2743 WINE_CONFIG_TEST(dlls/comctl32/tests)
2744 WINE_CONFIG_DLL(comdlg32,,[clean,implib,po])
2745 WINE_CONFIG_TEST(dlls/comdlg32/tests)
2746 WINE_CONFIG_DLL(comm.drv16,enable_win16)
2747 WINE_CONFIG_DLL(commdlg.dll16,enable_win16)
2748 WINE_CONFIG_DLL(compobj.dll16,enable_win16)
2749 WINE_CONFIG_DLL(compstui,,[implib])
2750 WINE_CONFIG_DLL(comsvcs,,[implib])
2751 WINE_CONFIG_DLL(credui,,[implib,po])
2752 WINE_CONFIG_TEST(dlls/credui/tests)
2753 WINE_CONFIG_DLL(crtdll,,[implib])
2754 WINE_CONFIG_DLL(crypt32,,[implib,po])
2755 WINE_CONFIG_TEST(dlls/crypt32/tests)
2756 WINE_CONFIG_DLL(cryptdlg,,[po])
2757 WINE_CONFIG_DLL(cryptdll,,[implib])
2758 WINE_CONFIG_DLL(cryptnet,,[implib])
2759 WINE_CONFIG_TEST(dlls/cryptnet/tests)
2760 WINE_CONFIG_DLL(cryptui,,[implib,po])
2761 WINE_CONFIG_TEST(dlls/cryptui/tests)
2762 WINE_CONFIG_DLL(ctapi32)
2763 WINE_CONFIG_DLL(ctl3d.dll16,enable_win16)
2764 WINE_CONFIG_DLL(ctl3d32,,[implib])
2765 WINE_CONFIG_DLL(ctl3dv2.dll16,enable_win16)
2766 WINE_CONFIG_DLL(d3d10,,[implib])
2767 WINE_CONFIG_TEST(dlls/d3d10/tests)
2768 WINE_CONFIG_DLL(d3d10core,,[implib])
2769 WINE_CONFIG_TEST(dlls/d3d10core/tests)
2770 WINE_CONFIG_DLL(d3d11)
2771 WINE_CONFIG_DLL(d3d8,,[implib])
2772 WINE_CONFIG_TEST(dlls/d3d8/tests)
2773 WINE_CONFIG_DLL(d3d9,,[implib])
2774 WINE_CONFIG_TEST(dlls/d3d9/tests)
2775 WINE_CONFIG_DLL(d3dcompiler_33)
2776 WINE_CONFIG_DLL(d3dcompiler_34)
2777 WINE_CONFIG_DLL(d3dcompiler_35)
2778 WINE_CONFIG_DLL(d3dcompiler_36)
2779 WINE_CONFIG_DLL(d3dcompiler_37)
2780 WINE_CONFIG_DLL(d3dcompiler_38)
2781 WINE_CONFIG_DLL(d3dcompiler_39)
2782 WINE_CONFIG_DLL(d3dcompiler_40)
2783 WINE_CONFIG_DLL(d3dcompiler_41)
2784 WINE_CONFIG_DLL(d3dcompiler_42)
2785 WINE_CONFIG_DLL(d3dcompiler_43,,[implib],[d3dcompiler])
2786 WINE_CONFIG_TEST(dlls/d3dcompiler_43/tests)
2787 WINE_CONFIG_DLL(d3dim,,[implib])
2788 WINE_CONFIG_DLL(d3drm,,[implib])
2789 WINE_CONFIG_TEST(dlls/d3drm/tests)
2790 WINE_CONFIG_DLL(d3dx10_33)
2791 WINE_CONFIG_DLL(d3dx10_34)
2792 WINE_CONFIG_DLL(d3dx10_35)
2793 WINE_CONFIG_DLL(d3dx10_36)
2794 WINE_CONFIG_DLL(d3dx10_37)
2795 WINE_CONFIG_DLL(d3dx10_38)
2796 WINE_CONFIG_DLL(d3dx10_39)
2797 WINE_CONFIG_DLL(d3dx10_40)
2798 WINE_CONFIG_DLL(d3dx10_41)
2799 WINE_CONFIG_DLL(d3dx10_42)
2800 WINE_CONFIG_DLL(d3dx10_43)
2801 WINE_CONFIG_DLL(d3dx11_42)
2802 WINE_CONFIG_DLL(d3dx11_43)
2803 WINE_CONFIG_DLL(d3dx9_24)
2804 WINE_CONFIG_DLL(d3dx9_25)
2805 WINE_CONFIG_DLL(d3dx9_26)
2806 WINE_CONFIG_DLL(d3dx9_27)
2807 WINE_CONFIG_DLL(d3dx9_28)
2808 WINE_CONFIG_DLL(d3dx9_29)
2809 WINE_CONFIG_DLL(d3dx9_30)
2810 WINE_CONFIG_DLL(d3dx9_31)
2811 WINE_CONFIG_DLL(d3dx9_32)
2812 WINE_CONFIG_DLL(d3dx9_33)
2813 WINE_CONFIG_DLL(d3dx9_34)
2814 WINE_CONFIG_DLL(d3dx9_35)
2815 WINE_CONFIG_DLL(d3dx9_36,,[implib],[d3dx9])
2816 WINE_CONFIG_TEST(dlls/d3dx9_36/tests)
2817 WINE_CONFIG_DLL(d3dx9_37)
2818 WINE_CONFIG_DLL(d3dx9_38)
2819 WINE_CONFIG_DLL(d3dx9_39)
2820 WINE_CONFIG_DLL(d3dx9_40)
2821 WINE_CONFIG_DLL(d3dx9_41)
2822 WINE_CONFIG_DLL(d3dx9_42)
2823 WINE_CONFIG_DLL(d3dx9_43)
2824 WINE_CONFIG_DLL(d3dxof,,[clean,implib])
2825 WINE_CONFIG_TEST(dlls/d3dxof/tests)
2826 WINE_CONFIG_DLL(dbgeng,,[implib])
2827 WINE_CONFIG_DLL(dbghelp,,[implib])
2828 WINE_CONFIG_DLL(dciman32,,[implib])
2829 WINE_CONFIG_DLL(ddeml.dll16,enable_win16)
2830 WINE_CONFIG_DLL(ddraw,,[clean,implib])
2831 WINE_CONFIG_TEST(dlls/ddraw/tests)
2832 WINE_CONFIG_DLL(ddrawex,,[clean])
2833 WINE_CONFIG_TEST(dlls/ddrawex/tests)
2834 WINE_CONFIG_DLL(devenum,,[clean,po])
2835 WINE_CONFIG_TEST(dlls/devenum/tests)
2836 WINE_CONFIG_DLL(dhcpcsvc)
2837 WINE_CONFIG_DLL(difxapi)
2838 WINE_CONFIG_DLL(dinput,,[clean,implib,po,staticimplib])
2839 WINE_CONFIG_TEST(dlls/dinput/tests)
2840 WINE_CONFIG_DLL(dinput8,,[clean,implib])
2841 WINE_CONFIG_TEST(dlls/dinput8/tests)
2842 WINE_CONFIG_DLL(dispdib.dll16,enable_win16)
2843 WINE_CONFIG_DLL(dispex,,[clean])
2844 WINE_CONFIG_TEST(dlls/dispex/tests)
2845 WINE_CONFIG_DLL(display.drv16,enable_win16)
2846 WINE_CONFIG_DLL(dmband,,[clean])
2847 WINE_CONFIG_TEST(dlls/dmband/tests)
2848 WINE_CONFIG_DLL(dmcompos,,[clean])
2849 WINE_CONFIG_DLL(dmime,,[clean])
2850 WINE_CONFIG_TEST(dlls/dmime/tests)
2851 WINE_CONFIG_DLL(dmloader,,[clean])
2852 WINE_CONFIG_TEST(dlls/dmloader/tests)
2853 WINE_CONFIG_DLL(dmscript,,[clean])
2854 WINE_CONFIG_DLL(dmstyle,,[clean])
2855 WINE_CONFIG_DLL(dmsynth,,[clean])
2856 WINE_CONFIG_TEST(dlls/dmsynth/tests)
2857 WINE_CONFIG_DLL(dmusic,,[clean])
2858 WINE_CONFIG_TEST(dlls/dmusic/tests)
2859 WINE_CONFIG_DLL(dmusic32,,[implib])
2860 WINE_CONFIG_DLL(dnsapi,,[implib])
2861 WINE_CONFIG_TEST(dlls/dnsapi/tests)
2862 WINE_CONFIG_DLL(dplay,,[implib])
2863 WINE_CONFIG_DLL(dplayx,,[clean,implib])
2864 WINE_CONFIG_TEST(dlls/dplayx/tests)
2865 WINE_CONFIG_DLL(dpnaddr)
2866 WINE_CONFIG_DLL(dpnet,,[clean,implib])
2867 WINE_CONFIG_TEST(dlls/dpnet/tests)
2868 WINE_CONFIG_DLL(dpnhpast)
2869 WINE_CONFIG_DLL(dpnlobby)
2870 WINE_CONFIG_DLL(dpwsockx)
2871 WINE_CONFIG_DLL(drmclien)
2872 WINE_CONFIG_DLL(dsound,,[clean,implib])
2873 WINE_CONFIG_TEST(dlls/dsound/tests)
2874 WINE_CONFIG_DLL(dssenh)
2875 WINE_CONFIG_TEST(dlls/dssenh/tests)
2876 WINE_CONFIG_DLL(dswave,,[clean])
2877 WINE_CONFIG_DLL(dwmapi,,[implib])
2878 WINE_CONFIG_DLL(dwrite,,[implib])
2879 WINE_CONFIG_TEST(dlls/dwrite/tests)
2880 WINE_CONFIG_DLL(dxdiagn,,[clean,po])
2881 WINE_CONFIG_TEST(dlls/dxdiagn/tests)
2882 WINE_CONFIG_LIB(dxerr8)
2883 WINE_CONFIG_LIB(dxerr9)
2884 WINE_CONFIG_DLL(dxgi,,[implib])
2885 WINE_CONFIG_TEST(dlls/dxgi/tests)
2886 WINE_CONFIG_LIB(dxguid)
2887 WINE_CONFIG_DLL(explorerframe,,[clean])
2888 WINE_CONFIG_TEST(dlls/explorerframe/tests)
2889 WINE_CONFIG_DLL(faultrep,,[implib])
2890 WINE_CONFIG_TEST(dlls/faultrep/tests)
2891 WINE_CONFIG_DLL(fltlib)
2892 WINE_CONFIG_DLL(fusion)
2893 WINE_CONFIG_TEST(dlls/fusion/tests)
2894 WINE_CONFIG_DLL(fwpuclnt)
2895 WINE_CONFIG_DLL(gameux,,[clean])
2896 WINE_CONFIG_TEST(dlls/gameux/tests)
2897 WINE_CONFIG_DLL(gdi.exe16,enable_win16)
2898 WINE_CONFIG_DLL(gdi32,,[clean,implib,po])
2899 WINE_CONFIG_TEST(dlls/gdi32/tests)
2900 WINE_CONFIG_DLL(gdiplus,,[implib])
2901 WINE_CONFIG_TEST(dlls/gdiplus/tests)
2902 WINE_CONFIG_DLL(glu32,,[implib])
2903 WINE_CONFIG_DLL(gphoto2.ds,,[po])
2904 WINE_CONFIG_DLL(gpkcsp)
2905 WINE_CONFIG_DLL(hal)
2906 WINE_CONFIG_DLL(hhctrl.ocx,,[clean,implib,po],[htmlhelp])
2907 WINE_CONFIG_DLL(hid,,[implib])
2908 WINE_CONFIG_DLL(hlink,,[clean,implib])
2909 WINE_CONFIG_TEST(dlls/hlink/tests)
2910 WINE_CONFIG_DLL(hnetcfg,,[clean])
2911 WINE_CONFIG_DLL(httpapi)
2912 WINE_CONFIG_DLL(iccvid,,[po])
2913 WINE_CONFIG_DLL(icmp)
2914 WINE_CONFIG_DLL(ieframe,,[clean,implib,po])
2915 WINE_CONFIG_TEST(dlls/ieframe/tests)
2916 WINE_CONFIG_DLL(ifsmgr.vxd,enable_win16)
2917 WINE_CONFIG_DLL(imaadp32.acm)
2918 WINE_CONFIG_DLL(imagehlp,,[implib])
2919 WINE_CONFIG_TEST(dlls/imagehlp/tests)
2920 WINE_CONFIG_DLL(imm.dll16,enable_win16)
2921 WINE_CONFIG_DLL(imm32,,[implib])
2922 WINE_CONFIG_TEST(dlls/imm32/tests)
2923 WINE_CONFIG_DLL(inetcomm,,[clean,implib])
2924 WINE_CONFIG_TEST(dlls/inetcomm/tests)
2925 WINE_CONFIG_DLL(inetcpl.cpl,,[po])
2926 WINE_CONFIG_DLL(inetmib1)
2927 WINE_CONFIG_TEST(dlls/inetmib1/tests)
2928 WINE_CONFIG_DLL(infosoft,,[clean])
2929 WINE_CONFIG_TEST(dlls/infosoft/tests)
2930 WINE_CONFIG_DLL(initpki)
2931 WINE_CONFIG_DLL(inkobj)
2932 WINE_CONFIG_DLL(inseng,,[clean])
2933 WINE_CONFIG_DLL(iphlpapi,,[implib])
2934 WINE_CONFIG_TEST(dlls/iphlpapi/tests)
2935 WINE_CONFIG_DLL(itircl)
2936 WINE_CONFIG_DLL(itss,,[clean])
2937 WINE_CONFIG_TEST(dlls/itss/tests)
2938 WINE_CONFIG_DLL(joy.cpl,,[po])
2939 WINE_CONFIG_DLL(jscript,,[clean,po])
2940 WINE_CONFIG_TEST(dlls/jscript/tests)
2941 WINE_CONFIG_DLL(kernel32,,[clean,implib,mc])
2942 WINE_CONFIG_TEST(dlls/kernel32/tests)
2943 WINE_CONFIG_DLL(keyboard.drv16,enable_win16)
2944 WINE_CONFIG_DLL(krnl386.exe16,enable_win16,[implib],[kernel])
2945 WINE_CONFIG_DLL(ktmw32)
2946 WINE_CONFIG_DLL(loadperf,,[implib])
2947 WINE_CONFIG_DLL(localspl,,[po])
2948 WINE_CONFIG_TEST(dlls/localspl/tests)
2949 WINE_CONFIG_DLL(localui,,[po])
2950 WINE_CONFIG_TEST(dlls/localui/tests)
2951 WINE_CONFIG_DLL(lz32,,[implib])
2952 WINE_CONFIG_TEST(dlls/lz32/tests)
2953 WINE_CONFIG_DLL(lzexpand.dll16,enable_win16)
2954 WINE_CONFIG_DLL(mapi32,,[implib,po])
2955 WINE_CONFIG_TEST(dlls/mapi32/tests)
2956 WINE_CONFIG_DLL(mapistub)
2957 WINE_CONFIG_DLL(mciavi32)
2958 WINE_CONFIG_DLL(mcicda)
2959 WINE_CONFIG_DLL(mciqtz32)
2960 WINE_CONFIG_DLL(mciseq)
2961 WINE_CONFIG_DLL(mciwave)
2962 WINE_CONFIG_DLL(mgmtapi)
2963 WINE_CONFIG_DLL(midimap)
2964 WINE_CONFIG_DLL(mlang,,[clean,implib])
2965 WINE_CONFIG_TEST(dlls/mlang/tests)
2966 WINE_CONFIG_DLL(mmcndmgr,,[clean])
2967 WINE_CONFIG_TEST(dlls/mmcndmgr/tests)
2968 WINE_CONFIG_DLL(mmdevapi,,[clean])
2969 WINE_CONFIG_TEST(dlls/mmdevapi/tests)
2970 WINE_CONFIG_DLL(mmdevldr.vxd,enable_win16)
2971 WINE_CONFIG_DLL(mmsystem.dll16,enable_win16)
2972 WINE_CONFIG_DLL(monodebg.vxd,enable_win16)
2973 WINE_CONFIG_DLL(mountmgr.sys)
2974 WINE_CONFIG_DLL(mouse.drv16,enable_win16)
2975 WINE_CONFIG_DLL(mpr,,[implib,po])
2976 WINE_CONFIG_TEST(dlls/mpr/tests)
2977 WINE_CONFIG_DLL(mprapi,,[implib])
2978 WINE_CONFIG_DLL(msacm.dll16,enable_win16)
2979 WINE_CONFIG_DLL(msacm32.drv)
2980 WINE_CONFIG_DLL(msacm32,,[implib,po])
2981 WINE_CONFIG_TEST(dlls/msacm32/tests)
2982 WINE_CONFIG_DLL(msadp32.acm)
2983 WINE_CONFIG_DLL(mscat32)
2984 WINE_CONFIG_DLL(mscms,,[implib])
2985 WINE_CONFIG_TEST(dlls/mscms/tests)
2986 WINE_CONFIG_DLL(mscoree,,[clean])
2987 WINE_CONFIG_TEST(dlls/mscoree/tests)
2988 WINE_CONFIG_DLL(msctf,,[clean])
2989 WINE_CONFIG_TEST(dlls/msctf/tests)
2990 WINE_CONFIG_DLL(msdaps,,[clean])
2991 WINE_CONFIG_DLL(msdmo,,[implib])
2992 WINE_CONFIG_DLL(msftedit)
2993 WINE_CONFIG_DLL(msg711.acm)
2994 WINE_CONFIG_DLL(msgsm32.acm)
2995 WINE_CONFIG_DLL(mshtml.tlb,,[clean])
2996 WINE_CONFIG_DLL(mshtml,,[clean,implib,po])
2997 WINE_CONFIG_TEST(dlls/mshtml/tests,[clean])
2998 WINE_CONFIG_DLL(msi,,[clean,implib,po])
2999 WINE_CONFIG_TEST(dlls/msi/tests)
3000 WINE_CONFIG_DLL(msident,,[clean])
3001 WINE_CONFIG_DLL(msimg32,,[implib])
3002 WINE_CONFIG_DLL(msimsg)
3003 WINE_CONFIG_DLL(msimtf,,[clean])
3004 WINE_CONFIG_DLL(msisip)
3005 WINE_CONFIG_DLL(msisys.ocx)
3006 WINE_CONFIG_DLL(msls31)
3007 WINE_CONFIG_DLL(msnet32)
3008 WINE_CONFIG_DLL(mspatcha)
3009 WINE_CONFIG_DLL(msrle32,,[po])
3010 WINE_CONFIG_DLL(mssign32)
3011 WINE_CONFIG_DLL(mssip32)
3012 WINE_CONFIG_DLL(mstask,,[clean])
3013 WINE_CONFIG_TEST(dlls/mstask/tests)
3014 WINE_CONFIG_DLL(msvcirt)
3015 WINE_CONFIG_DLL(msvcm80)
3016 WINE_CONFIG_DLL(msvcm90)
3017 WINE_CONFIG_DLL(msvcp100)
3018 WINE_CONFIG_TEST(dlls/msvcp100/tests)
3019 WINE_CONFIG_DLL(msvcp110)
3020 WINE_CONFIG_DLL(msvcp60)
3021 WINE_CONFIG_TEST(dlls/msvcp60/tests)
3022 WINE_CONFIG_DLL(msvcp70)
3023 WINE_CONFIG_DLL(msvcp71)
3024 WINE_CONFIG_DLL(msvcp80)
3025 WINE_CONFIG_DLL(msvcp90)
3026 WINE_CONFIG_TEST(dlls/msvcp90/tests)
3027 WINE_CONFIG_DLL(msvcr100)
3028 WINE_CONFIG_TEST(dlls/msvcr100/tests)
3029 WINE_CONFIG_DLL(msvcr110)
3030 WINE_CONFIG_DLL(msvcr70,,[implib])
3031 WINE_CONFIG_DLL(msvcr71,,[implib])
3032 WINE_CONFIG_DLL(msvcr80)
3033 WINE_CONFIG_DLL(msvcr90)
3034 WINE_CONFIG_TEST(dlls/msvcr90/tests)
3035 WINE_CONFIG_DLL(msvcrt,,[implib])
3036 WINE_CONFIG_TEST(dlls/msvcrt/tests)
3037 WINE_CONFIG_DLL(msvcrt20,,[implib])
3038 WINE_CONFIG_DLL(msvcrt40,,[implib])
3039 WINE_CONFIG_DLL(msvcrtd,,[implib])
3040 WINE_CONFIG_TEST(dlls/msvcrtd/tests)
3041 WINE_CONFIG_DLL(msvfw32,,[implib,po])
3042 WINE_CONFIG_TEST(dlls/msvfw32/tests)
3043 WINE_CONFIG_DLL(msvidc32,,[po])
3044 WINE_CONFIG_DLL(msvideo.dll16,enable_win16)
3045 WINE_CONFIG_DLL(mswsock,,[implib])
3046 WINE_CONFIG_DLL(msxml,,[clean])
3047 WINE_CONFIG_DLL(msxml2,,[clean])
3048 WINE_CONFIG_DLL(msxml3,,[clean])
3049 WINE_CONFIG_TEST(dlls/msxml3/tests,[clean])
3050 WINE_CONFIG_DLL(msxml4,,[clean])
3051 WINE_CONFIG_DLL(msxml6,,[clean])
3052 WINE_CONFIG_DLL(nddeapi,,[implib])
3053 WINE_CONFIG_DLL(netapi32,,[implib])
3054 WINE_CONFIG_TEST(dlls/netapi32/tests)
3055 WINE_CONFIG_DLL(netcfgx)
3056 WINE_CONFIG_DLL(newdev,,[implib])
3057 WINE_CONFIG_DLL(normaliz,,[implib])
3058 WINE_CONFIG_DLL(npmshtml)
3059 WINE_CONFIG_DLL(ntdll,,[implib])
3060 WINE_CONFIG_TEST(dlls/ntdll/tests)
3061 WINE_CONFIG_DLL(ntdsapi,,[implib])
3062 WINE_CONFIG_TEST(dlls/ntdsapi/tests)
3063 WINE_CONFIG_DLL(ntoskrnl.exe,,[implib])
3064 WINE_CONFIG_DLL(ntprint)
3065 WINE_CONFIG_TEST(dlls/ntprint/tests)
3066 WINE_CONFIG_DLL(objsel,,[clean])
3067 WINE_CONFIG_DLL(odbc32,,[implib])
3068 WINE_CONFIG_DLL(odbccp32,,[implib])
3069 WINE_CONFIG_TEST(dlls/odbccp32/tests)
3070 WINE_CONFIG_DLL(odbccu32)
3071 WINE_CONFIG_DLL(ole2.dll16,enable_win16)
3072 WINE_CONFIG_DLL(ole2conv.dll16,enable_win16)
3073 WINE_CONFIG_DLL(ole2disp.dll16,enable_win16)
3074 WINE_CONFIG_DLL(ole2nls.dll16,enable_win16)
3075 WINE_CONFIG_DLL(ole2prox.dll16,enable_win16)
3076 WINE_CONFIG_DLL(ole2thk.dll16,enable_win16)
3077 WINE_CONFIG_DLL(ole32,,[clean,implib])
3078 WINE_CONFIG_TEST(dlls/ole32/tests)
3079 WINE_CONFIG_DLL(oleacc,,[clean,implib,po])
3080 WINE_CONFIG_TEST(dlls/oleacc/tests)
3081 WINE_CONFIG_DLL(oleaut32,,[clean,implib,po])
3082 WINE_CONFIG_TEST(dlls/oleaut32/tests,[clean])
3083 WINE_CONFIG_DLL(olecli.dll16,enable_win16)
3084 WINE_CONFIG_DLL(olecli32,,[implib])
3085 WINE_CONFIG_DLL(oledb32,,[clean])
3086 WINE_CONFIG_TEST(dlls/oledb32/tests,[clean])
3087 WINE_CONFIG_DLL(oledlg,,[implib,po])
3088 WINE_CONFIG_DLL(olepro32,,[implib])
3089 WINE_CONFIG_DLL(olesvr.dll16,enable_win16)
3090 WINE_CONFIG_DLL(olesvr32,,[implib])
3091 WINE_CONFIG_DLL(olethk32)
3092 WINE_CONFIG_DLL(openal32)
3093 WINE_CONFIG_DLL(opencl)
3094 WINE_CONFIG_DLL(opengl32,,[implib])
3095 WINE_CONFIG_TEST(dlls/opengl32/tests)
3096 WINE_CONFIG_DLL(pdh,,[implib])
3097 WINE_CONFIG_TEST(dlls/pdh/tests)
3098 WINE_CONFIG_DLL(photometadatahandler)
3099 WINE_CONFIG_DLL(pidgen)
3100 WINE_CONFIG_DLL(powrprof,,[implib])
3101 WINE_CONFIG_DLL(printui)
3102 WINE_CONFIG_DLL(propsys,,[clean,implib])
3103 WINE_CONFIG_TEST(dlls/propsys/tests)
3104 WINE_CONFIG_DLL(psapi,,[implib])
3105 WINE_CONFIG_TEST(dlls/psapi/tests)
3106 WINE_CONFIG_DLL(pstorec,,[clean])
3107 WINE_CONFIG_DLL(qcap)
3108 WINE_CONFIG_TEST(dlls/qcap/tests)
3109 WINE_CONFIG_DLL(qedit,,[clean])
3110 WINE_CONFIG_TEST(dlls/qedit/tests)
3111 WINE_CONFIG_DLL(qmgr,,[clean])
3112 WINE_CONFIG_TEST(dlls/qmgr/tests)
3113 WINE_CONFIG_DLL(qmgrprxy,,[clean])
3114 WINE_CONFIG_DLL(quartz,,[clean,implib])
3115 WINE_CONFIG_TEST(dlls/quartz/tests,[clean])
3116 WINE_CONFIG_DLL(query)
3117 WINE_CONFIG_DLL(rasapi16.dll16,enable_win16)
3118 WINE_CONFIG_DLL(rasapi32,,[implib])
3119 WINE_CONFIG_TEST(dlls/rasapi32/tests)
3120 WINE_CONFIG_DLL(rasdlg,,[implib])
3121 WINE_CONFIG_DLL(regapi)
3122 WINE_CONFIG_DLL(resutils,,[implib])
3123 WINE_CONFIG_DLL(riched20,,[implib])
3124 WINE_CONFIG_TEST(dlls/riched20/tests)
3125 WINE_CONFIG_DLL(riched32)
3126 WINE_CONFIG_TEST(dlls/riched32/tests)
3127 WINE_CONFIG_DLL(rpcrt4,,[clean,implib])
3128 WINE_CONFIG_TEST(dlls/rpcrt4/tests,[clean])
3129 WINE_CONFIG_DLL(rsabase)
3130 WINE_CONFIG_DLL(rsaenh,,[implib])
3131 WINE_CONFIG_TEST(dlls/rsaenh/tests)
3132 WINE_CONFIG_DLL(rstrtmgr)
3133 WINE_CONFIG_DLL(rtutils,,[implib])
3134 WINE_CONFIG_DLL(samlib)
3135 WINE_CONFIG_DLL(sane.ds,,[po])
3136 WINE_CONFIG_DLL(scarddlg)
3137 WINE_CONFIG_DLL(sccbase)
3138 WINE_CONFIG_DLL(schannel)
3139 WINE_CONFIG_TEST(dlls/schannel/tests)
3140 WINE_CONFIG_DLL(scrrun,,[clean])
3141 WINE_CONFIG_TEST(dlls/scrrun/tests,[clean])
3142 WINE_CONFIG_DLL(scsiport.sys)
3143 WINE_CONFIG_DLL(secur32,,[implib])
3144 WINE_CONFIG_TEST(dlls/secur32/tests)
3145 WINE_CONFIG_DLL(security)
3146 WINE_CONFIG_DLL(sensapi,,[implib])
3147 WINE_CONFIG_DLL(serialui,,[implib,po])
3148 WINE_CONFIG_TEST(dlls/serialui/tests)
3149 WINE_CONFIG_DLL(setupapi,,[implib,po])
3150 WINE_CONFIG_TEST(dlls/setupapi/tests)
3151 WINE_CONFIG_DLL(setupx.dll16,enable_win16)
3152 WINE_CONFIG_DLL(sfc,,[implib])
3153 WINE_CONFIG_DLL(sfc_os,,[implib])
3154 WINE_CONFIG_DLL(shdoclc,,[po])
3155 WINE_CONFIG_DLL(shdocvw,,[clean,implib])
3156 WINE_CONFIG_TEST(dlls/shdocvw/tests)
3157 WINE_CONFIG_DLL(shell.dll16,enable_win16)
3158 WINE_CONFIG_DLL(shell32,,[clean,implib,po])
3159 WINE_CONFIG_TEST(dlls/shell32/tests)
3160 WINE_CONFIG_DLL(shfolder,,[implib])
3161 WINE_CONFIG_DLL(shlwapi,,[implib,po])
3162 WINE_CONFIG_TEST(dlls/shlwapi/tests)
3163 WINE_CONFIG_DLL(slbcsp)
3164 WINE_CONFIG_DLL(slc,,[implib])
3165 WINE_CONFIG_DLL(snmpapi,,[implib])
3166 WINE_CONFIG_TEST(dlls/snmpapi/tests)
3167 WINE_CONFIG_DLL(softpub)
3168 WINE_CONFIG_DLL(sound.drv16,enable_win16)
3169 WINE_CONFIG_DLL(spoolss,,[implib])
3170 WINE_CONFIG_TEST(dlls/spoolss/tests)
3171 WINE_CONFIG_DLL(stdole2.tlb,,[clean])
3172 WINE_CONFIG_DLL(stdole32.tlb,,[clean])
3173 WINE_CONFIG_DLL(sti,,[clean,implib])
3174 WINE_CONFIG_TEST(dlls/sti/tests)
3175 WINE_CONFIG_DLL(storage.dll16,enable_win16)
3176 WINE_CONFIG_DLL(stress.dll16,enable_win16)
3177 WINE_CONFIG_LIB(strmbase)
3178 WINE_CONFIG_LIB(strmiids)
3179 WINE_CONFIG_DLL(svrapi)
3180 WINE_CONFIG_DLL(sxs,,[implib])
3181 WINE_CONFIG_TEST(dlls/sxs/tests)
3182 WINE_CONFIG_DLL(system.drv16,enable_win16)
3183 WINE_CONFIG_DLL(t2embed)
3184 WINE_CONFIG_DLL(tapi32,,[implib])
3185 WINE_CONFIG_DLL(toolhelp.dll16,enable_win16)
3186 WINE_CONFIG_DLL(traffic)
3187 WINE_CONFIG_DLL(twain.dll16,enable_win16)
3188 WINE_CONFIG_DLL(twain_32)
3189 WINE_CONFIG_TEST(dlls/twain_32/tests)
3190 WINE_CONFIG_DLL(typelib.dll16,enable_win16)
3191 WINE_CONFIG_DLL(unicows,,[implib])
3192 WINE_CONFIG_DLL(updspapi)
3193 WINE_CONFIG_DLL(url,,[implib])
3194 WINE_CONFIG_DLL(urlmon,,[clean,implib,po])
3195 WINE_CONFIG_TEST(dlls/urlmon/tests)
3196 WINE_CONFIG_DLL(usbd.sys,,[implib])
3197 WINE_CONFIG_DLL(user.exe16,enable_win16)
3198 WINE_CONFIG_DLL(user32,,[clean,implib,po])
3199 WINE_CONFIG_TEST(dlls/user32/tests)
3200 WINE_CONFIG_DLL(userenv,,[implib])
3201 WINE_CONFIG_TEST(dlls/userenv/tests)
3202 WINE_CONFIG_DLL(usp10,,[implib])
3203 WINE_CONFIG_TEST(dlls/usp10/tests)
3204 WINE_CONFIG_LIB(uuid)
3205 WINE_CONFIG_DLL(uxtheme,,[implib])
3206 WINE_CONFIG_TEST(dlls/uxtheme/tests)
3207 WINE_CONFIG_DLL(vbscript,,[clean])
3208 WINE_CONFIG_TEST(dlls/vbscript/tests,[clean])
3209 WINE_CONFIG_DLL(vcomp)
3210 WINE_CONFIG_DLL(vcomp100)
3211 WINE_CONFIG_DLL(vcomp90)
3212 WINE_CONFIG_DLL(vdhcp.vxd,enable_win16)
3213 WINE_CONFIG_DLL(vdmdbg,,[implib])
3214 WINE_CONFIG_DLL(ver.dll16,enable_win16)
3215 WINE_CONFIG_DLL(version,,[implib])
3216 WINE_CONFIG_TEST(dlls/version/tests)
3217 WINE_CONFIG_DLL(vmm.vxd,enable_win16)
3218 WINE_CONFIG_DLL(vnbt.vxd,enable_win16)
3219 WINE_CONFIG_DLL(vnetbios.vxd,enable_win16)
3220 WINE_CONFIG_DLL(vtdapi.vxd,enable_win16)
3221 WINE_CONFIG_DLL(vwin32.vxd,enable_win16)
3222 WINE_CONFIG_DLL(w32skrnl,enable_win16)
3223 WINE_CONFIG_DLL(w32sys.dll16,enable_win16)
3224 WINE_CONFIG_DLL(wbemdisp,,[clean])
3225 WINE_CONFIG_DLL(wbemprox,,[clean])
3226 WINE_CONFIG_TEST(dlls/wbemprox/tests)
3227 WINE_CONFIG_DLL(webservices,,[implib])
3228 WINE_CONFIG_DLL(wer,,[implib])
3229 WINE_CONFIG_TEST(dlls/wer/tests)
3230 WINE_CONFIG_DLL(wevtapi)
3231 WINE_CONFIG_DLL(wiaservc,,[clean])
3232 WINE_CONFIG_DLL(win32s16.dll16,enable_win16)
3233 WINE_CONFIG_DLL(win87em.dll16,enable_win16)
3234 WINE_CONFIG_DLL(winaspi.dll16,enable_win16)
3235 WINE_CONFIG_DLL(windebug.dll16,enable_win16)
3236 WINE_CONFIG_DLL(windowscodecs,,[clean,implib])
3237 WINE_CONFIG_TEST(dlls/windowscodecs/tests)
3238 WINE_CONFIG_DLL(windowscodecsext,,[implib])
3239 WINE_CONFIG_TEST(dlls/windowscodecsext/tests)
3240 WINE_CONFIG_DLL(winealsa.drv)
3241 WINE_CONFIG_DLL(winecoreaudio.drv)
3242 WINE_CONFIG_LIB(winecrt0)
3243 WINE_CONFIG_DLL(wined3d,,[implib])
3244 WINE_CONFIG_DLL(winegstreamer)
3245 WINE_CONFIG_DLL(winejoystick.drv)
3246 WINE_CONFIG_DLL(winemac.drv)
3247 WINE_CONFIG_DLL(winemapi)
3248 WINE_CONFIG_DLL(winemp3.acm)
3249 WINE_CONFIG_DLL(wineoss.drv)
3250 WINE_CONFIG_DLL(wineps.drv,,[clean,po])
3251 WINE_CONFIG_DLL(wineps16.drv16,enable_win16)
3252 WINE_CONFIG_DLL(wineqtdecoder)
3253 WINE_CONFIG_DLL(winex11.drv)
3254 WINE_CONFIG_DLL(wing.dll16,enable_win16)
3255 WINE_CONFIG_DLL(wing32)
3256 WINE_CONFIG_DLL(winhttp,,[clean,implib])
3257 WINE_CONFIG_TEST(dlls/winhttp/tests)
3258 WINE_CONFIG_DLL(wininet,,[implib,po])
3259 WINE_CONFIG_TEST(dlls/wininet/tests)
3260 WINE_CONFIG_DLL(winmm,,[implib,po])
3261 WINE_CONFIG_TEST(dlls/winmm/tests)
3262 WINE_CONFIG_DLL(winnls.dll16,enable_win16)
3263 WINE_CONFIG_DLL(winnls32,,[implib])
3264 WINE_CONFIG_DLL(winscard,,[implib])
3265 WINE_CONFIG_DLL(winsock.dll16,enable_win16)
3266 WINE_CONFIG_DLL(winspool.drv,,[implib,po],[winspool])
3267 WINE_CONFIG_TEST(dlls/winspool.drv/tests)
3268 WINE_CONFIG_DLL(winsta)
3269 WINE_CONFIG_DLL(wintab.dll16,enable_win16)
3270 WINE_CONFIG_DLL(wintab32,,[implib])
3271 WINE_CONFIG_TEST(dlls/wintab32/tests)
3272 WINE_CONFIG_DLL(wintrust,,[implib])
3273 WINE_CONFIG_TEST(dlls/wintrust/tests)
3274 WINE_CONFIG_DLL(wlanapi)
3275 WINE_CONFIG_DLL(wldap32,,[implib,po])
3276 WINE_CONFIG_TEST(dlls/wldap32/tests)
3277 WINE_CONFIG_DLL(wmi)
3278 WINE_CONFIG_DLL(wmiutils,,[clean])
3279 WINE_CONFIG_TEST(dlls/wmiutils/tests)
3280 WINE_CONFIG_DLL(wmvcore)
3281 WINE_CONFIG_DLL(wnaspi32,,[implib])
3282 WINE_CONFIG_DLL(wow32,enable_win16,[implib])
3283 WINE_CONFIG_DLL(ws2_32,,[implib])
3284 WINE_CONFIG_TEST(dlls/ws2_32/tests)
3285 WINE_CONFIG_DLL(wshom.ocx,,[clean])
3286 WINE_CONFIG_TEST(dlls/wshom.ocx/tests,[clean])
3287 WINE_CONFIG_DLL(wsnmp32,,[implib])
3288 WINE_CONFIG_TEST(dlls/wsnmp32/tests)
3289 WINE_CONFIG_DLL(wsock32,,[implib])
3290 WINE_CONFIG_DLL(wtsapi32,,[implib])
3291 WINE_CONFIG_DLL(wuapi,,[clean])
3292 WINE_CONFIG_DLL(wuaueng)
3293 WINE_CONFIG_DLL(xapofx1_1)
3294 WINE_CONFIG_DLL(xinput1_1)
3295 WINE_CONFIG_DLL(xinput1_2)
3296 WINE_CONFIG_DLL(xinput1_3,,[implib],[xinput])
3297 WINE_CONFIG_TEST(dlls/xinput1_3/tests)
3298 WINE_CONFIG_DLL(xinput1_4)
3299 WINE_CONFIG_DLL(xinput9_1_0)
3300 WINE_CONFIG_DLL(xmllite)
3301 WINE_CONFIG_TEST(dlls/xmllite/tests)
3302 WINE_CONFIG_DLL(xolehlp)
3303 WINE_CONFIG_DLL(xpsprint)
3304 WINE_CONFIG_DLL(xpssvcs)
3305 WINE_CONFIG_MAKEFILE([documentation],,[clean])
3306 WINE_CONFIG_MAKEFILE([fonts],,[clean,install-lib])
3307 WINE_CONFIG_MAKEFILE([include],,[clean,install-dev])
3308 WINE_CONFIG_MAKEFILE([libs/port])
3309 WINE_CONFIG_MAKEFILE([libs/wine],,[clean,install-dev,install-lib])
3310 WINE_CONFIG_MAKEFILE([libs/wpp])
3311 WINE_CONFIG_MAKEFILE([loader],,[clean,install-lib,manpage])
3312 WINE_CONFIG_PROGRAM(arp,,[install])
3313 WINE_CONFIG_PROGRAM(aspnet_regiis,,[install])
3314 WINE_CONFIG_PROGRAM(attrib,,[install,po])
3315 WINE_CONFIG_PROGRAM(cabarc,,[install])
3316 WINE_CONFIG_PROGRAM(cacls,,[install])
3317 WINE_CONFIG_PROGRAM(clock,,[install,po])
3318 WINE_CONFIG_PROGRAM(cmd,,[install,po])
3319 WINE_CONFIG_TEST(programs/cmd/tests)
3320 WINE_CONFIG_PROGRAM(conhost,,[install])
3321 WINE_CONFIG_PROGRAM(control,,[install])
3322 WINE_CONFIG_PROGRAM(cscript,,[install])
3323 WINE_CONFIG_PROGRAM(dxdiag,,[install,po])
3324 WINE_CONFIG_PROGRAM(eject,,[install])
3325 WINE_CONFIG_PROGRAM(expand,,[install])
3326 WINE_CONFIG_PROGRAM(explorer,,[install,po])
3327 WINE_CONFIG_PROGRAM(extrac32,,[install])
3328 WINE_CONFIG_PROGRAM(findstr,,[install])
3329 WINE_CONFIG_PROGRAM(hh,,[install])
3330 WINE_CONFIG_PROGRAM(hostname,,[install,po])
3331 WINE_CONFIG_PROGRAM(icinfo,,[install])
3332 WINE_CONFIG_PROGRAM(iexplore,,[install])
3333 WINE_CONFIG_PROGRAM(ipconfig,,[install,po])
3334 WINE_CONFIG_PROGRAM(lodctr,,[install])
3335 WINE_CONFIG_PROGRAM(mofcomp,,[install])
3336 WINE_CONFIG_PROGRAM(mshta,,[install])
3337 WINE_CONFIG_PROGRAM(msiexec,,[install,installbin,manpage])
3338 WINE_CONFIG_PROGRAM(net,,[install,po])
3339 WINE_CONFIG_PROGRAM(netsh,,[install])
3340 WINE_CONFIG_PROGRAM(netstat,,[install,po])
3341 WINE_CONFIG_PROGRAM(ngen,,[install])
3342 WINE_CONFIG_PROGRAM(notepad,,[install,installbin,manpage,po])
3343 WINE_CONFIG_PROGRAM(oleview,,[install,po])
3344 WINE_CONFIG_PROGRAM(ping,,[install])
3345 WINE_CONFIG_PROGRAM(plugplay,,[install])
3346 WINE_CONFIG_PROGRAM(presentationfontcache,,[install])
3347 WINE_CONFIG_PROGRAM(progman,,[install,po])
3348 WINE_CONFIG_PROGRAM(reg,,[install,po])
3349 WINE_CONFIG_PROGRAM(regasm,,[install])
3350 WINE_CONFIG_PROGRAM(regedit,,[install,installbin,manpage,po])
3351 WINE_CONFIG_TEST(programs/regedit/tests)
3352 WINE_CONFIG_PROGRAM(regsvcs,,[install])
3353 WINE_CONFIG_PROGRAM(regsvr32,,[install,installbin,manpage])
3354 WINE_CONFIG_PROGRAM(rpcss,,[clean,install])
3355 WINE_CONFIG_PROGRAM(rundll.exe16,enable_win16,[install])
3356 WINE_CONFIG_PROGRAM(rundll32,,[install])
3357 WINE_CONFIG_PROGRAM(sc,,[install])
3358 WINE_CONFIG_PROGRAM(schtasks,,[install])
3359 WINE_CONFIG_PROGRAM(secedit,,[install])
3360 WINE_CONFIG_PROGRAM(servicemodelreg,,[install])
3361 WINE_CONFIG_PROGRAM(services,,[clean,install])
3362 WINE_CONFIG_TEST(programs/services/tests)
3363 WINE_CONFIG_PROGRAM(spoolsv,,[install])
3364 WINE_CONFIG_PROGRAM(start,,[install,po])
3365 WINE_CONFIG_PROGRAM(svchost,,[install])
3366 WINE_CONFIG_PROGRAM(taskkill,,[install,po])
3367 WINE_CONFIG_PROGRAM(tasklist,,[install])
3368 WINE_CONFIG_PROGRAM(taskmgr,,[install,po])
3369 WINE_CONFIG_PROGRAM(termsv,,[install])
3370 WINE_CONFIG_PROGRAM(uninstaller,,[install,po])
3371 WINE_CONFIG_PROGRAM(unlodctr,,[install])
3372 WINE_CONFIG_PROGRAM(view,,[install,po])
3373 WINE_CONFIG_PROGRAM(wineboot,,[install,installbin,manpage,po])
3374 WINE_CONFIG_PROGRAM(winebrowser,,[install])
3375 WINE_CONFIG_PROGRAM(winecfg,,[install,installbin,manpage,po])
3376 WINE_CONFIG_PROGRAM(wineconsole,,[install,installbin,manpage,po])
3377 WINE_CONFIG_PROGRAM(winedbg,,[install,installbin,manpage,po])
3378 WINE_CONFIG_PROGRAM(winedevice,,[install])
3379 WINE_CONFIG_PROGRAM(winefile,,[install,installbin,manpage,po])
3380 WINE_CONFIG_PROGRAM(winemenubuilder,,[install])
3381 WINE_CONFIG_PROGRAM(winemine,,[install,installbin,manpage,po])
3382 WINE_CONFIG_PROGRAM(winemsibuilder,,[install])
3383 WINE_CONFIG_PROGRAM(winepath,,[install,installbin,manpage])
3384 WINE_CONFIG_PROGRAM(winetest,,[clean])
3385 WINE_CONFIG_PROGRAM(winevdm,enable_win16,[install])
3386 WINE_CONFIG_PROGRAM(winhelp.exe16,enable_win16,[install])
3387 WINE_CONFIG_PROGRAM(winhlp32,,[install,po])
3388 WINE_CONFIG_PROGRAM(winoldap.mod16,enable_win16,[install])
3389 WINE_CONFIG_PROGRAM(winver,,[install])
3390 WINE_CONFIG_PROGRAM(wmic,,[install,po])
3391 WINE_CONFIG_PROGRAM(wordpad,,[install,po])
3392 WINE_CONFIG_PROGRAM(write,,[install,po])
3393 WINE_CONFIG_PROGRAM(wscript,,[clean,install])
3394 WINE_CONFIG_TEST(programs/wscript/tests)
3395 WINE_CONFIG_PROGRAM(wusa,,[install])
3396 WINE_CONFIG_PROGRAM(xcopy,,[install,po])
3397 WINE_CONFIG_TEST(programs/xcopy/tests)
3398 WINE_CONFIG_MAKEFILE([server],,[clean,install-lib,manpage])
3399 WINE_CONFIG_TOOL(tools,[clean,install-dev,install-lib,manpage])
3400 WINE_CONFIG_TOOL(tools/widl,[clean,install-dev,manpage])
3401 WINE_CONFIG_TOOL(tools/winebuild,[clean,install-dev,manpage])
3402 WINE_CONFIG_TOOL(tools/winedump,[clean,install-dev,manpage])
3403 WINE_CONFIG_TOOL(tools/winegcc,[clean,install-dev,manpage])
3404 WINE_CONFIG_TOOL(tools/wmc,[clean,install-dev,manpage])
3405 WINE_CONFIG_TOOL(tools/wrc,[clean,install-dev,manpage])
3406
3407 AC_SUBST([LINGUAS],["\
3408 ar \
3409 bg \
3410 ca \
3411 cs \
3412 da \
3413 de \
3414 el \
3415 en \
3416 en_US \
3417 eo \
3418 es \
3419 fa \
3420 fi \
3421 fr \
3422 he \
3423 hi \
3424 hr \
3425 hu \
3426 it \
3427 ja \
3428 ko \
3429 lt \
3430 ml \
3431 nb_NO \
3432 nl \
3433 or \
3434 pa \
3435 pl \
3436 pt_BR \
3437 pt_PT \
3438 rm \
3439 ro \
3440 ru \
3441 sk \
3442 sl \
3443 sr_RS@cyrillic \
3444 sr_RS@latin \
3445 sv \
3446 te \
3447 th \
3448 tr \
3449 uk \
3450 wa \
3451 zh_CN \
3452 zh_TW"])
3453
3454 dnl End of auto-generated output commands
3455
3456 AC_CONFIG_COMMANDS([Makefile], [wine_fn_output_makefile Makefile],
3457 [wine_fn_output_makefile ()
3458 {
3459     cat Make.tmp - <<\_WINE_EOF >\$tmp/makefile && mv -f \$tmp/makefile \$[]1 && rm -f Make.tmp && return
3460 `cat $wine_rules_file`
3461 _WINE_EOF
3462     AS_ERROR([could not create Makefile])
3463 }])
3464
3465 AC_CONFIG_FILES([Make.tmp:Make.vars.in:Makefile.in])
3466
3467 dnl Some final makefile rules
3468
3469 if test "x$enable_maintainer_mode" = xyes
3470 then
3471     WINE_APPEND_RULE(
3472 [configure: configure.ac aclocal.m4
3473         autoconf --warnings=all
3474 include/config.h.in: include/stamp-h.in
3475 include/stamp-h.in: configure.ac aclocal.m4
3476         autoheader --warnings=all
3477         @echo timestamp > \$[@]])
3478 fi
3479
3480 if test "x$with_gettextpo" = xyes
3481 then
3482     test "$srcdir" = . || AC_MSG_ERROR([Rebuilding po files is not supported for out of tree builds.])
3483     WINE_APPEND_RULE(
3484 [ALL_POT_FILES =$ALL_POT_FILES
3485 \$(LINGUAS:%=po/%.po): po/wine.pot
3486         msgmerge --previous -q \$[@] po/wine.pot | msgattrib --no-obsolete -o \$[@].new && mv \$[@].new \$[@]
3487 po/wine.pot: \$(ALL_POT_FILES)
3488         msgcat -o \$[@] \$(ALL_POT_FILES)])
3489 fi
3490
3491 if test "$MSGFMT" != false
3492 then
3493     AC_SUBST([PORCFLAGS],["--po-dir=\$(top_builddir)/po"])
3494     WINE_APPEND_RULE(
3495 [__builddeps__: \$(ALL_MO_FILES)
3496 clean::
3497         \$(RM) \$(ALL_MO_FILES)])
3498
3499     posrc="po"
3500     test "$srcdir" = . || posrc="$srcdir/po"
3501     for i in $LINGUAS
3502     do
3503         WINE_APPEND_RULE(
3504 [po/$i.mo: $posrc/$i.po
3505         \$(MSGFMT) -o \$@ $posrc/$i.po])
3506     done
3507 else
3508     LINGUAS=
3509 fi
3510
3511 if test "x$enable_tools" != xno
3512 then
3513     AC_CONFIG_COMMANDS([tools],[AS_MKDIR_P(tools)])
3514     WINE_APPEND_RULE(
3515 [tools/makedep$ac_exeext: tools/makedep.c include/config.h
3516         \$(CC) -Iinclude -I$srcdir/include \$(ALLCFLAGS) -o \$@ $srcdir/tools/makedep.c \$(LDFLAGS)
3517 clean:: __clean__
3518         \$(RM) tools/makedep$ac_exeext])
3519 else
3520     WINE_APPEND_RULE(
3521 [\$(MAKEDEP):
3522         @echo \"You need to run make in $TOOLSDIR first\" && false])
3523 fi
3524
3525 if test -n "$with_wine64"
3526 then
3527     WINE_APPEND_RULE(
3528 [all: fonts server tools $with_wine64/loader/wine $with_wine64/loader/wine-preloader
3529 fonts server tools:
3530         \$(RM) \$[@] && \$(LN_S) $with_wine64/\$[@] \$[@]
3531 $with_wine64/loader/wine:
3532         \$(RM) \$[@] && \$(LN_S) $ac_pwd/loader/wine \$[@]
3533 $with_wine64/loader/wine-preloader:
3534         \$(RM) \$[@] && \$(LN_S) $ac_pwd/loader/wine-preloader \$[@]
3535 clean::
3536         \$(RM) fonts server tools $with_wine64/loader/wine $with_wine64/loader/wine-preloader])
3537 else
3538     AS_VAR_APPEND([LOADER_RULES],["
3539 all: wine.inf
3540
3541 wine.inf: wine.inf.in \$(top_builddir)/include/config.h
3542         LC_ALL=C sed -e 's,@PACKAGE_STRING@,$PACKAGE_STRING,g' \$(srcdir)/wine.inf.in >\$@ || (\$(RM) \$@ && false)
3543
3544 install install-lib:: wine.inf \$(DESTDIR)\$(datadir)/wine install-man-pages
3545         \$(INSTALL_DATA) wine.inf \$(DESTDIR)\$(datadir)/wine/wine.inf
3546         \$(INSTALL_DATA) \$(srcdir)/l_intl.nls \$(DESTDIR)\$(datadir)/wine/l_intl.nls
3547
3548 uninstall::
3549         \$(RM) \$(DESTDIR)\$(datadir)/wine/wine.inf \$(DESTDIR)\$(datadir)/wine/l_intl.nls
3550 "])
3551 fi
3552
3553 AS_ECHO(" done") >&AS_MESSAGE_FD
3554 AC_OUTPUT
3555
3556 if test "$no_create" = "yes"
3557 then
3558   exit 0
3559 fi
3560
3561 WINE_PRINT_MESSAGES
3562
3563 AS_ECHO("
3564 $as_me: Finished.  Do '${ac_make}' to compile Wine.
3565 ") >&AS_MESSAGE_FD
3566
3567 dnl Local Variables:
3568 dnl comment-start: "dnl "
3569 dnl comment-end: ""
3570 dnl comment-start-skip: "\\bdnl\\b\\s *"
3571 dnl compile-command: "autoreconf --warnings=all"
3572 dnl End: