| blob | 996a3d70882f5913e7642773c6ec4e7302a31918 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
19 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
20 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
25 if test "x$enable_win16" = "xno"
26 then
27 WIN16_FILES=""
28 WIN16_INSTALL=""
29 fi
30 if test "x$enable_debug" = "xno"
31 then
32 AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
33 fi
34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
35 then
36 AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
37 fi
39 dnl **** Check for some programs ****
41 AC_CANONICAL_HOST
42 AC_PROG_MAKE_SET
43 AC_PROG_CC
44 AC_PROG_CXX
45 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
46 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
48 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
49 [if test -z "$with_wine_tools"; then
50 if test "$cross_compiling" = "yes"; then
51 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
52 else
53 wine_cv_toolsdir="\$(TOPOBJDIR)"
54 fi
55 elif test -d "$with_wine_tools/tools/winebuild"; then
56 case $with_wine_tools in
57 /*) wine_cv_toolsdir="$with_wine_tools" ;;
58 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
59 esac
60 else
61 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
62 fi])
63 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
65 AC_PATH_XTRA
66 AC_PROG_YACC
67 AC_PROG_LEX
69 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
70 dnl **** without one present.
71 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
72 if test "$XYACC" = "none"
73 then
74 AC_MSG_ERROR([no suitable bison/yacc found. Please install the 'bison' package.])
75 fi
76 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
77 if test "$XLEX" = "none"
78 then
79 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
80 fi
82 AC_CHECK_TOOLS(AS,[gas as],as)
83 AC_CHECK_TOOL(LD,ld,ld)
84 AC_CHECK_TOOL(AR,ar,ar)
85 AC_PROG_RANLIB
86 AC_CHECK_TOOL(STRIP,strip,strip)
87 AC_CHECK_TOOL(WINDRES,windres,false)
88 AC_PROG_LN_S
89 WINE_PROG_LN
90 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
91 AC_PROG_INSTALL
92 dnl Prepend src dir to install path dir if it's a relative path
93 case "$INSTALL" in
94 [[\\/$]]* | ?:[[\\/]]* ) ;;
95 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
96 esac
98 dnl Check for lint
99 AC_CHECK_PROGS(LINT, lclint lint)
100 if test "$LINT" = "lint"
101 then
102 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
103 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
104 fi
105 AC_SUBST(LINT)
106 AC_SUBST(LINTFLAGS)
108 dnl Check for db2html
109 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
110 AC_SUBST(DB2HTML)
112 dnl Check for db2pdf
113 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
114 AC_SUBST(DB2PDF)
116 dnl Check for db2ps
117 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
118 AC_SUBST(DB2PS)
120 dnl Check for db2txt
121 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
122 AC_SUBST(DB2TXT)
124 dnl **** Check for some libraries ****
126 dnl Check for -lm
127 AC_CHECK_LIB(m,sqrt)
128 dnl Check for -li386 for NetBSD and OpenBSD
129 AC_CHECK_LIB(i386,i386_set_ldt)
130 dnl Check for -lossaudio for NetBSD
131 AC_CHECK_LIB(ossaudio,_oss_ioctl)
132 dnl Check for -lw for Solaris
133 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
134 dnl Check for -lnsl for Solaris
135 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
136 dnl Check for -lsocket for Solaris
137 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
138 dnl Check for -lresolv for Solaris
139 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
140 dnl Check for -lxpg4 for FreeBSD
141 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
142 dnl Check for -lpoll for Mac OS X/Darwin
143 AC_CHECK_LIB(poll,poll)
144 dnl Check for -lpthread
145 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
147 JPEGLIB=""
148 AC_SUBST(JPEGLIB)
149 AC_CHECK_HEADERS(jpeglib.h,
150 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
151 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
152 JPEGLIB="-ljpeg"
153 )
154 )
156 AC_SUBST(GIFLIB,"")
157 AC_CHECK_HEADERS(gif_lib.h,
158 AC_CHECK_LIB(ungif,DGifOpen,
159 [AC_DEFINE(HAVE_LIBGIF,1,[Define if you have libgif/libungif including devel headers])
160 GIFLIB="-lungif"],
161 [AC_CHECK_LIB(gif,DGifOpen,
162 [AC_DEFINE(HAVE_LIBGIF,1)
163 GIFLIB="-lgif"])]))
165 AC_SUBST(XLIB)
166 AC_SUBST(XFILES)
167 XFILES=""
168 AC_SUBST(OPENGLFILES)
169 OPENGLFILES=""
170 AC_SUBST(GLU32FILES)
171 GLU32FILES=""
172 AC_SUBST(OPENGL_LIBS)
173 OPENGL_LIBS=""
174 if test "$have_x" = "yes"
175 then
176 XLIB="-lXext -lX11"
177 ac_save_CPPFLAGS="$CPPFLAGS"
178 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
180 dnl *** All of the following tests require X11/Xlib.h
181 AC_CHECK_HEADERS(X11/Xlib.h,
182 [
183 AC_CHECK_HEADERS([X11/XKBlib.h \
184 X11/Xutil.h \
185 X11/extensions/shape.h \
186 X11/extensions/XInput.h \
187 X11/extensions/XShm.h \
188 X11/extensions/Xrandr.h \
189 X11/extensions/Xrender.h \
190 X11/extensions/Xvlib.h \
191 X11/extensions/xf86dga.h \
192 X11/extensions/xf86vmode.h],,,
193 [#include <X11/Xlib.h>
194 #ifdef HAVE_X11_XUTIL_H
195 # include <X11/Xutil.h>
196 #endif])
198 dnl *** Check for X keyboard extension
199 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
200 then
201 AC_CHECK_LIB(X11, XkbQueryExtension,
202 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
203 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
204 fi
206 dnl *** Check for X Shm extension
207 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
208 then
209 AC_CHECK_LIB(Xext, XShmQueryExtension,
210 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
211 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
212 fi
214 dnl *** Check for X shape extension
215 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
216 then
217 AC_CHECK_LIB(Xext,XShapeQueryExtension,
218 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
219 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
220 fi
222 dnl *** Check for XFree86 DGA / DGA 2.0 extension
223 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
224 then
225 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
226 [ dnl *** If found...
227 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
228 [Define if you have the Xxf86dga library version 2])
229 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
230 ],
231 [ dnl *** If not found, look for XF86DGAQueryExtension()
232 dnl *** instead (DGA 2.0 not found)...
233 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
234 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
235 [Define if you have the Xxf86dga library version 1])
236 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
237 ],,
238 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
239 )
240 ],
241 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
242 fi
244 dnl *** Check for XFree86 VMODE extension
245 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
246 then
247 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
248 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
249 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
250 ],,
251 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
252 fi
254 dnl *** Check for X RandR extension
255 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
256 then
257 AC_CHECK_LIB(Xrandr, XRRSetScreenConfigAndRate,
258 [ AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])
259 X_PRE_LIBS="$X_PRE_LIBS -lXrandr -lXrender"
260 ],,
261 $X_LIBS -lXrender -lXext -lX11 $X_EXTRA_LIBS)
262 fi
264 dnl *** Check for XVideo extension supporting XvImages
265 if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
266 then
267 AC_CHECK_LIB(Xv, XvShmCreateImage,
268 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
269 X_PRE_LIBS="$X_PRE_LIBS -lXv"
270 ],,
271 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
272 fi
273 ]
274 ) dnl *** End of X11/Xlib.h check
276 dnl Check for the presence of OpenGL
277 if test "x$with_opengl" != "xno"
278 then
279 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
280 then
281 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
282 This prevents linking to OpenGL. Delete the file and restart configure.])
283 fi
285 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
286 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
287 then
288 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
289 dnl Check for some problems due to old Mesa versions
290 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
291 AC_TRY_COMPILE(
292 [#include <GL/gl.h>],
293 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
294 [wine_cv_opengl_version_OK="yes"],
295 [wine_cv_opengl_version_OK="no"]
296 )
297 )
299 if test "$wine_cv_opengl_version_OK" = "yes"
300 then
301 dnl Check for the presence of the library
302 AC_CHECK_LIB(GL,glXCreateContext,
303 OPENGL_LIBS="-lGL"
304 ,,
305 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
307 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
308 then
309 OPENGLFILES='$(OPENGLFILES)'
310 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
312 AC_CHECK_LIB(GL,glXGetProcAddressARB,
313 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
314 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
315 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
317 if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
318 then
319 AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
320 [AC_TRY_COMPILE([#include <GL/gl.h>
321 #ifdef HAVE_GL_GLEXT_H
322 # include <GL/glext.h>
323 #endif
324 ],
325 [PFNGLCOLORTABLEEXTPROC test_proc;],
326 [wine_cv_extension_prototypes="yes"],
327 [wine_cv_extension_prototypes="no"]
328 )]
329 )
330 if test "$wine_cv_extension_prototypes" = "yes"
331 then
332 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
333 [Define if the OpenGL headers define extension typedefs])
334 fi
335 fi
337 fi
338 dnl Check for GLU32 library.
339 AC_CHECK_LIB(GLU,gluLookAt,
340 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
341 GLU32FILES='$(GLU32FILES)']
342 ,,
343 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
344 )
345 fi
347 dnl Check for glut32 library.
348 AC_CHECK_LIB(glut,glutMainLoop,
349 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
350 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
351 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
352 fi
353 fi
355 dnl **** Check for NAS ****
356 AC_SUBST(NASLIBS,"")
357 AC_CHECK_HEADERS(audio/audiolib.h,
358 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
359 AC_CHECK_LIB(audio,AuCreateFlow,
360 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
361 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
362 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
364 CPPFLAGS="$ac_save_CPPFLAGS"
365 XFILES='$(XFILES)'
366 else
367 XLIB=""
368 X_CFLAGS=""
369 X_LIBS=""
370 fi
372 dnl **** Check which curses lib to use ***
373 CURSESLIBS=""
374 if test "x$with_curses" != "xno"
375 then
376 AC_CHECK_HEADERS(ncurses.h,
377 [AC_CHECK_LIB(ncurses,waddch,
378 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
379 CURSESLIBS="-lncurses"],
380 [AC_CHECK_HEADERS(curses.h,
381 [AC_CHECK_LIB(curses,waddch,
382 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
383 CURSESLIBS="-lcurses"])])])])
384 saved_libs="$LIBS"
385 LIBS="$CURSESLIBS $LIBS"
386 AC_CHECK_FUNCS(getbkgd resizeterm)
387 LIBS="$saved_libs"
388 fi
389 AC_SUBST(CURSESLIBS)
391 dnl **** Check for SANE ****
392 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
393 if test "$sane_devel" = "no"
394 then
395 SANELIBS=""
396 SANEINCL=""
397 else
398 SANELIBS="`$sane_devel --libs`"
399 SANEINCL="`$sane_devel --cflags`"
400 ac_save_CPPFLAGS="$CPPFLAGS"
401 ac_save_LIBS="$LIBS"
402 CPPFLAGS="$CPPFLAGS $SANEINCL"
403 LIBS="$LIBS $SANELIBS"
404 AC_CHECK_HEADER(sane/sane.h,
405 [AC_CHECK_LIB(sane,sane_open,
406 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
407 [SANELIBS=""
408 SANEINCL=""])],
409 [SANELIBS=""
410 SANEINCL=""])
411 LIBS="$ac_save_LIBS"
412 CPPFLAGS="$ac_save_CPPFLAGS"
413 fi
414 AC_SUBST(SANELIBS)
415 AC_SUBST(SANEINCL)
417 dnl **** Check for the ICU library ****
418 AC_CHECK_HEADERS(unicode/ubidi.h)
419 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
420 then
421 saved_libs="$LIBS"
422 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
423 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libicuuc.a}"
424 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libicudata.a}"
425 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
426 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
427 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
428 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")])
429 LIBS="$saved_libs"
430 fi
432 dnl **** Check for FreeType 2 ****
433 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
434 if test "$ft_lib" = "no"
435 then
436 FREETYPEINCL=""
437 wine_cv_msg_freetype=no
438 else
439 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
440 if test "$ft_devel" = "no"
441 then
442 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
443 if test "$ft_devel2" = "freetype2-config"
444 then
445 ft_devel=$ft_devel2
446 fi
447 fi
448 if test "$ft_devel" = "no"
449 then
450 FREETYPEINCL=""
451 wine_cv_msg_freetype=yes
452 else
453 FREETYPEINCL=`$ft_devel --cflags`
454 ac_save_CPPFLAGS="$CPPFLAGS"
455 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
456 AC_CHECK_HEADERS(ft2build.h \
457 freetype/freetype.h \
458 freetype/ftglyph.h \
459 freetype/tttables.h \
460 freetype/ftnames.h \
461 freetype/ftsnames.h \
462 freetype/ttnameid.h \
463 freetype/ftoutln.h \
464 freetype/internal/sfnt.h,,,
465 [#if HAVE_FT2BUILD_H
466 #include <ft2build.h>
467 #endif])
468 AC_TRY_CPP([#include <ft2build.h>
469 #include <freetype/fttrigon.h>],
470 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
471 [Define if you have the <freetype/fttrigon.h> header file.])
472 wine_cv_fttrigon=yes],
473 wine_cv_fttrigon=no)
474 CPPFLAGS="$ac_save_CPPFLAGS"
475 dnl Check that we have at least freetype/freetype.h
476 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
477 then
478 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
479 wine_cv_msg_freetype=no
480 else
481 FREETYPEINCL=""
482 wine_cv_msg_freetype=yes
483 fi
484 fi
485 fi
486 AC_SUBST(FREETYPEINCL)
488 dnl **** Check for parport (currently Linux only) ****
489 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
490 AC_TRY_COMPILE(
491 [#include <linux/ppdev.h>],
492 [ioctl (1,PPCLAIM,0)],
493 [ac_cv_c_ppdev="yes"],
494 [ac_cv_c_ppdev="no"])
495 )
496 if test "$ac_cv_c_ppdev" = "yes"
497 then
498 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
499 fi
501 dnl **** Check for va_copy ****
502 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
503 AC_TRY_LINK(
504 [#include <stdarg.h>],
505 [va_list ap1, ap2;
506 va_copy(ap1,ap2);
507 ],
508 [ac_cv_c_va_copy="yes"],
509 [ac_cv_c_va_copy="no"])
510 )
511 if test "$ac_cv_c_va_copy" = "yes"
512 then
513 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
514 fi
515 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
516 AC_TRY_LINK(
517 [#include <stdarg.h>],
518 [va_list ap1, ap2;
519 __va_copy(ap1,ap2);
520 ],
521 [ac_cv_c___va_copy="yes"],
522 [ac_cv_c___va_copy="no"])
523 )
524 if test "$ac_cv_c___va_copy" = "yes"
525 then
526 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
527 fi
529 dnl **** Check for sigsetjmp ****
530 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
531 AC_TRY_LINK(
532 [#include <setjmp.h>],
533 [sigjmp_buf buf;
534 sigsetjmp( buf, 1 );
535 siglongjmp( buf, 1 );],
536 [ac_cv_c_sigsetjmp="yes"],
537 [ac_cv_c_sigsetjmp="no"])
538 )
539 if test "$ac_cv_c_sigsetjmp" = "yes"
540 then
541 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
542 fi
544 dnl **** Check for pthread_rwlock_t ****
545 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
546 #include <pthread.h>])
548 dnl **** Check for pthread_getattr_np ****
549 ac_save_LIBS="$LIBS"
550 LIBS="$LIBS $LIBPTHREAD"
551 AC_CHECK_FUNCS(pthread_getattr_np)
552 LIBS="$ac_save_LIBS"
554 dnl **** Check for Open Sound System ****
555 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
557 AC_CACHE_CHECK([for Open Sound System],
558 ac_cv_c_opensoundsystem,
559 AC_TRY_COMPILE([
560 #if defined(HAVE_SYS_SOUNDCARD_H)
561 #include <sys/soundcard.h>
562 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
563 #include <machine/soundcard.h>
564 #elif defined(HAVE_SOUNDCARD_H)
565 #include <soundcard.h>
566 #endif
567 ],[
569 /* check for one of the Open Sound System specific SNDCTL_ defines */
570 #if !defined(SNDCTL_DSP_STEREO)
571 #error No open sound system
572 #endif
573 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
575 if test "$ac_cv_c_opensoundsystem" = "yes"
576 then
577 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
578 fi
580 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
581 ac_cv_c_opensoundsystem_midi,
582 AC_TRY_COMPILE([
583 #if defined(HAVE_SYS_SOUNDCARD_H)
584 #include <sys/soundcard.h>
585 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
586 #include <machine/soundcard.h>
587 #elif defined(HAVE_SOUNDCARD_H)
588 #include <soundcard.h>
589 #endif
590 ],[
592 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
593 #if !defined(SNDCTL_SEQ_SYNC)
594 #error No open sound system MIDI interface
595 #endif
596 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
598 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
599 then
600 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
601 fi
603 dnl **** Check for aRts Sound Server ****
604 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
605 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
606 then
607 ARTSC_CFLAGS=""
608 for i in `$ARTSCCONFIG --cflags`
609 do
610 case "$i" in
611 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
612 esac
613 done
614 ARTSC_LIBS=`$ARTSCCONFIG --libs`
615 save_CFLAGS="$CFLAGS"
616 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
617 AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
618 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
619 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
620 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
621 CFLAGS="$save_CFLAGS"
622 fi
624 dnl **** Check for ALSA ****
625 AC_SUBST(ALSALIBS,"")
626 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
627 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
628 then
629 AC_CHECK_LIB(asound,snd_pcm_open,
630 AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
631 ALSALIBS="-lasound")
632 fi
634 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
636 AC_SUBST(AUDIOIOLIBS,"")
637 AC_CHECK_HEADERS(libaudioio.h,
638 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
639 [AUDIOIOLIBS="-laudioio"
640 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
642 dnl **** Check for capi4linux ****
644 AC_CHECK_HEADERS(capi20.h,[
645 AC_CHECK_HEADERS(linux/capi.h,[
646 AC_CHECK_LIB(capi20,capi20_register,[
647 AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
648 AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
649 ])
650 ])
651 ])
653 dnl **** Check for broken glibc mmap64 ****
655 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
656 AC_TRY_RUN([
657 #define _FILE_OFFSET_BITS 64
658 #include <stdio.h>
659 #include <unistd.h>
660 #include <fcntl.h>
661 #include <sys/mman.h>
662 #include <errno.h>
664 int main(int argc,char **argv) {
665 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
666 if (fd == -1) exit(1);
668 unlink("conftest.map");
670 write(fd,"test",4);
672 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
673 (errno == EINVAL)
674 ) {
675 exit(1);
676 }
677 close(fd);
678 fprintf(stderr,"success!\n");
679 exit(0);
680 }
682 ],
683 ac_cv_mmap64_works="yes",
684 ac_cv_mmap64_works="no",
685 ac_cv_mmap64_works="no") )
687 if test "$ac_cv_mmap64_works" = "yes"
688 then
689 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
690 fi
692 dnl **** Check for gcc specific options ****
694 AC_SUBST(EXTRACFLAGS,"")
695 if test "x${GCC}" = "xyes"
696 then
697 EXTRACFLAGS="-Wall -pipe"
699 dnl Check for strength-reduce bug
700 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
701 AC_TRY_RUN([
702 int L[[4]] = {0,1,2,3};
703 int main(void) {
704 static int Array[[3]];
705 unsigned int B = 3;
706 int i;
707 for(i=0; i<B; i++) Array[[i]] = i - 3;
708 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
709 L[[i]] = 4;
711 exit( Array[[1]] != -2 || L[[2]] != 3);
712 }],
713 ac_cv_c_gcc_strength_bug="no",
714 ac_cv_c_gcc_strength_bug="yes",
715 ac_cv_c_gcc_strength_bug="yes") )
716 if test "$ac_cv_c_gcc_strength_bug" = "yes"
717 then
718 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
719 fi
721 dnl Check for -fshort-wchar
722 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
723 [WINE_TRY_CFLAGS([-fshort-wchar],
724 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
725 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
726 then
727 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
728 fi
730 dnl Check for -mpreferred-stack-boundary
731 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
732 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
733 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
734 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
735 then
736 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
737 fi
739 dnl Check for -fno-strict-aliasing
740 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
741 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
742 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
743 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
744 then
745 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
746 fi
748 dnl Check for -gstabs+ option
749 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
750 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
751 if test "$ac_cv_c_gcc_gstabs" = "yes"
752 then
753 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
754 fi
756 dnl Check for noisy string.h
757 saved_CFLAGS="$CFLAGS"
758 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
759 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
760 AC_TRY_COMPILE([#include <string.h>],[],
761 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
762 CFLAGS="$saved_CFLAGS"
763 if test "$ac_cv_c_string_h_warnings" = "no"
764 then
765 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
766 fi
767 fi
769 dnl **** Check how to define a function in assembly code ****
771 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
772 WINE_TRY_ASM_LINK(
773 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
774 ac_cv_asm_func_def=".def",
775 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
776 ac_cv_asm_func_def=".type @function",
777 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
778 ac_cv_asm_func_def=".type 2",
779 ac_cv_asm_func_def="unknown")])]))
781 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
782 case "$ac_cv_asm_func_def" in
783 ".def")
784 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
785 ".type @function")
786 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
787 ".type 2")
788 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
789 *)
790 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
791 esac
793 dnl **** Check for underscore on external symbols ****
795 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
796 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
797 [extern int ac_test;],
798 [if (ac_test) return 1],
799 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
801 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
802 if test "$ac_cv_c_extern_prefix" = "yes"
803 then
804 AC_DEFINE([__ASM_NAME(name)], ["_" name])
805 else
806 AC_DEFINE([__ASM_NAME(name)], [name])
807 fi
809 dnl **** Check how to do strings in assembler ****
811 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
812 WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
813 WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
814 WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
815 AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
817 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
818 [Define to the assembler keyword used to specify an ASCII string])
820 dnl **** Check for .short in assembler ****
822 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
823 WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
824 WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
825 AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
827 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
828 [Define to the assembler keyword used to specify a word value])
830 dnl **** Check for working dll ****
832 AC_SUBST(DLLEXT,"")
833 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
834 AC_SUBST(DLLIBS,"")
835 AC_SUBST(LDSHARED,"")
836 AC_SUBST(LDDLLFLAGS,"")
837 AC_SUBST(LIBEXT,"so")
838 AC_SUBST(IMPLIBEXT,"def")
840 case $host_os in
841 cygwin*|mingw32*)
842 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
843 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
844 if test "$DLLWRAP" = "false"; then
845 LIBEXT="a"
846 else
847 dnl FIXME - check whether dllwrap works correctly...
848 LIBEXT="dll"
849 fi
850 IMPLIBEXT="a"
851 ;;
852 *)
853 AC_CHECK_HEADERS(dlfcn.h,
854 [AC_CHECK_FUNCS(dlopen,,
855 [AC_CHECK_LIB(dl,dlopen,
856 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
857 DLLIBS="-ldl"],
858 [LIBEXT="a"])])],
859 [LIBEXT="a"])
861 if test "$LIBEXT" = "so"
862 then
863 DLLFLAGS="$DLLFLAGS -fPIC"
864 DLLEXT=".so"
865 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
866 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
867 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
868 if test "$ac_cv_c_dll_gnuelf" = "yes"
869 then
870 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
871 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
872 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
873 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
874 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
875 if test "$ac_cv_c_dll_zdefs" = "yes"
876 then
877 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
878 fi
880 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
881 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
882 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
883 if test "$ac_cv_c_dll_init_fini" = "yes"
884 then
885 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
886 fi
888 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
889 [echo '{ global: *; };' >conftest.map
890 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
891 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
892 rm -f conftest.map])
893 if test "$ac_cv_c_ld_version_scripts" = "yes"
894 then
895 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
896 fi
898 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
899 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
900 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
901 if test "$ac_cv_c_export_dynamic" = "yes"
902 then
903 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
904 fi
906 case $host_cpu in
907 *i[[3456789]]86*)
908 AC_CACHE_CHECK([whether we can relocate the executable to 0x00110000], ac_cv_ld_reloc_exec,
909 [saved_CFLAGS="$CFLAGS"
910 CFLAGS="$CFLAGS -Wl,--section-start,.interp=0x00110400"
911 AC_TRY_RUN([#include <unistd.h>
912 int main() { return (sbrk(32*1024*1024) == (void *)-1); }],
913 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no", ac_cv_ld_reloc_exec="no")
914 CFLAGS="$saved_CFLAGS"])
915 if test "$ac_cv_ld_reloc_exec" = "yes"
916 then
917 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x00110400"
918 fi
919 ;;
920 esac
922 else
923 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
924 [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
925 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
926 if test "$ac_cv_c_dll_unixware" = "yes"
927 then
928 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
929 LDDLLFLAGS="-Wl,-G,-B,symbolic"
931 else
932 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
933 [WINE_TRY_CFLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
934 if test "$ac_cv_c_dll_macho" = "yes"
935 then
936 LIBEXT="dylib"
937 LDDLLFLAGS="-bundle -flat_namespace -undefined suppress"
938 LDSHARED="\$(CC) -dynamiclib"
939 CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
940 fi
941 fi
942 fi
943 fi
945 dnl Check for cross compiler to build test programs
946 AC_SUBST(CROSSTEST,"")
947 if test "$cross_compiling" = "no"
948 then
949 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
950 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
951 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
952 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
953 fi
954 ;;
955 esac
957 if test "$LIBEXT" = "a"; then
958 AC_MSG_ERROR(
959 [could not find a way to build shared libraries.
960 It is currently not possible to build Wine without shared library
961 (.so) support to allow transparent switch between .so and .dll files.
962 If you are using Linux, you will need a newer binutils.]
963 )
964 fi
966 case $build_os in
967 cygwin*|mingw32*)
968 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
969 darwin*|macosx*)
970 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
971 *)
972 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
973 esac
975 dnl Mingw needs explicit msvcrt for linking libwine
976 case $host_os in
977 mingw32*)
978 AC_SUBST(CRTLIBS,"-lmsvcrt") ;;
979 esac
981 case $host_os in
982 linux*)
983 AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread")
984 AC_SUBST(MAIN_BINARY,"wine-glibc")
985 ;;
986 *)
987 AC_SUBST(WINE_BINARIES,"wine-kthread")
988 AC_SUBST(MAIN_BINARY,"wine-kthread")
989 ;;
990 esac
992 dnl **** Get the soname for libraries that we load dynamically ****
994 if test "$LIBEXT" = "so"
995 then
996 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
997 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
998 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
999 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1000 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1001 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1002 WINE_GET_SONAME(cups,cupsGetDefault)
1003 WINE_GET_SONAME(jack,jack_client_new)
1004 WINE_GET_SONAME(fontconfig,FcInit)
1005 WINE_GET_SONAME(ssl,SSL_library_init)
1006 WINE_GET_SONAME(crypto,BIO_new_socket)
1007 WINE_GET_SONAME(ncurses,waddch)
1008 WINE_GET_SONAME(curses,waddch)
1009 fi
1012 dnl **** Check for functions ****
1014 AC_FUNC_ALLOCA()
1015 AC_CHECK_FUNCS(\
1016 _lwp_create \
1017 _lwp_self \
1018 _pclose \
1019 _popen \
1020 _snprintf \
1021 _spawnvp \
1022 _stricmp \
1023 _strnicmp \
1024 _vsnprintf \
1025 chsize \
1026 clone \
1027 finite \
1028 fpclass \
1029 ftruncate \
1030 ftruncate64 \
1031 getnetbyaddr \
1032 getnetbyname \
1033 getopt_long \
1034 getpagesize \
1035 getprotobyname \
1036 getprotobynumber \
1037 getpwuid \
1038 getservbyport \
1039 gettid \
1040 gettimeofday \
1041 inet_network \
1042 lseek64 \
1043 lstat \
1044 memmove \
1045 mmap \
1046 pclose \
1047 popen \
1048 pread \
1049 pwrite \
1050 readlink \
1051 rfork \
1052 select \
1053 sendmsg \
1054 settimeofday \
1055 sigaltstack \
1056 snprintf \
1057 spawnvp \
1058 statfs \
1059 statvfs \
1060 strcasecmp \
1061 strerror \
1062 strncasecmp \
1063 tcgetattr \
1064 timegm \
1065 usleep \
1066 vfscanf \
1067 vsnprintf \
1068 wait4 \
1069 waitpid \
1070 )
1072 dnl **** Check for header files ****
1074 AC_CHECK_HEADERS(\
1075 arpa/inet.h \
1076 arpa/nameser.h \
1077 cups/cups.h \
1078 direct.h \
1079 elf.h \
1080 float.h \
1081 fontconfig/fontconfig.h \
1082 getopt.h \
1083 ieeefp.h \
1084 io.h \
1085 jack/jack.h \
1086 libio.h \
1087 libutil.h \
1088 link.h \
1089 linux/cdrom.h \
1090 linux/hdreg.h \
1091 linux/input.h \
1092 linux/ioctl.h \
1093 linux/joystick.h \
1094 linux/major.h \
1095 linux/param.h \
1096 linux/serial.h \
1097 linux/ucdrom.h \
1098 machine/cpu.h \
1099 netdb.h \
1100 netinet/in.h \
1101 netinet/in_systm.h \
1102 netinet/tcp.h \
1103 netinet/tcp_fsm.h \
1104 openssl/ssl.h \
1105 process.h \
1106 pthread.h \
1107 pty.h \
1108 pwd.h \
1109 regex.h \
1110 sched.h \
1111 scsi/sg.h \
1112 scsi/scsi.h \
1113 scsi/scsi_ioctl.h \
1114 socket.h \
1115 stdint.h \
1116 strings.h \
1117 sys/cdio.h \
1118 sys/elf32.h \
1119 sys/errno.h \
1120 sys/exec_elf.h \
1121 sys/file.h \
1122 sys/filio.h \
1123 sys/inttypes.h \
1124 sys/ioctl.h \
1125 sys/ipc.h \
1126 sys/link.h \
1127 sys/lwp.h \
1128 sys/mman.h \
1129 sys/modem.h \
1130 sys/msg.h \
1131 sys/param.h \
1132 sys/poll.h \
1133 sys/ptrace.h \
1134 sys/reg.h \
1135 sys/scsiio.h \
1136 sys/shm.h \
1137 sys/signal.h \
1138 sys/socket.h \
1139 sys/sockio.h \
1140 sys/statfs.h \
1141 sys/statvfs.h \
1142 sys/strtio.h \
1143 sys/syscall.h \
1144 sys/sysctl.h \
1145 sys/time.h \
1146 sys/times.h \
1147 sys/uio.h \
1148 sys/un.h \
1149 sys/v86.h \
1150 sys/v86intr.h \
1151 sys/vfs.h \
1152 sys/vm86.h \
1153 sys/wait.h \
1154 syscall.h \
1155 termios.h \
1156 unistd.h \
1157 utime.h \
1158 valgrind/memcheck.h
1159 )
1160 AC_HEADER_STAT()
1162 dnl **** Checks for headers that depend on other ones ****
1164 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1165 [#include <sys/types.h>
1166 #if HAVE_SYS_PARAM_H
1167 # include <sys/param.h>
1168 #endif])
1170 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1171 [#include <sys/types.h>
1172 #if HAVE_SYS_SOCKET_H
1173 # include <sys/socket.h>
1174 #endif])
1176 AC_CHECK_HEADERS([resolv.h],,,
1177 [#include <sys/types.h>
1178 #if HAVE_SYS_SOCKET_H
1179 # include <sys/socket.h>
1180 #endif
1181 #if HAVE_NETINET_IN_H
1182 # include <netinet/in.h>
1183 #endif
1184 #if HAVE_ARPA_NAMESER_H
1185 # include <arpa/nameser.h>
1186 #endif])
1188 AC_CHECK_HEADERS(netinet/ip.h,,,
1189 [#include <sys/types.h>
1190 #if HAVE_SYS_SOCKET_H
1191 # include <sys/socket.h>
1192 #endif
1193 #if HAVE_NETINET_IN_SYSTM_H
1194 # include <netinet/in_systm.h>
1195 #endif])
1197 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1199 dnl **** Check for IPX headers (currently Linux only) ****
1201 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1202 AC_TRY_COMPILE(
1203 [#include <sys/types.h>
1204 #ifdef HAVE_SYS_SOCKET_H
1205 # include <sys/socket.h>
1206 #endif
1207 #include <netipx/ipx.h>],
1208 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1209 [ac_cv_c_ipx_gnu="yes"],
1210 [ac_cv_c_ipx_gnu="no"])
1211 )
1212 if test "$ac_cv_c_ipx_gnu" = "yes"
1213 then
1214 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1215 fi
1217 if test "$ac_cv_c_ipx_gnu" = "no"
1218 then
1219 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1220 AC_TRY_COMPILE(
1221 [#include <sys/types.h>
1222 #ifdef HAVE_SYS_SOCKET_H
1223 # include <sys/socket.h>
1224 #endif
1225 #include <asm/types.h>
1226 #include <linux/ipx.h>],
1227 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1228 [ac_cv_c_ipx_linux="yes"],
1229 [ac_cv_c_ipx_linux="no"])
1230 )
1231 if test "$ac_cv_c_ipx_linux" = "yes"
1232 then
1233 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1234 fi
1235 fi
1237 dnl **** Check for types ****
1239 AC_C_CONST
1240 AC_C_INLINE
1241 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1243 AC_CACHE_CHECK([whether linux/input.h is for real],
1244 wine_cv_linux_input_h,
1245 AC_TRY_COMPILE([
1246 #include <linux/input.h>
1247 ] , [
1248 int foo = EVIOCGBIT(EV_ABS,42);
1249 int bar = BTN_PINKIE;
1250 int fortytwo = 42;
1251 ],
1252 wine_cv_linux_input_h=yes,
1253 wine_cv_linux_input_h=no,
1254 no
1255 )
1256 )
1257 if test "$wine_cv_linux_input_h" = "yes"
1258 then
1259 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1260 [Define if we have linux/input.h AND it contains the INPUT event API])
1261 fi
1264 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1265 wine_cv_linux_gethostbyname_r_6,
1266 AC_TRY_LINK([
1267 #include <netdb.h>
1268 ], [
1269 char *name=NULL;
1270 struct hostent he;
1271 struct hostent *result;
1272 char *buf=NULL;
1273 int bufsize=0;
1274 int res,errnr;
1275 char *addr=NULL;
1276 int addrlen=0;
1277 int addrtype=0;
1278 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1279 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1280 ],
1281 wine_cv_linux_gethostbyname_r_6=yes,
1282 wine_cv_linux_gethostbyname_r_6=no
1283 )
1284 )
1285 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1286 then
1287 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1288 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1289 fi
1291 if test "$ac_cv_header_linux_joystick_h" = "yes"
1292 then
1293 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1294 wine_cv_linux_joystick_22_api,
1295 AC_TRY_COMPILE([
1296 #include <sys/ioctl.h>
1297 #include <linux/joystick.h>
1299 struct js_event blub;
1300 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1301 #error "no 2.2 header"
1302 #endif
1303 ],/*empty*/,
1304 wine_cv_linux_joystick_22_api=yes,
1305 wine_cv_linux_joystick_22_api=no,
1306 wine_cv_linux_joystick_22_api=no
1307 )
1308 )
1309 if test "$wine_cv_linux_joystick_22_api" = "yes"
1310 then
1311 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1312 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1313 fi
1314 fi
1316 dnl **** statfs checks ****
1318 if test "$ac_cv_header_sys_vfs_h" = "yes"
1319 then
1320 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1321 wine_cv_sys_vfs_has_statfs,
1322 AC_TRY_COMPILE([
1323 #include <sys/types.h>
1324 #ifdef HAVE_SYS_PARAM_H
1325 # include <sys/param.h>
1326 #endif
1327 #include <sys/vfs.h>
1328 ],[
1329 struct statfs stfs;
1331 memset(&stfs,0,sizeof(stfs));
1332 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1333 )
1334 )
1335 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1336 then
1337 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1338 [Define if the struct statfs is defined by <sys/vfs.h>])
1339 fi
1340 fi
1342 if test "$ac_cv_header_sys_statfs_h" = "yes"
1343 then
1344 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1345 wine_cv_sys_statfs_has_statfs,
1346 AC_TRY_COMPILE([
1347 #include <sys/types.h>
1348 #ifdef HAVE_SYS_PARAM_H
1349 # include <sys/param.h>
1350 #endif
1351 #include <sys/statfs.h>
1352 ],[
1353 struct statfs stfs;
1354 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1355 )
1356 )
1357 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1358 then
1359 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1360 [Define if the struct statfs is defined by <sys/statfs.h>])
1361 fi
1362 fi
1364 if test "$ac_cv_header_sys_mount_h" = "yes"
1365 then
1366 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1367 wine_cv_sys_mount_has_statfs,
1368 AC_TRY_COMPILE([
1369 #include <sys/types.h>
1370 #ifdef HAVE_SYS_PARAM_H
1371 # include <sys/param.h>
1372 #endif
1373 #include <sys/mount.h>
1374 ],[
1375 struct statfs stfs;
1376 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1377 )
1378 )
1379 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1380 then
1381 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1382 [Define if the struct statfs is defined by <sys/mount.h>])
1383 fi
1384 fi
1386 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1388 dnl Check for statfs members
1389 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1390 [#include <sys/types.h>
1391 #ifdef HAVE_SYS_PARAM_H
1392 # include <sys/param.h>
1393 #endif
1394 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1395 # include <sys/mount.h>
1396 #else
1397 # ifdef STATFS_DEFINED_BY_SYS_VFS
1398 # include <sys/vfs.h>
1399 # else
1400 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1401 # include <sys/statfs.h>
1402 # endif
1403 # endif
1404 #endif])
1406 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1407 [#ifdef HAVE_SYS_STATVFS_H
1408 #include <sys/statvfs.h>
1409 #endif])
1411 dnl Check for socket structure members
1412 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1413 [#include <sys/types.h>
1414 #ifdef HAVE_SYS_SOCKET_H
1415 # include <sys/socket.h>
1416 #endif
1417 #ifdef HAVE_SYS_UN_H
1418 # include <sys/un.h>
1419 #endif])
1421 dnl Check for siginfo_t members
1422 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1424 dnl Check for struct option
1425 AC_CHECK_MEMBERS([struct option.name],,,
1426 [#ifdef HAVE_GETOPT_H
1427 #include <getopt.h>
1428 #endif])
1430 dnl Check for stat.st_blocks
1431 AC_CHECK_MEMBERS([struct stat.st_blocks])
1433 dnl *** check for the need to define platform-specific symbols
1435 case $host_cpu in
1436 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1437 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1438 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1439 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1440 esac
1442 case $host_vendor in
1443 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1444 esac
1446 dnl **** Generate output files ****
1448 AH_TOP([#define __WINE_CONFIG_H])
1450 WINE_CONFIG_EXTRA_DIR(controls)
1451 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1452 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1453 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1454 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1455 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1456 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1457 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1458 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1459 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1460 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1461 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1462 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1463 WINE_CONFIG_EXTRA_DIR(files)
1464 WINE_CONFIG_EXTRA_DIR(include/wine)
1465 WINE_CONFIG_EXTRA_DIR(misc)
1466 WINE_CONFIG_EXTRA_DIR(objects)
1467 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1468 WINE_CONFIG_EXTRA_DIR(windows)
1470 MAKE_RULES=Make.rules
1471 AC_SUBST_FILE(MAKE_RULES)
1473 MAKE_DLL_RULES=dlls/Makedll.rules
1474 AC_SUBST_FILE(MAKE_DLL_RULES)
1476 MAKE_TEST_RULES=dlls/Maketest.rules
1477 AC_SUBST_FILE(MAKE_TEST_RULES)
1479 MAKE_LIB_RULES=libs/Makelib.rules
1480 AC_SUBST_FILE(MAKE_LIB_RULES)
1482 MAKE_PROG_RULES=programs/Makeprog.rules
1483 AC_SUBST_FILE(MAKE_PROG_RULES)
1485 AC_CONFIG_FILES([
1486 Make.rules
1487 dlls/Makedll.rules
1488 dlls/Maketest.rules
1489 libs/Makelib.rules
1490 programs/Makeprog.rules
1491 Makefile
1492 dlls/Makefile
1493 dlls/advapi32/Makefile
1494 dlls/advapi32/tests/Makefile
1495 dlls/amstream/Makefile
1496 dlls/avicap32/Makefile
1497 dlls/avifil32/Makefile
1498 dlls/cabinet/Makefile
1499 dlls/capi2032/Makefile
1500 dlls/cfgmgr32/Makefile
1501 dlls/comcat/Makefile
1502 dlls/comctl32/Makefile
1503 dlls/comctl32/tests/Makefile
1504 dlls/commdlg/Makefile
1505 dlls/crtdll/Makefile
1506 dlls/crypt32/Makefile
1507 dlls/ctl3d/Makefile
1508 dlls/d3d8/Makefile
1509 dlls/d3d9/Makefile
1510 dlls/d3dim/Makefile
1511 dlls/d3dx8/Makefile
1512 dlls/dciman32/Makefile
1513 dlls/ddraw/Makefile
1514 dlls/ddraw/tests/Makefile
1515 dlls/devenum/Makefile
1516 dlls/dinput/Makefile
1517 dlls/dinput8/Makefile
1518 dlls/dmband/Makefile
1519 dlls/dmcompos/Makefile
1520 dlls/dmime/Makefile
1521 dlls/dmloader/Makefile
1522 dlls/dmscript/Makefile
1523 dlls/dmstyle/Makefile
1524 dlls/dmsynth/Makefile
1525 dlls/dmusic/Makefile
1526 dlls/dmusic32/Makefile
1527 dlls/dplay/Makefile
1528 dlls/dplayx/Makefile
1529 dlls/dpnhpast/Makefile
1530 dlls/dsound/Makefile
1531 dlls/dsound/tests/Makefile
1532 dlls/dswave/Makefile
1533 dlls/dxguid/Makefile
1534 dlls/gdi/Makefile
1535 dlls/gdi/tests/Makefile
1536 dlls/glu32/Makefile
1537 dlls/glut32/Makefile
1538 dlls/iccvid/Makefile
1539 dlls/icmp/Makefile
1540 dlls/ifsmgr.vxd/Makefile
1541 dlls/imagehlp/Makefile
1542 dlls/imm32/Makefile
1543 dlls/iphlpapi/Makefile
1544 dlls/iphlpapi/tests/Makefile
1545 dlls/kernel/Makefile
1546 dlls/kernel/tests/Makefile
1547 dlls/lzexpand/Makefile
1548 dlls/mapi32/Makefile
1549 dlls/mmdevldr.vxd/Makefile
1550 dlls/monodebg.vxd/Makefile
1551 dlls/mpr/Makefile
1552 dlls/msacm/Makefile
1553 dlls/msacm/imaadp32/Makefile
1554 dlls/msacm/msadp32/Makefile
1555 dlls/msacm/msg711/Makefile
1556 dlls/msacm/winemp3/Makefile
1557 dlls/msdmo/Makefile
1558 dlls/mshtml/Makefile
1559 dlls/msi/Makefile
1560 dlls/msimg32/Makefile
1561 dlls/msisys/Makefile
1562 dlls/msnet32/Makefile
1563 dlls/msrle32/Makefile
1564 dlls/msvcrt/Makefile
1565 dlls/msvcrt/tests/Makefile
1566 dlls/msvcrt20/Makefile
1567 dlls/msvcrt40/Makefile
1568 dlls/msvcrtd/Makefile
1569 dlls/msvidc32/Makefile
1570 dlls/msvideo/Makefile
1571 dlls/mswsock/Makefile
1572 dlls/netapi32/Makefile
1573 dlls/netapi32/tests/Makefile
1574 dlls/newdev/Makefile
1575 dlls/ntdll/Makefile
1576 dlls/ntdll/tests/Makefile
1577 dlls/odbc32/Makefile
1578 dlls/ole32/Makefile
1579 dlls/oleacc/Makefile
1580 dlls/oleaut32/Makefile
1581 dlls/oleaut32/tests/Makefile
1582 dlls/olecli/Makefile
1583 dlls/oledlg/Makefile
1584 dlls/olepro32/Makefile
1585 dlls/olesvr/Makefile
1586 dlls/opengl32/Makefile
1587 dlls/psapi/Makefile
1588 dlls/qcap/Makefile
1589 dlls/quartz/Makefile
1590 dlls/rasapi32/Makefile
1591 dlls/richedit/Makefile
1592 dlls/rpcrt4/Makefile
1593 dlls/rpcrt4/tests/Makefile
1594 dlls/rsabase/Makefile
1595 dlls/secur32/Makefile
1596 dlls/serialui/Makefile
1597 dlls/setupapi/Makefile
1598 dlls/shdocvw/Makefile
1599 dlls/shell32/Makefile
1600 dlls/shell32/tests/Makefile
1601 dlls/shfolder/Makefile
1602 dlls/shlwapi/Makefile
1603 dlls/shlwapi/tests/Makefile
1604 dlls/snmpapi/Makefile
1605 dlls/sti/Makefile
1606 dlls/tapi32/Makefile
1607 dlls/ttydrv/Makefile
1608 dlls/twain/Makefile
1609 dlls/unicows/Makefile
1610 dlls/url/Makefile
1611 dlls/urlmon/Makefile
1612 dlls/urlmon/tests/Makefile
1613 dlls/user/Makefile
1614 dlls/user/tests/Makefile
1615 dlls/uuid/Makefile
1616 dlls/uxtheme/Makefile
1617 dlls/vdhcp.vxd/Makefile
1618 dlls/version/Makefile
1619 dlls/vmm.vxd/Makefile
1620 dlls/vnbt.vxd/Makefile
1621 dlls/vnetbios.vxd/Makefile
1622 dlls/vtdapi.vxd/Makefile
1623 dlls/vwin32.vxd/Makefile
1624 dlls/win32s/Makefile
1625 dlls/winaspi/Makefile
1626 dlls/wined3d/Makefile
1627 dlls/winedos/Makefile
1628 dlls/wineps/Makefile
1629 dlls/wininet/Makefile
1630 dlls/wininet/tests/Makefile
1631 dlls/winmm/Makefile
1632 dlls/winmm/joystick/Makefile
1633 dlls/winmm/mcianim/Makefile
1634 dlls/winmm/mciavi/Makefile
1635 dlls/winmm/mcicda/Makefile
1636 dlls/winmm/mciseq/Makefile
1637 dlls/winmm/mciwave/Makefile
1638 dlls/winmm/midimap/Makefile
1639 dlls/winmm/tests/Makefile
1640 dlls/winmm/wavemap/Makefile
1641 dlls/winmm/winealsa/Makefile
1642 dlls/winmm/winearts/Makefile
1643 dlls/winmm/wineaudioio/Makefile
1644 dlls/winmm/winejack/Makefile
1645 dlls/winmm/winenas/Makefile
1646 dlls/winmm/wineoss/Makefile
1647 dlls/winnls/Makefile
1648 dlls/winsock/Makefile
1649 dlls/winsock/tests/Makefile
1650 dlls/winspool/Makefile
1651 dlls/winspool/tests/Makefile
1652 dlls/wintab32/Makefile
1653 dlls/wintrust/Makefile
1654 dlls/wow32/Makefile
1655 dlls/wsock32/Makefile
1656 dlls/x11drv/Makefile
1657 documentation/Makefile
1658 include/Makefile
1659 libs/Makefile
1660 libs/port/Makefile
1661 libs/unicode/Makefile
1662 libs/wine/Makefile
1663 libs/wpp/Makefile
1664 loader/Makefile
1665 programs/Makefile
1666 programs/avitools/Makefile
1667 programs/clock/Makefile
1668 programs/cmdlgtst/Makefile
1669 programs/control/Makefile
1670 programs/expand/Makefile
1671 programs/notepad/Makefile
1672 programs/progman/Makefile
1673 programs/regedit/Makefile
1674 programs/regsvr32/Makefile
1675 programs/rpcss/Makefile
1676 programs/rundll32/Makefile
1677 programs/start/Makefile
1678 programs/uninstaller/Makefile
1679 programs/view/Makefile
1680 programs/wcmd/Makefile
1681 programs/wineboot/Makefile
1682 programs/winebrowser/Makefile
1683 programs/winecfg/Makefile
1684 programs/wineconsole/Makefile
1685 programs/winedbg/Makefile
1686 programs/winefile/Makefile
1687 programs/winemenubuilder/Makefile
1688 programs/winemine/Makefile
1689 programs/winepath/Makefile
1690 programs/winetest/Makefile
1691 programs/winevdm/Makefile
1692 programs/winhelp/Makefile
1693 programs/winver/Makefile
1694 server/Makefile
1695 tools/Makefile
1696 tools/widl/Makefile
1697 tools/winapi/Makefile
1698 tools/winebuild/Makefile
1699 tools/winedump/Makefile
1700 tools/winegcc/Makefile
1701 tools/wmc/Makefile
1702 tools/wrc/Makefile])
1704 AC_OUTPUT
1706 if test "$have_x" = "no"
1707 then
1708 echo
1709 echo "*** Warning: X development files not found. Wine will be built without"
1710 echo "*** X support, which currently does not work, and would probably not be"
1711 echo "*** what you want anyway. You will need to install devel packages of"
1712 echo "*** Xlib/Xfree86 at the very least."
1713 fi
1715 if test "$wine_cv_opengl_version_OK" = "no"
1716 then
1717 echo
1718 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1719 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1720 fi
1722 if test "$wine_cv_msg_freetype" = "yes"
1723 then
1724 echo
1725 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1726 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1727 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1728 echo "*** enable Wine to use TrueType fonts."
1729 fi
1731 echo
1732 echo "Configure finished. Do 'make depend && make' to compile Wine."
1733 echo
1735 dnl Local Variables:
1736 dnl comment-start: "dnl "
1737 dnl comment-end: ""
1738 dnl comment-start-skip: "\\bdnl\\b\\s *"
1739 dnl compile-command: "autoconf"
1740 dnl End: