configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 1999-2016 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 3.0.0-git)
   6 VERSION_MAJOR=3
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=git
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Vetinari"
  17 COPYRIGHT_YEARS="1996-2016"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 AM_SILENT_RULES([yes])
  31 AM_MAINTAINER_MODE([enable])
  32
  33 dnl
  34 dnl Directories
  35 dnl
  36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  37 dnl AC_SUBST(vlcincludedir)
  38 vlcdatadir="\${datadir}/\${PKGDIR}"
  39 AC_SUBST(vlcdatadir)
  40 vlclibdir="\${libdir}/\${PKGDIR}"
  41 AC_SUBST(vlclibdir)
  42
  43 dnl
  44 dnl Check for tools
  45 dnl
  46 AC_PROG_CC_C99
  47 AC_USE_SYSTEM_EXTENSIONS
  48 VLC_PROG_CC_C11
  49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  51 AH_TOP([
  52 #ifndef _REENTRANT
  53 # define _REENTRANT
  54 #endif
  55 ])
  56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  59
  60 AM_PROG_CC_C_O
  61 AC_PROG_CXX
  62 AC_PROG_CPP
  63 AC_PROG_OBJC
  64 _AM_DEPENDENCIES([OBJC])
  65 AC_PROG_EGREP
  66 AC_PROG_MAKE_SET
  67 AC_PROG_INSTALL
  68 AM_PROG_AS
  69
  70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
  73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
  74 AS_IF([test "$BUILDCC" = "false"], [
  75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
  76 ])
  77
  78 dnl Check for compiler properties
  79 AC_C_CONST
  80 AC_C_INLINE
  81 AC_C_RESTRICT
  82 AX_CXX_COMPILE_STDCXX_11(noext, optional)
  83
  84 dnl Extend the --help string at the current spot.
  85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  86
  87 dnl Allow binary package maintainer to pass a custom string to avoid
  88 dnl cache problem
  89 AC_ARG_WITH(binary-version,
  90     AS_HELP_STRING([--with-binary-version=STRING],
  91          [To avoid plugins cache problem between binary version]),[],[])
  92 AS_IF([test -n "${with_binary_version}"],[
  93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  94          [Binary specific version])
  95 ])
  96
  97 dnl
  98 dnl  Check the operating system
  99 dnl
 100 HAVE_WIN64="0"
 101 HAVE_IOS="0"
 102 HAVE_OSX="0"
 103 HAVE_TVOS="0"
 104
 105 case "${host_os}" in
 106   "")
 107     SYS=unknown
 108     ;;
 109   linux*)
 110     SYS=linux
 111     ;;
 112   bsdi*)
 113     SYS=bsdi
 114     CFLAGS="${CFLAGS} -pthread"
 115     ;;
 116   freebsd*)
 117     SYS=freebsd
 118     CFLAGS="${CFLAGS} -pthread"
 119     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 120     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 121     ;;
 122   openbsd*)
 123     SYS=openbsd
 124     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 125     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 126     ;;
 127   netbsd*)
 128     SYS=netbsd
 129     ;;
 130   dragonfly*)
 131     SYS=dragonfly
 132     ;;
 133   darwin*)
 134
 135     dnl Force gcc "-arch" flag
 136     ARCH_flag=""
 137     case "${host}" in
 138       i?86*)
 139         ARCH_flag="-arch i386"
 140       ;;
 141       ppc64*)
 142         ARCH_flag="-arch ppc64"
 143       ;;
 144       ppc*)
 145         ARCH_flag="-arch ppc"
 146       ;;
 147       x86_64*)
 148         ARCH_flag="-arch x86_64"
 149       ;;
 150       arm*)
 151         ac_cv_c_bigendian="no"
 152         ac_cv_c_attribute_packed="no"
 153       ;;
 154     esac
 155
 156     SYS=darwin
 157     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 158     CXX="${CXX} -stdlib=libc++ -std=c++11"
 159     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 160     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 161     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 162     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 163     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 164     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 165
 166     AC_EGREP_CPP(yes,
 167             [#import <TargetConditionals.h>
 168              #if TARGET_OS_IPHONE
 169              yes
 170              #endif],
 171              [HAVE_IOS="1"],
 172              [HAVE_OSX="1"])
 173
 174     AC_EGREP_CPP(yes,
 175             [#import <TargetConditionals.h>
 176              #if TARGET_OS_TV
 177              yes
 178              #endif],
 179              [HAVE_TVOS="1"
 180              HAVE_IOS="0"
 181              HAVE_OSX="0"
 182              ],)
 183
 184     dnl Allow binaries created on Lion to run on earlier releases
 185     AC_EGREP_CPP(yes,
 186            [#import <Cocoa/Cocoa.h>
 187             #ifdef MAC_OS_X_VERSION_10_7
 188             yes
 189             #endif],
 190             [AC_MSG_RESULT([yes])
 191             AC_LIBOBJ([getdelim])
 192             AC_LIBOBJ([strndup])
 193             AC_LIBOBJ([strnlen])],)
 194
 195     dnl
 196     dnl  Handle Mac OS X SDK flags
 197     dnl
 198     AC_ARG_WITH(macosx-sdk,
 199       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 200         [compile using the SDK in DIR])])
 201     if test "${with_macosx_sdk}" != "" ; then
 202         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 203         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 204         CC="${CC} -isysroot ${with_macosx_sdk}"
 205         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 206         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 207         LD="${LD} -syslibroot ${with_macosx_sdk}"
 208     fi
 209     AC_ARG_WITH(macosx-version-min,
 210       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 211         [compile for Mac OS X VERSION and above])])
 212     if test "${with_macosx_version_min}" != "" ; then
 213         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 214         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 215         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 216         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 217         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 218     fi
 219     ;;
 220   *mingw32* | *cygwin* | *wince* | *mingwce*)
 221     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
 222     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
 223     CXXFLAGS="${CXXFLAGS} -static-libgcc"
 224     AC_CHECK_TOOL(WINDRES, windres, :)
 225     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 226     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
 227     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
 228     AH_TOP([#endif])
 229     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 230     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 231     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 232     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 233     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 234     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 235     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 236     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 237     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 238     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 239     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 240
 241     case "${host_os}" in
 242       *mingw32*)
 243         SYS=mingw32
 244         ;;
 245       *cygwin*)
 246         dnl Check if we are using the mno-cygwin mode in which case we are
 247         dnl actually dealing with a mingw32 compiler.
 248         AC_EGREP_CPP(yes,
 249             [#ifdef _WIN32
 250              yes
 251              #endif],
 252             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 253         ;;
 254     esac
 255
 256     if test "${SYS}" = "mingw32"; then
 257         # DEP, ASLR, NO SEH
 258         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 259
 260         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 261         ac_default_prefix="`pwd`/_win32"
 262         DESTDIR="`pwd`/_win32/"
 263
 264         dnl
 265         dnl NSIS/MSI Installer prefix and WIN64
 266         dnl
 267         case "${host}" in
 268             amd64*|x86_64*)
 269                 HAVE_WIN64="1"
 270                 WINDOWS_ARCH="x64"
 271                 PROGRAMFILES="PROGRAMFILES64"
 272                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
 273             ;;
 274             *)
 275                 WINDOWS_ARCH="x86"
 276                 PROGRAMFILES="PROGRAMFILES"
 277             ;;
 278         esac
 279         AC_SUBST(WINDOWS_ARCH)
 280         AC_SUBST(PROGRAMFILES)
 281
 282     fi
 283     ;;
 284   *nto*)
 285     SYS=nto
 286     ;;
 287   solaris*)
 288     SYS=solaris
 289     ;;
 290   hpux*)
 291     SYS=hpux
 292     ;;
 293   *os2*)
 294     SYS=os2
 295     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 296     AC_LIBOBJ([freeaddrinfo])
 297     AC_LIBOBJ([gai_strerror])
 298     ;;
 299   *)
 300     SYS="${host_os}"
 301     ;;
 302 esac
 303
 304 dnl WinRT
 305 AC_ARG_ENABLE(winstore_app,
 306      AS_HELP_STRING([--enable-winstore-app],
 307                     [Build targetted for Windows Store apps (default disabled)]))
 308
 309 vlc_winstore_app=0
 310 AS_IF([test "${SYS}" = "mingw32"],[
 311   AS_IF([test "${enable_winstore_app}" = "yes"], [
 312     vlc_winstore_app=1
 313      VLC_ADD_LIBS([libvlccore], [-lole32 -lruntimeobject])
 314      AC_LIBOBJ([gai_strerror])
 315     ],[
 316      VLC_ADD_LIBS([libvlccore],[-lwinmm])
 317     ])
 318   ])
 319 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 320
 321 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 322 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 323
 324 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 325 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
 326 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
 327 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
 328
 329 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 330 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
 331 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 332 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
 333
 334 dnl
 335 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 336 dnl for program foo on win32
 337 case "${build_os}" in
 338     cygwin|msys)
 339         ac_executable_extensions=".exe"
 340     ;;
 341     os2*)
 342         BUILDEXEEXT=".exe"
 343     ;;
 344     *)
 345     ;;
 346 esac
 347 AC_SUBST(BUILDEXEEXT)
 348
 349 dnl Android is linux, but a bit different
 350 AS_IF([test "$SYS" = linux],[
 351     AC_MSG_CHECKING([for an Android system])
 352     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 353         [[#ifndef __ANDROID__
 354          # error Not Android
 355          #endif
 356         ]],[[;]])
 357     ],[
 358       HAVE_ANDROID="1"
 359       AC_MSG_RESULT([yes])
 360     ],[
 361       AC_MSG_RESULT([no])
 362     ])
 363 ])
 364 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 365
 366 dnl Tizen (minimum SDK version: 2.3)
 367 AS_IF([test "$SYS" = linux],[
 368     AC_MSG_CHECKING([for Tizen])
 369     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 370         [[#include <tizen.h>
 371         ]],[[;]])
 372     ],[
 373       HAVE_TIZEN="1"
 374       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
 375       AC_MSG_RESULT([yes])
 376     ],[
 377       AC_MSG_RESULT([no])
 378     ])
 379 ])
 380 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
 381
 382 dnl
 383 dnl  Check for the contrib directory
 384 dnl
 385 AC_ARG_WITH(contrib,
 386   [AS_HELP_STRING([--with-contrib[=DIR]],
 387     [search for 3rd party libraries in DIR/include and DIR/lib])
 388 ])
 389 AC_MSG_CHECKING([for 3rd party libraries path])
 390 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 391   CONTRIB_DIR="${srcdir}/contrib/${host}"
 392   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 393     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 394     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 395     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 396       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 397       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
 398       AS_IF([test ! -d "${CONTRIB_DIR}"], [
 399         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 400         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
 401         AS_IF([test ! -d "${CONTRIB_DIR}"], [
 402           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 403           CONTRIB_DIR=""
 404           AC_MSG_RESULT([not found])
 405         ])
 406       ])
 407     ])
 408   ])
 409 ], [
 410   AS_IF([test "${with_contrib}" != "no"], [
 411     CONTRIB_DIR="${with_contrib}"
 412   ], [
 413     CONTRIB_DIR=""
 414     AC_MSG_RESULT([disabled])
 415   ])
 416 ])
 417 AS_IF([test -n "${CONTRIB_DIR}"], [
 418   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 419     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 420   ], [
 421     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 422     CONTRIB_DIR=""
 423     AC_MSG_RESULT([not usable])
 424   ])
 425
 426 ])
 427 AS_IF([test -n "${CONTRIB_DIR}"], [
 428   AC_MSG_RESULT([${CONTRIB_DIR}])
 429   export PATH=${CONTRIB_DIR}/bin:$PATH
 430   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 431   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 432   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 433   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
 434   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 435   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 436
 437   AS_IF([test "${SYS}" = "darwin"], [
 438     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 439     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 440   ])
 441 ], [
 442   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 443     AC_MSG_ERROR([Third party libraries not found!])
 444   ])
 445 ])
 446 AC_SUBST(CONTRIB_DIR)
 447
 448 dnl Add extras/tools to the PATH
 449 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 450 AS_IF([test -d "${TOOLS_DIR}"], [
 451     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 452     export PATH="${TOOLS_DIR}":$PATH
 453 ])
 454
 455 dnl
 456 dnl  Libtool
 457 dnl  It's very bad, but our former custom system was worst
 458 dnl  -- Courmisch
 459 dnl
 460
 461 dnl override platform specific check for dependent libraries
 462 dnl otherwise libtool linking of shared libraries will
 463 dnl fail on anything other than pass_all.
 464 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 465     [lt_cv_deplibs_check_method=pass_all])
 466
 467 LT_INIT([dlopen win32-dll shared disable-static])
 468 LT_LANG([C++])
 469 LT_LANG([Windows Resource])
 470
 471 DOLT
 472
 473 lt_cv_deplibs_check_method=pass_all
 474
 475 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 476   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 477 ])
 478
 479 dnl
 480 dnl Gettext stuff
 481 dnl
 482 AM_GNU_GETTEXT_VERSION([0.19.6])
 483 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 484
 485 dnl
 486 dnl Iconv stuff
 487 dnl
 488 AM_ICONV
 489
 490 dnl
 491 dnl checks for mingw
 492 AS_IF([test "${SYS}" = "mingw32"], [
 493
 494 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 495 #if !defined(__MINGW32__)
 496 # error Not compiling with mingw
 497 #endif
 498     ])], [
 499
 500 dnl Check for broken versions of mingw-runtime compatability library
 501     AC_MSG_CHECKING(for broken mingw-runtime)
 502     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 503 #include <_mingw.h>
 504 #if defined(__MINGW64_VERSION_MAJOR)
 505 # if __MINGW64_VERSION_MAJOR < 3
 506 #  error Attempting to use mingw-runtime with broken vsnprintf and direct2d support
 507 # endif
 508 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
 509 # error Attempting to use mingw-runtime with broken vsnprintf support
 510 #endif
 511     ])], [
 512         AC_MSG_RESULT([ok])
 513     ], [
 514         AC_MSG_RESULT([present])
 515         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
 516     ])
 517
 518     dnl force use of mingw provided c99 *printf over msvcrt
 519     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 520
 521     dnl Add WinMainCRTStartup entry point to show it's a WinMain application
 522     VLC_ADD_LDFLAGS([vlc],[-mwindows])
 523
 524     dnl Check for the need to include the mingwex lib for mingw32
 525     VLC_SAVE_FLAGS
 526     AC_CHECK_LIB(mingwex,opendir,
 527         AC_CHECK_LIB(mingw32,opendir,,
 528             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 529     )
 530     VLC_RESTORE_FLAGS
 531     ], [
 532         AC_MSG_RESULT([Not compiling with mingw])
 533     ])
 534
 535     dnl Check for fnative-struct or mms-bitfields support for mingw32
 536     VLC_SAVE_FLAGS
 537     CFLAGS="${CFLAGS} -mms-bitfields"
 538     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
 539     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 540         [ac_cv_c_mms_bitfields],
 541         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 542     if test "${ac_cv_c_mms_bitfields}" = "no"; then
 543         VLC_RESTORE_FLAGS
 544         CFLAGS="${CFLAGS} -fnative-struct"
 545         CXXFLAGS="${CXXFLAGS} -fnative-struct"
 546         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 547             [ac_cv_c_fnative_struct],
 548             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 549         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
 550     fi
 551 ])
 552
 553
 554 dnl
 555 dnl Buggy glibc prevention. Purposedly not cached.
 556 dnl See sourceware.org bugs 5058 and 5443.
 557 dnl Ubuntu alone has 20 bug numbers for this...
 558 dnl
 559 AC_MSG_CHECKING(for buggy GNU/libc versions)
 560 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 561 #include <limits.h>
 562 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 563   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 564 # error GNU/libc with dcgettext killer bug!
 565 #endif
 566 ])], [
 567   AC_MSG_RESULT([not present])
 568 ], [
 569   AC_MSG_RESULT([found])
 570   AS_IF([test "x${enable_nls}" != "xno"], [
 571     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 572 work-around for this. Check with your distribution vendor on how to update the
 573 glibc run-time. Alternatively, build with --disable-nls.])
 574   ])
 575 ])
 576
 577 dnl Plugin compilation stuff
 578
 579 VLC_LIBRARY_SUFFIX
 580
 581 dnl Check for system libs needed
 582 need_libc=false
 583
 584 dnl Check for usual libc functions
 585 AC_CHECK_DECLS([nanosleep],,,[#include <time.h>])
 586 AC_CHECK_FUNCS([daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime uselocale pthread_cond_timedwait_monotonic_np pthread_condattr_setclock])
 587 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv nrand48 poll posix_memalign recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tdestroy timegm timespec_get strverscmp])
 588 AC_REPLACE_FUNCS([gettimeofday])
 589 AC_CHECK_FUNCS(fdatasync,,
 590   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 591 ])
 592
 593 dnl mingw64 implements those as static inline, not functions with C linkage
 594 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
 595 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
 596 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
 597 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
 598
 599 dnl C11 static_assert()
 600 AC_MSG_CHECKING([for static_assert in assert.h])
 601 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 602 static_assert(1, "The impossible happened.");
 603 ])], [
 604   AC_MSG_RESULT([yes])
 605   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 606 ], [
 607   AC_MSG_RESULT([no])
 608 ])
 609
 610 # Windows CE does not have strcoll()
 611 AC_FUNC_STRCOLL
 612
 613 dnl Check for non-standard system calls
 614 case "$SYS" in
 615   "linux")
 616     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity])
 617     ;;
 618   "mingw32")
 619     AC_CHECK_FUNCS([_lock_file])
 620     ;;
 621 esac
 622
 623 AH_BOTTOM([#include <vlc_fixups.h>])
 624
 625 dnl Check for struct pollfd
 626 AC_CHECK_TYPES([struct pollfd],,,
 627 [#include <sys/types.h>
 628 #if HAVE_POLL
 629 # include <poll.h>
 630 #elif defined (_WIN32)
 631 # include <winsock2.h>
 632 #endif
 633 ])
 634
 635 dnl Check for struct timespec
 636 AC_CHECK_TYPES([struct timespec],,,
 637 [#include <time.h>])
 638
 639 dnl Checks for socket stuff
 640 VLC_SAVE_FLAGS
 641 SOCKET_LIBS=""
 642 AC_SEARCH_LIBS(connect, [socket], [
 643   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 644     SOCKET_LIBS="$ac_cv_search_connect"
 645   ])
 646 ], [
 647   AS_IF([test "${SYS}" = "mingw32"], [
 648     SOCKET_LIBS="-lws2_32"
 649   ])
 650 ])
 651
 652 AC_SEARCH_LIBS([inet_pton], [nsl], [
 653  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
 654     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
 655   ])
 656 ],, [${SOCKET_LIBS}])
 657
 658 LIBS="${LIBS} ${SOCKET_LIBS}"
 659 AC_LINK_IFELSE([
 660     AC_LANG_PROGRAM([#ifdef _WIN32
 661         # if _WIN32_WINNT < 0x600
 662         #  error Needs vista+
 663         # endif
 664         #include <ws2tcpip.h>
 665         #else
 666         #include <sys/socket.h>
 667         #include <arpa/inet.h>
 668         #endif], [
 669         char dst[[sizeof(struct in_addr)]];
 670         inet_pton(AF_INET, "127.0.0.1", dst);
 671     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 672 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
 673 VLC_RESTORE_FLAGS
 674 AC_SUBST(SOCKET_LIBS)
 675
 676 dnl Check for socklen_t
 677 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 678 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 679 ac_cv_type_socklen_t,
 680 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 681 [#include <sys/types.h>
 682 #ifdef _WIN32
 683 # include <winsock2.h>
 684 # include <ws2tcpip.h>
 685 #else
 686 # include <sys/socket.h>
 687 #endif]], [[socklen_t len; len = 0;]])],
 688 ac_cv_type_socklen_t=yes,
 689 ac_cv_type_socklen_t=no)])
 690 AS_IF([test "$ac_cv_type_socklen_t" = no],
 691  [AC_DEFINE(socklen_t, int)])
 692
 693 dnl Check for struct sockaddr_storage
 694 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 695 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 696 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 697   [AC_TRY_COMPILE(
 698     [#include <sys/types.h>
 699      #if defined( _WIN32 )
 700      # include <winsock2.h>
 701      #else
 702      # include <sys/socket.h>
 703      #endif], [struct sockaddr_storage addr;],
 704      ac_cv_struct_sockaddr_storage=yes,
 705      ac_cv_struct_sockaddr_storage=no)])
 706 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 707   AC_DEFINE(sockaddr_storage, sockaddr)
 708   AC_DEFINE(ss_family, sa_family)
 709 ])
 710
 711 dnl FreeBSD has a gnugetopt library for this:
 712 GNUGETOPT_LIBS=""
 713 AC_CHECK_FUNC(getopt_long,, [
 714   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 715     GNUGETOPT_LIBS="-lgnugetopt"
 716   ])
 717 ])
 718 AC_SUBST(GNUGETOPT_LIBS)
 719
 720 AC_CHECK_LIB(m,cos,[
 721   LIBM="-lm"
 722 ], [
 723   LIBM=""
 724 ])
 725 AC_SUBST(LIBM)
 726
 727 AC_CHECK_LIB(m,lrintf, [
 728   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 729   VLC_ADD_LIBS([skins2],[-lm])
 730 ])
 731 AC_CHECK_LIB(m,nanf,
 732   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 733 )
 734
 735 dnl Check for dynamic plugins
 736 LIBDL=""
 737 have_dynamic_objects="no"
 738 VLC_SAVE_FLAGS
 739 AC_SEARCH_LIBS(dlsym, [dl svld], [
 740   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 741     LIBDL="$ac_cv_search_dlsym"
 742   ])
 743   have_dynamic_objects="yes"
 744 ])
 745 VLC_RESTORE_FLAGS
 746
 747 # Windows
 748 AS_IF([test "${SYS}" = "mingw32"], [
 749   LIBDL=""
 750   have_dynamic_objects="yes" #assume we can use shared objects
 751 ])
 752
 753 AS_IF([test "${enable_shared}" = "no"], [
 754   have_dynamic_objects=no
 755 ])
 756 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 757
 758 AC_SUBST(LIBDL)
 759
 760 dnl Check for thread library
 761 LIBPTHREAD=""
 762 AS_IF([test "${SYS}" != "mingw32"], [
 763   VLC_SAVE_FLAGS
 764   LIBS=""
 765   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 766     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 767       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 768     ])
 769   ])
 770   VLC_RESTORE_FLAGS
 771 ])
 772 AC_SUBST(LIBPTHREAD)
 773
 774 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
 775   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
 776     LIBRT="$ac_cv_search_clock_nanosleep"
 777   ])
 778 ], [
 779   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
 780     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
 781       LIBRT="$ac_cv_search_nanosleep"
 782     ])
 783   ])
 784 ])
 785 AC_SUBST(LIBRT)
 786
 787 dnl
 788 dnl Check for headers
 789 dnl
 790
 791 dnl  POSIX
 792 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
 793 AC_CHECK_HEADERS([net/if.h], [], [],
 794 [
 795 #include <sys/types.h>
 796 #include <sys/socket.h>
 797 ])
 798 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
 799 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
 800
 801 dnl  BSD
 802 AC_CHECK_HEADERS([netinet/udplite.h sys/param.h sys/mount.h])
 803
 804 dnl  GNU/Linux
 805 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 806
 807 dnl  MacOS
 808 AC_CHECK_HEADERS([xlocale.h])
 809
 810 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 811 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 812 AC_CHECK_TYPE(ssize_t,, [
 813   AC_DEFINE(ssize_t, int)
 814 ])
 815
 816 dnl It seems that autoconf detects pkg-config only during the first
 817 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 818 dnl it is nested within a conditional block, so it was not working right.
 819 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 820 AC_ARG_VAR(PKG_CONFIG_PATH,
 821        [Paths where to find .pc not at the default location])
 822 PKG_PROG_PKG_CONFIG()
 823
 824 dnl On some OS we need static linking
 825 AS_IF([test -n "${PKG_CONFIG}" ],[
 826     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 827         PKG_CONFIG="${PKG_CONFIG} --static"
 828     ])
 829 ])
 830
 831
 832 dnl
 833 dnl Check for zlib.h and -lz along with system -lminizip if available
 834 dnl
 835 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 836 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 837 if test "${have_zlib}" = "yes"
 838 then
 839   VLC_ADD_LIBS([skins2 sap unzip zip],[-lz])
 840   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 841     AC_CHECK_HEADERS([unzip.h], [
 842       have_minizip=yes
 843       MINIZIP_LIBS="-lminizip -lz"
 844     ], [
 845       VLC_ADD_CPPFLAGS([skins2], [-I\\\$(top_srcdir)/modules/access/zip/unzip])
 846       VLC_ADD_LIBS([skins2], [\\\$(top_builddir)/modules/libunzip.la])
 847       have_minizip=no
 848     ])
 849   ])
 850   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
 851   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
 852 fi
 853 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 854
 855
 856 dnl
 857 dnl Domain name i18n support via GNU libidn
 858 dnl
 859 PKG_CHECK_MODULES([IDN], [libidn], [
 860   have_libidn="yes"
 861   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 862 ], [
 863   have_libidn="no"
 864 ])
 865
 866
 867 dnl Check for dbus
 868 AC_ARG_ENABLE(dbus,
 869   [AS_HELP_STRING([--enable-dbus],
 870     [compile D-Bus message bus support (default enabled)])])
 871 have_dbus="no"
 872 AS_IF([test "${enable_dbus}" != "no"], [
 873   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 874     have_dbus="yes"
 875   ], [
 876     AS_IF([test -n "${enable_dbus}"], [
 877       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 878     ], [
 879       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 880     ])
 881   ])
 882 ])
 883 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 884
 885
 886 dnl Check for systemd
 887 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
 888   have_systemd="yes"
 889 ], [
 890   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
 891 ])
 892 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
 893
 894
 895 dnl Check for ntohl, etc.
 896 VLC_SAVE_FLAGS
 897 CFLAGS="${CFLAGS} -Wall -Werror"
 898 AC_CACHE_CHECK([for ntohl in sys/param.h],
 899     [ac_cv_c_ntohl_sys_param_h],
 900     [     AC_TRY_COMPILE([#include <sys/param.h>],
 901         [int meuh; ntohl(meuh);],
 902         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
 903 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
 904     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
 905 fi
 906 VLC_RESTORE_FLAGS
 907
 908 EXTEND_HELP_STRING([Optimization options:])
 909 dnl
 910 dnl  Compiler warnings
 911 dnl
 912
 913 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration init-self logical-op format-security])
 914 RDC_PROG_CC_FLAGS([-pipe])
 915 AC_LANG_PUSH([C++])
 916 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var format-security])
 917 AC_LANG_POP([C++])
 918
 919 dnl
 920 dnl  Debugging mode
 921 dnl
 922 AC_ARG_ENABLE(debug,
 923   [AS_HELP_STRING([--enable-debug],
 924     [build with run-time assertions (default disabled)])],,
 925   [enable_debug="no"])
 926 AH_TEMPLATE(NDEBUG,
 927             [Define to 1 if debug code should NOT be compiled])
 928 AS_IF([test "${enable_debug}" != "no"], [
 929   AC_CHECK_HEADERS([valgrind/valgrind.h])
 930 ], [
 931   AC_DEFINE(NDEBUG)
 932 ])
 933
 934 dnl
 935 dnl  Profiling
 936 dnl
 937 AC_ARG_ENABLE(gprof,
 938   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 939   [enable_gprof="no"])
 940 AS_IF([test "${enable_gprof}" != "no"], [
 941   CFLAGS="${CFLAGS} -pg"
 942   CXXFLAGS="${CXXFLAGS} -pg"
 943   OBJCFLAGS="${OBJCFLAGS} -pg"
 944   LDFLAGS="${LDFLAGS} -pg"
 945 ])
 946
 947 AC_ARG_ENABLE(cprof,
 948   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 949   [enable_cprof="no"])
 950 AS_IF([test "${enable_gprof}" != "no"], [
 951   CFLAGS="${CFLAGS} -finstrument-functions"
 952   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 953   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 954   LDFLAGS="${LDFLAGS} -finstrument-functions"
 955 ])
 956
 957 dnl
 958 dnl  Test coverage
 959 dnl
 960 AC_ARG_ENABLE(coverage,
 961   [AS_HELP_STRING([--enable-coverage],
 962     [build for test coverage (default disabled)])],,
 963   [enable_coverage="no"])
 964 AS_IF([test "${enable_coverage}" != "no"], [
 965   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 966   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 967   LDFLAGS="-lgcov ${LDFLAGS}"
 968 ])
 969
 970 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
 971   VLC_SAVE_FLAGS
 972   CFLAGS="${CFLAGS} -fvisibility=hidden"
 973   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
 974   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
 975   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
 976                  [ac_cv_c_visibility_hidden], [
 977     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 978       ac_cv_c_visibility_hidden=yes
 979     ], [
 980       ac_cv_c_visibility_hidden=no
 981     ])
 982   ])
 983   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
 984 ])
 985
 986
 987 dnl
 988 dnl  Enable/disable optimizations
 989 dnl
 990 AC_ARG_ENABLE(optimizations,
 991   [AS_HELP_STRING([--disable-optimizations],
 992     [disable compiler optimizations (default enabled)])],,
 993   [enable_optimizations="yes"])
 994
 995 dnl Check for various optimization flags
 996 AS_IF([test "${enable_optimizations}" != "no"], [
 997
 998   dnl -O3 only in production builds
 999   AS_IF([test "${enable_debug}" = "no"], [
1000     VLC_SAVE_FLAGS
1001     CFLAGS="${CFLAGS} -O3"
1002     CXXFLAGS="${CXXFLAGS} -O3"
1003     OBJCFLAGS="${OBJCFLAGS} -O3"
1004     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1005       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1006         ac_cv_c_o3=yes
1007       ], [
1008         ac_cv_c_o3=no
1009       ])
1010     ])
1011     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1012   ])
1013
1014   dnl Check for fast maths
1015   RDC_PROG_CC_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1016   AC_LANG_PUSH(C++)
1017   RDC_PROG_CXX_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1018   AC_LANG_POP
1019
1020 AH_BOTTOM([
1021 #if defined(_MSC_VER)
1022 # pragma fenv_access(off)
1023 # pragma fp_contract(on)
1024 #elif defined(__GNUC__)
1025 /* Not supported so far */
1026 #else
1027 # pragma STDC FENV_ACCESS OFF
1028 # pragma STDC FP_CONTRACT ON
1029 #endif
1030 ])
1031
1032   dnl Check for -funroll-loops
1033   VLC_SAVE_FLAGS
1034   CFLAGS="${CFLAGS} -funroll-loops"
1035   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1036   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1037   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1038     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1039       ac_cv_c_unroll_loops=yes
1040     ], [
1041       ac_cv_c_unroll_loops=no
1042     ])
1043   ])
1044   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1045
1046   AS_IF([test "$enable_debug" = "no"], [
1047     dnl Check for -fomit-frame-pointer
1048     VLC_SAVE_FLAGS
1049     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1050     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1051     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1052     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1053       [ac_cv_c_omit_frame_pointer], [
1054       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1055         ac_cv_c_omit_frame_pointer=yes
1056       ], [
1057         ac_cv_c_omit_frame_pointer=no
1058       ])
1059     ])
1060     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1061   ])
1062 ])
1063
1064 VLC_SAVE_FLAGS
1065 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1066 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1067   AC_TRY_LINK([],, [
1068     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1069   ], [
1070     ac_cv_ld_bsymbolic=""
1071   ])
1072 ])
1073 VLC_RESTORE_FLAGS
1074 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1075 AC_SUBST(SYMBOLIC_LDFLAGS)
1076
1077 dnl Checks for __attribute__(aligned()) directive
1078 VLC_SAVE_FLAGS
1079 CFLAGS="${CFLAGS} -Werror"
1080 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1081     [ac_cv_c_attribute_aligned],
1082     [ac_cv_c_attribute_aligned=0
1083     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1084         AC_TRY_COMPILE([],
1085         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1086         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1087     done])
1088 VLC_RESTORE_FLAGS
1089 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1090     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1091         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1092 fi
1093
1094 dnl Check for __attribute__((packed))
1095 AC_CACHE_CHECK([for __attribute__((packed))],
1096   [ac_cv_c_attribute_packed],
1097   [ac_cv_c_attribute_packed=no
1098    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1099                     [ac_cv_c_attribute_packed=yes])])
1100 if test "${ac_cv_c_attribute_packed}" != "no"; then
1101   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1102 fi
1103
1104 dnl
1105 dnl  Check the CPU
1106 dnl
1107 case "${host_cpu}" in
1108   "")
1109     ARCH=unknown
1110     ;;
1111   *)
1112     ARCH="${host_cpu}"
1113     ;;
1114 esac
1115
1116 dnl Check for backtrace() support
1117 AC_CHECK_HEADERS(execinfo.h)
1118 AC_CHECK_FUNCS(backtrace)
1119
1120 dnl
1121 dnl  default modules
1122 dnl
1123 ALIASES="${ALIASES} cvlc rvlc"
1124
1125 dnl
1126 dnl  Accelerated modules
1127 dnl
1128
1129 dnl  Check for fully working MMX intrinsics
1130 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1131 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1132 AC_ARG_ENABLE(mmx,
1133   [AS_HELP_STRING([--disable-mmx],
1134     [disable MMX optimizations (default auto)])],,[
1135   case "${host_cpu}" in
1136     i?86|x86_64)
1137       enable_mmx="yes"
1138       ;;
1139     *)
1140       enable_mmx="no"
1141       ;;
1142   esac
1143 ])
1144 have_mmx="no"
1145 have_mmxext="no"
1146 AS_IF([test "${enable_mmx}" != "no"], [
1147   ARCH="${ARCH} mmx"
1148   VLC_SAVE_FLAGS
1149   CFLAGS="${CFLAGS} -mmmx"
1150   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1151     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1152 [#include <mmintrin.h>
1153 #include <stdint.h>
1154 uint64_t frobzor;]], [
1155 [__m64 a, b, c;
1156 a = b = c = (__m64)frobzor;
1157 a = _mm_slli_pi16(a, 3);
1158 a = _mm_adds_pi16(a, b);
1159 c = _mm_srli_pi16(c, 8);
1160 c = _mm_slli_pi16(c, 3);
1161 b = _mm_adds_pi16(b, c);
1162 a = _mm_unpacklo_pi8(a, b);
1163 frobzor = (uint64_t)a;]])], [
1164       ac_cv_c_mmx_intrinsics=yes
1165     ], [
1166       ac_cv_c_mmx_intrinsics=no
1167     ])
1168   ])
1169   VLC_RESTORE_FLAGS
1170   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1171     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1172   ])
1173
1174   VLC_SAVE_FLAGS
1175   CFLAGS="${CFLAGS} -mmmx"
1176   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1177     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1178 void *p;
1179 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1180 ]])
1181     ], [
1182       ac_cv_mmx_inline=yes
1183     ], [
1184       ac_cv_mmx_inline=no
1185     ])
1186   ])
1187   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1188     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1189     have_mmx="yes"
1190   ])
1191
1192   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1193                  [ac_cv_mmxext_inline], [
1194     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1195 void *p;
1196 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1197 ]])
1198     ], [
1199       ac_cv_mmxext_inline=yes
1200     ], [
1201       ac_cv_mmxext_inline=no
1202     ])
1203   ])
1204   VLC_RESTORE_FLAGS
1205   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1206     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1207     have_mmxext="yes"
1208   ])
1209 ])
1210 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1211 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1212
1213 dnl  Check for fully workin SSE2 intrinsics
1214 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1215 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1216 AC_ARG_ENABLE(sse,
1217   [AS_HELP_STRING([--disable-sse],
1218     [disable SSE (1-4) optimizations (default auto)])],, [
1219   case "${host_cpu}" in
1220     i?86|x86_64)
1221       enable_sse=yes
1222       ;;
1223     *)
1224       enable_sse=no
1225       ;;
1226   esac
1227 ])
1228 have_sse2="no"
1229 AS_IF([test "${enable_sse}" != "no"], [
1230   ARCH="${ARCH} sse sse2"
1231
1232   VLC_SAVE_FLAGS
1233   CFLAGS="${CFLAGS} -msse2"
1234   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1235     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1236 [#include <emmintrin.h>
1237 #include <stdint.h>
1238 uint64_t frobzor;]], [
1239 [__m128i a, b, c;
1240 a = b = c = _mm_set1_epi64((__m64)frobzor);
1241 a = _mm_slli_epi16(a, 3);
1242 a = _mm_adds_epi16(a, b);
1243 c = _mm_srli_epi16(c, 8);
1244 c = _mm_slli_epi16(c, 3);
1245 b = _mm_adds_epi16(b, c);
1246 a = _mm_unpacklo_epi8(a, b);
1247 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1248       ac_cv_c_sse2_intrinsics=yes
1249     ], [
1250       ac_cv_c_sse2_intrinsics=no
1251     ])
1252   ])
1253   VLC_RESTORE_FLAGS
1254   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1255     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1256   ])
1257
1258   VLC_SAVE_FLAGS
1259   CFLAGS="${CFLAGS} -msse"
1260   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1261     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1262 void *p;
1263 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1264 ]])
1265     ], [
1266       ac_cv_sse_inline=yes
1267     ], [
1268       ac_cv_sse_inline=no
1269     ])
1270   ])
1271
1272   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1273     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1274   ])
1275
1276   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1277     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1278 void *p;
1279 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1280 ]])
1281     ], [
1282       ac_cv_sse2_inline=yes
1283     ], [
1284       ac_cv_sse2_inline=no
1285     ])
1286   ])
1287   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1288     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1289     have_sse2="yes"
1290   ])
1291
1292   # SSE3
1293   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1294     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1295 void *p;
1296 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1297 ]])
1298     ], [
1299       ac_cv_sse3_inline=yes
1300     ], [
1301       ac_cv_sse3_inline=no
1302     ])
1303   ])
1304
1305   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1306     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1307   # SSSE3
1308   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1309     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1310 void *p;
1311 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1312 ]])
1313     ], [
1314       ac_cv_ssse3_inline=yes
1315     ], [
1316       ac_cv_ssse3_inline=no
1317     ])
1318   ])
1319
1320   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1321     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1322
1323   # SSE4.1
1324   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1325                  [ac_cv_sse4_1_inline], [
1326     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1327 void *p;
1328 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1329 ]])
1330     ], [
1331       ac_cv_sse4_1_inline=yes
1332     ], [
1333       ac_cv_sse4_1_inline=no
1334     ])
1335   ])
1336
1337   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1338     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1339
1340   # SSE4.2
1341   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1342                  [ac_cv_sse4_2_inline], [
1343     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1344 void *p;
1345 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1346 ]])
1347     ], [
1348       ac_cv_sse4_2_inline=yes
1349     ], [
1350       ac_cv_sse4_2_inline=no
1351     ])
1352   ])
1353
1354   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1355     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1356
1357   # SSE4A
1358   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1359     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1360 void *p;
1361 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1362 ]])
1363     ], [
1364       ac_cv_sse4a_inline=yes
1365     ], [
1366       ac_cv_sse4a_inline=no
1367     ])
1368   ])
1369   VLC_RESTORE_FLAGS
1370   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1371     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1372 ])
1373 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1374
1375 VLC_SAVE_FLAGS
1376 CFLAGS="${CFLAGS} -mmmx"
1377 have_3dnow="no"
1378 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1379   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1380 void *p;
1381 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1382 ]])
1383   ], [
1384     ac_cv_3dnow_inline=yes
1385   ], [
1386     ac_cv_3dnow_inline=no
1387   ])
1388 ])
1389 VLC_RESTORE_FLAGS
1390 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1391   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1392             [Define to 1 if 3D Now! inline assembly is available.])
1393   have_3dnow="yes"
1394 ])
1395 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1396
1397
1398 AC_ARG_ENABLE(neon,
1399   [AS_HELP_STRING([--disable-neon],
1400     [disable NEON optimizations (default auto)])],, [
1401   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1402 ])
1403 AS_IF([test "${enable_neon}" != "no"], [
1404   VLC_SAVE_FLAGS
1405   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1406   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1407     AC_COMPILE_IFELSE([
1408       AC_LANG_PROGRAM(,[[
1409 asm volatile("vqmovun.s64 d0, q1":::"d0");
1410 ]])
1411     ], [
1412       ac_cv_arm_neon="yes"
1413     ], [
1414       ac_cv_arm_neon="no"
1415     ])
1416   ])
1417   VLC_RESTORE_FLAGS
1418 ])
1419 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1420
1421
1422 AC_ARG_ENABLE(altivec,
1423   [AS_HELP_STRING([--disable-altivec],
1424     [disable AltiVec optimizations (default auto)])],, [
1425   AS_CASE("${host_cpu}", [powerpc*],
1426         [enable_altivec=yes], [enable_altivec=no])
1427 ])
1428 have_altivec="no"
1429 ALTIVEC_CFLAGS=""
1430 AS_IF([test "${enable_altivec}" = "yes"], [
1431   ARCH="${ARCH} altivec";
1432   VLC_SAVE_FLAGS
1433   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1434     [ac_cv_altivec_inline],
1435     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1436          ac_cv_altivec_inline="yes",
1437          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1438           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1439             [ac_cv_altivec_inline="-Wa,-maltivec"],
1440             ac_cv_altivec_inline=no)
1441          ])])
1442   VLC_RESTORE_FLAGS
1443   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1444     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1445               [Define to 1 if AltiVec inline assembly is available.])
1446     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1447       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1448       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1449     ])
1450     have_altivec="yes"
1451   ])
1452
1453   VLC_SAVE_FLAGS
1454   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1455   [ac_cv_c_altivec], [
1456     CFLAGS="${CFLAGS} -maltivec"
1457     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1458 [#include <altivec.h>]], [
1459 [vec_ld(0, (unsigned char *)0);]])], [
1460       ac_cv_c_altivec="-maltivec"
1461     ], [
1462       ac_cv_c_altivec="no"
1463     ])
1464   ])
1465   VLC_RESTORE_FLAGS
1466   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1467     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1468     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1469     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1470     ALTIVEC_CFLAGS="$ALTIVEC_FLAGS ${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}"
1471     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1472     have_altivec="yes"
1473   ])
1474   AC_CHECK_HEADERS(altivec.h)
1475
1476   VLC_SAVE_FLAGS
1477   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1478   AC_CACHE_CHECK([if linker needs -framework vecLib],
1479     [ac_cv_ld_altivec],
1480     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1481   VLC_RESTORE_FLAGS
1482   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1483     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1484   ])
1485 ])
1486 AC_SUBST(ALTIVEC_CFLAGS)
1487 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1488
1489 dnl
1490 dnl  Memory usage
1491 dnl
1492 AC_ARG_ENABLE(optimize-memory,
1493   [AS_HELP_STRING([--enable-optimize-memory],
1494     [optimize memory usage over performance])])
1495 if test "${enable_optimize_memory}" = "yes"; then
1496   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1497 fi
1498
1499 dnl
1500 dnl Allow running as root (useful for people running on embedded platforms)
1501 dnl
1502 AC_ARG_ENABLE(run-as-root,
1503   [AS_HELP_STRING([--enable-run-as-root],
1504     [allow running VLC as root (default disabled)])])
1505 AS_IF([test "${enable_run_as_root}" = "yes"],[
1506     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1507               [Define to 1 to allow running VLC as root (uid 0).])
1508 ])
1509
1510 dnl
1511 dnl Stream output
1512 dnl
1513 AC_ARG_ENABLE(sout,
1514   [AS_HELP_STRING([--disable-sout],
1515     [disable streaming output (default enabled)])])
1516 AS_IF([test "${enable_sout}" != "no"], [
1517   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1518 ])
1519 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1520
1521 dnl Lua modules
1522 AC_ARG_ENABLE(lua,
1523   [AS_HELP_STRING([--disable-lua],
1524     [disable LUA scripting support (default enabled)])])
1525 if test "${enable_lua}" != "no"
1526 then
1527   PKG_CHECK_MODULES(LUA, lua5.2,
1528     [ have_lua=yes ],
1529     [
1530     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1531
1532     PKG_CHECK_MODULES(LUA, lua5.1,
1533       [ have_lua=yes ],
1534       [
1535       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1536       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1537         [ have_lua=yes ],
1538         [
1539           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1540           have_lua=yes
1541           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1542             [],
1543             [ have_lua=no ] )
1544           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1545             [LUA_LIBS="-llua5.2"],
1546           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1547             [LUA_LIBS="-llua5.1"],
1548             AC_CHECK_LIB( lua51 , luaL_newstate,
1549               [LUA_LIBS="-llua51"],
1550               AC_CHECK_LIB( lua , luaL_newstate,
1551                 [LUA_LIBS="-llua"],
1552                 [ have_lua=no
1553                 ], [-lm])
1554             )))
1555         ])
1556       ])
1557     ])
1558   if test "x${have_lua}" != "xyes" ;  then
1559       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1560   fi
1561   AC_ARG_VAR([LUAC], [LUA byte compiler])
1562   AC_CHECK_PROGS(LUAC, [${LUAC} luac], [false])
1563   AS_IF([test "${LUAC}" = "false"], [
1564     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1565   ])
1566   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1567     AC_MSG_WARN([You need 32-bits luac when using lua from contrib.])
1568     have_lua=no
1569   ])
1570 fi
1571 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1572
1573
1574 dnl
1575 dnl HTTP daemon
1576 dnl
1577 AC_ARG_ENABLE(httpd,
1578   [AS_HELP_STRING([--disable-httpd],
1579     [disable the built-in HTTP server (default enabled)])])
1580 if test "${enable_httpd}" != "no"
1581 then
1582   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1583 fi
1584 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1585
1586
1587 dnl
1588 dnl VideoLAN manager
1589 dnl
1590 AC_ARG_ENABLE(vlm,
1591   [AS_HELP_STRING([--disable-vlm],
1592     [disable the stream manager (default enabled)])],,
1593   [enable_vlm="${enable_sout}"])
1594 AS_IF([test "${enable_vlm}" != "no"], [
1595   AS_IF([test "${enable_sout}" = "no"], [
1596     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1597   ])
1598   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1599 ])
1600 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1601
1602
1603 dnl
1604 dnl Addons manager storage and repositories modules
1605 dnl
1606 AC_ARG_ENABLE(addonmanagermodules,
1607   [AS_HELP_STRING([--disable-addonmanagermodules],
1608     [disable the addons manager modules (default enabled)])])
1609 if test "${enable_addonmanagermodules}" != "no"
1610 then
1611   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1612 fi
1613 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1614
1615
1616 dnl
1617 dnl  Input plugins
1618 dnl
1619
1620 EXTEND_HELP_STRING([Input plugins:])
1621
1622 dnl
1623 dnl  libarchive access module
1624 dnl
1625 PKG_ENABLE_MODULES_VLC([ARCHIVE], [access_archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1626
1627 dnl
1628 dnl  live555 input
1629 dnl
1630 AC_ARG_ENABLE(live555,
1631   [AS_HELP_STRING([--enable-live555],
1632     [enable RTSP input through live555 (default enabled)])])
1633
1634 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1635   PKG_CHECK_MODULES(LIVE555, live555, [
1636     VLC_ADD_PLUGIN([live555])
1637     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1638     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1639   ], [
1640     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1641
1642     AC_LANG_PUSH(C++)
1643     VLC_SAVE_FLAGS
1644
1645     dnl detect include paths
1646     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment.hh"], [
1647       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1648     ], [
1649       AS_IF([test "${SYS}" != "os2"], [
1650         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1651         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1652       ], [
1653         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1654         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1655         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1656       ])
1657     ])
1658
1659     dnl CPP Flags
1660     AS_IF([test "${SYS}" = "solaris"], [
1661       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1662     ])
1663     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1664     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1665
1666     dnl version check
1667     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1668       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1669 [#include <liveMedia_version.hh>
1670 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1671 # error BOOM
1672 #endif]])
1673       ], [
1674         ac_cv_live555="yes"
1675       ], [
1676         ac_cv_live555="no"
1677       ])
1678     ])
1679
1680     AS_IF([test "$ac_cv_live555" = "no"], [
1681       AC_MSG_WARN([live555 is missing or its installed version is too old:
1682 Version 2011.12.23 or later is required to proceed.
1683 You can get an updated one from http://www.live555.com/liveMedia .])
1684       AS_IF([test -n "${enable_live555}"], [
1685         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1686       ])
1687     ], [
1688       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1689       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1690       AS_IF([test "${SYS}" = "mingw32"], [
1691         # add ws2_32 for closesocket, select, recv
1692         other_libs="$other_libs -lws2_32"
1693       ])
1694
1695       dnl We need to check for pic because live555 don't provide shared libs
1696       dnl and we want to build a plugins so we need -fPIC on some arch.
1697       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1698       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1699       AC_CHECK_LIB(liveMedia_pic, main, [
1700         VLC_ADD_PLUGIN([live555])
1701         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1702       ],[
1703         AC_CHECK_LIB(liveMedia, main, [
1704           VLC_ADD_PLUGIN([live555])
1705           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1706         ],[],[${other_libs}])
1707       ],[${other_libs_pic}])
1708     ])
1709     VLC_RESTORE_FLAGS
1710     AC_LANG_POP(C++)
1711   ])
1712 ])
1713
1714 dnl
1715 dnl IIDC and DV FireWire input modules
1716 dnl
1717 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1718 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1719
1720 dnl
1721 dnl - linsys modules: access module check for libzvbi
1722 dnl
1723 AC_ARG_ENABLE(linsys,
1724   [AS_HELP_STRING([--enable-linsys],
1725     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1726 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1727   VLC_ADD_PLUGIN([linsys_hdsdi])
1728   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1729     VLC_ADD_PLUGIN([linsys_sdi])
1730   ], [
1731     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1732   ])
1733 ])
1734
1735 dnl
1736 dnl dvdread module: check for libdvdread
1737 dnl
1738 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1739
1740 dnl
1741 dnl libdvdnav plugin
1742 dnl
1743 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1744 AS_IF([test "${enable_dvdnav}" != "no"], [
1745   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1746     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1747       AC_MSG_RESULT(yes)
1748       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1749       ],[
1750       AC_MSG_RESULT(no)
1751     ])
1752 ])
1753
1754 dnl
1755 dnl  Blu-ray Disc Support with libbluray
1756 dnl
1757 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1758
1759 dnl
1760 dnl  OpenCV wrapper and example filters
1761 dnl
1762 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1763
1764
1765 dnl
1766 dnl  libsmbclient plugin
1767 dnl
1768 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1769 AS_IF([test "${SYS}" = "mingw32" -a "${enable_smbclient}" != "no"], [ VLC_ADD_PLUGIN([smb]) ])
1770
1771 dnl
1772 dnl  liBDSM access module
1773 dnl
1774 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1775
1776 dnl
1777 dnl sftp access support
1778 dnl
1779 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1780
1781 dnl
1782 dnl nfs access support
1783 dnl
1784 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1785
1786 dnl
1787 dnl  Video4Linux 2
1788 dnl
1789 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1790   [disable Video4Linux version 2 (default auto)])])
1791 have_v4l2="no"
1792 AS_IF([test "$enable_v4l2" != "no"], [
1793   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1794     have_v4l2="yes"
1795   ])
1796 ])
1797 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1798
1799 dnl
1800 dnl special access module for Blackmagic SDI cards
1801 dnl
1802 AC_ARG_ENABLE(decklink,
1803   [AS_HELP_STRING([--disable-decklink],
1804     [disable Blackmagic DeckLink SDI input (default auto)])])
1805 AC_ARG_WITH(decklink_sdk,
1806   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1807     [                        location of Blackmagic DeckLink SDI SDK])])
1808 have_decklink=no
1809 if test "${enable_decklink}" != "no"
1810 then
1811   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1812   then
1813     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1814   fi
1815   VLC_SAVE_FLAGS
1816   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1817   AC_LANG_PUSH(C++)
1818   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1819       have_decklink=yes
1820   ], [
1821       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1822   ])
1823   AC_LANG_POP(C++)
1824   VLC_RESTORE_FLAGS
1825 fi
1826 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1827
1828
1829 dnl
1830 dnl  Built-in CD-DA and VCD module
1831 dnl
1832 AC_ARG_ENABLE(vcd,
1833   [AS_HELP_STRING([--disable-vcd],
1834     [disable built-in VCD and CD-DA support (default enabled)])])
1835
1836 AC_ARG_ENABLE(libcddb,
1837   [AS_HELP_STRING([--disable-libcddb],
1838     [disable CDDB for Audio CD (default enabled)])])
1839
1840 if test "${enable_vcd}" != "no"
1841 then
1842   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1843   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1844     AC_MSG_RESULT(yes)
1845     VLC_ADD_PLUGIN([vcd cdda])
1846   ],[
1847     AC_MSG_RESULT(no)
1848   ])
1849
1850   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1851   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1852     AC_MSG_RESULT(yes)
1853     VLC_ADD_PLUGIN([vcd cdda])
1854     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1855   ],[
1856     AC_MSG_RESULT(no)
1857   ])
1858
1859   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1860   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1861     AC_MSG_RESULT(yes)
1862     VLC_ADD_PLUGIN([vcd cdda])
1863     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1864   ],[
1865     AC_MSG_RESULT(no)
1866   ])
1867
1868   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1869   then
1870     VLC_ADD_PLUGIN([vcd cdda])
1871   fi
1872
1873   if test "$enable_libcddb" != "no"; then
1874     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1875       HAVE_LIBCDDB=yes
1876       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1877       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1878       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1879       ],:
1880       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1881       HAVE_LIBCDDB=no])
1882   fi
1883 fi
1884
1885 dnl
1886 dnl Linux DVB
1887 dnl
1888 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1889   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1890 [#include <linux/dvb/version.h>
1891 #if (DVB_API_VERSION < 5)
1892 # error Linux DVB API v3.2 and older are not supported.
1893 #endif
1894 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1895 # error Linux DVB API v5.0 is unsupported. Please update.
1896 #endif
1897 ]])], [
1898   ac_cv_linux_dvb_5_1=yes
1899 ], [
1900   ac_cv_linux_dvb_5_1=no
1901 ])])
1902 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1903
1904 dnl
1905 dnl  Screen capture module
1906 dnl
1907 AC_ARG_ENABLE(screen,
1908   [AS_HELP_STRING([--enable-screen],
1909     [disable screen capture (default enabled)])])
1910 if test "${enable_screen}" != "no"; then
1911   if test "${SYS}" = "darwin"; then
1912     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1913       VLC_ADD_PLUGIN([screen])
1914     ])
1915   fi
1916 fi
1917 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1918
1919 dnl
1920 dnl  VNC/RFB access module
1921 dnl
1922 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1923
1924 dnl  RDP/Remote Desktop access module
1925 dnl
1926 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1927
1928 dnl
1929 dnl  Real RTSP plugin
1930 dnl
1931 AC_ARG_ENABLE(realrtsp,
1932   [  --enable-realrtsp       Real RTSP module (default disabled)])
1933 if test "${enable_realrtsp}" = "yes"; then
1934   VLC_ADD_PLUGIN([access_realrtsp])
1935 fi
1936
1937 dnl
1938 dnl MacOS eyeTV
1939 AC_ARG_ENABLE(macosx-eyetv,
1940   [  --enable-macosx-eyetv   Mac OS X EyeTV (TNT Tuner) module (default enabled on Mac OS X)])
1941 if test "x${enable_macosx_eyetv}" != "xno" &&
1942   (test "${SYS}" = "darwin" || test "${enable_macosx_eyetv}" = "yes")
1943 then
1944   VLC_ADD_PLUGIN([access_eyetv])
1945 fi
1946
1947 dnl
1948 dnl QTKit
1949 AC_ARG_ENABLE(macosx-qtkit,
1950   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
1951 if test "x${enable_macosx_qtkit}" != "xno" &&
1952   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1953 then
1954   AC_CHECK_HEADERS(QTKit/QTKit.h, [
1955       VLC_ADD_PLUGIN([qtsound])
1956     ])
1957 fi
1958
1959 dnl
1960 dnl AVFoundation
1961 AC_SUBST(have_avfoundation, ["no"])
1962 AC_ARG_ENABLE(macosx-avfoundation,
1963   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
1964 if test "x${enable_macosx_avfoundation}" != "xno" &&
1965   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
1966 then
1967   SAVED_LIBS="${LIBS}"
1968   LIBS="-framework AVFoundation"
1969   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
1970   LIBS="${SAVED_LIBS}"
1971   if test "${have_avfoundation}" != "no"
1972   then
1973     VLC_ADD_PLUGIN([avcapture])
1974   fi
1975 fi
1976 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
1977
1978 dnl
1979 dnl  DCP plugin (using asdcplib)
1980 dnl
1981 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
1982 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
1983
1984 dnl
1985 dnl  Demux plugins
1986 dnl
1987
1988 EXTEND_HELP_STRING([Mux/Demux plugins:])
1989
1990 dnl
1991 dnl  libdvbpsi check for ts mux/demux
1992 dnl
1993 have_dvbpsi="no"
1994 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
1995 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
1996
1997
1998 dnl
1999 dnl  GME demux plugin
2000 dnl
2001 AC_ARG_ENABLE(gme,
2002   [AS_HELP_STRING([--enable-gme],
2003     [use Game Music Emu (default auto)])])
2004 AS_IF([test "${enable_gme}" != "no"], [
2005   AC_CHECK_HEADER([gme/gme.h], [
2006     VLC_ADD_LIBS([gme], [-lgme])
2007     VLC_ADD_PLUGIN([gme])
2008   ], [
2009     AS_IF([test "x${enable_gme}" != "x"], [
2010       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2011     ])
2012   ])
2013 ])
2014
2015
2016 dnl
2017 dnl  SIDPlay plugin
2018 dnl
2019 AC_ARG_ENABLE(sid,
2020     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2021 AS_IF([test "${enable_sid}" != "no"], [
2022     PKG_CHECK_MODULES(SID, [libsidplay2], [
2023         AC_LANG_PUSH(C++)
2024         oldCPPFLAGS="$CPPFLAGS"
2025         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2026         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2027             VLC_ADD_PLUGIN([sid])
2028             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2029             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2030         ], [
2031             AS_IF([test -n "${enable_sid}"],
2032                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2033                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2034                 )
2035         ])
2036         CPPFLAGS="$oldCPPFLAGS"
2037         AC_LANG_POP(C++)
2038     ], [
2039         AS_IF([test "x${enable_sid}" = "xyes"],
2040             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2041             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2042             )
2043     ])
2044 ])
2045
2046
2047 dnl
2048 dnl  ogg demux plugin
2049 dnl
2050 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2051 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2052     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2053 ],[true])
2054 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2055 if test "${enable_sout}" != "no"; then
2056 dnl Check for libshout
2057     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2058 fi
2059
2060 dnl
2061 dnl  matroska demux plugin
2062 dnl
2063 AC_ARG_ENABLE(mkv,
2064   [AS_HELP_STRING([--disable-mkv],
2065     [do not use libmatroska (default auto)])])
2066 if test "${enable_mkv}" != "no" -a "${CXX}" != ""; then
2067   AC_LANG_PUSH(C++)
2068   AC_CHECK_HEADERS(ebml/EbmlVersion.h, [
2069     AC_MSG_CHECKING(for libebml version >= 1.0.0)
2070     AC_EGREP_CPP(yes,
2071       [#include <ebml/EbmlVersion.h>
2072        #ifdef LIBEBML_VERSION
2073        #if LIBEBML_VERSION >= 0x010000
2074        yes
2075        #endif
2076        #endif],
2077       [AC_MSG_RESULT([yes])
2078         AC_CHECK_HEADERS(matroska/KaxVersion.h, [
2079           AC_MSG_CHECKING(for libmatroska version >= 1.0.0)
2080           AC_EGREP_CPP(yes,
2081             [#include <matroska/KaxVersion.h>
2082              #ifdef LIBMATROSKA_VERSION
2083              #if LIBMATROSKA_VERSION >= 0x010000
2084              yes
2085              #endif
2086              #endif],
2087             [AC_MSG_RESULT([yes])
2088               AC_CHECK_HEADERS(matroska/KaxAttachments.h)
2089               AC_CHECK_LIB(ebml_pic, main, [
2090                 VLC_ADD_PLUGIN([mkv])
2091                 VLC_ADD_LIBS([mkv],[-lmatroska -lebml_pic])
2092               ],[
2093                 AC_CHECK_LIB(ebml, main, [
2094                   VLC_ADD_PLUGIN([mkv])
2095                   VLC_ADD_LIBS([mkv],[-lmatroska -lebml])
2096                 ])
2097               ])
2098             ], [
2099               AC_MSG_RESULT([no])
2100               AC_MSG_ERROR([Your libmatroska is too old: you may get a more recent one from http://dl.matroska.org/downloads/libmatroska/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2101           ])
2102         ])
2103       ],
2104       [AC_MSG_RESULT([no])
2105         AC_MSG_ERROR([Your libebml is too old: you may get a more recent one from http://dl.matroska.org/downloads/libebml/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2106     ])
2107   ])
2108   AC_LANG_POP(C++)
2109 fi
2110
2111 dnl
2112 dnl  modplug demux plugin
2113 dnl
2114 AC_ARG_ENABLE(mod,
2115   [AS_HELP_STRING([--disable-mod],
2116     [do not use libmodplug (default auto)])])
2117 if test "${enable_mod}" != "no" ; then
2118     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2119           VLC_ADD_PLUGIN([mod])
2120           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2121           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2122           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2123     ],[
2124        AS_IF([test -n "${enable_mod}"],
2125          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2126          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2127     ])
2128 fi
2129
2130 dnl
2131 dnl  mpc demux plugin
2132 dnl
2133 AC_ARG_ENABLE(mpc,
2134   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2135 if test "${enable_mpc}" != "no"
2136 then
2137   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2138     VLC_ADD_PLUGIN([mpc])
2139     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2140     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2141     VLC_ADD_PLUGIN([mpc])
2142     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2143 fi
2144
2145 dnl
2146 dnl  Codec plugins
2147 dnl
2148
2149 EXTEND_HELP_STRING([Codec plugins:])
2150
2151 dnl
2152 dnl wmafixed plugin
2153 dnl
2154 AC_ARG_ENABLE(wma-fixed,
2155   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2156 if test "${enable_wma_fixed}" = "yes"
2157 then
2158   VLC_ADD_PLUGIN([wma_fixed])
2159 fi
2160
2161 dnl
2162 dnl shine encoder plugin
2163 dnl
2164 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2165
2166
2167 dnl
2168 dnl openmax il codec plugin
2169 dnl
2170 AC_ARG_ENABLE(omxil,
2171   [  --enable-omxil          openmax il codec module (default disabled)])
2172 if test "${enable_omxil}" = "yes"
2173 then
2174   VLC_ADD_PLUGIN([omxil])
2175 fi
2176
2177 dnl
2178 dnl openmax il vout plugin
2179 dnl
2180 AC_ARG_ENABLE(omxil-vout,
2181   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2182 if test "${enable_omxil_vout}" = "yes"
2183 then
2184   VLC_ADD_PLUGIN([omxil_vout])
2185 fi
2186
2187 dnl
2188 dnl raspberry pi openmax il configuration
2189 dnl
2190 AC_ARG_ENABLE(rpi-omxil,
2191   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2192 if test "${enable_rpi_omxil}" = "yes"
2193 then
2194   VLC_ADD_PLUGIN([omxil omxil_vout])
2195   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2196 fi
2197
2198 dnl
2199 dnl CrystalHD codec plugin
2200 dnl
2201 AC_ARG_ENABLE(crystalhd,
2202   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2203 if test "${enable_crystalhd}" != "no"; then
2204     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2205       VLC_ADD_PLUGIN([crystalhd])
2206       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2207     ],[
2208       if test "${SYS}" = "mingw32" ; then
2209         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2210           VLC_ADD_PLUGIN([crystalhd])
2211           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2212             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2213             ])
2214         ],[
2215           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2216                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2217                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2218         ],[#define __LINUX_USER__
2219                #include <libcrystalhd/bc_dts_types.h>
2220         ])
2221       fi
2222     ],[
2223        #include <libcrystalhd/bc_dts_types.h>
2224       ])
2225 fi
2226
2227 dnl
2228 dnl  mad plugin
2229 dnl
2230 have_mad="no"
2231 MAD_CFLAGS=""
2232 MAD_LIBS=""
2233
2234 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2235   enable_mad="yes"
2236 ], [
2237   with_mad="no"
2238 ])
2239 AS_IF([test "${with_mad}" != "no"], [
2240   MAD_CFLAGS="-I${with_mad}/include"
2241   MAD_LIBS="-L${with_mad}/lib"
2242 ])
2243
2244 AC_ARG_ENABLE(mad,
2245   [  --enable-mad            libmad module (default enabled)])
2246 AS_IF([test "${enable_mad}" != "no"], [
2247   VLC_SAVE_FLAGS
2248   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2249   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2250   AC_CHECK_HEADERS(mad.h, [
2251     AC_CHECK_LIB(mad, mad_bit_init, [
2252       have_mad="yes"
2253       MAD_LIBS="${MAD_LIBS} -lmad"
2254     ])
2255   ])
2256   VLC_RESTORE_FLAGS
2257   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2258     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2259   ])
2260 ])
2261 AC_SUBST(MAD_CFLAGS)
2262 AC_SUBST(MAD_LIBS)
2263 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2264
2265 dnl  mpg123 plugin
2266 dnl
2267 dnl
2268 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2269
2270
2271 AC_ARG_ENABLE(merge-ffmpeg,
2272 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2273   enable_merge_ffmpeg="no"
2274 ])
2275 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2276
2277 AC_MSG_CHECKING([for libavutil variant])
2278 PKG_CHECK_EXISTS([libavutil], [
2279   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2280   libavutil_micro="${libavutil_version##*.}"
2281   AS_IF([test ${libavutil_micro} -le 99], [
2282     avfork="libav"
2283   ], [
2284     avfork="ffmpeg"
2285   ])
2286 ], [
2287   avfork="none"
2288 ])
2289 AC_MSG_RESULT([${avfork}])
2290
2291 dnl
2292 dnl gstreamer stuff
2293 dnl
2294 AC_ARG_ENABLE(gst-decode,
2295   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2296
2297 have_gst_decode="no"
2298 AS_IF([test "${enable_gst_decode}" != "no"], [
2299   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2300     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2301       have_gst_decode="yes"
2302     ], [
2303       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2304     ])
2305   ], [
2306     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2307   ])
2308 ])
2309 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2310
2311 dnl
2312 dnl  avcodec decoder/encoder plugin
2313 dnl
2314 AC_ARG_ENABLE(avcodec,
2315 [  --enable-avcodec        libavcodec codec (default enabled)])
2316 AS_IF([test "${enable_avcodec}" != "no"], [
2317   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= 55.0.0 libavutil >= 52.0.0], [
2318     dnl PKG_CHECK_EXISTS([libavcodec < 56],, [
2319     dnl   AC_MSG_ERROR([libavcodec versions 56 and later are not supported yet.])
2320     dnl ])
2321     VLC_SAVE_FLAGS
2322     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2323     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2324     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2325     AC_CHECK_HEADERS(libavutil/avutil.h)
2326     VLC_RESTORE_FLAGS
2327     have_avcodec="yes"
2328   ],[
2329     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2330   ])
2331 ], [
2332   have_avcodec="no"
2333 ])
2334 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2335
2336 dnl
2337 dnl libva needs avcodec
2338 dnl
2339 AC_ARG_ENABLE(libva,
2340   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2341
2342 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2343   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2344 ])
2345
2346 have_vaapi="no"
2347 have_vaapi_drm="no"
2348 have_vaapi_x11="no"
2349 AS_IF([test "${enable_libva}" != "no"], [
2350   PKG_CHECK_EXISTS([libva], [
2351     have_vaapi="yes"
2352   ], [
2353     AS_IF([test -n "${enable_libva}"], [
2354       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2355     ], [
2356       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2357     ])
2358   ])
2359   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2360     have_vaapi_drm="yes"
2361   ], [
2362     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2363   ])
2364   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2365     have_vaapi_x11="yes"
2366   ], [
2367     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2368   ])
2369 ])
2370 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2371 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2372
2373 have_avcodec_vaapi="no"
2374 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2375   case "${avfork}" in
2376     ffmpeg)
2377       PKG_CHECK_EXISTS([libavcodec >= 57.10.100], [
2378         PKG_CHECK_EXISTS([libavcodec <= 57.12.100], [
2379           AC_MSG_ERROR([VA API requires FFmpeg libavcodec < 57.10 or > 57.12 or libav.])
2380         ])
2381       ])
2382       ;;
2383   esac
2384   VLC_SAVE_FLAGS
2385   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2386   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2387   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2388     AC_MSG_NOTICE([VA API acceleration activated])
2389     have_avcodec_vaapi="yes"
2390   ],[
2391     AS_IF([test -n "${enable_libva}"], [
2392       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2393     ], [
2394       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2395     ])
2396   ])
2397   VLC_RESTORE_FLAGS
2398 ])
2399 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2400
2401 dnl
2402 dnl dxva2 needs avcodec
2403 dnl
2404 AC_ARG_ENABLE(dxva2,
2405   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2406
2407 have_avcodec_dxva2="no"
2408 AS_IF([test "${enable_dxva2}" != "no"], [
2409   if test "${SYS}" = "mingw32"; then
2410   AS_IF([test "x${have_avcodec}" = "xyes"], [
2411     AC_CHECK_HEADERS(dxva2api.h,
2412       [
2413         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2414            AC_MSG_NOTICE([DxVA2 acceleration activated])
2415            have_avcodec_dxva2="yes"
2416         ],[
2417     AS_IF([test "${enable_dxva2}" = "yes"],
2418           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2419               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2420         ], [#undef _WIN32_WINNT
2421             /* DXVA2 is only available in Vista and above */
2422             #define _WIN32_WINNT 0x600])
2423       ],[
2424     AS_IF([test "${enable_dxva2}" = "yes"],
2425               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2426               [AC_MSG_WARN([dxva2api.h not found])])
2427       ],[#include <d3d9.h>])
2428   ],[
2429     AS_IF([test "x${enable_dxva2}" != "x"], [
2430       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2431     ])
2432   ])
2433   fi
2434 ])
2435 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2436
2437 dnl
2438 dnl d3d11va needs avcodec
2439 dnl
2440 AC_ARG_ENABLE(d3d11va,
2441   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2442
2443 have_avcodec_d3d11va="no"
2444 AS_IF([test "${enable_d3d11va}" != "no"], [
2445   if test "${SYS}" = "mingw32"; then
2446   AS_IF([test "x${have_avcodec}" = "xyes"], [
2447         AC_CHECK_TYPES([ID3D11VideoDecoder],
2448           [
2449             AC_CHECK_HEADERS(dxva2api.h,
2450               [
2451                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2452                    AC_MSG_NOTICE([D3D11 acceleration activated])
2453                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2454                    have_avcodec_d3d11va="yes"
2455                 ],[
2456                   AS_IF([test "${enable_d3d11va}" = "yes"],
2457                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2458                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2459                   ], [#undef _WIN32_WINNT
2460                       /* D3D11 is only available in Vista and above */
2461                       #define _WIN32_WINNT 0x600])
2462                   ],[
2463                     AS_IF([test "${enable_d3d11va}" = "yes"],
2464                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2465                           [AC_MSG_WARN([dxva2api.h not found])])
2466                   ],[#include <d3d9.h>])
2467           ],[
2468             AS_IF([test "${enable_d3d11va}" = "yes"],
2469                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2470                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2471           ], [#include <d3d11.h>])
2472   ],[
2473     AS_IF([test "x${enable_d3d11va}" != "x"], [
2474       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2475     ])
2476   ])
2477   fi
2478 ])
2479 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2480
2481 dnl
2482 dnl DXGI debug
2483 dnl
2484 AC_CHECK_HEADERS(dxgidebug.h)
2485
2486 dnl
2487 dnl vda needs avcodec
2488 dnl
2489 AC_ARG_ENABLE(vda,
2490   [  --enable-vda          VDA  support (default auto)])
2491
2492 have_avcodec_vda="no"
2493 AS_IF([test "${enable_vda}" != "no"], [
2494   if test "${SYS}" = "darwin"; then
2495   AS_IF([test "x${have_avcodec}" = "xyes"], [
2496     AC_CHECK_HEADERS(VideoDecodeAcceleration/VDADecoder.h,
2497       [
2498         AC_CHECK_HEADERS(libavcodec/vda.h, [
2499            have_avcodec_vda="yes"
2500         ],[
2501         AS_IF([test "${enable_vda}" = "yes"],
2502               [AC_MSG_ERROR([vda is present but libavcodec/vda.h is missing])],
2503               [AC_MSG_WARN([vda is present but libavcodec/vda.h is missing ])])
2504         ])
2505   ],[
2506         AS_IF([test "${enable_vda}" = "yes"],
2507               [AC_MSG_ERROR([Could not find required VideoDecodeAcceleration/VDADecoder.h])],
2508               [AC_MSG_WARN([VideoDecodeAcceleration/VDADecoder.h not found])])
2509       ])
2510   ],[
2511     AS_IF([test "x${enable_vda}" != "x"], [
2512       AC_MSG_ERROR([--enable-vda and --disable-avcodec options are mutually exclusive.])
2513     ])
2514  ])
2515  AS_IF([test "${have_avcodec_vda}" = "yes"], [
2516      SAVE_LIBS=$LIBS
2517      LIBS="$LIBS $AVCODEC_LIBS"
2518      AC_CHECK_FUNCS([av_vda_alloc_context])
2519      LIBS=$SAVE_LIBS
2520  ])
2521  fi
2522 ])
2523 AM_CONDITIONAL([HAVE_AVCODEC_VDA], [test "${have_avcodec_vda}" = "yes"])
2524
2525 dnl
2526 dnl  avformat demuxer/muxer plugin
2527 dnl
2528
2529 AC_ARG_ENABLE(avformat,
2530 [  --enable-avformat       libavformat containers (default enabled)],, [
2531   enable_avformat="${have_avcodec}"
2532 ])
2533 have_avformat="no"
2534 AS_IF([test "${enable_avformat}" != "no"], [
2535   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2536       have_avformat="yes"
2537       VLC_SAVE_FLAGS
2538       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2539       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2540       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2541       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2542       AC_CHECK_HEADERS(libavutil/avutil.h)
2543       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2544         have_avformat="no"
2545       ])
2546       VLC_RESTORE_FLAGS
2547     ],[
2548       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2549   ])
2550 ])
2551 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2552
2553 dnl
2554 dnl  swscale image scaling and conversion plugin
2555 dnl
2556
2557 AC_ARG_ENABLE(swscale,
2558   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2559           (default enabled)]))
2560 if test "${enable_swscale}" != "no"
2561 then
2562   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2563     [
2564       VLC_SAVE_FLAGS
2565       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2566       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2567       AC_CHECK_HEADERS(libswscale/swscale.h)
2568       AC_CHECK_HEADERS(libavutil/avutil.h)
2569       VLC_ADD_PLUGIN([swscale])
2570       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2571       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2572       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2573         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2574       ])
2575       VLC_RESTORE_FLAGS
2576     ],[
2577       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2578   ])
2579 fi
2580
2581 dnl
2582 dnl  postproc plugin
2583 dnl
2584
2585 AC_ARG_ENABLE(postproc,
2586 [  --enable-postproc       libpostproc image post-processing (default auto)])
2587 if test "${enable_postproc}" != "no"
2588 then
2589   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2590     [
2591       VLC_SAVE_FLAGS
2592       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2593       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2594       AC_CHECK_HEADERS(postproc/postprocess.h)
2595       VLC_ADD_PLUGIN([postproc])
2596       VLC_RESTORE_FLAGS
2597     ],[
2598       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2599   ])
2600 fi
2601
2602 dnl
2603 dnl  faad decoder plugin
2604 dnl
2605 AC_ARG_ENABLE(faad,
2606 [  --enable-faad           faad codec (default auto)])
2607 have_faad="no"
2608 AS_IF([test "${enable_faad}" != "no"], [
2609   AC_CHECK_HEADERS([neaacdec.h], [
2610     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2611
2612     AS_IF([test "${have_faad}" = "yes"], [
2613       VLC_ADD_PLUGIN([faad])
2614       VLC_ADD_LIBS([faad],[-lfaad])
2615     ], [
2616       AS_IF([test "${enable_faad}" = "yes"], [
2617         AC_MSG_ERROR([cannot find FAAD library])
2618       ], [
2619         AC_MSG_WARN([cannot find FAAD library])
2620       ])
2621     ])
2622   ])
2623 ])
2624
2625 dnl
2626 dnl libvpx decoder plugin
2627 dnl
2628 AC_ARG_ENABLE(vpx,
2629     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2630 AS_IF([test "${enable_vpx}" != "no"],[
2631     PKG_CHECK_MODULES([VPX], [vpx] , [
2632         VLC_ADD_PLUGIN([vpx])
2633         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2634         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2635         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2636             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2637         ], [], [${VPX_LIBS}])
2638         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2639             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2640         ], [], [${VPX_LIBS}])
2641         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2642             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2643         ], [], [${VPX_LIBS}])
2644         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2645             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2646         ], [], [${VPX_LIBS}])
2647     ], [
2648     AS_IF([test "${enable_vpx}" = "yes"],[
2649         AC_MSG_ERROR([libvpx was not found])
2650     ])])
2651 ])
2652
2653 dnl
2654 dnl twolame encoder plugin
2655 dnl
2656 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2657
2658 dnl
2659 dnl fdk-aac encoder plugin
2660 dnl
2661 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2662
2663
2664 dnl
2665 dnl A52/AC3 decoder plugin
2666 dnl
2667 AC_ARG_ENABLE(a52,
2668   [  --enable-a52            A/52 support with liba52 (default enabled)])
2669 if test "${enable_a52}" != "no"
2670 then
2671   AC_ARG_WITH(a52,
2672     [  --with-a52=PATH         a52 headers and libraries])
2673     if test -z "${with_a52}"
2674     then
2675       LDFLAGS_test=""
2676       CPPFLAGS_test=""
2677     else
2678       LDFLAGS_test="-L${with_a52}/lib"
2679       CPPFLAGS_test="-I${with_a52}/include"
2680     fi
2681     VLC_SAVE_FLAGS
2682     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52tofloat32}"
2683     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52tofloat32}"
2684     AC_CHECK_HEADERS(a52dec/a52.h, [
2685       AC_CHECK_LIB(a52, a52_free, [
2686         VLC_ADD_PLUGIN([a52tofloat32])
2687         VLC_ADD_LIBS([a52tofloat32],[${LDFLAGS_test} -la52])
2688         VLC_ADD_CPPFLAGS([a52tofloat32],[${CPPFLAGS_test}])
2689       ],[
2690         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2691         ], [$LIBM])
2692     ],[
2693       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2694     ])
2695     VLC_RESTORE_FLAGS
2696 fi
2697
2698 dnl
2699 dnl DTS Coherent Acoustics decoder plugin
2700 dnl
2701 PKG_ENABLE_MODULES_VLC([DCA], [dtstofloat32], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2702
2703 dnl
2704 dnl  Flac plugin
2705 dnl
2706 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2707
2708 dnl
2709 dnl  Libmpeg2 plugin
2710 dnl
2711 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2712
2713 dnl
2714 dnl  Vorbis plugin
2715 dnl
2716 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2717
2718 dnl
2719 dnl  Tremor plugin
2720 dnl
2721 AC_ARG_ENABLE(tremor,
2722   [  --enable-tremor         Tremor decoder support (default disabled)])
2723 if test "${enable_tremor}" = "yes"
2724 then
2725   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2726     VLC_ADD_PLUGIN([tremor])
2727    ],[])
2728 fi
2729
2730 dnl
2731 dnl  Speex plugins
2732 dnl
2733 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2734 have_speexdsp="no"
2735 AS_IF([test "${enable_speex}" != "no"], [
2736   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2737     have_speexdsp="yes"
2738   ], [
2739     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2740   ])
2741 ])
2742 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2743
2744 dnl
2745 dnl  Opus plugin
2746 dnl
2747 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2748
2749 dnl
2750 dnl  theora decoder plugin
2751 dnl
2752 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2753
2754 dnl
2755 dnl  OggSpots decoder plugin
2756 dnl
2757 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2758
2759 dnl
2760 dnl  Daala decoder plugin
2761 dnl
2762 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2763
2764 dnl
2765 dnl  schroedinger decoder plugin (for dirac format video)
2766 dnl
2767 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2768
2769 dnl
2770 dnl  PNG decoder module
2771 dnl
2772 AC_ARG_ENABLE(png,
2773   [  --enable-png            PNG support (default enabled)])
2774 AS_IF([test "${enable_png}" != "no"], [
2775 AC_CHECK_HEADERS(png.h, [
2776   VLC_SAVE_FLAGS
2777   LDFLAGS="${LDFLAGS} -lz $LIBM"
2778   AC_CHECK_LIB(png, png_set_rows, [
2779     VLC_ADD_PLUGIN([png])
2780   ], [], [-lz $LIBM])
2781   VLC_RESTORE_FLAGS
2782   ])
2783 ])
2784
2785 dnl
2786 dnl  JPEG decoder module
2787 dnl
2788 AC_ARG_ENABLE(jpeg,
2789   [  --enable-jpeg           JPEG support (default enabled)])
2790 AS_IF([test "${enable_jpeg}" != "no"], [
2791 AC_CHECK_HEADERS(jpeglib.h, [
2792   VLC_ADD_PLUGIN([jpeg])
2793   ])
2794 ])
2795
2796 dnl
2797 dnl  BPG decoder module
2798 dnl
2799 AC_ARG_ENABLE(bpg,
2800   [  --enable-bpg           BPG support (default disabled)])
2801 AS_IF([test "${enable_bpg}" != "no"], [
2802 AC_CHECK_HEADERS(libbpg.h, [
2803   VLC_ADD_PLUGIN([bpg])
2804   ])
2805 ])
2806
2807 dnl
2808 dnl H262 encoder plugin (lib262)
2809 dnl
2810 AC_ARG_ENABLE(x262,
2811   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2812 if test "${enable_x262}" != "no"; then
2813     PKG_CHECK_MODULES(X262, x262, [
2814         VLC_ADD_PLUGIN([x262])
2815         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2816         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2817           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2818         ])
2819         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2820         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2821           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2822         fi
2823     ], [
2824        if test "${enable_x262}" = "yes"; then
2825         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2826        fi
2827     ])
2828 fi
2829
2830 dnl x265 encoder
2831 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2832
2833 dnl
2834 dnl H264 encoder plugin (10-bit lib264)
2835 dnl
2836 AC_ARG_ENABLE(x26410b,
2837   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2838 if test "${enable_x26410b}" != "no"; then
2839     PKG_CHECK_MODULES(X26410B, x26410b, [
2840         VLC_ADD_PLUGIN([x26410b])
2841         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2842         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2843           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2844         ])
2845         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2846         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2847           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2848         fi
2849     ], [
2850        if test "${enable_x26410b}" = "yes"; then
2851         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2852        fi
2853     ])
2854 fi
2855
2856
2857 dnl
2858 dnl H264 encoder plugin (using libx264)
2859 dnl
2860 AC_ARG_ENABLE(x264,
2861   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2862 if test "${enable_x264}" != "no"; then
2863       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2864         VLC_ADD_PLUGIN([x264])
2865         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2866
2867         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2868           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2869         ])
2870
2871         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2872         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2873           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2874         fi
2875       ],[
2876         if test "${enable_x264}" = "yes"; then
2877             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2878           fi
2879       ])
2880 fi
2881
2882 dnl
2883 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2884 dnl
2885 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2886
2887 dnl
2888 dnl libfluidsynth (MIDI synthetizer) plugin
2889 dnl
2890 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2891
2892 dnl
2893 dnl Teletext Modules
2894 dnl vbi decoder plugin (using libzbvi)
2895 dnl telx module
2896 dnl uncompatible
2897 dnl
2898 AC_ARG_ENABLE(zvbi,
2899   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2900                   libzvbi (default enabled)]))
2901 AC_ARG_ENABLE(telx,
2902   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2903                   zvbi) (default enabled if zvbi is absent)]))
2904
2905 AS_IF( [test "${enable_zvbi}" != "no"],[
2906     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2907         [
2908           VLC_ADD_PLUGIN([zvbi])
2909           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2910           AS_IF( [test "${enable_telx}" = "yes"],[
2911                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2912                   ])
2913         ],[
2914           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2915         ])
2916     ])
2917 AS_IF( [test "${enable_telx}" != "no" ],[
2918   VLC_ADD_PLUGIN([telx])
2919   ])
2920
2921 dnl
2922 dnl libass subtitle rendering module
2923 dnl
2924 AC_ARG_ENABLE(libass,
2925   [  --enable-libass         Subtitle support using libass (default enabled)])
2926 AS_IF( [test "${enable_libass}" != "no"], [
2927   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2928       [
2929         VLC_ADD_PLUGIN([libass])
2930
2931         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2932           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2933            VLC_ADD_LIBS([libass],[-lfontconfig])
2934        ])
2935       ],[
2936         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2937       ])
2938   ])
2939
2940 dnl
2941 dnl ARIB subtitles rendering module
2942 dnl
2943 AC_ARG_ENABLE(aribsub,
2944   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2945 AS_IF( [test "${enable_aribsub}" != "no" ],[
2946   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2947       have_aribb24="yes"
2948       VLC_ADD_PLUGIN([aribsub])
2949       VLC_ADD_LIBS([aribsub],[-laribb24])
2950       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2951     ],[
2952       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2953       have_aribb24="no"
2954   ])
2955 ])
2956 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2957
2958 dnl
2959 dnl ARIB B25
2960 dnl
2961 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2962
2963 dnl
2964 dnl  kate decoder plugin
2965 dnl
2966 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2967
2968 dnl
2969 dnl  tiger rendering for kate decoder plugin
2970 dnl
2971 AC_ARG_ENABLE(tiger,
2972 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2973 AS_IF([test "${enable_tiger}" != "no"], [
2974   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2975       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2976         AS_IF([test -n "${enable_tiger}"], [
2977           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2978         ])
2979   ])
2980 ])
2981
2982
2983 dnl
2984 dnl  Video plugins
2985 dnl
2986
2987 EXTEND_HELP_STRING([Video plugins:])
2988
2989 dnl
2990 dnl  OpenGL
2991 dnl
2992 PKG_CHECK_MODULES([EGL], [egl], [
2993   have_egl="yes"
2994 ], [
2995   have_egl="no"
2996 ])
2997 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
2998
2999 have_gl="no"
3000 PKG_CHECK_MODULES([GL], [gl], [
3001   have_gl="yes"
3002 ], [
3003   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3004 #ifdef _WIN32
3005 # include <GL/glew.h>
3006 #endif
3007 #include <GL/gl.h>
3008 ]], [
3009     [int t0 = GL_TEXTURE0;]])
3010   ], [
3011     GL_CFLAGS=""
3012     have_gl="yes"
3013     AS_IF([test "${SYS}" != "mingw32"], [
3014       GL_LIBS="-lGL"
3015     ], [
3016       GL_LIBS="-lopengl32"
3017     ])
3018   ])
3019 ])
3020 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3021
3022 dnl OpenGL ES 2: depends on EGL 1.1
3023 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3024 dnl OpenGL ES 1: depends on EGL 1.0
3025 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [disabled])
3026
3027 dnl
3028 dnl  Xlib
3029 dnl
3030
3031 AC_PATH_XTRA()
3032 AC_CHECK_HEADERS(X11/Xlib.h)
3033
3034 dnl
3035 dnl  X C Bindings modules
3036 dnl
3037 AC_ARG_ENABLE(xcb,
3038   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3039   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3040     enable_xcb="yes"
3041   ], [
3042     enable_xcb="no"
3043   ])
3044 ])
3045 AC_ARG_ENABLE(xvideo,
3046   [  --enable-xvideo         XVideo support (default enabled)],, [
3047     enable_xvideo="$enable_xcb"
3048 ])
3049
3050 have_xcb="no"
3051 have_xcb_keysyms="no"
3052 have_xcb_randr="no"
3053 have_xcb_xvideo="no"
3054 AS_IF([test "${enable_xcb}" != "no"], [
3055   dnl libxcb
3056   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3057   have_xcb="yes"
3058   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3059   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3060   PKG_CHECK_MODULES(XPROTO, [xproto])
3061
3062   AS_IF([test "${enable_xvideo}" != "no"], [
3063     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3064   ])
3065
3066   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3067
3068   dnl xcb-utils
3069   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3070     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3071   ])
3072 ])
3073 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3074 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3075 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3076 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3077
3078
3079 dnl
3080 dnl VDPAU needs X11
3081 dnl
3082 AC_ARG_ENABLE(vdpau,
3083   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3084 have_vdpau="no"
3085 AS_IF([test "${enable_vdpau}" != "no"], [
3086   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3087     have_vdpau="yes"
3088     AS_IF([test "${no_x}" = "yes"], [
3089       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3090     ])
3091   ], [
3092     AS_IF([test -n "${enable_vdpau}"], [
3093       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3094     ])
3095   ])
3096 ])
3097 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3098
3099 have_avcodec_vdpau="no"
3100 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3101   case "${avfork}" in
3102     libav) av_vdpau_ver="55.26.0" ;;
3103     ffmpeg) av_vdpau_ver="55.42.100" ;;
3104   esac
3105   PKG_CHECK_EXISTS([libavutil >= 52.4.0 libavcodec >= ${av_vdpau_ver}], [
3106     have_avcodec_vdpau="yes"
3107     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3108   ], [
3109     AS_IF([test -n "${enable_vdpau}"], [
3110       AC_MSG_ERROR([libav libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3111     ], [
3112       AC_MSG_WARN([libav libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3113     ])
3114   ])
3115 ])
3116 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3117
3118
3119 dnl
3120 dnl  Wayland
3121 dnl
3122 AC_ARG_ENABLE(wayland,
3123   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3124 have_wayland="no"
3125 AC_ARG_VAR([WAYLAND_SCANNER], [Wayland scanner utility])
3126
3127 AS_IF([test "${enable_wayland}" != "no"], [
3128   AC_MSG_CHECKING([for the Wayland scanner])
3129   AS_IF([test -z "$WAYLAND_SCANNER"], [
3130     PKG_CHECK_EXISTS([wayland-scanner], [
3131       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3132     ], [
3133       WAYLAND_SCANNER="wayland-scanner"
3134     ])
3135   ])
3136   AC_MSG_RESULT([$WAYLAND_SCANNER])
3137
3138   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3139     have_wayland="yes"
3140   ], [
3141     AS_IF([test -n "${enable_wayland}"], [
3142       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3143     ])
3144   ])
3145
3146   AS_IF([test "${have_egl}" = "yes"], [
3147     PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3148       have_wayland_egl="yes"
3149     ], [
3150       AS_IF([test -n "${enable_wayland}"], [
3151         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3152       ])
3153     ])
3154   ])
3155 ])
3156 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3157 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3158
3159
3160 dnl
3161 dnl  SDL module
3162 dnl
3163 AC_ARG_ENABLE(sdl,
3164   [  --enable-sdl            SDL support (default enabled)])
3165 AC_ARG_ENABLE(sdl-image,
3166   [  --enable-sdl-image      SDL image support (default enabled)])
3167 if test "${enable_sdl}" != "no"
3168 then
3169    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3170       # SDL on Darwin is heavily patched and can only run SDL_image
3171       if test "${SYS}" != "darwin"; then
3172         VLC_ADD_PLUGIN([vout_sdl])
3173       fi
3174
3175       # SDL_image
3176       AS_IF([ test "${enable_sdl_image}" != "no"],[
3177         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3178           VLC_ADD_PLUGIN([sdl_image])],
3179           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3180           ])
3181       ])
3182    ],[
3183      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3184    ])
3185 fi
3186
3187 dnl
3188 dnl  freetype module
3189 dnl
3190 AC_ARG_ENABLE(freetype,
3191   [  --enable-freetype       freetype support   (default auto)])
3192 AC_ARG_ENABLE(fribidi,
3193   [  --enable-fribidi        fribidi support    (default auto)])
3194 AC_ARG_ENABLE(harfbuzz,
3195   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3196 AC_ARG_ENABLE(fontconfig,
3197   [  --enable-fontconfig     fontconfig support (default auto)])
3198
3199 AC_ARG_WITH([default-font],
3200     AS_HELP_STRING([--with-default-font=PATH],
3201         [Path to the default font]),
3202         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3203             "$withval", [Default font])])
3204 AC_ARG_WITH([default-monospace-font],
3205     AS_HELP_STRING([--with-default-monospace-font=PATH],
3206         [Path to the default font]),
3207         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3208             "$withval", [Default monospace font])])
3209
3210 AC_ARG_WITH([default-font-family],
3211     AS_HELP_STRING([--with-default-font-family=NAME],
3212         [Path to the default font family]),
3213         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3214             "$withval", [Default font family])])
3215 AC_ARG_WITH([default-monospace-font-family],
3216     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3217         [Path to the default font family]),
3218         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3219             "$withval", [Default monospace font family])])
3220
3221 have_freetype="no"
3222 have_fontconfig="no"
3223 have_fribidi="no"
3224 have_harfbuzz="no"
3225
3226 if test "${enable_freetype}" != "no"; then
3227    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3228       have_freetype="yes"
3229       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3230       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3231
3232       dnl fontconfig support
3233       if test "${SYS}" != "mingw32"; then
3234           if test "${enable_fontconfig}" != "no"; then
3235             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3236               have_fontconfig="yes"
3237             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3238           fi
3239       fi
3240
3241       dnl fribidi support
3242       if test "${enable_fribidi}" != "no"; then
3243         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3244           have_fribidi="yes"
3245           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3246           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3247         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3248       fi
3249
3250       dnl harfbuzz support
3251       if test "${have_fribidi}" != "no"; then
3252         if test "${enable_harfbuzz}" != "no"; then
3253           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3254             have_harfbuzz="yes"
3255             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3256             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3257           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3258         fi
3259       fi
3260   ],[
3261   AS_IF([test -n "${enable_freetype}"],[
3262     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3263     ])
3264   ])
3265 fi
3266
3267 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3268 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3269 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3270 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3271
3272 dnl
3273 dnl SAPI (text to Speech renderer for Windows)
3274 dnl
3275 AC_LANG_PUSH([C++])
3276 AC_CHECK_TYPES([ISpObjectToken],[
3277               have_sapi="yes"
3278             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3279               [#include <windows.h>
3280                #include <sapi.h>
3281                #include <sphelper.h>])
3282 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3283 AC_LANG_POP([C++])
3284
3285 dnl
3286 dnl  QuartzText vout module (iOS/Mac OS)
3287 dnl
3288 AC_ARG_ENABLE(macosx-quartztext,
3289   [  --enable-macosx-quartztext   Mac OS X quartz text module (default enabled on Mac OS X)])
3290 if test "x${enable_macosx_quartztext}" != "xno" &&
3291   (test "${SYS}" = "darwin" || test "${enable_macosx_quartztext}" = "yes")
3292 then
3293   VLC_ADD_PLUGIN([quartztext])
3294 fi
3295
3296 dnl
3297 dnl  SVG module (text rendering and image decoding)
3298 dnl
3299 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3300 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3301
3302 dnl
3303 dnl  Windows DirectX module
3304 dnl
3305
3306 AC_ARG_ENABLE(directx,
3307   [AS_HELP_STRING([--enable-directx],
3308     [Microsoft DirectX support (default enabled on Windows)])],, [
3309   AS_IF([test "${SYS}" = "mingw32"], [
3310     enable_directx="yes"
3311   ], [
3312     enable_directx="no"
3313   ])
3314 ])
3315 AS_IF([test "${enable_directx}" != "no"], [
3316   dnl DirectDraw
3317   AC_CHECK_HEADERS(ddraw.h, [
3318     VLC_ADD_PLUGIN([directdraw])
3319   ])
3320
3321   dnl OpenGL
3322   AC_CHECK_HEADERS(GL/wglew.h, [
3323     VLC_ADD_PLUGIN([glwin32, wgl])
3324   ],, [
3325     #include <windows.h>
3326     #include <GL/gl.h>
3327   ])
3328
3329   dnl Direct3D11
3330   AC_CHECK_HEADERS(d3d11.h, [
3331     VLC_ADD_PLUGIN([direct3d11])
3332   ])
3333
3334   dnl Direct3D9
3335   AC_CHECK_HEADERS(d3d9.h, [
3336     VLC_ADD_PLUGIN([direct3d9])
3337   ])
3338
3339   dnl Direct2D
3340   AC_CHECK_HEADERS(d2d1.h, [
3341     VLC_ADD_PLUGIN([direct2d])
3342   ])
3343 ])
3344
3345 dnl
3346 dnl  Linux framebuffer module
3347 dnl
3348 AC_CHECK_HEADER([linux/fb.h], [
3349   VLC_ADD_PLUGIN([fb])
3350 ])
3351
3352
3353 dnl
3354 dnl  DirectFB module
3355 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3356 dnl  TODO: support for static linking
3357 dnl
3358 AC_ARG_ENABLE(directfb,
3359   [  --enable-directfb       DirectFB support (default disabled)])
3360 AC_ARG_WITH(directfb,
3361   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3362
3363 if test "${enable_directfb}" = "yes"; then
3364     have_directfb="false"
3365     CPPFLAGS_mydirectfb=
3366     LIBS_mydirectfb=
3367     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3368         dnl Trying the given location
3369         VLC_SAVE_FLAGS
3370
3371         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3372         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3373
3374         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3375         LIBS="${LIBS} ${LIBS_new}"
3376
3377         dnl FIXME: too obscure
3378         AC_CHECK_HEADER([directfb.h], [
3379             AC_CHECK_LIB([direct],[direct_initialize], [
3380                 AC_CHECK_LIB([fusion], [fusion_enter], [
3381                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3382                 ], have_directfb="false")
3383             ], have_directfb="false")
3384         ], have_directfb="false")
3385
3386         VLC_RESTORE_FLAGS
3387
3388         if test "${have_directfb}" = "true"; then
3389             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3390             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3391         fi
3392     else
3393         dnl Look for directfb-config
3394         AC_PATH_PROG(DIRECTFB_CONFIG, directfb-config, no, ${PATH})
3395         if test "${DIRECTFB_CONFIG}" != "no"; then
3396             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3397             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3398             have_directfb="true"
3399         else
3400             dnl Trying with pkg-config
3401             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3402                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3403                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3404                 have_directfb="true"
3405                 ], [have_directfb="false"])
3406         fi
3407     fi
3408     if test "${have_directfb}" = "true"; then
3409         VLC_ADD_PLUGIN([directfb])
3410         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3411         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3412     else
3413         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3414     fi
3415 fi
3416
3417 dnl
3418 dnl  AA plugin
3419 dnl
3420 AC_ARG_ENABLE(aa,
3421   [  --enable-aa             aalib output (default disabled)])
3422 if test "${enable_aa}" = "yes"
3423 then
3424   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3425   if test "${have_aa}" = "true"
3426   then
3427     VLC_ADD_PLUGIN([aa])
3428   fi
3429 fi
3430
3431 dnl
3432 dnl  libcaca plugin
3433 dnl
3434 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3435
3436 dnl
3437 dnl  OS/2 KVA plugin
3438 dnl
3439 AC_ARG_ENABLE(kva,
3440   [AS_HELP_STRING([--enable-kva],
3441     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3442   AS_IF([test "$SYS" = "os2"], [
3443     enable_kva="yes"
3444   ])
3445 ])
3446 have_kva="no"
3447 KVA_LIBS=""
3448 AS_IF([test "$enable_kva" != "no"], [
3449   AC_CHECK_HEADERS([kva.h], [
3450     have_kva="yes"
3451     AC_CHECK_LIB(kva, main, [
3452       KVA_LIBS="-lkva"
3453     ])
3454   ])
3455 ])
3456 AC_SUBST(KVA_LIBS)
3457 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3458
3459 dnl
3460 dnl MMAL plugin
3461 dnl
3462 AC_ARG_ENABLE(mmal,
3463   AS_HELP_STRING([--enable-mmal],
3464     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3465 if test "${enable_mmal}" != "no"; then
3466   VLC_SAVE_FLAGS
3467   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3468   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3469   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3470     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3471         have_mmal="yes"
3472         VLC_ADD_PLUGIN([mmal])
3473         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3474         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3475         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lvchostif ]) ], [
3476           AS_IF([test "${enable_mmal}" = "yes"],
3477             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3478             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3479           ],
3480         [])
3481     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3482       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3483       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3484   VLC_RESTORE_FLAGS
3485 fi
3486 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3487
3488 dnl
3489 dnl evas plugin
3490 dnl
3491 AC_ARG_ENABLE(evas,
3492   [AS_HELP_STRING([--enable-evas],
3493     [use evas output module (default disabled)])])
3494 have_evas="no"
3495 AS_IF([test "${enable_evas}" = "yes"], [
3496   PKG_CHECK_MODULES(EVAS, [evas >= 1.15.99 ecore >= 1.15.99], [
3497       have_evas="yes"
3498       AC_DEFINE([HAVE_EVAS], [1], [Define to 1 if evas is enabled.])
3499     ],[
3500     AS_IF([test "x${enable_evas}" != "x"], [
3501       AC_MSG_ERROR([$EVAS_PKG_ERRORS. libevas and libecore 1.15.99 or later required.])
3502     ])
3503   ])
3504 ])
3505 AM_CONDITIONAL([HAVE_EVAS], [test "${have_evas}" = "yes"])
3506
3507 dnl
3508 dnl  Audio plugins
3509 dnl
3510
3511 EXTEND_HELP_STRING([Audio plugins:])
3512
3513 dnl
3514 dnl  Pulseaudio module
3515 dnl
3516 AC_ARG_ENABLE(pulse,
3517   [AS_HELP_STRING([--enable-pulse],
3518     [use the PulseAudio client library (default auto)])])
3519 have_pulse="no"
3520 AS_IF([test "${enable_pulse}" != "no"], [
3521   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3522     have_pulse="yes"
3523   ], [
3524     AS_IF([test "x${enable_pulse}" != "x"], [
3525       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3526     ])
3527   ])
3528 ])
3529 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3530
3531 dnl
3532 dnl  ALSA module
3533 dnl
3534 AC_ARG_ENABLE(alsa,
3535   [AS_HELP_STRING([--enable-alsa],
3536     [support the Advanced Linux Sound Architecture (default auto)])],, [
3537   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3538     enable_alsa="yes"
3539   ])
3540 ])
3541 have_alsa="no"
3542 AS_IF([test "${enable_alsa}" != "no"], [
3543   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3544     have_alsa="yes"
3545   ], [
3546     AS_IF([test "x${enable_alsa}" != "x"], [
3547       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3548     ])
3549   ])
3550 ])
3551 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3552
3553 dnl
3554 dnl  Open Sound System module
3555 dnl
3556 AC_ARG_ENABLE(oss,
3557   [AS_HELP_STRING([--enable-oss],
3558     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3559   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3560     enable_oss="no"
3561   ])
3562 ])
3563 have_oss="no"
3564 OSS_LIBS=""
3565 AS_IF([test "$enable_oss" != "no"], [
3566   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3567     have_oss="yes"
3568     AC_CHECK_LIB(ossaudio, main, [
3569       OSS_LIBS="-lossaudio"
3570     ])
3571   ])
3572 ])
3573 AC_SUBST(OSS_LIBS)
3574 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3575
3576 dnl
3577 dnl  OpenBSD sndio module
3578 dnl
3579 AC_ARG_ENABLE([sndio],
3580   [AS_HELP_STRING([--disable-sndio],
3581     [support the OpenBSD sndio (default auto)])],, [
3582   AS_IF([test "$SYS" = "openbsd"], [
3583     enable_sndio="yes"
3584   ])
3585 ])
3586 have_sndio="no"
3587 AS_IF([test "$enable_sndio" != "no"], [
3588   AC_CHECK_HEADER([sndio.h], [
3589     have_sndio="yes"
3590   ])
3591 ])
3592 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3593
3594 dnl
3595 dnl  Windows Audio Session plugin
3596 dnl
3597 AC_ARG_ENABLE([wasapi],
3598   [AS_HELP_STRING([--enable-wasapi],
3599     [use the Windows Audio Session API (default auto)])
3600 ])
3601 have_wasapi="no"
3602 AS_IF([test "$enable_wasapi" != "no"], [
3603   AC_CHECK_HEADER([audioclient.h], [
3604     have_wasapi="yes"
3605   ], [
3606     AS_IF([test "x${enable_wasapi}" != "x"], [
3607       AC_MSG_ERROR([Windows Audio Session API not found.])
3608     ])
3609   ])
3610 ])
3611 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3612
3613 dnl
3614 dnl  AudioQueue plugin
3615 dnl
3616 AC_ARG_ENABLE(audioqueue,
3617   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3618 if test "${enable_audioqueue}" = "yes"
3619 then
3620   VLC_ADD_PLUGIN([audioqueue])
3621 fi
3622
3623 dnl
3624 dnl  JACK modules
3625 dnl
3626 AC_ARG_ENABLE(jack,
3627   [AS_HELP_STRING([--disable-jack],
3628     [do not use jack (default auto)])])
3629 have_jack="no"
3630 AS_IF([test "${enable_jack}" != "no"], [
3631     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3632       [ have_jack=yes ],
3633       [
3634       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3635
3636       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3637       [ have_jack=yes ],
3638       [
3639       AS_IF([test -n "${enable_jack}"],
3640          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3641          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3642       ])
3643     ])
3644 ])
3645 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3646
3647 dnl
3648 dnl  OpenSLES Android
3649 dnl
3650 AC_ARG_ENABLE(opensles,
3651   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3652 if test "${HAVE_ANDROID}" = "1"; then
3653   if test "${enable_opensles}" = "yes"; then
3654       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3655         [ VLC_ADD_PLUGIN([opensles_android]) ],
3656         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3657   fi
3658 fi
3659
3660 dnl
3661 dnl  Tizen audio
3662 dnl
3663 AC_ARG_ENABLE(tizen_audio,
3664   [AS_HELP_STRING([--enable-tizen-audio],
3665     [Tizen audio module (default enabled on Tizen)])],, [
3666   AS_IF([test "$HAVE_TIZEN" = "1"], [
3667     enable_tizen_audio="yes"
3668   ])
3669 ])
3670 if test "${enable_tizen_audio}" = "yes"; then
3671   AC_CHECK_HEADERS(audio_io.h,
3672     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3673     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3674 fi
3675
3676 dnl
3677 dnl libsamplerate plugin
3678 dnl
3679 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3680
3681 dnl
3682 dnl  soxr module
3683 dnl
3684 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3685
3686 dnl
3687 dnl  OS/2 KAI plugin
3688 dnl
3689 AC_ARG_ENABLE(kai,
3690   [AS_HELP_STRING([--enable-kai],
3691     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3692   AS_IF([test "$SYS" = "os2"], [
3693     enable_kai="yes"
3694   ])
3695 ])
3696 have_kai="no"
3697 KAI_LIBS=""
3698 AS_IF([test "$enable_kai" != "no"], [
3699   AC_CHECK_HEADERS([kai.h], [
3700     have_kai="yes"
3701     AC_CHECK_LIB(kai, main, [
3702       KAI_LIBS="-lkai"
3703     ])
3704   ])
3705 ])
3706 AC_SUBST(KAI_LIBS)
3707 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3708
3709 dnl
3710 dnl  chromaprint audio track fingerprinter
3711 dnl
3712 m4_pushdef([libchromaprint_version], 0.6.0)
3713 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3714     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3715     AS_IF([test "${enable_chromaprint}" = "yes"],
3716         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3717         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3718          ),
3719     [(Chromaprint based audio fingerprinter)],[auto])
3720 m4_popdef([libchromaprint_version])
3721
3722 dnl
3723 dnl  Chromecast streaming support
3724 dnl
3725 m4_pushdef([protobuf_lite_version], 2.5.0)
3726 AC_ARG_VAR(PROTOC, [protobuf compiler])
3727 AC_CHECK_PROGS(PROTOC, protoc, no)
3728 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3729     AS_IF([test "x${PROTOC}" != "xno"], [
3730         build_chromecast="yes"
3731     ], [
3732     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3733     ])
3734 ], [
3735     AS_IF([test "${enable_chromecast}" = "yes"],
3736         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3737         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3738     )
3739     enable_chromecast="no"
3740 ], [(Chromecast streaming support)], [auto])
3741 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3742 m4_popdef([protobuf_lite_version])
3743
3744 dnl
3745 dnl  Interface plugins
3746 dnl
3747
3748 EXTEND_HELP_STRING([Interface plugins:])
3749
3750 dnl
3751 dnl QT
3752 dnl
3753 AC_ARG_ENABLE(qt, [
3754   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3755   AS_IF([test "${SYS}" = "darwin"], [
3756     enable_qt="no"
3757   ])
3758 ])
3759 AS_IF([test "${enable_qt}" != "no"], [
3760   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.2.0 Qt5Widgets Qt5Gui], [
3761       PKG_CHECK_MODULES([QTX11], [Qt5X11Extras], [
3762           VLC_ADD_LIBS([qt],[${QTX11_LIBS}])
3763           VLC_ADD_CXXFLAGS([qt],[${QTX11_CFLAGS} -DQT5_HAS_X11])
3764           PKG_CHECK_MODULES([XI], [xi], [
3765             VLC_ADD_LIBS([qt], [${XI_LIBS}])
3766             VLC_ADD_CXXFLAGS([qt], [${XI_CFLAGS} -DHAVE_XI])
3767           ], [
3768             PKG_CHECK_EXISTS([Qt5Gui >= 5.5], [
3769               AC_MSG_ERROR([${XI_PKG_ERRORS}.])
3770             ], [
3771               AC_MSG_WARN([${XI_PKG_ERRORS}.])
3772             ])
3773           ])
3774       ],[
3775           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3776       ])
3777       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3778       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3779       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3780       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3781       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3782     ], [
3783       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.8.0],, [
3784         AS_IF([test -n "${enable_qt}"],[
3785           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3786         ],[
3787           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3788         ])
3789         enable_qt="no"
3790       ])
3791       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3792       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3793       AC_PATH_PROG(RCC, rcc, rcc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3794       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3795     ])
3796 ])
3797 AS_IF([test "${enable_qt}" != "no"], [
3798   VLC_ADD_PLUGIN([qt])
3799   ALIASES="${ALIASES} qvlc"
3800 ])
3801 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3802
3803 dnl
3804 dnl detect kde4-config patch (used for kde solids and kwallet).
3805 dnl
3806 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3807 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3808   KDE4_CONFIG="kde4-config"
3809 ])
3810
3811 dnl
3812 dnl Simple test for skins2 dependency
3813 dnl
3814 AS_IF([test "$enable_qt" = "no"], [
3815   AS_IF([test "${enable_skins2}" = "yes"], [
3816     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3817   ], [
3818     enable_skins2="no"
3819     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3820   ])
3821 ])
3822
3823 dnl
3824 dnl Skins2 module
3825 dnl
3826 AC_ARG_ENABLE(skins2,
3827   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3828 AS_IF([test "${enable_skins2}" != "no"], [
3829   have_skins_deps="yes"
3830
3831   dnl Win32
3832   AS_IF([test "${SYS}" = "mingw32"], [
3833     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3834     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3835   dnl MacOS
3836   ], [test "${SYS}" = "darwin"], [
3837     VLC_ADD_CPPFLAGS([skins2],[ -DMACOSX_SKINS])
3838     VLC_ADD_LIBS([skins2],[-Wl,-framework,Carbon])
3839   dnl OS/2
3840   ], [test "${SYS}" = "os2"], [
3841     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3842   dnl Linux/Unix
3843   ], [
3844     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3845     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3846     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3847     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3848     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3849   ])
3850
3851   dnl for All OSes
3852   VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3853
3854   dnl we need freetype
3855   AS_IF([test "${have_freetype}" != "yes"], [
3856     have_skins_deps="no"
3857   ])
3858
3859   AS_IF([test "${have_skins_deps}" = "no"], [
3860     AS_IF([test "x${enable_skins2}" = "x"], [
3861       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3862     ], [
3863       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3864     ])
3865     enable_skins2="no"
3866   ], [
3867     VLC_ADD_PLUGIN([skins2])
3868     ALIASES="${ALIASES} svlc"
3869     enable_skins2="yes"
3870   ])
3871 ])
3872 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3873
3874 AC_ARG_ENABLE(libtar,
3875   [  --enable-libtar         libtar support for skins2 (default auto)])
3876 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3877   AC_CHECK_HEADERS(libtar.h, [
3878     VLC_ADD_LIBS([skins2],[-ltar])
3879   ])
3880 ])
3881
3882 dnl
3883 dnl  MacOS X gui module
3884 dnl
3885 AC_ARG_ENABLE(macosx,
3886   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3887 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3888 then
3889   VLC_ADD_PLUGIN([macosx])
3890
3891   if test ! -d ${CONTRIB_DIR}/BGHUDAppKit.framework
3892   then
3893     AC_MSG_ERROR([BGHUDAppKit framework is required and was not found in ${CONTRIB_DIR}])
3894   fi
3895 fi
3896 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no"])
3897
3898 dnl
3899 dnl  MacOS X sparkle update support
3900 dnl
3901 AC_ARG_ENABLE(sparkle,
3902   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3903 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3904 then
3905   if test ! -d ${CONTRIB_DIR}/Sparkle.framework
3906   then
3907     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3908   fi
3909
3910   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3911 fi
3912 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3913
3914
3915 dnl
3916 dnl  Minimal Mac OS X module
3917 dnl
3918 AC_ARG_ENABLE(minimal-macosx,
3919   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3920 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3921 then
3922   VLC_ADD_PLUGIN([minimal_macosx])
3923 fi
3924
3925 dnl
3926 dnl  VideoToolbox plugins
3927 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3928     VLC_ADD_PLUGIN([videotoolbox])
3929     VLC_ADD_PLUGIN([cvpx_i420])
3930   ])
3931
3932 dnl
3933 dnl  ncurses module
3934 dnl
3935 AC_ARG_ENABLE(ncurses,
3936 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3937 have_ncurses="no"
3938 AS_IF([test "${enable_ncurses}" != "no"] ,[
3939   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3940     have_ncurses="yes"
3941     ALIASES="${ALIASES} nvlc"
3942   ], [
3943     AS_IF([test -n "${enable_ncurses}"], [
3944       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3945     ])
3946   ])
3947 ])
3948 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3949
3950 dnl
3951 dnl  Lirc plugin
3952 dnl
3953 AC_ARG_ENABLE(lirc,
3954   [  --enable-lirc           lirc support (default disabled)])
3955 have_lirc="no"
3956 AS_IF([test "${enable_lirc}" = "yes"], [
3957   AC_CHECK_HEADER(lirc/lirc_client.h, [
3958     AC_CHECK_LIB(lirc_client, lirc_init, [
3959       have_lirc="true"
3960     ])
3961   ])
3962 ])
3963 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3964
3965 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3966 dnl
3967 dnl  goom visualization plugin
3968 dnl
3969 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3970
3971 dnl
3972 dnl libprojectM visualization plugin
3973 dnl
3974 AC_ARG_ENABLE(projectm,
3975   [  --enable-projectm       projectM visualization plugin (default enabled)])
3976 AS_IF([test "${enable_projectm}" != "no"],
3977   [
3978     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3979     [
3980       VLC_ADD_PLUGIN([projectm])
3981       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3982         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3983         [ AC_MSG_WARN( [Using libprojectM version 1] )
3984       ])
3985     ],[
3986       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3987     ])
3988   ])
3989
3990 dnl
3991 dnl Vovoid VSXu visualization plugin
3992 dnl
3993 AC_ARG_ENABLE(vsxu,
3994   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3995 AS_IF([test "${enable_vsxu}" != "no"],
3996   [
3997     PKG_CHECK_MODULES(VSXU, libvsxu,
3998     [
3999       VLC_ADD_PLUGIN([vsxu])
4000     ],[
4001       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
4002     ])
4003   ])
4004
4005 EXTEND_HELP_STRING([Service Discovery plugins:])
4006 dnl
4007 dnl  Avahi-Zeroconf services discovery
4008 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
4009
4010 dnl
4011 dnl  libudev services discovery
4012 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
4013
4014 dnl
4015 dnl MTP devices services discovery
4016 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
4017
4018 dnl
4019 dnl UPnP Plugin (Intel SDK)
4020 dnl
4021 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
4022
4023 dnl
4024 dnl mDNS using libmicrodns
4025 dnl
4026 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
4027
4028
4029 EXTEND_HELP_STRING([Misc options:])
4030
4031 dnl
4032 dnl  libxml2 module
4033 dnl
4034 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4035
4036
4037 dnl
4038 dnl libgcrypt
4039 dnl
4040 AC_ARG_ENABLE(libgcrypt,
4041   [  --disable-libgcrypt     gcrypt support (default enabled)])
4042 # require libgcrypt >= 1.6.0
4043 AS_IF([test "${enable_libgcrypt}" != "no"], [
4044   AC_TRY_COMPILE([
4045 #include <gcrypt.h>
4046 #if GCRYPT_VERSION_NUMBER < 0x010600
4047 #error
4048 #endif],
4049   [], [
4050     have_libgcrypt="yes"
4051     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4052     GCRYPT_CFLAGS="`libgcrypt-config --cflags`"
4053     GCRYPT_LIBS="`libgcrypt-config --libs`"
4054   ], [
4055     AS_IF([test "${enable_libgcrypt}" == "yes"], [
4056       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4057     ])
4058   ])
4059 ])
4060
4061 AC_SUBST(GCRYPT_CFLAGS)
4062 AC_SUBST(GCRYPT_LIBS)
4063 AM_CONDITIONAL([HAVE_GCRYPT], [test "${have_libgcrypt}" = "yes"])
4064
4065 dnl
4066 dnl TLS/SSL
4067 dnl
4068 AC_ARG_ENABLE(gnutls,
4069   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4070 AS_IF([test "${enable_gnutls}" != "no"], [
4071   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.2.0], [
4072     VLC_ADD_PLUGIN([gnutls])
4073   ], [
4074     AS_IF([test -n "${enable_gnutls}"], [
4075       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4076     ])
4077   ])
4078 ])
4079
4080
4081 dnl
4082 dnl Taglib plugin
4083 dnl
4084 AC_ARG_ENABLE(taglib,
4085   [AS_HELP_STRING([--disable-taglib],
4086     [do not use TagLib (default enabled)])])
4087 AS_IF([test "${enable_taglib}" != "no"], [
4088   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4089     VLC_ADD_PLUGIN([taglib])
4090   ], [
4091     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4092 ])
4093
4094 dnl
4095 dnl  libsecret
4096 dnl
4097 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4098
4099 dnl
4100 dnl  Developers helper modules (should be hidden from configure help)
4101 dnl
4102 AC_ARG_ENABLE(devtools, [], [], [enable_devtools="no"])
4103 AS_IF([test "${enable_devtools}" != "no"], [
4104   VLC_ADD_PLUGIN([accesstweaks])
4105 ])
4106
4107 dnl
4108 dnl update checking system
4109 dnl
4110 AC_ARG_ENABLE(update-check,
4111   [  --enable-update-check   update checking system (default disabled)])
4112 if test "${enable_update_check}" = "yes"
4113 then
4114   if test "${have_libgcrypt}" != "yes"
4115   then
4116     AC_MSG_ERROR([libgcrypt is required for update checking system])
4117   fi
4118   VLC_ADD_LIBS([libvlccore], [${GCRYPT_LIBS}])
4119   VLC_ADD_CFLAGS([libvlccore], [${GCRYPT_CFLAGS}])
4120   AC_DEFINE([UPDATE_CHECK], 1, [Define if you want to use the VLC update mechanism])
4121 fi
4122
4123 dnl
4124 dnl OS X notification plugin
4125 dnl
4126 AC_ARG_ENABLE(osx_notifications,
4127   [  --enable-osx-notifications          osx notification plugin (default disabled)],,
4128   [enable_osx_notifications=no])
4129 AS_IF([test "${enable_osx_notifications}" != "no"], [
4130     AC_CHECK_HEADERS(${CONTRIB_DIR}/Growl.framework/Versions/A/Headers/Growl.h, [
4131       VLC_ADD_PLUGIN([osx_notifications])
4132       VLC_ADD_LIBS([osx_notifications], [-F${CONTRIB_DIR} -Wl,-framework,Growl,-framework,Foundation])
4133       VLC_ADD_OBJCFLAGS([osx_notifications], [-F${CONTRIB_DIR}])
4134       VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4135     ])
4136   ]
4137 )
4138
4139 dnl
4140 dnl Libnotify notification plugin
4141 dnl
4142 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4143
4144 dnl
4145 dnl  Endianness check
4146 dnl
4147 AC_C_BIGENDIAN
4148 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4149   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4150 ], [
4151   DEFS_BIGENDIAN=""
4152 ])
4153 AC_SUBST(DEFS_BIGENDIAN)
4154
4155 dnl
4156 dnl Where to install KDE solid .desktop
4157 dnl
4158 AC_ARG_WITH(kde-solid,
4159   AS_HELP_STRING([--with-kde-solid=PATH],
4160                  [KDE Solid actions directory (auto)]),, [
4161
4162 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4163   with_kde_solid="yes"
4164 fi
4165 ])
4166 soliddatadir=""
4167 AS_IF([test "${with_kde_solid}" != "no"], [
4168   AS_IF([test "${with_kde_solid}" = "yes"], [
4169     kde4datadir="`${KDE4_CONFIG} --install data`"
4170     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4171     soliddatadir="${kde4datadir}/solid/actions"
4172   ], [
4173     soliddatadir="${with_kde_solid}"
4174   ])
4175 ])
4176 AC_SUBST(soliddatadir)
4177 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4178
4179 EXTEND_HELP_STRING([Components:])
4180
4181 dnl
4182 dnl  the VLC binary
4183 dnl
4184 AC_ARG_ENABLE(vlc,
4185   [  --enable-vlc            build the VLC media player (default enabled)])
4186 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4187
4188 AC_ARG_ENABLE(macosx-vlc-app,
4189   [  --enable-macosx-vlc-app build the VLC media player (default enabled on Mac OS X)])
4190 AM_CONDITIONAL(BUILD_MACOSX_VLC_APP, [test "${enable_macosx_vlc_app}" != "no" &&
4191     (test "${SYS}" = "darwin" || test "${enable_macosx_vlc_app}" = "yes") ])
4192
4193 dnl
4194 dnl  Stuff used by the program
4195 dnl
4196 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4197 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4198 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4199 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4200 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4201 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4202 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4203 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4204 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4205 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4206 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4207 AC_SUBST(COPYRIGHT_MESSAGE)
4208 AC_SUBST(VERSION_MESSAGE)
4209 AC_SUBST(VERSION_MAJOR)
4210 AC_SUBST(VERSION_MINOR)
4211 AC_SUBST(VERSION_REVISION)
4212 AC_SUBST(VERSION_EXTRA)
4213 AC_SUBST(COPYRIGHT_YEARS)
4214 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4215 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4216 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4217 dnl
4218 dnl  Handle substvars that use $(top_srcdir)
4219 dnl
4220 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4221
4222 dnl
4223 dnl  Configuration is finished
4224 dnl
4225 AC_SUBST(SYS)
4226 AC_SUBST(ARCH)
4227 AC_SUBST(ALIASES)
4228 AC_SUBST(ASM)
4229 AC_SUBST(MOC)
4230 AC_SUBST(RCC)
4231 AC_SUBST(UIC)
4232 AC_SUBST(WINDRES)
4233 AC_SUBST(WINE_SDK_PATH)
4234 AC_SUBST(LIBEXT)
4235 AC_SUBST(AM_CPPFLAGS)
4236 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4237 AC_SUBST(FILE_LIBVLCCORE_DLL)
4238 AC_SUBST(FILE_LIBVLC_DLL)
4239
4240 AC_CONFIG_FILES([
4241   Makefile
4242   doc/Makefile
4243   modules/Makefile
4244   m4/Makefile
4245   po/Makefile.in
4246   share/Makefile
4247   compat/Makefile
4248   src/Makefile
4249   lib/Makefile
4250   bin/Makefile
4251   test/Makefile
4252   modules/gui/macosx/Makefile
4253   modules/gui/qt/Makefile
4254   modules/gui/skins2/Makefile
4255   modules/hw/mmal/Makefile
4256 ])
4257
4258 AM_COND_IF([HAVE_WIN32], [
4259   AC_CONFIG_FILES([
4260     extras/package/win32/NSIS/spad.nsi
4261     extras/package/win32/NSIS/vlc.win32.nsi
4262     extras/package/win32/msi/config.wxi
4263   ])
4264 ])
4265
4266 AM_COND_IF([HAVE_DARWIN], [
4267   AC_CONFIG_FILES([
4268     extras/package/macosx/Info.plist
4269     extras/package/macosx/Resources/English.lproj/InfoPlist.strings
4270   ])
4271 ])
4272
4273 dnl Generate makefiles
4274 AC_OUTPUT
4275
4276 dnl Do we have to use make or gmake ?
4277 if make --version 2>&1|grep -q GNU
4278 then
4279     # GNU make, all seems good
4280     MAKE=make
4281 else
4282     # Known GNU make alias (on BSD)
4283     MAKE=gmake
4284 fi
4285 dnl Shortcut to nice compile message
4286 if test -n $SHELL; then
4287   SHELL=${CONFIG_SHELL-/bin/sh}
4288 fi
4289 rm -f compile
4290 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4291 echo "#! $SHELL
4292 rm -f .error\$\$
4293 ERROR=0
4294 export PATH=\"$PATH\" LANG=C
4295 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4296 test -f .error\$\$ && ERROR=1
4297 rm -f .error\$\$
4298 exit \$ERROR" >compile
4299 chmod a+x compile
4300
4301 echo "
4302 libvlc configuration
4303 --------------------
4304 version               : ${VERSION}
4305 system                : ${SYS}
4306 architecture          : ${ARCH}
4307 optimizations         : ${enable_optimizations}"
4308 if test "${enable_vlc}" != "no"; then
4309 echo "vlc aliases           :${ALIASES}"
4310 else
4311 echo "build vlc executable  : no"
4312 fi
4313 echo "
4314 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."