WebKit.pri

   1 # Include file to make it easy to include WebKit into Qt projects
   2
   3
   4 isEmpty(OUTPUT_DIR) {
   5     CONFIG(release):OUTPUT_DIR=$$PWD/WebKitBuild/Release
   6     CONFIG(debug):OUTPUT_DIR=$$PWD/WebKitBuild/Debug
   7 }
   8
   9 !gtk-port:CONFIG += qt-port
  10 qt-port:DEFINES += BUILDING_QT__=1
  11 qt-port:!building-libs {
  12     QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
  13     LIBS += -lQtWebKit
  14     DEPENDPATH += $$PWD/WebKit/qt/Api
  15 }
  16
  17 gtk-port:!building-libs {
  18     QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
  19     LIBS += -lWebKitGtk
  20     DEPENDPATH += $$PWD/WebKit/gtk/Api $$PWD/WebKit/gtk/WebCoreSupport
  21 }
  22
  23 gtk-port {
  24     CONFIG += link_pkgconfig
  25
  26     DEFINES += BUILDING_CAIRO__=1 BUILDING_GTK__=1
  27
  28     # We use FreeType directly with Cairo
  29     PKGCONFIG += cairo-ft
  30
  31     directfb: PKGCONFIG += cairo-directfb gtk+-directfb-2.0
  32     else: PKGCONFIG += cairo gtk+-2.0
  33
  34     # We use the curl http backend on all platforms
  35     PKGCONFIG += libcurl
  36
  37     LIBS += -lWebKitGtk -ljpeg -lpng
  38
  39     QMAKE_CXXFLAGS += $$system(icu-config --cppflags)
  40     QMAKE_LIBS += $$system(icu-config --ldflags)
  41
  42     # This set of warnings is borrowed from the Mac build
  43     QMAKE_CXXFLAGS += -Wall -W -Wcast-align -Wchar-subscripts -Wformat-security -Wmissing-format-attribute -Wpointer-arith -Wwrite-strings -Wno-format-y2k -Wno-unused-parameter -Wundef
  44 }
  45
  46 DEFINES += USE_SYSTEM_MALLOC
  47 CONFIG(release) {
  48     DEFINES += NDEBUG
  49 }
  50
  51 BASE_DIR = $$PWD
  52 qt-port:INCLUDEPATH += \
  53     $$PWD/WebKit/qt/Api
  54 gtk-port:INCLUDEPATH += \
  55     $$BASE_DIR/WebCore/platform/gtk \
  56     $$BASE_DIR/WebCore/platform/network/curl \
  57     $$BASE_DIR/WebCore/platform/graphics/cairo \
  58     $$BASE_DIR/WebCore/loader/gtk \
  59     $$BASE_DIR/WebCore/page/gtk \
  60     $$BASE_DIR/WebKit/gtk/Api \
  61     $$BASE_DIR/WebKit/gtk/WebCoreSupport
  62 INCLUDEPATH += \
  63     $$BASE_DIR/JavaScriptCore/ \
  64     $$BASE_DIR/JavaScriptCore/kjs \
  65     $$BASE_DIR/JavaScriptCore/bindings \
  66     $$BASE_DIR/JavaScriptCore/bindings/c \
  67     $$BASE_DIR/JavaScriptCore/wtf \
  68     $$BASE_DIR/JavaScriptCore/ForwardingHeaders \
  69     $$BASE_DIR/WebCore \
  70     $$BASE_DIR/WebCore/ForwardingHeaders \
  71     $$BASE_DIR/WebCore/platform \
  72     $$BASE_DIR/WebCore/platform/network \
  73     $$BASE_DIR/WebCore/platform/graphics \
  74     $$BASE_DIR/WebCore/loader \
  75     $$BASE_DIR/WebCore/page \
  76     $$BASE_DIR/WebCore/css \
  77     $$BASE_DIR/WebCore/dom \
  78     $$BASE_DIR/WebCore/bridge \
  79     $$BASE_DIR/WebCore/editing \
  80     $$BASE_DIR/WebCore/rendering \
  81     $$BASE_DIR/WebCore/history \
  82     $$BASE_DIR/WebCore/xml \
  83     $$BASE_DIR/WebCore/html
  84
  85
  86 macx {
  87         INCLUDEPATH += /usr/include/libxml2
  88         LIBS += -lxml2 -lxslt
  89 }