tools/make_requests

   1 #! /usr/bin/perl -w
   2 #
   3 # Build the server/trace.c and server/request.h files
   4 # from the contents of server/protocol.def.
   5 #
   6 # Copyright (C) 1998 Alexandre Julliard
   7 #
   8 # This library is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU Lesser General Public
  10 # License as published by the Free Software Foundation; either
  11 # version 2.1 of the License, or (at your option) any later version.
  12 #
  13 # This library is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # Lesser General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with this library; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  21 #
  22 use strict;
  23
  24 my %formats =
  25 (                     # size align format
  26     "int"           => [  4,   4,  "%d" ],
  27     "short int"     => [  2,   2,  "%d" ],
  28     "char"          => [  1,   1,  "%c" ],
  29     "unsigned char" => [  1,   1,  "%02x" ],
  30     "unsigned short"=> [  2,   2,  "%04x" ],
  31     "unsigned int"  => [  4,   4,  "%08x" ],
  32     "data_size_t"   => [  4,   4,  "%u" ],
  33     "obj_handle_t"  => [  4,   4,  "%04x" ],
  34     "atom_t"        => [  4,   4,  "%04x" ],
  35     "user_handle_t" => [  4,   4,  "%08x" ],
  36     "process_id_t"  => [  4,   4,  "%04x" ],
  37     "thread_id_t"   => [  4,   4,  "%04x" ],
  38     "client_ptr_t"  => [  8,   8,  "&dump_uint64" ],
  39     "mod_handle_t"  => [  8,   8,  "&dump_uint64" ],
  40     "lparam_t"      => [  8,   8,  "&dump_uint64" ],
  41     "apc_param_t"   => [  8,   8,  "&dump_uint64" ],
  42     "file_pos_t"    => [  8,   8,  "&dump_uint64" ],
  43     "mem_size_t"    => [  8,   8,  "&dump_uint64" ],
  44     "affinity_t"    => [  8,   8,  "&dump_uint64" ],
  45     "timeout_t"     => [  8,   8,  "&dump_timeout" ],
  46     "abstime_t"     => [  8,   8,  "&dump_abstime" ],
  47     "rectangle_t"   => [  16,  4,  "&dump_rectangle" ],
  48     "apc_call_t"    => [  48,  8,  "&dump_apc_call" ],
  49     "apc_result_t"  => [  40,  8,  "&dump_apc_result" ],
  50     "async_data_t"  => [  40,  8,  "&dump_async_data" ],
  51     "irp_params_t"  => [  32,  8,  "&dump_irp_params" ],
  52     "luid_t"        => [  8,   4,  "&dump_luid" ],
  53     "generic_map_t" => [  16,  4,  "&dump_generic_map" ],
  54     "ioctl_code_t"  => [  4,   4,  "&dump_ioctl_code" ],
  55     "client_cpu_t"  => [  4,   4,  "&dump_client_cpu" ],
  56     "hw_input_t"    => [  32,  8,  "&dump_hw_input" ],
  57 );
  58
  59 my @requests = ();
  60 my %replies = ();
  61 my @asserts = ();
  62
  63 my @trace_lines = ();
  64
  65 my $max_req_size = 64;
  66
  67 my $warnings = scalar(@ARGV) && $ARGV[0] eq "-w";
  68
  69 sub add_padding($$)
  70 {
  71     my ($offset, $padding) = @_;
  72     if ($offset % $padding)
  73     {
  74         my $count = $padding - ($offset % $padding);
  75         print SERVER_PROT "    char __pad_$offset\[$count\];\n";
  76         $offset += $count;
  77     }
  78     return $offset;
  79 }
  80
  81 ### Generate a dumping function
  82
  83 sub DO_DUMP_FUNC($$@)
  84 {
  85     my $name = shift;
  86     my $req = shift;
  87     my $prefix = " ";
  88     push @trace_lines, "static void dump_${name}_$req( const struct ${name}_$req *req )\n{\n";
  89     while ($#_ >= 0)
  90     {
  91         my $type = shift;
  92         my $var = shift;
  93         next if $var =~ /^__pad/;
  94         if (defined($formats{$type}))
  95         {
  96             my $fmt = ${$formats{$type}}[2];
  97             if ($fmt =~ /^&(.*)/)
  98             {
  99                 my $func = $1;
 100                 push @trace_lines, "    $func( \"$prefix$var=\", &req->$var );\n";
 101             }
 102             elsif ($fmt =~ /^(%.*)\s+\((.*)\)/)
 103             {
 104                 my ($format, $cast) = ($1, $2);
 105                 push @trace_lines, "    fprintf( stderr, \"$prefix$var=$format\", ($cast)req->$var );\n";
 106             }
 107             else
 108             {
 109                 push @trace_lines, "    fprintf( stderr, \"$prefix$var=$fmt\", req->$var );\n";
 110             }
 111         }
 112         else  # must be some varargs format
 113         {
 114             push @trace_lines, "    " . sprintf($type, "$prefix$var=") . ";\n";
 115         }
 116         $prefix = ", ";
 117     }
 118     push @trace_lines, "}\n\n";
 119 }
 120
 121 ### Parse the request definitions
 122
 123 sub PARSE_REQUESTS()
 124 {
 125     # states: 0 = header 1 = declarations 2 = inside @REQ 3 = inside @REPLY
 126     my $state = 0;
 127     my $offset = 0;
 128     my $name = "";
 129     my @in_struct = ();
 130     my @out_struct = ();
 131
 132     open(PROTOCOL,"server/protocol.def") or die "Can't open server/protocol.def";
 133
 134     while (<PROTOCOL>)
 135     {
 136         my ($type, $var);
 137         # strip comments
 138         s!/\*.*\*/!!g;
 139         # strip white space at end of line
 140         s/\s+$//;
 141
 142         if (/^\@HEADER/)
 143         {
 144             die "Misplaced \@HEADER" unless $state == 0;
 145             $state++;
 146             next;
 147         }
 148
 149         # ignore everything while in state 0
 150         next if $state == 0;
 151
 152         if (/^\@REQ\(\s*(\w+)\s*\)/)
 153         {
 154             $name = $1;
 155             die "Misplaced \@REQ" unless $state == 1;
 156             # start a new request
 157             @in_struct = ();
 158             @out_struct = ();
 159             $offset = 12;
 160             print SERVER_PROT "struct ${name}_request\n{\n";
 161             print SERVER_PROT "    struct request_header __header;\n";
 162             $state++;
 163             next;
 164         }
 165
 166         if (/^\@REPLY/)
 167         {
 168             die "Misplaced \@REPLY" unless $state == 2;
 169             $offset = add_padding( $offset, 8 ); # all requests should be 8-byte aligned
 170             die "request $name too large ($offset)" if ($offset > $max_req_size);
 171             push @asserts, "C_ASSERT( sizeof(struct ${name}_request) == $offset );\n";
 172             print SERVER_PROT "};\n";
 173             print SERVER_PROT "struct ${name}_reply\n{\n";
 174             print SERVER_PROT "    struct reply_header __header;\n";
 175             $offset = 8;
 176             $state++;
 177             next;
 178         }
 179
 180         if (/^\@END/)
 181         {
 182             die "Misplaced \@END" unless ($state == 2 || $state == 3);
 183
 184             $offset = add_padding( $offset, 8 ); # all requests should be 8-byte aligned
 185             print SERVER_PROT "};\n";
 186             if ($state == 2)  # build dummy reply struct
 187             {
 188                 die "request $name too large ($offset)" if ($offset > $max_req_size);
 189                 push @asserts, "C_ASSERT( sizeof(struct ${name}_request) == $offset );\n";
 190                 print SERVER_PROT "struct ${name}_reply\n{\n";
 191                 print SERVER_PROT "    struct reply_header __header;\n";
 192                 print SERVER_PROT "};\n";
 193             }
 194             else
 195             {
 196                 die "reply $name too large ($offset)" if ($offset > $max_req_size);
 197                 push @asserts, "C_ASSERT( sizeof(struct ${name}_reply) == $offset );\n";
 198             }
 199             # got a complete request
 200             push @requests, $name;
 201             DO_DUMP_FUNC( $name, "request", @in_struct);
 202             if ($#out_struct >= 0)
 203             {
 204                 $replies{$name} = 1;
 205                 DO_DUMP_FUNC( $name, "reply", @out_struct);
 206             }
 207             $state = 1;
 208             next;
 209         }
 210
 211         if ($state != 1)
 212         {
 213             # skip empty lines (but keep them in output file)
 214             if (/^$/)
 215             {
 216                 print SERVER_PROT "\n";
 217                 next;
 218             }
 219
 220             if (/^\s*VARARG\((\w+),(\w+),(\d+)\)/)
 221             {
 222                 $var = $1;
 223                 $type = "dump_varargs_$2( \"%s\", min(cur_size,$3) )";
 224                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 225             }
 226             elsif (/^\s*VARARG\((\w+),(\w+),(\w+)\)/)
 227             {
 228                 $var = $1;
 229                 $type = "dump_varargs_" . $2 . "( \"%s\", min(cur_size,req->" . $3 . ") )";
 230                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 231             }
 232             elsif (/^\s*VARARG\((\w+),(\w+)\)/)
 233             {
 234                 $var = $1;
 235                 $type = "dump_varargs_" . $2 . "( \"%s\", cur_size )";
 236                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 237             }
 238             elsif (/^\s*(\w+\**(\s+\w+\**)*)\s+(\w+);/)
 239             {
 240                 $type = $1;
 241                 $var = $3;
 242                 die "Unrecognized type $type" unless defined($formats{$type});
 243                 my @fmt = @{$formats{$type}};
 244                 if ($offset & ($fmt[1] - 1))
 245                 {
 246                     my $count = $fmt[1] - ($offset & ($fmt[1] - 1));
 247                     print "protocol.def:$.: warning: $name $offset $type $var needs padding\n" if $warnings;
 248                     print SERVER_PROT "    char __pad_$offset\[$count\];\n";
 249                     $offset += $count;
 250                 }
 251                 if ($state == 2)
 252                 {
 253                     push @asserts, "C_ASSERT( FIELD_OFFSET(struct ${name}_request, $var) == $offset );\n";
 254                 }
 255                 else
 256                 {
 257                     push @asserts, "C_ASSERT( FIELD_OFFSET(struct ${name}_reply, $var) == $offset );\n";
 258                 }
 259                 $offset += $fmt[0];
 260             }
 261             else
 262             {
 263                 die "Unrecognized syntax $_";
 264             }
 265             if ($state == 2) { push @in_struct, $type, $var; }
 266             if ($state == 3) { push @out_struct, $type, $var; }
 267         }
 268
 269         # Pass it through into the output file
 270         print SERVER_PROT $_ . "\n";
 271     }
 272     close PROTOCOL;
 273 }
 274
 275 ### Retrieve the server protocol version from the existing server_protocol.h file
 276
 277 sub GET_PROTOCOL_VERSION()
 278 {
 279     my $protocol = 0;
 280     open SERVER_PROT, "include/wine/server_protocol.h" or return 0;
 281     while (<SERVER_PROT>)
 282     {
 283         if (/^\#define SERVER_PROTOCOL_VERSION (\d+)/) { $protocol = $1; last; }
 284     }
 285     close SERVER_PROT;
 286     return $protocol;
 287 }
 288
 289 ### Retrieve the list of status and errors used in the server
 290
 291 sub GET_ERROR_NAMES()
 292 {
 293     my %errors = ();
 294     foreach my $f (glob "server/*.c")
 295     {
 296         next if $f eq "server/trace.c";
 297         open FILE, $f or die "Can't open $f";
 298         while (<FILE>)
 299         {
 300             while (/\bSTATUS_(\w+)/g)
 301             {
 302                 $errors{$1} = "STATUS_$1" unless ($1 eq "SUCCESS" || $1 eq "WAIT_0");
 303             }
 304             while (/\bset_win32_error\s*\(\s*(\w+)\s*\)/g)
 305             {
 306                 $errors{$1} = "0xc0010000 | $1";
 307             }
 308             while (/\breturn\s+(WSA\w+)/g)
 309             {
 310                 $errors{$1} = "0xc0010000 | $1";
 311             }
 312         }
 313         close FILE;
 314     }
 315     return %errors;
 316 }
 317
 318 # update a file if changed
 319 sub update_file($)
 320 {
 321     my $file = shift;
 322     my $ret = !(-f $file) || system "cmp $file $file.new >/dev/null";
 323     if (!$ret)
 324     {
 325         unlink "$file.new";
 326     }
 327     else
 328     {
 329         rename "$file.new", "$file";
 330         print "$file updated\n";
 331     }
 332     return $ret;
 333 }
 334
 335 # replace some lines in a file between two markers
 336 sub replace_in_file($$$@)
 337 {
 338     my $file = shift;
 339     my $start = shift;
 340     my $end = shift;
 341
 342     open NEW_FILE, ">$file.new" or die "cannot create $file.new";
 343
 344     if (defined($start))
 345     {
 346         open OLD_FILE, "$file" or die "cannot open $file";
 347         while (<OLD_FILE>)
 348         {
 349             print NEW_FILE $_;
 350             last if /$start/;
 351         }
 352     }
 353
 354     print NEW_FILE "\n", @_, "\n";
 355
 356     if (defined($end))
 357     {
 358         my $skip=1;
 359         while (<OLD_FILE>)
 360         {
 361             $skip = 0 if /$end/;
 362             print NEW_FILE $_ unless $skip;
 363         }
 364     }
 365
 366     close OLD_FILE if defined($start);
 367     close NEW_FILE;
 368     return update_file($file);
 369 }
 370
 371 ### Main
 372
 373 # Get the server protocol version
 374 my $protocol = GET_PROTOCOL_VERSION();
 375
 376 my %errors = GET_ERROR_NAMES();
 377
 378 ### Create server_protocol.h and print header
 379
 380 open SERVER_PROT, ">include/wine/server_protocol.h.new" or die "Cannot create include/wine/server_protocol.h.new";
 381 print SERVER_PROT "/*\n * Wine server protocol definitions\n *\n";
 382 print SERVER_PROT " * This file is automatically generated; DO NO EDIT!\n";
 383 print SERVER_PROT " * Edit server/protocol.def instead and re-run tools/make_requests\n";
 384 print SERVER_PROT " */\n\n";
 385 print SERVER_PROT "#ifndef __WINE_WINE_SERVER_PROTOCOL_H\n";
 386 print SERVER_PROT "#define __WINE_WINE_SERVER_PROTOCOL_H\n";
 387
 388 ### Parse requests to find request/reply structure definitions
 389
 390 PARSE_REQUESTS();
 391
 392 ### Build the request list and structures
 393
 394 print SERVER_PROT "\n\nenum request\n{\n";
 395 foreach my $req (@requests) { print SERVER_PROT "    REQ_$req,\n"; }
 396 print SERVER_PROT "    REQ_NB_REQUESTS\n};\n\n";
 397
 398 print SERVER_PROT "union generic_request\n{\n";
 399 print SERVER_PROT "    struct request_max_size max_size;\n";
 400 print SERVER_PROT "    struct request_header request_header;\n";
 401 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_request ${req}_request;\n"; }
 402 print SERVER_PROT "};\n";
 403
 404 print SERVER_PROT "union generic_reply\n{\n";
 405 print SERVER_PROT "    struct request_max_size max_size;\n";
 406 print SERVER_PROT "    struct reply_header reply_header;\n";
 407 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_reply ${req}_reply;\n"; }
 408 print SERVER_PROT "};\n\n";
 409
 410 print SERVER_PROT "/* ### protocol_version begin ### */\n\n";
 411 printf SERVER_PROT "#define SERVER_PROTOCOL_VERSION %d\n\n", $protocol;
 412 print SERVER_PROT "/* ### protocol_version end ### */\n\n";
 413 print SERVER_PROT "#endif /* __WINE_WINE_SERVER_PROTOCOL_H */\n";
 414 close SERVER_PROT;
 415
 416 if (update_file( "include/wine/server_protocol.h" ))
 417 {
 418     my @version_lines = ();
 419
 420     push @version_lines, sprintf( "#define SERVER_PROTOCOL_VERSION %d\n", $protocol + 1 );
 421
 422     replace_in_file( "include/wine/server_protocol.h",
 423                      "### protocol_version begin ###",
 424                      "### protocol_version end ###",
 425                      @version_lines );
 426 }
 427
 428 ### Output the dumping function tables
 429
 430 push @trace_lines, "static const dump_func req_dumpers[REQ_NB_REQUESTS] = {\n";
 431 foreach my $req (@requests)
 432 {
 433     push @trace_lines, "    (dump_func)dump_${req}_request,\n";
 434 }
 435 push @trace_lines, "};\n\n";
 436
 437 push @trace_lines, "static const dump_func reply_dumpers[REQ_NB_REQUESTS] = {\n";
 438 foreach my $req (@requests)
 439 {
 440     push @trace_lines, "    ", $replies{$req} ? "(dump_func)dump_${req}_reply,\n" : "NULL,\n";
 441 }
 442 push @trace_lines, "};\n\n";
 443
 444 push @trace_lines, "static const char * const req_names[REQ_NB_REQUESTS] = {\n";
 445 foreach my $req (@requests)
 446 {
 447     push @trace_lines, "    \"$req\",\n";
 448 }
 449 push @trace_lines, "};\n\n";
 450
 451 push @trace_lines, "static const struct\n{\n";
 452 push @trace_lines, "    const char  *name;\n";
 453 push @trace_lines, "    unsigned int value;\n";
 454 push @trace_lines, "} status_names[] =\n{\n";
 455
 456 foreach my $err (sort keys %errors)
 457 {
 458     push @trace_lines, sprintf("    { %-30s %s },\n", "\"$err\",", $errors{$err});
 459 }
 460 push @trace_lines, "    { NULL, 0 }\n";
 461 push @trace_lines, "};\n";
 462
 463 replace_in_file( "server/trace.c",
 464                  "### make_requests begin ###",
 465                  "### make_requests end ###",
 466                  @trace_lines );
 467
 468 ### Output the request handlers list
 469
 470 my @request_lines = ();
 471
 472 foreach my $req (@requests) { push @request_lines, "DECL_HANDLER($req);\n"; }
 473 push @request_lines, "\n#ifdef WANT_REQUEST_HANDLERS\n\n";
 474 push @request_lines, "typedef void (*req_handler)( const void *req, void *reply );\n";
 475 push @request_lines, "static const req_handler req_handlers[REQ_NB_REQUESTS] =\n{\n";
 476 foreach my $req (@requests)
 477 {
 478     push @request_lines, "    (req_handler)req_$req,\n";
 479 }
 480 push @request_lines, "};\n\n";
 481
 482 foreach my $type (sort keys %formats)
 483 {
 484     my $size = ${$formats{$type}}[0];
 485     push @request_lines, "C_ASSERT( sizeof($type) == $size );\n";
 486 }
 487 push @request_lines, @asserts;
 488 push @request_lines, "\n#endif  /* WANT_REQUEST_HANDLERS */\n";
 489
 490 replace_in_file( "server/request.h",
 491                  "### make_requests begin ###",
 492                  "### make_requests end ###",
 493                  @request_lines );