configure.ac

   1 AC_PREREQ(2.59)
   2
   3 m4_define([webkit_major_version], [1])
   4 m4_define([webkit_minor_version], [0])
   5 m4_define([webkit_micro_version], [2])
   6
   7 AC_INIT([WebKit],[webkit_major_version.webkit_minor_version.webkit_micro_version],[http://bugs.webkit.org/])
   8
   9 AC_CONFIG_HEADERS([aconfig.h])
  10
  11 WEBKIT_MAJOR_VERSION=webkit_major_version
  12 WEBKIT_MINOR_VERSION=webkit_minor_version
  13 WEBKIT_MICRO_VERSION=webkit_micro_version
  14 AC_SUBST(WEBKIT_MAJOR_VERSION)
  15 AC_SUBST(WEBKIT_MINOR_VERSION)
  16 AC_SUBST(WEBKIT_MICRO_VERSION)
  17
  18 AC_CONFIG_SRCDIR([WebCore/config.h])
  19
  20 dnl # Libtool library version, not to confuse with API version
  21 dnl # see http://www.gnu.org/software/libtool/manual.html#Versioning
  22 LIBWEBKITGTK_VERSION=1:0:0
  23 AC_SUBST([LIBWEBKITGTK_VERSION])
  24
  25 AM_INIT_AUTOMAKE([foreign subdir-objects])
  26
  27 AC_CANONICAL_HOST
  28
  29 # host checking - inspired by the GTK+ configure.in
  30 # TODO: os_mac, os_bsd
  31 AC_MSG_CHECKING([for native Win32])
  32 case "$host" in
  33      *-*-mingw*)
  34        os_win32=yes
  35        ;;
  36      *)
  37        os_win32=no
  38        ;;
  39 esac
  40 AC_MSG_RESULT([$os_win32])
  41
  42 case "$host" in
  43      *-*-linux*)
  44        os_linux=yes
  45        ;;
  46      *-*-freebsd*)
  47        os_freebsd=yes
  48        ;;
  49      *-*-darwin*)
  50        os_darwin=yes
  51        ;;
  52 esac
  53
  54 # If CXXFLAGS and CFLAGS are unset, default to empty.
  55 # This is to tell automake not to include '-g' if CXXFLAGS is not set
  56 # For more info - http://www.gnu.org/software/automake/manual/autoconf.html#C_002b_002b-Compiler
  57 if test -z "$CXXFLAGS"; then
  58    CXXFLAGS=""
  59 fi
  60 if test -z "$CFLAGS"; then
  61    CFLAGS=""
  62 fi
  63
  64 AM_PROG_CC_STDC
  65 AM_PROG_CC_C_O
  66 AC_PROG_CXX
  67 AC_PROG_INSTALL
  68 AC_DISABLE_STATIC
  69 AC_LIBTOOL_WIN32_DLL
  70 AC_PROG_LIBTOOL
  71 DOLT
  72
  73 # check for -fvisibility=hidden compiler support (GCC >= 4)
  74 saved_CFLAGS="$CFLAGS"
  75 CFLAGS="$CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  76 AC_MSG_CHECKING([if ${CXX} supports -fvisibility=hidden -fvisibility-inlines-hidden])
  77 AC_COMPILE_IFELSE([char foo;],
  78       [ AC_MSG_RESULT([yes])
  79         SYMBOL_VISIBILITY="-fvisibility=hidden" SYMBOL_VISIBILITY_INLINES="-fvisibility-inlines-hidden" ],
  80         AC_MSG_RESULT([no]))
  81 CFLAGS="$saved_CFLAGS"
  82 AC_SUBST(SYMBOL_VISIBILITY)
  83 AC_SUBST(SYMBOL_VISIBILITY_INLINES)
  84
  85 AC_PATH_PROG(PERL, perl)
  86 if test -z "$PERL"; then
  87    AC_MSG_ERROR([You need 'perl' to compile WebKit])
  88 fi
  89
  90 AC_PATH_PROG(BISON, bison)
  91 if test -z "$BISON"; then
  92    AC_MSG_ERROR([You need the 'bison' parser generator to compile WebKit])
  93 fi
  94
  95 AC_PATH_PROG(FLEX, flex)
  96 if test -z "$FLEX"; then
  97    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
  98 fi
  99
 100 AC_PATH_PROG(GPERF, gperf)
 101 if test -z "$GPERF"; then
 102    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
 103 fi
 104
 105 AC_PATH_PROG(MV, mv)
 106 if test -z "$MV"; then
 107    AC_MSG_ERROR([You need 'mv' to compile WebKit])
 108 fi
 109
 110 # GTK+ port only
 111 # Check for glib-genmarshal and glib-mkenums
 112 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
 113 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
 114 if test -z "$GLIB_GENMARSHAL" || test -z "$GLIB_MKENUMS"; then
 115    AC_MSG_ERROR([You need the GLib dev tools in your path])
 116 fi
 117
 118 # Check whether a C++ was found (AC_PROG_CXX sets $CXX to "g++" even when it
 119 # doesn't exist)
 120 AC_LANG_PUSH([C++])
 121 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[],[AC_MSG_ERROR([No C++ compiler found])])
 122 AC_LANG_POP([C++])
 123
 124 # C/C++ Language Features
 125 AC_C_CONST
 126 AC_C_INLINE
 127 AC_C_VOLATILE
 128
 129 # C/C++ Headers
 130 AC_HEADER_STDC
 131 AC_HEADER_STDBOOL
 132
 133 # pthread (not needed on Windows)
 134 if test "$os_win32" = "no"; then
 135 AC_CHECK_HEADERS([pthread.h],
 136                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exists]),
 137                  AC_MSG_ERROR([pthread support is required to build WebKit]))
 138 fi
 139
 140 # libjpeg headers
 141 AC_CHECK_HEADERS([jpeglib.h])
 142
 143 # check for pkg-config
 144 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 145 if test "$PKG_CONFIG" = "no"; then
 146    AC_MSG_ERROR([Cannot find pkg-config, make sure it is installed in your PATH])
 147 fi
 148
 149 # determine the Unicode backend
 150 AC_MSG_CHECKING([the Unicode backend to use])
 151 AC_ARG_WITH(unicode_backend,
 152             AC_HELP_STRING([--with-unicode-backend=@<:@icu@:>@],
 153                            [Select Unicode backend [default=icu]]),
 154             [],[unicode_backend="icu"])
 155
 156 case "$unicode_backend" in
 157      icu) ;;
 158      *) AC_MSG_ERROR([Invalid Unicode backend: must be icu.]) ;;
 159 esac
 160
 161 AC_MSG_RESULT([$unicode_backend])
 162
 163 if test "$unicode_backend" = "icu"; then
 164         if test "$os_darwin" = "yes"; then
 165                 UNICODE_CFLAGS="-I\$(srcdir)/JavaScriptCore/icu -I\$(srcdir)/WebCore/icu"
 166                 UNICODE_LIBS="-licucore"
 167         elif test "$os_win32" = "yes"; then
 168                 UNICODE_CFLAGS=""
 169                 UNICODE_LIBS="-licuin -licuuc"
 170         else
 171                 AC_PATH_PROG(icu_config, icu-config, no)
 172                 if test "$icu_config" = "no"; then
 173                         AC_MSG_ERROR([Cannot find icu-config. The ICU library is needed.])
 174                 fi
 175
 176                 # We don't use --cflags as this gives us a lot of things that we don't
 177                 # necessarily want, like debugging and optimization flags
 178                 # See man (1) icu-config for more info.
 179                 UNICODE_CFLAGS=`$icu_config --cppflags`
 180                 UNICODE_LIBS=`$icu_config --ldflags`
 181         fi
 182 fi
 183
 184 AC_SUBST([UNICODE_CFLAGS])
 185 AC_SUBST([UNICODE_LIBS])
 186
 187 # determine the GDK/GTK+ target
 188 AC_MSG_CHECKING([the target windowing system])
 189 AC_ARG_WITH(target,
 190             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
 191                            [Select webkit target [default=x11]]),
 192             [],[with_target="x11"])
 193
 194 case "$with_target" in
 195      x11|win32|quartz|directfb) ;;
 196      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
 197 esac
 198
 199 AC_MSG_RESULT([$with_target])
 200
 201 AC_MSG_CHECKING([for Hildon UI extensions])
 202 AC_ARG_WITH(hildon,
 203             AC_HELP_STRING([--with-hildon],
 204                            [Use Hildon UI extensions [default=no]]),
 205             [],[with_hildon="no"])
 206 AC_MSG_RESULT([$with_hildon])
 207
 208 if test "$with_hildon" = "yes"; then
 209     HILDON_CPPFLAGS="-DMAEMO_CHANGES"
 210     PKG_CHECK_MODULES([HILDON], [hildon-1])
 211     AC_SUBST([HILDON_CPPFLAGS])
 212     AC_SUBST([HILDON_CFLAGS])
 213     AC_SUBST([HILDON_LIBS])
 214 fi
 215
 216 # determine the http backend
 217 AC_MSG_CHECKING([the HTTP backend to use])
 218 AC_ARG_WITH(http_backend,
 219             AC_HELP_STRING([--with-http-backend=@<:@curl/soup@:>@],
 220                            [Select HTTP backend [default=curl]]),
 221             [],[with_http_backend="curl"])
 222
 223 case "$with_http_backend" in
 224      curl|soup) ;;
 225      *) AC_MSG_ERROR([Invalid HTTP backend: must be curl, soup.]) ;;
 226 esac
 227
 228 AC_MSG_RESULT([$with_http_backend])
 229
 230 # minimum base dependencies
 231 CAIRO_REQUIRED_VERSION=1.4
 232 FONTCONFIG_REQUIRED_VERSION=2.4
 233 FREETYPE2_REQUIRED_VERSION=9.0
 234 LIBXML_REQUIRED_VERSION=2.6
 235
 236 # minimum GTK+ base dependencies
 237 GLIB_REQUIRED_VERSION=2.0
 238 GOBJECT_REQUIRED_VERSION=2.0
 239 GTHREAD_REQUIRED_VERSION=2.0
 240 PANGO_REQUIRED_VERSION=1.0
 241 GTK_REQUIRED_VERSION=2.8
 242
 243 # optional modules
 244 LIBCURL_REQUIRED_VERSION=7.15
 245 LIBSOUP_REQUIRED_VERSION=2.23
 246 LIBXSLT_REQUIRED_VERSION=1.1.7
 247 SQLITE_REQUIRED_VERSION=3.0
 248 GSTREAMER_REQUIRED_VERSION=0.10
 249 GNOME_VFS_REQUIRED_VERSION=2.0
 250
 251 PKG_CHECK_MODULES([GLOBALDEPS],
 252                   [glib-2.0 >= $GLIB_REQUIRED_VERSION
 253                   gobject-2.0 >= $GOBJECT_REQUIRED_VERSION
 254                   gthread-2.0 >= $GTHREAD_REQUIRED_VERSION])
 255 AC_SUBST([GLOBALDEPS_CFLAGS])
 256 AC_SUBST([GLOBALDEPS_LIBS])
 257
 258 PKG_CHECK_MODULES([WEBKITDEPS],
 259                   [gtk+-2.0 >= $GTK_REQUIRED_VERSION
 260                   pango >= $PANGO_REQUIRED_VERSION
 261                   cairo >= $CAIRO_REQUIRED_VERSION
 262                   libxml-2.0 >= $LIBXML_REQUIRED_VERSION])
 263 AC_SUBST([WEBKITDEPS_CFLAGS])
 264 AC_SUBST([WEBKITDEPS_LIBS])
 265
 266 # check whether to build with debugging enabled
 267 AC_MSG_CHECKING([whether to do a debug build])
 268 AC_ARG_ENABLE(debug,
 269               AC_HELP_STRING([--enable-debug],
 270                              [turn on debugging [default=no]]),
 271               [],[enable_debug="no"])
 272 AC_MSG_RESULT([$enable_debug])
 273
 274 # check whether to enable dashboard support
 275 AC_MSG_CHECKING([whether to enable Dashboard support])
 276 AC_ARG_ENABLE(dashboard_support,
 277               AC_HELP_STRING([--enable-dashboard-support],
 278                              [enable Dashboard support [default=yes]]),
 279               [],[enable_dashboard_support="yes"])
 280 AC_MSG_RESULT([$enable_dashboard_support])
 281
 282 # check whether to enable HTML5 Offline Web Applications support
 283 AC_MSG_CHECKING([whether to enable HTML5 offline web applications support])
 284 AC_ARG_ENABLE(offline_web_applications,
 285               AC_HELP_STRING([--enable-offline-web-applications],
 286                              [enable HTML5 offline web applications support [default=yes]]),
 287               [],[enable_offline_web_applications="yes"])
 288 AC_MSG_RESULT([$enable_offline_web_applications])
 289
 290 # check whether to enable HTML5 client-side session and persitent storage support
 291 AC_MSG_CHECKING([whether to enable HTML5 client-side session and persistent storage support])
 292 AC_ARG_ENABLE(dom_storage,
 293               AC_HELP_STRING([--enable-dom-storage],
 294                              [enable HTML5 client-side session and persistent storage support [default=yes]]),
 295               [],[enable_dom_storage="yes"])
 296 AC_MSG_RESULT([$enable_dom_storage])
 297
 298 # check whether to build with database support
 299 AC_MSG_CHECKING([whether to enable HTML5 client-side database storage support])
 300 AC_ARG_ENABLE(database,
 301               AC_HELP_STRING([--enable-database],
 302                              [enable HTML5 client-side database storage support [default=yes]]),
 303               [],[enable_database="yes"])
 304 AC_MSG_RESULT([$enable_database])
 305
 306 # check whether to build with icon database support
 307 AC_MSG_CHECKING([whether to enable icon database support])
 308 AC_ARG_ENABLE(icon_database,
 309               AC_HELP_STRING([--enable-icon-database],
 310                              [enable icon database [default=yes]]),
 311               [],[enable_icon_database="yes"])
 312 AC_MSG_RESULT([$enable_icon_database])
 313
 314 # check whether to enable HTML5 audio/video support
 315 AC_MSG_CHECKING([whether to enable HTML5 video support])
 316 AC_ARG_ENABLE(video,
 317               AC_HELP_STRING([--enable-video],
 318                              [enable HTML5 video support [default=no]]),
 319               [],[enable_video="no"])
 320 AC_MSG_RESULT([$enable_video])
 321
 322 # check whether to enable XPath support
 323 AC_MSG_CHECKING([whether to enable XPath support])
 324 AC_ARG_ENABLE(xpath,
 325               AC_HELP_STRING([--enable-xpath],
 326                              [enable support for XPath [default=yes]]),
 327               [],[enable_xpath="yes"])
 328 AC_MSG_RESULT([$enable_xpath])
 329
 330 # check whether to enable XSLT support
 331 AC_MSG_CHECKING([whether to enable XSLT support])
 332 AC_ARG_ENABLE(xslt,
 333               AC_HELP_STRING([--enable-xslt],
 334                              [enable support for XSLT [default=yes]]),
 335               [],[enable_xslt="yes"])
 336 AC_MSG_RESULT([$enable_xslt])
 337
 338 # check whether to enable SVG support
 339 AC_MSG_CHECKING([whether to enable SVG support])
 340 AC_ARG_ENABLE(svg,
 341               AC_HELP_STRING([--enable-svg],
 342                              [enable support for SVG [default=yes]]),
 343               [],[enable_svg="yes"])
 344 AC_MSG_RESULT([$enable_svg])
 345
 346 # turn off svg features if --disable-svg is requested
 347 if test "$enable_svg" = "no"; then
 348    enable_svg_animation=no
 349    enable_svg_filters=no
 350    enable_svg_fonts=no
 351    enable_svg_foreign_object=no
 352    enable_svg_as_image=no
 353    enable_svg_use_element=no
 354 fi
 355
 356 # check whether to enable support for SVG animation
 357 AC_MSG_CHECKING([whether to enable support for SVG animation])
 358 AC_ARG_ENABLE(svg_animation,
 359               AC_HELP_STRING([--enable-svg-animation],
 360                              [enable support for SVG animation (experimental) [default=yes]]),
 361               [],[enable_svg_animation="yes"])
 362 AC_MSG_RESULT([$enable_svg_animation])
 363
 364 # check whether to enable support for SVG filters
 365 AC_MSG_CHECKING([whether to enable support for SVG filters])
 366 AC_ARG_ENABLE(svg_filters,
 367               AC_HELP_STRING([--enable-svg-filters],
 368                              [enable support for SVG filters (experimental) [default=no]]),
 369               [],[enable_svg_filters="no"])
 370 AC_MSG_RESULT([$enable_svg_filters])
 371
 372 # check whether to enable support for SVG fonts
 373 AC_MSG_CHECKING([whether to enable support for SVG fonts])
 374 AC_ARG_ENABLE(svg_fonts,
 375               AC_HELP_STRING([--enable-svg-fonts],
 376                              [enable support for SVG fonts (experimental) [default=yes]]),
 377               [],[enable_svg_fonts="yes"])
 378 AC_MSG_RESULT([$enable_svg_fonts])
 379
 380 # check whether to enable foreign objects support for SVG
 381 AC_MSG_CHECKING([whether to enable support for SVG foreign objects])
 382 AC_ARG_ENABLE(svg_foreign_object,
 383               AC_HELP_STRING([--enable-svg-foreign-object],
 384                              [enable support for SVG foreign objects (experimental) [default=yes]]),
 385               [],[enable_svg_foreign_object="yes"])
 386 AC_MSG_RESULT([$enable_svg_foreign_object])
 387
 388 # check whether to enable SVG As Image support
 389 AC_MSG_CHECKING([whether to enable SVG as Image support])
 390 AC_ARG_ENABLE(svg_as_image,
 391               AC_HELP_STRING([--enable-svg-as-image],
 392                              [enable SVG as Image support (experimental) [default=yes]]),
 393               [],[enable_svg_as_image="yes"])
 394 AC_MSG_RESULT([$enable_svg_as_image])
 395
 396 # check whether to enable SVG USE element support
 397 AC_MSG_CHECKING([whether to enable support for SVG use element])
 398 AC_ARG_ENABLE(svg_use_element,
 399               AC_HELP_STRING([--enable-svg-use-element],
 400                              [enable SVG use element support (experimental) [default=yes]]),
 401               [],[enable_svg_use_element="yes"])
 402 AC_MSG_RESULT([$enable_svg_use_element])
 403
 404 # check for SVG features, enabling SVG if necessary
 405 if test "$enable_svg_animation" = "yes" || \
 406    test "$enable_svg_filters" = "yes" || \
 407    test "$enable_svg_fonts" = "yes" || \
 408    test "$enable_svg_foreign_object" = "yes" || \
 409    test "$enable_svg_as_image" = "yes" || \
 410    test "$enable_svg_use_element" = "yes"; then
 411    svg_flags=yes
 412    if test "$enable_svg" = "no"; then
 413        AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
 414        enable_svg=yes
 415    fi
 416 fi
 417
 418 # check whether to enable code coverage
 419 AC_MSG_CHECKING([whether to enable code coverage support])
 420 AC_ARG_ENABLE(coverage,
 421               AC_HELP_STRING([--enable-coverage],
 422                              [enable code coverage support [default=no]]),
 423               [],[enable_coverage="no"])
 424 AC_MSG_RESULT([$enable_coverage])
 425
 426 # check whether to enable FastMalloc
 427 AC_MSG_CHECKING([whether to enable optimized memory allocator])
 428 AC_ARG_ENABLE(fast_malloc,
 429               AC_HELP_STRING([--enable-fast-malloc],
 430                              [enable optimized memory allocator default=yes, default=no for debug builds]),
 431               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
 432 AC_MSG_RESULT([$enable_fast_malloc])
 433
 434 # determine the font backend
 435 AC_MSG_CHECKING([the font backend to use])
 436 AC_ARG_WITH(font_backend,
 437             AC_HELP_STRING([--with-font-backend=@<:@freetype/pango@:>@],
 438                            [Select font backend [default=freetype]]),
 439             [],[with_font_backend="freetype"])
 440
 441 case "$with_font_backend" in
 442      freetype|pango) ;;
 443      *) AC_MSG_ERROR([Invalid font backend: must be freetype or pango.]) ;;
 444 esac
 445 AC_MSG_RESULT([$with_font_backend])
 446
 447 # Add '-g' flag to gcc if it's debug build
 448 if test "$enable_debug" = "yes"; then
 449    CXXFLAGS="$CXXFLAGS -g"
 450    CFLAGS="$CFLAGS -g"
 451 fi
 452
 453 # check if curl is available
 454 if test "$with_http_backend" = "curl"; then
 455    PKG_CHECK_MODULES([LIBCURL],
 456                      [libcurl >= $LIBCURL_REQUIRED_VERSION])
 457    if test "$os_win32" = "yes"; then
 458       LIBCURL_LIBS="$LIBCURL_LIBS -lWs2_32"
 459    fi
 460    AC_SUBST([LIBCURL_CFLAGS])
 461    AC_SUBST([LIBCURL_LIBS])
 462 fi
 463
 464 if test "$with_http_backend" = "soup"; then
 465    PKG_CHECK_MODULES([LIBSOUP],
 466                      [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
 467    AC_SUBST([LIBSOUP_CFLAGS])
 468    AC_SUBST([LIBSOUP_LIBS])
 469 fi
 470
 471 # check if FreeType/FontConfig are available
 472 if test "$with_font_backend" = "freetype"; then
 473    PKG_CHECK_MODULES([FREETYPE],
 474                      [cairo-ft
 475                      fontconfig >= $FONTCONFIG_REQUIRED_VERSION
 476                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
 477    AC_SUBST([FREETYPE_CFLAGS])
 478    AC_SUBST([FREETYPE_LIBS])
 479 fi
 480
 481 # check if sqlite 3 is available
 482 if test "$enable_icon_database" = "yes" || \
 483    test "$enable_database" = "yes" || \
 484    test "$enable_offline_web_applications" = "yes" || \
 485    test "$enable_dom_storage" = "yes"; then
 486    PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $SQLITE_REQUIRED_VERSION])
 487    AC_SUBST([SQLITE3_CFLAGS])
 488    AC_SUBST([SQLITE3_LIBS])
 489 fi
 490
 491 # check if libxslt is available
 492 if test "$enable_xslt" = "yes"; then
 493    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
 494    AC_SUBST([LIBXSLT_CFLAGS])
 495    AC_SUBST([LIBXSLT_LIBS])
 496 fi
 497
 498 # check if gstreamer is available
 499 if test "$enable_video" = "yes"; then
 500    PKG_CHECK_MODULES([GSTREAMER],
 501                      [gstreamer-0.10 >= $GSTREAMER_REQUIRED_VERSION
 502                      gstreamer-base-0.10,
 503                      gstreamer-plugins-base-0.10,
 504                      gnome-vfs-2.0 >= $GNOME_VFS_REQUIRED_VERSION])
 505    AC_SUBST([GSTREAMER_CFLAGS])
 506    AC_SUBST([GSTREAMER_LIBS])
 507 fi
 508
 509 # check for code coverage support
 510 if test "$enable_coverage" = "yes"; then
 511    COVERAGE_CFLAGS="-MD"
 512    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
 513    AC_SUBST([COVERAGE_CFLAGS])
 514    AC_SUBST([COVERAGE_LDFLAGS])
 515 fi
 516
 517 # check for HTML features
 518 if test "$enable_video" = "yes"; then
 519     html_flags=yes
 520 fi
 521
 522 # OS conditionals
 523 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
 524 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
 525 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
 526 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
 527
 528 # target conditionals
 529 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
 530 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
 531 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
 532 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
 533
 534 # HTTP backend conditionals
 535 AM_CONDITIONAL([USE_CURL], [test "$with_http_backend" = "curl"])
 536 AM_CONDITIONAL([USE_SOUP], [test "$with_http_backend" = "soup"])
 537
 538 # Font backend conditionals
 539 AM_CONDITIONAL([USE_FREETYPE], [test "$with_font_backend" = "freetype"])
 540 AM_CONDITIONAL([USE_PANGO], [test "$with_font_backend" = "pango"])
 541
 542 # WebKit feature conditionals
 543 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug" = "yes"])
 544 AM_CONDITIONAL([ENABLE_DASHBOARD_SUPPORT],[test "$enable_dashboard_support" = "yes"])
 545 AM_CONDITIONAL([ENABLE_OFFLINE_WEB_APPLICATIONS],[test "$enable_offline_web_applications" = "yes"])
 546 AM_CONDITIONAL([ENABLE_DOM_STORAGE],[test "$enable_dom_storage" = "yes"])
 547 AM_CONDITIONAL([ENABLE_DATABASE],[test "$enable_database" = "yes"])
 548 AM_CONDITIONAL([ENABLE_ICONDATABASE],[test "$enable_icon_database" = "yes"])
 549 AM_CONDITIONAL([ENABLE_XPATH],[test "$enable_xpath" = "yes"])
 550 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
 551 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
 552 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
 553 AM_CONDITIONAL([ENABLE_SVG_ANIMATION],[test "$enable_svg_animation" = "yes"])
 554 AM_CONDITIONAL([ENABLE_SVG_FILTERS],[test "$enable_svg_filters" = "yes"])
 555 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
 556 AM_CONDITIONAL([ENABLE_SVG_FOREIGN_OBJECT],[test "$enable_svg_foreign_object" = "yes"])
 557 AM_CONDITIONAL([ENABLE_SVG_AS_IMAGE],[test "$enable_svg_as_image" = "yes"])
 558 AM_CONDITIONAL([ENABLE_SVG_USE],[test "$enable_svg_use_element" = "yes"])
 559 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
 560 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
 561 AM_CONDITIONAL([SVG_FLAGS],[test "$svg_flags" = "yes"])
 562 AM_CONDITIONAL([HTML_FLAGS],[test "$html_flags" = "yes"])
 563
 564 AC_CONFIG_FILES([
 565 GNUmakefile
 566 WebKit/gtk/webkit-1.0.pc:WebKit/gtk/webkit.pc.in
 567 WebKit/gtk/webkit/webkitversion.h
 568 ]
 569 )
 570
 571 AC_OUTPUT
 572
 573 echo "
 574 WebKit was configured with the following options:
 575
 576 Build configuration:
 577  Enable debugging (slow)                                  : $enable_debug
 578  Code coverage support                                    : $enable_coverage
 579  Unicode backend                                          : $unicode_backend
 580  HTTP backend                                             : $with_http_backend
 581  Font backend                                             : $with_font_backend
 582  Optimized memory allocator                               : $enable_fast_malloc
 583 Features:
 584  Dashboard support                                        : $enable_dashboard_support
 585  HTML5 offline web applications support                   : $enable_offline_web_applications
 586  HTML5 client-side session and persistent storage support : $enable_dom_storage
 587  HTML5 client-side database storage support               : $enable_database
 588  HTML5 video element support                              : $enable_video
 589  Icon database support                                    : $enable_icon_database
 590  SVG support                                              : $enable_svg
 591  SVG animation support                                    : $enable_svg_animation
 592  SVG filters support                                      : $enable_svg_filters
 593  SVG fonts support                                        : $enable_svg_fonts
 594  SVG foreign object support                               : $enable_svg_foreign_object
 595  SVG as image support                                     : $enable_svg_as_image
 596  SVG use element support                                  : $enable_svg_use_element
 597  XPATH support                                            : $enable_xpath
 598  XSLT support                                             : $enable_xslt
 599 GTK+ configuration:
 600  GDK target                                               : $with_target
 601  Hildon UI extensions                                     : $with_hildon
 602 "