configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 1999-2017 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 4.0.0-git)
   6 VERSION_MAJOR=4
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=git
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Otto Chriek"
  17 COPYRIGHT_YEARS="1996-2017"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 AM_SILENT_RULES([yes])
  31 AM_MAINTAINER_MODE([enable])
  32
  33 dnl
  34 dnl Directories
  35 dnl
  36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  37 dnl AC_SUBST(vlcincludedir)
  38 vlcdatadir="\${datadir}/\${PKGDIR}"
  39 AC_SUBST(vlcdatadir)
  40 vlclibdir="\${libdir}/\${PKGDIR}"
  41 AC_SUBST(vlclibdir)
  42
  43 dnl
  44 dnl Check for tools
  45 dnl
  46 AC_PROG_CC
  47 AC_USE_SYSTEM_EXTENSIONS
  48 VLC_PROG_CC_C11
  49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  51 AH_TOP([
  52 #ifndef _REENTRANT
  53 # define _REENTRANT
  54 #endif
  55 ])
  56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  59
  60 AM_PROG_CC_C_O
  61 AC_PROG_CXX
  62 AC_PROG_CPP
  63 AC_PROG_OBJC
  64 AC_PROG_EGREP
  65 AC_PROG_MAKE_SET
  66 AC_PROG_INSTALL
  67 AM_PROG_AS
  68 AC_PROG_LEX
  69 AC_PROG_YACC
  70
  71 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  72 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  73 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
  74 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
  75 AS_IF([test "$BUILDCC" = "false"], [
  76   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
  77 ])
  78
  79 dnl Check for compiler properties
  80 AC_C_CONST
  81 AC_C_INLINE
  82 AC_C_RESTRICT
  83 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
  84
  85 dnl Extend the --help string at the current spot.
  86 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  87
  88 dnl Allow binary package maintainer to pass a custom string to avoid
  89 dnl cache problem
  90 AC_ARG_WITH(binary-version,
  91     AS_HELP_STRING([--with-binary-version=STRING],
  92          [To avoid plugins cache problem between binary version]),[],[])
  93 AS_IF([test -n "${with_binary_version}"],[
  94     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  95          [Binary specific version])
  96 ])
  97
  98 dnl Prevent clang from accepting unknown flags with a mere warning
  99 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CFLAGS])
 100 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CXXFLAGS])
 101
 102 dnl
 103 dnl  Check the operating system
 104 dnl
 105 HAVE_WIN64="0"
 106 HAVE_IOS="0"
 107 HAVE_OSX="0"
 108 HAVE_TVOS="0"
 109
 110 case "${host_os}" in
 111   "")
 112     SYS=unknown
 113     ;;
 114   linux*)
 115     SYS=linux
 116     ;;
 117   bsdi*)
 118     SYS=bsdi
 119     CFLAGS="${CFLAGS} -pthread"
 120     ;;
 121   freebsd*)
 122     SYS=freebsd
 123     CFLAGS="${CFLAGS} -pthread"
 124     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 125     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 126     ac_cv_ld_z_defs=no
 127     ;;
 128   openbsd*)
 129     SYS=openbsd
 130     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 131     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 132     ;;
 133   netbsd*)
 134     SYS=netbsd
 135     ;;
 136   dragonfly*)
 137     SYS=dragonfly
 138     ;;
 139   darwin*)
 140
 141     dnl Force gcc "-arch" flag
 142     ARCH_flag=""
 143     case "${host}" in
 144       i?86*)
 145         ARCH_flag="-arch i386"
 146       ;;
 147       ppc64*)
 148         ARCH_flag="-arch ppc64"
 149       ;;
 150       ppc*)
 151         ARCH_flag="-arch ppc"
 152       ;;
 153       x86_64*)
 154         ARCH_flag="-arch x86_64"
 155       ;;
 156       arm*)
 157         ac_cv_c_bigendian="no"
 158         ac_cv_c_attribute_packed="no"
 159       ;;
 160     esac
 161
 162     SYS=darwin
 163     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 164     CXX="${CXX} -stdlib=libc++ -std=c++11"
 165     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 166     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 167     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
 168     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 169     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 170     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 171
 172     AC_EGREP_CPP(yes,
 173             [#import <TargetConditionals.h>
 174              #if TARGET_OS_IPHONE
 175              yes
 176              #endif],
 177              [HAVE_IOS="1"],
 178              [HAVE_OSX="1"])
 179
 180     AC_EGREP_CPP(yes,
 181             [#import <TargetConditionals.h>
 182              #if TARGET_OS_TV
 183              yes
 184              #endif],
 185              [HAVE_TVOS="1"
 186              HAVE_IOS="0"
 187              HAVE_OSX="0"
 188              ],)
 189
 190     dnl Allow binaries created on Lion to run on earlier releases
 191     AC_EGREP_CPP(yes,
 192            [#import <Cocoa/Cocoa.h>
 193             #ifdef MAC_OS_X_VERSION_10_7
 194             yes
 195             #endif],
 196             [AC_MSG_RESULT([yes])
 197             AC_LIBOBJ([getdelim])
 198             AC_LIBOBJ([strndup])
 199             AC_LIBOBJ([strnlen])],)
 200
 201     dnl
 202     dnl  Handle Mac OS X SDK flags
 203     dnl
 204     AC_ARG_WITH(macosx-sdk,
 205       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 206         [compile using the SDK in DIR])])
 207     if test "${with_macosx_sdk}" != "" ; then
 208         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 209         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 210         CC="${CC} -isysroot ${with_macosx_sdk}"
 211         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 212         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 213         LD="${LD} -syslibroot ${with_macosx_sdk}"
 214     fi
 215     AC_ARG_WITH(macosx-version-min,
 216       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 217         [compile for Mac OS X VERSION and above])])
 218     if test "${with_macosx_version_min}" != "" ; then
 219         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 220         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 221         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 222         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 223         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 224     fi
 225     ;;
 226   *mingw32* | *cygwin* | *wince* | *mingwce*)
 227     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
 228     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
 229     CXXFLAGS="${CXXFLAGS} -static-libgcc"
 230     AC_CHECK_TOOL(WINDRES, windres, :)
 231     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 232     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
 233     AH_TOP([# define _WIN32_WINNT 0x0601 /* Windows 7 */])
 234     AH_TOP([#endif])
 235     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 236     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 237     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 238     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 239     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 240     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 241     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 242     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 243     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 244     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 245     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 246
 247     case "${host_os}" in
 248       *mingw32*)
 249         SYS=mingw32
 250         ;;
 251       *cygwin*)
 252         dnl Check if we are using the mno-cygwin mode in which case we are
 253         dnl actually dealing with a mingw32 compiler.
 254         AC_EGREP_CPP(yes,
 255             [#ifdef _WIN32
 256              yes
 257              #endif],
 258             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 259         ;;
 260     esac
 261
 262     if test "${SYS}" = "mingw32"; then
 263         # DEP, ASLR, NO SEH
 264         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 265
 266         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 267         ac_default_prefix="`pwd`/_win32"
 268         DESTDIR="`pwd`/_win32/"
 269
 270         dnl
 271         dnl NSIS/MSI Installer prefix and WIN64
 272         dnl
 273         case "${host}" in
 274             amd64*|x86_64*)
 275                 HAVE_WIN64="1"
 276                 WINDOWS_ARCH="x64"
 277                 PROGRAMFILES="PROGRAMFILES64"
 278                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
 279             ;;
 280             *)
 281                 WINDOWS_ARCH="x86"
 282                 PROGRAMFILES="PROGRAMFILES"
 283             ;;
 284         esac
 285         AC_SUBST(WINDOWS_ARCH)
 286         AC_SUBST(PROGRAMFILES)
 287
 288     fi
 289     ;;
 290   *nto*)
 291     SYS=nto
 292     ;;
 293   solaris*)
 294     SYS=solaris
 295     ;;
 296   hpux*)
 297     SYS=hpux
 298     ;;
 299   *os2*)
 300     SYS=os2
 301     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 302     AC_LIBOBJ([freeaddrinfo])
 303     AC_LIBOBJ([gai_strerror])
 304     ;;
 305   *nacl*)
 306     SYS=nacl
 307     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 308     AC_LIBOBJ([sigwait])
 309     AC_LIBOBJ([recvmsg])
 310     AC_LIBOBJ([sendmsg])
 311     ;;
 312   *)
 313     SYS="${host_os}"
 314     ;;
 315 esac
 316
 317 dnl WinRT
 318 AC_ARG_ENABLE(winstore_app,
 319      AS_HELP_STRING([--enable-winstore-app],
 320                     [Build targetted for Windows Store apps (default disabled)]))
 321
 322 vlc_winstore_app=0
 323 AS_IF([test "${SYS}" = "mingw32"],[
 324   LIBCOM="-lole32"
 325   AS_IF([test "${enable_winstore_app}" = "yes"], [
 326     vlc_winstore_app=1
 327     LIBCOM=""
 328      VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
 329      AC_LIBOBJ([gai_strerror])
 330     ],[])
 331   AC_SUBST(LIBCOM)
 332   ])
 333 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 334
 335 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 336 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 337
 338 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 339 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
 340 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
 341 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
 342
 343 AM_CONDITIONAL(HAVE_NACL,    test "${SYS}" = "nacl")
 344
 345 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 346 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
 347 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 348 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
 349
 350 dnl
 351 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 352 dnl for program foo on win32
 353 case "${build_os}" in
 354     cygwin|msys|mingw32)
 355         ac_executable_extensions=".exe"
 356         BUILDEXEEXT=".exe"
 357     ;;
 358     os2*)
 359         BUILDEXEEXT=".exe"
 360     ;;
 361     *)
 362     ;;
 363 esac
 364 AC_SUBST(BUILDEXEEXT)
 365
 366 dnl Android is linux, but a bit different
 367 AS_IF([test "$SYS" = linux],[
 368     AC_MSG_CHECKING([for an Android system])
 369     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 370         [[#ifndef __ANDROID__
 371          # error Not Android
 372          #endif
 373         ]],[[;]])
 374     ],[
 375       HAVE_ANDROID="1"
 376       AC_MSG_RESULT([yes])
 377     ],[
 378       AC_MSG_RESULT([no])
 379     ])
 380 ])
 381 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 382
 383 dnl Tizen (minimum SDK version: 2.3)
 384 AS_IF([test "$SYS" = linux],[
 385     AC_MSG_CHECKING([for Tizen])
 386     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 387         [[#include <tizen.h>
 388         ]],[[;]])
 389     ],[
 390       HAVE_TIZEN="1"
 391       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
 392       AC_MSG_RESULT([yes])
 393     ],[
 394       AC_MSG_RESULT([no])
 395     ])
 396 ])
 397 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
 398
 399 dnl
 400 dnl  Check for the contrib directory
 401 dnl
 402 AC_ARG_WITH(contrib,
 403   [AS_HELP_STRING([--with-contrib[=DIR]],
 404     [search for 3rd party libraries in DIR/include and DIR/lib])
 405 ])
 406 AC_MSG_CHECKING([for 3rd party libraries path])
 407 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 408   CONTRIB_DIR="${srcdir}/contrib/${host}"
 409   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 410     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 411     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 412     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 413       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 414       CONTRIB_DIR=""
 415       AC_MSG_RESULT([not found])
 416     ])
 417   ])
 418 ], [
 419   AS_IF([test "${with_contrib}" != "no"], [
 420     CONTRIB_DIR="${with_contrib}"
 421   ], [
 422     CONTRIB_DIR=""
 423     AC_MSG_RESULT([disabled])
 424   ])
 425 ])
 426 AS_IF([test -n "${CONTRIB_DIR}"], [
 427   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 428     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 429   ], [
 430     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 431     CONTRIB_DIR=""
 432     AC_MSG_RESULT([not usable])
 433   ])
 434
 435 ])
 436 AS_IF([test -n "${CONTRIB_DIR}"], [
 437   AC_MSG_RESULT([${CONTRIB_DIR}])
 438   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 439   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 440   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 441   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
 442   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 443   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 444
 445   AS_IF([test -z "$LUAC"], [
 446     dnl Old contribs mixed cross-tools and cross-compiled executables
 447     AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
 448       LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
 449     ])
 450
 451     dnl Newer contribs follow usual name space rules
 452     AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
 453       LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
 454     ])
 455   ])
 456
 457   AS_IF([test "${SYS}" = "darwin"], [
 458     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 459     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 460   ])
 461 ], [
 462   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 463     AC_MSG_ERROR([Third party libraries not found!])
 464   ])
 465 ])
 466 AC_SUBST(CONTRIB_DIR)
 467
 468 dnl Add extras/tools to the PATH
 469 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 470 AS_IF([test -d "${TOOLS_DIR}"], [
 471     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 472     export PATH="${TOOLS_DIR}":$PATH
 473 ])
 474
 475 dnl
 476 dnl  Libtool
 477 dnl  It's very bad, but our former custom system was worst
 478 dnl  -- Courmisch
 479 dnl
 480
 481 dnl override platform specific check for dependent libraries
 482 dnl otherwise libtool linking of shared libraries will
 483 dnl fail on anything other than pass_all.
 484 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 485     [lt_cv_deplibs_check_method=pass_all])
 486
 487 LT_INIT([dlopen win32-dll shared disable-static])
 488 LT_LANG([C++])
 489 LT_LANG([Windows Resource])
 490
 491 DOLT
 492
 493 lt_cv_deplibs_check_method=pass_all
 494
 495 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 496   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 497 ])
 498
 499 dnl
 500 dnl Gettext stuff
 501 dnl
 502 AM_GNU_GETTEXT_VERSION([0.19.8])
 503 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 504
 505 dnl
 506 dnl Iconv stuff
 507 dnl
 508 AM_ICONV
 509
 510 dnl
 511 dnl checks for mingw
 512 AS_IF([test "${SYS}" = "mingw32"], [
 513
 514 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 515 #if !defined(__MINGW32__)
 516 # error Not compiling with mingw
 517 #endif
 518     ])], [
 519
 520 dnl Check for broken versions of mingw-runtime compatability library
 521     AC_MSG_CHECKING(for broken mingw-runtime)
 522     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 523 #include <_mingw.h>
 524 #if defined(__MINGW64_VERSION_MAJOR)
 525 # if __MINGW64_VERSION_MAJOR < 3
 526 #  error Attempting to use mingw-runtime with broken vsnprintf support
 527 # endif
 528 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
 529 # error Attempting to use mingw-runtime with broken vsnprintf support
 530 #endif
 531     ])], [
 532         AC_MSG_RESULT([ok])
 533     ], [
 534         AC_MSG_RESULT([present])
 535         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
 536     ])
 537
 538     dnl force use of mingw provided c99 *printf over msvcrt
 539     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 540
 541     dnl Check for the need to include the mingwex lib for mingw32
 542     VLC_SAVE_FLAGS
 543     AC_CHECK_LIB(mingwex,opendir,
 544         AC_CHECK_LIB(mingw32,opendir,,
 545             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 546     )
 547     VLC_RESTORE_FLAGS
 548     ], [
 549         AC_MSG_RESULT([Not compiling with mingw])
 550     ])
 551
 552     dnl Check for fnative-struct or mms-bitfields support for mingw32
 553     VLC_SAVE_FLAGS
 554     CFLAGS="${CFLAGS} -mms-bitfields"
 555     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
 556     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 557         [ac_cv_c_mms_bitfields],
 558         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 559     if test "${ac_cv_c_mms_bitfields}" = "no"; then
 560         VLC_RESTORE_FLAGS
 561         CFLAGS="${CFLAGS} -fnative-struct"
 562         CXXFLAGS="${CXXFLAGS} -fnative-struct"
 563         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 564             [ac_cv_c_fnative_struct],
 565             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 566         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
 567     fi
 568 ])
 569
 570
 571 dnl
 572 dnl Buggy glibc prevention. Purposedly not cached.
 573 dnl See sourceware.org bugs 5058 and 5443.
 574 dnl Ubuntu alone has 20 bug numbers for this...
 575 dnl
 576 AC_MSG_CHECKING(for buggy GNU/libc versions)
 577 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 578 #include <limits.h>
 579 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 580   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 581 # error GNU/libc with dcgettext killer bug!
 582 #endif
 583 ])], [
 584   AC_MSG_RESULT([not present])
 585 ], [
 586   AC_MSG_RESULT([found])
 587   AS_IF([test "x${enable_nls}" != "xno"], [
 588     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 589 work-around for this. Check with your distribution vendor on how to update the
 590 glibc run-time. Alternatively, build with --disable-nls.])
 591   ])
 592 ])
 593
 594 dnl Plugin compilation stuff
 595
 596 VLC_LIBRARY_SUFFIX
 597
 598 dnl Check for system libs needed
 599 need_libc=false
 600
 601 dnl Check for usual libc functions
 602 AC_CHECK_FUNCS([daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp strptime tdestroy uselocale])
 603 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv memrchr nrand48 poll recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tfind timegm timespec_get strverscmp pathconf])
 604 AC_REPLACE_FUNCS([gettimeofday])
 605 AC_CHECK_FUNC(fdatasync,,
 606   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 607 ])
 608
 609 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
 610
 611 dnl mingw64 implements those as static inline, not functions with C linkage
 612 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
 613 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
 614 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
 615 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
 616
 617 dnl C11 static_assert()
 618 AC_MSG_CHECKING([for static_assert in assert.h])
 619 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 620 static_assert(1, "The impossible happened.");
 621 ])], [
 622   AC_MSG_RESULT([yes])
 623   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 624 ], [
 625   AC_MSG_RESULT([no])
 626 ])
 627
 628 # Windows CE does not have strcoll()
 629 AC_FUNC_STRCOLL
 630
 631 dnl Check for non-standard system calls
 632 case "$SYS" in
 633   "linux")
 634     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity recvmmsg])
 635     ;;
 636   "mingw32")
 637     AC_CHECK_FUNCS([_lock_file])
 638     ;;
 639 esac
 640
 641 AH_BOTTOM([#include <vlc_fixups.h>])
 642
 643 dnl Check for struct pollfd
 644 AC_CHECK_TYPES([struct pollfd],,,
 645 [#include <sys/types.h>
 646 #if HAVE_POLL
 647 # include <poll.h>
 648 #elif defined (_WIN32)
 649 # include <winsock2.h>
 650 #endif
 651 ])
 652
 653 dnl Check for struct timespec
 654 AC_CHECK_TYPES([struct timespec],,,
 655 [#include <time.h>])
 656
 657 dnl Check for max_align_t
 658 AC_CHECK_TYPES([max_align_t],,,
 659 [#include <stddef.h>])
 660
 661 dnl Checks for socket stuff
 662 VLC_SAVE_FLAGS
 663 SOCKET_LIBS=""
 664 AC_SEARCH_LIBS(connect, [socket], [
 665   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 666     SOCKET_LIBS="$ac_cv_search_connect"
 667   ])
 668 ], [
 669   AS_IF([test "${SYS}" = "mingw32"], [
 670     SOCKET_LIBS="-lws2_32"
 671   ])
 672 ])
 673
 674 AC_SEARCH_LIBS([inet_pton], [nsl], [
 675  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
 676     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
 677   ])
 678 ],, [${SOCKET_LIBS}])
 679
 680 LIBS="${LIBS} ${SOCKET_LIBS}"
 681 AC_LINK_IFELSE([
 682     AC_LANG_PROGRAM([#ifdef _WIN32
 683         # if _WIN32_WINNT < 0x600
 684         #  error Needs vista+
 685         # endif
 686         #include <ws2tcpip.h>
 687         #else
 688         #include <sys/socket.h>
 689         #include <arpa/inet.h>
 690         #endif], [
 691         char dst[[sizeof(struct in_addr)]];
 692         inet_pton(AF_INET, "127.0.0.1", dst);
 693     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 694 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
 695 VLC_RESTORE_FLAGS
 696 AC_SUBST(SOCKET_LIBS)
 697
 698 dnl Check for socklen_t
 699 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 700 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 701 ac_cv_type_socklen_t,
 702 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 703 [#include <sys/types.h>
 704 #ifdef _WIN32
 705 # include <winsock2.h>
 706 # include <ws2tcpip.h>
 707 #else
 708 # include <sys/socket.h>
 709 #endif]], [[socklen_t len; len = 0;]])],
 710 ac_cv_type_socklen_t=yes,
 711 ac_cv_type_socklen_t=no)])
 712 AS_IF([test "$ac_cv_type_socklen_t" = no],
 713  [AC_DEFINE(socklen_t, int)])
 714
 715 dnl Check for struct sockaddr_storage
 716 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 717 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 718 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 719   [AC_TRY_COMPILE(
 720     [#include <sys/types.h>
 721      #if defined( _WIN32 )
 722      # include <winsock2.h>
 723      #else
 724      # include <sys/socket.h>
 725      #endif], [struct sockaddr_storage addr;],
 726      ac_cv_struct_sockaddr_storage=yes,
 727      ac_cv_struct_sockaddr_storage=no)])
 728 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 729   AC_DEFINE(sockaddr_storage, sockaddr)
 730   AC_DEFINE(ss_family, sa_family)
 731 ])
 732
 733 dnl FreeBSD has a gnugetopt library for this:
 734 GNUGETOPT_LIBS=""
 735 AC_CHECK_FUNC(getopt_long,, [
 736   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 737     GNUGETOPT_LIBS="-lgnugetopt"
 738   ])
 739 ])
 740 AC_SUBST(GNUGETOPT_LIBS)
 741
 742 AC_CHECK_LIB(m,cos,[
 743   LIBM="-lm"
 744 ], [
 745   LIBM=""
 746 ])
 747 AC_SUBST(LIBM)
 748
 749 AC_CHECK_LIB(m,lrintf, [
 750   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 751   VLC_ADD_LIBS([skins2],[-lm])
 752 ])
 753 AC_CHECK_LIB(m,nanf,
 754   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 755 )
 756 AC_CHECK_LIB(m,sincos, [
 757   AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
 758 ], [
 759   AC_LIBOBJ([sincos])
 760 ])
 761
 762 AC_MSG_CHECKING([_Thread_local support])
 763 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
 764                    int main() {}])], [
 765     AC_MSG_RESULT([ok])
 766     AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
 767 ],[ AC_MSG_RESULT([no])])
 768
 769 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
 770 dnl check for its availability explicitely
 771 AC_CHECK_HEADERS([threads.h])
 772
 773 dnl Check for dynamic plugins
 774 LIBDL=""
 775 have_dynamic_objects="no"
 776 VLC_SAVE_FLAGS
 777 AC_SEARCH_LIBS(dlsym, [dl svld], [
 778   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 779     LIBDL="$ac_cv_search_dlsym"
 780   ])
 781   have_dynamic_objects="yes"
 782 ])
 783 VLC_RESTORE_FLAGS
 784
 785 # Windows
 786 AS_IF([test "${SYS}" = "mingw32"], [
 787   LIBDL=""
 788   have_dynamic_objects="yes" #assume we can use shared objects
 789 ])
 790
 791 AC_ARG_WITH([libfuzzer],
 792     [AS_HELP_STRING([--with-libfuzzer=DIR],
 793         [use libFuzzer library from DIR and triggers sanitize coverage (default disabled)])],
 794      [],
 795      [with_libfuzzer=no])
 796 AS_VAR_IF(with_libfuzzer, no, [], [
 797     enable_shared=no
 798     enable_static=yes
 799     enable_vlc=no
 800 ])
 801 AM_CONDITIONAL(HAVE_LIBFUZZER, [test "${with_libfuzzer}" != "no"])
 802
 803 AS_IF([test "${enable_shared}" = "no"], [
 804   have_dynamic_objects=no
 805 ])
 806 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 807
 808 AC_SUBST(LIBDL)
 809
 810 dnl Check for thread library
 811 LIBPTHREAD=""
 812 AS_IF([test "${SYS}" != "mingw32"], [
 813   VLC_SAVE_FLAGS
 814   LIBS=""
 815   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 816     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 817       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 818     ])
 819   ])
 820   VLC_RESTORE_FLAGS
 821 ])
 822 AC_SUBST(LIBPTHREAD)
 823
 824 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
 825   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
 826     LIBRT="$ac_cv_search_clock_nanosleep"
 827   ])
 828 ], [
 829   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
 830     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
 831       LIBRT="$ac_cv_search_nanosleep"
 832     ])
 833   ])
 834 ])
 835 AC_SUBST(LIBRT)
 836
 837 dnl
 838 dnl Check for headers
 839 dnl
 840
 841 dnl  POSIX
 842 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
 843 AC_CHECK_HEADERS([net/if.h], [], [],
 844 [
 845 #include <sys/types.h>
 846 #include <sys/socket.h>
 847 ])
 848 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
 849 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
 850
 851 dnl  BSD
 852 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
 853
 854 dnl  GNU/Linux
 855 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 856
 857 dnl  MacOS
 858 AC_CHECK_HEADERS([xlocale.h])
 859
 860 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 861 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 862 AC_CHECK_TYPE(ssize_t,, [
 863   AC_DEFINE(ssize_t, int)
 864 ])
 865
 866 dnl It seems that autoconf detects pkg-config only during the first
 867 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 868 dnl it is nested within a conditional block, so it was not working right.
 869 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 870 AC_ARG_VAR(PKG_CONFIG_PATH,
 871        [Paths where to find .pc not at the default location])
 872 PKG_PROG_PKG_CONFIG()
 873
 874 dnl On some OS we need static linking
 875 AS_IF([test -n "${PKG_CONFIG}" ],[
 876     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 877         PKG_CONFIG="${PKG_CONFIG} --static"
 878     ])
 879 ])
 880
 881
 882 dnl
 883 dnl Check for zlib.h and -lz along with system -lminizip if available
 884 dnl
 885 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 886 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 887 if test "${have_zlib}" = "yes"
 888 then
 889   VLC_ADD_LIBS([sap],[-lz])
 890   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 891     AC_CHECK_HEADERS([unzip.h], [
 892       have_minizip=yes
 893       MINIZIP_LIBS="-lminizip -lz"
 894     ], [
 895       have_minizip=no
 896     ])
 897   ])
 898 fi
 899 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 900
 901
 902 dnl
 903 dnl Domain name i18n support via GNU libidn
 904 dnl
 905 PKG_CHECK_MODULES([IDN], [libidn], [
 906   have_libidn="yes"
 907   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 908 ], [
 909   have_libidn="no"
 910 ])
 911
 912
 913 dnl Check for dbus
 914 AC_ARG_ENABLE(dbus,
 915   [AS_HELP_STRING([--enable-dbus],
 916     [compile D-Bus message bus support (default enabled)])])
 917 have_dbus="no"
 918 AS_IF([test "${enable_dbus}" != "no"], [
 919   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 920     have_dbus="yes"
 921   ], [
 922     AS_IF([test -n "${enable_dbus}"], [
 923       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 924     ], [
 925       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 926     ])
 927   ])
 928 ])
 929 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 930
 931
 932 dnl Check for systemd
 933 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
 934   have_systemd="yes"
 935 ], [
 936   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
 937 ])
 938 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
 939
 940
 941 EXTEND_HELP_STRING([Optimization options:])
 942 dnl
 943 dnl  Compiler warnings
 944 dnl
 945
 946 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CFLAGS])
 947 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CXXFLAGS])
 948
 949 AX_APPEND_COMPILE_FLAGS([-Wbad-function-cast -Wwrite-strings -Wmissing-prototypes -Werror-implicit-function-declaration -Winit-self -Wlogical-op -Wshadow=local], [CFLAGS])
 950 AX_APPEND_COMPILE_FLAGS([-pipe], [CFLAGS])
 951
 952 dnl
 953 dnl  Debugging mode
 954 dnl
 955 AC_ARG_ENABLE(debug,
 956   [AS_HELP_STRING([--enable-debug],
 957     [build with run-time assertions (default disabled)])],,
 958   [enable_debug="no"])
 959 AH_TEMPLATE(NDEBUG,
 960             [Define to 1 if debug code should NOT be compiled])
 961 AS_IF([test "${enable_debug}" != "no"], [
 962   AC_CHECK_HEADERS([valgrind/valgrind.h])
 963 ], [
 964   AC_DEFINE(NDEBUG)
 965 ])
 966
 967 dnl
 968 dnl  Profiling
 969 dnl
 970 AC_ARG_ENABLE(gprof,
 971   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 972   [enable_gprof="no"])
 973 AS_IF([test "${enable_gprof}" != "no"], [
 974   CFLAGS="${CFLAGS} -pg"
 975   CXXFLAGS="${CXXFLAGS} -pg"
 976   OBJCFLAGS="${OBJCFLAGS} -pg"
 977   LDFLAGS="${LDFLAGS} -pg"
 978 ])
 979
 980 AC_ARG_ENABLE(cprof,
 981   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 982   [enable_cprof="no"])
 983 AS_IF([test "${enable_gprof}" != "no"], [
 984   CFLAGS="${CFLAGS} -finstrument-functions"
 985   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 986   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 987   LDFLAGS="${LDFLAGS} -finstrument-functions"
 988 ])
 989
 990 dnl
 991 dnl  Test coverage
 992 dnl
 993 AC_ARG_ENABLE(coverage,
 994   [AS_HELP_STRING([--enable-coverage],
 995     [build for test coverage (default disabled)])],,
 996   [enable_coverage="no"])
 997 AS_IF([test "${enable_coverage}" != "no"], [
 998   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 999   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
1000   LDFLAGS="-lgcov ${LDFLAGS}"
1001 ])
1002
1003 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
1004   VLC_SAVE_FLAGS
1005   CFLAGS="${CFLAGS} -fvisibility=hidden"
1006   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
1007   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
1008   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
1009                  [ac_cv_c_visibility_hidden], [
1010     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1011       ac_cv_c_visibility_hidden=yes
1012     ], [
1013       ac_cv_c_visibility_hidden=no
1014     ])
1015   ])
1016   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1017 ])
1018
1019 dnl
1020 dnl Sanitizer flags
1021 dnl
1022 AC_ARG_WITH([sanitizer],
1023     [AS_HELP_STRING([--with-sanitizer=(address/memory/undefined/thread)],
1024         [build with sanitizer flags (default disabled)])],
1025      [],
1026      [with_sanitizer=no])
1027
1028 AS_VAR_IF(with_sanitizer, no, [], [
1029     AX_CHECK_COMPILE_FLAG([-fsanitize=${with_sanitizer}], [
1030         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}])
1031         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [CXXFLAGS])
1032         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [LDFLAGS])
1033     ], [
1034         AC_MSG_ERROR(["-fsanitize=${with_sanitizer} not supported!"])
1035     ])
1036     AX_APPEND_FLAG([-g])
1037     AX_APPEND_FLAG([-g], [CXXFLAGS])
1038
1039     AS_IF([test -z "${with_sanitizer##*address*}" ], [
1040        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer])
1041        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer], [CXXFLAGS])
1042     ])
1043     AS_IF([test -z "${with_sanitizer##*memory*}" ], [
1044         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1045         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1046     ])
1047     AS_IF([test -z "${with_sanitizer##*thread*}" ], [
1048         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1049         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1050     ])
1051 ])
1052
1053 dnl
1054 dnl  Enable/disable optimizations
1055 dnl
1056 AC_ARG_ENABLE(optimizations,
1057   [AS_HELP_STRING([--disable-optimizations],
1058     [disable compiler optimizations (default enabled)])],,
1059   [enable_optimizations="yes"])
1060
1061 dnl Check for various optimization flags
1062 AS_IF([test "${enable_optimizations}" != "no"], [
1063
1064   dnl -O3 only in production builds
1065   AS_IF([test "${enable_debug}" = "no"], [
1066     VLC_SAVE_FLAGS
1067     CFLAGS="${CFLAGS} -O3"
1068     CXXFLAGS="${CXXFLAGS} -O3"
1069     OBJCFLAGS="${OBJCFLAGS} -O3"
1070     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1071       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1072         ac_cv_c_o3=yes
1073       ], [
1074         ac_cv_c_o3=no
1075       ])
1076     ])
1077     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1078   ])
1079
1080   dnl Check for fast maths
1081   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CFLAGS])
1082   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CXXFLAGS])
1083
1084 AH_BOTTOM([
1085 #if defined(_MSC_VER) && !defined(__clang__)
1086 # pragma fenv_access(off)
1087 # pragma fp_contract(on)
1088 #elif defined(__GNUC__)
1089 /* Not supported so far */
1090 #else
1091 # pragma STDC FENV_ACCESS OFF
1092 # pragma STDC FP_CONTRACT ON
1093 #endif
1094 ])
1095
1096   dnl Check for -funroll-loops
1097   VLC_SAVE_FLAGS
1098   CFLAGS="${CFLAGS} -funroll-loops"
1099   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1100   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1101   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1102     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1103       ac_cv_c_unroll_loops=yes
1104     ], [
1105       ac_cv_c_unroll_loops=no
1106     ])
1107   ])
1108   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1109
1110   AS_IF([test "$enable_debug" = "no"], [
1111     dnl Check for -fomit-frame-pointer
1112     VLC_SAVE_FLAGS
1113     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1114     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1115     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1116     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1117       [ac_cv_c_omit_frame_pointer], [
1118       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1119         ac_cv_c_omit_frame_pointer=yes
1120       ], [
1121         ac_cv_c_omit_frame_pointer=no
1122       ])
1123     ])
1124     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1125   ])
1126
1127   AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong])
1128   AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong], [CXXFLAGS])
1129   dnl Win32 requires linking to ssp for stack-protection
1130   AS_IF([test "${SYS}" = "mingw32"], [
1131       LDFLAGS="${LDFLAGS} -lssp"
1132       AS_IF([test "${vlc_winstore_app}" != 1], [LDFLAGS="${LDFLAGS} -ladvapi32"])
1133   ])
1134 ])
1135
1136 VLC_SAVE_FLAGS
1137 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1138 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1139   AC_TRY_LINK([],, [
1140     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1141   ], [
1142     ac_cv_ld_bsymbolic=""
1143   ])
1144 ])
1145 VLC_RESTORE_FLAGS
1146 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1147 AC_SUBST(SYMBOLIC_LDFLAGS)
1148
1149 VLC_SAVE_FLAGS
1150 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1151 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1152   AC_TRY_LINK([],, [
1153     ac_cv_ld_z_defs="yes"
1154   ], [
1155     ac_cv_ld_z_defs="no"
1156   ])
1157 ])
1158 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1159
1160 dnl Check for __attribute__((packed))
1161 AC_CACHE_CHECK([for __attribute__((packed))],
1162   [ac_cv_c_attribute_packed],
1163   [ac_cv_c_attribute_packed=no
1164    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1165                     [ac_cv_c_attribute_packed=yes])])
1166 if test "${ac_cv_c_attribute_packed}" != "no"; then
1167   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1168 fi
1169
1170 dnl
1171 dnl  Check the CPU
1172 dnl
1173 case "${host_cpu}" in
1174   "")
1175     ARCH=unknown
1176     ;;
1177   *)
1178     ARCH="${host_cpu}"
1179     ;;
1180 esac
1181
1182 dnl Check for backtrace() support
1183 AC_CHECK_HEADERS(execinfo.h)
1184 AC_CHECK_FUNCS(backtrace)
1185
1186 dnl
1187 dnl  default modules
1188 dnl
1189 ALIASES="${ALIASES} cvlc rvlc"
1190
1191 dnl
1192 dnl  Accelerated modules
1193 dnl
1194
1195 dnl  Check for fully working MMX intrinsics
1196 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1197 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1198 AC_ARG_ENABLE(mmx,
1199   [AS_HELP_STRING([--disable-mmx],
1200     [disable MMX optimizations (default auto)])],,[
1201   case "${host_cpu}" in
1202     i?86|x86_64)
1203       enable_mmx="yes"
1204       ;;
1205     *)
1206       enable_mmx="no"
1207       ;;
1208   esac
1209 ])
1210 have_mmx="no"
1211 have_mmxext="no"
1212 AS_IF([test "${enable_mmx}" != "no"], [
1213   ARCH="${ARCH} mmx"
1214   VLC_SAVE_FLAGS
1215   CFLAGS="${CFLAGS} -mmmx"
1216   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1217     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1218 [#include <mmintrin.h>
1219 #include <stdint.h>
1220 uint64_t frobzor;]], [
1221 [__m64 a, b, c;
1222 a = b = c = (__m64)frobzor;
1223 a = _mm_slli_pi16(a, 3);
1224 a = _mm_adds_pi16(a, b);
1225 c = _mm_srli_pi16(c, 8);
1226 c = _mm_slli_pi16(c, 3);
1227 b = _mm_adds_pi16(b, c);
1228 a = _mm_unpacklo_pi8(a, b);
1229 frobzor = (uint64_t)a;]])], [
1230       ac_cv_c_mmx_intrinsics=yes
1231     ], [
1232       ac_cv_c_mmx_intrinsics=no
1233     ])
1234   ])
1235   VLC_RESTORE_FLAGS
1236   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1237     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1238   ])
1239
1240   VLC_SAVE_FLAGS
1241   CFLAGS="${CFLAGS} -mmmx"
1242   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1243     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1244 void *p;
1245 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1246 ]])
1247     ], [
1248       ac_cv_mmx_inline=yes
1249     ], [
1250       ac_cv_mmx_inline=no
1251     ])
1252   ])
1253   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1254     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1255     have_mmx="yes"
1256   ])
1257
1258   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1259                  [ac_cv_mmxext_inline], [
1260     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1261 void *p;
1262 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1263 ]])
1264     ], [
1265       ac_cv_mmxext_inline=yes
1266     ], [
1267       ac_cv_mmxext_inline=no
1268     ])
1269   ])
1270   VLC_RESTORE_FLAGS
1271   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1272     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1273     have_mmxext="yes"
1274   ])
1275 ])
1276 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1277 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1278
1279 dnl  Check for fully workin SSE2 intrinsics
1280 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1281 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1282 AC_ARG_ENABLE(sse,
1283   [AS_HELP_STRING([--disable-sse],
1284     [disable SSE (1-4) optimizations (default auto)])],, [
1285   case "${host_cpu}" in
1286     i?86|x86_64)
1287       enable_sse=yes
1288       ;;
1289     *)
1290       enable_sse=no
1291       ;;
1292   esac
1293 ])
1294 have_sse2="no"
1295 AS_IF([test "${enable_sse}" != "no"], [
1296   ARCH="${ARCH} sse sse2"
1297
1298   VLC_SAVE_FLAGS
1299   CFLAGS="${CFLAGS} -msse2"
1300   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1301     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1302 [#include <emmintrin.h>
1303 #include <stdint.h>
1304 uint64_t frobzor;]], [
1305 [__m128i a, b, c;
1306 a = b = c = _mm_set1_epi64((__m64)frobzor);
1307 a = _mm_slli_epi16(a, 3);
1308 a = _mm_adds_epi16(a, b);
1309 c = _mm_srli_epi16(c, 8);
1310 c = _mm_slli_epi16(c, 3);
1311 b = _mm_adds_epi16(b, c);
1312 a = _mm_unpacklo_epi8(a, b);
1313 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1314       ac_cv_c_sse2_intrinsics=yes
1315     ], [
1316       ac_cv_c_sse2_intrinsics=no
1317     ])
1318   ])
1319   VLC_RESTORE_FLAGS
1320   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1321     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1322   ])
1323
1324   VLC_SAVE_FLAGS
1325   CFLAGS="${CFLAGS} -msse"
1326   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1327     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1328 void *p;
1329 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1330 ]])
1331     ], [
1332       ac_cv_sse_inline=yes
1333     ], [
1334       ac_cv_sse_inline=no
1335     ])
1336   ])
1337
1338   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1339     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1340   ])
1341
1342   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1343     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1344 void *p;
1345 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1346 ]])
1347     ], [
1348       ac_cv_sse2_inline=yes
1349     ], [
1350       ac_cv_sse2_inline=no
1351     ])
1352   ])
1353   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1354     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1355     have_sse2="yes"
1356   ])
1357
1358   # SSE3
1359   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1360     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1361 void *p;
1362 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1363 ]])
1364     ], [
1365       ac_cv_sse3_inline=yes
1366     ], [
1367       ac_cv_sse3_inline=no
1368     ])
1369   ])
1370
1371   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1372     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1373   # SSSE3
1374   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1375     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1376 void *p;
1377 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1378 ]])
1379     ], [
1380       ac_cv_ssse3_inline=yes
1381     ], [
1382       ac_cv_ssse3_inline=no
1383     ])
1384   ])
1385
1386   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1387     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1388
1389   # SSE4.1
1390   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1391                  [ac_cv_sse4_1_inline], [
1392     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1393 void *p;
1394 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1395 ]])
1396     ], [
1397       ac_cv_sse4_1_inline=yes
1398     ], [
1399       ac_cv_sse4_1_inline=no
1400     ])
1401   ])
1402
1403   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1404     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1405
1406   # SSE4.2
1407   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1408                  [ac_cv_sse4_2_inline], [
1409     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1410 void *p;
1411 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1412 ]])
1413     ], [
1414       ac_cv_sse4_2_inline=yes
1415     ], [
1416       ac_cv_sse4_2_inline=no
1417     ])
1418   ])
1419
1420   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1421     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1422
1423   # SSE4A
1424   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1425     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1426 void *p;
1427 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1428 ]])
1429     ], [
1430       ac_cv_sse4a_inline=yes
1431     ], [
1432       ac_cv_sse4a_inline=no
1433     ])
1434   ])
1435   VLC_RESTORE_FLAGS
1436   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1437     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1438 ])
1439 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1440
1441 VLC_SAVE_FLAGS
1442 CFLAGS="${CFLAGS} -mmmx"
1443 have_3dnow="no"
1444 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1445   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1446 void *p;
1447 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1448 ]])
1449   ], [
1450     ac_cv_3dnow_inline=yes
1451   ], [
1452     ac_cv_3dnow_inline=no
1453   ])
1454 ])
1455 VLC_RESTORE_FLAGS
1456 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1457   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1458             [Define to 1 if 3D Now! inline assembly is available.])
1459   have_3dnow="yes"
1460 ])
1461 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1462
1463
1464 AC_ARG_ENABLE(neon,
1465   [AS_HELP_STRING([--disable-neon],
1466     [disable NEON optimizations (default auto)])],, [
1467   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1468 ])
1469 AS_IF([test "${enable_neon}" != "no"], [
1470   VLC_SAVE_FLAGS
1471   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1472   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1473     AC_COMPILE_IFELSE([
1474       AC_LANG_PROGRAM(,[[
1475 asm volatile("vqmovun.s64 d0, q1":::"d0");
1476 ]])
1477     ], [
1478       ac_cv_arm_neon="yes"
1479     ], [
1480       ac_cv_arm_neon="no"
1481     ])
1482   ])
1483   VLC_RESTORE_FLAGS
1484 ])
1485 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1486
1487 AC_ARG_ENABLE(arm64,
1488   [AS_HELP_STRING([--disable-arm64],
1489     [disable arm 64-bit optimizations (default auto)])],, [
1490   AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1491 ])
1492 AS_IF([test "${enable_arm64}" != "no"], [
1493   AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1494     AC_COMPILE_IFELSE([
1495       AC_LANG_PROGRAM(,[[
1496 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1497 ]])
1498     ], [
1499       ac_cv_arm64="yes"
1500     ], [
1501       ac_cv_arm64="no"
1502     ])
1503   ])
1504 ])
1505 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1506
1507
1508 AC_ARG_ENABLE(altivec,
1509   [AS_HELP_STRING([--disable-altivec],
1510     [disable AltiVec optimizations (default auto)])],, [
1511   AS_CASE("${host_cpu}", [powerpc*],
1512         [enable_altivec=yes], [enable_altivec=no])
1513 ])
1514 have_altivec="no"
1515 ALTIVEC_CFLAGS=""
1516 AS_IF([test "${enable_altivec}" = "yes"], [
1517   ARCH="${ARCH} altivec";
1518   VLC_SAVE_FLAGS
1519   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1520     [ac_cv_altivec_inline],
1521     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1522          ac_cv_altivec_inline="yes",
1523          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1524           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1525             [ac_cv_altivec_inline="-Wa,-maltivec"],
1526             ac_cv_altivec_inline=no)
1527          ])])
1528   VLC_RESTORE_FLAGS
1529   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1530     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1531               [Define to 1 if AltiVec inline assembly is available.])
1532     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1533       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1534       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1535     ])
1536     have_altivec="yes"
1537   ])
1538
1539   VLC_SAVE_FLAGS
1540   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1541   [ac_cv_c_altivec], [
1542     CFLAGS="${CFLAGS} -maltivec"
1543     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1544 [#include <altivec.h>]], [
1545 [vec_ld(0, (unsigned char *)0);]])], [
1546       ac_cv_c_altivec="-maltivec"
1547     ], [
1548       ac_cv_c_altivec="no"
1549     ])
1550   ])
1551   VLC_RESTORE_FLAGS
1552   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1553     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1554     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1555     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1556     ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1557     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1558     have_altivec="yes"
1559   ])
1560   AC_CHECK_HEADERS(altivec.h)
1561
1562   VLC_SAVE_FLAGS
1563   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1564   AC_CACHE_CHECK([if linker needs -framework vecLib],
1565     [ac_cv_ld_altivec],
1566     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1567   VLC_RESTORE_FLAGS
1568   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1569     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1570   ])
1571 ])
1572 AC_SUBST(ALTIVEC_CFLAGS)
1573 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1574
1575 dnl
1576 dnl  Memory usage
1577 dnl
1578 AC_ARG_ENABLE(optimize-memory,
1579   [AS_HELP_STRING([--enable-optimize-memory],
1580     [optimize memory usage over performance])])
1581 if test "${enable_optimize_memory}" = "yes"; then
1582   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1583 fi
1584
1585 dnl
1586 dnl Allow running as root (useful for people running on embedded platforms)
1587 dnl
1588 AC_ARG_ENABLE(run-as-root,
1589   [AS_HELP_STRING([--enable-run-as-root],
1590     [allow running VLC as root (default disabled)])])
1591 AS_IF([test "${enable_run_as_root}" = "yes"],[
1592     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1593               [Define to 1 to allow running VLC as root (uid 0).])
1594 ])
1595
1596 dnl
1597 dnl Stream output
1598 dnl
1599 AC_ARG_ENABLE(sout,
1600   [AS_HELP_STRING([--disable-sout],
1601     [disable streaming output (default enabled)])])
1602 AS_IF([test "${enable_sout}" != "no"], [
1603   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1604 ])
1605 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1606
1607 dnl Lua modules
1608 AC_ARG_ENABLE(lua,
1609   [AS_HELP_STRING([--disable-lua],
1610     [disable LUA scripting support (default enabled)])])
1611 if test "${enable_lua}" != "no"
1612 then
1613   PKG_CHECK_MODULES(LUA, lua5.2,
1614     [ have_lua=yes ],
1615     [
1616     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1617
1618     PKG_CHECK_MODULES(LUA, lua5.1,
1619       [ have_lua=yes ],
1620       [
1621       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1622       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1623         [ have_lua=yes ],
1624         [
1625           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1626           have_lua=yes
1627           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1628             [],
1629             [ have_lua=no ] )
1630           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1631             [LUA_LIBS="-llua5.2"],
1632           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1633             [LUA_LIBS="-llua5.1"],
1634             AC_CHECK_LIB( lua51 , luaL_newstate,
1635               [LUA_LIBS="-llua51"],
1636               AC_CHECK_LIB( lua , luaL_newstate,
1637                 [LUA_LIBS="-llua"],
1638                 [ have_lua=no
1639                 ], [-lm])
1640             )))
1641         ])
1642       ])
1643     ])
1644   if test "x${have_lua}" != "xyes" ;  then
1645       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1646   fi
1647   AC_ARG_VAR([LUAC], [LUA byte compiler])
1648   AS_IF([test -z "$LUAC"], [
1649      AC_CHECK_TOOL(LUAC, [luac], [false])
1650   ])
1651   AS_IF([test "${LUAC}" = "false"], [
1652     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1653   ])
1654   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1655     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1656   ])
1657 fi
1658 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1659
1660
1661 dnl
1662 dnl VideoLAN manager
1663 dnl
1664 AC_ARG_ENABLE(vlm,
1665   [AS_HELP_STRING([--disable-vlm],
1666     [disable the stream manager (default enabled)])],,
1667   [enable_vlm="${enable_sout}"])
1668 AS_IF([test "${enable_vlm}" != "no"], [
1669   AS_IF([test "${enable_sout}" = "no"], [
1670     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1671   ])
1672   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1673 ])
1674 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1675
1676
1677 dnl
1678 dnl Addons manager storage and repositories modules
1679 dnl
1680 AC_ARG_ENABLE(addonmanagermodules,
1681   [AS_HELP_STRING([--disable-addonmanagermodules],
1682     [disable the addons manager modules (default enabled)])])
1683 if test "${enable_addonmanagermodules}" != "no"
1684 then
1685   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1686 fi
1687 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1688
1689
1690 dnl
1691 dnl  Input plugins
1692 dnl
1693
1694 EXTEND_HELP_STRING([Input plugins:])
1695
1696 dnl
1697 dnl  libarchive access module
1698 dnl
1699 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1700
1701 dnl
1702 dnl  live555 input
1703 dnl
1704 AC_ARG_ENABLE(live555,
1705   [AS_HELP_STRING([--enable-live555],
1706     [enable RTSP input through live555 (default enabled)])])
1707
1708 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1709   PKG_CHECK_MODULES(LIVE555, live555, [
1710     VLC_ADD_PLUGIN([live555])
1711     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1712     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1713   ], [
1714     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1715
1716     AC_LANG_PUSH(C++)
1717     VLC_SAVE_FLAGS
1718
1719     dnl detect include paths
1720     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1721       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1722     ], [
1723       AS_IF([test "${SYS}" != "os2"], [
1724         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1725         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1726       ], [
1727         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1728         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1729         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1730       ])
1731     ])
1732
1733     dnl CPP Flags
1734     AS_IF([test "${SYS}" = "solaris"], [
1735       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1736     ])
1737     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1738     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1739
1740     dnl version check
1741     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1742       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1743 [#include <liveMedia_version.hh>
1744 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1745 # error BOOM
1746 #endif]])
1747       ], [
1748         ac_cv_live555="yes"
1749       ], [
1750         ac_cv_live555="no"
1751       ])
1752     ])
1753
1754     AS_IF([test "$ac_cv_live555" = "no"], [
1755       AC_MSG_WARN([live555 is missing or its installed version is too old:
1756 Version 2011.12.23 or later is required to proceed.
1757 You can get an updated one from http://www.live555.com/liveMedia .])
1758       AS_IF([test -n "${enable_live555}"], [
1759         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1760       ])
1761     ], [
1762       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1763       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1764       AS_IF([test "${SYS}" = "mingw32"], [
1765         # add ws2_32 for closesocket, select, recv
1766         other_libs="$other_libs -lws2_32"
1767       ])
1768
1769       dnl We need to check for pic because live555 don't provide shared libs
1770       dnl and we want to build a plugins so we need -fPIC on some arch.
1771       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1772       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1773       AC_CHECK_LIB(liveMedia_pic, main, [
1774         VLC_ADD_PLUGIN([live555])
1775         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1776       ],[
1777         AC_CHECK_LIB(liveMedia, main, [
1778           VLC_ADD_PLUGIN([live555])
1779           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1780         ],[],[${other_libs}])
1781       ],[${other_libs_pic}])
1782     ])
1783     VLC_RESTORE_FLAGS
1784     AC_LANG_POP(C++)
1785   ])
1786 ])
1787
1788 dnl
1789 dnl IIDC and DV FireWire input modules
1790 dnl
1791 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1792 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1793
1794 dnl
1795 dnl - linsys modules: access module check for libzvbi
1796 dnl
1797 AC_ARG_ENABLE(linsys,
1798   [AS_HELP_STRING([--enable-linsys],
1799     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1800 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1801   VLC_ADD_PLUGIN([linsys_hdsdi])
1802   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1803     VLC_ADD_PLUGIN([linsys_sdi])
1804   ], [
1805     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1806   ])
1807 ])
1808
1809 dnl
1810 dnl dvdread module: check for libdvdread
1811 dnl
1812 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1813
1814 dnl
1815 dnl libdvdnav plugin
1816 dnl
1817 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1818 AS_IF([test "${enable_dvdnav}" != "no"], [
1819   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1820     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1821       AC_MSG_RESULT(yes)
1822       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1823       ],[
1824       AC_MSG_RESULT(no)
1825     ])
1826 ])
1827
1828 dnl
1829 dnl  Blu-ray Disc Support with libbluray
1830 dnl
1831 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1832
1833 dnl
1834 dnl  OpenCV wrapper and example filters
1835 dnl
1836 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1837
1838
1839 dnl
1840 dnl  libsmbclient plugin
1841 dnl
1842 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1843 AS_IF([test "${SYS}" = "mingw32" -a "${enable_winstore_app}" != "yes"], [ VLC_ADD_PLUGIN([smb]) ])
1844
1845 dnl
1846 dnl  liBDSM access module
1847 dnl
1848 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1849
1850 dnl
1851 dnl sftp access support
1852 dnl
1853 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1854
1855 dnl
1856 dnl nfs access support
1857 dnl
1858 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1859
1860 dnl
1861 dnl  Video4Linux 2
1862 dnl
1863 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1864   [disable Video4Linux version 2 (default auto)])])
1865 have_v4l2="no"
1866 AS_IF([test "$enable_v4l2" != "no"], [
1867   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1868     have_v4l2="yes"
1869   ])
1870 ])
1871 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1872
1873 dnl
1874 dnl special access module for Blackmagic SDI cards
1875 dnl
1876 AC_ARG_ENABLE(decklink,
1877   [AS_HELP_STRING([--disable-decklink],
1878     [disable Blackmagic DeckLink SDI input (default auto)])])
1879 AC_ARG_WITH(decklink_sdk,
1880   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1881     [                        location of Blackmagic DeckLink SDI SDK])])
1882 have_decklink=no
1883 if test "${enable_decklink}" != "no"
1884 then
1885   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1886   then
1887     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1888   fi
1889   VLC_SAVE_FLAGS
1890   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1891   AC_LANG_PUSH(C++)
1892   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1893       have_decklink=yes
1894   ], [
1895       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1896   ])
1897   AC_LANG_POP(C++)
1898   VLC_RESTORE_FLAGS
1899 fi
1900 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1901
1902
1903 dnl
1904 dnl  Built-in CD-DA and VCD module
1905 dnl
1906 AC_ARG_ENABLE(vcd,
1907   [AS_HELP_STRING([--disable-vcd],
1908     [disable built-in VCD and CD-DA support (default enabled)])])
1909
1910 AC_ARG_ENABLE(libcddb,
1911   [AS_HELP_STRING([--disable-libcddb],
1912     [disable CDDB for Audio CD (default enabled)])])
1913
1914 if test "${enable_vcd}" != "no"
1915 then
1916   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1917   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1918     AC_MSG_RESULT(yes)
1919     VLC_ADD_PLUGIN([vcd cdda])
1920   ],[
1921     AC_MSG_RESULT(no)
1922   ])
1923
1924   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1925   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1926     AC_MSG_RESULT(yes)
1927     VLC_ADD_PLUGIN([vcd cdda])
1928     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1929   ],[
1930     AC_MSG_RESULT(no)
1931   ])
1932
1933   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1934   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1935     AC_MSG_RESULT(yes)
1936     VLC_ADD_PLUGIN([vcd cdda])
1937     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1938   ],[
1939     AC_MSG_RESULT(no)
1940   ])
1941
1942   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1943   then
1944     VLC_ADD_PLUGIN([vcd cdda])
1945   fi
1946
1947   if test "$enable_libcddb" != "no"; then
1948     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1949       HAVE_LIBCDDB=yes
1950       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1951       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1952       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1953       ],:
1954       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1955       HAVE_LIBCDDB=no])
1956   fi
1957 fi
1958
1959 dnl
1960 dnl Linux DVB
1961 dnl
1962 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1963   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1964 [#include <linux/dvb/version.h>
1965 #if (DVB_API_VERSION < 5)
1966 # error Linux DVB API v3.2 and older are not supported.
1967 #endif
1968 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1969 # error Linux DVB API v5.0 is unsupported. Please update.
1970 #endif
1971 ]])], [
1972   ac_cv_linux_dvb_5_1=yes
1973 ], [
1974   ac_cv_linux_dvb_5_1=no
1975 ])])
1976 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1977
1978 dnl
1979 dnl  Screen capture module
1980 dnl
1981 AC_ARG_ENABLE(screen,
1982   [AS_HELP_STRING([--enable-screen],
1983     [disable screen capture (default enabled)])])
1984 if test "${enable_screen}" != "no"; then
1985   if test "${SYS}" = "darwin"; then
1986     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1987       VLC_ADD_PLUGIN([screen])
1988     ])
1989   fi
1990 fi
1991 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1992
1993 dnl
1994 dnl  VNC/RFB access module
1995 dnl
1996 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1997
1998 dnl  RDP/Remote Desktop access module
1999 dnl
2000 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
2001
2002 dnl
2003 dnl  Real RTSP plugin
2004 dnl
2005 AC_ARG_ENABLE(realrtsp,
2006   [  --enable-realrtsp       Real RTSP module (default disabled)])
2007 if test "${enable_realrtsp}" = "yes"; then
2008   VLC_ADD_PLUGIN([access_realrtsp])
2009 fi
2010
2011 dnl
2012 dnl QTKit
2013 AC_ARG_ENABLE(macosx-qtkit,
2014   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
2015 if test "x${enable_macosx_qtkit}" != "xno" &&
2016   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
2017 then
2018   AC_CHECK_HEADERS(QTKit/QTKit.h, [
2019       VLC_ADD_PLUGIN([qtsound])
2020     ])
2021 fi
2022
2023 dnl
2024 dnl AVFoundation
2025 AC_SUBST(have_avfoundation, ["no"])
2026 AC_ARG_ENABLE(macosx-avfoundation,
2027   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
2028 if test "x${enable_macosx_avfoundation}" != "xno" &&
2029   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2030 then
2031   SAVED_LIBS="${LIBS}"
2032   LIBS="-framework AVFoundation"
2033   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2034   LIBS="${SAVED_LIBS}"
2035   if test "${have_avfoundation}" != "no"
2036   then
2037     VLC_ADD_PLUGIN([avcapture])
2038   fi
2039 fi
2040 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2041
2042 dnl
2043 dnl  DCP plugin (using asdcplib)
2044 dnl
2045 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2046 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2047
2048 dnl
2049 dnl  Demux plugins
2050 dnl
2051
2052 EXTEND_HELP_STRING([Mux/Demux plugins:])
2053
2054 dnl
2055 dnl  libdvbpsi check for ts mux/demux
2056 dnl
2057 have_dvbpsi="no"
2058 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2059 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2060
2061
2062 dnl
2063 dnl  GME demux plugin
2064 dnl
2065 AC_ARG_ENABLE(gme,
2066   [AS_HELP_STRING([--enable-gme],
2067     [use Game Music Emu (default auto)])])
2068 AS_IF([test "${enable_gme}" != "no"], [
2069   AC_CHECK_HEADER([gme/gme.h], [
2070     AC_CHECK_LIB([gme], [gme_identify_header], [
2071       VLC_ADD_PLUGIN([gme])
2072     ], [
2073       AC_CHECK_LIB([gme], [gme_identify_extension], [
2074          VLC_ADD_LIBS([gme], [-lstdc++ $LIBM])
2075          VLC_ADD_PLUGIN([gme])
2076       ],, [-lstdc++ $LIBM])
2077     ])
2078     VLC_ADD_LIBS([gme], [-lgme])
2079   ], [
2080     AS_IF([test "x${enable_gme}" != "x"], [
2081       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2082     ])
2083   ])
2084 ])
2085
2086
2087 dnl
2088 dnl  SIDPlay plugin
2089 dnl
2090 AC_ARG_ENABLE(sid,
2091     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2092 AS_IF([test "${enable_sid}" != "no"], [
2093     PKG_CHECK_MODULES(SID, [libsidplay2], [
2094         AC_LANG_PUSH(C++)
2095         oldCPPFLAGS="$CPPFLAGS"
2096         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2097         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2098             VLC_ADD_PLUGIN([sid])
2099             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2100             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2101         ], [
2102             AS_IF([test -n "${enable_sid}"],
2103                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2104                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2105                 )
2106         ])
2107         CPPFLAGS="$oldCPPFLAGS"
2108         AC_LANG_POP(C++)
2109     ], [
2110         AS_IF([test "x${enable_sid}" = "xyes"],
2111             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2112             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2113             )
2114     ])
2115 ])
2116
2117
2118 dnl
2119 dnl  ogg demux plugin
2120 dnl
2121 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2122 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2123     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2124 ],[true])
2125 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2126 if test "${enable_sout}" != "no"; then
2127 dnl Check for libshout
2128     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2129 fi
2130
2131 dnl
2132 dnl  matroska demux plugin
2133 dnl
2134 PKG_ENABLE_MODULES_VLC([MATROSKA], [mkv], [libebml libmatroska], [MKV format support], [auto])
2135
2136 dnl
2137 dnl  modplug demux plugin
2138 dnl
2139 AC_ARG_ENABLE(mod,
2140   [AS_HELP_STRING([--disable-mod],
2141     [do not use libmodplug (default auto)])])
2142 if test "${enable_mod}" != "no" ; then
2143     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2144           VLC_ADD_PLUGIN([mod])
2145           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2146           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2147           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2148     ],[
2149        AS_IF([test -n "${enable_mod}"],
2150          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2151          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2152     ])
2153 fi
2154
2155 dnl
2156 dnl  mpc demux plugin
2157 dnl
2158 AC_ARG_ENABLE(mpc,
2159   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2160 if test "${enable_mpc}" != "no"
2161 then
2162   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2163     VLC_ADD_PLUGIN([mpc])
2164     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2165     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2166     VLC_ADD_PLUGIN([mpc])
2167     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2168 fi
2169
2170 dnl
2171 dnl  Codec plugins
2172 dnl
2173
2174 EXTEND_HELP_STRING([Codec plugins:])
2175
2176 dnl
2177 dnl wmafixed plugin
2178 dnl
2179 AC_ARG_ENABLE(wma-fixed,
2180   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2181 if test "${enable_wma_fixed}" = "yes"
2182 then
2183   VLC_ADD_PLUGIN([wma_fixed])
2184 fi
2185
2186 dnl
2187 dnl shine encoder plugin
2188 dnl
2189 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2190
2191
2192 dnl
2193 dnl openmax il codec plugin
2194 dnl
2195 AC_ARG_ENABLE(omxil,
2196   [  --enable-omxil          openmax il codec module (default disabled)])
2197 if test "${enable_omxil}" = "yes"
2198 then
2199   VLC_ADD_PLUGIN([omxil])
2200 fi
2201
2202 dnl
2203 dnl openmax il vout plugin
2204 dnl
2205 AC_ARG_ENABLE(omxil-vout,
2206   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2207 if test "${enable_omxil_vout}" = "yes"
2208 then
2209   VLC_ADD_PLUGIN([omxil_vout])
2210 fi
2211
2212 dnl
2213 dnl raspberry pi openmax il configuration
2214 dnl
2215 AC_ARG_ENABLE(rpi-omxil,
2216   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2217 if test "${enable_rpi_omxil}" = "yes"
2218 then
2219   VLC_ADD_PLUGIN([omxil omxil_vout])
2220   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2221 fi
2222
2223 dnl
2224 dnl CrystalHD codec plugin
2225 dnl
2226 AC_ARG_ENABLE(crystalhd,
2227   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2228 if test "${enable_crystalhd}" != "no"; then
2229     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2230       VLC_ADD_PLUGIN([crystalhd])
2231       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2232     ],[
2233       if test "${SYS}" = "mingw32" ; then
2234         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2235           VLC_ADD_PLUGIN([crystalhd])
2236           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2237             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2238             ])
2239         ],[
2240           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2241                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2242                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2243         ],[#define __LINUX_USER__
2244                #include <libcrystalhd/bc_dts_types.h>
2245         ])
2246       fi
2247     ],[
2248        #include <libcrystalhd/bc_dts_types.h>
2249       ])
2250 fi
2251
2252 dnl
2253 dnl  mad plugin
2254 dnl
2255 have_mad="no"
2256 MAD_CFLAGS=""
2257 MAD_LIBS=""
2258
2259 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2260   enable_mad="yes"
2261 ], [
2262   with_mad="no"
2263 ])
2264 AS_IF([test "${with_mad}" != "no"], [
2265   MAD_CFLAGS="-I${with_mad}/include"
2266   MAD_LIBS="-L${with_mad}/lib"
2267 ])
2268
2269 AC_ARG_ENABLE(mad,
2270   [  --enable-mad            libmad module (default enabled)])
2271 AS_IF([test "${enable_mad}" != "no"], [
2272   VLC_SAVE_FLAGS
2273   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2274   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2275   AC_CHECK_HEADERS(mad.h, [
2276     AC_CHECK_LIB(mad, mad_bit_init, [
2277       have_mad="yes"
2278       MAD_LIBS="${MAD_LIBS} -lmad"
2279     ])
2280   ])
2281   VLC_RESTORE_FLAGS
2282   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2283     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2284   ])
2285 ])
2286 AC_SUBST(MAD_CFLAGS)
2287 AC_SUBST(MAD_LIBS)
2288 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2289
2290 dnl  mpg123 plugin
2291 dnl
2292 dnl
2293 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2294
2295 dnl
2296 dnl gstreamer stuff
2297 dnl
2298 AC_ARG_ENABLE(gst-decode,
2299   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2300
2301 have_gst_decode="no"
2302 AS_IF([test "${enable_gst_decode}" != "no"], [
2303   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2304     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2305       have_gst_decode="yes"
2306     ], [
2307       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2308     ])
2309   ], [
2310     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2311   ])
2312 ])
2313 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2314
2315 dnl
2316 dnl  avcodec decoder/encoder plugin
2317 dnl
2318 AC_ARG_ENABLE(merge-ffmpeg,
2319 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2320   enable_merge_ffmpeg="no"
2321 ])
2322 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2323
2324 AC_MSG_CHECKING([for libavutil variant])
2325 PKG_CHECK_EXISTS([libavutil], [
2326   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2327   libavutil_micro="${libavutil_version##*.}"
2328   AS_IF([test ${libavutil_micro} -le 99], [
2329     avfork="libav"
2330   ], [
2331     avfork="ffmpeg"
2332   ])
2333 ], [
2334   avfork="none"
2335 ])
2336 AC_MSG_RESULT([${avfork}])
2337
2338 AC_ARG_ENABLE(avcodec,
2339 [  --enable-avcodec        libavcodec codec (default enabled)])
2340 AS_IF([test "${enable_avcodec}" != "no"], [
2341   dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2342   case "${avfork}" in
2343     libav) av_codec_ver="57.16.0" ;;
2344     ffmpeg) av_codec_ver="57.37.100" ;;
2345     *) AC_MSG_ERROR([Missing libav or FFmpeg. Pass --disable-avcodec to ignore this error.])
2346   esac
2347   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2348     VLC_SAVE_FLAGS
2349     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2350     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2351     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2352     AC_CHECK_HEADERS(libavutil/avutil.h)
2353     VLC_RESTORE_FLAGS
2354     have_avcodec="yes"
2355   ],[
2356     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2357   ])
2358 ], [
2359   have_avcodec="no"
2360 ])
2361 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2362
2363 dnl
2364 dnl libva needs avcodec
2365 dnl
2366 AC_ARG_ENABLE(libva,
2367   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2368
2369 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2370   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2371 ])
2372
2373 have_vaapi="no"
2374 have_vaapi_drm="no"
2375 have_vaapi_x11="no"
2376 have_vaapi_wl="no"
2377 AS_IF([test "${enable_libva}" != "no"], [
2378   PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2379     have_vaapi="yes"
2380   ], [
2381     AS_IF([test -n "${enable_libva}"], [
2382       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2383     ], [
2384       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2385     ])
2386   ])
2387   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2388     have_vaapi_drm="yes"
2389   ], [
2390     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2391   ])
2392   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2393     have_vaapi_x11="yes"
2394   ], [
2395     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2396   ])
2397   PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2398     have_vaapi_wl="yes"
2399   ], [
2400     AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2401   ])
2402 ])
2403 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2404 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2405 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2406 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2407
2408 have_avcodec_vaapi="no"
2409 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2410   VLC_SAVE_FLAGS
2411   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2412   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2413   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2414     AC_MSG_NOTICE([VA API acceleration activated])
2415     have_avcodec_vaapi="yes"
2416   ],[
2417     AS_IF([test -n "${enable_libva}"], [
2418       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2419     ], [
2420       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2421     ])
2422   ])
2423   VLC_RESTORE_FLAGS
2424 ])
2425 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2426
2427 dnl
2428 dnl dxva2 needs avcodec
2429 dnl
2430 AC_ARG_ENABLE(dxva2,
2431   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2432
2433 have_avcodec_dxva2="no"
2434 AS_IF([test "${enable_dxva2}" != "no"], [
2435   if test "${SYS}" = "mingw32"; then
2436   AS_IF([test "x${have_avcodec}" = "xyes"], [
2437     AC_CHECK_HEADERS(dxva2api.h,
2438       [
2439         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2440            AC_MSG_NOTICE([DxVA2 acceleration activated])
2441            have_avcodec_dxva2="yes"
2442         ],[
2443     AS_IF([test "${enable_dxva2}" = "yes"],
2444           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2445               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2446         ], [#undef _WIN32_WINNT
2447             /* DXVA2 is only available in Vista and above */
2448             #define _WIN32_WINNT 0x600])
2449       ],[
2450     AS_IF([test "${enable_dxva2}" = "yes"],
2451               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2452               [AC_MSG_WARN([dxva2api.h not found])])
2453       ],[#include <d3d9.h>])
2454   ],[
2455     AS_IF([test "x${enable_dxva2}" != "x"], [
2456       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2457     ])
2458   ])
2459   fi
2460 ])
2461 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2462
2463 dnl
2464 dnl d3d11va needs avcodec
2465 dnl
2466 AC_ARG_ENABLE(d3d11va,
2467   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2468
2469 have_avcodec_d3d11va="no"
2470 AS_IF([test "${enable_d3d11va}" != "no"], [
2471   if test "${SYS}" = "mingw32"; then
2472   AS_IF([test "x${have_avcodec}" = "xyes"], [
2473         AC_CHECK_TYPES([ID3D11VideoDecoder],
2474           [
2475             AC_CHECK_HEADERS(dxva2api.h,
2476               [
2477                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2478                    AC_MSG_NOTICE([D3D11 acceleration activated])
2479                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2480                    have_avcodec_d3d11va="yes"
2481                 ],[
2482                   AS_IF([test "${enable_d3d11va}" = "yes"],
2483                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2484                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2485                   ], [#undef _WIN32_WINNT
2486                       /* D3D11 is only available in Vista and above */
2487                       #define _WIN32_WINNT 0x600])
2488                   ],[
2489                     AS_IF([test "${enable_d3d11va}" = "yes"],
2490                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2491                           [AC_MSG_WARN([dxva2api.h not found])])
2492                   ],[#include <d3d9.h>])
2493           ],[
2494             AS_IF([test "${enable_d3d11va}" = "yes"],
2495                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2496                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2497           ], [#include <d3d11.h>])
2498   ],[
2499     AS_IF([test "x${enable_d3d11va}" != "x"], [
2500       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2501     ])
2502   ])
2503   fi
2504 ])
2505 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2506
2507 dnl
2508 dnl DXGI debug
2509 dnl
2510 AC_CHECK_HEADERS(dxgidebug.h dxgi1_6.h)
2511
2512 dnl
2513 dnl  avformat demuxer/muxer plugin
2514 dnl
2515
2516 AC_ARG_ENABLE(avformat,
2517 [  --enable-avformat       libavformat containers (default enabled)],, [
2518   enable_avformat="${have_avcodec}"
2519 ])
2520 have_avformat="no"
2521 AS_IF([test "${enable_avformat}" != "no"], [
2522   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2523       have_avformat="yes"
2524       VLC_SAVE_FLAGS
2525       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2526       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2527       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2528       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2529       AC_CHECK_HEADERS(libavutil/avutil.h)
2530       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2531         have_avformat="no"
2532       ])
2533       VLC_RESTORE_FLAGS
2534     ],[
2535       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2536   ])
2537 ])
2538 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2539
2540 dnl
2541 dnl  swscale image scaling and conversion plugin
2542 dnl
2543
2544 AC_ARG_ENABLE(swscale,
2545   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2546           (default enabled)]))
2547 if test "${enable_swscale}" != "no"
2548 then
2549   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2550     [
2551       VLC_SAVE_FLAGS
2552       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2553       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2554       AC_CHECK_HEADERS(libswscale/swscale.h)
2555       AC_CHECK_HEADERS(libavutil/avutil.h)
2556       VLC_ADD_PLUGIN([swscale])
2557       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2558       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2559       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2560         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2561       ])
2562       VLC_RESTORE_FLAGS
2563     ],[
2564       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2565   ])
2566 fi
2567
2568 dnl
2569 dnl  postproc plugin
2570 dnl
2571
2572 AC_ARG_ENABLE(postproc,
2573 [  --enable-postproc       libpostproc image post-processing (default auto)])
2574 if test "${enable_postproc}" != "no"
2575 then
2576   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2577     [
2578       VLC_SAVE_FLAGS
2579       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2580       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2581       AC_CHECK_HEADERS(postproc/postprocess.h)
2582       VLC_ADD_PLUGIN([postproc])
2583       VLC_RESTORE_FLAGS
2584     ],[
2585       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2586   ])
2587 fi
2588
2589 dnl
2590 dnl  faad decoder plugin
2591 dnl
2592 AC_ARG_ENABLE(faad,
2593 [  --enable-faad           faad codec (default auto)])
2594 have_faad="no"
2595 AS_IF([test "${enable_faad}" != "no"], [
2596   AC_CHECK_HEADERS([neaacdec.h], [
2597     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2598
2599     AS_IF([test "${have_faad}" = "yes"], [
2600       VLC_ADD_PLUGIN([faad])
2601       VLC_ADD_LIBS([faad],[-lfaad])
2602     ], [
2603       AS_IF([test "${enable_faad}" = "yes"], [
2604         AC_MSG_ERROR([cannot find FAAD library])
2605       ], [
2606         AC_MSG_WARN([cannot find FAAD library])
2607       ])
2608     ])
2609   ])
2610 ])
2611
2612 dnl
2613 dnl  AOM decoder plugin
2614 dnl
2615 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec (default auto)])
2616
2617 dnl
2618 dnl libvpx decoder plugin
2619 dnl
2620 AC_ARG_ENABLE(vpx,
2621     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2622 AS_IF([test "${enable_vpx}" != "no"],[
2623     PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2624         VLC_ADD_PLUGIN([vpx])
2625         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2626         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2627         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2628             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2629         ], [], [${VPX_LIBS}])
2630         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2631             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2632         ], [], [${VPX_LIBS}])
2633         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2634             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2635         ], [], [${VPX_LIBS}])
2636         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2637             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2638         ], [], [${VPX_LIBS}])
2639     ], [
2640     AS_IF([test "${enable_vpx}" = "yes"],[
2641         AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2642     ])])
2643 ])
2644
2645 dnl
2646 dnl twolame encoder plugin
2647 dnl
2648 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2649
2650 dnl
2651 dnl fdk-aac encoder plugin
2652 dnl
2653 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2654
2655
2656 dnl
2657 dnl A52/AC3 decoder plugin
2658 dnl
2659 AC_ARG_ENABLE(a52,
2660   [  --enable-a52            A/52 support with liba52 (default enabled)])
2661 if test "${enable_a52}" != "no"
2662 then
2663   AC_ARG_WITH(a52,
2664     [  --with-a52=PATH         a52 headers and libraries])
2665     if test -z "${with_a52}"
2666     then
2667       LDFLAGS_test=""
2668       CPPFLAGS_test=""
2669     else
2670       LDFLAGS_test="-L${with_a52}/lib"
2671       CPPFLAGS_test="-I${with_a52}/include"
2672     fi
2673     VLC_SAVE_FLAGS
2674     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2675     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2676     AC_CHECK_HEADERS(a52dec/a52.h, [
2677       AC_CHECK_LIB(a52, a52_free, [
2678         VLC_ADD_PLUGIN([a52])
2679         VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2680         VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2681       ],[
2682         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2683         ], [$LIBM])
2684     ],[
2685       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2686     ])
2687     VLC_RESTORE_FLAGS
2688 fi
2689
2690 dnl
2691 dnl DTS Coherent Acoustics decoder plugin
2692 dnl
2693 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2694
2695 dnl
2696 dnl  Flac plugin
2697 dnl
2698 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2699
2700 dnl
2701 dnl  Libmpeg2 plugin
2702 dnl
2703 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2704
2705 dnl
2706 dnl  Vorbis plugin
2707 dnl
2708 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2709
2710 dnl
2711 dnl  Tremor plugin
2712 dnl
2713 AC_ARG_ENABLE(tremor,
2714   [  --enable-tremor         Tremor decoder support (default disabled)])
2715 if test "${enable_tremor}" = "yes"
2716 then
2717   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2718     VLC_ADD_PLUGIN([tremor])
2719    ],[])
2720 fi
2721
2722 dnl
2723 dnl  Speex plugins
2724 dnl
2725 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2726 have_speexdsp="no"
2727 AS_IF([test "${enable_speex}" != "no"], [
2728   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2729     have_speexdsp="yes"
2730   ], [
2731     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2732   ])
2733 ])
2734 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2735
2736 dnl
2737 dnl  Opus plugin
2738 dnl
2739 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2740
2741 dnl
2742 dnl  Ambisonic channel mixer and binauralizer plugin
2743 dnl
2744 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
2745
2746 dnl
2747 dnl  theora decoder plugin
2748 dnl
2749 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2750
2751 dnl
2752 dnl  OggSpots decoder plugin
2753 dnl
2754 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2755
2756 dnl
2757 dnl  Daala decoder plugin
2758 dnl
2759 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2760
2761 dnl
2762 dnl  schroedinger decoder plugin (for dirac format video)
2763 dnl
2764 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2765
2766 dnl
2767 dnl  PNG decoder module
2768 dnl
2769 AC_ARG_ENABLE(png,
2770   [  --enable-png            PNG support (default enabled)])
2771 AS_IF([test "${enable_png}" != "no"], [
2772 AC_CHECK_HEADERS(png.h, [
2773   VLC_SAVE_FLAGS
2774   LDFLAGS="${LDFLAGS} -lz $LIBM"
2775   AC_CHECK_LIB(png, png_set_alpha_mode, [
2776     VLC_ADD_PLUGIN([png])
2777   ], [], [-lz $LIBM])
2778   VLC_RESTORE_FLAGS
2779   ])
2780 ])
2781
2782 dnl
2783 dnl  JPEG decoder module
2784 dnl
2785 AC_ARG_ENABLE(jpeg,
2786   [  --enable-jpeg           JPEG support (default enabled)])
2787 AS_IF([test "${enable_jpeg}" != "no"], [
2788 AC_CHECK_HEADERS(jpeglib.h, [
2789   VLC_ADD_PLUGIN([jpeg])
2790   ])
2791 ])
2792
2793 dnl
2794 dnl  BPG decoder module
2795 dnl
2796 AC_ARG_ENABLE(bpg,
2797   [  --enable-bpg           BPG support (default disabled)])
2798 AS_IF([test "${enable_bpg}" != "no"], [
2799 AC_CHECK_HEADERS(libbpg.h, [
2800   VLC_ADD_PLUGIN([bpg])
2801   ])
2802 ])
2803
2804 dnl
2805 dnl H262 encoder plugin (lib262)
2806 dnl
2807 AC_ARG_ENABLE(x262,
2808   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2809 if test "${enable_x262}" != "no"; then
2810     PKG_CHECK_MODULES(X262, x262, [
2811         VLC_ADD_PLUGIN([x262])
2812         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2813         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2814           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2815         ])
2816         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2817         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2818           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2819         fi
2820     ], [
2821        if test "${enable_x262}" = "yes"; then
2822         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2823        fi
2824     ])
2825 fi
2826
2827 dnl x265 encoder
2828 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2829
2830 dnl
2831 dnl H264 encoder plugin (10-bit lib264)
2832 dnl
2833 AC_ARG_ENABLE(x26410b,
2834   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2835 if test "${enable_x26410b}" != "no"; then
2836     PKG_CHECK_MODULES(X26410B, x26410b, [
2837         VLC_ADD_PLUGIN([x26410b])
2838         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2839         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2840           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2841         ])
2842         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2843         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2844           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2845         fi
2846     ], [
2847        if test "${enable_x26410b}" = "yes"; then
2848         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2849        fi
2850     ])
2851 fi
2852
2853
2854 dnl
2855 dnl H264 encoder plugin (using libx264)
2856 dnl
2857 AC_ARG_ENABLE(x264,
2858   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2859 if test "${enable_x264}" != "no"; then
2860       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2861         VLC_ADD_PLUGIN([x264])
2862         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2863
2864         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2865           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2866         ])
2867
2868         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2869         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2870           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2871         fi
2872       ],[
2873         if test "${enable_x264}" = "yes"; then
2874             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2875           fi
2876       ])
2877 fi
2878
2879 dnl
2880 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2881 dnl
2882 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2883
2884 dnl
2885 dnl libfluidsynth (MIDI synthetizer) plugin
2886 dnl
2887 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2888 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2889 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2890
2891 dnl
2892 dnl Teletext Modules
2893 dnl vbi decoder plugin (using libzbvi)
2894 dnl telx module
2895 dnl uncompatible
2896 dnl
2897 AC_ARG_ENABLE(zvbi,
2898   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2899                   libzvbi (default enabled)]))
2900 AC_ARG_ENABLE(telx,
2901   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2902                   zvbi) (default enabled if zvbi is absent)]))
2903
2904 AS_IF( [test "${enable_zvbi}" != "no"],[
2905     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2906         [
2907           VLC_ADD_PLUGIN([zvbi])
2908           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2909           AS_IF( [test "${enable_telx}" = "yes"],[
2910                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2911                   ])
2912         ],[
2913           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2914         ])
2915     ])
2916 AS_IF( [test "${enable_telx}" != "no" ],[
2917   VLC_ADD_PLUGIN([telx])
2918   ])
2919
2920 dnl
2921 dnl libass subtitle rendering module
2922 dnl
2923 AC_ARG_ENABLE(libass,
2924   [  --enable-libass         Subtitle support using libass (default enabled)])
2925 AS_IF( [test "${enable_libass}" != "no"], [
2926   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2927       [
2928         VLC_ADD_PLUGIN([libass])
2929
2930         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2931           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2932            VLC_ADD_LIBS([libass],[-lfontconfig])
2933        ])
2934       ],[
2935         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2936       ])
2937   ])
2938
2939 dnl
2940 dnl ARIB subtitles rendering module
2941 dnl
2942 AC_ARG_ENABLE(aribsub,
2943   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2944 AS_IF( [test "${enable_aribsub}" != "no" ],[
2945   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2946       have_aribb24="yes"
2947       VLC_ADD_PLUGIN([aribsub])
2948       VLC_ADD_LIBS([aribsub],[-laribb24])
2949       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2950     ],[
2951       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2952       have_aribb24="no"
2953   ])
2954 ])
2955 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2956
2957 dnl
2958 dnl ARIB B25
2959 dnl
2960 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2961
2962 dnl
2963 dnl  kate decoder plugin
2964 dnl
2965 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2966
2967 dnl
2968 dnl  tiger rendering for kate decoder plugin
2969 dnl
2970 AC_ARG_ENABLE(tiger,
2971 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2972 AS_IF([test "${enable_tiger}" != "no"], [
2973   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2974       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2975         AS_IF([test -n "${enable_tiger}"], [
2976           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2977         ])
2978   ])
2979 ])
2980
2981 dnl
2982 dnl  check if we can build the css selector engine
2983 dnl
2984 AC_ARG_ENABLE(css,
2985 [  --enable-css            CSS selector engine (default auto)])
2986 AS_IF([test "${enable_css}" != "no"], [
2987   with_css="yes"
2988   AC_DEFINE(HAVE_CSS, 1, [Define if CSS engine is built])
2989 ])
2990 AM_CONDITIONAL([ENABLE_CSS], [test "${with_css}" = "yes"])
2991
2992
2993 dnl
2994 dnl  Video plugins
2995 dnl
2996
2997 EXTEND_HELP_STRING([Video plugins:])
2998
2999 dnl
3000 dnl  OpenGL
3001 dnl
3002 PKG_CHECK_MODULES([EGL], [egl], [
3003   have_egl="yes"
3004 ], [
3005   have_egl="no"
3006 ])
3007 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3008
3009 have_gl="no"
3010 PKG_CHECK_MODULES([GL], [gl], [
3011   have_gl="yes"
3012 ], [
3013   AC_MSG_CHECKING([for OpenGL])
3014   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3015 #ifdef _WIN32
3016 # include <GL/glew.h>
3017 #endif
3018 #include <GL/gl.h>
3019 ]], [
3020     [int t0 = GL_TEXTURE0;]])
3021   ], [
3022     GL_CFLAGS=""
3023     have_gl="yes"
3024     AS_IF([test "${SYS}" != "mingw32"], [
3025       GL_LIBS="-lGL"
3026     ], [
3027       GL_LIBS="-lopengl32"
3028     ])
3029   ])
3030   AC_MSG_RESULT([${have_gl}])
3031 ])
3032 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3033
3034 dnl OpenGL ES 2: depends on EGL 1.1
3035 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3036
3037 dnl
3038 dnl  Xlib
3039 dnl
3040
3041 AC_PATH_XTRA()
3042 AC_CHECK_HEADERS(X11/Xlib.h)
3043
3044 dnl
3045 dnl  X C Bindings modules
3046 dnl
3047 AC_ARG_ENABLE(xcb,
3048   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3049   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3050     enable_xcb="yes"
3051   ], [
3052     enable_xcb="no"
3053   ])
3054 ])
3055 AC_ARG_ENABLE(xvideo,
3056   [  --enable-xvideo         XVideo support (default enabled)],, [
3057     enable_xvideo="$enable_xcb"
3058 ])
3059
3060 have_xcb="no"
3061 have_xcb_keysyms="no"
3062 have_xcb_randr="no"
3063 have_xcb_xvideo="no"
3064 AS_IF([test "${enable_xcb}" != "no"], [
3065   dnl libxcb
3066   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3067   have_xcb="yes"
3068   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3069   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3070   PKG_CHECK_MODULES(XPROTO, [xproto])
3071
3072   AS_IF([test "${enable_xvideo}" != "no"], [
3073     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3074   ])
3075
3076   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3077
3078   dnl xcb-utils
3079   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3080     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3081   ])
3082 ])
3083 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3084 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3085 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3086 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3087
3088
3089 dnl
3090 dnl VDPAU needs X11
3091 dnl
3092 AC_ARG_ENABLE(vdpau,
3093   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3094 have_vdpau="no"
3095 AS_IF([test "${enable_vdpau}" != "no"], [
3096   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3097     have_vdpau="yes"
3098     AS_IF([test "${no_x}" = "yes"], [
3099       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3100     ])
3101   ], [
3102     AS_IF([test -n "${enable_vdpau}"], [
3103       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3104     ])
3105   ])
3106 ])
3107 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3108
3109 have_avcodec_vdpau="no"
3110 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3111   case "${avfork}" in
3112     libav) av_vdpau_ver="56.10.0" ;;
3113     ffmpeg) av_vdpau_ver="56.19.100" ;;
3114   esac
3115   PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3116     have_avcodec_vdpau="yes"
3117     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3118   ], [
3119     AS_IF([test -n "${enable_vdpau}"], [
3120       AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3121     ], [
3122       AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3123     ])
3124   ])
3125 ])
3126 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3127
3128
3129 dnl
3130 dnl  Wayland
3131 dnl
3132 AC_ARG_ENABLE(wayland,
3133   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3134 have_wayland="no"
3135 have_wayland_egl="no"
3136
3137 AS_IF([test "${enable_wayland}" != "no"], [
3138   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3139     AC_MSG_CHECKING([for the Wayland protocols])
3140     PKG_CHECK_EXISTS([wayland-protocols >= 1.4], [
3141       WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3142       AC_MSG_RESULT([${WAYLAND_PROTOCOLS}])
3143     ], [
3144       AC_MSG_RESULT([not found])
3145       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors 'wayland-protocols >= 1.4')])
3146     ])
3147
3148     AC_MSG_CHECKING([for the Wayland scanner])
3149     PKG_CHECK_EXISTS([wayland-scanner], [
3150       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3151       AC_MSG_RESULT([${WAYLAND_SCANNER}])
3152     ], [
3153       AC_MSG_RESULT([not found])
3154       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors wayland-scanner)])
3155     ])
3156
3157     have_wayland="yes"
3158
3159     AS_IF([test "${have_egl}" = "yes"], [
3160       PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3161         have_wayland_egl="yes"
3162       ], [
3163         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3164       ])
3165     ])
3166   ], [
3167     AS_IF([test -n "${enable_wayland}"], [
3168       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3169     ])
3170   ])
3171 ])
3172 AC_SUBST([WAYLAND_PROTOCOLS])
3173 AC_SUBST([WAYLAND_SCANNER])
3174 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3175 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3176
3177
3178 dnl
3179 dnl  SDL image decoder module
3180 dnl
3181 AC_ARG_ENABLE(sdl-image,
3182   [  --enable-sdl-image      SDL image support (default enabled)])
3183 AS_IF([test "${enable_sdl_image}" != "no"],[
3184   PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3185     VLC_ADD_PLUGIN([sdl_image])
3186   ], [
3187     AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3188   ])
3189 ])
3190
3191 dnl
3192 dnl  freetype module
3193 dnl
3194 AC_ARG_ENABLE(freetype,
3195   [  --enable-freetype       freetype support   (default auto)])
3196 AC_ARG_ENABLE(fribidi,
3197   [  --enable-fribidi        fribidi support    (default auto)])
3198 AC_ARG_ENABLE(harfbuzz,
3199   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3200 AC_ARG_ENABLE(fontconfig,
3201   [  --enable-fontconfig     fontconfig support (default auto)])
3202
3203 AC_ARG_WITH([default-font],
3204     AS_HELP_STRING([--with-default-font=PATH],
3205         [Path to the default font]),
3206         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3207             "$withval", [Default font])])
3208 AC_ARG_WITH([default-monospace-font],
3209     AS_HELP_STRING([--with-default-monospace-font=PATH],
3210         [Path to the default font]),
3211         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3212             "$withval", [Default monospace font])])
3213
3214 AC_ARG_WITH([default-font-family],
3215     AS_HELP_STRING([--with-default-font-family=NAME],
3216         [Path to the default font family]),
3217         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3218             "$withval", [Default font family])])
3219 AC_ARG_WITH([default-monospace-font-family],
3220     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3221         [Path to the default font family]),
3222         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3223             "$withval", [Default monospace font family])])
3224
3225 have_freetype="no"
3226 have_fontconfig="no"
3227 have_fribidi="no"
3228 have_harfbuzz="no"
3229
3230 if test "${enable_freetype}" != "no"; then
3231    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3232       have_freetype="yes"
3233       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3234       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3235
3236     dnl fontconfig support
3237     AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3238       PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3239         have_fontconfig="yes"
3240       ], [
3241         AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3242       ])
3243     ])
3244
3245       dnl fribidi support
3246       if test "${enable_fribidi}" != "no"; then
3247         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3248           have_fribidi="yes"
3249           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3250           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3251         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3252       fi
3253
3254       dnl harfbuzz support
3255       if test "${have_fribidi}" != "no"; then
3256         if test "${enable_harfbuzz}" != "no"; then
3257           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3258             have_harfbuzz="yes"
3259             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3260             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3261           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3262         fi
3263       fi
3264   ],[
3265   AS_IF([test -n "${enable_freetype}"],[
3266     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3267     ])
3268   ])
3269 fi
3270
3271 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3272 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3273 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3274 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3275
3276 dnl
3277 dnl SAPI (text to Speech renderer for Windows)
3278 dnl
3279 AC_LANG_PUSH([C++])
3280 AC_CHECK_TYPES([ISpObjectToken],[
3281               have_sapi="yes"
3282             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3283               [#include <windows.h>
3284                #include <sapi.h>
3285                #include <sphelper.h>])
3286 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3287 AC_LANG_POP([C++])
3288
3289 dnl
3290 dnl  SVG module (text rendering and image decoding)
3291 dnl
3292 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3293 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3294
3295 dnl
3296 dnl  Windows DirectX module
3297 dnl
3298
3299 AC_ARG_ENABLE(directx,
3300   [AS_HELP_STRING([--enable-directx],
3301     [Microsoft DirectX support (default enabled on Windows)])],, [
3302   AS_IF([test "${SYS}" = "mingw32"], [
3303     enable_directx="yes"
3304   ], [
3305     enable_directx="no"
3306   ])
3307 ])
3308 AS_IF([test "${enable_directx}" != "no"], [
3309   dnl DirectDraw
3310   AC_CHECK_HEADERS(ddraw.h, [
3311     VLC_ADD_PLUGIN([directdraw])
3312   ])
3313
3314   dnl OpenGL
3315   AC_CHECK_HEADERS(GL/wglew.h, [
3316     VLC_ADD_PLUGIN([glwin32 wgl])
3317   ],, [
3318     #include <windows.h>
3319     #include <GL/gl.h>
3320   ])
3321
3322   dnl Direct3D11
3323   AC_CHECK_HEADERS(d3d11.h, [
3324     VLC_ADD_PLUGIN([direct3d11 direct3d11_filters])
3325   ])
3326
3327   dnl Direct3D9
3328   AC_CHECK_HEADERS(d3d9.h, [
3329     VLC_ADD_PLUGIN([direct3d9])
3330     AC_CHECK_HEADERS(d3dx9effect.h)
3331
3332     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3333         [[#define COBJMACROS
3334           #include <d3d9.h>
3335           #include <dxva2api.h>
3336           #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3337           # error dxva2 too old
3338           #endif
3339         ]],[[;]])
3340       ],[
3341         VLC_ADD_PLUGIN([direct3d9_filters])
3342       ],
3343       [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3344
3345   ])
3346 ])
3347
3348 dnl
3349 dnl  Linux framebuffer module
3350 dnl
3351 AC_CHECK_HEADER([linux/fb.h], [
3352   VLC_ADD_PLUGIN([fb])
3353 ])
3354
3355
3356 dnl
3357 dnl  AA plugin
3358 dnl
3359 AC_ARG_ENABLE(aa,
3360   [  --enable-aa             aalib output (default disabled)])
3361 if test "${enable_aa}" = "yes"
3362 then
3363   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3364   if test "${have_aa}" = "true"
3365   then
3366     VLC_ADD_PLUGIN([aa])
3367   fi
3368 fi
3369
3370 dnl
3371 dnl  libcaca plugin
3372 dnl
3373 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3374
3375 dnl
3376 dnl  OS/2 KVA plugin
3377 dnl
3378 AC_ARG_ENABLE(kva,
3379   [AS_HELP_STRING([--enable-kva],
3380     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3381   AS_IF([test "$SYS" = "os2"], [
3382     enable_kva="yes"
3383   ])
3384 ])
3385 have_kva="no"
3386 KVA_LIBS=""
3387 AS_IF([test "$enable_kva" != "no"], [
3388   AC_CHECK_HEADERS([kva.h], [
3389     have_kva="yes"
3390     AC_CHECK_LIB(kva, main, [
3391       KVA_LIBS="-lkva"
3392     ])
3393   ])
3394 ])
3395 AC_SUBST(KVA_LIBS)
3396 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3397
3398 dnl
3399 dnl MMAL plugin
3400 dnl
3401 AC_ARG_ENABLE(mmal,
3402   AS_HELP_STRING([--enable-mmal],
3403     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3404 if test "${enable_mmal}" != "no"; then
3405   VLC_SAVE_FLAGS
3406   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3407   CPPFLAGS="${CPPFLAGS} -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux"
3408   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3409     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3410         have_mmal="yes"
3411         VLC_ADD_PLUGIN([mmal])
3412         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3413         VLC_ADD_CFLAGS([mmal],[ -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux ])
3414         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lmmal_core -lmmal_components -lmmal_util -lvchostif ]) ], [
3415           AS_IF([test "${enable_mmal}" = "yes"],
3416             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3417             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3418           ],
3419         [])
3420     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3421       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3422       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3423   VLC_RESTORE_FLAGS
3424 fi
3425 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3426
3427 dnl
3428 dnl evas plugin
3429 dnl
3430 AC_ARG_ENABLE(evas,
3431   [AS_HELP_STRING([--enable-evas],
3432     [use evas output module (default disabled)])])
3433 have_evas="no"
3434 AS_IF([test "${enable_evas}" = "yes"], [
3435   PKG_CHECK_MODULES(EVAS, [evas >= 1.15.99 ecore >= 1.15.99], [
3436       have_evas="yes"
3437       AC_DEFINE([HAVE_EVAS], [1], [Define to 1 if evas is enabled.])
3438     ],[
3439     AS_IF([test "x${enable_evas}" != "x"], [
3440       AC_MSG_ERROR([$EVAS_PKG_ERRORS. libevas and libecore 1.15.99 or later required.])
3441     ])
3442   ])
3443 ])
3444 AM_CONDITIONAL([HAVE_EVAS], [test "${have_evas}" = "yes"])
3445
3446 dnl
3447 dnl  Audio plugins
3448 dnl
3449
3450 EXTEND_HELP_STRING([Audio plugins:])
3451
3452 dnl
3453 dnl  Pulseaudio module
3454 dnl
3455 AC_ARG_ENABLE(pulse,
3456   [AS_HELP_STRING([--enable-pulse],
3457     [use the PulseAudio client library (default auto)])])
3458 have_pulse="no"
3459 AS_IF([test "${enable_pulse}" != "no"], [
3460   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3461     have_pulse="yes"
3462   ], [
3463     AS_IF([test "x${enable_pulse}" != "x"], [
3464       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3465     ])
3466   ])
3467 ])
3468 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3469
3470 dnl
3471 dnl  ALSA module
3472 dnl
3473 AC_ARG_ENABLE(alsa,
3474   [AS_HELP_STRING([--enable-alsa],
3475     [support the Advanced Linux Sound Architecture (default auto)])],, [
3476   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3477     enable_alsa="yes"
3478   ])
3479 ])
3480 have_alsa="no"
3481 AS_IF([test "${enable_alsa}" != "no"], [
3482   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3483     have_alsa="yes"
3484   ], [
3485     AS_IF([test "x${enable_alsa}" != "x"], [
3486       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required. Pass --disable-alsa to ignore this error.])
3487     ])
3488   ])
3489 ])
3490 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3491
3492 dnl
3493 dnl  Open Sound System module
3494 dnl
3495 AC_ARG_ENABLE(oss,
3496   [AS_HELP_STRING([--enable-oss],
3497     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3498   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3499     enable_oss="no"
3500   ])
3501 ])
3502 have_oss="no"
3503 OSS_LIBS=""
3504 AS_IF([test "$enable_oss" != "no"], [
3505   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3506     have_oss="yes"
3507     AC_CHECK_LIB(ossaudio, main, [
3508       OSS_LIBS="-lossaudio"
3509     ])
3510   ])
3511 ])
3512 AC_SUBST(OSS_LIBS)
3513 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3514
3515 dnl
3516 dnl  OpenBSD sndio module
3517 dnl
3518 AC_ARG_ENABLE([sndio],
3519   [AS_HELP_STRING([--disable-sndio],
3520     [support the OpenBSD sndio (default auto)])],, [
3521   AS_IF([test "$SYS" = "openbsd"], [
3522     enable_sndio="yes"
3523   ])
3524 ])
3525 have_sndio="no"
3526 AS_IF([test "$enable_sndio" != "no"], [
3527   AC_CHECK_HEADER([sndio.h], [
3528     have_sndio="yes"
3529   ])
3530 ])
3531 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3532
3533 dnl
3534 dnl  Windows Audio Session plugin
3535 dnl
3536 AC_ARG_ENABLE([wasapi],
3537   [AS_HELP_STRING([--enable-wasapi],
3538     [use the Windows Audio Session API (default auto)])
3539 ])
3540 have_wasapi="no"
3541 AS_IF([test "$enable_wasapi" != "no"], [
3542   AC_CHECK_HEADER([audioclient.h], [
3543     have_wasapi="yes"
3544   ], [
3545     AS_IF([test "x${enable_wasapi}" != "x"], [
3546       AC_MSG_ERROR([Windows Audio Session API not found.])
3547     ])
3548   ])
3549 ])
3550 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3551
3552 dnl
3553 dnl  JACK modules
3554 dnl
3555 AC_ARG_ENABLE(jack,
3556   [AS_HELP_STRING([--disable-jack],
3557     [do not use jack (default auto)])])
3558 have_jack="no"
3559 AS_IF([test "${enable_jack}" != "no"], [
3560     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3561       [ have_jack=yes ],
3562       [
3563       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3564
3565       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3566       [ have_jack=yes ],
3567       [
3568       AS_IF([test -n "${enable_jack}"],
3569          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3570          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3571       ])
3572     ])
3573 ])
3574 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3575
3576 dnl
3577 dnl  OpenSLES Android
3578 dnl
3579 AC_ARG_ENABLE(opensles,
3580   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3581 if test "${HAVE_ANDROID}" = "1"; then
3582   if test "${enable_opensles}" = "yes"; then
3583       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3584         [ VLC_ADD_PLUGIN([opensles_android]) ],
3585         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3586   fi
3587 fi
3588
3589 dnl
3590 dnl  Tizen audio
3591 dnl
3592 AC_ARG_ENABLE(tizen_audio,
3593   [AS_HELP_STRING([--enable-tizen-audio],
3594     [Tizen audio module (default enabled on Tizen)])],, [
3595   AS_IF([test "$HAVE_TIZEN" = "1"], [
3596     enable_tizen_audio="yes"
3597   ])
3598 ])
3599 if test "${enable_tizen_audio}" = "yes"; then
3600   AC_CHECK_HEADERS(audio_io.h,
3601     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3602     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3603 fi
3604
3605 dnl
3606 dnl libsamplerate plugin
3607 dnl
3608 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3609
3610 dnl
3611 dnl  soxr module
3612 dnl
3613 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3614
3615 dnl
3616 dnl  OS/2 KAI plugin
3617 dnl
3618 AC_ARG_ENABLE(kai,
3619   [AS_HELP_STRING([--enable-kai],
3620     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3621   AS_IF([test "$SYS" = "os2"], [
3622     enable_kai="yes"
3623   ])
3624 ])
3625 have_kai="no"
3626 KAI_LIBS=""
3627 AS_IF([test "$enable_kai" != "no"], [
3628   AC_CHECK_HEADERS([kai.h], [
3629     have_kai="yes"
3630     AC_CHECK_LIB(kai, main, [
3631       KAI_LIBS="-lkai"
3632     ])
3633   ])
3634 ])
3635 AC_SUBST(KAI_LIBS)
3636 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3637
3638 dnl
3639 dnl  chromaprint audio track fingerprinter
3640 dnl
3641 m4_pushdef([libchromaprint_version], 0.6.0)
3642 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3643     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3644     AS_IF([test "${enable_chromaprint}" = "yes"],
3645         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3646         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3647          ),
3648     [(Chromaprint based audio fingerprinter)],[auto])
3649 m4_popdef([libchromaprint_version])
3650
3651 dnl
3652 dnl  Chromecast streaming support
3653 dnl
3654 m4_pushdef([protobuf_lite_version], 2.5.0)
3655 AC_ARG_VAR(PROTOC, [protobuf compiler])
3656 AC_CHECK_PROGS(PROTOC, protoc, no)
3657 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3658     AS_IF([test "x${PROTOC}" != "xno"], [
3659         build_chromecast="yes"
3660     ], [
3661     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3662     ])
3663 ], [
3664     AS_IF([test "${enable_chromecast}" = "yes"],
3665         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3666         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3667     )
3668     enable_chromecast="no"
3669 ], [(Chromecast streaming support)], [auto])
3670 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3671 m4_popdef([protobuf_lite_version])
3672
3673 dnl
3674 dnl  Interface plugins
3675 dnl
3676
3677 EXTEND_HELP_STRING([Interface plugins:])
3678
3679 dnl
3680 dnl QT
3681 dnl
3682 AC_ARG_ENABLE(qt, [
3683   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3684   AS_IF([test "${SYS}" = "darwin"], [
3685     enable_qt="no"
3686   ])
3687 ])
3688 have_qt5_x11="no"
3689 AS_IF([test "${enable_qt}" != "no"], [
3690   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.5.0 Qt5Widgets Qt5Gui Qt5Svg], [
3691       PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3692           have_qt5_x11="yes"
3693       ],[
3694           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3695       ])
3696       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3697       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3698       QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3699       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3700       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3701       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3702     ], [
3703       AS_IF([test -n "${enable_qt}"],[
3704         AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3705       ],[
3706         AC_MSG_WARN([${QT_PKG_ERRORS}.])
3707       ])
3708       enable_qt="no"
3709     ])
3710 ])
3711
3712 AS_IF([test "${enable_qt}" != "no"], [
3713   ALIASES="${ALIASES} qvlc"
3714 ])
3715 AC_SUBST(QT_VERSION)
3716 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3717 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3718
3719 dnl
3720 dnl detect kde4-config patch (used for kde solids).
3721 dnl
3722 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3723 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3724   KDE4_CONFIG="kde4-config"
3725 ])
3726
3727 dnl
3728 dnl Simple test for skins2 dependency
3729 dnl
3730 AS_IF([test "$enable_qt" = "no"], [
3731   AS_IF([test "${enable_skins2}" = "yes"], [
3732     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3733   ], [
3734     enable_skins2="no"
3735     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3736   ])
3737 ])
3738
3739 dnl
3740 dnl Skins2 module
3741 dnl
3742 AC_ARG_ENABLE(skins2,
3743   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3744 AS_IF([test "${enable_skins2}" != "no"], [
3745   have_skins_deps="yes"
3746
3747   dnl Win32
3748   AS_IF([test "${SYS}" = "mingw32"], [
3749     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3750     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3751   dnl OS/2
3752   ], [test "${SYS}" = "os2"], [
3753     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3754   dnl Linux/Unix
3755   ], [
3756     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3757     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3758     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3759     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3760     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3761   ])
3762
3763   dnl we need freetype
3764   AS_IF([test "${have_freetype}" != "yes"], [
3765     have_skins_deps="no"
3766   ])
3767
3768   AS_IF([test "${have_skins_deps}" = "no"], [
3769     AS_IF([test "x${enable_skins2}" = "x"], [
3770       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3771     ], [
3772       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3773     ])
3774     enable_skins2="no"
3775   ], [
3776     ALIASES="${ALIASES} svlc"
3777     enable_skins2="yes"
3778   ])
3779 ])
3780 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3781
3782 AC_ARG_ENABLE(libtar,
3783   [  --enable-libtar         libtar support for skins2 (default auto)])
3784 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3785   AC_CHECK_HEADERS(libtar.h, [
3786     VLC_ADD_LIBS([skins2],[-ltar])
3787   ])
3788 ])
3789
3790 dnl
3791 dnl  MacOS X gui module
3792 dnl
3793 AC_ARG_ENABLE(macosx,
3794   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3795 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3796 then
3797
3798   dnl
3799   dnl If possible, use xcrun to find the right ibtool
3800   dnl
3801
3802   AC_PATH_PROG([XCRUN], [xcrun], [no])
3803   AS_IF([test ! "x${XCRUN}" = "xno"], [
3804     AC_MSG_CHECKING([for ibtool (using xcrun)])
3805     XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3806     AC_MSG_RESULT([${XIB}])
3807   ], [
3808     AC_MSG_WARN([Looking for tools without using xcrun])
3809   ])
3810
3811   AS_IF([test "x${XIB}" = "xno"], [
3812     AC_PATH_PROG(XIB, [ibtool], [no])
3813     AS_IF([test "x${XIB}" = "xno"], [
3814       AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3815     ])
3816   ])
3817 fi
3818 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3819
3820 dnl
3821 dnl  MacOS X sparkle update support
3822 dnl
3823 AC_ARG_ENABLE(sparkle,
3824   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3825 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3826 then
3827   if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3828   then
3829     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3830   fi
3831
3832   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3833 fi
3834 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3835
3836 dnl
3837 dnl  MacOS X breakpad creash reporter support
3838 dnl
3839 AC_ARG_WITH([breakpad],
3840   AS_HELP_STRING([--with-breakpad=URL], [Enable Breakpad reporter using given URL]), [], [with_breakpad=no])
3841
3842 AS_IF([test "$with_breakpad" != "no"], [
3843
3844   AS_IF([test "$with_breakpad" = "yes"], [
3845     AC_MSG_ERROR([You need to supply the CrashDragon Server URL as value for --with-breakpad])
3846   ])
3847
3848   AS_IF([test "$HAVE_OSX" != "1"], [
3849     AC_MSG_ERROR([Breakpad currently only works on macOS])
3850   ])
3851
3852   AC_MSG_CHECKING([for Breakpad framework])
3853   AS_IF([test ! -d ${CONTRIB_DIR}/Breakpad.framework -a \
3854               ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework], [
3855     AC_MSG_RESULT([no])
3856     AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3857   ], [
3858     AC_MSG_RESULT([yes])
3859     AC_DEFINE([HAVE_BREAKPAD], [1], [Define to 1 if breakpad is enabled.])
3860     AC_SUBST(BREAKPAD_URL, ["${with_breakpad}"])
3861   ])
3862
3863 ])
3864
3865 AM_CONDITIONAL(HAVE_BREAKPAD, [test "$with_breakpad" != "no"])
3866
3867 dnl
3868 dnl  Minimal Mac OS X module
3869 dnl
3870 AC_ARG_ENABLE(minimal-macosx,
3871   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3872 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3873 then
3874   VLC_ADD_PLUGIN([minimal_macosx])
3875 fi
3876
3877 dnl
3878 dnl Mac OS X fancy dmg build tool
3879 dnl
3880 if test "${HAVE_OSX}" = "1"
3881 then
3882   AC_PATH_PROG(DMGBUILD, dmgbuild, no)
3883   AS_IF([test "x${DMGBUILD}" = "xno"], [
3884     AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
3885   ])
3886 fi
3887 AM_CONDITIONAL(HAVE_DMGBUILD, [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
3888
3889 dnl
3890 dnl  VideoToolbox plugins
3891 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3892     VLC_ADD_PLUGIN([videotoolbox])
3893     VLC_ADD_PLUGIN([cvpx])
3894   ])
3895
3896 dnl
3897 dnl  ncurses module
3898 dnl
3899 AC_ARG_ENABLE(ncurses,
3900 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3901 have_ncurses="no"
3902 AS_IF([test "${enable_ncurses}" != "no"] ,[
3903   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3904     have_ncurses="yes"
3905     ALIASES="${ALIASES} nvlc"
3906   ], [
3907     AS_IF([test -n "${enable_ncurses}"], [
3908       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3909     ])
3910   ])
3911 ])
3912 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3913
3914 dnl
3915 dnl  Lirc plugin
3916 dnl
3917 AC_ARG_ENABLE(lirc,
3918   [  --enable-lirc           lirc support (default disabled)])
3919 have_lirc="no"
3920 AS_IF([test "${enable_lirc}" = "yes"], [
3921   AC_CHECK_HEADER(lirc/lirc_client.h, [
3922     AC_CHECK_LIB(lirc_client, lirc_init, [
3923       have_lirc="yes"
3924     ])
3925   ])
3926 ])
3927 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3928
3929 dnl
3930 dnl  SRT plugin
3931 dnl
3932 PKG_ENABLE_MODULES_VLC([SRT], [access_srt access_output_srt], [srt >= 1.2.2], [SRT input/output plugin], [auto], [], [], [-DENABLE_SRT])
3933
3934 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3935 dnl
3936 dnl  goom visualization plugin
3937 dnl
3938 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3939
3940 dnl
3941 dnl libprojectM visualization plugin
3942 dnl
3943 AC_ARG_ENABLE(projectm,
3944   [  --enable-projectm       projectM visualization plugin (default enabled)])
3945 AS_IF([test "${enable_projectm}" != "no"],
3946   [
3947     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3948     [
3949       VLC_ADD_PLUGIN([projectm])
3950       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3951         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3952         [ AC_MSG_WARN( [Using libprojectM version 1] )
3953       ])
3954     ],[
3955       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3956     ])
3957   ])
3958
3959 dnl
3960 dnl Vovoid VSXu visualization plugin
3961 dnl
3962 AC_ARG_ENABLE(vsxu,
3963   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3964 AS_IF([test "${enable_vsxu}" != "no"],
3965   [
3966     PKG_CHECK_MODULES(VSXU, libvsxu,
3967     [
3968       VLC_ADD_PLUGIN([vsxu])
3969     ],[
3970       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3971     ])
3972   ])
3973
3974 EXTEND_HELP_STRING([Service Discovery plugins:])
3975 dnl
3976 dnl  Avahi-Zeroconf services discovery
3977 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
3978
3979 dnl
3980 dnl  libudev services discovery
3981 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3982
3983 dnl
3984 dnl MTP devices services discovery
3985 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3986
3987 dnl
3988 dnl UPnP Plugin (Intel SDK)
3989 dnl
3990 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3991
3992 dnl
3993 dnl mDNS using libmicrodns
3994 dnl
3995 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
3996
3997
3998 EXTEND_HELP_STRING([Misc options:])
3999
4000 dnl
4001 dnl  libxml2 module
4002 dnl
4003 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4004
4005
4006 dnl
4007 dnl libgcrypt
4008 dnl
4009 AC_ARG_ENABLE(libgcrypt,
4010   [  --disable-libgcrypt     gcrypt support (default enabled)])
4011 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
4012 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4013
4014 # require libgcrypt >= 1.6.0
4015 AS_IF([test "${enable_libgcrypt}" != "no"], [
4016   AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4017     VLC_SAVE_FLAGS
4018     CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4019     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4020 [#include <gcrypt.h>
4021 #if GCRYPT_VERSION_NUMBER < 0x010600
4022 #error
4023 #endif]])], [
4024       ac_cv_lib_gcrypt=yes
4025     ], [
4026       ac_cv_lib_gcrypt=no
4027     ])
4028     VLC_RESTORE_FLAGS
4029   ])
4030
4031   AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4032     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4033   ], [
4034     AS_IF([test "${enable_libgcrypt}" = "yes"], [
4035       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4036     ])
4037   ])
4038 ])
4039
4040 AS_IF([test -z "$GCRYPT_LIBS"], [
4041   GCRYPT_LIBS="-lgcrypt -lgpg-error"
4042 ])
4043
4044 AC_SUBST(GCRYPT_CFLAGS)
4045 AC_SUBST(GCRYPT_LIBS)
4046 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4047
4048 dnl
4049 dnl TLS/SSL
4050 dnl
4051 AC_ARG_ENABLE(gnutls,
4052   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4053 AS_IF([test "${enable_gnutls}" != "no"], [
4054   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4055     VLC_ADD_PLUGIN([gnutls])
4056   ], [
4057     AS_IF([test -n "${enable_gnutls}"], [
4058       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4059     ])
4060   ])
4061 ])
4062
4063
4064 dnl
4065 dnl Taglib plugin
4066 dnl
4067 AC_ARG_ENABLE(taglib,
4068   [AS_HELP_STRING([--disable-taglib],
4069     [do not use TagLib (default enabled)])])
4070 AS_IF([test "${enable_taglib}" != "no"], [
4071   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4072     VLC_ADD_PLUGIN([taglib])
4073   ], [
4074     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4075 ])
4076
4077 dnl
4078 dnl  libsecret
4079 dnl
4080 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4081
4082 dnl
4083 dnl  kwallet
4084 dnl
4085 AC_ARG_ENABLE(kwallet,
4086   [AS_HELP_STRING([--enable-kwallet],
4087     [use kwallet (via D-Bus) for keystore (default enabled)])])
4088 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4089   VLC_ADD_PLUGIN([kwallet])
4090 ])
4091
4092 dnl
4093 dnl update checking system
4094 dnl
4095 AC_ARG_ENABLE(update-check,
4096   [  --enable-update-check   update checking system (default disabled)])
4097 if test "${enable_update_check}" = "yes"
4098 then
4099  AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4100     AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4101 fi
4102 AM_CONDITIONAL(UPDATE_CHECK, [test "${enable_update_check}" = "yes"])
4103
4104 dnl
4105 dnl OS X notification plugin
4106 dnl
4107 AC_ARG_ENABLE(osx_notifications,
4108   [  --enable-osx-notifications          osx notification plugin (default disabled)],,
4109   [enable_osx_notifications=no])
4110 AS_IF([test "${enable_osx_notifications}" != "no"], [
4111   if test -d ${CONTRIB_DIR}/Growl.framework -o -d ${CONTRIB_DIR}/Frameworks/Growl.framework
4112   then
4113       VLC_ADD_PLUGIN([osx_notifications])
4114       VLC_ADD_LIBS([osx_notifications], [-Wl,-framework,Growl,-framework,Foundation])
4115       VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4116   fi
4117 ])
4118
4119 dnl
4120 dnl Libnotify notification plugin
4121 dnl
4122 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4123
4124 dnl
4125 dnl  libplacebo support
4126 dnl
4127 AC_ARG_ENABLE(libplacebo,
4128   [AS_HELP_STRING([--disable-libplacebo],
4129       [disable libplacebo support (default auto)])])
4130
4131 AS_IF([test "$enable_libplacebo" != "no"], [
4132   PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 0.1], [
4133     AC_DEFINE([HAVE_LIBPLACEBO], [1], [Define to 1 if libplacebo is enabled.])
4134   ], [
4135     AS_IF([test -n "${enable_libplacebo}"], [
4136       AC_MSG_ERROR([${LIBPLACEBO_PKG_ERRORS}.])
4137     ])
4138     enable_libplacebo="no"
4139   ])
4140 ])
4141 AM_CONDITIONAL(HAVE_LIBPLACEBO, [test "$enable_libplacebo" != "no"])
4142
4143
4144 dnl
4145 dnl  Endianness check
4146 dnl
4147 AC_C_BIGENDIAN
4148 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4149   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4150 ], [
4151   DEFS_BIGENDIAN=""
4152 ])
4153 AC_SUBST(DEFS_BIGENDIAN)
4154
4155 dnl
4156 dnl Where to install KDE solid .desktop
4157 dnl
4158 AC_ARG_WITH(kde-solid,
4159   AS_HELP_STRING([--with-kde-solid=PATH],
4160                  [KDE Solid actions directory (auto)]),, [
4161
4162 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4163   with_kde_solid="yes"
4164 fi
4165 ])
4166 soliddatadir=""
4167 AS_IF([test "${with_kde_solid}" != "no"], [
4168   AS_IF([test "${with_kde_solid}" = "yes"], [
4169     kde4datadir="`${KDE4_CONFIG} --install data`"
4170     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4171     soliddatadir="${kde4datadir}/solid/actions"
4172   ], [
4173     soliddatadir="${with_kde_solid}"
4174   ])
4175 ])
4176 AC_SUBST(soliddatadir)
4177 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4178
4179 dnl
4180 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4181 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4182 dnl
4183 if test "${SYS}" = "mingw32"; then
4184     AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4185 fi
4186
4187 EXTEND_HELP_STRING([Components:])
4188
4189 dnl
4190 dnl  the VLC binary
4191 dnl
4192 AC_ARG_ENABLE(vlc,
4193   [  --enable-vlc            build the VLC media player (default enabled)])
4194 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4195
4196 dnl
4197 dnl Fuzzer (at the end in order to don't mess dependencies FLAGS)
4198 dnl
4199 AS_VAR_IF(with_libfuzzer, no, [], [
4200     LIBS="-lstdc++ ${LIBM} ${LIBPTHREAD} -L${with_libfuzzer} -lFuzzer"
4201     AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc-guard, [
4202         AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard])
4203         AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard], [CXXFLAGS])
4204         AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp])
4205         AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp], [CXXFLAGS])
4206     ], [
4207         AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc, [
4208             AX_APPEND_FLAG([-fsanitize-coverage=trace-pc])
4209             AX_APPEND_FLAG([-fsanitize-coverage=trace-pc], [CXXFLAGS])
4210         ], [
4211             AC_MSG_ERROR([Sanitizer coverage not supported by your compiler])
4212         ])
4213     ])
4214 ])
4215
4216 dnl
4217 dnl  Stuff used by the program
4218 dnl
4219 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4220 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4221 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4222 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4223 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4224 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4225 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4226 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4227 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4228 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4229 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4230 AC_SUBST(COPYRIGHT_MESSAGE)
4231 AC_SUBST(VERSION_MESSAGE)
4232 AC_SUBST(VERSION_MAJOR)
4233 AC_SUBST(VERSION_MINOR)
4234 AC_SUBST(VERSION_REVISION)
4235 AC_SUBST(VERSION_EXTRA)
4236 AC_SUBST(COPYRIGHT_YEARS)
4237 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4238 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4239 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4240 dnl
4241 dnl  Handle substvars that use $(top_srcdir)
4242 dnl
4243 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4244
4245 dnl
4246 dnl  Configuration is finished
4247 dnl
4248 AC_SUBST(SYS)
4249 AC_SUBST(ARCH)
4250 AC_SUBST(ALIASES)
4251 AC_SUBST(ASM)
4252 AC_SUBST(MOC)
4253 AC_SUBST(RCC)
4254 AC_SUBST(UIC)
4255 AC_SUBST(WINDRES)
4256 AC_SUBST(WINE_SDK_PATH)
4257 AC_SUBST(LIBEXT)
4258 AC_SUBST(AM_CPPFLAGS)
4259 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4260 AC_SUBST(FILE_LIBVLCCORE_DLL)
4261 AC_SUBST(FILE_LIBVLC_DLL)
4262
4263 AC_CONFIG_FILES([
4264   Makefile
4265   doc/Makefile
4266   modules/Makefile
4267   m4/Makefile
4268   po/Makefile.in
4269   share/Makefile
4270   compat/Makefile
4271   src/Makefile
4272   lib/Makefile
4273   bin/Makefile
4274   test/Makefile
4275   modules/hw/mmal/Makefile
4276   share/vlc.appdata.xml.in
4277 ])
4278
4279 AM_COND_IF([HAVE_WIN32], [
4280   AC_CONFIG_FILES([
4281     extras/package/win32/NSIS/spad.nsi
4282     extras/package/win32/NSIS/vlc.win32.nsi
4283     extras/package/win32/msi/config.wxi
4284   ])
4285 ])
4286
4287 AM_COND_IF([HAVE_DARWIN], [
4288   AC_CONFIG_FILES([
4289     modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4290     share/macosx/Info.plist:share/Info.plist.in
4291   ])
4292 ])
4293
4294 dnl Generate makefiles
4295 AC_OUTPUT
4296
4297 dnl Do we have to use make or gmake ?
4298 if make --version 2>&1|grep -q GNU
4299 then
4300     # GNU make, all seems good
4301     MAKE=make
4302 else
4303     # Known GNU make alias (on BSD)
4304     MAKE=gmake
4305 fi
4306 dnl Shortcut to nice compile message
4307 if test -n $SHELL; then
4308   SHELL=${CONFIG_SHELL-/bin/sh}
4309 fi
4310 rm -f compile
4311 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4312 echo "#! $SHELL
4313 rm -f .error\$\$
4314 ERROR=0
4315 export PATH=\"$PATH\" LANG=C
4316 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4317 test -f .error\$\$ && ERROR=1
4318 rm -f .error\$\$
4319 exit \$ERROR" >compile
4320 chmod a+x compile
4321
4322 echo "
4323 libvlc configuration
4324 --------------------
4325 version               : ${VERSION}
4326 system                : ${SYS}
4327 architecture          : ${ARCH}
4328 optimizations         : ${enable_optimizations}"
4329 if test "${enable_vlc}" != "no"; then
4330 echo "vlc aliases           :${ALIASES}"
4331 else
4332 echo "build vlc executable  : no"
4333 fi
4334 echo "
4335 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."