aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl WINE_CHECK_HOST_TOOL(VARIABLE, PROG-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND], [PATH])
  26 dnl
  27 dnl Like AC_CHECK_TOOL but without the broken fallback to non-prefixed name
  28 dnl
  29 AC_DEFUN([WINE_CHECK_HOST_TOOL],
  30 [AS_VAR_SET_IF([ac_tool_prefix],
  31   AC_CHECK_PROG([$1],[${ac_tool_prefix}$2],[${ac_tool_prefix}$2],,[$4]))
  32 AS_VAR_IF([ac_cv_prog_$1],[],
  33   [AS_VAR_IF([cross_compiling],[yes],[],
  34     [AS_UNSET([ac_cv_prog_$1])
  35      AC_CHECK_PROG([$1],[$2],[$2],[$3],[$4])])],
  36 [AS_VAR_COPY([$1],[ac_cv_prog_$1])])])
  37
  38 dnl **** Initialize the programs used by other checks ****
  39 dnl
  40 dnl Usage: WINE_PATH_SONAME_TOOLS
  41 dnl Usage: WINE_PATH_PKG_CONFIG
  42 dnl
  43 AC_DEFUN([WINE_PATH_SONAME_TOOLS],
  44 [AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)
  45 AC_CHECK_TOOL(READELF,[readelf],true)])
  46
  47 AC_DEFUN([WINE_PATH_PKG_CONFIG],
  48 [WINE_CHECK_HOST_TOOL(PKG_CONFIG,[pkg-config])])
  49
  50 dnl **** Extract the soname of a library ****
  51 dnl
  52 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  53 dnl
  54 AC_DEFUN([WINE_CHECK_SONAME],
  55 [AC_REQUIRE([WINE_PATH_SONAME_TOOLS])dnl
  56 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  57 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  58 AC_MSG_CHECKING([for -l$1])
  59 AC_CACHE_VAL(ac_Lib,
  60 [ac_check_soname_save_LIBS=$LIBS
  61 LIBS="-l$1 $5 $LIBS"
  62   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  63   [case "$LIBEXT" in
  64     dll) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest.exe | grep "$1" | sed -e "s/dll.*/dll/"';2,$d'`]) ;;
  65     dylib) AS_VAR_SET(ac_Lib,[`otool -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  66     *) AS_VAR_SET(ac_Lib,[`$READELF -d conftest$ac_exeext | grep "NEEDED.*ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\\m4_dquote(\\(ac_lib_pattern\\.$LIBEXT[[^    ]]*\\)\\).*$/\1/"';2,$d'`])
  67        AS_VAR_IF([ac_Lib],[],
  68              [AS_VAR_SET(ac_Lib,[`$LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^  ]]*\).*$/\1/"';2,$d'`])]) ;;
  69   esac])
  70   LIBS=$ac_check_soname_save_LIBS])dnl
  71 AS_VAR_IF([ac_Lib],[],
  72       [AC_MSG_RESULT([not found])
  73        $4],
  74       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
  75        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
  76                           [Define to the soname of the lib$1 library.])
  77        $3])dnl
  78 m4_popdef([ac_lib_pattern])dnl
  79 AS_VAR_POPDEF([ac_Lib])])
  80
  81 dnl **** Get flags from pkg-config or alternate xxx-config program ****
  82 dnl
  83 dnl Usage: WINE_PACKAGE_FLAGS(var,pkg-name,[default-lib,[cflags-alternate,libs-alternate,[checks]]])
  84 dnl
  85 AC_DEFUN([WINE_PACKAGE_FLAGS],
  86 [AC_REQUIRE([WINE_PATH_PKG_CONFIG])dnl
  87 AS_VAR_PUSHDEF([ac_cflags],[[$1]_CFLAGS])dnl
  88 AS_VAR_PUSHDEF([ac_libs],[[$1]_LIBS])dnl
  89 AC_ARG_VAR(ac_cflags, [C compiler flags for $2, overriding pkg-config])dnl
  90 AS_VAR_IF([ac_cflags],[],
  91       [AS_VAR_SET_IF([PKG_CONFIG],
  92       [ac_cflags=`$PKG_CONFIG --cflags [$2] 2>/dev/null`])])
  93 m4_ifval([$4],[test "$cross_compiling" = yes || ac_cflags=[$]{ac_cflags:-[$4]}])
  94 AC_ARG_VAR(ac_libs, [Linker flags for $2, overriding pkg-config])dnl
  95 AS_VAR_IF([ac_libs],[],
  96       [AS_VAR_SET_IF([PKG_CONFIG],
  97       [ac_libs=`$PKG_CONFIG --libs [$2] 2>/dev/null`])])
  98 m4_ifval([$5],[test "$cross_compiling" = yes || ac_libs=[$]{ac_libs:-[$5]}])
  99 m4_ifval([$3],[ac_libs=[$]{ac_libs:-"$3"}])
 100 AS_ECHO(["$as_me:${as_lineno-$LINENO}: $2 cflags: $ac_cflags"]) >&AS_MESSAGE_LOG_FD
 101 AS_ECHO(["$as_me:${as_lineno-$LINENO}: $2 libs: $ac_libs"]) >&AS_MESSAGE_LOG_FD
 102 ac_save_CPPFLAGS=$CPPFLAGS
 103 CPPFLAGS="$CPPFLAGS $ac_cflags"
 104 $6
 105 CPPFLAGS=$ac_save_CPPFLAGS
 106 test -z "$ac_cflags" || ac_cflags=`echo " $ac_cflags" | sed 's/ -I\([[^/]]\)/ -I\$(top_builddir)\/\1/g'`
 107 test -z "$ac_libs" || ac_libs=`echo " $ac_libs" | sed 's/ -L\([[^/]]\)/ -L\$(top_builddir)\/\1/g'`
 108 AS_VAR_POPDEF([ac_libs])dnl
 109 AS_VAR_POPDEF([ac_cflags])])dnl
 110
 111 dnl **** Link C code with an assembly file ****
 112 dnl
 113 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
 114 dnl
 115 AC_DEFUN([WINE_TRY_ASM_LINK],
 116 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[$2]],[[asm($1); $3]])],[$4],[$5])])
 117
 118 dnl **** Check if we can link an empty program with special CFLAGS ****
 119 dnl
 120 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
 121 dnl
 122 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
 123 dnl
 124 AC_DEFUN([WINE_TRY_CFLAGS],
 125 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
 126 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
 127 [ac_wine_try_cflags_saved=$CFLAGS
 128 CFLAGS="$CFLAGS $1"
 129 AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv) { return 0; }]])],
 130                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
 131 CFLAGS=$ac_wine_try_cflags_saved])
 132 AS_VAR_IF([ac_var],[yes],[m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
 133 AS_VAR_POPDEF([ac_var])])
 134
 135 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
 136 dnl
 137 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
 138 dnl
 139 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
 140 [ac_wine_try_cflags_saved=$CFLAGS
 141 CFLAGS="$CFLAGS $1"
 142 AC_LINK_IFELSE([AC_LANG_SOURCE([void myfunc() {}])],[$2],[$3])
 143 CFLAGS=$ac_wine_try_cflags_saved])
 144
 145 dnl **** Check whether we need to define a symbol on the compiler command line ****
 146 dnl
 147 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
 148 dnl
 149 AC_DEFUN([WINE_CHECK_DEFINE],
 150 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 151 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 152     AC_EGREP_CPP(yes,[#ifndef $1
 153 yes
 154 #endif],
 155     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 156 AS_VAR_IF([ac_var],[yes],
 157       [CFLAGS="$CFLAGS -D$1"
 158   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 159 AS_VAR_POPDEF([ac_var])])
 160
 161 dnl **** Check for functions with some extra libraries ****
 162 dnl
 163 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 164 dnl
 165 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 166 [ac_wine_check_funcs_save_LIBS="$LIBS"
 167 LIBS="$LIBS $2"
 168 AC_CHECK_FUNCS([$1],[$3],[$4])
 169 LIBS="$ac_wine_check_funcs_save_LIBS"])
 170
 171 dnl **** Check for a mingw program, trying the various mingw prefixes ****
 172 dnl
 173 dnl Usage: WINE_CHECK_MINGW_PROG(variable,prog,[value-if-not-found],[path])
 174 dnl
 175 AC_DEFUN([WINE_CHECK_MINGW_PROG],
 176 [case "$host_cpu" in
 177   i[[3456789]]86*)
 178     ac_prefix_list="m4_foreach([ac_wine_prefix],[w64-mingw32, pc-mingw32, mingw32msvc, mingw32],
 179                         m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-ac_wine_prefix-$2 ]))
 180                         mingw32-$2" ;;
 181   x86_64)
 182     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32, w64-mingw32, mingw32msvc],
 183                         m4_foreach([ac_wine_cpu],[x86_64,amd64],[ac_wine_cpu-ac_wine_prefix-$2 ]))" ;;
 184   *)
 185     ac_prefix_list="" ;;
 186 esac
 187 AC_CHECK_PROGS([$1],[$ac_prefix_list],[$3],[$4])])
 188
 189
 190 dnl **** Define helper functions for creating config.status files ****
 191 dnl
 192 dnl Usage: AC_REQUIRE([WINE_CONFIG_HELPERS])
 193 dnl
 194 AC_DEFUN([WINE_CONFIG_HELPERS],
 195 [wine_rules_file=conf$$rules.make
 196 rm -f $wine_rules_file
 197 ALL_POT_FILES=""
 198 GITIGNORE="# Automatically generated by configure; DO NOT EDIT!!"
 199 AC_SUBST(ALL_TEST_RESOURCES,"")
 200
 201 wine_fn_append_file ()
 202 {
 203     AS_VAR_APPEND($[1]," \\$as_nl       $[2]")
 204 }
 205
 206 wine_fn_ignore_file ()
 207 {
 208     case "$[1]" in
 209       */*) AS_VAR_APPEND([GITIGNORE],"$as_nl$[1]") ;;
 210       \**) AS_VAR_APPEND([GITIGNORE],"$as_nl$[1]") ;;
 211       *)   AS_VAR_APPEND([GITIGNORE],"$as_nl/$[1]") ;;
 212     esac
 213 }
 214
 215 wine_fn_append_rule ()
 216 {
 217     AS_ECHO("$[1]") >>$wine_rules_file
 218 }
 219
 220 wine_fn_has_flag ()
 221 {
 222     expr ",$ac_flags," : ".*,$[1],.*" >/dev/null
 223 }
 224
 225 wine_fn_depend_rules ()
 226 {
 227     wine_fn_append_rule \
 228 "$ac_dir/Makefile: $srcdir/$ac_dir/Makefile.in $srcdir/Make.vars.in config.status \$(MAKEDEP)
 229         @./config.status --file $ac_dir/Makefile:Make.vars.in:$ac_dir/Makefile.in && \$(MAKEDEP) $ac_dir
 230 depend: $ac_dir/depend
 231 .PHONY: $ac_dir/depend
 232 $ac_dir/depend: \$(MAKEDEP) dummy
 233         @./config.status --file $ac_dir/Makefile:Make.vars.in:$ac_dir/Makefile.in && \$(MAKEDEP) $ac_dir"
 234 }
 235
 236 wine_fn_pot_rules ()
 237 {
 238     test "x$with_gettextpo" = xyes || return
 239
 240     if wine_fn_has_flag mc
 241     then
 242         wine_fn_append_file ALL_POT_FILES $ac_dir/msg.pot
 243         wine_fn_append_rule \
 244 "$ac_dir/msg.pot: $ac_dir/Makefile dummy
 245         @cd $ac_dir && \$(MAKE) msg.pot
 246 $ac_dir/msg.pot: tools/wmc include"
 247     fi
 248     if wine_fn_has_flag po
 249     then
 250         wine_fn_append_file ALL_POT_FILES $ac_dir/rsrc.pot
 251         wine_fn_append_rule \
 252 "$ac_dir/rsrc.pot: $ac_dir/Makefile dummy
 253         @cd $ac_dir && \$(MAKE) rsrc.pot
 254 $ac_dir/rsrc.pot: tools/wrc include"
 255     fi
 256 }
 257
 258 wine_fn_all_rules ()
 259 {
 260     wine_fn_depend_rules
 261     wine_fn_append_rule \
 262 "all: $ac_dir
 263 .PHONY: $ac_dir
 264 $ac_dir: $ac_dir/Makefile dummy
 265         @cd $ac_dir && \$(MAKE)"
 266 }
 267
 268 wine_fn_install_rules ()
 269 {
 270     wine_fn_has_flag install-lib || wine_fn_has_flag install-dev || return
 271
 272     wine_fn_append_rule \
 273 ".PHONY: $ac_dir/install $ac_dir/uninstall
 274 $ac_dir/install:: $ac_dir
 275         @cd $ac_dir && \$(MAKE) install
 276 $ac_dir/uninstall:: $ac_dir/Makefile
 277         @cd $ac_dir && \$(MAKE) uninstall
 278 install:: $ac_dir/install
 279 __uninstall__: $ac_dir/uninstall"
 280
 281     if wine_fn_has_flag install-lib
 282     then
 283         wine_fn_append_rule \
 284 ".PHONY: $ac_dir/install-lib
 285 $ac_dir/install-lib:: $ac_dir
 286         @cd $ac_dir && \$(MAKE) install-lib
 287 install-lib:: $ac_dir/install-lib"
 288     fi
 289
 290     if wine_fn_has_flag install-dev
 291     then
 292         wine_fn_append_rule \
 293 ".PHONY: $ac_dir/install-dev
 294 $ac_dir/install-dev:: $ac_dir
 295         @cd $ac_dir && \$(MAKE) install-dev
 296 install-dev:: $ac_dir/install-dev"
 297     fi
 298 }
 299
 300 wine_fn_clean_rules ()
 301 {
 302     ac_clean=$[@]
 303     ac_extraclean="$ac_dir/Makefile"
 304     test "$srcdir" = . && ac_extraclean="$ac_extraclean $ac_dir/.gitignore"
 305     case $ac_dir in
 306         */tests) ac_extraclean="$ac_extraclean $ac_dir/testlist.c" ;;
 307     esac
 308
 309     if wine_fn_has_flag clean
 310     then
 311         wine_fn_append_rule \
 312 "__clean__: $ac_dir/clean
 313 .PHONY: $ac_dir/clean
 314 $ac_dir/clean: $ac_dir/Makefile
 315         @cd $ac_dir && \$(MAKE) clean
 316         \$(RM) $ac_extraclean"
 317     else
 318         wine_fn_append_rule \
 319 "__clean__: $ac_dir/clean
 320 .PHONY: $ac_dir/clean
 321 $ac_dir/clean: dummy
 322         \$(RM) \$(CLEAN_FILES:%=$ac_dir/%) $ac_clean $ac_extraclean"
 323     fi
 324 }
 325
 326 wine_fn_disabled_rules ()
 327 {
 328     ac_clean=$[@]
 329     ac_extraclean="$ac_dir/Makefile"
 330     test "$srcdir" = . && ac_extraclean="$ac_extraclean $ac_dir/.gitignore"
 331
 332     wine_fn_append_rule \
 333 "__clean__: $ac_dir/clean
 334 .PHONY: $ac_dir/clean
 335 $ac_dir/clean: dummy
 336         \$(RM) \$(CLEAN_FILES:%=$ac_dir/%) $ac_clean $ac_extraclean"
 337 }
 338
 339 wine_fn_config_makefile ()
 340 {
 341     ac_dir=$[1]
 342     ac_enable=$[2]
 343     ac_flags=$[3]
 344
 345     AS_VAR_IF([$ac_enable],[no],[wine_fn_disabled_rules; return])
 346     wine_fn_all_rules
 347     wine_fn_install_rules
 348     wine_fn_clean_rules
 349 }
 350
 351 wine_fn_config_lib ()
 352 {
 353     ac_name=$[1]
 354     ac_flags=$[2]
 355     ac_dir=dlls/$ac_name
 356     ac_deps="include"
 357
 358     AS_VAR_IF([enable_tools],[no],,[ac_deps="tools/widl tools/winebuild tools/winegcc $ac_deps"])
 359     wine_fn_all_rules
 360     wine_fn_clean_rules
 361
 362     wine_fn_append_rule \
 363 ".PHONY: $ac_dir/install $ac_dir/uninstall
 364 $ac_dir/install:: $ac_dir
 365         \$(INSTALL_DATA) $ac_dir/lib$ac_name.a \$(DESTDIR)\$(dlldir)/lib$ac_name.a
 366 $ac_dir/uninstall::
 367         \$(RM) \$(DESTDIR)\$(dlldir)/lib$ac_name.a
 368 install install-dev:: $ac_dir/install
 369 __uninstall__: $ac_dir/uninstall
 370 __builddeps__: $ac_dir
 371 $ac_dir: $ac_deps"
 372 }
 373
 374 wine_fn_config_dll ()
 375 {
 376     ac_name=$[1]
 377     ac_dir=dlls/$ac_name
 378     ac_enable=$[2]
 379     ac_flags=$[3]
 380     ac_implib=${4:-$ac_name}
 381     ac_file=$ac_dir/lib$ac_implib
 382     ac_dll=$ac_name
 383     ac_deps="include"
 384     ac_implibflags=""
 385
 386     AS_VAR_IF([enable_tools],[no],,[ac_deps="tools/widl tools/winebuild tools/winegcc $ac_deps"])
 387     case $ac_name in
 388       *16) ac_implibflags=" -m16" ;;
 389       *.*) ;;
 390       *)   ac_dll=$ac_dll.dll ;;
 391     esac
 392
 393     ac_clean=
 394     wine_fn_has_flag implib && ac_clean="$ac_clean $ac_file.$IMPLIBEXT"
 395     wine_fn_has_flag mc && ac_clean="$ac_clean $ac_dir/msg.pot"
 396     wine_fn_has_flag po && ac_clean="$ac_clean $ac_dir/rsrc.pot"
 397     test -n "$DLLEXT" || ac_clean="$ac_clean $ac_dir/$ac_dll"
 398
 399     AS_VAR_IF([$ac_enable],[no],
 400               dnl enable_win16 is special in that it disables import libs too
 401               [if wine_fn_has_flag implib && test "$ac_enable" != enable_win16
 402                then
 403                    wine_fn_depend_rules
 404                    wine_fn_clean_rules $ac_clean
 405                else
 406                    wine_fn_disabled_rules $ac_clean
 407                    return
 408                fi],
 409
 410               [wine_fn_all_rules
 411                wine_fn_clean_rules $ac_clean
 412                wine_fn_append_rule \
 413 "$ac_dir: __builddeps__
 414 manpages htmlpages sgmlpages xmlpages:: $ac_dir/Makefile
 415         @cd $ac_dir && \$(MAKE) \$[@]
 416 .PHONY: $ac_dir/install-lib $ac_dir/uninstall
 417 install install-lib:: $ac_dir/install-lib
 418 __uninstall__: $ac_dir/uninstall"
 419                 if test -n "$DLLEXT"
 420                 then
 421                     wine_fn_append_rule \
 422 "$ac_dir/install-lib:: $ac_dir
 423         \$(INSTALL_PROGRAM) $ac_dir/$ac_dll$DLLEXT \$(DESTDIR)\$(dlldir)/$DLLPREFIX$ac_dll$DLLEXT
 424         \$(INSTALL_DATA) $ac_dir/$ac_dll.fake \$(DESTDIR)\$(fakedlldir)/$ac_dll
 425 $ac_dir/uninstall::
 426         \$(RM) \$(DESTDIR)\$(dlldir)/$DLLPREFIX$ac_dll$DLLEXT \$(DESTDIR)\$(fakedlldir)/$ac_dll"
 427                 else
 428                     wine_fn_append_rule \
 429 "$ac_dir/install-lib:: $ac_dir
 430         \$(INSTALL_PROGRAM) $ac_dir/$ac_dll \$(DESTDIR)\$(dlldir)/$ac_dll
 431 $ac_dir/uninstall::
 432         \$(RM) \$(DESTDIR)\$(dlldir)/$ac_dll"
 433                 fi
 434
 435                 wine_fn_pot_rules])
 436
 437     if wine_fn_has_flag staticimplib
 438     then
 439         wine_fn_append_rule \
 440 "__builddeps__: $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT
 441 $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: $ac_deps
 442 $ac_file.def: $srcdir/$ac_dir/$ac_name.spec $ac_dir/Makefile \$(WINEBUILD)
 443         \$(WINEBUILD) \$(TARGETFLAGS)$ac_implibflags -w --def -o \$[@] --export $srcdir/$ac_dir/$ac_name.spec
 444 $ac_file.$STATIC_IMPLIBEXT: $ac_dir/Makefile dummy
 445         @cd $ac_dir && \$(MAKE) lib$ac_implib.$STATIC_IMPLIBEXT
 446 .PHONY: $ac_dir/install-dev $ac_dir/uninstall
 447 $ac_dir/install-dev:: $ac_file.$IMPLIBEXT
 448         \$(INSTALL_DATA) $ac_file.$IMPLIBEXT \$(DESTDIR)\$(dlldir)/lib$ac_implib.$IMPLIBEXT
 449 $ac_dir/uninstall::
 450         \$(RM) \$(DESTDIR)\$(dlldir)/lib$ac_implib.$IMPLIBEXT
 451 install install-dev:: $ac_dir/install-dev
 452 __uninstall__: $ac_dir/uninstall"
 453
 454         if test "$IMPLIBEXT" != "$STATIC_IMPLIBEXT"
 455         then
 456             wine_fn_append_rule \
 457 "$ac_dir/install-dev:: $ac_file.$STATIC_IMPLIBEXT __builddeps__
 458         \$(INSTALL_DATA) $ac_file.$STATIC_IMPLIBEXT \$(DESTDIR)\$(dlldir)/lib$ac_implib.$STATIC_IMPLIBEXT
 459 $ac_dir/uninstall::
 460         \$(RM) \$(DESTDIR)\$(dlldir)/lib$ac_implib.$STATIC_IMPLIBEXT"
 461         fi
 462
 463         if test -n "$CROSSTARGET" -a -z "$ac_implibflags"
 464         then
 465             wine_fn_append_rule \
 466 "__builddeps__: $ac_file.cross.a
 467 $ac_file.cross.a: $ac_dir/Makefile dummy
 468         @cd $ac_dir && \$(MAKE) lib$ac_implib.cross.a"
 469         fi
 470
 471     elif wine_fn_has_flag implib
 472     then
 473         wine_fn_append_rule \
 474 "__builddeps__: $ac_file.$IMPLIBEXT
 475 $ac_file.def: $srcdir/$ac_dir/$ac_name.spec $ac_dir/Makefile \$(WINEBUILD)
 476         \$(WINEBUILD) \$(TARGETFLAGS)$ac_implibflags -w --def -o \$[@] --export $srcdir/$ac_dir/$ac_name.spec
 477 $ac_file.a: $srcdir/$ac_dir/$ac_name.spec $ac_dir/Makefile \$(WINEBUILD)
 478         \$(WINEBUILD) \$(TARGETFLAGS)$ac_implibflags -w --implib -o \$[@] --export $srcdir/$ac_dir/$ac_name.spec
 479 .PHONY: $ac_dir/install-dev $ac_dir/uninstall
 480 $ac_dir/install-dev:: $ac_file.$IMPLIBEXT
 481         \$(INSTALL_DATA) $ac_file.$IMPLIBEXT \$(DESTDIR)\$(dlldir)/lib$ac_implib.$IMPLIBEXT
 482 $ac_dir/uninstall::
 483         \$(RM) \$(DESTDIR)\$(dlldir)/lib$ac_implib.$IMPLIBEXT
 484 install install-dev:: $ac_dir/install-dev
 485 __uninstall__: $ac_dir/uninstall"
 486         if test -n "$CROSSTARGET" -a -z "$ac_implibflags"
 487         then
 488             wine_fn_append_rule \
 489 "__builddeps__: $ac_file.cross.a
 490 $ac_file.cross.a: $srcdir/$ac_dir/$ac_name.spec $ac_dir/Makefile \$(WINEBUILD)
 491         \$(WINEBUILD) \$(CROSSTARGET:%=-b %)$ac_implibflags -w --implib -o \$[@] --export $srcdir/$ac_dir/$ac_name.spec"
 492         fi
 493
 494         if test "$ac_name" != "$ac_implib"
 495         then
 496             wine_fn_append_rule \
 497 "__builddeps__: dlls/lib$ac_implib.$IMPLIBEXT
 498 dlls/lib$ac_implib.$IMPLIBEXT: $ac_file.$IMPLIBEXT
 499         \$(RM) \$[@] && \$(LN_S) $ac_name/lib$ac_implib.$IMPLIBEXT \$[@]
 500 clean::
 501         \$(RM) dlls/lib$ac_implib.$IMPLIBEXT"
 502             wine_fn_ignore_file "dlls/lib$ac_implib.$IMPLIBEXT"
 503             if test -n "$CROSSTARGET" -a -z "$ac_implibflags"
 504             then
 505                 wine_fn_append_rule \
 506 "__builddeps__: dlls/lib$ac_implib.cross.a
 507 dlls/lib$ac_implib.cross.a: $ac_file.cross.a
 508         \$(RM) \$[@] && \$(LN_S) $ac_name/lib$ac_implib.cross.a \$[@]
 509 clean::
 510         \$(RM) dlls/lib$ac_implib.cross.a"
 511                 wine_fn_ignore_file "dlls/lib$ac_implib.cross.a"
 512             fi
 513         fi
 514     fi
 515 }
 516
 517 wine_fn_config_program ()
 518 {
 519     ac_name=$[1]
 520     ac_dir=programs/$ac_name
 521     ac_enable=$[2]
 522     ac_flags=$[3]
 523     ac_program=$ac_name
 524
 525     case $ac_name in
 526       *.*) ;;
 527       *)   ac_program=$ac_program.exe ;;
 528     esac
 529
 530     ac_clean=
 531     wine_fn_has_flag mc && ac_clean="$ac_clean $ac_dir/msg.pot"
 532     wine_fn_has_flag po && ac_clean="$ac_clean $ac_dir/rsrc.pot"
 533     wine_fn_has_flag manpage && ac_clean="$ac_clean $ac_dir/$ac_name.man"
 534     test -n "$DLLEXT" || ac_clean="$ac_clean $ac_dir/$ac_program"
 535
 536     AS_VAR_IF([$ac_enable],[no],[wine_fn_disabled_rules $ac_clean; return])
 537
 538     wine_fn_all_rules
 539     wine_fn_clean_rules $ac_clean
 540     wine_fn_append_rule "$ac_dir: __builddeps__"
 541     wine_fn_pot_rules
 542
 543     wine_fn_has_flag install || return
 544     wine_fn_append_rule \
 545 ".PHONY: $ac_dir/install $ac_dir/uninstall
 546 install install-lib:: $ac_dir/install
 547 __uninstall__: $ac_dir/uninstall"
 548
 549     if test -n "$DLLEXT"
 550     then
 551         wine_fn_append_rule \
 552 "$ac_dir/install:: $ac_dir
 553         \$(INSTALL_PROGRAM) $ac_dir/$ac_program$DLLEXT \$(DESTDIR)\$(dlldir)/$DLLPREFIX$ac_program$DLLEXT
 554         \$(INSTALL_DATA) $ac_dir/$ac_program.fake \$(DESTDIR)\$(fakedlldir)/$ac_program
 555 $ac_dir/uninstall::
 556         \$(RM) \$(DESTDIR)\$(dlldir)/$DLLPREFIX$ac_program$DLLEXT \$(DESTDIR)\$(fakedlldir)/$ac_program"
 557
 558         if test -z "$with_wine64" && wine_fn_has_flag installbin
 559         then
 560             wine_fn_append_rule \
 561 "$ac_dir/install:: __tooldeps__
 562         \$(INSTALL_SCRIPT) \$(TOOLSDIR)/tools/wineapploader \$(DESTDIR)\$(bindir)/$ac_name
 563 $ac_dir/uninstall::
 564         \$(RM) \$(DESTDIR)\$(bindir)/$ac_name"
 565         fi
 566     else
 567         wine_fn_append_rule \
 568 "$ac_dir/install:: $ac_dir
 569         \$(INSTALL_PROGRAM) $ac_dir/$ac_program \$(DESTDIR)\$(bindir)/$ac_program
 570 $ac_dir/uninstall::
 571         \$(RM) \$(DESTDIR)\$(bindir)/$ac_program"
 572     fi
 573
 574     if test -z "$with_wine64" && wine_fn_has_flag manpage
 575     then
 576         wine_fn_append_rule \
 577 "$ac_dir/install:: $ac_dir
 578         \$(INSTALL_DATA) $ac_dir/$ac_name.man \$(DESTDIR)\$(mandir)/man\$(prog_manext)/$ac_name.\$(prog_manext)
 579 $ac_dir/uninstall::
 580         \$(RM) \$(DESTDIR)\$(mandir)/man\$(prog_manext)/$ac_name.\$(prog_manext)"
 581     fi
 582 }
 583
 584 wine_fn_config_test ()
 585 {
 586     ac_dir=$[1]
 587     ac_name=$[2]
 588     ac_flags=$[3]
 589
 590     ac_clean=
 591     test -n "$CROSSTARGET" && ac_clean=`expr $ac_dir/${ac_name} : "\\(.*\\)_test"`_crosstest.exe
 592     test -n "$DLLEXT" || ac_clean="$ac_dir/${ac_name}.exe $ac_dir/${ac_name}-stripped.exe"
 593
 594     AS_VAR_IF([enable_tests],[no],[wine_fn_disabled_rules $ac_clean; return])
 595
 596     wine_fn_append_file ALL_TEST_RESOURCES $ac_name.res
 597     wine_fn_all_rules
 598     wine_fn_clean_rules $ac_clean
 599
 600     wine_fn_append_rule \
 601 "$ac_dir: programs/winetest/Makefile __builddeps__
 602 programs/winetest: $ac_dir
 603 check test: $ac_dir/test
 604 .PHONY: $ac_dir/test
 605 $ac_dir/test: dummy
 606         @cd $ac_dir && \$(MAKE) test
 607 testclean::
 608         \$(RM) $ac_dir/*.ok"
 609
 610         if test -n "$CROSSTARGET"
 611         then
 612             wine_fn_append_rule \
 613 "crosstest: $ac_dir/crosstest
 614 .PHONY: $ac_dir/crosstest
 615 $ac_dir/crosstest: $ac_dir/Makefile __builddeps__ dummy
 616         @cd $ac_dir && \$(MAKE) crosstest"
 617         fi
 618 }
 619
 620 wine_fn_config_tool ()
 621 {
 622     ac_dir=$[1]
 623     ac_flags=$[2]
 624     AS_VAR_IF([enable_tools],[no],[return])
 625
 626     wine_fn_all_rules
 627     wine_fn_install_rules
 628     wine_fn_clean_rules
 629
 630     wine_fn_append_rule "__tooldeps__: $ac_dir"
 631     wine_fn_append_rule "$ac_dir: libs/port"
 632     case $ac_dir in
 633       tools/winebuild) wine_fn_append_rule "\$(WINEBUILD): $ac_dir" ;;
 634     esac
 635 }
 636
 637 wine_fn_config_symlink ()
 638 {
 639     ac_linkdir=
 640     if test "x$[1]" = "x-d"
 641     then
 642         ac_linkdir=$[2]
 643         shift; shift
 644     fi
 645     ac_links=$[@]
 646     wine_fn_append_rule \
 647 "$ac_links:
 648         @./config.status \$[@]
 649 distclean::
 650         \$(RM) $ac_links"
 651     for f in $ac_links; do wine_fn_ignore_file $f; done
 652     test -n "$ac_linkdir" || return
 653     wine_fn_append_rule "$ac_linkdir/Makefile $ac_linkdir/depend: $ac_links"
 654 }])
 655
 656 dnl **** Define helper function to append a file to a makefile file list ****
 657 dnl
 658 dnl Usage: WINE_APPEND_FILE(var,file)
 659 dnl
 660 AC_DEFUN([WINE_APPEND_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_file $1 "$2"])
 661
 662 dnl **** Define helper function to append a rule to a makefile command list ****
 663 dnl
 664 dnl Usage: WINE_APPEND_RULE(rule)
 665 dnl
 666 AC_DEFUN([WINE_APPEND_RULE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_rule "$1"])
 667
 668 dnl **** Create symlinks from config.status ****
 669 dnl
 670 dnl Usage: WINE_CONFIG_SYMLINK(target,src,files,enable,srcfile)
 671 dnl
 672 AC_DEFUN([WINE_CONFIG_SYMLINK],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 673 m4_ifval([$4],[if test "x$[$4]" != xno; then
 674 ])m4_foreach([f],[$3],
 675 [AC_CONFIG_LINKS(m4_ifval([$1],[$1/])f[:]m4_ifval([$2],[$2/])m4_ifval([$5],[$5],f))])dnl
 676 m4_if([$1],[$2],[test "$srcdir" = "." || ])dnl
 677 wine_fn_config_symlink[]m4_if([$1],[$2],,m4_ifval([$1],[ -d $1]))[]m4_foreach([f],[$3],[ ]m4_ifval([$1],[$1/])f)m4_ifval([$4],[
 678 fi])[]dnl
 679 ])])
 680
 681 dnl **** Create a makefile from config.status ****
 682 dnl
 683 dnl Usage: WINE_CONFIG_MAKEFILE(file,enable,flags)
 684 dnl
 685 AC_DEFUN([WINE_CONFIG_MAKEFILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 686 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 687 m4_append_uniq([_AC_USER_OPTS],ac_enable,[
 688 ])dnl
 689 wine_fn_config_makefile [$1] ac_enable [$3]dnl
 690 AS_VAR_POPDEF([ac_enable])])
 691
 692 dnl **** Create a dll makefile from config.status ****
 693 dnl
 694 dnl Usage: WINE_CONFIG_DLL(name,enable,flags,implib)
 695 dnl
 696 AC_DEFUN([WINE_CONFIG_DLL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 697 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 698 m4_append_uniq([_AC_USER_OPTS],ac_enable,[
 699 ])dnl
 700 wine_fn_config_dll [$1] ac_enable [$3] [$4]dnl
 701 AS_VAR_POPDEF([ac_enable])])
 702
 703 dnl **** Create a program makefile from config.status ****
 704 dnl
 705 dnl Usage: WINE_CONFIG_PROGRAM(name,enable,flags)
 706 dnl
 707 AC_DEFUN([WINE_CONFIG_PROGRAM],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 708 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 709 m4_append_uniq([_AC_USER_OPTS],ac_enable,[
 710 ])dnl
 711 wine_fn_config_program [$1] ac_enable [$3]dnl
 712 AS_VAR_POPDEF([ac_enable])])
 713
 714 dnl **** Create a test makefile from config.status ****
 715 dnl
 716 dnl Usage: WINE_CONFIG_TEST(dir,flags)
 717 dnl
 718 AC_DEFUN([WINE_CONFIG_TEST],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 719 m4_pushdef([ac_suffix],m4_if(m4_substr([$1],0,9),[programs/],[.exe_test],[_test]))dnl
 720 m4_pushdef([ac_name],[m4_bpatsubst([$1],[.*/\(.*\)/tests$],[\1])])dnl
 721 wine_fn_config_test $1 ac_name[]ac_suffix [$2]dnl
 722 m4_popdef([ac_suffix])dnl
 723 m4_popdef([ac_name])])
 724
 725 dnl **** Create a static lib makefile from config.status ****
 726 dnl
 727 dnl Usage: WINE_CONFIG_LIB(name,flags)
 728 dnl
 729 AC_DEFUN([WINE_CONFIG_LIB],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 730 wine_fn_config_lib [$1] [$2]])
 731
 732 dnl **** Create a tool makefile from config.status ****
 733 dnl
 734 dnl Usage: WINE_CONFIG_TOOL(name,flags)
 735 dnl
 736 AC_DEFUN([WINE_CONFIG_TOOL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 737 m4_append_uniq([_AC_USER_OPTS],[enable_tools],[
 738 ])dnl
 739 wine_fn_config_tool [$1] [$2]])
 740
 741 dnl **** Append a file to the .gitignore list ****
 742 dnl
 743 dnl Usage: WINE_IGNORE_FILE(file,enable)
 744 dnl
 745 AC_DEFUN([WINE_IGNORE_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 746 m4_ifval([$2],[test "x$[$2]" = xno || ])wine_fn_ignore_file $1])
 747
 748 dnl **** Add a message to the list displayed at the end ****
 749 dnl
 750 dnl Usage: WINE_NOTICE(notice)
 751 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice)
 752 dnl Usage: WINE_WARNING(warning)
 753 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning)
 754 dnl Usage: WINE_PRINT_MESSAGES
 755 dnl
 756 AC_DEFUN([WINE_NOTICE],[AS_VAR_APPEND([wine_notices],["|$1"])])
 757 AC_DEFUN([WINE_WARNING],[AS_VAR_APPEND([wine_warnings],["|$1"])])
 758
 759 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 760   x)   WINE_NOTICE([$3]) ;;
 761   xno) ;;
 762   *)   AC_MSG_ERROR([$3
 763 This is an error since --with-$1 was requested.]) ;;
 764 esac])])
 765
 766 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 767   x)   WINE_WARNING([$3]) ;;
 768   xno) ;;
 769   *)   AC_MSG_ERROR([$3
 770 This is an error since --with-$1 was requested.]) ;;
 771 esac])])
 772
 773 AC_DEFUN([WINE_ERROR_WITH],[AS_IF([$2],[case "x$with_$1" in
 774   xno) ;;
 775   *)   AC_MSG_ERROR([$3
 776 Use the --without-$1 option if you really want this.]) ;;
 777 esac])])
 778
 779 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 780 if test "x$wine_notices != "x; then
 781     echo >&AS_MESSAGE_FD
 782     IFS="|"
 783     for msg in $wine_notices; do
 784         IFS="$ac_save_IFS"
 785         AS_VAR_IF([msg],[],,[AC_MSG_NOTICE([$msg])])
 786     done
 787 fi
 788 IFS="|"
 789 for msg in $wine_warnings; do
 790     IFS="$ac_save_IFS"
 791     AS_VAR_IF([msg],[],,[echo >&2
 792         AC_MSG_WARN([$msg])])
 793 done
 794 IFS="$ac_save_IFS"])
 795
 796 dnl Local Variables:
 797 dnl compile-command: "autoreconf --warnings=all"
 798 dnl End: