configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 1999-2017 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 3.0.0-git)
   6 VERSION_MAJOR=3
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=git
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Vetinari"
  17 COPYRIGHT_YEARS="1996-2017"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 AM_SILENT_RULES([yes])
  31 AM_MAINTAINER_MODE([enable])
  32
  33 dnl
  34 dnl Directories
  35 dnl
  36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  37 dnl AC_SUBST(vlcincludedir)
  38 vlcdatadir="\${datadir}/\${PKGDIR}"
  39 AC_SUBST(vlcdatadir)
  40 vlclibdir="\${libdir}/\${PKGDIR}"
  41 AC_SUBST(vlclibdir)
  42
  43 dnl
  44 dnl Check for tools
  45 dnl
  46 AC_PROG_CC_C99
  47 AC_USE_SYSTEM_EXTENSIONS
  48 VLC_PROG_CC_C11
  49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  51 AH_TOP([
  52 #ifndef _REENTRANT
  53 # define _REENTRANT
  54 #endif
  55 ])
  56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  59
  60 AM_PROG_CC_C_O
  61 AC_PROG_CXX
  62 AC_PROG_CPP
  63 AC_PROG_OBJC
  64 _AM_DEPENDENCIES([OBJC])
  65 AC_PROG_EGREP
  66 AC_PROG_MAKE_SET
  67 AC_PROG_INSTALL
  68 AM_PROG_AS
  69
  70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
  73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
  74 AS_IF([test "$BUILDCC" = "false"], [
  75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
  76 ])
  77
  78 dnl Check for compiler properties
  79 AC_C_CONST
  80 AC_C_INLINE
  81 AC_C_RESTRICT
  82 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
  83
  84 dnl Extend the --help string at the current spot.
  85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  86
  87 dnl Allow binary package maintainer to pass a custom string to avoid
  88 dnl cache problem
  89 AC_ARG_WITH(binary-version,
  90     AS_HELP_STRING([--with-binary-version=STRING],
  91          [To avoid plugins cache problem between binary version]),[],[])
  92 AS_IF([test -n "${with_binary_version}"],[
  93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  94          [Binary specific version])
  95 ])
  96
  97 dnl
  98 dnl  Check the operating system
  99 dnl
 100 HAVE_WIN64="0"
 101 HAVE_IOS="0"
 102 HAVE_OSX="0"
 103 HAVE_TVOS="0"
 104
 105 case "${host_os}" in
 106   "")
 107     SYS=unknown
 108     ;;
 109   linux*)
 110     SYS=linux
 111     ;;
 112   bsdi*)
 113     SYS=bsdi
 114     CFLAGS="${CFLAGS} -pthread"
 115     ;;
 116   freebsd*)
 117     SYS=freebsd
 118     CFLAGS="${CFLAGS} -pthread"
 119     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 120     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 121     ac_cv_ld_z_defs=no
 122     ;;
 123   openbsd*)
 124     SYS=openbsd
 125     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 126     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 127     ;;
 128   netbsd*)
 129     SYS=netbsd
 130     ;;
 131   dragonfly*)
 132     SYS=dragonfly
 133     ;;
 134   darwin*)
 135
 136     dnl Force gcc "-arch" flag
 137     ARCH_flag=""
 138     case "${host}" in
 139       i?86*)
 140         ARCH_flag="-arch i386"
 141       ;;
 142       ppc64*)
 143         ARCH_flag="-arch ppc64"
 144       ;;
 145       ppc*)
 146         ARCH_flag="-arch ppc"
 147       ;;
 148       x86_64*)
 149         ARCH_flag="-arch x86_64"
 150       ;;
 151       arm*)
 152         ac_cv_c_bigendian="no"
 153         ac_cv_c_attribute_packed="no"
 154       ;;
 155     esac
 156
 157     SYS=darwin
 158     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 159     CXX="${CXX} -stdlib=libc++ -std=c++11"
 160     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 161     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 162     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
 163     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 164     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 165     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 166
 167     AC_EGREP_CPP(yes,
 168             [#import <TargetConditionals.h>
 169              #if TARGET_OS_IPHONE
 170              yes
 171              #endif],
 172              [HAVE_IOS="1"],
 173              [HAVE_OSX="1"])
 174
 175     AC_EGREP_CPP(yes,
 176             [#import <TargetConditionals.h>
 177              #if TARGET_OS_TV
 178              yes
 179              #endif],
 180              [HAVE_TVOS="1"
 181              HAVE_IOS="0"
 182              HAVE_OSX="0"
 183              ],)
 184
 185     dnl Allow binaries created on Lion to run on earlier releases
 186     AC_EGREP_CPP(yes,
 187            [#import <Cocoa/Cocoa.h>
 188             #ifdef MAC_OS_X_VERSION_10_7
 189             yes
 190             #endif],
 191             [AC_MSG_RESULT([yes])
 192             AC_LIBOBJ([getdelim])
 193             AC_LIBOBJ([strndup])
 194             AC_LIBOBJ([strnlen])],)
 195
 196     dnl
 197     dnl  Handle Mac OS X SDK flags
 198     dnl
 199     AC_ARG_WITH(macosx-sdk,
 200       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 201         [compile using the SDK in DIR])])
 202     if test "${with_macosx_sdk}" != "" ; then
 203         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 204         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 205         CC="${CC} -isysroot ${with_macosx_sdk}"
 206         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 207         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 208         LD="${LD} -syslibroot ${with_macosx_sdk}"
 209     fi
 210     AC_ARG_WITH(macosx-version-min,
 211       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 212         [compile for Mac OS X VERSION and above])])
 213     if test "${with_macosx_version_min}" != "" ; then
 214         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 215         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 216         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 217         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 218         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 219     fi
 220     ;;
 221   *mingw32* | *cygwin* | *wince* | *mingwce*)
 222     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
 223     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
 224     CXXFLAGS="${CXXFLAGS} -static-libgcc"
 225     AC_CHECK_TOOL(WINDRES, windres, :)
 226     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 227     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
 228     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
 229     AH_TOP([#endif])
 230     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 231     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 232     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 233     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 234     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 235     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 236     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 237     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 238     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 239     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 240     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 241
 242     case "${host_os}" in
 243       *mingw32*)
 244         SYS=mingw32
 245         ;;
 246       *cygwin*)
 247         dnl Check if we are using the mno-cygwin mode in which case we are
 248         dnl actually dealing with a mingw32 compiler.
 249         AC_EGREP_CPP(yes,
 250             [#ifdef _WIN32
 251              yes
 252              #endif],
 253             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 254         ;;
 255     esac
 256
 257     if test "${SYS}" = "mingw32"; then
 258         # DEP, ASLR, NO SEH
 259         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 260
 261         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 262         ac_default_prefix="`pwd`/_win32"
 263         DESTDIR="`pwd`/_win32/"
 264
 265         dnl
 266         dnl NSIS/MSI Installer prefix and WIN64
 267         dnl
 268         case "${host}" in
 269             amd64*|x86_64*)
 270                 HAVE_WIN64="1"
 271                 WINDOWS_ARCH="x64"
 272                 PROGRAMFILES="PROGRAMFILES64"
 273                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
 274             ;;
 275             *)
 276                 WINDOWS_ARCH="x86"
 277                 PROGRAMFILES="PROGRAMFILES"
 278             ;;
 279         esac
 280         AC_SUBST(WINDOWS_ARCH)
 281         AC_SUBST(PROGRAMFILES)
 282
 283     fi
 284     ;;
 285   *nto*)
 286     SYS=nto
 287     ;;
 288   solaris*)
 289     SYS=solaris
 290     ;;
 291   hpux*)
 292     SYS=hpux
 293     ;;
 294   *os2*)
 295     SYS=os2
 296     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 297     AC_LIBOBJ([freeaddrinfo])
 298     AC_LIBOBJ([gai_strerror])
 299     ;;
 300   *nacl*)
 301     SYS=nacl
 302     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 303     AC_LIBOBJ([sigwait])
 304     AC_LIBOBJ([recvmsg])
 305     AC_LIBOBJ([sendmsg])
 306     ;;
 307   *)
 308     SYS="${host_os}"
 309     ;;
 310 esac
 311
 312 dnl WinRT
 313 AC_ARG_ENABLE(winstore_app,
 314      AS_HELP_STRING([--enable-winstore-app],
 315                     [Build targetted for Windows Store apps (default disabled)]))
 316
 317 vlc_winstore_app=0
 318 AS_IF([test "${SYS}" = "mingw32"],[
 319   LIBCOM="-lole32"
 320   AS_IF([test "${enable_winstore_app}" = "yes"], [
 321     vlc_winstore_app=1
 322     LIBCOM=""
 323      VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
 324      AC_LIBOBJ([gai_strerror])
 325     ],[])
 326   AC_SUBST(LIBCOM)
 327   ])
 328 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 329
 330 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 331 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 332
 333 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 334 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
 335 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
 336 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
 337
 338 AM_CONDITIONAL(HAVE_NACL,    test "${SYS}" = "nacl")
 339
 340 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 341 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
 342 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 343 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
 344
 345 dnl
 346 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 347 dnl for program foo on win32
 348 case "${build_os}" in
 349     cygwin|msys|mingw32)
 350         ac_executable_extensions=".exe"
 351         BUILDEXEEXT=".exe"
 352     ;;
 353     os2*)
 354         BUILDEXEEXT=".exe"
 355     ;;
 356     *)
 357     ;;
 358 esac
 359 AC_SUBST(BUILDEXEEXT)
 360
 361 dnl Android is linux, but a bit different
 362 AS_IF([test "$SYS" = linux],[
 363     AC_MSG_CHECKING([for an Android system])
 364     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 365         [[#ifndef __ANDROID__
 366          # error Not Android
 367          #endif
 368         ]],[[;]])
 369     ],[
 370       HAVE_ANDROID="1"
 371       AC_MSG_RESULT([yes])
 372     ],[
 373       AC_MSG_RESULT([no])
 374     ])
 375 ])
 376 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 377
 378 dnl Tizen (minimum SDK version: 2.3)
 379 AS_IF([test "$SYS" = linux],[
 380     AC_MSG_CHECKING([for Tizen])
 381     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 382         [[#include <tizen.h>
 383         ]],[[;]])
 384     ],[
 385       HAVE_TIZEN="1"
 386       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
 387       AC_MSG_RESULT([yes])
 388     ],[
 389       AC_MSG_RESULT([no])
 390     ])
 391 ])
 392 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
 393
 394 dnl
 395 dnl  Check for the contrib directory
 396 dnl
 397 AC_ARG_WITH(contrib,
 398   [AS_HELP_STRING([--with-contrib[=DIR]],
 399     [search for 3rd party libraries in DIR/include and DIR/lib])
 400 ])
 401 AC_MSG_CHECKING([for 3rd party libraries path])
 402 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 403   CONTRIB_DIR="${srcdir}/contrib/${host}"
 404   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 405     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 406     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 407     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 408       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 409       CONTRIB_DIR=""
 410       AC_MSG_RESULT([not found])
 411     ])
 412   ])
 413 ], [
 414   AS_IF([test "${with_contrib}" != "no"], [
 415     CONTRIB_DIR="${with_contrib}"
 416   ], [
 417     CONTRIB_DIR=""
 418     AC_MSG_RESULT([disabled])
 419   ])
 420 ])
 421 AS_IF([test -n "${CONTRIB_DIR}"], [
 422   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 423     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 424   ], [
 425     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 426     CONTRIB_DIR=""
 427     AC_MSG_RESULT([not usable])
 428   ])
 429
 430 ])
 431 AS_IF([test -n "${CONTRIB_DIR}"], [
 432   AC_MSG_RESULT([${CONTRIB_DIR}])
 433   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 434   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 435   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 436   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
 437   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 438   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 439
 440   AS_IF([test -z "$LUAC"], [
 441     dnl Old contribs mixed cross-tools and cross-compiled executables
 442     AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
 443       LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
 444     ])
 445
 446     dnl Newer contribs follow usual name space rules
 447     AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
 448       LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
 449     ])
 450   ])
 451
 452   AS_IF([test "${SYS}" = "darwin"], [
 453     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 454     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 455   ])
 456 ], [
 457   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 458     AC_MSG_ERROR([Third party libraries not found!])
 459   ])
 460 ])
 461 AC_SUBST(CONTRIB_DIR)
 462
 463 dnl Add extras/tools to the PATH
 464 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 465 AS_IF([test -d "${TOOLS_DIR}"], [
 466     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 467     export PATH="${TOOLS_DIR}":$PATH
 468 ])
 469
 470 dnl
 471 dnl  Libtool
 472 dnl  It's very bad, but our former custom system was worst
 473 dnl  -- Courmisch
 474 dnl
 475
 476 dnl override platform specific check for dependent libraries
 477 dnl otherwise libtool linking of shared libraries will
 478 dnl fail on anything other than pass_all.
 479 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 480     [lt_cv_deplibs_check_method=pass_all])
 481
 482 LT_INIT([dlopen win32-dll shared disable-static])
 483 LT_LANG([C++])
 484 LT_LANG([Windows Resource])
 485
 486 DOLT
 487
 488 lt_cv_deplibs_check_method=pass_all
 489
 490 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 491   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 492 ])
 493
 494 dnl
 495 dnl Gettext stuff
 496 dnl
 497 AM_GNU_GETTEXT_VERSION([0.19.8])
 498 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 499
 500 dnl
 501 dnl Iconv stuff
 502 dnl
 503 AM_ICONV
 504
 505 dnl
 506 dnl checks for mingw
 507 AS_IF([test "${SYS}" = "mingw32"], [
 508
 509 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 510 #if !defined(__MINGW32__)
 511 # error Not compiling with mingw
 512 #endif
 513     ])], [
 514
 515 dnl Check for broken versions of mingw-runtime compatability library
 516     AC_MSG_CHECKING(for broken mingw-runtime)
 517     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 518 #include <_mingw.h>
 519 #if defined(__MINGW64_VERSION_MAJOR)
 520 # if __MINGW64_VERSION_MAJOR < 3
 521 #  error Attempting to use mingw-runtime with broken vsnprintf support
 522 # endif
 523 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
 524 # error Attempting to use mingw-runtime with broken vsnprintf support
 525 #endif
 526     ])], [
 527         AC_MSG_RESULT([ok])
 528     ], [
 529         AC_MSG_RESULT([present])
 530         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
 531     ])
 532
 533     dnl force use of mingw provided c99 *printf over msvcrt
 534     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 535
 536     dnl Add WinMainCRTStartup entry point to show it's a WinMain application
 537     VLC_ADD_LDFLAGS([vlc],[-mwindows])
 538
 539     dnl Check for the need to include the mingwex lib for mingw32
 540     VLC_SAVE_FLAGS
 541     AC_CHECK_LIB(mingwex,opendir,
 542         AC_CHECK_LIB(mingw32,opendir,,
 543             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 544     )
 545     VLC_RESTORE_FLAGS
 546     ], [
 547         AC_MSG_RESULT([Not compiling with mingw])
 548     ])
 549
 550     dnl Check for fnative-struct or mms-bitfields support for mingw32
 551     VLC_SAVE_FLAGS
 552     CFLAGS="${CFLAGS} -mms-bitfields"
 553     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
 554     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 555         [ac_cv_c_mms_bitfields],
 556         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 557     if test "${ac_cv_c_mms_bitfields}" = "no"; then
 558         VLC_RESTORE_FLAGS
 559         CFLAGS="${CFLAGS} -fnative-struct"
 560         CXXFLAGS="${CXXFLAGS} -fnative-struct"
 561         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 562             [ac_cv_c_fnative_struct],
 563             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 564         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
 565     fi
 566 ])
 567
 568
 569 dnl
 570 dnl Buggy glibc prevention. Purposedly not cached.
 571 dnl See sourceware.org bugs 5058 and 5443.
 572 dnl Ubuntu alone has 20 bug numbers for this...
 573 dnl
 574 AC_MSG_CHECKING(for buggy GNU/libc versions)
 575 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 576 #include <limits.h>
 577 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 578   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 579 # error GNU/libc with dcgettext killer bug!
 580 #endif
 581 ])], [
 582   AC_MSG_RESULT([not present])
 583 ], [
 584   AC_MSG_RESULT([found])
 585   AS_IF([test "x${enable_nls}" != "xno"], [
 586     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 587 work-around for this. Check with your distribution vendor on how to update the
 588 glibc run-time. Alternatively, build with --disable-nls.])
 589   ])
 590 ])
 591
 592 dnl Plugin compilation stuff
 593
 594 VLC_LIBRARY_SUFFIX
 595
 596 dnl Check for system libs needed
 597 need_libc=false
 598
 599 dnl Check for usual libc functions
 600 AC_CHECK_FUNCS([daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime tdestroy uselocale])
 601 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv memrchr nrand48 poll posix_memalign recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tfind timegm timespec_get strverscmp pathconf])
 602 AC_REPLACE_FUNCS([gettimeofday])
 603 AC_CHECK_FUNC(fdatasync,,
 604   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 605 ])
 606
 607 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
 608
 609 dnl mingw64 implements those as static inline, not functions with C linkage
 610 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
 611 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
 612 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
 613 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
 614
 615 dnl C11 static_assert()
 616 AC_MSG_CHECKING([for static_assert in assert.h])
 617 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 618 static_assert(1, "The impossible happened.");
 619 ])], [
 620   AC_MSG_RESULT([yes])
 621   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 622 ], [
 623   AC_MSG_RESULT([no])
 624 ])
 625
 626 # Windows CE does not have strcoll()
 627 AC_FUNC_STRCOLL
 628
 629 dnl Check for non-standard system calls
 630 case "$SYS" in
 631   "linux")
 632     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity recvmmsg])
 633     ;;
 634   "mingw32")
 635     AC_CHECK_FUNCS([_lock_file])
 636     ;;
 637 esac
 638
 639 AH_BOTTOM([#include <vlc_fixups.h>])
 640
 641 dnl Check for struct pollfd
 642 AC_CHECK_TYPES([struct pollfd],,,
 643 [#include <sys/types.h>
 644 #if HAVE_POLL
 645 # include <poll.h>
 646 #elif defined (_WIN32)
 647 # include <winsock2.h>
 648 #endif
 649 ])
 650
 651 dnl Check for struct timespec
 652 AC_CHECK_TYPES([struct timespec],,,
 653 [#include <time.h>])
 654
 655 dnl Check for max_align_t
 656 AC_CHECK_TYPES([max_align_t],,,
 657 [#include <stddef.h>])
 658
 659 dnl Checks for socket stuff
 660 VLC_SAVE_FLAGS
 661 SOCKET_LIBS=""
 662 AC_SEARCH_LIBS(connect, [socket], [
 663   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 664     SOCKET_LIBS="$ac_cv_search_connect"
 665   ])
 666 ], [
 667   AS_IF([test "${SYS}" = "mingw32"], [
 668     SOCKET_LIBS="-lws2_32"
 669   ])
 670 ])
 671
 672 AC_SEARCH_LIBS([inet_pton], [nsl], [
 673  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
 674     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
 675   ])
 676 ],, [${SOCKET_LIBS}])
 677
 678 LIBS="${LIBS} ${SOCKET_LIBS}"
 679 AC_LINK_IFELSE([
 680     AC_LANG_PROGRAM([#ifdef _WIN32
 681         # if _WIN32_WINNT < 0x600
 682         #  error Needs vista+
 683         # endif
 684         #include <ws2tcpip.h>
 685         #else
 686         #include <sys/socket.h>
 687         #include <arpa/inet.h>
 688         #endif], [
 689         char dst[[sizeof(struct in_addr)]];
 690         inet_pton(AF_INET, "127.0.0.1", dst);
 691     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 692 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
 693 VLC_RESTORE_FLAGS
 694 AC_SUBST(SOCKET_LIBS)
 695
 696 dnl Check for socklen_t
 697 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 698 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 699 ac_cv_type_socklen_t,
 700 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 701 [#include <sys/types.h>
 702 #ifdef _WIN32
 703 # include <winsock2.h>
 704 # include <ws2tcpip.h>
 705 #else
 706 # include <sys/socket.h>
 707 #endif]], [[socklen_t len; len = 0;]])],
 708 ac_cv_type_socklen_t=yes,
 709 ac_cv_type_socklen_t=no)])
 710 AS_IF([test "$ac_cv_type_socklen_t" = no],
 711  [AC_DEFINE(socklen_t, int)])
 712
 713 dnl Check for struct sockaddr_storage
 714 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 715 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 716 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 717   [AC_TRY_COMPILE(
 718     [#include <sys/types.h>
 719      #if defined( _WIN32 )
 720      # include <winsock2.h>
 721      #else
 722      # include <sys/socket.h>
 723      #endif], [struct sockaddr_storage addr;],
 724      ac_cv_struct_sockaddr_storage=yes,
 725      ac_cv_struct_sockaddr_storage=no)])
 726 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 727   AC_DEFINE(sockaddr_storage, sockaddr)
 728   AC_DEFINE(ss_family, sa_family)
 729 ])
 730
 731 dnl FreeBSD has a gnugetopt library for this:
 732 GNUGETOPT_LIBS=""
 733 AC_CHECK_FUNC(getopt_long,, [
 734   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 735     GNUGETOPT_LIBS="-lgnugetopt"
 736   ])
 737 ])
 738 AC_SUBST(GNUGETOPT_LIBS)
 739
 740 AC_CHECK_LIB(m,cos,[
 741   LIBM="-lm"
 742 ], [
 743   LIBM=""
 744 ])
 745 AC_SUBST(LIBM)
 746
 747 AC_CHECK_LIB(m,lrintf, [
 748   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 749   VLC_ADD_LIBS([skins2],[-lm])
 750 ])
 751 AC_CHECK_LIB(m,nanf,
 752   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 753 )
 754 AC_CHECK_LIB(m,sincos, [
 755   AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
 756 ], [
 757   AC_LIBOBJ([sincos])
 758 ])
 759
 760 dnl Check for dynamic plugins
 761 LIBDL=""
 762 have_dynamic_objects="no"
 763 VLC_SAVE_FLAGS
 764 AC_SEARCH_LIBS(dlsym, [dl svld], [
 765   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 766     LIBDL="$ac_cv_search_dlsym"
 767   ])
 768   have_dynamic_objects="yes"
 769 ])
 770 VLC_RESTORE_FLAGS
 771
 772 # Windows
 773 AS_IF([test "${SYS}" = "mingw32"], [
 774   LIBDL=""
 775   have_dynamic_objects="yes" #assume we can use shared objects
 776 ])
 777
 778 AS_IF([test "${enable_shared}" = "no"], [
 779   have_dynamic_objects=no
 780 ])
 781 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 782
 783 AC_SUBST(LIBDL)
 784
 785 dnl Check for thread library
 786 LIBPTHREAD=""
 787 AS_IF([test "${SYS}" != "mingw32"], [
 788   VLC_SAVE_FLAGS
 789   LIBS=""
 790   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 791     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 792       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 793     ])
 794   ])
 795   VLC_RESTORE_FLAGS
 796 ])
 797 AC_SUBST(LIBPTHREAD)
 798
 799 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
 800   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
 801     LIBRT="$ac_cv_search_clock_nanosleep"
 802   ])
 803 ], [
 804   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
 805     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
 806       LIBRT="$ac_cv_search_nanosleep"
 807     ])
 808   ])
 809 ])
 810 AC_SUBST(LIBRT)
 811
 812 dnl
 813 dnl Check for headers
 814 dnl
 815
 816 dnl  POSIX
 817 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
 818 AC_CHECK_HEADERS([net/if.h], [], [],
 819 [
 820 #include <sys/types.h>
 821 #include <sys/socket.h>
 822 ])
 823 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
 824 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
 825
 826 dnl  BSD
 827 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
 828
 829 dnl  GNU/Linux
 830 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 831
 832 dnl  MacOS
 833 AC_CHECK_HEADERS([xlocale.h])
 834
 835 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 836 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 837 AC_CHECK_TYPE(ssize_t,, [
 838   AC_DEFINE(ssize_t, int)
 839 ])
 840
 841 dnl It seems that autoconf detects pkg-config only during the first
 842 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 843 dnl it is nested within a conditional block, so it was not working right.
 844 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 845 AC_ARG_VAR(PKG_CONFIG_PATH,
 846        [Paths where to find .pc not at the default location])
 847 PKG_PROG_PKG_CONFIG()
 848
 849 dnl On some OS we need static linking
 850 AS_IF([test -n "${PKG_CONFIG}" ],[
 851     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 852         PKG_CONFIG="${PKG_CONFIG} --static"
 853     ])
 854 ])
 855
 856
 857 dnl
 858 dnl Check for zlib.h and -lz along with system -lminizip if available
 859 dnl
 860 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 861 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 862 if test "${have_zlib}" = "yes"
 863 then
 864   VLC_ADD_LIBS([sap],[-lz])
 865   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 866     AC_CHECK_HEADERS([unzip.h], [
 867       have_minizip=yes
 868       MINIZIP_LIBS="-lminizip -lz"
 869     ], [
 870       have_minizip=no
 871     ])
 872   ])
 873 fi
 874 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 875
 876
 877 dnl
 878 dnl Domain name i18n support via GNU libidn
 879 dnl
 880 PKG_CHECK_MODULES([IDN], [libidn], [
 881   have_libidn="yes"
 882   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 883 ], [
 884   have_libidn="no"
 885 ])
 886
 887
 888 dnl Check for dbus
 889 AC_ARG_ENABLE(dbus,
 890   [AS_HELP_STRING([--enable-dbus],
 891     [compile D-Bus message bus support (default enabled)])])
 892 have_dbus="no"
 893 AS_IF([test "${enable_dbus}" != "no"], [
 894   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 895     have_dbus="yes"
 896   ], [
 897     AS_IF([test -n "${enable_dbus}"], [
 898       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 899     ], [
 900       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 901     ])
 902   ])
 903 ])
 904 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 905
 906
 907 dnl Check for systemd
 908 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
 909   have_systemd="yes"
 910 ], [
 911   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
 912 ])
 913 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
 914
 915
 916 dnl Check for ntohl, etc.
 917 VLC_SAVE_FLAGS
 918 CFLAGS="${CFLAGS} -Wall -Werror"
 919 AC_CACHE_CHECK([for ntohl in sys/param.h],
 920     [ac_cv_c_ntohl_sys_param_h],
 921     [     AC_TRY_COMPILE([#include <sys/param.h>],
 922         [int meuh; ntohl(meuh);],
 923         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
 924 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
 925     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
 926 fi
 927 VLC_RESTORE_FLAGS
 928
 929 EXTEND_HELP_STRING([Optimization options:])
 930 dnl
 931 dnl  Compiler warnings
 932 dnl
 933
 934 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration init-self logical-op format-security])
 935 RDC_PROG_CC_FLAGS([-pipe])
 936 AC_LANG_PUSH([C++])
 937 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var format-security])
 938 AC_LANG_POP([C++])
 939
 940 dnl
 941 dnl  Debugging mode
 942 dnl
 943 AC_ARG_ENABLE(debug,
 944   [AS_HELP_STRING([--enable-debug],
 945     [build with run-time assertions (default disabled)])],,
 946   [enable_debug="no"])
 947 AH_TEMPLATE(NDEBUG,
 948             [Define to 1 if debug code should NOT be compiled])
 949 AS_IF([test "${enable_debug}" != "no"], [
 950   AC_CHECK_HEADERS([valgrind/valgrind.h])
 951 ], [
 952   AC_DEFINE(NDEBUG)
 953 ])
 954
 955 dnl
 956 dnl  Profiling
 957 dnl
 958 AC_ARG_ENABLE(gprof,
 959   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 960   [enable_gprof="no"])
 961 AS_IF([test "${enable_gprof}" != "no"], [
 962   CFLAGS="${CFLAGS} -pg"
 963   CXXFLAGS="${CXXFLAGS} -pg"
 964   OBJCFLAGS="${OBJCFLAGS} -pg"
 965   LDFLAGS="${LDFLAGS} -pg"
 966 ])
 967
 968 AC_ARG_ENABLE(cprof,
 969   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 970   [enable_cprof="no"])
 971 AS_IF([test "${enable_gprof}" != "no"], [
 972   CFLAGS="${CFLAGS} -finstrument-functions"
 973   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 974   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 975   LDFLAGS="${LDFLAGS} -finstrument-functions"
 976 ])
 977
 978 dnl
 979 dnl  Test coverage
 980 dnl
 981 AC_ARG_ENABLE(coverage,
 982   [AS_HELP_STRING([--enable-coverage],
 983     [build for test coverage (default disabled)])],,
 984   [enable_coverage="no"])
 985 AS_IF([test "${enable_coverage}" != "no"], [
 986   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 987   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 988   LDFLAGS="-lgcov ${LDFLAGS}"
 989 ])
 990
 991 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
 992   VLC_SAVE_FLAGS
 993   CFLAGS="${CFLAGS} -fvisibility=hidden"
 994   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
 995   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
 996   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
 997                  [ac_cv_c_visibility_hidden], [
 998     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 999       ac_cv_c_visibility_hidden=yes
1000     ], [
1001       ac_cv_c_visibility_hidden=no
1002     ])
1003   ])
1004   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1005 ])
1006
1007
1008 dnl
1009 dnl  Enable/disable optimizations
1010 dnl
1011 AC_ARG_ENABLE(optimizations,
1012   [AS_HELP_STRING([--disable-optimizations],
1013     [disable compiler optimizations (default enabled)])],,
1014   [enable_optimizations="yes"])
1015
1016 dnl Check for various optimization flags
1017 AS_IF([test "${enable_optimizations}" != "no"], [
1018
1019   dnl -O3 only in production builds
1020   AS_IF([test "${enable_debug}" = "no"], [
1021     VLC_SAVE_FLAGS
1022     CFLAGS="${CFLAGS} -O3"
1023     CXXFLAGS="${CXXFLAGS} -O3"
1024     OBJCFLAGS="${OBJCFLAGS} -O3"
1025     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1026       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1027         ac_cv_c_o3=yes
1028       ], [
1029         ac_cv_c_o3=no
1030       ])
1031     ])
1032     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1033   ])
1034
1035   dnl Check for fast maths
1036   RDC_PROG_CC_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1037   AC_LANG_PUSH(C++)
1038   RDC_PROG_CXX_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1039   AC_LANG_POP
1040
1041 AH_BOTTOM([
1042 #if defined(_MSC_VER) && !defined(__clang__)
1043 # pragma fenv_access(off)
1044 # pragma fp_contract(on)
1045 #elif defined(__GNUC__)
1046 /* Not supported so far */
1047 #else
1048 # pragma STDC FENV_ACCESS OFF
1049 # pragma STDC FP_CONTRACT ON
1050 #endif
1051 ])
1052
1053   dnl Check for -funroll-loops
1054   VLC_SAVE_FLAGS
1055   CFLAGS="${CFLAGS} -funroll-loops"
1056   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1057   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1058   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1059     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1060       ac_cv_c_unroll_loops=yes
1061     ], [
1062       ac_cv_c_unroll_loops=no
1063     ])
1064   ])
1065   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1066
1067   AS_IF([test "$enable_debug" = "no"], [
1068     dnl Check for -fomit-frame-pointer
1069     VLC_SAVE_FLAGS
1070     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1071     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1072     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1073     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1074       [ac_cv_c_omit_frame_pointer], [
1075       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1076         ac_cv_c_omit_frame_pointer=yes
1077       ], [
1078         ac_cv_c_omit_frame_pointer=no
1079       ])
1080     ])
1081     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1082   ])
1083 ])
1084
1085 VLC_SAVE_FLAGS
1086 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1087 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1088   AC_TRY_LINK([],, [
1089     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1090   ], [
1091     ac_cv_ld_bsymbolic=""
1092   ])
1093 ])
1094 VLC_RESTORE_FLAGS
1095 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1096 AC_SUBST(SYMBOLIC_LDFLAGS)
1097
1098 VLC_SAVE_FLAGS
1099 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1100 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1101   AC_TRY_LINK([],, [
1102     ac_cv_ld_z_defs="yes"
1103   ], [
1104     ac_cv_ld_z_defs="no"
1105   ])
1106 ])
1107 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1108
1109 dnl Check for __attribute__((packed))
1110 AC_CACHE_CHECK([for __attribute__((packed))],
1111   [ac_cv_c_attribute_packed],
1112   [ac_cv_c_attribute_packed=no
1113    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1114                     [ac_cv_c_attribute_packed=yes])])
1115 if test "${ac_cv_c_attribute_packed}" != "no"; then
1116   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1117 fi
1118
1119 dnl
1120 dnl  Check the CPU
1121 dnl
1122 case "${host_cpu}" in
1123   "")
1124     ARCH=unknown
1125     ;;
1126   *)
1127     ARCH="${host_cpu}"
1128     ;;
1129 esac
1130
1131 dnl Check for backtrace() support
1132 AC_CHECK_HEADERS(execinfo.h)
1133 AC_CHECK_FUNCS(backtrace)
1134
1135 dnl
1136 dnl  default modules
1137 dnl
1138 ALIASES="${ALIASES} cvlc rvlc"
1139
1140 dnl
1141 dnl  Accelerated modules
1142 dnl
1143
1144 dnl  Check for fully working MMX intrinsics
1145 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1146 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1147 AC_ARG_ENABLE(mmx,
1148   [AS_HELP_STRING([--disable-mmx],
1149     [disable MMX optimizations (default auto)])],,[
1150   case "${host_cpu}" in
1151     i?86|x86_64)
1152       enable_mmx="yes"
1153       ;;
1154     *)
1155       enable_mmx="no"
1156       ;;
1157   esac
1158 ])
1159 have_mmx="no"
1160 have_mmxext="no"
1161 AS_IF([test "${enable_mmx}" != "no"], [
1162   ARCH="${ARCH} mmx"
1163   VLC_SAVE_FLAGS
1164   CFLAGS="${CFLAGS} -mmmx"
1165   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1166     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1167 [#include <mmintrin.h>
1168 #include <stdint.h>
1169 uint64_t frobzor;]], [
1170 [__m64 a, b, c;
1171 a = b = c = (__m64)frobzor;
1172 a = _mm_slli_pi16(a, 3);
1173 a = _mm_adds_pi16(a, b);
1174 c = _mm_srli_pi16(c, 8);
1175 c = _mm_slli_pi16(c, 3);
1176 b = _mm_adds_pi16(b, c);
1177 a = _mm_unpacklo_pi8(a, b);
1178 frobzor = (uint64_t)a;]])], [
1179       ac_cv_c_mmx_intrinsics=yes
1180     ], [
1181       ac_cv_c_mmx_intrinsics=no
1182     ])
1183   ])
1184   VLC_RESTORE_FLAGS
1185   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1186     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1187   ])
1188
1189   VLC_SAVE_FLAGS
1190   CFLAGS="${CFLAGS} -mmmx"
1191   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1192     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1193 void *p;
1194 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1195 ]])
1196     ], [
1197       ac_cv_mmx_inline=yes
1198     ], [
1199       ac_cv_mmx_inline=no
1200     ])
1201   ])
1202   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1203     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1204     have_mmx="yes"
1205   ])
1206
1207   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1208                  [ac_cv_mmxext_inline], [
1209     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1210 void *p;
1211 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1212 ]])
1213     ], [
1214       ac_cv_mmxext_inline=yes
1215     ], [
1216       ac_cv_mmxext_inline=no
1217     ])
1218   ])
1219   VLC_RESTORE_FLAGS
1220   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1221     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1222     have_mmxext="yes"
1223   ])
1224 ])
1225 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1226 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1227
1228 dnl  Check for fully workin SSE2 intrinsics
1229 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1230 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1231 AC_ARG_ENABLE(sse,
1232   [AS_HELP_STRING([--disable-sse],
1233     [disable SSE (1-4) optimizations (default auto)])],, [
1234   case "${host_cpu}" in
1235     i?86|x86_64)
1236       enable_sse=yes
1237       ;;
1238     *)
1239       enable_sse=no
1240       ;;
1241   esac
1242 ])
1243 have_sse2="no"
1244 AS_IF([test "${enable_sse}" != "no"], [
1245   ARCH="${ARCH} sse sse2"
1246
1247   VLC_SAVE_FLAGS
1248   CFLAGS="${CFLAGS} -msse2"
1249   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1250     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1251 [#include <emmintrin.h>
1252 #include <stdint.h>
1253 uint64_t frobzor;]], [
1254 [__m128i a, b, c;
1255 a = b = c = _mm_set1_epi64((__m64)frobzor);
1256 a = _mm_slli_epi16(a, 3);
1257 a = _mm_adds_epi16(a, b);
1258 c = _mm_srli_epi16(c, 8);
1259 c = _mm_slli_epi16(c, 3);
1260 b = _mm_adds_epi16(b, c);
1261 a = _mm_unpacklo_epi8(a, b);
1262 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1263       ac_cv_c_sse2_intrinsics=yes
1264     ], [
1265       ac_cv_c_sse2_intrinsics=no
1266     ])
1267   ])
1268   VLC_RESTORE_FLAGS
1269   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1270     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1271   ])
1272
1273   VLC_SAVE_FLAGS
1274   CFLAGS="${CFLAGS} -msse"
1275   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1276     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1277 void *p;
1278 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1279 ]])
1280     ], [
1281       ac_cv_sse_inline=yes
1282     ], [
1283       ac_cv_sse_inline=no
1284     ])
1285   ])
1286
1287   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1288     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1289   ])
1290
1291   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1292     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1293 void *p;
1294 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1295 ]])
1296     ], [
1297       ac_cv_sse2_inline=yes
1298     ], [
1299       ac_cv_sse2_inline=no
1300     ])
1301   ])
1302   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1303     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1304     have_sse2="yes"
1305   ])
1306
1307   # SSE3
1308   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1309     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1310 void *p;
1311 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1312 ]])
1313     ], [
1314       ac_cv_sse3_inline=yes
1315     ], [
1316       ac_cv_sse3_inline=no
1317     ])
1318   ])
1319
1320   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1321     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1322   # SSSE3
1323   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1324     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1325 void *p;
1326 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1327 ]])
1328     ], [
1329       ac_cv_ssse3_inline=yes
1330     ], [
1331       ac_cv_ssse3_inline=no
1332     ])
1333   ])
1334
1335   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1336     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1337
1338   # SSE4.1
1339   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1340                  [ac_cv_sse4_1_inline], [
1341     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1342 void *p;
1343 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1344 ]])
1345     ], [
1346       ac_cv_sse4_1_inline=yes
1347     ], [
1348       ac_cv_sse4_1_inline=no
1349     ])
1350   ])
1351
1352   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1353     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1354
1355   # SSE4.2
1356   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1357                  [ac_cv_sse4_2_inline], [
1358     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1359 void *p;
1360 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1361 ]])
1362     ], [
1363       ac_cv_sse4_2_inline=yes
1364     ], [
1365       ac_cv_sse4_2_inline=no
1366     ])
1367   ])
1368
1369   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1370     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1371
1372   # SSE4A
1373   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1374     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1375 void *p;
1376 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1377 ]])
1378     ], [
1379       ac_cv_sse4a_inline=yes
1380     ], [
1381       ac_cv_sse4a_inline=no
1382     ])
1383   ])
1384   VLC_RESTORE_FLAGS
1385   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1386     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1387 ])
1388 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1389
1390 VLC_SAVE_FLAGS
1391 CFLAGS="${CFLAGS} -mmmx"
1392 have_3dnow="no"
1393 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1394   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1395 void *p;
1396 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1397 ]])
1398   ], [
1399     ac_cv_3dnow_inline=yes
1400   ], [
1401     ac_cv_3dnow_inline=no
1402   ])
1403 ])
1404 VLC_RESTORE_FLAGS
1405 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1406   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1407             [Define to 1 if 3D Now! inline assembly is available.])
1408   have_3dnow="yes"
1409 ])
1410 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1411
1412
1413 AC_ARG_ENABLE(neon,
1414   [AS_HELP_STRING([--disable-neon],
1415     [disable NEON optimizations (default auto)])],, [
1416   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1417 ])
1418 AS_IF([test "${enable_neon}" != "no"], [
1419   VLC_SAVE_FLAGS
1420   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1421   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1422     AC_COMPILE_IFELSE([
1423       AC_LANG_PROGRAM(,[[
1424 asm volatile("vqmovun.s64 d0, q1":::"d0");
1425 ]])
1426     ], [
1427       ac_cv_arm_neon="yes"
1428     ], [
1429       ac_cv_arm_neon="no"
1430     ])
1431   ])
1432   VLC_RESTORE_FLAGS
1433 ])
1434 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1435
1436 AC_ARG_ENABLE(arm64,
1437   [AS_HELP_STRING([--disable-arm64],
1438     [disable arm 64-bit optimizations (default auto)])],, [
1439   AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1440 ])
1441 AS_IF([test "${enable_arm64}" != "no"], [
1442   AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1443     AC_COMPILE_IFELSE([
1444       AC_LANG_PROGRAM(,[[
1445 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1446 ]])
1447     ], [
1448       ac_cv_arm64="yes"
1449     ], [
1450       ac_cv_arm64="no"
1451     ])
1452   ])
1453 ])
1454 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1455
1456
1457 AC_ARG_ENABLE(altivec,
1458   [AS_HELP_STRING([--disable-altivec],
1459     [disable AltiVec optimizations (default auto)])],, [
1460   AS_CASE("${host_cpu}", [powerpc*],
1461         [enable_altivec=yes], [enable_altivec=no])
1462 ])
1463 have_altivec="no"
1464 ALTIVEC_CFLAGS=""
1465 AS_IF([test "${enable_altivec}" = "yes"], [
1466   ARCH="${ARCH} altivec";
1467   VLC_SAVE_FLAGS
1468   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1469     [ac_cv_altivec_inline],
1470     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1471          ac_cv_altivec_inline="yes",
1472          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1473           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1474             [ac_cv_altivec_inline="-Wa,-maltivec"],
1475             ac_cv_altivec_inline=no)
1476          ])])
1477   VLC_RESTORE_FLAGS
1478   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1479     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1480               [Define to 1 if AltiVec inline assembly is available.])
1481     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1482       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1483       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1484     ])
1485     have_altivec="yes"
1486   ])
1487
1488   VLC_SAVE_FLAGS
1489   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1490   [ac_cv_c_altivec], [
1491     CFLAGS="${CFLAGS} -maltivec"
1492     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1493 [#include <altivec.h>]], [
1494 [vec_ld(0, (unsigned char *)0);]])], [
1495       ac_cv_c_altivec="-maltivec"
1496     ], [
1497       ac_cv_c_altivec="no"
1498     ])
1499   ])
1500   VLC_RESTORE_FLAGS
1501   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1502     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1503     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1504     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1505     ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1506     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1507     have_altivec="yes"
1508   ])
1509   AC_CHECK_HEADERS(altivec.h)
1510
1511   VLC_SAVE_FLAGS
1512   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1513   AC_CACHE_CHECK([if linker needs -framework vecLib],
1514     [ac_cv_ld_altivec],
1515     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1516   VLC_RESTORE_FLAGS
1517   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1518     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1519   ])
1520 ])
1521 AC_SUBST(ALTIVEC_CFLAGS)
1522 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1523
1524 dnl
1525 dnl  Memory usage
1526 dnl
1527 AC_ARG_ENABLE(optimize-memory,
1528   [AS_HELP_STRING([--enable-optimize-memory],
1529     [optimize memory usage over performance])])
1530 if test "${enable_optimize_memory}" = "yes"; then
1531   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1532 fi
1533
1534 dnl
1535 dnl Allow running as root (useful for people running on embedded platforms)
1536 dnl
1537 AC_ARG_ENABLE(run-as-root,
1538   [AS_HELP_STRING([--enable-run-as-root],
1539     [allow running VLC as root (default disabled)])])
1540 AS_IF([test "${enable_run_as_root}" = "yes"],[
1541     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1542               [Define to 1 to allow running VLC as root (uid 0).])
1543 ])
1544
1545 dnl
1546 dnl Stream output
1547 dnl
1548 AC_ARG_ENABLE(sout,
1549   [AS_HELP_STRING([--disable-sout],
1550     [disable streaming output (default enabled)])])
1551 AS_IF([test "${enable_sout}" != "no"], [
1552   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1553 ])
1554 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1555
1556 dnl Lua modules
1557 AC_ARG_ENABLE(lua,
1558   [AS_HELP_STRING([--disable-lua],
1559     [disable LUA scripting support (default enabled)])])
1560 if test "${enable_lua}" != "no"
1561 then
1562   PKG_CHECK_MODULES(LUA, lua5.2,
1563     [ have_lua=yes ],
1564     [
1565     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1566
1567     PKG_CHECK_MODULES(LUA, lua5.1,
1568       [ have_lua=yes ],
1569       [
1570       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1571       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1572         [ have_lua=yes ],
1573         [
1574           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1575           have_lua=yes
1576           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1577             [],
1578             [ have_lua=no ] )
1579           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1580             [LUA_LIBS="-llua5.2"],
1581           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1582             [LUA_LIBS="-llua5.1"],
1583             AC_CHECK_LIB( lua51 , luaL_newstate,
1584               [LUA_LIBS="-llua51"],
1585               AC_CHECK_LIB( lua , luaL_newstate,
1586                 [LUA_LIBS="-llua"],
1587                 [ have_lua=no
1588                 ], [-lm])
1589             )))
1590         ])
1591       ])
1592     ])
1593   if test "x${have_lua}" != "xyes" ;  then
1594       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1595   fi
1596   AC_ARG_VAR([LUAC], [LUA byte compiler])
1597   AS_IF([test -z "$LUAC"], [
1598      AC_CHECK_TOOL(LUAC, [luac], [false])
1599   ])
1600   AS_IF([test "${LUAC}" = "false"], [
1601     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1602   ])
1603   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1604     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1605   ])
1606 fi
1607 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1608
1609
1610 dnl
1611 dnl HTTP daemon
1612 dnl
1613 AC_ARG_ENABLE(httpd,
1614   [AS_HELP_STRING([--disable-httpd],
1615     [disable the built-in HTTP server (default enabled)])])
1616 if test "${enable_httpd}" != "no"
1617 then
1618   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1619 fi
1620 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1621
1622
1623 dnl
1624 dnl VideoLAN manager
1625 dnl
1626 AC_ARG_ENABLE(vlm,
1627   [AS_HELP_STRING([--disable-vlm],
1628     [disable the stream manager (default enabled)])],,
1629   [enable_vlm="${enable_sout}"])
1630 AS_IF([test "${enable_vlm}" != "no"], [
1631   AS_IF([test "${enable_sout}" = "no"], [
1632     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1633   ])
1634   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1635 ])
1636 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1637
1638
1639 dnl
1640 dnl Addons manager storage and repositories modules
1641 dnl
1642 AC_ARG_ENABLE(addonmanagermodules,
1643   [AS_HELP_STRING([--disable-addonmanagermodules],
1644     [disable the addons manager modules (default enabled)])])
1645 if test "${enable_addonmanagermodules}" != "no"
1646 then
1647   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1648 fi
1649 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1650
1651
1652 dnl
1653 dnl  Input plugins
1654 dnl
1655
1656 EXTEND_HELP_STRING([Input plugins:])
1657
1658 dnl
1659 dnl  libarchive access module
1660 dnl
1661 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1662
1663 dnl
1664 dnl  live555 input
1665 dnl
1666 AC_ARG_ENABLE(live555,
1667   [AS_HELP_STRING([--enable-live555],
1668     [enable RTSP input through live555 (default enabled)])])
1669
1670 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1671   PKG_CHECK_MODULES(LIVE555, live555, [
1672     VLC_ADD_PLUGIN([live555])
1673     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1674     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1675   ], [
1676     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1677
1678     AC_LANG_PUSH(C++)
1679     VLC_SAVE_FLAGS
1680
1681     dnl detect include paths
1682     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1683       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1684     ], [
1685       AS_IF([test "${SYS}" != "os2"], [
1686         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1687         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1688       ], [
1689         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1690         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1691         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1692       ])
1693     ])
1694
1695     dnl CPP Flags
1696     AS_IF([test "${SYS}" = "solaris"], [
1697       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1698     ])
1699     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1700     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1701
1702     dnl version check
1703     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1704       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1705 [#include <liveMedia_version.hh>
1706 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1707 # error BOOM
1708 #endif]])
1709       ], [
1710         ac_cv_live555="yes"
1711       ], [
1712         ac_cv_live555="no"
1713       ])
1714     ])
1715
1716     AS_IF([test "$ac_cv_live555" = "no"], [
1717       AC_MSG_WARN([live555 is missing or its installed version is too old:
1718 Version 2011.12.23 or later is required to proceed.
1719 You can get an updated one from http://www.live555.com/liveMedia .])
1720       AS_IF([test -n "${enable_live555}"], [
1721         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1722       ])
1723     ], [
1724       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1725       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1726       AS_IF([test "${SYS}" = "mingw32"], [
1727         # add ws2_32 for closesocket, select, recv
1728         other_libs="$other_libs -lws2_32"
1729       ])
1730
1731       dnl We need to check for pic because live555 don't provide shared libs
1732       dnl and we want to build a plugins so we need -fPIC on some arch.
1733       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1734       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1735       AC_CHECK_LIB(liveMedia_pic, main, [
1736         VLC_ADD_PLUGIN([live555])
1737         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1738       ],[
1739         AC_CHECK_LIB(liveMedia, main, [
1740           VLC_ADD_PLUGIN([live555])
1741           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1742         ],[],[${other_libs}])
1743       ],[${other_libs_pic}])
1744     ])
1745     VLC_RESTORE_FLAGS
1746     AC_LANG_POP(C++)
1747   ])
1748 ])
1749
1750 dnl
1751 dnl IIDC and DV FireWire input modules
1752 dnl
1753 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1754 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1755
1756 dnl
1757 dnl - linsys modules: access module check for libzvbi
1758 dnl
1759 AC_ARG_ENABLE(linsys,
1760   [AS_HELP_STRING([--enable-linsys],
1761     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1762 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1763   VLC_ADD_PLUGIN([linsys_hdsdi])
1764   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1765     VLC_ADD_PLUGIN([linsys_sdi])
1766   ], [
1767     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1768   ])
1769 ])
1770
1771 dnl
1772 dnl dvdread module: check for libdvdread
1773 dnl
1774 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1775
1776 dnl
1777 dnl libdvdnav plugin
1778 dnl
1779 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1780 AS_IF([test "${enable_dvdnav}" != "no"], [
1781   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1782     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1783       AC_MSG_RESULT(yes)
1784       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1785       ],[
1786       AC_MSG_RESULT(no)
1787     ])
1788 ])
1789
1790 dnl
1791 dnl  Blu-ray Disc Support with libbluray
1792 dnl
1793 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1794
1795 dnl
1796 dnl  OpenCV wrapper and example filters
1797 dnl
1798 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1799
1800
1801 dnl
1802 dnl  libsmbclient plugin
1803 dnl
1804 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1805 AS_IF([test "${SYS}" = "mingw32" -a "${enable_winstore_app}" != "yes"], [ VLC_ADD_PLUGIN([smb]) ])
1806
1807 dnl
1808 dnl  liBDSM access module
1809 dnl
1810 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1811
1812 dnl
1813 dnl sftp access support
1814 dnl
1815 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1816
1817 dnl
1818 dnl nfs access support
1819 dnl
1820 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1821
1822 dnl
1823 dnl  Video4Linux 2
1824 dnl
1825 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1826   [disable Video4Linux version 2 (default auto)])])
1827 have_v4l2="no"
1828 AS_IF([test "$enable_v4l2" != "no"], [
1829   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1830     have_v4l2="yes"
1831   ])
1832 ])
1833 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1834
1835 dnl
1836 dnl special access module for Blackmagic SDI cards
1837 dnl
1838 AC_ARG_ENABLE(decklink,
1839   [AS_HELP_STRING([--disable-decklink],
1840     [disable Blackmagic DeckLink SDI input (default auto)])])
1841 AC_ARG_WITH(decklink_sdk,
1842   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1843     [                        location of Blackmagic DeckLink SDI SDK])])
1844 have_decklink=no
1845 if test "${enable_decklink}" != "no"
1846 then
1847   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1848   then
1849     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1850   fi
1851   VLC_SAVE_FLAGS
1852   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1853   AC_LANG_PUSH(C++)
1854   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1855       have_decklink=yes
1856   ], [
1857       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1858   ])
1859   AC_LANG_POP(C++)
1860   VLC_RESTORE_FLAGS
1861 fi
1862 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1863
1864
1865 dnl
1866 dnl  Built-in CD-DA and VCD module
1867 dnl
1868 AC_ARG_ENABLE(vcd,
1869   [AS_HELP_STRING([--disable-vcd],
1870     [disable built-in VCD and CD-DA support (default enabled)])])
1871
1872 AC_ARG_ENABLE(libcddb,
1873   [AS_HELP_STRING([--disable-libcddb],
1874     [disable CDDB for Audio CD (default enabled)])])
1875
1876 if test "${enable_vcd}" != "no"
1877 then
1878   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1879   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1880     AC_MSG_RESULT(yes)
1881     VLC_ADD_PLUGIN([vcd cdda])
1882   ],[
1883     AC_MSG_RESULT(no)
1884   ])
1885
1886   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1887   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1888     AC_MSG_RESULT(yes)
1889     VLC_ADD_PLUGIN([vcd cdda])
1890     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1891   ],[
1892     AC_MSG_RESULT(no)
1893   ])
1894
1895   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1896   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1897     AC_MSG_RESULT(yes)
1898     VLC_ADD_PLUGIN([vcd cdda])
1899     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1900   ],[
1901     AC_MSG_RESULT(no)
1902   ])
1903
1904   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1905   then
1906     VLC_ADD_PLUGIN([vcd cdda])
1907   fi
1908
1909   if test "$enable_libcddb" != "no"; then
1910     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1911       HAVE_LIBCDDB=yes
1912       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1913       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1914       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1915       ],:
1916       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1917       HAVE_LIBCDDB=no])
1918   fi
1919 fi
1920
1921 dnl
1922 dnl Linux DVB
1923 dnl
1924 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1925   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1926 [#include <linux/dvb/version.h>
1927 #if (DVB_API_VERSION < 5)
1928 # error Linux DVB API v3.2 and older are not supported.
1929 #endif
1930 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1931 # error Linux DVB API v5.0 is unsupported. Please update.
1932 #endif
1933 ]])], [
1934   ac_cv_linux_dvb_5_1=yes
1935 ], [
1936   ac_cv_linux_dvb_5_1=no
1937 ])])
1938 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1939
1940 dnl
1941 dnl  Screen capture module
1942 dnl
1943 AC_ARG_ENABLE(screen,
1944   [AS_HELP_STRING([--enable-screen],
1945     [disable screen capture (default enabled)])])
1946 if test "${enable_screen}" != "no"; then
1947   if test "${SYS}" = "darwin"; then
1948     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1949       VLC_ADD_PLUGIN([screen])
1950     ])
1951   fi
1952 fi
1953 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1954
1955 dnl
1956 dnl  VNC/RFB access module
1957 dnl
1958 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1959
1960 dnl  RDP/Remote Desktop access module
1961 dnl
1962 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1963
1964 dnl
1965 dnl  Real RTSP plugin
1966 dnl
1967 AC_ARG_ENABLE(realrtsp,
1968   [  --enable-realrtsp       Real RTSP module (default disabled)])
1969 if test "${enable_realrtsp}" = "yes"; then
1970   VLC_ADD_PLUGIN([access_realrtsp])
1971 fi
1972
1973 dnl
1974 dnl QTKit
1975 AC_ARG_ENABLE(macosx-qtkit,
1976   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
1977 if test "x${enable_macosx_qtkit}" != "xno" &&
1978   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1979 then
1980   AC_CHECK_HEADERS(QTKit/QTKit.h, [
1981       VLC_ADD_PLUGIN([qtsound])
1982     ])
1983 fi
1984
1985 dnl
1986 dnl AVFoundation
1987 AC_SUBST(have_avfoundation, ["no"])
1988 AC_ARG_ENABLE(macosx-avfoundation,
1989   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
1990 if test "x${enable_macosx_avfoundation}" != "xno" &&
1991   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
1992 then
1993   SAVED_LIBS="${LIBS}"
1994   LIBS="-framework AVFoundation"
1995   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
1996   LIBS="${SAVED_LIBS}"
1997   if test "${have_avfoundation}" != "no"
1998   then
1999     VLC_ADD_PLUGIN([avcapture])
2000   fi
2001 fi
2002 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2003
2004 dnl
2005 dnl  DCP plugin (using asdcplib)
2006 dnl
2007 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2008 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2009
2010 dnl
2011 dnl  Demux plugins
2012 dnl
2013
2014 EXTEND_HELP_STRING([Mux/Demux plugins:])
2015
2016 dnl
2017 dnl  libdvbpsi check for ts mux/demux
2018 dnl
2019 have_dvbpsi="no"
2020 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2021 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2022
2023
2024 dnl
2025 dnl  GME demux plugin
2026 dnl
2027 AC_ARG_ENABLE(gme,
2028   [AS_HELP_STRING([--enable-gme],
2029     [use Game Music Emu (default auto)])])
2030 AS_IF([test "${enable_gme}" != "no"], [
2031   AC_CHECK_HEADER([gme/gme.h], [
2032     VLC_ADD_LIBS([gme], [-lgme])
2033     VLC_ADD_PLUGIN([gme])
2034   ], [
2035     AS_IF([test "x${enable_gme}" != "x"], [
2036       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2037     ])
2038   ])
2039 ])
2040
2041
2042 dnl
2043 dnl  SIDPlay plugin
2044 dnl
2045 AC_ARG_ENABLE(sid,
2046     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2047 AS_IF([test "${enable_sid}" != "no"], [
2048     PKG_CHECK_MODULES(SID, [libsidplay2], [
2049         AC_LANG_PUSH(C++)
2050         oldCPPFLAGS="$CPPFLAGS"
2051         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2052         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2053             VLC_ADD_PLUGIN([sid])
2054             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2055             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2056         ], [
2057             AS_IF([test -n "${enable_sid}"],
2058                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2059                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2060                 )
2061         ])
2062         CPPFLAGS="$oldCPPFLAGS"
2063         AC_LANG_POP(C++)
2064     ], [
2065         AS_IF([test "x${enable_sid}" = "xyes"],
2066             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2067             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2068             )
2069     ])
2070 ])
2071
2072
2073 dnl
2074 dnl  ogg demux plugin
2075 dnl
2076 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2077 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2078     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2079 ],[true])
2080 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2081 if test "${enable_sout}" != "no"; then
2082 dnl Check for libshout
2083     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2084 fi
2085
2086 dnl
2087 dnl  matroska demux plugin
2088 dnl
2089 PKG_ENABLE_MODULES_VLC([MATROSKA], [mkv], [libebml libmatroska], [MKV format support], [auto])
2090
2091 dnl
2092 dnl  modplug demux plugin
2093 dnl
2094 AC_ARG_ENABLE(mod,
2095   [AS_HELP_STRING([--disable-mod],
2096     [do not use libmodplug (default auto)])])
2097 if test "${enable_mod}" != "no" ; then
2098     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2099           VLC_ADD_PLUGIN([mod])
2100           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2101           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2102           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2103     ],[
2104        AS_IF([test -n "${enable_mod}"],
2105          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2106          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2107     ])
2108 fi
2109
2110 dnl
2111 dnl  mpc demux plugin
2112 dnl
2113 AC_ARG_ENABLE(mpc,
2114   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2115 if test "${enable_mpc}" != "no"
2116 then
2117   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2118     VLC_ADD_PLUGIN([mpc])
2119     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2120     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2121     VLC_ADD_PLUGIN([mpc])
2122     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2123 fi
2124
2125 dnl
2126 dnl  Codec plugins
2127 dnl
2128
2129 EXTEND_HELP_STRING([Codec plugins:])
2130
2131 dnl
2132 dnl wmafixed plugin
2133 dnl
2134 AC_ARG_ENABLE(wma-fixed,
2135   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2136 if test "${enable_wma_fixed}" = "yes"
2137 then
2138   VLC_ADD_PLUGIN([wma_fixed])
2139 fi
2140
2141 dnl
2142 dnl shine encoder plugin
2143 dnl
2144 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2145
2146
2147 dnl
2148 dnl openmax il codec plugin
2149 dnl
2150 AC_ARG_ENABLE(omxil,
2151   [  --enable-omxil          openmax il codec module (default disabled)])
2152 if test "${enable_omxil}" = "yes"
2153 then
2154   VLC_ADD_PLUGIN([omxil])
2155 fi
2156
2157 dnl
2158 dnl openmax il vout plugin
2159 dnl
2160 AC_ARG_ENABLE(omxil-vout,
2161   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2162 if test "${enable_omxil_vout}" = "yes"
2163 then
2164   VLC_ADD_PLUGIN([omxil_vout])
2165 fi
2166
2167 dnl
2168 dnl raspberry pi openmax il configuration
2169 dnl
2170 AC_ARG_ENABLE(rpi-omxil,
2171   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2172 if test "${enable_rpi_omxil}" = "yes"
2173 then
2174   VLC_ADD_PLUGIN([omxil omxil_vout])
2175   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2176 fi
2177
2178 dnl
2179 dnl CrystalHD codec plugin
2180 dnl
2181 AC_ARG_ENABLE(crystalhd,
2182   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2183 if test "${enable_crystalhd}" != "no"; then
2184     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2185       VLC_ADD_PLUGIN([crystalhd])
2186       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2187     ],[
2188       if test "${SYS}" = "mingw32" ; then
2189         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2190           VLC_ADD_PLUGIN([crystalhd])
2191           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2192             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2193             ])
2194         ],[
2195           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2196                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2197                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2198         ],[#define __LINUX_USER__
2199                #include <libcrystalhd/bc_dts_types.h>
2200         ])
2201       fi
2202     ],[
2203        #include <libcrystalhd/bc_dts_types.h>
2204       ])
2205 fi
2206
2207 dnl
2208 dnl  mad plugin
2209 dnl
2210 have_mad="no"
2211 MAD_CFLAGS=""
2212 MAD_LIBS=""
2213
2214 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2215   enable_mad="yes"
2216 ], [
2217   with_mad="no"
2218 ])
2219 AS_IF([test "${with_mad}" != "no"], [
2220   MAD_CFLAGS="-I${with_mad}/include"
2221   MAD_LIBS="-L${with_mad}/lib"
2222 ])
2223
2224 AC_ARG_ENABLE(mad,
2225   [  --enable-mad            libmad module (default enabled)])
2226 AS_IF([test "${enable_mad}" != "no"], [
2227   VLC_SAVE_FLAGS
2228   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2229   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2230   AC_CHECK_HEADERS(mad.h, [
2231     AC_CHECK_LIB(mad, mad_bit_init, [
2232       have_mad="yes"
2233       MAD_LIBS="${MAD_LIBS} -lmad"
2234     ])
2235   ])
2236   VLC_RESTORE_FLAGS
2237   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2238     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2239   ])
2240 ])
2241 AC_SUBST(MAD_CFLAGS)
2242 AC_SUBST(MAD_LIBS)
2243 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2244
2245 dnl  mpg123 plugin
2246 dnl
2247 dnl
2248 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2249
2250 dnl
2251 dnl gstreamer stuff
2252 dnl
2253 AC_ARG_ENABLE(gst-decode,
2254   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2255
2256 have_gst_decode="no"
2257 AS_IF([test "${enable_gst_decode}" != "no"], [
2258   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2259     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2260       have_gst_decode="yes"
2261     ], [
2262       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2263     ])
2264   ], [
2265     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2266   ])
2267 ])
2268 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2269
2270 dnl
2271 dnl  avcodec decoder/encoder plugin
2272 dnl
2273 AC_ARG_ENABLE(merge-ffmpeg,
2274 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2275   enable_merge_ffmpeg="no"
2276 ])
2277 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2278
2279 AC_MSG_CHECKING([for libavutil variant])
2280 PKG_CHECK_EXISTS([libavutil], [
2281   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2282   libavutil_micro="${libavutil_version##*.}"
2283   AS_IF([test ${libavutil_micro} -le 99], [
2284     avfork="libav"
2285   ], [
2286     avfork="ffmpeg"
2287   ])
2288 ], [
2289   avfork="none"
2290 ])
2291 AC_MSG_RESULT([${avfork}])
2292
2293 AC_ARG_ENABLE(avcodec,
2294 [  --enable-avcodec        libavcodec codec (default enabled)])
2295 AS_IF([test "${enable_avcodec}" != "no"], [
2296   dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2297   case "${avfork}" in
2298     libav) av_codec_ver="57.16.0" ;;
2299     ffmpeg) av_codec_ver="57.37.100" ;;
2300     *) AC_MSG_ERROR([Missing libav or FFmpeg])
2301   esac
2302   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2303     VLC_SAVE_FLAGS
2304     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2305     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2306     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2307     AC_CHECK_HEADERS(libavutil/avutil.h)
2308     VLC_RESTORE_FLAGS
2309     have_avcodec="yes"
2310   ],[
2311     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2312   ])
2313 ], [
2314   have_avcodec="no"
2315 ])
2316 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2317
2318 dnl
2319 dnl libva needs avcodec
2320 dnl
2321 AC_ARG_ENABLE(libva,
2322   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2323
2324 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2325   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2326 ])
2327
2328 have_vaapi="no"
2329 have_vaapi_drm="no"
2330 have_vaapi_x11="no"
2331 AS_IF([test "${enable_libva}" != "no"], [
2332   PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2333     have_vaapi="yes"
2334   ], [
2335     AS_IF([test -n "${enable_libva}"], [
2336       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2337     ], [
2338       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2339     ])
2340   ])
2341   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2342     have_vaapi_drm="yes"
2343   ], [
2344     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2345   ])
2346   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2347     have_vaapi_x11="yes"
2348   ], [
2349     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2350   ])
2351 ])
2352 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2353 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2354
2355 have_avcodec_vaapi="no"
2356 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2357   VLC_SAVE_FLAGS
2358   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2359   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2360   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2361     AC_MSG_NOTICE([VA API acceleration activated])
2362     have_avcodec_vaapi="yes"
2363   ],[
2364     AS_IF([test -n "${enable_libva}"], [
2365       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2366     ], [
2367       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2368     ])
2369   ])
2370   VLC_RESTORE_FLAGS
2371 ])
2372 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2373
2374 dnl
2375 dnl dxva2 needs avcodec
2376 dnl
2377 AC_ARG_ENABLE(dxva2,
2378   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2379
2380 have_avcodec_dxva2="no"
2381 AS_IF([test "${enable_dxva2}" != "no"], [
2382   if test "${SYS}" = "mingw32"; then
2383   AS_IF([test "x${have_avcodec}" = "xyes"], [
2384     AC_CHECK_HEADERS(dxva2api.h,
2385       [
2386         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2387            AC_MSG_NOTICE([DxVA2 acceleration activated])
2388            have_avcodec_dxva2="yes"
2389         ],[
2390     AS_IF([test "${enable_dxva2}" = "yes"],
2391           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2392               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2393         ], [#undef _WIN32_WINNT
2394             /* DXVA2 is only available in Vista and above */
2395             #define _WIN32_WINNT 0x600])
2396       ],[
2397     AS_IF([test "${enable_dxva2}" = "yes"],
2398               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2399               [AC_MSG_WARN([dxva2api.h not found])])
2400       ],[#include <d3d9.h>])
2401   ],[
2402     AS_IF([test "x${enable_dxva2}" != "x"], [
2403       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2404     ])
2405   ])
2406   fi
2407 ])
2408 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2409
2410 dnl
2411 dnl d3d11va needs avcodec
2412 dnl
2413 AC_ARG_ENABLE(d3d11va,
2414   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2415
2416 have_avcodec_d3d11va="no"
2417 AS_IF([test "${enable_d3d11va}" != "no"], [
2418   if test "${SYS}" = "mingw32"; then
2419   AS_IF([test "x${have_avcodec}" = "xyes"], [
2420         AC_CHECK_TYPES([ID3D11VideoDecoder],
2421           [
2422             AC_CHECK_HEADERS(dxva2api.h,
2423               [
2424                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2425                    AC_MSG_NOTICE([D3D11 acceleration activated])
2426                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2427                    have_avcodec_d3d11va="yes"
2428                 ],[
2429                   AS_IF([test "${enable_d3d11va}" = "yes"],
2430                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2431                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2432                   ], [#undef _WIN32_WINNT
2433                       /* D3D11 is only available in Vista and above */
2434                       #define _WIN32_WINNT 0x600])
2435                   ],[
2436                     AS_IF([test "${enable_d3d11va}" = "yes"],
2437                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2438                           [AC_MSG_WARN([dxva2api.h not found])])
2439                   ],[#include <d3d9.h>])
2440           ],[
2441             AS_IF([test "${enable_d3d11va}" = "yes"],
2442                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2443                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2444           ], [#include <d3d11.h>])
2445   ],[
2446     AS_IF([test "x${enable_d3d11va}" != "x"], [
2447       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2448     ])
2449   ])
2450   fi
2451 ])
2452 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2453
2454 dnl
2455 dnl DXGI debug
2456 dnl
2457 AC_CHECK_HEADERS(dxgidebug.h)
2458
2459 dnl
2460 dnl  avformat demuxer/muxer plugin
2461 dnl
2462
2463 AC_ARG_ENABLE(avformat,
2464 [  --enable-avformat       libavformat containers (default enabled)],, [
2465   enable_avformat="${have_avcodec}"
2466 ])
2467 have_avformat="no"
2468 AS_IF([test "${enable_avformat}" != "no"], [
2469   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2470       have_avformat="yes"
2471       VLC_SAVE_FLAGS
2472       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2473       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2474       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2475       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2476       AC_CHECK_HEADERS(libavutil/avutil.h)
2477       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2478         have_avformat="no"
2479       ])
2480       VLC_RESTORE_FLAGS
2481     ],[
2482       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2483   ])
2484 ])
2485 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2486
2487 dnl
2488 dnl  swscale image scaling and conversion plugin
2489 dnl
2490
2491 AC_ARG_ENABLE(swscale,
2492   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2493           (default enabled)]))
2494 if test "${enable_swscale}" != "no"
2495 then
2496   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2497     [
2498       VLC_SAVE_FLAGS
2499       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2500       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2501       AC_CHECK_HEADERS(libswscale/swscale.h)
2502       AC_CHECK_HEADERS(libavutil/avutil.h)
2503       VLC_ADD_PLUGIN([swscale])
2504       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2505       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2506       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2507         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2508       ])
2509       VLC_RESTORE_FLAGS
2510     ],[
2511       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2512   ])
2513 fi
2514
2515 dnl
2516 dnl  postproc plugin
2517 dnl
2518
2519 AC_ARG_ENABLE(postproc,
2520 [  --enable-postproc       libpostproc image post-processing (default auto)])
2521 if test "${enable_postproc}" != "no"
2522 then
2523   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2524     [
2525       VLC_SAVE_FLAGS
2526       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2527       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2528       AC_CHECK_HEADERS(postproc/postprocess.h)
2529       VLC_ADD_PLUGIN([postproc])
2530       VLC_RESTORE_FLAGS
2531     ],[
2532       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2533   ])
2534 fi
2535
2536 dnl
2537 dnl  faad decoder plugin
2538 dnl
2539 AC_ARG_ENABLE(faad,
2540 [  --enable-faad           faad codec (default auto)])
2541 have_faad="no"
2542 AS_IF([test "${enable_faad}" != "no"], [
2543   AC_CHECK_HEADERS([neaacdec.h], [
2544     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2545
2546     AS_IF([test "${have_faad}" = "yes"], [
2547       VLC_ADD_PLUGIN([faad])
2548       VLC_ADD_LIBS([faad],[-lfaad])
2549     ], [
2550       AS_IF([test "${enable_faad}" = "yes"], [
2551         AC_MSG_ERROR([cannot find FAAD library])
2552       ], [
2553         AC_MSG_WARN([cannot find FAAD library])
2554       ])
2555     ])
2556   ])
2557 ])
2558
2559 dnl
2560 dnl  AOM decoder plugin
2561 dnl
2562 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec], [disabled])
2563
2564 dnl
2565 dnl libvpx decoder plugin
2566 dnl
2567 AC_ARG_ENABLE(vpx,
2568     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2569 AS_IF([test "${enable_vpx}" != "no"],[
2570     PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2571         VLC_ADD_PLUGIN([vpx])
2572         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2573         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2574         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2575             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2576         ], [], [${VPX_LIBS}])
2577         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2578             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2579         ], [], [${VPX_LIBS}])
2580         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2581             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2582         ], [], [${VPX_LIBS}])
2583         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2584             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2585         ], [], [${VPX_LIBS}])
2586     ], [
2587     AS_IF([test "${enable_vpx}" = "yes"],[
2588         AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2589     ])])
2590 ])
2591
2592 dnl
2593 dnl twolame encoder plugin
2594 dnl
2595 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2596
2597 dnl
2598 dnl fdk-aac encoder plugin
2599 dnl
2600 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2601
2602
2603 dnl
2604 dnl A52/AC3 decoder plugin
2605 dnl
2606 AC_ARG_ENABLE(a52,
2607   [  --enable-a52            A/52 support with liba52 (default enabled)])
2608 if test "${enable_a52}" != "no"
2609 then
2610   AC_ARG_WITH(a52,
2611     [  --with-a52=PATH         a52 headers and libraries])
2612     if test -z "${with_a52}"
2613     then
2614       LDFLAGS_test=""
2615       CPPFLAGS_test=""
2616     else
2617       LDFLAGS_test="-L${with_a52}/lib"
2618       CPPFLAGS_test="-I${with_a52}/include"
2619     fi
2620     VLC_SAVE_FLAGS
2621     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2622     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2623     AC_CHECK_HEADERS(a52dec/a52.h, [
2624       AC_CHECK_LIB(a52, a52_free, [
2625         VLC_ADD_PLUGIN([a52])
2626         VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2627         VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2628       ],[
2629         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2630         ], [$LIBM])
2631     ],[
2632       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2633     ])
2634     VLC_RESTORE_FLAGS
2635 fi
2636
2637 dnl
2638 dnl DTS Coherent Acoustics decoder plugin
2639 dnl
2640 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2641
2642 dnl
2643 dnl  Flac plugin
2644 dnl
2645 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2646
2647 dnl
2648 dnl  Libmpeg2 plugin
2649 dnl
2650 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2651
2652 dnl
2653 dnl  Vorbis plugin
2654 dnl
2655 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2656
2657 dnl
2658 dnl  Tremor plugin
2659 dnl
2660 AC_ARG_ENABLE(tremor,
2661   [  --enable-tremor         Tremor decoder support (default disabled)])
2662 if test "${enable_tremor}" = "yes"
2663 then
2664   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2665     VLC_ADD_PLUGIN([tremor])
2666    ],[])
2667 fi
2668
2669 dnl
2670 dnl  Speex plugins
2671 dnl
2672 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2673 have_speexdsp="no"
2674 AS_IF([test "${enable_speex}" != "no"], [
2675   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2676     have_speexdsp="yes"
2677   ], [
2678     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2679   ])
2680 ])
2681 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2682
2683 dnl
2684 dnl  Opus plugin
2685 dnl
2686 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2687
2688 dnl
2689 dnl  theora decoder plugin
2690 dnl
2691 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2692
2693 dnl
2694 dnl  OggSpots decoder plugin
2695 dnl
2696 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2697
2698 dnl
2699 dnl  Daala decoder plugin
2700 dnl
2701 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2702
2703 dnl
2704 dnl  schroedinger decoder plugin (for dirac format video)
2705 dnl
2706 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2707
2708 dnl
2709 dnl  PNG decoder module
2710 dnl
2711 AC_ARG_ENABLE(png,
2712   [  --enable-png            PNG support (default enabled)])
2713 AS_IF([test "${enable_png}" != "no"], [
2714 AC_CHECK_HEADERS(png.h, [
2715   VLC_SAVE_FLAGS
2716   LDFLAGS="${LDFLAGS} -lz $LIBM"
2717   AC_CHECK_LIB(png, png_set_alpha_mode, [
2718     VLC_ADD_PLUGIN([png])
2719   ], [], [-lz $LIBM])
2720   VLC_RESTORE_FLAGS
2721   ])
2722 ])
2723
2724 dnl
2725 dnl  JPEG decoder module
2726 dnl
2727 AC_ARG_ENABLE(jpeg,
2728   [  --enable-jpeg           JPEG support (default enabled)])
2729 AS_IF([test "${enable_jpeg}" != "no"], [
2730 AC_CHECK_HEADERS(jpeglib.h, [
2731   VLC_ADD_PLUGIN([jpeg])
2732   ])
2733 ])
2734
2735 dnl
2736 dnl  BPG decoder module
2737 dnl
2738 AC_ARG_ENABLE(bpg,
2739   [  --enable-bpg           BPG support (default disabled)])
2740 AS_IF([test "${enable_bpg}" != "no"], [
2741 AC_CHECK_HEADERS(libbpg.h, [
2742   VLC_ADD_PLUGIN([bpg])
2743   ])
2744 ])
2745
2746 dnl
2747 dnl H262 encoder plugin (lib262)
2748 dnl
2749 AC_ARG_ENABLE(x262,
2750   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2751 if test "${enable_x262}" != "no"; then
2752     PKG_CHECK_MODULES(X262, x262, [
2753         VLC_ADD_PLUGIN([x262])
2754         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2755         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2756           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2757         ])
2758         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2759         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2760           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2761         fi
2762     ], [
2763        if test "${enable_x262}" = "yes"; then
2764         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2765        fi
2766     ])
2767 fi
2768
2769 dnl x265 encoder
2770 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2771
2772 dnl
2773 dnl H264 encoder plugin (10-bit lib264)
2774 dnl
2775 AC_ARG_ENABLE(x26410b,
2776   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2777 if test "${enable_x26410b}" != "no"; then
2778     PKG_CHECK_MODULES(X26410B, x26410b, [
2779         VLC_ADD_PLUGIN([x26410b])
2780         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2781         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2782           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2783         ])
2784         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2785         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2786           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2787         fi
2788     ], [
2789        if test "${enable_x26410b}" = "yes"; then
2790         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2791        fi
2792     ])
2793 fi
2794
2795
2796 dnl
2797 dnl H264 encoder plugin (using libx264)
2798 dnl
2799 AC_ARG_ENABLE(x264,
2800   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2801 if test "${enable_x264}" != "no"; then
2802       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2803         VLC_ADD_PLUGIN([x264])
2804         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2805
2806         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2807           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2808         ])
2809
2810         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2811         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2812           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2813         fi
2814       ],[
2815         if test "${enable_x264}" = "yes"; then
2816             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2817           fi
2818       ])
2819 fi
2820
2821 dnl
2822 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2823 dnl
2824 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2825
2826 dnl
2827 dnl libfluidsynth (MIDI synthetizer) plugin
2828 dnl
2829 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2830 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2831 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2832
2833 dnl
2834 dnl Teletext Modules
2835 dnl vbi decoder plugin (using libzbvi)
2836 dnl telx module
2837 dnl uncompatible
2838 dnl
2839 AC_ARG_ENABLE(zvbi,
2840   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2841                   libzvbi (default enabled)]))
2842 AC_ARG_ENABLE(telx,
2843   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2844                   zvbi) (default enabled if zvbi is absent)]))
2845
2846 AS_IF( [test "${enable_zvbi}" != "no"],[
2847     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2848         [
2849           VLC_ADD_PLUGIN([zvbi])
2850           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2851           AS_IF( [test "${enable_telx}" = "yes"],[
2852                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2853                   ])
2854         ],[
2855           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2856         ])
2857     ])
2858 AS_IF( [test "${enable_telx}" != "no" ],[
2859   VLC_ADD_PLUGIN([telx])
2860   ])
2861
2862 dnl
2863 dnl libass subtitle rendering module
2864 dnl
2865 AC_ARG_ENABLE(libass,
2866   [  --enable-libass         Subtitle support using libass (default enabled)])
2867 AS_IF( [test "${enable_libass}" != "no"], [
2868   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2869       [
2870         VLC_ADD_PLUGIN([libass])
2871
2872         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2873           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2874            VLC_ADD_LIBS([libass],[-lfontconfig])
2875        ])
2876       ],[
2877         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2878       ])
2879   ])
2880
2881 dnl
2882 dnl ARIB subtitles rendering module
2883 dnl
2884 AC_ARG_ENABLE(aribsub,
2885   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2886 AS_IF( [test "${enable_aribsub}" != "no" ],[
2887   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2888       have_aribb24="yes"
2889       VLC_ADD_PLUGIN([aribsub])
2890       VLC_ADD_LIBS([aribsub],[-laribb24])
2891       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2892     ],[
2893       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2894       have_aribb24="no"
2895   ])
2896 ])
2897 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2898
2899 dnl
2900 dnl ARIB B25
2901 dnl
2902 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2903
2904 dnl
2905 dnl  kate decoder plugin
2906 dnl
2907 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2908
2909 dnl
2910 dnl  tiger rendering for kate decoder plugin
2911 dnl
2912 AC_ARG_ENABLE(tiger,
2913 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2914 AS_IF([test "${enable_tiger}" != "no"], [
2915   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2916       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2917         AS_IF([test -n "${enable_tiger}"], [
2918           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2919         ])
2920   ])
2921 ])
2922
2923
2924 dnl
2925 dnl  Video plugins
2926 dnl
2927
2928 EXTEND_HELP_STRING([Video plugins:])
2929
2930 dnl
2931 dnl  OpenGL
2932 dnl
2933 PKG_CHECK_MODULES([EGL], [egl], [
2934   have_egl="yes"
2935 ], [
2936   have_egl="no"
2937 ])
2938 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
2939
2940 have_gl="no"
2941 PKG_CHECK_MODULES([GL], [gl], [
2942   have_gl="yes"
2943 ], [
2944   AC_MSG_CHECKING([for OpenGL])
2945   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2946 #ifdef _WIN32
2947 # include <GL/glew.h>
2948 #endif
2949 #include <GL/gl.h>
2950 ]], [
2951     [int t0 = GL_TEXTURE0;]])
2952   ], [
2953     GL_CFLAGS=""
2954     have_gl="yes"
2955     AS_IF([test "${SYS}" != "mingw32"], [
2956       GL_LIBS="-lGL"
2957     ], [
2958       GL_LIBS="-lopengl32"
2959     ])
2960   ])
2961   AC_MSG_RESULT([${have_gl}])
2962 ])
2963 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
2964
2965 dnl OpenGL ES 2: depends on EGL 1.1
2966 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
2967
2968 dnl
2969 dnl  Xlib
2970 dnl
2971
2972 AC_PATH_XTRA()
2973 AC_CHECK_HEADERS(X11/Xlib.h)
2974
2975 dnl
2976 dnl  X C Bindings modules
2977 dnl
2978 AC_ARG_ENABLE(xcb,
2979   [  --enable-xcb            X11 support with XCB (default enabled)],, [
2980   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
2981     enable_xcb="yes"
2982   ], [
2983     enable_xcb="no"
2984   ])
2985 ])
2986 AC_ARG_ENABLE(xvideo,
2987   [  --enable-xvideo         XVideo support (default enabled)],, [
2988     enable_xvideo="$enable_xcb"
2989 ])
2990
2991 have_xcb="no"
2992 have_xcb_keysyms="no"
2993 have_xcb_randr="no"
2994 have_xcb_xvideo="no"
2995 AS_IF([test "${enable_xcb}" != "no"], [
2996   dnl libxcb
2997   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
2998   have_xcb="yes"
2999   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3000   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3001   PKG_CHECK_MODULES(XPROTO, [xproto])
3002
3003   AS_IF([test "${enable_xvideo}" != "no"], [
3004     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3005   ])
3006
3007   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3008
3009   dnl xcb-utils
3010   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3011     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3012   ])
3013 ])
3014 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3015 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3016 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3017 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3018
3019
3020 dnl
3021 dnl VDPAU needs X11
3022 dnl
3023 AC_ARG_ENABLE(vdpau,
3024   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3025 have_vdpau="no"
3026 AS_IF([test "${enable_vdpau}" != "no"], [
3027   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3028     have_vdpau="yes"
3029     AS_IF([test "${no_x}" = "yes"], [
3030       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3031     ])
3032   ], [
3033     AS_IF([test -n "${enable_vdpau}"], [
3034       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3035     ])
3036   ])
3037 ])
3038 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3039
3040 have_avcodec_vdpau="no"
3041 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3042   case "${avfork}" in
3043     libav) av_vdpau_ver="56.10.0" ;;
3044     ffmpeg) av_vdpau_ver="56.19.100" ;;
3045   esac
3046   PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3047     have_avcodec_vdpau="yes"
3048     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3049   ], [
3050     AS_IF([test -n "${enable_vdpau}"], [
3051       AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3052     ], [
3053       AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3054     ])
3055   ])
3056 ])
3057 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3058
3059
3060 dnl
3061 dnl  Wayland
3062 dnl
3063 AC_ARG_ENABLE(wayland,
3064   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3065 have_wayland="no"
3066 have_wayland_egl="no"
3067
3068 AS_IF([test "${enable_wayland}" != "no"], [
3069   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3070     AC_MSG_CHECKING([for the Wayland protocols])
3071     PKG_CHECK_EXISTS([wayland-protocols >= 1.4], [
3072       WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3073       AC_MSG_RESULT([${WAYLAND_PROTOCOLS}])
3074     ], [
3075       AC_MSG_RESULT([not found])
3076       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors 'wayland-protocols >= 1.4')])
3077     ])
3078
3079     AC_MSG_CHECKING([for the Wayland scanner])
3080     PKG_CHECK_EXISTS([wayland-scanner], [
3081       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3082       AC_MSG_RESULT([${WAYLAND_SCANNER}])
3083     ], [
3084       AC_MSG_RESULT([not found])
3085       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors wayland-scanner)])
3086     ])
3087
3088     have_wayland="yes"
3089
3090     AS_IF([test "${have_egl}" = "yes"], [
3091       PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3092         have_wayland_egl="yes"
3093       ], [
3094         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3095       ])
3096     ])
3097   ], [
3098     AS_IF([test -n "${enable_wayland}"], [
3099       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3100     ])
3101   ])
3102 ])
3103 AC_SUBST([WAYLAND_PROTOCOLS])
3104 AC_SUBST([WAYLAND_SCANNER])
3105 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3106 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3107
3108
3109 dnl
3110 dnl  SDL module
3111 dnl
3112 AC_ARG_ENABLE(sdl,
3113   [  --enable-sdl            SDL support (default enabled)])
3114 AC_ARG_ENABLE(sdl-image,
3115   [  --enable-sdl-image      SDL image support (default enabled)])
3116 if test "${enable_sdl}" != "no"
3117 then
3118    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3119       # SDL on Darwin is heavily patched and can only run SDL_image
3120       if test "${SYS}" != "darwin"; then
3121         VLC_ADD_PLUGIN([vout_sdl])
3122       fi
3123
3124       # SDL_image
3125       AS_IF([ test "${enable_sdl_image}" != "no"],[
3126         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3127           VLC_ADD_PLUGIN([sdl_image])],
3128           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3129           ])
3130       ])
3131    ],[
3132      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3133    ])
3134 fi
3135
3136 dnl
3137 dnl  freetype module
3138 dnl
3139 AC_ARG_ENABLE(freetype,
3140   [  --enable-freetype       freetype support   (default auto)])
3141 AC_ARG_ENABLE(fribidi,
3142   [  --enable-fribidi        fribidi support    (default auto)])
3143 AC_ARG_ENABLE(harfbuzz,
3144   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3145 AC_ARG_ENABLE(fontconfig,
3146   [  --enable-fontconfig     fontconfig support (default auto)])
3147
3148 AC_ARG_WITH([default-font],
3149     AS_HELP_STRING([--with-default-font=PATH],
3150         [Path to the default font]),
3151         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3152             "$withval", [Default font])])
3153 AC_ARG_WITH([default-monospace-font],
3154     AS_HELP_STRING([--with-default-monospace-font=PATH],
3155         [Path to the default font]),
3156         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3157             "$withval", [Default monospace font])])
3158
3159 AC_ARG_WITH([default-font-family],
3160     AS_HELP_STRING([--with-default-font-family=NAME],
3161         [Path to the default font family]),
3162         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3163             "$withval", [Default font family])])
3164 AC_ARG_WITH([default-monospace-font-family],
3165     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3166         [Path to the default font family]),
3167         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3168             "$withval", [Default monospace font family])])
3169
3170 have_freetype="no"
3171 have_fontconfig="no"
3172 have_fribidi="no"
3173 have_harfbuzz="no"
3174
3175 if test "${enable_freetype}" != "no"; then
3176    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3177       have_freetype="yes"
3178       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3179       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3180
3181     dnl fontconfig support
3182     AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3183       PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3184         have_fontconfig="yes"
3185       ], [
3186         AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3187       ])
3188     ])
3189
3190       dnl fribidi support
3191       if test "${enable_fribidi}" != "no"; then
3192         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3193           have_fribidi="yes"
3194           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3195           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3196         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3197       fi
3198
3199       dnl harfbuzz support
3200       if test "${have_fribidi}" != "no"; then
3201         if test "${enable_harfbuzz}" != "no"; then
3202           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3203             have_harfbuzz="yes"
3204             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3205             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3206           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3207         fi
3208       fi
3209   ],[
3210   AS_IF([test -n "${enable_freetype}"],[
3211     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3212     ])
3213   ])
3214 fi
3215
3216 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3217 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3218 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3219 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3220
3221 dnl
3222 dnl SAPI (text to Speech renderer for Windows)
3223 dnl
3224 AC_LANG_PUSH([C++])
3225 AC_CHECK_TYPES([ISpObjectToken],[
3226               have_sapi="yes"
3227             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3228               [#include <windows.h>
3229                #include <sapi.h>
3230                #include <sphelper.h>])
3231 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3232 AC_LANG_POP([C++])
3233
3234 dnl
3235 dnl  SVG module (text rendering and image decoding)
3236 dnl
3237 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3238 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3239
3240 dnl
3241 dnl  Windows DirectX module
3242 dnl
3243
3244 AC_ARG_ENABLE(directx,
3245   [AS_HELP_STRING([--enable-directx],
3246     [Microsoft DirectX support (default enabled on Windows)])],, [
3247   AS_IF([test "${SYS}" = "mingw32"], [
3248     enable_directx="yes"
3249   ], [
3250     enable_directx="no"
3251   ])
3252 ])
3253 AS_IF([test "${enable_directx}" != "no"], [
3254   dnl DirectDraw
3255   AC_CHECK_HEADERS(ddraw.h, [
3256     VLC_ADD_PLUGIN([directdraw])
3257   ])
3258
3259   dnl OpenGL
3260   AC_CHECK_HEADERS(GL/wglew.h, [
3261     VLC_ADD_PLUGIN([glwin32 wgl])
3262   ],, [
3263     #include <windows.h>
3264     #include <GL/gl.h>
3265   ])
3266
3267   dnl Direct3D11
3268   AC_CHECK_HEADERS(d3d11.h, [
3269     VLC_ADD_PLUGIN([direct3d11 direct3d11_deinterlace])
3270   ])
3271
3272   dnl Direct3D9
3273   AC_CHECK_HEADERS(d3d9.h, [
3274     VLC_ADD_PLUGIN([direct3d9])
3275
3276     AC_CHECK_FUNCS([IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids],
3277       [
3278         VLC_ADD_PLUGIN([dxva2_deinterlace])
3279       ],
3280       [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])],
3281       [#include <d3d9.h>
3282        #include <dxva2api.h>])
3283
3284   ])
3285 ])
3286
3287 dnl
3288 dnl  Linux framebuffer module
3289 dnl
3290 AC_CHECK_HEADER([linux/fb.h], [
3291   VLC_ADD_PLUGIN([fb])
3292 ])
3293
3294
3295 dnl
3296 dnl  DirectFB module
3297 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3298 dnl  TODO: support for static linking
3299 dnl
3300 AC_ARG_ENABLE(directfb,
3301   [  --enable-directfb       DirectFB support (default disabled)])
3302 AC_ARG_WITH(directfb,
3303   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3304
3305 if test "${enable_directfb}" = "yes"; then
3306     have_directfb="false"
3307     CPPFLAGS_mydirectfb=
3308     LIBS_mydirectfb=
3309     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3310         dnl Trying the given location
3311         VLC_SAVE_FLAGS
3312
3313         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3314         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3315
3316         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3317         LIBS="${LIBS} ${LIBS_new}"
3318
3319         dnl FIXME: too obscure
3320         AC_CHECK_HEADER([directfb.h], [
3321             AC_CHECK_LIB([direct],[direct_initialize], [
3322                 AC_CHECK_LIB([fusion], [fusion_enter], [
3323                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3324                 ], have_directfb="false")
3325             ], have_directfb="false")
3326         ], have_directfb="false")
3327
3328         VLC_RESTORE_FLAGS
3329
3330         if test "${have_directfb}" = "true"; then
3331             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3332             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3333         fi
3334     else
3335         dnl Look for directfb-config
3336         AC_CHECK_PROG(DIRECTFB_CONFIG, [directfb-config], [false])
3337         AS_IF(["${DIRECTFB_CONFIG}" != "false"], [
3338             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3339             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3340             have_directfb="true"
3341         ], [
3342             dnl Trying with pkg-config
3343             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3344                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3345                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3346                 have_directfb="true"
3347                 ], [have_directfb="false"])
3348         ])
3349     fi
3350     if test "${have_directfb}" = "true"; then
3351         VLC_ADD_PLUGIN([directfb])
3352         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3353         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3354     else
3355         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3356     fi
3357 fi
3358
3359 dnl
3360 dnl  AA plugin
3361 dnl
3362 AC_ARG_ENABLE(aa,
3363   [  --enable-aa             aalib output (default disabled)])
3364 if test "${enable_aa}" = "yes"
3365 then
3366   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3367   if test "${have_aa}" = "true"
3368   then
3369     VLC_ADD_PLUGIN([aa])
3370   fi
3371 fi
3372
3373 dnl
3374 dnl  libcaca plugin
3375 dnl
3376 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3377
3378 dnl
3379 dnl  OS/2 KVA plugin
3380 dnl
3381 AC_ARG_ENABLE(kva,
3382   [AS_HELP_STRING([--enable-kva],
3383     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3384   AS_IF([test "$SYS" = "os2"], [
3385     enable_kva="yes"
3386   ])
3387 ])
3388 have_kva="no"
3389 KVA_LIBS=""
3390 AS_IF([test "$enable_kva" != "no"], [
3391   AC_CHECK_HEADERS([kva.h], [
3392     have_kva="yes"
3393     AC_CHECK_LIB(kva, main, [
3394       KVA_LIBS="-lkva"
3395     ])
3396   ])
3397 ])
3398 AC_SUBST(KVA_LIBS)
3399 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3400
3401 dnl
3402 dnl MMAL plugin
3403 dnl
3404 AC_ARG_ENABLE(mmal,
3405   AS_HELP_STRING([--enable-mmal],
3406     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3407 if test "${enable_mmal}" != "no"; then
3408   VLC_SAVE_FLAGS
3409   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3410   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3411   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3412     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3413         have_mmal="yes"
3414         VLC_ADD_PLUGIN([mmal])
3415         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3416         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3417         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lvchostif ]) ], [
3418           AS_IF([test "${enable_mmal}" = "yes"],
3419             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3420             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3421           ],
3422         [])
3423     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3424       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3425       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3426   VLC_RESTORE_FLAGS
3427 fi
3428 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3429
3430 dnl
3431 dnl evas plugin
3432 dnl
3433 AC_ARG_ENABLE(evas,
3434   [AS_HELP_STRING([--enable-evas],
3435     [use evas output module (default disabled)])])
3436 have_evas="no"
3437 AS_IF([test "${enable_evas}" = "yes"], [
3438   PKG_CHECK_MODULES(EVAS, [evas >= 1.15.99 ecore >= 1.15.99], [
3439       have_evas="yes"
3440       AC_DEFINE([HAVE_EVAS], [1], [Define to 1 if evas is enabled.])
3441     ],[
3442     AS_IF([test "x${enable_evas}" != "x"], [
3443       AC_MSG_ERROR([$EVAS_PKG_ERRORS. libevas and libecore 1.15.99 or later required.])
3444     ])
3445   ])
3446 ])
3447 AM_CONDITIONAL([HAVE_EVAS], [test "${have_evas}" = "yes"])
3448
3449 dnl
3450 dnl  Audio plugins
3451 dnl
3452
3453 EXTEND_HELP_STRING([Audio plugins:])
3454
3455 dnl
3456 dnl  Pulseaudio module
3457 dnl
3458 AC_ARG_ENABLE(pulse,
3459   [AS_HELP_STRING([--enable-pulse],
3460     [use the PulseAudio client library (default auto)])])
3461 have_pulse="no"
3462 AS_IF([test "${enable_pulse}" != "no"], [
3463   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3464     have_pulse="yes"
3465   ], [
3466     AS_IF([test "x${enable_pulse}" != "x"], [
3467       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3468     ])
3469   ])
3470 ])
3471 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3472
3473 dnl
3474 dnl  ALSA module
3475 dnl
3476 AC_ARG_ENABLE(alsa,
3477   [AS_HELP_STRING([--enable-alsa],
3478     [support the Advanced Linux Sound Architecture (default auto)])],, [
3479   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3480     enable_alsa="yes"
3481   ])
3482 ])
3483 have_alsa="no"
3484 AS_IF([test "${enable_alsa}" != "no"], [
3485   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3486     have_alsa="yes"
3487   ], [
3488     AS_IF([test "x${enable_alsa}" != "x"], [
3489       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3490     ])
3491   ])
3492 ])
3493 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3494
3495 dnl
3496 dnl  Open Sound System module
3497 dnl
3498 AC_ARG_ENABLE(oss,
3499   [AS_HELP_STRING([--enable-oss],
3500     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3501   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3502     enable_oss="no"
3503   ])
3504 ])
3505 have_oss="no"
3506 OSS_LIBS=""
3507 AS_IF([test "$enable_oss" != "no"], [
3508   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3509     have_oss="yes"
3510     AC_CHECK_LIB(ossaudio, main, [
3511       OSS_LIBS="-lossaudio"
3512     ])
3513   ])
3514 ])
3515 AC_SUBST(OSS_LIBS)
3516 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3517
3518 dnl
3519 dnl  OpenBSD sndio module
3520 dnl
3521 AC_ARG_ENABLE([sndio],
3522   [AS_HELP_STRING([--disable-sndio],
3523     [support the OpenBSD sndio (default auto)])],, [
3524   AS_IF([test "$SYS" = "openbsd"], [
3525     enable_sndio="yes"
3526   ])
3527 ])
3528 have_sndio="no"
3529 AS_IF([test "$enable_sndio" != "no"], [
3530   AC_CHECK_HEADER([sndio.h], [
3531     have_sndio="yes"
3532   ])
3533 ])
3534 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3535
3536 dnl
3537 dnl  Windows Audio Session plugin
3538 dnl
3539 AC_ARG_ENABLE([wasapi],
3540   [AS_HELP_STRING([--enable-wasapi],
3541     [use the Windows Audio Session API (default auto)])
3542 ])
3543 have_wasapi="no"
3544 AS_IF([test "$enable_wasapi" != "no"], [
3545   AC_CHECK_HEADER([audioclient.h], [
3546     have_wasapi="yes"
3547   ], [
3548     AS_IF([test "x${enable_wasapi}" != "x"], [
3549       AC_MSG_ERROR([Windows Audio Session API not found.])
3550     ])
3551   ])
3552 ])
3553 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3554
3555 dnl
3556 dnl  JACK modules
3557 dnl
3558 AC_ARG_ENABLE(jack,
3559   [AS_HELP_STRING([--disable-jack],
3560     [do not use jack (default auto)])])
3561 have_jack="no"
3562 AS_IF([test "${enable_jack}" != "no"], [
3563     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3564       [ have_jack=yes ],
3565       [
3566       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3567
3568       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3569       [ have_jack=yes ],
3570       [
3571       AS_IF([test -n "${enable_jack}"],
3572          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3573          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3574       ])
3575     ])
3576 ])
3577 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3578
3579 dnl
3580 dnl  OpenSLES Android
3581 dnl
3582 AC_ARG_ENABLE(opensles,
3583   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3584 if test "${HAVE_ANDROID}" = "1"; then
3585   if test "${enable_opensles}" = "yes"; then
3586       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3587         [ VLC_ADD_PLUGIN([opensles_android]) ],
3588         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3589   fi
3590 fi
3591
3592 dnl
3593 dnl  Tizen audio
3594 dnl
3595 AC_ARG_ENABLE(tizen_audio,
3596   [AS_HELP_STRING([--enable-tizen-audio],
3597     [Tizen audio module (default enabled on Tizen)])],, [
3598   AS_IF([test "$HAVE_TIZEN" = "1"], [
3599     enable_tizen_audio="yes"
3600   ])
3601 ])
3602 if test "${enable_tizen_audio}" = "yes"; then
3603   AC_CHECK_HEADERS(audio_io.h,
3604     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3605     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3606 fi
3607
3608 dnl
3609 dnl libsamplerate plugin
3610 dnl
3611 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3612
3613 dnl
3614 dnl  soxr module
3615 dnl
3616 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3617
3618 dnl
3619 dnl  OS/2 KAI plugin
3620 dnl
3621 AC_ARG_ENABLE(kai,
3622   [AS_HELP_STRING([--enable-kai],
3623     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3624   AS_IF([test "$SYS" = "os2"], [
3625     enable_kai="yes"
3626   ])
3627 ])
3628 have_kai="no"
3629 KAI_LIBS=""
3630 AS_IF([test "$enable_kai" != "no"], [
3631   AC_CHECK_HEADERS([kai.h], [
3632     have_kai="yes"
3633     AC_CHECK_LIB(kai, main, [
3634       KAI_LIBS="-lkai"
3635     ])
3636   ])
3637 ])
3638 AC_SUBST(KAI_LIBS)
3639 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3640
3641 dnl
3642 dnl  chromaprint audio track fingerprinter
3643 dnl
3644 m4_pushdef([libchromaprint_version], 0.6.0)
3645 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3646     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3647     AS_IF([test "${enable_chromaprint}" = "yes"],
3648         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3649         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3650          ),
3651     [(Chromaprint based audio fingerprinter)],[auto])
3652 m4_popdef([libchromaprint_version])
3653
3654 dnl
3655 dnl  Chromecast streaming support
3656 dnl
3657 m4_pushdef([protobuf_lite_version], 2.5.0)
3658 AC_ARG_VAR(PROTOC, [protobuf compiler])
3659 AC_CHECK_PROGS(PROTOC, protoc, no)
3660 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3661     AS_IF([test "x${PROTOC}" != "xno"], [
3662         build_chromecast="yes"
3663     ], [
3664     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3665     ])
3666 ], [
3667     AS_IF([test "${enable_chromecast}" = "yes"],
3668         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3669         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3670     )
3671     enable_chromecast="no"
3672 ], [(Chromecast streaming support)], [auto])
3673 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3674 m4_popdef([protobuf_lite_version])
3675
3676 dnl
3677 dnl  Interface plugins
3678 dnl
3679
3680 EXTEND_HELP_STRING([Interface plugins:])
3681
3682 dnl
3683 dnl QT
3684 dnl
3685 AC_ARG_ENABLE(qt, [
3686   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3687   AS_IF([test "${SYS}" = "darwin"], [
3688     enable_qt="no"
3689   ])
3690 ])
3691 have_qt5_x11="no"
3692 AS_IF([test "${enable_qt}" != "no"], [
3693   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.2.0 Qt5Widgets Qt5Gui], [
3694       PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3695           have_qt5_x11="yes"
3696       ],[
3697           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3698       ])
3699       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3700       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3701       QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3702       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3703       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3704       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3705     ], [
3706       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.8.0],, [
3707         AS_IF([test -n "${enable_qt}"],[
3708           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3709         ],[
3710           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3711         ])
3712         enable_qt="no"
3713       ])
3714       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3715       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin"])
3716       AC_PATH_PROG(RCC, rcc, rcc, ["${QT_PATH}/bin"])
3717       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin"])
3718     ])
3719 ])
3720 AS_IF([test "${enable_qt}" != "no"], [
3721   ALIASES="${ALIASES} qvlc"
3722 ])
3723 AC_SUBST(QT_VERSION)
3724 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3725 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3726
3727 dnl
3728 dnl detect kde4-config patch (used for kde solids).
3729 dnl
3730 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3731 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3732   KDE4_CONFIG="kde4-config"
3733 ])
3734
3735 dnl
3736 dnl Simple test for skins2 dependency
3737 dnl
3738 AS_IF([test "$enable_qt" = "no"], [
3739   AS_IF([test "${enable_skins2}" = "yes"], [
3740     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3741   ], [
3742     enable_skins2="no"
3743     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3744   ])
3745 ])
3746
3747 dnl
3748 dnl Skins2 module
3749 dnl
3750 AC_ARG_ENABLE(skins2,
3751   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3752 AS_IF([test "${enable_skins2}" != "no"], [
3753   have_skins_deps="yes"
3754
3755   dnl Win32
3756   AS_IF([test "${SYS}" = "mingw32"], [
3757     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3758     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3759   dnl OS/2
3760   ], [test "${SYS}" = "os2"], [
3761     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3762   dnl Linux/Unix
3763   ], [
3764     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3765     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3766     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3767     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3768     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3769   ])
3770
3771   dnl we need freetype
3772   AS_IF([test "${have_freetype}" != "yes"], [
3773     have_skins_deps="no"
3774   ])
3775
3776   AS_IF([test "${have_skins_deps}" = "no"], [
3777     AS_IF([test "x${enable_skins2}" = "x"], [
3778       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3779     ], [
3780       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3781     ])
3782     enable_skins2="no"
3783   ], [
3784     ALIASES="${ALIASES} svlc"
3785     enable_skins2="yes"
3786   ])
3787 ])
3788 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3789
3790 AC_ARG_ENABLE(libtar,
3791   [  --enable-libtar         libtar support for skins2 (default auto)])
3792 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3793   AC_CHECK_HEADERS(libtar.h, [
3794     VLC_ADD_LIBS([skins2],[-ltar])
3795   ])
3796 ])
3797
3798 dnl
3799 dnl  MacOS X gui module
3800 dnl
3801 AC_ARG_ENABLE(macosx,
3802   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3803 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3804 then
3805
3806   dnl
3807   dnl If possible, use xcrun to find the right ibtool
3808   dnl
3809
3810   AC_PATH_PROG([XCRUN], [xcrun], [no])
3811   AS_IF([test ! "x${XCRUN}" = "xno"], [
3812     AC_MSG_CHECKING([for ibtool (using xcrun)])
3813     XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3814     AC_MSG_RESULT([${XIB}])
3815   ], [
3816     AC_MSG_WARN([Looking for tools without using xcrun])
3817   ])
3818
3819   AS_IF([test "x${XIB}" = "xno"], [
3820     AC_PATH_PROG(XIB, [ibtool], [no])
3821     AS_IF([test "x${XIB}" = "xno"], [
3822       AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3823     ])
3824   ])
3825
3826   VLC_ADD_PLUGIN([macosx])
3827 fi
3828 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3829
3830 dnl
3831 dnl  MacOS X sparkle update support
3832 dnl
3833 AC_ARG_ENABLE(sparkle,
3834   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3835 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3836 then
3837   if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3838   then
3839     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3840   fi
3841
3842   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3843 fi
3844 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3845
3846 dnl
3847 dnl  MacOS X breakpad creash reporter support
3848 dnl
3849 AC_ARG_ENABLE(breakpad,
3850   [  --enable-breakpad       Breakpad crash reporter support for OS X (default enabled on Mac OS X)])
3851 if test "x${enable_breakpad}" != "xno" -a "${HAVE_OSX}" = "1"
3852 then
3853   if test ! -d ${CONTRIB_DIR}/Breakpad.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework
3854   then
3855     AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3856   fi
3857
3858   AC_DEFINE([HAVE_BREAKPAD], [1], [Define to 1 if breakpad is enabled.])
3859 fi
3860 AM_CONDITIONAL(HAVE_BREAKPAD, [test "$enable_breakpad" != "no"])
3861
3862
3863 dnl
3864 dnl  Minimal Mac OS X module
3865 dnl
3866 AC_ARG_ENABLE(minimal-macosx,
3867   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3868 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3869 then
3870   VLC_ADD_PLUGIN([minimal_macosx])
3871 fi
3872
3873 dnl
3874 dnl Mac OS X fancy dmg build tool
3875 dnl
3876 if test "${HAVE_OSX}" = "1"
3877 then
3878   AC_PATH_PROG(DMGBUILD, dmgbuild, no)
3879   AS_IF([test "x${DMGBUILD}" = "xno"], [
3880     AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
3881   ])
3882 fi
3883 AM_CONDITIONAL(HAVE_DMGBUILD, [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
3884
3885 dnl
3886 dnl  VideoToolbox plugins
3887 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3888     VLC_ADD_PLUGIN([videotoolbox])
3889     VLC_ADD_PLUGIN([cvpx_i420])
3890   ])
3891
3892 dnl
3893 dnl  ncurses module
3894 dnl
3895 AC_ARG_ENABLE(ncurses,
3896 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3897 have_ncurses="no"
3898 AS_IF([test "${enable_ncurses}" != "no"] ,[
3899   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3900     have_ncurses="yes"
3901     ALIASES="${ALIASES} nvlc"
3902   ], [
3903     AS_IF([test -n "${enable_ncurses}"], [
3904       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3905     ])
3906   ])
3907 ])
3908 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3909
3910 dnl
3911 dnl  Lirc plugin
3912 dnl
3913 AC_ARG_ENABLE(lirc,
3914   [  --enable-lirc           lirc support (default disabled)])
3915 have_lirc="no"
3916 AS_IF([test "${enable_lirc}" = "yes"], [
3917   AC_CHECK_HEADER(lirc/lirc_client.h, [
3918     AC_CHECK_LIB(lirc_client, lirc_init, [
3919       have_lirc="yes"
3920     ])
3921   ])
3922 ])
3923 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3924
3925 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3926 dnl
3927 dnl  goom visualization plugin
3928 dnl
3929 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3930
3931 dnl
3932 dnl libprojectM visualization plugin
3933 dnl
3934 AC_ARG_ENABLE(projectm,
3935   [  --enable-projectm       projectM visualization plugin (default enabled)])
3936 AS_IF([test "${enable_projectm}" != "no"],
3937   [
3938     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3939     [
3940       VLC_ADD_PLUGIN([projectm])
3941       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3942         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3943         [ AC_MSG_WARN( [Using libprojectM version 1] )
3944       ])
3945     ],[
3946       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3947     ])
3948   ])
3949
3950 dnl
3951 dnl Vovoid VSXu visualization plugin
3952 dnl
3953 AC_ARG_ENABLE(vsxu,
3954   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3955 AS_IF([test "${enable_vsxu}" != "no"],
3956   [
3957     PKG_CHECK_MODULES(VSXU, libvsxu,
3958     [
3959       VLC_ADD_PLUGIN([vsxu])
3960     ],[
3961       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3962     ])
3963   ])
3964
3965 EXTEND_HELP_STRING([Service Discovery plugins:])
3966 dnl
3967 dnl  Avahi-Zeroconf services discovery
3968 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
3969
3970 dnl
3971 dnl  libudev services discovery
3972 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3973
3974 dnl
3975 dnl MTP devices services discovery
3976 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3977
3978 dnl
3979 dnl UPnP Plugin (Intel SDK)
3980 dnl
3981 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3982
3983 dnl
3984 dnl mDNS using libmicrodns
3985 dnl
3986 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
3987
3988
3989 EXTEND_HELP_STRING([Misc options:])
3990
3991 dnl
3992 dnl  libxml2 module
3993 dnl
3994 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3995
3996
3997 dnl
3998 dnl libgcrypt
3999 dnl
4000 AC_ARG_ENABLE(libgcrypt,
4001   [  --disable-libgcrypt     gcrypt support (default enabled)])
4002 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
4003 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4004
4005 # require libgcrypt >= 1.6.0
4006 AS_IF([test "${enable_libgcrypt}" != "no"], [
4007   AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4008     VLC_SAVE_FLAGS
4009     CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4010     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4011 [#include <gcrypt.h>
4012 #if GCRYPT_VERSION_NUMBER < 0x010600
4013 #error
4014 #endif]])], [
4015       ac_cv_lib_gcrypt=yes
4016     ], [
4017       ac_cv_lib_gcrypt=no
4018     ])
4019     VLC_RESTORE_FLAGS
4020   ])
4021
4022   AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4023     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4024   ], [
4025     AS_IF([test "${enable_libgcrypt}" = "yes"], [
4026       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4027     ])
4028   ])
4029 ])
4030
4031 AS_IF([test -z "$GCRYPT_LIBS"], [
4032   GCRYPT_LIBS="-lgcrypt -lgpg-error"
4033 ])
4034
4035 AC_SUBST(GCRYPT_CFLAGS)
4036 AC_SUBST(GCRYPT_LIBS)
4037 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4038
4039 dnl
4040 dnl TLS/SSL
4041 dnl
4042 AC_ARG_ENABLE(gnutls,
4043   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4044 AS_IF([test "${enable_gnutls}" != "no"], [
4045   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4046     VLC_ADD_PLUGIN([gnutls])
4047   ], [
4048     AS_IF([test -n "${enable_gnutls}"], [
4049       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4050     ])
4051   ])
4052 ])
4053
4054
4055 dnl
4056 dnl Taglib plugin
4057 dnl
4058 AC_ARG_ENABLE(taglib,
4059   [AS_HELP_STRING([--disable-taglib],
4060     [do not use TagLib (default enabled)])])
4061 AS_IF([test "${enable_taglib}" != "no"], [
4062   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4063     VLC_ADD_PLUGIN([taglib])
4064   ], [
4065     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4066 ])
4067
4068 dnl
4069 dnl  libsecret
4070 dnl
4071 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4072
4073 dnl
4074 dnl  kwallet
4075 dnl
4076 AC_ARG_ENABLE(kwallet,
4077   [AS_HELP_STRING([--enable-kwallet],
4078     [use kwallet (via D-Bus) for keystore (default enabled)])])
4079 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4080   VLC_ADD_PLUGIN([kwallet])
4081 ])
4082
4083 dnl
4084 dnl  Developers helper modules (should be hidden from configure help)
4085 dnl
4086 AC_ARG_ENABLE(devtools, [], [], [enable_devtools="no"])
4087 AS_IF([test "${enable_devtools}" != "no"], [
4088   VLC_ADD_PLUGIN([accesstweaks])
4089 ])
4090
4091 dnl
4092 dnl update checking system
4093 dnl
4094 AC_ARG_ENABLE(update-check,
4095   [  --enable-update-check   update checking system (default disabled)])
4096 if test "${enable_update_check}" = "yes"
4097 then
4098  AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4099     AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4100 fi
4101 AM_CONDITIONAL(UPDATE_CHECK, [test "${enable_update_check}" = "yes"])
4102
4103 dnl
4104 dnl OS X notification plugin
4105 dnl
4106 AC_ARG_ENABLE(osx_notifications,
4107   [  --enable-osx-notifications          osx notification plugin (default disabled)],,
4108   [enable_osx_notifications=no])
4109 AS_IF([test "${enable_osx_notifications}" != "no"], [
4110   if test -d ${CONTRIB_DIR}/Growl.framework -o -d ${CONTRIB_DIR}/Frameworks/Growl.framework
4111   then
4112       VLC_ADD_PLUGIN([osx_notifications])
4113       VLC_ADD_LIBS([osx_notifications], [-Wl,-framework,Growl,-framework,Foundation])
4114       VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4115   fi
4116 ])
4117
4118 dnl
4119 dnl Libnotify notification plugin
4120 dnl
4121 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4122
4123 dnl
4124 dnl  Endianness check
4125 dnl
4126 AC_C_BIGENDIAN
4127 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4128   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4129 ], [
4130   DEFS_BIGENDIAN=""
4131 ])
4132 AC_SUBST(DEFS_BIGENDIAN)
4133
4134 dnl
4135 dnl Where to install KDE solid .desktop
4136 dnl
4137 AC_ARG_WITH(kde-solid,
4138   AS_HELP_STRING([--with-kde-solid=PATH],
4139                  [KDE Solid actions directory (auto)]),, [
4140
4141 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4142   with_kde_solid="yes"
4143 fi
4144 ])
4145 soliddatadir=""
4146 AS_IF([test "${with_kde_solid}" != "no"], [
4147   AS_IF([test "${with_kde_solid}" = "yes"], [
4148     kde4datadir="`${KDE4_CONFIG} --install data`"
4149     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4150     soliddatadir="${kde4datadir}/solid/actions"
4151   ], [
4152     soliddatadir="${with_kde_solid}"
4153   ])
4154 ])
4155 AC_SUBST(soliddatadir)
4156 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4157
4158 dnl
4159 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4160 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4161 dnl
4162 if test "${SYS}" = "mingw32"; then
4163     AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4164 fi
4165
4166 EXTEND_HELP_STRING([Components:])
4167
4168 dnl
4169 dnl  the VLC binary
4170 dnl
4171 AC_ARG_ENABLE(vlc,
4172   [  --enable-vlc            build the VLC media player (default enabled)])
4173 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4174
4175 dnl
4176 dnl  Stuff used by the program
4177 dnl
4178 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4179 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4180 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4181 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4182 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4183 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4184 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4185 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4186 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4187 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4188 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4189 AC_SUBST(COPYRIGHT_MESSAGE)
4190 AC_SUBST(VERSION_MESSAGE)
4191 AC_SUBST(VERSION_MAJOR)
4192 AC_SUBST(VERSION_MINOR)
4193 AC_SUBST(VERSION_REVISION)
4194 AC_SUBST(VERSION_EXTRA)
4195 AC_SUBST(COPYRIGHT_YEARS)
4196 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4197 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4198 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4199 dnl
4200 dnl  Handle substvars that use $(top_srcdir)
4201 dnl
4202 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4203
4204 dnl
4205 dnl  Configuration is finished
4206 dnl
4207 AC_SUBST(SYS)
4208 AC_SUBST(ARCH)
4209 AC_SUBST(ALIASES)
4210 AC_SUBST(ASM)
4211 AC_SUBST(MOC)
4212 AC_SUBST(RCC)
4213 AC_SUBST(UIC)
4214 AC_SUBST(WINDRES)
4215 AC_SUBST(WINE_SDK_PATH)
4216 AC_SUBST(LIBEXT)
4217 AC_SUBST(AM_CPPFLAGS)
4218 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4219 AC_SUBST(FILE_LIBVLCCORE_DLL)
4220 AC_SUBST(FILE_LIBVLC_DLL)
4221
4222 AC_CONFIG_FILES([
4223   Makefile
4224   doc/Makefile
4225   modules/Makefile
4226   m4/Makefile
4227   po/Makefile.in
4228   share/Makefile
4229   compat/Makefile
4230   src/Makefile
4231   lib/Makefile
4232   bin/Makefile
4233   test/Makefile
4234   modules/gui/macosx/Makefile
4235   modules/hw/mmal/Makefile
4236   share/vlc.appdata.xml.in
4237 ])
4238
4239 AM_COND_IF([HAVE_WIN32], [
4240   AC_CONFIG_FILES([
4241     extras/package/win32/NSIS/spad.nsi
4242     extras/package/win32/NSIS/vlc.win32.nsi
4243     extras/package/win32/msi/config.wxi
4244   ])
4245 ])
4246
4247 AM_COND_IF([HAVE_DARWIN], [
4248   AC_CONFIG_FILES([
4249     modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4250     share/macosx/Info.plist:share/Info.plist.in
4251   ])
4252 ])
4253
4254 dnl Generate makefiles
4255 AC_OUTPUT
4256
4257 dnl Do we have to use make or gmake ?
4258 if make --version 2>&1|grep -q GNU
4259 then
4260     # GNU make, all seems good
4261     MAKE=make
4262 else
4263     # Known GNU make alias (on BSD)
4264     MAKE=gmake
4265 fi
4266 dnl Shortcut to nice compile message
4267 if test -n $SHELL; then
4268   SHELL=${CONFIG_SHELL-/bin/sh}
4269 fi
4270 rm -f compile
4271 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4272 echo "#! $SHELL
4273 rm -f .error\$\$
4274 ERROR=0
4275 export PATH=\"$PATH\" LANG=C
4276 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4277 test -f .error\$\$ && ERROR=1
4278 rm -f .error\$\$
4279 exit \$ERROR" >compile
4280 chmod a+x compile
4281
4282 echo "
4283 libvlc configuration
4284 --------------------
4285 version               : ${VERSION}
4286 system                : ${SYS}
4287 architecture          : ${ARCH}
4288 optimizations         : ${enable_optimizations}"
4289 if test "${enable_vlc}" != "no"; then
4290 echo "vlc aliases           :${ALIASES}"
4291 else
4292 echo "build vlc executable  : no"
4293 fi
4294 echo "
4295 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."