configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 1999-2017 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 3.0.0-git)
   6 VERSION_MAJOR=3
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=git
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Vetinari"
  17 COPYRIGHT_YEARS="1996-2017"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 AM_SILENT_RULES([yes])
  31 AM_MAINTAINER_MODE([enable])
  32
  33 dnl
  34 dnl Directories
  35 dnl
  36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  37 dnl AC_SUBST(vlcincludedir)
  38 vlcdatadir="\${datadir}/\${PKGDIR}"
  39 AC_SUBST(vlcdatadir)
  40 vlclibdir="\${libdir}/\${PKGDIR}"
  41 AC_SUBST(vlclibdir)
  42
  43 dnl
  44 dnl Check for tools
  45 dnl
  46 AC_PROG_CC_C99
  47 AC_USE_SYSTEM_EXTENSIONS
  48 VLC_PROG_CC_C11
  49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  51 AH_TOP([
  52 #ifndef _REENTRANT
  53 # define _REENTRANT
  54 #endif
  55 ])
  56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  59
  60 AM_PROG_CC_C_O
  61 AC_PROG_CXX
  62 AC_PROG_CPP
  63 AC_PROG_OBJC
  64 _AM_DEPENDENCIES([OBJC])
  65 AC_PROG_EGREP
  66 AC_PROG_MAKE_SET
  67 AC_PROG_INSTALL
  68 AM_PROG_AS
  69
  70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
  73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
  74 AS_IF([test "$BUILDCC" = "false"], [
  75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
  76 ])
  77
  78 dnl Check for compiler properties
  79 AC_C_CONST
  80 AC_C_INLINE
  81 AC_C_RESTRICT
  82 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
  83
  84 dnl Extend the --help string at the current spot.
  85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  86
  87 dnl Allow binary package maintainer to pass a custom string to avoid
  88 dnl cache problem
  89 AC_ARG_WITH(binary-version,
  90     AS_HELP_STRING([--with-binary-version=STRING],
  91          [To avoid plugins cache problem between binary version]),[],[])
  92 AS_IF([test -n "${with_binary_version}"],[
  93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  94          [Binary specific version])
  95 ])
  96
  97 dnl
  98 dnl  Check the operating system
  99 dnl
 100 HAVE_WIN64="0"
 101 HAVE_IOS="0"
 102 HAVE_OSX="0"
 103 HAVE_TVOS="0"
 104
 105 case "${host_os}" in
 106   "")
 107     SYS=unknown
 108     ;;
 109   linux*)
 110     SYS=linux
 111     ;;
 112   bsdi*)
 113     SYS=bsdi
 114     CFLAGS="${CFLAGS} -pthread"
 115     ;;
 116   freebsd*)
 117     SYS=freebsd
 118     CFLAGS="${CFLAGS} -pthread"
 119     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 120     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 121     ac_cv_ld_z_defs=no
 122     ;;
 123   openbsd*)
 124     SYS=openbsd
 125     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 126     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 127     ;;
 128   netbsd*)
 129     SYS=netbsd
 130     ;;
 131   dragonfly*)
 132     SYS=dragonfly
 133     ;;
 134   darwin*)
 135
 136     dnl Force gcc "-arch" flag
 137     ARCH_flag=""
 138     case "${host}" in
 139       i?86*)
 140         ARCH_flag="-arch i386"
 141       ;;
 142       ppc64*)
 143         ARCH_flag="-arch ppc64"
 144       ;;
 145       ppc*)
 146         ARCH_flag="-arch ppc"
 147       ;;
 148       x86_64*)
 149         ARCH_flag="-arch x86_64"
 150       ;;
 151       arm*)
 152         ac_cv_c_bigendian="no"
 153         ac_cv_c_attribute_packed="no"
 154       ;;
 155     esac
 156
 157     SYS=darwin
 158     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 159     CXX="${CXX} -stdlib=libc++ -std=c++11"
 160     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 161     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 162     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
 163     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 164     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 165     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 166
 167     AC_EGREP_CPP(yes,
 168             [#import <TargetConditionals.h>
 169              #if TARGET_OS_IPHONE
 170              yes
 171              #endif],
 172              [HAVE_IOS="1"],
 173              [HAVE_OSX="1"])
 174
 175     AC_EGREP_CPP(yes,
 176             [#import <TargetConditionals.h>
 177              #if TARGET_OS_TV
 178              yes
 179              #endif],
 180              [HAVE_TVOS="1"
 181              HAVE_IOS="0"
 182              HAVE_OSX="0"
 183              ],)
 184
 185     dnl Allow binaries created on Lion to run on earlier releases
 186     AC_EGREP_CPP(yes,
 187            [#import <Cocoa/Cocoa.h>
 188             #ifdef MAC_OS_X_VERSION_10_7
 189             yes
 190             #endif],
 191             [AC_MSG_RESULT([yes])
 192             AC_LIBOBJ([getdelim])
 193             AC_LIBOBJ([strndup])
 194             AC_LIBOBJ([strnlen])],)
 195
 196     dnl
 197     dnl  Handle Mac OS X SDK flags
 198     dnl
 199     AC_ARG_WITH(macosx-sdk,
 200       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 201         [compile using the SDK in DIR])])
 202     if test "${with_macosx_sdk}" != "" ; then
 203         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 204         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 205         CC="${CC} -isysroot ${with_macosx_sdk}"
 206         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 207         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 208         LD="${LD} -syslibroot ${with_macosx_sdk}"
 209     fi
 210     AC_ARG_WITH(macosx-version-min,
 211       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 212         [compile for Mac OS X VERSION and above])])
 213     if test "${with_macosx_version_min}" != "" ; then
 214         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 215         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 216         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 217         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 218         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 219     fi
 220     ;;
 221   *mingw32* | *cygwin* | *wince* | *mingwce*)
 222     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
 223     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
 224     CXXFLAGS="${CXXFLAGS} -static-libgcc"
 225     AC_CHECK_TOOL(WINDRES, windres, :)
 226     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 227     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
 228     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
 229     AH_TOP([#endif])
 230     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 231     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 232     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 233     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 234     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 235     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 236     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 237     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 238     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 239     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 240     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 241
 242     case "${host_os}" in
 243       *mingw32*)
 244         SYS=mingw32
 245         ;;
 246       *cygwin*)
 247         dnl Check if we are using the mno-cygwin mode in which case we are
 248         dnl actually dealing with a mingw32 compiler.
 249         AC_EGREP_CPP(yes,
 250             [#ifdef _WIN32
 251              yes
 252              #endif],
 253             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 254         ;;
 255     esac
 256
 257     if test "${SYS}" = "mingw32"; then
 258         # DEP, ASLR, NO SEH
 259         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 260
 261         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 262         ac_default_prefix="`pwd`/_win32"
 263         DESTDIR="`pwd`/_win32/"
 264
 265         dnl
 266         dnl NSIS/MSI Installer prefix and WIN64
 267         dnl
 268         case "${host}" in
 269             amd64*|x86_64*)
 270                 HAVE_WIN64="1"
 271                 WINDOWS_ARCH="x64"
 272                 PROGRAMFILES="PROGRAMFILES64"
 273                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
 274             ;;
 275             *)
 276                 WINDOWS_ARCH="x86"
 277                 PROGRAMFILES="PROGRAMFILES"
 278             ;;
 279         esac
 280         AC_SUBST(WINDOWS_ARCH)
 281         AC_SUBST(PROGRAMFILES)
 282
 283     fi
 284     ;;
 285   *nto*)
 286     SYS=nto
 287     ;;
 288   solaris*)
 289     SYS=solaris
 290     ;;
 291   hpux*)
 292     SYS=hpux
 293     ;;
 294   *os2*)
 295     SYS=os2
 296     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 297     AC_LIBOBJ([freeaddrinfo])
 298     AC_LIBOBJ([gai_strerror])
 299     ;;
 300   *nacl*)
 301     SYS=nacl
 302     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 303     AC_LIBOBJ([sigwait])
 304     AC_LIBOBJ([recvmsg])
 305     AC_LIBOBJ([sendmsg])
 306     ;;
 307   *)
 308     SYS="${host_os}"
 309     ;;
 310 esac
 311
 312 dnl WinRT
 313 AC_ARG_ENABLE(winstore_app,
 314      AS_HELP_STRING([--enable-winstore-app],
 315                     [Build targetted for Windows Store apps (default disabled)]))
 316
 317 vlc_winstore_app=0
 318 AS_IF([test "${SYS}" = "mingw32"],[
 319   LIBCOM="-lole32"
 320   AS_IF([test "${enable_winstore_app}" = "yes"], [
 321     vlc_winstore_app=1
 322     LIBCOM=""
 323      VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
 324      AC_LIBOBJ([gai_strerror])
 325     ],[])
 326   AC_SUBST(LIBCOM)
 327   ])
 328 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 329
 330 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 331 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 332
 333 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 334 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
 335 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
 336 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
 337
 338 AM_CONDITIONAL(HAVE_NACL,    test "${SYS}" = "nacl")
 339
 340 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 341 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
 342 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 343 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
 344
 345 dnl
 346 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 347 dnl for program foo on win32
 348 case "${build_os}" in
 349     cygwin|msys|mingw32)
 350         ac_executable_extensions=".exe"
 351         BUILDEXEEXT=".exe"
 352     ;;
 353     os2*)
 354         BUILDEXEEXT=".exe"
 355     ;;
 356     *)
 357     ;;
 358 esac
 359 AC_SUBST(BUILDEXEEXT)
 360
 361 dnl Android is linux, but a bit different
 362 AS_IF([test "$SYS" = linux],[
 363     AC_MSG_CHECKING([for an Android system])
 364     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 365         [[#ifndef __ANDROID__
 366          # error Not Android
 367          #endif
 368         ]],[[;]])
 369     ],[
 370       HAVE_ANDROID="1"
 371       AC_MSG_RESULT([yes])
 372     ],[
 373       AC_MSG_RESULT([no])
 374     ])
 375 ])
 376 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 377
 378 dnl Tizen (minimum SDK version: 2.3)
 379 AS_IF([test "$SYS" = linux],[
 380     AC_MSG_CHECKING([for Tizen])
 381     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 382         [[#include <tizen.h>
 383         ]],[[;]])
 384     ],[
 385       HAVE_TIZEN="1"
 386       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
 387       AC_MSG_RESULT([yes])
 388     ],[
 389       AC_MSG_RESULT([no])
 390     ])
 391 ])
 392 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
 393
 394 dnl
 395 dnl  Check for the contrib directory
 396 dnl
 397 AC_ARG_WITH(contrib,
 398   [AS_HELP_STRING([--with-contrib[=DIR]],
 399     [search for 3rd party libraries in DIR/include and DIR/lib])
 400 ])
 401 AC_MSG_CHECKING([for 3rd party libraries path])
 402 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 403   CONTRIB_DIR="${srcdir}/contrib/${host}"
 404   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 405     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 406     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 407     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 408       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 409       CONTRIB_DIR=""
 410       AC_MSG_RESULT([not found])
 411     ])
 412   ])
 413 ], [
 414   AS_IF([test "${with_contrib}" != "no"], [
 415     CONTRIB_DIR="${with_contrib}"
 416   ], [
 417     CONTRIB_DIR=""
 418     AC_MSG_RESULT([disabled])
 419   ])
 420 ])
 421 AS_IF([test -n "${CONTRIB_DIR}"], [
 422   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 423     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 424   ], [
 425     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 426     CONTRIB_DIR=""
 427     AC_MSG_RESULT([not usable])
 428   ])
 429
 430 ])
 431 AS_IF([test -n "${CONTRIB_DIR}"], [
 432   AC_MSG_RESULT([${CONTRIB_DIR}])
 433   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 434   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 435   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 436   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
 437   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 438   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 439
 440   AS_IF([test -z "$LUAC"], [
 441     dnl Old contribs mixed cross-tools and cross-compiled executables
 442     AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
 443       LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
 444     ])
 445
 446     dnl Newer contribs follow usual name space rules
 447     AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
 448       LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
 449     ])
 450   ])
 451
 452   AS_IF([test "${SYS}" = "darwin"], [
 453     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 454     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 455   ])
 456 ], [
 457   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 458     AC_MSG_ERROR([Third party libraries not found!])
 459   ])
 460 ])
 461 AC_SUBST(CONTRIB_DIR)
 462
 463 dnl Add extras/tools to the PATH
 464 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 465 AS_IF([test -d "${TOOLS_DIR}"], [
 466     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 467     export PATH="${TOOLS_DIR}":$PATH
 468 ])
 469
 470 dnl
 471 dnl  Libtool
 472 dnl  It's very bad, but our former custom system was worst
 473 dnl  -- Courmisch
 474 dnl
 475
 476 dnl override platform specific check for dependent libraries
 477 dnl otherwise libtool linking of shared libraries will
 478 dnl fail on anything other than pass_all.
 479 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 480     [lt_cv_deplibs_check_method=pass_all])
 481
 482 LT_INIT([dlopen win32-dll shared disable-static])
 483 LT_LANG([C++])
 484 LT_LANG([Windows Resource])
 485
 486 DOLT
 487
 488 lt_cv_deplibs_check_method=pass_all
 489
 490 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 491   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 492 ])
 493
 494 dnl
 495 dnl Gettext stuff
 496 dnl
 497 AM_GNU_GETTEXT_VERSION([0.19.8])
 498 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 499
 500 dnl
 501 dnl Iconv stuff
 502 dnl
 503 AM_ICONV
 504
 505 dnl
 506 dnl checks for mingw
 507 AS_IF([test "${SYS}" = "mingw32"], [
 508
 509 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 510 #if !defined(__MINGW32__)
 511 # error Not compiling with mingw
 512 #endif
 513     ])], [
 514
 515 dnl Check for broken versions of mingw-runtime compatability library
 516     AC_MSG_CHECKING(for broken mingw-runtime)
 517     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 518 #include <_mingw.h>
 519 #if defined(__MINGW64_VERSION_MAJOR)
 520 # if __MINGW64_VERSION_MAJOR < 3
 521 #  error Attempting to use mingw-runtime with broken vsnprintf support
 522 # endif
 523 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
 524 # error Attempting to use mingw-runtime with broken vsnprintf support
 525 #endif
 526     ])], [
 527         AC_MSG_RESULT([ok])
 528     ], [
 529         AC_MSG_RESULT([present])
 530         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
 531     ])
 532
 533     dnl force use of mingw provided c99 *printf over msvcrt
 534     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 535
 536     dnl Add WinMainCRTStartup entry point to show it's a WinMain application
 537     VLC_ADD_LDFLAGS([vlc],[-mwindows])
 538
 539     dnl Check for the need to include the mingwex lib for mingw32
 540     VLC_SAVE_FLAGS
 541     AC_CHECK_LIB(mingwex,opendir,
 542         AC_CHECK_LIB(mingw32,opendir,,
 543             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 544     )
 545     VLC_RESTORE_FLAGS
 546     ], [
 547         AC_MSG_RESULT([Not compiling with mingw])
 548     ])
 549
 550     dnl Check for fnative-struct or mms-bitfields support for mingw32
 551     VLC_SAVE_FLAGS
 552     CFLAGS="${CFLAGS} -mms-bitfields"
 553     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
 554     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 555         [ac_cv_c_mms_bitfields],
 556         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 557     if test "${ac_cv_c_mms_bitfields}" = "no"; then
 558         VLC_RESTORE_FLAGS
 559         CFLAGS="${CFLAGS} -fnative-struct"
 560         CXXFLAGS="${CXXFLAGS} -fnative-struct"
 561         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 562             [ac_cv_c_fnative_struct],
 563             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 564         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
 565     fi
 566 ])
 567
 568
 569 dnl
 570 dnl Buggy glibc prevention. Purposedly not cached.
 571 dnl See sourceware.org bugs 5058 and 5443.
 572 dnl Ubuntu alone has 20 bug numbers for this...
 573 dnl
 574 AC_MSG_CHECKING(for buggy GNU/libc versions)
 575 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 576 #include <limits.h>
 577 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 578   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 579 # error GNU/libc with dcgettext killer bug!
 580 #endif
 581 ])], [
 582   AC_MSG_RESULT([not present])
 583 ], [
 584   AC_MSG_RESULT([found])
 585   AS_IF([test "x${enable_nls}" != "xno"], [
 586     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 587 work-around for this. Check with your distribution vendor on how to update the
 588 glibc run-time. Alternatively, build with --disable-nls.])
 589   ])
 590 ])
 591
 592 dnl Plugin compilation stuff
 593
 594 VLC_LIBRARY_SUFFIX
 595
 596 dnl Check for system libs needed
 597 need_libc=false
 598
 599 dnl Check for usual libc functions
 600 AC_CHECK_FUNCS([daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp strptime tdestroy uselocale])
 601 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv memrchr nrand48 poll recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tfind timegm timespec_get strverscmp pathconf])
 602 AC_REPLACE_FUNCS([gettimeofday])
 603 AC_CHECK_FUNC(fdatasync,,
 604   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 605 ])
 606
 607 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
 608
 609 dnl mingw64 implements those as static inline, not functions with C linkage
 610 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
 611 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
 612 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
 613 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
 614
 615 dnl C11 static_assert()
 616 AC_MSG_CHECKING([for static_assert in assert.h])
 617 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 618 static_assert(1, "The impossible happened.");
 619 ])], [
 620   AC_MSG_RESULT([yes])
 621   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 622 ], [
 623   AC_MSG_RESULT([no])
 624 ])
 625
 626 # Windows CE does not have strcoll()
 627 AC_FUNC_STRCOLL
 628
 629 dnl Check for non-standard system calls
 630 case "$SYS" in
 631   "linux")
 632     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity recvmmsg])
 633     ;;
 634   "mingw32")
 635     AC_CHECK_FUNCS([_lock_file])
 636     ;;
 637 esac
 638
 639 AH_BOTTOM([#include <vlc_fixups.h>])
 640
 641 dnl Check for struct pollfd
 642 AC_CHECK_TYPES([struct pollfd],,,
 643 [#include <sys/types.h>
 644 #if HAVE_POLL
 645 # include <poll.h>
 646 #elif defined (_WIN32)
 647 # include <winsock2.h>
 648 #endif
 649 ])
 650
 651 dnl Check for struct timespec
 652 AC_CHECK_TYPES([struct timespec],,,
 653 [#include <time.h>])
 654
 655 dnl Check for max_align_t
 656 AC_CHECK_TYPES([max_align_t],,,
 657 [#include <stddef.h>])
 658
 659 dnl Checks for socket stuff
 660 VLC_SAVE_FLAGS
 661 SOCKET_LIBS=""
 662 AC_SEARCH_LIBS(connect, [socket], [
 663   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 664     SOCKET_LIBS="$ac_cv_search_connect"
 665   ])
 666 ], [
 667   AS_IF([test "${SYS}" = "mingw32"], [
 668     SOCKET_LIBS="-lws2_32"
 669   ])
 670 ])
 671
 672 AC_SEARCH_LIBS([inet_pton], [nsl], [
 673  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
 674     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
 675   ])
 676 ],, [${SOCKET_LIBS}])
 677
 678 LIBS="${LIBS} ${SOCKET_LIBS}"
 679 AC_LINK_IFELSE([
 680     AC_LANG_PROGRAM([#ifdef _WIN32
 681         # if _WIN32_WINNT < 0x600
 682         #  error Needs vista+
 683         # endif
 684         #include <ws2tcpip.h>
 685         #else
 686         #include <sys/socket.h>
 687         #include <arpa/inet.h>
 688         #endif], [
 689         char dst[[sizeof(struct in_addr)]];
 690         inet_pton(AF_INET, "127.0.0.1", dst);
 691     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 692 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
 693 VLC_RESTORE_FLAGS
 694 AC_SUBST(SOCKET_LIBS)
 695
 696 dnl Check for socklen_t
 697 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 698 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 699 ac_cv_type_socklen_t,
 700 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 701 [#include <sys/types.h>
 702 #ifdef _WIN32
 703 # include <winsock2.h>
 704 # include <ws2tcpip.h>
 705 #else
 706 # include <sys/socket.h>
 707 #endif]], [[socklen_t len; len = 0;]])],
 708 ac_cv_type_socklen_t=yes,
 709 ac_cv_type_socklen_t=no)])
 710 AS_IF([test "$ac_cv_type_socklen_t" = no],
 711  [AC_DEFINE(socklen_t, int)])
 712
 713 dnl Check for struct sockaddr_storage
 714 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 715 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 716 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 717   [AC_TRY_COMPILE(
 718     [#include <sys/types.h>
 719      #if defined( _WIN32 )
 720      # include <winsock2.h>
 721      #else
 722      # include <sys/socket.h>
 723      #endif], [struct sockaddr_storage addr;],
 724      ac_cv_struct_sockaddr_storage=yes,
 725      ac_cv_struct_sockaddr_storage=no)])
 726 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 727   AC_DEFINE(sockaddr_storage, sockaddr)
 728   AC_DEFINE(ss_family, sa_family)
 729 ])
 730
 731 dnl FreeBSD has a gnugetopt library for this:
 732 GNUGETOPT_LIBS=""
 733 AC_CHECK_FUNC(getopt_long,, [
 734   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 735     GNUGETOPT_LIBS="-lgnugetopt"
 736   ])
 737 ])
 738 AC_SUBST(GNUGETOPT_LIBS)
 739
 740 AC_CHECK_LIB(m,cos,[
 741   LIBM="-lm"
 742 ], [
 743   LIBM=""
 744 ])
 745 AC_SUBST(LIBM)
 746
 747 AC_CHECK_LIB(m,lrintf, [
 748   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 749   VLC_ADD_LIBS([skins2],[-lm])
 750 ])
 751 AC_CHECK_LIB(m,nanf,
 752   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 753 )
 754 AC_CHECK_LIB(m,sincos, [
 755   AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
 756 ], [
 757   AC_LIBOBJ([sincos])
 758 ])
 759
 760 AC_MSG_CHECKING([_Thread_local support])
 761 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
 762                    int main() {}])], [
 763     AC_MSG_RESULT([ok])
 764     AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
 765 ],[ AC_MSG_RESULT([no])])
 766
 767 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
 768 dnl check for its availability explicitely
 769 AC_CHECK_HEADERS([threads.h])
 770
 771 dnl Check for dynamic plugins
 772 LIBDL=""
 773 have_dynamic_objects="no"
 774 VLC_SAVE_FLAGS
 775 AC_SEARCH_LIBS(dlsym, [dl svld], [
 776   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 777     LIBDL="$ac_cv_search_dlsym"
 778   ])
 779   have_dynamic_objects="yes"
 780 ])
 781 VLC_RESTORE_FLAGS
 782
 783 # Windows
 784 AS_IF([test "${SYS}" = "mingw32"], [
 785   LIBDL=""
 786   have_dynamic_objects="yes" #assume we can use shared objects
 787 ])
 788
 789 AS_IF([test "${enable_shared}" = "no"], [
 790   have_dynamic_objects=no
 791 ])
 792 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 793
 794 AC_SUBST(LIBDL)
 795
 796 dnl Check for thread library
 797 LIBPTHREAD=""
 798 AS_IF([test "${SYS}" != "mingw32"], [
 799   VLC_SAVE_FLAGS
 800   LIBS=""
 801   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 802     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 803       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 804     ])
 805   ])
 806   VLC_RESTORE_FLAGS
 807 ])
 808 AC_SUBST(LIBPTHREAD)
 809
 810 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
 811   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
 812     LIBRT="$ac_cv_search_clock_nanosleep"
 813   ])
 814 ], [
 815   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
 816     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
 817       LIBRT="$ac_cv_search_nanosleep"
 818     ])
 819   ])
 820 ])
 821 AC_SUBST(LIBRT)
 822
 823 dnl
 824 dnl Check for headers
 825 dnl
 826
 827 dnl  POSIX
 828 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
 829 AC_CHECK_HEADERS([net/if.h], [], [],
 830 [
 831 #include <sys/types.h>
 832 #include <sys/socket.h>
 833 ])
 834 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
 835 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
 836
 837 dnl  BSD
 838 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
 839
 840 dnl  GNU/Linux
 841 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 842
 843 dnl  MacOS
 844 AC_CHECK_HEADERS([xlocale.h])
 845
 846 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 847 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 848 AC_CHECK_TYPE(ssize_t,, [
 849   AC_DEFINE(ssize_t, int)
 850 ])
 851
 852 dnl It seems that autoconf detects pkg-config only during the first
 853 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 854 dnl it is nested within a conditional block, so it was not working right.
 855 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 856 AC_ARG_VAR(PKG_CONFIG_PATH,
 857        [Paths where to find .pc not at the default location])
 858 PKG_PROG_PKG_CONFIG()
 859
 860 dnl On some OS we need static linking
 861 AS_IF([test -n "${PKG_CONFIG}" ],[
 862     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 863         PKG_CONFIG="${PKG_CONFIG} --static"
 864     ])
 865 ])
 866
 867
 868 dnl
 869 dnl Check for zlib.h and -lz along with system -lminizip if available
 870 dnl
 871 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 872 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 873 if test "${have_zlib}" = "yes"
 874 then
 875   VLC_ADD_LIBS([sap],[-lz])
 876   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 877     AC_CHECK_HEADERS([unzip.h], [
 878       have_minizip=yes
 879       MINIZIP_LIBS="-lminizip -lz"
 880     ], [
 881       have_minizip=no
 882     ])
 883   ])
 884 fi
 885 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 886
 887
 888 dnl
 889 dnl Domain name i18n support via GNU libidn
 890 dnl
 891 PKG_CHECK_MODULES([IDN], [libidn], [
 892   have_libidn="yes"
 893   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 894 ], [
 895   have_libidn="no"
 896 ])
 897
 898
 899 dnl Check for dbus
 900 AC_ARG_ENABLE(dbus,
 901   [AS_HELP_STRING([--enable-dbus],
 902     [compile D-Bus message bus support (default enabled)])])
 903 have_dbus="no"
 904 AS_IF([test "${enable_dbus}" != "no"], [
 905   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 906     have_dbus="yes"
 907   ], [
 908     AS_IF([test -n "${enable_dbus}"], [
 909       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 910     ], [
 911       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 912     ])
 913   ])
 914 ])
 915 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 916
 917
 918 dnl Check for systemd
 919 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
 920   have_systemd="yes"
 921 ], [
 922   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
 923 ])
 924 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
 925
 926
 927 dnl Check for ntohl, etc.
 928 VLC_SAVE_FLAGS
 929 CFLAGS="${CFLAGS} -Wall -Werror"
 930 AC_CACHE_CHECK([for ntohl in sys/param.h],
 931     [ac_cv_c_ntohl_sys_param_h],
 932     [     AC_TRY_COMPILE([#include <sys/param.h>],
 933         [int meuh; ntohl(meuh);],
 934         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
 935 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
 936     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
 937 fi
 938 VLC_RESTORE_FLAGS
 939
 940 EXTEND_HELP_STRING([Optimization options:])
 941 dnl
 942 dnl  Compiler warnings
 943 dnl
 944
 945 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration init-self logical-op format-security shadow=local])
 946 RDC_PROG_CC_FLAGS([-pipe])
 947 AC_LANG_PUSH([C++])
 948 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var format-security])
 949 AC_LANG_POP([C++])
 950
 951 dnl
 952 dnl  Debugging mode
 953 dnl
 954 AC_ARG_ENABLE(debug,
 955   [AS_HELP_STRING([--enable-debug],
 956     [build with run-time assertions (default disabled)])],,
 957   [enable_debug="no"])
 958 AH_TEMPLATE(NDEBUG,
 959             [Define to 1 if debug code should NOT be compiled])
 960 AS_IF([test "${enable_debug}" != "no"], [
 961   AC_CHECK_HEADERS([valgrind/valgrind.h])
 962 ], [
 963   AC_DEFINE(NDEBUG)
 964 ])
 965
 966 dnl
 967 dnl  Profiling
 968 dnl
 969 AC_ARG_ENABLE(gprof,
 970   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 971   [enable_gprof="no"])
 972 AS_IF([test "${enable_gprof}" != "no"], [
 973   CFLAGS="${CFLAGS} -pg"
 974   CXXFLAGS="${CXXFLAGS} -pg"
 975   OBJCFLAGS="${OBJCFLAGS} -pg"
 976   LDFLAGS="${LDFLAGS} -pg"
 977 ])
 978
 979 AC_ARG_ENABLE(cprof,
 980   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 981   [enable_cprof="no"])
 982 AS_IF([test "${enable_gprof}" != "no"], [
 983   CFLAGS="${CFLAGS} -finstrument-functions"
 984   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 985   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 986   LDFLAGS="${LDFLAGS} -finstrument-functions"
 987 ])
 988
 989 dnl
 990 dnl  Test coverage
 991 dnl
 992 AC_ARG_ENABLE(coverage,
 993   [AS_HELP_STRING([--enable-coverage],
 994     [build for test coverage (default disabled)])],,
 995   [enable_coverage="no"])
 996 AS_IF([test "${enable_coverage}" != "no"], [
 997   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 998   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 999   LDFLAGS="-lgcov ${LDFLAGS}"
1000 ])
1001
1002 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
1003   VLC_SAVE_FLAGS
1004   CFLAGS="${CFLAGS} -fvisibility=hidden"
1005   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
1006   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
1007   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
1008                  [ac_cv_c_visibility_hidden], [
1009     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1010       ac_cv_c_visibility_hidden=yes
1011     ], [
1012       ac_cv_c_visibility_hidden=no
1013     ])
1014   ])
1015   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1016 ])
1017
1018
1019 dnl
1020 dnl  Enable/disable optimizations
1021 dnl
1022 AC_ARG_ENABLE(optimizations,
1023   [AS_HELP_STRING([--disable-optimizations],
1024     [disable compiler optimizations (default enabled)])],,
1025   [enable_optimizations="yes"])
1026
1027 dnl Check for various optimization flags
1028 AS_IF([test "${enable_optimizations}" != "no"], [
1029
1030   dnl -O3 only in production builds
1031   AS_IF([test "${enable_debug}" = "no"], [
1032     VLC_SAVE_FLAGS
1033     CFLAGS="${CFLAGS} -O3"
1034     CXXFLAGS="${CXXFLAGS} -O3"
1035     OBJCFLAGS="${OBJCFLAGS} -O3"
1036     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1037       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1038         ac_cv_c_o3=yes
1039       ], [
1040         ac_cv_c_o3=no
1041       ])
1042     ])
1043     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1044   ])
1045
1046   dnl Check for fast maths
1047   RDC_PROG_CC_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1048   AC_LANG_PUSH(C++)
1049   RDC_PROG_CXX_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1050   AC_LANG_POP
1051
1052 AH_BOTTOM([
1053 #if defined(_MSC_VER) && !defined(__clang__)
1054 # pragma fenv_access(off)
1055 # pragma fp_contract(on)
1056 #elif defined(__GNUC__)
1057 /* Not supported so far */
1058 #else
1059 # pragma STDC FENV_ACCESS OFF
1060 # pragma STDC FP_CONTRACT ON
1061 #endif
1062 ])
1063
1064   dnl Check for -funroll-loops
1065   VLC_SAVE_FLAGS
1066   CFLAGS="${CFLAGS} -funroll-loops"
1067   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1068   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1069   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1070     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1071       ac_cv_c_unroll_loops=yes
1072     ], [
1073       ac_cv_c_unroll_loops=no
1074     ])
1075   ])
1076   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1077
1078   AS_IF([test "$enable_debug" = "no"], [
1079     dnl Check for -fomit-frame-pointer
1080     VLC_SAVE_FLAGS
1081     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1082     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1083     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1084     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1085       [ac_cv_c_omit_frame_pointer], [
1086       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1087         ac_cv_c_omit_frame_pointer=yes
1088       ], [
1089         ac_cv_c_omit_frame_pointer=no
1090       ])
1091     ])
1092     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1093   ])
1094 ])
1095
1096 VLC_SAVE_FLAGS
1097 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1098 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1099   AC_TRY_LINK([],, [
1100     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1101   ], [
1102     ac_cv_ld_bsymbolic=""
1103   ])
1104 ])
1105 VLC_RESTORE_FLAGS
1106 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1107 AC_SUBST(SYMBOLIC_LDFLAGS)
1108
1109 VLC_SAVE_FLAGS
1110 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1111 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1112   AC_TRY_LINK([],, [
1113     ac_cv_ld_z_defs="yes"
1114   ], [
1115     ac_cv_ld_z_defs="no"
1116   ])
1117 ])
1118 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1119
1120 dnl Check for __attribute__((packed))
1121 AC_CACHE_CHECK([for __attribute__((packed))],
1122   [ac_cv_c_attribute_packed],
1123   [ac_cv_c_attribute_packed=no
1124    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1125                     [ac_cv_c_attribute_packed=yes])])
1126 if test "${ac_cv_c_attribute_packed}" != "no"; then
1127   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1128 fi
1129
1130 dnl
1131 dnl  Check the CPU
1132 dnl
1133 case "${host_cpu}" in
1134   "")
1135     ARCH=unknown
1136     ;;
1137   *)
1138     ARCH="${host_cpu}"
1139     ;;
1140 esac
1141
1142 dnl Check for backtrace() support
1143 AC_CHECK_HEADERS(execinfo.h)
1144 AC_CHECK_FUNCS(backtrace)
1145
1146 dnl
1147 dnl  default modules
1148 dnl
1149 ALIASES="${ALIASES} cvlc rvlc"
1150
1151 dnl
1152 dnl  Accelerated modules
1153 dnl
1154
1155 dnl  Check for fully working MMX intrinsics
1156 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1157 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1158 AC_ARG_ENABLE(mmx,
1159   [AS_HELP_STRING([--disable-mmx],
1160     [disable MMX optimizations (default auto)])],,[
1161   case "${host_cpu}" in
1162     i?86|x86_64)
1163       enable_mmx="yes"
1164       ;;
1165     *)
1166       enable_mmx="no"
1167       ;;
1168   esac
1169 ])
1170 have_mmx="no"
1171 have_mmxext="no"
1172 AS_IF([test "${enable_mmx}" != "no"], [
1173   ARCH="${ARCH} mmx"
1174   VLC_SAVE_FLAGS
1175   CFLAGS="${CFLAGS} -mmmx"
1176   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1177     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1178 [#include <mmintrin.h>
1179 #include <stdint.h>
1180 uint64_t frobzor;]], [
1181 [__m64 a, b, c;
1182 a = b = c = (__m64)frobzor;
1183 a = _mm_slli_pi16(a, 3);
1184 a = _mm_adds_pi16(a, b);
1185 c = _mm_srli_pi16(c, 8);
1186 c = _mm_slli_pi16(c, 3);
1187 b = _mm_adds_pi16(b, c);
1188 a = _mm_unpacklo_pi8(a, b);
1189 frobzor = (uint64_t)a;]])], [
1190       ac_cv_c_mmx_intrinsics=yes
1191     ], [
1192       ac_cv_c_mmx_intrinsics=no
1193     ])
1194   ])
1195   VLC_RESTORE_FLAGS
1196   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1197     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1198   ])
1199
1200   VLC_SAVE_FLAGS
1201   CFLAGS="${CFLAGS} -mmmx"
1202   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1203     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1204 void *p;
1205 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1206 ]])
1207     ], [
1208       ac_cv_mmx_inline=yes
1209     ], [
1210       ac_cv_mmx_inline=no
1211     ])
1212   ])
1213   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1214     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1215     have_mmx="yes"
1216   ])
1217
1218   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1219                  [ac_cv_mmxext_inline], [
1220     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1221 void *p;
1222 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1223 ]])
1224     ], [
1225       ac_cv_mmxext_inline=yes
1226     ], [
1227       ac_cv_mmxext_inline=no
1228     ])
1229   ])
1230   VLC_RESTORE_FLAGS
1231   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1232     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1233     have_mmxext="yes"
1234   ])
1235 ])
1236 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1237 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1238
1239 dnl  Check for fully workin SSE2 intrinsics
1240 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1241 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1242 AC_ARG_ENABLE(sse,
1243   [AS_HELP_STRING([--disable-sse],
1244     [disable SSE (1-4) optimizations (default auto)])],, [
1245   case "${host_cpu}" in
1246     i?86|x86_64)
1247       enable_sse=yes
1248       ;;
1249     *)
1250       enable_sse=no
1251       ;;
1252   esac
1253 ])
1254 have_sse2="no"
1255 AS_IF([test "${enable_sse}" != "no"], [
1256   ARCH="${ARCH} sse sse2"
1257
1258   VLC_SAVE_FLAGS
1259   CFLAGS="${CFLAGS} -msse2"
1260   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1261     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1262 [#include <emmintrin.h>
1263 #include <stdint.h>
1264 uint64_t frobzor;]], [
1265 [__m128i a, b, c;
1266 a = b = c = _mm_set1_epi64((__m64)frobzor);
1267 a = _mm_slli_epi16(a, 3);
1268 a = _mm_adds_epi16(a, b);
1269 c = _mm_srli_epi16(c, 8);
1270 c = _mm_slli_epi16(c, 3);
1271 b = _mm_adds_epi16(b, c);
1272 a = _mm_unpacklo_epi8(a, b);
1273 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1274       ac_cv_c_sse2_intrinsics=yes
1275     ], [
1276       ac_cv_c_sse2_intrinsics=no
1277     ])
1278   ])
1279   VLC_RESTORE_FLAGS
1280   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1281     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1282   ])
1283
1284   VLC_SAVE_FLAGS
1285   CFLAGS="${CFLAGS} -msse"
1286   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1287     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1288 void *p;
1289 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1290 ]])
1291     ], [
1292       ac_cv_sse_inline=yes
1293     ], [
1294       ac_cv_sse_inline=no
1295     ])
1296   ])
1297
1298   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1299     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1300   ])
1301
1302   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1303     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1304 void *p;
1305 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1306 ]])
1307     ], [
1308       ac_cv_sse2_inline=yes
1309     ], [
1310       ac_cv_sse2_inline=no
1311     ])
1312   ])
1313   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1314     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1315     have_sse2="yes"
1316   ])
1317
1318   # SSE3
1319   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1320     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1321 void *p;
1322 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1323 ]])
1324     ], [
1325       ac_cv_sse3_inline=yes
1326     ], [
1327       ac_cv_sse3_inline=no
1328     ])
1329   ])
1330
1331   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1332     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1333   # SSSE3
1334   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1335     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1336 void *p;
1337 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1338 ]])
1339     ], [
1340       ac_cv_ssse3_inline=yes
1341     ], [
1342       ac_cv_ssse3_inline=no
1343     ])
1344   ])
1345
1346   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1347     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1348
1349   # SSE4.1
1350   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1351                  [ac_cv_sse4_1_inline], [
1352     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1353 void *p;
1354 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1355 ]])
1356     ], [
1357       ac_cv_sse4_1_inline=yes
1358     ], [
1359       ac_cv_sse4_1_inline=no
1360     ])
1361   ])
1362
1363   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1364     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1365
1366   # SSE4.2
1367   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1368                  [ac_cv_sse4_2_inline], [
1369     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1370 void *p;
1371 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1372 ]])
1373     ], [
1374       ac_cv_sse4_2_inline=yes
1375     ], [
1376       ac_cv_sse4_2_inline=no
1377     ])
1378   ])
1379
1380   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1381     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1382
1383   # SSE4A
1384   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1385     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1386 void *p;
1387 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1388 ]])
1389     ], [
1390       ac_cv_sse4a_inline=yes
1391     ], [
1392       ac_cv_sse4a_inline=no
1393     ])
1394   ])
1395   VLC_RESTORE_FLAGS
1396   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1397     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1398 ])
1399 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1400
1401 VLC_SAVE_FLAGS
1402 CFLAGS="${CFLAGS} -mmmx"
1403 have_3dnow="no"
1404 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1405   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1406 void *p;
1407 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1408 ]])
1409   ], [
1410     ac_cv_3dnow_inline=yes
1411   ], [
1412     ac_cv_3dnow_inline=no
1413   ])
1414 ])
1415 VLC_RESTORE_FLAGS
1416 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1417   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1418             [Define to 1 if 3D Now! inline assembly is available.])
1419   have_3dnow="yes"
1420 ])
1421 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1422
1423
1424 AC_ARG_ENABLE(neon,
1425   [AS_HELP_STRING([--disable-neon],
1426     [disable NEON optimizations (default auto)])],, [
1427   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1428 ])
1429 AS_IF([test "${enable_neon}" != "no"], [
1430   VLC_SAVE_FLAGS
1431   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1432   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1433     AC_COMPILE_IFELSE([
1434       AC_LANG_PROGRAM(,[[
1435 asm volatile("vqmovun.s64 d0, q1":::"d0");
1436 ]])
1437     ], [
1438       ac_cv_arm_neon="yes"
1439     ], [
1440       ac_cv_arm_neon="no"
1441     ])
1442   ])
1443   VLC_RESTORE_FLAGS
1444 ])
1445 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1446
1447 AC_ARG_ENABLE(arm64,
1448   [AS_HELP_STRING([--disable-arm64],
1449     [disable arm 64-bit optimizations (default auto)])],, [
1450   AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1451 ])
1452 AS_IF([test "${enable_arm64}" != "no"], [
1453   AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1454     AC_COMPILE_IFELSE([
1455       AC_LANG_PROGRAM(,[[
1456 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1457 ]])
1458     ], [
1459       ac_cv_arm64="yes"
1460     ], [
1461       ac_cv_arm64="no"
1462     ])
1463   ])
1464 ])
1465 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1466
1467
1468 AC_ARG_ENABLE(altivec,
1469   [AS_HELP_STRING([--disable-altivec],
1470     [disable AltiVec optimizations (default auto)])],, [
1471   AS_CASE("${host_cpu}", [powerpc*],
1472         [enable_altivec=yes], [enable_altivec=no])
1473 ])
1474 have_altivec="no"
1475 ALTIVEC_CFLAGS=""
1476 AS_IF([test "${enable_altivec}" = "yes"], [
1477   ARCH="${ARCH} altivec";
1478   VLC_SAVE_FLAGS
1479   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1480     [ac_cv_altivec_inline],
1481     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1482          ac_cv_altivec_inline="yes",
1483          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1484           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1485             [ac_cv_altivec_inline="-Wa,-maltivec"],
1486             ac_cv_altivec_inline=no)
1487          ])])
1488   VLC_RESTORE_FLAGS
1489   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1490     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1491               [Define to 1 if AltiVec inline assembly is available.])
1492     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1493       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1494       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1495     ])
1496     have_altivec="yes"
1497   ])
1498
1499   VLC_SAVE_FLAGS
1500   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1501   [ac_cv_c_altivec], [
1502     CFLAGS="${CFLAGS} -maltivec"
1503     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1504 [#include <altivec.h>]], [
1505 [vec_ld(0, (unsigned char *)0);]])], [
1506       ac_cv_c_altivec="-maltivec"
1507     ], [
1508       ac_cv_c_altivec="no"
1509     ])
1510   ])
1511   VLC_RESTORE_FLAGS
1512   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1513     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1514     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1515     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1516     ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1517     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1518     have_altivec="yes"
1519   ])
1520   AC_CHECK_HEADERS(altivec.h)
1521
1522   VLC_SAVE_FLAGS
1523   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1524   AC_CACHE_CHECK([if linker needs -framework vecLib],
1525     [ac_cv_ld_altivec],
1526     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1527   VLC_RESTORE_FLAGS
1528   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1529     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1530   ])
1531 ])
1532 AC_SUBST(ALTIVEC_CFLAGS)
1533 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1534
1535 dnl
1536 dnl  Memory usage
1537 dnl
1538 AC_ARG_ENABLE(optimize-memory,
1539   [AS_HELP_STRING([--enable-optimize-memory],
1540     [optimize memory usage over performance])])
1541 if test "${enable_optimize_memory}" = "yes"; then
1542   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1543 fi
1544
1545 dnl
1546 dnl Allow running as root (useful for people running on embedded platforms)
1547 dnl
1548 AC_ARG_ENABLE(run-as-root,
1549   [AS_HELP_STRING([--enable-run-as-root],
1550     [allow running VLC as root (default disabled)])])
1551 AS_IF([test "${enable_run_as_root}" = "yes"],[
1552     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1553               [Define to 1 to allow running VLC as root (uid 0).])
1554 ])
1555
1556 dnl
1557 dnl Stream output
1558 dnl
1559 AC_ARG_ENABLE(sout,
1560   [AS_HELP_STRING([--disable-sout],
1561     [disable streaming output (default enabled)])])
1562 AS_IF([test "${enable_sout}" != "no"], [
1563   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1564 ])
1565 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1566
1567 dnl Lua modules
1568 AC_ARG_ENABLE(lua,
1569   [AS_HELP_STRING([--disable-lua],
1570     [disable LUA scripting support (default enabled)])])
1571 if test "${enable_lua}" != "no"
1572 then
1573   PKG_CHECK_MODULES(LUA, lua5.2,
1574     [ have_lua=yes ],
1575     [
1576     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1577
1578     PKG_CHECK_MODULES(LUA, lua5.1,
1579       [ have_lua=yes ],
1580       [
1581       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1582       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1583         [ have_lua=yes ],
1584         [
1585           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1586           have_lua=yes
1587           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1588             [],
1589             [ have_lua=no ] )
1590           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1591             [LUA_LIBS="-llua5.2"],
1592           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1593             [LUA_LIBS="-llua5.1"],
1594             AC_CHECK_LIB( lua51 , luaL_newstate,
1595               [LUA_LIBS="-llua51"],
1596               AC_CHECK_LIB( lua , luaL_newstate,
1597                 [LUA_LIBS="-llua"],
1598                 [ have_lua=no
1599                 ], [-lm])
1600             )))
1601         ])
1602       ])
1603     ])
1604   if test "x${have_lua}" != "xyes" ;  then
1605       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1606   fi
1607   AC_ARG_VAR([LUAC], [LUA byte compiler])
1608   AS_IF([test -z "$LUAC"], [
1609      AC_CHECK_TOOL(LUAC, [luac], [false])
1610   ])
1611   AS_IF([test "${LUAC}" = "false"], [
1612     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1613   ])
1614   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1615     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1616   ])
1617 fi
1618 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1619
1620
1621 dnl
1622 dnl HTTP daemon
1623 dnl
1624 AC_ARG_ENABLE(httpd,
1625   [AS_HELP_STRING([--disable-httpd],
1626     [disable the built-in HTTP server (default enabled)])])
1627 if test "${enable_httpd}" != "no"
1628 then
1629   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1630 fi
1631 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1632
1633
1634 dnl
1635 dnl VideoLAN manager
1636 dnl
1637 AC_ARG_ENABLE(vlm,
1638   [AS_HELP_STRING([--disable-vlm],
1639     [disable the stream manager (default enabled)])],,
1640   [enable_vlm="${enable_sout}"])
1641 AS_IF([test "${enable_vlm}" != "no"], [
1642   AS_IF([test "${enable_sout}" = "no"], [
1643     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1644   ])
1645   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1646 ])
1647 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1648
1649
1650 dnl
1651 dnl Addons manager storage and repositories modules
1652 dnl
1653 AC_ARG_ENABLE(addonmanagermodules,
1654   [AS_HELP_STRING([--disable-addonmanagermodules],
1655     [disable the addons manager modules (default enabled)])])
1656 if test "${enable_addonmanagermodules}" != "no"
1657 then
1658   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1659 fi
1660 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1661
1662
1663 dnl
1664 dnl  Input plugins
1665 dnl
1666
1667 EXTEND_HELP_STRING([Input plugins:])
1668
1669 dnl
1670 dnl  libarchive access module
1671 dnl
1672 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1673
1674 dnl
1675 dnl  live555 input
1676 dnl
1677 AC_ARG_ENABLE(live555,
1678   [AS_HELP_STRING([--enable-live555],
1679     [enable RTSP input through live555 (default enabled)])])
1680
1681 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1682   PKG_CHECK_MODULES(LIVE555, live555, [
1683     VLC_ADD_PLUGIN([live555])
1684     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1685     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1686   ], [
1687     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1688
1689     AC_LANG_PUSH(C++)
1690     VLC_SAVE_FLAGS
1691
1692     dnl detect include paths
1693     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1694       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1695     ], [
1696       AS_IF([test "${SYS}" != "os2"], [
1697         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1698         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1699       ], [
1700         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1701         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1702         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1703       ])
1704     ])
1705
1706     dnl CPP Flags
1707     AS_IF([test "${SYS}" = "solaris"], [
1708       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1709     ])
1710     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1711     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1712
1713     dnl version check
1714     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1715       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1716 [#include <liveMedia_version.hh>
1717 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1718 # error BOOM
1719 #endif]])
1720       ], [
1721         ac_cv_live555="yes"
1722       ], [
1723         ac_cv_live555="no"
1724       ])
1725     ])
1726
1727     AS_IF([test "$ac_cv_live555" = "no"], [
1728       AC_MSG_WARN([live555 is missing or its installed version is too old:
1729 Version 2011.12.23 or later is required to proceed.
1730 You can get an updated one from http://www.live555.com/liveMedia .])
1731       AS_IF([test -n "${enable_live555}"], [
1732         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1733       ])
1734     ], [
1735       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1736       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1737       AS_IF([test "${SYS}" = "mingw32"], [
1738         # add ws2_32 for closesocket, select, recv
1739         other_libs="$other_libs -lws2_32"
1740       ])
1741
1742       dnl We need to check for pic because live555 don't provide shared libs
1743       dnl and we want to build a plugins so we need -fPIC on some arch.
1744       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1745       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1746       AC_CHECK_LIB(liveMedia_pic, main, [
1747         VLC_ADD_PLUGIN([live555])
1748         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1749       ],[
1750         AC_CHECK_LIB(liveMedia, main, [
1751           VLC_ADD_PLUGIN([live555])
1752           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1753         ],[],[${other_libs}])
1754       ],[${other_libs_pic}])
1755     ])
1756     VLC_RESTORE_FLAGS
1757     AC_LANG_POP(C++)
1758   ])
1759 ])
1760
1761 dnl
1762 dnl IIDC and DV FireWire input modules
1763 dnl
1764 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1765 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1766
1767 dnl
1768 dnl - linsys modules: access module check for libzvbi
1769 dnl
1770 AC_ARG_ENABLE(linsys,
1771   [AS_HELP_STRING([--enable-linsys],
1772     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1773 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1774   VLC_ADD_PLUGIN([linsys_hdsdi])
1775   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1776     VLC_ADD_PLUGIN([linsys_sdi])
1777   ], [
1778     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1779   ])
1780 ])
1781
1782 dnl
1783 dnl dvdread module: check for libdvdread
1784 dnl
1785 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1786
1787 dnl
1788 dnl libdvdnav plugin
1789 dnl
1790 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1791 AS_IF([test "${enable_dvdnav}" != "no"], [
1792   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1793     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1794       AC_MSG_RESULT(yes)
1795       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1796       ],[
1797       AC_MSG_RESULT(no)
1798     ])
1799 ])
1800
1801 dnl
1802 dnl  Blu-ray Disc Support with libbluray
1803 dnl
1804 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1805
1806 dnl
1807 dnl  OpenCV wrapper and example filters
1808 dnl
1809 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1810
1811
1812 dnl
1813 dnl  libsmbclient plugin
1814 dnl
1815 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1816 AS_IF([test "${SYS}" = "mingw32" -a "${enable_winstore_app}" != "yes"], [ VLC_ADD_PLUGIN([smb]) ])
1817
1818 dnl
1819 dnl  liBDSM access module
1820 dnl
1821 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1822
1823 dnl
1824 dnl sftp access support
1825 dnl
1826 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1827
1828 dnl
1829 dnl nfs access support
1830 dnl
1831 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1832
1833 dnl
1834 dnl  Video4Linux 2
1835 dnl
1836 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1837   [disable Video4Linux version 2 (default auto)])])
1838 have_v4l2="no"
1839 AS_IF([test "$enable_v4l2" != "no"], [
1840   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1841     have_v4l2="yes"
1842   ])
1843 ])
1844 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1845
1846 dnl
1847 dnl special access module for Blackmagic SDI cards
1848 dnl
1849 AC_ARG_ENABLE(decklink,
1850   [AS_HELP_STRING([--disable-decklink],
1851     [disable Blackmagic DeckLink SDI input (default auto)])])
1852 AC_ARG_WITH(decklink_sdk,
1853   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1854     [                        location of Blackmagic DeckLink SDI SDK])])
1855 have_decklink=no
1856 if test "${enable_decklink}" != "no"
1857 then
1858   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1859   then
1860     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1861   fi
1862   VLC_SAVE_FLAGS
1863   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1864   AC_LANG_PUSH(C++)
1865   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1866       have_decklink=yes
1867   ], [
1868       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1869   ])
1870   AC_LANG_POP(C++)
1871   VLC_RESTORE_FLAGS
1872 fi
1873 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1874
1875
1876 dnl
1877 dnl  Built-in CD-DA and VCD module
1878 dnl
1879 AC_ARG_ENABLE(vcd,
1880   [AS_HELP_STRING([--disable-vcd],
1881     [disable built-in VCD and CD-DA support (default enabled)])])
1882
1883 AC_ARG_ENABLE(libcddb,
1884   [AS_HELP_STRING([--disable-libcddb],
1885     [disable CDDB for Audio CD (default enabled)])])
1886
1887 if test "${enable_vcd}" != "no"
1888 then
1889   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1890   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1891     AC_MSG_RESULT(yes)
1892     VLC_ADD_PLUGIN([vcd cdda])
1893   ],[
1894     AC_MSG_RESULT(no)
1895   ])
1896
1897   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1898   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1899     AC_MSG_RESULT(yes)
1900     VLC_ADD_PLUGIN([vcd cdda])
1901     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1902   ],[
1903     AC_MSG_RESULT(no)
1904   ])
1905
1906   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1907   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1908     AC_MSG_RESULT(yes)
1909     VLC_ADD_PLUGIN([vcd cdda])
1910     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1911   ],[
1912     AC_MSG_RESULT(no)
1913   ])
1914
1915   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1916   then
1917     VLC_ADD_PLUGIN([vcd cdda])
1918   fi
1919
1920   if test "$enable_libcddb" != "no"; then
1921     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1922       HAVE_LIBCDDB=yes
1923       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1924       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1925       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1926       ],:
1927       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1928       HAVE_LIBCDDB=no])
1929   fi
1930 fi
1931
1932 dnl
1933 dnl Linux DVB
1934 dnl
1935 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1936   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1937 [#include <linux/dvb/version.h>
1938 #if (DVB_API_VERSION < 5)
1939 # error Linux DVB API v3.2 and older are not supported.
1940 #endif
1941 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1942 # error Linux DVB API v5.0 is unsupported. Please update.
1943 #endif
1944 ]])], [
1945   ac_cv_linux_dvb_5_1=yes
1946 ], [
1947   ac_cv_linux_dvb_5_1=no
1948 ])])
1949 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1950
1951 dnl
1952 dnl  Screen capture module
1953 dnl
1954 AC_ARG_ENABLE(screen,
1955   [AS_HELP_STRING([--enable-screen],
1956     [disable screen capture (default enabled)])])
1957 if test "${enable_screen}" != "no"; then
1958   if test "${SYS}" = "darwin"; then
1959     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1960       VLC_ADD_PLUGIN([screen])
1961     ])
1962   fi
1963 fi
1964 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1965
1966 dnl
1967 dnl  VNC/RFB access module
1968 dnl
1969 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1970
1971 dnl  RDP/Remote Desktop access module
1972 dnl
1973 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1974
1975 dnl
1976 dnl  Real RTSP plugin
1977 dnl
1978 AC_ARG_ENABLE(realrtsp,
1979   [  --enable-realrtsp       Real RTSP module (default disabled)])
1980 if test "${enable_realrtsp}" = "yes"; then
1981   VLC_ADD_PLUGIN([access_realrtsp])
1982 fi
1983
1984 dnl
1985 dnl QTKit
1986 AC_ARG_ENABLE(macosx-qtkit,
1987   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
1988 if test "x${enable_macosx_qtkit}" != "xno" &&
1989   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1990 then
1991   AC_CHECK_HEADERS(QTKit/QTKit.h, [
1992       VLC_ADD_PLUGIN([qtsound])
1993     ])
1994 fi
1995
1996 dnl
1997 dnl AVFoundation
1998 AC_SUBST(have_avfoundation, ["no"])
1999 AC_ARG_ENABLE(macosx-avfoundation,
2000   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
2001 if test "x${enable_macosx_avfoundation}" != "xno" &&
2002   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2003 then
2004   SAVED_LIBS="${LIBS}"
2005   LIBS="-framework AVFoundation"
2006   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2007   LIBS="${SAVED_LIBS}"
2008   if test "${have_avfoundation}" != "no"
2009   then
2010     VLC_ADD_PLUGIN([avcapture])
2011   fi
2012 fi
2013 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2014
2015 dnl
2016 dnl  DCP plugin (using asdcplib)
2017 dnl
2018 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2019 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2020
2021 dnl
2022 dnl  Demux plugins
2023 dnl
2024
2025 EXTEND_HELP_STRING([Mux/Demux plugins:])
2026
2027 dnl
2028 dnl  libdvbpsi check for ts mux/demux
2029 dnl
2030 have_dvbpsi="no"
2031 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2032 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2033
2034
2035 dnl
2036 dnl  GME demux plugin
2037 dnl
2038 AC_ARG_ENABLE(gme,
2039   [AS_HELP_STRING([--enable-gme],
2040     [use Game Music Emu (default auto)])])
2041 AS_IF([test "${enable_gme}" != "no"], [
2042   AC_CHECK_HEADER([gme/gme.h], [
2043     VLC_ADD_LIBS([gme], [-lgme])
2044     VLC_ADD_PLUGIN([gme])
2045   ], [
2046     AS_IF([test "x${enable_gme}" != "x"], [
2047       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2048     ])
2049   ])
2050 ])
2051
2052
2053 dnl
2054 dnl  SIDPlay plugin
2055 dnl
2056 AC_ARG_ENABLE(sid,
2057     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2058 AS_IF([test "${enable_sid}" != "no"], [
2059     PKG_CHECK_MODULES(SID, [libsidplay2], [
2060         AC_LANG_PUSH(C++)
2061         oldCPPFLAGS="$CPPFLAGS"
2062         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2063         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2064             VLC_ADD_PLUGIN([sid])
2065             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2066             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2067         ], [
2068             AS_IF([test -n "${enable_sid}"],
2069                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2070                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2071                 )
2072         ])
2073         CPPFLAGS="$oldCPPFLAGS"
2074         AC_LANG_POP(C++)
2075     ], [
2076         AS_IF([test "x${enable_sid}" = "xyes"],
2077             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2078             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2079             )
2080     ])
2081 ])
2082
2083
2084 dnl
2085 dnl  ogg demux plugin
2086 dnl
2087 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2088 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2089     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2090 ],[true])
2091 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2092 if test "${enable_sout}" != "no"; then
2093 dnl Check for libshout
2094     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2095 fi
2096
2097 dnl
2098 dnl  matroska demux plugin
2099 dnl
2100 PKG_ENABLE_MODULES_VLC([MATROSKA], [mkv], [libebml libmatroska], [MKV format support], [auto])
2101
2102 dnl
2103 dnl  modplug demux plugin
2104 dnl
2105 AC_ARG_ENABLE(mod,
2106   [AS_HELP_STRING([--disable-mod],
2107     [do not use libmodplug (default auto)])])
2108 if test "${enable_mod}" != "no" ; then
2109     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2110           VLC_ADD_PLUGIN([mod])
2111           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2112           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2113           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2114     ],[
2115        AS_IF([test -n "${enable_mod}"],
2116          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2117          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2118     ])
2119 fi
2120
2121 dnl
2122 dnl  mpc demux plugin
2123 dnl
2124 AC_ARG_ENABLE(mpc,
2125   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2126 if test "${enable_mpc}" != "no"
2127 then
2128   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2129     VLC_ADD_PLUGIN([mpc])
2130     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2131     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2132     VLC_ADD_PLUGIN([mpc])
2133     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2134 fi
2135
2136 dnl
2137 dnl  Codec plugins
2138 dnl
2139
2140 EXTEND_HELP_STRING([Codec plugins:])
2141
2142 dnl
2143 dnl wmafixed plugin
2144 dnl
2145 AC_ARG_ENABLE(wma-fixed,
2146   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2147 if test "${enable_wma_fixed}" = "yes"
2148 then
2149   VLC_ADD_PLUGIN([wma_fixed])
2150 fi
2151
2152 dnl
2153 dnl shine encoder plugin
2154 dnl
2155 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2156
2157
2158 dnl
2159 dnl openmax il codec plugin
2160 dnl
2161 AC_ARG_ENABLE(omxil,
2162   [  --enable-omxil          openmax il codec module (default disabled)])
2163 if test "${enable_omxil}" = "yes"
2164 then
2165   VLC_ADD_PLUGIN([omxil])
2166 fi
2167
2168 dnl
2169 dnl openmax il vout plugin
2170 dnl
2171 AC_ARG_ENABLE(omxil-vout,
2172   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2173 if test "${enable_omxil_vout}" = "yes"
2174 then
2175   VLC_ADD_PLUGIN([omxil_vout])
2176 fi
2177
2178 dnl
2179 dnl raspberry pi openmax il configuration
2180 dnl
2181 AC_ARG_ENABLE(rpi-omxil,
2182   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2183 if test "${enable_rpi_omxil}" = "yes"
2184 then
2185   VLC_ADD_PLUGIN([omxil omxil_vout])
2186   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2187 fi
2188
2189 dnl
2190 dnl CrystalHD codec plugin
2191 dnl
2192 AC_ARG_ENABLE(crystalhd,
2193   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2194 if test "${enable_crystalhd}" != "no"; then
2195     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2196       VLC_ADD_PLUGIN([crystalhd])
2197       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2198     ],[
2199       if test "${SYS}" = "mingw32" ; then
2200         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2201           VLC_ADD_PLUGIN([crystalhd])
2202           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2203             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2204             ])
2205         ],[
2206           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2207                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2208                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2209         ],[#define __LINUX_USER__
2210                #include <libcrystalhd/bc_dts_types.h>
2211         ])
2212       fi
2213     ],[
2214        #include <libcrystalhd/bc_dts_types.h>
2215       ])
2216 fi
2217
2218 dnl
2219 dnl  mad plugin
2220 dnl
2221 have_mad="no"
2222 MAD_CFLAGS=""
2223 MAD_LIBS=""
2224
2225 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2226   enable_mad="yes"
2227 ], [
2228   with_mad="no"
2229 ])
2230 AS_IF([test "${with_mad}" != "no"], [
2231   MAD_CFLAGS="-I${with_mad}/include"
2232   MAD_LIBS="-L${with_mad}/lib"
2233 ])
2234
2235 AC_ARG_ENABLE(mad,
2236   [  --enable-mad            libmad module (default enabled)])
2237 AS_IF([test "${enable_mad}" != "no"], [
2238   VLC_SAVE_FLAGS
2239   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2240   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2241   AC_CHECK_HEADERS(mad.h, [
2242     AC_CHECK_LIB(mad, mad_bit_init, [
2243       have_mad="yes"
2244       MAD_LIBS="${MAD_LIBS} -lmad"
2245     ])
2246   ])
2247   VLC_RESTORE_FLAGS
2248   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2249     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2250   ])
2251 ])
2252 AC_SUBST(MAD_CFLAGS)
2253 AC_SUBST(MAD_LIBS)
2254 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2255
2256 dnl  mpg123 plugin
2257 dnl
2258 dnl
2259 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2260
2261 dnl
2262 dnl gstreamer stuff
2263 dnl
2264 AC_ARG_ENABLE(gst-decode,
2265   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2266
2267 have_gst_decode="no"
2268 AS_IF([test "${enable_gst_decode}" != "no"], [
2269   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2270     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2271       have_gst_decode="yes"
2272     ], [
2273       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2274     ])
2275   ], [
2276     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2277   ])
2278 ])
2279 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2280
2281 dnl
2282 dnl  avcodec decoder/encoder plugin
2283 dnl
2284 AC_ARG_ENABLE(merge-ffmpeg,
2285 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2286   enable_merge_ffmpeg="no"
2287 ])
2288 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2289
2290 AC_MSG_CHECKING([for libavutil variant])
2291 PKG_CHECK_EXISTS([libavutil], [
2292   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2293   libavutil_micro="${libavutil_version##*.}"
2294   AS_IF([test ${libavutil_micro} -le 99], [
2295     avfork="libav"
2296   ], [
2297     avfork="ffmpeg"
2298   ])
2299 ], [
2300   avfork="none"
2301 ])
2302 AC_MSG_RESULT([${avfork}])
2303
2304 AC_ARG_ENABLE(avcodec,
2305 [  --enable-avcodec        libavcodec codec (default enabled)])
2306 AS_IF([test "${enable_avcodec}" != "no"], [
2307   dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2308   case "${avfork}" in
2309     libav) av_codec_ver="57.16.0" ;;
2310     ffmpeg) av_codec_ver="57.37.100" ;;
2311     *) AC_MSG_ERROR([Missing libav or FFmpeg])
2312   esac
2313   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2314     VLC_SAVE_FLAGS
2315     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2316     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2317     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2318     AC_CHECK_HEADERS(libavutil/avutil.h)
2319     VLC_RESTORE_FLAGS
2320     have_avcodec="yes"
2321   ],[
2322     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2323   ])
2324 ], [
2325   have_avcodec="no"
2326 ])
2327 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2328
2329 dnl
2330 dnl libva needs avcodec
2331 dnl
2332 AC_ARG_ENABLE(libva,
2333   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2334
2335 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2336   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2337 ])
2338
2339 have_vaapi="no"
2340 have_vaapi_drm="no"
2341 have_vaapi_x11="no"
2342 have_vaapi_wl="no"
2343 AS_IF([test "${enable_libva}" != "no"], [
2344   PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2345     have_vaapi="yes"
2346   ], [
2347     AS_IF([test -n "${enable_libva}"], [
2348       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2349     ], [
2350       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2351     ])
2352   ])
2353   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2354     have_vaapi_drm="yes"
2355   ], [
2356     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2357   ])
2358   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2359     have_vaapi_x11="yes"
2360   ], [
2361     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2362   ])
2363   PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2364     have_vaapi_wl="yes"
2365   ], [
2366     AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2367   ])
2368 ])
2369 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2370 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2371 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2372 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2373
2374 have_avcodec_vaapi="no"
2375 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2376   VLC_SAVE_FLAGS
2377   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2378   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2379   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2380     AC_MSG_NOTICE([VA API acceleration activated])
2381     have_avcodec_vaapi="yes"
2382   ],[
2383     AS_IF([test -n "${enable_libva}"], [
2384       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2385     ], [
2386       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2387     ])
2388   ])
2389   VLC_RESTORE_FLAGS
2390 ])
2391 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2392
2393 dnl
2394 dnl dxva2 needs avcodec
2395 dnl
2396 AC_ARG_ENABLE(dxva2,
2397   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2398
2399 have_avcodec_dxva2="no"
2400 AS_IF([test "${enable_dxva2}" != "no"], [
2401   if test "${SYS}" = "mingw32"; then
2402   AS_IF([test "x${have_avcodec}" = "xyes"], [
2403     AC_CHECK_HEADERS(dxva2api.h,
2404       [
2405         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2406            AC_MSG_NOTICE([DxVA2 acceleration activated])
2407            have_avcodec_dxva2="yes"
2408         ],[
2409     AS_IF([test "${enable_dxva2}" = "yes"],
2410           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2411               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2412         ], [#undef _WIN32_WINNT
2413             /* DXVA2 is only available in Vista and above */
2414             #define _WIN32_WINNT 0x600])
2415       ],[
2416     AS_IF([test "${enable_dxva2}" = "yes"],
2417               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2418               [AC_MSG_WARN([dxva2api.h not found])])
2419       ],[#include <d3d9.h>])
2420   ],[
2421     AS_IF([test "x${enable_dxva2}" != "x"], [
2422       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2423     ])
2424   ])
2425   fi
2426 ])
2427 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2428
2429 dnl
2430 dnl d3d11va needs avcodec
2431 dnl
2432 AC_ARG_ENABLE(d3d11va,
2433   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2434
2435 have_avcodec_d3d11va="no"
2436 AS_IF([test "${enable_d3d11va}" != "no"], [
2437   if test "${SYS}" = "mingw32"; then
2438   AS_IF([test "x${have_avcodec}" = "xyes"], [
2439         AC_CHECK_TYPES([ID3D11VideoDecoder],
2440           [
2441             AC_CHECK_HEADERS(dxva2api.h,
2442               [
2443                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2444                    AC_MSG_NOTICE([D3D11 acceleration activated])
2445                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2446                    have_avcodec_d3d11va="yes"
2447                 ],[
2448                   AS_IF([test "${enable_d3d11va}" = "yes"],
2449                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2450                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2451                   ], [#undef _WIN32_WINNT
2452                       /* D3D11 is only available in Vista and above */
2453                       #define _WIN32_WINNT 0x600])
2454                   ],[
2455                     AS_IF([test "${enable_d3d11va}" = "yes"],
2456                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2457                           [AC_MSG_WARN([dxva2api.h not found])])
2458                   ],[#include <d3d9.h>])
2459           ],[
2460             AS_IF([test "${enable_d3d11va}" = "yes"],
2461                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2462                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2463           ], [#include <d3d11.h>])
2464   ],[
2465     AS_IF([test "x${enable_d3d11va}" != "x"], [
2466       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2467     ])
2468   ])
2469   fi
2470 ])
2471 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2472
2473 dnl
2474 dnl DXGI debug
2475 dnl
2476 AC_CHECK_HEADERS(dxgidebug.h)
2477
2478 dnl
2479 dnl  avformat demuxer/muxer plugin
2480 dnl
2481
2482 AC_ARG_ENABLE(avformat,
2483 [  --enable-avformat       libavformat containers (default enabled)],, [
2484   enable_avformat="${have_avcodec}"
2485 ])
2486 have_avformat="no"
2487 AS_IF([test "${enable_avformat}" != "no"], [
2488   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2489       have_avformat="yes"
2490       VLC_SAVE_FLAGS
2491       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2492       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2493       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2494       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2495       AC_CHECK_HEADERS(libavutil/avutil.h)
2496       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2497         have_avformat="no"
2498       ])
2499       VLC_RESTORE_FLAGS
2500     ],[
2501       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2502   ])
2503 ])
2504 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2505
2506 dnl
2507 dnl  swscale image scaling and conversion plugin
2508 dnl
2509
2510 AC_ARG_ENABLE(swscale,
2511   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2512           (default enabled)]))
2513 if test "${enable_swscale}" != "no"
2514 then
2515   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2516     [
2517       VLC_SAVE_FLAGS
2518       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2519       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2520       AC_CHECK_HEADERS(libswscale/swscale.h)
2521       AC_CHECK_HEADERS(libavutil/avutil.h)
2522       VLC_ADD_PLUGIN([swscale])
2523       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2524       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2525       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2526         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2527       ])
2528       VLC_RESTORE_FLAGS
2529     ],[
2530       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2531   ])
2532 fi
2533
2534 dnl
2535 dnl  postproc plugin
2536 dnl
2537
2538 AC_ARG_ENABLE(postproc,
2539 [  --enable-postproc       libpostproc image post-processing (default auto)])
2540 if test "${enable_postproc}" != "no"
2541 then
2542   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2543     [
2544       VLC_SAVE_FLAGS
2545       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2546       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2547       AC_CHECK_HEADERS(postproc/postprocess.h)
2548       VLC_ADD_PLUGIN([postproc])
2549       VLC_RESTORE_FLAGS
2550     ],[
2551       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2552   ])
2553 fi
2554
2555 dnl
2556 dnl  faad decoder plugin
2557 dnl
2558 AC_ARG_ENABLE(faad,
2559 [  --enable-faad           faad codec (default auto)])
2560 have_faad="no"
2561 AS_IF([test "${enable_faad}" != "no"], [
2562   AC_CHECK_HEADERS([neaacdec.h], [
2563     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2564
2565     AS_IF([test "${have_faad}" = "yes"], [
2566       VLC_ADD_PLUGIN([faad])
2567       VLC_ADD_LIBS([faad],[-lfaad])
2568     ], [
2569       AS_IF([test "${enable_faad}" = "yes"], [
2570         AC_MSG_ERROR([cannot find FAAD library])
2571       ], [
2572         AC_MSG_WARN([cannot find FAAD library])
2573       ])
2574     ])
2575   ])
2576 ])
2577
2578 dnl
2579 dnl  AOM decoder plugin
2580 dnl
2581 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec], [disabled])
2582
2583 dnl
2584 dnl libvpx decoder plugin
2585 dnl
2586 AC_ARG_ENABLE(vpx,
2587     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2588 AS_IF([test "${enable_vpx}" != "no"],[
2589     PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2590         VLC_ADD_PLUGIN([vpx])
2591         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2592         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2593         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2594             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2595         ], [], [${VPX_LIBS}])
2596         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2597             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2598         ], [], [${VPX_LIBS}])
2599         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2600             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2601         ], [], [${VPX_LIBS}])
2602         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2603             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2604         ], [], [${VPX_LIBS}])
2605     ], [
2606     AS_IF([test "${enable_vpx}" = "yes"],[
2607         AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2608     ])])
2609 ])
2610
2611 dnl
2612 dnl twolame encoder plugin
2613 dnl
2614 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2615
2616 dnl
2617 dnl fdk-aac encoder plugin
2618 dnl
2619 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2620
2621
2622 dnl
2623 dnl A52/AC3 decoder plugin
2624 dnl
2625 AC_ARG_ENABLE(a52,
2626   [  --enable-a52            A/52 support with liba52 (default enabled)])
2627 if test "${enable_a52}" != "no"
2628 then
2629   AC_ARG_WITH(a52,
2630     [  --with-a52=PATH         a52 headers and libraries])
2631     if test -z "${with_a52}"
2632     then
2633       LDFLAGS_test=""
2634       CPPFLAGS_test=""
2635     else
2636       LDFLAGS_test="-L${with_a52}/lib"
2637       CPPFLAGS_test="-I${with_a52}/include"
2638     fi
2639     VLC_SAVE_FLAGS
2640     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2641     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2642     AC_CHECK_HEADERS(a52dec/a52.h, [
2643       AC_CHECK_LIB(a52, a52_free, [
2644         VLC_ADD_PLUGIN([a52])
2645         VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2646         VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2647       ],[
2648         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2649         ], [$LIBM])
2650     ],[
2651       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2652     ])
2653     VLC_RESTORE_FLAGS
2654 fi
2655
2656 dnl
2657 dnl DTS Coherent Acoustics decoder plugin
2658 dnl
2659 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2660
2661 dnl
2662 dnl  Flac plugin
2663 dnl
2664 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2665
2666 dnl
2667 dnl  Libmpeg2 plugin
2668 dnl
2669 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2670
2671 dnl
2672 dnl  Vorbis plugin
2673 dnl
2674 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2675
2676 dnl
2677 dnl  Tremor plugin
2678 dnl
2679 AC_ARG_ENABLE(tremor,
2680   [  --enable-tremor         Tremor decoder support (default disabled)])
2681 if test "${enable_tremor}" = "yes"
2682 then
2683   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2684     VLC_ADD_PLUGIN([tremor])
2685    ],[])
2686 fi
2687
2688 dnl
2689 dnl  Speex plugins
2690 dnl
2691 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2692 have_speexdsp="no"
2693 AS_IF([test "${enable_speex}" != "no"], [
2694   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2695     have_speexdsp="yes"
2696   ], [
2697     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2698   ])
2699 ])
2700 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2701
2702 dnl
2703 dnl  Opus plugin
2704 dnl
2705 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2706
2707 dnl
2708 dnl  Ambisonic channel mixer and binauralizer plugin
2709 dnl
2710 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
2711
2712 dnl
2713 dnl  theora decoder plugin
2714 dnl
2715 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2716
2717 dnl
2718 dnl  OggSpots decoder plugin
2719 dnl
2720 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2721
2722 dnl
2723 dnl  Daala decoder plugin
2724 dnl
2725 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2726
2727 dnl
2728 dnl  schroedinger decoder plugin (for dirac format video)
2729 dnl
2730 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2731
2732 dnl
2733 dnl  PNG decoder module
2734 dnl
2735 AC_ARG_ENABLE(png,
2736   [  --enable-png            PNG support (default enabled)])
2737 AS_IF([test "${enable_png}" != "no"], [
2738 AC_CHECK_HEADERS(png.h, [
2739   VLC_SAVE_FLAGS
2740   LDFLAGS="${LDFLAGS} -lz $LIBM"
2741   AC_CHECK_LIB(png, png_set_alpha_mode, [
2742     VLC_ADD_PLUGIN([png])
2743   ], [], [-lz $LIBM])
2744   VLC_RESTORE_FLAGS
2745   ])
2746 ])
2747
2748 dnl
2749 dnl  JPEG decoder module
2750 dnl
2751 AC_ARG_ENABLE(jpeg,
2752   [  --enable-jpeg           JPEG support (default enabled)])
2753 AS_IF([test "${enable_jpeg}" != "no"], [
2754 AC_CHECK_HEADERS(jpeglib.h, [
2755   VLC_ADD_PLUGIN([jpeg])
2756   ])
2757 ])
2758
2759 dnl
2760 dnl  BPG decoder module
2761 dnl
2762 AC_ARG_ENABLE(bpg,
2763   [  --enable-bpg           BPG support (default disabled)])
2764 AS_IF([test "${enable_bpg}" != "no"], [
2765 AC_CHECK_HEADERS(libbpg.h, [
2766   VLC_ADD_PLUGIN([bpg])
2767   ])
2768 ])
2769
2770 dnl
2771 dnl H262 encoder plugin (lib262)
2772 dnl
2773 AC_ARG_ENABLE(x262,
2774   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2775 if test "${enable_x262}" != "no"; then
2776     PKG_CHECK_MODULES(X262, x262, [
2777         VLC_ADD_PLUGIN([x262])
2778         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2779         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2780           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2781         ])
2782         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2783         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2784           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2785         fi
2786     ], [
2787        if test "${enable_x262}" = "yes"; then
2788         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2789        fi
2790     ])
2791 fi
2792
2793 dnl x265 encoder
2794 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2795
2796 dnl
2797 dnl H264 encoder plugin (10-bit lib264)
2798 dnl
2799 AC_ARG_ENABLE(x26410b,
2800   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2801 if test "${enable_x26410b}" != "no"; then
2802     PKG_CHECK_MODULES(X26410B, x26410b, [
2803         VLC_ADD_PLUGIN([x26410b])
2804         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2805         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2806           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2807         ])
2808         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2809         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2810           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2811         fi
2812     ], [
2813        if test "${enable_x26410b}" = "yes"; then
2814         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2815        fi
2816     ])
2817 fi
2818
2819
2820 dnl
2821 dnl H264 encoder plugin (using libx264)
2822 dnl
2823 AC_ARG_ENABLE(x264,
2824   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2825 if test "${enable_x264}" != "no"; then
2826       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2827         VLC_ADD_PLUGIN([x264])
2828         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2829
2830         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2831           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2832         ])
2833
2834         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2835         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2836           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2837         fi
2838       ],[
2839         if test "${enable_x264}" = "yes"; then
2840             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2841           fi
2842       ])
2843 fi
2844
2845 dnl
2846 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2847 dnl
2848 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2849
2850 dnl
2851 dnl libfluidsynth (MIDI synthetizer) plugin
2852 dnl
2853 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2854 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2855 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2856
2857 dnl
2858 dnl Teletext Modules
2859 dnl vbi decoder plugin (using libzbvi)
2860 dnl telx module
2861 dnl uncompatible
2862 dnl
2863 AC_ARG_ENABLE(zvbi,
2864   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2865                   libzvbi (default enabled)]))
2866 AC_ARG_ENABLE(telx,
2867   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2868                   zvbi) (default enabled if zvbi is absent)]))
2869
2870 AS_IF( [test "${enable_zvbi}" != "no"],[
2871     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2872         [
2873           VLC_ADD_PLUGIN([zvbi])
2874           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2875           AS_IF( [test "${enable_telx}" = "yes"],[
2876                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2877                   ])
2878         ],[
2879           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2880         ])
2881     ])
2882 AS_IF( [test "${enable_telx}" != "no" ],[
2883   VLC_ADD_PLUGIN([telx])
2884   ])
2885
2886 dnl
2887 dnl libass subtitle rendering module
2888 dnl
2889 AC_ARG_ENABLE(libass,
2890   [  --enable-libass         Subtitle support using libass (default enabled)])
2891 AS_IF( [test "${enable_libass}" != "no"], [
2892   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2893       [
2894         VLC_ADD_PLUGIN([libass])
2895
2896         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2897           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2898            VLC_ADD_LIBS([libass],[-lfontconfig])
2899        ])
2900       ],[
2901         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2902       ])
2903   ])
2904
2905 dnl
2906 dnl ARIB subtitles rendering module
2907 dnl
2908 AC_ARG_ENABLE(aribsub,
2909   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2910 AS_IF( [test "${enable_aribsub}" != "no" ],[
2911   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2912       have_aribb24="yes"
2913       VLC_ADD_PLUGIN([aribsub])
2914       VLC_ADD_LIBS([aribsub],[-laribb24])
2915       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2916     ],[
2917       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2918       have_aribb24="no"
2919   ])
2920 ])
2921 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2922
2923 dnl
2924 dnl ARIB B25
2925 dnl
2926 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2927
2928 dnl
2929 dnl  kate decoder plugin
2930 dnl
2931 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2932
2933 dnl
2934 dnl  tiger rendering for kate decoder plugin
2935 dnl
2936 AC_ARG_ENABLE(tiger,
2937 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2938 AS_IF([test "${enable_tiger}" != "no"], [
2939   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2940       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2941         AS_IF([test -n "${enable_tiger}"], [
2942           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2943         ])
2944   ])
2945 ])
2946
2947
2948 dnl
2949 dnl  Video plugins
2950 dnl
2951
2952 EXTEND_HELP_STRING([Video plugins:])
2953
2954 dnl
2955 dnl  OpenGL
2956 dnl
2957 PKG_CHECK_MODULES([EGL], [egl], [
2958   have_egl="yes"
2959 ], [
2960   have_egl="no"
2961 ])
2962 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
2963
2964 have_gl="no"
2965 PKG_CHECK_MODULES([GL], [gl], [
2966   have_gl="yes"
2967 ], [
2968   AC_MSG_CHECKING([for OpenGL])
2969   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2970 #ifdef _WIN32
2971 # include <GL/glew.h>
2972 #endif
2973 #include <GL/gl.h>
2974 ]], [
2975     [int t0 = GL_TEXTURE0;]])
2976   ], [
2977     GL_CFLAGS=""
2978     have_gl="yes"
2979     AS_IF([test "${SYS}" != "mingw32"], [
2980       GL_LIBS="-lGL"
2981     ], [
2982       GL_LIBS="-lopengl32"
2983     ])
2984   ])
2985   AC_MSG_RESULT([${have_gl}])
2986 ])
2987 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
2988
2989 dnl OpenGL ES 2: depends on EGL 1.1
2990 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
2991
2992 dnl
2993 dnl  Xlib
2994 dnl
2995
2996 AC_PATH_XTRA()
2997 AC_CHECK_HEADERS(X11/Xlib.h)
2998
2999 dnl
3000 dnl  X C Bindings modules
3001 dnl
3002 AC_ARG_ENABLE(xcb,
3003   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3004   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3005     enable_xcb="yes"
3006   ], [
3007     enable_xcb="no"
3008   ])
3009 ])
3010 AC_ARG_ENABLE(xvideo,
3011   [  --enable-xvideo         XVideo support (default enabled)],, [
3012     enable_xvideo="$enable_xcb"
3013 ])
3014
3015 have_xcb="no"
3016 have_xcb_keysyms="no"
3017 have_xcb_randr="no"
3018 have_xcb_xvideo="no"
3019 AS_IF([test "${enable_xcb}" != "no"], [
3020   dnl libxcb
3021   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3022   have_xcb="yes"
3023   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3024   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3025   PKG_CHECK_MODULES(XPROTO, [xproto])
3026
3027   AS_IF([test "${enable_xvideo}" != "no"], [
3028     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3029   ])
3030
3031   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3032
3033   dnl xcb-utils
3034   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3035     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3036   ])
3037 ])
3038 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3039 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3040 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3041 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3042
3043
3044 dnl
3045 dnl VDPAU needs X11
3046 dnl
3047 AC_ARG_ENABLE(vdpau,
3048   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3049 have_vdpau="no"
3050 AS_IF([test "${enable_vdpau}" != "no"], [
3051   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3052     have_vdpau="yes"
3053     AS_IF([test "${no_x}" = "yes"], [
3054       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3055     ])
3056   ], [
3057     AS_IF([test -n "${enable_vdpau}"], [
3058       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3059     ])
3060   ])
3061 ])
3062 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3063
3064 have_avcodec_vdpau="no"
3065 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3066   case "${avfork}" in
3067     libav) av_vdpau_ver="56.10.0" ;;
3068     ffmpeg) av_vdpau_ver="56.19.100" ;;
3069   esac
3070   PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3071     have_avcodec_vdpau="yes"
3072     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3073   ], [
3074     AS_IF([test -n "${enable_vdpau}"], [
3075       AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3076     ], [
3077       AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3078     ])
3079   ])
3080 ])
3081 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3082
3083
3084 dnl
3085 dnl  Wayland
3086 dnl
3087 AC_ARG_ENABLE(wayland,
3088   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3089 have_wayland="no"
3090 have_wayland_egl="no"
3091
3092 AS_IF([test "${enable_wayland}" != "no"], [
3093   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3094     AC_MSG_CHECKING([for the Wayland protocols])
3095     PKG_CHECK_EXISTS([wayland-protocols >= 1.4], [
3096       WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3097       AC_MSG_RESULT([${WAYLAND_PROTOCOLS}])
3098     ], [
3099       AC_MSG_RESULT([not found])
3100       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors 'wayland-protocols >= 1.4')])
3101     ])
3102
3103     AC_MSG_CHECKING([for the Wayland scanner])
3104     PKG_CHECK_EXISTS([wayland-scanner], [
3105       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3106       AC_MSG_RESULT([${WAYLAND_SCANNER}])
3107     ], [
3108       AC_MSG_RESULT([not found])
3109       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors wayland-scanner)])
3110     ])
3111
3112     have_wayland="yes"
3113
3114     AS_IF([test "${have_egl}" = "yes"], [
3115       PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3116         have_wayland_egl="yes"
3117       ], [
3118         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3119       ])
3120     ])
3121   ], [
3122     AS_IF([test -n "${enable_wayland}"], [
3123       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3124     ])
3125   ])
3126 ])
3127 AC_SUBST([WAYLAND_PROTOCOLS])
3128 AC_SUBST([WAYLAND_SCANNER])
3129 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3130 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3131
3132
3133 dnl
3134 dnl  SDL module
3135 dnl
3136 AC_ARG_ENABLE(sdl,
3137   [  --enable-sdl            SDL support (default enabled)])
3138 AC_ARG_ENABLE(sdl-image,
3139   [  --enable-sdl-image      SDL image support (default enabled)])
3140 if test "${enable_sdl}" != "no"
3141 then
3142    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3143       # SDL on Darwin is heavily patched and can only run SDL_image
3144       if test "${SYS}" != "darwin"; then
3145         VLC_ADD_PLUGIN([vout_sdl])
3146       fi
3147
3148       # SDL_image
3149       AS_IF([ test "${enable_sdl_image}" != "no"],[
3150         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3151           VLC_ADD_PLUGIN([sdl_image])],
3152           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3153           ])
3154       ])
3155    ],[
3156      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3157    ])
3158 fi
3159
3160 dnl
3161 dnl  freetype module
3162 dnl
3163 AC_ARG_ENABLE(freetype,
3164   [  --enable-freetype       freetype support   (default auto)])
3165 AC_ARG_ENABLE(fribidi,
3166   [  --enable-fribidi        fribidi support    (default auto)])
3167 AC_ARG_ENABLE(harfbuzz,
3168   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3169 AC_ARG_ENABLE(fontconfig,
3170   [  --enable-fontconfig     fontconfig support (default auto)])
3171
3172 AC_ARG_WITH([default-font],
3173     AS_HELP_STRING([--with-default-font=PATH],
3174         [Path to the default font]),
3175         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3176             "$withval", [Default font])])
3177 AC_ARG_WITH([default-monospace-font],
3178     AS_HELP_STRING([--with-default-monospace-font=PATH],
3179         [Path to the default font]),
3180         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3181             "$withval", [Default monospace font])])
3182
3183 AC_ARG_WITH([default-font-family],
3184     AS_HELP_STRING([--with-default-font-family=NAME],
3185         [Path to the default font family]),
3186         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3187             "$withval", [Default font family])])
3188 AC_ARG_WITH([default-monospace-font-family],
3189     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3190         [Path to the default font family]),
3191         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3192             "$withval", [Default monospace font family])])
3193
3194 have_freetype="no"
3195 have_fontconfig="no"
3196 have_fribidi="no"
3197 have_harfbuzz="no"
3198
3199 if test "${enable_freetype}" != "no"; then
3200    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3201       have_freetype="yes"
3202       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3203       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3204
3205     dnl fontconfig support
3206     AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3207       PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3208         have_fontconfig="yes"
3209       ], [
3210         AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3211       ])
3212     ])
3213
3214       dnl fribidi support
3215       if test "${enable_fribidi}" != "no"; then
3216         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3217           have_fribidi="yes"
3218           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3219           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3220         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3221       fi
3222
3223       dnl harfbuzz support
3224       if test "${have_fribidi}" != "no"; then
3225         if test "${enable_harfbuzz}" != "no"; then
3226           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3227             have_harfbuzz="yes"
3228             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3229             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3230           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3231         fi
3232       fi
3233   ],[
3234   AS_IF([test -n "${enable_freetype}"],[
3235     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3236     ])
3237   ])
3238 fi
3239
3240 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3241 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3242 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3243 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3244
3245 dnl
3246 dnl SAPI (text to Speech renderer for Windows)
3247 dnl
3248 AC_LANG_PUSH([C++])
3249 AC_CHECK_TYPES([ISpObjectToken],[
3250               have_sapi="yes"
3251             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3252               [#include <windows.h>
3253                #include <sapi.h>
3254                #include <sphelper.h>])
3255 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3256 AC_LANG_POP([C++])
3257
3258 dnl
3259 dnl  SVG module (text rendering and image decoding)
3260 dnl
3261 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3262 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3263
3264 dnl
3265 dnl  Windows DirectX module
3266 dnl
3267
3268 AC_ARG_ENABLE(directx,
3269   [AS_HELP_STRING([--enable-directx],
3270     [Microsoft DirectX support (default enabled on Windows)])],, [
3271   AS_IF([test "${SYS}" = "mingw32"], [
3272     enable_directx="yes"
3273   ], [
3274     enable_directx="no"
3275   ])
3276 ])
3277 AS_IF([test "${enable_directx}" != "no"], [
3278   dnl DirectDraw
3279   AC_CHECK_HEADERS(ddraw.h, [
3280     VLC_ADD_PLUGIN([directdraw])
3281   ])
3282
3283   dnl OpenGL
3284   AC_CHECK_HEADERS(GL/wglew.h, [
3285     VLC_ADD_PLUGIN([glwin32 wgl])
3286   ],, [
3287     #include <windows.h>
3288     #include <GL/gl.h>
3289   ])
3290
3291   dnl Direct3D11
3292   AC_CHECK_HEADERS(d3d11.h, [
3293     VLC_ADD_PLUGIN([direct3d11 direct3d11_deinterlace direct3d11_adjust])
3294   ])
3295
3296   dnl Direct3D9
3297   AC_CHECK_HEADERS(d3d9.h, [
3298     VLC_ADD_PLUGIN([direct3d9])
3299     AC_CHECK_HEADERS(d3dx9effect.h)
3300
3301     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3302         [[#define COBJMACROS
3303           #include <d3d9.h>
3304           #include <dxva2api.h>
3305           #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3306           # error dxva2 too old
3307           #endif
3308         ]],[[;]])
3309       ],[
3310         VLC_ADD_PLUGIN([direct3d9_deinterlace direct3d9_adjust])
3311       ],
3312       [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3313
3314   ])
3315 ])
3316
3317 dnl
3318 dnl  Linux framebuffer module
3319 dnl
3320 AC_CHECK_HEADER([linux/fb.h], [
3321   VLC_ADD_PLUGIN([fb])
3322 ])
3323
3324
3325 dnl
3326 dnl  DirectFB module
3327 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3328 dnl  TODO: support for static linking
3329 dnl
3330 AC_ARG_ENABLE(directfb,
3331   [  --enable-directfb       DirectFB support (default disabled)])
3332 AC_ARG_WITH(directfb,
3333   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3334
3335 if test "${enable_directfb}" = "yes"; then
3336     have_directfb="false"
3337     CPPFLAGS_mydirectfb=
3338     LIBS_mydirectfb=
3339     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3340         dnl Trying the given location
3341         VLC_SAVE_FLAGS
3342
3343         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3344         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3345
3346         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3347         LIBS="${LIBS} ${LIBS_new}"
3348
3349         dnl FIXME: too obscure
3350         AC_CHECK_HEADER([directfb.h], [
3351             AC_CHECK_LIB([direct],[direct_initialize], [
3352                 AC_CHECK_LIB([fusion], [fusion_enter], [
3353                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3354                 ], have_directfb="false")
3355             ], have_directfb="false")
3356         ], have_directfb="false")
3357
3358         VLC_RESTORE_FLAGS
3359
3360         if test "${have_directfb}" = "true"; then
3361             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3362             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3363         fi
3364     else
3365         dnl Look for directfb-config
3366         AC_CHECK_PROG(DIRECTFB_CONFIG, [directfb-config], [false])
3367         AS_IF(["${DIRECTFB_CONFIG}" != "false"], [
3368             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3369             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3370             have_directfb="true"
3371         ], [
3372             dnl Trying with pkg-config
3373             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3374                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3375                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3376                 have_directfb="true"
3377                 ], [have_directfb="false"])
3378         ])
3379     fi
3380     if test "${have_directfb}" = "true"; then
3381         VLC_ADD_PLUGIN([directfb])
3382         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3383         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3384     else
3385         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3386     fi
3387 fi
3388
3389 dnl
3390 dnl  AA plugin
3391 dnl
3392 AC_ARG_ENABLE(aa,
3393   [  --enable-aa             aalib output (default disabled)])
3394 if test "${enable_aa}" = "yes"
3395 then
3396   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3397   if test "${have_aa}" = "true"
3398   then
3399     VLC_ADD_PLUGIN([aa])
3400   fi
3401 fi
3402
3403 dnl
3404 dnl  libcaca plugin
3405 dnl
3406 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3407
3408 dnl
3409 dnl  OS/2 KVA plugin
3410 dnl
3411 AC_ARG_ENABLE(kva,
3412   [AS_HELP_STRING([--enable-kva],
3413     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3414   AS_IF([test "$SYS" = "os2"], [
3415     enable_kva="yes"
3416   ])
3417 ])
3418 have_kva="no"
3419 KVA_LIBS=""
3420 AS_IF([test "$enable_kva" != "no"], [
3421   AC_CHECK_HEADERS([kva.h], [
3422     have_kva="yes"
3423     AC_CHECK_LIB(kva, main, [
3424       KVA_LIBS="-lkva"
3425     ])
3426   ])
3427 ])
3428 AC_SUBST(KVA_LIBS)
3429 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3430
3431 dnl
3432 dnl MMAL plugin
3433 dnl
3434 AC_ARG_ENABLE(mmal,
3435   AS_HELP_STRING([--enable-mmal],
3436     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3437 if test "${enable_mmal}" != "no"; then
3438   VLC_SAVE_FLAGS
3439   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3440   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3441   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3442     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3443         have_mmal="yes"
3444         VLC_ADD_PLUGIN([mmal])
3445         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3446         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3447         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lvchostif ]) ], [
3448           AS_IF([test "${enable_mmal}" = "yes"],
3449             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3450             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3451           ],
3452         [])
3453     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3454       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3455       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3456   VLC_RESTORE_FLAGS
3457 fi
3458 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3459
3460 dnl
3461 dnl evas plugin
3462 dnl
3463 AC_ARG_ENABLE(evas,
3464   [AS_HELP_STRING([--enable-evas],
3465     [use evas output module (default disabled)])])
3466 have_evas="no"
3467 AS_IF([test "${enable_evas}" = "yes"], [
3468   PKG_CHECK_MODULES(EVAS, [evas >= 1.15.99 ecore >= 1.15.99], [
3469       have_evas="yes"
3470       AC_DEFINE([HAVE_EVAS], [1], [Define to 1 if evas is enabled.])
3471     ],[
3472     AS_IF([test "x${enable_evas}" != "x"], [
3473       AC_MSG_ERROR([$EVAS_PKG_ERRORS. libevas and libecore 1.15.99 or later required.])
3474     ])
3475   ])
3476 ])
3477 AM_CONDITIONAL([HAVE_EVAS], [test "${have_evas}" = "yes"])
3478
3479 dnl
3480 dnl  Audio plugins
3481 dnl
3482
3483 EXTEND_HELP_STRING([Audio plugins:])
3484
3485 dnl
3486 dnl  Pulseaudio module
3487 dnl
3488 AC_ARG_ENABLE(pulse,
3489   [AS_HELP_STRING([--enable-pulse],
3490     [use the PulseAudio client library (default auto)])])
3491 have_pulse="no"
3492 AS_IF([test "${enable_pulse}" != "no"], [
3493   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3494     have_pulse="yes"
3495   ], [
3496     AS_IF([test "x${enable_pulse}" != "x"], [
3497       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3498     ])
3499   ])
3500 ])
3501 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3502
3503 dnl
3504 dnl  ALSA module
3505 dnl
3506 AC_ARG_ENABLE(alsa,
3507   [AS_HELP_STRING([--enable-alsa],
3508     [support the Advanced Linux Sound Architecture (default auto)])],, [
3509   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3510     enable_alsa="yes"
3511   ])
3512 ])
3513 have_alsa="no"
3514 AS_IF([test "${enable_alsa}" != "no"], [
3515   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3516     have_alsa="yes"
3517   ], [
3518     AS_IF([test "x${enable_alsa}" != "x"], [
3519       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3520     ])
3521   ])
3522 ])
3523 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3524
3525 dnl
3526 dnl  Open Sound System module
3527 dnl
3528 AC_ARG_ENABLE(oss,
3529   [AS_HELP_STRING([--enable-oss],
3530     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3531   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3532     enable_oss="no"
3533   ])
3534 ])
3535 have_oss="no"
3536 OSS_LIBS=""
3537 AS_IF([test "$enable_oss" != "no"], [
3538   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3539     have_oss="yes"
3540     AC_CHECK_LIB(ossaudio, main, [
3541       OSS_LIBS="-lossaudio"
3542     ])
3543   ])
3544 ])
3545 AC_SUBST(OSS_LIBS)
3546 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3547
3548 dnl
3549 dnl  OpenBSD sndio module
3550 dnl
3551 AC_ARG_ENABLE([sndio],
3552   [AS_HELP_STRING([--disable-sndio],
3553     [support the OpenBSD sndio (default auto)])],, [
3554   AS_IF([test "$SYS" = "openbsd"], [
3555     enable_sndio="yes"
3556   ])
3557 ])
3558 have_sndio="no"
3559 AS_IF([test "$enable_sndio" != "no"], [
3560   AC_CHECK_HEADER([sndio.h], [
3561     have_sndio="yes"
3562   ])
3563 ])
3564 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3565
3566 dnl
3567 dnl  Windows Audio Session plugin
3568 dnl
3569 AC_ARG_ENABLE([wasapi],
3570   [AS_HELP_STRING([--enable-wasapi],
3571     [use the Windows Audio Session API (default auto)])
3572 ])
3573 have_wasapi="no"
3574 AS_IF([test "$enable_wasapi" != "no"], [
3575   AC_CHECK_HEADER([audioclient.h], [
3576     have_wasapi="yes"
3577   ], [
3578     AS_IF([test "x${enable_wasapi}" != "x"], [
3579       AC_MSG_ERROR([Windows Audio Session API not found.])
3580     ])
3581   ])
3582 ])
3583 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3584
3585 dnl
3586 dnl  JACK modules
3587 dnl
3588 AC_ARG_ENABLE(jack,
3589   [AS_HELP_STRING([--disable-jack],
3590     [do not use jack (default auto)])])
3591 have_jack="no"
3592 AS_IF([test "${enable_jack}" != "no"], [
3593     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3594       [ have_jack=yes ],
3595       [
3596       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3597
3598       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3599       [ have_jack=yes ],
3600       [
3601       AS_IF([test -n "${enable_jack}"],
3602          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3603          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3604       ])
3605     ])
3606 ])
3607 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3608
3609 dnl
3610 dnl  OpenSLES Android
3611 dnl
3612 AC_ARG_ENABLE(opensles,
3613   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3614 if test "${HAVE_ANDROID}" = "1"; then
3615   if test "${enable_opensles}" = "yes"; then
3616       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3617         [ VLC_ADD_PLUGIN([opensles_android]) ],
3618         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3619   fi
3620 fi
3621
3622 dnl
3623 dnl  Tizen audio
3624 dnl
3625 AC_ARG_ENABLE(tizen_audio,
3626   [AS_HELP_STRING([--enable-tizen-audio],
3627     [Tizen audio module (default enabled on Tizen)])],, [
3628   AS_IF([test "$HAVE_TIZEN" = "1"], [
3629     enable_tizen_audio="yes"
3630   ])
3631 ])
3632 if test "${enable_tizen_audio}" = "yes"; then
3633   AC_CHECK_HEADERS(audio_io.h,
3634     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3635     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3636 fi
3637
3638 dnl
3639 dnl libsamplerate plugin
3640 dnl
3641 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3642
3643 dnl
3644 dnl  soxr module
3645 dnl
3646 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3647
3648 dnl
3649 dnl  OS/2 KAI plugin
3650 dnl
3651 AC_ARG_ENABLE(kai,
3652   [AS_HELP_STRING([--enable-kai],
3653     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3654   AS_IF([test "$SYS" = "os2"], [
3655     enable_kai="yes"
3656   ])
3657 ])
3658 have_kai="no"
3659 KAI_LIBS=""
3660 AS_IF([test "$enable_kai" != "no"], [
3661   AC_CHECK_HEADERS([kai.h], [
3662     have_kai="yes"
3663     AC_CHECK_LIB(kai, main, [
3664       KAI_LIBS="-lkai"
3665     ])
3666   ])
3667 ])
3668 AC_SUBST(KAI_LIBS)
3669 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3670
3671 dnl
3672 dnl  chromaprint audio track fingerprinter
3673 dnl
3674 m4_pushdef([libchromaprint_version], 0.6.0)
3675 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3676     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3677     AS_IF([test "${enable_chromaprint}" = "yes"],
3678         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3679         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3680          ),
3681     [(Chromaprint based audio fingerprinter)],[auto])
3682 m4_popdef([libchromaprint_version])
3683
3684 dnl
3685 dnl  Chromecast streaming support
3686 dnl
3687 m4_pushdef([protobuf_lite_version], 2.5.0)
3688 AC_ARG_VAR(PROTOC, [protobuf compiler])
3689 AC_CHECK_PROGS(PROTOC, protoc, no)
3690 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3691     AS_IF([test "x${PROTOC}" != "xno"], [
3692         build_chromecast="yes"
3693     ], [
3694     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3695     ])
3696 ], [
3697     AS_IF([test "${enable_chromecast}" = "yes"],
3698         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3699         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3700     )
3701     enable_chromecast="no"
3702 ], [(Chromecast streaming support)], [auto])
3703 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3704 m4_popdef([protobuf_lite_version])
3705
3706 dnl
3707 dnl  Interface plugins
3708 dnl
3709
3710 EXTEND_HELP_STRING([Interface plugins:])
3711
3712 dnl
3713 dnl QT
3714 dnl
3715 AC_ARG_ENABLE(qt, [
3716   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3717   AS_IF([test "${SYS}" = "darwin"], [
3718     enable_qt="no"
3719   ])
3720 ])
3721 have_qt5_x11="no"
3722 AS_IF([test "${enable_qt}" != "no"], [
3723   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.2.0 Qt5Widgets Qt5Gui], [
3724       PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3725           have_qt5_x11="yes"
3726       ],[
3727           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3728       ])
3729       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3730       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3731       QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3732       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3733       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3734       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3735     ], [
3736       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.8.0],, [
3737         AS_IF([test -n "${enable_qt}"],[
3738           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3739         ],[
3740           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3741         ])
3742         enable_qt="no"
3743       ])
3744       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3745       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin"])
3746       AC_PATH_PROG(RCC, rcc, rcc, ["${QT_PATH}/bin"])
3747       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin"])
3748     ])
3749 ])
3750 AS_IF([test "${enable_qt}" != "no"], [
3751   ALIASES="${ALIASES} qvlc"
3752 ])
3753 AC_SUBST(QT_VERSION)
3754 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3755 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3756
3757 dnl
3758 dnl detect kde4-config patch (used for kde solids).
3759 dnl
3760 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3761 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3762   KDE4_CONFIG="kde4-config"
3763 ])
3764
3765 dnl
3766 dnl Simple test for skins2 dependency
3767 dnl
3768 AS_IF([test "$enable_qt" = "no"], [
3769   AS_IF([test "${enable_skins2}" = "yes"], [
3770     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3771   ], [
3772     enable_skins2="no"
3773     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3774   ])
3775 ])
3776
3777 dnl
3778 dnl Skins2 module
3779 dnl
3780 AC_ARG_ENABLE(skins2,
3781   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3782 AS_IF([test "${enable_skins2}" != "no"], [
3783   have_skins_deps="yes"
3784
3785   dnl Win32
3786   AS_IF([test "${SYS}" = "mingw32"], [
3787     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3788     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3789   dnl OS/2
3790   ], [test "${SYS}" = "os2"], [
3791     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3792   dnl Linux/Unix
3793   ], [
3794     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3795     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3796     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3797     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3798     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3799   ])
3800
3801   dnl we need freetype
3802   AS_IF([test "${have_freetype}" != "yes"], [
3803     have_skins_deps="no"
3804   ])
3805
3806   AS_IF([test "${have_skins_deps}" = "no"], [
3807     AS_IF([test "x${enable_skins2}" = "x"], [
3808       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3809     ], [
3810       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3811     ])
3812     enable_skins2="no"
3813   ], [
3814     ALIASES="${ALIASES} svlc"
3815     enable_skins2="yes"
3816   ])
3817 ])
3818 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3819
3820 AC_ARG_ENABLE(libtar,
3821   [  --enable-libtar         libtar support for skins2 (default auto)])
3822 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3823   AC_CHECK_HEADERS(libtar.h, [
3824     VLC_ADD_LIBS([skins2],[-ltar])
3825   ])
3826 ])
3827
3828 dnl
3829 dnl  MacOS X gui module
3830 dnl
3831 AC_ARG_ENABLE(macosx,
3832   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3833 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3834 then
3835
3836   dnl
3837   dnl If possible, use xcrun to find the right ibtool
3838   dnl
3839
3840   AC_PATH_PROG([XCRUN], [xcrun], [no])
3841   AS_IF([test ! "x${XCRUN}" = "xno"], [
3842     AC_MSG_CHECKING([for ibtool (using xcrun)])
3843     XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3844     AC_MSG_RESULT([${XIB}])
3845   ], [
3846     AC_MSG_WARN([Looking for tools without using xcrun])
3847   ])
3848
3849   AS_IF([test "x${XIB}" = "xno"], [
3850     AC_PATH_PROG(XIB, [ibtool], [no])
3851     AS_IF([test "x${XIB}" = "xno"], [
3852       AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3853     ])
3854   ])
3855 fi
3856 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3857
3858 dnl
3859 dnl  MacOS X sparkle update support
3860 dnl
3861 AC_ARG_ENABLE(sparkle,
3862   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3863 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3864 then
3865   if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3866   then
3867     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3868   fi
3869
3870   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3871 fi
3872 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3873
3874 dnl
3875 dnl  MacOS X breakpad creash reporter support
3876 dnl
3877 AC_ARG_ENABLE(breakpad,
3878   [  --enable-breakpad       Breakpad crash reporter support for OS X (default enabled on Mac OS X)])
3879 if test "x${enable_breakpad}" != "xno" -a "${HAVE_OSX}" = "1"
3880 then
3881   if test ! -d ${CONTRIB_DIR}/Breakpad.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework
3882   then
3883     AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3884   fi
3885
3886   AC_DEFINE([HAVE_BREAKPAD], [1], [Define to 1 if breakpad is enabled.])
3887 fi
3888 AM_CONDITIONAL(HAVE_BREAKPAD, [test "$enable_breakpad" != "no"])
3889
3890
3891 dnl
3892 dnl  Minimal Mac OS X module
3893 dnl
3894 AC_ARG_ENABLE(minimal-macosx,
3895   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3896 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3897 then
3898   VLC_ADD_PLUGIN([minimal_macosx])
3899 fi
3900
3901 dnl
3902 dnl Mac OS X fancy dmg build tool
3903 dnl
3904 if test "${HAVE_OSX}" = "1"
3905 then
3906   AC_PATH_PROG(DMGBUILD, dmgbuild, no)
3907   AS_IF([test "x${DMGBUILD}" = "xno"], [
3908     AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
3909   ])
3910 fi
3911 AM_CONDITIONAL(HAVE_DMGBUILD, [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
3912
3913 dnl
3914 dnl  VideoToolbox plugins
3915 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3916     VLC_ADD_PLUGIN([videotoolbox])
3917     VLC_ADD_PLUGIN([cvpx])
3918   ])
3919
3920 dnl
3921 dnl  ncurses module
3922 dnl
3923 AC_ARG_ENABLE(ncurses,
3924 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3925 have_ncurses="no"
3926 AS_IF([test "${enable_ncurses}" != "no"] ,[
3927   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3928     have_ncurses="yes"
3929     ALIASES="${ALIASES} nvlc"
3930   ], [
3931     AS_IF([test -n "${enable_ncurses}"], [
3932       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3933     ])
3934   ])
3935 ])
3936 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3937
3938 dnl
3939 dnl  Lirc plugin
3940 dnl
3941 AC_ARG_ENABLE(lirc,
3942   [  --enable-lirc           lirc support (default disabled)])
3943 have_lirc="no"
3944 AS_IF([test "${enable_lirc}" = "yes"], [
3945   AC_CHECK_HEADER(lirc/lirc_client.h, [
3946     AC_CHECK_LIB(lirc_client, lirc_init, [
3947       have_lirc="yes"
3948     ])
3949   ])
3950 ])
3951 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3952
3953 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3954 dnl
3955 dnl  goom visualization plugin
3956 dnl
3957 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3958
3959 dnl
3960 dnl libprojectM visualization plugin
3961 dnl
3962 AC_ARG_ENABLE(projectm,
3963   [  --enable-projectm       projectM visualization plugin (default enabled)])
3964 AS_IF([test "${enable_projectm}" != "no"],
3965   [
3966     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3967     [
3968       VLC_ADD_PLUGIN([projectm])
3969       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3970         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3971         [ AC_MSG_WARN( [Using libprojectM version 1] )
3972       ])
3973     ],[
3974       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3975     ])
3976   ])
3977
3978 dnl
3979 dnl Vovoid VSXu visualization plugin
3980 dnl
3981 AC_ARG_ENABLE(vsxu,
3982   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3983 AS_IF([test "${enable_vsxu}" != "no"],
3984   [
3985     PKG_CHECK_MODULES(VSXU, libvsxu,
3986     [
3987       VLC_ADD_PLUGIN([vsxu])
3988     ],[
3989       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3990     ])
3991   ])
3992
3993 EXTEND_HELP_STRING([Service Discovery plugins:])
3994 dnl
3995 dnl  Avahi-Zeroconf services discovery
3996 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
3997
3998 dnl
3999 dnl  libudev services discovery
4000 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
4001
4002 dnl
4003 dnl MTP devices services discovery
4004 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
4005
4006 dnl
4007 dnl UPnP Plugin (Intel SDK)
4008 dnl
4009 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
4010
4011 dnl
4012 dnl mDNS using libmicrodns
4013 dnl
4014 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
4015
4016
4017 EXTEND_HELP_STRING([Misc options:])
4018
4019 dnl
4020 dnl  libxml2 module
4021 dnl
4022 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4023
4024
4025 dnl
4026 dnl libgcrypt
4027 dnl
4028 AC_ARG_ENABLE(libgcrypt,
4029   [  --disable-libgcrypt     gcrypt support (default enabled)])
4030 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
4031 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4032
4033 # require libgcrypt >= 1.6.0
4034 AS_IF([test "${enable_libgcrypt}" != "no"], [
4035   AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4036     VLC_SAVE_FLAGS
4037     CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4038     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4039 [#include <gcrypt.h>
4040 #if GCRYPT_VERSION_NUMBER < 0x010600
4041 #error
4042 #endif]])], [
4043       ac_cv_lib_gcrypt=yes
4044     ], [
4045       ac_cv_lib_gcrypt=no
4046     ])
4047     VLC_RESTORE_FLAGS
4048   ])
4049
4050   AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4051     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4052   ], [
4053     AS_IF([test "${enable_libgcrypt}" = "yes"], [
4054       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4055     ])
4056   ])
4057 ])
4058
4059 AS_IF([test -z "$GCRYPT_LIBS"], [
4060   GCRYPT_LIBS="-lgcrypt -lgpg-error"
4061 ])
4062
4063 AC_SUBST(GCRYPT_CFLAGS)
4064 AC_SUBST(GCRYPT_LIBS)
4065 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4066
4067 dnl
4068 dnl TLS/SSL
4069 dnl
4070 AC_ARG_ENABLE(gnutls,
4071   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4072 AS_IF([test "${enable_gnutls}" != "no"], [
4073   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4074     VLC_ADD_PLUGIN([gnutls])
4075   ], [
4076     AS_IF([test -n "${enable_gnutls}"], [
4077       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4078     ])
4079   ])
4080 ])
4081
4082
4083 dnl
4084 dnl Taglib plugin
4085 dnl
4086 AC_ARG_ENABLE(taglib,
4087   [AS_HELP_STRING([--disable-taglib],
4088     [do not use TagLib (default enabled)])])
4089 AS_IF([test "${enable_taglib}" != "no"], [
4090   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4091     VLC_ADD_PLUGIN([taglib])
4092   ], [
4093     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4094 ])
4095
4096 dnl
4097 dnl  libsecret
4098 dnl
4099 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4100
4101 dnl
4102 dnl  kwallet
4103 dnl
4104 AC_ARG_ENABLE(kwallet,
4105   [AS_HELP_STRING([--enable-kwallet],
4106     [use kwallet (via D-Bus) for keystore (default enabled)])])
4107 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4108   VLC_ADD_PLUGIN([kwallet])
4109 ])
4110
4111 dnl
4112 dnl  Developers helper modules (should be hidden from configure help)
4113 dnl
4114 AC_ARG_ENABLE(devtools, [], [], [enable_devtools="no"])
4115 AS_IF([test "${enable_devtools}" != "no"], [
4116   VLC_ADD_PLUGIN([accesstweaks])
4117 ])
4118
4119 dnl
4120 dnl update checking system
4121 dnl
4122 AC_ARG_ENABLE(update-check,
4123   [  --enable-update-check   update checking system (default disabled)])
4124 if test "${enable_update_check}" = "yes"
4125 then
4126  AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4127     AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4128 fi
4129 AM_CONDITIONAL(UPDATE_CHECK, [test "${enable_update_check}" = "yes"])
4130
4131 dnl
4132 dnl OS X notification plugin
4133 dnl
4134 AC_ARG_ENABLE(osx_notifications,
4135   [  --enable-osx-notifications          osx notification plugin (default disabled)],,
4136   [enable_osx_notifications=no])
4137 AS_IF([test "${enable_osx_notifications}" != "no"], [
4138   if test -d ${CONTRIB_DIR}/Growl.framework -o -d ${CONTRIB_DIR}/Frameworks/Growl.framework
4139   then
4140       VLC_ADD_PLUGIN([osx_notifications])
4141       VLC_ADD_LIBS([osx_notifications], [-Wl,-framework,Growl,-framework,Foundation])
4142       VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4143   fi
4144 ])
4145
4146 dnl
4147 dnl Libnotify notification plugin
4148 dnl
4149 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4150
4151 dnl
4152 dnl  Endianness check
4153 dnl
4154 AC_C_BIGENDIAN
4155 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4156   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4157 ], [
4158   DEFS_BIGENDIAN=""
4159 ])
4160 AC_SUBST(DEFS_BIGENDIAN)
4161
4162 dnl
4163 dnl Where to install KDE solid .desktop
4164 dnl
4165 AC_ARG_WITH(kde-solid,
4166   AS_HELP_STRING([--with-kde-solid=PATH],
4167                  [KDE Solid actions directory (auto)]),, [
4168
4169 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4170   with_kde_solid="yes"
4171 fi
4172 ])
4173 soliddatadir=""
4174 AS_IF([test "${with_kde_solid}" != "no"], [
4175   AS_IF([test "${with_kde_solid}" = "yes"], [
4176     kde4datadir="`${KDE4_CONFIG} --install data`"
4177     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4178     soliddatadir="${kde4datadir}/solid/actions"
4179   ], [
4180     soliddatadir="${with_kde_solid}"
4181   ])
4182 ])
4183 AC_SUBST(soliddatadir)
4184 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4185
4186 dnl
4187 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4188 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4189 dnl
4190 if test "${SYS}" = "mingw32"; then
4191     AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4192 fi
4193
4194 EXTEND_HELP_STRING([Components:])
4195
4196 dnl
4197 dnl  the VLC binary
4198 dnl
4199 AC_ARG_ENABLE(vlc,
4200   [  --enable-vlc            build the VLC media player (default enabled)])
4201 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4202
4203 dnl
4204 dnl  Stuff used by the program
4205 dnl
4206 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4207 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4208 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4209 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4210 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4211 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4212 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4213 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4214 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4215 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4216 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4217 AC_SUBST(COPYRIGHT_MESSAGE)
4218 AC_SUBST(VERSION_MESSAGE)
4219 AC_SUBST(VERSION_MAJOR)
4220 AC_SUBST(VERSION_MINOR)
4221 AC_SUBST(VERSION_REVISION)
4222 AC_SUBST(VERSION_EXTRA)
4223 AC_SUBST(COPYRIGHT_YEARS)
4224 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4225 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4226 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4227 dnl
4228 dnl  Handle substvars that use $(top_srcdir)
4229 dnl
4230 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4231
4232 dnl
4233 dnl  Configuration is finished
4234 dnl
4235 AC_SUBST(SYS)
4236 AC_SUBST(ARCH)
4237 AC_SUBST(ALIASES)
4238 AC_SUBST(ASM)
4239 AC_SUBST(MOC)
4240 AC_SUBST(RCC)
4241 AC_SUBST(UIC)
4242 AC_SUBST(WINDRES)
4243 AC_SUBST(WINE_SDK_PATH)
4244 AC_SUBST(LIBEXT)
4245 AC_SUBST(AM_CPPFLAGS)
4246 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4247 AC_SUBST(FILE_LIBVLCCORE_DLL)
4248 AC_SUBST(FILE_LIBVLC_DLL)
4249
4250 AC_CONFIG_FILES([
4251   Makefile
4252   doc/Makefile
4253   modules/Makefile
4254   m4/Makefile
4255   po/Makefile.in
4256   share/Makefile
4257   compat/Makefile
4258   src/Makefile
4259   lib/Makefile
4260   bin/Makefile
4261   test/Makefile
4262   modules/hw/mmal/Makefile
4263   share/vlc.appdata.xml.in
4264 ])
4265
4266 AM_COND_IF([HAVE_WIN32], [
4267   AC_CONFIG_FILES([
4268     extras/package/win32/NSIS/spad.nsi
4269     extras/package/win32/NSIS/vlc.win32.nsi
4270     extras/package/win32/msi/config.wxi
4271   ])
4272 ])
4273
4274 AM_COND_IF([HAVE_DARWIN], [
4275   AC_CONFIG_FILES([
4276     modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4277     share/macosx/Info.plist:share/Info.plist.in
4278   ])
4279 ])
4280
4281 dnl Generate makefiles
4282 AC_OUTPUT
4283
4284 dnl Do we have to use make or gmake ?
4285 if make --version 2>&1|grep -q GNU
4286 then
4287     # GNU make, all seems good
4288     MAKE=make
4289 else
4290     # Known GNU make alias (on BSD)
4291     MAKE=gmake
4292 fi
4293 dnl Shortcut to nice compile message
4294 if test -n $SHELL; then
4295   SHELL=${CONFIG_SHELL-/bin/sh}
4296 fi
4297 rm -f compile
4298 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4299 echo "#! $SHELL
4300 rm -f .error\$\$
4301 ERROR=0
4302 export PATH=\"$PATH\" LANG=C
4303 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4304 test -f .error\$\$ && ERROR=1
4305 rm -f .error\$\$
4306 exit \$ERROR" >compile
4307 chmod a+x compile
4308
4309 echo "
4310 libvlc configuration
4311 --------------------
4312 version               : ${VERSION}
4313 system                : ${SYS}
4314 architecture          : ${ARCH}
4315 optimizations         : ${enable_optimizations}"
4316 if test "${enable_vlc}" != "no"; then
4317 echo "vlc aliases           :${ALIASES}"
4318 else
4319 echo "build vlc executable  : no"
4320 fi
4321 echo "
4322 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."