configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 1999-2018 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 4.0.0-dev)
   6 VERSION_MAJOR=4
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=dev
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Otto Chriek"
  17 COPYRIGHT_YEARS="1996-2018"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 AM_SILENT_RULES([yes])
  31 AM_MAINTAINER_MODE([enable])
  32
  33 dnl
  34 dnl Directories
  35 dnl
  36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  37 dnl AC_SUBST(vlcincludedir)
  38 vlcdatadir="\${datadir}/\${PKGDIR}"
  39 AC_SUBST(vlcdatadir)
  40 vlclibdir="\${libdir}/\${PKGDIR}"
  41 AC_SUBST(vlclibdir)
  42
  43 dnl
  44 dnl Check for tools
  45 dnl
  46 AC_PROG_CC
  47 AC_USE_SYSTEM_EXTENSIONS
  48 VLC_PROG_CC_C11
  49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  51 AH_TOP([
  52 #ifndef _REENTRANT
  53 # define _REENTRANT
  54 #endif
  55 ])
  56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  59
  60 AC_PROG_CXX
  61 AC_PROG_CPP
  62 AC_PROG_OBJC
  63 AC_PROG_EGREP
  64 AC_PROG_MAKE_SET
  65 AC_PROG_INSTALL
  66 AM_PROG_AS
  67 AC_PROG_LEX
  68 AC_PROG_YACC
  69
  70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
  73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
  74 AS_IF([test "$BUILDCC" = "false"], [
  75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
  76 ])
  77
  78 dnl Check for compiler properties
  79 AC_C_CONST
  80 AC_C_INLINE
  81 AC_C_RESTRICT
  82 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
  83
  84 dnl Extend the --help string at the current spot.
  85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  86
  87 dnl Allow binary package maintainer to pass a custom string to avoid
  88 dnl cache problem
  89 AC_ARG_WITH(binary-version,
  90     AS_HELP_STRING([--with-binary-version=STRING],
  91          [To avoid plugins cache problem between binary version]),[],[])
  92 AS_IF([test -n "${with_binary_version}"],[
  93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  94          [Binary specific version])
  95 ])
  96
  97 dnl Prevent clang from accepting unknown flags with a mere warning
  98 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CFLAGS])
  99 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CXXFLAGS])
 100
 101 dnl
 102 dnl  Check the operating system
 103 dnl
 104 HAVE_WIN64="0"
 105 HAVE_IOS="0"
 106 HAVE_OSX="0"
 107 HAVE_TVOS="0"
 108
 109 case "${host_os}" in
 110   "")
 111     SYS=unknown
 112     ;;
 113   linux*)
 114     SYS=linux
 115     ;;
 116   bsdi*)
 117     SYS=bsdi
 118     CFLAGS="${CFLAGS} -pthread"
 119     ;;
 120   freebsd*)
 121     SYS=freebsd
 122     CFLAGS="${CFLAGS} -pthread"
 123     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 124     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 125     ac_cv_ld_z_defs=no
 126     ;;
 127   openbsd*)
 128     SYS=openbsd
 129     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 130     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 131     ;;
 132   netbsd*)
 133     SYS=netbsd
 134     ;;
 135   dragonfly*)
 136     SYS=dragonfly
 137     ;;
 138   darwin*)
 139
 140     dnl Force gcc "-arch" flag
 141     ARCH_flag=""
 142     case "${host}" in
 143       i?86*)
 144         ARCH_flag="-arch i386"
 145       ;;
 146       ppc64*)
 147         ARCH_flag="-arch ppc64"
 148       ;;
 149       ppc*)
 150         ARCH_flag="-arch ppc"
 151       ;;
 152       x86_64*)
 153         ARCH_flag="-arch x86_64"
 154       ;;
 155       arm*)
 156         ac_cv_c_bigendian="no"
 157         ac_cv_c_attribute_packed="no"
 158       ;;
 159     esac
 160
 161     SYS=darwin
 162     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 163     CXX="${CXX} -stdlib=libc++ -std=c++11"
 164     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 165     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 166     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
 167     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 168     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 169     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 170
 171     AC_EGREP_CPP(yes,
 172             [#import <TargetConditionals.h>
 173              #if TARGET_OS_IPHONE
 174              yes
 175              #endif],
 176              [HAVE_IOS="1"],
 177              [HAVE_OSX="1"])
 178
 179     AC_EGREP_CPP(yes,
 180             [#import <TargetConditionals.h>
 181              #if TARGET_OS_TV
 182              yes
 183              #endif],
 184              [HAVE_TVOS="1"
 185              HAVE_IOS="0"
 186              HAVE_OSX="0"
 187              ],)
 188
 189     dnl
 190     dnl  Handle Mac OS X SDK flags
 191     dnl
 192     AC_ARG_WITH(macosx-sdk,
 193       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 194         [compile using the SDK in DIR])])
 195     if test "${with_macosx_sdk}" != "" ; then
 196         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 197         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 198         CC="${CC} -isysroot ${with_macosx_sdk}"
 199         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 200         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 201         LD="${LD} -syslibroot ${with_macosx_sdk}"
 202     fi
 203     AC_ARG_WITH(macosx-version-min,
 204       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 205         [compile for Mac OS X VERSION and above])])
 206     if test "${with_macosx_version_min}" != "" ; then
 207         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 208         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 209         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 210         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 211         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 212     fi
 213     ;;
 214   *mingw32* | *cygwin* | *wince* | *mingwce*)
 215     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
 216     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
 217     CXXFLAGS="${CXXFLAGS} -static-libgcc"
 218     AC_CHECK_TOOL(WINDRES, windres, :)
 219     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 220     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
 221     AH_TOP([# define _WIN32_WINNT 0x0601 /* Windows 7 */])
 222     AH_TOP([#endif])
 223     AC_DEFINE([_WIN32_WINNT], 0x0601, [Define to '0x0601' for Windows 7 APIs.])
 224     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 225     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 226     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 227     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 228     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 229     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 230     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 231     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 232     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 233     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 234     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 235
 236     case "${host_os}" in
 237       *mingw32*)
 238         SYS=mingw32
 239         ;;
 240       *cygwin*)
 241         dnl Check if we are using the mno-cygwin mode in which case we are
 242         dnl actually dealing with a mingw32 compiler.
 243         AC_EGREP_CPP(yes,
 244             [#ifdef _WIN32
 245              yes
 246              #endif],
 247             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 248         ;;
 249     esac
 250
 251     if test "${SYS}" = "mingw32"; then
 252         # DEP, ASLR, NO SEH
 253         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 254
 255         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 256         ac_default_prefix="`pwd`/_win32"
 257         DESTDIR="`pwd`/_win32/"
 258
 259         dnl
 260         dnl NSIS/MSI Installer prefix and WIN64
 261         dnl
 262         case "${host}" in
 263             amd64*|x86_64*)
 264                 HAVE_WIN64="1"
 265                 WINDOWS_ARCH="x64"
 266                 PROGRAMFILES="PROGRAMFILES64"
 267                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
 268             ;;
 269             *)
 270                 WINDOWS_ARCH="x86"
 271                 PROGRAMFILES="PROGRAMFILES"
 272             ;;
 273         esac
 274         AC_SUBST(WINDOWS_ARCH)
 275         AC_SUBST(PROGRAMFILES)
 276
 277     fi
 278     ;;
 279   *nto*)
 280     SYS=nto
 281     ;;
 282   solaris*)
 283     SYS=solaris
 284     ;;
 285   hpux*)
 286     SYS=hpux
 287     ;;
 288   *os2*)
 289     SYS=os2
 290     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 291     AC_LIBOBJ([freeaddrinfo])
 292     AC_LIBOBJ([gai_strerror])
 293     AC_CHECK_FUNCS([if_nametoindex])
 294     ;;
 295   *nacl*)
 296     SYS=nacl
 297     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 298     AC_LIBOBJ([sigwait])
 299     AC_LIBOBJ([recvmsg])
 300     AC_LIBOBJ([sendmsg])
 301     ;;
 302   *)
 303     SYS="${host_os}"
 304     ;;
 305 esac
 306
 307 dnl WinRT
 308 AC_ARG_ENABLE(winstore_app,
 309      AS_HELP_STRING([--enable-winstore-app],
 310                     [Build targetted for Windows Store apps (default disabled)]))
 311
 312 vlc_winstore_app=0
 313 AS_IF([test "${SYS}" = "mingw32"],[
 314   LIBCOM="-lole32"
 315   AS_IF([test "${enable_winstore_app}" = "yes"], [
 316     vlc_winstore_app=1
 317     LIBCOM=""
 318      VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
 319      AC_LIBOBJ([gai_strerror])
 320     ],[])
 321   AC_SUBST(LIBCOM)
 322   ])
 323 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 324
 325 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 326 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 327
 328 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 329 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
 330 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
 331 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
 332
 333 AM_CONDITIONAL(HAVE_NACL,    test "${SYS}" = "nacl")
 334 AM_CONDITIONAL(HAVE_LIBANL,  test "${HAVE_LIBANL}" = "1")
 335
 336 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 337 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
 338 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 339 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
 340
 341 dnl
 342 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 343 dnl for program foo on win32
 344 case "${build_os}" in
 345     cygwin|msys|mingw32)
 346         ac_executable_extensions=".exe"
 347         BUILDEXEEXT=".exe"
 348     ;;
 349     os2*)
 350         BUILDEXEEXT=".exe"
 351     ;;
 352     *)
 353     ;;
 354 esac
 355 AC_SUBST(BUILDEXEEXT)
 356
 357 dnl Android is linux, but a bit different
 358 AS_IF([test "$SYS" = linux],[
 359     AC_MSG_CHECKING([for an Android system])
 360     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 361         [[#ifndef __ANDROID__
 362          # error Not Android
 363          #endif
 364         ]],[[;]])
 365     ],[
 366       HAVE_ANDROID="1"
 367       AC_MSG_RESULT([yes])
 368     ],[
 369       AC_MSG_RESULT([no])
 370     ])
 371 ])
 372 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 373
 374 dnl Tizen (minimum SDK version: 2.3)
 375 AS_IF([test "$SYS" = linux],[
 376     AC_MSG_CHECKING([for Tizen])
 377     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 378         [[#include <tizen.h>
 379         ]],[[;]])
 380     ],[
 381       HAVE_TIZEN="1"
 382       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
 383       AC_MSG_RESULT([yes])
 384     ],[
 385       AC_MSG_RESULT([no])
 386     ])
 387 ])
 388 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
 389
 390 dnl
 391 dnl  Check for the contrib directory
 392 dnl
 393 AC_ARG_WITH(contrib,
 394   [AS_HELP_STRING([--with-contrib[=DIR]],
 395     [search for 3rd party libraries in DIR/include and DIR/lib])
 396 ])
 397 AC_MSG_CHECKING([for 3rd party libraries path])
 398 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 399   CONTRIB_DIR="${srcdir}/contrib/${host}"
 400   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 401     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 402     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 403     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 404       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 405       CONTRIB_DIR=""
 406       AC_MSG_RESULT([not found])
 407     ])
 408   ])
 409 ], [
 410   AS_IF([test "${with_contrib}" != "no"], [
 411     CONTRIB_DIR="${with_contrib}"
 412   ], [
 413     CONTRIB_DIR=""
 414     AC_MSG_RESULT([disabled])
 415   ])
 416 ])
 417 AS_IF([test -n "${CONTRIB_DIR}"], [
 418   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 419     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 420   ], [
 421     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 422     CONTRIB_DIR=""
 423     AC_MSG_RESULT([not usable])
 424   ])
 425
 426 ])
 427 AS_IF([test -n "${CONTRIB_DIR}"], [
 428   AC_MSG_RESULT([${CONTRIB_DIR}])
 429   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 430   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 431   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 432   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
 433   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 434   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 435
 436   AS_IF([test -z "$LUAC"], [
 437     dnl Old contribs mixed cross-tools and cross-compiled executables
 438     AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
 439       LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
 440     ])
 441
 442     dnl Newer contribs follow usual name space rules
 443     AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
 444       LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
 445     ])
 446   ])
 447
 448   AS_IF([test "${SYS}" = "darwin"], [
 449     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 450     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 451   ])
 452 ], [
 453   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 454     AC_MSG_ERROR([Third party libraries not found!])
 455   ])
 456 ])
 457 AC_SUBST(CONTRIB_DIR)
 458
 459 dnl Add extras/tools to the PATH
 460 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 461 AS_IF([test -d "${TOOLS_DIR}"], [
 462     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 463     export PATH="${TOOLS_DIR}":$PATH
 464 ])
 465
 466 dnl
 467 dnl  Libtool
 468 dnl  It's very bad, but our former custom system was worst
 469 dnl  -- Courmisch
 470 dnl
 471
 472 dnl override platform specific check for dependent libraries
 473 dnl otherwise libtool linking of shared libraries will
 474 dnl fail on anything other than pass_all.
 475 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 476     [lt_cv_deplibs_check_method=pass_all])
 477
 478 LT_INIT([dlopen win32-dll shared disable-static])
 479 LT_LANG([C++])
 480 LT_LANG([Windows Resource])
 481
 482 DOLT
 483
 484 lt_cv_deplibs_check_method=pass_all
 485
 486 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 487   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 488 ])
 489
 490 dnl
 491 dnl Gettext stuff
 492 dnl
 493 AM_GNU_GETTEXT_VERSION([0.19.8])
 494 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 495
 496 dnl
 497 dnl Iconv stuff
 498 dnl
 499 AM_ICONV
 500
 501 dnl
 502 dnl checks for mingw
 503 AS_IF([test "${SYS}" = "mingw32"], [
 504
 505 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 506 #if !defined(__MINGW32__)
 507 # error Not compiling with mingw
 508 #endif
 509     ])], [
 510
 511 dnl Check for broken versions of mingw-runtime compatability library
 512     AC_MSG_CHECKING(for broken mingw-runtime)
 513     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 514 #include <_mingw.h>
 515 #if defined(__MINGW64_VERSION_MAJOR)
 516 # if __MINGW64_VERSION_MAJOR < 5
 517 #  error Update your mingw-w64! This one is too old.
 518 # endif
 519 #else
 520 # error You cannot compile with Mingw. Use Mingw-w64!
 521 #endif
 522     ])], [
 523         AC_MSG_RESULT([ok])
 524     ], [
 525         AC_MSG_RESULT([present])
 526         AC_MSG_ERROR([LibVLC requires Mingw-w64 version 5.0 or higher!])
 527     ])
 528
 529     dnl force use of mingw provided c99 *printf over msvcrt
 530     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 531
 532     dnl Check for the need to include the mingwex lib for mingw32
 533     VLC_SAVE_FLAGS
 534     AC_CHECK_LIB(mingwex,opendir,
 535         AC_CHECK_LIB(mingw32,opendir,,
 536             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 537     )
 538     VLC_RESTORE_FLAGS
 539     ], [
 540         AC_MSG_RESULT([Not compiling with mingw])
 541     ])
 542
 543     dnl Check for fnative-struct or mms-bitfields support for mingw32
 544     AX_CHECK_COMPILE_FLAG([-mms-bitfields], [
 545         AX_APPEND_FLAG([-mms-bitfields], [CFLAGS])
 546         AX_APPEND_FLAG([-mms-bitfields], [CXXFLAGS])
 547     ], [
 548         AX_CHECK_COMPILE_FLAG([-fnative-struct], [
 549             AX_APPEND_FLAG([-fnative-struct], [CFLAGS])
 550             AX_APPEND_FLAG([-fnative-struct], [CXXFLAGS])
 551         ])
 552     ])
 553 ])
 554
 555
 556 dnl
 557 dnl Buggy glibc prevention. Purposedly not cached.
 558 dnl See sourceware.org bugs 5058 and 5443.
 559 dnl Ubuntu alone has 20 bug numbers for this...
 560 dnl
 561 AC_MSG_CHECKING(for buggy GNU/libc versions)
 562 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 563 #include <limits.h>
 564 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 565   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 566 # error GNU/libc with dcgettext killer bug!
 567 #endif
 568 ])], [
 569   AC_MSG_RESULT([not present])
 570 ], [
 571   AC_MSG_RESULT([found])
 572   AS_IF([test "x${enable_nls}" != "xno"], [
 573     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 574 work-around for this. Check with your distribution vendor on how to update the
 575 glibc run-time. Alternatively, build with --disable-nls.])
 576   ])
 577 ])
 578
 579 dnl Plugin compilation stuff
 580
 581 VLC_LIBRARY_SUFFIX
 582
 583 dnl Check for system libs needed
 584 need_libc=false
 585
 586 dnl Check for usual libc functions
 587 AC_CHECK_FUNCS([accept4 daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty memalign mkostemp mmap open_memstream newlocale openat pipe2 pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp strptime uselocale])
 588 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir flockfile fsync getdelim getpid lldiv memrchr nrand48 poll recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tdestroy tfind timegm timespec_get strverscmp pathconf])
 589 AC_REPLACE_FUNCS([gettimeofday])
 590 AC_CHECK_FUNC(fdatasync,,
 591   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 592 ])
 593
 594 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
 595
 596 dnl mingw64 implements those as static inline, not functions with C linkage
 597 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
 598 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
 599 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
 600 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
 601
 602 dnl C11 static_assert()
 603 AC_MSG_CHECKING([for static_assert in assert.h])
 604 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 605 static_assert(1, "The impossible happened.");
 606 ])], [
 607   AC_MSG_RESULT([yes])
 608   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 609 ], [
 610   AC_MSG_RESULT([no])
 611 ])
 612
 613 # Windows CE does not have strcoll()
 614 AC_FUNC_STRCOLL
 615
 616 dnl Check for non-standard system calls
 617 case "$SYS" in
 618   "linux")
 619     AC_CHECK_FUNCS([eventfd vmsplice sched_getaffinity recvmmsg memfd_create])
 620     ;;
 621   "mingw32")
 622     AC_CHECK_FUNCS([_lock_file])
 623     ;;
 624 esac
 625
 626 AH_BOTTOM([#include <vlc_fixups.h>])
 627
 628 dnl Check for struct pollfd
 629 AC_CHECK_TYPES([struct pollfd],,,
 630 [#include <sys/types.h>
 631 #if HAVE_POLL
 632 # include <poll.h>
 633 #elif defined (_WIN32)
 634 # include <winsock2.h>
 635 #endif
 636 ])
 637
 638 dnl Check for struct timespec
 639 AC_CHECK_TYPES([struct timespec],,,
 640 [#include <time.h>])
 641
 642 dnl Check for max_align_t
 643 AC_CHECK_TYPES([max_align_t],,,
 644 [#include <stddef.h>])
 645
 646 dnl Checks for socket stuff
 647 VLC_SAVE_FLAGS
 648 SOCKET_LIBS=""
 649 AC_SEARCH_LIBS(connect, [socket], [
 650   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 651     SOCKET_LIBS="$ac_cv_search_connect"
 652   ])
 653 ], [
 654   AS_IF([test "${SYS}" = "mingw32"], [
 655     SOCKET_LIBS="-lws2_32 -liphlpapi"
 656   ])
 657 ])
 658
 659 AC_SEARCH_LIBS([inet_pton], [nsl], [
 660  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
 661     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
 662   ])
 663 ],, [${SOCKET_LIBS}])
 664
 665 LIBS="${LIBS} ${SOCKET_LIBS}"
 666 AC_LINK_IFELSE([
 667     AC_LANG_PROGRAM([#ifdef _WIN32
 668         #include <ws2tcpip.h>
 669         #include <windows.h>
 670         # if _WIN32_WINNT < 0x600
 671         #  error Needs vista+
 672         # endif
 673         #else
 674         #include <sys/socket.h>
 675         #include <arpa/inet.h>
 676         #endif], [
 677         char dst[[sizeof(struct in_addr)]];
 678         inet_pton(AF_INET, "127.0.0.1", dst);
 679     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 680 AC_CHECK_FUNCS([if_nameindex])
 681 VLC_RESTORE_FLAGS
 682 AC_SUBST(SOCKET_LIBS)
 683
 684 dnl Check for socklen_t
 685 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 686 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 687 ac_cv_type_socklen_t,
 688 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 689 [#include <sys/types.h>
 690 #ifdef _WIN32
 691 # include <winsock2.h>
 692 # include <ws2tcpip.h>
 693 #else
 694 # include <sys/socket.h>
 695 #endif]], [[socklen_t len; len = 0;]])],
 696 ac_cv_type_socklen_t=yes,
 697 ac_cv_type_socklen_t=no)])
 698 AS_IF([test "$ac_cv_type_socklen_t" = no],
 699  [AC_DEFINE(socklen_t, int)])
 700
 701 dnl Check for struct sockaddr_storage
 702 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 703 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 704 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 705   [AC_TRY_COMPILE(
 706     [#include <sys/types.h>
 707      #if defined( _WIN32 )
 708      # include <winsock2.h>
 709      #else
 710      # include <sys/socket.h>
 711      #endif], [struct sockaddr_storage addr;],
 712      ac_cv_struct_sockaddr_storage=yes,
 713      ac_cv_struct_sockaddr_storage=no)])
 714 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 715   AC_DEFINE(sockaddr_storage, sockaddr)
 716   AC_DEFINE(ss_family, sa_family)
 717 ])
 718
 719 dnl FreeBSD has a gnugetopt library for this:
 720 GNUGETOPT_LIBS=""
 721 AC_CHECK_FUNC(getopt_long,, [
 722   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 723     GNUGETOPT_LIBS="-lgnugetopt"
 724   ])
 725 ])
 726 AC_SUBST(GNUGETOPT_LIBS)
 727
 728 AC_CHECK_LIB(m,cos,[
 729   LIBM="-lm"
 730 ], [
 731   LIBM=""
 732 ])
 733 AC_SUBST(LIBM)
 734
 735 AC_CHECK_LIB(m,lrintf, [
 736   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 737   VLC_ADD_LIBS([skins2],[-lm])
 738 ])
 739 AC_CHECK_LIB(m,nanf,
 740   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 741 )
 742 AC_CHECK_LIB(m,sincos, [
 743   AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
 744 ], [
 745   AC_LIBOBJ([sincos])
 746 ])
 747
 748 AC_MSG_CHECKING([_Thread_local support])
 749 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
 750                    int main() {}])], [
 751     AC_MSG_RESULT([ok])
 752     AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
 753 ],[ AC_MSG_RESULT([no])])
 754
 755 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
 756 dnl check for its availability explicitely
 757 AC_CHECK_HEADERS([threads.h])
 758
 759 AC_CHECK_LIB([anl],[getaddrinfo_a],[
 760   AC_DEFINE(HAVE_LIBANL, 1, [Define to 1 if you have the anl library])
 761 ])
 762
 763 dnl Check for dynamic plugins
 764 LIBDL=""
 765 have_dynamic_objects="no"
 766 VLC_SAVE_FLAGS
 767 AC_SEARCH_LIBS(dlsym, [dl svld], [
 768   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 769     LIBDL="$ac_cv_search_dlsym"
 770   ])
 771   have_dynamic_objects="yes"
 772 ])
 773 VLC_RESTORE_FLAGS
 774
 775 # Windows
 776 AS_IF([test "${SYS}" = "mingw32"], [
 777   LIBDL=""
 778   have_dynamic_objects="yes" #assume we can use shared objects
 779 ])
 780
 781 AC_ARG_WITH([libfuzzer],
 782     [AS_HELP_STRING([--with-libfuzzer=DIR],
 783         [use libFuzzer library from DIR and triggers sanitize coverage (default disabled)])],
 784      [],
 785      [with_libfuzzer=no])
 786 AS_VAR_IF(with_libfuzzer, no, [], [
 787     enable_shared=no
 788     enable_static=yes
 789     enable_vlc=no
 790 ])
 791 AM_CONDITIONAL(HAVE_LIBFUZZER, [test "${with_libfuzzer}" != "no"])
 792
 793 AS_IF([test "${enable_shared}" = "no"], [
 794   have_dynamic_objects=no
 795 ])
 796 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 797
 798 AC_SUBST(LIBDL)
 799
 800 dnl Check for thread library
 801 LIBPTHREAD=""
 802 AS_IF([test "${SYS}" != "mingw32"], [
 803   VLC_SAVE_FLAGS
 804   LIBS=""
 805   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 806     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 807       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 808     ])
 809   ])
 810   VLC_RESTORE_FLAGS
 811 ])
 812 AC_SUBST(LIBPTHREAD)
 813
 814 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
 815   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
 816     LIBRT="$ac_cv_search_clock_nanosleep"
 817   ])
 818 ], [
 819   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
 820     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
 821       LIBRT="$ac_cv_search_nanosleep"
 822     ])
 823   ])
 824 ])
 825 AC_SUBST(LIBRT)
 826
 827 dnl
 828 dnl Check for headers
 829 dnl
 830
 831 dnl  POSIX
 832 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
 833 AC_CHECK_HEADERS([net/if.h], [], [],
 834 [
 835 #include <sys/types.h>
 836 #include <sys/socket.h>
 837 ])
 838 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
 839 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
 840
 841 dnl  BSD
 842 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
 843
 844 dnl  GNU/Linux
 845 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 846
 847 dnl  MacOS
 848 AC_CHECK_HEADERS([xlocale.h])
 849
 850 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 851 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 852 AC_CHECK_TYPE(ssize_t,, [
 853   AC_DEFINE(ssize_t, int)
 854 ])
 855
 856 dnl It seems that autoconf detects pkg-config only during the first
 857 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 858 dnl it is nested within a conditional block, so it was not working right.
 859 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 860 AC_ARG_VAR(PKG_CONFIG_PATH,
 861        [Paths where to find .pc not at the default location])
 862 PKG_PROG_PKG_CONFIG()
 863
 864 dnl On some OS we need static linking
 865 AS_IF([test -n "${PKG_CONFIG}" ],[
 866     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 867         PKG_CONFIG="${PKG_CONFIG} --static"
 868     ])
 869 ])
 870
 871
 872 dnl
 873 dnl Check for zlib.h and -lz along with system -lminizip if available
 874 dnl
 875 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 876 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 877 if test "${have_zlib}" = "yes"
 878 then
 879   VLC_ADD_LIBS([sap],[-lz])
 880   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 881     AC_CHECK_HEADERS([unzip.h], [
 882       have_minizip=yes
 883       MINIZIP_LIBS="-lminizip -lz"
 884     ], [
 885       have_minizip=no
 886     ])
 887   ])
 888 fi
 889 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 890
 891
 892 dnl
 893 dnl Domain name i18n support via GNU libidn
 894 dnl
 895 PKG_CHECK_MODULES([IDN], [libidn], [
 896   have_libidn="yes"
 897   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 898 ], [
 899   have_libidn="no"
 900 ])
 901
 902
 903 dnl Check for dbus
 904 AC_ARG_ENABLE(dbus,
 905   [AS_HELP_STRING([--enable-dbus],
 906     [compile D-Bus message bus support (default enabled)])])
 907 have_dbus="no"
 908 AS_IF([test "${enable_dbus}" != "no"], [
 909   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 910     have_dbus="yes"
 911   ], [
 912     AS_IF([test -n "${enable_dbus}"], [
 913       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 914     ], [
 915       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 916     ])
 917   ])
 918 ])
 919 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 920
 921
 922 dnl Check for systemd
 923 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
 924   have_systemd="yes"
 925 ], [
 926   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
 927 ])
 928 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
 929
 930
 931 EXTEND_HELP_STRING([Optimization options:])
 932 dnl
 933 dnl  Compiler warnings
 934 dnl
 935
 936 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CFLAGS])
 937 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CXXFLAGS])
 938
 939 AX_APPEND_COMPILE_FLAGS([-Wbad-function-cast -Wwrite-strings -Wmissing-prototypes -Werror-implicit-function-declaration -Winit-self -Wlogical-op -Wshadow=local -Wmultistatement-macros], [CFLAGS])
 940 AX_APPEND_COMPILE_FLAGS([-pipe], [CFLAGS])
 941
 942 dnl
 943 dnl  Debugging mode
 944 dnl
 945 AC_ARG_ENABLE(debug,
 946   [AS_HELP_STRING([--enable-debug],
 947     [build with run-time assertions (default disabled)])],,
 948   [enable_debug="no"])
 949 AH_TEMPLATE(NDEBUG,
 950             [Define to 1 if debug code should NOT be compiled])
 951 AS_IF([test "${enable_debug}" != "no"], [
 952   AC_CHECK_HEADERS([valgrind/valgrind.h])
 953 ], [
 954   AC_DEFINE(NDEBUG)
 955 ])
 956
 957 dnl
 958 dnl  Profiling
 959 dnl
 960 AC_ARG_ENABLE(gprof,
 961   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 962   [enable_gprof="no"])
 963 AS_IF([test "${enable_gprof}" != "no"], [
 964   CFLAGS="${CFLAGS} -pg"
 965   CXXFLAGS="${CXXFLAGS} -pg"
 966   OBJCFLAGS="${OBJCFLAGS} -pg"
 967   LDFLAGS="${LDFLAGS} -pg"
 968 ])
 969
 970 AC_ARG_ENABLE(cprof,
 971   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 972   [enable_cprof="no"])
 973 AS_IF([test "${enable_gprof}" != "no"], [
 974   CFLAGS="${CFLAGS} -finstrument-functions"
 975   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 976   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 977   LDFLAGS="${LDFLAGS} -finstrument-functions"
 978 ])
 979
 980 dnl
 981 dnl  Test coverage
 982 dnl
 983 AC_ARG_ENABLE(coverage,
 984   [AS_HELP_STRING([--enable-coverage],
 985     [build for test coverage (default disabled)])],,
 986   [enable_coverage="no"])
 987 AS_IF([test "${enable_coverage}" != "no"], [
 988   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 989   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 990   LDFLAGS="-lgcov ${LDFLAGS}"
 991 ])
 992
 993 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
 994   VLC_SAVE_FLAGS
 995   CFLAGS="${CFLAGS} -fvisibility=hidden"
 996   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
 997   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
 998   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
 999                  [ac_cv_c_visibility_hidden], [
1000     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1001       ac_cv_c_visibility_hidden=yes
1002     ], [
1003       ac_cv_c_visibility_hidden=no
1004     ])
1005   ])
1006   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1007 ])
1008
1009 dnl
1010 dnl Sanitizer flags
1011 dnl
1012 AC_ARG_WITH([sanitizer],
1013     [AS_HELP_STRING([--with-sanitizer=(address/memory/undefined/thread)],
1014         [build with sanitizer flags (default disabled)])],
1015      [],
1016      [with_sanitizer=no])
1017
1018 AS_VAR_IF(with_sanitizer, no, [], [
1019     AX_CHECK_COMPILE_FLAG([-fsanitize=${with_sanitizer}], [
1020         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}])
1021         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [CXXFLAGS])
1022         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [LDFLAGS])
1023     ], [
1024         AC_MSG_ERROR(["-fsanitize=${with_sanitizer} not supported!"])
1025     ])
1026     AX_APPEND_FLAG([-g])
1027     AX_APPEND_FLAG([-g], [CXXFLAGS])
1028
1029     AS_IF([test -z "${with_sanitizer##*address*}" ], [
1030        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer])
1031        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer], [CXXFLAGS])
1032     ])
1033     AS_IF([test -z "${with_sanitizer##*memory*}" ], [
1034         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1035         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1036     ])
1037     AS_IF([test -z "${with_sanitizer##*thread*}" ], [
1038         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1039         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1040     ])
1041 ])
1042
1043 dnl
1044 dnl  Enable/disable optimizations
1045 dnl
1046 AC_ARG_ENABLE(optimizations,
1047   [AS_HELP_STRING([--disable-optimizations],
1048     [disable compiler optimizations (default enabled)])],,
1049   [enable_optimizations="yes"])
1050
1051 dnl Check for various optimization flags
1052 AS_IF([test "${enable_optimizations}" != "no"], [
1053
1054   dnl -O3 only in production builds
1055   AS_IF([test "${enable_debug}" = "no"], [
1056     VLC_SAVE_FLAGS
1057     CFLAGS="${CFLAGS} -O3"
1058     CXXFLAGS="${CXXFLAGS} -O3"
1059     OBJCFLAGS="${OBJCFLAGS} -O3"
1060     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1061       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1062         ac_cv_c_o3=yes
1063       ], [
1064         ac_cv_c_o3=no
1065       ])
1066     ])
1067     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1068   ])
1069
1070   dnl Check for fast maths
1071   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CFLAGS])
1072   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CXXFLAGS])
1073
1074 AH_BOTTOM([
1075 #if defined(_MSC_VER) && !defined(__clang__)
1076 # pragma fenv_access(off)
1077 # pragma fp_contract(on)
1078 #elif defined(__GNUC__)
1079 /* Not supported so far */
1080 #else
1081 # pragma STDC FENV_ACCESS OFF
1082 # pragma STDC FP_CONTRACT ON
1083 #endif
1084 ])
1085
1086   dnl Check for -funroll-loops
1087   VLC_SAVE_FLAGS
1088   CFLAGS="${CFLAGS} -funroll-loops"
1089   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1090   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1091   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1092     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1093       ac_cv_c_unroll_loops=yes
1094     ], [
1095       ac_cv_c_unroll_loops=no
1096     ])
1097   ])
1098   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1099
1100   AS_IF([test "$enable_debug" = "no"], [
1101     dnl Check for -fomit-frame-pointer
1102     VLC_SAVE_FLAGS
1103     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1104     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1105     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1106     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1107       [ac_cv_c_omit_frame_pointer], [
1108       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1109         ac_cv_c_omit_frame_pointer=yes
1110       ], [
1111         ac_cv_c_omit_frame_pointer=no
1112       ])
1113     ])
1114     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1115   ])
1116
1117   AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong])
1118   AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong], [CXXFLAGS])
1119   dnl Win32 requires linking to ssp for stack-protection
1120   AS_IF([test "${SYS}" = "mingw32"], [
1121       LDFLAGS="${LDFLAGS} -lssp"
1122       AS_IF([test "${vlc_winstore_app}" != 1], [LDFLAGS="${LDFLAGS} -ladvapi32"])
1123   ])
1124 ])
1125
1126 VLC_SAVE_FLAGS
1127 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1128 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1129   AC_TRY_LINK([],, [
1130     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1131   ], [
1132     ac_cv_ld_bsymbolic=""
1133   ])
1134 ])
1135 VLC_RESTORE_FLAGS
1136 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1137 AC_SUBST(SYMBOLIC_LDFLAGS)
1138
1139 VLC_SAVE_FLAGS
1140 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1141 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1142   AC_TRY_LINK([],, [
1143     ac_cv_ld_z_defs="yes"
1144   ], [
1145     ac_cv_ld_z_defs="no"
1146   ])
1147 ])
1148 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1149
1150 dnl Check for __attribute__((packed))
1151 AC_CACHE_CHECK([for __attribute__((packed))],
1152   [ac_cv_c_attribute_packed],
1153   [ac_cv_c_attribute_packed=no
1154    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1155                     [ac_cv_c_attribute_packed=yes])])
1156 if test "${ac_cv_c_attribute_packed}" != "no"; then
1157   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1158 fi
1159
1160 dnl
1161 dnl  Check the CPU
1162 dnl
1163 case "${host_cpu}" in
1164   "")
1165     ARCH=unknown
1166     ;;
1167   armv*)
1168     ARCH="arm"
1169     host_cpu="arm"
1170     ;;
1171   *)
1172     ARCH="${host_cpu}"
1173     ;;
1174 esac
1175
1176 dnl Check for backtrace() support
1177 AC_CHECK_HEADERS(execinfo.h)
1178 AC_CHECK_FUNCS(backtrace)
1179
1180 dnl
1181 dnl  default modules
1182 dnl
1183 ALIASES="${ALIASES} cvlc rvlc"
1184
1185 dnl
1186 dnl  Accelerated modules
1187 dnl
1188
1189 dnl  Check for fully working MMX intrinsics
1190 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1191 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1192 AC_ARG_ENABLE(mmx,
1193   [AS_HELP_STRING([--disable-mmx],
1194     [disable MMX optimizations (default auto)])],,[
1195   case "${host_cpu}" in
1196     i?86|x86_64)
1197       enable_mmx="yes"
1198       ;;
1199     *)
1200       enable_mmx="no"
1201       ;;
1202   esac
1203 ])
1204 have_mmx="no"
1205 have_mmxext="no"
1206 AS_IF([test "${enable_mmx}" != "no"], [
1207   ARCH="${ARCH} mmx"
1208   VLC_SAVE_FLAGS
1209   CFLAGS="${CFLAGS} -mmmx"
1210   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1211     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1212 [#include <mmintrin.h>
1213 #include <stdint.h>
1214 uint64_t frobzor;]], [
1215 [__m64 a, b, c;
1216 a = b = c = (__m64)frobzor;
1217 a = _mm_slli_pi16(a, 3);
1218 a = _mm_adds_pi16(a, b);
1219 c = _mm_srli_pi16(c, 8);
1220 c = _mm_slli_pi16(c, 3);
1221 b = _mm_adds_pi16(b, c);
1222 a = _mm_unpacklo_pi8(a, b);
1223 frobzor = (uint64_t)a;]])], [
1224       ac_cv_c_mmx_intrinsics=yes
1225     ], [
1226       ac_cv_c_mmx_intrinsics=no
1227     ])
1228   ])
1229   VLC_RESTORE_FLAGS
1230   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1231     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1232   ])
1233
1234   VLC_SAVE_FLAGS
1235   CFLAGS="${CFLAGS} -mmmx"
1236   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1237     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1238 void *p;
1239 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1240 ]])
1241     ], [
1242       ac_cv_mmx_inline=yes
1243     ], [
1244       ac_cv_mmx_inline=no
1245     ])
1246   ])
1247   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1248     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1249     have_mmx="yes"
1250   ])
1251
1252   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1253                  [ac_cv_mmxext_inline], [
1254     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1255 void *p;
1256 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1257 ]])
1258     ], [
1259       ac_cv_mmxext_inline=yes
1260     ], [
1261       ac_cv_mmxext_inline=no
1262     ])
1263   ])
1264   VLC_RESTORE_FLAGS
1265   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1266     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1267     have_mmxext="yes"
1268   ])
1269 ])
1270 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1271 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1272
1273 dnl  Check for fully workin SSE2 intrinsics
1274 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1275 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1276 AC_ARG_ENABLE(sse,
1277   [AS_HELP_STRING([--disable-sse],
1278     [disable SSE (1-4) optimizations (default auto)])],, [
1279   case "${host_cpu}" in
1280     i?86|x86_64)
1281       enable_sse=yes
1282       ;;
1283     *)
1284       enable_sse=no
1285       ;;
1286   esac
1287 ])
1288 have_sse2="no"
1289 AS_IF([test "${enable_sse}" != "no"], [
1290   ARCH="${ARCH} sse sse2"
1291
1292   VLC_SAVE_FLAGS
1293   CFLAGS="${CFLAGS} -msse2"
1294   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1295     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1296 [#include <emmintrin.h>
1297 #include <stdint.h>
1298 uint64_t frobzor;]], [
1299 [__m128i a, b, c;
1300 a = b = c = _mm_set1_epi64((__m64)frobzor);
1301 a = _mm_slli_epi16(a, 3);
1302 a = _mm_adds_epi16(a, b);
1303 c = _mm_srli_epi16(c, 8);
1304 c = _mm_slli_epi16(c, 3);
1305 b = _mm_adds_epi16(b, c);
1306 a = _mm_unpacklo_epi8(a, b);
1307 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1308       ac_cv_c_sse2_intrinsics=yes
1309     ], [
1310       ac_cv_c_sse2_intrinsics=no
1311     ])
1312   ])
1313   VLC_RESTORE_FLAGS
1314   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1315     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1316   ])
1317
1318   VLC_SAVE_FLAGS
1319   CFLAGS="${CFLAGS} -msse"
1320   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1321     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1322 void *p;
1323 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1324 ]])
1325     ], [
1326       ac_cv_sse_inline=yes
1327     ], [
1328       ac_cv_sse_inline=no
1329     ])
1330   ])
1331
1332   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1333     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1334   ])
1335
1336   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1337     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1338 void *p;
1339 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1340 ]])
1341     ], [
1342       ac_cv_sse2_inline=yes
1343     ], [
1344       ac_cv_sse2_inline=no
1345     ])
1346   ])
1347   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1348     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1349     have_sse2="yes"
1350   ])
1351
1352   # SSE3
1353   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1354     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1355 void *p;
1356 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1357 ]])
1358     ], [
1359       ac_cv_sse3_inline=yes
1360     ], [
1361       ac_cv_sse3_inline=no
1362     ])
1363   ])
1364
1365   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1366     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1367   # SSSE3
1368   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1369     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1370 void *p;
1371 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1372 ]])
1373     ], [
1374       ac_cv_ssse3_inline=yes
1375     ], [
1376       ac_cv_ssse3_inline=no
1377     ])
1378   ])
1379
1380   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1381     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1382
1383   # SSE4.1
1384   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1385                  [ac_cv_sse4_1_inline], [
1386     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1387 void *p;
1388 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1389 ]])
1390     ], [
1391       ac_cv_sse4_1_inline=yes
1392     ], [
1393       ac_cv_sse4_1_inline=no
1394     ])
1395   ])
1396
1397   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1398     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1399
1400   # SSE4.2
1401   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1402                  [ac_cv_sse4_2_inline], [
1403     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1404 void *p;
1405 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1406 ]])
1407     ], [
1408       ac_cv_sse4_2_inline=yes
1409     ], [
1410       ac_cv_sse4_2_inline=no
1411     ])
1412   ])
1413
1414   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1415     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1416
1417   # SSE4A
1418   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1419     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1420 void *p;
1421 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1422 ]])
1423     ], [
1424       ac_cv_sse4a_inline=yes
1425     ], [
1426       ac_cv_sse4a_inline=no
1427     ])
1428   ])
1429   VLC_RESTORE_FLAGS
1430   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1431     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1432 ])
1433 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1434
1435 VLC_SAVE_FLAGS
1436 CFLAGS="${CFLAGS} -mmmx"
1437 have_3dnow="no"
1438 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1439   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1440 void *p;
1441 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1442 ]])
1443   ], [
1444     ac_cv_3dnow_inline=yes
1445   ], [
1446     ac_cv_3dnow_inline=no
1447   ])
1448 ])
1449 VLC_RESTORE_FLAGS
1450 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1451   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1452             [Define to 1 if 3D Now! inline assembly is available.])
1453   have_3dnow="yes"
1454 ])
1455 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1456
1457
1458 AC_ARG_ENABLE(neon,
1459   [AS_HELP_STRING([--disable-neon],
1460     [disable NEON optimizations (default auto)])],, [
1461   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1462 ])
1463 AS_IF([test "${enable_neon}" != "no"], [
1464   VLC_SAVE_FLAGS
1465   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1466   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1467     AC_COMPILE_IFELSE([
1468       AC_LANG_PROGRAM(,[[
1469 asm volatile("vqmovun.s64 d0, q1":::"d0");
1470 ]])
1471     ], [
1472       ac_cv_arm_neon="yes"
1473     ], [
1474       ac_cv_arm_neon="no"
1475     ])
1476   ])
1477   VLC_RESTORE_FLAGS
1478 ])
1479 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1480
1481 AC_ARG_ENABLE(arm64,
1482   [AS_HELP_STRING([--disable-arm64],
1483     [disable arm 64-bit optimizations (default auto)])],, [
1484   AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1485 ])
1486 AS_IF([test "${enable_arm64}" != "no"], [
1487   AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1488     AC_COMPILE_IFELSE([
1489       AC_LANG_PROGRAM(,[[
1490 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1491 ]])
1492     ], [
1493       ac_cv_arm64="yes"
1494     ], [
1495       ac_cv_arm64="no"
1496     ])
1497   ])
1498 ])
1499 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1500
1501
1502 AC_ARG_ENABLE(altivec,
1503   [AS_HELP_STRING([--disable-altivec],
1504     [disable AltiVec optimizations (default auto)])],, [
1505   AS_CASE("${host_cpu}", [powerpc*],
1506         [enable_altivec=yes], [enable_altivec=no])
1507 ])
1508 have_altivec="no"
1509 ALTIVEC_CFLAGS=""
1510 AS_IF([test "${enable_altivec}" = "yes"], [
1511   ARCH="${ARCH} altivec";
1512   VLC_SAVE_FLAGS
1513   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1514     [ac_cv_altivec_inline],
1515     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1516          ac_cv_altivec_inline="yes",
1517          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1518           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1519             [ac_cv_altivec_inline="-Wa,-maltivec"],
1520             ac_cv_altivec_inline=no)
1521          ])])
1522   VLC_RESTORE_FLAGS
1523   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1524     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1525               [Define to 1 if AltiVec inline assembly is available.])
1526     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1527       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1528       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1529     ])
1530     have_altivec="yes"
1531   ])
1532
1533   VLC_SAVE_FLAGS
1534   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1535   [ac_cv_c_altivec], [
1536     CFLAGS="${CFLAGS} -maltivec"
1537     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1538 [#include <altivec.h>]], [
1539 [vec_ld(0, (unsigned char *)0);]])], [
1540       ac_cv_c_altivec="-maltivec"
1541     ], [
1542       ac_cv_c_altivec="no"
1543     ])
1544   ])
1545   VLC_RESTORE_FLAGS
1546   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1547     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1548     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1549     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1550     ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1551     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1552     have_altivec="yes"
1553   ])
1554   AC_CHECK_HEADERS(altivec.h)
1555
1556   VLC_SAVE_FLAGS
1557   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1558   AC_CACHE_CHECK([if linker needs -framework vecLib],
1559     [ac_cv_ld_altivec],
1560     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1561   VLC_RESTORE_FLAGS
1562   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1563     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1564   ])
1565 ])
1566 AC_SUBST(ALTIVEC_CFLAGS)
1567 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1568
1569 dnl
1570 dnl  Memory usage
1571 dnl
1572 AC_ARG_ENABLE(optimize-memory,
1573   [AS_HELP_STRING([--enable-optimize-memory],
1574     [optimize memory usage over performance])])
1575 if test "${enable_optimize_memory}" = "yes"; then
1576   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1577 fi
1578
1579 dnl
1580 dnl Allow running as root (useful for people running on embedded platforms)
1581 dnl
1582 AC_ARG_ENABLE(run-as-root,
1583   [AS_HELP_STRING([--enable-run-as-root],
1584     [allow running VLC as root (default disabled)])])
1585 AS_IF([test "${enable_run_as_root}" = "yes"],[
1586     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1587               [Define to 1 to allow running VLC as root (uid 0).])
1588 ])
1589
1590 dnl
1591 dnl Stream output
1592 dnl
1593 AC_ARG_ENABLE(sout,
1594   [AS_HELP_STRING([--disable-sout],
1595     [disable streaming output (default enabled)])])
1596 AS_IF([test "${enable_sout}" != "no"], [
1597   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1598 ])
1599 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1600
1601 dnl Lua modules
1602 AC_ARG_ENABLE(lua,
1603   [AS_HELP_STRING([--disable-lua],
1604     [disable LUA scripting support (default enabled)])])
1605 if test "${enable_lua}" != "no"
1606 then
1607   PKG_CHECK_MODULES(LUA, lua5.2,
1608     [ have_lua=yes ],
1609     [
1610     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1611
1612     PKG_CHECK_MODULES(LUA, lua5.1,
1613       [ have_lua=yes ],
1614       [
1615       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1616       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1617         [ have_lua=yes ],
1618         [
1619           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1620           have_lua=yes
1621           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1622             [],
1623             [ have_lua=no ] )
1624           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1625             [LUA_LIBS="-llua5.2"],
1626           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1627             [LUA_LIBS="-llua5.1"],
1628             AC_CHECK_LIB( lua51 , luaL_newstate,
1629               [LUA_LIBS="-llua51"],
1630               AC_CHECK_LIB( lua , luaL_newstate,
1631                 [LUA_LIBS="-llua"],
1632                 [ have_lua=no
1633                 ], [-lm])
1634             )))
1635         ])
1636       ])
1637     ])
1638   if test "x${have_lua}" != "xyes" ;  then
1639       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1640   fi
1641   AC_ARG_VAR([LUAC], [LUA byte compiler])
1642   AS_IF([test -z "$LUAC"], [
1643      AC_CHECK_TOOL(LUAC, [luac], [false])
1644   ])
1645   AS_IF([test "${LUAC}" = "false"], [
1646     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1647   ])
1648   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1649     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1650   ])
1651 fi
1652 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1653
1654
1655 dnl
1656 dnl VideoLAN manager
1657 dnl
1658 AC_ARG_ENABLE(vlm,
1659   [AS_HELP_STRING([--disable-vlm],
1660     [disable the stream manager (default enabled)])],,
1661   [enable_vlm="${enable_sout}"])
1662 AS_IF([test "${enable_vlm}" != "no"], [
1663   AS_IF([test "${enable_sout}" = "no"], [
1664     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1665   ])
1666   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1667 ])
1668 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1669
1670
1671 dnl
1672 dnl Addons manager storage and repositories modules
1673 dnl
1674 AC_ARG_ENABLE(addonmanagermodules,
1675   [AS_HELP_STRING([--disable-addonmanagermodules],
1676     [disable the addons manager modules (default enabled)])])
1677 if test "${enable_addonmanagermodules}" != "no"
1678 then
1679   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1680 fi
1681 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1682
1683
1684 dnl
1685 dnl  Input plugins
1686 dnl
1687
1688 EXTEND_HELP_STRING([Input plugins:])
1689
1690 dnl
1691 dnl  libarchive access module
1692 dnl
1693 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1694
1695 dnl
1696 dnl  live555 input
1697 dnl
1698 AC_ARG_ENABLE(live555,
1699   [AS_HELP_STRING([--enable-live555],
1700     [enable RTSP input through live555 (default enabled)])])
1701
1702 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1703   PKG_CHECK_MODULES(LIVE555, live555, [
1704     VLC_ADD_PLUGIN([live555])
1705     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1706     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1707   ], [
1708     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1709
1710     AC_LANG_PUSH(C++)
1711     VLC_SAVE_FLAGS
1712
1713     dnl detect include paths
1714     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1715       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1716     ], [
1717       AS_IF([test "${SYS}" != "os2"], [
1718         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1719         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1720       ], [
1721         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1722         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1723         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1724       ])
1725     ])
1726
1727     dnl CPP Flags
1728     AS_IF([test "${SYS}" = "solaris"], [
1729       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1730     ])
1731     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1732     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1733
1734     dnl version check
1735     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1736       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1737 [#include <liveMedia_version.hh>
1738 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1739 # error BOOM
1740 #endif]])
1741       ], [
1742         ac_cv_live555="yes"
1743       ], [
1744         ac_cv_live555="no"
1745       ])
1746     ])
1747
1748     AS_IF([test "$ac_cv_live555" = "no"], [
1749       AC_MSG_WARN([live555 is missing or its installed version is too old:
1750 Version 2011.12.23 or later is required to proceed.
1751 You can get an updated one from http://www.live555.com/liveMedia .])
1752       AS_IF([test -n "${enable_live555}"], [
1753         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1754       ])
1755     ], [
1756       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1757       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1758       AS_IF([test "${SYS}" = "mingw32"], [
1759         # add ws2_32 for closesocket, select, recv
1760         other_libs="$other_libs -lws2_32"
1761       ])
1762
1763       dnl We need to check for pic because live555 don't provide shared libs
1764       dnl and we want to build a plugins so we need -fPIC on some arch.
1765       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1766       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1767       AC_CHECK_LIB(liveMedia_pic, main, [
1768         VLC_ADD_PLUGIN([live555])
1769         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1770       ],[
1771         AC_CHECK_LIB(liveMedia, main, [
1772           VLC_ADD_PLUGIN([live555])
1773           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1774         ],[],[${other_libs}])
1775       ],[${other_libs_pic}])
1776     ])
1777     VLC_RESTORE_FLAGS
1778     AC_LANG_POP(C++)
1779   ])
1780 ])
1781
1782 dnl
1783 dnl IIDC and DV FireWire input modules
1784 dnl
1785 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1786 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1787
1788 dnl
1789 dnl - linsys modules: access module check for libzvbi
1790 dnl
1791 AC_ARG_ENABLE(linsys,
1792   [AS_HELP_STRING([--enable-linsys],
1793     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1794 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1795   VLC_ADD_PLUGIN([linsys_hdsdi])
1796   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1797     VLC_ADD_PLUGIN([linsys_sdi])
1798   ], [
1799     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1800   ])
1801 ])
1802
1803 dnl
1804 dnl dvdread module: check for libdvdread
1805 dnl
1806 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1807
1808 dnl
1809 dnl libdvdnav plugin
1810 dnl
1811 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1812 AS_IF([test "${enable_dvdnav}" != "no"], [
1813   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1814     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1815       AC_MSG_RESULT(yes)
1816       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1817       ],[
1818       AC_MSG_RESULT(no)
1819     ])
1820 ])
1821
1822 dnl
1823 dnl  Blu-ray Disc Support with libbluray
1824 dnl
1825 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1826
1827 dnl
1828 dnl  OpenCV wrapper and example filters
1829 dnl
1830 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1831
1832
1833 dnl
1834 dnl  libsmbclient plugin
1835 dnl
1836 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1837 AS_IF([test "${SYS}" = "mingw32" -a "${enable_winstore_app}" != "yes"], [ VLC_ADD_PLUGIN([smb]) ])
1838
1839 dnl
1840 dnl  liBDSM access module
1841 dnl
1842 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1843
1844 dnl
1845 dnl sftp access support
1846 dnl
1847 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1848
1849 dnl
1850 dnl nfs access support
1851 dnl
1852 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1853
1854 dnl
1855 dnl  Video4Linux 2
1856 dnl
1857 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1858   [disable Video4Linux version 2 (default auto)])])
1859 have_v4l2="no"
1860 AS_IF([test "$enable_v4l2" != "no"], [
1861   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1862     have_v4l2="yes"
1863   ])
1864 ])
1865 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1866
1867 dnl
1868 dnl special access module for Blackmagic SDI cards
1869 dnl
1870 AC_ARG_ENABLE(decklink,
1871   [AS_HELP_STRING([--disable-decklink],
1872     [disable Blackmagic DeckLink SDI input (default auto)])])
1873 AC_ARG_WITH(decklink_sdk,
1874   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1875     [                        location of Blackmagic DeckLink SDI SDK])])
1876 have_decklink=no
1877 if test "${enable_decklink}" != "no"
1878 then
1879   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1880   then
1881     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1882   fi
1883   VLC_SAVE_FLAGS
1884   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1885   AC_LANG_PUSH(C++)
1886   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1887       have_decklink=yes
1888   ], [
1889       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1890   ])
1891   AC_LANG_POP(C++)
1892   VLC_RESTORE_FLAGS
1893 fi
1894 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1895
1896
1897 dnl
1898 dnl  Built-in CD-DA and VCD module
1899 dnl
1900 AC_ARG_ENABLE(vcd,
1901   [AS_HELP_STRING([--disable-vcd],
1902     [disable built-in VCD and CD-DA support (default enabled)])])
1903
1904 AC_ARG_ENABLE(libcddb,
1905   [AS_HELP_STRING([--disable-libcddb],
1906     [disable CDDB for Audio CD (default enabled)])])
1907
1908 if test "${enable_vcd}" != "no"
1909 then
1910   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1911   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1912     AC_MSG_RESULT(yes)
1913     VLC_ADD_PLUGIN([vcd cdda])
1914   ],[
1915     AC_MSG_RESULT(no)
1916   ])
1917
1918   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1919   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1920     AC_MSG_RESULT(yes)
1921     VLC_ADD_PLUGIN([vcd cdda])
1922     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1923   ],[
1924     AC_MSG_RESULT(no)
1925   ])
1926
1927   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1928   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1929     AC_MSG_RESULT(yes)
1930     VLC_ADD_PLUGIN([vcd cdda])
1931     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1932   ],[
1933     AC_MSG_RESULT(no)
1934   ])
1935
1936   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1937   then
1938     VLC_ADD_PLUGIN([vcd cdda])
1939   fi
1940
1941   if test "$enable_libcddb" != "no"; then
1942     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1943       HAVE_LIBCDDB=yes
1944       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1945       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1946       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1947       ],:
1948       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1949       HAVE_LIBCDDB=no])
1950   fi
1951 fi
1952
1953 dnl
1954 dnl Linux DVB
1955 dnl
1956 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1957   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1958 [#include <linux/dvb/version.h>
1959 #if (DVB_API_VERSION < 5)
1960 # error Linux DVB API v3.2 and older are not supported.
1961 #endif
1962 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1963 # error Linux DVB API v5.0 is unsupported. Please update.
1964 #endif
1965 ]])], [
1966   ac_cv_linux_dvb_5_1=yes
1967 ], [
1968   ac_cv_linux_dvb_5_1=no
1969 ])])
1970 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1971
1972 dnl
1973 dnl  Screen capture module
1974 dnl
1975 AC_ARG_ENABLE(screen,
1976   [AS_HELP_STRING([--enable-screen],
1977     [disable screen capture (default enabled)])])
1978 if test "${enable_screen}" != "no"; then
1979   if test "${SYS}" = "darwin"; then
1980     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1981       VLC_ADD_PLUGIN([screen])
1982     ])
1983   fi
1984 fi
1985 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1986
1987 dnl
1988 dnl  VNC/RFB access module
1989 dnl
1990 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1991
1992 dnl  RDP/Remote Desktop access module
1993 dnl
1994 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1995
1996 dnl
1997 dnl  Real RTSP plugin
1998 dnl
1999 AC_ARG_ENABLE(realrtsp,
2000   [  --enable-realrtsp       Real RTSP module (default disabled)])
2001 if test "${enable_realrtsp}" = "yes"; then
2002   VLC_ADD_PLUGIN([access_realrtsp])
2003 fi
2004
2005 dnl
2006 dnl QTKit
2007 AC_ARG_ENABLE(macosx-qtkit,
2008   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
2009 if test "x${enable_macosx_qtkit}" != "xno" &&
2010   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
2011 then
2012   AC_CHECK_HEADERS(QTKit/QTKit.h, [
2013       VLC_ADD_PLUGIN([qtsound])
2014     ])
2015 fi
2016
2017 dnl
2018 dnl AVFoundation
2019 AC_SUBST(have_avfoundation, ["no"])
2020 AC_ARG_ENABLE(macosx-avfoundation,
2021   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
2022 if test "x${enable_macosx_avfoundation}" != "xno" &&
2023   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2024 then
2025   SAVED_LIBS="${LIBS}"
2026   LIBS="-framework AVFoundation"
2027   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2028   LIBS="${SAVED_LIBS}"
2029   if test "${have_avfoundation}" != "no"
2030   then
2031     VLC_ADD_PLUGIN([avcapture])
2032   fi
2033 fi
2034 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2035
2036 dnl
2037 dnl  DCP plugin (using asdcplib)
2038 dnl
2039 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2040 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2041
2042 dnl
2043 dnl  Demux plugins
2044 dnl
2045
2046 EXTEND_HELP_STRING([Mux/Demux plugins:])
2047
2048 dnl
2049 dnl  libdvbpsi check for ts mux/demux
2050 dnl
2051 have_dvbpsi="no"
2052 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2053 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2054
2055
2056 dnl
2057 dnl  GME demux plugin
2058 dnl
2059 AC_ARG_ENABLE(gme,
2060   [AS_HELP_STRING([--enable-gme],
2061     [use Game Music Emu (default auto)])])
2062 AS_IF([test "${enable_gme}" != "no"], [
2063   AC_CHECK_HEADER([gme/gme.h], [
2064     AC_CHECK_LIB([gme], [gme_identify_header], [
2065       VLC_ADD_PLUGIN([gme])
2066     ], [
2067       AC_CHECK_LIB([gme], [gme_identify_extension], [
2068          VLC_ADD_LIBS([gme], [-lstdc++ $LIBM])
2069          VLC_ADD_PLUGIN([gme])
2070       ],, [-lstdc++ $LIBM])
2071     ])
2072     VLC_ADD_LIBS([gme], [-lgme])
2073   ], [
2074     AS_IF([test "x${enable_gme}" != "x"], [
2075       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2076     ])
2077   ])
2078 ])
2079
2080
2081 dnl
2082 dnl  SIDPlay plugin
2083 dnl
2084 AC_ARG_ENABLE(sid,
2085     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2086 AS_IF([test "${enable_sid}" != "no"], [
2087     PKG_CHECK_MODULES(SID, [libsidplay2], [
2088         AC_LANG_PUSH(C++)
2089         oldCPPFLAGS="$CPPFLAGS"
2090         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2091         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2092             VLC_ADD_PLUGIN([sid])
2093             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2094             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2095         ], [
2096             AS_IF([test -n "${enable_sid}"],
2097                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2098                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2099                 )
2100         ])
2101         CPPFLAGS="$oldCPPFLAGS"
2102         AC_LANG_POP(C++)
2103     ], [
2104         AS_IF([test "x${enable_sid}" = "xyes"],
2105             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2106             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2107             )
2108     ])
2109 ])
2110
2111
2112 dnl
2113 dnl  ogg demux plugin
2114 dnl
2115 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2116 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2117     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2118 ],[true])
2119 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2120 if test "${enable_sout}" != "no"; then
2121 dnl Check for libshout
2122     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2123 fi
2124
2125 dnl
2126 dnl  matroska demux plugin
2127 dnl
2128 PKG_ENABLE_MODULES_VLC([MATROSKA], [mkv], [libebml libmatroska], [MKV format support], [auto])
2129
2130 dnl
2131 dnl  modplug demux plugin
2132 dnl
2133 AC_ARG_ENABLE(mod,
2134   [AS_HELP_STRING([--disable-mod],
2135     [do not use libmodplug (default auto)])])
2136 if test "${enable_mod}" != "no" ; then
2137     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2138           VLC_ADD_PLUGIN([mod])
2139           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2140           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2141           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2142     ],[
2143        AS_IF([test -n "${enable_mod}"],
2144          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2145          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2146     ])
2147 fi
2148
2149 dnl
2150 dnl  mpc demux plugin
2151 dnl
2152 AC_ARG_ENABLE(mpc,
2153   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2154 if test "${enable_mpc}" != "no"
2155 then
2156   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2157     VLC_ADD_PLUGIN([mpc])
2158     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2159     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2160     VLC_ADD_PLUGIN([mpc])
2161     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2162 fi
2163
2164 dnl
2165 dnl  Codec plugins
2166 dnl
2167
2168 EXTEND_HELP_STRING([Codec plugins:])
2169
2170 dnl
2171 dnl wmafixed plugin
2172 dnl
2173 AC_ARG_ENABLE(wma-fixed,
2174   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2175 if test "${enable_wma_fixed}" = "yes"
2176 then
2177   VLC_ADD_PLUGIN([wma_fixed])
2178 fi
2179
2180 dnl
2181 dnl shine encoder plugin
2182 dnl
2183 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2184
2185
2186 dnl
2187 dnl openmax il codec plugin
2188 dnl
2189 AC_ARG_ENABLE(omxil,
2190   [  --enable-omxil          openmax il codec module (default disabled)])
2191 if test "${enable_omxil}" = "yes"
2192 then
2193   VLC_ADD_PLUGIN([omxil])
2194 fi
2195
2196 dnl
2197 dnl raspberry pi openmax il configuration
2198 dnl
2199 AC_ARG_ENABLE(rpi-omxil,
2200   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2201 if test "${enable_rpi_omxil}" = "yes"
2202 then
2203   VLC_ADD_PLUGIN([omxil])
2204   VLC_ADD_CFLAGS([omxil],[-DRPI_OMX])
2205 fi
2206
2207 dnl
2208 dnl CrystalHD codec plugin
2209 dnl
2210 AC_ARG_ENABLE(crystalhd,
2211   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2212 if test "${enable_crystalhd}" != "no"; then
2213     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2214       VLC_ADD_PLUGIN([crystalhd])
2215       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2216     ],[
2217       if test "${SYS}" = "mingw32" ; then
2218         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2219           VLC_ADD_PLUGIN([crystalhd])
2220           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2221             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2222             ])
2223         ],[
2224           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2225                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2226                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2227         ],[#define __LINUX_USER__
2228                #include <libcrystalhd/bc_dts_types.h>
2229         ])
2230       fi
2231     ],[
2232        #include <libcrystalhd/bc_dts_types.h>
2233       ])
2234 fi
2235
2236 dnl
2237 dnl  mad plugin
2238 dnl
2239 have_mad="no"
2240 MAD_CFLAGS=""
2241 MAD_LIBS=""
2242
2243 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2244   enable_mad="yes"
2245 ], [
2246   with_mad="no"
2247 ])
2248 AS_IF([test "${with_mad}" != "no"], [
2249   MAD_CFLAGS="-I${with_mad}/include"
2250   MAD_LIBS="-L${with_mad}/lib"
2251 ])
2252
2253 AC_ARG_ENABLE(mad,
2254   [  --enable-mad            libmad module (default enabled)])
2255 AS_IF([test "${enable_mad}" != "no"], [
2256   VLC_SAVE_FLAGS
2257   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2258   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2259   AC_CHECK_HEADERS(mad.h, [
2260     AC_CHECK_LIB(mad, mad_bit_init, [
2261       have_mad="yes"
2262       MAD_LIBS="${MAD_LIBS} -lmad"
2263     ])
2264   ])
2265   VLC_RESTORE_FLAGS
2266   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2267     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2268   ])
2269 ])
2270 AC_SUBST(MAD_CFLAGS)
2271 AC_SUBST(MAD_LIBS)
2272 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2273
2274 dnl  mpg123 plugin
2275 dnl
2276 dnl
2277 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2278
2279 dnl
2280 dnl gstreamer stuff
2281 dnl
2282 AC_ARG_ENABLE(gst-decode,
2283   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2284
2285 have_gst_decode="no"
2286 AS_IF([test "${enable_gst_decode}" != "no"], [
2287   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2288     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2289       have_gst_decode="yes"
2290     ], [
2291       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2292     ])
2293   ], [
2294     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2295   ])
2296 ])
2297 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2298
2299 dnl
2300 dnl  avcodec decoder/encoder plugin
2301 dnl
2302 AC_ARG_ENABLE(merge-ffmpeg,
2303 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2304   enable_merge_ffmpeg="no"
2305 ])
2306 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2307
2308 AC_MSG_CHECKING([for libavutil variant])
2309 PKG_CHECK_EXISTS([libavutil], [
2310   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2311   libavutil_micro="${libavutil_version##*.}"
2312   AS_IF([test ${libavutil_micro} -le 99], [
2313     avfork="libav"
2314   ], [
2315     avfork="ffmpeg"
2316   ])
2317 ], [
2318   avfork="none"
2319 ])
2320 AC_MSG_RESULT([${avfork}])
2321
2322 AC_ARG_ENABLE(avcodec,
2323 [  --enable-avcodec        libavcodec codec (default enabled)])
2324 AS_IF([test "${enable_avcodec}" != "no"], [
2325   dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2326   case "${avfork}" in
2327     libav) av_codec_ver="57.16.0" ;;
2328     ffmpeg) av_codec_ver="57.37.100" ;;
2329     *) AC_MSG_ERROR([Missing libav or FFmpeg. Pass --disable-avcodec to ignore this error.])
2330   esac
2331   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2332     VLC_SAVE_FLAGS
2333     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2334     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2335     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2336     AC_CHECK_HEADERS(libavutil/avutil.h)
2337     VLC_RESTORE_FLAGS
2338     have_avcodec="yes"
2339   ],[
2340     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2341   ])
2342 ], [
2343   have_avcodec="no"
2344 ])
2345 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2346
2347 dnl
2348 dnl libva needs avcodec
2349 dnl
2350 AC_ARG_ENABLE(libva,
2351   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2352
2353 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2354   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2355 ])
2356
2357 have_vaapi="no"
2358 have_vaapi_drm="no"
2359 have_vaapi_x11="no"
2360 have_vaapi_wl="no"
2361 AS_IF([test "${enable_libva}" != "no"], [
2362   PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2363     have_vaapi="yes"
2364   ], [
2365     AS_IF([test -n "${enable_libva}"], [
2366       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2367     ], [
2368       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2369     ])
2370   ])
2371   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2372     have_vaapi_drm="yes"
2373   ], [
2374     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2375   ])
2376   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2377     have_vaapi_x11="yes"
2378   ], [
2379     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2380   ])
2381   PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2382     have_vaapi_wl="yes"
2383   ], [
2384     AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2385   ])
2386 ])
2387 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2388 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2389 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2390 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2391
2392 have_avcodec_vaapi="no"
2393 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2394   VLC_SAVE_FLAGS
2395   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2396   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2397   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2398     AC_MSG_NOTICE([VA API acceleration activated])
2399     have_avcodec_vaapi="yes"
2400   ],[
2401     AS_IF([test -n "${enable_libva}"], [
2402       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2403     ], [
2404       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2405     ])
2406   ])
2407   VLC_RESTORE_FLAGS
2408 ])
2409 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2410
2411 dnl
2412 dnl dxva2 needs avcodec
2413 dnl
2414 AC_ARG_ENABLE(dxva2,
2415   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2416
2417 have_avcodec_dxva2="no"
2418 AS_IF([test "${enable_dxva2}" != "no"], [
2419   if test "${SYS}" = "mingw32"; then
2420   AS_IF([test "x${have_avcodec}" = "xyes"], [
2421     AC_CHECK_HEADERS(dxva2api.h,
2422       [
2423         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2424            AC_MSG_NOTICE([DxVA2 acceleration activated])
2425            have_avcodec_dxva2="yes"
2426         ],[
2427     AS_IF([test "${enable_dxva2}" = "yes"],
2428           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2429               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2430         ], [#undef _WIN32_WINNT
2431             /* DXVA2 is only available in Vista and above */
2432             #define _WIN32_WINNT 0x600])
2433       ],[
2434     AS_IF([test "${enable_dxva2}" = "yes"],
2435               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2436               [AC_MSG_WARN([dxva2api.h not found])])
2437       ],[#include <d3d9.h>])
2438   ],[
2439     AS_IF([test "x${enable_dxva2}" != "x"], [
2440       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2441     ])
2442   ])
2443   fi
2444 ])
2445 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2446
2447 dnl
2448 dnl d3d11va needs avcodec
2449 dnl
2450 AC_ARG_ENABLE(d3d11va,
2451   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2452
2453 have_avcodec_d3d11va="no"
2454 AS_IF([test "${enable_d3d11va}" != "no"], [
2455   if test "${SYS}" = "mingw32"; then
2456   AS_IF([test "x${have_avcodec}" = "xyes"], [
2457         AC_CHECK_TYPES([ID3D11VideoDecoder],
2458           [
2459             AC_CHECK_HEADERS(dxva2api.h,
2460               [
2461                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2462                    AC_MSG_NOTICE([D3D11 acceleration activated])
2463                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2464                    have_avcodec_d3d11va="yes"
2465                 ],[
2466                   AS_IF([test "${enable_d3d11va}" = "yes"],
2467                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2468                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2469                   ], [#undef _WIN32_WINNT
2470                       /* D3D11 is only available in Vista and above */
2471                       #define _WIN32_WINNT 0x600])
2472                   ],[
2473                     AS_IF([test "${enable_d3d11va}" = "yes"],
2474                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2475                           [AC_MSG_WARN([dxva2api.h not found])])
2476                   ],[#include <d3d9.h>])
2477           ],[
2478             AS_IF([test "${enable_d3d11va}" = "yes"],
2479                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2480                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2481           ], [#include <d3d11.h>])
2482   ],[
2483     AS_IF([test "x${enable_d3d11va}" != "x"], [
2484       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2485     ])
2486   ])
2487   fi
2488 ])
2489 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2490
2491 dnl
2492 dnl DXGI debug
2493 dnl
2494 AC_CHECK_HEADERS(dxgidebug.h dxgi1_6.h)
2495
2496 dnl
2497 dnl  avformat demuxer/muxer plugin
2498 dnl
2499
2500 AC_ARG_ENABLE(avformat,
2501 [  --enable-avformat       libavformat containers (default enabled)],, [
2502   enable_avformat="${have_avcodec}"
2503 ])
2504 have_avformat="no"
2505 AS_IF([test "${enable_avformat}" != "no"], [
2506   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2507       have_avformat="yes"
2508       VLC_SAVE_FLAGS
2509       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2510       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2511       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2512       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2513       AC_CHECK_HEADERS(libavutil/avutil.h)
2514       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2515         have_avformat="no"
2516       ])
2517       VLC_RESTORE_FLAGS
2518     ],[
2519       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2520   ])
2521 ])
2522 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2523
2524 dnl
2525 dnl  swscale image scaling and conversion plugin
2526 dnl
2527
2528 AC_ARG_ENABLE(swscale,
2529   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2530           (default enabled)]))
2531 if test "${enable_swscale}" != "no"
2532 then
2533   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2534     [
2535       VLC_SAVE_FLAGS
2536       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2537       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2538       AC_CHECK_HEADERS(libswscale/swscale.h)
2539       AC_CHECK_HEADERS(libavutil/avutil.h)
2540       VLC_ADD_PLUGIN([swscale])
2541       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2542       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2543       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2544         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2545       ])
2546       VLC_RESTORE_FLAGS
2547     ],[
2548       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2549   ])
2550 fi
2551
2552 dnl
2553 dnl  postproc plugin
2554 dnl
2555
2556 AC_ARG_ENABLE(postproc,
2557 [  --enable-postproc       libpostproc image post-processing (default auto)])
2558 if test "${enable_postproc}" != "no"
2559 then
2560   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2561     [
2562       VLC_SAVE_FLAGS
2563       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2564       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2565       AC_CHECK_HEADERS(postproc/postprocess.h)
2566       VLC_ADD_PLUGIN([postproc])
2567       VLC_RESTORE_FLAGS
2568     ],[
2569       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2570   ])
2571 fi
2572
2573 dnl
2574 dnl  faad decoder plugin
2575 dnl
2576 AC_ARG_ENABLE(faad,
2577 [  --enable-faad           faad codec (default auto)])
2578 have_faad="no"
2579 AS_IF([test "${enable_faad}" != "no"], [
2580   AC_CHECK_HEADERS([neaacdec.h], [
2581     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2582
2583     AS_IF([test "${have_faad}" = "yes"], [
2584       VLC_ADD_PLUGIN([faad])
2585       VLC_ADD_LIBS([faad],[-lfaad])
2586     ], [
2587       AS_IF([test "${enable_faad}" = "yes"], [
2588         AC_MSG_ERROR([cannot find FAAD library])
2589       ], [
2590         AC_MSG_WARN([cannot find FAAD library])
2591       ])
2592     ])
2593   ])
2594 ])
2595
2596 dnl
2597 dnl  AOM decoder plugin
2598 dnl
2599 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec (default auto)])
2600
2601 dnl
2602 dnl libvpx decoder plugin
2603 dnl
2604 AC_ARG_ENABLE(vpx,
2605     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2606 AS_IF([test "${enable_vpx}" != "no"],[
2607     PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2608         VLC_ADD_PLUGIN([vpx])
2609         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2610         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2611         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2612             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2613         ], [], [${VPX_LIBS}])
2614         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2615             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2616         ], [], [${VPX_LIBS}])
2617         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2618             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2619         ], [], [${VPX_LIBS}])
2620         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2621             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2622         ], [], [${VPX_LIBS}])
2623     ], [
2624     AS_IF([test "${enable_vpx}" = "yes"],[
2625         AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2626     ])])
2627 ])
2628
2629 dnl
2630 dnl twolame encoder plugin
2631 dnl
2632 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2633
2634 dnl
2635 dnl fdk-aac encoder plugin
2636 dnl
2637 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2638
2639
2640 dnl
2641 dnl A52/AC3 decoder plugin
2642 dnl
2643 AC_ARG_ENABLE(a52,
2644   [  --enable-a52            A/52 support with liba52 (default enabled)])
2645 if test "${enable_a52}" != "no"
2646 then
2647   AC_ARG_WITH(a52,
2648     [  --with-a52=PATH         a52 headers and libraries])
2649     if test -z "${with_a52}"
2650     then
2651       LDFLAGS_test=""
2652       CPPFLAGS_test=""
2653     else
2654       LDFLAGS_test="-L${with_a52}/lib"
2655       CPPFLAGS_test="-I${with_a52}/include"
2656     fi
2657     VLC_SAVE_FLAGS
2658     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2659     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2660     AC_CHECK_HEADERS(a52dec/a52.h, [
2661       AC_CHECK_LIB(a52, a52_free, [
2662         VLC_ADD_PLUGIN([a52])
2663         VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2664         VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2665       ],[
2666         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2667         ], [$LIBM])
2668     ],[
2669       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2670     ])
2671     VLC_RESTORE_FLAGS
2672 fi
2673
2674 dnl
2675 dnl DTS Coherent Acoustics decoder plugin
2676 dnl
2677 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2678
2679 dnl
2680 dnl  Flac plugin
2681 dnl
2682 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2683
2684 dnl
2685 dnl  Libmpeg2 plugin
2686 dnl
2687 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2688
2689 dnl
2690 dnl  Vorbis plugin
2691 dnl
2692 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2693
2694 dnl
2695 dnl  Tremor plugin
2696 dnl
2697 AC_ARG_ENABLE(tremor,
2698   [  --enable-tremor         Tremor decoder support (default disabled)])
2699 if test "${enable_tremor}" = "yes"
2700 then
2701   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2702     VLC_ADD_PLUGIN([tremor])
2703    ],[])
2704 fi
2705
2706 dnl
2707 dnl  Speex plugins
2708 dnl
2709 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2710 have_speexdsp="no"
2711 AS_IF([test "${enable_speex}" != "no"], [
2712   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2713     have_speexdsp="yes"
2714   ], [
2715     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2716   ])
2717 ])
2718 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2719
2720 dnl
2721 dnl  Opus plugin
2722 dnl
2723 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2724
2725 dnl
2726 dnl  Ambisonic channel mixer and binauralizer plugin
2727 dnl
2728 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
2729
2730 dnl
2731 dnl  theora decoder plugin
2732 dnl
2733 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2734
2735 dnl
2736 dnl  OggSpots decoder plugin
2737 dnl
2738 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2739
2740 dnl
2741 dnl  Daala decoder plugin
2742 dnl
2743 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2744
2745 dnl
2746 dnl  schroedinger decoder plugin (for dirac format video)
2747 dnl
2748 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2749
2750 dnl
2751 dnl  PNG decoder module
2752 dnl
2753 AC_ARG_ENABLE(png,
2754   [  --enable-png            PNG support (default enabled)])
2755 AS_IF([test "${enable_png}" != "no"], [
2756 AC_CHECK_HEADERS(png.h, [
2757   VLC_SAVE_FLAGS
2758   LDFLAGS="${LDFLAGS} -lz $LIBM"
2759   AC_CHECK_LIB(png, png_set_alpha_mode, [
2760     VLC_ADD_PLUGIN([png])
2761   ], [], [-lz $LIBM])
2762   VLC_RESTORE_FLAGS
2763   ])
2764 ])
2765
2766 dnl
2767 dnl  JPEG decoder module
2768 dnl
2769 AC_ARG_ENABLE(jpeg,
2770   [  --enable-jpeg           JPEG support (default enabled)])
2771 AS_IF([test "${enable_jpeg}" != "no"], [
2772 AC_CHECK_HEADERS(jpeglib.h, [
2773   VLC_ADD_PLUGIN([jpeg])
2774   ])
2775 ])
2776
2777 dnl
2778 dnl  BPG decoder module
2779 dnl
2780 AC_ARG_ENABLE(bpg,
2781   [  --enable-bpg           BPG support (default disabled)])
2782 AS_IF([test "${enable_bpg}" != "no"], [
2783 AC_CHECK_HEADERS(libbpg.h, [
2784   VLC_ADD_PLUGIN([bpg])
2785   ])
2786 ])
2787
2788 dnl
2789 dnl H262 encoder plugin (lib262)
2790 dnl
2791 AC_ARG_ENABLE(x262,
2792   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2793 if test "${enable_x262}" != "no"; then
2794     PKG_CHECK_MODULES(X262, x262, [
2795         VLC_ADD_PLUGIN([x262])
2796         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2797         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2798           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2799         ])
2800         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2801         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2802           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2803         fi
2804     ], [
2805        if test "${enable_x262}" = "yes"; then
2806         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2807        fi
2808     ])
2809 fi
2810
2811 dnl x265 encoder
2812 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2813
2814 dnl
2815 dnl H264 encoder plugin (10-bit lib264)
2816 dnl
2817 AC_ARG_ENABLE(x26410b,
2818   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2819 if test "${enable_x26410b}" != "no"; then
2820     PKG_CHECK_MODULES(X26410B, x26410b, [
2821         VLC_ADD_PLUGIN([x26410b])
2822         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2823         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2824           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2825         ])
2826         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2827         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2828           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2829         fi
2830     ], [
2831        if test "${enable_x26410b}" = "yes"; then
2832         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2833        fi
2834     ])
2835 fi
2836
2837
2838 dnl
2839 dnl H264 encoder plugin (using libx264)
2840 dnl
2841 AC_ARG_ENABLE(x264,
2842   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2843 if test "${enable_x264}" != "no"; then
2844       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2845         VLC_ADD_PLUGIN([x264])
2846         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2847
2848         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2849           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2850         ])
2851
2852         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2853         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2854           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2855         fi
2856       ],[
2857         if test "${enable_x264}" = "yes"; then
2858             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2859           fi
2860       ])
2861 fi
2862
2863 dnl
2864 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2865 dnl
2866 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2867
2868 dnl
2869 dnl libfluidsynth (MIDI synthetizer) plugin
2870 dnl
2871 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2872 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2873 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2874
2875 dnl
2876 dnl Teletext Modules
2877 dnl vbi decoder plugin (using libzbvi)
2878 dnl telx module
2879 dnl uncompatible
2880 dnl
2881 AC_ARG_ENABLE(zvbi,
2882   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2883                   libzvbi (default enabled)]))
2884 AC_ARG_ENABLE(telx,
2885   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2886                   zvbi) (default enabled if zvbi is absent)]))
2887
2888 AS_IF( [test "${enable_zvbi}" != "no"],[
2889     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2890         [
2891           VLC_ADD_PLUGIN([zvbi])
2892           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2893           AS_IF( [test "${enable_telx}" = "yes"],[
2894                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2895                   ])
2896         ],[
2897           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2898         ])
2899     ])
2900 AS_IF( [test "${enable_telx}" != "no" ],[
2901   VLC_ADD_PLUGIN([telx])
2902   ])
2903
2904 dnl
2905 dnl libass subtitle rendering module
2906 dnl
2907 AC_ARG_ENABLE(libass,
2908   [  --enable-libass         Subtitle support using libass (default enabled)])
2909 AS_IF( [test "${enable_libass}" != "no"], [
2910   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2911       [
2912         VLC_ADD_PLUGIN([libass])
2913
2914         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2915           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2916            VLC_ADD_LIBS([libass],[-lfontconfig])
2917        ])
2918       ],[
2919         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2920       ])
2921   ])
2922
2923 dnl
2924 dnl ARIB subtitles rendering module
2925 dnl
2926 AC_ARG_ENABLE(aribsub,
2927   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2928 AS_IF( [test "${enable_aribsub}" != "no" ],[
2929   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2930       have_aribb24="yes"
2931       VLC_ADD_PLUGIN([aribsub])
2932       VLC_ADD_LIBS([aribsub],[-laribb24])
2933       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2934     ],[
2935       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2936       have_aribb24="no"
2937   ])
2938 ])
2939 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2940
2941 dnl
2942 dnl ARIB B25
2943 dnl
2944 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2945
2946 dnl
2947 dnl  kate decoder plugin
2948 dnl
2949 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2950
2951 dnl
2952 dnl  tiger rendering for kate decoder plugin
2953 dnl
2954 AC_ARG_ENABLE(tiger,
2955 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2956 AS_IF([test "${enable_tiger}" != "no"], [
2957   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2958       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2959         AS_IF([test -n "${enable_tiger}"], [
2960           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2961         ])
2962   ])
2963 ])
2964
2965 dnl
2966 dnl  check if we can build the css selector engine
2967 dnl
2968 AC_ARG_ENABLE(css,
2969 [  --enable-css            CSS selector engine (default auto)])
2970 AS_IF([test "${enable_css}" != "no"], [
2971   with_css="yes"
2972   AC_DEFINE(HAVE_CSS, 1, [Define if CSS engine is built])
2973 ])
2974 AM_CONDITIONAL([ENABLE_CSS], [test "${with_css}" = "yes"])
2975
2976
2977 dnl
2978 dnl  Video plugins
2979 dnl
2980
2981 EXTEND_HELP_STRING([Video plugins:])
2982
2983 dnl
2984 dnl  OpenGL
2985 dnl
2986 PKG_CHECK_MODULES([EGL], [egl], [
2987   have_egl="yes"
2988 ], [
2989   have_egl="no"
2990 ])
2991 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
2992
2993 have_gl="no"
2994 PKG_CHECK_MODULES([GL], [gl], [
2995   have_gl="yes"
2996 ], [
2997   AC_MSG_CHECKING([for OpenGL])
2998   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2999 #ifdef _WIN32
3000 # include <GL/glew.h>
3001 #endif
3002 #include <GL/gl.h>
3003 ]], [
3004     [int t0 = GL_TEXTURE0;]])
3005   ], [
3006     GL_CFLAGS=""
3007     have_gl="yes"
3008     AS_IF([test "${SYS}" != "mingw32"], [
3009       GL_LIBS="-lGL"
3010     ], [
3011       GL_LIBS="-lopengl32"
3012     ])
3013   ])
3014   AC_MSG_RESULT([${have_gl}])
3015 ])
3016 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3017
3018 dnl OpenGL ES 2: depends on EGL 1.1
3019 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3020
3021 dnl
3022 dnl  Xlib
3023 dnl
3024
3025 AC_PATH_XTRA()
3026 AC_CHECK_HEADERS(X11/Xlib.h)
3027
3028 dnl
3029 dnl  X C Bindings modules
3030 dnl
3031 AC_ARG_ENABLE(xcb,
3032   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3033   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3034     enable_xcb="yes"
3035   ], [
3036     enable_xcb="no"
3037   ])
3038 ])
3039 AC_ARG_ENABLE(xvideo,
3040   [  --enable-xvideo         XVideo support (default enabled)],, [
3041     enable_xvideo="$enable_xcb"
3042 ])
3043
3044 have_xcb="no"
3045 have_xcb_keysyms="no"
3046 have_xcb_randr="no"
3047 have_xcb_xvideo="no"
3048 AS_IF([test "${enable_xcb}" != "no"], [
3049   dnl libxcb
3050   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3051   have_xcb="yes"
3052   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3053   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3054   PKG_CHECK_MODULES(XPROTO, [xproto])
3055
3056   AS_IF([test "${enable_xvideo}" != "no"], [
3057     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3058   ])
3059
3060   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3061
3062   dnl xcb-utils
3063   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3064     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3065   ])
3066 ])
3067 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3068 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3069 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3070 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3071
3072
3073 dnl
3074 dnl VDPAU needs X11
3075 dnl
3076 AC_ARG_ENABLE(vdpau,
3077   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3078 have_vdpau="no"
3079 AS_IF([test "${enable_vdpau}" != "no"], [
3080   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3081     have_vdpau="yes"
3082     AS_IF([test "${no_x}" = "yes"], [
3083       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3084     ])
3085   ], [
3086     AS_IF([test -n "${enable_vdpau}"], [
3087       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3088     ])
3089   ])
3090 ])
3091 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3092
3093 have_avcodec_vdpau="no"
3094 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3095   case "${avfork}" in
3096     libav) av_vdpau_ver="56.10.0" ;;
3097     ffmpeg) av_vdpau_ver="56.19.100" ;;
3098   esac
3099   PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3100     have_avcodec_vdpau="yes"
3101     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3102   ], [
3103     AS_IF([test -n "${enable_vdpau}"], [
3104       AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3105     ], [
3106       AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3107     ])
3108   ])
3109 ])
3110 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3111
3112
3113 dnl
3114 dnl  Wayland
3115 dnl
3116 AC_ARG_ENABLE(wayland,
3117   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3118 have_wayland="no"
3119 have_wayland_egl="no"
3120
3121 AS_IF([test "${enable_wayland}" != "no"], [
3122   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3123     AC_MSG_CHECKING([for the Wayland protocols])
3124     PKG_CHECK_EXISTS([wayland-protocols >= 1.4], [
3125       WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3126       AC_MSG_RESULT([${WAYLAND_PROTOCOLS}])
3127     ], [
3128       AC_MSG_RESULT([not found])
3129       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors 'wayland-protocols >= 1.4')])
3130     ])
3131
3132     AC_MSG_CHECKING([for the Wayland scanner])
3133     PKG_CHECK_EXISTS([wayland-scanner], [
3134       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3135       AC_MSG_RESULT([${WAYLAND_SCANNER}])
3136     ], [
3137       AC_MSG_RESULT([not found])
3138       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors wayland-scanner)])
3139     ])
3140
3141     have_wayland="yes"
3142
3143     AS_IF([test "${have_egl}" = "yes"], [
3144       PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3145         have_wayland_egl="yes"
3146       ], [
3147         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3148       ])
3149     ])
3150   ], [
3151     AS_IF([test -n "${enable_wayland}"], [
3152       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3153     ])
3154   ])
3155 ])
3156 AC_SUBST([WAYLAND_PROTOCOLS])
3157 AC_SUBST([WAYLAND_SCANNER])
3158 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3159 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3160
3161
3162 dnl
3163 dnl  SDL image decoder module
3164 dnl
3165 AC_ARG_ENABLE(sdl-image,
3166   [  --enable-sdl-image      SDL image support (default enabled)])
3167 AS_IF([test "${enable_sdl_image}" != "no"],[
3168   PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3169     VLC_ADD_PLUGIN([sdl_image])
3170   ], [
3171     AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3172   ])
3173 ])
3174
3175 dnl
3176 dnl  freetype module
3177 dnl
3178 AC_ARG_ENABLE(freetype,
3179   [  --enable-freetype       freetype support   (default auto)])
3180 AC_ARG_ENABLE(fribidi,
3181   [  --enable-fribidi        fribidi support    (default auto)])
3182 AC_ARG_ENABLE(harfbuzz,
3183   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3184 AC_ARG_ENABLE(fontconfig,
3185   [  --enable-fontconfig     fontconfig support (default auto)])
3186
3187 AC_ARG_WITH([default-font],
3188     AS_HELP_STRING([--with-default-font=PATH],
3189         [Path to the default font]),
3190         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3191             "$withval", [Default font])])
3192 AC_ARG_WITH([default-monospace-font],
3193     AS_HELP_STRING([--with-default-monospace-font=PATH],
3194         [Path to the default font]),
3195         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3196             "$withval", [Default monospace font])])
3197
3198 AC_ARG_WITH([default-font-family],
3199     AS_HELP_STRING([--with-default-font-family=NAME],
3200         [Path to the default font family]),
3201         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3202             "$withval", [Default font family])])
3203 AC_ARG_WITH([default-monospace-font-family],
3204     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3205         [Path to the default font family]),
3206         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3207             "$withval", [Default monospace font family])])
3208
3209 have_freetype="no"
3210 have_fontconfig="no"
3211 have_fribidi="no"
3212 have_harfbuzz="no"
3213
3214 if test "${enable_freetype}" != "no"; then
3215    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3216       have_freetype="yes"
3217       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3218       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3219
3220     dnl fontconfig support
3221     AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3222       PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3223         have_fontconfig="yes"
3224       ], [
3225         AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3226       ])
3227     ])
3228
3229       dnl fribidi support
3230       if test "${enable_fribidi}" != "no"; then
3231         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3232           have_fribidi="yes"
3233           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3234           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3235         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3236       fi
3237
3238       dnl harfbuzz support
3239       if test "${have_fribidi}" != "no"; then
3240         if test "${enable_harfbuzz}" != "no"; then
3241           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3242             have_harfbuzz="yes"
3243             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3244             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3245           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3246         fi
3247       fi
3248   ],[
3249   AS_IF([test -n "${enable_freetype}"],[
3250     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3251     ])
3252   ])
3253 fi
3254
3255 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3256 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3257 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3258 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3259
3260 dnl
3261 dnl SAPI (text to Speech renderer for Windows)
3262 dnl
3263 AC_LANG_PUSH([C++])
3264 AC_CHECK_TYPES([ISpObjectToken],[
3265               have_sapi="yes"
3266             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3267               [#include <windows.h>
3268                #include <sapi.h>
3269                #include <sphelper.h>])
3270 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3271 AC_LANG_POP([C++])
3272
3273 dnl
3274 dnl  SVG module (text rendering and image decoding)
3275 dnl
3276 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3277 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3278
3279 dnl
3280 dnl  Windows DirectX module
3281 dnl
3282
3283 AC_ARG_ENABLE(directx,
3284   [AS_HELP_STRING([--enable-directx],
3285     [Microsoft DirectX support (default enabled on Windows)])],, [
3286   AS_IF([test "${SYS}" = "mingw32"], [
3287     enable_directx="yes"
3288   ], [
3289     enable_directx="no"
3290   ])
3291 ])
3292 AS_IF([test "${enable_directx}" != "no"], [
3293   dnl DirectDraw
3294   AC_CHECK_HEADERS(ddraw.h, [
3295     VLC_ADD_PLUGIN([directdraw])
3296   ])
3297
3298   dnl OpenGL
3299   AC_CHECK_HEADERS(GL/wglew.h, [
3300     VLC_ADD_PLUGIN([glwin32 wgl])
3301   ],, [
3302     #include <windows.h>
3303     #include <GL/gl.h>
3304   ])
3305
3306   dnl Direct3D11
3307   AC_CHECK_HEADERS(d3d11.h, [
3308     VLC_ADD_PLUGIN([direct3d11 direct3d11_filters])
3309   ])
3310
3311   dnl Direct3D9
3312   AC_CHECK_HEADERS(d3d9.h, [
3313     VLC_ADD_PLUGIN([direct3d9])
3314     AC_CHECK_HEADERS(d3dx9effect.h)
3315
3316     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3317         [[#define COBJMACROS
3318           #include <d3d9.h>
3319           #include <dxva2api.h>
3320           #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3321           # error dxva2 too old
3322           #endif
3323         ]],[[;]])
3324       ],[
3325         VLC_ADD_PLUGIN([direct3d9_filters])
3326       ],
3327       [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3328
3329   ])
3330 ])
3331
3332 dnl
3333 dnl  Linux framebuffer module
3334 dnl
3335 AC_CHECK_HEADER([linux/fb.h], [
3336   VLC_ADD_PLUGIN([fb])
3337 ])
3338
3339 dnl
3340 dnl  libcaca plugin
3341 dnl
3342 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3343
3344 dnl
3345 dnl  OS/2 KVA plugin
3346 dnl
3347 AC_ARG_ENABLE(kva,
3348   [AS_HELP_STRING([--enable-kva],
3349     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3350   AS_IF([test "$SYS" = "os2"], [
3351     enable_kva="yes"
3352   ])
3353 ])
3354 have_kva="no"
3355 KVA_LIBS=""
3356 AS_IF([test "$enable_kva" != "no"], [
3357   AC_CHECK_HEADERS([kva.h], [
3358     have_kva="yes"
3359     AC_CHECK_LIB(kva, main, [
3360       KVA_LIBS="-lkva"
3361     ])
3362   ])
3363 ])
3364 AC_SUBST(KVA_LIBS)
3365 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3366
3367 dnl
3368 dnl MMAL plugin
3369 dnl
3370 AC_ARG_ENABLE(mmal,
3371   AS_HELP_STRING([--enable-mmal],
3372     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3373 if test "${enable_mmal}" != "no"; then
3374   VLC_SAVE_FLAGS
3375   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3376   CPPFLAGS="${CPPFLAGS} -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux"
3377   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3378     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3379         have_mmal="yes"
3380         VLC_ADD_PLUGIN([mmal])
3381         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3382         VLC_ADD_CFLAGS([mmal],[ -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux ])
3383         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lmmal_core -lmmal_components -lmmal_util -lvchostif ]) ], [
3384           AS_IF([test "${enable_mmal}" = "yes"],
3385             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3386             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3387           ],
3388         [])
3389     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3390       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3391       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3392   VLC_RESTORE_FLAGS
3393 fi
3394 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3395
3396 dnl
3397 dnl  Audio plugins
3398 dnl
3399
3400 EXTEND_HELP_STRING([Audio plugins:])
3401
3402 dnl
3403 dnl  Pulseaudio module
3404 dnl
3405 AC_ARG_ENABLE(pulse,
3406   [AS_HELP_STRING([--enable-pulse],
3407     [use the PulseAudio client library (default auto)])])
3408 have_pulse="no"
3409 AS_IF([test "${enable_pulse}" != "no"], [
3410   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3411     have_pulse="yes"
3412   ], [
3413     AS_IF([test "x${enable_pulse}" != "x"], [
3414       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3415     ])
3416   ])
3417 ])
3418 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3419
3420 dnl
3421 dnl  ALSA module
3422 dnl
3423 AC_ARG_ENABLE(alsa,
3424   [AS_HELP_STRING([--enable-alsa],
3425     [support the Advanced Linux Sound Architecture (default auto)])],, [
3426   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3427     enable_alsa="yes"
3428   ])
3429 ])
3430 have_alsa="no"
3431 AS_IF([test "${enable_alsa}" != "no"], [
3432   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3433     have_alsa="yes"
3434   ], [
3435     AS_IF([test "x${enable_alsa}" != "x"], [
3436       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required. Pass --disable-alsa to ignore this error.])
3437     ])
3438   ])
3439 ])
3440 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3441
3442 dnl
3443 dnl  Open Sound System module
3444 dnl
3445 AC_ARG_ENABLE(oss,
3446   [AS_HELP_STRING([--enable-oss],
3447     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3448   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3449     enable_oss="no"
3450   ])
3451 ])
3452 have_oss="no"
3453 OSS_LIBS=""
3454 AS_IF([test "$enable_oss" != "no"], [
3455   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3456     have_oss="yes"
3457     AC_CHECK_LIB(ossaudio, main, [
3458       OSS_LIBS="-lossaudio"
3459     ])
3460   ])
3461 ])
3462 AC_SUBST(OSS_LIBS)
3463 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3464
3465 dnl
3466 dnl  OpenBSD sndio module
3467 dnl
3468 AC_ARG_ENABLE([sndio],
3469   [AS_HELP_STRING([--disable-sndio],
3470     [support the OpenBSD sndio (default auto)])],, [
3471   AS_IF([test "$SYS" = "openbsd"], [
3472     enable_sndio="yes"
3473   ])
3474 ])
3475 have_sndio="no"
3476 AS_IF([test "$enable_sndio" != "no"], [
3477   AC_CHECK_HEADER([sndio.h], [
3478     have_sndio="yes"
3479   ])
3480 ])
3481 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3482
3483 dnl
3484 dnl  Windows Audio Session plugin
3485 dnl
3486 AC_ARG_ENABLE([wasapi],
3487   [AS_HELP_STRING([--enable-wasapi],
3488     [use the Windows Audio Session API (default auto)])
3489 ])
3490 have_wasapi="no"
3491 AS_IF([test "$enable_wasapi" != "no"], [
3492   AC_CHECK_HEADER([audioclient.h], [
3493     have_wasapi="yes"
3494   ], [
3495     AS_IF([test "x${enable_wasapi}" != "x"], [
3496       AC_MSG_ERROR([Windows Audio Session API not found.])
3497     ])
3498   ])
3499 ])
3500 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3501
3502 dnl
3503 dnl  JACK modules
3504 dnl
3505 AC_ARG_ENABLE(jack,
3506   [AS_HELP_STRING([--disable-jack],
3507     [do not use jack (default auto)])])
3508 have_jack="no"
3509 AS_IF([test "${enable_jack}" != "no"], [
3510     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3511       [ have_jack=yes ],
3512       [
3513       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3514
3515       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3516       [ have_jack=yes ],
3517       [
3518       AS_IF([test -n "${enable_jack}"],
3519          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3520          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3521       ])
3522     ])
3523 ])
3524 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3525
3526 dnl
3527 dnl  OpenSLES Android
3528 dnl
3529 AC_ARG_ENABLE(opensles,
3530   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3531 if test "${HAVE_ANDROID}" = "1"; then
3532   if test "${enable_opensles}" = "yes"; then
3533       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3534         [ VLC_ADD_PLUGIN([opensles_android]) ],
3535         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3536   fi
3537 fi
3538
3539 dnl
3540 dnl  Tizen audio
3541 dnl
3542 AC_ARG_ENABLE(tizen_audio,
3543   [AS_HELP_STRING([--enable-tizen-audio],
3544     [Tizen audio module (default enabled on Tizen)])],, [
3545   AS_IF([test "$HAVE_TIZEN" = "1"], [
3546     enable_tizen_audio="yes"
3547   ])
3548 ])
3549 if test "${enable_tizen_audio}" = "yes"; then
3550   AC_CHECK_HEADERS(audio_io.h,
3551     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3552     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3553 fi
3554
3555 dnl
3556 dnl libsamplerate plugin
3557 dnl
3558 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3559
3560 dnl
3561 dnl  soxr module
3562 dnl
3563 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3564
3565 dnl
3566 dnl  OS/2 KAI plugin
3567 dnl
3568 AC_ARG_ENABLE(kai,
3569   [AS_HELP_STRING([--enable-kai],
3570     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3571   AS_IF([test "$SYS" = "os2"], [
3572     enable_kai="yes"
3573   ])
3574 ])
3575 have_kai="no"
3576 KAI_LIBS=""
3577 AS_IF([test "$enable_kai" != "no"], [
3578   AC_CHECK_HEADERS([kai.h], [
3579     have_kai="yes"
3580     AC_CHECK_LIB(kai, main, [
3581       KAI_LIBS="-lkai"
3582     ])
3583   ])
3584 ])
3585 AC_SUBST(KAI_LIBS)
3586 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3587
3588 dnl
3589 dnl  chromaprint audio track fingerprinter
3590 dnl
3591 m4_pushdef([libchromaprint_version], 0.6.0)
3592 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3593     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3594     AS_IF([test "${enable_chromaprint}" = "yes"],
3595         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3596         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3597          ),
3598     [(Chromaprint based audio fingerprinter)],[auto])
3599 m4_popdef([libchromaprint_version])
3600
3601 dnl
3602 dnl  Chromecast streaming support
3603 dnl
3604 m4_pushdef([protobuf_lite_version], 2.5.0)
3605 AC_ARG_VAR(PROTOC, [protobuf compiler])
3606 AC_CHECK_PROGS(PROTOC, protoc, no)
3607 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3608     AS_IF([test "x${PROTOC}" != "xno"], [
3609         build_chromecast="yes"
3610     ], [
3611     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3612     ])
3613 ], [
3614     AS_IF([test "${enable_chromecast}" = "yes"],
3615         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3616         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3617     )
3618     enable_chromecast="no"
3619 ], [(Chromecast streaming support)], [auto])
3620 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3621 m4_popdef([protobuf_lite_version])
3622
3623 dnl
3624 dnl  Interface plugins
3625 dnl
3626
3627 EXTEND_HELP_STRING([Interface plugins:])
3628
3629 dnl
3630 dnl QT
3631 dnl
3632 AC_ARG_ENABLE(qt, [
3633   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3634   AS_IF([test "${SYS}" = "darwin"], [
3635     enable_qt="no"
3636   ])
3637 ])
3638 have_qt5_x11="no"
3639 AS_IF([test "${enable_qt}" != "no"], [
3640   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.5.0 Qt5Widgets Qt5Gui Qt5Svg], [
3641       PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3642           have_qt5_x11="yes"
3643       ],[
3644           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3645       ])
3646       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3647       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3648       QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3649       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3650       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3651       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3652     ], [
3653       AS_IF([test -n "${enable_qt}"],[
3654         AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3655       ],[
3656         AC_MSG_WARN([${QT_PKG_ERRORS}.])
3657       ])
3658       enable_qt="no"
3659     ])
3660 ])
3661
3662 AS_IF([test "${enable_qt}" != "no"], [
3663   ALIASES="${ALIASES} qvlc"
3664 ])
3665 AC_SUBST(QT_VERSION)
3666 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3667 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3668
3669 dnl
3670 dnl detect kde4-config patch (used for kde solids).
3671 dnl
3672 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3673 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3674   KDE4_CONFIG="kde4-config"
3675 ])
3676
3677 dnl
3678 dnl Simple test for skins2 dependency
3679 dnl
3680 AS_IF([test "$enable_qt" = "no"], [
3681   AS_IF([test "${enable_skins2}" = "yes"], [
3682     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3683   ], [
3684     enable_skins2="no"
3685     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3686   ])
3687 ])
3688
3689 dnl
3690 dnl Skins2 module
3691 dnl
3692 AC_ARG_ENABLE(skins2,
3693   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3694 AS_IF([test "${enable_skins2}" != "no"], [
3695   have_skins_deps="yes"
3696
3697   dnl Win32
3698   AS_IF([test "${SYS}" = "mingw32"], [
3699     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3700     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3701   dnl OS/2
3702   ], [test "${SYS}" = "os2"], [
3703     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3704   dnl Linux/Unix
3705   ], [
3706     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3707     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3708     PKG_CHECK_MODULES([XCURSOR], [xcursor],, [have_skins_deps="no"])
3709     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3710     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3711     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} ${XCURSOR_LIBS} -lX11])
3712   ])
3713
3714   dnl we need freetype
3715   AS_IF([test "${have_freetype}" != "yes"], [
3716     have_skins_deps="no"
3717   ])
3718
3719   AS_IF([test "${have_skins_deps}" = "no"], [
3720     AS_IF([test "x${enable_skins2}" = "x"], [
3721       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3722     ], [
3723       AC_MSG_ERROR([Skins2 interface requires FreeType, libxcursor, libxpm, libxext and libxinerama])
3724     ])
3725     enable_skins2="no"
3726   ], [
3727     ALIASES="${ALIASES} svlc"
3728     enable_skins2="yes"
3729   ])
3730 ])
3731 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3732
3733 AC_ARG_ENABLE(libtar,
3734   [  --enable-libtar         libtar support for skins2 (default auto)])
3735 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3736   AC_CHECK_HEADERS(libtar.h, [
3737     VLC_ADD_LIBS([skins2],[-ltar])
3738   ])
3739 ])
3740
3741 dnl
3742 dnl  MacOS X gui module
3743 dnl
3744 AC_ARG_ENABLE(macosx,
3745   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3746 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3747 then
3748
3749   dnl
3750   dnl If possible, use xcrun to find the right ibtool
3751   dnl
3752
3753   AC_PATH_PROG([XCRUN], [xcrun], [no])
3754   AS_IF([test ! "x${XCRUN}" = "xno"], [
3755     AC_MSG_CHECKING([for ibtool (using xcrun)])
3756     XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3757     AC_MSG_RESULT([${XIB}])
3758   ], [
3759     AC_MSG_WARN([Looking for tools without using xcrun])
3760   ])
3761
3762   AS_IF([test "x${XIB}" = "xno"], [
3763     AC_PATH_PROG(XIB, [ibtool], [no])
3764     AS_IF([test "x${XIB}" = "xno"], [
3765       AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3766     ])
3767   ])
3768 fi
3769 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3770
3771 dnl
3772 dnl  MacOS X sparkle update support
3773 dnl
3774 AC_ARG_ENABLE(sparkle,
3775   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3776 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3777 then
3778   if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3779   then
3780     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3781   fi
3782
3783   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3784 fi
3785 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3786
3787 dnl
3788 dnl  MacOS X breakpad creash reporter support
3789 dnl
3790 AC_ARG_WITH([breakpad],
3791   AS_HELP_STRING([--with-breakpad=URL], [Enable Breakpad reporter using given URL]), [], [with_breakpad=no])
3792
3793 AS_IF([test "$with_breakpad" != "no"], [
3794
3795   AS_IF([test "$with_breakpad" = "yes"], [
3796     AC_MSG_ERROR([You need to supply the CrashDragon Server URL as value for --with-breakpad])
3797   ])
3798
3799   AS_IF([test "$HAVE_OSX" = "1"], [
3800     AC_MSG_CHECKING([for Breakpad framework])
3801     AS_IF([test ! -d ${CONTRIB_DIR}/Breakpad.framework -a \
3802                 ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework], [
3803       AC_MSG_RESULT([no])
3804       with_breakpad="no"
3805       AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3806     ], [
3807       AC_MSG_RESULT([yes])
3808     ])
3809   ],[
3810     PKG_CHECK_MODULES([BREAKPAD], [breakpad-client], [
3811       LDFLAGS="${LDFLAGS} -Wl,--build-id"
3812     ], [
3813       AC_MSG_ERROR(["breakpad not found"])
3814     ])
3815   ])
3816 ])
3817
3818 AM_CONDITIONAL(HAVE_BREAKPAD, [test "$with_breakpad" != "no"])
3819 AS_IF([test "$with_breakpad" != "no"], [
3820   AC_SUBST(BREAKPAD_URL, ["${with_breakpad}"])
3821 ])
3822
3823 dnl
3824 dnl  Minimal Mac OS X module
3825 dnl
3826 AC_ARG_ENABLE(minimal-macosx,
3827   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3828 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3829 then
3830   VLC_ADD_PLUGIN([minimal_macosx])
3831 fi
3832
3833 dnl
3834 dnl Mac OS X fancy dmg build tool
3835 dnl
3836 if test "${HAVE_OSX}" = "1"
3837 then
3838   AC_PATH_PROG(DMGBUILD, dmgbuild, no)
3839   AS_IF([test "x${DMGBUILD}" = "xno"], [
3840     AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
3841   ])
3842 fi
3843 AM_CONDITIONAL(HAVE_DMGBUILD, [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
3844
3845 dnl
3846 dnl  VideoToolbox plugins
3847 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3848     VLC_ADD_PLUGIN([videotoolbox])
3849     VLC_ADD_PLUGIN([cvpx])
3850   ])
3851
3852 dnl
3853 dnl  AudioToolbox MIDI plugin
3854 AC_CHECK_HEADERS([AudioToolbox/AudioToolbox.h], [
3855   VLC_ADD_PLUGIN([audiotoolboxmidi])
3856 ])
3857
3858 dnl
3859 dnl  ncurses module
3860 dnl
3861 AC_ARG_ENABLE(ncurses,
3862 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3863 have_ncurses="no"
3864 AS_IF([test "${enable_ncurses}" != "no"] ,[
3865   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3866     have_ncurses="yes"
3867     ALIASES="${ALIASES} nvlc"
3868   ], [
3869     AS_IF([test -n "${enable_ncurses}"], [
3870       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3871     ])
3872   ])
3873 ])
3874 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3875
3876 dnl
3877 dnl  Lirc plugin
3878 dnl
3879 AC_ARG_ENABLE(lirc,
3880   [  --enable-lirc           lirc support (default disabled)])
3881 have_lirc="no"
3882 AS_IF([test "${enable_lirc}" = "yes"], [
3883   AC_CHECK_HEADER(lirc/lirc_client.h, [
3884     AC_CHECK_LIB(lirc_client, lirc_init, [
3885       have_lirc="yes"
3886     ])
3887   ])
3888 ])
3889 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3890
3891 dnl
3892 dnl  SRT plugin
3893 dnl
3894 PKG_ENABLE_MODULES_VLC([SRT], [access_srt access_output_srt], [srt >= 1.2.2], [SRT input/output plugin], [auto], [], [], [-DENABLE_SRT])
3895
3896 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3897 dnl
3898 dnl  goom visualization plugin
3899 dnl
3900 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3901
3902 dnl
3903 dnl libprojectM visualization plugin
3904 dnl
3905 AC_ARG_ENABLE(projectm,
3906   [  --enable-projectm       projectM visualization plugin (default enabled)])
3907 AS_IF([test "${enable_projectm}" != "no"],
3908   [
3909     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3910     [
3911       VLC_ADD_PLUGIN([projectm])
3912       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3913         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3914         [ AC_MSG_WARN( [Using libprojectM version 1] )
3915       ])
3916     ],[
3917       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3918     ])
3919   ])
3920
3921 dnl
3922 dnl Vovoid VSXu visualization plugin
3923 dnl
3924 AC_ARG_ENABLE(vsxu,
3925   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3926 AS_IF([test "${enable_vsxu}" != "no"],
3927   [
3928     PKG_CHECK_MODULES(VSXU, libvsxu,
3929     [
3930       VLC_ADD_PLUGIN([vsxu])
3931     ],[
3932       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3933     ])
3934   ])
3935
3936 EXTEND_HELP_STRING([Service Discovery plugins:])
3937 dnl
3938 dnl  Avahi-Zeroconf services discovery
3939 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
3940
3941 dnl
3942 dnl  libudev services discovery
3943 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3944
3945 dnl
3946 dnl MTP devices services discovery
3947 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3948
3949 dnl
3950 dnl UPnP Plugin (Intel SDK)
3951 dnl
3952 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3953
3954 dnl
3955 dnl mDNS using libmicrodns
3956 dnl
3957 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
3958
3959
3960 EXTEND_HELP_STRING([Misc options:])
3961
3962 dnl
3963 dnl  libxml2 module
3964 dnl
3965 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3966
3967
3968 dnl
3969 dnl libgcrypt
3970 dnl
3971 AC_ARG_ENABLE(libgcrypt,
3972   [  --disable-libgcrypt     gcrypt support (default enabled)])
3973 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
3974 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
3975
3976 # require libgcrypt >= 1.6.0
3977 AS_IF([test "${enable_libgcrypt}" != "no"], [
3978   AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
3979     VLC_SAVE_FLAGS
3980     CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
3981     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
3982 [#include <gcrypt.h>
3983 #if GCRYPT_VERSION_NUMBER < 0x010600
3984 #error
3985 #endif]])], [
3986       ac_cv_lib_gcrypt=yes
3987     ], [
3988       ac_cv_lib_gcrypt=no
3989     ])
3990     VLC_RESTORE_FLAGS
3991   ])
3992
3993   AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
3994     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
3995   ], [
3996     AS_IF([test "${enable_libgcrypt}" = "yes"], [
3997       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
3998     ])
3999   ])
4000 ])
4001
4002 AS_IF([test -z "$GCRYPT_LIBS"], [
4003   GCRYPT_LIBS="-lgcrypt -lgpg-error"
4004 ])
4005
4006 AC_SUBST(GCRYPT_CFLAGS)
4007 AC_SUBST(GCRYPT_LIBS)
4008 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4009
4010 dnl
4011 dnl TLS/SSL
4012 dnl
4013 AC_ARG_ENABLE(gnutls,
4014   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4015 AS_IF([test "${enable_gnutls}" != "no"], [
4016   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4017     VLC_ADD_PLUGIN([gnutls])
4018   ], [
4019     AS_IF([test -n "${enable_gnutls}"], [
4020       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4021     ])
4022   ])
4023 ])
4024
4025
4026 dnl
4027 dnl Taglib plugin
4028 dnl
4029 AC_ARG_ENABLE(taglib,
4030   [AS_HELP_STRING([--disable-taglib],
4031     [do not use TagLib (default enabled)])])
4032 AS_IF([test "${enable_taglib}" != "no"], [
4033   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4034     VLC_ADD_PLUGIN([taglib])
4035   ], [
4036     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4037 ])
4038
4039 dnl
4040 dnl  libsecret
4041 dnl
4042 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4043
4044 dnl
4045 dnl  kwallet
4046 dnl
4047 AC_ARG_ENABLE(kwallet,
4048   [AS_HELP_STRING([--enable-kwallet],
4049     [use kwallet (via D-Bus) for keystore (default enabled)])])
4050 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4051   VLC_ADD_PLUGIN([kwallet])
4052 ])
4053
4054 dnl
4055 dnl update checking system
4056 dnl
4057 AC_ARG_ENABLE(update-check,
4058   [  --enable-update-check   update checking system (default disabled)])
4059 if test "${enable_update_check}" = "yes"
4060 then
4061  AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4062     AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4063 fi
4064 AM_CONDITIONAL(UPDATE_CHECK, [test "${enable_update_check}" = "yes"])
4065
4066 dnl
4067 dnl OS X notification plugin
4068 dnl
4069 AC_ARG_ENABLE(osx_notifications,
4070   [  --enable-osx-notifications          osx notification plugin (default disabled)],,
4071   [enable_osx_notifications=no])
4072 AS_IF([test "${enable_osx_notifications}" != "no"], [
4073   if test -d ${CONTRIB_DIR}/Growl.framework -o -d ${CONTRIB_DIR}/Frameworks/Growl.framework
4074   then
4075       VLC_ADD_PLUGIN([osx_notifications])
4076       VLC_ADD_LIBS([osx_notifications], [-Wl,-framework,Growl,-framework,Foundation])
4077       VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4078   fi
4079 ])
4080
4081 dnl
4082 dnl Libnotify notification plugin
4083 dnl
4084 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-3.0], [libnotify notification], [auto])
4085
4086 dnl
4087 dnl  libplacebo support
4088 dnl
4089 AC_ARG_ENABLE(libplacebo,
4090   [AS_HELP_STRING([--disable-libplacebo],
4091       [disable libplacebo support (default auto)])])
4092
4093 AS_IF([test "$enable_libplacebo" != "no"], [
4094   PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 0.2.1], [
4095     AC_DEFINE([HAVE_LIBPLACEBO], [1], [Define to 1 if libplacebo is enabled.])
4096   ], [
4097     AS_IF([test -n "${enable_libplacebo}"], [
4098       AC_MSG_ERROR([${LIBPLACEBO_PKG_ERRORS}.])
4099     ])
4100     enable_libplacebo="no"
4101   ])
4102 ])
4103 AM_CONDITIONAL(HAVE_LIBPLACEBO, [test "$enable_libplacebo" != "no"])
4104
4105
4106 dnl
4107 dnl  Endianness check
4108 dnl
4109 AC_C_BIGENDIAN
4110 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4111   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4112 ], [
4113   DEFS_BIGENDIAN=""
4114 ])
4115 AC_SUBST(DEFS_BIGENDIAN)
4116
4117 dnl
4118 dnl Where to install KDE solid .desktop
4119 dnl
4120 AC_ARG_WITH(kde-solid,
4121   AS_HELP_STRING([--with-kde-solid=PATH],
4122                  [KDE Solid actions directory (auto)]),, [
4123
4124 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4125   with_kde_solid="yes"
4126 fi
4127 ])
4128 soliddatadir=""
4129 AS_IF([test "${with_kde_solid}" != "no"], [
4130   AS_IF([test "${with_kde_solid}" = "yes"], [
4131     kde4datadir="`${KDE4_CONFIG} --install data`"
4132     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4133     soliddatadir="${kde4datadir}/solid/actions"
4134   ], [
4135     soliddatadir="${with_kde_solid}"
4136   ])
4137 ])
4138 AC_SUBST(soliddatadir)
4139 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4140
4141 dnl
4142 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4143 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4144 dnl
4145 if test "${SYS}" = "mingw32"; then
4146     AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4147 fi
4148
4149 EXTEND_HELP_STRING([Components:])
4150
4151 dnl
4152 dnl  the VLC binary
4153 dnl
4154 AC_ARG_ENABLE(vlc,
4155   [  --enable-vlc            build the VLC media player (default enabled)])
4156 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4157
4158 dnl
4159 dnl Fuzzer (at the end in order to don't mess dependencies FLAGS)
4160 dnl
4161 AS_VAR_IF(with_libfuzzer, no, [], [
4162     LIBS="-lstdc++ ${LIBM} ${LIBPTHREAD} -L${with_libfuzzer} -lFuzzer"
4163     AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc-guard, [
4164         AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard])
4165         AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard], [CXXFLAGS])
4166         AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp])
4167         AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp], [CXXFLAGS])
4168     ], [
4169         AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc, [
4170             AX_APPEND_FLAG([-fsanitize-coverage=trace-pc])
4171             AX_APPEND_FLAG([-fsanitize-coverage=trace-pc], [CXXFLAGS])
4172         ], [
4173             AC_MSG_ERROR([Sanitizer coverage not supported by your compiler])
4174         ])
4175     ])
4176 ])
4177
4178 dnl
4179 dnl  Stuff used by the program
4180 dnl
4181 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4182 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4183 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4184 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4185 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4186 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4187 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4188 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4189 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4190 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4191 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4192 AC_SUBST(COPYRIGHT_MESSAGE)
4193 AC_SUBST(VERSION_MESSAGE)
4194 AC_SUBST(VERSION_MAJOR)
4195 AC_SUBST(VERSION_MINOR)
4196 AC_SUBST(VERSION_REVISION)
4197 AC_SUBST(VERSION_EXTRA)
4198 AC_SUBST(COPYRIGHT_YEARS)
4199 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4200 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4201 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4202 dnl
4203 dnl  Handle substvars that use $(top_srcdir)
4204 dnl
4205 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4206
4207 dnl
4208 dnl  Configuration is finished
4209 dnl
4210 AC_SUBST(SYS)
4211 AC_SUBST(ARCH)
4212 AC_SUBST(ALIASES)
4213 AC_SUBST(ASM)
4214 AC_SUBST(MOC)
4215 AC_SUBST(RCC)
4216 AC_SUBST(UIC)
4217 AC_SUBST(WINDRES)
4218 AC_SUBST(WINE_SDK_PATH)
4219 AC_SUBST(LIBEXT)
4220 AC_SUBST(AM_CPPFLAGS)
4221 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4222 AC_SUBST(FILE_LIBVLCCORE_DLL)
4223 AC_SUBST(FILE_LIBVLC_DLL)
4224
4225 AC_CONFIG_FILES([
4226   Makefile
4227   doc/Makefile
4228   modules/Makefile
4229   m4/Makefile
4230   po/Makefile.in
4231   share/Makefile
4232   compat/Makefile
4233   src/Makefile
4234   lib/Makefile
4235   bin/Makefile
4236   test/Makefile
4237   modules/hw/mmal/Makefile
4238   share/vlc.appdata.xml.in
4239 ])
4240
4241 AM_COND_IF([HAVE_WIN32], [
4242   AC_CONFIG_FILES([
4243     extras/package/win32/NSIS/spad.nsi
4244     extras/package/win32/NSIS/vlc.win32.nsi
4245     extras/package/win32/msi/config.wxi
4246   ])
4247 ])
4248
4249 AM_COND_IF([HAVE_DARWIN], [
4250   AC_CONFIG_FILES([
4251     modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4252     share/macosx/Info.plist:share/Info.plist.in
4253   ])
4254 ])
4255
4256 dnl Generate makefiles
4257 AC_OUTPUT
4258
4259 dnl Do we have to use make or gmake ?
4260 if make --version 2>&1|grep -q GNU
4261 then
4262     # GNU make, all seems good
4263     MAKE=make
4264 else
4265     # Known GNU make alias (on BSD)
4266     MAKE=gmake
4267 fi
4268 dnl Shortcut to nice compile message
4269 if test -n $SHELL; then
4270   SHELL=${CONFIG_SHELL-/bin/sh}
4271 fi
4272 rm -f compile
4273 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4274 echo "#! $SHELL
4275 rm -f .error\$\$
4276 ERROR=0
4277 export PATH=\"$PATH\" LANG=C
4278 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4279 test -f .error\$\$ && ERROR=1
4280 rm -f .error\$\$
4281 exit \$ERROR" >compile
4282 chmod a+x compile
4283
4284 echo "
4285 libvlc configuration
4286 --------------------
4287 version               : ${VERSION}
4288 system                : ${SYS}
4289 architecture          : ${ARCH}
4290 optimizations         : ${enable_optimizations}"
4291 if test "${enable_vlc}" != "no"; then
4292 echo "vlc aliases           :${ALIASES}"
4293 else
4294 echo "build vlc executable  : no"
4295 fi
4296 echo "
4297 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."