| blob | b461aca0264bacb3b91411cc4fb47c95874c54e5 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
19 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
20 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
25 if test "x$enable_win16" = "xno"
26 then
27 WIN16_FILES=""
28 WIN16_INSTALL=""
29 fi
30 if test "x$enable_debug" = "xno"
31 then
32 AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
33 fi
34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
35 then
36 AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
37 fi
39 dnl **** Check for some programs ****
41 AC_CANONICAL_HOST
42 AC_PROG_MAKE_SET
43 AC_PROG_CC
44 AC_PROG_CXX
45 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
46 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
48 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
49 [if test -z "$with_wine_tools"; then
50 if test "$cross_compiling" = "yes"; then
51 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
52 else
53 wine_cv_toolsdir="\$(TOPOBJDIR)"
54 fi
55 elif test -d "$with_wine_tools/tools/winebuild"; then
56 case $with_wine_tools in
57 /*) wine_cv_toolsdir="$with_wine_tools" ;;
58 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
59 esac
60 else
61 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
62 fi])
63 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
65 AC_PATH_XTRA
66 AC_PROG_LEX
68 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
69 dnl **** without one present.
70 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
71 if test "$XLEX" = "none"
72 then
73 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
74 fi
76 dnl Check for bison
77 AC_CHECK_PROGS(BISON,bison,none)
78 if test "$BISON" = "none"
79 then
80 AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
81 fi
83 AC_CHECK_TOOLS(AS,[gas as],as)
84 AC_CHECK_TOOL(LD,ld,ld)
85 AC_CHECK_TOOL(AR,ar,ar)
86 AC_PROG_RANLIB
87 AC_CHECK_TOOL(STRIP,strip,strip)
88 AC_CHECK_TOOL(WINDRES,windres,false)
89 AC_PROG_LN_S
90 WINE_PROG_LN
91 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
92 AC_PROG_INSTALL
93 dnl Prepend src dir to install path dir if it's a relative path
94 case "$INSTALL" in
95 [[\\/$]]* | ?:[[\\/]]* ) ;;
96 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
97 esac
99 dnl Check for lint
100 AC_CHECK_PROGS(LINT, lclint lint)
101 if test "$LINT" = "lint"
102 then
103 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
104 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
105 fi
106 AC_SUBST(LINT)
107 AC_SUBST(LINTFLAGS)
109 dnl Check for db2html
110 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
111 AC_SUBST(DB2HTML)
113 dnl Check for db2pdf
114 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
115 AC_SUBST(DB2PDF)
117 dnl Check for db2ps
118 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
119 AC_SUBST(DB2PS)
121 dnl Check for db2txt
122 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
123 AC_SUBST(DB2TXT)
125 dnl **** Check for some libraries ****
127 dnl Check for -li386 for NetBSD and OpenBSD
128 AC_CHECK_LIB(i386,i386_set_ldt)
129 dnl Check for -lossaudio for NetBSD
130 AC_CHECK_LIB(ossaudio,_oss_ioctl)
131 dnl Check for -lw for Solaris
132 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
133 dnl Check for -lnsl for Solaris
134 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
135 dnl Check for -lsocket for Solaris
136 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
137 dnl Check for -lresolv for Solaris
138 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
139 dnl Check for -lxpg4 for FreeBSD
140 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
141 dnl Check for -lpoll for Mac OS X/Darwin
142 AC_CHECK_LIB(poll,poll)
143 dnl Check for -lpthread
144 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
146 JPEGLIB=""
147 AC_SUBST(JPEGLIB)
148 AC_CHECK_HEADERS(jpeglib.h,
149 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
150 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
151 JPEGLIB="-ljpeg"
152 )
153 )
155 AC_SUBST(GIFLIB,"")
156 AC_CHECK_HEADERS(gif_lib.h,
157 AC_CHECK_LIB(ungif,DGifOpen,
158 [AC_DEFINE(HAVE_LIBGIF,1,[Define if you have libgif/libungif including devel headers])
159 GIFLIB="-lungif"],
160 [AC_CHECK_LIB(gif,DGifOpen,
161 [AC_DEFINE(HAVE_LIBGIF,1)
162 GIFLIB="-lgif"])]))
164 AC_SUBST(XLIB)
165 AC_SUBST(XFILES)
166 XFILES=""
167 AC_SUBST(OPENGLFILES)
168 OPENGLFILES=""
169 AC_SUBST(GLU32FILES)
170 GLU32FILES=""
171 AC_SUBST(OPENGL_LIBS)
172 OPENGL_LIBS=""
173 if test "$have_x" = "yes"
174 then
175 XLIB="-lXext -lX11"
176 ac_save_CPPFLAGS="$CPPFLAGS"
177 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
179 dnl *** All of the following tests require X11/Xlib.h
180 AC_CHECK_HEADERS(X11/Xlib.h,
181 [
182 AC_CHECK_HEADERS([X11/XKBlib.h \
183 X11/Xutil.h \
184 X11/extensions/shape.h \
185 X11/extensions/XInput.h \
186 X11/extensions/XShm.h \
187 X11/extensions/Xrandr.h \
188 X11/extensions/Xrender.h \
189 X11/extensions/Xvlib.h \
190 X11/extensions/xf86dga.h \
191 X11/extensions/xf86vmode.h],,,
192 [#include <X11/Xlib.h>
193 #ifdef HAVE_X11_XUTIL_H
194 # include <X11/Xutil.h>
195 #endif])
197 dnl *** Check for X keyboard extension
198 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
199 then
200 AC_CHECK_LIB(X11, XkbQueryExtension,
201 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
202 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
203 fi
205 dnl *** Check for X Shm extension
206 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
207 then
208 AC_CHECK_LIB(Xext, XShmQueryExtension,
209 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
210 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
211 fi
213 dnl *** Check for X shape extension
214 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
215 then
216 AC_CHECK_LIB(Xext,XShapeQueryExtension,
217 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
218 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
219 fi
221 dnl *** Check for XFree86 DGA / DGA 2.0 extension
222 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
223 then
224 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
225 [ dnl *** If found...
226 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
227 [Define if you have the Xxf86dga library version 2])
228 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
229 ],
230 [ dnl *** If not found, look for XF86DGAQueryExtension()
231 dnl *** instead (DGA 2.0 not found)...
232 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
233 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
234 [Define if you have the Xxf86dga library version 1])
235 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
236 ],,
237 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
238 )
239 ],
240 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
241 fi
243 dnl *** Check for XFree86 VMODE extension
244 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
245 then
246 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
247 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
248 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
249 ],,
250 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
251 fi
253 dnl *** Check for X RandR extension
254 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
255 then
256 AC_CHECK_LIB(Xrandr, XRRSetScreenConfigAndRate,
257 [ AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])
258 X_PRE_LIBS="$X_PRE_LIBS -lXrandr -lXrender"
259 ],,
260 $X_LIBS -lXrender -lXext -lX11 $X_EXTRA_LIBS)
261 fi
263 dnl *** Check for XVideo extension supporting XvImages
264 if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
265 then
266 AC_CHECK_LIB(Xv, XvShmCreateImage,
267 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
268 X_PRE_LIBS="$X_PRE_LIBS -lXv"
269 ],,
270 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
271 fi
272 ]
273 ) dnl *** End of X11/Xlib.h check
275 dnl Check for the presence of OpenGL
276 if test "x$with_opengl" != "xno"
277 then
278 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
279 then
280 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
281 This prevents linking to OpenGL. Delete the file and restart configure.])
282 fi
284 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
285 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
286 then
287 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
288 dnl Check for some problems due to old Mesa versions
289 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
290 AC_TRY_COMPILE(
291 [#include <GL/gl.h>],
292 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
293 [wine_cv_opengl_version_OK="yes"],
294 [wine_cv_opengl_version_OK="no"]
295 )
296 )
298 if test "$wine_cv_opengl_version_OK" = "yes"
299 then
300 dnl Check for the presence of the library
301 AC_CHECK_LIB(GL,glXCreateContext,
302 OPENGL_LIBS="-lGL"
303 ,,
304 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
306 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
307 then
308 OPENGLFILES='$(OPENGLFILES)'
309 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
311 AC_CHECK_LIB(GL,glXGetProcAddressARB,
312 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
313 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
314 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
316 if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
317 then
318 AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
319 [AC_TRY_COMPILE([#include <GL/gl.h>
320 #ifdef HAVE_GL_GLEXT_H
321 # include <GL/glext.h>
322 #endif
323 ],
324 [PFNGLCOLORTABLEEXTPROC test_proc;],
325 [wine_cv_extension_prototypes="yes"],
326 [wine_cv_extension_prototypes="no"]
327 )]
328 )
329 if test "$wine_cv_extension_prototypes" = "yes"
330 then
331 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
332 [Define if the OpenGL headers define extension typedefs])
333 fi
334 fi
336 fi
337 dnl Check for GLU32 library.
338 AC_CHECK_LIB(GLU,gluLookAt,
339 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
340 GLU32FILES='$(GLU32FILES)']
341 ,,
342 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
343 )
344 fi
346 dnl Check for glut32 library.
347 AC_CHECK_LIB(glut,glutMainLoop,
348 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
349 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
350 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
351 fi
352 fi
354 dnl **** Check for NAS ****
355 AC_SUBST(NASLIBS,"")
356 AC_CHECK_HEADERS(audio/audiolib.h,
357 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
358 AC_CHECK_LIB(audio,AuCreateFlow,
359 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
360 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
361 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
363 CPPFLAGS="$ac_save_CPPFLAGS"
364 XFILES='$(XFILES)'
365 else
366 XLIB=""
367 X_CFLAGS=""
368 X_LIBS=""
369 fi
371 dnl **** Check which curses lib to use ***
372 CURSESLIBS=""
373 if test "x$with_curses" != "xno"
374 then
375 AC_CHECK_HEADERS(ncurses.h,
376 [AC_CHECK_LIB(ncurses,waddch,
377 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
378 CURSESLIBS="-lncurses"],
379 [AC_CHECK_HEADERS(curses.h,
380 [AC_CHECK_LIB(curses,waddch,
381 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
382 CURSESLIBS="-lcurses"])])])])
383 saved_libs="$LIBS"
384 LIBS="$CURSESLIBS $LIBS"
385 AC_CHECK_FUNCS(getbkgd resizeterm)
386 LIBS="$saved_libs"
387 fi
388 AC_SUBST(CURSESLIBS)
390 dnl **** Check for SANE ****
391 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
392 if test "$sane_devel" = "no"
393 then
394 SANELIBS=""
395 SANEINCL=""
396 else
397 SANELIBS="`$sane_devel --libs`"
398 SANEINCL="`$sane_devel --cflags`"
399 ac_save_CPPFLAGS="$CPPFLAGS"
400 ac_save_LIBS="$LIBS"
401 CPPFLAGS="$CPPFLAGS $SANEINCL"
402 LIBS="$LIBS $SANELIBS"
403 AC_CHECK_HEADER(sane/sane.h,
404 [AC_CHECK_LIB(sane,sane_open,
405 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
406 [SANELIBS=""
407 SANEINCL=""])],
408 [SANELIBS=""
409 SANEINCL=""])
410 LIBS="$ac_save_LIBS"
411 CPPFLAGS="$ac_save_CPPFLAGS"
412 fi
413 AC_SUBST(SANELIBS)
414 AC_SUBST(SANEINCL)
416 dnl **** Check for the ICU library ****
417 AC_CHECK_HEADERS(unicode/ubidi.h)
418 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
419 then
420 saved_libs="$LIBS"
421 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
422 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
423 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
424 AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
425 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
426 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
427 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
428 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
429 AC_MSG_RESULT(yes)],
430 [AC_MSG_RESULT(no)])
431 LIBS="$saved_libs"
432 fi
434 dnl **** Check for FreeType 2 ****
435 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
436 if test "$ft_lib" = "no"
437 then
438 FREETYPEINCL=""
439 wine_cv_msg_freetype=no
440 else
441 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
442 if test "$ft_devel" = "no"
443 then
444 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
445 if test "$ft_devel2" = "freetype2-config"
446 then
447 ft_devel=$ft_devel2
448 fi
449 fi
450 if test "$ft_devel" = "no"
451 then
452 FREETYPEINCL=""
453 wine_cv_msg_freetype=yes
454 else
455 FREETYPEINCL=`$ft_devel --cflags`
456 ac_save_CPPFLAGS="$CPPFLAGS"
457 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
458 AC_CHECK_HEADERS(ft2build.h \
459 freetype/freetype.h \
460 freetype/ftglyph.h \
461 freetype/tttables.h \
462 freetype/ftnames.h \
463 freetype/ftsnames.h \
464 freetype/ttnameid.h \
465 freetype/ftoutln.h \
466 freetype/internal/sfnt.h,,,
467 [#if HAVE_FT2BUILD_H
468 #include <ft2build.h>
469 #endif])
470 AC_TRY_CPP([#include <ft2build.h>
471 #include <freetype/fttrigon.h>],
472 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
473 [Define if you have the <freetype/fttrigon.h> header file.])
474 wine_cv_fttrigon=yes],
475 wine_cv_fttrigon=no)
476 CPPFLAGS="$ac_save_CPPFLAGS"
477 dnl Check that we have at least freetype/freetype.h
478 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
479 then
480 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
481 wine_cv_msg_freetype=no
482 else
483 FREETYPEINCL=""
484 wine_cv_msg_freetype=yes
485 fi
486 fi
487 fi
488 AC_SUBST(FREETYPEINCL)
490 dnl **** Check for parport (currently Linux only) ****
491 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
492 AC_TRY_COMPILE(
493 [#include <linux/ppdev.h>],
494 [ioctl (1,PPCLAIM,0)],
495 [ac_cv_c_ppdev="yes"],
496 [ac_cv_c_ppdev="no"])
497 )
498 if test "$ac_cv_c_ppdev" = "yes"
499 then
500 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
501 fi
503 dnl **** Check for va_copy ****
504 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
505 AC_TRY_LINK(
506 [#include <stdarg.h>],
507 [va_list ap1, ap2;
508 va_copy(ap1,ap2);
509 ],
510 [ac_cv_c_va_copy="yes"],
511 [ac_cv_c_va_copy="no"])
512 )
513 if test "$ac_cv_c_va_copy" = "yes"
514 then
515 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
516 fi
517 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
518 AC_TRY_LINK(
519 [#include <stdarg.h>],
520 [va_list ap1, ap2;
521 __va_copy(ap1,ap2);
522 ],
523 [ac_cv_c___va_copy="yes"],
524 [ac_cv_c___va_copy="no"])
525 )
526 if test "$ac_cv_c___va_copy" = "yes"
527 then
528 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
529 fi
531 dnl **** Check for sigsetjmp ****
532 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
533 AC_TRY_LINK(
534 [#include <setjmp.h>],
535 [sigjmp_buf buf;
536 sigsetjmp( buf, 1 );
537 siglongjmp( buf, 1 );],
538 [ac_cv_c_sigsetjmp="yes"],
539 [ac_cv_c_sigsetjmp="no"])
540 )
541 if test "$ac_cv_c_sigsetjmp" = "yes"
542 then
543 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
544 fi
546 dnl **** Check for pthread_rwlock_t ****
547 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
548 #include <pthread.h>])
550 dnl **** Check for pthread_getattr_np ****
551 ac_save_LIBS="$LIBS"
552 LIBS="$LIBS $LIBPTHREAD"
553 AC_CHECK_FUNCS(pthread_getattr_np)
554 LIBS="$ac_save_LIBS"
556 dnl **** Check for Open Sound System ****
557 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
559 AC_CACHE_CHECK([for Open Sound System],
560 ac_cv_c_opensoundsystem,
561 AC_TRY_COMPILE([
562 #if defined(HAVE_SYS_SOUNDCARD_H)
563 #include <sys/soundcard.h>
564 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
565 #include <machine/soundcard.h>
566 #elif defined(HAVE_SOUNDCARD_H)
567 #include <soundcard.h>
568 #endif
569 ],[
571 /* check for one of the Open Sound System specific SNDCTL_ defines */
572 #if !defined(SNDCTL_DSP_STEREO)
573 #error No open sound system
574 #endif
575 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
577 if test "$ac_cv_c_opensoundsystem" = "yes"
578 then
579 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
580 fi
582 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
583 ac_cv_c_opensoundsystem_midi,
584 AC_TRY_COMPILE([
585 #if defined(HAVE_SYS_SOUNDCARD_H)
586 #include <sys/soundcard.h>
587 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
588 #include <machine/soundcard.h>
589 #elif defined(HAVE_SOUNDCARD_H)
590 #include <soundcard.h>
591 #endif
592 ],[
594 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
595 #if !defined(SNDCTL_SEQ_SYNC)
596 #error No open sound system MIDI interface
597 #endif
598 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
600 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
601 then
602 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
603 fi
605 dnl **** Check for aRts Sound Server ****
606 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
607 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
608 then
609 ARTSC_CFLAGS=""
610 for i in `$ARTSCCONFIG --cflags`
611 do
612 case "$i" in
613 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
614 esac
615 done
616 ARTSC_LIBS=`$ARTSCCONFIG --libs`
617 save_CFLAGS="$CFLAGS"
618 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
619 AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
620 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
621 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
622 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
623 CFLAGS="$save_CFLAGS"
624 fi
626 dnl **** Check for ALSA ****
627 AC_SUBST(ALSALIBS,"")
628 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
629 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
630 then
631 AC_CHECK_LIB(asound,snd_pcm_open,
632 AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
633 ALSALIBS="-lasound")
634 fi
636 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
638 AC_SUBST(AUDIOIOLIBS,"")
639 AC_CHECK_HEADERS(libaudioio.h,
640 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
641 [AUDIOIOLIBS="-laudioio"
642 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
644 dnl **** Check for capi4linux ****
646 AC_CHECK_HEADERS(capi20.h,[
647 AC_CHECK_HEADERS(linux/capi.h,[
648 AC_CHECK_LIB(capi20,capi20_register,[
649 AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
650 AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
651 ])
652 ])
653 ])
655 dnl **** Check for broken glibc mmap64 ****
657 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
658 AC_TRY_RUN([
659 #define _FILE_OFFSET_BITS 64
660 #include <stdio.h>
661 #include <unistd.h>
662 #include <fcntl.h>
663 #include <sys/mman.h>
664 #include <errno.h>
666 int main(int argc,char **argv) {
667 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
668 if (fd == -1) exit(1);
670 unlink("conftest.map");
672 write(fd,"test",4);
674 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
675 (errno == EINVAL)
676 ) {
677 exit(1);
678 }
679 close(fd);
680 fprintf(stderr,"success!\n");
681 exit(0);
682 }
684 ],
685 ac_cv_mmap64_works="yes",
686 ac_cv_mmap64_works="no",
687 ac_cv_mmap64_works="no") )
689 if test "$ac_cv_mmap64_works" = "yes"
690 then
691 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
692 fi
694 dnl **** Check for gcc specific options ****
696 AC_SUBST(EXTRACFLAGS,"")
697 if test "x${GCC}" = "xyes"
698 then
699 EXTRACFLAGS="-Wall -pipe"
701 dnl Check for strength-reduce bug
702 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
703 AC_TRY_RUN([
704 int L[[4]] = {0,1,2,3};
705 int main(void) {
706 static int Array[[3]];
707 unsigned int B = 3;
708 int i;
709 for(i=0; i<B; i++) Array[[i]] = i - 3;
710 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
711 L[[i]] = 4;
713 exit( Array[[1]] != -2 || L[[2]] != 3);
714 }],
715 ac_cv_c_gcc_strength_bug="no",
716 ac_cv_c_gcc_strength_bug="yes",
717 ac_cv_c_gcc_strength_bug="yes") )
718 if test "$ac_cv_c_gcc_strength_bug" = "yes"
719 then
720 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
721 fi
723 dnl Check for -fshort-wchar
724 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
725 [WINE_TRY_CFLAGS([-fshort-wchar],
726 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
727 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
728 then
729 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
730 fi
732 dnl Check for -mpreferred-stack-boundary
733 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
734 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
735 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
736 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
737 then
738 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
739 fi
741 dnl Check for -fno-strict-aliasing
742 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
743 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
744 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
745 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
746 then
747 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
748 fi
750 dnl Check for -gstabs+ option
751 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
752 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
753 if test "$ac_cv_c_gcc_gstabs" = "yes"
754 then
755 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
756 fi
758 dnl Check for noisy string.h
759 saved_CFLAGS="$CFLAGS"
760 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
761 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
762 AC_TRY_COMPILE([#include <string.h>],[],
763 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
764 CFLAGS="$saved_CFLAGS"
765 if test "$ac_cv_c_string_h_warnings" = "no"
766 then
767 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
768 fi
769 fi
771 dnl **** Check how to define a function in assembly code ****
773 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
774 WINE_TRY_ASM_LINK(
775 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
776 ac_cv_asm_func_def=".def",
777 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
778 ac_cv_asm_func_def=".type @function",
779 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
780 ac_cv_asm_func_def=".type 2",
781 ac_cv_asm_func_def="unknown")])]))
783 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
784 case "$ac_cv_asm_func_def" in
785 ".def")
786 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
787 ".type @function")
788 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
789 ".type 2")
790 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
791 *)
792 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
793 esac
795 dnl **** Check for underscore on external symbols ****
797 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
798 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
799 [extern int ac_test;],
800 [if (ac_test) return 1],
801 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
803 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
804 if test "$ac_cv_c_extern_prefix" = "yes"
805 then
806 AC_DEFINE([__ASM_NAME(name)], ["_" name])
807 else
808 AC_DEFINE([__ASM_NAME(name)], [name])
809 fi
811 dnl **** Check how to do strings in assembler ****
813 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
814 WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
815 WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
816 WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
817 AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
819 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
820 [Define to the assembler keyword used to specify an ASCII string])
822 dnl **** Check for .short in assembler ****
824 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
825 WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
826 WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
827 AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
829 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
830 [Define to the assembler keyword used to specify a word value])
832 dnl **** Check for working dll ****
834 AC_SUBST(DLLEXT,"")
835 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
836 AC_SUBST(DLLIBS,"")
837 AC_SUBST(LDSHARED,"")
838 AC_SUBST(LDDLLFLAGS,"")
839 AC_SUBST(LIBEXT,"so")
840 AC_SUBST(IMPLIBEXT,"def")
842 case $host_os in
843 cygwin*|mingw32*)
844 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
845 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
846 if test "$DLLWRAP" = "false"; then
847 LIBEXT="a"
848 else
849 dnl FIXME - check whether dllwrap works correctly...
850 LIBEXT="dll"
851 fi
852 IMPLIBEXT="a"
853 ;;
854 *)
855 AC_CHECK_HEADERS(dlfcn.h,
856 [AC_CHECK_FUNCS(dlopen,,
857 [AC_CHECK_LIB(dl,dlopen,
858 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
859 DLLIBS="-ldl"],
860 [LIBEXT="a"])])],
861 [LIBEXT="a"])
863 if test "$LIBEXT" = "so"
864 then
865 DLLFLAGS="$DLLFLAGS -fPIC"
866 DLLEXT=".so"
867 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
868 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
869 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
870 if test "$ac_cv_c_dll_gnuelf" = "yes"
871 then
872 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
873 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
874 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
875 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
876 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
877 if test "$ac_cv_c_dll_zdefs" = "yes"
878 then
879 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
880 fi
882 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
883 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
884 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
885 if test "$ac_cv_c_dll_init_fini" = "yes"
886 then
887 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
888 fi
890 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
891 [echo '{ global: *; };' >conftest.map
892 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
893 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
894 rm -f conftest.map])
895 if test "$ac_cv_c_ld_version_scripts" = "yes"
896 then
897 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
898 fi
900 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
901 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
902 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
903 if test "$ac_cv_c_export_dynamic" = "yes"
904 then
905 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
906 fi
908 case $host_cpu in
909 *i[[3456789]]86*)
910 AC_CACHE_CHECK([whether we can relocate the executable to 0x00110000], ac_cv_ld_reloc_exec,
911 [saved_CFLAGS="$CFLAGS"
912 CFLAGS="$CFLAGS -Wl,--section-start,.interp=0x00110400"
913 AC_TRY_RUN([#include <unistd.h>
914 int main() { return (sbrk(32*1024*1024) == (void *)-1); }],
915 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no", ac_cv_ld_reloc_exec="no")
916 CFLAGS="$saved_CFLAGS"])
917 if test "$ac_cv_ld_reloc_exec" = "yes"
918 then
919 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x00110400"
920 fi
921 ;;
922 esac
924 else
925 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
926 [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
927 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
928 if test "$ac_cv_c_dll_unixware" = "yes"
929 then
930 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
931 LDDLLFLAGS="-Wl,-G,-B,symbolic"
933 else
934 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
935 [WINE_TRY_CFLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
936 if test "$ac_cv_c_dll_macho" = "yes"
937 then
938 LIBEXT="dylib"
939 LDDLLFLAGS="-bundle -flat_namespace -undefined suppress"
940 LDSHARED="\$(CC) -dynamiclib"
941 CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
942 fi
943 fi
944 fi
945 fi
947 dnl Check for cross compiler to build test programs
948 AC_SUBST(CROSSTEST,"")
949 if test "$cross_compiling" = "no"
950 then
951 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
952 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
953 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
954 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
955 fi
956 ;;
957 esac
959 if test "$LIBEXT" = "a"; then
960 AC_MSG_ERROR(
961 [could not find a way to build shared libraries.
962 It is currently not possible to build Wine without shared library
963 (.so) support to allow transparent switch between .so and .dll files.
964 If you are using Linux, you will need a newer binutils.]
965 )
966 fi
968 case $build_os in
969 cygwin*|mingw32*)
970 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
971 darwin*|macosx*)
972 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
973 *)
974 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
975 esac
977 dnl Mingw needs explicit msvcrt for linking libwine
978 case $host_os in
979 mingw32*)
980 AC_SUBST(CRTLIBS,"-lmsvcrt") ;;
981 esac
983 case $host_os in
984 linux*)
985 AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread")
986 AC_SUBST(MAIN_BINARY,"wine-glibc")
987 ;;
988 *)
989 AC_SUBST(WINE_BINARIES,"wine-kthread")
990 AC_SUBST(MAIN_BINARY,"wine-kthread")
991 ;;
992 esac
994 dnl **** Get the soname for libraries that we load dynamically ****
996 if test "$LIBEXT" = "so"
997 then
998 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
999 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1000 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1001 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1002 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1003 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1004 WINE_GET_SONAME(cups,cupsGetDefault)
1005 WINE_GET_SONAME(jack,jack_client_new)
1006 WINE_GET_SONAME(fontconfig,FcInit)
1007 WINE_GET_SONAME(ssl,SSL_library_init)
1008 WINE_GET_SONAME(crypto,BIO_new_socket)
1009 WINE_GET_SONAME(ncurses,waddch)
1010 WINE_GET_SONAME(curses,waddch)
1011 fi
1014 dnl **** Check for functions ****
1016 AC_FUNC_ALLOCA()
1017 AC_CHECK_FUNCS(\
1018 _lwp_create \
1019 _lwp_self \
1020 _pclose \
1021 _popen \
1022 _snprintf \
1023 _spawnvp \
1024 _stricmp \
1025 _strnicmp \
1026 _vsnprintf \
1027 chsize \
1028 clone \
1029 finite \
1030 fpclass \
1031 fstatfs \
1032 fstatvfs \
1033 ftruncate \
1034 ftruncate64 \
1035 futimes \
1036 getnetbyaddr \
1037 getnetbyname \
1038 getopt_long \
1039 getpagesize \
1040 getprotobyname \
1041 getprotobynumber \
1042 getpwuid \
1043 getservbyport \
1044 gettid \
1045 gettimeofday \
1046 inet_network \
1047 lseek64 \
1048 lstat \
1049 memmove \
1050 mmap \
1051 pclose \
1052 popen \
1053 pread \
1054 pwrite \
1055 readlink \
1056 rfork \
1057 select \
1058 sendmsg \
1059 settimeofday \
1060 sigaltstack \
1061 snprintf \
1062 spawnvp \
1063 statfs \
1064 statvfs \
1065 strcasecmp \
1066 strerror \
1067 strncasecmp \
1068 tcgetattr \
1069 timegm \
1070 usleep \
1071 vfscanf \
1072 vsnprintf \
1073 wait4 \
1074 waitpid \
1075 )
1077 dnl **** Check for header files ****
1079 AC_CHECK_HEADERS(\
1080 arpa/inet.h \
1081 arpa/nameser.h \
1082 cups/cups.h \
1083 direct.h \
1084 elf.h \
1085 float.h \
1086 fontconfig/fontconfig.h \
1087 getopt.h \
1088 ieeefp.h \
1089 io.h \
1090 jack/jack.h \
1091 libio.h \
1092 libutil.h \
1093 link.h \
1094 linux/cdrom.h \
1095 linux/hdreg.h \
1096 linux/input.h \
1097 linux/ioctl.h \
1098 linux/joystick.h \
1099 linux/major.h \
1100 linux/param.h \
1101 linux/serial.h \
1102 linux/ucdrom.h \
1103 machine/cpu.h \
1104 netdb.h \
1105 netinet/in.h \
1106 netinet/in_systm.h \
1107 netinet/tcp.h \
1108 netinet/tcp_fsm.h \
1109 openssl/ssl.h \
1110 process.h \
1111 pthread.h \
1112 pty.h \
1113 pwd.h \
1114 regex.h \
1115 sched.h \
1116 scsi/sg.h \
1117 scsi/scsi.h \
1118 scsi/scsi_ioctl.h \
1119 socket.h \
1120 stdint.h \
1121 strings.h \
1122 sys/cdio.h \
1123 sys/elf32.h \
1124 sys/errno.h \
1125 sys/exec_elf.h \
1126 sys/file.h \
1127 sys/filio.h \
1128 sys/inttypes.h \
1129 sys/ioctl.h \
1130 sys/ipc.h \
1131 sys/link.h \
1132 sys/lwp.h \
1133 sys/mman.h \
1134 sys/modem.h \
1135 sys/msg.h \
1136 sys/param.h \
1137 sys/poll.h \
1138 sys/ptrace.h \
1139 sys/reg.h \
1140 sys/scsiio.h \
1141 sys/shm.h \
1142 sys/signal.h \
1143 sys/socket.h \
1144 sys/sockio.h \
1145 sys/statfs.h \
1146 sys/statvfs.h \
1147 sys/strtio.h \
1148 sys/syscall.h \
1149 sys/sysctl.h \
1150 sys/time.h \
1151 sys/times.h \
1152 sys/uio.h \
1153 sys/un.h \
1154 sys/v86.h \
1155 sys/v86intr.h \
1156 sys/vfs.h \
1157 sys/vm86.h \
1158 sys/wait.h \
1159 syscall.h \
1160 termios.h \
1161 unistd.h \
1162 utime.h \
1163 valgrind/memcheck.h
1164 )
1165 AC_HEADER_STAT()
1167 dnl **** Checks for headers that depend on other ones ****
1169 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1170 [#include <sys/types.h>
1171 #if HAVE_SYS_PARAM_H
1172 # include <sys/param.h>
1173 #endif])
1175 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1176 [#include <sys/types.h>
1177 #if HAVE_SYS_SOCKET_H
1178 # include <sys/socket.h>
1179 #endif])
1181 AC_CHECK_HEADERS([resolv.h],,,
1182 [#include <sys/types.h>
1183 #if HAVE_SYS_SOCKET_H
1184 # include <sys/socket.h>
1185 #endif
1186 #if HAVE_NETINET_IN_H
1187 # include <netinet/in.h>
1188 #endif
1189 #if HAVE_ARPA_NAMESER_H
1190 # include <arpa/nameser.h>
1191 #endif])
1193 AC_CHECK_HEADERS(netinet/ip.h,,,
1194 [#include <sys/types.h>
1195 #if HAVE_SYS_SOCKET_H
1196 # include <sys/socket.h>
1197 #endif
1198 #if HAVE_NETINET_IN_SYSTM_H
1199 # include <netinet/in_systm.h>
1200 #endif])
1202 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1204 dnl **** Check for IPX headers (currently Linux only) ****
1206 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1207 AC_TRY_COMPILE(
1208 [#include <sys/types.h>
1209 #ifdef HAVE_SYS_SOCKET_H
1210 # include <sys/socket.h>
1211 #endif
1212 #include <netipx/ipx.h>],
1213 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1214 [ac_cv_c_ipx_gnu="yes"],
1215 [ac_cv_c_ipx_gnu="no"])
1216 )
1217 if test "$ac_cv_c_ipx_gnu" = "yes"
1218 then
1219 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1220 fi
1222 if test "$ac_cv_c_ipx_gnu" = "no"
1223 then
1224 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1225 AC_TRY_COMPILE(
1226 [#include <sys/types.h>
1227 #ifdef HAVE_SYS_SOCKET_H
1228 # include <sys/socket.h>
1229 #endif
1230 #include <asm/types.h>
1231 #include <linux/ipx.h>],
1232 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1233 [ac_cv_c_ipx_linux="yes"],
1234 [ac_cv_c_ipx_linux="no"])
1235 )
1236 if test "$ac_cv_c_ipx_linux" = "yes"
1237 then
1238 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1239 fi
1240 fi
1242 dnl **** Check for types ****
1244 AC_C_CONST
1245 AC_C_INLINE
1246 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1248 AC_CACHE_CHECK([whether linux/input.h is for real],
1249 wine_cv_linux_input_h,
1250 AC_TRY_COMPILE([
1251 #include <linux/input.h>
1252 ] , [
1253 int foo = EVIOCGBIT(EV_ABS,42);
1254 int bar = BTN_PINKIE;
1255 int fortytwo = 42;
1256 ],
1257 wine_cv_linux_input_h=yes,
1258 wine_cv_linux_input_h=no,
1259 no
1260 )
1261 )
1262 if test "$wine_cv_linux_input_h" = "yes"
1263 then
1264 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1265 [Define if we have linux/input.h AND it contains the INPUT event API])
1266 fi
1269 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1270 wine_cv_linux_gethostbyname_r_6,
1271 AC_TRY_LINK([
1272 #include <netdb.h>
1273 ], [
1274 char *name=NULL;
1275 struct hostent he;
1276 struct hostent *result;
1277 char *buf=NULL;
1278 int bufsize=0;
1279 int res,errnr;
1280 char *addr=NULL;
1281 int addrlen=0;
1282 int addrtype=0;
1283 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1284 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1285 ],
1286 wine_cv_linux_gethostbyname_r_6=yes,
1287 wine_cv_linux_gethostbyname_r_6=no
1288 )
1289 )
1290 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1291 then
1292 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1293 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1294 fi
1296 if test "$ac_cv_header_linux_joystick_h" = "yes"
1297 then
1298 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1299 wine_cv_linux_joystick_22_api,
1300 AC_TRY_COMPILE([
1301 #include <sys/ioctl.h>
1302 #include <linux/joystick.h>
1304 struct js_event blub;
1305 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1306 #error "no 2.2 header"
1307 #endif
1308 ],/*empty*/,
1309 wine_cv_linux_joystick_22_api=yes,
1310 wine_cv_linux_joystick_22_api=no,
1311 wine_cv_linux_joystick_22_api=no
1312 )
1313 )
1314 if test "$wine_cv_linux_joystick_22_api" = "yes"
1315 then
1316 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1317 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1318 fi
1319 fi
1321 dnl **** statfs checks ****
1323 if test "$ac_cv_header_sys_vfs_h" = "yes"
1324 then
1325 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1326 wine_cv_sys_vfs_has_statfs,
1327 AC_TRY_COMPILE([
1328 #include <sys/types.h>
1329 #ifdef HAVE_SYS_PARAM_H
1330 # include <sys/param.h>
1331 #endif
1332 #include <sys/vfs.h>
1333 ],[
1334 struct statfs stfs;
1336 memset(&stfs,0,sizeof(stfs));
1337 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1338 )
1339 )
1340 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1341 then
1342 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1343 [Define if the struct statfs is defined by <sys/vfs.h>])
1344 fi
1345 fi
1347 if test "$ac_cv_header_sys_statfs_h" = "yes"
1348 then
1349 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1350 wine_cv_sys_statfs_has_statfs,
1351 AC_TRY_COMPILE([
1352 #include <sys/types.h>
1353 #ifdef HAVE_SYS_PARAM_H
1354 # include <sys/param.h>
1355 #endif
1356 #include <sys/statfs.h>
1357 ],[
1358 struct statfs stfs;
1359 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1360 )
1361 )
1362 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1363 then
1364 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1365 [Define if the struct statfs is defined by <sys/statfs.h>])
1366 fi
1367 fi
1369 if test "$ac_cv_header_sys_mount_h" = "yes"
1370 then
1371 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1372 wine_cv_sys_mount_has_statfs,
1373 AC_TRY_COMPILE([
1374 #include <sys/types.h>
1375 #ifdef HAVE_SYS_PARAM_H
1376 # include <sys/param.h>
1377 #endif
1378 #include <sys/mount.h>
1379 ],[
1380 struct statfs stfs;
1381 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1382 )
1383 )
1384 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1385 then
1386 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1387 [Define if the struct statfs is defined by <sys/mount.h>])
1388 fi
1389 fi
1391 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1393 dnl Check for statfs members
1394 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1395 [#include <sys/types.h>
1396 #ifdef HAVE_SYS_PARAM_H
1397 # include <sys/param.h>
1398 #endif
1399 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1400 # include <sys/mount.h>
1401 #else
1402 # ifdef STATFS_DEFINED_BY_SYS_VFS
1403 # include <sys/vfs.h>
1404 # else
1405 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1406 # include <sys/statfs.h>
1407 # endif
1408 # endif
1409 #endif])
1411 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1412 [#ifdef HAVE_SYS_STATVFS_H
1413 #include <sys/statvfs.h>
1414 #endif])
1416 dnl Check for socket structure members
1417 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1418 [#include <sys/types.h>
1419 #ifdef HAVE_SYS_SOCKET_H
1420 # include <sys/socket.h>
1421 #endif
1422 #ifdef HAVE_SYS_UN_H
1423 # include <sys/un.h>
1424 #endif])
1426 dnl Check for siginfo_t members
1427 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1429 dnl Check for struct option
1430 AC_CHECK_MEMBERS([struct option.name],,,
1431 [#ifdef HAVE_GETOPT_H
1432 #include <getopt.h>
1433 #endif])
1435 dnl Check for stat.st_blocks
1436 AC_CHECK_MEMBERS([struct stat.st_blocks])
1438 dnl *** check for the need to define platform-specific symbols
1440 case $host_cpu in
1441 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1442 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1443 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1444 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1445 esac
1447 case $host_vendor in
1448 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1449 esac
1451 dnl **** Generate output files ****
1453 AH_TOP([#define __WINE_CONFIG_H])
1455 WINE_CONFIG_EXTRA_DIR(controls)
1456 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1457 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1458 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1459 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1460 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1461 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1462 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1463 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1464 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1465 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1466 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1467 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1468 WINE_CONFIG_EXTRA_DIR(files)
1469 WINE_CONFIG_EXTRA_DIR(include/wine)
1470 WINE_CONFIG_EXTRA_DIR(misc)
1471 WINE_CONFIG_EXTRA_DIR(objects)
1472 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1473 WINE_CONFIG_EXTRA_DIR(windows)
1475 MAKE_RULES=Make.rules
1476 AC_SUBST_FILE(MAKE_RULES)
1478 MAKE_DLL_RULES=dlls/Makedll.rules
1479 AC_SUBST_FILE(MAKE_DLL_RULES)
1481 MAKE_TEST_RULES=dlls/Maketest.rules
1482 AC_SUBST_FILE(MAKE_TEST_RULES)
1484 MAKE_LIB_RULES=libs/Makelib.rules
1485 AC_SUBST_FILE(MAKE_LIB_RULES)
1487 MAKE_PROG_RULES=programs/Makeprog.rules
1488 AC_SUBST_FILE(MAKE_PROG_RULES)
1490 AC_CONFIG_FILES([
1491 Make.rules
1492 dlls/Makedll.rules
1493 dlls/Maketest.rules
1494 libs/Makelib.rules
1495 programs/Makeprog.rules
1496 Makefile
1497 dlls/Makefile
1498 dlls/advapi32/Makefile
1499 dlls/advapi32/tests/Makefile
1500 dlls/amstream/Makefile
1501 dlls/avicap32/Makefile
1502 dlls/avifil32/Makefile
1503 dlls/cabinet/Makefile
1504 dlls/capi2032/Makefile
1505 dlls/cards/Makefile
1506 dlls/cfgmgr32/Makefile
1507 dlls/comcat/Makefile
1508 dlls/comctl32/Makefile
1509 dlls/comctl32/tests/Makefile
1510 dlls/commdlg/Makefile
1511 dlls/crtdll/Makefile
1512 dlls/crypt32/Makefile
1513 dlls/ctl3d/Makefile
1514 dlls/d3d8/Makefile
1515 dlls/d3d9/Makefile
1516 dlls/d3dim/Makefile
1517 dlls/d3dx8/Makefile
1518 dlls/dbghelp/Makefile
1519 dlls/dciman32/Makefile
1520 dlls/ddraw/Makefile
1521 dlls/ddraw/tests/Makefile
1522 dlls/devenum/Makefile
1523 dlls/dinput/Makefile
1524 dlls/dinput8/Makefile
1525 dlls/dmband/Makefile
1526 dlls/dmcompos/Makefile
1527 dlls/dmime/Makefile
1528 dlls/dmloader/Makefile
1529 dlls/dmscript/Makefile
1530 dlls/dmstyle/Makefile
1531 dlls/dmsynth/Makefile
1532 dlls/dmusic/Makefile
1533 dlls/dmusic32/Makefile
1534 dlls/dplay/Makefile
1535 dlls/dplayx/Makefile
1536 dlls/dpnhpast/Makefile
1537 dlls/dsound/Makefile
1538 dlls/dsound/tests/Makefile
1539 dlls/dswave/Makefile
1540 dlls/dxerr8/Makefile
1541 dlls/dxerr9/Makefile
1542 dlls/dxguid/Makefile
1543 dlls/gdi/Makefile
1544 dlls/gdi/tests/Makefile
1545 dlls/glu32/Makefile
1546 dlls/glut32/Makefile
1547 dlls/iccvid/Makefile
1548 dlls/icmp/Makefile
1549 dlls/ifsmgr.vxd/Makefile
1550 dlls/imagehlp/Makefile
1551 dlls/imm32/Makefile
1552 dlls/iphlpapi/Makefile
1553 dlls/iphlpapi/tests/Makefile
1554 dlls/kernel/Makefile
1555 dlls/kernel/tests/Makefile
1556 dlls/lzexpand/Makefile
1557 dlls/mapi32/Makefile
1558 dlls/mmdevldr.vxd/Makefile
1559 dlls/monodebg.vxd/Makefile
1560 dlls/mpr/Makefile
1561 dlls/msacm/Makefile
1562 dlls/msacm/imaadp32/Makefile
1563 dlls/msacm/msadp32/Makefile
1564 dlls/msacm/msg711/Makefile
1565 dlls/msacm/winemp3/Makefile
1566 dlls/msdmo/Makefile
1567 dlls/mshtml/Makefile
1568 dlls/msi/Makefile
1569 dlls/msimg32/Makefile
1570 dlls/msisys/Makefile
1571 dlls/msnet32/Makefile
1572 dlls/msrle32/Makefile
1573 dlls/msvcrt/Makefile
1574 dlls/msvcrt/tests/Makefile
1575 dlls/msvcrt20/Makefile
1576 dlls/msvcrt40/Makefile
1577 dlls/msvcrtd/Makefile
1578 dlls/msvidc32/Makefile
1579 dlls/msvideo/Makefile
1580 dlls/mswsock/Makefile
1581 dlls/netapi32/Makefile
1582 dlls/netapi32/tests/Makefile
1583 dlls/newdev/Makefile
1584 dlls/ntdll/Makefile
1585 dlls/ntdll/tests/Makefile
1586 dlls/odbc32/Makefile
1587 dlls/ole32/Makefile
1588 dlls/oleacc/Makefile
1589 dlls/oleaut32/Makefile
1590 dlls/oleaut32/tests/Makefile
1591 dlls/olecli/Makefile
1592 dlls/oledlg/Makefile
1593 dlls/olepro32/Makefile
1594 dlls/olesvr/Makefile
1595 dlls/opengl32/Makefile
1596 dlls/psapi/Makefile
1597 dlls/qcap/Makefile
1598 dlls/quartz/Makefile
1599 dlls/rasapi32/Makefile
1600 dlls/richedit/Makefile
1601 dlls/rpcrt4/Makefile
1602 dlls/rpcrt4/tests/Makefile
1603 dlls/rsabase/Makefile
1604 dlls/secur32/Makefile
1605 dlls/serialui/Makefile
1606 dlls/setupapi/Makefile
1607 dlls/shdocvw/Makefile
1608 dlls/shell32/Makefile
1609 dlls/shell32/tests/Makefile
1610 dlls/shfolder/Makefile
1611 dlls/shlwapi/Makefile
1612 dlls/shlwapi/tests/Makefile
1613 dlls/snmpapi/Makefile
1614 dlls/sti/Makefile
1615 dlls/tapi32/Makefile
1616 dlls/ttydrv/Makefile
1617 dlls/twain/Makefile
1618 dlls/unicows/Makefile
1619 dlls/url/Makefile
1620 dlls/urlmon/Makefile
1621 dlls/urlmon/tests/Makefile
1622 dlls/user/Makefile
1623 dlls/user/tests/Makefile
1624 dlls/uuid/Makefile
1625 dlls/uxtheme/Makefile
1626 dlls/vdhcp.vxd/Makefile
1627 dlls/version/Makefile
1628 dlls/version/tests/Makefile
1629 dlls/vmm.vxd/Makefile
1630 dlls/vnbt.vxd/Makefile
1631 dlls/vnetbios.vxd/Makefile
1632 dlls/vtdapi.vxd/Makefile
1633 dlls/vwin32.vxd/Makefile
1634 dlls/win32s/Makefile
1635 dlls/winaspi/Makefile
1636 dlls/wined3d/Makefile
1637 dlls/winedos/Makefile
1638 dlls/wineps/Makefile
1639 dlls/wininet/Makefile
1640 dlls/wininet/tests/Makefile
1641 dlls/winmm/Makefile
1642 dlls/winmm/joystick/Makefile
1643 dlls/winmm/mcianim/Makefile
1644 dlls/winmm/mciavi/Makefile
1645 dlls/winmm/mcicda/Makefile
1646 dlls/winmm/mciseq/Makefile
1647 dlls/winmm/mciwave/Makefile
1648 dlls/winmm/midimap/Makefile
1649 dlls/winmm/tests/Makefile
1650 dlls/winmm/wavemap/Makefile
1651 dlls/winmm/winealsa/Makefile
1652 dlls/winmm/winearts/Makefile
1653 dlls/winmm/wineaudioio/Makefile
1654 dlls/winmm/winejack/Makefile
1655 dlls/winmm/winenas/Makefile
1656 dlls/winmm/wineoss/Makefile
1657 dlls/winnls/Makefile
1658 dlls/winsock/Makefile
1659 dlls/winsock/tests/Makefile
1660 dlls/winspool/Makefile
1661 dlls/winspool/tests/Makefile
1662 dlls/wintab32/Makefile
1663 dlls/wintrust/Makefile
1664 dlls/wow32/Makefile
1665 dlls/wsock32/Makefile
1666 dlls/x11drv/Makefile
1667 documentation/Makefile
1668 include/Makefile
1669 libs/Makefile
1670 libs/port/Makefile
1671 libs/unicode/Makefile
1672 libs/wine/Makefile
1673 libs/wpp/Makefile
1674 loader/Makefile
1675 programs/Makefile
1676 programs/avitools/Makefile
1677 programs/clock/Makefile
1678 programs/cmdlgtst/Makefile
1679 programs/control/Makefile
1680 programs/expand/Makefile
1681 programs/notepad/Makefile
1682 programs/progman/Makefile
1683 programs/regedit/Makefile
1684 programs/regsvr32/Makefile
1685 programs/rpcss/Makefile
1686 programs/rundll32/Makefile
1687 programs/start/Makefile
1688 programs/taskmgr/Makefile
1689 programs/uninstaller/Makefile
1690 programs/view/Makefile
1691 programs/wcmd/Makefile
1692 programs/wineboot/Makefile
1693 programs/winebrowser/Makefile
1694 programs/winecfg/Makefile
1695 programs/wineconsole/Makefile
1696 programs/winedbg/Makefile
1697 programs/winefile/Makefile
1698 programs/winemenubuilder/Makefile
1699 programs/winemine/Makefile
1700 programs/winepath/Makefile
1701 programs/winetest/Makefile
1702 programs/winevdm/Makefile
1703 programs/winhelp/Makefile
1704 programs/winver/Makefile
1705 server/Makefile
1706 tools/Makefile
1707 tools/widl/Makefile
1708 tools/winapi/Makefile
1709 tools/winebuild/Makefile
1710 tools/winedump/Makefile
1711 tools/winegcc/Makefile
1712 tools/wmc/Makefile
1713 tools/wrc/Makefile])
1715 AC_OUTPUT
1717 if test "$have_x" = "no"
1718 then
1719 echo
1720 echo "*** Warning: X development files not found. Wine will be built without"
1721 echo "*** X support, which currently does not work, and would probably not be"
1722 echo "*** what you want anyway. You will need to install devel packages of"
1723 echo "*** Xlib/Xfree86 at the very least."
1724 fi
1726 if test "$wine_cv_opengl_version_OK" = "no"
1727 then
1728 echo
1729 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1730 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1731 fi
1733 if test "$wine_cv_msg_freetype" = "yes"
1734 then
1735 echo
1736 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1737 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1738 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1739 echo "*** enable Wine to use TrueType fonts."
1740 fi
1742 echo
1743 echo "Configure finished. Do 'make depend && make' to compile Wine."
1744 echo
1746 dnl Local Variables:
1747 dnl comment-start: "dnl "
1748 dnl comment-end: ""
1749 dnl comment-start-skip: "\\bdnl\\b\\s *"
1750 dnl compile-command: "autoconf"
1751 dnl End: