configure.ac

   1 AC_PREREQ(2.59)
   2
   3 m4_define([webkit_major_version], [1])
   4 m4_define([webkit_minor_version], [0])
   5 m4_define([webkit_micro_version], [2])
   6
   7 AC_INIT([WebKit],[webkit_major_version.webkit_minor_version.webkit_micro_version],[http://bugs.webkit.org/])
   8
   9 AC_CONFIG_HEADERS([aconfig.h])
  10
  11 WEBKIT_MAJOR_VERSION=webkit_major_version
  12 WEBKIT_MINOR_VERSION=webkit_minor_version
  13 WEBKIT_MICRO_VERSION=webkit_micro_version
  14 AC_SUBST(WEBKIT_MAJOR_VERSION)
  15 AC_SUBST(WEBKIT_MINOR_VERSION)
  16 AC_SUBST(WEBKIT_MICRO_VERSION)
  17
  18 AC_CONFIG_SRCDIR([WebCore/config.h])
  19
  20 dnl # Libtool library version, not to confuse with API version
  21 dnl # see http://www.gnu.org/software/libtool/manual.html#Versioning
  22 LIBWEBKITGTK_VERSION=1:0:0
  23 AC_SUBST([LIBWEBKITGTK_VERSION])
  24
  25 AM_INIT_AUTOMAKE([foreign subdir-objects])
  26
  27 AC_CANONICAL_HOST
  28
  29 # host checking - inspired by the GTK+ configure.in
  30 # TODO: os_mac, os_bsd
  31 AC_MSG_CHECKING([for native Win32])
  32 case "$host" in
  33      *-*-mingw*)
  34        os_win32=yes
  35        ;;
  36      *)
  37        os_win32=no
  38        ;;
  39 esac
  40 AC_MSG_RESULT([$os_win32])
  41
  42 case "$host" in
  43      *-*-linux*)
  44        os_linux=yes
  45        ;;
  46      *-*-freebsd*)
  47        os_freebsd=yes
  48        ;;
  49      *-*-darwin*)
  50        os_darwin=yes
  51        ;;
  52 esac
  53
  54 # If CXXFLAGS and CFLAGS are unset, default to empty.
  55 # This is to tell automake not to include '-g' if CXXFLAGS is not set
  56 # For more info - http://www.gnu.org/software/automake/manual/autoconf.html#C_002b_002b-Compiler
  57 if test -z "$CXXFLAGS"; then
  58    CXXFLAGS=""
  59 fi
  60 if test -z "$CFLAGS"; then
  61    CFLAGS=""
  62 fi
  63
  64 AM_PROG_CC_STDC
  65 AM_PROG_CC_C_O
  66 AC_PROG_CXX
  67 AC_PROG_INSTALL
  68 AC_DISABLE_STATIC
  69 AC_LIBTOOL_WIN32_DLL
  70 AC_PROG_LIBTOOL
  71 DOLT
  72
  73 # check for -fvisibility=hidden compiler support (GCC >= 4)
  74 saved_CFLAGS="$CFLAGS"
  75 CFLAGS="$CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  76 AC_MSG_CHECKING([if ${CXX} supports -fvisibility=hidden -fvisibility-inlines-hidden])
  77 AC_COMPILE_IFELSE([char foo;],
  78       [ AC_MSG_RESULT([yes])
  79         SYMBOL_VISIBILITY="-fvisibility=hidden" SYMBOL_VISIBILITY_INLINES="-fvisibility-inlines-hidden" ],
  80         AC_MSG_RESULT([no]))
  81 CFLAGS="$saved_CFLAGS"
  82 AC_SUBST(SYMBOL_VISIBILITY)
  83 AC_SUBST(SYMBOL_VISIBILITY_INLINES)
  84
  85 AC_PATH_PROG(PERL, perl)
  86 if test -z "$PERL"; then
  87    AC_MSG_ERROR([You need 'perl' to compile WebKit])
  88 fi
  89
  90 AC_PATH_PROG(BISON, bison)
  91 if test -z "$BISON"; then
  92    AC_MSG_ERROR([You need the 'bison' parser generator to compile WebKit])
  93 fi
  94
  95 AC_PATH_PROG(FLEX, flex)
  96 if test -z "$FLEX"; then
  97    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
  98 fi
  99
 100 AC_PATH_PROG(GPERF, gperf)
 101 if test -z "$GPERF"; then
 102    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
 103 fi
 104
 105 AC_PATH_PROG(MV, mv)
 106 if test -z "$MV"; then
 107    AC_MSG_ERROR([You need 'mv' to compile WebKit])
 108 fi
 109
 110 # GTK+ port only
 111 # Check for glib-genmarshal and glib-mkenums
 112 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
 113 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
 114 if test -z "$GLIB_GENMARSHAL" || test -z "$GLIB_MKENUMS"; then
 115    AC_MSG_ERROR([You need the GLib dev tools in your path])
 116 fi
 117
 118 # Check whether a C++ was found (AC_PROG_CXX sets $CXX to "g++" even when it
 119 # doesn't exist)
 120 AC_LANG_PUSH([C++])
 121 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[],[AC_MSG_ERROR([No C++ compiler found])])
 122 AC_LANG_POP([C++])
 123
 124 # C/C++ Language Features
 125 AC_C_CONST
 126 AC_C_INLINE
 127 AC_C_VOLATILE
 128
 129 # C/C++ Headers
 130 AC_HEADER_STDC
 131 AC_HEADER_STDBOOL
 132
 133 # pthread (not needed on Windows)
 134 if test "$os_win32" = "no"; then
 135 AC_CHECK_HEADERS([pthread.h],
 136                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exists]),
 137                  AC_MSG_ERROR([pthread support is required to build WebKit]))
 138 fi
 139
 140 # check for libjpeg the way Gtk does it.
 141 AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 142                    jpeg_ok=yes, jpeg_ok=no
 143                    AC_MSG_ERROR([JPEG library (libjpeg) not found]))
 144 if test "$jpeg_ok" = yes; then
 145    AC_MSG_CHECKING([for jpeglib])
 146    AC_TRY_CPP(
 147 [#include <stdio.h>
 148 #undef PACKAGE
 149 #undef VERSION
 150 #undef HAVE_STDLIB_H
 151 #include <jpeglib.h>],
 152          jpeg_ok=yes,
 153          jpeg_ok=no)
 154    AC_MSG_RESULT($jpeg_ok)
 155    if test "$jpeg_ok" = yes; then
 156       JPEG_LIBS="-ljpeg"
 157       # should we check for progressive JPEG like GTK+ as well?
 158    else
 159       AC_MSG_ERROR([JPEG library (libjpeg) not found])
 160    fi
 161 fi
 162 AC_SUBST([JPEG_LIBS])
 163
 164 # check for pkg-config
 165 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 166 if test "$PKG_CONFIG" = "no"; then
 167    AC_MSG_ERROR([Cannot find pkg-config, make sure it is installed in your PATH])
 168 fi
 169
 170 # determine the Unicode backend
 171 AC_MSG_CHECKING([the Unicode backend to use])
 172 AC_ARG_WITH(unicode_backend,
 173             AC_HELP_STRING([--with-unicode-backend=@<:@icu@:>@],
 174                            [Select Unicode backend [default=icu]]),
 175             [],[unicode_backend="icu"])
 176
 177 case "$unicode_backend" in
 178      icu) ;;
 179      *) AC_MSG_ERROR([Invalid Unicode backend: must be icu.]) ;;
 180 esac
 181
 182 AC_MSG_RESULT([$unicode_backend])
 183
 184 if test "$unicode_backend" = "icu"; then
 185         if test "$os_darwin" = "yes"; then
 186                 UNICODE_CFLAGS="-I\$(srcdir)/JavaScriptCore/icu -I\$(srcdir)/WebCore/icu"
 187                 UNICODE_LIBS="-licucore"
 188         elif test "$os_win32" = "yes"; then
 189                 UNICODE_CFLAGS=""
 190                 UNICODE_LIBS="-licuin -licuuc"
 191         else
 192                 AC_PATH_PROG(icu_config, icu-config, no)
 193                 if test "$icu_config" = "no"; then
 194                         AC_MSG_ERROR([Cannot find icu-config. The ICU library is needed.])
 195                 fi
 196
 197                 # We don't use --cflags as this gives us a lot of things that we don't
 198                 # necessarily want, like debugging and optimization flags
 199                 # See man (1) icu-config for more info.
 200                 UNICODE_CFLAGS=`$icu_config --cppflags`
 201                 UNICODE_LIBS=`$icu_config --ldflags`
 202         fi
 203 fi
 204
 205 AC_SUBST([UNICODE_CFLAGS])
 206 AC_SUBST([UNICODE_LIBS])
 207
 208 # determine the GDK/GTK+ target
 209 AC_MSG_CHECKING([the target windowing system])
 210 AC_ARG_WITH(target,
 211             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
 212                            [Select webkit target [default=x11]]),
 213             [],[with_target="x11"])
 214
 215 case "$with_target" in
 216      x11|win32|quartz|directfb) ;;
 217      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
 218 esac
 219
 220 AC_MSG_RESULT([$with_target])
 221
 222 AC_MSG_CHECKING([for Hildon UI extensions])
 223 AC_ARG_WITH(hildon,
 224             AC_HELP_STRING([--with-hildon],
 225                            [Use Hildon UI extensions [default=no]]),
 226             [],[with_hildon="no"])
 227 AC_MSG_RESULT([$with_hildon])
 228
 229 if test "$with_hildon" = "yes"; then
 230     HILDON_CPPFLAGS="-DMAEMO_CHANGES"
 231     PKG_CHECK_MODULES([HILDON], [hildon-1])
 232     AC_SUBST([HILDON_CPPFLAGS])
 233     AC_SUBST([HILDON_CFLAGS])
 234     AC_SUBST([HILDON_LIBS])
 235 fi
 236
 237 # determine the http backend
 238 AC_MSG_CHECKING([the HTTP backend to use])
 239 AC_ARG_WITH(http_backend,
 240             AC_HELP_STRING([--with-http-backend=@<:@curl/soup@:>@],
 241                            [Select HTTP backend [default=curl]]),
 242             [],[with_http_backend="curl"])
 243
 244 case "$with_http_backend" in
 245      curl|soup) ;;
 246      *) AC_MSG_ERROR([Invalid HTTP backend: must be curl, soup.]) ;;
 247 esac
 248
 249 AC_MSG_RESULT([$with_http_backend])
 250
 251 # minimum base dependencies
 252 CAIRO_REQUIRED_VERSION=1.4
 253 FONTCONFIG_REQUIRED_VERSION=2.4
 254 FREETYPE2_REQUIRED_VERSION=9.0
 255 LIBXML_REQUIRED_VERSION=2.6
 256
 257 # minimum GTK+ base dependencies
 258 GLIB_REQUIRED_VERSION=2.0
 259 GOBJECT_REQUIRED_VERSION=2.0
 260 GTHREAD_REQUIRED_VERSION=2.0
 261 PANGO_REQUIRED_VERSION=1.0
 262 GTK_REQUIRED_VERSION=2.8
 263
 264 # optional modules
 265 LIBCURL_REQUIRED_VERSION=7.15
 266 LIBSOUP_REQUIRED_VERSION=2.23
 267 LIBXSLT_REQUIRED_VERSION=1.1.7
 268 SQLITE_REQUIRED_VERSION=3.0
 269 GSTREAMER_REQUIRED_VERSION=0.10
 270 GNOME_VFS_REQUIRED_VERSION=2.0
 271
 272 PKG_CHECK_MODULES([GLOBALDEPS],
 273                   [glib-2.0 >= $GLIB_REQUIRED_VERSION
 274                   gobject-2.0 >= $GOBJECT_REQUIRED_VERSION
 275                   gthread-2.0 >= $GTHREAD_REQUIRED_VERSION])
 276 AC_SUBST([GLOBALDEPS_CFLAGS])
 277 AC_SUBST([GLOBALDEPS_LIBS])
 278
 279 PKG_CHECK_MODULES([WEBKITDEPS],
 280                   [gtk+-2.0 >= $GTK_REQUIRED_VERSION
 281                   pango >= $PANGO_REQUIRED_VERSION
 282                   cairo >= $CAIRO_REQUIRED_VERSION
 283                   libxml-2.0 >= $LIBXML_REQUIRED_VERSION])
 284 AC_SUBST([WEBKITDEPS_CFLAGS])
 285 AC_SUBST([WEBKITDEPS_LIBS])
 286
 287 # check whether to build with debugging enabled
 288 AC_MSG_CHECKING([whether to do a debug build])
 289 AC_ARG_ENABLE(debug,
 290               AC_HELP_STRING([--enable-debug],
 291                              [turn on debugging [default=no]]),
 292               [],[enable_debug="no"])
 293 AC_MSG_RESULT([$enable_debug])
 294
 295 # check whether to enable dashboard support
 296 AC_MSG_CHECKING([whether to enable Dashboard support])
 297 AC_ARG_ENABLE(dashboard_support,
 298               AC_HELP_STRING([--enable-dashboard-support],
 299                              [enable Dashboard support [default=yes]]),
 300               [],[enable_dashboard_support="yes"])
 301 AC_MSG_RESULT([$enable_dashboard_support])
 302
 303 # check whether to enable HTML5 Offline Web Applications support
 304 AC_MSG_CHECKING([whether to enable HTML5 offline web applications support])
 305 AC_ARG_ENABLE(offline_web_applications,
 306               AC_HELP_STRING([--enable-offline-web-applications],
 307                              [enable HTML5 offline web applications support [default=yes]]),
 308               [],[enable_offline_web_applications="yes"])
 309 AC_MSG_RESULT([$enable_offline_web_applications])
 310
 311 # check whether to enable HTML5 client-side session and persitent storage support
 312 AC_MSG_CHECKING([whether to enable HTML5 client-side session and persistent storage support])
 313 AC_ARG_ENABLE(dom_storage,
 314               AC_HELP_STRING([--enable-dom-storage],
 315                              [enable HTML5 client-side session and persistent storage support [default=yes]]),
 316               [],[enable_dom_storage="yes"])
 317 AC_MSG_RESULT([$enable_dom_storage])
 318
 319 # check whether to build with database support
 320 AC_MSG_CHECKING([whether to enable HTML5 client-side database storage support])
 321 AC_ARG_ENABLE(database,
 322               AC_HELP_STRING([--enable-database],
 323                              [enable HTML5 client-side database storage support [default=yes]]),
 324               [],[enable_database="yes"])
 325 AC_MSG_RESULT([$enable_database])
 326
 327 # check whether to build with icon database support
 328 AC_MSG_CHECKING([whether to enable icon database support])
 329 AC_ARG_ENABLE(icon_database,
 330               AC_HELP_STRING([--enable-icon-database],
 331                              [enable icon database [default=yes]]),
 332               [],[enable_icon_database="yes"])
 333 AC_MSG_RESULT([$enable_icon_database])
 334
 335 # check whether to enable HTML5 audio/video support
 336 AC_MSG_CHECKING([whether to enable HTML5 video support])
 337 AC_ARG_ENABLE(video,
 338               AC_HELP_STRING([--enable-video],
 339                              [enable HTML5 video support [default=no]]),
 340               [],[enable_video="no"])
 341 AC_MSG_RESULT([$enable_video])
 342
 343 # check whether to enable XPath support
 344 AC_MSG_CHECKING([whether to enable XPath support])
 345 AC_ARG_ENABLE(xpath,
 346               AC_HELP_STRING([--enable-xpath],
 347                              [enable support for XPath [default=yes]]),
 348               [],[enable_xpath="yes"])
 349 AC_MSG_RESULT([$enable_xpath])
 350
 351 # check whether to enable XSLT support
 352 AC_MSG_CHECKING([whether to enable XSLT support])
 353 AC_ARG_ENABLE(xslt,
 354               AC_HELP_STRING([--enable-xslt],
 355                              [enable support for XSLT [default=yes]]),
 356               [],[enable_xslt="yes"])
 357 AC_MSG_RESULT([$enable_xslt])
 358
 359 # check whether to enable SVG support
 360 AC_MSG_CHECKING([whether to enable SVG support])
 361 AC_ARG_ENABLE(svg,
 362               AC_HELP_STRING([--enable-svg],
 363                              [enable support for SVG [default=yes]]),
 364               [],[enable_svg="yes"])
 365 AC_MSG_RESULT([$enable_svg])
 366
 367 # turn off svg features if --disable-svg is requested
 368 if test "$enable_svg" = "no"; then
 369    enable_svg_animation=no
 370    enable_svg_filters=no
 371    enable_svg_fonts=no
 372    enable_svg_foreign_object=no
 373    enable_svg_as_image=no
 374    enable_svg_use_element=no
 375 fi
 376
 377 # check whether to enable support for SVG animation
 378 AC_MSG_CHECKING([whether to enable support for SVG animation])
 379 AC_ARG_ENABLE(svg_animation,
 380               AC_HELP_STRING([--enable-svg-animation],
 381                              [enable support for SVG animation (experimental) [default=yes]]),
 382               [],[enable_svg_animation="yes"])
 383 AC_MSG_RESULT([$enable_svg_animation])
 384
 385 # check whether to enable support for SVG filters
 386 AC_MSG_CHECKING([whether to enable support for SVG filters])
 387 AC_ARG_ENABLE(svg_filters,
 388               AC_HELP_STRING([--enable-svg-filters],
 389                              [enable support for SVG filters (experimental) [default=no]]),
 390               [],[enable_svg_filters="no"])
 391 AC_MSG_RESULT([$enable_svg_filters])
 392
 393 # check whether to enable support for SVG fonts
 394 AC_MSG_CHECKING([whether to enable support for SVG fonts])
 395 AC_ARG_ENABLE(svg_fonts,
 396               AC_HELP_STRING([--enable-svg-fonts],
 397                              [enable support for SVG fonts (experimental) [default=yes]]),
 398               [],[enable_svg_fonts="yes"])
 399 AC_MSG_RESULT([$enable_svg_fonts])
 400
 401 # check whether to enable foreign objects support for SVG
 402 AC_MSG_CHECKING([whether to enable support for SVG foreign objects])
 403 AC_ARG_ENABLE(svg_foreign_object,
 404               AC_HELP_STRING([--enable-svg-foreign-object],
 405                              [enable support for SVG foreign objects (experimental) [default=yes]]),
 406               [],[enable_svg_foreign_object="yes"])
 407 AC_MSG_RESULT([$enable_svg_foreign_object])
 408
 409 # check whether to enable SVG As Image support
 410 AC_MSG_CHECKING([whether to enable SVG as Image support])
 411 AC_ARG_ENABLE(svg_as_image,
 412               AC_HELP_STRING([--enable-svg-as-image],
 413                              [enable SVG as Image support (experimental) [default=yes]]),
 414               [],[enable_svg_as_image="yes"])
 415 AC_MSG_RESULT([$enable_svg_as_image])
 416
 417 # check whether to enable SVG USE element support
 418 AC_MSG_CHECKING([whether to enable support for SVG use element])
 419 AC_ARG_ENABLE(svg_use_element,
 420               AC_HELP_STRING([--enable-svg-use-element],
 421                              [enable SVG use element support (experimental) [default=yes]]),
 422               [],[enable_svg_use_element="yes"])
 423 AC_MSG_RESULT([$enable_svg_use_element])
 424
 425 # check for SVG features, enabling SVG if necessary
 426 if test "$enable_svg_animation" = "yes" || \
 427    test "$enable_svg_filters" = "yes" || \
 428    test "$enable_svg_fonts" = "yes" || \
 429    test "$enable_svg_foreign_object" = "yes" || \
 430    test "$enable_svg_as_image" = "yes" || \
 431    test "$enable_svg_use_element" = "yes"; then
 432    svg_flags=yes
 433    if test "$enable_svg" = "no"; then
 434        AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
 435        enable_svg=yes
 436    fi
 437 fi
 438
 439 # check whether to enable code coverage
 440 AC_MSG_CHECKING([whether to enable code coverage support])
 441 AC_ARG_ENABLE(coverage,
 442               AC_HELP_STRING([--enable-coverage],
 443                              [enable code coverage support [default=no]]),
 444               [],[enable_coverage="no"])
 445 AC_MSG_RESULT([$enable_coverage])
 446
 447 # check whether to enable FastMalloc
 448 AC_MSG_CHECKING([whether to enable optimized memory allocator])
 449 AC_ARG_ENABLE(fast_malloc,
 450               AC_HELP_STRING([--enable-fast-malloc],
 451                              [enable optimized memory allocator default=yes, default=no for debug builds]),
 452               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
 453 AC_MSG_RESULT([$enable_fast_malloc])
 454
 455 # determine the font backend
 456 AC_MSG_CHECKING([the font backend to use])
 457 AC_ARG_WITH(font_backend,
 458             AC_HELP_STRING([--with-font-backend=@<:@freetype/pango@:>@],
 459                            [Select font backend [default=freetype]]),
 460             [],[with_font_backend="freetype"])
 461
 462 case "$with_font_backend" in
 463      freetype|pango) ;;
 464      *) AC_MSG_ERROR([Invalid font backend: must be freetype or pango.]) ;;
 465 esac
 466 AC_MSG_RESULT([$with_font_backend])
 467
 468 # Add '-g' flag to gcc if it's debug build
 469 if test "$enable_debug" = "yes"; then
 470    CXXFLAGS="$CXXFLAGS -g"
 471    CFLAGS="$CFLAGS -g"
 472 fi
 473
 474 # check if curl is available
 475 if test "$with_http_backend" = "curl"; then
 476    PKG_CHECK_MODULES([LIBCURL],
 477                      [libcurl >= $LIBCURL_REQUIRED_VERSION])
 478    if test "$os_win32" = "yes"; then
 479       LIBCURL_LIBS="$LIBCURL_LIBS -lWs2_32"
 480    fi
 481    AC_SUBST([LIBCURL_CFLAGS])
 482    AC_SUBST([LIBCURL_LIBS])
 483 fi
 484
 485 if test "$with_http_backend" = "soup"; then
 486    PKG_CHECK_MODULES([LIBSOUP],
 487                      [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
 488    AC_SUBST([LIBSOUP_CFLAGS])
 489    AC_SUBST([LIBSOUP_LIBS])
 490 fi
 491
 492 # check if FreeType/FontConfig are available
 493 if test "$with_font_backend" = "freetype"; then
 494    PKG_CHECK_MODULES([FREETYPE],
 495                      [cairo-ft
 496                      fontconfig >= $FONTCONFIG_REQUIRED_VERSION
 497                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
 498    AC_SUBST([FREETYPE_CFLAGS])
 499    AC_SUBST([FREETYPE_LIBS])
 500 fi
 501
 502 # check if sqlite 3 is available
 503 if test "$enable_icon_database" = "yes" || \
 504    test "$enable_database" = "yes" || \
 505    test "$enable_offline_web_applications" = "yes" || \
 506    test "$enable_dom_storage" = "yes"; then
 507    PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $SQLITE_REQUIRED_VERSION])
 508    AC_SUBST([SQLITE3_CFLAGS])
 509    AC_SUBST([SQLITE3_LIBS])
 510 fi
 511
 512 # check if libxslt is available
 513 if test "$enable_xslt" = "yes"; then
 514    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
 515    AC_SUBST([LIBXSLT_CFLAGS])
 516    AC_SUBST([LIBXSLT_LIBS])
 517 fi
 518
 519 # check if gstreamer is available
 520 if test "$enable_video" = "yes"; then
 521    PKG_CHECK_MODULES([GSTREAMER],
 522                      [gstreamer-0.10 >= $GSTREAMER_REQUIRED_VERSION
 523                      gstreamer-base-0.10,
 524                      gstreamer-plugins-base-0.10,
 525                      gnome-vfs-2.0 >= $GNOME_VFS_REQUIRED_VERSION])
 526    AC_SUBST([GSTREAMER_CFLAGS])
 527    AC_SUBST([GSTREAMER_LIBS])
 528 fi
 529
 530 # check for code coverage support
 531 if test "$enable_coverage" = "yes"; then
 532    COVERAGE_CFLAGS="-MD"
 533    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
 534    AC_SUBST([COVERAGE_CFLAGS])
 535    AC_SUBST([COVERAGE_LDFLAGS])
 536 fi
 537
 538 # check for HTML features
 539 if test "$enable_video" = "yes"; then
 540     html_flags=yes
 541 fi
 542
 543 # OS conditionals
 544 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
 545 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
 546 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
 547 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
 548
 549 # target conditionals
 550 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
 551 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
 552 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
 553 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
 554
 555 # HTTP backend conditionals
 556 AM_CONDITIONAL([USE_CURL], [test "$with_http_backend" = "curl"])
 557 AM_CONDITIONAL([USE_SOUP], [test "$with_http_backend" = "soup"])
 558
 559 # Font backend conditionals
 560 AM_CONDITIONAL([USE_FREETYPE], [test "$with_font_backend" = "freetype"])
 561 AM_CONDITIONAL([USE_PANGO], [test "$with_font_backend" = "pango"])
 562
 563 # WebKit feature conditionals
 564 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug" = "yes"])
 565 AM_CONDITIONAL([ENABLE_DASHBOARD_SUPPORT],[test "$enable_dashboard_support" = "yes"])
 566 AM_CONDITIONAL([ENABLE_OFFLINE_WEB_APPLICATIONS],[test "$enable_offline_web_applications" = "yes"])
 567 AM_CONDITIONAL([ENABLE_DOM_STORAGE],[test "$enable_dom_storage" = "yes"])
 568 AM_CONDITIONAL([ENABLE_DATABASE],[test "$enable_database" = "yes"])
 569 AM_CONDITIONAL([ENABLE_ICONDATABASE],[test "$enable_icon_database" = "yes"])
 570 AM_CONDITIONAL([ENABLE_XPATH],[test "$enable_xpath" = "yes"])
 571 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
 572 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
 573 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
 574 AM_CONDITIONAL([ENABLE_SVG_ANIMATION],[test "$enable_svg_animation" = "yes"])
 575 AM_CONDITIONAL([ENABLE_SVG_FILTERS],[test "$enable_svg_filters" = "yes"])
 576 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
 577 AM_CONDITIONAL([ENABLE_SVG_FOREIGN_OBJECT],[test "$enable_svg_foreign_object" = "yes"])
 578 AM_CONDITIONAL([ENABLE_SVG_AS_IMAGE],[test "$enable_svg_as_image" = "yes"])
 579 AM_CONDITIONAL([ENABLE_SVG_USE],[test "$enable_svg_use_element" = "yes"])
 580 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
 581 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
 582 AM_CONDITIONAL([SVG_FLAGS],[test "$svg_flags" = "yes"])
 583 AM_CONDITIONAL([HTML_FLAGS],[test "$html_flags" = "yes"])
 584
 585 AC_CONFIG_FILES([
 586 GNUmakefile
 587 WebKit/gtk/webkit-1.0.pc:WebKit/gtk/webkit.pc.in
 588 WebKit/gtk/webkit/webkitversion.h
 589 ]
 590 )
 591
 592 AC_OUTPUT
 593
 594 echo "
 595 WebKit was configured with the following options:
 596
 597 Build configuration:
 598  Enable debugging (slow)                                  : $enable_debug
 599  Code coverage support                                    : $enable_coverage
 600  Unicode backend                                          : $unicode_backend
 601  HTTP backend                                             : $with_http_backend
 602  Font backend                                             : $with_font_backend
 603  Optimized memory allocator                               : $enable_fast_malloc
 604 Features:
 605  Dashboard support                                        : $enable_dashboard_support
 606  HTML5 offline web applications support                   : $enable_offline_web_applications
 607  HTML5 client-side session and persistent storage support : $enable_dom_storage
 608  HTML5 client-side database storage support               : $enable_database
 609  HTML5 video element support                              : $enable_video
 610  Icon database support                                    : $enable_icon_database
 611  SVG support                                              : $enable_svg
 612  SVG animation support                                    : $enable_svg_animation
 613  SVG filters support                                      : $enable_svg_filters
 614  SVG fonts support                                        : $enable_svg_fonts
 615  SVG foreign object support                               : $enable_svg_foreign_object
 616  SVG as image support                                     : $enable_svg_as_image
 617  SVG use element support                                  : $enable_svg_use_element
 618  XPATH support                                            : $enable_xpath
 619  XSLT support                                             : $enable_xslt
 620 GTK+ configuration:
 621  GDK target                                               : $with_target
 622  Hildon UI extensions                                     : $with_hildon
 623 "