| blob | 8f718b3e887abc3515515a1e478608325ce5ab5f |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION)
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
19 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
20 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
21 AC_ARG_WITH(nptl, AC_HELP_STRING([--with-nptl],[use glibc NPTL threading support]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
25 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
26 if test "x$enable_win16" = "xno"
27 then
28 WIN16_FILES=""
29 WIN16_INSTALL=""
30 fi
31 if test "x$enable_debug" = "xno"
32 then
33 AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
34 fi
35 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
36 then
37 AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
38 fi
39 if test "x$with_nptl" = "xyes"
40 then
41 AC_DEFINE(HAVE_NPTL,1,[Define to use glibc NPTL threading support.])
42 AC_SUBST(LIBPTHREAD,"-lpthread")
43 fi
45 dnl **** Check for some programs ****
47 AC_CANONICAL_HOST
48 AC_PROG_MAKE_SET
49 AC_PROG_CC
50 AC_PROG_CPP
52 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
53 [if test -z "$with_wine_tools"; then
54 if test "$cross_compiling" = "yes"; then
55 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
56 else
57 wine_cv_toolsdir="\$(TOPOBJDIR)"
58 fi
59 elif test -d "$with_wine_tools/tools/winebuild"; then
60 case $with_wine_tools in
61 /*) wine_cv_toolsdir="$with_wine_tools" ;;
62 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
63 esac
64 else
65 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
66 fi])
67 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
69 AC_PATH_XTRA
70 AC_PROG_YACC
71 AC_PROG_LEX
73 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
74 dnl **** without one present.
75 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
76 if test "$XYACC" = "none"
77 then
78 AC_MSG_ERROR([no suitable bison/yacc found. Please install the 'bison' package.])
79 fi
80 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
81 if test "$XLEX" = "none"
82 then
83 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
84 fi
86 AC_CHECK_TOOLS(AS,[gas as],as)
87 AC_CHECK_TOOL(LD,ld,ld)
88 AC_CHECK_TOOL(AR,ar,ar)
89 AC_PROG_RANLIB
90 AC_CHECK_TOOL(STRIP,strip,strip)
91 AC_CHECK_TOOL(WINDRES,windres,false)
92 AC_PROG_LN_S
93 WINE_PROG_LN
94 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
95 AC_PROG_INSTALL
96 dnl Prepend src dir to install path dir if it's a relative path
97 case "$INSTALL" in
98 [[\\/$]]* | ?:[[\\/]]* ) ;;
99 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
100 esac
102 dnl Check for lint
103 AC_CHECK_PROGS(LINT, lclint lint)
104 if test "$LINT" = "lint"
105 then
106 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
107 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
108 fi
109 AC_SUBST(LINT)
110 AC_SUBST(LINTFLAGS)
112 dnl Check for db2html
113 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
114 AC_SUBST(DB2HTML)
116 dnl Check for db2pdf
117 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
118 AC_SUBST(DB2PDF)
120 dnl Check for db2ps
121 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
122 AC_SUBST(DB2PS)
124 dnl **** Check for some libraries ****
126 dnl Check for -lm
127 AC_CHECK_LIB(m,sqrt)
128 dnl Check for -li386 for NetBSD and OpenBSD
129 AC_CHECK_LIB(i386,i386_set_ldt)
130 dnl Check for -lossaudio for NetBSD
131 AC_CHECK_LIB(ossaudio,_oss_ioctl)
132 dnl Check for -lw for Solaris
133 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
134 dnl Check for -lnsl for Solaris
135 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
136 dnl Check for -lsocket for Solaris
137 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
138 dnl Check for -lresolv for Solaris
139 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
140 dnl Check for -lxpg4 for FreeBSD
141 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
142 dnl Check for -lmmap for OS/2
143 AC_CHECK_LIB(mmap,mmap)
145 JPEGLIB=""
146 AC_SUBST(JPEGLIB)
147 AC_CHECK_HEADERS(jpeglib.h,
148 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
149 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
150 JPEGLIB="-ljpeg"
151 )
152 )
154 AC_SUBST(GIFLIB,"")
155 AC_CHECK_HEADERS(gif_lib.h,
156 AC_CHECK_LIB(ungif,DGifOpen,
157 [AC_DEFINE(HAVE_LIBGIF,1,[Define if you have libgif/libungif including devel headers])
158 GIFLIB="-lungif"],
159 [AC_CHECK_LIB(gif,DGifOpen,
160 [AC_DEFINE(HAVE_LIBGIF,1)
161 GIFLIB="-lgif"])]))
163 AC_SUBST(XLIB)
164 AC_SUBST(XFILES)
165 XFILES=""
166 AC_SUBST(OPENGLFILES)
167 OPENGLFILES=""
168 AC_SUBST(GLU32FILES)
169 GLU32FILES=""
170 AC_SUBST(OPENGL_LIBS)
171 OPENGL_LIBS=""
172 if test "$have_x" = "yes"
173 then
174 XLIB="-lXext -lX11"
175 ac_save_CPPFLAGS="$CPPFLAGS"
176 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
178 dnl *** All of the following tests require X11/Xlib.h
179 AC_CHECK_HEADERS(X11/Xlib.h,
180 [
181 dnl *** Check for X keyboard extension
182 AC_CHECK_HEADERS(X11/XKBlib.h,
183 [ dnl *** If X11/XKBlib.h exists...
184 AC_CHECK_LIB(X11, XkbQueryExtension,
185 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
186 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
187 ],
188 AC_MSG_WARN([[Xkb extension not found, Wine will be built without it]]),
189 [#include <X11/Xlib.h>])
191 dnl *** Check for X Shm extension
192 AC_CHECK_HEADERS(X11/extensions/XShm.h,
193 [ dnl *** If X11/extensions/XShm.h exists...
194 AC_CHECK_LIB(Xext, XShmQueryExtension,
195 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
196 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
197 ],
198 AC_MSG_WARN([[XShm extension not found, Wine will be built without it]]),
199 [#include <X11/Xlib.h>])
201 dnl *** Check for Xutil
202 AC_CHECK_HEADERS(X11/Xutil.h,,,
203 [#include <X11/Xlib.h>])
205 dnl *** Check for X shape extension
206 AC_CHECK_HEADERS(X11/extensions/shape.h,
207 [ dnl *** If X11/extensions/shape.h exists...
208 AC_CHECK_LIB(Xext,XShapeQueryExtension,
209 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
210 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
211 ],
212 AC_MSG_WARN([[XShape extension not found, Wine will be built without it]]),
213 [#include <X11/Xlib.h>
214 #ifdef HAVE_X11_XUTIL_H
215 # include <X11/Xutil.h>
216 #endif])
218 dnl *** Check for XFree86 DGA / DGA 2.0 extension
219 AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
220 [ dnl *** If X11/extensions/xf86dga.h exists, check
221 dnl *** for XDGAQueryExtension()...
222 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
223 [ dnl *** If found...
224 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
225 [Define if you have the Xxf86dga library version 2])
226 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
227 ],
228 [ dnl *** If not found, look for XF86DGAQueryExtension()
229 dnl *** instead (DGA 2.0 not found)...
230 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
231 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
232 [Define if you have the Xxf86dga library version 1])
233 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
234 ],,
235 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
236 )
237 ],
238 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
239 )
240 ],
241 AC_MSG_WARN([[DGA extension not found, Wine will be built without it]]),
242 [#include <X11/Xlib.h>])
244 dnl *** Check for XFree86 VMODE extension
245 AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
246 [ dnl *** If X11/extensions/xf86vmode.h exists...
247 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
248 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
249 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
250 ],,
251 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
252 )
253 ],
254 AC_MSG_WARN([[XFree86 VMODE extension not found, Wine will be built without it]]),
255 [#include <X11/Xlib.h>])
257 dnl *** Check for XVideo extension supporting XvImages
258 AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
259 [ dnl *** If X11/extensions/Xvlib.h exists...
260 AC_CHECK_LIB(Xv, XvShmCreateImage,
261 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
262 X_PRE_LIBS="$X_PRE_LIBS -lXv"
263 ],,
264 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
265 )
266 ],
267 AC_MSG_WARN([[XVideo extension not found, Wine will be built without it]]),
268 [#include <X11/Xlib.h>])
270 dnl *** Check for XRender include file
271 AC_CHECK_HEADERS(X11/extensions/Xrender.h,,,[#include <X11/Xlib.h>])
272 ]
273 ) dnl *** End of X11/Xlib.h check
275 dnl Check for the presence of OpenGL
276 if test "x$with_opengl" != "xno"
277 then
278 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
279 then
280 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
281 This prevents linking to OpenGL. Delete the file and restart configure.])
282 fi
284 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
285 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
286 then
287 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
288 dnl Check for some problems due to old Mesa versions
289 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
290 AC_TRY_COMPILE(
291 [#include <GL/gl.h>],
292 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
293 [wine_cv_opengl_version_OK="yes"],
294 [wine_cv_opengl_version_OK="no"]
295 )
296 )
298 if test "$wine_cv_opengl_version_OK" = "yes"
299 then
300 dnl Check for the presence of the library
301 AC_CHECK_LIB(GL,glXCreateContext,
302 OPENGL_LIBS="-lGL"
303 ,,
304 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
306 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
307 then
308 OPENGLFILES='$(OPENGLFILES)'
309 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
311 AC_CHECK_LIB(GL,glXGetProcAddressARB,
312 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
313 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
314 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
316 if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
317 then
318 AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
319 [AC_TRY_COMPILE([#include <GL/gl.h>
320 #ifdef HAVE_GL_GLEXT_H
321 # include <GL/glext.h>
322 #endif
323 ],
324 [PFNGLCOLORTABLEEXTPROC test_proc;],
325 [wine_cv_extension_prototypes="yes"],
326 [wine_cv_extension_prototypes="no"]
327 )]
328 )
329 if test "$wine_cv_extension_prototypes" = "yes"
330 then
331 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
332 [Define if the OpenGL headers define extension typedefs])
333 fi
334 fi
336 fi
337 dnl Check for GLU32 library.
338 AC_CHECK_LIB(GLU,gluLookAt,
339 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
340 GLU32FILES='$(GLU32FILES)']
341 ,,
342 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
343 )
344 fi
345 fi
346 fi
348 dnl **** Check for NAS ****
349 AC_SUBST(NASLIBS,"")
350 AC_CHECK_HEADERS(audio/audiolib.h,
351 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
352 AC_CHECK_LIB(audio,AuCreateFlow,
353 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
354 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
355 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
357 CPPFLAGS="$ac_save_CPPFLAGS"
358 XFILES='$(XFILES)'
359 else
360 XLIB=""
361 X_CFLAGS=""
362 X_LIBS=""
363 fi
365 dnl **** Check which curses lib to use ***
366 CURSESLIBS=""
367 if test "x$with_curses" != "xno"
368 then
369 AC_CHECK_HEADERS(ncurses.h,
370 [AC_CHECK_LIB(ncurses,waddch,
371 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
372 CURSESLIBS="-lncurses"],
373 [AC_CHECK_HEADERS(curses.h,
374 [AC_CHECK_LIB(curses,waddch,
375 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
376 CURSESLIBS="-lcurses"])])])])
377 saved_libs="$LIBS"
378 LIBS="$CURSESLIBS $LIBS"
379 AC_CHECK_FUNCS(getbkgd resizeterm)
380 LIBS="$saved_libs"
381 fi
382 AC_SUBST(CURSESLIBS)
384 dnl **** Check for SANE ****
385 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
386 if test "$sane_devel" = "no"
387 then
388 SANELIBS=""
389 SANEINCL=""
390 else
391 SANELIBS="`$sane_devel --libs`"
392 SANEINCL="`$sane_devel --cflags`"
393 ac_save_CPPFLAGS="$CPPFLAGS"
394 ac_save_LIBS="$LIBS"
395 CPPFLAGS="$CPPFLAGS $SANEINCL"
396 LIBS="$LIBS $SANELIBS"
397 AC_CHECK_HEADER(sane/sane.h,
398 [AC_CHECK_LIB(sane,sane_open,
399 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
400 [SANELIBS=""
401 SANEINCL=""])],
402 [SANELIBS=""
403 SANEINCL=""])
404 LIBS="$ac_save_LIBS"
405 CPPFLAGS="$ac_save_CPPFLAGS"
406 fi
407 AC_SUBST(SANELIBS)
408 AC_SUBST(SANEINCL)
410 dnl **** Check for the ICU library ****
411 AC_CHECK_HEADERS(unicode/ubidi.h)
412 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
413 then
414 AC_CACHE_CHECK([whether we can statically link the ICU libraries], ac_cv_lib_icu,
415 [saved_libs="$LIBS"
416 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
417 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libicuuc.a}"
418 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libicudata.a}"
419 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
420 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
421 [ac_cv_lib_icu="yes"],[ac_cv_lib_icu="no"])
422 LIBS="$saved_libs"])
423 if test "$ac_cv_lib_icu" = "yes"
424 then
425 AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
426 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
427 fi
428 fi
430 dnl **** Check for FreeType 2 ****
431 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
432 if test "$ft_lib" = "no"
433 then
434 FREETYPEINCL=""
435 wine_cv_msg_freetype=no
436 else
437 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
438 if test "$ft_devel" = "no"
439 then
440 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
441 if test "$ft_devel2" = "freetype2-config"
442 then
443 ft_devel=$ft_devel2
444 fi
445 fi
446 if test "$ft_devel" = "no"
447 then
448 FREETYPEINCL=""
449 wine_cv_msg_freetype=yes
450 else
451 FREETYPEINCL=`$ft_devel --cflags`
452 ac_save_CPPFLAGS="$CPPFLAGS"
453 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
454 AC_CHECK_HEADERS(freetype/freetype.h \
455 freetype/ftglyph.h \
456 freetype/tttables.h \
457 freetype/ftnames.h \
458 freetype/ftsnames.h \
459 freetype/ttnameid.h \
460 freetype/ftoutln.h \
461 freetype/internal/sfnt.h)
462 AC_TRY_CPP([#include <ft2build.h>
463 #include <freetype/fttrigon.h>],
464 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
465 [Define if you have the <freetype/fttrigon.h> header file.])
466 wine_cv_fttrigon=yes],
467 wine_cv_fttrigon=no)
468 CPPFLAGS="$ac_save_CPPFLAGS"
469 dnl Check that we have at least freetype/freetype.h
470 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
471 then
472 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
473 wine_cv_msg_freetype=no
474 else
475 FREETYPEINCL=""
476 wine_cv_msg_freetype=yes
477 fi
478 fi
479 fi
480 AC_SUBST(FREETYPEINCL)
482 dnl **** Check for parport (currently Linux only) ****
483 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
484 AC_TRY_COMPILE(
485 [#include <linux/ppdev.h>],
486 [ioctl (1,PPCLAIM,0)],
487 [ac_cv_c_ppdev="yes"],
488 [ac_cv_c_ppdev="no"])
489 )
490 if test "$ac_cv_c_ppdev" = "yes"
491 then
492 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
493 fi
495 dnl **** Check for va_copy ****
496 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
497 AC_TRY_LINK(
498 [#include <stdarg.h>],
499 [va_list ap1, ap2;
500 va_copy(ap1,ap2);
501 ],
502 [ac_cv_c_va_copy="yes"],
503 [ac_cv_c_va_copy="no"])
504 )
505 if test "$ac_cv_c_va_copy" = "yes"
506 then
507 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
508 fi
509 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
510 AC_TRY_LINK(
511 [#include <stdarg.h>],
512 [va_list ap1, ap2;
513 __va_copy(ap1,ap2);
514 ],
515 [ac_cv_c___va_copy="yes"],
516 [ac_cv_c___va_copy="no"])
517 )
518 if test "$ac_cv_c___va_copy" = "yes"
519 then
520 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
521 fi
523 dnl **** Check for Open Sound System ****
524 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
526 AC_CACHE_CHECK([for Open Sound System],
527 ac_cv_c_opensoundsystem,
528 AC_TRY_COMPILE([
529 #if defined(HAVE_SYS_SOUNDCARD_H)
530 #include <sys/soundcard.h>
531 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
532 #include <machine/soundcard.h>
533 #elif defined(HAVE_SOUNDCARD_H)
534 #include <soundcard.h>
535 #endif
536 ],[
538 /* check for one of the Open Sound System specific SNDCTL_ defines */
539 #if !defined(SNDCTL_DSP_STEREO)
540 #error No open sound system
541 #endif
542 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
544 if test "$ac_cv_c_opensoundsystem" = "yes"
545 then
546 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
547 fi
549 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
550 ac_cv_c_opensoundsystem_midi,
551 AC_TRY_COMPILE([
552 #if defined(HAVE_SYS_SOUNDCARD_H)
553 #include <sys/soundcard.h>
554 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
555 #include <machine/soundcard.h>
556 #elif defined(HAVE_SOUNDCARD_H)
557 #include <soundcard.h>
558 #endif
559 ],[
561 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
562 #if !defined(SNDCTL_SEQ_SYNC)
563 #error No open sound system MIDI interface
564 #endif
565 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
567 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
568 then
569 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
570 fi
572 dnl **** Check for aRts Sound Server ****
573 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
574 AC_CACHE_CHECK([for aRts Sound server],
575 ac_cv_c_artsserver,
576 if test x$ARTSCCONFIG = x -o x$ARTSCCONFIG = x'"$ARTSCCONFIG"';
577 then
578 ac_cv_c_artsserver=no
579 else
580 ARTSC_CFLAGS=`$ARTSCCONFIG --cflags`
581 ARTSC_LIBS=`$ARTSCCONFIG --libs`
582 ac_cv_c_artsserver=no
583 save_CFLAGS="$CFLAGS"
584 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
585 AC_TRY_COMPILE([
586 #include <artsc.h>
587 ],[
588 arts_stream_t stream;
589 ],[
590 ac_cv_c_artsserver=yes
591 ])
592 CFLAGS="$save_CFLAGS"
593 fi)
595 if test "$ac_cv_c_artsserver" = "yes"
596 then
597 AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
598 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
600 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])
601 fi
603 dnl **** Check for ALSA ****
604 AC_SUBST(ALSALIBS,"")
605 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
606 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
607 then
608 AC_CHECK_LIB(asound,snd_pcm_open,
609 AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
610 ALSALIBS="-lasound")
611 fi
613 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
615 AC_SUBST(AUDIOIOLIBS,"")
616 AC_CHECK_HEADERS(libaudioio.h,
617 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
618 [AUDIOIOLIBS="-laudioio"
619 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
621 dnl **** Check for broken glibc mmap64 ****
623 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
624 AC_TRY_RUN([
625 #define _FILE_OFFSET_BITS 64
626 #include <stdio.h>
627 #include <unistd.h>
628 #include <fcntl.h>
629 #include <sys/mman.h>
630 #include <errno.h>
632 int main(int argc,char **argv) {
633 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
634 if (fd == -1) exit(1);
636 unlink("conftest.map");
638 write(fd,"test",4);
640 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
641 (errno == EINVAL)
642 ) {
643 exit(1);
644 }
645 close(fd);
646 fprintf(stderr,"success!\n");
647 exit(0);
648 }
650 ],
651 ac_cv_mmap64_works="yes",
652 ac_cv_mmap64_works="no",
653 ac_cv_mmap64_works="no") )
655 if test "$ac_cv_mmap64_works" = "yes"
656 then
657 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
658 fi
660 dnl **** Check for gcc specific options ****
662 AC_SUBST(EXTRACFLAGS,"")
663 if test "x${GCC}" = "xyes"
664 then
665 EXTRACFLAGS=-Wall
667 dnl Check for strength-reduce bug
668 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
669 AC_TRY_RUN([
670 int L[[4]] = {0,1,2,3};
671 int main(void) {
672 static int Array[[3]];
673 unsigned int B = 3;
674 int i;
675 for(i=0; i<B; i++) Array[[i]] = i - 3;
676 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
677 L[[i]] = 4;
679 exit( Array[[1]] != -2 || L[[2]] != 3);
680 }],
681 ac_cv_c_gcc_strength_bug="no",
682 ac_cv_c_gcc_strength_bug="yes",
683 ac_cv_c_gcc_strength_bug="yes") )
684 if test "$ac_cv_c_gcc_strength_bug" = "yes"
685 then
686 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
687 fi
689 dnl Check for -mpreferred-stack-boundary
690 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
691 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
692 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
693 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
694 then
695 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
696 fi
698 dnl Check for -fno-strict-aliasing
699 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
700 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
701 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
702 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
703 then
704 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
705 fi
707 dnl Check for -gstabs+ option
708 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
709 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
710 if test "$ac_cv_c_gcc_gstabs" = "yes"
711 then
712 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
713 fi
715 dnl Check for noisy string.h
716 saved_CFLAGS="$CFLAGS"
717 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
718 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
719 AC_TRY_COMPILE([#include <string.h>],[],
720 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
721 CFLAGS="$saved_CFLAGS"
722 if test "$ac_cv_c_string_h_warnings" = "no"
723 then
724 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
725 fi
726 fi
728 dnl **** Check how to define a function in assembly code ****
730 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
731 WINE_TRY_ASM_LINK(
732 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
733 ac_cv_asm_func_def=".def",
734 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
735 ac_cv_asm_func_def=".type @function",
736 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
737 ac_cv_asm_func_def=".type 2",
738 ac_cv_asm_func_def="unknown")])]))
740 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
741 case "$ac_cv_asm_func_def" in
742 ".def")
743 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
744 ".type @function")
745 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
746 ".type 2")
747 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
748 *)
749 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
750 esac
752 dnl **** Check for underscore on external symbols ****
754 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
755 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
756 [extern int ac_test;],
757 [if (ac_test) return 1],
758 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
760 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
761 if test "$ac_cv_c_extern_prefix" = "yes"
762 then
763 AC_DEFINE([__ASM_NAME(name)], ["_" name])
764 else
765 AC_DEFINE([__ASM_NAME(name)], [name])
766 fi
768 dnl **** Check how to do strings in assembler ****
770 AC_CACHE_CHECK([whether assembler accepts .string], ac_cv_c_asm_string,
771 WINE_TRY_ASM_LINK([".data\n\t.string \"test\"\n\t.text"],,,
772 ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no"))
773 if test "$ac_cv_c_asm_string" = "yes"
774 then
775 AC_DEFINE(__ASM_STRING, [".string"], [Define to the assembler keyword used to specify an ASCII string])
776 else
777 AC_CACHE_CHECK([whether assembler accepts .asciz], ac_cv_c_asm_asciz,
778 WINE_TRY_ASM_LINK([".data\n\t.asciz \"test\"\n\t.text"],,,
779 ac_cv_c_asm_asciz="yes",ac_cv_c_asm_asciz="no"))
780 if test "$ac_cv_c_asm_asciz" = "yes"
781 then
782 AC_DEFINE(__ASM_STRING, [".asciz"])
783 else
784 AC_DEFINE(__ASM_STRING, [".ascii"])
785 fi
786 fi
788 dnl **** Check for .short in assembler ****
790 AC_CACHE_CHECK([whether assembler accepts .short], ac_cv_c_asm_short,
791 WINE_TRY_ASM_LINK([".data\n\t.short 1\n\t.text"],,,
792 ac_cv_c_asm_short="yes",ac_cv_c_asm_short="no"))
793 if test "$ac_cv_c_asm_short" = "yes"
794 then
795 AC_DEFINE(__ASM_SHORT, [".short"], [Define to the assembler keyword used to specify a word value])
796 else
797 AC_DEFINE(__ASM_SHORT, [".half"])
798 fi
800 dnl **** Check for working dll ****
802 AC_SUBST(DLLEXT,"")
803 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
804 AC_SUBST(DLLIBS,"")
805 AC_SUBST(LDDLLFLAGS,"")
806 AC_SUBST(LDSHARED,"")
807 AC_SUBST(LIBEXT,"so")
808 AC_SUBST(IMPLIBEXT,"def")
810 case $host_os in
811 cygwin*|mingw32*)
812 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
813 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
814 if test "$DLLWRAP" = "false"; then
815 LIBEXT="a"
816 else
817 dnl FIXME - check whether dllwrap works correctly...
818 LIBEXT="dll"
819 fi
820 IMPLIBEXT="a"
821 ;;
822 *)
823 AC_CHECK_HEADERS(dlfcn.h,
824 [AC_CHECK_FUNCS(dlopen,,
825 [AC_CHECK_LIB(dl,dlopen,
826 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
827 DLLIBS="-ldl"],
828 [LIBEXT="a"])])],
829 [LIBEXT="a"])
831 if test "$LIBEXT" = "so"
832 then
833 DLLFLAGS="$DLLFLAGS -fPIC"
834 DLLEXT=".so"
835 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
836 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
837 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
838 if test "$ac_cv_c_dll_gnuelf" = "yes"
839 then
840 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
841 LDDLLFLAGS="-Wl,-Bsymbolic"
842 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
843 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
844 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
845 if test "$ac_cv_c_dll_zdefs" = "yes"
846 then
847 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
848 fi
849 AC_CACHE_CHECK([whether we can relocate the executable to 0x3c000000], ac_cv_ld_reloc_exec,
850 [saved_CFLAGS="$CFLAGS"
851 CFLAGS="$CFLAGS -Wl,--section-start,.interp=0x3c000100"
852 AC_TRY_RUN([#include <unistd.h>
853 int main() { return (sbrk(32*1024*1024) == (void *)-1); }],
854 ac_cv_ld_reloc_exec="yes",
855 ac_cv_ld_reloc_exec="no",
856 ac_cv_ld_reloc_exec="no")
857 CFLAGS="$saved_CFLAGS"])
858 if test "$ac_cv_ld_reloc_exec" = "yes"
859 then
860 AC_SUBST(LDEXECFLAGS,["-Wl,--section-start,.interp=0x3c000100"])
861 fi
862 else
863 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
864 [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
865 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
866 if test "$ac_cv_c_dll_unixware" = "yes"
867 then
868 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
869 LDDLLFLAGS="-Wl,-B,symbolic"
870 fi
871 fi
872 fi
874 dnl Check for cross compiler to build test programs
875 AC_SUBST(CROSSTEST,"")
876 if test "$cross_compiling" = "no"
877 then
878 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32-gcc,false)
879 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32-dlltool,false)
880 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32-windres,false)
881 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
882 fi
883 ;;
884 esac
886 if test "$LIBEXT" = "a"; then
887 AC_MSG_ERROR(
888 [could not find a way to build shared libraries.
889 It is currently not possible to build Wine without shared library
890 (.so) support to allow transparent switch between .so and .dll files.
891 If you are using Linux, you will need a newer binutils.]
892 )
893 fi
895 case $build_os in
896 cygwin*|mingw32*)
897 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
898 *)
899 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
900 esac
902 dnl Mingw needs explicit msvcrt for linking libwine
903 AC_SUBST(CRTLIBS,"")
904 case $host_os in
905 mingw32*)
906 CRTLIBS="-lmsvcrt" ;;
907 esac
909 dnl **** Get the soname for libraries that we load dynamically ****
911 if test "$LIBEXT" = "so"
912 then
913 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
914 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
915 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
916 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
917 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
918 WINE_GET_SONAME(cups,cupsGetDefault)
919 WINE_GET_SONAME(jack,jack_client_new)
920 WINE_GET_SONAME(ssl,SSL_library_init)
921 WINE_GET_SONAME(crypto,BIO_new_socket)
922 fi
925 dnl **** Check for functions ****
927 AC_FUNC_ALLOCA()
928 AC_CHECK_FUNCS(\
929 _lwp_create \
930 _lwp_self \
931 _pclose \
932 _popen \
933 _snprintf \
934 _spawnvp \
935 _stricmp \
936 _strnicmp \
937 _vsnprintf \
938 chsize \
939 clone \
940 finite \
941 fpclass \
942 ftruncate \
943 ftruncate64 \
944 getnetbyaddr \
945 getnetbyname \
946 getopt_long \
947 getpagesize \
948 getprotobyname \
949 getprotobynumber \
950 getpwuid \
951 getservbyport \
952 gettimeofday \
953 inet_network \
954 lseek64 \
955 lstat \
956 memmove \
957 mmap \
958 pclose \
959 popen \
960 pread \
961 pthread_getspecific \
962 pthread_key_create \
963 pthread_mutex_lock \
964 pthread_mutex_unlock \
965 pthread_setspecific \
966 pwrite \
967 rfork \
968 select \
969 sendmsg \
970 settimeofday \
971 sigaltstack \
972 snprintf \
973 statfs \
974 strcasecmp \
975 strerror \
976 strncasecmp \
977 tcgetattr \
978 timegm \
979 usleep \
980 vfscanf \
981 vsnprintf \
982 wait4 \
983 waitpid \
984 )
986 dnl **** Check for header files ****
988 AC_CHECK_HEADERS(\
989 arpa/inet.h \
990 arpa/nameser.h \
991 cups/cups.h \
992 direct.h \
993 elf.h \
994 float.h \
995 getopt.h \
996 ieeefp.h \
997 io.h \
998 jack/jack.h \
999 libio.h \
1000 libutil.h \
1001 link.h \
1002 linux/cdrom.h \
1003 linux/hdreg.h \
1004 linux/input.h \
1005 linux/joystick.h \
1006 linux/major.h \
1007 linux/param.h \
1008 linux/serial.h \
1009 linux/ucdrom.h \
1010 machine/cpu.h \
1011 netdb.h \
1012 netinet/in.h \
1013 netinet/in_systm.h \
1014 netinet/tcp.h \
1015 netinet/tcp_fsm.h \
1016 openssl/ssl.h \
1017 pty.h \
1018 pwd.h \
1019 regex.h \
1020 sched.h \
1021 scsi/sg.h \
1022 socket.h \
1023 stdint.h \
1024 strings.h \
1025 sys/cdio.h \
1026 sys/errno.h \
1027 sys/file.h \
1028 sys/filio.h \
1029 sys/inttypes.h \
1030 sys/ioctl.h \
1031 sys/ipc.h \
1032 sys/link.h \
1033 sys/lwp.h \
1034 sys/mman.h \
1035 sys/modem.h \
1036 sys/msg.h \
1037 sys/param.h \
1038 sys/poll.h \
1039 sys/ptrace.h \
1040 sys/reg.h \
1041 sys/scsiio.h \
1042 sys/shm.h \
1043 sys/signal.h \
1044 sys/socket.h \
1045 sys/sockio.h \
1046 sys/statfs.h \
1047 sys/strtio.h \
1048 sys/syscall.h \
1049 sys/sysctl.h \
1050 sys/time.h \
1051 sys/times.h \
1052 sys/uio.h \
1053 sys/un.h \
1054 sys/v86.h \
1055 sys/v86intr.h \
1056 sys/vfs.h \
1057 sys/vm86.h \
1058 sys/wait.h \
1059 syscall.h \
1060 termios.h \
1061 unistd.h \
1062 utime.h \
1063 valgrind/memcheck.h
1064 )
1065 AC_HEADER_STAT()
1067 dnl **** Checks for headers that depend on other ones ****
1069 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1070 [#include <sys/types.h>
1071 #if HAVE_SYS_PARAM_H
1072 # include <sys/param.h>
1073 #endif])
1075 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h resolv.h],,,
1076 [#include <sys/types.h>
1077 #if HAVE_SYS_SOCKET_H
1078 # include <sys/socket.h>
1079 #endif])
1081 AC_CHECK_HEADERS(netinet/ip.h,,,
1082 [#include <sys/types.h>
1083 #if HAVE_SYS_SOCKET_H
1084 # include <sys/socket.h>
1085 #endif
1086 #if HAVE_NETINET_IN_SYSTM_H
1087 # include <netinet/in_systm.h>
1088 #endif])
1090 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1092 dnl **** Check for IPX headers (currently Linux only) ****
1094 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1095 AC_TRY_COMPILE(
1096 [#include <sys/types.h>
1097 #ifdef HAVE_SYS_SOCKET_H
1098 # include <sys/socket.h>
1099 #endif
1100 #include <netipx/ipx.h>],
1101 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1102 [ac_cv_c_ipx_gnu="yes"],
1103 [ac_cv_c_ipx_gnu="no"])
1104 )
1105 if test "$ac_cv_c_ipx_gnu" = "yes"
1106 then
1107 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1108 fi
1110 if test "$ac_cv_c_ipx_gnu" = "no"
1111 then
1112 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1113 AC_TRY_COMPILE(
1114 [#include <sys/types.h>
1115 #ifdef HAVE_SYS_SOCKET_H
1116 # include <sys/socket.h>
1117 #endif
1118 #include <asm/types.h>
1119 #include <linux/ipx.h>],
1120 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1121 [ac_cv_c_ipx_linux="yes"],
1122 [ac_cv_c_ipx_linux="no"])
1123 )
1124 if test "$ac_cv_c_ipx_linux" = "yes"
1125 then
1126 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1127 fi
1128 fi
1130 dnl **** Check for types ****
1132 AC_C_CONST
1133 AC_C_INLINE
1134 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t])
1135 AC_CHECK_SIZEOF(long long,0)
1137 AC_CACHE_CHECK([whether linux/input.h is for real],
1138 wine_cv_linux_input_h,
1139 AC_TRY_COMPILE([
1140 #include <linux/input.h>
1141 ] , [
1142 int foo = EVIOCGBIT(EV_ABS,42);
1143 int bar = BTN_PINKIE;
1144 int fortytwo = 42;
1145 ],
1146 wine_cv_linux_input_h=yes,
1147 wine_cv_linux_input_h=no,
1148 no
1149 )
1150 )
1151 if test "$wine_cv_linux_input_h" = "yes"
1152 then
1153 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1154 [Define if we have linux/input.h AND it contains the INPUT event API])
1155 fi
1158 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1159 wine_cv_linux_gethostbyname_r_6,
1160 AC_TRY_COMPILE([
1161 #include <netdb.h>
1162 ], [
1163 char *name=NULL;
1164 struct hostent he;
1165 struct hostent *result;
1166 char *buf=NULL;
1167 int bufsize=0;
1168 int res,errnr;
1169 char *addr=NULL;
1170 int addrlen=0;
1171 int addrtype=0;
1172 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1173 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1174 ],
1175 wine_cv_linux_gethostbyname_r_6=yes,
1176 wine_cv_linux_gethostbyname_r_6=no
1177 )
1178 )
1179 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1180 then
1181 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1182 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1183 fi
1185 if test "$ac_cv_header_linux_joystick_h" = "yes"
1186 then
1187 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1188 wine_cv_linux_joystick_22_api,
1189 AC_TRY_COMPILE([
1190 #include <sys/ioctl.h>
1191 #include <linux/joystick.h>
1193 struct js_event blub;
1194 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1195 #error "no 2.2 header"
1196 #endif
1197 ],/*empty*/,
1198 wine_cv_linux_joystick_22_api=yes,
1199 wine_cv_linux_joystick_22_api=no,
1200 wine_cv_linux_joystick_22_api=no
1201 )
1202 )
1203 if test "$wine_cv_linux_joystick_22_api" = "yes"
1204 then
1205 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1206 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1207 fi
1208 fi
1210 dnl **** statfs checks ****
1212 if test "$ac_cv_header_sys_vfs_h" = "yes"
1213 then
1214 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1215 wine_cv_sys_vfs_has_statfs,
1216 AC_TRY_COMPILE([
1217 #include <sys/types.h>
1218 #ifdef HAVE_SYS_PARAM_H
1219 # include <sys/param.h>
1220 #endif
1221 #include <sys/vfs.h>
1222 ],[
1223 struct statfs stfs;
1225 memset(&stfs,0,sizeof(stfs));
1226 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1227 )
1228 )
1229 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1230 then
1231 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1232 [Define if the struct statfs is defined by <sys/vfs.h>])
1233 fi
1234 fi
1236 if test "$ac_cv_header_sys_statfs_h" = "yes"
1237 then
1238 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1239 wine_cv_sys_statfs_has_statfs,
1240 AC_TRY_COMPILE([
1241 #include <sys/types.h>
1242 #ifdef HAVE_SYS_PARAM_H
1243 # include <sys/param.h>
1244 #endif
1245 #include <sys/statfs.h>
1246 ],[
1247 struct statfs stfs;
1248 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1249 )
1250 )
1251 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1252 then
1253 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1254 [Define if the struct statfs is defined by <sys/statfs.h>])
1255 fi
1256 fi
1258 if test "$ac_cv_header_sys_mount_h" = "yes"
1259 then
1260 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1261 wine_cv_sys_mount_has_statfs,
1262 AC_TRY_COMPILE([
1263 #include <sys/types.h>
1264 #ifdef HAVE_SYS_PARAM_H
1265 # include <sys/param.h>
1266 #endif
1267 #include <sys/mount.h>
1268 ],[
1269 struct statfs stfs;
1270 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1271 )
1272 )
1273 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1274 then
1275 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1276 [Define if the struct statfs is defined by <sys/mount.h>])
1277 fi
1278 fi
1280 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1282 dnl Check for statfs members
1283 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail],,,
1284 [#include <sys/types.h>
1285 #ifdef HAVE_SYS_PARAM_H
1286 # include <sys/param.h>
1287 #endif
1288 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1289 # include <sys/mount.h>
1290 #else
1291 # ifdef STATFS_DEFINED_BY_SYS_VFS
1292 # include <sys/vfs.h>
1293 # else
1294 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1295 # include <sys/statfs.h>
1296 # endif
1297 # endif
1298 #endif])
1300 dnl Check for socket structure members
1301 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1302 [#include <sys/types.h>
1303 #ifdef HAVE_SYS_SOCKET_H
1304 # include <sys/socket.h>
1305 #endif
1306 #ifdef HAVE_SYS_UN_H
1307 # include <sys/un.h>
1308 #endif])
1310 dnl Check for siginfo_t members
1311 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1313 dnl Check for struct option
1314 AC_CHECK_MEMBERS([struct option.name],,,
1315 [#ifdef HAVE_GETOPT_H
1316 #include <getopt.h>
1317 #endif])
1319 dnl *** check for the need to define platform-specific symbols
1321 case $host_cpu in
1322 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1323 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1324 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1325 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1326 esac
1328 case $host_vendor in
1329 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1330 esac
1332 dnl **** Generate output files ****
1334 AH_TOP([#define __WINE_CONFIG_H])
1336 WINE_CONFIG_EXTRA_DIR(controls)
1337 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1338 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1339 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1340 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1341 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1342 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1343 WINE_CONFIG_EXTRA_DIR(dlls/dinput/joystick)
1344 WINE_CONFIG_EXTRA_DIR(dlls/dinput/keyboard)
1345 WINE_CONFIG_EXTRA_DIR(dlls/dinput/mouse)
1346 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1347 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1348 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1349 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1350 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1351 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1352 WINE_CONFIG_EXTRA_DIR(files)
1353 WINE_CONFIG_EXTRA_DIR(graphics)
1354 WINE_CONFIG_EXTRA_DIR(graphics/x11drv)
1355 WINE_CONFIG_EXTRA_DIR(if1632)
1356 WINE_CONFIG_EXTRA_DIR(include/wine)
1357 WINE_CONFIG_EXTRA_DIR(loader)
1358 WINE_CONFIG_EXTRA_DIR(loader/ne)
1359 WINE_CONFIG_EXTRA_DIR(memory)
1360 WINE_CONFIG_EXTRA_DIR(misc)
1361 WINE_CONFIG_EXTRA_DIR(msdos)
1362 WINE_CONFIG_EXTRA_DIR(objects)
1363 WINE_CONFIG_EXTRA_DIR(programs/regapi/tests)
1364 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1365 WINE_CONFIG_EXTRA_DIR(relay32)
1366 WINE_CONFIG_EXTRA_DIR(scheduler)
1367 WINE_CONFIG_EXTRA_DIR(win32)
1368 WINE_CONFIG_EXTRA_DIR(windows)
1370 MAKE_RULES=Make.rules
1371 AC_SUBST_FILE(MAKE_RULES)
1373 MAKE_DLL_RULES=dlls/Makedll.rules
1374 AC_SUBST_FILE(MAKE_DLL_RULES)
1376 MAKE_TEST_RULES=dlls/Maketest.rules
1377 AC_SUBST_FILE(MAKE_TEST_RULES)
1379 MAKE_LIB_RULES=libs/Makelib.rules
1380 AC_SUBST_FILE(MAKE_LIB_RULES)
1382 MAKE_PROG_RULES=programs/Makeprog.rules
1383 AC_SUBST_FILE(MAKE_PROG_RULES)
1385 AC_CONFIG_FILES([
1386 Make.rules
1387 dlls/Makedll.rules
1388 dlls/Maketest.rules
1389 libs/Makelib.rules
1390 programs/Makeprog.rules
1391 Makefile
1392 dlls/Makefile
1393 dlls/advapi32/Makefile
1394 dlls/advapi32/tests/Makefile
1395 dlls/avicap32/Makefile
1396 dlls/avifil32/Makefile
1397 dlls/cabinet/Makefile
1398 dlls/comcat/Makefile
1399 dlls/comctl32/Makefile
1400 dlls/comctl32/tests/Makefile
1401 dlls/commdlg/Makefile
1402 dlls/crtdll/Makefile
1403 dlls/crypt32/Makefile
1404 dlls/ctl3d/Makefile
1405 dlls/d3d8/Makefile
1406 dlls/d3d9/Makefile
1407 dlls/d3dim/Makefile
1408 dlls/d3dx8/Makefile
1409 dlls/dciman32/Makefile
1410 dlls/ddraw/Makefile
1411 dlls/devenum/Makefile
1412 dlls/dinput/Makefile
1413 dlls/dinput8/Makefile
1414 dlls/dmband/Makefile
1415 dlls/dmcompos/Makefile
1416 dlls/dmime/Makefile
1417 dlls/dmloader/Makefile
1418 dlls/dmscript/Makefile
1419 dlls/dmstyle/Makefile
1420 dlls/dmsynth/Makefile
1421 dlls/dmusic/Makefile
1422 dlls/dmusic32/Makefile
1423 dlls/dplay/Makefile
1424 dlls/dplayx/Makefile
1425 dlls/dpnhpast/Makefile
1426 dlls/dsound/Makefile
1427 dlls/dsound/tests/Makefile
1428 dlls/gdi/Makefile
1429 dlls/gdi/tests/Makefile
1430 dlls/glu32/Makefile
1431 dlls/icmp/Makefile
1432 dlls/imagehlp/Makefile
1433 dlls/imm32/Makefile
1434 dlls/iphlpapi/Makefile
1435 dlls/kernel/Makefile
1436 dlls/kernel/tests/Makefile
1437 dlls/lzexpand/Makefile
1438 dlls/mapi32/Makefile
1439 dlls/mpr/Makefile
1440 dlls/msacm/Makefile
1441 dlls/msacm/imaadp32/Makefile
1442 dlls/msacm/msadp32/Makefile
1443 dlls/msacm/msg711/Makefile
1444 dlls/msacm/winemp3/Makefile
1445 dlls/msdmo/Makefile
1446 dlls/msimg32/Makefile
1447 dlls/msisys/Makefile
1448 dlls/msnet32/Makefile
1449 dlls/msvcrt/Makefile
1450 dlls/msvcrt/tests/Makefile
1451 dlls/msvcrt20/Makefile
1452 dlls/msvcrtd/Makefile
1453 dlls/msvideo/Makefile
1454 dlls/msvideo/msrle32/Makefile
1455 dlls/netapi32/Makefile
1456 dlls/netapi32/tests/Makefile
1457 dlls/ntdll/Makefile
1458 dlls/ntdll/tests/Makefile
1459 dlls/odbc32/Makefile
1460 dlls/ole32/Makefile
1461 dlls/oleacc/Makefile
1462 dlls/oleaut32/Makefile
1463 dlls/oleaut32/tests/Makefile
1464 dlls/olecli/Makefile
1465 dlls/oledlg/Makefile
1466 dlls/olepro32/Makefile
1467 dlls/olesvr/Makefile
1468 dlls/opengl32/Makefile
1469 dlls/psapi/Makefile
1470 dlls/qcap/Makefile
1471 dlls/quartz/Makefile
1472 dlls/rasapi32/Makefile
1473 dlls/richedit/Makefile
1474 dlls/rpcrt4/Makefile
1475 dlls/rpcrt4/tests/Makefile
1476 dlls/serialui/Makefile
1477 dlls/setupapi/Makefile
1478 dlls/shdocvw/Makefile
1479 dlls/shell32/Makefile
1480 dlls/shell32/tests/Makefile
1481 dlls/shfolder/Makefile
1482 dlls/shlwapi/Makefile
1483 dlls/shlwapi/tests/Makefile
1484 dlls/snmpapi/Makefile
1485 dlls/sti/Makefile
1486 dlls/tapi32/Makefile
1487 dlls/ttydrv/Makefile
1488 dlls/twain/Makefile
1489 dlls/url/Makefile
1490 dlls/urlmon/Makefile
1491 dlls/urlmon/tests/Makefile
1492 dlls/user/Makefile
1493 dlls/user/tests/Makefile
1494 dlls/version/Makefile
1495 dlls/win32s/Makefile
1496 dlls/winaspi/Makefile
1497 dlls/winedos/Makefile
1498 dlls/wineps/Makefile
1499 dlls/wininet/Makefile
1500 dlls/wininet/tests/Makefile
1501 dlls/winmm/Makefile
1502 dlls/winmm/joystick/Makefile
1503 dlls/winmm/mcianim/Makefile
1504 dlls/winmm/mciavi/Makefile
1505 dlls/winmm/mcicda/Makefile
1506 dlls/winmm/mciseq/Makefile
1507 dlls/winmm/mciwave/Makefile
1508 dlls/winmm/midimap/Makefile
1509 dlls/winmm/tests/Makefile
1510 dlls/winmm/wavemap/Makefile
1511 dlls/winmm/winealsa/Makefile
1512 dlls/winmm/winearts/Makefile
1513 dlls/winmm/wineaudioio/Makefile
1514 dlls/winmm/winenas/Makefile
1515 dlls/winmm/winejack/Makefile
1516 dlls/winmm/wineoss/Makefile
1517 dlls/winnls/Makefile
1518 dlls/winsock/Makefile
1519 dlls/winsock/tests/Makefile
1520 dlls/winspool/Makefile
1521 dlls/winspool/tests/Makefile
1522 dlls/wintab32/Makefile
1523 dlls/wintrust/Makefile
1524 dlls/wow32/Makefile
1525 dlls/wsock32/Makefile
1526 dlls/x11drv/Makefile
1527 documentation/Makefile
1528 include/Makefile
1529 libs/Makefile
1530 libs/port/Makefile
1531 libs/unicode/Makefile
1532 libs/uuid/Makefile
1533 libs/wine/Makefile
1534 libs/wpp/Makefile
1535 miscemu/Makefile
1536 programs/Makefile
1537 programs/avitools/Makefile
1538 programs/clock/Makefile
1539 programs/cmdlgtst/Makefile
1540 programs/control/Makefile
1541 programs/expand/Makefile
1542 programs/notepad/Makefile
1543 programs/osversioncheck/Makefile
1544 programs/progman/Makefile
1545 programs/regapi/Makefile
1546 programs/regedit/Makefile
1547 programs/regsvr32/Makefile
1548 programs/regtest/Makefile
1549 programs/rpcss/Makefile
1550 programs/rundll32/Makefile
1551 programs/start/Makefile
1552 programs/uninstaller/Makefile
1553 programs/view/Makefile
1554 programs/wcmd/Makefile
1555 programs/wineboot/Makefile
1556 programs/winecfg/Makefile
1557 programs/wineconsole/Makefile
1558 programs/winedbg/Makefile
1559 programs/winefile/Makefile
1560 programs/winemenubuilder/Makefile
1561 programs/winemine/Makefile
1562 programs/winepath/Makefile
1563 programs/winevdm/Makefile
1564 programs/winhelp/Makefile
1565 programs/winver/Makefile
1566 server/Makefile
1567 tools/Makefile
1568 tools/widl/Makefile
1569 tools/winapi/Makefile
1570 tools/winebuild/Makefile
1571 tools/winedump/Makefile
1572 tools/wmc/Makefile
1573 tools/wrc/Makefile])
1575 AC_OUTPUT
1577 if test "$have_x" = "no"
1578 then
1579 echo
1580 echo "*** Warning: X development files not found. Wine will be built without"
1581 echo "*** X support, which currently does not work, and would probably not be"
1582 echo "*** what you want anyway. You will need to install devel packages of"
1583 echo "*** Xlib/Xfree86 at the very least."
1584 fi
1586 if test "$wine_cv_opengl_version_OK" = "no"
1587 then
1588 echo
1589 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1590 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1591 fi
1593 if test "$wine_cv_msg_freetype" = "yes"
1594 then
1595 echo
1596 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1597 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1598 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1599 echo "*** enable Wine to use TrueType fonts."
1600 fi
1602 echo
1603 echo "Configure finished. Do 'make depend && make' to compile Wine."
1604 echo
1606 dnl Local Variables:
1607 dnl comment-start: "dnl "
1608 dnl comment-end: ""
1609 dnl comment-start-skip: "\\bdnl\\b\\s *"
1610 dnl compile-command: "autoconf"
1611 dnl End: