tools/make_specfiles

   1 #!/usr/bin/perl -w
   2 #
   3 # Update spec files across dlls that share an implementation
   4 #
   5 # Copyright 2011 Alexandre Julliard
   6 #
   7 # This library is free software; you can redistribute it and/or
   8 # modify it under the terms of the GNU Lesser General Public
   9 # License as published by the Free Software Foundation; either
  10 # version 2.1 of the License, or (at your option) any later version.
  11 #
  12 # This library is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # Lesser General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU Lesser General Public
  18 # License along with this library; if not, write to the Free Software
  19 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20 #
  21
  22 use strict;
  23
  24 my %funcs;
  25 my $group_head;
  26
  27 my @dll_groups =
  28 (
  29  [
  30   "msvcrt",
  31   "msvcr100",
  32   "msvcr110",
  33   "msvcirt",
  34   "msvcr90",
  35   "msvcr80",
  36   "msvcr71",
  37   "msvcr70",
  38   "msvcrt40",
  39   "msvcrt20",
  40   "msvcrtd",
  41   "crtdll",
  42  ],
  43  [
  44   "msvcrt",
  45   "msvcp90",
  46   "msvcp100",
  47   "msvcp110",
  48   "msvcp71",
  49   "msvcp80",
  50   "msvcp70",
  51   "msvcp60",
  52  ],
  53  [
  54   "d3dx9_36",
  55   "d3dx9_43",
  56   "d3dx9_42",
  57   "d3dx9_41",
  58   "d3dx9_40",
  59   "d3dx9_39",
  60   "d3dx9_38",
  61   "d3dx9_37",
  62   "d3dx9_35",
  63   "d3dx9_34",
  64   "d3dx9_33",
  65   "d3dx9_32",
  66   "d3dx9_31",
  67   "d3dx9_30",
  68   "d3dx9_29",
  69   "d3dx9_28",
  70   "d3dx9_27",
  71   "d3dx9_26",
  72   "d3dx9_25",
  73   "d3dx9_24",
  74  ],
  75  [
  76   "d3dx10_43",
  77   "d3dx10_42",
  78   "d3dx10_41",
  79   "d3dx10_40",
  80   "d3dx10_39",
  81   "d3dx10_38",
  82   "d3dx10_37",
  83   "d3dx10_36",
  84   "d3dx10_35",
  85   "d3dx10_34",
  86   "d3dx10_33",
  87  ],
  88  [
  89   "d3dx11_43",
  90   "d3dx11_42",
  91  ],
  92  [
  93   "d3dcompiler_43",
  94   "d3dcompiler_42",
  95   "d3dcompiler_41",
  96   "d3dcompiler_40",
  97   "d3dcompiler_39",
  98   "d3dcompiler_38",
  99   "d3dcompiler_37",
 100   "d3dcompiler_36",
 101   "d3dcompiler_35",
 102   "d3dcompiler_34",
 103   "d3dcompiler_33",
 104  ],
 105  [
 106   "xinput1_3",
 107   "xinput1_4",
 108   "xinput1_2",
 109   "xinput1_1",
 110   "xinput9_1_0",
 111  ],
 112  [
 113   "setupapi",
 114   "cfgmgr32",
 115  ],
 116  [
 117   "vcomp",
 118   "vcomp100",
 119   "vcomp90",
 120  ],
 121  [
 122   "advapi32",
 123   "api-ms-win-core-localregistry-l1-1-0",
 124   "api-ms-win-downlevel-advapi32-l1-1-0",
 125   "api-ms-win-downlevel-advapi32-l2-1-0",
 126   "api-ms-win-security-base-l1-1-0",
 127   "api-ms-win-core-registry-l1-1-0",
 128   "api-ms-win-eventing-provider-l1-1-0",
 129   "api-ms-win-security-base-l1-2-0",
 130   "api-ms-win-security-sddl-l1-1-0",
 131   "api-ms-win-service-core-l1-1-1",
 132   "api-ms-win-service-management-l1-1-0",
 133   "api-ms-win-service-winsvc-l1-2-0",
 134  ],
 135  [
 136   "kernel32",
 137   "api-ms-win-downlevel-normaliz-l1-1-0",
 138   "api-ms-win-core-processthreads-l1-1-0",
 139   "api-ms-win-core-processthreads-l1-1-1",
 140   "api-ms-win-core-debug-l1-1-1",
 141   "api-ms-win-core-errorhandling-l1-1-1",
 142   "api-ms-win-core-interlocked-l1-2-0",
 143   "api-ms-win-core-profile-l1-1-0",
 144   "api-ms-win-core-string-l1-1-0",
 145   "api-ms-win-core-sysinfo-l1-2-0",
 146   "api-ms-win-core-util-l1-1-0",
 147   "api-ms-win-core-synch-l1-2-0",
 148   "api-ms-win-core-console-l1-1-0",
 149   "api-ms-win-core-file-l1-2-0",
 150   "api-ms-win-core-handle-l1-1-0",
 151   "api-ms-win-core-heap-l1-2-0",
 152   "api-ms-win-core-heap-obsolete-l1-1-0",
 153   "api-ms-win-core-io-l1-1-1",
 154   "api-ms-win-core-kernel32-legacy-l1-1-0",
 155   "api-ms-win-core-libraryloader-l1-1-1",
 156   "api-ms-win-core-localization-l1-2-0",
 157   "api-ms-win-core-localization-obsolete-l1-1-0",
 158   "api-ms-win-core-memory-l1-1-1",
 159   "api-ms-win-core-namedpipe-l1-2-0",
 160   "api-ms-win-core-processenvironment-l1-2-0",
 161   "api-ms-win-core-psapi-l1-1-0",
 162   "api-ms-win-core-threadpool-legacy-l1-1-0",
 163   "api-ms-win-core-timezone-l1-1-0",
 164  ],
 165  [
 166   "ole32",
 167   "api-ms-win-downlevel-ole32-l1-1-0",
 168   "api-ms-win-core-com-l1-1-0",
 169  ],
 170  [
 171   "shell32",
 172   "api-ms-win-downlevel-shell32-l1-1-0",
 173  ],
 174  [
 175   "shlwapi",
 176   "api-ms-win-downlevel-shlwapi-l1-1-0",
 177   "api-ms-win-downlevel-shlwapi-l2-1-0",
 178   "api-ms-win-core-shlwapi-legacy-l1-1-0",
 179   "api-ms-win-core-url-l1-1-0",
 180  ],
 181  [
 182   "user32",
 183   "api-ms-win-downlevel-user32-l1-1-0",
 184   "api-ms-win-ntuser-dc-access-l1-1-0",
 185  ],
 186  [
 187   "version",
 188   "api-ms-win-downlevel-version-l1-1-0",
 189  ],
 190  [
 191   "msvcrt",
 192   "ntdll",
 193   "ntoskrnl.exe",
 194   "api-ms-win-core-rtlsupport-l1-2-0",
 195  ],
 196  [
 197   "gdi32",
 198   "ext-ms-win-gdi-devcaps-l1-1-0",
 199  ],
 200 );
 201
 202 my $update_flags = 0;
 203 my $show_duplicates = 0;
 204
 205 foreach my $arg (@ARGV)
 206 {
 207     if ($arg eq "-f") { $update_flags = 1; }
 208     elsif ($arg eq "-d") { $show_duplicates = 1; }
 209 }
 210
 211 sub update_file($)
 212 {
 213     my $file = shift;
 214     my $ret = !(-f $file) || system "cmp $file $file.new >/dev/null";
 215     if (!$ret)
 216     {
 217         unlink "$file.new";
 218     }
 219     else
 220     {
 221         #system "diff -u $file $file.new";
 222         rename "$file.new", "$file";
 223         print "$file updated\n";
 224     }
 225     return $ret;
 226 }
 227
 228 # parse a spec file line
 229 sub parse_line($$$)
 230 {
 231     my ($name, $line, $str) = @_;
 232
 233     if ($str =~ /^\s*(\@|\d+)\s+(stdcall|cdecl|varargs|thiscall|stub|extern)\s+((?:-\S+\s+)*)([A-Za-z0-9_\@\$?]+)(?:\s*(\([^)]*\)))?(?:\s+([A-Za-z0-9_\@\$?.]+))?(\s*\#.*)?/)
 234     {
 235         return ( "ordinal" => $1, "callconv" => $2, "flags" => $3, "name" => $4, "args" => $5 || "",
 236                  "target" => $6 || $4, "comment" => $7, "spec" => $name );
 237     }
 238     return () if $str =~ /^\s*$/;
 239     return () if $str =~ /^\s*\#/;
 240     printf STDERR "$name.spec:$line: error: Unrecognized line $_\n";
 241 }
 242
 243 sub read_spec_file($)
 244 {
 245     my $name = shift;
 246     my $file = "dlls/$name/$name.spec";
 247     my %stubs;
 248     open SPEC, "<$file" or die "cannot open $file";
 249     while (<SPEC>)
 250     {
 251         chomp;
 252         my %descr = parse_line( $name, $., $_ );
 253         next unless %descr;
 254
 255         my $func = $descr{name};
 256         next if defined $funcs{$func};
 257         $funcs{$func} = \%descr;
 258     }
 259     close SPEC;
 260 }
 261
 262 sub update_spec_file($)
 263 {
 264     my $name = shift;
 265     my $file = "dlls/$name/$name.spec";
 266     my %stubs;
 267
 268     open SPEC, "<$file" or die "cannot open $file";
 269     open NEW, ">$file.new" or die "cannot create $file.new";
 270     while (<SPEC>)
 271     {
 272         chomp;
 273
 274         my $commented_out = 0;
 275         my %descr = parse_line( $name, $., $_ );
 276         if (!%descr)
 277         {
 278             # check for commented out exports
 279             if (/^\s*\#\s*((?:\@|\d+)\s+)?((?:extern|stub|stdcall|cdecl|varargs|thiscall)\s+.*)/)
 280             {
 281                 $commented_out = 1;
 282                 %descr = parse_line( $name, $., ($1 || "\@ ") . $2 );
 283             }
 284         }
 285         goto done unless %descr;
 286
 287         my $func = $descr{name};
 288         if (!defined $funcs{$func})
 289         {
 290             $funcs{$func} = \%descr unless $commented_out;
 291             goto done;
 292         }
 293
 294         my %parent = %{$funcs{$func}};
 295         goto done if $parent{spec} eq $descr{spec};  # the definition is in this spec file
 296         goto done if $descr{comment} && $descr{comment} =~ /don't forward/;
 297         if ($descr{callconv} ne "stub" && $descr{target} !~ /\./ && !$commented_out)
 298         {
 299             printf "%s:%u: note: %s already defined in %s\n", $file, $., $func, $parent{spec} if $show_duplicates;
 300             goto done;
 301         }
 302
 303         my $flags = $descr{flags};
 304         if ($parent{callconv} ne "stub" || $update_flags)
 305         {
 306             $flags = $parent{flags};
 307             $flags =~ s/-ordinal\s*// if $descr{ordinal} eq "@";
 308             $flags =~ s/-noname\s*// if $descr{ordinal} eq "@";
 309             if ($descr{flags} =~ /-private/)  # preserve -private flag
 310             {
 311                 $flags = "-private " . $flags unless $flags =~ /-private/;
 312             }
 313         }
 314
 315         if ($parent{callconv} ne "stub" || $parent{args})
 316         {
 317             my $callconv = $parent{callconv} ne "stub" ? $parent{callconv} :
 318                            $parent{spec} =~ /msvc/ ? "cdecl" : "stdcall";  # hack
 319             $_ = sprintf "$descr{ordinal} %s %s%s", $callconv, $flags, $func;
 320
 321             if ($parent{target} =~ /$group_head\./)  # use the same forward as parent if possible
 322             {
 323                 $_ .= sprintf "%s %s", $parent{args}, $parent{target};
 324             }
 325             else
 326             {
 327                 $_ .= sprintf "%s %s.%s", $parent{args}, $parent{spec}, $func;
 328             }
 329         }
 330         else
 331         {
 332             $_ = sprintf "$descr{ordinal} stub %s%s", $flags, $func;
 333         }
 334         $_ .= $descr{comment} || "";
 335
 336       done:
 337         print NEW "$_\n";
 338     }
 339     close SPEC;
 340     close NEW;
 341     update_file( $file );
 342 }
 343
 344 sub sync_spec_files(@)
 345 {
 346     %funcs = ();
 347     $group_head = shift;
 348     read_spec_file( $group_head );
 349     foreach my $spec (@_) { update_spec_file($spec); }
 350 }
 351
 352 foreach my $group (@dll_groups)
 353 {
 354     sync_spec_files( @{$group} );
 355 }