aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl WINE_CHECK_HOST_TOOL(VARIABLE, PROG-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND], [PATH])
  26 dnl
  27 dnl Like AC_CHECK_TOOL but without the broken fallback to non-prefixed name
  28 dnl
  29 AC_DEFUN([WINE_CHECK_HOST_TOOL],
  30 [AS_VAR_SET_IF([ac_tool_prefix],
  31   [AC_CHECK_PROG([$1],[${ac_tool_prefix}$2],[${ac_tool_prefix}$2],,[$4])])
  32 AS_VAR_IF([ac_cv_prog_$1],[],
  33   [AS_VAR_IF([cross_compiling],[yes],[],
  34     [AS_UNSET([ac_cv_prog_$1])
  35      AC_CHECK_PROG([$1],[$2],[$2],[$3],[$4])])],
  36 [AS_VAR_COPY([$1],[ac_cv_prog_$1])])])
  37
  38 dnl WINE_HEADER_MAJOR()
  39 dnl
  40 dnl Same as AC_HEADER_MAJOR but fixed to handle the glibc 2.25 sys/types.h breakage
  41 dnl
  42 AC_DEFUN([WINE_HEADER_MAJOR],
  43 [AC_CHECK_HEADER(sys/mkdev.h,
  44                 [AC_DEFINE(MAJOR_IN_MKDEV, 1,
  45                            [Define to 1 if `major', `minor', and `makedev' are
  46                             declared in <mkdev.h>.])])
  47 if test $ac_cv_header_sys_mkdev_h = no; then
  48   AC_CHECK_HEADER(sys/sysmacros.h,
  49                   [AC_DEFINE(MAJOR_IN_SYSMACROS, 1,
  50                              [Define to 1 if `major', `minor', and `makedev'
  51                               are declared in <sysmacros.h>.])])
  52 fi])
  53
  54 dnl **** Initialize the programs used by other checks ****
  55 dnl
  56 dnl Usage: WINE_PATH_SONAME_TOOLS
  57 dnl Usage: WINE_PATH_PKG_CONFIG
  58 dnl
  59 AC_DEFUN([WINE_PATH_SONAME_TOOLS],
  60 [AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)
  61 AC_CHECK_TOOL(OTOOL,otool,otool)
  62 AC_CHECK_TOOL(READELF,[readelf],true)])
  63
  64 AC_DEFUN([WINE_PATH_PKG_CONFIG],
  65 [WINE_CHECK_HOST_TOOL(PKG_CONFIG,[pkg-config])])
  66
  67 AC_DEFUN([WINE_PATH_MINGW_PKG_CONFIG],
  68 [case "$host_cpu" in
  69   i[[3456789]]86*)
  70     ac_prefix_list="m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-w64-mingw32-pkg-config ])" ;;
  71   *)
  72     ac_prefix_list="$host_cpu-w64-mingw32-pkg-config" ;;
  73 esac
  74 AC_CHECK_PROGS(MINGW_PKG_CONFIG,[$ac_prefix_list],false)])
  75
  76 dnl **** Extract the soname of a library ****
  77 dnl
  78 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  79 dnl
  80 AC_DEFUN([WINE_CHECK_SONAME],
  81 [AC_REQUIRE([WINE_PATH_SONAME_TOOLS])dnl
  82 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  83 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  84 AC_MSG_CHECKING([for -l$1])
  85 AC_CACHE_VAL(ac_Lib,
  86 [ac_check_soname_save_LIBS=$LIBS
  87 LIBS="-l$1 $5 $LIBS"
  88   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  89   [case "$LIBEXT" in
  90     dll) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest.exe | grep "$1" | sed -e "s/dll.*/dll/"';2,$d'`]) ;;
  91     dylib) AS_VAR_SET(ac_Lib,[`$OTOOL -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  92     *) AS_VAR_SET(ac_Lib,[`$READELF -d conftest$ac_exeext | grep "NEEDED.*ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\\m4_dquote(\\(ac_lib_pattern\\.$LIBEXT[[^    ]]*\\)\\).*$/\1/"';2,$d'`])
  93        AS_VAR_IF([ac_Lib],[],
  94              [AS_VAR_SET(ac_Lib,[`$LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^  ]]*\).*$/\1/"';2,$d'`])]) ;;
  95   esac],
  96   [AS_VAR_SET(ac_Lib,[])])
  97   LIBS=$ac_check_soname_save_LIBS])dnl
  98 AS_VAR_IF([ac_Lib],[],
  99       [AC_MSG_RESULT([not found])
 100        $4],
 101       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
 102        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
 103                           [Define to the soname of the lib$1 library.])
 104        $3])dnl
 105 m4_popdef([ac_lib_pattern])dnl
 106 AS_VAR_POPDEF([ac_Lib])])
 107
 108 dnl **** Get flags from pkg-config or alternate xxx-config program ****
 109 dnl
 110 dnl Usage: WINE_PACKAGE_FLAGS(var,pkg-name,[default-lib,[cflags-alternate,libs-alternate,[checks]]])
 111 dnl
 112 AC_DEFUN([WINE_PACKAGE_FLAGS],
 113 [AC_REQUIRE([WINE_PATH_PKG_CONFIG])dnl
 114 AS_VAR_PUSHDEF([ac_cflags],[[$1]_CFLAGS])dnl
 115 AS_VAR_PUSHDEF([ac_libs],[[$1]_LIBS])dnl
 116 AC_ARG_VAR(ac_cflags, [C compiler flags for $2, overriding pkg-config])dnl
 117 AS_VAR_IF([ac_cflags],[],
 118       [AS_VAR_SET_IF([PKG_CONFIG],
 119       [ac_cflags=`$PKG_CONFIG --cflags [$2] 2>/dev/null`])])
 120 m4_ifval([$4],[test "$cross_compiling" = yes || ac_cflags=[$]{ac_cflags:-[$4]}])
 121 AC_ARG_VAR(ac_libs, [Linker flags for $2, overriding pkg-config])dnl
 122 AS_VAR_IF([ac_libs],[],
 123       [AS_VAR_SET_IF([PKG_CONFIG],
 124       [ac_libs=`$PKG_CONFIG --libs [$2] 2>/dev/null`])])
 125 m4_ifval([$5],[test "$cross_compiling" = yes || ac_libs=[$]{ac_libs:-[$5]}])
 126 m4_ifval([$3],[ac_libs=[$]{ac_libs:-"$3"}])
 127 AS_ECHO(["$as_me:${as_lineno-$LINENO}: $2 cflags: $ac_cflags"]) >&AS_MESSAGE_LOG_FD
 128 AS_ECHO(["$as_me:${as_lineno-$LINENO}: $2 libs: $ac_libs"]) >&AS_MESSAGE_LOG_FD
 129 ac_save_CPPFLAGS=$CPPFLAGS
 130 CPPFLAGS="$CPPFLAGS $ac_cflags"
 131 $6
 132 CPPFLAGS=$ac_save_CPPFLAGS
 133 AS_VAR_POPDEF([ac_libs])dnl
 134 AS_VAR_POPDEF([ac_cflags])])dnl
 135
 136 dnl **** Get flags from MinGW pkg-config or alternate xxx-config program ****
 137 dnl
 138 dnl Usage: WINE_MINGW_PACKAGE_FLAGS(var,pkg-name,[default-lib,[checks]])
 139 dnl
 140 AC_DEFUN([WINE_MINGW_PACKAGE_FLAGS],
 141 [AC_REQUIRE([WINE_PATH_MINGW_PKG_CONFIG])dnl
 142 AS_VAR_PUSHDEF([ac_cflags],[[$1]_PE_CFLAGS])dnl
 143 AS_VAR_PUSHDEF([ac_libs],[[$1]_PE_LIBS])dnl
 144 AS_VAR_IF([ac_cflags],[],
 145       [AS_VAR_SET_IF([MINGW_PKG_CONFIG],
 146       [ac_cflags=`$MINGW_PKG_CONFIG --cflags [$2] 2>/dev/null`])])
 147 AS_VAR_IF([ac_libs],[],
 148       [AS_VAR_SET_IF([MINGW_PKG_CONFIG],
 149       [ac_libs=`$MINGW_PKG_CONFIG --libs [$2] 2>/dev/null`])])
 150 m4_ifval([$3],[ac_libs=[$]{ac_libs:-"$3"}])
 151 ac_save_CPPFLAGS=$CPPFLAGS
 152 CPPFLAGS="$CPPFLAGS $ac_cflags"
 153 $4
 154 CPPFLAGS=$ac_save_CPPFLAGS
 155 AS_VAR_POPDEF([ac_libs])dnl
 156 AS_VAR_POPDEF([ac_cflags])])dnl
 157
 158 dnl **** Get flags for an external lib program ****
 159 dnl
 160 dnl Usage: WINE_EXTLIB_FLAGS(var,pkg-name,default-libs,default-cflags)
 161 dnl
 162 AC_DEFUN([WINE_EXTLIB_FLAGS],
 163 [AS_VAR_PUSHDEF([ac_cflags],[[$1]_PE_CFLAGS])dnl
 164 AS_VAR_PUSHDEF([ac_libs],[[$1]_PE_LIBS])dnl
 165 AC_ARG_VAR(ac_cflags, [C compiler flags for the PE $2, overriding the bundled version])dnl
 166 AC_ARG_VAR(ac_libs, [Linker flags for the PE $2, overriding the bundled version])dnl
 167 AS_VAR_IF([ac_libs],[],
 168   [ac_libs=$3
 169    AS_VAR_IF([ac_cflags],[],[ac_cflags=$4],[enable_$2=no])],
 170   [enable_$2=no])
 171 AS_ECHO(["$as_me:${as_lineno-$LINENO}: $2 cflags: $ac_cflags"]) >&AS_MESSAGE_LOG_FD
 172 AS_ECHO(["$as_me:${as_lineno-$LINENO}: $2 libs: $ac_libs"]) >&AS_MESSAGE_LOG_FD
 173 AS_VAR_POPDEF([ac_libs])dnl
 174 AS_VAR_POPDEF([ac_cflags])])dnl
 175
 176 dnl **** Link C code with an assembly file ****
 177 dnl
 178 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
 179 dnl
 180 AC_DEFUN([WINE_TRY_ASM_LINK],
 181 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[$2]],[[asm($1); $3]])],[$4],[$5])])
 182
 183 dnl **** Check if we can link an empty program with special CFLAGS ****
 184 dnl
 185 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
 186 dnl
 187 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
 188 dnl
 189 AC_DEFUN([WINE_TRY_CFLAGS],
 190 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
 191 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
 192 [ac_wine_try_cflags_saved=$CFLAGS
 193 CFLAGS="$CFLAGS $1"
 194 AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv) { return 0; }]])],
 195                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
 196 CFLAGS=$ac_wine_try_cflags_saved])
 197 AS_VAR_IF([ac_var],[yes],[m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
 198 AS_VAR_POPDEF([ac_var])])
 199
 200 dnl **** Check if we can link an empty program with special CFLAGS ****
 201 dnl
 202 dnl Usage: WINE_TRY_CROSSCFLAGS(flags,[action-if-yes,[action-if-no]])
 203 dnl
 204 dnl The default action-if-yes is to append the flags to EXTRACROSSCFLAGS.
 205 dnl
 206 AC_DEFUN([WINE_TRY_CROSSCFLAGS],
 207 [AS_VAR_PUSHDEF([ac_var], ac_cv_crosscflags_[[$1]])dnl
 208 AC_CACHE_CHECK([whether the cross-compiler supports $1], ac_var,
 209 [ac_wine_try_cflags_saved=$CFLAGS
 210 ac_wine_try_cflags_saved_cc=$CC
 211 ac_wine_try_cflags_saved_exeext=$ac_exeext
 212 CFLAGS="$CFLAGS $EXTRACROSSCFLAGS -nostartfiles -nodefaultlibs $1"
 213 CC="$CROSSCC"
 214 ac_exeext=".exe"
 215 AC_LINK_IFELSE([AC_LANG_SOURCE([[int __cdecl mainCRTStartup(void) { return 0; }]])],
 216                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
 217 CFLAGS=$ac_wine_try_cflags_saved
 218 CC=$ac_wine_try_cflags_saved_cc
 219 ac_exeext=$ac_wine_try_cflags_saved_exeext])
 220 AS_VAR_IF([ac_var],[yes],[m4_default([$2], [EXTRACROSSCFLAGS="$EXTRACROSSCFLAGS $1"])], [$3])dnl
 221 AS_VAR_POPDEF([ac_var])])
 222
 223 dnl **** Check whether the given MinGW header is available ****
 224 dnl
 225 dnl Usage: WINE_CHECK_MINGW_HEADER(header,[action-if-found],[action-if-not-found],[other-includes])
 226 dnl
 227 AC_DEFUN([WINE_CHECK_MINGW_HEADER],
 228 [AS_VAR_PUSHDEF([ac_var],[ac_cv_mingw_header_$1])dnl
 229 AC_CACHE_CHECK([for MinGW $1], ac_var,
 230 [ac_wine_check_headers_saved_cc=$CC
 231 ac_wine_check_headers_saved_exeext=$ac_exeext
 232 CC="$CROSSCC"
 233 ac_exeext=".exe"
 234 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[$4
 235 #include <$1>]])],[AS_VAR_SET([ac_var],[yes])],[AS_VAR_SET([ac_var],[no])])
 236 CC=$ac_wine_check_headers_saved_cc
 237 ac_exeext=$ac_wine_check_headers_saved_exeext])
 238 AS_VAR_IF([ac_var],[yes],[$2],[$3])dnl
 239 AS_VAR_POPDEF([ac_var])])
 240
 241 dnl **** Check whether the given MinGW library is available ****
 242 dnl
 243 dnl Usage: WINE_CHECK_MINGW_LIB(library,function,[action-if-found],[action-if-not-found],[other-libraries])
 244 dnl
 245 AC_DEFUN([WINE_CHECK_MINGW_LIB],
 246 [AS_VAR_PUSHDEF([ac_var],[ac_cv_mingw_lib_$1])dnl
 247 AC_CACHE_CHECK([for $2 in MinGW -l$1], ac_var,
 248 [ac_wine_check_headers_saved_cc=$CC
 249 ac_wine_check_headers_saved_exeext=$ac_exeext
 250 ac_wine_check_headers_saved_libs=$LIBS
 251 CC="$CROSSCC"
 252 ac_exeext=".exe"
 253 LIBS="-l$1 $5 $LIBS"
 254 AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],[AS_VAR_SET([ac_var],[yes])],[AS_VAR_SET([ac_var],[no])])
 255 CC=$ac_wine_check_headers_saved_cc
 256 ac_exeext=$ac_wine_check_headers_saved_exeext
 257 LIBS=$ac_wine_check_headers_saved_libs])
 258 AS_VAR_IF([ac_var],[yes],[$3],[$4])dnl
 259 AS_VAR_POPDEF([ac_var])])
 260
 261 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
 262 dnl
 263 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
 264 dnl
 265 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
 266 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
 267 ac_wine_try_cflags_saved=$CFLAGS
 268 CFLAGS="$CFLAGS $1"
 269 AC_LINK_IFELSE([AC_LANG_SOURCE([[void myfunc() {}]])],
 270                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
 271 CFLAGS=$ac_wine_try_cflags_saved
 272 AS_VAR_IF([ac_var],[yes], [$2], [$3])dnl
 273 AS_VAR_POPDEF([ac_var])])
 274
 275 dnl **** Check whether we need to define a symbol on the compiler command line ****
 276 dnl
 277 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
 278 dnl
 279 AC_DEFUN([WINE_CHECK_DEFINE],
 280 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 281 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 282     AC_EGREP_CPP(yes,[#ifndef $1
 283 yes
 284 #endif],
 285     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 286 AS_VAR_IF([ac_var],[yes],
 287       [CFLAGS="$CFLAGS -D$1"
 288   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 289 AS_VAR_POPDEF([ac_var])])
 290
 291 dnl **** Check for functions with some extra libraries ****
 292 dnl
 293 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 294 dnl
 295 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 296 [ac_wine_check_funcs_save_LIBS="$LIBS"
 297 LIBS="$LIBS $2"
 298 AC_CHECK_FUNCS([$1],[$3],[$4])
 299 LIBS="$ac_wine_check_funcs_save_LIBS"])
 300
 301 dnl **** Check for a mingw program, trying the various mingw prefixes ****
 302 dnl
 303 dnl Usage: WINE_CHECK_MINGW_PROG(variable,[value-if-not-found],[path])
 304 dnl
 305 AC_DEFUN([WINE_CHECK_MINGW_PROG],
 306 [case "$host_cpu" in
 307   aarch64*)
 308     ac_prefix_list="aarch64-w64-mingw32-clang aarch64-w64-mingw32-gcc clang" ;;
 309   arm*)
 310     ac_prefix_list="armv7-w64-mingw32-clang armv7-w64-mingw32-gcc clang" ;;
 311   i[[3456789]]86*)
 312     ac_prefix_list="m4_foreach([ac_wine_prefix],[w64-mingw32, pc-mingw32, mingw32msvc, mingw32],
 313                         m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-ac_wine_prefix-gcc ]))
 314                      m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-w64-mingw32-clang ])
 315                      mingw32-gcc clang" ;;
 316   x86_64)
 317     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32, w64-mingw32, mingw32msvc],
 318                         m4_foreach([ac_wine_cpu],[x86_64,amd64],[ac_wine_cpu-ac_wine_prefix-gcc ]))
 319                     m4_foreach([ac_wine_cpu],[x86_64,amd64],[ac_wine_cpu-w64-mingw32-clang ]) clang" ;;
 320   *)
 321     ac_prefix_list="" ;;
 322 esac
 323 AC_CHECK_PROGS([$1],[$ac_prefix_list],[$2],[$3])])
 324
 325
 326 dnl **** Define helper functions for creating config.status files ****
 327 dnl
 328 dnl Usage: AC_REQUIRE([WINE_CONFIG_HELPERS])
 329 dnl
 330 AC_DEFUN([WINE_CONFIG_HELPERS],
 331 [AS_VAR_SET([wine_rules],["all:"])
 332 AC_SUBST(SUBDIRS,"")
 333 AC_SUBST(DISABLED_SUBDIRS,"")
 334 AC_SUBST(CONFIGURE_TARGETS,"")
 335
 336 wine_fn_append_file ()
 337 {
 338     AS_VAR_APPEND($[1]," \\$as_nl       $[2]")
 339 }
 340
 341 wine_fn_append_rule ()
 342 {
 343     AS_VAR_APPEND(wine_rules,"$as_nl$[1]")
 344 }
 345
 346 wine_fn_config_makefile ()
 347 {
 348     wine_fn_append_file SUBDIRS $[1]
 349     AS_VAR_IF([$[2]],[no],[wine_fn_append_file DISABLED_SUBDIRS $[1]])
 350 }
 351
 352 wine_fn_config_symlink ()
 353 {
 354     ac_links=$[@]
 355     wine_fn_append_rule \
 356 "$ac_links:
 357         @./config.status \$[@]"
 358     for f in $ac_links; do wine_fn_append_file CONFIGURE_TARGETS $f; done
 359 }])
 360
 361 dnl **** Define helper function to append a rule to a makefile command list ****
 362 dnl
 363 dnl Usage: WINE_APPEND_RULE(rule)
 364 dnl
 365 AC_DEFUN([WINE_APPEND_RULE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_rule "$1"])
 366
 367 dnl **** Create symlinks from config.status ****
 368 dnl
 369 dnl Usage: WINE_CONFIG_SYMLINK(target,src,enable)
 370 dnl
 371 AC_DEFUN([WINE_CONFIG_SYMLINK],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 372 m4_ifval([$3],[if test $3; then
 373 ])AC_CONFIG_LINKS([$1:$2])dnl
 374 wine_fn_config_symlink[ $1]m4_ifval([$3],[
 375 fi])[]dnl
 376 ])])
 377
 378 dnl **** Create a makefile from config.status ****
 379 dnl
 380 dnl Usage: WINE_CONFIG_MAKEFILE(file,enable,condition)
 381 dnl
 382 AC_DEFUN([WINE_CONFIG_MAKEFILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 383 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]m4_bpatsubst([$1],[.*/\([^/]*\)$],[\1])))dnl
 384 m4_append_uniq([_AC_USER_OPTS],ac_enable,[
 385 ])dnl
 386 m4_ifval([$3],[$3 || ])wine_fn_config_makefile [$1] ac_enable[]dnl
 387 AS_VAR_POPDEF([ac_enable])])
 388
 389 dnl **** Append a file to the .gitignore list ****
 390 dnl
 391 dnl Usage: WINE_IGNORE_FILE(file,enable)
 392 dnl
 393 AC_DEFUN([WINE_IGNORE_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 394 m4_ifval([$2],[test "x$[$2]" = xno || ])wine_fn_append_file CONFIGURE_TARGETS $1])
 395
 396 dnl **** Add a message to the list displayed at the end ****
 397 dnl
 398 dnl Usage: WINE_NOTICE(notice)
 399 dnl Usage: WINE_WARNING(warning)
 400 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice, enable)
 401 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning, enable)
 402 dnl Usage: WINE_ERROR_WITH(with_flag, test, error, enable)
 403 dnl Usage: WINE_PRINT_MESSAGES
 404 dnl
 405 AC_DEFUN([WINE_NOTICE],[AS_VAR_APPEND([wine_notices],["|$1"])])
 406 AC_DEFUN([WINE_WARNING],[AS_VAR_APPEND([wine_warnings],["|$1"])])
 407
 408 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 409   x)   WINE_NOTICE([$3]) ;;
 410   xno) ;;
 411   *)   AC_MSG_ERROR([$3
 412 This is an error since --with-$1 was requested.]) ;;
 413 esac
 414 m4_ifval([$4],[$4=${$4:-no}])])])
 415
 416 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 417   x)   WINE_WARNING([$3]) ;;
 418   xno) ;;
 419   *)   AC_MSG_ERROR([$3
 420 This is an error since --with-$1 was requested.]) ;;
 421 esac
 422 m4_ifval([$4],[$4=${$4:-no}])])])
 423
 424 AC_DEFUN([WINE_ERROR_WITH],[AS_IF([$2],[case "x$with_$1" in
 425   xno) ;;
 426   *)   AC_MSG_ERROR([$3
 427 Use the --without-$1 option if you really want this.]) ;;
 428 esac
 429 m4_ifval([$4],[$4=${$4:-no}])])])
 430
 431 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 432 if test "x$wine_notices" != x; then
 433     echo >&AS_MESSAGE_FD
 434     IFS="|"
 435     for msg in $wine_notices; do
 436         IFS="$ac_save_IFS"
 437         AS_VAR_IF([msg],[],,[AC_MSG_NOTICE([$msg])])
 438     done
 439 fi
 440 IFS="|"
 441 for msg in $wine_warnings; do
 442     IFS="$ac_save_IFS"
 443     AS_VAR_IF([msg],[],,[echo >&2
 444         AC_MSG_WARN([$msg])])
 445 done
 446 IFS="$ac_save_IFS"])
 447
 448 dnl Local Variables:
 449 dnl compile-command: "autoreconf --warnings=all"
 450 dnl End: