tools/make_unicode

   1 #!/usr/bin/perl -w
   2 #
   3 # Generate code page .c files from ftp.unicode.org descriptions
   4 #
   5 # Copyright 2000 Alexandre Julliard
   6 #
   7 # This library is free software; you can redistribute it and/or
   8 # modify it under the terms of the GNU Lesser General Public
   9 # License as published by the Free Software Foundation; either
  10 # version 2.1 of the License, or (at your option) any later version.
  11 #
  12 # This library is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # Lesser General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU Lesser General Public
  18 # License along with this library; if not, write to the Free Software
  19 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20 #
  21
  22 use strict;
  23
  24 # base URLs for www.unicode.org files
  25 my $MAPPINGS = "http://www.unicode.org/Public/MAPPINGS";
  26 my $UNIDATA = "http://www.unicode.org/Public/8.0.0/ucd";
  27 my $REPORTS = "http://www.unicode.org/reports";
  28 my $RFCS = "http://www.rfc-editor.org/rfc";
  29 my $VERTICALDATA = "http://www.unicode.org/Public/vertical/revision-15";
  30
  31 # Sort keys file
  32 my $SORTKEYS = "tr10/allkeys.txt";
  33
  34 # RFC3454 (stringprep data)
  35 my $STRINGPREP = "rfc3454.txt";
  36
  37 # Defaults mapping
  38 my $DEFAULTS = "tools/unicode-defaults";
  39
  40 # Default char for undefined mappings
  41 my $DEF_CHAR = ord '?';
  42
  43 my @allfiles =
  44 (
  45     [ 37,    "VENDORS/MICSFT/EBCDIC/CP037.TXT",   0, "IBM EBCDIC US Canada", 0, 0x6f ],
  46     [ 424,   "VENDORS/MISC/CP424.TXT",            0, "IBM EBCDIC Hebrew" ],
  47     [ 437,   "VENDORS/MICSFT/PC/CP437.TXT",       1, "OEM United States" ],
  48     [ 500,   "VENDORS/MICSFT/EBCDIC/CP500.TXT",   0, "IBM EBCDIC International", 0, 0x6f ],
  49     [ 737,   "VENDORS/MICSFT/PC/CP737.TXT",       1, "OEM Greek 437G" ],
  50     [ 775,   "VENDORS/MICSFT/PC/CP775.TXT",       1, "OEM Baltic" ],
  51     [ 850,   "VENDORS/MICSFT/PC/CP850.TXT",       1, "OEM Multilingual Latin 1" ],
  52     [ 852,   "VENDORS/MICSFT/PC/CP852.TXT",       1, "OEM Slovak Latin 2" ],
  53     [ 855,   "VENDORS/MICSFT/PC/CP855.TXT",       1, "OEM Cyrillic" ],
  54     [ 856,   "VENDORS/MISC/CP856.TXT",            0, "Hebrew PC" ],
  55     [ 857,   "VENDORS/MICSFT/PC/CP857.TXT",       1, "OEM Turkish", 0xf8bb ],
  56     [ 860,   "VENDORS/MICSFT/PC/CP860.TXT",       1, "OEM Portuguese" ],
  57     [ 861,   "VENDORS/MICSFT/PC/CP861.TXT",       1, "OEM Icelandic" ],
  58     [ 862,   "VENDORS/MICSFT/PC/CP862.TXT",       1, "OEM Hebrew" ],
  59     [ 863,   "VENDORS/MICSFT/PC/CP863.TXT",       1, "OEM Canadian French" ],
  60     [ 864,   "VENDORS/MICSFT/PC/CP864.TXT",       0, "OEM Arabic", 0xf8bb ],
  61     [ 865,   "VENDORS/MICSFT/PC/CP865.TXT",       1, "OEM Nordic" ],
  62     [ 866,   "VENDORS/MICSFT/PC/CP866.TXT",       1, "OEM Russian" ],
  63     [ 869,   "VENDORS/MICSFT/PC/CP869.TXT",       1, "OEM Greek" ],
  64     [ 874,   "VENDORS/MICSFT/WindowsBestFit/bestfit874.txt",  1, "ANSI/OEM Thai" ],
  65     [ 875,   "VENDORS/MICSFT/EBCDIC/CP875.TXT",               0, "IBM EBCDIC Greek", 0, 0x6f ],
  66     [ 878,   "VENDORS/MISC/KOI8-R.TXT",                       0, "Russian KOI8" ],
  67     [ 932,   "VENDORS/MICSFT/WindowsBestFit/bestfit932.txt",  0, "ANSI/OEM Japanese Shift-JIS" ],
  68     [ 936,   "VENDORS/MICSFT/WindowsBestFit/bestfit936.txt",  0, "ANSI/OEM Simplified Chinese GBK" ],
  69     [ 949,   "VENDORS/MICSFT/WindowsBestFit/bestfit949.txt",  0, "ANSI/OEM Korean Unified Hangul" ],
  70     [ 950,   "VENDORS/MICSFT/WindowsBestFit/bestfit950.txt",  0, "ANSI/OEM Traditional Chinese Big5" ],
  71     [ 1006,  "VENDORS/MISC/CP1006.TXT",                       0, "IBM Arabic" ],
  72     [ 1026,  "VENDORS/MICSFT/EBCDIC/CP1026.TXT",              0, "IBM EBCDIC Latin 5 Turkish", 0, 0x6f ],
  73     [ 1250,  "VENDORS/MICSFT/WindowsBestFit/bestfit1250.txt", 0, "ANSI Eastern Europe" ],
  74     [ 1251,  "VENDORS/MICSFT/WindowsBestFit/bestfit1251.txt", 0, "ANSI Cyrillic" ],
  75     [ 1252,  "VENDORS/MICSFT/WindowsBestFit/bestfit1252.txt", 0, "ANSI Latin 1" ],
  76     [ 1253,  "VENDORS/MICSFT/WindowsBestFit/bestfit1253.txt", 0, "ANSI Greek" ],
  77     [ 1254,  "VENDORS/MICSFT/WindowsBestFit/bestfit1254.txt", 0, "ANSI Turkish" ],
  78     [ 1255,  "VENDORS/MICSFT/WindowsBestFit/bestfit1255.txt", 0, "ANSI Hebrew" ],
  79     [ 1256,  "VENDORS/MICSFT/WindowsBestFit/bestfit1256.txt", 0, "ANSI Arabic" ],
  80     [ 1257,  "VENDORS/MICSFT/WindowsBestFit/bestfit1257.txt", 0, "ANSI Baltic" ],
  81     [ 1258,  "VENDORS/MICSFT/WindowsBestFit/bestfit1258.txt", 0, "ANSI/OEM Viet Nam" ],
  82     [ 1361,  "VENDORS/MICSFT/WindowsBestFit/bestfit1361.txt", 0, "Korean Johab" ],
  83     [ 10000, "VENDORS/MICSFT/MAC/ROMAN.TXT",      0, "Mac Roman" ],
  84     [ 10001, "VENDORS/APPLE/JAPANESE.TXT",        0, "Mac Japanese" ],
  85     [ 10002, "VENDORS/APPLE/CHINTRAD.TXT",        0, "Mac Traditional Chinese" ],
  86     [ 10003, "VENDORS/APPLE/KOREAN.TXT",          0, "Mac Korean", 0xf8e5 ],
  87     [ 10004, "VENDORS/APPLE/ARABIC.TXT",          0, "Mac Arabic", 0xf826 ],
  88     [ 10005, "VENDORS/APPLE/HEBREW.TXT",          0, "Mac Hebrew", 0xf7fa ],
  89     [ 10006, "VENDORS/MICSFT/MAC/GREEK.TXT",      0, "Mac Greek" ],
  90     [ 10007, "VENDORS/MICSFT/MAC/CYRILLIC.TXT",   0, "Mac Cyrillic" ],
  91     [ 10008, "VENDORS/APPLE/CHINSIMP.TXT",        0, "Mac Simplified Chinese" ],
  92     [ 10010, "VENDORS/APPLE/ROMANIAN.TXT",        0, "Mac Romanian" ],
  93     [ 10017, "VENDORS/APPLE/CYRILLIC.TXT",        0, "Mac Ukrainian" ],
  94     [ 10021, "VENDORS/APPLE/THAI.TXT",            0, "Mac Thai" ],
  95     [ 10029, "VENDORS/MICSFT/MAC/LATIN2.TXT",     0, "Mac Latin 2" ],
  96     [ 10079, "VENDORS/MICSFT/MAC/ICELAND.TXT",    0, "Mac Icelandic" ],
  97     [ 10081, "VENDORS/MICSFT/MAC/TURKISH.TXT",    0, "Mac Turkish", 0xf89f ],
  98     [ 10082, "VENDORS/APPLE/CROATIAN.TXT",        0, "Mac Croatian" ],
  99     [ 20127, undef,                               0, "US-ASCII (7bit)" ],
 100     [ 20866, "VENDORS/MISC/KOI8-R.TXT",           0, "Russian KOI8" ],
 101     [ 20932, "OBSOLETE/EASTASIA/JIS/JIS0208.TXT", 0, "EUC-JP", 0, 0x3f, 0x30fb  ],
 102     [ 21866, "VENDORS/MISC/KOI8-U.TXT",           0, "Ukrainian KOI8" ],
 103     [ 28591, "ISO8859/8859-1.TXT",                0, "ISO 8859-1 Latin 1" ],
 104     [ 28592, "ISO8859/8859-2.TXT",                0, "ISO 8859-2 Latin 2 (East European)" ],
 105     [ 28593, "ISO8859/8859-3.TXT",                0, "ISO 8859-3 Latin 3 (South European)", 0xf7f5 ],
 106     [ 28594, "ISO8859/8859-4.TXT",                0, "ISO 8859-4 Latin 4 (Baltic old)" ],
 107     [ 28595, "ISO8859/8859-5.TXT",                0, "ISO 8859-5 Cyrillic" ],
 108     [ 28596, "ISO8859/8859-6.TXT",                0, "ISO 8859-6 Arabic", 0xf7c8 ],
 109     [ 28597, "ISO8859/8859-7.TXT",                0, "ISO 8859-7 Greek", 0xf7c5 ],
 110     [ 28598, "ISO8859/8859-8.TXT",                0, "ISO 8859-8 Hebrew", 0xf79c ],
 111     [ 28599, "ISO8859/8859-9.TXT",                0, "ISO 8859-9 Latin 5 (Turkish)" ],
 112     [ 28600, "ISO8859/8859-10.TXT",               0, "ISO 8859-10 Latin 6 (Nordic)" ],
 113     [ 28603, "ISO8859/8859-13.TXT",               0, "ISO 8859-13 Latin 7 (Baltic)" ],
 114     [ 28604, "ISO8859/8859-14.TXT",               0, "ISO 8859-14 Latin 8 (Celtic)" ],
 115     [ 28605, "ISO8859/8859-15.TXT",               0, "ISO 8859-15 Latin 9 (Euro)" ],
 116     [ 28606, "ISO8859/8859-16.TXT",               0, "ISO 8859-16 Latin 10 (Balkan)" ]
 117 );
 118
 119
 120 my %ctype =
 121 (
 122     "upper"  => 0x0001,
 123     "lower"  => 0x0002,
 124     "digit"  => 0x0004,
 125     "space"  => 0x0008,
 126     "punct"  => 0x0010,
 127     "cntrl"  => 0x0020,
 128     "blank"  => 0x0040,
 129     "xdigit" => 0x0080,
 130     "alpha"  => 0x0100,
 131     "defin"  => 0x0200
 132 );
 133
 134 my %bracket_types =
 135 (
 136     "o" => 0x0000,
 137     "c" => 0x0001,
 138 );
 139
 140 my %indic_types =
 141 (
 142     "Other"    => 0x0000,
 143     "Bindu"    => 0x0001,
 144     "Visarga"  => 0x0002,
 145     "Avagraha" => 0x0003,
 146     "Nukta"    => 0x0004,
 147     "Virama"   => 0x0005,
 148     "Vowel_Independent"  => 0x0006,
 149     "Vowel_Dependent"  => 0x0007,
 150     "Vowel"  => 0x0008,
 151     "Consonant_Placeholder"  => 0x0009,
 152     "Consonant"  => 0x000a,
 153     "Consonant_Dead"  => 0x000b,
 154     "Consonant_Succeeding_Repha" => 0x000c,
 155     "Consonant_Subjoined"  => 0x000d,
 156     "Consonant_Medial"  => 0x000e,
 157     "Consonant_Final"  => 0x000f,
 158     "Consonant_Head_Letter"  => 0x0010,
 159     "Modifying_Letter"  => 0x0011,
 160     "Tone_Letter"  => 0x0012,
 161     "Tone_Mark"  => 0x0013,
 162     "Register_Shifter"  => 0x0014,
 163     "Consonant_Preceding_Repha" => 0x0015,
 164     "Pure_Killer" => 0x0016,
 165     "Invisible_Stacker" => 0x0017,
 166     "Gemination_Mark" => 0x0018,
 167     "Cantillation_Mark" => 0x0019,
 168     "Non_Joiner" => 0x001a,
 169     "Joiner" => 0x001b,
 170     "Number_Joiner" => 0x001c,
 171     "Number" => 0x001d,
 172     "Brahmi_Joining_Number" => 0x001e,
 173     "Consonant_With_Stacker" => 0x001f,
 174     "Consonant_Prefixed" => 0x0020,
 175     "Syllable_Modifier" => 0x0021,
 176     "Consonant_Killer" => 0x0022
 177 );
 178
 179 my %matra_types =
 180 (
 181     "Right"    => 0x01,
 182     "Left"  => 0x02,
 183     "Visual_Order_Left" => 0x03,
 184     "Left_And_Right"    => 0x04,
 185     "Top"   => 0x05,
 186     "Bottom"  => 0x06,
 187     "Top_And_Bottom"  => 0x07,
 188     "Top_And_Right"  => 0x08,
 189     "Top_And_Left"  => 0x09,
 190     "Top_And_Left_And_Right"  => 0x0a,
 191     "Bottom_And_Right"  => 0x0b,
 192     "Top_And_Bottom_And_Right"  => 0x0c,
 193     "Overstruck"  => 0x0d,
 194     "Invisible"  => 0x0e
 195 );
 196
 197 my %nameprep_flags =
 198 (
 199     "unassigned" => 0x01,
 200     "prohibited" => 0x02,
 201     "bidi_ral"   => 0x04,
 202     "bidi_l"     => 0x08
 203 );
 204
 205 my %break_types =
 206 (
 207     "BK"  => 0x0001,
 208     "CR"  => 0x0002,
 209     "LF"  => 0x0003,
 210     "CM"  => 0x0004,
 211     "SG"  => 0x0005,
 212     "GL"  => 0x0006,
 213     "CB"  => 0x0007,
 214     "SP"  => 0x0008,
 215     "ZW"  => 0x0009,
 216     "NL"  => 0x000a,
 217     "WJ"  => 0x000b,
 218     "JL"  => 0x000c,
 219     "JV"  => 0x000d,
 220     "JT"  => 0x000e,
 221     "H2"  => 0x000f,
 222     "H3"  => 0x0010,
 223     "XX"  => 0x0011,
 224     "OP"  => 0x0012,
 225     "CL"  => 0x0013,
 226     "CP"  => 0x0014,
 227     "QU"  => 0x0015,
 228     "NS"  => 0x0016,
 229     "EX"  => 0x0017,
 230     "SY"  => 0x0018,
 231     "IS"  => 0x0019,
 232     "PR"  => 0x001a,
 233     "PO"  => 0x001b,
 234     "NU"  => 0x001c,
 235     "AL"  => 0x001d,
 236     "ID"  => 0x001e,
 237     "IN"  => 0x001f,
 238     "HY"  => 0x0020,
 239     "BB"  => 0x0021,
 240     "BA"  => 0x0022,
 241     "SA"  => 0x0023,
 242     "AI"  => 0x0024,
 243     "B2"  => 0x0025,
 244     "HL"  => 0x0026,
 245     "CJ"  => 0x0027,
 246     "RI"  => 0x0028,
 247 );
 248
 249 my %vertical_types =
 250 (
 251     "R"  => 0x0000,
 252     "U"  => 0x0001,
 253     "Tr" => 0x0002,
 254     "Tu" => 0x0003,
 255 );
 256
 257 my %categories =
 258 (
 259     "Lu" => $ctype{"defin"}|$ctype{"alpha"}|$ctype{"upper"}, # Letter, Uppercase
 260     "Ll" => $ctype{"defin"}|$ctype{"alpha"}|$ctype{"lower"}, # Letter, Lowercase
 261     "Lt" => $ctype{"defin"}|$ctype{"alpha"}|$ctype{"upper"}|$ctype{"lower"},    # Letter, Titlecase
 262     "Mn" => $ctype{"defin"},                    # Mark, Non-Spacing
 263     "Mc" => $ctype{"defin"},                    # Mark, Spacing Combining
 264     "Me" => $ctype{"defin"},                    # Mark, Enclosing
 265     "Nd" => $ctype{"defin"}|$ctype{"digit"},    # Number, Decimal Digit
 266     "Nl" => $ctype{"defin"}|$ctype{"alpha"},    # Number, Letter
 267     "No" => $ctype{"defin"},                    # Number, Other
 268     "Zs" => $ctype{"defin"}|$ctype{"space"},    # Separator, Space
 269     "Zl" => $ctype{"defin"}|$ctype{"space"},    # Separator, Line
 270     "Zp" => $ctype{"defin"}|$ctype{"space"},    # Separator, Paragraph
 271     "Cc" => $ctype{"defin"}|$ctype{"cntrl"},    # Other, Control
 272     "Cf" => $ctype{"defin"}|$ctype{"cntrl"},    # Other, Format
 273     "Cs" => $ctype{"defin"},                    # Other, Surrogate
 274     "Co" => $ctype{"defin"},                    # Other, Private Use
 275     "Cn" => $ctype{"defin"},                    # Other, Not Assigned
 276     "Lm" => $ctype{"defin"}|$ctype{"alpha"},    # Letter, Modifier
 277     "Lo" => $ctype{"defin"}|$ctype{"alpha"},    # Letter, Other
 278     "Pc" => $ctype{"defin"}|$ctype{"punct"},    # Punctuation, Connector
 279     "Pd" => $ctype{"defin"}|$ctype{"punct"},    # Punctuation, Dash
 280     "Ps" => $ctype{"defin"}|$ctype{"punct"},    # Punctuation, Open
 281     "Pe" => $ctype{"defin"}|$ctype{"punct"},    # Punctuation, Close
 282     "Pi" => $ctype{"defin"}|$ctype{"punct"},    # Punctuation, Initial quote
 283     "Pf" => $ctype{"defin"}|$ctype{"punct"},    # Punctuation, Final quote
 284     "Po" => $ctype{"defin"}|$ctype{"punct"},    # Punctuation, Other
 285     "Sm" => $ctype{"defin"},                    # Symbol, Math
 286     "Sc" => $ctype{"defin"},                    # Symbol, Currency
 287     "Sk" => $ctype{"defin"},                    # Symbol, Modifier
 288     "So" => $ctype{"defin"}                     # Symbol, Other
 289 );
 290
 291 # a few characters need additional categories that cannot be determined automatically
 292 my %special_categories =
 293 (
 294     "xdigit" => [ ord('0')..ord('9'),ord('A')..ord('F'),ord('a')..ord('f'),
 295                   0xff10..0xff19, 0xff21..0xff26, 0xff41..0xff46 ],
 296     "space"  => [ 0x09..0x0d, 0x85 ],
 297     "blank"  => [ 0x09, 0x20, 0xa0, 0x3000, 0xfeff ],
 298     "cntrl"  => [ 0x070f, 0x200c, 0x200d,
 299                   0x200e, 0x200f, 0x202a, 0x202b, 0x202c, 0x202d, 0x202e,
 300                   0x206a, 0x206b, 0x206c, 0x206d, 0x206e, 0x206f, 0xfeff,
 301                   0xfff9, 0xfffa, 0xfffb ],
 302     "punct"  => [ 0x24, 0x2b, 0x3c..0x3e, 0x5e, 0x60, 0x7c, 0x7e, 0xa2..0xbe,
 303                   0xd7, 0xf7 ],
 304     "digit"  => [ 0xb2, 0xb3, 0xb9 ],
 305     "lower"  => [ 0x2071, 0x207f ]
 306 );
 307
 308 my %directions =
 309 (
 310     "L"   => 1,    # Left-to-Right
 311     "R"   => 2,    # Right-to-Left
 312     "AL"  => 12,   # Right-to-Left Arabic
 313     "EN"  => 3,    # European Number
 314     "ES"  => 4,    # European Number Separator
 315     "ET"  => 5,    # European Number Terminator
 316     "AN"  => 6,    # Arabic Number
 317     "CS"  => 7,    # Common Number Separator
 318     "NSM" => 13,   # Non-Spacing Mark
 319     "BN"  => 14,   # Boundary Neutral
 320     "B"   => 8,    # Paragraph Separator
 321     "S"   => 9,    # Segment Separator
 322     "WS"  => 10,   # Whitespace
 323     "ON"  => 11,   # Other Neutrals
 324     "LRE" => 15,   # Left-to-Right Embedding
 325     "LRO" => 15,   # Left-to-Right Override
 326     "RLE" => 15,   # Right-to-Left Embedding
 327     "RLO" => 15,   # Right-to-Left Override
 328     "PDF" => 15,   # Pop Directional Format
 329     "LRI" => 15,   # Left-to-Right Isolate
 330     "RLI" => 15,   # Right-to-Left Isolate
 331     "FSI" => 15,   # First Strong Isolate
 332     "PDI" => 15    # Pop Directional Isolate
 333 );
 334
 335 my %joining_types =
 336 (
 337    "U" => 0,    # Non_Joining
 338    "T" => 1,    # Transparent
 339    "R" => 2,    # Right_Joining
 340    "L" => 3,    # Left_Joining
 341    "D" => 4,    # Dual_Joining
 342    "C" => 5,    # Join_Causing
 343 );
 344
 345 my @cp2uni = ();
 346 my @lead_bytes = ();
 347 my @uni2cp = ();
 348 my @unicode_defaults = ();
 349 my @unicode_aliases = ();
 350 my @tolower_table = ();
 351 my @toupper_table = ();
 352 my @digitmap_table = ();
 353 my @compatmap_table = ();
 354 my @category_table = ();
 355 my @joining_table = ();
 356 my @direction_table = ();
 357 my @decomp_table = ();
 358 my @compose_table = ();
 359 my $default_char;
 360 my $default_wchar;
 361
 362 my %joining_forms =
 363 (
 364    "isolated" => [],
 365    "final" => [],
 366    "initial" => [],
 367    "medial" => []
 368 );
 369
 370 ################################################################
 371 # fetch a unicode.org file and open it
 372 sub open_data_file($$)
 373 {
 374     my ($base, $name) = @_;
 375     (my $dir = "data/$name") =~ s/\/[^\/]+$//;
 376     local *FILE;
 377     unless (-f "data/$name")
 378     {
 379         print "Fetching $base/$name...\n";
 380         system "mkdir", "-p", $dir;
 381         !system "wget", "-q", "-O", "data/$name", "$base/$name" or die "cannot fetch $base/$name";
 382     }
 383     open FILE, "<data/$name" or die "cannot open data/$name";
 384     return *FILE;
 385 }
 386
 387 ################################################################
 388 # read in the defaults file
 389 sub READ_DEFAULTS($)
 390 {
 391     my $filename = shift;
 392     my $start;
 393
 394     # first setup a few default mappings
 395
 396     open DEFAULTS, "$filename" or die "Cannot open $filename";
 397     print "Loading $filename\n";
 398     while (<DEFAULTS>)
 399     {
 400         next if /^\#/;  # skip comments
 401         next if /^$/;  # skip empty lines
 402         if (/^(([0-9a-fA-F]+)(,[0-9a-fA-F]+)*)\s+([0-9a-fA-F]+|'.'|none)\s+(\#.*)?/)
 403         {
 404             my @src = map hex, split /,/,$1;
 405             my $dst = $4;
 406             my $comment = $5;
 407             if ($#src > 0) { push @unicode_aliases, \@src; }
 408             next if ($dst eq "none");
 409             $dst = ($dst =~ /\'.\'/) ? ord substr($dst,1,1) : hex $dst;
 410             foreach my $src (@src)
 411             {
 412                 die "Duplicate value" if defined($unicode_defaults[$src]);
 413                 $unicode_defaults[$src] = $dst;
 414             }
 415             next;
 416         }
 417         die "Unrecognized line $_\n";
 418     }
 419     close DEFAULTS;
 420
 421     # now build mappings from the decomposition field of the Unicode database
 422
 423     my $UNICODE_DATA = open_data_file( $UNIDATA, "UnicodeData.txt" );
 424     while (<$UNICODE_DATA>)
 425     {
 426         # Decode the fields ...
 427         my ($code, $name, $cat, $comb, $bidi,
 428             $decomp, $dec, $dig, $num, $mirror,
 429             $oldname, $comment, $upper, $lower, $title) = split /;/;
 430         my $dst;
 431         my $src = hex $code;
 432
 433         die "unknown category $cat" unless defined $categories{$cat};
 434         die "unknown directionality $bidi" unless defined $directions{$bidi};
 435
 436         $category_table[$src] = $categories{$cat};
 437         $direction_table[$src] = $directions{$bidi};
 438         $joining_table[$src] = $joining_types{"T"} if $cat eq "Mn" || $cat eq "Me" || $cat eq "Cf";
 439
 440         if ($lower ne "")
 441         {
 442             $tolower_table[$src] = hex $lower;
 443         }
 444         if ($upper ne "")
 445         {
 446             $toupper_table[$src] = hex $upper;
 447         }
 448         if ($dec ne "")
 449         {
 450             $category_table[$src] |= $ctype{"digit"};
 451         }
 452         if ($dig ne "")
 453         {
 454             $digitmap_table[$src] = ord $dig;
 455         }
 456
 457         # copy the category and direction for everything between First/Last pairs
 458         if ($name =~ /, First>/) { $start = $src; }
 459         if ($name =~ /, Last>/)
 460         {
 461             while ($start < $src)
 462             {
 463                 $category_table[$start] = $category_table[$src];
 464                 $direction_table[$start] = $direction_table[$src];
 465                 $start++;
 466             }
 467         }
 468
 469         next if $decomp eq "";  # no decomposition, skip it
 470
 471         if ($decomp =~ /^<([a-zA-Z]+)>\s+([0-9a-fA-F]+)$/)
 472         {
 473             # decomposition of the form "<foo> 1234" -> use char if type is known
 474             if (($src >= 0xf900 && $src < 0xfb00) || ($src >= 0xfe30 && $src < 0xfffd))
 475             {
 476                 # Single char decomposition in the compatibility range
 477                 $compatmap_table[$src] = hex $2;
 478             }
 479             if ($1 eq "isolated" || $1 eq "final" || $1 eq "initial" || $1 eq "medial")
 480             {
 481                 ${joining_forms{$1}}[hex $2] = $src;
 482                 next;
 483             }
 484             next unless ($1 eq "font" ||
 485                          $1 eq "noBreak" ||
 486                          $1 eq "circle" ||
 487                          $1 eq "super" ||
 488                          $1 eq "sub" ||
 489                          $1 eq "wide" ||
 490                          $1 eq "narrow" ||
 491                          $1 eq "compat" ||
 492                          $1 eq "small");
 493             $dst = hex $2;
 494         }
 495         elsif ($decomp =~ /^<compat>\s+0020\s+([0-9a-fA-F]+)/)
 496         {
 497             # decomposition "<compat> 0020 1234" -> combining accent
 498             $dst = hex $1;
 499         }
 500         elsif ($decomp =~ /^([0-9a-fA-F]+)/)
 501         {
 502             # decomposition contains only char values without prefix -> use first char
 503             $dst = hex $1;
 504             $category_table[$src] |= $category_table[$dst] if defined $category_table[$dst];
 505             # store decomposition if it contains two chars
 506             if ($decomp =~ /^([0-9a-fA-F]+)\s+([0-9a-fA-F]+)$/)
 507             {
 508                 $decomp_table[$src] = [ hex $1, hex $2 ];
 509                 push @compose_table, [ hex $1, hex $2, $src ];
 510             }
 511             elsif ($decomp =~ /^(<[a-z]+>\s)*([0-9a-fA-F]+)$/ &&
 512                    (($src >= 0xf900 && $src < 0xfb00) || ($src >= 0xfe30 && $src < 0xfffd)))
 513             {
 514                 # Single char decomposition in the compatibility range
 515                 $compatmap_table[$src] = hex $2;
 516             }
 517         }
 518         else
 519         {
 520             next;
 521         }
 522
 523         next if defined($unicode_defaults[$src]);  # may have been set in the defaults file
 524
 525         # check for loops
 526         for (my $i = $dst; ; $i = $unicode_defaults[$i])
 527         {
 528             die sprintf("loop detected for %04x -> %04x",$src,$dst) if $i == $src;
 529             last unless defined($unicode_defaults[$i]);
 530         }
 531         $unicode_defaults[$src] = $dst;
 532     }
 533     close $UNICODE_DATA;
 534
 535     # patch the category of some special characters
 536
 537     foreach my $cat (keys %special_categories)
 538     {
 539         my $flag = $ctype{$cat};
 540         foreach my $i (@{$special_categories{$cat}}) { $category_table[$i] |= $flag; }
 541     }
 542 }
 543
 544
 545 ################################################################
 546 # define a new lead byte
 547 sub add_lead_byte($)
 548 {
 549     my $ch = shift;
 550     push @lead_bytes, $ch;
 551     $cp2uni[$ch] = 0;
 552 }
 553
 554 ################################################################
 555 # define a new char mapping
 556 sub add_mapping($$)
 557 {
 558     my ($cp, $uni) = @_;
 559     $cp2uni[$cp] = $uni unless defined($cp2uni[$cp]);
 560     $uni2cp[$uni] = $cp unless defined($uni2cp[$uni]);
 561     if ($cp > 0xff && !defined($cp2uni[$cp >> 8]))
 562     {
 563         add_lead_byte( $cp >> 8 );
 564     }
 565 }
 566
 567 ################################################################
 568 # parse a standard codepage file
 569 sub read_codepage_file($)
 570 {
 571     my $name = shift;
 572     my $INPUT = open_data_file( $MAPPINGS, $name );
 573
 574     while (<$INPUT>)
 575     {
 576         next if /^\#/;  # skip comments
 577         next if /^$/;  # skip empty lines
 578         next if /\x1a/;  # skip ^Z
 579         next if (/^0x([0-9a-fA-F]+)\s+\#UNDEFINED/);  # undefined char
 580
 581         if (/^0x([0-9a-fA-F]+)\s+\#DBCS LEAD BYTE/)
 582         {
 583             add_lead_byte( hex $1 );
 584             next;
 585         }
 586         # 0x12 0x3456
 587         if (/^0x([0-9a-fA-F]+)\s+0x([0-9a-fA-F]+)\s+(\#.*)?/)
 588         {
 589             add_mapping( hex $1, hex $2 );
 590             next;
 591         }
 592         # 0x12 0x3456+0x7890
 593         if (/^0x([0-9a-fA-F]+)\s+0x([0-9a-fA-F]+)\+.*\s+(\#.*)?/)
 594         {
 595             add_mapping( hex $1, hex $2 );
 596             next;
 597         }
 598         # 0x12 <LR>+0x3456
 599         if (/^0x([0-9a-fA-F]+)\s+<LR>\+0x([0-9a-fA-F]+)\s+(\#.*)?/)
 600         {
 601             add_mapping( hex $1, hex $2 );
 602             next;
 603         }
 604         # 0x12 <RL>+0x3456
 605         if (/^0x([0-9a-fA-F]+)\s+<RL>\+0x([0-9a-fA-F]+)\s+(\#.*)?/)
 606         {
 607             my $uni = hex $2;
 608             add_mapping( hex $1, $uni ) if $uni >= 0x80;
 609             next;
 610         }
 611         die "$name: Unrecognized line $_\n";
 612     }
 613     close $INPUT;
 614 }
 615
 616
 617 ################################################################
 618 # fill input data for the 20127 (us-ascii) codepage
 619 sub fill_20127_codepage()
 620 {
 621     for (my $i = 0; $i < 128; $i++) { $cp2uni[$i] = $uni2cp[$i] = $i; }
 622     for (my $i = 128; $i < 256; $i++) { $cp2uni[$i] = $i & 0x7f; }
 623 }
 624
 625 ################################################################
 626 # get a mapping including glyph chars for MB_USEGLYPHCHARS
 627
 628 sub get_glyphs_mapping(@)
 629 {
 630     $_[0x01] = 0x263a;  # (WHITE SMILING FACE)
 631     $_[0x02] = 0x263b;  # (BLACK SMILING FACE)
 632     $_[0x03] = 0x2665;  # (BLACK HEART SUIT)
 633     $_[0x04] = 0x2666;  # (BLACK DIAMOND SUIT)
 634     $_[0x05] = 0x2663;  # (BLACK CLUB SUIT)
 635     $_[0x06] = 0x2660;  # (BLACK SPADE SUIT)
 636     $_[0x07] = 0x2022;  # (BULLET)
 637     $_[0x08] = 0x25d8;  # (INVERSE BULLET)
 638     $_[0x09] = 0x25cb;  # (WHITE CIRCLE)
 639     $_[0x0a] = 0x25d9;  # (INVERSE WHITE CIRCLE)
 640     $_[0x0b] = 0x2642;  # (MALE SIGN)
 641     $_[0x0c] = 0x2640;  # (FEMALE SIGN)
 642     $_[0x0d] = 0x266a;  # (EIGHTH NOTE)
 643     $_[0x0e] = 0x266b;  # (BEAMED EIGHTH NOTES)
 644     $_[0x0f] = 0x263c;  # (WHITE SUN WITH RAYS)
 645     $_[0x10] = 0x25ba;  # (BLACK RIGHT-POINTING POINTER)
 646     $_[0x11] = 0x25c4;  # (BLACK LEFT-POINTING POINTER)
 647     $_[0x12] = 0x2195;  # (UP DOWN ARROW)
 648     $_[0x13] = 0x203c;  # (DOUBLE EXCLAMATION MARK)
 649     $_[0x14] = 0x00b6;  # (PILCROW SIGN)
 650     $_[0x15] = 0x00a7;  # (SECTION SIGN)
 651     $_[0x16] = 0x25ac;  # (BLACK RECTANGLE)
 652     $_[0x17] = 0x21a8;  # (UP DOWN ARROW WITH BASE)
 653     $_[0x18] = 0x2191;  # (UPWARDS ARROW)
 654     $_[0x19] = 0x2193;  # (DOWNWARDS ARROW)
 655     $_[0x1a] = 0x2192;  # (RIGHTWARDS ARROW)
 656     $_[0x1b] = 0x2190;  # (LEFTWARDS ARROW)
 657     $_[0x1c] = 0x221f;  # (RIGHT ANGLE)
 658     $_[0x1d] = 0x2194;  # (LEFT RIGHT ARROW)
 659     $_[0x1e] = 0x25b2;  # (BLACK UP-POINTING TRIANGLE)
 660     $_[0x1f] = 0x25bc;  # (BLACK DOWN-POINTING TRIANGLE)
 661     $_[0x7f] = 0x2302;  # (HOUSE)
 662     return @_;
 663 }
 664
 665 ################################################################
 666 # build EUC-JP table from the JIS 0208 file
 667 # FIXME: for proper EUC-JP we should probably read JIS 0212 too
 668 # but this would require 3-byte DBCS characters
 669 sub READ_JIS0208_FILE($)
 670 {
 671     my $name = shift;
 672
 673     # ASCII chars
 674     for (my $i = 0x00; $i <= 0x7f; $i++)
 675     {
 676         $cp2uni[$i] = $i;
 677         $uni2cp[$i] = $i;
 678     }
 679
 680     # JIS X 0201 right plane
 681     for (my $i = 0xa1; $i <= 0xdf; $i++)
 682     {
 683         $cp2uni[0x8e00 + $i] = 0xfec0 + $i;
 684         $uni2cp[0xfec0 + $i] = 0x8e00 + $i;
 685     }
 686
 687     # lead bytes
 688     foreach my $i (0x8e, 0x8f, 0xa1 .. 0xfe)
 689     {
 690         add_lead_byte($i);
 691     }
 692
 693     # undefined chars
 694     foreach my $i (0x80 .. 0x8d, 0x90 .. 0xa0, 0xff)
 695     {
 696         $cp2uni[$i] = $DEF_CHAR;
 697     }
 698
 699     # Shift-JIS compatibility
 700     $uni2cp[0x00a5] = 0x5c;
 701     $uni2cp[0x203e] = 0x7e;
 702
 703     # Fix backslash conversion
 704     $cp2uni[0xa1c0] = 0xff3c;
 705     $uni2cp[0xff3c] = 0xa1c0;
 706
 707     my $INPUT = open_data_file( $MAPPINGS, $name );
 708     while (<$INPUT>)
 709     {
 710         next if /^\#/;  # skip comments
 711         next if /^$/;  # skip empty lines
 712         next if /\x1a/;  # skip ^Z
 713         if (/^0x[0-9a-fA-F]+\s+0x([0-9a-fA-F]+)\s+0x([0-9a-fA-F]+)\s+(\#.*)?/)
 714         {
 715             my $cp = 0x8080 + hex $1;
 716             my $uni = hex $2;
 717             $cp2uni[$cp] = $uni unless defined($cp2uni[$cp]);
 718             $uni2cp[$uni] = $cp unless defined($uni2cp[$uni]);
 719             next;
 720         }
 721         die "$name: Unrecognized line $_\n";
 722     }
 723     close $INPUT;
 724 }
 725
 726
 727 ################################################################
 728 # build the sort keys table
 729 sub READ_SORTKEYS_FILE()
 730 {
 731     my @sortkeys = ();
 732     for (my $i = 0; $i < 65536; $i++) { $sortkeys[$i] = [ -1, 0, 0, 0, 0 ] };
 733
 734     my $INPUT = open_data_file( $REPORTS, $SORTKEYS );
 735     while (<$INPUT>)
 736     {
 737         next if /^\#/;  # skip comments
 738         next if /^$/;  # skip empty lines
 739         next if /\x1a/;  # skip ^Z
 740         next if /^\@version/;  # skip @version header
 741         if (/^([0-9a-fA-F]+)\s+;\s+\[([*.])([0-9a-fA-F]{4})\.([0-9a-fA-F]{4})\.([0-9a-fA-F]{4})\.([0-9a-fA-F]+)\]/)
 742         {
 743             my ($uni,$variable) = (hex $1, $2);
 744             next if $uni > 65535;
 745             $sortkeys[$uni] = [ $uni, hex $3, hex $4, hex $5, hex $6 ];
 746             next;
 747         }
 748         if (/^([0-9a-fA-F]+\s+)+;\s+\[[*.]([0-9a-fA-F]{4})\.([0-9a-fA-F]{4})\.([0-9a-fA-F]{4})\.([0-9a-fA-F]+)\]/)
 749         {
 750             # multiple character sequence, ignored for now
 751             next;
 752         }
 753         die "$SORTKEYS: Unrecognized line $_\n";
 754     }
 755     close $INPUT;
 756
 757     # compress the keys to 32 bit:
 758     # key 1 to 16 bits, key 2 to 8 bits, key 3 to 4 bits, key 4 to 1 bit
 759
 760     @sortkeys = sort { ${$a}[1] <=> ${$b}[1] or
 761                        ${$a}[2] <=> ${$b}[2] or
 762                        ${$a}[3] <=> ${$b}[3] or
 763                        ${$a}[4] <=> ${$b}[4] or
 764                        $a cmp $b; } @sortkeys;
 765
 766     my ($n2, $n3) = (1, 1);
 767     my @keys = (-1, -1, -1, -1, -1 );
 768     my @flatkeys = ();
 769
 770     for (my $i = 0; $i < 65536; $i++)
 771     {
 772         my @current = @{$sortkeys[$i]};
 773         next if $current[0] == -1;
 774         if ($current[1] == $keys[1])
 775         {
 776             if ($current[2] == $keys[2])
 777             {
 778                 if ($current[3] == $keys[3])
 779                 {
 780                     # nothing
 781                 }
 782                 else
 783                 {
 784                     $keys[3] = $current[3];
 785                     $n3++;
 786                     die if ($n3 >= 16);
 787                 }
 788             }
 789             else
 790             {
 791                 $keys[2] = $current[2];
 792                 $keys[3] = $current[3];
 793                 $n2++;
 794                 $n3 = 1;
 795                 die if ($n2 >= 256);
 796             }
 797         }
 798         else
 799         {
 800             $keys[1] = $current[1];
 801             $keys[2] = $current[2];
 802             $keys[3] = $current[3];
 803             $n2 = 1;
 804             $n3 = 1;
 805         }
 806
 807         if ($current[2]) { $current[2] = $n2; }
 808         if ($current[3]) { $current[3] = $n3; }
 809         if ($current[4]) { $current[4] = 1; }
 810
 811         $flatkeys[$current[0]] = ($current[1] << 16) | ($current[2] << 8) | ($current[3] << 4) | $current[4];
 812     }
 813     return @flatkeys;
 814 }
 815
 816
 817 ################################################################
 818 # build the sort keys table
 819 sub DUMP_SORTKEYS($@)
 820 {
 821     my ($filename, @keys) = @_;
 822
 823     # count the number of 256-key ranges that contain something
 824
 825     my @offsets = ();
 826     my $ranges = 2;
 827     for (my $i = 0; $i < 256; $i++) { $offsets[$i] = 256; }
 828     for (my $i = 0; $i < 65536; $i++)
 829     {
 830         next unless defined $keys[$i];
 831         $offsets[$i >> 8] = $ranges * 256;
 832         $ranges++;
 833         $i |= 255;
 834     }
 835
 836     # output the range offsets
 837
 838     open OUTPUT,">$filename.new" or die "Cannot create $filename";
 839     printf "Building $filename\n";
 840     printf OUTPUT "/* Unicode collation element table */\n";
 841     printf OUTPUT "/* generated from %s */\n", "$REPORTS/$SORTKEYS";
 842     printf OUTPUT "/* DO NOT EDIT!! */\n\n";
 843
 844     printf OUTPUT "const unsigned int collation_table[%d] =\n{\n", $ranges*256;
 845     printf OUTPUT "    /* index */\n";
 846     printf OUTPUT "%s,\n", DUMP_ARRAY( "0x%08x", 0, @offsets );
 847
 848     # output the default values
 849
 850     printf OUTPUT "    /* defaults */\n";
 851     printf OUTPUT "%s", DUMP_ARRAY( "0x%08x", 0, (0xffffffff) x 256 );
 852
 853     # output all the key ranges
 854
 855     for (my $i = 0; $i < 256; $i++)
 856     {
 857         next if $offsets[$i] == 256;
 858         printf OUTPUT ",\n    /* 0x%02x00 .. 0x%02xff */\n", $i, $i;
 859         printf OUTPUT "%s", DUMP_ARRAY( "0x%08x", 0xffffffff, @keys[($i<<8) .. ($i<<8)+255] );
 860     }
 861     printf OUTPUT "\n};\n";
 862     close OUTPUT;
 863     save_file($filename);
 864 }
 865
 866
 867 ################################################################
 868 # add default mappings once the file had been read
 869 sub add_default_mappings($)
 870 {
 871     my $first_private = shift;
 872
 873     # Apply aliases
 874
 875     foreach my $alias (@unicode_aliases)
 876     {
 877         my $target = undef;
 878         foreach my $src (@$alias)
 879         {
 880             if (defined($uni2cp[$src]))
 881             {
 882                 $target = $uni2cp[$src];
 883                 last;
 884             }
 885         }
 886         next unless defined($target);
 887
 888         # At least one char of the alias set is defined, set the others to the same value
 889         foreach my $src (@$alias)
 890         {
 891             $uni2cp[$src] = $target unless defined($uni2cp[$src]);
 892         }
 893     }
 894
 895     # For every src -> target mapping in the defaults table,
 896     # make uni2cp[src] = uni2cp[target] if uni2cp[target] is defined
 897
 898     for (my $src = 0; $src < 65536; $src++)
 899     {
 900         next if defined($uni2cp[$src]);  # source has a definition already
 901         next unless defined($unicode_defaults[$src]);  # no default for this char
 902         my $target = $unicode_defaults[$src];
 903
 904         # do a recursive mapping until we find a target char that is defined
 905         while (!defined($uni2cp[$target]) &&
 906                defined($unicode_defaults[$target])) { $target = $unicode_defaults[$target]; }
 907
 908         if (defined($uni2cp[$target])) { $uni2cp[$src] = $uni2cp[$target]; }
 909     }
 910
 911     # Add a private char mapping for undefined chars
 912
 913     if ($first_private)
 914     {
 915         for (my $i = 32; $i < 256; $i++)
 916         {
 917             next if defined($cp2uni[$i]);
 918             $cp2uni[$i] = $first_private;
 919             $uni2cp[$first_private] = $i;
 920             $first_private++;
 921         }
 922     }
 923
 924     # Add an identity mapping for all undefined chars
 925
 926     for (my $i = 0; $i < 256; $i++)
 927     {
 928         next if defined($cp2uni[$i]);
 929         next if defined($uni2cp[$i]);
 930         $cp2uni[$i] = $uni2cp[$i] = $i;
 931     }
 932 }
 933
 934 ################################################################
 935 # dump an array of integers
 936 sub DUMP_ARRAY($$@)
 937 {
 938     my ($format,$default,@array) = @_;
 939     my $i;
 940     my $ret = "    ";
 941     for ($i = 0; $i < $#array; $i++)
 942     {
 943         $ret .= sprintf($format, defined $array[$i] ? $array[$i] : $default);
 944         $ret .= (($i % 8) != 7) ? ", " : ",\n    ";
 945     }
 946     $ret .= sprintf($format, defined $array[$i] ? $array[$i] : $default);
 947     return $ret;
 948 }
 949
 950
 951 ################################################################
 952 # dump a unicode->ascii mapping table
 953 sub dump_uni2cp_table($$)
 954 {
 955     my ($width, $def) = @_;
 956
 957     # count the number of unicode->ascii subtables that contain something
 958
 959     my @lowerbounds;
 960     my @upperbounds;
 961     my $index = 0;
 962     my @filled = (-1) x 256;
 963     for (my $i = 0; $i < 65536; $i++)
 964     {
 965         next unless defined $uni2cp[$i];
 966         if ($filled[$i >> 8] == -1)
 967         {
 968           $lowerbounds[$index] = $i & 0xff;
 969           $upperbounds[$index] = 0xff - $lowerbounds[$index];
 970           $filled[$i >> 8] = $index * 256;
 971           $index++;
 972         }
 973         else
 974         {
 975           $upperbounds[$index-1] = 0xff - ($i & 0xff);
 976         }
 977     }
 978
 979     # add defaults mapping at the end
 980     $filled[256] = $index * 256;
 981     $lowerbounds[$index] = 255;
 982     $upperbounds[$index] = 0;
 983     $index++;
 984
 985     # collapse blocks upwards if possible
 986     my $removed = 0;
 987     $index = 0;
 988     for (my $i = 0; $i < 257; $i++)
 989     {
 990         next if $filled[$i] == -1;
 991         if ($upperbounds[$index - 1] > $lowerbounds[$index])
 992         {
 993            $removed += $lowerbounds[$index];
 994         }
 995         else
 996         {
 997            $removed += $upperbounds[$index - 1];
 998            $lowerbounds[$index] = $upperbounds[$index - 1];
 999         }
1000         $filled[$i] -= $removed;
1001         $index++;
1002     }
1003
1004     # output all the subtables into a single array
1005
1006     printf OUTPUT "static const unsigned %s uni2cp_low[%d] =\n{\n",
1007                   $width == 8 ? "char" : "short", ($index + 1) * 256 - $removed;
1008
1009     my $format = $width == 8 ? "0x%02x" : "0x%04x";
1010     for (my $i = $index = 0; $i < 257; $i++)
1011     {
1012         next if $filled[$i] == -1;
1013         my $start = ($i << 8) + $lowerbounds[$index];
1014         my $end = ($i << 8) + 255;
1015         if ($i == 256)
1016         {
1017             print OUTPUT "    /* defaults */\n";
1018             printf OUTPUT "%s\n};\n\n", DUMP_ARRAY( $format, 0, ($def) x ($end - $start + 1) );
1019         }
1020         else
1021         {
1022             printf OUTPUT "    /* 0x%04x .. 0x%04x */\n", $start, $end;
1023             printf OUTPUT "%s,\n", DUMP_ARRAY( $format, $def, @uni2cp[$start .. $end] );
1024         }
1025         $index++;
1026     }
1027
1028     # output a table of the offsets of the subtables in the previous array
1029
1030     for (my $i = 0; $i < 256; $i++)
1031     {
1032         if ($filled[$i] == -1) { $filled[$i] = $filled[256]; }
1033     }
1034     printf OUTPUT "static const unsigned short uni2cp_high[256] =\n";
1035     printf OUTPUT "{\n%s\n};\n\n", DUMP_ARRAY( "0x%04x", 0, @filled[0..255] );
1036 }
1037
1038 ################################################################
1039 # dump an SBCS mapping table
1040 sub dump_sbcs_table($$$$$)
1041 {
1042     my ($codepage, $has_glyphs, $name, $def, $defw) = @_;
1043     my $i;
1044
1045     # output the ascii->unicode table
1046
1047     if ($has_glyphs)
1048     {
1049         printf OUTPUT "static const WCHAR cp2uni[512] =\n";
1050         printf OUTPUT "{\n%s", DUMP_ARRAY( "0x%04x", $defw, @cp2uni[0 .. 255] );
1051         printf OUTPUT ",\n    /* glyphs */\n%s\n};\n\n",
1052                       DUMP_ARRAY( "0x%04x", $defw, get_glyphs_mapping(@cp2uni[0 .. 255]) );
1053     }
1054     else
1055     {
1056         printf OUTPUT "static const WCHAR cp2uni[256] =\n";
1057         printf OUTPUT "{\n%s\n};\n\n", DUMP_ARRAY( "0x%04x", $defw, @cp2uni[0 .. 255] );
1058     }
1059
1060     dump_uni2cp_table( 8, $def );
1061
1062     # output the code page descriptor
1063
1064     printf OUTPUT "const struct sbcs_table DECLSPEC_HIDDEN cptable_%03d =\n{\n", $codepage;
1065     printf OUTPUT "    { %d, 1, 0x%04x, 0x%04x, \"%s\" },\n",
1066                   $codepage, $def, $defw, $name;
1067     printf OUTPUT "    cp2uni,\n";
1068     if ($has_glyphs) { printf OUTPUT "    cp2uni + 256,\n"; }
1069     else { printf OUTPUT "    cp2uni,\n"; }
1070     printf OUTPUT "    uni2cp_low,\n";
1071     printf OUTPUT "    uni2cp_high\n};\n";
1072 }
1073
1074
1075 ################################################################
1076 # dump a DBCS mapping table
1077 sub dump_dbcs_table($$$$@)
1078 {
1079     my ($codepage, $name, $def, $defw, @lb_ranges) = @_;
1080
1081     # build a list of lead bytes that are actually used
1082
1083     my @lblist = ();
1084     LBLOOP: for (my $y = 0; $y <= $#lead_bytes; $y++)
1085     {
1086         $cp2uni[$lead_bytes[$y]] = $defw;
1087         my $base = $lead_bytes[$y] << 8;
1088         for (my $x = 0; $x < 256; $x++)
1089         {
1090             if (defined $cp2uni[$base+$x])
1091             {
1092                 push @lblist,$lead_bytes[$y];
1093                 next LBLOOP;
1094             }
1095         }
1096     }
1097     my $unused = ($#lead_bytes > $#lblist);
1098
1099     # output the ascii->unicode table for the single byte chars
1100
1101     printf OUTPUT "static const WCHAR cp2uni[%d] =\n", 256 * ($#lblist + 2 + $unused);
1102     printf OUTPUT "{\n%s,\n", DUMP_ARRAY( "0x%04x", $defw, @cp2uni[0 .. 255] );
1103
1104     # output the default table for unused lead bytes
1105
1106     if ($unused)
1107     {
1108         printf OUTPUT "    /* unused lead bytes */\n";
1109         printf OUTPUT "%s,\n", DUMP_ARRAY( "0x%04x", 0, ($defw) x 256 );
1110     }
1111
1112     # output the ascii->unicode table for each DBCS lead byte
1113
1114     for (my $y = 0; $y <= $#lblist; $y++)
1115     {
1116         my $base = $lblist[$y] << 8;
1117         printf OUTPUT "    /* lead byte %02x */\n", $lblist[$y];
1118         printf OUTPUT "%s", DUMP_ARRAY( "0x%04x", $defw, @cp2uni[$base .. $base+255] );
1119         printf OUTPUT ($y < $#lblist) ? ",\n" : "\n};\n\n";
1120     }
1121
1122     # output the lead byte subtables offsets
1123
1124     my @offsets = (0) x 256;
1125     for (my $x = 0; $x <= $#lblist; $x++) { $offsets[$lblist[$x]] = $x + 1; }
1126     if ($unused)
1127     {
1128         # increment all lead bytes offset to take into account the unused table
1129         for (my $x = 0; $x <= $#lead_bytes; $x++) { $offsets[$lead_bytes[$x]]++; }
1130     }
1131     printf OUTPUT "static const unsigned char cp2uni_leadbytes[256] =\n";
1132     printf OUTPUT "{\n%s\n};\n\n", DUMP_ARRAY( "0x%02x", 0, @offsets );
1133
1134     dump_uni2cp_table( 16, $def );
1135
1136     # output the code page descriptor
1137
1138     printf OUTPUT "const struct dbcs_table DECLSPEC_HIDDEN cptable_%03d =\n{\n", $codepage;
1139     printf OUTPUT "    { %d, 2, 0x%04x, 0x%04x, \"%s\" },\n",
1140                   $codepage, $def, $defw, $name;
1141     printf OUTPUT "    cp2uni,\n";
1142     printf OUTPUT "    cp2uni_leadbytes,\n";
1143     printf OUTPUT "    uni2cp_low,\n";
1144     printf OUTPUT "    uni2cp_high,\n";
1145     printf OUTPUT "    {\n    %s\n    }\n", DUMP_ARRAY( "0x%02x", 0, @lb_ranges, 0, 0 );
1146     printf OUTPUT "};\n";
1147 }
1148
1149
1150 ################################################################
1151 # get the list of defined lead byte ranges
1152 sub get_lb_ranges()
1153 {
1154     my @list = ();
1155     my @ranges = ();
1156     my $i = 0;
1157     foreach $i (@lead_bytes) { $list[$i] = 1; }
1158     my $on = 0;
1159     for (my $i = 0; $i < 256; $i++)
1160     {
1161         if ($on)
1162         {
1163             if (!defined $list[$i]) { push @ranges, $i-1; $on = 0; }
1164         }
1165         else
1166         {
1167             if ($list[$i]) { push @ranges, $i; $on = 1; }
1168         }
1169     }
1170     if ($on) { push @ranges, 0xff; }
1171     return @ranges;
1172 }
1173
1174 ################################################################
1175 # dump the Indic Syllabic Category table
1176 sub dump_indic($)
1177 {
1178     my $filename = shift;
1179     my @indic_table;
1180
1181     my $INPUT = open_data_file( $UNIDATA, "IndicSyllabicCategory.txt" );
1182     while (<$INPUT>)
1183     {
1184         next if /^\#/;  # skip comments
1185         next if /^\s*$/;  # skip empty lines
1186         next if /\x1a/;  # skip ^Z
1187         if (/^\s*([0-9a-fA-F]+)\s*;\s*([a-zA-Z_]+)\s*#/)
1188         {
1189             my $type = $2;
1190             die "unknown indic $type" unless defined $indic_types{$type};
1191             if (hex $1 < 65536)
1192             {
1193                 $indic_table[hex $1] = $indic_types{$type};
1194             }
1195             next;
1196         }
1197         elsif (/^\s*([0-9a-fA-F]+)..\s*([0-9a-fA-F]+)\s*;\s*([A-Za-z_]+)\s*#/)
1198         {
1199             my $type = $3;
1200             die "unknown indic $type" unless defined $indic_types{$type};
1201             if (hex $1 < 65536 and hex $2 < 65536)
1202             {
1203                 foreach my $i (hex $1 .. hex $2)
1204                 {
1205                     $indic_table[$i] = $indic_types{$type};
1206                 }
1207             }
1208             next;
1209         }
1210         die "malformed line $_";
1211     }
1212     close $INPUT;
1213
1214     $INPUT = open_data_file( $UNIDATA, "IndicPositionalCategory.txt" );
1215     while (<$INPUT>)
1216     {
1217         next if /^\#/;  # skip comments
1218         next if /^\s*$/;  # skip empty lines
1219         next if /\x1a/;  # skip ^Z
1220         if (/^\s*([0-9a-fA-F]+)\s*;\s*([a-zA-Z]+)\s*#/)
1221         {
1222             my $type = $2;
1223             die "unknown matra $type" unless defined $matra_types{$type};
1224             $indic_table[hex $1] += $matra_types{$type} << 8;
1225             next;
1226         }
1227         elsif (/^\s*([0-9a-fA-F]+)..\s*([0-9a-fA-F]+)\s*;\s*([A-Za-z_]+)\s*#/)
1228         {
1229             my $type = $3;
1230             die "unknown matra $type" unless defined $matra_types{$type};
1231             foreach my $i (hex $1 .. hex $2)
1232             {
1233                 $indic_table[$i] += $matra_types{$type} << 8;
1234             }
1235             next;
1236         }
1237         die "malformed line $_";
1238     }
1239     close $INPUT;
1240
1241     open OUTPUT,">$filename.new" or die "Cannot create $filename";
1242     print "Building $filename\n";
1243     print OUTPUT "/* Unicode Indic Syllabic Category */\n";
1244     print OUTPUT "/* generated from $UNIDATA/IndicSyllabicCategory.txt */\n";
1245     print OUTPUT "/*       and from $UNIDATA/IndicPositionalCategory.txt */\n";
1246     print OUTPUT "/* DO NOT EDIT!! */\n\n";
1247     print OUTPUT "#include \"wine/unicode.h\"\n\n";
1248
1249     dump_two_level_mapping( "indic_syllabic_table", $indic_types{'Other'}, @indic_table );
1250
1251     close OUTPUT;
1252     save_file($filename);
1253 }
1254
1255 ################################################################
1256 # dump the Line Break Properties table
1257 sub dump_linebreak($)
1258 {
1259     my $filename = shift;
1260     my @break_table;
1261     my $next_group = 0;
1262
1263     my $INPUT = open_data_file( $UNIDATA, "LineBreak.txt" );
1264     while (<$INPUT>)
1265     {
1266         next if /^\#/;  # skip comments
1267         next if /^\s*$/;  # skip empty lines
1268         next if /\x1a/;  # skip ^Z
1269         if (/^\s*([0-9a-fA-F]+)\s*;\s*([0-9A-Z][0-9A-Z])+\s*/)
1270         {
1271             my $type = $2;
1272             die "unknown breaktype $type" unless defined $break_types{$type};
1273             $break_table[hex $1] = $break_types{$type};
1274             next;
1275         }
1276         elsif (/^\s*([0-9a-fA-F]+)..\s*([0-9a-fA-F]+)\s*;\s*([0-9A-Z][0-9A-Z])+\s*/)
1277         {
1278             my $type = $3;
1279             die "unknown breaktype $type" unless defined $break_types{$type};
1280             foreach my $i (hex $1 .. hex $2)
1281             {
1282                 $break_table[$i] = $break_types{$type};
1283             }
1284             next;
1285         }
1286         die "malformed line $_";
1287     }
1288     close $INPUT;
1289
1290     open OUTPUT,">$filename.new" or die "Cannot create $filename";
1291     print "Building $filename\n";
1292     print OUTPUT "/* Unicode Line Break Properties */\n";
1293     print OUTPUT "/* generated from $UNIDATA/LineBreak.txt */\n";
1294     print OUTPUT "/* DO NOT EDIT!! */\n\n";
1295     print OUTPUT "#include \"wine/unicode.h\"\n\n";
1296
1297     dump_two_level_mapping( "wine_linebreak_table", $break_types{'XX'}, @break_table );
1298
1299     close OUTPUT;
1300     save_file($filename);
1301 }
1302
1303 ################################################################
1304 # dump Script IDs table
1305 sub dump_scripts($)
1306 {
1307     my $filename = shift;
1308     my $header = $filename;
1309     my @scripts_table;
1310     my $script_index;
1311     my %scripts;
1312     my $i;
1313
1314     my $INPUT = open_data_file( $UNIDATA, "Scripts.txt" );
1315     while (<$INPUT>)
1316     {
1317         my $type = "";
1318
1319         next if /^\#/;  # skip comments
1320         next if /^\s*$/;  # skip empty lines
1321         next if /\x1a/;  # skip ^Z
1322         if (/^\s*([0-9a-fA-F]+)\s*;\s*([_a-zA-Z]+)\s*/)
1323         {
1324             $type = $2;
1325         }
1326         elsif (/^\s*([0-9a-fA-F]+)..\s*([0-9a-fA-F]+)\s*;\s*([_a-zA-Z]+)\s*/)
1327         {
1328             $type = $3;
1329         }
1330         else
1331         {
1332             die "malformed line $_";
1333         }
1334
1335         # ignore some scripts
1336         if ($type eq "Common" || $type eq "Inherited")
1337         {
1338             next;
1339         }
1340
1341         $scripts{$type} = -1;
1342     }
1343
1344     # assign script indices, starting from index 2
1345     $script_index = 1;
1346     foreach my $script (sort keys %scripts) {
1347         $scripts{$script} = ++$script_index;
1348     }
1349     # indices change when new scripts are added to the standard,
1350     # keep Unknown/Common at fixed positions, Inherited is treated as Unknown
1351     $scripts{"Unknown"} = 0;
1352     $scripts{"Inherited"} = 0;
1353     $scripts{"Common"} = 1;
1354
1355     # now fill a table
1356     seek $INPUT, 0, 0;
1357     while (<$INPUT>)
1358     {
1359         my $type = "";
1360
1361         next if /^\#/;  # skip comments
1362         next if /^\s*$/;  # skip empty lines
1363         next if /\x1a/;  # skip ^Z
1364         if (/^\s*([0-9a-fA-F]+)\s*;\s*([a-zA-Z]+)\s*/)
1365         {
1366             $type = $2;
1367             if (defined $scripts{$type})
1368             {
1369                 $scripts_table[hex $1] = $scripts{$type};
1370             }
1371             next;
1372         }
1373         elsif (/^\s*([0-9a-fA-F]+)..\s*([0-9a-fA-F]+)\s*;\s*([a-zA-Z]+)\s*/)
1374         {
1375             $type = $3;
1376             if (defined $scripts{$type})
1377             {
1378                 foreach my $i (hex $1 .. hex $2)
1379                 {
1380                     $scripts_table[$i] = $scripts{$type};
1381                 }
1382             }
1383             next;
1384         }
1385     }
1386
1387     close $INPUT;
1388
1389     $header = "$filename.h";
1390     open OUTPUT,">$header.new" or die "Cannot create $header";
1391     print "Building $header\n";
1392     print OUTPUT "/* Unicode Script IDs */\n";
1393     print OUTPUT "/* generated from $UNIDATA/Scripts.txt */\n";
1394     print OUTPUT "/* DO NOT EDIT!! */\n\n";
1395
1396     # Inherited was consumed by Unknown, we don't need it as a separate enum member
1397     delete $scripts{"Inherited"};
1398     print OUTPUT "enum unicode_script_id {\n";
1399     foreach my $script (sort { $scripts{$a} <=> $scripts{$b} } keys %scripts)
1400     {
1401         print OUTPUT "    Script_$script = $scripts{$script},\n";
1402     }
1403     print OUTPUT "    Script_LastId = $script_index\n";
1404     print OUTPUT "};\n";
1405
1406     close OUTPUT;
1407     save_file($header);
1408
1409     $filename = "$filename.c";
1410     open OUTPUT,">$filename.new" or die "Cannot create $header";
1411     print "Building $filename\n";
1412     print OUTPUT "/* Unicode Script IDs */\n";
1413     print OUTPUT "/* generated from $UNIDATA/Scripts.txt */\n";
1414     print OUTPUT "/* DO NOT EDIT!! */\n\n";
1415     print OUTPUT "#include \"wine/unicode.h\"\n\n";
1416
1417     dump_two_level_mapping( "wine_scripts_table", 0, @scripts_table );
1418     close OUTPUT;
1419     save_file($filename);
1420 }
1421
1422 ################################################################
1423 # dump the BiDi mirroring table
1424 sub dump_mirroring($)
1425 {
1426     my $filename = shift;
1427     my @mirror_table = ();
1428
1429     my $INPUT = open_data_file( $UNIDATA, "BidiMirroring.txt" );
1430     while (<$INPUT>)
1431     {
1432         next if /^\#/;  # skip comments
1433         next if /^$/;  # skip empty lines
1434         next if /\x1a/;  # skip ^Z
1435         if (/^\s*([0-9a-fA-F]+)\s*;\s*([0-9a-fA-F]+)/)
1436         {
1437             $mirror_table[hex $1] = hex $2;
1438             next;
1439         }
1440         die "malformed line $_";
1441     }
1442     close $INPUT;
1443
1444     open OUTPUT,">$filename.new" or die "Cannot create $filename";
1445     print "Building $filename\n";
1446     print OUTPUT "/* Unicode BiDi mirroring */\n";
1447     print OUTPUT "/* generated from $UNIDATA/BidiMirroring.txt */\n";
1448     print OUTPUT "/* DO NOT EDIT!! */\n\n";
1449     print OUTPUT "#include \"wine/unicode.h\"\n\n";
1450     DUMP_CASE_TABLE( "DECLSPEC_HIDDEN wine_mirror_map", @mirror_table );
1451     close OUTPUT;
1452     save_file($filename);
1453 }
1454
1455 ################################################################
1456 # dump the Bidi Brackets
1457 sub dump_bracket($)
1458 {
1459     my $filename = shift;
1460     my @bracket_table;
1461
1462     my $INPUT = open_data_file( $UNIDATA, "BidiBrackets.txt" );
1463     while (<$INPUT>)
1464     {
1465         next if /^\#/;  # skip comments
1466         next if /^\s*$/;  # skip empty lines
1467         next if /\x1a/;  # skip ^Z
1468         if (/^\s*([0-9a-fA-F]+)\s*;\s*([0-9a-fA-F]+);\s*([con])/)
1469         {
1470             my $type = $3;
1471             die "unknown bracket $type" unless defined $bracket_types{$type};
1472             die "characters too distant $1 and $2" if abs(hex($2) - hex($1)) >= 128;
1473             $bracket_table[hex $1] = (hex($2) - hex($1)) % 255;
1474             $bracket_table[hex $1] += $bracket_types{$type} << 8;
1475             next;
1476         }
1477         die "malformed line $_";
1478     }
1479     close $INPUT;
1480
1481     open OUTPUT,">$filename.new" or die "Cannot create $filename";
1482     print "Building $filename\n";
1483     print OUTPUT "/* Unicode Bidirectional Bracket table */\n";
1484     print OUTPUT "/* generated from $UNIDATA/BidiBrackets.txt */\n";
1485     print OUTPUT "/* DO NOT EDIT!! */\n\n";
1486     print OUTPUT "#include \"wine/unicode.h\"\n\n";
1487
1488     dump_two_level_mapping( "bidi_bracket_table", 0, @bracket_table );
1489
1490     close OUTPUT;
1491     save_file($filename);
1492 }
1493
1494 ################################################################
1495 # dump the Arabic shaping table
1496 sub dump_shaping($)
1497 {
1498     my $filename = shift;
1499     my %groups;
1500     my $next_group = 0;
1501
1502     $groups{"No_Joining_Group"} = $next_group++;
1503
1504     my $INPUT = open_data_file( $UNIDATA, "ArabicShaping.txt" );
1505     while (<$INPUT>)
1506     {
1507         next if /^\#/;  # skip comments
1508         next if /^\s*$/;  # skip empty lines
1509         next if /\x1a/;  # skip ^Z
1510         if (/^\s*([0-9a-fA-F]+)\s*;.*;\s*([RLDCUT])\s*;\s*(\w+)/)
1511         {
1512             my $type = $2;
1513             my $group = $3;
1514             $groups{$group} = $next_group++ unless defined $groups{$group};
1515             $joining_table[hex $1] = $joining_types{$type} | ($groups{$group} << 8);
1516             next;
1517         }
1518         die "malformed line $_";
1519     }
1520     close $INPUT;
1521
1522     open OUTPUT,">$filename.new" or die "Cannot create $filename";
1523     print "Building $filename\n";
1524     print OUTPUT "/* Unicode Arabic shaping */\n";
1525     print OUTPUT "/* generated from $UNIDATA/ArabicShaping.txt */\n";
1526     print OUTPUT "/* DO NOT EDIT!! */\n\n";
1527     print OUTPUT "#include \"wine/unicode.h\"\n\n";
1528
1529     dump_two_level_mapping( "wine_shaping_table", 0, @joining_table );
1530
1531     print OUTPUT "\nconst unsigned short DECLSPEC_HIDDEN wine_shaping_forms[256][4] =\n{\n";
1532     for (my $i = 0x600; $i <= 0x6ff; $i++)
1533     {
1534         printf OUTPUT "    { 0x%04x, 0x%04x, 0x%04x, 0x%04x },\n",
1535             ${joining_forms{"isolated"}}[$i] || $i,
1536             ${joining_forms{"final"}}[$i] || $i,
1537             ${joining_forms{"initial"}}[$i] || $i,
1538             ${joining_forms{"medial"}}[$i] || $i;
1539     }
1540     print OUTPUT "};\n";
1541
1542     close OUTPUT;
1543     save_file($filename);
1544 }
1545
1546 ################################################################
1547 # dump the Vertical Orientation table
1548 sub dump_vertical($)
1549 {
1550     my $filename = shift;
1551     my @vertical_table;
1552
1553     my $INPUT = open_data_file( $VERTICALDATA, "VerticalOrientation-15.txt" );
1554     while (<$INPUT>)
1555     {
1556         next if /^\#/;  # skip comments
1557         next if /^\s*$/;  # skip empty lines
1558         next if /\x1a/;  # skip ^Z
1559         if (/^\s*([0-9a-fA-F]+)\s*;\s*([a-zA-Z_]+)\s*/)
1560         {
1561             my $type = $2;
1562             die "unknown vertical $type" unless defined $vertical_types{$type};
1563             if (hex $1 < 65536)
1564             {
1565                 $vertical_table[hex $1] = $vertical_types{$type};
1566             }
1567             next;
1568         }
1569         elsif (/^\s*([0-9a-fA-F]+)..\s*([0-9a-fA-F]+)\s*;\s*([A-Za-z_]+)\s*/)
1570         {
1571             my $type = $3;
1572             die "unknown vertical $type" unless defined $vertical_types{$type};
1573             foreach my $i (hex $1 .. hex $2)
1574             {
1575                 $vertical_table[$i] = $vertical_types{$type};
1576             }
1577             next;
1578         }
1579         die "malformed line $_";
1580     }
1581     close $INPUT;
1582
1583     open OUTPUT,">$filename.new" or die "Cannot create $filename";
1584     print "Building $filename\n";
1585     print OUTPUT "/* Unicode Vertical Orientation */\n";
1586     print OUTPUT "/* generated from $VERTICALDATA/VerticalOrientation-15.txt */\n";
1587     print OUTPUT "/* DO NOT EDIT!! */\n\n";
1588     print OUTPUT "#include \"wine/unicode.h\"\n\n";
1589
1590     dump_two_level_mapping( "vertical_orientation_table", $vertical_types{'R'}, @vertical_table );
1591
1592     close OUTPUT;
1593     save_file($filename);
1594 }
1595
1596 ################################################################
1597 # dump the digit folding tables
1598 sub dump_digit_folding($)
1599 {
1600     my $filename = shift;
1601     open OUTPUT,">$filename.new" or die "Cannot create $filename";
1602     print "Building $filename\n";
1603     print OUTPUT "/* Unicode digit folding mappings */\n";
1604     print OUTPUT "/* generated from $UNIDATA/UnicodeData.txt */\n";
1605     print OUTPUT "/* DO NOT EDIT!! */\n\n";
1606     print OUTPUT "#include \"wine/unicode.h\"\n\n";
1607
1608     DUMP_CASE_TABLE( "DECLSPEC_HIDDEN wine_digitmap",  @digitmap_table );
1609     print OUTPUT "\n";
1610     DUMP_CASE_TABLE( "DECLSPEC_HIDDEN wine_compatmap", @compatmap_table );
1611     close OUTPUT;
1612     save_file($filename);
1613 }
1614
1615
1616 ################################################################
1617 # dump the case mapping tables
1618 sub DUMP_CASE_MAPPINGS($)
1619 {
1620     my $filename = shift;
1621     open OUTPUT,">$filename.new" or die "Cannot create $filename";
1622     print "Building $filename\n";
1623     print OUTPUT "/* Unicode case mappings */\n";
1624     print OUTPUT "/* generated from $UNIDATA/UnicodeData.txt */\n";
1625     print OUTPUT "/* DO NOT EDIT!! */\n\n";
1626     print OUTPUT "#include \"wine/unicode.h\"\n\n";
1627
1628     DUMP_CASE_TABLE( "wine_casemap_lower", @tolower_table );
1629     print OUTPUT "\n";
1630     DUMP_CASE_TABLE( "wine_casemap_upper", @toupper_table );
1631     close OUTPUT;
1632     save_file($filename);
1633 }
1634
1635
1636 ################################################################
1637 # dump a case mapping table
1638 sub DUMP_CASE_TABLE($@)
1639 {
1640     my ($name,@table) = @_;
1641
1642     # count the number of sub tables that contain something
1643     # also compute the low and upper populated bounds
1644
1645     my @lowerbounds = ( 0, 0 );
1646     my @upperbounds = ( 0, 255 );
1647     my $index = 0;
1648     my @filled = ();
1649     for (my $i = 0; $i < 65536; $i++)
1650     {
1651         next unless defined $table[$i];
1652         if (!defined $filled[$i >> 8])
1653         {
1654           $lowerbounds[$index] = $i & 0xff;
1655           $upperbounds[$index] = 0xff - $lowerbounds[$index];
1656           $filled[$i >> 8] = $index * 256 + 512;
1657           $index++;
1658         }
1659         else
1660         {
1661           $upperbounds[$index-1] = 0xff - ($i & 0xff);
1662         }
1663         $table[$i] = ($table[$i] - $i) & 0xffff;
1664     }
1665
1666     # Collapse blocks upwards if possible
1667     my $removed = 0;
1668     $index = 0;
1669     for (my $i = 0; $i < 256; $i++)
1670     {
1671         next unless defined $filled[$i];
1672         if ($upperbounds[$index - 1] > $lowerbounds[$index])
1673         {
1674            $removed = $removed + $lowerbounds[$index];
1675         }
1676         else
1677         {
1678            $removed = $removed + $upperbounds[$index - 1];
1679            $lowerbounds[$index] = $upperbounds[$index - 1];
1680         }
1681         $filled[$i] = $filled[$i] - $removed;
1682         $index++;
1683     }
1684
1685     # dump the table
1686
1687     printf OUTPUT "const WCHAR %s[%d] =\n", $name, $index * 256 + 512 - $removed;
1688     printf OUTPUT "{\n    /* index */\n";
1689     printf OUTPUT "%s,\n", DUMP_ARRAY( "0x%04x", 256, @filled );
1690     printf OUTPUT "    /* defaults */\n";
1691     printf OUTPUT "%s", DUMP_ARRAY( "0x%04x", 0, (0) x 256 );
1692     $index = 0;
1693     for (my $i = 0; $i < 256; $i++)
1694     {
1695         next unless $filled[$i];
1696         printf OUTPUT ",\n    /* 0x%02x%02x .. 0x%02xff */\n", $i, $lowerbounds[$index], $i;
1697         printf OUTPUT "%s", DUMP_ARRAY( "0x%04x", 0,
1698                       @table[($i<<8) + $lowerbounds[$index] .. ($i<<8)+255] );
1699         $index++;
1700     }
1701     printf OUTPUT "\n};\n";
1702 }
1703
1704 ################################################################
1705 # compress a mapping table by removing identical rows
1706 sub compress_array($$@)
1707 {
1708     my $rows = shift;
1709     my $def = shift;
1710     my @table = @_;
1711     my $len = @table / $rows;
1712     my @array = (0) x $rows;
1713     my %sequences;
1714
1715     # try to merge table rows
1716     for (my $row = 0; $row < $rows; $row++)
1717     {
1718         my @table_row = map { defined($_) ? $_ : $def; } @table[($row * $len)..($row * $len + $len - 1)];
1719         my $rowtxt = pack "S*", @table_row;
1720         if (defined($sequences{$rowtxt}))
1721         {
1722             # reuse an existing row
1723             $array[$row] = $sequences{$rowtxt};
1724         }
1725         else
1726         {
1727             # create a new row
1728             $sequences{$rowtxt} = $array[$row] = $#array + 1;
1729             push @array, @table_row;
1730         }
1731     }
1732     return @array;
1733 }
1734
1735 ################################################################
1736 # dump a simple char -> 16-bit value mapping table
1737 sub dump_simple_mapping($$@)
1738 {
1739     my $name = shift;
1740     my $def = shift;
1741     my @array = compress_array( 256, $def, @_[0..65535] );
1742
1743     printf OUTPUT "const unsigned short %s[%d] =\n{\n", $name, $#array+1;
1744     printf OUTPUT "    /* offsets */\n%s,\n", DUMP_ARRAY( "0x%04x", 0, @array[0..255] );
1745     printf OUTPUT "    /* values */\n%s\n};\n", DUMP_ARRAY( "0x%04x", 0, @array[256..$#array] );
1746 }
1747
1748 ################################################################
1749 # dump a char -> 16-bit value mapping table using two-level tables
1750 sub dump_two_level_mapping($$@)
1751 {
1752     my $name = shift;
1753     my $def = shift;
1754     my @row_array = compress_array( 4096, $def, @_[0..65535] );
1755     my @array = compress_array( 256, 0, @row_array[0..4095] );
1756
1757     for (my $i = 256; $i < @array; $i++) { $array[$i] += @array - 4096; }
1758
1759     printf OUTPUT "const unsigned short DECLSPEC_HIDDEN %s[%d] =\n{\n", $name, @array + @row_array - 4096;
1760     printf OUTPUT "    /* level 1 offsets */\n%s,\n", DUMP_ARRAY( "0x%04x", 0, @array[0..255] );
1761     printf OUTPUT "    /* level 2 offsets */\n%s,\n", DUMP_ARRAY( "0x%04x", 0, @array[256..$#array] );
1762     printf OUTPUT "    /* values */\n%s\n};\n", DUMP_ARRAY( "0x%04x", 0, @row_array[4096..$#row_array] );
1763 }
1764
1765 ################################################################
1766 # dump a binary case mapping table in l_intl.nls format
1767 sub dump_binary_case_table(@)
1768 {
1769     my (@table) = @_;
1770
1771     my %difftables_hash = ();
1772     my @difftables;
1773     my %offtables2_hash = ();
1774     my @offtables2 = ();
1775
1776     my @offtable = ();
1777     for (my $i = 0; $i < 256; $i++)
1778     {
1779         my @offtable2 = ();
1780         for(my $j = 0; $j < 16; $j++) # offset table for xx00-xxFF characters
1781         {
1782             my @difftable;
1783             for (my $k = 0; $k < 16; $k++) # case map table for xxx0-xxxF characters
1784             {
1785                 my $char = ($i<<8) + ($j<<4) + $k;
1786                 $difftable[$k] = (defined $table[$char]) ? (($table[$char]-$char) & 0xffff) : 0;
1787             }
1788
1789             my $diff_key = pack "S*", @difftable;
1790             my $offset3 = $difftables_hash{$diff_key};
1791             if (!defined $offset3)
1792             {
1793                 $offset3 = scalar @difftables;
1794                 $difftables_hash{$diff_key} = $offset3;
1795                 push @difftables, @difftable;
1796             }
1797             $offtable2[$j] = $offset3;
1798         }
1799
1800         my $offtable2_key = pack "S*", @offtable2;
1801         my $offset2 = $offtables2_hash{$offtable2_key};
1802         if (!defined $offset2)
1803         {
1804             $offset2 = scalar @offtables2;
1805             $offtables2_hash{$offtable2_key} = $offset2;
1806             push @offtables2, \@offtable2;
1807         }
1808         $offtable[$i] = $offset2;
1809     }
1810
1811     my @output;
1812     my $offset = 0x100; # offset of first subtable in words
1813     foreach (@offtable)
1814     {
1815         push @output, 0x10 * $_ + $offset; # offset of subtable in words
1816     }
1817
1818     $offset = 0x100 + 0x10 * scalar @offtables2; # offset of first difftable in words
1819     foreach(@offtables2)
1820     {
1821         my $table = $_;
1822         foreach(@$table)
1823         {
1824             push @output, $_ + $offset; # offset of difftable in words
1825         }
1826     }
1827
1828     my $len = 1 + scalar @output + scalar @difftables;
1829     return pack "S<*", $len, @output, @difftables;
1830 }
1831
1832
1833 ################################################################
1834 # dump case mappings for l_intl.nls
1835 sub dump_intl_nls($)
1836 {
1837     my $filename = shift;
1838     open OUTPUT,">$filename.new" or die "Cannot create $filename";
1839     printf "Building $filename\n";
1840
1841     binmode OUTPUT;
1842     print OUTPUT pack "S<", 1;  # version
1843     print OUTPUT dump_binary_case_table( @toupper_table );
1844     print OUTPUT dump_binary_case_table( @tolower_table );
1845     close OUTPUT;
1846     save_file($filename);
1847 }
1848
1849
1850 sub load_nameprep_range_table($$$)
1851 {
1852     my ($INPUT, $val, $table_ref) = @_;
1853
1854     while (<$INPUT>)
1855     {
1856         if (/^\s*([0-9a-fA-F]+)-([0-9a-fA-F]+)/)
1857         {
1858             my $last = hex $2;
1859             $last = 65535 if($last >= 65536);
1860             foreach my $i (hex $1 .. $last)
1861             {
1862                 $table_ref->[$i] |= $val;
1863             }
1864             next;
1865         }
1866         elsif (/^\s*([0-9a-fA-F]+)/)
1867         {
1868             if (hex $1 < 65536)
1869             {
1870                 $table_ref->[hex $1] |= $val;
1871             }
1872             next;
1873         }
1874
1875         return if (/End\sTable/);
1876     }
1877 }
1878
1879 sub load_nameprep_map_table($$)
1880 {
1881     my ($INPUT, $table_ref) = @_;
1882
1883     while (<$INPUT>)
1884     {
1885         if (/^\s*([0-9a-fA-F]+);\s;/)
1886         {
1887             # special value for map to nothing
1888             $table_ref->[hex $1] = [0xffff, 0xffff, 0xffff];
1889             next;
1890         }
1891         elsif (/^\s*([0-9a-fA-F]+);\s([0-9a-fA-F]+);/)
1892         {
1893             $table_ref->[hex $1] = [hex $2, 0, 0];
1894             next;
1895         }
1896         elsif (/^\s*([0-9a-fA-F]+);\s([0-9a-fA-F]+)\s([0-9a-fA-F]+);/)
1897         {
1898             $table_ref->[hex $1] = [hex $2, hex $3, 0];
1899             next;
1900         }
1901         elsif (/^\s*([0-9a-fA-F]+);\s([0-9a-fA-F]+)\s([0-9a-fA-F]+)\s([0-9a-fA-F]+);/)
1902         {
1903             $table_ref->[hex $1] = [hex $2, hex $3, hex $4];
1904             next;
1905         }
1906
1907         return if (/End\sTable/);
1908     }
1909 }
1910
1911 ################################################################
1912 # dump mapping table, prohibited characters set, unassigned
1913 # characters, bidirectional rules used by nameprep algorithm
1914 sub dump_nameprep($)
1915 {
1916     my $filename = shift;
1917     my @mapping_table = ();
1918     my @flags_table;
1919
1920     my $INPUT = open_data_file( $RFCS, $STRINGPREP );
1921     while (<$INPUT>)
1922     {
1923         next unless /Start\sTable/;
1924
1925         load_nameprep_range_table($INPUT, $nameprep_flags{"unassigned"}, \@flags_table) if (/A.1/);
1926         load_nameprep_range_table($INPUT, $nameprep_flags{"prohibited"}, \@flags_table) if (/C.1.2/);
1927         load_nameprep_range_table($INPUT, $nameprep_flags{"prohibited"}, \@flags_table) if (/C.2.2/);
1928         load_nameprep_range_table($INPUT, $nameprep_flags{"prohibited"}, \@flags_table) if (/C.3/);
1929         load_nameprep_range_table($INPUT, $nameprep_flags{"prohibited"}, \@flags_table) if (/C.4/);
1930         load_nameprep_range_table($INPUT, $nameprep_flags{"prohibited"}, \@flags_table) if (/C.5/);
1931         load_nameprep_range_table($INPUT, $nameprep_flags{"prohibited"}, \@flags_table) if (/C.6/);
1932         load_nameprep_range_table($INPUT, $nameprep_flags{"prohibited"}, \@flags_table) if (/C.7/);
1933         load_nameprep_range_table($INPUT, $nameprep_flags{"prohibited"}, \@flags_table) if (/C.8/);
1934         load_nameprep_range_table($INPUT, $nameprep_flags{"prohibited"}, \@flags_table) if (/C.9/);
1935         load_nameprep_range_table($INPUT, $nameprep_flags{"bidi_ral"}, \@flags_table) if (/D.1/);
1936         load_nameprep_range_table($INPUT, $nameprep_flags{"bidi_l"}, \@flags_table) if (/D.2/);
1937
1938         load_nameprep_map_table($INPUT, \@mapping_table) if (/B.1/);
1939         load_nameprep_map_table($INPUT, \@mapping_table) if (/B.2/);
1940     }
1941     close $INPUT;
1942
1943     open OUTPUT,">$filename.new" or die "Cannot create $filename";
1944     print "Building $filename\n";
1945     print OUTPUT "/* Nameprep algorithm related data */\n";
1946     print OUTPUT "/* generated from $RFCS/$STRINGPREP */\n";
1947     print OUTPUT "/* DO NOT EDIT!! */\n\n";
1948     print OUTPUT "#include \"wine/unicode.h\"\n\n";
1949
1950     dump_two_level_mapping( "nameprep_char_type", 0, @flags_table );
1951
1952     ######### mapping table
1953     # first determine all the 16-char subsets that contain something
1954     my @filled = ();
1955     my $pos = 16*3;  # for the null subset
1956     for (my $i = 0; $i < 65536; $i++)
1957     {
1958         next unless defined $mapping_table[$i];
1959         $filled[$i >> 4] = $pos;
1960         $pos += 16*3;
1961         $i |= 15;
1962     }
1963     my $total = $pos;
1964
1965     # now count the 256-char subsets that contain something
1966     my @filled_idx = (256) x 256;
1967     $pos = 256 + 16;
1968     for (my $i = 0; $i < 4096; $i++)
1969     {
1970         next unless $filled[$i];
1971         $filled_idx[$i >> 4] = $pos;
1972         $pos += 16;
1973         $i |= 15;
1974     }
1975     my $null_offset = $pos;
1976     $total += $pos;
1977
1978     # add the index offsets to the subsets positions
1979     for (my $i = 0; $i < 4096; $i++)
1980     {
1981         next unless $filled[$i];
1982         $filled[$i] += $null_offset;
1983     }
1984
1985     # dump the main index
1986     printf OUTPUT "const unsigned short DECLSPEC_HIDDEN nameprep_mapping[%d] =\n", $total;
1987     printf OUTPUT "{\n    /* index */\n";
1988     printf OUTPUT "%s", DUMP_ARRAY( "0x%04x", 0, @filled_idx );
1989     printf OUTPUT ",\n    /* null sub-index */\n%s", DUMP_ARRAY( "0x%04x", 0, ($null_offset) x 16 );
1990
1991     # dump the second-level indexes
1992     for (my $i = 0; $i < 256; $i++)
1993     {
1994         next unless ($filled_idx[$i] > 256);
1995         my @table = @filled[($i<<4)..($i<<4)+15];
1996         for (my $j = 0; $j < 16; $j++) { $table[$j] ||= $null_offset; }
1997         printf OUTPUT ",\n    /* sub-index %02x */\n", $i;
1998         printf OUTPUT "%s", DUMP_ARRAY( "0x%04x", 0, @table );
1999     }
2000
2001     # dump the 16-char subsets
2002     printf OUTPUT ",\n    /* null mapping */\n";
2003         printf OUTPUT "%s", DUMP_ARRAY( "0x%04x", 0, (0) x 48 );
2004
2005     for (my $i = 0; $i < 4096; $i++)
2006     {
2007         next unless $filled[$i];
2008         my @table = (0) x 48;
2009         for (my $j = 0; $j < 16; $j++)
2010         {
2011             if (defined $mapping_table[($i<<4) + $j])
2012             {
2013                 $table[3 * $j] = ${$mapping_table[($i << 4) + $j]}[0];
2014                 $table[3 * $j + 1] = ${$mapping_table[($i << 4) + $j]}[1];
2015                 $table[3 * $j + 2] = ${$mapping_table[($i << 4) + $j]}[2];
2016             }
2017         }
2018         printf OUTPUT ",\n    /* 0x%03x0 .. 0x%03xf */\n", $i, $i;
2019         printf OUTPUT "%s", DUMP_ARRAY( "0x%04x", 0, @table );
2020     }
2021
2022     printf OUTPUT "\n};\n";
2023
2024     close OUTPUT;
2025     save_file($filename);
2026 }
2027
2028 ################################################################
2029 # dump the ctype tables
2030 sub DUMP_CTYPE_TABLES($)
2031 {
2032     my $filename = shift;
2033     open OUTPUT,">$filename.new" or die "Cannot create $filename";
2034     printf "Building $filename\n";
2035     printf OUTPUT "/* Unicode ctype tables */\n";
2036     printf OUTPUT "/* Automatically generated; DO NOT EDIT!! */\n\n";
2037     printf OUTPUT "#include \"wine/unicode.h\"\n\n";
2038
2039     # add the direction in the high 4 bits of the category
2040     for (my $i = 0; $i < 65536; $i++)
2041     {
2042         $category_table[$i] |= $direction_table[$i] << 12 if defined $direction_table[$i];
2043     }
2044
2045     dump_simple_mapping( "wine_wctype_table", 0, @category_table );
2046
2047     close OUTPUT;
2048     save_file($filename);
2049 }
2050
2051
2052 ################################################################
2053 # dump the char composition table
2054 sub dump_compose_table($)
2055 {
2056     my $filename = shift;
2057
2058     open OUTPUT,">$filename.new" or die "Cannot create $filename";
2059     print "Building $filename\n";
2060     print OUTPUT "/* Unicode char composition */\n";
2061     print OUTPUT "/* generated from $UNIDATA/UnicodeData.txt */\n";
2062     print OUTPUT "/* DO NOT EDIT!! */\n\n";
2063     print OUTPUT "#include \"wine/unicode.h\"\n\n";
2064
2065     my @filled = ();
2066     foreach my $i (@compose_table)
2067     {
2068         my @comp = @$i;
2069         push @{$filled[$comp[1]]}, [ $comp[0], $comp[2] ];
2070     }
2071
2072     # count how many different second chars we have
2073
2074     my $count = 0;
2075     for (my $i = 0; $i < 65536; $i++)
2076     {
2077         next unless defined $filled[$i];
2078         $count++;
2079     }
2080
2081     # build the table of second chars and offsets
2082
2083     my $pos = $count + 1;
2084     my @table = ();
2085     for (my $i = 0; $i < 65536; $i++)
2086     {
2087         next unless defined $filled[$i];
2088         push @table, $i, $pos;
2089         $pos += @{$filled[$i]};
2090     }
2091     # terminator with last position
2092     push @table, 0, $pos;
2093     printf OUTPUT "static const WCHAR table[0x%x] =\n{\n", 2*$pos;
2094     printf OUTPUT "    /* second chars + offsets */\n%s", DUMP_ARRAY( "0x%04x", 0, @table );
2095
2096     # build the table of first chars and mappings
2097
2098     for (my $i = 0; $i < 65536; $i++)
2099     {
2100         next unless defined $filled[$i];
2101         my @table = ();
2102         my @list = sort { $a->[0] <=> $b->[0] } @{$filled[$i]};
2103         for (my $j = 0; $j <= $#list; $j++)
2104         {
2105             push @table, $list[$j][0], $list[$j][1];
2106         }
2107         printf OUTPUT ",\n    /* 0x%04x */\n%s", $i, DUMP_ARRAY( "0x%04x", 0, @table );
2108     }
2109     print OUTPUT "\n};\n\n";
2110     print OUTPUT <<"EOF";
2111 static inline int binary_search( WCHAR ch, int low, int high )
2112 {
2113     while (low <= high)
2114     {
2115         int pos = (low + high) / 2;
2116         if (table[2 * pos] < ch) low = pos + 1;
2117         else if (table[2 * pos] > ch) high = pos - 1;
2118         else return pos;
2119     }
2120     return -1;
2121 }
2122
2123 WCHAR DECLSPEC_HIDDEN wine_compose( const WCHAR *str )
2124 {
2125     int pos, idx = 1, start = 0, count = $count;
2126     for (;;)
2127     {
2128         if ((pos = binary_search( str[idx], start, count - 1 )) == -1) return 0;
2129         if (!idx--) return table[2 * pos + 1];
2130         start = table[2 * pos + 1];
2131         count = table[2 * pos + 3];
2132     }
2133 }
2134 EOF
2135     close OUTPUT;
2136     save_file($filename);
2137 }
2138
2139 ################################################################
2140 # dump the char decomposition table
2141 sub dump_decompose_table($)
2142 {
2143     my $filename = shift;
2144
2145     open OUTPUT,">$filename.new" or die "Cannot create $filename";
2146     print "Building $filename\n";
2147     print OUTPUT "/* Unicode char composition */\n";
2148     print OUTPUT "/* generated from $UNIDATA/UnicodeData.txt */\n";
2149     print OUTPUT "/* DO NOT EDIT!! */\n\n";
2150     print OUTPUT "#include \"wine/unicode.h\"\n\n";
2151
2152     # first determine all the 16-char subsets that contain something
2153
2154     my @filled = (0) x 4096;
2155     my $pos = 16*2;  # for the null subset
2156     for (my $i = 0; $i < 65536; $i++)
2157     {
2158         next unless defined $decomp_table[$i];
2159         $filled[$i >> 4] = $pos;
2160         $pos += 16*2;
2161         $i |= 15;
2162     }
2163     my $total = $pos;
2164
2165     # now count the 256-char subsets that contain something
2166
2167     my @filled_idx = (256) x 256;
2168     $pos = 256 + 16;
2169     for (my $i = 0; $i < 4096; $i++)
2170     {
2171         next unless $filled[$i];
2172         $filled_idx[$i >> 4] = $pos;
2173         $pos += 16;
2174         $i |= 15;
2175     }
2176     my $null_offset = $pos;  # null mapping
2177     $total += $pos;
2178
2179     # add the index offsets to the subsets positions
2180
2181     for (my $i = 0; $i < 4096; $i++)
2182     {
2183         next unless $filled[$i];
2184         $filled[$i] += $null_offset;
2185     }
2186
2187     # dump the main index
2188
2189     printf OUTPUT "static const WCHAR table[%d] =\n", $total;
2190     printf OUTPUT "{\n    /* index */\n";
2191     printf OUTPUT "%s", DUMP_ARRAY( "0x%04x", 0, @filled_idx );
2192     printf OUTPUT ",\n    /* null sub-index */\n%s", DUMP_ARRAY( "0x%04x", 0, ($null_offset) x 16 );
2193
2194     # dump the second-level indexes
2195
2196     for (my $i = 0; $i < 256; $i++)
2197     {
2198         next unless ($filled_idx[$i] > 256);
2199         my @table = @filled[($i<<4)..($i<<4)+15];
2200         for (my $j = 0; $j < 16; $j++) { $table[$j] ||= $null_offset; }
2201         printf OUTPUT ",\n    /* sub-index %02x */\n", $i;
2202         printf OUTPUT "%s", DUMP_ARRAY( "0x%04x", 0, @table );
2203     }
2204
2205     # dump the 16-char subsets
2206
2207     printf OUTPUT ",\n    /* null mapping */\n";
2208     printf OUTPUT "%s", DUMP_ARRAY( "0x%04x", 0, (0) x 32 );
2209
2210     for (my $i = 0; $i < 4096; $i++)
2211     {
2212         next unless $filled[$i];
2213         my @table = (0) x 32;
2214         for (my $j = 0; $j < 16; $j++)
2215         {
2216             if (defined $decomp_table[($i<<4) + $j])
2217             {
2218                 $table[2 * $j] = ${$decomp_table[($i << 4) + $j]}[0];
2219                 $table[2 * $j + 1] = ${$decomp_table[($i << 4) + $j]}[1];
2220             }
2221         }
2222         printf OUTPUT ",\n    /* 0x%03x0 .. 0x%03xf */\n", $i, $i;
2223         printf OUTPUT "%s", DUMP_ARRAY( "0x%04x", 0, @table );
2224     }
2225
2226     printf OUTPUT "\n};\n\n";
2227     print OUTPUT <<"EOF";
2228 unsigned int DECLSPEC_HIDDEN wine_decompose( WCHAR ch, WCHAR *dst, unsigned int dstlen )
2229 {
2230     const WCHAR *ptr = table + table[table[ch >> 8] + ((ch >> 4) & 0x0f)] + 2 * (ch & 0xf);
2231     unsigned int res;
2232
2233     *dst = ch;
2234     if (!*ptr) return 1;
2235     if (dstlen <= 1) return 0;
2236     /* apply the decomposition recursively to the first char */
2237     if ((res = wine_decompose( *ptr, dst, dstlen-1 ))) dst[res++] = ptr[1];
2238     return res;
2239 }
2240 EOF
2241     close OUTPUT;
2242     save_file($filename);
2243 }
2244
2245 ################################################################
2246 # output a codepage definition file from the global tables
2247 sub output_codepage_file($$$$)
2248 {
2249     my ($codepage, $filename, $comment, $has_glyphs) = @_;
2250
2251     my $output = sprintf "libs/port/c_%03d.c", $codepage;
2252     open OUTPUT,">$output.new" or die "Cannot create $output";
2253
2254     printf "Building %s from %s (%s)\n", $output, $filename || "hardcoded data", $comment;
2255
2256     # dump all tables
2257
2258     printf OUTPUT "/* code page %03d (%s) */\n", $codepage, $comment;
2259     if ($filename)
2260     {
2261         print OUTPUT "/* generated from $MAPPINGS/$filename */\n";
2262         print OUTPUT "/* DO NOT EDIT!! */\n\n";
2263     }
2264     else
2265     {
2266         printf OUTPUT "/* Automatically generated; DO NOT EDIT!! */\n\n";
2267     }
2268     printf OUTPUT "#include \"wine/unicode.h\"\n\n";
2269
2270     if (!@lead_bytes) { dump_sbcs_table( $codepage, $has_glyphs, $comment, $default_char, $default_wchar ); }
2271     else { dump_dbcs_table( $codepage, $comment, $default_char, $default_wchar, get_lb_ranges() ); }
2272     close OUTPUT;
2273     save_file($output);
2274 }
2275
2276 ################################################################
2277 # read a "bestfit" Windows mapping file
2278 sub read_bestfit_file($)
2279 {
2280     my ($filename) = @_;
2281     my $state = "";
2282     my ($codepage, $width, $count);
2283     my ($lb_cur, $lb_end);
2284
2285     my $INPUT = open_data_file( $MAPPINGS, $filename ) or die "Cannot open $filename";
2286
2287     while (<$INPUT>)
2288     {
2289         next if /^;/;  # skip comments
2290         next if /^\s*$/;  # skip empty lines
2291         next if /\x1a/;  # skip ^Z
2292         last if /^ENDCODEPAGE/;
2293
2294         if (/^CODEPAGE\s+(\d+)/)
2295         {
2296             $codepage = $1;
2297             next;
2298         }
2299         if (/^CPINFO\s+(\d+)\s+0x([0-9a-fA-f]+)\s+0x([0-9a-fA-F]+)/)
2300         {
2301             $width = $1;
2302             $default_char = hex $2;
2303             $default_wchar = hex $3;
2304             next;
2305         }
2306         if (/^(MBTABLE|WCTABLE|DBCSRANGE|DBCSTABLE)\s+(\d+)/)
2307         {
2308             $state = $1;
2309             $count = $2;
2310             next;
2311         }
2312         if (/^0x([0-9a-fA-F]+)\s+0x([0-9a-fA-F]+)/)
2313         {
2314             if ($state eq "MBTABLE")
2315             {
2316                 my $cp = hex $1;
2317                 my $uni = hex $2;
2318                 $cp2uni[$cp] = $uni unless defined($cp2uni[$cp]);
2319                 next;
2320             }
2321             if ($state eq "WCTABLE")
2322             {
2323                 my $uni = hex $1;
2324                 my $cp = hex $2;
2325                 $uni2cp[$uni] = $cp unless defined($uni2cp[$uni]);
2326                 next;
2327             }
2328             if ($state eq "DBCSRANGE")
2329             {
2330                 my $start = hex $1;
2331                 my $end = hex $2;
2332                 for (my $i = $start; $i <= $end; $i++) { add_lead_byte( $i ); }
2333                 $lb_cur = $start;
2334                 $lb_end = $end;
2335                 next;
2336             }
2337             if ($state eq "DBCSTABLE")
2338             {
2339                 my $mb = hex $1;
2340                 my $uni = hex $2;
2341                 my $cp = ($lb_cur << 8) | $mb;
2342                 $cp2uni[$cp] = $uni unless defined($cp2uni[$cp]);
2343                 if (!--$count)
2344                 {
2345                     if (++$lb_cur > $lb_end) { $state = "DBCSRANGE"; }
2346                 }
2347                 next;
2348             }
2349         }
2350         die "$filename: Unrecognized line $_\n";
2351     }
2352     close $INPUT;
2353 }
2354
2355
2356 ################################################################
2357 # read an input file and generate the corresponding .c file
2358 sub HANDLE_FILE(@)
2359 {
2360     my ($codepage,$filename,$has_glyphs,$comment,$first_private,$def,$defw) = @_;
2361
2362     @cp2uni = ();
2363     @lead_bytes = ();
2364     @uni2cp = ();
2365     $default_char = $def || $DEF_CHAR;
2366     $default_wchar = $defw || $DEF_CHAR;
2367
2368     # some codepage files are special
2369     if ($codepage == 20932)
2370     {
2371         READ_JIS0208_FILE( $filename );
2372         add_default_mappings( $first_private );
2373     }
2374     elsif ($codepage == 20127)
2375     {
2376         fill_20127_codepage();
2377         add_default_mappings( $first_private );
2378     }
2379     elsif ($filename =~ /\/bestfit/)
2380     {
2381         read_bestfit_file( $filename );
2382     }
2383     else
2384     {
2385         read_codepage_file( $filename );
2386         if ($codepage == 10001)
2387         {
2388             # add Shift-JIS mappings
2389             read_bestfit_file( "VENDORS/MICSFT/WindowsBestFit/bestfit932.txt" );
2390         }
2391         else
2392         {
2393             add_default_mappings( $first_private );
2394         }
2395     }
2396
2397     output_codepage_file( $codepage, $filename, $comment, $has_glyphs );
2398 }
2399
2400
2401 ################################################################
2402 # save a file if modified
2403 sub save_file($)
2404 {
2405     my $file = shift;
2406     if (-f $file && !system "cmp $file $file.new >/dev/null")
2407     {
2408         unlink "$file.new";
2409     }
2410     else
2411     {
2412         rename "$file.new", "$file";
2413     }
2414 }
2415
2416
2417 ################################################################
2418 # output the list of codepage tables into the cptable.c file
2419 sub output_cptable($)
2420 {
2421     my $output = shift;
2422     my @tables_decl = ();
2423
2424     printf "Building %s\n", $output;
2425
2426     foreach my $file (@allfiles)
2427     {
2428         my ($codepage,$filename) = @$file;
2429         push @tables_decl, sprintf("extern union cptable cptable_%03d;\n",$codepage);
2430     }
2431
2432     push @tables_decl, sprintf("\nstatic const union cptable * const cptables[%d] =\n{\n",$#allfiles+1);
2433     foreach my $file (@allfiles)
2434     {
2435         my ($codepage,$filename) = @$file;
2436         push @tables_decl, sprintf("    &cptable_%03d,\n", $codepage);
2437     }
2438     push @tables_decl, "};";
2439     REPLACE_IN_FILE( $output, @tables_decl );
2440 }
2441
2442 ################################################################
2443 # replace the contents of a file between ### cpmap ### marks
2444
2445 sub REPLACE_IN_FILE($@)
2446 {
2447     my $name = shift;
2448     my @data = @_;
2449     my @lines = ();
2450     open(FILE,$name) or die "Can't open $name";
2451     while (<FILE>)
2452     {
2453         push @lines, $_;
2454         last if /\#\#\# cpmap begin \#\#\#/;
2455     }
2456     push @lines, @data;
2457     while (<FILE>)
2458     {
2459         if (/\#\#\# cpmap end \#\#\#/) { push @lines, "\n", $_; last; }
2460     }
2461     push @lines, <FILE>;
2462     open(FILE,">$name.new") or die "Can't modify $name";
2463     print FILE @lines;
2464     close(FILE);
2465     save_file($name);
2466 }
2467
2468 ################################################################
2469 # main routine
2470
2471 chdir ".." if -f "./make_unicode";
2472 READ_DEFAULTS( $DEFAULTS );
2473 DUMP_CASE_MAPPINGS( "libs/wine/casemap.c" );
2474 DUMP_SORTKEYS( "libs/wine/collation.c", READ_SORTKEYS_FILE() );
2475 dump_compose_table( "libs/port/compose.c" );
2476 dump_decompose_table( "libs/port/decompose.c" );
2477 DUMP_CTYPE_TABLES( "libs/wine/wctype.c" );
2478 dump_digit_folding( "libs/port/digitmap.c" );
2479 dump_mirroring( "dlls/usp10/mirror.c" );
2480 dump_mirroring( "dlls/dwrite/mirror.c" );
2481 dump_bracket( "dlls/usp10/bracket.c" );
2482 dump_bracket( "dlls/dwrite/bracket.c" );
2483 dump_shaping( "dlls/usp10/shaping.c" );
2484 dump_linebreak( "dlls/usp10/linebreak.c" );
2485 dump_linebreak( "dlls/dwrite/linebreak.c" );
2486 dump_scripts( "dlls/dwrite/scripts" );
2487 dump_indic( "dlls/usp10/indicsyllable.c" );
2488 dump_intl_nls("loader/l_intl.nls");
2489 dump_vertical( "dlls/gdi32/vertical.c" );
2490 dump_vertical( "dlls/wineps.drv/vertical.c" );
2491 dump_nameprep( "dlls/kernel32/nameprep.c" );
2492
2493 foreach my $file (@allfiles) { HANDLE_FILE( @{$file} ); }
2494
2495 output_cptable("libs/port/cptable.c");
2496
2497 exit 0;
2498
2499 # Local Variables:
2500 # compile-command: "./make_unicode"
2501 # End: