| blob | 3db7272437d8af10606573a4440a4c03425e4a9b |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53b)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
20 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
21 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(DLLDEFS,"")
25 if test "x$enable_debug" = "xno"
26 then
27 DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
28 fi
29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
30 then
31 DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
32 fi
34 AC_CANONICAL_HOST
35 case $host in
36 x86_64*linux*)
37 if test "x$enable_win64" != "xyes"
38 then
39 test -n "$CC" || CC="gcc -m32"
40 test -n "$LD" || LD="ld -m elf_i386"
41 test -n "$AS" || AS="as --32"
42 host_cpu="i386"
43 fi
44 ;;
45 esac
47 dnl enable_win16 defaults to yes on x86, to no on other CPUs
48 case $host_cpu in
49 *i[[3456789]]86*)
50 if test "x$enable_win16" != "xno"
51 then
52 enable_win16="yes"
53 fi
54 ;;
55 esac
57 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
58 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
59 if test "x$enable_win16" != "xyes"
60 then
61 WIN16_FILES=""
62 WIN16_INSTALL=""
63 fi
65 dnl **** Check for some programs ****
67 AC_PROG_MAKE_SET
68 AC_PROG_CC
69 AC_PROG_CXX
70 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
71 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
73 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
74 [if test -z "$with_wine_tools"; then
75 if test "$cross_compiling" = "yes"; then
76 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
77 else
78 wine_cv_toolsdir="\$(TOPOBJDIR)"
79 fi
80 elif test -d "$with_wine_tools/tools/winebuild"; then
81 case $with_wine_tools in
82 /*) wine_cv_toolsdir="$with_wine_tools" ;;
83 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
84 esac
85 else
86 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
87 fi])
88 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
90 AC_PATH_XTRA
91 AC_PROG_LEX
93 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
94 dnl **** without one present.
95 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
96 if test "$XLEX" = "none"
97 then
98 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
99 fi
101 dnl Check for bison
102 AC_CHECK_PROGS(BISON,bison,none)
103 if test "$BISON" = "none"
104 then
105 AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
106 fi
108 AC_CHECK_TOOLS(AS,[gas as],as)
109 AC_CHECK_TOOL(LD,ld,ld)
110 AC_CHECK_TOOL(AR,ar,ar)
111 AC_PROG_RANLIB
112 AC_CHECK_TOOL(STRIP,strip,strip)
113 AC_CHECK_TOOL(WINDRES,windres,false)
114 AC_PROG_LN_S
115 WINE_PROG_LN
116 AC_PROG_EGREP
117 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
118 AC_PROG_INSTALL
119 dnl Prepend src dir to install path dir if it's a relative path
120 case "$INSTALL" in
121 [[\\/$]]* | ?:[[\\/]]* ) ;;
122 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
123 esac
125 dnl Check for lint
126 AC_CHECK_PROGS(LINT, lclint lint)
127 if test "$LINT" = "lint"
128 then
129 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
130 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
131 fi
132 AC_SUBST(LINT)
133 AC_SUBST(LINTFLAGS)
135 dnl Check for various programs
136 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
137 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
139 case $host_cpu in
140 *i[[3456789]]86*)
141 AC_CHECK_PROGS(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
142 ;;
143 esac
145 dnl **** Check for some libraries ****
147 dnl Check for -li386 for NetBSD and OpenBSD
148 AC_CHECK_LIB(i386,i386_set_ldt)
149 dnl Check for -lossaudio for NetBSD
150 AC_CHECK_LIB(ossaudio,_oss_ioctl)
151 dnl Check for -lnsl for Solaris
152 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
153 dnl Check for -lsocket for Solaris
154 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
155 dnl Check for -lresolv for Solaris
156 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
157 dnl Check for -lxpg4 for FreeBSD
158 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
159 dnl Check for -lpoll for Mac OS X/Darwin
160 AC_CHECK_LIB(poll,poll)
161 dnl Check for -lresolv for Mac OS X/Darwin
162 AC_CHECK_LIB(resolv,res_9_init)
163 dnl Check for -lpthread
164 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
166 AC_SUBST(XLIB,"")
167 AC_SUBST(XFILES,"")
168 AC_SUBST(OPENGLFILES,"")
169 AC_SUBST(GLU32FILES,"")
170 AC_SUBST(OPENGL_LIBS,"")
172 dnl **** Check for header files ****
174 AC_CHECK_HEADERS(\
175 IOKit/IOKitLib.h \
176 alsa/asoundlib.h \
177 arpa/inet.h \
178 arpa/nameser.h \
179 asm/types.h \
180 capi20.h \
181 cups/cups.h \
182 curses.h \
183 direct.h \
184 dlfcn.h \
185 elf.h \
186 float.h \
187 fontconfig/fontconfig.h \
188 getopt.h \
189 gif_lib.h \
190 ieeefp.h \
191 io.h \
192 jack/jack.h \
193 jpeglib.h \
194 lber.h \
195 lcms.h \
196 lcms/lcms.h \
197 ldap.h \
198 libaudioio.h \
199 link.h \
200 linux/capi.h \
201 linux/cdrom.h \
202 linux/compiler.h \
203 linux/hdreg.h \
204 linux/input.h \
205 linux/ioctl.h \
206 linux/joystick.h \
207 linux/major.h \
208 linux/param.h \
209 linux/serial.h \
210 linux/ucdrom.h \
211 mach/machine.h \
212 machine/cpu.h \
213 machine/limits.h \
214 machine/soundcard.h \
215 mntent.h \
216 ncurses.h \
217 netdb.h \
218 netinet/in.h \
219 netinet/in_systm.h \
220 netinet/tcp.h \
221 netinet/tcp_fsm.h \
222 openssl/err.h \
223 openssl/ssl.h \
224 poll.h \
225 process.h \
226 pthread.h \
227 pwd.h \
228 regex.h \
229 sched.h \
230 scsi/scsi.h \
231 scsi/scsi_ioctl.h \
232 scsi/sg.h \
233 soundcard.h \
234 stdint.h \
235 strings.h \
236 sys/asoundlib.h \
237 sys/cdio.h \
238 sys/elf32.h \
239 sys/epoll.h \
240 sys/errno.h \
241 sys/exec_elf.h \
242 sys/filio.h \
243 sys/ioctl.h \
244 sys/ipc.h \
245 sys/limits.h \
246 sys/link.h \
247 sys/lwp.h \
248 sys/mman.h \
249 sys/modem.h \
250 sys/msg.h \
251 sys/param.h \
252 sys/poll.h \
253 sys/ptrace.h \
254 sys/reg.h \
255 sys/scsiio.h \
256 sys/shm.h \
257 sys/signal.h \
258 sys/socket.h \
259 sys/sockio.h \
260 sys/soundcard.h \
261 sys/statvfs.h \
262 sys/strtio.h \
263 sys/syscall.h \
264 sys/sysctl.h \
265 sys/time.h \
266 sys/times.h \
267 sys/uio.h \
268 sys/un.h \
269 sys/vm86.h \
270 sys/wait.h \
271 syscall.h \
272 termios.h \
273 unicode/ubidi.h \
274 unistd.h \
275 utime.h \
276 valgrind/memcheck.h
277 )
278 AC_HEADER_STAT()
280 dnl **** Check for X11 ****
282 if test "$have_x" = "yes"
283 then
284 XLIB="-lXext -lX11"
285 ac_save_CPPFLAGS="$CPPFLAGS"
286 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
288 dnl *** All of the following tests require X11/Xlib.h
289 AC_CHECK_HEADERS([X11/Xlib.h \
290 X11/XKBlib.h \
291 X11/Xutil.h \
292 X11/extensions/shape.h \
293 X11/extensions/XInput.h \
294 X11/extensions/XShm.h \
295 X11/extensions/Xrandr.h \
296 X11/extensions/Xrender.h \
297 X11/extensions/xf86dga.h \
298 X11/extensions/xf86vmode.h],,,
299 [#ifdef HAVE_X11_XLIB_H
300 # include <X11/Xlib.h>
301 #endif
302 #ifdef HAVE_X11_XUTIL_H
303 # include <X11/Xutil.h>
304 #endif])
306 dnl *** Check for X keyboard extension
307 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
308 then
309 AC_CHECK_LIB(X11, XkbQueryExtension,
310 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
311 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
312 fi
314 dnl *** Check for X Shm extension
315 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
316 then
317 AC_CHECK_LIB(Xext, XShmQueryExtension,
318 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
319 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
320 fi
322 dnl *** Check for X shape extension
323 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
324 then
325 AC_CHECK_LIB(Xext,XShapeQueryExtension,
326 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
327 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
328 fi
330 dnl *** Check for XFree86 DGA / DGA 2.0 extension
331 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
332 then
333 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
334 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
335 [Define if you have the Xxf86dga library version 2])
336 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
337 ],,
338 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
339 fi
341 dnl *** Check for XFree86 VMODE extension
342 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
343 then
344 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
345 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
346 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
347 ],,
348 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
349 fi
351 dnl *** Check for X RandR extension
352 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
353 then
354 AC_TRY_COMPILE([#include <X11/Xlib.h>
355 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
356 [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
357 fi
359 dnl *** Check for Transform functions in Xrender
360 if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
361 then
362 AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
363 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
364 [Define if Xrender has the XRenderSetPictureTransform function])],,
365 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
366 fi
367 dnl *** End of X11/Xlib.h check
369 dnl Check for the presence of OpenGL
370 if test "x$with_opengl" != "xno"
371 then
372 AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h,,,
373 [#ifdef HAVE_GL_GLX_H
374 # include <GL/glx.h>
375 #endif])
376 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
377 then
378 dnl Check for some problems due to old Mesa versions
379 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
380 AC_TRY_COMPILE(
381 [#include <GL/gl.h>],
382 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
383 [wine_cv_opengl_version_OK="yes"],
384 [wine_cv_opengl_version_OK="no"]
385 )
386 )
388 if test "$wine_cv_opengl_version_OK" = "yes"
389 then
390 dnl Check for the presence of the library
391 AC_CHECK_LIB(GL,glXCreateContext,
392 OPENGL_LIBS="-lGL"
393 ,,
394 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
396 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
397 then
398 OPENGLFILES='$(OPENGLFILES)'
399 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
400 else
401 if test -f /usr/X11R6/lib/libGL.a
402 then
403 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
404 This prevents linking to OpenGL. Delete the file and restart configure.])
405 fi
406 fi
408 dnl Check for GLU32 library.
409 AC_CHECK_LIB(GLU,gluLookAt,
410 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
411 GLU32FILES='$(GLU32FILES)']
412 ,,
413 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
414 )
415 fi
417 dnl Check for glut32 library.
418 AC_CHECK_LIB(glut,glutMainLoop,
419 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
420 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
421 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
422 fi
423 fi
425 dnl **** Check for NAS ****
426 AC_SUBST(NASLIBS,"")
427 AC_CHECK_HEADERS(audio/audiolib.h,
428 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
429 AC_CHECK_LIB(audio,AuCreateFlow,
430 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
431 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
432 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
434 CPPFLAGS="$ac_save_CPPFLAGS"
435 XFILES='$(XFILES)'
436 else
437 XLIB=""
438 X_CFLAGS=""
439 X_LIBS=""
440 fi
442 dnl **** Check for libxml2 ****
444 AC_SUBST(XML2LIBS,"")
445 AC_SUBST(XML2INCL,"")
446 AC_SUBST(XSLTLIBS,"")
447 AC_SUBST(XSLTINCL,"")
448 if test "$PKG_CONFIG" != "false"
449 then
450 ac_save_CPPFLAGS="$CPPFLAGS"
451 ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0`"
452 ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0`"
453 CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
454 AC_CHECK_HEADERS(libxml/parser.h,
455 [AC_CHECK_LIB(xml2, xmlParseMemory,
456 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
457 XML2LIBS="$ac_xml_libs"
458 XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
459 AC_CHECK_LIB(xml2, xmlReadMemory,
460 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
461 ])
462 CPPFLAGS="$ac_save_CPPFLAGS"
463 ac_xslt_libs="`$PKG_CONFIG --libs libxslt`"
464 ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt`"
465 CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
466 AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
467 [AC_CHECK_LIB(xslt, xsltCompilePattern,
468 [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
469 XSLTLIBS="$ac_xslt_libs"
470 XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
471 ],,
472 [#ifdef HAVE_LIBXSLT_PATTERN_H
473 # include <libxslt/pattern.h>
474 #endif])
475 CPPFLAGS="$ac_save_CPPFLAGS"
476 fi
478 dnl **** Check which curses lib to use ***
479 CURSESLIBS=""
480 if test "x$with_curses" != "xno"
481 then
482 if test "$ac_cv_header_ncurses_h" = "yes"
483 then
484 AC_CHECK_LIB(ncurses,waddch,
485 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
486 CURSESLIBS="-lncurses"])
487 elif test "$ac_cv_header_curses_h" = "yes"
488 then
489 AC_CHECK_LIB(curses,waddch,
490 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
491 CURSESLIBS="-lcurses"])
492 fi
493 fi
494 AC_SUBST(CURSESLIBS)
496 dnl **** Check for SANE ****
497 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
498 AC_SUBST(SANELIBS,"")
499 AC_SUBST(SANEINCL,"")
500 if test "$sane_devel" != "no"
501 then
502 SANELIBS="`$sane_devel --libs`"
503 SANEINCL="`$sane_devel --cflags`"
504 ac_save_CPPFLAGS="$CPPFLAGS"
505 ac_save_LIBS="$LIBS"
506 CPPFLAGS="$CPPFLAGS $SANEINCL"
507 LIBS="$LIBS $SANELIBS"
508 AC_CHECK_HEADER(sane/sane.h,
509 [AC_CHECK_LIB(sane,sane_open,
510 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
511 [SANELIBS=""
512 SANEINCL=""])],
513 [SANELIBS=""
514 SANEINCL=""])
515 LIBS="$ac_save_LIBS"
516 CPPFLAGS="$ac_save_CPPFLAGS"
517 fi
519 dnl **** Check for the ICU library ****
520 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
521 then
522 saved_libs="$LIBS"
523 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
524 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
525 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
526 AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
527 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
528 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
529 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
530 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
531 AC_MSG_RESULT(yes)],
532 [AC_MSG_RESULT(no)])
533 LIBS="$saved_libs"
534 fi
536 dnl **** Check for LittleCMS ***
537 AC_SUBST(LCMSLIBS,"")
538 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
539 then
540 AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
541 [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
542 LCMSLIBS="-llcms"])
543 fi
545 dnl **** Check for OpenLDAP ***
546 AC_SUBST(LDAPLIBS,"")
547 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
548 then
549 AC_CHECK_LIB(ldap_r, ldap_initialize,
550 [AC_CHECK_LIB(lber, ber_init,
551 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
552 LDAPLIBS="-lldap_r -llber"],,
553 [$LIBPTHREAD])],,
554 [$LIBPTHREAD])
555 ac_save_LIBS="$LIBS"
556 LIBS="$LIBS $LDAPLIBS $LIBPTHREAD"
557 AC_CHECK_FUNCS(\
558 ldap_count_references \
559 ldap_first_reference \
560 ldap_next_reference \
561 ldap_parse_reference)
562 LIBS="$ac_save_LIBS"
563 fi
565 dnl **** Check for FreeType 2 ****
566 AC_SUBST(FREETYPELIBS,"")
567 AC_SUBST(FREETYPEINCL,"")
568 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
569 if test "$ft_lib" = "no"
570 then
571 wine_cv_msg_freetype=no
572 else
573 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
574 if test "$ft_devel" = "no"
575 then
576 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
577 if test "$ft_devel2" = "freetype2-config"
578 then
579 ft_devel=$ft_devel2
580 fi
581 fi
582 if test "$ft_devel" = "no"
583 then
584 wine_cv_msg_freetype=yes
585 else
586 FREETYPELIBS=`$ft_devel --libs`
587 FREETYPEINCL=`$ft_devel --cflags`
588 ac_save_CPPFLAGS="$CPPFLAGS"
589 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
590 AC_CHECK_HEADERS(ft2build.h \
591 freetype/freetype.h \
592 freetype/ftglyph.h \
593 freetype/tttables.h \
594 freetype/ftnames.h \
595 freetype/ftsnames.h \
596 freetype/ttnameid.h \
597 freetype/ftoutln.h \
598 freetype/ftwinfnt.h \
599 freetype/internal/sfnt.h,,,
600 [#if HAVE_FT2BUILD_H
601 #include <ft2build.h>
602 #endif])
603 AC_TRY_CPP([#include <ft2build.h>
604 #include <freetype/fttrigon.h>],
605 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
606 [Define if you have the <freetype/fttrigon.h> header file.])
607 wine_cv_fttrigon=yes],
608 wine_cv_fttrigon=no)
609 CPPFLAGS="$ac_save_CPPFLAGS"
610 dnl Check that we have at least freetype/freetype.h
611 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
612 then
613 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
614 wine_cv_msg_freetype=no
615 else
616 FREETYPELIBS=""
617 FREETYPEINCL=""
618 wine_cv_msg_freetype=yes
619 fi
620 fi
621 fi
623 dnl Only build the fonts dir if we have both freetype and fontforge
624 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
625 then
626 AC_SUBST(FONTSSUBDIRS,"fonts")
627 fi
629 dnl **** Check for parport (currently Linux only) ****
630 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
631 AC_TRY_COMPILE(
632 [#include <linux/ppdev.h>],
633 [ioctl (1,PPCLAIM,0)],
634 [ac_cv_c_ppdev="yes"],
635 [ac_cv_c_ppdev="no"])
636 )
637 if test "$ac_cv_c_ppdev" = "yes"
638 then
639 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
640 fi
642 dnl **** Check for va_copy ****
643 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
644 AC_TRY_LINK(
645 [#include <stdarg.h>],
646 [va_list ap1, ap2;
647 va_copy(ap1,ap2);
648 ],
649 [ac_cv_c_va_copy="yes"],
650 [ac_cv_c_va_copy="no"])
651 )
652 if test "$ac_cv_c_va_copy" = "yes"
653 then
654 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
655 fi
656 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
657 AC_TRY_LINK(
658 [#include <stdarg.h>],
659 [va_list ap1, ap2;
660 __va_copy(ap1,ap2);
661 ],
662 [ac_cv_c___va_copy="yes"],
663 [ac_cv_c___va_copy="no"])
664 )
665 if test "$ac_cv_c___va_copy" = "yes"
666 then
667 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
668 fi
670 dnl **** Check for sigsetjmp ****
671 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
672 AC_TRY_LINK(
673 [#include <setjmp.h>],
674 [sigjmp_buf buf;
675 sigsetjmp( buf, 1 );
676 siglongjmp( buf, 1 );],
677 [ac_cv_c_sigsetjmp="yes"],
678 [ac_cv_c_sigsetjmp="no"])
679 )
680 if test "$ac_cv_c_sigsetjmp" = "yes"
681 then
682 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
683 fi
685 dnl **** Check for pthread_rwlock_t ****
686 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
687 #include <pthread.h>])
689 dnl **** Check for pthread functions ****
690 ac_save_LIBS="$LIBS"
691 LIBS="$LIBS $LIBPTHREAD"
692 AC_CHECK_FUNCS(\
693 pthread_getattr_np \
694 pthread_get_stackaddr_np \
695 pthread_get_stacksize_np \
696 )
697 LIBS="$ac_save_LIBS"
699 dnl **** Check for aRts Sound Server ****
700 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
701 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
702 then
703 ARTSC_CFLAGS=""
704 for i in `$ARTSCCONFIG --cflags`
705 do
706 case "$i" in
707 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
708 esac
709 done
710 ARTSC_LIBS=`$ARTSCCONFIG --libs`
711 save_CFLAGS="$CFLAGS"
712 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
713 AC_CHECK_LIB(artsc,arts_init,
714 [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
715 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
716 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
717 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
718 $ARTSC_LIBS)
719 CFLAGS="$save_CFLAGS"
720 fi
722 dnl **** Check for EsounD ****
723 AC_PATH_PROG(ESDCONFIG, esd-config)
724 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
725 then
726 ESD_CFLAGS=""
727 for i in `$ESDCONFIG --cflags`
728 do
729 case "$i" in
730 -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
731 esac
732 done
733 ESD_LIBS=`$ESDCONFIG --libs`
734 save_CFLAGS="$CFLAGS"
735 CFLAGS="$CFLAGS $ESD_CFLAGS"
736 AC_CHECK_LIB(esd,esd_open_sound,
737 [AC_SUBST(ESDLIBS, $ESD_LIBS)
738 AC_SUBST(ESDINCL, $ESD_CFLAGS)
739 AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
740 CFLAGS="$save_CFLAGS"
741 fi
743 dnl **** Check for ALSA 1.x ****
744 AC_SUBST(ALSALIBS,"")
745 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
746 then
747 AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
748 [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
749 #include <alsa/asoundlib.h>
750 #elif defined(HAVE_SYS_ASOUNDLIB_H)
751 #include <sys/asoundlib.h>
752 #endif],
753 [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
754 [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
755 ALSALIBS="-lasound"])])
756 fi
758 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
760 AC_SUBST(AUDIOIOLIBS,"")
761 if test "$ac_cv_header_libaudioio_h" = "yes"
762 then
763 AC_CHECK_LIB(audioio,AudioIOGetVersion,
764 [AUDIOIOLIBS="-laudioio"
765 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
766 fi
768 dnl **** Check for capi4linux ****
770 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
771 then
772 AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
773 fi
775 dnl **** Check for gcc specific options ****
777 AC_SUBST(EXTRACFLAGS,"")
778 if test "x${GCC}" = "xyes"
779 then
780 EXTRACFLAGS="-Wall -pipe"
782 dnl Check for strength-reduce bug
783 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
784 AC_TRY_RUN([
785 int L[[4]] = {0,1,2,3};
786 int main(void) {
787 static int Array[[3]];
788 unsigned int B = 3;
789 int i;
790 for(i=0; i<B; i++) Array[[i]] = i - 3;
791 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
792 L[[i]] = 4;
794 exit( Array[[1]] != -2 || L[[2]] != 3);
795 }],
796 ac_cv_c_gcc_strength_bug="no",
797 ac_cv_c_gcc_strength_bug="yes",
798 ac_cv_c_gcc_strength_bug="yes") )
799 if test "$ac_cv_c_gcc_strength_bug" = "yes"
800 then
801 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
802 fi
804 dnl Check for -fshort-wchar
805 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
806 [WINE_TRY_CFLAGS([-fshort-wchar],
807 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
808 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
809 then
810 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
811 fi
813 dnl Check for -mpreferred-stack-boundary
814 case $host_cpu in
815 *i[[3456789]]86*)
816 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
817 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
818 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
819 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
820 then
821 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
822 fi
823 ;;
824 esac
826 dnl Check for -fno-strict-aliasing
827 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
828 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
829 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
830 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
831 then
832 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
833 fi
835 dnl Check for -gstabs+ option
836 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
837 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
838 if test "$ac_cv_c_gcc_gstabs" = "yes"
839 then
840 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
841 fi
843 dnl Check for -Wdeclaration-after-statement option
844 AC_CACHE_CHECK([for gcc -Wdeclaration-after-statement support], ac_cv_c_gcc_decl_after_statement,
845 [WINE_TRY_CFLAGS([-Wdeclaration-after-statement],ac_cv_c_gcc_decl_after_statement="yes", ac_cv_c_gcc_decl_after_statement="no")])
846 if test "$ac_cv_c_gcc_decl_after_statement" = "yes"
847 then
848 EXTRACFLAGS="$EXTRACFLAGS -Wdeclaration-after-statement"
849 fi
851 dnl Check for noisy string.h
852 saved_CFLAGS="$CFLAGS"
853 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
854 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
855 AC_TRY_COMPILE([#include <string.h>],[],
856 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
857 CFLAGS="$saved_CFLAGS"
858 if test "$ac_cv_c_string_h_warnings" = "no"
859 then
860 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
861 fi
863 AC_SUBST(BUILTINFLAG,"")
864 saved_CFLAGS="$CFLAGS"
865 CFLAGS="$CFLAGS -Werror"
866 AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
867 AC_TRY_COMPILE([],
868 [int iswlower(unsigned short);],
869 [ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
870 CFLAGS="$saved_CFLAGS"
871 if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
872 then
873 BUILTINFLAG=""
874 for builtin in \
875 iswalnum iswalpha iswcntrl iswdigit iswgraph iswlower \
876 iswprint iswpunct iswspace iswupper iswxdigit towlower towupper
877 do
878 BUILTINFLAG="$BUILTINFLAG -fno-builtin-$builtin"
879 done
880 fi
881 fi
883 dnl **** Check how to define a function in assembly code ****
885 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
886 WINE_TRY_ASM_LINK(
887 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
888 ac_cv_asm_func_def=".def",
889 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
890 ac_cv_asm_func_def=".type @function",
891 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
892 ac_cv_asm_func_def=".type 2",
893 ac_cv_asm_func_def="unknown")])]))
895 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
896 case "$ac_cv_asm_func_def" in
897 ".def")
898 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
899 ".type @function")
900 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
901 ".type 2")
902 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
903 *)
904 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
905 esac
907 dnl **** Check for underscore on external symbols ****
909 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
910 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
911 [extern int ac_test;],
912 [if (ac_test) return 1],
913 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
915 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
916 if test "$ac_cv_c_extern_prefix" = "yes"
917 then
918 AC_DEFINE([__ASM_NAME(name)], ["_" name])
919 else
920 AC_DEFINE([__ASM_NAME(name)], [name])
921 fi
923 dnl **** Check for working dll ****
925 AC_SUBST(DLLEXT,"")
926 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
927 AC_SUBST(DLLIBS,"")
928 AC_SUBST(LDSHARED,"")
929 AC_SUBST(LDDLLFLAGS,"")
930 AC_SUBST(LIBEXT,"so")
931 AC_SUBST(IMPLIBEXT,"def")
933 case $host_os in
934 cygwin*|mingw32*)
935 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
936 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
937 if test "$DLLWRAP" = "false"; then
938 LIBEXT="a"
939 else
940 dnl FIXME - check whether dllwrap works correctly...
941 LIBEXT="dll"
942 fi
943 IMPLIBEXT="a"
944 dnl We can't build 16-bit NE dlls
945 WIN16_FILES=""
946 WIN16_INSTALL=""
947 ;;
948 *)
949 if test "$ac_cv_header_dlfcn_h" = "yes"
950 then
951 AC_CHECK_FUNCS(dlopen,,
952 [AC_CHECK_LIB(dl,dlopen,
953 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
954 DLLIBS="-ldl"],
955 [LIBEXT="a"])])
956 else
957 LIBEXT="a"
958 fi
960 if test "$LIBEXT" = "so"
961 then
962 DLLFLAGS="$DLLFLAGS -fPIC"
963 DLLEXT=".so"
964 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
965 [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
966 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
967 if test "$ac_cv_c_dll_gnuelf" = "yes"
968 then
969 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
970 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
971 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
972 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
973 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
974 if test "$ac_cv_c_dll_zdefs" = "yes"
975 then
976 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
977 fi
979 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
980 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
981 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
982 if test "$ac_cv_c_dll_init_fini" = "yes"
983 then
984 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
985 fi
987 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
988 [echo '{ global: *; };' >conftest.map
989 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
990 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
991 rm -f conftest.map])
992 if test "$ac_cv_c_ld_version_scripts" = "yes"
993 then
994 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
995 fi
997 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
998 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
999 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
1000 if test "$ac_cv_c_export_dynamic" = "yes"
1001 then
1002 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
1003 fi
1005 case $host_cpu in
1006 *i[[3456789]]86*)
1007 AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
1008 [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
1009 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
1010 if test "$ac_cv_ld_reloc_exec" = "yes"
1011 then
1012 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
1013 fi
1014 ;;
1015 esac
1017 else
1018 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
1019 [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
1020 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1021 if test "$ac_cv_c_dll_unixware" = "yes"
1022 then
1023 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1024 LDDLLFLAGS="-Wl,-G,-B,symbolic"
1026 else
1027 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1028 [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1029 if test "$ac_cv_c_dll_macho" = "yes"
1030 then
1031 LIBEXT="dylib"
1032 LDDLLFLAGS="-bundle"
1033 LDSHARED="\$(CC) -dynamiclib"
1034 STRIP="$STRIP -u -r"
1035 dnl declare needed frameworks
1036 AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1037 AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
1038 case $host_cpu in
1039 *i[[3456789]]86*)
1040 AC_SUBST(LDEXECFLAGS,"-image_base 0x7bf00000")
1041 ;;
1042 *powerpc*)
1043 CFLAGS="$CFLAGS -ffixed-r13"
1044 LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"
1045 dnl Relocate wine executable (FIXME: is this really needed?)
1046 AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
1047 AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
1048 ;;
1049 esac
1051 else
1052 AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1053 [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1054 if test "$ac_cv_c_dll_hpux" = "yes"
1055 then
1056 LIBEXT="sl"
1057 DLLEXT=".sl"
1058 LDDLLFLAGS="-shared -fPIC"
1059 LDSHARED="\$(CC) -shared"
1060 fi
1061 fi
1062 fi
1063 fi
1064 fi
1066 dnl Check for cross compiler to build test programs
1067 AC_SUBST(CROSSTEST,"")
1068 if test "$cross_compiling" = "no"
1069 then
1070 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1071 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1072 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1073 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1074 fi
1075 ;;
1076 esac
1078 if test "$LIBEXT" = "a"; then
1079 AC_MSG_ERROR(
1080 [could not find a way to build shared libraries.
1081 It is currently not possible to build Wine without shared library
1082 (.so) support to allow transparent switch between .so and .dll files.
1083 If you are using Linux, you will need a newer binutils.]
1084 )
1085 fi
1087 case $build_os in
1088 cygwin*|mingw32*)
1089 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1090 darwin*|macosx*)
1091 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1092 *)
1093 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1094 esac
1096 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1097 case $host_os in
1098 mingw32*)
1099 AC_SUBST(CRTLIBS,"-lmsvcrt")
1100 AC_SUBST(SOCKETLIBS,"-lws2_32")
1101 ;;
1102 esac
1104 case $host_os in
1105 linux*)
1106 case $host_cpu in
1107 *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1108 *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1109 esac
1110 AC_SUBST(MAIN_BINARY,"wine-glibc")
1111 ;;
1112 darwin*)
1113 AC_SUBST(WINE_BINARIES,"wine-pthread")
1114 AC_SUBST(MAIN_BINARY,"wine-pthread")
1115 ;;
1116 *)
1117 AC_SUBST(WINE_BINARIES,"wine-kthread")
1118 AC_SUBST(MAIN_BINARY,"wine-kthread")
1119 ;;
1120 esac
1122 dnl **** Get the soname for libraries that we load dynamically ****
1124 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1125 then
1126 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1127 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1128 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1129 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1130 WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1131 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1132 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1133 WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1134 WINE_GET_SONAME(cups,cupsGetDefault)
1135 WINE_GET_SONAME(jack,jack_client_new)
1136 WINE_GET_SONAME(fontconfig,FcInit)
1137 WINE_GET_SONAME(ssl,SSL_library_init)
1138 WINE_GET_SONAME(crypto,BIO_new_socket)
1139 WINE_GET_SONAME(ncurses,waddch)
1140 WINE_GET_SONAME(curses,waddch)
1141 WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1142 WINE_GET_SONAME(ungif,DGifOpen)
1143 WINE_GET_SONAME(gif,DGifOpen)
1144 WINE_GET_SONAME(capi20,capi20_isinstalled)
1145 fi
1148 dnl **** Check for functions ****
1150 AC_CHECK_FUNCS(\
1151 _lwp_create \
1152 _lwp_self \
1153 _pclose \
1154 _popen \
1155 _snprintf \
1156 _spawnvp \
1157 _stricmp \
1158 _strnicmp \
1159 _vsnprintf \
1160 chsize \
1161 clone \
1162 epoll_create \
1163 ffs \
1164 finite \
1165 fork \
1166 fpclass \
1167 fstatfs \
1168 fstatvfs \
1169 ftruncate \
1170 futimes \
1171 futimesat \
1172 getaddrinfo \
1173 getnetbyname \
1174 getopt_long \
1175 getpagesize \
1176 getprotobyname \
1177 getprotobynumber \
1178 getpwuid \
1179 getservbyport \
1180 gettid \
1181 gettimeofday \
1182 getuid \
1183 inet_network \
1184 lstat \
1185 memmove \
1186 mmap \
1187 pclose \
1188 popen \
1189 pread \
1190 pwrite \
1191 readlink \
1192 rfork \
1193 sched_yield \
1194 select \
1195 sendmsg \
1196 settimeofday \
1197 sigaltstack \
1198 sigprocmask \
1199 snprintf \
1200 spawnvp \
1201 statfs \
1202 statvfs \
1203 strcasecmp \
1204 strerror \
1205 strncasecmp \
1206 tcgetattr \
1207 timegm \
1208 usleep \
1209 vsnprintf \
1210 wait4 \
1211 waitpid \
1212 )
1214 dnl **** Checks for headers that depend on other ones ****
1216 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
1217 [#include <sys/types.h>
1218 #if HAVE_SYS_PARAM_H
1219 # include <sys/param.h>
1220 #endif])
1222 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
1223 [#include <sys/types.h>
1224 #if HAVE_SYS_SOCKET_H
1225 # include <sys/socket.h>
1226 #endif])
1228 AC_CHECK_HEADERS([resolv.h],,,
1229 [#include <sys/types.h>
1230 #if HAVE_SYS_SOCKET_H
1231 # include <sys/socket.h>
1232 #endif
1233 #if HAVE_NETINET_IN_H
1234 # include <netinet/in.h>
1235 #endif
1236 #if HAVE_ARPA_NAMESER_H
1237 # include <arpa/nameser.h>
1238 #endif])
1240 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1242 AC_CHECK_HEADERS([linux/ipx.h linux/videodev.h],,,
1243 [#ifdef HAVE_SYS_TIME_H
1244 #include <sys/time.h>
1245 #endif
1246 #include <sys/types.h>
1247 #ifdef HAVE_ASM_TYPES_H
1248 #include <asm/types.h>
1249 #endif])
1251 dnl **** Check for types ****
1253 AC_C_CONST
1254 AC_C_INLINE
1255 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1256 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1257 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1259 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1260 [#ifdef HAVE_LINUX_INPUT_H
1261 #include <linux/input.h>
1262 #endif])
1264 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1265 AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1266 wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1267 if test "$wine_cv_have_sigaddset" = "yes"
1268 then
1269 AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1270 fi
1273 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1274 wine_cv_linux_gethostbyname_r_6,
1275 AC_TRY_LINK([
1276 #include <netdb.h>
1277 ], [
1278 char *name=NULL;
1279 struct hostent he;
1280 struct hostent *result;
1281 char *buf=NULL;
1282 int bufsize=0;
1283 int res,errnr;
1284 char *addr=NULL;
1285 int addrlen=0;
1286 int addrtype=0;
1287 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1288 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1289 ],
1290 wine_cv_linux_gethostbyname_r_6=yes,
1291 wine_cv_linux_gethostbyname_r_6=no
1292 )
1293 )
1294 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1295 then
1296 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1297 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1298 fi
1300 if test "$ac_cv_header_linux_joystick_h" = "yes"
1301 then
1302 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1303 wine_cv_linux_joystick_22_api,
1304 AC_TRY_COMPILE([
1305 #include <sys/ioctl.h>
1306 #include <linux/joystick.h>
1308 struct js_event blub;
1309 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1310 #error "no 2.2 header"
1311 #endif
1312 ],/*empty*/,
1313 wine_cv_linux_joystick_22_api=yes,
1314 wine_cv_linux_joystick_22_api=no,
1315 wine_cv_linux_joystick_22_api=no
1316 )
1317 )
1318 if test "$wine_cv_linux_joystick_22_api" = "yes"
1319 then
1320 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1321 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1322 fi
1323 fi
1325 dnl **** statfs checks ****
1327 if test "$ac_cv_header_sys_vfs_h" = "yes"
1328 then
1329 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1330 wine_cv_sys_vfs_has_statfs,
1331 AC_TRY_COMPILE([
1332 #include <sys/types.h>
1333 #ifdef HAVE_SYS_PARAM_H
1334 # include <sys/param.h>
1335 #endif
1336 #include <sys/vfs.h>
1337 ],[
1338 struct statfs stfs;
1340 memset(&stfs,0,sizeof(stfs));
1341 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1342 )
1343 )
1344 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1345 then
1346 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1347 [Define if the struct statfs is defined by <sys/vfs.h>])
1348 fi
1349 fi
1351 if test "$ac_cv_header_sys_statfs_h" = "yes"
1352 then
1353 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1354 wine_cv_sys_statfs_has_statfs,
1355 AC_TRY_COMPILE([
1356 #include <sys/types.h>
1357 #ifdef HAVE_SYS_PARAM_H
1358 # include <sys/param.h>
1359 #endif
1360 #include <sys/statfs.h>
1361 ],[
1362 struct statfs stfs;
1363 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1364 )
1365 )
1366 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1367 then
1368 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1369 [Define if the struct statfs is defined by <sys/statfs.h>])
1370 fi
1371 fi
1373 if test "$ac_cv_header_sys_mount_h" = "yes"
1374 then
1375 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1376 wine_cv_sys_mount_has_statfs,
1377 AC_TRY_COMPILE([
1378 #include <sys/types.h>
1379 #ifdef HAVE_SYS_PARAM_H
1380 # include <sys/param.h>
1381 #endif
1382 #include <sys/mount.h>
1383 ],[
1384 struct statfs stfs;
1385 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1386 )
1387 )
1388 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1389 then
1390 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1391 [Define if the struct statfs is defined by <sys/mount.h>])
1392 fi
1393 fi
1395 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1397 dnl Check for statfs members
1398 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1399 [#include <sys/types.h>
1400 #ifdef HAVE_SYS_PARAM_H
1401 # include <sys/param.h>
1402 #endif
1403 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1404 # include <sys/mount.h>
1405 #else
1406 # ifdef STATFS_DEFINED_BY_SYS_VFS
1407 # include <sys/vfs.h>
1408 # else
1409 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1410 # include <sys/statfs.h>
1411 # endif
1412 # endif
1413 #endif])
1415 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1416 [#ifdef HAVE_SYS_STATVFS_H
1417 #include <sys/statvfs.h>
1418 #endif])
1420 dnl Check for socket structure members
1421 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1422 [#include <sys/types.h>
1423 #ifdef HAVE_SYS_SOCKET_H
1424 # include <sys/socket.h>
1425 #endif
1426 #ifdef HAVE_SYS_UN_H
1427 # include <sys/un.h>
1428 #endif])
1430 dnl Check for scsireq_t and sg_io_hdr_t members
1431 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1432 [#include <sys/types.h>
1433 #ifdef HAVE_SCSI_SG_H
1434 #include <scsi/sg.h>
1435 #endif])
1437 dnl Check for siginfo_t members
1438 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1440 dnl Check for struct option
1441 AC_CHECK_MEMBERS([struct option.name],,,
1442 [#ifdef HAVE_GETOPT_H
1443 #include <getopt.h>
1444 #endif])
1446 dnl Check for stat.st_blocks
1447 AC_CHECK_MEMBERS([struct stat.st_blocks])
1449 dnl Check for the external timezone variables timezone and daylight
1450 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1451 AC_TRY_LINK([#include <time.h>],[timezone;],
1452 ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1453 if test "$ac_cv_have_timezone" = "yes"
1454 then
1455 AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1456 fi
1457 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1458 AC_TRY_LINK([#include <time.h>],[daylight;],
1459 ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1460 if test "$ac_cv_have_daylight" = "yes"
1461 then
1462 AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1463 fi
1465 dnl *** check for the need to define platform-specific symbols
1467 case $host_cpu in
1468 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1469 *x86_64*) WINE_CHECK_DEFINE([__x86_64__]) ;;
1470 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1471 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1472 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1473 esac
1475 case $host_vendor in
1476 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1477 esac
1479 dnl **** Generate output files ****
1481 AH_TOP([#define __WINE_CONFIG_H])
1483 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1484 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1485 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1486 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1487 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1488 WINE_CONFIG_EXTRA_DIR(include/wine)
1490 MAKE_RULES=Make.rules
1491 AC_SUBST_FILE(MAKE_RULES)
1493 MAKE_DLL_RULES=dlls/Makedll.rules
1494 AC_SUBST_FILE(MAKE_DLL_RULES)
1496 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1497 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1499 MAKE_TEST_RULES=dlls/Maketest.rules
1500 AC_SUBST_FILE(MAKE_TEST_RULES)
1502 MAKE_LIB_RULES=libs/Makelib.rules
1503 AC_SUBST_FILE(MAKE_LIB_RULES)
1505 MAKE_PROG_RULES=programs/Makeprog.rules
1506 AC_SUBST_FILE(MAKE_PROG_RULES)
1508 AC_CONFIG_FILES([
1509 Make.rules
1510 dlls/Makedll.rules
1511 dlls/Makeimplib.rules
1512 dlls/Maketest.rules
1513 libs/Makelib.rules
1514 programs/Makeprog.rules
1515 Makefile
1516 dlls/Makefile
1517 dlls/activeds/Makefile
1518 dlls/advapi32/Makefile
1519 dlls/advapi32/tests/Makefile
1520 dlls/advpack/Makefile
1521 dlls/advpack/tests/Makefile
1522 dlls/amstream/Makefile
1523 dlls/atl/Makefile
1524 dlls/avicap32/Makefile
1525 dlls/avifil32/Makefile
1526 dlls/cabinet/Makefile
1527 dlls/capi2032/Makefile
1528 dlls/cards/Makefile
1529 dlls/cfgmgr32/Makefile
1530 dlls/comcat/Makefile
1531 dlls/comctl32/Makefile
1532 dlls/comctl32/tests/Makefile
1533 dlls/commdlg/Makefile
1534 dlls/crtdll/Makefile
1535 dlls/crypt32/Makefile
1536 dlls/crypt32/tests/Makefile
1537 dlls/cryptdll/Makefile
1538 dlls/ctl3d/Makefile
1539 dlls/d3d8/Makefile
1540 dlls/d3d9/Makefile
1541 dlls/d3d9/tests/Makefile
1542 dlls/d3dim/Makefile
1543 dlls/d3drm/Makefile
1544 dlls/d3dx8/Makefile
1545 dlls/d3dxof/Makefile
1546 dlls/dbghelp/Makefile
1547 dlls/dciman32/Makefile
1548 dlls/ddraw/Makefile
1549 dlls/ddraw/tests/Makefile
1550 dlls/devenum/Makefile
1551 dlls/dinput/Makefile
1552 dlls/dinput/tests/Makefile
1553 dlls/dinput8/Makefile
1554 dlls/dmband/Makefile
1555 dlls/dmcompos/Makefile
1556 dlls/dmime/Makefile
1557 dlls/dmloader/Makefile
1558 dlls/dmscript/Makefile
1559 dlls/dmstyle/Makefile
1560 dlls/dmsynth/Makefile
1561 dlls/dmusic/Makefile
1562 dlls/dmusic32/Makefile
1563 dlls/dplay/Makefile
1564 dlls/dplayx/Makefile
1565 dlls/dpnet/Makefile
1566 dlls/dpnhpast/Makefile
1567 dlls/dsound/Makefile
1568 dlls/dsound/tests/Makefile
1569 dlls/dswave/Makefile
1570 dlls/dxdiagn/Makefile
1571 dlls/dxerr8/Makefile
1572 dlls/dxerr9/Makefile
1573 dlls/dxguid/Makefile
1574 dlls/gdi/Makefile
1575 dlls/gdi/tests/Makefile
1576 dlls/glu32/Makefile
1577 dlls/glut32/Makefile
1578 dlls/hhctrl.ocx/Makefile
1579 dlls/iccvid/Makefile
1580 dlls/icmp/Makefile
1581 dlls/ifsmgr.vxd/Makefile
1582 dlls/imagehlp/Makefile
1583 dlls/imm32/Makefile
1584 dlls/iphlpapi/Makefile
1585 dlls/iphlpapi/tests/Makefile
1586 dlls/itss/Makefile
1587 dlls/kernel/Makefile
1588 dlls/kernel/tests/Makefile
1589 dlls/lzexpand/Makefile
1590 dlls/lzexpand/tests/Makefile
1591 dlls/mapi32/Makefile
1592 dlls/mapi32/tests/Makefile
1593 dlls/mciavi32/Makefile
1594 dlls/mcicda/Makefile
1595 dlls/mciseq/Makefile
1596 dlls/midimap/Makefile
1597 dlls/mlang/Makefile
1598 dlls/mlang/tests/Makefile
1599 dlls/mmdevldr.vxd/Makefile
1600 dlls/monodebg.vxd/Makefile
1601 dlls/mpr/Makefile
1602 dlls/msacm/Makefile
1603 dlls/msacm/imaadp32/Makefile
1604 dlls/msacm/msadp32/Makefile
1605 dlls/msacm/msg711/Makefile
1606 dlls/msacm/tests/Makefile
1607 dlls/msacm/winemp3/Makefile
1608 dlls/mscms/Makefile
1609 dlls/mscms/tests/Makefile
1610 dlls/msdmo/Makefile
1611 dlls/mshtml/Makefile
1612 dlls/mshtml/tests/Makefile
1613 dlls/msi/Makefile
1614 dlls/msi/tests/Makefile
1615 dlls/msimg32/Makefile
1616 dlls/msisys/Makefile
1617 dlls/msnet32/Makefile
1618 dlls/msrle32/Makefile
1619 dlls/msvcrt/Makefile
1620 dlls/msvcrt/tests/Makefile
1621 dlls/msvcrt20/Makefile
1622 dlls/msvcrt40/Makefile
1623 dlls/msvcrtd/Makefile
1624 dlls/msvcrtd/tests/Makefile
1625 dlls/msvidc32/Makefile
1626 dlls/msvideo/Makefile
1627 dlls/mswsock/Makefile
1628 dlls/msxml3/Makefile
1629 dlls/msxml3/tests/Makefile
1630 dlls/netapi32/Makefile
1631 dlls/netapi32/tests/Makefile
1632 dlls/newdev/Makefile
1633 dlls/ntdll/Makefile
1634 dlls/ntdll/tests/Makefile
1635 dlls/objsel/Makefile
1636 dlls/odbc32/Makefile
1637 dlls/odbccp32/Makefile
1638 dlls/ole32/Makefile
1639 dlls/ole32/tests/Makefile
1640 dlls/oleacc/Makefile
1641 dlls/oleaut32/Makefile
1642 dlls/oleaut32/tests/Makefile
1643 dlls/olecli/Makefile
1644 dlls/oledlg/Makefile
1645 dlls/olepro32/Makefile
1646 dlls/olesvr/Makefile
1647 dlls/opengl32/Makefile
1648 dlls/powrprof/Makefile
1649 dlls/psapi/Makefile
1650 dlls/psapi/tests/Makefile
1651 dlls/qcap/Makefile
1652 dlls/quartz/Makefile
1653 dlls/quartz/tests/Makefile
1654 dlls/rasapi32/Makefile
1655 dlls/riched20/Makefile
1656 dlls/richedit/Makefile
1657 dlls/rpcrt4/Makefile
1658 dlls/rpcrt4/tests/Makefile
1659 dlls/rsabase/Makefile
1660 dlls/rsabase/tests/Makefile
1661 dlls/rsaenh/Makefile
1662 dlls/rsaenh/tests/Makefile
1663 dlls/secur32/Makefile
1664 dlls/secur32/tests/Makefile
1665 dlls/security/Makefile
1666 dlls/sensapi/Makefile
1667 dlls/serialui/Makefile
1668 dlls/setupapi/Makefile
1669 dlls/setupapi/tests/Makefile
1670 dlls/shdocvw/Makefile
1671 dlls/shdocvw/tests/Makefile
1672 dlls/shell32/Makefile
1673 dlls/shell32/tests/Makefile
1674 dlls/shfolder/Makefile
1675 dlls/shlwapi/Makefile
1676 dlls/shlwapi/tests/Makefile
1677 dlls/snmpapi/Makefile
1678 dlls/stdole2.tlb/Makefile
1679 dlls/stdole32.tlb/Makefile
1680 dlls/sti/Makefile
1681 dlls/strmiids/Makefile
1682 dlls/tapi32/Makefile
1683 dlls/twain/Makefile
1684 dlls/unicows/Makefile
1685 dlls/url/Makefile
1686 dlls/urlmon/Makefile
1687 dlls/urlmon/tests/Makefile
1688 dlls/user/Makefile
1689 dlls/user/tests/Makefile
1690 dlls/usp10/Makefile
1691 dlls/uuid/Makefile
1692 dlls/uxtheme/Makefile
1693 dlls/vdhcp.vxd/Makefile
1694 dlls/vdmdbg/Makefile
1695 dlls/version/Makefile
1696 dlls/version/tests/Makefile
1697 dlls/vmm.vxd/Makefile
1698 dlls/vnbt.vxd/Makefile
1699 dlls/vnetbios.vxd/Makefile
1700 dlls/vtdapi.vxd/Makefile
1701 dlls/vwin32.vxd/Makefile
1702 dlls/win32s/Makefile
1703 dlls/winaspi/Makefile
1704 dlls/winecrt0/Makefile
1705 dlls/wined3d/Makefile
1706 dlls/winedos/Makefile
1707 dlls/wineps/Makefile
1708 dlls/wininet/Makefile
1709 dlls/wininet/tests/Makefile
1710 dlls/winmm/Makefile
1711 dlls/winmm/joystick/Makefile
1712 dlls/winmm/mciwave/Makefile
1713 dlls/winmm/tests/Makefile
1714 dlls/winmm/wavemap/Makefile
1715 dlls/winmm/winealsa/Makefile
1716 dlls/winmm/winearts/Makefile
1717 dlls/winmm/wineaudioio/Makefile
1718 dlls/winmm/wineesd/Makefile
1719 dlls/winmm/winejack/Makefile
1720 dlls/winmm/winenas/Makefile
1721 dlls/winmm/wineoss/Makefile
1722 dlls/winnls/Makefile
1723 dlls/winsock/Makefile
1724 dlls/winsock/tests/Makefile
1725 dlls/winspool/Makefile
1726 dlls/winspool/tests/Makefile
1727 dlls/wintab32/Makefile
1728 dlls/wintrust/Makefile
1729 dlls/wldap32/Makefile
1730 dlls/wow32/Makefile
1731 dlls/wsock32/Makefile
1732 dlls/wtsapi32/Makefile
1733 dlls/x11drv/Makefile
1734 documentation/Makefile
1735 fonts/Makefile
1736 include/Makefile
1737 libs/Makefile
1738 libs/port/Makefile
1739 libs/unicode/Makefile
1740 libs/wine/Makefile
1741 libs/wpp/Makefile
1742 loader/Makefile
1743 programs/Makefile
1744 programs/avitools/Makefile
1745 programs/clock/Makefile
1746 programs/cmdlgtst/Makefile
1747 programs/control/Makefile
1748 programs/eject/Makefile
1749 programs/expand/Makefile
1750 programs/explorer/Makefile
1751 programs/hh/Makefile
1752 programs/msiexec/Makefile
1753 programs/notepad/Makefile
1754 programs/progman/Makefile
1755 programs/regedit/Makefile
1756 programs/regsvr32/Makefile
1757 programs/rpcss/Makefile
1758 programs/rundll32/Makefile
1759 programs/start/Makefile
1760 programs/taskmgr/Makefile
1761 programs/uninstaller/Makefile
1762 programs/view/Makefile
1763 programs/wcmd/Makefile
1764 programs/wineboot/Makefile
1765 programs/winebrowser/Makefile
1766 programs/winecfg/Makefile
1767 programs/wineconsole/Makefile
1768 programs/winedbg/Makefile
1769 programs/winefile/Makefile
1770 programs/winemenubuilder/Makefile
1771 programs/winemine/Makefile
1772 programs/winepath/Makefile
1773 programs/winetest/Makefile
1774 programs/winevdm/Makefile
1775 programs/winhelp/Makefile
1776 programs/winver/Makefile
1777 server/Makefile
1778 tools/Makefile
1779 tools/widl/Makefile
1780 tools/winapi/Makefile
1781 tools/winebuild/Makefile
1782 tools/winedump/Makefile
1783 tools/winegcc/Makefile
1784 tools/wmc/Makefile
1785 tools/wrc/Makefile])
1787 AC_OUTPUT
1789 if test "$have_x" = "no"
1790 then
1791 echo
1792 echo "*** Warning: X development files not found. Wine will be built without"
1793 echo "*** X support, which currently does not work, and would probably not be"
1794 echo "*** what you want anyway. You will need to install devel packages of"
1795 echo "*** Xlib/Xfree86 at the very least."
1796 fi
1798 if test "$wine_cv_opengl_version_OK" = "no"
1799 then
1800 echo
1801 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1802 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1803 fi
1805 if test "$wine_cv_msg_freetype" = "yes"
1806 then
1807 echo
1808 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1809 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1810 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1811 echo "*** enable Wine to use TrueType fonts."
1812 fi
1814 if test -z "$ALSALIBS" -a \
1815 -z "$ARTSC_LIBS" -a \
1816 -z "$AUDIOIOLIBS" -a \
1817 -z "$NASLIBS" -a \
1818 -z "$ESD_LIBS" -a \
1819 -z "$ac_cv_lib_soname_jack" -a \
1820 "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1821 "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1822 "$ac_cv_header_soundcard_h" != "yes"
1823 then
1824 echo "*** No sound system was found. Windows applications will be silent."
1825 echo "*** The currently supported sound systems are:"
1826 echo "*** ALSA, ARTS, EsounD, AudioIO, Jack, NAS and OSS"
1827 fi
1829 echo
1830 echo "Configure finished. Do '${ac_make} depend && ${ac_make}' to compile Wine."
1831 echo
1833 dnl Local Variables:
1834 dnl comment-start: "dnl "
1835 dnl comment-end: ""
1836 dnl comment-start-skip: "\\bdnl\\b\\s *"
1837 dnl compile-command: "autoconf"
1838 dnl End: