m4/stdcxx_11.m4

   1 # ============================================================================
   2 #  http://www.gnu.org/software/autoconf-archive/ax_cxx_compile_stdcxx_11.html
   3 # ============================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_CXX_COMPILE_STDCXX_11([ext|noext],[mandatory|optional])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   Check for baseline language coverage in the compiler for the C++11
  12 #   standard; if necessary, add switches to CXXFLAGS to enable support.
  13 #
  14 #   The first argument, if specified, indicates whether you insist on an
  15 #   extended mode (e.g. -std=gnu++11) or a strict conformance mode (e.g.
  16 #   -std=c++11).  If neither is specified, you get whatever works, with
  17 #   preference for an extended mode.
  18 #
  19 #   The second argument, if specified 'mandatory' or if left unspecified,
  20 #   indicates that baseline C++11 support is required and that the macro
  21 #   should error out if no mode with that support is found.  If specified
  22 #   'optional', then configuration proceeds regardless, after defining
  23 #   HAVE_CXX11 if and only if a supporting mode is found.
  24 #
  25 # LICENSE
  26 #
  27 #   Copyright (c) 2008 Benjamin Kosnik <bkoz@redhat.com>
  28 #   Copyright (c) 2012 Zack Weinberg <zackw@panix.com>
  29 #   Copyright (c) 2013 Roy Stogner <roystgnr@ices.utexas.edu>
  30 #   Copyright (c) 2014 Alexey Sokolov <sokolov@google.com>
  31 #   Copyright (c) 2014, 2015 Google Inc.
  32 #   Copyright (c) 2015 VLC authors and VideoLAN
  33 #
  34 #   Copying and distribution of this file, with or without modification, are
  35 #   permitted in any medium without royalty provided the copyright notice
  36 #   and this notice are preserved. This file is offered as-is, without any
  37 #   warranty.
  38
  39 #serial 7
  40
  41 m4_define([_AX_CXX_COMPILE_STDCXX_11_testbody], [[
  42   template <typename T>
  43     struct check
  44     {
  45       static_assert(sizeof(int) <= sizeof(T), "not big enough");
  46     };
  47
  48     struct Base {
  49     virtual void f() {}
  50     };
  51     struct Child : public Base {
  52     virtual void f() override {}
  53     };
  54
  55     typedef check<check<bool>> right_angle_brackets;
  56
  57     int a;
  58     decltype(a) b;
  59
  60     typedef check<int> check_type;
  61     check_type c;
  62     check_type&& cr = static_cast<check_type&&>(c);
  63
  64     auto d = a;
  65     auto l = [](){};
  66
  67     // http://stackoverflow.com/questions/13728184/template-aliases-and-sfinae
  68     // Clang 3.1 fails with headers of libstd++ 4.8.3 when using std::function because of this
  69     namespace test_template_alias_sfinae {
  70         struct foo {};
  71
  72         template<typename T>
  73         using member = typename T::member_type;
  74
  75         template<typename T>
  76         void func(...) {}
  77
  78         template<typename T>
  79         void func(member<T>*) {}
  80
  81         void test() {
  82             func<foo>(0);
  83         }
  84     }
  85
  86     #include <cinttypes>
  87     constexpr uint64_t constantname = UINT64_C(0x100000000);
  88 ]])
  89
  90 AC_DEFUN([AX_CXX_COMPILE_STDCXX_11], [dnl
  91   m4_if([$1], [], [],
  92         [$1], [ext], [],
  93         [$1], [noext], [],
  94         [m4_fatal([invalid argument `$1' to AX_CXX_COMPILE_STDCXX_11])])dnl
  95   m4_if([$2], [], [ax_cxx_compile_cxx11_required=true],
  96         [$2], [mandatory], [ax_cxx_compile_cxx11_required=true],
  97         [$2], [optional], [ax_cxx_compile_cxx11_required=false],
  98         [m4_fatal([invalid second argument `$2' to AX_CXX_COMPILE_STDCXX_11])])
  99   AC_LANG_PUSH([C++])dnl
 100   ac_success=no
 101   AC_CACHE_CHECK(whether $CXX supports C++11 features by default,
 102   ax_cv_cxx_compile_cxx11,
 103   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([_AX_CXX_COMPILE_STDCXX_11_testbody])],
 104     [ax_cv_cxx_compile_cxx11=yes],
 105     [ax_cv_cxx_compile_cxx11=no])])
 106   if test x$ax_cv_cxx_compile_cxx11 = xyes; then
 107     ac_success=yes
 108   fi
 109
 110   m4_if([$1], [noext], [], [dnl
 111   if test x$ac_success = xno; then
 112     for switch in -std=gnu++11 -std=gnu++0x; do
 113       cachevar=AS_TR_SH([ax_cv_cxx_compile_cxx11_$switch])
 114       AC_CACHE_CHECK(whether $CXX supports C++11 features with $switch,
 115                      $cachevar,
 116         [ac_save_CXXFLAGS="$CXXFLAGS"
 117          CXXFLAGS="$CXXFLAGS $switch"
 118          AC_COMPILE_IFELSE([AC_LANG_SOURCE([_AX_CXX_COMPILE_STDCXX_11_testbody])],
 119           [eval $cachevar=yes],
 120           [eval $cachevar=no])
 121          CXXFLAGS="$ac_save_CXXFLAGS"])
 122       if eval test x\$$cachevar = xyes; then
 123         CXXFLAGS="$CXXFLAGS $switch"
 124         ac_success=yes
 125         break
 126       fi
 127     done
 128   fi])
 129
 130   m4_if([$1], [ext], [], [dnl
 131   if test x$ac_success = xno; then
 132     for switch in -std=c++11 -std=c++0x; do
 133       cachevar=AS_TR_SH([ax_cv_cxx_compile_cxx11_$switch])
 134       AC_CACHE_CHECK(whether $CXX supports C++11 features with $switch,
 135                      $cachevar,
 136         [ac_save_CXXFLAGS="$CXXFLAGS"
 137          CXXFLAGS="$CXXFLAGS $switch"
 138          AC_COMPILE_IFELSE([AC_LANG_SOURCE([_AX_CXX_COMPILE_STDCXX_11_testbody])],
 139           [eval $cachevar=yes],
 140           [eval $cachevar=no])
 141          CXXFLAGS="$ac_save_CXXFLAGS"])
 142       if eval test x\$$cachevar = xyes; then
 143         CXXFLAGS="$CXXFLAGS $switch"
 144         ac_success=yes
 145         break
 146       fi
 147     done
 148   fi])
 149   AC_LANG_POP([C++])
 150   if test x$ax_cxx_compile_cxx11_required = xtrue; then
 151     if test x$ac_success = xno; then
 152       AC_MSG_ERROR([*** A compiler with support for C++11 language features is required.])
 153     fi
 154   else
 155     if test x$ac_success = xno; then
 156       HAVE_CXX11=0
 157       AC_MSG_NOTICE([No compiler with C++11 support was found])
 158     else
 159       HAVE_CXX11=1
 160       AC_DEFINE(HAVE_CXX11,1,
 161                 [define if the compiler supports basic C++11 syntax])
 162     fi
 163
 164     AC_SUBST(HAVE_CXX11)
 165   fi
 166 ])