programs/winedbg/debug.l

   1 /* -*-C-*-
   2  * Lexical scanner for command line parsing
   3  *
   4  * Copyright 1993 Eric Youngdale
   5  *           2000 Eric Pouech
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 %option nounput interactive 8bit prefix="dbg_"
  23
  24 %{
  25 #include <stdlib.h>
  26 #include <string.h>
  27 #include <stdarg.h>
  28
  29 #include "debugger.h"
  30 #include "dbg.tab.h"
  31
  32 #undef YY_INPUT
  33
  34 static int read_input(const char* pfx, char* buf, int size)
  35 {
  36     size_t      len;
  37 static char*  last_line = NULL;
  38 static size_t last_line_idx = 0;
  39
  40     /* try first to fetch the remaining of an existing line */
  41     if (last_line_idx == 0)
  42     {
  43         char* tmp = NULL;
  44         /* no remaining chars to be read from last line, grab a brand new line up to '\n' */
  45         lexeme_flush();
  46         len = input_fetch_entire_line(pfx, &tmp);
  47         /* FIXME: should have a pair of buffers, and switch between the two, instead of
  48          * reallocating a new one for each line
  49          */
  50         if (last_line && (len == 0 || (len == 1 && tmp[0] == '\n') || (len == 2 && tmp[0] == '\r' && tmp[1] == '\n')))
  51         {
  52             HeapFree(GetProcessHeap(), 0, tmp);
  53         }
  54         else
  55         {
  56             HeapFree(GetProcessHeap(), 0, last_line);
  57             last_line = tmp;
  58         }
  59     }
  60
  61     len = min(strlen(last_line + last_line_idx), size - 1);
  62     memcpy(buf, last_line + last_line_idx, len);
  63     buf[len] = '\0';
  64     if ((last_line_idx += len) >= strlen(last_line))
  65         last_line_idx = 0;
  66     return len;
  67 }
  68
  69 #define YY_INPUT(buf,result,max_size) \
  70         if ((result = read_input("Wine-dbg>", buf, max_size)) < 0) \
  71             YY_FATAL_ERROR("read_input in flex scanner failed");
  72
  73 static int syntax_error;
  74 %}
  75
  76 DIGIT      [0-9]
  77 HEXDIGIT   [0-9a-fA-F]
  78 FORMAT     [ubcdgiswx]
  79 IDENTIFIER [_a-zA-Z~?][_a-zA-Z0-9~?@]*
  80 PATHNAME   [\\/-_a-zA-Z0-9\.~@]+
  81 STRING     \"[^\n"]+\"
  82
  83 %s FORMAT_EXPECTED
  84 %s PATH_EXPECTED
  85 %s INFO_CMD
  86 %s HELP_CMD
  87 %s BD_CMD
  88 %s LOCAL_CMD
  89 %s SHOW_CMD
  90 %s MODE_CMD
  91 %s MAINT_CMD
  92 %s NOCMD
  93
  94 %x ASTRING_EXPECTED
  95 %x NOPROCESS
  96 %%
  97                                         /* set to special state when no process is loaded. */
  98                                         if (!dbg_curr_process && YYSTATE == INITIAL) {BEGIN(NOPROCESS);}
  99
 100 <<EOF>>                                 { return tEOF; }
 101 <*>\n                                   { BEGIN(INITIAL); syntax_error = 0; return tEOL; }
 102                                         /* Indicates end of command. Reset state. */
 103
 104                                         /* This rule must precede the ones below, */
 105                                         /* otherwise paths like '/' or '0x9' would */
 106                                         /* get parsed as an operator or tNUM */
 107 <PATH_EXPECTED>{PATHNAME}               { dbg_lval.string = lexeme_alloc(yytext); return tPATH; }
 108
 109 "||"                                    { return OP_LOR; }
 110 "&&"                                    { return OP_LAND; }
 111 "=="                                    { return OP_EQ; }
 112 "!="                                    { return OP_NE; }
 113 "<="                                    { return OP_LE; }
 114 ">="                                    { return OP_GE; }
 115 "<<"                                    { return OP_SHL; }
 116 ">>"                                    { return OP_SHR; }
 117 "->"                                    { return OP_DRF; }
 118 "::"                                    { return OP_SCOPE; }
 119 [-+<=>|&^()*/%:!~,\.]                   { return *yytext; }
 120 "["                                     { return *yytext; }
 121 "]"                                     { return *yytext; }
 122
 123 "0x"{HEXDIGIT}+                         { sscanf(yytext, "%x", &dbg_lval.integer); return tNUM; }
 124 {DIGIT}+                                { sscanf(yytext, "%d", &dbg_lval.integer); return tNUM; }
 125
 126 <FORMAT_EXPECTED>"/"{DIGIT}+{FORMAT}    { char* last;
 127                                           dbg_lval.integer = strtol(yytext+1, &last, 0) << 8;
 128                                           dbg_lval.integer |= *last;
 129                                           return tFORMAT; }
 130
 131 <FORMAT_EXPECTED>"/"{FORMAT}            { dbg_lval.integer = (1 << 8) | yytext[1]; return tFORMAT; }
 132
 133 {STRING}                                { dbg_lval.string = lexeme_alloc(yytext + 1); dbg_lval.string[strlen(dbg_lval.string) - 1] = '\0'; return tSTRING; }
 134 <ASTRING_EXPECTED>[^\n]+                { char* p = yytext; while (*p == ' ' || *p == '\t') p++;
 135                                           dbg_lval.string = lexeme_alloc(p); return tSTRING; }
 136
 137 <INITIAL,NOPROCESS>info|inf|in          { BEGIN(INFO_CMD); return tINFO; }
 138 <INITIAL>up                             { BEGIN(NOCMD); return tUP; }
 139 <INITIAL>down|dow|do                    { BEGIN(NOCMD); return tDOWN; }
 140 <INITIAL>frame|fram|fra|fr              { BEGIN(NOCMD); return tFRAME; }
 141 <INITIAL>list|lis|li|l                  { BEGIN(PATH_EXPECTED); return tLIST; }
 142 <INITIAL>enable|enabl|enab|ena          { BEGIN(BD_CMD); return tENABLE;}
 143 <INITIAL>disable|disabl|disab|disa|dis  { BEGIN(BD_CMD); return tDISABLE; }
 144 <INITIAL>disassemble|disassembl|disassemb|disassem|disasse|disass|disas { BEGIN(NOCMD); return tDISASSEMBLE; }
 145 <INITIAL>locally|local                  { BEGIN(LOCAL_CMD); return tLOCAL; }
 146 <INITIAL,LOCAL_CMD>display|displa|displ|disp    { BEGIN(FORMAT_EXPECTED); return tDISPLAY; }
 147 <INFO_CMD,BD_CMD>display|displa|displ|disp|dis|di|d     { BEGIN(NOCMD); return tDISPLAY; }
 148 <INITIAL>undisplay|undispla|undispl|undisp|undis|undi|und       { BEGIN(NOCMD); return tUNDISPLAY; }
 149 <INITIAL>delete|delet|dele|del          { BEGIN(BD_CMD); return tDELETE; }
 150 <INITIAL,NOPROCESS>quit|qui|qu|q        { BEGIN(NOCMD); return tQUIT; }
 151 <INITIAL>set|se                         { BEGIN(NOCMD); return tSET; }
 152 <INITIAL>x                              { BEGIN(FORMAT_EXPECTED); return tEXAM; }
 153 <INITIAL,NOPROCESS>help|hel|he|"?"      { BEGIN(HELP_CMD); return tHELP; }
 154
 155 <INITIAL,NOPROCESS>backtrace|backtrac|backtra|backt|back|bac|ba|bt { BEGIN(NOCMD); return tBACKTRACE; }
 156 <INITIAL,NOPROCESS>where|wher|whe       { BEGIN(NOCMD); return tBACKTRACE; }
 157
 158 <INITIAL>cont|con|co|c                  { BEGIN(NOCMD); return tCONT; }
 159 <INITIAL>pass|pas|pa                    { BEGIN(NOCMD); return tPASS; }
 160 <INITIAL>condition|conditio|conditi|condit|condi|cond   { BEGIN(NOCMD); return tCOND; }
 161 <INITIAL>step|ste|st|s                  { BEGIN(NOCMD); return tSTEP; }
 162 <INITIAL>next|nex|ne|n                  { BEGIN(NOCMD); return tNEXT; }
 163 <INITIAL>stepi|si                       { BEGIN(NOCMD); return tSTEPI; }
 164 <INITIAL>nexti|ni                       { BEGIN(NOCMD); return tNEXTI; }
 165 <INITIAL>finish|finis|fini|fin|fi       { BEGIN(NOCMD); return tFINISH; }
 166
 167 <INITIAL>abort|abor|abo                 { BEGIN(NOCMD); return tABORT; }
 168 <INITIAL>print|prin|pri|pr|p            { BEGIN(FORMAT_EXPECTED); return tPRINT; }
 169
 170 <INITIAL>show|sho|sh                    { BEGIN(SHOW_CMD); return tSHOW; }
 171 <INITIAL,NOPROCESS>source|sourc|sour|src { BEGIN(PATH_EXPECTED); return tSOURCE; }
 172 <INITIAL>symbolfile|symbols|symbol|sf   { BEGIN(PATH_EXPECTED); return tSYMBOLFILE; }
 173
 174 <INITIAL,INFO_CMD,BD_CMD>break|brea|bre|br|b    { BEGIN(NOCMD); return tBREAK; }
 175 <INITIAL,INFO_CMD,BD_CMD>hbreak|hbrea|hbre|hbr|hb { BEGIN(NOCMD); return tHBREAK; }
 176 <INITIAL>watch|watc|wat                 { BEGIN(NOCMD); return tWATCH; }
 177 <INITIAL>whatis|whati|what              { BEGIN(NOCMD); return tWHATIS; }
 178 <INITIAL,NOPROCESS>run|ru|r             { BEGIN(ASTRING_EXPECTED); return tRUN;}
 179 <INITIAL>detach|detac|deta|det          { BEGIN(NOCMD); return tDETACH; }
 180 <INITIAL>maintenance|maint              { BEGIN(MAINT_CMD); return tMAINTENANCE; }
 181 <INITIAL>minidump|mdmp                  { BEGIN(PATH_EXPECTED); return tMINIDUMP; }
 182 <INITIAL>echo                           { BEGIN(ASTRING_EXPECTED); return tECHO; }
 183 <NOPROCESS>attach|attac|atta|att        { BEGIN(NOCMD); return tATTACH; }
 184 <INFO_CMD>share|shar|sha                { return tSHARE; }
 185 <INFO_CMD>locals|local|loca|loc         { return tLOCAL; }
 186 <INFO_CMD>class|clas|cla                { return tCLASS; }
 187 <INFO_CMD>process|proces|proce|proc     { return tPROCESS; }
 188 <INFO_CMD>threads|thread|threa|thre|thr|th { return tTHREAD; }
 189 <INFO_CMD>exception|except|exc|ex       { return tEXCEPTION; }
 190 <INFO_CMD>registers|regs|reg|re         { return tREGS; }
 191 <INFO_CMD>allregs|allreg|allre          { return tALLREGS; }
 192 <INFO_CMD>"all-registers"|"all-regs"|"all-reg"|"all-re" { return tALLREGS; }
 193 <INFO_CMD>segments|segment|segm|seg|se  { return tSEGMENTS; }
 194 <INFO_CMD>stack|stac|sta|st             { return tSTACK; }
 195 <INFO_CMD>symbol|symbo|symb|sym         { BEGIN(ASTRING_EXPECTED); return tSYMBOL; }
 196 <INFO_CMD>maps|map                      { return tMAPS; }
 197 <INFO_CMD>window|windo|wind|win|wnd     { return tWND; }
 198 <HELP_CMD>info|inf|in                   { return tINFO; }
 199 <MAINT_CMD>type                         { return tTYPE; }
 200
 201 <INITIAL,SHOW_CMD>directories|directorie|directori|director|directo|direct|direc|direc|dir {
 202                                           BEGIN(PATH_EXPECTED); return tDIR; }
 203
 204 char                                    { return tCHAR; }
 205 short                                   { return tSHORT; }
 206 int                                     { return tINT; }
 207 long                                    { return tLONG; }
 208 float                                   { return tFLOAT; }
 209 double                                  { return tDOUBLE; }
 210 unsigned                                { return tUNSIGNED; }
 211 signed                                  { return tSIGNED; }
 212 struct                                  { return tSTRUCT; }
 213 union                                   { return tUNION; }
 214 enum                                    { return tENUM; }
 215 all                                     { return tALL; }
 216
 217 {IDENTIFIER}                            { dbg_lval.string = lexeme_alloc(yytext); return tIDENTIFIER; }
 218 "$"{IDENTIFIER}                         { dbg_lval.string = lexeme_alloc(yytext+1); return tINTVAR; }
 219
 220 <*>[ \t\r]+                             /* Eat up whitespace and DOS LF */
 221
 222 <NOPROCESS>.                            { BEGIN(ASTRING_EXPECTED); yyless(0); return tNOPROCESS;}
 223 <*>.                                    { if (syntax_error == 0) { syntax_error++; dbg_printf("Syntax Error (%s)\n", yytext); } }
 224 %%
 225
 226 #ifndef dbg_wrap
 227 int dbg_wrap(void) { return 1; }
 228 #endif
 229
 230 static char** local_lexemes /* = NULL */;
 231 static int next_lexeme /* = 0 */;
 232 static int alloc_lexeme /* = 0 */;
 233
 234 char* lexeme_alloc_size(int size)
 235 {
 236     assert(0 <= next_lexeme && next_lexeme < alloc_lexeme + 1);
 237     if (next_lexeme >= alloc_lexeme)
 238     {
 239         alloc_lexeme += 32;
 240         local_lexemes = dbg_heap_realloc(local_lexemes, alloc_lexeme * sizeof(local_lexemes[0]));
 241         assert(local_lexemes);
 242     }
 243     return local_lexemes[next_lexeme++] = HeapAlloc(GetProcessHeap(), 0, size + 1);
 244 }
 245
 246 char* lexeme_alloc(const char* lexeme)
 247 {
 248     char*       ptr = lexeme_alloc_size(strlen(lexeme) + 1);
 249     return strcpy(ptr, lexeme);
 250 }
 251
 252 void lexeme_flush(void)
 253 {
 254     while (--next_lexeme >= 0) HeapFree(GetProcessHeap(), 0, local_lexemes[next_lexeme]);
 255     next_lexeme = 0;
 256 }