dlls/d3dx9_36/asmshader.l

   1 /*
   2  * Direct3D shader assembler
   3  *
   4  * Copyright 2008 Stefan Dösinger
   5  * Copyright 2009 Matteo Bruni
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 %{
  23 #include "config.h"
  24 #include "wine/port.h"
  25 #include "wine/debug.h"
  26
  27 #include "d3dx9_36_private.h"
  28 #include "asmshader.tab.h"
  29
  30 WINE_DEFAULT_DEBUG_CHANNEL(asmshader);
  31 %}
  32
  33 %option noyywrap
  34 %option prefix="asmshader_"
  35 %option noinput nounput
  36
  37 /* Swizzles and writemasks consist of a dot and up to 4 x, y, z or w characters,
  38  * or up to 4 a, r, g, b characters. There are different rules for swizzles and
  39  * writemasks wrt repetition, those are handled in the grammar.
  40  */
  41 DOT                     \.
  42 COMPONENT               [xyzw]|[rgba]
  43
  44 /* Registers */
  45 REG_TEMP                r[0-9]+
  46 /* for relative addressing in the form o[x], v[x] and c[x] */
  47 REG_OUTPUT              o[0-9]*
  48 REG_INPUT               v[0-9]*
  49 REG_CONSTFLOAT          c[0-9]*
  50 REG_CONSTINT            i[0-9]+
  51 REG_CONSTBOOL           b[0-9]+
  52 REG_TEXTURE             t[0-9]+
  53 REG_TEXCRDOUT           oT[0-9]+
  54 REG_SAMPLER             s[0-9]+
  55 REG_OPOS                oPos
  56 REG_OFOG                oFog
  57 REG_OPTS                oPts
  58 REG_VERTEXCOLOR         oD[01]
  59 REG_FRAGCOLOR           oC[0-9]+
  60 REG_FRAGDEPTH           oDepth
  61 REG_VPOS                vPos
  62 REG_VFACE               vFace
  63 REG_ADDRESS             a0
  64 REG_LOOP                aL
  65 REG_PREDICATE           p0
  66 /* Not really a register, but it is considered as such */
  67 REG_LABEL               l[0-9]+
  68
  69 DCL_POSITION            _position[0-9]*
  70 DCL_BLENDWEIGHT         _blendweight[0-9]*
  71 DCL_BLENDINDICES        _blendindices[0-9]*
  72 DCL_NORMAL              _normal[0-9]*
  73 DCL_PSIZE               _psize[0-9]*
  74 DCL_TEXCOORD            _texcoord[0-9]*
  75 DCL_TANGENT             _tangent[0-9]*
  76 DCL_BINORMAL            _binormal[0-9]*
  77 DCL_TESSFACTOR          _tessfactor[0-9]*
  78 DCL_POSITIONT           _positiont[0-9]*
  79 DCL_COLOR               _color[0-9]*
  80 DCL_FOG                 _fog[0-9]*
  81 DCL_DEPTH               _depth[0-9]*
  82 DCL_SAMPLE              _sample[0-9]*
  83
  84 DCL_SAMPLER1D           _1d
  85 DCL_SAMPLER2D           _2d
  86 DCL_SAMPLERCUBE         _cube
  87 DCL_SAMPLERVOLUME       _volume
  88
  89 PREPROCESSORDIRECTIVE   #[^\n]*\n
  90
  91 /* Comments */
  92 DOUBLESLASHCOMMENT      "//"[^\n]*
  93 SEMICOLONCOMMENT        ";"[^\n]*
  94
  95 /* Whitespaces are spaces, tabs and newlines */
  96 WHITESPACE              [ \t]+
  97 NEWLINE                 (\n)|(\r\n)
  98
  99 COMMA                   ","
 100
 101 IMMVAL                  \-?(([0-9]+)|([0-9]*\.[0-9]+))(f)?
 102
 103 ANY                     (.)
 104
 105 %%
 106
 107     /* Common instructions(vertex and pixel shaders) */
 108 add                     {return INSTR_ADD;          }
 109 nop                     {return INSTR_NOP;          }
 110 mov                     {return INSTR_MOV;          }
 111 sub                     {return INSTR_SUB;          }
 112 mad                     {return INSTR_MAD;          }
 113 mul                     {return INSTR_MUL;          }
 114 rcp                     {return INSTR_RCP;          }
 115 rsq                     {return INSTR_RSQ;          }
 116 dp3                     {return INSTR_DP3;          }
 117 dp4                     {return INSTR_DP4;          }
 118 min                     {return INSTR_MIN;          }
 119 max                     {return INSTR_MAX;          }
 120 slt                     {return INSTR_SLT;          }
 121 sge                     {return INSTR_SGE;          }
 122 abs                     {return INSTR_ABS;          }
 123 exp                     {return INSTR_EXP;          }
 124 log                     {return INSTR_LOG;          }
 125 expp                    {return INSTR_EXPP;         }
 126 logp                    {return INSTR_LOGP;         }
 127 dst                     {return INSTR_DST;          }
 128 lrp                     {return INSTR_LRP;          }
 129 frc                     {return INSTR_FRC;          }
 130 pow                     {return INSTR_POW;          }
 131 crs                     {return INSTR_CRS;          }
 132 sgn                     {return INSTR_SGN;          }
 133 nrm                     {return INSTR_NRM;          }
 134 sincos                  {return INSTR_SINCOS;       }
 135 m4x4                    {return INSTR_M4x4;         }
 136 m4x3                    {return INSTR_M4x3;         }
 137 m3x4                    {return INSTR_M3x4;         }
 138 m3x3                    {return INSTR_M3x3;         }
 139 m3x2                    {return INSTR_M3x2;         }
 140 dcl                     {return INSTR_DCL;          }
 141 def                     {return INSTR_DEF;          }
 142 defb                    {return INSTR_DEFB;         }
 143 defi                    {return INSTR_DEFI;         }
 144 rep                     {return INSTR_REP;          }
 145 endrep                  {return INSTR_ENDREP;       }
 146 if                      {return INSTR_IF;           }
 147 else                    {return INSTR_ELSE;         }
 148 endif                   {return INSTR_ENDIF;        }
 149 break                   {return INSTR_BREAK;        }
 150 breakp                  {return INSTR_BREAKP;       }
 151 call                    {return INSTR_CALL;         }
 152 callnz                  {return INSTR_CALLNZ;       }
 153 loop                    {return INSTR_LOOP;         }
 154 ret                     {return INSTR_RET;          }
 155 endloop                 {return INSTR_ENDLOOP;      }
 156 label                   {return INSTR_LABEL;        }
 157 setp                    {return INSTR_SETP;         }
 158 texldl                  {return INSTR_TEXLDL;       }
 159
 160     /* Vertex shader only instructions  */
 161 lit                     {return INSTR_LIT;          }
 162 mova                    {return INSTR_MOVA;         }
 163
 164     /* Pixel shader only instructions   */
 165 cmp                     {return INSTR_CMP;          }
 166 dp2add                  {return INSTR_DP2ADD;       }
 167 texkill                 {return INSTR_TEXKILL;      }
 168 texld                   {return INSTR_TEXLD;        }
 169 dsx                     {return INSTR_DSX;          }
 170 dsy                     {return INSTR_DSY;          }
 171 texldp                  {return INSTR_TEXLDP;       }
 172 texldb                  {return INSTR_TEXLDB;       }
 173 texldd                  {return INSTR_TEXLDD;       }
 174
 175 {REG_TEMP}              {
 176                             asmshader_lval.regnum = atoi(yytext + 1);
 177                             return REG_TEMP;
 178                         }
 179 {REG_OUTPUT}            {
 180                             asmshader_lval.regnum = atoi(yytext + 1);
 181                             return REG_OUTPUT;
 182                         }
 183 {REG_INPUT}             {
 184                             asmshader_lval.regnum = atoi(yytext + 1);
 185                             return REG_INPUT;
 186                         }
 187 {REG_CONSTFLOAT}        {
 188                             asmshader_lval.regnum = atoi(yytext + 1);
 189                             return REG_CONSTFLOAT;
 190                         }
 191 {REG_CONSTINT}          {
 192                             asmshader_lval.regnum = atoi(yytext + 1);
 193                             return REG_CONSTINT;
 194                         }
 195 {REG_CONSTBOOL}         {
 196                             asmshader_lval.regnum = atoi(yytext + 1);
 197                             return REG_CONSTBOOL;
 198                         }
 199 {REG_TEXTURE}           {
 200                             asmshader_lval.regnum = atoi(yytext + 1);
 201                             return REG_TEXTURE;
 202                         }
 203 {REG_TEXCRDOUT}         {
 204                             asmshader_lval.regnum = atoi(yytext + 2);
 205                             return REG_TEXCRDOUT;
 206                         }
 207 {REG_SAMPLER}           {
 208                             asmshader_lval.regnum = atoi(yytext + 1);
 209                             return REG_SAMPLER;
 210                         }
 211 {REG_OPOS}              {return REG_OPOS;           }
 212 {REG_OFOG}              {return REG_OFOG;           }
 213 {REG_OPTS}              {return REG_OPTS;           }
 214 {REG_VERTEXCOLOR}       {
 215                             asmshader_lval.regnum = atoi(yytext + 2);
 216                             return REG_VERTEXCOLOR;
 217                         }
 218 {REG_FRAGCOLOR}         {
 219                             asmshader_lval.regnum = atoi(yytext + 2);
 220                             return REG_FRAGCOLOR;
 221                         }
 222 {REG_FRAGDEPTH}         {return REG_FRAGDEPTH;      }
 223 {REG_VPOS}              {return REG_VPOS;           }
 224 {REG_VFACE}             {return REG_VFACE;          }
 225 {REG_ADDRESS}           {return REG_ADDRESS;        }
 226 {REG_LOOP}              {return REG_LOOP;           }
 227 {REG_PREDICATE}         {return REG_PREDICATE;      }
 228
 229 {REG_LABEL}             {
 230                             asmshader_lval.regnum = atoi(yytext + 1);
 231                             return REG_LABEL;
 232                         }
 233
 234     /* Shader versions. These are important to select the correct
 235      * parser profile.
 236      */
 237 vs\.1\.0|vs_1_0         {return VER_VS10;       }
 238 vs\.1\.1|vs_1_1         {return VER_VS11;       }
 239
 240 vs_2_0                  {return VER_VS20;       }
 241 vs_2_x                  {return VER_VS2X;       }
 242 vs_3_0                  {return VER_VS30;       }
 243
 244 ps\.1\.0|ps_1_0         {return VER_PS10;       }
 245 ps\.1\.1|ps_1_1         {return VER_PS11;       }
 246 ps\.1\.2|ps_1_2         {return VER_PS12;       }
 247 ps\.1\.3|ps_1_3         {return VER_PS13;       }
 248 ps\.1\.4|ps_1_4         {return VER_PS14;       }
 249
 250 ps_2_0                  {return VER_PS20;       }
 251 ps_2_x                  {return VER_PS2X;       }
 252 ps_3_0                  {return VER_PS30;       }
 253
 254 {DOT}                   {return yytext[0];      }
 255 {COMPONENT}             {
 256                             switch(yytext[0]) {
 257                                 case 'x':
 258                                 case 'r':
 259                                     asmshader_lval.component = 0;
 260                                     break;
 261                                 case 'y':
 262                                 case 'g':
 263                                     asmshader_lval.component = 1;
 264                                     break;
 265                                 case 'z':
 266                                 case 'b':
 267                                     asmshader_lval.component = 2;
 268                                     break;
 269                                 case 'w':
 270                                 case 'a':
 271                                     asmshader_lval.component = 3;
 272                                     break;
 273                             }
 274                             return COMPONENT;
 275                         }
 276
 277     /* Output modifiers */
 278 \_x2                    {return SHIFT_X2;           }
 279 \_x4                    {return SHIFT_X4;           }
 280 \_x8                    {return SHIFT_X8;           }
 281 \_d2                    {return SHIFT_D2;           }
 282 \_d4                    {return SHIFT_D4;           }
 283 \_d8                    {return SHIFT_D8;           }
 284 \_sat                   {return MOD_SAT;            }
 285 \_pp                    {return MOD_PP;             }
 286 \_centroid              {return MOD_CENTROID;       }
 287
 288     /* compare params */
 289 \_gt                    {return COMP_GT;            }
 290 \_lt                    {return COMP_LT;            }
 291 \_ge                    {return COMP_GE;            }
 292 \_le                    {return COMP_LE;            }
 293 \_eq                    {return COMP_EQ;            }
 294 \_ne                    {return COMP_NE;            }
 295
 296 {IMMVAL}                {
 297                             asmshader_lval.immval.val = atof(yytext);
 298                             asmshader_lval.immval.integer = ((strstr(yytext, ".") == NULL) && (strstr(yytext, "f") == NULL));
 299                             return IMMVAL;
 300                         }
 301 true                    {
 302                             asmshader_lval.immbool = TRUE;
 303                             return IMMBOOL;
 304                         }
 305 false                   {
 306                             asmshader_lval.immbool = FALSE;
 307                             return IMMBOOL;
 308                         }
 309
 310 {COMMA}                 {return yytext[0];          }
 311 -                       {return yytext[0];          }
 312 \(                      {return yytext[0];          }
 313 \)                      {return yytext[0];          }
 314
 315     /* for relative addressing */
 316 \[|\]|\+                {return yytext[0];          }
 317
 318 \_bias                  {return SMOD_BIAS;          }
 319     /* No _x2 here; it is identical to MOD_X2 */
 320 \_bx2                   {return SMOD_SCALEBIAS;     }
 321 \_dz                    {return SMOD_DZ;            }
 322 \_dw                    {return SMOD_DW;            }
 323 \_abs                   {return SMOD_ABS;           }
 324
 325 !                       {return SMOD_NOT;           }
 326
 327 {DCL_POSITION}          {
 328                             if(yytext[strlen("_position")] == '\0') {
 329                                 asmshader_lval.regnum = 0;
 330                             } else {
 331                                 asmshader_lval.regnum = atoi(yytext + strlen("_position"));
 332                             }
 333                             return USAGE_POSITION;
 334                         }
 335 {DCL_BLENDWEIGHT}       {
 336                             if(yytext[strlen("_blendweight")] == '\0') {
 337                                 asmshader_lval.regnum = 0;
 338                             } else {
 339                                 asmshader_lval.regnum = atoi(yytext + strlen("_blendweight"));
 340                             }
 341                             return USAGE_BLENDWEIGHT;
 342                         }
 343 {DCL_BLENDINDICES}      {
 344                             if(yytext[strlen("_blendindices")] == '\0') {
 345                                 asmshader_lval.regnum = 0;
 346                             } else {
 347                                 asmshader_lval.regnum = atoi(yytext + strlen("_blendindices"));
 348                             }
 349                             return USAGE_BLENDINDICES;
 350                         }
 351 {DCL_NORMAL}            {
 352                             if(yytext[strlen("_normal")] == '\0') {
 353                                 asmshader_lval.regnum = 0;
 354                             } else {
 355                                 asmshader_lval.regnum = atoi(yytext + strlen("_normal"));
 356                             }
 357                             return USAGE_NORMAL;
 358                         }
 359 {DCL_PSIZE}             {
 360                             if(yytext[strlen("_psize")] == '\0') {
 361                                 asmshader_lval.regnum = 0;
 362                             } else {
 363                                 asmshader_lval.regnum = atoi(yytext + strlen("_psize"));
 364                             }
 365                             return USAGE_PSIZE;
 366                         }
 367 {DCL_TEXCOORD}          {
 368                             if(yytext[strlen("_texcoord")] == '\0') {
 369                                 asmshader_lval.regnum = 0;
 370                             } else {
 371                                 asmshader_lval.regnum = atoi(yytext + strlen("_texcoord"));
 372                             }
 373                             return USAGE_TEXCOORD;
 374                         }
 375 {DCL_TANGENT}           {
 376                             if(yytext[strlen("_tangent")] == '\0') {
 377                                 asmshader_lval.regnum = 0;
 378                             } else {
 379                                 asmshader_lval.regnum = atoi(yytext + strlen("_tangent"));
 380                             }
 381                             return USAGE_TANGENT;
 382                         }
 383 {DCL_BINORMAL}          {
 384                             if(yytext[strlen("_binormal")] == '\0') {
 385                                 asmshader_lval.regnum = 0;
 386                             } else {
 387                                 asmshader_lval.regnum = atoi(yytext + strlen("_binormal"));
 388                             }
 389                             return USAGE_BINORMAL;
 390                         }
 391 {DCL_TESSFACTOR}        {
 392                             if(yytext[strlen("_tessfactor")] == '\0') {
 393                                 asmshader_lval.regnum = 0;
 394                             } else {
 395                                 asmshader_lval.regnum = atoi(yytext + strlen("_tessfactor"));
 396                             }
 397                             return USAGE_TESSFACTOR;
 398                         }
 399 {DCL_POSITIONT}         {
 400                             if(yytext[strlen("_positiont")] == '\0') {
 401                                 asmshader_lval.regnum = 0;
 402                             } else {
 403                                 asmshader_lval.regnum = atoi(yytext + strlen("_positiont"));
 404                             }
 405                             return USAGE_POSITIONT;
 406                         }
 407 {DCL_COLOR}             {
 408                             if(yytext[strlen("_color")] == '\0') {
 409                                 asmshader_lval.regnum = 0;
 410                             } else {
 411                                 asmshader_lval.regnum = atoi(yytext + strlen("_color"));
 412                             }
 413                             return USAGE_COLOR;
 414                         }
 415 {DCL_FOG}               {
 416                             if(yytext[strlen("_fog")] == '\0') {
 417                                 asmshader_lval.regnum = 0;
 418                             } else {
 419                                 asmshader_lval.regnum = atoi(yytext + strlen("_fog"));
 420                             }
 421                             return USAGE_FOG;
 422                         }
 423 {DCL_DEPTH}             {
 424                             if(yytext[strlen("_depth")] == '\0') {
 425                                 asmshader_lval.regnum = 0;
 426                             } else {
 427                                 asmshader_lval.regnum = atoi(yytext + strlen("_depth"));
 428                             }
 429                             return USAGE_DEPTH;
 430                         }
 431 {DCL_SAMPLE}            {
 432                             if(yytext[strlen("_sample")] == '\0') {
 433                                 asmshader_lval.regnum = 0;
 434                             } else {
 435                                 asmshader_lval.regnum = atoi(yytext + strlen("_sample"));
 436                             }
 437                             return USAGE_SAMPLE;
 438                         }
 439
 440 {DCL_SAMPLER1D}         { return SAMPTYPE_1D;       }
 441 {DCL_SAMPLER2D}         { return SAMPTYPE_2D;       }
 442 {DCL_SAMPLERCUBE}       { return SAMPTYPE_CUBE;     }
 443 {DCL_SAMPLERVOLUME}     { return SAMPTYPE_VOLUME;   }
 444
 445 {PREPROCESSORDIRECTIVE} {
 446                             /* TODO: update current line information */
 447                             TRACE("line info update: %s", yytext);
 448                         }
 449
 450     /* Skip comments */
 451 {DOUBLESLASHCOMMENT}    {                           }
 452 {SEMICOLONCOMMENT}      {                           }
 453
 454 {WHITESPACE}            { /* Do nothing */          }
 455 {NEWLINE}               {
 456                             asm_ctx.line_no++;
 457                         }
 458
 459 {ANY}                   {
 460                             asmparser_message(&asm_ctx, "Line %u: Unexpected input %s\n", asm_ctx.line_no, yytext);
 461                             set_parse_status(&asm_ctx, PARSE_ERR);
 462                         }
 463
 464 %%
 465
 466 struct bwriter_shader *SlAssembleShader(const char *text, char **messages) {
 467     struct bwriter_shader *ret = NULL;
 468     YY_BUFFER_STATE buffer;
 469     TRACE("%p, %p\n", text, messages);
 470
 471     buffer = asmshader__scan_string(text);
 472     asmshader__switch_to_buffer(buffer);
 473
 474     ret = parse_asm_shader(messages);
 475
 476     asmshader__delete_buffer(buffer);
 477
 478     return ret;
 479 }