dlls/d3dx9_36/asmshader.l

   1 /*
   2  * Direct3D shader assembler
   3  *
   4  * Copyright 2008 Stefan Dösinger
   5  * Copyright 2009 Matteo Bruni
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 %{
  23 #include "config.h"
  24 #include "wine/port.h"
  25 #include "wine/debug.h"
  26
  27 #include "d3dx9_36_private.h"
  28 #include "asmshader.tab.h"
  29
  30 WINE_DEFAULT_DEBUG_CHANNEL(asmshader);
  31 %}
  32
  33 %option noyywrap
  34 %option prefix="asmshader_"
  35 %option noinput nounput
  36
  37 /* Swizzles and writemasks consist of a dot and up to 4 x, y, z or w characters,
  38  * or up to 4 a, r, g, b characters. There are different rules for swizzles and
  39  * writemasks wrt repetition, those are handled in the grammar.
  40  */
  41 DOT                     \.
  42 COMPONENT               [xyzw]|[rgba]
  43
  44 /* Registers */
  45 REG_TEMP                r[0-9]+
  46 /* for relative addressing in the form o[x], v[x] and c[x] */
  47 REG_OUTPUT              o[0-9]*
  48 REG_INPUT               v[0-9]*
  49 REG_CONSTFLOAT          c[0-9]*
  50 REG_CONSTINT            i[0-9]+
  51 REG_CONSTBOOL           b[0-9]+
  52 REG_TEXTURE             t[0-9]+
  53 REG_TEXCRDOUT           oT[0-9]+
  54 REG_SAMPLER             s[0-9]+
  55 REG_OPOS                oPos
  56 REG_OFOG                oFog
  57 REG_OPTS                oPts
  58 REG_VERTEXCOLOR         oD[01]
  59 REG_FRAGCOLOR           oC[0-9]+
  60 REG_FRAGDEPTH           oDepth
  61 REG_VPOS                vPos
  62 REG_VFACE               vFace
  63 REG_ADDRESS             a0
  64 REG_LOOP                aL
  65 REG_PREDICATE           p0
  66 /* Not really a register, but it is considered as such */
  67 REG_LABEL               l[0-9]+
  68
  69 DCL_POSITION            _position[0-9]*
  70 DCL_BLENDWEIGHT         _blendweight[0-9]*
  71 DCL_BLENDINDICES        _blendindices[0-9]*
  72 DCL_NORMAL              _normal[0-9]*
  73 DCL_PSIZE               _psize[0-9]*
  74 DCL_TEXCOORD            _texcoord[0-9]*
  75 DCL_TANGENT             _tangent[0-9]*
  76 DCL_BINORMAL            _binormal[0-9]*
  77 DCL_TESSFACTOR          _tessfactor[0-9]*
  78 DCL_POSITIONT           _positiont[0-9]*
  79 DCL_COLOR               _color[0-9]*
  80 DCL_FOG                 _fog[0-9]*
  81 DCL_DEPTH               _depth[0-9]*
  82 DCL_SAMPLE              _sample[0-9]*
  83
  84 DCL_SAMPLER1D           _1d
  85 DCL_SAMPLER2D           _2d
  86 DCL_SAMPLERCUBE         _cube
  87 DCL_SAMPLERVOLUME       _volume
  88
  89 PREPROCESSORDIRECTIVE   #[^\n]*\n
  90
  91 /* Comments */
  92 DOUBLESLASHCOMMENT      "//"[^\n]*
  93 SEMICOLONCOMMENT        ";"[^\n]*
  94
  95 /* Whitespaces are spaces, tabs and newlines */
  96 WHITESPACE              [ \t]+
  97 NEWLINE                 (\n)|(\r\n)
  98
  99 COMMA                   ","
 100
 101 IMMVAL                  \-?(([0-9]+)|([0-9]*\.[0-9]+))(f)?
 102
 103 ANY                     (.)
 104
 105 %%
 106
 107     /* Common instructions(vertex and pixel shaders) */
 108 add                     {return INSTR_ADD;          }
 109 nop                     {return INSTR_NOP;          }
 110 mov                     {return INSTR_MOV;          }
 111 sub                     {return INSTR_SUB;          }
 112 mad                     {return INSTR_MAD;          }
 113 mul                     {return INSTR_MUL;          }
 114 rcp                     {return INSTR_RCP;          }
 115 rsq                     {return INSTR_RSQ;          }
 116 dp3                     {return INSTR_DP3;          }
 117 dp4                     {return INSTR_DP4;          }
 118 min                     {return INSTR_MIN;          }
 119 max                     {return INSTR_MAX;          }
 120 slt                     {return INSTR_SLT;          }
 121 sge                     {return INSTR_SGE;          }
 122 abs                     {return INSTR_ABS;          }
 123 exp                     {return INSTR_EXP;          }
 124 log                     {return INSTR_LOG;          }
 125 expp                    {return INSTR_EXPP;         }
 126 logp                    {return INSTR_LOGP;         }
 127 dst                     {return INSTR_DST;          }
 128 lrp                     {return INSTR_LRP;          }
 129 frc                     {return INSTR_FRC;          }
 130 pow                     {return INSTR_POW;          }
 131 crs                     {return INSTR_CRS;          }
 132 sgn                     {return INSTR_SGN;          }
 133 nrm                     {return INSTR_NRM;          }
 134 sincos                  {return INSTR_SINCOS;       }
 135 m4x4                    {return INSTR_M4x4;         }
 136 m4x3                    {return INSTR_M4x3;         }
 137 m3x4                    {return INSTR_M3x4;         }
 138 m3x3                    {return INSTR_M3x3;         }
 139 m3x2                    {return INSTR_M3x2;         }
 140 dcl                     {return INSTR_DCL;          }
 141 rep                     {return INSTR_REP;          }
 142 endrep                  {return INSTR_ENDREP;       }
 143 if                      {return INSTR_IF;           }
 144 else                    {return INSTR_ELSE;         }
 145 endif                   {return INSTR_ENDIF;        }
 146 break                   {return INSTR_BREAK;        }
 147 breakp                  {return INSTR_BREAKP;       }
 148 call                    {return INSTR_CALL;         }
 149 callnz                  {return INSTR_CALLNZ;       }
 150 loop                    {return INSTR_LOOP;         }
 151 ret                     {return INSTR_RET;          }
 152 endloop                 {return INSTR_ENDLOOP;      }
 153 label                   {return INSTR_LABEL;        }
 154 setp                    {return INSTR_SETP;         }
 155 texldl                  {return INSTR_TEXLDL;       }
 156
 157     /* Vertex shader only instructions  */
 158 lit                     {return INSTR_LIT;          }
 159 mova                    {return INSTR_MOVA;         }
 160
 161
 162 {REG_TEMP}              {
 163                             asmshader_lval.regnum = atoi(yytext + 1);
 164                             return REG_TEMP;
 165                         }
 166 {REG_OUTPUT}            {
 167                             asmshader_lval.regnum = atoi(yytext + 1);
 168                             return REG_OUTPUT;
 169                         }
 170 {REG_INPUT}             {
 171                             asmshader_lval.regnum = atoi(yytext + 1);
 172                             return REG_INPUT;
 173                         }
 174 {REG_CONSTFLOAT}        {
 175                             asmshader_lval.regnum = atoi(yytext + 1);
 176                             return REG_CONSTFLOAT;
 177                         }
 178 {REG_CONSTINT}          {
 179                             asmshader_lval.regnum = atoi(yytext + 1);
 180                             return REG_CONSTINT;
 181                         }
 182 {REG_CONSTBOOL}         {
 183                             asmshader_lval.regnum = atoi(yytext + 1);
 184                             return REG_CONSTBOOL;
 185                         }
 186 {REG_TEXTURE}           {
 187                             asmshader_lval.regnum = atoi(yytext + 1);
 188                             return REG_TEXTURE;
 189                         }
 190 {REG_TEXCRDOUT}         {
 191                             asmshader_lval.regnum = atoi(yytext + 2);
 192                             return REG_TEXCRDOUT;
 193                         }
 194 {REG_SAMPLER}           {
 195                             asmshader_lval.regnum = atoi(yytext + 1);
 196                             return REG_SAMPLER;
 197                         }
 198 {REG_OPOS}              {return REG_OPOS;           }
 199 {REG_OFOG}              {return REG_OFOG;           }
 200 {REG_OPTS}              {return REG_OPTS;           }
 201 {REG_VERTEXCOLOR}       {
 202                             asmshader_lval.regnum = atoi(yytext + 2);
 203                             return REG_VERTEXCOLOR;
 204                         }
 205 {REG_FRAGCOLOR}         {
 206                             asmshader_lval.regnum = atoi(yytext + 2);
 207                             return REG_FRAGCOLOR;
 208                         }
 209 {REG_FRAGDEPTH}         {return REG_FRAGDEPTH;      }
 210 {REG_VPOS}              {return REG_VPOS;           }
 211 {REG_VFACE}             {return REG_VFACE;          }
 212 {REG_ADDRESS}           {return REG_ADDRESS;        }
 213 {REG_LOOP}              {return REG_LOOP;           }
 214 {REG_PREDICATE}         {return REG_PREDICATE;      }
 215
 216 {REG_LABEL}             {
 217                             asmshader_lval.regnum = atoi(yytext + 1);
 218                             return REG_LABEL;
 219                         }
 220
 221     /* Shader versions. These are important to select the correct
 222      * parser profile.
 223      */
 224 vs\.1\.0|vs_1_0         {return VER_VS10;       }
 225 vs\.1\.1|vs_1_1         {return VER_VS11;       }
 226
 227 vs_2_0                  {return VER_VS20;       }
 228 vs_2_x                  {return VER_VS2X;       }
 229 vs_3_0                  {return VER_VS30;       }
 230
 231 ps\.1\.0|ps_1_0         {return VER_PS10;       }
 232 ps\.1\.1|ps_1_1         {return VER_PS11;       }
 233 ps\.1\.2|ps_1_2         {return VER_PS12;       }
 234 ps\.1\.3|ps_1_3         {return VER_PS13;       }
 235 ps\.1\.4|ps_1_4         {return VER_PS14;       }
 236
 237 ps_2_0                  {return VER_PS20;       }
 238 ps_2_x                  {return VER_PS2X;       }
 239 ps_3_0                  {return VER_PS30;       }
 240
 241 {DOT}                   {return yytext[0];      }
 242 {COMPONENT}             {
 243                             switch(yytext[0]) {
 244                                 case 'x':
 245                                 case 'r':
 246                                     asmshader_lval.component = 0;
 247                                     break;
 248                                 case 'y':
 249                                 case 'g':
 250                                     asmshader_lval.component = 1;
 251                                     break;
 252                                 case 'z':
 253                                 case 'b':
 254                                     asmshader_lval.component = 2;
 255                                     break;
 256                                 case 'w':
 257                                 case 'a':
 258                                     asmshader_lval.component = 3;
 259                                     break;
 260                             }
 261                             return COMPONENT;
 262                         }
 263
 264     /* Output modifiers */
 265 \_sat                   {return MOD_SAT;            }
 266 \_pp                    {return MOD_PP;             }
 267 \_centroid              {return MOD_CENTROID;       }
 268
 269     /* compare params */
 270 \_gt                    {return COMP_GT;            }
 271 \_lt                    {return COMP_LT;            }
 272 \_ge                    {return COMP_GE;            }
 273 \_le                    {return COMP_LE;            }
 274 \_eq                    {return COMP_EQ;            }
 275 \_ne                    {return COMP_NE;            }
 276
 277 {IMMVAL}                {
 278                             asmshader_lval.immval.val = atof(yytext);
 279                             asmshader_lval.immval.integer = ((strstr(yytext, ".") == NULL) && (strstr(yytext, "f") == NULL));
 280                             return IMMVAL;
 281                         }
 282
 283 {COMMA}                 {return yytext[0];          }
 284 -                       {return yytext[0];          }
 285 \(                      {return yytext[0];          }
 286 \)                      {return yytext[0];          }
 287
 288     /* for relative addressing */
 289 \[|\]|\+                {return yytext[0];          }
 290
 291 \_abs                   {return SMOD_ABS;           }
 292
 293 !                       {return SMOD_NOT;           }
 294
 295 {DCL_POSITION}          {
 296                             if(yytext[strlen("_position")] == '\0') {
 297                                 asmshader_lval.regnum = 0;
 298                             } else {
 299                                 asmshader_lval.regnum = atoi(yytext + strlen("_position"));
 300                             }
 301                             return USAGE_POSITION;
 302                         }
 303 {DCL_BLENDWEIGHT}       {
 304                             if(yytext[strlen("_blendweight")] == '\0') {
 305                                 asmshader_lval.regnum = 0;
 306                             } else {
 307                                 asmshader_lval.regnum = atoi(yytext + strlen("_blendweight"));
 308                             }
 309                             return USAGE_BLENDWEIGHT;
 310                         }
 311 {DCL_BLENDINDICES}      {
 312                             if(yytext[strlen("_blendindices")] == '\0') {
 313                                 asmshader_lval.regnum = 0;
 314                             } else {
 315                                 asmshader_lval.regnum = atoi(yytext + strlen("_blendindices"));
 316                             }
 317                             return USAGE_BLENDINDICES;
 318                         }
 319 {DCL_NORMAL}            {
 320                             if(yytext[strlen("_normal")] == '\0') {
 321                                 asmshader_lval.regnum = 0;
 322                             } else {
 323                                 asmshader_lval.regnum = atoi(yytext + strlen("_normal"));
 324                             }
 325                             return USAGE_NORMAL;
 326                         }
 327 {DCL_PSIZE}             {
 328                             if(yytext[strlen("_psize")] == '\0') {
 329                                 asmshader_lval.regnum = 0;
 330                             } else {
 331                                 asmshader_lval.regnum = atoi(yytext + strlen("_psize"));
 332                             }
 333                             return USAGE_PSIZE;
 334                         }
 335 {DCL_TEXCOORD}          {
 336                             if(yytext[strlen("_texcoord")] == '\0') {
 337                                 asmshader_lval.regnum = 0;
 338                             } else {
 339                                 asmshader_lval.regnum = atoi(yytext + strlen("_texcoord"));
 340                             }
 341                             return USAGE_TEXCOORD;
 342                         }
 343 {DCL_TANGENT}           {
 344                             if(yytext[strlen("_tangent")] == '\0') {
 345                                 asmshader_lval.regnum = 0;
 346                             } else {
 347                                 asmshader_lval.regnum = atoi(yytext + strlen("_tangent"));
 348                             }
 349                             return USAGE_TANGENT;
 350                         }
 351 {DCL_BINORMAL}          {
 352                             if(yytext[strlen("_binormal")] == '\0') {
 353                                 asmshader_lval.regnum = 0;
 354                             } else {
 355                                 asmshader_lval.regnum = atoi(yytext + strlen("_binormal"));
 356                             }
 357                             return USAGE_BINORMAL;
 358                         }
 359 {DCL_TESSFACTOR}        {
 360                             if(yytext[strlen("_tessfactor")] == '\0') {
 361                                 asmshader_lval.regnum = 0;
 362                             } else {
 363                                 asmshader_lval.regnum = atoi(yytext + strlen("_tessfactor"));
 364                             }
 365                             return USAGE_TESSFACTOR;
 366                         }
 367 {DCL_POSITIONT}         {
 368                             if(yytext[strlen("_positiont")] == '\0') {
 369                                 asmshader_lval.regnum = 0;
 370                             } else {
 371                                 asmshader_lval.regnum = atoi(yytext + strlen("_positiont"));
 372                             }
 373                             return USAGE_POSITIONT;
 374                         }
 375 {DCL_COLOR}             {
 376                             if(yytext[strlen("_color")] == '\0') {
 377                                 asmshader_lval.regnum = 0;
 378                             } else {
 379                                 asmshader_lval.regnum = atoi(yytext + strlen("_color"));
 380                             }
 381                             return USAGE_COLOR;
 382                         }
 383 {DCL_FOG}               {
 384                             if(yytext[strlen("_fog")] == '\0') {
 385                                 asmshader_lval.regnum = 0;
 386                             } else {
 387                                 asmshader_lval.regnum = atoi(yytext + strlen("_fog"));
 388                             }
 389                             return USAGE_FOG;
 390                         }
 391 {DCL_DEPTH}             {
 392                             if(yytext[strlen("_depth")] == '\0') {
 393                                 asmshader_lval.regnum = 0;
 394                             } else {
 395                                 asmshader_lval.regnum = atoi(yytext + strlen("_depth"));
 396                             }
 397                             return USAGE_DEPTH;
 398                         }
 399 {DCL_SAMPLE}            {
 400                             if(yytext[strlen("_sample")] == '\0') {
 401                                 asmshader_lval.regnum = 0;
 402                             } else {
 403                                 asmshader_lval.regnum = atoi(yytext + strlen("_sample"));
 404                             }
 405                             return USAGE_SAMPLE;
 406                         }
 407
 408 {DCL_SAMPLER1D}         { return SAMPTYPE_1D;       }
 409 {DCL_SAMPLER2D}         { return SAMPTYPE_2D;       }
 410 {DCL_SAMPLERCUBE}       { return SAMPTYPE_CUBE;     }
 411 {DCL_SAMPLERVOLUME}     { return SAMPTYPE_VOLUME;   }
 412
 413 {PREPROCESSORDIRECTIVE} {
 414                             /* TODO: update current line information */
 415                             TRACE("line info update: %s", yytext);
 416                         }
 417
 418     /* Skip comments */
 419 {DOUBLESLASHCOMMENT}    {                           }
 420 {SEMICOLONCOMMENT}      {                           }
 421
 422 {WHITESPACE}            { /* Do nothing */          }
 423 {NEWLINE}               {
 424                             asm_ctx.line_no++;
 425                         }
 426
 427 {ANY}                   {
 428                             asmparser_message(&asm_ctx, "Line %u: Unexpected input %s\n", asm_ctx.line_no, yytext);
 429                             set_parse_status(&asm_ctx, PARSE_ERR);
 430                         }
 431
 432 %%
 433
 434 struct bwriter_shader *SlAssembleShader(const char *text, char **messages) {
 435     struct bwriter_shader *ret = NULL;
 436     YY_BUFFER_STATE buffer;
 437     TRACE("%p, %p\n", text, messages);
 438
 439     buffer = asmshader__scan_string(text);
 440     asmshader__switch_to_buffer(buffer);
 441
 442     ret = parse_asm_shader(messages);
 443
 444     asmshader__delete_buffer(buffer);
 445
 446     return ret;
 447 }