| blob | 161211eb8c38f0d6dc9baccda054006fd9ed4189 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
19 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
20 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
25 if test "x$enable_win16" = "xno"
26 then
27 WIN16_FILES=""
28 WIN16_INSTALL=""
29 fi
30 if test "x$enable_debug" = "xno"
31 then
32 AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
33 fi
34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
35 then
36 AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
37 fi
39 dnl **** Check for some programs ****
41 AC_CANONICAL_HOST
42 AC_PROG_MAKE_SET
43 AC_PROG_CC
44 AC_PROG_CPP
46 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
47 [if test -z "$with_wine_tools"; then
48 if test "$cross_compiling" = "yes"; then
49 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
50 else
51 wine_cv_toolsdir="\$(TOPOBJDIR)"
52 fi
53 elif test -d "$with_wine_tools/tools/winebuild"; then
54 case $with_wine_tools in
55 /*) wine_cv_toolsdir="$with_wine_tools" ;;
56 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
57 esac
58 else
59 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
60 fi])
61 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
63 AC_PATH_XTRA
64 AC_PROG_YACC
65 AC_PROG_LEX
67 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
68 dnl **** without one present.
69 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
70 if test "$XYACC" = "none"
71 then
72 AC_MSG_ERROR([no suitable bison/yacc found. Please install the 'bison' package.])
73 fi
74 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
75 if test "$XLEX" = "none"
76 then
77 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
78 fi
80 AC_CHECK_TOOLS(AS,[gas as],as)
81 AC_CHECK_TOOL(LD,ld,ld)
82 AC_CHECK_TOOL(AR,ar,ar)
83 AC_PROG_RANLIB
84 AC_CHECK_TOOL(STRIP,strip,strip)
85 AC_CHECK_TOOL(WINDRES,windres,false)
86 AC_PROG_LN_S
87 WINE_PROG_LN
88 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
89 AC_PROG_INSTALL
90 dnl Prepend src dir to install path dir if it's a relative path
91 case "$INSTALL" in
92 [[\\/$]]* | ?:[[\\/]]* ) ;;
93 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
94 esac
96 dnl Check for lint
97 AC_CHECK_PROGS(LINT, lclint lint)
98 if test "$LINT" = "lint"
99 then
100 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
101 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
102 fi
103 AC_SUBST(LINT)
104 AC_SUBST(LINTFLAGS)
106 dnl Check for db2html
107 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
108 AC_SUBST(DB2HTML)
110 dnl Check for db2pdf
111 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
112 AC_SUBST(DB2PDF)
114 dnl Check for db2ps
115 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
116 AC_SUBST(DB2PS)
118 dnl Check for db2txt
119 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
120 AC_SUBST(DB2TXT)
122 dnl **** Check for some libraries ****
124 dnl Check for -lm
125 AC_CHECK_LIB(m,sqrt)
126 dnl Check for -li386 for NetBSD and OpenBSD
127 AC_CHECK_LIB(i386,i386_set_ldt)
128 dnl Check for -lossaudio for NetBSD
129 AC_CHECK_LIB(ossaudio,_oss_ioctl)
130 dnl Check for -lw for Solaris
131 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
132 dnl Check for -lnsl for Solaris
133 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
134 dnl Check for -lsocket for Solaris
135 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
136 dnl Check for -lresolv for Solaris
137 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
138 dnl Check for -lxpg4 for FreeBSD
139 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
140 dnl Check for -lpoll for Mac OS X/Darwin
141 AC_CHECK_LIB(poll,poll)
142 dnl Check for -lpthread
143 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
145 JPEGLIB=""
146 AC_SUBST(JPEGLIB)
147 AC_CHECK_HEADERS(jpeglib.h,
148 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
149 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
150 JPEGLIB="-ljpeg"
151 )
152 )
154 AC_SUBST(GIFLIB,"")
155 AC_CHECK_HEADERS(gif_lib.h,
156 AC_CHECK_LIB(ungif,DGifOpen,
157 [AC_DEFINE(HAVE_LIBGIF,1,[Define if you have libgif/libungif including devel headers])
158 GIFLIB="-lungif"],
159 [AC_CHECK_LIB(gif,DGifOpen,
160 [AC_DEFINE(HAVE_LIBGIF,1)
161 GIFLIB="-lgif"])]))
163 AC_SUBST(XLIB)
164 AC_SUBST(XFILES)
165 XFILES=""
166 AC_SUBST(OPENGLFILES)
167 OPENGLFILES=""
168 AC_SUBST(GLU32FILES)
169 GLU32FILES=""
170 AC_SUBST(OPENGL_LIBS)
171 OPENGL_LIBS=""
172 if test "$have_x" = "yes"
173 then
174 XLIB="-lXext -lX11"
175 ac_save_CPPFLAGS="$CPPFLAGS"
176 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
178 dnl *** All of the following tests require X11/Xlib.h
179 AC_CHECK_HEADERS(X11/Xlib.h,
180 [
181 AC_CHECK_HEADERS([X11/XKBlib.h \
182 X11/Xutil.h \
183 X11/extensions/shape.h \
184 X11/extensions/XShm.h \
185 X11/extensions/Xrandr.h \
186 X11/extensions/Xrender.h \
187 X11/extensions/Xvlib.h \
188 X11/extensions/xf86dga.h \
189 X11/extensions/xf86vmode.h],,,
190 [#include <X11/Xlib.h>
191 #ifdef HAVE_X11_XUTIL_H
192 # include <X11/Xutil.h>
193 #endif])
195 dnl *** Check for X keyboard extension
196 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
197 then
198 AC_CHECK_LIB(X11, XkbQueryExtension,
199 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
200 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
201 fi
203 dnl *** Check for X Shm extension
204 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
205 then
206 AC_CHECK_LIB(Xext, XShmQueryExtension,
207 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
208 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
209 fi
211 dnl *** Check for X shape extension
212 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
213 then
214 AC_CHECK_LIB(Xext,XShapeQueryExtension,
215 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
216 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
217 fi
219 dnl *** Check for XFree86 DGA / DGA 2.0 extension
220 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
221 then
222 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
223 [ dnl *** If found...
224 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
225 [Define if you have the Xxf86dga library version 2])
226 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
227 ],
228 [ dnl *** If not found, look for XF86DGAQueryExtension()
229 dnl *** instead (DGA 2.0 not found)...
230 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
231 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
232 [Define if you have the Xxf86dga library version 1])
233 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
234 ],,
235 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
236 )
237 ],
238 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
239 fi
241 dnl *** Check for XFree86 VMODE extension
242 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
243 then
244 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
245 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
246 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
247 ],,
248 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
249 fi
251 dnl *** Check for X RandR extension
252 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
253 then
254 AC_CHECK_LIB(Xrandr, XRRSetScreenConfigAndRate,
255 [ AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])
256 X_PRE_LIBS="$X_PRE_LIBS -lXrandr -lXrender"
257 ],,
258 $X_LIBS -lXrender -lXext -lX11 $X_EXTRA_LIBS)
259 fi
261 dnl *** Check for XVideo extension supporting XvImages
262 if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
263 then
264 AC_CHECK_LIB(Xv, XvShmCreateImage,
265 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
266 X_PRE_LIBS="$X_PRE_LIBS -lXv"
267 ],,
268 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
269 fi
270 ]
271 ) dnl *** End of X11/Xlib.h check
273 dnl Check for the presence of OpenGL
274 if test "x$with_opengl" != "xno"
275 then
276 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
277 then
278 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
279 This prevents linking to OpenGL. Delete the file and restart configure.])
280 fi
282 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
283 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
284 then
285 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
286 dnl Check for some problems due to old Mesa versions
287 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
288 AC_TRY_COMPILE(
289 [#include <GL/gl.h>],
290 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
291 [wine_cv_opengl_version_OK="yes"],
292 [wine_cv_opengl_version_OK="no"]
293 )
294 )
296 if test "$wine_cv_opengl_version_OK" = "yes"
297 then
298 dnl Check for the presence of the library
299 AC_CHECK_LIB(GL,glXCreateContext,
300 OPENGL_LIBS="-lGL"
301 ,,
302 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
304 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
305 then
306 OPENGLFILES='$(OPENGLFILES)'
307 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
309 AC_CHECK_LIB(GL,glXGetProcAddressARB,
310 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
311 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
312 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
314 if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
315 then
316 AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
317 [AC_TRY_COMPILE([#include <GL/gl.h>
318 #ifdef HAVE_GL_GLEXT_H
319 # include <GL/glext.h>
320 #endif
321 ],
322 [PFNGLCOLORTABLEEXTPROC test_proc;],
323 [wine_cv_extension_prototypes="yes"],
324 [wine_cv_extension_prototypes="no"]
325 )]
326 )
327 if test "$wine_cv_extension_prototypes" = "yes"
328 then
329 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
330 [Define if the OpenGL headers define extension typedefs])
331 fi
332 fi
334 fi
335 dnl Check for GLU32 library.
336 AC_CHECK_LIB(GLU,gluLookAt,
337 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
338 GLU32FILES='$(GLU32FILES)']
339 ,,
340 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
341 )
342 fi
344 dnl Check for glut32 library.
345 AC_CHECK_LIB(glut,glutMainLoop,
346 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
347 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
348 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
349 fi
350 fi
352 dnl **** Check for NAS ****
353 AC_SUBST(NASLIBS,"")
354 AC_CHECK_HEADERS(audio/audiolib.h,
355 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
356 AC_CHECK_LIB(audio,AuCreateFlow,
357 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
358 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
359 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
361 CPPFLAGS="$ac_save_CPPFLAGS"
362 XFILES='$(XFILES)'
363 else
364 XLIB=""
365 X_CFLAGS=""
366 X_LIBS=""
367 fi
369 dnl **** Check which curses lib to use ***
370 CURSESLIBS=""
371 if test "x$with_curses" != "xno"
372 then
373 AC_CHECK_HEADERS(ncurses.h,
374 [AC_CHECK_LIB(ncurses,waddch,
375 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
376 CURSESLIBS="-lncurses"],
377 [AC_CHECK_HEADERS(curses.h,
378 [AC_CHECK_LIB(curses,waddch,
379 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
380 CURSESLIBS="-lcurses"])])])])
381 saved_libs="$LIBS"
382 LIBS="$CURSESLIBS $LIBS"
383 AC_CHECK_FUNCS(getbkgd resizeterm)
384 LIBS="$saved_libs"
385 fi
386 AC_SUBST(CURSESLIBS)
388 dnl **** Check for SANE ****
389 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
390 if test "$sane_devel" = "no"
391 then
392 SANELIBS=""
393 SANEINCL=""
394 else
395 SANELIBS="`$sane_devel --libs`"
396 SANEINCL="`$sane_devel --cflags`"
397 ac_save_CPPFLAGS="$CPPFLAGS"
398 ac_save_LIBS="$LIBS"
399 CPPFLAGS="$CPPFLAGS $SANEINCL"
400 LIBS="$LIBS $SANELIBS"
401 AC_CHECK_HEADER(sane/sane.h,
402 [AC_CHECK_LIB(sane,sane_open,
403 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
404 [SANELIBS=""
405 SANEINCL=""])],
406 [SANELIBS=""
407 SANEINCL=""])
408 LIBS="$ac_save_LIBS"
409 CPPFLAGS="$ac_save_CPPFLAGS"
410 fi
411 AC_SUBST(SANELIBS)
412 AC_SUBST(SANEINCL)
414 dnl **** Check for the ICU library ****
415 AC_CHECK_HEADERS(unicode/ubidi.h)
416 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
417 then
418 AC_CACHE_CHECK([whether we can statically link the ICU libraries], ac_cv_lib_icu,
419 [saved_libs="$LIBS"
420 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
421 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libicuuc.a}"
422 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libicudata.a}"
423 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
424 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
425 [ac_cv_lib_icu="yes"],[ac_cv_lib_icu="no"])
426 LIBS="$saved_libs"])
427 if test "$ac_cv_lib_icu" = "yes"
428 then
429 AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
430 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
431 fi
432 fi
434 dnl **** Check for FreeType 2 ****
435 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
436 if test "$ft_lib" = "no"
437 then
438 FREETYPEINCL=""
439 wine_cv_msg_freetype=no
440 else
441 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
442 if test "$ft_devel" = "no"
443 then
444 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
445 if test "$ft_devel2" = "freetype2-config"
446 then
447 ft_devel=$ft_devel2
448 fi
449 fi
450 if test "$ft_devel" = "no"
451 then
452 FREETYPEINCL=""
453 wine_cv_msg_freetype=yes
454 else
455 FREETYPEINCL=`$ft_devel --cflags`
456 ac_save_CPPFLAGS="$CPPFLAGS"
457 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
458 AC_CHECK_HEADERS(ft2build.h \
459 freetype/freetype.h \
460 freetype/ftglyph.h \
461 freetype/tttables.h \
462 freetype/ftnames.h \
463 freetype/ftsnames.h \
464 freetype/ttnameid.h \
465 freetype/ftoutln.h \
466 freetype/internal/sfnt.h,,,
467 [#if HAVE_FT2BUILD_H
468 #include <ft2build.h>
469 #endif])
470 AC_TRY_CPP([#include <ft2build.h>
471 #include <freetype/fttrigon.h>],
472 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
473 [Define if you have the <freetype/fttrigon.h> header file.])
474 wine_cv_fttrigon=yes],
475 wine_cv_fttrigon=no)
476 CPPFLAGS="$ac_save_CPPFLAGS"
477 dnl Check that we have at least freetype/freetype.h
478 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
479 then
480 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
481 wine_cv_msg_freetype=no
482 else
483 FREETYPEINCL=""
484 wine_cv_msg_freetype=yes
485 fi
486 fi
487 fi
488 AC_SUBST(FREETYPEINCL)
490 dnl **** Check for parport (currently Linux only) ****
491 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
492 AC_TRY_COMPILE(
493 [#include <linux/ppdev.h>],
494 [ioctl (1,PPCLAIM,0)],
495 [ac_cv_c_ppdev="yes"],
496 [ac_cv_c_ppdev="no"])
497 )
498 if test "$ac_cv_c_ppdev" = "yes"
499 then
500 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
501 fi
503 dnl **** Check for va_copy ****
504 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
505 AC_TRY_LINK(
506 [#include <stdarg.h>],
507 [va_list ap1, ap2;
508 va_copy(ap1,ap2);
509 ],
510 [ac_cv_c_va_copy="yes"],
511 [ac_cv_c_va_copy="no"])
512 )
513 if test "$ac_cv_c_va_copy" = "yes"
514 then
515 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
516 fi
517 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
518 AC_TRY_LINK(
519 [#include <stdarg.h>],
520 [va_list ap1, ap2;
521 __va_copy(ap1,ap2);
522 ],
523 [ac_cv_c___va_copy="yes"],
524 [ac_cv_c___va_copy="no"])
525 )
526 if test "$ac_cv_c___va_copy" = "yes"
527 then
528 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
529 fi
531 dnl **** Check for sigsetjmp ****
532 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
533 AC_TRY_LINK(
534 [#include <setjmp.h>],
535 [sigjmp_buf buf;
536 sigsetjmp( buf, 1 );
537 siglongjmp( buf, 1 );],
538 [ac_cv_c_sigsetjmp="yes"],
539 [ac_cv_c_sigsetjmp="no"])
540 )
541 if test "$ac_cv_c_sigsetjmp" = "yes"
542 then
543 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
544 fi
546 dnl **** Check for pthread_rwlock_t ****
547 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
548 #include <pthread.h>])
550 dnl **** Check for pthread_getattr_np ****
551 ac_save_LIBS="$LIBS"
552 LIBS="$LIBS $LIBPTHREAD"
553 AC_CHECK_FUNCS(pthread_getattr_np)
554 LIBS="$ac_save_LIBS"
556 dnl **** Check for Open Sound System ****
557 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
559 AC_CACHE_CHECK([for Open Sound System],
560 ac_cv_c_opensoundsystem,
561 AC_TRY_COMPILE([
562 #if defined(HAVE_SYS_SOUNDCARD_H)
563 #include <sys/soundcard.h>
564 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
565 #include <machine/soundcard.h>
566 #elif defined(HAVE_SOUNDCARD_H)
567 #include <soundcard.h>
568 #endif
569 ],[
571 /* check for one of the Open Sound System specific SNDCTL_ defines */
572 #if !defined(SNDCTL_DSP_STEREO)
573 #error No open sound system
574 #endif
575 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
577 if test "$ac_cv_c_opensoundsystem" = "yes"
578 then
579 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
580 fi
582 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
583 ac_cv_c_opensoundsystem_midi,
584 AC_TRY_COMPILE([
585 #if defined(HAVE_SYS_SOUNDCARD_H)
586 #include <sys/soundcard.h>
587 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
588 #include <machine/soundcard.h>
589 #elif defined(HAVE_SOUNDCARD_H)
590 #include <soundcard.h>
591 #endif
592 ],[
594 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
595 #if !defined(SNDCTL_SEQ_SYNC)
596 #error No open sound system MIDI interface
597 #endif
598 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
600 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
601 then
602 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
603 fi
605 dnl **** Check for aRts Sound Server ****
606 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
607 AC_CACHE_CHECK([for aRts Sound server],
608 ac_cv_c_artsserver,
609 if test x$ARTSCCONFIG = x -o x$ARTSCCONFIG = x'"$ARTSCCONFIG"';
610 then
611 ac_cv_c_artsserver=no
612 else
613 ARTSC_CFLAGS=`$ARTSCCONFIG --cflags`
614 ARTSC_LIBS=`$ARTSCCONFIG --libs`
615 ac_cv_c_artsserver=no
616 save_CFLAGS="$CFLAGS"
617 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
618 AC_TRY_COMPILE([
619 #include <artsc.h>
620 ],[
621 arts_stream_t stream;
622 ],[
623 ac_cv_c_artsserver=yes
624 ])
625 CFLAGS="$save_CFLAGS"
626 fi)
628 if test "$ac_cv_c_artsserver" = "yes"
629 then
630 AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
631 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
633 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])
634 fi
636 dnl **** Check for ALSA ****
637 AC_SUBST(ALSALIBS,"")
638 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
639 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
640 then
641 AC_CHECK_LIB(asound,snd_pcm_open,
642 AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
643 ALSALIBS="-lasound")
644 fi
646 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
648 AC_SUBST(AUDIOIOLIBS,"")
649 AC_CHECK_HEADERS(libaudioio.h,
650 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
651 [AUDIOIOLIBS="-laudioio"
652 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
654 dnl **** Check for capi4linux ****
656 AC_CHECK_HEADERS(capi20.h,[
657 AC_CHECK_HEADERS(linux/capi.h,[
658 AC_CHECK_LIB(capi20,capi20_register,[
659 AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
660 AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
661 ])
662 ])
663 ])
665 dnl **** Check for broken glibc mmap64 ****
667 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
668 AC_TRY_RUN([
669 #define _FILE_OFFSET_BITS 64
670 #include <stdio.h>
671 #include <unistd.h>
672 #include <fcntl.h>
673 #include <sys/mman.h>
674 #include <errno.h>
676 int main(int argc,char **argv) {
677 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
678 if (fd == -1) exit(1);
680 unlink("conftest.map");
682 write(fd,"test",4);
684 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
685 (errno == EINVAL)
686 ) {
687 exit(1);
688 }
689 close(fd);
690 fprintf(stderr,"success!\n");
691 exit(0);
692 }
694 ],
695 ac_cv_mmap64_works="yes",
696 ac_cv_mmap64_works="no",
697 ac_cv_mmap64_works="no") )
699 if test "$ac_cv_mmap64_works" = "yes"
700 then
701 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
702 fi
704 dnl **** Check for gcc specific options ****
706 AC_SUBST(EXTRACFLAGS,"")
707 if test "x${GCC}" = "xyes"
708 then
709 EXTRACFLAGS="-Wall -pipe"
711 dnl Check for strength-reduce bug
712 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
713 AC_TRY_RUN([
714 int L[[4]] = {0,1,2,3};
715 int main(void) {
716 static int Array[[3]];
717 unsigned int B = 3;
718 int i;
719 for(i=0; i<B; i++) Array[[i]] = i - 3;
720 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
721 L[[i]] = 4;
723 exit( Array[[1]] != -2 || L[[2]] != 3);
724 }],
725 ac_cv_c_gcc_strength_bug="no",
726 ac_cv_c_gcc_strength_bug="yes",
727 ac_cv_c_gcc_strength_bug="yes") )
728 if test "$ac_cv_c_gcc_strength_bug" = "yes"
729 then
730 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
731 fi
733 dnl Check for -mpreferred-stack-boundary
734 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
735 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
736 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
737 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
738 then
739 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
740 fi
742 dnl Check for -fno-strict-aliasing
743 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
744 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
745 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
746 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
747 then
748 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
749 fi
751 dnl Check for -gstabs+ option
752 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
753 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
754 if test "$ac_cv_c_gcc_gstabs" = "yes"
755 then
756 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
757 fi
759 dnl Check for noisy string.h
760 saved_CFLAGS="$CFLAGS"
761 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
762 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
763 AC_TRY_COMPILE([#include <string.h>],[],
764 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
765 CFLAGS="$saved_CFLAGS"
766 if test "$ac_cv_c_string_h_warnings" = "no"
767 then
768 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
769 fi
770 fi
772 dnl **** Check how to define a function in assembly code ****
774 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
775 WINE_TRY_ASM_LINK(
776 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
777 ac_cv_asm_func_def=".def",
778 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
779 ac_cv_asm_func_def=".type @function",
780 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
781 ac_cv_asm_func_def=".type 2",
782 ac_cv_asm_func_def="unknown")])]))
784 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
785 case "$ac_cv_asm_func_def" in
786 ".def")
787 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
788 ".type @function")
789 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
790 ".type 2")
791 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
792 *)
793 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
794 esac
796 dnl **** Check for underscore on external symbols ****
798 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
799 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
800 [extern int ac_test;],
801 [if (ac_test) return 1],
802 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
804 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
805 if test "$ac_cv_c_extern_prefix" = "yes"
806 then
807 AC_DEFINE([__ASM_NAME(name)], ["_" name])
808 else
809 AC_DEFINE([__ASM_NAME(name)], [name])
810 fi
812 dnl **** Check how to do strings in assembler ****
814 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
815 WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
816 WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
817 WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
818 AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
820 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
821 [Define to the assembler keyword used to specify an ASCII string])
823 dnl **** Check for .short in assembler ****
825 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
826 WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
827 WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
828 AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
830 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
831 [Define to the assembler keyword used to specify a word value])
833 dnl **** Check for working dll ****
835 AC_SUBST(DLLEXT,"")
836 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
837 AC_SUBST(DLLIBS,"")
838 AC_SUBST(LDSHARED,"")
839 AC_SUBST(LDDLL,"")
840 AC_SUBST(LIBEXT,"so")
841 AC_SUBST(IMPLIBEXT,"def")
843 case $host_os in
844 cygwin*|mingw32*)
845 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
846 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
847 if test "$DLLWRAP" = "false"; then
848 LIBEXT="a"
849 else
850 dnl FIXME - check whether dllwrap works correctly...
851 LIBEXT="dll"
852 fi
853 IMPLIBEXT="a"
854 ;;
855 *)
856 AC_CHECK_HEADERS(dlfcn.h,
857 [AC_CHECK_FUNCS(dlopen,,
858 [AC_CHECK_LIB(dl,dlopen,
859 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
860 DLLIBS="-ldl"],
861 [LIBEXT="a"])])],
862 [LIBEXT="a"])
864 if test "$LIBEXT" = "so"
865 then
866 DLLFLAGS="$DLLFLAGS -fPIC"
867 DLLEXT=".so"
868 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
869 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
870 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
871 if test "$ac_cv_c_dll_gnuelf" = "yes"
872 then
873 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
874 LDDLL="\$(CC) -shared -Wl,-Bsymbolic"
875 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
876 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
877 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
878 if test "$ac_cv_c_dll_zdefs" = "yes"
879 then
880 LDDLL="$LDDLL,-z,defs"
881 fi
883 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
884 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
885 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
886 if test "$ac_cv_c_export_dynamic" = "yes"
887 then
888 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
889 fi
891 case $host_cpu in
892 *i[[3456789]]86*)
893 AC_CACHE_CHECK([whether we can relocate the executable to 0x00110000], ac_cv_ld_reloc_exec,
894 [saved_CFLAGS="$CFLAGS"
895 CFLAGS="$CFLAGS -Wl,--section-start,.interp=0x00110400"
896 AC_TRY_RUN([#include <unistd.h>
897 int main() { return (sbrk(32*1024*1024) == (void *)-1); }],
898 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no", ac_cv_ld_reloc_exec="no")
899 CFLAGS="$saved_CFLAGS"])
900 if test "$ac_cv_ld_reloc_exec" = "yes"
901 then
902 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x00110400"
903 fi
904 ;;
905 esac
907 else
908 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
909 [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
910 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
911 if test "$ac_cv_c_dll_unixware" = "yes"
912 then
913 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
914 LDDLL="\$(CC) -Wl,-G,-B,symbolic"
916 else
917 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
918 [WINE_TRY_CFLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
919 if test "$ac_cv_c_dll_macho" = "yes"
920 then
921 LIBEXT="dylib"
922 LDDLL="\$(CC) -bundle -flat_namespace -undefined suppress"
923 LDSHARED="\$(CC) -dynamiclib"
924 CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
925 fi
926 fi
927 fi
928 fi
930 dnl Check for cross compiler to build test programs
931 AC_SUBST(CROSSTEST,"")
932 if test "$cross_compiling" = "no"
933 then
934 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
935 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
936 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
937 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
938 fi
939 ;;
940 esac
942 if test "$LIBEXT" = "a"; then
943 AC_MSG_ERROR(
944 [could not find a way to build shared libraries.
945 It is currently not possible to build Wine without shared library
946 (.so) support to allow transparent switch between .so and .dll files.
947 If you are using Linux, you will need a newer binutils.]
948 )
949 fi
951 case $build_os in
952 cygwin*|mingw32*)
953 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
954 darwin*|macosx*)
955 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
956 *)
957 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
958 esac
960 dnl Mingw needs explicit msvcrt for linking libwine
961 case $host_os in
962 mingw32*)
963 AC_SUBST(CRTLIBS,"-lmsvcrt") ;;
964 esac
966 case $host_os in
967 linux*)
968 AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread")
969 AC_SUBST(MAIN_BINARY,"wine-glibc")
970 ;;
971 *)
972 AC_SUBST(WINE_BINARIES,"wine-kthread")
973 AC_SUBST(MAIN_BINARY,"wine-kthread")
974 ;;
975 esac
977 dnl **** Get the soname for libraries that we load dynamically ****
979 if test "$LIBEXT" = "so"
980 then
981 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
982 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
983 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
984 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
985 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
986 WINE_GET_SONAME(cups,cupsGetDefault)
987 WINE_GET_SONAME(jack,jack_client_new)
988 WINE_GET_SONAME(fontconfig,FcInit)
989 WINE_GET_SONAME(ssl,SSL_library_init)
990 WINE_GET_SONAME(crypto,BIO_new_socket)
991 WINE_GET_SONAME(ncurses,waddch)
992 WINE_GET_SONAME(curses,waddch)
993 fi
996 dnl **** Check for functions ****
998 AC_FUNC_ALLOCA()
999 AC_CHECK_FUNCS(\
1000 _lwp_create \
1001 _lwp_self \
1002 _pclose \
1003 _popen \
1004 _snprintf \
1005 _spawnvp \
1006 _stricmp \
1007 _strnicmp \
1008 _vsnprintf \
1009 chsize \
1010 clone \
1011 finite \
1012 fpclass \
1013 ftruncate \
1014 ftruncate64 \
1015 getnetbyaddr \
1016 getnetbyname \
1017 getopt_long \
1018 getpagesize \
1019 getprotobyname \
1020 getprotobynumber \
1021 getpwuid \
1022 getservbyport \
1023 gettid \
1024 gettimeofday \
1025 inet_network \
1026 lseek64 \
1027 lstat \
1028 memmove \
1029 mmap \
1030 pclose \
1031 popen \
1032 pread \
1033 pwrite \
1034 rfork \
1035 select \
1036 sendmsg \
1037 settimeofday \
1038 sigaltstack \
1039 snprintf \
1040 spawnvp \
1041 statfs \
1042 strcasecmp \
1043 strerror \
1044 strncasecmp \
1045 tcgetattr \
1046 timegm \
1047 usleep \
1048 vfscanf \
1049 vsnprintf \
1050 wait4 \
1051 waitpid \
1052 )
1054 dnl **** Check for header files ****
1056 AC_CHECK_HEADERS(\
1057 arpa/inet.h \
1058 arpa/nameser.h \
1059 cups/cups.h \
1060 direct.h \
1061 elf.h \
1062 float.h \
1063 fontconfig/fontconfig.h \
1064 getopt.h \
1065 ieeefp.h \
1066 io.h \
1067 jack/jack.h \
1068 libio.h \
1069 libutil.h \
1070 link.h \
1071 linux/cdrom.h \
1072 linux/hdreg.h \
1073 linux/input.h \
1074 linux/joystick.h \
1075 linux/major.h \
1076 linux/param.h \
1077 linux/serial.h \
1078 linux/ucdrom.h \
1079 machine/cpu.h \
1080 netdb.h \
1081 netinet/in.h \
1082 netinet/in_systm.h \
1083 netinet/tcp.h \
1084 netinet/tcp_fsm.h \
1085 openssl/ssl.h \
1086 process.h \
1087 pthread.h \
1088 pty.h \
1089 pwd.h \
1090 regex.h \
1091 sched.h \
1092 scsi/sg.h \
1093 scsi/scsi.h \
1094 scsi/scsi_ioctl.h \
1095 socket.h \
1096 stdint.h \
1097 strings.h \
1098 sys/cdio.h \
1099 sys/errno.h \
1100 sys/file.h \
1101 sys/filio.h \
1102 sys/inttypes.h \
1103 sys/ioctl.h \
1104 sys/ipc.h \
1105 sys/link.h \
1106 sys/lwp.h \
1107 sys/mman.h \
1108 sys/modem.h \
1109 sys/msg.h \
1110 sys/param.h \
1111 sys/poll.h \
1112 sys/ptrace.h \
1113 sys/reg.h \
1114 sys/scsiio.h \
1115 sys/shm.h \
1116 sys/signal.h \
1117 sys/socket.h \
1118 sys/sockio.h \
1119 sys/statfs.h \
1120 sys/strtio.h \
1121 sys/syscall.h \
1122 sys/sysctl.h \
1123 sys/time.h \
1124 sys/times.h \
1125 sys/uio.h \
1126 sys/un.h \
1127 sys/v86.h \
1128 sys/v86intr.h \
1129 sys/vfs.h \
1130 sys/vm86.h \
1131 sys/wait.h \
1132 syscall.h \
1133 termios.h \
1134 unistd.h \
1135 utime.h \
1136 valgrind/memcheck.h
1137 )
1138 AC_HEADER_STAT()
1140 dnl **** Checks for headers that depend on other ones ****
1142 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1143 [#include <sys/types.h>
1144 #if HAVE_SYS_PARAM_H
1145 # include <sys/param.h>
1146 #endif])
1148 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1149 [#include <sys/types.h>
1150 #if HAVE_SYS_SOCKET_H
1151 # include <sys/socket.h>
1152 #endif])
1154 AC_CHECK_HEADERS([resolv.h],,,
1155 [#include <sys/types.h>
1156 #if HAVE_SYS_SOCKET_H
1157 # include <sys/socket.h>
1158 #endif
1159 #if HAVE_NETINET_IN_H
1160 # include <netinet/in.h>
1161 #endif
1162 #if HAVE_ARPA_NAMESER_H
1163 # include <arpa/nameser.h>
1164 #endif])
1166 AC_CHECK_HEADERS(netinet/ip.h,,,
1167 [#include <sys/types.h>
1168 #if HAVE_SYS_SOCKET_H
1169 # include <sys/socket.h>
1170 #endif
1171 #if HAVE_NETINET_IN_SYSTM_H
1172 # include <netinet/in_systm.h>
1173 #endif])
1175 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1177 dnl **** Check for IPX headers (currently Linux only) ****
1179 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1180 AC_TRY_COMPILE(
1181 [#include <sys/types.h>
1182 #ifdef HAVE_SYS_SOCKET_H
1183 # include <sys/socket.h>
1184 #endif
1185 #include <netipx/ipx.h>],
1186 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1187 [ac_cv_c_ipx_gnu="yes"],
1188 [ac_cv_c_ipx_gnu="no"])
1189 )
1190 if test "$ac_cv_c_ipx_gnu" = "yes"
1191 then
1192 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1193 fi
1195 if test "$ac_cv_c_ipx_gnu" = "no"
1196 then
1197 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1198 AC_TRY_COMPILE(
1199 [#include <sys/types.h>
1200 #ifdef HAVE_SYS_SOCKET_H
1201 # include <sys/socket.h>
1202 #endif
1203 #include <asm/types.h>
1204 #include <linux/ipx.h>],
1205 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1206 [ac_cv_c_ipx_linux="yes"],
1207 [ac_cv_c_ipx_linux="no"])
1208 )
1209 if test "$ac_cv_c_ipx_linux" = "yes"
1210 then
1211 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1212 fi
1213 fi
1215 dnl **** Check for types ****
1217 AC_C_CONST
1218 AC_C_INLINE
1219 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t])
1220 AC_CHECK_SIZEOF(long long,0)
1222 AC_CACHE_CHECK([whether linux/input.h is for real],
1223 wine_cv_linux_input_h,
1224 AC_TRY_COMPILE([
1225 #include <linux/input.h>
1226 ] , [
1227 int foo = EVIOCGBIT(EV_ABS,42);
1228 int bar = BTN_PINKIE;
1229 int fortytwo = 42;
1230 ],
1231 wine_cv_linux_input_h=yes,
1232 wine_cv_linux_input_h=no,
1233 no
1234 )
1235 )
1236 if test "$wine_cv_linux_input_h" = "yes"
1237 then
1238 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1239 [Define if we have linux/input.h AND it contains the INPUT event API])
1240 fi
1243 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1244 wine_cv_linux_gethostbyname_r_6,
1245 AC_TRY_LINK([
1246 #include <netdb.h>
1247 ], [
1248 char *name=NULL;
1249 struct hostent he;
1250 struct hostent *result;
1251 char *buf=NULL;
1252 int bufsize=0;
1253 int res,errnr;
1254 char *addr=NULL;
1255 int addrlen=0;
1256 int addrtype=0;
1257 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1258 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1259 ],
1260 wine_cv_linux_gethostbyname_r_6=yes,
1261 wine_cv_linux_gethostbyname_r_6=no
1262 )
1263 )
1264 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1265 then
1266 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1267 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1268 fi
1270 if test "$ac_cv_header_linux_joystick_h" = "yes"
1271 then
1272 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1273 wine_cv_linux_joystick_22_api,
1274 AC_TRY_COMPILE([
1275 #include <sys/ioctl.h>
1276 #include <linux/joystick.h>
1278 struct js_event blub;
1279 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1280 #error "no 2.2 header"
1281 #endif
1282 ],/*empty*/,
1283 wine_cv_linux_joystick_22_api=yes,
1284 wine_cv_linux_joystick_22_api=no,
1285 wine_cv_linux_joystick_22_api=no
1286 )
1287 )
1288 if test "$wine_cv_linux_joystick_22_api" = "yes"
1289 then
1290 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1291 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1292 fi
1293 fi
1295 dnl **** statfs checks ****
1297 if test "$ac_cv_header_sys_vfs_h" = "yes"
1298 then
1299 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1300 wine_cv_sys_vfs_has_statfs,
1301 AC_TRY_COMPILE([
1302 #include <sys/types.h>
1303 #ifdef HAVE_SYS_PARAM_H
1304 # include <sys/param.h>
1305 #endif
1306 #include <sys/vfs.h>
1307 ],[
1308 struct statfs stfs;
1310 memset(&stfs,0,sizeof(stfs));
1311 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1312 )
1313 )
1314 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1315 then
1316 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1317 [Define if the struct statfs is defined by <sys/vfs.h>])
1318 fi
1319 fi
1321 if test "$ac_cv_header_sys_statfs_h" = "yes"
1322 then
1323 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1324 wine_cv_sys_statfs_has_statfs,
1325 AC_TRY_COMPILE([
1326 #include <sys/types.h>
1327 #ifdef HAVE_SYS_PARAM_H
1328 # include <sys/param.h>
1329 #endif
1330 #include <sys/statfs.h>
1331 ],[
1332 struct statfs stfs;
1333 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1334 )
1335 )
1336 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1337 then
1338 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1339 [Define if the struct statfs is defined by <sys/statfs.h>])
1340 fi
1341 fi
1343 if test "$ac_cv_header_sys_mount_h" = "yes"
1344 then
1345 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1346 wine_cv_sys_mount_has_statfs,
1347 AC_TRY_COMPILE([
1348 #include <sys/types.h>
1349 #ifdef HAVE_SYS_PARAM_H
1350 # include <sys/param.h>
1351 #endif
1352 #include <sys/mount.h>
1353 ],[
1354 struct statfs stfs;
1355 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1356 )
1357 )
1358 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1359 then
1360 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1361 [Define if the struct statfs is defined by <sys/mount.h>])
1362 fi
1363 fi
1365 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1367 dnl Check for statfs members
1368 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail],,,
1369 [#include <sys/types.h>
1370 #ifdef HAVE_SYS_PARAM_H
1371 # include <sys/param.h>
1372 #endif
1373 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1374 # include <sys/mount.h>
1375 #else
1376 # ifdef STATFS_DEFINED_BY_SYS_VFS
1377 # include <sys/vfs.h>
1378 # else
1379 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1380 # include <sys/statfs.h>
1381 # endif
1382 # endif
1383 #endif])
1385 dnl Check for socket structure members
1386 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1387 [#include <sys/types.h>
1388 #ifdef HAVE_SYS_SOCKET_H
1389 # include <sys/socket.h>
1390 #endif
1391 #ifdef HAVE_SYS_UN_H
1392 # include <sys/un.h>
1393 #endif])
1395 dnl Check for siginfo_t members
1396 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1398 dnl Check for struct option
1399 AC_CHECK_MEMBERS([struct option.name],,,
1400 [#ifdef HAVE_GETOPT_H
1401 #include <getopt.h>
1402 #endif])
1404 dnl Check for stat.st_blocks
1405 AC_CHECK_MEMBERS([struct stat.st_blocks])
1407 dnl *** check for the need to define platform-specific symbols
1409 case $host_cpu in
1410 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1411 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1412 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1413 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1414 esac
1416 case $host_vendor in
1417 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1418 esac
1420 dnl **** Generate output files ****
1422 AH_TOP([#define __WINE_CONFIG_H])
1424 WINE_CONFIG_EXTRA_DIR(controls)
1425 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1426 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1427 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1428 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1429 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1430 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1431 WINE_CONFIG_EXTRA_DIR(dlls/dinput/joystick)
1432 WINE_CONFIG_EXTRA_DIR(dlls/dinput/keyboard)
1433 WINE_CONFIG_EXTRA_DIR(dlls/dinput/mouse)
1434 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1435 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1436 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1437 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1438 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1439 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1440 WINE_CONFIG_EXTRA_DIR(files)
1441 WINE_CONFIG_EXTRA_DIR(graphics)
1442 WINE_CONFIG_EXTRA_DIR(include/wine)
1443 WINE_CONFIG_EXTRA_DIR(misc)
1444 WINE_CONFIG_EXTRA_DIR(objects)
1445 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1446 WINE_CONFIG_EXTRA_DIR(windows)
1448 MAKE_RULES=Make.rules
1449 AC_SUBST_FILE(MAKE_RULES)
1451 MAKE_DLL_RULES=dlls/Makedll.rules
1452 AC_SUBST_FILE(MAKE_DLL_RULES)
1454 MAKE_TEST_RULES=dlls/Maketest.rules
1455 AC_SUBST_FILE(MAKE_TEST_RULES)
1457 MAKE_LIB_RULES=libs/Makelib.rules
1458 AC_SUBST_FILE(MAKE_LIB_RULES)
1460 MAKE_PROG_RULES=programs/Makeprog.rules
1461 AC_SUBST_FILE(MAKE_PROG_RULES)
1463 AC_CONFIG_FILES([
1464 Make.rules
1465 dlls/Makedll.rules
1466 dlls/Maketest.rules
1467 libs/Makelib.rules
1468 programs/Makeprog.rules
1469 Makefile
1470 dlls/Makefile
1471 dlls/advapi32/Makefile
1472 dlls/advapi32/tests/Makefile
1473 dlls/avicap32/Makefile
1474 dlls/avifil32/Makefile
1475 dlls/cabinet/Makefile
1476 dlls/capi2032/Makefile
1477 dlls/cfgmgr32/Makefile
1478 dlls/comcat/Makefile
1479 dlls/comctl32/Makefile
1480 dlls/comctl32/tests/Makefile
1481 dlls/commdlg/Makefile
1482 dlls/crtdll/Makefile
1483 dlls/crypt32/Makefile
1484 dlls/ctl3d/Makefile
1485 dlls/wined3d/Makefile
1486 dlls/d3d8/Makefile
1487 dlls/d3d9/Makefile
1488 dlls/d3dim/Makefile
1489 dlls/d3dx8/Makefile
1490 dlls/dciman32/Makefile
1491 dlls/ddraw/Makefile
1492 dlls/ddraw/tests/Makefile
1493 dlls/devenum/Makefile
1494 dlls/dinput/Makefile
1495 dlls/dinput8/Makefile
1496 dlls/dmband/Makefile
1497 dlls/dmcompos/Makefile
1498 dlls/dmime/Makefile
1499 dlls/dmloader/Makefile
1500 dlls/dmscript/Makefile
1501 dlls/dmstyle/Makefile
1502 dlls/dmsynth/Makefile
1503 dlls/dmusic/Makefile
1504 dlls/dmusic32/Makefile
1505 dlls/dplay/Makefile
1506 dlls/dplayx/Makefile
1507 dlls/dpnhpast/Makefile
1508 dlls/dsound/Makefile
1509 dlls/dsound/tests/Makefile
1510 dlls/gdi/Makefile
1511 dlls/gdi/tests/Makefile
1512 dlls/glu32/Makefile
1513 dlls/glut32/Makefile
1514 dlls/icmp/Makefile
1515 dlls/imagehlp/Makefile
1516 dlls/imm32/Makefile
1517 dlls/iphlpapi/Makefile
1518 dlls/iphlpapi/tests/Makefile
1519 dlls/kernel/Makefile
1520 dlls/kernel/tests/Makefile
1521 dlls/lzexpand/Makefile
1522 dlls/mapi32/Makefile
1523 dlls/mpr/Makefile
1524 dlls/msacm/Makefile
1525 dlls/msacm/imaadp32/Makefile
1526 dlls/msacm/msadp32/Makefile
1527 dlls/msacm/msg711/Makefile
1528 dlls/msacm/winemp3/Makefile
1529 dlls/msdmo/Makefile
1530 dlls/mshtml/Makefile
1531 dlls/msi/Makefile
1532 dlls/msimg32/Makefile
1533 dlls/msisys/Makefile
1534 dlls/msnet32/Makefile
1535 dlls/msvcrt/Makefile
1536 dlls/msvcrt/tests/Makefile
1537 dlls/msvcrt20/Makefile
1538 dlls/msvcrtd/Makefile
1539 dlls/msvideo/Makefile
1540 dlls/msvideo/msrle32/Makefile
1541 dlls/mswsock/Makefile
1542 dlls/netapi32/Makefile
1543 dlls/netapi32/tests/Makefile
1544 dlls/newdev/Makefile
1545 dlls/ntdll/Makefile
1546 dlls/ntdll/tests/Makefile
1547 dlls/odbc32/Makefile
1548 dlls/ole32/Makefile
1549 dlls/oleacc/Makefile
1550 dlls/oleaut32/Makefile
1551 dlls/oleaut32/tests/Makefile
1552 dlls/olecli/Makefile
1553 dlls/oledlg/Makefile
1554 dlls/olepro32/Makefile
1555 dlls/olesvr/Makefile
1556 dlls/opengl32/Makefile
1557 dlls/psapi/Makefile
1558 dlls/qcap/Makefile
1559 dlls/quartz/Makefile
1560 dlls/rasapi32/Makefile
1561 dlls/richedit/Makefile
1562 dlls/rpcrt4/Makefile
1563 dlls/rpcrt4/tests/Makefile
1564 dlls/serialui/Makefile
1565 dlls/setupapi/Makefile
1566 dlls/shdocvw/Makefile
1567 dlls/shell32/Makefile
1568 dlls/shell32/tests/Makefile
1569 dlls/shfolder/Makefile
1570 dlls/shlwapi/Makefile
1571 dlls/shlwapi/tests/Makefile
1572 dlls/snmpapi/Makefile
1573 dlls/sti/Makefile
1574 dlls/tapi32/Makefile
1575 dlls/ttydrv/Makefile
1576 dlls/twain/Makefile
1577 dlls/unicows/Makefile
1578 dlls/url/Makefile
1579 dlls/urlmon/Makefile
1580 dlls/urlmon/tests/Makefile
1581 dlls/user/Makefile
1582 dlls/user/tests/Makefile
1583 dlls/uxtheme/Makefile
1584 dlls/version/Makefile
1585 dlls/win32s/Makefile
1586 dlls/winaspi/Makefile
1587 dlls/winedos/Makefile
1588 dlls/wineps/Makefile
1589 dlls/wininet/Makefile
1590 dlls/wininet/tests/Makefile
1591 dlls/winmm/Makefile
1592 dlls/winmm/joystick/Makefile
1593 dlls/winmm/mcianim/Makefile
1594 dlls/winmm/mciavi/Makefile
1595 dlls/winmm/mcicda/Makefile
1596 dlls/winmm/mciseq/Makefile
1597 dlls/winmm/mciwave/Makefile
1598 dlls/winmm/midimap/Makefile
1599 dlls/winmm/tests/Makefile
1600 dlls/winmm/wavemap/Makefile
1601 dlls/winmm/winealsa/Makefile
1602 dlls/winmm/winearts/Makefile
1603 dlls/winmm/wineaudioio/Makefile
1604 dlls/winmm/winenas/Makefile
1605 dlls/winmm/winejack/Makefile
1606 dlls/winmm/wineoss/Makefile
1607 dlls/winnls/Makefile
1608 dlls/winsock/Makefile
1609 dlls/winsock/tests/Makefile
1610 dlls/winspool/Makefile
1611 dlls/winspool/tests/Makefile
1612 dlls/wintab32/Makefile
1613 dlls/wintrust/Makefile
1614 dlls/wow32/Makefile
1615 dlls/wsock32/Makefile
1616 dlls/x11drv/Makefile
1617 documentation/Makefile
1618 include/Makefile
1619 libs/Makefile
1620 libs/port/Makefile
1621 libs/unicode/Makefile
1622 libs/uuid/Makefile
1623 libs/wine/Makefile
1624 libs/wpp/Makefile
1625 loader/Makefile
1626 programs/Makefile
1627 programs/avitools/Makefile
1628 programs/clock/Makefile
1629 programs/cmdlgtst/Makefile
1630 programs/control/Makefile
1631 programs/expand/Makefile
1632 programs/notepad/Makefile
1633 programs/progman/Makefile
1634 programs/regedit/Makefile
1635 programs/regsvr32/Makefile
1636 programs/rpcss/Makefile
1637 programs/rundll32/Makefile
1638 programs/start/Makefile
1639 programs/uninstaller/Makefile
1640 programs/view/Makefile
1641 programs/wcmd/Makefile
1642 programs/wineboot/Makefile
1643 programs/winebrowser/Makefile
1644 programs/winecfg/Makefile
1645 programs/wineconsole/Makefile
1646 programs/winedbg/Makefile
1647 programs/winefile/Makefile
1648 programs/winemenubuilder/Makefile
1649 programs/winemine/Makefile
1650 programs/winepath/Makefile
1651 programs/winetest/Makefile
1652 programs/winevdm/Makefile
1653 programs/winhelp/Makefile
1654 programs/winver/Makefile
1655 server/Makefile
1656 tools/Makefile
1657 tools/widl/Makefile
1658 tools/winapi/Makefile
1659 tools/winebuild/Makefile
1660 tools/winedump/Makefile
1661 tools/winegcc/Makefile
1662 tools/wmc/Makefile
1663 tools/wrc/Makefile])
1665 AC_OUTPUT
1667 if test "$have_x" = "no"
1668 then
1669 echo
1670 echo "*** Warning: X development files not found. Wine will be built without"
1671 echo "*** X support, which currently does not work, and would probably not be"
1672 echo "*** what you want anyway. You will need to install devel packages of"
1673 echo "*** Xlib/Xfree86 at the very least."
1674 fi
1676 if test "$wine_cv_opengl_version_OK" = "no"
1677 then
1678 echo
1679 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1680 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1681 fi
1683 if test "$wine_cv_msg_freetype" = "yes"
1684 then
1685 echo
1686 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1687 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1688 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1689 echo "*** enable Wine to use TrueType fonts."
1690 fi
1692 echo
1693 echo "Configure finished. Do 'make depend && make' to compile Wine."
1694 echo
1696 dnl Local Variables:
1697 dnl comment-start: "dnl "
1698 dnl comment-end: ""
1699 dnl comment-start-skip: "\\bdnl\\b\\s *"
1700 dnl compile-command: "autoconf"
1701 dnl End: