configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 1999-2017 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 3.0.0-git)
   6 VERSION_MAJOR=3
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=git
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Vetinari"
  17 COPYRIGHT_YEARS="1996-2017"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 AM_SILENT_RULES([yes])
  31 AM_MAINTAINER_MODE([enable])
  32
  33 dnl
  34 dnl Directories
  35 dnl
  36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  37 dnl AC_SUBST(vlcincludedir)
  38 vlcdatadir="\${datadir}/\${PKGDIR}"
  39 AC_SUBST(vlcdatadir)
  40 vlclibdir="\${libdir}/\${PKGDIR}"
  41 AC_SUBST(vlclibdir)
  42
  43 dnl
  44 dnl Check for tools
  45 dnl
  46 AC_PROG_CC_C99
  47 AC_USE_SYSTEM_EXTENSIONS
  48 VLC_PROG_CC_C11
  49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  51 AH_TOP([
  52 #ifndef _REENTRANT
  53 # define _REENTRANT
  54 #endif
  55 ])
  56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  59
  60 AM_PROG_CC_C_O
  61 AC_PROG_CXX
  62 AC_PROG_CPP
  63 AC_PROG_OBJC
  64 _AM_DEPENDENCIES([OBJC])
  65 AC_PROG_EGREP
  66 AC_PROG_MAKE_SET
  67 AC_PROG_INSTALL
  68 AM_PROG_AS
  69
  70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
  73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
  74 AS_IF([test "$BUILDCC" = "false"], [
  75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
  76 ])
  77
  78 dnl Check for compiler properties
  79 AC_C_CONST
  80 AC_C_INLINE
  81 AC_C_RESTRICT
  82 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
  83
  84 dnl Extend the --help string at the current spot.
  85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  86
  87 dnl Allow binary package maintainer to pass a custom string to avoid
  88 dnl cache problem
  89 AC_ARG_WITH(binary-version,
  90     AS_HELP_STRING([--with-binary-version=STRING],
  91          [To avoid plugins cache problem between binary version]),[],[])
  92 AS_IF([test -n "${with_binary_version}"],[
  93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  94          [Binary specific version])
  95 ])
  96
  97 dnl
  98 dnl  Check the operating system
  99 dnl
 100 HAVE_WIN64="0"
 101 HAVE_IOS="0"
 102 HAVE_OSX="0"
 103 HAVE_TVOS="0"
 104
 105 case "${host_os}" in
 106   "")
 107     SYS=unknown
 108     ;;
 109   linux*)
 110     SYS=linux
 111     ;;
 112   bsdi*)
 113     SYS=bsdi
 114     CFLAGS="${CFLAGS} -pthread"
 115     ;;
 116   freebsd*)
 117     SYS=freebsd
 118     CFLAGS="${CFLAGS} -pthread"
 119     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 120     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 121     ac_cv_ld_z_defs=no
 122     ;;
 123   openbsd*)
 124     SYS=openbsd
 125     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 126     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 127     ;;
 128   netbsd*)
 129     SYS=netbsd
 130     ;;
 131   dragonfly*)
 132     SYS=dragonfly
 133     ;;
 134   darwin*)
 135
 136     dnl Force gcc "-arch" flag
 137     ARCH_flag=""
 138     case "${host}" in
 139       i?86*)
 140         ARCH_flag="-arch i386"
 141       ;;
 142       ppc64*)
 143         ARCH_flag="-arch ppc64"
 144       ;;
 145       ppc*)
 146         ARCH_flag="-arch ppc"
 147       ;;
 148       x86_64*)
 149         ARCH_flag="-arch x86_64"
 150       ;;
 151       arm*)
 152         ac_cv_c_bigendian="no"
 153         ac_cv_c_attribute_packed="no"
 154       ;;
 155     esac
 156
 157     SYS=darwin
 158     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 159     CXX="${CXX} -stdlib=libc++ -std=c++11"
 160     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 161     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 162     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
 163     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 164     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 165     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 166
 167     AC_EGREP_CPP(yes,
 168             [#import <TargetConditionals.h>
 169              #if TARGET_OS_IPHONE
 170              yes
 171              #endif],
 172              [HAVE_IOS="1"],
 173              [HAVE_OSX="1"])
 174
 175     AC_EGREP_CPP(yes,
 176             [#import <TargetConditionals.h>
 177              #if TARGET_OS_TV
 178              yes
 179              #endif],
 180              [HAVE_TVOS="1"
 181              HAVE_IOS="0"
 182              HAVE_OSX="0"
 183              ],)
 184
 185     dnl Allow binaries created on Lion to run on earlier releases
 186     AC_EGREP_CPP(yes,
 187            [#import <Cocoa/Cocoa.h>
 188             #ifdef MAC_OS_X_VERSION_10_7
 189             yes
 190             #endif],
 191             [AC_MSG_RESULT([yes])
 192             AC_LIBOBJ([getdelim])
 193             AC_LIBOBJ([strndup])
 194             AC_LIBOBJ([strnlen])],)
 195
 196     dnl
 197     dnl  Handle Mac OS X SDK flags
 198     dnl
 199     AC_ARG_WITH(macosx-sdk,
 200       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 201         [compile using the SDK in DIR])])
 202     if test "${with_macosx_sdk}" != "" ; then
 203         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 204         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 205         CC="${CC} -isysroot ${with_macosx_sdk}"
 206         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 207         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 208         LD="${LD} -syslibroot ${with_macosx_sdk}"
 209     fi
 210     AC_ARG_WITH(macosx-version-min,
 211       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 212         [compile for Mac OS X VERSION and above])])
 213     if test "${with_macosx_version_min}" != "" ; then
 214         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 215         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 216         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 217         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 218         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 219     fi
 220     ;;
 221   *mingw32* | *cygwin* | *wince* | *mingwce*)
 222     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
 223     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
 224     CXXFLAGS="${CXXFLAGS} -static-libgcc"
 225     AC_CHECK_TOOL(WINDRES, windres, :)
 226     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 227     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
 228     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
 229     AH_TOP([#endif])
 230     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 231     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 232     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 233     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 234     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 235     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 236     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 237     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 238     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 239     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 240     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 241
 242     case "${host_os}" in
 243       *mingw32*)
 244         SYS=mingw32
 245         ;;
 246       *cygwin*)
 247         dnl Check if we are using the mno-cygwin mode in which case we are
 248         dnl actually dealing with a mingw32 compiler.
 249         AC_EGREP_CPP(yes,
 250             [#ifdef _WIN32
 251              yes
 252              #endif],
 253             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 254         ;;
 255     esac
 256
 257     if test "${SYS}" = "mingw32"; then
 258         # DEP, ASLR, NO SEH
 259         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 260
 261         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 262         ac_default_prefix="`pwd`/_win32"
 263         DESTDIR="`pwd`/_win32/"
 264
 265         dnl
 266         dnl NSIS/MSI Installer prefix and WIN64
 267         dnl
 268         case "${host}" in
 269             amd64*|x86_64*)
 270                 HAVE_WIN64="1"
 271                 WINDOWS_ARCH="x64"
 272                 PROGRAMFILES="PROGRAMFILES64"
 273                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
 274             ;;
 275             *)
 276                 WINDOWS_ARCH="x86"
 277                 PROGRAMFILES="PROGRAMFILES"
 278             ;;
 279         esac
 280         AC_SUBST(WINDOWS_ARCH)
 281         AC_SUBST(PROGRAMFILES)
 282
 283     fi
 284     ;;
 285   *nto*)
 286     SYS=nto
 287     ;;
 288   solaris*)
 289     SYS=solaris
 290     ;;
 291   hpux*)
 292     SYS=hpux
 293     ;;
 294   *os2*)
 295     SYS=os2
 296     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 297     AC_LIBOBJ([freeaddrinfo])
 298     AC_LIBOBJ([gai_strerror])
 299     ;;
 300   *nacl*)
 301     SYS=nacl
 302     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 303     AC_LIBOBJ([sigwait])
 304     AC_LIBOBJ([recvmsg])
 305     AC_LIBOBJ([sendmsg])
 306     ;;
 307   *)
 308     SYS="${host_os}"
 309     ;;
 310 esac
 311
 312 dnl WinRT
 313 AC_ARG_ENABLE(winstore_app,
 314      AS_HELP_STRING([--enable-winstore-app],
 315                     [Build targetted for Windows Store apps (default disabled)]))
 316
 317 vlc_winstore_app=0
 318 AS_IF([test "${SYS}" = "mingw32"],[
 319   LIBCOM="-lole32"
 320   AS_IF([test "${enable_winstore_app}" = "yes"], [
 321     vlc_winstore_app=1
 322     LIBCOM=""
 323      VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
 324      AC_LIBOBJ([gai_strerror])
 325     ],[])
 326   AC_SUBST(LIBCOM)
 327   ])
 328 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 329
 330 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 331 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 332
 333 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 334 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
 335 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
 336 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
 337
 338 AM_CONDITIONAL(HAVE_NACL,    test "${SYS}" = "nacl")
 339
 340 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 341 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
 342 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 343 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
 344
 345 dnl
 346 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 347 dnl for program foo on win32
 348 case "${build_os}" in
 349     cygwin|msys|mingw32)
 350         ac_executable_extensions=".exe"
 351         BUILDEXEEXT=".exe"
 352     ;;
 353     os2*)
 354         BUILDEXEEXT=".exe"
 355     ;;
 356     *)
 357     ;;
 358 esac
 359 AC_SUBST(BUILDEXEEXT)
 360
 361 dnl Android is linux, but a bit different
 362 AS_IF([test "$SYS" = linux],[
 363     AC_MSG_CHECKING([for an Android system])
 364     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 365         [[#ifndef __ANDROID__
 366          # error Not Android
 367          #endif
 368         ]],[[;]])
 369     ],[
 370       HAVE_ANDROID="1"
 371       AC_MSG_RESULT([yes])
 372     ],[
 373       AC_MSG_RESULT([no])
 374     ])
 375 ])
 376 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 377
 378 dnl Tizen (minimum SDK version: 2.3)
 379 AS_IF([test "$SYS" = linux],[
 380     AC_MSG_CHECKING([for Tizen])
 381     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 382         [[#include <tizen.h>
 383         ]],[[;]])
 384     ],[
 385       HAVE_TIZEN="1"
 386       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
 387       AC_MSG_RESULT([yes])
 388     ],[
 389       AC_MSG_RESULT([no])
 390     ])
 391 ])
 392 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
 393
 394 dnl
 395 dnl  Check for the contrib directory
 396 dnl
 397 AC_ARG_WITH(contrib,
 398   [AS_HELP_STRING([--with-contrib[=DIR]],
 399     [search for 3rd party libraries in DIR/include and DIR/lib])
 400 ])
 401 AC_MSG_CHECKING([for 3rd party libraries path])
 402 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 403   CONTRIB_DIR="${srcdir}/contrib/${host}"
 404   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 405     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 406     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 407     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 408       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 409       CONTRIB_DIR=""
 410       AC_MSG_RESULT([not found])
 411     ])
 412   ])
 413 ], [
 414   AS_IF([test "${with_contrib}" != "no"], [
 415     CONTRIB_DIR="${with_contrib}"
 416   ], [
 417     CONTRIB_DIR=""
 418     AC_MSG_RESULT([disabled])
 419   ])
 420 ])
 421 AS_IF([test -n "${CONTRIB_DIR}"], [
 422   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 423     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 424   ], [
 425     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 426     CONTRIB_DIR=""
 427     AC_MSG_RESULT([not usable])
 428   ])
 429
 430 ])
 431 AS_IF([test -n "${CONTRIB_DIR}"], [
 432   AC_MSG_RESULT([${CONTRIB_DIR}])
 433   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 434   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 435   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 436   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
 437   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 438   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 439
 440   AS_IF([test -z "$LUAC"], [
 441     dnl Old contribs mixed cross-tools and cross-compiled executables
 442     AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
 443       LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
 444     ])
 445
 446     dnl Newer contribs follow usual name space rules
 447     AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
 448       LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
 449     ])
 450   ])
 451
 452   AS_IF([test "${SYS}" = "darwin"], [
 453     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 454     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 455   ])
 456 ], [
 457   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 458     AC_MSG_ERROR([Third party libraries not found!])
 459   ])
 460 ])
 461 AC_SUBST(CONTRIB_DIR)
 462
 463 dnl Add extras/tools to the PATH
 464 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 465 AS_IF([test -d "${TOOLS_DIR}"], [
 466     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 467     export PATH="${TOOLS_DIR}":$PATH
 468 ])
 469
 470 dnl
 471 dnl  Libtool
 472 dnl  It's very bad, but our former custom system was worst
 473 dnl  -- Courmisch
 474 dnl
 475
 476 dnl override platform specific check for dependent libraries
 477 dnl otherwise libtool linking of shared libraries will
 478 dnl fail on anything other than pass_all.
 479 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 480     [lt_cv_deplibs_check_method=pass_all])
 481
 482 LT_INIT([dlopen win32-dll shared disable-static])
 483 LT_LANG([C++])
 484 LT_LANG([Windows Resource])
 485
 486 DOLT
 487
 488 lt_cv_deplibs_check_method=pass_all
 489
 490 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 491   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 492 ])
 493
 494 dnl
 495 dnl Gettext stuff
 496 dnl
 497 AM_GNU_GETTEXT_VERSION([0.19.8])
 498 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 499
 500 dnl
 501 dnl Iconv stuff
 502 dnl
 503 AM_ICONV
 504
 505 dnl
 506 dnl checks for mingw
 507 AS_IF([test "${SYS}" = "mingw32"], [
 508
 509 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 510 #if !defined(__MINGW32__)
 511 # error Not compiling with mingw
 512 #endif
 513     ])], [
 514
 515 dnl Check for broken versions of mingw-runtime compatability library
 516     AC_MSG_CHECKING(for broken mingw-runtime)
 517     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 518 #include <_mingw.h>
 519 #if defined(__MINGW64_VERSION_MAJOR)
 520 # if __MINGW64_VERSION_MAJOR < 3
 521 #  error Attempting to use mingw-runtime with broken vsnprintf support
 522 # endif
 523 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
 524 # error Attempting to use mingw-runtime with broken vsnprintf support
 525 #endif
 526     ])], [
 527         AC_MSG_RESULT([ok])
 528     ], [
 529         AC_MSG_RESULT([present])
 530         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
 531     ])
 532
 533     dnl force use of mingw provided c99 *printf over msvcrt
 534     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 535
 536     dnl Add WinMainCRTStartup entry point to show it's a WinMain application
 537     VLC_ADD_LDFLAGS([vlc],[-mwindows])
 538
 539     dnl Check for the need to include the mingwex lib for mingw32
 540     VLC_SAVE_FLAGS
 541     AC_CHECK_LIB(mingwex,opendir,
 542         AC_CHECK_LIB(mingw32,opendir,,
 543             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 544     )
 545     VLC_RESTORE_FLAGS
 546     ], [
 547         AC_MSG_RESULT([Not compiling with mingw])
 548     ])
 549
 550     dnl Check for fnative-struct or mms-bitfields support for mingw32
 551     VLC_SAVE_FLAGS
 552     CFLAGS="${CFLAGS} -mms-bitfields"
 553     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
 554     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 555         [ac_cv_c_mms_bitfields],
 556         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 557     if test "${ac_cv_c_mms_bitfields}" = "no"; then
 558         VLC_RESTORE_FLAGS
 559         CFLAGS="${CFLAGS} -fnative-struct"
 560         CXXFLAGS="${CXXFLAGS} -fnative-struct"
 561         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 562             [ac_cv_c_fnative_struct],
 563             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 564         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
 565     fi
 566 ])
 567
 568
 569 dnl
 570 dnl Buggy glibc prevention. Purposedly not cached.
 571 dnl See sourceware.org bugs 5058 and 5443.
 572 dnl Ubuntu alone has 20 bug numbers for this...
 573 dnl
 574 AC_MSG_CHECKING(for buggy GNU/libc versions)
 575 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 576 #include <limits.h>
 577 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 578   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 579 # error GNU/libc with dcgettext killer bug!
 580 #endif
 581 ])], [
 582   AC_MSG_RESULT([not present])
 583 ], [
 584   AC_MSG_RESULT([found])
 585   AS_IF([test "x${enable_nls}" != "xno"], [
 586     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 587 work-around for this. Check with your distribution vendor on how to update the
 588 glibc run-time. Alternatively, build with --disable-nls.])
 589   ])
 590 ])
 591
 592 dnl Plugin compilation stuff
 593
 594 VLC_LIBRARY_SUFFIX
 595
 596 dnl Check for system libs needed
 597 need_libc=false
 598
 599 dnl Check for usual libc functions
 600 AC_CHECK_FUNCS([daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp strptime tdestroy uselocale])
 601 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv memrchr nrand48 poll recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tfind timegm timespec_get strverscmp pathconf])
 602 AC_REPLACE_FUNCS([gettimeofday])
 603 AC_CHECK_FUNC(fdatasync,,
 604   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 605 ])
 606
 607 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
 608
 609 dnl mingw64 implements those as static inline, not functions with C linkage
 610 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
 611 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
 612 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
 613 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
 614
 615 dnl C11 static_assert()
 616 AC_MSG_CHECKING([for static_assert in assert.h])
 617 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 618 static_assert(1, "The impossible happened.");
 619 ])], [
 620   AC_MSG_RESULT([yes])
 621   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 622 ], [
 623   AC_MSG_RESULT([no])
 624 ])
 625
 626 # Windows CE does not have strcoll()
 627 AC_FUNC_STRCOLL
 628
 629 dnl Check for non-standard system calls
 630 case "$SYS" in
 631   "linux")
 632     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity recvmmsg])
 633     ;;
 634   "mingw32")
 635     AC_CHECK_FUNCS([_lock_file])
 636     ;;
 637 esac
 638
 639 AH_BOTTOM([#include <vlc_fixups.h>])
 640
 641 dnl Check for struct pollfd
 642 AC_CHECK_TYPES([struct pollfd],,,
 643 [#include <sys/types.h>
 644 #if HAVE_POLL
 645 # include <poll.h>
 646 #elif defined (_WIN32)
 647 # include <winsock2.h>
 648 #endif
 649 ])
 650
 651 dnl Check for struct timespec
 652 AC_CHECK_TYPES([struct timespec],,,
 653 [#include <time.h>])
 654
 655 dnl Check for max_align_t
 656 AC_CHECK_TYPES([max_align_t],,,
 657 [#include <stddef.h>])
 658
 659 dnl Checks for socket stuff
 660 VLC_SAVE_FLAGS
 661 SOCKET_LIBS=""
 662 AC_SEARCH_LIBS(connect, [socket], [
 663   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 664     SOCKET_LIBS="$ac_cv_search_connect"
 665   ])
 666 ], [
 667   AS_IF([test "${SYS}" = "mingw32"], [
 668     SOCKET_LIBS="-lws2_32"
 669   ])
 670 ])
 671
 672 AC_SEARCH_LIBS([inet_pton], [nsl], [
 673  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
 674     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
 675   ])
 676 ],, [${SOCKET_LIBS}])
 677
 678 LIBS="${LIBS} ${SOCKET_LIBS}"
 679 AC_LINK_IFELSE([
 680     AC_LANG_PROGRAM([#ifdef _WIN32
 681         # if _WIN32_WINNT < 0x600
 682         #  error Needs vista+
 683         # endif
 684         #include <ws2tcpip.h>
 685         #else
 686         #include <sys/socket.h>
 687         #include <arpa/inet.h>
 688         #endif], [
 689         char dst[[sizeof(struct in_addr)]];
 690         inet_pton(AF_INET, "127.0.0.1", dst);
 691     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 692 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
 693 VLC_RESTORE_FLAGS
 694 AC_SUBST(SOCKET_LIBS)
 695
 696 dnl Check for socklen_t
 697 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 698 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 699 ac_cv_type_socklen_t,
 700 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 701 [#include <sys/types.h>
 702 #ifdef _WIN32
 703 # include <winsock2.h>
 704 # include <ws2tcpip.h>
 705 #else
 706 # include <sys/socket.h>
 707 #endif]], [[socklen_t len; len = 0;]])],
 708 ac_cv_type_socklen_t=yes,
 709 ac_cv_type_socklen_t=no)])
 710 AS_IF([test "$ac_cv_type_socklen_t" = no],
 711  [AC_DEFINE(socklen_t, int)])
 712
 713 dnl Check for struct sockaddr_storage
 714 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 715 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 716 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 717   [AC_TRY_COMPILE(
 718     [#include <sys/types.h>
 719      #if defined( _WIN32 )
 720      # include <winsock2.h>
 721      #else
 722      # include <sys/socket.h>
 723      #endif], [struct sockaddr_storage addr;],
 724      ac_cv_struct_sockaddr_storage=yes,
 725      ac_cv_struct_sockaddr_storage=no)])
 726 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 727   AC_DEFINE(sockaddr_storage, sockaddr)
 728   AC_DEFINE(ss_family, sa_family)
 729 ])
 730
 731 dnl FreeBSD has a gnugetopt library for this:
 732 GNUGETOPT_LIBS=""
 733 AC_CHECK_FUNC(getopt_long,, [
 734   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 735     GNUGETOPT_LIBS="-lgnugetopt"
 736   ])
 737 ])
 738 AC_SUBST(GNUGETOPT_LIBS)
 739
 740 AC_CHECK_LIB(m,cos,[
 741   LIBM="-lm"
 742 ], [
 743   LIBM=""
 744 ])
 745 AC_SUBST(LIBM)
 746
 747 AC_CHECK_LIB(m,lrintf, [
 748   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 749   VLC_ADD_LIBS([skins2],[-lm])
 750 ])
 751 AC_CHECK_LIB(m,nanf,
 752   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 753 )
 754 AC_CHECK_LIB(m,sincos, [
 755   AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
 756 ], [
 757   AC_LIBOBJ([sincos])
 758 ])
 759
 760 AC_MSG_CHECKING([_Thread_local support])
 761 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
 762                    int main() {}])], [
 763     AC_MSG_RESULT([ok])
 764     AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
 765 ],[ AC_MSG_RESULT([no])])
 766
 767 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
 768 dnl check for its availability explicitely
 769 AC_CHECK_HEADERS([threads.h])
 770
 771 dnl Check for dynamic plugins
 772 LIBDL=""
 773 have_dynamic_objects="no"
 774 VLC_SAVE_FLAGS
 775 AC_SEARCH_LIBS(dlsym, [dl svld], [
 776   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 777     LIBDL="$ac_cv_search_dlsym"
 778   ])
 779   have_dynamic_objects="yes"
 780 ])
 781 VLC_RESTORE_FLAGS
 782
 783 # Windows
 784 AS_IF([test "${SYS}" = "mingw32"], [
 785   LIBDL=""
 786   have_dynamic_objects="yes" #assume we can use shared objects
 787 ])
 788
 789 AS_IF([test "${enable_shared}" = "no"], [
 790   have_dynamic_objects=no
 791 ])
 792 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 793
 794 AC_SUBST(LIBDL)
 795
 796 dnl Check for thread library
 797 LIBPTHREAD=""
 798 AS_IF([test "${SYS}" != "mingw32"], [
 799   VLC_SAVE_FLAGS
 800   LIBS=""
 801   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 802     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 803       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 804     ])
 805   ])
 806   VLC_RESTORE_FLAGS
 807 ])
 808 AC_SUBST(LIBPTHREAD)
 809
 810 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
 811   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
 812     LIBRT="$ac_cv_search_clock_nanosleep"
 813   ])
 814 ], [
 815   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
 816     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
 817       LIBRT="$ac_cv_search_nanosleep"
 818     ])
 819   ])
 820 ])
 821 AC_SUBST(LIBRT)
 822
 823 dnl
 824 dnl Check for headers
 825 dnl
 826
 827 dnl  POSIX
 828 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
 829 AC_CHECK_HEADERS([net/if.h], [], [],
 830 [
 831 #include <sys/types.h>
 832 #include <sys/socket.h>
 833 ])
 834 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
 835 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
 836
 837 dnl  BSD
 838 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
 839
 840 dnl  GNU/Linux
 841 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 842
 843 dnl  MacOS
 844 AC_CHECK_HEADERS([xlocale.h])
 845
 846 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 847 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 848 AC_CHECK_TYPE(ssize_t,, [
 849   AC_DEFINE(ssize_t, int)
 850 ])
 851
 852 dnl It seems that autoconf detects pkg-config only during the first
 853 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 854 dnl it is nested within a conditional block, so it was not working right.
 855 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 856 AC_ARG_VAR(PKG_CONFIG_PATH,
 857        [Paths where to find .pc not at the default location])
 858 PKG_PROG_PKG_CONFIG()
 859
 860 dnl On some OS we need static linking
 861 AS_IF([test -n "${PKG_CONFIG}" ],[
 862     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 863         PKG_CONFIG="${PKG_CONFIG} --static"
 864     ])
 865 ])
 866
 867
 868 dnl
 869 dnl Check for zlib.h and -lz along with system -lminizip if available
 870 dnl
 871 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 872 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 873 if test "${have_zlib}" = "yes"
 874 then
 875   VLC_ADD_LIBS([sap],[-lz])
 876   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 877     AC_CHECK_HEADERS([unzip.h], [
 878       have_minizip=yes
 879       MINIZIP_LIBS="-lminizip -lz"
 880     ], [
 881       have_minizip=no
 882     ])
 883   ])
 884 fi
 885 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 886
 887
 888 dnl
 889 dnl Domain name i18n support via GNU libidn
 890 dnl
 891 PKG_CHECK_MODULES([IDN], [libidn], [
 892   have_libidn="yes"
 893   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 894 ], [
 895   have_libidn="no"
 896 ])
 897
 898
 899 dnl Check for dbus
 900 AC_ARG_ENABLE(dbus,
 901   [AS_HELP_STRING([--enable-dbus],
 902     [compile D-Bus message bus support (default enabled)])])
 903 have_dbus="no"
 904 AS_IF([test "${enable_dbus}" != "no"], [
 905   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 906     have_dbus="yes"
 907   ], [
 908     AS_IF([test -n "${enable_dbus}"], [
 909       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 910     ], [
 911       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 912     ])
 913   ])
 914 ])
 915 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 916
 917
 918 dnl Check for systemd
 919 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
 920   have_systemd="yes"
 921 ], [
 922   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
 923 ])
 924 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
 925
 926
 927 dnl Check for ntohl, etc.
 928 VLC_SAVE_FLAGS
 929 CFLAGS="${CFLAGS} -Wall -Werror"
 930 AC_CACHE_CHECK([for ntohl in sys/param.h],
 931     [ac_cv_c_ntohl_sys_param_h],
 932     [     AC_TRY_COMPILE([#include <sys/param.h>],
 933         [int meuh; ntohl(meuh);],
 934         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
 935 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
 936     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
 937 fi
 938 VLC_RESTORE_FLAGS
 939
 940 EXTEND_HELP_STRING([Optimization options:])
 941 dnl
 942 dnl  Compiler warnings
 943 dnl
 944
 945 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration init-self logical-op format-security shadow=local])
 946 RDC_PROG_CC_FLAGS([-pipe])
 947 AC_LANG_PUSH([C++])
 948 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var format-security])
 949 AC_LANG_POP([C++])
 950
 951 dnl
 952 dnl  Debugging mode
 953 dnl
 954 AC_ARG_ENABLE(debug,
 955   [AS_HELP_STRING([--enable-debug],
 956     [build with run-time assertions (default disabled)])],,
 957   [enable_debug="no"])
 958 AH_TEMPLATE(NDEBUG,
 959             [Define to 1 if debug code should NOT be compiled])
 960 AS_IF([test "${enable_debug}" != "no"], [
 961   AC_CHECK_HEADERS([valgrind/valgrind.h])
 962 ], [
 963   AC_DEFINE(NDEBUG)
 964 ])
 965
 966 dnl
 967 dnl  Profiling
 968 dnl
 969 AC_ARG_ENABLE(gprof,
 970   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 971   [enable_gprof="no"])
 972 AS_IF([test "${enable_gprof}" != "no"], [
 973   CFLAGS="${CFLAGS} -pg"
 974   CXXFLAGS="${CXXFLAGS} -pg"
 975   OBJCFLAGS="${OBJCFLAGS} -pg"
 976   LDFLAGS="${LDFLAGS} -pg"
 977 ])
 978
 979 AC_ARG_ENABLE(cprof,
 980   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 981   [enable_cprof="no"])
 982 AS_IF([test "${enable_gprof}" != "no"], [
 983   CFLAGS="${CFLAGS} -finstrument-functions"
 984   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 985   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 986   LDFLAGS="${LDFLAGS} -finstrument-functions"
 987 ])
 988
 989 dnl
 990 dnl  Test coverage
 991 dnl
 992 AC_ARG_ENABLE(coverage,
 993   [AS_HELP_STRING([--enable-coverage],
 994     [build for test coverage (default disabled)])],,
 995   [enable_coverage="no"])
 996 AS_IF([test "${enable_coverage}" != "no"], [
 997   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 998   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 999   LDFLAGS="-lgcov ${LDFLAGS}"
1000 ])
1001
1002 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
1003   VLC_SAVE_FLAGS
1004   CFLAGS="${CFLAGS} -fvisibility=hidden"
1005   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
1006   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
1007   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
1008                  [ac_cv_c_visibility_hidden], [
1009     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1010       ac_cv_c_visibility_hidden=yes
1011     ], [
1012       ac_cv_c_visibility_hidden=no
1013     ])
1014   ])
1015   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1016 ])
1017
1018
1019 dnl
1020 dnl  Enable/disable optimizations
1021 dnl
1022 AC_ARG_ENABLE(optimizations,
1023   [AS_HELP_STRING([--disable-optimizations],
1024     [disable compiler optimizations (default enabled)])],,
1025   [enable_optimizations="yes"])
1026
1027 dnl Check for various optimization flags
1028 AS_IF([test "${enable_optimizations}" != "no"], [
1029
1030   dnl -O3 only in production builds
1031   AS_IF([test "${enable_debug}" = "no"], [
1032     VLC_SAVE_FLAGS
1033     CFLAGS="${CFLAGS} -O3"
1034     CXXFLAGS="${CXXFLAGS} -O3"
1035     OBJCFLAGS="${OBJCFLAGS} -O3"
1036     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1037       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1038         ac_cv_c_o3=yes
1039       ], [
1040         ac_cv_c_o3=no
1041       ])
1042     ])
1043     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1044   ])
1045
1046   dnl Check for fast maths
1047   RDC_PROG_CC_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1048   AC_LANG_PUSH(C++)
1049   RDC_PROG_CXX_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1050   AC_LANG_POP
1051
1052 AH_BOTTOM([
1053 #if defined(_MSC_VER) && !defined(__clang__)
1054 # pragma fenv_access(off)
1055 # pragma fp_contract(on)
1056 #elif defined(__GNUC__)
1057 /* Not supported so far */
1058 #else
1059 # pragma STDC FENV_ACCESS OFF
1060 # pragma STDC FP_CONTRACT ON
1061 #endif
1062 ])
1063
1064   dnl Check for -funroll-loops
1065   VLC_SAVE_FLAGS
1066   CFLAGS="${CFLAGS} -funroll-loops"
1067   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1068   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1069   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1070     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1071       ac_cv_c_unroll_loops=yes
1072     ], [
1073       ac_cv_c_unroll_loops=no
1074     ])
1075   ])
1076   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1077
1078   AS_IF([test "$enable_debug" = "no"], [
1079     dnl Check for -fomit-frame-pointer
1080     VLC_SAVE_FLAGS
1081     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1082     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1083     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1084     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1085       [ac_cv_c_omit_frame_pointer], [
1086       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1087         ac_cv_c_omit_frame_pointer=yes
1088       ], [
1089         ac_cv_c_omit_frame_pointer=no
1090       ])
1091     ])
1092     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1093   ])
1094 ])
1095
1096 VLC_SAVE_FLAGS
1097 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1098 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1099   AC_TRY_LINK([],, [
1100     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1101   ], [
1102     ac_cv_ld_bsymbolic=""
1103   ])
1104 ])
1105 VLC_RESTORE_FLAGS
1106 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1107 AC_SUBST(SYMBOLIC_LDFLAGS)
1108
1109 VLC_SAVE_FLAGS
1110 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1111 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1112   AC_TRY_LINK([],, [
1113     ac_cv_ld_z_defs="yes"
1114   ], [
1115     ac_cv_ld_z_defs="no"
1116   ])
1117 ])
1118 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1119
1120 dnl Check for __attribute__((packed))
1121 AC_CACHE_CHECK([for __attribute__((packed))],
1122   [ac_cv_c_attribute_packed],
1123   [ac_cv_c_attribute_packed=no
1124    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1125                     [ac_cv_c_attribute_packed=yes])])
1126 if test "${ac_cv_c_attribute_packed}" != "no"; then
1127   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1128 fi
1129
1130 dnl
1131 dnl  Check the CPU
1132 dnl
1133 case "${host_cpu}" in
1134   "")
1135     ARCH=unknown
1136     ;;
1137   *)
1138     ARCH="${host_cpu}"
1139     ;;
1140 esac
1141
1142 dnl Check for backtrace() support
1143 AC_CHECK_HEADERS(execinfo.h)
1144 AC_CHECK_FUNCS(backtrace)
1145
1146 dnl
1147 dnl  default modules
1148 dnl
1149 ALIASES="${ALIASES} cvlc rvlc"
1150
1151 dnl
1152 dnl  Accelerated modules
1153 dnl
1154
1155 dnl  Check for fully working MMX intrinsics
1156 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1157 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1158 AC_ARG_ENABLE(mmx,
1159   [AS_HELP_STRING([--disable-mmx],
1160     [disable MMX optimizations (default auto)])],,[
1161   case "${host_cpu}" in
1162     i?86|x86_64)
1163       enable_mmx="yes"
1164       ;;
1165     *)
1166       enable_mmx="no"
1167       ;;
1168   esac
1169 ])
1170 have_mmx="no"
1171 have_mmxext="no"
1172 AS_IF([test "${enable_mmx}" != "no"], [
1173   ARCH="${ARCH} mmx"
1174   VLC_SAVE_FLAGS
1175   CFLAGS="${CFLAGS} -mmmx"
1176   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1177     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1178 [#include <mmintrin.h>
1179 #include <stdint.h>
1180 uint64_t frobzor;]], [
1181 [__m64 a, b, c;
1182 a = b = c = (__m64)frobzor;
1183 a = _mm_slli_pi16(a, 3);
1184 a = _mm_adds_pi16(a, b);
1185 c = _mm_srli_pi16(c, 8);
1186 c = _mm_slli_pi16(c, 3);
1187 b = _mm_adds_pi16(b, c);
1188 a = _mm_unpacklo_pi8(a, b);
1189 frobzor = (uint64_t)a;]])], [
1190       ac_cv_c_mmx_intrinsics=yes
1191     ], [
1192       ac_cv_c_mmx_intrinsics=no
1193     ])
1194   ])
1195   VLC_RESTORE_FLAGS
1196   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1197     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1198   ])
1199
1200   VLC_SAVE_FLAGS
1201   CFLAGS="${CFLAGS} -mmmx"
1202   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1203     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1204 void *p;
1205 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1206 ]])
1207     ], [
1208       ac_cv_mmx_inline=yes
1209     ], [
1210       ac_cv_mmx_inline=no
1211     ])
1212   ])
1213   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1214     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1215     have_mmx="yes"
1216   ])
1217
1218   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1219                  [ac_cv_mmxext_inline], [
1220     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1221 void *p;
1222 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1223 ]])
1224     ], [
1225       ac_cv_mmxext_inline=yes
1226     ], [
1227       ac_cv_mmxext_inline=no
1228     ])
1229   ])
1230   VLC_RESTORE_FLAGS
1231   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1232     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1233     have_mmxext="yes"
1234   ])
1235 ])
1236 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1237 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1238
1239 dnl  Check for fully workin SSE2 intrinsics
1240 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1241 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1242 AC_ARG_ENABLE(sse,
1243   [AS_HELP_STRING([--disable-sse],
1244     [disable SSE (1-4) optimizations (default auto)])],, [
1245   case "${host_cpu}" in
1246     i?86|x86_64)
1247       enable_sse=yes
1248       ;;
1249     *)
1250       enable_sse=no
1251       ;;
1252   esac
1253 ])
1254 have_sse2="no"
1255 AS_IF([test "${enable_sse}" != "no"], [
1256   ARCH="${ARCH} sse sse2"
1257
1258   VLC_SAVE_FLAGS
1259   CFLAGS="${CFLAGS} -msse2"
1260   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1261     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1262 [#include <emmintrin.h>
1263 #include <stdint.h>
1264 uint64_t frobzor;]], [
1265 [__m128i a, b, c;
1266 a = b = c = _mm_set1_epi64((__m64)frobzor);
1267 a = _mm_slli_epi16(a, 3);
1268 a = _mm_adds_epi16(a, b);
1269 c = _mm_srli_epi16(c, 8);
1270 c = _mm_slli_epi16(c, 3);
1271 b = _mm_adds_epi16(b, c);
1272 a = _mm_unpacklo_epi8(a, b);
1273 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1274       ac_cv_c_sse2_intrinsics=yes
1275     ], [
1276       ac_cv_c_sse2_intrinsics=no
1277     ])
1278   ])
1279   VLC_RESTORE_FLAGS
1280   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1281     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1282   ])
1283
1284   VLC_SAVE_FLAGS
1285   CFLAGS="${CFLAGS} -msse"
1286   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1287     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1288 void *p;
1289 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1290 ]])
1291     ], [
1292       ac_cv_sse_inline=yes
1293     ], [
1294       ac_cv_sse_inline=no
1295     ])
1296   ])
1297
1298   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1299     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1300   ])
1301
1302   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1303     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1304 void *p;
1305 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1306 ]])
1307     ], [
1308       ac_cv_sse2_inline=yes
1309     ], [
1310       ac_cv_sse2_inline=no
1311     ])
1312   ])
1313   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1314     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1315     have_sse2="yes"
1316   ])
1317
1318   # SSE3
1319   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1320     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1321 void *p;
1322 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1323 ]])
1324     ], [
1325       ac_cv_sse3_inline=yes
1326     ], [
1327       ac_cv_sse3_inline=no
1328     ])
1329   ])
1330
1331   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1332     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1333   # SSSE3
1334   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1335     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1336 void *p;
1337 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1338 ]])
1339     ], [
1340       ac_cv_ssse3_inline=yes
1341     ], [
1342       ac_cv_ssse3_inline=no
1343     ])
1344   ])
1345
1346   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1347     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1348
1349   # SSE4.1
1350   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1351                  [ac_cv_sse4_1_inline], [
1352     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1353 void *p;
1354 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1355 ]])
1356     ], [
1357       ac_cv_sse4_1_inline=yes
1358     ], [
1359       ac_cv_sse4_1_inline=no
1360     ])
1361   ])
1362
1363   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1364     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1365
1366   # SSE4.2
1367   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1368                  [ac_cv_sse4_2_inline], [
1369     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1370 void *p;
1371 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1372 ]])
1373     ], [
1374       ac_cv_sse4_2_inline=yes
1375     ], [
1376       ac_cv_sse4_2_inline=no
1377     ])
1378   ])
1379
1380   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1381     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1382
1383   # SSE4A
1384   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1385     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1386 void *p;
1387 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1388 ]])
1389     ], [
1390       ac_cv_sse4a_inline=yes
1391     ], [
1392       ac_cv_sse4a_inline=no
1393     ])
1394   ])
1395   VLC_RESTORE_FLAGS
1396   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1397     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1398 ])
1399 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1400
1401 VLC_SAVE_FLAGS
1402 CFLAGS="${CFLAGS} -mmmx"
1403 have_3dnow="no"
1404 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1405   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1406 void *p;
1407 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1408 ]])
1409   ], [
1410     ac_cv_3dnow_inline=yes
1411   ], [
1412     ac_cv_3dnow_inline=no
1413   ])
1414 ])
1415 VLC_RESTORE_FLAGS
1416 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1417   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1418             [Define to 1 if 3D Now! inline assembly is available.])
1419   have_3dnow="yes"
1420 ])
1421 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1422
1423
1424 AC_ARG_ENABLE(neon,
1425   [AS_HELP_STRING([--disable-neon],
1426     [disable NEON optimizations (default auto)])],, [
1427   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1428 ])
1429 AS_IF([test "${enable_neon}" != "no"], [
1430   VLC_SAVE_FLAGS
1431   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1432   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1433     AC_COMPILE_IFELSE([
1434       AC_LANG_PROGRAM(,[[
1435 asm volatile("vqmovun.s64 d0, q1":::"d0");
1436 ]])
1437     ], [
1438       ac_cv_arm_neon="yes"
1439     ], [
1440       ac_cv_arm_neon="no"
1441     ])
1442   ])
1443   VLC_RESTORE_FLAGS
1444 ])
1445 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1446
1447 AC_ARG_ENABLE(arm64,
1448   [AS_HELP_STRING([--disable-arm64],
1449     [disable arm 64-bit optimizations (default auto)])],, [
1450   AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1451 ])
1452 AS_IF([test "${enable_arm64}" != "no"], [
1453   AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1454     AC_COMPILE_IFELSE([
1455       AC_LANG_PROGRAM(,[[
1456 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1457 ]])
1458     ], [
1459       ac_cv_arm64="yes"
1460     ], [
1461       ac_cv_arm64="no"
1462     ])
1463   ])
1464 ])
1465 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1466
1467
1468 AC_ARG_ENABLE(altivec,
1469   [AS_HELP_STRING([--disable-altivec],
1470     [disable AltiVec optimizations (default auto)])],, [
1471   AS_CASE("${host_cpu}", [powerpc*],
1472         [enable_altivec=yes], [enable_altivec=no])
1473 ])
1474 have_altivec="no"
1475 ALTIVEC_CFLAGS=""
1476 AS_IF([test "${enable_altivec}" = "yes"], [
1477   ARCH="${ARCH} altivec";
1478   VLC_SAVE_FLAGS
1479   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1480     [ac_cv_altivec_inline],
1481     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1482          ac_cv_altivec_inline="yes",
1483          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1484           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1485             [ac_cv_altivec_inline="-Wa,-maltivec"],
1486             ac_cv_altivec_inline=no)
1487          ])])
1488   VLC_RESTORE_FLAGS
1489   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1490     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1491               [Define to 1 if AltiVec inline assembly is available.])
1492     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1493       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1494       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1495     ])
1496     have_altivec="yes"
1497   ])
1498
1499   VLC_SAVE_FLAGS
1500   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1501   [ac_cv_c_altivec], [
1502     CFLAGS="${CFLAGS} -maltivec"
1503     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1504 [#include <altivec.h>]], [
1505 [vec_ld(0, (unsigned char *)0);]])], [
1506       ac_cv_c_altivec="-maltivec"
1507     ], [
1508       ac_cv_c_altivec="no"
1509     ])
1510   ])
1511   VLC_RESTORE_FLAGS
1512   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1513     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1514     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1515     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1516     ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1517     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1518     have_altivec="yes"
1519   ])
1520   AC_CHECK_HEADERS(altivec.h)
1521
1522   VLC_SAVE_FLAGS
1523   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1524   AC_CACHE_CHECK([if linker needs -framework vecLib],
1525     [ac_cv_ld_altivec],
1526     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1527   VLC_RESTORE_FLAGS
1528   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1529     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1530   ])
1531 ])
1532 AC_SUBST(ALTIVEC_CFLAGS)
1533 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1534
1535 dnl
1536 dnl  Memory usage
1537 dnl
1538 AC_ARG_ENABLE(optimize-memory,
1539   [AS_HELP_STRING([--enable-optimize-memory],
1540     [optimize memory usage over performance])])
1541 if test "${enable_optimize_memory}" = "yes"; then
1542   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1543 fi
1544
1545 dnl
1546 dnl Allow running as root (useful for people running on embedded platforms)
1547 dnl
1548 AC_ARG_ENABLE(run-as-root,
1549   [AS_HELP_STRING([--enable-run-as-root],
1550     [allow running VLC as root (default disabled)])])
1551 AS_IF([test "${enable_run_as_root}" = "yes"],[
1552     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1553               [Define to 1 to allow running VLC as root (uid 0).])
1554 ])
1555
1556 dnl
1557 dnl Stream output
1558 dnl
1559 AC_ARG_ENABLE(sout,
1560   [AS_HELP_STRING([--disable-sout],
1561     [disable streaming output (default enabled)])])
1562 AS_IF([test "${enable_sout}" != "no"], [
1563   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1564 ])
1565 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1566
1567 dnl Lua modules
1568 AC_ARG_ENABLE(lua,
1569   [AS_HELP_STRING([--disable-lua],
1570     [disable LUA scripting support (default enabled)])])
1571 if test "${enable_lua}" != "no"
1572 then
1573   PKG_CHECK_MODULES(LUA, lua5.2,
1574     [ have_lua=yes ],
1575     [
1576     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1577
1578     PKG_CHECK_MODULES(LUA, lua5.1,
1579       [ have_lua=yes ],
1580       [
1581       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1582       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1583         [ have_lua=yes ],
1584         [
1585           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1586           have_lua=yes
1587           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1588             [],
1589             [ have_lua=no ] )
1590           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1591             [LUA_LIBS="-llua5.2"],
1592           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1593             [LUA_LIBS="-llua5.1"],
1594             AC_CHECK_LIB( lua51 , luaL_newstate,
1595               [LUA_LIBS="-llua51"],
1596               AC_CHECK_LIB( lua , luaL_newstate,
1597                 [LUA_LIBS="-llua"],
1598                 [ have_lua=no
1599                 ], [-lm])
1600             )))
1601         ])
1602       ])
1603     ])
1604   if test "x${have_lua}" != "xyes" ;  then
1605       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1606   fi
1607   AC_ARG_VAR([LUAC], [LUA byte compiler])
1608   AS_IF([test -z "$LUAC"], [
1609      AC_CHECK_TOOL(LUAC, [luac], [false])
1610   ])
1611   AS_IF([test "${LUAC}" = "false"], [
1612     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1613   ])
1614   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1615     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1616   ])
1617 fi
1618 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1619
1620
1621 dnl
1622 dnl VideoLAN manager
1623 dnl
1624 AC_ARG_ENABLE(vlm,
1625   [AS_HELP_STRING([--disable-vlm],
1626     [disable the stream manager (default enabled)])],,
1627   [enable_vlm="${enable_sout}"])
1628 AS_IF([test "${enable_vlm}" != "no"], [
1629   AS_IF([test "${enable_sout}" = "no"], [
1630     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1631   ])
1632   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1633 ])
1634 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1635
1636
1637 dnl
1638 dnl Addons manager storage and repositories modules
1639 dnl
1640 AC_ARG_ENABLE(addonmanagermodules,
1641   [AS_HELP_STRING([--disable-addonmanagermodules],
1642     [disable the addons manager modules (default enabled)])])
1643 if test "${enable_addonmanagermodules}" != "no"
1644 then
1645   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1646 fi
1647 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1648
1649
1650 dnl
1651 dnl  Input plugins
1652 dnl
1653
1654 EXTEND_HELP_STRING([Input plugins:])
1655
1656 dnl
1657 dnl  libarchive access module
1658 dnl
1659 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1660
1661 dnl
1662 dnl  live555 input
1663 dnl
1664 AC_ARG_ENABLE(live555,
1665   [AS_HELP_STRING([--enable-live555],
1666     [enable RTSP input through live555 (default enabled)])])
1667
1668 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1669   PKG_CHECK_MODULES(LIVE555, live555, [
1670     VLC_ADD_PLUGIN([live555])
1671     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1672     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1673   ], [
1674     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1675
1676     AC_LANG_PUSH(C++)
1677     VLC_SAVE_FLAGS
1678
1679     dnl detect include paths
1680     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1681       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1682     ], [
1683       AS_IF([test "${SYS}" != "os2"], [
1684         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1685         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1686       ], [
1687         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1688         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1689         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1690       ])
1691     ])
1692
1693     dnl CPP Flags
1694     AS_IF([test "${SYS}" = "solaris"], [
1695       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1696     ])
1697     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1698     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1699
1700     dnl version check
1701     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1702       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1703 [#include <liveMedia_version.hh>
1704 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1705 # error BOOM
1706 #endif]])
1707       ], [
1708         ac_cv_live555="yes"
1709       ], [
1710         ac_cv_live555="no"
1711       ])
1712     ])
1713
1714     AS_IF([test "$ac_cv_live555" = "no"], [
1715       AC_MSG_WARN([live555 is missing or its installed version is too old:
1716 Version 2011.12.23 or later is required to proceed.
1717 You can get an updated one from http://www.live555.com/liveMedia .])
1718       AS_IF([test -n "${enable_live555}"], [
1719         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1720       ])
1721     ], [
1722       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1723       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1724       AS_IF([test "${SYS}" = "mingw32"], [
1725         # add ws2_32 for closesocket, select, recv
1726         other_libs="$other_libs -lws2_32"
1727       ])
1728
1729       dnl We need to check for pic because live555 don't provide shared libs
1730       dnl and we want to build a plugins so we need -fPIC on some arch.
1731       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1732       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1733       AC_CHECK_LIB(liveMedia_pic, main, [
1734         VLC_ADD_PLUGIN([live555])
1735         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1736       ],[
1737         AC_CHECK_LIB(liveMedia, main, [
1738           VLC_ADD_PLUGIN([live555])
1739           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1740         ],[],[${other_libs}])
1741       ],[${other_libs_pic}])
1742     ])
1743     VLC_RESTORE_FLAGS
1744     AC_LANG_POP(C++)
1745   ])
1746 ])
1747
1748 dnl
1749 dnl IIDC and DV FireWire input modules
1750 dnl
1751 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1752 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1753
1754 dnl
1755 dnl - linsys modules: access module check for libzvbi
1756 dnl
1757 AC_ARG_ENABLE(linsys,
1758   [AS_HELP_STRING([--enable-linsys],
1759     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1760 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1761   VLC_ADD_PLUGIN([linsys_hdsdi])
1762   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1763     VLC_ADD_PLUGIN([linsys_sdi])
1764   ], [
1765     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1766   ])
1767 ])
1768
1769 dnl
1770 dnl dvdread module: check for libdvdread
1771 dnl
1772 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1773
1774 dnl
1775 dnl libdvdnav plugin
1776 dnl
1777 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1778 AS_IF([test "${enable_dvdnav}" != "no"], [
1779   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1780     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1781       AC_MSG_RESULT(yes)
1782       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1783       ],[
1784       AC_MSG_RESULT(no)
1785     ])
1786 ])
1787
1788 dnl
1789 dnl  Blu-ray Disc Support with libbluray
1790 dnl
1791 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1792
1793 dnl
1794 dnl  OpenCV wrapper and example filters
1795 dnl
1796 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1797
1798
1799 dnl
1800 dnl  libsmbclient plugin
1801 dnl
1802 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1803 AS_IF([test "${SYS}" = "mingw32" -a "${enable_winstore_app}" != "yes"], [ VLC_ADD_PLUGIN([smb]) ])
1804
1805 dnl
1806 dnl  liBDSM access module
1807 dnl
1808 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1809
1810 dnl
1811 dnl sftp access support
1812 dnl
1813 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1814
1815 dnl
1816 dnl nfs access support
1817 dnl
1818 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1819
1820 dnl
1821 dnl  Video4Linux 2
1822 dnl
1823 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1824   [disable Video4Linux version 2 (default auto)])])
1825 have_v4l2="no"
1826 AS_IF([test "$enable_v4l2" != "no"], [
1827   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1828     have_v4l2="yes"
1829   ])
1830 ])
1831 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1832
1833 dnl
1834 dnl special access module for Blackmagic SDI cards
1835 dnl
1836 AC_ARG_ENABLE(decklink,
1837   [AS_HELP_STRING([--disable-decklink],
1838     [disable Blackmagic DeckLink SDI input (default auto)])])
1839 AC_ARG_WITH(decklink_sdk,
1840   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1841     [                        location of Blackmagic DeckLink SDI SDK])])
1842 have_decklink=no
1843 if test "${enable_decklink}" != "no"
1844 then
1845   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1846   then
1847     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1848   fi
1849   VLC_SAVE_FLAGS
1850   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1851   AC_LANG_PUSH(C++)
1852   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1853       have_decklink=yes
1854   ], [
1855       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1856   ])
1857   AC_LANG_POP(C++)
1858   VLC_RESTORE_FLAGS
1859 fi
1860 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1861
1862
1863 dnl
1864 dnl  Built-in CD-DA and VCD module
1865 dnl
1866 AC_ARG_ENABLE(vcd,
1867   [AS_HELP_STRING([--disable-vcd],
1868     [disable built-in VCD and CD-DA support (default enabled)])])
1869
1870 AC_ARG_ENABLE(libcddb,
1871   [AS_HELP_STRING([--disable-libcddb],
1872     [disable CDDB for Audio CD (default enabled)])])
1873
1874 if test "${enable_vcd}" != "no"
1875 then
1876   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1877   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1878     AC_MSG_RESULT(yes)
1879     VLC_ADD_PLUGIN([vcd cdda])
1880   ],[
1881     AC_MSG_RESULT(no)
1882   ])
1883
1884   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1885   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1886     AC_MSG_RESULT(yes)
1887     VLC_ADD_PLUGIN([vcd cdda])
1888     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1889   ],[
1890     AC_MSG_RESULT(no)
1891   ])
1892
1893   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1894   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1895     AC_MSG_RESULT(yes)
1896     VLC_ADD_PLUGIN([vcd cdda])
1897     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1898   ],[
1899     AC_MSG_RESULT(no)
1900   ])
1901
1902   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1903   then
1904     VLC_ADD_PLUGIN([vcd cdda])
1905   fi
1906
1907   if test "$enable_libcddb" != "no"; then
1908     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1909       HAVE_LIBCDDB=yes
1910       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1911       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1912       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1913       ],:
1914       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1915       HAVE_LIBCDDB=no])
1916   fi
1917 fi
1918
1919 dnl
1920 dnl Linux DVB
1921 dnl
1922 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1923   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1924 [#include <linux/dvb/version.h>
1925 #if (DVB_API_VERSION < 5)
1926 # error Linux DVB API v3.2 and older are not supported.
1927 #endif
1928 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1929 # error Linux DVB API v5.0 is unsupported. Please update.
1930 #endif
1931 ]])], [
1932   ac_cv_linux_dvb_5_1=yes
1933 ], [
1934   ac_cv_linux_dvb_5_1=no
1935 ])])
1936 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1937
1938 dnl
1939 dnl  Screen capture module
1940 dnl
1941 AC_ARG_ENABLE(screen,
1942   [AS_HELP_STRING([--enable-screen],
1943     [disable screen capture (default enabled)])])
1944 if test "${enable_screen}" != "no"; then
1945   if test "${SYS}" = "darwin"; then
1946     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1947       VLC_ADD_PLUGIN([screen])
1948     ])
1949   fi
1950 fi
1951 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1952
1953 dnl
1954 dnl  VNC/RFB access module
1955 dnl
1956 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1957
1958 dnl  RDP/Remote Desktop access module
1959 dnl
1960 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1961
1962 dnl
1963 dnl  Real RTSP plugin
1964 dnl
1965 AC_ARG_ENABLE(realrtsp,
1966   [  --enable-realrtsp       Real RTSP module (default disabled)])
1967 if test "${enable_realrtsp}" = "yes"; then
1968   VLC_ADD_PLUGIN([access_realrtsp])
1969 fi
1970
1971 dnl
1972 dnl QTKit
1973 AC_ARG_ENABLE(macosx-qtkit,
1974   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
1975 if test "x${enable_macosx_qtkit}" != "xno" &&
1976   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1977 then
1978   AC_CHECK_HEADERS(QTKit/QTKit.h, [
1979       VLC_ADD_PLUGIN([qtsound])
1980     ])
1981 fi
1982
1983 dnl
1984 dnl AVFoundation
1985 AC_SUBST(have_avfoundation, ["no"])
1986 AC_ARG_ENABLE(macosx-avfoundation,
1987   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
1988 if test "x${enable_macosx_avfoundation}" != "xno" &&
1989   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
1990 then
1991   SAVED_LIBS="${LIBS}"
1992   LIBS="-framework AVFoundation"
1993   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
1994   LIBS="${SAVED_LIBS}"
1995   if test "${have_avfoundation}" != "no"
1996   then
1997     VLC_ADD_PLUGIN([avcapture])
1998   fi
1999 fi
2000 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2001
2002 dnl
2003 dnl  DCP plugin (using asdcplib)
2004 dnl
2005 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2006 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2007
2008 dnl
2009 dnl  Demux plugins
2010 dnl
2011
2012 EXTEND_HELP_STRING([Mux/Demux plugins:])
2013
2014 dnl
2015 dnl  libdvbpsi check for ts mux/demux
2016 dnl
2017 have_dvbpsi="no"
2018 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2019 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2020
2021
2022 dnl
2023 dnl  GME demux plugin
2024 dnl
2025 AC_ARG_ENABLE(gme,
2026   [AS_HELP_STRING([--enable-gme],
2027     [use Game Music Emu (default auto)])])
2028 AS_IF([test "${enable_gme}" != "no"], [
2029   AC_CHECK_HEADER([gme/gme.h], [
2030     VLC_ADD_LIBS([gme], [-lgme])
2031     VLC_ADD_PLUGIN([gme])
2032   ], [
2033     AS_IF([test "x${enable_gme}" != "x"], [
2034       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2035     ])
2036   ])
2037 ])
2038
2039
2040 dnl
2041 dnl  SIDPlay plugin
2042 dnl
2043 AC_ARG_ENABLE(sid,
2044     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2045 AS_IF([test "${enable_sid}" != "no"], [
2046     PKG_CHECK_MODULES(SID, [libsidplay2], [
2047         AC_LANG_PUSH(C++)
2048         oldCPPFLAGS="$CPPFLAGS"
2049         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2050         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2051             VLC_ADD_PLUGIN([sid])
2052             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2053             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2054         ], [
2055             AS_IF([test -n "${enable_sid}"],
2056                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2057                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2058                 )
2059         ])
2060         CPPFLAGS="$oldCPPFLAGS"
2061         AC_LANG_POP(C++)
2062     ], [
2063         AS_IF([test "x${enable_sid}" = "xyes"],
2064             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2065             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2066             )
2067     ])
2068 ])
2069
2070
2071 dnl
2072 dnl  ogg demux plugin
2073 dnl
2074 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2075 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2076     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2077 ],[true])
2078 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2079 if test "${enable_sout}" != "no"; then
2080 dnl Check for libshout
2081     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2082 fi
2083
2084 dnl
2085 dnl  matroska demux plugin
2086 dnl
2087 PKG_ENABLE_MODULES_VLC([MATROSKA], [mkv], [libebml libmatroska], [MKV format support], [auto])
2088
2089 dnl
2090 dnl  modplug demux plugin
2091 dnl
2092 AC_ARG_ENABLE(mod,
2093   [AS_HELP_STRING([--disable-mod],
2094     [do not use libmodplug (default auto)])])
2095 if test "${enable_mod}" != "no" ; then
2096     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2097           VLC_ADD_PLUGIN([mod])
2098           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2099           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2100           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2101     ],[
2102        AS_IF([test -n "${enable_mod}"],
2103          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2104          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2105     ])
2106 fi
2107
2108 dnl
2109 dnl  mpc demux plugin
2110 dnl
2111 AC_ARG_ENABLE(mpc,
2112   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2113 if test "${enable_mpc}" != "no"
2114 then
2115   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2116     VLC_ADD_PLUGIN([mpc])
2117     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2118     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2119     VLC_ADD_PLUGIN([mpc])
2120     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2121 fi
2122
2123 dnl
2124 dnl  Codec plugins
2125 dnl
2126
2127 EXTEND_HELP_STRING([Codec plugins:])
2128
2129 dnl
2130 dnl wmafixed plugin
2131 dnl
2132 AC_ARG_ENABLE(wma-fixed,
2133   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2134 if test "${enable_wma_fixed}" = "yes"
2135 then
2136   VLC_ADD_PLUGIN([wma_fixed])
2137 fi
2138
2139 dnl
2140 dnl shine encoder plugin
2141 dnl
2142 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2143
2144
2145 dnl
2146 dnl openmax il codec plugin
2147 dnl
2148 AC_ARG_ENABLE(omxil,
2149   [  --enable-omxil          openmax il codec module (default disabled)])
2150 if test "${enable_omxil}" = "yes"
2151 then
2152   VLC_ADD_PLUGIN([omxil])
2153 fi
2154
2155 dnl
2156 dnl openmax il vout plugin
2157 dnl
2158 AC_ARG_ENABLE(omxil-vout,
2159   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2160 if test "${enable_omxil_vout}" = "yes"
2161 then
2162   VLC_ADD_PLUGIN([omxil_vout])
2163 fi
2164
2165 dnl
2166 dnl raspberry pi openmax il configuration
2167 dnl
2168 AC_ARG_ENABLE(rpi-omxil,
2169   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2170 if test "${enable_rpi_omxil}" = "yes"
2171 then
2172   VLC_ADD_PLUGIN([omxil omxil_vout])
2173   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2174 fi
2175
2176 dnl
2177 dnl CrystalHD codec plugin
2178 dnl
2179 AC_ARG_ENABLE(crystalhd,
2180   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2181 if test "${enable_crystalhd}" != "no"; then
2182     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2183       VLC_ADD_PLUGIN([crystalhd])
2184       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2185     ],[
2186       if test "${SYS}" = "mingw32" ; then
2187         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2188           VLC_ADD_PLUGIN([crystalhd])
2189           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2190             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2191             ])
2192         ],[
2193           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2194                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2195                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2196         ],[#define __LINUX_USER__
2197                #include <libcrystalhd/bc_dts_types.h>
2198         ])
2199       fi
2200     ],[
2201        #include <libcrystalhd/bc_dts_types.h>
2202       ])
2203 fi
2204
2205 dnl
2206 dnl  mad plugin
2207 dnl
2208 have_mad="no"
2209 MAD_CFLAGS=""
2210 MAD_LIBS=""
2211
2212 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2213   enable_mad="yes"
2214 ], [
2215   with_mad="no"
2216 ])
2217 AS_IF([test "${with_mad}" != "no"], [
2218   MAD_CFLAGS="-I${with_mad}/include"
2219   MAD_LIBS="-L${with_mad}/lib"
2220 ])
2221
2222 AC_ARG_ENABLE(mad,
2223   [  --enable-mad            libmad module (default enabled)])
2224 AS_IF([test "${enable_mad}" != "no"], [
2225   VLC_SAVE_FLAGS
2226   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2227   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2228   AC_CHECK_HEADERS(mad.h, [
2229     AC_CHECK_LIB(mad, mad_bit_init, [
2230       have_mad="yes"
2231       MAD_LIBS="${MAD_LIBS} -lmad"
2232     ])
2233   ])
2234   VLC_RESTORE_FLAGS
2235   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2236     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2237   ])
2238 ])
2239 AC_SUBST(MAD_CFLAGS)
2240 AC_SUBST(MAD_LIBS)
2241 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2242
2243 dnl  mpg123 plugin
2244 dnl
2245 dnl
2246 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2247
2248 dnl
2249 dnl gstreamer stuff
2250 dnl
2251 AC_ARG_ENABLE(gst-decode,
2252   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2253
2254 have_gst_decode="no"
2255 AS_IF([test "${enable_gst_decode}" != "no"], [
2256   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2257     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2258       have_gst_decode="yes"
2259     ], [
2260       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2261     ])
2262   ], [
2263     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2264   ])
2265 ])
2266 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2267
2268 dnl
2269 dnl  avcodec decoder/encoder plugin
2270 dnl
2271 AC_ARG_ENABLE(merge-ffmpeg,
2272 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2273   enable_merge_ffmpeg="no"
2274 ])
2275 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2276
2277 AC_MSG_CHECKING([for libavutil variant])
2278 PKG_CHECK_EXISTS([libavutil], [
2279   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2280   libavutil_micro="${libavutil_version##*.}"
2281   AS_IF([test ${libavutil_micro} -le 99], [
2282     avfork="libav"
2283   ], [
2284     avfork="ffmpeg"
2285   ])
2286 ], [
2287   avfork="none"
2288 ])
2289 AC_MSG_RESULT([${avfork}])
2290
2291 AC_ARG_ENABLE(avcodec,
2292 [  --enable-avcodec        libavcodec codec (default enabled)])
2293 AS_IF([test "${enable_avcodec}" != "no"], [
2294   dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2295   case "${avfork}" in
2296     libav) av_codec_ver="57.16.0" ;;
2297     ffmpeg) av_codec_ver="57.37.100" ;;
2298     *) AC_MSG_ERROR([Missing libav or FFmpeg. Pass --disable-avcodec to ignore this error.])
2299   esac
2300   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2301     VLC_SAVE_FLAGS
2302     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2303     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2304     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2305     AC_CHECK_HEADERS(libavutil/avutil.h)
2306     VLC_RESTORE_FLAGS
2307     have_avcodec="yes"
2308   ],[
2309     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2310   ])
2311 ], [
2312   have_avcodec="no"
2313 ])
2314 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2315
2316 dnl
2317 dnl libva needs avcodec
2318 dnl
2319 AC_ARG_ENABLE(libva,
2320   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2321
2322 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2323   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2324 ])
2325
2326 have_vaapi="no"
2327 have_vaapi_drm="no"
2328 have_vaapi_x11="no"
2329 have_vaapi_wl="no"
2330 AS_IF([test "${enable_libva}" != "no"], [
2331   PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2332     have_vaapi="yes"
2333   ], [
2334     AS_IF([test -n "${enable_libva}"], [
2335       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2336     ], [
2337       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2338     ])
2339   ])
2340   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2341     have_vaapi_drm="yes"
2342   ], [
2343     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2344   ])
2345   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2346     have_vaapi_x11="yes"
2347   ], [
2348     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2349   ])
2350   PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2351     have_vaapi_wl="yes"
2352   ], [
2353     AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2354   ])
2355 ])
2356 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2357 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2358 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2359 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2360
2361 have_avcodec_vaapi="no"
2362 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2363   VLC_SAVE_FLAGS
2364   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2365   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2366   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2367     AC_MSG_NOTICE([VA API acceleration activated])
2368     have_avcodec_vaapi="yes"
2369   ],[
2370     AS_IF([test -n "${enable_libva}"], [
2371       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2372     ], [
2373       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2374     ])
2375   ])
2376   VLC_RESTORE_FLAGS
2377 ])
2378 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2379
2380 dnl
2381 dnl dxva2 needs avcodec
2382 dnl
2383 AC_ARG_ENABLE(dxva2,
2384   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2385
2386 have_avcodec_dxva2="no"
2387 AS_IF([test "${enable_dxva2}" != "no"], [
2388   if test "${SYS}" = "mingw32"; then
2389   AS_IF([test "x${have_avcodec}" = "xyes"], [
2390     AC_CHECK_HEADERS(dxva2api.h,
2391       [
2392         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2393            AC_MSG_NOTICE([DxVA2 acceleration activated])
2394            have_avcodec_dxva2="yes"
2395         ],[
2396     AS_IF([test "${enable_dxva2}" = "yes"],
2397           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2398               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2399         ], [#undef _WIN32_WINNT
2400             /* DXVA2 is only available in Vista and above */
2401             #define _WIN32_WINNT 0x600])
2402       ],[
2403     AS_IF([test "${enable_dxva2}" = "yes"],
2404               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2405               [AC_MSG_WARN([dxva2api.h not found])])
2406       ],[#include <d3d9.h>])
2407   ],[
2408     AS_IF([test "x${enable_dxva2}" != "x"], [
2409       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2410     ])
2411   ])
2412   fi
2413 ])
2414 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2415
2416 dnl
2417 dnl d3d11va needs avcodec
2418 dnl
2419 AC_ARG_ENABLE(d3d11va,
2420   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2421
2422 have_avcodec_d3d11va="no"
2423 AS_IF([test "${enable_d3d11va}" != "no"], [
2424   if test "${SYS}" = "mingw32"; then
2425   AS_IF([test "x${have_avcodec}" = "xyes"], [
2426         AC_CHECK_TYPES([ID3D11VideoDecoder],
2427           [
2428             AC_CHECK_HEADERS(dxva2api.h,
2429               [
2430                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2431                    AC_MSG_NOTICE([D3D11 acceleration activated])
2432                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2433                    have_avcodec_d3d11va="yes"
2434                 ],[
2435                   AS_IF([test "${enable_d3d11va}" = "yes"],
2436                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2437                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2438                   ], [#undef _WIN32_WINNT
2439                       /* D3D11 is only available in Vista and above */
2440                       #define _WIN32_WINNT 0x600])
2441                   ],[
2442                     AS_IF([test "${enable_d3d11va}" = "yes"],
2443                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2444                           [AC_MSG_WARN([dxva2api.h not found])])
2445                   ],[#include <d3d9.h>])
2446           ],[
2447             AS_IF([test "${enable_d3d11va}" = "yes"],
2448                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2449                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2450           ], [#include <d3d11.h>])
2451   ],[
2452     AS_IF([test "x${enable_d3d11va}" != "x"], [
2453       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2454     ])
2455   ])
2456   fi
2457 ])
2458 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2459
2460 dnl
2461 dnl DXGI debug
2462 dnl
2463 AC_CHECK_HEADERS(dxgidebug.h)
2464
2465 dnl
2466 dnl  avformat demuxer/muxer plugin
2467 dnl
2468
2469 AC_ARG_ENABLE(avformat,
2470 [  --enable-avformat       libavformat containers (default enabled)],, [
2471   enable_avformat="${have_avcodec}"
2472 ])
2473 have_avformat="no"
2474 AS_IF([test "${enable_avformat}" != "no"], [
2475   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2476       have_avformat="yes"
2477       VLC_SAVE_FLAGS
2478       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2479       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2480       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2481       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2482       AC_CHECK_HEADERS(libavutil/avutil.h)
2483       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2484         have_avformat="no"
2485       ])
2486       VLC_RESTORE_FLAGS
2487     ],[
2488       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2489   ])
2490 ])
2491 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2492
2493 dnl
2494 dnl  swscale image scaling and conversion plugin
2495 dnl
2496
2497 AC_ARG_ENABLE(swscale,
2498   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2499           (default enabled)]))
2500 if test "${enable_swscale}" != "no"
2501 then
2502   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2503     [
2504       VLC_SAVE_FLAGS
2505       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2506       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2507       AC_CHECK_HEADERS(libswscale/swscale.h)
2508       AC_CHECK_HEADERS(libavutil/avutil.h)
2509       VLC_ADD_PLUGIN([swscale])
2510       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2511       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2512       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2513         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2514       ])
2515       VLC_RESTORE_FLAGS
2516     ],[
2517       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2518   ])
2519 fi
2520
2521 dnl
2522 dnl  postproc plugin
2523 dnl
2524
2525 AC_ARG_ENABLE(postproc,
2526 [  --enable-postproc       libpostproc image post-processing (default auto)])
2527 if test "${enable_postproc}" != "no"
2528 then
2529   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2530     [
2531       VLC_SAVE_FLAGS
2532       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2533       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2534       AC_CHECK_HEADERS(postproc/postprocess.h)
2535       VLC_ADD_PLUGIN([postproc])
2536       VLC_RESTORE_FLAGS
2537     ],[
2538       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2539   ])
2540 fi
2541
2542 dnl
2543 dnl  faad decoder plugin
2544 dnl
2545 AC_ARG_ENABLE(faad,
2546 [  --enable-faad           faad codec (default auto)])
2547 have_faad="no"
2548 AS_IF([test "${enable_faad}" != "no"], [
2549   AC_CHECK_HEADERS([neaacdec.h], [
2550     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2551
2552     AS_IF([test "${have_faad}" = "yes"], [
2553       VLC_ADD_PLUGIN([faad])
2554       VLC_ADD_LIBS([faad],[-lfaad])
2555     ], [
2556       AS_IF([test "${enable_faad}" = "yes"], [
2557         AC_MSG_ERROR([cannot find FAAD library])
2558       ], [
2559         AC_MSG_WARN([cannot find FAAD library])
2560       ])
2561     ])
2562   ])
2563 ])
2564
2565 dnl
2566 dnl  AOM decoder plugin
2567 dnl
2568 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec], [disabled])
2569
2570 dnl
2571 dnl libvpx decoder plugin
2572 dnl
2573 AC_ARG_ENABLE(vpx,
2574     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2575 AS_IF([test "${enable_vpx}" != "no"],[
2576     PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2577         VLC_ADD_PLUGIN([vpx])
2578         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2579         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2580         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2581             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2582         ], [], [${VPX_LIBS}])
2583         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2584             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2585         ], [], [${VPX_LIBS}])
2586         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2587             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2588         ], [], [${VPX_LIBS}])
2589         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2590             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2591         ], [], [${VPX_LIBS}])
2592     ], [
2593     AS_IF([test "${enable_vpx}" = "yes"],[
2594         AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2595     ])])
2596 ])
2597
2598 dnl
2599 dnl twolame encoder plugin
2600 dnl
2601 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2602
2603 dnl
2604 dnl fdk-aac encoder plugin
2605 dnl
2606 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2607
2608
2609 dnl
2610 dnl A52/AC3 decoder plugin
2611 dnl
2612 AC_ARG_ENABLE(a52,
2613   [  --enable-a52            A/52 support with liba52 (default enabled)])
2614 if test "${enable_a52}" != "no"
2615 then
2616   AC_ARG_WITH(a52,
2617     [  --with-a52=PATH         a52 headers and libraries])
2618     if test -z "${with_a52}"
2619     then
2620       LDFLAGS_test=""
2621       CPPFLAGS_test=""
2622     else
2623       LDFLAGS_test="-L${with_a52}/lib"
2624       CPPFLAGS_test="-I${with_a52}/include"
2625     fi
2626     VLC_SAVE_FLAGS
2627     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2628     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2629     AC_CHECK_HEADERS(a52dec/a52.h, [
2630       AC_CHECK_LIB(a52, a52_free, [
2631         VLC_ADD_PLUGIN([a52])
2632         VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2633         VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2634       ],[
2635         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2636         ], [$LIBM])
2637     ],[
2638       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2639     ])
2640     VLC_RESTORE_FLAGS
2641 fi
2642
2643 dnl
2644 dnl DTS Coherent Acoustics decoder plugin
2645 dnl
2646 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2647
2648 dnl
2649 dnl  Flac plugin
2650 dnl
2651 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2652
2653 dnl
2654 dnl  Libmpeg2 plugin
2655 dnl
2656 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2657
2658 dnl
2659 dnl  Vorbis plugin
2660 dnl
2661 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2662
2663 dnl
2664 dnl  Tremor plugin
2665 dnl
2666 AC_ARG_ENABLE(tremor,
2667   [  --enable-tremor         Tremor decoder support (default disabled)])
2668 if test "${enable_tremor}" = "yes"
2669 then
2670   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2671     VLC_ADD_PLUGIN([tremor])
2672    ],[])
2673 fi
2674
2675 dnl
2676 dnl  Speex plugins
2677 dnl
2678 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2679 have_speexdsp="no"
2680 AS_IF([test "${enable_speex}" != "no"], [
2681   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2682     have_speexdsp="yes"
2683   ], [
2684     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2685   ])
2686 ])
2687 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2688
2689 dnl
2690 dnl  Opus plugin
2691 dnl
2692 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2693
2694 dnl
2695 dnl  Ambisonic channel mixer and binauralizer plugin
2696 dnl
2697 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
2698
2699 dnl
2700 dnl  theora decoder plugin
2701 dnl
2702 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2703
2704 dnl
2705 dnl  OggSpots decoder plugin
2706 dnl
2707 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2708
2709 dnl
2710 dnl  Daala decoder plugin
2711 dnl
2712 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2713
2714 dnl
2715 dnl  schroedinger decoder plugin (for dirac format video)
2716 dnl
2717 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2718
2719 dnl
2720 dnl  PNG decoder module
2721 dnl
2722 AC_ARG_ENABLE(png,
2723   [  --enable-png            PNG support (default enabled)])
2724 AS_IF([test "${enable_png}" != "no"], [
2725 AC_CHECK_HEADERS(png.h, [
2726   VLC_SAVE_FLAGS
2727   LDFLAGS="${LDFLAGS} -lz $LIBM"
2728   AC_CHECK_LIB(png, png_set_alpha_mode, [
2729     VLC_ADD_PLUGIN([png])
2730   ], [], [-lz $LIBM])
2731   VLC_RESTORE_FLAGS
2732   ])
2733 ])
2734
2735 dnl
2736 dnl  JPEG decoder module
2737 dnl
2738 AC_ARG_ENABLE(jpeg,
2739   [  --enable-jpeg           JPEG support (default enabled)])
2740 AS_IF([test "${enable_jpeg}" != "no"], [
2741 AC_CHECK_HEADERS(jpeglib.h, [
2742   VLC_ADD_PLUGIN([jpeg])
2743   ])
2744 ])
2745
2746 dnl
2747 dnl  BPG decoder module
2748 dnl
2749 AC_ARG_ENABLE(bpg,
2750   [  --enable-bpg           BPG support (default disabled)])
2751 AS_IF([test "${enable_bpg}" != "no"], [
2752 AC_CHECK_HEADERS(libbpg.h, [
2753   VLC_ADD_PLUGIN([bpg])
2754   ])
2755 ])
2756
2757 dnl
2758 dnl H262 encoder plugin (lib262)
2759 dnl
2760 AC_ARG_ENABLE(x262,
2761   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2762 if test "${enable_x262}" != "no"; then
2763     PKG_CHECK_MODULES(X262, x262, [
2764         VLC_ADD_PLUGIN([x262])
2765         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2766         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2767           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2768         ])
2769         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2770         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2771           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2772         fi
2773     ], [
2774        if test "${enable_x262}" = "yes"; then
2775         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2776        fi
2777     ])
2778 fi
2779
2780 dnl x265 encoder
2781 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2782
2783 dnl
2784 dnl H264 encoder plugin (10-bit lib264)
2785 dnl
2786 AC_ARG_ENABLE(x26410b,
2787   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2788 if test "${enable_x26410b}" != "no"; then
2789     PKG_CHECK_MODULES(X26410B, x26410b, [
2790         VLC_ADD_PLUGIN([x26410b])
2791         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2792         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2793           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2794         ])
2795         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2796         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2797           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2798         fi
2799     ], [
2800        if test "${enable_x26410b}" = "yes"; then
2801         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2802        fi
2803     ])
2804 fi
2805
2806
2807 dnl
2808 dnl H264 encoder plugin (using libx264)
2809 dnl
2810 AC_ARG_ENABLE(x264,
2811   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2812 if test "${enable_x264}" != "no"; then
2813       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2814         VLC_ADD_PLUGIN([x264])
2815         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2816
2817         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2818           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2819         ])
2820
2821         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2822         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2823           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2824         fi
2825       ],[
2826         if test "${enable_x264}" = "yes"; then
2827             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2828           fi
2829       ])
2830 fi
2831
2832 dnl
2833 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2834 dnl
2835 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2836
2837 dnl
2838 dnl libfluidsynth (MIDI synthetizer) plugin
2839 dnl
2840 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2841 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2842 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2843
2844 dnl
2845 dnl Teletext Modules
2846 dnl vbi decoder plugin (using libzbvi)
2847 dnl telx module
2848 dnl uncompatible
2849 dnl
2850 AC_ARG_ENABLE(zvbi,
2851   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2852                   libzvbi (default enabled)]))
2853 AC_ARG_ENABLE(telx,
2854   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2855                   zvbi) (default enabled if zvbi is absent)]))
2856
2857 AS_IF( [test "${enable_zvbi}" != "no"],[
2858     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2859         [
2860           VLC_ADD_PLUGIN([zvbi])
2861           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2862           AS_IF( [test "${enable_telx}" = "yes"],[
2863                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2864                   ])
2865         ],[
2866           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2867         ])
2868     ])
2869 AS_IF( [test "${enable_telx}" != "no" ],[
2870   VLC_ADD_PLUGIN([telx])
2871   ])
2872
2873 dnl
2874 dnl libass subtitle rendering module
2875 dnl
2876 AC_ARG_ENABLE(libass,
2877   [  --enable-libass         Subtitle support using libass (default enabled)])
2878 AS_IF( [test "${enable_libass}" != "no"], [
2879   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2880       [
2881         VLC_ADD_PLUGIN([libass])
2882
2883         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2884           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2885            VLC_ADD_LIBS([libass],[-lfontconfig])
2886        ])
2887       ],[
2888         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2889       ])
2890   ])
2891
2892 dnl
2893 dnl ARIB subtitles rendering module
2894 dnl
2895 AC_ARG_ENABLE(aribsub,
2896   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2897 AS_IF( [test "${enable_aribsub}" != "no" ],[
2898   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2899       have_aribb24="yes"
2900       VLC_ADD_PLUGIN([aribsub])
2901       VLC_ADD_LIBS([aribsub],[-laribb24])
2902       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2903     ],[
2904       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2905       have_aribb24="no"
2906   ])
2907 ])
2908 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2909
2910 dnl
2911 dnl ARIB B25
2912 dnl
2913 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2914
2915 dnl
2916 dnl  kate decoder plugin
2917 dnl
2918 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2919
2920 dnl
2921 dnl  tiger rendering for kate decoder plugin
2922 dnl
2923 AC_ARG_ENABLE(tiger,
2924 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2925 AS_IF([test "${enable_tiger}" != "no"], [
2926   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2927       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2928         AS_IF([test -n "${enable_tiger}"], [
2929           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2930         ])
2931   ])
2932 ])
2933
2934
2935 dnl
2936 dnl  Video plugins
2937 dnl
2938
2939 EXTEND_HELP_STRING([Video plugins:])
2940
2941 dnl
2942 dnl  OpenGL
2943 dnl
2944 PKG_CHECK_MODULES([EGL], [egl], [
2945   have_egl="yes"
2946 ], [
2947   have_egl="no"
2948 ])
2949 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
2950
2951 have_gl="no"
2952 PKG_CHECK_MODULES([GL], [gl], [
2953   have_gl="yes"
2954 ], [
2955   AC_MSG_CHECKING([for OpenGL])
2956   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2957 #ifdef _WIN32
2958 # include <GL/glew.h>
2959 #endif
2960 #include <GL/gl.h>
2961 ]], [
2962     [int t0 = GL_TEXTURE0;]])
2963   ], [
2964     GL_CFLAGS=""
2965     have_gl="yes"
2966     AS_IF([test "${SYS}" != "mingw32"], [
2967       GL_LIBS="-lGL"
2968     ], [
2969       GL_LIBS="-lopengl32"
2970     ])
2971   ])
2972   AC_MSG_RESULT([${have_gl}])
2973 ])
2974 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
2975
2976 dnl OpenGL ES 2: depends on EGL 1.1
2977 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
2978
2979 dnl
2980 dnl  Xlib
2981 dnl
2982
2983 AC_PATH_XTRA()
2984 AC_CHECK_HEADERS(X11/Xlib.h)
2985
2986 dnl
2987 dnl  X C Bindings modules
2988 dnl
2989 AC_ARG_ENABLE(xcb,
2990   [  --enable-xcb            X11 support with XCB (default enabled)],, [
2991   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
2992     enable_xcb="yes"
2993   ], [
2994     enable_xcb="no"
2995   ])
2996 ])
2997 AC_ARG_ENABLE(xvideo,
2998   [  --enable-xvideo         XVideo support (default enabled)],, [
2999     enable_xvideo="$enable_xcb"
3000 ])
3001
3002 have_xcb="no"
3003 have_xcb_keysyms="no"
3004 have_xcb_randr="no"
3005 have_xcb_xvideo="no"
3006 AS_IF([test "${enable_xcb}" != "no"], [
3007   dnl libxcb
3008   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3009   have_xcb="yes"
3010   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3011   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3012   PKG_CHECK_MODULES(XPROTO, [xproto])
3013
3014   AS_IF([test "${enable_xvideo}" != "no"], [
3015     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3016   ])
3017
3018   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3019
3020   dnl xcb-utils
3021   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3022     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3023   ])
3024 ])
3025 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3026 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3027 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3028 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3029
3030
3031 dnl
3032 dnl VDPAU needs X11
3033 dnl
3034 AC_ARG_ENABLE(vdpau,
3035   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3036 have_vdpau="no"
3037 AS_IF([test "${enable_vdpau}" != "no"], [
3038   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3039     have_vdpau="yes"
3040     AS_IF([test "${no_x}" = "yes"], [
3041       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3042     ])
3043   ], [
3044     AS_IF([test -n "${enable_vdpau}"], [
3045       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3046     ])
3047   ])
3048 ])
3049 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3050
3051 have_avcodec_vdpau="no"
3052 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3053   case "${avfork}" in
3054     libav) av_vdpau_ver="56.10.0" ;;
3055     ffmpeg) av_vdpau_ver="56.19.100" ;;
3056   esac
3057   PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3058     have_avcodec_vdpau="yes"
3059     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3060   ], [
3061     AS_IF([test -n "${enable_vdpau}"], [
3062       AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3063     ], [
3064       AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3065     ])
3066   ])
3067 ])
3068 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3069
3070
3071 dnl
3072 dnl  Wayland
3073 dnl
3074 AC_ARG_ENABLE(wayland,
3075   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3076 have_wayland="no"
3077 have_wayland_egl="no"
3078
3079 AS_IF([test "${enable_wayland}" != "no"], [
3080   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3081     AC_MSG_CHECKING([for the Wayland protocols])
3082     PKG_CHECK_EXISTS([wayland-protocols >= 1.4], [
3083       WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3084       AC_MSG_RESULT([${WAYLAND_PROTOCOLS}])
3085     ], [
3086       AC_MSG_RESULT([not found])
3087       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors 'wayland-protocols >= 1.4')])
3088     ])
3089
3090     AC_MSG_CHECKING([for the Wayland scanner])
3091     PKG_CHECK_EXISTS([wayland-scanner], [
3092       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3093       AC_MSG_RESULT([${WAYLAND_SCANNER}])
3094     ], [
3095       AC_MSG_RESULT([not found])
3096       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors wayland-scanner)])
3097     ])
3098
3099     have_wayland="yes"
3100
3101     AS_IF([test "${have_egl}" = "yes"], [
3102       PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3103         have_wayland_egl="yes"
3104       ], [
3105         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3106       ])
3107     ])
3108   ], [
3109     AS_IF([test -n "${enable_wayland}"], [
3110       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3111     ])
3112   ])
3113 ])
3114 AC_SUBST([WAYLAND_PROTOCOLS])
3115 AC_SUBST([WAYLAND_SCANNER])
3116 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3117 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3118
3119
3120 dnl
3121 dnl  SDL image decoder module
3122 dnl
3123 AC_ARG_ENABLE(sdl-image,
3124   [  --enable-sdl-image      SDL image support (default enabled)])
3125 AS_IF([test "${enable_sdl_image}" != "no"],[
3126   PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3127     VLC_ADD_PLUGIN([sdl_image])
3128   ], [
3129     AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3130   ])
3131 ])
3132
3133 dnl
3134 dnl  freetype module
3135 dnl
3136 AC_ARG_ENABLE(freetype,
3137   [  --enable-freetype       freetype support   (default auto)])
3138 AC_ARG_ENABLE(fribidi,
3139   [  --enable-fribidi        fribidi support    (default auto)])
3140 AC_ARG_ENABLE(harfbuzz,
3141   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3142 AC_ARG_ENABLE(fontconfig,
3143   [  --enable-fontconfig     fontconfig support (default auto)])
3144
3145 AC_ARG_WITH([default-font],
3146     AS_HELP_STRING([--with-default-font=PATH],
3147         [Path to the default font]),
3148         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3149             "$withval", [Default font])])
3150 AC_ARG_WITH([default-monospace-font],
3151     AS_HELP_STRING([--with-default-monospace-font=PATH],
3152         [Path to the default font]),
3153         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3154             "$withval", [Default monospace font])])
3155
3156 AC_ARG_WITH([default-font-family],
3157     AS_HELP_STRING([--with-default-font-family=NAME],
3158         [Path to the default font family]),
3159         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3160             "$withval", [Default font family])])
3161 AC_ARG_WITH([default-monospace-font-family],
3162     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3163         [Path to the default font family]),
3164         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3165             "$withval", [Default monospace font family])])
3166
3167 have_freetype="no"
3168 have_fontconfig="no"
3169 have_fribidi="no"
3170 have_harfbuzz="no"
3171
3172 if test "${enable_freetype}" != "no"; then
3173    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3174       have_freetype="yes"
3175       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3176       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3177
3178     dnl fontconfig support
3179     AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3180       PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3181         have_fontconfig="yes"
3182       ], [
3183         AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3184       ])
3185     ])
3186
3187       dnl fribidi support
3188       if test "${enable_fribidi}" != "no"; then
3189         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3190           have_fribidi="yes"
3191           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3192           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3193         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3194       fi
3195
3196       dnl harfbuzz support
3197       if test "${have_fribidi}" != "no"; then
3198         if test "${enable_harfbuzz}" != "no"; then
3199           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3200             have_harfbuzz="yes"
3201             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3202             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3203           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3204         fi
3205       fi
3206   ],[
3207   AS_IF([test -n "${enable_freetype}"],[
3208     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3209     ])
3210   ])
3211 fi
3212
3213 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3214 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3215 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3216 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3217
3218 dnl
3219 dnl SAPI (text to Speech renderer for Windows)
3220 dnl
3221 AC_LANG_PUSH([C++])
3222 AC_CHECK_TYPES([ISpObjectToken],[
3223               have_sapi="yes"
3224             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3225               [#include <windows.h>
3226                #include <sapi.h>
3227                #include <sphelper.h>])
3228 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3229 AC_LANG_POP([C++])
3230
3231 dnl
3232 dnl  SVG module (text rendering and image decoding)
3233 dnl
3234 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3235 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3236
3237 dnl
3238 dnl  Windows DirectX module
3239 dnl
3240
3241 AC_ARG_ENABLE(directx,
3242   [AS_HELP_STRING([--enable-directx],
3243     [Microsoft DirectX support (default enabled on Windows)])],, [
3244   AS_IF([test "${SYS}" = "mingw32"], [
3245     enable_directx="yes"
3246   ], [
3247     enable_directx="no"
3248   ])
3249 ])
3250 AS_IF([test "${enable_directx}" != "no"], [
3251   dnl DirectDraw
3252   AC_CHECK_HEADERS(ddraw.h, [
3253     VLC_ADD_PLUGIN([directdraw])
3254   ])
3255
3256   dnl OpenGL
3257   AC_CHECK_HEADERS(GL/wglew.h, [
3258     VLC_ADD_PLUGIN([glwin32 wgl])
3259   ],, [
3260     #include <windows.h>
3261     #include <GL/gl.h>
3262   ])
3263
3264   dnl Direct3D11
3265   AC_CHECK_HEADERS(d3d11.h, [
3266     VLC_ADD_PLUGIN([direct3d11 direct3d11_deinterlace direct3d11_adjust])
3267   ])
3268
3269   dnl Direct3D9
3270   AC_CHECK_HEADERS(d3d9.h, [
3271     VLC_ADD_PLUGIN([direct3d9])
3272     AC_CHECK_HEADERS(d3dx9effect.h)
3273
3274     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3275         [[#define COBJMACROS
3276           #include <d3d9.h>
3277           #include <dxva2api.h>
3278           #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3279           # error dxva2 too old
3280           #endif
3281         ]],[[;]])
3282       ],[
3283         VLC_ADD_PLUGIN([direct3d9_deinterlace direct3d9_adjust])
3284       ],
3285       [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3286
3287   ])
3288 ])
3289
3290 dnl
3291 dnl  Linux framebuffer module
3292 dnl
3293 AC_CHECK_HEADER([linux/fb.h], [
3294   VLC_ADD_PLUGIN([fb])
3295 ])
3296
3297
3298 dnl
3299 dnl  AA plugin
3300 dnl
3301 AC_ARG_ENABLE(aa,
3302   [  --enable-aa             aalib output (default disabled)])
3303 if test "${enable_aa}" = "yes"
3304 then
3305   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3306   if test "${have_aa}" = "true"
3307   then
3308     VLC_ADD_PLUGIN([aa])
3309   fi
3310 fi
3311
3312 dnl
3313 dnl  libcaca plugin
3314 dnl
3315 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3316
3317 dnl
3318 dnl  OS/2 KVA plugin
3319 dnl
3320 AC_ARG_ENABLE(kva,
3321   [AS_HELP_STRING([--enable-kva],
3322     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3323   AS_IF([test "$SYS" = "os2"], [
3324     enable_kva="yes"
3325   ])
3326 ])
3327 have_kva="no"
3328 KVA_LIBS=""
3329 AS_IF([test "$enable_kva" != "no"], [
3330   AC_CHECK_HEADERS([kva.h], [
3331     have_kva="yes"
3332     AC_CHECK_LIB(kva, main, [
3333       KVA_LIBS="-lkva"
3334     ])
3335   ])
3336 ])
3337 AC_SUBST(KVA_LIBS)
3338 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3339
3340 dnl
3341 dnl MMAL plugin
3342 dnl
3343 AC_ARG_ENABLE(mmal,
3344   AS_HELP_STRING([--enable-mmal],
3345     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3346 if test "${enable_mmal}" != "no"; then
3347   VLC_SAVE_FLAGS
3348   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3349   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3350   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3351     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3352         have_mmal="yes"
3353         VLC_ADD_PLUGIN([mmal])
3354         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3355         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3356         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lvchostif ]) ], [
3357           AS_IF([test "${enable_mmal}" = "yes"],
3358             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3359             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3360           ],
3361         [])
3362     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3363       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3364       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3365   VLC_RESTORE_FLAGS
3366 fi
3367 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3368
3369 dnl
3370 dnl evas plugin
3371 dnl
3372 AC_ARG_ENABLE(evas,
3373   [AS_HELP_STRING([--enable-evas],
3374     [use evas output module (default disabled)])])
3375 have_evas="no"
3376 AS_IF([test "${enable_evas}" = "yes"], [
3377   PKG_CHECK_MODULES(EVAS, [evas >= 1.15.99 ecore >= 1.15.99], [
3378       have_evas="yes"
3379       AC_DEFINE([HAVE_EVAS], [1], [Define to 1 if evas is enabled.])
3380     ],[
3381     AS_IF([test "x${enable_evas}" != "x"], [
3382       AC_MSG_ERROR([$EVAS_PKG_ERRORS. libevas and libecore 1.15.99 or later required.])
3383     ])
3384   ])
3385 ])
3386 AM_CONDITIONAL([HAVE_EVAS], [test "${have_evas}" = "yes"])
3387
3388 dnl
3389 dnl  Audio plugins
3390 dnl
3391
3392 EXTEND_HELP_STRING([Audio plugins:])
3393
3394 dnl
3395 dnl  Pulseaudio module
3396 dnl
3397 AC_ARG_ENABLE(pulse,
3398   [AS_HELP_STRING([--enable-pulse],
3399     [use the PulseAudio client library (default auto)])])
3400 have_pulse="no"
3401 AS_IF([test "${enable_pulse}" != "no"], [
3402   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3403     have_pulse="yes"
3404   ], [
3405     AS_IF([test "x${enable_pulse}" != "x"], [
3406       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3407     ])
3408   ])
3409 ])
3410 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3411
3412 dnl
3413 dnl  ALSA module
3414 dnl
3415 AC_ARG_ENABLE(alsa,
3416   [AS_HELP_STRING([--enable-alsa],
3417     [support the Advanced Linux Sound Architecture (default auto)])],, [
3418   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3419     enable_alsa="yes"
3420   ])
3421 ])
3422 have_alsa="no"
3423 AS_IF([test "${enable_alsa}" != "no"], [
3424   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3425     have_alsa="yes"
3426   ], [
3427     AS_IF([test "x${enable_alsa}" != "x"], [
3428       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required. Pass --disable-alsa to ignore this error.])
3429     ])
3430   ])
3431 ])
3432 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3433
3434 dnl
3435 dnl  Open Sound System module
3436 dnl
3437 AC_ARG_ENABLE(oss,
3438   [AS_HELP_STRING([--enable-oss],
3439     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3440   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3441     enable_oss="no"
3442   ])
3443 ])
3444 have_oss="no"
3445 OSS_LIBS=""
3446 AS_IF([test "$enable_oss" != "no"], [
3447   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3448     have_oss="yes"
3449     AC_CHECK_LIB(ossaudio, main, [
3450       OSS_LIBS="-lossaudio"
3451     ])
3452   ])
3453 ])
3454 AC_SUBST(OSS_LIBS)
3455 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3456
3457 dnl
3458 dnl  OpenBSD sndio module
3459 dnl
3460 AC_ARG_ENABLE([sndio],
3461   [AS_HELP_STRING([--disable-sndio],
3462     [support the OpenBSD sndio (default auto)])],, [
3463   AS_IF([test "$SYS" = "openbsd"], [
3464     enable_sndio="yes"
3465   ])
3466 ])
3467 have_sndio="no"
3468 AS_IF([test "$enable_sndio" != "no"], [
3469   AC_CHECK_HEADER([sndio.h], [
3470     have_sndio="yes"
3471   ])
3472 ])
3473 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3474
3475 dnl
3476 dnl  Windows Audio Session plugin
3477 dnl
3478 AC_ARG_ENABLE([wasapi],
3479   [AS_HELP_STRING([--enable-wasapi],
3480     [use the Windows Audio Session API (default auto)])
3481 ])
3482 have_wasapi="no"
3483 AS_IF([test "$enable_wasapi" != "no"], [
3484   AC_CHECK_HEADER([audioclient.h], [
3485     have_wasapi="yes"
3486   ], [
3487     AS_IF([test "x${enable_wasapi}" != "x"], [
3488       AC_MSG_ERROR([Windows Audio Session API not found.])
3489     ])
3490   ])
3491 ])
3492 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3493
3494 dnl
3495 dnl  JACK modules
3496 dnl
3497 AC_ARG_ENABLE(jack,
3498   [AS_HELP_STRING([--disable-jack],
3499     [do not use jack (default auto)])])
3500 have_jack="no"
3501 AS_IF([test "${enable_jack}" != "no"], [
3502     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3503       [ have_jack=yes ],
3504       [
3505       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3506
3507       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3508       [ have_jack=yes ],
3509       [
3510       AS_IF([test -n "${enable_jack}"],
3511          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3512          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3513       ])
3514     ])
3515 ])
3516 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3517
3518 dnl
3519 dnl  OpenSLES Android
3520 dnl
3521 AC_ARG_ENABLE(opensles,
3522   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3523 if test "${HAVE_ANDROID}" = "1"; then
3524   if test "${enable_opensles}" = "yes"; then
3525       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3526         [ VLC_ADD_PLUGIN([opensles_android]) ],
3527         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3528   fi
3529 fi
3530
3531 dnl
3532 dnl  Tizen audio
3533 dnl
3534 AC_ARG_ENABLE(tizen_audio,
3535   [AS_HELP_STRING([--enable-tizen-audio],
3536     [Tizen audio module (default enabled on Tizen)])],, [
3537   AS_IF([test "$HAVE_TIZEN" = "1"], [
3538     enable_tizen_audio="yes"
3539   ])
3540 ])
3541 if test "${enable_tizen_audio}" = "yes"; then
3542   AC_CHECK_HEADERS(audio_io.h,
3543     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3544     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3545 fi
3546
3547 dnl
3548 dnl libsamplerate plugin
3549 dnl
3550 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3551
3552 dnl
3553 dnl  soxr module
3554 dnl
3555 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3556
3557 dnl
3558 dnl  OS/2 KAI plugin
3559 dnl
3560 AC_ARG_ENABLE(kai,
3561   [AS_HELP_STRING([--enable-kai],
3562     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3563   AS_IF([test "$SYS" = "os2"], [
3564     enable_kai="yes"
3565   ])
3566 ])
3567 have_kai="no"
3568 KAI_LIBS=""
3569 AS_IF([test "$enable_kai" != "no"], [
3570   AC_CHECK_HEADERS([kai.h], [
3571     have_kai="yes"
3572     AC_CHECK_LIB(kai, main, [
3573       KAI_LIBS="-lkai"
3574     ])
3575   ])
3576 ])
3577 AC_SUBST(KAI_LIBS)
3578 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3579
3580 dnl
3581 dnl  chromaprint audio track fingerprinter
3582 dnl
3583 m4_pushdef([libchromaprint_version], 0.6.0)
3584 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3585     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3586     AS_IF([test "${enable_chromaprint}" = "yes"],
3587         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3588         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3589          ),
3590     [(Chromaprint based audio fingerprinter)],[auto])
3591 m4_popdef([libchromaprint_version])
3592
3593 dnl
3594 dnl  Chromecast streaming support
3595 dnl
3596 m4_pushdef([protobuf_lite_version], 2.5.0)
3597 AC_ARG_VAR(PROTOC, [protobuf compiler])
3598 AC_CHECK_PROGS(PROTOC, protoc, no)
3599 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3600     AS_IF([test "x${PROTOC}" != "xno"], [
3601         build_chromecast="yes"
3602     ], [
3603     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3604     ])
3605 ], [
3606     AS_IF([test "${enable_chromecast}" = "yes"],
3607         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3608         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3609     )
3610     enable_chromecast="no"
3611 ], [(Chromecast streaming support)], [auto])
3612 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3613 m4_popdef([protobuf_lite_version])
3614
3615 dnl
3616 dnl  Interface plugins
3617 dnl
3618
3619 EXTEND_HELP_STRING([Interface plugins:])
3620
3621 dnl
3622 dnl QT
3623 dnl
3624 AC_ARG_ENABLE(qt, [
3625   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3626   AS_IF([test "${SYS}" = "darwin"], [
3627     enable_qt="no"
3628   ])
3629 ])
3630 have_qt5_x11="no"
3631 AS_IF([test "${enable_qt}" != "no"], [
3632   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.2.0 Qt5Widgets Qt5Gui], [
3633       PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3634           have_qt5_x11="yes"
3635       ],[
3636           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3637       ])
3638       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3639       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3640       QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3641       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3642       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3643       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3644     ], [
3645       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.8.0],, [
3646         AS_IF([test -n "${enable_qt}"],[
3647           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3648         ],[
3649           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3650         ])
3651         enable_qt="no"
3652       ])
3653       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3654       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin"])
3655       AC_PATH_PROG(RCC, rcc, rcc, ["${QT_PATH}/bin"])
3656       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin"])
3657     ])
3658 ])
3659 AS_IF([test "${enable_qt}" != "no"], [
3660   ALIASES="${ALIASES} qvlc"
3661 ])
3662 AC_SUBST(QT_VERSION)
3663 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3664 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3665
3666 dnl
3667 dnl detect kde4-config patch (used for kde solids).
3668 dnl
3669 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3670 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3671   KDE4_CONFIG="kde4-config"
3672 ])
3673
3674 dnl
3675 dnl Simple test for skins2 dependency
3676 dnl
3677 AS_IF([test "$enable_qt" = "no"], [
3678   AS_IF([test "${enable_skins2}" = "yes"], [
3679     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3680   ], [
3681     enable_skins2="no"
3682     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3683   ])
3684 ])
3685
3686 dnl
3687 dnl Skins2 module
3688 dnl
3689 AC_ARG_ENABLE(skins2,
3690   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3691 AS_IF([test "${enable_skins2}" != "no"], [
3692   have_skins_deps="yes"
3693
3694   dnl Win32
3695   AS_IF([test "${SYS}" = "mingw32"], [
3696     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3697     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3698   dnl OS/2
3699   ], [test "${SYS}" = "os2"], [
3700     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3701   dnl Linux/Unix
3702   ], [
3703     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3704     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3705     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3706     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3707     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3708   ])
3709
3710   dnl we need freetype
3711   AS_IF([test "${have_freetype}" != "yes"], [
3712     have_skins_deps="no"
3713   ])
3714
3715   AS_IF([test "${have_skins_deps}" = "no"], [
3716     AS_IF([test "x${enable_skins2}" = "x"], [
3717       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3718     ], [
3719       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3720     ])
3721     enable_skins2="no"
3722   ], [
3723     ALIASES="${ALIASES} svlc"
3724     enable_skins2="yes"
3725   ])
3726 ])
3727 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3728
3729 AC_ARG_ENABLE(libtar,
3730   [  --enable-libtar         libtar support for skins2 (default auto)])
3731 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3732   AC_CHECK_HEADERS(libtar.h, [
3733     VLC_ADD_LIBS([skins2],[-ltar])
3734   ])
3735 ])
3736
3737 dnl
3738 dnl  MacOS X gui module
3739 dnl
3740 AC_ARG_ENABLE(macosx,
3741   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3742 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3743 then
3744
3745   dnl
3746   dnl If possible, use xcrun to find the right ibtool
3747   dnl
3748
3749   AC_PATH_PROG([XCRUN], [xcrun], [no])
3750   AS_IF([test ! "x${XCRUN}" = "xno"], [
3751     AC_MSG_CHECKING([for ibtool (using xcrun)])
3752     XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3753     AC_MSG_RESULT([${XIB}])
3754   ], [
3755     AC_MSG_WARN([Looking for tools without using xcrun])
3756   ])
3757
3758   AS_IF([test "x${XIB}" = "xno"], [
3759     AC_PATH_PROG(XIB, [ibtool], [no])
3760     AS_IF([test "x${XIB}" = "xno"], [
3761       AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3762     ])
3763   ])
3764 fi
3765 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3766
3767 dnl
3768 dnl  MacOS X sparkle update support
3769 dnl
3770 AC_ARG_ENABLE(sparkle,
3771   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3772 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3773 then
3774   if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3775   then
3776     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3777   fi
3778
3779   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3780 fi
3781 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3782
3783 dnl
3784 dnl  MacOS X breakpad creash reporter support
3785 dnl
3786 AC_ARG_ENABLE(breakpad,
3787   [  --enable-breakpad       Breakpad crash reporter support for OS X (default enabled on Mac OS X)])
3788 if test "x${enable_breakpad}" != "xno" -a "${HAVE_OSX}" = "1"
3789 then
3790   if test ! -d ${CONTRIB_DIR}/Breakpad.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework
3791   then
3792     AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3793   fi
3794
3795   AC_DEFINE([HAVE_BREAKPAD], [1], [Define to 1 if breakpad is enabled.])
3796 fi
3797 AM_CONDITIONAL(HAVE_BREAKPAD, [test "$enable_breakpad" != "no"])
3798
3799
3800 dnl
3801 dnl  Minimal Mac OS X module
3802 dnl
3803 AC_ARG_ENABLE(minimal-macosx,
3804   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3805 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3806 then
3807   VLC_ADD_PLUGIN([minimal_macosx])
3808 fi
3809
3810 dnl
3811 dnl Mac OS X fancy dmg build tool
3812 dnl
3813 if test "${HAVE_OSX}" = "1"
3814 then
3815   AC_PATH_PROG(DMGBUILD, dmgbuild, no)
3816   AS_IF([test "x${DMGBUILD}" = "xno"], [
3817     AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
3818   ])
3819 fi
3820 AM_CONDITIONAL(HAVE_DMGBUILD, [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
3821
3822 dnl
3823 dnl  VideoToolbox plugins
3824 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3825     VLC_ADD_PLUGIN([videotoolbox])
3826     VLC_ADD_PLUGIN([cvpx])
3827   ])
3828
3829 dnl
3830 dnl  ncurses module
3831 dnl
3832 AC_ARG_ENABLE(ncurses,
3833 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3834 have_ncurses="no"
3835 AS_IF([test "${enable_ncurses}" != "no"] ,[
3836   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3837     have_ncurses="yes"
3838     ALIASES="${ALIASES} nvlc"
3839   ], [
3840     AS_IF([test -n "${enable_ncurses}"], [
3841       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3842     ])
3843   ])
3844 ])
3845 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3846
3847 dnl
3848 dnl  Lirc plugin
3849 dnl
3850 AC_ARG_ENABLE(lirc,
3851   [  --enable-lirc           lirc support (default disabled)])
3852 have_lirc="no"
3853 AS_IF([test "${enable_lirc}" = "yes"], [
3854   AC_CHECK_HEADER(lirc/lirc_client.h, [
3855     AC_CHECK_LIB(lirc_client, lirc_init, [
3856       have_lirc="yes"
3857     ])
3858   ])
3859 ])
3860 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3861
3862 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3863 dnl
3864 dnl  goom visualization plugin
3865 dnl
3866 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3867
3868 dnl
3869 dnl libprojectM visualization plugin
3870 dnl
3871 AC_ARG_ENABLE(projectm,
3872   [  --enable-projectm       projectM visualization plugin (default enabled)])
3873 AS_IF([test "${enable_projectm}" != "no"],
3874   [
3875     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3876     [
3877       VLC_ADD_PLUGIN([projectm])
3878       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3879         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3880         [ AC_MSG_WARN( [Using libprojectM version 1] )
3881       ])
3882     ],[
3883       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3884     ])
3885   ])
3886
3887 dnl
3888 dnl Vovoid VSXu visualization plugin
3889 dnl
3890 AC_ARG_ENABLE(vsxu,
3891   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3892 AS_IF([test "${enable_vsxu}" != "no"],
3893   [
3894     PKG_CHECK_MODULES(VSXU, libvsxu,
3895     [
3896       VLC_ADD_PLUGIN([vsxu])
3897     ],[
3898       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3899     ])
3900   ])
3901
3902 EXTEND_HELP_STRING([Service Discovery plugins:])
3903 dnl
3904 dnl  Avahi-Zeroconf services discovery
3905 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
3906
3907 dnl
3908 dnl  libudev services discovery
3909 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3910
3911 dnl
3912 dnl MTP devices services discovery
3913 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3914
3915 dnl
3916 dnl UPnP Plugin (Intel SDK)
3917 dnl
3918 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3919
3920 dnl
3921 dnl mDNS using libmicrodns
3922 dnl
3923 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
3924
3925
3926 EXTEND_HELP_STRING([Misc options:])
3927
3928 dnl
3929 dnl  libxml2 module
3930 dnl
3931 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3932
3933
3934 dnl
3935 dnl libgcrypt
3936 dnl
3937 AC_ARG_ENABLE(libgcrypt,
3938   [  --disable-libgcrypt     gcrypt support (default enabled)])
3939 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
3940 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
3941
3942 # require libgcrypt >= 1.6.0
3943 AS_IF([test "${enable_libgcrypt}" != "no"], [
3944   AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
3945     VLC_SAVE_FLAGS
3946     CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
3947     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
3948 [#include <gcrypt.h>
3949 #if GCRYPT_VERSION_NUMBER < 0x010600
3950 #error
3951 #endif]])], [
3952       ac_cv_lib_gcrypt=yes
3953     ], [
3954       ac_cv_lib_gcrypt=no
3955     ])
3956     VLC_RESTORE_FLAGS
3957   ])
3958
3959   AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
3960     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
3961   ], [
3962     AS_IF([test "${enable_libgcrypt}" = "yes"], [
3963       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
3964     ])
3965   ])
3966 ])
3967
3968 AS_IF([test -z "$GCRYPT_LIBS"], [
3969   GCRYPT_LIBS="-lgcrypt -lgpg-error"
3970 ])
3971
3972 AC_SUBST(GCRYPT_CFLAGS)
3973 AC_SUBST(GCRYPT_LIBS)
3974 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
3975
3976 dnl
3977 dnl TLS/SSL
3978 dnl
3979 AC_ARG_ENABLE(gnutls,
3980   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
3981 AS_IF([test "${enable_gnutls}" != "no"], [
3982   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
3983     VLC_ADD_PLUGIN([gnutls])
3984   ], [
3985     AS_IF([test -n "${enable_gnutls}"], [
3986       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
3987     ])
3988   ])
3989 ])
3990
3991
3992 dnl
3993 dnl Taglib plugin
3994 dnl
3995 AC_ARG_ENABLE(taglib,
3996   [AS_HELP_STRING([--disable-taglib],
3997     [do not use TagLib (default enabled)])])
3998 AS_IF([test "${enable_taglib}" != "no"], [
3999   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4000     VLC_ADD_PLUGIN([taglib])
4001   ], [
4002     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4003 ])
4004
4005 dnl
4006 dnl  libsecret
4007 dnl
4008 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4009
4010 dnl
4011 dnl  kwallet
4012 dnl
4013 AC_ARG_ENABLE(kwallet,
4014   [AS_HELP_STRING([--enable-kwallet],
4015     [use kwallet (via D-Bus) for keystore (default enabled)])])
4016 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4017   VLC_ADD_PLUGIN([kwallet])
4018 ])
4019
4020 dnl
4021 dnl  Developers helper modules (should be hidden from configure help)
4022 dnl
4023 AC_ARG_ENABLE(devtools, [], [], [enable_devtools="no"])
4024 AS_IF([test "${enable_devtools}" != "no"], [
4025   VLC_ADD_PLUGIN([accesstweaks])
4026 ])
4027
4028 dnl
4029 dnl update checking system
4030 dnl
4031 AC_ARG_ENABLE(update-check,
4032   [  --enable-update-check   update checking system (default disabled)])
4033 if test "${enable_update_check}" = "yes"
4034 then
4035  AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4036     AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4037 fi
4038 AM_CONDITIONAL(UPDATE_CHECK, [test "${enable_update_check}" = "yes"])
4039
4040 dnl
4041 dnl OS X notification plugin
4042 dnl
4043 AC_ARG_ENABLE(osx_notifications,
4044   [  --enable-osx-notifications          osx notification plugin (default disabled)],,
4045   [enable_osx_notifications=no])
4046 AS_IF([test "${enable_osx_notifications}" != "no"], [
4047   if test -d ${CONTRIB_DIR}/Growl.framework -o -d ${CONTRIB_DIR}/Frameworks/Growl.framework
4048   then
4049       VLC_ADD_PLUGIN([osx_notifications])
4050       VLC_ADD_LIBS([osx_notifications], [-Wl,-framework,Growl,-framework,Foundation])
4051       VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4052   fi
4053 ])
4054
4055 dnl
4056 dnl Libnotify notification plugin
4057 dnl
4058 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4059
4060 dnl
4061 dnl  Endianness check
4062 dnl
4063 AC_C_BIGENDIAN
4064 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4065   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4066 ], [
4067   DEFS_BIGENDIAN=""
4068 ])
4069 AC_SUBST(DEFS_BIGENDIAN)
4070
4071 dnl
4072 dnl Where to install KDE solid .desktop
4073 dnl
4074 AC_ARG_WITH(kde-solid,
4075   AS_HELP_STRING([--with-kde-solid=PATH],
4076                  [KDE Solid actions directory (auto)]),, [
4077
4078 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4079   with_kde_solid="yes"
4080 fi
4081 ])
4082 soliddatadir=""
4083 AS_IF([test "${with_kde_solid}" != "no"], [
4084   AS_IF([test "${with_kde_solid}" = "yes"], [
4085     kde4datadir="`${KDE4_CONFIG} --install data`"
4086     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4087     soliddatadir="${kde4datadir}/solid/actions"
4088   ], [
4089     soliddatadir="${with_kde_solid}"
4090   ])
4091 ])
4092 AC_SUBST(soliddatadir)
4093 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4094
4095 dnl
4096 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4097 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4098 dnl
4099 if test "${SYS}" = "mingw32"; then
4100     AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4101 fi
4102
4103 EXTEND_HELP_STRING([Components:])
4104
4105 dnl
4106 dnl  the VLC binary
4107 dnl
4108 AC_ARG_ENABLE(vlc,
4109   [  --enable-vlc            build the VLC media player (default enabled)])
4110 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4111
4112 dnl
4113 dnl  Stuff used by the program
4114 dnl
4115 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4116 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4117 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4118 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4119 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4120 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4121 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4122 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4123 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4124 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4125 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4126 AC_SUBST(COPYRIGHT_MESSAGE)
4127 AC_SUBST(VERSION_MESSAGE)
4128 AC_SUBST(VERSION_MAJOR)
4129 AC_SUBST(VERSION_MINOR)
4130 AC_SUBST(VERSION_REVISION)
4131 AC_SUBST(VERSION_EXTRA)
4132 AC_SUBST(COPYRIGHT_YEARS)
4133 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4134 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4135 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4136 dnl
4137 dnl  Handle substvars that use $(top_srcdir)
4138 dnl
4139 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4140
4141 dnl
4142 dnl  Configuration is finished
4143 dnl
4144 AC_SUBST(SYS)
4145 AC_SUBST(ARCH)
4146 AC_SUBST(ALIASES)
4147 AC_SUBST(ASM)
4148 AC_SUBST(MOC)
4149 AC_SUBST(RCC)
4150 AC_SUBST(UIC)
4151 AC_SUBST(WINDRES)
4152 AC_SUBST(WINE_SDK_PATH)
4153 AC_SUBST(LIBEXT)
4154 AC_SUBST(AM_CPPFLAGS)
4155 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4156 AC_SUBST(FILE_LIBVLCCORE_DLL)
4157 AC_SUBST(FILE_LIBVLC_DLL)
4158
4159 AC_CONFIG_FILES([
4160   Makefile
4161   doc/Makefile
4162   modules/Makefile
4163   m4/Makefile
4164   po/Makefile.in
4165   share/Makefile
4166   compat/Makefile
4167   src/Makefile
4168   lib/Makefile
4169   bin/Makefile
4170   test/Makefile
4171   modules/hw/mmal/Makefile
4172   share/vlc.appdata.xml.in
4173 ])
4174
4175 AM_COND_IF([HAVE_WIN32], [
4176   AC_CONFIG_FILES([
4177     extras/package/win32/NSIS/spad.nsi
4178     extras/package/win32/NSIS/vlc.win32.nsi
4179     extras/package/win32/msi/config.wxi
4180   ])
4181 ])
4182
4183 AM_COND_IF([HAVE_DARWIN], [
4184   AC_CONFIG_FILES([
4185     modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4186     share/macosx/Info.plist:share/Info.plist.in
4187   ])
4188 ])
4189
4190 dnl Generate makefiles
4191 AC_OUTPUT
4192
4193 dnl Do we have to use make or gmake ?
4194 if make --version 2>&1|grep -q GNU
4195 then
4196     # GNU make, all seems good
4197     MAKE=make
4198 else
4199     # Known GNU make alias (on BSD)
4200     MAKE=gmake
4201 fi
4202 dnl Shortcut to nice compile message
4203 if test -n $SHELL; then
4204   SHELL=${CONFIG_SHELL-/bin/sh}
4205 fi
4206 rm -f compile
4207 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4208 echo "#! $SHELL
4209 rm -f .error\$\$
4210 ERROR=0
4211 export PATH=\"$PATH\" LANG=C
4212 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4213 test -f .error\$\$ && ERROR=1
4214 rm -f .error\$\$
4215 exit \$ERROR" >compile
4216 chmod a+x compile
4217
4218 echo "
4219 libvlc configuration
4220 --------------------
4221 version               : ${VERSION}
4222 system                : ${SYS}
4223 architecture          : ${ARCH}
4224 optimizations         : ${enable_optimizations}"
4225 if test "${enable_vlc}" != "no"; then
4226 echo "vlc aliases           :${ALIASES}"
4227 else
4228 echo "build vlc executable  : no"
4229 fi
4230 echo "
4231 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."