configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 2002-2011 the VideoLAN team])
   4
   5 AC_INIT(vlc, 1.2.0-git)
   6 VERSION_MAJOR=1
   7 VERSION_MINOR=2
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=git
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Twoflower"
  17 COPYRIGHT_YEARS="1996-2011"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests)
  28 AM_CONFIG_HEADER(config.h)
  29
  30 # Disable with "./configure --disable-silent-rules" or "make V=1"
  31 AM_SILENT_RULES([yes])
  32
  33 dnl Too many people are not aware of maintainer mode:
  34 dnl If you want to use it, you definitely know what you are doing, so
  35 dnl you can specify "--disable-maintainer-mode". But if you want the default
  36 dnl automake behavior, you've likely never heard of maintainer mode, so we
  37 dnl can't expect you to enable it manually.
  38 AS_IF([test "x${enable_maintainer_mode}" != "xno"],
  39     [enable_maintainer_mode="yes"])
  40 AM_MAINTAINER_MODE
  41
  42 dnl
  43 dnl Directories
  44 dnl
  45 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  46 dnl AC_SUBST(vlcincludedir)
  47 vlcdatadir="\${datadir}/\${PKGDIR}"
  48 AC_SUBST(vlcdatadir)
  49 vlclibdir="\${libdir}/\${PKGDIR}"
  50 AC_SUBST(vlclibdir)
  51
  52 dnl
  53 dnl Check for tools
  54 dnl
  55 AC_PROG_CC_C99
  56 AC_USE_SYSTEM_EXTENSIONS
  57 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  58 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  59 AC_DEFINE([_REENTRANT],, [Define to expose reentrant functions.])
  60 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  61 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  62
  63 AM_PROG_CC_C_O
  64 AC_PROG_CXX
  65 AC_PROG_CPP
  66 AC_PROG_OBJC
  67 _AM_DEPENDENCIES([OBJC])
  68 AC_PROG_EGREP
  69 AC_PROG_MAKE_SET
  70 AC_PROG_INSTALL
  71 AM_PROG_AS
  72
  73 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  74 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  75
  76 dnl Check for compiler properties
  77 AC_C_CONST
  78 AC_C_INLINE
  79 AC_C_RESTRICT
  80
  81 dnl
  82 dnl  Save *FLAGS
  83 dnl
  84 VLC_SAVE_FLAGS
  85
  86 dnl Extend the --help string at the current spot.
  87 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  88
  89 dnl Allow binary package maintainer to pass a custom string to avoid
  90 dnl cache problem
  91 AC_ARG_WITH(binary-version,
  92     AS_HELP_STRING([--with-binary-version=STRING],
  93          [To avoid plugins cache problem between binary version]),[],[])
  94 AS_IF([test -n "${with_binary_version}"],[
  95     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  96          [Binary specific version])
  97 ])
  98
  99 dnl
 100 dnl  Check for the contrib directory
 101 dnl
 102 AC_ARG_WITH(contrib,
 103   [AS_HELP_STRING([--with-contrib[=DIR]],
 104     [search for 3rd party libraries in DIR/include and DIR/lib])
 105 ])
 106 AC_MSG_CHECKING([for 3rd party libraries path])
 107 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 108   CONTRIB_DIR="${srcdir}/contrib/${host}"
 109   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 110     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 111     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 112     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 113       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 114       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
 115       AS_IF([test ! -d "${CONTRIB_DIR}"], [
 116         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 117         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
 118         AS_IF([test ! -d "${CONTRIB_DIR}"], [
 119           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 120           CONTRIB_DIR=""
 121           AC_MSG_RESULT([not found])
 122         ])
 123       ])
 124     ])
 125   ])
 126 ], [
 127   AS_IF([test "${with_contrib}" != "no"], [
 128     CONTRIB_DIR="${with_contrib}"
 129   ], [
 130     CONTRIB_DIR=""
 131     AC_MSG_RESULT([disabled])
 132   ])
 133 ])
 134 AS_IF([test -n "${CONTRIB_DIR}"], [
 135   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 136     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 137   ], [
 138     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 139     CONTRIB_DIR=""
 140     AC_MSG_RESULT([not usable])
 141   ])
 142
 143 ])
 144 AS_IF([test -n "${CONTRIB_DIR}"], [
 145   AC_MSG_RESULT([${CONTRIB_DIR}])
 146   export PATH=${CONTRIB_DIR}/bin:$PATH
 147   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 148   CPPFLAGS_save="${CPPFLAGS_save} -I${CONTRIB_DIR}/include"
 149   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 150   CFLAGS_save="${CFLAGS_save} -I${CONTRIB_DIR}/include"
 151   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 152   CXXFLAGS_save="${CXXFLAGS_save} -I${CONTRIB_DIR}/include"
 153   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
 154   OBJCFLAGS_save="${OBJCFLAGS_save} -I${CONTRIB_DIR}/include"
 155   AS_IF([test "$build" = "$host" -o "$PKG_CONFIG_LIBDIR"], [
 156     export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 157   ], [
 158     export PKG_CONFIG_LIBDIR="${CONTRIB_DIR}/lib/pkgconfig"
 159   ])
 160   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 161   LDFLAGS_save="${LDFLAGS_save} -L${CONTRIB_DIR}/lib"
 162
 163   AS_IF([test "${SYS}" = "darwin"], [
 164     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 165     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 166   ])
 167 ], [
 168   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 169     AC_MSG_ERROR([Third party libraries not found!])
 170   ])
 171 ])
 172 AC_SUBST(CONTRIB_DIR)
 173
 174 dnl
 175 dnl  Set default values
 176 dnl
 177 LDFLAGS_vlc="${LDFLAGS}"
 178
 179 dnl
 180 dnl  Check the operating system
 181 dnl
 182 HAVE_WIN64="0"
 183 case "${host_os}" in
 184   "")
 185     SYS=unknown
 186     ;;
 187   linux*)
 188     SYS=linux
 189     ;;
 190   bsdi*)
 191     SYS=bsdi
 192     CFLAGS_save="${CFLAGS_save} -pthread"; CFLAGS="${CFLAGS_save}"
 193     VLC_ADD_LIBS([vcd cdda vcdx],[-ldvd])
 194     ;;
 195   *bsd*)
 196     SYS="${host_os}"
 197     CFLAGS_save="${CFLAGS_save} -pthread"; CFLAGS="${CFLAGS_save}"
 198     case "${host_os}" in
 199       freebsd*)
 200         CPPFLAGS_save="${CPPFLAGS_save} -I/usr/local/include"
 201         CPPFLAGS="${CPPFLAGS_save}"
 202         LDFLAGS_save="${LDFLAGS_save} -L/usr/local/lib"
 203         LDFLAGS="${LDFLAGS_save}"
 204         ;;
 205       openbsd*)
 206         CPPFLAGS_save="${CPPFLAGS_save} -I/usr/local/include -I/usr/X11R6/include"
 207         CPPFLAGS="${CPPFLAGS_save}"
 208         LDFLAGS_save="${LDFLAGS_save} -L/usr/local/lib -L/usr/X11R6/lib/"
 209         LDFLAGS="${LDFLAGS_save}"
 210         ;;
 211     esac
 212     ;;
 213   darwin*)
 214
 215     dnl Force gcc "-arch" flag
 216     ARCH_flag=""
 217     case "${host}" in
 218       i386*)
 219         ARCH_flag="-arch i386"
 220       ;;
 221       ppc64*)
 222         ARCH_flag="-arch ppc64"
 223       ;;
 224       ppc*)
 225         ARCH_flag="-arch ppc"
 226       ;;
 227       x86_64*)
 228         ARCH_flag="-arch x86_64"
 229       ;;
 230     esac
 231
 232     SYS=darwin
 233     CFLAGS_save="${CFLAGS_save} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"; CFLAGS="${CFLAGS_save}"
 234     CXXFLAGS_save="${CXXFLAGS_save} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"; CXXFLAGS="${CXXFLAGS_save}"
 235     CPPFLAGS_save="${CPPFLAGS_save} ${ARCH_flag}"; CPPFLAGS="${CPPFLAGS_save}"
 236     OBJCFLAGS_save="${OBJCFLAGS_save} -D_INTL_REDIRECT_MACROS -std=gnu99 ${ARCH_flag}"; OBJCFLAGS="${OBJCFLAGS_save}"
 237     LDFLAGS_save="${LDFLAGS_save} -Wl,-headerpad_max_install_names ${ARCH_flag}"; LDFLAGS="${LDFLAGS_save}"
 238     VLC_ADD_LIBS([mkv mp4 motion], [-Wl,-framework,IOKit,-framework,CoreFoundation])
 239     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup])
 240     VLC_ADD_LIBS([avcodec avformat access_avio swscale postproc i420_rgb_mmx x264],[-Wl,-read_only_relocs,suppress])
 241     VLC_ADD_CFLAGS([motion],[-fconstant-cfstrings])
 242     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation])
 243     AC_ARG_ENABLE(macosx-defaults,
 244       AS_HELP_STRING([--enable-macosx-defaults],[Build the default configuration on Mac OS X (default enabled)]))
 245     if test "x${enable_macosx_defaults}" != "xno"
 246     then
 247         echo ""
 248         echo "Building with Mac OS X defaults:"
 249         build_dir=`pwd`
 250         echo "  Assuming --prefix=${build_dir}/vlc_install_dir"
 251         ac_default_prefix="${build_dir}/vlc_install_dir"
 252         enable_faad="yes"
 253         echo "  Assuming --enable-faad"
 254         enable_flac="yes"
 255         echo "  Assuming --enable-flac"
 256         enable_theora="yes"
 257         echo "  Assuming --enable-theora"
 258         enable_shout="yes"
 259         echo "  Assuming --enable-shout"
 260         enable_vcdx="yes"
 261         echo "  Assuming --enable-vcdx"
 262         enable_caca="yes"
 263         echo "  Assuming --enable-caca"
 264         enable_ncurses="yes"
 265         echo "  Assuming --enable-ncurses"
 266         enable_twolame="yes"
 267         echo "  Assuming --enable-twolame"
 268         enable_realrtsp="yes"
 269         echo "  Assuming --enable-realrtsp"
 270         enable_libass="yes"
 271         echo "  Assuming --enable-libass"
 272
 273         enable_skins2="no"
 274         echo "  Assuming --disable-skins2"
 275         enable_xcb="no"
 276         echo "  Assuming --disable-xcb"
 277     fi
 278     dnl
 279     dnl  Check for Mac OS X SDK settings
 280     dnl
 281     AC_ARG_WITH(macosx-sdk,
 282       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 283         [compile using the SDK in DIR])])
 284     if test "${with_macosx_sdk}" != "" ; then
 285         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 286         CC="${CC} -isysroot ${with_macosx_sdk}"
 287         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 288         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 289         LD="${LD} -syslibroot ${with_macosx_sdk}"
 290     else
 291         echo "  No desired SDK version given, falling back to 10.5"
 292         CPP="${CPP} -isysroot /Developer/SDKs/MacOSX10.5.sdk"
 293         CC="${CC} -isysroot /Developer/SDKs/MacOSX10.5.sdk"
 294         CXX="${CXX} -isysroot /Developer/SDKs/MacOSX10.5.sdk"
 295         OBJC="${OBJC} -isysroot /Developer/SDKs/MacOSX10.5.sdk"
 296         LD="${LD} -syslibroot /Developer/SDKs/MacOSX10.5.sdk"
 297         with_macosx_version_min="10.5"
 298         echo "  Assuming --with-macosx-version-min=10.5"
 299     fi
 300     AC_ARG_WITH(macosx-version-min,
 301       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 302         [compile for MacOS X VERSION and above])])
 303     if test "${with_macosx_version_min}" != "" ; then
 304         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 305         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 306         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 307         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 308         LD="${LD} -macosx_version_min=${with_macosx_version_min}"
 309         CFLAGS_save="${CFLAGS_save} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"; CFLAGS="${CFLAGS_save}"
 310         CXXFLAGS_save="${CXXFLAGS_save} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"; CXXFLAGS="${CXXFLAGS_save}"
 311         OBJCFLAGS_save="${OBJCFLAGS_save} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"; OBJCFLAGS="${OBJCFLAGS_save}"
 312         MACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}
 313         export MACOSX_DEPLOYMENT_TARGET
 314     fi
 315     ;;
 316   *mingw32* | *cygwin* | *wince* | *mingwce*)
 317     AC_CHECK_TOOL(WINDRES, windres, :)
 318     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 319     AC_DEFINE([_WIN32_WINNT], 0x0502, [Define to '0x0502' for Windows XP SP2 APIs.])
 320     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 321
 322     case "${host_os}" in
 323       *wince* | *mingwce* | *mingw32ce*)
 324         SYS=mingwce
 325         dnl Sadly CeGCC still needs non-wince macros
 326         ;;
 327       *mingw32*)
 328         SYS=mingw32
 329         ;;
 330       *cygwin*)
 331         dnl Check if we are using the mno-cygwin mode in which case we are
 332         dnl actually dealing with a mingw32 compiler.
 333         AC_EGREP_CPP(yes,
 334             [#ifdef WIN32
 335              yes
 336              #endif],
 337             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 338         ;;
 339     esac
 340
 341     if test "${SYS}" = "mingw32"; then
 342         VLC_ADD_LIBS([libvlccore],[-lnetapi32 -lwinmm])
 343         VLC_ADD_LDFLAGS([vlc],[-mwindows])
 344         VLC_ADD_LIBS([win32text],[-lgdi32])
 345         VLC_ADD_LIBS([cdda vcdx sdl_image vout_sdl],[-lwinmm])
 346         dnl
 347         dnl DEP and ASLR options
 348         dnl
 349         AC_ARG_WITH(peflags,
 350           [AS_HELP_STRING([--with-peflags],
 351             [use peflags (default enabled on Windows)])])
 352         if test "${with_peflags}" != "no" ; then
 353           AC_PATH_TOOL(PEFLAGS, peflags, :)
 354         fi
 355         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 356         ac_default_prefix="`pwd`/_win32"
 357         DESTDIR="`pwd`/_win32/"
 358
 359         dnl
 360         dnl NSIS Installer prefix and WIN64
 361         dnl
 362         case "${host}" in
 363             amd64*|i686-w64*|x86_64*)
 364                 HAVE_WIN64="1"
 365                 PROGRAMFILES="PROGRAMFILES64"
 366             ;;
 367             *)
 368                 PROGRAMFILES="PROGRAMFILES"
 369             ;;
 370         esac
 371         AC_SUBST(PROGRAMFILES)
 372
 373     fi
 374     if test "${SYS}" = "mingwce"; then
 375         VLC_ADD_LIBS([libvlccore],[-lmmtimer])
 376         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 377         ac_default_prefix="`pwd`/_wince"
 378         DESTDIR="`pwd`/_wince/"
 379     fi
 380     ;;
 381   *nto*)
 382     SYS=nto
 383     ;;
 384   solaris*)
 385     SYS=solaris
 386     ;;
 387   hpux*)
 388     SYS=hpux
 389     ;;
 390   symbian*)
 391     SYS=symbian
 392     ;;
 393   *os2*)
 394     SYS=os2
 395     LDFLAGS_save="${LDFLAGS_save} -Zomf -Zbin-files -Zargs-wild"; LDFLAGS="${LDFLAGS_save}"
 396     ;;
 397   *)
 398     SYS="${host_os}"
 399     ;;
 400 esac
 401 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 402 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 403 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 404 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 405 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1")
 406 AM_CONDITIONAL(HAVE_WINCE,   test "${SYS}" = "mingwce")
 407 AM_CONDITIONAL(HAVE_SYMBIAN, test "${SYS}" = "symbian")
 408 AM_CONDITIONAL(USE_PEFLAGS,  test "${with_peflags}" = "yes")
 409
 410 dnl
 411 dnl Sadly autoconf doesn't think about testing foo.exe when ask to test
 412 dnl for program foo on win32
 413
 414 case "${build_os}" in
 415     cygwin|msys)
 416         ac_executable_extensions=".exe"
 417     ;;
 418     *)
 419     ;;
 420 esac
 421
 422 dnl Android is linux, but a bit different
 423 AS_IF([test "$SYS" = linux],[
 424     AC_MSG_CHECKING([for an Android system])
 425     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 426         [[#ifndef __ANDROID__
 427          # error Not Android
 428          #endif
 429         ]],[[;]])
 430     ],[
 431       HAVE_ANDROID="1"
 432       AC_MSG_RESULT([yes])
 433     ],[
 434       AC_MSG_RESULT([no])
 435     ])
 436 ])
 437 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 438
 439 dnl
 440 dnl  Libtool
 441 dnl  It's very bad, but our former custom system was worst
 442 dnl  -- Courmisch
 443 dnl
 444
 445 dnl override platform specific check for dependent libraries
 446 dnl otherwise libtool linking of shared libraries will
 447 dnl fail on anything other than pass_all.
 448 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 449     [lt_cv_deplibs_check_method=pass_all])
 450
 451 LT_INIT([dlopen win32-dll shared disable-static])
 452 LT_LANG([C++])
 453 LT_LANG([Windows Resource])
 454
 455 m4_undefine([AC_DEPLIBS_CHECK_METHOD])
 456 m4_defun([AC_DEPLIBS_CHECK_METHOD],[])
 457
 458 lt_cv_deplibs_check_method=pass_all
 459
 460 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 461   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 462 ])
 463
 464 dnl
 465 dnl Gettext stuff
 466 dnl
 467 AM_GNU_GETTEXT_VERSION([0.18.1])
 468 AM_GNU_GETTEXT([external])
 469
 470 dnl
 471 dnl Iconv stuff
 472 dnl
 473 AM_ICONV
 474
 475 dnl Check for broken versions of mingw-runtime compatability library
 476 AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"], [
 477     AC_MSG_CHECKING(for broken mingw-runtime)
 478     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 479 #include <_mingw.h>
 480 #if (__MINGW32_MAJOR_VERSION == 3) && (__MINGW32_MINOR_VERSION < 15)
 481 #ifndef __MINGW64_VERSION_MAJOR
 482 # error Attempting to use mingw-runtime with broken vsnprintf support
 483 #endif
 484 #endif
 485     ])], [
 486         AC_MSG_RESULT([ok])
 487     ], [
 488         AC_MSG_RESULT([present])
 489         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher!])
 490     ])
 491     dnl force use of mingw provided c99 *printf over msvcrt
 492     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 493     CPPFLAGS_save="${CPPFLAGS_save} -D__USE_MINGW_ANSI_STDIO=1"
 494 ])
 495
 496 dnl Check for the need to include the mingwex lib for mingw32
 497 if test "${SYS}" = "mingw32" ; then
 498     AC_CHECK_LIB(mingwex,opendir,
 499         AC_CHECK_LIB(mingw32,opendir,,
 500             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 501     )
 502 fi
 503
 504 dnl Check for fnative-struct or mms-bitfields support for mingw32
 505 if test "${SYS}" = "mingw32" ; then
 506     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 507         [ac_cv_c_mms_bitfields],
 508         [CFLAGS="${CFLAGS_save} -mms-bitfields"
 509          AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 510     if test "${ac_cv_c_mms_bitfields}" != "no"; then
 511         CFLAGS_save="${CFLAGS_save} -mms-bitfields";
 512         CXXFLAGS_save="${CXXFLAGS_save} -mms-bitfields";
 513     else
 514         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 515             [ac_cv_c_fnative_struct],
 516             [CFLAGS="${CFLAGS_save} -fnative-struct"
 517              AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 518         if test "${ac_cv_c_fnative_struct}" != "no"; then
 519             CFLAGS_save="${CFLAGS_save} -fnative-struct";
 520             CXXFLAGS_save="${CXXFLAGS_save} -fnative-struct";
 521         fi
 522     fi
 523
 524     CFLAGS="${CFLAGS_save}"; CXXFLAGS="${CXXFLAGS_save}"
 525 fi
 526
 527 dnl
 528 dnl Buggy glibc prevention. Purposedly not cached.
 529 dnl See sourceware.org bugs 5058 and 5443.
 530 dnl Ubuntu alone has 20 bug numbers for this...
 531 dnl
 532 AC_MSG_CHECKING(for buggy GNU/libc versions)
 533 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 534 #include <limits.h>
 535 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 536   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 537 # error GNU/libc with dcgettext killer bug!
 538 #endif
 539 ])], [
 540   AC_MSG_RESULT([not present])
 541 ], [
 542   AC_MSG_RESULT([found])
 543   AS_IF([test "x${enable_nls}" != "xno"], [
 544     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 545 work-around for this. Check with your distribution vendor on how to update the
 546 glibc run-time. Alternatively, build with --disable-nls.])
 547   ], [
 548     AC_DEFINE(DISABLE_BUGGY_GLIBC_CHECK, 1, [Disables runtime check for buggy glibc.])
 549   ])
 550 ])
 551
 552 dnl Plugin compilation stuff
 553
 554 VLC_LIBRARY_SUFFIX
 555
 556 dnl Check for system libs needed
 557 need_libc=false
 558
 559 dnl Check for usual libc functions
 560 AC_CHECK_DECLS([nanosleep],,,[#include <time.h>])
 561 AC_CHECK_FUNCS([daemon fcntl fstatvfs fork getenv getpwuid_r if_nameindex if_nametoindex isatty lstat memalign mmap openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp uselocale])
 562 AC_REPLACE_FUNCS([asprintf atof atoll dirfd fdopendir flockfile fsync getdelim getpid gmtime_r lldiv localtime_r nrand48 rewind setenv strcasecmp strcasestr strdup strlcpy strncasecmp strndup strnlen strsep strtof strtok_r strtoll swab tdestroy vasprintf])
 563 AC_CHECK_FUNCS(fdatasync,,
 564   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 565 ])
 566
 567 # Windows CE doesn't have strcoll()
 568 AC_FUNC_STRCOLL
 569
 570 dnl Check for non-standard system calls
 571 AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity])
 572
 573 AH_BOTTOM([#include <vlc_fixups.h>])
 574
 575 dnl Check for poll
 576 AC_SEARCH_LIBS(poll, [poll], [
 577   AC_DEFINE(HAVE_POLL, 1, [Define to 1 if the OS has poll().])
 578 ], [
 579   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"], [
 580     AC_MSG_ERROR([poll() is required.])
 581   ])
 582 ])
 583
 584 dnl Check for struct pollfd
 585 AC_CHECK_TYPES([struct pollfd],,,
 586 [#include <sys/types.h>
 587 #if HAVE_POLL
 588 # include <poll.h>
 589 #elif defined (WIN32)
 590 # include <winsock2.h>
 591 #endif
 592 ])
 593
 594 dnl Check for connect
 595 LIBS_save="$LIBS"
 596 SOCKET_LIBS=""
 597 AC_SEARCH_LIBS(connect, [socket], [
 598   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 599     SOCKET_LIBS="$ac_cv_search_connect"
 600   ])
 601 ], [
 602   AS_IF([test "${SYS}" = "mingw32"], [
 603     SOCKET_LIBS="-lws2_32"
 604   ])
 605   AS_IF([test "${SYS}" = "mingwce"], [
 606     SOCKET_LIBS="-lws2"
 607   ])
 608 ])
 609 LIBS="$LIBS_save"
 610 AS_IF([test -n "$SOCKET_LIBS"], [
 611   VLC_ADD_LIBS([access_http access_mms access_udp access_tcp access_ftp access_rtmp access_output_udp access_output_shout sap stream_out_select stream_out_standard stream_out_rtp stream_out_raop vod_rtsp access_realrtsp rtp oldrc netsync gnutls flac ts audioscrobbler lua remoteosd zvbi audiobargraph_a netsync],[${SOCKET_LIBS}])
 612 ])
 613 AC_SUBST(SOCKET_LIBS)
 614
 615 dnl Check for socklen_t
 616 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 617 AC_CACHE_CHECK([for socklen_t in sys/socket.h],
 618 ac_cv_type_socklen_t,
 619 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 620 [#include <sys/types.h>
 621 #ifdef WIN32
 622 # include <winsock2.h>
 623 # include <ws2tcpip.h>
 624 #else
 625 # include <sys/socket.h>
 626 #endif]], [[socklen_t len; len = 0;]])],
 627 ac_cv_type_socklen_t=yes,
 628 ac_cv_type_socklen_t=no)])
 629 AS_IF([test "$ac_cv_type_socklen_t" = no],
 630  [AC_DEFINE(socklen_t, int)])
 631
 632 dnl Check for struct sockaddr_storage
 633 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.])
 634 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.])
 635 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 636   [AC_TRY_COMPILE(
 637     [#include <sys/types.h>
 638      #if defined( UNDER_CE )
 639      # include <winsock2.h>
 640      #elif defined( WIN32 )
 641      # include <winsock2.h>
 642      #else
 643      # include <sys/socket.h>
 644      #endif], [struct sockaddr_storage addr;],
 645      ac_cv_struct_sockaddr_storage=yes,
 646      ac_cv_struct_sockaddr_storage=no)])
 647 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 648   AC_DEFINE(sockaddr_storage, sockaddr)
 649   AC_DEFINE(ss_family, sa_family)
 650 ])
 651
 652 dnl getaddrinfo, getnameinfo and gai_strerror check
 653 dnl  -lnsl and -lsocket are needed on Solaris;
 654 dnl  we purposedly make the test fail on Windows
 655 LIBS_save="${LIBS}"
 656 AC_SEARCH_LIBS([getaddrinfo], [nsl],,, [${SOCKET_LIBS}])
 657 LIBS="${LIBS_save}"
 658
 659 AC_CHECK_FUNCS(inet_aton,,[
 660   AC_CHECK_LIB(resolv,inet_aton,[
 661     VLC_ADD_LIBS([libvlccore],[-lresolv])
 662   ])
 663 ])
 664
 665 dnl FreeBSD has a gnugetopt library for this:
 666 GNUGETOPT_LIBS=""
 667 AC_CHECK_FUNC(getopt_long,, [
 668   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 669     GNUGETOPT_LIBS="-lgnugetopt"
 670   ])
 671 ])
 672 AC_SUBST(GNUGETOPT_LIBS)
 673
 674 AC_CHECK_LIB(m,cos,[
 675   VLC_ADD_LIBS([adjust wave ripple psychedelic gradient a52tofloat32 dtstofloat32 x264 goom visual panoramix rotate noise grain scene kate flac lua chorus_flanger freetype avcodec avformat access_avio swscale postproc i420_rgb faad twolame equalizer spatializer param_eq samplerate freetype mod mpc dmo quicktime realvideo qt4 compressor headphone_channel_mixer normvol audiobargraph_a speex mono colorthres extract ball access_imem hotkeys mosaic gaussianblur dbus x264],[-lm])
 676   LIBM="-lm"
 677 ], [
 678   LIBM=""
 679 ])
 680 AC_SUBST(LIBM)
 681
 682 AC_CHECK_LIB(m,lrintf, [
 683   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 684   VLC_ADD_LIBS([skins2],[-lm])
 685 ])
 686
 687 dnl Check for dynamic plugins
 688 LIBDL=""
 689 have_dynamic_objects="no"
 690 LIBS_save="$LIBS"
 691 AC_SEARCH_LIBS(dlopen, [dl svld], [
 692   AS_IF([test "$ac_cv_search_dlopen" != "none required"], [
 693     LIBDL="$ac_cv_search_dlopen"
 694   ])
 695   have_dynamic_objects="yes"
 696 ])
 697 LIBS="$LIBS_save"
 698
 699 # Windows
 700 AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"], [
 701   LIBDL=""
 702   have_dynamic_objects="yes" #assume we can use shared objects
 703 ])
 704
 705 test "${enable_shared}" = "no" && have_dynamic_objects=no
 706
 707 AS_IF([test "${have_dynamic_objects}" != "no"], [
 708   AC_DEFINE(HAVE_DYNAMIC_PLUGINS, 1,
 709             [Define to 1 if dynamic plugins are supported.])
 710 ], [
 711   dnl Clear $LIBDL so as not to break linking
 712   LIBDL=""
 713 ])
 714 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 715
 716 AC_SUBST(LIBDL)
 717 VLC_ADD_LIBS([realvideo lua],[$LIBDL])
 718
 719 dnl Check for thread library
 720 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
 721   dnl Check for pthreads - borrowed from XMMS
 722   THREAD_LIB=error
 723   if test "${THREAD_LIB}" = "error"; then
 724     AC_CHECK_LIB(pthread,main,THREAD_LIB="-lpthread")
 725   fi
 726   if test "${THREAD_LIB}" = "error"; then
 727     AC_CHECK_LIB(pthreads,main,THREAD_LIB="-lpthreads")
 728   fi
 729   if test "${THREAD_LIB}" = "error"; then
 730     AC_CHECK_LIB(c_r,main,THREAD_LIB="-lc_r")
 731   fi
 732   if test "${THREAD_LIB}" = "error"; then
 733     AC_CHECK_FUNCS(pthread_mutex_lock)
 734     THREAD_LIB=""
 735   fi
 736
 737   VLC_ADD_LIBS([libvlccore libvlc vlc plugin],[${THREAD_LIB}])
 738
 739   AC_CHECK_LIB(rt, clock_nanosleep, [
 740     VLC_ADD_LIBS([libvlccore],[-lrt])
 741   ], [
 742     AC_CHECK_FUNC(nanosleep,,[
 743       AC_CHECK_LIB(rt,nanosleep, [
 744         VLC_ADD_LIBS([libvlccore],[-lrt])
 745       ], [
 746         AC_CHECK_LIB(posix4,nanosleep, [
 747           VLC_ADD_LIBS([libvlccore],[-lposix4])
 748         ])
 749       ])
 750     ])
 751     dnl HP/UX port
 752     AC_CHECK_LIB(rt,sem_init, [VLC_ADD_LIBS([libvlccore],[-lrt])])
 753   ])
 754 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
 755
 756 dnl Check for misc headers
 757 AC_MSG_CHECKING(for strncasecmp in strings.h)
 758 AC_EGREP_HEADER(strncasecmp,strings.h,[
 759   AC_MSG_RESULT(yes)
 760   AC_DEFINE(STRNCASECMP_IN_STRINGS_H, 1,
 761             Define if <strings.h> defines strncasecmp.)],[
 762   AC_MSG_RESULT(no)])
 763
 764 dnl Check for headers
 765 AC_CHECK_HEADERS([search.h])
 766 AC_CHECK_HEADERS(getopt.h strings.h locale.h xlocale.h)
 767 AC_CHECK_HEADERS(fcntl.h sys/time.h sys/ioctl.h sys/stat.h)
 768 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h netinet/udplite.h sys/eventfd.h])
 769 AC_CHECK_HEADERS([net/if.h], [], [],
 770   [
 771     #include <sys/types.h>
 772     #include <sys/socket.h>
 773   ])
 774 AC_CHECK_HEADERS([sys/mount.h], [], [],
 775   [
 776     #include <sys/param.h>
 777   ])
 778
 779 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
 780   AC_CHECK_HEADERS(machine/param.h sys/shm.h)
 781   AC_CHECK_HEADERS([linux/version.h linux/dccp.h scsi/scsi.h linux/magic.h])
 782   AC_CHECK_HEADERS(syslog.h)
 783 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
 784
 785 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 786 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.])
 787 AC_CHECK_TYPE(ssize_t,, [
 788   AC_DEFINE(ssize_t, int)
 789 ])
 790
 791 dnl Check for threads library
 792 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
 793   AC_CHECK_HEADERS(pthread.h)
 794 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
 795
 796 dnl It seems that autoconf detects pkg-config only during the first
 797 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 798 dnl it is nested within a conditional block, so it was not working right.
 799 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 800 AC_ARG_VAR(PKG_CONFIG_PATH,
 801        [Paths where to find .pc not at the default location])
 802 PKG_PROG_PKG_CONFIG()
 803
 804 dnl On some OS we need static linking
 805 AS_IF([test -n "${PKG_CONFIG}" ],[
 806     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 807         PKG_CONFIG="${PKG_CONFIG} --static"
 808     ])
 809 ])
 810
 811
 812 dnl
 813 dnl Check for zlib.h and -lz along with system -lminizip if available
 814 dnl
 815 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 816 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 817 if test "${have_zlib}" = "yes"
 818 then
 819   VLC_ADD_LIBS([access_http mp4 skins2 sap mkv unzip zip],[-lz])
 820   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 821     AC_CHECK_HEADERS([unzip.h], [
 822       have_minizip=yes
 823       MINIZIP_LIBS="-lminizip -lz"
 824     ], [
 825       have_minizip=no
 826       MINIZIP_CFLAGS="-I\\\${top_srcdir}/modules/access/zip/unzip"
 827       MINIZIP_LIBS="\\\${top_builddir}/modules/access/zip/unzip/libunzip.la"
 828     ])
 829   ])
 830   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
 831   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
 832 fi
 833 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 834
 835
 836 dnl Manual switch for UTF-8
 837 AC_ARG_ENABLE(non-utf8,
 838   [AS_HELP_STRING([--enable-non-utf8],
 839     [support legacy non-UTF-8 systems (default disabled)])],, [
 840   AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce" -o "${SYS}" = "os2"], [
 841     enable_non_utf8="no"
 842   ])
 843 ])
 844 AS_IF([test "${enable_non_utf8}" != "no"], [
 845   AC_DEFINE([ASSUME_UTF8], [1],
 846             [Define to 1 if the operating system uses UTF-8 internally])
 847 ])
 848
 849
 850 dnl Check for dbus
 851 AC_ARG_ENABLE(dbus,
 852   [AS_HELP_STRING([--enable-dbus],
 853     [compile D-Bus message bus support (default enabled)])])
 854 case "${SYS}" in
 855     linux*|*bsd*)
 856 if test "${enable_dbus}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
 857 then
 858   dnl api stable dbus
 859   PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0.0,
 860     [ AC_DEFINE( HAVE_DBUS, 1, [Define if you have the D-BUS library] )
 861       VLC_ADD_LIBS([libvlccore],[$DBUS_LIBS])
 862       VLC_ADD_CFLAGS([libvlccore],[$DBUS_CFLAGS])
 863       dnl Check for dbus control interface
 864         AC_ARG_ENABLE(dbus-control,
 865           [AS_HELP_STRING([--disable-dbus-control],
 866             [D-Bus control interface (default enabled)])])
 867         if test "${enable_dbus_control}" != "no"
 868         then
 869           VLC_ADD_PLUGIN([dbus])
 870           VLC_ADD_LIBS([dbus],[$DBUS_LIBS])
 871           VLC_ADD_CFLAGS([dbus],[$DBUS_CFLAGS])
 872         fi
 873       dnl Check for Telepathy
 874         AC_ARG_ENABLE(telepathy,
 875           AS_HELP_STRING([--enable-telepathy],[Telepathy Presence plugin through DBus(default enabled)]))
 876         if test "${enable_telepathy}" != "no"; then
 877           VLC_ADD_PLUGIN([telepathy])
 878           VLC_ADD_LIBS([telepathy],[$DBUS_LIBS])
 879           VLC_ADD_CFLAGS([telepathy],[$DBUS_CFLAGS])
 880         fi
 881         dnl Power Management Inhibiter
 882         VLC_ADD_PLUGIN([inhibit])
 883         VLC_ADD_LIBS([inhibit],[$DBUS_LIBS])
 884         VLC_ADD_CFLAGS([inhibit],[$DBUS_CFLAGS])
 885     ],
 886     [AC_MSG_ERROR([Couldn't find DBus >= 1.0.0, install libdbus-dev ?])]
 887   )
 888 fi
 889 ;;
 890 esac
 891
 892 dnl Check for ntohl, etc.
 893 AC_CACHE_CHECK([for ntohl in sys/param.h],
 894     [ac_cv_c_ntohl_sys_param_h],
 895     [CFLAGS="${CFLAGS_save} -Wall -Werror"
 896      AC_TRY_COMPILE([#include <sys/param.h>],
 897         [int meuh; ntohl(meuh);],
 898         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
 899 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
 900     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
 901 fi
 902
 903 EXTEND_HELP_STRING([Optimization options:])
 904 VLC_RESTORE_FLAGS
 905 dnl
 906 dnl  Compiler warnings
 907 dnl
 908
 909 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration])
 910 RDC_PROG_CC_FLAGS([-pipe])
 911 AC_LANG_PUSH([C++])
 912 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var])
 913 AC_LANG_POP([C++])
 914
 915 dnl
 916 dnl  Debugging mode
 917 dnl
 918 AC_ARG_ENABLE(debug,
 919   [AS_HELP_STRING([--enable-debug],
 920     [build with run-time assertions (default disabled)])],,
 921   [enable_debug="no"])
 922 AH_TEMPLATE(NDEBUG,
 923             [Define to 1 if debug code should NOT be compiled])
 924 AS_IF([test "${enable_debug}" != "no"], [
 925   AC_CHECK_HEADERS([valgrind/valgrind.h])
 926 ], [
 927   AC_DEFINE(NDEBUG)
 928 ])
 929
 930 dnl
 931 dnl  Profiling
 932 dnl
 933 AC_ARG_ENABLE(gprof,
 934   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 935   [enable_gprof="no"])
 936 AS_IF([test "${enable_gprof}" != "no"], [
 937   CFLAGS="${CFLAGS} -pg"
 938   CXXFLAGS="${CXXFLAGS} -pg"
 939   OBJCFLAGS="${OBJCFLAGS} -pg"
 940   LDFLAGS="${LDFLAGS} -pg"
 941 ])
 942
 943 AC_ARG_ENABLE(cprof,
 944   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 945   [enable_cprof="no"])
 946 AS_IF([test "${enable_gprof}" != "no"], [
 947   CFLAGS="${CFLAGS} -finstrument-functions"
 948   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 949   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 950   LDFLAGS="${LDFLAGS} -finstrument-functions"
 951 ])
 952
 953 dnl
 954 dnl  Test coverage
 955 dnl
 956 AC_ARG_ENABLE(coverage,
 957   [AS_HELP_STRING([--enable-coverage],
 958     [build for test coverage (default disabled)])],,
 959   [enable_coverage="no"])
 960 AS_IF([test "${enable_coverage}" != "no"], [
 961   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 962   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 963   LDFLAGS="-lgcov ${LDFLAGS}"
 964 ])
 965
 966 VLC_SAVE_FLAGS
 967
 968 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"], [
 969   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
 970                  [ac_cv_c_visibility_hidden], [
 971     CFLAGS="${CFLAGS_save} -fvisibility=hidden"
 972     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 973       ac_cv_c_visibility_hidden=yes
 974     ], [
 975       ac_cv_c_visibility_hidden=no
 976     ])
 977   ])
 978   AS_IF([test "${ac_cv_c_visibility_hidden}" != "no"], [
 979     VLC_RESTORE_FLAGS
 980     CFLAGS="${CFLAGS} -fvisibility=hidden"
 981     CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
 982     OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
 983     VLC_SAVE_FLAGS
 984   ])
 985 ])
 986
 987
 988 dnl
 989 dnl  Enable/disable optimizations
 990 dnl
 991 AC_ARG_ENABLE(optimizations,
 992   [AS_HELP_STRING([--disable-optimizations],
 993     [disable compiler optimizations (default enabled)])],,
 994   [enable_optimizations="yes"])
 995 AS_IF([test "${enable_optimizations}" != "no"], [
 996   enable_optimizations="speed"
 997 ])
 998
 999 dnl Check for various optimization flags
1000 AS_IF([test "${enable_optimizations}" != "no"], [
1001
1002   C_O=""
1003   dnl -O4 and -O3 only in production builds
1004   AS_IF([test "{enable_debug}" = "no"], [
1005     AC_CACHE_CHECK([if $CC accepts -O4], [ac_cv_c_o4], [
1006       CFLAGS="${CFLAGS_save} -O4"
1007       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1008         ac_cv_c_o4=yes
1009       ], [
1010         ac_cv_c_o4=no
1011       ])
1012     ])
1013     AS_IF([test "${ac_cv_c_o4}" != "no"], [
1014       C_O="-O4"
1015     ], [
1016       AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1017         CFLAGS="${CFLAGS_save} -O3"
1018         AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1019           ac_cv_c_o3=yes
1020         ], [
1021           ac_cv_c_o3=no
1022         ])
1023       ])
1024       AS_IF([test "${ac_cv_c_o3}" != "no"], [
1025         C_O="-O3"
1026       ])
1027     ])
1028   ])
1029
1030   VLC_RESTORE_FLAGS
1031   CFLAGS="${CFLAGS} ${C_O}"
1032   CXXFLAGS="${CXXFLAGS} ${C_O}"
1033   OBJCFLAGS="${OBJCFLAGS} ${C_O}"
1034   VLC_SAVE_FLAGS
1035
1036   dnl Check for -ffast-math
1037   AC_CACHE_CHECK([if $CC accepts -ffast-math], [ac_cv_c_fast_math], [
1038     CFLAGS="${CFLAGS_save} -ffast-math"
1039     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1040       ac_cv_c_fast_math=yes
1041     ], [
1042       ac_cv_c_fast_math=no
1043     ])
1044   ])
1045   AS_IF([test "${ac_cv_c_fast_math}" != "no"], [
1046     VLC_RESTORE_FLAGS
1047     CFLAGS="${CFLAGS} -ffast-math"
1048     CXXFLAGS="${CXXFLAGS} -ffast-math"
1049     OBJCFLAGS="${OBJCFLAGS} -ffast-math"
1050     VLC_SAVE_FLAGS
1051   ])
1052
1053   dnl Check for -funroll-loops
1054   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1055     CFLAGS="${CFLAGS_save} -funroll-loops"
1056     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1057       ac_cv_c_unroll_loops=yes
1058     ], [
1059       ac_cv_c_unroll_loops=no
1060     ])
1061   ])
1062   AS_IF([test "${ac_cv_c_unroll_loops}" != "no"], [
1063     VLC_RESTORE_FLAGS
1064     CFLAGS="${CFLAGS} -funroll-loops"
1065     CXXFLAGS="${CXXFLAGS} -funroll-loops"
1066     OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1067     VLC_SAVE_FLAGS
1068   ])
1069
1070   AS_IF([test "$enable_debug" = "no"], [
1071     dnl Check for -fomit-frame-pointer
1072     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1073       [ac_cv_c_omit_frame_pointer], [
1074       CFLAGS="${CFLAGS_save} -fomit-frame-pointer"
1075       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1076         ac_cv_c_omit_frame_pointer=yes
1077       ], [
1078         ac_cv_c_omit_frame_pointer=no
1079       ])
1080     ])
1081     AS_IF([test "${ac_cv_c_omit_frame_pointer}" != "no"], [
1082       VLC_RESTORE_FLAGS
1083       AS_IF([test "${SYS}" != "darwin"], [
1084         CFLAGS="${CFLAGS} -fomit-frame-pointer"
1085         CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1086       ], [
1087         dnl On darwin we explicitely disable it.
1088         CFLAGS="${CFLAGS} -fno-omit-frame-pointer"
1089         CXXFLAGS="${CXXFLAGS} -fno-omit-frame-pointer"
1090         OBJCFLAGS="${OBJCFLAGS} -fno-omit-frame-pointer"
1091       ])
1092       VLC_SAVE_FLAGS
1093     ])
1094   ])
1095 ])
1096
1097 dnl Check for Darwin plugin linking flags
1098 AS_IF([test "${SYS}" = "darwin"], [
1099   AC_CACHE_CHECK([if $CC accepts -bundle -undefined error],
1100     [ac_cv_ld_darwin], [
1101     CFLAGS="${CFLAGS_save} -bundle -undefined error"
1102     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1103       ac_cv_ld_darwin=yes
1104     ], [
1105       ac_cv_ld_darwin=no
1106     ])
1107   ])
1108   AS_IF([test "${ac_cv_ld_darwin}" != "no"], [
1109     VLC_ADD_LDFLAGS([plugin],[-bundle -undefined error])
1110   ])
1111 ])
1112
1113 dnl Checks for __attribute__(aligned()) directive
1114 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1115     [ac_cv_c_attribute_aligned],
1116     [ac_cv_c_attribute_aligned=0
1117         CFLAGS="${CFLAGS_save} -Werror"
1118     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1119         AC_TRY_COMPILE([],
1120         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1121         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1122     done
1123         CFLAGS="${CFLAGS_save}"])
1124 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1125     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1126         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1127 fi
1128
1129 dnl Check for __attribute__((packed))
1130 AC_CACHE_CHECK([for __attribute__((packed))],
1131   [ac_cv_c_attribute_packed],
1132   [ac_cv_c_attribute_packed=no
1133    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1134                     [ac_cv_c_attribute_packed=yes])])
1135 if test "${ac_cv_c_attribute_packed}" != "no"; then
1136   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1137 fi
1138
1139 dnl
1140 dnl  Check the CPU
1141 dnl
1142 case "${host_cpu}" in
1143   "")
1144     ARCH=unknown
1145     ;;
1146   *)
1147     ARCH="${host_cpu}"
1148     ;;
1149 esac
1150
1151 dnl Check for backtrace() support
1152 AC_CHECK_HEADERS(execinfo.h)
1153 AC_CHECK_FUNCS(backtrace)
1154
1155 dnl
1156 dnl  default modules
1157 dnl
1158 ALIASES="${ALIASES} cvlc rvlc"
1159
1160 dnl
1161 dnl Some plugins aren't useful on some platforms
1162 dnl
1163 if test "${SYS}" = "os2"; then
1164     VLC_ADD_PLUGIN([dynamicoverlay])
1165 elif test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
1166     VLC_ADD_PLUGIN([dynamicoverlay access_shm])
1167 elif test "${SYS}" != "mingwce"; then
1168     VLC_ADD_PLUGIN([access_smb dmo globalhotkeys])
1169     VLC_ADD_LIBS([dmo],[-lole32 -luuid])
1170 fi
1171 if test "${SYS}" = "darwin"; then
1172     VLC_ADD_LIBS([quartztext],[-Wl,-framework,ApplicationServices])
1173 fi
1174
1175 dnl
1176 dnl  Accelerated modules
1177 dnl
1178
1179 dnl  Check for fully working MMX intrinsics
1180 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1181 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1182 AC_ARG_ENABLE(mmx,
1183   [AS_HELP_STRING([--disable-mmx],
1184     [disable MMX optimizations (default auto)])],,[
1185   case "${host_cpu}" in
1186     i?86|x86_64)
1187       enable_mmx="yes"
1188       ;;
1189     *)
1190       enable_mmx="no"
1191       ;;
1192   esac
1193 ])
1194 have_mmx="no"
1195 have_mmxext="no"
1196 AS_IF([test "${enable_mmx}" != "no"], [
1197   ARCH="${ARCH} mmx"
1198
1199   AC_CACHE_CHECK([if $CC groks MMX intrinsics],
1200     [ac_cv_c_mmx_intrinsics],
1201     [CFLAGS="${CFLAGS_save} -O -mmmx"
1202      AC_TRY_COMPILE([#include <mmintrin.h>
1203                      #include <stdint.h>
1204                      uint64_t frobzor;],
1205                     [__m64 a, b, c;
1206                      a = b = c = (__m64)frobzor;
1207                      a = _mm_slli_pi16(a, 3);
1208                      a = _mm_adds_pi16(a, b);
1209                      c = _mm_srli_pi16(c, 8);
1210                      c = _mm_slli_pi16(c, 3);
1211                      b = _mm_adds_pi16(b, c);
1212                      a = _mm_unpacklo_pi8(a, b);
1213                      frobzor = (uint64_t)a;],
1214                     [ac_cv_c_mmx_intrinsics=yes],
1215                     [ac_cv_c_mmx_intrinsics=no])])
1216   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1217     AC_DEFINE(HAVE_MMX_INTRINSICS, 1,
1218               [Define to 1 if MMX intrinsics are available.])
1219   ])
1220
1221   AC_CACHE_CHECK([if $CC groks MMX inline assembly],
1222     [ac_cv_mmx_inline],
1223     [CFLAGS="${CFLAGS_save}"
1224      AC_TRY_COMPILE(,[void *p;asm volatile("packuswb %%mm1,%%mm2"::"r"(p));],
1225                     ac_cv_mmx_inline=yes, ac_cv_mmx_inline=no)])
1226   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1227     AC_DEFINE(CAN_COMPILE_MMX, 1,
1228               [Define to 1 inline MMX assembly is available.])
1229     have_mmx="yes"
1230   ])
1231
1232   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1233     [ac_cv_mmxext_inline],
1234     [CFLAGS="${CFLAGS_save}"
1235      AC_TRY_COMPILE(,[void *p;asm volatile("maskmovq %%mm1,%%mm2"::"r"(p));],
1236                     ac_cv_mmxext_inline=yes, ac_cv_mmxext_inline=no)])
1237   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1238     AC_DEFINE(CAN_COMPILE_MMXEXT, 1,
1239               [Define to 1 if MMX EXT inline assembly is available.])
1240     have_mmxext="yes"
1241   ])
1242 ])
1243 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1244 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1245
1246 dnl  Check for fully workin SSE2 intrinsics
1247 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1248 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1249 AC_ARG_ENABLE(sse,
1250   [AS_HELP_STRING([--disable-sse],
1251     [disable SSE (1-4) optimizations (default auto)])],, [
1252   case "${host_cpu}" in
1253     i?86|x86_64)
1254       enable_sse=yes
1255       ;;
1256     *)
1257       enable_sse=no
1258       ;;
1259   esac
1260 ])
1261 have_sse2="no"
1262 AS_IF([test "${enable_sse}" != "no"], [
1263   ARCH="${ARCH} sse sse2"
1264
1265   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics],
1266     [ac_cv_c_sse2_intrinsics],
1267     [CFLAGS="${CFLAGS_save} -O -msse2"
1268      AC_TRY_COMPILE([#include <emmintrin.h>
1269                      #include <stdint.h>
1270                      uint64_t frobzor;],
1271                     [__m128i a, b, c;
1272                      a = b = c = _mm_set1_epi64((__m64)frobzor);
1273                      a = _mm_slli_epi16(a, 3);
1274                      a = _mm_adds_epi16(a, b);
1275                      c = _mm_srli_epi16(c, 8);
1276                      c = _mm_slli_epi16(c, 3);
1277                      b = _mm_adds_epi16(b, c);
1278                      a = _mm_unpacklo_epi8(a, b);
1279                      frobzor = (uint64_t)_mm_movepi64_pi64(a);],
1280                     [ac_cv_c_sse2_intrinsics=yes],
1281                     [ac_cv_c_sse2_intrinsics=no])])
1282   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1283     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1,
1284               [Define to 1 if SSE2 intrinsics are available.])
1285   ])
1286
1287   AC_CACHE_CHECK([if $CC groks SSE inline assembly],
1288     [ac_cv_sse_inline],
1289     [CFLAGS="${CFLAGS_save}"
1290      AC_TRY_COMPILE(,[void *p;asm volatile("xorps %%xmm1,%%xmm2"::"r"(p));],
1291                     ac_cv_sse_inline=yes, ac_cv_sse_inline=no)])
1292   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1293     AC_DEFINE(CAN_COMPILE_SSE, 1,
1294               [Define to 1 if SSE inline assembly is available.])
1295   ])
1296
1297   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly],
1298     [ac_cv_sse2_inline],
1299     [CFLAGS="${CFLAGS_save}"
1300      AC_TRY_COMPILE(,[void *p;asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p));],
1301                     ac_cv_sse2_inline=yes, ac_cv_sse2_inline=no)])
1302   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1303     AC_DEFINE(CAN_COMPILE_SSE2, 1,
1304               [Define to 1 if SSE2 inline assembly is available.])
1305     have_sse2="yes"
1306   ])
1307
1308   # SSE3
1309   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly],
1310     [ac_cv_sse3_inline],
1311     [CFLAGS="${CFLAGS_save}"
1312      AC_TRY_COMPILE(,[void *p;asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p));],
1313                     ac_cv_sse3_inline=yes, ac_cv_sse3_inline=no)])
1314   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1315     AC_DEFINE(CAN_COMPILE_SSE3, 1,
1316               [Define to 1 if SSE3 inline assembly is available.]) ])
1317   # SSSE3
1318   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly],
1319     [ac_cv_ssse3_inline],
1320     [CFLAGS="${CFLAGS_save}"
1321      AC_TRY_COMPILE(,[void *p;asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p));],
1322                     ac_cv_ssse3_inline=yes, ac_cv_ssse3_inline=no)])
1323   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1324     AC_DEFINE(CAN_COMPILE_SSSE3, 1,
1325               [Define to 1 if SSSE3 inline assembly is available.]) ])
1326
1327   # SSE4.1
1328   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1329     [ac_cv_sse4_1_inline],
1330     [CFLAGS="${CFLAGS_save}"
1331      AC_TRY_COMPILE(,[void *p;asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p));],
1332                     ac_cv_sse4_1_inline=yes, ac_cv_sse4_1_inline=no)])
1333   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1334     AC_DEFINE(CAN_COMPILE_SSE4_1, 1,
1335               [Define to 1 if SSE4_1 inline assembly is available.]) ])
1336
1337   # SSE4.2
1338   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1339     [ac_cv_sse4_2_inline],
1340     [CFLAGS="${CFLAGS_save}"
1341      AC_TRY_COMPILE(,[void *p;asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p));],
1342                     ac_cv_sse4_2_inline=yes, ac_cv_sse4_2_inline=no)])
1343   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1344     AC_DEFINE(CAN_COMPILE_SSE4_2, 1,
1345               [Define to 1 if SSE4_2 inline assembly is available.]) ])
1346
1347   # SSE4A
1348   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly],
1349     [ac_cv_sse4a_inline],
1350     [CFLAGS="${CFLAGS_save}"
1351      AC_TRY_COMPILE(,[void *p;asm volatile("insertq %%xmm1,%%xmm0"::"r"(p));],
1352                     ac_cv_sse4a_inline=yes, ac_cv_sse4a_inline=no)])
1353   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1354     AC_DEFINE(CAN_COMPILE_SSE4A, 1,
1355               [Define to 1 if SSE4A inline assembly is available.]) ])
1356 ])
1357 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1358
1359 have_3dnow="no"
1360 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly],
1361     [ac_cv_3dnow_inline],
1362     [CFLAGS="${CFLAGS_save}"
1363      AC_TRY_COMPILE(,[void *p;asm volatile("pfadd %%mm1,%%mm2"::"r"(p));],
1364                     ac_cv_3dnow_inline=yes, ac_cv_3dnow_inline=no)])
1365 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1366   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1367             [Define to 1 if 3D Now! inline assembly is available.])
1368   have_3dnow="yes"
1369 ])
1370 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1371
1372
1373 AC_ARG_ENABLE(neon,
1374   [AS_HELP_STRING([--disable-neon],
1375     [disable NEON optimizations (default auto)])],, [
1376   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1377 ])
1378 AS_IF([test "${enable_neon}" != "no"], [
1379   AC_CACHE_CHECK([if $CC groks NEON inline assembly], [ac_cv_neon_inline], [
1380     CFLAGS="${CFLAGS_save} -mfpu=neon"
1381     AC_COMPILE_IFELSE([
1382       AC_LANG_PROGRAM(,[[
1383 asm volatile("vqmovun.s64 d0, q1":::"d0");
1384 asm volatile("ssat r0, #1, r0":::"r0"); /* assume ARMv6 */
1385 ]])
1386     ], [
1387       ac_cv_neon_inline="-mfpu=neon"
1388     ], [
1389       ac_cv_neon_inline="no"
1390     ])
1391     CFLAGS="${CFLAGS_save}"
1392   ])
1393   AS_IF([test "$ac_cv_neon_inline" != "no"], [
1394     NEON_CFLAGS="$ac_cv_neon_inline"
1395     AC_DEFINE([CAN_COMPILE_NEON], 1,
1396       [Define to 1 if NEON (and ARMv6) assembly is available with NEON_CFLAGS.])
1397   ])
1398 ], [
1399   ac_cv_neon_inline="no"
1400 ])
1401 AC_SUBST(NEON_CFLAGS)
1402 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_neon_inline}" != "no"])
1403
1404
1405 AC_ARG_ENABLE(altivec,
1406   [AS_HELP_STRING([--disable-altivec],
1407     [disable AltiVec optimizations (default auto)])],, [
1408   AS_IF([test "${host_cpu}" = "powerpc"],
1409         [enable_altivec=yes], [enable_altivec=no])
1410 ])
1411 have_altivec="no"
1412 AS_IF([test "${enable_altivec}" = "yes"], [
1413   ARCH="${ARCH} altivec";
1414   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1415     [ac_cv_altivec_inline],
1416     [CFLAGS="${CFLAGS_save}"
1417      AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1418          ac_cv_altivec_inline="yes",
1419          [CFLAGS="${CFLAGS_save} -Wa,-m7400"
1420           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1421             [ac_cv_altivec_inline="-Wa,-m7400"],
1422             ac_cv_altivec_inline=no)
1423          ])])
1424   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1425     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1426               [Define to 1 if AltiVec inline assembly is available.])
1427     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1428       VLC_ADD_CFLAGS([memcpyaltivec],[${ac_cv_altivec_inline}])
1429       VLC_ADD_CFLAGS([i420_yuy2_altivec],[${ac_cv_altivec_inline}])
1430       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1431     ])
1432     have_altivec="yes"
1433   ])
1434
1435 dnl The AltiVec C extensions
1436 dnl
1437 dnl There are several possible cases:
1438 dnl - OS X PPC, gcc 4.x: use -mpim-altivec -force_cpusubtype_ALL, don't
1439 dnl                      need <altivec.h>
1440 dnl - OS X PPC, gcc 3.x: need -faltivec, don't need <altivec.h>
1441 dnl - Linux PPC, gcc 3.4, 4.x: need <altivec.h> which requires -maltivec
1442 dnl - Linux PPC, gcc 3.3: need <altivec.h> and -maltivec -mabi=altivec
1443 dnl - Linux PPC, gcc 3.x: need <altivec.h> and -fvec
1444 dnl - Others: test should fail
1445   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1446   [ac_cv_c_altivec],
1447   [# OS X/PPC test (gcc 4.x)
1448    CFLAGS="${CFLAGS_save} -mpim-altivec -force_cpusubtype_ALL"
1449    AC_TRY_COMPILE([vector unsigned char foo;],
1450      [vec_ld(0, (unsigned char *)0);],
1451      [ac_cv_c_altivec="-mpim-altivec -force_cpusubtype_ALL"],
1452      [# OS X/PPC test (gcc 3.x)
1453       CFLAGS="${CFLAGS_save} -faltivec"
1454       AC_TRY_COMPILE([vector unsigned char foo;],
1455         [vec_ld(1 * sizeof(vector float), (unsigned char *)0);],
1456         [ac_cv_c_altivec="-faltivec"],
1457         dnl Below this are the Linux tests
1458         [# Linux/PPC test (gcc 4.x)
1459          CFLAGS="${CFLAGS_save} -maltivec"
1460          AC_TRY_COMPILE([#include <altivec.h>],
1461            [vec_ld(0, (unsigned char *)0);],
1462            [ac_cv_c_altivec="-maltivec"],
1463            [# Linux/PPC test (gcc 3.3)
1464             CFLAGS="${CFLAGS_save} -maltivec -mabi=altivec"
1465             AC_TRY_COMPILE([#include <altivec.h>],
1466               [vec_ld(0, (unsigned char *)0);],
1467               [ac_cv_c_altivec=""
1468                ac_cv_c_altivec_abi="-maltivec -mabi=altivec"],
1469               [# Linux/PPC test (gcc 3.3)
1470                CFLAGS="${CFLAGS_save} -fvec"
1471                AC_TRY_COMPILE([#include <altivec.h>],
1472                  [vec_ld(0, (unsigned char *)0);],
1473                  [ac_cv_c_altivec="-fvec"],
1474                  [ac_cv_c_altivec=no])
1475               ])
1476            ])
1477         ])
1478      ])
1479    CFLAGS="${CFLAGS_save}"
1480   ])
1481   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1482     CPPFLAGS="${CPPFLAGS_save} ${ac_cv_c_altivec}"
1483   ])
1484
1485   AC_CHECK_HEADERS(altivec.h)
1486   CPPFLAGS="${CPPFLAGS_save}"
1487
1488   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1489     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1,
1490               [Define to 1 if C AltiVec extensions are available.])
1491     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1492     VLC_ADD_CFLAGS([i420_yuy2_altivec memcpyaltivec deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1493     have_altivec="yes"
1494   ])
1495
1496   AC_CACHE_CHECK([if linker needs -framework vecLib],
1497     [ac_cv_ld_altivec],
1498     [LDFLAGS="${LDFLAGS_vlc} -Wl,-framework,vecLib"
1499      AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)
1500      LDFLAGS="${LDFLAGS_save}"
1501     ])
1502   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1503     VLC_ADD_LIBS([libvlccore memcpyaltivec],[-Wl,-framework,vecLib])
1504   ])
1505 ])
1506 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1507
1508 dnl
1509 dnl  Special arch tuning
1510 dnl
1511 AC_ARG_WITH(tuning,
1512   [AS_HELP_STRING([--with-tuning=ARCH],
1513     [tune compilation for an architecture (default varies)])])
1514 if test -n "${with_tuning}"; then
1515     if test "${with_tuning}" != "no"; then
1516         CFLAGS_TUNING="-mtune=${with_tuning}"
1517     fi
1518 else
1519     if test "${SYS}" = "darwin" -a "${host_cpu}" = "i686"; then
1520         CFLAGS_TUNING="-march=prescott -mtune=generic"
1521     elif test "${SYS}" = "darwin" -a "${host_cpu}" = "x86_64"; then
1522         CFLAGS_TUNING="-march=core2 -mtune=core2"
1523     elif test "${host_cpu}" = "i686" -o "${host_cpu}" = "i586" -o "${host_cpu}" = "i486" -o "${host_cpu}" = "i386"; then
1524         CFLAGS_TUNING="-mtune=pentium2"
1525     elif test "${host_cpu}" = "x86_64"; then
1526         CFLAGS_TUNING="-mtune=athlon64"
1527     elif test "${host_cpu}" = "powerpc"; then
1528         CFLAGS_TUNING="-mtune=G4";
1529     fi
1530 fi
1531
1532 dnl NOTE: this can't be cached cleanly
1533 AS_IF([test "${CFLAGS_TUNING}"],
1534    [CFLAGS_save="${CFLAGS}"
1535     CFLAGS="${CFLAGS} ${CFLAGS_TUNING}"
1536
1537     AC_MSG_CHECKING([whether $CC accepts ${CFLAGS_TUNING}])
1538     AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
1539                       [tuning="yes"],
1540                       [CFLAGS_TUNING=""; tuning="no"
1541                        AS_IF([test "${with_tuning}"],
1542                              [AC_MSG_ERROR([requested tuning not supported])])])
1543
1544     AC_MSG_RESULT([$tuning])
1545     CFLAGS="${CFLAGS_save}"
1546 ])
1547
1548 dnl
1549 dnl  Memory usage
1550 dnl
1551 AC_ARG_ENABLE(optimize-memory,
1552   [AS_HELP_STRING([--enable-optimize-memory],
1553     [optimize memory usage over performance])])
1554 if test "${enable_optimize_memory}" = "yes"; then
1555   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1556 fi
1557
1558 dnl
1559 dnl Allow running as root (useful for people running on embedded platforms)
1560 dnl
1561 AC_ARG_ENABLE(run-as-root,
1562   [AS_HELP_STRING([--enable-run-as-root],
1563     [allow running VLC as root (default disabled)])])
1564 AS_IF([test "${enable_run_as_root}" = "yes"],[
1565     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1566               [Define to 1 to allow running VLC as root (uid 0).])
1567 ])
1568
1569 dnl
1570 dnl Stream output
1571 dnl
1572 AC_ARG_ENABLE(sout,
1573   [AS_HELP_STRING([--disable-sout],
1574     [disable streaming output (default enabled)])])
1575 AS_IF([test "${enable_sout}" != "no"], [
1576   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1577 ])
1578 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1579
1580 dnl Lua modules
1581 AC_ARG_ENABLE(lua,
1582   [AS_HELP_STRING([--disable-lua],
1583     [disable LUA scripting support (default enabled)])])
1584 if test "${enable_lua}" != "no"
1585 then
1586   PKG_CHECK_MODULES(LUA, lua5.1,
1587     [ have_lua=yes ],
1588     [
1589     AC_MSG_WARN([lua5.1 not found, trying lua >= 5.1 instead])
1590     PKG_CHECK_MODULES(LUA, lua >= 5.1,
1591       [ have_lua=yes ],
1592       [
1593         have_lua=yes
1594         AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1595           [],
1596           [ have_lua=no ] )
1597         AC_CHECK_LIB(  lua5.1 , luaL_newstate,
1598           [LUA_LIBS="-llua5.1"],
1599           AC_CHECK_LIB( lua51 , luaL_newstate,
1600             [LUA_LIBS="-llua51"],
1601             AC_CHECK_LIB( lua , luaL_newstate,
1602               [LUA_LIBS="-llua"],
1603               [ have_lua=no
1604               ], [-lm])
1605           )
1606         )
1607       ])
1608     ])
1609   if test "x${have_lua}" = "xyes" ;  then
1610      VLC_ADD_LIBS([lua],[$LUA_LIBS])
1611      VLC_ADD_CFLAGS([lua],[$LUA_CFLAGS])
1612   else
1613       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1614   fi
1615   AC_ARG_VAR([LUAC], [LUA byte compiler])
1616   AC_PATH_PROGS(LUAC,[${LUAC} luac], [false])
1617   AS_IF([test "${LUAC}" = "false"], [
1618     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1619   ])
1620 fi
1621 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1622
1623
1624 dnl
1625 dnl HTTP daemon
1626 dnl
1627 AC_ARG_ENABLE(httpd,
1628   [AS_HELP_STRING([--disable-httpd],
1629     [disable the built-in HTTP server (default enabled)])])
1630 if test "${enable_httpd}" != "no"
1631 then
1632   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP dameon support)
1633 fi
1634 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1635
1636
1637 dnl
1638 dnl VideoLAN manager
1639 dnl
1640 AC_ARG_ENABLE(vlm,
1641   [AS_HELP_STRING([--disable-vlm],
1642     [disable the stream manager (default enabled)])],,
1643   [enable_vlm="${enable_sout}"])
1644 AS_IF([test "${enable_vlm}" != "no"], [
1645   AS_IF([test "${enable_sout}" = "no"], [
1646     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1647   ])
1648   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1649 ])
1650 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1651
1652
1653 dnl
1654 dnl  ipv6 support
1655 dnl
1656 have_ipv6=no
1657 AC_CHECK_FUNCS(inet_pton,[have_ipv6=yes],[
1658   AC_CHECK_LIB(nsl,inet_pton, [have_ipv6=yes])
1659 ])
1660
1661 AS_IF([test "${have_ipv6}" = "yes"], [
1662   AC_DEFINE(HAVE_INET_PTON, 1, [Define to 1 if you have inet_pton().])])
1663
1664
1665 AC_CHECK_FUNCS(inet_ntop,[
1666   AC_DEFINE(HAVE_INET_NTOP, 1, [Define to 1 if you have inet_ntop().])])
1667
1668
1669 dnl
1670 dnl  Input plugins
1671 dnl
1672
1673 EXTEND_HELP_STRING([Input plugins:])
1674
1675 dnl
1676 dnl libproxy support
1677 dnl
1678 AC_ARG_ENABLE(libproxy,
1679   [AS_HELP_STRING([--enable-libproxy],[support libproxy (default auto)])])
1680 AS_IF([test "${enable_libproxy}" != "no"], [
1681   PKG_CHECK_MODULES(LIBPROXY, libproxy-1.0, [
1682     AC_DEFINE(HAVE_LIBPROXY, 1, [Define if libproxy is available])
1683     VLC_ADD_CFLAGS([access_http],[$LIBPROXY_CFLAGS])
1684     VLC_ADD_LIBS([access_http],[$LIBPROXY_LIBS])
1685   ], [
1686     AS_IF([test "x${enable_libproxy}" != "x"], [
1687       AC_MSG_ERROR([libproxy could not be found on your system])
1688     ])
1689   ])
1690 ])
1691
1692 dnl
1693 dnl  live555 input
1694 dnl
1695 AC_ARG_ENABLE(live555,
1696   [AS_HELP_STRING([--enable-live555],
1697     [enable RTSP input through live555 (default enabled)])])
1698 AC_ARG_WITH(live555-tree,
1699   [AS_HELP_STRING([--with-live555-tree=PATH],
1700     [live555 tree for static linking])])
1701 if test "${enable_live555}" != "no"; then
1702
1703   dnl
1704   dnl test for --with-live555-tree
1705   dnl
1706   if test -z "${with_live555_tree}" -a "${CXX}" != ""; then
1707     AC_LANG_PUSH(C++)
1708     CPPFLAGS_save="${CPPFLAGS}"
1709     if test -z "${CONTRIB_DIR}"; then
1710         CPPFLAGS_live555="-I/usr/include/liveMedia -I/usr/include/groupsock -I/usr/include/BasicUsageEnvironment -I/usr/include/UsageEnvironment"
1711     else
1712         CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1713     fi
1714     if test "${SYS}" = "solaris"; then
1715       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1716     fi
1717     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1718
1719     AC_CHECK_HEADERS(liveMedia_version.hh, [
1720       AC_MSG_CHECKING(for liveMedia version >= 1275091200 )
1721       AC_EGREP_CPP(yes,
1722         [#include <liveMedia_version.hh>
1723          #ifdef LIVEMEDIA_LIBRARY_VERSION_INT
1724          #if LIVEMEDIA_LIBRARY_VERSION_INT < 1275091200
1725          yes
1726          #endif
1727          #endif],
1728         [AC_MSG_RESULT([no])
1729           AC_MSG_WARN([The installed liveMedia version is too old:
1730 Version 2010.05.29 or later is required to proceed.
1731 You can get an updated one from http://www.live555.com/liveMedia .])
1732           AS_IF([test "${enable_live555}" = "yes"], [
1733             AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable the plugin.])
1734           ])
1735         ],[
1736           AC_MSG_RESULT([yes])
1737           other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1738           other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1739           if test "${SYS}" = "mingw32"; then
1740             # add ws2_32 for closesocket, select, recv
1741             other_libs="$other_libs -lws2_32"
1742           elif test "${SYS}" = "mingwce"; then
1743             # add ws2 for closesocket, select, recv
1744             other_libs="$other_libs -lws2"
1745           fi
1746
1747           dnl We need to check for pic because live555 don't provide shared libs
1748           dnl and we want to build a plugins so we need -fPIC on some arch.
1749           VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1750           AC_CHECK_LIB(liveMedia_pic, main, [
1751             VLC_ADD_PLUGIN([live555])
1752             VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1753           ],[
1754             AC_CHECK_LIB(liveMedia, main, [
1755             VLC_ADD_PLUGIN([live555])
1756             VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1757           ],[],[${other_libs}]) ],[${other_libs_pic}])
1758
1759           CPPFLAGS="${CPPFLAGS_save}"
1760           AC_LANG_POP(C++)
1761         ])
1762       ])
1763   else
1764     AC_MSG_CHECKING(for liveMedia/libliveMedia.a in ${with_live555_tree})
1765     real_live555_tree="`cd ${with_live555_tree} 2>/dev/null && pwd`"
1766     if test -z "${real_live555_tree}"; then
1767       dnl  The given directory can't be found
1768       AC_MSG_RESULT(no)
1769       AC_MSG_ERROR([cannot cd to ${with_live555_tree}])
1770     fi
1771     if test -f "${real_live555_tree}/liveMedia/libliveMedia.a"; then
1772       AC_MSG_RESULT(${real_live555_tree}/liveMedia/libliveMedia.a)
1773
1774       AC_CHECK_HEADERS(${real_live555_tree}/liveMedia/include/liveMedia_version.hh,[
1775         AC_MSG_CHECKING(for liveMedia version >= 1275091200 )
1776         AC_EGREP_CPP(yes,
1777           [#include "${real_live555_tree}/liveMedia/include/liveMedia_version.hh"
1778            #ifdef LIVEMEDIA_LIBRARY_VERSION_INT
1779            #if LIVEMEDIA_LIBRARY_VERSION_INT < 1275091200
1780            yes
1781            #endif
1782            #endif],
1783           [AC_MSG_RESULT([no])
1784            AC_MSG_ERROR([Your version of liveMedia is too old: you may get a more recent one from http://www.live555.com/liveMedia.
1785 lternatively you can use --disable-live555 to disable the liveMedia plugin.])
1786         ],[
1787        AC_MSG_RESULT([yes])
1788        ])
1789       ])
1790
1791       VLC_ADD_PLUGIN([live555])
1792
1793       if test "${SYS}" = "mingw32"; then
1794         # add ws2_32 for closesocket, select, recv
1795         VLC_ADD_LIBS([live555],[-lws2_32])
1796       fi
1797
1798       VLC_ADD_LIBS([live555],[-L${real_live555_tree}/UsageEnvironment -lUsageEnvironment])
1799       VLC_ADD_LIBS([live555],[-L${real_live555_tree}/BasicUsageEnvironment -lBasicUsageEnvironment])
1800       VLC_ADD_LIBS([live555],[-L${real_live555_tree}/groupsock -lgroupsock])
1801       VLC_ADD_LIBS([live555],[-L${real_live555_tree}/liveMedia -lliveMedia])
1802
1803       VLC_ADD_CXXFLAGS([live555],[-I${real_live555_tree}/BasicUsageEnvironment/include])
1804       VLC_ADD_CXXFLAGS([live555],[-I${real_live555_tree}/groupsock/include])
1805       VLC_ADD_CXXFLAGS([live555],[-I${real_live555_tree}/liveMedia/include])
1806       VLC_ADD_CXXFLAGS([live555],[-I${real_live555_tree}/UsageEnvironment/include ])
1807       if test "${SYS}" = "solaris"; then
1808         VLC_ADD_CXXFLAGS([live555],[-DSOLARIS])
1809       fi
1810     else
1811       dnl  The given live555 wasn't built
1812         AC_MSG_RESULT(no)
1813       if test "${enable_live555}" = "yes"; then
1814         AC_MSG_ERROR([cannot find ${real_live555_tree}/liveMedia/libliveMedia.a, make sure you compiled live555 in ${with_live555_tree}])
1815       fi
1816     fi
1817   fi
1818 fi
1819
1820 dnl
1821 dnl - special access module for dc1394 input
1822 dnl - dv module: digital video module check for libraw1394
1823 dnl - linsys modules: access module check for libzvbi
1824 dnl
1825 PKG_ENABLE_MODULES_VLC([DC1394], [], [libraw1394 >= 2.0.1 libdc1394-2 >= 2.1.0], [dc1394 access module], [auto])
1826 PKG_ENABLE_MODULES_VLC([DV], [access_dv], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV input module], [auto])
1827
1828 AC_ARG_ENABLE(linsys,
1829   [AS_HELP_STRING([--enable-linsys],
1830     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1831 if test "$SYS" = "linux" -a "${enable_linsys}" != "no"; then
1832   VLC_ADD_PLUGIN([linsys_hdsdi])
1833   PKG_CHECK_MODULES(LINSYS_SDI, zvbi-0.2 >= 0.2.28,
1834     [ VLC_ADD_LIBS([linsys_sdi],[$LINSYS_SDI_LIBS])
1835       VLC_ADD_CFLAGS([linsys_sdi],[$LINSYS_SDI_CFLAGS])
1836       VLC_ADD_PLUGIN([linsys_sdi]) ],
1837     [AC_MSG_WARN([Could not find zvbi >= 0.2.28, install libzvbi-dev ?])]
1838   )
1839 fi
1840
1841 dnl
1842 dnl dvdread module: check for libdvdread
1843 dnl
1844 dnl prepend -ldvdcss on OS that need it
1845 AS_CASE(["${SYS}"], [mingw32|darwin], [VLC_ADD_LIBS([dvdread], [-ldvdcss])])
1846 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread], [dvdread input module], [auto])
1847
1848 dnl
1849 dnl libdvdnav plugin
1850 dnl
1851 AC_ARG_ENABLE(dvdnav,
1852   [AS_HELP_STRING([--disable-dvdnav],
1853     [disable DVD navigation with libdvdnav (default auto)])])
1854 if test "${enable_dvdnav}" != "no"
1855 then
1856   dnl prepend -ldvdcss on OS that need it
1857   AS_CASE(["${SYS}"], [mingw32|darwin], [VLC_ADD_LIBS([dvdnav], [-ldvdcss])])
1858
1859   PKG_CHECK_MODULES(DVDNAV, dvdnav, [
1860     VLC_ADD_PLUGIN([dvdnav])
1861     VLC_ADD_CFLAGS([dvdnav],[${DVDNAV_CFLAGS}])
1862     VLC_ADD_LIBS([dvdnav],[${DVDNAV_LIBS}])
1863     AC_CHECK_LIB(dvdnav, dvdnav_get_video_resolution,
1864       AC_DEFINE(HAVE_DVDNAV_GET_VIDEO_RESOLUTION, 1, [Define if you have dvdnav_get_video_resolution.]),
1865         [], [${LIBS_dvdnav}])
1866     AC_CHECK_LIB(dvdnav, dvdnav_describe_title_chapters,
1867       AC_DEFINE(HAVE_DVDNAV_DESCRIBE_TITLE_CHAPTERS, 1, [Define if you have dvdnav_describe_title_chapters.]),
1868         [], [${LIBS_dvdnav}])],
1869       [AC_MSG_WARN(dvdnav library not found)])
1870 fi
1871
1872 dnl
1873 dnl  Windows DirectShow access module
1874 dnl
1875 AC_ARG_ENABLE(dshow,
1876   [AS_HELP_STRING([--disable-dshow],
1877     [support DirectShow (default auto)])])
1878 if test "${enable_dshow}" != "no"
1879 then
1880   if test "${SYS}" = "mingw32"
1881   then
1882     AC_LANG_PUSH(C++)
1883       AC_CHECK_HEADERS(dshow.h,
1884       [ VLC_ADD_PLUGIN([dshow])
1885         VLC_ADD_CXXFLAGS([dshow],[])
1886         VLC_ADD_LIBS([dshow],[-lole32 -loleaut32 -luuid]) ])
1887     AC_LANG_POP(C++)
1888   fi
1889 fi
1890
1891 dnl
1892 dnl  Blu-ray Disc Support with libbluray
1893 dnl
1894 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.2 libxml-2.0 >= 2.6 ], (libbluray for Blu-ray disc support ) )
1895
1896 dnl
1897 dnl  OpenCV wrapper and example filters
1898 dnl
1899 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv], (OpenCV (computer vision) filter), [off])
1900
1901
1902 dnl
1903 dnl  libsmbclient plugin
1904 dnl
1905 AC_ARG_ENABLE(smb,
1906   [AS_HELP_STRING([--disable-smb], [disable SMB/CIFS support (default auto)])])
1907 if test "${enable_smb}" != "no"; then
1908   AC_CHECK_HEADERS(libsmbclient.h,
1909     [ VLC_ADD_PLUGIN([access_smb])
1910       VLC_ADD_LIBS([access_smb],[-lsmbclient]) ],
1911     [ if test -n "${enable_smb}"; then
1912         AC_MSG_ERROR([cannot find libsmbclient headers])
1913      fi ])
1914 fi
1915
1916
1917 dnl
1918 dnl sftp access support
1919 dnl
1920 AC_ARG_ENABLE(sftp,
1921   [AS_HELP_STRING([--enable-sftp],
1922     [support SFTP file transfer via libssh2 (default disabled)])])
1923 if test "${enable_sftp}" = "yes"; then
1924   AC_CHECK_HEADERS(libssh2.h, [
1925     VLC_ADD_PLUGIN([access_sftp])
1926     VLC_ADD_LIBS([access_sftp], [-lssh2])
1927   ])
1928 fi
1929
1930 dnl
1931 dnl  Video4Linux 2
1932 dnl
1933 AC_ARG_ENABLE(libv4l2, [AS_HELP_STRING([--disable-libv4l2],
1934   [disable userspace V4L2 library (default auto)])])
1935 AC_ARG_ENABLE(pvr, [AS_HELP_STRING([--enable-pvr],
1936   [support PVR V4L2 cards (default disabled)])])
1937 have_v4l2="no"
1938 AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1939   have_v4l2="yes"
1940 ])
1941 AS_IF([test "$have_v4l2" = "yes"], [
1942   AS_IF([test "${enable_libv4l2}" != "no"], [
1943     PKG_CHECK_MODULES(LIBV4L2, libv4l2, [
1944       AC_DEFINE(HAVE_LIBV4L2, 1, [Define to 1 if libv4l2 is available])
1945     ], [
1946       AC_MSG_WARN([${LIBV4L2_PKG_ERRORS}])
1947     ])
1948   ])
1949   AS_IF([test "${enable_pvr}" = "yes"], [
1950     VLC_ADD_PLUGIN([pvr])
1951   ])
1952 ])
1953 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1954
1955 dnl
1956 dnl special access module for Blackmagic SDI cards
1957 dnl
1958 AC_ARG_ENABLE(decklink,
1959   [AS_HELP_STRING([--disable-decklink],
1960     [disable Blackmagic DeckLink SDI input (default auto)])])
1961 AC_ARG_WITH(decklink_sdk,
1962   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1963     [                        location of Blackmagic DeckLink SDI SDK])])
1964 if test "${enable_decklink}" != "no"
1965 then
1966   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1967   then
1968     VLC_ADD_CPPFLAGS([decklink],[-I${with_decklink_sdk}/include])
1969   fi
1970   CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_decklink}"
1971   AC_LANG_PUSH(C++)
1972   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1973     VLC_ADD_PLUGIN([decklink])
1974   ],[AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)])
1975   AC_LANG_POP(C++)
1976   CPPFLAGS="${CPPFLAGS_save}"
1977 fi
1978
1979
1980 dnl
1981 dnl  gnomeVFS access module
1982 dnl
1983 PKG_ENABLE_MODULES_VLC([GNOMEVFS], [access_gnomevfs], [gnome-vfs-2.0], [GnomeVFS access module], [auto])
1984
1985 dnl
1986 dnl  VCDX modules
1987 dnl
1988 AC_ARG_ENABLE(vcdx,
1989   [AS_HELP_STRING([--enable-vcdx],
1990     [navigate VCD with libvcdinfo (default disabled)])])
1991 if test "${enable_vcdx}" = "yes"
1992 then
1993     PKG_CHECK_MODULES(LIBCDIO, [libcdio >= 0.78.2 libiso9660 >= 0.72],
1994       [VLC_ADD_LIBS([vcdx],[$LIBCDIO_LIBS])
1995          VLC_ADD_CFLAGS([vcdx],[$LIBCDIO_CFLAGS])],
1996         [AC_MSG_ERROR([vcdx plugin requires libcdio >= 0.78.2 and libiso9660 >= 0.72])])
1997     PKG_CHECK_MODULES(LIBVCDINFO, libvcdinfo >= 0.7.22,
1998         [VLC_ADD_LIBS([vcdx],[$LIBVCDINFO_LIBS])
1999          VLC_ADD_CFLAGS([vcdx],[$LIBVCDINFO_CFLAGS])],
2000       [AC_MSG_ERROR([vcdx plugin requires libvcdinfo library >= 0.7.22])])
2001         VLC_ADD_PLUGIN([vcdx])
2002 fi
2003
2004 dnl
2005 dnl  Built-in CD-DA and VCD module
2006 dnl
2007 AC_ARG_ENABLE(vcd,
2008   [AS_HELP_STRING([--disable-vcd],
2009     [disable built-in VCD and CD-DA support (default enabled)])])
2010
2011 AC_ARG_ENABLE(libcddb,
2012   [AS_HELP_STRING([--disable-libcddb],
2013     [disable CDDB for Audio CD (default enabled)])])
2014
2015 if test "${enable_vcd}" != "no"
2016 then
2017   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
2018   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
2019     AC_MSG_RESULT(yes)
2020     VLC_ADD_PLUGIN([vcd cdda])
2021   ],[
2022     AC_MSG_RESULT(no)
2023   ])
2024
2025   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
2026   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
2027     AC_MSG_RESULT(yes)
2028     VLC_ADD_PLUGIN([vcd cdda])
2029     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
2030   ],[
2031     AC_MSG_RESULT(no)
2032   ])
2033
2034   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
2035   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
2036     AC_MSG_RESULT(yes)
2037     VLC_ADD_PLUGIN([vcd cdda])
2038     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
2039   ],[
2040     AC_MSG_RESULT(no)
2041   ])
2042
2043   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32"
2044   then
2045     VLC_ADD_PLUGIN([vcd cdda])
2046   fi
2047
2048   if test "${SYS}" = "darwin"
2049   then
2050     VLC_ADD_PLUGIN([vcd cdda])
2051     VLC_ADD_LIBS([vcd vcdx cdda],[-Wl,-framework,IOKit,-framework,CoreFoundation])
2052     VLC_ADD_LIBS([vcdx cdda],[-liconv])
2053   fi
2054
2055   if test "$enable_libcddb" != "no"; then
2056     PKG_CHECK_MODULES(LIBCDDB, libcddb >= 0.9.5, [
2057       HAVE_LIBCDDB=yes
2058       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
2059       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
2060       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
2061       ],:
2062       [AC_MSG_WARN(new enough libcddb not found. CDDB access disabled)
2063       HAVE_LIBCDDB=no])
2064   fi
2065 fi
2066
2067 dnl
2068 dnl Linux DVB
2069 dnl
2070 AC_CACHE_CHECK([for Linux DVB version 5], [ac_cv_linux_s2api], [
2071   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
2072 [#include <linux/dvb/version.h>
2073 #if (DVB_API_VERSION < 5)
2074 EXPLODE
2075 #endif]])], [
2076   ac_cv_linux_s2api=yes
2077 ], [
2078   ac_cv_linux_s2api=no
2079 ])])
2080 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_s2api" = "yes"])
2081
2082 dnl
2083 dnl  Screen capture module
2084 dnl
2085 AC_ARG_ENABLE(screen,
2086   [AS_HELP_STRING([--enable-screen],
2087     [disable screen capture (default enabled)])])
2088 if test "${enable_screen}" != "no"; then
2089   if test "${SYS}" = "darwin"; then
2090     AC_CHECK_HEADERS(OpenGL/gl.h, [
2091       AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
2092         VLC_ADD_PLUGIN([screen])
2093         VLC_ADD_LIBS([screen],[-Wl,-framework,OpenGL,-framework,ApplicationServices])
2094       ])
2095     ])
2096   elif test "${SYS}" = "mingw32"; then
2097     VLC_ADD_PLUGIN([screen])
2098     VLC_ADD_LIBS([screen],[-lgdi32])
2099   elif test "${SYS}" = "mingwce"; then
2100     CPPFLAGS="${CPPFLAGS_save}"
2101   fi
2102 fi
2103
2104 dnl
2105 dnl  Real RTSP plugin
2106 dnl
2107 AC_ARG_ENABLE(realrtsp,
2108   [  --enable-realrtsp       Real RTSP module (default disabled)])
2109 if test "${enable_realrtsp}" = "yes"; then
2110   VLC_ADD_PLUGIN([access_realrtsp])
2111 fi
2112
2113 dnl
2114 dnl MacOS eyeTV
2115 AC_ARG_ENABLE(macosx-eyetv,
2116   [  --enable-macosx-eyetv   Mac OS X EyeTV (TNT Tuner) module (default enabled on Mac OS X)])
2117 if test "x${enable_macosx_eyetv}" != "xno" &&
2118   (test "${SYS}" = "darwin" || test "${enable_macosx_eyetv}" = "yes")
2119 then
2120   VLC_ADD_LIBS([access_eyetv], [-Wl,-framework,Foundation])
2121   VLC_ADD_PLUGIN([access_eyetv])
2122 fi
2123
2124 dnl
2125 dnl QTCapture
2126 AC_ARG_ENABLE(macosx-qtcapture,
2127   [  --enable-macosx-qtcapture Mac OS X qtcapture (iSight) module (default enabled on Mac OS X)])
2128 if test "x${enable_macosx_qtcapture}" != "xno" &&
2129   (test "${SYS}" = "darwin" || test "${enable_macosx_qtcapture}" = "yes")
2130 then
2131   VLC_ADD_LIBS([qtcapture], [-Wl,-framework,Cocoa])
2132   VLC_ADD_LIBS([qtcapture], [-Wl,-framework,QTKit])
2133   VLC_ADD_LIBS([qtcapture], [-Wl,-framework,CoreAudio])
2134   VLC_ADD_LIBS([qtcapture], [-Wl,-framework,QuartzCore])
2135   VLC_ADD_LIBS([qtcapture], [-Wl,-framework,CoreVideo])
2136   VLC_ADD_PLUGIN([qtcapture])
2137 fi
2138
2139
2140 dnl
2141 dnl  Demux plugins
2142 dnl
2143
2144 EXTEND_HELP_STRING([Mux/Demux plugins:])
2145
2146 dnl
2147 dnl  libdvbpsi check for ts mux/demux
2148 dnl
2149 have_dvbpsi="no"
2150 PKG_WITH_MODULES([DVBPSI], [libdvbpsi], [have_dvbpsi="yes"])
2151 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2152
2153
2154 dnl
2155 dnl  GME demux plugin
2156 dnl
2157 AC_ARG_ENABLE(gme,
2158   [AS_HELP_STRING([--enable-gme],
2159     [use Game Music Emu (default auto)])])
2160 AS_IF([test "${enable_gme}" != "no"], [
2161   AC_CHECK_HEADER([gme/gme.h], [
2162     VLC_ADD_LIBS([gme], [-lgme])
2163     VLC_ADD_PLUGIN([gme])
2164   ], [
2165     AS_IF([test "x${enable_gme}" != "x"], [
2166       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2167     ])
2168   ])
2169 ])
2170
2171
2172 dnl
2173 dnl  SIDPlay plugin
2174 dnl
2175 AC_ARG_ENABLE(sid,
2176     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2177 AS_IF([test "${enable_sid}" != "no"], [
2178     PKG_CHECK_MODULES(SID, [libsidplay2], [
2179         AC_LANG_PUSH(C++)
2180         oldCPPFLAGS="$CPPFLAGS"
2181         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2182         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2183             VLC_ADD_PLUGIN([sid])
2184             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2185             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2186         ], [
2187             AS_IF([test "x${enable_sid}" = "xyes"],
2188                 [AC_MSG_ERROR(Library libresid-builder needed for sid was not found)],
2189                 [AC_MSG_WARN(Library libresid-builder needed for sid was not found)]
2190                 )
2191         ])
2192         CPPFLAGS="$oldCPPFLAGS"
2193         AC_LANG_POP(C++)
2194     ], [
2195         AS_IF([test "x${enable_sid}" = "xyes"],
2196             [AC_MSG_ERROR(Library libsidplay2 needed for sid was not found)],
2197             [AC_MSG_WARN(Library libsidplay2 needed for sid was not found)]
2198             )
2199     ])
2200 ])
2201
2202
2203 dnl
2204 dnl  ogg demux plugin
2205 dnl
2206 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto])
2207 if test "${enable_sout}" != "no"; then
2208     PKG_ENABLE_MODULES_VLC([MUX_OGG], [], [ogg >= 1.0], [Ogg mux support], [auto])
2209 dnl Check for libshout
2210     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2211 fi
2212
2213 dnl
2214 dnl  matroska demux plugin
2215 dnl
2216 AC_ARG_ENABLE(mkv,
2217   [AS_HELP_STRING([--disable-mkv],
2218     [do not use libmatroska (default auto)])])
2219 if test "${enable_mkv}" != "no" -a "${CXX}" != ""; then
2220   AC_LANG_PUSH(C++)
2221   AC_CHECK_HEADERS(ebml/EbmlVersion.h, [
2222     AC_MSG_CHECKING(for libebml version >= 1.0.0)
2223     AC_EGREP_CPP(yes,
2224       [#include <ebml/EbmlVersion.h>
2225        #ifdef LIBEBML_VERSION
2226        #if LIBEBML_VERSION >= 0x010000
2227        yes
2228        #endif
2229        #endif],
2230       [AC_MSG_RESULT([yes])
2231         AC_CHECK_HEADERS(matroska/KaxVersion.h, [
2232           AC_MSG_CHECKING(for libmatroska version >= 1.0.0)
2233           AC_EGREP_CPP(yes,
2234             [#include <matroska/KaxVersion.h>
2235              #ifdef LIBMATROSKA_VERSION
2236              #if LIBMATROSKA_VERSION >= 0x010000
2237              yes
2238              #endif
2239              #endif],
2240             [AC_MSG_RESULT([yes])
2241               AC_CHECK_HEADERS(matroska/KaxAttachments.h)
2242               VLC_ADD_CXXFLAGS([mkv],[])
2243               if test "${SYS}" = "darwin"; then
2244                 VLC_ADD_CXXFLAGS([mkv],[-O1])
2245               fi
2246               AC_CHECK_LIB(ebml_pic, main, [
2247                 VLC_ADD_PLUGIN([mkv])
2248                 VLC_ADD_LIBS([mkv],[-lmatroska -lebml_pic])
2249               ],[
2250                 AC_CHECK_LIB(ebml, main, [
2251                   VLC_ADD_PLUGIN([mkv])
2252                   VLC_ADD_LIBS([mkv],[-lmatroska -lebml])
2253                 ])
2254               ])
2255             ], [
2256               AC_MSG_RESULT([no])
2257               AC_MSG_ERROR([Your libmatroska is too old: you may get a more recent one from http://dl.matroska.org/downloads/libmatroska/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2258           ])
2259         ])
2260       ],
2261       [AC_MSG_RESULT([no])
2262         AC_MSG_ERROR([Your libebml is too old: you may get a more recent one from http://dl.matroska.org/downloads/libebml/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2263     ])
2264   ])
2265   AC_LANG_POP(C++)
2266 fi
2267
2268 dnl
2269 dnl  modplug demux plugin
2270 dnl
2271 AC_ARG_ENABLE(mod,
2272   [AS_HELP_STRING([--disable-mod],
2273     [do not use libmodplug (default auto)])])
2274 if test "${enable_mod}" != "no" ; then
2275     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2276           VLC_ADD_PLUGIN([mod])
2277           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2278           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2279     ],[
2280        AS_IF([test x"${enable_mod}" = "xyes"],
2281          [AC_MSG_ERROR(libmodplug not found or a broken version (0.8.8.0) was found!)],
2282          [AC_MSG_WARN(libmodplug not found or a broken version (0.8.8.0) was found!)])
2283     ])
2284 fi
2285
2286 dnl
2287 dnl  mpc demux plugin
2288 dnl
2289 AC_ARG_ENABLE(mpc,
2290   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2291 if test "${enable_mpc}" != "no"
2292 then
2293   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2294     VLC_ADD_PLUGIN([mpc])
2295     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2296     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2297     VLC_ADD_PLUGIN([mpc])
2298     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2299 fi
2300
2301 dnl
2302 dnl  Codec plugins
2303 dnl
2304
2305 EXTEND_HELP_STRING([Codec plugins:])
2306
2307 dnl
2308 dnl wmafixed plugin
2309 dnl
2310 AC_ARG_ENABLE(wma-fixed,
2311   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2312 if test "${enable_wma_fixed}" = "yes"
2313 then
2314   VLC_ADD_PLUGIN([wma_fixed])
2315 fi
2316
2317 dnl
2318 dnl shine fixed point mp3 encoder
2319 dnl
2320 AC_ARG_ENABLE(shine,
2321   [  --enable-shine          shine mp3 encoding module (default disabled)])
2322 if test "${enable_shine}" = "yes"
2323 then
2324   VLC_ADD_PLUGIN([shine])
2325 fi
2326
2327 dnl
2328 dnl openmax il codec plugin
2329 dnl
2330 AC_ARG_ENABLE(omxil,
2331   [  --enable-omxil          openmax il codec module (default disabled)])
2332 if test "${enable_omxil}" = "yes"
2333 then
2334   VLC_ADD_PLUGIN([omxil])
2335   VLC_ADD_LIBS([omxil], [$LIBDL])
2336 fi
2337
2338 dnl
2339 dnl iomx codec plugin
2340 dnl
2341 AC_ARG_ENABLE(iomx,
2342   [  --enable-iomx           iomx codec module (default disabled)])
2343 if test "${enable_iomx}" = "yes"
2344 then
2345   CPPFLAGS_save="${CPPFLAGS}"
2346   CPPFLAGS="${CPPFLAGS} -I${srcdir}/modules/codec/omxil" # For the OMX headers
2347   AC_LANG_PUSH([C++])
2348   AC_CHECK_HEADER(media/stagefright/OMXClient.h, [
2349     VLC_ADD_PLUGIN([iomx])
2350     VLC_ADD_CXXFLAGS([iomx], [-fno-exceptions -fno-rtti])
2351     VLC_ADD_LIBS([iomx], [-lstagefright -lmedia -lutils -lbinder])
2352   ], [
2353     AC_MSG_ERROR("Could not find IOMX headers")
2354   ])
2355   AC_LANG_POP([C++])
2356   CPPFLAGS="${CPPFLAGS_save}"
2357 fi
2358
2359 dnl
2360 dnl CrystalHD codec plugin
2361 dnl
2362 AC_ARG_ENABLE(crystalhd,
2363   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2364 if test "${enable_crystalhd}" != "no"; then
2365     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2366       VLC_ADD_PLUGIN([crystalhd])
2367       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2368     ],[
2369       if test "${SYS}" = "mingw32" ; then
2370         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2371           VLC_ADD_PLUGIN([crystalhd])
2372           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2373             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2374             ])
2375         ],[
2376           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2377                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2378                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2379         ],[#define __LINUX_USER__
2380                #include <libcrystalhd/bc_dts_types.h>
2381         ])
2382       fi
2383     ],[
2384        #include <libcrystalhd/bc_dts_types.h>
2385       ])
2386 fi
2387
2388 dnl
2389 dnl  mad plugin
2390 dnl
2391 AC_ARG_ENABLE(mad,
2392   [  --enable-mad            libmad module (default enabled)])
2393 if test "${enable_mad}" != "no"
2394 then
2395   AC_ARG_WITH(mad,
2396     [  --with-mad=PATH         path to libmad],[],[])
2397   if test "${with_mad}" != "no" -a -n "${with_mad}"
2398   then
2399     VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${with_mad}/include])
2400     VLC_ADD_LIBS([mpgatofixed32],[-L${with_mad}/lib])
2401   fi
2402
2403   AC_ARG_WITH(mad-tree,
2404     [  --with-mad-tree=PATH    mad tree for static linking],[],[])
2405   if test "${with_mad_tree}" != "no" -a -n "${with_mad_tree}"
2406   then
2407     real_mad_tree="`cd ${with_mad_tree} 2>/dev/null && pwd`"
2408     if test -z "${real_mad_tree}"
2409     then
2410       dnl  The given directory can't be found
2411       AC_MSG_RESULT(no)
2412       AC_MSG_ERROR([${with_mad_tree} directory doesn't exist])
2413     fi
2414     dnl  Use a custom libmad
2415     AC_MSG_CHECKING(for mad.h in ${real_mad_tree})
2416     if test -f ${real_mad_tree}/mad.h
2417     then
2418       AC_MSG_RESULT(yes)
2419       VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${real_mad_tree}])
2420       VLC_ADD_LIBS([mpgatofixed32],[-L${real_mad_tree}/.libs])
2421       LDFLAGS="${LDFLAGS_save} ${LIBS_mpgatofixed32}"
2422       AC_CHECK_LIB(mad, mad_bit_init, [
2423         VLC_ADD_PLUGIN([mpgatofixed32])
2424         VLC_ADD_LIBS([mpgatofixed32],[-lmad])
2425         ],[ AC_MSG_ERROR([the specified tree hasn't been compiled ])
2426       ],[])
2427       LDFLAGS="${LDFLAGS_save}"
2428     else
2429       AC_MSG_RESULT(no)
2430       AC_MSG_ERROR([the specified tree doesn't have mad.h])
2431     fi
2432   else
2433     CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_mpgatofixed32}"
2434     LDFLAGS="${LDFLAGS_save} ${LIBS_mpgatofixed32}"
2435     AC_CHECK_HEADERS(mad.h, ,
2436       [ AC_MSG_ERROR([Could not find libmad on your system: you may get it from http://www.underbit.com/products/mad/. Alternatively you can use --disable-mad to disable the mad plugin.]) ])
2437     AC_CHECK_LIB(mad, mad_bit_init, [
2438       VLC_ADD_PLUGIN([mpgatofixed32])
2439       VLC_ADD_LIBS([mpgatofixed32],[-lmad])],
2440       [ AC_MSG_ERROR([Cannot find libmad library...]) ])
2441     CPPFLAGS="${CPPFLAGS_save}"
2442     LDFLAGS="${LDFLAGS_save}"
2443   fi
2444 fi
2445
2446
2447 AC_ARG_ENABLE(merge-ffmpeg,
2448 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2449   enable_merge_ffmpeg="no"
2450 ])
2451 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2452
2453 AC_CACHE_CHECK([if linker supports -Bsymbolic],
2454   [ac_cv_ld_bsymbolic],
2455   [LDFLAGS="${LDFLAGS_vlc} -Wl,-Bsymbolic"
2456     AC_TRY_LINK([],,ac_cv_ld_bsymbolic=yes,ac_cv_ld_bsymbolic=no)
2457     LDFLAGS="${LDFLAGS_save}"
2458   ])
2459
2460 dnl
2461 dnl  avcodec decoder/encoder plugin
2462 dnl
2463 AC_ARG_ENABLE(avcodec,
2464 [  --enable-avcodec        libavcodec codec (default enabled)])
2465 AS_IF([test "${enable_avcodec}" != "no"], [
2466   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= 52.25.0 libavutil],
2467     [
2468       VLC_SAVE_FLAGS
2469       CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2470       CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2471       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2472       AC_CHECK_HEADERS(libavutil/avutil.h)
2473       VLC_ADD_PLUGIN([avcodec])
2474       VLC_ADD_LIBS([avcodec],[$AVCODEC_LIBS])
2475       AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2476         VLC_ADD_LIBS([avcodec],[-Wl,-Bsymbolic])
2477       ])
2478       VLC_ADD_CFLAGS([avcodec],[$AVCODEC_CFLAGS])
2479       VLC_RESTORE_FLAGS
2480       have_avcodec="yes"
2481     ],[
2482       AC_MSG_ERROR([Could not find libavcodec or libavutil. Use --disable-avcodec to ignore this error.])
2483   ])
2484 ], [
2485   have_avcodec="no"
2486 ])
2487
2488 dnl
2489 dnl libva needs avcodec
2490 dnl
2491 AC_ARG_ENABLE(libva,
2492   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2493
2494 AS_IF([test "${enable_libva}" != "no"], [
2495   AS_IF([test "x${have_avcodec}" = "xyes"], [
2496     PKG_CHECK_MODULES(LIBVA, [libva libva-x11],
2497       [
2498         VLC_SAVE_FLAGS
2499         CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2500         CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2501         AC_CHECK_HEADERS(libavcodec/vaapi.h, [
2502            VLC_ADD_LIBS([avcodec],[$LIBVA_LIBS ${X_LIBS} ${X_PRE_LIBS} -lX11])
2503            VLC_ADD_CFLAGS([avcodec],[$LIBVA_CFLAGS ${X_CFLAGS}])
2504            AC_DEFINE(HAVE_AVCODEC_VAAPI, 1, [Define if avcodec has to be built with VAAPI support.])
2505            echo "VAAPI acceleration activated"
2506         ],[
2507     AS_IF([test "${enable_libva}" = "yes"],
2508           [AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])],
2509               [AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])])
2510         ])
2511         VLC_RESTORE_FLAGS
2512       ],[
2513     AS_IF([test "${enable_libva}" = "yes"],
2514               [AC_MSG_ERROR([Could not find required libva.])],
2515               [AC_MSG_WARN([libva not found  ])])
2516       ])
2517   ],[
2518     AS_IF([test "x${enable_libva}" != "x"], [
2519       AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive.])
2520     ])
2521   ])
2522 ])
2523
2524 dnl
2525 dnl dxva2 needs avcodec
2526 dnl
2527 AC_ARG_ENABLE(dxva2,
2528   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2529
2530 AS_IF([test "${enable_dxva2}" != "no"], [
2531   if test "${SYS}" = "mingw32"; then
2532   AS_IF([test "x${have_avcodec}" = "xyes"], [
2533     AC_CHECK_HEADERS(dxva2api.h,
2534       [
2535         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2536            VLC_ADD_LIBS([avcodec],[-lole32 -lshlwapi -luuid])
2537            AC_DEFINE(HAVE_AVCODEC_DXVA2, 1, [Define if avcodec has to be built with DxVA2 support.])
2538            echo "DxVA2 acceleration activated"
2539         ],[
2540     AS_IF([test "${enable_dxva2}" = "yes"],
2541           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2542               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2543         ])
2544       ],[
2545     AS_IF([test "${enable_dxva2}" = "yes"],
2546               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2547               [AC_MSG_WARN([dxva2api.h not found])])
2548       ])
2549   ],[
2550     AS_IF([test "x${enable_dxva2}" != "x"], [
2551       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2552     ])
2553   ])
2554   fi
2555 ])
2556
2557
2558 dnl
2559 dnl stream_out switcher needs libavcodec
2560 dnl
2561 AC_ARG_ENABLE(switcher,
2562   [  --enable-switcher       Stream-out switcher plugin (default disabled)])
2563 AS_IF([test "${enable_switcher}" = "yes"], [
2564   AS_IF([test "x${have_avcodec}" = "xyes"], [
2565     VLC_ADD_PLUGIN([stream_out_switcher])
2566     VLC_ADD_LIBS([stream_out_switcher],[$AVCODEC_LIBS $AVUTIL_LIBS])
2567     VLC_ADD_CFLAGS([stream_out_switcher],[$AVCODEC_CFLAGS $AVUTIL_CFLAGS])
2568   ],[AC_MSG_ERROR([Stream_out switcher depends on avcodec])
2569   ])
2570 ])
2571
2572
2573 dnl
2574 dnl  avformat demuxer/muxer plugin
2575 dnl
2576
2577 AC_ARG_ENABLE(avformat,
2578 [  --enable-avformat       libavformat containers (default enabled)],, [
2579   enable_avformat="${have_avcodec}"
2580 ])
2581 if test "${enable_avformat}" != "no"
2582 then
2583   PKG_CHECK_MODULES(AVFORMAT,[libavformat > 52.30.0 libavcodec libavutil],
2584     [
2585       VLC_SAVE_FLAGS
2586       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2587       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2588       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2589       AC_CHECK_HEADERS(libavutil/avutil.h)
2590       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2591         VLC_ADD_PLUGIN([avformat access_avio])
2592         VLC_ADD_LIBS([avformat access_avio],[$AVFORMAT_LIBS $AVUTIL_LIBS])
2593         VLC_ADD_CFLAGS([avformat access_avio],[$AVFORMAT_CFLAGS $AVUTIL_CFLAGS])
2594         AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2595           VLC_ADD_LIBS([avformat access_avio],[-Wl,-Bsymbolic])
2596         ])
2597       ], [
2598         VLC_ADD_LIBS([avcodec],[$AVFORMAT_LIBS $AVUTIL_LIBS])
2599         VLC_ADD_CFLAGS([avcodec],[$AVFORMAT_CFLAGS $AVUTIL_CFLAGS])
2600       ])
2601       VLC_RESTORE_FLAGS
2602     ],[
2603       AC_MSG_ERROR([Could not find libavformat or libavutil. Use --disable-avformat to ignore this error.])
2604   ])
2605 fi
2606
2607 dnl
2608 dnl  swscale image scaling and conversion plugin
2609 dnl
2610
2611 AC_ARG_ENABLE(swscale,
2612   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2613           (default enabled)]))
2614 if test "${enable_swscale}" != "no"
2615 then
2616   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2617     [
2618       VLC_SAVE_FLAGS
2619       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2620       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2621       AC_CHECK_HEADERS(libswscale/swscale.h)
2622       VLC_ADD_PLUGIN([swscale])
2623       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2624       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2625       AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2626         VLC_ADD_LIBS([swscale],[-Wl,-Bsymbolic])
2627       ])
2628       VLC_RESTORE_FLAGS
2629     ],[
2630       AC_MSG_ERROR([Could not find libswscale. Use --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2631   ])
2632 fi
2633
2634 dnl
2635 dnl  postproc plugin
2636 dnl
2637
2638 AC_ARG_ENABLE(postproc,
2639 [  --enable-postproc       libpostproc image post-processing (default enabled)])
2640 if test "${enable_postproc}" != "no"
2641 then
2642   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2643     [
2644       VLC_SAVE_FLAGS
2645       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2646       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2647       AC_CHECK_HEADERS(postproc/postprocess.h)
2648       VLC_ADD_PLUGIN([postproc])
2649       VLC_ADD_LIBS([postproc],[$POSTPROC_LIBS $AVUTIL_LIBS])
2650       VLC_ADD_CFLAGS([postproc],[$POSTPROC_CFLAGS $AVUTIL_CFLAGS])
2651       VLC_RESTORE_FLAGS
2652     ],[
2653       AC_MSG_ERROR([Could not find libpostproc. Use --disable-postproc to ignore this error.])
2654   ])
2655 fi
2656
2657 dnl
2658 dnl  faad decoder plugin
2659 dnl
2660 AC_ARG_ENABLE(faad,
2661 [  --enable-faad           faad codec (default disabled)])
2662 if test "${enable_faad}" = "yes"
2663 then
2664   AC_ARG_WITH(faad-tree,
2665   [  --with-faad-tree=PATH   faad tree for static linking])
2666   if test -n "${with_faad_tree}"
2667   then
2668     AC_MSG_CHECKING(for libfaad.a in ${with_faad_tree})
2669     real_faad_tree="`cd ${with_faad_tree} 2>/dev/null && pwd`"
2670     if test -z "${real_faad_tree}"
2671     then
2672       dnl  The given directory can't be found
2673       AC_MSG_RESULT(no)
2674       AC_MSG_ERROR([cannot cd to ${with_faad_tree}])
2675     fi
2676     if test -f "${real_faad_tree}/libfaad/.libs/libfaad.a"
2677     then
2678       dnl  Use a custom faad
2679       AC_MSG_RESULT(${real_faad_tree}/libfaad/.libs/libfaad.a)
2680       VLC_ADD_PLUGIN([faad])
2681       VLC_ADD_LIBS([faad],[${real_faad_tree}/libfaad/.libs/libfaad.a])
2682       VLC_ADD_CPPFLAGS([faad],[-I${real_faad_tree}/include])
2683     else
2684       dnl  The given libfaad wasn't built
2685       AC_MSG_RESULT(no)
2686       AC_MSG_ERROR([cannot find ${real_faad_tree}/libfaad/.libs/libfaad.a, make sure you compiled libfaad in ${with_faad_tree}])
2687     fi
2688   else
2689     CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_faad}"
2690     LDFLAGS="${LDFLAGS_save} ${LIBS_faad}"
2691     AC_CHECK_HEADERS(faad.h, ,
2692       [ AC_MSG_ERROR([Cannot find development headers for libfaad...]) ])
2693     AC_CHECK_LIB(faad, faacDecOpen, [
2694       VLC_ADD_PLUGIN([faad])
2695       VLC_ADD_LIBS([faad],[-lfaad]) ],
2696       AC_CHECK_LIB(faad, NeAACDecOpen, [
2697         VLC_ADD_PLUGIN([faad])
2698         VLC_ADD_LIBS([faad],[-lfaad]) ],
2699         [ AC_MSG_ERROR([Cannot find libfaad library...]) ]))
2700     LDFLAGS="${LDFLAGS_save}"
2701     CPPFLAGS="${CPPFLAGS_save}"
2702   fi
2703 fi
2704
2705 dnl
2706 dnl twolame encoder plugin
2707 dnl
2708 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2709
2710 dnl
2711 dnl  QuickTime plugin
2712 dnl
2713 AC_ARG_ENABLE(quicktime,
2714   [  --enable-quicktime      QuickTime module (deprecated)])
2715 if test "${enable_quicktime}" = "yes"; then
2716   if test "${SYS}" = "mingw32"; then
2717     VLC_ADD_PLUGIN([quicktime])
2718   else
2719   AC_CHECK_HEADERS(QuickTime/QuickTime.h,
2720     [ VLC_ADD_PLUGIN([quicktime])
2721       VLC_ADD_LIBS([quicktime],[-Wl,-framework,QuickTime,-framework,Carbon])
2722     ], [ AC_MSG_ERROR([cannot find QuickTime headers]) ])
2723   fi
2724 fi
2725
2726 dnl
2727 dnl  Real plugin
2728 dnl
2729 AC_ARG_ENABLE(real,
2730   [  --enable-real           Real video decoder module (default disabled)])
2731 if test "${enable_real}" = "yes"; then
2732   VLC_ADD_PLUGIN([realvideo])
2733 fi
2734
2735 dnl
2736 dnl A52/AC3 decoder plugin
2737 dnl
2738 AC_ARG_ENABLE(a52,
2739   [  --enable-a52            A/52 support with liba52 (default enabled)])
2740 if test "${enable_a52}" != "no"
2741 then
2742   AC_ARG_WITH(a52,
2743     [  --with-a52=PATH         a52 headers and libraries])
2744   AC_ARG_WITH(a52-tree,
2745     [  --with-a52-tree=PATH    a52dec tree for static linking ],[],[])
2746   if test "${with_a52_tree}" != "no" -a -n "${with_a52_tree}"
2747   then
2748     real_a52_tree="`cd ${with_a52_tree} 2>/dev/null && pwd`"
2749     if test -z "${real_a52_tree}"
2750     then
2751       dnl  The given directory can't be found
2752       AC_MSG_RESULT(no)
2753       AC_MSG_ERROR([${with_a52_tree} directory doesn't exist])
2754     fi
2755     dnl  Use a custom a52dec
2756     AC_MSG_CHECKING(for a52.h in ${real_a52_tree}/include)
2757     if test -f ${real_a52_tree}/include/a52.h
2758     then
2759       AC_MSG_RESULT(yes)
2760       VLC_ADD_CPPFLAGS([a52tofloat32],[-I${real_a52_tree}])
2761       VLC_ADD_LIBS([a52tofloat32],[-L${real_a52_tree}/liba52/.libs])
2762       LDFLAGS="${LDFLAGS_save} ${LIBS_a52tofloat32}"
2763       AC_CHECK_LIB(a52, a52_free, [
2764         VLC_ADD_PLUGIN([a52tofloat32])
2765         VLC_ADD_CPPFLAGS([a52tofloat32],[-DUSE_A52DEC_TREE])
2766         VLC_ADD_LIBS([a52tofloat32],[-la52])
2767         ],[
2768         if test -f ${real_a52_tree}/liba52/.libs/liba52.a
2769         then
2770           AC_MSG_ERROR([make sure you have at least a52dec-0.7.3 ($real_a52_tree)])
2771         else
2772           AC_MSG_ERROR([the specified tree hasn't been compiled])
2773         fi
2774       ])
2775       LDFLAGS="${LDFLAGS_save}"
2776     else
2777       AC_MSG_RESULT(no)
2778       AC_MSG_ERROR([the specified tree doesn't have a52.h])
2779     fi
2780   else
2781     if test -z "${with_a52}"
2782     then
2783       LDFLAGS_test=""
2784       CPPFLAGS_test=""
2785     else
2786       LDFLAGS_test="-L${with_a52}/lib"
2787       CPPFLAGS_test="-I${with_a52}/include"
2788     fi
2789     CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_test} ${CPPFLAGS_a52tofloat32}"
2790     LDFLAGS="${LDFLAGS_save} ${LDFLAGS_test} ${LIBS_a52tofloat32}"
2791     AC_CHECK_HEADERS(a52dec/a52.h, [
2792       AC_CHECK_LIB(a52, a52_free, [
2793         VLC_ADD_PLUGIN([a52tofloat32])
2794         VLC_ADD_LIBS([a52tofloat32],[${LDFLAGS_test} -la52])
2795         VLC_ADD_CPPFLAGS([a52tofloat32],[${CPPFLAGS_test}])
2796       ],[
2797         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2798         ])
2799     ],[
2800       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2801     ])
2802     CPPFLAGS="${CPPFLAGS_save}"
2803     LDFLAGS="${LDFLAGS_save}"
2804   fi
2805 fi
2806
2807 AC_ARG_WITH(a52-fixed,
2808       [  --with-a52-fixed        specify if liba52 has been compiled with fixed point support],
2809       [
2810         VLC_ADD_CPPFLAGS([a52tofloat32],[-DLIBA52_FIXED]) ])
2811
2812 dnl
2813 dnl DTS Coherent Acoustics decoder plugin
2814 dnl
2815 PKG_ENABLE_MODULES_VLC([DCA], [dtstofloat32], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2816
2817 dnl
2818 dnl  Flac plugin
2819 dnl
2820 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2821
2822 dnl
2823 dnl  Libmpeg2 plugin
2824 dnl
2825 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2826
2827 dnl
2828 dnl  Vorbis plugin
2829 dnl
2830 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2831
2832 dnl
2833 dnl  Tremor plugin
2834 dnl
2835 AC_ARG_ENABLE(tremor,
2836   [  --enable-tremor         Tremor decoder support (default disabled)])
2837 if test "${enable_tremor}" = "yes"
2838 then
2839   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2840     VLC_ADD_PLUGIN([tremor])
2841     VLC_ADD_LIBS([tremor],[-lvorbisidec -logg])
2842    ],[])
2843 fi
2844
2845 dnl
2846 dnl  Speex plugin
2847 dnl
2848 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex decoder support], [auto])
2849
2850 dnl
2851 dnl  theora decoder plugin
2852 dnl
2853 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theora >= 1.0], [experimental theora codec], [auto])
2854
2855 dnl
2856 dnl  dirac encoder plugin
2857 dnl
2858 PKG_ENABLE_MODULES_VLC([DIRAC], [], [dirac >= 0.10.0], [dirac encoder], [auto])
2859
2860 dnl
2861 dnl  schroedinger decoder plugin (for dirac format video)
2862 dnl
2863 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2864
2865 dnl
2866 dnl  PNG decoder module
2867 dnl
2868 AC_ARG_ENABLE(png,
2869   [  --enable-png            PNG support (default enabled)])
2870 if test "${enable_png}" != "no"; then
2871 AC_CHECK_HEADERS(png.h, [
2872   LDFLAGS="${LDFLAGS_save} -lz"
2873   AC_CHECK_LIB(png, png_set_rows, [
2874     VLC_ADD_LIBS([png],[-lpng -lz -lm])
2875     VLC_ADD_PLUGIN([png osdmenu osd_parser])],
2876     [],[-lz])
2877     LDFLAGS="${LDFLAGS_save}"
2878   ])
2879 fi
2880 AM_CONDITIONAL(BUILD_OSDMENU, [test "${enable_png}" != "no"])
2881
2882 dnl
2883 dnl H264 encoder plugin (using libx264)
2884 dnl
2885 AC_ARG_ENABLE(x264,
2886   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2887 if test "${enable_x264}" != "no"; then
2888   AC_ARG_WITH(x264-tree,
2889     [  --with-x264-tree=PATH   x264 tree for static linking ],[],[])
2890   if test "${with_x264_tree}" != "no" -a -n "${with_x264_tree}"
2891   then
2892     real_x264_tree="`cd ${with_x264_tree} 2>/dev/null && pwd`"
2893     if test -z "${real_x264_tree}"
2894     then
2895       dnl  The given directory can't be found
2896       AC_MSG_RESULT(no)
2897       AC_MSG_ERROR([${with_x264_tree} directory doesn't exist])
2898     fi
2899     dnl  Use a custom libx264
2900     AC_MSG_CHECKING(for x264.h in ${real_x264_tree})
2901     if test -f ${real_x264_tree}/x264.h
2902     then
2903       AC_MSG_RESULT(yes)
2904       VLC_ADD_CPPFLAGS([x264],[-I${real_x264_tree}])
2905       VLC_ADD_LIBS([x264],[-L${real_x264_tree}])
2906       PKG_CHECK_MODULES(X264,x264, [
2907         VLC_ADD_PLUGIN([x264])
2908         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2909         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2910         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2911           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2912         fi
2913       ],[
2914         AC_MSG_ERROR([the specified tree hasn't been compiled])
2915       ])
2916       LDFLAGS="${LDFLAGS_save}"
2917     else
2918       AC_MSG_RESULT(no)
2919       AC_MSG_ERROR([the specified tree doesn't have x264.h])
2920     fi
2921   else
2922       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2923         VLC_ADD_PLUGIN([x264])
2924         VLC_ADD_LDFLAGS([x264],[${X264_LIBS}])
2925
2926         AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2927           VLC_ADD_LIBS([x264],[-Wl,-Bsymbolic])
2928         ])
2929
2930         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2931         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2932           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2933         fi
2934       ],[
2935         if test "${enable_x264}" = "yes"; then
2936             AC_MSG_ERROR([Could not find libx264 >= 0.86 on your system: you may get it from http://www.videolan.org/x264.html])
2937           fi
2938       ])
2939     LDFLAGS="${LDFLAGS_save}"
2940   fi
2941 fi
2942
2943 dnl
2944 dnl libfluidsynth (MIDI synthetizer) plugin
2945 dnl
2946 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth], [MIDI synthetiser with libfluidsynth], [auto])
2947
2948 dnl
2949 dnl Teletext Modules
2950 dnl vbi decoder plugin (using libzbvi)
2951 dnl telx module
2952 dnl uncompatible
2953 dnl
2954 AC_ARG_ENABLE(zvbi,
2955   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2956                   libzvbi (default enabled)]))
2957 AC_ARG_ENABLE(telx,
2958   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2959                   zvbi) (default enabled if zvbi is absent)]))
2960
2961 AS_IF( [test "${enable_zvbi}" != "no"],[
2962     PKG_CHECK_MODULES(ZVBI,
2963         zvbi-0.2 >= 0.2.28,
2964         [
2965           VLC_ADD_LIBS([zvbi],[$ZVBI_LIBS])
2966           if test "${SYS}" = "mingw32"; then
2967               VLC_ADD_LIBS([zvbi],[ -lpthreadGC2])
2968           fi
2969           VLC_ADD_CFLAGS([zvbi],[$ZVBI_CFLAGS])
2970           VLC_ADD_PLUGIN([zvbi])
2971           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2972           AS_IF( [test "${enable_telx}" = "yes"],[
2973                   AC_MSG_WARN([The zvbi and telx modules are uncompatibles.
2974                                Using zvbi.])
2975                   ])
2976         ],[
2977           AC_MSG_WARN(ZVBI library not found. Enabling the telx module instead)
2978         ])
2979     ])
2980 AS_IF( [test "${enable_telx}" != "no" ],[
2981   VLC_ADD_PLUGIN([telx])
2982   ])
2983
2984 dnl
2985 dnl libass subtitle rendering module
2986 dnl
2987 AC_ARG_ENABLE(libass,
2988   [  --enable-libass         Subtitle support using libass (default enabled)])
2989 AS_IF( [test "${enable_libass}" != "no"], [
2990   PKG_CHECK_MODULES(LIBASS, libass >= 0.9.8,
2991       [
2992         VLC_ADD_LIBS([libass],[$LIBASS_LIBS])
2993         VLC_ADD_CFLAGS([libass],[$LIBASS_CFLAGS])
2994         VLC_ADD_PLUGIN([libass])
2995
2996         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2997           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2998            VLC_ADD_LIBS([libass],[-lfontconfig])
2999        ])
3000       ],[
3001         AC_MSG_WARN([LIBASS library not found])
3002       ])
3003   ])
3004
3005 dnl
3006 dnl  kate decoder plugin
3007 dnl
3008 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
3009
3010 dnl
3011 dnl  tiger rendering for kate decoder plugin
3012 dnl
3013 AC_ARG_ENABLE(tiger,
3014 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
3015 AS_IF([test "${enable_tiger}" != "no"], [
3016   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
3017       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])
3018       VLC_ADD_CFLAGS([kate],[$TIGER_CFLAGS])
3019       VLC_ADD_LIBS([kate],[$TIGER_LIBS]) ],[
3020         AS_IF([test "x${enable_tiger}" != "x"], [
3021           AC_MSG_ERROR([libtiger does not appear to be installed on your system.])
3022         ])
3023   ])
3024 ])
3025
3026
3027 dnl
3028 dnl  Video plugins
3029 dnl
3030
3031 EXTEND_HELP_STRING([Video plugins:])
3032
3033 dnl
3034 dnl  Xlib
3035 dnl
3036
3037 AC_PATH_XTRA()
3038 AC_CHECK_HEADERS(X11/Xlib.h)
3039
3040 dnl
3041 dnl  X C Bindings modules
3042 dnl
3043 AC_ARG_ENABLE(xcb,
3044   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3045   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce" -a "${SYS}" != "darwin" -a "${SYS}" != "symbian"], [
3046     enable_xcb="yes"
3047   ], [
3048     enable_xcb="no"
3049   ])
3050 ])
3051 AC_ARG_ENABLE(xvideo,
3052   [  --enable-xvideo         XVideo support (default enabled)],, [
3053     enable_xvideo="$enable_xcb"
3054 ])
3055
3056 have_xcb="no"
3057 AS_IF([test "${enable_xcb}" != "no"], [
3058   dnl libxcb
3059   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3060   have_xcb="yes"
3061   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3062   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3063
3064   AS_IF([test "${enable_xvideo}" != "no"], [
3065     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [
3066       VLC_ADD_PLUGIN([xcb_xv])
3067     ])
3068   ])
3069
3070   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [
3071     VLC_ADD_PLUGIN([panoramix])
3072     VLC_ADD_LIBS([panoramix],[${XCB_RANDR_LIBS} ${XCB_LIBS}])
3073     VLC_ADD_CFLAGS([panoramix],[${XCB_RANDR_CFLAGS} ${XCB_CFLAGS}])
3074   ], [
3075     AC_MSG_WARN([libxcb-randr not found. Panoramix filter will not be supported.])
3076   ])
3077
3078   dnl xcb-utils
3079   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [
3080     PKG_CHECK_MODULES(XPROTO, [xproto])
3081     VLC_ADD_PLUGIN([globalhotkeys])
3082     VLC_ADD_CFLAGS([globalhotkeys], [${XCB_KEYSYMS_CFLAGS} ${XCB_CFLAGS}])
3083     VLC_ADD_LIBS([globalhotkeys], [${XCB_KEYSYMS_LIBS} ${XCB_LIBS}])
3084     VLC_ADD_CFLAGS([xcb_window], [-DHAVE_XCB_KEYSYMS])
3085   ], [
3086     AC_MSG_WARN([libxcb-keysyms (0.3.4 or later) not found. Hotkeys will not work.])
3087   ])
3088 ])
3089 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3090
3091 AC_ARG_ENABLE(glx,
3092   [  --enable-glx            X11 OpenGL (GLX) support (default enabled)],, [
3093   enable_glx="$enable_xcb"
3094 ])
3095 AS_IF([test "${enable_glx}" != "no"], [
3096   PKG_CHECK_MODULES(XLIB_XCB, [x11-xcb])
3097   PKG_CHECK_MODULES(GL, [gl],, [
3098     AC_CHECK_HEADER([GL/gl.h], [
3099       GL_CFLAGS=""
3100       GL_LIBS="-lGL"
3101     ], [
3102       AC_MSG_ERROR([GLX (libGL) cannot be found. If you do not need OpenGL with X11, use --disable-glx.])
3103     ])
3104   ])
3105   VLC_ADD_PLUGIN([xcb_glx])
3106 ])
3107
3108 dnl
3109 dnl  OpenGL
3110 dnl
3111 PKG_ENABLE_MODULES_VLC([GL], [], [gl], [OpenGL support], [auto])
3112 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [auto])
3113 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [auto])
3114 PKG_ENABLE_MODULES_VLC([EGL], [], [egl], [EGL support], [auto])
3115
3116 dnl
3117 dnl  SDL module
3118 dnl
3119 AC_ARG_ENABLE(sdl,
3120   [  --enable-sdl            SDL support (default enabled)])
3121 AC_ARG_ENABLE(sdl-image,
3122   [  --enable-sdl-image      SDL image support (default enabled)])
3123 if test "${enable_sdl}" != "no"
3124 then
3125    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3126       # SDL on Darwin is heavily patched and can only run SDL_image
3127       if test "${SYS}" != "darwin"; then
3128         VLC_ADD_PLUGIN([vout_sdl])
3129       fi
3130       if test "${SYS}" != "mingw32" -a "${SYS}" != "os2"; then
3131         VLC_ADD_LIBS([vout_sdl],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3132       fi
3133       VLC_ADD_CFLAGS([vout_sdl],[${SDL_CFLAGS}])
3134       VLC_ADD_LIBS([vout_sdl],[${SDL_LIBS}])
3135
3136       # SDL_image
3137       AS_IF([ test "${enable_sdl_image}" != "no"],[
3138         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3139           VLC_ADD_PLUGIN([sdl_image])
3140           VLC_ADD_LIBS([sdl_image],[${SDL_IMAGE_LIBS}])
3141           VLC_ADD_CFLAGS([sdl_image], [${SDL_IMAGE_CFLAGS}])],
3142           [ AC_MSG_WARN([The development package for SDL_image is not installed.
3143     You should install it alongside your SDL package.])
3144           ])
3145       ])
3146    ],[
3147      AC_MSG_WARN([The development package for SDL is not present or too old.
3148                   You need 1.2.10. Alternatively you can also configure with
3149                   --disable-sdl.])
3150    ])
3151 fi
3152
3153
3154 dnl
3155 dnl Mac Vout
3156 AC_ARG_ENABLE(macosx-vout,
3157   [  --enable-macosx-vout    Mac OS X video output module (default enabled on Mac OS X)])
3158 if test "x${enable_macosx_vout}" != "xno" &&
3159   (test "${SYS}" = "darwin" || test "${enable_macosx_vout}" = "yes")
3160 then
3161   VLC_ADD_LIBS([vout_macosx],[-Wl,-framework,Cocoa])
3162   VLC_ADD_LIBS([vout_macosx],[-Wl,-framework,OpenGL])
3163   VLC_ADD_PLUGIN([vout_macosx])
3164 fi
3165
3166
3167 dnl
3168 dnl  freetype module
3169 dnl
3170 AC_ARG_ENABLE(freetype,
3171   [  --enable-freetype       freetype support   (default auto)])
3172 AC_ARG_ENABLE(fribidi,
3173   [  --enable-fribidi        fribidi support    (default auto)])
3174 AC_ARG_ENABLE(fontconfig,
3175   [  --enable-fontconfig     fontconfig support (default auto)])
3176
3177 if test "${enable_freetype}" != "no"; then
3178    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3179       have_freetype=yes
3180       VLC_ADD_PLUGIN([freetype])
3181       VLC_ADD_CPPFLAGS([freetype skins2],[${FREETYPE_CFLAGS}])
3182       if test "${SYS}" = "mingw32"; then
3183         VLC_ADD_LIBS([freetype],[-liconv -lz])
3184       fi
3185       VLC_ADD_LIBS([freetype skins2],[${FREETYPE_LIBS}])
3186
3187       AC_CHECK_HEADERS(Carbon/Carbon.h,
3188                        [VLC_ADD_LIBS([freetype],[-Wl,-framework,Carbon])])
3189
3190       dnl fontconfig support
3191       if test "${SYS}" != "mingw32"; then
3192           if test "${enable_fontconfig}" != "no"; then
3193             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3194               VLC_ADD_CPPFLAGS([freetype],[-DHAVE_FONTCONFIG])
3195               VLC_ADD_LIBS([freetype],[-lfontconfig])
3196             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3197           fi
3198       else
3199           VLC_ADD_LIBS([freetype],[-lgdi32])
3200       fi
3201
3202       dnl fribidi support
3203       if test "${enable_fribidi}" != "no"; then
3204         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3205           VLC_ADD_CPPFLAGS([freetype skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3206           VLC_ADD_LIBS([freetype skins2], [${FRIBIDI_LIBS}])
3207         ],[AC_MSG_WARN([library fribidi not found. Bidirectional support will be disabled in freetype])])
3208       fi
3209
3210   ],[
3211   have_freetype=no
3212   AS_IF([ test "${enable_freetype}" = "yes"],[
3213     AC_MSG_ERROR([Freetype2 package cannot be detected. Install Freetype2 development or configure with --disable-freetype.])
3214     ])
3215   ])
3216 fi
3217
3218
3219 dnl
3220 dnl  QuartzText vout module (iOS/Mac OS)
3221 dnl
3222 AC_ARG_ENABLE(macosx-quartztext,
3223   [  --enable-macosx-quartztext   Mac OS X quartz text module (default enabled on Mac OS X)])
3224 if test "x${enable_macosx_quartztext}" != "xno" &&
3225   (test "${SYS}" = "darwin" || test "${enable_macosx_quartztext}" = "yes")
3226 then
3227   VLC_ADD_PLUGIN([quartztext])
3228   VLC_ADD_LIBS([quartztext],[-Wl,-framework,ApplicationServices])
3229 fi
3230
3231 dnl
3232 dnl  SVG module
3233 dnl
3234 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3235
3236 dnl
3237 dnl  android surface module
3238 dnl
3239 AC_ARG_ENABLE(android-surface,
3240   [  --enable-android-surface   Android Surface video output module (default disabled)])
3241 if test "${enable_android_surface}" = "yes"; then
3242   if test "${HAVE_ANDROID}" = "1"; then
3243      VLC_ADD_PLUGIN([android_surface])
3244      VLC_ADD_LDFLAGS([android_surface], [-ldl])
3245   fi
3246 fi
3247
3248
3249 dnl
3250 dnl  iOS vout module
3251 dnl
3252 AC_ARG_ENABLE(ios-vout,
3253   [  --enable-ios-vout    iOS video output module (default disabled)])
3254 if test "${enable_ios_vout}" = "yes"
3255 then
3256   VLC_ADD_PLUGIN([vout_ios])
3257   VLC_ADD_CFLAGS([vout_ios], [-DUSE_OPENGL_ES=1])
3258   VLC_ADD_LIBS([vout_ios], [-Wl,-framework,OpenGLES,-framework,QuartzCore,-framework,UIKit,-framework,Foundation])
3259 fi
3260
3261 dnl
3262 dnl  Windows DirectX module
3263 dnl
3264
3265 if test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"
3266 then
3267   VLC_ADD_PLUGIN([panoramix])
3268 fi
3269
3270 AC_ARG_ENABLE(directx,
3271   [  --enable-directx        Win32 DirectX support (default enabled on Win32)])
3272 if test "${enable_directx}" != "no"; then
3273   if test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"; then
3274       dnl DDraw
3275       AC_CHECK_HEADERS(ddraw.h,
3276       [ VLC_ADD_PLUGIN([directx aout_directx])
3277         VLC_ADD_LIBS([directx],[-luser32 -lgdi32])
3278       ],[AC_MSG_ERROR([Cannot find DirectX headers!])]
3279       )
3280
3281       dnl OpenGL
3282       AC_CHECK_HEADERS(GL/glext.h,
3283       [ VLC_ADD_PLUGIN([glwin32])
3284         VLC_ADD_LIBS([glwin32],[-lopengl32 -lgdi32])
3285       ],[],[
3286         #include <GL/gl.h>
3287       ])
3288
3289       dnl Direct3D
3290       AC_CHECK_HEADERS(d3d9.h,
3291       [ VLC_ADD_PLUGIN([direct3d])
3292         VLC_ADD_LIBS([direct3d],[-lgdi32])
3293       ])
3294       VLC_ADD_LIBS([direct3d directx glwin32],[-lole32])
3295   fi
3296 fi
3297
3298 dnl
3299 dnl  Windows Direct2D plugin
3300 dnl
3301 AC_ARG_ENABLE(direct2d,
3302   [  --enable-direct2d       Win7/VistaPU Direct2D support (default auto on Win32)],, [
3303   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"], [
3304     enable_direct2d="no"
3305   ])
3306 ])
3307 AS_IF([test "${enable_direct2d}" != "no"], [
3308   AC_CHECK_HEADERS(d2d1.h, [
3309     VLC_ADD_PLUGIN([direct2d])
3310     VLC_ADD_LIBS([direct2d],[-lgdi32 -lole32])
3311   ], [
3312     AC_MSG_WARN([Cannot find Direct2D headers!])
3313   ])
3314 ])
3315
3316 dnl
3317 dnl  win32 GDI plugin
3318 dnl
3319 AC_ARG_ENABLE(wingdi,
3320   [  --enable-wingdi         Win32 GDI module (default enabled on Win32)])
3321 if test "${enable_wingdi}" != "no"; then
3322   if test "${SYS}" = "mingw32"; then
3323     VLC_ADD_PLUGIN([wingdi])
3324     VLC_ADD_LIBS([wingdi],[-lgdi32 -lole32])
3325   fi
3326   if test "${SYS}" = "mingwce"; then
3327     VLC_ADD_PLUGIN([wingdi wingapi])
3328     VLC_ADD_LIBS([wingdi],[-laygshell])
3329     VLC_ADD_LIBS([wingapi],[-laygshell])
3330   fi
3331 fi
3332
3333
3334 dnl
3335 dnl  Linux framebuffer module
3336 dnl
3337 AC_CHECK_HEADER([linux/fb.h], [
3338   VLC_ADD_PLUGIN([fb])
3339 ])
3340
3341
3342 dnl
3343 dnl  DirectFB module
3344 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3345 dnl  TODO: support for static linking
3346 dnl
3347 AC_ARG_ENABLE(directfb,
3348   [  --enable-directfb       DirectFB support (default disabled)])
3349 AC_ARG_WITH(directfb,
3350   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3351
3352 if test "${enable_directfb}" = "yes"; then
3353     have_directfb="false"
3354     CPPFLAGS_mydirectfb=
3355     LIBS_mydirectfb=
3356     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3357         dnl Trying the given location
3358         CPPFLAGS_save="${CPPFLAGS}"
3359         LIBS_save="${LIBS}"
3360
3361         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3362         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/"
3363         LIBS_new="${LIBS_new} -L${with_directfb}/src/.libs/"
3364
3365         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3366         LIBS="${LIBS} ${LIBS_new}"
3367
3368         dnl FIXME: too obscure
3369         AC_CHECK_HEADER([directfb.h], [
3370             AC_CHECK_LIB([direct],[direct_initialize], [
3371                 AC_CHECK_LIB([fusion], [fusion_enter], [
3372                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3373                 ], have_directfb="false")
3374             ], have_directfb="false")
3375         ], have_directfb="false")
3376
3377         dnl Restore flags
3378         CPPFLAGS="${CPPFLAGS_save}"
3379         LIBS="${LIBS_save}"
3380
3381         if test "${have_directfb}" = "true"; then
3382             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3383             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3384         fi
3385     else
3386         dnl Look for directfb-config
3387         AC_PATH_PROG(DIRECTFB_CONFIG, directfb-config, no, ${PATH})
3388         if test "${DIRECTFB_CONFIG}" != "no"; then
3389             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3390             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3391             have_directfb="true"
3392         else
3393             dnl Trying with pkg-config
3394             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3395                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3396                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3397                 have_directfb="true"
3398                 ], [have_directfb="false"])
3399         fi
3400     fi
3401     if test "${have_directfb}" = "true"; then
3402         VLC_ADD_PLUGIN([directfb])
3403         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3404         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3405     else
3406         AC_MSG_ERROR([cannot find directfb headers and/or libraries ])
3407     fi
3408 fi
3409
3410 dnl
3411 dnl  AA plugin
3412 dnl
3413 AC_ARG_ENABLE(aa,
3414   [  --enable-aa             aalib output (default disabled)])
3415 if test "${enable_aa}" = "yes"
3416 then
3417   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3418   if test "${have_aa}" = "true"
3419   then
3420     VLC_ADD_PLUGIN([aa])
3421     VLC_ADD_LIBS([aa],[-laa])
3422     if test "${SYS}" != "mingw32"; then
3423       VLC_ADD_LIBS([aa],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3424     fi
3425   fi
3426 fi
3427
3428 dnl
3429 dnl  libcaca plugin
3430 dnl
3431 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3432
3433 dnl
3434 dnl  Audio plugins
3435 dnl
3436
3437 EXTEND_HELP_STRING([Audio plugins:])
3438
3439 dnl
3440 dnl  Pulseaudio module
3441 dnl
3442 AC_ARG_ENABLE(pulse,
3443   [AS_HELP_STRING([--enable-pulse],
3444     [use the PulseAudio client library (default auto)])])
3445 have_pulse="no"
3446 AS_IF([test "${enable_pulse}" != "no"], [
3447   PKG_CHECK_MODULES([PULSE], [libpulse >= 0.9.22], [
3448     have_pulse="yes"
3449   ], [
3450     PKG_CHECK_MODULES([PULSE], [libpulse >= 0.9.16], [
3451       AS_IF([test "${no_x}" != "yes"], [
3452         have_pulse="yes"
3453         PULSE_LIBS="$PULSE_LIBS ${X_LIBS} ${X_PRE_LIBS} -lX11"
3454       ], [
3455         AS_IF([test "${enable_pulse}" = "yes"], [
3456           AC_MSG_ERROR([Xlib is required with PulseAudio pre-0.9.22 versions
3457 (see http://www.pulseaudio.org/ticket/799 for further reference).])
3458         ])
3459       ])
3460     ], [
3461       AS_IF([test "x${enable_pulse}" != "x"], [
3462         AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 0.9.22 or later required.])
3463       ])
3464     ])
3465   ])
3466 ])
3467 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3468
3469 dnl
3470 dnl  ALSA module
3471 dnl
3472 AC_ARG_ENABLE(alsa,
3473   [AS_HELP_STRING([--enable-alsa],
3474     [support the Advanced Linux Sound Architecture (default auto)])],, [
3475   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3476     enable_alsa="yes"
3477   ])
3478 ])
3479 have_alsa="no"
3480 AS_IF([test "${enable_alsa}" != "no"], [
3481   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.16], [
3482     have_alsa="yes"
3483   ], [
3484     AS_IF([test "x${enable_alsa}" != "x"], [
3485       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.16 or later required.])
3486     ])
3487   ])
3488 ])
3489 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3490
3491 dnl
3492 dnl  Open Sound System module
3493 dnl
3494 AC_ARG_ENABLE(oss,
3495   [AS_HELP_STRING([--enable-oss],
3496     [support the Open Sound System OSS (default enabled on BSD)])],, [
3497   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "mingwce" -o "$SYS" = "linux"], [
3498     enable_oss="no"
3499   ])
3500 ])
3501 have_oss="no"
3502 OSS_LIBS=""
3503 AS_IF([test "$enable_oss" != "no"], [
3504   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3505     have_oss="yes"
3506     AC_CHECK_LIB(ossaudio, main, [
3507       OSS_LIBS="-lossaudio"
3508     ])
3509   ])
3510 ])
3511 AC_SUBST(OSS_LIBS)
3512 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3513
3514 dnl
3515 dnl  Portaudio module
3516 dnl
3517 PKG_ENABLE_MODULES_VLC([PORTAUDIO], [], [portaudio-2.0], [Portaudio library support], [auto])
3518
3519 dnl
3520 dnl  win32 waveOut plugin
3521 dnl
3522 AC_ARG_ENABLE(waveout,
3523   [  --enable-waveout        Win32 waveOut module (default enabled on Win32)])
3524 if test "${enable_waveout}" != "no"; then
3525   if test "${SYS}" = "mingw32"; then
3526     VLC_ADD_PLUGIN([waveout])
3527     VLC_ADD_LIBS([waveout],[-lwinmm])
3528   fi
3529   if test "${SYS}" = "mingwce"; then
3530     VLC_ADD_PLUGIN([waveout])
3531   fi
3532 fi
3533
3534 dnl
3535 dnl  CoreAudio plugin
3536 dnl
3537 AC_ARG_ENABLE(macosx-audio,
3538   [  --enable-macosx-audio   Mac OS X audio module (default enabled on MacOS X)])
3539 if test "x${enable_macosx_audio}" != "xno" &&
3540   (test "${SYS}" = "darwin" || test "${enable_macosx_audio}" = "yes")
3541 then
3542   AC_CHECK_HEADERS(CoreAudio/CoreAudio.h,
3543     [ VLC_ADD_PLUGIN([auhal])
3544       VLC_ADD_LIBS([auhal],[-Wl,-framework,CoreAudio,-framework,AudioUnit,-framework,AudioToolbox,-framework,Carbon])
3545     ], [ AC_MSG_ERROR([cannot find CoreAudio headers]) ])
3546 fi
3547
3548 dnl
3549 dnl  AudioQueue plugin
3550 dnl
3551 AC_ARG_ENABLE(audioqueue,
3552   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3553 if test "${enable_audioqueue}" = "yes"
3554 then
3555   VLC_ADD_PLUGIN([audioqueue])
3556   VLC_ADD_LIBS([audioqueue], [-Wl,-framework,AudioToolbox,-framework,CoreFoundation])
3557 fi
3558
3559 dnl
3560 dnl  JACK modules
3561 dnl
3562 PKG_ENABLE_MODULES_VLC([JACK], [jack access_jack], [jack], [JACK audio I/O modules],[auto])
3563
3564 dnl
3565 dnl  OpenSLES Android
3566 dnl
3567 AC_ARG_ENABLE(opensles,
3568   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3569 if test "${HAVE_ANDROID}" = "1"; then
3570   if test "${enable_opensles}" = "yes"; then
3571       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3572         [ VLC_ADD_PLUGIN([opensles_android]) ],
3573         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3574   fi
3575 fi
3576
3577 dnl
3578 dnl libsamplerate plugin
3579 dnl
3580 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3581
3582 dnl
3583 dnl  Interface plugins
3584 dnl
3585
3586 EXTEND_HELP_STRING([Interface plugins:])
3587
3588 dnl
3589 dnl Skins2 module
3590 dnl
3591 AC_ARG_ENABLE(skins2,
3592   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3593 AS_IF([test "${enable_skins2}" != "no"], [
3594   have_skins_deps="yes"
3595   AS_IF([test "${SYS}" = "mingw32"], [
3596     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -Imodules/gui/skins2 -DWIN32_SKINS])
3597     VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3598     VLC_ADD_LIBS([skins2],[-loleaut32 -lwinspool -lwinmm -lshell32 -ladvapi32 -lwsock32 -lgdi32 -lcomdlg32 -lole32 -luuid -lcomctl32  -lmsimg32 -luser32])
3599
3600   ], [test "${SYS}" = "darwin"], [
3601     VLC_ADD_CPPFLAGS([skins2],[-Imodules/gui/skins2 -DMACOSX_SKINS])
3602     VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3603     VLC_ADD_LIBS([skins2],[-Wl,-framework,Carbon])
3604
3605   ], [
3606     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3607     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3608     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3609     VLC_ADD_CPPFLAGS([skins2],[-Imodules/gui/skins2 ${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3610     VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3611     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3612
3613   ])
3614   AS_IF([test "${have_freetype}" != "yes"], [
3615     have_skins_deps="no"
3616   ])
3617
3618   AS_IF([test "${have_skins_deps}" = "no"], [
3619     AS_IF([test "x${enable_skins2}" = "x"], [
3620       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3621     ], [
3622       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3623     ])
3624     enable_skins2="no"
3625   ], [
3626     VLC_ADD_PLUGIN([skins2])
3627     ALIASES="${ALIASES} svlc"
3628   ])
3629 ])
3630 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3631
3632 AC_ARG_ENABLE(libtar,
3633   [  --enable-libtar         libtar support for skins2 (default auto)])
3634 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3635   AC_CHECK_HEADERS(libtar.h, [
3636     VLC_ADD_LIBS([skins2],[-ltar])
3637   ])
3638 ])
3639
3640 dnl
3641 dnl Hildon UI
3642 dnl
3643 AC_ARG_ENABLE(hildon,
3644   [  --enable-hildon         Hildon touchscreen UI (default disabled)])
3645 AS_IF([test "${enable_hildon}" = "yes"], [
3646   PKG_CHECK_MODULES(HILDON, [hildon-1], [
3647     PKG_CHECK_MODULES(HILDON_FM, hildon-fm-2, [
3648       VLC_ADD_CFLAGS([hildon],[${HILDON_FM_CFLAGS} -DHAVE_HILDON_FM])
3649       VLC_ADD_LIBS([hildon],[${HILDON_FM_LIBS}])
3650     ], [
3651       AC_MSG_WARN(hildon-fm-2 not found)
3652     ])
3653     VLC_ADD_CFLAGS([hildon],[${HILDON_CFLAGS} ${X_CFLAGS}])
3654     VLC_ADD_LIBS([hildon],[${HILDON_LIBS} ${X_LIBS} ${X_PRE_LIBS} -lX11])
3655     VLC_ADD_PLUGIN([hildon])
3656     ALIASES="${ALIASES} mvlc"
3657   ], [
3658     AS_IF([test "${enable_hildon}" = "yes"],[
3659       AC_MSG_ERROR([Hildon libraries not found])
3660     ])
3661     enable_hildon="no"
3662   ])
3663 ])
3664 AM_CONDITIONAL(BUILD_HILDON, [test "${enable_hildon}" = "yes"])
3665
3666 dnl
3667 dnl QT 4
3668 dnl
3669 AC_ARG_ENABLE(qt4,
3670   [  --enable-qt4            Qt 4 support (default enabled) ],, [
3671   AS_IF([test "${SYS}" = "darwin"], [enable_qt4=no])
3672 ])
3673 AS_IF([test "${enable_qt4}" != "no"], [
3674   PKG_CHECK_MODULES(QT4, [QtCore QtGui >= 4.6.0], [
3675     VLC_ADD_PLUGIN([qt4])
3676     VLC_ADD_LIBS([qt4],[${QT4_LIBS}])
3677     VLC_ADD_CXXFLAGS([qt4],[${QT4_CFLAGS}])
3678     ALIASES="${ALIASES} qvlc"
3679
3680     AC_LANG_PUSH([C++])
3681     CPPFLAGS_save="${CPPFLAGS}"
3682
3683     AC_MSG_CHECKING([whether Qt uses X11])
3684     CPPFLAGS="${CPPFLAGS} ${QT4_CFLAGS}"
3685     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
3686 #include <QWidget>
3687 #if !defined (Q_WS_X11)
3688 # error Fail
3689 #endif
3690     ])], [
3691       AC_MSG_RESULT([yes])
3692       VLC_ADD_LIBS([qt4],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3693       VLC_ADD_CXXFLAGS([qt4],[${X_CFLAGS}])
3694     ], [
3695       AC_MSG_RESULT([no])
3696     ])
3697
3698     CPPFLAGS="${CPPFLAGS_save}"
3699     AC_LANG_POP([C++])
3700
3701     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"], [
3702         VLC_ADD_LIBS([qt4],[-lole32])
3703     ])
3704     AS_IF([test "${SYS}" = "darwin" ],[
3705          VLC_ADD_LIBS([qt4], [-Wl,-framework,Cocoa])
3706     ])
3707     AC_PATH_PROGS(MOC, [moc-qt4 moc], moc,`eval $PKG_CONFIG --variable=exec_prefix QtCore`/bin)
3708     AC_PATH_PROG(RCC, rcc, rcc,`eval $PKG_CONFIG --variable=exec_prefix QtCore`/bin)
3709     AC_PATH_PROGS(UIC, [uic-qt4 uic], uic,`eval $PKG_CONFIG --variable=exec_prefix QtCore`/bin)
3710   ], [
3711     AS_IF([test "${enable_qt4}" = "yes"],[
3712       AC_MSG_ERROR([Qt 4 library not found])
3713     ],[
3714       AC_MSG_WARN([Qt 4 library not found])
3715     ])
3716     enable_qt4="no"
3717   ])
3718 ])
3719 AM_CONDITIONAL(ENABLE_QT4, [test "x$enable_qt4" != "xno"])
3720
3721 dnl
3722 dnl Simple test for skins2 dependency
3723 dnl
3724 AS_IF([test "${enable_skins2}" != "no" && test "x$enable_qt4" = "xno"], [
3725   AC_MSG_ERROR([The skins2 module depends on a the Qt4 development package. Without it you won't be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt4 development package or alternatively you can also configure with: --disable-qt4 --disable-skins2.])
3726 ])
3727
3728 dnl
3729 dnl  MacOS X gui module
3730 dnl
3731 AC_ARG_ENABLE(macosx,
3732   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3733 if test "x${enable_macosx}" != "xno" &&
3734 (test "${SYS}" = "darwin" || test "${enable_macosx}" = "yes")
3735 then
3736   VLC_ADD_LIBS([macosx minimal_macosx],[-Wl,-framework,Cocoa])
3737   VLC_ADD_LIBS([macosx minimal_macosx],[-Wl,-framework,OpenGL])
3738   VLC_ADD_LIBS([macosx minimal_macosx],            [-Wl,-framework,Carbon])
3739   VLC_ADD_LIBS([macosx minimal_macosx],            [-Wl,-framework,CoreServices])
3740   VLC_ADD_LIBS([macosx minimal_macosx],            [-Wl,-framework,AGL])
3741   VLC_ADD_LIBS([macosx],                           [-Wl,-framework,QTKit])
3742   VLC_ADD_LIBS([macosx],                           [-Wl,-framework,IOKit])
3743   VLC_ADD_LIBS([macosx],                           [-F${CONTRIB_DIR}/Sparkle -Wl,-framework,Sparkle])
3744   VLC_ADD_OBJCFLAGS([macosx],                         [-F${CONTRIB_DIR}/Sparkle])
3745   VLC_ADD_LIBS([macosx],                           [-F${CONTRIB_DIR}/BGHUDAppKit -Wl,-framework,BGHUDAppKit])
3746   VLC_ADD_OBJCFLAGS([macosx],                         [-F${CONTRIB_DIR}/BGHUDAppKit])
3747   dnl For bug report
3748   VLC_ADD_LIBS([macosx],                           [-Wl,-framework,AddressBook])
3749   VLC_ADD_LIBS([macosx],                           [-Wl,-framework,WebKit])
3750   VLC_ADD_OBJCFLAGS([macosx minimal_macosx], [-fobjc-exceptions] )
3751
3752   VLC_ADD_PLUGIN([macosx minimal_macosx])
3753 fi
3754
3755 dnl
3756 dnl  MacOS X dialor provider
3757 dnl
3758 AC_ARG_ENABLE(macosx-dialog-provider,
3759   [  --enable-macosx-dialog-provider Mac OS X dialog module (default enabled on Mac OS X)])
3760 if test "x${enable_macosx_dialog_provider}" != "xno" &&
3761   (test "${SYS}" = "darwin" || test "${enable_macosx_dialog_provider}" = "yes")
3762 then
3763   VLC_ADD_LIBS([macosx_dialog_provider],[-Wl,-framework,Cocoa])
3764   VLC_ADD_PLUGIN([macosx_dialog_provider])
3765 fi
3766
3767 dnl
3768 dnl  ncurses module
3769 dnl
3770 AC_ARG_ENABLE(ncurses,
3771   [  --disable-ncurses       ncurses interface support (default disabled)],
3772   [if test "${enable_ncurses}" != "no"; then
3773     AC_CHECK_HEADER(ncurses.h,
3774       [AC_CHECK_LIB(ncursesw, mvprintw,
3775         [VLC_ADD_PLUGIN([ncurses])
3776         VLC_ADD_LIBS([ncurses],[-lncursesw])
3777         ALIASES="${ALIASES} nvlc"
3778         AC_CHECK_LIB(ncursesw, tgetent, [],
3779           AC_CHECK_LIB(tinfow, tgetent, [VLC_ADD_LIBS([ncurses],[-ltinfow])],
3780             [AC_CHECK_LIB(tinfo, tgetent, [VLC_ADD_LIBS([ncurses],[-ltinfo])],
3781               [AS_IF([test "${enable_ncurses}" = "yes"],
3782                 [AC_MSG_ERROR([tgetent not found in ncursesw tinfow tinfo]
3783                )])])
3784             ]
3785           )
3786         )
3787         ],
3788           [AS_IF([test "${enable_ncurses}" = "yes"], [
3789             AC_MSG_ERROR([libncursesw not found])])]
3790         )],
3791         [AS_IF([test "${enable_ncurses}" = "yes"], [
3792           AC_MSG_ERROR([ncurses.h not found])])]
3793         )
3794   fi]
3795 )
3796
3797 dnl
3798 dnl  XOSD plugin
3799 dnl
3800 AC_ARG_ENABLE(xosd,
3801   [  --enable-xosd           xosd interface support (default disabled)])
3802 if test "${enable_xosd}" = "yes"
3803 then
3804   AC_CHECK_HEADERS(xosd.h,
3805     AC_CHECK_LIB(xosd, xosd_set_horizontal_offset, [
3806       VLC_ADD_PLUGIN([xosd])
3807       VLC_ADD_LIBS([xosd],[-lxosd])
3808     ])
3809   )
3810 fi
3811
3812 dnl
3813 dnl Framebuffer (overlay) plugin
3814 dnl
3815 AC_ARG_ENABLE(fbosd,
3816   [  --enable-fbosd          fbosd interface support (default disabled)])
3817 if test "${enable_fbosd}" = "yes"
3818 then
3819   AC_CHECK_HEADERS(linux/fb.h, [
3820     VLC_ADD_PLUGIN([fbosd])
3821  ])
3822 fi
3823
3824 dnl
3825 dnl  Lirc plugin
3826 dnl
3827 AC_ARG_ENABLE(lirc,
3828   [  --enable-lirc           lirc support (default disabled)])
3829 if test "${enable_lirc}" = "yes"
3830 then
3831   AC_CHECK_HEADER(lirc/lirc_client.h, AC_CHECK_LIB(lirc_client, lirc_init, have_lirc="true", have_lirc="false"),have_lirc="false")
3832   if test "${have_lirc}" = "true"
3833   then
3834     VLC_ADD_PLUGIN([lirc])
3835     VLC_ADD_LIBS([lirc],[-llirc_client])
3836   fi
3837 fi
3838
3839 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3840 dnl
3841 dnl Visualisation plugin
3842 dnl
3843 AC_ARG_ENABLE(visual,
3844   [  --enable-visual         visualisation plugin (default enabled)])
3845 if test "${enable_visual}" != "no"
3846 then
3847     VLC_ADD_PLUGIN([visual])
3848 fi
3849
3850 dnl
3851 dnl  goom visualization plugin
3852 dnl
3853 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3854
3855 dnl
3856 dnl libprojectM visualization plugin
3857 dnl
3858 AC_ARG_ENABLE(projectm,
3859   [  --enable-projectm       projectM visualization plugin (default enabled)])
3860 AS_IF([test "${enable_projectm}" != "no"],
3861   [
3862     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3863     [
3864       VLC_ADD_PLUGIN([projectm])
3865       VLC_ADD_CXXFLAGS([projectm],[$PROJECTM_CFLAGS])
3866       VLC_ADD_LIBS([projectm],[$PROJECTM_LIBS])
3867       PKG_CHECK_MODULES(PROJECTM2, [libprojectM >= 2.0.0],
3868         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3869         [ AC_MSG_WARN( [Using libprojectM version 1] )
3870       ])
3871     ],[
3872       AC_MSG_WARN([libprojectM library not found])
3873     ])
3874   ])
3875
3876 dnl
3877 dnl  AtmoLight (homemade Philips Ambilight clone)
3878 dnl
3879 AC_ARG_ENABLE(atmo,
3880 AS_HELP_STRING([--disable-atmo],[AtmoLight (homemade Philips Ambilight clone)
3881                 (default enabled)]),, [enable_atmo="yes"])
3882 AS_IF([test "${enable_atmo}" != no], [
3883   AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "linux"], [
3884     AC_LANG_PUSH(C++)
3885     VLC_ADD_PLUGIN([atmo])
3886     AC_LANG_POP(C++)
3887   ])
3888 ])
3889
3890 EXTEND_HELP_STRING([Service Discovery plugins:])
3891 dnl
3892 dnl  Bonjour services discovery
3893 PKG_ENABLE_MODULES_VLC([BONJOUR], [], [avahi-client >= 0.6], [Bonjour services discovery], [auto])
3894
3895 dnl
3896 dnl  libudev services discovery
3897 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3898
3899 dnl
3900 dnl MTP devices services discovery
3901 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3902
3903 dnl
3904 dnl UPnP Plugin (Intel SDK)
3905 dnl
3906 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3907 VLC_ADD_CXXFLAGS([upnp],[${UPNP_CFLAGS}])
3908
3909 EXTEND_HELP_STRING([Misc options:])
3910
3911 dnl
3912 dnl  libxml2 module
3913 dnl
3914 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3915
3916
3917 dnl
3918 dnl libgcrypt
3919 dnl
3920 AC_ARG_ENABLE(libgcrypt,
3921   [  --disable-libgcrypt     gcrypt support (default enabled)])
3922 AS_IF([test "${enable_libgcrypt}" != "no"], [
3923   AC_CHECK_DECL([GCRYCTL_SET_THREAD_CBS], [
3924     libgcrypt-config --version >/dev/null || \
3925         AC_MSG_ERROR([gcrypt.h present but libgcrypt-config could not be found])
3926     AC_CHECK_LIB(gcrypt, gcry_control, [
3927       have_libgcrypt="yes"
3928       GCRYPT_CFLAGS="`libgcrypt-config --cflags`"
3929       GCRYPT_LIBS="`libgcrypt-config --libs`"
3930     ], [
3931       AC_MSG_ERROR([libgcrypt not found. Install libgcrypt or use --disable-libgcrypt. Have a nice day.])
3932     ], [`libgcrypt-config --libs`])
3933   ], [
3934     AC_MSG_ERROR([libgcrypt version 1.1.94 or higher not found. Install libgcrypt or use --disable-libgcrypt. Have a nice day.])
3935   ], [#include <gcrypt.h>]
3936   )
3937 ])
3938
3939 if test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"; then
3940   AS_IF([test "${have_libgcrypt}" = "yes"],[
3941     VLC_ADD_LIBS([rtp stream_out_rtp], [${GCRYPT_LIBS}])
3942   ])
3943 fi
3944 AC_SUBST(GCRYPT_CFLAGS)
3945 AC_SUBST(GCRYPT_LIBS)
3946 AM_CONDITIONAL([HAVE_GCRYPT], [test "${have_libgcrypt}" = "yes"])
3947
3948 dnl
3949 dnl TLS/SSL
3950 dnl
3951 AC_ARG_ENABLE(gnutls,
3952   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
3953
3954 AS_IF([test "${have_libgcrypt}" != "yes"], [
3955   AS_IF([test "${enable_gnutls}" = "yes"], [
3956     AC_MSG_ERROR([--enable-gnutls and --disable-libgcrypt are mutually exclusive.])
3957   ])
3958   enable_gnutls="no"
3959 ])
3960 AS_IF([test "${enable_gnutls}" != "no"], [
3961   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 2.0.0], [
3962     VLC_ADD_PLUGIN([gnutls])
3963     VLC_ADD_CFLAGS([gnutls], [$GNUTLS_CFLAGS])
3964     AS_IF([test "${SYS}" = "mingw32"], [
3965       dnl pkg-config --libs gnutls omits these
3966       VLC_ADD_LIBS([gnutls], [-lz ${LTLIBINTL} -lcrypt32])
3967     ])
3968     VLC_ADD_LIBS([gnutls], [${GCRYPT_LIBS}])
3969     VLC_ADD_CFLAGS([gnutls], [${GCRYPT_CFLAGS}])
3970     VLC_ADD_LIBS([gnutls], [$GNUTLS_LIBS])
3971   ], [
3972     AS_IF([test "${enable_gnutls}" = "yes"], [
3973       AC_MSG_ERROR([GNU TLS not present or too old (version 2.0.0 required)])
3974     ])
3975   ])
3976 ])
3977
3978
3979 dnl
3980 dnl RemoteOSD plugin (VNC client as video filter)
3981 dnl
3982 AC_MSG_CHECKING([whether to enable the RemoteOSD plugin])
3983 AS_IF([test "${have_libgcrypt}" = "yes"],[
3984   AC_MSG_RESULT(yes)
3985   VLC_ADD_PLUGIN([remoteosd])
3986   VLC_ADD_LIBS([remoteosd], ${GCRYPT_LIBS})
3987   VLC_ADD_CFLAGS([remoteosd], ${GCRYPT_CFLAGS})
3988 ], [
3989   AC_MSG_RESULT(no)
3990   AC_MSG_WARN([libgcrypt support required for RemoteOSD plugin])
3991 ])
3992
3993
3994 dnl
3995 dnl RAOP plugin
3996 dnl
3997 AC_MSG_CHECKING([whether to enable the RAOP plugin])
3998 AS_IF([test "${have_libgcrypt}" = "yes"], [
3999   AC_MSG_RESULT(yes)
4000   VLC_ADD_PLUGIN([stream_out_raop])
4001   VLC_ADD_LIBS([stream_out_raop], [${GCRYPT_LIBS} -lgpg-error])
4002   VLC_ADD_CFLAGS([stream_out_raop], [${GCRYPT_CFLAGS}])
4003 ], [
4004   AC_MSG_RESULT(no)
4005   AC_MSG_WARN([libgcrypt support required for RAOP plugin])
4006 ])
4007
4008
4009 dnl
4010 dnl Nokia MCE plugin (Maemo screen unblanking)
4011 dnl
4012 PKG_CHECK_MODULES([MCE], [dbus-1 mce], [VLC_ADD_PLUGIN([mce])], [true])
4013
4014
4015 AS_IF([test -f "/etc/maemo_version"], [
4016   AC_DEFINE([HAVE_MAEMO], 1, [Define to 1 if building for the Maemo platform.])
4017 ])
4018
4019
4020 dnl
4021 dnl Taglib plugin
4022 dnl
4023 AC_ARG_ENABLE(taglib,
4024   [AS_HELP_STRING([--disable-taglib],
4025     [do not use TagLib (default enabled)])])
4026 AS_IF([test "${enable_taglib}" != "no"], [
4027   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5, [
4028     VLC_ADD_PLUGIN([taglib])
4029     VLC_ADD_LIBS([taglib],[$TAGLIB_LIBS -lz])
4030     VLC_ADD_CXXFLAGS([taglib],[$TAGLIB_CFLAGS])
4031   ], [
4032     AC_MSG_WARN(TagLib library not found)])
4033 ])
4034
4035
4036 dnl
4037 dnl update checking system
4038 dnl
4039 AC_ARG_ENABLE(update-check,
4040   [  --enable-update-check   update checking system (default disabled)])
4041 if test "${enable_update_check}" = "yes"
4042 then
4043   if test "${have_libgcrypt}" != "yes"
4044   then
4045     AC_MSG_ERROR([libgcrypt is required for update checking system])
4046   fi
4047   VLC_ADD_LIBS([libvlccore], [${GCRYPT_LIBS}])
4048   VLC_ADD_CFLAGS([libvlccore], [${GCRYPT_CFLAGS}])
4049   AC_DEFINE([UPDATE_CHECK], 1, [Define if you want to use the VLC update mechanism])
4050 fi
4051
4052 dnl
4053 dnl Growl notification plugin
4054 dnl
4055 AC_ARG_ENABLE(growl,
4056   [  --enable-growl          growl notification plugin (default disabled)],,
4057   [enable_growl=no])
4058 AS_IF([test "${enable_growl}" != "no"], [
4059     AC_CHECK_HEADERS(${CONTRIB_DIR}/Growl/Growl.framework/Versions/A/Headers/GrowlDefines.h, [
4060       VLC_ADD_PLUGIN([growl])
4061       VLC_ADD_LIBS([growl], [-F${CONTRIB_DIR}/Growl -Wl,-framework,Growl,-framework,CoreFoundation])
4062       VLC_ADD_OBJCFLAGS([growl], [-F${CONTRIB_DIR}/Growl])
4063       VLC_ADD_OBJCFLAGS([growl], [-fobjc-exceptions] )
4064     ])
4065   ]
4066 )
4067
4068 dnl
4069 dnl Libnotify notification plugin
4070 dnl
4071 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4072
4073 dnl
4074 dnl media library
4075 dnl
4076 AC_ARG_ENABLE(media-library,
4077     [  --enable-media-library  media library (default disabled)])
4078 AS_IF([test "${enable_media_library}" = "yes"], [
4079   AC_DEFINE([MEDIA_LIBRARY], 1, [Define if you want to use the VLC media library])
4080   VLC_ADD_CPPFLAGS([qt4],"-DMEDIA_LIBRARY")
4081   VLC_ADD_PLUGIN([media_library])
4082
4083 dnl
4084 dnl SQLite
4085 dnl
4086   AS_IF([test "${SYS}" != "darwin"], [
4087     PKG_ENABLE_MODULES_VLC([SQLITE], [], [sqlite3 >= 3.6.0], [sqlite3], [auto])
4088   ], [
4089     AS_IF([test "${enable_sqlite}" != "no"], [
4090       AC_CHECK_HEADERS(sqlite3.h, [
4091         VLC_ADD_PLUGIN([sqlite])
4092         VLC_ADD_LIBS([sqlite], [-lsqlite3])
4093       ], [
4094         AC_MSG_ERROR([sqlite3 is required for the media library])
4095       ])
4096     ])
4097   ])
4098 ])
4099
4100
4101 dnl
4102 dnl  Endianness check
4103 dnl
4104 AC_C_BIGENDIAN
4105 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4106   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4107 ], [
4108   DEFS_BIGENDIAN=""
4109 ])
4110 AC_SUBST(DEFS_BIGENDIAN)
4111
4112 dnl
4113 dnl Where to install KDE solid .desktop
4114 dnl
4115 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
4116 AS_IF([test "x$KDE4_CONFIG" = "x"], [
4117   KDE4_CONFIG="kde4-config"
4118 ])
4119
4120 AC_ARG_WITH(kde-solid,
4121   AS_HELP_STRING([--with-kde-solid=PATH],
4122                  [KDE Solid actions directory (auto)]),, [
4123
4124 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce" ; then
4125   with_kde_solid="yes"
4126 fi
4127 ])
4128 soliddatadir=""
4129 AS_IF([test "${with_kde_solid}" != "no"], [
4130   AS_IF([test "${with_kde_solid}" = "yes"], [
4131     kde4datadir="`${KDE4_CONFIG} --install data`"
4132     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4133     soliddatadir="${kde4datadir}/solid/actions"
4134   ], [
4135     soliddatadir="${with_kde_solid}"
4136   ])
4137 ])
4138 AC_SUBST(soliddatadir)
4139 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4140
4141 dnl
4142 dnl  DLL loader copied from MPlayer copied from somewhere else (WINE ?)
4143 dnl
4144 loader=false
4145 AC_ARG_ENABLE(loader,
4146   AS_HELP_STRING([--enable-loader],[build DLL loader for ELF i386 platforms
4147           (default disabled)]))
4148 AM_CONDITIONAL(LOADER, [test "${enable_loader}" = "yes"])
4149 AS_IF([test "${enable_loader}" = "yes"],
4150   [ VLC_ADD_PLUGIN([dmo])
4151     VLC_ADD_CPPFLAGS([dmo quicktime realvideo],[-I\\\${top_srcdir}/modules/codec/loader])
4152     VLC_ADD_LIBS([dmo quicktime realvideo],[\\\${top_builddir}/modules/codec/loader/libloader.la])
4153     VLC_ADD_CPPFLAGS([realvideo], [-DLOADER])
4154     VLC_ADD_LIBS([dmo quicktime], [-lpthread])
4155   ])
4156
4157 EXTEND_HELP_STRING([Components:])
4158
4159 dnl
4160 dnl  the VLC binary
4161 dnl
4162 AC_ARG_ENABLE(vlc,
4163   [  --enable-vlc            build the VLC media player (default enabled)])
4164 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4165
4166 AC_ARG_ENABLE(macosx-vlc-app,
4167   [  --enable-macosx-vlc-app build the VLC media player (default enabled on Mac OS X)])
4168 AM_CONDITIONAL(BUILD_MACOSX_VLC_APP, [test "${enable_macosx_vlc_app}" != "no" &&
4169     (test "${SYS}" = "darwin" || test "${enable_macosx_vlc_app}" = "yes") ])
4170
4171
4172 dnl
4173 dnl Pic and shared libvlc stuff
4174 dnl
4175 AS_IF([test "${SYS}" = "mingw32"], [
4176   FILE_LIBVLCCORE_DLL="!define LIBVLCCORE_DLL libvlccore.dll"
4177   FILE_LIBVLC_DLL="!define LIBVLC_DLL libvlc.dll"
4178 ])
4179
4180 dnl
4181 dnl  Stuff used by the program
4182 dnl
4183 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4184 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4185 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4186 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4187 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4188 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4189 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4190 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4191 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4192 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4193 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4194 AC_SUBST(COPYRIGHT_MESSAGE)
4195 AC_SUBST(VERSION_MESSAGE)
4196 AC_SUBST(VERSION_MAJOR)
4197 AC_SUBST(VERSION_MINOR)
4198 AC_SUBST(VERSION_REVISION)
4199 AC_SUBST(VERSION_EXTRA)
4200 AC_SUBST(COPYRIGHT_YEARS)
4201 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami`", [user who ran configure])
4202 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4203 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1`", [compiler])
4204 dnl
4205 dnl  Handle substvars that use $(top_srcdir)
4206 dnl
4207 CPPFLAGS_save="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS_save}"
4208
4209 dnl
4210 dnl  Restore *FLAGS
4211 dnl
4212 VLC_RESTORE_FLAGS
4213
4214 dnl
4215 dnl Sort the modules list
4216 dnl
4217 PLUGINS=$( (for i in `echo $PLUGINS`; do echo $i; done)|sort|xargs )
4218
4219 dnl
4220 dnl  Configuration is finished
4221 dnl
4222 AC_SUBST(SYS)
4223 AC_SUBST(ARCH)
4224 AC_SUBST(ALIASES)
4225 AC_SUBST(ASM)
4226 AC_SUBST(MOC)
4227 AC_SUBST(RCC)
4228 AC_SUBST(UIC)
4229 AC_SUBST(WINDRES)
4230 AC_SUBST(WINE_SDK_PATH)
4231 AC_SUBST(LIBEXT)
4232 AC_SUBST(AM_CPPFLAGS)
4233 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4234 AC_SUBST(FILE_LIBVLCCORE_DLL)
4235 AC_SUBST(FILE_LIBVLC_DLL)
4236
4237 AC_CONFIG_FILES([
4238   Makefile
4239   doc/Makefile
4240   modules/Makefile
4241   m4/Makefile
4242   po/Makefile.in
4243   share/Makefile
4244   compat/Makefile
4245   src/Makefile
4246   src/test/Makefile
4247   lib/Makefile
4248   bin/Makefile
4249   test/Makefile
4250   modules/access/Makefile
4251   modules/access/bd/Makefile
4252   modules/access/dshow/Makefile
4253   modules/access/mms/Makefile
4254   modules/access/rtp/Makefile
4255   modules/access/rtsp/Makefile
4256   modules/access/vcd/Makefile
4257   modules/access/vcdx/Makefile
4258   modules/access/screen/Makefile
4259   modules/access/zip/Makefile
4260   modules/access/zip/unzip/Makefile
4261   modules/access_output/Makefile
4262   modules/audio_filter/Makefile
4263   modules/audio_mixer/Makefile
4264   modules/audio_output/Makefile
4265   modules/codec/Makefile
4266   modules/codec/avcodec/Makefile
4267   modules/codec/dmo/Makefile
4268   modules/codec/loader/Makefile
4269   modules/codec/omxil/Makefile
4270   modules/codec/shine/Makefile
4271   modules/codec/spudec/Makefile
4272   modules/codec/wmafixed/Makefile
4273   modules/control/Makefile
4274   modules/control/dbus/Makefile
4275   modules/control/globalhotkeys/Makefile
4276   modules/demux/Makefile
4277   modules/demux/asf/Makefile
4278   modules/demux/avformat/Makefile
4279   modules/demux/avi/Makefile
4280   modules/demux/mkv/Makefile
4281   modules/demux/mp4/Makefile
4282   modules/demux/mpeg/Makefile
4283   modules/demux/playlist/Makefile
4284   modules/gui/Makefile
4285   modules/gui/macosx/Makefile
4286   modules/gui/hildon/Makefile
4287   modules/gui/minimal_macosx/Makefile
4288   modules/gui/macosx_dialog_provider/Makefile
4289   modules/gui/qt4/Makefile
4290   modules/gui/skins2/Makefile
4291   modules/lua/Makefile
4292   modules/meta_engine/Makefile
4293   modules/misc/Makefile
4294   modules/misc/playlist/Makefile
4295   modules/misc/osd/Makefile
4296   modules/misc/stats/Makefile
4297   modules/media_library/Makefile
4298   modules/mux/Makefile
4299   modules/mux/mpeg/Makefile
4300   modules/notify/Makefile
4301   modules/packetizer/Makefile
4302   modules/services_discovery/Makefile
4303   modules/stream_filter/Makefile
4304   modules/stream_out/Makefile
4305   modules/stream_out/transcode/Makefile
4306   modules/text_renderer/Makefile
4307   modules/video_chroma/Makefile
4308   modules/video_filter/Makefile
4309   modules/video_filter/dynamicoverlay/Makefile
4310   modules/video_output/Makefile
4311   modules/video_output/msw/Makefile
4312   modules/visualization/Makefile
4313   modules/visualization/visual/Makefile
4314   modules/mmx/Makefile
4315   modules/mmxext/Makefile
4316   modules/3dnow/Makefile
4317   modules/sse2/Makefile
4318   modules/altivec/Makefile
4319   modules/arm_neon/Makefile
4320 ])
4321
4322 AM_COND_IF([HAVE_WIN32], [
4323   AC_CONFIG_FILES([
4324     extras/package/win32/spad.nsi
4325     extras/package/win32/vlc.win32.nsi
4326   ])
4327 ])
4328
4329 AM_COND_IF([HAVE_DARWIN], [
4330   AC_CONFIG_FILES([
4331     extras/package/macosx/Info.plist
4332     extras/package/macosx/Resources/English.lproj/InfoPlist.strings
4333   ])
4334 ])
4335
4336 dnl Generate makefiles
4337 AC_OUTPUT
4338
4339 /bin/echo -n "Enabled modules: ${PLUGINS}"
4340
4341 dnl Do we have to use make or gmake ?
4342 USE_MAKE_OR_GMAKE=`case "${SYS}" in openbsd*) echo "gmake";; *) echo "make";; esac`
4343 dnl Shortcut to nice compile message
4344 rm -f compile
4345 if test -n $SHELL; then
4346   SHELL=${CONFIG_SHELL-/bin/sh}
4347 fi
4348 echo '#! '$SHELL >compile
4349 echo rm -f .error\$\$ >>compile
4350 echo ERROR=0 >>compile
4351 echo export PATH=$PATH LANG=C >>compile
4352 echo "($USE_MAKE_OR_GMAKE V=1 \$@ 2>&1 || touch .error\$\$)| \\" >>compile
4353 echo '`sed -ne "s/^top_srcdir *= *//p" < Makefile`/extras/buildsystem/make.pl' >>compile
4354 echo test -f .error\$\$ \&\& ERROR=1 >>compile
4355 echo rm -f .error\$\$ >>compile
4356 echo exit \$ERROR >>compile
4357 chmod a+x compile
4358
4359 printf "
4360 libvlc configuration
4361 --------------------
4362 version               : ${VERSION}
4363 system                : ${SYS}
4364 architecture          : ${ARCH}
4365 build flavour         : "
4366 test "${enable_optimizations}" != "no" && printf ${enable_optimizations}
4367 echo ""
4368 if test "${enable_vlc}" != "no"; then
4369 echo "vlc aliases           :${ALIASES}"
4370 else
4371 echo "build vlc executable  : no"
4372 fi
4373 echo "
4374 To build vlc and its plugins, type \`./compile' or \`$USE_MAKE_OR_GMAKE'."