aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl WINE_CHECK_HOST_TOOL(VARIABLE, PROG-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND], [PATH])
  26 dnl
  27 dnl Like AC_CHECK_TOOL but without the broken fallback to non-prefixed name
  28 dnl
  29 AC_DEFUN([WINE_CHECK_HOST_TOOL],
  30 [AS_VAR_SET_IF([ac_tool_prefix],
  31   [AC_CHECK_PROG([$1],[${ac_tool_prefix}$2],[${ac_tool_prefix}$2],,[$4])])
  32 AS_VAR_IF([ac_cv_prog_$1],[],
  33   [AS_VAR_IF([cross_compiling],[yes],[],
  34     [AS_UNSET([ac_cv_prog_$1])
  35      AC_CHECK_PROG([$1],[$2],[$2],[$3],[$4])])],
  36 [AS_VAR_COPY([$1],[ac_cv_prog_$1])])])
  37
  38 dnl WINE_HEADER_MAJOR()
  39 dnl
  40 dnl Same as AC_HEADER_MAJOR but fixed to handle the glibc 2.25 sys/types.h breakage
  41 dnl
  42 AC_DEFUN([WINE_HEADER_MAJOR],
  43 [AC_CHECK_HEADER(sys/mkdev.h,
  44                 [AC_DEFINE(MAJOR_IN_MKDEV, 1,
  45                            [Define to 1 if `major', `minor', and `makedev' are
  46                             declared in <mkdev.h>.])])
  47 if test $ac_cv_header_sys_mkdev_h = no; then
  48   AC_CHECK_HEADER(sys/sysmacros.h,
  49                   [AC_DEFINE(MAJOR_IN_SYSMACROS, 1,
  50                              [Define to 1 if `major', `minor', and `makedev'
  51                               are declared in <sysmacros.h>.])])
  52 fi])
  53
  54 dnl **** Initialize the programs used by other checks ****
  55 dnl
  56 dnl Usage: WINE_PATH_SONAME_TOOLS
  57 dnl Usage: WINE_PATH_PKG_CONFIG
  58 dnl
  59 AC_DEFUN([WINE_PATH_SONAME_TOOLS],
  60 [AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)
  61 AC_CHECK_TOOL(OTOOL,otool,otool)
  62 AC_CHECK_TOOL(READELF,[readelf],true)])
  63
  64 AC_DEFUN([WINE_PATH_PKG_CONFIG],
  65 [WINE_CHECK_HOST_TOOL(PKG_CONFIG,[pkg-config])])
  66
  67 AC_DEFUN([WINE_PATH_MINGW_PKG_CONFIG],
  68 [AS_VAR_IF([HOST_ARCH],[i386],
  69            [ac_prefix_list="m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-w64-mingw32-pkg-config ])"],
  70            [ac_prefix_list="$host_cpu-w64-mingw32-pkg-config"])
  71 AC_CHECK_PROGS(MINGW_PKG_CONFIG,[$ac_prefix_list],false)])
  72
  73 dnl **** Extract the soname of a library ****
  74 dnl
  75 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  76 dnl
  77 AC_DEFUN([WINE_CHECK_SONAME],
  78 [AC_REQUIRE([WINE_PATH_SONAME_TOOLS])dnl
  79 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  80 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  81 AC_MSG_CHECKING([for -l$1])
  82 AC_CACHE_VAL(ac_Lib,
  83 [ac_check_soname_save_LIBS=$LIBS
  84 LIBS="-l$1 $5 $LIBS"
  85   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  86   [case "$LIBEXT" in
  87     dll) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest.exe | grep "$1" | sed -e "s/dll.*/dll/"';2,$d'`]) ;;
  88     dylib) AS_VAR_SET(ac_Lib,[`$OTOOL -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  89     *) AS_VAR_SET(ac_Lib,[`$READELF -d conftest$ac_exeext | grep "NEEDED.*ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\\m4_dquote(\\(ac_lib_pattern\\.$LIBEXT[[^    ]]*\\)\\).*$/\1/"';2,$d'`])
  90        AS_VAR_IF([ac_Lib],[],
  91              [AS_VAR_SET(ac_Lib,[`$LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^  ]]*\).*$/\1/"';2,$d'`])]) ;;
  92   esac],
  93   [AS_VAR_SET(ac_Lib,[])])
  94   LIBS=$ac_check_soname_save_LIBS])dnl
  95 AS_VAR_IF([ac_Lib],[],
  96       [AC_MSG_RESULT([not found])
  97        $4],
  98       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
  99        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
 100                           [Define to the soname of the lib$1 library.])
 101        $3])dnl
 102 m4_popdef([ac_lib_pattern])dnl
 103 AS_VAR_POPDEF([ac_Lib])])
 104
 105 dnl **** Get flags from pkg-config or alternate xxx-config program ****
 106 dnl
 107 dnl Usage: WINE_PACKAGE_FLAGS(var,pkg-name,[default-lib,[cflags-alternate,libs-alternate,[checks]]])
 108 dnl
 109 AC_DEFUN([WINE_PACKAGE_FLAGS],
 110 [AC_REQUIRE([WINE_PATH_PKG_CONFIG])dnl
 111 AS_VAR_PUSHDEF([ac_cflags],[[$1]_CFLAGS])dnl
 112 AS_VAR_PUSHDEF([ac_libs],[[$1]_LIBS])dnl
 113 rm -f conftest.err
 114 AC_ARG_VAR(ac_cflags, [C compiler flags for $2, overriding pkg-config])dnl
 115 AS_VAR_IF([ac_cflags],[],
 116       [AS_VAR_SET_IF([PKG_CONFIG],
 117       [ac_cflags=`$PKG_CONFIG --cflags [$2] 2>conftest.err`])])
 118 m4_ifval([$4],[test "$cross_compiling" = yes || ac_cflags=[$]{ac_cflags:-[$4]}])
 119 AC_ARG_VAR(ac_libs, [Linker flags for $2, overriding pkg-config])dnl
 120 AS_VAR_IF([ac_libs],[],
 121       [AS_VAR_SET_IF([PKG_CONFIG],
 122       [ac_libs=`$PKG_CONFIG --libs [$2] 2>/dev/null`])])
 123 m4_ifval([$5],[test "$cross_compiling" = yes || ac_libs=[$]{ac_libs:-[$5]}])
 124 m4_ifval([$3],[ac_libs=[$]{ac_libs:-"$3"}])
 125 AS_ECHO(["$as_me:${as_lineno-$LINENO}: $2 cflags: $ac_cflags"]) >&AS_MESSAGE_LOG_FD
 126 AS_ECHO(["$as_me:${as_lineno-$LINENO}: $2 libs: $ac_libs"]) >&AS_MESSAGE_LOG_FD
 127 if test -s conftest.err; then
 128      AS_ECHO_N(["$as_me:${as_lineno-$LINENO}: $2 errors: "]) >&AS_MESSAGE_LOG_FD
 129      cat conftest.err >&AS_MESSAGE_LOG_FD
 130 fi
 131 rm -f conftest.err
 132 ac_save_CPPFLAGS=$CPPFLAGS
 133 CPPFLAGS="$CPPFLAGS $ac_cflags"
 134 $6
 135 CPPFLAGS=$ac_save_CPPFLAGS
 136 AS_VAR_POPDEF([ac_libs])dnl
 137 AS_VAR_POPDEF([ac_cflags])])dnl
 138
 139 dnl **** Get flags from MinGW pkg-config or alternate xxx-config program ****
 140 dnl
 141 dnl Usage: WINE_MINGW_PACKAGE_FLAGS(var,pkg-name,[default-lib,[checks]])
 142 dnl
 143 AC_DEFUN([WINE_MINGW_PACKAGE_FLAGS],
 144 [AC_REQUIRE([WINE_PATH_MINGW_PKG_CONFIG])dnl
 145 AS_VAR_PUSHDEF([ac_cflags],[[$1]_PE_CFLAGS])dnl
 146 AS_VAR_PUSHDEF([ac_libs],[[$1]_PE_LIBS])dnl
 147 AS_VAR_IF([ac_cflags],[],
 148       [AS_VAR_SET_IF([MINGW_PKG_CONFIG],
 149       [ac_cflags=`$MINGW_PKG_CONFIG --cflags [$2] 2>/dev/null`])])
 150 AS_VAR_IF([ac_libs],[],
 151       [AS_VAR_SET_IF([MINGW_PKG_CONFIG],
 152       [ac_libs=`$MINGW_PKG_CONFIG --libs [$2] 2>/dev/null`])])
 153 m4_ifval([$3],[ac_libs=[$]{ac_libs:-"$3"}])
 154 ac_save_CPPFLAGS=$CPPFLAGS
 155 CPPFLAGS="$CPPFLAGS $ac_cflags"
 156 $4
 157 CPPFLAGS=$ac_save_CPPFLAGS
 158 AS_VAR_POPDEF([ac_libs])dnl
 159 AS_VAR_POPDEF([ac_cflags])])dnl
 160
 161 dnl **** Get flags for an external lib program ****
 162 dnl
 163 dnl Usage: WINE_EXTLIB_FLAGS(var,pkg-name,default-libs,default-cflags)
 164 dnl
 165 AC_DEFUN([WINE_EXTLIB_FLAGS],
 166 [AS_VAR_PUSHDEF([ac_cflags],[[$1]_PE_CFLAGS])dnl
 167 AS_VAR_PUSHDEF([ac_libs],[[$1]_PE_LIBS])dnl
 168 AC_ARG_VAR(ac_cflags, [C compiler flags for the PE $2, overriding the bundled version])dnl
 169 AC_ARG_VAR(ac_libs, [Linker flags for the PE $2, overriding the bundled version])dnl
 170 AS_VAR_IF([ac_libs],[],
 171   [ac_libs=$3
 172    AS_VAR_IF([ac_cflags],[],[ac_cflags=$4],[enable_$2=no])],
 173   [enable_$2=no])
 174 AS_ECHO(["$as_me:${as_lineno-$LINENO}: $2 cflags: $ac_cflags"]) >&AS_MESSAGE_LOG_FD
 175 AS_ECHO(["$as_me:${as_lineno-$LINENO}: $2 libs: $ac_libs"]) >&AS_MESSAGE_LOG_FD
 176 AS_VAR_POPDEF([ac_libs])dnl
 177 AS_VAR_POPDEF([ac_cflags])])dnl
 178
 179 dnl **** Link C code with an assembly file ****
 180 dnl
 181 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
 182 dnl
 183 AC_DEFUN([WINE_TRY_ASM_LINK],
 184 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[$2]],[[asm($1); $3]])],[$4],[$5])])
 185
 186 dnl **** Check if we can link an empty program with special CFLAGS ****
 187 dnl
 188 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
 189 dnl
 190 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
 191 dnl
 192 AC_DEFUN([WINE_TRY_CFLAGS],
 193 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
 194 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
 195 [ac_wine_try_cflags_saved=$CFLAGS
 196 CFLAGS="$CFLAGS $1"
 197 AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv) { return 0; }]])],
 198                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
 199 CFLAGS=$ac_wine_try_cflags_saved])
 200 AS_VAR_IF([ac_var],[yes],[m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
 201 AS_VAR_POPDEF([ac_var])])
 202
 203 dnl **** Check if we can link an empty program with special CFLAGS ****
 204 dnl
 205 dnl Usage: WINE_TRY_PE_CFLAGS(flags,[action-if-yes,[action-if-no]])
 206 dnl
 207 dnl The default action-if-yes is to append the flags to the arch-specific EXTRACFLAGS.
 208 dnl
 209 AC_DEFUN([WINE_TRY_PE_CFLAGS],
 210 [{ AS_VAR_PUSHDEF([ac_var], ac_cv_${wine_arch}_cflags_[[$1]])dnl
 211 AC_CACHE_CHECK([whether $CC supports $1], ac_var,
 212 [ac_wine_try_cflags_saved=$CFLAGS
 213 ac_wine_try_cflags_saved_exeext=$ac_exeext
 214 CFLAGS="$CFLAGS -nostdlib -nodefaultlibs $1"
 215 ac_exeext=".exe"
 216 AC_LINK_IFELSE([AC_LANG_SOURCE([[int __cdecl mainCRTStartup(void) { return 0; }]])],
 217                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
 218 CFLAGS=$ac_wine_try_cflags_saved
 219 ac_exeext=$ac_wine_try_cflags_saved_exeext])
 220 AS_VAR_IF([ac_var],[yes],[m4_default([$2], [AS_VAR_APPEND([${wine_arch}_EXTRACFLAGS],[" $1"])], [$3])])dnl
 221 AS_VAR_POPDEF([ac_var]) }])
 222
 223 dnl **** Check whether the given MinGW header is available ****
 224 dnl
 225 dnl Usage: WINE_CHECK_MINGW_HEADER(header,[action-if-found],[action-if-not-found],[other-includes])
 226 dnl
 227 AC_DEFUN([WINE_CHECK_MINGW_HEADER],
 228 [AS_VAR_PUSHDEF([ac_var],[ac_cv_mingw_header_$1])dnl
 229 AC_CACHE_CHECK([for MinGW $1], ac_var,
 230 [ac_wine_check_headers_saved_cc=$CC
 231 ac_wine_check_headers_saved_exeext=$ac_exeext
 232 AS_VAR_COPY([CC],[${wine_arch}_CC])
 233 ac_exeext=".exe"
 234 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[$4
 235 #include <$1>]])],[AS_VAR_SET([ac_var],[yes])],[AS_VAR_SET([ac_var],[no])])
 236 CC=$ac_wine_check_headers_saved_cc
 237 ac_exeext=$ac_wine_check_headers_saved_exeext])
 238 AS_VAR_IF([ac_var],[yes],[$2],[$3])dnl
 239 AS_VAR_POPDEF([ac_var])])
 240
 241 dnl **** Check whether the given MinGW library is available ****
 242 dnl
 243 dnl Usage: WINE_CHECK_MINGW_LIB(library,function,[action-if-found],[action-if-not-found],[other-libraries])
 244 dnl
 245 AC_DEFUN([WINE_CHECK_MINGW_LIB],
 246 [AS_VAR_PUSHDEF([ac_var],[ac_cv_mingw_lib_$1])dnl
 247 AC_CACHE_CHECK([for $2 in MinGW -l$1], ac_var,
 248 [ac_wine_check_headers_saved_cc=$CC
 249 ac_wine_check_headers_saved_exeext=$ac_exeext
 250 ac_wine_check_headers_saved_libs=$LIBS
 251 AS_VAR_COPY([CC],[${wine_arch}_CC])
 252 ac_exeext=".exe"
 253 LIBS="-l$1 $5 $LIBS"
 254 AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],[AS_VAR_SET([ac_var],[yes])],[AS_VAR_SET([ac_var],[no])])
 255 CC=$ac_wine_check_headers_saved_cc
 256 ac_exeext=$ac_wine_check_headers_saved_exeext
 257 LIBS=$ac_wine_check_headers_saved_libs])
 258 AS_VAR_IF([ac_var],[yes],[$3],[$4])dnl
 259 AS_VAR_POPDEF([ac_var])])
 260
 261 dnl **** Check whether we need to define a symbol on the compiler command line ****
 262 dnl
 263 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
 264 dnl
 265 AC_DEFUN([WINE_CHECK_DEFINE],
 266 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 267 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 268     AC_EGREP_CPP(yes,[#ifndef $1
 269 yes
 270 #endif],
 271     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 272 AS_VAR_IF([ac_var],[yes],
 273       [CFLAGS="$CFLAGS -D$1"
 274   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 275 AS_VAR_POPDEF([ac_var])])
 276
 277 dnl **** Check for functions with some extra libraries ****
 278 dnl
 279 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 280 dnl
 281 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 282 [ac_wine_check_funcs_save_LIBS="$LIBS"
 283 LIBS="$LIBS $2"
 284 AC_CHECK_FUNCS([$1],[$3],[$4])
 285 LIBS="$ac_wine_check_funcs_save_LIBS"])
 286
 287 dnl **** Define helper functions for creating config.status files ****
 288 dnl
 289 dnl Usage: AC_REQUIRE([WINE_CONFIG_HELPERS])
 290 dnl
 291 AC_DEFUN([WINE_CONFIG_HELPERS],
 292 [AS_VAR_SET([wine_rules],["all:"])
 293 AC_SUBST(SUBDIRS,"")
 294 AC_SUBST(DISABLED_SUBDIRS,"")
 295 AC_SUBST(CONFIGURE_TARGETS,"")
 296
 297 wine_fn_config_makefile ()
 298 {
 299     AS_VAR_APPEND([SUBDIRS],[" \\$as_nl $[1]"])
 300     AS_VAR_COPY([enable],[$[2]])
 301     case "$enable" in
 302       no) AS_VAR_APPEND([DISABLED_SUBDIRS],[" $[1]"]) ;;
 303       *aarch64*|*arm*|*i386*|*x86_64*)
 304         if test -n "$PE_ARCHS"
 305         then
 306             for i in $PE_ARCHS
 307             do
 308                 test $(expr ",$enable," : ".*,$i,") -gt 0 || AS_VAR_APPEND([${i}_DISABLED_SUBDIRS],[" $[1]"])
 309             done
 310         else
 311             test $(expr ",$enable," : ".*,$HOST_ARCH,") -gt 0 || AS_VAR_APPEND([DISABLED_SUBDIRS],[" $[1]"])
 312         fi;;
 313     esac
 314 }
 315
 316 wine_fn_config_symlink ()
 317 {
 318     ac_links=$[@]
 319     AS_VAR_APPEND([wine_rules],["
 320 $ac_links:
 321         @./config.status \$[@]"])
 322     for f in $ac_links; do AS_VAR_APPEND([CONFIGURE_TARGETS],[" $f"]); done
 323 }])
 324
 325 dnl **** Define helper function to append a rule to a makefile command list ****
 326 dnl
 327 dnl Usage: WINE_APPEND_RULE(rule)
 328 dnl
 329 AC_DEFUN([WINE_APPEND_RULE],[AC_REQUIRE([WINE_CONFIG_HELPERS])AS_VAR_APPEND([wine_rules],["
 330 $1"])])
 331
 332 dnl **** Create symlinks from config.status ****
 333 dnl
 334 dnl Usage: WINE_CONFIG_SYMLINK(target,src,enable)
 335 dnl
 336 AC_DEFUN([WINE_CONFIG_SYMLINK],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 337 m4_ifval([$3],[if test $3; then
 338 ])AC_CONFIG_LINKS([$1:$2])dnl
 339 wine_fn_config_symlink[ $1]m4_ifval([$3],[
 340 fi])[]dnl
 341 ])])
 342
 343 dnl **** Create a makefile from config.status ****
 344 dnl
 345 dnl Usage: WINE_CONFIG_MAKEFILE(file,enable,condition)
 346 dnl
 347 AC_DEFUN([WINE_CONFIG_MAKEFILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 348 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]m4_bpatsubst([$1],[.*/\([^/]*\)$],[\1])))dnl
 349 m4_append_uniq([_AC_USER_OPTS],ac_enable,[
 350 ])dnl
 351 m4_ifval([$3],[$3 || ])wine_fn_config_makefile [$1] ac_enable[]dnl
 352 AS_VAR_POPDEF([ac_enable])])
 353
 354 dnl **** Append a file to the .gitignore list ****
 355 dnl
 356 dnl Usage: WINE_IGNORE_FILE(file,enable)
 357 dnl
 358 AC_DEFUN([WINE_IGNORE_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 359 m4_ifval([$2],[test "x$[$2]" = xno || ])AS_VAR_APPEND([CONFIGURE_TARGETS],[" $1"])])
 360
 361 dnl **** Add a message to the list displayed at the end ****
 362 dnl
 363 dnl Usage: WINE_NOTICE(notice)
 364 dnl Usage: WINE_WARNING(warning)
 365 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice, enable)
 366 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning, enable)
 367 dnl Usage: WINE_ERROR_WITH(with_flag, test, error, enable)
 368 dnl Usage: WINE_PRINT_MESSAGES
 369 dnl
 370 AC_DEFUN([WINE_NOTICE],[AS_VAR_APPEND([wine_notices],["|$1"])])
 371 AC_DEFUN([WINE_WARNING],[AS_VAR_APPEND([wine_warnings],["|$1"])])
 372
 373 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 374   x)   WINE_NOTICE([$3]) ;;
 375   xno) ;;
 376   *)   AC_MSG_ERROR([$3
 377 This is an error since --with-$1 was requested.]) ;;
 378 esac
 379 m4_ifval([$4],[$4=${$4:-no}])])])
 380
 381 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 382   x)   WINE_WARNING([$3]) ;;
 383   xno) ;;
 384   *)   AC_MSG_ERROR([$3
 385 This is an error since --with-$1 was requested.]) ;;
 386 esac
 387 m4_ifval([$4],[$4=${$4:-no}])])])
 388
 389 AC_DEFUN([WINE_ERROR_WITH],[AS_IF([$2],[case "x$with_$1" in
 390   xno) ;;
 391   *)   AC_MSG_ERROR([$3
 392 Use the --without-$1 option if you really want this.]) ;;
 393 esac
 394 m4_ifval([$4],[$4=${$4:-no}])])])
 395
 396 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 397 if test "x$wine_notices" != x; then
 398     echo >&AS_MESSAGE_FD
 399     IFS="|"
 400     for msg in $wine_notices; do
 401         IFS="$ac_save_IFS"
 402         AS_VAR_IF([msg],[],,[AC_MSG_NOTICE([$msg])])
 403     done
 404 fi
 405 IFS="|"
 406 for msg in $wine_warnings; do
 407     IFS="$ac_save_IFS"
 408     AS_VAR_IF([msg],[],,[echo >&2
 409         AC_MSG_WARN([$msg])])
 410 done
 411 IFS="$ac_save_IFS"])
 412
 413 dnl Local Variables:
 414 dnl compile-command: "autoreconf --warnings=all"
 415 dnl End: