configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  19 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  20
  21 AC_CANONICAL_HOST
  22 case $host in
  23   x86_64*linux*)
  24     if test "x$enable_win64" != "xyes"
  25     then
  26       test -n "$CC" || CC="gcc -m32"
  27       test -n "$LD" || LD="ld -m elf_i386"
  28       test -n "$AS" || AS="as --32"
  29       host_cpu="i386"
  30     fi
  31     ;;
  32 esac
  33
  34 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  35 case $host_cpu in
  36   *i[[3456789]]86*)
  37     if test "x$enable_win16" != "xno"
  38     then
  39       enable_win16="yes"
  40     fi
  41     ;;
  42 esac
  43
  44 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  45 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  46 if test "x$enable_win16" != "xyes"
  47 then
  48   WIN16_FILES=""
  49   WIN16_INSTALL=""
  50 fi
  51
  52 dnl **** Check for some programs ****
  53
  54 AC_PROG_MAKE_SET
  55 AC_PROG_CC
  56 AC_PROG_CXX
  57 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  58 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  59
  60 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  61   [if test -z "$with_wine_tools"; then
  62      if test "$cross_compiling" = "yes"; then
  63        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  64      else
  65        wine_cv_toolsdir="\$(TOPOBJDIR)"
  66      fi
  67    elif test -d "$with_wine_tools/tools/winebuild"; then
  68      case $with_wine_tools in
  69        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  70        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  71      esac
  72    else
  73      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  74    fi])
  75 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  76
  77 AC_PATH_XTRA
  78 AC_PROG_LEX
  79
  80 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  81 dnl **** without one present.
  82 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  83 if test "$XLEX" = "none"
  84 then
  85   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  86 fi
  87
  88 dnl Check for bison
  89 AC_CHECK_PROGS(BISON,bison,none)
  90 if test "$BISON" = "none"
  91 then
  92   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  93 fi
  94
  95 AC_CHECK_TOOLS(AS,[gas as],as)
  96 AC_CHECK_TOOL(LD,ld,ld)
  97 AC_CHECK_TOOL(AR,ar,ar)
  98 AC_PROG_RANLIB
  99 AC_CHECK_TOOL(STRIP,strip,strip)
 100 AC_CHECK_TOOL(WINDRES,windres,false)
 101 AC_PROG_LN_S
 102 WINE_PROG_LN
 103 AC_PROG_EGREP
 104 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 105 AC_PROG_INSTALL
 106 dnl Prepend src dir to install path dir if it's a relative path
 107 case "$INSTALL" in
 108   [[\\/$]]* | ?:[[\\/]]* ) ;;
 109   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 110 esac
 111
 112 dnl Check for lint
 113 AC_CHECK_PROGS(LINT, lclint lint)
 114 if test "$LINT" = "lint"
 115 then
 116   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 117   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 118 fi
 119 AC_SUBST(LINT)
 120 AC_SUBST(LINTFLAGS)
 121
 122 dnl Check for various programs
 123 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 124 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 125
 126 case $host_cpu in
 127   *i[[3456789]]86*)
 128     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 129     ;;
 130 esac
 131
 132 dnl **** Check for some libraries ****
 133
 134 dnl Check for -li386 for NetBSD and OpenBSD
 135 AC_CHECK_LIB(i386,i386_set_ldt)
 136 dnl Check for -lossaudio for NetBSD
 137 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 138 dnl Check for -lxpg4 for FreeBSD
 139 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 140 dnl Check for -lpthread
 141 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 142
 143 AC_SUBST(XLIB,"")
 144 AC_SUBST(XFILES,"")
 145 AC_SUBST(OPENGLFILES,"")
 146 AC_SUBST(GLU32FILES,"")
 147 AC_SUBST(OPENGL_LIBS,"")
 148 AC_SUBST(QUARTZFILES,"")
 149
 150 dnl **** Check for header files ****
 151
 152 AC_CHECK_HEADERS(\
 153         AudioUnit/AudioUnit.h \
 154         Carbon/Carbon.h \
 155         CoreAudio/CoreAudio.h \
 156         DiskArbitration/DiskArbitration.h \
 157         IOKit/IOKitLib.h \
 158         alsa/asoundlib.h \
 159         arpa/inet.h \
 160         arpa/nameser.h \
 161         asm/types.h \
 162         capi20.h \
 163         cups/cups.h \
 164         curses.h \
 165         direct.h \
 166         dlfcn.h \
 167         elf.h \
 168         float.h \
 169         fontconfig/fontconfig.h \
 170         getopt.h \
 171         ieeefp.h \
 172         io.h \
 173         jack/jack.h \
 174         jpeglib.h \
 175         lber.h \
 176         lcms.h \
 177         lcms/lcms.h \
 178         ldap.h \
 179         libaudioio.h \
 180         link.h \
 181         linux/cdrom.h \
 182         linux/compiler.h \
 183         linux/hdreg.h \
 184         linux/input.h \
 185         linux/ioctl.h \
 186         linux/joystick.h \
 187         linux/major.h \
 188         linux/param.h \
 189         linux/serial.h \
 190         linux/ucdrom.h \
 191         mach/machine.h \
 192         machine/cpu.h \
 193         machine/limits.h \
 194         machine/soundcard.h \
 195         mntent.h \
 196         ncurses.h \
 197         netdb.h \
 198         netinet/in.h \
 199         netinet/in_systm.h \
 200         netinet/tcp.h \
 201         netinet/tcp_fsm.h \
 202         openssl/err.h \
 203         openssl/ssl.h \
 204         poll.h \
 205         process.h \
 206         pthread.h \
 207         pwd.h \
 208         regex.h \
 209         sched.h \
 210         scsi/scsi.h \
 211         scsi/scsi_ioctl.h \
 212         scsi/sg.h \
 213         soundcard.h \
 214         stdint.h \
 215         strings.h \
 216         sys/asoundlib.h \
 217         sys/cdio.h \
 218         sys/elf32.h \
 219         sys/epoll.h \
 220         sys/errno.h \
 221         sys/event.h \
 222         sys/exec_elf.h \
 223         sys/filio.h \
 224         sys/ioctl.h \
 225         sys/ipc.h \
 226         sys/limits.h \
 227         sys/link.h \
 228         sys/lwp.h \
 229         sys/mman.h \
 230         sys/modem.h \
 231         sys/msg.h \
 232         sys/mtio.h \
 233         sys/param.h \
 234         sys/poll.h \
 235         sys/prctl.h \
 236         sys/ptrace.h \
 237         sys/reg.h \
 238         sys/resource.h \
 239         sys/scsiio.h \
 240         sys/shm.h \
 241         sys/signal.h \
 242         sys/socket.h \
 243         sys/sockio.h \
 244         sys/soundcard.h \
 245         sys/statvfs.h \
 246         sys/strtio.h \
 247         sys/syscall.h \
 248         sys/sysctl.h \
 249         sys/time.h \
 250         sys/times.h \
 251         sys/uio.h \
 252         sys/un.h \
 253         sys/vm86.h \
 254         sys/wait.h \
 255         syscall.h \
 256         termios.h \
 257         unicode/ubidi.h \
 258         unistd.h \
 259         utime.h \
 260         valgrind/memcheck.h
 261 )
 262 AC_HEADER_STAT()
 263
 264 dnl **** Checks for headers that depend on other ones ****
 265
 266 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 267     [#include <sys/types.h>
 268      #if HAVE_SYS_PARAM_H
 269      # include <sys/param.h>
 270      #endif])
 271
 272 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 273     [#include <sys/types.h>
 274      #if HAVE_SYS_SOCKET_H
 275      # include <sys/socket.h>
 276      #endif])
 277
 278 AC_CHECK_HEADERS([linux/ipx.h],,,
 279     [#include <sys/types.h>
 280      #ifdef HAVE_ASM_TYPES_H
 281      # include <asm/types.h>
 282      #endif
 283      #if HAVE_SYS_SOCKET_H
 284      # include <sys/socket.h>
 285      #endif])
 286
 287 AC_CHECK_HEADERS([resolv.h],,,
 288     [#include <sys/types.h>
 289      #if HAVE_SYS_SOCKET_H
 290      # include <sys/socket.h>
 291      #endif
 292      #if HAVE_NETINET_IN_H
 293      # include <netinet/in.h>
 294      #endif
 295      #if HAVE_ARPA_NAMESER_H
 296      # include <arpa/nameser.h>
 297      #endif])
 298
 299 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 300
 301 AC_CHECK_HEADERS([pthread_np.h],,,
 302 [#ifdef HAVE_PTHREAD_H
 303 #include <pthread.h>
 304 #endif])
 305
 306 AC_CHECK_HEADERS([linux/videodev.h],,,
 307 [#ifdef HAVE_SYS_TIME_H
 308 #include <sys/time.h>
 309 #endif
 310 #include <sys/types.h>
 311 #ifdef HAVE_ASM_TYPES_H
 312 #include <asm/types.h>
 313 #endif])
 314
 315 dnl Check for broken kernel header that doesn't define __user
 316 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 317
 318 dnl **** Check for X11 ****
 319
 320 if test "$have_x" = "yes"
 321 then
 322     XLIB="-lXext -lX11"
 323     ac_save_CPPFLAGS="$CPPFLAGS"
 324     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 325
 326     dnl *** All of the following tests require X11/Xlib.h
 327     AC_CHECK_HEADERS([X11/Xlib.h \
 328                       X11/XKBlib.h \
 329                       X11/Xutil.h \
 330                       X11/extensions/shape.h \
 331                       X11/extensions/XInput.h \
 332                       X11/extensions/XShm.h \
 333                       X11/extensions/Xinerama.h \
 334                       X11/extensions/Xrandr.h \
 335                       X11/extensions/Xrender.h \
 336                       X11/extensions/xf86vmode.h],,,
 337 [#ifdef HAVE_X11_XLIB_H
 338 # include <X11/Xlib.h>
 339 #endif
 340 #ifdef HAVE_X11_XUTIL_H
 341 # include <X11/Xutil.h>
 342 #endif])
 343
 344         dnl *** Check for X keyboard extension
 345         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 346         then
 347               AC_CHECK_LIB(X11, XkbQueryExtension,
 348               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 349               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 350         fi
 351
 352         dnl *** Check for X Shm extension
 353         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 354         then
 355               AC_CHECK_LIB(Xext, XShmQueryExtension,
 356               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 357               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 358         fi
 359
 360         dnl *** Check for X shape extension
 361         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 362         then
 363               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 364               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 365               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 366         fi
 367
 368         dnl *** Check for XFree86 VMODE extension
 369         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 370         then
 371                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 372                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 373                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 374                   ],,
 375                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 376         fi
 377
 378         dnl *** Check for X RandR extension
 379         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 380         then
 381                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 382 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 383                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 384         fi
 385
 386         dnl *** Check for Transform functions in Xrender
 387         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 388         then
 389               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 390                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 391                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 392                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 393         fi
 394
 395         dnl *** Check for Xinerama extension
 396         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 397         then
 398                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 399 #include <X11/extensions/Xinerama.h>],[static typeof(XineramaQueryScreens) * func;],
 400                   [AC_DEFINE(HAVE_LIBXINERAMA, 1, [Define if you have the Xinerama library])])
 401         fi
 402
 403     dnl *** End of X11/Xlib.h check
 404
 405     dnl Check for the presence of OpenGL
 406     if test "x$with_opengl" != "xno"
 407     then
 408         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 409 [#ifdef HAVE_GL_GLX_H
 410 # include <GL/glx.h>
 411 #endif])
 412         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 413         then
 414             dnl Check for some problems due to old Mesa versions
 415             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 416               AC_TRY_COMPILE(
 417                 [#include <GL/gl.h>],
 418                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 419                 [wine_cv_opengl_header_version_OK="yes"],
 420                 [wine_cv_opengl_header_version_OK="no"]
 421               )
 422             )
 423
 424             if test "$wine_cv_opengl_header_version_OK" = "yes"
 425             then
 426                 dnl Check for the presence of the library
 427                 AC_CHECK_LIB(GL,glXCreateContext,
 428                              [OPENGL_LIBS="-lGL"
 429                              OPENGLFILES='$(OPENGLFILES)'
 430                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])]
 431                              ,,
 432                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 433
 434                 dnl Check for GLU32 library.
 435                 AC_CHECK_LIB(GLU,gluLookAt,
 436                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 437                              GLU32FILES='$(GLU32FILES)']
 438                              ,,
 439                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 440                 )
 441              fi
 442          else
 443              wine_cv_opengl_headers_found="no"
 444          fi
 445     fi
 446     dnl **** Check for NAS ****
 447     AC_SUBST(NASLIBS,"")
 448     AC_CHECK_HEADERS(audio/audiolib.h,
 449          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 450           AC_CHECK_LIB(audio,AuCreateFlow,
 451                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 452                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 453                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 454
 455     CPPFLAGS="$ac_save_CPPFLAGS"
 456     XFILES='$(XFILES)'
 457 else
 458     XLIB=""
 459     X_CFLAGS=""
 460     X_LIBS=""
 461 fi
 462
 463 dnl **** Check for libxml2 ****
 464
 465 AC_SUBST(XML2LIBS,"")
 466 AC_SUBST(XML2INCL,"")
 467 AC_SUBST(XSLTLIBS,"")
 468 AC_SUBST(XSLTINCL,"")
 469 if test "$PKG_CONFIG" != "false"
 470 then
 471     ac_save_CPPFLAGS="$CPPFLAGS"
 472     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 473     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 474     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 475     AC_CHECK_HEADERS(libxml/parser.h,
 476         [AC_CHECK_LIB(xml2, xmlParseMemory,
 477             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 478              XML2LIBS="$ac_xml_libs"
 479              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 480          AC_CHECK_LIB(xml2, xmlReadMemory,
 481             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 482          AC_CHECK_LIB(xml2, xmlNewDocPI,
 483             [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 484         ])
 485     CPPFLAGS="$ac_save_CPPFLAGS"
 486     ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 487     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 488     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 489     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 490         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 491             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 492              XSLTLIBS="$ac_xslt_libs"
 493              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 494         ],,
 495 [#ifdef HAVE_LIBXSLT_PATTERN_H
 496 # include <libxslt/pattern.h>
 497 #endif])
 498     CPPFLAGS="$ac_save_CPPFLAGS"
 499 fi
 500
 501 dnl **** Check for libhal ****
 502 AC_SUBST(HALINCL,"")
 503 if test "$PKG_CONFIG" != "false"
 504 then
 505     ac_save_CPPFLAGS="$CPPFLAGS"
 506     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 507     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 508     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 509     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 510     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 511     then
 512         AC_CHECK_LIB(hal, libhal_ctx_new,
 513           [AC_CHECK_LIB(dbus-1, dbus_connection_close,
 514             [AC_DEFINE(HAVE_LIBHAL, 1, [Define if you have the hal library])
 515              HALINCL="$ac_hal_cflags"],,$ac_hal_libs)])
 516     fi
 517     CPPFLAGS="$ac_save_CPPFLAGS"
 518 fi
 519
 520 dnl **** Check which curses lib to use ***
 521 CURSESLIBS=""
 522 if test "$ac_cv_header_ncurses_h" = "yes"
 523 then
 524     AC_CHECK_LIB(ncurses,waddch,[CURSESLIBS="-lncurses"])
 525 elif test "$ac_cv_header_curses_h" = "yes"
 526 then
 527     AC_CHECK_LIB(curses,waddch,[CURSESLIBS="-lcurses"])
 528 fi
 529 ac_save_LIBS="$LIBS"
 530 LIBS="$LIBS $CURSESLIBS"
 531 AC_CHECK_FUNCS(mousemask)
 532 LIBS="$ac_save_LIBS"
 533
 534 dnl **** Check for SANE ****
 535 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 536 AC_SUBST(SANELIBS,"")
 537 AC_SUBST(SANEINCL,"")
 538 if test "$sane_devel" != "no"
 539 then
 540     SANELIBS="`$sane_devel --libs`"
 541     SANEINCL="`$sane_devel --cflags`"
 542     ac_save_CPPFLAGS="$CPPFLAGS"
 543     ac_save_LIBS="$LIBS"
 544     CPPFLAGS="$CPPFLAGS $SANEINCL"
 545     LIBS="$LIBS $SANELIBS"
 546     AC_CHECK_HEADER(sane/sane.h,
 547                     [AC_CHECK_LIB(sane,sane_open,
 548                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 549                                   [SANELIBS=""
 550                                   SANEINCL=""])],
 551                     [SANELIBS=""
 552                     SANEINCL=""])
 553     LIBS="$ac_save_LIBS"
 554     CPPFLAGS="$ac_save_CPPFLAGS"
 555 fi
 556
 557 dnl **** Check for libgphoto2 ****
 558 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 559 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 560 AC_SUBST(GPHOTO2LIBS,"")
 561 AC_SUBST(GPHOTO2INCL,"")
 562 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
 563 then
 564     GPHOTO2INCL="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 565     GPHOTO2LIBS=""
 566     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 567     do
 568       case "$i" in
 569         -L/usr/lib|-L/usr/lib64) ;;
 570         -L*|-l*) GPHOTO2LIBS="$GPHOTO2LIBS $i";;
 571       esac
 572     done
 573     ac_save_CPPFLAGS="$CPPFLAGS"
 574     ac_save_LIBS="$LIBS"
 575     CPPFLAGS="$CPPFLAGS $GPHOTO2INCL"
 576     LIBS="$LIBS $GPHOTO2LIBS"
 577     AC_CHECK_HEADER(gphoto2-camera.h,
 578                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 579                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])],
 580                                   [GPHOTO2LIBS=""
 581                                   GPHOTO2INCL=""])],
 582                     [GPHOTO2LIBS=""
 583                     GPHOTO2INCL=""])
 584     LIBS="$ac_save_LIBS"
 585     CPPFLAGS="$ac_save_CPPFLAGS"
 586 fi
 587
 588 dnl **** Check for the ICU library ****
 589 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 590 then
 591     saved_libs="$LIBS"
 592     for i in ${ICU_LIB_DIR-/usr/lib}/libsicu ${ICU_LIB_DIR-/usr/lib}/libicu
 593     do
 594         TEST_ICUUC_LIB="${ICUUC_LIB-${i}uc.a}"
 595         TEST_ICUDATA_LIB="${ICUDATA_LIB-${i}data.a}"
 596         AC_MSG_CHECKING(whether can link with ICU libraries $TEST_ICUUC_LIB and $TEST_ICUDATA_LIB)
 597         LIBS="$saved_libs $TEST_ICUUC_LIB $TEST_ICUDATA_LIB -lstdc++ -lgcc_s"
 598         AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 599                     [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 600                      AC_SUBST(ICULIBS,"$TEST_ICUUC_LIB $TEST_ICUDATA_LIB -lstdc++ -lgcc_s")
 601                      AC_MSG_RESULT(yes)],
 602                     [AC_MSG_RESULT(no)])
 603     done
 604     LIBS="$saved_libs"
 605 fi
 606
 607 dnl **** Check for resolver library ***
 608 AC_SUBST(RESOLVLIBS,"")
 609 if test "$ac_cv_header_resolv_h" = "yes"
 610 then
 611     AC_CHECK_LIB(resolv, res_query,
 612         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 613          RESOLVLIBS="-lresolv"])
 614 fi
 615
 616 dnl **** Check for LittleCMS ***
 617 AC_SUBST(LCMSLIBS,"")
 618 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 619 then
 620     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 621         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 622          LCMSLIBS="-llcms"])
 623 fi
 624
 625 dnl **** Check for OpenLDAP ***
 626 AC_SUBST(LDAPLIBS,"")
 627 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 628 then
 629     AC_CHECK_LIB(ldap_r, ldap_initialize,
 630         [AC_CHECK_LIB(lber, ber_init,
 631             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 632              LDAPLIBS="-lldap_r -llber"],,
 633              [$LIBPTHREAD])],,
 634              [$LIBPTHREAD])
 635     WINE_CHECK_LIB_FUNCS(\
 636         ldap_count_references \
 637         ldap_first_reference \
 638         ldap_next_reference \
 639         ldap_parse_reference,
 640         [$LDAPLIBS $LIBPTHREAD])
 641 fi
 642
 643 dnl **** Check for FreeType 2 ****
 644 AC_SUBST(FREETYPELIBS,"")
 645 AC_SUBST(FREETYPEINCL,"")
 646 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 647 if test "$ft_devel" = "no"
 648 then
 649     AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 650     if test "$ft_devel2" = "freetype2-config"
 651     then
 652         ft_devel=$ft_devel2
 653     fi
 654 fi
 655
 656 if test "$ft_devel" = "no"
 657 then
 658     wine_cv_msg_freetype=yes
 659 else
 660     FREETYPELIBS=`$ft_devel --libs`
 661     FREETYPEINCL=`$ft_devel --cflags`
 662     AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$FREETYPELIBS)
 663     if test "$ft_lib" = "no"
 664     then
 665         wine_cv_msg_freetype=yes
 666         FREETYPELIBS=""
 667         FREETYPEINCL=""
 668     else
 669         ac_save_CPPFLAGS="$CPPFLAGS"
 670         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 671         AC_CHECK_HEADERS(ft2build.h \
 672                          freetype/freetype.h \
 673                          freetype/ftglyph.h \
 674                          freetype/tttables.h \
 675                          freetype/ftnames.h \
 676                          freetype/ftsnames.h \
 677                          freetype/ttnameid.h \
 678                          freetype/ftoutln.h \
 679                          freetype/ftwinfnt.h \
 680                          freetype/ftmodapi.h \
 681                          freetype/internal/sfnt.h,,,
 682                          [#if HAVE_FT2BUILD_H
 683                           #include <ft2build.h>
 684                           #endif])
 685         AC_TRY_CPP([#include <ft2build.h>
 686                     #include <freetype/fttrigon.h>],
 687                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 688           [Define if you have the <freetype/fttrigon.h> header file.])
 689                     wine_cv_fttrigon=yes],
 690                     wine_cv_fttrigon=no)
 691         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 692         ac_save_CFLAGS="$CFLAGS"
 693         CFLAGS="$CFLAGS $FREETYPELIBS"
 694         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 695         CFLAGS="$ac_save_CFLAGS"
 696         CPPFLAGS="$ac_save_CPPFLAGS"
 697         dnl Check that we have at least freetype/freetype.h
 698         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 699         then
 700             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 701             wine_cv_msg_freetype=no
 702         else
 703             FREETYPELIBS=""
 704             FREETYPEINCL=""
 705             wine_cv_msg_freetype=yes
 706         fi
 707     fi
 708 fi
 709
 710 dnl Only build the fonts dir if we have both freetype and fontforge
 711 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 712 then
 713   AC_SUBST(FONTSSUBDIRS,"fonts")
 714 fi
 715
 716 dnl **** Check for parport (currently Linux only) ****
 717 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 718  AC_TRY_COMPILE(
 719    [#include <linux/ppdev.h>],
 720    [ioctl (1,PPCLAIM,0)],
 721    [ac_cv_c_ppdev="yes"],
 722    [ac_cv_c_ppdev="no"])
 723  )
 724 if test "$ac_cv_c_ppdev" = "yes"
 725 then
 726     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 727 fi
 728
 729 dnl **** Check for va_copy ****
 730 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 731  AC_TRY_LINK(
 732    [#include <stdarg.h>],
 733    [va_list ap1, ap2;
 734     va_copy(ap1,ap2);
 735    ],
 736    [ac_cv_c_va_copy="yes"],
 737    [ac_cv_c_va_copy="no"])
 738  )
 739 if test "$ac_cv_c_va_copy" = "yes"
 740 then
 741     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 742 fi
 743 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 744  AC_TRY_LINK(
 745    [#include <stdarg.h>],
 746    [va_list ap1, ap2;
 747     __va_copy(ap1,ap2);
 748    ],
 749    [ac_cv_c___va_copy="yes"],
 750    [ac_cv_c___va_copy="no"])
 751  )
 752 if test "$ac_cv_c___va_copy" = "yes"
 753 then
 754     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 755 fi
 756
 757 dnl **** Check for sigsetjmp ****
 758 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 759  AC_TRY_LINK(
 760    [#include <setjmp.h>],
 761    [sigjmp_buf buf;
 762     sigsetjmp( buf, 1 );
 763     siglongjmp( buf, 1 );],
 764    [ac_cv_c_sigsetjmp="yes"],
 765    [ac_cv_c_sigsetjmp="no"])
 766  )
 767 if test "$ac_cv_c_sigsetjmp" = "yes"
 768 then
 769     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 770 fi
 771
 772 dnl **** Check for pthread_rwlock_t ****
 773 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 774 #include <pthread.h>])
 775
 776 dnl **** Check for pthread functions ****
 777 WINE_CHECK_LIB_FUNCS(\
 778         pthread_attr_get_np \
 779         pthread_getattr_np \
 780         pthread_get_stackaddr_np \
 781         pthread_get_stacksize_np,
 782         [$LIBPTHREAD])
 783
 784 dnl **** Check for aRts Sound Server ****
 785 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 786 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 787 then
 788     ARTSC_CFLAGS=""
 789     for i in `$ARTSCCONFIG --cflags`
 790     do
 791       case "$i" in
 792         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 793       esac
 794     done
 795     ARTSC_LIBS=""
 796     for i in `$ARTSCCONFIG --libs`
 797     do
 798       case "$i" in
 799         -L/usr/lib|-L/usr/lib64) ;;
 800         -L*|-l*) ARTSC_LIBS="$ARTSC_LIBS $i";;
 801       esac
 802     done
 803     save_CFLAGS="$CFLAGS"
 804     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 805     AC_CHECK_LIB(artsc,arts_init,
 806         [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 807             [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 808             AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 809             AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
 810             $ARTSC_LIBS)
 811     CFLAGS="$save_CFLAGS"
 812 fi
 813
 814 dnl **** Check for EsounD ****
 815 AC_PATH_PROG(ESDCONFIG, esd-config)
 816 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 817 then
 818     ESD_CFLAGS=""
 819     for i in `$ESDCONFIG --cflags`
 820     do
 821       case "$i" in
 822         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 823       esac
 824     done
 825     ESD_LIBS=`$ESDCONFIG --libs`
 826     save_CFLAGS="$CFLAGS"
 827     CFLAGS="$CFLAGS $ESD_CFLAGS"
 828     AC_CHECK_LIB(esd,esd_open_sound,
 829         [AC_SUBST(ESDLIBS, $ESD_LIBS)
 830          AC_SUBST(ESDINCL, $ESD_CFLAGS)
 831          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
 832     CFLAGS="$save_CFLAGS"
 833 fi
 834
 835 dnl **** Check for ALSA 1.x ****
 836 AC_SUBST(ALSALIBS,"")
 837 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 838 then
 839     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 840         [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
 841 #include <alsa/asoundlib.h>
 842 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 843 #include <sys/asoundlib.h>
 844 #endif],
 845                         [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
 846                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 847                          ALSALIBS="-lasound"])])
 848 fi
 849
 850 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 851
 852 AC_SUBST(AUDIOIOLIBS,"")
 853 if test "$ac_cv_header_libaudioio_h" = "yes"
 854 then
 855     AC_CHECK_LIB(audioio,AudioIOGetVersion,
 856                   [AUDIOIOLIBS="-laudioio"
 857                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
 858 fi
 859
 860 dnl **** Check for capi4linux ****
 861
 862 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
 863 then
 864     AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
 865 fi
 866
 867 dnl **** Check for gcc specific options ****
 868
 869 AC_SUBST(EXTRACFLAGS,"")
 870 if test "x${GCC}" = "xyes"
 871 then
 872   EXTRACFLAGS="-Wall -pipe"
 873
 874   dnl Check for strength-reduce bug
 875   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 876                   AC_TRY_RUN([
 877 int     L[[4]] = {0,1,2,3};
 878 int main(void) {
 879   static int Array[[3]];
 880   unsigned int B = 3;
 881   int i;
 882   for(i=0; i<B; i++) Array[[i]] = i - 3;
 883   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 884   L[[i]] = 4;
 885
 886   exit( Array[[1]] != -2 || L[[2]] != 3);
 887 }],
 888     ac_cv_c_gcc_strength_bug="no",
 889     ac_cv_c_gcc_strength_bug="yes",
 890     ac_cv_c_gcc_strength_bug="yes") )
 891   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 892   then
 893     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 894   fi
 895
 896   dnl Check for some compiler flags
 897
 898   WINE_TRY_CFLAGS([-fshort-wchar],
 899                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
 900                              [Specifies the compiler flag that forces a short wchar_t])])
 901   WINE_TRY_CFLAGS([-fno-strict-aliasing])
 902   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
 903   WINE_TRY_CFLAGS([-Wwrite-strings])
 904
 905   dnl Check for noisy string.h
 906   saved_CFLAGS="$CFLAGS"
 907   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 908   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 909       AC_TRY_COMPILE([#include <string.h>],[],
 910                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 911   CFLAGS="$saved_CFLAGS"
 912   if test "$ac_cv_c_string_h_warnings" = "no"
 913   then
 914     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 915   fi
 916
 917   AC_SUBST(BUILTINFLAG,"")
 918   saved_CFLAGS="$CFLAGS"
 919   CFLAGS="$CFLAGS -Werror"
 920   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
 921       AC_TRY_COMPILE([],
 922                      [int iswlower(unsigned short);],
 923                      [ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
 924   CFLAGS="$saved_CFLAGS"
 925   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
 926   then
 927     BUILTINFLAG="-fno-builtin"
 928   fi
 929 fi
 930
 931 dnl **** Check how to define a function in assembly code ****
 932
 933 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 934   WINE_TRY_ASM_LINK(
 935       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 936       ac_cv_asm_func_def=".def",
 937     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 938       ac_cv_asm_func_def=".type @function",
 939     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 940       ac_cv_asm_func_def=".type 2",
 941       ac_cv_asm_func_def="unknown")])]))
 942
 943 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 944 case "$ac_cv_asm_func_def" in
 945   ".def")
 946      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 947   ".type @function")
 948      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 949   ".type 2")
 950      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 951   *)
 952      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 953 esac
 954
 955 dnl **** Check for underscore on external symbols ****
 956
 957 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 958     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 959                       [extern int ac_test;],
 960                       [if (ac_test) return 1],
 961                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 962
 963 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 964 if test "$ac_cv_c_extern_prefix" = "yes"
 965 then
 966   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 967 else
 968   AC_DEFINE([__ASM_NAME(name)], [name])
 969 fi
 970
 971 dnl **** Check for working dll ****
 972
 973 AC_SUBST(DLLEXT,"")
 974 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 975 AC_SUBST(LDSHARED,"")
 976 AC_SUBST(LDDLLFLAGS,"")
 977 AC_SUBST(LIBEXT,"so")
 978 AC_SUBST(IMPLIBEXT,"def")
 979 AC_SUBST(LIBWINE_LDFLAGS,"")
 980
 981 case $host_os in
 982   cygwin*|mingw32*)
 983     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 984     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 985     if test "$DLLWRAP" = "false"; then
 986       LIBEXT="a"
 987     else
 988       dnl FIXME - check whether dllwrap works correctly...
 989       LIBEXT="dll"
 990     fi
 991     IMPLIBEXT="a"
 992     dnl We can't build 16-bit NE dlls
 993     WIN16_FILES=""
 994     WIN16_INSTALL=""
 995     ;;
 996   darwin*|macosx*)
 997     DLLEXT=".so"
 998     LIBEXT="dylib"
 999     DLLFLAGS="$DLLFLAGS -fPIC"
1000     LDDLLFLAGS="-bundle -multiply_defined suppress"
1001     LIBWINE_LDFLAGS="-multiply_defined suppress"
1002     LDSHARED="\$(CC) -dynamiclib -install_name @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/\$(DYNAME)"
1003     STRIP="$STRIP -u -r"
1004     dnl declare needed frameworks
1005     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1006     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
1007     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
1008     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
1009     then
1010         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
1011         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
1012     fi
1013     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
1014     then
1015         dnl CoreServices needed by AudioUnit
1016         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices")
1017     fi
1018     case $host_cpu in
1019       *powerpc*)
1020         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
1021         ;;
1022     esac
1023     dnl Enable quartz driver on Mac OS X
1024     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
1025     then
1026         QUARTZFILES='$(QUARTZFILES)'
1027     fi
1028     ;;
1029   *)
1030     DLLFLAGS="$DLLFLAGS -fPIC"
1031     DLLEXT=".so"
1032     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
1033         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
1034                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
1035     if test "$ac_cv_c_dll_gnuelf" = "yes"
1036     then
1037       LDSHARED="\$(CC) -shared"
1038       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
1039       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
1040                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
1041                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
1042                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
1043
1044       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
1045
1046       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
1047                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
1048
1049       echo '{ global: *; };' >conftest.map
1050       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
1051                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
1052       rm -f conftest.map
1053
1054       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
1055                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
1056
1057       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
1058                       [LIBWINE_LDFLAGS="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"])
1059
1060       case $host_cpu in
1061         *i[[3456789]]86* | x86_64)
1062           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
1063                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
1064           ;;
1065       esac
1066
1067     else
1068       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
1069           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
1070                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1071       if test "$ac_cv_c_dll_unixware" = "yes"
1072       then
1073         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1074         LDDLLFLAGS="-Wl,-G,-B,symbolic"
1075
1076       else
1077         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1078           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1079         if test "$ac_cv_c_dll_hpux" = "yes"
1080         then
1081           LIBEXT="sl"
1082           DLLEXT=".sl"
1083           LDDLLFLAGS="-shared -fPIC"
1084           LDSHARED="\$(CC) -shared"
1085         fi
1086       fi
1087     fi
1088
1089     dnl Check for cross compiler to build test programs
1090     AC_SUBST(CROSSTEST,"")
1091     if test "$cross_compiling" = "no"
1092     then
1093       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw32-gcc mingw-gcc,false)
1094       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw32-dlltool mingw-dlltool,false)
1095       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw32-windres mingw-windres,false)
1096       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1097     fi
1098     ;;
1099 esac
1100
1101 if test "$LIBEXT" = "a"; then
1102   AC_MSG_ERROR(
1103 [could not find a way to build shared libraries.
1104 It is currently not possible to build Wine without shared library
1105 (.so) support to allow transparent switch between .so and .dll files.
1106 If you are using Linux, you will need a newer binutils.]
1107 )
1108 fi
1109
1110 case $build_os in
1111   cygwin*|mingw32*)
1112     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\"") ;;
1113   darwin*|macosx*)
1114     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$DYLD_LIBRARY_PATH\"") ;;
1115   *)
1116     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\"") ;;
1117 esac
1118
1119 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1120 case $host_os in
1121   mingw32*)
1122     AC_SUBST(CRTLIBS,"-lmsvcrt")
1123     AC_SUBST(SOCKETLIBS,"-lws2_32")
1124     ;;
1125 esac
1126
1127 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1128 case $host_cpu in
1129   *i[[3456789]]86*)
1130     case $host_os in
1131       linux* | k*bsd*-gnu)
1132         AC_SUBST(MAIN_BINARY,"wine-glibc")
1133         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1134     esac
1135     ;;
1136 esac
1137
1138 dnl **** Get the soname for libraries that we load dynamically ****
1139
1140 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1141 then
1142   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1143   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1144   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1145   WINE_GET_SONAME(Xinerama,XineramaQueryScreens,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1146   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1147   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1148   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1149   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1150   WINE_GET_SONAME(hal,libhal_ctx_new)
1151   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1152   WINE_GET_SONAME(cups,cupsGetDefault)
1153   WINE_GET_SONAME(jack,jack_client_new)
1154   WINE_GET_SONAME(fontconfig,FcInit)
1155   WINE_GET_SONAME(ssl,SSL_library_init)
1156   WINE_GET_SONAME(crypto,BIO_new_socket)
1157   WINE_GET_SONAME(ncurses,waddch)
1158   WINE_GET_SONAME(curses,waddch)
1159   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1160   WINE_GET_SONAME(capi20,capi20_isinstalled)
1161 fi
1162
1163
1164 dnl **** Check for functions ****
1165
1166 AC_CHECK_FUNCS(\
1167         _pclose \
1168         _popen \
1169         _snprintf \
1170         _spawnvp \
1171         _stricmp \
1172         _strnicmp \
1173         _vsnprintf \
1174         asctime_r \
1175         chsize \
1176         clone \
1177         connect \
1178         dlopen \
1179         epoll_create \
1180         ffs \
1181         finite \
1182         fork \
1183         fpclass \
1184         fstatfs \
1185         fstatvfs \
1186         ftruncate \
1187         futimes \
1188         futimesat \
1189         getaddrinfo \
1190         getdirentries \
1191         gethostbyname \
1192         getnameinfo \
1193         getnetbyname \
1194         getopt_long \
1195         getpagesize \
1196         getprotobyname \
1197         getprotobynumber \
1198         getpwuid \
1199         getservbyport \
1200         gettid \
1201         gettimeofday \
1202         getuid \
1203         inet_aton \
1204         inet_network \
1205         kqueue \
1206         lstat \
1207         memmove \
1208         mmap \
1209         pclose \
1210         poll \
1211         popen \
1212         prctl \
1213         pread \
1214         pwrite \
1215         readlink \
1216         rfork \
1217         sched_yield \
1218         select \
1219         sendmsg \
1220         setrlimit \
1221         settimeofday \
1222         sigaltstack \
1223         sigprocmask \
1224         snprintf \
1225         spawnvp \
1226         statfs \
1227         statvfs \
1228         strcasecmp \
1229         strerror \
1230         strncasecmp \
1231         tcgetattr \
1232         timegm \
1233         usleep \
1234         vsnprintf \
1235         wait4 \
1236         waitpid \
1237 )
1238
1239 dnl Check for -ldl
1240 if test "$ac_cv_func_dlopen" = no
1241 then
1242     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1243 fi
1244 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1245
1246 dnl Check for -lpoll for Mac OS X/Darwin
1247 if test "$ac_cv_func_poll" = no
1248 then
1249     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1250 fi
1251
1252 dnl Check for -lnsl for Solaris
1253 if test "$ac_cv_func_gethostbyname" = no
1254 then
1255     AC_CHECK_LIB(nsl,gethostbyname)
1256 fi
1257
1258 dnl Check for -lsocket for Solaris
1259 if test "$ac_cv_func_connect" = no
1260 then
1261     AC_CHECK_LIB(socket,connect)
1262 fi
1263
1264 dnl Check for -lresolv for Solaris
1265 if test "$ac_cv_func_inet_aton" = no
1266 then
1267     AC_CHECK_LIB(resolv,inet_aton)
1268 fi
1269
1270 dnl **** Check for types ****
1271
1272 AC_C_CONST
1273 AC_C_INLINE
1274 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1275 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1276 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1277
1278 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1279 [#ifdef HAVE_LINUX_INPUT_H
1280 #include <linux/input.h>
1281 #endif])
1282
1283 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1284                AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1285                            wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1286 if test "$wine_cv_have_sigaddset" = "yes"
1287 then
1288   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1289 fi
1290
1291
1292 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1293         wine_cv_linux_gethostbyname_r_6,
1294         AC_TRY_LINK([
1295 #include <netdb.h>
1296         ], [
1297     char *name=NULL;
1298     struct hostent he;
1299     struct hostent *result;
1300     char *buf=NULL;
1301     int bufsize=0;
1302     int res,errnr;
1303     char *addr=NULL;
1304     int addrlen=0;
1305     int addrtype=0;
1306     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1307     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1308     ],
1309         wine_cv_linux_gethostbyname_r_6=yes,
1310         wine_cv_linux_gethostbyname_r_6=no
1311         )
1312    )
1313    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1314    then
1315       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1316                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1317    fi
1318
1319 if test "$ac_cv_header_linux_joystick_h" = "yes"
1320 then
1321    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1322         wine_cv_linux_joystick_22_api,
1323         AC_TRY_COMPILE([
1324         #include <sys/ioctl.h>
1325         #include <linux/joystick.h>
1326
1327         struct js_event blub;
1328         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1329         #error "no 2.2 header"
1330         #endif
1331         ],/*empty*/,
1332         wine_cv_linux_joystick_22_api=yes,
1333         wine_cv_linux_joystick_22_api=no,
1334         wine_cv_linux_joystick_22_api=no
1335         )
1336    )
1337    if test "$wine_cv_linux_joystick_22_api" = "yes"
1338    then
1339       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1340                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1341    fi
1342 fi
1343
1344 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1345
1346 dnl Check for statfs members
1347 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1348 [#include <sys/types.h>
1349 #ifdef HAVE_SYS_PARAM_H
1350 # include <sys/param.h>
1351 #endif
1352 #ifdef HAVE_SYS_MOUNT_H
1353 # include <sys/mount.h>
1354 #endif
1355 #ifdef HAVE_SYS_VFS_H
1356 # include <sys/vfs.h>
1357 #endif
1358 #ifdef HAVE_SYS_STATFS_H
1359 # include <sys/statfs.h>
1360 #endif])
1361
1362 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1363 [#ifdef HAVE_SYS_STATVFS_H
1364 #include <sys/statvfs.h>
1365 #endif])
1366
1367 dnl Check for socket structure members
1368 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1369 [#include <sys/types.h>
1370 #ifdef HAVE_SYS_SOCKET_H
1371 # include <sys/socket.h>
1372 #endif
1373 #ifdef HAVE_SYS_UN_H
1374 # include <sys/un.h>
1375 #endif])
1376
1377 dnl Check for scsireq_t and sg_io_hdr_t members
1378 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1379 [#include <sys/types.h>
1380 #ifdef HAVE_SCSI_SG_H
1381 #include <scsi/sg.h>
1382 #endif])
1383
1384 dnl Check for siginfo_t members
1385 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1386
1387 dnl Check for struct mtget members
1388 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1389 [#include <sys/types.h>
1390 #ifdef HAVE_SYS_MTIO_H
1391 #include <sys/mtio.h>
1392 #endif])
1393
1394 dnl Check for struct option
1395 AC_CHECK_MEMBERS([struct option.name],,,
1396 [#ifdef HAVE_GETOPT_H
1397 #include <getopt.h>
1398 #endif])
1399
1400 dnl Check for stat.st_blocks
1401 AC_CHECK_MEMBERS([struct stat.st_blocks])
1402
1403 dnl Check for sin6_scope_id
1404 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1405 [#ifdef HAVE_SYS_TYPES_H
1406 #include <sys/types.h>
1407 #endif
1408 #ifdef HAVE_NETINET_IN_H
1409 #include <netinet/in.h>
1410 #endif])
1411
1412 dnl Check for ns_msg ptr member
1413 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1414 [#ifdef HAVE_SYS_TYPES_H
1415 #include <sys/types.h>
1416 #endif
1417 #ifdef HAVE_NETINET_IN_H
1418 # include <netinet/in.h>
1419 #endif
1420 #ifdef HAVE_ARPA_NAMESER_H
1421 # include <arpa/nameser.h>
1422 #endif])
1423
1424 dnl Check for the external timezone variables timezone and daylight
1425 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1426                AC_TRY_LINK([#include <time.h>],[timezone = 1],
1427                            ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1428 if test "$ac_cv_have_timezone" = "yes"
1429 then
1430     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1431 fi
1432 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1433                AC_TRY_LINK([#include <time.h>],[daylight = 1],
1434                            ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1435 if test "$ac_cv_have_daylight" = "yes"
1436 then
1437     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1438 fi
1439
1440 dnl *** check for the need to define platform-specific symbols
1441
1442 case $host_cpu in
1443   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1444   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1445   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1446   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1447   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1448 esac
1449
1450 case $host_vendor in
1451   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1452 esac
1453
1454 dnl **** Generate output files ****
1455
1456 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1457 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1458 ["### Dependencies:\\
1459 \\
1460 .INIT: Makefile\\
1461 .BEGIN: Makefile\\
1462 Makefile: dummy\\
1463         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1464 \\
1465 \$(ALL_OBJS): \$(IDL_H_SRCS:.idl=.h)\\
1466 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1467 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1468 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1469 ["### Dependencies:
1470
1471 .INIT: Makefile
1472 .BEGIN: Makefile
1473 Makefile: dummy
1474         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1475
1476 \$(ALL_OBJS): \$(IDL_H_SRCS:.idl=.h)
1477 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1478 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1479 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1480
1481 AH_TOP([#define __WINE_CONFIG_H])
1482
1483 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1484
1485 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1486 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1487 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1488 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1489 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1490 WINE_CONFIG_EXTRA_DIR(include/wine)
1491
1492 MAKE_RULES=Make.rules
1493 AC_SUBST_FILE(MAKE_RULES)
1494
1495 MAKE_DLL_RULES=dlls/Makedll.rules
1496 AC_SUBST_FILE(MAKE_DLL_RULES)
1497
1498 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1499 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1500
1501 MAKE_TEST_RULES=dlls/Maketest.rules
1502 AC_SUBST_FILE(MAKE_TEST_RULES)
1503
1504 MAKE_PROG_RULES=programs/Makeprog.rules
1505 AC_SUBST_FILE(MAKE_PROG_RULES)
1506
1507 AC_CONFIG_FILES([
1508 Make.rules
1509 dlls/Makedll.rules
1510 dlls/Makeimplib.rules
1511 dlls/Maketest.rules
1512 programs/Makeprog.rules
1513 Makefile
1514 dlls/Makefile
1515 dlls/activeds/Makefile
1516 dlls/advapi32/Makefile
1517 dlls/advapi32/tests/Makefile
1518 dlls/advpack/Makefile
1519 dlls/advpack/tests/Makefile
1520 dlls/amstream/Makefile
1521 dlls/atl/Makefile
1522 dlls/avicap32/Makefile
1523 dlls/avifil32/Makefile
1524 dlls/cabinet/Makefile
1525 dlls/cabinet/tests/Makefile
1526 dlls/capi2032/Makefile
1527 dlls/cards/Makefile
1528 dlls/cfgmgr32/Makefile
1529 dlls/clusapi/Makefile
1530 dlls/comcat/Makefile
1531 dlls/comcat/tests/Makefile
1532 dlls/comctl32/Makefile
1533 dlls/comctl32/tests/Makefile
1534 dlls/comdlg32/Makefile
1535 dlls/comdlg32/tests/Makefile
1536 dlls/compstui/Makefile
1537 dlls/crtdll/Makefile
1538 dlls/crypt32/Makefile
1539 dlls/crypt32/tests/Makefile
1540 dlls/cryptdll/Makefile
1541 dlls/cryptnet/Makefile
1542 dlls/ctl3d32/Makefile
1543 dlls/d3d8/Makefile
1544 dlls/d3d8/tests/Makefile
1545 dlls/d3d9/Makefile
1546 dlls/d3d9/tests/Makefile
1547 dlls/d3dim/Makefile
1548 dlls/d3drm/Makefile
1549 dlls/d3dx8/Makefile
1550 dlls/d3dxof/Makefile
1551 dlls/dbghelp/Makefile
1552 dlls/dciman32/Makefile
1553 dlls/ddraw/Makefile
1554 dlls/ddraw/tests/Makefile
1555 dlls/ddrawex/Makefile
1556 dlls/devenum/Makefile
1557 dlls/dinput/Makefile
1558 dlls/dinput/tests/Makefile
1559 dlls/dinput8/Makefile
1560 dlls/dmband/Makefile
1561 dlls/dmcompos/Makefile
1562 dlls/dmime/Makefile
1563 dlls/dmloader/Makefile
1564 dlls/dmscript/Makefile
1565 dlls/dmstyle/Makefile
1566 dlls/dmsynth/Makefile
1567 dlls/dmusic/Makefile
1568 dlls/dmusic32/Makefile
1569 dlls/dnsapi/Makefile
1570 dlls/dnsapi/tests/Makefile
1571 dlls/dplay/Makefile
1572 dlls/dplayx/Makefile
1573 dlls/dpnet/Makefile
1574 dlls/dpnhpast/Makefile
1575 dlls/dsound/Makefile
1576 dlls/dsound/tests/Makefile
1577 dlls/dswave/Makefile
1578 dlls/dxdiagn/Makefile
1579 dlls/dxerr8/Makefile
1580 dlls/dxerr9/Makefile
1581 dlls/dxguid/Makefile
1582 dlls/gdi32/Makefile
1583 dlls/gdi32/tests/Makefile
1584 dlls/glu32/Makefile
1585 dlls/gphoto2.ds/Makefile
1586 dlls/hhctrl.ocx/Makefile
1587 dlls/hid/Makefile
1588 dlls/hlink/Makefile
1589 dlls/hlink/tests/Makefile
1590 dlls/iccvid/Makefile
1591 dlls/icmp/Makefile
1592 dlls/ifsmgr.vxd/Makefile
1593 dlls/imaadp32.acm/Makefile
1594 dlls/imagehlp/Makefile
1595 dlls/imm32/Makefile
1596 dlls/infosoft/Makefile
1597 dlls/infosoft/tests/Makefile
1598 dlls/inseng/Makefile
1599 dlls/iphlpapi/Makefile
1600 dlls/iphlpapi/tests/Makefile
1601 dlls/itss/Makefile
1602 dlls/kernel32/Makefile
1603 dlls/kernel32/tests/Makefile
1604 dlls/localspl/Makefile
1605 dlls/localspl/tests/Makefile
1606 dlls/lz32/Makefile
1607 dlls/lz32/tests/Makefile
1608 dlls/mapi32/Makefile
1609 dlls/mapi32/tests/Makefile
1610 dlls/mciavi32/Makefile
1611 dlls/mcicda/Makefile
1612 dlls/mciseq/Makefile
1613 dlls/mciwave/Makefile
1614 dlls/midimap/Makefile
1615 dlls/mlang/Makefile
1616 dlls/mlang/tests/Makefile
1617 dlls/mmdevldr.vxd/Makefile
1618 dlls/monodebg.vxd/Makefile
1619 dlls/mpr/Makefile
1620 dlls/mprapi/Makefile
1621 dlls/msacm32.drv/Makefile
1622 dlls/msacm32/Makefile
1623 dlls/msacm32/tests/Makefile
1624 dlls/msadp32.acm/Makefile
1625 dlls/mscms/Makefile
1626 dlls/mscms/tests/Makefile
1627 dlls/mscoree/Makefile
1628 dlls/msdmo/Makefile
1629 dlls/msftedit/Makefile
1630 dlls/msg711.acm/Makefile
1631 dlls/mshtml/Makefile
1632 dlls/mshtml/tests/Makefile
1633 dlls/msi/Makefile
1634 dlls/msi/tests/Makefile
1635 dlls/msimg32/Makefile
1636 dlls/msisys.ocx/Makefile
1637 dlls/msnet32/Makefile
1638 dlls/msrle32/Makefile
1639 dlls/msvcrt/Makefile
1640 dlls/msvcrt/tests/Makefile
1641 dlls/msvcrt20/Makefile
1642 dlls/msvcrt40/Makefile
1643 dlls/msvcrtd/Makefile
1644 dlls/msvcrtd/tests/Makefile
1645 dlls/msvfw32/Makefile
1646 dlls/msvidc32/Makefile
1647 dlls/mswsock/Makefile
1648 dlls/msxml3/Makefile
1649 dlls/msxml3/tests/Makefile
1650 dlls/nddeapi/Makefile
1651 dlls/netapi32/Makefile
1652 dlls/netapi32/tests/Makefile
1653 dlls/newdev/Makefile
1654 dlls/ntdll/Makefile
1655 dlls/ntdll/tests/Makefile
1656 dlls/ntdsapi/Makefile
1657 dlls/objsel/Makefile
1658 dlls/odbc32/Makefile
1659 dlls/odbccp32/Makefile
1660 dlls/ole32/Makefile
1661 dlls/ole32/tests/Makefile
1662 dlls/oleacc/Makefile
1663 dlls/oleaut32/Makefile
1664 dlls/oleaut32/tests/Makefile
1665 dlls/olecli32/Makefile
1666 dlls/oledlg/Makefile
1667 dlls/olepro32/Makefile
1668 dlls/olesvr32/Makefile
1669 dlls/opengl32/Makefile
1670 dlls/powrprof/Makefile
1671 dlls/psapi/Makefile
1672 dlls/psapi/tests/Makefile
1673 dlls/pstorec/Makefile
1674 dlls/qcap/Makefile
1675 dlls/quartz/Makefile
1676 dlls/quartz/tests/Makefile
1677 dlls/query/Makefile
1678 dlls/rasapi32/Makefile
1679 dlls/resutils/Makefile
1680 dlls/riched20/Makefile
1681 dlls/riched20/tests/Makefile
1682 dlls/riched32/Makefile
1683 dlls/rpcrt4/Makefile
1684 dlls/rpcrt4/tests/Makefile
1685 dlls/rsabase/Makefile
1686 dlls/rsabase/tests/Makefile
1687 dlls/rsaenh/Makefile
1688 dlls/rsaenh/tests/Makefile
1689 dlls/sane.ds/Makefile
1690 dlls/secur32/Makefile
1691 dlls/secur32/tests/Makefile
1692 dlls/security/Makefile
1693 dlls/sensapi/Makefile
1694 dlls/serialui/Makefile
1695 dlls/setupapi/Makefile
1696 dlls/setupapi/tests/Makefile
1697 dlls/sfc/Makefile
1698 dlls/shdoclc/Makefile
1699 dlls/shdocvw/Makefile
1700 dlls/shdocvw/tests/Makefile
1701 dlls/shell32/Makefile
1702 dlls/shell32/tests/Makefile
1703 dlls/shfolder/Makefile
1704 dlls/shlwapi/Makefile
1705 dlls/shlwapi/tests/Makefile
1706 dlls/snmpapi/Makefile
1707 dlls/spoolss/Makefile
1708 dlls/stdole2.tlb/Makefile
1709 dlls/stdole32.tlb/Makefile
1710 dlls/sti/Makefile
1711 dlls/strmiids/Makefile
1712 dlls/svrapi/Makefile
1713 dlls/tapi32/Makefile
1714 dlls/twain_32/Makefile
1715 dlls/unicows/Makefile
1716 dlls/url/Makefile
1717 dlls/urlmon/Makefile
1718 dlls/urlmon/tests/Makefile
1719 dlls/user32/Makefile
1720 dlls/user32/tests/Makefile
1721 dlls/userenv/Makefile
1722 dlls/usp10/Makefile
1723 dlls/usp10/tests/Makefile
1724 dlls/uuid/Makefile
1725 dlls/uxtheme/Makefile
1726 dlls/uxtheme/tests/Makefile
1727 dlls/vdhcp.vxd/Makefile
1728 dlls/vdmdbg/Makefile
1729 dlls/version/Makefile
1730 dlls/version/tests/Makefile
1731 dlls/vmm.vxd/Makefile
1732 dlls/vnbt.vxd/Makefile
1733 dlls/vnetbios.vxd/Makefile
1734 dlls/vtdapi.vxd/Makefile
1735 dlls/vwin32.vxd/Makefile
1736 dlls/w32skrnl/Makefile
1737 dlls/winecrt0/Makefile
1738 dlls/wined3d/Makefile
1739 dlls/winedos/Makefile
1740 dlls/winemp3.acm/Makefile
1741 dlls/wineps.drv/Makefile
1742 dlls/winequartz.drv/Makefile
1743 dlls/winex11.drv/Makefile
1744 dlls/wininet/Makefile
1745 dlls/wininet/tests/Makefile
1746 dlls/winmm/Makefile
1747 dlls/winmm/joystick/Makefile
1748 dlls/winmm/tests/Makefile
1749 dlls/winmm/winealsa/Makefile
1750 dlls/winmm/winearts/Makefile
1751 dlls/winmm/wineaudioio/Makefile
1752 dlls/winmm/winecoreaudio/Makefile
1753 dlls/winmm/wineesd/Makefile
1754 dlls/winmm/winejack/Makefile
1755 dlls/winmm/winenas/Makefile
1756 dlls/winmm/wineoss/Makefile
1757 dlls/winnls32/Makefile
1758 dlls/winspool.drv/Makefile
1759 dlls/winspool.drv/tests/Makefile
1760 dlls/wintab32/Makefile
1761 dlls/wintrust/Makefile
1762 dlls/wintrust/tests/Makefile
1763 dlls/wldap32/Makefile
1764 dlls/wnaspi32/Makefile
1765 dlls/wow32/Makefile
1766 dlls/ws2_32/Makefile
1767 dlls/ws2_32/tests/Makefile
1768 dlls/wsock32/Makefile
1769 dlls/wtsapi32/Makefile
1770 documentation/Makefile
1771 fonts/Makefile
1772 include/Makefile
1773 libs/Makefile
1774 libs/port/Makefile
1775 libs/wine/Makefile
1776 libs/wpp/Makefile
1777 loader/Makefile
1778 programs/Makefile
1779 programs/clock/Makefile
1780 programs/cmd/Makefile
1781 programs/cmdlgtst/Makefile
1782 programs/control/Makefile
1783 programs/eject/Makefile
1784 programs/expand/Makefile
1785 programs/explorer/Makefile
1786 programs/hh/Makefile
1787 programs/icinfo/Makefile
1788 programs/iexplore/Makefile
1789 programs/msiexec/Makefile
1790 programs/notepad/Makefile
1791 programs/oleview/Makefile
1792 programs/progman/Makefile
1793 programs/regedit/Makefile
1794 programs/regsvr32/Makefile
1795 programs/rpcss/Makefile
1796 programs/rundll32/Makefile
1797 programs/start/Makefile
1798 programs/taskmgr/Makefile
1799 programs/uninstaller/Makefile
1800 programs/view/Makefile
1801 programs/wineboot/Makefile
1802 programs/winebrowser/Makefile
1803 programs/winecfg/Makefile
1804 programs/wineconsole/Makefile
1805 programs/winedbg/Makefile
1806 programs/winefile/Makefile
1807 programs/winemenubuilder/Makefile
1808 programs/winemine/Makefile
1809 programs/winepath/Makefile
1810 programs/winetest/Makefile
1811 programs/winevdm/Makefile
1812 programs/winhelp/Makefile
1813 programs/winver/Makefile
1814 programs/wordpad/Makefile
1815 server/Makefile
1816 tools/Makefile
1817 tools/widl/Makefile
1818 tools/winebuild/Makefile
1819 tools/winedump/Makefile
1820 tools/winegcc/Makefile
1821 tools/wmc/Makefile
1822 tools/wrc/Makefile])
1823
1824 AC_OUTPUT
1825
1826 dnl **** Display messages about additional packages ***
1827
1828 if test "$no_create" = "yes"
1829 then
1830   exit 0
1831 fi
1832
1833 if test "$verbose" = "yes"
1834 then
1835   dnl **** libcapi20-dev devel package ***
1836   if test "$ac_cv_header_capi20_h" != "yes" -o "$ac_cv_header_linux_capi_h" != "yes"
1837   then
1838     echo >&2
1839     AC_MSG_NOTICE([libcapi20 development files not found.])
1840     AC_MSG_NOTICE([Wine will be built without ISDN support. (capi2032.dll)])
1841   fi
1842
1843   dnl **** libcupsys-dev devel package ***
1844   if test "$ac_cv_header_cups_cups_h" != "yes"
1845   then
1846     echo >&2
1847     AC_MSG_NOTICE([libcups development files not found.])
1848     AC_MSG_NOTICE([Wine will be built without CUPS support.])
1849   fi
1850
1851   dnl **** libcurses devel package: see libncurses ***
1852   dnl **** libdbus-1 devel package ***
1853   dnl **** libdbus-1-dev is required for libhal-dev ***
1854
1855   dnl **** libgphoto2 devel package ***
1856   if test "$ac_cv_header_gphoto2_camera_h" != "yes"
1857   then
1858     echo >&2
1859     AC_MSG_NOTICE([libgphoto2 development files not found.])
1860     if test "$ac_cv_header_sane_sane_h" = "yes"
1861     then
1862       AC_MSG_NOTICE([Wine will be built with limited Digital Camera support. (twain_32.dll)])
1863     else
1864       AC_MSG_NOTICE([Wine will be built without Digital Camera support. (gphoto2.ds/twain_32.dll)])
1865     fi
1866   fi
1867
1868   dnl **** libhal devel package ***
1869   dnl **** libhal-dev depends on libdbus-1-dev ***
1870   if test "$ac_cv_header_hal_libhal_h" != "yes"
1871   then
1872     echo >&2
1873     AC_MSG_NOTICE([libhal development files not found.])
1874     AC_MSG_NOTICE([Wine will be built without dynamic device support. (explorer.exe)])
1875   fi
1876
1877   dnl **** libicu devel package ****
1878   if test "$ac_cv_header_unicode_ubidi_h" != "yes"
1879   then
1880     echo >&2
1881     AC_MSG_NOTICE([libicu development files not found.])
1882     AC_MSG_NOTICE([Wine will be built without bidi (Right to Left) support. (gdi32.dll)])
1883   fi
1884
1885   dnl **** liblcms devel package ****
1886   if test "$ac_cv_header_lcms_h" != "yes" -a "$ac_cv_header_lcms_lcms_h" != "yes"
1887   then
1888     echo >&2
1889     AC_MSG_NOTICE([liblcms development files not found.])
1890     AC_MSG_NOTICE([Wine will be built without Color Management support. (mscms.dll)])
1891   fi
1892
1893   dnl **** libldap devel package ****
1894   if test "$ac_cv_header_ldap_h" != "yes" -o "$ac_cv_header_lber_h" != "yes"
1895   then
1896     echo >&2
1897     AC_MSG_NOTICE([libldap (OpenLDAP) development files not found.])
1898     AC_MSG_NOTICE([Wine will be built without LDAP support. (wldap32.dll)])
1899   fi
1900
1901   dnl **** libncurses / libcurses devel package ***
1902   if test "x$with_curses" != "xno" -a "$ac_cv_header_ncurses_h" != "yes" -a "$ac_cv_header_curses_h" != "yes"
1903   then
1904     echo >&2
1905     AC_MSG_NOTICE([lib(n)curses development files not found.])
1906     AC_MSG_NOTICE([Wine will be built without (n)curses support. (wineconsole.exe)])
1907   fi
1908
1909   dnl **** libsane devel package ***
1910   if test "$ac_cv_header_sane_sane_h" != "yes"
1911   then
1912     echo >&2
1913     AC_MSG_NOTICE([libsane development files not found.])
1914     AC_MSG_NOTICE([Wine will be built without Scanner support. (sane.ds/twain_32.dll)])
1915   fi
1916
1917   dnl **** libX11-dev includes Xlib.h and Xutil.h and depends on ***
1918   dnl **** x11proto-input-dev (extensions/XInput.h) and x11proto-kb-dev (XKBlib.h) ***
1919   if test "$have_x" = "yes"
1920   then
1921     dnl **** libX11 - extension: Xext ***
1922     if test "$ac_cv_header_X11_extensions_shape_h" != "yes" -o "$ac_cv_header_X11_extensions_XShm_h" != "yes"
1923     then
1924       echo >&2
1925       AC_MSG_NOTICE([libxext development files not found.])
1926       AC_MSG_NOTICE([Wine will be built without Shm / Shape support. (winex11.drv)])
1927     fi
1928
1929     dnl **** libX11 - extension: Xrandr ***
1930     if test "$ac_cv_header_X11_extensions_Xrandr_h" != "yes"
1931     then
1932       echo >&2
1933       AC_MSG_NOTICE([libXrandr development files not found.])
1934       AC_MSG_NOTICE([Wine will be built without Xrandr support. (winex11.drv)])
1935     fi
1936
1937     dnl **** libX11 - extension: Xrender ***
1938     if test "$ac_cv_header_X11_extensions_Xrender_h" != "yes"
1939     then
1940       echo >&2
1941       AC_MSG_NOTICE([libXrender development files not found.])
1942       AC_MSG_NOTICE([Wine will be built without Xrender support. (winex11.drv)])
1943     fi
1944
1945     dnl **** libX11 - extension: Xxf86vm ***
1946     if test "$ac_cv_header_X11_extensions_xf86vmode_h" != "yes"
1947     then
1948       echo >&2
1949       AC_MSG_NOTICE([libXxf86vm development files not found.])
1950       AC_MSG_NOTICE([Wine will be built without XFree86-VidMode support. (winex11.drv)])
1951     fi
1952   fi
1953
1954   dnl **** libxml2 devel package ***
1955   if test "$ac_cv_header_libxml_parser_h" != "yes"
1956   then
1957     echo >&2
1958     AC_MSG_NOTICE([libxml2 development files not found.])
1959     AC_MSG_NOTICE([Wine will be built without XML support. (msxml.dll)])
1960   fi
1961
1962   dnl **** libxslt devel package ***
1963   if test "$ac_cv_header_libxslt_pattern_h" != "yes" -o "$ac_cv_header_libxslt_transform_h" != "yes"
1964   then
1965     echo >&2
1966     AC_MSG_NOTICE([libxslt development files not found.])
1967     AC_MSG_NOTICE([Wine will be built without xslt support. (msxml.dll)])
1968   fi
1969 fi
1970
1971
1972 dnl **** Display warnings about important packages ***
1973 if test "$have_x" = "no"
1974 then
1975   echo >&2
1976   AC_MSG_WARN([X development files not found. Wine will be built without])
1977   AC_MSG_WARN([X support, which currently does not work, and probably])
1978   AC_MSG_WARN([isn't what you want anyway. You will need to install devel])
1979   AC_MSG_WARN([ packages of Xlib/Xfree86 at the very least.])
1980 fi
1981
1982 if test -z "$OPENGLFILES"
1983 then
1984   echo >&2
1985   AC_MSG_WARN([Wine will be build without OpenGL or Direct3D support])
1986   AC_MSG_WARN([because something is wrong with the OpenGL setup:])
1987   if test "$wine_cv_opengl_headers_found" = "no"
1988   then
1989     AC_MSG_WARN([No OpenGL development headers were found])
1990   fi
1991   if test "$wine_cv_opengl_header_version_OK" = "no"
1992   then
1993     AC_MSG_WARN([Old Mesa headers detected. Consider upgrading your Mesa libraries (http://www.mesa3d.org/).])
1994   elif test "$ac_cv_lib_GL_glXCreateContext" = "no"
1995   then
1996      if test -f /usr/X11R6/lib/libGL.a
1997      then
1998         AC_MSG_WARN([/usr/X11R6/lib/libGL.a is present on your system.
1999 This probably prevents linking to OpenGL. Try deleting the file and restarting configure.])
2000      else
2001         AC_MSG_WARN([No OpenGL library found on this system.])
2002      fi
2003   fi
2004 fi
2005
2006 if test "$wine_cv_msg_freetype" = "yes"
2007 then
2008   echo >&2
2009   AC_MSG_WARN([Your system appears to have the FreeType 2 runtime libraries])
2010   AC_MSG_WARN([installed, but 'freetype-config' is not in your PATH. Install])
2011   AC_MSG_WARN([the freetype-devel package (or its equivalent on your distribution)])
2012   AC_MSG_WARN([to enable Wine to use TrueType fonts.])
2013 fi
2014
2015 if test -z "$FONTSSUBDIRS"
2016 then
2017   echo >&2
2018   if test "$FONTFORGE" = "false"
2019   then
2020     AC_MSG_WARN([FontForge is missing.])
2021   else
2022     AC_MSG_WARN([FreeType is missing.])
2023   fi
2024   AC_MSG_WARN([Fonts will not be built. Dialog text may be invisible or unaligned.])
2025 fi
2026
2027 if test -z "$ALSALIBS" -a \
2028         -z "$ARTSC_LIBS" -a \
2029         -z "$AUDIOIOLIBS" -a \
2030         -z "$NASLIBS" -a \
2031         -z "$ESD_LIBS" -a \
2032         -z "$ac_cv_lib_soname_jack" -a \
2033         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
2034         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
2035         "$ac_cv_header_soundcard_h" != "yes"
2036 then
2037   echo >&2
2038   AC_MSG_WARN([No sound system was found. Windows applications will be silent.])
2039   AC_MSG_WARN([The currently supported sound systems are:])
2040   AC_MSG_WARN([ALSA, ARTS, EsounD, AudioIO, Jack, NAS and OSS])
2041 fi
2042
2043 echo
2044 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
2045 echo
2046
2047 dnl Local Variables:
2048 dnl comment-start: "dnl "
2049 dnl comment-end: ""
2050 dnl comment-start-skip: "\\bdnl\\b\\s *"
2051 dnl compile-command: "autoconf && autoheader"
2052 dnl End: