configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl For detailed change history, see the git commit logs.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 dnl autoconf versions before 2.62 don't handle source dir symlinks correctly
   8 AC_PREREQ(2.62)
   9 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org],[wine],[http://www.winehq.org])
  10 AC_CONFIG_SRCDIR(server/atom.c)
  11 AC_CONFIG_HEADERS(include/config.h)
  12 AC_CONFIG_AUX_DIR(tools)
  13
  14 dnl autoconf versions before 2.63b don't have AS_VAR_APPEND or AS_VAR_IF
  15 m4_ifdef([AS_VAR_APPEND],,[as_fn_append () { eval $[1]=\$$[1]\$[2]; }
  16 AC_DEFUN([AS_VAR_APPEND],[as_fn_append $1 $2])])dnl
  17 m4_ifdef([AS_VAR_IF],,[AC_DEFUN([AS_VAR_IF],
  18 [AS_LITERAL_IF([$1],
  19   [AS_IF([test "x$$1" = x""$2], [$3], [$4])],
  20   [eval as_val=\$$1
  21    AS_IF([test "x$as_val" = x""$2], [$3], [$4])])])])dnl
  22 dnl autoconf versions before 2.64 don't have AC_PACKAGE_URL
  23 m4_ifdef([AC_PACKAGE_URL],,
  24   [AC_DEFINE([PACKAGE_URL], ["http://www.winehq.org"], [Define to the home page for this package.])
  25    AC_SUBST([PACKAGE_URL], ["http://www.winehq.org"])])dnl
  26
  27 dnl **** Command-line arguments ****
  28
  29 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  30 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  31 AC_ARG_ENABLE(tests, AS_HELP_STRING([--disable-tests],[do not build the regression tests]))
  32 AC_ARG_ENABLE(maintainer-mode, AS_HELP_STRING([--enable-maintainer-mode],[enable maintainer-specific build rules]))
  33
  34 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  35             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  36 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]))
  37 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]))
  38 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  39             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  40 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]))
  41 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  42             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  43 AC_ARG_WITH(dbus,      AS_HELP_STRING([--without-dbus],[do not use DBus (dynamic device support)]))
  44 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]))
  45 AC_ARG_WITH(freetype,  AS_HELP_STRING([--without-freetype],[do not use the FreeType library]))
  46 AC_ARG_WITH(gettext,   AS_HELP_STRING([--without-gettext],[do not use gettext]))
  47 AC_ARG_WITH(gettextpo, AS_HELP_STRING([--with-gettextpo],[use the GetTextPO library to rebuild po files]),
  48             [if test "x$withval" = "xno"; then ac_cv_header_gettext_po_h=no; fi])
  49 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  50 AC_ARG_WITH(glu,       AS_HELP_STRING([--without-glu],[do not use the GLU library]))
  51 AC_ARG_WITH(gnutls,    AS_HELP_STRING([--without-gnutls],[do not use GnuTLS (schannel support)]))
  52 AC_ARG_WITH(gsm,       AS_HELP_STRING([--without-gsm],[do not use libgsm (GSM 06.10 codec support)]),
  53             [if test "x$withval" = "xno"; then ac_cv_header_gsm_h=no; ac_cv_header_gsm_gsm_h=no; fi])
  54 AC_ARG_WITH(gstreamer, AS_HELP_STRING([--without-gstreamer],[do not use GStreamer (codecs support)]))
  55 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  56 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]))
  57 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  58             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  59 AC_ARG_WITH(mpg123,    AS_HELP_STRING([--without-mpg123],[do not use the mpg123 library]))
  60 AC_ARG_WITH(openal,    AS_HELP_STRING([--without-openal],[do not use OpenAL]),
  61             [if test "x$withval" = "xno"; then ac_cv_header_AL_al_h=no; ac_cv_header_OpenAL_al_h=no; fi])
  62 AC_ARG_WITH(opencl,    AS_HELP_STRING([--without-opencl],[do not use OpenCL]),
  63             [if test "x$withval" = "xno"; then ac_cv_header_CL_cl_h=no; ac_cv_header_OpenCL_opencl_h=no; fi])
  64 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  65 AC_ARG_WITH(osmesa,     AS_HELP_STRING([--without-osmesa],[do not use the OSMesa library]))
  66 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]))
  67 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]))
  68 AC_ARG_WITH(pthread,   AS_HELP_STRING([--without-pthread],[do not use the pthread library]),
  69             [if test "x$withval" = "xno"; then ac_cv_header_pthread_h=no; fi])
  70 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  71 AC_ARG_WITH(tiff,      AS_HELP_STRING([--without-tiff],[do not use TIFF]))
  72 AC_ARG_WITH(v4l,       AS_HELP_STRING([--without-v4l],[do not use v4l1 (v4l support)]))
  73 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  74             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  75 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  76             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  77 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  78             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  79 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  80             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  81 AC_ARG_WITH(xinput2,   AS_HELP_STRING([--without-xinput2],[do not use the Xinput 2 extension]),
  82             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput2_h=no; fi])
  83 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  84 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  85             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  86 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
  87             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
  88 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
  89             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
  90 AC_ARG_WITH(xshm,      AS_HELP_STRING([--without-xshm],[do not use XShm (shared memory extension)]),
  91             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XShm_h=no; fi])
  92 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
  93 AC_ARG_WITH(xxf86vm,   AS_HELP_STRING([--without-xxf86vm],[do not use XFree video mode extension]),
  94             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; ac_cv_header_X11_extensions_xf86vmproto_h=no; fi])
  95 AC_ARG_WITH(zlib,      AS_HELP_STRING([--without-zlib],[do not use Zlib (data compression)]),
  96             [if test "x$withval" = "xno"; then ac_cv_header_zlib_h=no; fi])
  97
  98 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
  99 AC_ARG_WITH(wine64,    AS_HELP_STRING([--with-wine64=DIR],[use the 64-bit Wine in DIR for a Wow64 build]))
 100
 101 AC_CANONICAL_HOST
 102
 103 dnl check for out of tree build with unclean source tree
 104 case "$srcdir" in
 105  .) ;;
 106  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 107       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 108 You need to run 'make distclean' in the source tree first.])
 109     fi ;;
 110 esac
 111
 112 dnl **** Check for some programs ****
 113
 114 AC_PROG_MAKE_SET
 115 AC_PROG_CC
 116 AC_PROG_CXX
 117 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 118 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 119 AC_DEFINE_UNQUOTED(EXEEXT,["$ac_exeext"],[Define to the file extension for executables.])
 120
 121 case $host in
 122   *-darwin*)
 123     if test "x$enable_win64" = "xyes"
 124     then
 125       CC="$CC -m64"
 126       CXX="$CXX -m64"
 127       host_cpu="x86_64"
 128       notice_platform="64-bit "
 129       AC_SUBST(TARGETFLAGS,"-m64")
 130     else
 131       CC="$CC -m32"
 132       CXX="$CXX -m32"
 133       host_cpu="i386"
 134       notice_platform="32-bit "
 135       AC_SUBST(TARGETFLAGS,"-m32")
 136       enable_win16=${enable_win16:-yes}
 137     fi
 138     with_fontconfig=${with_fontconfig:-no}
 139     ;;
 140   x86_64*)
 141     if test "x$enable_win64" != "xyes" -a "$cross_compiling" != "yes"
 142     then
 143       CC="$CC -m32"
 144       CXX="$CXX -m32"
 145       AC_MSG_CHECKING([whether $CC works])
 146       AC_LINK_IFELSE([AC_LANG_PROGRAM()],AC_MSG_RESULT([yes]),
 147                      [AC_MSG_RESULT([no])
 148                       AC_MSG_ERROR([Cannot build a 32-bit program, you need to install 32-bit development libraries.])])
 149       host_cpu="i386"
 150       notice_platform="32-bit "
 151       AC_SUBST(TARGETFLAGS,"-m32")
 152       enable_win16=${enable_win16:-yes}
 153     else
 154       if test "x${GCC}" = "xyes"
 155       then
 156         AC_MSG_CHECKING([whether $CC supports __builtin_ms_va_list])
 157         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[void func(__builtin_ms_va_list *args);]])],
 158                           [AC_MSG_RESULT([yes])],
 159                           [AC_MSG_RESULT([no])
 160                            AC_MSG_ERROR([You need gcc >= 4.4 to build Wine as 64-bit.])])
 161       fi
 162       AC_SUBST(TARGETFLAGS,"-m64")
 163     fi
 164     ;;
 165   arm*)
 166     AC_MSG_CHECKING([whether $CC supports Thumb])
 167     WINE_TRY_ASM_LINK([".thumb\nblx ac_test\n.arm"],[int ac_test(int i) { return i; }], [if (ac_test(1)) return 1],
 168                       [AC_MSG_RESULT([yes])],
 169                       [AC_MSG_RESULT([no])
 170                        AC_MSG_ERROR([You need a target with Thumb support to build Wine for ARM.])])
 171     CFLAGS="$CFLAGS -marm"
 172     ;;
 173   *-mingw32*|*-cygwin*)
 174     enable_win16=${enable_win16:-no}
 175     CFLAGS="$CFLAGS -D_WIN32"
 176     ;;
 177   i[[3456789]]86*)
 178     enable_win16=${enable_win16:-yes}
 179     ;;
 180 esac
 181
 182 dnl enable_win16 defaults to yes on x86, to no on other CPUs
 183 enable_win16=${enable_win16:-no}
 184 enable_win64=${enable_win64:-no}
 185
 186 dnl Disable winetest too if tests are disabled
 187 enable_winetest=${enable_winetest:-$enable_tests}
 188
 189 dnl Some special cases for the wow64 build
 190 if test -n "$with_wine64"
 191 then
 192     if test "x$enable_win64" = "xyes"
 193     then
 194         AC_MSG_ERROR([--enable-win64 and --with-wine64 are mutually exclusive.
 195 --enable-win64 should be used in the 64-bit build tree, --with-wine64 in the 32-bit Wow64 build tree.])
 196     fi
 197     enable_fonts=${enable_fonts:-no}
 198     enable_server=${enable_server:-no}
 199 elif test "x$enable_win64" = "xyes"
 200 then
 201     test "x$libdir" != "x\${exec_prefix}/lib" || libdir="\${exec_prefix}/lib64"
 202 fi
 203
 204 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 205   [wine_cv_toolsdir="$with_wine_tools"
 206    if test -z "$with_wine_tools"; then
 207      if test "$cross_compiling" = "yes"; then
 208        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 209      elif test -n "$with_wine64"; then
 210        wine_cv_toolsdir="$with_wine64"
 211      fi
 212    fi
 213    if test -z "$wine_cv_toolsdir"; then
 214      wine_cv_toolsdir="\$(top_builddir)"
 215    elif test -d "$wine_cv_toolsdir/tools/winebuild"; then
 216      case "$wine_cv_toolsdir" in
 217        /*) ;;
 218        *)  wine_cv_toolsdir="\$(top_builddir)/$wine_cv_toolsdir" ;;
 219      esac
 220      enable_tools=${enable_tools:-no}
 221    else
 222      AC_MSG_ERROR([could not find Wine tools in $wine_cv_toolsdir])
 223    fi])
 224 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 225 if test -n "$host_alias" -a "$host_alias" != "$build_alias"
 226 then
 227     AC_SUBST(TARGETFLAGS,"-b $host_alias $TARGETFLAGS")
 228 fi
 229
 230 dnl Check for flex
 231 AC_CHECK_PROGS(FLEX,flex,none)
 232 if test "$FLEX" = "none"
 233 then
 234   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 235 fi
 236 AC_MSG_CHECKING([whether flex is recent enough])
 237 cat >conftest.l <<EOF
 238 %top{
 239 #include "prediluvian.h"
 240 }
 241 %%
 242 EOF
 243 if $FLEX -t conftest.l >/dev/null 2>&AS_MESSAGE_LOG_FD
 244 then
 245   AC_MSG_RESULT([yes])
 246 else
 247   AC_MSG_RESULT([no])
 248   AC_MSG_ERROR([Your flex version is too old. Please install flex version 2.5.33 or newer.])
 249 fi
 250
 251 dnl Check for bison
 252 AC_CHECK_PROGS(BISON,bison,none)
 253 if test "$BISON" = "none"
 254 then
 255   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 256 fi
 257
 258 AC_CHECK_TOOLS(AR,[ar gar],ar)
 259 AC_CHECK_TOOL(STRIP,strip,strip)
 260 AC_SUBST(ARFLAGS,rc)
 261 AC_PROG_RANLIB
 262 AC_PROG_LN_S
 263 AC_PROG_EGREP
 264 AC_PROG_MKDIR_P
 265 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 266
 267 dnl Use the correct strip to install programs
 268 test -z "$INSTALL_PROGRAM" && INSTALL_PROGRAM="STRIPPROG=\"\$(STRIP)\" \$(top_srcdir)/tools/install-sh"
 269 AC_PROG_INSTALL
 270
 271 dnl Check for various programs
 272 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 273 AC_CHECK_PROGS(RSVG, rsvg, false)
 274 AC_CHECK_PROGS(CONVERT, convert, false)
 275 AC_CHECK_PROGS(ICOTOOL, icotool, false)
 276 AC_CHECK_PROGS(MSGFMT, msgfmt, false)
 277 WINE_PATH_PKG_CONFIG
 278
 279 if test "x$enable_maintainer_mode" != "xyes"
 280 then
 281   AC_SUBST([MAINTAINER_MODE],[\#])
 282 else
 283   test "$srcdir" = . || AC_MSG_ERROR([Maintainer mode cannot work out of tree.])
 284   if test "$FONTFORGE" = "false"; then AC_MSG_ERROR([You need fontforge to rebuild fonts in maintainer mode.]); fi
 285   if test "$RSVG" = "false"; then AC_MSG_ERROR([You need rsvg to rebuild icons in maintainer mode.]); fi
 286
 287   dnl Check the imagemagick version
 288   if test "$CONVERT" = false
 289   then
 290     AC_MSG_ERROR([You need imagemagick to rebuild icons in maintainer mode.])
 291   else
 292     AC_MSG_CHECKING([for recent enough imagemagick])
 293     convert_version=`convert --version | head -n1`
 294     if test "x$convert_version" != "x"
 295     then
 296       convert_version_major=`expr "$convert_version" : '.* \([[0-9]]*\)\.[[0-9]]*'`
 297       convert_version_minor=`expr "$convert_version" : '.* [[0-9]]*\.\([[0-9]]*\)'`
 298       if test "$convert_version_major" -eq 6 -a "$convert_version_minor" -lt 6
 299       then
 300         CONVERT=false
 301       fi
 302     fi
 303     if test "$CONVERT" = false
 304     then
 305       AC_MSG_RESULT([no ($convert_version_major.$convert_version_minor)])
 306       AC_MSG_ERROR([You need imagemagick version 6.6 or newer to rebuild icons in maintainer mode.])
 307     else
 308       AC_MSG_RESULT([yes ($convert_version_major.$convert_version_minor)])
 309     fi
 310   fi
 311
 312   dnl Check the icotool version
 313   if test "$ICOTOOL" = false
 314   then
 315     AC_MSG_ERROR([You need icotool to rebuild icons in maintainer mode.])
 316   else
 317     AC_MSG_CHECKING([for recent enough icotool])
 318     icotool_version=`icotool --version | head -n1`
 319     if test "x$icotool_version" != "x"
 320     then
 321       icotool_version_major=`expr "$icotool_version" : '.* \([[0-9]]*\)\.[[0-9]]*'`
 322       icotool_version_minor=`expr "$icotool_version" : '.* [[0-9]]*\.\([[0-9]]*\)'`
 323       if test "$icotool_version_major" -eq 0 -a "$icotool_version_minor" -lt 29
 324       then
 325         ICOTOOL=false
 326         WINE_WARNING([icotool version 0.29.0 or newer is needed to rebuild icons.])
 327       fi
 328     fi
 329     if test "$ICOTOOL" = false
 330     then
 331       AC_MSG_RESULT([no ($icotool_version_major.$icotool_version_minor)])
 332       AC_MSG_ERROR([You need icotool version 0.29.0 or newer to rebuild icons in maintainer mode.])
 333     else
 334       AC_MSG_RESULT([yes ($icotool_version_major.$icotool_version_minor)])
 335     fi
 336   fi
 337
 338   dnl Maintainer mode requires gettext
 339   with_gettext=yes
 340   with_gettextpo=yes
 341   AS_UNSET(ac_cv_header_gettext_po_h)
 342 fi
 343
 344 test "x$with_gettext" != xno || MSGFMT=false
 345 if test "$MSGFMT" != "false"
 346 then
 347   AC_MSG_CHECKING([whether msgfmt supports contexts])
 348   cat >conftest.po <<EOF
 349 # comment
 350 msgctxt "ctxt"
 351 msgid "id"
 352 msgstr "str"
 353 EOF
 354   if $MSGFMT -o /dev/null conftest.po 2>&AS_MESSAGE_LOG_FD
 355   then
 356     AC_MSG_RESULT([yes])
 357   else
 358     AC_MSG_RESULT([no])
 359     MSGFMT=false
 360   fi
 361 fi
 362 WINE_WARNING_WITH(gettext,[test "$MSGFMT" = false],
 363                   [gettext tools not found (or too old), translations won't be built.])
 364
 365 dnl **** Check for some libraries ****
 366
 367 dnl Check for -li386 for NetBSD and OpenBSD
 368 AC_CHECK_LIB(i386,i386_set_ldt)
 369 dnl Check for -lossaudio for NetBSD
 370 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 371
 372 AC_SUBST(XLIB,"")
 373 AC_SUBST(OPENGL_LIBS,"")
 374
 375 dnl **** Check for header files ****
 376
 377 test "x$with_fontconfig" != "xno" || ac_cv_header_fontconfig_fontconfig_h=no
 378
 379 AC_SYS_LARGEFILE()
 380
 381 AC_CHECK_HEADERS(\
 382         AL/al.h \
 383         ApplicationServices/ApplicationServices.h \
 384         AudioToolbox/AudioConverter.h \
 385         AudioUnit/AudioUnit.h \
 386         AudioUnit/AudioComponent.h \
 387         CL/cl.h \
 388         Carbon/Carbon.h \
 389         CoreAudio/CoreAudio.h \
 390         CoreServices/CoreServices.h \
 391         DiskArbitration/DiskArbitration.h \
 392         IOKit/IOKitLib.h \
 393         IOKit/hid/IOHIDLib.h \
 394         OpenAL/al.h \
 395         OpenCL/opencl.h \
 396         QuickTime/ImageCompression.h \
 397         Security/Security.h \
 398         alias.h \
 399         alsa/asoundlib.h \
 400         arpa/inet.h \
 401         arpa/nameser.h \
 402         asm/types.h \
 403         asm/user.h \
 404         curses.h \
 405         direct.h \
 406         dirent.h \
 407         dlfcn.h \
 408         elf.h \
 409         float.h \
 410         fnmatch.h \
 411         fontconfig/fontconfig.h \
 412         getopt.h \
 413         gettext-po.h \
 414         grp.h \
 415         gsm.h \
 416         gsm/gsm.h \
 417         ieeefp.h \
 418         inet/mib2.h \
 419         io.h \
 420         kstat.h \
 421         lber.h \
 422         ldap.h \
 423         libproc.h \
 424         link.h \
 425         linux/cdrom.h \
 426         linux/compiler.h \
 427         linux/filter.h \
 428         linux/hdreg.h \
 429         linux/input.h \
 430         linux/ioctl.h \
 431         linux/joystick.h \
 432         linux/major.h \
 433         linux/param.h \
 434         linux/serial.h \
 435         linux/types.h \
 436         linux/ucdrom.h \
 437         lwp.h \
 438         mach-o/nlist.h \
 439         mach-o/loader.h \
 440         mach/mach.h \
 441         mach/machine.h \
 442         machine/cpu.h \
 443         machine/limits.h \
 444         machine/sysarch.h \
 445         mntent.h \
 446         ncurses.h \
 447         netdb.h \
 448         netinet/in.h \
 449         netinet/in_systm.h \
 450         netinet/tcp.h \
 451         netinet/tcp_fsm.h \
 452         poll.h \
 453         port.h \
 454         process.h \
 455         pthread.h \
 456         pwd.h \
 457         sched.h \
 458         scsi/scsi.h \
 459         scsi/scsi_ioctl.h \
 460         scsi/sg.h \
 461         stdbool.h \
 462         stdint.h \
 463         stropts.h \
 464         sys/asoundlib.h \
 465         sys/attr.h \
 466         sys/cdio.h \
 467         sys/elf32.h \
 468         sys/epoll.h \
 469         sys/event.h \
 470         sys/exec_elf.h \
 471         sys/filio.h \
 472         sys/inotify.h \
 473         sys/ioctl.h \
 474         sys/ipc.h \
 475         sys/limits.h \
 476         sys/link.h \
 477         sys/mman.h \
 478         sys/modem.h \
 479         sys/msg.h \
 480         sys/mtio.h \
 481         sys/param.h \
 482         sys/poll.h \
 483         sys/prctl.h \
 484         sys/protosw.h \
 485         sys/ptrace.h \
 486         sys/queue.h \
 487         sys/resource.h \
 488         sys/scsiio.h \
 489         sys/shm.h \
 490         sys/signal.h \
 491         sys/socket.h \
 492         sys/socketvar.h \
 493         sys/sockio.h \
 494         sys/statvfs.h \
 495         sys/strtio.h \
 496         sys/syscall.h \
 497         sys/tihdr.h \
 498         sys/time.h \
 499         sys/timeout.h \
 500         sys/times.h \
 501         sys/uio.h \
 502         sys/user.h \
 503         sys/utsname.h \
 504         sys/vm86.h \
 505         sys/wait.h \
 506         syscall.h \
 507         termios.h \
 508         unistd.h \
 509         utime.h \
 510         valgrind/memcheck.h \
 511         valgrind/valgrind.h \
 512         zlib.h
 513 )
 514 AC_HEADER_STAT()
 515
 516 dnl **** Checks for headers that depend on other ones ****
 517
 518 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/sysctl.h sys/user.h sys/vfs.h],,,
 519     [#include <sys/types.h>
 520      #ifdef HAVE_SYS_PARAM_H
 521      # include <sys/param.h>
 522      #endif])
 523
 524 AC_CHECK_HEADERS(\
 525         netinet/ip.h \
 526         net/if.h \
 527         net/if_arp.h \
 528         net/if_dl.h \
 529         net/if_types.h \
 530         net/route.h \
 531         netinet/if_ether.h \
 532         netinet/if_inarp.h \
 533         netinet/in_pcb.h \
 534         netinet/ip_icmp.h \
 535         netinet/ip_var.h \
 536         netinet/udp.h \
 537         netipx/ipx.h \
 538         sys/un.h \
 539 ,,,[#include <sys/types.h>
 540      #ifdef HAVE_SYS_SOCKET_H
 541      # include <sys/socket.h>
 542      #endif
 543      #ifdef HAVE_SYS_SOCKETVAR_H
 544      # include <sys/socketvar.h>
 545      #endif
 546      #ifdef HAVE_NET_ROUTE_H
 547      # include <net/route.h>
 548      #endif
 549      #ifdef HAVE_NETINET_IN_H
 550      # include <netinet/in.h>
 551      #endif
 552      #ifdef HAVE_NETINET_IN_SYSTM_H
 553      # include <netinet/in_systm.h>
 554      #endif
 555      #ifdef HAVE_NET_IF_H
 556      # include <net/if.h>
 557      #endif
 558      #ifdef HAVE_NETINET_IP_H
 559      # include <netinet/ip.h>
 560      #endif])
 561
 562 AC_CHECK_HEADERS([netinet/tcp_timer.h netinet/udp_var.h netinet/icmp_var.h netinet/tcp_var.h ],,,
 563     [#include <sys/types.h>
 564      #ifdef HAVE_ALIAS_H
 565      # include <alias.h>
 566      #endif
 567      #ifdef HAVE_SYS_SOCKET_H
 568      # include <sys/socket.h>
 569      #endif
 570      #ifdef HAVE_SYS_SOCKETVAR_H
 571      # include <sys/socketvar.h>
 572      #endif
 573      #ifdef HAVE_SYS_TIMEOUT_H
 574      # include <sys/timeout.h>
 575      #endif
 576      #ifdef HAVE_NETINET_IN_H
 577      # include <netinet/in.h>
 578      #endif
 579      #ifdef HAVE_NETINET_IN_SYSTM_H
 580      # include <netinet/in_systm.h>
 581      #endif
 582      #ifdef HAVE_NETINET_IP_H
 583      # include <netinet/ip.h>
 584      #endif
 585      #ifdef HAVE_NETINET_IP_VAR_H
 586      # include <netinet/ip_var.h>
 587      #endif
 588      #ifdef HAVE_NETINET_IP_ICMP_H
 589      # include <netinet/ip_icmp.h>
 590      #endif
 591      #ifdef HAVE_NETINET_UDP_H
 592      # include <netinet/udp.h>
 593      #endif
 594      #ifdef HAVE_NETINET_TCP_H
 595      # include <netinet/tcp.h>
 596      #endif
 597      #ifdef HAVE_NETINET_TCP_TIMER_H
 598      #include <netinet/tcp_timer.h>
 599      #endif])
 600
 601 AC_CHECK_HEADERS([linux/ipx.h linux/irda.h linux/rtnetlink.h],,,
 602     [#include <sys/types.h>
 603      #ifdef HAVE_ASM_TYPES_H
 604      # include <asm/types.h>
 605      #endif
 606      #ifdef HAVE_SYS_SOCKET_H
 607      # include <sys/socket.h>
 608      #endif
 609      #ifdef HAVE_LINUX_TYPES_H
 610      # include <linux/types.h>
 611      #endif])
 612
 613 AC_CHECK_HEADERS([mach-o/dyld_images.h],,,
 614     [#ifdef HAVE_STDBOOL_H
 615      # include <stdbool.h>
 616      #endif
 617      #ifdef HAVE_STDINT_H
 618      # include <stdint.h>
 619      #endif])
 620
 621 AC_CHECK_HEADERS([resolv.h],,,
 622     [#include <sys/types.h>
 623      #ifdef HAVE_SYS_SOCKET_H
 624      # include <sys/socket.h>
 625      #endif
 626      #ifdef HAVE_NETINET_IN_H
 627      # include <netinet/in.h>
 628      #endif
 629      #ifdef HAVE_ARPA_NAMESER_H
 630      # include <arpa/nameser.h>
 631      #endif])
 632
 633 AC_CHECK_HEADERS([ifaddrs.h],,,[#include <sys/types.h>])
 634
 635 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 636
 637 AC_CHECK_HEADERS([sys/thr.h],,,
 638 [#include <sys/types.h>
 639 #ifdef HAVE_UCONTEXT_H
 640 #include <ucontext.h>
 641 #endif])
 642
 643 AC_CHECK_HEADERS([pthread_np.h],,,
 644 [#ifdef HAVE_PTHREAD_H
 645 #include <pthread.h>
 646 #endif])
 647
 648 AC_CHECK_HEADERS([linux/videodev.h linux/videodev2.h libv4l1.h],,,
 649 [#ifdef HAVE_SYS_TIME_H
 650 #include <sys/time.h>
 651 #endif
 652 #include <sys/types.h>
 653 #ifdef HAVE_ASM_TYPES_H
 654 #include <asm/types.h>
 655 #endif])
 656
 657 AC_CHECK_HEADERS([libprocstat.h],,,
 658 [#ifdef HAVE_SYS_PARAM_H
 659 #include <sys/param.h>
 660 #endif
 661 #ifdef HAVE_SYS_QUEUE_H
 662 #include <sys/queue.h>
 663 #endif
 664 #ifdef HAVE_SYS_SOCKET_H
 665 #include <sys/socket.h>
 666 #endif])
 667
 668 dnl **** Check for working dll ****
 669
 670 AC_SUBST(dlldir,"\${libdir}/wine")
 671 AC_SUBST(DLLPREFIX,"")
 672 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 673 AC_SUBST(IMPLIBEXT,"def")
 674 AC_SUBST(LDRPATH_INSTALL,"")
 675 AC_SUBST(LDRPATH_LOCAL,"")
 676 LIBEXT="so"
 677 DLLEXT=".so"
 678 STATIC_IMPLIBEXT="def.a"
 679 WINE_PATH_SONAME_TOOLS
 680
 681 wine_binary="wine"
 682 test "x$enable_win64" != "xyes" || wine_binary="wine64"
 683
 684 AC_SUBST(LOADER_RULES,["
 685 all: $wine_binary wine-installed
 686
 687 install install-lib:: wine-installed \$(DESTDIR)\$(bindir)
 688         \$(INSTALL_PROGRAM) wine-installed \$(DESTDIR)\$(bindir)/$wine_binary
 689
 690 uninstall::
 691         \$(RM) \$(DESTDIR)\$(bindir)/$wine_binary
 692 "])
 693
 694 case $host_os in
 695   cygwin*|mingw32*)
 696     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 697     LIBEXT="dll"
 698     DLLEXT=""
 699     IMPLIBEXT="a"
 700     STATIC_IMPLIBEXT="a"
 701     dnl Disable modules that can't be used on Windows
 702     enable_iphlpapi=${enable_iphlpapi:-no}
 703     enable_kernel32=${enable_kernel32:-no}
 704     enable_msvcrt=${enable_msvcrt:-no}
 705     enable_ntdll=${enable_ntdll:-no}
 706     enable_ws2_32=${enable_ws2_32:-no}
 707     enable_loader=${enable_loader:-no}
 708     enable_server=${enable_server:-no}
 709     dnl Disable dependencies that are not useful on Windows
 710     with_x=${with_x:-no}
 711     with_pthread=${with_pthread:-no}
 712
 713     dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
 714     crtlibs=""
 715     case $host_os in
 716         mingw32*)
 717           crtlibs="-lmsvcrt"
 718           AC_SUBST(SOCKETLIBS,"-L\$(top_builddir)/dlls/ws2_32 -lws2_32") ;;
 719     esac
 720
 721     AC_SUBST(LIBWINE_RULES,["
 722 all: libwine.dll libwine.a
 723
 724 libwine.a: wine.def
 725         \$(DLLTOOL) -l \$@ -d \$(srcdir)/wine.def
 726
 727 libwine.dll: \$(OBJS) wine.def Makefile.in
 728         \$(CC) -shared \$(srcdir)/wine.def -o \$@ \$(OBJS) $crtlibs \$(EXTRALIBS)
 729
 730 install install-lib:: libwine.dll \$(DESTDIR)\$(libdir) dummy
 731         \$(INSTALL_DATA) libwine.dll \$(DESTDIR)\$(libdir)/libwine.dll
 732
 733 install install-dev:: libwine.a \$(DESTDIR)\$(libdir) dummy
 734         \$(INSTALL_DATA) libwine.a \$(DESTDIR)\$(libdir)/libwine.a
 735
 736 uninstall::
 737         -cd \$(DESTDIR)\$(libdir) && \$(RM) libwine.a libwine.dll
 738
 739 clean::
 740         \$(RM) libwine.dll version.c
 741 "])
 742     ;;
 743
 744   darwin*|macosx*)
 745     LIBEXT="dylib"
 746     DLLFLAGS="$DLLFLAGS -fPIC"
 747     LIBWINE_LDFLAGS="-multiply_defined suppress"
 748     LDRPATH_INSTALL="-Wl,-rpath,@loader_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 749     LDRPATH_LOCAL="-Wl,-rpath,@loader_path/\$(top_builddir)/libs/wine"
 750     dnl declare needed frameworks
 751     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 752     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 753     AC_SUBST(FORCEFEEDBACKLIB,"-framework ForceFeedback -framework CoreFoundation")
 754     AC_SUBST(APPLICATIONSERVICESLIB,"-framework ApplicationServices")
 755     AC_SUBST(CORESERVICESLIB,"-framework CoreServices")
 756     AC_SUBST(APPKITLIB,"-framework AppKit")
 757     LDEXECFLAGS="-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00001000,-segaddr,WINE_SHAREDHEAP,0x7f000000,-sectcreate,__TEXT,__info_plist,wine_info.plist"
 758     case $host_os in
 759       darwin11*) LDEXECFLAGS="-Wl,-macosx_version_min,10.6 $LDEXECFLAGS" ;;
 760     esac
 761     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 762     then
 763         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 764         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 765     fi
 766     if test "$ac_cv_header_Security_Security_h" = "yes"
 767     then
 768         AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 769         dnl Check for the SSLCopyPeerCertificates function
 770         ac_save_LIBS="$LIBS"
 771         LIBS="$LIBS $SECURITYLIB"
 772         AC_CHECK_FUNCS(SSLCopyPeerCertificates)
 773         LIBS="$ac_save_LIBS"
 774         with_gnutls=${with_gnutls:-no}
 775     fi
 776     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 777     then
 778         if test "$ac_cv_header_AudioUnit_AudioComponent_h" = "yes"
 779         then
 780             AC_SUBST(COREAUDIO,"-framework CoreFoundation -framework CoreAudio -framework AudioUnit -framework AudioToolbox -framework CoreMIDI")
 781         else
 782             dnl CoreServices needed by AudioUnit
 783             AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 784         fi
 785         dnl Check for the AUGraphAddNode function
 786         ac_save_LIBS="$LIBS"
 787         LIBS="$LIBS $COREAUDIO"
 788         AC_CHECK_FUNCS(AUGraphAddNode)
 789         LIBS="$ac_save_LIBS"
 790     fi
 791     if test "$ac_cv_header_OpenAL_al_h" = "yes"
 792     then
 793         AC_SUBST(FRAMEWORK_OPENAL,"-framework OpenAL")
 794         AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])
 795         ac_cv_lib_openal=yes
 796     fi
 797     if test "$ac_cv_header_OpenCL_opencl_h" = "yes"
 798     then
 799         AC_SUBST(LIBOPENCL,"-framework OpenCL")
 800         ac_cv_lib_OpenCL_clGetPlatformInfo=yes
 801     fi
 802     if test "$ac_cv_header_IOKit_hid_IOHIDLib_h" = "yes"
 803     then
 804         ac_save_LIBS="$LIBS"
 805         LIBS="$LIBS $IOKITLIB"
 806         AC_CHECK_FUNCS(IOHIDManagerCreate)
 807         LIBS="$ac_save_LIBS"
 808     fi
 809     if test "$ac_cv_header_QuickTime_ImageCompression_h" = "yes"
 810     then
 811         AC_SUBST(QUICKTIMELIB,"-framework QuickTime -framework ApplicationServices -framework CoreVideo")
 812         enable_wineqtdecoder=${enable_wineqtdecoder:-yes}
 813     else
 814         WINE_NOTICE([QuickTime ${notice_platform}development files not found, video decoding won't be supported.])
 815     fi
 816     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 817     then
 818         AC_SUBST(CARBONLIB,"-framework Carbon")
 819     fi
 820
 821     dnl Enable Mac driver on Mac OS X 10.6 or later
 822     if test "$ac_cv_header_ApplicationServices_ApplicationServices_h" = "yes"
 823     then
 824         ac_save_LIBS="$LIBS"
 825         LIBS="$LIBS $APPLICATIONSERVICESLIB"
 826         AC_CHECK_FUNC(CGDisplayModeGetWidth,enable_winemac_drv=${enable_winemac_drv:-yes})
 827         LIBS="$ac_save_LIBS"
 828     fi
 829
 830     dnl Check for Xcode 3.x broken 16-bit support
 831     if test "x$enable_win16" = "xyes"
 832     then
 833         AC_MSG_CHECKING([whether 16-bit code can be built correctly])
 834         AC_RUN_IFELSE([AC_LANG_PROGRAM([[asm(".text\n"
 835                                             "bad:\tnop;nop\n"
 836                                             "good:\tnop;nop\n\t"
 837                                             ".globl _testfunc\n"
 838                                             "_testfunc:\tcallw good");
 839                                         extern void testfunc();]],
 840                                       [[unsigned short *p = (unsigned short *)testfunc;
 841                                         return p[0] != 0xe866 || p[1] != 0xfffa]])],
 842                                       AC_MSG_RESULT(yes),
 843                                       [AC_MSG_RESULT(no)
 844                                        AC_MSG_ERROR([Xcode 3.x cannot build 16-bit code correctly. Use --disable-win16 if you don't need 16-bit support.])],
 845                                        AC_MSG_RESULT([[cross-compiling, assuming yes]]))
 846     fi
 847
 848     AC_SUBST(LIBWINE_RULES,["
 849 all: libwine.dylib
 850
 851 libwine.\$(VERSION).dylib: \$(OBJS) \$(RELPATH) Makefile.in
 852         \$(CC) -dynamiclib -install_name @rpath/libwine.\$(SOVERSION).dylib -Wl,-rpath,@loader_path/ -compatibility_version \$(SOVERSION) -current_version \$(VERSION) \$(OBJS) \$(EXTRALIBS) \$(LDFLAGS) \$(LIBS) -o \$@
 853
 854 libwine.\$(SOVERSION).dylib: libwine.\$(VERSION).dylib
 855         \$(RM) \$@ && \$(LN_S) libwine.\$(VERSION).dylib \$@
 856
 857 libwine.dylib: libwine.\$(SOVERSION).dylib
 858         \$(RM) \$@ && \$(LN_S) libwine.\$(SOVERSION).dylib \$@
 859
 860 install install-lib:: libwine.\$(VERSION).dylib \$(DESTDIR)\$(libdir) dummy
 861         \$(INSTALL_PROGRAM) libwine.\$(VERSION).dylib \$(DESTDIR)\$(libdir)/libwine.\$(VERSION).dylib
 862         cd \$(DESTDIR)\$(libdir) && \$(RM) libwine.\$(SOVERSION).dylib && \$(LN_S) libwine.\$(VERSION).dylib libwine.\$(SOVERSION).dylib
 863
 864 install install-dev:: \$(DESTDIR)\$(libdir) dummy
 865         cd \$(DESTDIR)\$(libdir) && \$(RM) libwine.dylib && \$(LN_S) libwine.\$(VERSION).dylib libwine.dylib
 866
 867 uninstall::
 868         -cd \$(DESTDIR)\$(libdir) && \$(RM) libwine.dylib libwine.\$(VERSION).dylib libwine.\$(SOVERSION).dylib
 869
 870 clean::
 871         \$(RM) libwine.dylib libwine.\$(VERSION).dylib libwine.\$(SOVERSION).dylib version.c
 872 "])
 873
 874     AS_VAR_APPEND([LOADER_RULES],["
 875 $wine_binary: main.o Makefile.in wine_info.plist
 876         \$(CC) -o \$@ $LDEXECFLAGS main.o \$(LIBWINE) \$(LIBPORT) \$(EXTRALIBS) \$(LDFLAGS) \$(LDRPATH_LOCAL)
 877
 878 wine-installed: main.o Makefile.in wine_info.plist
 879         \$(CC) -o \$@ $LDEXECFLAGS main.o \$(LIBWINE) \$(LIBPORT) \$(EXTRALIBS) \$(LDFLAGS) \$(LDRPATH_INSTALL)
 880
 881 wine_info.plist: wine_info.plist.in \$(top_builddir)/include/config.h
 882         LC_ALL=C sed -e 's,@PACKAGE_VERSION@,$PACKAGE_VERSION,g' \$(srcdir)/wine_info.plist.in >\$@ || (\$(RM) \$@ && false)
 883 "])
 884     ;;
 885
 886   linux-android*)
 887     DLLFLAGS="$DLLFLAGS -fPIC"
 888     DLLPREFIX="lib"
 889     LDEXECFLAGS=""
 890     dlldir="\${libdir}"
 891     WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 892                     [LDEXECFLAGS="-Wl,--export-dynamic"])
 893     WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 894                     [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 895                      LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"],
 896         [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 897                          [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 898                           LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"])])
 899
 900     WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 901                     [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 902
 903     case $host_cpu in
 904       *i[[3456789]]86* | x86_64)
 905         WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 906                         [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 907         ;;
 908     esac
 909
 910     AC_SUBST(LIBWINE_RULES,["
 911 all: libwine.so
 912
 913 libwine.so: \$(OBJS) Makefile.in
 914         \$(CC) -shared \$(OBJS) \$(EXTRALIBS) \$(LDFLAGS) \$(LIBS) -o \$@
 915
 916 install install-lib:: libwine.so \$(DESTDIR)\$(libdir) dummy
 917         \$(INSTALL_PROGRAM) libwine.so \$(DESTDIR)\$(libdir)/libwine.so
 918
 919 uninstall::
 920         \$(RM) \$(DESTDIR)\$(libdir)/libwine.so
 921
 922 clean::
 923         \$(RM) libwine.so version.c
 924 "])
 925
 926     AS_VAR_APPEND([LOADER_RULES],["
 927 $wine_binary: main.o Makefile.in
 928         \$(CC) -o \$@ $LDEXECFLAGS main.o \$(LIBWINE) \$(LIBPORT) \$(EXTRALIBS) \$(LDFLAGS) \$(LDRPATH_LOCAL)
 929
 930 wine-installed: main.o Makefile.in
 931         \$(CC) -o \$@ $LDEXECFLAGS main.o \$(LIBWINE) \$(LIBPORT) \$(EXTRALIBS) \$(LDFLAGS) \$(LDRPATH_INSTALL)
 932 "])
 933     ;;
 934
 935   *)
 936     DLLFLAGS="$DLLFLAGS -fPIC"
 937     LDEXECFLAGS=""
 938     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 939         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 940                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 941     if test "$ac_cv_c_dll_gnuelf" = "yes"
 942     then
 943       LDSHARED="\$(CC) -shared"
 944       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 945                       [LDSHARED="\$(CC) -shared -Wl,-soname,libwine.so.\$(SOVERSION)"],
 946                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 947                                        [LDSHARED="\$(CC) -shared -Wl,-h,libwine.so.\$(SOVERSION)"])])
 948
 949       echo '{ global: *; };' >conftest.map
 950       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 951                       [LDSHARED="$LDSHARED -Wl,--version-script=\$(srcdir)/wine.map"])
 952       rm -f conftest.map
 953
 954       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 955                       [LDEXECFLAGS="-Wl,--export-dynamic"])
 956
 957       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 958                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 959                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"],
 960           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 961                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 962                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"])])
 963
 964       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 965                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 966
 967       case $host_cpu in
 968         *i[[3456789]]86* | x86_64)
 969           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 970                           [case $host_os in
 971                            freebsd* | kfreebsd*-gnu) LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x60000400" ;;
 972                            *) LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400" ;;
 973                            esac
 974                           ])
 975           AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 976           if test "x$PRELINK" = xfalse
 977           then
 978               WINE_WARNING([prelink not found, base address of core dlls won't be set correctly.])
 979           fi
 980           ;;
 981       esac
 982
 983     else
 984       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 985           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 986                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 987       if test "$ac_cv_c_dll_unixware" = "yes"
 988       then
 989         LDSHARED="\$(CC) -Wl,-G,-h,libwine.so.\$(SOVERSION)"
 990       fi
 991     fi
 992     AC_SUBST(LIBWINE_RULES,["
 993 all: libwine.so
 994
 995 libwine.so.\$(VERSION): \$(OBJS) wine.map Makefile.in
 996         $LDSHARED \$(OBJS) \$(EXTRALIBS) \$(LDFLAGS) \$(LIBS) -o \$@
 997
 998 libwine.so.\$(SOVERSION): libwine.so.\$(VERSION)
 999         \$(RM) \$@ && \$(LN_S) libwine.so.\$(VERSION) \$@
1000
1001 libwine.so: libwine.so.\$(SOVERSION)
1002         \$(RM) \$@ && \$(LN_S) libwine.so.\$(SOVERSION) \$@
1003
1004 install install-lib:: libwine.so.\$(VERSION) \$(DESTDIR)\$(libdir) dummy
1005         \$(INSTALL_PROGRAM) libwine.so.\$(VERSION) \$(DESTDIR)\$(libdir)/libwine.so.\$(VERSION)
1006         cd \$(DESTDIR)\$(libdir) && \$(RM) libwine.so.\$(SOVERSION) && \$(LN_S) libwine.so.\$(VERSION) libwine.so.\$(SOVERSION)
1007
1008 install install-dev:: \$(DESTDIR)\$(libdir) dummy
1009         cd \$(DESTDIR)\$(libdir) && \$(RM) libwine.so && \$(LN_S) libwine.so.\$(VERSION) libwine.so
1010
1011 uninstall::
1012         -cd \$(DESTDIR)\$(libdir) && \$(RM) libwine.so libwine.so.\$(VERSION) libwine.so.\$(SOVERSION)
1013
1014 clean::
1015         \$(RM) libwine.so.\$(SOVERSION) libwine.so.\$(VERSION) version.c
1016 "])
1017
1018     AS_VAR_APPEND([LOADER_RULES],["
1019 $wine_binary: main.o Makefile.in
1020         \$(CC) -o \$@ $LDEXECFLAGS main.o \$(LIBWINE) \$(LIBPORT) \$(EXTRALIBS) \$(LDFLAGS) \$(LDRPATH_LOCAL)
1021
1022 wine-installed: main.o Makefile.in
1023         \$(CC) -o \$@ $LDEXECFLAGS main.o \$(LIBWINE) \$(LIBPORT) \$(EXTRALIBS) \$(LDFLAGS) \$(LDRPATH_INSTALL)
1024 "])
1025     ;;
1026 esac
1027
1028 enable_wineqtdecoder=${enable_wineqtdecoder:-no}
1029 enable_winemac_drv=${enable_winemac_drv:-no}
1030
1031 dnl Check for cross compiler to build test programs
1032 AC_SUBST(CROSSTARGET,"")
1033 if test "$cross_compiling" = "no" -a "x$enable_tests" != xno -a "$LIBEXT" != "dll"
1034 then
1035     WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
1036     if test "$CROSSCC" != "false"
1037     then
1038         ac_save_CC="$CC"
1039         CC="$CROSSCC"
1040         AC_MSG_CHECKING([whether $CROSSCC works])
1041         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
1042                           [AC_MSG_RESULT([yes])
1043                            set x $CROSSCC
1044                            shift
1045                            while test $# -ge 1
1046                            do
1047                                case "$1" in
1048                                  *-gcc) CROSSTARGET=`expr "$1" : '\(.*\)-gcc'` ;;
1049                                esac
1050                                shift
1051                            done],
1052                           [AC_MSG_RESULT([no])])
1053         CC="$ac_save_CC"
1054     fi
1055 fi
1056
1057 dnl **** Check for pthread ****
1058
1059 if test "$ac_cv_header_pthread_h" = "yes"
1060 then
1061     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,[AC_SUBST(LIBPTHREAD,"-lpthread")])])
1062 fi
1063 WINE_ERROR_WITH(pthread,[test "x$ac_cv_func_pthread_create" != xyes -a "x$LIBPTHREAD" = x],
1064 [pthread ${notice_platform}development files not found.
1065 Wine cannot support threads without libpthread.])
1066
1067 dnl **** Check for X11 ****
1068
1069 AC_PATH_XTRA
1070
1071 if test "$have_x" = "yes"
1072 then
1073     XLIB="-lX11"
1074     ac_save_CPPFLAGS="$CPPFLAGS"
1075     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1076
1077     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
1078     WINE_CHECK_SONAME(Xext,XextCreateExtension,[XLIB="-lXext $XLIB"],,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1079
1080     dnl *** All of the following tests require X11/Xlib.h
1081     AC_CHECK_HEADERS([X11/Xlib.h \
1082                       X11/XKBlib.h \
1083                       X11/Xutil.h \
1084                       X11/Xcursor/Xcursor.h \
1085                       X11/extensions/shape.h \
1086                       X11/extensions/XInput.h \
1087                       X11/extensions/XInput2.h \
1088                       X11/extensions/XShm.h \
1089                       X11/extensions/Xcomposite.h \
1090                       X11/extensions/Xinerama.h \
1091                       X11/extensions/Xrandr.h \
1092                       X11/extensions/Xrender.h \
1093                       X11/extensions/xf86vmode.h \
1094                       X11/extensions/xf86vmproto.h],,,
1095 [#ifdef HAVE_X11_XLIB_H
1096 # include <X11/Xlib.h>
1097 #endif
1098 #ifdef HAVE_X11_XUTIL_H
1099 # include <X11/Xutil.h>
1100 #endif])
1101
1102         dnl *** Check for X keyboard extension
1103         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
1104         then
1105               AC_CHECK_LIB(X11, XkbQueryExtension,
1106               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
1107               $X_LIBS $XLIB $X_EXTRA_LIBS)
1108         fi
1109
1110         dnl *** Check for X cursor
1111         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
1112         then
1113             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1114         fi
1115         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
1116                          [libxcursor ${notice_platform}development files not found, the Xcursor extension won't be supported.])
1117
1118         dnl *** Check for X input extension
1119         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
1120         then
1121             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1122         fi
1123         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
1124                          [libxi ${notice_platform}development files not found, the Xinput extension won't be supported.])
1125
1126         dnl *** Check for X input 2 extension
1127         if test "x$ac_cv_lib_soname_Xi" != x
1128         then
1129             WINE_NOTICE_WITH(xinput2,[test "$ac_cv_header_X11_extensions_XInput2_h" != "yes"],
1130                              [XInput2 headers not found, the XInput 2 extension won't be supported.])
1131         fi
1132
1133         dnl *** Check for X Shm extension
1134         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
1135         then
1136               AC_CHECK_LIB(Xext, XShmQueryExtension,
1137               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
1138               $X_LIBS $XLIB $X_EXTRA_LIBS)
1139         fi
1140         WINE_NOTICE_WITH(xshm,[test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],
1141                          [XShm ${notice_platform}development files not found, X Shared Memory won't be supported.])
1142
1143         dnl *** Check for X shape extension
1144         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
1145         then
1146               AC_CHECK_LIB(Xext,XShapeQueryExtension,
1147               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
1148               $X_LIBS $XLIB $X_EXTRA_LIBS)
1149         fi
1150         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
1151                          [XShape ${notice_platform}development files not found, XShape won't be supported.])
1152
1153         dnl *** Check for XFree86 VMODE extension
1154         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes" -o "$ac_cv_header_X11_extensions_xf86vmproto_h" = "yes"
1155         then
1156             WINE_CHECK_SONAME(Xxf86vm,XF86VidModeQueryExtension,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1157         fi
1158         WINE_NOTICE_WITH(xxf86vm,[test "x$ac_cv_lib_soname_Xxf86vm" = "x"],
1159                          [libXxf86vm ${notice_platform}development files not found, XFree86 Vidmode won't be supported.])
1160
1161         dnl *** Check for Transform functions in Xrender
1162         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
1163         then
1164             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
1165               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
1166                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
1167                  [Define if Xrender has the XRenderSetPictureTransform function])],,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1168                AC_CHECK_LIB(Xrender,XRenderCreateLinearGradient,
1169                 [AC_DEFINE(HAVE_XRENDERCREATELINEARGRADIENT, 1,
1170                  [Define if Xrender has the XRenderCreateLinearGradient function])],,[$X_LIBS $XLIB $X_EXTRA_LIBS])],,
1171               [$X_LIBS $XLIB $X_EXTRA_LIBS])
1172
1173         fi
1174         WINE_WARNING_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
1175                          [libxrender ${notice_platform}development files not found, XRender won't be supported.])
1176
1177         dnl *** Check for X RandR extension
1178         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
1179         then
1180                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1181 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func; if (func) return 0;]])],
1182                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,
1183                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1184 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRGetScreenResources) *f; if (f) return 0;]])],
1185                       [AC_DEFINE(HAVE_XRRGETSCREENRESOURCES, 1,
1186                         [Define if Xrandr has the XRRGetScreenResources function])])],,
1187                     [$X_LIBS $XLIB $X_EXTRA_LIBS])])
1188         fi
1189         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
1190                          [libxrandr ${notice_platform}development files not found, XRandr won't be supported.])
1191
1192         dnl *** Check for Xinerama extension
1193         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
1194         then
1195                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1196 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func; if (func) return 0;]])],
1197                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])])
1198         fi
1199         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
1200                          [libxinerama ${notice_platform}development files not found, multi-monitor setups won't be supported.])
1201
1202         dnl *** Check for X Composite extension
1203         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
1204         then
1205             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1206         fi
1207         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
1208                          [libxcomposite ${notice_platform}development files not found, Xcomposite won't be supported.])
1209
1210         dnl *** Check for XICCallback struct
1211         AC_CHECK_MEMBERS([XICCallback.callback, XEvent.xcookie],,,
1212 [#ifdef HAVE_X11_XLIB_H
1213 #include <X11/Xlib.h>
1214 #endif])
1215
1216     dnl *** End of X11/Xlib.h check
1217
1218     dnl Check for the presence of OpenGL
1219     opengl_msg=""
1220     if test "x$with_opengl" != "xno"
1221     then
1222         WINE_CHECK_SONAME(GL,glXCreateContext,
1223                      [OPENGL_LIBS="-lGL"],
1224                      [WINE_CHECK_SONAME(GL,glXCreateContext,
1225                             [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"],
1226                             [if test -f /usr/X11R6/lib/libGL.a
1227                             then
1228                                 opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
1229 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
1230                             else
1231                                 opengl_msg="No OpenGL library found on this system."
1232                             fi],
1233                             $X_LIBS $XLIB -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
1234                      $X_LIBS $XLIB -lm $X_EXTRA_LIBS)
1235         if test "x$with_glu" != "xno"
1236         then
1237             AC_CHECK_LIB(GLU,gluLookAt,[:],,[$OPENGL_LIBS $X_LIBS $XLIB -lm $X_EXTRA_LIBS])
1238             WINE_NOTICE_WITH(glu,[test "x$ac_cv_lib_GLU_gluLookAt" != xyes],
1239                              [libGLU ${notice_platform}development files not found, GLU won't be supported.])
1240         fi
1241
1242         if test "x$with_osmesa" != "xno"
1243         then
1244             WINE_CHECK_SONAME(OSMesa,glAccum,,,[$X_LIBS $XLIB -lm $X_EXTRA_LIBS])
1245             WINE_NOTICE_WITH(osmesa,[test "x$ac_cv_lib_soname_OSMesa" = "x"],
1246                              [libOSMesa ${notice_platform}development files not found (or too old), OpenGL rendering in bitmaps won't be supported.])
1247         fi
1248     fi
1249     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
1250 OpenGL and Direct3D won't be supported.])
1251
1252     CPPFLAGS="$ac_save_CPPFLAGS"
1253 else
1254     XLIB=""
1255     X_CFLAGS=""
1256     X_LIBS=""
1257     enable_winex11_drv=${enable_winex11_drv:-no}
1258 fi
1259 WINE_ERROR_WITH(x,[test "x$XLIB" = "x"],[X ${notice_platform}development files not found. Wine will be built
1260 without X support, which probably isn't what you want. You will need
1261 to install ${notice_platform}development packages of Xlib/Xfree86 at the very least.])
1262
1263 test "x$ac_cv_lib_GLU_gluLookAt" != xyes && enable_glu32=${enable_glu32:-no}
1264
1265 dnl **** Check for OpenCL ****
1266 if test "$ac_cv_header_CL_cl_h" = "yes"
1267 then
1268     AC_CHECK_LIB(OpenCL,clGetPlatformInfo,[AC_SUBST(LIBOPENCL,["-lOpenCL"])])
1269 fi
1270 WINE_NOTICE_WITH(opencl,[test "x$ac_cv_lib_OpenCL_clGetPlatformInfo" != xyes],
1271                  [OpenCL ${notice_platform}development files not found, OpenCL won't be supported.])
1272 test "x$ac_cv_lib_OpenCL_clGetPlatformInfo" != xyes && enable_opencl=${enable_opencl:-no}
1273
1274 dnl **** Check for libxml2 ****
1275
1276 if test "x$with_xml" != "xno"
1277 then
1278     WINE_PACKAGE_FLAGS(XML2,[libxml-2.0],[-lxml2],
1279                        [`xml2-config --cflags 2>/dev/null`],[`xml2-config --libs 2>/dev/null`],
1280         [AC_CHECK_HEADERS([libxml/parser.h libxml/xmlsave.h libxml/SAX2.h])
1281         if test "$ac_cv_header_libxml_parser_h" = "yes" -a "$ac_cv_header_libxml_xmlsave_h" = "yes" -a "$ac_cv_header_libxml_SAX2_h" = "yes"
1282         then
1283             AC_CHECK_LIB(xml2, xmlParseMemory,
1284                 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])],[XML2_LIBS=""],[$XML2_LIBS])
1285             AC_CHECK_LIB(xml2, xmlReadMemory,
1286                 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,[$XML2_LIBS])
1287             AC_CHECK_LIB(xml2, xmlNewDocPI,
1288                 [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,[$XML2_LIBS])
1289             AC_CHECK_LIB(xml2, xmlSchemaSetParserStructuredErrors,
1290                 [AC_DEFINE(HAVE_XMLSCHEMASSETPARSERSTRUCTUREDERRORS,1,[Define if libxml2 has the xmlSchemaSetParserStructuredErrors function])],,[$XML2_LIBS])
1291             AC_CHECK_LIB(xml2, xmlSchemaSetValidStructuredErrors,
1292                 [AC_DEFINE(HAVE_XMLSCHEMASSETVALIDSTRUCTUREDERRORS,1,[Define if libxml2 has the xmlSchemaSetValidStructuredErrors function])],,[$XML2_LIBS])
1293             AC_CHECK_LIB(xml2, xmlFirstElementChild,
1294                 [AC_DEFINE(HAVE_XMLFIRSTELEMENTCHILD,1,[Define if libxml2 has the xmlFirstElementChild function])],,[$XML2_LIBS])
1295             AC_CHECK_TYPE([xmlDocProperties],
1296                 [AC_DEFINE(HAVE_XMLDOC_PROPERTIES,1,[Define if libxml2 has the xmlDocProperties enum])],,[[#include <libxml/tree.h>]])
1297         else
1298             XML2_CFLAGS=""
1299             XML2_LIBS=""
1300         fi])
1301 fi
1302 WINE_WARNING_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
1303                  [libxml2 ${notice_platform}development files not found (or too old), XML won't be supported.])
1304
1305 if test "x$with_xslt" != "xno"
1306 then
1307     WINE_PACKAGE_FLAGS(XSLT,[libxslt],[-lxml2],
1308                        [`xslt-config --cflags 2>/dev/null`],[`xslt-config --libs 2>/dev/null`],
1309         [AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],,,
1310         [#ifdef HAVE_LIBXSLT_PATTERN_H
1311 # include <libxslt/pattern.h>
1312 #endif])
1313         if test "$ac_cv_header_libxslt_transform_h" = "yes"
1314         then
1315             WINE_CHECK_SONAME(xslt,xsltCompilePattern,,,[$XSLT_LIBS])
1316         else
1317             XSLT_CFLAGS=""
1318         fi])
1319 fi
1320 WINE_WARNING_WITH(xslt,[test "x$ac_cv_lib_soname_xslt" = "x"],
1321                  [libxslt ${notice_platform}development files not found, xslt won't be supported.])
1322
1323 dnl **** Check for libdbus ****
1324 if test "x$with_dbus" != "xno"
1325 then
1326     WINE_PACKAGE_FLAGS(DBUS,[dbus-1],,,,
1327         [AC_CHECK_HEADER([dbus/dbus.h],
1328             [WINE_CHECK_SONAME(dbus-1, dbus_connection_close,,[DBUS_CFLAGS=""],[$DBUS_LIBS])],
1329             [DBUS_CFLAGS=""])])
1330 fi
1331 WINE_NOTICE_WITH(dbus,[test "x$ac_cv_lib_soname_dbus_1" = "x" -a \
1332                             "x$ac_cv_header_DiskArbitration_DiskArbitration_h" != "xyes"],
1333                  [libdbus ${notice_platform}development files not found, no dynamic device support.])
1334
1335 dnl **** Check for libhal ****
1336 if test "x$with_hal" != "xno" -a "x$ac_cv_lib_soname_dbus_1" != x
1337 then
1338     WINE_PACKAGE_FLAGS(HAL,[hal],[-ldbus-1],,,
1339         [AC_CHECK_HEADER([hal/libhal.h],
1340             [WINE_CHECK_SONAME(hal, libhal_ctx_new,,[HAL_CFLAGS=""],[$HAL_LIBS])],
1341             [HAL_CFLAGS=""])])
1342     WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x" -a \
1343                                "x$ac_cv_header_DiskArbitration_DiskArbitration_h" != "xyes"],
1344                      [libhal ${notice_platform}development files not found, no legacy dynamic device support.])
1345 fi
1346
1347 dnl **** Check for libgnutls ****
1348 if test "x$with_gnutls" != "xno"
1349 then
1350     WINE_PACKAGE_FLAGS(GNUTLS,[gnutls],,,,
1351         [AC_CHECK_HEADER(gnutls/gnutls.h,
1352             [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>
1353 #include <gnutls/crypto.h>]], [[static typeof(gnutls_mac_get_key_size) *func; if (func) return 0;]])],
1354                 [WINE_CHECK_SONAME(gnutls,gnutls_global_init,,[GNUTLS_CFLAGS=""],[$GNUTLS_LIBS])])],
1355             [GNUTLS_CFLAGS=""])])
1356 fi
1357 WINE_NOTICE_WITH(gnutls,[test "x$ac_cv_lib_soname_gnutls" = "x"],
1358                  [libgnutls ${notice_platform}development files not found, no schannel support.])
1359
1360 dnl **** Check which curses lib to use ***
1361 CURSESLIBS=""
1362 if test "$ac_cv_header_ncurses_h" = "yes"
1363 then
1364     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
1365 elif test "$ac_cv_header_curses_h" = "yes"
1366 then
1367     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
1368 fi
1369 ac_save_LIBS="$LIBS"
1370 LIBS="$LIBS $CURSESLIBS"
1371 AC_CHECK_FUNCS(mousemask)
1372 LIBS="$ac_save_LIBS"
1373 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
1374                  [lib(n)curses ${notice_platform}development files not found, curses won't be supported.])
1375
1376 dnl **** Check for SANE ****
1377 if test "x$with_sane" != "xno"
1378 then
1379     WINE_PACKAGE_FLAGS(SANE,[libsane],,[`sane-config --cflags 2>/dev/null`],[`sane-config --ldflags 2>/dev/null`],
1380         [AC_CHECK_HEADER(sane/sane.h,
1381             [WINE_CHECK_SONAME(sane,sane_init,,[SANE_CFLAGS=""],[$SANE_LIBS])],
1382             [SANE_CFLAGS=""])])
1383 fi
1384 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
1385                  [libsane ${notice_platform}development files not found, scanners won't be supported.])
1386
1387 dnl **** Check for libv4l1 ****
1388 if test "x$with_v4l" != "xno"
1389 then
1390     WINE_CHECK_SONAME(v4l1,v4l1_open,,,)
1391 fi
1392 WINE_NOTICE_WITH(v4l,[test "x$ac_cv_lib_soname_v4l1" = "x"],
1393                  [libv4l ${notice_platform}development files not found.])
1394
1395 dnl **** Check for libgphoto2 ****
1396 if test "x$with_gphoto" != "xno"
1397 then
1398     WINE_PACKAGE_FLAGS(GPHOTO2,[libgphoto2],[-lgphoto2],
1399                        [`gphoto2-config --cflags 2>/dev/null`],[`gphoto2-config --libs 2>/dev/null`],
1400         [AC_CHECK_HEADER(gphoto2-camera.h,
1401                         [AC_CHECK_LIB(gphoto2,gp_camera_new,
1402                                       [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have the libgphoto2 development environment])],
1403                                       [GPHOTO2_LIBS=""; GPHOTO2_CFLAGS=""],
1404                                       [$GPHOTO2_LIBS])],
1405                         [GPHOTO2_LIBS=""; GPHOTO2_CFLAGS=""])])
1406     WINE_PACKAGE_FLAGS(GPHOTO2_PORT,[libgphoto2_port],[-lgphoto2_port],
1407                        [`gphoto2-port-config --cflags 2>/dev/null`],
1408                        [`gphoto2-port-config --libs 2>/dev/null`],
1409         [AC_CHECK_HEADER(gphoto2-port.h,
1410                         [AC_CHECK_LIB(gphoto2_port,gp_port_info_list_new,
1411                                       [AC_DEFINE(HAVE_GPHOTO2_PORT, 1, [Define if we have the libgphoto2_port development environment])],
1412                                       [GPHOTO2_PORT_LIBS=""; GPHOTO2_PORT_CFLAGS=""],
1413                                       [$GPHOTO2_PORT_LIBS])],
1414                         [GPHOTO2_PORT_LIBS=""; GPHOTO2_PORT_CFLAGS=""])])
1415 fi
1416 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
1417                  [libgphoto2 ${notice_platform}development files not found, digital cameras won't be supported.])
1418 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_port_gp_port_info_list_new" != "yes"],
1419                  [libgphoto2_port ${notice_platform}development files not found, digital cameras won't be auto-detected.])
1420
1421
1422 dnl **** Check for resolver library ***
1423 if test "$ac_cv_header_resolv_h" = "yes"
1424 then
1425     ac_save_LIBS="$LIBS"
1426     for lib in '' -lresolv
1427     do
1428       LIBS="$lib $ac_save_LIBS"
1429       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_NETINET_IN_H
1430 #include <netinet/in.h>
1431 #endif
1432 #include <resolv.h>]],[[res_query("foo",ns_c_in,0,0,0);]])],
1433         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
1434          AC_SUBST(RESOLVLIBS,"$lib")])
1435       if test "${RESOLVLIBS+set}" = set; then
1436         break
1437       fi
1438     done
1439     LIBS="$ac_save_LIBS"
1440 fi
1441
1442 dnl **** Check for LittleCMS ***
1443 if test "x$with_lcms2" != "xno"
1444 then
1445     WINE_PACKAGE_FLAGS(LCMS2,[lcms2],[-llcms2],,,
1446         [AC_CHECK_HEADERS([lcms2.h])
1447         if test "$ac_cv_header_lcms2_h" = "yes"
1448         then
1449             AC_CHECK_LIB(lcms2, cmsOpenProfileFromFile,
1450                 [AC_DEFINE(HAVE_LCMS2, 1, [Define if you have the LittleCMS development environment])],[LCMS2_LIBS=""])
1451         else
1452             LCMS2_CFLAGS=""
1453             LCMS2_LIBS=""
1454         fi])
1455 fi
1456 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms2_cmsOpenProfileFromFile" != "yes"],
1457                  [liblcms2 ${notice_platform}development files not found, Color Management won't be supported.])
1458
1459 dnl **** Check for FreeType 2 ****
1460 if test "x$with_freetype" != "xno"
1461 then
1462     WINE_PACKAGE_FLAGS(FREETYPE,[freetype2],[-lfreetype],
1463                        [`(freetype-config --cflags || freetype2-config --cflags) 2>/dev/null`],
1464                        [`(freetype-config --libs || freetype2-config --libs) 2>/dev/null`],
1465         [WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$FREETYPE_LIBS])
1466         if test "$ft_lib" = "yes"
1467         then
1468         AC_CHECK_HEADERS(ft2build.h \
1469                              freetype/freetype.h \
1470                              freetype/ftglyph.h \
1471                              freetype/fttypes.h \
1472                              freetype/tttables.h \
1473                              freetype/ftsnames.h \
1474                              freetype/ttnameid.h \
1475                              freetype/ftoutln.h \
1476                              freetype/ftwinfnt.h \
1477                              freetype/ftmodapi.h \
1478                              freetype/ftlcdfil.h,,,
1479                              [#ifdef HAVE_FT2BUILD_H
1480 # include <ft2build.h>
1481 #endif])
1482         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
1483 #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
1484               [Define if you have the <freetype/fttrigon.h> header file.])
1485                         wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
1486             AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
1487         dnl Check that we have at least freetype/freetype.h
1488         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
1489         then
1490             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
1491             else
1492                 FREETYPE_LIBS=""
1493         fi
1494         else
1495             FREETYPE_LIBS=""
1496         fi])
1497 fi
1498 WINE_ERROR_WITH(freetype,[test "x$ac_cv_header_freetype_freetype_h" != xyes -o "x$wine_cv_fttrigon" != xyes],
1499                 [FreeType ${notice_platform}development files not found. Fonts will not be built.])
1500 test "x$ac_cv_header_freetype_freetype_h" = xyes -a "x$wine_cv_fttrigon" = xyes || enable_fonts=${enable_fonts:-no}
1501
1502 dnl **** Check for parport (currently Linux only) ****
1503 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1504  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_SYS_IOCTL_H
1505 # include <sys/ioctl.h>
1506 #endif
1507 #include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1508     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1509 if test "$ac_cv_c_ppdev" = "yes"
1510 then
1511     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1512 fi
1513
1514 dnl **** Check for pthread functions ****
1515 WINE_CHECK_LIB_FUNCS(\
1516         pthread_attr_get_np \
1517         pthread_getattr_np \
1518         pthread_getthreadid_np \
1519         pthread_get_stackaddr_np \
1520         pthread_get_stacksize_np,
1521         [$LIBPTHREAD])
1522
1523 dnl **** Check for zlib ****
1524 if test "$ac_cv_header_zlib_h" = "yes"
1525 then
1526     AC_CHECK_LIB(z,inflate,[AC_DEFINE(HAVE_ZLIB,1,[Define to 1 if you have the `z' library (-lz).])
1527                             AC_SUBST(ZLIB,"-lz")])
1528 fi
1529 WINE_NOTICE_WITH(zlib,[test "x$ZLIB" = "x"],[libz ${notice_platform}development files not found, data compression won't be supported.])
1530
1531 dnl **** Check for gettextpo ****
1532 if test "x$enable_tools" != xno
1533 then
1534     if test "$ac_cv_header_gettext_po_h" = "yes"
1535     then
1536         AC_CHECK_LIB(gettextpo,po_message_msgctxt,
1537                      [AC_DEFINE(HAVE_LIBGETTEXTPO,1,[Define to 1 if you have the `gettextpo' library (-lgettextpo).])
1538                       AC_SUBST(LIBGETTEXTPO,"-lgettextpo")])
1539     fi
1540     test "x$with_gettextpo" != xyes || WINE_NOTICE_WITH(gettextpo,[test "x$LIBGETTEXTPO" = "x"],
1541           [GetText ${notice_platform}development files not found (or too old), po files can't be rebuilt.])
1542 fi
1543
1544 dnl **** Check for gstreamer ****
1545 if test "x$with_gstreamer" != "xno"
1546 then
1547     WINE_PACKAGE_FLAGS(GSTREAMER,[gstreamer-app-0.10],,,,
1548         [ac_gst_incl=""
1549         for i in $GSTREAMER_CFLAGS
1550         do
1551             case "$i" in
1552                 -I*) ac_gst_incl="$ac_gst_incl $i";;
1553             esac
1554         done
1555         GSTREAMER_CFLAGS=$ac_gst_incl
1556         CPPFLAGS="$ac_save_CPPFLAGS $GSTREAMER_CFLAGS"
1557         AC_CHECK_HEADER([gst/gstpad.h],
1558             [AC_CHECK_HEADER([gst/app/gstappsink.h],
1559                  [AC_MSG_CHECKING([whether gint64 defined by gst/app/gstappsink.h is indeed 64-bit])
1560                   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gst/app/gstappsink.h>]],
1561                                                      [[static int a[sizeof(gint64) > 4 ? 1 : -1]; if (a[0]) return 0;]])],
1562                     [AC_MSG_RESULT([yes])
1563                      AC_CHECK_LIB(gstreamer-0.10,gst_pad_get_caps_reffed,
1564                        [AC_CHECK_LIB(gstapp-0.10,gst_app_buffer_new,[:],,[$GSTREAMER_LIBS])])],
1565                     [AC_MSG_RESULT([no])])])],
1566             [GSTREAMER_CFLAGS=""])])
1567 fi
1568 WINE_NOTICE_WITH(gstreamer,[test "x$ac_cv_lib_gstapp_0_10_gst_app_buffer_new" != xyes -a "x$ac_cv_header_QuickTime_ImageCompression_h" != xyes],
1569                  [gstreamer-0.10 base plugins ${notice_platform}development files not found, gstreamer support disabled])
1570 test "x$ac_cv_lib_gstapp_0_10_gst_app_buffer_new" = xyes || enable_winegstreamer=${enable_winegstreamer:-no}
1571
1572 dnl **** Check for ALSA 1.x ****
1573 AC_SUBST(ALSALIBS,"")
1574 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1575 then
1576     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access_mask,
1577         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1578 #include <alsa/asoundlib.h>
1579 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1580 #include <sys/asoundlib.h>
1581 #endif]], [[snd_pcm_hw_params_get_access_mask(NULL, NULL)]])],
1582                         [ALSALIBS="-lasound"])])
1583 fi
1584
1585 dnl **** Check for OSSv4 ****
1586 if test "x$with_oss" != xno
1587 then
1588     ac_save_CPPFLAGS="$CPPFLAGS"
1589     if test -f /etc/oss.conf
1590     then
1591         . /etc/oss.conf
1592     fi
1593     ac_oss_incl="-I${OSSLIBDIR:-/usr/lib/oss}/include"
1594     CPPFLAGS="$CPPFLAGS $ac_oss_incl"
1595     AC_CHECK_HEADER([sys/soundcard.h],
1596         [AC_CHECK_MEMBERS([oss_sysinfo.numaudioengines],
1597                           [AC_SUBST(OSS4INCL,"$ac_oss_incl")],,
1598                           [#include <sys/soundcard.h>])])
1599     CPPFLAGS="$ac_save_CPPFLAGS"
1600     if test "x$ac_cv_member_oss_sysinfo_numaudioengines" != xyes
1601     then
1602         WINE_NOTICE([OSS sound system found but too old (OSSv4 needed), OSS won't be supported.])
1603     fi
1604 fi
1605
1606 dnl **** Check for capi4linux ****
1607 if test "x$with_capi" != "xno"
1608 then
1609     WINE_PACKAGE_FLAGS(CAPI20,[capi20],,,,
1610      dnl Check for broken kernel header that doesn't define __user
1611     [AC_CHECK_HEADERS([capi20.h linux/capi.h],,,[#define __user])
1612     if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1613     then
1614         WINE_CHECK_SONAME(capi20,capi20_register,,,[$CAPI20_LIBS])
1615     fi])
1616 fi
1617 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1618                  [libcapi20 ${notice_platform}development files not found, ISDN won't be supported.])
1619
1620 dnl **** Check for cups ****
1621 AC_SUBST(CUPSINCL,"")
1622 if test "x$with_cups" != "xno"
1623 then
1624     ac_save_CPPFLAGS="$CPPFLAGS"
1625     ac_cups_cflags=`cups-config --cflags 2>/dev/null`
1626     ac_cups_libs=`cups-config --ldflags 2>/dev/null`
1627     CPPFLAGS="$CPPFLAGS $ac_cups_cflags"
1628     AC_CHECK_HEADERS(cups/cups.h,
1629             [WINE_CHECK_SONAME(cups,cupsGetDefault,
1630                        [CUPSINCL="$ac_cups_cflags"],,
1631                        [$ac_cups_libs])])
1632     CPPFLAGS="$ac_save_CPPFLAGS"
1633 fi
1634 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1635                  [libcups ${notice_platform}development files not found, CUPS won't be supported.])
1636
1637 dnl **** Check for fontconfig ****
1638 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1639 then
1640     WINE_CHECK_SONAME(fontconfig,FcInit)
1641 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1642 then
1643     dnl fontconfig is in the X directory on Mac OS X
1644     ac_save_CPPFLAGS="$CPPFLAGS"
1645     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1646     $as_unset ac_cv_header_fontconfig_fontconfig_h
1647     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1648     CPPFLAGS="$ac_save_CPPFLAGS"
1649     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1650     then
1651         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1652         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1653     fi
1654 fi
1655 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1656                  [fontconfig ${notice_platform}development files not found, fontconfig won't be supported.])
1657
1658 dnl **** Check for gsm codec ****
1659 if test "$ac_cv_header_gsm_h" = "yes" -o "$ac_cv_header_gsm_gsm_h" = "yes"
1660 then
1661     WINE_CHECK_SONAME(gsm,gsm_create)
1662 fi
1663 WINE_NOTICE_WITH(gsm,[test "x$ac_cv_lib_soname_gsm" = "x"],
1664                  [libgsm ${notice_platform}development files not found, gsm 06.10 codec won't be supported.])
1665
1666 dnl **** Check for libjpeg ****
1667 if test "x$with_jpeg" != "xno"
1668 then
1669     WINE_PACKAGE_FLAGS(JPEG,[libjpeg],,,,
1670         [AC_CHECK_HEADERS([jpeglib.h])
1671         if test "$ac_cv_header_jpeglib_h" = "yes"
1672         then
1673             WINE_CHECK_SONAME(jpeg,jpeg_start_decompress,,[JPEG_CFLAGS=""],[$JPEG_LIBS])
1674         else
1675             JPEG_CFLAGS=""
1676         fi])
1677 fi
1678 WINE_WARNING_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1679                  [libjpeg ${notice_platform}development files not found, JPEG won't be supported.])
1680
1681 dnl **** Check for libpng ****
1682 if test "x$with_png" != "xno"
1683 then
1684     WINE_PACKAGE_FLAGS(PNG,[libpng],,[$X_CFLAGS],[$X_LIBS],
1685         [AC_CHECK_HEADERS([png.h])
1686         if test "$ac_cv_header_png_h" = "yes"
1687         then
1688             WINE_CHECK_SONAME(png,png_create_read_struct,
1689                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <png.h>]],[[typeof(png_set_expand_gray_1_2_4_to_8) *p]])],
1690                     [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1,[Define to 1 if libpng has the png_set_expand_gray_1_2_4_to_8 function.])])],
1691                 [PNG_CFLAGS=""],[$PNG_LIBS -lm -lz],[[libpng[[0-9]]*]])
1692         else
1693             PNG_CFLAGS=""
1694         fi])
1695 fi
1696 WINE_WARNING_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1697                  [libpng ${notice_platform}development files not found, PNG won't be supported.])
1698
1699 dnl **** Check for libtiff ****
1700 if test "x$with_tiff" != "xno"
1701 then
1702     WINE_PACKAGE_FLAGS(TIFF,[libtiff],,,,
1703         [AC_CHECK_HEADERS([tiffio.h])
1704         if test "$ac_cv_header_tiffio_h" = "yes"
1705         then
1706             WINE_CHECK_SONAME(tiff,TIFFClientOpen,,,[$TIFF_LIBS])
1707         fi])
1708 fi
1709 WINE_NOTICE_WITH(tiff,[test "x$ac_cv_lib_soname_tiff" = "x"],
1710                  [libtiff ${notice_platform}development files not found, TIFF won't be supported.])
1711
1712 dnl **** Check for mpg123 ****
1713 if test "x$with_mpg123" != "xno"
1714 then
1715     WINE_PACKAGE_FLAGS(MPG123,[libmpg123],[-lmpg123],,,
1716         [AC_CHECK_HEADERS([mpg123.h])
1717         if test "$ac_cv_header_mpg123_h" = "yes"
1718         then
1719             AC_CHECK_LIB(mpg123,mpg123_feed,[:],[MPG123_LIBS=""],[$MPG123_LIBS])
1720         else
1721             MPG123_CFLAGS=""
1722             MPG123_LIBS=""
1723         fi])
1724 fi
1725 WINE_NOTICE_WITH(mpg123,[test "x$ac_cv_lib_mpg123_mpg123_feed" != xyes -a x"$ac_cv_header_CoreAudio_CoreAudio_h" != xyes],
1726                  [libmpg123 ${notice_platform}development files not found (or too old), mp3 codec won't be supported.])
1727 test "x$ac_cv_lib_mpg123_mpg123_feed" = xyes -o "x$ac_cv_header_AudioToolbox_AudioConverter_h" = xyes || enable_winemp3_acm=${enable_winemp3_acm:-no}
1728
1729 dnl **** Check for OpenAL 1.1 ****
1730 if test "$ac_cv_header_AL_al_h" = "yes"
1731 then
1732     WINE_CHECK_SONAME(openal,alGetSource3i,[AC_SUBST(LIBOPENAL,"-lopenal")
1733                       ac_cv_lib_openal=yes
1734                       AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])],,)
1735 fi
1736 WINE_NOTICE_WITH(openal,[test "x$ac_cv_lib_openal" != xyes],
1737                  [libopenal ${notice_platform}development files not found (or too old), OpenAL won't be supported.])
1738 test "x$ac_cv_lib_openal" = xyes || enable_openal32=${enable_openal32:-no}
1739
1740 dnl **** Check for libkstat ****
1741 if test "$ac_cv_header_kstat_h" = "yes"
1742 then
1743     AC_CHECK_LIB(kstat,kstat_open,
1744                  [AC_DEFINE(HAVE_LIBKSTAT, 1, [Define to 1 if you have the `kstat' library (-lkstat).])
1745                   AC_SUBST(LIBKSTAT,"-lkstat")])
1746 fi
1747
1748 dnl **** Check for libprocstat ****
1749 if test "$ac_cv_header_libprocstat_h" = "yes"
1750 then
1751     AC_CHECK_LIB(procstat,procstat_open_sysctl,
1752                  [AC_DEFINE(HAVE_LIBPROCSTAT, 1, [Define to 1 if you have the `procstat' library (-lprocstat).])
1753                   AC_SUBST(LIBPROCSTAT,"-lprocstat")])
1754 fi
1755
1756 dnl **** Check for libodbc ****
1757 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1758
1759 dnl **** Disable unsupported winmm drivers ****
1760 test -n "$ALSALIBS" || enable_winealsa_drv=${enable_winealsa_drv:-no}
1761 test -n "$COREAUDIO" || enable_winecoreaudio_drv=${enable_winecoreaudio_drv:-no}
1762 test "x$ac_cv_member_oss_sysinfo_numaudioengines" = xyes || enable_wineoss_drv=${enable_wineoss_drv:-no}
1763 test "$ac_cv_header_linux_joystick_h" = "yes" || enable_winejoystick_drv=${enable_winejoystick_drv:-no}
1764
1765 dnl **** Check for any sound system ****
1766 if test "x$ALSALIBS$COREAUDIO" = "x" -a \
1767         "x$ac_cv_member_oss_sysinfo_numaudioengines" != xyes -a \
1768         "x$with_alsa$with_coreaudio$with_oss" != xnonono
1769 then
1770     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1771 fi
1772
1773 dnl **** Check for gcc specific options ****
1774
1775 AC_SUBST(EXTRACFLAGS,"")
1776 if test "x${GCC}" = "xyes"
1777 then
1778   EXTRACFLAGS="-Wall -pipe"
1779
1780   dnl Check for strength-reduce bug
1781   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1782                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1783 [[static int Array[[3]];
1784   unsigned int B = 3;
1785   int i;
1786   for(i=0; i<B; i++) Array[[i]] = i - 3;
1787   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1788   L[[i]] = 4;
1789   return (Array[[1]] != -2 || L[[2]] != 3)]])],
1790     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1791   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1792   then
1793     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1794   fi
1795
1796   dnl Check for some compiler flags
1797   WINE_TRY_CFLAGS([-fno-builtin],[AC_SUBST(BUILTINFLAG,"-fno-builtin")])
1798   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1799   dnl clang needs to be told to fail on unknown options
1800   saved_CFLAGS=$CFLAGS
1801   WINE_TRY_CFLAGS([-Werror=unknown-warning-option],[CFLAGS="$CFLAGS -Werror=unknown-warning-option"])
1802   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1803   WINE_TRY_CFLAGS([-Wempty-body])
1804   WINE_TRY_CFLAGS([-Wignored-qualifiers])
1805   WINE_TRY_CFLAGS([-Wstrict-prototypes])
1806   WINE_TRY_CFLAGS([-Wtype-limits])
1807   WINE_TRY_CFLAGS([-Wunused-but-set-parameter])
1808   WINE_TRY_CFLAGS([-Wwrite-strings])
1809
1810   dnl Check for noisy string.h
1811   WINE_TRY_CFLAGS([-Wpointer-arith],
1812      [saved_string_h_CFLAGS=$CFLAGS
1813       CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1814       AC_CACHE_CHECK([for broken string.h that generates warnings with -Wpointer-arith], ac_cv_c_string_h_warnings,
1815           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1816       test "$ac_cv_c_string_h_warnings" = yes || EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1817       CFLAGS=$saved_string_h_CFLAGS])
1818
1819   dnl Check for noisy string.h on logical ops
1820   WINE_TRY_CFLAGS([-Wlogical-op],
1821      [saved_string_h_CFLAGS=$CFLAGS
1822       CFLAGS="$CFLAGS -Wlogical-op -Werror"
1823       AC_CACHE_CHECK([for broken string.h that generates warnings with -Wlogical-op], ac_cv_c_logicalop_noisy,
1824           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>
1825 char*f(const char *h,char n) {return strchr(h,n);}]])],[ac_cv_c_logicalop_noisy=no],[ac_cv_c_logicalop_noisy=yes]))
1826       CFLAGS=$saved_string_h_CFLAGS
1827       test "$ac_cv_c_logicalop_noisy" = yes || EXTRACFLAGS="$EXTRACFLAGS -Wlogical-op"])
1828
1829   CFLAGS=$saved_CFLAGS
1830
1831   dnl On Darwin, prefer stabs; everywhere else, default to dwarf-2 debug info
1832   for ac_flag in $CFLAGS; do
1833     case $ac_flag in
1834       -g) case $host_os in
1835             darwin*) WINE_TRY_CFLAGS([-gstabs+]) ;;
1836             *) WINE_TRY_CFLAGS([-gdwarf-2])
1837                WINE_TRY_CFLAGS([-gstrict-dwarf]) ;;
1838           esac ;;
1839     esac
1840   done
1841
1842   dnl gcc-4.6+ omits frame pointers by default, breaking some copy protections
1843   case $host_cpu in
1844     *i[[3456789]]86*) WINE_TRY_CFLAGS([-fno-omit-frame-pointer]) ;;
1845   esac
1846
1847   dnl mingw uses Windows 64-bit types, not Unix ones
1848   case $host in
1849     x86_64-*mingw32*|x86_64-*cygwin*) WINE_TRY_CFLAGS([-Wno-format]) ;;
1850   esac
1851
1852   dnl Enable -Werror for maintainer mode
1853   if test "x$enable_maintainer_mode" = "xyes"
1854   then
1855       WINE_TRY_CFLAGS([-Werror])
1856   fi
1857
1858   dnl Check for ms_hook_prologue support
1859   saved_CFLAGS="$CFLAGS"
1860   CFLAGS="$CFLAGS -Werror"
1861   AC_CACHE_CHECK([for ms_hook_prologue attribute], ac_cv_have_ms_hook_prologue,
1862                  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[int __attribute__((__ms_hook_prologue__)) test(void) { return 0; }]])],
1863                                    [ac_cv_have_ms_hook_prologue="yes"],[ac_cv_have_ms_hook_prologue="no"]))
1864   CFLAGS="$saved_CFLAGS"
1865   if test "$ac_cv_have_ms_hook_prologue" = "yes"
1866   then
1867       AC_DEFINE(DECLSPEC_HOTPATCH, [__attribute__((__ms_hook_prologue__))],
1868                 [Define to a function attribute for Microsoft hotpatch assembly prefix.])
1869   else
1870       AC_DEFINE(DECLSPEC_HOTPATCH, [/* */])
1871   fi
1872 fi
1873
1874 dnl **** Disable Fortify, it has too many false positives
1875
1876 AC_CACHE_CHECK([for the need to disable Fortify], ac_cv_c_fortify_enabled,
1877     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]],
1878 [[#if defined(__USE_FORTIFY_LEVEL) && __USE_FORTIFY_LEVEL > 0
1879 #error Fortify enabled
1880 #endif]])],
1881         [ac_cv_c_fortify_enabled=no],[ac_cv_c_fortify_enabled=yes]))
1882 if test "$ac_cv_c_fortify_enabled" = yes
1883 then
1884     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=0"
1885 fi
1886
1887 dnl **** Check for underscore on external symbols ****
1888
1889 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1890     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1891                       [extern int ac_test;],
1892                       [if (ac_test) return 1],
1893                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1894
1895 case $host_cpu in
1896   *i[[3456789]]86*)
1897     AC_CACHE_CHECK([whether external symbols need stdcall decoration], ac_cv_c_stdcall_suffix,
1898         WINE_TRY_ASM_LINK(["jmp _ac_test@4"],
1899 [#ifndef _MSC_VER
1900 #define __stdcall __attribute__((__stdcall__))
1901 #endif
1902 int __stdcall ac_test(int i) { return i; }],
1903                           [if (ac_test(1)) return 1],
1904                           ac_cv_c_stdcall_suffix="yes",ac_cv_c_stdcall_suffix="no")) ;;
1905   *) ac_cv_c_stdcall_suffix="no" ;;
1906 esac
1907
1908 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1909 if test "$ac_cv_c_extern_prefix" = "yes"
1910 then
1911     AC_DEFINE([__ASM_NAME(name)], ["_" name])
1912     asm_name_prefix="_"
1913 else
1914     AC_DEFINE([__ASM_NAME(name)], [name])
1915     asm_name_prefix=""
1916 fi
1917
1918 AH_TEMPLATE(__ASM_STDCALL,[Define to a macro to generate an stdcall suffix])
1919 if test "$ac_cv_c_stdcall_suffix" = "yes"
1920 then
1921     AC_DEFINE([__ASM_STDCALL(args)],["@" #args])
1922 else
1923     AC_DEFINE([__ASM_STDCALL(args)],[""])
1924 fi
1925
1926 dnl **** Check how to define a function in assembly code ****
1927
1928 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1929   WINE_TRY_ASM_LINK(
1930       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1931       ac_cv_asm_func_def=".def",
1932     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1933       ac_cv_asm_func_def=".type @function",
1934     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1935       ac_cv_asm_func_def=".type 2",
1936       ac_cv_asm_func_def="unknown")])]))
1937
1938 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1939 case "$ac_cv_asm_func_def" in
1940   ".def")
1941      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"])
1942      asm_func_header=".def $asm_name_prefix\" #name suffix \"; .scl 2; .type 32; .endef" ;;
1943   ".type @function")
1944      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"])
1945      asm_func_header=".type $asm_name_prefix\" #name suffix \",@function" ;;
1946   ".type 2")
1947      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"])
1948      asm_func_header=".type $asm_name_prefix\" #name suffix \",2" ;;
1949   *)
1950      AC_DEFINE([__ASM_FUNC(name)], [""])
1951      asm_func_header="" ;;
1952 esac
1953
1954 AC_CACHE_CHECK([whether asm() works outside of functions], ac_cv_c_asm_outside_funcs,
1955     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\n\t.long 0");]],)],
1956                       ac_cv_c_asm_outside_funcs="yes",ac_cv_c_asm_outside_funcs="no"))
1957
1958 AC_CACHE_CHECK([whether .previous is supported in assembly code], ac_cv_c_dot_previous,
1959     WINE_TRY_ASM_LINK([".text\nac_test:\t.long 0\n\t.previous"],,,
1960                       ac_cv_c_dot_previous="yes",ac_cv_c_dot_previous="no"))
1961
1962 AC_CACHE_CHECK([whether CFI directives are supported in assembly code], ac_cv_c_cfi_support,
1963     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\nac_test:\t.cfi_startproc\n\t.long 0\n\t.cfi_endproc");]])],
1964                       ac_cv_c_cfi_support="yes",ac_cv_c_cfi_support="no"))
1965
1966 asm_func_header=".globl $asm_name_prefix\" #name suffix \"\\n\\t$asm_func_header\\n$asm_name_prefix\" #name suffix \":\\n\\t"
1967 asm_func_trailer=""
1968 if test "$ac_cv_c_dot_previous" = "yes"
1969 then
1970    asm_func_trailer="\\n\\t.previous"
1971 fi
1972 if test "$ac_cv_c_cfi_support" = "yes"
1973 then
1974    asm_func_header="$asm_func_header.cfi_startproc\\n\\t"
1975    asm_func_trailer="\\n\\t.cfi_endproc$asm_func_trailer"
1976    AC_DEFINE([__ASM_CFI(str)],[str],[Define to a macro to output a .cfi assembly pseudo-op])
1977    AC_SUBST([UNWINDFLAGS],[-fasynchronous-unwind-tables])
1978 else
1979    AC_DEFINE([__ASM_CFI(str)],[""])
1980 fi
1981
1982 asm_func_code="$asm_func_header\" code \"$asm_func_trailer"
1983
1984 AH_TEMPLATE(__ASM_DEFINE_FUNC,[Define to a macro to define an assembly function])
1985 if test "$ac_cv_c_asm_outside_funcs" = "yes"
1986 then
1987     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[asm(".text\n\t.align 4\n\t$asm_func_code");])
1988 else
1989     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[void __asm_dummy_##name(void) { asm(".text\n\t.align 4\n\t$asm_func_code"); }])
1990 fi
1991 AC_DEFINE([__ASM_GLOBAL_FUNC(name,code)],[__ASM_DEFINE_FUNC(name,"",code)],
1992           [Define to a macro to generate an assembly function with C calling convention])
1993 AC_DEFINE([__ASM_STDCALL_FUNC(name,args,code)],[__ASM_DEFINE_FUNC(name,__ASM_STDCALL(args),code)],
1994           [Define to a macro to generate an assembly function with stdcall calling convention])
1995
1996 dnl **** Platform-specific checks ****
1997
1998 case $build_os in
1999   cygwin*|mingw32*) AC_SUBST(TOOLSEXT,".exe") ;;
2000 esac
2001
2002 case $host_os in
2003   linux*)
2004     case $host_cpu in
2005       *i[[3456789]]86*|x86_64*)
2006         AS_VAR_APPEND([LOADER_RULES],["
2007 all: $wine_binary-preloader
2008
2009 $wine_binary-preloader: preloader.o Makefile.in
2010         \$(CC) -o \$@ -static -nostartfiles -nodefaultlibs -Wl,-Ttext=0x7c400000 preloader.o \$(LIBPORT) \$(LDFLAGS)
2011
2012 install install-lib:: $wine_binary-preloader \$(DESTDIR)\$(bindir)
2013         \$(INSTALL_PROGRAM) $wine_binary-preloader \$(DESTDIR)\$(bindir)/$wine_binary-preloader
2014
2015 uninstall::
2016         \$(RM) \$(DESTDIR)\$(bindir)/$wine_binary-preloader
2017 "]) ;;
2018     esac
2019     ;;
2020 esac
2021
2022 dnl **** Check for functions ****
2023
2024 ac_save_CFLAGS="$CFLAGS"
2025 CFLAGS="$CFLAGS $BUILTINFLAG"
2026 AC_CHECK_FUNCS(\
2027         __res_get_state \
2028         __res_getservers \
2029         _finite \
2030         _isnan \
2031         _pclose \
2032         _popen \
2033         _snprintf \
2034         _spawnvp \
2035         _strdup \
2036         _stricmp \
2037         _strnicmp \
2038         _strtoi64 \
2039         _strtoui64 \
2040         _vsnprintf \
2041         asctime_r \
2042         chsize \
2043         dlopen \
2044         epoll_create \
2045         ffs \
2046         finite \
2047         fnmatch \
2048         fork \
2049         fpclass \
2050         fstatfs \
2051         fstatvfs \
2052         ftruncate \
2053         futimens \
2054         futimes \
2055         futimesat \
2056         getattrlist \
2057         getdirentries \
2058         getopt_long_only \
2059         getpwuid \
2060         gettimeofday \
2061         getuid \
2062         if_nameindex \
2063         kqueue \
2064         lstat \
2065         memmove \
2066         mmap \
2067         pclose \
2068         pipe2 \
2069         poll \
2070         popen \
2071         port_create \
2072         prctl \
2073         pread \
2074         proc_pidinfo \
2075         pwrite \
2076         readdir \
2077         readlink \
2078         sched_yield \
2079         select \
2080         setproctitle \
2081         setrlimit \
2082         settimeofday \
2083         sigaltstack \
2084         sigprocmask \
2085         snprintf \
2086         statfs \
2087         statvfs \
2088         strcasecmp \
2089         strdup \
2090         strerror \
2091         strncasecmp \
2092         strtold \
2093         strtoll \
2094         strtoull \
2095         symlink \
2096         tcdrain \
2097         thr_kill2 \
2098         timegm \
2099         usleep \
2100         vsnprintf
2101 )
2102 CFLAGS="$ac_save_CFLAGS"
2103
2104 dnl Check for -ldl
2105 if test "$ac_cv_func_dlopen" = no
2106 then
2107     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
2108 fi
2109 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
2110
2111 dnl Check for -lpoll for Mac OS X/Darwin
2112 if test "$ac_cv_func_poll" = no
2113 then
2114     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
2115 fi
2116
2117 dnl Check for -lnsl for Solaris
2118 AC_SEARCH_LIBS(gethostbyname, nsl)
2119
2120 dnl Check for -lsocket for Solaris
2121 AC_SEARCH_LIBS(connect, socket)
2122
2123 dnl Check for -lresolv for Solaris
2124 AC_SEARCH_LIBS(inet_aton, resolv)
2125
2126 dnl **** Check for functions which may rely on -lsocket on Solaris.
2127 AC_CHECK_FUNCS(\
2128         getaddrinfo \
2129         getnameinfo \
2130         getnetbyname \
2131         getprotobyname \
2132         getprotobynumber \
2133         getservbyport \
2134         inet_addr \
2135         inet_network \
2136         inet_ntop \
2137         inet_pton \
2138         sendmsg \
2139         socketpair \
2140 )
2141
2142 dnl Check for clock_gettime which may be in -lrt
2143 ac_save_LIBS=$LIBS
2144 AC_SEARCH_LIBS(clock_gettime, rt,
2145                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define to 1 if you have the `clock_gettime' function.])
2146                 test "$ac_res" = "none required" || AC_SUBST(LIBRT,"$ac_res")])
2147 LIBS=$ac_save_LIBS
2148
2149 dnl **** Check for OpenLDAP ***
2150 AC_SUBST(LDAPLIBS,"")
2151 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
2152 then
2153     AC_CHECK_TYPE(LDAPSortKey,
2154         [AC_CHECK_LIB(ldap_r, ldap_initialize,
2155             [AC_CHECK_LIB(lber, ber_init,
2156                 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
2157                  LDAPLIBS="-lldap_r -llber"],,
2158                  [$LIBPTHREAD])],,
2159                  [$LIBPTHREAD])],,
2160         [#include <ldap.h>])
2161     WINE_CHECK_LIB_FUNCS(\
2162         ldap_count_references \
2163         ldap_first_reference \
2164         ldap_next_reference \
2165         ldap_parse_reference \
2166         ldap_parse_sort_control \
2167         ldap_parse_sortresponse_control \
2168         ldap_parse_vlv_control \
2169         ldap_parse_vlvresponse_control,
2170         [$LDAPLIBS $LIBPTHREAD])
2171 fi
2172 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
2173                  [libldap (OpenLDAP) ${notice_platform}development files not found, LDAP won't be supported.])
2174
2175 AC_CACHE_CHECK([whether mkdir takes only one argument],
2176         wine_cv_one_arg_mkdir,
2177         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/stat.h>]],[[mkdir("foo");]])],
2178                           [wine_cv_one_arg_mkdir=yes],[wine_cv_one_arg_mkdir=no]))
2179 if test "$wine_cv_one_arg_mkdir" = "yes"
2180 then
2181   AC_DEFINE(HAVE_ONE_ARG_MKDIR, 1, [Define if mkdir takes only one argument])
2182 fi
2183
2184 AC_CACHE_CHECK([for sched_setaffinity],wine_cv_have_sched_setaffinity,
2185                 AC_LINK_IFELSE([AC_LANG_PROGRAM(
2186 [[#define _GNU_SOURCE
2187 #include <sched.h>]], [[sched_setaffinity(0, 0, 0);]])],[wine_cv_have_sched_setaffinity=yes],[wine_cv_have_sched_setaffinity=no]))
2188 if test "$wine_cv_have_sched_setaffinity" = "yes"
2189 then
2190   AC_DEFINE(HAVE_SCHED_SETAFFINITY, 1, [Define to 1 if you have the `sched_setaffinity' function.])
2191 fi
2192
2193 AC_CACHE_CHECK([for fallocate],wine_cv_have_fallocate,
2194                 AC_LINK_IFELSE([AC_LANG_PROGRAM(
2195 [[#define _GNU_SOURCE
2196 #include <fcntl.h>]], [[fallocate(-1, 0, 0, 0);]])],[wine_cv_have_fallocate=yes],[wine_cv_have_fallocate=no]))
2197 if test "$wine_cv_have_fallocate" = "yes"
2198 then
2199   AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the `fallocate' function.])
2200 fi
2201
2202 dnl **** Check for types ****
2203
2204 AC_C_INLINE
2205 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
2206 AC_CHECK_TYPES([sigset_t],,,[#include <sys/types.h>
2207 #include <signal.h>])
2208 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
2209
2210 AC_CHECK_TYPES([struct xinpgen],,,
2211 [#include <sys/types.h>
2212 #ifdef HAVE_SYS_SOCKET_H
2213 #include <sys/socket.h>
2214 #endif
2215 #ifdef HAVE_SYS_SOCKETVAR_H
2216 #include <sys/socketvar.h>
2217 #endif
2218 #ifdef HAVE_NET_ROUTE_H
2219 #include <net/route.h>
2220 #endif
2221 #ifdef HAVE_NETINET_IN_H
2222 #include <netinet/in.h>
2223 #endif
2224 #ifdef HAVE_NETINET_IN_SYSTM_H
2225 #include <netinet/in_systm.h>
2226 #endif
2227 #ifdef HAVE_NETINET_IP_H
2228 #include <netinet/ip.h>
2229 #endif
2230 #ifdef HAVE_NETINET_IN_PCB_H
2231 #include <netinet/in_pcb.h>
2232 #endif])
2233
2234 AC_CHECK_TYPES([struct r_debug, struct link_map],,,
2235 [#ifdef HAVE_LINK_H
2236 #include <link.h>
2237 #endif
2238 #ifdef HAVE_SYS_LINK_H
2239 #include <sys/link.h>
2240 #endif])
2241
2242 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
2243 [#ifdef HAVE_LINUX_INPUT_H
2244 #include <linux/input.h>
2245 #endif])
2246
2247 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
2248                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
2249 if test "$wine_cv_have_sigaddset" = "yes"
2250 then
2251   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
2252 fi
2253
2254
2255 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
2256         wine_cv_linux_gethostbyname_r_6,
2257         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
2258     char *name=0;
2259     struct hostent he;
2260     struct hostent *result;
2261     char *buf=0;
2262     int bufsize=0;
2263     int errnr;
2264     char *addr=0;
2265     int addrlen=0;
2266     int addrtype=0;
2267     gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
2268     gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
2269     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
2270         ])
2271    )
2272    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
2273    then
2274       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
2275                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
2276    fi
2277
2278 if test "$ac_cv_header_linux_joystick_h" = "yes"
2279 then
2280    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
2281         wine_cv_linux_joystick_22_api,
2282         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2283         #include <sys/ioctl.h>
2284         #include <sys/types.h>
2285         #include <linux/joystick.h>
2286
2287         struct js_event blub;
2288         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
2289         #error "no 2.2 header"
2290         #endif
2291         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
2292    )
2293    if test "$wine_cv_linux_joystick_22_api" = "yes"
2294    then
2295       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
2296                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
2297    fi
2298 fi
2299
2300 dnl **** FIXME: what about mixed cases, where we need two of them? ***
2301
2302 dnl Check for statfs members
2303 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
2304 [#include <sys/types.h>
2305 #ifdef HAVE_SYS_PARAM_H
2306 # include <sys/param.h>
2307 #endif
2308 #ifdef HAVE_SYS_MOUNT_H
2309 # include <sys/mount.h>
2310 #endif
2311 #ifdef HAVE_SYS_VFS_H
2312 # include <sys/vfs.h>
2313 #endif
2314 #ifdef HAVE_SYS_STATFS_H
2315 # include <sys/statfs.h>
2316 #endif])
2317
2318 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
2319 [#ifdef HAVE_SYS_STATVFS_H
2320 #include <sys/statvfs.h>
2321 #endif])
2322
2323 dnl Check for dirent.d_reclen
2324 AC_CHECK_MEMBERS([struct dirent.d_reclen],,,
2325 [#ifdef HAVE_DIRENT_H
2326 #include <dirent.h>
2327 #endif])
2328
2329 dnl Check for socket structure members
2330 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
2331 [#include <sys/types.h>
2332 #ifdef HAVE_SYS_SOCKET_H
2333 # include <sys/socket.h>
2334 #endif
2335 #ifdef HAVE_SYS_UN_H
2336 # include <sys/un.h>
2337 #endif])
2338
2339 dnl Check for scsireq_t and sg_io_hdr_t members
2340 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
2341 [#include <sys/types.h>
2342 #ifdef HAVE_SCSI_SG_H
2343 #include <scsi/sg.h>
2344 #endif])
2345
2346 dnl Check for siginfo_t members
2347 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
2348
2349 dnl Check for struct mtget members
2350 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
2351 [#include <sys/types.h>
2352 #ifdef HAVE_SYS_MTIO_H
2353 #include <sys/mtio.h>
2354 #endif])
2355
2356 dnl Check for struct option
2357 AC_CHECK_MEMBERS([struct option.name],,,
2358 [#ifdef HAVE_GETOPT_H
2359 #include <getopt.h>
2360 #endif])
2361
2362 dnl Check for stat.st_blocks and ns-resolved times
2363 AC_CHECK_MEMBERS([
2364         struct stat.st_blocks,
2365         struct stat.st_mtim,
2366         struct stat.st_mtimespec,
2367         struct stat.st_ctim,
2368         struct stat.st_ctimespec,
2369         struct stat.st_atim,
2370         struct stat.st_atimespec,
2371         struct stat.st_birthtime,
2372         struct stat.st_birthtim,
2373         struct stat.st_birthtimespec,
2374         struct stat.__st_birthtime,
2375         struct stat.__st_birthtim])
2376
2377 dnl Check for sin6_scope_id
2378 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
2379 [#ifdef HAVE_SYS_TYPES_H
2380 #include <sys/types.h>
2381 #endif
2382 #ifdef HAVE_NETINET_IN_H
2383 #include <netinet/in.h>
2384 #endif])
2385
2386 dnl Check for struct __res_state
2387 AC_CHECK_TYPES([struct __res_state],,,
2388 [#ifdef HAVE_RESOLV_H
2389 #include <resolv.h>
2390 #endif])
2391
2392 dnl Check for _u._ext.nscount6
2393 AC_CHECK_MEMBERS([struct __res_state._u._ext.nscount6],,,
2394 [#ifdef HAVE_RESOLV_H
2395 #include <resolv.h>
2396 #endif])
2397
2398 dnl Check for ns_msg ptr member
2399 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
2400 [#ifdef HAVE_SYS_TYPES_H
2401 #include <sys/types.h>
2402 #endif
2403 #ifdef HAVE_NETINET_IN_H
2404 # include <netinet/in.h>
2405 #endif
2406 #ifdef HAVE_ARPA_NAMESER_H
2407 # include <arpa/nameser.h>
2408 #endif])
2409
2410 dnl Check for struct icmpstat
2411 AC_CHECK_MEMBERS([struct icmpstat.icps_inhist],,,
2412 [#ifdef HAVE_SYS_TYPES_H
2413 #include <sys/types.h>
2414 #endif
2415 #ifdef HAVE_NETINET_IP_H
2416 #include <netinet/ip.h>
2417 #endif
2418 #ifdef HAVE_NETINET_IP_ICMP_H
2419 #include <netinet/ip_icmp.h>
2420 #endif
2421 #ifdef HAVE_NETINET_ICMP_VAR_H
2422 #include <netinet/icmp_var.h>
2423 #endif])
2424
2425 dnl Check for struct icmpstat.icps_outhist
2426 AC_CHECK_MEMBERS([struct icmpstat.icps_outhist],,,
2427 [#ifdef HAVE_SYS_TYPES_H
2428 #include <sys/types.h>
2429 #endif
2430 #ifdef HAVE_ALIAS_H
2431 #include <alias.h>
2432 #endif
2433 #ifdef HAVE_SYS_SOCKET_H
2434 #include <sys/socket.h>
2435 #endif
2436 #ifdef HAVE_SYS_SOCKETVAR_H
2437 #include <sys/socketvar.h>
2438 #endif
2439 #ifdef HAVE_SYS_TIMEOUT_H
2440 #include <sys/timeout.h>
2441 #endif
2442 #ifdef HAVE_NETINET_IN_H
2443 #include <netinet/in.h>
2444 #endif
2445 #ifdef HAVE_NETINET_IN_SYSTM_H
2446 #include <netinet/in_systm.h>
2447 #endif
2448 #ifdef HAVE_NETINET_IP_H
2449 #include <netinet/ip.h>
2450 #endif
2451 #ifdef HAVE_NETINET_IP_VAR_H
2452 #include <netinet/ip_var.h>
2453 #endif
2454 #ifdef HAVE_NETINET_IP_ICMP_H
2455 #include <netinet/ip_icmp.h>
2456 #endif
2457 #ifdef HAVE_NETINET_ICMP_VAR_H
2458 #include <netinet/icmp_var.h>
2459 #endif])
2460
2461 dnl Check for struct ipstat
2462 AC_CHECK_MEMBERS([struct ipstat.ips_total],,,
2463 [#ifdef HAVE_SYS_TYPES_H
2464 #include <sys/types.h>
2465 #endif
2466 #ifdef HAVE_SYS_SOCKETVAR_H
2467 #include <sys/socketvar.h>
2468 #endif
2469 #ifdef HAVE_NETINET_IN_H
2470 #include <netinet/in.h>
2471 #endif
2472 #ifdef HAVE_NETINET_IP_VAR_H
2473 #include <netinet/ip_var.h>
2474 #endif])
2475
2476 dnl Check for struct ip_stats
2477 AC_CHECK_MEMBERS([struct ip_stats.ips_total],,,
2478 [#ifdef HAVE_NETINET_IP_VAR_H
2479 #include <netinet/ip_var.h>
2480 #endif])
2481
2482 dnl Check for struct tcpstat
2483 AC_CHECK_MEMBERS([struct tcpstat.tcps_connattempt],,,
2484 [#ifdef HAVE_SYS_TYPES_H
2485 #include <sys/types.h>
2486 #endif
2487 #ifdef HAVE_SYS_SOCKETVAR_H
2488 #include <sys/socketvar.h>
2489 #endif
2490 #ifdef HAVE_NETINET_IN_H
2491 #include <netinet/in.h>
2492 #endif
2493 #ifdef HAVE_NETINET_TCP_H
2494 #include <netinet/tcp.h>
2495 #endif
2496 #ifdef HAVE_NETINET_TCP_VAR_H
2497 #include <netinet/tcp_var.h>
2498 #endif])
2499
2500 dnl Check for struct tcp_stats
2501 AC_CHECK_MEMBERS([struct tcp_stats.tcps_connattempt],,,
2502 [#ifdef HAVE_NETINET_TCP_VAR_H
2503 #include <netinet/tcp_var.h>
2504 #endif])
2505
2506 dnl Check for struct udpstat
2507 AC_CHECK_MEMBERS([struct udpstat.udps_ipackets],,,
2508 [#ifdef HAVE_SYS_TYPES_H
2509 #include <sys/types.h>
2510 #endif
2511 #ifdef HAVE_NETINET_IN_H
2512 #include <netinet/in.h>
2513 #endif
2514 #ifdef HAVE_NETINET_IP_VAR_H
2515 #include <netinet/ip_var.h>
2516 #endif
2517 #ifdef HAVE_NETINET_UDP_H
2518 #include <netinet/udp.h>
2519 #endif
2520 #ifdef HAVE_NETINET_UDP_VAR_H
2521 #include <netinet/udp_var.h>
2522 #endif])
2523
2524 dnl Check for struct ifreq.ifr_hwaddr
2525 AC_CHECK_MEMBERS([struct ifreq.ifr_hwaddr],,,
2526 [#ifdef HAVE_SYS_TYPES_H
2527 #include <sys/types.h>
2528 #endif
2529 #ifdef HAVE_NET_IF_H
2530 # include <net/if.h>
2531 #endif])
2532
2533 dnl Check for the external timezone variables timezone and daylight
2534 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
2535                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
2536 if test "$ac_cv_have_timezone" = "yes"
2537 then
2538     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
2539 fi
2540 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
2541                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
2542 if test "$ac_cv_have_daylight" = "yes"
2543 then
2544     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
2545 fi
2546
2547 dnl Check for isinf
2548 ac_save_LIBS="$LIBS"
2549 LIBS="$LIBS -lm"
2550 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
2551                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; return isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
2552 if test "$ac_cv_have_isinf" = "yes"
2553 then
2554     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
2555 fi
2556
2557 dnl Check for isnan
2558 AC_CACHE_CHECK([for isnan], ac_cv_have_isnan,
2559                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; return isnan(f)]])],[ac_cv_have_isnan="yes"],[ac_cv_have_isnan="no"]))
2560 if test "$ac_cv_have_isnan" = "yes"
2561 then
2562     AC_DEFINE(HAVE_ISNAN, 1, [Define to 1 if you have the `isnan' function.])
2563 fi
2564 LIBS="$ac_save_LIBS"
2565
2566 dnl *** check for the need to define platform-specific symbols
2567
2568 case $host_cpu in
2569   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
2570   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
2571   *sparc64*)        WINE_CHECK_DEFINE([__sparc64__]) ;;
2572   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
2573   *powerpc64*)      WINE_CHECK_DEFINE([__powerpc64__]) ;;
2574   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
2575   *aarch64*)        WINE_CHECK_DEFINE([__aarch64__]) ;;
2576   *arm*)            WINE_CHECK_DEFINE([__arm__]) ;;
2577 esac
2578
2579 case $host_vendor in
2580   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
2581 esac
2582
2583 dnl **** Generate output files ****
2584
2585 AH_TOP([#ifndef __WINE_CONFIG_H
2586 #define __WINE_CONFIG_H
2587 #ifndef WINE_CROSSTEST])
2588 AH_BOTTOM([#endif /* WINE_CROSSTEST */
2589 #endif /* __WINE_CONFIG_H */])
2590
2591 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
2592 AS_ECHO_N("creating Makefile rules...") >&AS_MESSAGE_FD
2593
2594 dnl Import library rules
2595
2596 AC_SUBST(MAKE_IMPLIB_RULES,"DLLFLAGS = $DLLFLAGS
2597 ")
2598 if test -n "$CROSSTARGET"
2599 then
2600     AS_VAR_APPEND([MAKE_IMPLIB_RULES],"MAKEDEPFLAGS = -xo -xcross.o
2601 all: \$(STATICLIB:.a=.cross.a)
2602 ")
2603 fi
2604
2605 dnl Dll and program rules
2606
2607 if test -n "$DLLEXT"
2608 then
2609     deps="\$(MODULE)$DLLEXT \$(MODULE).fake"
2610 else
2611     deps="\$(MODULE)"
2612 fi
2613
2614 AC_SUBST(MAKE_DLL_RULES,"
2615 DLLFLAGS    = $DLLFLAGS
2616 MAINSPEC    = \$(MODULE:%.dll=%).spec
2617 IDL_TLB_RES = \$(IDL_TLB_SRCS:.idl=_t.res)
2618 MODULEFLAGS = -shared \$(srcdir)/\$(MAINSPEC) \$(EXTRADLLFLAGS)
2619
2620 all: $deps
2621 ")
2622
2623 AC_SUBST(MAKE_PROG_RULES,"
2624 DLLFLAGS    = $DLLFLAGS
2625
2626 all: $deps
2627 ")
2628
2629 dnl Test rules
2630
2631 AC_SUBST(MAKE_TEST_RULES,"
2632 DLLFLAGS     = $DLLFLAGS
2633 TESTMODULE   = \$(TESTDLL:%.dll=%)_test.exe
2634 TESTMODULE_STRIPPED = \$(TESTDLL:%.dll=%)_test-stripped.exe$DLLEXT
2635 WINETEST_RES = \$(top_builddir)/programs/winetest/\$(TESTDLL:%.dll=%)_test.res
2636 RUNTESTFLAGS = -q -P wine -T \$(top_builddir) -M \$(TESTDLL) -p \$(TESTMODULE)$DLLEXT
2637 EXTRA_OBJS   = testlist.o
2638
2639 all: \$(TESTMODULE)$DLLEXT \$(WINETEST_RES)
2640
2641 \$(C_SRCS:.c=.ok): \$(TESTMODULE)$DLLEXT \$(TESTDLL:%=../%$DLLEXT)
2642
2643 check test: \$(C_SRCS:.c=.ok)
2644
2645 .PHONY: check test crosstest
2646 ")
2647 if test -n "$CROSSTARGET"
2648 then
2649     AS_VAR_APPEND([MAKE_TEST_RULES],"
2650 MAKEDEPFLAGS    = -xo -xcross.o
2651 CROSSTESTMODULE = \$(TESTDLL:%.dll=%)_crosstest.exe
2652
2653 crosstest: \$(CROSSTESTMODULE)
2654 ")
2655 fi
2656
2657 dnl Main makefile
2658
2659 WINE_APPEND_RULE([
2660 # Rules automatically generated by configure
2661
2662 .INIT: Makefile
2663 .MAKEFILEDEPS:
2664 all: Makefile
2665 Makefile: Makefile.in Make.vars.in Make.rules config.status
2666         @./config.status Make.tmp Makefile])
2667
2668 WINE_CONFIG_SYMLINK(dlls/shell32,,[AUTHORS])
2669 WINE_CONFIG_SYMLINK(fonts,fonts,[marlett.ttf,symbol.ttf,tahoma.ttf,tahomabd.ttf],enable_fonts)
2670 WINE_CONFIG_SYMLINK(loader,loader,[l_intl.nls])
2671 WINE_CONFIG_SYMLINK(po,po,[LINGUAS])
2672 WINE_CONFIG_SYMLINK(,tools,[wine],,winewrapper)
2673 WINE_CONFIG_SYMLINK(,tools,[wine64],enable_win64,winewrapper)
2674
2675 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/dibdrv)
2676 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
2677 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
2678 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
2679 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
2680 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
2681 WINE_CONFIG_EXTRA_DIR(include/wine)
2682
2683 WINE_CONFIG_MAKERULES([Make.rules],[MAKE_RULES])
2684
2685 WINE_CONFIG_DLL(acledit)
2686 WINE_CONFIG_DLL(aclui,,[implib])
2687 WINE_CONFIG_DLL(activeds,,[implib])
2688 WINE_CONFIG_DLL(actxprxy,,[clean])
2689 WINE_CONFIG_LIB(adsiid)
2690 WINE_CONFIG_DLL(advapi32,,[clean,implib])
2691 WINE_CONFIG_TEST(dlls/advapi32/tests)
2692 WINE_CONFIG_DLL(advpack,,[implib])
2693 WINE_CONFIG_TEST(dlls/advpack/tests)
2694 WINE_CONFIG_DLL(amstream,,[clean])
2695 WINE_CONFIG_TEST(dlls/amstream/tests)
2696 WINE_CONFIG_DLL(api-ms-win-core-localregistry-l1-1-0)
2697 WINE_CONFIG_DLL(api-ms-win-core-processthreads-l1-1-0)
2698 WINE_CONFIG_DLL(api-ms-win-core-winrt-error-l1-1-0)
2699 WINE_CONFIG_DLL(api-ms-win-core-winrt-string-l1-1-0)
2700 WINE_CONFIG_DLL(api-ms-win-downlevel-advapi32-l1-1-0)
2701 WINE_CONFIG_DLL(api-ms-win-downlevel-advapi32-l2-1-0)
2702 WINE_CONFIG_DLL(api-ms-win-downlevel-normaliz-l1-1-0)
2703 WINE_CONFIG_DLL(api-ms-win-downlevel-ole32-l1-1-0)
2704 WINE_CONFIG_DLL(api-ms-win-downlevel-shell32-l1-1-0)
2705 WINE_CONFIG_DLL(api-ms-win-downlevel-shlwapi-l1-1-0)
2706 WINE_CONFIG_DLL(api-ms-win-downlevel-shlwapi-l2-1-0)
2707 WINE_CONFIG_DLL(api-ms-win-downlevel-user32-l1-1-0)
2708 WINE_CONFIG_DLL(api-ms-win-downlevel-version-l1-1-0)
2709 WINE_CONFIG_DLL(api-ms-win-security-base-l1-1-0)
2710 WINE_CONFIG_DLL(apphelp)
2711 WINE_CONFIG_TEST(dlls/apphelp/tests)
2712 WINE_CONFIG_DLL(appwiz.cpl,,[po])
2713 WINE_CONFIG_DLL(atl,,[clean,implib])
2714 WINE_CONFIG_TEST(dlls/atl/tests)
2715 WINE_CONFIG_DLL(atl100,,[implib])
2716 WINE_CONFIG_TEST(dlls/atl100/tests)
2717 WINE_CONFIG_DLL(atl110)
2718 WINE_CONFIG_DLL(atl80,,[implib])
2719 WINE_CONFIG_TEST(dlls/atl80/tests)
2720 WINE_CONFIG_DLL(atl90)
2721 WINE_CONFIG_DLL(authz)
2722 WINE_CONFIG_DLL(avicap32,,[implib])
2723 WINE_CONFIG_DLL(avifil32,,[clean,implib,po])
2724 WINE_CONFIG_TEST(dlls/avifil32/tests)
2725 WINE_CONFIG_DLL(avifile.dll16,enable_win16)
2726 WINE_CONFIG_DLL(avrt,,[implib])
2727 WINE_CONFIG_DLL(bcrypt)
2728 WINE_CONFIG_DLL(browseui,,[clean,po])
2729 WINE_CONFIG_TEST(dlls/browseui/tests)
2730 WINE_CONFIG_DLL(cabinet,,[implib])
2731 WINE_CONFIG_TEST(dlls/cabinet/tests)
2732 WINE_CONFIG_DLL(capi2032,,[implib])
2733 WINE_CONFIG_DLL(cards,,[implib])
2734 WINE_CONFIG_DLL(cfgmgr32,,[implib])
2735 WINE_CONFIG_DLL(clusapi,,[implib])
2736 WINE_CONFIG_DLL(comcat)
2737 WINE_CONFIG_TEST(dlls/comcat/tests)
2738 WINE_CONFIG_DLL(comctl32,,[implib,po])
2739 WINE_CONFIG_TEST(dlls/comctl32/tests)
2740 WINE_CONFIG_DLL(comdlg32,,[clean,implib,po])
2741 WINE_CONFIG_TEST(dlls/comdlg32/tests)
2742 WINE_CONFIG_DLL(comm.drv16,enable_win16)
2743 WINE_CONFIG_DLL(commdlg.dll16,enable_win16)
2744 WINE_CONFIG_DLL(compobj.dll16,enable_win16)
2745 WINE_CONFIG_DLL(compstui,,[implib])
2746 WINE_CONFIG_DLL(comsvcs,,[implib])
2747 WINE_CONFIG_DLL(credui,,[implib,po])
2748 WINE_CONFIG_TEST(dlls/credui/tests)
2749 WINE_CONFIG_DLL(crtdll,,[implib])
2750 WINE_CONFIG_DLL(crypt32,,[implib,po])
2751 WINE_CONFIG_TEST(dlls/crypt32/tests)
2752 WINE_CONFIG_DLL(cryptdlg,,[po])
2753 WINE_CONFIG_DLL(cryptdll,,[implib])
2754 WINE_CONFIG_DLL(cryptnet,,[implib])
2755 WINE_CONFIG_TEST(dlls/cryptnet/tests)
2756 WINE_CONFIG_DLL(cryptui,,[implib,po])
2757 WINE_CONFIG_TEST(dlls/cryptui/tests)
2758 WINE_CONFIG_DLL(ctapi32)
2759 WINE_CONFIG_DLL(ctl3d.dll16,enable_win16)
2760 WINE_CONFIG_DLL(ctl3d32,,[implib])
2761 WINE_CONFIG_DLL(ctl3dv2.dll16,enable_win16)
2762 WINE_CONFIG_DLL(d3d10,,[implib])
2763 WINE_CONFIG_TEST(dlls/d3d10/tests)
2764 WINE_CONFIG_DLL(d3d10core,,[implib])
2765 WINE_CONFIG_TEST(dlls/d3d10core/tests)
2766 WINE_CONFIG_DLL(d3d11)
2767 WINE_CONFIG_DLL(d3d8,,[implib])
2768 WINE_CONFIG_TEST(dlls/d3d8/tests)
2769 WINE_CONFIG_DLL(d3d9,,[implib])
2770 WINE_CONFIG_TEST(dlls/d3d9/tests)
2771 WINE_CONFIG_DLL(d3dcompiler_33)
2772 WINE_CONFIG_DLL(d3dcompiler_34)
2773 WINE_CONFIG_DLL(d3dcompiler_35)
2774 WINE_CONFIG_DLL(d3dcompiler_36)
2775 WINE_CONFIG_DLL(d3dcompiler_37)
2776 WINE_CONFIG_DLL(d3dcompiler_38)
2777 WINE_CONFIG_DLL(d3dcompiler_39)
2778 WINE_CONFIG_DLL(d3dcompiler_40)
2779 WINE_CONFIG_DLL(d3dcompiler_41)
2780 WINE_CONFIG_DLL(d3dcompiler_42)
2781 WINE_CONFIG_DLL(d3dcompiler_43,,[implib],[d3dcompiler])
2782 WINE_CONFIG_TEST(dlls/d3dcompiler_43/tests)
2783 WINE_CONFIG_DLL(d3dim,,[implib])
2784 WINE_CONFIG_DLL(d3drm,,[implib])
2785 WINE_CONFIG_TEST(dlls/d3drm/tests)
2786 WINE_CONFIG_DLL(d3dx10_33)
2787 WINE_CONFIG_DLL(d3dx10_34)
2788 WINE_CONFIG_DLL(d3dx10_35)
2789 WINE_CONFIG_DLL(d3dx10_36)
2790 WINE_CONFIG_DLL(d3dx10_37)
2791 WINE_CONFIG_DLL(d3dx10_38)
2792 WINE_CONFIG_DLL(d3dx10_39)
2793 WINE_CONFIG_DLL(d3dx10_40)
2794 WINE_CONFIG_DLL(d3dx10_41)
2795 WINE_CONFIG_DLL(d3dx10_42)
2796 WINE_CONFIG_DLL(d3dx10_43)
2797 WINE_CONFIG_DLL(d3dx11_42)
2798 WINE_CONFIG_DLL(d3dx11_43)
2799 WINE_CONFIG_DLL(d3dx9_24)
2800 WINE_CONFIG_DLL(d3dx9_25)
2801 WINE_CONFIG_DLL(d3dx9_26)
2802 WINE_CONFIG_DLL(d3dx9_27)
2803 WINE_CONFIG_DLL(d3dx9_28)
2804 WINE_CONFIG_DLL(d3dx9_29)
2805 WINE_CONFIG_DLL(d3dx9_30)
2806 WINE_CONFIG_DLL(d3dx9_31)
2807 WINE_CONFIG_DLL(d3dx9_32)
2808 WINE_CONFIG_DLL(d3dx9_33)
2809 WINE_CONFIG_DLL(d3dx9_34)
2810 WINE_CONFIG_DLL(d3dx9_35)
2811 WINE_CONFIG_DLL(d3dx9_36,,[implib],[d3dx9])
2812 WINE_CONFIG_TEST(dlls/d3dx9_36/tests)
2813 WINE_CONFIG_DLL(d3dx9_37)
2814 WINE_CONFIG_DLL(d3dx9_38)
2815 WINE_CONFIG_DLL(d3dx9_39)
2816 WINE_CONFIG_DLL(d3dx9_40)
2817 WINE_CONFIG_DLL(d3dx9_41)
2818 WINE_CONFIG_DLL(d3dx9_42)
2819 WINE_CONFIG_DLL(d3dx9_43)
2820 WINE_CONFIG_DLL(d3dxof,,[clean,implib])
2821 WINE_CONFIG_TEST(dlls/d3dxof/tests)
2822 WINE_CONFIG_DLL(dbgeng,,[implib])
2823 WINE_CONFIG_DLL(dbghelp,,[implib])
2824 WINE_CONFIG_DLL(dciman32,,[implib])
2825 WINE_CONFIG_DLL(ddeml.dll16,enable_win16)
2826 WINE_CONFIG_DLL(ddraw,,[clean,implib])
2827 WINE_CONFIG_TEST(dlls/ddraw/tests)
2828 WINE_CONFIG_DLL(ddrawex,,[clean])
2829 WINE_CONFIG_TEST(dlls/ddrawex/tests)
2830 WINE_CONFIG_DLL(devenum,,[clean,po])
2831 WINE_CONFIG_TEST(dlls/devenum/tests)
2832 WINE_CONFIG_DLL(dhcpcsvc)
2833 WINE_CONFIG_DLL(difxapi)
2834 WINE_CONFIG_DLL(dinput,,[clean,implib,po,staticimplib])
2835 WINE_CONFIG_TEST(dlls/dinput/tests)
2836 WINE_CONFIG_DLL(dinput8,,[clean,implib])
2837 WINE_CONFIG_TEST(dlls/dinput8/tests)
2838 WINE_CONFIG_DLL(dispdib.dll16,enable_win16)
2839 WINE_CONFIG_DLL(dispex,,[clean])
2840 WINE_CONFIG_TEST(dlls/dispex/tests)
2841 WINE_CONFIG_DLL(display.drv16,enable_win16)
2842 WINE_CONFIG_DLL(dmband,,[clean])
2843 WINE_CONFIG_TEST(dlls/dmband/tests)
2844 WINE_CONFIG_DLL(dmcompos,,[clean])
2845 WINE_CONFIG_DLL(dmime,,[clean])
2846 WINE_CONFIG_TEST(dlls/dmime/tests)
2847 WINE_CONFIG_DLL(dmloader,,[clean])
2848 WINE_CONFIG_TEST(dlls/dmloader/tests)
2849 WINE_CONFIG_DLL(dmscript,,[clean])
2850 WINE_CONFIG_DLL(dmstyle,,[clean])
2851 WINE_CONFIG_DLL(dmsynth,,[clean])
2852 WINE_CONFIG_TEST(dlls/dmsynth/tests)
2853 WINE_CONFIG_DLL(dmusic,,[clean])
2854 WINE_CONFIG_TEST(dlls/dmusic/tests)
2855 WINE_CONFIG_DLL(dmusic32,,[implib])
2856 WINE_CONFIG_DLL(dnsapi,,[implib])
2857 WINE_CONFIG_TEST(dlls/dnsapi/tests)
2858 WINE_CONFIG_DLL(dplay,,[implib])
2859 WINE_CONFIG_DLL(dplayx,,[clean,implib])
2860 WINE_CONFIG_TEST(dlls/dplayx/tests)
2861 WINE_CONFIG_DLL(dpnaddr)
2862 WINE_CONFIG_DLL(dpnet,,[clean,implib])
2863 WINE_CONFIG_TEST(dlls/dpnet/tests)
2864 WINE_CONFIG_DLL(dpnhpast)
2865 WINE_CONFIG_DLL(dpnlobby)
2866 WINE_CONFIG_DLL(dpwsockx)
2867 WINE_CONFIG_DLL(drmclien)
2868 WINE_CONFIG_DLL(dsound,,[clean,implib])
2869 WINE_CONFIG_TEST(dlls/dsound/tests)
2870 WINE_CONFIG_DLL(dssenh)
2871 WINE_CONFIG_TEST(dlls/dssenh/tests)
2872 WINE_CONFIG_DLL(dswave,,[clean])
2873 WINE_CONFIG_DLL(dwmapi,,[implib])
2874 WINE_CONFIG_DLL(dwrite,,[implib])
2875 WINE_CONFIG_TEST(dlls/dwrite/tests)
2876 WINE_CONFIG_DLL(dxdiagn,,[clean,po])
2877 WINE_CONFIG_TEST(dlls/dxdiagn/tests)
2878 WINE_CONFIG_LIB(dxerr8)
2879 WINE_CONFIG_LIB(dxerr9)
2880 WINE_CONFIG_DLL(dxgi,,[implib])
2881 WINE_CONFIG_TEST(dlls/dxgi/tests)
2882 WINE_CONFIG_LIB(dxguid)
2883 WINE_CONFIG_DLL(explorerframe,,[clean])
2884 WINE_CONFIG_TEST(dlls/explorerframe/tests)
2885 WINE_CONFIG_DLL(faultrep,,[implib])
2886 WINE_CONFIG_TEST(dlls/faultrep/tests)
2887 WINE_CONFIG_DLL(fltlib)
2888 WINE_CONFIG_DLL(fusion)
2889 WINE_CONFIG_TEST(dlls/fusion/tests)
2890 WINE_CONFIG_DLL(fwpuclnt)
2891 WINE_CONFIG_DLL(gameux,,[clean])
2892 WINE_CONFIG_TEST(dlls/gameux/tests)
2893 WINE_CONFIG_DLL(gdi.exe16,enable_win16)
2894 WINE_CONFIG_DLL(gdi32,,[implib,po])
2895 WINE_CONFIG_TEST(dlls/gdi32/tests)
2896 WINE_CONFIG_DLL(gdiplus,,[implib])
2897 WINE_CONFIG_TEST(dlls/gdiplus/tests)
2898 WINE_CONFIG_DLL(glu32,,[implib])
2899 WINE_CONFIG_DLL(gphoto2.ds,,[po])
2900 WINE_CONFIG_DLL(gpkcsp)
2901 WINE_CONFIG_DLL(hal)
2902 WINE_CONFIG_DLL(hhctrl.ocx,,[clean,implib,po],[htmlhelp])
2903 WINE_CONFIG_DLL(hid,,[implib])
2904 WINE_CONFIG_DLL(hlink,,[clean,implib])
2905 WINE_CONFIG_TEST(dlls/hlink/tests)
2906 WINE_CONFIG_DLL(hnetcfg,,[clean])
2907 WINE_CONFIG_DLL(httpapi)
2908 WINE_CONFIG_DLL(iccvid,,[po])
2909 WINE_CONFIG_DLL(icmp)
2910 WINE_CONFIG_DLL(ieframe,,[clean,implib,po])
2911 WINE_CONFIG_TEST(dlls/ieframe/tests)
2912 WINE_CONFIG_DLL(ifsmgr.vxd,enable_win16)
2913 WINE_CONFIG_DLL(imaadp32.acm)
2914 WINE_CONFIG_DLL(imagehlp,,[implib])
2915 WINE_CONFIG_TEST(dlls/imagehlp/tests)
2916 WINE_CONFIG_DLL(imm.dll16,enable_win16)
2917 WINE_CONFIG_DLL(imm32,,[implib])
2918 WINE_CONFIG_TEST(dlls/imm32/tests)
2919 WINE_CONFIG_DLL(inetcomm,,[clean,implib])
2920 WINE_CONFIG_TEST(dlls/inetcomm/tests)
2921 WINE_CONFIG_DLL(inetcpl.cpl,,[po])
2922 WINE_CONFIG_DLL(inetmib1)
2923 WINE_CONFIG_TEST(dlls/inetmib1/tests)
2924 WINE_CONFIG_DLL(infosoft,,[clean])
2925 WINE_CONFIG_TEST(dlls/infosoft/tests)
2926 WINE_CONFIG_DLL(initpki)
2927 WINE_CONFIG_DLL(inkobj)
2928 WINE_CONFIG_DLL(inseng,,[clean])
2929 WINE_CONFIG_DLL(iphlpapi,,[implib])
2930 WINE_CONFIG_TEST(dlls/iphlpapi/tests)
2931 WINE_CONFIG_DLL(itircl)
2932 WINE_CONFIG_DLL(itss,,[clean])
2933 WINE_CONFIG_TEST(dlls/itss/tests)
2934 WINE_CONFIG_DLL(joy.cpl,,[po])
2935 WINE_CONFIG_DLL(jscript,,[clean,po])
2936 WINE_CONFIG_TEST(dlls/jscript/tests)
2937 WINE_CONFIG_DLL(kernel32,,[implib,mc])
2938 WINE_CONFIG_TEST(dlls/kernel32/tests)
2939 WINE_CONFIG_DLL(keyboard.drv16,enable_win16)
2940 WINE_CONFIG_DLL(krnl386.exe16,enable_win16,[implib],[kernel])
2941 WINE_CONFIG_DLL(ktmw32)
2942 WINE_CONFIG_DLL(loadperf,,[implib])
2943 WINE_CONFIG_DLL(localspl,,[po])
2944 WINE_CONFIG_TEST(dlls/localspl/tests)
2945 WINE_CONFIG_DLL(localui,,[po])
2946 WINE_CONFIG_TEST(dlls/localui/tests)
2947 WINE_CONFIG_DLL(lz32,,[implib])
2948 WINE_CONFIG_TEST(dlls/lz32/tests)
2949 WINE_CONFIG_DLL(lzexpand.dll16,enable_win16)
2950 WINE_CONFIG_DLL(mapi32,,[implib,po])
2951 WINE_CONFIG_TEST(dlls/mapi32/tests)
2952 WINE_CONFIG_DLL(mapistub)
2953 WINE_CONFIG_DLL(mciavi32)
2954 WINE_CONFIG_DLL(mcicda)
2955 WINE_CONFIG_DLL(mciqtz32)
2956 WINE_CONFIG_DLL(mciseq)
2957 WINE_CONFIG_DLL(mciwave)
2958 WINE_CONFIG_DLL(mgmtapi)
2959 WINE_CONFIG_DLL(midimap)
2960 WINE_CONFIG_DLL(mlang,,[clean,implib])
2961 WINE_CONFIG_TEST(dlls/mlang/tests)
2962 WINE_CONFIG_DLL(mmcndmgr,,[clean])
2963 WINE_CONFIG_TEST(dlls/mmcndmgr/tests)
2964 WINE_CONFIG_DLL(mmdevapi,,[clean])
2965 WINE_CONFIG_TEST(dlls/mmdevapi/tests)
2966 WINE_CONFIG_DLL(mmdevldr.vxd,enable_win16)
2967 WINE_CONFIG_DLL(mmsystem.dll16,enable_win16)
2968 WINE_CONFIG_DLL(monodebg.vxd,enable_win16)
2969 WINE_CONFIG_DLL(mountmgr.sys)
2970 WINE_CONFIG_DLL(mouse.drv16,enable_win16)
2971 WINE_CONFIG_DLL(mpr,,[implib,po])
2972 WINE_CONFIG_TEST(dlls/mpr/tests)
2973 WINE_CONFIG_DLL(mprapi,,[implib])
2974 WINE_CONFIG_DLL(msacm.dll16,enable_win16)
2975 WINE_CONFIG_DLL(msacm32.drv)
2976 WINE_CONFIG_DLL(msacm32,,[implib,po])
2977 WINE_CONFIG_TEST(dlls/msacm32/tests)
2978 WINE_CONFIG_DLL(msadp32.acm)
2979 WINE_CONFIG_DLL(mscat32)
2980 WINE_CONFIG_DLL(mscms,,[implib])
2981 WINE_CONFIG_TEST(dlls/mscms/tests)
2982 WINE_CONFIG_DLL(mscoree,,[clean])
2983 WINE_CONFIG_TEST(dlls/mscoree/tests)
2984 WINE_CONFIG_DLL(msctf,,[clean])
2985 WINE_CONFIG_TEST(dlls/msctf/tests)
2986 WINE_CONFIG_DLL(msdaps,,[clean])
2987 WINE_CONFIG_DLL(msdmo,,[implib])
2988 WINE_CONFIG_DLL(msftedit)
2989 WINE_CONFIG_DLL(msg711.acm)
2990 WINE_CONFIG_DLL(msgsm32.acm)
2991 WINE_CONFIG_DLL(mshtml.tlb,,[clean])
2992 WINE_CONFIG_DLL(mshtml,,[clean,implib,po])
2993 WINE_CONFIG_TEST(dlls/mshtml/tests,[clean])
2994 WINE_CONFIG_DLL(msi,,[clean,implib,po])
2995 WINE_CONFIG_TEST(dlls/msi/tests)
2996 WINE_CONFIG_DLL(msident,,[clean])
2997 WINE_CONFIG_DLL(msimg32,,[implib])
2998 WINE_CONFIG_DLL(msimsg)
2999 WINE_CONFIG_DLL(msimtf,,[clean])
3000 WINE_CONFIG_DLL(msisip)
3001 WINE_CONFIG_DLL(msisys.ocx)
3002 WINE_CONFIG_DLL(msls31)
3003 WINE_CONFIG_DLL(msnet32)
3004 WINE_CONFIG_DLL(mspatcha)
3005 WINE_CONFIG_DLL(msrle32,,[po])
3006 WINE_CONFIG_DLL(mssign32)
3007 WINE_CONFIG_DLL(mssip32)
3008 WINE_CONFIG_DLL(mstask,,[clean])
3009 WINE_CONFIG_TEST(dlls/mstask/tests)
3010 WINE_CONFIG_DLL(msvcirt)
3011 WINE_CONFIG_DLL(msvcm80)
3012 WINE_CONFIG_DLL(msvcm90)
3013 WINE_CONFIG_DLL(msvcp100)
3014 WINE_CONFIG_TEST(dlls/msvcp100/tests)
3015 WINE_CONFIG_DLL(msvcp110)
3016 WINE_CONFIG_DLL(msvcp60)
3017 WINE_CONFIG_TEST(dlls/msvcp60/tests)
3018 WINE_CONFIG_DLL(msvcp70)
3019 WINE_CONFIG_DLL(msvcp71)
3020 WINE_CONFIG_DLL(msvcp80)
3021 WINE_CONFIG_DLL(msvcp90)
3022 WINE_CONFIG_TEST(dlls/msvcp90/tests)
3023 WINE_CONFIG_DLL(msvcr100)
3024 WINE_CONFIG_TEST(dlls/msvcr100/tests)
3025 WINE_CONFIG_DLL(msvcr110)
3026 WINE_CONFIG_DLL(msvcr70,,[implib])
3027 WINE_CONFIG_DLL(msvcr71,,[implib])
3028 WINE_CONFIG_DLL(msvcr80)
3029 WINE_CONFIG_DLL(msvcr90)
3030 WINE_CONFIG_TEST(dlls/msvcr90/tests)
3031 WINE_CONFIG_DLL(msvcrt,,[implib])
3032 WINE_CONFIG_TEST(dlls/msvcrt/tests)
3033 WINE_CONFIG_DLL(msvcrt20,,[implib])
3034 WINE_CONFIG_DLL(msvcrt40,,[implib])
3035 WINE_CONFIG_DLL(msvcrtd,,[implib])
3036 WINE_CONFIG_TEST(dlls/msvcrtd/tests)
3037 WINE_CONFIG_DLL(msvfw32,,[implib,po])
3038 WINE_CONFIG_TEST(dlls/msvfw32/tests)
3039 WINE_CONFIG_DLL(msvidc32,,[po])
3040 WINE_CONFIG_DLL(msvideo.dll16,enable_win16)
3041 WINE_CONFIG_DLL(mswsock,,[implib])
3042 WINE_CONFIG_DLL(msxml,,[clean])
3043 WINE_CONFIG_DLL(msxml2,,[clean])
3044 WINE_CONFIG_DLL(msxml3,,[clean])
3045 WINE_CONFIG_TEST(dlls/msxml3/tests,[clean])
3046 WINE_CONFIG_DLL(msxml4,,[clean])
3047 WINE_CONFIG_DLL(msxml6,,[clean])
3048 WINE_CONFIG_DLL(nddeapi,,[implib])
3049 WINE_CONFIG_DLL(netapi32,,[implib])
3050 WINE_CONFIG_TEST(dlls/netapi32/tests)
3051 WINE_CONFIG_DLL(netcfgx)
3052 WINE_CONFIG_DLL(newdev,,[implib])
3053 WINE_CONFIG_DLL(normaliz,,[implib])
3054 WINE_CONFIG_DLL(npmshtml)
3055 WINE_CONFIG_DLL(ntdll,,[implib])
3056 WINE_CONFIG_TEST(dlls/ntdll/tests)
3057 WINE_CONFIG_DLL(ntdsapi,,[implib])
3058 WINE_CONFIG_TEST(dlls/ntdsapi/tests)
3059 WINE_CONFIG_DLL(ntoskrnl.exe,,[implib])
3060 WINE_CONFIG_DLL(ntprint)
3061 WINE_CONFIG_TEST(dlls/ntprint/tests)
3062 WINE_CONFIG_DLL(objsel,,[clean])
3063 WINE_CONFIG_DLL(odbc32,,[implib])
3064 WINE_CONFIG_DLL(odbccp32,,[implib])
3065 WINE_CONFIG_TEST(dlls/odbccp32/tests)
3066 WINE_CONFIG_DLL(odbccu32)
3067 WINE_CONFIG_DLL(ole2.dll16,enable_win16)
3068 WINE_CONFIG_DLL(ole2conv.dll16,enable_win16)
3069 WINE_CONFIG_DLL(ole2disp.dll16,enable_win16)
3070 WINE_CONFIG_DLL(ole2nls.dll16,enable_win16)
3071 WINE_CONFIG_DLL(ole2prox.dll16,enable_win16)
3072 WINE_CONFIG_DLL(ole2thk.dll16,enable_win16)
3073 WINE_CONFIG_DLL(ole32,,[clean,implib])
3074 WINE_CONFIG_TEST(dlls/ole32/tests)
3075 WINE_CONFIG_DLL(oleacc,,[clean,implib,po])
3076 WINE_CONFIG_TEST(dlls/oleacc/tests)
3077 WINE_CONFIG_DLL(oleaut32,,[clean,implib,po])
3078 WINE_CONFIG_TEST(dlls/oleaut32/tests,[clean])
3079 WINE_CONFIG_DLL(olecli.dll16,enable_win16)
3080 WINE_CONFIG_DLL(olecli32,,[implib])
3081 WINE_CONFIG_DLL(oledb32,,[clean])
3082 WINE_CONFIG_TEST(dlls/oledb32/tests,[clean])
3083 WINE_CONFIG_DLL(oledlg,,[implib,po])
3084 WINE_CONFIG_DLL(olepro32,,[implib])
3085 WINE_CONFIG_DLL(olesvr.dll16,enable_win16)
3086 WINE_CONFIG_DLL(olesvr32,,[implib])
3087 WINE_CONFIG_DLL(olethk32)
3088 WINE_CONFIG_DLL(openal32)
3089 WINE_CONFIG_DLL(opencl)
3090 WINE_CONFIG_DLL(opengl32,,[implib])
3091 WINE_CONFIG_TEST(dlls/opengl32/tests)
3092 WINE_CONFIG_DLL(pdh,,[implib])
3093 WINE_CONFIG_TEST(dlls/pdh/tests)
3094 WINE_CONFIG_DLL(photometadatahandler)
3095 WINE_CONFIG_DLL(pidgen)
3096 WINE_CONFIG_DLL(powrprof,,[implib])
3097 WINE_CONFIG_DLL(printui)
3098 WINE_CONFIG_DLL(propsys,,[clean,implib])
3099 WINE_CONFIG_TEST(dlls/propsys/tests)
3100 WINE_CONFIG_DLL(psapi,,[implib])
3101 WINE_CONFIG_TEST(dlls/psapi/tests)
3102 WINE_CONFIG_DLL(pstorec,,[clean])
3103 WINE_CONFIG_DLL(qcap)
3104 WINE_CONFIG_TEST(dlls/qcap/tests)
3105 WINE_CONFIG_DLL(qedit,,[clean])
3106 WINE_CONFIG_TEST(dlls/qedit/tests)
3107 WINE_CONFIG_DLL(qmgr,,[clean])
3108 WINE_CONFIG_TEST(dlls/qmgr/tests)
3109 WINE_CONFIG_DLL(qmgrprxy,,[clean])
3110 WINE_CONFIG_DLL(quartz,,[clean,implib])
3111 WINE_CONFIG_TEST(dlls/quartz/tests,[clean])
3112 WINE_CONFIG_DLL(query)
3113 WINE_CONFIG_DLL(rasapi16.dll16,enable_win16)
3114 WINE_CONFIG_DLL(rasapi32,,[implib])
3115 WINE_CONFIG_TEST(dlls/rasapi32/tests)
3116 WINE_CONFIG_DLL(rasdlg,,[implib])
3117 WINE_CONFIG_DLL(regapi)
3118 WINE_CONFIG_DLL(resutils,,[implib])
3119 WINE_CONFIG_DLL(riched20,,[implib])
3120 WINE_CONFIG_TEST(dlls/riched20/tests)
3121 WINE_CONFIG_DLL(riched32)
3122 WINE_CONFIG_TEST(dlls/riched32/tests)
3123 WINE_CONFIG_DLL(rpcrt4,,[clean,implib])
3124 WINE_CONFIG_TEST(dlls/rpcrt4/tests,[clean])
3125 WINE_CONFIG_DLL(rsabase)
3126 WINE_CONFIG_DLL(rsaenh,,[implib])
3127 WINE_CONFIG_TEST(dlls/rsaenh/tests)
3128 WINE_CONFIG_DLL(rstrtmgr)
3129 WINE_CONFIG_DLL(rtutils,,[implib])
3130 WINE_CONFIG_DLL(samlib)
3131 WINE_CONFIG_DLL(sane.ds,,[po])
3132 WINE_CONFIG_DLL(scarddlg)
3133 WINE_CONFIG_DLL(sccbase)
3134 WINE_CONFIG_DLL(schannel)
3135 WINE_CONFIG_TEST(dlls/schannel/tests)
3136 WINE_CONFIG_DLL(scrrun,,[clean])
3137 WINE_CONFIG_TEST(dlls/scrrun/tests,[clean])
3138 WINE_CONFIG_DLL(scsiport.sys)
3139 WINE_CONFIG_DLL(secur32,,[implib])
3140 WINE_CONFIG_TEST(dlls/secur32/tests)
3141 WINE_CONFIG_DLL(security)
3142 WINE_CONFIG_DLL(sensapi,,[implib])
3143 WINE_CONFIG_DLL(serialui,,[implib,po])
3144 WINE_CONFIG_TEST(dlls/serialui/tests)
3145 WINE_CONFIG_DLL(setupapi,,[implib,po])
3146 WINE_CONFIG_TEST(dlls/setupapi/tests)
3147 WINE_CONFIG_DLL(setupx.dll16,enable_win16)
3148 WINE_CONFIG_DLL(sfc,,[implib])
3149 WINE_CONFIG_DLL(sfc_os,,[implib])
3150 WINE_CONFIG_DLL(shdoclc,,[po])
3151 WINE_CONFIG_DLL(shdocvw,,[clean,implib])
3152 WINE_CONFIG_TEST(dlls/shdocvw/tests)
3153 WINE_CONFIG_DLL(shell.dll16,enable_win16)
3154 WINE_CONFIG_DLL(shell32,,[clean,implib,po])
3155 WINE_CONFIG_TEST(dlls/shell32/tests)
3156 WINE_CONFIG_DLL(shfolder,,[implib])
3157 WINE_CONFIG_DLL(shlwapi,,[implib,po])
3158 WINE_CONFIG_TEST(dlls/shlwapi/tests)
3159 WINE_CONFIG_DLL(slbcsp)
3160 WINE_CONFIG_DLL(slc,,[implib])
3161 WINE_CONFIG_DLL(snmpapi,,[implib])
3162 WINE_CONFIG_TEST(dlls/snmpapi/tests)
3163 WINE_CONFIG_DLL(softpub)
3164 WINE_CONFIG_DLL(sound.drv16,enable_win16)
3165 WINE_CONFIG_DLL(spoolss,,[implib])
3166 WINE_CONFIG_TEST(dlls/spoolss/tests)
3167 WINE_CONFIG_DLL(stdole2.tlb,,[clean])
3168 WINE_CONFIG_DLL(stdole32.tlb,,[clean])
3169 WINE_CONFIG_DLL(sti,,[clean,implib])
3170 WINE_CONFIG_TEST(dlls/sti/tests)
3171 WINE_CONFIG_DLL(storage.dll16,enable_win16)
3172 WINE_CONFIG_DLL(stress.dll16,enable_win16)
3173 WINE_CONFIG_LIB(strmbase)
3174 WINE_CONFIG_LIB(strmiids)
3175 WINE_CONFIG_DLL(svrapi)
3176 WINE_CONFIG_DLL(sxs,,[implib])
3177 WINE_CONFIG_TEST(dlls/sxs/tests)
3178 WINE_CONFIG_DLL(system.drv16,enable_win16)
3179 WINE_CONFIG_DLL(t2embed)
3180 WINE_CONFIG_DLL(tapi32,,[implib])
3181 WINE_CONFIG_DLL(toolhelp.dll16,enable_win16)
3182 WINE_CONFIG_DLL(traffic)
3183 WINE_CONFIG_DLL(twain.dll16,enable_win16)
3184 WINE_CONFIG_DLL(twain_32)
3185 WINE_CONFIG_TEST(dlls/twain_32/tests)
3186 WINE_CONFIG_DLL(typelib.dll16,enable_win16)
3187 WINE_CONFIG_DLL(unicows,,[implib])
3188 WINE_CONFIG_DLL(updspapi)
3189 WINE_CONFIG_DLL(url,,[implib])
3190 WINE_CONFIG_DLL(urlmon,,[clean,implib,po])
3191 WINE_CONFIG_TEST(dlls/urlmon/tests)
3192 WINE_CONFIG_DLL(usbd.sys,,[implib])
3193 WINE_CONFIG_DLL(user.exe16,enable_win16)
3194 WINE_CONFIG_DLL(user32,,[implib,po])
3195 WINE_CONFIG_TEST(dlls/user32/tests)
3196 WINE_CONFIG_DLL(userenv,,[implib])
3197 WINE_CONFIG_TEST(dlls/userenv/tests)
3198 WINE_CONFIG_DLL(usp10,,[implib])
3199 WINE_CONFIG_TEST(dlls/usp10/tests)
3200 WINE_CONFIG_LIB(uuid)
3201 WINE_CONFIG_DLL(uxtheme,,[implib])
3202 WINE_CONFIG_TEST(dlls/uxtheme/tests)
3203 WINE_CONFIG_DLL(vbscript,,[clean])
3204 WINE_CONFIG_TEST(dlls/vbscript/tests,[clean])
3205 WINE_CONFIG_DLL(vcomp)
3206 WINE_CONFIG_DLL(vcomp100)
3207 WINE_CONFIG_DLL(vcomp90)
3208 WINE_CONFIG_DLL(vdhcp.vxd,enable_win16)
3209 WINE_CONFIG_DLL(vdmdbg,,[implib])
3210 WINE_CONFIG_DLL(ver.dll16,enable_win16)
3211 WINE_CONFIG_DLL(version,,[implib])
3212 WINE_CONFIG_TEST(dlls/version/tests)
3213 WINE_CONFIG_DLL(vmm.vxd,enable_win16)
3214 WINE_CONFIG_DLL(vnbt.vxd,enable_win16)
3215 WINE_CONFIG_DLL(vnetbios.vxd,enable_win16)
3216 WINE_CONFIG_DLL(vtdapi.vxd,enable_win16)
3217 WINE_CONFIG_DLL(vwin32.vxd,enable_win16)
3218 WINE_CONFIG_DLL(w32skrnl,enable_win16)
3219 WINE_CONFIG_DLL(w32sys.dll16,enable_win16)
3220 WINE_CONFIG_DLL(wbemdisp,,[clean])
3221 WINE_CONFIG_DLL(wbemprox,,[clean])
3222 WINE_CONFIG_TEST(dlls/wbemprox/tests)
3223 WINE_CONFIG_DLL(webservices,,[implib])
3224 WINE_CONFIG_DLL(wer,,[implib])
3225 WINE_CONFIG_TEST(dlls/wer/tests)
3226 WINE_CONFIG_DLL(wevtapi)
3227 WINE_CONFIG_DLL(wiaservc,,[clean])
3228 WINE_CONFIG_DLL(win32s16.dll16,enable_win16)
3229 WINE_CONFIG_DLL(win87em.dll16,enable_win16)
3230 WINE_CONFIG_DLL(winaspi.dll16,enable_win16)
3231 WINE_CONFIG_DLL(windebug.dll16,enable_win16)
3232 WINE_CONFIG_DLL(windowscodecs,,[clean,implib])
3233 WINE_CONFIG_TEST(dlls/windowscodecs/tests)
3234 WINE_CONFIG_DLL(windowscodecsext,,[implib])
3235 WINE_CONFIG_TEST(dlls/windowscodecsext/tests)
3236 WINE_CONFIG_DLL(winealsa.drv)
3237 WINE_CONFIG_DLL(winecoreaudio.drv)
3238 WINE_CONFIG_LIB(winecrt0)
3239 WINE_CONFIG_DLL(wined3d,,[implib])
3240 WINE_CONFIG_DLL(winegstreamer)
3241 WINE_CONFIG_DLL(winejoystick.drv)
3242 WINE_CONFIG_DLL(winemac.drv)
3243 WINE_CONFIG_DLL(winemapi)
3244 WINE_CONFIG_DLL(winemp3.acm)
3245 WINE_CONFIG_DLL(wineoss.drv)
3246 WINE_CONFIG_DLL(wineps.drv,,[po])
3247 WINE_CONFIG_DLL(wineps16.drv16,enable_win16)
3248 WINE_CONFIG_DLL(wineqtdecoder)
3249 WINE_CONFIG_DLL(winex11.drv)
3250 WINE_CONFIG_DLL(wing.dll16,enable_win16)
3251 WINE_CONFIG_DLL(wing32)
3252 WINE_CONFIG_DLL(winhttp,,[clean,implib])
3253 WINE_CONFIG_TEST(dlls/winhttp/tests)
3254 WINE_CONFIG_DLL(wininet,,[implib,po])
3255 WINE_CONFIG_TEST(dlls/wininet/tests)
3256 WINE_CONFIG_DLL(winmm,,[implib,po])
3257 WINE_CONFIG_TEST(dlls/winmm/tests)
3258 WINE_CONFIG_DLL(winnls.dll16,enable_win16)
3259 WINE_CONFIG_DLL(winnls32,,[implib])
3260 WINE_CONFIG_DLL(winscard,,[implib])
3261 WINE_CONFIG_DLL(winsock.dll16,enable_win16)
3262 WINE_CONFIG_DLL(winspool.drv,,[implib,po],[winspool])
3263 WINE_CONFIG_TEST(dlls/winspool.drv/tests)
3264 WINE_CONFIG_DLL(winsta)
3265 WINE_CONFIG_DLL(wintab.dll16,enable_win16)
3266 WINE_CONFIG_DLL(wintab32,,[implib])
3267 WINE_CONFIG_TEST(dlls/wintab32/tests)
3268 WINE_CONFIG_DLL(wintrust,,[implib])
3269 WINE_CONFIG_TEST(dlls/wintrust/tests)
3270 WINE_CONFIG_DLL(wlanapi)
3271 WINE_CONFIG_DLL(wldap32,,[implib,po])
3272 WINE_CONFIG_TEST(dlls/wldap32/tests)
3273 WINE_CONFIG_DLL(wmi)
3274 WINE_CONFIG_DLL(wmiutils,,[clean])
3275 WINE_CONFIG_TEST(dlls/wmiutils/tests)
3276 WINE_CONFIG_DLL(wmvcore)
3277 WINE_CONFIG_DLL(wnaspi32,,[implib])
3278 WINE_CONFIG_DLL(wow32,enable_win16,[implib])
3279 WINE_CONFIG_DLL(ws2_32,,[implib])
3280 WINE_CONFIG_TEST(dlls/ws2_32/tests)
3281 WINE_CONFIG_DLL(wshom.ocx,,[clean])
3282 WINE_CONFIG_TEST(dlls/wshom.ocx/tests,[clean])
3283 WINE_CONFIG_DLL(wsnmp32,,[implib])
3284 WINE_CONFIG_TEST(dlls/wsnmp32/tests)
3285 WINE_CONFIG_DLL(wsock32,,[implib])
3286 WINE_CONFIG_DLL(wtsapi32,,[implib])
3287 WINE_CONFIG_DLL(wuapi,,[clean])
3288 WINE_CONFIG_DLL(wuaueng)
3289 WINE_CONFIG_DLL(xapofx1_1)
3290 WINE_CONFIG_DLL(xinput1_1)
3291 WINE_CONFIG_DLL(xinput1_2)
3292 WINE_CONFIG_DLL(xinput1_3,,[implib],[xinput])
3293 WINE_CONFIG_TEST(dlls/xinput1_3/tests)
3294 WINE_CONFIG_DLL(xinput1_4)
3295 WINE_CONFIG_DLL(xinput9_1_0)
3296 WINE_CONFIG_DLL(xmllite)
3297 WINE_CONFIG_TEST(dlls/xmllite/tests)
3298 WINE_CONFIG_DLL(xolehlp)
3299 WINE_CONFIG_DLL(xpsprint)
3300 WINE_CONFIG_DLL(xpssvcs)
3301 WINE_CONFIG_MAKEFILE([documentation],,[clean])
3302 WINE_CONFIG_MAKEFILE([fonts],,[clean,install-lib])
3303 WINE_CONFIG_MAKEFILE([include],,[clean,install-dev])
3304 WINE_CONFIG_MAKEFILE([libs/port])
3305 WINE_CONFIG_MAKEFILE([libs/wine],,[clean,install-dev,install-lib])
3306 WINE_CONFIG_MAKEFILE([libs/wpp])
3307 WINE_CONFIG_MAKEFILE([loader],,[clean,install-lib,manpage])
3308 WINE_CONFIG_PROGRAM(aspnet_regiis,,[install])
3309 WINE_CONFIG_PROGRAM(attrib,,[install,po])
3310 WINE_CONFIG_PROGRAM(cabarc,,[install])
3311 WINE_CONFIG_PROGRAM(cacls,,[install])
3312 WINE_CONFIG_PROGRAM(clock,,[install,po])
3313 WINE_CONFIG_PROGRAM(cmd,,[install,po])
3314 WINE_CONFIG_TEST(programs/cmd/tests)
3315 WINE_CONFIG_PROGRAM(conhost,,[install])
3316 WINE_CONFIG_PROGRAM(control,,[install])
3317 WINE_CONFIG_PROGRAM(cscript,,[install])
3318 WINE_CONFIG_PROGRAM(dxdiag,,[install,po])
3319 WINE_CONFIG_PROGRAM(eject,,[install])
3320 WINE_CONFIG_PROGRAM(expand,,[install])
3321 WINE_CONFIG_PROGRAM(explorer,,[install,po])
3322 WINE_CONFIG_PROGRAM(extrac32,,[install])
3323 WINE_CONFIG_PROGRAM(findstr,,[install])
3324 WINE_CONFIG_PROGRAM(hh,,[install])
3325 WINE_CONFIG_PROGRAM(hostname,,[install,po])
3326 WINE_CONFIG_PROGRAM(icinfo,,[install])
3327 WINE_CONFIG_PROGRAM(iexplore,,[install])
3328 WINE_CONFIG_PROGRAM(ipconfig,,[install,po])
3329 WINE_CONFIG_PROGRAM(lodctr,,[install])
3330 WINE_CONFIG_PROGRAM(mofcomp,,[install])
3331 WINE_CONFIG_PROGRAM(mshta,,[install])
3332 WINE_CONFIG_PROGRAM(msiexec,,[install,installbin,manpage])
3333 WINE_CONFIG_PROGRAM(net,,[install,po])
3334 WINE_CONFIG_PROGRAM(netsh,,[install])
3335 WINE_CONFIG_PROGRAM(netstat,,[install,po])
3336 WINE_CONFIG_PROGRAM(ngen,,[install])
3337 WINE_CONFIG_PROGRAM(notepad,,[install,installbin,manpage,po])
3338 WINE_CONFIG_PROGRAM(oleview,,[install,po])
3339 WINE_CONFIG_PROGRAM(ping,,[install])
3340 WINE_CONFIG_PROGRAM(plugplay,,[install])
3341 WINE_CONFIG_PROGRAM(presentationfontcache,,[install])
3342 WINE_CONFIG_PROGRAM(progman,,[install,po])
3343 WINE_CONFIG_PROGRAM(reg,,[install,po])
3344 WINE_CONFIG_PROGRAM(regasm,,[install])
3345 WINE_CONFIG_PROGRAM(regedit,,[install,installbin,manpage,po])
3346 WINE_CONFIG_TEST(programs/regedit/tests)
3347 WINE_CONFIG_PROGRAM(regsvcs,,[install])
3348 WINE_CONFIG_PROGRAM(regsvr32,,[install,installbin,manpage])
3349 WINE_CONFIG_PROGRAM(rpcss,,[clean,install])
3350 WINE_CONFIG_PROGRAM(rundll.exe16,enable_win16,[install])
3351 WINE_CONFIG_PROGRAM(rundll32,,[install])
3352 WINE_CONFIG_PROGRAM(sc,,[install])
3353 WINE_CONFIG_PROGRAM(schtasks,,[install])
3354 WINE_CONFIG_PROGRAM(secedit,,[install])
3355 WINE_CONFIG_PROGRAM(servicemodelreg,,[install])
3356 WINE_CONFIG_PROGRAM(services,,[clean,install])
3357 WINE_CONFIG_TEST(programs/services/tests)
3358 WINE_CONFIG_PROGRAM(spoolsv,,[install])
3359 WINE_CONFIG_PROGRAM(start,,[install,po])
3360 WINE_CONFIG_PROGRAM(svchost,,[install])
3361 WINE_CONFIG_PROGRAM(taskkill,,[install,po])
3362 WINE_CONFIG_PROGRAM(tasklist,,[install])
3363 WINE_CONFIG_PROGRAM(taskmgr,,[install,po])
3364 WINE_CONFIG_PROGRAM(termsv,,[install])
3365 WINE_CONFIG_PROGRAM(uninstaller,,[install,po])
3366 WINE_CONFIG_PROGRAM(unlodctr,,[install])
3367 WINE_CONFIG_PROGRAM(view,,[install,po])
3368 WINE_CONFIG_PROGRAM(wineboot,,[install,installbin,manpage,po])
3369 WINE_CONFIG_PROGRAM(winebrowser,,[install])
3370 WINE_CONFIG_PROGRAM(winecfg,,[install,installbin,manpage,po])
3371 WINE_CONFIG_PROGRAM(wineconsole,,[install,installbin,manpage,po])
3372 WINE_CONFIG_PROGRAM(winedbg,,[install,installbin,manpage,po])
3373 WINE_CONFIG_PROGRAM(winedevice,,[install])
3374 WINE_CONFIG_PROGRAM(winefile,,[install,installbin,manpage,po])
3375 WINE_CONFIG_PROGRAM(winemenubuilder,,[install])
3376 WINE_CONFIG_PROGRAM(winemine,,[install,installbin,manpage,po])
3377 WINE_CONFIG_PROGRAM(winemsibuilder,,[install])
3378 WINE_CONFIG_PROGRAM(winepath,,[install,installbin,manpage])
3379 WINE_CONFIG_PROGRAM(winetest,,[clean])
3380 WINE_CONFIG_PROGRAM(winevdm,enable_win16,[install])
3381 WINE_CONFIG_PROGRAM(winhelp.exe16,enable_win16,[install])
3382 WINE_CONFIG_PROGRAM(winhlp32,,[install,po])
3383 WINE_CONFIG_PROGRAM(winoldap.mod16,enable_win16,[install])
3384 WINE_CONFIG_PROGRAM(winver,,[install])
3385 WINE_CONFIG_PROGRAM(wmic,,[install,po])
3386 WINE_CONFIG_PROGRAM(wordpad,,[install,po])
3387 WINE_CONFIG_PROGRAM(write,,[install,po])
3388 WINE_CONFIG_PROGRAM(wscript,,[clean,install])
3389 WINE_CONFIG_TEST(programs/wscript/tests)
3390 WINE_CONFIG_PROGRAM(wusa,,[install])
3391 WINE_CONFIG_PROGRAM(xcopy,,[install,po])
3392 WINE_CONFIG_MAKEFILE([server],,[clean,install-lib,manpage])
3393 WINE_CONFIG_TOOL(tools,[clean,install-dev,install-lib,manpage])
3394 WINE_CONFIG_TOOL(tools/widl,[clean,install-dev,manpage])
3395 WINE_CONFIG_TOOL(tools/winebuild,[clean,install-dev,manpage])
3396 WINE_CONFIG_TOOL(tools/winedump,[clean,install-dev,manpage])
3397 WINE_CONFIG_TOOL(tools/winegcc,[clean,install-dev,manpage])
3398 WINE_CONFIG_TOOL(tools/wmc,[clean,install-dev,manpage])
3399 WINE_CONFIG_TOOL(tools/wrc,[clean,install-dev,manpage])
3400
3401 AC_SUBST([LINGUAS],["\
3402 ar \
3403 bg \
3404 ca \
3405 cs \
3406 da \
3407 de \
3408 el \
3409 en \
3410 en_US \
3411 eo \
3412 es \
3413 fa \
3414 fi \
3415 fr \
3416 he \
3417 hi \
3418 hr \
3419 hu \
3420 it \
3421 ja \
3422 ko \
3423 lt \
3424 ml \
3425 nb_NO \
3426 nl \
3427 or \
3428 pa \
3429 pl \
3430 pt_BR \
3431 pt_PT \
3432 rm \
3433 ro \
3434 ru \
3435 sk \
3436 sl \
3437 sr_RS@cyrillic \
3438 sr_RS@latin \
3439 sv \
3440 te \
3441 th \
3442 tr \
3443 uk \
3444 wa \
3445 zh_CN \
3446 zh_TW"])
3447
3448 dnl End of auto-generated output commands
3449
3450 AC_CONFIG_COMMANDS([Makefile], [wine_fn_output_makefile Makefile],
3451 [wine_fn_output_makefile ()
3452 {
3453     cat Make.tmp - <<\_WINE_EOF >\$tmp/makefile && mv -f \$tmp/makefile \$[]1 && rm -f Make.tmp && return
3454 `cat $wine_rules_file`
3455 _WINE_EOF
3456     AS_ERROR([could not create Makefile])
3457 }])
3458
3459 AC_CONFIG_FILES([Make.tmp:Make.vars.in:Makefile.in])
3460
3461 dnl Some final makefile rules
3462
3463 if test "x$enable_maintainer_mode" = xyes
3464 then
3465     WINE_APPEND_RULE(
3466 [configure: configure.ac aclocal.m4
3467         autoconf --warnings=all
3468 include/config.h.in: include/stamp-h.in
3469 include/stamp-h.in: configure.ac aclocal.m4
3470         autoheader --warnings=all
3471         @echo timestamp > \$[@]])
3472 fi
3473
3474 if test "x$with_gettextpo" = xyes
3475 then
3476     test "$srcdir" = . || AC_MSG_ERROR([Rebuilding po files is not supported for out of tree builds.])
3477     WINE_APPEND_RULE(
3478 [ALL_POT_FILES =$ALL_POT_FILES
3479 \$(LINGUAS:%=po/%.po): po/wine.pot
3480         msgmerge --previous -q \$[@] po/wine.pot | msgattrib --no-obsolete -o \$[@].new && mv \$[@].new \$[@]
3481 po/wine.pot: \$(ALL_POT_FILES)
3482         msgcat -o \$[@] \$(ALL_POT_FILES)])
3483 fi
3484
3485 if test "$MSGFMT" != false
3486 then
3487     AC_SUBST([PORCFLAGS],["--po-dir=\$(top_builddir)/po"])
3488     WINE_APPEND_RULE([__builddeps__: \$(ALL_MO_FILES)])
3489 else
3490     LINGUAS=
3491 fi
3492
3493 if test "x$enable_tools" != xno
3494 then
3495     AC_CONFIG_COMMANDS([tools],[AS_MKDIR_P(tools)])
3496     WINE_APPEND_RULE(
3497 [tools/makedep$ac_exeext: tools/makedep.c include/config.h
3498         \$(CC) \$(ALLCFLAGS) -o \$@ $srcdir/tools/makedep.c \$(LDFLAGS)
3499 clean:: __clean__
3500         \$(RM) tools/makedep$ac_exeext])
3501 fi
3502
3503 if test -n "$with_wine64"
3504 then
3505     WINE_APPEND_RULE(
3506 [all: fonts server tools $with_wine64/loader/wine $with_wine64/loader/wine-preloader
3507 fonts server tools:
3508         \$(RM) \$[@] && \$(LN_S) $with_wine64/\$[@] \$[@]
3509 $with_wine64/loader/wine:
3510         \$(RM) \$[@] && \$(LN_S) $ac_pwd/loader/wine \$[@]
3511 $with_wine64/loader/wine-preloader:
3512         \$(RM) \$[@] && \$(LN_S) $ac_pwd/loader/wine-preloader \$[@]
3513 clean::
3514         \$(RM) fonts server tools $with_wine64/loader/wine $with_wine64/loader/wine-preloader])
3515 else
3516     AS_VAR_APPEND([LOADER_RULES],["
3517 all: wine.inf
3518
3519 wine.inf: wine.inf.in \$(top_builddir)/include/config.h
3520         LC_ALL=C sed -e 's,@PACKAGE_STRING@,$PACKAGE_STRING,g' \$(srcdir)/wine.inf.in >\$@ || (\$(RM) \$@ && false)
3521
3522 install install-lib:: wine.inf \$(DESTDIR)\$(datadir)/wine install-man-pages
3523         \$(INSTALL_DATA) wine.inf \$(DESTDIR)\$(datadir)/wine/wine.inf
3524         \$(INSTALL_DATA) \$(srcdir)/l_intl.nls \$(DESTDIR)\$(datadir)/wine/l_intl.nls
3525
3526 uninstall::
3527         \$(RM) \$(DESTDIR)\$(datadir)/wine/wine.inf \$(DESTDIR)\$(datadir)/wine/l_intl.nls
3528 "])
3529 fi
3530
3531 AS_ECHO(" done") >&AS_MESSAGE_FD
3532 AC_OUTPUT
3533
3534 if test "$no_create" = "yes"
3535 then
3536   exit 0
3537 fi
3538
3539 WINE_PRINT_MESSAGES
3540
3541 AS_ECHO("
3542 $as_me: Finished.  Do '${ac_make}' to compile Wine.
3543 ") >&AS_MESSAGE_FD
3544
3545 dnl Local Variables:
3546 dnl comment-start: "dnl "
3547 dnl comment-end: ""
3548 dnl comment-start-skip: "\\bdnl\\b\\s *"
3549 dnl compile-command: "autoreconf --warnings=all"
3550 dnl End: