| blob | e1a4800ccb997bb918d9d6e6136711f40b78570d |
1 dnl Autoconf settings for vlc
3 AC_COPYRIGHT([Copyright 1999-2018 VLC authors and VideoLAN])
5 AC_INIT(vlc, 4.0.0-dev)
6 VERSION_MAJOR=4
7 VERSION_MINOR=0
8 VERSION_REVISION=0
9 VERSION_EXTRA=0
10 VERSION_DEV=dev
12 PKGDIR="vlc"
13 AC_SUBST(PKGDIR)
15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
16 CODENAME="Otto Chriek"
17 COPYRIGHT_YEARS="1996-2018"
19 AC_CONFIG_SRCDIR(src/libvlc.c)
20 AC_CONFIG_AUX_DIR(autotools)
21 AC_CONFIG_MACRO_DIR(m4)
22 AC_CONFIG_LIBOBJ_DIR(compat)
23 AC_CANONICAL_BUILD
24 AC_CANONICAL_HOST
25 AC_PRESERVE_HELP_ORDER
27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
28 AC_CONFIG_HEADERS([config.h])
30 AM_SILENT_RULES([yes])
31 AM_MAINTAINER_MODE([enable])
33 dnl
34 dnl Check for tools
35 dnl
36 AC_PROG_CC
37 AC_USE_SYSTEM_EXTENSIONS
38 VLC_PROG_CC_C11
39 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
40 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
41 AH_TOP([
42 #ifndef _REENTRANT
43 # define _REENTRANT
44 #endif
45 ])
46 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
47 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
48 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
50 AC_PROG_CXX
51 AC_PROG_CPP
52 AC_PROG_OBJC
53 AC_PROG_EGREP
54 AC_PROG_MAKE_SET
55 AC_PROG_INSTALL
56 AM_PROG_AS
57 AC_PROG_LEX
58 AC_PROG_YACC
60 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
61 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
62 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
63 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
64 AS_IF([test "$BUILDCC" = "false"], [
65 AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
66 ])
68 dnl Check for compiler properties
69 AC_C_CONST
70 AC_C_INLINE
71 AC_C_RESTRICT
72 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
74 dnl Extend the --help string at the current spot.
75 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
77 dnl Allow binary package maintainer to pass a custom string to avoid
78 dnl cache problem
79 AC_ARG_WITH(binary-version,
80 AS_HELP_STRING([--with-binary-version=STRING],
81 [To avoid plugins cache problem between binary version]),[],[])
82 AS_IF([test -n "${with_binary_version}"],[
83 AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
84 [Binary specific version])
85 ])
87 dnl Prevent clang from accepting unknown flags with a mere warning
88 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CFLAGS])
89 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CXXFLAGS])
91 dnl
92 dnl Check the operating system
93 dnl
94 HAVE_WIN64="0"
95 HAVE_IOS="0"
96 HAVE_OSX="0"
97 HAVE_TVOS="0"
99 case "${host_os}" in
100 "")
101 SYS=unknown
102 ;;
103 linux*)
104 SYS=linux
105 ;;
106 bsdi*)
107 SYS=bsdi
108 CFLAGS="${CFLAGS} -pthread"
109 ;;
110 freebsd*)
111 SYS=freebsd
112 CFLAGS="${CFLAGS} -pthread"
113 CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
114 LDFLAGS="${LDFLAGS} -L/usr/local/lib"
115 ac_cv_ld_z_defs=no
116 ;;
117 openbsd*)
118 SYS=openbsd
119 CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
120 LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
121 ;;
122 netbsd*)
123 SYS=netbsd
124 ;;
125 dragonfly*)
126 SYS=dragonfly
127 ;;
128 darwin*)
130 dnl Force gcc "-arch" flag
131 ARCH_flag=""
132 case "${host}" in
133 i?86*)
134 ARCH_flag="-arch i386"
135 ;;
136 ppc64*)
137 ARCH_flag="-arch ppc64"
138 ;;
139 ppc*)
140 ARCH_flag="-arch ppc"
141 ;;
142 x86_64*)
143 ARCH_flag="-arch x86_64"
144 ;;
145 arm*)
146 ac_cv_c_bigendian="no"
147 ac_cv_c_attribute_packed="no"
148 ;;
149 esac
151 SYS=darwin
152 CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
153 CXX="${CXX} -stdlib=libc++ -std=c++11"
154 CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
155 CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
156 OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
157 LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
158 VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
159 VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
161 AC_EGREP_CPP(yes,
162 [#import <TargetConditionals.h>
163 #if TARGET_OS_IPHONE
164 yes
165 #endif],
166 [HAVE_IOS="1"],
167 [HAVE_OSX="1"])
169 AC_EGREP_CPP(yes,
170 [#import <TargetConditionals.h>
171 #if TARGET_OS_TV
172 yes
173 #endif],
174 [HAVE_TVOS="1"
175 HAVE_IOS="0"
176 HAVE_OSX="0"
177 ],)
179 dnl
180 dnl Handle Mac OS X SDK flags
181 dnl
182 AC_ARG_WITH(macosx-sdk,
183 [AS_HELP_STRING([--with-macosx-sdk=DIR],
184 [compile using the SDK in DIR])])
185 if test "${with_macosx_sdk}" != "" ; then
186 test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
187 CPP="${CPP} -isysroot ${with_macosx_sdk}"
188 CC="${CC} -isysroot ${with_macosx_sdk}"
189 CXX="${CXX} -isysroot ${with_macosx_sdk}"
190 OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
191 LD="${LD} -syslibroot ${with_macosx_sdk}"
192 fi
193 AC_ARG_WITH(macosx-version-min,
194 [AS_HELP_STRING([--with-macosx-version-min=VERSION],
195 [compile for Mac OS X VERSION and above])])
196 if test "${with_macosx_version_min}" != "" ; then
197 CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
198 CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
199 CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
200 OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
201 LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
202 fi
203 ;;
204 *mingw32* | *cygwin* | *wince* | *mingwce*)
205 dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
206 dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
207 CXXFLAGS="${CXXFLAGS} -static-libgcc"
208 AC_CHECK_TOOL(WINDRES, windres, :)
209 AC_CHECK_TOOL(OBJCOPY, objcopy, :)
210 AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
211 AH_TOP([# define _WIN32_WINNT 0x0601 /* Windows 7 */])
212 AH_TOP([#endif])
213 AC_DEFINE([_WIN32_WINNT], 0x0601, [Define to '0x0601' for Windows 7 APIs.])
214 AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
215 AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
216 AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
217 AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
218 AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
219 AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
220 AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
221 AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
222 AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
223 AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
224 AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
226 case "${host_os}" in
227 *mingw32*)
228 SYS=mingw32
229 ;;
230 *cygwin*)
231 dnl Check if we are using the mno-cygwin mode in which case we are
232 dnl actually dealing with a mingw32 compiler.
233 AC_EGREP_CPP(yes,
234 [#ifdef _WIN32
235 yes
236 #endif],
237 SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
238 ;;
239 esac
241 if test "${SYS}" = "mingw32"; then
242 # DEP, ASLR, NO SEH
243 LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
245 AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
246 ac_default_prefix="`pwd`/_win32"
247 DESTDIR="`pwd`/_win32/"
249 dnl
250 dnl NSIS/MSI Installer prefix and WIN64
251 dnl
252 case "${host}" in
253 amd64*|x86_64*)
254 HAVE_WIN64="1"
255 WINDOWS_ARCH="x64"
256 PROGRAMFILES="PROGRAMFILES64"
257 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
258 ;;
259 *)
260 WINDOWS_ARCH="x86"
261 PROGRAMFILES="PROGRAMFILES"
262 ;;
263 esac
264 AC_SUBST(WINDOWS_ARCH)
265 AC_SUBST(PROGRAMFILES)
267 fi
268 ;;
269 *nto*)
270 SYS=nto
271 ;;
272 solaris*)
273 SYS=solaris
274 ;;
275 hpux*)
276 SYS=hpux
277 ;;
278 *os2*)
279 SYS=os2
280 LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
281 AC_LIBOBJ([freeaddrinfo])
282 AC_LIBOBJ([gai_strerror])
283 AC_CHECK_FUNCS([if_nametoindex])
284 ;;
285 *nacl*)
286 SYS=nacl
287 AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
288 AC_LIBOBJ([sigwait])
289 AC_LIBOBJ([recvmsg])
290 AC_LIBOBJ([sendmsg])
291 ;;
292 *)
293 SYS="${host_os}"
294 ;;
295 esac
297 dnl WinRT
298 AC_ARG_ENABLE(winstore_app,
299 AS_HELP_STRING([--enable-winstore-app],
300 [Build targetted for Windows Store apps (default disabled)]))
302 vlc_winstore_app=0
303 AS_IF([test "${SYS}" = "mingw32"],[
304 LIBCOM="-lole32"
305 AS_IF([test "${enable_winstore_app}" = "yes"], [
306 vlc_winstore_app=1
307 LIBCOM=""
308 VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
309 AC_LIBOBJ([gai_strerror])
310 ],[])
311 AC_SUBST(LIBCOM)
312 ])
313 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
315 AM_CONDITIONAL(HAVE_LINUX, test "${SYS}" = "linux")
316 AM_CONDITIONAL(HAVE_OS2, test "${SYS}" = "os2")
318 AM_CONDITIONAL(HAVE_DARWIN, test "${SYS}" = "darwin")
319 AM_CONDITIONAL(HAVE_IOS, test "${HAVE_IOS}" = "1")
320 AM_CONDITIONAL(HAVE_OSX, test "${HAVE_OSX}" = "1")
321 AM_CONDITIONAL(HAVE_TVOS, test "${HAVE_TVOS}" = "1")
323 AM_CONDITIONAL(HAVE_NACL, test "${SYS}" = "nacl")
324 AM_CONDITIONAL(HAVE_LIBANL, test "${HAVE_LIBANL}" = "1")
326 AM_CONDITIONAL(HAVE_WIN32, test "${SYS}" = "mingw32")
327 AM_CONDITIONAL(HAVE_WIN64, test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
328 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
329 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
331 dnl
332 dnl Sadly autoconf does not think about testing foo.exe when ask to test
333 dnl for program foo on win32
334 case "${build_os}" in
335 cygwin|msys|mingw32)
336 ac_executable_extensions=".exe"
337 BUILDEXEEXT=".exe"
338 ;;
339 os2*)
340 BUILDEXEEXT=".exe"
341 ;;
342 *)
343 ;;
344 esac
345 AC_SUBST(BUILDEXEEXT)
347 dnl Android is linux, but a bit different
348 AS_IF([test "$SYS" = linux],[
349 AC_MSG_CHECKING([for an Android system])
350 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
351 [[#ifndef __ANDROID__
352 # error Not Android
353 #endif
354 ]],[[;]])
355 ],[
356 HAVE_ANDROID="1"
357 AC_MSG_RESULT([yes])
358 ],[
359 AC_MSG_RESULT([no])
360 ])
361 ])
362 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
364 dnl Tizen (minimum SDK version: 2.3)
365 AS_IF([test "$SYS" = linux],[
366 AC_MSG_CHECKING([for Tizen])
367 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
368 [[#include <tizen.h>
369 ]],[[;]])
370 ],[
371 HAVE_TIZEN="1"
372 AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
373 AC_MSG_RESULT([yes])
374 ],[
375 AC_MSG_RESULT([no])
376 ])
377 ])
378 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
380 dnl
381 dnl Check for the contrib directory
382 dnl
383 AC_ARG_WITH(contrib,
384 [AS_HELP_STRING([--with-contrib[=DIR]],
385 [search for 3rd party libraries in DIR/include and DIR/lib])
386 ])
387 AC_MSG_CHECKING([for 3rd party libraries path])
388 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
389 CONTRIB_DIR="${srcdir}/contrib/${host}"
390 AS_IF([test ! -d "${CONTRIB_DIR}"], [
391 echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
392 CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
393 AS_IF([test ! -d "${CONTRIB_DIR}"], [
394 echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
395 CONTRIB_DIR=""
396 AC_MSG_RESULT([not found])
397 ])
398 ])
399 ], [
400 AS_IF([test "${with_contrib}" != "no"], [
401 CONTRIB_DIR="${with_contrib}"
402 ], [
403 CONTRIB_DIR=""
404 AC_MSG_RESULT([disabled])
405 ])
406 ])
407 AS_IF([test -n "${CONTRIB_DIR}"], [
408 AS_IF([test -d "${CONTRIB_DIR}/lib"],[
409 CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
410 ], [
411 echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
412 CONTRIB_DIR=""
413 AC_MSG_RESULT([not usable])
414 ])
416 ])
417 AS_IF([test -n "${CONTRIB_DIR}"], [
418 AC_MSG_RESULT([${CONTRIB_DIR}])
419 CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
420 CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
421 CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
422 OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
423 export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
424 LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
426 AS_IF([test -z "$LUAC"], [
427 dnl Old contribs mixed cross-tools and cross-compiled executables
428 AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
429 LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
430 ])
432 dnl Newer contribs follow usual name space rules
433 AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
434 LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
435 ])
436 ])
438 AS_IF([test "${SYS}" = "darwin"], [
439 export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
440 export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
441 ])
442 ], [
443 AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
444 AC_MSG_ERROR([Third party libraries not found!])
445 ])
446 ])
447 AC_SUBST(CONTRIB_DIR)
449 dnl Add extras/tools to the PATH
450 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
451 AS_IF([test -d "${TOOLS_DIR}"], [
452 TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
453 export PATH="${TOOLS_DIR}":$PATH
454 ])
456 dnl
457 dnl Libtool
458 dnl It's very bad, but our former custom system was worst
459 dnl -- Courmisch
460 dnl
462 dnl override platform specific check for dependent libraries
463 dnl otherwise libtool linking of shared libraries will
464 dnl fail on anything other than pass_all.
465 AC_CACHE_VAL(lt_cv_deplibs_check_method,
466 [lt_cv_deplibs_check_method=pass_all])
468 LT_INIT([dlopen win32-dll shared disable-static])
469 LT_LANG([C++])
470 LT_LANG([Windows Resource])
472 DOLT
474 lt_cv_deplibs_check_method=pass_all
476 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
477 AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
478 ])
480 dnl
481 dnl Gettext stuff
482 dnl
483 AM_GNU_GETTEXT_VERSION([0.19.8])
484 AM_GNU_GETTEXT([external], [need-formatstring-macros])
486 dnl
487 dnl Iconv stuff
488 dnl
489 AM_ICONV
491 dnl
492 dnl checks for mingw
493 AS_IF([test "${SYS}" = "mingw32"], [
495 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
496 #if !defined(__MINGW32__)
497 # error Not compiling with mingw
498 #endif
499 ])], [
501 dnl Check for broken versions of mingw-runtime compatability library
502 AC_MSG_CHECKING(for broken mingw-runtime)
503 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
504 #include <_mingw.h>
505 #if defined(__MINGW64_VERSION_MAJOR)
506 # if __MINGW64_VERSION_MAJOR < 5
507 # error Update your mingw-w64! This one is too old.
508 # endif
509 #else
510 # error You cannot compile with Mingw. Use Mingw-w64!
511 #endif
512 ])], [
513 AC_MSG_RESULT([ok])
514 ], [
515 AC_MSG_RESULT([present])
516 AC_MSG_ERROR([LibVLC requires Mingw-w64 version 5.0 or higher!])
517 ])
519 dnl force use of mingw provided c99 *printf over msvcrt
520 CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
522 dnl Check for the need to include the mingwex lib for mingw32
523 VLC_SAVE_FLAGS
524 AC_CHECK_LIB(mingwex,opendir,
525 AC_CHECK_LIB(mingw32,opendir,,
526 [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
527 )
528 VLC_RESTORE_FLAGS
529 ], [
530 AC_MSG_RESULT([Not compiling with mingw])
531 ])
533 dnl Check for fnative-struct or mms-bitfields support for mingw32
534 AX_CHECK_COMPILE_FLAG([-mms-bitfields], [
535 AX_APPEND_FLAG([-mms-bitfields], [CFLAGS])
536 AX_APPEND_FLAG([-mms-bitfields], [CXXFLAGS])
537 # Check for the warning flag without "-Wno-", GCC accepts
538 # -Wno-<anything> for unsupported warnings, which can trigger
539 # other warnings instead.
540 AX_CHECK_COMPILE_FLAG([-Wincompatible-ms-struct], [
541 AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CFLAGS])
542 AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CXXFLAGS])
543 ])
544 ], [
545 AX_CHECK_COMPILE_FLAG([-fnative-struct], [
546 AX_APPEND_FLAG([-fnative-struct], [CFLAGS])
547 AX_APPEND_FLAG([-fnative-struct], [CXXFLAGS])
548 ])
549 ])
550 ])
553 dnl
554 dnl Buggy glibc prevention. Purposedly not cached.
555 dnl See sourceware.org bugs 5058 and 5443.
556 dnl Ubuntu alone has 20 bug numbers for this...
557 dnl
558 AC_MSG_CHECKING(for buggy GNU/libc versions)
559 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
560 #include <limits.h>
561 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
562 && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
563 # error GNU/libc with dcgettext killer bug!
564 #endif
565 ])], [
566 AC_MSG_RESULT([not present])
567 ], [
568 AC_MSG_RESULT([found])
569 AS_IF([test "x${enable_nls}" != "xno"], [
570 AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
571 work-around for this. Check with your distribution vendor on how to update the
572 glibc run-time. Alternatively, build with --disable-nls.])
573 ])
574 ])
576 dnl Plugin compilation stuff
578 VLC_LIBRARY_SUFFIX
580 dnl Check for system libs needed
581 need_libc=false
583 dnl Check for usual libc functions
584 AC_CHECK_FUNCS([accept4 daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty memalign mkostemp mmap open_memstream newlocale openat pipe2 pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp strptime uselocale])
585 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir flockfile fsync getdelim getpid lldiv memrchr nrand48 poll recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tdestroy tfind timegm timespec_get strverscmp pathconf])
586 AC_REPLACE_FUNCS([gettimeofday])
587 AC_CHECK_FUNC(fdatasync,,
588 [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
589 ])
591 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
593 dnl mingw64 implements those as static inline, not functions with C linkage
594 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
595 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
596 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
597 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
599 dnl C11 static_assert()
600 AC_MSG_CHECKING([for static_assert in assert.h])
601 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
602 static_assert(1, "The impossible happened.");
603 ])], [
604 AC_MSG_RESULT([yes])
605 AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
606 ], [
607 AC_MSG_RESULT([no])
608 ])
610 # Windows CE does not have strcoll()
611 AC_FUNC_STRCOLL
613 dnl Check for non-standard system calls
614 case "$SYS" in
615 "linux")
616 AC_CHECK_FUNCS([eventfd vmsplice sched_getaffinity recvmmsg memfd_create])
617 ;;
618 "mingw32")
619 AC_CHECK_FUNCS([_lock_file])
620 ;;
621 esac
623 AH_BOTTOM([#include <vlc_fixups.h>])
625 dnl Check for struct pollfd
626 AC_CHECK_TYPES([struct pollfd],,,
627 [#include <sys/types.h>
628 #if HAVE_POLL
629 # include <poll.h>
630 #elif defined (_WIN32)
631 # include <winsock2.h>
632 #endif
633 ])
635 dnl Check for struct timespec
636 AC_CHECK_TYPES([struct timespec],,,
637 [#include <time.h>])
639 dnl Check for max_align_t
640 AC_CHECK_TYPES([max_align_t],,,
641 [#include <stddef.h>])
643 dnl Checks for socket stuff
644 VLC_SAVE_FLAGS
645 SOCKET_LIBS=""
646 AC_SEARCH_LIBS(connect, [socket], [
647 AS_IF([test "$ac_cv_search_connect" != "none required"], [
648 SOCKET_LIBS="$ac_cv_search_connect"
649 ])
650 ], [
651 AS_IF([test "${SYS}" = "mingw32"], [
652 SOCKET_LIBS="-lws2_32 -liphlpapi"
653 ])
654 ])
656 AC_SEARCH_LIBS([inet_pton], [nsl], [
657 AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
658 SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
659 ])
660 ],, [${SOCKET_LIBS}])
662 LIBS="${LIBS} ${SOCKET_LIBS}"
663 AC_LINK_IFELSE([
664 AC_LANG_PROGRAM([#ifdef _WIN32
665 #include <ws2tcpip.h>
666 #include <windows.h>
667 # if _WIN32_WINNT < 0x600
668 # error Needs vista+
669 # endif
670 #else
671 #include <sys/socket.h>
672 #include <arpa/inet.h>
673 #endif], [
674 char dst[[sizeof(struct in_addr)]];
675 inet_pton(AF_INET, "127.0.0.1", dst);
676 ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
677 AC_CHECK_FUNCS([if_nameindex])
678 VLC_RESTORE_FLAGS
679 AC_SUBST(SOCKET_LIBS)
681 dnl Check for socklen_t
682 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
683 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
684 ac_cv_type_socklen_t,
685 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
686 [#include <sys/types.h>
687 #ifdef _WIN32
688 # include <winsock2.h>
689 # include <ws2tcpip.h>
690 #else
691 # include <sys/socket.h>
692 #endif]], [[socklen_t len; len = 0;]])],
693 ac_cv_type_socklen_t=yes,
694 ac_cv_type_socklen_t=no)])
695 AS_IF([test "$ac_cv_type_socklen_t" = no],
696 [AC_DEFINE(socklen_t, int)])
698 dnl Check for struct sockaddr_storage
699 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
700 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
701 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
702 [AC_TRY_COMPILE(
703 [#include <sys/types.h>
704 #if defined( _WIN32 )
705 # include <winsock2.h>
706 #else
707 # include <sys/socket.h>
708 #endif], [struct sockaddr_storage addr;],
709 ac_cv_struct_sockaddr_storage=yes,
710 ac_cv_struct_sockaddr_storage=no)])
711 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
712 AC_DEFINE(sockaddr_storage, sockaddr)
713 AC_DEFINE(ss_family, sa_family)
714 ])
716 dnl FreeBSD has a gnugetopt library for this:
717 GNUGETOPT_LIBS=""
718 AC_CHECK_FUNC(getopt_long,, [
719 AC_CHECK_LIB([gnugetopt],[getopt_long], [
720 GNUGETOPT_LIBS="-lgnugetopt"
721 ])
722 ])
723 AC_SUBST(GNUGETOPT_LIBS)
725 AC_CHECK_LIB(m,cos,[
726 LIBM="-lm"
727 ], [
728 LIBM=""
729 ])
730 AC_SUBST(LIBM)
732 AC_CHECK_LIB(m,lrintf, [
733 AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
734 VLC_ADD_LIBS([skins2],[-lm])
735 ])
736 AC_CHECK_LIB(m,nanf,
737 AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
738 )
739 AC_CHECK_LIB(m,sincos, [
740 AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
741 ], [
742 AC_LIBOBJ([sincos])
743 ])
745 AC_MSG_CHECKING([_Thread_local support])
746 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
747 int main() {}])], [
748 AC_MSG_RESULT([ok])
749 AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
750 ],[ AC_MSG_RESULT([no])])
752 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
753 dnl check for its availability explicitely
754 AC_CHECK_HEADERS([threads.h])
756 AC_CHECK_LIB([anl],[getaddrinfo_a],[
757 AC_DEFINE(HAVE_LIBANL, 1, [Define to 1 if you have the anl library])
758 ])
760 dnl Check for dynamic plugins
761 LIBDL=""
762 have_dynamic_objects="no"
763 VLC_SAVE_FLAGS
764 AC_SEARCH_LIBS(dlsym, [dl svld], [
765 AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
766 LIBDL="$ac_cv_search_dlsym"
767 ])
768 have_dynamic_objects="yes"
769 ])
770 VLC_RESTORE_FLAGS
772 # Windows
773 AS_IF([test "${SYS}" = "mingw32"], [
774 LIBDL=""
775 have_dynamic_objects="yes" #assume we can use shared objects
776 ])
778 AC_ARG_WITH([libfuzzer],
779 [AS_HELP_STRING([--with-libfuzzer=DIR],
780 [use libFuzzer library from DIR and triggers sanitize coverage (default disabled)])],
781 [],
782 [with_libfuzzer=no])
783 AS_VAR_IF(with_libfuzzer, no, [], [
784 enable_shared=no
785 enable_static=yes
786 enable_vlc=no
787 ])
788 AM_CONDITIONAL(HAVE_LIBFUZZER, [test "${with_libfuzzer}" != "no"])
790 AS_IF([test "${enable_shared}" = "no"], [
791 have_dynamic_objects=no
792 ])
793 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
795 AC_SUBST(LIBDL)
797 dnl Check for thread library
798 LIBPTHREAD=""
799 AS_IF([test "${SYS}" != "mingw32"], [
800 VLC_SAVE_FLAGS
801 LIBS=""
802 AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
803 AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
804 LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
805 ])
806 ])
807 VLC_RESTORE_FLAGS
808 ])
809 AC_SUBST(LIBPTHREAD)
811 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
812 AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
813 LIBRT="$ac_cv_search_clock_nanosleep"
814 ])
815 ], [
816 AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
817 AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
818 LIBRT="$ac_cv_search_nanosleep"
819 ])
820 ])
821 ])
822 AC_SUBST(LIBRT)
824 dnl
825 dnl Check for headers
826 dnl
828 dnl POSIX
829 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
830 AC_CHECK_HEADERS([net/if.h], [], [],
831 [
832 #include <sys/types.h>
833 #include <sys/socket.h>
834 ])
835 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
836 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
838 dnl BSD
839 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
841 dnl GNU/Linux
842 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
844 dnl MacOS
845 AC_CHECK_HEADERS([xlocale.h])
847 dnl Check if C++ headers define locale_t
848 AC_LANG_PUSH(C++)
849 AC_CACHE_CHECK([if C++ headers define locale_t],
850 [ac_cv_cxx_locale_t],
851 [ac_cv_cxx_locale_t=no
852 AC_TRY_COMPILE([#include <locale>], [locale_t loc;],
853 [ac_cv_cxx_locale_t=yes])])
854 if test "${ac_cv_cxx_locale_t}" != "no"; then
855 AC_DEFINE(HAVE_CXX_LOCALE_T, 1, Define to 1 if C++ headers define locale_t)
856 fi
857 AC_LANG_POP(C++)
859 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
860 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
861 AC_CHECK_TYPE(ssize_t,, [
862 AC_DEFINE(ssize_t, int)
863 ])
865 dnl It seems that autoconf detects pkg-config only during the first
866 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
867 dnl it is nested within a conditional block, so it was not working right.
868 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
869 AC_ARG_VAR(PKG_CONFIG_PATH,
870 [Paths where to find .pc not at the default location])
871 PKG_PROG_PKG_CONFIG()
873 dnl On some OS we need static linking
874 AS_IF([test -n "${PKG_CONFIG}" ],[
875 AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
876 PKG_CONFIG="${PKG_CONFIG} --static"
877 ])
878 ])
881 dnl
882 dnl Check for zlib.h and -lz along with system -lminizip if available
883 dnl
884 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
885 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
886 if test "${have_zlib}" = "yes"
887 then
888 VLC_ADD_LIBS([sap],[-lz])
889 PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
890 AC_CHECK_HEADERS([unzip.h], [
891 have_minizip=yes
892 MINIZIP_LIBS="-lminizip -lz"
893 ], [
894 have_minizip=no
895 ])
896 ])
897 fi
898 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
901 dnl
902 dnl Domain name i18n support via GNU libidn
903 dnl
904 PKG_CHECK_MODULES([IDN], [libidn], [
905 have_libidn="yes"
906 AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
907 ], [
908 have_libidn="no"
909 ])
912 dnl Check for dbus
913 AC_ARG_ENABLE(dbus,
914 [AS_HELP_STRING([--enable-dbus],
915 [compile D-Bus message bus support (default enabled)])])
916 have_dbus="no"
917 AS_IF([test "${enable_dbus}" != "no"], [
918 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
919 have_dbus="yes"
920 ], [
921 AS_IF([test -n "${enable_dbus}"], [
922 AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
923 ], [
924 AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
925 ])
926 ])
927 ])
928 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
931 dnl Check for systemd
932 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
933 have_systemd="yes"
934 ], [
935 AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
936 ])
937 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
940 EXTEND_HELP_STRING([Optimization options:])
941 dnl
942 dnl Compiler warnings
943 dnl
945 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CFLAGS])
946 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CXXFLAGS])
948 AX_APPEND_COMPILE_FLAGS([-Wbad-function-cast -Wwrite-strings -Wmissing-prototypes -Werror-implicit-function-declaration -Winit-self -Wlogical-op -Wshadow=local -Wmultistatement-macros], [CFLAGS])
949 AX_APPEND_COMPILE_FLAGS([-pipe], [CFLAGS])
951 dnl
952 dnl Debugging mode
953 dnl
954 AC_ARG_ENABLE(debug,
955 [AS_HELP_STRING([--enable-debug],
956 [build with run-time assertions (default disabled)])],,
957 [enable_debug="no"])
958 AH_TEMPLATE(NDEBUG,
959 [Define to 1 if debug code should NOT be compiled])
960 AS_IF([test "${enable_debug}" != "no"], [
961 AC_CHECK_HEADERS([valgrind/valgrind.h])
962 ], [
963 AC_DEFINE(NDEBUG)
964 ])
966 dnl
967 dnl Profiling
968 dnl
969 AC_ARG_ENABLE(gprof,
970 [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
971 [enable_gprof="no"])
972 AS_IF([test "${enable_gprof}" != "no"], [
973 CFLAGS="${CFLAGS} -pg"
974 CXXFLAGS="${CXXFLAGS} -pg"
975 OBJCFLAGS="${OBJCFLAGS} -pg"
976 LDFLAGS="${LDFLAGS} -pg"
977 ])
979 AC_ARG_ENABLE(cprof,
980 [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
981 [enable_cprof="no"])
982 AS_IF([test "${enable_gprof}" != "no"], [
983 CFLAGS="${CFLAGS} -finstrument-functions"
984 CXXFLAGS="${CXXFLAGS} -finstrument-functions"
985 OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
986 LDFLAGS="${LDFLAGS} -finstrument-functions"
987 ])
989 dnl
990 dnl Test coverage
991 dnl
992 AC_ARG_ENABLE(coverage,
993 [AS_HELP_STRING([--enable-coverage],
994 [build for test coverage (default disabled)])],,
995 [enable_coverage="no"])
996 AS_IF([test "${enable_coverage}" != "no"], [
997 CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
998 CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
999 LDFLAGS="-lgcov ${LDFLAGS}"
1000 ])
1002 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
1003 VLC_SAVE_FLAGS
1004 CFLAGS="${CFLAGS} -fvisibility=hidden"
1005 CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
1006 OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
1007 AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
1008 [ac_cv_c_visibility_hidden], [
1009 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1010 ac_cv_c_visibility_hidden=yes
1011 ], [
1012 ac_cv_c_visibility_hidden=no
1013 ])
1014 ])
1015 AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1016 ])
1018 dnl
1019 dnl Sanitizer flags
1020 dnl
1021 AC_ARG_WITH([sanitizer],
1022 [AS_HELP_STRING([--with-sanitizer=(address/memory/undefined/thread)],
1023 [build with sanitizer flags (default disabled)])],
1024 [],
1025 [with_sanitizer=no])
1027 AS_VAR_IF(with_sanitizer, no, [], [
1028 AX_CHECK_COMPILE_FLAG([-fsanitize=${with_sanitizer}], [
1029 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}])
1030 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [CXXFLAGS])
1031 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [LDFLAGS])
1032 ], [
1033 AC_MSG_ERROR(["-fsanitize=${with_sanitizer} not supported!"])
1034 ])
1035 AX_APPEND_FLAG([-g])
1036 AX_APPEND_FLAG([-g], [CXXFLAGS])
1038 AS_IF([test -z "${with_sanitizer##*address*}" ], [
1039 AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer])
1040 AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer], [CXXFLAGS])
1041 ])
1042 AS_IF([test -z "${with_sanitizer##*memory*}" ], [
1043 AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1044 AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1045 ])
1046 AS_IF([test -z "${with_sanitizer##*thread*}" ], [
1047 AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1048 AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1049 ])
1050 ])
1052 dnl
1053 dnl Enable/disable optimizations
1054 dnl
1055 AC_ARG_ENABLE(optimizations,
1056 [AS_HELP_STRING([--disable-optimizations],
1057 [disable compiler optimizations (default enabled)])],,
1058 [enable_optimizations="yes"])
1060 dnl Check for various optimization flags
1061 AS_IF([test "${enable_optimizations}" != "no"], [
1063 dnl -O3 only in production builds
1064 AS_IF([test "${enable_debug}" = "no"], [
1065 VLC_SAVE_FLAGS
1066 CFLAGS="${CFLAGS} -O3"
1067 CXXFLAGS="${CXXFLAGS} -O3"
1068 OBJCFLAGS="${OBJCFLAGS} -O3"
1069 AC_CACHE_CHECK([if $CC accepts -O3], [ac_cv_c_o3], [
1070 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1071 ac_cv_c_o3=yes
1072 ], [
1073 ac_cv_c_o3=no
1074 ])
1075 ])
1076 AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1077 ])
1079 dnl Check for fast maths
1080 AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CFLAGS])
1081 AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CXXFLAGS])
1083 AH_BOTTOM([
1084 #if defined(_MSC_VER) && !defined(__clang__)
1085 # pragma fenv_access(off)
1086 # pragma fp_contract(on)
1087 #elif defined(__GNUC__)
1088 /* Not supported so far */
1089 #else
1090 # pragma STDC FENV_ACCESS OFF
1091 # pragma STDC FP_CONTRACT ON
1092 #endif
1093 ])
1095 dnl Check for -funroll-loops
1096 VLC_SAVE_FLAGS
1097 CFLAGS="${CFLAGS} -funroll-loops"
1098 CXXFLAGS="${CXXFLAGS} -funroll-loops"
1099 OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1100 AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1101 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1102 ac_cv_c_unroll_loops=yes
1103 ], [
1104 ac_cv_c_unroll_loops=no
1105 ])
1106 ])
1107 AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1109 AS_IF([test "$enable_debug" = "no"], [
1110 dnl Check for -fomit-frame-pointer
1111 VLC_SAVE_FLAGS
1112 CFLAGS="${CFLAGS} -fomit-frame-pointer"
1113 CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1114 OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1115 AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1116 [ac_cv_c_omit_frame_pointer], [
1117 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1118 ac_cv_c_omit_frame_pointer=yes
1119 ], [
1120 ac_cv_c_omit_frame_pointer=no
1121 ])
1122 ])
1123 AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1124 ])
1126 ])
1128 AC_ARG_ENABLE(ssp, [
1129 AS_HELP_STRING([--disable-ssp],
1130 [disable stack smashing protection (default enabled for optimized builds)])
1131 ],,[enable_ssp="yes"])
1133 AS_IF([test "${enable_ssp}" != "no" -a "${enable_optimizations}" != "no"], [
1134 VLC_SAVE_FLAGS
1135 AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong])
1136 AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong], [CXXFLAGS])
1137 dnl Win32 requires linking to ssp for stack-protection
1138 AS_IF([test "${SYS}" = "mingw32"], [
1139 LDFLAGS="${LDFLAGS} -lssp"
1140 AS_IF([test "${vlc_winstore_app}" != 1], [LDFLAGS="${LDFLAGS} -ladvapi32"])
1141 AC_CACHE_CHECK([if linker supports stack protectors], [ac_cv_ld_ssp], [
1142 AC_TRY_LINK([#include <stdio.h>],[char buf[100]; fgets(buf, sizeof(buf), stdin);], [
1143 ac_cv_ld_ssp="yes"
1144 ], [
1145 ac_cv_ld_ssp="no"
1146 ])
1147 ])
1148 AS_IF([test "${ac_cv_ld_ssp}" = "no"], [VLC_RESTORE_FLAGS])
1149 ])
1150 ])
1152 VLC_SAVE_FLAGS
1153 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1154 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1155 AC_TRY_LINK([],, [
1156 ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1157 ], [
1158 ac_cv_ld_bsymbolic=""
1159 ])
1160 ])
1161 VLC_RESTORE_FLAGS
1162 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1163 AC_SUBST(SYMBOLIC_LDFLAGS)
1165 VLC_SAVE_FLAGS
1166 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1167 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1168 AC_TRY_LINK([],, [
1169 ac_cv_ld_z_defs="yes"
1170 ], [
1171 ac_cv_ld_z_defs="no"
1172 ])
1173 ])
1174 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1176 dnl Check for __attribute__((packed))
1177 AC_CACHE_CHECK([for __attribute__((packed))],
1178 [ac_cv_c_attribute_packed],
1179 [ac_cv_c_attribute_packed=no
1180 AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1181 [ac_cv_c_attribute_packed=yes])])
1182 if test "${ac_cv_c_attribute_packed}" != "no"; then
1183 AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1184 fi
1186 dnl
1187 dnl Check the CPU
1188 dnl
1189 case "${host_cpu}" in
1190 "")
1191 ARCH=unknown
1192 ;;
1193 armv*)
1194 ARCH="arm"
1195 host_cpu="arm"
1196 ;;
1197 *)
1198 ARCH="${host_cpu}"
1199 ;;
1200 esac
1202 dnl Check for backtrace() support
1203 AC_CHECK_HEADERS(execinfo.h)
1204 AC_CHECK_FUNCS(backtrace)
1206 dnl
1207 dnl default modules
1208 dnl
1209 ALIASES="${ALIASES} cvlc rvlc"
1211 dnl
1212 dnl Accelerated modules
1213 dnl
1215 dnl Check for fully working MMX intrinsics
1216 dnl We need support for -mmmx, we need <mmintrin.h>, and we also need a
1217 dnl working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1218 AC_ARG_ENABLE(mmx,
1219 [AS_HELP_STRING([--disable-mmx],
1220 [disable MMX optimizations (default auto)])],,[
1221 case "${host_cpu}" in
1222 i?86|x86_64)
1223 enable_mmx="yes"
1224 ;;
1225 *)
1226 enable_mmx="no"
1227 ;;
1228 esac
1229 ])
1230 have_mmx="no"
1231 have_mmxext="no"
1232 AS_IF([test "${enable_mmx}" != "no"], [
1233 ARCH="${ARCH} mmx"
1234 VLC_SAVE_FLAGS
1235 CFLAGS="${CFLAGS} -mmmx"
1236 AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1237 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1238 [#include <mmintrin.h>
1239 #include <stdint.h>
1240 uint64_t frobzor;]], [
1241 [__m64 a, b, c;
1242 a = b = c = (__m64)frobzor;
1243 a = _mm_slli_pi16(a, 3);
1244 a = _mm_adds_pi16(a, b);
1245 c = _mm_srli_pi16(c, 8);
1246 c = _mm_slli_pi16(c, 3);
1247 b = _mm_adds_pi16(b, c);
1248 a = _mm_unpacklo_pi8(a, b);
1249 frobzor = (uint64_t)a;]])], [
1250 ac_cv_c_mmx_intrinsics=yes
1251 ], [
1252 ac_cv_c_mmx_intrinsics=no
1253 ])
1254 ])
1255 VLC_RESTORE_FLAGS
1256 AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1257 AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1258 ])
1260 VLC_SAVE_FLAGS
1261 CFLAGS="${CFLAGS} -mmmx"
1262 AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1263 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1264 void *p;
1265 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1266 ]])
1267 ], [
1268 ac_cv_mmx_inline=yes
1269 ], [
1270 ac_cv_mmx_inline=no
1271 ])
1272 ])
1273 AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1274 AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1275 have_mmx="yes"
1276 ])
1278 AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1279 [ac_cv_mmxext_inline], [
1280 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1281 void *p;
1282 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1283 ]])
1284 ], [
1285 ac_cv_mmxext_inline=yes
1286 ], [
1287 ac_cv_mmxext_inline=no
1288 ])
1289 ])
1290 VLC_RESTORE_FLAGS
1291 AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1292 AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1293 have_mmxext="yes"
1294 ])
1295 ])
1296 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1297 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1299 dnl Check for fully workin SSE2 intrinsics
1300 dnl We need support for -mmmx, we need <emmintrin.h>, and we also need a
1301 dnl working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1302 AC_ARG_ENABLE(sse,
1303 [AS_HELP_STRING([--disable-sse],
1304 [disable SSE (1-4) optimizations (default auto)])],, [
1305 case "${host_cpu}" in
1306 i?86|x86_64)
1307 enable_sse=yes
1308 ;;
1309 *)
1310 enable_sse=no
1311 ;;
1312 esac
1313 ])
1314 have_sse2="no"
1315 AS_IF([test "${enable_sse}" != "no"], [
1316 ARCH="${ARCH} sse sse2"
1318 VLC_SAVE_FLAGS
1319 CFLAGS="${CFLAGS} -msse2"
1320 AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1321 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1322 [#include <emmintrin.h>
1323 #include <stdint.h>
1324 uint64_t frobzor;]], [
1325 [__m128i a, b, c;
1326 a = b = c = _mm_set1_epi64((__m64)frobzor);
1327 a = _mm_slli_epi16(a, 3);
1328 a = _mm_adds_epi16(a, b);
1329 c = _mm_srli_epi16(c, 8);
1330 c = _mm_slli_epi16(c, 3);
1331 b = _mm_adds_epi16(b, c);
1332 a = _mm_unpacklo_epi8(a, b);
1333 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1334 ac_cv_c_sse2_intrinsics=yes
1335 ], [
1336 ac_cv_c_sse2_intrinsics=no
1337 ])
1338 ])
1339 VLC_RESTORE_FLAGS
1340 AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1341 AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1342 ])
1344 VLC_SAVE_FLAGS
1345 CFLAGS="${CFLAGS} -msse"
1346 AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1347 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1348 void *p;
1349 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1350 ]])
1351 ], [
1352 ac_cv_sse_inline=yes
1353 ], [
1354 ac_cv_sse_inline=no
1355 ])
1356 ])
1358 AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1359 AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1360 ])
1362 AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1363 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1364 void *p;
1365 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1366 ]])
1367 ], [
1368 ac_cv_sse2_inline=yes
1369 ], [
1370 ac_cv_sse2_inline=no
1371 ])
1372 ])
1373 AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1374 AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1375 have_sse2="yes"
1376 ])
1378 # SSE3
1379 AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1380 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1381 void *p;
1382 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1383 ]])
1384 ], [
1385 ac_cv_sse3_inline=yes
1386 ], [
1387 ac_cv_sse3_inline=no
1388 ])
1389 ])
1391 AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1392 AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1393 # SSSE3
1394 AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1395 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1396 void *p;
1397 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1398 ]])
1399 ], [
1400 ac_cv_ssse3_inline=yes
1401 ], [
1402 ac_cv_ssse3_inline=no
1403 ])
1404 ])
1406 AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1407 AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1409 # SSE4.1
1410 AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1411 [ac_cv_sse4_1_inline], [
1412 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1413 void *p;
1414 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1415 ]])
1416 ], [
1417 ac_cv_sse4_1_inline=yes
1418 ], [
1419 ac_cv_sse4_1_inline=no
1420 ])
1421 ])
1423 AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1424 AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1426 # SSE4.2
1427 AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1428 [ac_cv_sse4_2_inline], [
1429 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1430 void *p;
1431 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1432 ]])
1433 ], [
1434 ac_cv_sse4_2_inline=yes
1435 ], [
1436 ac_cv_sse4_2_inline=no
1437 ])
1438 ])
1440 AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1441 AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1443 # SSE4A
1444 AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1445 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1446 void *p;
1447 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1448 ]])
1449 ], [
1450 ac_cv_sse4a_inline=yes
1451 ], [
1452 ac_cv_sse4a_inline=no
1453 ])
1454 ])
1455 VLC_RESTORE_FLAGS
1456 AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1457 AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1458 ])
1459 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1461 VLC_SAVE_FLAGS
1462 CFLAGS="${CFLAGS} -mmmx"
1463 have_3dnow="no"
1464 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1465 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1466 void *p;
1467 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1468 ]])
1469 ], [
1470 ac_cv_3dnow_inline=yes
1471 ], [
1472 ac_cv_3dnow_inline=no
1473 ])
1474 ])
1475 VLC_RESTORE_FLAGS
1476 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1477 AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1478 [Define to 1 if 3D Now! inline assembly is available.])
1479 have_3dnow="yes"
1480 ])
1481 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1484 AC_ARG_ENABLE(neon,
1485 [AS_HELP_STRING([--disable-neon],
1486 [disable NEON optimizations (default auto)])],, [
1487 AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1488 ])
1489 AS_IF([test "${enable_neon}" != "no"], [
1490 VLC_SAVE_FLAGS
1491 CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1492 AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1493 AC_COMPILE_IFELSE([
1494 AC_LANG_PROGRAM(,[[
1495 asm volatile("vqmovun.s64 d0, q1":::"d0");
1496 ]])
1497 ], [
1498 ac_cv_arm_neon="yes"
1499 ], [
1500 ac_cv_arm_neon="no"
1501 ])
1502 ])
1503 VLC_RESTORE_FLAGS
1504 ])
1505 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1507 AC_ARG_ENABLE(arm64,
1508 [AS_HELP_STRING([--disable-arm64],
1509 [disable arm 64-bit optimizations (default auto)])],, [
1510 AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1511 ])
1512 AS_IF([test "${enable_arm64}" != "no"], [
1513 AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1514 AC_COMPILE_IFELSE([
1515 AC_LANG_PROGRAM(,[[
1516 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1517 ]])
1518 ], [
1519 ac_cv_arm64="yes"
1520 ], [
1521 ac_cv_arm64="no"
1522 ])
1523 ])
1524 ])
1525 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1528 AC_ARG_ENABLE(altivec,
1529 [AS_HELP_STRING([--disable-altivec],
1530 [disable AltiVec optimizations (default auto)])],, [
1531 AS_CASE("${host_cpu}", [powerpc*],
1532 [enable_altivec=yes], [enable_altivec=no])
1533 ])
1534 have_altivec="no"
1535 ALTIVEC_CFLAGS=""
1536 AS_IF([test "${enable_altivec}" = "yes"], [
1537 ARCH="${ARCH} altivec";
1538 VLC_SAVE_FLAGS
1539 AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1540 [ac_cv_altivec_inline],
1541 [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1542 ac_cv_altivec_inline="yes",
1543 [CFLAGS="${CFLAGS} -Wa,-maltivec"
1544 AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1545 [ac_cv_altivec_inline="-Wa,-maltivec"],
1546 ac_cv_altivec_inline=no)
1547 ])])
1548 VLC_RESTORE_FLAGS
1549 AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1550 AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1551 [Define to 1 if AltiVec inline assembly is available.])
1552 AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1553 ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1554 VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1555 ])
1556 have_altivec="yes"
1557 ])
1559 VLC_SAVE_FLAGS
1560 AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1561 [ac_cv_c_altivec], [
1562 CFLAGS="${CFLAGS} -maltivec"
1563 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1564 [#include <altivec.h>]], [
1565 [vec_ld(0, (unsigned char *)0);]])], [
1566 ac_cv_c_altivec="-maltivec"
1567 ], [
1568 ac_cv_c_altivec="no"
1569 ])
1570 ])
1571 VLC_RESTORE_FLAGS
1572 AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1573 CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1574 AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1575 VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1576 ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1577 VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1578 have_altivec="yes"
1579 ])
1580 AC_CHECK_HEADERS(altivec.h)
1582 VLC_SAVE_FLAGS
1583 LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1584 AC_CACHE_CHECK([if linker needs -framework vecLib],
1585 [ac_cv_ld_altivec],
1586 [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1587 VLC_RESTORE_FLAGS
1588 AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1589 VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1590 ])
1591 ])
1592 AC_SUBST(ALTIVEC_CFLAGS)
1593 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1595 dnl
1596 dnl Memory usage
1597 dnl
1598 AC_ARG_ENABLE(optimize-memory,
1599 [AS_HELP_STRING([--enable-optimize-memory],
1600 [optimize memory usage over performance])])
1601 if test "${enable_optimize_memory}" = "yes"; then
1602 AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1603 fi
1605 dnl
1606 dnl Allow running as root (useful for people running on embedded platforms)
1607 dnl
1608 AC_ARG_ENABLE(run-as-root,
1609 [AS_HELP_STRING([--enable-run-as-root],
1610 [allow running VLC as root (default disabled)])])
1611 AS_IF([test "${enable_run_as_root}" = "yes"],[
1612 AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1613 [Define to 1 to allow running VLC as root (uid 0).])
1614 ])
1616 dnl
1617 dnl Stream output
1618 dnl
1619 AC_ARG_ENABLE(sout,
1620 [AS_HELP_STRING([--disable-sout],
1621 [disable streaming output (default enabled)])])
1622 AS_IF([test "${enable_sout}" != "no"], [
1623 AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1624 ])
1625 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1627 dnl Lua modules
1628 AC_ARG_ENABLE(lua,
1629 [AS_HELP_STRING([--disable-lua],
1630 [disable LUA scripting support (default enabled)])])
1631 if test "${enable_lua}" != "no"
1632 then
1633 PKG_CHECK_MODULES(LUA, lua5.2,
1634 [ have_lua=yes ],
1635 [
1636 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1638 PKG_CHECK_MODULES(LUA, lua5.1,
1639 [ have_lua=yes ],
1640 [
1641 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1642 PKG_CHECK_MODULES(LUA, lua >= 5.1,
1643 [ have_lua=yes ],
1644 [
1645 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1646 have_lua=yes
1647 AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1648 [],
1649 [ have_lua=no ] )
1650 AC_CHECK_LIB( lua5.2 , luaL_newstate,
1651 [LUA_LIBS="-llua5.2"],
1652 AC_CHECK_LIB( lua5.1 , luaL_newstate,
1653 [LUA_LIBS="-llua5.1"],
1654 AC_CHECK_LIB( lua51 , luaL_newstate,
1655 [LUA_LIBS="-llua51"],
1656 AC_CHECK_LIB( lua , luaL_newstate,
1657 [LUA_LIBS="-llua"],
1658 [ have_lua=no
1659 ], [-lm])
1660 )))
1661 ])
1662 ])
1663 ])
1664 if test "x${have_lua}" != "xyes" ; then
1665 AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1666 fi
1667 AC_ARG_VAR([LUAC], [LUA byte compiler])
1668 AS_IF([test -z "$LUAC"], [
1669 AC_CHECK_TOOL(LUAC, [luac], [false])
1670 ])
1671 AS_IF([test "${LUAC}" = "false"], [
1672 AC_MSG_ERROR([Could not find the LUA byte compiler.])
1673 ])
1674 AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1675 AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1676 ])
1677 fi
1678 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1681 dnl
1682 dnl VideoLAN manager
1683 dnl
1684 AC_ARG_ENABLE(vlm,
1685 [AS_HELP_STRING([--disable-vlm],
1686 [disable the stream manager (default enabled)])],,
1687 [enable_vlm="${enable_sout}"])
1688 AS_IF([test "${enable_vlm}" != "no"], [
1689 AS_IF([test "${enable_sout}" = "no"], [
1690 AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1691 ])
1692 AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1693 ])
1694 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1697 dnl
1698 dnl Addons manager storage and repositories modules
1699 dnl
1700 AC_ARG_ENABLE(addonmanagermodules,
1701 [AS_HELP_STRING([--disable-addonmanagermodules],
1702 [disable the addons manager modules (default enabled)])])
1703 if test "${enable_addonmanagermodules}" != "no"
1704 then
1705 AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1706 fi
1707 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1710 dnl
1711 dnl Input plugins
1712 dnl
1714 EXTEND_HELP_STRING([Input plugins:])
1716 dnl
1717 dnl libarchive access module
1718 dnl
1719 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1721 dnl
1722 dnl live555 input
1723 dnl
1724 AC_ARG_ENABLE(live555,
1725 [AS_HELP_STRING([--enable-live555],
1726 [enable RTSP input through live555 (default enabled)])])
1728 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1729 PKG_CHECK_MODULES(LIVE555, live555, [
1730 VLC_ADD_PLUGIN([live555])
1731 VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1732 VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1733 ], [
1734 AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1736 AC_LANG_PUSH(C++)
1737 VLC_SAVE_FLAGS
1739 dnl detect include paths
1740 AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1741 CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1742 ], [
1743 AS_IF([test "${SYS}" != "os2"], [
1744 LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1745 CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1746 ], [
1747 LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1748 CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1749 LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1750 ])
1751 ])
1753 dnl CPP Flags
1754 AS_IF([test "${SYS}" = "solaris"], [
1755 CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1756 ])
1757 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1758 LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1760 dnl version check
1761 AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1762 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1763 [#include <liveMedia_version.hh>
1764 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1765 # error BOOM
1766 #endif]])
1767 ], [
1768 ac_cv_live555="yes"
1769 ], [
1770 ac_cv_live555="no"
1771 ])
1772 ])
1774 AS_IF([test "$ac_cv_live555" = "no"], [
1775 AC_MSG_WARN([live555 is missing or its installed version is too old:
1776 Version 2011.12.23 or later is required to proceed.
1777 You can get an updated one from http://www.live555.com/liveMedia .])
1778 AS_IF([test -n "${enable_live555}"], [
1779 AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1780 ])
1781 ], [
1782 other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1783 other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1784 AS_IF([test "${SYS}" = "mingw32"], [
1785 # add ws2_32 for closesocket, select, recv
1786 other_libs="$other_libs -lws2_32"
1787 ])
1789 dnl We need to check for pic because live555 don't provide shared libs
1790 dnl and we want to build a plugins so we need -fPIC on some arch.
1791 VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1792 VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1793 AC_CHECK_LIB(liveMedia_pic, main, [
1794 VLC_ADD_PLUGIN([live555])
1795 VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1796 ],[
1797 AC_CHECK_LIB(liveMedia, main, [
1798 VLC_ADD_PLUGIN([live555])
1799 VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1800 ],[],[${other_libs}])
1801 ],[${other_libs_pic}])
1802 ])
1803 VLC_RESTORE_FLAGS
1804 AC_LANG_POP(C++)
1805 ])
1806 ])
1808 dnl
1809 dnl IIDC and DV FireWire input modules
1810 dnl
1811 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1812 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1814 dnl
1815 dnl - linsys modules: access module check for libzvbi
1816 dnl
1817 AC_ARG_ENABLE(linsys,
1818 [AS_HELP_STRING([--enable-linsys],
1819 [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1820 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1821 VLC_ADD_PLUGIN([linsys_hdsdi])
1822 PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1823 VLC_ADD_PLUGIN([linsys_sdi])
1824 ], [
1825 AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1826 ])
1827 ])
1829 dnl
1830 dnl dvdread module: check for libdvdread
1831 dnl
1832 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1834 dnl
1835 dnl libdvdnav plugin
1836 dnl
1837 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1838 AS_IF([test "${enable_dvdnav}" != "no"], [
1839 AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1840 AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1841 AC_MSG_RESULT(yes)
1842 AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1843 ],[
1844 AC_MSG_RESULT(no)
1845 ])
1846 ])
1848 dnl
1849 dnl Blu-ray Disc Support with libbluray
1850 dnl
1851 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1853 dnl
1854 dnl OpenCV wrapper and example filters
1855 dnl
1856 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1859 dnl
1860 dnl libsmbclient plugin
1861 dnl
1862 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smbc], [smbclient], (SMB/CIFS support), [auto])
1864 dnl
1865 dnl liBDSM access module
1866 dnl
1867 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1869 dnl
1870 dnl sftp access support
1871 dnl
1872 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1874 dnl
1875 dnl nfs access support
1876 dnl
1877 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1879 dnl
1880 dnl Video4Linux 2
1881 dnl
1882 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1883 [disable Video4Linux version 2 (default auto)])])
1884 have_v4l2="no"
1885 AS_IF([test "$enable_v4l2" != "no"], [
1886 AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1887 have_v4l2="yes"
1888 ])
1889 ])
1890 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1892 dnl
1893 dnl special access module for Blackmagic SDI cards
1894 dnl
1895 AC_ARG_ENABLE(decklink,
1896 [AS_HELP_STRING([--disable-decklink],
1897 [disable Blackmagic DeckLink SDI input (default auto)])])
1898 AC_ARG_WITH(decklink_sdk,
1899 [AS_HELP_STRING[--with-decklink-sdk=DIR],
1900 [ location of Blackmagic DeckLink SDI SDK])])
1901 have_decklink=no
1902 if test "${enable_decklink}" != "no"
1903 then
1904 if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1905 then
1906 VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1907 fi
1908 VLC_SAVE_FLAGS
1909 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1910 AC_LANG_PUSH(C++)
1911 AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1912 have_decklink=yes
1913 ], [
1914 AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1915 ])
1916 AC_LANG_POP(C++)
1917 VLC_RESTORE_FLAGS
1918 fi
1919 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1922 dnl
1923 dnl Built-in CD-DA and VCD module
1924 dnl
1925 AC_ARG_ENABLE(vcd,
1926 [AS_HELP_STRING([--disable-vcd],
1927 [disable built-in VCD and CD-DA support (default enabled)])])
1929 AC_ARG_ENABLE(libcddb,
1930 [AS_HELP_STRING([--disable-libcddb],
1931 [disable CDDB for Audio CD (default enabled)])])
1933 if test "${enable_vcd}" != "no"
1934 then
1935 AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1936 AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1937 AC_MSG_RESULT(yes)
1938 VLC_ADD_PLUGIN([vcd cdda])
1939 ],[
1940 AC_MSG_RESULT(no)
1941 ])
1943 AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1944 AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1945 AC_MSG_RESULT(yes)
1946 VLC_ADD_PLUGIN([vcd cdda])
1947 AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1948 ],[
1949 AC_MSG_RESULT(no)
1950 ])
1952 AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1953 AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1954 AC_MSG_RESULT(yes)
1955 VLC_ADD_PLUGIN([vcd cdda])
1956 AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1957 ],[
1958 AC_MSG_RESULT(no)
1959 ])
1961 if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1962 then
1963 VLC_ADD_PLUGIN([vcd cdda])
1964 fi
1966 if test "$enable_libcddb" != "no"; then
1967 PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1968 HAVE_LIBCDDB=yes
1969 AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1970 VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1971 VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1972 ],:
1973 [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1974 HAVE_LIBCDDB=no])
1975 fi
1976 fi
1978 dnl
1979 dnl Linux DVB
1980 dnl
1981 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1982 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1983 [#include <linux/dvb/version.h>
1984 #if (DVB_API_VERSION < 5)
1985 # error Linux DVB API v3.2 and older are not supported.
1986 #endif
1987 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1988 # error Linux DVB API v5.0 is unsupported. Please update.
1989 #endif
1990 ]])], [
1991 ac_cv_linux_dvb_5_1=yes
1992 ], [
1993 ac_cv_linux_dvb_5_1=no
1994 ])])
1995 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1997 dnl
1998 dnl Screen capture module
1999 dnl
2000 AC_ARG_ENABLE(screen,
2001 [AS_HELP_STRING([--enable-screen],
2002 [disable screen capture (default enabled)])])
2003 if test "${enable_screen}" != "no"; then
2004 if test "${SYS}" = "darwin"; then
2005 AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
2006 VLC_ADD_PLUGIN([screen])
2007 ])
2008 fi
2009 fi
2010 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
2012 dnl
2013 dnl VNC/RFB access module
2014 dnl
2015 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
2017 dnl RDP/Remote Desktop access module
2018 dnl
2019 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
2021 dnl
2022 dnl Real RTSP plugin
2023 dnl
2024 AC_ARG_ENABLE(realrtsp,
2025 [ --enable-realrtsp Real RTSP module (default disabled)])
2026 if test "${enable_realrtsp}" = "yes"; then
2027 VLC_ADD_PLUGIN([access_realrtsp])
2028 fi
2030 dnl
2031 dnl QTKit
2032 AC_ARG_ENABLE(macosx-qtkit,
2033 [ --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
2034 if test "x${enable_macosx_qtkit}" != "xno" &&
2035 (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
2036 then
2037 AC_CHECK_HEADERS(QTKit/QTKit.h, [
2038 VLC_ADD_PLUGIN([qtsound])
2039 ])
2040 fi
2042 dnl
2043 dnl AVFoundation
2044 AC_SUBST(have_avfoundation, ["no"])
2045 AC_ARG_ENABLE(macosx-avfoundation,
2046 [ --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
2047 if test "x${enable_macosx_avfoundation}" != "xno" &&
2048 (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2049 then
2050 SAVED_LIBS="${LIBS}"
2051 LIBS="-framework AVFoundation"
2052 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2053 LIBS="${SAVED_LIBS}"
2054 if test "${have_avfoundation}" != "no"
2055 then
2056 VLC_ADD_PLUGIN([avcapture])
2057 fi
2058 fi
2059 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2061 dnl
2062 dnl DCP plugin (using asdcplib)
2063 dnl
2064 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2065 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2067 dnl
2068 dnl Demux plugins
2069 dnl
2071 EXTEND_HELP_STRING([Mux/Demux plugins:])
2073 dnl
2074 dnl libdvbpsi check for ts mux/demux
2075 dnl
2076 have_dvbpsi="no"
2077 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2078 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2081 dnl
2082 dnl GME demux plugin
2083 dnl
2084 AC_ARG_ENABLE(gme,
2085 [AS_HELP_STRING([--enable-gme],
2086 [use Game Music Emu (default auto)])])
2087 AS_IF([test "${enable_gme}" != "no"], [
2088 AC_CHECK_HEADER([gme/gme.h], [
2089 AC_CHECK_LIB([gme], [gme_identify_header], [
2090 VLC_ADD_PLUGIN([gme])
2091 ], [
2092 AC_CHECK_LIB([gme], [gme_identify_extension], [
2093 VLC_ADD_LIBS([gme], [-lstdc++ $LIBM])
2094 VLC_ADD_PLUGIN([gme])
2095 ],, [-lstdc++ $LIBM])
2096 ])
2097 VLC_ADD_LIBS([gme], [-lgme])
2098 ], [
2099 AS_IF([test "x${enable_gme}" != "x"], [
2100 AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2101 ])
2102 ])
2103 ])
2106 dnl
2107 dnl SIDPlay plugin
2108 dnl
2109 AC_ARG_ENABLE(sid,
2110 [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2111 AS_IF([test "${enable_sid}" != "no"], [
2112 PKG_CHECK_MODULES(SID, [libsidplay2], [
2113 AC_LANG_PUSH(C++)
2114 oldCPPFLAGS="$CPPFLAGS"
2115 CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2116 AC_CHECK_HEADER([sidplay/builders/resid.h], [
2117 VLC_ADD_PLUGIN([sid])
2118 VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2119 VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2120 ], [
2121 AS_IF([test -n "${enable_sid}"],
2122 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2123 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2124 )
2125 ])
2126 CPPFLAGS="$oldCPPFLAGS"
2127 AC_LANG_POP(C++)
2128 ], [
2129 AS_IF([test "x${enable_sid}" = "xyes"],
2130 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2131 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2132 )
2133 ])
2134 ])
2137 dnl
2138 dnl ogg demux plugin
2139 dnl
2140 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2141 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2142 AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2143 ],[true])
2144 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2145 if test "${enable_sout}" != "no"; then
2146 dnl Check for libshout
2147 PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2148 fi
2150 dnl
2151 dnl matroska demux plugin
2152 dnl
2153 PKG_WITH_MODULES([MATROSKA], [libebml libmatroska], [
2154 VLC_ADD_PLUGIN([mkv])
2155 VLC_ADD_CFLAGS([mkv], [$MATROSKA_CFLAGS])
2156 VLC_ADD_LIBS([mkv], [$MATROSKA_LIBS])
2157 have_matroska="yes"
2158 ],,[MKV format support], [auto])
2159 AM_CONDITIONAL([HAVE_MATROSKA], [test "${have_matroska}" = "yes"])
2161 dnl
2162 dnl modplug demux plugin
2163 dnl
2164 AC_ARG_ENABLE(mod,
2165 [AS_HELP_STRING([--disable-mod],
2166 [do not use libmodplug (default auto)])])
2167 if test "${enable_mod}" != "no" ; then
2168 PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2169 VLC_ADD_PLUGIN([mod])
2170 VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2171 VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2172 VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2173 ],[
2174 AS_IF([test -n "${enable_mod}"],
2175 [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2176 [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2177 ])
2178 fi
2180 dnl
2181 dnl mpc demux plugin
2182 dnl
2183 AC_ARG_ENABLE(mpc,
2184 [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2185 if test "${enable_mpc}" != "no"
2186 then
2187 AC_CHECK_HEADERS([mpc/mpcdec.h], [
2188 VLC_ADD_PLUGIN([mpc])
2189 VLC_ADD_LIBS([mpc],[-lmpcdec])],
2190 [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2191 VLC_ADD_PLUGIN([mpc])
2192 VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2193 fi
2195 dnl
2196 dnl Codec plugins
2197 dnl
2199 EXTEND_HELP_STRING([Codec plugins:])
2201 dnl
2202 dnl wmafixed plugin
2203 dnl
2204 AC_ARG_ENABLE(wma-fixed,
2205 [ --enable-wma-fixed libwma-fixed module (default disabled)])
2206 if test "${enable_wma_fixed}" = "yes"
2207 then
2208 VLC_ADD_PLUGIN([wma_fixed])
2209 fi
2211 dnl
2212 dnl shine encoder plugin
2213 dnl
2214 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2217 dnl
2218 dnl openmax il codec plugin
2219 dnl
2220 AC_ARG_ENABLE(omxil,
2221 [ --enable-omxil openmax il codec module (default disabled)])
2222 if test "${enable_omxil}" = "yes"
2223 then
2224 VLC_ADD_PLUGIN([omxil])
2225 fi
2227 dnl
2228 dnl raspberry pi openmax il configuration
2229 dnl
2230 AC_ARG_ENABLE(rpi-omxil,
2231 [ --enable-rpi-omxil openmax il configured for raspberry pi (default disabled)])
2232 if test "${enable_rpi_omxil}" = "yes"
2233 then
2234 VLC_ADD_PLUGIN([omxil])
2235 VLC_ADD_CFLAGS([omxil],[-DRPI_OMX])
2236 fi
2238 dnl
2239 dnl CrystalHD codec plugin
2240 dnl
2241 AC_ARG_ENABLE(crystalhd,
2242 [ --enable-crystalhd crystalhd codec plugin (default auto)])
2243 if test "${enable_crystalhd}" != "no"; then
2244 AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2245 VLC_ADD_PLUGIN([crystalhd])
2246 VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2247 ],[
2248 if test "${SYS}" = "mingw32" ; then
2249 AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2250 VLC_ADD_PLUGIN([crystalhd])
2251 AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2252 VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2253 ])
2254 ],[
2255 AS_IF([test x"${enable_crystalhd}" = "xyes"],
2256 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2257 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2258 ],[#define __LINUX_USER__
2259 #include <libcrystalhd/bc_dts_types.h>
2260 ])
2261 fi
2262 ],[
2263 #include <libcrystalhd/bc_dts_types.h>
2264 ])
2265 fi
2267 dnl
2268 dnl mad plugin
2269 dnl
2270 have_mad="no"
2271 MAD_CFLAGS=""
2272 MAD_LIBS=""
2274 AC_ARG_WITH(mad, [ --with-mad=PATH path to libmad], [
2275 enable_mad="yes"
2276 ], [
2277 with_mad="no"
2278 ])
2279 AS_IF([test "${with_mad}" != "no"], [
2280 MAD_CFLAGS="-I${with_mad}/include"
2281 MAD_LIBS="-L${with_mad}/lib"
2282 ])
2284 AC_ARG_ENABLE(mad,
2285 [ --enable-mad libmad module (default enabled)])
2286 AS_IF([test "${enable_mad}" != "no"], [
2287 VLC_SAVE_FLAGS
2288 CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2289 LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2290 AC_CHECK_HEADERS(mad.h, [
2291 AC_CHECK_LIB(mad, mad_bit_init, [
2292 have_mad="yes"
2293 MAD_LIBS="${MAD_LIBS} -lmad"
2294 ])
2295 ])
2296 VLC_RESTORE_FLAGS
2297 AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2298 AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2299 ])
2300 ])
2301 AC_SUBST(MAD_CFLAGS)
2302 AC_SUBST(MAD_LIBS)
2303 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2305 dnl mpg123 plugin
2306 dnl
2307 dnl
2308 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2310 dnl
2311 dnl gstreamer stuff
2312 dnl
2313 AC_ARG_ENABLE(gst-decode,
2314 [ --enable-gst-decode GStreamer based decoding support (currently supports only video decoding) (default auto)])
2316 have_gst_decode="no"
2317 AS_IF([test "${enable_gst_decode}" != "no"], [
2318 PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2319 PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2320 have_gst_decode="yes"
2321 ], [
2322 AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2323 ])
2324 ], [
2325 AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2326 ])
2327 ])
2328 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2330 dnl
2331 dnl avcodec decoder/encoder plugin
2332 dnl
2333 AC_ARG_ENABLE(merge-ffmpeg,
2334 [ --enable-merge-ffmpeg merge FFmpeg-based plugins (default disabled)],, [
2335 enable_merge_ffmpeg="no"
2336 ])
2337 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2339 AC_MSG_CHECKING([for libavutil variant])
2340 PKG_CHECK_EXISTS([libavutil], [
2341 libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2342 libavutil_micro="${libavutil_version##*.}"
2343 AS_IF([test ${libavutil_micro} -le 99], [
2344 avfork="libav"
2345 ], [
2346 avfork="ffmpeg"
2347 ])
2348 ], [
2349 avfork="none"
2350 ])
2351 AC_MSG_RESULT([${avfork}])
2353 AC_ARG_ENABLE(avcodec,
2354 [ --enable-avcodec libavcodec codec (default enabled)])
2355 AS_IF([test "${enable_avcodec}" != "no"], [
2356 dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2357 case "${avfork}" in
2358 libav) av_codec_ver="57.16.0" ;;
2359 ffmpeg) av_codec_ver="57.37.100" ;;
2360 *) AC_MSG_ERROR([Missing libav or FFmpeg. Pass --disable-avcodec to ignore this error.])
2361 esac
2362 PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2363 VLC_SAVE_FLAGS
2364 CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2365 CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2366 AC_CHECK_HEADERS(libavcodec/avcodec.h)
2367 AC_CHECK_HEADERS(libavutil/avutil.h)
2368 VLC_RESTORE_FLAGS
2369 have_avcodec="yes"
2370 ],[
2371 AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2372 ])
2373 ], [
2374 have_avcodec="no"
2375 ])
2376 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2378 dnl
2379 dnl libva needs avcodec
2380 dnl
2381 AC_ARG_ENABLE(libva,
2382 [ --enable-libva VAAPI GPU decoding support (libVA) (default auto)])
2384 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2385 AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2386 ])
2388 have_vaapi="no"
2389 have_vaapi_drm="no"
2390 have_vaapi_x11="no"
2391 have_vaapi_wl="no"
2392 AS_IF([test "${enable_libva}" != "no"], [
2393 PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2394 have_vaapi="yes"
2395 ], [
2396 AS_IF([test -n "${enable_libva}"], [
2397 AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2398 ], [
2399 AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2400 ])
2401 ])
2402 PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2403 have_vaapi_drm="yes"
2404 ], [
2405 AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2406 ])
2407 PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2408 have_vaapi_x11="yes"
2409 ], [
2410 AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2411 ])
2412 PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2413 have_vaapi_wl="yes"
2414 ], [
2415 AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2416 ])
2417 ])
2418 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2419 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2420 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2421 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2423 have_avcodec_vaapi="no"
2424 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2425 VLC_SAVE_FLAGS
2426 CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2427 CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2428 AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2429 AC_MSG_NOTICE([VA API acceleration activated])
2430 have_avcodec_vaapi="yes"
2431 ],[
2432 AS_IF([test -n "${enable_libva}"], [
2433 AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2434 ], [
2435 AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2436 ])
2437 ])
2438 VLC_RESTORE_FLAGS
2439 ])
2440 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2442 dnl
2443 dnl dxva2 needs avcodec
2444 dnl
2445 AC_ARG_ENABLE(dxva2,
2446 [ --enable-dxva2 DxVA2 GPU decoding support (default auto)])
2448 have_avcodec_dxva2="no"
2449 AS_IF([test "${enable_dxva2}" != "no"], [
2450 if test "${SYS}" = "mingw32"; then
2451 AS_IF([test "x${have_avcodec}" = "xyes"], [
2452 AC_CHECK_HEADERS(dxva2api.h,
2453 [
2454 AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2455 AC_MSG_NOTICE([DxVA2 acceleration activated])
2456 have_avcodec_dxva2="yes"
2457 ],[
2458 AS_IF([test "${enable_dxva2}" = "yes"],
2459 [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2460 [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2461 ], [#undef _WIN32_WINNT
2462 /* DXVA2 is only available in Vista and above */
2463 #define _WIN32_WINNT 0x600])
2464 ],[
2465 AS_IF([test "${enable_dxva2}" = "yes"],
2466 [AC_MSG_ERROR([Could not find required dxva2api.h])],
2467 [AC_MSG_WARN([dxva2api.h not found])])
2468 ],[#include <d3d9.h>])
2469 ],[
2470 AS_IF([test "x${enable_dxva2}" != "x"], [
2471 AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2472 ])
2473 ])
2474 fi
2475 ])
2476 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2478 dnl
2479 dnl d3d11va needs avcodec
2480 dnl
2481 AC_ARG_ENABLE(d3d11va,
2482 [ --enable-d3d11va D3D11 GPU decoding support (default auto)])
2484 have_avcodec_d3d11va="no"
2485 AS_IF([test "${enable_d3d11va}" != "no"], [
2486 if test "${SYS}" = "mingw32"; then
2487 AS_IF([test "x${have_avcodec}" = "xyes"], [
2488 AC_CHECK_TYPES([ID3D11VideoDecoder],
2489 [
2490 AC_CHECK_HEADERS(dxva2api.h,
2491 [
2492 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2493 AC_MSG_NOTICE([D3D11 acceleration activated])
2494 AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2495 have_avcodec_d3d11va="yes"
2496 ],[
2497 AS_IF([test "${enable_d3d11va}" = "yes"],
2498 [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2499 [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2500 ], [#undef _WIN32_WINNT
2501 /* D3D11 is only available in Vista and above */
2502 #define _WIN32_WINNT 0x600])
2503 ],[
2504 AS_IF([test "${enable_d3d11va}" = "yes"],
2505 [AC_MSG_ERROR([Could not find required dxva2api.h])],
2506 [AC_MSG_WARN([dxva2api.h not found])])
2507 ],[#include <d3d9.h>])
2508 ],[
2509 AS_IF([test "${enable_d3d11va}" = "yes"],
2510 [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2511 [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2512 ], [#include <d3d11.h>])
2513 ],[
2514 AS_IF([test "x${enable_d3d11va}" != "x"], [
2515 AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2516 ])
2517 ])
2518 fi
2519 ])
2520 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2522 dnl
2523 dnl DXGI debug
2524 dnl
2525 AC_CHECK_HEADERS(dxgidebug.h dxgi1_6.h)
2527 dnl
2528 dnl avformat demuxer/muxer plugin
2529 dnl
2531 AC_ARG_ENABLE(avformat,
2532 [ --enable-avformat libavformat containers (default enabled)],, [
2533 enable_avformat="${have_avcodec}"
2534 ])
2535 have_avformat="no"
2536 AS_IF([test "${enable_avformat}" != "no"], [
2537 PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2538 have_avformat="yes"
2539 VLC_SAVE_FLAGS
2540 CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2541 CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2542 AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2543 AC_CHECK_HEADERS(libavcodec/avcodec.h)
2544 AC_CHECK_HEADERS(libavutil/avutil.h)
2545 AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2546 have_avformat="no"
2547 ])
2548 VLC_RESTORE_FLAGS
2549 ],[
2550 AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2551 ])
2552 ])
2553 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2555 dnl
2556 dnl swscale image scaling and conversion plugin
2557 dnl
2559 AC_ARG_ENABLE(swscale,
2560 AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2561 (default enabled)]))
2562 if test "${enable_swscale}" != "no"
2563 then
2564 PKG_CHECK_MODULES(SWSCALE,[libswscale],
2565 [
2566 VLC_SAVE_FLAGS
2567 CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2568 CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2569 AC_CHECK_HEADERS(libswscale/swscale.h)
2570 AC_CHECK_HEADERS(libavutil/avutil.h)
2571 VLC_ADD_PLUGIN([swscale])
2572 VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2573 VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2574 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2575 VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2576 ])
2577 VLC_RESTORE_FLAGS
2578 ],[
2579 AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2580 ])
2581 fi
2583 dnl
2584 dnl postproc plugin
2585 dnl
2587 AC_ARG_ENABLE(postproc,
2588 [ --enable-postproc libpostproc image post-processing (default auto)])
2589 if test "${enable_postproc}" != "no"
2590 then
2591 PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2592 [
2593 VLC_SAVE_FLAGS
2594 CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2595 CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2596 AC_CHECK_HEADERS(postproc/postprocess.h)
2597 VLC_ADD_PLUGIN([postproc])
2598 VLC_RESTORE_FLAGS
2599 ],[
2600 AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2601 ])
2602 fi
2604 dnl
2605 dnl faad decoder plugin
2606 dnl
2607 AC_ARG_ENABLE(faad,
2608 [ --enable-faad faad codec (default auto)])
2609 have_faad="no"
2610 AS_IF([test "${enable_faad}" != "no"], [
2611 AC_CHECK_HEADERS([neaacdec.h], [
2612 AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2614 AS_IF([test "${have_faad}" = "yes"], [
2615 VLC_ADD_PLUGIN([faad])
2616 VLC_ADD_LIBS([faad],[-lfaad])
2617 ], [
2618 AS_IF([test "${enable_faad}" = "yes"], [
2619 AC_MSG_ERROR([cannot find FAAD library])
2620 ], [
2621 AC_MSG_WARN([cannot find FAAD library])
2622 ])
2623 ])
2624 ])
2625 ])
2627 dnl
2628 dnl AOM decoder plugin
2629 dnl
2630 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec (default auto)])
2632 dnl
2633 dnl libvpx decoder plugin
2634 dnl
2635 AC_ARG_ENABLE(vpx,
2636 AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2637 AS_IF([test "${enable_vpx}" != "no"],[
2638 PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2639 VLC_ADD_PLUGIN([vpx])
2640 VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2641 VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2642 AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2643 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2644 ], [], [${VPX_LIBS}])
2645 AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2646 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2647 ], [], [${VPX_LIBS}])
2648 AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2649 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2650 ], [], [${VPX_LIBS}])
2651 AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2652 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2653 ], [], [${VPX_LIBS}])
2654 ], [
2655 AS_IF([test "${enable_vpx}" = "yes"],[
2656 AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2657 ])])
2658 ])
2660 dnl
2661 dnl twolame encoder plugin
2662 dnl
2663 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2665 dnl
2666 dnl fdk-aac encoder plugin
2667 dnl
2668 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2671 dnl
2672 dnl A52/AC3 decoder plugin
2673 dnl
2674 AC_ARG_ENABLE(a52,
2675 [ --enable-a52 A/52 support with liba52 (default enabled)])
2676 if test "${enable_a52}" != "no"
2677 then
2678 AC_ARG_WITH(a52,
2679 [ --with-a52=PATH a52 headers and libraries])
2680 if test -z "${with_a52}"
2681 then
2682 LDFLAGS_test=""
2683 CPPFLAGS_test=""
2684 else
2685 LDFLAGS_test="-L${with_a52}/lib"
2686 CPPFLAGS_test="-I${with_a52}/include"
2687 fi
2688 VLC_SAVE_FLAGS
2689 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2690 LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2691 AC_CHECK_HEADERS(a52dec/a52.h, [
2692 AC_CHECK_LIB(a52, a52_free, [
2693 VLC_ADD_PLUGIN([a52])
2694 VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2695 VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2696 ],[
2697 AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2698 ], [$LIBM])
2699 ],[
2700 AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2701 ])
2702 VLC_RESTORE_FLAGS
2703 fi
2705 dnl
2706 dnl DTS Coherent Acoustics decoder plugin
2707 dnl
2708 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2710 dnl
2711 dnl Flac plugin
2712 dnl
2713 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2715 dnl
2716 dnl Libmpeg2 plugin
2717 dnl
2718 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2720 dnl
2721 dnl Vorbis plugin
2722 dnl
2723 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2725 dnl
2726 dnl Tremor plugin
2727 dnl
2728 AC_ARG_ENABLE(tremor,
2729 [ --enable-tremor Tremor decoder support (default disabled)])
2730 if test "${enable_tremor}" = "yes"
2731 then
2732 AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2733 VLC_ADD_PLUGIN([tremor])
2734 ],[])
2735 fi
2737 dnl
2738 dnl Speex plugins
2739 dnl
2740 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2741 have_speexdsp="no"
2742 AS_IF([test "${enable_speex}" != "no"], [
2743 PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2744 have_speexdsp="yes"
2745 ], [
2746 AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2747 ])
2748 ])
2749 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2751 dnl
2752 dnl Opus plugin
2753 dnl
2754 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2756 dnl
2757 dnl Ambisonic channel mixer and binauralizer plugin
2758 dnl
2759 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
2761 dnl
2762 dnl theora decoder plugin
2763 dnl
2764 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2766 dnl
2767 dnl OggSpots decoder plugin
2768 dnl
2769 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2771 dnl
2772 dnl Daala decoder plugin
2773 dnl
2774 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2776 dnl
2777 dnl schroedinger decoder plugin (for dirac format video)
2778 dnl
2779 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2781 dnl
2782 dnl PNG decoder module
2783 dnl
2784 AC_ARG_ENABLE(png,
2785 [ --enable-png PNG support (default enabled)])
2786 AS_IF([test "${enable_png}" != "no"], [
2787 AC_CHECK_HEADERS(png.h, [
2788 VLC_SAVE_FLAGS
2789 LDFLAGS="${LDFLAGS} -lz $LIBM"
2790 AC_CHECK_LIB(png, png_set_alpha_mode, [
2791 VLC_ADD_PLUGIN([png])
2792 ], [], [-lz $LIBM])
2793 VLC_RESTORE_FLAGS
2794 ])
2795 ])
2797 dnl
2798 dnl JPEG decoder module
2799 dnl
2800 AC_ARG_ENABLE(jpeg,
2801 [ --enable-jpeg JPEG support (default enabled)])
2802 AS_IF([test "${enable_jpeg}" != "no"], [
2803 AC_CHECK_HEADERS(jpeglib.h, [
2804 VLC_ADD_PLUGIN([jpeg])
2805 ])
2806 ])
2808 dnl
2809 dnl BPG decoder module
2810 dnl
2811 AC_ARG_ENABLE(bpg,
2812 [ --enable-bpg BPG support (default disabled)])
2813 AS_IF([test "${enable_bpg}" != "no"], [
2814 AC_CHECK_HEADERS(libbpg.h, [
2815 VLC_ADD_PLUGIN([bpg])
2816 ])
2817 ])
2819 dnl
2820 dnl H262 encoder plugin (lib262)
2821 dnl
2822 AC_ARG_ENABLE(x262,
2823 [ --enable-x262 H262 encoding support with static libx262 (default disabled)])
2824 if test "${enable_x262}" != "no"; then
2825 PKG_CHECK_MODULES(X262, x262, [
2826 VLC_ADD_PLUGIN([x262])
2827 VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2828 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2829 VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2830 ])
2831 VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2832 if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2833 VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2834 fi
2835 ], [
2836 if test "${enable_x262}" = "yes"; then
2837 AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2838 fi
2839 ])
2840 fi
2842 dnl x265 encoder
2843 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2845 dnl
2846 dnl H264 encoder plugin (using libx264)
2847 dnl
2848 AC_ARG_ENABLE(x264,
2849 [ --enable-x264 H264 encoding support with libx264 (default enabled)])
2850 if test "${enable_x264}" != "no"; then
2851 PKG_CHECK_MODULES(X264,x264 >= 0.148, [
2852 VLC_ADD_PLUGIN([x264])
2853 VLC_ADD_LIBS([x264],[${X264_LIBS}])
2855 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2856 VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2857 ])
2859 VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2860 if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2861 VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2862 fi
2863 ],[
2864 if test "${enable_x264}" = "yes"; then
2865 AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2866 fi
2867 ])
2868 fi
2870 dnl
2871 dnl H264 encoder plugin (libx264 > 153)
2872 dnl
2873 AC_ARG_ENABLE(x26410b,
2874 [ --enable-x26410b H264 10-bit encoding support with libx264 (default enabled)])
2875 if test "${enable_x26410b}" != "no"; then
2876 PKG_CHECK_MODULES(X26410b,x264 >= 0.153, [
2877 VLC_ADD_PLUGIN([x26410b])
2878 VLC_ADD_LIBS([x26410b],[${X264_LIBS}])
2880 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2881 VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2882 ])
2884 VLC_ADD_CFLAGS([x26410b],[${X264_CFLAGS}])
2885 if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2886 VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2887 fi
2888 ],[
2889 if test "${enable_x26410b}" = "yes"; then
2890 AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2891 fi
2892 ])
2893 fi
2896 dnl
2897 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2898 dnl
2899 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2901 dnl
2902 dnl libfluidsynth (MIDI synthetizer) plugin
2903 dnl
2904 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2905 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2906 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2908 dnl
2909 dnl Teletext Modules
2910 dnl vbi decoder plugin (using libzbvi)
2911 dnl telx module
2912 dnl uncompatible
2913 dnl
2914 AC_ARG_ENABLE(zvbi,
2915 AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2916 libzvbi (default enabled)]))
2917 AC_ARG_ENABLE(telx,
2918 AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2919 zvbi) (default enabled if zvbi is absent)]))
2921 AS_IF( [test "${enable_zvbi}" != "no"],[
2922 PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2923 [
2924 VLC_ADD_PLUGIN([zvbi])
2925 AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2926 AS_IF( [test "${enable_telx}" = "yes"],[
2927 AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2928 ])
2929 ],[
2930 AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2931 ])
2932 ])
2933 AS_IF( [test "${enable_telx}" != "no" ],[
2934 VLC_ADD_PLUGIN([telx])
2935 ])
2937 dnl
2938 dnl libass subtitle rendering module
2939 dnl
2940 AC_ARG_ENABLE(libass,
2941 [ --enable-libass Subtitle support using libass (default enabled)])
2942 AS_IF( [test "${enable_libass}" != "no"], [
2943 PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2944 [
2945 VLC_ADD_PLUGIN([libass])
2947 AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2948 [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2949 VLC_ADD_LIBS([libass],[-lfontconfig])
2950 ])
2951 ],[
2952 AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2953 ])
2954 ])
2956 dnl
2957 dnl ARIB subtitles rendering module
2958 dnl
2959 AC_ARG_ENABLE(aribsub,
2960 [ --enable-aribsub ARIB Subtitles support (default enabled)])
2961 AS_IF( [test "${enable_aribsub}" != "no" ],[
2962 PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2963 have_aribb24="yes"
2964 VLC_ADD_PLUGIN([aribsub])
2965 VLC_ADD_LIBS([aribsub],[-laribb24])
2966 AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2967 ],[
2968 AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2969 have_aribb24="no"
2970 ])
2971 ])
2972 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2974 dnl
2975 dnl ARIB B25
2976 dnl
2977 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2979 dnl
2980 dnl kate decoder plugin
2981 dnl
2982 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2984 dnl
2985 dnl tiger rendering for kate decoder plugin
2986 dnl
2987 AC_ARG_ENABLE(tiger,
2988 [ --enable-tiger Tiger rendering library for Kate streams (default auto)])
2989 AS_IF([test "${enable_tiger}" != "no"], [
2990 PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2991 AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2992 AS_IF([test -n "${enable_tiger}"], [
2993 AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2994 ])
2995 ])
2996 ])
2998 dnl
2999 dnl check if we can build the css selector engine
3000 dnl
3001 AC_ARG_ENABLE(css,
3002 [ --enable-css CSS selector engine (default auto)])
3003 AS_IF([test "${enable_css}" != "no"], [
3004 with_css="yes"
3005 AC_DEFINE(HAVE_CSS, 1, [Define if CSS engine is built])
3006 ])
3007 AM_CONDITIONAL([ENABLE_CSS], [test "${with_css}" = "yes"])
3010 dnl
3011 dnl Video plugins
3012 dnl
3014 EXTEND_HELP_STRING([Video plugins:])
3016 dnl
3017 dnl OpenGL
3018 dnl
3019 PKG_CHECK_MODULES([EGL], [egl], [
3020 have_egl="yes"
3021 ], [
3022 have_egl="no"
3023 ])
3024 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3026 have_gl="no"
3027 PKG_CHECK_MODULES([GL], [gl], [
3028 have_gl="yes"
3029 ], [
3030 AC_MSG_CHECKING([for OpenGL])
3031 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3032 #ifdef _WIN32
3033 # include <GL/glew.h>
3034 #endif
3035 #include <GL/gl.h>
3036 ]], [
3037 [int t0 = GL_TEXTURE0;]])
3038 ], [
3039 GL_CFLAGS=""
3040 have_gl="yes"
3041 AS_IF([test "${SYS}" != "mingw32"], [
3042 GL_LIBS="-lGL"
3043 ], [
3044 GL_LIBS="-lopengl32"
3045 ])
3046 ])
3047 AC_MSG_RESULT([${have_gl}])
3048 ])
3049 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3051 dnl OpenGL ES 2: depends on EGL 1.1
3052 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3054 dnl
3055 dnl Xlib
3056 dnl
3058 AC_PATH_XTRA()
3059 AC_CHECK_HEADERS(X11/Xlib.h)
3061 dnl
3062 dnl X C Bindings modules
3063 dnl
3064 AC_ARG_ENABLE(xcb,
3065 [ --enable-xcb X11 support with XCB (default enabled)],, [
3066 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3067 enable_xcb="yes"
3068 ], [
3069 enable_xcb="no"
3070 ])
3071 ])
3072 AC_ARG_ENABLE(xvideo,
3073 [ --enable-xvideo XVideo support (default enabled)],, [
3074 enable_xvideo="$enable_xcb"
3075 ])
3077 have_xcb="no"
3078 have_xcb_keysyms="no"
3079 have_xcb_randr="no"
3080 have_xcb_xvideo="no"
3081 AS_IF([test "${enable_xcb}" != "no"], [
3082 dnl libxcb
3083 PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3084 have_xcb="yes"
3085 PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3086 PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3087 PKG_CHECK_MODULES(XPROTO, [xproto])
3089 AS_IF([test "${enable_xvideo}" != "no"], [
3090 PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3091 ])
3093 PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3095 dnl xcb-utils
3096 PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3097 AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3098 ])
3099 ])
3100 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3101 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3102 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3103 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3106 dnl
3107 dnl VDPAU needs X11
3108 dnl
3109 AC_ARG_ENABLE(vdpau,
3110 [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3111 have_vdpau="no"
3112 AS_IF([test "${enable_vdpau}" != "no"], [
3113 PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3114 have_vdpau="yes"
3115 AS_IF([test "${no_x}" = "yes"], [
3116 AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3117 ])
3118 ], [
3119 AS_IF([test -n "${enable_vdpau}"], [
3120 AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3121 ])
3122 ])
3123 ])
3124 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3126 have_avcodec_vdpau="no"
3127 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3128 case "${avfork}" in
3129 libav) av_vdpau_ver="56.10.0" ;;
3130 ffmpeg) av_vdpau_ver="56.19.100" ;;
3131 esac
3132 PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3133 have_avcodec_vdpau="yes"
3134 AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3135 ], [
3136 AS_IF([test -n "${enable_vdpau}"], [
3137 AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3138 ], [
3139 AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3140 ])
3141 ])
3142 ])
3143 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3146 dnl
3147 dnl Wayland
3148 dnl
3149 AC_ARG_ENABLE(wayland,
3150 [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3151 have_wayland="no"
3152 have_wayland_egl="no"
3154 AS_IF([test "${enable_wayland}" != "no"], [
3155 PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3156 AC_MSG_CHECKING([for the Wayland protocols])
3157 PKG_CHECK_EXISTS([wayland-protocols >= 1.4], [
3158 WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3159 AC_MSG_RESULT([${WAYLAND_PROTOCOLS}])
3160 ], [
3161 AC_MSG_RESULT([not found])
3162 AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors 'wayland-protocols >= 1.4')])
3163 ])
3165 AC_MSG_CHECKING([for the Wayland scanner])
3166 PKG_CHECK_EXISTS([wayland-scanner], [
3167 WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3168 AC_MSG_RESULT([${WAYLAND_SCANNER}])
3169 ], [
3170 AC_MSG_RESULT([not found])
3171 AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors wayland-scanner)])
3172 ])
3174 have_wayland="yes"
3176 AS_IF([test "${have_egl}" = "yes"], [
3177 PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3178 have_wayland_egl="yes"
3179 ], [
3180 AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3181 ])
3182 ])
3183 ], [
3184 AS_IF([test -n "${enable_wayland}"], [
3185 AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3186 ])
3187 ])
3188 ])
3189 AC_SUBST([WAYLAND_PROTOCOLS])
3190 AC_SUBST([WAYLAND_SCANNER])
3191 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3192 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3195 dnl
3196 dnl SDL image decoder module
3197 dnl
3198 AC_ARG_ENABLE(sdl-image,
3199 [ --enable-sdl-image SDL image support (default enabled)])
3200 AS_IF([test "${enable_sdl_image}" != "no"],[
3201 PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3202 VLC_ADD_PLUGIN([sdl_image])
3203 ], [
3204 AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3205 ])
3206 ])
3208 dnl
3209 dnl freetype module
3210 dnl
3211 AC_ARG_ENABLE(freetype,
3212 [ --enable-freetype freetype support (default auto)])
3213 AC_ARG_ENABLE(fribidi,
3214 [ --enable-fribidi fribidi support (default auto)])
3215 AC_ARG_ENABLE(harfbuzz,
3216 [ --enable-harfbuzz harfbuzz support (default auto)])
3217 AC_ARG_ENABLE(fontconfig,
3218 [ --enable-fontconfig fontconfig support (default auto)])
3220 AC_ARG_WITH([default-font],
3221 AS_HELP_STRING([--with-default-font=PATH],
3222 [Path to the default font]),
3223 [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3224 "$withval", [Default font])])
3225 AC_ARG_WITH([default-monospace-font],
3226 AS_HELP_STRING([--with-default-monospace-font=PATH],
3227 [Path to the default font]),
3228 [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3229 "$withval", [Default monospace font])])
3231 AC_ARG_WITH([default-font-family],
3232 AS_HELP_STRING([--with-default-font-family=NAME],
3233 [Path to the default font family]),
3234 [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3235 "$withval", [Default font family])])
3236 AC_ARG_WITH([default-monospace-font-family],
3237 AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3238 [Path to the default font family]),
3239 [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3240 "$withval", [Default monospace font family])])
3242 have_freetype="no"
3243 have_fontconfig="no"
3244 have_fribidi="no"
3245 have_harfbuzz="no"
3247 if test "${enable_freetype}" != "no"; then
3248 PKG_CHECK_MODULES(FREETYPE, freetype2, [
3249 have_freetype="yes"
3250 VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3251 VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3253 dnl fontconfig support
3254 AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3255 PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3256 have_fontconfig="yes"
3257 ], [
3258 AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3259 ])
3260 ])
3262 dnl fribidi support
3263 if test "${enable_fribidi}" != "no"; then
3264 PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3265 have_fribidi="yes"
3266 VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3267 VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3268 ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3269 fi
3271 dnl harfbuzz support
3272 if test "${have_fribidi}" != "no"; then
3273 if test "${enable_harfbuzz}" != "no"; then
3274 PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3275 have_harfbuzz="yes"
3276 VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3277 VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3278 ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3279 fi
3280 fi
3281 ],[
3282 AS_IF([test -n "${enable_freetype}"],[
3283 AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3284 ])
3285 ])
3286 fi
3288 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3289 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3290 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3291 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3293 dnl
3294 dnl SAPI (text to Speech renderer for Windows)
3295 dnl
3296 AC_LANG_PUSH([C++])
3297 AC_CHECK_TYPES([ISpObjectToken],[
3298 have_sapi="yes"
3299 ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3300 [#include <windows.h>
3301 #include <sapi.h>
3302 #include <sphelper.h>])
3303 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3304 AC_LANG_POP([C++])
3306 dnl
3307 dnl SVG module (text rendering and image decoding)
3308 dnl
3309 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3310 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3312 dnl
3313 dnl Windows DirectX module
3314 dnl
3316 AC_ARG_ENABLE(directx,
3317 [AS_HELP_STRING([--enable-directx],
3318 [Microsoft DirectX support (default enabled on Windows)])],, [
3319 AS_IF([test "${SYS}" = "mingw32"], [
3320 enable_directx="yes"
3321 ], [
3322 enable_directx="no"
3323 ])
3324 ])
3325 AS_IF([test "${enable_directx}" != "no"], [
3326 dnl DirectDraw
3327 AC_CHECK_HEADERS(ddraw.h, [
3328 VLC_ADD_PLUGIN([directdraw])
3329 ])
3331 dnl OpenGL
3332 AC_CHECK_HEADERS(GL/wglew.h, [
3333 VLC_ADD_PLUGIN([glwin32 wgl])
3334 ],, [
3335 #include <windows.h>
3336 #include <GL/gl.h>
3337 ])
3339 dnl Direct3D11
3340 AC_CHECK_HEADERS(d3d11.h, [
3341 VLC_ADD_PLUGIN([direct3d11 direct3d11_filters])
3342 ])
3344 dnl Direct3D9
3345 AC_CHECK_HEADERS(d3d9.h, [
3346 VLC_ADD_PLUGIN([direct3d9])
3347 AC_CHECK_HEADERS(d3dx9effect.h)
3349 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3350 [[#define COBJMACROS
3351 #include <d3d9.h>
3352 #include <dxva2api.h>
3353 #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3354 # error dxva2 too old
3355 #endif
3356 ]],[[;]])
3357 ],[
3358 VLC_ADD_PLUGIN([direct3d9_filters])
3359 ],
3360 [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3362 ])
3363 ])
3365 dnl
3366 dnl Linux framebuffer module
3367 dnl
3368 AC_CHECK_HEADER([linux/fb.h], [
3369 VLC_ADD_PLUGIN([fb])
3370 ])
3372 dnl
3373 dnl libcaca plugin
3374 dnl
3375 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3377 dnl
3378 dnl OS/2 KVA plugin
3379 dnl
3380 AC_ARG_ENABLE(kva,
3381 [AS_HELP_STRING([--enable-kva],
3382 [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3383 AS_IF([test "$SYS" = "os2"], [
3384 enable_kva="yes"
3385 ])
3386 ])
3387 have_kva="no"
3388 KVA_LIBS=""
3389 AS_IF([test "$enable_kva" != "no"], [
3390 AC_CHECK_HEADERS([kva.h], [
3391 have_kva="yes"
3392 AC_CHECK_LIB(kva, main, [
3393 KVA_LIBS="-lkva"
3394 ])
3395 ])
3396 ])
3397 AC_SUBST(KVA_LIBS)
3398 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3400 dnl
3401 dnl MMAL plugin
3402 dnl
3403 AC_ARG_ENABLE(mmal,
3404 AS_HELP_STRING([--enable-mmal],
3405 [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3406 if test "${enable_mmal}" != "no"; then
3407 VLC_SAVE_FLAGS
3408 LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3409 CPPFLAGS="${CPPFLAGS} -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux"
3410 AC_CHECK_HEADERS(interface/mmal/mmal.h,
3411 [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3412 have_mmal="yes"
3413 VLC_ADD_PLUGIN([mmal])
3414 VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3415 VLC_ADD_CFLAGS([mmal],[ -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux ])
3416 VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lmmal_core -lmmal_components -lmmal_util -lvchostif ]) ], [
3417 AS_IF([test "${enable_mmal}" = "yes"],
3418 [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3419 [ AC_MSG_WARN([Cannot find bcm library...]) ])
3420 ],
3421 [])
3422 ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3423 [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3424 [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3425 VLC_RESTORE_FLAGS
3426 fi
3427 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3429 dnl
3430 dnl Audio plugins
3431 dnl
3433 EXTEND_HELP_STRING([Audio plugins:])
3435 dnl
3436 dnl Pulseaudio module
3437 dnl
3438 AC_ARG_ENABLE(pulse,
3439 [AS_HELP_STRING([--enable-pulse],
3440 [use the PulseAudio client library (default auto)])])
3441 have_pulse="no"
3442 AS_IF([test "${enable_pulse}" != "no"], [
3443 PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3444 have_pulse="yes"
3445 ], [
3446 AS_IF([test "x${enable_pulse}" != "x"], [
3447 AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3448 ])
3449 ])
3450 ])
3451 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3453 dnl
3454 dnl ALSA module
3455 dnl
3456 AC_ARG_ENABLE(alsa,
3457 [AS_HELP_STRING([--enable-alsa],
3458 [support the Advanced Linux Sound Architecture (default auto)])],, [
3459 AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3460 enable_alsa="yes"
3461 ])
3462 ])
3463 have_alsa="no"
3464 AS_IF([test "${enable_alsa}" != "no"], [
3465 PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3466 have_alsa="yes"
3467 ], [
3468 AS_IF([test "x${enable_alsa}" != "x"], [
3469 AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required. Pass --disable-alsa to ignore this error.])
3470 ])
3471 ])
3472 ])
3473 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3475 dnl
3476 dnl Open Sound System module
3477 dnl
3478 AC_ARG_ENABLE(oss,
3479 [AS_HELP_STRING([--enable-oss],
3480 [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3481 AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3482 enable_oss="no"
3483 ])
3484 ])
3485 have_oss="no"
3486 OSS_LIBS=""
3487 AS_IF([test "$enable_oss" != "no"], [
3488 AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3489 have_oss="yes"
3490 AC_CHECK_LIB(ossaudio, main, [
3491 OSS_LIBS="-lossaudio"
3492 ])
3493 ])
3494 ])
3495 AC_SUBST(OSS_LIBS)
3496 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3498 dnl
3499 dnl OpenBSD sndio module
3500 dnl
3501 AC_ARG_ENABLE([sndio],
3502 [AS_HELP_STRING([--disable-sndio],
3503 [support the OpenBSD sndio (default auto)])],, [
3504 AS_IF([test "$SYS" = "openbsd"], [
3505 enable_sndio="yes"
3506 ])
3507 ])
3508 have_sndio="no"
3509 AS_IF([test "$enable_sndio" != "no"], [
3510 AC_CHECK_HEADER([sndio.h], [
3511 have_sndio="yes"
3512 ])
3513 ])
3514 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3516 dnl
3517 dnl Windows Audio Session plugin
3518 dnl
3519 AC_ARG_ENABLE([wasapi],
3520 [AS_HELP_STRING([--enable-wasapi],
3521 [use the Windows Audio Session API (default auto)])
3522 ])
3523 have_wasapi="no"
3524 AS_IF([test "$enable_wasapi" != "no"], [
3525 AC_CHECK_HEADER([audioclient.h], [
3526 have_wasapi="yes"
3527 ], [
3528 AS_IF([test "x${enable_wasapi}" != "x"], [
3529 AC_MSG_ERROR([Windows Audio Session API not found.])
3530 ])
3531 ])
3532 ])
3533 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3535 dnl
3536 dnl JACK modules
3537 dnl
3538 AC_ARG_ENABLE(jack,
3539 [AS_HELP_STRING([--disable-jack],
3540 [do not use jack (default auto)])])
3541 have_jack="no"
3542 AS_IF([test "${enable_jack}" != "no"], [
3543 PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3544 [ have_jack=yes ],
3545 [
3546 AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3548 PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3549 [ have_jack=yes ],
3550 [
3551 AS_IF([test -n "${enable_jack}"],
3552 [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3553 [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3554 ])
3555 ])
3556 ])
3557 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3559 dnl
3560 dnl OpenSLES Android
3561 dnl
3562 AC_ARG_ENABLE(opensles,
3563 [ --enable-opensles Android OpenSL ES audio module (default disabled)])
3564 if test "${HAVE_ANDROID}" = "1"; then
3565 if test "${enable_opensles}" = "yes"; then
3566 AC_CHECK_HEADERS(SLES/OpenSLES.h,
3567 [ VLC_ADD_PLUGIN([opensles_android]) ],
3568 [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3569 fi
3570 fi
3572 dnl
3573 dnl Tizen audio
3574 dnl
3575 AC_ARG_ENABLE(tizen_audio,
3576 [AS_HELP_STRING([--enable-tizen-audio],
3577 [Tizen audio module (default enabled on Tizen)])],, [
3578 AS_IF([test "$HAVE_TIZEN" = "1"], [
3579 enable_tizen_audio="yes"
3580 ])
3581 ])
3582 if test "${enable_tizen_audio}" = "yes"; then
3583 AC_CHECK_HEADERS(audio_io.h,
3584 [ VLC_ADD_PLUGIN([tizen_audio]) ],
3585 [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3586 fi
3588 dnl
3589 dnl libsamplerate plugin
3590 dnl
3591 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3593 dnl
3594 dnl soxr module
3595 dnl
3596 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3598 dnl
3599 dnl OS/2 KAI plugin
3600 dnl
3601 AC_ARG_ENABLE(kai,
3602 [AS_HELP_STRING([--enable-kai],
3603 [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3604 AS_IF([test "$SYS" = "os2"], [
3605 enable_kai="yes"
3606 ])
3607 ])
3608 have_kai="no"
3609 KAI_LIBS=""
3610 AS_IF([test "$enable_kai" != "no"], [
3611 AC_CHECK_HEADERS([kai.h], [
3612 have_kai="yes"
3613 AC_CHECK_LIB(kai, main, [
3614 KAI_LIBS="-lkai"
3615 ])
3616 ])
3617 ])
3618 AC_SUBST(KAI_LIBS)
3619 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3621 dnl
3622 dnl chromaprint audio track fingerprinter
3623 dnl
3624 m4_pushdef([libchromaprint_version], 0.6.0)
3625 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3626 VLC_ADD_PLUGIN([stream_out_chromaprint]),
3627 AS_IF([test "${enable_chromaprint}" = "yes"],
3628 [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3629 [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3630 ),
3631 [(Chromaprint based audio fingerprinter)],[auto])
3632 m4_popdef([libchromaprint_version])
3634 dnl
3635 dnl Chromecast streaming support
3636 dnl
3637 m4_pushdef([protobuf_lite_version], 2.5.0)
3638 AC_ARG_VAR(PROTOC, [protobuf compiler])
3639 AC_CHECK_PROGS(PROTOC, protoc, no)
3640 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3641 AS_IF([test "x${PROTOC}" != "xno"], [
3642 build_chromecast="yes"
3643 ], [
3644 AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3645 ])
3646 ], [
3647 AS_IF([test "${enable_chromecast}" = "yes"],
3648 AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3649 AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3650 )
3651 enable_chromecast="no"
3652 ], [(Chromecast streaming support)], [auto])
3653 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3654 m4_popdef([protobuf_lite_version])
3656 dnl
3657 dnl Interface plugins
3658 dnl
3660 EXTEND_HELP_STRING([Interface plugins:])
3662 dnl
3663 dnl QT
3664 dnl
3665 AC_ARG_ENABLE(qt, [
3666 AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3667 AS_IF([test "${SYS}" = "darwin"], [
3668 enable_qt="no"
3669 ])
3670 ])
3671 have_qt5_x11="no"
3672 AS_IF([test "${enable_qt}" != "no"], [
3673 PKG_CHECK_MODULES([QT], [Qt5Core >= 5.5.0 Qt5Widgets Qt5Gui Qt5Svg], [
3674 PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3675 have_qt5_x11="yes"
3676 ],[
3677 AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3678 ])
3679 QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3680 QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3681 QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3682 AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3683 AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3684 AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3685 ], [
3686 AS_IF([test -n "${enable_qt}"],[
3687 AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3688 ],[
3689 AC_MSG_WARN([${QT_PKG_ERRORS}.])
3690 ])
3691 enable_qt="no"
3692 ])
3693 ])
3695 AS_IF([test "${enable_qt}" != "no"], [
3696 ALIASES="${ALIASES} qvlc"
3697 ])
3698 AC_SUBST(QT_VERSION)
3699 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3700 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3702 dnl
3703 dnl detect kde4-config patch (used for kde solids).
3704 dnl
3705 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3706 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3707 KDE4_CONFIG="kde4-config"
3708 ])
3710 dnl
3711 dnl Simple test for skins2 dependency
3712 dnl
3713 AS_IF([test "$enable_qt" = "no"], [
3714 AS_IF([test "${enable_skins2}" = "yes"], [
3715 AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3716 ], [
3717 enable_skins2="no"
3718 AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3719 ])
3720 ])
3722 dnl
3723 dnl Skins2 module
3724 dnl
3725 AC_ARG_ENABLE(skins2,
3726 [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3727 AS_IF([test "${enable_skins2}" != "no"], [
3728 have_skins_deps="yes"
3730 dnl Win32
3731 AS_IF([test "${SYS}" = "mingw32"], [
3732 VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3733 VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3734 dnl OS/2
3735 ], [test "${SYS}" = "os2"], [
3736 VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3737 dnl Linux/Unix
3738 ], [
3739 PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3740 PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3741 PKG_CHECK_MODULES([XCURSOR], [xcursor],, [have_skins_deps="no"])
3742 PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3743 VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3744 VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} ${XCURSOR_LIBS} -lX11])
3745 ])
3747 dnl we need freetype
3748 AS_IF([test "${have_freetype}" != "yes"], [
3749 have_skins_deps="no"
3750 ])
3752 AS_IF([test "${have_skins_deps}" = "no"], [
3753 AS_IF([test "x${enable_skins2}" = "x"], [
3754 AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3755 ], [
3756 AC_MSG_ERROR([Skins2 interface requires FreeType, libxcursor, libxpm, libxext and libxinerama])
3757 ])
3758 enable_skins2="no"
3759 ], [
3760 ALIASES="${ALIASES} svlc"
3761 enable_skins2="yes"
3762 ])
3763 ])
3764 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3766 AC_ARG_ENABLE(libtar,
3767 [ --enable-libtar libtar support for skins2 (default auto)])
3768 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3769 AC_CHECK_HEADERS(libtar.h, [
3770 VLC_ADD_LIBS([skins2],[-ltar])
3771 ])
3772 ])
3774 dnl
3775 dnl MacOS X gui module
3776 dnl
3777 AC_ARG_ENABLE(macosx,
3778 [ --enable-macosx Mac OS X gui support (default enabled on Mac OS X)])
3779 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3780 then
3782 dnl
3783 dnl If possible, use xcrun to find the right ibtool
3784 dnl
3786 AC_PATH_PROG([XCRUN], [xcrun], [no])
3787 AS_IF([test ! "x${XCRUN}" = "xno"], [
3788 AC_MSG_CHECKING([for ibtool (using xcrun)])
3789 XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3790 AC_MSG_RESULT([${XIB}])
3791 ], [
3792 AC_MSG_WARN([Looking for tools without using xcrun])
3793 ])
3795 AS_IF([test "x${XIB}" = "xno"], [
3796 AC_PATH_PROG(XIB, [ibtool], [no])
3797 AS_IF([test "x${XIB}" = "xno"], [
3798 AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3799 ])
3800 ])
3801 fi
3802 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3804 dnl
3805 dnl MacOS X sparkle update support
3806 dnl
3807 AC_ARG_ENABLE(sparkle,
3808 [ --enable-sparkle Sparkle update support for OS X (default enabled on Mac OS X)])
3809 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3810 then
3811 if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3812 then
3813 AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3814 fi
3816 AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3817 fi
3818 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3820 dnl
3821 dnl MacOS X breakpad creash reporter support
3822 dnl
3823 AC_ARG_WITH([breakpad],
3824 AS_HELP_STRING([--with-breakpad=URL], [Enable Breakpad reporter using given URL]), [], [with_breakpad=no])
3826 AS_IF([test "$with_breakpad" != "no"], [
3828 AS_IF([test "$with_breakpad" = "yes"], [
3829 AC_MSG_ERROR([You need to supply the CrashDragon Server URL as value for --with-breakpad])
3830 ])
3832 AS_IF([test "$HAVE_OSX" = "1"], [
3833 AC_MSG_CHECKING([for Breakpad framework])
3834 AS_IF([test ! -d ${CONTRIB_DIR}/Breakpad.framework -a \
3835 ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework], [
3836 AC_MSG_RESULT([no])
3837 with_breakpad="no"
3838 AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3839 ], [
3840 AC_MSG_RESULT([yes])
3841 ])
3842 ],[
3843 PKG_CHECK_MODULES([BREAKPAD], [breakpad-client], [
3844 LDFLAGS="${LDFLAGS} -Wl,--build-id"
3845 ], [
3846 AC_MSG_ERROR(["breakpad not found"])
3847 ])
3848 ])
3849 ])
3851 AM_CONDITIONAL(HAVE_BREAKPAD, [test "$with_breakpad" != "no"])
3852 AS_IF([test "$with_breakpad" != "no"], [
3853 AC_SUBST(BREAKPAD_URL, ["${with_breakpad}"])
3854 ])
3856 dnl
3857 dnl Minimal Mac OS X module
3858 dnl
3859 AC_ARG_ENABLE(minimal-macosx,
3860 [ --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3861 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3862 then
3863 VLC_ADD_PLUGIN([minimal_macosx])
3864 fi
3866 dnl
3867 dnl Mac OS X fancy dmg build tool
3868 dnl
3869 if test "${HAVE_OSX}" = "1"
3870 then
3871 AC_PATH_PROG(DMGBUILD, dmgbuild, no)
3872 AS_IF([test "x${DMGBUILD}" = "xno"], [
3873 AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
3874 ])
3875 fi
3876 AM_CONDITIONAL(HAVE_DMGBUILD, [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
3878 dnl
3879 dnl VideoToolbox plugins
3880 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3881 VLC_ADD_PLUGIN([videotoolbox])
3882 VLC_ADD_PLUGIN([cvpx])
3883 ])
3885 dnl
3886 dnl AudioToolbox MIDI plugin
3887 AC_CHECK_HEADERS([AudioToolbox/AudioToolbox.h], [
3888 VLC_ADD_PLUGIN([audiotoolboxmidi])
3889 ])
3891 dnl
3892 dnl ncurses module
3893 dnl
3894 AC_ARG_ENABLE(ncurses,
3895 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3896 have_ncurses="no"
3897 AS_IF([test "${enable_ncurses}" != "no"] ,[
3898 PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3899 have_ncurses="yes"
3900 ALIASES="${ALIASES} nvlc"
3901 ], [
3902 AS_IF([test -n "${enable_ncurses}"], [
3903 AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3904 ])
3905 ])
3906 ])
3907 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3909 dnl
3910 dnl Lirc plugin
3911 dnl
3912 AC_ARG_ENABLE(lirc,
3913 [ --enable-lirc lirc support (default disabled)])
3914 have_lirc="no"
3915 AS_IF([test "${enable_lirc}" = "yes"], [
3916 AC_CHECK_HEADER(lirc/lirc_client.h, [
3917 AC_CHECK_LIB(lirc_client, lirc_init, [
3918 have_lirc="yes"
3919 ])
3920 ])
3921 ])
3922 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3924 dnl
3925 dnl SRT plugin
3926 dnl
3927 PKG_ENABLE_MODULES_VLC([SRT], [access_srt access_output_srt], [srt >= 1.2.2], [SRT input/output plugin], [auto], [], [], [-DENABLE_SRT])
3929 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3930 dnl
3931 dnl goom visualization plugin
3932 dnl
3933 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3935 dnl
3936 dnl libprojectM visualization plugin
3937 dnl
3938 AC_ARG_ENABLE(projectm,
3939 [ --enable-projectm projectM visualization plugin (default enabled)])
3940 AS_IF([test "${enable_projectm}" != "no"],
3941 [
3942 PKG_CHECK_MODULES(PROJECTM, libprojectM,
3943 [
3944 VLC_ADD_PLUGIN([projectm])
3945 PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3946 [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3947 [ AC_MSG_WARN( [Using libprojectM version 1] )
3948 ])
3949 ],[
3950 AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3951 ])
3952 ])
3954 dnl
3955 dnl Vovoid VSXu visualization plugin
3956 dnl
3957 AC_ARG_ENABLE(vsxu,
3958 [ --enable-vsxu Vovoid VSXu visualization plugin (default auto)])
3959 AS_IF([test "${enable_vsxu}" != "no"],
3960 [
3961 PKG_CHECK_MODULES(VSXU, libvsxu,
3962 [
3963 VLC_ADD_PLUGIN([vsxu])
3964 ],[
3965 AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3966 ])
3967 ])
3969 EXTEND_HELP_STRING([Service Discovery plugins:])
3970 dnl
3971 dnl Avahi-Zeroconf services discovery
3972 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
3974 dnl
3975 dnl libudev services discovery
3976 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3978 dnl
3979 dnl MTP devices services discovery
3980 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3982 dnl
3983 dnl UPnP Plugin (Intel SDK)
3984 dnl
3985 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3987 dnl
3988 dnl mDNS using libmicrodns
3989 dnl
3990 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
3993 EXTEND_HELP_STRING([Misc options:])
3995 dnl
3996 dnl libxml2 module
3997 dnl
3998 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4001 dnl
4002 dnl libgcrypt
4003 dnl
4004 AC_ARG_ENABLE(libgcrypt,
4005 [ --disable-libgcrypt gcrypt support (default enabled)])
4006 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
4007 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4009 # require libgcrypt >= 1.6.0
4010 AS_IF([test "${enable_libgcrypt}" != "no"], [
4011 AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4012 VLC_SAVE_FLAGS
4013 CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4014 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4015 [#include <gcrypt.h>
4016 #if GCRYPT_VERSION_NUMBER < 0x010600
4017 #error
4018 #endif]])], [
4019 ac_cv_lib_gcrypt=yes
4020 ], [
4021 ac_cv_lib_gcrypt=no
4022 ])
4023 VLC_RESTORE_FLAGS
4024 ])
4026 AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4027 AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4028 ], [
4029 AS_IF([test "${enable_libgcrypt}" = "yes"], [
4030 AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4031 ])
4032 ])
4033 ])
4035 AS_IF([test -z "$GCRYPT_LIBS"], [
4036 GCRYPT_LIBS="-lgcrypt -lgpg-error"
4037 ])
4039 AC_SUBST(GCRYPT_CFLAGS)
4040 AC_SUBST(GCRYPT_LIBS)
4041 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4043 dnl
4044 dnl TLS/SSL
4045 dnl
4046 AC_ARG_ENABLE(gnutls,
4047 [ --enable-gnutls GNU TLS TLS/SSL support (default enabled)])
4048 AS_IF([test "${enable_gnutls}" != "no"], [
4049 PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4050 VLC_ADD_PLUGIN([gnutls])
4051 ], [
4052 AS_IF([test -n "${enable_gnutls}"], [
4053 AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4054 ])
4055 ])
4056 ])
4059 dnl
4060 dnl Taglib plugin
4061 dnl
4062 AC_ARG_ENABLE(taglib,
4063 [AS_HELP_STRING([--disable-taglib],
4064 [do not use TagLib (default enabled)])])
4065 AS_IF([test "${enable_taglib}" != "no"], [
4066 PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4067 VLC_ADD_PLUGIN([taglib])
4068 ], [
4069 AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4070 ])
4072 dnl
4073 dnl libsecret
4074 dnl
4075 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4077 dnl
4078 dnl kwallet
4079 dnl
4080 AC_ARG_ENABLE(kwallet,
4081 [AS_HELP_STRING([--enable-kwallet],
4082 [use kwallet (via D-Bus) for keystore (default enabled)])])
4083 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4084 VLC_ADD_PLUGIN([kwallet])
4085 ])
4087 dnl
4088 dnl update checking system
4089 dnl
4090 AC_ARG_ENABLE(update-check,
4091 [ --enable-update-check update checking system (default disabled)])
4092 if test "${enable_update_check}" = "yes"
4093 then
4094 AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4095 AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4096 fi
4097 AM_CONDITIONAL(UPDATE_CHECK, [test "${enable_update_check}" = "yes"])
4099 dnl
4100 dnl OS X notification plugin
4101 dnl
4102 AC_ARG_ENABLE(osx_notifications,
4103 [ --enable-osx-notifications osx notification plugin (default disabled)],,
4104 [enable_osx_notifications=no])
4105 AS_IF([test "${enable_osx_notifications}" != "no"], [
4106 if test -d ${CONTRIB_DIR}/Growl.framework -o -d ${CONTRIB_DIR}/Frameworks/Growl.framework
4107 then
4108 VLC_ADD_PLUGIN([osx_notifications])
4109 VLC_ADD_LIBS([osx_notifications], [-Wl,-framework,Growl,-framework,Foundation])
4110 VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4111 fi
4112 ])
4114 dnl
4115 dnl Libnotify notification plugin
4116 dnl
4117 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-3.0], [libnotify notification], [auto])
4119 dnl
4120 dnl libplacebo support
4121 dnl
4122 AC_ARG_ENABLE(libplacebo,
4123 [AS_HELP_STRING([--disable-libplacebo],
4124 [disable libplacebo support (default auto)])])
4126 AS_IF([test "$enable_libplacebo" != "no"], [
4127 PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 0.2.1], [
4128 AC_DEFINE([HAVE_LIBPLACEBO], [1], [Define to 1 if libplacebo is enabled.])
4129 ], [
4130 AS_IF([test -n "${enable_libplacebo}"], [
4131 AC_MSG_ERROR([${LIBPLACEBO_PKG_ERRORS}.])
4132 ])
4133 enable_libplacebo="no"
4134 ])
4135 ])
4136 AM_CONDITIONAL(HAVE_LIBPLACEBO, [test "$enable_libplacebo" != "no"])
4139 dnl
4140 dnl Endianness check
4141 dnl
4142 AC_C_BIGENDIAN
4143 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4144 DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4145 ], [
4146 DEFS_BIGENDIAN=""
4147 ])
4148 AC_SUBST(DEFS_BIGENDIAN)
4150 dnl
4151 dnl Where to install KDE solid .desktop
4152 dnl
4153 AC_ARG_WITH(kde-solid,
4154 AS_HELP_STRING([--with-kde-solid=PATH],
4155 [KDE Solid actions directory (auto)]),, [
4157 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4158 with_kde_solid="yes"
4159 fi
4160 ])
4161 soliddatadir=""
4162 AS_IF([test "${with_kde_solid}" != "no"], [
4163 AS_IF([test "${with_kde_solid}" = "yes"], [
4164 kde4datadir="`${KDE4_CONFIG} --install data`"
4165 AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4166 soliddatadir="${kde4datadir}/solid/actions"
4167 ], [
4168 soliddatadir="${with_kde_solid}"
4169 ])
4170 ])
4171 AC_SUBST(soliddatadir)
4172 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4174 dnl
4175 dnl Find tools for win32 packaging
4176 dnl
4177 AS_IF([test "${SYS}" = "mingw32"], [
4178 dnl
4179 dnl Find makensis required to build the NSIS installer
4180 dnl
4181 nsis_major_required="3"
4182 nsis_version_ok="no"
4183 AC_PATH_PROG([MAKENSIS], [makensis], [no])
4184 AS_IF([test "$MAKENSIS" != "no"], [
4185 # Check version
4186 AC_MSG_CHECKING([makensis version])
4187 nsis_version=$($MAKENSIS -VERSION)
4188 AC_MSG_RESULT([$nsis_version])
4189 nsis_version_major=$(echo "$nsis_version" | awk -F \. '{print $1}' | sed 's/v//')
4190 # Check if major version is a valid number
4191 AS_IF([test -n "$nsis_version_major" && \
4192 test "$nsis_version_major" -eq "$nsis_version_major" 2> /dev/null], [
4193 # Do the version check using major version
4194 AS_IF([test "$nsis_version_major" -lt "$nsis_major_required"], [
4195 AC_MSG_WARN([makensis too old, (needs ${nsis_major_required}.x, have ${nsis_version_major}.x)])
4196 ], [
4197 nsis_version_ok="yes"
4198 ])
4199 ], [
4200 AC_MSG_WARN([failed to check the makensis version])
4201 ])
4202 ])
4203 dnl
4204 dnl Find 7zip
4205 dnl
4206 AC_PATH_PROG([SEVENZIP], [7z], [7z])
4207 ])
4208 AM_CONDITIONAL(HAVE_MAKENSIS, [test "x$MAKENSIS" != "xno" && test "$nsis_version_ok" = "yes"])
4210 dnl
4211 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4212 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4213 dnl
4214 if test "${SYS}" = "mingw32"; then
4215 AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4216 fi
4218 EXTEND_HELP_STRING([Components:])
4220 dnl
4221 dnl the VLC binary
4222 dnl
4223 AC_ARG_ENABLE(vlc,
4224 [ --enable-vlc build the VLC media player (default enabled)])
4225 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4227 dnl
4228 dnl Fuzzer (at the end in order to don't mess dependencies FLAGS)
4229 dnl
4230 AS_VAR_IF(with_libfuzzer, no, [], [
4231 LIBS="-lstdc++ ${LIBM} ${LIBPTHREAD} -L${with_libfuzzer} -lFuzzer"
4232 AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc-guard, [
4233 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard])
4234 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard], [CXXFLAGS])
4235 AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp])
4236 AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp], [CXXFLAGS])
4237 ], [
4238 AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc, [
4239 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc])
4240 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc], [CXXFLAGS])
4241 ], [
4242 AC_MSG_ERROR([Sanitizer coverage not supported by your compiler])
4243 ])
4244 ])
4245 ])
4247 dnl
4248 dnl Stuff used by the program
4249 dnl
4250 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4251 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4252 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4253 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4254 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4255 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4256 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4257 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4258 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4259 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4260 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4261 AC_SUBST(COPYRIGHT_MESSAGE)
4262 AC_SUBST(VERSION_MESSAGE)
4263 AC_SUBST(VERSION_MAJOR)
4264 AC_SUBST(VERSION_MINOR)
4265 AC_SUBST(VERSION_REVISION)
4266 AC_SUBST(VERSION_EXTRA)
4267 AC_SUBST(COPYRIGHT_YEARS)
4268 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4269 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4270 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4271 dnl
4272 dnl Handle substvars that use $(top_srcdir)
4273 dnl
4274 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4276 dnl
4277 dnl Configuration is finished
4278 dnl
4279 AC_SUBST(SYS)
4280 AC_SUBST(ARCH)
4281 AC_SUBST(ALIASES)
4282 AC_SUBST(ASM)
4283 AC_SUBST(MOC)
4284 AC_SUBST(RCC)
4285 AC_SUBST(UIC)
4286 AC_SUBST(WINDRES)
4287 AC_SUBST(WINE_SDK_PATH)
4288 AC_SUBST(LIBEXT)
4289 AC_SUBST(AM_CPPFLAGS)
4290 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4291 AC_SUBST(FILE_LIBVLCCORE_DLL)
4292 AC_SUBST(FILE_LIBVLC_DLL)
4294 AC_CONFIG_FILES([
4295 Makefile
4296 doc/Makefile
4297 modules/Makefile
4298 m4/Makefile
4299 po/Makefile.in
4300 share/Makefile
4301 compat/Makefile
4302 src/Makefile
4303 lib/Makefile
4304 bin/Makefile
4305 test/Makefile
4306 modules/hw/mmal/Makefile
4307 share/vlc.appdata.xml.in
4308 ])
4310 AM_COND_IF([HAVE_WIN32], [
4311 AC_CONFIG_FILES([
4312 extras/package/win32/NSIS/spad.nsi
4313 extras/package/win32/NSIS/vlc.win32.nsi
4314 extras/package/win32/msi/config.wxi
4315 ])
4316 ])
4318 AM_COND_IF([HAVE_DARWIN], [
4319 AC_CONFIG_FILES([
4320 modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4321 share/macosx/Info.plist:share/Info.plist.in
4322 ])
4323 ])
4325 dnl Generate makefiles
4326 AC_OUTPUT
4328 dnl Do we have to use make or gmake ?
4329 if make --version 2>&1|grep -q GNU
4330 then
4331 # GNU make, all seems good
4332 MAKE=make
4333 else
4334 # Known GNU make alias (on BSD)
4335 MAKE=gmake
4336 fi
4337 dnl Shortcut to nice compile message
4338 if test -n $SHELL; then
4339 SHELL=${CONFIG_SHELL-/bin/sh}
4340 fi
4341 rm -f compile
4342 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4343 echo "#! $SHELL
4344 rm -f .error\$\$
4345 ERROR=0
4346 export PATH=\"$PATH\" LANG=C
4347 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4348 test -f .error\$\$ && ERROR=1
4349 rm -f .error\$\$
4350 exit \$ERROR" >compile
4351 chmod a+x compile
4353 echo "
4354 libvlc configuration
4355 --------------------
4356 version : ${VERSION}
4357 system : ${SYS}
4358 architecture : ${ARCH}
4359 optimizations : ${enable_optimizations}"
4360 if test "${enable_vlc}" != "no"; then
4361 echo "vlc aliases :${ALIASES}"
4362 else
4363 echo "build vlc executable : no"
4364 fi
4365 echo "
4366 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."