configure.ac

   1 AC_PREREQ(2.59)
   2
   3 m4_define([webkit_major_version], [1])
   4 m4_define([webkit_minor_version], [1])
   5 m4_define([webkit_micro_version], [12])
   6
   7 # This is the version we'll be using as part of our User-Agent string
   8 # e.g., AppleWebKit/$(webkit_user_agent_version) ...
   9 #
  10 # Sourced from WebCore/Configurations/Version.xcconfig
  11 m4_define([webkit_user_agent_major_version], [531])
  12 m4_define([webkit_user_agent_minor_version], [2])
  13
  14 AC_INIT([WebKit],[webkit_major_version.webkit_minor_version.webkit_micro_version],[http://bugs.webkit.org/])
  15
  16 AC_CONFIG_MACRO_DIR([autotools])
  17 AC_CONFIG_AUX_DIR([autotools])
  18 AC_SUBST(ACLOCAL_AMFLAGS, "-I autotools")
  19
  20 AC_CONFIG_HEADERS([autotoolsconfig.h])
  21 AC_CANONICAL_HOST
  22
  23 WEBKIT_MAJOR_VERSION=webkit_major_version
  24 WEBKIT_MINOR_VERSION=webkit_minor_version
  25 WEBKIT_MICRO_VERSION=webkit_micro_version
  26 WEBKIT_USER_AGENT_MAJOR_VERSION=webkit_user_agent_major_version
  27 WEBKIT_USER_AGENT_MINOR_VERSION=webkit_user_agent_minor_version
  28 AC_SUBST(WEBKIT_MAJOR_VERSION)
  29 AC_SUBST(WEBKIT_MINOR_VERSION)
  30 AC_SUBST(WEBKIT_MICRO_VERSION)
  31 AC_SUBST(WEBKIT_USER_AGENT_MAJOR_VERSION)
  32 AC_SUBST(WEBKIT_USER_AGENT_MINOR_VERSION)
  33
  34 AC_CONFIG_SRCDIR([WebCore/config.h])
  35
  36 dnl # Libtool library version, not to confuse with API version
  37 dnl # see http://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html#Libtool-versioning
  38 LIBWEBKITGTK_VERSION=10:1:8
  39 AC_SUBST([LIBWEBKITGTK_VERSION])
  40
  41 AM_INIT_AUTOMAKE([foreign subdir-objects tar-ustar])
  42
  43 # Use AM_SILENT_RULES if present
  44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  45
  46 # host checking - inspired by the GTK+ configure.in
  47 # TODO: move these to webkit.m4?
  48 AC_MSG_CHECKING([for native Win32])
  49 case "$host" in
  50      *-*-mingw*)
  51        os_win32=yes
  52        ;;
  53      *)
  54        os_win32=no
  55        ;;
  56 esac
  57 AC_MSG_RESULT([$os_win32])
  58
  59 case "$host" in
  60      *-*-linux*)
  61        os_linux=yes
  62        ;;
  63      *-*-freebsd*)
  64        os_freebsd=yes
  65        ;;
  66      *-*-darwin*)
  67        os_darwin=yes
  68        ;;
  69 esac
  70
  71 case "$host_os" in
  72      gnu* | linux* | k*bsd*-gnu)
  73        os_gnu=yes
  74        ;;
  75      *)
  76        os_gnu=no
  77        ;;
  78 esac
  79
  80 # initialize webkit options
  81 WEBKIT_INIT
  82 AC_DISABLE_STATIC
  83 AC_LIBTOOL_WIN32_DLL
  84 AC_PROG_LIBTOOL
  85 # use dolt to speedup the build
  86 DOLT
  87
  88 AC_PATH_PROG(FLEX, flex)
  89 if test -z "$FLEX"; then
  90    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
  91 else
  92    FLEX_VERSION=`$FLEX --version | sed 's,.*\ \([0-9]*\.[0-9]*\.[0-9]*\)$,\1,'`
  93    AX_COMPARE_VERSION([2.5.33],[gt],[$FLEX_VERSION],
  94       AC_MSG_WARN([You need at least version 2.5.33 of the 'flex' lexer generator to compile WebKit correctly]))
  95 fi
  96
  97 AC_PATH_PROG(GPERF, gperf)
  98 if test -z "$GPERF"; then
  99    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
 100 fi
 101
 102 # pthread (not needed on Windows)
 103 if test "$os_win32" = "no"; then
 104 AC_CHECK_HEADERS([pthread.h],
 105                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exists]),
 106                  AC_MSG_ERROR([pthread support is required to build WebKit]))
 107 fi
 108
 109 # check for libjpeg the way Gtk does it.
 110 AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 111                    jpeg_ok=yes, jpeg_ok=no
 112                    AC_MSG_ERROR([JPEG library (libjpeg) not found]))
 113 if test "$jpeg_ok" = yes; then
 114    AC_MSG_CHECKING([for jpeglib])
 115    AC_TRY_CPP(
 116 [#include <stdio.h>
 117 #undef PACKAGE
 118 #undef VERSION
 119 #undef HAVE_STDLIB_H
 120 #include <jpeglib.h>],
 121          jpeg_ok=yes,
 122          jpeg_ok=no)
 123    AC_MSG_RESULT($jpeg_ok)
 124    if test "$jpeg_ok" = yes; then
 125       JPEG_LIBS="-ljpeg"
 126       # should we check for progressive JPEG like GTK+ as well?
 127    else
 128       AC_MSG_ERROR([JPEG library (libjpeg) not found])
 129    fi
 130 fi
 131 AC_SUBST([JPEG_LIBS])
 132
 133 # Check for libpng the way Gtk+ does it
 134 AC_MSG_CHECKING(for libpng12)
 135 if $PKG_CONFIG --exists libpng12 ; then
 136     AC_MSG_RESULT(yes)
 137     PNG_LIBS=`$PKG_CONFIG --libs libpng12`
 138 else
 139   AC_MSG_RESULT(no)
 140   AC_CHECK_LIB(png, png_read_info,
 141     [AC_CHECK_HEADER(png.h,
 142       png_ok=yes,
 143       png_ok=no)],
 144     AC_MSG_ERROR([PNG library (libpng) not found]), -lz -lm)
 145   if test "$png_ok" = yes; then
 146     AC_MSG_CHECKING([for png_structp in png.h])
 147     AC_TRY_COMPILE([#include <png.h>],
 148       [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
 149       png_ok=yes,
 150       png_ok=no)
 151     AC_MSG_RESULT($png_ok)
 152     if test "$png_ok" = yes; then
 153       PNG_LIBS='-lpng -lz'
 154     else
 155       AC_MSG_ERROR([PNG library (libpng) not found])
 156     fi
 157   else
 158    AC_MSG_ERROR([PNG library (libpng) not found])
 159   fi
 160 fi
 161 AC_SUBST([PNG_LIBS])
 162
 163 # determine the GDK/GTK+ target
 164 AC_MSG_CHECKING([the target windowing system])
 165 AC_ARG_WITH(target,
 166             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
 167                            [Select webkit target [default=x11]]),
 168             [],[with_target="x11"])
 169
 170 case "$with_target" in
 171      x11|win32|quartz|directfb) ;;
 172      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
 173 esac
 174
 175 AC_MSG_RESULT([$with_target])
 176
 177 AC_MSG_CHECKING([for Hildon UI extensions])
 178 AC_ARG_WITH(hildon,
 179             AC_HELP_STRING([--with-hildon],
 180                            [Use Hildon UI extensions [default=no]]),
 181             [],[with_hildon="no"])
 182 AC_MSG_RESULT([$with_hildon])
 183
 184 if test "$with_hildon" = "yes"; then
 185     HILDON_CPPFLAGS="-DMAEMO_CHANGES"
 186     PKG_CHECK_MODULES([HILDON], [hildon-1])
 187     AC_SUBST([HILDON_CPPFLAGS])
 188     AC_SUBST([HILDON_CFLAGS])
 189     AC_SUBST([HILDON_LIBS])
 190 fi
 191
 192 # minimum base dependencies
 193 LIBSOUP_REQUIRED_VERSION=2.27.4
 194 CAIRO_REQUIRED_VERSION=1.2
 195 FONTCONFIG_REQUIRED_VERSION=2.4
 196 FREETYPE2_REQUIRED_VERSION=9.0
 197 LIBXML_REQUIRED_VERSION=2.6
 198
 199 # minimum GTK+ base dependencies
 200 PANGO_REQUIRED_VERSION=1.12
 201 GTK_REQUIRED_VERSION=2.10
 202
 203 # optional modules
 204 LIBXSLT_REQUIRED_VERSION=1.1.7
 205 SQLITE_REQUIRED_VERSION=3.0
 206 GSTREAMER_REQUIRED_VERSION=0.10
 207 GNOME_KEYRING_REQUIRED_VERSION=2.26.0
 208 ENCHANT_REQUIRED_VERSION=0.22
 209 GAIL_REQUIRED_VERSION=1.8
 210
 211 # Available modules
 212 #
 213 # glib - glib and includes gthread
 214 # unicode - check and identify which unicode backend to use
 215 #
 216 # todo: webcore gtk
 217 WEBKIT_CHECK_DEPENDENCIES([glib unicode])
 218
 219 GETTEXT_PACKAGE=$PACKAGE
 220 AC_SUBST(GETTEXT_PACKAGE)
 221 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",
 222                    [The gettext catalog name])
 223
 224 PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= $LIBXML_REQUIRED_VERSION)
 225 AC_SUBST(LIBXML_CFLAGS)
 226 AC_SUBST(LIBXML_LIBS)
 227
 228 PKG_CHECK_MODULES(PANGO,
 229                   [pango >= $PANGO_REQUIRED_VERSION
 230                    pangoft2])
 231 AC_SUBST(PANGO_CFLAGS)
 232 AC_SUBST(PANGO_LIBS)
 233
 234 PKG_CHECK_MODULES(ENCHANT, enchant >= $ENCHANT_REQUIRED_VERSION)
 235 AC_SUBST(ENCHANT_CFLAGS)
 236 AC_SUBST(ENCHANT_LIBS)
 237
 238 PKG_CHECK_MODULES(GAIL, gail >= $GAIL_REQUIRED_VERSION)
 239 AC_SUBST(GAIL_CFLAGS)
 240 AC_SUBST(GAIL_LIBS)
 241
 242 # check for target-specific dependencies
 243 if test "$with_target" = "directfb"; then
 244    PKG_CHECK_MODULES(CAIRO, cairo-directfb >= $CAIRO_REQUIRED_VERSION)
 245    PKG_CHECK_MODULES(GTK, gtk+-directfb-2.0 >= $GTK_REQUIRED_VERSION)
 246    AC_DEFINE([WTF_PLATFORM_DIRECTFB],[1],[Define if target is DirectFB])
 247 else
 248    PKG_CHECK_MODULES(CAIRO, cairo >= $CAIRO_REQUIRED_VERSION)
 249    PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED_VERSION)
 250
 251    if test "$with_target" = "x11" && test "$os_win32" = "no"; then
 252       # check for XT
 253       PKG_CHECK_MODULES([XT],
 254                         [xt],
 255                         [xt_has_pkg_config=yes],
 256                         [xt_has_pkg_config=no])
 257       # some old versions of Xt do not provide xt.pc, so try to link against Xt
 258       # and if it's installed fall back to just adding -lXt
 259       if test "$xt_has_pkg_config" = "no"; then
 260          # using AC_CHECK_LIB instead of AC_SEARCH_LIB is fine in this case as
 261          # we don't care about the XtOpenDisplay symbol but only about the
 262          # existence of libXt
 263          AC_CHECK_LIB([Xt], [XtOpenDisplay],
 264                       [XT_CFLAGS=""; XT_LIBS="-lXt"],
 265                       [AC_MSG_ERROR([X Toolkit Intrinsics library (libXt) not found])])
 266       fi
 267       AC_SUBST([XT_CFLAGS])
 268       AC_SUBST([XT_LIBS])
 269       AC_DEFINE([WTF_PLATFORM_X11],[1],[Define if target is X11])
 270    fi
 271 fi
 272 AC_SUBST(GTK_CFLAGS)
 273 AC_SUBST(GTK_LIBS)
 274 AC_SUBST(CAIRO_CFLAGS)
 275 AC_SUBST(CAIRO_LIBS)
 276
 277 # check whether to build with debugging enabled
 278 AC_MSG_CHECKING([whether to do a debug build])
 279 AC_ARG_ENABLE(debug,
 280               AC_HELP_STRING([--enable-debug],
 281                              [turn on debugging [default=no]]),
 282               [],[enable_debug="no"])
 283 AC_MSG_RESULT([$enable_debug])
 284
 285 # check whether to enable optimized builds
 286 AC_MSG_CHECKING([whether to enable optimized builds])
 287 AC_ARG_ENABLE(optimizations,
 288               AC_HELP_STRING([--enable-optimizations],
 289                              [turn on optimize builds (GCC only)
 290                              [default=yes]]),
 291               [enable_optimizations=$enableval],
 292               [if test "$enable_debug" = "yes"; then enable_optimizations="no"; else enable_optimizations="yes"; fi])
 293 AC_MSG_RESULT([$enable_optimizations])
 294
 295 # check whether to enable dashboard support
 296 AC_MSG_CHECKING([whether to enable Dashboard support])
 297 AC_ARG_ENABLE(dashboard_support,
 298               AC_HELP_STRING([--enable-dashboard-support],
 299                              [enable Dashboard support [default=yes]]),
 300               [],[enable_dashboard_support="yes"])
 301 AC_MSG_RESULT([$enable_dashboard_support])
 302
 303 # check whether to enable 3D transforms support
 304 AC_MSG_CHECKING([whether to enable support for 3D Transforms])
 305 AC_ARG_ENABLE(3D_transforms,
 306               AC_HELP_STRING([--enable-3D-transforms],
 307                              [enable support for 3D transforms [default=no]]),
 308               [],[enable_3D_transforms="no"])
 309 AC_MSG_RESULT([$enable_3D_transforms])
 310
 311 # check whether to enable channel messaging support
 312 AC_MSG_CHECKING([whether to enable HTML5 Channel Messaging support])
 313 AC_ARG_ENABLE(channel_messaging,
 314               AC_HELP_STRING([--enable-channel-messaging],
 315                              [enable HTML5 channel messaging support [default=yes]]),
 316               [],[enable_channel_messaging="yes"])
 317 AC_MSG_RESULT([$enable_channel_messaging])
 318
 319 # check whether to enable JavaScript debugger/profiler support
 320 AC_MSG_CHECKING([whether to enable JavaScript debugger/profiler support])
 321 AC_ARG_ENABLE(javascript_debugger,
 322               AC_HELP_STRING([--enable-javascript-debugger],
 323                              [enable JavaScript debugger/profiler support [default=yes]]),
 324               [],[enable_javascript_debugger="yes"])
 325 AC_MSG_RESULT([$enable_javascript_debugger])
 326
 327 # check whether to enable HTML5 Offline Web Applications support
 328 AC_MSG_CHECKING([whether to enable HTML5 offline web applications support])
 329 AC_ARG_ENABLE(offline_web_applications,
 330               AC_HELP_STRING([--enable-offline-web-applications],
 331                              [enable HTML5 offline web applications support [default=yes]]),
 332               [],[enable_offline_web_applications="yes"])
 333 AC_MSG_RESULT([$enable_offline_web_applications])
 334
 335 # check whether to enable HTML5 client-side session and persitent storage support
 336 AC_MSG_CHECKING([whether to enable HTML5 client-side session and persistent storage support])
 337 AC_ARG_ENABLE(dom_storage,
 338               AC_HELP_STRING([--enable-dom-storage],
 339                              [enable HTML5 client-side session and persistent storage support [default=yes]]),
 340               [],[enable_dom_storage="yes"])
 341 AC_MSG_RESULT([$enable_dom_storage])
 342
 343 # check whether to build with database support
 344 AC_MSG_CHECKING([whether to enable HTML5 client-side database storage support])
 345 AC_ARG_ENABLE(database,
 346               AC_HELP_STRING([--enable-database],
 347                              [enable HTML5 client-side database storage support [default=yes]]),
 348               [],[enable_database="yes"])
 349 AC_MSG_RESULT([$enable_database])
 350
 351 # check whether to build with icon database support
 352 AC_MSG_CHECKING([whether to enable icon database support])
 353 AC_ARG_ENABLE(icon_database,
 354               AC_HELP_STRING([--enable-icon-database],
 355                              [enable icon database [default=yes]]),
 356               [],[enable_icon_database="yes"])
 357 AC_MSG_RESULT([$enable_icon_database])
 358
 359 # check whether to enable HTML5 ruby support
 360 AC_MSG_CHECKING([whether to enable HTML5 ruby support])
 361 AC_ARG_ENABLE(ruby,
 362               AC_HELP_STRING([--enable-ruby],
 363                              [enable HTML5 ruby support [default=yes]]),
 364               [],[enable_ruby="yes"])
 365 AC_MSG_RESULT([$enable_ruby])
 366
 367 # check whether to enable HTML5 audio/video support
 368 AC_MSG_CHECKING([whether to enable HTML5 video support])
 369 AC_ARG_ENABLE(video,
 370               AC_HELP_STRING([--enable-video],
 371                              [enable HTML5 video support [default=yes]]),
 372               [],[enable_video="yes"])
 373 AC_MSG_RESULT([$enable_video])
 374
 375 # check whether to enable XPath support
 376 AC_MSG_CHECKING([whether to enable XPath support])
 377 AC_ARG_ENABLE(xpath,
 378               AC_HELP_STRING([--enable-xpath],
 379                              [enable support for XPath [default=yes]]),
 380               [],[enable_xpath="yes"])
 381 AC_MSG_RESULT([$enable_xpath])
 382
 383 # check whether to enable XSLT support
 384 AC_MSG_CHECKING([whether to enable XSLT support])
 385 AC_ARG_ENABLE(xslt,
 386               AC_HELP_STRING([--enable-xslt],
 387                              [enable support for XSLT [default=yes]]),
 388               [],[enable_xslt="yes"])
 389 AC_MSG_RESULT([$enable_xslt])
 390
 391 # check whether to enable geolocation support
 392 AC_MSG_CHECKING([whether to enable geolocation support])
 393 AC_ARG_ENABLE(geolocation,
 394               AC_HELP_STRING([--enable-geolocation],
 395                              [enable support for geolocation [default=no]]),
 396               [],[enable_geolocation="no"])
 397 AC_MSG_RESULT([$enable_geolocation])
 398
 399 # check whether to enable gnomekeyring support
 400 AC_MSG_CHECKING([whether to enable gnomekeyring support])
 401 AC_ARG_ENABLE(gnomekeyring,
 402               AC_HELP_STRING([--enable-gnomekeyring],
 403                              [enable support for gnomekeyring [default=no]]),
 404               [],[enable_gnomekeyring="no"])
 405 AC_MSG_RESULT([$enable_gnomekeyring])
 406
 407 # check whether to enable SVG support
 408 AC_MSG_CHECKING([whether to enable SVG support])
 409 AC_ARG_ENABLE(svg,
 410               AC_HELP_STRING([--enable-svg],
 411                              [enable support for SVG [default=yes]]),
 412               [],[enable_svg="yes"])
 413 AC_MSG_RESULT([$enable_svg])
 414
 415 # check whether to enable WML support
 416 AC_MSG_CHECKING([whether to enable WML support])
 417 AC_ARG_ENABLE(wml,
 418               AC_HELP_STRING([--enable-wml],
 419                              [enable support for WML [default=no]]),
 420               [],[enable_wml="no"])
 421 AC_MSG_RESULT([$enable_wml])
 422
 423 # check whether to enable SharedWorkers support
 424 AC_MSG_CHECKING([whether to enable SharedWorkers support])
 425 AC_ARG_ENABLE(shared_workers,
 426               AC_HELP_STRING([--enable-shared-workers],
 427                              [enable support for SharedWorkers [default=no]]),
 428               [],[enable_shared_workers="no"])
 429 AC_MSG_RESULT([$enable_shared_workers])
 430
 431 # check whether to enable Web Workers support
 432 AC_MSG_CHECKING([whether to enable Web Workers support])
 433 AC_ARG_ENABLE(workers,
 434               AC_HELP_STRING([--enable-workers],
 435                              [enable support for Web Workers [default=yes]]),
 436               [],[enable_workers="yes"])
 437 AC_MSG_RESULT([$enable_workers])
 438
 439 # turn off svg features if --disable-svg is requested
 440 if test "$enable_svg" = "no"; then
 441    enable_svg_animation=no
 442    enable_svg_fonts=no
 443    enable_svg_foreign_object=no
 444    enable_svg_as_image=no
 445    enable_svg_use=no
 446 fi
 447
 448 # check whether to enable support for SVG animation
 449 AC_MSG_CHECKING([whether to enable support for SVG animation])
 450 AC_ARG_ENABLE(svg_animation,
 451               AC_HELP_STRING([--enable-svg-animation],
 452                              [enable support for SVG animation (experimental) [default=yes]]),
 453               [],[enable_svg_animation="yes"])
 454 AC_MSG_RESULT([$enable_svg_animation])
 455
 456 # check whether to enable support for filters
 457 AC_MSG_CHECKING([whether to enable support for filters])
 458 AC_ARG_ENABLE(filters,
 459               AC_HELP_STRING([--enable-filters],
 460                              [enable support for filters (experimental) [default=no]]),
 461               [],[enable_filters="no"])
 462 AC_MSG_RESULT([$enable_filters])
 463
 464 # check whether to enable support for SVG fonts
 465 AC_MSG_CHECKING([whether to enable support for SVG fonts])
 466 AC_ARG_ENABLE(svg_fonts,
 467               AC_HELP_STRING([--enable-svg-fonts],
 468                              [enable support for SVG fonts (experimental) [default=yes]]),
 469               [],[enable_svg_fonts="yes"])
 470 AC_MSG_RESULT([$enable_svg_fonts])
 471
 472 # check whether to enable foreign objects support for SVG
 473 AC_MSG_CHECKING([whether to enable support for SVG foreign objects])
 474 AC_ARG_ENABLE(svg_foreign_object,
 475               AC_HELP_STRING([--enable-svg-foreign-object],
 476                              [enable support for SVG foreign objects (experimental) [default=yes]]),
 477               [],[enable_svg_foreign_object="yes"])
 478 AC_MSG_RESULT([$enable_svg_foreign_object])
 479
 480 # check whether to enable SVG As Image support
 481 AC_MSG_CHECKING([whether to enable SVG as Image support])
 482 AC_ARG_ENABLE(svg_as_image,
 483               AC_HELP_STRING([--enable-svg-as-image],
 484                              [enable SVG as Image support (experimental) [default=yes]]),
 485               [],[enable_svg_as_image="yes"])
 486 AC_MSG_RESULT([$enable_svg_as_image])
 487
 488 # check whether to enable SVG USE element support
 489 AC_MSG_CHECKING([whether to enable support for SVG use element])
 490 AC_ARG_ENABLE(svg_use,
 491               AC_HELP_STRING([--enable-svg-use],
 492                              [enable SVG use element support (experimental) [default=yes]]),
 493               [],[enable_svg_use="yes"])
 494 AC_MSG_RESULT([$enable_svg_use])
 495
 496 # check for SVG features, enabling SVG if necessary
 497 if test "$enable_svg_animation" = "yes" || \
 498    test "$enable_svg_fonts" = "yes" || \
 499    test "$enable_svg_foreign_object" = "yes" || \
 500    test "$enable_svg_as_image" = "yes" || \
 501    test "$enable_svg_use" = "yes"; then
 502    svg_flags=yes
 503    if test "$enable_svg" = "no"; then
 504        AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
 505        enable_svg=yes
 506    fi
 507 fi
 508
 509 # check whether to enable Web Socket support
 510 AC_MSG_CHECKING([whether to enable Web Sockets support])
 511 AC_ARG_ENABLE(web_sockets,
 512               AC_HELP_STRING([--enable-web-sockets],
 513                              [enable support for Web Sockets [default=yes]]),
 514               [],[enable_web_sockets="no"])
 515 AC_MSG_RESULT([$enable_web_sockets])
 516
 517 # check whether to enable code coverage
 518 AC_MSG_CHECKING([whether to enable code coverage support])
 519 AC_ARG_ENABLE(coverage,
 520               AC_HELP_STRING([--enable-coverage],
 521                              [enable code coverage support [default=no]]),
 522               [],[enable_coverage="no"])
 523 AC_MSG_RESULT([$enable_coverage])
 524
 525 # check whether to enable FastMalloc
 526 AC_MSG_CHECKING([whether to enable optimized memory allocator])
 527 AC_ARG_ENABLE(fast_malloc,
 528               AC_HELP_STRING([--enable-fast-malloc],
 529                              [enable optimized memory allocator default=yes, default=no for debug builds]),
 530               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
 531 AC_MSG_RESULT([$enable_fast_malloc])
 532
 533 AC_MSG_CHECKING([whether to enable JIT compilation])
 534 AC_ARG_ENABLE([jit],
 535               AC_HELP_STRING([--enable-jit],
 536                              [Enable JIT compilation default=yes]),
 537               [],[enable_jit="yes"])
 538 if test "$enable_jit" = "yes"; then
 539     case "$host_cpu" in
 540         i*86|x86_64)
 541             AC_DEFINE([ENABLE_JIT], [1], [Define to enable JIT])
 542             AC_DEFINE([ENABLE_YARR], [1], [Define to enable YARR])
 543             AC_DEFINE([ENABLE_YARR_JIT], [1], [Define to enable YARR JIT])
 544             AC_DEFINE([ENABLE_JIT_OPTIMIZE_CALL], [1], [Define to enable optimizing calls])
 545             AC_DEFINE([ENABLE_JIT_OPTIMIZE_PROPERTY_ACCESS], [1], [Define to enable optimized property access])
 546             AC_DEFINE([ENABLE_JIT_OPTIMIZE_ARITHMETIC], [1], [Define to enable optimized arithmetic])
 547             case "$host_cpu" in
 548                 i*86)
 549                     AC_DEFINE([WTF_USE_JIT_STUB_ARGUMENT_VA_LIST], [1], [Use stub va_list])
 550                 ;;
 551                 x86_64)
 552                     AC_DEFINE([WTF_USE_JIT_STUB_ARGUMENT_REGISTER], [1], [Use stub register])
 553                     AC_DEFINE([WTF_USE_ALTERNATE_JSIMMEDIATE], [1], [Use alternate JSImmediate])
 554                 ;;
 555             esac
 556         ;;
 557         *)
 558             enable_jit="no (CPU '$host_cpu' not supported)"
 559         ;;
 560     esac
 561 fi
 562 AC_MSG_RESULT([$enable_jit])
 563
 564 # determine the font backend
 565 AC_MSG_CHECKING([the font backend to use])
 566 AC_ARG_WITH(font_backend,
 567             AC_HELP_STRING([--with-font-backend=@<:@freetype/pango@:>@],
 568                            [Select font backend [default=freetype]]),
 569             [],[with_font_backend="freetype"])
 570
 571 case "$with_font_backend" in
 572      freetype|pango) ;;
 573      *) AC_MSG_ERROR([Invalid font backend: must be freetype or pango.]) ;;
 574 esac
 575 AC_MSG_RESULT([$with_font_backend])
 576
 577 # Add '-g' flag to gcc if it's debug build
 578 if test "$enable_debug" = "yes"; then
 579    CXXFLAGS="$CXXFLAGS -g"
 580    CFLAGS="$CFLAGS -g"
 581 else
 582    AC_DEFINE([NDEBUG], [1], [Define to disable debugging features])
 583 fi
 584
 585 # Add the appropriate 'O' level for optimized builds
 586 if test "$enable_optimizations" = "yes"; then
 587    CXXFLAGS="$CXXFLAGS -O2"
 588    CFLAGS="$CFLAGS -O2"
 589 else
 590    CXXFLAGS="$CXXFLAGS -O0"
 591    CFLAGS="$CFLAGS -O0"
 592 fi
 593
 594 PKG_CHECK_MODULES([LIBSOUP],
 595                   [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
 596 AC_SUBST([LIBSOUP_CFLAGS])
 597 AC_SUBST([LIBSOUP_LIBS])
 598
 599 if test "$enable_gnomekeyring" = "yes"; then
 600    PKG_CHECK_MODULES([GNOMEKEYRING],
 601                      [gnome-keyring-1 >= $GNOME_KEYRING_REQUIRED_VERSION])
 602    AC_SUBST([GNOMEKEYRING_CFLAGS])
 603    AC_SUBST([GNOMEKEYRING_LIBS])
 604 fi
 605
 606 # check if FreeType/FontConfig are available
 607 if test "$with_font_backend" = "freetype"; then
 608    if test "$with_target" = "directfb"; then
 609    PKG_CHECK_MODULES([FREETYPE],
 610                      [fontconfig >= $FONTCONFIG_REQUIRED_VERSION
 611                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
 612    else
 613    PKG_CHECK_MODULES([FREETYPE],
 614                      [cairo-ft
 615                      fontconfig >= $FONTCONFIG_REQUIRED_VERSION
 616                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
 617    fi
 618    AC_SUBST([FREETYPE_CFLAGS])
 619    AC_SUBST([FREETYPE_LIBS])
 620 fi
 621
 622 # check if sqlite 3 is available
 623 if test "$enable_icon_database" = "yes" || \
 624    test "$enable_database" = "yes" || \
 625    test "$enable_offline_web_applications" = "yes" || \
 626    test "$enable_dom_storage" = "yes"; then
 627    PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $SQLITE_REQUIRED_VERSION])
 628    AC_SUBST([SQLITE3_CFLAGS])
 629    AC_SUBST([SQLITE3_LIBS])
 630 fi
 631
 632 # check if libxslt is available
 633 if test "$enable_xslt" = "yes"; then
 634    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
 635    AC_SUBST([LIBXSLT_CFLAGS])
 636    AC_SUBST([LIBXSLT_LIBS])
 637 fi
 638
 639 # check if geoclue is available
 640 if test "$enable_geolocation" = "yes"; then
 641     PKG_CHECK_MODULES([GEOCLUE], [geoclue])
 642     AC_SUBST([GEOCLUE_CFLAGS])
 643     AC_SUBST([GEOCLUE_LIBS])
 644 fi
 645
 646 # check if gstreamer is available
 647 if test "$enable_video" = "yes"; then
 648    PKG_CHECK_MODULES([GSTREAMER],
 649                      [gstreamer-0.10 >= $GSTREAMER_REQUIRED_VERSION
 650                      gstreamer-base-0.10
 651                      gstreamer-plugins-base-0.10
 652                      gstreamer-video-0.10])
 653    AC_SUBST([GSTREAMER_CFLAGS])
 654    AC_SUBST([GSTREAMER_LIBS])
 655 fi
 656
 657 # check for code coverage support
 658 if test "$enable_coverage" = "yes"; then
 659    COVERAGE_CFLAGS="-MD"
 660    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
 661    AC_SUBST([COVERAGE_CFLAGS])
 662    AC_SUBST([COVERAGE_LDFLAGS])
 663 fi
 664
 665 # check for HTML features
 666 if test "$enable_video" = "yes"; then
 667     html_flags=yes
 668 fi
 669
 670 GTK_DOC_CHECK([1.10])
 671
 672 # OS conditionals
 673 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
 674 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
 675 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
 676 AM_CONDITIONAL([OS_GNU],[test "$os_gnu" = "yes"])
 677 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
 678
 679 # target conditionals
 680 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
 681 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
 682 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
 683 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
 684
 685 # Unicode backend conditionals
 686 AM_CONDITIONAL([USE_ICU_UNICODE], [test "$with_unicode_backend" = "icu"])
 687 AM_CONDITIONAL([USE_GLIB_UNICODE], [test "$with_unicode_backend" = "glib"])
 688
 689 # Auth backend conditionals
 690 AM_CONDITIONAL([USE_GNOMEKEYRING], [test "$enable_gnomekeyring" = "yes"])
 691
 692 # Font backend conditionals
 693 AM_CONDITIONAL([USE_FREETYPE], [test "$with_font_backend" = "freetype"])
 694 AM_CONDITIONAL([USE_PANGO], [test "$with_font_backend" = "pango"])
 695
 696 # WebKit feature conditionals
 697 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug" = "yes"])
 698 AM_CONDITIONAL([ENABLE_DASHBOARD_SUPPORT],[test "$enable_dashboard_support" = "yes"])
 699 AM_CONDITIONAL([ENABLE_3D_TRANSFORMS],[test "$enable_3D_transforms" = "yes"])
 700 AM_CONDITIONAL([ENABLE_CHANNEL_MESSAGING],[test "$enable_channel_messaging" = "yes"])
 701 AM_CONDITIONAL([ENABLE_JAVASCRIPT_DEBUGGER],[test "$enable_javascript_debugger" = "yes"])
 702 AM_CONDITIONAL([ENABLE_OFFLINE_WEB_APPLICATIONS],[test "$enable_offline_web_applications" = "yes"])
 703 AM_CONDITIONAL([ENABLE_DOM_STORAGE],[test "$enable_dom_storage" = "yes"])
 704 AM_CONDITIONAL([ENABLE_DATABASE],[test "$enable_database" = "yes"])
 705 AM_CONDITIONAL([ENABLE_ICONDATABASE],[test "$enable_icon_database" = "yes"])
 706 AM_CONDITIONAL([ENABLE_XPATH],[test "$enable_xpath" = "yes"])
 707 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
 708 AM_CONDITIONAL([ENABLE_FILTERS],[test "$enable_filters" = "yes"])
 709 AM_CONDITIONAL([ENABLE_GEOLOCATION], [test "$enable_geolocation" = "yes"])
 710 AM_CONDITIONAL([ENABLE_RUBY],[test "$enable_ruby" = "yes"])
 711 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
 712 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
 713 AM_CONDITIONAL([ENABLE_SVG_ANIMATION],[test "$enable_svg_animation" = "yes"])
 714 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
 715 AM_CONDITIONAL([ENABLE_SVG_FOREIGN_OBJECT],[test "$enable_svg_foreign_object" = "yes"])
 716 AM_CONDITIONAL([ENABLE_SVG_AS_IMAGE],[test "$enable_svg_as_image" = "yes"])
 717 AM_CONDITIONAL([ENABLE_SVG_USE],[test "$enable_svg_use" = "yes"])
 718 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
 719 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
 720 AM_CONDITIONAL([ENABLE_WML],[test "$enable_wml" = "yes"])
 721 AM_CONDITIONAL([ENABLE_WORKERS],[test "$enable_workers" = "yes"])
 722 AM_CONDITIONAL([ENABLE_SHARED_WORKERS],[test "$enable_shared_workers" = "yes"])
 723 AM_CONDITIONAL([SVG_FLAGS],[test "$svg_flags" = "yes"])
 724 AM_CONDITIONAL([HTML_FLAGS],[test "$html_flags" = "yes"])
 725 AM_CONDITIONAL([ENABLE_WEB_SOCKETS],[test "$enable_web_sockets" = "yes"])
 726
 727 AC_CONFIG_FILES([
 728 GNUmakefile
 729 WebKit/gtk/webkit-1.0.pc:WebKit/gtk/webkit.pc.in
 730 WebKit/gtk/webkit/webkitversion.h
 731 WebKit/gtk/docs/GNUmakefile
 732 WebKit/gtk/docs/version.xml
 733 ]
 734 )
 735
 736 AC_OUTPUT
 737
 738 echo "
 739 WebKit was configured with the following options:
 740
 741 Build configuration:
 742  Enable debugging (slow)                                  : $enable_debug
 743  Enable GCC build optimization                            : $enable_optimizations
 744  Code coverage support                                    : $enable_coverage
 745  Unicode backend                                          : $with_unicode_backend
 746  Font backend                                             : $with_font_backend
 747  Optimized memory allocator                               : $enable_fast_malloc
 748 Features:
 749  3D Transforms                                            : $enable_3D_transforms
 750  JIT compilation                                          : $enable_jit
 751  Dashboard support                                        : $enable_dashboard_support
 752  Filters support                                          : $enable_filters
 753  Geolocation support                                      : $enable_geolocation
 754  GNOME Keyring support                                    : $enable_gnomekeyring
 755  JavaScript debugger/profiler support                     : $enable_javascript_debugger
 756  HTML5 offline web applications support                   : $enable_offline_web_applications
 757  HTML5 channel messaging support                          : $enable_channel_messaging
 758  HTML5 client-side session and persistent storage support : $enable_dom_storage
 759  HTML5 client-side database storage support               : $enable_database
 760  HTML5 ruby support                                       : $enable_ruby
 761  HTML5 video element support                              : $enable_video
 762  Icon database support                                    : $enable_icon_database
 763  SharedWorkers support                                    : $enable_shared_workers
 764  SVG support                                              : $enable_svg
 765  SVG animation support                                    : $enable_svg_animation
 766  SVG fonts support                                        : $enable_svg_fonts
 767  SVG foreign object support                               : $enable_svg_foreign_object
 768  SVG as image support                                     : $enable_svg_as_image
 769  SVG use element support                                  : $enable_svg_use
 770  WML support                                              : $enable_wml
 771  Web Sockets support                                      : $enable_web_sockets
 772  Web Workers support                                      : $enable_workers
 773  XPATH support                                            : $enable_xpath
 774  XSLT support                                             : $enable_xslt
 775 GTK+ configuration:
 776  GDK target                                               : $with_target
 777  Hildon UI extensions                                     : $with_hildon
 778 "
 779 if test "$with_unicode_backend" = "glib"; then
 780    echo "     >> WARNING: the glib-based unicode backend is slow and incomplete <<"
 781    echo
 782    echo
 783 fi