configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 2002-2014 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 3.0.0-git)
   6 VERSION_MAJOR=3
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=git
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Vetinari"
  17 COPYRIGHT_YEARS="1996-2014"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 # Disable with "./configure --disable-silent-rules" or "make V=1"
  31 AM_SILENT_RULES([yes])
  32
  33 dnl Too many people are not aware of maintainer mode:
  34 dnl If you want to use it, you definitely know what you are doing, so
  35 dnl you can specify "--disable-maintainer-mode". But if you want the default
  36 dnl automake behavior, you've likely never heard of maintainer mode, so we
  37 dnl can't expect you to enable it manually.
  38 AS_IF([test "x${enable_maintainer_mode}" != "xno"],
  39     [enable_maintainer_mode="yes"])
  40 AM_MAINTAINER_MODE
  41
  42 dnl
  43 dnl Directories
  44 dnl
  45 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  46 dnl AC_SUBST(vlcincludedir)
  47 vlcdatadir="\${datadir}/\${PKGDIR}"
  48 AC_SUBST(vlcdatadir)
  49 vlclibdir="\${libdir}/\${PKGDIR}"
  50 AC_SUBST(vlclibdir)
  51
  52 dnl
  53 dnl Check for tools
  54 dnl
  55 AC_PROG_CC_C99
  56 AC_USE_SYSTEM_EXTENSIONS
  57 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  58 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  59 AH_TOP([
  60 #ifndef _REENTRANT
  61 # define _REENTRANT
  62 #endif
  63 ])
  64 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  65 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  66 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  67
  68 AM_PROG_CC_C_O
  69 AC_PROG_CXX
  70 AC_PROG_CPP
  71 AC_PROG_OBJC
  72 _AM_DEPENDENCIES([OBJC])
  73 AC_PROG_EGREP
  74 AC_PROG_MAKE_SET
  75 AC_PROG_INSTALL
  76 AM_PROG_AS
  77
  78 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  79 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  80 AC_PATH_PROG(YASM, yasm)
  81
  82 dnl Check for compiler properties
  83 AC_C_CONST
  84 AC_C_INLINE
  85 AC_C_RESTRICT
  86
  87 dnl Extend the --help string at the current spot.
  88 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  89
  90 dnl Allow binary package maintainer to pass a custom string to avoid
  91 dnl cache problem
  92 AC_ARG_WITH(binary-version,
  93     AS_HELP_STRING([--with-binary-version=STRING],
  94          [To avoid plugins cache problem between binary version]),[],[])
  95 AS_IF([test -n "${with_binary_version}"],[
  96     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  97          [Binary specific version])
  98 ])
  99
 100 dnl
 101 dnl  Check the operating system
 102 dnl
 103 HAVE_WIN64="0"
 104 HAVE_IOS="0"
 105 HAVE_OSX="0"
 106
 107 YASMFLAGS=""
 108 case "${host}" in
 109     i?86*)
 110     YASMFLAGS="-f elf32"
 111         ;;
 112     x86_64*)
 113     YASMFLAGS="-f elf64"
 114         ;;
 115 esac
 116
 117
 118 case "${host_os}" in
 119   "")
 120     SYS=unknown
 121     ;;
 122   linux*)
 123     SYS=linux
 124     ;;
 125   bsdi*)
 126     SYS=bsdi
 127     CFLAGS="${CFLAGS} -pthread"
 128     ;;
 129   freebsd*)
 130     SYS=freebsd
 131     CFLAGS="${CFLAGS} -pthread"
 132     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 133     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 134     ;;
 135   openbsd*)
 136     SYS=openbsd
 137     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 138     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 139     ;;
 140   netbsd*)
 141     SYS=netbsd
 142     ;;
 143   dragonfly*)
 144     SYS=dragonfly
 145     ;;
 146   darwin*)
 147
 148     dnl Force gcc "-arch" flag
 149     ARCH_flag=""
 150     case "${host}" in
 151       i?86*)
 152         ARCH_flag="-arch i386"
 153         YASMFLAGS="-f macho32"
 154       ;;
 155       ppc64*)
 156         ARCH_flag="-arch ppc64"
 157       ;;
 158       ppc*)
 159         ARCH_flag="-arch ppc"
 160       ;;
 161       x86_64*)
 162         ARCH_flag="-arch x86_64"
 163         YASMFLAGS="-f macho64"
 164       ;;
 165       arm*)
 166         ac_cv_c_bigendian="no"
 167         ac_cv_c_attribute_packed="no"
 168       ;;
 169     esac
 170
 171     SYS=darwin
 172     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 173     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 174     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 175     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu99 ${ARCH_flag}"
 176     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 177     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 178     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 179
 180     AC_EGREP_CPP(yes,
 181             [#import <TargetConditionals.h>
 182              #if TARGET_OS_IPHONE
 183              yes
 184              #endif],
 185              [HAVE_IOS="1"],
 186              [HAVE_OSX="1"])
 187
 188     dnl Allow binaries created on Lion to run on earlier releases
 189     AC_EGREP_CPP(yes,
 190            [#import <Cocoa/Cocoa.h>
 191             #ifdef MAC_OS_X_VERSION_10_7
 192             yes
 193             #endif],
 194             [AC_MSG_RESULT([yes])
 195             AC_LIBOBJ([getdelim])
 196             AC_LIBOBJ([strndup])
 197             AC_LIBOBJ([strnlen])],)
 198
 199     dnl
 200     dnl  Handle Mac OS X SDK flags
 201     dnl
 202     AC_ARG_WITH(macosx-sdk,
 203       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 204         [compile using the SDK in DIR])])
 205     if test "${with_macosx_sdk}" != "" ; then
 206         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 207         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 208         CC="${CC} -isysroot ${with_macosx_sdk}"
 209         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 210         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 211         LD="${LD} -syslibroot ${with_macosx_sdk}"
 212     fi
 213     AC_ARG_WITH(macosx-version-min,
 214       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 215         [compile for Mac OS X VERSION and above])])
 216     if test "${with_macosx_version_min}" != "" ; then
 217         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 218         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 219         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 220         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 221         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 222     fi
 223     ;;
 224   *mingw32* | *cygwin* | *wince* | *mingwce*)
 225     AC_CHECK_TOOL(WINDRES, windres, :)
 226     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 227     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
 228     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
 229     AH_TOP([#endif])
 230     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 231     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 232     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 233     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 234     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 235     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 236     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 237     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 238     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 239     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 240     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 241
 242     case "${host_os}" in
 243       *mingw32*)
 244         SYS=mingw32
 245         ;;
 246       *cygwin*)
 247         dnl Check if we are using the mno-cygwin mode in which case we are
 248         dnl actually dealing with a mingw32 compiler.
 249         AC_EGREP_CPP(yes,
 250             [#ifdef _WIN32
 251              yes
 252              #endif],
 253             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 254         ;;
 255     esac
 256
 257     if test "${SYS}" = "mingw32"; then
 258         # DEP, ASLR, NO SEH
 259         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 260
 261         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 262         ac_default_prefix="`pwd`/_win32"
 263         DESTDIR="`pwd`/_win32/"
 264
 265         dnl
 266         dnl NSIS/MSI Installer prefix and WIN64
 267         dnl
 268         case "${host}" in
 269             amd64*|x86_64*)
 270                 HAVE_WIN64="1"
 271                 WINDOWS_ARCH="x64"
 272                 PROGRAMFILES="PROGRAMFILES64"
 273                 YASMFLAGS="-f win64"
 274             ;;
 275             *)
 276                 WINDOWS_ARCH="x86"
 277                 PROGRAMFILES="PROGRAMFILES"
 278                 YASMFLAGS="-f win32"
 279             ;;
 280         esac
 281         AC_SUBST(WINDOWS_ARCH)
 282         AC_SUBST(PROGRAMFILES)
 283
 284     fi
 285     ;;
 286   *nto*)
 287     SYS=nto
 288     ;;
 289   solaris*)
 290     SYS=solaris
 291     ;;
 292   hpux*)
 293     SYS=hpux
 294     ;;
 295   symbian*)
 296     SYS=symbian
 297     ;;
 298   *os2*)
 299     SYS=os2
 300     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 301     AC_LIBOBJ([freeaddrinfo])
 302     ;;
 303   *)
 304     SYS="${host_os}"
 305     ;;
 306 esac
 307 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 308 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 309 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 310 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 311 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1")
 312 AM_CONDITIONAL(HAVE_SYMBIAN, test "${SYS}" = "symbian")
 313 AM_CONDITIONAL(HAVE_IOS,   test "${HAVE_IOS}" = "1")
 314 AM_CONDITIONAL(HAVE_OSX,   test "${HAVE_OSX}" = "1")
 315
 316 AC_SUBST(YASMFLAGS)
 317
 318 dnl
 319 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 320 dnl for program foo on win32
 321 case "${build_os}" in
 322     cygwin|msys)
 323         ac_executable_extensions=".exe"
 324     ;;
 325     *)
 326     ;;
 327 esac
 328
 329 dnl Android is linux, but a bit different
 330 AS_IF([test "$SYS" = linux],[
 331     AC_MSG_CHECKING([for an Android system])
 332     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 333         [[#ifndef __ANDROID__
 334          # error Not Android
 335          #endif
 336         ]],[[;]])
 337     ],[
 338       HAVE_ANDROID="1"
 339       AC_MSG_RESULT([yes])
 340     ],[
 341       AC_MSG_RESULT([no])
 342     ])
 343 ])
 344 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 345
 346
 347 dnl
 348 dnl  Check for the contrib directory
 349 dnl
 350 AC_ARG_WITH(contrib,
 351   [AS_HELP_STRING([--with-contrib[=DIR]],
 352     [search for 3rd party libraries in DIR/include and DIR/lib])
 353 ])
 354 AC_MSG_CHECKING([for 3rd party libraries path])
 355 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 356   CONTRIB_DIR="${srcdir}/contrib/${host}"
 357   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 358     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 359     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 360     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 361       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 362       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
 363       AS_IF([test ! -d "${CONTRIB_DIR}"], [
 364         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 365         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
 366         AS_IF([test ! -d "${CONTRIB_DIR}"], [
 367           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 368           CONTRIB_DIR=""
 369           AC_MSG_RESULT([not found])
 370         ])
 371       ])
 372     ])
 373   ])
 374 ], [
 375   AS_IF([test "${with_contrib}" != "no"], [
 376     CONTRIB_DIR="${with_contrib}"
 377   ], [
 378     CONTRIB_DIR=""
 379     AC_MSG_RESULT([disabled])
 380   ])
 381 ])
 382 AS_IF([test -n "${CONTRIB_DIR}"], [
 383   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 384     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 385   ], [
 386     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 387     CONTRIB_DIR=""
 388     AC_MSG_RESULT([not usable])
 389   ])
 390
 391 ])
 392 AS_IF([test -n "${CONTRIB_DIR}"], [
 393   AC_MSG_RESULT([${CONTRIB_DIR}])
 394   export PATH=${CONTRIB_DIR}/bin:$PATH
 395   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 396   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 397   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 398   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
 399   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 400   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 401
 402   AS_IF([test "${SYS}" = "darwin"], [
 403     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 404     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 405   ])
 406 ], [
 407   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 408     AC_MSG_ERROR([Third party libraries not found!])
 409   ])
 410 ])
 411 AC_SUBST(CONTRIB_DIR)
 412
 413 dnl Add extras/tools to the PATH
 414 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 415 AS_IF([test -d "${TOOLS_DIR}"], [
 416     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 417     export PATH="${TOOLS_DIR}":$PATH
 418 ])
 419
 420 dnl
 421 dnl  Libtool
 422 dnl  It's very bad, but our former custom system was worst
 423 dnl  -- Courmisch
 424 dnl
 425
 426 dnl override platform specific check for dependent libraries
 427 dnl otherwise libtool linking of shared libraries will
 428 dnl fail on anything other than pass_all.
 429 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 430     [lt_cv_deplibs_check_method=pass_all])
 431
 432 LT_INIT([dlopen win32-dll shared disable-static])
 433 LT_LANG([C++])
 434 LT_LANG([Windows Resource])
 435
 436 DOLT
 437
 438 lt_cv_deplibs_check_method=pass_all
 439
 440 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 441   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 442 ])
 443
 444 dnl
 445 dnl Gettext stuff
 446 dnl
 447 AM_GNU_GETTEXT_VERSION([0.19.2])
 448 AM_GNU_GETTEXT([external], [need-ngettext])
 449
 450 dnl
 451 dnl Iconv stuff
 452 dnl
 453 AM_ICONV
 454
 455 dnl
 456 dnl checks for mingw
 457 AS_IF([test "${SYS}" = "mingw32"], [
 458
 459 dnl Check for broken versions of mingw-runtime compatability library
 460     AC_MSG_CHECKING(for broken mingw-runtime)
 461     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 462 #include <_mingw.h>
 463 #if defined(__MINGW64_VERSION_MAJOR)
 464 # if __MINGW64_VERSION_MAJOR < 3
 465 #  error Attempting to use mingw-runtime with broken vsnprintf and direct2d support
 466 # endif
 467 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
 468 # error Attempting to use mingw-runtime with broken vsnprintf support
 469 #endif
 470     ])], [
 471         AC_MSG_RESULT([ok])
 472     ], [
 473         AC_MSG_RESULT([present])
 474         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
 475     ])
 476
 477     dnl force use of mingw provided c99 *printf over msvcrt
 478     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 479
 480     dnl Add WinMainCRTStartup entry point to show it's a WinMain application
 481     VLC_ADD_LDFLAGS([vlc],[-mwindows])
 482
 483     dnl Check for the need to include the mingwex lib for mingw32
 484     VLC_SAVE_FLAGS
 485     AC_CHECK_LIB(mingwex,opendir,
 486         AC_CHECK_LIB(mingw32,opendir,,
 487             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 488     )
 489     VLC_RESTORE_FLAGS
 490
 491     dnl Check for fnative-struct or mms-bitfields support for mingw32
 492     VLC_SAVE_FLAGS
 493     CFLAGS="${CFLAGS} -mms-bitfields"
 494     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
 495     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 496         [ac_cv_c_mms_bitfields],
 497         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 498     if test "${ac_cv_c_mms_bitfields}" = "no"; then
 499         VLC_RESTORE_FLAGS
 500         CFLAGS="${CFLAGS} -fnative-struct"
 501         CXXFLAGS="${CXXFLAGS} -fnative-struct"
 502         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 503             [ac_cv_c_fnative_struct],
 504             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 505         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
 506     fi
 507 ])
 508
 509 AC_ARG_ENABLE(winstore_app,
 510      AS_HELP_STRING([--enable-winstore-app],
 511                     [Build targetted for Windows Store apps (default disabled)]))
 512
 513 vlc_winstore_app=0
 514 AS_IF([test "${SYS}" = "mingw32"],[
 515   AS_IF([test "${enable_winstore_app}" = "yes"], [
 516     vlc_winstore_app=1
 517      VLC_ADD_LIBS([libvlccore], [-lole32 -lruntimeobject])
 518     ],[
 519      VLC_ADD_LIBS([win32text],[-lgdi32])
 520      VLC_ADD_LIBS([libvlccore],[-lwinmm])
 521     ])
 522   ])
 523 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 524 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 525
 526
 527 dnl
 528 dnl Buggy glibc prevention. Purposedly not cached.
 529 dnl See sourceware.org bugs 5058 and 5443.
 530 dnl Ubuntu alone has 20 bug numbers for this...
 531 dnl
 532 AC_MSG_CHECKING(for buggy GNU/libc versions)
 533 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 534 #include <limits.h>
 535 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 536   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 537 # error GNU/libc with dcgettext killer bug!
 538 #endif
 539 ])], [
 540   AC_MSG_RESULT([not present])
 541 ], [
 542   AC_MSG_RESULT([found])
 543   AS_IF([test "x${enable_nls}" != "xno"], [
 544     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 545 work-around for this. Check with your distribution vendor on how to update the
 546 glibc run-time. Alternatively, build with --disable-nls.])
 547   ])
 548 ])
 549
 550 dnl Plugin compilation stuff
 551
 552 VLC_LIBRARY_SUFFIX
 553
 554 dnl Check for system libs needed
 555 need_libc=false
 556
 557 dnl Check for usual libc functions
 558 AC_CHECK_DECLS([nanosleep],,,[#include <time.h>])
 559 AC_CHECK_FUNCS([daemon fcntl fstatvfs fork getenv getpwuid_r isatty lstat memalign mmap open_memstream openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime uselocale pthread_cond_timedwait_monotonic_np pthread_condattr_setclock])
 560 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir flockfile fsync getdelim getpid gmtime_r lldiv localtime_r nrand48 poll posix_memalign rewind setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strsep strtof strtok_r strtoll swab tdestroy strverscmp])
 561 AC_CHECK_FUNCS(fdatasync,,
 562   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 563 ])
 564
 565 dnl mingw64 implements those as static inline, not functions with C linkage
 566 AC_LINK_IFELSE([
 567     AC_LANG_PROGRAM([#include <stdio.h>], [
 568         char *c;
 569         if (asprintf(&c, "%s %d", "string", 1) == -1)
 570             c = NULL;
 571     ])],[AC_DEFINE([HAVE_ASPRINTF],[1],[Define to 1 if you have asprintf function])],[AC_LIBOBJ([asprintf])])
 572 AC_LINK_IFELSE([
 573     AC_LANG_PROGRAM([#include <stdio.h>
 574                      #include <stdarg.h>], [
 575         char *c;
 576         va_list ap;
 577         if (vasprintf(&c, "%s %d", ap) == -1)
 578             c = NULL;
 579     ])],[AC_DEFINE([HAVE_VASPRINTF],[1],[Define to 1 if you have asprintf function])],[AC_LIBOBJ([vasprintf])])
 580
 581 dnl C11 static_assert()
 582 AC_MSG_CHECKING([for static_assert in assert.h])
 583 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 584 static_assert(1, "The impossible happened.");
 585 ])], [
 586   AC_MSG_RESULT([yes])
 587   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 588 ], [
 589   AC_MSG_RESULT([no])
 590 ])
 591
 592 # Windows CE does not have strcoll()
 593 AC_FUNC_STRCOLL
 594
 595 dnl Check for non-standard system calls
 596 case "$SYS" in
 597   "linux")
 598     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity])
 599     ;;
 600   "mingw32")
 601     AC_CHECK_FUNCS([_lock_file])
 602     ;;
 603 esac
 604
 605 AH_BOTTOM([#include <vlc_fixups.h>])
 606
 607 dnl Check for struct pollfd
 608 AC_CHECK_TYPES([struct pollfd],,,
 609 [#include <sys/types.h>
 610 #if HAVE_POLL
 611 # include <poll.h>
 612 #elif defined (_WIN32)
 613 # define _WIN32_WINNT 0x502
 614 # include <winsock2.h>
 615 #endif
 616 ])
 617
 618 dnl Checks for socket stuff
 619 VLC_SAVE_FLAGS
 620 SOCKET_LIBS=""
 621 AC_SEARCH_LIBS(connect, [socket], [
 622   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 623     SOCKET_LIBS="$ac_cv_search_connect"
 624   ])
 625 ], [
 626   AS_IF([test "${SYS}" = "mingw32"], [
 627     SOCKET_LIBS="-lws2_32"
 628   ])
 629 ])
 630
 631 AC_SEARCH_LIBS([inet_pton], [nsl], [
 632  AS_IF([test "$ac_cv_search_getaddrinfo" != "none required"], [
 633     SOCKET_LIBS="$ac_cv_search_getaddrinfo $SOCKET_LIBS"
 634   ])
 635 ],, [${SOCKET_LIBS}])
 636
 637 LIBS="${LIBS} ${SOCKET_LIBS}"
 638 AC_LINK_IFELSE([
 639     AC_LANG_PROGRAM([#ifdef _WIN32
 640         # if _WIN32_WINNT < 0x600
 641         #  error Needs vista+
 642         # endif
 643         #include <ws2tcpip.h>
 644         #else
 645         #include <sys/socket.h>
 646         #include <arpa/inet.h>
 647         #endif], [
 648         char dst[[sizeof(struct in_addr)]];
 649         inet_pton(AF_INET, "127.0.0.1", dst);
 650     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 651 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
 652 VLC_RESTORE_FLAGS
 653
 654 AS_IF([test -n "$SOCKET_LIBS"], [
 655   VLC_ADD_LIBS([access_rtmp access_output_shout sap stream_out_standard stream_out_rtp stream_out_raop stream_out_chromecast oldrc netsync ts remoteosd audiobargraph_a],[${SOCKET_LIBS}])
 656 ])
 657 AC_SUBST(SOCKET_LIBS)
 658
 659 dnl Check for socklen_t
 660 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 661 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 662 ac_cv_type_socklen_t,
 663 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 664 [#include <sys/types.h>
 665 #ifdef _WIN32
 666 # include <winsock2.h>
 667 # include <ws2tcpip.h>
 668 #else
 669 # include <sys/socket.h>
 670 #endif]], [[socklen_t len; len = 0;]])],
 671 ac_cv_type_socklen_t=yes,
 672 ac_cv_type_socklen_t=no)])
 673 AS_IF([test "$ac_cv_type_socklen_t" = no],
 674  [AC_DEFINE(socklen_t, int)])
 675
 676 dnl Check for struct sockaddr_storage
 677 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 678 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 679 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 680   [AC_TRY_COMPILE(
 681     [#include <sys/types.h>
 682      #if defined( _WIN32 )
 683      # include <winsock2.h>
 684      #else
 685      # include <sys/socket.h>
 686      #endif], [struct sockaddr_storage addr;],
 687      ac_cv_struct_sockaddr_storage=yes,
 688      ac_cv_struct_sockaddr_storage=no)])
 689 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 690   AC_DEFINE(sockaddr_storage, sockaddr)
 691   AC_DEFINE(ss_family, sa_family)
 692 ])
 693
 694 dnl FreeBSD has a gnugetopt library for this:
 695 GNUGETOPT_LIBS=""
 696 AC_CHECK_FUNC(getopt_long,, [
 697   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 698     GNUGETOPT_LIBS="-lgnugetopt"
 699   ])
 700 ])
 701 AC_SUBST(GNUGETOPT_LIBS)
 702
 703 AC_CHECK_LIB(m,cos,[
 704   VLC_ADD_LIBS([adjust wave ripple psychedelic gradient a52tofloat32 dtstofloat32 x264 goom noise grain scene chorus_flanger freetype swscale postproc equalizer spatializer param_eq samplerate freetype mpc qt4 compressor headphone_channel_mixer normvol audiobargraph_a audiobargraph_v mono colorthres extract ball hotkeys mosaic gaussianblur x262 x26410b hqdn3d anaglyph oldrc ncurses oldmovie glspectrum smooth],[-lm])
 705   LIBM="-lm"
 706 ], [
 707   LIBM=""
 708 ])
 709 AC_SUBST(LIBM)
 710
 711 AC_CHECK_LIB(m,lrintf, [
 712   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 713   VLC_ADD_LIBS([skins2],[-lm])
 714 ])
 715 AC_CHECK_LIB(m,nanf,
 716   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 717 )
 718
 719 dnl Check for dynamic plugins
 720 LIBDL=""
 721 have_dynamic_objects="no"
 722 VLC_SAVE_FLAGS
 723 AC_SEARCH_LIBS(dlsym, [dl svld], [
 724   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 725     LIBDL="$ac_cv_search_dlsym"
 726   ])
 727   have_dynamic_objects="yes"
 728 ])
 729 VLC_RESTORE_FLAGS
 730
 731 # Windows
 732 AS_IF([test "${SYS}" = "mingw32"], [
 733   LIBDL=""
 734   have_dynamic_objects="yes" #assume we can use shared objects
 735 ])
 736
 737 AS_IF([test "${enable_shared}" = "no"], [
 738   have_dynamic_objects=no
 739 ])
 740 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 741
 742 AC_SUBST(LIBDL)
 743
 744 dnl Check for thread library
 745 LIBPTHREAD=""
 746 AS_IF([test "${SYS}" != "mingw32"], [
 747   VLC_SAVE_FLAGS
 748   LIBS=""
 749   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 750     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 751       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 752     ])
 753   ])
 754   VLC_RESTORE_FLAGS
 755
 756   AC_CHECK_LIB(rt, clock_nanosleep, [
 757     VLC_ADD_LIBS([libvlccore],[-lrt])
 758   ], [
 759     AC_CHECK_FUNC(nanosleep,,[
 760       AC_CHECK_LIB(rt,nanosleep, [
 761         VLC_ADD_LIBS([libvlccore],[-lrt])
 762       ], [
 763         AC_CHECK_LIB(posix4,nanosleep, [
 764           VLC_ADD_LIBS([libvlccore],[-lposix4])
 765         ])
 766       ])
 767     ])
 768     dnl HP/UX port
 769     AC_CHECK_LIB(rt,sem_init, [VLC_ADD_LIBS([libvlccore],[-lrt])])
 770   ])
 771 ])
 772 AC_SUBST(LIBPTHREAD)
 773
 774 dnl Check for headers
 775 dnl  POSIX
 776 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h syslog.h sys/shm.h sys/socket.h])
 777 AC_CHECK_HEADERS([net/if.h], [], [],
 778 [
 779 #include <sys/types.h>
 780 #include <sys/socket.h>
 781 ])
 782 dnl  BSD
 783 AC_CHECK_HEADERS([netinet/udplite.h sys/param.h sys/mount.h])
 784 dnl  GNU/Linux
 785 AC_CHECK_HEADERS([getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 786 dnl  MacOS
 787 AC_CHECK_HEADERS([xlocale.h])
 788
 789 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 790 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 791 AC_CHECK_TYPE(ssize_t,, [
 792   AC_DEFINE(ssize_t, int)
 793 ])
 794
 795 dnl It seems that autoconf detects pkg-config only during the first
 796 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 797 dnl it is nested within a conditional block, so it was not working right.
 798 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 799 AC_ARG_VAR(PKG_CONFIG_PATH,
 800        [Paths where to find .pc not at the default location])
 801 PKG_PROG_PKG_CONFIG()
 802
 803 dnl On some OS we need static linking
 804 AS_IF([test -n "${PKG_CONFIG}" ],[
 805     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 806         PKG_CONFIG="${PKG_CONFIG} --static"
 807     ])
 808 ])
 809
 810
 811 dnl
 812 dnl Check for zlib.h and -lz along with system -lminizip if available
 813 dnl
 814 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 815 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 816 if test "${have_zlib}" = "yes"
 817 then
 818   VLC_ADD_LIBS([skins2 sap unzip zip],[-lz])
 819   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 820     AC_CHECK_HEADERS([unzip.h], [
 821       have_minizip=yes
 822       MINIZIP_LIBS="-lminizip -lz"
 823     ], [
 824       VLC_ADD_CPPFLAGS([skins2], [-I\\\$(top_srcdir)/modules/access/zip/unzip])
 825       VLC_ADD_LIBS([skins2], [\\\$(top_builddir)/modules/libunzip.la])
 826       have_minizip=no
 827     ])
 828   ])
 829   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
 830   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
 831 fi
 832 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 833
 834
 835 dnl
 836 dnl Domain name i18n support via GNU libidn
 837 dnl
 838 PKG_CHECK_MODULES([IDN], [libidn], [
 839   have_libidn="yes"
 840   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 841 ], [
 842   have_libidn="no"
 843 ])
 844
 845
 846 dnl Check for dbus
 847 AC_ARG_ENABLE(dbus,
 848   [AS_HELP_STRING([--enable-dbus],
 849     [compile D-Bus message bus support (default enabled)])])
 850 have_dbus="no"
 851 AS_IF([test "${enable_dbus}" != "no"], [
 852   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 853     have_dbus="yes"
 854   ], [
 855     AS_IF([test -n "${enable_dbus}"], [
 856       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 857     ], [
 858       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 859     ])
 860   ])
 861 ])
 862 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 863
 864 dnl Check for ntohl, etc.
 865 VLC_SAVE_FLAGS
 866 CFLAGS="${CFLAGS} -Wall -Werror"
 867 AC_CACHE_CHECK([for ntohl in sys/param.h],
 868     [ac_cv_c_ntohl_sys_param_h],
 869     [     AC_TRY_COMPILE([#include <sys/param.h>],
 870         [int meuh; ntohl(meuh);],
 871         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
 872 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
 873     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
 874 fi
 875 VLC_RESTORE_FLAGS
 876
 877 EXTEND_HELP_STRING([Optimization options:])
 878 dnl
 879 dnl  Compiler warnings
 880 dnl
 881
 882 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration init-self logical-op])
 883 RDC_PROG_CC_FLAGS([-pipe])
 884 AC_LANG_PUSH([C++])
 885 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var])
 886 AC_LANG_POP([C++])
 887
 888 dnl
 889 dnl  Debugging mode
 890 dnl
 891 AC_ARG_ENABLE(debug,
 892   [AS_HELP_STRING([--enable-debug],
 893     [build with run-time assertions (default disabled)])],,
 894   [enable_debug="no"])
 895 AH_TEMPLATE(NDEBUG,
 896             [Define to 1 if debug code should NOT be compiled])
 897 AS_IF([test "${enable_debug}" != "no"], [
 898   AC_CHECK_HEADERS([valgrind/valgrind.h])
 899 ], [
 900   AC_DEFINE(NDEBUG)
 901 ])
 902
 903 dnl
 904 dnl  Profiling
 905 dnl
 906 AC_ARG_ENABLE(gprof,
 907   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 908   [enable_gprof="no"])
 909 AS_IF([test "${enable_gprof}" != "no"], [
 910   CFLAGS="${CFLAGS} -pg"
 911   CXXFLAGS="${CXXFLAGS} -pg"
 912   OBJCFLAGS="${OBJCFLAGS} -pg"
 913   LDFLAGS="${LDFLAGS} -pg"
 914 ])
 915
 916 AC_ARG_ENABLE(cprof,
 917   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 918   [enable_cprof="no"])
 919 AS_IF([test "${enable_gprof}" != "no"], [
 920   CFLAGS="${CFLAGS} -finstrument-functions"
 921   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 922   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 923   LDFLAGS="${LDFLAGS} -finstrument-functions"
 924 ])
 925
 926 dnl
 927 dnl  Test coverage
 928 dnl
 929 AC_ARG_ENABLE(coverage,
 930   [AS_HELP_STRING([--enable-coverage],
 931     [build for test coverage (default disabled)])],,
 932   [enable_coverage="no"])
 933 AS_IF([test "${enable_coverage}" != "no"], [
 934   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 935   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 936   LDFLAGS="-lgcov ${LDFLAGS}"
 937 ])
 938
 939 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
 940   VLC_SAVE_FLAGS
 941   CFLAGS="${CFLAGS} -fvisibility=hidden"
 942   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
 943   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
 944   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
 945                  [ac_cv_c_visibility_hidden], [
 946     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 947       ac_cv_c_visibility_hidden=yes
 948     ], [
 949       ac_cv_c_visibility_hidden=no
 950     ])
 951   ])
 952   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
 953 ])
 954
 955
 956 dnl
 957 dnl  Enable/disable optimizations
 958 dnl
 959 AC_ARG_ENABLE(optimizations,
 960   [AS_HELP_STRING([--disable-optimizations],
 961     [disable compiler optimizations (default enabled)])],,
 962   [enable_optimizations="yes"])
 963
 964 dnl Check for various optimization flags
 965 AS_IF([test "${enable_optimizations}" != "no"], [
 966
 967   dnl -O3 only in production builds
 968   AS_IF([test "${enable_debug}" = "no"], [
 969     VLC_SAVE_FLAGS
 970     CFLAGS="${CFLAGS} -O3"
 971     CXXFLAGS="${CXXFLAGS} -O3"
 972     OBJCFLAGS="${OBJCFLAGS} -O3"
 973     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
 974       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 975         ac_cv_c_o3=yes
 976       ], [
 977         ac_cv_c_o3=no
 978       ])
 979     ])
 980     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
 981   ])
 982
 983   dnl Check for -ffast-math
 984   VLC_SAVE_FLAGS
 985   CFLAGS="${CFLAGS} -ffast-math"
 986   CXXFLAGS="${CXXFLAGS} -ffast-math"
 987   OBJCFLAGS="${OBJCFLAGS} -ffast-math"
 988   AC_CACHE_CHECK([if $CC accepts -ffast-math], [ac_cv_c_fast_math], [
 989     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 990       ac_cv_c_fast_math=yes
 991     ], [
 992       ac_cv_c_fast_math=no
 993     ])
 994   ])
 995   AS_IF([test "${ac_cv_c_fast_math}" = "no"], [VLC_RESTORE_FLAGS])
 996   AH_BOTTOM([
 997 #ifndef __FAST_MATH__
 998 # ifndef _MSC_VER
 999 #  pragma STDC FENV_ACCESS OFF
1000 #  pragma STDC FP_CONTRACT ON
1001 # else
1002 #  pragma fenv_access(off)
1003 #  pragma fp_contract(on)
1004 # endif
1005 #endif
1006 ])
1007
1008   dnl Check for -funroll-loops
1009   VLC_SAVE_FLAGS
1010   CFLAGS="${CFLAGS} -funroll-loops"
1011   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1012   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1013   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1014     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1015       ac_cv_c_unroll_loops=yes
1016     ], [
1017       ac_cv_c_unroll_loops=no
1018     ])
1019   ])
1020   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1021
1022   AS_IF([test "$enable_debug" = "no"], [
1023     dnl Check for -fomit-frame-pointer
1024     VLC_SAVE_FLAGS
1025     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1026     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1027     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1028     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1029       [ac_cv_c_omit_frame_pointer], [
1030       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1031         ac_cv_c_omit_frame_pointer=yes
1032       ], [
1033         ac_cv_c_omit_frame_pointer=no
1034       ])
1035     ])
1036     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1037   ])
1038 ])
1039
1040 VLC_SAVE_FLAGS
1041 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1042 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1043   AC_TRY_LINK([],, [
1044     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1045   ], [
1046     ac_cv_ld_bsymbolic=""
1047   ])
1048 ])
1049 VLC_RESTORE_FLAGS
1050 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1051 AC_SUBST(SYMBOLIC_LDFLAGS)
1052
1053 dnl Checks for __attribute__(aligned()) directive
1054 VLC_SAVE_FLAGS
1055 CFLAGS="${CFLAGS} -Werror"
1056 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1057     [ac_cv_c_attribute_aligned],
1058     [ac_cv_c_attribute_aligned=0
1059     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1060         AC_TRY_COMPILE([],
1061         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1062         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1063     done])
1064 VLC_RESTORE_FLAGS
1065 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1066     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1067         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1068 fi
1069
1070 dnl Check for __attribute__((packed))
1071 AC_CACHE_CHECK([for __attribute__((packed))],
1072   [ac_cv_c_attribute_packed],
1073   [ac_cv_c_attribute_packed=no
1074    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1075                     [ac_cv_c_attribute_packed=yes])])
1076 if test "${ac_cv_c_attribute_packed}" != "no"; then
1077   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1078 fi
1079
1080 dnl
1081 dnl  Check the CPU
1082 dnl
1083 case "${host_cpu}" in
1084   "")
1085     ARCH=unknown
1086     ;;
1087   *)
1088     ARCH="${host_cpu}"
1089     ;;
1090 esac
1091
1092 dnl Check for backtrace() support
1093 AC_CHECK_HEADERS(execinfo.h)
1094 AC_CHECK_FUNCS(backtrace)
1095
1096 dnl
1097 dnl  default modules
1098 dnl
1099 ALIASES="${ALIASES} cvlc rvlc"
1100
1101 dnl
1102 dnl  Accelerated modules
1103 dnl
1104
1105 dnl  Check for fully working MMX intrinsics
1106 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1107 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1108 AC_ARG_ENABLE(mmx,
1109   [AS_HELP_STRING([--disable-mmx],
1110     [disable MMX optimizations (default auto)])],,[
1111   case "${host_cpu}" in
1112     i?86|x86_64)
1113       enable_mmx="yes"
1114       ;;
1115     *)
1116       enable_mmx="no"
1117       ;;
1118   esac
1119 ])
1120 have_mmx="no"
1121 have_mmxext="no"
1122 AS_IF([test "${enable_mmx}" != "no"], [
1123   ARCH="${ARCH} mmx"
1124   VLC_SAVE_FLAGS
1125   CFLAGS="${CFLAGS} -mmmx"
1126   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1127     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1128 [#include <mmintrin.h>
1129 #include <stdint.h>
1130 uint64_t frobzor;]], [
1131 [__m64 a, b, c;
1132 a = b = c = (__m64)frobzor;
1133 a = _mm_slli_pi16(a, 3);
1134 a = _mm_adds_pi16(a, b);
1135 c = _mm_srli_pi16(c, 8);
1136 c = _mm_slli_pi16(c, 3);
1137 b = _mm_adds_pi16(b, c);
1138 a = _mm_unpacklo_pi8(a, b);
1139 frobzor = (uint64_t)a;]])], [
1140       ac_cv_c_mmx_intrinsics=yes
1141     ], [
1142       ac_cv_c_mmx_intrinsics=no
1143     ])
1144   ])
1145   VLC_RESTORE_FLAGS
1146   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1147     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1148   ])
1149
1150   VLC_SAVE_FLAGS
1151   CFLAGS="${CFLAGS} -mmmx"
1152   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1153     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1154 void *p;
1155 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1156 ]])
1157     ], [
1158       ac_cv_mmx_inline=yes
1159     ], [
1160       ac_cv_mmx_inline=no
1161     ])
1162   ])
1163   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1164     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1165     have_mmx="yes"
1166   ])
1167
1168   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1169                  [ac_cv_mmxext_inline], [
1170     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1171 void *p;
1172 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1173 ]])
1174     ], [
1175       ac_cv_mmxext_inline=yes
1176     ], [
1177       ac_cv_mmxext_inline=no
1178     ])
1179   ])
1180   VLC_RESTORE_FLAGS
1181   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1182     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1183     have_mmxext="yes"
1184   ])
1185 ])
1186 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1187 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1188
1189 dnl  Check for fully workin SSE2 intrinsics
1190 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1191 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1192 AC_ARG_ENABLE(sse,
1193   [AS_HELP_STRING([--disable-sse],
1194     [disable SSE (1-4) optimizations (default auto)])],, [
1195   case "${host_cpu}" in
1196     i?86|x86_64)
1197       enable_sse=yes
1198       ;;
1199     *)
1200       enable_sse=no
1201       ;;
1202   esac
1203 ])
1204 have_sse2="no"
1205 AS_IF([test "${enable_sse}" != "no"], [
1206   ARCH="${ARCH} sse sse2"
1207
1208   VLC_SAVE_FLAGS
1209   CFLAGS="${CFLAGS} -msse2"
1210   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1211     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1212 [#include <emmintrin.h>
1213 #include <stdint.h>
1214 uint64_t frobzor;]], [
1215 [__m128i a, b, c;
1216 a = b = c = _mm_set1_epi64((__m64)frobzor);
1217 a = _mm_slli_epi16(a, 3);
1218 a = _mm_adds_epi16(a, b);
1219 c = _mm_srli_epi16(c, 8);
1220 c = _mm_slli_epi16(c, 3);
1221 b = _mm_adds_epi16(b, c);
1222 a = _mm_unpacklo_epi8(a, b);
1223 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1224       ac_cv_c_sse2_intrinsics=yes
1225     ], [
1226       ac_cv_c_sse2_intrinsics=no
1227     ])
1228   ])
1229   VLC_RESTORE_FLAGS
1230   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1231     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1232   ])
1233
1234   VLC_SAVE_FLAGS
1235   CFLAGS="${CFLAGS} -msse"
1236   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1237     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1238 void *p;
1239 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1240 ]])
1241     ], [
1242       ac_cv_sse_inline=yes
1243     ], [
1244       ac_cv_sse_inline=no
1245     ])
1246   ])
1247
1248   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1249     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1250   ])
1251
1252   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1253     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1254 void *p;
1255 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1256 ]])
1257     ], [
1258       ac_cv_sse2_inline=yes
1259     ], [
1260       ac_cv_sse2_inline=no
1261     ])
1262   ])
1263   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1264     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1265     have_sse2="yes"
1266   ])
1267
1268   # SSE3
1269   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1270     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1271 void *p;
1272 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1273 ]])
1274     ], [
1275       ac_cv_sse3_inline=yes
1276     ], [
1277       ac_cv_sse3_inline=no
1278     ])
1279   ])
1280
1281   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1282     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1283   # SSSE3
1284   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1285     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1286 void *p;
1287 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1288 ]])
1289     ], [
1290       ac_cv_ssse3_inline=yes
1291     ], [
1292       ac_cv_ssse3_inline=no
1293     ])
1294   ])
1295
1296   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1297     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1298
1299   # SSE4.1
1300   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1301                  [ac_cv_sse4_1_inline], [
1302     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1303 void *p;
1304 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1305 ]])
1306     ], [
1307       ac_cv_sse4_1_inline=yes
1308     ], [
1309       ac_cv_sse4_1_inline=no
1310     ])
1311   ])
1312
1313   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1314     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1315
1316   # SSE4.2
1317   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1318                  [ac_cv_sse4_2_inline], [
1319     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1320 void *p;
1321 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1322 ]])
1323     ], [
1324       ac_cv_sse4_2_inline=yes
1325     ], [
1326       ac_cv_sse4_2_inline=no
1327     ])
1328   ])
1329
1330   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1331     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1332
1333   # SSE4A
1334   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1335     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1336 void *p;
1337 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1338 ]])
1339     ], [
1340       ac_cv_sse4a_inline=yes
1341     ], [
1342       ac_cv_sse4a_inline=no
1343     ])
1344   ])
1345   VLC_RESTORE_FLAGS
1346   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1347     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1348 ])
1349 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1350
1351 VLC_SAVE_FLAGS
1352 CFLAGS="${CFLAGS} -mmmx"
1353 have_3dnow="no"
1354 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1355   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1356 void *p;
1357 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1358 ]])
1359   ], [
1360     ac_cv_3dnow_inline=yes
1361   ], [
1362     ac_cv_3dnow_inline=no
1363   ])
1364 ])
1365 VLC_RESTORE_FLAGS
1366 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1367   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1368             [Define to 1 if 3D Now! inline assembly is available.])
1369   have_3dnow="yes"
1370 ])
1371 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1372
1373
1374 AC_ARG_ENABLE(neon,
1375   [AS_HELP_STRING([--disable-neon],
1376     [disable NEON optimizations (default auto)])],, [
1377   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1378 ])
1379 AS_IF([test "${enable_neon}" != "no"], [
1380   VLC_SAVE_FLAGS
1381   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1382   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1383     AC_COMPILE_IFELSE([
1384       AC_LANG_PROGRAM(,[[
1385 asm volatile("vqmovun.s64 d0, q1":::"d0");
1386 ]])
1387     ], [
1388       ac_cv_arm_neon="yes"
1389     ], [
1390       ac_cv_arm_neon="no"
1391     ])
1392   ])
1393   VLC_RESTORE_FLAGS
1394 ])
1395 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1396
1397
1398 AC_ARG_ENABLE(altivec,
1399   [AS_HELP_STRING([--disable-altivec],
1400     [disable AltiVec optimizations (default auto)])],, [
1401   AS_CASE("${host_cpu}", [powerpc*],
1402         [enable_altivec=yes], [enable_altivec=no])
1403 ])
1404 have_altivec="no"
1405 ALTIVEC_CFLAGS=""
1406 AS_IF([test "${enable_altivec}" = "yes"], [
1407   ARCH="${ARCH} altivec";
1408   VLC_SAVE_FLAGS
1409   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1410     [ac_cv_altivec_inline],
1411     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1412          ac_cv_altivec_inline="yes",
1413          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1414           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1415             [ac_cv_altivec_inline="-Wa,-maltivec"],
1416             ac_cv_altivec_inline=no)
1417          ])])
1418   VLC_RESTORE_FLAGS
1419   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1420     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1421               [Define to 1 if AltiVec inline assembly is available.])
1422     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1423       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1424       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1425     ])
1426     have_altivec="yes"
1427   ])
1428
1429   VLC_SAVE_FLAGS
1430   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1431   [ac_cv_c_altivec], [
1432     CFLAGS="${CFLAGS} -maltivec"
1433     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1434 [#include <altivec.h>]], [
1435 [vec_ld(0, (unsigned char *)0);]])], [
1436       ac_cv_c_altivec="-maltivec"
1437     ], [
1438       ac_cv_c_altivec="no"
1439     ])
1440   ])
1441   VLC_RESTORE_FLAGS
1442   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1443     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1444     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1445     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1446     ALTIVEC_CFLAGS="$ALTIVEC_FLAGS ${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}"
1447     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1448     have_altivec="yes"
1449   ])
1450   AC_CHECK_HEADERS(altivec.h)
1451
1452   VLC_SAVE_FLAGS
1453   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1454   AC_CACHE_CHECK([if linker needs -framework vecLib],
1455     [ac_cv_ld_altivec],
1456     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1457   VLC_RESTORE_FLAGS
1458   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1459     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1460   ])
1461 ])
1462 AC_SUBST(ALTIVEC_CFLAGS)
1463 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1464
1465 dnl
1466 dnl  Memory usage
1467 dnl
1468 AC_ARG_ENABLE(optimize-memory,
1469   [AS_HELP_STRING([--enable-optimize-memory],
1470     [optimize memory usage over performance])])
1471 if test "${enable_optimize_memory}" = "yes"; then
1472   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1473 fi
1474
1475 dnl
1476 dnl Allow running as root (useful for people running on embedded platforms)
1477 dnl
1478 AC_ARG_ENABLE(run-as-root,
1479   [AS_HELP_STRING([--enable-run-as-root],
1480     [allow running VLC as root (default disabled)])])
1481 AS_IF([test "${enable_run_as_root}" = "yes"],[
1482     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1483               [Define to 1 to allow running VLC as root (uid 0).])
1484 ])
1485
1486 dnl
1487 dnl Stream output
1488 dnl
1489 AC_ARG_ENABLE(sout,
1490   [AS_HELP_STRING([--disable-sout],
1491     [disable streaming output (default enabled)])])
1492 AS_IF([test "${enable_sout}" != "no"], [
1493   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1494 ])
1495 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1496
1497 dnl Lua modules
1498 AC_ARG_ENABLE(lua,
1499   [AS_HELP_STRING([--disable-lua],
1500     [disable LUA scripting support (default enabled)])])
1501 if test "${enable_lua}" != "no"
1502 then
1503   PKG_CHECK_MODULES(LUA, lua5.2,
1504     [ have_lua=yes ],
1505     [
1506     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1507
1508     PKG_CHECK_MODULES(LUA, lua5.1,
1509       [ have_lua=yes ],
1510       [
1511       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1512       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1513         [ have_lua=yes ],
1514         [
1515           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1516           have_lua=yes
1517           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1518             [],
1519             [ have_lua=no ] )
1520           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1521             [LUA_LIBS="-llua5.2"],
1522           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1523             [LUA_LIBS="-llua5.1"],
1524             AC_CHECK_LIB( lua51 , luaL_newstate,
1525               [LUA_LIBS="-llua51"],
1526               AC_CHECK_LIB( lua , luaL_newstate,
1527                 [LUA_LIBS="-llua"],
1528                 [ have_lua=no
1529                 ], [-lm])
1530             )))
1531         ])
1532       ])
1533     ])
1534   if test "x${have_lua}" != "xyes" ;  then
1535       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1536   fi
1537   AC_ARG_VAR([LUAC], [LUA byte compiler])
1538   AC_PATH_PROGS(LUAC,[${LUAC} luac], [false])
1539   AS_IF([test "${LUAC}" = "false"], [
1540     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1541   ])
1542   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1543     AC_MSG_ERROR([You need 32-bits luac when using using lua from contrib.])
1544   ])
1545 fi
1546 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1547
1548
1549 dnl
1550 dnl HTTP daemon
1551 dnl
1552 AC_ARG_ENABLE(httpd,
1553   [AS_HELP_STRING([--disable-httpd],
1554     [disable the built-in HTTP server (default enabled)])])
1555 if test "${enable_httpd}" != "no"
1556 then
1557   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1558 fi
1559 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1560
1561
1562 dnl
1563 dnl VideoLAN manager
1564 dnl
1565 AC_ARG_ENABLE(vlm,
1566   [AS_HELP_STRING([--disable-vlm],
1567     [disable the stream manager (default enabled)])],,
1568   [enable_vlm="${enable_sout}"])
1569 AS_IF([test "${enable_vlm}" != "no"], [
1570   AS_IF([test "${enable_sout}" = "no"], [
1571     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1572   ])
1573   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1574 ])
1575 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1576
1577
1578 dnl
1579 dnl Addons manager storage and repositories modules
1580 dnl
1581 AC_ARG_ENABLE(addonmanagermodules,
1582   [AS_HELP_STRING([--disable-addonmanagermodules],
1583     [disable the addons manager modules (default enabled)])])
1584 if test "${enable_addonmanagermodules}" != "no"
1585 then
1586   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1587 fi
1588 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1589
1590
1591 dnl
1592 dnl  Input plugins
1593 dnl
1594
1595 EXTEND_HELP_STRING([Input plugins:])
1596
1597 dnl
1598 dnl  libarchive access module
1599 dnl
1600 PKG_ENABLE_MODULES_VLC([ARCHIVE], [access_archive], [libarchive >= 2.8.5], (libarchive support), [auto])
1601
1602 dnl
1603 dnl  live555 input
1604 dnl
1605 AC_ARG_ENABLE(live555,
1606   [AS_HELP_STRING([--enable-live555],
1607     [enable RTSP input through live555 (default enabled)])])
1608
1609 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1610   PKG_CHECK_MODULES(LIVE555, live555, [
1611     VLC_ADD_PLUGIN([live555])
1612     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1613     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1614   ], [
1615     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1616
1617     AC_LANG_PUSH(C++)
1618     VLC_SAVE_FLAGS
1619
1620     dnl detect include paths
1621     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment.hh"], [
1622       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1623     ], [
1624       AS_IF([test "${SYS}" != "os2"], [
1625         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1626         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1627       ], [
1628         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1629         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1630         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1631       ])
1632     ])
1633
1634     dnl CPP Flags
1635     AS_IF([test "${SYS}" = "solaris"], [
1636       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1637     ])
1638     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1639     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1640
1641     dnl version check
1642     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1643       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1644 [#include <liveMedia_version.hh>
1645 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1646 # error BOOM
1647 #endif]])
1648       ], [
1649         ac_cv_live555="yes"
1650       ], [
1651         ac_cv_live555="no"
1652       ])
1653     ])
1654
1655     AS_IF([test "$ac_cv_live555" = "no"], [
1656       AC_MSG_WARN([live555 is missing or its installed version is too old:
1657 Version 2011.12.23 or later is required to proceed.
1658 You can get an updated one from http://www.live555.com/liveMedia .])
1659       AS_IF([test -n "${enable_live555}"], [
1660         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1661       ])
1662     ], [
1663       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1664       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1665       AS_IF([test "${SYS}" = "mingw32"], [
1666         # add ws2_32 for closesocket, select, recv
1667         other_libs="$other_libs -lws2_32"
1668       ])
1669
1670       dnl We need to check for pic because live555 don't provide shared libs
1671       dnl and we want to build a plugins so we need -fPIC on some arch.
1672       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1673       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1674       AC_CHECK_LIB(liveMedia_pic, main, [
1675         VLC_ADD_PLUGIN([live555])
1676         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1677       ],[
1678         AC_CHECK_LIB(liveMedia, main, [
1679           VLC_ADD_PLUGIN([live555])
1680           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1681         ],[],[${other_libs}])
1682       ],[${other_libs_pic}])
1683     ])
1684     VLC_RESTORE_FLAGS
1685     AC_LANG_POP(C++)
1686   ])
1687 ])
1688
1689 dnl
1690 dnl IIDC and DV FireWire input modules
1691 dnl
1692 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1693 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1694
1695 dnl
1696 dnl - linsys modules: access module check for libzvbi
1697 dnl
1698 AC_ARG_ENABLE(linsys,
1699   [AS_HELP_STRING([--enable-linsys],
1700     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1701 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1702   VLC_ADD_PLUGIN([linsys_hdsdi])
1703   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1704     VLC_ADD_PLUGIN([linsys_sdi])
1705   ], [
1706     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1707   ])
1708 ])
1709
1710 dnl
1711 dnl dvdread module: check for libdvdread
1712 dnl
1713 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1714
1715 dnl
1716 dnl libdvdnav plugin
1717 dnl
1718 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1719
1720 dnl
1721 dnl  Blu-ray Disc Support with libbluray
1722 dnl
1723 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.3.0], (libbluray for Blu-ray disc support ) )
1724
1725 dnl
1726 dnl  OpenCV wrapper and example filters
1727 dnl
1728 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1729
1730
1731 dnl
1732 dnl  libsmbclient plugin
1733 dnl
1734 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1735 AS_IF([test "${SYS}" = "mingw32"], [ VLC_ADD_PLUGIN([access_smb]) ])
1736
1737 dnl
1738 dnl  liBDSM access module
1739 dnl
1740 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm], [libdsm SMB/CIFS access/sd module], [auto])
1741
1742 dnl
1743 dnl sftp access support
1744 dnl
1745 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1746
1747 dnl
1748 dnl  Video4Linux 2
1749 dnl
1750 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1751   [disable Video4Linux version 2 (default auto)])])
1752 have_v4l2="no"
1753 AS_IF([test "$enable_v4l2" != "no"], [
1754   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1755     have_v4l2="yes"
1756   ])
1757 ])
1758 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1759
1760 dnl
1761 dnl special access module for Blackmagic SDI cards
1762 dnl
1763 AC_ARG_ENABLE(decklink,
1764   [AS_HELP_STRING([--disable-decklink],
1765     [disable Blackmagic DeckLink SDI input (default auto)])])
1766 AC_ARG_WITH(decklink_sdk,
1767   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1768     [                        location of Blackmagic DeckLink SDI SDK])])
1769 have_decklink=no
1770 if test "${enable_decklink}" != "no"
1771 then
1772   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1773   then
1774     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1775   fi
1776   VLC_SAVE_FLAGS
1777   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1778   AC_LANG_PUSH(C++)
1779   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1780       have_decklink=yes
1781   ], [
1782       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1783   ])
1784   AC_LANG_POP(C++)
1785   VLC_RESTORE_FLAGS
1786 fi
1787 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1788
1789
1790 dnl
1791 dnl  gnomeVFS access module
1792 dnl
1793 PKG_ENABLE_MODULES_VLC([GNOMEVFS], [gnomevfs], [gnome-vfs-2.0], [GnomeVFS access module], [auto])
1794
1795 dnl
1796 dnl  VCDX modules
1797 dnl
1798 PKG_ENABLE_MODULES_VLC([VCDX], [vcdx], [libcdio >= 0.78.2 libiso9660 >= 0.72 libvcdinfo >= 0.7.22], [navigate VCD with libvcdinfo], [no])
1799
1800 dnl
1801 dnl  Built-in CD-DA and VCD module
1802 dnl
1803 AC_ARG_ENABLE(vcd,
1804   [AS_HELP_STRING([--disable-vcd],
1805     [disable built-in VCD and CD-DA support (default enabled)])])
1806
1807 AC_ARG_ENABLE(libcddb,
1808   [AS_HELP_STRING([--disable-libcddb],
1809     [disable CDDB for Audio CD (default enabled)])])
1810
1811 if test "${enable_vcd}" != "no"
1812 then
1813   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1814   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1815     AC_MSG_RESULT(yes)
1816     VLC_ADD_PLUGIN([vcd cdda])
1817   ],[
1818     AC_MSG_RESULT(no)
1819   ])
1820
1821   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1822   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1823     AC_MSG_RESULT(yes)
1824     VLC_ADD_PLUGIN([vcd cdda])
1825     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1826   ],[
1827     AC_MSG_RESULT(no)
1828   ])
1829
1830   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1831   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1832     AC_MSG_RESULT(yes)
1833     VLC_ADD_PLUGIN([vcd cdda])
1834     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1835   ],[
1836     AC_MSG_RESULT(no)
1837   ])
1838
1839   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1840   then
1841     VLC_ADD_PLUGIN([vcd cdda])
1842   fi
1843
1844   if test "$enable_libcddb" != "no"; then
1845     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1846       HAVE_LIBCDDB=yes
1847       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1848       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1849       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1850       ],:
1851       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1852       HAVE_LIBCDDB=no])
1853   fi
1854 fi
1855
1856 dnl
1857 dnl Linux DVB
1858 dnl
1859 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1860   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1861 [#include <linux/dvb/version.h>
1862 #if (DVB_API_VERSION < 5)
1863 # error Linux DVB API v3.2 and older are not supported.
1864 #endif
1865 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1866 # error Linux DVB API v5.0 is unsupported. Please update.
1867 #endif
1868 ]])], [
1869   ac_cv_linux_dvb_5_1=yes
1870 ], [
1871   ac_cv_linux_dvb_5_1=no
1872 ])])
1873 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1874
1875 dnl
1876 dnl  Screen capture module
1877 dnl
1878 AC_ARG_ENABLE(screen,
1879   [AS_HELP_STRING([--enable-screen],
1880     [disable screen capture (default enabled)])])
1881 if test "${enable_screen}" != "no"; then
1882   if test "${SYS}" = "darwin"; then
1883     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1884       VLC_ADD_PLUGIN([screen])
1885     ])
1886   fi
1887 fi
1888 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1889
1890 dnl
1891 dnl  VNC/RFB access module
1892 dnl
1893 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1894
1895 dnl  RDP/Remote Desktop access module
1896 dnl
1897 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1898
1899 dnl
1900 dnl  Real RTSP plugin
1901 dnl
1902 AC_ARG_ENABLE(realrtsp,
1903   [  --enable-realrtsp       Real RTSP module (default disabled)])
1904 if test "${enable_realrtsp}" = "yes"; then
1905   VLC_ADD_PLUGIN([access_realrtsp])
1906 fi
1907
1908 dnl
1909 dnl MacOS eyeTV
1910 AC_ARG_ENABLE(macosx-eyetv,
1911   [  --enable-macosx-eyetv   Mac OS X EyeTV (TNT Tuner) module (default enabled on Mac OS X)])
1912 if test "x${enable_macosx_eyetv}" != "xno" &&
1913   (test "${SYS}" = "darwin" || test "${enable_macosx_eyetv}" = "yes")
1914 then
1915   VLC_ADD_PLUGIN([access_eyetv])
1916 fi
1917
1918 dnl
1919 dnl QTKit
1920 AC_ARG_ENABLE(macosx-qtkit,
1921   [  --enable-macosx-qtkit Mac OS X qtcapture (video) and qtsound (audio) module (default enabled on Mac OS X)])
1922 if test "x${enable_macosx_qtkit}" != "xno" &&
1923   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1924 then
1925   VLC_ADD_PLUGIN([qtcapture])
1926   VLC_ADD_PLUGIN([qtsound])
1927 fi
1928 AM_CONDITIONAL(HAVE_QTKIT, [test "${SYS}" = "darwin" -a "x${enable_macosx_qtkit}" != "xno"])
1929
1930 dnl
1931 dnl AVFoundation
1932 AC_SUBST(have_avfoundation, ["no"])
1933 AC_ARG_ENABLE(macosx-avfoundation,
1934   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
1935 if test "x${enable_macosx_avfoundation}" != "xno" &&
1936   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
1937 then
1938   SAVED_LIBS="${LIBS}"
1939   LIBS="-framework AVFoundation"
1940   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
1941   LIBS="${SAVED_LIBS}"
1942   if test "${have_avfoundation}" != "no"
1943   then
1944     VLC_ADD_PLUGIN([avcapture])
1945   fi
1946 fi
1947 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
1948
1949 dnl
1950 dnl  DCP plugin (using asdcplib)
1951 dnl
1952 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
1953 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
1954
1955 dnl
1956 dnl  Demux plugins
1957 dnl
1958
1959 EXTEND_HELP_STRING([Mux/Demux plugins:])
1960
1961 dnl
1962 dnl  libdvbpsi check for ts mux/demux
1963 dnl
1964 have_dvbpsi="no"
1965 PKG_WITH_MODULES([DVBPSI], [libdvbpsi], [have_dvbpsi="yes"])
1966 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
1967
1968
1969 dnl
1970 dnl  GME demux plugin
1971 dnl
1972 AC_ARG_ENABLE(gme,
1973   [AS_HELP_STRING([--enable-gme],
1974     [use Game Music Emu (default auto)])])
1975 AS_IF([test "${enable_gme}" != "no"], [
1976   AC_CHECK_HEADER([gme/gme.h], [
1977     VLC_ADD_LIBS([gme], [-lgme])
1978     VLC_ADD_PLUGIN([gme])
1979   ], [
1980     AS_IF([test "x${enable_gme}" != "x"], [
1981       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
1982     ])
1983   ])
1984 ])
1985
1986
1987 dnl
1988 dnl  SIDPlay plugin
1989 dnl
1990 AC_ARG_ENABLE(sid,
1991     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
1992 AS_IF([test "${enable_sid}" != "no"], [
1993     PKG_CHECK_MODULES(SID, [libsidplay2], [
1994         AC_LANG_PUSH(C++)
1995         oldCPPFLAGS="$CPPFLAGS"
1996         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
1997         AC_CHECK_HEADER([sidplay/builders/resid.h], [
1998             VLC_ADD_PLUGIN([sid])
1999             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2000             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2001         ], [
2002             AS_IF([test -n "${enable_sid}"],
2003                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2004                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2005                 )
2006         ])
2007         CPPFLAGS="$oldCPPFLAGS"
2008         AC_LANG_POP(C++)
2009     ], [
2010         AS_IF([test "x${enable_sid}" = "xyes"],
2011             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2012             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2013             )
2014     ])
2015 ])
2016
2017
2018 dnl
2019 dnl  ogg demux plugin
2020 dnl
2021 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto])
2022 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2023     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2024 ],[true])
2025 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2026 if test "${enable_sout}" != "no"; then
2027     PKG_ENABLE_MODULES_VLC([MUX_OGG], [], [ogg >= 1.0], [Ogg mux support], [auto])
2028 dnl Check for libshout
2029     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2030 fi
2031
2032 dnl
2033 dnl  matroska demux plugin
2034 dnl
2035 AC_ARG_ENABLE(mkv,
2036   [AS_HELP_STRING([--disable-mkv],
2037     [do not use libmatroska (default auto)])])
2038 if test "${enable_mkv}" != "no" -a "${CXX}" != ""; then
2039   AC_LANG_PUSH(C++)
2040   AC_CHECK_HEADERS(ebml/EbmlVersion.h, [
2041     AC_MSG_CHECKING(for libebml version >= 1.0.0)
2042     AC_EGREP_CPP(yes,
2043       [#include <ebml/EbmlVersion.h>
2044        #ifdef LIBEBML_VERSION
2045        #if LIBEBML_VERSION >= 0x010000
2046        yes
2047        #endif
2048        #endif],
2049       [AC_MSG_RESULT([yes])
2050         AC_CHECK_HEADERS(matroska/KaxVersion.h, [
2051           AC_MSG_CHECKING(for libmatroska version >= 1.0.0)
2052           AC_EGREP_CPP(yes,
2053             [#include <matroska/KaxVersion.h>
2054              #ifdef LIBMATROSKA_VERSION
2055              #if LIBMATROSKA_VERSION >= 0x010000
2056              yes
2057              #endif
2058              #endif],
2059             [AC_MSG_RESULT([yes])
2060               AC_CHECK_HEADERS(matroska/KaxAttachments.h)
2061               AC_CHECK_LIB(ebml_pic, main, [
2062                 VLC_ADD_PLUGIN([mkv])
2063                 VLC_ADD_LIBS([mkv],[-lmatroska -lebml_pic])
2064               ],[
2065                 AC_CHECK_LIB(ebml, main, [
2066                   VLC_ADD_PLUGIN([mkv])
2067                   VLC_ADD_LIBS([mkv],[-lmatroska -lebml])
2068                 ])
2069               ])
2070             ], [
2071               AC_MSG_RESULT([no])
2072               AC_MSG_ERROR([Your libmatroska is too old: you may get a more recent one from http://dl.matroska.org/downloads/libmatroska/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2073           ])
2074         ])
2075       ],
2076       [AC_MSG_RESULT([no])
2077         AC_MSG_ERROR([Your libebml is too old: you may get a more recent one from http://dl.matroska.org/downloads/libebml/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2078     ])
2079   ])
2080   AC_LANG_POP(C++)
2081 fi
2082
2083 dnl
2084 dnl  modplug demux plugin
2085 dnl
2086 AC_ARG_ENABLE(mod,
2087   [AS_HELP_STRING([--disable-mod],
2088     [do not use libmodplug (default auto)])])
2089 if test "${enable_mod}" != "no" ; then
2090     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2091           VLC_ADD_PLUGIN([mod])
2092           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2093           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2094           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2095     ],[
2096        AS_IF([test -n "${enable_mod}"],
2097          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2098          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2099     ])
2100 fi
2101
2102 dnl
2103 dnl  mpc demux plugin
2104 dnl
2105 AC_ARG_ENABLE(mpc,
2106   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2107 if test "${enable_mpc}" != "no"
2108 then
2109   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2110     VLC_ADD_PLUGIN([mpc])
2111     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2112     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2113     VLC_ADD_PLUGIN([mpc])
2114     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2115 fi
2116
2117 dnl
2118 dnl  Codec plugins
2119 dnl
2120
2121 EXTEND_HELP_STRING([Codec plugins:])
2122
2123 dnl
2124 dnl wmafixed plugin
2125 dnl
2126 AC_ARG_ENABLE(wma-fixed,
2127   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2128 if test "${enable_wma_fixed}" = "yes"
2129 then
2130   VLC_ADD_PLUGIN([wma_fixed])
2131 fi
2132
2133 dnl
2134 dnl shine encoder plugin
2135 dnl
2136 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2137
2138
2139 dnl
2140 dnl openmax il codec plugin
2141 dnl
2142 AC_ARG_ENABLE(omxil,
2143   [  --enable-omxil          openmax il codec module (default disabled)])
2144 if test "${enable_omxil}" = "yes"
2145 then
2146   VLC_ADD_PLUGIN([omxil])
2147 fi
2148
2149 dnl
2150 dnl openmax il vout plugin
2151 dnl
2152 AC_ARG_ENABLE(omxil-vout,
2153   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2154 if test "${enable_omxil_vout}" = "yes"
2155 then
2156   VLC_ADD_PLUGIN([omxil_vout])
2157 fi
2158
2159 dnl
2160 dnl raspberry pi openmax il configuration
2161 dnl
2162 AC_ARG_ENABLE(rpi-omxil,
2163   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2164 if test "${enable_rpi_omxil}" = "yes"
2165 then
2166   VLC_ADD_PLUGIN([omxil omxil_vout])
2167   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2168 fi
2169
2170 dnl
2171 dnl CrystalHD codec plugin
2172 dnl
2173 AC_ARG_ENABLE(crystalhd,
2174   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2175 if test "${enable_crystalhd}" != "no"; then
2176     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2177       VLC_ADD_PLUGIN([crystalhd])
2178       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2179     ],[
2180       if test "${SYS}" = "mingw32" ; then
2181         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2182           VLC_ADD_PLUGIN([crystalhd])
2183           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2184             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2185             ])
2186         ],[
2187           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2188                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2189                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2190         ],[#define __LINUX_USER__
2191                #include <libcrystalhd/bc_dts_types.h>
2192         ])
2193       fi
2194     ],[
2195        #include <libcrystalhd/bc_dts_types.h>
2196       ])
2197 fi
2198
2199 dnl
2200 dnl  mad plugin
2201 dnl
2202 AC_ARG_ENABLE(mad,
2203   [  --enable-mad            libmad module (default enabled)])
2204 if test "${enable_mad}" != "no"
2205 then
2206   AC_ARG_WITH(mad,
2207     [  --with-mad=PATH         path to libmad],[],[])
2208   if test "${with_mad}" != "no" -a -n "${with_mad}"
2209   then
2210     VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${with_mad}/include])
2211     VLC_ADD_LIBS([mpgatofixed32],[-L${with_mad}/lib])
2212   fi
2213
2214   AC_ARG_WITH(mad-tree,
2215     [  --with-mad-tree=PATH    mad tree for static linking],[],[])
2216   if test "${with_mad_tree}" != "no" -a -n "${with_mad_tree}"
2217   then
2218     real_mad_tree="`cd ${with_mad_tree} 2>/dev/null && pwd`"
2219     if test -z "${real_mad_tree}"
2220     then
2221       dnl  The given directory can't be found
2222       AC_MSG_RESULT(no)
2223       AC_MSG_ERROR([${with_mad_tree} directory does not exist])
2224     fi
2225     dnl  Use a custom libmad
2226     AC_MSG_CHECKING(for mad.h in ${real_mad_tree})
2227     if test -f ${real_mad_tree}/mad.h
2228     then
2229       AC_MSG_RESULT(yes)
2230       VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${real_mad_tree}])
2231       VLC_ADD_LIBS([mpgatofixed32],[-L${real_mad_tree}/.libs])
2232       VLC_SAVE_FLAGS
2233       LDFLAGS="${LDFLAGS} ${LIBS_mpgatofixed32}"
2234       AC_CHECK_LIB(mad, mad_bit_init, [
2235         VLC_ADD_PLUGIN([mpgatofixed32])
2236         VLC_ADD_LIBS([mpgatofixed32],[-lmad])
2237         ],[ AC_MSG_ERROR([the specified tree has not been compiled ])
2238       ],[])
2239       VLC_RESTORE_FLAGS
2240     else
2241       AC_MSG_RESULT(no)
2242       AC_MSG_ERROR([the specified tree does not have mad.h])
2243     fi
2244   else
2245     VLC_SAVE_FLAGS
2246     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_mpgatofixed32}"
2247     LDFLAGS="${LDFLAGS} ${LIBS_mpgatofixed32}"
2248     AC_CHECK_HEADERS(mad.h, ,
2249       [ AC_MSG_ERROR([Could not find libmad on your system: you may get it from http://www.underbit.com/products/mad/. Alternatively you can use --disable-mad to disable the mad plugin.]) ])
2250     AC_CHECK_LIB(mad, mad_bit_init, [
2251       VLC_ADD_PLUGIN([mpgatofixed32])
2252       VLC_ADD_LIBS([mpgatofixed32],[-lmad])],
2253       [ AC_MSG_ERROR([Cannot find libmad library...]) ])
2254     VLC_RESTORE_FLAGS
2255   fi
2256 fi
2257
2258
2259 AC_ARG_ENABLE(merge-ffmpeg,
2260 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2261   enable_merge_ffmpeg="no"
2262 ])
2263 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2264
2265 AC_MSG_CHECKING([for libavutil variant])
2266 PKG_CHECK_EXISTS([libavutil], [
2267   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2268   libavutil_micro="${libavutil_version##*.}"
2269   AS_IF([test ${libavutil_micro} -le 99], [
2270     avfork="libav"
2271   ], [
2272     avfork="ffmpeg"
2273   ])
2274 ], [
2275   avfork="none"
2276 ])
2277 AC_MSG_RESULT([${avfork}])
2278
2279 dnl
2280 dnl gstreamer stuff
2281 dnl
2282 AC_ARG_ENABLE(gst-decode,
2283   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2284
2285 have_gst_decode="no"
2286 AS_IF([test "${enable_gst_decode}" != "no"], [
2287   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2288     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2289       have_gst_decode="yes"
2290     ], [
2291       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2292     ])
2293   ], [
2294     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2295   ])
2296 ])
2297 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2298
2299 dnl
2300 dnl  avcodec decoder/encoder plugin
2301 dnl
2302 AC_ARG_ENABLE(avcodec,
2303 [  --enable-avcodec        libavcodec codec (default enabled)])
2304 AS_IF([test "${enable_avcodec}" != "no"], [
2305   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= 54.25.0 libavutil >= 52.0.0], [
2306     dnl PKG_CHECK_EXISTS([libavcodec < 56],, [
2307     dnl   AC_MSG_ERROR([libavcodec versions 56 and later are not supported yet.])
2308     dnl ])
2309     VLC_SAVE_FLAGS
2310     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2311     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2312     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2313     AC_CHECK_HEADERS(libavutil/avutil.h)
2314     VLC_RESTORE_FLAGS
2315     have_avcodec="yes"
2316   ],[
2317     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2318   ])
2319 ], [
2320   have_avcodec="no"
2321 ])
2322 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2323
2324 dnl
2325 dnl libva needs avcodec
2326 dnl
2327 AC_ARG_ENABLE(libva,
2328   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2329
2330 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2331   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2332 ])
2333
2334 have_vaapi="no"
2335 have_vaapi_drm="no"
2336 have_vaapi_x11="no"
2337 AS_IF([test "${enable_libva}" != "no"], [
2338   PKG_CHECK_EXISTS([libva], [
2339     have_vaapi="yes"
2340   ], [
2341     AS_IF([test -n "${enable_libva}"], [
2342       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2343     ], [
2344       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2345     ])
2346   ])
2347   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2348     have_vaapi_drm="yes"
2349   ], [
2350     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2351   ])
2352   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2353     have_vaapi_x11="yes"
2354   ], [
2355     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2356   ])
2357 ])
2358 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2359 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2360
2361 have_avcodec_vaapi="no"
2362 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2363   VLC_SAVE_FLAGS
2364   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2365   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2366   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2367     AC_MSG_NOTICE([VAAPI acceleration activated])
2368     have_avcodec_vaapi="yes"
2369   ],[
2370     AS_IF([test -n "${enable_libva}"], [
2371       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2372     ], [
2373       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2374     ])
2375   ])
2376   VLC_RESTORE_FLAGS
2377 ])
2378 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2379
2380 dnl
2381 dnl dxva2 needs avcodec
2382 dnl
2383 AC_ARG_ENABLE(dxva2,
2384   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2385
2386 have_avcodec_dxva2="no"
2387 AS_IF([test "${enable_dxva2}" != "no"], [
2388   if test "${SYS}" = "mingw32"; then
2389   AS_IF([test "x${have_avcodec}" = "xyes"], [
2390     AC_CHECK_HEADERS(dxva2api.h,
2391       [
2392         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2393            AC_MSG_NOTICE([DxVA2 acceleration activated])
2394            have_avcodec_dxva2="yes"
2395         ],[
2396     AS_IF([test "${enable_dxva2}" = "yes"],
2397           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2398               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2399         ], [#undef _WIN32_WINNT
2400             /* DXVA2 is only available in Vista and above */
2401             #define _WIN32_WINNT 0x600])
2402       ],[
2403     AS_IF([test "${enable_dxva2}" = "yes"],
2404               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2405               [AC_MSG_WARN([dxva2api.h not found])])
2406       ])
2407   ],[
2408     AS_IF([test "x${enable_dxva2}" != "x"], [
2409       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2410     ])
2411   ])
2412   fi
2413 ])
2414 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2415
2416 dnl
2417 dnl vda needs avcodec
2418 dnl
2419 AC_ARG_ENABLE(vda,
2420   [  --enable-vda          VDA  support (default auto)])
2421
2422 have_avcodec_vda="no"
2423 AS_IF([test "${enable_vda}" != "no"], [
2424   if test "${SYS}" = "darwin"; then
2425   AS_IF([test "x${have_avcodec}" = "xyes"], [
2426     AC_CHECK_HEADERS(VideoDecodeAcceleration/VDADecoder.h,
2427       [
2428         AC_CHECK_HEADERS(libavcodec/vda.h, [
2429            have_avcodec_vda="yes"
2430         ],[
2431         AS_IF([test "${enable_vda}" = "yes"],
2432               [AC_MSG_ERROR([vda is present but libavcodec/vda.h is missing])],
2433               [AC_MSG_WARN([vda is present but libavcodec/vda.h is missing ])])
2434         ])
2435   ],[
2436         AS_IF([test "${enable_vda}" = "yes"],
2437               [AC_MSG_ERROR([Could not find required VideoDecodeAcceleration/VDADecoder.h])],
2438               [AC_MSG_WARN([VideoDecodeAcceleration/VDADecoder.h not found])])
2439       ])
2440   ],[
2441     AS_IF([test "x${enable_vda}" != "x"], [
2442       AC_MSG_ERROR([--enable-vda and --disable-avcodec options are mutually exclusive.])
2443     ])
2444  ])
2445  AS_IF([test "${have_avcodec_vda}" = "yes"], [
2446      SAVE_LIBS=$LIBS
2447      LIBS="$LIBS $AVCODEC_LIBS"
2448      AC_CHECK_FUNCS([av_vda_alloc_context])
2449      LIBS=$SAVE_LIBS
2450  ])
2451  fi
2452 ])
2453 AM_CONDITIONAL([HAVE_AVCODEC_VDA], [test "${have_avcodec_vda}" = "yes"])
2454
2455 dnl
2456 dnl  avformat demuxer/muxer plugin
2457 dnl
2458
2459 AC_ARG_ENABLE(avformat,
2460 [  --enable-avformat       libavformat containers (default enabled)],, [
2461   enable_avformat="${have_avcodec}"
2462 ])
2463 have_avformat="no"
2464 AS_IF([test "${enable_avformat}" != "no"], [
2465   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2466       have_avformat="yes"
2467       VLC_SAVE_FLAGS
2468       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2469       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2470       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2471       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2472       AC_CHECK_HEADERS(libavutil/avutil.h)
2473       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2474         have_avformat="no"
2475       ])
2476       VLC_RESTORE_FLAGS
2477     ],[
2478       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2479   ])
2480 ])
2481 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2482
2483 dnl
2484 dnl  swscale image scaling and conversion plugin
2485 dnl
2486
2487 AC_ARG_ENABLE(swscale,
2488   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2489           (default enabled)]))
2490 if test "${enable_swscale}" != "no"
2491 then
2492   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2493     [
2494       VLC_SAVE_FLAGS
2495       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2496       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2497       AC_CHECK_HEADERS(libswscale/swscale.h)
2498       AC_CHECK_HEADERS(libavutil/avutil.h)
2499       VLC_ADD_PLUGIN([swscale])
2500       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2501       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2502       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2503         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2504       ])
2505       VLC_RESTORE_FLAGS
2506     ],[
2507       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2508   ])
2509 fi
2510
2511 dnl
2512 dnl  postproc plugin
2513 dnl
2514
2515 AC_ARG_ENABLE(postproc,
2516 [  --enable-postproc       libpostproc image post-processing (default auto)])
2517 if test "${enable_postproc}" != "no"
2518 then
2519   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2520     [
2521       VLC_SAVE_FLAGS
2522       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2523       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2524       AC_CHECK_HEADERS(postproc/postprocess.h)
2525       VLC_ADD_PLUGIN([postproc])
2526       VLC_ADD_LIBS([postproc],[$POSTPROC_LIBS $AVUTIL_LIBS])
2527       VLC_ADD_CFLAGS([postproc],[$POSTPROC_CFLAGS $AVUTIL_CFLAGS])
2528       VLC_RESTORE_FLAGS
2529     ],[
2530       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2531   ])
2532 fi
2533
2534 dnl
2535 dnl  faad decoder plugin
2536 dnl
2537 AC_ARG_ENABLE(faad,
2538 [  --enable-faad           faad codec (default auto)])
2539 if test "${enable_faad}" != "no"; then
2540   AC_ARG_WITH(faad-tree,  [  --with-faad-tree=PATH   faad tree for static linking])
2541   if test -n "${with_faad_tree}"; then
2542     AC_MSG_CHECKING(for libfaad.a in ${with_faad_tree})
2543     real_faad_tree="`cd ${with_faad_tree} 2>/dev/null && pwd`"
2544     if test -z "${real_faad_tree}"; then
2545       dnl  The given directory can't be found
2546       AC_MSG_RESULT(no)
2547       AC_MSG_ERROR([cannot cd to ${with_faad_tree}])
2548     fi
2549     if test -f "${real_faad_tree}/libfaad/.libs/libfaad.a"; then
2550       dnl  Use the custom faad
2551       AC_MSG_RESULT(${real_faad_tree}/libfaad/.libs/libfaad.a)
2552       VLC_ADD_PLUGIN([faad])
2553       VLC_ADD_LIBS([faad],[${real_faad_tree}/libfaad/.libs/libfaad.a])
2554       VLC_ADD_CPPFLAGS([faad],[-I${real_faad_tree}/include])
2555     else
2556       dnl  The given libfaad wasn't built
2557       AC_MSG_RESULT(no)
2558       AC_MSG_ERROR([cannot find ${real_faad_tree}/libfaad/.libs/libfaad.a, make sure you compiled libfaad in ${with_faad_tree}])
2559     fi
2560   else
2561     VLC_SAVE_FLAGS
2562     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_faad}"
2563     LDFLAGS="${LDFLAGS} ${LIBS_faad}"
2564     AC_CHECK_HEADERS(faad.h,
2565       [ AC_CHECK_LIB(faad, faacDecOpen, [
2566           VLC_ADD_PLUGIN([faad])
2567           VLC_ADD_LIBS([faad],[-lfaad]) ], [
2568             AC_CHECK_LIB(faad, NeAACDecOpen, [
2569               VLC_ADD_PLUGIN([faad])
2570               VLC_ADD_LIBS([faad],[-lfaad]) ], [
2571                 AS_IF([test "${enable_faad}" = "yes"],
2572                 [ AC_MSG_ERROR([Cannot find libfaad library...]) ],
2573                 [ AC_MSG_WARN([Cannot find libfaad library...]) ]) ]) ])
2574       ] , [ AS_IF([test "${enable_faad}" = "yes"],
2575         [ AC_MSG_ERROR([Cannot find development headers for libfaad...]) ],
2576         [ AC_MSG_WARN([Cannot find development headers for libfaad...]) ]) ])
2577     VLC_RESTORE_FLAGS
2578   fi
2579 fi
2580
2581 dnl
2582 dnl libvpx decoder plugin
2583 dnl
2584 AC_ARG_ENABLE(vpx,
2585     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 decoder (default auto)]))
2586 AS_IF([test "${enable_vpx}" != "no"],[
2587     PKG_CHECK_MODULES([VPX], [vpx] , [
2588         VLC_ADD_PLUGIN([vpx])
2589         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2590         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2591         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2592             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2593         ], [], [${VPX_LIBS}])
2594         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2595             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2596         ], [], [${VPX_LIBS}])
2597     ], [
2598     AS_IF([test "${enable_vpx}" = "yes"],[
2599         AC_MSG_ERROR([libvpx was not found])
2600     ])])
2601 ])
2602
2603 dnl
2604 dnl twolame encoder plugin
2605 dnl
2606 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2607
2608 dnl
2609 dnl fdk-aac encoder plugin
2610 dnl
2611 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2612
2613 dnl
2614 dnl  QuickTime plugin
2615 dnl
2616 AC_ARG_ENABLE(quicktime,
2617   [  --enable-quicktime      QuickTime module (deprecated)])
2618 if test "${enable_quicktime}" = "yes"; then
2619   if test "${SYS}" = "mingw32"; then
2620     VLC_ADD_PLUGIN([quicktime])
2621   else
2622   AC_CHECK_HEADERS(QuickTime/QuickTime.h,
2623     [ VLC_ADD_PLUGIN([quicktime])
2624       VLC_ADD_LIBS([quicktime],[-Wl,-framework,QuickTime,-framework,Carbon])
2625     ], [ AC_MSG_ERROR([cannot find QuickTime headers]) ])
2626   fi
2627 fi
2628
2629 dnl
2630 dnl A52/AC3 decoder plugin
2631 dnl
2632 AC_ARG_ENABLE(a52,
2633   [  --enable-a52            A/52 support with liba52 (default enabled)])
2634 if test "${enable_a52}" != "no"
2635 then
2636   AC_ARG_WITH(a52,
2637     [  --with-a52=PATH         a52 headers and libraries])
2638   AC_ARG_WITH(a52-tree,
2639     [  --with-a52-tree=PATH    a52dec tree for static linking ],[],[])
2640   if test "${with_a52_tree}" != "no" -a -n "${with_a52_tree}"
2641   then
2642     real_a52_tree="`cd ${with_a52_tree} 2>/dev/null && pwd`"
2643     if test -z "${real_a52_tree}"
2644     then
2645       dnl  The given directory can't be found
2646       AC_MSG_RESULT(no)
2647       AC_MSG_ERROR([${with_a52_tree} directory does not exist])
2648     fi
2649     dnl  Use a custom a52dec
2650     AC_MSG_CHECKING(for a52.h in ${real_a52_tree}/include)
2651     if test -f ${real_a52_tree}/include/a52.h
2652     then
2653       AC_MSG_RESULT(yes)
2654       VLC_ADD_CPPFLAGS([a52tofloat32],[-I${real_a52_tree}])
2655       VLC_ADD_LIBS([a52tofloat32],[-L${real_a52_tree}/liba52/.libs])
2656       VLC_SAVE_FLAGS
2657       LDFLAGS="${LDFLAGS} ${LIBS_a52tofloat32}"
2658       AC_CHECK_LIB(a52, a52_free, [
2659         VLC_ADD_PLUGIN([a52tofloat32])
2660         VLC_ADD_CPPFLAGS([a52tofloat32],[-DUSE_A52DEC_TREE])
2661         VLC_ADD_LIBS([a52tofloat32],[-la52])
2662         ],[
2663         if test -f ${real_a52_tree}/liba52/.libs/liba52.a
2664         then
2665           AC_MSG_ERROR([make sure you have at least a52dec-0.7.3 ($real_a52_tree)])
2666         else
2667           AC_MSG_ERROR([the specified tree has not been compiled])
2668         fi
2669       ])
2670     else
2671       AC_MSG_RESULT(no)
2672       AC_MSG_ERROR([the specified tree does not have a52.h])
2673     fi
2674   else
2675     if test -z "${with_a52}"
2676     then
2677       LDFLAGS_test=""
2678       CPPFLAGS_test=""
2679     else
2680       LDFLAGS_test="-L${with_a52}/lib"
2681       CPPFLAGS_test="-I${with_a52}/include"
2682     fi
2683     VLC_SAVE_FLAGS
2684     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52tofloat32}"
2685     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52tofloat32}"
2686     AC_CHECK_HEADERS(a52dec/a52.h, [
2687       AC_CHECK_LIB(a52, a52_free, [
2688         VLC_ADD_PLUGIN([a52tofloat32])
2689         VLC_ADD_LIBS([a52tofloat32],[${LDFLAGS_test} -la52])
2690         VLC_ADD_CPPFLAGS([a52tofloat32],[${CPPFLAGS_test}])
2691       ],[
2692         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2693         ], [$LIBM])
2694     ],[
2695       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2696     ])
2697     VLC_RESTORE_FLAGS
2698   fi
2699 fi
2700
2701 dnl
2702 dnl DTS Coherent Acoustics decoder plugin
2703 dnl
2704 PKG_ENABLE_MODULES_VLC([DCA], [dtstofloat32], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2705
2706 dnl
2707 dnl  Flac plugin
2708 dnl
2709 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2710
2711 dnl
2712 dnl  Libmpeg2 plugin
2713 dnl
2714 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2715
2716 dnl
2717 dnl  Vorbis plugin
2718 dnl
2719 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2720
2721 dnl
2722 dnl  Tremor plugin
2723 dnl
2724 AC_ARG_ENABLE(tremor,
2725   [  --enable-tremor         Tremor decoder support (default disabled)])
2726 if test "${enable_tremor}" = "yes"
2727 then
2728   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2729     VLC_ADD_PLUGIN([tremor])
2730    ],[])
2731 fi
2732
2733 dnl
2734 dnl  Speex plugins
2735 dnl
2736 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2737 have_speexdsp="no"
2738 AS_IF([test "${enable_speex}" != "no"], [
2739   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2740     have_speexdsp="yes"
2741   ], [
2742     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2743   ])
2744 ])
2745 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2746
2747 dnl
2748 dnl  Opus plugin
2749 dnl
2750 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2751
2752 dnl
2753 dnl  theora decoder plugin
2754 dnl
2755 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2756
2757 dnl
2758 dnl  Daala decoder plugin
2759 dnl
2760 PKG_ENABLE_MODULES_VLC([DAALA], [], [ogg daaladec daalaenc], [experimental daala codec], [disabled])
2761
2762 dnl
2763 dnl  schroedinger decoder plugin (for dirac format video)
2764 dnl
2765 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2766
2767 dnl
2768 dnl  PNG decoder module
2769 dnl
2770 AC_ARG_ENABLE(png,
2771   [  --enable-png            PNG support (default enabled)])
2772 AS_IF([test "${enable_png}" != "no"], [
2773 AC_CHECK_HEADERS(png.h, [
2774   VLC_SAVE_FLAGS
2775   LDFLAGS="${LDFLAGS} -lz $LIBM"
2776   AC_CHECK_LIB(png, png_set_rows, [
2777     VLC_ADD_PLUGIN([png])
2778   ], [], [-lz $LIBM])
2779   VLC_RESTORE_FLAGS
2780   ])
2781 ])
2782
2783 dnl
2784 dnl  JPEG decoder module
2785 dnl
2786 AC_ARG_ENABLE(jpeg,
2787   [  --enable-jpeg           JPEG support (default enabled)])
2788 AS_IF([test "${enable_jpeg}" != "no"], [
2789 AC_CHECK_HEADERS(jpeglib.h, [
2790   VLC_ADD_PLUGIN([jpeg])
2791   ])
2792 ])
2793
2794 dnl
2795 dnl H262 encoder plugin (lib262)
2796 dnl
2797 AC_ARG_ENABLE(x262,
2798   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2799 if test "${enable_x262}" != "no"; then
2800 AC_ARG_WITH(x262-tree,
2801   [ --with-x262-tree=PATH      H262 encoding module with libx262 (static linking)],[],[])
2802   if test "${with_x262_tree}" != "no" -a -n "${with_x262_tree}"
2803   then
2804     real_x262_tree="̧`cd ${with_x262_tree} 2>/dev/null && pwd`"
2805     if test -z "${real_x262_tree}"
2806     then
2807       AC_MSG_RESULT(no)
2808       AC_MSG_ERROR([${with_x262_tree} directory does not exist])
2809     fi
2810     AC_MSG_CHECKING(for x262.h in ${real_x262_tree})
2811     if test -f ${with_x262_tree}/x262_config.h
2812     then
2813       VLC_ADD_PLUGIN([x262])
2814       VLC_ADD_CFLAGS([x262],[-I${with_x262_tree}])
2815       VLC_ADD_LIBS([x262],[-L${with_x262_tree} -lm -lpthread -lx262])
2816     else
2817       AC_MSG_RESULT(no)
2818       AC_MSG_ERROR([${with_x262_tree} doesnt have x262_config.h])
2819     fi
2820   else
2821     PKG_CHECK_MODULES(X262, x262, [
2822         VLC_ADD_PLUGIN([x262])
2823         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2824         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2825           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2826         ])
2827         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2828         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2829           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2830         fi
2831     ], [
2832        if test "${enable_x262}" = "yes"; then
2833         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2834        fi
2835     ])
2836   fi
2837 fi
2838
2839 dnl x265 encoder
2840 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2841
2842 dnl
2843 dnl H264 encoder plugin (10-bit lib264)
2844 dnl
2845 AC_ARG_ENABLE(x26410b,
2846   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2847 if test "${enable_x26410b}" != "no"; then
2848 AC_ARG_WITH(x26410b-tree,
2849   [ --with-x26410b-tree=PATH      H264 10-bit encoding module with libx264 (static linking)],[],[])
2850   if test "${with_x26410b_tree}" != "no" -a -n "${with_x26410b_tree}"
2851   then
2852     real_x26410b_tree="̧`cd ${with_x26410b_tree} 2>/dev/null && pwd`"
2853     if test -z "${real_x26410b_tree}"
2854     then
2855       AC_MSG_RESULT(no)
2856       AC_MSG_ERROR([${with_x26410b_tree} directory does not exist])
2857     fi
2858     AC_MSG_CHECKING(for x264.h in ${real_x26410b_tree})
2859     if test -f ${with_x26410b_tree}/x264_config.h
2860     then
2861       AC_MSG_RESULT(yes)
2862       AC_MSG_CHECKING(for 10-bit build of x264)
2863       if grep -q "BIT_DEPTH.*10"  ${with_x26410b_tree}/x264_config.h ;then
2864         AC_MSG_RESULT(yes)
2865         VLC_ADD_PLUGIN([x26410b])
2866         VLC_ADD_CFLAGS([x26410b],[-I${with_x26410b_tree}])
2867         VLC_ADD_LIBS([x26410b],[-L${with_x26410b_tree} -lm -lpthread -lx264])
2868       else
2869         AC_MSG_RESULT(no)
2870         AC_MSG_ERROR([${with_x26410b_tree} isnt build 10-bit])
2871       fi
2872     else
2873       AC_MSG_RESULT(no)
2874       AC_MSG_ERROR([${with_x26410b_tree} doesnt have x264_config.h])
2875     fi
2876   else
2877     PKG_CHECK_MODULES(X26410B, x26410b, [
2878         VLC_ADD_PLUGIN([x26410b])
2879         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2880         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2881           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2882         ])
2883         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2884         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2885           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2886         fi
2887     ], [
2888        if test "${enable_x26410b}" = "yes"; then
2889         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2890        fi
2891     ])
2892   fi
2893 fi
2894
2895
2896 dnl
2897 dnl H264 encoder plugin (using libx264)
2898 dnl
2899 AC_ARG_ENABLE(x264,
2900   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2901 if test "${enable_x264}" != "no"; then
2902   AC_ARG_WITH(x264-tree,
2903     [  --with-x264-tree=PATH   x264 tree for static linking ],[],[])
2904   if test "${with_x264_tree}" != "no" -a -n "${with_x264_tree}"
2905   then
2906     real_x264_tree="`cd ${with_x264_tree} 2>/dev/null && pwd`"
2907     if test -z "${real_x264_tree}"
2908     then
2909       dnl  The given directory can't be found
2910       AC_MSG_RESULT(no)
2911       AC_MSG_ERROR([${with_x264_tree} directory does not exist])
2912     fi
2913     dnl  Use a custom libx264
2914     AC_MSG_CHECKING(for x264.h in ${real_x264_tree})
2915     if test -f ${real_x264_tree}/x264.h
2916     then
2917       AC_MSG_RESULT(yes)
2918       VLC_ADD_CPPFLAGS([x264],[-I${real_x264_tree}])
2919       VLC_ADD_LIBS([x264],[-L${real_x264_tree}])
2920       PKG_CHECK_MODULES(X264,x264, [
2921         VLC_ADD_PLUGIN([x264])
2922         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2923         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2924         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2925           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2926         fi
2927       ],[
2928         AC_MSG_ERROR([the specified tree has not been compiled])
2929       ])
2930     else
2931       AC_MSG_RESULT(no)
2932       AC_MSG_ERROR([the specified tree does not have x264.h])
2933     fi
2934   else
2935       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2936         VLC_ADD_PLUGIN([x264])
2937         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2938
2939         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2940           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2941         ])
2942
2943         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2944         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2945           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2946         fi
2947       ],[
2948         if test "${enable_x264}" = "yes"; then
2949             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2950           fi
2951       ])
2952   fi
2953 fi
2954
2955 dnl
2956 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2957 dnl
2958 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2959
2960 dnl
2961 dnl libfluidsynth (MIDI synthetizer) plugin
2962 dnl
2963 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2964
2965 dnl
2966 dnl Teletext Modules
2967 dnl vbi decoder plugin (using libzbvi)
2968 dnl telx module
2969 dnl uncompatible
2970 dnl
2971 AC_ARG_ENABLE(zvbi,
2972   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2973                   libzvbi (default enabled)]))
2974 AC_ARG_ENABLE(telx,
2975   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2976                   zvbi) (default enabled if zvbi is absent)]))
2977
2978 AS_IF( [test "${enable_zvbi}" != "no"],[
2979     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2980         [
2981           VLC_ADD_PLUGIN([zvbi])
2982           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2983           AS_IF( [test "${enable_telx}" = "yes"],[
2984                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2985                   ])
2986         ],[
2987           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2988         ])
2989     ])
2990 AS_IF( [test "${enable_telx}" != "no" ],[
2991   VLC_ADD_PLUGIN([telx])
2992   ])
2993
2994 dnl
2995 dnl libass subtitle rendering module
2996 dnl
2997 AC_ARG_ENABLE(libass,
2998   [  --enable-libass         Subtitle support using libass (default enabled)])
2999 AS_IF( [test "${enable_libass}" != "no"], [
3000   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
3001       [
3002         VLC_ADD_PLUGIN([libass])
3003
3004         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
3005           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
3006            VLC_ADD_LIBS([libass],[-lfontconfig])
3007        ])
3008       ],[
3009         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
3010       ])
3011   ])
3012
3013 dnl
3014 dnl ARIB subtitles rendering module
3015 dnl
3016 AC_ARG_ENABLE(aribsub,
3017   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
3018 AS_IF( [test "${enable_aribsub}" != "no" ],[
3019   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
3020       have_aribb24="yes"
3021       VLC_ADD_PLUGIN([aribsub])
3022       VLC_ADD_LIBS([aribsub],[-laribb24])
3023       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
3024     ],[
3025       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
3026       have_aribb24="no"
3027   ])
3028 ])
3029 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
3030
3031 dnl
3032 dnl ARIB B25
3033 dnl
3034 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
3035
3036 dnl
3037 dnl  kate decoder plugin
3038 dnl
3039 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
3040
3041 dnl
3042 dnl  tiger rendering for kate decoder plugin
3043 dnl
3044 AC_ARG_ENABLE(tiger,
3045 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
3046 AS_IF([test "${enable_tiger}" != "no"], [
3047   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
3048       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
3049         AS_IF([test -n "${enable_tiger}"], [
3050           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
3051         ])
3052   ])
3053 ])
3054
3055
3056 dnl
3057 dnl  Video plugins
3058 dnl
3059
3060 EXTEND_HELP_STRING([Video plugins:])
3061
3062 dnl
3063 dnl  OpenGL
3064 dnl
3065 PKG_CHECK_MODULES([EGL], [egl], [
3066   have_egl="yes"
3067 ], [
3068   have_egl="no"
3069 ])
3070 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3071
3072 have_gl="no"
3073 PKG_CHECK_MODULES([GL], [gl], [
3074   have_gl="yes"
3075 ], [
3076   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3077 #ifdef _WIN32
3078 # include <GL/glew.h>
3079 #endif
3080 #include <GL/gl.h>
3081 ]], [
3082     [int t0 = GL_TEXTURE0;]])
3083   ], [
3084     GL_CFLAGS=""
3085     have_gl="yes"
3086     AS_IF([test "${SYS}" != "mingw32"], [
3087       GL_LIBS="-lGL"
3088     ], [
3089       GL_LIBS="-lopengl32"
3090     ])
3091   ])
3092 ])
3093 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3094
3095 dnl OpenGL ES 2: depends on EGL 1.1
3096 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3097 dnl OpenGL ES 1: depends on EGL 1.0
3098 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [disabled])
3099
3100 dnl
3101 dnl  Xlib
3102 dnl
3103
3104 AC_PATH_XTRA()
3105 AC_CHECK_HEADERS(X11/Xlib.h)
3106
3107 dnl
3108 dnl  X C Bindings modules
3109 dnl
3110 AC_ARG_ENABLE(xcb,
3111   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3112   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" -a "${SYS}" != "symbian"], [
3113     enable_xcb="yes"
3114   ], [
3115     enable_xcb="no"
3116   ])
3117 ])
3118 AC_ARG_ENABLE(xvideo,
3119   [  --enable-xvideo         XVideo support (default enabled)],, [
3120     enable_xvideo="$enable_xcb"
3121 ])
3122 AC_ARG_ENABLE(glx,
3123   [  --enable-glx            OpenGL support through GLX (default enabled)],, [
3124   enable_glx="$enable_xcb"
3125 ])
3126
3127 have_xcb="no"
3128 have_xcb_keysyms="no"
3129 have_xcb_randr="no"
3130 have_xcb_xvideo="no"
3131 AS_IF([test "${enable_xcb}" != "no"], [
3132   dnl libxcb
3133   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3134   have_xcb="yes"
3135   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3136   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3137   PKG_CHECK_MODULES(XPROTO, [xproto])
3138
3139   AS_IF([test "${enable_xvideo}" != "no"], [
3140     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3141   ])
3142
3143   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3144
3145   dnl xcb-utils
3146   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3147     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3148   ])
3149 ])
3150 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3151 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3152 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3153 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3154
3155
3156 dnl
3157 dnl VDPAU needs X11
3158 dnl
3159 AC_ARG_ENABLE(vdpau,
3160   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3161 have_vdpau="no"
3162 AS_IF([test "${enable_vdpau}" != "no"], [
3163   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3164     have_vdpau="yes"
3165     AS_IF([test "${no_x}" = "yes"], [
3166       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3167     ])
3168   ], [
3169     AS_IF([test -n "${enable_vdpau}"], [
3170       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3171     ])
3172   ])
3173 ])
3174 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3175
3176 have_avcodec_vdpau="no"
3177 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3178   case "${avfork}" in
3179     libav) av_vdpau_ver="55.26.0" ;;
3180     ffmpeg) av_vdpau_ver="55.42.100" ;;
3181   esac
3182   PKG_CHECK_EXISTS([libavutil >= 52.4.0 libavcodec >= ${av_vdpau_ver}], [
3183     have_avcodec_vdpau="yes"
3184     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3185   ], [
3186     AS_IF([test -n "${enable_vdpau}"], [
3187       AC_MSG_ERROR([libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3188     ], [
3189       AC_MSG_WARN([libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3190     ])
3191   ])
3192 ])
3193 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3194
3195
3196 dnl
3197 dnl  Wayland
3198 dnl
3199 AC_ARG_ENABLE(wayland,
3200   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3201 have_wayland="no"
3202 AC_ARG_VAR([WAYLAND_SCANNER], [Wayland scanner utility])
3203
3204 AS_IF([test "${enable_wayland}" != "no"], [
3205   AC_MSG_CHECKING([for the Wayland scanner])
3206   AS_IF([test -z "$WAYLAND_SCANNER"], [
3207     PKG_CHECK_EXISTS([wayland-scanner], [
3208       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3209     ], [
3210       WAYLAND_SCANNER="wayland-scanner"
3211     ])
3212   ])
3213   AC_MSG_RESULT([$WAYLAND_SCANNER])
3214
3215   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3216     have_wayland="yes"
3217   ], [
3218     AS_IF([test -n "${enable_wayland}"], [
3219       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3220     ])
3221   ])
3222
3223   AS_IF([test "${have_egl}" = "yes"], [
3224     PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3225       have_wayland_egl="yes"
3226     ], [
3227       AS_IF([test -n "${enable_wayland}"], [
3228         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3229       ])
3230     ])
3231   ])
3232 ])
3233 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3234 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3235
3236
3237 dnl
3238 dnl  SDL module
3239 dnl
3240 AC_ARG_ENABLE(sdl,
3241   [  --enable-sdl            SDL support (default enabled)])
3242 AC_ARG_ENABLE(sdl-image,
3243   [  --enable-sdl-image      SDL image support (default enabled)])
3244 if test "${enable_sdl}" != "no"
3245 then
3246    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3247       # SDL on Darwin is heavily patched and can only run SDL_image
3248       if test "${SYS}" != "darwin"; then
3249         VLC_ADD_PLUGIN([vout_sdl])
3250       fi
3251
3252       # SDL_image
3253       AS_IF([ test "${enable_sdl_image}" != "no"],[
3254         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3255           VLC_ADD_PLUGIN([sdl_image])],
3256           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3257           ])
3258       ])
3259    ],[
3260      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3261    ])
3262 fi
3263
3264 dnl
3265 dnl  freetype module
3266 dnl
3267 AC_ARG_ENABLE(freetype,
3268   [  --enable-freetype       freetype support   (default auto)])
3269 AC_ARG_ENABLE(fribidi,
3270   [  --enable-fribidi        fribidi support    (default auto)])
3271 AC_ARG_ENABLE(fontconfig,
3272   [  --enable-fontconfig     fontconfig support (default auto)])
3273
3274 AC_ARG_WITH([default-font],
3275     AS_HELP_STRING([--with-default-font=PATH],
3276         [Path to the default font]),
3277         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3278             "$withval", [Default font])])
3279 AC_ARG_WITH([default-monospace-font],
3280     AS_HELP_STRING([--with-default-monospace-font=PATH],
3281         [Path to the default font]),
3282         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3283             "$withval", [Default monospace font])])
3284
3285 AC_ARG_WITH([default-font-family],
3286     AS_HELP_STRING([--with-default-font-family=NAME],
3287         [Path to the default font family]),
3288         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3289             "$withval", [Default font family])])
3290 AC_ARG_WITH([default-monospace-font-family],
3291     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3292         [Path to the default font family]),
3293         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3294             "$withval", [Default monospace font family])])
3295
3296 if test "${enable_freetype}" != "no"; then
3297    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3298       have_freetype=yes
3299       VLC_ADD_PLUGIN([freetype])
3300       VLC_ADD_CPPFLAGS([freetype skins2],[${FREETYPE_CFLAGS}])
3301       if test "${SYS}" = "mingw32"; then
3302         VLC_ADD_LIBS([freetype],[-liconv -lz])
3303       fi
3304       VLC_ADD_LIBS([freetype skins2],[${FREETYPE_LIBS}])
3305
3306       AC_CHECK_HEADERS(Carbon/Carbon.h,
3307                        [VLC_ADD_LIBS([freetype],[-Wl,-framework,Carbon])])
3308
3309       dnl fontconfig support
3310       if test "${SYS}" != "mingw32"; then
3311           if test "${enable_fontconfig}" != "no"; then
3312             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3313               VLC_ADD_CPPFLAGS([freetype],[-DHAVE_FONTCONFIG])
3314               VLC_ADD_LIBS([freetype],[-lfontconfig])
3315             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3316           fi
3317       else
3318           AS_IF([test "$vlc_winstore_app" != "1"],[
3319             VLC_ADD_LIBS([freetype],[-lgdi32])
3320           ])
3321       fi
3322
3323       dnl fribidi support
3324       if test "${enable_fribidi}" != "no"; then
3325         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3326           VLC_ADD_CPPFLAGS([freetype skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3327           VLC_ADD_LIBS([freetype skins2], [${FRIBIDI_LIBS}])
3328         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional support will be disabled in FreeType.])])
3329       fi
3330
3331   ],[
3332   have_freetype=no
3333   AS_IF([test -n "${enable_freetype}"],[
3334     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3335     ])
3336   ])
3337 fi
3338
3339
3340 dnl
3341 dnl  QuartzText vout module (iOS/Mac OS)
3342 dnl
3343 AC_ARG_ENABLE(macosx-quartztext,
3344   [  --enable-macosx-quartztext   Mac OS X quartz text module (default enabled on Mac OS X)])
3345 if test "x${enable_macosx_quartztext}" != "xno" &&
3346   (test "${SYS}" = "darwin" || test "${enable_macosx_quartztext}" = "yes")
3347 then
3348   VLC_ADD_PLUGIN([quartztext])
3349   VLC_ADD_LIBS([quartztext],[-Wl,-framework,ApplicationServices])
3350 fi
3351
3352 dnl
3353 dnl  SVG module (text rendering and image decoding)
3354 dnl
3355 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3356 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3357
3358 dnl
3359 dnl  android surface module
3360 dnl
3361 AC_ARG_ENABLE(android-surface,
3362   [  --enable-android-surface   Android Surface video output module (default disabled)])
3363 if test "${enable_android_surface}" = "yes"; then
3364      VLC_ADD_PLUGIN([android_surface])
3365      VLC_ADD_PLUGIN([android_window])
3366 fi
3367
3368 dnl
3369 dnl  Windows DirectX module
3370 dnl
3371
3372 AC_ARG_ENABLE(directx,
3373   [AS_HELP_STRING([--enable-directx],
3374     [Microsoft DirectX support (default enabled on Windows)])],, [
3375   AS_IF([test "${SYS}" = "mingw32"], [
3376     enable_directx="yes"
3377   ], [
3378     enable_directx="no"
3379   ])
3380 ])
3381 have_directx="no"
3382 AS_IF([test "${enable_directx}" != "no"], [
3383   dnl DirectDraw
3384   AC_CHECK_HEADERS(ddraw.h, [
3385     have_directx="yes"
3386   ], [
3387     AC_MSG_ERROR([Cannot find DirectX headers!])
3388   ])
3389
3390   dnl OpenGL
3391   AC_CHECK_HEADERS(GL/wglew.h, [
3392     VLC_ADD_PLUGIN([glwin32])
3393   ],, [
3394     #include <windows.h>
3395     #include <GL/gl.h>
3396   ])
3397
3398   dnl Direct3D
3399   AC_CHECK_HEADERS(d3d9.h, [
3400     VLC_ADD_PLUGIN([direct3d])
3401   ])
3402
3403   dnl Direct2D
3404   AC_CHECK_HEADERS(d2d1.h, [
3405     VLC_ADD_PLUGIN([direct2d])
3406   ])
3407 ])
3408 AM_CONDITIONAL([HAVE_DIRECTX], [test "$have_directx" = "yes"])
3409
3410 dnl
3411 dnl  Linux framebuffer module
3412 dnl
3413 AC_CHECK_HEADER([linux/fb.h], [
3414   VLC_ADD_PLUGIN([fb])
3415 ])
3416
3417
3418 dnl
3419 dnl  DirectFB module
3420 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3421 dnl  TODO: support for static linking
3422 dnl
3423 AC_ARG_ENABLE(directfb,
3424   [  --enable-directfb       DirectFB support (default disabled)])
3425 AC_ARG_WITH(directfb,
3426   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3427
3428 if test "${enable_directfb}" = "yes"; then
3429     have_directfb="false"
3430     CPPFLAGS_mydirectfb=
3431     LIBS_mydirectfb=
3432     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3433         dnl Trying the given location
3434         VLC_SAVE_FLAGS
3435
3436         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3437         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3438
3439         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3440         LIBS="${LIBS} ${LIBS_new}"
3441
3442         dnl FIXME: too obscure
3443         AC_CHECK_HEADER([directfb.h], [
3444             AC_CHECK_LIB([direct],[direct_initialize], [
3445                 AC_CHECK_LIB([fusion], [fusion_enter], [
3446                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3447                 ], have_directfb="false")
3448             ], have_directfb="false")
3449         ], have_directfb="false")
3450
3451         VLC_RESTORE_FLAGS
3452
3453         if test "${have_directfb}" = "true"; then
3454             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3455             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3456         fi
3457     else
3458         dnl Look for directfb-config
3459         AC_PATH_PROG(DIRECTFB_CONFIG, directfb-config, no, ${PATH})
3460         if test "${DIRECTFB_CONFIG}" != "no"; then
3461             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3462             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3463             have_directfb="true"
3464         else
3465             dnl Trying with pkg-config
3466             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3467                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3468                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3469                 have_directfb="true"
3470                 ], [have_directfb="false"])
3471         fi
3472     fi
3473     if test "${have_directfb}" = "true"; then
3474         VLC_ADD_PLUGIN([directfb])
3475         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3476         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3477     else
3478         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3479     fi
3480 fi
3481
3482 dnl
3483 dnl  AA plugin
3484 dnl
3485 AC_ARG_ENABLE(aa,
3486   [  --enable-aa             aalib output (default disabled)])
3487 if test "${enable_aa}" = "yes"
3488 then
3489   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3490   if test "${have_aa}" = "true"
3491   then
3492     VLC_ADD_PLUGIN([aa])
3493   fi
3494 fi
3495
3496 dnl
3497 dnl  libcaca plugin
3498 dnl
3499 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3500
3501 dnl
3502 dnl  OS/2 KVA plugin
3503 dnl
3504 AC_ARG_ENABLE(kva,
3505   [AS_HELP_STRING([--enable-kva],
3506     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3507   AS_IF([test "$SYS" = "os2"], [
3508     enable_kva="yes"
3509   ])
3510 ])
3511 have_kva="no"
3512 KVA_LIBS=""
3513 AS_IF([test "$enable_kva" != "no"], [
3514   AC_CHECK_HEADERS([kva.h], [
3515     have_kva="yes"
3516     AC_CHECK_LIB(kva, main, [
3517       KVA_LIBS="-lkva"
3518     ])
3519   ])
3520 ])
3521 AC_SUBST(KVA_LIBS)
3522 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3523
3524 dnl
3525 dnl MMAL plugin
3526 dnl
3527 AC_ARG_ENABLE(mmal,
3528   AS_HELP_STRING([--enable-mmal],
3529     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3530 if test "${enable_mmal}" != "no"; then
3531   VLC_SAVE_FLAGS
3532   LDFLAGS="${LDFLAGS} -L/opt/vc/lib"
3533   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3534   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3535     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3536         have_mmal="yes"
3537         VLC_ADD_PLUGIN([mmal])
3538         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3539         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3540         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal ]) ], [
3541           AS_IF([test "${enable_mmal}" = "yes"],
3542             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3543             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3544           ],
3545         [])
3546     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3547       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3548       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3549   VLC_RESTORE_FLAGS
3550 fi
3551 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3552
3553 dnl
3554 dnl  Audio plugins
3555 dnl
3556
3557 EXTEND_HELP_STRING([Audio plugins:])
3558
3559 dnl
3560 dnl  Pulseaudio module
3561 dnl
3562 AC_ARG_ENABLE(pulse,
3563   [AS_HELP_STRING([--enable-pulse],
3564     [use the PulseAudio client library (default auto)])])
3565 have_pulse="no"
3566 AS_IF([test "${enable_pulse}" != "no"], [
3567   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3568     have_pulse="yes"
3569   ], [
3570     AS_IF([test "x${enable_pulse}" != "x"], [
3571       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3572     ])
3573   ])
3574 ])
3575 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3576
3577 dnl
3578 dnl  ALSA module
3579 dnl
3580 AC_ARG_ENABLE(alsa,
3581   [AS_HELP_STRING([--enable-alsa],
3582     [support the Advanced Linux Sound Architecture (default auto)])],, [
3583   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3584     enable_alsa="yes"
3585   ])
3586 ])
3587 have_alsa="no"
3588 AS_IF([test "${enable_alsa}" != "no"], [
3589   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3590     have_alsa="yes"
3591   ], [
3592     AS_IF([test "x${enable_alsa}" != "x"], [
3593       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3594     ])
3595   ])
3596 ])
3597 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3598
3599 dnl
3600 dnl  Open Sound System module
3601 dnl
3602 AC_ARG_ENABLE(oss,
3603   [AS_HELP_STRING([--enable-oss],
3604     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3605   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3606     enable_oss="no"
3607   ])
3608 ])
3609 have_oss="no"
3610 OSS_LIBS=""
3611 AS_IF([test "$enable_oss" != "no"], [
3612   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3613     have_oss="yes"
3614     AC_CHECK_LIB(ossaudio, main, [
3615       OSS_LIBS="-lossaudio"
3616     ])
3617   ])
3618 ])
3619 AC_SUBST(OSS_LIBS)
3620 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3621
3622 dnl
3623 dnl  OpenBSD sndio module
3624 dnl
3625 AC_ARG_ENABLE([sndio],
3626   [AS_HELP_STRING([--disable-sndio],
3627     [support the OpenBSD sndio (default auto)])],, [
3628   AS_IF([test "$SYS" = "openbsd"], [
3629     enable_sndio="yes"
3630   ])
3631 ])
3632 have_sndio="no"
3633 AS_IF([test "$enable_sndio" != "no"], [
3634   AC_CHECK_HEADER([sndio.h], [
3635     have_sndio="yes"
3636   ])
3637 ])
3638 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3639
3640 dnl
3641 dnl  Windows Audio Session plugin
3642 dnl
3643 AC_ARG_ENABLE([wasapi],
3644   [AS_HELP_STRING([--enable-wasapi],
3645     [use the Windows Audio Session API (default auto)])
3646 ])
3647 have_wasapi="no"
3648 AS_IF([test "$enable_wasapi" != "no"], [
3649   AC_CHECK_HEADER([audioclient.h], [
3650     have_wasapi="yes"
3651   ], [
3652     AS_IF([test "x${enable_wasapi}" != "x"], [
3653       AC_MSG_ERROR([Windows Audio Session API not found.])
3654     ])
3655   ])
3656 ])
3657 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3658
3659 dnl
3660 dnl  AudioQueue plugin
3661 dnl
3662 AC_ARG_ENABLE(audioqueue,
3663   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3664 if test "${enable_audioqueue}" = "yes"
3665 then
3666   VLC_ADD_PLUGIN([audioqueue])
3667 fi
3668
3669 dnl
3670 dnl  JACK modules
3671 dnl
3672 AC_ARG_ENABLE(jack,
3673   [AS_HELP_STRING([--disable-jack],
3674     [do not use jack (default auto)])])
3675 have_jack="no"
3676 AS_IF([test "${enable_jack}" != "no"], [
3677     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3678       [ have_jack=yes ],
3679       [
3680       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3681
3682       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3683       [ have_jack=yes ],
3684       [
3685       AS_IF([test -n "${enable_jack}"],
3686          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3687          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3688       ])
3689     ])
3690 ])
3691 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3692
3693 dnl
3694 dnl  OpenSLES Android
3695 dnl
3696 AC_ARG_ENABLE(opensles,
3697   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3698 if test "${HAVE_ANDROID}" = "1"; then
3699   if test "${enable_opensles}" = "yes"; then
3700       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3701         [ VLC_ADD_PLUGIN([opensles_android]) ],
3702         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3703   fi
3704 fi
3705
3706 dnl
3707 dnl libsamplerate plugin
3708 dnl
3709 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3710
3711 dnl
3712 dnl  OS/2 KAI plugin
3713 dnl
3714 AC_ARG_ENABLE(kai,
3715   [AS_HELP_STRING([--enable-kai],
3716     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3717   AS_IF([test "$SYS" = "os2"], [
3718     enable_kai="yes"
3719   ])
3720 ])
3721 have_kai="no"
3722 KAI_LIBS=""
3723 AS_IF([test "$enable_kai" != "no"], [
3724   AC_CHECK_HEADERS([kai.h], [
3725     have_kai="yes"
3726     AC_CHECK_LIB(kai, main, [
3727       KAI_LIBS="-lkai"
3728     ])
3729   ])
3730 ])
3731 AC_SUBST(KAI_LIBS)
3732 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3733
3734 dnl
3735 dnl  chromaprint audio track fingerprinter
3736 dnl
3737 m4_pushdef([libchromaprint_version], 0.6.0)
3738 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3739     VLC_ADD_PLUGIN([stream_out_chromaprint])
3740     VLC_ADD_CFLAGS([stream_out_chromaprint],[${CHROMAPRINT_CFLAGS}] [-I./webservices -I../stream_out])
3741     VLC_ADD_LIBS([stream_out_chromaprint],[${CHROMAPRINT_LIBS}]),
3742     AS_IF([test "${enable_chromaprint}" = "yes"],
3743         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3744         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3745          ),
3746     [(Chromaprint based audio fingerprinter)],[auto])
3747 m4_popdef([libchromaprint_version])
3748
3749 dnl
3750 dnl  Chromecast streaming support
3751 dnl
3752 m4_pushdef([protobuf_lite_version], 2.5.0)
3753 AC_ARG_VAR(PROTOC, [protobuf compiler])
3754 AC_PATH_PROGS(PROTOC, protoc, no)
3755 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3756     AS_IF([test "x${PROTOC}" != "xno"], [
3757         VLC_ADD_PLUGIN([stream_out_chromecast])
3758         VLC_ADD_CXXFLAGS([stream_out_chromecast],[${CHROMECAST_CFLAGS}] [-I./chromecast])
3759         VLC_ADD_LIBS([stream_out_chromecast],[${CHROMECAST_LIBS}])
3760         build_chromecast="yes"
3761     ], [
3762     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3763     ])
3764 ], [
3765     AS_IF([test "${enable_chromecast}" = "yes"],
3766         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3767         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3768     )
3769     enable_chromecast="no"
3770 ], [(Chromecast streaming support)], [auto])
3771 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3772 m4_popdef([protobuf_lite_version])
3773
3774 dnl
3775 dnl  Interface plugins
3776 dnl
3777
3778 EXTEND_HELP_STRING([Interface plugins:])
3779
3780 dnl
3781 dnl QT
3782 dnl
3783 AC_ARG_ENABLE(qt, [
3784   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3785   AS_IF([test "${SYS}" = "darwin"], [
3786     enable_qt="no"
3787   ])
3788 ])
3789 AS_IF([test "${enable_qt}" != "no"], [
3790   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.1.0 Qt5Widgets Qt5Gui], [
3791       PKG_CHECK_MODULES([QTX11], [Qt5X11Extras], [
3792           VLC_ADD_LIBS([qt4],[${QTX11_LIBS}])
3793           VLC_ADD_CXXFLAGS([qt4],[${QTX11_CFLAGS} -DQT5_HAS_X11])
3794       ],[
3795           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3796       ])
3797       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3798       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3799       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3800       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3801       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3802     ], [
3803       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.6.0],, [
3804         AS_IF([test -n "${enable_qt}"],[
3805           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3806         ],[
3807           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3808         ])
3809         enable_qt="no"
3810       ])
3811       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3812       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3813       AC_PATH_PROG(RCC, rcc, rcc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3814       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3815     ])
3816 ])
3817 AS_IF([test "${enable_qt}" != "no"], [
3818   VLC_ADD_PLUGIN([qt4])
3819   ALIASES="${ALIASES} qvlc"
3820 ])
3821 AM_CONDITIONAL(ENABLE_QT4, [test "$enable_qt" != "no"])
3822
3823 dnl
3824 dnl Simple test for skins2 dependency
3825 dnl
3826 AS_IF([test "$enable_qt" = "no"], [
3827   AS_IF([test "${enable_skins2}" = "yes"], [
3828     AC_MSG_ERROR([The skins2 module depends on the Qt4 interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt4 development package or alternatively you can also configure with: --disable-qt4 --disable-skins2.])
3829   ], [
3830     enable_skins2="no"
3831     AC_MSG_WARN([The skins2 module depends on the Qt4 interface, Qt4 is not built so skins2 is disabled.])
3832   ])
3833 ])
3834
3835 dnl
3836 dnl Skins2 module
3837 dnl
3838 AC_ARG_ENABLE(skins2,
3839   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3840 AS_IF([test "${enable_skins2}" != "no"], [
3841   have_skins_deps="yes"
3842
3843   dnl Win32
3844   AS_IF([test "${SYS}" = "mingw32"], [
3845     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3846     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3847   dnl MacOS
3848   ], [test "${SYS}" = "darwin"], [
3849     VLC_ADD_CPPFLAGS([skins2],[ -DMACOSX_SKINS])
3850     VLC_ADD_LIBS([skins2],[-Wl,-framework,Carbon])
3851   dnl OS/2
3852   ], [test "${SYS}" = "os2"], [
3853     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3854   dnl Linux/Unix
3855   ], [
3856     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3857     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3858     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3859     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3860     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3861   ])
3862
3863   dnl for All OSes
3864   VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3865
3866   dnl we need freetype
3867   AS_IF([test "${have_freetype}" != "yes"], [
3868     have_skins_deps="no"
3869   ])
3870
3871   AS_IF([test "${have_skins_deps}" = "no"], [
3872     AS_IF([test "x${enable_skins2}" = "x"], [
3873       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3874     ], [
3875       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3876     ])
3877     enable_skins2="no"
3878   ], [
3879     VLC_ADD_PLUGIN([skins2])
3880     ALIASES="${ALIASES} svlc"
3881     enable_skins2="yes"
3882   ])
3883 ])
3884 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3885
3886 AC_ARG_ENABLE(libtar,
3887   [  --enable-libtar         libtar support for skins2 (default auto)])
3888 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3889   AC_CHECK_HEADERS(libtar.h, [
3890     VLC_ADD_LIBS([skins2],[-ltar])
3891   ])
3892 ])
3893
3894 dnl
3895 dnl  MacOS X gui module
3896 dnl
3897 AC_ARG_ENABLE(macosx,
3898   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3899 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3900 then
3901   VLC_ADD_LIBS([macosx], [-Wl,-framework,Cocoa -Wl,-framework,Carbon -Wl,-framework,CoreServices])
3902   VLC_ADD_OBJCFLAGS([macosx], [-fobjc-exceptions] )
3903   VLC_ADD_PLUGIN([macosx])
3904
3905   VLC_ADD_LIBS([macosx], [-Wl,-framework,QTKit -Wl,-framework,IOKit -Wl,-framework,AddressBook -Wl,-framework,WebKit -Wl,-framework,CoreAudio -Wl,-framework,SystemConfiguration -Wl,-framework,ScriptingBridge])
3906
3907   if test ! -d ${CONTRIB_DIR}/Sparkle.framework
3908   then
3909     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3910   fi
3911   VLC_ADD_LIBS([macosx], [-F${CONTRIB_DIR} -Wl,-framework,Sparkle])
3912   VLC_ADD_OBJCFLAGS([macosx], [-F${CONTRIB_DIR}])
3913
3914   if test ! -d ${CONTRIB_DIR}/BGHUDAppKit.framework
3915   then
3916     AC_MSG_ERROR([BGHUDAppKit framework is required and was not found in ${CONTRIB_DIR}])
3917   fi
3918   VLC_ADD_LIBS([macosx], [-F${CONTRIB_DIR} -Wl,-framework,BGHUDAppKit])
3919   VLC_ADD_OBJCFLAGS([macosx], [-F${CONTRIB_DIR}])
3920 fi
3921 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no"])
3922
3923 dnl
3924 dnl  Minimal Mac OS X module
3925 dnl
3926 AC_ARG_ENABLE(minimal-macosx,
3927   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3928 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3929 then
3930   VLC_ADD_LIBS([minimal_macosx], [-Wl,-framework,Cocoa])
3931   VLC_ADD_OBJCFLAGS([minimal_macosx], [-fobjc-exceptions] )
3932   VLC_ADD_PLUGIN([minimal_macosx])
3933 fi
3934 AM_CONDITIONAL(ENABLE_MINIMAL_MACOSX, [test "$enable_minimal_macosx" != "no"])
3935
3936 dnl
3937 dnl  MacOS X dialog provider
3938 dnl
3939 AC_ARG_ENABLE(macosx-dialog-provider,
3940   [  --enable-macosx-dialog-provider Mac OS X dialog module (default enabled on Mac OS X)])
3941 if test "x${enable_macosx_dialog_provider}" != "xno" &&
3942   (test "${SYS}" = "darwin" || test "${enable_macosx_dialog_provider}" = "yes")
3943 then
3944   VLC_ADD_LIBS([macosx_dialog_provider],[-Wl,-framework,Cocoa])
3945   VLC_ADD_PLUGIN([macosx_dialog_provider])
3946 fi
3947 AM_CONDITIONAL(ENABLE_MACOSX_DIALOG_PROVIDER, [test "$enable_macosx_dialog_provider" != "no"])
3948
3949 dnl
3950 dnl  ncurses module
3951 dnl
3952 AC_ARG_ENABLE(ncurses,
3953 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3954 AS_IF([test "${enable_ncurses}" != "no"] ,[
3955   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3956     VLC_ADD_PLUGIN([ncurses])
3957     VLC_ADD_CFLAGS([ncurses],[${NCURSES_CFLAGS}])
3958     VLC_ADD_LIBS([ncurses],[${NCURSES_LIBS}])
3959     ALIASES="${ALIASES} nvlc"
3960   ], [
3961     AS_IF([test -n "${enable_ncurses}"], [
3962       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3963     ])
3964   ])
3965 ])
3966
3967 dnl
3968 dnl  Lirc plugin
3969 dnl
3970 AC_ARG_ENABLE(lirc,
3971   [  --enable-lirc           lirc support (default disabled)])
3972 if test "${enable_lirc}" = "yes"
3973 then
3974   AC_CHECK_HEADER(lirc/lirc_client.h, AC_CHECK_LIB(lirc_client, lirc_init, have_lirc="true", have_lirc="false"),have_lirc="false")
3975   if test "${have_lirc}" = "true"
3976   then
3977     VLC_ADD_PLUGIN([lirc])
3978     VLC_ADD_LIBS([lirc],[-llirc_client])
3979   fi
3980 fi
3981
3982 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3983 dnl
3984 dnl  goom visualization plugin
3985 dnl
3986 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3987
3988 dnl
3989 dnl libprojectM visualization plugin
3990 dnl
3991 AC_ARG_ENABLE(projectm,
3992   [  --enable-projectm       projectM visualization plugin (default enabled)])
3993 AS_IF([test "${enable_projectm}" != "no"],
3994   [
3995     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3996     [
3997       VLC_ADD_PLUGIN([projectm])
3998       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3999         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
4000         [ AC_MSG_WARN( [Using libprojectM version 1] )
4001       ])
4002     ],[
4003       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
4004     ])
4005   ])
4006
4007 dnl
4008 dnl Vovoid VSXu visualization plugin
4009 dnl
4010 AC_ARG_ENABLE(vsxu,
4011   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
4012 AS_IF([test "${enable_vsxu}" != "no"],
4013   [
4014     PKG_CHECK_MODULES(VSXU, libvsxu,
4015     [
4016       VLC_ADD_PLUGIN([vsxu])
4017       VLC_ADD_CXXFLAGS([vsxu],[$VSXU_CFLAGS])
4018       VLC_ADD_LIBS([vsxu],[$VSXU_LIBS])
4019     ],[
4020       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
4021     ])
4022   ])
4023
4024 dnl
4025 dnl  AtmoLight (homemade Philips Ambilight clone)
4026 dnl
4027 AC_ARG_ENABLE(atmo,
4028 AS_HELP_STRING([--disable-atmo],[AtmoLight (homemade Philips Ambilight clone)
4029                 (default enabled)]),, [enable_atmo="yes"])
4030 AS_IF([test "${enable_atmo}" != no], [
4031   AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "linux"], [
4032     AC_LANG_PUSH(C++)
4033     VLC_ADD_PLUGIN([atmo])
4034     AC_LANG_POP(C++)
4035   ])
4036 ])
4037
4038 dnl
4039 dnl  glSpectrum
4040 dnl
4041 AC_ARG_ENABLE(glspectrum,
4042   [  --enable-glspectrum    3D OpenGL spectrum visualization (default auto)])
4043 if test "${enable_glspectrum}" != "no" && test "${have_gl}" = "yes"
4044 then
4045     VLC_ADD_PLUGIN([glspectrum])
4046     VLC_ADD_LIBS([glspectrum],[$GL_LIBS])
4047 fi
4048
4049 EXTEND_HELP_STRING([Service Discovery plugins:])
4050 dnl
4051 dnl  Bonjour services discovery
4052 PKG_ENABLE_MODULES_VLC([BONJOUR], [], [avahi-client >= 0.6], [Bonjour services discovery], [auto])
4053
4054 dnl
4055 dnl  libudev services discovery
4056 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
4057
4058 dnl
4059 dnl MTP devices services discovery
4060 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
4061
4062 dnl
4063 dnl UPnP Plugin (Intel SDK)
4064 dnl
4065 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
4066
4067 EXTEND_HELP_STRING([Misc options:])
4068
4069 dnl
4070 dnl  libxml2 module
4071 dnl
4072 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4073
4074
4075 dnl
4076 dnl libgcrypt
4077 dnl
4078 AC_ARG_ENABLE(libgcrypt,
4079   [  --disable-libgcrypt     gcrypt support (default enabled)])
4080 AS_IF([test "${enable_libgcrypt}" != "no"], [
4081   AC_CHECK_DECL([GCRYCTL_SET_THREAD_CBS], [
4082     libgcrypt-config --version >/dev/null || \
4083         AC_MSG_ERROR([gcrypt.h present but libgcrypt-config could not be found])
4084     AC_CHECK_LIB(gcrypt, gcry_control, [
4085       have_libgcrypt="yes"
4086       GCRYPT_CFLAGS="`libgcrypt-config --cflags`"
4087       GCRYPT_LIBS="`libgcrypt-config --libs`"
4088     ], [
4089       AC_MSG_ERROR([libgcrypt not found. Install libgcrypt or pass --disable-libgcrypt.])
4090     ], [`libgcrypt-config --libs`])
4091   ], [
4092     AC_MSG_ERROR([libgcrypt version 1.1.94 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4093   ], [#include <gcrypt.h>]
4094   )
4095 ])
4096
4097 AC_SUBST(GCRYPT_CFLAGS)
4098 AC_SUBST(GCRYPT_LIBS)
4099 AM_CONDITIONAL([HAVE_GCRYPT], [test "${have_libgcrypt}" = "yes"])
4100
4101 dnl
4102 dnl TLS/SSL
4103 dnl
4104 AC_ARG_ENABLE(gnutls,
4105   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4106 AS_IF([test "${enable_gnutls}" != "no"], [
4107   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.2.0], [
4108     VLC_ADD_PLUGIN([gnutls])
4109   ], [
4110     AS_IF([test -n "${enable_gnutls}"], [
4111       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4112     ])
4113   ])
4114 ])
4115
4116
4117 dnl
4118 dnl Taglib plugin
4119 dnl
4120 AC_ARG_ENABLE(taglib,
4121   [AS_HELP_STRING([--disable-taglib],
4122     [do not use TagLib (default enabled)])])
4123 AS_IF([test "${enable_taglib}" != "no"], [
4124   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4125     VLC_ADD_PLUGIN([taglib])
4126   ], [
4127     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4128 ])
4129
4130
4131 dnl
4132 dnl update checking system
4133 dnl
4134 AC_ARG_ENABLE(update-check,
4135   [  --enable-update-check   update checking system (default disabled)])
4136 if test "${enable_update_check}" = "yes"
4137 then
4138   if test "${have_libgcrypt}" != "yes"
4139   then
4140     AC_MSG_ERROR([libgcrypt is required for update checking system])
4141   fi
4142   VLC_ADD_LIBS([libvlccore], [${GCRYPT_LIBS}])
4143   VLC_ADD_CFLAGS([libvlccore], [${GCRYPT_CFLAGS}])
4144   AC_DEFINE([UPDATE_CHECK], 1, [Define if you want to use the VLC update mechanism])
4145 fi
4146
4147 dnl
4148 dnl Growl notification plugin
4149 dnl
4150 AC_ARG_ENABLE(growl,
4151   [  --enable-growl          growl notification plugin (default disabled)],,
4152   [enable_growl=no])
4153 AS_IF([test "${enable_growl}" != "no"], [
4154     AC_CHECK_HEADERS(${CONTRIB_DIR}/Growl.framework/Versions/A/Headers/Growl.h, [
4155       VLC_ADD_PLUGIN([growl])
4156       VLC_ADD_LIBS([growl], [-F${CONTRIB_DIR} -Wl,-framework,Growl,-framework,Foundation])
4157       VLC_ADD_OBJCFLAGS([growl], [-F${CONTRIB_DIR}])
4158       VLC_ADD_OBJCFLAGS([growl], [-fobjc-exceptions] )
4159     ])
4160   ]
4161 )
4162
4163 dnl
4164 dnl Libnotify notification plugin
4165 dnl
4166 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4167
4168 dnl
4169 dnl  Endianness check
4170 dnl
4171 AC_C_BIGENDIAN
4172 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4173   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4174 ], [
4175   DEFS_BIGENDIAN=""
4176 ])
4177 AC_SUBST(DEFS_BIGENDIAN)
4178
4179 dnl
4180 dnl Where to install KDE solid .desktop
4181 dnl
4182 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
4183 AS_IF([test "x$KDE4_CONFIG" = "x"], [
4184   KDE4_CONFIG="kde4-config"
4185 ])
4186
4187 AC_ARG_WITH(kde-solid,
4188   AS_HELP_STRING([--with-kde-solid=PATH],
4189                  [KDE Solid actions directory (auto)]),, [
4190
4191 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4192   with_kde_solid="yes"
4193 fi
4194 ])
4195 soliddatadir=""
4196 AS_IF([test "${with_kde_solid}" != "no"], [
4197   AS_IF([test "${with_kde_solid}" = "yes"], [
4198     kde4datadir="`${KDE4_CONFIG} --install data`"
4199     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4200     soliddatadir="${kde4datadir}/solid/actions"
4201   ], [
4202     soliddatadir="${with_kde_solid}"
4203   ])
4204 ])
4205 AC_SUBST(soliddatadir)
4206 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4207
4208 EXTEND_HELP_STRING([Components:])
4209
4210 dnl
4211 dnl  the VLC binary
4212 dnl
4213 AC_ARG_ENABLE(vlc,
4214   [  --enable-vlc            build the VLC media player (default enabled)])
4215 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4216
4217 AC_ARG_ENABLE(macosx-vlc-app,
4218   [  --enable-macosx-vlc-app build the VLC media player (default enabled on Mac OS X)])
4219 AM_CONDITIONAL(BUILD_MACOSX_VLC_APP, [test "${enable_macosx_vlc_app}" != "no" &&
4220     (test "${SYS}" = "darwin" || test "${enable_macosx_vlc_app}" = "yes") ])
4221
4222 dnl
4223 dnl  Stuff used by the program
4224 dnl
4225 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4226 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4227 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4228 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4229 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4230 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4231 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4232 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4233 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4234 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4235 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4236 AC_SUBST(COPYRIGHT_MESSAGE)
4237 AC_SUBST(VERSION_MESSAGE)
4238 AC_SUBST(VERSION_MAJOR)
4239 AC_SUBST(VERSION_MINOR)
4240 AC_SUBST(VERSION_REVISION)
4241 AC_SUBST(VERSION_EXTRA)
4242 AC_SUBST(COPYRIGHT_YEARS)
4243 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4244 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4245 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4246 dnl
4247 dnl  Handle substvars that use $(top_srcdir)
4248 dnl
4249 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4250
4251 dnl
4252 dnl  Configuration is finished
4253 dnl
4254 AC_SUBST(SYS)
4255 AC_SUBST(ARCH)
4256 AC_SUBST(ALIASES)
4257 AC_SUBST(ASM)
4258 AC_SUBST(MOC)
4259 AC_SUBST(RCC)
4260 AC_SUBST(UIC)
4261 AC_SUBST(WINDRES)
4262 AC_SUBST(WINE_SDK_PATH)
4263 AC_SUBST(LIBEXT)
4264 AC_SUBST(AM_CPPFLAGS)
4265 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4266 AC_SUBST(FILE_LIBVLCCORE_DLL)
4267 AC_SUBST(FILE_LIBVLC_DLL)
4268
4269 AC_CONFIG_FILES([
4270   Makefile
4271   doc/Makefile
4272   modules/Makefile
4273   m4/Makefile
4274   po/Makefile.in
4275   share/Makefile
4276   compat/Makefile
4277   src/Makefile
4278   lib/Makefile
4279   bin/Makefile
4280   test/Makefile
4281   modules/access_output/Makefile
4282   modules/audio_filter/Makefile
4283   modules/control/Makefile
4284   modules/gui/Makefile
4285   modules/gui/ios_dialog_provider/Makefile
4286   modules/gui/macosx/Makefile
4287   modules/gui/minimal_macosx/Makefile
4288   modules/gui/macosx_dialog_provider/Makefile
4289   modules/gui/qt4/Makefile
4290   modules/gui/skins2/Makefile
4291   modules/mux/Makefile
4292   modules/packetizer/Makefile
4293   modules/stream_out/Makefile
4294   modules/text_renderer/Makefile
4295   modules/video_filter/Makefile
4296   modules/visualization/Makefile
4297   modules/hw/mmal/Makefile
4298 ])
4299
4300 AM_COND_IF([HAVE_WIN32], [
4301   AC_CONFIG_FILES([
4302     extras/package/win32/NSIS/spad.nsi
4303     extras/package/win32/NSIS/vlc.win32.nsi
4304     extras/package/win32/msi/config.wxi
4305   ])
4306 ])
4307
4308 AM_COND_IF([HAVE_DARWIN], [
4309   AC_CONFIG_FILES([
4310     extras/package/macosx/Info.plist
4311     extras/package/macosx/Resources/English.lproj/InfoPlist.strings
4312   ])
4313 ])
4314
4315 dnl Generate makefiles
4316 AC_OUTPUT
4317
4318 dnl Do we have to use make or gmake ?
4319 if make --version 2>&1|grep -q GNU
4320 then
4321     # GNU make, all seems good
4322     MAKE=make
4323 else
4324     # Known GNU make alias (on BSD)
4325     MAKE=gmake
4326 fi
4327 dnl Shortcut to nice compile message
4328 if test -n $SHELL; then
4329   SHELL=${CONFIG_SHELL-/bin/sh}
4330 fi
4331 rm -f compile
4332 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4333 echo "#! $SHELL
4334 rm -f .error\$\$
4335 ERROR=0
4336 export PATH=\"$PATH\" LANG=C
4337 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4338 test -f .error\$\$ && ERROR=1
4339 rm -f .error\$\$
4340 exit \$ERROR" >compile
4341 chmod a+x compile
4342
4343 echo "
4344 libvlc configuration
4345 --------------------
4346 version               : ${VERSION}
4347 system                : ${SYS}
4348 architecture          : ${ARCH}
4349 optimizations         : ${enable_optimizations}"
4350 if test "${enable_vlc}" != "no"; then
4351 echo "vlc aliases           :${ALIASES}"
4352 else
4353 echo "build vlc executable  : no"
4354 fi
4355 echo "
4356 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."