configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 dnl **** Command-line arguments ****
  10
  11 dnl Default values
  12 LIBEXT=so       # library type .so or .a
  13 TRACE_MSGS=yes  # the TRACE() macro
  14 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  15 CURSES=yes
  16 OPENGL=normal
  17
  18 AC_ARG_ENABLE(debug,
  19 [  --disable-debug         compile out all debugging messages],
  20 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  21
  22 AC_ARG_ENABLE(opengl,
  23 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe via pthread],
  24 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  25
  26 AC_ARG_ENABLE(trace,
  27 [  --disable-trace         compile out TRACE messages],
  28 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  29
  30 AC_ARG_WITH(curses,
  31 [  --without-curses        do not use curses],
  32 [if test "$withval" = "no"; then CURSES="no"; fi])
  33
  34 AC_ARG_WITH(reentrant-x,
  35 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  36
  37 AC_SUBST(OPTIONS)
  38
  39 if test "$DEBUG_MSGS" = "no"
  40 then
  41     AC_DEFINE(NO_DEBUG_MSGS)
  42     AC_DEFINE(NO_TRACE_MSGS)
  43 else
  44     if test "$TRACE_MSGS" = "no"
  45     then
  46         AC_DEFINE(NO_TRACE_MSGS)
  47     fi
  48 fi
  49
  50 dnl **** Check for some programs ****
  51
  52 AC_PROG_MAKE_SET
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PATH_XTRA
  56 AC_PROG_YACC
  57 AC_PROG_LEX
  58 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  59 if test "$XLEX" = "none"
  60 then
  61         echo "*** Error: No suitable lex found. ***"
  62         echo "    Please install the 'flex' package."
  63         exit 1
  64 fi
  65 AC_DECL_YYTEXT
  66 AC_PROG_RANLIB
  67 AC_PROG_INSTALL
  68 AC_PROG_LN_S
  69 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  70 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  71 AC_CYGWIN
  72 AC_CHECK_PROG(DLLWRAP,dllwrap,dllwrap,false)
  73
  74 dnl Check for lint
  75 AC_CHECK_PROGS(LINT, lclint lint)
  76 if test "$LINT" = "lint"
  77 then
  78   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  79   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  80 fi
  81 AC_SUBST(LINT)
  82 AC_SUBST(LINTFLAGS)
  83
  84 if test "$CYGWIN" = "yes"
  85 then
  86     LDCOMBINE="ld -r --enable-stdcall-fixup"
  87 else
  88     LDCOMBINE="ld -r"
  89 fi
  90 AC_SUBST(LDCOMBINE)
  91
  92 dnl **** Check for some libraries ****
  93
  94 dnl Check for -lm for BeOS
  95 AC_CHECK_LIB(m,sqrt)
  96 dnl Check for -li386 for NetBSD and OpenBSD
  97 AC_CHECK_LIB(i386,i386_set_ldt)
  98 dnl Check for -lossaudio for NetBSD
  99 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 100 dnl Check for -lw for Solaris
 101 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 102 dnl Check for -lnsl for Solaris
 103 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 104 dnl Check for -lsocket for Solaris
 105 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 106 dnl Check for -lxpg4 for FreeBSD
 107 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 108 dnl Check for -lmmap for OS/2
 109 AC_CHECK_LIB(mmap,mmap)
 110 dnl Check for openpty
 111 AC_CHECK_FUNCS(openpty,,
 112         AC_CHECK_LIB(util,openpty,
 113                 AC_DEFINE(HAVE_OPENPTY)
 114                 LIBS="$LIBS -lutil"
 115         ))
 116
 117 AC_CHECK_HEADERS(dlfcn.h,
 118         AC_CHECK_FUNCS(dlopen,
 119                 AC_DEFINE(HAVE_DL_API),
 120                 AC_CHECK_LIB(dl,dlopen,
 121                         AC_DEFINE(HAVE_DL_API)
 122                         LIBS="$LIBS -ldl",
 123                         LIBEXT="a"
 124                 )
 125         ),
 126         LIBEXT="a"
 127 )
 128 AC_SUBST(XLIB)
 129 AC_SUBST(X_DLLS)
 130 X_DLLS=""
 131 AC_SUBST(XFILES)
 132 XFILES=""
 133 AC_SUBST(OPENGLFILES)
 134 OPENGLFILES=""
 135 AC_SUBST(OPENGL32_DLL)
 136 OPENGL32_DLL=""
 137 if test "$have_x" = "yes"
 138 then
 139     XLIB="-lXext -lX11"
 140     ac_save_CPPFLAGS="$CPPFLAGS"
 141     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 142
 143     dnl *** Check for -lXpm
 144     AC_CHECK_HEADERS(X11/xpm.h,
 145       [ dnl *** If X11/xpm.h exists...
 146         AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
 147           [ AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
 148           $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 149         )
 150       ],
 151       [ dnl *** If X11/xpm.h does not exist...
 152         dnl NOTE: autoconf does not allow commas inside the third
 153         dnl       parameter to AC_CHECK_HEADERS, due to some quoting
 154         dnl       magic it does.
 155         echo "Redhat            :       xpm xpm-devel"
 156         echo "Caldera OpenLinux :       xpm xpm-devel xpm-devel-static"
 157         echo "SuSE              :       xpm"
 158         echo "Debian/Corel Linux:       xpm4g xpm4g-dev"
 159         echo
 160         echo "Or get the sources from ftp.x.org and all its mirror sites from "
 161         echo "the directory /contrib/libraries."
 162         echo
 163         exit 1
 164       ]
 165     )
 166
 167     dnl *** All three of the following tests require X11/Xlib.h
 168     AC_CHECK_HEADERS(X11/Xlib.h,
 169       [
 170         dnl *** Check for X keyboard extension
 171         AC_CHECK_HEADERS(X11/XKBlib.h,
 172             [ dnl *** If X11/XKBlib.h exists...
 173               AC_CHECK_LIB(X11, XkbQueryExtension,
 174               AC_DEFINE(HAVE_XKB),,
 175               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 176             ],
 177             AC_MSG_WARN([XKB extension not found!!])
 178         )
 179
 180         dnl *** Check for X Shm extension
 181         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 182             [ dnl *** If X11/extensions/XShm.h exists...
 183               AC_CHECK_LIB(Xext, XShmQueryExtension,
 184               AC_DEFINE(HAVE_LIBXXSHM),,
 185               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 186             ],
 187             AC_MSG_WARN([Xshm extension not found!!])
 188         )
 189
 190         dnl *** Check for X shape extension
 191         AC_CHECK_HEADERS(X11/extensions/shape.h,
 192             [ dnl *** If X11/extensions/shape.h exists...
 193               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 194               AC_DEFINE(HAVE_LIBXSHAPE),,
 195               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 196             ],
 197             AC_MSG_WARN([XShape extension not found!!])
 198         )
 199
 200         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 201         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 202             [ dnl *** If X11/extensions/xf86dga.h exists, check
 203               dnl *** for XDGAQueryExtension()...
 204               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 205                 [ dnl *** If found...
 206                   AC_DEFINE(HAVE_LIBXXF86DGA2)
 207                   AC_DEFINE(HAVE_LIBXXF86DGA)
 208                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 209                ],
 210                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 211                   dnl *** instead (DGA 2.0 not found)...
 212                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 213                     [ AC_DEFINE(HAVE_LIBXXF86DGA)
 214                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 215                     ],,
 216                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 217                   )
 218                 ],
 219                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 220               )
 221             ],
 222             AC_MSG_WARN([DGA extension not found!!])
 223         )
 224
 225         dnl *** Check for XFree86 VMODE extension
 226         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 227             [ dnl *** If X11/extensions/xf86vmode.h exists...
 228                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 229                   [ AC_DEFINE(HAVE_LIBXXF86VM)
 230                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 231                   ],,
 232                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 233                 )
 234             ],
 235             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 236         )
 237
 238         dnl *** Check for XVideo extension supporting XvImages
 239         AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
 240             [ dnl *** If X11/extensions/Xvlib.h exists...
 241                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 242                   [ AC_DEFINE(HAVE_XVIDEO)
 243                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 244                   ],,
 245                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 246                 )
 247             ],
 248             AC_MSG_WARN([XVideo extension not found !!])
 249         )
 250
 251       ]
 252     ) dnl *** End of X11/Xlib.h check
 253
 254     dnl Check for the presence of OpenGL
 255     if test $OPENGL = "yes" -o $OPENGL = "normal"
 256     then
 257         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 258         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 259         then
 260             dnl Check for some problems due to old Mesa versions
 261             AC_CACHE_CHECK("for up-to-date OpenGL version", wine_cv_opengl_version_OK,
 262               AC_TRY_COMPILE(
 263                 [#include <GL/gl.h>],
 264                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 265                 [wine_cv_opengl_version_OK="yes"],
 266                 [wine_cv_opengl_version_OK="no"]
 267               )
 268             )
 269
 270             dnl Check for the thread-safety of the OpenGL library
 271             AC_CACHE_CHECK("for thread-safe OpenGL version",
 272                            wine_cv_opengl_version_threadsafe,
 273               [saved_libs=$LIBS
 274                LIBS="$X_LIBS -lGL"
 275                AC_TRY_LINK([],[pthread_getspecific();],
 276                               [wine_cv_opengl_version_threadsafe="yes"],
 277                               [wine_cv_opengl_version_threadsafe="no"])
 278                LIBS=$saved_libs]
 279             )
 280
 281             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 282             then
 283                 dnl Check for the presence of the library
 284                 AC_CHECK_LIB(GL,glXCreateContext,
 285                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 286                              ,,
 287                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 288
 289                 if test $ac_cv_lib_GL_glXCreateContext = "yes"
 290                 then
 291
 292                         OPENGLFILES='$(OPENGLFILES)'
 293                         AC_DEFINE(HAVE_OPENGL)
 294
 295                         AC_CHECK_LIB(GL,glXGetProcAddressARB,AC_DEFINE(HAVE_GLX_GETPROCADDRESS),,$X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 296
 297                         if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
 298                         then
 299                                AC_CACHE_CHECK("for OpenGL extension functions prototypes", wine_cv_extension_prototypes,
 300                                   AC_TRY_COMPILE([#include <GL/gl.h>
 301                                                   #ifdef HAVE_GL_GLEXT_H
 302                                                   # include <GL/glext.h>
 303                                                   #endif
 304                                                   ],
 305                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 306                                                  [wine_cv_extension_prototypes="yes"],
 307                                                  [wine_cv_extension_prototypes="no"]
 308                                   )
 309                                 )
 310                                 if test $wine_cv_extension_prototypes = "yes"
 311                                 then
 312                                         AC_DEFINE(HAVE_GLEXT_PROTOTYPES)
 313                                 fi
 314
 315                                 OPENGL32_DLL=opengl32
 316                         fi
 317
 318                         AC_CHECK_HEADERS(GL/osmesa.h,
 319                             [ dnl *** If GL/osmesa.h exists...
 320                                 AC_CHECK_LIB(GL, OSMesaCreateContext,
 321                                   AC_DEFINE(HAVE_OSMESA),
 322                                   AC_CHECK_LIB(OSMesa, OSMesaCreateContext,
 323                                   [ AC_DEFINE(HAVE_OSMESA)
 324                                     X_PRE_LIBS="$X_PRE_LIBS -lOSMesa"
 325                                   ],,-lGL $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS),
 326                                   $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 327                                 )
 328                             ]
 329                         )
 330                 fi
 331              fi
 332          fi
 333     fi
 334
 335     CPPFLAGS="$ac_save_CPPFLAGS"
 336     X_DLLS='$(X_DLLS)'
 337     XFILES='$(XFILES)'
 338 else
 339     XLIB=""
 340     X_CFLAGS=""
 341     X_LIBS=""
 342 fi
 343
 344 dnl **** Check which curses lib to use ***
 345 if test "$CURSES" = "yes"
 346 then
 347     AC_CHECK_HEADERS(ncurses.h)
 348     if test "$ac_cv_header_ncurses_h" = "yes"
 349     then
 350         AC_CHECK_LIB(ncurses,waddch)
 351     fi
 352     if test "$ac_cv_lib_ncurses_waddch" = "yes"
 353     then
 354         AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 355         AC_CHECK_LIB(ncurses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 356     else
 357         AC_CHECK_HEADERS(curses.h)
 358         if test "$ac_cv_header_curses_h" = "yes"
 359         then
 360             AC_CHECK_LIB(curses,waddch)
 361             if test "$ac_cv_lib_curses_waddch" = "yes"
 362             then
 363                 AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 364                 AC_CHECK_LIB(curses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 365             fi
 366         fi
 367     fi
 368 fi
 369
 370 CUPSLIBS=""
 371 dnl **** Check for CUPS ****
 372 wine_cv_warn_cups_h=no
 373 AC_CHECK_LIB(cups,cupsGetPPD,
 374         AC_CHECK_HEADER(cups/cups.h,
 375             AC_DEFINE(HAVE_CUPS)
 376             CUPSLIBS="-lcups",
 377             wine_cv_warn_cups_h=yes)
 378 )
 379 AC_SUBST(CUPSLIBS)
 380
 381 dnl **** Check for FreeType 2 ****
 382 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no)
 383 if test "$ft_lib" = "no"
 384 then
 385     FREETYPELIBS=""
 386     FREETYPEINCL=""
 387     wine_cv_msg_freetype=no
 388 else
 389     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 390     if test "$ft_devel" = "no"
 391     then
 392         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 393         if test "$ft_devel2" = "freetype2-config"
 394         then
 395                 ft_devel=$ft_devel2
 396         fi
 397     fi
 398     if test "$ft_devel" = "no"
 399     then
 400         FREETYPELIBS=""
 401         FREETYPEINCL=""
 402         wine_cv_msg_freetype=yes
 403     else
 404         AC_DEFINE(HAVE_FREETYPE)
 405         FREETYPELIBS=`$ft_devel --libs`
 406         FREETYPEINCL=`$ft_devel --cflags`
 407         wine_cv_msg_freetype=no
 408     fi
 409 fi
 410 AC_SUBST(FREETYPELIBS)
 411 AC_SUBST(FREETYPEINCL)
 412
 413 dnl **** Check for IPX (currently Linux only) ****
 414 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 415  AC_TRY_COMPILE(
 416    [#include <sys/socket.h>
 417     #include <netipx/ipx.h>],
 418    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 419    [ac_cv_c_ipx_gnu="yes"],
 420    [ac_cv_c_ipx_gnu="no"])
 421  )
 422 if test "$ac_cv_c_ipx_gnu" = "yes"
 423 then
 424     AC_DEFINE(HAVE_IPX_GNU)
 425 fi
 426
 427 if test "$ac_cv_c_ipx_gnu" = "no"
 428 then
 429  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 430   AC_TRY_COMPILE(
 431     [#include <sys/socket.h>
 432      #include <asm/types.h>
 433      #include <linux/ipx.h>],
 434     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 435     [ac_cv_c_ipx_linux="yes"],
 436     [ac_cv_c_ipx_linux="no"])
 437   )
 438   if test "$ac_cv_c_ipx_linux" = "yes"
 439   then
 440       AC_DEFINE(HAVE_IPX_LINUX)
 441   fi
 442 fi
 443
 444 dnl **** Check for Open Sound System ****
 445 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 446
 447 AC_CACHE_CHECK("for Open Sound System",
 448         ac_cv_c_opensoundsystem,
 449         AC_TRY_COMPILE([
 450         #if defined(HAVE_SYS_SOUNDCARD_H)
 451                 #include <sys/soundcard.h>
 452         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 453                 #include <machine/soundcard.h>
 454         #elif defined(HAVE_SOUNDCARD_H)
 455                 #include <soundcard.h>
 456         #endif
 457         ],[
 458
 459 /* check for one of the Open Sound System specific SNDCTL_ defines */
 460 #if !defined(SNDCTL_DSP_STEREO)
 461 #error No open sound system
 462 #endif
 463 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 464
 465 if test "$ac_cv_c_opensoundsystem" = "yes"
 466 then
 467     AC_DEFINE(HAVE_OSS)
 468 fi
 469
 470 AC_CACHE_CHECK("for Open Sound System/MIDI interface",
 471         ac_cv_c_opensoundsystem_midi,
 472         AC_TRY_COMPILE([
 473         #if defined(HAVE_SYS_SOUNDCARD_H)
 474                 #include <sys/soundcard.h>
 475         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 476                 #include <machine/soundcard.h>
 477         #elif defined(HAVE_SOUNDCARD_H)
 478                 #include <soundcard.h>
 479         #endif
 480         ],[
 481
 482 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 483 #if !defined(SNDCTL_SEQ_SYNC)
 484 #error No open sound system MIDI interface
 485 #endif
 486 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 487
 488 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 489 then
 490     AC_DEFINE(HAVE_OSS_MIDI)
 491 fi
 492
 493 dnl **** If ln -s doesn't work, use cp instead ****
 494 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 495
 496 dnl **** Check for gcc strength-reduce bug ****
 497
 498 if test "x${GCC}" = "xyes"
 499 then
 500   CFLAGS="$CFLAGS -Wall"
 501   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 502                   AC_TRY_RUN([
 503 int     L[[4]] = {0,1,2,3};
 504 int main(void) {
 505   static int Array[[3]];
 506   unsigned int B = 3;
 507   int i;
 508   for(i=0; i<B; i++) Array[[i]] = i - 3;
 509   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 510   L[[i]] = 4;
 511
 512   exit( Array[[1]] != -2 || L[[2]] != 3);
 513 }],
 514     ac_cv_c_gcc_strength_bug="no",
 515     ac_cv_c_gcc_strength_bug="yes",
 516     ac_cv_c_gcc_strength_bug="yes") )
 517   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 518   then
 519     CFLAGS="$CFLAGS -fno-strength-reduce"
 520   fi
 521
 522   dnl Check for -mpreferred-stack-boundary
 523   AC_CACHE_CHECK("for gcc -mpreferred-stack-boundary=2 support",
 524                  ac_cv_c_gcc_stack_boundary,
 525   [saved_cflags=$CFLAGS
 526   CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 527   AC_TRY_COMPILE(,[return 0],ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")
 528   CFLAGS=$saved_cflags
 529   ])
 530   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 531   then
 532     CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 533   fi
 534 fi
 535
 536 dnl **** Check if we need to place .type inside a .def directive ****
 537
 538 AC_CACHE_CHECK("whether .type must sit inside a .def directive",
 539                ac_cv_c_type_in_def,
 540 [saved_libs=$LIBS
 541 LIBS="conftest_asm.s $LIBS"
 542 cat > conftest_asm.s <<EOF
 543         .globl _ac_test
 544         .def _ac_test; .scl 2; .type 32; .endef
 545 _ac_test:
 546         .long 0
 547 EOF
 548 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
 549 LIBS=$saved_libs])
 550 if test "$ac_cv_c_type_in_def" = "yes"
 551 then
 552   AC_DEFINE(NEED_TYPE_IN_DEF)
 553 fi
 554
 555 dnl **** Check for underscore on external symbols ****
 556
 557 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 558                ac_cv_c_extern_prefix,
 559 [saved_libs=$LIBS
 560 LIBS="conftest_asm.s $LIBS"
 561 cat > conftest_asm.s <<EOF
 562         .globl _ac_test
 563 _ac_test:
 564         .long 0
 565 EOF
 566 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 567             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 568 LIBS=$saved_libs])
 569 if test "$ac_cv_c_extern_prefix" = "yes"
 570 then
 571   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 572 fi
 573
 574 dnl **** Check for .string in assembler ****
 575
 576 AC_CACHE_CHECK("whether assembler accepts .string",
 577                ac_cv_c_asm_string,
 578 [saved_libs=$LIBS
 579 LIBS="conftest_asm.s $LIBS"
 580 cat > conftest_asm.s <<EOF
 581         .string "test"
 582 EOF
 583 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 584 LIBS=$saved_libs])
 585 if test "$ac_cv_c_asm_string" = "yes"
 586 then
 587   AC_DEFINE(HAVE_ASM_STRING)
 588 fi
 589
 590 dnl **** Check for working dll ****
 591
 592 LDSHARED=""
 593 LDDLLFLAGS=""
 594 if test "$LIBEXT" = "so"
 595 then
 596   AC_CACHE_CHECK("whether we can build a Linux dll",
 597                  ac_cv_c_dll_linux,
 598   [saved_cflags=$CFLAGS
 599   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
 600   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 601   CFLAGS=$saved_cflags
 602   ])
 603   if test "$ac_cv_c_dll_linux" = "yes"
 604   then
 605     LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%) -Wl,-rpath,\$(libdir)"
 606     LDDLLFLAGS="-Wl,-Bsymbolic"
 607   else
 608     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 609                  ac_cv_c_dll_unixware,
 610     [saved_cflags=$CFLAGS
 611     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
 612     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 613     CFLAGS=$saved_cflags
 614     ])
 615     if test "$ac_cv_c_dll_unixware" = "yes"
 616     then
 617       LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,\$(libdir)/%)"
 618       LDDLLFLAGS="-Wl,-B,symbolic"
 619     else
 620       AC_CACHE_CHECK("whether we can build a NetBSD a.out dll",
 621                    ac_cv_c_dll_netbsd,
 622       [saved_cflags=$CFLAGS
 623       CFLAGS="$CFLAGS -fPIC -Wl,-Bshareable,-Bforcearchive"
 624       AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 625       CFLAGS=$saved_cflags
 626       ])
 627       if test "$ac_cv_c_dll_netbsd" = "yes"
 628       then
 629         LDSHARED="\$(CC) -Wl,-Bshareable,-Bforcearchive"
 630         LDDLLFLAGS="" #FIXME
 631       fi
 632     fi
 633   fi
 634   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_unixware" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 635   then
 636     LIBEXT="a"
 637     if test "$DLLWRAP" = "dllwrap"; then
 638       dnl FIXME - check whether dllwrap works correctly...
 639       if test "$CYGWIN" = "yes"; then
 640         echo "*** use dllwrap for building shared library."
 641         LIBEXT="dll"
 642       fi
 643     fi
 644   fi
 645 fi
 646
 647 if test "$LIBEXT" = "a"; then
 648   echo "*** It is currently not possible to build WINE without shared"
 649   echo "*** library (.so) support to allow transparent switch between .so"
 650   echo "*** and .dll files."
 651   echo "*** If you are using Linux, you will need a newer binutils."
 652   exit 1
 653 fi
 654
 655 DLLFLAGS=""
 656 LDPATH=""
 657
 658 if test "$LIBEXT" = "so"; then
 659     DLLFLAGS="-fPIC"
 660     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
 661     LDPATH="LD_LIBRARY_PATH=\"\$(TOPOBJDIR)/unicode:\$\$LD_LIBRARY_PATH\""
 662 elif test "$LIBEXT" = "dll"; then
 663     #DLLFLAGS="-fPIC" # -fPIC doesn't work(at least in cygwin-b20) - FIXME
 664     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
 665     LDPATH="PATH=\"\$(TOPOBJDIR)/unicode:\$\$PATH\""
 666 else
 667     DLL_LINK="-L\$(DLLDIR) \$(DLLS:%=-l%) \$(LIBWINE) \$(LIBUNICODE) \$(X_LIBS) \$(XLIB)"
 668     AC_CACHE_CHECK([whether the linker supports --[[no]]-whole-archive (Linux)],
 669                    ac_cv_c_whole_archive,
 670             [saved_cflags=$CFLAGS
 671             CFLAGS="$CFLAGS -Wl,--whole-archive -Wl,--no-whole-archive"
 672             AC_TRY_LINK(,[return 1],ac_cv_c_whole_archive="yes",ac_cv_c_whole_archive="no")
 673             CFLAGS=$saved_cflags
 674             ])
 675     if test "$ac_cv_c_whole_archive" = "yes"
 676     then
 677         DLL_LINK="-Wl,--whole-archive $DLL_LINK -Wl,--no-whole-archive"
 678     else
 679         AC_CACHE_CHECK([whether the linker supports -z {all,default}extract (Linux)],
 680                        ac_cv_c_allextract,
 681                 [saved_cflags=$CFLAGS
 682                 CFLAGS="$CFLAGS -Wl,-z,allextract -Wl,-z,defaultextract"
 683                 AC_TRY_LINK(,[return 1],ac_cv_c_allextract="yes",ac_cv_c_allextract="no")
 684                 CFLAGS=$saved_cflags
 685                 ])
 686         if test "$ac_cv_c_allextract" = "yes"
 687         then
 688             DLL_LINK="-Wl,-z,allextract $DLL_LINK -Wl,-z,defaultextract"
 689         fi
 690     fi
 691 fi
 692
 693 AC_SUBST(DLL_LINK)
 694 AC_SUBST(DLLFLAGS)
 695 AC_SUBST(LDSHARED)
 696 AC_SUBST(LDDLLFLAGS)
 697 AC_SUBST(LIBEXT)
 698 AC_SUBST(LDPATH)
 699
 700 dnl **** Check for reentrant libc ****
 701 dnl
 702 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 703 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 704
 705 AC_DEFUN(WINE_CHECK_ERRNO,
 706 [
 707   AC_CACHE_CHECK(for reentrant libc: $1, wine_cv_libc_r_$1,
 708   [AC_TRY_RUN([int myerrno = 0;
 709 char buf[256];
 710 int *$1(){return &myerrno;}
 711 main(){connect(0,buf,255); exit(!myerrno);}],
 712   wine_cv_libc_r_$1=yes, wine_cv_libc_r_$1=no,
 713   wine_cv_libc_r_$1=yes )
 714 ])
 715 if test "$wine_cv_libc_r_$1" = "yes"
 716 then
 717     wine_cv_libc_reentrant=$1
 718 fi
 719 ])
 720
 721 wine_cv_libc_reentrant=no
 722 dnl Linux style errno location
 723 WINE_CHECK_ERRNO(__errno_location)
 724 dnl FreeBSD style errno location
 725 WINE_CHECK_ERRNO(__error)
 726 dnl Solaris style errno location
 727 WINE_CHECK_ERRNO(___errno)
 728 dnl UnixWare style errno location
 729 WINE_CHECK_ERRNO(__thr_errno)
 730 dnl NetBSD style errno location
 731 WINE_CHECK_ERRNO(__errno)
 732
 733 if test "$wine_cv_libc_reentrant" != "no"
 734 then
 735   AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant)
 736 fi
 737
 738 dnl **** Check for reentrant X libraries ****
 739 dnl
 740 dnl This may fail to determine whether X libraries are reentrant if
 741 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 742 dnl is possible with the --without-reentrant-x option.
 743
 744 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 745 then
 746 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 747   [ if test "x$with_reentrant_x" = "xno"
 748     then
 749         wine_cv_x_reentrant=no
 750     else
 751         libX11_check=none
 752         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 753             if test -r $dir/libX11.so; then
 754                 libX11_check="-D $dir/libX11.so"
 755                 break 1
 756             fi
 757             if test -r $dir/libX11.a; then
 758                 libX11_check="$dir/libX11.a"
 759                 break 1
 760             fi
 761         done
 762         if test "$libX11_check" != "none"; then
 763             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 764             then
 765                 wine_cv_x_reentrant=yes
 766             else
 767                 wine_cv_x_reentrant=no
 768             fi
 769         else
 770             wine_cv_x_reentrant=unknown
 771         fi
 772     fi ] )
 773 else
 774     wine_cv_x_reentrant=no
 775 fi
 776 if test "$wine_cv_x_reentrant" = "no"
 777 then
 778   AC_DEFINE(NO_REENTRANT_X11)
 779 fi
 780
 781
 782 dnl **** Check for functions ****
 783
 784 AC_FUNC_ALLOCA()
 785 AC_CHECK_FUNCS(\
 786         __libc_fork \
 787         _lwp_create \
 788         clone \
 789         ecvt \
 790         finite \
 791         fpclass \
 792         ftruncate64 \
 793         getnetbyaddr \
 794         getnetbyname \
 795         getpagesize \
 796         getprotobyname \
 797         getprotobynumber \
 798         getrlimit \
 799         getservbyport \
 800         getsockopt \
 801         inet_network \
 802         lseek64 \
 803         lstat \
 804         memmove \
 805         mmap \
 806         rfork \
 807         select \
 808         sendmsg \
 809         settimeofday \
 810         sigaltstack \
 811         statfs \
 812         strcasecmp \
 813         strerror \
 814         strncasecmp \
 815         tcgetattr \
 816         timegm \
 817         usleep \
 818         vfscanf \
 819         wait4 \
 820         waitpid \
 821 )
 822
 823 dnl **** Check for header files ****
 824
 825 AC_CHECK_HEADERS(\
 826         arpa/inet.h \
 827         arpa/nameser.h \
 828         elf.h \
 829         float.h \
 830         ieeefp.h \
 831         libio.h \
 832         libutil.h \
 833         link.h \
 834         linux/cdrom.h \
 835         linux/input.h \
 836         linux/joystick.h \
 837         linux/ucdrom.h \
 838         net/if.h \
 839         netdb.h \
 840         netinet/in.h \
 841         netinet/in_systm.h \
 842         netinet/ip.h \
 843         netinet/tcp.h \
 844         pty.h \
 845         resolv.h \
 846         sched.h \
 847         socket.h \
 848         strings.h \
 849         sys/cdio.h \
 850         sys/errno.h \
 851         sys/file.h \
 852         sys/filio.h \
 853         sys/ipc.h \
 854         sys/lwp.h \
 855         sys/mman.h \
 856         sys/modem.h \
 857         sys/mount.h \
 858         sys/msg.h \
 859         sys/param.h \
 860         sys/ptrace.h \
 861         sys/reg.h \
 862         sys/signal.h \
 863         sys/shm.h \
 864         sys/socket.h \
 865         sys/sockio.h \
 866         sys/statfs.h \
 867         sys/strtio.h \
 868         sys/syscall.h \
 869         sys/user.h \
 870         sys/wait.h \
 871         sys/v86.h \
 872         sys/v86intr.h \
 873         sys/vfs.h \
 874         sys/vm86.h \
 875         syscall.h \
 876         ucontext.h \
 877 )
 878 AC_HEADER_STAT()
 879
 880 dnl **** Check for types ****
 881
 882 AC_C_CONST()
 883 AC_C_INLINE()
 884 AC_TYPE_SIZE_T()
 885 AC_CHECK_SIZEOF(long long,0)
 886
 887 AC_CACHE_CHECK("whether linux/input.h is for real",
 888         wine_cv_linux_input_h,
 889         AC_TRY_COMPILE([
 890             #include <linux/input.h>
 891         ] , [
 892             int foo = EVIOCGBIT(EV_ABS,42);
 893             int bar = BTN_PINKIE;
 894             int fortytwo = 42;
 895         ],
 896         wine_cv_linux_input_h=yes,
 897         wine_cv_linux_input_h=no,
 898         no
 899         )
 900     )
 901     if test "$wine_cv_linux_input_h" = "yes"
 902     then
 903         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H)
 904     fi
 905
 906
 907 AC_CACHE_CHECK("whether we can use re-entrant gethostbyname_r Linux style",
 908         wine_cv_linux_gethostbyname_r_6,
 909         AC_TRY_COMPILE([
 910 #include <netdb.h>
 911         ], [
 912     char *name=NULL;
 913     struct hostent he;
 914     struct hostent *result;
 915     char *buf=NULL;
 916     int bufsize=0;
 917     int res,errnr;
 918     char *addr=NULL;
 919     int addrlen=0;
 920     int addrtype=0;
 921     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
 922     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
 923     ],
 924         wine_cv_linux_gethostbyname_r_6=yes,
 925         wine_cv_linux_gethostbyname_r_6=no
 926         )
 927    )
 928    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
 929    then
 930       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6)
 931    fi
 932
 933 if test "$ac_cv_header_linux_joystick_h" = "yes"
 934 then
 935    AC_CACHE_CHECK("whether linux/joystick.h uses the Linux 2.2+ API",
 936         wine_cv_linux_joystick_22_api,
 937         AC_TRY_COMPILE([
 938         #include <sys/ioctl.h>
 939         #include <linux/joystick.h>
 940
 941         struct js_event blub;
 942         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 943         #error "no 2.2 header"
 944         #endif
 945         ],/*empty*/,
 946         wine_cv_linux_joystick_22_api=yes,
 947         wine_cv_linux_joystick_22_api=no,
 948         wine_cv_linux_joystick_22_api=no
 949         )
 950    )
 951    if test "$wine_cv_linux_joystick_22_api" = "yes"
 952    then
 953       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API)
 954    fi
 955 fi
 956
 957 dnl **** statfs checks ****
 958
 959 if test "$ac_cv_header_sys_vfs_h" = "yes"
 960 then
 961     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 962                     wine_cv_sys_vfs_has_statfs,
 963         AC_TRY_COMPILE([
 964         #include <sys/types.h>
 965         #ifdef HAVE_SYS_PARAM_H
 966         # include <sys/param.h>
 967         #endif
 968         #include <sys/vfs.h>
 969         ],[
 970                 struct statfs stfs;
 971
 972                 memset(&stfs,0,sizeof(stfs));
 973         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 974         )
 975     )
 976     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 977     then
 978       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 979     fi
 980 fi
 981
 982 if test "$ac_cv_header_sys_statfs_h" = "yes"
 983 then
 984     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 985                     wine_cv_sys_statfs_has_statfs,
 986         AC_TRY_COMPILE([
 987         #include <sys/types.h>
 988         #ifdef HAVE_SYS_PARAM_H
 989         # include <sys/param.h>
 990         #endif
 991         #include <sys/statfs.h>
 992         ],[
 993                 struct statfs stfs;
 994         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 995         )
 996     )
 997     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 998     then
 999       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
1000     fi
1001 fi
1002
1003 if test "$ac_cv_header_sys_mount_h" = "yes"
1004 then
1005     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
1006                     wine_cv_sys_mount_has_statfs,
1007         AC_TRY_COMPILE([
1008         #include <sys/types.h>
1009         #ifdef HAVE_SYS_PARAM_H
1010         # include <sys/param.h>
1011         #endif
1012         #include <sys/mount.h>
1013         ],[
1014                 struct statfs stfs;
1015         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1016         )
1017     )
1018     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1019     then
1020       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
1021     fi
1022 fi
1023
1024 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1025
1026 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
1027   [ if test "x$statfs_bfree" = "xno"
1028     then
1029         wine_cv_statfs_bfree=no
1030     else
1031         AC_TRY_COMPILE([
1032         #include <sys/types.h>
1033         #ifdef HAVE_SYS_PARAM_H
1034         # include <sys/param.h>
1035         #endif
1036         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1037         # include <sys/mount.h>
1038         #else
1039         # ifdef STATFS_DEFINED_BY_SYS_VFS
1040         #  include <sys/vfs.h>
1041         # else
1042         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1043         #   include <sys/statfs.h>
1044         #  endif
1045         # endif
1046         #endif
1047         ],[
1048                 struct statfs stfs;
1049
1050                 stfs.f_bfree++;
1051         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
1052         )
1053     fi ] )
1054 if test "$wine_cv_statfs_bfree" = "yes"
1055 then
1056   AC_DEFINE(STATFS_HAS_BFREE)
1057 fi
1058
1059 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
1060   [ if test "x$statfs_bavail" = "xno"
1061     then
1062         wine_cv_statfs_bavail=no
1063     else
1064         AC_TRY_COMPILE([
1065         #include <sys/types.h>
1066         #ifdef HAVE_SYS_PARAM_H
1067         # include <sys/param.h>
1068         #endif
1069         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1070         # include <sys/mount.h>
1071         #else
1072         # ifdef STATFS_DEFINED_BY_SYS_VFS
1073         #  include <sys/vfs.h>
1074         # else
1075         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1076         #   include <sys/statfs.h>
1077         #  endif
1078         # endif
1079         #endif
1080         ],[
1081                 struct statfs stfs;
1082
1083                 stfs.f_bavail++;
1084         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1085         )
1086     fi ] )
1087 if test "$wine_cv_statfs_bavail" = "yes"
1088 then
1089   AC_DEFINE(STATFS_HAS_BAVAIL)
1090 fi
1091
1092 dnl *** check for file descriptor passing with msg_accrights
1093
1094 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
1095  AC_TRY_COMPILE([#include <sys/types.h>
1096 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1097                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1098 if test "$ac_cv_c_msg_accrights" = "yes"
1099 then
1100     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
1101 fi
1102
1103 dnl *** Check for the sun_len member in struct sockaddr_un
1104
1105 AC_CACHE_CHECK("for sun_len in struct sockaddr_un", ac_cv_c_sun_len,
1106  AC_TRY_COMPILE([#include <sys/types.h>
1107 #include <sys/socket.h>
1108 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1109                 ac_cv_c_sun_len="yes", ac_cv_c_sun_len="no"))
1110 if test "$ac_cv_c_sun_len" = "yes"
1111 then
1112     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)
1113 fi
1114
1115 dnl *** check for the need to define __i386__
1116
1117 AC_CACHE_CHECK("whether we need to define __i386__",ac_cv_cpp_def_i386,
1118  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1119 yes
1120 #endif],
1121  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1122 if test "$ac_cv_cpp_def_i386" = "yes"
1123 then
1124     CFLAGS="$CFLAGS -D__i386__"
1125     LINTFLAGS="$LINTFLAGS -D__i386__"
1126 fi
1127
1128 dnl $GCC is set by autoconf
1129 GCC_NO_BUILTIN=""
1130 if test "$GCC" = "yes"
1131 then
1132     GCC_NO_BUILTIN="-fno-builtin"
1133 fi
1134 AC_SUBST(GCC_NO_BUILTIN)
1135
1136 dnl **** Generate output files ****
1137
1138 AC_OUTPUT_COMMANDS([
1139 extra_subdirs="\
1140 dlls/ddraw/d3ddevice \
1141 dlls/ddraw/dclipper \
1142 dlls/ddraw/ddraw \
1143 dlls/ddraw/direct3d \
1144 dlls/ddraw/dpalette \
1145 dlls/ddraw/dsurface \
1146 dlls/dinput/joystick \
1147 dlls/dinput/keyboard \
1148 dlls/dinput/mouse \
1149 dlls/kernel/messages \
1150 dlls/user/resources \
1151 dlls/wineps/data \
1152 "
1153 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1154
1155 MAKE_RULES=Make.rules
1156 AC_SUBST_FILE(MAKE_RULES)
1157
1158 MAKE_DLL_RULES=dlls/Makedll.rules
1159 AC_SUBST_FILE(MAKE_DLL_RULES)
1160
1161 MAKE_PROG_RULES=programs/Makeprog.rules
1162 AC_SUBST_FILE(MAKE_PROG_RULES)
1163
1164 AC_OUTPUT([
1165 Make.rules
1166 dlls/Makedll.rules
1167 programs/Makeprog.rules
1168 Makefile
1169 console/Makefile
1170 controls/Makefile
1171 debugger/Makefile
1172 dlls/Makefile
1173 dlls/advapi32/Makefile
1174 dlls/avifil32/Makefile
1175 dlls/comctl32/Makefile
1176 dlls/commdlg/Makefile
1177 dlls/crtdll/Makefile
1178 dlls/dciman32/Makefile
1179 dlls/ddraw/Makefile
1180 dlls/dinput/Makefile
1181 dlls/dplay/Makefile
1182 dlls/dplayx/Makefile
1183 dlls/dsound/Makefile
1184 dlls/gdi/Makefile
1185 dlls/icmp/Makefile
1186 dlls/imagehlp/Makefile
1187 dlls/imm32/Makefile
1188 dlls/kernel/Makefile
1189 dlls/lzexpand/Makefile
1190 dlls/mpr/Makefile
1191 dlls/msacm/Makefile
1192 dlls/msnet32/Makefile
1193 dlls/msvcrt/Makefile
1194 dlls/msvideo/Makefile
1195 dlls/ntdll/Makefile
1196 dlls/odbc32/Makefile
1197 dlls/ole32/Makefile
1198 dlls/oleaut32/Makefile
1199 dlls/olecli/Makefile
1200 dlls/oledlg/Makefile
1201 dlls/olepro32/Makefile
1202 dlls/olesvr/Makefile
1203 dlls/opengl32/Makefile
1204 dlls/psapi/Makefile
1205 dlls/rasapi32/Makefile
1206 dlls/richedit/Makefile
1207 dlls/rpcrt4/Makefile
1208 dlls/serialui/Makefile
1209 dlls/setupapi/Makefile
1210 dlls/shdocvw/Makefile
1211 dlls/shell32/Makefile
1212 dlls/shfolder/Makefile
1213 dlls/shlwapi/Makefile
1214 dlls/tapi32/Makefile
1215 dlls/ttydrv/Makefile
1216 dlls/urlmon/Makefile
1217 dlls/user/Makefile
1218 dlls/version/Makefile
1219 dlls/win32s/Makefile
1220 dlls/winaspi/Makefile
1221 dlls/winedos/Makefile
1222 dlls/wineps/Makefile
1223 dlls/wininet/Makefile
1224 dlls/winmm/Makefile
1225 dlls/winmm/joystick/Makefile
1226 dlls/winmm/mcianim/Makefile
1227 dlls/winmm/mciavi/Makefile
1228 dlls/winmm/mcicda/Makefile
1229 dlls/winmm/mciseq/Makefile
1230 dlls/winmm/mciwave/Makefile
1231 dlls/winmm/midimap/Makefile
1232 dlls/winmm/wavemap/Makefile
1233 dlls/winmm/wineoss/Makefile
1234 dlls/winnls/Makefile
1235 dlls/winsock/Makefile
1236 dlls/winspool/Makefile
1237 dlls/wintrust/Makefile
1238 dlls/wow32/Makefile
1239 dlls/wsock32/Makefile
1240 dlls/x11drv/Makefile
1241 documentation/Makefile
1242 documentation/wine.conf.man
1243 documentation/wine.man
1244 files/Makefile
1245 graphics/Makefile
1246 graphics/enhmetafiledrv/Makefile
1247 graphics/metafiledrv/Makefile
1248 graphics/win16drv/Makefile
1249 graphics/x11drv/Makefile
1250 if1632/Makefile
1251 include/Makefile
1252 library/Makefile
1253 libtest/Makefile
1254 loader/Makefile
1255 loader/dos/Makefile
1256 loader/ne/Makefile
1257 memory/Makefile
1258 misc/Makefile
1259 miscemu/Makefile
1260 msdos/Makefile
1261 objects/Makefile
1262 ole/Makefile
1263 programs/Makefile
1264 programs/avitools/Makefile
1265 programs/clock/Makefile
1266 programs/cmdlgtst/Makefile
1267 programs/control/Makefile
1268 programs/notepad/Makefile
1269 programs/osversioncheck/Makefile
1270 programs/progman/Makefile
1271 programs/regapi/Makefile
1272 programs/regtest/Makefile
1273 programs/uninstaller/Makefile
1274 programs/view/Makefile
1275 programs/wcmd/Makefile
1276 programs/winemine/Makefile
1277 programs/winetest/Makefile
1278 programs/winhelp/Makefile
1279 programs/winver/Makefile
1280 relay32/Makefile
1281 scheduler/Makefile
1282 server/Makefile
1283 tools/Makefile
1284 tools/cvdump/Makefile
1285 tools/specmaker/Makefile
1286 tools/winebuild/Makefile
1287 tools/winelauncher
1288 tools/wmc/Makefile
1289 tools/wrc/Makefile
1290 tsx11/Makefile
1291 unicode/Makefile
1292 win32/Makefile
1293 windows/Makefile
1294 windows/x11drv/Makefile ])
1295
1296 if test "$have_x" = "no"
1297 then
1298   echo
1299   echo "*** Warning: X development files not found. Wine will be built without"
1300   echo "*** X support, which currently does not work, and would probably not be"
1301   echo "*** what you want anyway. You will need to install devel packages of"
1302   echo "*** Xlib/Xfree86 and Xpm at the very least."
1303 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1304 then
1305   echo
1306   echo "*** Warning: Xpm development files not found. Wine will be built without"
1307   echo "*** Xpm support, which currently does not work. You will need to install"
1308   echo "*** devel packages of Xpm."
1309 fi
1310
1311 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1312 then
1313   echo
1314   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1315   echo "*** terminal resize support. Consider upgrading ncurses."
1316 fi
1317
1318 if test "$wine_cv_libc_reentrant" = "no"
1319 then
1320   echo
1321   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1322   echo "*** thread support. Consider upgrading libc to a more recent"
1323   echo "*** reentrant version of libc."
1324 fi
1325
1326 if test "$wine_cv_opengl_version_OK" = "no"
1327 then
1328   echo
1329   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1330   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1331 fi
1332
1333 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1334 then
1335   echo
1336   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1337   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1338   echo "*** A fix for glibc 2.1.3 that seems to work is included in this version of Wine,"
1339   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1340 fi
1341
1342 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1343 then
1344   echo
1345   echo "*** Warning: you explicitly linked in a thread-safe OpenGL version. If you"
1346   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1347   echo "*** support before reporting bugs."
1348 fi
1349
1350 if test "$wine_cv_warn_cups_h" = "yes"
1351 then
1352   echo
1353   echo "*** Note: You have cups runtime libraries, but no development"
1354   echo "*** libraries. Install the cups-devel package or whichever package"
1355   echo "*** contains cups.h to enable CUPS support in WINE."
1356 fi
1357
1358 if test "$wine_cv_msg_freetype" = "yes"
1359 then
1360   echo
1361   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1362   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1363   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1364   echo "*** enable Wine to use TrueType fonts."
1365 fi
1366
1367 echo
1368 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1369 echo
1370
1371 dnl Local Variables:
1372 dnl comment-start: "dnl "
1373 dnl comment-end: ""
1374 dnl comment-start-skip: "\\bdnl\\b\\s *"
1375 dnl compile-command: "autoconf"
1376 dnl End: