configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 1999-2019 VLC authors and VideoLAN])
   4
   5 AC_INIT([vlc], [4.0.0-dev])
   6 VERSION_MAJOR=4
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=dev
  11
  12 PKGDIR="vlc"
  13 AC_SUBST([PKGDIR])
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Otto Chriek"
  17 COPYRIGHT_YEARS="1996-2019"
  18
  19 AC_CONFIG_SRCDIR([src/libvlc.c])
  20 AC_CONFIG_AUX_DIR([autotools])
  21 AC_CONFIG_MACRO_DIR([m4])
  22 AC_CONFIG_LIBOBJ_DIR([compat])
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE([tar-ustar color-tests foreign])
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 AM_SILENT_RULES([yes])
  31 AM_MAINTAINER_MODE([enable])
  32
  33 dnl
  34 dnl Check for tools
  35 dnl
  36 AC_PROG_CC
  37 AC_USE_SYSTEM_EXTENSIONS
  38 VLC_PROG_CC_C11
  39 AH_VERBATIM([FORTIFY_SOURCE],
  40   [/* Enable compile-time and run-time bounds-checking, and some warnings,
  41    without upsetting glibc 2.15+ or toolchains predefining _FORTIFY_SOURCE */
  42 #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
  43 # define _FORTIFY_SOURCE 2
  44 #endif])
  45 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  46 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  47 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  48
  49 AC_PROG_CXX
  50 AC_PROG_CPP
  51 AC_PROG_OBJC
  52 AC_PROG_EGREP
  53 AC_PROG_MAKE_SET
  54 AC_PROG_INSTALL
  55 AM_PROG_AS
  56 AC_PROG_LEX
  57 AC_PROG_YACC
  58
  59 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  60 AC_CHECK_PROGS([DESKTOP_FILE_VALIDATE], [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  61 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
  62 AC_CHECK_PROGS([BUILDCC], [c11-gcc c11 c99-gcc c99], [false])
  63 AS_IF([test "$BUILDCC" = "false"], [
  64   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
  65 ])
  66
  67 dnl Check for compiler properties
  68 AC_C_CONST
  69 AC_C_INLINE
  70 AC_C_RESTRICT
  71 AX_CXX_COMPILE_STDCXX_11([noext], [mandatory])
  72
  73 dnl Extend the --help string at the current spot.
  74 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  75
  76 dnl Allow binary package maintainer to pass a custom string to avoid
  77 dnl cache problem
  78 AC_ARG_WITH([binary-version],
  79     AS_HELP_STRING([--with-binary-version=STRING],
  80          [To avoid plugins cache problem between binary version]),[],[])
  81 AS_IF([test -n "${with_binary_version}"],[
  82     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  83          [Binary specific version])
  84 ])
  85
  86 dnl Prevent clang from accepting unknown flags with a mere warning
  87 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CFLAGS])
  88 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CXXFLAGS])
  89
  90 dnl
  91 dnl  Check the operating system
  92 dnl
  93 HAVE_WIN64="0"
  94 HAVE_IOS="0"
  95 HAVE_OSX="0"
  96 HAVE_TVOS="0"
  97
  98 dnl  Set x86 asm flags and defines
  99 X86ASMFLAGS=""
 100 case "${host_cpu}" in
 101     i?86)
 102     X86ASMFLAGS="-f elf32"
 103     X86ASMDEFS="-DARCH_X86_32=1 -DARCH_X86_64=0"
 104         ;;
 105     x86_64)
 106     X86ASMFLAGS="-f elf64"
 107     X86ASMDEFS="-DARCH_X86_32=0 -DARCH_X86_64=1"
 108         ;;
 109 esac
 110
 111 case "${host_os}" in
 112   "")
 113     SYS=unknown
 114     ;;
 115   linux*)
 116     SYS=linux
 117     CFLAGS="${CFLAGS} -pthread"
 118     ;;
 119   bsdi*)
 120     SYS=bsdi
 121     CFLAGS="${CFLAGS} -pthread"
 122     ;;
 123   freebsd*)
 124     SYS=freebsd
 125     CFLAGS="${CFLAGS} -pthread"
 126     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 127     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 128     ac_cv_ld_z_defs=no
 129     ;;
 130   openbsd*)
 131     SYS=openbsd
 132     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 133     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 134     ;;
 135   netbsd*)
 136     SYS=netbsd
 137     ;;
 138   dragonfly*)
 139     SYS=dragonfly
 140     ;;
 141   darwin*)
 142
 143     dnl Force gcc "-arch" flag
 144     ARCH_flag=""
 145     case "${host_cpu}" in
 146       i?86)
 147         ARCH_flag="-arch i386"
 148         X86ASMFLAGS="-f macho32"
 149         X86ASMDEFS="${X86ASMDEFS} -DPREFIX"
 150       ;;
 151       ppc64*)
 152         ARCH_flag="-arch ppc64"
 153       ;;
 154       ppc*)
 155         ARCH_flag="-arch ppc"
 156       ;;
 157       x86_64)
 158         ARCH_flag="-arch x86_64"
 159         X86ASMFLAGS="-f macho64"
 160         X86ASMDEFS="${X86ASMDEFS} -DPREFIX"
 161       ;;
 162       arm*)
 163         ac_cv_c_bigendian="no"
 164         ac_cv_c_attribute_packed="no"
 165       ;;
 166     esac
 167
 168     SYS=darwin
 169     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 170     CXX="${CXX} -stdlib=libc++ -std=c++11"
 171     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 172     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 173     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
 174     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 175     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 176     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 177
 178     AC_EGREP_CPP(yes,
 179             [#import <TargetConditionals.h>
 180              #if TARGET_OS_IPHONE
 181              yes
 182              #endif],
 183              [HAVE_IOS="1"],
 184              [HAVE_OSX="1"])
 185
 186     AC_EGREP_CPP(yes,
 187             [#import <TargetConditionals.h>
 188              #if TARGET_OS_TV
 189              yes
 190              #endif],
 191              [HAVE_TVOS="1"
 192              HAVE_IOS="0"
 193              HAVE_OSX="0"
 194              ],)
 195
 196     dnl
 197     dnl  Handle Mac OS X SDK flags
 198     dnl
 199     AC_ARG_WITH(macosx-sdk,
 200       AS_HELP_STRING([--with-macosx-sdk=DIR],
 201         [compile using the SDK in DIR]))
 202     if test "${with_macosx_sdk}" != "" ; then
 203         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 204         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 205         CC="${CC} -isysroot ${with_macosx_sdk}"
 206         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 207         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 208         LD="${LD} -syslibroot ${with_macosx_sdk}"
 209     fi
 210     AC_ARG_WITH(macosx-version-min,
 211       AS_HELP_STRING([--with-macosx-version-min=VERSION],
 212         [compile for Mac OS X VERSION and above]))
 213     if test "${with_macosx_version_min}" != "" ; then
 214         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 215         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 216         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 217         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 218         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 219     fi
 220     ;;
 221   *mingw32* | *cygwin* | *wince* | *mingwce*)
 222     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
 223     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
 224     CXXFLAGS="${CXXFLAGS} -static-libgcc"
 225     AC_CHECK_TOOL(WINDRES, windres, :)
 226     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 227     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 228       [[#ifdef _WIN32_WINNT
 229        # error _WIN32_WINNT already defined
 230        #endif
 231       ]],[[;]])
 232     ],[
 233       AC_DEFINE([_WIN32_WINNT], 0x0601, [Define to '0x0601' for Windows 7 APIs.])
 234     ])
 235     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 236     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 237     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 238     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 239     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 240     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 241     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 242     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 243     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 244     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 245     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 246
 247     case "${host_os}" in
 248       *mingw32*)
 249         SYS=mingw32
 250         ;;
 251       *cygwin*)
 252         dnl Check if we are using the mno-cygwin mode in which case we are
 253         dnl actually dealing with a mingw32 compiler.
 254         AC_EGREP_CPP(yes,
 255             [#ifdef _WIN32
 256              yes
 257              #endif],
 258             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 259         ;;
 260     esac
 261
 262     if test "${SYS}" = "mingw32"; then
 263         # DEP, ASLR, NO SEH
 264         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 265
 266         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 267         ac_default_prefix="`pwd`/_win32"
 268         DESTDIR="`pwd`/_win32/"
 269
 270         dnl
 271         dnl NSIS/MSI Installer prefix and WIN64
 272         dnl
 273         case "${host_cpu}" in
 274             aarch64)
 275                 HAVE_WIN64="1"
 276                 WINDOWS_ARCH="arm64"
 277                 PROGRAMFILES="PROGRAMFILES64"
 278                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
 279             ;;
 280             amd64|x86_64)
 281                 HAVE_WIN64="1"
 282                 WINDOWS_ARCH="x64"
 283                 PROGRAMFILES="PROGRAMFILES64"
 284                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
 285                 X86ASMFLAGS="-f win64"
 286             ;;
 287             armv7)
 288                 WINDOWS_ARCH="arm"
 289                 PROGRAMFILES="PROGRAMFILES"
 290             ;;
 291             *)
 292                 WINDOWS_ARCH="x86"
 293                 PROGRAMFILES="PROGRAMFILES"
 294                 X86ASMFLAGS="-f win32"
 295                 X86ASMDEFS="${X86ASMDEFS} -DPREFIX"
 296             ;;
 297         esac
 298         AC_SUBST([WINDOWS_ARCH])
 299         AC_SUBST([PROGRAMFILES])
 300
 301     fi
 302     ;;
 303   *nto*)
 304     SYS=nto
 305     ;;
 306   solaris*)
 307     SYS=solaris
 308     ;;
 309   hpux*)
 310     SYS=hpux
 311     ;;
 312   *os2*)
 313     SYS=os2
 314     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 315     AC_LIBOBJ([freeaddrinfo])
 316     AC_LIBOBJ([gai_strerror])
 317     AC_CHECK_FUNCS([if_nametoindex])
 318     ;;
 319   *nacl*)
 320     SYS=nacl
 321     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 322     AC_LIBOBJ([sigwait])
 323     AC_LIBOBJ([recvmsg])
 324     AC_LIBOBJ([sendmsg])
 325     ;;
 326   *)
 327     SYS="${host_os}"
 328     ;;
 329 esac
 330
 331 dnl WinRT
 332 AC_ARG_ENABLE([winstore_app],
 333      AS_HELP_STRING([--enable-winstore-app],
 334                     [Build targetted for Windows Store apps (default disabled)]))
 335
 336 vlc_winstore_app=0
 337 AS_IF([test "${SYS}" = "mingw32"],[
 338   LIBCOM="-lole32"
 339   AS_IF([test "${enable_winstore_app}" = "yes"], [
 340     vlc_winstore_app=1
 341     LIBCOM=""
 342      VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
 343      AC_LIBOBJ([gai_strerror])
 344     ],[])
 345   AC_SUBST([LIBCOM])
 346   ])
 347 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 348
 349 AM_CONDITIONAL([HAVE_LINUX],   [test "${SYS}" = "linux"])
 350 AM_CONDITIONAL([HAVE_OS2],     [test "${SYS}" = "os2"])
 351
 352 AM_CONDITIONAL([HAVE_DARWIN],  [test "${SYS}" = "darwin"])
 353 AM_CONDITIONAL([HAVE_IOS],     [test "${HAVE_IOS}" = "1"])
 354 AM_CONDITIONAL([HAVE_OSX],     [test "${HAVE_OSX}" = "1"])
 355 AM_CONDITIONAL([HAVE_TVOS],    [test "${HAVE_TVOS}" = "1"])
 356
 357 AM_CONDITIONAL([HAVE_NACL],    [test "${SYS}" = "nacl"])
 358 AM_CONDITIONAL([HAVE_LIBANL],  [test "${HAVE_LIBANL}" = "1"])
 359
 360 AM_CONDITIONAL([HAVE_WIN32],   [test "${SYS}" = "mingw32"])
 361 AM_CONDITIONAL([HAVE_WIN64],   [test "${HAVE_WIN64}" = "1"]) dnl Only used for the packaging
 362 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 363 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
 364
 365 dnl Use nasm/yasm only on x86
 366 AC_CHECK_PROGS(X86ASM, [nasm yasm])
 367 AM_CONDITIONAL([HAVE_X86ASM], [test -n "${X86ASM}" && test -n "${X86ASMFLAGS}"])
 368 AM_COND_IF([HAVE_X86ASM], [
 369   AC_DEFINE([HAVE_X86ASM], [1], [Use external asm on x86.])
 370 ])
 371 AC_SUBST([X86ASMFLAGS])
 372 AC_SUBST([X86ASMDEFS])
 373
 374 dnl
 375 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 376 dnl for program foo on win32
 377 case "${build_os}" in
 378     cygwin|msys|mingw32)
 379         ac_executable_extensions=".exe"
 380         BUILDEXEEXT=".exe"
 381     ;;
 382     os2*)
 383         BUILDEXEEXT=".exe"
 384     ;;
 385     *)
 386     ;;
 387 esac
 388 AC_SUBST([BUILDEXEEXT])
 389
 390 dnl Android is linux, but a bit different
 391 AS_IF([test "$SYS" = linux],[
 392     AC_MSG_CHECKING([for an Android system])
 393     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 394         [[#ifndef __ANDROID__
 395          # error Not Android
 396          #endif
 397         ]],[[;]])
 398     ],[
 399       HAVE_ANDROID="1"
 400       AC_MSG_RESULT([yes])
 401     ],[
 402       AC_MSG_RESULT([no])
 403     ])
 404 ])
 405 AM_CONDITIONAL([HAVE_ANDROID], [test "${HAVE_ANDROID}" = "1"])
 406
 407 dnl Tizen (minimum SDK version: 2.3)
 408 AS_IF([test "$SYS" = linux],[
 409     AC_MSG_CHECKING([for Tizen])
 410     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 411         [[#include <tizen.h>
 412         ]],[[;]])
 413     ],[
 414       HAVE_TIZEN="1"
 415       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
 416       AC_MSG_RESULT([yes])
 417     ],[
 418       AC_MSG_RESULT([no])
 419     ])
 420 ])
 421 AM_CONDITIONAL([HAVE_TIZEN], [test "${HAVE_TIZEN}" = "1"])
 422
 423 dnl
 424 dnl  Check for the contrib directory
 425 dnl
 426 AC_ARG_WITH(contrib,
 427   AS_HELP_STRING([--with-contrib[=DIR]],
 428     [search for 3rd party libraries in DIR/include and DIR/lib])
 429 )
 430 AC_MSG_CHECKING([for 3rd party libraries path])
 431 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 432   CONTRIB_DIR="${srcdir}/contrib/${host}"
 433   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 434     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 435     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 436     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 437       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 438       CONTRIB_DIR=""
 439       AC_MSG_RESULT([not found])
 440     ])
 441   ])
 442 ], [
 443   AS_IF([test "${with_contrib}" != "no"], [
 444     CONTRIB_DIR="${with_contrib}"
 445   ], [
 446     CONTRIB_DIR=""
 447     AC_MSG_RESULT([disabled])
 448   ])
 449 ])
 450 AS_IF([test -n "${CONTRIB_DIR}"], [
 451   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 452     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 453   ], [
 454     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 455     CONTRIB_DIR=""
 456     AC_MSG_RESULT([not usable])
 457   ])
 458
 459 ])
 460 AS_IF([test -n "${CONTRIB_DIR}"], [
 461   AC_MSG_RESULT([${CONTRIB_DIR}])
 462   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 463   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 464   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 465   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
 466   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:${CONTRIB_DIR}/share/pkgconfig:$PKG_CONFIG_PATH"
 467   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 468
 469   AS_IF([test -z "$LUAC"], [
 470     dnl Old contribs mixed cross-tools and cross-compiled executables
 471     AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
 472       LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
 473     ])
 474
 475     dnl Newer contribs follow usual name space rules
 476     AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
 477       LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
 478     ])
 479   ])
 480
 481   AS_IF([test "${SYS}" = "darwin"], [
 482     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 483     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 484   ])
 485 ], [
 486   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 487     AC_MSG_ERROR([Third party libraries not found!])
 488   ])
 489 ])
 490 AC_SUBST([CONTRIB_DIR])
 491
 492 dnl Add extras/tools to the PATH
 493 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 494 AS_IF([test -d "${TOOLS_DIR}"], [
 495     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 496     export PATH="${TOOLS_DIR}":$PATH
 497 ])
 498
 499 dnl
 500 dnl  Libtool
 501 dnl  It's very bad, but our former custom system was worst
 502 dnl  -- Courmisch
 503 dnl
 504
 505 dnl override platform specific check for dependent libraries
 506 dnl otherwise libtool linking of shared libraries will
 507 dnl fail on anything other than pass_all.
 508 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 509     [lt_cv_deplibs_check_method=pass_all])
 510
 511 LT_INIT([dlopen win32-dll shared disable-static])
 512 LT_LANG([C++])
 513 LT_LANG([Windows Resource])
 514
 515 DOLT
 516
 517 lt_cv_deplibs_check_method=pass_all
 518
 519 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 520   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 521 ])
 522
 523 dnl
 524 dnl Gettext stuff
 525 dnl
 526 AM_GNU_GETTEXT_VERSION([0.19.8])
 527 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 528
 529 dnl
 530 dnl Iconv stuff
 531 dnl
 532 AM_ICONV
 533
 534 dnl
 535 dnl checks for mingw
 536 AS_IF([test "${SYS}" = "mingw32"], [
 537
 538 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 539 #if !defined(__MINGW32__)
 540 # error Not compiling with mingw
 541 #endif
 542     ])], [
 543
 544 dnl Check for broken versions of mingw-runtime compatability library
 545     AC_MSG_CHECKING(for broken mingw-runtime)
 546     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 547 #include <_mingw.h>
 548 #if defined(__MINGW64_VERSION_MAJOR)
 549 # if __MINGW64_VERSION_MAJOR < 5
 550 #  error Update your mingw-w64! This one is too old.
 551 # endif
 552 #else
 553 # error You cannot compile with Mingw. Use Mingw-w64!
 554 #endif
 555     ])], [
 556         AC_MSG_RESULT([ok])
 557     ], [
 558         AC_MSG_RESULT([present])
 559         AC_MSG_ERROR([LibVLC requires Mingw-w64 version 5.0 or higher!])
 560     ])
 561
 562     dnl force use of mingw provided c99 *printf over msvcrt
 563     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 564
 565     dnl Check for the need to include the mingwex lib for mingw32
 566     VLC_SAVE_FLAGS
 567     AC_CHECK_LIB([mingwex], [opendir],
 568         AC_CHECK_LIB([mingw32], [opendir],,
 569             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 570     )
 571     VLC_RESTORE_FLAGS
 572     ], [
 573         AC_MSG_RESULT([Not compiling with mingw])
 574     ])
 575
 576     dnl Check for fnative-struct or mms-bitfields support for mingw32
 577     AX_CHECK_COMPILE_FLAG([-mms-bitfields], [
 578         AX_APPEND_FLAG([-mms-bitfields], [CFLAGS])
 579         AX_APPEND_FLAG([-mms-bitfields], [CXXFLAGS])
 580         # Check for the warning flag without "-Wno-", GCC accepts
 581         # -Wno-<anything> for unsupported warnings, which can trigger
 582         # other warnings instead.
 583         AX_CHECK_COMPILE_FLAG([-Wincompatible-ms-struct], [
 584             AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CFLAGS])
 585             AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CXXFLAGS])
 586         ])
 587     ], [
 588         AX_CHECK_COMPILE_FLAG([-fnative-struct], [
 589             AX_APPEND_FLAG([-fnative-struct], [CFLAGS])
 590             AX_APPEND_FLAG([-fnative-struct], [CXXFLAGS])
 591         ])
 592     ])
 593 ])
 594
 595
 596 dnl
 597 dnl Buggy glibc prevention. Purposedly not cached.
 598 dnl See sourceware.org bugs 5058 and 5443.
 599 dnl Ubuntu alone has 20 bug numbers for this...
 600 dnl
 601 AC_MSG_CHECKING(for buggy GNU/libc versions)
 602 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 603 #include <limits.h>
 604 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 605   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 606 # error GNU/libc with dcgettext killer bug!
 607 #endif
 608 ])], [
 609   AC_MSG_RESULT([not present])
 610 ], [
 611   AC_MSG_RESULT([found])
 612   AS_IF([test "x${enable_nls}" != "xno"], [
 613     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 614 work-around for this. Check with your distribution vendor on how to update the
 615 glibc run-time. Alternatively, build with --disable-nls.])
 616   ])
 617 ])
 618
 619 dnl Plugin compilation stuff
 620
 621 VLC_LIBRARY_SUFFIX
 622
 623 dnl Check for system libs needed
 624 need_libc=false
 625
 626 dnl Check for usual libc functions
 627 AC_CHECK_FUNCS([accept4 daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty memalign mkostemp mmap open_memstream newlocale openat pipe2 pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp strptime uselocale])
 628 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir flockfile fsync getdelim getpid lfind lldiv memrchr nrand48 poll recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tdestroy tfind timegm timespec_get strverscmp pathconf])
 629 AC_REPLACE_FUNCS([gettimeofday])
 630 AC_CHECK_FUNC(fdatasync,,
 631   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 632 ])
 633
 634 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
 635
 636 dnl mingw64 implements those as static inline, not functions with C linkage
 637 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
 638 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
 639 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
 640 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
 641
 642 dnl C11 static_assert()
 643 AC_MSG_CHECKING([for static_assert in assert.h])
 644 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 645 static_assert(1, "The impossible happened.");
 646 ])], [
 647   AC_MSG_RESULT([yes])
 648   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 649 ], [
 650   AC_MSG_RESULT([no])
 651 ])
 652
 653 # Windows CE does not have strcoll()
 654 AC_FUNC_STRCOLL
 655
 656 dnl Check for non-standard system calls
 657 case "$SYS" in
 658   "linux")
 659     AC_CHECK_FUNCS([eventfd vmsplice sched_getaffinity recvmmsg memfd_create])
 660     ;;
 661   "mingw32")
 662     AC_CHECK_FUNCS([_lock_file])
 663     ;;
 664 esac
 665
 666 AH_BOTTOM([#include <vlc_fixups.h>])
 667
 668 dnl Check for struct pollfd
 669 AC_CHECK_TYPES([struct pollfd],,,
 670 [#include <sys/types.h>
 671 #if HAVE_POLL
 672 # include <poll.h>
 673 #elif defined (_WIN32)
 674 # include <winsock2.h>
 675 #endif
 676 ])
 677
 678 dnl Check for struct timespec
 679 AC_CHECK_TYPES([struct timespec],,,
 680 [#include <time.h>])
 681
 682 dnl Check for max_align_t
 683 AC_CHECK_TYPES([max_align_t],,,
 684 [#include <stddef.h>])
 685
 686 dnl Checks for socket stuff
 687 VLC_SAVE_FLAGS
 688 SOCKET_LIBS=""
 689 AC_SEARCH_LIBS(connect, [socket], [
 690   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 691     SOCKET_LIBS="$ac_cv_search_connect"
 692   ])
 693 ], [
 694   AS_IF([test "${SYS}" = "mingw32"], [
 695     SOCKET_LIBS="-lws2_32 -liphlpapi"
 696   ])
 697 ])
 698
 699 AC_SEARCH_LIBS([inet_pton], [nsl], [
 700  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
 701     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
 702   ])
 703 ],, [${SOCKET_LIBS}])
 704
 705 LIBS="${LIBS} ${SOCKET_LIBS}"
 706 AC_LINK_IFELSE([
 707     AC_LANG_PROGRAM([#ifdef _WIN32
 708         #include <ws2tcpip.h>
 709         #include <windows.h>
 710         # if _WIN32_WINNT < 0x600
 711         #  error Needs vista+
 712         # endif
 713         #else
 714         #include <sys/socket.h>
 715         #include <arpa/inet.h>
 716         #endif], [
 717         char dst[[sizeof(struct in_addr)]];
 718         inet_pton(AF_INET, "127.0.0.1", dst);
 719     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 720 AC_CHECK_TYPES([struct if_nameindex],,,[#include <net/if.h>])
 721 AC_CHECK_FUNCS([if_nameindex])
 722 VLC_RESTORE_FLAGS
 723 AC_SUBST([SOCKET_LIBS])
 724
 725 dnl Check for socklen_t
 726 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 727 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 728 ac_cv_type_socklen_t,
 729 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 730 [#include <sys/types.h>
 731 #ifdef _WIN32
 732 # include <winsock2.h>
 733 # include <ws2tcpip.h>
 734 #else
 735 # include <sys/socket.h>
 736 #endif]], [[socklen_t len; len = 0;]])],
 737 ac_cv_type_socklen_t=yes,
 738 ac_cv_type_socklen_t=no)])
 739 AS_IF([test "$ac_cv_type_socklen_t" = no],
 740  [AC_DEFINE(socklen_t, int)])
 741
 742 dnl Check for struct sockaddr_storage
 743 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 744 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 745 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 746   [AC_TRY_COMPILE(
 747     [#include <sys/types.h>
 748      #if defined( _WIN32 )
 749      # include <winsock2.h>
 750      #else
 751      # include <sys/socket.h>
 752      #endif], [struct sockaddr_storage addr;],
 753      ac_cv_struct_sockaddr_storage=yes,
 754      ac_cv_struct_sockaddr_storage=no)])
 755 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 756   AC_DEFINE(sockaddr_storage, sockaddr)
 757   AC_DEFINE(ss_family, sa_family)
 758 ])
 759
 760 dnl FreeBSD has a gnugetopt library for this:
 761 GNUGETOPT_LIBS=""
 762 AC_CHECK_FUNC(getopt_long,, [
 763   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 764     GNUGETOPT_LIBS="-lgnugetopt"
 765   ])
 766 ])
 767 AC_SUBST([GNUGETOPT_LIBS])
 768
 769 AC_CHECK_LIB([m], [cos], [
 770   LIBM="-lm"
 771 ], [
 772   LIBM=""
 773 ])
 774 AC_SUBST([LIBM])
 775
 776 AC_CHECK_LIB([m], [lrintf], [
 777   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 778   VLC_ADD_LIBS([skins2],[-lm])
 779 ])
 780 AC_CHECK_LIB([m], [nanf],
 781   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 782 )
 783 AC_CHECK_LIB([m], [sincos], [
 784   AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
 785 ], [
 786   AC_LIBOBJ([sincos])
 787 ])
 788
 789 AC_MSG_CHECKING([broken qsort_r prototype])
 790 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <stdlib.h>
 791
 792 _Static_assert(_Generic((qsort_r),
 793     void (*)(void *, size_t, size_t, void *,
 794              int (*)(void *, const void *, const void *)) : 1, default: 0),
 795     "Bad prototype not matched");
 796 ])], [
 797   AC_MSG_RESULT([broken])
 798   AC_DEFINE([HAVE_BROKEN_QSORT_R], 1, [Defined to 1 if the qsort_r() prototype contradicts the upcoming POSIX standard.])
 799 ], [
 800   AC_MSG_RESULT([no])
 801 ])
 802
 803 AC_MSG_CHECKING([_Thread_local support])
 804 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
 805                    int main() {}])], [
 806     AC_MSG_RESULT([ok])
 807     AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
 808 ],[ AC_MSG_RESULT([no])])
 809
 810 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
 811 dnl check for its availability explicitely
 812 AC_CHECK_HEADERS([threads.h])
 813
 814 AC_CHECK_LIB([anl],[getaddrinfo_a],[
 815   AC_DEFINE(HAVE_LIBANL, 1, [Define to 1 if you have the anl library])
 816 ])
 817
 818 dnl Check for dynamic plugins
 819 LIBDL=""
 820 have_dynamic_objects="no"
 821 VLC_SAVE_FLAGS
 822 AC_SEARCH_LIBS(dlsym, [dl svld], [
 823   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 824     LIBDL="$ac_cv_search_dlsym"
 825   ])
 826   have_dynamic_objects="yes"
 827 ])
 828 VLC_RESTORE_FLAGS
 829
 830 # Windows
 831 AS_IF([test "${SYS}" = "mingw32"], [
 832   LIBDL=""
 833   have_dynamic_objects="yes" #assume we can use shared objects
 834 ])
 835
 836 AC_ARG_WITH([libfuzzer],
 837     AS_HELP_STRING([--with-libfuzzer=DIR],
 838         [use libFuzzer library from DIR and triggers sanitize coverage (default disabled)]),
 839      [],
 840      [with_libfuzzer=no])
 841 AS_VAR_IF(with_libfuzzer, no, [], [
 842     enable_shared=no
 843     enable_static=yes
 844     enable_vlc=no
 845 ])
 846 AM_CONDITIONAL([HAVE_LIBFUZZER], [test "${with_libfuzzer}" != "no"])
 847
 848 AS_IF([test "${enable_shared}" = "no"], [
 849   have_dynamic_objects=no
 850 ])
 851 AM_CONDITIONAL([HAVE_DYNAMIC_PLUGINS], [test "${have_dynamic_objects}" != "no"])
 852
 853 AC_SUBST([LIBDL])
 854
 855 AS_IF([test "${SYS}" != "mingw32"], [
 856   AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
 857     AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
 858       LIBRT="$ac_cv_search_clock_nanosleep"
 859     ])
 860   ], [
 861     AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
 862       AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
 863         LIBRT="$ac_cv_search_nanosleep"
 864       ])
 865     ])
 866   ])
 867 ])
 868 AC_SUBST([LIBRT])
 869
 870 dnl
 871 dnl Check for headers
 872 dnl
 873
 874 dnl  POSIX
 875 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
 876 AC_CHECK_HEADERS([net/if.h], [], [],
 877 [
 878 #include <sys/types.h>
 879 #include <sys/socket.h>
 880 ])
 881 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
 882 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
 883
 884 dnl  BSD
 885 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
 886
 887 dnl  GNU/Linux
 888 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 889
 890 dnl  MacOS
 891 AC_CHECK_HEADERS([xlocale.h])
 892
 893 dnl Check if C++ headers define locale_t
 894 AC_LANG_PUSH(C++)
 895 AC_CACHE_CHECK([if C++ headers define locale_t],
 896   [ac_cv_cxx_locale_t],
 897   [ac_cv_cxx_locale_t=no
 898    AC_TRY_COMPILE([#include <locale>], [locale_t loc;],
 899                     [ac_cv_cxx_locale_t=yes])])
 900 if test "${ac_cv_cxx_locale_t}" != "no"; then
 901   AC_DEFINE(HAVE_CXX_LOCALE_T, 1, Define to 1 if C++ headers define locale_t)
 902 fi
 903 AC_LANG_POP(C++)
 904
 905 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 906 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 907 AC_CHECK_TYPE(ssize_t,, [
 908   AC_DEFINE(ssize_t, int)
 909 ])
 910
 911 dnl It seems that autoconf detects pkg-config only during the first
 912 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 913 dnl it is nested within a conditional block, so it was not working right.
 914 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 915 AC_ARG_VAR(PKG_CONFIG_PATH,
 916        [Paths where to find .pc not at the default location])
 917 PKG_PROG_PKG_CONFIG()
 918
 919 dnl On some OS we need static linking
 920 AS_IF([test -n "${PKG_CONFIG}" ],[
 921     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 922         PKG_CONFIG="${PKG_CONFIG} --static"
 923     ])
 924 ])
 925
 926
 927 dnl
 928 dnl Check for zlib.h and -lz if available
 929 dnl
 930 AC_CHECK_HEADERS([zlib.h], [ have_zlib=yes ], [ have_zlib=no ])
 931 AM_CONDITIONAL([HAVE_ZLIB], [ test "${have_zlib}" = "yes" ])
 932 if test "${have_zlib}" = "yes"
 933 then
 934   VLC_ADD_LIBS([sap],[-lz])
 935 fi
 936
 937
 938 dnl
 939 dnl Domain name i18n support via GNU libidn
 940 dnl
 941 PKG_CHECK_MODULES([IDN], [libidn], [
 942   have_libidn="yes"
 943   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 944 ], [
 945   have_libidn="no"
 946 ])
 947
 948
 949 dnl Check for dbus
 950 AC_ARG_ENABLE([dbus],
 951   AS_HELP_STRING([--enable-dbus],
 952     [compile D-Bus message bus support (default enabled)]))
 953 have_dbus="no"
 954 AS_IF([test "${enable_dbus}" != "no"], [
 955   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 956     have_dbus="yes"
 957   ], [
 958     AS_IF([test -n "${enable_dbus}"], [
 959       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 960     ], [
 961       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 962     ])
 963   ])
 964 ])
 965 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 966
 967
 968 dnl Check for systemd
 969 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
 970   have_systemd="yes"
 971 ], [
 972   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
 973 ])
 974 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
 975
 976
 977 EXTEND_HELP_STRING([Optimization options:])
 978 dnl
 979 dnl  Compiler warnings
 980 dnl
 981
 982 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security -Wduplicated-branches -Wduplicated-cond], [CFLAGS])
 983 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security -Wduplicated-branches -Wduplicated-cond], [CXXFLAGS])
 984
 985 AX_APPEND_COMPILE_FLAGS([-Wbad-function-cast -Wwrite-strings -Wmissing-prototypes -Werror-implicit-function-declaration -Winit-self -Wlogical-op -Wshadow=local -Wmultistatement-macros], [CFLAGS])
 986 AX_APPEND_COMPILE_FLAGS([-pipe], [CFLAGS])
 987
 988 dnl
 989 dnl  Debugging mode
 990 dnl
 991 AC_ARG_ENABLE([debug],
 992   AS_HELP_STRING([--disable-debug],
 993     [disable run-time assertions (default enabled)]),,
 994   [enable_debug="yes"])
 995 AH_TEMPLATE(NDEBUG,
 996             [Define to 1 if debug code should NOT be compiled])
 997 AS_IF([test "${enable_debug}" != "no"], [
 998   AC_CHECK_HEADERS([valgrind/valgrind.h])
 999 ], [
1000   AC_DEFINE(NDEBUG)
1001 ])
1002
1003 dnl
1004 dnl  Profiling
1005 dnl
1006 AC_ARG_ENABLE([gprof],
1007   AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)]),,
1008   [enable_gprof="no"])
1009 AS_IF([test "${enable_gprof}" != "no"], [
1010   CFLAGS="${CFLAGS} -pg"
1011   CXXFLAGS="${CXXFLAGS} -pg"
1012   OBJCFLAGS="${OBJCFLAGS} -pg"
1013   LDFLAGS="${LDFLAGS} -pg"
1014 ])
1015
1016 AC_ARG_ENABLE([cprof],
1017   AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)]),,
1018   [enable_cprof="no"])
1019 AS_IF([test "${enable_gprof}" != "no"], [
1020   CFLAGS="${CFLAGS} -finstrument-functions"
1021   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
1022   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
1023   LDFLAGS="${LDFLAGS} -finstrument-functions"
1024 ])
1025
1026 dnl
1027 dnl  Test coverage
1028 dnl
1029 AC_ARG_ENABLE([coverage],
1030   AS_HELP_STRING([--enable-coverage],
1031     [build for test coverage (default disabled)]),,
1032   [enable_coverage="no"])
1033 AS_IF([test "${enable_coverage}" != "no"], [
1034   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
1035   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
1036   LDFLAGS="-lgcov ${LDFLAGS}"
1037 ])
1038
1039 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
1040   VLC_SAVE_FLAGS
1041   CFLAGS="${CFLAGS} -fvisibility=hidden"
1042   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
1043   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
1044   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
1045                  [ac_cv_c_visibility_hidden], [
1046     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1047       ac_cv_c_visibility_hidden=yes
1048     ], [
1049       ac_cv_c_visibility_hidden=no
1050     ])
1051   ])
1052   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1053 ])
1054
1055 dnl
1056 dnl Sanitizer flags
1057 dnl
1058 AC_ARG_WITH([sanitizer],
1059     AS_HELP_STRING([--with-sanitizer=(address/memory/undefined/thread)],
1060         [build with sanitizer flags (default disabled)]),
1061      [],
1062      [with_sanitizer=no])
1063
1064 AS_VAR_IF(with_sanitizer, no, [], [
1065     AX_CHECK_COMPILE_FLAG([-fsanitize=${with_sanitizer}], [
1066         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}])
1067         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [CXXFLAGS])
1068         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [LDFLAGS])
1069     ], [
1070         AC_MSG_ERROR(["-fsanitize=${with_sanitizer} not supported!"])
1071     ])
1072     AX_APPEND_FLAG([-g])
1073     AX_APPEND_FLAG([-g], [CXXFLAGS])
1074
1075     AS_IF([test -z "${with_sanitizer##*address*}" ], [
1076        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer -fsanitize=pointer-compare -fsanitize=pointer-subtract])
1077        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer -fsanitize=pointer-compare -fsanitize=pointer-subtract], [CXXFLAGS])
1078     ])
1079     AS_IF([test -z "${with_sanitizer##*memory*}" ], [
1080         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1081         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1082     ])
1083     AS_IF([test -z "${with_sanitizer##*thread*}" ], [
1084         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1085         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1086     ])
1087 ])
1088
1089 dnl
1090 dnl  Enable/disable optimizations
1091 dnl
1092 AC_ARG_ENABLE([optimizations],
1093   AS_HELP_STRING([--disable-optimizations],
1094     [disable compiler optimizations (default enabled)]),,
1095   [enable_optimizations="yes"])
1096
1097 dnl Check for various optimization flags
1098 AS_IF([test "${enable_optimizations}" != "no"], [
1099
1100   dnl -O3 only in production builds
1101   AS_IF([test "${enable_debug}" = "no"], [
1102     VLC_SAVE_FLAGS
1103     CFLAGS="${CFLAGS} -O3"
1104     CXXFLAGS="${CXXFLAGS} -O3"
1105     OBJCFLAGS="${OBJCFLAGS} -O3"
1106     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1107       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1108         ac_cv_c_o3=yes
1109       ], [
1110         ac_cv_c_o3=no
1111       ])
1112     ])
1113     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1114   ])
1115
1116   dnl Check for fast maths
1117   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CFLAGS])
1118   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CXXFLAGS])
1119
1120 AH_BOTTOM([
1121 #if defined(_MSC_VER) && !defined(__clang__)
1122 # pragma fenv_access(off)
1123 # pragma fp_contract(on)
1124 #elif defined(__GNUC__)
1125 /* Not supported so far */
1126 #else
1127 # pragma STDC FENV_ACCESS OFF
1128 # pragma STDC FP_CONTRACT ON
1129 #endif
1130 ])
1131
1132   dnl Check for -funroll-loops
1133   VLC_SAVE_FLAGS
1134   CFLAGS="${CFLAGS} -funroll-loops"
1135   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1136   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1137   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1138     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1139       ac_cv_c_unroll_loops=yes
1140     ], [
1141       ac_cv_c_unroll_loops=no
1142     ])
1143   ])
1144   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1145
1146   AS_IF([test "$enable_debug" = "no"], [
1147     dnl Check for -fomit-frame-pointer
1148     VLC_SAVE_FLAGS
1149     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1150     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1151     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1152     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1153       [ac_cv_c_omit_frame_pointer], [
1154       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1155         ac_cv_c_omit_frame_pointer=yes
1156       ], [
1157         ac_cv_c_omit_frame_pointer=no
1158       ])
1159     ])
1160     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1161   ])
1162
1163 ])
1164
1165 AC_ARG_ENABLE([ssp],
1166   AS_HELP_STRING([--disable-ssp],
1167   [disable stack smashing protection (default enabled for optimized builds)]), [],
1168   [enable_ssp="yes"])
1169
1170 AS_IF([test "${enable_ssp}" != "no" -a "${enable_optimizations}" != "no"], [
1171   VLC_SAVE_FLAGS
1172   AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong])
1173   AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong], [CXXFLAGS])
1174   dnl Win32 requires linking to ssp for stack-protection
1175   AS_IF([test "${SYS}" = "mingw32"], [
1176       LDFLAGS="${LDFLAGS} -lssp"
1177       AC_CACHE_CHECK([if linker supports stack protectors], [ac_cv_ld_ssp], [
1178         AC_TRY_LINK([#include <stdio.h>],[char buf[100]; fgets(buf, sizeof(buf), stdin);], [
1179           ac_cv_ld_ssp="yes"
1180         ], [
1181           ac_cv_ld_ssp="no"
1182         ])
1183       ])
1184       AS_IF([test "${ac_cv_ld_ssp}" = "no"], [VLC_RESTORE_FLAGS])
1185   ])
1186 ])
1187
1188 AS_IF([test "${SYS}" = "mingw32"], [
1189     dnl library for BCrypt APIs
1190     AS_IF([test "${vlc_winstore_app}" = 1],
1191           [LDFLAGS="${LDFLAGS} -lbcrypt"])
1192 ])
1193
1194 VLC_SAVE_FLAGS
1195 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1196 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1197   AC_TRY_LINK([],, [
1198     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1199   ], [
1200     ac_cv_ld_bsymbolic=""
1201   ])
1202 ])
1203 VLC_RESTORE_FLAGS
1204 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1205 AC_SUBST([SYMBOLIC_LDFLAGS])
1206
1207 VLC_SAVE_FLAGS
1208 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1209 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1210   AC_TRY_LINK([],, [
1211     ac_cv_ld_z_defs="yes"
1212   ], [
1213     ac_cv_ld_z_defs="no"
1214   ])
1215 ])
1216 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1217
1218 dnl Check for __attribute__((packed))
1219 AC_CACHE_CHECK([for __attribute__((packed))],
1220   [ac_cv_c_attribute_packed],
1221   [ac_cv_c_attribute_packed=no
1222    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1223                     [ac_cv_c_attribute_packed=yes])])
1224 if test "${ac_cv_c_attribute_packed}" != "no"; then
1225   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1226 fi
1227
1228 dnl
1229 dnl  Check the CPU
1230 dnl
1231 case "${host_cpu}" in
1232   "")
1233     ARCH=unknown
1234     ;;
1235   armv*)
1236     ARCH="arm"
1237     host_cpu="arm"
1238     ;;
1239   *)
1240     ARCH="${host_cpu}"
1241     ;;
1242 esac
1243
1244 dnl Check for backtrace() support
1245 AC_CHECK_HEADERS([execinfo.h])
1246 AC_CHECK_FUNCS([backtrace])
1247
1248 dnl
1249 dnl  default modules
1250 dnl
1251 ALIASES="${ALIASES} cvlc rvlc"
1252
1253 dnl
1254 dnl  Accelerated modules
1255 dnl
1256
1257 dnl  Check for fully working MMX intrinsics
1258 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1259 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1260 AC_ARG_ENABLE([mmx],
1261   AS_HELP_STRING([--disable-mmx],
1262     [disable MMX optimizations (default auto)]),,[
1263   case "${host_cpu}" in
1264     i?86|x86_64)
1265       enable_mmx="yes"
1266       ;;
1267     *)
1268       enable_mmx="no"
1269       ;;
1270   esac
1271 ])
1272 have_mmx="no"
1273 have_mmxext="no"
1274 AS_IF([test "${enable_mmx}" != "no"], [
1275   ARCH="${ARCH} mmx"
1276   VLC_SAVE_FLAGS
1277   CFLAGS="${CFLAGS} -mmmx"
1278   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1279     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1280 [#include <mmintrin.h>
1281 #include <stdint.h>
1282 uint64_t frobzor;]], [
1283 [__m64 a, b, c;
1284 a = b = c = (__m64)frobzor;
1285 a = _mm_slli_pi16(a, 3);
1286 a = _mm_adds_pi16(a, b);
1287 c = _mm_srli_pi16(c, 8);
1288 c = _mm_slli_pi16(c, 3);
1289 b = _mm_adds_pi16(b, c);
1290 a = _mm_unpacklo_pi8(a, b);
1291 frobzor = (uint64_t)a;]])], [
1292       ac_cv_c_mmx_intrinsics=yes
1293     ], [
1294       ac_cv_c_mmx_intrinsics=no
1295     ])
1296   ])
1297   VLC_RESTORE_FLAGS
1298   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1299     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1300   ])
1301
1302   VLC_SAVE_FLAGS
1303   CFLAGS="${CFLAGS} -mmmx"
1304   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1305     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1306 void *p;
1307 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1308 ]])
1309     ], [
1310       ac_cv_mmx_inline=yes
1311     ], [
1312       ac_cv_mmx_inline=no
1313     ])
1314   ])
1315   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1316     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1317     have_mmx="yes"
1318   ])
1319
1320   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1321                  [ac_cv_mmxext_inline], [
1322     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1323 void *p;
1324 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1325 ]])
1326     ], [
1327       ac_cv_mmxext_inline=yes
1328     ], [
1329       ac_cv_mmxext_inline=no
1330     ])
1331   ])
1332   VLC_RESTORE_FLAGS
1333   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1334     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1335     have_mmxext="yes"
1336   ])
1337 ])
1338 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1339 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1340
1341 dnl  Check for fully workin SSE2 intrinsics
1342 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1343 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1344 AC_ARG_ENABLE([sse],
1345   AS_HELP_STRING([--disable-sse],
1346     [disable SSE (1-4) optimizations (default auto)]),, [
1347   case "${host_cpu}" in
1348     i?86|x86_64)
1349       enable_sse=yes
1350       ;;
1351     *)
1352       enable_sse=no
1353       ;;
1354   esac
1355 ])
1356 have_sse2="no"
1357 AS_IF([test "${enable_sse}" != "no"], [
1358   ARCH="${ARCH} sse sse2"
1359
1360   VLC_SAVE_FLAGS
1361   CFLAGS="${CFLAGS} -msse2"
1362   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1363     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1364 [#include <emmintrin.h>
1365 #include <stdint.h>
1366 uint64_t frobzor;]], [
1367 [__m128i a, b, c;
1368 a = b = c = _mm_set1_epi64((__m64)frobzor);
1369 a = _mm_slli_epi16(a, 3);
1370 a = _mm_adds_epi16(a, b);
1371 c = _mm_srli_epi16(c, 8);
1372 c = _mm_slli_epi16(c, 3);
1373 b = _mm_adds_epi16(b, c);
1374 a = _mm_unpacklo_epi8(a, b);
1375 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1376       ac_cv_c_sse2_intrinsics=yes
1377     ], [
1378       ac_cv_c_sse2_intrinsics=no
1379     ])
1380   ])
1381   VLC_RESTORE_FLAGS
1382   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1383     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1384   ])
1385
1386   VLC_SAVE_FLAGS
1387   CFLAGS="${CFLAGS} -msse"
1388   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1389     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1390 void *p;
1391 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1392 ]])
1393     ], [
1394       ac_cv_sse_inline=yes
1395     ], [
1396       ac_cv_sse_inline=no
1397     ])
1398   ])
1399
1400   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1401     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1402   ])
1403
1404   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1405     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1406 void *p;
1407 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1408 ]])
1409     ], [
1410       ac_cv_sse2_inline=yes
1411     ], [
1412       ac_cv_sse2_inline=no
1413     ])
1414   ])
1415   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1416     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1417     have_sse2="yes"
1418   ])
1419
1420   # SSE3
1421   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1422     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1423 void *p;
1424 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1425 ]])
1426     ], [
1427       ac_cv_sse3_inline=yes
1428     ], [
1429       ac_cv_sse3_inline=no
1430     ])
1431   ])
1432
1433   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1434     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1435   # SSSE3
1436   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1437     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1438 void *p;
1439 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1440 ]])
1441     ], [
1442       ac_cv_ssse3_inline=yes
1443     ], [
1444       ac_cv_ssse3_inline=no
1445     ])
1446   ])
1447
1448   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1449     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1450
1451   # SSE4.1
1452   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1453                  [ac_cv_sse4_1_inline], [
1454     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1455 void *p;
1456 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1457 ]])
1458     ], [
1459       ac_cv_sse4_1_inline=yes
1460     ], [
1461       ac_cv_sse4_1_inline=no
1462     ])
1463   ])
1464
1465   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1466     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1467
1468   # SSE4.2
1469   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1470                  [ac_cv_sse4_2_inline], [
1471     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1472 void *p;
1473 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1474 ]])
1475     ], [
1476       ac_cv_sse4_2_inline=yes
1477     ], [
1478       ac_cv_sse4_2_inline=no
1479     ])
1480   ])
1481
1482   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1483     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1484
1485   # SSE4A
1486   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1487     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1488 void *p;
1489 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1490 ]])
1491     ], [
1492       ac_cv_sse4a_inline=yes
1493     ], [
1494       ac_cv_sse4a_inline=no
1495     ])
1496   ])
1497   VLC_RESTORE_FLAGS
1498   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1499     AC_DEFINE([CAN_COMPILE_SSE4A], [1], [Define to 1 if SSE4A inline assembly is available.]) ])
1500 ])
1501 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1502
1503 VLC_SAVE_FLAGS
1504 CFLAGS="${CFLAGS} -mmmx"
1505 have_3dnow="no"
1506 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1507   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1508 void *p;
1509 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1510 ]])
1511   ], [
1512     ac_cv_3dnow_inline=yes
1513   ], [
1514     ac_cv_3dnow_inline=no
1515   ])
1516 ])
1517 VLC_RESTORE_FLAGS
1518 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1519   AC_DEFINE([CAN_COMPILE_3DNOW], 1,
1520             [Define to 1 if 3D Now! inline assembly is available.])
1521   have_3dnow="yes"
1522 ])
1523 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1524
1525
1526 AC_ARG_ENABLE([neon],
1527   AS_HELP_STRING([--disable-neon],
1528     [disable ARM NEON optimizations (default auto)]),, [
1529   case "${host_cpu}" in
1530     "arm")
1531       enable_neon="32"
1532       ;;
1533     "aarch64")
1534       enable_neon="64"
1535       ;;
1536     *)
1537       enable_neon="no"
1538       ;;
1539   esac
1540 ])
1541 AS_IF([test "${enable_neon}" != "no"], [
1542   VLC_SAVE_FLAGS
1543   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1544     AS_IF([test "${enable_neon}" != "64"], [
1545       CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1546       AC_COMPILE_IFELSE([
1547         AC_LANG_PROGRAM(,[[
1548 asm volatile("vqmovun.s64 d0, q1":::"d0");
1549 ]])
1550       ], [
1551         ac_cv_arm_neon="32"
1552       ], [
1553         ac_cv_arm_neon="no"
1554       ])
1555     ], [
1556       CFLAGS="${CFLAGS} -march=armv8-a+simd"
1557       AC_COMPILE_IFELSE([
1558         AC_LANG_PROGRAM(,[[
1559 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1560 ]])
1561       ], [
1562         ac_cv_arm_neon="64"
1563       ], [
1564         ac_cv_arm_neon="no"
1565       ])
1566     ])
1567   ])
1568   VLC_RESTORE_FLAGS
1569 ])
1570 AM_CONDITIONAL([HAVE_NEON], [test "${ac_cv_arm_neon}" = "32"])
1571 AM_CONDITIONAL([HAVE_ARM64], [test "${ac_cv_arm_neon}" = "64"])
1572
1573 AC_ARG_ENABLE([sve],
1574   AS_HELP_STRING([--disable-sve],
1575     [disable ARM SVE optimizations (default auto)]),, [
1576   AS_IF([test "${host_cpu}" = "aarch64"], [enable_sve="yes"] ,[enable_sve="no"])
1577 ])
1578 AS_IF([test "${enable_sve}" != "no"], [
1579   VLC_SAVE_FLAGS
1580   CFLAGS="${CFLAGS} -march=armv8-a+sve"
1581   AC_CACHE_CHECK([if $CCAS groks ARM SVE assembly], [ac_cv_arm_sve], [
1582     AC_COMPILE_IFELSE([
1583       AC_LANG_PROGRAM(,[[
1584 asm volatile("ptrue p0.s" ::: "p0");
1585 ]])
1586     ], [
1587       ac_cv_arm_sve="yes"
1588     ], [
1589       ac_cv_arm_sve="no"
1590     ])
1591   ])
1592   VLC_RESTORE_FLAGS
1593 ])
1594 AM_CONDITIONAL([HAVE_SVE], [test "${ac_cv_arm_sve}" = "yes"])
1595
1596
1597 AC_ARG_ENABLE([altivec],
1598   AS_HELP_STRING([--disable-altivec],
1599     [disable AltiVec optimizations (default auto)]),, [
1600   AS_CASE("${host_cpu}", [powerpc*],
1601         [enable_altivec=yes], [enable_altivec=no])
1602 ])
1603 have_altivec="no"
1604 ALTIVEC_CFLAGS=""
1605 AS_IF([test "${enable_altivec}" = "yes"], [
1606   ARCH="${ARCH} altivec";
1607   VLC_SAVE_FLAGS
1608   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1609     [ac_cv_altivec_inline],
1610     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1611          ac_cv_altivec_inline="yes",
1612          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1613           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1614             [ac_cv_altivec_inline="-Wa,-maltivec"],
1615             ac_cv_altivec_inline=no)
1616          ])])
1617   VLC_RESTORE_FLAGS
1618   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1619     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1620               [Define to 1 if AltiVec inline assembly is available.])
1621     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1622       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1623       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1624     ])
1625     have_altivec="yes"
1626   ])
1627
1628   VLC_SAVE_FLAGS
1629   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1630   [ac_cv_c_altivec], [
1631     CFLAGS="${CFLAGS} -maltivec"
1632     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1633 [#include <altivec.h>]], [
1634 [vec_ld(0, (unsigned char *)0);]])], [
1635       ac_cv_c_altivec="-maltivec"
1636     ], [
1637       ac_cv_c_altivec="no"
1638     ])
1639   ])
1640   VLC_RESTORE_FLAGS
1641   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1642     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1643     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1644     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1645     ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1646     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1647     have_altivec="yes"
1648   ])
1649   AC_CHECK_HEADERS([altivec.h])
1650
1651   VLC_SAVE_FLAGS
1652   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1653   AC_CACHE_CHECK([if linker needs -framework vecLib],
1654     [ac_cv_ld_altivec],
1655     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1656   VLC_RESTORE_FLAGS
1657   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1658     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1659   ])
1660 ])
1661 AC_SUBST([ALTIVEC_CFLAGS])
1662 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1663
1664 dnl
1665 dnl  Memory usage
1666 dnl
1667 AC_ARG_ENABLE([optimize-memory],
1668   AS_HELP_STRING([--enable-optimize-memory],
1669     [optimize memory usage over performance]))
1670 if test "${enable_optimize_memory}" = "yes"; then
1671   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1672 fi
1673
1674 dnl
1675 dnl Allow running as root (useful for people running on embedded platforms)
1676 dnl
1677 AC_ARG_ENABLE([run-as-root],
1678   AS_HELP_STRING([--enable-run-as-root],
1679     [allow running VLC as root (default disabled)]))
1680 AS_IF([test "${enable_run_as_root}" = "yes"],[
1681     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1682               [Define to 1 to allow running VLC as root (uid 0).])
1683 ])
1684
1685 dnl
1686 dnl Stream output
1687 dnl
1688 AC_ARG_ENABLE([sout],
1689   AS_HELP_STRING([--disable-sout],
1690     [disable streaming output (default enabled)]))
1691 AS_IF([test "${enable_sout}" != "no"], [
1692   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1693 ])
1694 AM_CONDITIONAL([ENABLE_SOUT], [test "${enable_sout}" != "no"])
1695
1696 dnl Lua modules
1697 AC_ARG_ENABLE([lua],
1698   AS_HELP_STRING([--disable-lua],
1699     [disable LUA scripting support (default enabled)]))
1700 if test "${enable_lua}" != "no"
1701 then
1702   PKG_CHECK_MODULES(LUA, lua5.2,
1703     [ have_lua=yes ],
1704     [
1705     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1706
1707     PKG_CHECK_MODULES(LUA, lua5.1,
1708       [ have_lua=yes ],
1709       [
1710       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1711       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1712         [ have_lua=yes ],
1713         [
1714           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1715           have_lua=yes
1716           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1717             [],
1718             [ have_lua=no ] )
1719           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1720             [LUA_LIBS="-llua5.2"],
1721           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1722             [LUA_LIBS="-llua5.1"],
1723             AC_CHECK_LIB( lua51 , luaL_newstate,
1724               [LUA_LIBS="-llua51"],
1725               AC_CHECK_LIB( lua , luaL_newstate,
1726                 [LUA_LIBS="-llua"],
1727                 [ have_lua=no
1728                 ], [-lm])
1729             )))
1730         ])
1731       ])
1732     ])
1733   if test "x${have_lua}" != "xyes" ;  then
1734       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1735   fi
1736   AC_ARG_VAR([LUAC], [LUA byte compiler])
1737   AS_IF([test -z "$LUAC"], [
1738      AC_CHECK_TOOL(LUAC, [luac], [false])
1739   ])
1740   AS_IF([test "${LUAC}" = "false"], [
1741     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1742   ])
1743   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1744     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1745   ])
1746 fi
1747 AM_CONDITIONAL([BUILD_LUA], [test "${have_lua}" = "yes"])
1748
1749
1750 dnl
1751 dnl VideoLAN manager
1752 dnl
1753 AC_ARG_ENABLE([vlm],
1754   AS_HELP_STRING([--disable-vlm],
1755     [disable the stream manager (default enabled)]),,
1756   [enable_vlm="${enable_sout}"])
1757 AS_IF([test "${enable_vlm}" != "no"], [
1758   AS_IF([test "${enable_sout}" = "no"], [
1759     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1760   ])
1761   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1762 ])
1763 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1764
1765
1766 dnl
1767 dnl Addons manager storage and repositories modules
1768 dnl
1769 AC_ARG_ENABLE([addonmanagermodules],
1770   AS_HELP_STRING([--disable-addonmanagermodules],
1771     [disable the addons manager modules (default enabled)]))
1772 if test "${enable_addonmanagermodules}" != "no"
1773 then
1774   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1775 fi
1776 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1777
1778
1779 dnl
1780 dnl  Input plugins
1781 dnl
1782
1783 EXTEND_HELP_STRING([Input plugins:])
1784
1785 dnl
1786 dnl  libarchive access module
1787 dnl
1788 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1789
1790 dnl
1791 dnl  live555 input
1792 dnl
1793 AC_ARG_ENABLE([live555],
1794   AS_HELP_STRING([--enable-live555],
1795     [enable RTSP input through live555 (default enabled)]))
1796
1797 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1798   PKG_CHECK_MODULES(LIVE555, live555, [
1799     VLC_ADD_PLUGIN([live555])
1800     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1801     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1802   ], [
1803     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1804
1805     AC_LANG_PUSH(C++)
1806     VLC_SAVE_FLAGS
1807
1808     dnl detect include paths
1809     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1810       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1811     ], [
1812       AS_IF([test "${SYS}" != "os2"], [
1813         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1814         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1815       ], [
1816         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1817         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1818         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1819       ])
1820     ])
1821
1822     dnl CPP Flags
1823     AS_IF([test "${SYS}" = "solaris"], [
1824       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1825     ])
1826     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1827     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1828
1829     dnl version check
1830     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1831       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1832 [#include <liveMedia_version.hh>
1833 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1834 # error BOOM
1835 #endif]])
1836       ], [
1837         ac_cv_live555="yes"
1838       ], [
1839         ac_cv_live555="no"
1840       ])
1841     ])
1842
1843     AS_IF([test "$ac_cv_live555" = "no"], [
1844       AC_MSG_WARN([live555 is missing or its installed version is too old:
1845 Version 2011.12.23 or later is required to proceed.
1846 You can get an updated one from http://www.live555.com/liveMedia .])
1847       AS_IF([test -n "${enable_live555}"], [
1848         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1849       ])
1850     ], [
1851       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1852       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1853       AS_IF([test "${SYS}" = "mingw32"], [
1854         # add ws2_32 for closesocket, select, recv
1855         other_libs="$other_libs -lws2_32"
1856       ])
1857
1858       dnl We need to check for pic because live555 don't provide shared libs
1859       dnl and we want to build a plugins so we need -fPIC on some arch.
1860       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1861       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1862       AC_CHECK_LIB([liveMedia_pic], [main], [
1863         VLC_ADD_PLUGIN([live555])
1864         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1865       ],[
1866         AC_CHECK_LIB([liveMedia], [main], [
1867           VLC_ADD_PLUGIN([live555])
1868           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1869         ],[],[${other_libs}])
1870       ],[${other_libs_pic}])
1871     ])
1872     VLC_RESTORE_FLAGS
1873     AC_LANG_POP(C++)
1874   ])
1875 ])
1876
1877 dnl
1878 dnl IIDC and DV FireWire input modules
1879 dnl
1880 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1881 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1882
1883 dnl
1884 dnl - linsys modules: access module check for libzvbi
1885 dnl
1886 AC_ARG_ENABLE([linsys],
1887   AS_HELP_STRING([--enable-linsys],
1888     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)]))
1889 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1890   VLC_ADD_PLUGIN([linsys_hdsdi])
1891   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1892     VLC_ADD_PLUGIN([linsys_sdi])
1893   ], [
1894     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1895   ])
1896 ])
1897
1898 dnl
1899 dnl dvdread module: check for libdvdread
1900 dnl
1901 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1902
1903 dnl
1904 dnl libdvdnav plugin
1905 dnl
1906 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1907 AS_IF([test "${enable_dvdnav}" != "no"], [
1908   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1909     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1910       AC_MSG_RESULT(yes)
1911       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1912       ],[
1913       AC_MSG_RESULT(no)
1914     ])
1915 ])
1916
1917 dnl
1918 dnl  Blu-ray Disc Support with libbluray
1919 dnl
1920 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1921
1922 dnl
1923 dnl  OpenCV wrapper and example filters
1924 dnl
1925 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1926
1927
1928 dnl
1929 dnl  libsmbclient plugin
1930 dnl
1931 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smbc], [smbclient], (SMB/CIFS support), [auto])
1932
1933 dnl
1934 dnl  liBDSM access module
1935 dnl
1936 AM_CONDITIONAL([HAVE_DSM], [test "$AS_TR_SH(with_dsm)" = "yes"])
1937 PKG_WITH_MODULES([DSM], [libdsm >= 0.2.0], [
1938        VLC_ADD_PLUGIN([dsm])
1939        VLC_ADD_CFLAGS([dsm], [$DSM_CFLAGS])
1940        VLC_ADD_LIBS([dsm], [$DSM_LIBS])
1941        have_dsm="yes"
1942    ],,[libdsm SMB/CIFS access/sd module], [auto])
1943 AM_CONDITIONAL([HAVE_DSM], [test "${have_dsm}" = "yes"])
1944
1945 dnl
1946 dnl sftp access support
1947 dnl
1948 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1949
1950 dnl
1951 dnl nfs access support
1952 dnl
1953 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1954
1955 dnl
1956 dnl smb2 access support
1957 dnl
1958 PKG_ENABLE_MODULES_VLC([SMB2], [smb2], [libsmb2 >= 2.0.0], (support smb2 protocol via libsmb2), [auto])
1959
1960 dnl
1961 dnl  Video4Linux 2
1962 dnl
1963 AC_ARG_ENABLE([v4l2], AS_HELP_STRING([--disable-v4l2],
1964   [disable Video4Linux version 2 (default auto)]))
1965 have_v4l2="no"
1966 AS_IF([test "$enable_v4l2" != "no"], [
1967   AC_CHECK_HEADERS([linux/videodev2.h], [
1968     have_v4l2="yes"
1969   ])
1970 ])
1971 AM_CONDITIONAL([HAVE_V4L2], [test "${have_v4l2}" != "no"])
1972
1973 dnl
1974 dnl special access module for Blackmagic SDI cards
1975 dnl
1976 AC_ARG_ENABLE([decklink],
1977   AS_HELP_STRING([--disable-decklink],
1978     [disable Blackmagic DeckLink SDI input (default auto)]))
1979 AC_ARG_WITH([decklink_sdk],
1980   AS_HELP_STRING([--with-decklink-sdk=DIR],
1981     [location of Blackmagic DeckLink SDI SDK]))
1982 have_decklink=no
1983 if test "${enable_decklink}" != "no"
1984 then
1985   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1986   then
1987     VLC_ADD_CPPFLAGS([decklink decklinkoutput stream_out_sdi],[-I${with_decklink_sdk}/include])
1988   fi
1989   VLC_SAVE_FLAGS
1990   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1991   AC_LANG_PUSH([C++])
1992   AC_CHECK_HEADERS([DeckLinkAPIDispatch.cpp], [
1993       have_decklink=yes
1994       AS_IF([test "${SYS}" = "darwin"], [
1995         VLC_ADD_LIBS([decklink decklinkoutput],[-Wl,-framework,CoreFoundation])
1996       ])
1997   ], [
1998       AS_IF([test "${enable_decklink}" = "yes"], [
1999         AC_MSG_ERROR([Blackmagic DeckLink SDI include files not found!])
2000       ], [
2001         AC_MSG_WARN([Blackmagic DeckLink SDI include files not found, decklink disabled])
2002       ])
2003   ])
2004   AC_LANG_POP([C++])
2005   VLC_RESTORE_FLAGS
2006 fi
2007 AM_CONDITIONAL([HAVE_DECKLINK], [ test "${have_decklink}" != "no" ])
2008
2009
2010 dnl
2011 dnl  Built-in CD-DA and VCD module
2012 dnl
2013 AC_ARG_ENABLE([vcd],
2014   AS_HELP_STRING([--disable-vcd],
2015     [disable built-in VCD and CD-DA support (default enabled)]))
2016
2017 AC_ARG_ENABLE([libcddb],
2018   AS_HELP_STRING([--disable-libcddb],
2019     [disable CDDB for Audio CD (default enabled)]))
2020
2021 if test "${enable_vcd}" != "no"
2022 then
2023   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
2024   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
2025     AC_MSG_RESULT(yes)
2026     VLC_ADD_PLUGIN([vcd cdda])
2027   ],[
2028     AC_MSG_RESULT(no)
2029   ])
2030
2031   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
2032   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
2033     AC_MSG_RESULT(yes)
2034     VLC_ADD_PLUGIN([vcd cdda])
2035     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
2036   ],[
2037     AC_MSG_RESULT(no)
2038   ])
2039
2040   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
2041   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
2042     AC_MSG_RESULT(yes)
2043     VLC_ADD_PLUGIN([vcd cdda])
2044     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
2045   ],[
2046     AC_MSG_RESULT(no)
2047   ])
2048
2049   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
2050   then
2051     VLC_ADD_PLUGIN([vcd cdda])
2052   fi
2053
2054   if test "$enable_libcddb" != "no"; then
2055     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
2056       HAVE_LIBCDDB=yes
2057       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
2058       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
2059       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
2060       ],:
2061       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
2062       HAVE_LIBCDDB=no])
2063   fi
2064 fi
2065
2066 dnl
2067 dnl Linux DVB
2068 dnl
2069 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
2070   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
2071 [#include <linux/dvb/version.h>
2072 #if (DVB_API_VERSION < 5)
2073 # error Linux DVB API v3.2 and older are not supported.
2074 #endif
2075 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
2076 # error Linux DVB API v5.0 is unsupported. Please update.
2077 #endif
2078 ]])], [
2079   ac_cv_linux_dvb_5_1=yes
2080 ], [
2081   ac_cv_linux_dvb_5_1=no
2082 ])])
2083 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
2084
2085 dnl
2086 dnl  Screen capture module
2087 dnl
2088 AC_ARG_ENABLE([screen],
2089   AS_HELP_STRING([--enable-screen],
2090     [disable screen capture (default enabled)]))
2091 if test "${enable_screen}" != "no"; then
2092   if test "${SYS}" = "darwin"; then
2093     AC_CHECK_HEADERS([ApplicationServices/ApplicationServices.h], [
2094       VLC_ADD_PLUGIN([screen])
2095     ])
2096   fi
2097 fi
2098 AM_CONDITIONAL([HAVE_MAC_SCREEN], [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
2099
2100 dnl
2101 dnl  VNC/RFB access module
2102 dnl
2103 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
2104
2105 dnl  RDP/Remote Desktop access module
2106 dnl
2107 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
2108
2109 dnl
2110 dnl AVFoundation
2111 AC_SUBST([have_avfoundation], ["no"])
2112 AC_ARG_ENABLE([macosx-avfoundation],
2113   AS_HELP_STRING([--enable-macosx-avfoundation], [Mac OS X avcapture (video) module (default enabled on Mac OS X)]))
2114 if test "x${enable_macosx_avfoundation}" != "xno" &&
2115   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2116 then
2117   SAVED_LIBS="${LIBS}"
2118   LIBS="-framework AVFoundation"
2119   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2120   LIBS="${SAVED_LIBS}"
2121   if test "${have_avfoundation}" != "no"
2122   then
2123     VLC_ADD_PLUGIN([avcapture])
2124   fi
2125 fi
2126 AM_CONDITIONAL([HAVE_AVFOUNDATION], [test "${have_avfoundation}" != "no"])
2127
2128 dnl
2129 dnl  DCP plugin (using asdcplib)
2130 dnl
2131 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2132 AM_CONDITIONAL([HAVE_ASDCP], [test "${have_asdcp}" = "yes"])
2133
2134 dnl
2135 dnl  Demux plugins
2136 dnl
2137
2138 EXTEND_HELP_STRING([Mux/Demux plugins:])
2139
2140 dnl
2141 dnl  libdvbpsi check for ts mux/demux
2142 dnl
2143 have_dvbpsi="no"
2144 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2145 AM_CONDITIONAL([HAVE_DVBPSI], [test "${have_dvbpsi}" = "yes"])
2146
2147
2148 dnl
2149 dnl  GME demux plugin
2150 dnl
2151 AC_ARG_ENABLE([gme],
2152   AS_HELP_STRING([--enable-gme],
2153     [use Game Music Emu (default auto)]))
2154 AS_IF([test "${enable_gme}" != "no"], [
2155   AC_CHECK_HEADER([gme/gme.h], [
2156     AC_CHECK_LIB([gme], [gme_identify_header], [
2157       VLC_ADD_PLUGIN([gme])
2158     ], [
2159       AC_CHECK_LIB([gme], [gme_identify_extension], [
2160          VLC_ADD_LIBS([gme], [-lstdc++ $LIBM])
2161          VLC_ADD_PLUGIN([gme])
2162       ],, [-lstdc++ $LIBM])
2163     ])
2164     VLC_ADD_LIBS([gme], [-lgme])
2165   ], [
2166     AS_IF([test "x${enable_gme}" != "x"], [
2167       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2168     ])
2169   ])
2170 ])
2171
2172
2173 dnl
2174 dnl  SIDPlay plugin
2175 dnl
2176 AC_ARG_ENABLE([sid],
2177     AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)]))
2178 AS_IF([test "${enable_sid}" != "no"], [
2179     PKG_CHECK_MODULES(SID, [libsidplay2], [
2180         AC_LANG_PUSH(C++)
2181         oldCPPFLAGS="$CPPFLAGS"
2182         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2183         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2184             VLC_ADD_PLUGIN([sid])
2185             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2186             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2187         ], [
2188             AS_IF([test -n "${enable_sid}"],
2189                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2190                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2191                 )
2192         ])
2193         CPPFLAGS="$oldCPPFLAGS"
2194         AC_LANG_POP(C++)
2195     ], [
2196         AS_IF([test "x${enable_sid}" = "xyes"],
2197             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2198             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2199             )
2200     ])
2201 ])
2202
2203
2204 dnl
2205 dnl  ogg demux plugin
2206 dnl
2207 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2208 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2209     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2210 ],[true])
2211 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2212 if test "${enable_sout}" != "no"; then
2213 dnl Check for libshout
2214     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2215 fi
2216
2217 dnl
2218 dnl  matroska demux plugin
2219 dnl
2220 PKG_WITH_MODULES([MATROSKA], [libebml libmatroska], [
2221        VLC_ADD_PLUGIN([mkv])
2222        VLC_ADD_CFLAGS([mkv], [$MATROSKA_CFLAGS])
2223        VLC_ADD_LIBS([mkv], [$MATROSKA_LIBS])
2224        have_matroska="yes"
2225    ],,[MKV format support], [auto])
2226 AM_CONDITIONAL([HAVE_MATROSKA], [test "${have_matroska}" = "yes"])
2227
2228 dnl
2229 dnl  modplug demux plugin
2230 dnl
2231 AC_ARG_ENABLE([mod],
2232   AS_HELP_STRING([--disable-mod],
2233     [do not use libmodplug (default auto)]))
2234 if test "${enable_mod}" != "no" ; then
2235     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2236           VLC_ADD_PLUGIN([mod])
2237           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2238           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2239           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2240     ],[
2241        AS_IF([test -n "${enable_mod}"],
2242          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2243          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2244     ])
2245 fi
2246
2247 dnl
2248 dnl  mpc demux plugin
2249 dnl
2250 AC_ARG_ENABLE([mpc],
2251   AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)]))
2252 if test "${enable_mpc}" != "no"
2253 then
2254     AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2255     VLC_ADD_PLUGIN([mpc])
2256     VLC_ADD_LIBS([mpc],[-lmpcdec])])
2257 fi
2258
2259 dnl
2260 dnl  Codec plugins
2261 dnl
2262
2263 EXTEND_HELP_STRING([Codec plugins:])
2264
2265 dnl
2266 dnl wmafixed plugin
2267 dnl
2268 AC_ARG_ENABLE([wma-fixed],
2269   AS_HELP_STRING([--enable-wma-fixed], [libwma-fixed module (default disabled)]))
2270 if test "${enable_wma_fixed}" = "yes"
2271 then
2272   VLC_ADD_PLUGIN([wma_fixed])
2273 fi
2274
2275 dnl
2276 dnl shine encoder plugin
2277 dnl
2278 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2279
2280
2281 dnl
2282 dnl openmax il codec plugin
2283 dnl
2284 AC_ARG_ENABLE([omxil],
2285   AS_HELP_STRING([--enable-omxil], [openmax il codec module (default disabled)]))
2286 if test "${enable_omxil}" = "yes"
2287 then
2288   VLC_ADD_PLUGIN([omxil])
2289 fi
2290
2291 dnl
2292 dnl raspberry pi openmax il configuration
2293 dnl
2294 AC_ARG_ENABLE([rpi-omxil],
2295   AS_HELP_STRING([--enable-rpi-omxil], [openmax il configured for raspberry pi (default disabled)]))
2296 if test "${enable_rpi_omxil}" = "yes"
2297 then
2298   VLC_ADD_PLUGIN([omxil])
2299   VLC_ADD_CFLAGS([omxil],[-DRPI_OMX])
2300 fi
2301
2302 dnl
2303 dnl CrystalHD codec plugin
2304 dnl
2305 AC_ARG_ENABLE([crystalhd],
2306   AS_HELP_STRING([--enable-crystalhd], [crystalhd codec plugin (default auto)]))
2307 if test "${enable_crystalhd}" != "no"; then
2308     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2309       VLC_ADD_PLUGIN([crystalhd])
2310       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2311     ],[
2312       if test "${SYS}" = "mingw32" ; then
2313         AC_CHECK_HEADERS([libcrystalhd/bc_dts_defs.h], [
2314           VLC_ADD_PLUGIN([crystalhd])
2315           AC_CHECK_HEADERS([libcrystalhd/bc_drv_if.h], [
2316             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2317             ])
2318         ],[
2319           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2320                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2321                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2322         ],[#define __LINUX_USER__
2323                #include <libcrystalhd/bc_dts_types.h>
2324         ])
2325       fi
2326     ],[
2327        #include <libcrystalhd/bc_dts_types.h>
2328       ])
2329 fi
2330
2331 dnl
2332 dnl  mad plugin
2333 dnl
2334 have_mad="no"
2335 MAD_CFLAGS=""
2336 MAD_LIBS=""
2337
2338 AC_ARG_WITH(mad, AS_HELP_STRING([--with-mad=PATH], [path to libmad]), [
2339   enable_mad="yes"
2340 ], [
2341   with_mad="no"
2342 ])
2343 AS_IF([test "${with_mad}" != "no"], [
2344   MAD_CFLAGS="-I${with_mad}/include"
2345   MAD_LIBS="-L${with_mad}/lib"
2346 ])
2347
2348 AC_ARG_ENABLE([mad],
2349   AS_HELP_STRING([--enable-mad], [libmad module (default enabled)]))
2350 AS_IF([test "${enable_mad}" != "no"], [
2351   VLC_SAVE_FLAGS
2352   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2353   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2354   AC_CHECK_HEADERS([mad.h], [
2355     AC_CHECK_LIB([mad], [mad_bit_init], [
2356       have_mad="yes"
2357       MAD_LIBS="${MAD_LIBS} -lmad"
2358     ])
2359   ])
2360   VLC_RESTORE_FLAGS
2361   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2362     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2363   ])
2364 ])
2365 AC_SUBST([MAD_CFLAGS])
2366 AC_SUBST([MAD_LIBS])
2367 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2368
2369 dnl  mpg123 plugin
2370 dnl
2371 dnl
2372 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2373
2374 dnl
2375 dnl gstreamer stuff
2376 dnl
2377 AC_ARG_ENABLE([gst-decode],
2378   AS_HELP_STRING([--enable-gst-decode], [GStreamer based decoding support (currently supports only video decoding) (default auto)]))
2379
2380 have_gst_decode="no"
2381 AS_IF([test "${enable_gst_decode}" != "no"], [
2382   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2383     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2384       have_gst_decode="yes"
2385     ], [
2386       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2387     ])
2388   ], [
2389     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2390   ])
2391 ])
2392 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2393
2394 dnl
2395 dnl  avcodec decoder/encoder plugin
2396 dnl
2397 AC_ARG_ENABLE([merge-ffmpeg],
2398 AS_HELP_STRING([--enable-merge-ffmpeg], [merge FFmpeg-based plugins (default disabled)]),, [
2399   enable_merge_ffmpeg="no"
2400 ])
2401 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2402
2403 AC_MSG_CHECKING([for libavutil variant])
2404 PKG_CHECK_EXISTS([libavutil], [
2405   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2406   libavutil_micro="${libavutil_version##*.}"
2407   AS_IF([test ${libavutil_micro} -le 99], [
2408     avfork="libav"
2409   ], [
2410     avfork="ffmpeg"
2411   ])
2412 ], [
2413   avfork="none"
2414 ])
2415 AC_MSG_RESULT([${avfork}])
2416
2417 AC_ARG_ENABLE([avcodec],
2418 AS_HELP_STRING([--enable-avcodec], [libavcodec codec (default enabled)]))
2419 AS_IF([test "${enable_avcodec}" != "no"], [
2420   dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2421   case "${avfork}" in
2422     libav) av_codec_ver="57.16.0" ;;
2423     dnl 05f66706d182eb0c36af54d72614bf4c33e957a9  includes libavutil 55.9.0
2424     ffmpeg) av_codec_ver="57.37.100" ;;
2425     dnl 7fc329e2dd6226dfecaa4a1d7adf353bf2773726  include libavutil 55.22.101
2426     *) AC_MSG_ERROR([Missing libav or FFmpeg. Pass --disable-avcodec to ignore this error.])
2427   esac
2428   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 55.9.0], [
2429     VLC_SAVE_FLAGS
2430     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2431     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2432     AC_CHECK_HEADERS([libavcodec/avcodec.h])
2433     AC_CHECK_HEADERS([libavutil/avutil.h])
2434     VLC_RESTORE_FLAGS
2435     have_avcodec="yes"
2436   ],[
2437     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2438   ])
2439 ], [
2440   have_avcodec="no"
2441 ])
2442 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2443
2444 dnl
2445 dnl libva needs avcodec
2446 dnl
2447 AC_ARG_ENABLE([libva],
2448   AS_HELP_STRING([--enable-libva], [VAAPI GPU decoding support (libVA) (default auto)]))
2449
2450 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2451   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2452 ])
2453
2454 have_vaapi="no"
2455 have_vaapi_drm="no"
2456 have_vaapi_x11="no"
2457 have_vaapi_wl="no"
2458 AS_IF([test "${enable_libva}" != "no"], [
2459   PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2460     have_vaapi="yes"
2461   ], [
2462     AS_IF([test -n "${enable_libva}"], [
2463       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2464     ], [
2465       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2466     ])
2467   ])
2468   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2469     have_vaapi_drm="yes"
2470   ], [
2471     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2472   ])
2473   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2474     have_vaapi_x11="yes"
2475   ], [
2476     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2477   ])
2478   PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2479     have_vaapi_wl="yes"
2480   ], [
2481     AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2482   ])
2483 ])
2484 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2485 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2486 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2487 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2488
2489 have_avcodec_vaapi="no"
2490 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2491   VLC_SAVE_FLAGS
2492   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2493   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2494   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2495     AC_MSG_NOTICE([VA API acceleration activated])
2496     have_avcodec_vaapi="yes"
2497   ],[
2498     AS_IF([test -n "${enable_libva}"], [
2499       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2500     ], [
2501       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2502     ])
2503   ])
2504   VLC_RESTORE_FLAGS
2505 ])
2506 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2507
2508 dnl
2509 dnl dxva2 needs avcodec
2510 dnl
2511 AC_ARG_ENABLE([dxva2],
2512   AS_HELP_STRING([--enable-dxva2], [DxVA2 GPU decoding support (default auto)]))
2513
2514 have_avcodec_dxva2="no"
2515 AS_IF([test "${enable_dxva2}" != "no"], [
2516   if test "${SYS}" = "mingw32"; then
2517   AS_IF([test "x${have_avcodec}" = "xyes"], [
2518     AC_CHECK_HEADERS([dxva2api.h],
2519       [
2520         AC_CHECK_HEADERS([libavcodec/dxva2.h], [
2521            AC_MSG_NOTICE([DxVA2 acceleration activated])
2522            have_avcodec_dxva2="yes"
2523         ],[
2524     AS_IF([test "${enable_dxva2}" = "yes"],
2525           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2526               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2527         ], [#undef _WIN32_WINNT
2528             /* DXVA2 is only available in Vista and above */
2529             #define _WIN32_WINNT 0x600])
2530       ],[
2531     AS_IF([test "${enable_dxva2}" = "yes"],
2532               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2533               [AC_MSG_WARN([dxva2api.h not found])])
2534       ],[#include <d3d9.h>])
2535   ],[
2536     AS_IF([test "x${enable_dxva2}" != "x"], [
2537       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2538     ])
2539   ])
2540   fi
2541 ])
2542 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2543
2544 dnl
2545 dnl d3d11va needs avcodec
2546 dnl
2547 AC_ARG_ENABLE([d3d11va],
2548   AS_HELP_STRING([--enable-d3d11va], [D3D11 GPU decoding support (default auto)]))
2549
2550 have_avcodec_d3d11va="no"
2551 AS_IF([test "${enable_d3d11va}" != "no"], [
2552   if test "${SYS}" = "mingw32"; then
2553   AS_IF([test "x${have_avcodec}" = "xyes"], [
2554         AC_CHECK_TYPES([ID3D11VideoDecoder],
2555           [
2556             AC_CHECK_HEADERS([dxva2api.h],
2557               [
2558                 AC_CHECK_HEADERS([libavcodec/d3d11va.h], [
2559                    AC_MSG_NOTICE([D3D11 acceleration activated])
2560                    AC_DEFINE([HAVE_AVCODEC_D3D11VA], [1], [Define if the d3d11va module is built])
2561                    have_avcodec_d3d11va="yes"
2562                 ],[
2563                   AS_IF([test "${enable_d3d11va}" = "yes"],
2564                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2565                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2566                   ], [#undef _WIN32_WINNT
2567                       /* D3D11 is only available in Vista and above */
2568                       #define _WIN32_WINNT 0x600])
2569                   ],[
2570                     AS_IF([test "${enable_d3d11va}" = "yes"],
2571                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2572                           [AC_MSG_WARN([dxva2api.h not found])])
2573                   ],[#include <d3d9.h>])
2574           ],[
2575             AS_IF([test "${enable_d3d11va}" = "yes"],
2576                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2577                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2578           ], [#include <d3d11.h>])
2579   ],[
2580     AS_IF([test "x${enable_d3d11va}" != "x"], [
2581       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2582     ])
2583   ])
2584   fi
2585 ])
2586 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2587
2588 dnl
2589 dnl DXGI debug
2590 dnl
2591 AC_CHECK_HEADERS([dxgidebug.h dxgi1_6.h])
2592
2593 dnl
2594 dnl  avformat demuxer/muxer plugin
2595 dnl
2596
2597 AC_ARG_ENABLE([avformat],
2598 AS_HELP_STRING([--enable-avformat], [libavformat containers (default enabled)]),, [
2599   enable_avformat="${have_avcodec}"
2600 ])
2601 have_avformat="no"
2602 AS_IF([test "${enable_avformat}" != "no"], [
2603   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2604       have_avformat="yes"
2605       VLC_SAVE_FLAGS
2606       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2607       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2608       AC_CHECK_HEADERS([libavformat/avformat.h libavformat/avio.h])
2609       AC_CHECK_HEADERS([libavcodec/avcodec.h])
2610       AC_CHECK_HEADERS([libavutil/avutil.h])
2611       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2612         have_avformat="no"
2613       ])
2614       VLC_RESTORE_FLAGS
2615     ],[
2616       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2617   ])
2618 ])
2619 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2620
2621 dnl
2622 dnl  swscale image scaling and conversion plugin
2623 dnl
2624
2625 AC_ARG_ENABLE([swscale],
2626   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2627           (default enabled)]))
2628 if test "${enable_swscale}" != "no"
2629 then
2630   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2631     [
2632       VLC_SAVE_FLAGS
2633       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2634       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2635       AC_CHECK_HEADERS([libswscale/swscale.h])
2636       AC_CHECK_HEADERS([libavutil/avutil.h])
2637       VLC_ADD_PLUGIN([swscale])
2638       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2639       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2640       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2641         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2642       ])
2643       VLC_RESTORE_FLAGS
2644     ],[
2645       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2646   ])
2647 fi
2648
2649 dnl
2650 dnl  postproc plugin
2651 dnl
2652
2653 AC_ARG_ENABLE([postproc],
2654 AS_HELP_STRING([--enable-postproc], [libpostproc image post-processing (default auto)]))
2655 if test "${enable_postproc}" != "no"
2656 then
2657   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2658     [
2659       VLC_SAVE_FLAGS
2660       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2661       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2662       AC_CHECK_HEADERS([postproc/postprocess.h])
2663       VLC_ADD_PLUGIN([postproc])
2664       VLC_RESTORE_FLAGS
2665     ],[
2666       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2667   ])
2668 fi
2669
2670 dnl
2671 dnl  faad decoder plugin
2672 dnl
2673 AC_ARG_ENABLE([faad],
2674 AS_HELP_STRING([--enable-faad], [faad codec (default auto)]))
2675 have_faad="no"
2676 AS_IF([test "${enable_faad}" != "no"], [
2677   AC_CHECK_HEADERS([neaacdec.h], [
2678     AC_CHECK_LIB([faad], [NeAACDecOpen], [have_faad="yes"],, [$LIBM])
2679
2680     AS_IF([test "${have_faad}" = "yes"], [
2681       VLC_ADD_PLUGIN([faad])
2682       VLC_ADD_LIBS([faad],[-lfaad])
2683     ], [
2684       AS_IF([test "${enable_faad}" = "yes"], [
2685         AC_MSG_ERROR([cannot find FAAD library])
2686       ], [
2687         AC_MSG_WARN([cannot find FAAD library])
2688       ])
2689     ])
2690   ])
2691 ])
2692
2693 dnl
2694 dnl  AOM decoder plugin
2695 dnl
2696 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec (default auto)])
2697
2698 dnl
2699 dnl  Dav1d decoder plugin
2700 dnl
2701 PKG_ENABLE_MODULES_VLC([DAV1D], [], [dav1d], [AV1 decoder (default auto)])
2702
2703 dnl
2704 dnl libvpx decoder plugin
2705 dnl
2706 AC_ARG_ENABLE([vpx],
2707     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2708 AS_IF([test "${enable_vpx}" != "no"],[
2709     PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2710         VLC_ADD_PLUGIN([vpx])
2711         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2712         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2713         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2714             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2715         ], [], [${VPX_LIBS}])
2716         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2717             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2718         ], [], [${VPX_LIBS}])
2719         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2720             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2721         ], [], [${VPX_LIBS}])
2722         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2723             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2724         ], [], [${VPX_LIBS}])
2725     ], [
2726     AS_IF([test "${enable_vpx}" = "yes"],[
2727         AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2728     ])])
2729 ])
2730
2731 dnl
2732 dnl twolame encoder plugin
2733 dnl
2734 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2735
2736 dnl
2737 dnl fdk-aac encoder plugin
2738 dnl
2739 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2740
2741
2742 dnl
2743 dnl A52/AC3 decoder plugin
2744 dnl
2745 AC_ARG_ENABLE([a52],
2746   AS_HELP_STRING([--enable-a52], [A/52 support with liba52 (default enabled)]))
2747 if test "${enable_a52}" != "no"
2748 then
2749   AC_ARG_WITH([a52],
2750     AS_HELP_STRING([--with-a52=PATH], [a52 headers and libraries]))
2751     if test -z "${with_a52}"
2752     then
2753       LDFLAGS_test=""
2754       CPPFLAGS_test=""
2755     else
2756       LDFLAGS_test="-L${with_a52}/lib"
2757       CPPFLAGS_test="-I${with_a52}/include"
2758     fi
2759     VLC_SAVE_FLAGS
2760     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2761     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2762     AC_CHECK_HEADERS([a52dec/a52.h], [
2763       AC_CHECK_LIB([a52], [a52_free], [
2764         VLC_ADD_PLUGIN([a52])
2765         VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2766         VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2767       ],[
2768         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2769         ], [$LIBM])
2770     ],[
2771       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2772     ])
2773     VLC_RESTORE_FLAGS
2774 fi
2775
2776 dnl
2777 dnl DTS Coherent Acoustics decoder plugin
2778 dnl
2779 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2780
2781 dnl
2782 dnl  Flac plugin
2783 dnl
2784 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2785
2786 dnl
2787 dnl  Libmpeg2 plugin
2788 dnl
2789 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2790
2791 dnl
2792 dnl  Vorbis plugin
2793 dnl
2794 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2795
2796 dnl
2797 dnl  Tremor plugin
2798 dnl
2799 AC_ARG_ENABLE([tremor],
2800   AS_HELP_STRING([--enable-tremor], [Tremor decoder support (default disabled)]))
2801 if test "${enable_tremor}" = "yes"
2802 then
2803   AC_CHECK_HEADERS([tremor/ivorbiscodec.h], [
2804     VLC_ADD_PLUGIN([tremor])
2805    ],[])
2806 fi
2807
2808 dnl
2809 dnl  Speex plugins
2810 dnl
2811 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2812 have_speexdsp="no"
2813 AS_IF([test "${enable_speex}" != "no"], [
2814   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2815     have_speexdsp="yes"
2816   ], [
2817     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2818   ])
2819 ])
2820 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2821
2822 dnl
2823 dnl  Opus plugin
2824 dnl
2825 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2826
2827 dnl
2828 dnl  Ambisonic channel mixer and binauralizer plugin
2829 dnl
2830 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
2831
2832 dnl
2833 dnl  theora decoder plugin
2834 dnl
2835 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2836
2837 dnl
2838 dnl  OggSpots decoder plugin
2839 dnl
2840 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2841
2842 dnl
2843 dnl  Daala decoder plugin
2844 dnl
2845 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2846
2847 dnl
2848 dnl  schroedinger decoder plugin (for dirac format video)
2849 dnl
2850 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2851
2852 dnl
2853 dnl  PNG decoder module
2854 dnl
2855 AC_ARG_ENABLE([png],
2856   AS_HELP_STRING([--enable-png], [PNG support (default enabled)]))
2857 AS_IF([test "${enable_png}" != "no"], [
2858 AC_CHECK_HEADERS([png.h], [
2859   VLC_SAVE_FLAGS
2860   LDFLAGS="${LDFLAGS} -lz $LIBM"
2861   AC_CHECK_LIB([png], [png_set_alpha_mode], [
2862     VLC_ADD_PLUGIN([png])
2863   ], [], [-lz $LIBM])
2864   VLC_RESTORE_FLAGS
2865   ])
2866 ])
2867
2868 dnl
2869 dnl  JPEG decoder module
2870 dnl
2871 AC_ARG_ENABLE([jpeg],
2872   AS_HELP_STRING([--enable-jpeg], [JPEG support (default enabled)]))
2873 AS_IF([test "${enable_jpeg}" != "no"], [
2874 AC_CHECK_HEADERS([jpeglib.h], [
2875   VLC_ADD_PLUGIN([jpeg])
2876   ])
2877 ])
2878
2879 dnl
2880 dnl  BPG decoder module
2881 dnl
2882 AC_ARG_ENABLE([bpg],
2883   AS_HELP_STRING([--enable-bpg], [BPG support (default disabled)]))
2884 AS_IF([test "${enable_bpg}" != "no"], [
2885 AC_CHECK_HEADERS([libbpg.h], [
2886   VLC_ADD_PLUGIN([bpg])
2887   ])
2888 ])
2889
2890 dnl
2891 dnl H262 encoder plugin (lib262)
2892 dnl
2893 AC_ARG_ENABLE([x262],
2894   AS_HELP_STRING([--enable-x262], [H262 encoding support with static libx262 (default disabled)]))
2895 if test "${enable_x262}" != "no"; then
2896     PKG_CHECK_MODULES(X262, x262, [
2897         VLC_ADD_PLUGIN([x262])
2898         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2899         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2900           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2901         ])
2902         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2903         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2904           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2905         fi
2906     ], [
2907        if test "${enable_x262}" = "yes"; then
2908         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2909        fi
2910     ])
2911 fi
2912
2913 dnl x265 encoder
2914 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2915
2916 dnl
2917 dnl H264 encoder plugin (using libx264)
2918 dnl
2919 AC_ARG_ENABLE([x264],
2920   AS_HELP_STRING([--enable-x264], [H264 encoding support with libx264 (default enabled)]))
2921 if test "${enable_x264}" != "no"; then
2922       PKG_CHECK_MODULES(X264,x264 >= 0.148, [
2923         VLC_ADD_PLUGIN([x264])
2924         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2925
2926         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2927           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2928         ])
2929
2930         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2931         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2932           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2933         fi
2934       ],[
2935         if test "${enable_x264}" = "yes"; then
2936             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2937           fi
2938       ])
2939 fi
2940
2941 dnl
2942 dnl H264 encoder plugin (libx264 > 153)
2943 dnl
2944 AC_ARG_ENABLE([x26410b],
2945   AS_HELP_STRING([--enable-x26410b], [H264 10-bit encoding support with libx264 (default enabled)]))
2946 if test "${enable_x26410b}" != "no"; then
2947       PKG_CHECK_MODULES(X26410b,x264 >= 0.153, [
2948         VLC_ADD_PLUGIN([x26410b])
2949         VLC_ADD_LIBS([x26410b],[${X264_LIBS}])
2950
2951         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2952           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2953         ])
2954
2955         VLC_ADD_CFLAGS([x26410b],[${X264_CFLAGS}])
2956         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2957           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2958         fi
2959       ],[
2960         if test "${enable_x26410b}" = "yes"; then
2961             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2962           fi
2963       ])
2964 fi
2965
2966
2967 dnl
2968 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2969 dnl
2970 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2971
2972 dnl
2973 dnl libfluidsynth (MIDI synthetizer) plugin
2974 dnl
2975 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2976 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2977 AC_CHECK_HEADERS([fluidlite.h], [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2978
2979 dnl
2980 dnl Teletext Modules
2981 dnl vbi decoder plugin (using libzbvi)
2982 dnl telx module
2983 dnl uncompatible
2984 dnl
2985 AC_ARG_ENABLE([zvbi],
2986   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2987                   libzvbi (default enabled)]))
2988 AC_ARG_ENABLE([telx],
2989   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2990                   zvbi) (default enabled if zvbi is absent)]))
2991
2992 AS_IF( [test "${enable_zvbi}" != "no"],[
2993     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2994         [
2995           VLC_ADD_PLUGIN([zvbi])
2996           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2997           AS_IF( [test "${enable_telx}" = "yes"],[
2998                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2999                   ])
3000         ],[
3001           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
3002         ])
3003     ])
3004 AS_IF( [test "${enable_telx}" != "no" ],[
3005   VLC_ADD_PLUGIN([telx])
3006   ])
3007
3008 dnl
3009 dnl ARIB subtitles rendering module
3010 dnl
3011 AC_ARG_ENABLE([aribsub],
3012   AS_HELP_STRING([--enable-aribsub],[ARIB Subtitles support (default enabled)]))
3013 AS_IF( [test "${enable_aribsub}" != "no" ],[
3014   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
3015       have_aribb24="yes"
3016       VLC_ADD_PLUGIN([aribsub])
3017       VLC_ADD_LIBS([aribsub],[-laribb24])
3018       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
3019     ],[
3020       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
3021       have_aribb24="no"
3022   ])
3023 ])
3024 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
3025
3026 dnl
3027 dnl ARIB B25
3028 dnl
3029 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
3030
3031 dnl
3032 dnl  kate decoder plugin
3033 dnl
3034 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
3035
3036 dnl
3037 dnl  tiger rendering for kate decoder plugin
3038 dnl
3039 AC_ARG_ENABLE([tiger],
3040 AS_HELP_STRING([--enable-tiger], [Tiger rendering library for Kate streams (default auto)]))
3041 AS_IF([test "${enable_tiger}" != "no"], [
3042   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
3043       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
3044         AS_IF([test -n "${enable_tiger}"], [
3045           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
3046         ])
3047   ])
3048 ])
3049
3050 dnl
3051 dnl  check if we can build the css selector engine
3052 dnl
3053 AC_ARG_ENABLE([css],
3054 AS_HELP_STRING([--enable-css], [CSS selector engine (default auto)]))
3055 AS_IF([test "${enable_css}" != "no"], [
3056   with_css="yes"
3057   AC_DEFINE(HAVE_CSS, 1, [Define if CSS engine is built])
3058 ])
3059 AM_CONDITIONAL([ENABLE_CSS], [test "${with_css}" = "yes"])
3060
3061
3062 dnl
3063 dnl  Video plugins
3064 dnl
3065
3066 EXTEND_HELP_STRING([Video plugins:])
3067
3068 dnl
3069 dnl  libplacebo support
3070 dnl
3071 AC_ARG_ENABLE([libplacebo],
3072   AS_HELP_STRING([--disable-libplacebo],
3073       [disable libplacebo support (default auto)]))
3074
3075 AS_IF([test "$enable_libplacebo" != "no"], [
3076   PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 0.5], [
3077     AC_DEFINE([HAVE_LIBPLACEBO], [1], [Define to 1 if libplacebo is enabled.])
3078     PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 1.7],
3079       [have_libplacebo_vk="yes"], [have_libplacebo_vk="no"])
3080   ], [
3081     AS_IF([test -n "${enable_libplacebo}"], [
3082       AC_MSG_ERROR([${LIBPLACEBO_PKG_ERRORS}.])
3083     ])
3084     enable_libplacebo="no"
3085   ])
3086 ])
3087 AM_CONDITIONAL([HAVE_LIBPLACEBO], [test "$enable_libplacebo" != "no"])
3088
3089 dnl
3090 dnl  OpenGL
3091 dnl
3092 PKG_CHECK_MODULES([EGL], [egl], [
3093   have_egl="yes"
3094 ], [
3095   have_egl="no"
3096 ])
3097 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3098
3099 have_gl="no"
3100 PKG_CHECK_MODULES([GL], [gl], [
3101   have_gl="yes"
3102 ], [
3103   AC_MSG_CHECKING([for OpenGL])
3104   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3105 #ifdef _WIN32
3106 # include <GL/glew.h>
3107 #endif
3108 #include <GL/gl.h>
3109 ]], [
3110     [int t0 = GL_TEXTURE0;]])
3111   ], [
3112     GL_CFLAGS=""
3113     have_gl="yes"
3114     AS_IF([test "${SYS}" != "mingw32"], [
3115       GL_LIBS="-lGL"
3116     ], [
3117       GL_LIBS="-lopengl32"
3118     ])
3119   ])
3120   AC_MSG_RESULT([${have_gl}])
3121 ])
3122 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3123 AS_IF([test "${have_gl}" = "yes"], [
3124   AC_DEFINE([HAVE_GL], 1, [Defined if having OpenGL])
3125 ])
3126
3127 dnl OpenGL ES 2: depends on EGL 1.1
3128 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3129
3130 dnl
3131 dnl Vulkan
3132 dnl
3133 AC_ARG_ENABLE(vulkan,
3134   [AS_HELP_STRING([--disable-vulkan],
3135       [disable Vulkan support (default auto)])])
3136
3137 AS_IF([test "$enable_vulkan" != "no"], [
3138   AS_IF([test "$have_libplacebo_vk" = "yes"], [
3139     PKG_CHECK_MODULES([VULKAN], [vulkan >= 1.0.26], [
3140       AC_DEFINE([HAVE_VULKAN], [1], [Define to 1 if vulkan is enabled.])
3141     ], [
3142       AS_IF([test -n "${enable_vulkan}"], [
3143         AC_MSG_ERROR([${VULKAN_PKG_ERRORS}.])
3144       ])
3145       enable_vulkan="no"
3146     ])
3147   ], [
3148     AS_IF([test -n "${enable_vulkan}"], [
3149       AC_MSG_ERROR([Vulkan support requires libplacebo 1.7 as well. Do not use --disable-libplacebo.])
3150     ])
3151     enable_vulkan="no"
3152   ])
3153 ])
3154 AM_CONDITIONAL(HAVE_VULKAN, [test "$enable_vulkan" != "no"])
3155
3156 dnl
3157 dnl  Xlib
3158 dnl
3159
3160 AC_PATH_XTRA()
3161 AC_CHECK_HEADERS([X11/Xlib.h])
3162
3163 dnl
3164 dnl  X C Bindings modules
3165 dnl
3166 AC_ARG_ENABLE([xcb],
3167   AS_HELP_STRING([--enable-xcb], [X11 support with XCB (default enabled)]),, [
3168   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3169     enable_xcb="yes"
3170   ], [
3171     enable_xcb="no"
3172   ])
3173 ])
3174
3175 have_xcb="no"
3176 have_xkbcommon_x11="no"
3177 have_xcb_keysyms="no"
3178 AS_IF([test "${enable_xcb}" != "no"], [
3179   xcb_err=""
3180
3181   dnl libxcb
3182   PKG_CHECK_MODULES([XCB], [xcb >= 1.6],, [
3183     xcb_err="$xcb_err ${XCB_PKG_ERRORS}."])
3184   PKG_CHECK_MODULES([XCB_COMPOSITE], [xcb-composite],, [
3185     xcb_err="$xcb_err ${XCB_COMPOSITE_PKG_ERRORS}."])
3186   PKG_CHECK_MODULES([XCB_RANDR], [xcb-randr >= 1.3],, [
3187     xcb_err="$xcb_err ${XCB_RANDR_PKG_ERRORS}."])
3188   PKG_CHECK_MODULES([XCB_RENDER], [xcb-render],, [
3189     xcb_err="$xcb_err ${XCB_RENDER_PKG_ERRORS}."])
3190   PKG_CHECK_MODULES([XCB_SHM], [xcb-shm >= 1.9.2],, [
3191     xcb_err="$xcb_err ${XCB_SHM_PKG_ERRORS}."])
3192   PKG_CHECK_MODULES([XCB_XKB], [xcb-xkb],, [
3193     xcb_err="$xcb_err ${XCB_XKB_PKG_ERRORS}."])
3194   PKG_CHECK_MODULES([XCB_XV], [xcb-xv >= 1.1.90.1],, [
3195     xcb_err="$xcb_err ${XCB_XV_PKG_ERRORS}."])
3196
3197   dnl xproto
3198   PKG_CHECK_MODULES(XPROTO, [xproto],, [
3199     xcb_err="$xcb_err ${XPROTO_PKG_ERRORS}."])
3200
3201   AS_IF([test -n "$xcb_err"], [
3202     AC_MSG_ERROR([$xcb_err Pass --disable-xcb to skip X11 support.])
3203   ])
3204
3205   dnl xkbcommon
3206   PKG_CHECK_MODULES([XKBCOMMON_X11], [xkbcommon-x11], [
3207     have_xkbcommon_x11="yes"
3208   ], [
3209     AC_MSG_WARN([${XKBCOMMON_X11_PKG_ERRORS}. Hotkeys are disabled.])
3210   ])
3211
3212   dnl xcb-utils
3213   PKG_CHECK_MODULES([XCB_KEYSYMS], [xcb-keysyms >= 0.3.4], [
3214     have_xcb_keysyms="yes"
3215   ], [
3216     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Global hotkeys are disabled.])
3217   ])
3218
3219   have_xcb="yes"
3220 ])
3221 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3222 AM_CONDITIONAL([HAVE_XKBCOMMON_X11], [test "${have_xkbcommon_x11}" = "yes"])
3223 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3224
3225
3226 dnl
3227 dnl VDPAU needs X11
3228 dnl
3229 AC_ARG_ENABLE([vdpau],
3230   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3231 have_vdpau="no"
3232 AS_IF([test "${enable_vdpau}" != "no"], [
3233   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3234     have_vdpau="yes"
3235     AS_IF([test "${no_x}" = "yes"], [
3236       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3237     ])
3238   ], [
3239     AS_IF([test -n "${enable_vdpau}"], [
3240       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3241     ])
3242   ])
3243 ])
3244 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3245
3246 have_avcodec_vdpau="no"
3247 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3248   case "${avfork}" in
3249     libav) av_vdpau_ver="56.10.0" ;;
3250     ffmpeg) av_vdpau_ver="56.19.100" ;;
3251   esac
3252   PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3253     have_avcodec_vdpau="yes"
3254     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3255   ], [
3256     AS_IF([test -n "${enable_vdpau}"], [
3257       AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3258     ], [
3259       AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3260     ])
3261   ])
3262 ])
3263 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3264
3265
3266 dnl
3267 dnl  Wayland
3268 dnl
3269 AC_ARG_ENABLE([wayland],
3270   AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)]))
3271
3272 have_wayland="no"
3273 AS_IF([test "${enable_wayland}" != "no"], [
3274   wl_err=""
3275
3276   dnl wayland
3277   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91],, [
3278     wl_err="$wl_err ${WAYLAND_CLIENT_PKG_ERRORS}."
3279   ])
3280   PKG_CHECK_MODULES([WAYLAND_CURSOR], [wayland-cursor],, [
3281     wl_err="$wl_err ${WAYLAND_CURSOR_PKG_ERRORS}."
3282   ])
3283   PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl],, [
3284     wl_err="$wl_err ${WAYLAND_EGL_PKG_ERRORS}."
3285   ])
3286   PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner >= 1.15], [
3287     WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3288   ], [
3289     wl_err="$wl_err ${WAYLAND_SCANNER_PKG_ERRORS}."
3290   ])
3291
3292   dnl wayland-protocols
3293   PKG_CHECK_MODULES([WAYLAND_PROTOCOLS], [wayland-protocols >= 1.15], [
3294     WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3295   ], [
3296     wl_err="$wl_err ${WAYLAND_PROTOCOLS_PKG_ERRORS}."
3297   ])
3298
3299   AS_IF([test -n "$wl_err"], [
3300     AS_IF([test -n "$enable_wayland"], [
3301       AC_MSG_ERROR([$wl_err])
3302     ], [
3303       AC_MSG_WARN([$wl_err])
3304     ])
3305   ], [
3306     have_wayland="yes"
3307   ])
3308
3309   dnl xkbcommon
3310   PKG_CHECK_MODULES([XKBCOMMON], [xkbcommon], [
3311     have_xkbcommon="yes"
3312   ], [
3313     AC_MSG_WARN([${XKBCOMMON_PKG_ERRORS}. Hotkeys are disabled.])
3314   ])
3315 ])
3316 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3317 AC_SUBST([WAYLAND_PROTOCOLS])
3318 AC_SUBST([WAYLAND_SCANNER])
3319 AM_CONDITIONAL([HAVE_XKBCOMMON], [test "${have_xkbcommon}" = "yes"])
3320
3321
3322 dnl
3323 dnl  SDL image decoder module
3324 dnl
3325 AC_ARG_ENABLE([sdl-image],
3326   AS_HELP_STRING([--enable-sdl-image], [SDL image support (default enabled)]))
3327 AS_IF([test "${enable_sdl_image}" != "no"],[
3328   PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3329     VLC_ADD_PLUGIN([sdl_image])
3330   ], [
3331     AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3332   ])
3333 ])
3334
3335 dnl
3336 dnl  freetype module
3337 dnl
3338 AC_ARG_ENABLE([freetype],
3339   AS_HELP_STRING([--enable-freetype],   [freetype support   (default auto)]))
3340 AC_ARG_ENABLE([fribidi],
3341   AS_HELP_STRING([--enable-fribidi],    [fribidi support    (default auto)]))
3342 AC_ARG_ENABLE([harfbuzz],
3343   AS_HELP_STRING([--enable-harfbuzz],   [harfbuzz support   (default auto)]))
3344 AC_ARG_ENABLE([fontconfig],
3345   AS_HELP_STRING([--enable-fontconfig], [fontconfig support (default auto)]))
3346
3347 AC_ARG_WITH([default-font],
3348     AS_HELP_STRING([--with-default-font=PATH],
3349         [Path to the default font]),
3350         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3351             "$withval", [Default font])])
3352 AC_ARG_WITH([default-monospace-font],
3353     AS_HELP_STRING([--with-default-monospace-font=PATH],
3354         [Path to the default font]),
3355         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3356             "$withval", [Default monospace font])])
3357
3358 AC_ARG_WITH([default-font-family],
3359     AS_HELP_STRING([--with-default-font-family=NAME],
3360         [Name of the default font family]),
3361         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3362             "$withval", [Default font family])])
3363 AC_ARG_WITH([default-monospace-font-family],
3364     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3365         [Name of the default font family]),
3366         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3367             "$withval", [Default monospace font family])])
3368
3369 have_freetype="no"
3370 have_fontconfig="no"
3371 have_fribidi="no"
3372 have_harfbuzz="no"
3373
3374 if test "${enable_freetype}" != "no"; then
3375    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3376       have_freetype="yes"
3377       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3378       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3379
3380     dnl fontconfig support
3381     AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3382       PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3383         have_fontconfig="yes"
3384       ], [
3385         AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3386       ])
3387     ])
3388
3389       dnl fribidi support
3390       if test "${enable_fribidi}" != "no"; then
3391         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3392           have_fribidi="yes"
3393           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3394           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3395         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3396       fi
3397
3398       dnl harfbuzz support
3399       if test "${have_fribidi}" != "no"; then
3400         if test "${enable_harfbuzz}" != "no"; then
3401           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3402             have_harfbuzz="yes"
3403             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3404             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3405           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3406         fi
3407       fi
3408   ],[
3409   AS_IF([test -n "${enable_freetype}"],[
3410     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3411     ])
3412   ])
3413 fi
3414
3415 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3416 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3417 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3418 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3419
3420 dnl
3421 dnl libass subtitle rendering module
3422 dnl
3423 AC_ARG_ENABLE([libass],
3424   AS_HELP_STRING([--enable-libass], [Subtitle support using libass (default enabled)]))
3425 AS_IF( [test "${enable_libass}" != "no"], [
3426   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
3427       [
3428         VLC_ADD_PLUGIN([libass])
3429
3430         if test "${have_fontconfig}" != "no"; then
3431             VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
3432             VLC_ADD_LIBS([libass],[${FONTCONFIG_LIBS}])
3433         fi
3434       ],[
3435         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
3436       ])
3437   ])
3438
3439 dnl
3440 dnl SAPI (text to Speech renderer for Windows)
3441 dnl
3442 AC_LANG_PUSH([C++])
3443 AC_CHECK_TYPES([ISpObjectToken],[
3444               have_sapi="yes"
3445             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3446               [#include <windows.h>
3447                #include <sapi.h>
3448                #include <sphelper.h>])
3449 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3450 AC_LANG_POP([C++])
3451
3452 dnl
3453 dnl  SVG module (text rendering and image decoding)
3454 dnl
3455 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3456 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3457
3458 dnl
3459 dnl  Windows DirectX module
3460 dnl
3461
3462 AC_ARG_ENABLE([directx],
3463   AS_HELP_STRING([--enable-directx],
3464     [Microsoft DirectX support (default enabled on Windows)]),, [
3465   AS_IF([test "${SYS}" = "mingw32"], [
3466     enable_directx="yes"
3467   ], [
3468     enable_directx="no"
3469   ])
3470 ])
3471 AS_IF([test "${enable_directx}" != "no"], [
3472   dnl DirectDraw
3473   AC_CHECK_HEADERS([ddraw.h], [
3474     VLC_ADD_PLUGIN([directdraw])
3475   ])
3476
3477   dnl OpenGL
3478   AC_CHECK_HEADERS([GL/glew.h], [
3479     AC_CHECK_HEADERS([GL/wglew.h], [
3480         VLC_ADD_PLUGIN([glwin32 wgl])
3481       ],, [
3482         #include <windows.h>
3483         #include <GL/glew.h>
3484       ])],, [
3485       #include <windows.h>
3486    ])
3487
3488   dnl Direct3D11
3489   AC_CHECK_HEADERS([d3d11.h], [
3490     VLC_ADD_PLUGIN([direct3d11 direct3d11_filters])
3491   ])
3492
3493   dnl Direct3D9
3494   AC_CHECK_HEADERS([d3d9.h], [
3495     VLC_ADD_PLUGIN([direct3d9])
3496     AC_CHECK_HEADERS([d3dx9effect.h])
3497
3498     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3499         [[#define COBJMACROS
3500           #include <d3d9.h>
3501           #include <dxva2api.h>
3502           #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3503           # error dxva2 too old
3504           #endif
3505         ]],[[;]])
3506       ],[
3507         VLC_ADD_PLUGIN([direct3d9_filters])
3508       ],
3509       [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3510
3511   ])
3512 ])
3513
3514 dnl
3515 dnl  Linux framebuffer module
3516 dnl
3517 AC_CHECK_HEADER([linux/fb.h], [
3518   VLC_ADD_PLUGIN([fb])
3519 ])
3520
3521 dnl
3522 dnl  Linux kernel mode setting module
3523 dnl
3524 PKG_ENABLE_MODULES_VLC([KMS], [], [libdrm >= 2.4.83], [Linux kernel mode setting output], [auto])
3525
3526 dnl
3527 dnl  libcaca plugin
3528 dnl
3529 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3530
3531 dnl
3532 dnl  OS/2 KVA plugin
3533 dnl
3534 AC_ARG_ENABLE([kva],
3535   AS_HELP_STRING([--enable-kva],
3536     [support the K Video Accelerator KVA (default enabled on OS/2)]),, [
3537   AS_IF([test "$SYS" = "os2"], [
3538     enable_kva="yes"
3539   ])
3540 ])
3541 have_kva="no"
3542 KVA_LIBS=""
3543 AS_IF([test "$enable_kva" != "no"], [
3544   AC_CHECK_HEADERS([kva.h], [
3545     have_kva="yes"
3546     AC_CHECK_LIB([kva], [main], [
3547       KVA_LIBS="-lkva"
3548     ])
3549   ])
3550 ])
3551 AC_SUBST([KVA_LIBS])
3552 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3553
3554 dnl
3555 dnl MMAL plugin
3556 dnl
3557 AC_ARG_ENABLE([mmal],
3558   AS_HELP_STRING([--enable-mmal],
3559     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3560 if test "${enable_mmal}" != "no"; then
3561   VLC_SAVE_FLAGS
3562   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3563   CPPFLAGS="${CPPFLAGS} -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux"
3564   AC_CHECK_HEADERS([interface/mmal/mmal.h],
3565     [ AC_CHECK_LIB([bcm_host], [vc_tv_unregister_callback_full], [
3566         have_mmal="yes"
3567         VLC_ADD_PLUGIN([mmal])
3568         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3569         VLC_ADD_CFLAGS([mmal],[ -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux ])
3570         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lmmal_core -lmmal_components -lmmal_util -lvchostif ]) ], [
3571           AS_IF([test "${enable_mmal}" = "yes"],
3572             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3573             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3574           ],
3575         [])
3576     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3577       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3578       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3579   VLC_RESTORE_FLAGS
3580 fi
3581 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3582
3583 dnl
3584 dnl  Audio plugins
3585 dnl
3586
3587 EXTEND_HELP_STRING([Audio plugins:])
3588
3589 dnl
3590 dnl  Pulseaudio module
3591 dnl
3592 AC_ARG_ENABLE([pulse],
3593   AS_HELP_STRING([--enable-pulse],
3594     [use the PulseAudio client library (default auto)]))
3595 have_pulse="no"
3596 AS_IF([test "${enable_pulse}" != "no"], [
3597   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3598     have_pulse="yes"
3599   ], [
3600     AS_IF([test "x${enable_pulse}" != "x"], [
3601       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3602     ])
3603   ])
3604 ])
3605 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3606
3607 dnl
3608 dnl  ALSA module
3609 dnl
3610 AC_ARG_ENABLE([alsa],
3611   AS_HELP_STRING([--enable-alsa],
3612     [support the Advanced Linux Sound Architecture (default auto)]),, [
3613   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3614     enable_alsa="yes"
3615   ])
3616 ])
3617 have_alsa="no"
3618 AS_IF([test "${enable_alsa}" != "no"], [
3619   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3620     have_alsa="yes"
3621   ], [
3622     AS_IF([test "x${enable_alsa}" != "x"], [
3623       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required. Pass --disable-alsa to ignore this error.])
3624     ])
3625   ])
3626 ])
3627 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3628
3629 dnl
3630 dnl  Open Sound System module
3631 dnl
3632 AC_ARG_ENABLE([oss],
3633   AS_HELP_STRING([--enable-oss],
3634     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)]),, [
3635   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3636     enable_oss="no"
3637   ])
3638 ])
3639 have_oss="no"
3640 OSS_LIBS=""
3641 AS_IF([test "$enable_oss" != "no"], [
3642   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3643     have_oss="yes"
3644     AC_CHECK_LIB([ossaudio], [main], [
3645       OSS_LIBS="-lossaudio"
3646     ])
3647   ])
3648 ])
3649 AC_SUBST([OSS_LIBS])
3650 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3651
3652 dnl
3653 dnl  OpenBSD sndio module
3654 dnl
3655 AC_ARG_ENABLE([sndio],
3656   AS_HELP_STRING([--disable-sndio],
3657     [support the OpenBSD sndio (default auto)]),, [
3658   AS_IF([test "$SYS" = "openbsd"], [
3659     enable_sndio="yes"
3660   ])
3661 ])
3662 have_sndio="no"
3663 AS_IF([test "$enable_sndio" != "no"], [
3664   AC_CHECK_HEADER([sndio.h], [
3665     have_sndio="yes"
3666   ])
3667 ])
3668 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3669
3670 dnl
3671 dnl  Windows Audio Session plugin
3672 dnl
3673 AC_ARG_ENABLE([wasapi],
3674   AS_HELP_STRING([--enable-wasapi],
3675     [use the Windows Audio Session API (default auto)])
3676 )
3677 have_wasapi="no"
3678 AS_IF([test "$enable_wasapi" != "no"], [
3679   AC_CHECK_HEADER([audioclient.h], [
3680     have_wasapi="yes"
3681   ], [
3682     AS_IF([test "x${enable_wasapi}" != "x"], [
3683       AC_MSG_ERROR([Windows Audio Session API not found.])
3684     ])
3685   ])
3686 ])
3687 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3688
3689 dnl
3690 dnl  JACK modules
3691 dnl
3692 AC_ARG_ENABLE([jack],
3693   AS_HELP_STRING([--disable-jack],
3694     [do not use jack (default auto)]))
3695 have_jack="no"
3696 AS_IF([test "${enable_jack}" != "no"], [
3697     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3698       [ have_jack=yes ],
3699       [
3700       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3701
3702       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3703       [ have_jack=yes ],
3704       [
3705       AS_IF([test -n "${enable_jack}"],
3706          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3707          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3708       ])
3709     ])
3710 ])
3711 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3712
3713 dnl
3714 dnl  OpenSLES Android
3715 dnl
3716 AC_ARG_ENABLE([opensles],
3717   AS_HELP_STRING([--enable-opensles], [Android OpenSL ES audio module (default disabled)]))
3718 if test "${HAVE_ANDROID}" = "1"; then
3719   if test "${enable_opensles}" = "yes"; then
3720       AC_CHECK_HEADERS([SLES/OpenSLES.h],
3721         [ VLC_ADD_PLUGIN([opensles_android]) ],
3722         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3723   fi
3724 fi
3725
3726 dnl
3727 dnl  Tizen audio
3728 dnl
3729 AC_ARG_ENABLE([tizen_audio],
3730   AS_HELP_STRING([--enable-tizen-audio],
3731     [Tizen audio module (default enabled on Tizen)]),, [
3732   AS_IF([test "$HAVE_TIZEN" = "1"], [
3733     enable_tizen_audio="yes"
3734   ])
3735 ])
3736 if test "${enable_tizen_audio}" = "yes"; then
3737   AC_CHECK_HEADERS([audio_io.h],
3738     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3739     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3740 fi
3741
3742 dnl
3743 dnl libsamplerate plugin
3744 dnl
3745 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3746
3747 dnl
3748 dnl  soxr module
3749 dnl
3750 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3751
3752 dnl
3753 dnl  OS/2 KAI plugin
3754 dnl
3755 AC_ARG_ENABLE([kai],
3756   AS_HELP_STRING([--enable-kai],
3757     [support the K Audio Interface KAI (default enabled on OS/2)]),, [
3758   AS_IF([test "$SYS" = "os2"], [
3759     enable_kai="yes"
3760   ])
3761 ])
3762 have_kai="no"
3763 KAI_LIBS=""
3764 AS_IF([test "$enable_kai" != "no"], [
3765   AC_CHECK_HEADERS([kai.h], [
3766     have_kai="yes"
3767     AC_CHECK_LIB([kai], [main], [
3768       KAI_LIBS="-lkai"
3769     ])
3770   ])
3771 ])
3772 AC_SUBST([KAI_LIBS])
3773 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3774
3775 dnl
3776 dnl  chromaprint audio track fingerprinter
3777 dnl
3778 m4_pushdef([libchromaprint_version], 0.6.0)
3779 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3780     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3781     AS_IF([test "${enable_chromaprint}" = "yes"],
3782         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3783         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3784          ),
3785     [(Chromaprint based audio fingerprinter)],[auto])
3786 m4_popdef([libchromaprint_version])
3787
3788 dnl
3789 dnl  Chromecast streaming support
3790 dnl
3791 m4_pushdef([protobuf_lite_version], 2.5.0)
3792 AC_ARG_VAR(PROTOC, [protobuf compiler])
3793 AC_CHECK_PROGS(PROTOC, protoc, no)
3794 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3795     AS_IF([test "x${PROTOC}" != "xno"], [
3796         build_chromecast="yes"
3797     ], [
3798     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3799     ])
3800 ], [
3801     AS_IF([test "${enable_chromecast}" = "yes"],
3802         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3803         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3804     )
3805     enable_chromecast="no"
3806 ], [(Chromecast streaming support)], [auto])
3807 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3808 m4_popdef([protobuf_lite_version])
3809
3810 dnl
3811 dnl  Interface plugins
3812 dnl
3813
3814 EXTEND_HELP_STRING([Interface plugins:])
3815
3816 dnl
3817 dnl QT
3818 dnl
3819 AC_ARG_ENABLE([qt],
3820   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)]),, [
3821   AS_IF([test "${enable_vlc}" != "no"], [enable_qt="yes"])
3822   AS_IF([test "${SYS}" = "darwin"], [
3823     enable_qt="no"
3824   ])
3825 ])
3826 have_qt5_x11="no"
3827 AS_IF([test "${enable_qt}" != "no"], [
3828   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.9.0 Qt5Widgets Qt5Gui Qt5Svg], [
3829       PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3830           have_qt5_x11="yes"
3831       ],[
3832           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3833       ])
3834       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3835       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3836       QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3837       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3838       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3839       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3840     ], [
3841       AS_IF([test -n "${enable_qt}"],[
3842         AC_MSG_ERROR([${QT_PKG_ERRORS}. If you want to build VLC without GUI, pass --disable-qt.])
3843       ],[
3844         AC_MSG_WARN([${QT_PKG_ERRORS}.])
3845       ])
3846       enable_qt="no"
3847     ])
3848 ])
3849
3850 AS_IF([test "${enable_qt}" != "no"], [
3851   ALIASES="${ALIASES} qvlc"
3852 ])
3853 AC_SUBST([QT_VERSION])
3854 AM_CONDITIONAL([ENABLE_QT], [test "$enable_qt" != "no"])
3855 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3856
3857 dnl
3858 dnl detect kde4-config patch (used for kde solids).
3859 dnl
3860 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3861 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3862   KDE4_CONFIG="kde4-config"
3863 ])
3864
3865 dnl
3866 dnl Simple test for skins2 dependency
3867 dnl
3868 AS_IF([test "$enable_qt" = "no"], [
3869   AS_IF([test "${enable_skins2}" = "yes"], [
3870     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3871   ], [
3872     enable_skins2="no"
3873     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3874   ])
3875 ])
3876
3877 dnl
3878 dnl Skins2 module
3879 dnl
3880 AC_ARG_ENABLE([skins2],
3881   AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)]))
3882 AS_IF([test "${enable_skins2}" != "no"], [
3883   have_skins_deps="yes"
3884
3885   dnl Win32
3886   AS_IF([test "${SYS}" = "mingw32"], [
3887     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3888     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3889   dnl OS/2
3890   ], [test "${SYS}" = "os2"], [
3891     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3892   dnl Linux/Unix
3893   ], [
3894     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3895     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3896     PKG_CHECK_MODULES([XCURSOR], [xcursor],, [have_skins_deps="no"])
3897     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3898     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3899     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} ${XCURSOR_LIBS} -lX11])
3900   ])
3901
3902   dnl we need freetype
3903   AS_IF([test "${have_freetype}" != "yes"], [
3904     have_skins_deps="no"
3905   ])
3906
3907   AS_IF([test "${have_skins_deps}" = "no"], [
3908     AS_IF([test "x${enable_skins2}" = "x"], [
3909       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3910     ], [
3911       AC_MSG_ERROR([Skins2 interface requires FreeType, libxcursor, libxpm, libxext and libxinerama])
3912     ])
3913     enable_skins2="no"
3914   ], [
3915     ALIASES="${ALIASES} svlc"
3916     enable_skins2="yes"
3917   ])
3918 ])
3919 AM_CONDITIONAL([BUILD_SKINS], [test "${enable_skins2}" = "yes"])
3920
3921 AC_ARG_ENABLE([libtar],
3922   AS_HELP_STRING([--enable-libtar], [libtar support for skins2 (default auto)]))
3923 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3924   AC_CHECK_HEADERS([libtar.h], [
3925     VLC_ADD_LIBS([skins2],[-ltar])
3926   ])
3927 ])
3928
3929 dnl
3930 dnl  MacOS X gui module
3931 dnl
3932 AC_ARG_ENABLE([macosx],
3933   AS_HELP_STRING([--enable-macosx], [Mac OS X gui support (default enabled on Mac OS X)]))
3934 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3935 then
3936
3937   dnl
3938   dnl If possible, use xcrun to find the right ibtool
3939   dnl
3940
3941   AC_PATH_PROG([XCRUN], [xcrun], [no])
3942   AS_IF([test ! "x${XCRUN}" = "xno"], [
3943     AC_MSG_CHECKING([for ibtool (using xcrun)])
3944     XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3945     AC_MSG_RESULT([${XIB}])
3946   ], [
3947     AC_MSG_WARN([Looking for tools without using xcrun])
3948   ])
3949
3950   AS_IF([test "x${XIB}" = "xno"], [
3951     AC_PATH_PROG(XIB, [ibtool], [no])
3952     AS_IF([test "x${XIB}" = "xno"], [
3953       AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3954     ])
3955   ])
3956 fi
3957 AM_CONDITIONAL([ENABLE_MACOSX_UI], [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3958
3959 dnl
3960 dnl  MacOS X sparkle update support
3961 dnl
3962 AC_ARG_ENABLE([sparkle],
3963   AS_HELP_STRING([--enable-sparkle], [Sparkle update support for OS X (default enabled on Mac OS X)]))
3964 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3965 then
3966   if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3967   then
3968     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3969   fi
3970
3971   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3972 fi
3973 AM_CONDITIONAL([HAVE_SPARKLE], [test "$enable_sparkle" != "no"])
3974
3975 dnl
3976 dnl  MacOS X breakpad creash reporter support
3977 dnl
3978 AC_ARG_WITH([breakpad],
3979   AS_HELP_STRING([--with-breakpad=URL], [Enable Breakpad reporter using given URL]), [], [with_breakpad=no])
3980
3981 AS_IF([test "$with_breakpad" != "no"], [
3982
3983   AS_IF([test "$with_breakpad" = "yes"], [
3984     AC_MSG_ERROR([You need to supply the CrashDragon Server URL as value for --with-breakpad])
3985   ])
3986
3987   AS_IF([test "$HAVE_OSX" = "1"], [
3988     AC_MSG_CHECKING([for Breakpad framework])
3989     AS_IF([test ! -d ${CONTRIB_DIR}/Breakpad.framework -a \
3990                 ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework], [
3991       AC_MSG_RESULT([no])
3992       with_breakpad="no"
3993       AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3994     ], [
3995       AC_MSG_RESULT([yes])
3996     ])
3997   ],[
3998     PKG_CHECK_MODULES([BREAKPAD], [breakpad-client], [
3999       LDFLAGS="${LDFLAGS} -Wl,--build-id"
4000     ], [
4001       AC_MSG_ERROR(["breakpad not found"])
4002     ])
4003   ])
4004 ])
4005
4006 AM_CONDITIONAL([HAVE_BREAKPAD], [test "$with_breakpad" != "no"])
4007 AS_IF([test "$with_breakpad" != "no"], [
4008   AC_SUBST([BREAKPAD_URL], ["${with_breakpad}"])
4009 ])
4010
4011 dnl
4012 dnl  Minimal Mac OS X module
4013 dnl
4014 AC_ARG_ENABLE([minimal-macosx],
4015   AS_HELP_STRING([--enable-minimal-macosx], [Minimal Mac OS X support (default disabled)]))
4016 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
4017 then
4018   VLC_ADD_PLUGIN([minimal_macosx])
4019 fi
4020
4021 dnl
4022 dnl Mac OS X fancy dmg build tool
4023 dnl
4024 if test "${HAVE_OSX}" = "1"
4025 then
4026   AC_PATH_PROG(DMGBUILD, dmgbuild, no)
4027   AS_IF([test "x${DMGBUILD}" = "xno"], [
4028     AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
4029   ])
4030 fi
4031 AM_CONDITIONAL([HAVE_DMGBUILD], [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
4032
4033 dnl
4034 dnl  VideoToolbox plugins
4035 AC_CHECK_HEADERS([VideoToolbox/VideoToolbox.h], [
4036     VLC_ADD_PLUGIN([videotoolbox])
4037     VLC_ADD_PLUGIN([cvpx])
4038   ])
4039
4040 dnl
4041 dnl  AudioToolbox MIDI plugin
4042 AC_CHECK_HEADERS([AudioToolbox/AudioToolbox.h], [
4043   VLC_ADD_PLUGIN([audiotoolboxmidi])
4044 ])
4045
4046 dnl
4047 dnl  ncurses module
4048 dnl
4049 AC_ARG_ENABLE([ncurses],
4050 AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)]))
4051 have_ncurses="no"
4052 AS_IF([test "${enable_ncurses}" != "no"] ,[
4053   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
4054     have_ncurses="yes"
4055     ALIASES="${ALIASES} nvlc"
4056   ], [
4057     AS_IF([test -n "${enable_ncurses}"], [
4058       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
4059     ])
4060   ])
4061 ])
4062 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
4063
4064 dnl
4065 dnl  Lirc plugin
4066 dnl
4067 AC_ARG_ENABLE([lirc],
4068   AS_HELP_STRING([--enable-lirc], [lirc support (default disabled)]))
4069 have_lirc="no"
4070 AS_IF([test "${enable_lirc}" = "yes"], [
4071   AC_CHECK_HEADER(lirc/lirc_client.h, [
4072     AC_CHECK_LIB([lirc_client], [lirc_init], [
4073       have_lirc="yes"
4074     ])
4075   ])
4076 ])
4077 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
4078
4079 dnl
4080 dnl  Bitstream
4081 dnl
4082 PKG_CHECK_MODULES([BITSTREAM], [bitstream > 1.4],[have_bitstream="yes"], [have_bitstream="no"])
4083 AM_CONDITIONAL([HAVE_BITSTREAM], [test "${have_bitstream}" = "yes"])
4084
4085 dnl
4086 dnl  SRT plugin
4087 dnl
4088 PKG_ENABLE_MODULES_VLC([SRT], [access_srt access_output_srt], [srt >= 1.2.2], [SRT input/output plugin], [auto], [], [], [-DENABLE_SRT])
4089
4090 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
4091 dnl
4092 dnl  goom visualization plugin
4093 dnl
4094 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
4095
4096 dnl
4097 dnl libprojectM visualization plugin
4098 dnl
4099 AC_ARG_ENABLE([projectm],
4100   AS_HELP_STRING([--enable-projectm], [projectM visualization plugin (default enabled)]))
4101 AS_IF([test "${enable_projectm}" != "no"],
4102   [
4103     PKG_CHECK_MODULES(PROJECTM, libprojectM,
4104     [
4105       VLC_ADD_PLUGIN([projectm])
4106       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
4107         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
4108         [ AC_MSG_WARN( [Using libprojectM version 1] )
4109       ])
4110     ],[
4111       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
4112     ])
4113   ])
4114
4115 dnl
4116 dnl Vovoid VSXu visualization plugin
4117 dnl
4118 AC_ARG_ENABLE([vsxu],
4119   AS_HELP_STRING([--enable-vsxu], [Vovoid VSXu visualization plugin (default auto)]))
4120 AS_IF([test "${enable_vsxu}" != "no"],
4121   [
4122     PKG_CHECK_MODULES(VSXU, libvsxu,
4123     [
4124       VLC_ADD_PLUGIN([vsxu])
4125     ],[
4126       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
4127     ])
4128   ])
4129
4130 EXTEND_HELP_STRING([Service Discovery plugins:])
4131 dnl
4132 dnl  Avahi-Zeroconf services discovery
4133 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
4134
4135 dnl
4136 dnl  libudev services discovery
4137 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
4138
4139 dnl
4140 dnl MTP devices services discovery
4141 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
4142
4143 dnl
4144 dnl UPnP Plugin (Intel SDK)
4145 dnl
4146 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
4147
4148 dnl
4149 dnl mDNS using libmicrodns
4150 dnl
4151 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
4152
4153
4154 EXTEND_HELP_STRING([Misc options:])
4155
4156 dnl
4157 dnl  libxml2 module
4158 dnl
4159 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4160
4161
4162 dnl
4163 dnl libgcrypt
4164 dnl
4165 AC_ARG_ENABLE([libgcrypt],
4166   AS_HELP_STRING([--disable-libgcrypt], [gcrypt support (default enabled)]))
4167 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
4168 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4169
4170 # require libgcrypt >= 1.6.0
4171 AS_IF([test "${enable_libgcrypt}" != "no"], [
4172   AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4173     VLC_SAVE_FLAGS
4174     CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4175     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4176 [#include <gcrypt.h>
4177 #if GCRYPT_VERSION_NUMBER < 0x010600
4178 #error
4179 #endif]])], [
4180       ac_cv_lib_gcrypt=yes
4181     ], [
4182       ac_cv_lib_gcrypt=no
4183     ])
4184     VLC_RESTORE_FLAGS
4185   ])
4186
4187   AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4188     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4189   ], [
4190     AS_IF([test "${enable_libgcrypt}" = "yes"], [
4191       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4192     ])
4193   ])
4194 ])
4195
4196 AS_IF([test -z "$GCRYPT_LIBS"], [
4197   GCRYPT_LIBS="-lgcrypt -lgpg-error"
4198 ])
4199
4200 AC_SUBST([GCRYPT_CFLAGS])
4201 AC_SUBST([GCRYPT_LIBS])
4202 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4203
4204 dnl
4205 dnl TLS/SSL
4206 dnl
4207 AC_ARG_ENABLE([gnutls],
4208   AS_HELP_STRING([--enable-gnutls], [GNU TLS TLS/SSL support (default enabled)]))
4209 AS_IF([test "${enable_gnutls}" != "no"], [
4210   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4211     VLC_ADD_PLUGIN([gnutls])
4212   ], [
4213     AS_IF([test -n "${enable_gnutls}"], [
4214       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4215     ])
4216   ])
4217 ])
4218
4219
4220 dnl
4221 dnl Taglib plugin
4222 dnl
4223 AC_ARG_ENABLE([taglib],
4224   AS_HELP_STRING([--disable-taglib],
4225     [do not use TagLib (default enabled)]))
4226 AS_IF([test "${enable_taglib}" != "no"], [
4227   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.11, [
4228     VLC_ADD_PLUGIN([taglib])
4229   ], [
4230     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4231 ])
4232
4233 dnl
4234 dnl  libsecret
4235 dnl
4236 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4237
4238 dnl
4239 dnl  kwallet
4240 dnl
4241 AC_ARG_ENABLE([kwallet],
4242   AS_HELP_STRING([--enable-kwallet],
4243     [use kwallet (via D-Bus) for keystore (default enabled)]))
4244 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4245   VLC_ADD_PLUGIN([kwallet])
4246 ])
4247
4248 dnl
4249 dnl update checking system
4250 dnl
4251 AC_ARG_ENABLE([update-check],
4252   AS_HELP_STRING([--enable-update-check], [update checking system (default disabled)]))
4253 if test "${enable_update_check}" = "yes"
4254 then
4255  AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4256     AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4257 fi
4258 AM_CONDITIONAL([UPDATE_CHECK], [test "${enable_update_check}" = "yes"])
4259
4260 dnl
4261 dnl OS X notification plugin
4262 dnl
4263 AC_ARG_ENABLE([osx_notifications],
4264   AS_HELP_STRING([--enable-osx-notifications],
4265     [macOS notification plugin (default disabled)]),,
4266   [enable_osx_notifications=no])
4267 AS_IF([test "${enable_osx_notifications}" != "no"], [
4268   VLC_ADD_PLUGIN([osx_notifications])
4269 ])
4270
4271 dnl
4272 dnl Libnotify notification plugin
4273 dnl
4274 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-3.0], [libnotify notification], [auto])
4275
4276 PKG_ENABLE_MODULES_VLC([MEDIALIBRARY], [medialibrary], [medialibrary], (medialibrary support), [auto])
4277
4278 dnl
4279 dnl  Endianness check
4280 dnl
4281 AC_C_BIGENDIAN
4282 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4283   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4284 ], [
4285   DEFS_BIGENDIAN=""
4286 ])
4287 AC_SUBST([DEFS_BIGENDIAN])
4288
4289 dnl
4290 dnl Where to install KDE solid .desktop
4291 dnl
4292 AC_ARG_WITH(kde-solid,
4293   AS_HELP_STRING([--with-kde-solid=PATH],
4294                  [KDE Solid actions directory (auto)]),, [
4295
4296 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" -a "${HAVE_ANDROID}" != "1" ; then
4297   with_kde_solid="yes"
4298 fi
4299 ])
4300 soliddatadir=""
4301 AS_IF([test "${with_kde_solid}" != "no"], [
4302   AS_IF([test "${with_kde_solid}" = "yes"], [
4303     kde4datadir="`${KDE4_CONFIG} --install data`"
4304     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4305     soliddatadir="${kde4datadir}/solid/actions"
4306   ], [
4307     soliddatadir="${with_kde_solid}"
4308   ])
4309 ])
4310 AC_SUBST([soliddatadir])
4311 AM_CONDITIONAL([KDE_SOLID], [test "x${soliddatadir}" != "x"])
4312
4313 dnl
4314 dnl  Find tools for win32 packaging
4315 dnl
4316 AS_IF([test "${SYS}" = "mingw32"], [
4317     dnl
4318     dnl Find makensis required to build the NSIS installer
4319     dnl
4320     nsis_major_required="3"
4321     nsis_version_ok="no"
4322     AC_PATH_PROG([MAKENSIS], [makensis], [no])
4323     AS_IF([test "$MAKENSIS" != "no"], [
4324         # Check version
4325         AC_MSG_CHECKING([makensis version])
4326         nsis_version=$($MAKENSIS -VERSION)
4327         AC_MSG_RESULT([$nsis_version])
4328         nsis_version_major=$(echo "$nsis_version" | awk -F \. '{print $1}' | sed 's/v//')
4329         # Check if major version is a valid number
4330         AS_IF([test -n "$nsis_version_major" && \
4331                test "$nsis_version_major" -eq "$nsis_version_major" 2> /dev/null], [
4332             # Do the version check using major version
4333             AS_IF([test "$nsis_version_major" -lt "$nsis_major_required"], [
4334                 AC_MSG_WARN([makensis too old, (needs ${nsis_major_required}.x, have ${nsis_version_major}.x)])
4335             ], [
4336                 nsis_version_ok="yes"
4337             ])
4338         ], [
4339             AC_MSG_WARN([failed to check the makensis version])
4340         ])
4341     ])
4342     dnl
4343     dnl Find 7zip
4344     dnl
4345     AC_PATH_PROG([SEVENZIP], [7z], [7z])
4346 ])
4347 AM_CONDITIONAL([HAVE_MAKENSIS], [test "x$MAKENSIS" != "xno" && test "$nsis_version_ok" = "yes"])
4348
4349 dnl
4350 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4351 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4352 dnl
4353 if test "${SYS}" = "mingw32"; then
4354     AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4355 fi
4356
4357 EXTEND_HELP_STRING([Components:])
4358
4359 dnl
4360 dnl  the VLC binary
4361 dnl
4362 AC_ARG_ENABLE([vlc],
4363   AS_HELP_STRING([--enable-vlc], [build the VLC media player (default enabled)]))
4364 AM_CONDITIONAL([BUILD_VLC], [test "${enable_vlc}" != "no"])
4365
4366 dnl
4367 dnl Fuzzer (at the end in order to don't mess dependencies FLAGS)
4368 dnl
4369 AS_VAR_IF(with_libfuzzer, no, [], [
4370     LIBS="-lstdc++ ${LIBM} -L${with_libfuzzer} -lFuzzer"
4371     AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc-guard, [
4372         AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard])
4373         AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard], [CXXFLAGS])
4374         AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp])
4375         AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp], [CXXFLAGS])
4376     ], [
4377         AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc, [
4378             AX_APPEND_FLAG([-fsanitize-coverage=trace-pc])
4379             AX_APPEND_FLAG([-fsanitize-coverage=trace-pc], [CXXFLAGS])
4380         ], [
4381             AC_MSG_ERROR([Sanitizer coverage not supported by your compiler])
4382         ])
4383     ])
4384 ])
4385
4386 dnl
4387 dnl  Stuff used by the program
4388 dnl
4389 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4390 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4391 AC_DEFINE_UNQUOTED([VERSION_MESSAGE], "${VERSION_MESSAGE}", [Simple version string])
4392 AC_DEFINE_UNQUOTED([COPYRIGHT_MESSAGE], "${COPYRIGHT_MESSAGE}", [Copyright string])
4393 AC_DEFINE_UNQUOTED([COPYRIGHT_YEARS], "${COPYRIGHT_YEARS}", [The copyright years])
4394 AC_DEFINE_UNQUOTED([CONFIGURE_LINE], "${CONFIGURE_LINE}", [The ./configure command line])
4395 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_MAJOR],${VERSION_MAJOR}, [version major number])
4396 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_MINOR],${VERSION_MINOR}, [version minor number])
4397 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_REVISION],${VERSION_REVISION}, [version revision number])
4398 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_EXTRA],${VERSION_EXTRA}, [version extra number])
4399 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_DEV],"${VERSION_DEV}", [version development string])
4400 AC_SUBST([COPYRIGHT_MESSAGE])
4401 AC_SUBST([VERSION_MESSAGE])
4402 AC_SUBST([VERSION_MAJOR])
4403 AC_SUBST([VERSION_MINOR])
4404 AC_SUBST([VERSION_REVISION])
4405 AC_SUBST([VERSION_EXTRA])
4406 AC_SUBST([COPYRIGHT_YEARS])
4407 AC_DEFINE_UNQUOTED([VLC_COMPILE_BY], "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4408 AC_DEFINE_UNQUOTED([VLC_COMPILE_HOST], "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4409 AC_DEFINE_UNQUOTED([VLC_COMPILER], "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4410 dnl
4411 dnl  Handle substvars that use $(top_srcdir)
4412 dnl
4413 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4414
4415 dnl
4416 dnl  Configuration is finished
4417 dnl
4418 AC_SUBST([SYS])
4419 AC_SUBST([ARCH])
4420 AC_SUBST([ALIASES])
4421 AC_SUBST([ASM])
4422 AC_SUBST([MOC])
4423 AC_SUBST([RCC])
4424 AC_SUBST([UIC])
4425 AC_SUBST([WINDRES])
4426 AC_SUBST([WINE_SDK_PATH])
4427 AC_SUBST([LIBEXT])
4428 AC_SUBST([AM_CPPFLAGS])
4429 AC_SUBST([MACOSX_DEPLOYMENT_TARGET])
4430 AC_SUBST([FILE_LIBVLCCORE_DLL])
4431 AC_SUBST([FILE_LIBVLC_DLL])
4432
4433 AC_CONFIG_FILES([
4434   Makefile
4435   doc/Makefile
4436   modules/Makefile
4437   m4/Makefile
4438   po/Makefile.in
4439   share/Makefile
4440   compat/Makefile
4441   src/Makefile
4442   lib/Makefile
4443   bin/Makefile
4444   test/Makefile
4445   modules/hw/mmal/Makefile
4446   share/vlc.appdata.xml.in
4447 ])
4448
4449 AM_COND_IF([HAVE_WIN32], [
4450   AC_CONFIG_FILES([
4451     extras/package/win32/NSIS/spad.nsi
4452     extras/package/win32/NSIS/vlc.win32.nsi
4453     extras/package/win32/msi/config.wxi
4454   ])
4455 ])
4456
4457 AM_COND_IF([HAVE_DARWIN], [
4458   AC_CONFIG_FILES([
4459     modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4460     share/macosx/Info.plist:share/Info.plist.in
4461   ])
4462 ])
4463
4464 dnl Generate makefiles
4465 AC_OUTPUT
4466
4467 dnl Do we have to use make or gmake ?
4468 if make --version 2>&1|grep -q GNU
4469 then
4470     # GNU make, all seems good
4471     MAKE=make
4472 else
4473     # Known GNU make alias (on BSD)
4474     MAKE=gmake
4475 fi
4476 dnl Shortcut to nice compile message
4477 if test -n $SHELL; then
4478   SHELL=${CONFIG_SHELL-/bin/sh}
4479 fi
4480 rm -f compile
4481 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4482 echo "#! $SHELL
4483 rm -f .error\$\$
4484 ERROR=0
4485 export PATH=\"$PATH\" LANG=C
4486 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4487 test -f .error\$\$ && ERROR=1
4488 rm -f .error\$\$
4489 exit \$ERROR" >compile
4490 chmod a+x compile
4491
4492 echo "
4493 libvlc configuration
4494 --------------------
4495 version               : ${VERSION}
4496 system                : ${SYS}
4497 architecture          : ${ARCH}
4498 optimizations         : ${enable_optimizations}"
4499 if test "${enable_vlc}" != "no"; then
4500 echo "vlc aliases           :${ALIASES}"
4501 else
4502 echo "build vlc executable  : no"
4503 fi
4504 echo "
4505 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."