configure.in

   1 dnl Autoconf settings for vlc
   2 AC_INIT(src/interface/main.c)
   3 AC_CONFIG_HEADER(include/defs.h)
   4
   5 AC_CANONICAL_HOST
   6
   7 VLC_VERSION=0.2.73
   8 AC_SUBST(VLC_VERSION)
   9 VLC_CODENAME=Ourumov
  10 AC_SUBST(VLC_CODENAME)
  11
  12 dnl Save CFLAGS
  13 save_CFLAGS="${CFLAGS}"
  14
  15 dnl Check for tools
  16 AC_PROG_MAKE_SET
  17 AC_PROG_CC
  18 AC_PROG_CPP
  19 AC_PROG_RANLIB
  20
  21 dnl AM_PROG_LIBTOOL
  22 AC_PROG_INSTALL
  23
  24 dnl Check for compiler environment
  25 AC_C_CONST
  26
  27 dnl Check for endianness if not cross-compiling
  28 if test x${cross_compiling} != xyes; then
  29   AC_C_BIGENDIAN
  30 fi
  31
  32 dnl Check for system libs needed
  33 AC_CHECK_FUNCS(gettimeofday select strerror strtod strtol)
  34 AC_CHECK_FUNCS(setenv putenv)
  35 AC_CHECK_FUNC(connect,,[
  36   AC_CHECK_LIB(socket,connect,LIB="${LIB} -lsocket")
  37 ])
  38 AC_CHECK_FUNC(gethostbyname,,[
  39   AC_CHECK_LIB(nsl,gethostbyname,LIB="${LIB} -lnsl")
  40 ])
  41 AC_CHECK_FUNC(nanosleep,,[
  42   AC_CHECK_LIB(rt,nanosleep,LIB="${LIB} -lrt",[
  43     AC_CHECK_LIB(posix4,nanosleep,LIB="${LIB} -lposix4")
  44   ])
  45 ])
  46 AC_CHECK_FUNCS(usleep)
  47 AC_CHECK_FUNC(inet_aton,,[
  48   AC_CHECK_LIB(resolv,inet_aton,LIB="${LIB} -lresolv")
  49 ])
  50 AC_CHECK_FUNCS(vasprintf)
  51 AC_CHECK_FUNCS(swab)
  52
  53 AC_CHECK_FUNC(getopt_long,[AC_DEFINE(HAVE_GETOPT_LONG,1,long getopt support)],
  54 [ # FreeBSD has a gnugetopt library for this:
  55   AC_CHECK_LIB([gnugetopt],[getopt_long],
  56     [AC_DEFINE(HAVE_GETOPT_LONG,1,getopt support) LIB="${LIB} -lgnugetopt"],
  57     [GETOPT=1])])
  58 AC_SUBST(GETOPT)
  59
  60 AC_FUNC_MMAP
  61 AC_TYPE_SIGNAL
  62 AC_CHECK_LIB(dl,dlopen,LIB="${LIB} -ldl")
  63 AC_CHECK_LIB(m,pow,LIB_YUV="${LIB_YUV} -lm")
  64 AC_MSG_CHECKING(for old style FreeBSD -pthread flag)
  65 AC_EGREP_CPP(yes,
  66         [#if defined(__FreeBSD_cc_version) && __FreeBSD_cc_version <= 500001
  67           yes
  68         #endif
  69         ], AC_MSG_RESULT(yes)
  70         DEFINE="${DEFINE} -D_THREAD_SAFE" LIB="${LIB} -pthread",
  71         AC_MSG_RESULT(no)
  72         AC_CHECK_LIB(pthread,pthread_create,LIB="${LIB} -lpthread"))
  73 AC_CHECK_LIB(threads,thread_create,LIB="${LIB} -lthreads")
  74
  75 CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
  76
  77 dnl Check for headers
  78 AC_CHECK_HEADERS(stddef.h getopt.h strings.h)
  79 AC_CHECK_HEADERS(sys/sockio.h fcntl.h sys/time.h unistd.h)
  80 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h)
  81 AC_CHECK_HEADERS(dlfcn.h image.h)
  82 AC_CHECK_HEADERS(arpa/inet.h net/if.h netinet/in.h sys/socket.h)
  83 AC_CHECK_HEADERS(machine/param.h)
  84
  85 dnl Check for threads library
  86 AC_CHECK_HEADERS(cthreads.h pthread.h kernel/scheduler.h kernel/OS.h)
  87
  88 dnl Check for misc headers
  89 AC_EGREP_HEADER(pthread_cond_t,pthread.h,[
  90   AC_DEFINE(PTHREAD_COND_T_IN_PTHREAD_H, 1,
  91             Define if <pthread.h> defines pthread_cond_t.)
  92 ])
  93 AC_EGREP_HEADER(strncasecmp,strings.h,[
  94   AC_DEFINE(STRNCASECMP_IN_STRINGS_H, 1,
  95             Define if <strings.h> defines strncasecmp.)
  96 ])
  97
  98 dnl Check for ntohl, etc.
  99 CFLAGS="${CFLAGS} -Wall -Werror"
 100 AC_MSG_CHECKING([for ntohl in sys/param.h])
 101 AC_TRY_COMPILE([#include <sys/param.h>
 102 void foo() { int meuh; ntohl(meuh); }],,
 103  AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
 104  AC_MSG_RESULT(yes), AC_MSG_RESULT(no))
 105
 106 dnl Check for -rdynamic flag
 107 CFLAGS="${CFLAGS} -rdynamic -Wall -Werror"
 108 AC_MSG_CHECKING([if \$CC miserably fails with the -rdynamic flag])
 109 AC_TRY_COMPILE([],,
 110  LCFLAGS="${LCFLAGS} -rdynamic"
 111  AC_MSG_RESULT(no), AC_MSG_RESULT(yes))
 112
 113 dnl End of the bizarre compilation tests
 114 CFLAGS="${save_CFLAGS}"
 115
 116 dnl Check for boolean_t
 117 AC_MSG_CHECKING([for boolean_t in sys/types.h])
 118 AC_TRY_COMPILE([#include <sys/types.h>
 119 void quux() { boolean_t foo; }],,
 120  AC_DEFINE(BOOLEAN_T_IN_SYS_TYPES_H, 1, Define if <sys/types.h> defines boolean_t.)
 121  AC_MSG_RESULT(yes), AC_MSG_RESULT(no))
 122 AC_MSG_CHECKING([for boolean_t in pthread.h])
 123 AC_TRY_COMPILE([#include <pthread.h>
 124 void quux() { boolean_t foo; }],,
 125  AC_DEFINE(BOOLEAN_T_IN_PTHREAD_H, 1, Define if <pthread.h> defines boolean_t.)
 126  AC_MSG_RESULT(yes), AC_MSG_RESULT(no))
 127
 128 dnl Checks for typedefs, structures, and compiler characteristics.
 129 AC_C_CONST
 130 AC_TYPE_SIZE_T
 131 AC_HEADER_TIME
 132
 133 ARCH=${host_cpu}
 134
 135 dnl
 136 dnl  default modules
 137 dnl
 138 BUILTINS="${BUILTINS} es ps ts yuv idct idctclassic motion"
 139
 140 dnl
 141 dnl  Accelerated modules
 142 dnl
 143 case x$host_os in
 144   xmingw32msvc)
 145     MMX_PLUGINS="idctmmx motionmmx"
 146     ;;
 147   *)
 148     MMX_PLUGINS="yuvmmx idctmmx motionmmx"
 149     ;;
 150 esac
 151
 152 AC_MSG_CHECKING([if \$CC groks MMX inline assembly])
 153 AC_TRY_COMPILE([void quux(){void *p;asm("packuswb %%mm1,%%mm2"::"r"(p));}],,
 154   ACCEL_PLUGINS="${ACCEL_PLUGINS} ${MMX_PLUGINS}"
 155   AC_MSG_RESULT(yes), AC_MSG_RESULT(no))
 156
 157 AC_MSG_CHECKING([if \$CC groks MMX EXT (SSE) inline assembly])
 158 AC_TRY_COMPILE([void quux(){void *p;asm("maskmovq %%mm1,%%mm2"::"r"(p));}],,
 159   ACCEL_PLUGINS="${ACCEL_PLUGINS} idctmmxext motionmmxext"
 160   AC_MSG_RESULT(yes), AC_MSG_RESULT(no))
 161
 162 dnl
 163 dnl  DVD module: check for DVD ioctls
 164 dnl
 165 AC_CHECK_HEADERS(sys/ioctl.h,[
 166   BUILTINS="${BUILTINS} dvd"
 167   AC_CHECK_HEADERS(sys/cdio.h sys/dvdio.h linux/cdrom.h)
 168   BSD_DVD_STRUCT=0
 169   dnl
 170   dnl Old FreeBSD: sys/cdio.h
 171   dnl
 172   AC_EGREP_HEADER(dvd_struct,sys/dvdio.h,[
 173     AC_DEFINE(DVD_STRUCT_IN_SYS_DVDIO_H, 1,
 174               Define if <sys/dvdio.h> defines dvd_struct.)
 175     BSD_DVD_STRUCT=1
 176   ])
 177   dnl
 178   dnl Newer FreeBSD: sys/dvdio.h
 179   dnl
 180   AC_EGREP_HEADER(dvd_struct,sys/cdio.h,[
 181     AC_DEFINE(DVD_STRUCT_IN_SYS_CDIO_H, 1,
 182               Define if <sys/cdio.h> defines dvd_struct.)
 183     BSD_DVD_STRUCT=1
 184   ])
 185   if test x$BSD_DVD_STRUCT = x1; then
 186     AC_DEFINE(HAVE_BSD_DVD_STRUCT, 1,
 187               Define if BSD-like dvd_struct is defined.)
 188   fi
 189   dnl
 190   dnl Linux: linux/cdrom.h
 191   dnl
 192   AC_EGREP_HEADER(dvd_struct,linux/cdrom.h,[
 193     AC_DEFINE(DVD_STRUCT_IN_LINUX_CDROM_H, 1,
 194               Define if <linux/cdrom.h> defines DVD_STRUCT.)
 195   ])
 196 ])
 197
 198 dnl
 199 dnl  dummy plugin
 200 dnl
 201 AC_ARG_ENABLE(dummy,
 202   [  --disable-dummy         dummy module (default enabled)])
 203 if test x$enable_dummy != xno; then
 204   BUILTINS="${BUILTINS} dummy"; fi
 205
 206 dnl
 207 dnl  null plugin
 208 dnl
 209 AC_ARG_ENABLE(null,
 210   [  --disable-null          Null module (default enabled)])
 211 if test x$enable_null != xno; then
 212   BUILTINS="${BUILTINS} null"; fi
 213
 214 dnl
 215 dnl  rc plugin
 216 dnl
 217 AC_ARG_ENABLE(rc,
 218   [  --disable-rc            rc module (default enabled)])
 219 if test x$enable_rc != xno; then
 220   BUILTINS="${BUILTINS} rc"; fi
 221
 222 dnl
 223 dnl  PentiumPro acceleration
 224 dnl
 225 AC_ARG_ENABLE(ppro,
 226 [  --disable-ppro          Disable PentiumPro optimizations (default enabled for x86)],
 227 [ if test x$enableval = xyes; then ARCH="${ARCH} ppro"; fi ],
 228 [ if test x${host_cpu} = xi686; then ARCH="${ARCH} ppro"; fi ])
 229
 230 dnl
 231 dnl  MMX acceleration
 232 dnl
 233 AC_ARG_ENABLE(mmx,
 234 [  --disable-mmx           Disable MMX optimizations (default enabled for x86)],
 235 [ if test x$enableval = xyes; then ARCH="${ARCH} mmx";
 236   BUILTINS="${BUILTINS} ${ACCEL_PLUGINS}"; fi ],
 237 [ if test x${host_cpu} = xi686 -o x${host_cpu} = xi586 -o x${host_cpu} = xx86 -o x${host_cpu} = xi386; then ARCH="${ARCH} mmx";
 238   BUILTINS="${BUILTINS} ${ACCEL_PLUGINS}"; fi ])
 239
 240 dnl
 241 dnl  AltiVec acceleration
 242 dnl
 243 AC_ARG_ENABLE(altivec,
 244 [  --enable-altivec        Enable altivec optimizations (default disabled since it is broken)],
 245 [ if test x$enableval = xyes; then ARCH="${ARCH} altivec";
 246     BUILTINS="${BUILTINS} idctaltivec"
 247     LIB_IDCTALTIVEC="-framework vecLib"
 248   fi ])
 249 #[ if test -d /System/Library/Frameworks/vecLib.framework; then ARCH="${ARCH} altivec"; PLUGINS="${PLUGINS} idctaltivec"; fi ])
 250
 251 dnl
 252 dnl  CSS DVD decryption
 253 dnl
 254 AC_ARG_ENABLE(css,
 255 [  --disable-css           Disable DVD CSS decryption (default enabled)],
 256 [ if test x$enableval = xyes; then CSS=1; else CSS=0; fi ], [ CSS=1; ])
 257 if test x${CSS} = x1; then AC_DEFINE(HAVE_CSS, 1, Define if you want DVD CSS decryption.) fi
 258
 259 dnl
 260 dnl  Debugging mode
 261 dnl
 262 AC_ARG_ENABLE(debug,
 263 [  --enable-debug          Enable debug mode (default disabled)],
 264 [ if test x$enableval = xyes; then DEBUG=1; fi ])
 265
 266 dnl
 267 dnl  Enable/disable statistics
 268 dnl
 269 AC_ARG_ENABLE(stats,
 270 [  --enable-stats          Enable printing of statistics (default disabled)],
 271 [ if test x$enableval = xyes; then STATS=1; fi ])
 272
 273 dnl
 274 dnl  Trace mode
 275 dnl
 276 AC_ARG_ENABLE(trace,
 277 [  --enable-trace          Enable trace mode (default disabled)],
 278 [ if test x$enableval = xyes; then TRACE=1; fi ])
 279
 280 dnl
 281 dnl  Enable/disable optimizations
 282 dnl
 283 AC_ARG_ENABLE(optimizations,
 284 [  --disable-optimizations Disable compiler optimizations (default enabled)],
 285 [ if test x$enableval = xno; then OPTIMS=0; fi ],
 286 [ OPTIMS=1 ])
 287
 288 SYS=${host_os}
 289
 290 dnl special case for BeOS
 291 if test x$host_os = xbeos; then
 292     BUILTINS="${BUILTINS} beos"
 293     LIB_BEOS="-lbe -lgame -lroot -ltracker"
 294
 295 dnl default case
 296 else
 297
 298 dnl
 299 dnl  OSS /dev/dsp module
 300 dnl
 301 AC_ARG_ENABLE(dsp,
 302   [  --disable-dsp           Linux /dev/dsp support (default enabled)])
 303 if test x$enable_dsp != xno; then
 304   if test -c /dev/dsp; then
 305     PLUGINS="${PLUGINS} dsp"
 306   fi
 307 fi
 308
 309 dnl
 310 dnl  Esound module
 311 dnl
 312 AC_ARG_ENABLE(esd,
 313   [  --enable-esd            Esound library support (default disabled)],
 314   [if test x$enable_esd = xyes; then
 315      AC_PATH_PROG(ESD_CONFIG, esd-config, no)
 316      if test x${ESD_CONFIG} != xno; then
 317        PLUGINS="${PLUGINS} esd"
 318        LIB_ESD="`${ESD_CONFIG} --libs`"
 319      fi
 320    fi])
 321
 322 dnl
 323 dnl  Darwin module
 324 dnl
 325 AC_ARG_ENABLE(darwin,
 326   [  --enable-darwin         Darwin sound support (default disabled)],
 327   [if test x$enable_darwin = xyes; then
 328      PLUGINS="${PLUGINS} darwin"
 329      LIB_DARWIN="-framework CoreAudio"
 330    fi])
 331
 332 dnl
 333 dnl  MacOS X module
 334 dnl
 335 AC_ARG_ENABLE(macosx,
 336   [  --enable-macosx         Mac OS X interface support (default enabled in Mac OS X)],
 337   [if test x$enable_macosx = xyes; then
 338      BUILTINS="${BUILTINS} macosx"
 339      LIB_MACOSX="-framework CoreAudio -framework Carbon -framework AGL"
 340      LIB_TS="${LIB_TS} -framework AGL -framework Carbon"
 341      LIB_SDL="${LIB_SDL} -framework AGL -framework Carbon"
 342    fi],
 343   [AC_CHECK_HEADERS(Carbon/Carbon.h,
 344      BUILTINS="${BUILTINS} macosx"
 345      LIB_MACOSX="-framework CoreAudio -framework Carbon -framework AGL"
 346      LIB_TS="${LIB_TS} -framework AGL -framework Carbon"
 347      LIB_SDL="${LIB_SDL} -framework AGL -framework Carbon"
 348    )])
 349
 350 dnl
 351 dnl  Linux framebuffer module
 352 dnl
 353 AC_ARG_ENABLE(fb,
 354   [  --enable-fb             Linux framebuffer support (default disabled)],
 355   [if test x$enable_fb = xyes; then PLUGINS="${PLUGINS} fb"; fi])
 356
 357 dnl
 358 dnl  GGI module
 359 dnl
 360 AC_ARG_WITH(ggi,
 361   [  --with-ggi[=name]       GGI support (default disabled)],
 362   [ if test "x$withval" != "xno";
 363     then
 364       PLUGINS="${PLUGINS} ggi";
 365       if test "x$withval" != "xyes";
 366       then
 367         LIB_GGI="-l"$withval
 368       else
 369         LIB_GGI="-lggi"
 370       fi
 371     fi ])
 372
 373 dnl
 374 dnl  SDL module
 375 dnl
 376 AC_ARG_WITH(sdl,
 377   [  --with-sdl[=name]       SDL support (default enabled)],
 378   [ if test "x$withval" != "xno";
 379     then
 380       PLUGINS="${PLUGINS} sdl";
 381       if test "x$withval" != "xyes";
 382       then
 383         LIB_SDL="${LIB_SDL} -L/usr/X11R6/lib -L"$withval"/lib -lSDL"
 384         INCLUDE="${INCLUDE} -I"$withval"/include"
 385       else
 386         AC_CHECK_HEADERS(SDL/SDL.h, , [echo "Cannot find SDL headers !"; exit])
 387         LIB_SDL="${LIB_SDL} -L/usr/X11R6/lib -lSDL"
 388       fi
 389     fi ])
 390     if test "x$withval" = "x";
 391     then
 392       AC_CHECK_HEADERS(SDL/SDL.h,
 393       [PLUGINS="${PLUGINS} sdl"
 394        LIB_SDL="${LIB_SDL} -L/usr/X11R6/lib -lSDL"])
 395     fi
 396
 397 dnl
 398 dnl  Glide module
 399 dnl
 400 AC_ARG_WITH(glide,
 401   [  --with-glide[=name]     Glide (3dfx) support (default disabled)],
 402   [ if test "x$withval" != "xno";
 403     then
 404       PLUGINS="${PLUGINS} glide";
 405       if test "x$withval" != "xyes";
 406       then
 407         LIB_GLIDE="-l"$withval
 408       else
 409         LIB_GLIDE="-lglide2x"
 410       fi
 411     fi ])
 412
 413 dnl
 414 dnl  ncurses module
 415 dnl
 416 AC_ARG_ENABLE(ncurses,
 417   [  --enable-ncurses        ncurses interface support (default disabled)],
 418   [if test x$enable_ncurses = xyes; then
 419      PLUGINS="${PLUGINS} ncurses"
 420      LIB_NCURSES="-lncurses"
 421    fi])
 422
 423 dnl
 424 dnl  Qt module
 425 dnl
 426 AC_ARG_ENABLE(qt,
 427   [  --enable-qt             Qt interface support (default disabled)],
 428   [if test x$enable_qt = xyes; then
 429      PLUGINS="${PLUGINS} qt"
 430      ALIASES="${ALIASES} qvlc"
 431      LIB_QT="-lqt -L${QTDIR}/lib"
 432      if test -x ${QTDIR}/bin/moc ;
 433      then
 434        MOC=${QTDIR}/bin/moc
 435      else
 436        MOC=moc
 437      fi
 438    fi])
 439
 440 dnl
 441 dnl  KDE module
 442 dnl
 443 AC_ARG_ENABLE(kde,
 444   [  --enable-kde            KDE interface support (default disabled)],
 445   [if test x$enable_kde = xyes; then PLUGINS="${PLUGINS} kde"; ALIASES="${ALIASES} kvlc"; fi])
 446
 447 dnl
 448 dnl  Gnome module
 449 dnl
 450 AC_ARG_ENABLE(gnome,
 451   [  --enable-gnome          Gnome interface support (default disabled)],
 452   [if test x$enable_gnome = xyes; then
 453      PLUGINS="${PLUGINS} gnome"
 454      ALIASES="${ALIASES} gnome-vlc"
 455      LIB_GNOME="`gnome-config --libs gnomeui | sed 's,-rdynamic,,'`"
 456    fi])
 457
 458 dnl
 459 dnl  Gtk+ module
 460 dnl
 461 AC_ARG_ENABLE(gtk,
 462   [  --disable-gtk           Gtk+ support (default enabled)])
 463 if test x$enable_gtk != xno; then
 464   AC_PATH_PROG(GTK_CONFIG, gtk-config, no)
 465   if test x${GTK_CONFIG} != xno; then
 466     PLUGINS="${PLUGINS} gtk"
 467     ALIASES="${ALIASES} gvlc"
 468     CFLAGS_GTK="`${GTK_CONFIG} --cflags gtk`"
 469     LIB_GTK="`${GTK_CONFIG} --libs gtk | sed 's,-rdynamic,,'`"
 470   fi
 471 fi
 472
 473 dnl
 474 dnl  X11 module
 475 dnl
 476 AC_ARG_ENABLE(x11,
 477   [  --disable-x11           X11 support (default enabled)])
 478 if test x$enable_x11 != xno; then
 479   if test x$x_includes = xNONE; then
 480     x_includes=/usr/X11R6/include
 481   fi
 482   if test x$x_libraries = xNONE; then
 483     x_libraries=/usr/X11R6/lib
 484   fi
 485   saved_CPPFLAGS=$CPPFLAGS
 486   CPPFLAGS="$CPPFLAGS -I$x_includes"
 487   AC_CHECK_HEADERS(X11/Xlib.h, [
 488     PLUGINS="${PLUGINS} x11"
 489     LIB_X11="-L$x_libraries -lX11 -lXext"
 490     CFLAGS_X11="-I$x_includes"
 491   ]
 492   CPPFLAGS=$saved_CPPFLAGS)
 493 fi
 494
 495 dnl
 496 dnl  XVideo module
 497 dnl
 498 AC_ARG_ENABLE(xvideo,
 499   [  --disable-xvideo        XVideo support (default enabled)])
 500 if test x$enable_xvideo != xno; then
 501   if test x$x_includes = xNONE; then
 502     x_includes=/usr/X11R6/include
 503   fi
 504   if test x$x_libraries = xNONE; then
 505     x_libraries=/usr/X11R6/lib
 506   fi
 507   saved_CPPFLAGS=$CPPFLAGS
 508   CPPFLAGS="$CPPFLAGS -I$x_includes"
 509   AC_CHECK_HEADERS(X11/extensions/Xv.h, [
 510     PLUGINS="${PLUGINS} xvideo"
 511     LIB_XVIDEO="-L$x_libraries -lX11 -lXext -lXv"
 512     CFLAGS_X11="-I$x_includes"
 513   ]
 514   CPPFLAGS=$saved_CPPFLAGS)
 515 fi
 516
 517 dnl
 518 dnl  ALSA module
 519 dnl
 520 AC_ARG_ENABLE(alsa,
 521   [  --enable-alsa           Alsa sound drivers support (Only for linux) (default disabled)],
 522   [if test x$enable_alsa = xyes; then AC_CHECK_HEADER(sys/asoundlib.h, AC_CHECK_LIB(asound, main, have_alsa="true", have_alsa="false"),have_alsa="false") if test x$have_alsa = xtrue; then
 523      PLUGINS="${PLUGINS} alsa"
 524      LIB_ALSA="-lasound"
 525    fi; fi])
 526
 527 dnl  end of non-BeOS stuff
 528 fi
 529
 530 dnl
 531 dnl  Configuration is finished
 532 dnl
 533 AC_SUBST(SYS)
 534 AC_SUBST(ARCH)
 535 AC_SUBST(PLUGINS)
 536 AC_SUBST(BUILTINS)
 537 AC_SUBST(ALIASES)
 538 AC_SUBST(DEFINE)
 539 AC_SUBST(INCLUDE)
 540 AC_SUBST(DEBUG)
 541 AC_SUBST(STATS)
 542 AC_SUBST(TRACE)
 543 AC_SUBST(OPTIMS)
 544 AC_SUBST(CSS)
 545 AC_SUBST(MOC)
 546
 547 AC_SUBST(LCFLAGS)
 548 AC_SUBST(LIB)
 549
 550 AC_SUBST(LIB_ALSA)
 551 AC_SUBST(LIB_BEOS)
 552 AC_SUBST(LIB_DARWIN)
 553 AC_SUBST(LIB_ESD)
 554 AC_SUBST(LIB_GGI)
 555 AC_SUBST(LIB_GLIDE)
 556 AC_SUBST(LIB_GNOME)
 557 AC_SUBST(LIB_GTK)
 558 AC_SUBST(LIB_IDCTALTIVEC)
 559 AC_SUBST(LIB_MACOSX)
 560 AC_SUBST(LIB_NCURSES)
 561 AC_SUBST(LIB_QT)
 562 AC_SUBST(LIB_TS)
 563 AC_SUBST(LIB_SDL)
 564 AC_SUBST(LIB_X11)
 565 AC_SUBST(LIB_XVIDEO)
 566 AC_SUBST(LIB_YUV)
 567
 568 AC_SUBST(CFLAGS_VLC)
 569 AC_SUBST(CFLAGS_GTK)
 570 AC_SUBST(CFLAGS_X11)
 571
 572 AC_OUTPUT([Makefile.opts include/config.h])
 573
 574 echo "
 575 vlc configuration
 576 -----------------
 577 vlc version           : ${VLC_VERSION}
 578 system                : ${SYS}
 579 architecture          : ${ARCH}
 580 debug mode            : ${DEBUG}
 581 statistics            : ${STATS}
 582 trace mode            : ${TRACE}
 583 optimizations         : ${OPTIMS}
 584 CSS decryption        : ${CSS}
 585 need builtin getopt   : ${GETOPT}
 586 built-in modules      :${BUILTINS}
 587 plugin modules        :${PLUGINS}
 588 vlc aliases           :${ALIASES}
 589
 590 You may now tune Makefile.opts at your convenience."
 591