?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
msvcrt: Added _fseeki64_nolock implementation.
[wine.git] / programs / winedbg / dbg.y
blob61acb909bfa3127c0a801e57ca4c7f40c242c98b
1 %{
2 /*
3 * Parser for command lines in the Wine debugger
4 *
5 * Copyright 1993 Eric Youngdale
6 * Copyright 1995 Morten Welinder
7 * Copyright 2000 Eric Pouech
8 *
9 * This library is free software; you can redistribute it and/or
10 * modify it under the terms of the GNU Lesser General Public
11 * License as published by the Free Software Foundation; either
12 * version 2.1 of the License, or (at your option) any later version.
13 *
14 * This library is distributed in the hope that it will be useful,
15 * but WITHOUT ANY WARRANTY; without even the implied warranty of
16 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
17 * Lesser General Public License for more details.
18 *
19 * You should have received a copy of the GNU Lesser General Public
20 * License along with this library; if not, write to the Free Software
21 * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
22 */
23
24 #include "config.h"
25 #include "wine/port.h"
26
27 #include <stdio.h>
28 #include <stdlib.h>
29 #include <string.h>
30
31 #include "debugger.h"
32 #include "wine/exception.h"
33 #include "expr.h"
34
35 int dbg_lex(void);
36 static int dbg_error(const char*);
37 static void parser(const char*);
38
39 %}
40
41 %union
42 {
43 struct dbg_lvalue lvalue;
44 char* string;
45 INT_PTR integer;
46 IMAGEHLP_LINE64 listing;
47 struct expr* expression;
48 struct type_expr_t type;
49 }
50
51 %token tCONT tPASS tSTEP tLIST tNEXT tQUIT tHELP tBACKTRACE tALL tINFO tUP tDOWN
52 %token tENABLE tDISABLE tBREAK tHBREAK tWATCH tRWATCH tDELETE tSET tPRINT tEXAM
53 %token tABORT tECHO
54 %token tCLASS tMAPS tSTACK tSEGMENTS tSYMBOL tREGS tALLREGS tWND tLOCAL tEXCEPTION
55 %token tPROCESS tTHREAD tEOL tEOF
56 %token tFRAME tSHARE tMODULE tCOND tDISPLAY tUNDISPLAY tDISASSEMBLE
57 %token tSTEPI tNEXTI tFINISH tSHOW tDIR tWHATIS tSOURCE
58 %token <string> tPATH tIDENTIFIER tSTRING tINTVAR
59 %token <integer> tNUM tFORMAT
60 %token tSYMBOLFILE tRUN tATTACH tDETACH tKILL tMAINTENANCE tTYPE tMINIDUMP
61 %token tNOPROCESS
62
63 %token tCHAR tSHORT tINT tLONG tFLOAT tDOUBLE tUNSIGNED tSIGNED
64 %token tSTRUCT tUNION tENUM
65
66 /* %left ',' */
67 /* %left '=' OP_OR_EQUAL OP_XOR_EQUAL OP_AND_EQUAL OP_SHL_EQUAL \
68 OP_SHR_EQUAL OP_PLUS_EQUAL OP_MINUS_EQUAL \
69 OP_TIMES_EQUAL OP_DIVIDE_EQUAL OP_MODULO_EQUAL */
70 /* %left OP_COND */ /* ... ? ... : ... */
71 %left OP_LOR
72 %left OP_LAND
73 %left '|'
74 %left '^'
75 %left '&'
76 %left OP_EQ OP_NE
77 %left '<' '>' OP_LE OP_GE
78 %left OP_SHL OP_SHR
79 %left '+' '-'
80 %left '*' '/' '%'
81 %left OP_SIGN '!' '~' OP_DEREF /* OP_INC OP_DEC OP_ADDR */
82 %left '.' '[' OP_DRF OP_SCOPE
83 %nonassoc ':'
84
85 %type <expression> expr lvalue
86 %type <lvalue> expr_lvalue lvalue_addr
87 %type <integer> expr_rvalue
88 %type <string> pathname identifier cpp_identifier
89 %type <listing> list_arg
90 %type <type> type_expr
91
92 %%
93
94 input:
95 line
96 | input line
97 ;
98
99 line:
100 command tEOL { expr_free_all(); }
101 | tEOL
102 | tEOF { return 1; }
103 | error tEOL { yyerrok; expr_free_all(); }
104 ;
105
106 command:
107 tQUIT { return 1; }
108 | tHELP { print_help(); }
109 | tHELP tINFO { info_help(); }
110 | tPASS { dbg_wait_next_exception(DBG_EXCEPTION_NOT_HANDLED, 0, 0); }
111 | tCONT { dbg_wait_next_exception(DBG_CONTINUE, 1, dbg_exec_cont); }
112 | tCONT tNUM { dbg_wait_next_exception(DBG_CONTINUE, $2, dbg_exec_cont); }
113 | tSTEP { dbg_wait_next_exception(DBG_CONTINUE, 1, dbg_exec_step_into_line); }
114 | tSTEP tNUM { dbg_wait_next_exception(DBG_CONTINUE, $2, dbg_exec_step_into_line); }
115 | tNEXT { dbg_wait_next_exception(DBG_CONTINUE, 1, dbg_exec_step_over_line); }
116 | tNEXT tNUM { dbg_wait_next_exception(DBG_CONTINUE, $2, dbg_exec_step_over_line); }
117 | tSTEPI { dbg_wait_next_exception(DBG_CONTINUE, 1, dbg_exec_step_into_insn); }
118 | tSTEPI tNUM { dbg_wait_next_exception(DBG_CONTINUE, $2, dbg_exec_step_into_insn); }
119 | tNEXTI { dbg_wait_next_exception(DBG_CONTINUE, 1, dbg_exec_step_over_insn); }
120 | tNEXTI tNUM { dbg_wait_next_exception(DBG_CONTINUE, $2, dbg_exec_step_over_insn); }
121 | tFINISH { dbg_wait_next_exception(DBG_CONTINUE, 0, dbg_exec_finish); }
122 | tABORT { abort(); }
123 | tBACKTRACE { stack_backtrace(dbg_curr_tid); }
124 | tBACKTRACE tNUM { stack_backtrace($2); }
125 | tBACKTRACE tALL { stack_backtrace(-1); }
126 | tUP { stack_set_frame(dbg_curr_thread->curr_frame + 1); }
127 | tUP tNUM { stack_set_frame(dbg_curr_thread->curr_frame + $2); }
128 | tDOWN { stack_set_frame(dbg_curr_thread->curr_frame - 1); }
129 | tDOWN tNUM { stack_set_frame(dbg_curr_thread->curr_frame - $2); }
130 | tFRAME tNUM { stack_set_frame($2); }
131 | tSHOW tDIR { source_show_path(); }
132 | tDIR pathname { source_add_path($2); }
133 | tDIR { source_nuke_path(dbg_curr_process); }
134 | tCOND tNUM { break_add_condition($2, NULL); }
135 | tCOND tNUM expr { break_add_condition($2, $3); }
136 | tSOURCE pathname { parser($2); }
137 | tSYMBOLFILE pathname { symbol_read_symtable($2, 0); }
138 | tSYMBOLFILE pathname expr_rvalue { symbol_read_symtable($2, $3); }
139 | tWHATIS expr_lvalue { dbg_printf("type = "); types_print_type(&$2.type, FALSE); dbg_printf("\n"); }
140 | tATTACH tNUM { dbg_attach_debuggee($2, FALSE); dbg_active_wait_for_first_exception(); }
141 | tDETACH { dbg_curr_process->process_io->close_process(dbg_curr_process, FALSE); }
142 | tKILL { dbg_curr_process->process_io->close_process(dbg_curr_process, TRUE); }
143 | tMINIDUMP pathname { minidump_write($2, (dbg_curr_thread && dbg_curr_thread->in_exception) ? &dbg_curr_thread->excpt_record : NULL);}
144 | tECHO tSTRING { dbg_printf("%s\n", $2); }
145 | run_command
146 | list_command
147 | disassemble_command
148 | set_command
149 | x_command
150 | print_command
151 | break_command
152 | watch_command
153 | display_command
154 | info_command
155 | maintenance_command
156 | noprocess_state
157 ;
158
159 pathname:
160 identifier { $$ = $1; }
161 | tSTRING { $$ = $1; }
162 | tPATH { $$ = $1; }
163 ;
164
165 cpp_identifier:
166 tIDENTIFIER { $$ = $1; }
167 | identifier OP_SCOPE tIDENTIFIER { $$ = lexeme_alloc_size(strlen($1) + 2 + strlen($3) + 1);
168 sprintf($$, "%s::%s", $1, $3); }
169 ;
170
171 identifier:
172 cpp_identifier { $$ = $1; }
173 | tIDENTIFIER '!' cpp_identifier { $$ = lexeme_alloc_size(strlen($1) + 1 + strlen($3) + 1);
174 sprintf($$, "%s!%s", $1, $3); }
175 ;
176
177 list_arg:
178 tNUM { $$.FileName = NULL; $$.LineNumber = $1; }
179 | pathname ':' tNUM { $$.FileName = $1; $$.LineNumber = $3; }
180 | identifier { symbol_get_line(NULL, $1, &$$); }
181 | pathname ':' identifier { symbol_get_line($1, $3, &$$); }
182 | '*' expr_lvalue { DWORD disp; ADDRESS64 addr; $$.SizeOfStruct = sizeof($$);
183 types_extract_as_address(&$2, &addr);
184 SymGetLineFromAddr64(dbg_curr_process->handle, (ULONG_PTR)memory_to_linear_addr(& addr), &disp, & $$); }
185 ;
186
187 run_command:
188 tRUN { dbg_run_debuggee(NULL); }
189 | tRUN tSTRING { dbg_run_debuggee($2); }
190 ;
191
192 list_command:
193 tLIST { source_list(NULL, NULL, 10); }
194 | tLIST '-' { source_list(NULL, NULL, -10); }
195 | tLIST list_arg { source_list(& $2, NULL, 10); }
196 | tLIST ',' list_arg { source_list(NULL, & $3, -10); }
197 | tLIST list_arg ',' list_arg { source_list(& $2, & $4, 0); }
198 ;
199
200 disassemble_command:
201 tDISASSEMBLE { memory_disassemble(NULL, NULL, 10); }
202 | tDISASSEMBLE expr_lvalue { memory_disassemble(&$2, NULL, 10); }
203 | tDISASSEMBLE expr_lvalue ',' expr_lvalue { memory_disassemble(&$2, &$4, 0); }
204 ;
205
206 set_command:
207 tSET lvalue_addr '=' expr_lvalue { types_store_value(&$2, &$4); }
208 | tSET '+' tIDENTIFIER { info_wine_dbg_channel(TRUE, NULL, $3); }
209 | tSET '+' tALL { info_wine_dbg_channel(TRUE, NULL, "all"); }
210 | tSET '-' tIDENTIFIER { info_wine_dbg_channel(FALSE, NULL, $3); }
211 | tSET '-' tALL { info_wine_dbg_channel(FALSE, NULL, "all"); }
212 | tSET tIDENTIFIER '+' tIDENTIFIER { info_wine_dbg_channel(TRUE, $2, $4); }
213 | tSET tIDENTIFIER '+' tALL { info_wine_dbg_channel(TRUE, $2, "all"); }
214 | tSET tIDENTIFIER '-' tIDENTIFIER { info_wine_dbg_channel(FALSE, $2, $4); }
215 | tSET tIDENTIFIER '-' tALL { info_wine_dbg_channel(FALSE, $2, "all"); }
216 | tSET '!' tIDENTIFIER tIDENTIFIER { dbg_set_option($3, $4); }
217 | tSET '!' tIDENTIFIER { dbg_set_option($3, NULL); }
218 ;
219
220 x_command:
221 tEXAM expr_lvalue { memory_examine(&$2, 1, 'x'); }
222 | tEXAM tFORMAT expr_lvalue { memory_examine(&$3, $2 >> 8, $2 & 0xff); }
223 ;
224
225 print_command:
226 tPRINT expr_lvalue { print_value(&$2, 0, 0); }
227 | tPRINT tFORMAT expr_lvalue { if (($2 >> 8) == 1) print_value(&$3, $2 & 0xff, 0); else dbg_printf("Count is meaningless in print command\n"); }
228 ;
229
230 break_command:
231 tBREAK '*' expr_lvalue { break_add_break_from_lvalue(&$3, TRUE); }
232 | tBREAK identifier { break_add_break_from_id($2, -1, TRUE); }
233 | tBREAK pathname ':' tNUM { break_add_break_from_lineno($2, $4, TRUE); }
234 | tBREAK tNUM { break_add_break_from_lineno(NULL, $2, TRUE); }
235 | tBREAK { break_add_break_from_lineno(NULL, -1, TRUE); }
236 | tHBREAK '*' expr_lvalue { break_add_break_from_lvalue(&$3, FALSE); }
237 | tHBREAK identifier { break_add_break_from_id($2, -1, FALSE); }
238 | tHBREAK pathname ':' tNUM { break_add_break_from_lineno($2, $4, FALSE); }
239 | tHBREAK tNUM { break_add_break_from_lineno(NULL, $2, FALSE); }
240 | tHBREAK { break_add_break_from_lineno(NULL, -1, FALSE); }
241 | tENABLE tNUM { break_enable_xpoint($2, TRUE); }
242 | tENABLE tBREAK tNUM { break_enable_xpoint($3, TRUE); }
243 | tDISABLE tNUM { break_enable_xpoint($2, FALSE); }
244 | tDISABLE tBREAK tNUM { break_enable_xpoint($3, FALSE); }
245 | tDELETE tNUM { break_delete_xpoint($2); }
246 | tDELETE tBREAK tNUM { break_delete_xpoint($3); }
247 ;
248
249 watch_command:
250 tWATCH '*' expr_lvalue { break_add_watch_from_lvalue(&$3, TRUE); }
251 | tWATCH identifier { break_add_watch_from_id($2, TRUE); }
252 | tRWATCH '*' expr_lvalue { break_add_watch_from_lvalue(&$3, FALSE); }
253 | tRWATCH identifier { break_add_watch_from_id($2, FALSE); }
254 ;
255
256
257 display_command:
258 tDISPLAY { display_print(); }
259 | tDISPLAY expr { display_add($2, 1, 0); }
260 | tDISPLAY tFORMAT expr { display_add($3, $2 >> 8, $2 & 0xff); }
261 | tENABLE tDISPLAY tNUM { display_enable($3, TRUE); }
262 | tDISABLE tDISPLAY tNUM { display_enable($3, FALSE); }
263 | tDELETE tDISPLAY tNUM { display_delete($3); }
264 | tDELETE tDISPLAY { display_delete(-1); }
265 | tUNDISPLAY tNUM { display_delete($2); }
266 | tUNDISPLAY { display_delete(-1); }
267 ;
268
269 info_command:
270 tINFO tBREAK { break_info(); }
271 | tINFO tSHARE { info_win32_module(0); }
272 | tINFO tSHARE expr_rvalue { info_win32_module($3); }
273 | tINFO tREGS { be_cpu->print_context(dbg_curr_thread->handle, &dbg_context, 0); }
274 | tINFO tALLREGS { be_cpu->print_context(dbg_curr_thread->handle, &dbg_context, 1); }
275 | tINFO tSEGMENTS expr_rvalue { info_win32_segments($3 >> 3, 1); }
276 | tINFO tSEGMENTS { info_win32_segments(0, -1); }
277 | tINFO tSTACK tNUM { stack_info($3); }
278 | tINFO tSTACK { stack_info(-1); }
279 | tINFO tSYMBOL tSTRING { symbol_info($3); }
280 | tINFO tLOCAL { symbol_info_locals(); }
281 | tINFO tDISPLAY { display_info(); }
282 | tINFO tCLASS { info_win32_class(NULL, NULL); }
283 | tINFO tCLASS tSTRING { info_win32_class(NULL, $3); }
284 | tINFO tWND { info_win32_window(NULL, FALSE); }
285 | tINFO tWND expr_rvalue { info_win32_window((HWND)$3, FALSE); }
286 | tINFO '*' tWND { info_win32_window(NULL, TRUE); }
287 | tINFO '*' tWND expr_rvalue { info_win32_window((HWND)$4, TRUE); }
288 | tINFO tPROCESS { info_win32_processes(); }
289 | tINFO tTHREAD { info_win32_threads(); }
290 | tINFO tFRAME { info_win32_frame_exceptions(dbg_curr_tid); }
291 | tINFO tFRAME expr_rvalue { info_win32_frame_exceptions($3); }
292 | tINFO tMAPS { info_win32_virtual(dbg_curr_pid); }
293 | tINFO tMAPS expr_rvalue { info_win32_virtual($3); }
294 | tINFO tEXCEPTION { info_win32_exception(); }
295 ;
296
297 maintenance_command:
298 tMAINTENANCE tTYPE { print_types(); }
299 | tMAINTENANCE tMODULE tSTRING { tgt_module_load($3, FALSE); }
300 | tMAINTENANCE '*' tMODULE tSTRING { tgt_module_load($4, TRUE); }
301 ;
302
303 noprocess_state:
304 tNOPROCESS {} /* <CR> shall not barf anything */
305 | tNOPROCESS tBACKTRACE tALL { stack_backtrace(-1); } /* can backtrace all threads with no attached process */
306 | tNOPROCESS tSTRING { dbg_printf("No process loaded, cannot execute '%s'\n", $2); }
307 ;
308
309 type_expr:
310 tCHAR { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_char; }
311 | tINT { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_int; }
312 | tLONG tINT { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_long_int; }
313 | tLONG { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_long_int; }
314 | tUNSIGNED tINT { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_int; }
315 | tUNSIGNED { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_int; }
316 | tLONG tUNSIGNED tINT { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_long_int; }
317 | tLONG tUNSIGNED { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_long_int; }
318 | tSHORT tINT { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_short_int; }
319 | tSHORT { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_short_int; }
320 | tSHORT tUNSIGNED tINT { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_short_int; }
321 | tSHORT tUNSIGNED { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_short_int; }
322 | tSIGNED tCHAR { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_char_int; }
323 | tUNSIGNED tCHAR { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_char_int; }
324 | tLONG tLONG tUNSIGNED tINT{ $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_longlong_int; }
325 | tLONG tLONG tUNSIGNED { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_longlong_int; }
326 | tLONG tLONG tINT { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_longlong_int; }
327 | tLONG tLONG { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_longlong_int; }
328 | tFLOAT { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_short_real; }
329 | tDOUBLE { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_real; }
330 | tLONG tDOUBLE { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_long_real; }
331 | type_expr '*' { $$ = $1; $$.deref_count++; }
332 | tCLASS identifier { $$.type = type_expr_udt_class; $$.deref_count = 0; $$.u.name = $2; }
333 | tSTRUCT identifier { $$.type = type_expr_udt_struct; $$.deref_count = 0; $$.u.name = $2; }
334 | tUNION identifier { $$.type = type_expr_udt_union; $$.deref_count = 0; $$.u.name = $2; }
335 | tENUM identifier { $$.type = type_expr_enumeration; $$.deref_count = 0; $$.u.name = $2; }
336 ;
337
338 expr_lvalue:
339 expr { $$ = expr_eval($1); }
340 ;
341
342 expr_rvalue:
343 expr_lvalue { $$ = types_extract_as_integer(&$1); }
344 ;
345
346 /*
347 * The expr rule builds an expression tree. When we are done, we call
348 * EvalExpr to evaluate the value of the expression. The advantage of
349 * the two-step approach is that it is possible to save expressions for
350 * use in 'display' commands, and in conditional watchpoints.
351 */
352 expr:
353 tNUM { $$ = expr_alloc_sconstant($1); }
354 | tSTRING { $$ = expr_alloc_string($1); }
355 | tINTVAR { $$ = expr_alloc_internal_var($1); }
356 | identifier { $$ = expr_alloc_symbol($1); }
357 | expr OP_DRF tIDENTIFIER { $$ = expr_alloc_pstruct($1, $3); }
358 | expr '.' tIDENTIFIER { $$ = expr_alloc_struct($1, $3); }
359 | identifier '(' ')' { $$ = expr_alloc_func_call($1, 0); }
360 | identifier '(' expr ')' { $$ = expr_alloc_func_call($1, 1, $3); }
361 | identifier '(' expr ',' expr ')' { $$ = expr_alloc_func_call($1, 2, $3, $5); }
362 | identifier '(' expr ',' expr ',' expr ')' { $$ = expr_alloc_func_call($1, 3, $3, $5, $7); }
363 | identifier '(' expr ',' expr ',' expr ',' expr ')' { $$ = expr_alloc_func_call($1, 4, $3, $5, $7, $9); }
364 | identifier '(' expr ',' expr ',' expr ',' expr ',' expr ')' { $$ = expr_alloc_func_call($1, 5, $3, $5, $7, $9, $11); }
365 | expr '[' expr ']' { $$ = expr_alloc_binary_op(EXP_OP_ARR, $1, $3); }
366 | expr ':' expr { $$ = expr_alloc_binary_op(EXP_OP_SEG, $1, $3); }
367 | expr OP_LOR expr { $$ = expr_alloc_binary_op(EXP_OP_LOR, $1, $3); }
368 | expr OP_LAND expr { $$ = expr_alloc_binary_op(EXP_OP_LAND, $1, $3); }
369 | expr '|' expr { $$ = expr_alloc_binary_op(EXP_OP_OR, $1, $3); }
370 | expr '&' expr { $$ = expr_alloc_binary_op(EXP_OP_AND, $1, $3); }
371 | expr '^' expr { $$ = expr_alloc_binary_op(EXP_OP_XOR, $1, $3); }
372 | expr OP_EQ expr { $$ = expr_alloc_binary_op(EXP_OP_EQ, $1, $3); }
373 | expr '>' expr { $$ = expr_alloc_binary_op(EXP_OP_GT, $1, $3); }
374 | expr '<' expr { $$ = expr_alloc_binary_op(EXP_OP_LT, $1, $3); }
375 | expr OP_GE expr { $$ = expr_alloc_binary_op(EXP_OP_GE, $1, $3); }
376 | expr OP_LE expr { $$ = expr_alloc_binary_op(EXP_OP_LE, $1, $3); }
377 | expr OP_NE expr { $$ = expr_alloc_binary_op(EXP_OP_NE, $1, $3); }
378 | expr OP_SHL expr { $$ = expr_alloc_binary_op(EXP_OP_SHL, $1, $3); }
379 | expr OP_SHR expr { $$ = expr_alloc_binary_op(EXP_OP_SHR, $1, $3); }
380 | expr '+' expr { $$ = expr_alloc_binary_op(EXP_OP_ADD, $1, $3); }
381 | expr '-' expr { $$ = expr_alloc_binary_op(EXP_OP_SUB, $1, $3); }
382 | expr '*' expr { $$ = expr_alloc_binary_op(EXP_OP_MUL, $1, $3); }
383 | expr '/' expr { $$ = expr_alloc_binary_op(EXP_OP_DIV, $1, $3); }
384 | expr '%' expr { $$ = expr_alloc_binary_op(EXP_OP_REM, $1, $3); }
385 | '-' expr %prec OP_SIGN { $$ = expr_alloc_unary_op(EXP_OP_NEG, $2); }
386 | '+' expr %prec OP_SIGN { $$ = $2; }
387 | '!' expr { $$ = expr_alloc_unary_op(EXP_OP_NOT, $2); }
388 | '~' expr { $$ = expr_alloc_unary_op(EXP_OP_LNOT, $2); }
389 | '(' expr ')' { $$ = $2; }
390 | '*' expr %prec OP_DEREF { $$ = expr_alloc_unary_op(EXP_OP_DEREF, $2); }
391 | '&' expr %prec OP_DEREF { $$ = expr_alloc_unary_op(EXP_OP_ADDR, $2); }
392 | '(' type_expr ')' expr %prec OP_DEREF { $$ = expr_alloc_typecast(&$2, $4); }
393 ;
394
395 /*
396 * The lvalue rule builds an expression tree. This is a limited form
397 * of expression that is suitable to be used as an lvalue.
398 */
399 lvalue_addr:
400 lvalue { $$ = expr_eval($1); }
401 ;
402
403 lvalue:
404 tNUM { $$ = expr_alloc_sconstant($1); }
405 | tINTVAR { $$ = expr_alloc_internal_var($1); }
406 | identifier { $$ = expr_alloc_symbol($1); }
407 | lvalue OP_DRF tIDENTIFIER { $$ = expr_alloc_pstruct($1, $3); }
408 | lvalue '.' tIDENTIFIER { $$ = expr_alloc_struct($1, $3); }
409 | lvalue '[' expr ']' { $$ = expr_alloc_binary_op(EXP_OP_ARR, $1, $3); }
410 | '*' expr { $$ = expr_alloc_unary_op(EXP_OP_FORCE_DEREF, $2); }
411 ;
412
413 %%
414
415 static LONG WINAPI wine_dbg_cmd(EXCEPTION_POINTERS *eptr)
416 {
417 switch (eptr->ExceptionRecord->ExceptionCode)
418 {
419 case DEBUG_STATUS_INTERNAL_ERROR:
420 dbg_printf("\nWineDbg internal error\n");
421 break;
422 case DEBUG_STATUS_NO_SYMBOL:
423 dbg_printf("\nUndefined symbol\n");
424 break;
425 case DEBUG_STATUS_DIV_BY_ZERO:
426 dbg_printf("\nDivision by zero\n");
427 break;
428 case DEBUG_STATUS_BAD_TYPE:
429 dbg_printf("\nNo type or type mismatch\n");
430 break;
431 case DEBUG_STATUS_NO_FIELD:
432 dbg_printf("\nNo such field in structure or union\n");
433 break;
434 case DEBUG_STATUS_CANT_DEREF:
435 dbg_printf("\nDereference failed (not a pointer, or out of array bounds)\n");
436 break;
437 case DEBUG_STATUS_ABORT:
438 break;
439 case DEBUG_STATUS_NOT_AN_INTEGER:
440 dbg_printf("\nNeeding an integral value\n");
441 break;
442 case CONTROL_C_EXIT:
443 /* this is generally sent by a ctrl-c when we run winedbg outside of wineconsole */
444 /* stop the debuggee, and continue debugger execution, we will be reentered by the
445 * debug events generated by stopping
446 */
447 dbg_interrupt_debuggee();
448 return EXCEPTION_CONTINUE_EXECUTION;
449 default:
450 dbg_printf("\nException %x\n", eptr->ExceptionRecord->ExceptionCode);
451 break;
452 }
453
454 return EXCEPTION_EXECUTE_HANDLER;
455 }
456
457 static HANDLE dbg_parser_input;
458 static HANDLE dbg_parser_output;
459
460 int input_fetch_entire_line(const char* pfx, char** line)
461 {
462 char* buffer;
463 char ch;
464 DWORD nread;
465 size_t len, alloc;
466
467 /* as of today, console handles can be file handles... so better use file APIs rather than
468 * console's
469 */
470 WriteFile(dbg_parser_output, pfx, strlen(pfx), &nread, NULL);
471
472 buffer = HeapAlloc(GetProcessHeap(), 0, alloc = 16);
473 assert(buffer != NULL);
474
475 len = 0;
476 do
477 {
478 if (!ReadFile(dbg_parser_input, &ch, 1, &nread, NULL) || nread == 0)
479 {
480 HeapFree(GetProcessHeap(), 0, buffer);
481 return -1;
482 }
483
484 if (len + 2 > alloc)
485 {
486 while (len + 2 > alloc) alloc *= 2;
487 buffer = dbg_heap_realloc(buffer, alloc);
488 }
489 buffer[len++] = ch;
490 }
491 while (ch != '\n');
492 buffer[len] = '\0';
493
494 *line = buffer;
495 return len;
496 }
497
498 int input_read_line(const char* pfx, char* buf, int size)
499 {
500 char* line = NULL;
501
502 int len = input_fetch_entire_line(pfx, &line);
503 if (len < 0) return 0;
504 /* remove trailing \n and \r */
505 while (len > 0 && (line[len - 1] == '\n' || line[len - 1] == '\r')) len--;
506 len = min(size - 1, len);
507 memcpy(buf, line, len);
508 buf[len] = '\0';
509 HeapFree(GetProcessHeap(), 0, line);
510 return 1;
511 }
512
513 /***********************************************************************
514 * parser_handle
515 *
516 * Debugger command line parser
517 */
518 void parser_handle(HANDLE input)
519 {
520 BOOL ret_ok;
521 HANDLE in_copy = dbg_parser_input;
522 HANDLE out_copy = dbg_parser_output;
523
524 ret_ok = FALSE;
525
526 if (input != INVALID_HANDLE_VALUE)
527 {
528 dbg_parser_output = INVALID_HANDLE_VALUE;
529 dbg_parser_input = input;
530 }
531 else
532 {
533 dbg_parser_output = GetStdHandle(STD_OUTPUT_HANDLE);
534 dbg_parser_input = GetStdHandle(STD_INPUT_HANDLE);
535 }
536
537 do
538 {
539 __TRY
540 {
541 ret_ok = TRUE;
542 dbg_parse();
543 }
544 __EXCEPT(wine_dbg_cmd)
545 {
546 ret_ok = FALSE;
547 }
548 __ENDTRY;
549 lexeme_flush();
550 } while (!ret_ok);
551
552 dbg_parser_input = in_copy;
553 dbg_parser_output = out_copy;
554 }
555
556 static void parser(const char* filename)
557 {
558 HANDLE h = CreateFileA(filename, GENERIC_READ, FILE_SHARE_READ, NULL, OPEN_EXISTING, 0L, 0);
559 if (h != INVALID_HANDLE_VALUE)
560 {
561 parser_handle(h);
562 CloseHandle(h);
563 }
564 }
565
566 static int dbg_error(const char* s)
567 {
568 dbg_printf("%s\n", s);
569 return 0;
570 }
571
572 HANDLE parser_generate_command_file(const char* pmt, ...)
573 {
574 HANDLE hFile;
575 char path[MAX_PATH], file[MAX_PATH];
576 DWORD w;
577 const char* p;
578
579 GetTempPathA(sizeof(path), path);
580 GetTempFileNameA(path, "WD", 0, file);
581 hFile = CreateFileA(file, GENERIC_READ|GENERIC_WRITE|DELETE, FILE_SHARE_DELETE,
582 NULL, CREATE_ALWAYS, FILE_ATTRIBUTE_NORMAL | FILE_FLAG_DELETE_ON_CLOSE, 0);
583 if (hFile != INVALID_HANDLE_VALUE)
584 {
585 va_list ap;
586
587 WriteFile(hFile, pmt, strlen(pmt), &w, 0);
588 va_start(ap, pmt);
589 while ((p = va_arg(ap, const char*)) != NULL)
590 {
591 WriteFile(hFile, "\n", 1, &w, 0);
592 WriteFile(hFile, p, strlen(p), &w, 0);
593 }
594 va_end(ap);
595 WriteFile(hFile, "\nquit\n", 6, &w, 0);
596 SetFilePointer(hFile, 0, NULL, FILE_BEGIN);
597 }
598 return hFile;
599 }
Windows API implementation