m4/gettext.m4

   1 # gettext.m4 serial 68 (gettext-0.19.8)
   2 dnl Copyright (C) 1995-2014, 2016 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6 dnl
   7 dnl This file can be used in projects which are not available under
   8 dnl the GNU General Public License or the GNU Library General Public
   9 dnl License but which still want to provide support for the GNU gettext
  10 dnl functionality.
  11 dnl Please note that the actual code of the GNU gettext library is covered
  12 dnl by the GNU Library General Public License, and the rest of the GNU
  13 dnl gettext package is covered by the GNU General Public License.
  14 dnl They are *not* in the public domain.
  15
  16 dnl Authors:
  17 dnl   Ulrich Drepper <drepper@cygnus.com>, 1995-2000.
  18 dnl   Bruno Haible <haible@clisp.cons.org>, 2000-2006, 2008-2010.
  19
  20 dnl Macro to add for using GNU gettext.
  21
  22 dnl Usage: AM_GNU_GETTEXT([INTLSYMBOL], [NEEDSYMBOL], [INTLDIR]).
  23 dnl INTLSYMBOL can be one of 'external', 'no-libtool', 'use-libtool'. The
  24 dnl    default (if it is not specified or empty) is 'no-libtool'.
  25 dnl    INTLSYMBOL should be 'external' for packages with no intl directory,
  26 dnl    and 'no-libtool' or 'use-libtool' for packages with an intl directory.
  27 dnl    If INTLSYMBOL is 'use-libtool', then a libtool library
  28 dnl    $(top_builddir)/intl/libintl.la will be created (shared and/or static,
  29 dnl    depending on --{enable,disable}-{shared,static} and on the presence of
  30 dnl    AM-DISABLE-SHARED). If INTLSYMBOL is 'no-libtool', a static library
  31 dnl    $(top_builddir)/intl/libintl.a will be created.
  32 dnl If NEEDSYMBOL is specified and is 'need-ngettext', then GNU gettext
  33 dnl    implementations (in libc or libintl) without the ngettext() function
  34 dnl    will be ignored.  If NEEDSYMBOL is specified and is
  35 dnl    'need-formatstring-macros', then GNU gettext implementations that don't
  36 dnl    support the ISO C 99 <inttypes.h> formatstring macros will be ignored.
  37 dnl INTLDIR is used to find the intl libraries.  If empty,
  38 dnl    the value '$(top_builddir)/intl/' is used.
  39 dnl
  40 dnl The result of the configuration is one of three cases:
  41 dnl 1) GNU gettext, as included in the intl subdirectory, will be compiled
  42 dnl    and used.
  43 dnl    Catalog format: GNU --> install in $(datadir)
  44 dnl    Catalog extension: .mo after installation, .gmo in source tree
  45 dnl 2) GNU gettext has been found in the system's C library.
  46 dnl    Catalog format: GNU --> install in $(datadir)
  47 dnl    Catalog extension: .mo after installation, .gmo in source tree
  48 dnl 3) No internationalization, always use English msgid.
  49 dnl    Catalog format: none
  50 dnl    Catalog extension: none
  51 dnl If INTLSYMBOL is 'external', only cases 2 and 3 can occur.
  52 dnl The use of .gmo is historical (it was needed to avoid overwriting the
  53 dnl GNU format catalogs when building on a platform with an X/Open gettext),
  54 dnl but we keep it in order not to force irrelevant filename changes on the
  55 dnl maintainers.
  56 dnl
  57 AC_DEFUN([AM_GNU_GETTEXT],
  58 [
  59   dnl Argument checking.
  60   ifelse([$1], [], , [ifelse([$1], [external], , [ifelse([$1], [no-libtool], , [ifelse([$1], [use-libtool], ,
  61     [errprint([ERROR: invalid first argument to AM_GNU_GETTEXT
  62 ])])])])])
  63   ifelse(ifelse([$1], [], [old])[]ifelse([$1], [no-libtool], [old]), [old],
  64     [AC_DIAGNOSE([obsolete], [Use of AM_GNU_GETTEXT without [external] argument is deprecated.])])
  65   ifelse([$2], [], , [ifelse([$2], [need-ngettext], , [ifelse([$2], [need-formatstring-macros], ,
  66     [errprint([ERROR: invalid second argument to AM_GNU_GETTEXT
  67 ])])])])
  68   define([gt_included_intl],
  69     ifelse([$1], [external],
  70       ifdef([AM_GNU_GETTEXT_][INTL_SUBDIR], [yes], [no]),
  71       [yes]))
  72   define([gt_libtool_suffix_prefix], ifelse([$1], [use-libtool], [l], []))
  73   gt_NEEDS_INIT
  74   AM_GNU_GETTEXT_NEED([$2])
  75
  76   AC_REQUIRE([AM_PO_SUBDIRS])dnl
  77   ifelse(gt_included_intl, yes, [
  78     AC_REQUIRE([AM_INTL_SUBDIR])dnl
  79   ])
  80
  81   dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
  82   AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
  83   AC_REQUIRE([AC_LIB_RPATH])
  84
  85   dnl Sometimes libintl requires libiconv, so first search for libiconv.
  86   dnl Ideally we would do this search only after the
  87   dnl      if test "$USE_NLS" = "yes"; then
  88   dnl        if { eval "gt_val=\$$gt_func_gnugettext_libc"; test "$gt_val" != "yes"; }; then
  89   dnl tests. But if configure.in invokes AM_ICONV after AM_GNU_GETTEXT
  90   dnl the configure script would need to contain the same shell code
  91   dnl again, outside any 'if'. There are two solutions:
  92   dnl - Invoke AM_ICONV_LINKFLAGS_BODY here, outside any 'if'.
  93   dnl - Control the expansions in more detail using AC_PROVIDE_IFELSE.
  94   dnl Since AC_PROVIDE_IFELSE is only in autoconf >= 2.52 and not
  95   dnl documented, we avoid it.
  96   ifelse(gt_included_intl, yes, , [
  97     AC_REQUIRE([AM_ICONV_LINKFLAGS_BODY])
  98   ])
  99
 100   dnl Sometimes, on Mac OS X, libintl requires linking with CoreFoundation.
 101   gt_INTL_MACOSX
 102
 103   dnl Set USE_NLS.
 104   AC_REQUIRE([AM_NLS])
 105
 106   ifelse(gt_included_intl, yes, [
 107     BUILD_INCLUDED_LIBINTL=no
 108     USE_INCLUDED_LIBINTL=no
 109   ])
 110   LIBINTL=
 111   LTLIBINTL=
 112   POSUB=
 113
 114   dnl Add a version number to the cache macros.
 115   case " $gt_needs " in
 116     *" need-formatstring-macros "*) gt_api_version=3 ;;
 117     *" need-ngettext "*) gt_api_version=2 ;;
 118     *) gt_api_version=1 ;;
 119   esac
 120   gt_func_gnugettext_libc="gt_cv_func_gnugettext${gt_api_version}_libc"
 121   gt_func_gnugettext_libintl="gt_cv_func_gnugettext${gt_api_version}_libintl"
 122
 123   dnl If we use NLS figure out what method
 124   if test "$USE_NLS" = "yes"; then
 125     gt_use_preinstalled_gnugettext=no
 126     ifelse(gt_included_intl, yes, [
 127       AC_MSG_CHECKING([whether included gettext is requested])
 128       AC_ARG_WITH([included-gettext],
 129         [  --with-included-gettext use the GNU gettext library included here],
 130         nls_cv_force_use_gnu_gettext=$withval,
 131         nls_cv_force_use_gnu_gettext=no)
 132       AC_MSG_RESULT([$nls_cv_force_use_gnu_gettext])
 133
 134       nls_cv_use_gnu_gettext="$nls_cv_force_use_gnu_gettext"
 135       if test "$nls_cv_force_use_gnu_gettext" != "yes"; then
 136     ])
 137         dnl User does not insist on using GNU NLS library.  Figure out what
 138         dnl to use.  If GNU gettext is available we use this.  Else we have
 139         dnl to fall back to GNU NLS library.
 140
 141         if test $gt_api_version -ge 3; then
 142           gt_revision_test_code='
 143 #ifndef __GNU_GETTEXT_SUPPORTED_REVISION
 144 #define __GNU_GETTEXT_SUPPORTED_REVISION(major) ((major) == 0 ? 0 : -1)
 145 #endif
 146 changequote(,)dnl
 147 typedef int array [2 * (__GNU_GETTEXT_SUPPORTED_REVISION(0) >= 1) - 1];
 148 changequote([,])dnl
 149 '
 150         else
 151           gt_revision_test_code=
 152         fi
 153         if test $gt_api_version -ge 2; then
 154           gt_expression_test_code=' + * ngettext ("", "", 0)'
 155         else
 156           gt_expression_test_code=
 157         fi
 158
 159         AC_CACHE_CHECK([for GNU gettext in libc], [$gt_func_gnugettext_libc],
 160          [AC_LINK_IFELSE(
 161             [AC_LANG_PROGRAM(
 162                [[
 163 #include <libintl.h>
 164 #ifndef __GNU_GETTEXT_SUPPORTED_REVISION
 165 extern int _nl_msg_cat_cntr;
 166 extern int *_nl_domain_bindings;
 167 #define __GNU_GETTEXT_SYMBOL_EXPRESSION (_nl_msg_cat_cntr + *_nl_domain_bindings)
 168 #else
 169 #define __GNU_GETTEXT_SYMBOL_EXPRESSION 0
 170 #endif
 171 $gt_revision_test_code
 172                ]],
 173                [[
 174 bindtextdomain ("", "");
 175 return * gettext ("")$gt_expression_test_code + __GNU_GETTEXT_SYMBOL_EXPRESSION
 176                ]])],
 177             [eval "$gt_func_gnugettext_libc=yes"],
 178             [eval "$gt_func_gnugettext_libc=no"])])
 179
 180         if { eval "gt_val=\$$gt_func_gnugettext_libc"; test "$gt_val" != "yes"; }; then
 181           dnl Sometimes libintl requires libiconv, so first search for libiconv.
 182           ifelse(gt_included_intl, yes, , [
 183             AM_ICONV_LINK
 184           ])
 185           dnl Search for libintl and define LIBINTL, LTLIBINTL and INCINTL
 186           dnl accordingly. Don't use AC_LIB_LINKFLAGS_BODY([intl],[iconv])
 187           dnl because that would add "-liconv" to LIBINTL and LTLIBINTL
 188           dnl even if libiconv doesn't exist.
 189           AC_LIB_LINKFLAGS_BODY([intl])
 190           AC_CACHE_CHECK([for GNU gettext in libintl],
 191             [$gt_func_gnugettext_libintl],
 192            [gt_save_CPPFLAGS="$CPPFLAGS"
 193             CPPFLAGS="$CPPFLAGS $INCINTL"
 194             gt_save_LIBS="$LIBS"
 195             LIBS="$LIBS $LIBINTL $INTL_MACOSX_LIBS"
 196             dnl Now see whether libintl exists and does not depend on libiconv.
 197             AC_LINK_IFELSE(
 198               [AC_LANG_PROGRAM(
 199                  [[
 200 #include <libintl.h>
 201 #ifndef __GNU_GETTEXT_SUPPORTED_REVISION
 202 extern int _nl_msg_cat_cntr;
 203 extern
 204 #ifdef __cplusplus
 205 "C"
 206 #endif
 207 const char *_nl_expand_alias (const char *);
 208 #define __GNU_GETTEXT_SYMBOL_EXPRESSION (_nl_msg_cat_cntr + *_nl_expand_alias (""))
 209 #else
 210 #define __GNU_GETTEXT_SYMBOL_EXPRESSION 0
 211 #endif
 212 $gt_revision_test_code
 213                  ]],
 214                  [[
 215 bindtextdomain ("", "");
 216 return * gettext ("")$gt_expression_test_code + __GNU_GETTEXT_SYMBOL_EXPRESSION
 217                  ]])],
 218               [eval "$gt_func_gnugettext_libintl=yes"],
 219               [eval "$gt_func_gnugettext_libintl=no"])
 220             dnl Now see whether libintl exists and depends on libiconv.
 221             if { eval "gt_val=\$$gt_func_gnugettext_libintl"; test "$gt_val" != yes; } && test -n "$LIBICONV"; then
 222               LIBS="$LIBS $LIBICONV"
 223               AC_LINK_IFELSE(
 224                 [AC_LANG_PROGRAM(
 225                    [[
 226 #include <libintl.h>
 227 #ifndef __GNU_GETTEXT_SUPPORTED_REVISION
 228 extern int _nl_msg_cat_cntr;
 229 extern
 230 #ifdef __cplusplus
 231 "C"
 232 #endif
 233 const char *_nl_expand_alias (const char *);
 234 #define __GNU_GETTEXT_SYMBOL_EXPRESSION (_nl_msg_cat_cntr + *_nl_expand_alias (""))
 235 #else
 236 #define __GNU_GETTEXT_SYMBOL_EXPRESSION 0
 237 #endif
 238 $gt_revision_test_code
 239                    ]],
 240                    [[
 241 bindtextdomain ("", "");
 242 return * gettext ("")$gt_expression_test_code + __GNU_GETTEXT_SYMBOL_EXPRESSION
 243                    ]])],
 244                 [LIBINTL="$LIBINTL $LIBICONV"
 245                  LTLIBINTL="$LTLIBINTL $LTLIBICONV"
 246                  eval "$gt_func_gnugettext_libintl=yes"
 247                 ])
 248             fi
 249             CPPFLAGS="$gt_save_CPPFLAGS"
 250             LIBS="$gt_save_LIBS"])
 251         fi
 252
 253         dnl If an already present or preinstalled GNU gettext() is found,
 254         dnl use it.  But if this macro is used in GNU gettext, and GNU
 255         dnl gettext is already preinstalled in libintl, we update this
 256         dnl libintl.  (Cf. the install rule in intl/Makefile.in.)
 257         if { eval "gt_val=\$$gt_func_gnugettext_libc"; test "$gt_val" = "yes"; } \
 258            || { { eval "gt_val=\$$gt_func_gnugettext_libintl"; test "$gt_val" = "yes"; } \
 259                 && test "$PACKAGE" != gettext-runtime \
 260                 && test "$PACKAGE" != gettext-tools; }; then
 261           gt_use_preinstalled_gnugettext=yes
 262         else
 263           dnl Reset the values set by searching for libintl.
 264           LIBINTL=
 265           LTLIBINTL=
 266           INCINTL=
 267         fi
 268
 269     ifelse(gt_included_intl, yes, [
 270         if test "$gt_use_preinstalled_gnugettext" != "yes"; then
 271           dnl GNU gettext is not found in the C library.
 272           dnl Fall back on included GNU gettext library.
 273           nls_cv_use_gnu_gettext=yes
 274         fi
 275       fi
 276
 277       if test "$nls_cv_use_gnu_gettext" = "yes"; then
 278         dnl Mark actions used to generate GNU NLS library.
 279         BUILD_INCLUDED_LIBINTL=yes
 280         USE_INCLUDED_LIBINTL=yes
 281         LIBINTL="ifelse([$3],[],\${top_builddir}/intl,[$3])/libintl.[]gt_libtool_suffix_prefix[]a $LIBICONV $LIBTHREAD"
 282         LTLIBINTL="ifelse([$3],[],\${top_builddir}/intl,[$3])/libintl.[]gt_libtool_suffix_prefix[]a $LTLIBICONV $LTLIBTHREAD"
 283         LIBS=`echo " $LIBS " | sed -e 's/ -lintl / /' -e 's/^ //' -e 's/ $//'`
 284       fi
 285
 286       CATOBJEXT=
 287       if test "$gt_use_preinstalled_gnugettext" = "yes" \
 288          || test "$nls_cv_use_gnu_gettext" = "yes"; then
 289         dnl Mark actions to use GNU gettext tools.
 290         CATOBJEXT=.gmo
 291       fi
 292     ])
 293
 294     if test -n "$INTL_MACOSX_LIBS"; then
 295       if test "$gt_use_preinstalled_gnugettext" = "yes" \
 296          || test "$nls_cv_use_gnu_gettext" = "yes"; then
 297         dnl Some extra flags are needed during linking.
 298         LIBINTL="$LIBINTL $INTL_MACOSX_LIBS"
 299         LTLIBINTL="$LTLIBINTL $INTL_MACOSX_LIBS"
 300       fi
 301     fi
 302
 303     if test "$gt_use_preinstalled_gnugettext" = "yes" \
 304        || test "$nls_cv_use_gnu_gettext" = "yes"; then
 305       AC_DEFINE([ENABLE_NLS], [1],
 306         [Define to 1 if translation of program messages to the user's native language
 307    is requested.])
 308     else
 309       USE_NLS=no
 310     fi
 311   fi
 312
 313   AC_MSG_CHECKING([whether to use NLS])
 314   AC_MSG_RESULT([$USE_NLS])
 315   if test "$USE_NLS" = "yes"; then
 316     AC_MSG_CHECKING([where the gettext function comes from])
 317     if test "$gt_use_preinstalled_gnugettext" = "yes"; then
 318       if { eval "gt_val=\$$gt_func_gnugettext_libintl"; test "$gt_val" = "yes"; }; then
 319         gt_source="external libintl"
 320       else
 321         gt_source="libc"
 322       fi
 323     else
 324       gt_source="included intl directory"
 325     fi
 326     AC_MSG_RESULT([$gt_source])
 327   fi
 328
 329   if test "$USE_NLS" = "yes"; then
 330
 331     if test "$gt_use_preinstalled_gnugettext" = "yes"; then
 332       if { eval "gt_val=\$$gt_func_gnugettext_libintl"; test "$gt_val" = "yes"; }; then
 333         AC_MSG_CHECKING([how to link with libintl])
 334         AC_MSG_RESULT([$LIBINTL])
 335         AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCINTL])
 336       fi
 337
 338       dnl For backward compatibility. Some packages may be using this.
 339       AC_DEFINE([HAVE_GETTEXT], [1],
 340        [Define if the GNU gettext() function is already present or preinstalled.])
 341       AC_DEFINE([HAVE_DCGETTEXT], [1],
 342        [Define if the GNU dcgettext() function is already present or preinstalled.])
 343     fi
 344
 345     dnl We need to process the po/ directory.
 346     POSUB=po
 347   fi
 348
 349   ifelse(gt_included_intl, yes, [
 350     dnl If this is used in GNU gettext we have to set BUILD_INCLUDED_LIBINTL
 351     dnl to 'yes' because some of the testsuite requires it.
 352     if test "$PACKAGE" = gettext-runtime || test "$PACKAGE" = gettext-tools; then
 353       BUILD_INCLUDED_LIBINTL=yes
 354     fi
 355
 356     dnl Make all variables we use known to autoconf.
 357     AC_SUBST([BUILD_INCLUDED_LIBINTL])
 358     AC_SUBST([USE_INCLUDED_LIBINTL])
 359     AC_SUBST([CATOBJEXT])
 360
 361     dnl For backward compatibility. Some configure.ins may be using this.
 362     nls_cv_header_intl=
 363     nls_cv_header_libgt=
 364
 365     dnl For backward compatibility. Some Makefiles may be using this.
 366     DATADIRNAME=share
 367     AC_SUBST([DATADIRNAME])
 368
 369     dnl For backward compatibility. Some Makefiles may be using this.
 370     INSTOBJEXT=.mo
 371     AC_SUBST([INSTOBJEXT])
 372
 373     dnl For backward compatibility. Some Makefiles may be using this.
 374     GENCAT=gencat
 375     AC_SUBST([GENCAT])
 376
 377     dnl For backward compatibility. Some Makefiles may be using this.
 378     INTLOBJS=
 379     if test "$USE_INCLUDED_LIBINTL" = yes; then
 380       INTLOBJS="\$(GETTOBJS)"
 381     fi
 382     AC_SUBST([INTLOBJS])
 383
 384     dnl Enable libtool support if the surrounding package wishes it.
 385     INTL_LIBTOOL_SUFFIX_PREFIX=gt_libtool_suffix_prefix
 386     AC_SUBST([INTL_LIBTOOL_SUFFIX_PREFIX])
 387   ])
 388
 389   dnl For backward compatibility. Some Makefiles may be using this.
 390   INTLLIBS="$LIBINTL"
 391   AC_SUBST([INTLLIBS])
 392
 393   dnl Make all documented variables known to autoconf.
 394   AC_SUBST([LIBINTL])
 395   AC_SUBST([LTLIBINTL])
 396   AC_SUBST([POSUB])
 397 ])
 398
 399
 400 dnl gt_NEEDS_INIT ensures that the gt_needs variable is initialized.
 401 m4_define([gt_NEEDS_INIT],
 402 [
 403   m4_divert_text([DEFAULTS], [gt_needs=])
 404   m4_define([gt_NEEDS_INIT], [])
 405 ])
 406
 407
 408 dnl Usage: AM_GNU_GETTEXT_NEED([NEEDSYMBOL])
 409 AC_DEFUN([AM_GNU_GETTEXT_NEED],
 410 [
 411   m4_divert_text([INIT_PREPARE], [gt_needs="$gt_needs $1"])
 412 ])
 413
 414
 415 dnl Usage: AM_GNU_GETTEXT_VERSION([gettext-version])
 416 AC_DEFUN([AM_GNU_GETTEXT_VERSION], [])
 417
 418
 419 dnl Usage: AM_GNU_GETTEXT_REQUIRE_VERSION([gettext-version])
 420 AC_DEFUN([AM_GNU_GETTEXT_REQUIRE_VERSION], [])