wesnoth-mode.el

   1 ;;; wesnoth-mode.el --- A major mode for editing WML.
   2 ;; Copyright (C) 2006, 2007, 2008 Chris Mann
   3
   4 ;; This file is part of wesnoth-mode.
   5
   6 ;; This program is free software; you can redistribute it and/or
   7 ;; modify it under the terms of the GNU General Public License as
   8 ;; published by the Free Software Foundation; either version 2 of the
   9 ;; License, or (at your option) any later version.
  10
  11 ;; This program is distributed in the hope that it will be useful, but
  12 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 ;; General Public License for more details.
  15
  16 ;; You should have received a copy of the GNU General Public License
  17 ;; along with this program; see the file COPYING.  If not, write to the
  18 ;; Free Software Foundation, 51 Franklin Street, Fifth Floor, Boston,
  19 ;; MA 02139, USA.
  20
  21 ;;; Description:
  22 ;; wesnoth-mode is a major mode for Emacs which assists in the editing
  23 ;; of Wesnoth Markup Language (WML) files.  Currently, this major-mode
  24 ;; features syntax highlighting support, automatic indentation,
  25 ;; context-sensitive completion and WML checking.
  26
  27 ;;; Commentary:
  28 ;; Add the following to your .emacs:
  29 ;;   (add-to-list 'load-path "path/to/wesnoth-mode")
  30 ;;   (autoload 'wesnoth-mode "wesnoth-mode" "Major mode for editing WML." t)
  31 ;; Optionally adding:
  32 ;;   (add-to-list 'auto-mode-alist '("\\.cfg\\'" . wesnoth-mode))
  33 ;; to automatically load wesnoth-mode for all files ending in '.cfg'.
  34
  35 ;;; History:
  36 ;; 1.3.3
  37 ;; * Improve performance when inserting missing elements.  Support for
  38 ;;   searching for missing elements over a region has been removed;
  39 ;;   `narrow-to-region' can be used to provide the functionality when
  40 ;;   required.
  41 ;; * All warnings found when checking WML are now underlined in the buffer.
  42 ;; * Next and previous warning can be jumped to using C-c C-f (or C-x `) and
  43 ;;   C-c C-b, respectively.
  44 ;; * Any macro arguments are now prompted for and inserted when performing
  45 ;;   completing, as suggested by fabi.
  46 ;; * Improved handling of completion; no longer prompt when no completion
  47 ;;   found, as suggested by uzytkownik.
  48 ;; * Added indentation for FOREACH, as suggested by fabi.
  49 ;; * Several bugs and inconsistencies corrected.
  50 ;; 1.3.2
  51 ;; * Major performance improvements to indentation and WML checking.
  52 ;; * Fixed a bug where nesting could break when inserting multiple elements
  53 ;;   near the last element in a buffer.
  54 ;; * Fixed a bug where attributes immediately within #ifn?def were always
  55 ;;   reported to be illegal.
  56 ;; * Fixed a bug where tags immediately within #ifn?def were always legal.
  57 ;; * Fixed a bug where when inserting missing tags, scanning would only be
  58 ;;   performed up to point.
  59 ;; * Fixed a bug when jumping between preprocessor statements.
  60 ;; 1.3.1
  61 ;; * Completion history available is now specific to wesnoth-mode.
  62 ;; * Added binding to explicitly update macro information from the current
  63 ;;   buffer (C-c C-u).
  64 ;; * Significantly improved performance of completion and WML checking.
  65 ;; * Improved performance for inserting missing tags.
  66 ;; * Fixed a bug where #ifdef was never matched when checking WML.
  67 ;; * Added completion for preprocessor statements.
  68 ;; * Improved macro completion and checking.
  69 ;; 1.3.0
  70 ;; * Added support for Xemacs.
  71 ;; * WML checking is now context sensitive; checks attributes and macros.
  72 ;; * WML checks are now always performed on the entire buffer, with results
  73 ;;   displayed in a temporary buffer.
  74 ;; * Context-sensitive completion for attributes and tags.
  75 ;; * Completion for built-in and project-specific macros.
  76 ;; * Changed the following bindings:
  77 ;;   `wesnoth-insert-tag' - C-c e -> C-c t
  78 ;;   `wesnoth-jump-to-matching' - C-c m -> C-c o
  79 ;;   `wesnoth-check-structure' -> `wesnoth-check-wml' - C-c c
  80 ;; * Added the following bindings:
  81 ;;   `wesnoth-complete-attribute' - C-c a
  82 ;;   `wesnoth-complete-macro' - C-c m
  83 ;;   `wesnoth-complete-tag' - C-c t
  84 ;; * Removed the following bindings:
  85 ;;   `wesnoth-check-tag-names' - C-c n
  86 ;; * Removed `wesnoth-check-tag-names'.  Replaced by `wesnoth-check-wml'.
  87 ;; * Completion for an incomplete attribute, tag, or macro at point is
  88 ;;   attempted via TAB.
  89 ;; 1.2.5
  90 ;; * Fixed support for GNU Emacs 21.
  91 ;; * Added several new tags to `wesnoth-tags-list'.
  92 ;; * Added M-TAB binding for `wesnoth-insert-tag'.
  93 ;; * `wesnoth-insert-tag' now takes an optional numeric argument indicating
  94 ;;   how many blocks to wrap across instead of a region.
  95 ;; * Support for `wesnoth-indent-preprocessor-bol' removed.
  96 ;; * Fixed a bug in `wesnoth-insert-tag' and `wesnoth-insert-missing-closing'
  97 ;;   causing tags not to be inserted in the correct position.
  98 ;; * Fixed highlighting of array indexes as tags.
  99 ;; 1.2.4
 100 ;; * Improved syntax-highlighting for macro calls.
 101 ;; * Underscore is now treated as whitespace.
 102 ;; * Fixed incorrect indentation when preprocessor preceeded by whitespace.
 103 ;; * Point is now placed at the first non-whitespace character of the line,
 104 ;;   instead of the last.
 105 ;; * Corrected minor indentation bugs.
 106 ;; * Indenting across large regions is now much more efficient.
 107 ;; * Fix hooks modifying wesnoth-mode-map causing default bindings not being
 108 ;;   applied.
 109 ;; 1.2.3
 110 ;; * Now compatible with GNU Emacs 21.4.
 111 ;; * Added support for several new tags.
 112 ;; * Added menu entry for wesnoth-mode.
 113 ;; * Significant speed increase to indentation.
 114 ;; * Indentation can now be customised using `wesnoth-indent-preprocessor-bol'
 115 ;;   and `wesnoth-indent-savefile'; support for `wesnoth-indentation-function'
 116 ;;   has been removed.
 117 ;; * Trailing whitespace is no longer created when creating a second
 118 ;;   consecutive newline.
 119 ;; * Spurious newlines are no longer created when inserting a tag elements
 120 ;;   around a region.
 121 ;; 1.2.2
 122 ;; * Added functions: `wesnoth-indent', `wesnoth-element-closing',
 123 ;;   `wesnoth-element', `wesnoth-element-opening',
 124 ;;   `wesnoth-insert-and-indent', `wesnoth-insert-missing-closing'.
 125 ;; * Renamed `wesnoth-indent-line-default', `wesnoth-indent-line-savefile' and
 126 ;;   `wesnoth-jump-backward', `wesnoth-jump-forward' to
 127 ;;   `wesnoth-indent-withtags-inline', `wesnoth-indent-default-inline' and
 128 ;;   `wesnoth-backward-tag', `wesnoth-forward-tag', respectively.
 129 ;; * Fixed a bug in indentation where content was needed between elements pairs
 130 ;;   for indentation to work.
 131 ;; * Fixed `wesnoth-newline-and-indent' ignoring the state of
 132 ;;   `wesnoth-auto-indent-flag'.
 133 ;; * Fixed `{...}' and `#endif' not font-locking correctly.
 134 ;; * Added indentation styles: `wesnoth-indent-default',
 135 ;;   `wesnoth-indent-withtags' which implement a a similar indentation
 136 ;;   style to the existing styles, however all preprocessor statements are
 137 ;;   indented to the first column.
 138 ;; * Added support for several new tags.
 139 ;; * Modified `wesnoth-newline' to behave more consistently.
 140 ;; * `wesnoth-jump-to-matching', `wesnoth-forward-tag', `wesnoth-backward-tag'
 141 ;;   now leaves point at the beginning (when moving backward) or end (when
 142 ;;   moving forward) of the match.
 143 ;; * `wesnoth-jump-to-matching' now attempts to find a target if necessary and
 144 ;;   will now work on preprocessor statements.  Will now warn if jump
 145 ;;   destination may not be correct (due to errors in WML structure).
 146 ;; * Indentation style is now determined by `wesnoth-indentation-function'.
 147 ;; * `wesnoth-check-structure' can now be applied over an active region and
 148 ;;   now checks preprocessor statements for correct nesting.
 149 ;; * `wesnoth-newline' and `wesnoth-newline-and-indent' can now be forced to
 150 ;;   perform indentation by providing a prefix argument.
 151 ;; * Indentation styles now leave point at the first non-whitespace character
 152 ;;   of the line.
 153 ;; * `wesnoth-check-tag-names' now reports on success.
 154 ;; * `wesnoth-insert-tag' is now able to insert tags around a region.
 155 ;; * `outline-minor-mode' now works on macro definitions.
 156 ;; 1.2.1
 157 ;; * Base indent now defaults to 4.
 158 ;; * Added support for #ifndef.
 159 \f
 160 ;;; Code:
 161 (require 'easymenu)
 162 (require 'wesnoth-update)
 163 (require 'wesnoth-wml-data)
 164
 165 (defconst wesnoth-mode-version "1.3.3a"
 166   "The current version of `wesnoth-mode'.")
 167
 168 (defgroup wesnoth-mode nil "Wesnoth-mode access"
 169   :group 'languages
 170   :prefix "wesnoth-")
 171
 172 (defcustom wesnoth-auto-indent-flag t
 173   "Non-nil means indent the current line upon creating a newline."
 174   :type 'boolean
 175   :group 'wesnoth-mode)
 176
 177 (defcustom wesnoth-indent-savefile t
 178   "Non-nil means to use the current indentation conventions.
 179 If nil, use the old convention for indentation.
 180 The current convention is all attributes are indented a level deeper
 181 than their parent; in the past attributes were indented to the same
 182 level as their parent.")
 183
 184 (defcustom wesnoth-base-indent 4
 185   "The number of columns to indent WML."
 186   :type 'integer
 187   :group 'wesnoth-mode)
 188
 189 (defconst wesnoth-preprocessor-regexp
 190   "[\t ]*#\\(enddef\\|define \\|e\\(lse\\|nd\\(\\(de\\|i\\)f\\)\\)\\|\\(ifn?\\|un\\)def \\)"
 191   "Regular expression to match all preprocessor statements.")
 192
 193 (defconst wesnoth-preprocessor-opening-regexp
 194   "[\t ]*#\\(define \\|else\\|ifdef \\|ifndef \\)"
 195   "Regular expression to match \"opening\" preprocessor statements.")
 196
 197 (defconst wesnoth-preprocessor-closing-regexp
 198   "[\t ]*#\\(end\\(\\(de\\|i\\)f\\)\\)"
 199   "Regular expression to match \"closing\" preprocessor statements.")
 200
 201 (defvar wesnoth-define-blocks '()
 202   "Cache of all toplevel #define and #enddef pairs.")
 203
 204 (defvar wesnoth-history-list '()
 205   "History of inserted WML elements.")
 206
 207 (defvar wesnoth-warning-markers '()
 208   "Markers for warnings in the buffer.")
 209
 210 (defvar wesnoth-mode-hook nil)
 211
 212 (defface wesnoth-warning-face
 213   '((t (:underline "tomato1")))
 214   "Face to use for warnings in wesnoth-mode"
 215   :group 'wesnoth-mode)
 216
 217 (defvar wesnoth-mode-map
 218   (let ((map (make-sparse-keymap)))
 219     (define-key map (kbd "C-M-a") 'wesnoth-backward-element)
 220     (define-key map (kbd "C-M-e") 'wesnoth-forward-element)
 221     (define-key map (kbd "C-m") 'wesnoth-newline)
 222     (define-key map (kbd "C-j") 'wesnoth-newline-and-indent)
 223     (define-key map (kbd "C-c C-c") 'wesnoth-check-wml)
 224     (define-key map (kbd "C-c C-a") 'wesnoth-complete-attribute)
 225     (define-key map (kbd "C-c C-t") 'wesnoth-complete-tag)
 226     (define-key map (kbd "C-c C-p") 'wesnoth-complete-preprocessor)
 227     (define-key map (kbd "C-c C-u") 'wesnoth-update-project-information)
 228     (define-key map (kbd "M-TAB") 'wesnoth-complete-tag)
 229     (define-key map (kbd "C-c C-m") 'wesnoth-complete-macro)
 230     (define-key map (kbd "C-c C-o") 'wesnoth-jump-to-matching)
 231     (define-key map (kbd "C-c C-f") 'wesnoth-forward-warning)
 232     (define-key map (kbd "C-x `") 'wesnoth-forward-warning)
 233     (define-key map (kbd "C-c C-b") 'wesnoth-backward-warning)
 234     (define-key map (kbd "C-c C-/") 'wesnoth-insert-missing-closing)
 235     (define-key map (kbd "TAB") 'wesnoth-indent-or-complete)
 236     map)
 237   "Keymap used in `wesnoth-mode'.")
 238
 239 (easy-menu-define wesnoth-menu wesnoth-mode-map "Menu for wesnoth-mode"
 240   '("WML"
 241     ["Check WML" wesnoth-check-wml t]
 242     ["Indent or Complete" wesnoth-indent-or-complete t]
 243     ["Indent buffer" (lambda ()
 244                        (interactive)
 245                        (wesnoth-indent-region (point-min) (point-max))) t]
 246     ["Insert Tag" wesnoth-complete-tag t]
 247     ["Insert Attribute" wesnoth-complete-attribute t]
 248     ["Insert Macro" wesnoth-complete-macro t]
 249     ["Insert Preprocessor" wesnoth-complete-preprocessor t]
 250     ["Insert Missing Tag" wesnoth-insert-missing-closing t]
 251     ["Jump to Matching" wesnoth-jump-to-matching t]
 252     ["Update Macros" wesnoth-update-project-information t]))
 253
 254 (defvar wesnoth-syntax-table
 255   (let ((wesnoth-syntax-table (make-syntax-table)))
 256     (modify-syntax-entry ?# "<" wesnoth-syntax-table)
 257     (modify-syntax-entry ?\" "\"" wesnoth-syntax-table)
 258     (modify-syntax-entry ?= "." wesnoth-syntax-table)
 259     (modify-syntax-entry ?| "w" wesnoth-syntax-table)
 260     (modify-syntax-entry ?_ "_" wesnoth-syntax-table)
 261     (modify-syntax-entry ?- "_" wesnoth-syntax-table)
 262     (modify-syntax-entry ?. "_" wesnoth-syntax-table)
 263     (modify-syntax-entry ?\n ">" wesnoth-syntax-table)
 264     (modify-syntax-entry ?\r ">" wesnoth-syntax-table)
 265     wesnoth-syntax-table)
 266   "Syntax table for `wesnoth-mode'.")
 267
 268 ;; Prevents automatic syntax-highlighting of elements which might be
 269 ;; pre-processor statements.
 270 (defvar wesnoth-syntactic-keywords
 271   (list
 272    '("\\([\t ]*\\(#\\(?:define \\|e\\(?:lse\\|nd\\(?:\\(?:de\\|i\\)f\\)\\)\\|\\(?:ifn?\\|un\\)def \\)\\)\\)" 1 "w"))
 273   "Syntactic keywords for preprocessor statements within `wesnoth-mode'.")
 274
 275 (defvar wesnoth-font-lock-keywords
 276   (list
 277    '("#\\(?:define\\|\\(?:ifn?\\|un\\)def\\)" . font-lock-keyword-face)
 278    '("\\(#e\\(?:lse\\|nd\\(?:\\(?:de\\|i\\)f\\)\\)\\)" .
 279      font-lock-keyword-face)
 280    '("\\(#\\(?:define\\|\\(?:ifn?\\|un\\)def\\)\\)[\t ]+\\(\\(\\w\\|_\\)+\\)"
 281      2 font-lock-function-name-face)
 282    '("\\({[@~]?\\(\\w\\|\\.\\|/\\|-\\)+}\\)" (1 font-lock-function-name-face))
 283    '("\\({\\(\\w\\|:\\|_\\)+\\|{[~@]?\\)" (1 font-lock-function-name-face))
 284    '("}" .  font-lock-function-name-face)
 285    '("[\t ]*\\(\\[/?[^$]\\(\\w\\|_\\)+\\]\\)" 1 font-lock-type-face)
 286    '("\\$\\(\\w\\|_\\)+" . font-lock-variable-name-face)
 287    '("\\(\\(\\w\\|_\\)+\\(\\,[\t ]*\\(\\w\\|_\\)+\\)*\\)="
 288      1 font-lock-variable-name-face))
 289   "Syntax highlighting for `wesnoth-mode'.")
 290
 291 (defun wesnoth-element-closing (&optional limited)
 292   "Return the regexp to match a closing element.
 293 If LIMITED is non-nil, return a regexp which matches only the
 294 #enddef preprocessor."
 295   (concat "^[\t ]*\\(\\[/\\(\\w\\|_\\)+\\]\\|"
 296           (if limited
 297               "#enddef"
 298             "#end\\(?:def\\|if\\)")
 299           "\\)"))
 300
 301 (defun wesnoth-element-opening (&optional limited)
 302   "Return the regexp to match a closing element.
 303 If LIMITED is non-nil, return a regexp which matches only the
 304 #define preprocessor."
 305   (concat "^[\t ]*\\(\\[\\+?\\(\\w\\|_\\)+\\]\\|#define "
 306           (if limited
 307               "{FOREACH .+}"
 308             "\\|#ifn?def ")
 309           "\\)"))
 310
 311 (defun wesnoth-element (&optional limited)
 312   "Return the regexp to match a closing element.
 313 If LIMITED is non-nil, return a regexp which matches only the
 314 #define and #enddef preprocessors."
 315   (concat "^[\t ]*\\(\\[[+/]?\\(\\w\\|_\\)+\\]?\\|"
 316           (if limited
 317               "#define \\|#enddef"
 318             (substring wesnoth-preprocessor-regexp 5))
 319           "\\)"))
 320
 321 (defun wesnoth-find-next (type)
 322   "Find the next element of TYPE.
 323 TYPE is a symbol representing an element type, or a list of
 324 element types to find."
 325   (let ((element (wesnoth-next-element)))
 326     (while (and element (if (listp type)
 327                             (not (member (car element) type))
 328                           (not (eq (car element) type))))
 329       (setq element (wesnoth-next-element)))
 330     (when (if (listp type)
 331               (member (car element) type)
 332             (eq (car element) type))
 333       element)))
 334
 335 (defun wesnoth-next-element ()
 336   "Move to the next element in the buffer.
 337 Return non-nil when an element is found.  Otherwise, return nil."
 338   (interactive)
 339   (save-match-data
 340     (and (or (eolp) (looking-at "[}\t ]"))
 341          (search-forward-regexp "[^}
 342 \t ]" (point-max) t)
 343          (forward-char -1)))
 344   (let ((details (wesnoth-element-type (point))))
 345     (save-match-data
 346       (when (nth 2 details)
 347         (goto-char (nth 2 details))
 348         (while (nth 3 (parse-partial-sexp
 349                        (save-excursion (search-backward-regexp
 350                                         (wesnoth-element t) (point-min) t)
 351                                        (point))
 352                        (point)))
 353           (search-forward "\"" (point-max) t))))
 354     details))
 355
 356 (defun wesnoth-element-type (point)
 357   "Return details regarding the element at POINT.
 358 A list is returned, the elements of the list represent the
 359 following, respectively: A symbol representing the type of
 360 element; the position of the start of the element and the
 361 position of the end of the element.  POINT must be at the start
 362 of the element."
 363   (let ((element-matches
 364          '(("{\\(.*?[/\]\\)+}" . nil)  ;; pathnames
 365            ("{\\(\\w\\|_\\)+" . macro)
 366            ("\\[\\+?[^/]+?\\]" . tag-opening)
 367            ("\\[/.+?\\]" . tag-closing)
 368            ("\\(\\w\\|_\\)+[\t ]*=" . attribute)
 369            ("#\\(enddef\\|define \\|e\\(lse\\|nd\\(\\(de\\|i\\)f\\)\\)\\|\\(ifn?\\|un\\)def \\)"
 370             . preprocessor)
 371            ("#.*$" . comment)
 372            ("[^\t ]+") . nil)))
 373     (catch 'result
 374       (dolist (pair element-matches)
 375         (when (looking-at (car pair))
 376           (throw 'result (list (cdr pair)
 377                                (match-beginning 0)
 378                                (min (save-excursion (forward-line 1) (point))
 379                                     (match-end 0)))))))))
 380
 381 (defun wesnoth-estimate-element-type (point)
 382   "Return match data for a partial element at POINT."
 383   (save-excursion
 384     (goto-char point)
 385     (let ((element-matches
 386            '(("{\\(.*?[/\]\\)+$" . nil) ;; pathnames
 387              ("{\\(\\w\\|_\\)*$" . macro)
 388              ("\\[/\\(\\w\\|_\\)*$" . tag-closing)
 389              ("\\[\\+?\\(\\w\\|_\\)*$" . tag-opening)
 390              ("^[\t ]*\\(\\w\\|_\\)+$" . attribute)
 391              ("^[\t ]*#\\w*$" . preprocessor))))
 392       (catch 'result
 393         (dolist (pair element-matches)
 394           (when (looking-at (car pair))
 395             (throw 'result (list (cdr pair)
 396                                  (match-beginning 0)
 397                                  (match-end 0)))))))))
 398
 399 (defun wesnoth-guess-element-type (point)
 400   "Return details for the the element near POINT.
 401 Locate the start of the element before determining details.
 402 BOUND is the limit to search backwards."
 403   (let ((details (wesnoth-estimate-element-type point))
 404         (bound (save-excursion
 405                  (goto-char point)
 406                  (beginning-of-line)
 407                  (point))))
 408     (while (and (not (car details)) (> point bound))
 409       (setq point (1- point)
 410             details (wesnoth-estimate-element-type point)))
 411     (and (nth 1 details)
 412          (>= (point) (nth 1 details))
 413          (nth 2 details)
 414          (<= (point) (nth 2 details))
 415          details)))
 416
 417 \f
 418 ;;; Insertion and completion
 419 (defmacro wesnoth-element-completion (completions prompt partial
 420                                                   &optional completep)
 421   "Process completion of COMPLETIONS, displaying PROMPT.
 422 PARTIAL is the partial string on which to attempt completion.
 423 If COMPLETEP is non-nil, do not prompt if no completion is found."
 424   `(let* ((element (when ,partial (try-completion ,partial ,completions))))
 425      (cond ((eq element t)
 426             ,partial)
 427            ((and completep (null element))
 428             nil)
 429            ((and element (eq (try-completion element ,completions) t))
 430             element)
 431            ((> (length (all-completions (or element "") ,completions)) 1)
 432             (completing-read ,prompt ,completions
 433                              nil nil element
 434                              'wesnoth-history-list))
 435            (t
 436             element))))
 437
 438 (defun wesnoth-parent-tag ()
 439   "Return the name of the parent tag.
 440 If the parent is a preprocessor statement, return non-nil.
 441 If the element does not have a parent, return nil.
 442 Otherwise, return a string containing the name of the parent tag."
 443   (save-excursion
 444     (let ((start-point (point))
 445           (depth 1))
 446       (when (save-excursion (> (point) (progn (back-to-indentation)
 447                                               (point))))
 448         (end-of-line))
 449       (while (and (> depth 0)
 450                   (search-backward-regexp (wesnoth-element t)
 451                                           (point-min) t))
 452         (if (string-match "[\t ]*\\[/" (match-string 0))
 453             (setq depth (1+ depth))
 454           (setq depth (1- depth))))
 455       (beginning-of-line)
 456       (if (> depth 0)
 457           nil
 458         (when (looking-at (wesnoth-element-opening))
 459           (let ((parent (match-string-no-properties 1)))
 460             (if (or (string-match wesnoth-preprocessor-opening-regexp parent)
 461                     ;; Check if we're immediately within a macro
 462                     (and (goto-char start-point)
 463                          (search-backward-regexp "[}{]" (point-min) t)
 464                          (string= (match-string 0) "{")
 465                          (goto-char start-point)
 466                          (not (and (search-backward parent (point-min) t)
 467                                    (search-backward-regexp "[}{]" (point-min) t)
 468                                    (string= (match-string 0) "{")))))
 469                 t
 470               (substring parent 1 (1- (length parent))))))))))
 471
 472 (defun wesnoth-partial-macro-p ()
 473   "Return non-nil if point is in a partial macro."
 474   (save-excursion
 475     (let ((opened 0))
 476       (search-backward-regexp "{" (point-min) t)
 477       (while (search-forward-regexp "[{}]" (point-max) t)
 478         (if (string= (match-string 0) "{")
 479             (setq opened (1+ opened))
 480           (setq opened (1- opened))))
 481       (> opened 0))))
 482
 483 (defun wesnoth-indent-or-complete (&optional elements)
 484   "Indent or complete the line at point, depending on context.
 485 ELEMENTS is the number of elements to wrap around if inserting
 486 matching tags."
 487   (interactive "P")
 488   (or elements (setq elements 0))
 489   (let ((details (wesnoth-guess-element-type (point))))
 490     (cond
 491      ((eq (car details) 'tag-opening)
 492       (wesnoth-complete-tag elements t))
 493      ((and (eq (car details) 'macro)
 494            (wesnoth-partial-macro-p))
 495       (wesnoth-complete-macro t))
 496      ((eq (car details) 'preprocessor)
 497       (wesnoth-complete-preprocessor elements t))
 498      ((eq (car details) 'tag-closing)
 499       ;; FIXME: Solve incorrect behaviour when partial closing is "[/"
 500       (insert "a")
 501       (and (wesnoth-insert-missing-closing t)
 502            (delete-region (nth 1 details)
 503                           (save-excursion (beginning-of-line) (point))))
 504       (end-of-line)
 505       (wesnoth-indent))
 506      ((eq (car details) 'attribute)
 507       (wesnoth-complete-attribute t))
 508      (t
 509       (wesnoth-indent)))))
 510
 511 (defun wesnoth-preprocessor-closed-p (preprocessor)
 512   "Determine whether PREPROCESSOR has been closed.
 513 PREPROCESSOR is a string matching the preprocessor statement to
 514 be inserted."
 515   (save-excursion
 516     (back-to-indentation)
 517     (wesnoth-jump-to-matching preprocessor)
 518     (looking-at
 519      (if (string= preprocessor "#define ")
 520          "#enddef"
 521        "#endif"))))
 522
 523 (defun wesnoth-complete-preprocessor (&optional elements completep)
 524   "Complete and insert the preprocessor at point.
 525 ELEMENTS is the number of elements to wrap around.
 526 If COMPLETEP is non-nil, attempt to complete preprocessor at point."
 527   (interactive "P")
 528   (or elements (setq elements 0))
 529   (let* ((completions (wesnoth-emacs-completion-formats
 530                        '("define" "else" "ifdef" "ifndef"
 531                          "enddef" "endif" "undef")))
 532          (partial (when completep
 533                     (save-excursion
 534                       (back-to-indentation)
 535                       (when (looking-at "#\\(\\w*\\)$")
 536                         (match-string-no-properties 1)))))
 537          (preprocessor (wesnoth-element-completion
 538                         completions "Preprocessor: " partial completep))
 539          (closedp
 540           (save-excursion
 541             (when preprocessor
 542               (unless (string= "#" (substring preprocessor 0 1))
 543                 (setq preprocessor (concat "#" preprocessor)))
 544               (when (string-match "#\\(define\\|ifn?def\\|undef\\)" preprocessor)
 545                 (setq preprocessor (concat preprocessor " ")))
 546               (when partial
 547                 (delete-region
 548                  (save-excursion
 549                    (progn (search-backward
 550                            "#"
 551                            (save-excursion (back-to-indentation)
 552                                            (point))
 553                            t)
 554                           (point)))
 555                  (point)))
 556               (wesnoth-preprocessor-closed-p preprocessor)))))
 557     (when preprocessor
 558       (when partial
 559         (delete-region
 560          (save-excursion
 561            (progn (search-backward
 562                    "#" (save-excursion (back-to-indentation)
 563                                        (point))
 564                    t)
 565                   (point)))
 566          (point)))
 567       (if (and (string-match "#\\(define \\|ifn?def\\)" preprocessor)
 568                (not closedp))
 569           (progn
 570             (wesnoth-insert-tag elements preprocessor)
 571             (forward-line -1)
 572             (end-of-line))
 573         (wesnoth-insert-element-separately preprocessor)))))
 574
 575 (defun wesnoth-macro-arguments ()
 576   "Find any current macro arguments."
 577   (let ((results '())
 578         (depth (wesnoth-within-define (point))))
 579     (save-excursion
 580       (while (> depth 0)
 581         (save-match-data
 582           (search-backward-regexp
 583            "[\t ]*#define \\(?:\\w+\\|_\\)*\\(\\([\t ]*\\(\\w\\|_\\)+\\)*\\)"
 584            (point-min) t)
 585           (when (<= (wesnoth-within-define (point)) depth)
 586             (and (> depth 0)
 587                  (setq results
 588                        (append (mapcar (lambda (macro)
 589                                          (list macro nil))
 590                                        (split-string
 591                                         (match-string-no-properties 1)))
 592                                results)))
 593             (setq depth (1- depth)))))
 594       results)))
 595
 596 (defun wesnoth-complete-macro (&optional completep)
 597   "Complete and insert the macro at point.
 598 If COMPLETEP is non-nil, attempt to complete the macro at point."
 599   (interactive)
 600   (wesnoth-update-project-information)
 601   (let* ((macro-information (append (wesnoth-macro-arguments)
 602                                     wesnoth-macro-data
 603                                     wesnoth-local-macro-data))
 604          (completions (wesnoth-emacs-completion-formats
 605                        (mapcar 'car macro-information)))
 606          (details (wesnoth-guess-element-type (point)))
 607          (partial (when
 608                       (save-excursion
 609                         (and completep
 610                              (eq (car details) 'macro)
 611                              (goto-char (cadr details))
 612                              (looking-at "{\\(\\(\\w\\|_\\)*\\)")))
 613                     (match-string-no-properties 1)))
 614          (macro (wesnoth-element-completion completions "Macro: " partial
 615                                             completep))
 616          (args (cadr (assoc macro macro-information))))
 617     (when macro
 618       (if partial
 619           (progn
 620             ;; Delete the region corresponding to the current macro.
 621             (delete-region (nth 1 details) (nth 2 details))
 622             (insert "{" macro (if args " }" "}")))
 623         (wesnoth-insert-element-separately "{" macro (if args " }" "}")))
 624       (save-excursion
 625         (wesnoth-indent))
 626       (forward-char -1)
 627       (when args
 628         (let ((input (read-string (concat (car args) ": "))))
 629           (insert input (if (and (cdr args)
 630                                  (not (string= input "")))
 631                             " " ""))
 632           (while (and (setq args (cdr args)) (not (string= input "")))
 633             (insert (setq input (read-string (concat (car args) ": ")))
 634                     (if (and (not (string= input ""))
 635                              (cdr args))
 636                         " " "")))))
 637       (when (null args) (forward-char 1)))))
 638
 639 (defun wesnoth-complete-attribute (&optional completep)
 640   "Insert the attribute at point.
 641 If COMPLETEP is non-nil, attempt to complete the attribute at point."
 642   (interactive)
 643   (let* ((details (save-excursion
 644                     (back-to-indentation)
 645                     (wesnoth-guess-element-type (point))))
 646          (completions (save-excursion (goto-char (nth 1 details))
 647                                       (wesnoth-build-completion 1)))
 648          (partial (when completep
 649                     (when (save-excursion
 650                             (back-to-indentation)
 651                             (looking-at "\\(\\(\\w\\|_\\)+\\)"))
 652                       (match-string-no-properties 1))))
 653          (attribute (wesnoth-element-completion completions "Attribute: "
 654                                                 partial completep)))
 655     (when attribute
 656       (if partial
 657           (progn
 658             (delete-region (nth 1 details) (nth 2 details))
 659             (insert attribute "="))
 660         (wesnoth-insert-element-separately attribute
 661                                            (if (string-match "=" attribute)
 662                                                ""
 663                                              "=")))
 664       (save-excursion
 665         (wesnoth-indent)))))
 666
 667 (defun wesnoth-complete-tag (&optional elements completep)
 668   "Complete and insert the tag at point.
 669 ELEMENTS is the number of elements to wrap around.
 670 If COMPLETEP is non-nil, attempt to complete tag at point."
 671   (interactive "P")
 672   (or elements (setq elements 0))
 673   (let* ((details (wesnoth-guess-element-type (point)))
 674          (completions (save-excursion (goto-char (nth 1 details))
 675                                        (wesnoth-build-completion 0)))
 676          (partial (save-excursion
 677                     (when (and completep
 678                                (eq (car details) 'tag-opening)
 679                                (goto-char (cadr details))
 680                                (looking-at "\\[\\(\\(\\w\\|_\\)*\\)[\t ]*$"))
 681                       (match-string-no-properties 1))))
 682          (tag (wesnoth-element-completion completions "Tag: " partial
 683                                           completep))
 684          (closedp
 685           (save-excursion
 686             (wesnoth-jump-to-matching (concat "[" tag "]"))
 687             (back-to-indentation)
 688             (and (looking-at "\\[/\\(\\(\\w\\|_\\)+\\)")
 689                  (string= tag (match-string 1))))))
 690     (if tag
 691         (progn
 692           (if completep
 693               (progn
 694                 (delete-region (nth 1 details) (nth 2 details))
 695                 (if closedp
 696                     (progn
 697                       (wesnoth-insert-and-indent "[" tag "]")
 698                       (end-of-line))
 699                   (wesnoth-insert-tag elements tag)))
 700             (wesnoth-insert-tag elements tag)))
 701       (or completep (wesnoth-insert-tag elements)))))
 702
 703 (defun wesnoth-build-completion (position)
 704   "Create a new list for tag completion if necessary.
 705 Rebuilding list is required for versions of GNU Emacs earlier
 706 than 22.  POSITION is the argument passed to `nth' for
 707 `wesnoth-tag-data'."
 708   (interactive "P")
 709   (let ((parent (wesnoth-parent-tag)))
 710     (wesnoth-emacs-completion-formats
 711      (if (or (stringp parent) (null parent))
 712          (nth position (gethash parent wesnoth-tag-hash-table))
 713        (mapcar 'car wesnoth-tag-data)))))
 714
 715 (defun wesnoth-emacs-completion-formats (candidates)
 716   "Return the completions in the correct format for `emacs-major-version'.
 717 CANDIDATES is a list of all possible completions."
 718   (if (> emacs-major-version 21)
 719       candidates
 720     (let ((tags '())
 721           (iter 0))
 722       (dolist (tag candidates)
 723         (setq iter (1+ iter))
 724         (setq tags (append tags (list (cons tag iter)))))
 725       tags)))
 726
 727 (defun wesnoth-insert-tag (&optional elements tagname)
 728   "Insert the specified opening tag and it's matching closing tag.
 729 Both the opening and closing tags will be placed on their own
 730 lines with point positioned between them.  Completion of tags at
 731 the prompt uses `wesnoth-tags-list'.
 732
 733 ELEMENTS is specifies the number of following blocks which the
 734 tag should wrap around.
 735
 736 TAGNAME is the name of the tag to be inserted."
 737   (interactive "Ps")
 738   (unless tagname
 739     (setq tagname (completing-read "Tag: " (wesnoth-build-completion 0)
 740                                    nil nil nil 'wesnoth-history-list)))
 741   (when (or (not elements)
 742             (looking-at (concat "[\t ]*\\(:?\\[/\\|"
 743                                 wesnoth-preprocessor-regexp "\\)")))
 744     (setq elements 0))
 745   (let ((start (save-excursion (forward-line -1) (point)))
 746         (end (unless (= elements 0)
 747                ;; Work around some strange behaviour when the target is at the
 748                ;; end of the buffer.
 749                (save-excursion
 750                  (goto-char (point-max))
 751                  (beginning-of-line)
 752                  (unless (looking-at "^[\t ]*$")
 753                    (end-of-line)
 754                    (newline)))
 755                (wesnoth-nth-pair-position elements))))
 756     (if (string-match wesnoth-preprocessor-regexp tagname)
 757         (wesnoth-insert-element-separately tagname)
 758       (wesnoth-insert-element-separately "[" tagname "]"))
 759     (save-excursion
 760       (if end
 761           (goto-char (marker-position end))
 762         (newline (if (string-match wesnoth-preprocessor-regexp tagname) 1 2)))
 763       (if (string-match wesnoth-preprocessor-opening-regexp tagname)
 764           (wesnoth-insert-element-separately
 765            (if (string= tagname "#define ")
 766                "#enddef"
 767              "#endif"))
 768         (wesnoth-insert-element-separately "[/" tagname "]"))
 769       (indent-region start (point) nil))
 770     (unless end
 771       (forward-line 1)))
 772   (wesnoth-indent))
 773
 774 (defun wesnoth-insert-element-separately (&rest strings)
 775   "Concatenate STRINGS and insert them on a line of their own."
 776   (if (save-excursion (and (> (point) (progn (back-to-indentation) (point)))))
 777       (if (save-excursion (forward-line 1) (looking-at "^[\t ]*$"))
 778           (progn
 779             (forward-line 1)
 780             (end-of-line))
 781         (end-of-line)
 782         (newline))
 783     (beginning-of-line)
 784     (if (looking-at "^[\t ]*$")
 785         (end-of-line)
 786       (open-line 1)))
 787   (insert (apply 'concat strings)))
 788
 789 (defun wesnoth-insert-missing-closing (&optional completep)
 790   "Insert the next expected closing element at point.
 791 If COMPLETEP is non-nil, do not move forward a line when scanning
 792 for the matching tag."
 793   (interactive)
 794   (let ((match nil))
 795     (save-excursion
 796       (when (wesnoth-search-for-matching-tag
 797              'search-backward-regexp (wesnoth-element-opening) 'point-min
 798              (if completep nil 1))
 799         (setq match (and (looking-at (wesnoth-element-opening))
 800                          (match-string-no-properties 1)))))
 801     (when match
 802       (if (string= (substring match 0 1) "[")
 803           (wesnoth-insert-element-separately
 804            "[/" (substring match 1 (1- (length match))) "]")
 805         (wesnoth-insert-element-separately
 806          (cdr (assoc match '(("#define " . "#enddef")
 807                              ("#ifndef " . "#endif")
 808                              ("#ifdef " . "#endif")))))))
 809     (wesnoth-indent)
 810     (end-of-line)
 811     match))
 812
 813 (defun wesnoth-insert-and-indent (&rest args)
 814   "Concatenate and insert the given string(s) before indenting.
 815
 816 ARGS is a list of strings to be inserted."
 817   (insert (apply 'concat args))
 818   (wesnoth-indent))
 819
 820 (defun wesnoth-newline (&optional indent)
 821   "Indent the current line and create a newline.
 822 If `wesnoth-auto-indent-flag' is nil, indentation will not be
 823 performed.  Indentation can be forced by setting INDENT to
 824 non-nil."
 825   (interactive "P")
 826   (newline)
 827   (save-excursion
 828     (forward-line -1)
 829     (when (and (or wesnoth-auto-indent-flag indent)
 830                (not (looking-at "^[\t ]*$")))
 831       (wesnoth-indent))))
 832 \f
 833 ;;; Movement
 834 (defun wesnoth-navigate-element (repeat search-function bound)
 835   "Move point to the tag in the given direction REPEAT times.
 836
 837 SEARCH-FUNCTION is the symbol of the function for searching in
 838 the required direction, with BOUND marking the furthest point to
 839 search."
 840   (or repeat (setq repeat 1))
 841   (while (> repeat 0)
 842     (and (eq search-function 'search-forward-regexp) (end-of-line))
 843     (funcall search-function (wesnoth-element-opening) bound t)
 844     (back-to-indentation)
 845     (setq repeat (1- repeat))))
 846
 847 (defun wesnoth-nth-pair-position (count)
 848   "Return `point' after COUNT number of matching element pairs.
 849 COUNT is a positive number representing the number of balanced
 850 pairs to move across.
 851 `point' is returned as a marker object."
 852   (save-excursion
 853     (let ((failed nil))
 854       (if (> (point) (save-excursion (back-to-indentation) (point)))
 855           (end-of-line)
 856         (beginning-of-line))
 857       (while (> count 0)
 858         ;; Currently looking-at target tag.  Stop here to avoid
 859         ;; incorrect nesting.
 860         (unless (wesnoth-search-for-matching-tag
 861                  'search-forward-regexp (wesnoth-element-closing) 'point-max)
 862           (setq count 0)
 863           (setq failed t))
 864         (and (> (setq count (1- count)) 0) (forward-line 1)))
 865       (if failed
 866           (beginning-of-line)
 867         (end-of-line))
 868       (point-marker))))
 869
 870 (defun wesnoth-forward-element (repeat)
 871   "Move point to the end of the next tag.
 872 REPEAT is an optional numeric argument.  If REPEAT is non-nil,
 873 jump forward the specified number of tags."
 874   (interactive "p")
 875   (if (< repeat 0)
 876       (wesnoth-backward-element (abs repeat))
 877     (wesnoth-navigate-element repeat 'search-forward-regexp (point-max))))
 878
 879 (defun wesnoth-backward-element (repeat)
 880   "Move point to the beginning of the previous tag.
 881 REPEAT is an optional numeric argument.  If REPEAT is non-nil,
 882 jump backward the specified number of tags."
 883   (interactive "p")
 884   (if (< repeat 0)
 885       (wesnoth-forward-element (abs repeat))
 886     (wesnoth-navigate-element repeat 'search-backward-regexp (point-min))))
 887
 888 (defmacro wesnoth-search-for-matching-tag (search-function
 889                                            search-string bound &optional skip)
 890   "Search for the matching tag for the current line.
 891 SEARCH-FUNCTION is the name of the function used to perform the search.
 892 SEARCH-STRING is a string representing the matching tag type.
 893 BOUND is the bound to be passed to the search function.
 894 If SKIP is non-nil, skip the first element and continue from there."
 895   `(let ((depth 1))
 896      (when (and (or (and (numberp ,skip) (forward-line ,skip))
 897                     (funcall ,search-function (wesnoth-element) (funcall ,bound) t))
 898                 (or ,skip (not (string-match ,search-string (match-string 0)))))
 899        (while (and (> depth 0)
 900                    (funcall ,search-function (wesnoth-element)
 901                             (funcall ,bound) t))
 902          (if (string-match ,search-string (match-string 0))
 903              (setq depth (1- depth))
 904            (setq depth (1+ depth))))
 905        (= depth 0))))
 906
 907 (defun wesnoth-jump-to-matching (&optional element)
 908   "Jump point to the matching opening/closing tag.
 909 ELEMENT is an element to find a match for."
 910   (interactive)
 911   (beginning-of-line)
 912   (let ((target nil)
 913         (first-element nil))
 914     (save-excursion
 915       (cond
 916        ((or (and (stringp element)
 917                  (string-match (wesnoth-element-opening) element))
 918             (looking-at (wesnoth-element-opening)))
 919         (setq first-element (match-string-no-properties 0 element))
 920         (when (wesnoth-search-for-matching-tag
 921                'search-forward-regexp (wesnoth-element-closing) 'point-max
 922                (and (stringp element) 1))
 923           (beginning-of-line)
 924           (if (and (string-match wesnoth-preprocessor-opening-regexp
 925                                  first-element)
 926                    (looking-at (wesnoth-element-closing)))
 927               (when (string= (match-string-no-properties 0)
 928                              (cdr (assoc first-element
 929                                          '(("#define " . "#enddef")
 930                                            ("#ifndef " . "#endif")
 931                                            ("#ifdef " . "#endif")))))
 932                 (setq target (point)))
 933             (setq target (point)))))
 934        ((or (and (stringp element)
 935                  (string-match (wesnoth-element-closing) element))
 936             (looking-at (wesnoth-element-closing)))
 937         (end-of-line)
 938         (setq first-element (match-string-no-properties 0 element))
 939         (when (wesnoth-search-for-matching-tag
 940                'search-backward-regexp (wesnoth-element-opening)
 941                'wesnoth-wml-start-pos (and (stringp element) -1))
 942           (if (and (string-match wesnoth-preprocessor-closing-regexp
 943                                  first-element)
 944                    (looking-at (wesnoth-element-opening)))
 945               (progn
 946                 (when (or (and (string= "#enddef" first-element)
 947                                (string= "#define "
 948                                         (match-string-no-properties
 949                                          0)))
 950                           (and (string= "#endif" first-element)
 951                                (string-match
 952                                 "#ifn?def "
 953                                 (match-string-no-properties
 954                                  0))))
 955                   (setq target (point))))
 956             (setq target (point)))))
 957        (t
 958         (search-backward-regexp (wesnoth-element-opening) (point-min) t)
 959         (setq target (point)))))
 960     (if target
 961         (progn
 962           (goto-char target)
 963           (back-to-indentation))
 964       (when (interactive-p)
 965         (message "%s" "Tag does not appear to be matched")))))
 966 \f
 967 ;;; Indentation
 968 (defun wesnoth-wml-start-pos ()
 969   "Determine the position of `point' relative to where the actual WML begins.
 970 Return the likely starting position of the WML if it is found.
 971 Otherwise return nil."
 972   (save-excursion
 973     (goto-char (point-min))
 974     (when (search-forward-regexp (wesnoth-element) (point-max) t)
 975       (beginning-of-line)
 976       (point))))
 977
 978 (defun wesnoth-first-column-indent-p (point)
 979   "Return non-nil if the current line should not be indented.
 980
 981 POINT is the position in the buffer to check.
 982 CONTEXT represents the type of element which precedes the current element."
 983   (or (not (wesnoth-wml-start-pos))
 984       (<= (point) (wesnoth-wml-start-pos))
 985       (nth 3 (parse-partial-sexp
 986               (save-excursion (search-backward-regexp
 987                                (wesnoth-element t) (point-min) t)
 988                               (point))
 989               point))
 990       (looking-at wesnoth-preprocessor-regexp)))
 991
 992 (defun wesnoth-indent ()
 993   "Indent the current line as WML."
 994   (save-excursion
 995     (beginning-of-line)
 996     (let* ((cur-indent 0)
 997            (context-data (wesnoth-determine-context (point)))
 998            (context (car context-data))
 999            (ref-indent (cdr context-data)))
1000       (unless (wesnoth-first-column-indent-p (point))
1001         (cond
1002          ((eq context 'opening)
1003           (if (or (and wesnoth-indent-savefile
1004                        (or (looking-at "[\t ]*{NEXT ")
1005                            (and (not (looking-at (wesnoth-element-closing t)))
1006                                 (not (looking-at "[\t ]*{NEXT ")))))
1007                   (looking-at (wesnoth-element-opening t))
1008                   (looking-at "[\t ]*{FOREACH "))
1009               (setq cur-indent (+ ref-indent wesnoth-base-indent))
1010             (setq cur-indent ref-indent)))
1011          ((eq context 'closing)
1012           (if (or (looking-at "^[\t ]*\\(\\[/\\)")
1013                   (and (not wesnoth-indent-savefile)
1014                        (not (looking-at (wesnoth-element-opening t)))
1015                        (not (looking-at "[\t ]*{FOREACH "))))
1016               (setq cur-indent (- ref-indent wesnoth-base-indent))
1017             (setq cur-indent ref-indent)))))
1018       (indent-line-to (max cur-indent 0))))
1019   (when (> (save-excursion (back-to-indentation) (point))
1020            (point))
1021     (back-to-indentation)))
1022
1023 (defun wesnoth-within-define (position)
1024   "Determine whether point is currently inside a #define block.
1025 POSITION is the initial cursor position."
1026   (save-match-data
1027     (let ((depth 0)
1028           (defblocks (or wesnoth-define-blocks
1029                          (wesnoth-find-macro-definitions))))
1030       (unless (equal (car defblocks) 'none)
1031         (dolist (element defblocks)
1032           (when (= (cadr (sort (append (mapcar 'marker-position (cadr element))
1033                                        (list position)) '>)) position)
1034             (setq depth (max (car element) depth)))))
1035       depth)))
1036
1037 (defun wesnoth-find-macro-definitions ()
1038   "Return information regarding positioning of macro definitions."
1039   (save-excursion
1040     (goto-char (point-min))
1041     (let ((depth 0)
1042           openings cache)
1043       (while (search-forward-regexp "#define\\|#enddef" (point-max) t)
1044         (and (string= (match-string 0) "#define") (beginning-of-line))
1045         (setq depth
1046               (if (string= (match-string 0) "#define")
1047                   (progn
1048                     (add-to-list 'openings (point-marker))
1049                     (1+ depth))
1050                 (if openings
1051                     (progn
1052                       (add-to-list 'cache
1053                                    (list depth (list (car openings)
1054                                                      (point-marker))))
1055                       (setq openings (cdr openings))
1056                       (1- depth))
1057                   depth)))
1058         (end-of-line))
1059       (or cache (list 'none)))))
1060
1061 (defun wesnoth-indent-region (start end)
1062   "Indent the region from START to END.
1063 Creates and destroys a cache of macro definition details as necessary."
1064   (interactive "r")
1065   (unwind-protect
1066       (save-excursion
1067         (goto-char end)
1068         (setq end (point-marker))
1069         (goto-char start)
1070         (setq wesnoth-define-blocks (wesnoth-find-macro-definitions))
1071         (or (bolp) (forward-line 1))
1072         (while (< (point) end)
1073           (if (looking-at "^[\t ]*$")
1074               (indent-line-to 0)
1075             (funcall indent-line-function))
1076           (forward-line 1)))
1077     (setq wesnoth-define-blocks nil)))
1078
1079 (defun wesnoth-determine-context (position)
1080   "Determine the type of the last relevant element.
1081 POSITION is the buffer position of the element for which to
1082 determine the context."
1083   (save-excursion
1084     (let* ((elements (concat (substring (wesnoth-element t)
1085                                         0 (- (length (wesnoth-element t)) 3))
1086                              "\\|{FOREACH .+}\\|{NEXT .+}\\)"))
1087            (match (or
1088                    (and (search-backward-regexp
1089                          elements (point-min) t)
1090                         (progn
1091                           (while (save-match-data
1092                                    (looking-at "^[\t ]*\\[[^/].+\\]\\[/.+\\]"))
1093                             (search-backward-regexp elements
1094                                                     (point-min) t))
1095                           t)
1096                         (match-string 1))
1097                    ""))
1098            (depth (wesnoth-within-define position)))
1099       (while (and (wesnoth-wml-start-pos)
1100                   (> (wesnoth-within-define (point)) depth)
1101                   (not (= (point) (wesnoth-wml-start-pos))))
1102         (search-backward-regexp elements
1103                                 (wesnoth-wml-start-pos) t)
1104         (setq match (match-string 1)))
1105       (when (and (wesnoth-wml-start-pos)
1106                  (= (point) (wesnoth-wml-start-pos))
1107                  (= depth 0)
1108                  (string-match "#define" match))
1109         ;; Found nothing of use; reset match and assume top-level tag.
1110         (setq match ""))
1111       (cond
1112        ((string-match "\\[/\\|#enddef" match)
1113         (cons 'closing (current-indentation)))
1114        ((string-match "{NEXT " match)
1115         (cons 'closing (if wesnoth-indent-savefile
1116                            (- (current-indentation) wesnoth-base-indent)
1117                          (current-indentation))))
1118        ((string-match "\\[[^/]?\\|#define\\|{FOREACH " match)
1119         (cons 'opening (current-indentation)))))))
1120
1121 (defun wesnoth-newline-and-indent (&optional indent)
1122   "Indent both the current line and the newline created.
1123 If `wesnoth-auto-indent-flag' is nil, indentation will not be
1124 performed.
1125
1126 If the optional argument, INDENT is non-nil, force indentation to
1127 be performed."
1128   (interactive)
1129   (wesnoth-newline)
1130   (when (or wesnoth-auto-indent-flag indent)
1131     (wesnoth-indent)))
1132 \f
1133 ;;; WML checks
1134 (defun wesnoth-check-element-type (position)
1135   "Determine the context of the element.
1136 POSITION is the position of the element in the list."
1137   (let ((parent (save-match-data (wesnoth-parent-tag))))
1138     (if (or (stringp parent) (null parent))
1139         (member (match-string-no-properties 1)
1140                 (nth position (gethash parent wesnoth-tag-hash-table)))
1141       (member (match-string-no-properties 1)
1142               (let ((result '()))
1143                 (mapc
1144                  '(lambda (x)
1145                     (let ((value (nth position (cdr x))))
1146                       (and value (mapc '(lambda (y)
1147                                           (setq result (cons y result)))
1148                                        value))))
1149                  wesnoth-tag-data)
1150                 result)))))
1151
1152 ;; Provide `line-number-at-pos' implementation (not available in Emacs 21).
1153 (defun wesnoth-line-number-at-pos (&optional pos)
1154   "Return (narrowed) buffer line number at position POS.
1155 If POS is nil, use current buffer location.
1156 Counting starts at (point-min), so the value refers
1157 to the contents of the accessible portion of the buffer."
1158   (let ((opoint (or pos (point))) start)
1159     (save-excursion
1160       (goto-char (point-min))
1161       (setq start (point))
1162       (goto-char opoint)
1163       (forward-line 0)
1164       (1+ (count-lines start (point))))))
1165
1166 (defun wesnoth-check-output (buffer format-string &rest args)
1167   "Output the string as passed to `format'.
1168 BUFFER is the buffer to output the result.
1169 FORMAT-STRING is the string as the first argument of `format'.
1170 ARGS is any additional data required by `format' to handle FORMAT-STRING."
1171   (save-excursion
1172     (let ((lnap (wesnoth-line-number-at-pos)))
1173       (set-buffer buffer)
1174       (let ((buffer-read-only nil))
1175         (insert (apply 'format (concat "Line %d: " format-string "\n")
1176                        lnap args))))))
1177
1178 (defun wesnoth-extract-macro-details (macro-arguments)
1179   "Return a list of all macros in MACRO-ARGUMENTS."
1180   (when macro-arguments
1181     (let ((results '()))
1182       (dolist (macro (split-string macro-arguments "[{}][\t ]*"))
1183         (when (string-match "^\\(\\(?:\\w\\|_\\)+\\)"
1184                             macro)
1185           (add-to-list 'results (match-string-no-properties 1 macro))))
1186       results)))
1187
1188 (defmacro wesnoth-check-process (format-string &rest args)
1189   "Output to buffer where requested and position overlays as required.
1190 FORMAT-STRING is the string to pass as the first argument to
1191 `format' for the error.  ARGS is a list of arguments required by
1192 FORMAT-STRING."
1193   `(progn
1194      (wesnoth-check-output outbuf ,format-string ,@args)
1195      (wesnoth-place-overlay (match-beginning 0) (match-end 0))))
1196
1197 (defmacro wesnoth-overlay-at-pos-p (position)
1198   "Return non-nil when there is an overlay at POSITION."
1199   `(and (overlays-at (goto-char ,position))
1200         (overlay-get (car (overlays-at (point))) 'wesnoth-error)
1201         (overlay-start (car (overlays-at (point))))))
1202
1203 (defmacro wesnoth-locate-warning (string start end)
1204   "Search for STRING and move to the warning in the given direction.
1205 Searching starts from `point' and will wrap from START if no
1206 match was found.  STRING is a form to locate the warning in the
1207 required direction.  START is the start of the region searched.
1208 END is the end of the region searched."
1209   `(let ((target nil))
1210      (save-excursion
1211        (cond
1212         ((setq target (wesnoth-overlay-at-pos-p ,string)))
1213         ((setq target (wesnoth-overlay-at-pos-p ,start)))
1214         ((and (not (= (goto-char ,string) ,end))
1215               (setq target (wesnoth-overlay-at-pos-p (point)))))))
1216      target))
1217
1218 (defun wesnoth-forward-warning ()
1219   "Move to the next warning."
1220   (interactive)
1221   (let ((target
1222          (if (fboundp 'next-overlay-change)
1223              (save-excursion
1224                (end-of-line)
1225                (wesnoth-locate-warning (next-overlay-change (point))
1226                                        (point-min)
1227                                        (point-max)))
1228            (wesnoth-target-position '< '>))))
1229     (if target
1230         (goto-char target)
1231       (message "%s" "No warnings found"))))
1232
1233 (defun wesnoth-backward-warning ()
1234   "Move to the previous warning."
1235   (interactive)
1236   (let ((target
1237          (if (fboundp 'previous-overlay-change)
1238              (save-excursion
1239                (beginning-of-line)
1240                (wesnoth-locate-warning (1- (previous-overlay-change (point)))
1241                                        (point-max)
1242                                        (point-min)))
1243            (wesnoth-target-position '> '< t))))
1244     (if target
1245         (goto-char target)
1246       (message "%s" "No warnings found"))))
1247
1248 (defun wesnoth-target-position (predicate search &optional lastp)
1249   "Return the target marker position.
1250 PREDICATE is the function to use to sort
1251 `wesnoth-warning-markers'.  SEARCH must be a function which
1252 returns non-nil when the match is correct.  If LASTP is non-nil,
1253 swap the order of the sorted positions when attempting to
1254 fallback."
1255   (let ((positions (sort (mapcar 'marker-position wesnoth-warning-markers)
1256                          predicate)))
1257     (or (catch 'pos
1258           (dolist (position positions)
1259             (when (funcall search position (point))
1260               (throw 'pos position))))
1261         (car positions))))
1262
1263 (defun wesnoth-place-overlay (start end)
1264   "Place overlay in the region and apply necessary properties.
1265 START is the start of the region to place the overlay.  END is
1266 the end of the region to place the overlay."
1267   (if (fboundp 'overlay-put)
1268       (let ((overlay (make-overlay start end)))
1269         (overlay-put overlay 'wesnoth-error t)
1270         (overlay-put overlay 'face 'wesnoth-warning-face))
1271     (add-to-list 'wesnoth-warning-markers (save-excursion
1272                                             (goto-char start)
1273                                             (point-marker)))))
1274
1275 (defun wesnoth-check-wml ()
1276   "Perform context-sensitive analysis of WML-code."
1277   (interactive)
1278   (wesnoth-update-project-information)
1279   (if (fboundp 'delete-overlay)
1280       (dolist (overlay (overlays-in (point-min) (point-max)))
1281         (if (eq 'wesnoth-warning-face (overlay-get overlay 'face))
1282             (delete-overlay overlay)))
1283     (setq wesnoth-warning-markers nil))
1284   (when (= 0 (hash-table-count wesnoth-tag-hash-table))
1285     (error "WML data not available; unable to generate report"))
1286   (setq wesnoth-define-blocks (wesnoth-find-macro-definitions))
1287   (let ((unmatched '())
1288         (outbuf (and (interactive-p) (get-buffer-create "*WML*")))
1289         (last-match-pos 1)
1290         (details nil)
1291         (foreach '()))
1292     (save-excursion
1293       (set-buffer outbuf)
1294       (let ((buffer (buffer-name))
1295             (buffer-read-only nil))
1296         (erase-buffer)
1297         (insert (format "Checking %s...\n" buffer))
1298         (message (format "Checking %s..." buffer))))
1299     (save-excursion
1300       (goto-char (point-min))
1301       (while (setq details (wesnoth-find-next
1302                             '(tag-opening tag-closing preprocessor attribute
1303                                           macro)))
1304         (save-excursion
1305           (goto-char (match-beginning 0))
1306           (cond ((nth 3 (parse-partial-sexp last-match-pos (point)))
1307                  nil)
1308                 ((eq (car details) 'macro)
1309                  (dolist (macro (save-match-data
1310                                   (wesnoth-extract-macro-details
1311                                    (match-string-no-properties 0))))
1312                    (unless (assoc macro
1313                                   (append (wesnoth-macro-arguments)
1314                                           wesnoth-local-macro-data
1315                                           wesnoth-macro-data))
1316                      (wesnoth-check-process "Unknown macro: '%s'"
1317                                             macro)))
1318                  (save-match-data
1319                    (when
1320                        (looking-at
1321                         "{\\(FOREACH\\|NEXT\\).*[\t ]+\\(\\(?:\\w\\|_\\)+\\)}")
1322                      (if (string= (match-string-no-properties 1) "FOREACH")
1323                          (setq foreach
1324                                (cons (match-string-no-properties 2) foreach))
1325                        (if (string= (match-string-no-properties 1) "NEXT")
1326                            (progn
1327                              (unless (string= (car foreach)
1328                                               (match-string-no-properties 2))
1329                                (wesnoth-check-process
1330                                 (concat "NEXT does not match corresponding "
1331                                         "FOREACH: '%s' found; '%s' expected.")
1332                                 (match-string-no-properties 2)
1333                                 (car foreach)))
1334                              (setq foreach (cdr foreach))))))))
1335                 ((looking-at "[\t ]*\\[\\+?\\(\\(\\w\\|_\\)+\\)\\]")
1336                  (unless (wesnoth-check-element-type 0)
1337                    (wesnoth-check-process
1338                     "Tag not available in this context: '%s'"
1339                     (match-string-no-properties 1)))
1340                  (setq unmatched (cons (match-string-no-properties 1)
1341                                        unmatched)))
1342                 ((looking-at
1343                   (concat "[\t ]*\\(#define\\|#ifdef\\|#ifndef\\|#undef\\)"
1344                           "\\( \\(\\w\\|_\\)+\\)*"))
1345                  (unless (match-string-no-properties 2)
1346                    (wesnoth-check-process
1347                     (concat "Preprocessor statement has no argument: "
1348                             (match-string-no-properties 1))))
1349                  (unless (string= (match-string-no-properties 1) "#undef")
1350                    (setq unmatched (cons (match-string-no-properties 1)
1351                                          unmatched))))
1352                 ((looking-at wesnoth-preprocessor-closing-regexp)
1353                  (when (and unmatched
1354                             (not (string-match
1355                                   (cdr (assoc (match-string-no-properties 1)
1356                                               '(("enddef" . "#define")
1357                                                 ("endif" . "#ifn?def"))))
1358                                   (car unmatched))))
1359                    (wesnoth-check-process
1360                     "Preprocessor statement does not nest correctly"))
1361                  (setq unmatched (cdr unmatched)))
1362                 ((looking-at "[\t ]*\\(\\(\\w\\|_\\)+\\)=\\(.+\\)?")
1363                  (unless (wesnoth-check-element-type 1)
1364                    (wesnoth-check-process
1365                     "Attribute not available in this context: '%s'"
1366                     (match-string-no-properties 1)))
1367                  (unless (match-string 3)
1368                    (wesnoth-check-process
1369                     "Attribute has no value")))
1370                 ((looking-at "[\t ]*#else")
1371                  (unless (string-match "ifn?def" (car unmatched))
1372                    (if (string= (car unmatched) "#define")
1373                        (wesnoth-check-process "Expecting: '%s'"
1374                                               (car unmatched))
1375                      (wesnoth-check-process "Expecting: '[/%s]'"
1376                                             (car unmatched)))))
1377                 ((looking-at "[\t ]*\\[/\\(\\(\\w\\|_\\)+\\)\\]")
1378                  (when (and unmatched
1379                             (not (string= (match-string-no-properties 1)
1380                                           (car unmatched))))
1381                    (wesnoth-check-process
1382                     "Expecting '%s'"
1383                     (or (cdr (assoc (car unmatched)
1384                                     '(("#define" . "#enddef")
1385                                       ("#ifdef" . "#endif")
1386                                       ("#ifndef" . "#endif"))))
1387                         (concat "[/" (car unmatched) "]"))))
1388                  (setq unmatched (cdr unmatched)
1389                        last-match-pos (point))))))
1390       (when foreach
1391         (dolist (var foreach)
1392           (wesnoth-check-process "Unmatched FOREACH: '%s'" var)))
1393       (when unmatched
1394         (dolist (element unmatched)
1395           (wesnoth-check-process "Unmatched element: '%s'" element))))
1396     (save-excursion
1397       (setq wesnoth-define-blocks nil)
1398       (set-buffer outbuf)
1399       (toggle-read-only t)
1400       (let ((buffer (buffer-name))
1401             (buffer-read-only nil))
1402         (display-buffer outbuf t)
1403         (let ((warnings (- (wesnoth-line-number-at-pos
1404                             (save-excursion (goto-char (point-max)))) 2)))
1405           (insert (format (concat "\nCheck complete.  %d warning"
1406                                   (if (= warnings 1) "." "s.")) warnings)))
1407         (message (format "Checking %s...done" buffer))))))
1408
1409 \f
1410 ;;; wesnoth-mode
1411 (define-derived-mode wesnoth-mode fundamental-mode "wesnoth-mode"
1412   "Major mode for editing WML."
1413   (kill-all-local-variables)
1414   (use-local-map wesnoth-mode-map)
1415   (setq major-mode 'wesnoth-mode)
1416   (setq mode-name "WML")
1417   (set-syntax-table wesnoth-syntax-table)
1418   (set (make-local-variable 'outline-regexp) "[\t ]*#define")
1419   (set (make-local-variable 'comment-start) "#")
1420   (set (make-local-variable 'indent-line-function) 'wesnoth-indent)
1421   (set (make-local-variable 'indent-region-function) 'wesnoth-indent-region)
1422   (set (make-local-variable 'wesnoth-warning-markers) '())
1423   (set (make-local-variable 'font-lock-defaults)
1424        '(wesnoth-font-lock-keywords
1425          nil t nil nil
1426          (font-lock-syntactic-keywords . wesnoth-syntactic-keywords)))
1427   (setq indent-tabs-mode nil)
1428   (easy-menu-add wesnoth-menu wesnoth-mode-map)
1429   (wesnoth-create-wml-hash-table)
1430   (wesnoth-update-project-information)
1431   (run-hooks 'wesnoth-mode-hook))
1432
1433 (provide 'wesnoth-mode)
1434
1435 ;;; wesnoth-mode.el ends here