configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17 AC_ARG_ENABLE(maintainer-mode, AS_HELP_STRING([--enable-maintainer-mode],[enable maintainer-specific build rules]),
  18                                ,[AC_SUBST([MAINTAINER_MODE],[\#])])
  19
  20 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  21             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  22 AC_ARG_WITH(audioio,   AS_HELP_STRING([--without-audioio],[do not use the AudioIO sound support]),
  23             [if test "x$withval" = "xno"; then ac_cv_header_libaudioio_h=no; fi])
  24 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]),
  25             [if test "x$withval" = "xno"; then ac_cv_header_capi20_h=no; ac_cv_header_linux_capi_h=no; fi])
  26 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]),
  27             [if test "x$withval" = "xno"; then ac_cv_header_lcms_h=no; ac_cv_header_lcms_lcms_h=no; fi])
  28 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  29             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  30 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]))
  31 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  32             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  33 AC_ARG_WITH(esd,       AS_HELP_STRING([--without-esd],[do not use the EsounD sound support]))
  34 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]),
  35             [if test "x$withval" = "xno"; then ac_cv_header_fontconfig_fontconfig_h=no; fi])
  36 AC_ARG_WITH(freetype,  AS_HELP_STRING([--without-freetype],[do not use the FreeType library]))
  37 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  38 AC_ARG_WITH(glu,       AS_HELP_STRING([--without-glu],[do not use the GLU library]),
  39             [if test "x$withval" = "xno"; then ac_cv_header_GL_glu_h=no; fi])
  40 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  41 AC_ARG_WITH(jack,      AS_HELP_STRING([--without-jack],[do not use the Jack sound support]),
  42             [if test "x$withval" = "xno"; then ac_cv_header_jack_jack_h=no; fi])
  43 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]),
  44             [if test "x$withval" = "xno"; then ac_cv_header_jpeglib_h=no; fi])
  45 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  46             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  47 AC_ARG_WITH(nas,       AS_HELP_STRING([--without-nas],[do not use the NAS sound support]),
  48             [if test "x$withval" = "xno"; then ac_cv_header_audio_audiolib_h=no; fi])
  49 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  50 AC_ARG_WITH(openssl,   AS_HELP_STRING([--without-openssl],[do not use OpenSSL]),
  51             [if test "x$withval" = "xno"; then ac_cv_header_openssl_err_h=no; ac_cv_header_openssl_ssl_h=no; fi])
  52 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]),
  53             [if test "x$withval" = "xno"; then ac_cv_header_soundcard_h=no; ac_cv_header_sys_soundcard_h=no; ac_cv_header_machine_soundcard_h=no; fi])
  54 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]),
  55             [if test "x$withval" = "xno"; then ac_cv_header_png_h=no; fi])
  56 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  57 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  58             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  59 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  60             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  61 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  62             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  63 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  64             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  65 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  66 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  67             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  68 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
  69             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
  70 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
  71             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
  72 AC_ARG_WITH(xshm,      AS_HELP_STRING([--without-xshm],[do not use XShm (shared memory extension)]),
  73             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XShm_h=no; fi])
  74 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
  75 AC_ARG_WITH(xxf86vm,   AS_HELP_STRING([--without-xxf86vm],[do not use XFree video mode extension]),
  76             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; fi])
  77
  78 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
  79
  80 AC_CANONICAL_HOST
  81 case $host in
  82   x86_64*linux*)
  83     if test "x$enable_win64" != "xyes"
  84     then
  85       test -n "$CC" || CC="gcc -m32"
  86       test -n "$CXX"|| CXX="g++ -m32"
  87       test -n "$LD" || LD="ld -m elf_i386"
  88       test -n "$AS" || AS="as --32"
  89       host_cpu="i386"
  90     fi
  91     ;;
  92 esac
  93
  94 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  95 case $host_cpu in
  96   *i[[3456789]]86*)
  97     if test "x$enable_win16" != "xno"
  98     then
  99       enable_win16="yes"
 100     fi
 101     ;;
 102 esac
 103
 104 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
 105 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
 106 if test "x$enable_win16" != "xyes"
 107 then
 108   WIN16_FILES=""
 109   WIN16_INSTALL=""
 110 fi
 111
 112 dnl check for out of tree build with unclean source tree
 113 case "$srcdir" in
 114  .) ;;
 115  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 116       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 117 You need to run 'make distclean' in the source tree first.])
 118     fi ;;
 119 esac
 120
 121 dnl **** Check for some programs ****
 122
 123 AC_PROG_MAKE_SET
 124 AC_PROG_CC
 125 AC_PROG_CXX
 126 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 127 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 128
 129 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 130   [if test -z "$with_wine_tools"; then
 131      if test "$cross_compiling" = "yes"; then
 132        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 133      else
 134        wine_cv_toolsdir="\$(TOPOBJDIR)"
 135      fi
 136    elif test -d "$with_wine_tools/tools/winebuild"; then
 137      case $with_wine_tools in
 138        /*) wine_cv_toolsdir="$with_wine_tools" ;;
 139        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
 140      esac
 141    else
 142      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
 143    fi])
 144 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 145
 146 AC_PATH_XTRA
 147
 148 dnl Check for flex
 149 AC_CHECK_PROGS(FLEX,flex,none)
 150 if test "$FLEX" = "none"
 151 then
 152   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 153 fi
 154
 155 dnl Check for bison
 156 AC_CHECK_PROGS(BISON,bison,none)
 157 if test "$BISON" = "none"
 158 then
 159   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 160 fi
 161
 162 AC_CHECK_TOOLS(AS,[gas as],as)
 163 AC_CHECK_TOOLS(LD,[ld gld],ld)
 164 AC_CHECK_TOOLS(NM,[nm gnm],nm)
 165 AC_CHECK_TOOLS(AR,[ar gar],ar)
 166 AC_SUBST(ARFLAGS,rc)
 167 AC_PROG_RANLIB
 168 AC_CHECK_TOOL(STRIP,strip,strip)
 169 AC_CHECK_TOOL(WINDRES,windres,false)
 170 AC_PROG_LN_S
 171 WINE_PROG_LN
 172 AC_PROG_EGREP
 173 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 174 AC_PROG_INSTALL
 175 dnl Prepend src dir to install path dir if it's a relative path
 176 case "$INSTALL" in
 177   [[\\/$]]* | ?:[[\\/]]* ) ;;
 178   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 179 esac
 180
 181 dnl Check for lint
 182 AC_CHECK_PROGS(LINT, lclint lint)
 183 if test "$LINT" = "lint"
 184 then
 185   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 186   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 187 fi
 188 AC_SUBST(LINT)
 189 AC_SUBST(LINTFLAGS)
 190
 191 dnl Check for various programs
 192 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 193 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 194 AC_CHECK_PROGS(RSVG, rsvg, false)
 195 AC_CHECK_PROGS(ICOTOOL, icotool, false)
 196
 197 if test "${enable_maintainer_mode+set}" = set
 198 then
 199   if test "$FONTFORGE" = "false"; then WINE_WARNING([fontforge is missing, fonts can't be rebuilt.]); fi
 200   if test "$RSVG" = "false"; then WINE_WARNING([rsvg is missing, icons can't be rebuilt.]); fi
 201   if test "$ICOTOOL" = "false"; then WINE_WARNING([icotool is missing, icons can't be rebuilt.]); fi
 202 fi
 203
 204 case $host_cpu in
 205   *i[[3456789]]86*)
 206     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 207     ;;
 208 esac
 209
 210 dnl **** Check for some libraries ****
 211
 212 dnl Check for -li386 for NetBSD and OpenBSD
 213 AC_CHECK_LIB(i386,i386_set_ldt)
 214 dnl Check for -lossaudio for NetBSD
 215 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 216 dnl Check for -lpthread
 217 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 218
 219 AC_SUBST(XLIB,"")
 220 AC_SUBST(XFILES,"")
 221 AC_SUBST(OPENGLFILES,"")
 222 AC_SUBST(GLU32FILES,"")
 223 AC_SUBST(OPENGL_LIBS,"")
 224 AC_SUBST(QUARTZFILES,"")
 225
 226 dnl **** Check for header files ****
 227
 228 AC_CHECK_HEADERS(\
 229         AudioUnit/AudioUnit.h \
 230         Carbon/Carbon.h \
 231         CoreAudio/CoreAudio.h \
 232         DiskArbitration/DiskArbitration.h \
 233         IOKit/IOKitLib.h \
 234         alias.h \
 235         alsa/asoundlib.h \
 236         arpa/inet.h \
 237         arpa/nameser.h \
 238         asm/types.h \
 239         capi20.h \
 240         curses.h \
 241         direct.h \
 242         dlfcn.h \
 243         elf.h \
 244         float.h \
 245         fontconfig/fontconfig.h \
 246         getopt.h \
 247         ieeefp.h \
 248         io.h \
 249         jack/jack.h \
 250         jpeglib.h \
 251         lber.h \
 252         lcms.h \
 253         lcms/lcms.h \
 254         ldap.h \
 255         libaudioio.h \
 256         link.h \
 257         linux/cdrom.h \
 258         linux/compiler.h \
 259         linux/hdreg.h \
 260         linux/input.h \
 261         linux/ioctl.h \
 262         linux/joystick.h \
 263         linux/major.h \
 264         linux/param.h \
 265         linux/serial.h \
 266         linux/ucdrom.h \
 267         mach/mach.h \
 268         mach/machine.h \
 269         machine/cpu.h \
 270         machine/limits.h \
 271         machine/soundcard.h \
 272         mntent.h \
 273         ncurses.h \
 274         netdb.h \
 275         netinet/in.h \
 276         netinet/in_systm.h \
 277         netinet/tcp.h \
 278         netinet/tcp_fsm.h \
 279         openssl/err.h \
 280         openssl/ssl.h \
 281         png.h \
 282         poll.h \
 283         process.h \
 284         pthread.h \
 285         pwd.h \
 286         regex.h \
 287         sched.h \
 288         scsi/scsi.h \
 289         scsi/scsi_ioctl.h \
 290         scsi/sg.h \
 291         soundcard.h \
 292         stdint.h \
 293         strings.h \
 294         sys/asoundlib.h \
 295         sys/cdio.h \
 296         sys/elf32.h \
 297         sys/epoll.h \
 298         sys/errno.h \
 299         sys/event.h \
 300         sys/exec_elf.h \
 301         sys/filio.h \
 302         sys/ioctl.h \
 303         sys/ipc.h \
 304         sys/limits.h \
 305         sys/link.h \
 306         sys/lwp.h \
 307         sys/mman.h \
 308         sys/modem.h \
 309         sys/msg.h \
 310         sys/mtio.h \
 311         sys/param.h \
 312         sys/poll.h \
 313         sys/prctl.h \
 314         sys/ptrace.h \
 315         sys/reg.h \
 316         sys/resource.h \
 317         sys/scsiio.h \
 318         sys/shm.h \
 319         sys/signal.h \
 320         sys/socket.h \
 321         sys/socketvar.h \
 322         sys/sockio.h \
 323         sys/soundcard.h \
 324         sys/statvfs.h \
 325         sys/strtio.h \
 326         sys/syscall.h \
 327         sys/sysctl.h \
 328         sys/time.h \
 329         sys/times.h \
 330         sys/uio.h \
 331         sys/un.h \
 332         sys/vm86.h \
 333         sys/wait.h \
 334         syscall.h \
 335         termios.h \
 336         unistd.h \
 337         utime.h \
 338         valgrind/memcheck.h \
 339         valgrind/valgrind.h
 340 )
 341 AC_HEADER_STAT()
 342
 343 dnl **** Checks for headers that depend on other ones ****
 344
 345 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 346     [#include <sys/types.h>
 347      #ifdef HAVE_SYS_PARAM_H
 348      # include <sys/param.h>
 349      #endif])
 350
 351 AC_CHECK_HEADERS(\
 352         netinet/ip.h \
 353         net/if.h \
 354         net/if_arp.h \
 355         net/if_dl.h \
 356         net/if_types.h \
 357         net/route.h \
 358         netinet/if_ether.h \
 359         netinet/in_pcb.h \
 360         netinet/ip_icmp.h \
 361         netinet/ip_var.h \
 362         netinet/udp.h \
 363         netipx/ipx.h \
 364 ,,,[#include <sys/types.h>
 365      #ifdef HAVE_SYS_SOCKET_H
 366      # include <sys/socket.h>
 367      #endif
 368      #ifdef HAVE_SYS_SOCKETVAR_H
 369      # include <sys/socketvar.h>
 370      #endif
 371      #ifdef HAVE_NETINET_IN_H
 372      # include <netinet/in.h>
 373      #endif
 374      #ifdef HAVE_NETINET_IP_H
 375      # include <netinet/ip.h>
 376      #endif])
 377
 378 AC_CHECK_HEADERS([netinet/tcp_var.h netinet/udp_var.h netinet/icmp_var.h netinet/tcp_timer.h ],,,
 379     [#include <sys/types.h>
 380      #ifdef HAVE_ALIAS_H
 381      # include <alias.h>
 382      #endif
 383      #ifdef HAVE_SYS_SOCKET_H
 384      # include <sys/socket.h>
 385      #endif
 386      #ifdef HAVE_SYS_SOCKETVAR_H
 387      # include <sys/socketvar.h>
 388      #endif
 389      #ifdef HAVE_NETINET_IN_H
 390      # include <netinet/in.h>
 391      #endif
 392      #ifdef HAVE_NETINET_IP_H
 393      # include <netinet/ip.h>
 394      #endif
 395      #ifdef HAVE_NETINET_IP_VAR_H
 396      # include <netinet/ip_var.h>
 397      #endif
 398      #ifdef HAVE_NETINET_IP_ICMP_H
 399      # include <netinet/ip_icmp.h>
 400      #endif
 401      #ifdef HAVE_NETINET_UDP_H
 402      # include <netinet/udp.h>
 403      #endif
 404      #ifdef HAVE_NETINET_TCP_H
 405      # include <netinet/tcp.h>
 406      #endif])
 407
 408 AC_CHECK_HEADERS([linux/ipx.h],,,
 409     [#include <sys/types.h>
 410      #ifdef HAVE_ASM_TYPES_H
 411      # include <asm/types.h>
 412      #endif
 413      #ifdef HAVE_SYS_SOCKET_H
 414      # include <sys/socket.h>
 415      #endif])
 416
 417 AC_CHECK_HEADERS([resolv.h],,,
 418     [#include <sys/types.h>
 419      #ifdef HAVE_SYS_SOCKET_H
 420      # include <sys/socket.h>
 421      #endif
 422      #ifdef HAVE_NETINET_IN_H
 423      # include <netinet/in.h>
 424      #endif
 425      #ifdef HAVE_ARPA_NAMESER_H
 426      # include <arpa/nameser.h>
 427      #endif])
 428
 429 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 430
 431 AC_CHECK_HEADERS([sys/thr.h],,,
 432 [#include <sys/types.h>
 433 #ifdef HAVE_UCONTEXT_H
 434 #include <ucontext.h>
 435 #endif])
 436
 437 AC_CHECK_HEADERS([pthread_np.h],,,
 438 [#ifdef HAVE_PTHREAD_H
 439 #include <pthread.h>
 440 #endif])
 441
 442 AC_CHECK_HEADERS([linux/videodev.h],,,
 443 [#ifdef HAVE_SYS_TIME_H
 444 #include <sys/time.h>
 445 #endif
 446 #include <sys/types.h>
 447 #ifdef HAVE_ASM_TYPES_H
 448 #include <asm/types.h>
 449 #endif])
 450
 451 dnl Check for broken kernel header that doesn't define __user
 452 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 453
 454 dnl **** Check for working dll ****
 455
 456 AC_SUBST(DLLEXT,"")
 457 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 458 AC_SUBST(LDSHARED,"")
 459 AC_SUBST(LDDLLFLAGS,"")
 460 AC_SUBST(LIBEXT,"so")
 461 AC_SUBST(IMPLIBEXT,"def")
 462 AC_SUBST(LDRPATH_INSTALL,"")
 463 AC_SUBST(LDRPATH_LOCAL,"")
 464 WINE_PATH_LDD
 465
 466 case $host_os in
 467   cygwin*|mingw32*)
 468     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 469     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 470     AC_CHECK_TOOL(MINGWAR,ar,false)
 471     if test "$DLLWRAP" = "false"; then
 472       LIBEXT="a"
 473     else
 474       dnl FIXME - check whether dllwrap works correctly...
 475       LIBEXT="dll"
 476     fi
 477     IMPLIBEXT="a"
 478     dnl We can't build 16-bit NE dlls
 479     WIN16_FILES=""
 480     WIN16_INSTALL=""
 481     ;;
 482   darwin*|macosx*)
 483     DLLEXT=".so"
 484     LIBEXT="dylib"
 485     DLLFLAGS="$DLLFLAGS -fPIC"
 486     LDDLLFLAGS="-bundle -multiply_defined suppress"
 487     LIBWINE_LDFLAGS="-multiply_defined suppress"
 488     LDSHARED="\$(CC) -dynamiclib"
 489     STRIP="$STRIP -x"
 490     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 491     dnl declare needed frameworks
 492     AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 493     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 494     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 495     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 496     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 497     then
 498         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 499         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 500     fi
 501     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 502     then
 503         dnl CoreServices needed by AudioUnit
 504         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 505     fi
 506     case $host_cpu in
 507       *powerpc*)
 508         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 509         ;;
 510     esac
 511     dnl Enable quartz driver on Mac OS X
 512     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 513     then
 514         AC_SUBST(CARBONLIB,"-framework Carbon")
 515         QUARTZFILES='$(QUARTZFILES)'
 516     fi
 517     ;;
 518   *)
 519     DLLFLAGS="$DLLFLAGS -fPIC"
 520     DLLEXT=".so"
 521     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 522         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 523                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 524     if test "$ac_cv_c_dll_gnuelf" = "yes"
 525     then
 526       LDSHARED="\$(CC) -shared"
 527       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 528       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 529                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 530                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 531                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 532
 533       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 534
 535       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 536                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 537
 538       echo '{ global: *; };' >conftest.map
 539       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 540                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 541       rm -f conftest.map
 542
 543       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 544                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 545
 546       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 547                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 548                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 549           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 550                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 551                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 552
 553       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 554                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 555
 556       case $host_cpu in
 557         *i[[3456789]]86* | x86_64)
 558           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 559                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 560           ;;
 561       esac
 562
 563     else
 564       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 565           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 566                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 567       if test "$ac_cv_c_dll_unixware" = "yes"
 568       then
 569         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 570         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 571
 572       else
 573         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 574           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 575         if test "$ac_cv_c_dll_hpux" = "yes"
 576         then
 577           LIBEXT="sl"
 578           DLLEXT=".sl"
 579           LDDLLFLAGS="-shared -fPIC"
 580           LDSHARED="\$(CC) -shared"
 581         fi
 582       fi
 583     fi
 584
 585     dnl Check for cross compiler to build test programs
 586     AC_SUBST(CROSSTEST,"")
 587     if test "$cross_compiling" = "no"
 588     then
 589       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 590       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
 591       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
 592       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
 593       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 594     fi
 595     ;;
 596 esac
 597
 598 if test "$LIBEXT" = "a"; then
 599   AC_MSG_ERROR(
 600 [could not find a way to build shared libraries.
 601 It is currently not possible to build Wine without shared library
 602 (.so) support to allow transparent switch between .so and .dll files.
 603 If you are using Linux, you will need a newer binutils.]
 604 )
 605 fi
 606
 607 dnl **** Check for X11 ****
 608
 609 if test "$have_x" = "yes"
 610 then
 611     XLIB="-lXext -lX11"
 612     ac_save_CPPFLAGS="$CPPFLAGS"
 613     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 614
 615     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 616     WINE_CHECK_SONAME(Xext,XextCreateExtension,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 617
 618     dnl *** All of the following tests require X11/Xlib.h
 619     AC_CHECK_HEADERS([X11/Xlib.h \
 620                       X11/XKBlib.h \
 621                       X11/Xutil.h \
 622                       X11/Xcursor/Xcursor.h \
 623                       X11/extensions/shape.h \
 624                       X11/extensions/XInput.h \
 625                       X11/extensions/XShm.h \
 626                       X11/extensions/Xcomposite.h \
 627                       X11/extensions/Xinerama.h \
 628                       X11/extensions/Xrandr.h \
 629                       X11/extensions/Xrender.h \
 630                       X11/extensions/xf86vmode.h],,,
 631 [#ifdef HAVE_X11_XLIB_H
 632 # include <X11/Xlib.h>
 633 #endif
 634 #ifdef HAVE_X11_XUTIL_H
 635 # include <X11/Xutil.h>
 636 #endif])
 637
 638         dnl *** Check for X keyboard extension
 639         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 640         then
 641               AC_CHECK_LIB(X11, XkbQueryExtension,
 642               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 643               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 644         fi
 645
 646         dnl *** Check for X cursor
 647         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 648         then
 649             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 650         fi
 651         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
 652                          [libxcursor development files not found, the Xcursor extension won't be supported.])
 653
 654         dnl *** Check for X input extension
 655         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 656         then
 657             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 658         fi
 659         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
 660                          [libxi development files not found, the Xinput extension won't be supported.])
 661
 662         dnl *** Check for X Shm extension
 663         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 664         then
 665               AC_CHECK_LIB(Xext, XShmQueryExtension,
 666               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 667               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 668         fi
 669         WINE_NOTICE_WITH(xshm,[test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],
 670                          [XShm development files not found, X Shared Memory won't be supported.])
 671
 672         dnl *** Check for X shape extension
 673         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 674         then
 675               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 676               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 677               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 678         fi
 679         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
 680                          [XShape development files not found, XShape won't be supported.])
 681
 682         dnl *** Check for XFree86 VMODE extension
 683         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 684         then
 685             WINE_CHECK_SONAME(Xxf86vm,XF86VidModeQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 686         fi
 687         WINE_NOTICE_WITH(xxf86vm,[test "x$ac_cv_lib_soname_Xxf86vm" = "x"],
 688                          [libXxf86vm development files not found, XFree86 Vidmode won't be supported.])
 689
 690         dnl *** Check for Transform functions in Xrender
 691         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
 692         then
 693             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
 694               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
 695                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 696                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 697                 [$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])],,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 698
 699         fi
 700         WINE_WARNING_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
 701                          [libxrender development files not found, XRender won't be supported.])
 702
 703         dnl *** Check for X RandR extension
 704         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
 705         then
 706                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 707 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 708                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 709         fi
 710         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
 711                          [libxrandr development files not found, XRandr won't be supported.])
 712
 713         dnl *** Check for Xinerama extension
 714         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 715         then
 716                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 717 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 718                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 719         fi
 720         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
 721                          [libxinerama development files not found, multi-monitor setups won't be supported.])
 722
 723         dnl *** Check for X Composite extension
 724         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
 725         then
 726             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 727         fi
 728         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
 729                          [libxcomposite development files not found, Xcomposite won't be supported.])
 730
 731         dnl *** Check for XICCallback struct
 732         AC_CHECK_MEMBERS([XICCallback.callback],,,
 733 [#ifdef HAVE_X11_XLIB_H
 734 #include <X11/Xlib.h>
 735 #endif])
 736
 737     dnl *** End of X11/Xlib.h check
 738
 739     dnl Check for the presence of OpenGL
 740     opengl_msg=""
 741     if test "x$with_opengl" != "xno"
 742     then
 743         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 744 [#ifdef HAVE_GL_GLX_H
 745 # include <GL/glx.h>
 746 #endif])
 747         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 748         then
 749             dnl Check for some problems due to old Mesa versions
 750             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 751               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 752                 [wine_cv_opengl_header_version_OK="yes"],
 753                 [wine_cv_opengl_header_version_OK="no"]))
 754
 755             if test "$wine_cv_opengl_header_version_OK" = "yes"
 756             then
 757                 dnl Check for the presence of the library
 758                 WINE_CHECK_SONAME(GL,glXCreateContext,
 759                              [OPENGL_LIBS="-lGL"
 760                              OPENGLFILES='$(OPENGLFILES)'
 761                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 762                              [WINE_CHECK_SONAME(GL,glXCreateContext,
 763                                     [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"
 764                                     OPENGLFILES='$(OPENGLFILES)'
 765                                     AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 766                                     [if test -f /usr/X11R6/lib/libGL.a
 767                                     then
 768                                         opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
 769 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
 770                                     else
 771                                         opengl_msg="No OpenGL library found on this system."
 772                                     fi],
 773                                     $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
 774                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 775                  if test "$ac_cv_header_GL_glu_h" = "yes"
 776                  then
 777                     WINE_CHECK_SONAME(GLU,gluLookAt,[GLU32FILES='$(GLU32FILES)'],,
 778                                       [$OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS])
 779                  fi
 780                  WINE_NOTICE_WITH(glu,[test "x$ac_cv_lib_soname_GLU" = "x"],
 781                                  [libGLU development files not found, GLU won't be supported.])
 782              else
 783                  opengl_msg="Old Mesa headers detected. Consider upgrading your Mesa libraries."
 784              fi
 785          else
 786              opengl_msg="OpenGL development headers not found."
 787          fi
 788     fi
 789     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
 790 OpenGL and Direct3D won't be supported.])
 791
 792     dnl **** Check for NAS ****
 793     AC_SUBST(NASLIBS,"")
 794     AC_CHECK_HEADERS(audio/audiolib.h,
 795          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 796           AC_CHECK_LIB(audio,AuCreateFlow,
 797                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 798                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 799                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 800                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 801                           [$X_LIBS])
 802                        ],,
 803                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 804
 805     CPPFLAGS="$ac_save_CPPFLAGS"
 806     XFILES='$(XFILES)'
 807 else
 808     XLIB=""
 809     X_CFLAGS=""
 810     X_LIBS=""
 811 fi
 812 WINE_ERROR_WITH(x,[test "x$XLIB" = "x"],[X development files not found. Wine will be built
 813 without X support, which probably isn't what you want. You will need to install
 814 development packages of Xlib/Xfree86 at the very least.])
 815
 816 dnl **** Check for libxml2 ****
 817
 818 AC_SUBST(XML2LIBS,"")
 819 AC_SUBST(XML2INCL,"")
 820 AC_SUBST(XSLTLIBS,"")
 821 AC_SUBST(XSLTINCL,"")
 822 if test "x$with_xml" != "xno"
 823 then
 824     ac_save_CPPFLAGS="$CPPFLAGS"
 825     if test "$PKG_CONFIG" != "false"
 826     then
 827         ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 828         ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 829     else
 830         ac_xml_libs="`xml2-config --libs 2>/dev/null`"
 831         ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
 832     fi
 833     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 834     AC_CHECK_HEADERS(libxml/parser.h,
 835             [AC_CHECK_LIB(xml2, xmlParseMemory,
 836                 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 837                  XML2LIBS="$ac_xml_libs"
 838                  XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 839              AC_CHECK_LIB(xml2, xmlReadMemory,
 840                 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 841              AC_CHECK_LIB(xml2, xmlNewDocPI,
 842                 [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 843         ])
 844     CPPFLAGS="$ac_save_CPPFLAGS"
 845 fi
 846 WINE_WARNING_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
 847                  [libxml2 development files not found, XML won't be supported.])
 848
 849 if test "x$with_xslt" != "xno"
 850 then
 851     if test "$PKG_CONFIG" != "false"
 852     then
 853         ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 854         ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 855     else
 856         ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
 857         ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
 858     fi
 859     ac_save_CPPFLAGS="$CPPFLAGS"
 860     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 861     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],,,
 862     [#ifdef HAVE_LIBXSLT_PATTERN_H
 863 # include <libxslt/pattern.h>
 864 #endif])
 865     CPPFLAGS="$ac_save_CPPFLAGS"
 866     if test "$ac_cv_header_libxslt_transform_h" = "yes"
 867     then
 868         AC_CHECK_LIB(xslt, xsltCompilePattern,
 869             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 870              XSLTLIBS="$ac_xslt_libs"
 871              XSLTINCL="$ac_xslt_cflags"
 872              ac_save_LIBS="$LIBS"
 873              LIBS="$LIBS $ac_xslt_libs"
 874              AC_CHECK_FUNCS(xsltInit)
 875              LIBS="$ac_save_LIBS"],,$ac_xslt_libs)
 876     fi
 877 fi
 878 WINE_WARNING_WITH(xslt,[test "$ac_cv_lib_xslt_xsltCompilePattern" != "yes"],
 879                  [libxslt development files not found, xslt won't be supported.])
 880
 881 dnl **** Check for libhal ****
 882 AC_SUBST(HALINCL,"")
 883 if test "x$with_hal" != "xno" -a "$PKG_CONFIG" != "false"
 884 then
 885     ac_save_CPPFLAGS="$CPPFLAGS"
 886     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 887     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 888     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 889     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 890     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 891     then
 892         AC_CHECK_LIB(dbus-1, dbus_connection_close,
 893           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
 894             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
 895     fi
 896     CPPFLAGS="$ac_save_CPPFLAGS"
 897 fi
 898 WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x"],
 899                  [libhal development files not found, no dynamic device support.])
 900
 901 dnl **** Check which curses lib to use ***
 902 CURSESLIBS=""
 903 if test "$ac_cv_header_ncurses_h" = "yes"
 904 then
 905     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
 906 elif test "$ac_cv_header_curses_h" = "yes"
 907 then
 908     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
 909 fi
 910 ac_save_LIBS="$LIBS"
 911 LIBS="$LIBS $CURSESLIBS"
 912 AC_CHECK_FUNCS(mousemask)
 913 LIBS="$ac_save_LIBS"
 914 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
 915                  [lib(n)curses development files not found, curses won't be supported.])
 916
 917 dnl **** Check for SANE ****
 918 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 919 if test "$sane_devel" != "no" -a "x$with_sane" != "xno"
 920 then
 921     ac_sane_incl="`$sane_devel --cflags`"
 922     ac_sane_libs="`$sane_devel --ldflags`"
 923     ac_save_CPPFLAGS="$CPPFLAGS"
 924     CPPFLAGS="$CPPFLAGS $ac_sane_incl"
 925     AC_CHECK_HEADER(sane/sane.h,
 926         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")],,[$ac_sane_libs])])
 927     CPPFLAGS="$ac_save_CPPFLAGS"
 928 fi
 929 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
 930                  [libsane development files not found, scanners won't be supported.])
 931
 932 dnl **** Check for libgphoto2 ****
 933 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 934 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 935 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no" -a "x$with_gphoto" != "xno"
 936 then
 937     ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 938     ac_gphoto2_libs=""
 939     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 940     do
 941       case "$i" in
 942         -L/usr/lib|-L/usr/lib64) ;;
 943         -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
 944       esac
 945     done
 946     ac_save_CPPFLAGS="$CPPFLAGS"
 947     CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
 948     AC_CHECK_HEADER(gphoto2-camera.h,
 949                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 950                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
 951                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
 952                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
 953                                   [$ac_gphoto2_libs])])
 954     CPPFLAGS="$ac_save_CPPFLAGS"
 955 fi
 956 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
 957                  [libgphoto2 development files not found, digital cameras won't be supported.])
 958
 959
 960 dnl **** Check for resolver library ***
 961 AC_SUBST(RESOLVLIBS,"")
 962 if test "$ac_cv_header_resolv_h" = "yes"
 963 then
 964     AC_CHECK_LIB(resolv, res_query,
 965         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 966          RESOLVLIBS="-lresolv"])
 967 fi
 968
 969 dnl **** Check for LittleCMS ***
 970 AC_SUBST(LCMSLIBS,"")
 971 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 972 then
 973     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 974         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 975          LCMSLIBS="-llcms"])
 976 fi
 977 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],
 978                  [liblcms development files not found, Color Management won't be supported.])
 979
 980 dnl **** Check for FreeType 2 ****
 981 AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],false)
 982 if test "$ft_devel" != "false" -a "x$with_freetype" != "xno"
 983 then
 984     ac_freetype_libs=`$ft_devel --libs`
 985     ac_freetype_incl=`$ft_devel --cflags`
 986     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
 987     if test "$ft_lib" = "yes"
 988     then
 989         ac_save_CPPFLAGS="$CPPFLAGS"
 990         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
 991         AC_CHECK_HEADERS(ft2build.h \
 992                          freetype/freetype.h \
 993                          freetype/ftglyph.h \
 994                          freetype/fttypes.h \
 995                          freetype/tttables.h \
 996                          freetype/ftnames.h \
 997                          freetype/ftsnames.h \
 998                          freetype/ttnameid.h \
 999                          freetype/ftoutln.h \
1000                          freetype/ftwinfnt.h \
1001                          freetype/ftmodapi.h \
1002                          freetype/internal/sfnt.h,,,
1003                          [#ifdef HAVE_FT2BUILD_H
1004                           # include <ft2build.h>
1005                           #endif])
1006         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
1007                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
1008           [Define if you have the <freetype/fttrigon.h> header file.])
1009                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
1010         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
1011         ac_save_CFLAGS="$CFLAGS"
1012         CFLAGS="$CFLAGS $ac_freetype_libs"
1013         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
1014         CFLAGS="$ac_save_CFLAGS"
1015         CPPFLAGS="$ac_save_CPPFLAGS"
1016         dnl Check that we have at least freetype/freetype.h
1017         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
1018         then
1019             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
1020             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
1021             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
1022             AC_SUBST(FONTSSUBDIRS,"fonts")
1023         fi
1024     fi
1025 fi
1026 WINE_ERROR_WITH(freetype,[test "x$FREETYPELIBS" = "x"],[FreeType development files not found.
1027 Fonts will not be built. Dialog text may be invisible or unaligned.])
1028
1029 dnl **** Check for parport (currently Linux only) ****
1030 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1031  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1032     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1033 if test "$ac_cv_c_ppdev" = "yes"
1034 then
1035     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1036 fi
1037
1038 dnl **** Check for va_copy ****
1039 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
1040  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; va_copy(ap1,ap2);]])],
1041     [ac_cv_c_va_copy="yes"],[ac_cv_c_va_copy="no"])
1042  )
1043 if test "$ac_cv_c_va_copy" = "yes"
1044 then
1045     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
1046 fi
1047 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
1048  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; __va_copy(ap1,ap2);]])],
1049     [ac_cv_c___va_copy="yes"],[ac_cv_c___va_copy="no"])
1050  )
1051 if test "$ac_cv_c___va_copy" = "yes"
1052 then
1053     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
1054 fi
1055
1056 dnl **** Check for pthread_rwlock_t ****
1057 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
1058 #include <pthread.h>])
1059
1060 dnl **** Check for pthread functions ****
1061 WINE_CHECK_LIB_FUNCS(\
1062         pthread_attr_get_np \
1063         pthread_getattr_np \
1064         pthread_get_stackaddr_np \
1065         pthread_get_stacksize_np,
1066         [$LIBPTHREAD])
1067
1068 dnl **** Check for EsounD ****
1069 AC_PATH_PROG(ESDCONFIG, esd-config)
1070 if test "x$with_esd" != xno -a "x$ESDCONFIG" != x -a "x$ESDCONFIG" != x'"$ESDCONFIG"';
1071 then
1072     ac_esd_incl=""
1073     for i in `$ESDCONFIG --cflags`
1074     do
1075       case "$i" in
1076         -I*) ac_esd_incl="$ac_esd_incl $i";;
1077       esac
1078     done
1079     ac_esd_libs=`$ESDCONFIG --libs`
1080     save_CFLAGS="$CFLAGS"
1081     CFLAGS="$CFLAGS $ac_esd_incl"
1082     AC_CHECK_LIB(esd,esd_open_sound,
1083         [AC_SUBST(ESDINCL, "$ac_esd_incl")
1084          AC_SUBST(ESDLIBS, "$ac_esd_libs")
1085          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])],,
1086         [$ac_esd_libs])
1087     CFLAGS="$save_CFLAGS"
1088 fi
1089
1090 dnl **** Check for ALSA 1.x ****
1091 AC_SUBST(ALSALIBS,"")
1092 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1093 then
1094     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
1095         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1096 #include <alsa/asoundlib.h>
1097 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1098 #include <sys/asoundlib.h>
1099 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
1100                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
1101                          ALSALIBS="-lasound"],[])])
1102 fi
1103
1104 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
1105 AC_SUBST(AUDIOIOLIBS,"")
1106 if test "$ac_cv_header_libaudioio_h" = "yes"
1107 then
1108     AC_CHECK_LIB(audioio,AudioIOGetVersion,
1109                   [AUDIOIOLIBS="-laudioio"
1110                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
1111 fi
1112
1113 dnl **** Check for capi4linux ****
1114
1115 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1116 then
1117     WINE_CHECK_SONAME(capi20,capi20_register)
1118 fi
1119 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1120                  [libcapi20 development files not found, ISDN won't be supported.])
1121
1122 dnl **** Check for cups ****
1123 AC_SUBST(CUPSINCL,"")
1124 if test "x$with_cups" != "xno"
1125 then
1126     ac_save_CPPFLAGS="$CPPFLAGS"
1127     ac_cups_cflags=`cups-config --cflags 2>/dev/null`
1128     ac_cups_libs=`cups-config --ldflags 2>/dev/null`
1129     CPPFLAGS="$CPPFLAGS $ac_cups_cflags"
1130     AC_CHECK_HEADERS(cups/cups.h,
1131             [WINE_CHECK_SONAME(cups,cupsGetDefault,
1132                        [CUPSINCL="$ac_cups_cflags"],,
1133                        [$ac_cups_libs])])
1134     CPPFLAGS="$ac_save_CPPFLAGS"
1135 fi
1136 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1137                  [libcups development files not found, CUPS won't be supported.])
1138
1139 dnl **** Check for jack ****
1140 if test "$ac_cv_header_jack_jack_h" = "yes"
1141 then
1142     WINE_CHECK_SONAME(jack,jack_client_new,,,,[[libjack-*[[0-9.]]*]])
1143 fi
1144
1145 dnl **** Check for fontconfig ****
1146 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1147 then
1148     WINE_CHECK_SONAME(fontconfig,FcInit)
1149 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1150 then
1151     dnl fontconfig is in the X directory on Mac OS X
1152     ac_save_CPPFLAGS="$CPPFLAGS"
1153     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1154     $as_unset ac_cv_header_fontconfig_fontconfig_h
1155     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1156     CPPFLAGS="$ac_save_CPPFLAGS"
1157     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1158     then
1159         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1160         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1161     fi
1162 fi
1163 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1164                  [fontconfig development files not found, fontconfig won't be supported.])
1165
1166 dnl **** Check for SSL ****
1167 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1168 then
1169     WINE_CHECK_SONAME(ssl,SSL_library_init)
1170     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1171 fi
1172 WINE_WARNING_WITH(openssl,[test "x$ac_cv_lib_soname_ssl" = "x" -o "x$ac_cv_lib_soname_crypto" = "x"],
1173                  [OpenSSL development files not found, SSL won't be supported.])
1174
1175 dnl **** Check for libjpeg ****
1176 if test "$ac_cv_header_jpeglib_h" = "yes"
1177 then
1178     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1179 fi
1180 WINE_WARNING_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1181                  [libjpeg development files not found, JPEG won't be supported.])
1182
1183 dnl **** Check for libpng ****
1184 if test "$ac_cv_header_png_h" = "yes"
1185 then
1186     WINE_CHECK_SONAME(png,png_create_read_struct,,,-lm,[[libpng[[0-9]]*]])
1187 fi
1188 WINE_WARNING_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1189                  [libpng development files not found, PNG won't be supported.])
1190
1191 dnl **** Check for libodbc ****
1192 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1193
1194 dnl **** Check for any sound system ****
1195 if test "x$ALSALIBS$AUDIOIOLIBS$COREAUDIO$NASLIBS$ESDLIBS$ac_cv_lib_soname_jack" = "x" -a \
1196         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1197         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1198         "$ac_cv_header_soundcard_h" != "yes" -a \
1199         "x$with_alsa$with_audioio$with_coreaudio$with_nas$with_esd$with_jack$with_oss" != xnonononononono
1200 then
1201     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1202 fi
1203
1204 dnl **** Check for gcc specific options ****
1205
1206 AC_SUBST(EXTRACFLAGS,"")
1207 if test "x${GCC}" = "xyes"
1208 then
1209   EXTRACFLAGS="-Wall -pipe"
1210
1211   dnl Check for strength-reduce bug
1212   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1213                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1214 [[static int Array[[3]];
1215   unsigned int B = 3;
1216   int i;
1217   for(i=0; i<B; i++) Array[[i]] = i - 3;
1218   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1219   L[[i]] = 4;
1220   exit( Array[[1]] != -2 || L[[2]] != 3)]])],
1221     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1222   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1223   then
1224     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1225   fi
1226
1227   dnl Check for some compiler flags
1228
1229   WINE_TRY_CFLAGS([-fshort-wchar],
1230                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
1231                              [Specifies the compiler flag that forces a short wchar_t])])
1232   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1233   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1234   WINE_TRY_CFLAGS([-Wwrite-strings])
1235   WINE_TRY_CFLAGS([-Wtype-limits])
1236
1237   dnl Check for noisy string.h
1238   saved_CFLAGS="$CFLAGS"
1239   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1240   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1241       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1242   CFLAGS="$saved_CFLAGS"
1243   if test "$ac_cv_c_string_h_warnings" = "no"
1244   then
1245     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1246   fi
1247
1248   AC_SUBST(BUILTINFLAG,"")
1249   saved_CFLAGS="$CFLAGS"
1250   CFLAGS="$CFLAGS -Werror"
1251   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
1252       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int iswlower(unsigned short);]])],[ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
1253   CFLAGS="$saved_CFLAGS"
1254   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
1255   then
1256     BUILTINFLAG="-fno-builtin"
1257   fi
1258 fi
1259
1260 dnl **** Check how to define a function in assembly code ****
1261
1262 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1263   WINE_TRY_ASM_LINK(
1264       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1265       ac_cv_asm_func_def=".def",
1266     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1267       ac_cv_asm_func_def=".type @function",
1268     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1269       ac_cv_asm_func_def=".type 2",
1270       ac_cv_asm_func_def="unknown")])]))
1271
1272 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1273 case "$ac_cv_asm_func_def" in
1274   ".def")
1275      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
1276   ".type @function")
1277      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
1278   ".type 2")
1279      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
1280   *)
1281      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
1282 esac
1283
1284 dnl **** Check for underscore on external symbols ****
1285
1286 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1287     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1288                       [extern int ac_test;],
1289                       [if (ac_test) return 1],
1290                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1291
1292 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1293 if test "$ac_cv_c_extern_prefix" = "yes"
1294 then
1295   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1296 else
1297   AC_DEFINE([__ASM_NAME(name)], [name])
1298 fi
1299
1300 dnl **** Platform-specific checks ****
1301
1302 AC_SUBST(LDPATH,"")
1303 case $build_os in
1304   cygwin*|mingw32*)
1305     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1306     ;;
1307   darwin*|macosx*)
1308     ;;
1309   linux*|solaris*)  dnl FIXME: What other platforms support $ORIGIN?
1310     if test -z "$LDRPATH_LOCAL"
1311     then
1312       LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1313     fi
1314     ;;
1315   *)
1316     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1317     ;;
1318 esac
1319
1320 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1321 case $host_os in
1322   mingw32*)
1323     AC_SUBST(CRTLIBS,"-lmsvcrt")
1324     AC_SUBST(SOCKETLIBS,"-lws2_32")
1325     ;;
1326 esac
1327
1328 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1329 case $host_cpu in
1330   *i[[3456789]]86*)
1331     case $host_os in
1332       linux* | k*bsd*-gnu)
1333         AC_SUBST(MAIN_BINARY,"wine-glibc")
1334         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1335       freebsd*)
1336         AC_SUBST(MAIN_BINARY,"wine-freebsd")
1337         AC_SUBST(EXTRA_BINARIES,"wine-pthread") ;;
1338     esac
1339     ;;
1340 esac
1341
1342 dnl **** Check for functions ****
1343
1344 AC_CHECK_FUNCS(\
1345         _pclose \
1346         _popen \
1347         _snprintf \
1348         _spawnvp \
1349         _strdup \
1350         _stricmp \
1351         _strnicmp \
1352         _strtoi64 \
1353         _strtoui64 \
1354         _vsnprintf \
1355         asctime_r \
1356         chsize \
1357         clone \
1358         dlopen \
1359         epoll_create \
1360         ffs \
1361         finite \
1362         fork \
1363         fpclass \
1364         fstatfs \
1365         fstatvfs \
1366         ftruncate \
1367         futimes \
1368         futimesat \
1369         getdirentries \
1370         getopt_long \
1371         getpagesize \
1372         getpwuid \
1373         gettid \
1374         gettimeofday \
1375         getuid \
1376         inet_pton \
1377         kqueue \
1378         lstat \
1379         memmove \
1380         mmap \
1381         pclose \
1382         poll \
1383         popen \
1384         prctl \
1385         pread \
1386         pwrite \
1387         readlink \
1388         rfork \
1389         sched_yield \
1390         select \
1391         setproctitle \
1392         setrlimit \
1393         settimeofday \
1394         sigaltstack \
1395         sigprocmask \
1396         snprintf \
1397         spawnvp \
1398         statfs \
1399         statvfs \
1400         strcasecmp \
1401         strdup \
1402         strerror \
1403         strncasecmp \
1404         strtold \
1405         strtoll \
1406         strtoull \
1407         tcgetattr \
1408         thr_kill2 \
1409         timegm \
1410         usleep \
1411         vsnprintf \
1412         wait4 \
1413         waitpid \
1414 )
1415
1416 dnl Check for -ldl
1417 if test "$ac_cv_func_dlopen" = no
1418 then
1419     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1420 fi
1421 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1422
1423 dnl Check for -lpoll for Mac OS X/Darwin
1424 if test "$ac_cv_func_poll" = no
1425 then
1426     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1427 fi
1428
1429 dnl Check for -lnsl for Solaris
1430 AC_SEARCH_LIBS(gethostbyname, nsl)
1431
1432 dnl Check for -lsocket for Solaris
1433 AC_SEARCH_LIBS(connect, socket)
1434
1435 dnl Check for -lresolv for Solaris
1436 AC_SEARCH_LIBS(inet_aton, resolv)
1437
1438 dnl **** Check for functions which may rely on -lsocket on Solaris.
1439 AC_CHECK_FUNCS(\
1440         getaddrinfo \
1441         getnameinfo \
1442         getnetbyname \
1443         getprotobyname \
1444         getprotobynumber \
1445         getservbyport \
1446         inet_network \
1447         sendmsg \
1448 )
1449
1450 dnl **** Check for OpenLDAP ***
1451 AC_SUBST(LDAPLIBS,"")
1452 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
1453 then
1454     AC_CHECK_TYPE(LDAPSortKey,
1455         [AC_CHECK_LIB(ldap_r, ldap_initialize,
1456             [AC_CHECK_LIB(lber, ber_init,
1457                 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
1458                  LDAPLIBS="-lldap_r -llber"],,
1459                  [$LIBPTHREAD])],,
1460                  [$LIBPTHREAD])],,
1461         [#include <ldap.h>])
1462     WINE_CHECK_LIB_FUNCS(\
1463         ldap_count_references \
1464         ldap_first_reference \
1465         ldap_next_reference \
1466         ldap_parse_reference \
1467         ldap_parse_sort_control \
1468         ldap_parse_sortresponse_control \
1469         ldap_parse_vlv_control \
1470         ldap_parse_vlvresponse_control,
1471         [$LDAPLIBS $LIBPTHREAD])
1472 fi
1473 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
1474                  [libldap (OpenLDAP) development files not found, LDAP won't be supported.])
1475
1476 dnl **** Check for types ****
1477
1478 AC_C_CONST
1479 AC_C_INLINE
1480 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1481 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1482 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1483
1484 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1485 [#ifdef HAVE_LINUX_INPUT_H
1486 #include <linux/input.h>
1487 #endif])
1488
1489 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1490                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1491 if test "$wine_cv_have_sigaddset" = "yes"
1492 then
1493   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1494 fi
1495
1496
1497 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1498         wine_cv_linux_gethostbyname_r_6,
1499         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1500     char *name=0;
1501     struct hostent he;
1502     struct hostent *result;
1503     char *buf=0;
1504     int bufsize=0;
1505     int res,errnr;
1506     char *addr=0;
1507     int addrlen=0;
1508     int addrtype=0;
1509     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1510     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1511     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1512         ])
1513    )
1514    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1515    then
1516       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1517                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1518    fi
1519
1520 if test "$ac_cv_header_linux_joystick_h" = "yes"
1521 then
1522    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1523         wine_cv_linux_joystick_22_api,
1524         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1525         #include <sys/ioctl.h>
1526         #include <sys/types.h>
1527         #include <linux/joystick.h>
1528
1529         struct js_event blub;
1530         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1531         #error "no 2.2 header"
1532         #endif
1533         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1534    )
1535    if test "$wine_cv_linux_joystick_22_api" = "yes"
1536    then
1537       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1538                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1539    fi
1540 fi
1541
1542 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1543
1544 dnl Check for statfs members
1545 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1546 [#include <sys/types.h>
1547 #ifdef HAVE_SYS_PARAM_H
1548 # include <sys/param.h>
1549 #endif
1550 #ifdef HAVE_SYS_MOUNT_H
1551 # include <sys/mount.h>
1552 #endif
1553 #ifdef HAVE_SYS_VFS_H
1554 # include <sys/vfs.h>
1555 #endif
1556 #ifdef HAVE_SYS_STATFS_H
1557 # include <sys/statfs.h>
1558 #endif])
1559
1560 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1561 [#ifdef HAVE_SYS_STATVFS_H
1562 #include <sys/statvfs.h>
1563 #endif])
1564
1565 dnl Check for socket structure members
1566 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1567 [#include <sys/types.h>
1568 #ifdef HAVE_SYS_SOCKET_H
1569 # include <sys/socket.h>
1570 #endif
1571 #ifdef HAVE_SYS_UN_H
1572 # include <sys/un.h>
1573 #endif])
1574
1575 dnl Check for scsireq_t and sg_io_hdr_t members
1576 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1577 [#include <sys/types.h>
1578 #ifdef HAVE_SCSI_SG_H
1579 #include <scsi/sg.h>
1580 #endif])
1581
1582 dnl Check for siginfo_t members
1583 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1584
1585 dnl Check for struct mtget members
1586 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1587 [#include <sys/types.h>
1588 #ifdef HAVE_SYS_MTIO_H
1589 #include <sys/mtio.h>
1590 #endif])
1591
1592 dnl Check for struct option
1593 AC_CHECK_MEMBERS([struct option.name],,,
1594 [#ifdef HAVE_GETOPT_H
1595 #include <getopt.h>
1596 #endif])
1597
1598 dnl Check for stat.st_blocks
1599 AC_CHECK_MEMBERS([struct stat.st_blocks])
1600
1601 dnl Check for sin6_scope_id
1602 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1603 [#ifdef HAVE_SYS_TYPES_H
1604 #include <sys/types.h>
1605 #endif
1606 #ifdef HAVE_NETINET_IN_H
1607 #include <netinet/in.h>
1608 #endif])
1609
1610 dnl Check for ns_msg ptr member
1611 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1612 [#ifdef HAVE_SYS_TYPES_H
1613 #include <sys/types.h>
1614 #endif
1615 #ifdef HAVE_NETINET_IN_H
1616 # include <netinet/in.h>
1617 #endif
1618 #ifdef HAVE_ARPA_NAMESER_H
1619 # include <arpa/nameser.h>
1620 #endif])
1621
1622 dnl Check for the external timezone variables timezone and daylight
1623 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1624                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
1625 if test "$ac_cv_have_timezone" = "yes"
1626 then
1627     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1628 fi
1629 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1630                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
1631 if test "$ac_cv_have_daylight" = "yes"
1632 then
1633     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1634 fi
1635
1636 dnl Check for isinf
1637 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
1638                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
1639 if test "$ac_cv_have_isinf" = "yes"
1640 then
1641     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
1642 fi
1643
1644 dnl *** check for the need to define platform-specific symbols
1645
1646 case $host_cpu in
1647   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1648   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1649   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1650   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1651   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1652 esac
1653
1654 case $host_vendor in
1655   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1656 esac
1657
1658 dnl **** Generate output files ****
1659
1660 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1661 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1662 ["### Dependencies:\\
1663 \\
1664 .INIT: Makefile\\
1665 .BEGIN: Makefile\\
1666 Makefile: dummy\\
1667         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1668 \\
1669 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1670 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1671 \$(RC_SRCS:.rc=.res): \$(IDL_TLB_SRCS:.idl=.tlb)\\
1672 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1673 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1674 ["### Dependencies:
1675
1676 .INIT: Makefile
1677 .BEGIN: Makefile
1678 Makefile: dummy
1679         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1680
1681 \$(OBJS): \$(IDL_GEN_HEADERS)
1682 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1683 \$(RC_SRCS:.rc=.res): \$(IDL_TLB_SRCS:.idl=.tlb)
1684 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1685 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1686
1687 AH_TOP([#define __WINE_CONFIG_H])
1688
1689 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1690
1691 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1692 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1693 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1694 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1695 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1696 WINE_CONFIG_EXTRA_DIR(include/wine)
1697
1698 MAKE_RULES=Make.rules
1699 AC_SUBST_FILE(MAKE_RULES)
1700
1701 MAKE_DLL_RULES=dlls/Makedll.rules
1702 AC_SUBST_FILE(MAKE_DLL_RULES)
1703
1704 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1705 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1706
1707 MAKE_TEST_RULES=dlls/Maketest.rules
1708 AC_SUBST_FILE(MAKE_TEST_RULES)
1709
1710 MAKE_PROG_RULES=programs/Makeprog.rules
1711 AC_SUBST_FILE(MAKE_PROG_RULES)
1712
1713 AC_CONFIG_FILES([Make.rules])
1714 AC_CONFIG_FILES([dlls/Makedll.rules])
1715 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1716 AC_CONFIG_FILES([dlls/Maketest.rules])
1717 AC_CONFIG_FILES([programs/Makeprog.rules])
1718 AC_CONFIG_FILES([Makefile])
1719 AC_CONFIG_FILES([dlls/Makefile])
1720 AC_CONFIG_FILES([dlls/acledit/Makefile])
1721 AC_CONFIG_FILES([dlls/activeds/Makefile])
1722 AC_CONFIG_FILES([dlls/actxprxy/Makefile])
1723 AC_CONFIG_FILES([dlls/adsiid/Makefile])
1724 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1725 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1726 AC_CONFIG_FILES([dlls/advpack/Makefile])
1727 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1728 AC_CONFIG_FILES([dlls/amstream/Makefile])
1729 AC_CONFIG_FILES([dlls/appwiz.cpl/Makefile])
1730 AC_CONFIG_FILES([dlls/atl/Makefile])
1731 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1732 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1733 AC_CONFIG_FILES([dlls/browseui/Makefile])
1734 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1735 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1736 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1737 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1738 AC_CONFIG_FILES([dlls/cards/Makefile])
1739 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1740 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1741 AC_CONFIG_FILES([dlls/comcat/Makefile])
1742 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1743 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1744 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1745 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1746 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1747 AC_CONFIG_FILES([dlls/compstui/Makefile])
1748 AC_CONFIG_FILES([dlls/credui/Makefile])
1749 AC_CONFIG_FILES([dlls/credui/tests/Makefile])
1750 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1751 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1752 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1753 AC_CONFIG_FILES([dlls/cryptdlg/Makefile])
1754 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1755 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1756 AC_CONFIG_FILES([dlls/cryptnet/tests/Makefile])
1757 AC_CONFIG_FILES([dlls/cryptui/Makefile])
1758 AC_CONFIG_FILES([dlls/ctapi32/Makefile])
1759 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1760 AC_CONFIG_FILES([dlls/d3d10/Makefile])
1761 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1762 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1763 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1764 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1765 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1766 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1767 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1768 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1769 AC_CONFIG_FILES([dlls/d3dx8/tests/Makefile])
1770 AC_CONFIG_FILES([dlls/d3dx9_24/Makefile])
1771 AC_CONFIG_FILES([dlls/d3dx9_25/Makefile])
1772 AC_CONFIG_FILES([dlls/d3dx9_26/Makefile])
1773 AC_CONFIG_FILES([dlls/d3dx9_27/Makefile])
1774 AC_CONFIG_FILES([dlls/d3dx9_28/Makefile])
1775 AC_CONFIG_FILES([dlls/d3dx9_29/Makefile])
1776 AC_CONFIG_FILES([dlls/d3dx9_30/Makefile])
1777 AC_CONFIG_FILES([dlls/d3dx9_31/Makefile])
1778 AC_CONFIG_FILES([dlls/d3dx9_32/Makefile])
1779 AC_CONFIG_FILES([dlls/d3dx9_33/Makefile])
1780 AC_CONFIG_FILES([dlls/d3dx9_34/Makefile])
1781 AC_CONFIG_FILES([dlls/d3dx9_35/Makefile])
1782 AC_CONFIG_FILES([dlls/d3dx9_36/Makefile])
1783 AC_CONFIG_FILES([dlls/d3dx9_36/tests/Makefile])
1784 AC_CONFIG_FILES([dlls/d3dx9_37/Makefile])
1785 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1786 AC_CONFIG_FILES([dlls/d3dxof/tests/Makefile])
1787 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1788 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1789 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1790 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1791 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1792 AC_CONFIG_FILES([dlls/devenum/Makefile])
1793 AC_CONFIG_FILES([dlls/dinput/Makefile])
1794 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1795 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1796 AC_CONFIG_FILES([dlls/dmband/Makefile])
1797 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1798 AC_CONFIG_FILES([dlls/dmime/Makefile])
1799 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1800 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1801 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1802 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1803 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1804 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1805 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1806 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1807 AC_CONFIG_FILES([dlls/dplay/Makefile])
1808 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1809 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1810 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1811 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1812 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1813 AC_CONFIG_FILES([dlls/dpnlobby/Makefile])
1814 AC_CONFIG_FILES([dlls/dpwsockx/Makefile])
1815 AC_CONFIG_FILES([dlls/dsound/Makefile])
1816 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1817 AC_CONFIG_FILES([dlls/dssenh/Makefile])
1818 AC_CONFIG_FILES([dlls/dswave/Makefile])
1819 AC_CONFIG_FILES([dlls/dwmapi/Makefile])
1820 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1821 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1822 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1823 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1824 AC_CONFIG_FILES([dlls/faultrep/Makefile])
1825 AC_CONFIG_FILES([dlls/fusion/Makefile])
1826 AC_CONFIG_FILES([dlls/fusion/tests/Makefile])
1827 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1828 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1829 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1830 AC_CONFIG_FILES([dlls/gdiplus/tests/Makefile])
1831 AC_CONFIG_FILES([dlls/glu32/Makefile])
1832 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1833 AC_CONFIG_FILES([dlls/gpkcsp/Makefile])
1834 AC_CONFIG_FILES([dlls/hal/Makefile])
1835 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1836 AC_CONFIG_FILES([dlls/hid/Makefile])
1837 AC_CONFIG_FILES([dlls/hlink/Makefile])
1838 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1839 AC_CONFIG_FILES([dlls/hnetcfg/Makefile])
1840 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1841 AC_CONFIG_FILES([dlls/icmp/Makefile])
1842 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1843 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1844 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1845 AC_CONFIG_FILES([dlls/imm32/Makefile])
1846 AC_CONFIG_FILES([dlls/imm32/tests/Makefile])
1847 AC_CONFIG_FILES([dlls/inetcomm/Makefile])
1848 AC_CONFIG_FILES([dlls/inetcomm/tests/Makefile])
1849 AC_CONFIG_FILES([dlls/inetmib1/Makefile])
1850 AC_CONFIG_FILES([dlls/inetmib1/tests/Makefile])
1851 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1852 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1853 AC_CONFIG_FILES([dlls/initpki/Makefile])
1854 AC_CONFIG_FILES([dlls/inkobj/Makefile])
1855 AC_CONFIG_FILES([dlls/inseng/Makefile])
1856 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1857 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1858 AC_CONFIG_FILES([dlls/itircl/Makefile])
1859 AC_CONFIG_FILES([dlls/itss/Makefile])
1860 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1861 AC_CONFIG_FILES([dlls/jscript/Makefile])
1862 AC_CONFIG_FILES([dlls/jscript/tests/Makefile])
1863 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1864 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1865 AC_CONFIG_FILES([dlls/localspl/Makefile])
1866 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1867 AC_CONFIG_FILES([dlls/localui/Makefile])
1868 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1869 AC_CONFIG_FILES([dlls/lz32/Makefile])
1870 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1871 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1872 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1873 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1874 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1875 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1876 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1877 AC_CONFIG_FILES([dlls/midimap/Makefile])
1878 AC_CONFIG_FILES([dlls/mlang/Makefile])
1879 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1880 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1881 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1882 AC_CONFIG_FILES([dlls/mountmgr.sys/Makefile])
1883 AC_CONFIG_FILES([dlls/mpr/Makefile])
1884 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1885 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1886 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1887 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1888 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1889 AC_CONFIG_FILES([dlls/mscat32/Makefile])
1890 AC_CONFIG_FILES([dlls/mscms/Makefile])
1891 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1892 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1893 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1894 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1895 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1896 AC_CONFIG_FILES([dlls/mshtml.tlb/Makefile])
1897 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1898 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1899 AC_CONFIG_FILES([dlls/msi/Makefile])
1900 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1901 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1902 AC_CONFIG_FILES([dlls/msimtf/Makefile])
1903 AC_CONFIG_FILES([dlls/msisip/Makefile])
1904 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1905 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1906 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1907 AC_CONFIG_FILES([dlls/mssip32/Makefile])
1908 AC_CONFIG_FILES([dlls/mstask/Makefile])
1909 AC_CONFIG_FILES([dlls/mstask/tests/Makefile])
1910 AC_CONFIG_FILES([dlls/msvcirt/Makefile])
1911 AC_CONFIG_FILES([dlls/msvcr71/Makefile])
1912 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1913 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1914 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1915 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1916 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1917 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1918 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1919 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1920 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1921 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1922 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1923 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1924 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1925 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1926 AC_CONFIG_FILES([dlls/newdev/Makefile])
1927 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1928 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1929 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1930 AC_CONFIG_FILES([dlls/ntdsapi/tests/Makefile])
1931 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1932 AC_CONFIG_FILES([dlls/ntprint/Makefile])
1933 AC_CONFIG_FILES([dlls/ntprint/tests/Makefile])
1934 AC_CONFIG_FILES([dlls/objsel/Makefile])
1935 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1936 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1937 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1938 AC_CONFIG_FILES([dlls/ole32/Makefile])
1939 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1940 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1941 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1942 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1943 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1944 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1945 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1946 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1947 AC_CONFIG_FILES([dlls/olethk32/Makefile])
1948 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1949 AC_CONFIG_FILES([dlls/opengl32/tests/Makefile])
1950 AC_CONFIG_FILES([dlls/pdh/Makefile])
1951 AC_CONFIG_FILES([dlls/pdh/tests/Makefile])
1952 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1953 AC_CONFIG_FILES([dlls/printui/Makefile])
1954 AC_CONFIG_FILES([dlls/propsys/Makefile])
1955 AC_CONFIG_FILES([dlls/psapi/Makefile])
1956 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1957 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1958 AC_CONFIG_FILES([dlls/qcap/Makefile])
1959 AC_CONFIG_FILES([dlls/qedit/Makefile])
1960 AC_CONFIG_FILES([dlls/qedit/tests/Makefile])
1961 AC_CONFIG_FILES([dlls/qmgr/Makefile])
1962 AC_CONFIG_FILES([dlls/qmgr/tests/Makefile])
1963 AC_CONFIG_FILES([dlls/qmgrprxy/Makefile])
1964 AC_CONFIG_FILES([dlls/quartz/Makefile])
1965 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1966 AC_CONFIG_FILES([dlls/query/Makefile])
1967 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1968 AC_CONFIG_FILES([dlls/rasapi32/tests/Makefile])
1969 AC_CONFIG_FILES([dlls/resutils/Makefile])
1970 AC_CONFIG_FILES([dlls/riched20/Makefile])
1971 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1972 AC_CONFIG_FILES([dlls/riched32/Makefile])
1973 AC_CONFIG_FILES([dlls/riched32/tests/Makefile])
1974 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1975 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1976 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1977 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1978 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1979 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1980 AC_CONFIG_FILES([dlls/sccbase/Makefile])
1981 AC_CONFIG_FILES([dlls/schannel/Makefile])
1982 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1983 AC_CONFIG_FILES([dlls/secur32/Makefile])
1984 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1985 AC_CONFIG_FILES([dlls/security/Makefile])
1986 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1987 AC_CONFIG_FILES([dlls/serialui/Makefile])
1988 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1989 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1990 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1991 AC_CONFIG_FILES([dlls/sfc/Makefile])
1992 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1993 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1994 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1995 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1996 AC_CONFIG_FILES([dlls/shell32/Makefile])
1997 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1998 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1999 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
2000 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
2001 AC_CONFIG_FILES([dlls/slbcsp/Makefile])
2002 AC_CONFIG_FILES([dlls/slc/Makefile])
2003 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
2004 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
2005 AC_CONFIG_FILES([dlls/softpub/Makefile])
2006 AC_CONFIG_FILES([dlls/spoolss/Makefile])
2007 AC_CONFIG_FILES([dlls/spoolss/tests/Makefile])
2008 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
2009 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
2010 AC_CONFIG_FILES([dlls/sti/Makefile])
2011 AC_CONFIG_FILES([dlls/strmiids/Makefile])
2012 AC_CONFIG_FILES([dlls/svrapi/Makefile])
2013 AC_CONFIG_FILES([dlls/sxs/Makefile])
2014 AC_CONFIG_FILES([dlls/tapi32/Makefile])
2015 AC_CONFIG_FILES([dlls/twain_32/Makefile])
2016 AC_CONFIG_FILES([dlls/unicows/Makefile])
2017 AC_CONFIG_FILES([dlls/url/Makefile])
2018 AC_CONFIG_FILES([dlls/urlmon/Makefile])
2019 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
2020 AC_CONFIG_FILES([dlls/user32/Makefile])
2021 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
2022 AC_CONFIG_FILES([dlls/userenv/Makefile])
2023 AC_CONFIG_FILES([dlls/userenv/tests/Makefile])
2024 AC_CONFIG_FILES([dlls/usp10/Makefile])
2025 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
2026 AC_CONFIG_FILES([dlls/uuid/Makefile])
2027 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
2028 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
2029 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
2030 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
2031 AC_CONFIG_FILES([dlls/version/Makefile])
2032 AC_CONFIG_FILES([dlls/version/tests/Makefile])
2033 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
2034 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
2035 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
2036 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
2037 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
2038 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
2039 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
2040 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
2041 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
2042 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
2043 AC_CONFIG_FILES([dlls/wined3d/Makefile])
2044 AC_CONFIG_FILES([dlls/winedos/Makefile])
2045 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
2046 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
2047 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
2048 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
2049 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
2050 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
2051 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
2052 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
2053 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
2054 AC_CONFIG_FILES([dlls/wing32/Makefile])
2055 AC_CONFIG_FILES([dlls/winhttp/Makefile])
2056 AC_CONFIG_FILES([dlls/winhttp/tests/Makefile])
2057 AC_CONFIG_FILES([dlls/wininet/Makefile])
2058 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
2059 AC_CONFIG_FILES([dlls/winmm/Makefile])
2060 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
2061 AC_CONFIG_FILES([dlls/winnls32/Makefile])
2062 AC_CONFIG_FILES([dlls/winscard/Makefile])
2063 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
2064 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
2065 AC_CONFIG_FILES([dlls/wintab32/Makefile])
2066 AC_CONFIG_FILES([dlls/wintrust/Makefile])
2067 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
2068 AC_CONFIG_FILES([dlls/wldap32/Makefile])
2069 AC_CONFIG_FILES([dlls/wmi/Makefile])
2070 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
2071 AC_CONFIG_FILES([dlls/wow32/Makefile])
2072 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
2073 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
2074 AC_CONFIG_FILES([dlls/wsock32/Makefile])
2075 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
2076 AC_CONFIG_FILES([documentation/Makefile])
2077 AC_CONFIG_FILES([fonts/Makefile])
2078 AC_CONFIG_FILES([include/Makefile])
2079 AC_CONFIG_FILES([libs/Makefile])
2080 AC_CONFIG_FILES([libs/port/Makefile])
2081 AC_CONFIG_FILES([libs/wine/Makefile])
2082 AC_CONFIG_FILES([libs/wpp/Makefile])
2083 AC_CONFIG_FILES([loader/Makefile])
2084 AC_CONFIG_FILES([programs/Makefile])
2085 AC_CONFIG_FILES([programs/clock/Makefile])
2086 AC_CONFIG_FILES([programs/cmd/Makefile])
2087 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
2088 AC_CONFIG_FILES([programs/control/Makefile])
2089 AC_CONFIG_FILES([programs/eject/Makefile])
2090 AC_CONFIG_FILES([programs/expand/Makefile])
2091 AC_CONFIG_FILES([programs/explorer/Makefile])
2092 AC_CONFIG_FILES([programs/hh/Makefile])
2093 AC_CONFIG_FILES([programs/icinfo/Makefile])
2094 AC_CONFIG_FILES([programs/iexplore/Makefile])
2095 AC_CONFIG_FILES([programs/msiexec/Makefile])
2096 AC_CONFIG_FILES([programs/net/Makefile])
2097 AC_CONFIG_FILES([programs/notepad/Makefile])
2098 AC_CONFIG_FILES([programs/oleview/Makefile])
2099 AC_CONFIG_FILES([programs/progman/Makefile])
2100 AC_CONFIG_FILES([programs/reg/Makefile])
2101 AC_CONFIG_FILES([programs/regedit/Makefile])
2102 AC_CONFIG_FILES([programs/regsvr32/Makefile])
2103 AC_CONFIG_FILES([programs/rpcss/Makefile])
2104 AC_CONFIG_FILES([programs/rundll32/Makefile])
2105 AC_CONFIG_FILES([programs/secedit/Makefile])
2106 AC_CONFIG_FILES([programs/services/Makefile])
2107 AC_CONFIG_FILES([programs/spoolsv/Makefile])
2108 AC_CONFIG_FILES([programs/start/Makefile])
2109 AC_CONFIG_FILES([programs/svchost/Makefile])
2110 AC_CONFIG_FILES([programs/taskmgr/Makefile])
2111 AC_CONFIG_FILES([programs/uninstaller/Makefile])
2112 AC_CONFIG_FILES([programs/view/Makefile])
2113 AC_CONFIG_FILES([programs/wineboot/Makefile])
2114 AC_CONFIG_FILES([programs/winebrowser/Makefile])
2115 AC_CONFIG_FILES([programs/winecfg/Makefile])
2116 AC_CONFIG_FILES([programs/wineconsole/Makefile])
2117 AC_CONFIG_FILES([programs/winedbg/Makefile])
2118 AC_CONFIG_FILES([programs/winedevice/Makefile])
2119 AC_CONFIG_FILES([programs/winefile/Makefile])
2120 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
2121 AC_CONFIG_FILES([programs/winemine/Makefile])
2122 AC_CONFIG_FILES([programs/winepath/Makefile])
2123 AC_CONFIG_FILES([programs/winetest/Makefile])
2124 AC_CONFIG_FILES([programs/winevdm/Makefile])
2125 AC_CONFIG_FILES([programs/winhlp32/Makefile])
2126 AC_CONFIG_FILES([programs/winver/Makefile])
2127 AC_CONFIG_FILES([programs/wordpad/Makefile])
2128 AC_CONFIG_FILES([programs/write/Makefile])
2129 AC_CONFIG_FILES([programs/xcopy/Makefile])
2130 AC_CONFIG_FILES([server/Makefile])
2131 AC_CONFIG_FILES([tools/Makefile])
2132 AC_CONFIG_FILES([tools/widl/Makefile])
2133 AC_CONFIG_FILES([tools/winebuild/Makefile])
2134 AC_CONFIG_FILES([tools/winedump/Makefile])
2135 AC_CONFIG_FILES([tools/winegcc/Makefile])
2136 AC_CONFIG_FILES([tools/wmc/Makefile])
2137 AC_CONFIG_FILES([tools/wrc/Makefile])
2138
2139 AC_OUTPUT
2140
2141 if test "$no_create" = "yes"
2142 then
2143   exit 0
2144 fi
2145
2146 WINE_PRINT_MESSAGES
2147
2148 echo "
2149 $as_me: Finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine.
2150 " >&AS_MESSAGE_FD
2151
2152 dnl Local Variables:
2153 dnl comment-start: "dnl "
2154 dnl comment-end: ""
2155 dnl comment-start-skip: "\\bdnl\\b\\s *"
2156 dnl compile-command: "autoreconf --warnings=all"
2157 dnl End: