configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 2002-2013 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 2.2.0-git)
   6 VERSION_MAJOR=2
   7 VERSION_MINOR=2
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=git
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Weatherwax"
  17 COPYRIGHT_YEARS="1996-2013"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 # Disable with "./configure --disable-silent-rules" or "make V=1"
  31 AM_SILENT_RULES([yes])
  32
  33 dnl Too many people are not aware of maintainer mode:
  34 dnl If you want to use it, you definitely know what you are doing, so
  35 dnl you can specify "--disable-maintainer-mode". But if you want the default
  36 dnl automake behavior, you've likely never heard of maintainer mode, so we
  37 dnl can't expect you to enable it manually.
  38 AS_IF([test "x${enable_maintainer_mode}" != "xno"],
  39     [enable_maintainer_mode="yes"])
  40 AM_MAINTAINER_MODE
  41
  42 dnl
  43 dnl Directories
  44 dnl
  45 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  46 dnl AC_SUBST(vlcincludedir)
  47 vlcdatadir="\${datadir}/\${PKGDIR}"
  48 AC_SUBST(vlcdatadir)
  49 vlclibdir="\${libdir}/\${PKGDIR}"
  50 AC_SUBST(vlclibdir)
  51
  52 dnl
  53 dnl Check for tools
  54 dnl
  55 AC_PROG_CC_C99
  56 AC_USE_SYSTEM_EXTENSIONS
  57 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  58 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  59 AC_DEFINE([_REENTRANT],, [Define to expose reentrant functions.])
  60 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  61 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  62 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  63
  64 AM_PROG_CC_C_O
  65 AC_PROG_CXX
  66 AC_PROG_CPP
  67 AC_PROG_OBJC
  68 _AM_DEPENDENCIES([OBJC])
  69 AC_PROG_EGREP
  70 AC_PROG_MAKE_SET
  71 AC_PROG_INSTALL
  72 AM_PROG_AS
  73
  74 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  75 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  76
  77 dnl Check for compiler properties
  78 AC_C_CONST
  79 AC_C_INLINE
  80 AC_C_RESTRICT
  81
  82 dnl Extend the --help string at the current spot.
  83 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  84
  85 dnl Allow binary package maintainer to pass a custom string to avoid
  86 dnl cache problem
  87 AC_ARG_WITH(binary-version,
  88     AS_HELP_STRING([--with-binary-version=STRING],
  89          [To avoid plugins cache problem between binary version]),[],[])
  90 AS_IF([test -n "${with_binary_version}"],[
  91     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  92          [Binary specific version])
  93 ])
  94
  95 dnl
  96 dnl  Check the operating system
  97 dnl
  98 HAVE_WIN64="0"
  99 case "${host_os}" in
 100   "")
 101     SYS=unknown
 102     ;;
 103   linux*)
 104     SYS=linux
 105     ;;
 106   bsdi*)
 107     SYS=bsdi
 108     CFLAGS="${CFLAGS} -pthread"
 109     ;;
 110   freebsd*)
 111     SYS=freebsd
 112     CFLAGS="${CFLAGS} -pthread"
 113     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 114     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 115     ;;
 116   openbsd*)
 117     SYS=openbsd
 118     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 119     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 120     ;;
 121   netbsd*)
 122     SYS=netbsd
 123     ;;
 124   dragonfly*)
 125     SYS=dragonfly
 126     ;;
 127   darwin*)
 128
 129     dnl Force gcc "-arch" flag
 130     ARCH_flag=""
 131     case "${host}" in
 132       i?86*)
 133         ARCH_flag="-arch i386"
 134       ;;
 135       ppc64*)
 136         ARCH_flag="-arch ppc64"
 137       ;;
 138       ppc*)
 139         ARCH_flag="-arch ppc"
 140       ;;
 141       x86_64*)
 142         ARCH_flag="-arch x86_64"
 143       ;;
 144       arm*)
 145         ac_cv_c_bigendian="no"
 146         ac_cv_c_attribute_packed="no"
 147       ;;
 148     esac
 149
 150     SYS=darwin
 151     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 152     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 153     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 154     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu99 ${ARCH_flag}"
 155     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 156     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 157     VLC_ADD_LIBS([avcodec access_avio swscale postproc i420_rgb_mmx x262 x264 x26410b],[-Wl,-read_only_relocs,suppress])
 158     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,SystemConfiguration])
 159
 160     dnl Allow binaries created on Lion to run on earlier releases
 161     AC_EGREP_CPP(yes,
 162            [#import <Cocoa/Cocoa.h>
 163             #ifdef MAC_OS_X_VERSION_10_7
 164             yes
 165             #endif],
 166             [AC_MSG_RESULT([yes])
 167             AC_LIBOBJ([getdelim])
 168             AC_LIBOBJ([strndup])
 169             AC_LIBOBJ([strnlen])],)
 170
 171     dnl
 172     dnl  Handle Mac OS X SDK flags
 173     dnl
 174     AC_ARG_WITH(macosx-sdk,
 175       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 176         [compile using the SDK in DIR])])
 177     if test "${with_macosx_sdk}" != "" ; then
 178         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 179         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 180         CC="${CC} -isysroot ${with_macosx_sdk}"
 181         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 182         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 183         LD="${LD} -syslibroot ${with_macosx_sdk}"
 184     fi
 185     AC_ARG_WITH(macosx-version-min,
 186       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 187         [compile for Mac OS X VERSION and above])])
 188     if test "${with_macosx_version_min}" != "" ; then
 189         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 190         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 191         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 192         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 193         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 194     fi
 195     ;;
 196   *mingw32* | *cygwin* | *wince* | *mingwce*)
 197     AC_CHECK_TOOL(WINDRES, windres, :)
 198     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 199     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
 200     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
 201     AH_TOP([#endif])
 202     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 203     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 204     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 205
 206     case "${host_os}" in
 207       *mingw32*)
 208         SYS=mingw32
 209         ;;
 210       *cygwin*)
 211         dnl Check if we are using the mno-cygwin mode in which case we are
 212         dnl actually dealing with a mingw32 compiler.
 213         AC_EGREP_CPP(yes,
 214             [#ifdef _WIN32
 215              yes
 216              #endif],
 217             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 218         ;;
 219     esac
 220
 221     if test "${SYS}" = "mingw32"; then
 222         # DEP, ASLR, NO SEH
 223         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 224
 225         VLC_ADD_LIBS([libvlccore],[-lwinmm])
 226         VLC_ADD_LDFLAGS([vlc],[-mwindows])
 227         VLC_ADD_LIBS([win32text],[-lgdi32])
 228         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 229         ac_default_prefix="`pwd`/_win32"
 230         DESTDIR="`pwd`/_win32/"
 231
 232         dnl
 233         dnl NSIS/MSI Installer prefix and WIN64
 234         dnl
 235         case "${host}" in
 236             amd64*|x86_64*)
 237                 HAVE_WIN64="1"
 238                 WINDOWS_ARCH="x64"
 239                 PROGRAMFILES="PROGRAMFILES64"
 240             ;;
 241             *)
 242                 WINDOWS_ARCH="x86"
 243                 PROGRAMFILES="PROGRAMFILES"
 244             ;;
 245         esac
 246         AC_SUBST(WINDOWS_ARCH)
 247         AC_SUBST(PROGRAMFILES)
 248
 249     fi
 250     ;;
 251   *nto*)
 252     SYS=nto
 253     ;;
 254   solaris*)
 255     SYS=solaris
 256     ;;
 257   hpux*)
 258     SYS=hpux
 259     ;;
 260   symbian*)
 261     SYS=symbian
 262     ;;
 263   *os2*)
 264     SYS=os2
 265     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild"
 266     ;;
 267   *)
 268     SYS="${host_os}"
 269     ;;
 270 esac
 271 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 272 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 273 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 274 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 275 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1")
 276 AM_CONDITIONAL(HAVE_SYMBIAN, test "${SYS}" = "symbian")
 277
 278 dnl
 279 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 280 dnl for program foo on win32
 281 case "${build_os}" in
 282     cygwin|msys)
 283         ac_executable_extensions=".exe"
 284     ;;
 285     *)
 286     ;;
 287 esac
 288
 289 dnl Android is linux, but a bit different
 290 AS_IF([test "$SYS" = linux],[
 291     AC_MSG_CHECKING([for an Android system])
 292     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 293         [[#ifndef __ANDROID__
 294          # error Not Android
 295          #endif
 296         ]],[[;]])
 297     ],[
 298       HAVE_ANDROID="1"
 299       AC_MSG_RESULT([yes])
 300     ],[
 301       AC_MSG_RESULT([no])
 302     ])
 303 ])
 304 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 305
 306
 307 dnl
 308 dnl  Check for the contrib directory
 309 dnl
 310 AC_ARG_WITH(contrib,
 311   [AS_HELP_STRING([--with-contrib[=DIR]],
 312     [search for 3rd party libraries in DIR/include and DIR/lib])
 313 ])
 314 AC_MSG_CHECKING([for 3rd party libraries path])
 315 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 316   CONTRIB_DIR="${srcdir}/contrib/${host}"
 317   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 318     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 319     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 320     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 321       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 322       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
 323       AS_IF([test ! -d "${CONTRIB_DIR}"], [
 324         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 325         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
 326         AS_IF([test ! -d "${CONTRIB_DIR}"], [
 327           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 328           CONTRIB_DIR=""
 329           AC_MSG_RESULT([not found])
 330         ])
 331       ])
 332     ])
 333   ])
 334 ], [
 335   AS_IF([test "${with_contrib}" != "no"], [
 336     CONTRIB_DIR="${with_contrib}"
 337   ], [
 338     CONTRIB_DIR=""
 339     AC_MSG_RESULT([disabled])
 340   ])
 341 ])
 342 AS_IF([test -n "${CONTRIB_DIR}"], [
 343   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 344     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 345   ], [
 346     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 347     CONTRIB_DIR=""
 348     AC_MSG_RESULT([not usable])
 349   ])
 350
 351 ])
 352 AS_IF([test -n "${CONTRIB_DIR}"], [
 353   AC_MSG_RESULT([${CONTRIB_DIR}])
 354   export PATH=${CONTRIB_DIR}/bin:$PATH
 355   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 356   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 357   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 358   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
 359   AS_IF([test "$build" = "$host" -o "$PKG_CONFIG_LIBDIR"], [
 360     export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 361   ], [
 362     export PKG_CONFIG_LIBDIR="${CONTRIB_DIR}/lib/pkgconfig"
 363   ])
 364   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 365
 366   AS_IF([test "${SYS}" = "darwin"], [
 367     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 368     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 369   ])
 370 ], [
 371   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 372     AC_MSG_ERROR([Third party libraries not found!])
 373   ])
 374 ])
 375 AC_SUBST(CONTRIB_DIR)
 376
 377 dnl
 378 dnl  Libtool
 379 dnl  It's very bad, but our former custom system was worst
 380 dnl  -- Courmisch
 381 dnl
 382
 383 dnl override platform specific check for dependent libraries
 384 dnl otherwise libtool linking of shared libraries will
 385 dnl fail on anything other than pass_all.
 386 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 387     [lt_cv_deplibs_check_method=pass_all])
 388
 389 LT_INIT([dlopen win32-dll shared disable-static])
 390 LT_LANG([C++])
 391 LT_LANG([Windows Resource])
 392
 393 DOLT
 394
 395 lt_cv_deplibs_check_method=pass_all
 396
 397 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 398   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 399 ])
 400
 401 dnl
 402 dnl Gettext stuff
 403 dnl
 404 AM_GNU_GETTEXT_VERSION([0.18.3])
 405 AM_GNU_GETTEXT([external], [need-ngettext])
 406
 407 dnl
 408 dnl Iconv stuff
 409 dnl
 410 AM_ICONV
 411
 412 dnl
 413 dnl checks for mingw
 414 AS_IF([test "${SYS}" = "mingw32"], [
 415 dnl Check for broken versions of mingw-runtime compatability library
 416     AC_MSG_CHECKING(for broken mingw-runtime)
 417     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 418 #include <_mingw.h>
 419 #if defined(__MINGW64_VERSION_MAJOR)
 420 # if __MINGW64_VERSION_MAJOR < 3
 421 #  error Attempting to use mingw-runtime with broken vsnprintf and direct2d support
 422 # endif
 423 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
 424 # error Attempting to use mingw-runtime with broken vsnprintf support
 425 #endif
 426     ])], [
 427         AC_MSG_RESULT([ok])
 428     ], [
 429         AC_MSG_RESULT([present])
 430         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
 431     ])
 432     dnl force use of mingw provided c99 *printf over msvcrt
 433     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 434
 435 dnl Check for the need to include the mingwex lib for mingw32
 436     VLC_SAVE_FLAGS
 437     AC_CHECK_LIB(mingwex,opendir,
 438         AC_CHECK_LIB(mingw32,opendir,,
 439             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 440     )
 441     VLC_RESTORE_FLAGS
 442
 443 dnl Check for fnative-struct or mms-bitfields support for mingw32
 444     VLC_SAVE_FLAGS
 445     CFLAGS="${CFLAGS} -mms-bitfields"
 446     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
 447     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 448         [ac_cv_c_mms_bitfields],
 449         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 450     if test "${ac_cv_c_mms_bitfields}" = "no"; then
 451         VLC_RESTORE_FLAGS
 452         CFLAGS="${CFLAGS} -fnative-struct"
 453         CXXFLAGS="${CXXFLAGS} -fnative-struct"
 454         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 455             [ac_cv_c_fnative_struct],
 456             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 457         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
 458     fi
 459 ])
 460
 461 AC_ARG_ENABLE(winstore_app,
 462      AS_HELP_STRING([--enable-winstore-app],
 463                     [Build targetted for Windows Store apps (default disabled)]))
 464
 465 vlc_winstore_app=0
 466 AS_IF([test "${SYS}" = "mingw32" -a "${enable_winstore_app}" = "yes"], [
 467     vlc_winstore_app=1
 468     VLC_ADD_LIBS([libvlccore], [-lole32 -lruntimeobject])
 469     ])
 470 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 471
 472
 473 dnl
 474 dnl Buggy glibc prevention. Purposedly not cached.
 475 dnl See sourceware.org bugs 5058 and 5443.
 476 dnl Ubuntu alone has 20 bug numbers for this...
 477 dnl
 478 AC_MSG_CHECKING(for buggy GNU/libc versions)
 479 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 480 #include <limits.h>
 481 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 482   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 483 # error GNU/libc with dcgettext killer bug!
 484 #endif
 485 ])], [
 486   AC_MSG_RESULT([not present])
 487 ], [
 488   AC_MSG_RESULT([found])
 489   AS_IF([test "x${enable_nls}" != "xno"], [
 490     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 491 work-around for this. Check with your distribution vendor on how to update the
 492 glibc run-time. Alternatively, build with --disable-nls.])
 493   ])
 494 ])
 495
 496 dnl Plugin compilation stuff
 497
 498 VLC_LIBRARY_SUFFIX
 499
 500 dnl Check for system libs needed
 501 need_libc=false
 502
 503 dnl Check for usual libc functions
 504 AC_CHECK_DECLS([nanosleep],,,[#include <time.h>])
 505 AC_CHECK_FUNCS([daemon fcntl fstatvfs fork getenv getpwuid_r isatty lstat memalign mmap openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime uselocale])
 506 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir flockfile fsync getdelim getpid gmtime_r lldiv localtime_r nrand48 poll posix_memalign rewind setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strsep strtof strtok_r strtoll swab tdestroy strverscmp])
 507 AC_CHECK_FUNCS(fdatasync,,
 508   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 509 ])
 510
 511 dnl mingw64 implements those as static inline, not functions with C linkage
 512 AC_LINK_IFELSE([
 513     AC_LANG_PROGRAM([#include <stdio.h>], [
 514         char *c;
 515         if (asprintf(&c, "%s %d", "string", 1) == -1)
 516             c = NULL;
 517     ])],[AC_DEFINE([HAVE_ASPRINTF],[1],[Define to 1 if you have asprintf function])],[AC_LIBOBJ([asprintf])])
 518 AC_LINK_IFELSE([
 519     AC_LANG_PROGRAM([#include <stdio.h>
 520                      #include <stdarg.h>], [
 521         char *c;
 522         va_list ap;
 523         if (vasprintf(&c, "%s %d", ap) == -1)
 524             c = NULL;
 525     ])],[AC_DEFINE([HAVE_VASPRINTF],[1],[Define to 1 if you have asprintf function])],[AC_LIBOBJ([vasprintf])])
 526
 527 dnl C11 static_assert()
 528 AC_MSG_CHECKING([for static_assert in assert.h])
 529 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 530 static_assert(1, "The impossible happened.");
 531 ])], [
 532   AC_MSG_RESULT([yes])
 533   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 534 ], [
 535   AC_MSG_RESULT([no])
 536 ])
 537
 538 # Windows CE does not have strcoll()
 539 AC_FUNC_STRCOLL
 540
 541 dnl Check for non-standard system calls
 542 case "$SYS" in
 543   "linux")
 544     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity])
 545     ;;
 546   "mingw32")
 547     AC_CHECK_FUNCS([_lock_file])
 548     ;;
 549 esac
 550
 551 AH_BOTTOM([#include <vlc_fixups.h>])
 552
 553 dnl Check for struct pollfd
 554 AC_CHECK_TYPES([struct pollfd],,,
 555 [#include <sys/types.h>
 556 #if HAVE_POLL
 557 # include <poll.h>
 558 #elif defined (_WIN32)
 559 # include <winsock2.h>
 560 #endif
 561 ])
 562
 563 dnl Checks for socket stuff
 564 VLC_SAVE_FLAGS
 565 SOCKET_LIBS=""
 566 AC_SEARCH_LIBS(connect, [socket], [
 567   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 568     SOCKET_LIBS="$ac_cv_search_connect"
 569   ])
 570 ], [
 571   AS_IF([test "${SYS}" = "mingw32"], [
 572     SOCKET_LIBS="-lws2_32"
 573   ])
 574 ])
 575
 576 AC_SEARCH_LIBS([getaddrinfo], [nsl], [
 577  AS_IF([test "$ac_cv_search_getaddrinfo" != "none required"], [
 578     SOCKET_LIBS="$ac_cv_search_getaddrinfo $SOCKET_LIBS"
 579   ])
 580 ],, [${SOCKET_LIBS}])
 581
 582 LIBS="${LIBS} ${SOCKET_LIBS}"
 583 AC_LINK_IFELSE([
 584     AC_LANG_PROGRAM([#ifdef _WIN32
 585         # if _WIN32_WINNT < 0x600
 586         #  error Needs vista+
 587         # endif
 588         #include <ws2tcpip.h>
 589         #else
 590         #include <sys/socket.h>
 591         #include <arpa/inet.h>
 592         #endif], [
 593         char dst[[sizeof(struct in_addr)]];
 594         inet_pton(AF_INET, "127.0.0.1", dst);
 595     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 596 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
 597 VLC_RESTORE_FLAGS
 598
 599 AS_IF([test -n "$SOCKET_LIBS"], [
 600   VLC_ADD_LIBS([access_rtmp access_output_shout sap stream_out_standard stream_out_rtp stream_out_raop vod_rtsp oldrc netsync gnutls ts remoteosd audiobargraph_a],[${SOCKET_LIBS}])
 601 ])
 602 AC_SUBST(SOCKET_LIBS)
 603
 604 dnl Check for socklen_t
 605 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 606 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 607 ac_cv_type_socklen_t,
 608 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 609 [#include <sys/types.h>
 610 #ifdef _WIN32
 611 # include <winsock2.h>
 612 # include <ws2tcpip.h>
 613 #else
 614 # include <sys/socket.h>
 615 #endif]], [[socklen_t len; len = 0;]])],
 616 ac_cv_type_socklen_t=yes,
 617 ac_cv_type_socklen_t=no)])
 618 AS_IF([test "$ac_cv_type_socklen_t" = no],
 619  [AC_DEFINE(socklen_t, int)])
 620
 621 dnl Check for struct sockaddr_storage
 622 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 623 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 624 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 625   [AC_TRY_COMPILE(
 626     [#include <sys/types.h>
 627      #if defined( _WIN32 )
 628      # include <winsock2.h>
 629      #else
 630      # include <sys/socket.h>
 631      #endif], [struct sockaddr_storage addr;],
 632      ac_cv_struct_sockaddr_storage=yes,
 633      ac_cv_struct_sockaddr_storage=no)])
 634 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 635   AC_DEFINE(sockaddr_storage, sockaddr)
 636   AC_DEFINE(ss_family, sa_family)
 637 ])
 638
 639 dnl FreeBSD has a gnugetopt library for this:
 640 GNUGETOPT_LIBS=""
 641 AC_CHECK_FUNC(getopt_long,, [
 642   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 643     GNUGETOPT_LIBS="-lgnugetopt"
 644   ])
 645 ])
 646 AC_SUBST(GNUGETOPT_LIBS)
 647
 648 AC_CHECK_LIB(m,cos,[
 649   VLC_ADD_LIBS([adjust wave ripple psychedelic gradient a52tofloat32 dtstofloat32 x264 goom noise grain scene chorus_flanger freetype swscale postproc equalizer spatializer param_eq samplerate freetype mpc qt4 compressor headphone_channel_mixer normvol audiobargraph_a audiobargraph_v mono colorthres extract ball hotkeys mosaic gaussianblur x262 x26410b hqdn3d anaglyph oldrc ncurses oldmovie glspectrum],[-lm])
 650   LIBM="-lm"
 651 ], [
 652   LIBM=""
 653 ])
 654 AC_SUBST(LIBM)
 655
 656 AC_CHECK_LIB(m,lrintf, [
 657   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 658   VLC_ADD_LIBS([skins2],[-lm])
 659 ])
 660
 661 dnl Check for dynamic plugins
 662 LIBDL=""
 663 have_dynamic_objects="no"
 664 VLC_SAVE_FLAGS
 665 AC_SEARCH_LIBS(dlopen, [dl svld], [
 666   AS_IF([test "$ac_cv_search_dlopen" != "none required"], [
 667     LIBDL="$ac_cv_search_dlopen"
 668   ])
 669   have_dynamic_objects="yes"
 670 ])
 671 VLC_RESTORE_FLAGS
 672
 673 # Windows
 674 AS_IF([test "${SYS}" = "mingw32"], [
 675   LIBDL=""
 676   have_dynamic_objects="yes" #assume we can use shared objects
 677 ])
 678
 679 AS_IF([test "${enable_shared}" = "no"], [
 680   have_dynamic_objects=no
 681 ])
 682 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 683
 684 AC_SUBST(LIBDL)
 685
 686 dnl Check for thread library
 687 LIBPTHREAD=""
 688 AS_IF([test "${SYS}" != "mingw32"], [
 689   VLC_SAVE_FLAGS
 690   LIBS=""
 691   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 692     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 693       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 694     ])
 695   ])
 696   VLC_RESTORE_FLAGS
 697
 698   AC_CHECK_LIB(rt, clock_nanosleep, [
 699     VLC_ADD_LIBS([libvlccore],[-lrt])
 700   ], [
 701     AC_CHECK_FUNC(nanosleep,,[
 702       AC_CHECK_LIB(rt,nanosleep, [
 703         VLC_ADD_LIBS([libvlccore],[-lrt])
 704       ], [
 705         AC_CHECK_LIB(posix4,nanosleep, [
 706           VLC_ADD_LIBS([libvlccore],[-lposix4])
 707         ])
 708       ])
 709     ])
 710     dnl HP/UX port
 711     AC_CHECK_LIB(rt,sem_init, [VLC_ADD_LIBS([libvlccore],[-lrt])])
 712   ])
 713 ])
 714 AC_SUBST(LIBPTHREAD)
 715
 716 dnl Check for headers
 717 AC_CHECK_HEADERS([search.h])
 718 AC_CHECK_HEADERS(getopt.h locale.h xlocale.h)
 719 AC_CHECK_HEADERS([sys/time.h sys/ioctl.h])
 720 AC_CHECK_HEADERS([arpa/inet.h netinet/udplite.h sys/eventfd.h])
 721 AC_CHECK_HEADERS([net/if.h], [], [],
 722   [
 723     #include <sys/types.h>
 724     #include <sys/socket.h>
 725   ])
 726 AC_CHECK_HEADERS([sys/mount.h], [], [],
 727   [
 728     #include <sys/param.h>
 729   ])
 730
 731 if test "${SYS}" != "mingw32"; then
 732   AC_CHECK_HEADERS(machine/param.h sys/shm.h)
 733   AC_CHECK_HEADERS([linux/version.h linux/dccp.h scsi/scsi.h linux/magic.h])
 734   AC_CHECK_HEADERS(syslog.h mntent.h)
 735 fi # end "${SYS}" != "mingw32"
 736
 737 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 738 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 739 AC_CHECK_TYPE(ssize_t,, [
 740   AC_DEFINE(ssize_t, int)
 741 ])
 742
 743 dnl Check for threads library
 744 if test "${SYS}" != "mingw32"; then
 745   AC_CHECK_HEADERS(pthread.h)
 746 fi # end "${SYS}" != "mingw32"
 747
 748 dnl It seems that autoconf detects pkg-config only during the first
 749 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 750 dnl it is nested within a conditional block, so it was not working right.
 751 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 752 AC_ARG_VAR(PKG_CONFIG_PATH,
 753        [Paths where to find .pc not at the default location])
 754 PKG_PROG_PKG_CONFIG()
 755
 756 dnl On some OS we need static linking
 757 AS_IF([test -n "${PKG_CONFIG}" ],[
 758     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 759         PKG_CONFIG="${PKG_CONFIG} --static"
 760     ])
 761 ])
 762
 763
 764 dnl
 765 dnl Check for zlib.h and -lz along with system -lminizip if available
 766 dnl
 767 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 768 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 769 if test "${have_zlib}" = "yes"
 770 then
 771   VLC_ADD_LIBS([skins2 sap unzip zip],[-lz])
 772   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 773     AC_CHECK_HEADERS([unzip.h], [
 774       have_minizip=yes
 775       MINIZIP_LIBS="-lminizip -lz"
 776     ], [
 777       VLC_ADD_CPPFLAGS([skins2], [-I\\\$(top_srcdir)/modules/access/zip/unzip])
 778       VLC_ADD_LIBS([skins2], [\\\$(top_builddir)/modules/libunzip.la])
 779       have_minizip=no
 780     ])
 781   ])
 782   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
 783   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
 784 fi
 785 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 786
 787
 788 dnl
 789 dnl Domain name i18n support via GNU libidn
 790 dnl
 791 PKG_CHECK_MODULES([IDN], [libidn], [
 792   have_libidn="yes"
 793   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 794 ], [
 795   have_libidn="no"
 796 ])
 797
 798
 799 dnl Check for dbus
 800 AC_ARG_ENABLE(dbus,
 801   [AS_HELP_STRING([--enable-dbus],
 802     [compile D-Bus message bus support (default enabled)])])
 803 have_dbus="no"
 804 AS_IF([test "${enable_dbus}" != "no"], [
 805   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 806     have_dbus="yes"
 807   ], [
 808     AS_IF([test -n "${enable_dbus}"], [
 809       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 810     ], [
 811       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 812     ])
 813   ])
 814 ])
 815 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 816
 817 dnl Check for ntohl, etc.
 818 VLC_SAVE_FLAGS
 819 CFLAGS="${CFLAGS} -Wall -Werror"
 820 AC_CACHE_CHECK([for ntohl in sys/param.h],
 821     [ac_cv_c_ntohl_sys_param_h],
 822     [     AC_TRY_COMPILE([#include <sys/param.h>],
 823         [int meuh; ntohl(meuh);],
 824         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
 825 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
 826     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
 827 fi
 828 VLC_RESTORE_FLAGS
 829
 830 EXTEND_HELP_STRING([Optimization options:])
 831 dnl
 832 dnl  Compiler warnings
 833 dnl
 834
 835 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration])
 836 RDC_PROG_CC_FLAGS([-pipe])
 837 AC_LANG_PUSH([C++])
 838 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var])
 839 AC_LANG_POP([C++])
 840
 841 dnl
 842 dnl  Debugging mode
 843 dnl
 844 AC_ARG_ENABLE(debug,
 845   [AS_HELP_STRING([--enable-debug],
 846     [build with run-time assertions (default disabled)])],,
 847   [enable_debug="no"])
 848 AH_TEMPLATE(NDEBUG,
 849             [Define to 1 if debug code should NOT be compiled])
 850 AS_IF([test "${enable_debug}" != "no"], [
 851   AC_CHECK_HEADERS([valgrind/valgrind.h])
 852 ], [
 853   AC_DEFINE(NDEBUG)
 854 ])
 855
 856 dnl
 857 dnl  Profiling
 858 dnl
 859 AC_ARG_ENABLE(gprof,
 860   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 861   [enable_gprof="no"])
 862 AS_IF([test "${enable_gprof}" != "no"], [
 863   CFLAGS="${CFLAGS} -pg"
 864   CXXFLAGS="${CXXFLAGS} -pg"
 865   OBJCFLAGS="${OBJCFLAGS} -pg"
 866   LDFLAGS="${LDFLAGS} -pg"
 867 ])
 868
 869 AC_ARG_ENABLE(cprof,
 870   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 871   [enable_cprof="no"])
 872 AS_IF([test "${enable_gprof}" != "no"], [
 873   CFLAGS="${CFLAGS} -finstrument-functions"
 874   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 875   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 876   LDFLAGS="${LDFLAGS} -finstrument-functions"
 877 ])
 878
 879 dnl
 880 dnl  Test coverage
 881 dnl
 882 AC_ARG_ENABLE(coverage,
 883   [AS_HELP_STRING([--enable-coverage],
 884     [build for test coverage (default disabled)])],,
 885   [enable_coverage="no"])
 886 AS_IF([test "${enable_coverage}" != "no"], [
 887   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 888   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 889   LDFLAGS="-lgcov ${LDFLAGS}"
 890 ])
 891
 892 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
 893   VLC_SAVE_FLAGS
 894   CFLAGS="${CFLAGS} -fvisibility=hidden"
 895   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
 896   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
 897   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
 898                  [ac_cv_c_visibility_hidden], [
 899     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 900       ac_cv_c_visibility_hidden=yes
 901     ], [
 902       ac_cv_c_visibility_hidden=no
 903     ])
 904   ])
 905   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
 906 ])
 907
 908
 909 dnl
 910 dnl  Enable/disable optimizations
 911 dnl
 912 AC_ARG_ENABLE(optimizations,
 913   [AS_HELP_STRING([--disable-optimizations],
 914     [disable compiler optimizations (default enabled)])],,
 915   [enable_optimizations="yes"])
 916
 917 dnl Check for various optimization flags
 918 AS_IF([test "${enable_optimizations}" != "no"], [
 919
 920   dnl -O4 and -O3 only in production builds
 921   AS_IF([test "{enable_debug}" = "no"], [
 922     VLC_SAVE_FLAGS
 923     CFLAGS="${CFLAGS} -O4"
 924     CXXFLAGS="${CXXFLAGS} -O4"
 925     OBJCFLAGS="${OBJCFLAGS} -O4"
 926     AC_CACHE_CHECK([if $CC accepts -O4], [ac_cv_c_o4], [
 927       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 928         ac_cv_c_o4=yes
 929       ], [
 930         ac_cv_c_o4=no
 931       ])
 932     ])
 933     AS_IF([test "${ac_cv_c_o4}" = "no"], [
 934       VLC_RESTORE_FLAGS
 935       CFLAGS="${CFLAGS} -O3"
 936       CXXFLAGS="${CXXFLAGS} -O3"
 937       OBJCFLAGS="${OBJCFLAGS} -O3"
 938       AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
 939         AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 940           ac_cv_c_o3=yes
 941         ], [
 942           ac_cv_c_o3=no
 943         ])
 944       ])
 945       AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
 946     ])
 947   ])
 948
 949   dnl Check for -ffast-math
 950   VLC_SAVE_FLAGS
 951   CFLAGS="${CFLAGS} -ffast-math"
 952   CXXFLAGS="${CXXFLAGS} -ffast-math"
 953   OBJCFLAGS="${OBJCFLAGS} -ffast-math"
 954   AC_CACHE_CHECK([if $CC accepts -ffast-math], [ac_cv_c_fast_math], [
 955     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 956       ac_cv_c_fast_math=yes
 957     ], [
 958       ac_cv_c_fast_math=no
 959     ])
 960   ])
 961   AS_IF([test "${ac_cv_c_fast_math}" = "no"], [VLC_RESTORE_FLAGS])
 962   AH_BOTTOM([
 963 #ifndef __FAST_MATH__
 964 # pragma STDC FENV_ACCESS OFF
 965 # pragma STDC FP_CONTRACT ON
 966 #endif
 967 ])
 968
 969   dnl Check for -funroll-loops
 970   VLC_SAVE_FLAGS
 971   CFLAGS="${CFLAGS} -funroll-loops"
 972   CXXFLAGS="${CXXFLAGS} -funroll-loops"
 973   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
 974   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
 975     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 976       ac_cv_c_unroll_loops=yes
 977     ], [
 978       ac_cv_c_unroll_loops=no
 979     ])
 980   ])
 981   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
 982
 983   AS_IF([test "$enable_debug" = "no"], [
 984     dnl Check for -fomit-frame-pointer
 985     VLC_SAVE_FLAGS
 986     CFLAGS="${CFLAGS} -fomit-frame-pointer"
 987     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
 988     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
 989     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
 990       [ac_cv_c_omit_frame_pointer], [
 991       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 992         ac_cv_c_omit_frame_pointer=yes
 993       ], [
 994         ac_cv_c_omit_frame_pointer=no
 995       ])
 996     ])
 997     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
 998   ])
 999 ])
1000
1001 VLC_SAVE_FLAGS
1002 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1003 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1004   AC_TRY_LINK([],, [
1005     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1006   ], [
1007     ac_cv_ld_bsymbolic=""
1008   ])
1009 ])
1010 VLC_RESTORE_FLAGS
1011 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1012 AC_SUBST(SYMBOLIC_LDFLAGS)
1013
1014 dnl Checks for __attribute__(aligned()) directive
1015 VLC_SAVE_FLAGS
1016 CFLAGS="${CFLAGS} -Werror"
1017 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1018     [ac_cv_c_attribute_aligned],
1019     [ac_cv_c_attribute_aligned=0
1020     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1021         AC_TRY_COMPILE([],
1022         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1023         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1024     done])
1025 VLC_RESTORE_FLAGS
1026 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1027     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1028         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1029 fi
1030
1031 dnl Check for __attribute__((packed))
1032 AC_CACHE_CHECK([for __attribute__((packed))],
1033   [ac_cv_c_attribute_packed],
1034   [ac_cv_c_attribute_packed=no
1035    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1036                     [ac_cv_c_attribute_packed=yes])])
1037 if test "${ac_cv_c_attribute_packed}" != "no"; then
1038   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1039 fi
1040
1041 dnl
1042 dnl  Check the CPU
1043 dnl
1044 case "${host_cpu}" in
1045   "")
1046     ARCH=unknown
1047     ;;
1048   *)
1049     ARCH="${host_cpu}"
1050     ;;
1051 esac
1052
1053 dnl Check for backtrace() support
1054 AC_CHECK_HEADERS(execinfo.h)
1055 AC_CHECK_FUNCS(backtrace)
1056
1057 dnl
1058 dnl  default modules
1059 dnl
1060 ALIASES="${ALIASES} cvlc rvlc"
1061
1062 dnl
1063 dnl  Accelerated modules
1064 dnl
1065
1066 dnl  Check for fully working MMX intrinsics
1067 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1068 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1069 AC_ARG_ENABLE(mmx,
1070   [AS_HELP_STRING([--disable-mmx],
1071     [disable MMX optimizations (default auto)])],,[
1072   case "${host_cpu}" in
1073     i?86|x86_64)
1074       enable_mmx="yes"
1075       ;;
1076     *)
1077       enable_mmx="no"
1078       ;;
1079   esac
1080 ])
1081 have_mmx="no"
1082 have_mmxext="no"
1083 AS_IF([test "${enable_mmx}" != "no"], [
1084   ARCH="${ARCH} mmx"
1085   VLC_SAVE_FLAGS
1086   CFLAGS="${CFLAGS} -mmmx"
1087   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1088     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1089 [#include <mmintrin.h>
1090 #include <stdint.h>
1091 uint64_t frobzor;]], [
1092 [__m64 a, b, c;
1093 a = b = c = (__m64)frobzor;
1094 a = _mm_slli_pi16(a, 3);
1095 a = _mm_adds_pi16(a, b);
1096 c = _mm_srli_pi16(c, 8);
1097 c = _mm_slli_pi16(c, 3);
1098 b = _mm_adds_pi16(b, c);
1099 a = _mm_unpacklo_pi8(a, b);
1100 frobzor = (uint64_t)a;]])], [
1101       ac_cv_c_mmx_intrinsics=yes
1102     ], [
1103       ac_cv_c_mmx_intrinsics=no
1104     ])
1105   ])
1106   VLC_RESTORE_FLAGS
1107   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1108     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1109   ])
1110
1111   VLC_SAVE_FLAGS
1112   CFLAGS="${CFLAGS} -mmmx"
1113   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1114     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1115 void *p;
1116 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1117 ]])
1118     ], [
1119       ac_cv_mmx_inline=yes
1120     ], [
1121       ac_cv_mmx_inline=no
1122     ])
1123   ])
1124   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1125     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1126     have_mmx="yes"
1127   ])
1128
1129   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1130                  [ac_cv_mmxext_inline], [
1131     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1132 void *p;
1133 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1134 ]])
1135     ], [
1136       ac_cv_mmxext_inline=yes
1137     ], [
1138       ac_cv_mmxext_inline=no
1139     ])
1140   ])
1141   VLC_RESTORE_FLAGS
1142   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1143     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1144     have_mmxext="yes"
1145   ])
1146 ])
1147 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1148 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1149
1150 dnl  Check for fully workin SSE2 intrinsics
1151 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1152 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1153 AC_ARG_ENABLE(sse,
1154   [AS_HELP_STRING([--disable-sse],
1155     [disable SSE (1-4) optimizations (default auto)])],, [
1156   case "${host_cpu}" in
1157     i?86|x86_64)
1158       enable_sse=yes
1159       ;;
1160     *)
1161       enable_sse=no
1162       ;;
1163   esac
1164 ])
1165 have_sse2="no"
1166 AS_IF([test "${enable_sse}" != "no"], [
1167   ARCH="${ARCH} sse sse2"
1168
1169   VLC_SAVE_FLAGS
1170   CFLAGS="${CFLAGS} -msse2"
1171   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1172     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1173 [#include <emmintrin.h>
1174 #include <stdint.h>
1175 uint64_t frobzor;]], [
1176 [__m128i a, b, c;
1177 a = b = c = _mm_set1_epi64((__m64)frobzor);
1178 a = _mm_slli_epi16(a, 3);
1179 a = _mm_adds_epi16(a, b);
1180 c = _mm_srli_epi16(c, 8);
1181 c = _mm_slli_epi16(c, 3);
1182 b = _mm_adds_epi16(b, c);
1183 a = _mm_unpacklo_epi8(a, b);
1184 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1185       ac_cv_c_sse2_intrinsics=yes
1186     ], [
1187       ac_cv_c_sse2_intrinsics=no
1188     ])
1189   ])
1190   VLC_RESTORE_FLAGS
1191   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1192     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1193   ])
1194
1195   VLC_SAVE_FLAGS
1196   CFLAGS="${CFLAGS} -msse"
1197   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1198     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1199 void *p;
1200 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1201 ]])
1202     ], [
1203       ac_cv_sse_inline=yes
1204     ], [
1205       ac_cv_sse_inline=no
1206     ])
1207   ])
1208
1209   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1210     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1211   ])
1212
1213   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1214     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1215 void *p;
1216 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1217 ]])
1218     ], [
1219       ac_cv_sse2_inline=yes
1220     ], [
1221       ac_cv_sse2_inline=no
1222     ])
1223   ])
1224   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1225     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1226     have_sse2="yes"
1227   ])
1228
1229   # SSE3
1230   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1231     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1232 void *p;
1233 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1234 ]])
1235     ], [
1236       ac_cv_sse3_inline=yes
1237     ], [
1238       ac_cv_sse3_inline=no
1239     ])
1240   ])
1241
1242   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1243     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1244   # SSSE3
1245   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1246     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1247 void *p;
1248 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1249 ]])
1250     ], [
1251       ac_cv_ssse3_inline=yes
1252     ], [
1253       ac_cv_ssse3_inline=no
1254     ])
1255   ])
1256
1257   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1258     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1259
1260   # SSE4.1
1261   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1262                  [ac_cv_sse4_1_inline], [
1263     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1264 void *p;
1265 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1266 ]])
1267     ], [
1268       ac_cv_sse4_1_inline=yes
1269     ], [
1270       ac_cv_sse4_1_inline=no
1271     ])
1272   ])
1273
1274   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1275     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1276
1277   # SSE4.2
1278   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1279                  [ac_cv_sse4_2_inline], [
1280     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1281 void *p;
1282 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1283 ]])
1284     ], [
1285       ac_cv_sse4_2_inline=yes
1286     ], [
1287       ac_cv_sse4_2_inline=no
1288     ])
1289   ])
1290
1291   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1292     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1293
1294   # SSE4A
1295   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1296     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1297 void *p;
1298 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1299 ]])
1300     ], [
1301       ac_cv_sse4a_inline=yes
1302     ], [
1303       ac_cv_sse4a_inline=no
1304     ])
1305   ])
1306   VLC_RESTORE_FLAGS
1307   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1308     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1309 ])
1310 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1311
1312 VLC_SAVE_FLAGS
1313 CFLAGS="${CFLAGS} -mmmx"
1314 have_3dnow="no"
1315 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1316   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1317 void *p;
1318 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1319 ]])
1320   ], [
1321     ac_cv_3dnow_inline=yes
1322   ], [
1323     ac_cv_3dnow_inline=no
1324   ])
1325 ])
1326 VLC_RESTORE_FLAGS
1327 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1328   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1329             [Define to 1 if 3D Now! inline assembly is available.])
1330   have_3dnow="yes"
1331 ])
1332 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1333
1334
1335 AC_ARG_ENABLE(neon,
1336   [AS_HELP_STRING([--disable-neon],
1337     [disable NEON optimizations (default auto)])],, [
1338   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1339 ])
1340 AS_IF([test "${enable_neon}" != "no"], [
1341   VLC_SAVE_FLAGS
1342   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1343   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1344     AC_COMPILE_IFELSE([
1345       AC_LANG_PROGRAM(,[[
1346 asm volatile("vqmovun.s64 d0, q1":::"d0");
1347 ]])
1348     ], [
1349       ac_cv_arm_neon="yes"
1350     ], [
1351       ac_cv_arm_neon="no"
1352     ])
1353   ])
1354   VLC_RESTORE_FLAGS
1355 ])
1356 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1357
1358
1359 AC_ARG_ENABLE(altivec,
1360   [AS_HELP_STRING([--disable-altivec],
1361     [disable AltiVec optimizations (default auto)])],, [
1362   AS_CASE("${host_cpu}", [powerpc*],
1363         [enable_altivec=yes], [enable_altivec=no])
1364 ])
1365 have_altivec="no"
1366 ALTIVEC_CFLAGS=""
1367 AS_IF([test "${enable_altivec}" = "yes"], [
1368   ARCH="${ARCH} altivec";
1369   VLC_SAVE_FLAGS
1370   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1371     [ac_cv_altivec_inline],
1372     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1373          ac_cv_altivec_inline="yes",
1374          [CFLAGS="${CFLAGS} -Wa,-m7400"
1375           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1376             [ac_cv_altivec_inline="-Wa,-m7400"],
1377             ac_cv_altivec_inline=no)
1378          ])])
1379   VLC_RESTORE_FLAGS
1380   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1381     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1382               [Define to 1 if AltiVec inline assembly is available.])
1383     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1384       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1385       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1386     ])
1387     have_altivec="yes"
1388   ])
1389
1390 dnl The AltiVec C extensions
1391 dnl
1392 dnl There are several possible cases:
1393 dnl - OS X PPC, gcc 4.x: use -mpim-altivec -force_cpusubtype_ALL, don't
1394 dnl                      need <altivec.h>
1395 dnl - OS X PPC, gcc 3.x: need -faltivec, don't need <altivec.h>
1396 dnl - Linux PPC, gcc 3.4, 4.x: need <altivec.h> which requires -maltivec
1397 dnl - Linux PPC, gcc 3.3: need <altivec.h> and -maltivec -mabi=altivec
1398 dnl - Linux PPC, gcc 3.x: need <altivec.h> and -fvec
1399 dnl - Others: test should fail
1400   VLC_SAVE_FLAGS
1401   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1402   [ac_cv_c_altivec],
1403   [# OS X/PPC test (gcc 4.x)
1404    CFLAGS="${CFLAGS} -mpim-altivec -force_cpusubtype_ALL"
1405    AC_TRY_COMPILE([vector unsigned char foo;],
1406      [vec_ld(0, (unsigned char *)0);],
1407      [ac_cv_c_altivec="-mpim-altivec -force_cpusubtype_ALL"],
1408      [# OS X/PPC test (gcc 3.x)
1409       CFLAGS="${CFLAGS} -faltivec"
1410       AC_TRY_COMPILE([vector unsigned char foo;],
1411         [vec_ld(1 * sizeof(vector float), (unsigned char *)0);],
1412         [ac_cv_c_altivec="-faltivec"],
1413         dnl Below this are the Linux tests
1414         [# Linux/PPC test (gcc 4.x)
1415          CFLAGS="${CFLAGS} -maltivec"
1416          AC_TRY_COMPILE([#include <altivec.h>],
1417            [vec_ld(0, (unsigned char *)0);],
1418            [ac_cv_c_altivec="-maltivec"],
1419            [# Linux/PPC test (gcc 3.3)
1420             CFLAGS="${CFLAGS} -maltivec -mabi=altivec"
1421             AC_TRY_COMPILE([#include <altivec.h>],
1422               [vec_ld(0, (unsigned char *)0);],
1423               [ac_cv_c_altivec=""
1424                ac_cv_c_altivec_abi="-maltivec -mabi=altivec"],
1425               [# Linux/PPC test (gcc 3.3)
1426                CFLAGS="${CFLAGS} -fvec"
1427                AC_TRY_COMPILE([#include <altivec.h>],
1428                  [vec_ld(0, (unsigned char *)0);],
1429                  [ac_cv_c_altivec="-fvec"],
1430                  [ac_cv_c_altivec=no])
1431               ])
1432            ])
1433         ])
1434      ])
1435   ])
1436
1437   VLC_RESTORE_FLAGS
1438   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1439     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1440     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1441     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1442     ALTIVEC_CFLAGS="$ALTIVEC_FLAGS ${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}"
1443     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1444     have_altivec="yes"
1445   ])
1446   AC_CHECK_HEADERS(altivec.h)
1447
1448   VLC_SAVE_FLAGS
1449   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1450   AC_CACHE_CHECK([if linker needs -framework vecLib],
1451     [ac_cv_ld_altivec],
1452     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1453   VLC_RESTORE_FLAGS
1454   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1455     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1456   ])
1457 ])
1458 AC_SUBST(ALTIVEC_CFLAGS)
1459 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1460
1461 dnl
1462 dnl  Memory usage
1463 dnl
1464 AC_ARG_ENABLE(optimize-memory,
1465   [AS_HELP_STRING([--enable-optimize-memory],
1466     [optimize memory usage over performance])])
1467 if test "${enable_optimize_memory}" = "yes"; then
1468   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1469 fi
1470
1471 dnl
1472 dnl Allow running as root (useful for people running on embedded platforms)
1473 dnl
1474 AC_ARG_ENABLE(run-as-root,
1475   [AS_HELP_STRING([--enable-run-as-root],
1476     [allow running VLC as root (default disabled)])])
1477 AS_IF([test "${enable_run_as_root}" = "yes"],[
1478     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1479               [Define to 1 to allow running VLC as root (uid 0).])
1480 ])
1481
1482 dnl
1483 dnl Stream output
1484 dnl
1485 AC_ARG_ENABLE(sout,
1486   [AS_HELP_STRING([--disable-sout],
1487     [disable streaming output (default enabled)])])
1488 AS_IF([test "${enable_sout}" != "no"], [
1489   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1490 ])
1491 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1492
1493 dnl Lua modules
1494 AC_ARG_ENABLE(lua,
1495   [AS_HELP_STRING([--disable-lua],
1496     [disable LUA scripting support (default enabled)])])
1497 if test "${enable_lua}" != "no"
1498 then
1499   PKG_CHECK_MODULES(LUA, lua5.2,
1500     [ have_lua=yes ],
1501     [
1502     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1503
1504     PKG_CHECK_MODULES(LUA, lua5.1,
1505       [ have_lua=yes ],
1506       [
1507       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1508       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1509         [ have_lua=yes ],
1510         [
1511           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1512           have_lua=yes
1513           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1514             [],
1515             [ have_lua=no ] )
1516           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1517             [LUA_LIBS="-llua5.2"],
1518           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1519             [LUA_LIBS="-llua5.1"],
1520             AC_CHECK_LIB( lua51 , luaL_newstate,
1521               [LUA_LIBS="-llua51"],
1522               AC_CHECK_LIB( lua , luaL_newstate,
1523                 [LUA_LIBS="-llua"],
1524                 [ have_lua=no
1525                 ], [-lm])
1526             )))
1527         ])
1528       ])
1529     ])
1530   if test "x${have_lua}" != "xyes" ;  then
1531       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1532   fi
1533   AC_ARG_VAR([LUAC], [LUA byte compiler])
1534   AC_PATH_PROGS(LUAC,[${LUAC} luac], [false])
1535   AS_IF([test "${LUAC}" = "false"], [
1536     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1537   ])
1538   AS_IF([test -d ${CONTRIB_DIR} -a -f ${CONTRIB_DIR}/lib/liblua.a -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|cut -d' ' -f2` != 0404], [
1539     AC_MSG_ERROR([You need 32-bits luac when using using lua from contrib.])
1540   ])
1541 fi
1542 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1543
1544
1545 dnl
1546 dnl HTTP daemon
1547 dnl
1548 AC_ARG_ENABLE(httpd,
1549   [AS_HELP_STRING([--disable-httpd],
1550     [disable the built-in HTTP server (default enabled)])])
1551 if test "${enable_httpd}" != "no"
1552 then
1553   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1554 fi
1555 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1556
1557
1558 dnl
1559 dnl VideoLAN manager
1560 dnl
1561 AC_ARG_ENABLE(vlm,
1562   [AS_HELP_STRING([--disable-vlm],
1563     [disable the stream manager (default enabled)])],,
1564   [enable_vlm="${enable_sout}"])
1565 AS_IF([test "${enable_vlm}" != "no"], [
1566   AS_IF([test "${enable_sout}" = "no"], [
1567     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1568   ])
1569   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1570 ])
1571 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1572
1573
1574 dnl
1575 dnl  Input plugins
1576 dnl
1577
1578 EXTEND_HELP_STRING([Input plugins:])
1579
1580 dnl
1581 dnl  live555 input
1582 dnl
1583 AC_ARG_ENABLE(live555,
1584   [AS_HELP_STRING([--enable-live555],
1585     [enable RTSP input through live555 (default enabled)])])
1586
1587 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1588   PKG_CHECK_MODULES(LIVE555, live555, [
1589     VLC_ADD_PLUGIN([live555])
1590     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1591     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1592   ], [
1593     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1594
1595     AC_LANG_PUSH(C++)
1596     VLC_SAVE_FLAGS
1597
1598     dnl detect include paths
1599     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment.hh"], [
1600       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1601     ], [
1602       AS_IF([test "${SYS}" != "os2"], [
1603         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1604         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1605       ], [
1606         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1607         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1608         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1609       ])
1610     ])
1611
1612     dnl CPP Flags
1613     AS_IF([test "${SYS}" = "solaris"], [
1614       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1615     ])
1616     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1617     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1618
1619     dnl version check
1620     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1621       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1622 [#include <liveMedia_version.hh>
1623 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1624 # error BOOM
1625 #endif]])
1626       ], [
1627         ac_cv_live555="yes"
1628       ], [
1629         ac_cv_live555="no"
1630       ])
1631     ])
1632
1633     AS_IF([test "$ac_cv_live555" = "no"], [
1634       AC_MSG_WARN([live555 is missing or its installed version is too old:
1635 Version 2011.12.23 or later is required to proceed.
1636 You can get an updated one from http://www.live555.com/liveMedia .])
1637       AS_IF([test -n "${enable_live555}"], [
1638         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1639       ])
1640     ], [
1641       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1642       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1643       AS_IF([test "${SYS}" = "mingw32"], [
1644         # add ws2_32 for closesocket, select, recv
1645         other_libs="$other_libs -lws2_32"
1646       ])
1647
1648       dnl We need to check for pic because live555 don't provide shared libs
1649       dnl and we want to build a plugins so we need -fPIC on some arch.
1650       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1651       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1652       AC_CHECK_LIB(liveMedia_pic, main, [
1653         VLC_ADD_PLUGIN([live555])
1654         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1655       ],[
1656         AC_CHECK_LIB(liveMedia, main, [
1657           VLC_ADD_PLUGIN([live555])
1658           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1659         ],[],[${other_libs}])
1660       ],[${other_libs_pic}])
1661     ])
1662     VLC_RESTORE_FLAGS
1663     AC_LANG_POP(C++)
1664   ])
1665 ])
1666
1667 dnl
1668 dnl IIDC and DV FireWire input modules
1669 dnl
1670 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1671 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1672
1673 dnl
1674 dnl - linsys modules: access module check for libzvbi
1675 dnl
1676 AC_ARG_ENABLE(linsys,
1677   [AS_HELP_STRING([--enable-linsys],
1678     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1679 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1680   VLC_ADD_PLUGIN([linsys_hdsdi])
1681   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1682     VLC_ADD_PLUGIN([linsys_sdi])
1683   ], [
1684     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1685   ])
1686 ])
1687
1688 dnl
1689 dnl dvdread module: check for libdvdread
1690 dnl
1691 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread], [dvdread input module], [auto])
1692
1693 dnl
1694 dnl libdvdnav plugin
1695 dnl
1696 AC_ARG_ENABLE(dvdnav,
1697   [AS_HELP_STRING([--disable-dvdnav],
1698     [disable DVD navigation with libdvdnav (default auto)])])
1699 AS_IF([test "${enable_dvdnav}" != "no"], [
1700   PKG_CHECK_MODULES(DVDNAV, dvdnav, [
1701     VLC_ADD_PLUGIN([dvdnav])
1702     AC_CHECK_LIB(dvdnav, dvdnav_get_video_resolution,
1703       AC_DEFINE(HAVE_DVDNAV_GET_VIDEO_RESOLUTION, 1, [Define if you have dvdnav_get_video_resolution.]),
1704         [], [${LIBS_dvdnav}])
1705     AC_CHECK_LIB(dvdnav, dvdnav_describe_title_chapters,
1706       AC_DEFINE(HAVE_DVDNAV_DESCRIBE_TITLE_CHAPTERS, 1, [Define if you have dvdnav_describe_title_chapters.]),
1707         [], [${LIBS_dvdnav}])],
1708       [AC_MSG_WARN([${DVDNAV_PKG_ERRORS}.])])
1709 ])
1710
1711 dnl
1712 dnl  Blu-ray Disc Support with libbluray
1713 dnl
1714 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.2.1], (libbluray for Blu-ray disc support ) )
1715
1716 dnl
1717 dnl  OpenCV wrapper and example filters
1718 dnl
1719 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1720
1721
1722 dnl
1723 dnl  libsmbclient plugin
1724 dnl
1725 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1726 AS_IF([test "${SYS}" = "mingw32"], [ VLC_ADD_PLUGIN([access_smb]) ])
1727
1728
1729 dnl
1730 dnl sftp access support
1731 dnl
1732 PKG_ENABLE_MODULES_VLC([SFTP], [access_sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1733
1734 dnl
1735 dnl  Video4Linux 2
1736 dnl
1737 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1738   [disable Video4Linux version 2 (default auto)])])
1739 have_v4l2="no"
1740 AS_IF([test "$enable_v4l2" != "no"], [
1741   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1742     have_v4l2="yes"
1743   ])
1744 ])
1745 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1746
1747 dnl
1748 dnl special access module for Blackmagic SDI cards
1749 dnl
1750 AC_ARG_ENABLE(decklink,
1751   [AS_HELP_STRING([--disable-decklink],
1752     [disable Blackmagic DeckLink SDI input (default auto)])])
1753 AC_ARG_WITH(decklink_sdk,
1754   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1755     [                        location of Blackmagic DeckLink SDI SDK])])
1756 have_decklink=no
1757 if test "${enable_decklink}" != "no"
1758 then
1759   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1760   then
1761     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1762   fi
1763   VLC_SAVE_FLAGS
1764   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1765   AC_LANG_PUSH(C++)
1766   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1767       have_decklink=yes
1768   ], [
1769       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1770   ])
1771   AC_LANG_POP(C++)
1772   VLC_RESTORE_FLAGS
1773 fi
1774 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1775
1776
1777 dnl
1778 dnl  gnomeVFS access module
1779 dnl
1780 PKG_ENABLE_MODULES_VLC([GNOMEVFS], [gnomevfs], [gnome-vfs-2.0], [GnomeVFS access module], [auto])
1781
1782 dnl
1783 dnl  VCDX modules
1784 dnl
1785 PKG_ENABLE_MODULES_VLC([VCDX], [vcdx], [libcdio >= 0.78.2 libiso9660 >= 0.72 libvcdinfo >= 0.7.22], [navigate VCD with libvcdinfo], [no])
1786
1787 dnl
1788 dnl  Built-in CD-DA and VCD module
1789 dnl
1790 AC_ARG_ENABLE(vcd,
1791   [AS_HELP_STRING([--disable-vcd],
1792     [disable built-in VCD and CD-DA support (default enabled)])])
1793
1794 AC_ARG_ENABLE(libcddb,
1795   [AS_HELP_STRING([--disable-libcddb],
1796     [disable CDDB for Audio CD (default enabled)])])
1797
1798 if test "${enable_vcd}" != "no"
1799 then
1800   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1801   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1802     AC_MSG_RESULT(yes)
1803     VLC_ADD_PLUGIN([vcd cdda])
1804   ],[
1805     AC_MSG_RESULT(no)
1806   ])
1807
1808   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1809   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1810     AC_MSG_RESULT(yes)
1811     VLC_ADD_PLUGIN([vcd cdda])
1812     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1813   ],[
1814     AC_MSG_RESULT(no)
1815   ])
1816
1817   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1818   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1819     AC_MSG_RESULT(yes)
1820     VLC_ADD_PLUGIN([vcd cdda])
1821     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1822   ],[
1823     AC_MSG_RESULT(no)
1824   ])
1825
1826   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1827   then
1828     VLC_ADD_PLUGIN([vcd cdda])
1829   fi
1830
1831   if test "$enable_libcddb" != "no"; then
1832     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1833       HAVE_LIBCDDB=yes
1834       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1835       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1836       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1837       ],:
1838       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1839       HAVE_LIBCDDB=no])
1840   fi
1841 fi
1842
1843 dnl
1844 dnl Linux DVB
1845 dnl
1846 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1847   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1848 [#include <linux/dvb/version.h>
1849 #if (DVB_API_VERSION < 5)
1850 # error Linux DVB API v3.2 and older are not supported.
1851 #endif
1852 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1853 # error Linux DVB API v5.0 is unsupported. Please update.
1854 #endif
1855 ]])], [
1856   ac_cv_linux_dvb_5_1=yes
1857 ], [
1858   ac_cv_linux_dvb_5_1=no
1859 ])])
1860 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1861
1862 dnl
1863 dnl  Screen capture module
1864 dnl
1865 AC_ARG_ENABLE(screen,
1866   [AS_HELP_STRING([--enable-screen],
1867     [disable screen capture (default enabled)])])
1868 if test "${enable_screen}" != "no"; then
1869   if test "${SYS}" = "darwin"; then
1870     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1871       VLC_ADD_PLUGIN([screen])
1872     ])
1873   fi
1874 fi
1875 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1876
1877 dnl
1878 dnl  VNC/RFB access module
1879 dnl
1880 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1881
1882 dnl  RDP/Remote Desktop access module
1883 dnl
1884 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1885
1886 dnl
1887 dnl  Real RTSP plugin
1888 dnl
1889 AC_ARG_ENABLE(realrtsp,
1890   [  --enable-realrtsp       Real RTSP module (default disabled)])
1891 if test "${enable_realrtsp}" = "yes"; then
1892   VLC_ADD_PLUGIN([access_realrtsp])
1893 fi
1894
1895 dnl
1896 dnl MacOS eyeTV
1897 AC_ARG_ENABLE(macosx-eyetv,
1898   [  --enable-macosx-eyetv   Mac OS X EyeTV (TNT Tuner) module (default enabled on Mac OS X)])
1899 if test "x${enable_macosx_eyetv}" != "xno" &&
1900   (test "${SYS}" = "darwin" || test "${enable_macosx_eyetv}" = "yes")
1901 then
1902   VLC_ADD_PLUGIN([access_eyetv])
1903 fi
1904
1905 dnl
1906 dnl QTKit
1907 AC_ARG_ENABLE(macosx-qtkit,
1908   [  --enable-macosx-qtkit Mac OS X qtcapture (video) and qtsound (audio) module (default enabled on Mac OS X)])
1909 if test "x${enable_macosx_qtkit}" != "xno" &&
1910   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1911 then
1912   VLC_ADD_PLUGIN([qtcapture])
1913   VLC_ADD_PLUGIN([qtsound])
1914 fi
1915 AM_CONDITIONAL(HAVE_QTKIT, [test "${SYS}" = "darwin" -a "x${enable_macosx_qtkit}" != "xno"])
1916
1917 dnl
1918 dnl AVFoundation
1919 AC_SUBST(have_avfoundation, ["no"])
1920 AC_ARG_ENABLE(macosx-avfoundation,
1921   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
1922 if test "x${enable_macosx_avfoundation}" != "xno" &&
1923   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
1924 then
1925   SAVED_LIBS="${LIBS}"
1926   LIBS="-framework AVFoundation"
1927   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
1928   LIBS="${SAVED_LIBS}"
1929   if test "${have_avfoundation}" != "no"
1930   then
1931     VLC_ADD_PLUGIN([avcapture])
1932   fi
1933 fi
1934 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
1935
1936 dnl
1937 dnl  Demux plugins
1938 dnl
1939
1940 EXTEND_HELP_STRING([Mux/Demux plugins:])
1941
1942 dnl
1943 dnl  libdvbpsi check for ts mux/demux
1944 dnl
1945 have_dvbpsi="no"
1946 PKG_WITH_MODULES([DVBPSI], [libdvbpsi], [have_dvbpsi="yes"])
1947 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
1948
1949
1950 dnl
1951 dnl  GME demux plugin
1952 dnl
1953 AC_ARG_ENABLE(gme,
1954   [AS_HELP_STRING([--enable-gme],
1955     [use Game Music Emu (default auto)])])
1956 AS_IF([test "${enable_gme}" != "no"], [
1957   AC_CHECK_HEADER([gme/gme.h], [
1958     VLC_ADD_LIBS([gme], [-lgme])
1959     VLC_ADD_PLUGIN([gme])
1960   ], [
1961     AS_IF([test "x${enable_gme}" != "x"], [
1962       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
1963     ])
1964   ])
1965 ])
1966
1967
1968 dnl
1969 dnl  SIDPlay plugin
1970 dnl
1971 AC_ARG_ENABLE(sid,
1972     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
1973 AS_IF([test "${enable_sid}" != "no"], [
1974     PKG_CHECK_MODULES(SID, [libsidplay2], [
1975         AC_LANG_PUSH(C++)
1976         oldCPPFLAGS="$CPPFLAGS"
1977         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
1978         AC_CHECK_HEADER([sidplay/builders/resid.h], [
1979             VLC_ADD_PLUGIN([sid])
1980             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
1981             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
1982         ], [
1983             AS_IF([test -n "${enable_sid}"],
1984                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
1985                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
1986                 )
1987         ])
1988         CPPFLAGS="$oldCPPFLAGS"
1989         AC_LANG_POP(C++)
1990     ], [
1991         AS_IF([test "x${enable_sid}" = "xyes"],
1992             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
1993             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
1994             )
1995     ])
1996 ])
1997
1998
1999 dnl
2000 dnl  ogg demux plugin
2001 dnl
2002 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto])
2003 if test "${enable_sout}" != "no"; then
2004     PKG_ENABLE_MODULES_VLC([MUX_OGG], [], [ogg >= 1.0], [Ogg mux support], [auto])
2005 dnl Check for libshout
2006     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2007 fi
2008
2009 dnl
2010 dnl  matroska demux plugin
2011 dnl
2012 AC_ARG_ENABLE(mkv,
2013   [AS_HELP_STRING([--disable-mkv],
2014     [do not use libmatroska (default auto)])])
2015 if test "${enable_mkv}" != "no" -a "${CXX}" != ""; then
2016   AC_LANG_PUSH(C++)
2017   AC_CHECK_HEADERS(ebml/EbmlVersion.h, [
2018     AC_MSG_CHECKING(for libebml version >= 1.0.0)
2019     AC_EGREP_CPP(yes,
2020       [#include <ebml/EbmlVersion.h>
2021        #ifdef LIBEBML_VERSION
2022        #if LIBEBML_VERSION >= 0x010000
2023        yes
2024        #endif
2025        #endif],
2026       [AC_MSG_RESULT([yes])
2027         AC_CHECK_HEADERS(matroska/KaxVersion.h, [
2028           AC_MSG_CHECKING(for libmatroska version >= 1.0.0)
2029           AC_EGREP_CPP(yes,
2030             [#include <matroska/KaxVersion.h>
2031              #ifdef LIBMATROSKA_VERSION
2032              #if LIBMATROSKA_VERSION >= 0x010000
2033              yes
2034              #endif
2035              #endif],
2036             [AC_MSG_RESULT([yes])
2037               AC_CHECK_HEADERS(matroska/KaxAttachments.h)
2038               AC_CHECK_LIB(ebml_pic, main, [
2039                 VLC_ADD_PLUGIN([mkv])
2040                 VLC_ADD_LIBS([mkv],[-lmatroska -lebml_pic])
2041               ],[
2042                 AC_CHECK_LIB(ebml, main, [
2043                   VLC_ADD_PLUGIN([mkv])
2044                   VLC_ADD_LIBS([mkv],[-lmatroska -lebml])
2045                 ])
2046               ])
2047             ], [
2048               AC_MSG_RESULT([no])
2049               AC_MSG_ERROR([Your libmatroska is too old: you may get a more recent one from http://dl.matroska.org/downloads/libmatroska/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2050           ])
2051         ])
2052       ],
2053       [AC_MSG_RESULT([no])
2054         AC_MSG_ERROR([Your libebml is too old: you may get a more recent one from http://dl.matroska.org/downloads/libebml/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2055     ])
2056   ])
2057   AC_LANG_POP(C++)
2058 fi
2059
2060 dnl
2061 dnl  modplug demux plugin
2062 dnl
2063 AC_ARG_ENABLE(mod,
2064   [AS_HELP_STRING([--disable-mod],
2065     [do not use libmodplug (default auto)])])
2066 if test "${enable_mod}" != "no" ; then
2067     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2068           VLC_ADD_PLUGIN([mod])
2069           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2070           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2071     ],[
2072        AS_IF([test -n "${enable_mod}"],
2073          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2074          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2075     ])
2076 fi
2077
2078 dnl
2079 dnl  mpc demux plugin
2080 dnl
2081 AC_ARG_ENABLE(mpc,
2082   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2083 if test "${enable_mpc}" != "no"
2084 then
2085   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2086     VLC_ADD_PLUGIN([mpc])
2087     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2088     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2089     VLC_ADD_PLUGIN([mpc])
2090     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2091 fi
2092
2093 dnl
2094 dnl  Codec plugins
2095 dnl
2096
2097 EXTEND_HELP_STRING([Codec plugins:])
2098
2099 dnl
2100 dnl wmafixed plugin
2101 dnl
2102 AC_ARG_ENABLE(wma-fixed,
2103   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2104 if test "${enable_wma_fixed}" = "yes"
2105 then
2106   VLC_ADD_PLUGIN([wma_fixed])
2107 fi
2108
2109 dnl
2110 dnl shine fixed point mp3 encoder
2111 dnl
2112 AC_ARG_ENABLE(shine,
2113   [  --enable-shine          shine mp3 encoding module (default disabled)])
2114 if test "${enable_shine}" = "yes"
2115 then
2116   VLC_ADD_PLUGIN([shine])
2117 fi
2118
2119 dnl
2120 dnl openmax il codec plugin
2121 dnl
2122 AC_ARG_ENABLE(omxil,
2123   [  --enable-omxil          openmax il codec module (default disabled)])
2124 if test "${enable_omxil}" = "yes"
2125 then
2126   VLC_ADD_PLUGIN([omxil])
2127 fi
2128
2129 dnl
2130 dnl openmax il vout plugin
2131 dnl
2132 AC_ARG_ENABLE(omxil-vout,
2133   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2134 if test "${enable_omxil_vout}" = "yes"
2135 then
2136   VLC_ADD_PLUGIN([omxil_vout])
2137 fi
2138
2139 dnl
2140 dnl raspberry pi openmax il configuration
2141 dnl
2142 AC_ARG_ENABLE(rpi-omxil,
2143   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2144 if test "${enable_rpi_omxil}" = "yes"
2145 then
2146   VLC_ADD_PLUGIN([omxil omxil_vout])
2147   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2148 fi
2149
2150 dnl
2151 dnl CrystalHD codec plugin
2152 dnl
2153 AC_ARG_ENABLE(crystalhd,
2154   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2155 if test "${enable_crystalhd}" != "no"; then
2156     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2157       VLC_ADD_PLUGIN([crystalhd])
2158       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2159     ],[
2160       if test "${SYS}" = "mingw32" ; then
2161         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2162           VLC_ADD_PLUGIN([crystalhd])
2163           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2164             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2165             ])
2166         ],[
2167           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2168                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2169                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2170         ],[#define __LINUX_USER__
2171                #include <libcrystalhd/bc_dts_types.h>
2172         ])
2173       fi
2174     ],[
2175        #include <libcrystalhd/bc_dts_types.h>
2176       ])
2177 fi
2178
2179 dnl
2180 dnl  mad plugin
2181 dnl
2182 AC_ARG_ENABLE(mad,
2183   [  --enable-mad            libmad module (default enabled)])
2184 if test "${enable_mad}" != "no"
2185 then
2186   AC_ARG_WITH(mad,
2187     [  --with-mad=PATH         path to libmad],[],[])
2188   if test "${with_mad}" != "no" -a -n "${with_mad}"
2189   then
2190     VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${with_mad}/include])
2191     VLC_ADD_LIBS([mpgatofixed32],[-L${with_mad}/lib])
2192   fi
2193
2194   AC_ARG_WITH(mad-tree,
2195     [  --with-mad-tree=PATH    mad tree for static linking],[],[])
2196   if test "${with_mad_tree}" != "no" -a -n "${with_mad_tree}"
2197   then
2198     real_mad_tree="`cd ${with_mad_tree} 2>/dev/null && pwd`"
2199     if test -z "${real_mad_tree}"
2200     then
2201       dnl  The given directory can't be found
2202       AC_MSG_RESULT(no)
2203       AC_MSG_ERROR([${with_mad_tree} directory does not exist])
2204     fi
2205     dnl  Use a custom libmad
2206     AC_MSG_CHECKING(for mad.h in ${real_mad_tree})
2207     if test -f ${real_mad_tree}/mad.h
2208     then
2209       AC_MSG_RESULT(yes)
2210       VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${real_mad_tree}])
2211       VLC_ADD_LIBS([mpgatofixed32],[-L${real_mad_tree}/.libs])
2212       VLC_SAVE_FLAGS
2213       LDFLAGS="${LDFLAGS} ${LIBS_mpgatofixed32}"
2214       AC_CHECK_LIB(mad, mad_bit_init, [
2215         VLC_ADD_PLUGIN([mpgatofixed32])
2216         VLC_ADD_LIBS([mpgatofixed32],[-lmad])
2217         ],[ AC_MSG_ERROR([the specified tree has not been compiled ])
2218       ],[])
2219       VLC_RESTORE_FLAGS
2220     else
2221       AC_MSG_RESULT(no)
2222       AC_MSG_ERROR([the specified tree does not have mad.h])
2223     fi
2224   else
2225     VLC_SAVE_FLAGS
2226     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_mpgatofixed32}"
2227     LDFLAGS="${LDFLAGS} ${LIBS_mpgatofixed32}"
2228     AC_CHECK_HEADERS(mad.h, ,
2229       [ AC_MSG_ERROR([Could not find libmad on your system: you may get it from http://www.underbit.com/products/mad/. Alternatively you can use --disable-mad to disable the mad plugin.]) ])
2230     AC_CHECK_LIB(mad, mad_bit_init, [
2231       VLC_ADD_PLUGIN([mpgatofixed32])
2232       VLC_ADD_LIBS([mpgatofixed32],[-lmad])],
2233       [ AC_MSG_ERROR([Cannot find libmad library...]) ])
2234     VLC_RESTORE_FLAGS
2235   fi
2236 fi
2237
2238
2239 AC_ARG_ENABLE(merge-ffmpeg,
2240 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2241   enable_merge_ffmpeg="no"
2242 ])
2243 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2244
2245 dnl
2246 dnl  avcodec decoder/encoder plugin
2247 dnl
2248 AC_ARG_ENABLE(avcodec,
2249 [  --enable-avcodec        libavcodec codec (default enabled)])
2250 AS_IF([test "${enable_avcodec}" != "no"], [
2251   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= 53.34.0 libavutil >= 51.22.0], [
2252     dnl PKG_CHECK_EXISTS([libavcodec < 56],, [
2253     dnl   AC_MSG_ERROR([libavcodec versions 56 and later are not supported yet.])
2254     dnl ])
2255     VLC_SAVE_FLAGS
2256     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2257     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2258     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2259     AC_CHECK_HEADERS(libavutil/avutil.h)
2260     VLC_RESTORE_FLAGS
2261     have_avcodec="yes"
2262   ],[
2263     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2264   ])
2265 ], [
2266   have_avcodec="no"
2267 ])
2268 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2269
2270 dnl
2271 dnl libva needs avcodec
2272 dnl
2273 AC_ARG_ENABLE(libva,
2274   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2275
2276 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2277   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2278 ])
2279 have_avcodec_vaapi="no"
2280 AS_IF([test "${enable_libva}" != "no" -a "${have_avcodec}" = "yes"], [
2281   PKG_CHECK_MODULES(LIBVA, [libva libva-x11], [
2282     VLC_SAVE_FLAGS
2283     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2284     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2285     AC_CHECK_HEADERS(libavcodec/vaapi.h, [
2286       AC_MSG_NOTICE([VAAPI acceleration activated])
2287       have_avcodec_vaapi="yes"
2288     ],[
2289       AS_IF([test -n "${enable_libva}"], [
2290         AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2291       ], [
2292         AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2293       ])
2294     ])
2295     VLC_RESTORE_FLAGS
2296   ],[
2297     AS_IF([test -n "${enable_libva}"], [
2298       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2299     ], [
2300       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2301     ])
2302   ])
2303 ])
2304 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2305
2306 dnl
2307 dnl dxva2 needs avcodec
2308 dnl
2309 AC_ARG_ENABLE(dxva2,
2310   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2311
2312 have_avcodec_dxva2="no"
2313 AS_IF([test "${enable_dxva2}" != "no"], [
2314   if test "${SYS}" = "mingw32"; then
2315   AS_IF([test "x${have_avcodec}" = "xyes"], [
2316     AC_CHECK_HEADERS(dxva2api.h,
2317       [
2318         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2319            AC_MSG_NOTICE([DxVA2 acceleration activated])
2320            have_avcodec_dxva2="yes"
2321         ],[
2322     AS_IF([test "${enable_dxva2}" = "yes"],
2323           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2324               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2325         ], [#undef _WIN32_WINNT
2326             /* DXVA2 is only available in Vista and above */
2327             #define _WIN32_WINNT 0x600])
2328       ],[
2329     AS_IF([test "${enable_dxva2}" = "yes"],
2330               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2331               [AC_MSG_WARN([dxva2api.h not found])])
2332       ])
2333   ],[
2334     AS_IF([test "x${enable_dxva2}" != "x"], [
2335       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2336     ])
2337   ])
2338   fi
2339 ])
2340 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2341
2342 dnl
2343 dnl vda needs avcodec
2344 dnl
2345 AC_ARG_ENABLE(vda,
2346   [  --enable-vda          VDA  support (default auto)])
2347
2348 have_avcodec_vda="no"
2349 AS_IF([test "${enable_vda}" != "no"], [
2350   if test "${SYS}" = "darwin"; then
2351   AS_IF([test "x${have_avcodec}" = "xyes"], [
2352     AC_CHECK_HEADERS(VideoDecodeAcceleration/VDADecoder.h,
2353     [
2354       PKG_CHECK_EXISTS([libavcodec >= 55.19.0], [
2355         have_avcodec_vda="yes"
2356       ],[
2357         AS_IF([test "${enable_vda}" = "yes"],
2358          [AC_MSG_ERROR([libavcodec >= 55.19.0 is required for VDA decoding])],
2359          [AC_MSG_WARN([libavcodec >= 55.19.0 is required for VDA decoding])])
2360       ])
2361     ],[
2362         AS_IF([test "${enable_vda}" = "yes"],
2363       [AC_MSG_ERROR([Could not find required VideoDecodeAcceleration/VDADecoder.h])],
2364       [AC_MSG_WARN([VideoDecodeAcceleration/VDADecoder.h not found])])
2365     ])
2366   ],[
2367     AS_IF([test "x${enable_vda}" != "x"], [
2368       AC_MSG_ERROR([--enable-vda and --disable-avcodec options are mutually exclusive.])
2369     ])
2370   ])
2371   fi
2372 ])
2373 AM_CONDITIONAL([HAVE_AVCODEC_VDA], [test "${have_avcodec_vda}" = "yes"])
2374
2375 dnl
2376 dnl  avformat demuxer/muxer plugin
2377 dnl
2378
2379 AC_ARG_ENABLE(avformat,
2380 [  --enable-avformat       libavformat containers (default enabled)],, [
2381   enable_avformat="${have_avcodec}"
2382 ])
2383 have_avformat="no"
2384 AS_IF([test "${enable_avformat}" != "no"], [
2385   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2386       have_avformat="yes"
2387       VLC_SAVE_FLAGS
2388       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2389       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2390       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2391       AC_CHECK_HEADERS(libavutil/avutil.h)
2392       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2393         have_avformat="no"
2394       ])
2395       VLC_RESTORE_FLAGS
2396     ],[
2397       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2398   ])
2399 ])
2400 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2401
2402 dnl
2403 dnl  swscale image scaling and conversion plugin
2404 dnl
2405
2406 AC_ARG_ENABLE(swscale,
2407   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2408           (default enabled)]))
2409 if test "${enable_swscale}" != "no"
2410 then
2411   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2412     [
2413       VLC_SAVE_FLAGS
2414       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2415       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2416       AC_CHECK_HEADERS(libswscale/swscale.h)
2417       VLC_ADD_PLUGIN([swscale])
2418       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2419       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2420       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2421         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2422       ])
2423       VLC_RESTORE_FLAGS
2424     ],[
2425       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2426   ])
2427 fi
2428
2429 dnl
2430 dnl  postproc plugin
2431 dnl
2432
2433 AC_ARG_ENABLE(postproc,
2434 [  --enable-postproc       libpostproc image post-processing (default auto)])
2435 if test "${enable_postproc}" != "no"
2436 then
2437   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2438     [
2439       VLC_SAVE_FLAGS
2440       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2441       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2442       AC_CHECK_HEADERS(postproc/postprocess.h)
2443       VLC_ADD_PLUGIN([postproc])
2444       VLC_ADD_LIBS([postproc],[$POSTPROC_LIBS $AVUTIL_LIBS])
2445       VLC_ADD_CFLAGS([postproc],[$POSTPROC_CFLAGS $AVUTIL_CFLAGS])
2446       VLC_RESTORE_FLAGS
2447     ],[
2448       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2449   ])
2450 fi
2451
2452 dnl
2453 dnl  faad decoder plugin
2454 dnl
2455 AC_ARG_ENABLE(faad,
2456 [  --enable-faad           faad codec (default auto)])
2457 if test "${enable_faad}" != "no"; then
2458   AC_ARG_WITH(faad-tree,  [  --with-faad-tree=PATH   faad tree for static linking])
2459   if test -n "${with_faad_tree}"; then
2460     AC_MSG_CHECKING(for libfaad.a in ${with_faad_tree})
2461     real_faad_tree="`cd ${with_faad_tree} 2>/dev/null && pwd`"
2462     if test -z "${real_faad_tree}"; then
2463       dnl  The given directory can't be found
2464       AC_MSG_RESULT(no)
2465       AC_MSG_ERROR([cannot cd to ${with_faad_tree}])
2466     fi
2467     if test -f "${real_faad_tree}/libfaad/.libs/libfaad.a"; then
2468       dnl  Use the custom faad
2469       AC_MSG_RESULT(${real_faad_tree}/libfaad/.libs/libfaad.a)
2470       VLC_ADD_PLUGIN([faad])
2471       VLC_ADD_LIBS([faad],[${real_faad_tree}/libfaad/.libs/libfaad.a])
2472       VLC_ADD_CPPFLAGS([faad],[-I${real_faad_tree}/include])
2473     else
2474       dnl  The given libfaad wasn't built
2475       AC_MSG_RESULT(no)
2476       AC_MSG_ERROR([cannot find ${real_faad_tree}/libfaad/.libs/libfaad.a, make sure you compiled libfaad in ${with_faad_tree}])
2477     fi
2478   else
2479     VLC_SAVE_FLAGS
2480     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_faad}"
2481     LDFLAGS="${LDFLAGS} ${LIBS_faad}"
2482     AC_CHECK_HEADERS(faad.h,
2483       [ AC_CHECK_LIB(faad, faacDecOpen, [
2484           VLC_ADD_PLUGIN([faad])
2485           VLC_ADD_LIBS([faad],[-lfaad]) ], [
2486             AC_CHECK_LIB(faad, NeAACDecOpen, [
2487               VLC_ADD_PLUGIN([faad])
2488               VLC_ADD_LIBS([faad],[-lfaad]) ], [
2489                 AS_IF([test "${enable_faad}" = "yes"],
2490                 [ AC_MSG_ERROR([Cannot find libfaad library...]) ],
2491                 [ AC_MSG_WARN([Cannot find libfaad library...]) ]) ]) ])
2492       ] , [ AS_IF([test "${enable_faad}" = "yes"],
2493         [ AC_MSG_ERROR([Cannot find development headers for libfaad...]) ],
2494         [ AC_MSG_WARN([Cannot find development headers for libfaad...]) ]) ])
2495     VLC_RESTORE_FLAGS
2496   fi
2497 fi
2498
2499 dnl
2500 dnl twolame encoder plugin
2501 dnl
2502 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2503
2504 dnl
2505 dnl fdk-aac encoder plugin
2506 dnl
2507 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2508
2509 dnl
2510 dnl  QuickTime plugin
2511 dnl
2512 AC_ARG_ENABLE(quicktime,
2513   [  --enable-quicktime      QuickTime module (deprecated)])
2514 if test "${enable_quicktime}" = "yes"; then
2515   if test "${SYS}" = "mingw32"; then
2516     VLC_ADD_PLUGIN([quicktime])
2517   else
2518   AC_CHECK_HEADERS(QuickTime/QuickTime.h,
2519     [ VLC_ADD_PLUGIN([quicktime])
2520       VLC_ADD_LIBS([quicktime],[-Wl,-framework,QuickTime,-framework,Carbon])
2521     ], [ AC_MSG_ERROR([cannot find QuickTime headers]) ])
2522   fi
2523 fi
2524
2525 dnl
2526 dnl A52/AC3 decoder plugin
2527 dnl
2528 AC_ARG_ENABLE(a52,
2529   [  --enable-a52            A/52 support with liba52 (default enabled)])
2530 if test "${enable_a52}" != "no"
2531 then
2532   AC_ARG_WITH(a52,
2533     [  --with-a52=PATH         a52 headers and libraries])
2534   AC_ARG_WITH(a52-tree,
2535     [  --with-a52-tree=PATH    a52dec tree for static linking ],[],[])
2536   if test "${with_a52_tree}" != "no" -a -n "${with_a52_tree}"
2537   then
2538     real_a52_tree="`cd ${with_a52_tree} 2>/dev/null && pwd`"
2539     if test -z "${real_a52_tree}"
2540     then
2541       dnl  The given directory can't be found
2542       AC_MSG_RESULT(no)
2543       AC_MSG_ERROR([${with_a52_tree} directory does not exist])
2544     fi
2545     dnl  Use a custom a52dec
2546     AC_MSG_CHECKING(for a52.h in ${real_a52_tree}/include)
2547     if test -f ${real_a52_tree}/include/a52.h
2548     then
2549       AC_MSG_RESULT(yes)
2550       VLC_ADD_CPPFLAGS([a52tofloat32],[-I${real_a52_tree}])
2551       VLC_ADD_LIBS([a52tofloat32],[-L${real_a52_tree}/liba52/.libs])
2552       VLC_SAVE_FLAGS
2553       LDFLAGS="${LDFLAGS} ${LIBS_a52tofloat32}"
2554       AC_CHECK_LIB(a52, a52_free, [
2555         VLC_ADD_PLUGIN([a52tofloat32])
2556         VLC_ADD_CPPFLAGS([a52tofloat32],[-DUSE_A52DEC_TREE])
2557         VLC_ADD_LIBS([a52tofloat32],[-la52])
2558         ],[
2559         if test -f ${real_a52_tree}/liba52/.libs/liba52.a
2560         then
2561           AC_MSG_ERROR([make sure you have at least a52dec-0.7.3 ($real_a52_tree)])
2562         else
2563           AC_MSG_ERROR([the specified tree has not been compiled])
2564         fi
2565       ])
2566     else
2567       AC_MSG_RESULT(no)
2568       AC_MSG_ERROR([the specified tree does not have a52.h])
2569     fi
2570   else
2571     if test -z "${with_a52}"
2572     then
2573       LDFLAGS_test=""
2574       CPPFLAGS_test=""
2575     else
2576       LDFLAGS_test="-L${with_a52}/lib"
2577       CPPFLAGS_test="-I${with_a52}/include"
2578     fi
2579     VLC_SAVE_FLAGS
2580     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52tofloat32}"
2581     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52tofloat32}"
2582     AC_CHECK_HEADERS(a52dec/a52.h, [
2583       AC_CHECK_LIB(a52, a52_free, [
2584         VLC_ADD_PLUGIN([a52tofloat32])
2585         VLC_ADD_LIBS([a52tofloat32],[${LDFLAGS_test} -la52])
2586         VLC_ADD_CPPFLAGS([a52tofloat32],[${CPPFLAGS_test}])
2587       ],[
2588         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2589         ], [$LIBM])
2590     ],[
2591       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2592     ])
2593     VLC_RESTORE_FLAGS
2594   fi
2595 fi
2596
2597 dnl
2598 dnl DTS Coherent Acoustics decoder plugin
2599 dnl
2600 PKG_ENABLE_MODULES_VLC([DCA], [dtstofloat32], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2601
2602 dnl
2603 dnl  Flac plugin
2604 dnl
2605 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2606
2607 dnl
2608 dnl  Libmpeg2 plugin
2609 dnl
2610 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2611
2612 dnl
2613 dnl  Vorbis plugin
2614 dnl
2615 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2616
2617 dnl
2618 dnl  Tremor plugin
2619 dnl
2620 AC_ARG_ENABLE(tremor,
2621   [  --enable-tremor         Tremor decoder support (default disabled)])
2622 if test "${enable_tremor}" = "yes"
2623 then
2624   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2625     VLC_ADD_PLUGIN([tremor])
2626    ],[])
2627 fi
2628
2629 dnl
2630 dnl  Speex plugins
2631 dnl
2632 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2633 have_speexdsp="no"
2634 AS_IF([test "${enable_speex}" != "no"], [
2635   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2636     have_speexdsp="yes"
2637   ], [
2638     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2639   ])
2640 ])
2641 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2642
2643 dnl
2644 dnl  Opus plugin
2645 dnl
2646 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2647
2648 dnl
2649 dnl  theora decoder plugin
2650 dnl
2651 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2652
2653 dnl
2654 dnl  dirac encoder plugin
2655 dnl
2656 PKG_ENABLE_MODULES_VLC([DIRAC], [], [dirac >= 0.10.0], [dirac encoder], [auto])
2657
2658 dnl
2659 dnl  schroedinger decoder plugin (for dirac format video)
2660 dnl
2661 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2662
2663 dnl
2664 dnl  PNG decoder module
2665 dnl
2666 AC_ARG_ENABLE(png,
2667   [  --enable-png            PNG support (default enabled)])
2668 AS_IF([test "${enable_png}" != "no"], [
2669 AC_CHECK_HEADERS(png.h, [
2670   VLC_SAVE_FLAGS
2671   LDFLAGS="${LDFLAGS} -lz $LIBM"
2672   AC_CHECK_LIB(png, png_set_rows, [
2673     VLC_ADD_PLUGIN([png])
2674   ], [], [-lz $LIBM])
2675   VLC_RESTORE_FLAGS
2676   ])
2677 ])
2678
2679 dnl
2680 dnl H262 encoder plugin (lib262)
2681 dnl
2682 AC_ARG_ENABLE(x262,
2683   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2684 if test "${enable_x262}" != "no"; then
2685 AC_ARG_WITH(x262-tree,
2686   [ --with-x262-tree=PATH      H262 encoding module with libx262 (static linking)],[],[])
2687   if test "${with_x262_tree}" != "no" -a -n "${with_x262_tree}"
2688   then
2689     real_x262_tree="̧`cd ${with_x262_tree} 2>/dev/null && pwd`"
2690     if test -z "${real_x262_tree}"
2691     then
2692       AC_MSG_RESULT(no)
2693       AC_MSG_ERROR([${with_x262_tree} directory does not exist])
2694     fi
2695     AC_MSG_CHECKING(for x262.h in ${real_x262_tree})
2696     if test -f ${with_x262_tree}/x262_config.h
2697     then
2698       VLC_ADD_PLUGIN([x262])
2699       VLC_ADD_CFLAGS([x262],[-I${with_x262_tree}])
2700       VLC_ADD_LIBS([x262],[-L${with_x262_tree} -lm -lpthread -lx262])
2701     else
2702       AC_MSG_RESULT(no)
2703       AC_MSG_ERROR([${with_x262_tree} doesnt have x262_config.h])
2704     fi
2705   else
2706     PKG_CHECK_MODULES(X262, x262, [
2707         VLC_ADD_PLUGIN([x262])
2708         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2709         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2710           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2711         ])
2712         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2713         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2714           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2715         fi
2716     ], [
2717        if test "${enable_x262}" = "yes"; then
2718         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2719        fi
2720     ])
2721   fi
2722 fi
2723
2724 dnl x265 encoder
2725 AC_ARG_ENABLE(x265,
2726   AS_HELP_STRING([--enable-x265],[H265 / HEVC encoding support with libx265 (default enabled)]))
2727 AS_IF( [test "${enable_x265}" != "no"],[
2728   AC_CHECK_HEADER([x265.h], [
2729       AC_CHECK_LIB([x265],[x265_encoder_open], [
2730         VLC_ADD_PLUGIN([x265])
2731         VLC_ADD_LIBS([x265], [-lx265 -lstdc++ -lm -lpthread])
2732       ], [
2733         AC_MSG_ERROR([x265 library not found])
2734       ], [-lstdc++ -lm -lpthread])
2735   ], [
2736     AS_IF([test "${enable_x265}" = "yes"], [
2737         AC_MSG_ERROR([x265.h not found])
2738     ])
2739   ])
2740 ])
2741
2742
2743 dnl
2744 dnl H264 encoder plugin (10-bit lib264)
2745 dnl
2746 AC_ARG_ENABLE(x26410b,
2747   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2748 if test "${enable_x26410b}" != "no"; then
2749 AC_ARG_WITH(x26410b-tree,
2750   [ --with-x26410b-tree=PATH      H264 10-bit encoding module with libx264 (static linking)],[],[])
2751   if test "${with_x26410b_tree}" != "no" -a -n "${with_x26410b_tree}"
2752   then
2753     real_x26410b_tree="̧`cd ${with_x26410b_tree} 2>/dev/null && pwd`"
2754     if test -z "${real_x26410b_tree}"
2755     then
2756       AC_MSG_RESULT(no)
2757       AC_MSG_ERROR([${with_x26410b_tree} directory does not exist])
2758     fi
2759     AC_MSG_CHECKING(for x264.h in ${real_x26410b_tree})
2760     if test -f ${with_x26410b_tree}/x264_config.h
2761     then
2762       AC_MSG_RESULT(yes)
2763       AC_MSG_CHECKING(for 10-bit build of x264)
2764       if grep -q "BIT_DEPTH.*10"  ${with_x26410b_tree}/x264_config.h ;then
2765         AC_MSG_RESULT(yes)
2766         VLC_ADD_PLUGIN([x26410b])
2767         VLC_ADD_CFLAGS([x26410b],[-I${with_x26410b_tree}])
2768         VLC_ADD_LIBS([x26410b],[-L${with_x26410b_tree} -lm -lpthread -lx264])
2769       else
2770         AC_MSG_RESULT(no)
2771         AC_MSG_ERROR([${with_x26410b_tree} isnt build 10-bit])
2772       fi
2773     else
2774       AC_MSG_RESULT(no)
2775       AC_MSG_ERROR([${with_x26410b_tree} doesnt have x264_config.h])
2776     fi
2777   else
2778     PKG_CHECK_MODULES(X26410B, x26410b, [
2779         VLC_ADD_PLUGIN([x26410b])
2780         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2781         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2782           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2783         ])
2784         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2785         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2786           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2787         fi
2788     ], [
2789        if test "${enable_x26410b}" = "yes"; then
2790         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2791        fi
2792     ])
2793   fi
2794 fi
2795
2796
2797 dnl
2798 dnl H264 encoder plugin (using libx264)
2799 dnl
2800 AC_ARG_ENABLE(x264,
2801   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2802 if test "${enable_x264}" != "no"; then
2803   AC_ARG_WITH(x264-tree,
2804     [  --with-x264-tree=PATH   x264 tree for static linking ],[],[])
2805   if test "${with_x264_tree}" != "no" -a -n "${with_x264_tree}"
2806   then
2807     real_x264_tree="`cd ${with_x264_tree} 2>/dev/null && pwd`"
2808     if test -z "${real_x264_tree}"
2809     then
2810       dnl  The given directory can't be found
2811       AC_MSG_RESULT(no)
2812       AC_MSG_ERROR([${with_x264_tree} directory does not exist])
2813     fi
2814     dnl  Use a custom libx264
2815     AC_MSG_CHECKING(for x264.h in ${real_x264_tree})
2816     if test -f ${real_x264_tree}/x264.h
2817     then
2818       AC_MSG_RESULT(yes)
2819       VLC_ADD_CPPFLAGS([x264],[-I${real_x264_tree}])
2820       VLC_ADD_LIBS([x264],[-L${real_x264_tree}])
2821       PKG_CHECK_MODULES(X264,x264, [
2822         VLC_ADD_PLUGIN([x264])
2823         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2824         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2825         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2826           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2827         fi
2828       ],[
2829         AC_MSG_ERROR([the specified tree has not been compiled])
2830       ])
2831     else
2832       AC_MSG_RESULT(no)
2833       AC_MSG_ERROR([the specified tree does not have x264.h])
2834     fi
2835   else
2836       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2837         VLC_ADD_PLUGIN([x264])
2838         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2839
2840         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2841           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2842         ])
2843
2844         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2845         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2846           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2847         fi
2848       ],[
2849         if test "${enable_x264}" = "yes"; then
2850             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2851           fi
2852       ])
2853   fi
2854 fi
2855
2856 dnl
2857 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2858 dnl
2859 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2860
2861 dnl
2862 dnl libfluidsynth (MIDI synthetizer) plugin
2863 dnl
2864 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2865
2866 dnl
2867 dnl Teletext Modules
2868 dnl vbi decoder plugin (using libzbvi)
2869 dnl telx module
2870 dnl uncompatible
2871 dnl
2872 AC_ARG_ENABLE(zvbi,
2873   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2874                   libzvbi (default enabled)]))
2875 AC_ARG_ENABLE(telx,
2876   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2877                   zvbi) (default enabled if zvbi is absent)]))
2878
2879 AS_IF( [test "${enable_zvbi}" != "no"],[
2880     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2881         [
2882           VLC_ADD_PLUGIN([zvbi])
2883           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2884           AS_IF( [test "${enable_telx}" = "yes"],[
2885                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2886                   ])
2887         ],[
2888           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2889         ])
2890     ])
2891 AS_IF( [test "${enable_telx}" != "no" ],[
2892   VLC_ADD_PLUGIN([telx])
2893   ])
2894
2895 dnl
2896 dnl libass subtitle rendering module
2897 dnl
2898 AC_ARG_ENABLE(libass,
2899   [  --enable-libass         Subtitle support using libass (default enabled)])
2900 AS_IF( [test "${enable_libass}" != "no"], [
2901   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2902       [
2903         VLC_ADD_PLUGIN([libass])
2904
2905         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2906           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2907            VLC_ADD_LIBS([libass],[-lfontconfig])
2908        ])
2909       ],[
2910         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2911       ])
2912   ])
2913
2914 dnl
2915 dnl  kate decoder plugin
2916 dnl
2917 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2918
2919 dnl
2920 dnl  tiger rendering for kate decoder plugin
2921 dnl
2922 AC_ARG_ENABLE(tiger,
2923 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2924 AS_IF([test "${enable_tiger}" != "no"], [
2925   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2926       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2927         AS_IF([test -n "${enable_tiger}"], [
2928           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2929         ])
2930   ])
2931 ])
2932
2933
2934 dnl
2935 dnl  Video plugins
2936 dnl
2937
2938 EXTEND_HELP_STRING([Video plugins:])
2939
2940 dnl
2941 dnl  OpenGL
2942 dnl
2943 PKG_CHECK_MODULES([GL], [gl], [
2944   have_gl="yes"
2945 ], [
2946   AC_CHECK_HEADER([GL/gl.h], [
2947     have_gl="yes"
2948     GL_CFLAGS=""
2949     AS_IF([test "${SYS}" = "mingw32"], [
2950       AC_CHECK_HEADER([GL/glew.h], [
2951       ], [
2952         have_gl="no"
2953       ])
2954       GL_LIBS="-lopengl32"
2955     ], [
2956       GL_LIBS="-lGL"
2957     ])
2958   ], [
2959     have_gl="no"
2960   ])
2961 ])
2962 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
2963
2964 dnl OpenGL ES 2: depends on EGL 1.1
2965 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
2966 dnl OpenGL ES 1: depends on EGL 1.0
2967 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [disabled])
2968
2969 AC_ARG_ENABLE(egl,
2970   [  --enable-egl            OpenGL support through EGL (default disabled)],, [
2971   enable_egl="no"
2972 ])
2973 AS_IF([test "$enable_egl" != "no"], [
2974   PKG_CHECK_MODULES([EGL], [egl], [
2975     VLC_ADD_PLUGIN([egl])
2976   ])
2977 ])
2978
2979 dnl
2980 dnl  Xlib
2981 dnl
2982
2983 AC_PATH_XTRA()
2984 AC_CHECK_HEADERS(X11/Xlib.h)
2985
2986 dnl
2987 dnl  X C Bindings modules
2988 dnl
2989 AC_ARG_ENABLE(xcb,
2990   [  --enable-xcb            X11 support with XCB (default enabled)],, [
2991   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" -a "${SYS}" != "symbian"], [
2992     enable_xcb="yes"
2993   ], [
2994     enable_xcb="no"
2995   ])
2996 ])
2997 AC_ARG_ENABLE(xvideo,
2998   [  --enable-xvideo         XVideo support (default enabled)],, [
2999     enable_xvideo="$enable_xcb"
3000 ])
3001 AC_ARG_ENABLE(glx,
3002   [  --enable-glx            OpenGL support through GLX (default enabled)],, [
3003   enable_glx="$enable_xcb"
3004 ])
3005
3006 have_xcb="no"
3007 have_xcb_keysyms="no"
3008 have_xcb_randr="no"
3009 have_xcb_xvideo="no"
3010 AS_IF([test "${enable_xcb}" != "no"], [
3011   dnl libxcb
3012   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3013   have_xcb="yes"
3014   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3015   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3016   PKG_CHECK_MODULES(XPROTO, [xproto])
3017
3018   AS_IF([test "${enable_xvideo}" != "no"], [
3019     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3020   ])
3021
3022   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3023
3024   dnl xcb-utils
3025   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3026     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3027   ])
3028 ])
3029 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3030 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3031 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3032 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3033
3034
3035 dnl
3036 dnl VDPAU needs X11
3037 dnl
3038 AC_ARG_ENABLE(vdpau,
3039   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3040 have_vdpau="no"
3041 AS_IF([test "${enable_vdpau}" != "no"], [
3042   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3043     have_vdpau="yes"
3044     AS_IF([test "${no_x}" = "yes"], [
3045       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3046     ])
3047   ], [
3048     AS_IF([test -n "${enable_vdpau}"], [
3049       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3050     ])
3051   ])
3052 ])
3053 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3054
3055 have_avcodec_vdpau="no"
3056 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3057   PKG_CHECK_EXISTS([libavutil >= 0.52.4 libavcodec >= 54.36.0], [
3058     have_avcodec_vdpau="yes"
3059     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3060   ], [
3061     AS_IF([test -n "${enable_vdpau}"], [
3062       AC_MSG_ERROR([libavutil >= 0.52.4 and libavcodec >= 54.36.0 are required for VDPAU decoding.])
3063     ], [
3064       AC_MSG_WARN([libavutil >= 0.52.4 and libavcodec >= 54.36.0 are required for VDPAU decoding.])
3065     ])
3066   ])
3067 ])
3068 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3069
3070
3071 dnl
3072 dnl  SDL module
3073 dnl
3074 AC_ARG_ENABLE(sdl,
3075   [  --enable-sdl            SDL support (default enabled)])
3076 AC_ARG_ENABLE(sdl-image,
3077   [  --enable-sdl-image      SDL image support (default enabled)])
3078 if test "${enable_sdl}" != "no"
3079 then
3080    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3081       # SDL on Darwin is heavily patched and can only run SDL_image
3082       if test "${SYS}" != "darwin"; then
3083         VLC_ADD_PLUGIN([vout_sdl])
3084       fi
3085       if test "${SYS}" != "mingw32" -a "${SYS}" != "os2"; then
3086         VLC_ADD_LIBS([vout_sdl],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3087       fi
3088       VLC_ADD_CFLAGS([vout_sdl],[${SDL_CFLAGS}])
3089       VLC_ADD_LIBS([vout_sdl],[${SDL_LIBS}])
3090
3091       # SDL_image
3092       AS_IF([ test "${enable_sdl_image}" != "no"],[
3093         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3094           VLC_ADD_PLUGIN([sdl_image])],
3095           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3096           ])
3097       ])
3098    ],[
3099      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3100    ])
3101 fi
3102
3103
3104 dnl
3105 dnl Mac Vout
3106 AC_ARG_ENABLE(macosx-vout,
3107   [  --enable-macosx-vout    Mac OS X video output module (default enabled on Mac OS X)])
3108 if test "x${enable_macosx_vout}" != "xno" &&
3109   (test "${SYS}" = "darwin" || test "${enable_macosx_vout}" = "yes")
3110 then
3111   VLC_ADD_LIBS([vout_macosx],[-Wl,-framework,Cocoa])
3112   VLC_ADD_LIBS([vout_macosx],[-Wl,-framework,OpenGL])
3113   VLC_ADD_PLUGIN([vout_macosx])
3114 fi
3115
3116 dnl
3117 dnl Mac CoreGraphics Layer Vout
3118 AC_ARG_ENABLE(coregraphicslayer-vout,
3119   [  --enable-coregraphicslayer-vout CoreGraphics layered video output module (default disabled)])
3120 if test "${enable_coregraphicslayer_vout}" = "yes"; then
3121   VLC_ADD_LIBS([vout_coregraphicslayer],[-Wl,-framework,Cocoa])
3122   VLC_ADD_LIBS([vout_coregraphicslayer],[-Wl,-framework,QuartzCore])
3123   VLC_ADD_PLUGIN([vout_coregraphicslayer])
3124 fi
3125
3126 dnl
3127 dnl  freetype module
3128 dnl
3129 AC_ARG_ENABLE(freetype,
3130   [  --enable-freetype       freetype support   (default auto)])
3131 AC_ARG_ENABLE(fribidi,
3132   [  --enable-fribidi        fribidi support    (default auto)])
3133 AC_ARG_ENABLE(fontconfig,
3134   [  --enable-fontconfig     fontconfig support (default auto)])
3135
3136 AC_ARG_WITH([default-font],
3137     AS_HELP_STRING([--with-default-font=PATH],
3138         [Path to the default font]),
3139         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3140             "$withval", [Default font])])
3141 AC_ARG_WITH([default-monospace-font],
3142     AS_HELP_STRING([--with-default-monospace-font=PATH],
3143         [Path to the default font]),
3144         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3145             "$withval", [Default monospace font])])
3146
3147 AC_ARG_WITH([default-font-family],
3148     AS_HELP_STRING([--with-default-font-family=NAME],
3149         [Path to the default font family]),
3150         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3151             "$withval", [Default font family])])
3152 AC_ARG_WITH([default-monospace-font-family],
3153     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3154         [Path to the default font family]),
3155         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3156             "$withval", [Default monospace font family])])
3157
3158 if test "${enable_freetype}" != "no"; then
3159    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3160       have_freetype=yes
3161       VLC_ADD_PLUGIN([freetype])
3162       VLC_ADD_CPPFLAGS([freetype skins2],[${FREETYPE_CFLAGS}])
3163       if test "${SYS}" = "mingw32"; then
3164         VLC_ADD_LIBS([freetype],[-liconv -lz])
3165       fi
3166       VLC_ADD_LIBS([freetype skins2],[${FREETYPE_LIBS}])
3167
3168       AC_CHECK_HEADERS(Carbon/Carbon.h,
3169                        [VLC_ADD_LIBS([freetype],[-Wl,-framework,Carbon])])
3170
3171       dnl fontconfig support
3172       if test "${SYS}" != "mingw32"; then
3173           if test "${enable_fontconfig}" != "no"; then
3174             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3175               VLC_ADD_CPPFLAGS([freetype],[-DHAVE_FONTCONFIG])
3176               VLC_ADD_LIBS([freetype],[-lfontconfig])
3177             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3178           fi
3179       else
3180           VLC_ADD_LIBS([freetype],[-lgdi32])
3181       fi
3182
3183       dnl fribidi support
3184       if test "${enable_fribidi}" != "no"; then
3185         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3186           VLC_ADD_CPPFLAGS([freetype skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3187           VLC_ADD_LIBS([freetype skins2], [${FRIBIDI_LIBS}])
3188         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional support will be disabled in FreeType.])])
3189       fi
3190
3191   ],[
3192   have_freetype=no
3193   AS_IF([test -n "${enable_freetype}"],[
3194     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3195     ])
3196   ])
3197 fi
3198
3199
3200 dnl
3201 dnl  QuartzText vout module (iOS/Mac OS)
3202 dnl
3203 AC_ARG_ENABLE(macosx-quartztext,
3204   [  --enable-macosx-quartztext   Mac OS X quartz text module (default enabled on Mac OS X)])
3205 if test "x${enable_macosx_quartztext}" != "xno" &&
3206   (test "${SYS}" = "darwin" || test "${enable_macosx_quartztext}" = "yes")
3207 then
3208   VLC_ADD_PLUGIN([quartztext])
3209   VLC_ADD_LIBS([quartztext],[-Wl,-framework,ApplicationServices])
3210 fi
3211
3212 dnl
3213 dnl  SVG module
3214 dnl
3215 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3216
3217 dnl
3218 dnl  android surface module
3219 dnl
3220 AC_ARG_ENABLE(android-surface,
3221   [  --enable-android-surface   Android Surface video output module (default disabled)])
3222 if test "${enable_android_surface}" = "yes"; then
3223   if test "${HAVE_ANDROID}" = "1"; then
3224      VLC_ADD_PLUGIN([android_surface])
3225      VLC_ADD_LIBS([android_surface], [-ldl])
3226   fi
3227 fi
3228
3229
3230 dnl
3231 dnl  iOS vout module
3232 dnl
3233 AC_ARG_ENABLE(ios-vout,
3234   [  --enable-ios-vout    iOS video output module (default disabled)])
3235 if test "${enable_ios_vout}" = "yes"
3236 then
3237   VLC_ADD_PLUGIN([vout_ios])
3238   VLC_ADD_LIBS([vout_ios], [-Wl,-framework,OpenGLES,-framework,QuartzCore,-framework,UIKit,-framework,Foundation])
3239 fi
3240
3241 dnl
3242 dnl  iOS ES2 vout module
3243 dnl
3244 AC_ARG_ENABLE(ios-vout2,
3245   [  --enable-ios-vout2    iOS video output module (default disabled)])
3246 if test "${enable_ios_vout2}" = "yes"
3247 then
3248   VLC_ADD_PLUGIN([vout_ios2])
3249   VLC_ADD_LIBS([vout_ios2], [-Wl,-framework,OpenGLES,-framework,QuartzCore,-framework,UIKit])
3250 fi
3251
3252
3253 dnl
3254 dnl  Windows DirectX module
3255 dnl
3256
3257 AC_ARG_ENABLE(directx,
3258   [AS_HELP_STRING([--enable-directx],
3259     [Microsoft DirectX support (default enabled on Windows)])],, [
3260   AS_IF([test "${SYS}" = "mingw32"], [
3261     enable_directx="yes"
3262   ], [
3263     enable_directx="no"
3264   ])
3265 ])
3266 have_directx="no"
3267 AS_IF([test "${enable_directx}" != "no"], [
3268   dnl DirectDraw
3269   AC_CHECK_HEADERS(ddraw.h, [
3270     have_directx="yes"
3271   ], [
3272     AC_MSG_ERROR([Cannot find DirectX headers!])
3273   ])
3274
3275   dnl OpenGL
3276   AC_CHECK_HEADERS(GL/wglew.h, [
3277     VLC_ADD_PLUGIN([glwin32])
3278   ],, [
3279     #include <windows.h>
3280     #include <GL/gl.h>
3281   ])
3282
3283   dnl Direct3D
3284   AC_CHECK_HEADERS(d3d9.h, [
3285     VLC_ADD_PLUGIN([direct3d])
3286   ])
3287
3288   dnl Direct2D
3289   AC_CHECK_HEADERS(d2d1.h, [
3290     VLC_ADD_PLUGIN([direct2d])
3291   ])
3292 ])
3293 AM_CONDITIONAL([HAVE_DIRECTX], [test "$have_directx" = "yes"])
3294
3295 dnl
3296 dnl  Linux framebuffer module
3297 dnl
3298 AC_CHECK_HEADER([linux/fb.h], [
3299   VLC_ADD_PLUGIN([fb])
3300 ])
3301
3302
3303 dnl
3304 dnl  DirectFB module
3305 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3306 dnl  TODO: support for static linking
3307 dnl
3308 AC_ARG_ENABLE(directfb,
3309   [  --enable-directfb       DirectFB support (default disabled)])
3310 AC_ARG_WITH(directfb,
3311   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3312
3313 if test "${enable_directfb}" = "yes"; then
3314     have_directfb="false"
3315     CPPFLAGS_mydirectfb=
3316     LIBS_mydirectfb=
3317     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3318         dnl Trying the given location
3319         VLC_SAVE_FLAGS
3320
3321         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3322         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3323
3324         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3325         LIBS="${LIBS} ${LIBS_new}"
3326
3327         dnl FIXME: too obscure
3328         AC_CHECK_HEADER([directfb.h], [
3329             AC_CHECK_LIB([direct],[direct_initialize], [
3330                 AC_CHECK_LIB([fusion], [fusion_enter], [
3331                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3332                 ], have_directfb="false")
3333             ], have_directfb="false")
3334         ], have_directfb="false")
3335
3336         VLC_RESTORE_FLAGS
3337
3338         if test "${have_directfb}" = "true"; then
3339             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3340             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3341         fi
3342     else
3343         dnl Look for directfb-config
3344         AC_PATH_PROG(DIRECTFB_CONFIG, directfb-config, no, ${PATH})
3345         if test "${DIRECTFB_CONFIG}" != "no"; then
3346             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3347             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3348             have_directfb="true"
3349         else
3350             dnl Trying with pkg-config
3351             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3352                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3353                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3354                 have_directfb="true"
3355                 ], [have_directfb="false"])
3356         fi
3357     fi
3358     if test "${have_directfb}" = "true"; then
3359         VLC_ADD_PLUGIN([directfb])
3360         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3361         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3362     else
3363         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3364     fi
3365 fi
3366
3367 dnl
3368 dnl  AA plugin
3369 dnl
3370 AC_ARG_ENABLE(aa,
3371   [  --enable-aa             aalib output (default disabled)])
3372 if test "${enable_aa}" = "yes"
3373 then
3374   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3375   if test "${have_aa}" = "true"
3376   then
3377     VLC_ADD_PLUGIN([aa])
3378     VLC_ADD_LIBS([aa],[-laa])
3379     if test "${SYS}" != "mingw32"; then
3380       VLC_ADD_LIBS([aa],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3381     fi
3382   fi
3383 fi
3384
3385 dnl
3386 dnl  libcaca plugin
3387 dnl
3388 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3389
3390 dnl
3391 dnl  OS/2 KVA plugin
3392 dnl
3393 AC_ARG_ENABLE(kva,
3394   [AS_HELP_STRING([--enable-kva],
3395     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3396   AS_IF([test "$SYS" = "os2"], [
3397     enable_kva="yes"
3398   ])
3399 ])
3400 have_kva="no"
3401 KVA_LIBS=""
3402 AS_IF([test "$enable_kva" != "no"], [
3403   AC_CHECK_HEADERS([kva.h], [
3404     have_kva="yes"
3405     AC_CHECK_LIB(kva, main, [
3406       KVA_LIBS="-lkva"
3407     ])
3408   ])
3409 ])
3410 AC_SUBST(KVA_LIBS)
3411 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3412
3413 dnl
3414 dnl  Audio plugins
3415 dnl
3416
3417 EXTEND_HELP_STRING([Audio plugins:])
3418
3419 dnl
3420 dnl  Pulseaudio module
3421 dnl
3422 AC_ARG_ENABLE(pulse,
3423   [AS_HELP_STRING([--enable-pulse],
3424     [use the PulseAudio client library (default auto)])])
3425 have_pulse="no"
3426 AS_IF([test "${enable_pulse}" != "no"], [
3427   PKG_CHECK_MODULES([PULSE], [libpulse >= 0.9.22], [
3428     have_pulse="yes"
3429   ], [
3430     PKG_CHECK_MODULES([PULSE], [libpulse >= 0.9.16], [
3431       AS_IF([test "${no_x}" != "yes"], [
3432         have_pulse="yes"
3433         PULSE_LIBS="$PULSE_LIBS ${X_LIBS} ${X_PRE_LIBS} -lX11"
3434       ], [
3435         AS_IF([test "${enable_pulse}" = "yes"], [
3436           AC_MSG_ERROR([Xlib is required with PulseAudio pre-0.9.22 versions
3437 (see http://www.pulseaudio.org/ticket/799 for further reference).])
3438         ])
3439       ])
3440     ], [
3441       AS_IF([test "x${enable_pulse}" != "x"], [
3442         AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 0.9.22 or later required.])
3443       ])
3444     ])
3445   ])
3446 ])
3447 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3448
3449 dnl
3450 dnl  ALSA module
3451 dnl
3452 AC_ARG_ENABLE(alsa,
3453   [AS_HELP_STRING([--enable-alsa],
3454     [support the Advanced Linux Sound Architecture (default auto)])],, [
3455   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3456     enable_alsa="yes"
3457   ])
3458 ])
3459 have_alsa="no"
3460 AS_IF([test "${enable_alsa}" != "no"], [
3461   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3462     have_alsa="yes"
3463   ], [
3464     AS_IF([test "x${enable_alsa}" != "x"], [
3465       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3466     ])
3467   ])
3468 ])
3469 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3470
3471 dnl
3472 dnl  Open Sound System module
3473 dnl
3474 AC_ARG_ENABLE(oss,
3475   [AS_HELP_STRING([--enable-oss],
3476     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3477   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3478     enable_oss="no"
3479   ])
3480 ])
3481 have_oss="no"
3482 OSS_LIBS=""
3483 AS_IF([test "$enable_oss" != "no"], [
3484   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3485     have_oss="yes"
3486     AC_CHECK_LIB(ossaudio, main, [
3487       OSS_LIBS="-lossaudio"
3488     ])
3489   ])
3490 ])
3491 AC_SUBST(OSS_LIBS)
3492 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3493
3494 dnl
3495 dnl  OpenBSD sndio module
3496 dnl
3497 AC_ARG_ENABLE([sndio],
3498   [AS_HELP_STRING([--disable-sndio],
3499     [support the OpenBSD sndio (default auto)])],, [
3500   AS_IF([test "$SYS" = "openbsd"], [
3501     enable_sndio="yes"
3502   ])
3503 ])
3504 have_sndio="no"
3505 AS_IF([test "$enable_sndio" != "no"], [
3506   AC_CHECK_HEADER([sndio.h], [
3507     have_sndio="yes"
3508   ])
3509 ])
3510 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3511
3512 dnl
3513 dnl  Windows Audio Session plugin
3514 dnl
3515 AC_ARG_ENABLE([wasapi],
3516   [AS_HELP_STRING([--enable-wasapi],
3517     [use the Windows Audio Session API (default auto)])
3518 ])
3519 have_wasapi="no"
3520 AS_IF([test "$enable_wasapi" != "no"], [
3521   AC_CHECK_HEADER([audioclient.h], [
3522     have_wasapi="yes"
3523   ], [
3524     AS_IF([test "x${enable_wasapi}" != "x"], [
3525       AC_MSG_ERROR([Windows Audio Session API not found.])
3526     ])
3527   ])
3528 ])
3529 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3530
3531 dnl
3532 dnl  CoreAudio plugin
3533 dnl
3534 AC_ARG_ENABLE(macosx-audio,
3535   [  --enable-macosx-audio   Mac OS X audio module (default enabled on MacOS X)])
3536 if test "x${enable_macosx_audio}" != "xno" &&
3537   (test "${SYS}" = "darwin" || test "${enable_macosx_audio}" = "yes")
3538 then
3539   AC_CHECK_HEADER([CoreAudio/CoreAudio.h],
3540     [ VLC_ADD_PLUGIN([auhal])
3541     ], [ AC_MSG_ERROR([cannot find CoreAudio headers]) ])
3542 fi
3543
3544 dnl
3545 dnl  iOS CoreAudio plugin
3546 dnl
3547 AC_ARG_ENABLE(ios-audio,
3548   [  --enable-ios-audio       Audio module for iOS (default disabled)])
3549 if test "${enable_ios_audio}" = "yes"
3550 then
3551   AC_CHECK_HEADER([AudioUnit/AudioUnit.h],
3552     [ VLC_ADD_PLUGIN([audiounit_ios])
3553     ], [ AC_MSG_ERROR([cannot find AudioUnit headers]) ])
3554 fi
3555
3556 dnl
3557 dnl  AudioQueue plugin
3558 dnl
3559 AC_ARG_ENABLE(audioqueue,
3560   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3561 if test "${enable_audioqueue}" = "yes"
3562 then
3563   VLC_ADD_PLUGIN([audioqueue])
3564 fi
3565
3566 dnl
3567 dnl  JACK modules
3568 dnl
3569 AC_ARG_ENABLE(jack,
3570   [AS_HELP_STRING([--disable-jack],
3571     [do not use jack (default auto)])])
3572 have_jack="no"
3573 AS_IF([test "${enable_jack}" != "no"], [
3574     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3575       [ have_jack=yes ],
3576       [
3577       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3578
3579       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3580       [ have_jack=yes ],
3581       [
3582       AS_IF([test -n "${enable_jack}"],
3583          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3584          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3585       ])
3586     ])
3587 ])
3588 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3589
3590 dnl
3591 dnl  OpenSLES Android
3592 dnl
3593 AC_ARG_ENABLE(opensles,
3594   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3595 if test "${HAVE_ANDROID}" = "1"; then
3596   if test "${enable_opensles}" = "yes"; then
3597       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3598         [ VLC_ADD_PLUGIN([opensles_android]) ],
3599         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3600   fi
3601 fi
3602
3603 dnl
3604 dnl libsamplerate plugin
3605 dnl
3606 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3607
3608 dnl
3609 dnl  OS/2 KAI plugin
3610 dnl
3611 AC_ARG_ENABLE(kai,
3612   [AS_HELP_STRING([--enable-kai],
3613     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3614   AS_IF([test "$SYS" = "os2"], [
3615     enable_kai="yes"
3616   ])
3617 ])
3618 have_kai="no"
3619 KAI_LIBS=""
3620 AS_IF([test "$enable_kai" != "no"], [
3621   AC_CHECK_HEADERS([kai.h], [
3622     have_kai="yes"
3623     AC_CHECK_LIB(kai, main, [
3624       KAI_LIBS="-lkai"
3625     ])
3626   ])
3627 ])
3628 AC_SUBST(KAI_LIBS)
3629 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3630
3631 dnl
3632 dnl  chromaprint audio track fingerprinter
3633 dnl
3634 m4_pushdef([libchromaprint_version], 0.6.0)
3635 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3636     VLC_ADD_PLUGIN([stream_out_chromaprint])
3637     VLC_ADD_CFLAGS([stream_out_chromaprint],[${CHROMAPRINT_CFLAGS}] [-I./webservices -I../stream_out])
3638     VLC_ADD_LIBS([stream_out_chromaprint],[${CHROMAPRINT_LIBS}]),
3639     AS_IF([test "${enable_chromaprint}" = "yes"],
3640         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3641         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3642          ),
3643     [(Chromaprint based audio fingerprinter)],[auto])
3644 m4_popdef([libchromaprint_version])
3645
3646 dnl
3647 dnl  Interface plugins
3648 dnl
3649
3650 EXTEND_HELP_STRING([Interface plugins:])
3651
3652 dnl
3653 dnl QT
3654 dnl
3655 AC_ARG_ENABLE(qt, [
3656   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3657   AS_IF([test "${SYS}" = "darwin"], [
3658     enable_qt="no"
3659   ])
3660 ])
3661 AS_IF([test "${enable_qt}" != "no"], [
3662   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.1.0 Qt5Widgets Qt5Gui], [
3663       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3664       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3665       AC_PATH_PROG(RCC, [rcc-qt5 rcc], rcc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3666       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3667     ], [
3668       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.6.0],, [
3669         AS_IF([test -n "${enable_qt}"],[
3670           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3671         ],[
3672           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3673         ])
3674         enable_qt="no"
3675       ])
3676       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3677       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3678       AC_PATH_PROG(RCC, rcc, rcc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3679       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3680     ])
3681 ])
3682 AS_IF([test "${enable_qt}" != "no"], [
3683   VLC_ADD_PLUGIN([qt4])
3684   ALIASES="${ALIASES} qvlc"
3685
3686   AC_LANG_PUSH([C++])
3687   VLC_SAVE_FLAGS
3688
3689   AC_MSG_CHECKING([whether Qt uses Xlib])
3690   CPPFLAGS="${CPPFLAGS} ${QT_CFLAGS}"
3691   AC_PREPROC_IFELSE([AC_LANG_SOURCE([
3692 #include <QWidget>
3693 #if !defined (Q_WS_X11)
3694 # error Fail
3695 #endif
3696   ])], [
3697     AC_MSG_RESULT([yes])
3698   ], [
3699     AC_MSG_RESULT([no])
3700   ])
3701
3702   VLC_RESTORE_FLAGS
3703   AC_LANG_POP([C++])
3704
3705 ])
3706 AM_CONDITIONAL(ENABLE_QT4, [test "$enable_qt" != "no"])
3707
3708 dnl
3709 dnl Simple test for skins2 dependency
3710 dnl
3711 AS_IF([test "$enable_qt" = "no"], [
3712   AS_IF([test "${enable_skins2}" = "yes"], [
3713     AC_MSG_ERROR([The skins2 module depends on the Qt4 interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt4 development package or alternatively you can also configure with: --disable-qt4 --disable-skins2.])
3714   ], [
3715     enable_skins2="no"
3716     AC_MSG_WARN([The skins2 module depends on the Qt4 interface, Qt4 is not built so skins2 is disabled.])
3717   ])
3718 ])
3719
3720 dnl
3721 dnl Skins2 module
3722 dnl
3723 AC_ARG_ENABLE(skins2,
3724   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3725 AS_IF([test "${enable_skins2}" != "no"], [
3726   have_skins_deps="yes"
3727
3728   dnl Win32
3729   AS_IF([test "${SYS}" = "mingw32"], [
3730     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3731     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3732   dnl MacOS
3733   ], [test "${SYS}" = "darwin"], [
3734     VLC_ADD_CPPFLAGS([skins2],[ -DMACOSX_SKINS])
3735     VLC_ADD_LIBS([skins2],[-Wl,-framework,Carbon])
3736   dnl OS/2
3737   ], [test "${SYS}" = "os2"], [
3738     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3739   dnl Linux/Unix
3740   ], [
3741     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3742     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3743     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3744     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3745     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3746   ])
3747
3748   dnl for All OSes
3749   VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3750
3751   dnl we need freetype
3752   AS_IF([test "${have_freetype}" != "yes"], [
3753     have_skins_deps="no"
3754   ])
3755
3756   AS_IF([test "${have_skins_deps}" = "no"], [
3757     AS_IF([test "x${enable_skins2}" = "x"], [
3758       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3759     ], [
3760       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3761     ])
3762     enable_skins2="no"
3763   ], [
3764     VLC_ADD_PLUGIN([skins2])
3765     ALIASES="${ALIASES} svlc"
3766     enable_skins2="yes"
3767   ])
3768 ])
3769 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3770
3771 AC_ARG_ENABLE(libtar,
3772   [  --enable-libtar         libtar support for skins2 (default auto)])
3773 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3774   AC_CHECK_HEADERS(libtar.h, [
3775     VLC_ADD_LIBS([skins2],[-ltar])
3776   ])
3777 ])
3778
3779 dnl
3780 dnl  MacOS X gui module
3781 dnl
3782 AC_ARG_ENABLE(macosx,
3783   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3784 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3785 then
3786   VLC_ADD_LIBS([macosx], [-Wl,-framework,Cocoa -Wl,-framework,Carbon -Wl,-framework,CoreServices])
3787   VLC_ADD_OBJCFLAGS([macosx], [-fobjc-exceptions] )
3788   VLC_ADD_PLUGIN([macosx])
3789
3790   VLC_ADD_LIBS([macosx], [-Wl,-framework,QTKit -Wl,-framework,IOKit -Wl,-framework,AddressBook -Wl,-framework,WebKit -Wl,-framework,CoreAudio -Wl,-framework,SystemConfiguration -Wl,-framework,ScriptingBridge])
3791
3792   if test ! -d ${CONTRIB_DIR}/Sparkle.framework
3793   then
3794     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3795   fi
3796   VLC_ADD_LIBS([macosx], [-F${CONTRIB_DIR} -Wl,-framework,Sparkle])
3797   VLC_ADD_OBJCFLAGS([macosx], [-F${CONTRIB_DIR}])
3798
3799   if test ! -d ${CONTRIB_DIR}/BGHUDAppKit.framework
3800   then
3801     AC_MSG_ERROR([BGHUDAppKit framework is required and was not found in ${CONTRIB_DIR}])
3802   fi
3803   VLC_ADD_LIBS([macosx], [-F${CONTRIB_DIR} -Wl,-framework,BGHUDAppKit])
3804   VLC_ADD_OBJCFLAGS([macosx], [-F${CONTRIB_DIR}])
3805 fi
3806 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no"])
3807
3808 dnl
3809 dnl  Minimal Mac OS X module
3810 dnl
3811 AC_ARG_ENABLE(minimal-macosx,
3812   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3813 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3814 then
3815   VLC_ADD_LIBS([minimal_macosx], [-Wl,-framework,Cocoa])
3816   VLC_ADD_OBJCFLAGS([minimal_macosx], [-fobjc-exceptions] )
3817   VLC_ADD_PLUGIN([minimal_macosx])
3818 fi
3819 AM_CONDITIONAL(ENABLE_MINIMAL_MACOSX, [test "$enable_minimal_macosx" != "no"])
3820
3821 dnl
3822 dnl  MacOS X dialog provider
3823 dnl
3824 AC_ARG_ENABLE(macosx-dialog-provider,
3825   [  --enable-macosx-dialog-provider Mac OS X dialog module (default enabled on Mac OS X)])
3826 if test "x${enable_macosx_dialog_provider}" != "xno" &&
3827   (test "${SYS}" = "darwin" || test "${enable_macosx_dialog_provider}" = "yes")
3828 then
3829   VLC_ADD_LIBS([macosx_dialog_provider],[-Wl,-framework,Cocoa])
3830   VLC_ADD_PLUGIN([macosx_dialog_provider])
3831 fi
3832 AM_CONDITIONAL(ENABLE_MACOSX_DIALOG_PROVIDER, [test "$enable_macosx_dialog_provider" != "no"])
3833
3834 dnl
3835 dnl  ncurses module
3836 dnl
3837 AC_ARG_ENABLE(ncurses,
3838 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3839 AS_IF([test "${enable_ncurses}" != "no"] ,[
3840   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3841     VLC_ADD_PLUGIN([ncurses])
3842     VLC_ADD_CFLAGS([ncurses],[${NCURSES_CFLAGS}])
3843     VLC_ADD_LIBS([ncurses],[${NCURSES_LIBS}])
3844     ALIASES="${ALIASES} nvlc"
3845   ], [
3846     AS_IF([test -n "${enable_ncurses}"], [
3847       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3848     ])
3849   ])
3850 ])
3851
3852 dnl
3853 dnl  Lirc plugin
3854 dnl
3855 AC_ARG_ENABLE(lirc,
3856   [  --enable-lirc           lirc support (default disabled)])
3857 if test "${enable_lirc}" = "yes"
3858 then
3859   AC_CHECK_HEADER(lirc/lirc_client.h, AC_CHECK_LIB(lirc_client, lirc_init, have_lirc="true", have_lirc="false"),have_lirc="false")
3860   if test "${have_lirc}" = "true"
3861   then
3862     VLC_ADD_PLUGIN([lirc])
3863     VLC_ADD_LIBS([lirc],[-llirc_client])
3864   fi
3865 fi
3866
3867 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3868 dnl
3869 dnl  goom visualization plugin
3870 dnl
3871 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3872
3873 dnl
3874 dnl libprojectM visualization plugin
3875 dnl
3876 AC_ARG_ENABLE(projectm,
3877   [  --enable-projectm       projectM visualization plugin (default enabled)])
3878 AS_IF([test "${enable_projectm}" != "no"],
3879   [
3880     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3881     [
3882       VLC_ADD_PLUGIN([projectm])
3883       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3884         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3885         [ AC_MSG_WARN( [Using libprojectM version 1] )
3886       ])
3887     ],[
3888       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3889     ])
3890   ])
3891
3892 dnl
3893 dnl Vovoid VSXu visualization plugin
3894 dnl
3895 AC_ARG_ENABLE(vsxu,
3896   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3897 AS_IF([test "${enable_vsxu}" != "no"],
3898   [
3899     PKG_CHECK_MODULES(VSXU, libvsxu,
3900     [
3901       VLC_ADD_PLUGIN([vsxu])
3902       VLC_ADD_CXXFLAGS([vsxu],[$VSXU_CFLAGS])
3903       VLC_ADD_LIBS([vsxu],[$VSXU_LIBS])
3904     ],[
3905       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3906     ])
3907   ])
3908
3909 dnl
3910 dnl  AtmoLight (homemade Philips Ambilight clone)
3911 dnl
3912 AC_ARG_ENABLE(atmo,
3913 AS_HELP_STRING([--disable-atmo],[AtmoLight (homemade Philips Ambilight clone)
3914                 (default enabled)]),, [enable_atmo="yes"])
3915 AS_IF([test "${enable_atmo}" != no], [
3916   AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "linux"], [
3917     AC_LANG_PUSH(C++)
3918     VLC_ADD_PLUGIN([atmo])
3919     AC_LANG_POP(C++)
3920   ])
3921 ])
3922
3923 dnl
3924 dnl  glSpectrum
3925 dnl
3926 AC_ARG_ENABLE(glspectrum,
3927   [  --enable-glspectrum    3D OpenGL spectrum visualization (default auto)])
3928 if test "${enable_glspectrum}" != "no" && test "${have_gl}" = "yes"
3929 then
3930     VLC_ADD_PLUGIN([glspectrum])
3931     VLC_ADD_LIBS([glspectrum],[$GL_LIBS])
3932 fi
3933
3934 EXTEND_HELP_STRING([Service Discovery plugins:])
3935 dnl
3936 dnl  Bonjour services discovery
3937 PKG_ENABLE_MODULES_VLC([BONJOUR], [], [avahi-client >= 0.6], [Bonjour services discovery], [auto])
3938
3939 dnl
3940 dnl  libudev services discovery
3941 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3942
3943 dnl
3944 dnl MTP devices services discovery
3945 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3946
3947 dnl
3948 dnl UPnP Plugin (Intel SDK)
3949 dnl
3950 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3951
3952 EXTEND_HELP_STRING([Misc options:])
3953
3954 dnl
3955 dnl  libxml2 module
3956 dnl
3957 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3958
3959
3960 dnl
3961 dnl libgcrypt
3962 dnl
3963 AC_ARG_ENABLE(libgcrypt,
3964   [  --disable-libgcrypt     gcrypt support (default enabled)])
3965 AS_IF([test "${enable_libgcrypt}" != "no"], [
3966   AC_CHECK_DECL([GCRYCTL_SET_THREAD_CBS], [
3967     libgcrypt-config --version >/dev/null || \
3968         AC_MSG_ERROR([gcrypt.h present but libgcrypt-config could not be found])
3969     AC_CHECK_LIB(gcrypt, gcry_control, [
3970       have_libgcrypt="yes"
3971       GCRYPT_CFLAGS="`libgcrypt-config --cflags`"
3972       GCRYPT_LIBS="`libgcrypt-config --libs`"
3973     ], [
3974       AC_MSG_ERROR([libgcrypt not found. Install libgcrypt or use --disable-libgcrypt. Have a nice day.])
3975     ], [`libgcrypt-config --libs`])
3976   ], [
3977     AC_MSG_ERROR([libgcrypt version 1.1.94 or higher not found. Install libgcrypt or use --disable-libgcrypt. Have a nice day.])
3978   ], [#include <gcrypt.h>]
3979   )
3980 ])
3981
3982 AC_SUBST(GCRYPT_CFLAGS)
3983 AC_SUBST(GCRYPT_LIBS)
3984 AM_CONDITIONAL([HAVE_GCRYPT], [test "${have_libgcrypt}" = "yes"])
3985
3986 dnl
3987 dnl TLS/SSL
3988 dnl
3989 AC_ARG_ENABLE(gnutls,
3990   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
3991 AS_IF([test "${enable_gnutls}" != "no"], [
3992   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.0.20], [
3993     VLC_ADD_PLUGIN([gnutls])
3994   ], [
3995     AS_IF([test -n "${enable_gnutls}"], [
3996       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
3997     ])
3998   ])
3999 ])
4000
4001
4002 dnl
4003 dnl Taglib plugin
4004 dnl
4005 AC_ARG_ENABLE(taglib,
4006   [AS_HELP_STRING([--disable-taglib],
4007     [do not use TagLib (default enabled)])])
4008 AS_IF([test "${enable_taglib}" != "no"], [
4009   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.6.1, [
4010     VLC_ADD_PLUGIN([taglib])
4011   ], [
4012     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4013 ])
4014
4015
4016 dnl
4017 dnl update checking system
4018 dnl
4019 AC_ARG_ENABLE(update-check,
4020   [  --enable-update-check   update checking system (default disabled)])
4021 if test "${enable_update_check}" = "yes"
4022 then
4023   if test "${have_libgcrypt}" != "yes"
4024   then
4025     AC_MSG_ERROR([libgcrypt is required for update checking system])
4026   fi
4027   VLC_ADD_LIBS([libvlccore], [${GCRYPT_LIBS}])
4028   VLC_ADD_CFLAGS([libvlccore], [${GCRYPT_CFLAGS}])
4029   AC_DEFINE([UPDATE_CHECK], 1, [Define if you want to use the VLC update mechanism])
4030 fi
4031
4032 dnl
4033 dnl Growl notification plugin
4034 dnl
4035 AC_ARG_ENABLE(growl,
4036   [  --enable-growl          growl notification plugin (default disabled)],,
4037   [enable_growl=no])
4038 AS_IF([test "${enable_growl}" != "no"], [
4039     AC_CHECK_HEADERS(${CONTRIB_DIR}/Growl.framework/Versions/A/Headers/Growl.h, [
4040       VLC_ADD_PLUGIN([growl])
4041       VLC_ADD_LIBS([growl], [-F${CONTRIB_DIR} -Wl,-framework,Growl,-framework,Foundation])
4042       VLC_ADD_OBJCFLAGS([growl], [-F${CONTRIB_DIR}])
4043       VLC_ADD_OBJCFLAGS([growl], [-fobjc-exceptions] )
4044     ])
4045   ]
4046 )
4047
4048 dnl
4049 dnl Libnotify notification plugin
4050 dnl
4051 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4052
4053 dnl
4054 dnl  Endianness check
4055 dnl
4056 AC_C_BIGENDIAN
4057 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4058   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4059 ], [
4060   DEFS_BIGENDIAN=""
4061 ])
4062 AC_SUBST(DEFS_BIGENDIAN)
4063
4064 dnl
4065 dnl Where to install KDE solid .desktop
4066 dnl
4067 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
4068 AS_IF([test "x$KDE4_CONFIG" = "x"], [
4069   KDE4_CONFIG="kde4-config"
4070 ])
4071
4072 AC_ARG_WITH(kde-solid,
4073   AS_HELP_STRING([--with-kde-solid=PATH],
4074                  [KDE Solid actions directory (auto)]),, [
4075
4076 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4077   with_kde_solid="yes"
4078 fi
4079 ])
4080 soliddatadir=""
4081 AS_IF([test "${with_kde_solid}" != "no"], [
4082   AS_IF([test "${with_kde_solid}" = "yes"], [
4083     kde4datadir="`${KDE4_CONFIG} --install data`"
4084     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4085     soliddatadir="${kde4datadir}/solid/actions"
4086   ], [
4087     soliddatadir="${with_kde_solid}"
4088   ])
4089 ])
4090 AC_SUBST(soliddatadir)
4091 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4092
4093 EXTEND_HELP_STRING([Components:])
4094
4095 dnl
4096 dnl  the VLC binary
4097 dnl
4098 AC_ARG_ENABLE(vlc,
4099   [  --enable-vlc            build the VLC media player (default enabled)])
4100 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4101
4102 AC_ARG_ENABLE(macosx-vlc-app,
4103   [  --enable-macosx-vlc-app build the VLC media player (default enabled on Mac OS X)])
4104 AM_CONDITIONAL(BUILD_MACOSX_VLC_APP, [test "${enable_macosx_vlc_app}" != "no" &&
4105     (test "${SYS}" = "darwin" || test "${enable_macosx_vlc_app}" = "yes") ])
4106
4107 dnl
4108 dnl  Stuff used by the program
4109 dnl
4110 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4111 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4112 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4113 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4114 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4115 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4116 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4117 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4118 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4119 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4120 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4121 AC_SUBST(COPYRIGHT_MESSAGE)
4122 AC_SUBST(VERSION_MESSAGE)
4123 AC_SUBST(VERSION_MAJOR)
4124 AC_SUBST(VERSION_MINOR)
4125 AC_SUBST(VERSION_REVISION)
4126 AC_SUBST(VERSION_EXTRA)
4127 AC_SUBST(COPYRIGHT_YEARS)
4128 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4129 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4130 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4131 dnl
4132 dnl  Handle substvars that use $(top_srcdir)
4133 dnl
4134 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4135
4136 dnl
4137 dnl  Configuration is finished
4138 dnl
4139 AC_SUBST(SYS)
4140 AC_SUBST(ARCH)
4141 AC_SUBST(ALIASES)
4142 AC_SUBST(ASM)
4143 AC_SUBST(MOC)
4144 AC_SUBST(RCC)
4145 AC_SUBST(UIC)
4146 AC_SUBST(WINDRES)
4147 AC_SUBST(WINE_SDK_PATH)
4148 AC_SUBST(LIBEXT)
4149 AC_SUBST(AM_CPPFLAGS)
4150 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4151 AC_SUBST(FILE_LIBVLCCORE_DLL)
4152 AC_SUBST(FILE_LIBVLC_DLL)
4153
4154 AC_CONFIG_FILES([
4155   Makefile
4156   doc/Makefile
4157   modules/Makefile
4158   m4/Makefile
4159   po/Makefile.in
4160   share/Makefile
4161   compat/Makefile
4162   src/Makefile
4163   lib/Makefile
4164   bin/Makefile
4165   test/Makefile
4166   modules/access_output/Makefile
4167   modules/audio_filter/Makefile
4168   modules/control/Makefile
4169   modules/gui/Makefile
4170   modules/gui/macosx/Makefile
4171   modules/gui/minimal_macosx/Makefile
4172   modules/gui/macosx_dialog_provider/Makefile
4173   modules/gui/qt4/Makefile
4174   modules/gui/skins2/Makefile
4175   modules/misc/Makefile
4176   modules/mux/Makefile
4177   modules/packetizer/Makefile
4178   modules/stream_out/Makefile
4179   modules/text_renderer/Makefile
4180   modules/video_filter/Makefile
4181   modules/video_output/Makefile
4182   modules/visualization/Makefile
4183   modules/hw/vdpau/Makefile
4184 ])
4185
4186 AM_COND_IF([HAVE_WIN32], [
4187   AC_CONFIG_FILES([
4188     extras/package/win32/NSIS/spad.nsi
4189     extras/package/win32/NSIS/vlc.win32.nsi
4190     extras/package/win32/msi/config.wxi
4191   ])
4192 ])
4193
4194 AM_COND_IF([HAVE_DARWIN], [
4195   AC_CONFIG_FILES([
4196     extras/package/macosx/Info.plist
4197     extras/package/macosx/Resources/English.lproj/InfoPlist.strings
4198   ])
4199 ])
4200
4201 dnl Generate makefiles
4202 AC_OUTPUT
4203
4204 dnl Do we have to use make or gmake ?
4205 if make --version 2>&1|grep -q GNU
4206 then
4207     # GNU make, all seems good
4208     MAKE=make
4209 else
4210     # Known GNU make alias (on BSD)
4211     MAKE=gmake
4212 fi
4213 dnl Shortcut to nice compile message
4214 if test -n $SHELL; then
4215   SHELL=${CONFIG_SHELL-/bin/sh}
4216 fi
4217 rm -f compile
4218 echo "#! $SHELL
4219 rm -f .error\$\$
4220 ERROR=0
4221 export PATH=\"$PATH\" LANG=C
4222 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| `sed -ne \"s/^top_srcdir *= *//p\" < Makefile`/extras/buildsystem/make.pl
4223 test -f .error\$\$ && ERROR=1
4224 rm -f .error\$\$
4225 exit \$ERROR" >compile
4226 chmod a+x compile
4227
4228 echo "
4229 libvlc configuration
4230 --------------------
4231 version               : ${VERSION}
4232 system                : ${SYS}
4233 architecture          : ${ARCH}
4234 optimizations         : ${enable_optimizations}"
4235 if test "${enable_vlc}" != "no"; then
4236 echo "vlc aliases           :${ALIASES}"
4237 else
4238 echo "build vlc executable  : no"
4239 fi
4240 echo "
4241 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."