configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  19 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  20
  21 AC_CANONICAL_HOST
  22 case $host in
  23   x86_64*linux*)
  24     if test "x$enable_win64" != "xyes"
  25     then
  26       test -n "$CC" || CC="gcc -m32"
  27       test -n "$CXX"|| CXX="g++ -m32"
  28       test -n "$LD" || LD="ld -m elf_i386"
  29       test -n "$AS" || AS="as --32"
  30       host_cpu="i386"
  31     fi
  32     ;;
  33 esac
  34
  35 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  36 case $host_cpu in
  37   *i[[3456789]]86*)
  38     if test "x$enable_win16" != "xno"
  39     then
  40       enable_win16="yes"
  41     fi
  42     ;;
  43 esac
  44
  45 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  46 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  47 if test "x$enable_win16" != "xyes"
  48 then
  49   WIN16_FILES=""
  50   WIN16_INSTALL=""
  51 fi
  52
  53 dnl check for out of tree build with unclean source tree
  54 case "$srcdir" in
  55  .) ;;
  56  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
  57       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
  58 You need to run 'make distclean' in the source tree first.])
  59     fi ;;
  60 esac
  61
  62 dnl **** Check for some programs ****
  63
  64 AC_PROG_MAKE_SET
  65 AC_PROG_CC
  66 AC_PROG_CXX
  67 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  68 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  69
  70 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  71   [if test -z "$with_wine_tools"; then
  72      if test "$cross_compiling" = "yes"; then
  73        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  74      else
  75        wine_cv_toolsdir="\$(TOPOBJDIR)"
  76      fi
  77    elif test -d "$with_wine_tools/tools/winebuild"; then
  78      case $with_wine_tools in
  79        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  80        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  81      esac
  82    else
  83      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  84    fi])
  85 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  86
  87 AC_PATH_XTRA
  88
  89 dnl Check for flex
  90 AC_CHECK_PROGS(FLEX,flex,none)
  91 if test "$FLEX" = "none"
  92 then
  93   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
  94 fi
  95
  96 dnl Check for bison
  97 AC_CHECK_PROGS(BISON,bison,none)
  98 if test "$BISON" = "none"
  99 then
 100   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 101 fi
 102
 103 AC_CHECK_TOOLS(AS,[gas as],as)
 104 AC_CHECK_TOOL(LD,ld,ld)
 105 AC_CHECK_TOOL(AR,ar,ar)
 106 AC_PROG_RANLIB
 107 AC_CHECK_TOOL(STRIP,strip,strip)
 108 AC_CHECK_TOOL(WINDRES,windres,false)
 109 AC_PROG_LN_S
 110 WINE_PROG_LN
 111 AC_PROG_EGREP
 112 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 113 AC_PROG_INSTALL
 114 dnl Prepend src dir to install path dir if it's a relative path
 115 case "$INSTALL" in
 116   [[\\/$]]* | ?:[[\\/]]* ) ;;
 117   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 118 esac
 119
 120 dnl Check for lint
 121 AC_CHECK_PROGS(LINT, lclint lint)
 122 if test "$LINT" = "lint"
 123 then
 124   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 125   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 126 fi
 127 AC_SUBST(LINT)
 128 AC_SUBST(LINTFLAGS)
 129
 130 dnl Check for various programs
 131 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 132 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 133
 134 case $host_cpu in
 135   *i[[3456789]]86*)
 136     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 137     ;;
 138 esac
 139
 140 dnl **** Check for some libraries ****
 141
 142 dnl Check for -li386 for NetBSD and OpenBSD
 143 AC_CHECK_LIB(i386,i386_set_ldt)
 144 dnl Check for -lossaudio for NetBSD
 145 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 146 dnl Check for -lpthread
 147 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 148
 149 AC_SUBST(XLIB,"")
 150 AC_SUBST(XFILES,"")
 151 AC_SUBST(OPENGLFILES,"")
 152 AC_SUBST(GLU32FILES,"")
 153 AC_SUBST(OPENGL_LIBS,"")
 154 AC_SUBST(QUARTZFILES,"")
 155
 156 dnl **** Check for header files ****
 157
 158 AC_CHECK_HEADERS(\
 159         AudioUnit/AudioUnit.h \
 160         Carbon/Carbon.h \
 161         CoreAudio/CoreAudio.h \
 162         DiskArbitration/DiskArbitration.h \
 163         IOKit/IOKitLib.h \
 164         alsa/asoundlib.h \
 165         arpa/inet.h \
 166         arpa/nameser.h \
 167         asm/types.h \
 168         capi20.h \
 169         cups/cups.h \
 170         curses.h \
 171         direct.h \
 172         dlfcn.h \
 173         elf.h \
 174         float.h \
 175         fontconfig/fontconfig.h \
 176         getopt.h \
 177         ieeefp.h \
 178         io.h \
 179         jack/jack.h \
 180         jpeglib.h \
 181         lber.h \
 182         lcms.h \
 183         lcms/lcms.h \
 184         ldap.h \
 185         libaudioio.h \
 186         link.h \
 187         linux/cdrom.h \
 188         linux/compiler.h \
 189         linux/hdreg.h \
 190         linux/input.h \
 191         linux/ioctl.h \
 192         linux/joystick.h \
 193         linux/major.h \
 194         linux/param.h \
 195         linux/serial.h \
 196         linux/ucdrom.h \
 197         mach/mach.h \
 198         mach/machine.h \
 199         machine/cpu.h \
 200         machine/limits.h \
 201         machine/soundcard.h \
 202         mntent.h \
 203         ncurses.h \
 204         netdb.h \
 205         netinet/in.h \
 206         netinet/in_systm.h \
 207         netinet/tcp.h \
 208         netinet/tcp_fsm.h \
 209         openssl/err.h \
 210         openssl/ssl.h \
 211         png.h \
 212         poll.h \
 213         process.h \
 214         pthread.h \
 215         pwd.h \
 216         regex.h \
 217         sched.h \
 218         scsi/scsi.h \
 219         scsi/scsi_ioctl.h \
 220         scsi/sg.h \
 221         soundcard.h \
 222         stdint.h \
 223         strings.h \
 224         sys/asoundlib.h \
 225         sys/cdio.h \
 226         sys/elf32.h \
 227         sys/epoll.h \
 228         sys/errno.h \
 229         sys/event.h \
 230         sys/exec_elf.h \
 231         sys/filio.h \
 232         sys/ioctl.h \
 233         sys/ipc.h \
 234         sys/limits.h \
 235         sys/link.h \
 236         sys/lwp.h \
 237         sys/mman.h \
 238         sys/modem.h \
 239         sys/msg.h \
 240         sys/mtio.h \
 241         sys/param.h \
 242         sys/poll.h \
 243         sys/prctl.h \
 244         sys/ptrace.h \
 245         sys/reg.h \
 246         sys/resource.h \
 247         sys/scsiio.h \
 248         sys/shm.h \
 249         sys/signal.h \
 250         sys/socket.h \
 251         sys/socketvar.h \
 252         sys/sockio.h \
 253         sys/soundcard.h \
 254         sys/statvfs.h \
 255         sys/strtio.h \
 256         sys/syscall.h \
 257         sys/sysctl.h \
 258         sys/time.h \
 259         sys/times.h \
 260         sys/uio.h \
 261         sys/un.h \
 262         sys/vm86.h \
 263         sys/wait.h \
 264         syscall.h \
 265         termios.h \
 266         unistd.h \
 267         utime.h \
 268         valgrind/memcheck.h
 269 )
 270 AC_HEADER_STAT()
 271
 272 dnl **** Checks for headers that depend on other ones ****
 273
 274 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 275     [#include <sys/types.h>
 276      #if HAVE_SYS_PARAM_H
 277      # include <sys/param.h>
 278      #endif])
 279
 280 AC_CHECK_HEADERS([netinet/in_pcb.h netinet/ip_var.h net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 281     [#include <sys/types.h>
 282      #if HAVE_SYS_SOCKET_H
 283      # include <sys/socket.h>
 284      #endif])
 285      #if HAVE_SYS_SOCKETVAR_H
 286      # include <sys/socketvar.h>
 287      #endif
 288
 289 AC_CHECK_HEADERS([netinet/tcp_var.h],,,
 290     [#include <sys/types.h>
 291      #if HAVE_SYS_SOCKET_H
 292      # include <sys/socket.h>
 293      #endif
 294      #if HAVE_SYS_SOCKETVAR_H
 295      # include <sys/socketvar.h>
 296      #endif
 297      #if HAVE_NETINET_IN_H
 298      # include <netinet/in.h>
 299      #endif
 300      #ifdef HAVE_NETINET_TCP_H
 301      # include <netinet/tcp.h>
 302      #endif])
 303
 304 AC_CHECK_HEADERS([linux/ipx.h],,,
 305     [#include <sys/types.h>
 306      #ifdef HAVE_ASM_TYPES_H
 307      # include <asm/types.h>
 308      #endif
 309      #if HAVE_SYS_SOCKET_H
 310      # include <sys/socket.h>
 311      #endif])
 312
 313 AC_CHECK_HEADERS([resolv.h],,,
 314     [#include <sys/types.h>
 315      #if HAVE_SYS_SOCKET_H
 316      # include <sys/socket.h>
 317      #endif
 318      #if HAVE_NETINET_IN_H
 319      # include <netinet/in.h>
 320      #endif
 321      #if HAVE_ARPA_NAMESER_H
 322      # include <arpa/nameser.h>
 323      #endif])
 324
 325 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 326
 327 AC_CHECK_HEADERS([sys/thr.h],,,
 328 [#include <sys/types.h>
 329 #if HAVE_UCONTEXT_H
 330 #include <ucontext.h>
 331 #endif])
 332
 333 AC_CHECK_HEADERS([pthread_np.h],,,
 334 [#ifdef HAVE_PTHREAD_H
 335 #include <pthread.h>
 336 #endif])
 337
 338 AC_CHECK_HEADERS([linux/videodev.h],,,
 339 [#ifdef HAVE_SYS_TIME_H
 340 #include <sys/time.h>
 341 #endif
 342 #include <sys/types.h>
 343 #ifdef HAVE_ASM_TYPES_H
 344 #include <asm/types.h>
 345 #endif])
 346
 347 dnl Check for broken kernel header that doesn't define __user
 348 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 349
 350 dnl **** Check for working dll ****
 351
 352 AC_SUBST(DLLEXT,"")
 353 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 354 AC_SUBST(LDSHARED,"")
 355 AC_SUBST(LDDLLFLAGS,"")
 356 AC_SUBST(LIBEXT,"so")
 357 AC_SUBST(IMPLIBEXT,"def")
 358 AC_SUBST(LDRPATH_INSTALL,"")
 359 AC_SUBST(LDRPATH_LOCAL,"")
 360 WINE_PATH_LDD
 361
 362 case $host_os in
 363   cygwin*|mingw32*)
 364     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 365     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 366     AC_CHECK_TOOL(MINGWAR,ar,false)
 367     if test "$DLLWRAP" = "false"; then
 368       LIBEXT="a"
 369     else
 370       dnl FIXME - check whether dllwrap works correctly...
 371       LIBEXT="dll"
 372     fi
 373     IMPLIBEXT="a"
 374     dnl We can't build 16-bit NE dlls
 375     WIN16_FILES=""
 376     WIN16_INSTALL=""
 377     ;;
 378   darwin*|macosx*)
 379     DLLEXT=".so"
 380     LIBEXT="dylib"
 381     DLLFLAGS="$DLLFLAGS -fPIC"
 382     LDDLLFLAGS="-bundle -multiply_defined suppress"
 383     LIBWINE_LDFLAGS="-multiply_defined suppress"
 384     LDSHARED="\$(CC) -dynamiclib"
 385     STRIP="$STRIP -x"
 386     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 387     dnl declare needed frameworks
 388     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 389     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 390     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 391     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 392     then
 393         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 394         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 395     fi
 396     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 397     then
 398         dnl CoreServices needed by AudioUnit
 399         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 400     fi
 401     case $host_cpu in
 402       *powerpc*)
 403         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 404         ;;
 405     esac
 406     dnl Enable quartz driver on Mac OS X
 407     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 408     then
 409         AC_SUBST(CARBONLIB,"-framework Carbon")
 410         QUARTZFILES='$(QUARTZFILES)'
 411     fi
 412     ;;
 413   *)
 414     DLLFLAGS="$DLLFLAGS -fPIC"
 415     DLLEXT=".so"
 416     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 417         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 418                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 419     if test "$ac_cv_c_dll_gnuelf" = "yes"
 420     then
 421       LDSHARED="\$(CC) -shared"
 422       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 423       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 424                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 425                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 426                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 427
 428       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 429
 430       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 431                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 432
 433       echo '{ global: *; };' >conftest.map
 434       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 435                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 436       rm -f conftest.map
 437
 438       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 439                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 440
 441       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 442                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 443                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 444           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 445                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 446                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 447
 448       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 449                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 450
 451       case $host_cpu in
 452         *i[[3456789]]86* | x86_64)
 453           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 454                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 455           ;;
 456       esac
 457
 458     else
 459       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 460           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 461                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 462       if test "$ac_cv_c_dll_unixware" = "yes"
 463       then
 464         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 465         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 466
 467       else
 468         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 469           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 470         if test "$ac_cv_c_dll_hpux" = "yes"
 471         then
 472           LIBEXT="sl"
 473           DLLEXT=".sl"
 474           LDDLLFLAGS="-shared -fPIC"
 475           LDSHARED="\$(CC) -shared"
 476         fi
 477       fi
 478     fi
 479
 480     dnl Check for cross compiler to build test programs
 481     AC_SUBST(CROSSTEST,"")
 482     if test "$cross_compiling" = "no"
 483     then
 484       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 485       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
 486       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
 487       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
 488       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 489     fi
 490     ;;
 491 esac
 492
 493 if test "$LIBEXT" = "a"; then
 494   AC_MSG_ERROR(
 495 [could not find a way to build shared libraries.
 496 It is currently not possible to build Wine without shared library
 497 (.so) support to allow transparent switch between .so and .dll files.
 498 If you are using Linux, you will need a newer binutils.]
 499 )
 500 fi
 501
 502 dnl **** Check for X11 ****
 503
 504 if test "$have_x" = "yes"
 505 then
 506     XLIB="-lXext -lX11"
 507     ac_save_CPPFLAGS="$CPPFLAGS"
 508     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 509
 510     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 511     WINE_CHECK_SONAME(Xext,XextCreateExtension,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 512
 513     dnl *** All of the following tests require X11/Xlib.h
 514     AC_CHECK_HEADERS([X11/Xlib.h \
 515                       X11/XKBlib.h \
 516                       X11/Xutil.h \
 517                       X11/Xcursor/Xcursor.h \
 518                       X11/extensions/shape.h \
 519                       X11/extensions/XInput.h \
 520                       X11/extensions/XShm.h \
 521                       X11/extensions/Xinerama.h \
 522                       X11/extensions/Xrandr.h \
 523                       X11/extensions/Xrender.h \
 524                       X11/extensions/xf86vmode.h],,,
 525 [#ifdef HAVE_X11_XLIB_H
 526 # include <X11/Xlib.h>
 527 #endif
 528 #ifdef HAVE_X11_XUTIL_H
 529 # include <X11/Xutil.h>
 530 #endif])
 531
 532         dnl *** Check for X keyboard extension
 533         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 534         then
 535               AC_CHECK_LIB(X11, XkbQueryExtension,
 536               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 537               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 538         fi
 539
 540         dnl *** Check for X cursor
 541         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 542         then
 543             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 544         fi
 545
 546         dnl *** Check for X input extension
 547         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 548         then
 549             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 550         fi
 551
 552         dnl *** Check for X Shm extension
 553         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 554         then
 555               AC_CHECK_LIB(Xext, XShmQueryExtension,
 556               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 557               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 558         fi
 559         WINE_NOTICE_IF([test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],[XShm development files not found.
 560 Wine will be built without XShm support. (winex11.drv)])
 561
 562         dnl *** Check for X shape extension
 563         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 564         then
 565               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 566               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 567               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 568         fi
 569         WINE_NOTICE_IF([test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],[XShape development files not found.
 570 Wine will be built without XShape support. (winex11.drv)])
 571
 572         dnl *** Check for XFree86 VMODE extension
 573         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 574         then
 575                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 576                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 577                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 578                   ],,
 579                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 580         fi
 581         WINE_NOTICE_IF([test "$ac_cv_lib_Xxf86vm_XF86VidModeQueryExtension" != "yes"],[Xxf86vm development files not found.
 582 Wine will be built without XF86 Vidmode support. (winex11.drv)])
 583
 584         dnl *** Check for Transform functions in Xrender
 585         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
 586         then
 587             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
 588               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
 589                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 590                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 591                 [$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])],,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 592
 593         fi
 594         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xrender" = "x"],[XRender development files not found.
 595 Wine will be built without XRender support. (winex11.drv)])
 596
 597         dnl *** Check for X RandR extension
 598         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
 599         then
 600                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 601 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 602                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 603         fi
 604         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xrandr" = "x"],[XRandr development files not found.
 605 Wine will be built without XRandr support. (winex11.drv)])
 606
 607         dnl *** Check for Xinerama extension
 608         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 609         then
 610                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 611 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 612                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 613         fi
 614         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xinerama" = "x"],[Xinerama development files not found.
 615 Wine will be built without Xinerama support. (winex11.drv)])
 616
 617     dnl *** End of X11/Xlib.h check
 618
 619     dnl Check for the presence of OpenGL
 620     if test "x$with_opengl" != "xno"
 621     then
 622         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 623 [#ifdef HAVE_GL_GLX_H
 624 # include <GL/glx.h>
 625 #endif])
 626         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 627         then
 628             dnl Check for some problems due to old Mesa versions
 629             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 630               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 631                 [wine_cv_opengl_header_version_OK="yes"],
 632                 [wine_cv_opengl_header_version_OK="no"]))
 633
 634             if test "$wine_cv_opengl_header_version_OK" = "yes"
 635             then
 636                 dnl Check for the presence of the library
 637                 WINE_CHECK_SONAME(GL,glXCreateContext,
 638                              [OPENGL_LIBS="-lGL"
 639                              OPENGLFILES='$(OPENGLFILES)'
 640                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 641                              [if test -f /usr/X11R6/lib/libGL.a
 642                               then
 643                                   WINE_WARNING([/usr/X11R6/lib/libGL.a is present on your system.
 644 This probably prevents linking to OpenGL. Try deleting the file and restarting configure.])
 645                               else
 646                                   WINE_WARNING([No OpenGL library found on this system.
 647 Wine will be build without OpenGL or Direct3D support.])
 648                               fi],
 649                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 650
 651                 dnl Check for GLU32 library.
 652                 AC_CHECK_LIB(GLU,gluLookAt,
 653                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 654                              GLU32FILES='$(GLU32FILES)']
 655                              ,,
 656                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 657              else
 658                  WINE_WARNING([Old Mesa headers detected. Consider upgrading your Mesa libraries (http://www.mesa3d.org/).
 659 Wine will be build without OpenGL or Direct3D support.])
 660              fi
 661          else
 662              WINE_WARNING([OpenGL development headers not found.
 663 Wine will be build without OpenGL or Direct3D support.])
 664          fi
 665     fi
 666
 667     dnl **** Check for NAS ****
 668     AC_SUBST(NASLIBS,"")
 669     AC_CHECK_HEADERS(audio/audiolib.h,
 670          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 671           AC_CHECK_LIB(audio,AuCreateFlow,
 672                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 673                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 674                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 675                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 676                           [$X_LIBS])
 677                        ],,
 678                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 679
 680     CPPFLAGS="$ac_save_CPPFLAGS"
 681     XFILES='$(XFILES)'
 682 else
 683     XLIB=""
 684     X_CFLAGS=""
 685     X_LIBS=""
 686     WINE_WARNING([X development files not found. Wine will be built
 687 without X support, which probably isn't what you want. You will need to install
 688 development packages of Xlib/Xfree86 at the very least.])
 689 fi
 690
 691 dnl **** Check for libxml2 ****
 692
 693 AC_SUBST(XML2LIBS,"")
 694 AC_SUBST(XML2INCL,"")
 695 AC_SUBST(XSLTLIBS,"")
 696 AC_SUBST(XSLTINCL,"")
 697 ac_save_CPPFLAGS="$CPPFLAGS"
 698 if test "$PKG_CONFIG" != "false"
 699 then
 700     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 701     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 702 else
 703     ac_xml_libs="`xml2-config --libs 2>/dev/null`"
 704     ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
 705 fi
 706 CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 707 AC_CHECK_HEADERS(libxml/parser.h,
 708         [AC_CHECK_LIB(xml2, xmlParseMemory,
 709             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 710              XML2LIBS="$ac_xml_libs"
 711              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 712          AC_CHECK_LIB(xml2, xmlReadMemory,
 713             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 714          AC_CHECK_LIB(xml2, xmlNewDocPI,
 715             [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 716     ])
 717 CPPFLAGS="$ac_save_CPPFLAGS"
 718 WINE_NOTICE_IF([test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],[libxml2 development files not found.
 719 Wine will be built without XML support. (msxml.dll)])
 720
 721 if test "$PKG_CONFIG" != "false"
 722 then
 723     ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 724     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 725 else
 726     ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
 727     ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
 728 fi
 729 CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 730 AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 731         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 732             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 733              XSLTLIBS="$ac_xslt_libs"
 734              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 735         ],,
 736 [#ifdef HAVE_LIBXSLT_PATTERN_H
 737 # include <libxslt/pattern.h>
 738 #endif])
 739 CPPFLAGS="$ac_save_CPPFLAGS"
 740 WINE_NOTICE_IF([test "$ac_cv_lib_xslt_xsltCompilePattern" != "yes"],[libxslt development files not found.
 741 Wine will be built without xslt support. (msxml.dll)])
 742
 743 dnl **** Check for libhal ****
 744 AC_SUBST(HALINCL,"")
 745 if test "$PKG_CONFIG" != "false"
 746 then
 747     ac_save_CPPFLAGS="$CPPFLAGS"
 748     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 749     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 750     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 751     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 752     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 753     then
 754         AC_CHECK_LIB(dbus-1, dbus_connection_close,
 755           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
 756             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
 757     fi
 758     CPPFLAGS="$ac_save_CPPFLAGS"
 759 fi
 760 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_hal" = "x"],[libhal development files not found.
 761 Wine will be built without dynamic device support. (explorer.exe)])
 762
 763 dnl **** Check which curses lib to use ***
 764 CURSESLIBS=""
 765 if test "$ac_cv_header_ncurses_h" = "yes"
 766 then
 767     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
 768 elif test "$ac_cv_header_curses_h" = "yes"
 769 then
 770     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
 771 fi
 772 ac_save_LIBS="$LIBS"
 773 LIBS="$LIBS $CURSESLIBS"
 774 AC_CHECK_FUNCS(mousemask)
 775 LIBS="$ac_save_LIBS"
 776 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],[lib(n)curses development files not found.
 777 Wine will be built without (n)curses support. (wineconsole.exe)])
 778
 779 dnl **** Check for SANE ****
 780 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 781 if test "$sane_devel" != "no"
 782 then
 783     ac_sane_incl="`$sane_devel --cflags`"
 784     ac_save_CPPFLAGS="$CPPFLAGS"
 785     CPPFLAGS="$CPPFLAGS $ac_sane_incl"
 786     AC_CHECK_HEADER(sane/sane.h,
 787         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")])])
 788     CPPFLAGS="$ac_save_CPPFLAGS"
 789 fi
 790 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_sane" = "x"],[libsane development files not found.
 791 Wine will be built without scanner support. (sane.ds/twain_32.dll)])
 792
 793 dnl **** Check for libgphoto2 ****
 794 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 795 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 796 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
 797 then
 798     ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 799     ac_gphoto2_libs=""
 800     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 801     do
 802       case "$i" in
 803         -L/usr/lib|-L/usr/lib64) ;;
 804         -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
 805       esac
 806     done
 807     ac_save_CPPFLAGS="$CPPFLAGS"
 808     CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
 809     AC_CHECK_HEADER(gphoto2-camera.h,
 810                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 811                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
 812                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
 813                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
 814                                   [$GPHOTO2LIBS])])
 815     CPPFLAGS="$ac_save_CPPFLAGS"
 816 fi
 817 WINE_NOTICE_IF([test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],[libgphoto2 development files not found.
 818 Wine will be built without Digital Camera support. (gphoto2.ds/twain_32.dll)])
 819
 820
 821 dnl **** Check for resolver library ***
 822 AC_SUBST(RESOLVLIBS,"")
 823 if test "$ac_cv_header_resolv_h" = "yes"
 824 then
 825     AC_CHECK_LIB(resolv, res_query,
 826         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 827          RESOLVLIBS="-lresolv"])
 828 fi
 829
 830 dnl **** Check for LittleCMS ***
 831 AC_SUBST(LCMSLIBS,"")
 832 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 833 then
 834     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 835         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 836          LCMSLIBS="-llcms"])
 837 fi
 838 WINE_NOTICE_IF([test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],[liblcms development files not found.
 839 Wine will be built without Color Management support. (mscms.dll)])
 840
 841 dnl **** Check for OpenLDAP ***
 842 AC_SUBST(LDAPLIBS,"")
 843 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 844 then
 845     AC_CHECK_LIB(ldap_r, ldap_initialize,
 846         [AC_CHECK_LIB(lber, ber_init,
 847             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 848              LDAPLIBS="-lldap_r -llber"],,
 849              [$LIBPTHREAD])],,
 850              [$LIBPTHREAD])
 851     WINE_CHECK_LIB_FUNCS(\
 852         ldap_count_references \
 853         ldap_first_reference \
 854         ldap_next_reference \
 855         ldap_parse_reference,
 856         [$LDAPLIBS $LIBPTHREAD])
 857 fi
 858 WINE_NOTICE_IF([test "x$LDAPLIBS" = "x"],[libldap (OpenLDAP) development files not found.
 859 Wine will be built without LDAP support. (wldap32.dll)])
 860
 861 dnl **** Check for FreeType 2 ****
 862 AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],false)
 863 if test "$ft_devel" != "false"
 864 then
 865     ac_freetype_libs=`$ft_devel --libs`
 866     ac_freetype_incl=`$ft_devel --cflags`
 867     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
 868     if test "$ft_lib" = "yes"
 869     then
 870         ac_save_CPPFLAGS="$CPPFLAGS"
 871         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
 872         AC_CHECK_HEADERS(ft2build.h \
 873                          freetype/freetype.h \
 874                          freetype/ftglyph.h \
 875                          freetype/fttypes.h \
 876                          freetype/tttables.h \
 877                          freetype/ftnames.h \
 878                          freetype/ftsnames.h \
 879                          freetype/ttnameid.h \
 880                          freetype/ftoutln.h \
 881                          freetype/ftwinfnt.h \
 882                          freetype/ftmodapi.h \
 883                          freetype/internal/sfnt.h,,,
 884                          [#if HAVE_FT2BUILD_H
 885                           #include <ft2build.h>
 886                           #endif])
 887         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
 888                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 889           [Define if you have the <freetype/fttrigon.h> header file.])
 890                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
 891         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 892         ac_save_CFLAGS="$CFLAGS"
 893         CFLAGS="$CFLAGS $ac_freetype_libs"
 894         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 895         CFLAGS="$ac_save_CFLAGS"
 896         CPPFLAGS="$ac_save_CPPFLAGS"
 897         dnl Check that we have at least freetype/freetype.h
 898         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 899         then
 900             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 901             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
 902             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
 903         fi
 904     fi
 905 fi
 906
 907 dnl Only build the fonts dir if we have both freetype and fontforge
 908 if test "$FONTFORGE" = "false"
 909 then
 910     WINE_WARNING([FontForge is missing.
 911 Fonts will not be built. Dialog text may be invisible or unaligned.])
 912 elif test "x$FREETYPELIBS" = "x"
 913 then
 914     WINE_WARNING([FreeType development files not found.
 915 Fonts will not be built. Dialog text may be invisible or unaligned.])
 916 else
 917   AC_SUBST(FONTSSUBDIRS,"fonts")
 918 fi
 919
 920 dnl **** Check for parport (currently Linux only) ****
 921 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 922  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
 923     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
 924 if test "$ac_cv_c_ppdev" = "yes"
 925 then
 926     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 927 fi
 928
 929 dnl **** Check for va_copy ****
 930 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 931  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; va_copy(ap1,ap2);]])],
 932     [ac_cv_c_va_copy="yes"],[ac_cv_c_va_copy="no"])
 933  )
 934 if test "$ac_cv_c_va_copy" = "yes"
 935 then
 936     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 937 fi
 938 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 939  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; __va_copy(ap1,ap2);]])],
 940     [ac_cv_c___va_copy="yes"],[ac_cv_c___va_copy="no"])
 941  )
 942 if test "$ac_cv_c___va_copy" = "yes"
 943 then
 944     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 945 fi
 946
 947 dnl **** Check for sigsetjmp ****
 948 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 949  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]], [[sigjmp_buf buf;
 950     sigsetjmp( buf, 1 );
 951     siglongjmp( buf, 1 );]])],[ac_cv_c_sigsetjmp="yes"],[ac_cv_c_sigsetjmp="no"])
 952  )
 953 if test "$ac_cv_c_sigsetjmp" = "yes"
 954 then
 955     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 956 fi
 957
 958 dnl **** Check for pthread_rwlock_t ****
 959 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 960 #include <pthread.h>])
 961
 962 dnl **** Check for pthread functions ****
 963 WINE_CHECK_LIB_FUNCS(\
 964         pthread_attr_get_np \
 965         pthread_getattr_np \
 966         pthread_get_stackaddr_np \
 967         pthread_get_stacksize_np,
 968         [$LIBPTHREAD])
 969
 970 dnl **** Check for EsounD ****
 971 AC_PATH_PROG(ESDCONFIG, esd-config)
 972 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 973 then
 974     ESD_CFLAGS=""
 975     for i in `$ESDCONFIG --cflags`
 976     do
 977       case "$i" in
 978         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 979       esac
 980     done
 981     ESD_LIBS=`$ESDCONFIG --libs`
 982     save_CFLAGS="$CFLAGS"
 983     CFLAGS="$CFLAGS $ESD_CFLAGS"
 984     AC_CHECK_LIB(esd,esd_open_sound,
 985         [AC_SUBST(ESDLIBS, $ESD_LIBS)
 986          AC_SUBST(ESDINCL, $ESD_CFLAGS)
 987          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
 988     CFLAGS="$save_CFLAGS"
 989 fi
 990
 991 dnl **** Check for ALSA 1.x ****
 992 AC_SUBST(ALSALIBS,"")
 993 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 994 then
 995     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 996         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
 997 #include <alsa/asoundlib.h>
 998 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 999 #include <sys/asoundlib.h>
1000 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
1001                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
1002                          ALSALIBS="-lasound"],[])])
1003 fi
1004
1005 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
1006 AC_SUBST(AUDIOIOLIBS,"")
1007 if test "$ac_cv_header_libaudioio_h" = "yes"
1008 then
1009     AC_CHECK_LIB(audioio,AudioIOGetVersion,
1010                   [AUDIOIOLIBS="-laudioio"
1011                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
1012 fi
1013
1014 dnl **** Check for capi4linux ****
1015
1016 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1017 then
1018     WINE_CHECK_SONAME(capi20,capi20_register)
1019 fi
1020 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_capi20" = "x"],[libcapi20 development files not found.
1021 Wine will be built without ISDN support. (capi2032.dll)])
1022
1023 dnl **** Check for cups ****
1024 if test "$ac_cv_header_cups_cups_h" = "yes"
1025 then
1026     WINE_CHECK_SONAME(cups,cupsGetDefault)
1027 fi
1028 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_cups" = "x"],[libcups development files not found.
1029 Wine will be built without CUPS support.])
1030
1031 dnl **** Check for jack ****
1032 if test "$ac_cv_header_jack_jack_h" = "yes"
1033 then
1034     WINE_CHECK_SONAME(jack,jack_client_new)
1035 fi
1036
1037 dnl **** Check for fontconfig ****
1038 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1039 then
1040     WINE_CHECK_SONAME(fontconfig,FcInit)
1041 fi
1042 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_fontconfig" = "x"],[fontconfig development files not found.
1043 Wine will be built without fontconfig support.])
1044
1045 dnl **** Check for SSL ****
1046 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1047 then
1048     WINE_CHECK_SONAME(ssl,SSL_library_init)
1049     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1050 fi
1051 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_ssl" = "x"],[OpenSSL development files not found.
1052 Wine will be built without SSL support. (wininet.dll)])
1053
1054 dnl **** Check for libjpeg ****
1055 if test "$ac_cv_header_jpeglib_h" = "yes"
1056 then
1057     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1058 fi
1059 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_jpeg" = "x"],[libjpeg development files not found.
1060 Wine will be built without JPEG support. (oleaut32.dll)])
1061
1062 dnl **** Check for libpng ****
1063 if test "$ac_cv_header_png_h" = "yes"
1064 then
1065     WINE_CHECK_SONAME(png,png_create_read_struct,,,,[[libpng[[0-9]]*]])
1066 fi
1067 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_png" = "x"],[libpng development files not found.
1068 Wine will be built without PNG support. (oleaut32.dll)])
1069
1070 dnl **** Check for any sound system ****
1071 WINE_WARNING_IF([test "x$ALSALIBS$AUDIOIOLIBS$COREAUDIO$NASLIBS$ESD_LIBS$ac_cv_lib_soname_jack" = "x" -a \
1072                  "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1073                  "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1074                  "$ac_cv_header_soundcard_h" != "yes"],
1075 [No sound system was found. Windows applications will be silent.])
1076
1077 dnl **** Check for gcc specific options ****
1078
1079 AC_SUBST(EXTRACFLAGS,"")
1080 if test "x${GCC}" = "xyes"
1081 then
1082   EXTRACFLAGS="-Wall -pipe"
1083
1084   dnl Check for strength-reduce bug
1085   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1086                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1087 [[static int Array[[3]];
1088   unsigned int B = 3;
1089   int i;
1090   for(i=0; i<B; i++) Array[[i]] = i - 3;
1091   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1092   L[[i]] = 4;
1093   exit( Array[[1]] != -2 || L[[2]] != 3)]])],
1094     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1095   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1096   then
1097     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1098   fi
1099
1100   dnl Check for some compiler flags
1101
1102   WINE_TRY_CFLAGS([-fshort-wchar],
1103                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
1104                              [Specifies the compiler flag that forces a short wchar_t])])
1105   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1106   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1107   WINE_TRY_CFLAGS([-Wwrite-strings])
1108
1109   dnl Check for noisy string.h
1110   saved_CFLAGS="$CFLAGS"
1111   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1112   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1113       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1114   CFLAGS="$saved_CFLAGS"
1115   if test "$ac_cv_c_string_h_warnings" = "no"
1116   then
1117     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1118   fi
1119
1120   AC_SUBST(BUILTINFLAG,"")
1121   saved_CFLAGS="$CFLAGS"
1122   CFLAGS="$CFLAGS -Werror"
1123   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
1124       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int iswlower(unsigned short);]])],[ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
1125   CFLAGS="$saved_CFLAGS"
1126   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
1127   then
1128     BUILTINFLAG="-fno-builtin"
1129   fi
1130 fi
1131
1132 dnl **** Check how to define a function in assembly code ****
1133
1134 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1135   WINE_TRY_ASM_LINK(
1136       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1137       ac_cv_asm_func_def=".def",
1138     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1139       ac_cv_asm_func_def=".type @function",
1140     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1141       ac_cv_asm_func_def=".type 2",
1142       ac_cv_asm_func_def="unknown")])]))
1143
1144 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1145 case "$ac_cv_asm_func_def" in
1146   ".def")
1147      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
1148   ".type @function")
1149      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
1150   ".type 2")
1151      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
1152   *)
1153      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
1154 esac
1155
1156 dnl **** Check for underscore on external symbols ****
1157
1158 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1159     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1160                       [extern int ac_test;],
1161                       [if (ac_test) return 1],
1162                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1163
1164 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1165 if test "$ac_cv_c_extern_prefix" = "yes"
1166 then
1167   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1168 else
1169   AC_DEFINE([__ASM_NAME(name)], [name])
1170 fi
1171
1172 dnl **** Platform-specific checks ****
1173
1174 AC_SUBST(LDPATH,"")
1175 case $build_os in
1176   cygwin*|mingw32*)
1177     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1178     ;;
1179   darwin*|macosx*)
1180     ;;
1181   linux*|solaris*)  dnl FIXME: What other platforms support $ORIGIN?
1182     if test -z "$LDRPATH_LOCAL"
1183     then
1184       LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1185     fi
1186     ;;
1187   *)
1188     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1189     ;;
1190 esac
1191
1192 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1193 case $host_os in
1194   mingw32*)
1195     AC_SUBST(CRTLIBS,"-lmsvcrt")
1196     AC_SUBST(SOCKETLIBS,"-lws2_32")
1197     ;;
1198 esac
1199
1200 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1201 case $host_cpu in
1202   *i[[3456789]]86*)
1203     case $host_os in
1204       linux* | k*bsd*-gnu)
1205         AC_SUBST(MAIN_BINARY,"wine-glibc")
1206         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1207       freebsd*)
1208         AC_SUBST(MAIN_BINARY,"wine-freebsd")
1209         AC_SUBST(EXTRA_BINARIES,"wine-pthread") ;;
1210     esac
1211     ;;
1212 esac
1213
1214 dnl **** Check for functions ****
1215
1216 AC_CHECK_FUNCS(\
1217         _pclose \
1218         _popen \
1219         _snprintf \
1220         _spawnvp \
1221         _stricmp \
1222         _strnicmp \
1223         _vsnprintf \
1224         asctime_r \
1225         chsize \
1226         clone \
1227         dlopen \
1228         epoll_create \
1229         ffs \
1230         finite \
1231         fork \
1232         fpclass \
1233         fstatfs \
1234         fstatvfs \
1235         ftruncate \
1236         futimes \
1237         futimesat \
1238         getdirentries \
1239         getopt_long \
1240         getpagesize \
1241         getpwuid \
1242         gettid \
1243         gettimeofday \
1244         getuid \
1245         inet_pton \
1246         kqueue \
1247         lstat \
1248         memmove \
1249         mmap \
1250         pclose \
1251         poll \
1252         popen \
1253         prctl \
1254         pread \
1255         pwrite \
1256         readlink \
1257         rfork \
1258         sched_yield \
1259         select \
1260         setrlimit \
1261         settimeofday \
1262         sigaltstack \
1263         sigprocmask \
1264         snprintf \
1265         spawnvp \
1266         statfs \
1267         statvfs \
1268         strcasecmp \
1269         strerror \
1270         strncasecmp \
1271         strtold \
1272         tcgetattr \
1273         thr_kill2 \
1274         timegm \
1275         usleep \
1276         vsnprintf \
1277         wait4 \
1278         waitpid \
1279 )
1280
1281 dnl Check for -ldl
1282 if test "$ac_cv_func_dlopen" = no
1283 then
1284     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1285 fi
1286 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1287
1288 dnl Check for -lpoll for Mac OS X/Darwin
1289 if test "$ac_cv_func_poll" = no
1290 then
1291     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1292 fi
1293
1294 dnl Check for -lnsl for Solaris
1295 AC_SEARCH_LIBS(gethostbyname, nsl)
1296
1297 dnl Check for -lsocket for Solaris
1298 AC_SEARCH_LIBS(connect, socket)
1299
1300 dnl Check for -lresolv for Solaris
1301 AC_SEARCH_LIBS(inet_aton, resolv)
1302
1303 dnl **** Check for functions which may rely on -lsocket on Solaris.
1304 AC_CHECK_FUNCS(\
1305         getaddrinfo \
1306         getnameinfo \
1307         getnetbyname \
1308         getprotobyname \
1309         getprotobynumber \
1310         getservbyport \
1311         inet_network \
1312         sendmsg \
1313 )
1314
1315 dnl **** Check for types ****
1316
1317 AC_C_CONST
1318 AC_C_INLINE
1319 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1320 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1321 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1322
1323 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1324 [#ifdef HAVE_LINUX_INPUT_H
1325 #include <linux/input.h>
1326 #endif])
1327
1328 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1329                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1330 if test "$wine_cv_have_sigaddset" = "yes"
1331 then
1332   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1333 fi
1334
1335
1336 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1337         wine_cv_linux_gethostbyname_r_6,
1338         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1339     char *name=NULL;
1340     struct hostent he;
1341     struct hostent *result;
1342     char *buf=NULL;
1343     int bufsize=0;
1344     int res,errnr;
1345     char *addr=NULL;
1346     int addrlen=0;
1347     int addrtype=0;
1348     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1349     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1350     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1351         ])
1352    )
1353    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1354    then
1355       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1356                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1357    fi
1358
1359 if test "$ac_cv_header_linux_joystick_h" = "yes"
1360 then
1361    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1362         wine_cv_linux_joystick_22_api,
1363         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1364         #include <sys/ioctl.h>
1365         #include <sys/types.h>
1366         #include <linux/joystick.h>
1367
1368         struct js_event blub;
1369         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1370         #error "no 2.2 header"
1371         #endif
1372         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1373    )
1374    if test "$wine_cv_linux_joystick_22_api" = "yes"
1375    then
1376       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1377                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1378    fi
1379 fi
1380
1381 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1382
1383 dnl Check for statfs members
1384 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1385 [#include <sys/types.h>
1386 #ifdef HAVE_SYS_PARAM_H
1387 # include <sys/param.h>
1388 #endif
1389 #ifdef HAVE_SYS_MOUNT_H
1390 # include <sys/mount.h>
1391 #endif
1392 #ifdef HAVE_SYS_VFS_H
1393 # include <sys/vfs.h>
1394 #endif
1395 #ifdef HAVE_SYS_STATFS_H
1396 # include <sys/statfs.h>
1397 #endif])
1398
1399 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1400 [#ifdef HAVE_SYS_STATVFS_H
1401 #include <sys/statvfs.h>
1402 #endif])
1403
1404 dnl Check for socket structure members
1405 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1406 [#include <sys/types.h>
1407 #ifdef HAVE_SYS_SOCKET_H
1408 # include <sys/socket.h>
1409 #endif
1410 #ifdef HAVE_SYS_UN_H
1411 # include <sys/un.h>
1412 #endif])
1413
1414 dnl Check for scsireq_t and sg_io_hdr_t members
1415 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1416 [#include <sys/types.h>
1417 #ifdef HAVE_SCSI_SG_H
1418 #include <scsi/sg.h>
1419 #endif])
1420
1421 dnl Check for siginfo_t members
1422 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1423
1424 dnl Check for struct mtget members
1425 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1426 [#include <sys/types.h>
1427 #ifdef HAVE_SYS_MTIO_H
1428 #include <sys/mtio.h>
1429 #endif])
1430
1431 dnl Check for struct option
1432 AC_CHECK_MEMBERS([struct option.name],,,
1433 [#ifdef HAVE_GETOPT_H
1434 #include <getopt.h>
1435 #endif])
1436
1437 dnl Check for stat.st_blocks
1438 AC_CHECK_MEMBERS([struct stat.st_blocks])
1439
1440 dnl Check for sin6_scope_id
1441 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1442 [#ifdef HAVE_SYS_TYPES_H
1443 #include <sys/types.h>
1444 #endif
1445 #ifdef HAVE_NETINET_IN_H
1446 #include <netinet/in.h>
1447 #endif])
1448
1449 dnl Check for ns_msg ptr member
1450 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1451 [#ifdef HAVE_SYS_TYPES_H
1452 #include <sys/types.h>
1453 #endif
1454 #ifdef HAVE_NETINET_IN_H
1455 # include <netinet/in.h>
1456 #endif
1457 #ifdef HAVE_ARPA_NAMESER_H
1458 # include <arpa/nameser.h>
1459 #endif])
1460
1461 dnl Check for the external timezone variables timezone and daylight
1462 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1463                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
1464 if test "$ac_cv_have_timezone" = "yes"
1465 then
1466     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1467 fi
1468 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1469                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
1470 if test "$ac_cv_have_daylight" = "yes"
1471 then
1472     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1473 fi
1474
1475 dnl *** check for the need to define platform-specific symbols
1476
1477 case $host_cpu in
1478   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1479   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1480   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1481   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1482   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1483 esac
1484
1485 case $host_vendor in
1486   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1487 esac
1488
1489 dnl **** Generate output files ****
1490
1491 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1492 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1493 ["### Dependencies:\\
1494 \\
1495 .INIT: Makefile\\
1496 .BEGIN: Makefile\\
1497 Makefile: dummy\\
1498         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1499 \\
1500 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1501 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1502 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1503 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1504 ["### Dependencies:
1505
1506 .INIT: Makefile
1507 .BEGIN: Makefile
1508 Makefile: dummy
1509         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1510
1511 \$(OBJS): \$(IDL_GEN_HEADERS)
1512 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1513 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1514 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1515
1516 AH_TOP([#define __WINE_CONFIG_H])
1517
1518 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1519
1520 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1521 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1522 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1523 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1524 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1525 WINE_CONFIG_EXTRA_DIR(include/wine)
1526
1527 MAKE_RULES=Make.rules
1528 AC_SUBST_FILE(MAKE_RULES)
1529
1530 MAKE_DLL_RULES=dlls/Makedll.rules
1531 AC_SUBST_FILE(MAKE_DLL_RULES)
1532
1533 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1534 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1535
1536 MAKE_TEST_RULES=dlls/Maketest.rules
1537 AC_SUBST_FILE(MAKE_TEST_RULES)
1538
1539 MAKE_PROG_RULES=programs/Makeprog.rules
1540 AC_SUBST_FILE(MAKE_PROG_RULES)
1541
1542 AC_CONFIG_FILES([Make.rules])
1543 AC_CONFIG_FILES([dlls/Makedll.rules])
1544 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1545 AC_CONFIG_FILES([dlls/Maketest.rules])
1546 AC_CONFIG_FILES([programs/Makeprog.rules])
1547 AC_CONFIG_FILES([Makefile])
1548 AC_CONFIG_FILES([dlls/Makefile])
1549 AC_CONFIG_FILES([dlls/acledit/Makefile])
1550 AC_CONFIG_FILES([dlls/activeds/Makefile])
1551 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1552 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1553 AC_CONFIG_FILES([dlls/advpack/Makefile])
1554 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1555 AC_CONFIG_FILES([dlls/amstream/Makefile])
1556 AC_CONFIG_FILES([dlls/atl/Makefile])
1557 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1558 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1559 AC_CONFIG_FILES([dlls/browseui/Makefile])
1560 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1561 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1562 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1563 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1564 AC_CONFIG_FILES([dlls/cards/Makefile])
1565 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1566 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1567 AC_CONFIG_FILES([dlls/comcat/Makefile])
1568 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1569 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1570 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1571 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1572 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1573 AC_CONFIG_FILES([dlls/compstui/Makefile])
1574 AC_CONFIG_FILES([dlls/credui/Makefile])
1575 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1576 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1577 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1578 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1579 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1580 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1581 AC_CONFIG_FILES([dlls/d3d10/Makefile])
1582 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1583 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1584 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1585 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1586 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1587 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1588 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1589 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1590 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1591 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1592 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1593 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1594 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1595 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1596 AC_CONFIG_FILES([dlls/devenum/Makefile])
1597 AC_CONFIG_FILES([dlls/dinput/Makefile])
1598 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1599 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1600 AC_CONFIG_FILES([dlls/dmband/Makefile])
1601 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1602 AC_CONFIG_FILES([dlls/dmime/Makefile])
1603 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1604 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1605 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1606 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1607 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1608 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1609 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1610 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1611 AC_CONFIG_FILES([dlls/dplay/Makefile])
1612 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1613 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1614 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1615 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1616 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1617 AC_CONFIG_FILES([dlls/dpnlobby/Makefile])
1618 AC_CONFIG_FILES([dlls/dsound/Makefile])
1619 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1620 AC_CONFIG_FILES([dlls/dswave/Makefile])
1621 AC_CONFIG_FILES([dlls/dwmapi/Makefile])
1622 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1623 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1624 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1625 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1626 AC_CONFIG_FILES([dlls/faultrep/Makefile])
1627 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1628 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1629 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1630 AC_CONFIG_FILES([dlls/gdiplus/tests/Makefile])
1631 AC_CONFIG_FILES([dlls/glu32/Makefile])
1632 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1633 AC_CONFIG_FILES([dlls/hal/Makefile])
1634 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1635 AC_CONFIG_FILES([dlls/hid/Makefile])
1636 AC_CONFIG_FILES([dlls/hlink/Makefile])
1637 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1638 AC_CONFIG_FILES([dlls/hnetcfg/Makefile])
1639 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1640 AC_CONFIG_FILES([dlls/icmp/Makefile])
1641 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1642 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1643 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1644 AC_CONFIG_FILES([dlls/imm32/Makefile])
1645 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1646 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1647 AC_CONFIG_FILES([dlls/inkobj/Makefile])
1648 AC_CONFIG_FILES([dlls/inseng/Makefile])
1649 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1650 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1651 AC_CONFIG_FILES([dlls/itss/Makefile])
1652 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1653 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1654 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1655 AC_CONFIG_FILES([dlls/localspl/Makefile])
1656 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1657 AC_CONFIG_FILES([dlls/localui/Makefile])
1658 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1659 AC_CONFIG_FILES([dlls/lz32/Makefile])
1660 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1661 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1662 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1663 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1664 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1665 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1666 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1667 AC_CONFIG_FILES([dlls/midimap/Makefile])
1668 AC_CONFIG_FILES([dlls/mlang/Makefile])
1669 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1670 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1671 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1672 AC_CONFIG_FILES([dlls/mpr/Makefile])
1673 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1674 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1675 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1676 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1677 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1678 AC_CONFIG_FILES([dlls/mscms/Makefile])
1679 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1680 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1681 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1682 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1683 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1684 AC_CONFIG_FILES([dlls/mshtml.tlb/Makefile])
1685 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1686 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1687 AC_CONFIG_FILES([dlls/msi/Makefile])
1688 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1689 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1690 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1691 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1692 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1693 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1694 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1695 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1696 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1697 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1698 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1699 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1700 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1701 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1702 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1703 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1704 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1705 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1706 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1707 AC_CONFIG_FILES([dlls/newdev/Makefile])
1708 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1709 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1710 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1711 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1712 AC_CONFIG_FILES([dlls/ntprint/Makefile])
1713 AC_CONFIG_FILES([dlls/ntprint/tests/Makefile])
1714 AC_CONFIG_FILES([dlls/objsel/Makefile])
1715 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1716 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1717 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1718 AC_CONFIG_FILES([dlls/ole32/Makefile])
1719 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1720 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1721 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1722 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1723 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1724 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1725 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1726 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1727 AC_CONFIG_FILES([dlls/olethk32/Makefile])
1728 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1729 AC_CONFIG_FILES([dlls/opengl32/tests/Makefile])
1730 AC_CONFIG_FILES([dlls/pdh/Makefile])
1731 AC_CONFIG_FILES([dlls/pdh/tests/Makefile])
1732 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1733 AC_CONFIG_FILES([dlls/printui/Makefile])
1734 AC_CONFIG_FILES([dlls/psapi/Makefile])
1735 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1736 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1737 AC_CONFIG_FILES([dlls/qcap/Makefile])
1738 AC_CONFIG_FILES([dlls/quartz/Makefile])
1739 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1740 AC_CONFIG_FILES([dlls/query/Makefile])
1741 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1742 AC_CONFIG_FILES([dlls/resutils/Makefile])
1743 AC_CONFIG_FILES([dlls/riched20/Makefile])
1744 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1745 AC_CONFIG_FILES([dlls/riched32/Makefile])
1746 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1747 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1748 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1749 AC_CONFIG_FILES([dlls/rsabase/tests/Makefile])
1750 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1751 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1752 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1753 AC_CONFIG_FILES([dlls/schannel/Makefile])
1754 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1755 AC_CONFIG_FILES([dlls/secur32/Makefile])
1756 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1757 AC_CONFIG_FILES([dlls/security/Makefile])
1758 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1759 AC_CONFIG_FILES([dlls/serialui/Makefile])
1760 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1761 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1762 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1763 AC_CONFIG_FILES([dlls/sfc/Makefile])
1764 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1765 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1766 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1767 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1768 AC_CONFIG_FILES([dlls/shell32/Makefile])
1769 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1770 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1771 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1772 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1773 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1774 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1775 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1776 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1777 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1778 AC_CONFIG_FILES([dlls/sti/Makefile])
1779 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1780 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1781 AC_CONFIG_FILES([dlls/sxs/Makefile])
1782 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1783 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1784 AC_CONFIG_FILES([dlls/unicows/Makefile])
1785 AC_CONFIG_FILES([dlls/url/Makefile])
1786 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1787 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1788 AC_CONFIG_FILES([dlls/user32/Makefile])
1789 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
1790 AC_CONFIG_FILES([dlls/userenv/Makefile])
1791 AC_CONFIG_FILES([dlls/usp10/Makefile])
1792 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
1793 AC_CONFIG_FILES([dlls/uuid/Makefile])
1794 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
1795 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
1796 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
1797 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
1798 AC_CONFIG_FILES([dlls/version/Makefile])
1799 AC_CONFIG_FILES([dlls/version/tests/Makefile])
1800 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
1801 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
1802 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
1803 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
1804 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
1805 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
1806 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
1807 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
1808 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
1809 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
1810 AC_CONFIG_FILES([dlls/wined3d/Makefile])
1811 AC_CONFIG_FILES([dlls/winedos/Makefile])
1812 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
1813 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
1814 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
1815 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
1816 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
1817 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
1818 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
1819 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
1820 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
1821 AC_CONFIG_FILES([dlls/wing32/Makefile])
1822 AC_CONFIG_FILES([dlls/winhttp/Makefile])
1823 AC_CONFIG_FILES([dlls/wininet/Makefile])
1824 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
1825 AC_CONFIG_FILES([dlls/winmm/Makefile])
1826 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
1827 AC_CONFIG_FILES([dlls/winnls32/Makefile])
1828 AC_CONFIG_FILES([dlls/winscard/Makefile])
1829 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
1830 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
1831 AC_CONFIG_FILES([dlls/wintab32/Makefile])
1832 AC_CONFIG_FILES([dlls/wintrust/Makefile])
1833 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
1834 AC_CONFIG_FILES([dlls/wldap32/Makefile])
1835 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
1836 AC_CONFIG_FILES([dlls/wow32/Makefile])
1837 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
1838 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
1839 AC_CONFIG_FILES([dlls/wsock32/Makefile])
1840 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
1841 AC_CONFIG_FILES([documentation/Makefile])
1842 AC_CONFIG_FILES([fonts/Makefile])
1843 AC_CONFIG_FILES([include/Makefile])
1844 AC_CONFIG_FILES([libs/Makefile])
1845 AC_CONFIG_FILES([libs/port/Makefile])
1846 AC_CONFIG_FILES([libs/wine/Makefile])
1847 AC_CONFIG_FILES([libs/wpp/Makefile])
1848 AC_CONFIG_FILES([loader/Makefile])
1849 AC_CONFIG_FILES([programs/Makefile])
1850 AC_CONFIG_FILES([programs/clock/Makefile])
1851 AC_CONFIG_FILES([programs/cmd/Makefile])
1852 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
1853 AC_CONFIG_FILES([programs/control/Makefile])
1854 AC_CONFIG_FILES([programs/eject/Makefile])
1855 AC_CONFIG_FILES([programs/expand/Makefile])
1856 AC_CONFIG_FILES([programs/explorer/Makefile])
1857 AC_CONFIG_FILES([programs/hh/Makefile])
1858 AC_CONFIG_FILES([programs/icinfo/Makefile])
1859 AC_CONFIG_FILES([programs/iexplore/Makefile])
1860 AC_CONFIG_FILES([programs/msiexec/Makefile])
1861 AC_CONFIG_FILES([programs/net/Makefile])
1862 AC_CONFIG_FILES([programs/notepad/Makefile])
1863 AC_CONFIG_FILES([programs/oleview/Makefile])
1864 AC_CONFIG_FILES([programs/progman/Makefile])
1865 AC_CONFIG_FILES([programs/regedit/Makefile])
1866 AC_CONFIG_FILES([programs/regsvr32/Makefile])
1867 AC_CONFIG_FILES([programs/rpcss/Makefile])
1868 AC_CONFIG_FILES([programs/rundll32/Makefile])
1869 AC_CONFIG_FILES([programs/spoolsv/Makefile])
1870 AC_CONFIG_FILES([programs/start/Makefile])
1871 AC_CONFIG_FILES([programs/taskmgr/Makefile])
1872 AC_CONFIG_FILES([programs/uninstaller/Makefile])
1873 AC_CONFIG_FILES([programs/view/Makefile])
1874 AC_CONFIG_FILES([programs/wineboot/Makefile])
1875 AC_CONFIG_FILES([programs/winebrowser/Makefile])
1876 AC_CONFIG_FILES([programs/winecfg/Makefile])
1877 AC_CONFIG_FILES([programs/wineconsole/Makefile])
1878 AC_CONFIG_FILES([programs/winedbg/Makefile])
1879 AC_CONFIG_FILES([programs/winedevice/Makefile])
1880 AC_CONFIG_FILES([programs/winefile/Makefile])
1881 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
1882 AC_CONFIG_FILES([programs/winemine/Makefile])
1883 AC_CONFIG_FILES([programs/winepath/Makefile])
1884 AC_CONFIG_FILES([programs/winetest/Makefile])
1885 AC_CONFIG_FILES([programs/winevdm/Makefile])
1886 AC_CONFIG_FILES([programs/winhelp/Makefile])
1887 AC_CONFIG_FILES([programs/winver/Makefile])
1888 AC_CONFIG_FILES([programs/wordpad/Makefile])
1889 AC_CONFIG_FILES([programs/write/Makefile])
1890 AC_CONFIG_FILES([programs/xcopy/Makefile])
1891 AC_CONFIG_FILES([server/Makefile])
1892 AC_CONFIG_FILES([tools/Makefile])
1893 AC_CONFIG_FILES([tools/widl/Makefile])
1894 AC_CONFIG_FILES([tools/winebuild/Makefile])
1895 AC_CONFIG_FILES([tools/winedump/Makefile])
1896 AC_CONFIG_FILES([tools/winegcc/Makefile])
1897 AC_CONFIG_FILES([tools/wmc/Makefile])
1898 AC_CONFIG_FILES([tools/wrc/Makefile])
1899
1900 AC_OUTPUT
1901
1902 if test "$no_create" = "yes"
1903 then
1904   exit 0
1905 fi
1906
1907 WINE_PRINT_MESSAGES
1908
1909 echo
1910 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1911 echo
1912
1913 dnl Local Variables:
1914 dnl comment-start: "dnl "
1915 dnl comment-end: ""
1916 dnl comment-start-skip: "\\bdnl\\b\\s *"
1917 dnl compile-command: "autoreconf --warnings=all"
1918 dnl End: