| blob | 8cf88a4ec6b0b7f2485466313cbd291ac815eec9 |
1 dnl Autoconf settings for vlc
3 AC_COPYRIGHT([Copyright 1999-2018 VLC authors and VideoLAN])
5 AC_INIT([vlc], [4.0.0-dev])
6 VERSION_MAJOR=4
7 VERSION_MINOR=0
8 VERSION_REVISION=0
9 VERSION_EXTRA=0
10 VERSION_DEV=dev
12 PKGDIR="vlc"
13 AC_SUBST([PKGDIR])
15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
16 CODENAME="Otto Chriek"
17 COPYRIGHT_YEARS="1996-2018"
19 AC_CONFIG_SRCDIR([src/libvlc.c])
20 AC_CONFIG_AUX_DIR([autotools])
21 AC_CONFIG_MACRO_DIR([m4])
22 AC_CONFIG_LIBOBJ_DIR([compat])
23 AC_CANONICAL_BUILD
24 AC_CANONICAL_HOST
25 AC_PRESERVE_HELP_ORDER
27 AM_INIT_AUTOMAKE([tar-ustar color-tests foreign])
28 AC_CONFIG_HEADERS([config.h])
30 AM_SILENT_RULES([yes])
31 AM_MAINTAINER_MODE([enable])
33 dnl
34 dnl Check for tools
35 dnl
36 AC_PROG_CC
37 AC_USE_SYSTEM_EXTENSIONS
38 VLC_PROG_CC_C11
39 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
40 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
41 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
42 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
44 AC_PROG_CXX
45 AC_PROG_CPP
46 AC_PROG_OBJC
47 AC_PROG_EGREP
48 AC_PROG_MAKE_SET
49 AC_PROG_INSTALL
50 AM_PROG_AS
51 AC_PROG_LEX
52 AC_PROG_YACC
54 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
55 AC_CHECK_PROGS([DESKTOP_FILE_VALIDATE], [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
56 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
57 AC_CHECK_PROGS([BUILDCC], [c11-gcc c11 c99-gcc c99], [false])
58 AS_IF([test "$BUILDCC" = "false"], [
59 AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
60 ])
62 dnl Check for compiler properties
63 AC_C_CONST
64 AC_C_INLINE
65 AC_C_RESTRICT
66 AX_CXX_COMPILE_STDCXX_11([noext], [mandatory])
68 dnl Extend the --help string at the current spot.
69 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
71 dnl Allow binary package maintainer to pass a custom string to avoid
72 dnl cache problem
73 AC_ARG_WITH([binary-version],
74 AS_HELP_STRING([--with-binary-version=STRING],
75 [To avoid plugins cache problem between binary version]),[],[])
76 AS_IF([test -n "${with_binary_version}"],[
77 AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
78 [Binary specific version])
79 ])
81 dnl Prevent clang from accepting unknown flags with a mere warning
82 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CFLAGS])
83 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CXXFLAGS])
85 dnl
86 dnl Check the operating system
87 dnl
88 HAVE_WIN64="0"
89 HAVE_IOS="0"
90 HAVE_OSX="0"
91 HAVE_TVOS="0"
93 case "${host_os}" in
94 "")
95 SYS=unknown
96 ;;
97 linux*)
98 SYS=linux
99 CFLAGS="${CFLAGS} -pthread"
100 ;;
101 bsdi*)
102 SYS=bsdi
103 CFLAGS="${CFLAGS} -pthread"
104 ;;
105 freebsd*)
106 SYS=freebsd
107 CFLAGS="${CFLAGS} -pthread"
108 CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
109 LDFLAGS="${LDFLAGS} -L/usr/local/lib"
110 ac_cv_ld_z_defs=no
111 ;;
112 openbsd*)
113 SYS=openbsd
114 CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
115 LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
116 ;;
117 netbsd*)
118 SYS=netbsd
119 ;;
120 dragonfly*)
121 SYS=dragonfly
122 ;;
123 darwin*)
125 dnl Force gcc "-arch" flag
126 ARCH_flag=""
127 case "${host_cpu}" in
128 i?86)
129 ARCH_flag="-arch i386"
130 ;;
131 ppc64*)
132 ARCH_flag="-arch ppc64"
133 ;;
134 ppc*)
135 ARCH_flag="-arch ppc"
136 ;;
137 x86_64)
138 ARCH_flag="-arch x86_64"
139 ;;
140 arm*)
141 ac_cv_c_bigendian="no"
142 ac_cv_c_attribute_packed="no"
143 ;;
144 esac
146 SYS=darwin
147 CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
148 CXX="${CXX} -stdlib=libc++ -std=c++11"
149 CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
150 CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
151 OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
152 LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
153 VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
154 VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
156 AC_EGREP_CPP(yes,
157 [#import <TargetConditionals.h>
158 #if TARGET_OS_IPHONE
159 yes
160 #endif],
161 [HAVE_IOS="1"],
162 [HAVE_OSX="1"])
164 AC_EGREP_CPP(yes,
165 [#import <TargetConditionals.h>
166 #if TARGET_OS_TV
167 yes
168 #endif],
169 [HAVE_TVOS="1"
170 HAVE_IOS="0"
171 HAVE_OSX="0"
172 ],)
174 dnl
175 dnl Handle Mac OS X SDK flags
176 dnl
177 AC_ARG_WITH(macosx-sdk,
178 AS_HELP_STRING([--with-macosx-sdk=DIR],
179 [compile using the SDK in DIR]))
180 if test "${with_macosx_sdk}" != "" ; then
181 test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
182 CPP="${CPP} -isysroot ${with_macosx_sdk}"
183 CC="${CC} -isysroot ${with_macosx_sdk}"
184 CXX="${CXX} -isysroot ${with_macosx_sdk}"
185 OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
186 LD="${LD} -syslibroot ${with_macosx_sdk}"
187 fi
188 AC_ARG_WITH(macosx-version-min,
189 AS_HELP_STRING([--with-macosx-version-min=VERSION],
190 [compile for Mac OS X VERSION and above]))
191 if test "${with_macosx_version_min}" != "" ; then
192 CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
193 CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
194 CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
195 OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
196 LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
197 fi
198 ;;
199 *mingw32* | *cygwin* | *wince* | *mingwce*)
200 dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
201 dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
202 CXXFLAGS="${CXXFLAGS} -static-libgcc"
203 AC_CHECK_TOOL(WINDRES, windres, :)
204 AC_CHECK_TOOL(OBJCOPY, objcopy, :)
205 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
206 [[#ifdef _WIN32_WINNT
207 # error _WIN32_WINNT already defined
208 #endif
209 ]],[[;]])
210 ],[
211 AC_DEFINE([_WIN32_WINNT], 0x0601, [Define to '0x0601' for Windows 7 APIs.])
212 ])
213 AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
214 AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
215 AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
216 AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
217 AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
218 AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
219 AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
220 AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
221 AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
222 AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
223 AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
225 case "${host_os}" in
226 *mingw32*)
227 SYS=mingw32
228 ;;
229 *cygwin*)
230 dnl Check if we are using the mno-cygwin mode in which case we are
231 dnl actually dealing with a mingw32 compiler.
232 AC_EGREP_CPP(yes,
233 [#ifdef _WIN32
234 yes
235 #endif],
236 SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
237 ;;
238 esac
240 if test "${SYS}" = "mingw32"; then
241 # DEP, ASLR, NO SEH
242 LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
244 AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
245 ac_default_prefix="`pwd`/_win32"
246 DESTDIR="`pwd`/_win32/"
248 dnl
249 dnl NSIS/MSI Installer prefix and WIN64
250 dnl
251 case "${host_cpu}" in
252 amd64|x86_64)
253 HAVE_WIN64="1"
254 WINDOWS_ARCH="x64"
255 PROGRAMFILES="PROGRAMFILES64"
256 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
257 ;;
258 *)
259 WINDOWS_ARCH="x86"
260 PROGRAMFILES="PROGRAMFILES"
261 ;;
262 esac
263 AC_SUBST([WINDOWS_ARCH])
264 AC_SUBST([PROGRAMFILES])
266 fi
267 ;;
268 *nto*)
269 SYS=nto
270 ;;
271 solaris*)
272 SYS=solaris
273 ;;
274 hpux*)
275 SYS=hpux
276 ;;
277 *os2*)
278 SYS=os2
279 LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
280 AC_LIBOBJ([freeaddrinfo])
281 AC_LIBOBJ([gai_strerror])
282 AC_CHECK_FUNCS([if_nametoindex])
283 ;;
284 *nacl*)
285 SYS=nacl
286 AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
287 AC_LIBOBJ([sigwait])
288 AC_LIBOBJ([recvmsg])
289 AC_LIBOBJ([sendmsg])
290 ;;
291 *)
292 SYS="${host_os}"
293 ;;
294 esac
296 dnl WinRT
297 AC_ARG_ENABLE([winstore_app],
298 AS_HELP_STRING([--enable-winstore-app],
299 [Build targetted for Windows Store apps (default disabled)]))
301 vlc_winstore_app=0
302 AS_IF([test "${SYS}" = "mingw32"],[
303 LIBCOM="-lole32"
304 AS_IF([test "${enable_winstore_app}" = "yes"], [
305 vlc_winstore_app=1
306 LIBCOM=""
307 VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
308 AC_LIBOBJ([gai_strerror])
309 ],[])
310 AC_SUBST([LIBCOM])
311 ])
312 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
314 AM_CONDITIONAL([HAVE_LINUX], [test "${SYS}" = "linux"])
315 AM_CONDITIONAL([HAVE_OS2], [test "${SYS}" = "os2"])
317 AM_CONDITIONAL([HAVE_DARWIN], [test "${SYS}" = "darwin"])
318 AM_CONDITIONAL([HAVE_IOS], [test "${HAVE_IOS}" = "1"])
319 AM_CONDITIONAL([HAVE_OSX], [test "${HAVE_OSX}" = "1"])
320 AM_CONDITIONAL([HAVE_TVOS], [test "${HAVE_TVOS}" = "1"])
322 AM_CONDITIONAL([HAVE_NACL], [test "${SYS}" = "nacl"])
323 AM_CONDITIONAL([HAVE_LIBANL], [test "${HAVE_LIBANL}" = "1"])
325 AM_CONDITIONAL([HAVE_WIN32], [test "${SYS}" = "mingw32"])
326 AM_CONDITIONAL([HAVE_WIN64], [test "${HAVE_WIN64}" = "1"]) dnl Only used for the packaging
327 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
328 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
330 dnl
331 dnl Sadly autoconf does not think about testing foo.exe when ask to test
332 dnl for program foo on win32
333 case "${build_os}" in
334 cygwin|msys|mingw32)
335 ac_executable_extensions=".exe"
336 BUILDEXEEXT=".exe"
337 ;;
338 os2*)
339 BUILDEXEEXT=".exe"
340 ;;
341 *)
342 ;;
343 esac
344 AC_SUBST([BUILDEXEEXT])
346 dnl Android is linux, but a bit different
347 AS_IF([test "$SYS" = linux],[
348 AC_MSG_CHECKING([for an Android system])
349 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
350 [[#ifndef __ANDROID__
351 # error Not Android
352 #endif
353 ]],[[;]])
354 ],[
355 HAVE_ANDROID="1"
356 AC_MSG_RESULT([yes])
357 ],[
358 AC_MSG_RESULT([no])
359 ])
360 ])
361 AM_CONDITIONAL([HAVE_ANDROID], [test "${HAVE_ANDROID}" = "1"])
363 dnl Tizen (minimum SDK version: 2.3)
364 AS_IF([test "$SYS" = linux],[
365 AC_MSG_CHECKING([for Tizen])
366 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
367 [[#include <tizen.h>
368 ]],[[;]])
369 ],[
370 HAVE_TIZEN="1"
371 AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
372 AC_MSG_RESULT([yes])
373 ],[
374 AC_MSG_RESULT([no])
375 ])
376 ])
377 AM_CONDITIONAL([HAVE_TIZEN], [test "${HAVE_TIZEN}" = "1"])
379 dnl
380 dnl Check for the contrib directory
381 dnl
382 AC_ARG_WITH(contrib,
383 AS_HELP_STRING([--with-contrib[=DIR]],
384 [search for 3rd party libraries in DIR/include and DIR/lib])
385 )
386 AC_MSG_CHECKING([for 3rd party libraries path])
387 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
388 CONTRIB_DIR="${srcdir}/contrib/${host}"
389 AS_IF([test ! -d "${CONTRIB_DIR}"], [
390 echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
391 CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
392 AS_IF([test ! -d "${CONTRIB_DIR}"], [
393 echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
394 CONTRIB_DIR=""
395 AC_MSG_RESULT([not found])
396 ])
397 ])
398 ], [
399 AS_IF([test "${with_contrib}" != "no"], [
400 CONTRIB_DIR="${with_contrib}"
401 ], [
402 CONTRIB_DIR=""
403 AC_MSG_RESULT([disabled])
404 ])
405 ])
406 AS_IF([test -n "${CONTRIB_DIR}"], [
407 AS_IF([test -d "${CONTRIB_DIR}/lib"],[
408 CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
409 ], [
410 echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
411 CONTRIB_DIR=""
412 AC_MSG_RESULT([not usable])
413 ])
415 ])
416 AS_IF([test -n "${CONTRIB_DIR}"], [
417 AC_MSG_RESULT([${CONTRIB_DIR}])
418 CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
419 CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
420 CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
421 OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
422 export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:${CONTRIB_DIR}/share/pkgconfig:$PKG_CONFIG_PATH"
423 LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
425 AS_IF([test -z "$LUAC"], [
426 dnl Old contribs mixed cross-tools and cross-compiled executables
427 AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
428 LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
429 ])
431 dnl Newer contribs follow usual name space rules
432 AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
433 LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
434 ])
435 ])
437 AS_IF([test "${SYS}" = "darwin"], [
438 export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
439 export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
440 ])
441 ], [
442 AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
443 AC_MSG_ERROR([Third party libraries not found!])
444 ])
445 ])
446 AC_SUBST([CONTRIB_DIR])
448 dnl Add extras/tools to the PATH
449 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
450 AS_IF([test -d "${TOOLS_DIR}"], [
451 TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
452 export PATH="${TOOLS_DIR}":$PATH
453 ])
455 dnl
456 dnl Libtool
457 dnl It's very bad, but our former custom system was worst
458 dnl -- Courmisch
459 dnl
461 dnl override platform specific check for dependent libraries
462 dnl otherwise libtool linking of shared libraries will
463 dnl fail on anything other than pass_all.
464 AC_CACHE_VAL(lt_cv_deplibs_check_method,
465 [lt_cv_deplibs_check_method=pass_all])
467 LT_INIT([dlopen win32-dll shared disable-static])
468 LT_LANG([C++])
469 LT_LANG([Windows Resource])
471 DOLT
473 lt_cv_deplibs_check_method=pass_all
475 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
476 AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
477 ])
479 dnl
480 dnl Gettext stuff
481 dnl
482 AM_GNU_GETTEXT_VERSION([0.19.8])
483 AM_GNU_GETTEXT([external], [need-formatstring-macros])
485 dnl
486 dnl Iconv stuff
487 dnl
488 AM_ICONV
490 dnl
491 dnl checks for mingw
492 AS_IF([test "${SYS}" = "mingw32"], [
494 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
495 #if !defined(__MINGW32__)
496 # error Not compiling with mingw
497 #endif
498 ])], [
500 dnl Check for broken versions of mingw-runtime compatability library
501 AC_MSG_CHECKING(for broken mingw-runtime)
502 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
503 #include <_mingw.h>
504 #if defined(__MINGW64_VERSION_MAJOR)
505 # if __MINGW64_VERSION_MAJOR < 5
506 # error Update your mingw-w64! This one is too old.
507 # endif
508 #else
509 # error You cannot compile with Mingw. Use Mingw-w64!
510 #endif
511 ])], [
512 AC_MSG_RESULT([ok])
513 ], [
514 AC_MSG_RESULT([present])
515 AC_MSG_ERROR([LibVLC requires Mingw-w64 version 5.0 or higher!])
516 ])
518 dnl force use of mingw provided c99 *printf over msvcrt
519 CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
521 dnl Check for the need to include the mingwex lib for mingw32
522 VLC_SAVE_FLAGS
523 AC_CHECK_LIB([mingwex], [opendir],
524 AC_CHECK_LIB([mingw32], [opendir],,
525 [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
526 )
527 VLC_RESTORE_FLAGS
528 ], [
529 AC_MSG_RESULT([Not compiling with mingw])
530 ])
532 dnl Check for fnative-struct or mms-bitfields support for mingw32
533 AX_CHECK_COMPILE_FLAG([-mms-bitfields], [
534 AX_APPEND_FLAG([-mms-bitfields], [CFLAGS])
535 AX_APPEND_FLAG([-mms-bitfields], [CXXFLAGS])
536 # Check for the warning flag without "-Wno-", GCC accepts
537 # -Wno-<anything> for unsupported warnings, which can trigger
538 # other warnings instead.
539 AX_CHECK_COMPILE_FLAG([-Wincompatible-ms-struct], [
540 AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CFLAGS])
541 AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CXXFLAGS])
542 ])
543 ], [
544 AX_CHECK_COMPILE_FLAG([-fnative-struct], [
545 AX_APPEND_FLAG([-fnative-struct], [CFLAGS])
546 AX_APPEND_FLAG([-fnative-struct], [CXXFLAGS])
547 ])
548 ])
549 ])
552 dnl
553 dnl Buggy glibc prevention. Purposedly not cached.
554 dnl See sourceware.org bugs 5058 and 5443.
555 dnl Ubuntu alone has 20 bug numbers for this...
556 dnl
557 AC_MSG_CHECKING(for buggy GNU/libc versions)
558 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
559 #include <limits.h>
560 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
561 && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
562 # error GNU/libc with dcgettext killer bug!
563 #endif
564 ])], [
565 AC_MSG_RESULT([not present])
566 ], [
567 AC_MSG_RESULT([found])
568 AS_IF([test "x${enable_nls}" != "xno"], [
569 AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
570 work-around for this. Check with your distribution vendor on how to update the
571 glibc run-time. Alternatively, build with --disable-nls.])
572 ])
573 ])
575 dnl Plugin compilation stuff
577 VLC_LIBRARY_SUFFIX
579 dnl Check for system libs needed
580 need_libc=false
582 dnl Check for usual libc functions
583 AC_CHECK_FUNCS([accept4 daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty memalign mkostemp mmap open_memstream newlocale openat pipe2 pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp strptime uselocale])
584 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir flockfile fsync getdelim getpid lfind lldiv memrchr nrand48 poll recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tdestroy tfind timegm timespec_get strverscmp pathconf])
585 AC_REPLACE_FUNCS([gettimeofday])
586 AC_CHECK_FUNC(fdatasync,,
587 [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
588 ])
590 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
592 dnl mingw64 implements those as static inline, not functions with C linkage
593 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
594 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
595 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
596 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
598 dnl C11 static_assert()
599 AC_MSG_CHECKING([for static_assert in assert.h])
600 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
601 static_assert(1, "The impossible happened.");
602 ])], [
603 AC_MSG_RESULT([yes])
604 AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
605 ], [
606 AC_MSG_RESULT([no])
607 ])
609 # Windows CE does not have strcoll()
610 AC_FUNC_STRCOLL
612 dnl Check for non-standard system calls
613 case "$SYS" in
614 "linux")
615 AC_CHECK_FUNCS([eventfd vmsplice sched_getaffinity recvmmsg memfd_create])
616 ;;
617 "mingw32")
618 AC_CHECK_FUNCS([_lock_file])
619 ;;
620 esac
622 AH_BOTTOM([#include <vlc_fixups.h>])
624 dnl Check for struct pollfd
625 AC_CHECK_TYPES([struct pollfd],,,
626 [#include <sys/types.h>
627 #if HAVE_POLL
628 # include <poll.h>
629 #elif defined (_WIN32)
630 # include <winsock2.h>
631 #endif
632 ])
634 dnl Check for struct timespec
635 AC_CHECK_TYPES([struct timespec],,,
636 [#include <time.h>])
638 dnl Check for max_align_t
639 AC_CHECK_TYPES([max_align_t],,,
640 [#include <stddef.h>])
642 dnl Checks for socket stuff
643 VLC_SAVE_FLAGS
644 SOCKET_LIBS=""
645 AC_SEARCH_LIBS(connect, [socket], [
646 AS_IF([test "$ac_cv_search_connect" != "none required"], [
647 SOCKET_LIBS="$ac_cv_search_connect"
648 ])
649 ], [
650 AS_IF([test "${SYS}" = "mingw32"], [
651 SOCKET_LIBS="-lws2_32 -liphlpapi"
652 ])
653 ])
655 AC_SEARCH_LIBS([inet_pton], [nsl], [
656 AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
657 SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
658 ])
659 ],, [${SOCKET_LIBS}])
661 LIBS="${LIBS} ${SOCKET_LIBS}"
662 AC_LINK_IFELSE([
663 AC_LANG_PROGRAM([#ifdef _WIN32
664 #include <ws2tcpip.h>
665 #include <windows.h>
666 # if _WIN32_WINNT < 0x600
667 # error Needs vista+
668 # endif
669 #else
670 #include <sys/socket.h>
671 #include <arpa/inet.h>
672 #endif], [
673 char dst[[sizeof(struct in_addr)]];
674 inet_pton(AF_INET, "127.0.0.1", dst);
675 ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
676 AC_CHECK_TYPES([struct if_nameindex],,,[#include <net/if.h>])
677 AC_CHECK_FUNCS([if_nameindex])
678 VLC_RESTORE_FLAGS
679 AC_SUBST([SOCKET_LIBS])
681 dnl Check for socklen_t
682 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
683 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
684 ac_cv_type_socklen_t,
685 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
686 [#include <sys/types.h>
687 #ifdef _WIN32
688 # include <winsock2.h>
689 # include <ws2tcpip.h>
690 #else
691 # include <sys/socket.h>
692 #endif]], [[socklen_t len; len = 0;]])],
693 ac_cv_type_socklen_t=yes,
694 ac_cv_type_socklen_t=no)])
695 AS_IF([test "$ac_cv_type_socklen_t" = no],
696 [AC_DEFINE(socklen_t, int)])
698 dnl Check for struct sockaddr_storage
699 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
700 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
701 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
702 [AC_TRY_COMPILE(
703 [#include <sys/types.h>
704 #if defined( _WIN32 )
705 # include <winsock2.h>
706 #else
707 # include <sys/socket.h>
708 #endif], [struct sockaddr_storage addr;],
709 ac_cv_struct_sockaddr_storage=yes,
710 ac_cv_struct_sockaddr_storage=no)])
711 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
712 AC_DEFINE(sockaddr_storage, sockaddr)
713 AC_DEFINE(ss_family, sa_family)
714 ])
716 dnl FreeBSD has a gnugetopt library for this:
717 GNUGETOPT_LIBS=""
718 AC_CHECK_FUNC(getopt_long,, [
719 AC_CHECK_LIB([gnugetopt],[getopt_long], [
720 GNUGETOPT_LIBS="-lgnugetopt"
721 ])
722 ])
723 AC_SUBST([GNUGETOPT_LIBS])
725 AC_CHECK_LIB([m], [cos], [
726 LIBM="-lm"
727 ], [
728 LIBM=""
729 ])
730 AC_SUBST([LIBM])
732 AC_CHECK_LIB([m], [lrintf], [
733 AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
734 VLC_ADD_LIBS([skins2],[-lm])
735 ])
736 AC_CHECK_LIB([m], [nanf],
737 AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
738 )
739 AC_CHECK_LIB([m], [sincos], [
740 AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
741 ], [
742 AC_LIBOBJ([sincos])
743 ])
745 AC_MSG_CHECKING([_Thread_local support])
746 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
747 int main() {}])], [
748 AC_MSG_RESULT([ok])
749 AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
750 ],[ AC_MSG_RESULT([no])])
752 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
753 dnl check for its availability explicitely
754 AC_CHECK_HEADERS([threads.h])
756 AC_CHECK_LIB([anl],[getaddrinfo_a],[
757 AC_DEFINE(HAVE_LIBANL, 1, [Define to 1 if you have the anl library])
758 ])
760 dnl Check for dynamic plugins
761 LIBDL=""
762 have_dynamic_objects="no"
763 VLC_SAVE_FLAGS
764 AC_SEARCH_LIBS(dlsym, [dl svld], [
765 AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
766 LIBDL="$ac_cv_search_dlsym"
767 ])
768 have_dynamic_objects="yes"
769 ])
770 VLC_RESTORE_FLAGS
772 # Windows
773 AS_IF([test "${SYS}" = "mingw32"], [
774 LIBDL=""
775 have_dynamic_objects="yes" #assume we can use shared objects
776 ])
778 AC_ARG_WITH([libfuzzer],
779 AS_HELP_STRING([--with-libfuzzer=DIR],
780 [use libFuzzer library from DIR and triggers sanitize coverage (default disabled)]),
781 [],
782 [with_libfuzzer=no])
783 AS_VAR_IF(with_libfuzzer, no, [], [
784 enable_shared=no
785 enable_static=yes
786 enable_vlc=no
787 ])
788 AM_CONDITIONAL([HAVE_LIBFUZZER], [test "${with_libfuzzer}" != "no"])
790 AS_IF([test "${enable_shared}" = "no"], [
791 have_dynamic_objects=no
792 ])
793 AM_CONDITIONAL([HAVE_DYNAMIC_PLUGINS], [test "${have_dynamic_objects}" != "no"])
795 AC_SUBST([LIBDL])
797 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
798 AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
799 LIBRT="$ac_cv_search_clock_nanosleep"
800 ])
801 ], [
802 AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
803 AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
804 LIBRT="$ac_cv_search_nanosleep"
805 ])
806 ])
807 ])
808 AC_SUBST([LIBRT])
810 dnl
811 dnl Check for headers
812 dnl
814 dnl POSIX
815 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
816 AC_CHECK_HEADERS([net/if.h], [], [],
817 [
818 #include <sys/types.h>
819 #include <sys/socket.h>
820 ])
821 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
822 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
824 dnl BSD
825 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
827 dnl GNU/Linux
828 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
830 dnl MacOS
831 AC_CHECK_HEADERS([xlocale.h])
833 dnl Check if C++ headers define locale_t
834 AC_LANG_PUSH(C++)
835 AC_CACHE_CHECK([if C++ headers define locale_t],
836 [ac_cv_cxx_locale_t],
837 [ac_cv_cxx_locale_t=no
838 AC_TRY_COMPILE([#include <locale>], [locale_t loc;],
839 [ac_cv_cxx_locale_t=yes])])
840 if test "${ac_cv_cxx_locale_t}" != "no"; then
841 AC_DEFINE(HAVE_CXX_LOCALE_T, 1, Define to 1 if C++ headers define locale_t)
842 fi
843 AC_LANG_POP(C++)
845 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
846 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
847 AC_CHECK_TYPE(ssize_t,, [
848 AC_DEFINE(ssize_t, int)
849 ])
851 dnl It seems that autoconf detects pkg-config only during the first
852 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
853 dnl it is nested within a conditional block, so it was not working right.
854 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
855 AC_ARG_VAR(PKG_CONFIG_PATH,
856 [Paths where to find .pc not at the default location])
857 PKG_PROG_PKG_CONFIG()
859 dnl On some OS we need static linking
860 AS_IF([test -n "${PKG_CONFIG}" ],[
861 AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
862 PKG_CONFIG="${PKG_CONFIG} --static"
863 ])
864 ])
867 dnl
868 dnl Check for zlib.h and -lz if available
869 dnl
870 AC_CHECK_HEADERS([zlib.h], [ have_zlib=yes ], [ have_zlib=no ])
871 AM_CONDITIONAL([HAVE_ZLIB], [ test "${have_zlib}" = "yes" ])
872 if test "${have_zlib}" = "yes"
873 then
874 VLC_ADD_LIBS([sap],[-lz])
875 fi
878 dnl
879 dnl Domain name i18n support via GNU libidn
880 dnl
881 PKG_CHECK_MODULES([IDN], [libidn], [
882 have_libidn="yes"
883 AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
884 ], [
885 have_libidn="no"
886 ])
889 dnl Check for dbus
890 AC_ARG_ENABLE([dbus],
891 AS_HELP_STRING([--enable-dbus],
892 [compile D-Bus message bus support (default enabled)]))
893 have_dbus="no"
894 AS_IF([test "${enable_dbus}" != "no"], [
895 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
896 have_dbus="yes"
897 ], [
898 AS_IF([test -n "${enable_dbus}"], [
899 AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
900 ], [
901 AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
902 ])
903 ])
904 ])
905 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
908 dnl Check for systemd
909 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
910 have_systemd="yes"
911 ], [
912 AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
913 ])
914 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
917 EXTEND_HELP_STRING([Optimization options:])
918 dnl
919 dnl Compiler warnings
920 dnl
922 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security -Wduplicated-branches -Wduplicated-cond], [CFLAGS])
923 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security -Wduplicated-branches -Wduplicated-cond], [CXXFLAGS])
925 AX_APPEND_COMPILE_FLAGS([-Wbad-function-cast -Wwrite-strings -Wmissing-prototypes -Werror-implicit-function-declaration -Winit-self -Wlogical-op -Wshadow=local -Wmultistatement-macros], [CFLAGS])
926 AX_APPEND_COMPILE_FLAGS([-pipe], [CFLAGS])
928 dnl
929 dnl Debugging mode
930 dnl
931 AC_ARG_ENABLE([debug],
932 AS_HELP_STRING([--enable-debug],
933 [build with run-time assertions (default disabled)]),,
934 [enable_debug="no"])
935 AH_TEMPLATE(NDEBUG,
936 [Define to 1 if debug code should NOT be compiled])
937 AS_IF([test "${enable_debug}" != "no"], [
938 AC_CHECK_HEADERS([valgrind/valgrind.h])
939 ], [
940 AC_DEFINE(NDEBUG)
941 ])
943 dnl
944 dnl Profiling
945 dnl
946 AC_ARG_ENABLE([gprof],
947 AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)]),,
948 [enable_gprof="no"])
949 AS_IF([test "${enable_gprof}" != "no"], [
950 CFLAGS="${CFLAGS} -pg"
951 CXXFLAGS="${CXXFLAGS} -pg"
952 OBJCFLAGS="${OBJCFLAGS} -pg"
953 LDFLAGS="${LDFLAGS} -pg"
954 ])
956 AC_ARG_ENABLE([cprof],
957 AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)]),,
958 [enable_cprof="no"])
959 AS_IF([test "${enable_gprof}" != "no"], [
960 CFLAGS="${CFLAGS} -finstrument-functions"
961 CXXFLAGS="${CXXFLAGS} -finstrument-functions"
962 OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
963 LDFLAGS="${LDFLAGS} -finstrument-functions"
964 ])
966 dnl
967 dnl Test coverage
968 dnl
969 AC_ARG_ENABLE([coverage],
970 AS_HELP_STRING([--enable-coverage],
971 [build for test coverage (default disabled)]),,
972 [enable_coverage="no"])
973 AS_IF([test "${enable_coverage}" != "no"], [
974 CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
975 CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
976 LDFLAGS="-lgcov ${LDFLAGS}"
977 ])
979 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
980 VLC_SAVE_FLAGS
981 CFLAGS="${CFLAGS} -fvisibility=hidden"
982 CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
983 OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
984 AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
985 [ac_cv_c_visibility_hidden], [
986 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
987 ac_cv_c_visibility_hidden=yes
988 ], [
989 ac_cv_c_visibility_hidden=no
990 ])
991 ])
992 AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
993 ])
995 dnl
996 dnl Sanitizer flags
997 dnl
998 AC_ARG_WITH([sanitizer],
999 AS_HELP_STRING([--with-sanitizer=(address/memory/undefined/thread)],
1000 [build with sanitizer flags (default disabled)]),
1001 [],
1002 [with_sanitizer=no])
1004 AS_VAR_IF(with_sanitizer, no, [], [
1005 AX_CHECK_COMPILE_FLAG([-fsanitize=${with_sanitizer}], [
1006 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}])
1007 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [CXXFLAGS])
1008 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [LDFLAGS])
1009 ], [
1010 AC_MSG_ERROR(["-fsanitize=${with_sanitizer} not supported!"])
1011 ])
1012 AX_APPEND_FLAG([-g])
1013 AX_APPEND_FLAG([-g], [CXXFLAGS])
1015 AS_IF([test -z "${with_sanitizer##*address*}" ], [
1016 AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer -fsanitize=pointer-compare -fsanitize=pointer-subtract])
1017 AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer -fsanitize=pointer-compare -fsanitize=pointer-subtract], [CXXFLAGS])
1018 ])
1019 AS_IF([test -z "${with_sanitizer##*memory*}" ], [
1020 AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1021 AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1022 ])
1023 AS_IF([test -z "${with_sanitizer##*thread*}" ], [
1024 AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1025 AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1026 ])
1027 ])
1029 dnl
1030 dnl Enable/disable optimizations
1031 dnl
1032 AC_ARG_ENABLE([optimizations],
1033 AS_HELP_STRING([--disable-optimizations],
1034 [disable compiler optimizations (default enabled)]),,
1035 [enable_optimizations="yes"])
1037 dnl Check for various optimization flags
1038 AS_IF([test "${enable_optimizations}" != "no"], [
1040 dnl -O3 only in production builds
1041 AS_IF([test "${enable_debug}" = "no"], [
1042 VLC_SAVE_FLAGS
1043 CFLAGS="${CFLAGS} -O3"
1044 CXXFLAGS="${CXXFLAGS} -O3"
1045 OBJCFLAGS="${OBJCFLAGS} -O3"
1046 AC_CACHE_CHECK([if $CC accepts -O3], [ac_cv_c_o3], [
1047 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1048 ac_cv_c_o3=yes
1049 ], [
1050 ac_cv_c_o3=no
1051 ])
1052 ])
1053 AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1054 ])
1056 dnl Check for fast maths
1057 AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CFLAGS])
1058 AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CXXFLAGS])
1060 AH_BOTTOM([
1061 #if defined(_MSC_VER) && !defined(__clang__)
1062 # pragma fenv_access(off)
1063 # pragma fp_contract(on)
1064 #elif defined(__GNUC__)
1065 /* Not supported so far */
1066 #else
1067 # pragma STDC FENV_ACCESS OFF
1068 # pragma STDC FP_CONTRACT ON
1069 #endif
1070 ])
1072 dnl Check for -funroll-loops
1073 VLC_SAVE_FLAGS
1074 CFLAGS="${CFLAGS} -funroll-loops"
1075 CXXFLAGS="${CXXFLAGS} -funroll-loops"
1076 OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1077 AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1078 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1079 ac_cv_c_unroll_loops=yes
1080 ], [
1081 ac_cv_c_unroll_loops=no
1082 ])
1083 ])
1084 AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1086 AS_IF([test "$enable_debug" = "no"], [
1087 dnl Check for -fomit-frame-pointer
1088 VLC_SAVE_FLAGS
1089 CFLAGS="${CFLAGS} -fomit-frame-pointer"
1090 CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1091 OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1092 AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1093 [ac_cv_c_omit_frame_pointer], [
1094 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1095 ac_cv_c_omit_frame_pointer=yes
1096 ], [
1097 ac_cv_c_omit_frame_pointer=no
1098 ])
1099 ])
1100 AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1101 ])
1103 ])
1105 AC_ARG_ENABLE([ssp],
1106 AS_HELP_STRING([--disable-ssp],
1107 [disable stack smashing protection (default enabled for optimized builds)]), [],
1108 [enable_ssp="yes"])
1110 AS_IF([test "${enable_ssp}" != "no" -a "${enable_optimizations}" != "no"], [
1111 VLC_SAVE_FLAGS
1112 AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong])
1113 AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong], [CXXFLAGS])
1114 dnl Win32 requires linking to ssp for stack-protection
1115 AS_IF([test "${SYS}" = "mingw32"], [
1116 LDFLAGS="${LDFLAGS} -lssp"
1117 AC_CACHE_CHECK([if linker supports stack protectors], [ac_cv_ld_ssp], [
1118 AC_TRY_LINK([#include <stdio.h>],[char buf[100]; fgets(buf, sizeof(buf), stdin);], [
1119 ac_cv_ld_ssp="yes"
1120 ], [
1121 ac_cv_ld_ssp="no"
1122 ])
1123 ])
1124 AS_IF([test "${ac_cv_ld_ssp}" = "no"], [VLC_RESTORE_FLAGS])
1125 ])
1126 ])
1128 AS_IF([test "${SYS}" = "mingw32"], [
1129 dnl library for BCrypt APIs
1130 AS_IF([test "${vlc_winstore_app}" = 1],
1131 [LDFLAGS="${LDFLAGS} -lbcrypt"])
1132 ])
1134 VLC_SAVE_FLAGS
1135 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1136 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1137 AC_TRY_LINK([],, [
1138 ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1139 ], [
1140 ac_cv_ld_bsymbolic=""
1141 ])
1142 ])
1143 VLC_RESTORE_FLAGS
1144 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1145 AC_SUBST([SYMBOLIC_LDFLAGS])
1147 VLC_SAVE_FLAGS
1148 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1149 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1150 AC_TRY_LINK([],, [
1151 ac_cv_ld_z_defs="yes"
1152 ], [
1153 ac_cv_ld_z_defs="no"
1154 ])
1155 ])
1156 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1158 dnl Check for __attribute__((packed))
1159 AC_CACHE_CHECK([for __attribute__((packed))],
1160 [ac_cv_c_attribute_packed],
1161 [ac_cv_c_attribute_packed=no
1162 AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1163 [ac_cv_c_attribute_packed=yes])])
1164 if test "${ac_cv_c_attribute_packed}" != "no"; then
1165 AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1166 fi
1168 dnl
1169 dnl Check the CPU
1170 dnl
1171 case "${host_cpu}" in
1172 "")
1173 ARCH=unknown
1174 ;;
1175 armv*)
1176 ARCH="arm"
1177 host_cpu="arm"
1178 ;;
1179 *)
1180 ARCH="${host_cpu}"
1181 ;;
1182 esac
1184 dnl Check for backtrace() support
1185 AC_CHECK_HEADERS([execinfo.h])
1186 AC_CHECK_FUNCS([backtrace])
1188 dnl
1189 dnl default modules
1190 dnl
1191 ALIASES="${ALIASES} cvlc rvlc"
1193 dnl
1194 dnl Accelerated modules
1195 dnl
1197 dnl Check for fully working MMX intrinsics
1198 dnl We need support for -mmmx, we need <mmintrin.h>, and we also need a
1199 dnl working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1200 AC_ARG_ENABLE([mmx],
1201 AS_HELP_STRING([--disable-mmx],
1202 [disable MMX optimizations (default auto)]),,[
1203 case "${host_cpu}" in
1204 i?86|x86_64)
1205 enable_mmx="yes"
1206 ;;
1207 *)
1208 enable_mmx="no"
1209 ;;
1210 esac
1211 ])
1212 have_mmx="no"
1213 have_mmxext="no"
1214 AS_IF([test "${enable_mmx}" != "no"], [
1215 ARCH="${ARCH} mmx"
1216 VLC_SAVE_FLAGS
1217 CFLAGS="${CFLAGS} -mmmx"
1218 AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1219 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1220 [#include <mmintrin.h>
1221 #include <stdint.h>
1222 uint64_t frobzor;]], [
1223 [__m64 a, b, c;
1224 a = b = c = (__m64)frobzor;
1225 a = _mm_slli_pi16(a, 3);
1226 a = _mm_adds_pi16(a, b);
1227 c = _mm_srli_pi16(c, 8);
1228 c = _mm_slli_pi16(c, 3);
1229 b = _mm_adds_pi16(b, c);
1230 a = _mm_unpacklo_pi8(a, b);
1231 frobzor = (uint64_t)a;]])], [
1232 ac_cv_c_mmx_intrinsics=yes
1233 ], [
1234 ac_cv_c_mmx_intrinsics=no
1235 ])
1236 ])
1237 VLC_RESTORE_FLAGS
1238 AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1239 AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1240 ])
1242 VLC_SAVE_FLAGS
1243 CFLAGS="${CFLAGS} -mmmx"
1244 AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1245 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1246 void *p;
1247 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1248 ]])
1249 ], [
1250 ac_cv_mmx_inline=yes
1251 ], [
1252 ac_cv_mmx_inline=no
1253 ])
1254 ])
1255 AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1256 AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1257 have_mmx="yes"
1258 ])
1260 AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1261 [ac_cv_mmxext_inline], [
1262 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1263 void *p;
1264 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1265 ]])
1266 ], [
1267 ac_cv_mmxext_inline=yes
1268 ], [
1269 ac_cv_mmxext_inline=no
1270 ])
1271 ])
1272 VLC_RESTORE_FLAGS
1273 AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1274 AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1275 have_mmxext="yes"
1276 ])
1277 ])
1278 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1279 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1281 dnl Check for fully workin SSE2 intrinsics
1282 dnl We need support for -mmmx, we need <emmintrin.h>, and we also need a
1283 dnl working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1284 AC_ARG_ENABLE([sse],
1285 AS_HELP_STRING([--disable-sse],
1286 [disable SSE (1-4) optimizations (default auto)]),, [
1287 case "${host_cpu}" in
1288 i?86|x86_64)
1289 enable_sse=yes
1290 ;;
1291 *)
1292 enable_sse=no
1293 ;;
1294 esac
1295 ])
1296 have_sse2="no"
1297 AS_IF([test "${enable_sse}" != "no"], [
1298 ARCH="${ARCH} sse sse2"
1300 VLC_SAVE_FLAGS
1301 CFLAGS="${CFLAGS} -msse2"
1302 AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1303 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1304 [#include <emmintrin.h>
1305 #include <stdint.h>
1306 uint64_t frobzor;]], [
1307 [__m128i a, b, c;
1308 a = b = c = _mm_set1_epi64((__m64)frobzor);
1309 a = _mm_slli_epi16(a, 3);
1310 a = _mm_adds_epi16(a, b);
1311 c = _mm_srli_epi16(c, 8);
1312 c = _mm_slli_epi16(c, 3);
1313 b = _mm_adds_epi16(b, c);
1314 a = _mm_unpacklo_epi8(a, b);
1315 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1316 ac_cv_c_sse2_intrinsics=yes
1317 ], [
1318 ac_cv_c_sse2_intrinsics=no
1319 ])
1320 ])
1321 VLC_RESTORE_FLAGS
1322 AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1323 AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1324 ])
1326 VLC_SAVE_FLAGS
1327 CFLAGS="${CFLAGS} -msse"
1328 AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1329 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1330 void *p;
1331 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1332 ]])
1333 ], [
1334 ac_cv_sse_inline=yes
1335 ], [
1336 ac_cv_sse_inline=no
1337 ])
1338 ])
1340 AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1341 AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1342 ])
1344 AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1345 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1346 void *p;
1347 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1348 ]])
1349 ], [
1350 ac_cv_sse2_inline=yes
1351 ], [
1352 ac_cv_sse2_inline=no
1353 ])
1354 ])
1355 AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1356 AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1357 have_sse2="yes"
1358 ])
1360 # SSE3
1361 AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1362 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1363 void *p;
1364 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1365 ]])
1366 ], [
1367 ac_cv_sse3_inline=yes
1368 ], [
1369 ac_cv_sse3_inline=no
1370 ])
1371 ])
1373 AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1374 AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1375 # SSSE3
1376 AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1377 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1378 void *p;
1379 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1380 ]])
1381 ], [
1382 ac_cv_ssse3_inline=yes
1383 ], [
1384 ac_cv_ssse3_inline=no
1385 ])
1386 ])
1388 AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1389 AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1391 # SSE4.1
1392 AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1393 [ac_cv_sse4_1_inline], [
1394 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1395 void *p;
1396 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1397 ]])
1398 ], [
1399 ac_cv_sse4_1_inline=yes
1400 ], [
1401 ac_cv_sse4_1_inline=no
1402 ])
1403 ])
1405 AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1406 AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1408 # SSE4.2
1409 AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1410 [ac_cv_sse4_2_inline], [
1411 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1412 void *p;
1413 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1414 ]])
1415 ], [
1416 ac_cv_sse4_2_inline=yes
1417 ], [
1418 ac_cv_sse4_2_inline=no
1419 ])
1420 ])
1422 AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1423 AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1425 # SSE4A
1426 AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1427 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1428 void *p;
1429 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1430 ]])
1431 ], [
1432 ac_cv_sse4a_inline=yes
1433 ], [
1434 ac_cv_sse4a_inline=no
1435 ])
1436 ])
1437 VLC_RESTORE_FLAGS
1438 AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1439 AC_DEFINE([CAN_COMPILE_SSE4A], [1], [Define to 1 if SSE4A inline assembly is available.]) ])
1440 ])
1441 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1443 VLC_SAVE_FLAGS
1444 CFLAGS="${CFLAGS} -mmmx"
1445 have_3dnow="no"
1446 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1447 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1448 void *p;
1449 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1450 ]])
1451 ], [
1452 ac_cv_3dnow_inline=yes
1453 ], [
1454 ac_cv_3dnow_inline=no
1455 ])
1456 ])
1457 VLC_RESTORE_FLAGS
1458 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1459 AC_DEFINE([CAN_COMPILE_3DNOW], 1,
1460 [Define to 1 if 3D Now! inline assembly is available.])
1461 have_3dnow="yes"
1462 ])
1463 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1466 AC_ARG_ENABLE([neon],
1467 AS_HELP_STRING([--disable-neon],
1468 [disable NEON optimizations (default auto)]),, [
1469 AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1470 ])
1471 AS_IF([test "${enable_neon}" != "no"], [
1472 VLC_SAVE_FLAGS
1473 CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1474 AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1475 AC_COMPILE_IFELSE([
1476 AC_LANG_PROGRAM(,[[
1477 asm volatile("vqmovun.s64 d0, q1":::"d0");
1478 ]])
1479 ], [
1480 ac_cv_arm_neon="yes"
1481 ], [
1482 ac_cv_arm_neon="no"
1483 ])
1484 ])
1485 VLC_RESTORE_FLAGS
1486 ])
1487 AM_CONDITIONAL([HAVE_NEON], [test "${ac_cv_arm_neon}" = "yes"])
1489 AC_ARG_ENABLE([arm64],
1490 AS_HELP_STRING([--disable-arm64],
1491 [disable arm 64-bit optimizations (default auto)]),, [
1492 AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1493 ])
1494 AS_IF([test "${enable_arm64}" != "no"], [
1495 AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1496 AC_COMPILE_IFELSE([
1497 AC_LANG_PROGRAM(,[[
1498 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1499 ]])
1500 ], [
1501 ac_cv_arm64="yes"
1502 ], [
1503 ac_cv_arm64="no"
1504 ])
1505 ])
1506 ])
1507 AM_CONDITIONAL([HAVE_ARM64], [test "${ac_cv_arm64}" = "yes"])
1510 AC_ARG_ENABLE([altivec],
1511 AS_HELP_STRING([--disable-altivec],
1512 [disable AltiVec optimizations (default auto)]),, [
1513 AS_CASE("${host_cpu}", [powerpc*],
1514 [enable_altivec=yes], [enable_altivec=no])
1515 ])
1516 have_altivec="no"
1517 ALTIVEC_CFLAGS=""
1518 AS_IF([test "${enable_altivec}" = "yes"], [
1519 ARCH="${ARCH} altivec";
1520 VLC_SAVE_FLAGS
1521 AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1522 [ac_cv_altivec_inline],
1523 [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1524 ac_cv_altivec_inline="yes",
1525 [CFLAGS="${CFLAGS} -Wa,-maltivec"
1526 AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1527 [ac_cv_altivec_inline="-Wa,-maltivec"],
1528 ac_cv_altivec_inline=no)
1529 ])])
1530 VLC_RESTORE_FLAGS
1531 AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1532 AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1533 [Define to 1 if AltiVec inline assembly is available.])
1534 AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1535 ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1536 VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1537 ])
1538 have_altivec="yes"
1539 ])
1541 VLC_SAVE_FLAGS
1542 AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1543 [ac_cv_c_altivec], [
1544 CFLAGS="${CFLAGS} -maltivec"
1545 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1546 [#include <altivec.h>]], [
1547 [vec_ld(0, (unsigned char *)0);]])], [
1548 ac_cv_c_altivec="-maltivec"
1549 ], [
1550 ac_cv_c_altivec="no"
1551 ])
1552 ])
1553 VLC_RESTORE_FLAGS
1554 AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1555 CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1556 AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1557 VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1558 ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1559 VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1560 have_altivec="yes"
1561 ])
1562 AC_CHECK_HEADERS([altivec.h])
1564 VLC_SAVE_FLAGS
1565 LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1566 AC_CACHE_CHECK([if linker needs -framework vecLib],
1567 [ac_cv_ld_altivec],
1568 [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1569 VLC_RESTORE_FLAGS
1570 AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1571 VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1572 ])
1573 ])
1574 AC_SUBST([ALTIVEC_CFLAGS])
1575 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1577 dnl
1578 dnl Memory usage
1579 dnl
1580 AC_ARG_ENABLE([optimize-memory],
1581 AS_HELP_STRING([--enable-optimize-memory],
1582 [optimize memory usage over performance]))
1583 if test "${enable_optimize_memory}" = "yes"; then
1584 AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1585 fi
1587 dnl
1588 dnl Allow running as root (useful for people running on embedded platforms)
1589 dnl
1590 AC_ARG_ENABLE([run-as-root],
1591 AS_HELP_STRING([--enable-run-as-root],
1592 [allow running VLC as root (default disabled)]))
1593 AS_IF([test "${enable_run_as_root}" = "yes"],[
1594 AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1595 [Define to 1 to allow running VLC as root (uid 0).])
1596 ])
1598 dnl
1599 dnl Stream output
1600 dnl
1601 AC_ARG_ENABLE([sout],
1602 AS_HELP_STRING([--disable-sout],
1603 [disable streaming output (default enabled)]))
1604 AS_IF([test "${enable_sout}" != "no"], [
1605 AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1606 ])
1607 AM_CONDITIONAL([ENABLE_SOUT], [test "${enable_sout}" != "no"])
1609 dnl Lua modules
1610 AC_ARG_ENABLE([lua],
1611 AS_HELP_STRING([--disable-lua],
1612 [disable LUA scripting support (default enabled)]))
1613 if test "${enable_lua}" != "no"
1614 then
1615 PKG_CHECK_MODULES(LUA, lua5.2,
1616 [ have_lua=yes ],
1617 [
1618 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1620 PKG_CHECK_MODULES(LUA, lua5.1,
1621 [ have_lua=yes ],
1622 [
1623 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1624 PKG_CHECK_MODULES(LUA, lua >= 5.1,
1625 [ have_lua=yes ],
1626 [
1627 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1628 have_lua=yes
1629 AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1630 [],
1631 [ have_lua=no ] )
1632 AC_CHECK_LIB( lua5.2 , luaL_newstate,
1633 [LUA_LIBS="-llua5.2"],
1634 AC_CHECK_LIB( lua5.1 , luaL_newstate,
1635 [LUA_LIBS="-llua5.1"],
1636 AC_CHECK_LIB( lua51 , luaL_newstate,
1637 [LUA_LIBS="-llua51"],
1638 AC_CHECK_LIB( lua , luaL_newstate,
1639 [LUA_LIBS="-llua"],
1640 [ have_lua=no
1641 ], [-lm])
1642 )))
1643 ])
1644 ])
1645 ])
1646 if test "x${have_lua}" != "xyes" ; then
1647 AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1648 fi
1649 AC_ARG_VAR([LUAC], [LUA byte compiler])
1650 AS_IF([test -z "$LUAC"], [
1651 AC_CHECK_TOOL(LUAC, [luac], [false])
1652 ])
1653 AS_IF([test "${LUAC}" = "false"], [
1654 AC_MSG_ERROR([Could not find the LUA byte compiler.])
1655 ])
1656 AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1657 AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1658 ])
1659 fi
1660 AM_CONDITIONAL([BUILD_LUA], [test "${have_lua}" = "yes"])
1663 dnl
1664 dnl VideoLAN manager
1665 dnl
1666 AC_ARG_ENABLE([vlm],
1667 AS_HELP_STRING([--disable-vlm],
1668 [disable the stream manager (default enabled)]),,
1669 [enable_vlm="${enable_sout}"])
1670 AS_IF([test "${enable_vlm}" != "no"], [
1671 AS_IF([test "${enable_sout}" = "no"], [
1672 AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1673 ])
1674 AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1675 ])
1676 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1679 dnl
1680 dnl Addons manager storage and repositories modules
1681 dnl
1682 AC_ARG_ENABLE([addonmanagermodules],
1683 AS_HELP_STRING([--disable-addonmanagermodules],
1684 [disable the addons manager modules (default enabled)]))
1685 if test "${enable_addonmanagermodules}" != "no"
1686 then
1687 AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1688 fi
1689 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1692 dnl
1693 dnl Input plugins
1694 dnl
1696 EXTEND_HELP_STRING([Input plugins:])
1698 dnl
1699 dnl libarchive access module
1700 dnl
1701 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1703 dnl
1704 dnl live555 input
1705 dnl
1706 AC_ARG_ENABLE([live555],
1707 AS_HELP_STRING([--enable-live555],
1708 [enable RTSP input through live555 (default enabled)]))
1710 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1711 PKG_CHECK_MODULES(LIVE555, live555, [
1712 VLC_ADD_PLUGIN([live555])
1713 VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1714 VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1715 ], [
1716 AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1718 AC_LANG_PUSH(C++)
1719 VLC_SAVE_FLAGS
1721 dnl detect include paths
1722 AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1723 CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1724 ], [
1725 AS_IF([test "${SYS}" != "os2"], [
1726 LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1727 CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1728 ], [
1729 LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1730 CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1731 LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1732 ])
1733 ])
1735 dnl CPP Flags
1736 AS_IF([test "${SYS}" = "solaris"], [
1737 CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1738 ])
1739 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1740 LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1742 dnl version check
1743 AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1744 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1745 [#include <liveMedia_version.hh>
1746 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1747 # error BOOM
1748 #endif]])
1749 ], [
1750 ac_cv_live555="yes"
1751 ], [
1752 ac_cv_live555="no"
1753 ])
1754 ])
1756 AS_IF([test "$ac_cv_live555" = "no"], [
1757 AC_MSG_WARN([live555 is missing or its installed version is too old:
1758 Version 2011.12.23 or later is required to proceed.
1759 You can get an updated one from http://www.live555.com/liveMedia .])
1760 AS_IF([test -n "${enable_live555}"], [
1761 AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1762 ])
1763 ], [
1764 other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1765 other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1766 AS_IF([test "${SYS}" = "mingw32"], [
1767 # add ws2_32 for closesocket, select, recv
1768 other_libs="$other_libs -lws2_32"
1769 ])
1771 dnl We need to check for pic because live555 don't provide shared libs
1772 dnl and we want to build a plugins so we need -fPIC on some arch.
1773 VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1774 VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1775 AC_CHECK_LIB([liveMedia_pic], [main], [
1776 VLC_ADD_PLUGIN([live555])
1777 VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1778 ],[
1779 AC_CHECK_LIB([liveMedia], [main], [
1780 VLC_ADD_PLUGIN([live555])
1781 VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1782 ],[],[${other_libs}])
1783 ],[${other_libs_pic}])
1784 ])
1785 VLC_RESTORE_FLAGS
1786 AC_LANG_POP(C++)
1787 ])
1788 ])
1790 dnl
1791 dnl IIDC and DV FireWire input modules
1792 dnl
1793 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1794 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1796 dnl
1797 dnl - linsys modules: access module check for libzvbi
1798 dnl
1799 AC_ARG_ENABLE([linsys],
1800 AS_HELP_STRING([--enable-linsys],
1801 [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)]))
1802 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1803 VLC_ADD_PLUGIN([linsys_hdsdi])
1804 PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1805 VLC_ADD_PLUGIN([linsys_sdi])
1806 ], [
1807 AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1808 ])
1809 ])
1811 dnl
1812 dnl dvdread module: check for libdvdread
1813 dnl
1814 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1816 dnl
1817 dnl libdvdnav plugin
1818 dnl
1819 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1820 AS_IF([test "${enable_dvdnav}" != "no"], [
1821 AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1822 AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1823 AC_MSG_RESULT(yes)
1824 AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1825 ],[
1826 AC_MSG_RESULT(no)
1827 ])
1828 ])
1830 dnl
1831 dnl Blu-ray Disc Support with libbluray
1832 dnl
1833 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1835 dnl
1836 dnl OpenCV wrapper and example filters
1837 dnl
1838 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1841 dnl
1842 dnl libsmbclient plugin
1843 dnl
1844 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smbc], [smbclient], (SMB/CIFS support), [auto])
1846 dnl
1847 dnl liBDSM access module
1848 dnl
1849 AM_CONDITIONAL([HAVE_DSM], [test "$AS_TR_SH(with_dsm)" = "yes"])
1850 PKG_WITH_MODULES([DSM], [libdsm >= 0.2.0], [
1851 VLC_ADD_PLUGIN([dsm])
1852 VLC_ADD_CFLAGS([dsm], [$DSM_CFLAGS])
1853 VLC_ADD_LIBS([dsm], [$DSM_LIBS])
1854 have_dsm="yes"
1855 ],,[libdsm SMB/CIFS access/sd module], [auto])
1856 AM_CONDITIONAL([HAVE_DSM], [test "${have_dsm}" = "yes"])
1858 dnl
1859 dnl sftp access support
1860 dnl
1861 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1863 dnl
1864 dnl nfs access support
1865 dnl
1866 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1868 dnl
1869 dnl smb2 access support
1870 dnl
1871 PKG_ENABLE_MODULES_VLC([SMB2], [smb2], [libsmb2 >= 2.0.0], (support smb2 protocol via libsmb2), [auto])
1873 dnl
1874 dnl Video4Linux 2
1875 dnl
1876 AC_ARG_ENABLE([v4l2], AS_HELP_STRING([--disable-v4l2],
1877 [disable Video4Linux version 2 (default auto)]))
1878 have_v4l2="no"
1879 AS_IF([test "$enable_v4l2" != "no"], [
1880 AC_CHECK_HEADERS([linux/videodev2.h], [
1881 have_v4l2="yes"
1882 ])
1883 ])
1884 AM_CONDITIONAL([HAVE_V4L2], [test "${have_v4l2}" != "no"])
1886 dnl
1887 dnl special access module for Blackmagic SDI cards
1888 dnl
1889 AC_ARG_ENABLE([decklink],
1890 AS_HELP_STRING([--disable-decklink],
1891 [disable Blackmagic DeckLink SDI input (default auto)]))
1892 AC_ARG_WITH([decklink_sdk],
1893 AS_HELP_STRING([--with-decklink-sdk=DIR],
1894 [location of Blackmagic DeckLink SDI SDK]))
1895 have_decklink=no
1896 if test "${enable_decklink}" != "no"
1897 then
1898 if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1899 then
1900 VLC_ADD_CPPFLAGS([decklink decklinkoutput stream_out_sdi],[-I${with_decklink_sdk}/include])
1901 fi
1902 VLC_SAVE_FLAGS
1903 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1904 AC_LANG_PUSH([C++])
1905 AC_CHECK_HEADERS([DeckLinkAPIDispatch.cpp], [
1906 have_decklink=yes
1907 AS_IF([test "${SYS}" = "darwin"], [
1908 VLC_ADD_LIBS([decklink decklinkoutput],[-Wl,-framework,CoreFoundation])
1909 ])
1910 ], [
1911 AS_IF([test "${enable_decklink}" = "yes"], [
1912 AC_MSG_ERROR([Blackmagic DeckLink SDI include files not found!])
1913 ], [
1914 AC_MSG_WARN([Blackmagic DeckLink SDI include files not found, decklink disabled])
1915 ])
1916 ])
1917 AC_LANG_POP([C++])
1918 VLC_RESTORE_FLAGS
1919 fi
1920 AM_CONDITIONAL([HAVE_DECKLINK], [ test "${have_decklink}" != "no" ])
1923 dnl
1924 dnl Built-in CD-DA and VCD module
1925 dnl
1926 AC_ARG_ENABLE([vcd],
1927 AS_HELP_STRING([--disable-vcd],
1928 [disable built-in VCD and CD-DA support (default enabled)]))
1930 AC_ARG_ENABLE([libcddb],
1931 AS_HELP_STRING([--disable-libcddb],
1932 [disable CDDB for Audio CD (default enabled)]))
1934 if test "${enable_vcd}" != "no"
1935 then
1936 AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1937 AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1938 AC_MSG_RESULT(yes)
1939 VLC_ADD_PLUGIN([vcd cdda])
1940 ],[
1941 AC_MSG_RESULT(no)
1942 ])
1944 AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1945 AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1946 AC_MSG_RESULT(yes)
1947 VLC_ADD_PLUGIN([vcd cdda])
1948 AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1949 ],[
1950 AC_MSG_RESULT(no)
1951 ])
1953 AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1954 AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1955 AC_MSG_RESULT(yes)
1956 VLC_ADD_PLUGIN([vcd cdda])
1957 AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1958 ],[
1959 AC_MSG_RESULT(no)
1960 ])
1962 if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1963 then
1964 VLC_ADD_PLUGIN([vcd cdda])
1965 fi
1967 if test "$enable_libcddb" != "no"; then
1968 PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1969 HAVE_LIBCDDB=yes
1970 AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1971 VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1972 VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1973 ],:
1974 [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1975 HAVE_LIBCDDB=no])
1976 fi
1977 fi
1979 dnl
1980 dnl Linux DVB
1981 dnl
1982 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1983 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1984 [#include <linux/dvb/version.h>
1985 #if (DVB_API_VERSION < 5)
1986 # error Linux DVB API v3.2 and older are not supported.
1987 #endif
1988 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1989 # error Linux DVB API v5.0 is unsupported. Please update.
1990 #endif
1991 ]])], [
1992 ac_cv_linux_dvb_5_1=yes
1993 ], [
1994 ac_cv_linux_dvb_5_1=no
1995 ])])
1996 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1998 dnl
1999 dnl Screen capture module
2000 dnl
2001 AC_ARG_ENABLE([screen],
2002 AS_HELP_STRING([--enable-screen],
2003 [disable screen capture (default enabled)]))
2004 if test "${enable_screen}" != "no"; then
2005 if test "${SYS}" = "darwin"; then
2006 AC_CHECK_HEADERS([ApplicationServices/ApplicationServices.h], [
2007 VLC_ADD_PLUGIN([screen])
2008 ])
2009 fi
2010 fi
2011 AM_CONDITIONAL([HAVE_MAC_SCREEN], [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
2013 dnl
2014 dnl VNC/RFB access module
2015 dnl
2016 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
2018 dnl RDP/Remote Desktop access module
2019 dnl
2020 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
2022 dnl
2023 dnl AVFoundation
2024 AC_SUBST([have_avfoundation], ["no"])
2025 AC_ARG_ENABLE([macosx-avfoundation],
2026 AS_HELP_STRING([--enable-macosx-avfoundation], [Mac OS X avcapture (video) module (default enabled on Mac OS X)]))
2027 if test "x${enable_macosx_avfoundation}" != "xno" &&
2028 (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2029 then
2030 SAVED_LIBS="${LIBS}"
2031 LIBS="-framework AVFoundation"
2032 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2033 LIBS="${SAVED_LIBS}"
2034 if test "${have_avfoundation}" != "no"
2035 then
2036 VLC_ADD_PLUGIN([avcapture])
2037 fi
2038 fi
2039 AM_CONDITIONAL([HAVE_AVFOUNDATION], [test "${have_avfoundation}" != "no"])
2041 dnl
2042 dnl DCP plugin (using asdcplib)
2043 dnl
2044 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2045 AM_CONDITIONAL([HAVE_ASDCP], [test "${have_asdcp}" = "yes"])
2047 dnl
2048 dnl Demux plugins
2049 dnl
2051 EXTEND_HELP_STRING([Mux/Demux plugins:])
2053 dnl
2054 dnl libdvbpsi check for ts mux/demux
2055 dnl
2056 have_dvbpsi="no"
2057 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2058 AM_CONDITIONAL([HAVE_DVBPSI], [test "${have_dvbpsi}" = "yes"])
2061 dnl
2062 dnl GME demux plugin
2063 dnl
2064 AC_ARG_ENABLE([gme],
2065 AS_HELP_STRING([--enable-gme],
2066 [use Game Music Emu (default auto)]))
2067 AS_IF([test "${enable_gme}" != "no"], [
2068 AC_CHECK_HEADER([gme/gme.h], [
2069 AC_CHECK_LIB([gme], [gme_identify_header], [
2070 VLC_ADD_PLUGIN([gme])
2071 ], [
2072 AC_CHECK_LIB([gme], [gme_identify_extension], [
2073 VLC_ADD_LIBS([gme], [-lstdc++ $LIBM])
2074 VLC_ADD_PLUGIN([gme])
2075 ],, [-lstdc++ $LIBM])
2076 ])
2077 VLC_ADD_LIBS([gme], [-lgme])
2078 ], [
2079 AS_IF([test "x${enable_gme}" != "x"], [
2080 AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2081 ])
2082 ])
2083 ])
2086 dnl
2087 dnl SIDPlay plugin
2088 dnl
2089 AC_ARG_ENABLE([sid],
2090 AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)]))
2091 AS_IF([test "${enable_sid}" != "no"], [
2092 PKG_CHECK_MODULES(SID, [libsidplay2], [
2093 AC_LANG_PUSH(C++)
2094 oldCPPFLAGS="$CPPFLAGS"
2095 CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2096 AC_CHECK_HEADER([sidplay/builders/resid.h], [
2097 VLC_ADD_PLUGIN([sid])
2098 VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2099 VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2100 ], [
2101 AS_IF([test -n "${enable_sid}"],
2102 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2103 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2104 )
2105 ])
2106 CPPFLAGS="$oldCPPFLAGS"
2107 AC_LANG_POP(C++)
2108 ], [
2109 AS_IF([test "x${enable_sid}" = "xyes"],
2110 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2111 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2112 )
2113 ])
2114 ])
2117 dnl
2118 dnl ogg demux plugin
2119 dnl
2120 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2121 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2122 AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2123 ],[true])
2124 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2125 if test "${enable_sout}" != "no"; then
2126 dnl Check for libshout
2127 PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2128 fi
2130 dnl
2131 dnl matroska demux plugin
2132 dnl
2133 PKG_WITH_MODULES([MATROSKA], [libebml libmatroska], [
2134 VLC_ADD_PLUGIN([mkv])
2135 VLC_ADD_CFLAGS([mkv], [$MATROSKA_CFLAGS])
2136 VLC_ADD_LIBS([mkv], [$MATROSKA_LIBS])
2137 have_matroska="yes"
2138 ],,[MKV format support], [auto])
2139 AM_CONDITIONAL([HAVE_MATROSKA], [test "${have_matroska}" = "yes"])
2141 dnl
2142 dnl modplug demux plugin
2143 dnl
2144 AC_ARG_ENABLE([mod],
2145 AS_HELP_STRING([--disable-mod],
2146 [do not use libmodplug (default auto)]))
2147 if test "${enable_mod}" != "no" ; then
2148 PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2149 VLC_ADD_PLUGIN([mod])
2150 VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2151 VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2152 VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2153 ],[
2154 AS_IF([test -n "${enable_mod}"],
2155 [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2156 [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2157 ])
2158 fi
2160 dnl
2161 dnl mpc demux plugin
2162 dnl
2163 AC_ARG_ENABLE([mpc],
2164 AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)]))
2165 if test "${enable_mpc}" != "no"
2166 then
2167 AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2168 VLC_ADD_PLUGIN([mpc])
2169 VLC_ADD_LIBS([mpc],[-lmpcdec])])
2170 fi
2172 dnl
2173 dnl Codec plugins
2174 dnl
2176 EXTEND_HELP_STRING([Codec plugins:])
2178 dnl
2179 dnl wmafixed plugin
2180 dnl
2181 AC_ARG_ENABLE([wma-fixed],
2182 AS_HELP_STRING([--enable-wma-fixed], [libwma-fixed module (default disabled)]))
2183 if test "${enable_wma_fixed}" = "yes"
2184 then
2185 VLC_ADD_PLUGIN([wma_fixed])
2186 fi
2188 dnl
2189 dnl shine encoder plugin
2190 dnl
2191 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2194 dnl
2195 dnl openmax il codec plugin
2196 dnl
2197 AC_ARG_ENABLE([omxil],
2198 AS_HELP_STRING([--enable-omxil], [openmax il codec module (default disabled)]))
2199 if test "${enable_omxil}" = "yes"
2200 then
2201 VLC_ADD_PLUGIN([omxil])
2202 fi
2204 dnl
2205 dnl raspberry pi openmax il configuration
2206 dnl
2207 AC_ARG_ENABLE([rpi-omxil],
2208 AS_HELP_STRING([--enable-rpi-omxil], [openmax il configured for raspberry pi (default disabled)]))
2209 if test "${enable_rpi_omxil}" = "yes"
2210 then
2211 VLC_ADD_PLUGIN([omxil])
2212 VLC_ADD_CFLAGS([omxil],[-DRPI_OMX])
2213 fi
2215 dnl
2216 dnl CrystalHD codec plugin
2217 dnl
2218 AC_ARG_ENABLE([crystalhd],
2219 AS_HELP_STRING([--enable-crystalhd], [crystalhd codec plugin (default auto)]))
2220 if test "${enable_crystalhd}" != "no"; then
2221 AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2222 VLC_ADD_PLUGIN([crystalhd])
2223 VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2224 ],[
2225 if test "${SYS}" = "mingw32" ; then
2226 AC_CHECK_HEADERS([libcrystalhd/bc_dts_defs.h], [
2227 VLC_ADD_PLUGIN([crystalhd])
2228 AC_CHECK_HEADERS([libcrystalhd/bc_drv_if.h], [
2229 VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2230 ])
2231 ],[
2232 AS_IF([test x"${enable_crystalhd}" = "xyes"],
2233 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2234 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2235 ],[#define __LINUX_USER__
2236 #include <libcrystalhd/bc_dts_types.h>
2237 ])
2238 fi
2239 ],[
2240 #include <libcrystalhd/bc_dts_types.h>
2241 ])
2242 fi
2244 dnl
2245 dnl mad plugin
2246 dnl
2247 have_mad="no"
2248 MAD_CFLAGS=""
2249 MAD_LIBS=""
2251 AC_ARG_WITH(mad, AS_HELP_STRING([--with-mad=PATH], [path to libmad]), [
2252 enable_mad="yes"
2253 ], [
2254 with_mad="no"
2255 ])
2256 AS_IF([test "${with_mad}" != "no"], [
2257 MAD_CFLAGS="-I${with_mad}/include"
2258 MAD_LIBS="-L${with_mad}/lib"
2259 ])
2261 AC_ARG_ENABLE([mad],
2262 AS_HELP_STRING([--enable-mad], [libmad module (default enabled)]))
2263 AS_IF([test "${enable_mad}" != "no"], [
2264 VLC_SAVE_FLAGS
2265 CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2266 LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2267 AC_CHECK_HEADERS([mad.h], [
2268 AC_CHECK_LIB([mad], [mad_bit_init], [
2269 have_mad="yes"
2270 MAD_LIBS="${MAD_LIBS} -lmad"
2271 ])
2272 ])
2273 VLC_RESTORE_FLAGS
2274 AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2275 AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2276 ])
2277 ])
2278 AC_SUBST([MAD_CFLAGS])
2279 AC_SUBST([MAD_LIBS])
2280 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2282 dnl mpg123 plugin
2283 dnl
2284 dnl
2285 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2287 dnl
2288 dnl gstreamer stuff
2289 dnl
2290 AC_ARG_ENABLE([gst-decode],
2291 AS_HELP_STRING([--enable-gst-decode], [GStreamer based decoding support (currently supports only video decoding) (default auto)]))
2293 have_gst_decode="no"
2294 AS_IF([test "${enable_gst_decode}" != "no"], [
2295 PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2296 PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2297 have_gst_decode="yes"
2298 ], [
2299 AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2300 ])
2301 ], [
2302 AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2303 ])
2304 ])
2305 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2307 dnl
2308 dnl avcodec decoder/encoder plugin
2309 dnl
2310 AC_ARG_ENABLE([merge-ffmpeg],
2311 AS_HELP_STRING([--enable-merge-ffmpeg], [merge FFmpeg-based plugins (default disabled)]),, [
2312 enable_merge_ffmpeg="no"
2313 ])
2314 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2316 AC_MSG_CHECKING([for libavutil variant])
2317 PKG_CHECK_EXISTS([libavutil], [
2318 libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2319 libavutil_micro="${libavutil_version##*.}"
2320 AS_IF([test ${libavutil_micro} -le 99], [
2321 avfork="libav"
2322 ], [
2323 avfork="ffmpeg"
2324 ])
2325 ], [
2326 avfork="none"
2327 ])
2328 AC_MSG_RESULT([${avfork}])
2330 AC_ARG_ENABLE([avcodec],
2331 AS_HELP_STRING([--enable-avcodec], [libavcodec codec (default enabled)]))
2332 AS_IF([test "${enable_avcodec}" != "no"], [
2333 dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2334 case "${avfork}" in
2335 libav) av_codec_ver="57.16.0" ;;
2336 dnl 05f66706d182eb0c36af54d72614bf4c33e957a9 includes libavutil 55.9.0
2337 ffmpeg) av_codec_ver="57.37.100" ;;
2338 dnl 7fc329e2dd6226dfecaa4a1d7adf353bf2773726 include libavutil 55.22.101
2339 *) AC_MSG_ERROR([Missing libav or FFmpeg. Pass --disable-avcodec to ignore this error.])
2340 esac
2341 PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 55.9.0], [
2342 VLC_SAVE_FLAGS
2343 CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2344 CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2345 AC_CHECK_HEADERS([libavcodec/avcodec.h])
2346 AC_CHECK_HEADERS([libavutil/avutil.h])
2347 VLC_RESTORE_FLAGS
2348 have_avcodec="yes"
2349 ],[
2350 AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2351 ])
2352 ], [
2353 have_avcodec="no"
2354 ])
2355 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2357 dnl
2358 dnl libva needs avcodec
2359 dnl
2360 AC_ARG_ENABLE([libva],
2361 AS_HELP_STRING([--enable-libva], [VAAPI GPU decoding support (libVA) (default auto)]))
2363 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2364 AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2365 ])
2367 have_vaapi="no"
2368 have_vaapi_drm="no"
2369 have_vaapi_x11="no"
2370 have_vaapi_wl="no"
2371 AS_IF([test "${enable_libva}" != "no"], [
2372 PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2373 have_vaapi="yes"
2374 ], [
2375 AS_IF([test -n "${enable_libva}"], [
2376 AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2377 ], [
2378 AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2379 ])
2380 ])
2381 PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2382 have_vaapi_drm="yes"
2383 ], [
2384 AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2385 ])
2386 PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2387 have_vaapi_x11="yes"
2388 ], [
2389 AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2390 ])
2391 PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2392 have_vaapi_wl="yes"
2393 ], [
2394 AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2395 ])
2396 ])
2397 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2398 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2399 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2400 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2402 have_avcodec_vaapi="no"
2403 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2404 VLC_SAVE_FLAGS
2405 CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2406 CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2407 AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2408 AC_MSG_NOTICE([VA API acceleration activated])
2409 have_avcodec_vaapi="yes"
2410 ],[
2411 AS_IF([test -n "${enable_libva}"], [
2412 AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2413 ], [
2414 AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2415 ])
2416 ])
2417 VLC_RESTORE_FLAGS
2418 ])
2419 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2421 dnl
2422 dnl dxva2 needs avcodec
2423 dnl
2424 AC_ARG_ENABLE([dxva2],
2425 AS_HELP_STRING([--enable-dxva2], [DxVA2 GPU decoding support (default auto)]))
2427 have_avcodec_dxva2="no"
2428 AS_IF([test "${enable_dxva2}" != "no"], [
2429 if test "${SYS}" = "mingw32"; then
2430 AS_IF([test "x${have_avcodec}" = "xyes"], [
2431 AC_CHECK_HEADERS([dxva2api.h],
2432 [
2433 AC_CHECK_HEADERS([libavcodec/dxva2.h], [
2434 AC_MSG_NOTICE([DxVA2 acceleration activated])
2435 have_avcodec_dxva2="yes"
2436 ],[
2437 AS_IF([test "${enable_dxva2}" = "yes"],
2438 [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2439 [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2440 ], [#undef _WIN32_WINNT
2441 /* DXVA2 is only available in Vista and above */
2442 #define _WIN32_WINNT 0x600])
2443 ],[
2444 AS_IF([test "${enable_dxva2}" = "yes"],
2445 [AC_MSG_ERROR([Could not find required dxva2api.h])],
2446 [AC_MSG_WARN([dxva2api.h not found])])
2447 ],[#include <d3d9.h>])
2448 ],[
2449 AS_IF([test "x${enable_dxva2}" != "x"], [
2450 AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2451 ])
2452 ])
2453 fi
2454 ])
2455 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2457 dnl
2458 dnl d3d11va needs avcodec
2459 dnl
2460 AC_ARG_ENABLE([d3d11va],
2461 AS_HELP_STRING([--enable-d3d11va], [D3D11 GPU decoding support (default auto)]))
2463 have_avcodec_d3d11va="no"
2464 AS_IF([test "${enable_d3d11va}" != "no"], [
2465 if test "${SYS}" = "mingw32"; then
2466 AS_IF([test "x${have_avcodec}" = "xyes"], [
2467 AC_CHECK_TYPES([ID3D11VideoDecoder],
2468 [
2469 AC_CHECK_HEADERS([dxva2api.h],
2470 [
2471 AC_CHECK_HEADERS([libavcodec/d3d11va.h], [
2472 AC_MSG_NOTICE([D3D11 acceleration activated])
2473 AC_DEFINE([HAVE_AVCODEC_D3D11VA], [1], [Define if the d3d11va module is built])
2474 have_avcodec_d3d11va="yes"
2475 ],[
2476 AS_IF([test "${enable_d3d11va}" = "yes"],
2477 [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2478 [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2479 ], [#undef _WIN32_WINNT
2480 /* D3D11 is only available in Vista and above */
2481 #define _WIN32_WINNT 0x600])
2482 ],[
2483 AS_IF([test "${enable_d3d11va}" = "yes"],
2484 [AC_MSG_ERROR([Could not find required dxva2api.h])],
2485 [AC_MSG_WARN([dxva2api.h not found])])
2486 ],[#include <d3d9.h>])
2487 ],[
2488 AS_IF([test "${enable_d3d11va}" = "yes"],
2489 [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2490 [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2491 ], [#include <d3d11.h>])
2492 ],[
2493 AS_IF([test "x${enable_d3d11va}" != "x"], [
2494 AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2495 ])
2496 ])
2497 fi
2498 ])
2499 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2501 dnl
2502 dnl DXGI debug
2503 dnl
2504 AC_CHECK_HEADERS([dxgidebug.h dxgi1_6.h])
2506 dnl
2507 dnl avformat demuxer/muxer plugin
2508 dnl
2510 AC_ARG_ENABLE([avformat],
2511 AS_HELP_STRING([--enable-avformat], [libavformat containers (default enabled)]),, [
2512 enable_avformat="${have_avcodec}"
2513 ])
2514 have_avformat="no"
2515 AS_IF([test "${enable_avformat}" != "no"], [
2516 PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2517 have_avformat="yes"
2518 VLC_SAVE_FLAGS
2519 CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2520 CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2521 AC_CHECK_HEADERS([libavformat/avformat.h libavformat/avio.h])
2522 AC_CHECK_HEADERS([libavcodec/avcodec.h])
2523 AC_CHECK_HEADERS([libavutil/avutil.h])
2524 AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2525 have_avformat="no"
2526 ])
2527 VLC_RESTORE_FLAGS
2528 ],[
2529 AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2530 ])
2531 ])
2532 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2534 dnl
2535 dnl swscale image scaling and conversion plugin
2536 dnl
2538 AC_ARG_ENABLE([swscale],
2539 AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2540 (default enabled)]))
2541 if test "${enable_swscale}" != "no"
2542 then
2543 PKG_CHECK_MODULES(SWSCALE,[libswscale],
2544 [
2545 VLC_SAVE_FLAGS
2546 CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2547 CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2548 AC_CHECK_HEADERS([libswscale/swscale.h])
2549 AC_CHECK_HEADERS([libavutil/avutil.h])
2550 VLC_ADD_PLUGIN([swscale])
2551 VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2552 VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2553 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2554 VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2555 ])
2556 VLC_RESTORE_FLAGS
2557 ],[
2558 AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2559 ])
2560 fi
2562 dnl
2563 dnl postproc plugin
2564 dnl
2566 AC_ARG_ENABLE([postproc],
2567 AS_HELP_STRING([--enable-postproc], [libpostproc image post-processing (default auto)]))
2568 if test "${enable_postproc}" != "no"
2569 then
2570 PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2571 [
2572 VLC_SAVE_FLAGS
2573 CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2574 CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2575 AC_CHECK_HEADERS([postproc/postprocess.h])
2576 VLC_ADD_PLUGIN([postproc])
2577 VLC_RESTORE_FLAGS
2578 ],[
2579 AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2580 ])
2581 fi
2583 dnl
2584 dnl faad decoder plugin
2585 dnl
2586 AC_ARG_ENABLE([faad],
2587 AS_HELP_STRING([--enable-faad], [faad codec (default auto)]))
2588 have_faad="no"
2589 AS_IF([test "${enable_faad}" != "no"], [
2590 AC_CHECK_HEADERS([neaacdec.h], [
2591 AC_CHECK_LIB([faad], [NeAACDecOpen], [have_faad="yes"],, [$LIBM])
2593 AS_IF([test "${have_faad}" = "yes"], [
2594 VLC_ADD_PLUGIN([faad])
2595 VLC_ADD_LIBS([faad],[-lfaad])
2596 ], [
2597 AS_IF([test "${enable_faad}" = "yes"], [
2598 AC_MSG_ERROR([cannot find FAAD library])
2599 ], [
2600 AC_MSG_WARN([cannot find FAAD library])
2601 ])
2602 ])
2603 ])
2604 ])
2606 dnl
2607 dnl AOM decoder plugin
2608 dnl
2609 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec (default auto)])
2611 dnl
2612 dnl Dav1d decoder plugin
2613 dnl
2614 PKG_ENABLE_MODULES_VLC([DAV1D], [], [dav1d], [AV1 decoder (default auto)])
2616 dnl
2617 dnl libvpx decoder plugin
2618 dnl
2619 AC_ARG_ENABLE([vpx],
2620 AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2621 AS_IF([test "${enable_vpx}" != "no"],[
2622 PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2623 VLC_ADD_PLUGIN([vpx])
2624 VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2625 VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2626 AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2627 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2628 ], [], [${VPX_LIBS}])
2629 AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2630 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2631 ], [], [${VPX_LIBS}])
2632 AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2633 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2634 ], [], [${VPX_LIBS}])
2635 AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2636 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2637 ], [], [${VPX_LIBS}])
2638 ], [
2639 AS_IF([test "${enable_vpx}" = "yes"],[
2640 AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2641 ])])
2642 ])
2644 dnl
2645 dnl twolame encoder plugin
2646 dnl
2647 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2649 dnl
2650 dnl fdk-aac encoder plugin
2651 dnl
2652 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2655 dnl
2656 dnl A52/AC3 decoder plugin
2657 dnl
2658 AC_ARG_ENABLE([a52],
2659 AS_HELP_STRING([--enable-a52], [A/52 support with liba52 (default enabled)]))
2660 if test "${enable_a52}" != "no"
2661 then
2662 AC_ARG_WITH([a52],
2663 AS_HELP_STRING([--with-a52=PATH], [a52 headers and libraries]))
2664 if test -z "${with_a52}"
2665 then
2666 LDFLAGS_test=""
2667 CPPFLAGS_test=""
2668 else
2669 LDFLAGS_test="-L${with_a52}/lib"
2670 CPPFLAGS_test="-I${with_a52}/include"
2671 fi
2672 VLC_SAVE_FLAGS
2673 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2674 LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2675 AC_CHECK_HEADERS([a52dec/a52.h], [
2676 AC_CHECK_LIB([a52], [a52_free], [
2677 VLC_ADD_PLUGIN([a52])
2678 VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2679 VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2680 ],[
2681 AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2682 ], [$LIBM])
2683 ],[
2684 AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2685 ])
2686 VLC_RESTORE_FLAGS
2687 fi
2689 dnl
2690 dnl DTS Coherent Acoustics decoder plugin
2691 dnl
2692 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2694 dnl
2695 dnl Flac plugin
2696 dnl
2697 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2699 dnl
2700 dnl Libmpeg2 plugin
2701 dnl
2702 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2704 dnl
2705 dnl Vorbis plugin
2706 dnl
2707 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2709 dnl
2710 dnl Tremor plugin
2711 dnl
2712 AC_ARG_ENABLE([tremor],
2713 AS_HELP_STRING([--enable-tremor], [Tremor decoder support (default disabled)]))
2714 if test "${enable_tremor}" = "yes"
2715 then
2716 AC_CHECK_HEADERS([tremor/ivorbiscodec.h], [
2717 VLC_ADD_PLUGIN([tremor])
2718 ],[])
2719 fi
2721 dnl
2722 dnl Speex plugins
2723 dnl
2724 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2725 have_speexdsp="no"
2726 AS_IF([test "${enable_speex}" != "no"], [
2727 PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2728 have_speexdsp="yes"
2729 ], [
2730 AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2731 ])
2732 ])
2733 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2735 dnl
2736 dnl Opus plugin
2737 dnl
2738 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2740 dnl
2741 dnl Ambisonic channel mixer and binauralizer plugin
2742 dnl
2743 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
2745 dnl
2746 dnl theora decoder plugin
2747 dnl
2748 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2750 dnl
2751 dnl OggSpots decoder plugin
2752 dnl
2753 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2755 dnl
2756 dnl Daala decoder plugin
2757 dnl
2758 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2760 dnl
2761 dnl schroedinger decoder plugin (for dirac format video)
2762 dnl
2763 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2765 dnl
2766 dnl PNG decoder module
2767 dnl
2768 AC_ARG_ENABLE([png],
2769 AS_HELP_STRING([--enable-png], [PNG support (default enabled)]))
2770 AS_IF([test "${enable_png}" != "no"], [
2771 AC_CHECK_HEADERS([png.h], [
2772 VLC_SAVE_FLAGS
2773 LDFLAGS="${LDFLAGS} -lz $LIBM"
2774 AC_CHECK_LIB([png], [png_set_alpha_mode], [
2775 VLC_ADD_PLUGIN([png])
2776 ], [], [-lz $LIBM])
2777 VLC_RESTORE_FLAGS
2778 ])
2779 ])
2781 dnl
2782 dnl JPEG decoder module
2783 dnl
2784 AC_ARG_ENABLE([jpeg],
2785 AS_HELP_STRING([--enable-jpeg], [JPEG support (default enabled)]))
2786 AS_IF([test "${enable_jpeg}" != "no"], [
2787 AC_CHECK_HEADERS([jpeglib.h], [
2788 VLC_ADD_PLUGIN([jpeg])
2789 ])
2790 ])
2792 dnl
2793 dnl BPG decoder module
2794 dnl
2795 AC_ARG_ENABLE([bpg],
2796 AS_HELP_STRING([--enable-bpg], [BPG support (default disabled)]))
2797 AS_IF([test "${enable_bpg}" != "no"], [
2798 AC_CHECK_HEADERS([libbpg.h], [
2799 VLC_ADD_PLUGIN([bpg])
2800 ])
2801 ])
2803 dnl
2804 dnl H262 encoder plugin (lib262)
2805 dnl
2806 AC_ARG_ENABLE([x262],
2807 AS_HELP_STRING([--enable-x262], [H262 encoding support with static libx262 (default disabled)]))
2808 if test "${enable_x262}" != "no"; then
2809 PKG_CHECK_MODULES(X262, x262, [
2810 VLC_ADD_PLUGIN([x262])
2811 VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2812 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2813 VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2814 ])
2815 VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2816 if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2817 VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2818 fi
2819 ], [
2820 if test "${enable_x262}" = "yes"; then
2821 AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2822 fi
2823 ])
2824 fi
2826 dnl x265 encoder
2827 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2829 dnl
2830 dnl H264 encoder plugin (using libx264)
2831 dnl
2832 AC_ARG_ENABLE([x264],
2833 AS_HELP_STRING([--enable-x264], [H264 encoding support with libx264 (default enabled)]))
2834 if test "${enable_x264}" != "no"; then
2835 PKG_CHECK_MODULES(X264,x264 >= 0.148, [
2836 VLC_ADD_PLUGIN([x264])
2837 VLC_ADD_LIBS([x264],[${X264_LIBS}])
2839 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2840 VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2841 ])
2843 VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2844 if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2845 VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2846 fi
2847 ],[
2848 if test "${enable_x264}" = "yes"; then
2849 AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2850 fi
2851 ])
2852 fi
2854 dnl
2855 dnl H264 encoder plugin (libx264 > 153)
2856 dnl
2857 AC_ARG_ENABLE([x26410b],
2858 AS_HELP_STRING([--enable-x26410b], [H264 10-bit encoding support with libx264 (default enabled)]))
2859 if test "${enable_x26410b}" != "no"; then
2860 PKG_CHECK_MODULES(X26410b,x264 >= 0.153, [
2861 VLC_ADD_PLUGIN([x26410b])
2862 VLC_ADD_LIBS([x26410b],[${X264_LIBS}])
2864 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2865 VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2866 ])
2868 VLC_ADD_CFLAGS([x26410b],[${X264_CFLAGS}])
2869 if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2870 VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2871 fi
2872 ],[
2873 if test "${enable_x26410b}" = "yes"; then
2874 AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2875 fi
2876 ])
2877 fi
2880 dnl
2881 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2882 dnl
2883 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2885 dnl
2886 dnl libfluidsynth (MIDI synthetizer) plugin
2887 dnl
2888 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2889 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2890 AC_CHECK_HEADERS([fluidlite.h], [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2892 dnl
2893 dnl Teletext Modules
2894 dnl vbi decoder plugin (using libzbvi)
2895 dnl telx module
2896 dnl uncompatible
2897 dnl
2898 AC_ARG_ENABLE([zvbi],
2899 AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2900 libzvbi (default enabled)]))
2901 AC_ARG_ENABLE([telx],
2902 AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2903 zvbi) (default enabled if zvbi is absent)]))
2905 AS_IF( [test "${enable_zvbi}" != "no"],[
2906 PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2907 [
2908 VLC_ADD_PLUGIN([zvbi])
2909 AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2910 AS_IF( [test "${enable_telx}" = "yes"],[
2911 AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2912 ])
2913 ],[
2914 AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2915 ])
2916 ])
2917 AS_IF( [test "${enable_telx}" != "no" ],[
2918 VLC_ADD_PLUGIN([telx])
2919 ])
2921 dnl
2922 dnl ARIB subtitles rendering module
2923 dnl
2924 AC_ARG_ENABLE([aribsub],
2925 AS_HELP_STRING([--enable-aribsub],[ARIB Subtitles support (default enabled)]))
2926 AS_IF( [test "${enable_aribsub}" != "no" ],[
2927 PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2928 have_aribb24="yes"
2929 VLC_ADD_PLUGIN([aribsub])
2930 VLC_ADD_LIBS([aribsub],[-laribb24])
2931 AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2932 ],[
2933 AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2934 have_aribb24="no"
2935 ])
2936 ])
2937 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2939 dnl
2940 dnl ARIB B25
2941 dnl
2942 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2944 dnl
2945 dnl kate decoder plugin
2946 dnl
2947 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2949 dnl
2950 dnl tiger rendering for kate decoder plugin
2951 dnl
2952 AC_ARG_ENABLE([tiger],
2953 AS_HELP_STRING([--enable-tiger], [Tiger rendering library for Kate streams (default auto)]))
2954 AS_IF([test "${enable_tiger}" != "no"], [
2955 PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2956 AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2957 AS_IF([test -n "${enable_tiger}"], [
2958 AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2959 ])
2960 ])
2961 ])
2963 dnl
2964 dnl check if we can build the css selector engine
2965 dnl
2966 AC_ARG_ENABLE([css],
2967 AS_HELP_STRING([--enable-css], [CSS selector engine (default auto)]))
2968 AS_IF([test "${enable_css}" != "no"], [
2969 with_css="yes"
2970 AC_DEFINE(HAVE_CSS, 1, [Define if CSS engine is built])
2971 ])
2972 AM_CONDITIONAL([ENABLE_CSS], [test "${with_css}" = "yes"])
2975 dnl
2976 dnl Video plugins
2977 dnl
2979 EXTEND_HELP_STRING([Video plugins:])
2981 dnl
2982 dnl libplacebo support
2983 dnl
2984 AC_ARG_ENABLE([libplacebo],
2985 AS_HELP_STRING([--disable-libplacebo],
2986 [disable libplacebo support (default auto)]))
2988 AS_IF([test "$enable_libplacebo" != "no"], [
2989 PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 0.5], [
2990 AC_DEFINE([HAVE_LIBPLACEBO], [1], [Define to 1 if libplacebo is enabled.])
2991 PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 1.7],
2992 [have_libplacebo_vk="yes"], [have_libplacebo_vk="no"])
2993 ], [
2994 AS_IF([test -n "${enable_libplacebo}"], [
2995 AC_MSG_ERROR([${LIBPLACEBO_PKG_ERRORS}.])
2996 ])
2997 enable_libplacebo="no"
2998 ])
2999 ])
3000 AM_CONDITIONAL([HAVE_LIBPLACEBO], [test "$enable_libplacebo" != "no"])
3002 dnl
3003 dnl OpenGL
3004 dnl
3005 PKG_CHECK_MODULES([EGL], [egl], [
3006 have_egl="yes"
3007 ], [
3008 have_egl="no"
3009 ])
3010 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3012 have_gl="no"
3013 PKG_CHECK_MODULES([GL], [gl], [
3014 have_gl="yes"
3015 ], [
3016 AC_MSG_CHECKING([for OpenGL])
3017 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3018 #ifdef _WIN32
3019 # include <GL/glew.h>
3020 #endif
3021 #include <GL/gl.h>
3022 ]], [
3023 [int t0 = GL_TEXTURE0;]])
3024 ], [
3025 GL_CFLAGS=""
3026 have_gl="yes"
3027 AS_IF([test "${SYS}" != "mingw32"], [
3028 GL_LIBS="-lGL"
3029 ], [
3030 GL_LIBS="-lopengl32"
3031 ])
3032 ])
3033 AC_MSG_RESULT([${have_gl}])
3034 ])
3035 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3036 AS_IF([test "${have_gl}" = "yes"], [
3037 AC_DEFINE([HAVE_GL], 1, [Defined if having OpenGL])
3038 ])
3040 dnl OpenGL ES 2: depends on EGL 1.1
3041 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3043 dnl
3044 dnl Vulkan
3045 dnl
3046 AC_ARG_ENABLE(vulkan,
3047 [AS_HELP_STRING([--disable-vulkan],
3048 [disable Vulkan support (default auto)])])
3050 AS_IF([test "$enable_vulkan" != "no"], [
3051 AS_IF([test "$have_libplacebo_vk" = "yes"], [
3052 PKG_CHECK_MODULES([VULKAN], [vulkan >= 1.0.26], [
3053 AC_DEFINE([HAVE_VULKAN], [1], [Define to 1 if vulkan is enabled.])
3054 ], [
3055 AS_IF([test -n "${enable_vulkan}"], [
3056 AC_MSG_ERROR([${VULKAN_PKG_ERRORS}.])
3057 ])
3058 enable_vulkan="no"
3059 ])
3060 ], [
3061 AS_IF([test -n "${enable_vulkan}"], [
3062 AC_MSG_ERROR([Vulkan support requires libplacebo 1.7 as well. Do not use --disable-libplacebo.])
3063 ])
3064 enable_vulkan="no"
3065 ])
3066 ])
3067 AM_CONDITIONAL(HAVE_VULKAN, [test "$enable_vulkan" != "no"])
3069 dnl
3070 dnl Xlib
3071 dnl
3073 AC_PATH_XTRA()
3074 AC_CHECK_HEADERS([X11/Xlib.h])
3076 dnl
3077 dnl X C Bindings modules
3078 dnl
3079 AC_ARG_ENABLE([xcb],
3080 AS_HELP_STRING([--enable-xcb], [X11 support with XCB (default enabled)]),, [
3081 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3082 enable_xcb="yes"
3083 ], [
3084 enable_xcb="no"
3085 ])
3086 ])
3088 have_xcb="no"
3089 have_xkbcommon_x11="no"
3090 have_xcb_keysyms="no"
3091 AS_IF([test "${enable_xcb}" != "no"], [
3092 xcb_err=""
3094 dnl libxcb
3095 PKG_CHECK_MODULES([XCB], [xcb >= 1.6],, [
3096 xcb_err="$xcb_err ${XCB_PKG_ERRORS}."])
3097 PKG_CHECK_MODULES([XCB_COMPOSITE], [xcb-composite],, [
3098 xcb_err="$xcb_err ${XCB_COMPOSITE_PKG_ERRORS}."])
3099 PKG_CHECK_MODULES([XCB_RANDR], [xcb-randr >= 1.3],, [
3100 xcb_err="$xcb_err ${XCB_RANDR_PKG_ERRORS}."])
3101 PKG_CHECK_MODULES([XCB_SHM], [xcb-shm],, [
3102 xcb_err="$xcb_err ${XCB_SHM_PKG_ERRORS}."])
3103 PKG_CHECK_MODULES([XCB_XKB], [xcb-xkb],, [
3104 xcb_err="$xcb_err ${XCB_XKB_PKG_ERRORS}."])
3105 PKG_CHECK_MODULES([XCB_XV], [xcb-xv >= 1.1.90.1],, [
3106 xcb_err="$xcb_err ${XCB_XV_PKG_ERRORS}."])
3108 dnl xproto
3109 PKG_CHECK_MODULES(XPROTO, [xproto],, [
3110 xcb_err="$xcb_err ${XPROTO_PKG_ERRORS}."])
3112 AS_IF([test -n "$xcb_err"], [
3113 AC_MSG_ERROR([$xcb_err Pass --disable-xcb to skip X11 support.])
3114 ])
3116 dnl xkbcommon
3117 PKG_CHECK_MODULES([XKBCOMMON_X11], [xkbcommon-x11], [
3118 have_xkbcommon_x11="yes"
3119 ], [
3120 AC_MSG_WARN([${XKBCOMMON_X11_PKG_ERRORS}. Hotkeys are disabled.])
3121 ])
3123 dnl xcb-utils
3124 PKG_CHECK_MODULES([XCB_KEYSYMS], [xcb-keysyms >= 0.3.4], [
3125 have_xcb_keysyms="yes"
3126 ], [
3127 AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Global hotkeys are disabled.])
3128 ])
3130 have_xcb="yes"
3131 ])
3132 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3133 AM_CONDITIONAL([HAVE_XKBCOMMON_X11], [test "${have_xkbcommon_x11}" = "yes"])
3134 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3137 dnl
3138 dnl VDPAU needs X11
3139 dnl
3140 AC_ARG_ENABLE([vdpau],
3141 [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3142 have_vdpau="no"
3143 AS_IF([test "${enable_vdpau}" != "no"], [
3144 PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3145 have_vdpau="yes"
3146 AS_IF([test "${no_x}" = "yes"], [
3147 AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3148 ])
3149 ], [
3150 AS_IF([test -n "${enable_vdpau}"], [
3151 AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3152 ])
3153 ])
3154 ])
3155 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3157 have_avcodec_vdpau="no"
3158 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3159 case "${avfork}" in
3160 libav) av_vdpau_ver="56.10.0" ;;
3161 ffmpeg) av_vdpau_ver="56.19.100" ;;
3162 esac
3163 PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3164 have_avcodec_vdpau="yes"
3165 AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3166 ], [
3167 AS_IF([test -n "${enable_vdpau}"], [
3168 AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3169 ], [
3170 AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3171 ])
3172 ])
3173 ])
3174 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3177 dnl
3178 dnl Wayland
3179 dnl
3180 AC_ARG_ENABLE([wayland],
3181 AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)]))
3183 have_wayland="no"
3184 AS_IF([test "${enable_wayland}" != "no"], [
3185 wl_err=""
3187 dnl wayland
3188 PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91],, [
3189 wl_err="$wl_err ${WAYLAND_CLIENT_PKG_ERRORS}."
3190 ])
3191 PKG_CHECK_MODULES([WAYLAND_CURSOR], [wayland-cursor],, [
3192 wl_err="$wl_err ${WAYLAND_CURSOR_PKG_ERRORS}."
3193 ])
3194 PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl],, [
3195 wl_err="$wl_err ${WAYLAND_EGL_PKG_ERRORS}."
3196 ])
3197 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner >= 1.15], [
3198 WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3199 ], [
3200 wl_err="$wl_err ${WAYLAND_SCANNER_PKG_ERRORS}."
3201 ])
3203 dnl wayland-protocols
3204 PKG_CHECK_MODULES([WAYLAND_PROTOCOLS], [wayland-protocols >= 1.12], [
3205 WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3206 ], [
3207 wl_err="$wl_err ${WAYLAND_PROTOCOLS_PKG_ERRORS}."
3208 ])
3210 AS_IF([test -n "$wl_err"], [
3211 AS_IF([test -n "$enable_wayland"], [
3212 AC_MSG_ERROR([$wl_err])
3213 ], [
3214 AC_MSG_WARN([$wl_err])
3215 ])
3216 ], [
3217 have_wayland="yes"
3218 ])
3220 dnl xkbcommon
3221 PKG_CHECK_MODULES([XKBCOMMON], [xkbcommon], [
3222 have_xkbcommon="yes"
3223 ], [
3224 AC_MSG_WARN([${XKBCOMMON_PKG_ERRORS}. Hotkeys are disabled.])
3225 ])
3226 ])
3227 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3228 AC_SUBST([WAYLAND_PROTOCOLS])
3229 AC_SUBST([WAYLAND_SCANNER])
3230 AM_CONDITIONAL([HAVE_XKBCOMMON], [test "${have_xkbcommon}" = "yes"])
3233 dnl
3234 dnl SDL image decoder module
3235 dnl
3236 AC_ARG_ENABLE([sdl-image],
3237 AS_HELP_STRING([--enable-sdl-image], [SDL image support (default enabled)]))
3238 AS_IF([test "${enable_sdl_image}" != "no"],[
3239 PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3240 VLC_ADD_PLUGIN([sdl_image])
3241 ], [
3242 AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3243 ])
3244 ])
3246 dnl
3247 dnl freetype module
3248 dnl
3249 AC_ARG_ENABLE([freetype],
3250 AS_HELP_STRING([--enable-freetype], [freetype support (default auto)]))
3251 AC_ARG_ENABLE([fribidi],
3252 AS_HELP_STRING([--enable-fribidi], [fribidi support (default auto)]))
3253 AC_ARG_ENABLE([harfbuzz],
3254 AS_HELP_STRING([--enable-harfbuzz], [harfbuzz support (default auto)]))
3255 AC_ARG_ENABLE([fontconfig],
3256 AS_HELP_STRING([--enable-fontconfig], [fontconfig support (default auto)]))
3258 AC_ARG_WITH([default-font],
3259 AS_HELP_STRING([--with-default-font=PATH],
3260 [Path to the default font]),
3261 [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3262 "$withval", [Default font])])
3263 AC_ARG_WITH([default-monospace-font],
3264 AS_HELP_STRING([--with-default-monospace-font=PATH],
3265 [Path to the default font]),
3266 [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3267 "$withval", [Default monospace font])])
3269 AC_ARG_WITH([default-font-family],
3270 AS_HELP_STRING([--with-default-font-family=NAME],
3271 [Name of the default font family]),
3272 [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3273 "$withval", [Default font family])])
3274 AC_ARG_WITH([default-monospace-font-family],
3275 AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3276 [Name of the default font family]),
3277 [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3278 "$withval", [Default monospace font family])])
3280 have_freetype="no"
3281 have_fontconfig="no"
3282 have_fribidi="no"
3283 have_harfbuzz="no"
3285 if test "${enable_freetype}" != "no"; then
3286 PKG_CHECK_MODULES(FREETYPE, freetype2, [
3287 have_freetype="yes"
3288 VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3289 VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3291 dnl fontconfig support
3292 AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3293 PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3294 have_fontconfig="yes"
3295 ], [
3296 AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3297 ])
3298 ])
3300 dnl fribidi support
3301 if test "${enable_fribidi}" != "no"; then
3302 PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3303 have_fribidi="yes"
3304 VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3305 VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3306 ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3307 fi
3309 dnl harfbuzz support
3310 if test "${have_fribidi}" != "no"; then
3311 if test "${enable_harfbuzz}" != "no"; then
3312 PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3313 have_harfbuzz="yes"
3314 VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3315 VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3316 ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3317 fi
3318 fi
3319 ],[
3320 AS_IF([test -n "${enable_freetype}"],[
3321 AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3322 ])
3323 ])
3324 fi
3326 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3327 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3328 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3329 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3331 dnl
3332 dnl libass subtitle rendering module
3333 dnl
3334 AC_ARG_ENABLE([libass],
3335 AS_HELP_STRING([--enable-libass], [Subtitle support using libass (default enabled)]))
3336 AS_IF( [test "${enable_libass}" != "no"], [
3337 PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
3338 [
3339 VLC_ADD_PLUGIN([libass])
3341 if test "${have_fontconfig}" != "no"; then
3342 VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
3343 VLC_ADD_LIBS([libass],[${FONTCONFIG_LIBS}])
3344 fi
3345 ],[
3346 AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
3347 ])
3348 ])
3350 dnl
3351 dnl SAPI (text to Speech renderer for Windows)
3352 dnl
3353 AC_LANG_PUSH([C++])
3354 AC_CHECK_TYPES([ISpObjectToken],[
3355 have_sapi="yes"
3356 ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3357 [#include <windows.h>
3358 #include <sapi.h>
3359 #include <sphelper.h>])
3360 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3361 AC_LANG_POP([C++])
3363 dnl
3364 dnl SVG module (text rendering and image decoding)
3365 dnl
3366 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3367 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3369 dnl
3370 dnl Windows DirectX module
3371 dnl
3373 AC_ARG_ENABLE([directx],
3374 AS_HELP_STRING([--enable-directx],
3375 [Microsoft DirectX support (default enabled on Windows)]),, [
3376 AS_IF([test "${SYS}" = "mingw32"], [
3377 enable_directx="yes"
3378 ], [
3379 enable_directx="no"
3380 ])
3381 ])
3382 AS_IF([test "${enable_directx}" != "no"], [
3383 dnl DirectDraw
3384 AC_CHECK_HEADERS([ddraw.h], [
3385 VLC_ADD_PLUGIN([directdraw])
3386 ])
3388 dnl OpenGL
3389 AC_CHECK_HEADERS([GL/wglew.h], [
3390 VLC_ADD_PLUGIN([glwin32 wgl])
3391 ],, [
3392 #include <windows.h>
3393 #include <GL/gl.h>
3394 ])
3396 dnl Direct3D11
3397 AC_CHECK_HEADERS([d3d11.h], [
3398 VLC_ADD_PLUGIN([direct3d11 direct3d11_filters])
3399 ])
3401 dnl Direct3D9
3402 AC_CHECK_HEADERS([d3d9.h], [
3403 VLC_ADD_PLUGIN([direct3d9])
3404 AC_CHECK_HEADERS([d3dx9effect.h])
3406 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3407 [[#define COBJMACROS
3408 #include <d3d9.h>
3409 #include <dxva2api.h>
3410 #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3411 # error dxva2 too old
3412 #endif
3413 ]],[[;]])
3414 ],[
3415 VLC_ADD_PLUGIN([direct3d9_filters])
3416 ],
3417 [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3419 ])
3420 ])
3422 dnl
3423 dnl Linux framebuffer module
3424 dnl
3425 AC_CHECK_HEADER([linux/fb.h], [
3426 VLC_ADD_PLUGIN([fb])
3427 ])
3429 dnl
3430 dnl Linux kernel mode setting module
3431 dnl
3432 PKG_ENABLE_MODULES_VLC([KMS], [], [libdrm >= 2.4.83], [Linux kernel mode setting output], [auto])
3434 dnl
3435 dnl libcaca plugin
3436 dnl
3437 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3439 dnl
3440 dnl OS/2 KVA plugin
3441 dnl
3442 AC_ARG_ENABLE([kva],
3443 AS_HELP_STRING([--enable-kva],
3444 [support the K Video Accelerator KVA (default enabled on OS/2)]),, [
3445 AS_IF([test "$SYS" = "os2"], [
3446 enable_kva="yes"
3447 ])
3448 ])
3449 have_kva="no"
3450 KVA_LIBS=""
3451 AS_IF([test "$enable_kva" != "no"], [
3452 AC_CHECK_HEADERS([kva.h], [
3453 have_kva="yes"
3454 AC_CHECK_LIB([kva], [main], [
3455 KVA_LIBS="-lkva"
3456 ])
3457 ])
3458 ])
3459 AC_SUBST([KVA_LIBS])
3460 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3462 dnl
3463 dnl MMAL plugin
3464 dnl
3465 AC_ARG_ENABLE([mmal],
3466 AS_HELP_STRING([--enable-mmal],
3467 [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3468 if test "${enable_mmal}" != "no"; then
3469 VLC_SAVE_FLAGS
3470 LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3471 CPPFLAGS="${CPPFLAGS} -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux"
3472 AC_CHECK_HEADERS([interface/mmal/mmal.h],
3473 [ AC_CHECK_LIB([bcm_host], [vc_tv_unregister_callback_full], [
3474 have_mmal="yes"
3475 VLC_ADD_PLUGIN([mmal])
3476 VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3477 VLC_ADD_CFLAGS([mmal],[ -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux ])
3478 VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lmmal_core -lmmal_components -lmmal_util -lvchostif ]) ], [
3479 AS_IF([test "${enable_mmal}" = "yes"],
3480 [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3481 [ AC_MSG_WARN([Cannot find bcm library...]) ])
3482 ],
3483 [])
3484 ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3485 [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3486 [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3487 VLC_RESTORE_FLAGS
3488 fi
3489 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3491 dnl
3492 dnl Audio plugins
3493 dnl
3495 EXTEND_HELP_STRING([Audio plugins:])
3497 dnl
3498 dnl Pulseaudio module
3499 dnl
3500 AC_ARG_ENABLE([pulse],
3501 AS_HELP_STRING([--enable-pulse],
3502 [use the PulseAudio client library (default auto)]))
3503 have_pulse="no"
3504 AS_IF([test "${enable_pulse}" != "no"], [
3505 PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3506 have_pulse="yes"
3507 ], [
3508 AS_IF([test "x${enable_pulse}" != "x"], [
3509 AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3510 ])
3511 ])
3512 ])
3513 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3515 dnl
3516 dnl ALSA module
3517 dnl
3518 AC_ARG_ENABLE([alsa],
3519 AS_HELP_STRING([--enable-alsa],
3520 [support the Advanced Linux Sound Architecture (default auto)]),, [
3521 AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3522 enable_alsa="yes"
3523 ])
3524 ])
3525 have_alsa="no"
3526 AS_IF([test "${enable_alsa}" != "no"], [
3527 PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3528 have_alsa="yes"
3529 ], [
3530 AS_IF([test "x${enable_alsa}" != "x"], [
3531 AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required. Pass --disable-alsa to ignore this error.])
3532 ])
3533 ])
3534 ])
3535 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3537 dnl
3538 dnl Open Sound System module
3539 dnl
3540 AC_ARG_ENABLE([oss],
3541 AS_HELP_STRING([--enable-oss],
3542 [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)]),, [
3543 AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3544 enable_oss="no"
3545 ])
3546 ])
3547 have_oss="no"
3548 OSS_LIBS=""
3549 AS_IF([test "$enable_oss" != "no"], [
3550 AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3551 have_oss="yes"
3552 AC_CHECK_LIB([ossaudio], [main], [
3553 OSS_LIBS="-lossaudio"
3554 ])
3555 ])
3556 ])
3557 AC_SUBST([OSS_LIBS])
3558 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3560 dnl
3561 dnl OpenBSD sndio module
3562 dnl
3563 AC_ARG_ENABLE([sndio],
3564 AS_HELP_STRING([--disable-sndio],
3565 [support the OpenBSD sndio (default auto)]),, [
3566 AS_IF([test "$SYS" = "openbsd"], [
3567 enable_sndio="yes"
3568 ])
3569 ])
3570 have_sndio="no"
3571 AS_IF([test "$enable_sndio" != "no"], [
3572 AC_CHECK_HEADER([sndio.h], [
3573 have_sndio="yes"
3574 ])
3575 ])
3576 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3578 dnl
3579 dnl Windows Audio Session plugin
3580 dnl
3581 AC_ARG_ENABLE([wasapi],
3582 AS_HELP_STRING([--enable-wasapi],
3583 [use the Windows Audio Session API (default auto)])
3584 )
3585 have_wasapi="no"
3586 AS_IF([test "$enable_wasapi" != "no"], [
3587 AC_CHECK_HEADER([audioclient.h], [
3588 have_wasapi="yes"
3589 ], [
3590 AS_IF([test "x${enable_wasapi}" != "x"], [
3591 AC_MSG_ERROR([Windows Audio Session API not found.])
3592 ])
3593 ])
3594 ])
3595 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3597 dnl
3598 dnl JACK modules
3599 dnl
3600 AC_ARG_ENABLE([jack],
3601 AS_HELP_STRING([--disable-jack],
3602 [do not use jack (default auto)]))
3603 have_jack="no"
3604 AS_IF([test "${enable_jack}" != "no"], [
3605 PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3606 [ have_jack=yes ],
3607 [
3608 AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3610 PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3611 [ have_jack=yes ],
3612 [
3613 AS_IF([test -n "${enable_jack}"],
3614 [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3615 [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3616 ])
3617 ])
3618 ])
3619 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3621 dnl
3622 dnl OpenSLES Android
3623 dnl
3624 AC_ARG_ENABLE([opensles],
3625 AS_HELP_STRING([--enable-opensles], [Android OpenSL ES audio module (default disabled)]))
3626 if test "${HAVE_ANDROID}" = "1"; then
3627 if test "${enable_opensles}" = "yes"; then
3628 AC_CHECK_HEADERS([SLES/OpenSLES.h],
3629 [ VLC_ADD_PLUGIN([opensles_android]) ],
3630 [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3631 fi
3632 fi
3634 dnl
3635 dnl Tizen audio
3636 dnl
3637 AC_ARG_ENABLE([tizen_audio],
3638 AS_HELP_STRING([--enable-tizen-audio],
3639 [Tizen audio module (default enabled on Tizen)]),, [
3640 AS_IF([test "$HAVE_TIZEN" = "1"], [
3641 enable_tizen_audio="yes"
3642 ])
3643 ])
3644 if test "${enable_tizen_audio}" = "yes"; then
3645 AC_CHECK_HEADERS([audio_io.h],
3646 [ VLC_ADD_PLUGIN([tizen_audio]) ],
3647 [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3648 fi
3650 dnl
3651 dnl libsamplerate plugin
3652 dnl
3653 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3655 dnl
3656 dnl soxr module
3657 dnl
3658 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3660 dnl
3661 dnl OS/2 KAI plugin
3662 dnl
3663 AC_ARG_ENABLE([kai],
3664 AS_HELP_STRING([--enable-kai],
3665 [support the K Audio Interface KAI (default enabled on OS/2)]),, [
3666 AS_IF([test "$SYS" = "os2"], [
3667 enable_kai="yes"
3668 ])
3669 ])
3670 have_kai="no"
3671 KAI_LIBS=""
3672 AS_IF([test "$enable_kai" != "no"], [
3673 AC_CHECK_HEADERS([kai.h], [
3674 have_kai="yes"
3675 AC_CHECK_LIB([kai], [main], [
3676 KAI_LIBS="-lkai"
3677 ])
3678 ])
3679 ])
3680 AC_SUBST([KAI_LIBS])
3681 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3683 dnl
3684 dnl chromaprint audio track fingerprinter
3685 dnl
3686 m4_pushdef([libchromaprint_version], 0.6.0)
3687 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3688 VLC_ADD_PLUGIN([stream_out_chromaprint]),
3689 AS_IF([test "${enable_chromaprint}" = "yes"],
3690 [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3691 [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3692 ),
3693 [(Chromaprint based audio fingerprinter)],[auto])
3694 m4_popdef([libchromaprint_version])
3696 dnl
3697 dnl Chromecast streaming support
3698 dnl
3699 m4_pushdef([protobuf_lite_version], 2.5.0)
3700 AC_ARG_VAR(PROTOC, [protobuf compiler])
3701 AC_CHECK_PROGS(PROTOC, protoc, no)
3702 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3703 AS_IF([test "x${PROTOC}" != "xno"], [
3704 build_chromecast="yes"
3705 ], [
3706 AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3707 ])
3708 ], [
3709 AS_IF([test "${enable_chromecast}" = "yes"],
3710 AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3711 AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3712 )
3713 enable_chromecast="no"
3714 ], [(Chromecast streaming support)], [auto])
3715 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3716 m4_popdef([protobuf_lite_version])
3718 dnl
3719 dnl Interface plugins
3720 dnl
3722 EXTEND_HELP_STRING([Interface plugins:])
3724 dnl
3725 dnl QT
3726 dnl
3727 AC_ARG_ENABLE([qt],
3728 AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)]),, [
3729 AS_IF([test "${enable_vlc}" != "no"], [enable_qt="yes"])
3730 AS_IF([test "${SYS}" = "darwin"], [
3731 enable_qt="no"
3732 ])
3733 ])
3734 have_qt5_x11="no"
3735 AS_IF([test "${enable_qt}" != "no"], [
3736 PKG_CHECK_MODULES([QT], [Qt5Core >= 5.9.0 Qt5Widgets Qt5Gui Qt5Svg], [
3737 PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3738 have_qt5_x11="yes"
3739 ],[
3740 AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3741 ])
3742 QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3743 QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3744 QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3745 AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3746 AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3747 AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3748 ], [
3749 AS_IF([test -n "${enable_qt}"],[
3750 AC_MSG_ERROR([${QT_PKG_ERRORS}. If you want to build VLC without GUI, pass --disable-qt.])
3751 ],[
3752 AC_MSG_WARN([${QT_PKG_ERRORS}.])
3753 ])
3754 enable_qt="no"
3755 ])
3756 ])
3758 AS_IF([test "${enable_qt}" != "no"], [
3759 ALIASES="${ALIASES} qvlc"
3760 ])
3761 AC_SUBST([QT_VERSION])
3762 AM_CONDITIONAL([ENABLE_QT], [test "$enable_qt" != "no"])
3763 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3765 dnl
3766 dnl detect kde4-config patch (used for kde solids).
3767 dnl
3768 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3769 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3770 KDE4_CONFIG="kde4-config"
3771 ])
3773 dnl
3774 dnl Simple test for skins2 dependency
3775 dnl
3776 AS_IF([test "$enable_qt" = "no"], [
3777 AS_IF([test "${enable_skins2}" = "yes"], [
3778 AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3779 ], [
3780 enable_skins2="no"
3781 AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3782 ])
3783 ])
3785 dnl
3786 dnl Skins2 module
3787 dnl
3788 AC_ARG_ENABLE([skins2],
3789 AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)]))
3790 AS_IF([test "${enable_skins2}" != "no"], [
3791 have_skins_deps="yes"
3793 dnl Win32
3794 AS_IF([test "${SYS}" = "mingw32"], [
3795 VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3796 VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3797 dnl OS/2
3798 ], [test "${SYS}" = "os2"], [
3799 VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3800 dnl Linux/Unix
3801 ], [
3802 PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3803 PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3804 PKG_CHECK_MODULES([XCURSOR], [xcursor],, [have_skins_deps="no"])
3805 PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3806 VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3807 VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} ${XCURSOR_LIBS} -lX11])
3808 ])
3810 dnl we need freetype
3811 AS_IF([test "${have_freetype}" != "yes"], [
3812 have_skins_deps="no"
3813 ])
3815 AS_IF([test "${have_skins_deps}" = "no"], [
3816 AS_IF([test "x${enable_skins2}" = "x"], [
3817 AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3818 ], [
3819 AC_MSG_ERROR([Skins2 interface requires FreeType, libxcursor, libxpm, libxext and libxinerama])
3820 ])
3821 enable_skins2="no"
3822 ], [
3823 ALIASES="${ALIASES} svlc"
3824 enable_skins2="yes"
3825 ])
3826 ])
3827 AM_CONDITIONAL([BUILD_SKINS], [test "${enable_skins2}" = "yes"])
3829 AC_ARG_ENABLE([libtar],
3830 AS_HELP_STRING([--enable-libtar], [libtar support for skins2 (default auto)]))
3831 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3832 AC_CHECK_HEADERS([libtar.h], [
3833 VLC_ADD_LIBS([skins2],[-ltar])
3834 ])
3835 ])
3837 dnl
3838 dnl MacOS X gui module
3839 dnl
3840 AC_ARG_ENABLE([macosx],
3841 AS_HELP_STRING([--enable-macosx], [Mac OS X gui support (default enabled on Mac OS X)]))
3842 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3843 then
3845 dnl
3846 dnl If possible, use xcrun to find the right ibtool
3847 dnl
3849 AC_PATH_PROG([XCRUN], [xcrun], [no])
3850 AS_IF([test ! "x${XCRUN}" = "xno"], [
3851 AC_MSG_CHECKING([for ibtool (using xcrun)])
3852 XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3853 AC_MSG_RESULT([${XIB}])
3854 ], [
3855 AC_MSG_WARN([Looking for tools without using xcrun])
3856 ])
3858 AS_IF([test "x${XIB}" = "xno"], [
3859 AC_PATH_PROG(XIB, [ibtool], [no])
3860 AS_IF([test "x${XIB}" = "xno"], [
3861 AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3862 ])
3863 ])
3864 fi
3865 AM_CONDITIONAL([ENABLE_MACOSX_UI], [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3867 dnl
3868 dnl MacOS X sparkle update support
3869 dnl
3870 AC_ARG_ENABLE([sparkle],
3871 AS_HELP_STRING([--enable-sparkle], [Sparkle update support for OS X (default enabled on Mac OS X)]))
3872 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3873 then
3874 if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3875 then
3876 AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3877 fi
3879 AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3880 fi
3881 AM_CONDITIONAL([HAVE_SPARKLE], [test "$enable_sparkle" != "no"])
3883 dnl
3884 dnl MacOS X breakpad creash reporter support
3885 dnl
3886 AC_ARG_WITH([breakpad],
3887 AS_HELP_STRING([--with-breakpad=URL], [Enable Breakpad reporter using given URL]), [], [with_breakpad=no])
3889 AS_IF([test "$with_breakpad" != "no"], [
3891 AS_IF([test "$with_breakpad" = "yes"], [
3892 AC_MSG_ERROR([You need to supply the CrashDragon Server URL as value for --with-breakpad])
3893 ])
3895 AS_IF([test "$HAVE_OSX" = "1"], [
3896 AC_MSG_CHECKING([for Breakpad framework])
3897 AS_IF([test ! -d ${CONTRIB_DIR}/Breakpad.framework -a \
3898 ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework], [
3899 AC_MSG_RESULT([no])
3900 with_breakpad="no"
3901 AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3902 ], [
3903 AC_MSG_RESULT([yes])
3904 ])
3905 ],[
3906 PKG_CHECK_MODULES([BREAKPAD], [breakpad-client], [
3907 LDFLAGS="${LDFLAGS} -Wl,--build-id"
3908 ], [
3909 AC_MSG_ERROR(["breakpad not found"])
3910 ])
3911 ])
3912 ])
3914 AM_CONDITIONAL([HAVE_BREAKPAD], [test "$with_breakpad" != "no"])
3915 AS_IF([test "$with_breakpad" != "no"], [
3916 AC_SUBST([BREAKPAD_URL], ["${with_breakpad}"])
3917 ])
3919 dnl
3920 dnl Minimal Mac OS X module
3921 dnl
3922 AC_ARG_ENABLE([minimal-macosx],
3923 AS_HELP_STRING([--enable-minimal-macosx], [Minimal Mac OS X support (default disabled)]))
3924 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3925 then
3926 VLC_ADD_PLUGIN([minimal_macosx])
3927 fi
3929 dnl
3930 dnl Mac OS X fancy dmg build tool
3931 dnl
3932 if test "${HAVE_OSX}" = "1"
3933 then
3934 AC_PATH_PROG(DMGBUILD, dmgbuild, no)
3935 AS_IF([test "x${DMGBUILD}" = "xno"], [
3936 AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
3937 ])
3938 fi
3939 AM_CONDITIONAL([HAVE_DMGBUILD], [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
3941 dnl
3942 dnl VideoToolbox plugins
3943 AC_CHECK_HEADERS([VideoToolbox/VideoToolbox.h], [
3944 VLC_ADD_PLUGIN([videotoolbox])
3945 VLC_ADD_PLUGIN([cvpx])
3946 ])
3948 dnl
3949 dnl AudioToolbox MIDI plugin
3950 AC_CHECK_HEADERS([AudioToolbox/AudioToolbox.h], [
3951 VLC_ADD_PLUGIN([audiotoolboxmidi])
3952 ])
3954 dnl
3955 dnl ncurses module
3956 dnl
3957 AC_ARG_ENABLE([ncurses],
3958 AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)]))
3959 have_ncurses="no"
3960 AS_IF([test "${enable_ncurses}" != "no"] ,[
3961 PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3962 have_ncurses="yes"
3963 ALIASES="${ALIASES} nvlc"
3964 ], [
3965 AS_IF([test -n "${enable_ncurses}"], [
3966 AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3967 ])
3968 ])
3969 ])
3970 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3972 dnl
3973 dnl Lirc plugin
3974 dnl
3975 AC_ARG_ENABLE([lirc],
3976 AS_HELP_STRING([--enable-lirc], [lirc support (default disabled)]))
3977 have_lirc="no"
3978 AS_IF([test "${enable_lirc}" = "yes"], [
3979 AC_CHECK_HEADER(lirc/lirc_client.h, [
3980 AC_CHECK_LIB([lirc_client], [lirc_init], [
3981 have_lirc="yes"
3982 ])
3983 ])
3984 ])
3985 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3987 dnl
3988 dnl Bitstream
3989 dnl
3990 PKG_CHECK_MODULES([BITSTREAM], [bitstream > 1.4],[have_bitstream="yes"], [have_bitstream="no"])
3991 AM_CONDITIONAL([HAVE_BITSTREAM], [test "${have_bitstream}" = "yes"])
3993 dnl
3994 dnl SRT plugin
3995 dnl
3996 PKG_ENABLE_MODULES_VLC([SRT], [access_srt access_output_srt], [srt >= 1.2.2], [SRT input/output plugin], [auto], [], [], [-DENABLE_SRT])
3998 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3999 dnl
4000 dnl goom visualization plugin
4001 dnl
4002 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
4004 dnl
4005 dnl libprojectM visualization plugin
4006 dnl
4007 AC_ARG_ENABLE([projectm],
4008 AS_HELP_STRING([--enable-projectm], [projectM visualization plugin (default enabled)]))
4009 AS_IF([test "${enable_projectm}" != "no"],
4010 [
4011 PKG_CHECK_MODULES(PROJECTM, libprojectM,
4012 [
4013 VLC_ADD_PLUGIN([projectm])
4014 PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
4015 [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
4016 [ AC_MSG_WARN( [Using libprojectM version 1] )
4017 ])
4018 ],[
4019 AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
4020 ])
4021 ])
4023 dnl
4024 dnl Vovoid VSXu visualization plugin
4025 dnl
4026 AC_ARG_ENABLE([vsxu],
4027 AS_HELP_STRING([--enable-vsxu], [Vovoid VSXu visualization plugin (default auto)]))
4028 AS_IF([test "${enable_vsxu}" != "no"],
4029 [
4030 PKG_CHECK_MODULES(VSXU, libvsxu,
4031 [
4032 VLC_ADD_PLUGIN([vsxu])
4033 ],[
4034 AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
4035 ])
4036 ])
4038 EXTEND_HELP_STRING([Service Discovery plugins:])
4039 dnl
4040 dnl Avahi-Zeroconf services discovery
4041 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
4043 dnl
4044 dnl libudev services discovery
4045 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
4047 dnl
4048 dnl MTP devices services discovery
4049 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
4051 dnl
4052 dnl UPnP Plugin (Intel SDK)
4053 dnl
4054 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
4056 dnl
4057 dnl mDNS using libmicrodns
4058 dnl
4059 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
4062 EXTEND_HELP_STRING([Misc options:])
4064 dnl
4065 dnl libxml2 module
4066 dnl
4067 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4070 dnl
4071 dnl libgcrypt
4072 dnl
4073 AC_ARG_ENABLE([libgcrypt],
4074 AS_HELP_STRING([--disable-libgcrypt], [gcrypt support (default enabled)]))
4075 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
4076 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4078 # require libgcrypt >= 1.6.0
4079 AS_IF([test "${enable_libgcrypt}" != "no"], [
4080 AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4081 VLC_SAVE_FLAGS
4082 CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4083 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4084 [#include <gcrypt.h>
4085 #if GCRYPT_VERSION_NUMBER < 0x010600
4086 #error
4087 #endif]])], [
4088 ac_cv_lib_gcrypt=yes
4089 ], [
4090 ac_cv_lib_gcrypt=no
4091 ])
4092 VLC_RESTORE_FLAGS
4093 ])
4095 AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4096 AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4097 ], [
4098 AS_IF([test "${enable_libgcrypt}" = "yes"], [
4099 AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4100 ])
4101 ])
4102 ])
4104 AS_IF([test -z "$GCRYPT_LIBS"], [
4105 GCRYPT_LIBS="-lgcrypt -lgpg-error"
4106 ])
4108 AC_SUBST([GCRYPT_CFLAGS])
4109 AC_SUBST([GCRYPT_LIBS])
4110 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4112 dnl
4113 dnl TLS/SSL
4114 dnl
4115 AC_ARG_ENABLE([gnutls],
4116 AS_HELP_STRING([--enable-gnutls], [GNU TLS TLS/SSL support (default enabled)]))
4117 AS_IF([test "${enable_gnutls}" != "no"], [
4118 PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4119 VLC_ADD_PLUGIN([gnutls])
4120 ], [
4121 AS_IF([test -n "${enable_gnutls}"], [
4122 AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4123 ])
4124 ])
4125 ])
4128 dnl
4129 dnl Taglib plugin
4130 dnl
4131 AC_ARG_ENABLE([taglib],
4132 AS_HELP_STRING([--disable-taglib],
4133 [do not use TagLib (default enabled)]))
4134 AS_IF([test "${enable_taglib}" != "no"], [
4135 PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4136 VLC_ADD_PLUGIN([taglib])
4137 ], [
4138 AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4139 ])
4141 dnl
4142 dnl libsecret
4143 dnl
4144 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4146 dnl
4147 dnl kwallet
4148 dnl
4149 AC_ARG_ENABLE([kwallet],
4150 AS_HELP_STRING([--enable-kwallet],
4151 [use kwallet (via D-Bus) for keystore (default enabled)]))
4152 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4153 VLC_ADD_PLUGIN([kwallet])
4154 ])
4156 dnl
4157 dnl update checking system
4158 dnl
4159 AC_ARG_ENABLE([update-check],
4160 AS_HELP_STRING([--enable-update-check], [update checking system (default disabled)]))
4161 if test "${enable_update_check}" = "yes"
4162 then
4163 AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4164 AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4165 fi
4166 AM_CONDITIONAL([UPDATE_CHECK], [test "${enable_update_check}" = "yes"])
4168 dnl
4169 dnl OS X notification plugin
4170 dnl
4171 AC_ARG_ENABLE([osx_notifications],
4172 AS_HELP_STRING([--enable-osx-notifications],
4173 [macOS notification plugin (default disabled)]),,
4174 [enable_osx_notifications=no])
4175 AS_IF([test "${enable_osx_notifications}" != "no"], [
4176 VLC_ADD_PLUGIN([osx_notifications])
4177 ])
4179 dnl
4180 dnl Libnotify notification plugin
4181 dnl
4182 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-3.0], [libnotify notification], [auto])
4184 PKG_ENABLE_MODULES_VLC([MEDIALIBRARY], [medialibrary], [medialibrary], (medialibrary support), [auto])
4186 dnl
4187 dnl Endianness check
4188 dnl
4189 AC_C_BIGENDIAN
4190 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4191 DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4192 ], [
4193 DEFS_BIGENDIAN=""
4194 ])
4195 AC_SUBST([DEFS_BIGENDIAN])
4197 dnl
4198 dnl Where to install KDE solid .desktop
4199 dnl
4200 AC_ARG_WITH(kde-solid,
4201 AS_HELP_STRING([--with-kde-solid=PATH],
4202 [KDE Solid actions directory (auto)]),, [
4204 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4205 with_kde_solid="yes"
4206 fi
4207 ])
4208 soliddatadir=""
4209 AS_IF([test "${with_kde_solid}" != "no"], [
4210 AS_IF([test "${with_kde_solid}" = "yes"], [
4211 kde4datadir="`${KDE4_CONFIG} --install data`"
4212 AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4213 soliddatadir="${kde4datadir}/solid/actions"
4214 ], [
4215 soliddatadir="${with_kde_solid}"
4216 ])
4217 ])
4218 AC_SUBST([soliddatadir])
4219 AM_CONDITIONAL([KDE_SOLID], [test "x${soliddatadir}" != "x"])
4221 dnl
4222 dnl Find tools for win32 packaging
4223 dnl
4224 AS_IF([test "${SYS}" = "mingw32"], [
4225 dnl
4226 dnl Find makensis required to build the NSIS installer
4227 dnl
4228 nsis_major_required="3"
4229 nsis_version_ok="no"
4230 AC_PATH_PROG([MAKENSIS], [makensis], [no])
4231 AS_IF([test "$MAKENSIS" != "no"], [
4232 # Check version
4233 AC_MSG_CHECKING([makensis version])
4234 nsis_version=$($MAKENSIS -VERSION)
4235 AC_MSG_RESULT([$nsis_version])
4236 nsis_version_major=$(echo "$nsis_version" | awk -F \. '{print $1}' | sed 's/v//')
4237 # Check if major version is a valid number
4238 AS_IF([test -n "$nsis_version_major" && \
4239 test "$nsis_version_major" -eq "$nsis_version_major" 2> /dev/null], [
4240 # Do the version check using major version
4241 AS_IF([test "$nsis_version_major" -lt "$nsis_major_required"], [
4242 AC_MSG_WARN([makensis too old, (needs ${nsis_major_required}.x, have ${nsis_version_major}.x)])
4243 ], [
4244 nsis_version_ok="yes"
4245 ])
4246 ], [
4247 AC_MSG_WARN([failed to check the makensis version])
4248 ])
4249 ])
4250 dnl
4251 dnl Find 7zip
4252 dnl
4253 AC_PATH_PROG([SEVENZIP], [7z], [7z])
4254 ])
4255 AM_CONDITIONAL([HAVE_MAKENSIS], [test "x$MAKENSIS" != "xno" && test "$nsis_version_ok" = "yes"])
4257 dnl
4258 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4259 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4260 dnl
4261 if test "${SYS}" = "mingw32"; then
4262 AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4263 fi
4265 EXTEND_HELP_STRING([Components:])
4267 dnl
4268 dnl the VLC binary
4269 dnl
4270 AC_ARG_ENABLE([vlc],
4271 AS_HELP_STRING([--enable-vlc], [build the VLC media player (default enabled)]))
4272 AM_CONDITIONAL([BUILD_VLC], [test "${enable_vlc}" != "no"])
4274 dnl
4275 dnl Fuzzer (at the end in order to don't mess dependencies FLAGS)
4276 dnl
4277 AS_VAR_IF(with_libfuzzer, no, [], [
4278 LIBS="-lstdc++ ${LIBM} -L${with_libfuzzer} -lFuzzer"
4279 AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc-guard, [
4280 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard])
4281 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard], [CXXFLAGS])
4282 AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp])
4283 AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp], [CXXFLAGS])
4284 ], [
4285 AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc, [
4286 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc])
4287 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc], [CXXFLAGS])
4288 ], [
4289 AC_MSG_ERROR([Sanitizer coverage not supported by your compiler])
4290 ])
4291 ])
4292 ])
4294 dnl
4295 dnl Stuff used by the program
4296 dnl
4297 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4298 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4299 AC_DEFINE_UNQUOTED([VERSION_MESSAGE], "${VERSION_MESSAGE}", [Simple version string])
4300 AC_DEFINE_UNQUOTED([COPYRIGHT_MESSAGE], "${COPYRIGHT_MESSAGE}", [Copyright string])
4301 AC_DEFINE_UNQUOTED([COPYRIGHT_YEARS], "${COPYRIGHT_YEARS}", [The copyright years])
4302 AC_DEFINE_UNQUOTED([CONFIGURE_LINE], "${CONFIGURE_LINE}", [The ./configure command line])
4303 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_MAJOR],${VERSION_MAJOR}, [version major number])
4304 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_MINOR],${VERSION_MINOR}, [version minor number])
4305 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_REVISION],${VERSION_REVISION}, [version revision number])
4306 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_EXTRA],${VERSION_EXTRA}, [version extra number])
4307 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_DEV],"${VERSION_DEV}", [version development string])
4308 AC_SUBST([COPYRIGHT_MESSAGE])
4309 AC_SUBST([VERSION_MESSAGE])
4310 AC_SUBST([VERSION_MAJOR])
4311 AC_SUBST([VERSION_MINOR])
4312 AC_SUBST([VERSION_REVISION])
4313 AC_SUBST([VERSION_EXTRA])
4314 AC_SUBST([COPYRIGHT_YEARS])
4315 AC_DEFINE_UNQUOTED([VLC_COMPILE_BY], "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4316 AC_DEFINE_UNQUOTED([VLC_COMPILE_HOST], "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4317 AC_DEFINE_UNQUOTED([VLC_COMPILER], "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4318 dnl
4319 dnl Handle substvars that use $(top_srcdir)
4320 dnl
4321 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4323 dnl
4324 dnl Configuration is finished
4325 dnl
4326 AC_SUBST([SYS])
4327 AC_SUBST([ARCH])
4328 AC_SUBST([ALIASES])
4329 AC_SUBST([ASM])
4330 AC_SUBST([MOC])
4331 AC_SUBST([RCC])
4332 AC_SUBST([UIC])
4333 AC_SUBST([WINDRES])
4334 AC_SUBST([WINE_SDK_PATH])
4335 AC_SUBST([LIBEXT])
4336 AC_SUBST([AM_CPPFLAGS])
4337 AC_SUBST([MACOSX_DEPLOYMENT_TARGET])
4338 AC_SUBST([FILE_LIBVLCCORE_DLL])
4339 AC_SUBST([FILE_LIBVLC_DLL])
4341 AC_CONFIG_FILES([
4342 Makefile
4343 doc/Makefile
4344 modules/Makefile
4345 m4/Makefile
4346 po/Makefile.in
4347 share/Makefile
4348 compat/Makefile
4349 src/Makefile
4350 lib/Makefile
4351 bin/Makefile
4352 test/Makefile
4353 modules/hw/mmal/Makefile
4354 share/vlc.appdata.xml.in
4355 ])
4357 AM_COND_IF([HAVE_WIN32], [
4358 AC_CONFIG_FILES([
4359 extras/package/win32/NSIS/spad.nsi
4360 extras/package/win32/NSIS/vlc.win32.nsi
4361 extras/package/win32/msi/config.wxi
4362 ])
4363 ])
4365 AM_COND_IF([HAVE_DARWIN], [
4366 AC_CONFIG_FILES([
4367 modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4368 share/macosx/Info.plist:share/Info.plist.in
4369 ])
4370 ])
4372 dnl Generate makefiles
4373 AC_OUTPUT
4375 dnl Do we have to use make or gmake ?
4376 if make --version 2>&1|grep -q GNU
4377 then
4378 # GNU make, all seems good
4379 MAKE=make
4380 else
4381 # Known GNU make alias (on BSD)
4382 MAKE=gmake
4383 fi
4384 dnl Shortcut to nice compile message
4385 if test -n $SHELL; then
4386 SHELL=${CONFIG_SHELL-/bin/sh}
4387 fi
4388 rm -f compile
4389 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4390 echo "#! $SHELL
4391 rm -f .error\$\$
4392 ERROR=0
4393 export PATH=\"$PATH\" LANG=C
4394 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4395 test -f .error\$\$ && ERROR=1
4396 rm -f .error\$\$
4397 exit \$ERROR" >compile
4398 chmod a+x compile
4400 echo "
4401 libvlc configuration
4402 --------------------
4403 version : ${VERSION}
4404 system : ${SYS}
4405 architecture : ${ARCH}
4406 optimizations : ${enable_optimizations}"
4407 if test "${enable_vlc}" != "no"; then
4408 echo "vlc aliases :${ALIASES}"
4409 else
4410 echo "build vlc executable : no"
4411 fi
4412 echo "
4413 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."