configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 1999-2017 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 3.0.0-git)
   6 VERSION_MAJOR=3
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=git
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Vetinari"
  17 COPYRIGHT_YEARS="1996-2017"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 AM_SILENT_RULES([yes])
  31 AM_MAINTAINER_MODE([enable])
  32
  33 dnl
  34 dnl Directories
  35 dnl
  36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  37 dnl AC_SUBST(vlcincludedir)
  38 vlcdatadir="\${datadir}/\${PKGDIR}"
  39 AC_SUBST(vlcdatadir)
  40 vlclibdir="\${libdir}/\${PKGDIR}"
  41 AC_SUBST(vlclibdir)
  42
  43 dnl
  44 dnl Check for tools
  45 dnl
  46 AC_PROG_CC_C99
  47 AC_USE_SYSTEM_EXTENSIONS
  48 VLC_PROG_CC_C11
  49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  51 AH_TOP([
  52 #ifndef _REENTRANT
  53 # define _REENTRANT
  54 #endif
  55 ])
  56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  59
  60 AM_PROG_CC_C_O
  61 AC_PROG_CXX
  62 AC_PROG_CPP
  63 AC_PROG_OBJC
  64 _AM_DEPENDENCIES([OBJC])
  65 AC_PROG_EGREP
  66 AC_PROG_MAKE_SET
  67 AC_PROG_INSTALL
  68 AM_PROG_AS
  69
  70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
  73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
  74 AS_IF([test "$BUILDCC" = "false"], [
  75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
  76 ])
  77
  78 dnl Check for compiler properties
  79 AC_C_CONST
  80 AC_C_INLINE
  81 AC_C_RESTRICT
  82 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
  83
  84 dnl Extend the --help string at the current spot.
  85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  86
  87 dnl Allow binary package maintainer to pass a custom string to avoid
  88 dnl cache problem
  89 AC_ARG_WITH(binary-version,
  90     AS_HELP_STRING([--with-binary-version=STRING],
  91          [To avoid plugins cache problem between binary version]),[],[])
  92 AS_IF([test -n "${with_binary_version}"],[
  93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  94          [Binary specific version])
  95 ])
  96
  97 dnl
  98 dnl  Check the operating system
  99 dnl
 100 HAVE_WIN64="0"
 101 HAVE_IOS="0"
 102 HAVE_OSX="0"
 103 HAVE_TVOS="0"
 104
 105 case "${host_os}" in
 106   "")
 107     SYS=unknown
 108     ;;
 109   linux*)
 110     SYS=linux
 111     ;;
 112   bsdi*)
 113     SYS=bsdi
 114     CFLAGS="${CFLAGS} -pthread"
 115     ;;
 116   freebsd*)
 117     SYS=freebsd
 118     CFLAGS="${CFLAGS} -pthread"
 119     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 120     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 121     ac_cv_ld_z_defs=no
 122     ;;
 123   openbsd*)
 124     SYS=openbsd
 125     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 126     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 127     ;;
 128   netbsd*)
 129     SYS=netbsd
 130     ;;
 131   dragonfly*)
 132     SYS=dragonfly
 133     ;;
 134   darwin*)
 135
 136     dnl Force gcc "-arch" flag
 137     ARCH_flag=""
 138     case "${host}" in
 139       i?86*)
 140         ARCH_flag="-arch i386"
 141       ;;
 142       ppc64*)
 143         ARCH_flag="-arch ppc64"
 144       ;;
 145       ppc*)
 146         ARCH_flag="-arch ppc"
 147       ;;
 148       x86_64*)
 149         ARCH_flag="-arch x86_64"
 150       ;;
 151       arm*)
 152         ac_cv_c_bigendian="no"
 153         ac_cv_c_attribute_packed="no"
 154       ;;
 155     esac
 156
 157     SYS=darwin
 158     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 159     CXX="${CXX} -stdlib=libc++ -std=c++11"
 160     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 161     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 162     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
 163     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 164     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 165     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 166
 167     AC_EGREP_CPP(yes,
 168             [#import <TargetConditionals.h>
 169              #if TARGET_OS_IPHONE
 170              yes
 171              #endif],
 172              [HAVE_IOS="1"],
 173              [HAVE_OSX="1"])
 174
 175     AC_EGREP_CPP(yes,
 176             [#import <TargetConditionals.h>
 177              #if TARGET_OS_TV
 178              yes
 179              #endif],
 180              [HAVE_TVOS="1"
 181              HAVE_IOS="0"
 182              HAVE_OSX="0"
 183              ],)
 184
 185     dnl Allow binaries created on Lion to run on earlier releases
 186     AC_EGREP_CPP(yes,
 187            [#import <Cocoa/Cocoa.h>
 188             #ifdef MAC_OS_X_VERSION_10_7
 189             yes
 190             #endif],
 191             [AC_MSG_RESULT([yes])
 192             AC_LIBOBJ([getdelim])
 193             AC_LIBOBJ([strndup])
 194             AC_LIBOBJ([strnlen])],)
 195
 196     dnl
 197     dnl  Handle Mac OS X SDK flags
 198     dnl
 199     AC_ARG_WITH(macosx-sdk,
 200       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 201         [compile using the SDK in DIR])])
 202     if test "${with_macosx_sdk}" != "" ; then
 203         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 204         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 205         CC="${CC} -isysroot ${with_macosx_sdk}"
 206         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 207         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 208         LD="${LD} -syslibroot ${with_macosx_sdk}"
 209     fi
 210     AC_ARG_WITH(macosx-version-min,
 211       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 212         [compile for Mac OS X VERSION and above])])
 213     if test "${with_macosx_version_min}" != "" ; then
 214         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 215         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 216         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 217         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 218         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 219     fi
 220     ;;
 221   *mingw32* | *cygwin* | *wince* | *mingwce*)
 222     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
 223     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
 224     CXXFLAGS="${CXXFLAGS} -static-libgcc"
 225     AC_CHECK_TOOL(WINDRES, windres, :)
 226     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 227     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
 228     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
 229     AH_TOP([#endif])
 230     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 231     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 232     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 233     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 234     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 235     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 236     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 237     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 238     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 239     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 240     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 241
 242     case "${host_os}" in
 243       *mingw32*)
 244         SYS=mingw32
 245         ;;
 246       *cygwin*)
 247         dnl Check if we are using the mno-cygwin mode in which case we are
 248         dnl actually dealing with a mingw32 compiler.
 249         AC_EGREP_CPP(yes,
 250             [#ifdef _WIN32
 251              yes
 252              #endif],
 253             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 254         ;;
 255     esac
 256
 257     if test "${SYS}" = "mingw32"; then
 258         # DEP, ASLR, NO SEH
 259         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 260
 261         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 262         ac_default_prefix="`pwd`/_win32"
 263         DESTDIR="`pwd`/_win32/"
 264
 265         dnl
 266         dnl NSIS/MSI Installer prefix and WIN64
 267         dnl
 268         case "${host}" in
 269             amd64*|x86_64*)
 270                 HAVE_WIN64="1"
 271                 WINDOWS_ARCH="x64"
 272                 PROGRAMFILES="PROGRAMFILES64"
 273                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
 274             ;;
 275             *)
 276                 WINDOWS_ARCH="x86"
 277                 PROGRAMFILES="PROGRAMFILES"
 278             ;;
 279         esac
 280         AC_SUBST(WINDOWS_ARCH)
 281         AC_SUBST(PROGRAMFILES)
 282
 283     fi
 284     ;;
 285   *nto*)
 286     SYS=nto
 287     ;;
 288   solaris*)
 289     SYS=solaris
 290     ;;
 291   hpux*)
 292     SYS=hpux
 293     ;;
 294   *os2*)
 295     SYS=os2
 296     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 297     AC_LIBOBJ([freeaddrinfo])
 298     AC_LIBOBJ([gai_strerror])
 299     ;;
 300   *nacl*)
 301     SYS=nacl
 302     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 303     AC_LIBOBJ([sigwait])
 304     ;;
 305   *)
 306     SYS="${host_os}"
 307     ;;
 308 esac
 309
 310 dnl WinRT
 311 AC_ARG_ENABLE(winstore_app,
 312      AS_HELP_STRING([--enable-winstore-app],
 313                     [Build targetted for Windows Store apps (default disabled)]))
 314
 315 vlc_winstore_app=0
 316 AS_IF([test "${SYS}" = "mingw32"],[
 317   LIBCOM="-lole32"
 318   AS_IF([test "${enable_winstore_app}" = "yes"], [
 319     vlc_winstore_app=1
 320     LIBCOM=""
 321      VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
 322      AC_LIBOBJ([gai_strerror])
 323     ],[])
 324   AC_SUBST(LIBCOM)
 325   ])
 326 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 327
 328 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 329 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 330
 331 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 332 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
 333 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
 334 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
 335
 336 AM_CONDITIONAL(HAVE_NACL,    test "${SYS}" = "nacl")
 337
 338 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 339 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
 340 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 341 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
 342
 343 dnl
 344 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 345 dnl for program foo on win32
 346 case "${build_os}" in
 347     cygwin|msys|mingw32)
 348         ac_executable_extensions=".exe"
 349         BUILDEXEEXT=".exe"
 350     ;;
 351     os2*)
 352         BUILDEXEEXT=".exe"
 353     ;;
 354     *)
 355     ;;
 356 esac
 357 AC_SUBST(BUILDEXEEXT)
 358
 359 dnl Android is linux, but a bit different
 360 AS_IF([test "$SYS" = linux],[
 361     AC_MSG_CHECKING([for an Android system])
 362     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 363         [[#ifndef __ANDROID__
 364          # error Not Android
 365          #endif
 366         ]],[[;]])
 367     ],[
 368       HAVE_ANDROID="1"
 369       AC_MSG_RESULT([yes])
 370     ],[
 371       AC_MSG_RESULT([no])
 372     ])
 373 ])
 374 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 375
 376 dnl Tizen (minimum SDK version: 2.3)
 377 AS_IF([test "$SYS" = linux],[
 378     AC_MSG_CHECKING([for Tizen])
 379     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 380         [[#include <tizen.h>
 381         ]],[[;]])
 382     ],[
 383       HAVE_TIZEN="1"
 384       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
 385       AC_MSG_RESULT([yes])
 386     ],[
 387       AC_MSG_RESULT([no])
 388     ])
 389 ])
 390 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
 391
 392 dnl
 393 dnl  Check for the contrib directory
 394 dnl
 395 AC_ARG_WITH(contrib,
 396   [AS_HELP_STRING([--with-contrib[=DIR]],
 397     [search for 3rd party libraries in DIR/include and DIR/lib])
 398 ])
 399 AC_MSG_CHECKING([for 3rd party libraries path])
 400 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 401   CONTRIB_DIR="${srcdir}/contrib/${host}"
 402   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 403     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 404     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 405     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 406       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 407       CONTRIB_DIR=""
 408       AC_MSG_RESULT([not found])
 409     ])
 410   ])
 411 ], [
 412   AS_IF([test "${with_contrib}" != "no"], [
 413     CONTRIB_DIR="${with_contrib}"
 414   ], [
 415     CONTRIB_DIR=""
 416     AC_MSG_RESULT([disabled])
 417   ])
 418 ])
 419 AS_IF([test -n "${CONTRIB_DIR}"], [
 420   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 421     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 422   ], [
 423     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 424     CONTRIB_DIR=""
 425     AC_MSG_RESULT([not usable])
 426   ])
 427
 428 ])
 429 AS_IF([test -n "${CONTRIB_DIR}"], [
 430   AC_MSG_RESULT([${CONTRIB_DIR}])
 431   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 432   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 433   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 434   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
 435   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 436   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 437
 438   AS_IF([test -z "$LUAC"], [
 439     dnl Old contribs mixed cross-tools and cross-compiled executables
 440     AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
 441       LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
 442     ])
 443
 444     dnl Newer contribs follow usual name space rules
 445     AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
 446       LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
 447     ])
 448   ])
 449
 450   AS_IF([test "${SYS}" = "darwin"], [
 451     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 452     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 453   ])
 454 ], [
 455   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 456     AC_MSG_ERROR([Third party libraries not found!])
 457   ])
 458 ])
 459 AC_SUBST(CONTRIB_DIR)
 460
 461 dnl Add extras/tools to the PATH
 462 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 463 AS_IF([test -d "${TOOLS_DIR}"], [
 464     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 465     export PATH="${TOOLS_DIR}":$PATH
 466 ])
 467
 468 dnl
 469 dnl  Libtool
 470 dnl  It's very bad, but our former custom system was worst
 471 dnl  -- Courmisch
 472 dnl
 473
 474 dnl override platform specific check for dependent libraries
 475 dnl otherwise libtool linking of shared libraries will
 476 dnl fail on anything other than pass_all.
 477 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 478     [lt_cv_deplibs_check_method=pass_all])
 479
 480 LT_INIT([dlopen win32-dll shared disable-static])
 481 LT_LANG([C++])
 482 LT_LANG([Windows Resource])
 483
 484 DOLT
 485
 486 lt_cv_deplibs_check_method=pass_all
 487
 488 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 489   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 490 ])
 491
 492 dnl
 493 dnl Gettext stuff
 494 dnl
 495 AM_GNU_GETTEXT_VERSION([0.19.8])
 496 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 497
 498 dnl
 499 dnl Iconv stuff
 500 dnl
 501 AM_ICONV
 502
 503 dnl
 504 dnl checks for mingw
 505 AS_IF([test "${SYS}" = "mingw32"], [
 506
 507 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 508 #if !defined(__MINGW32__)
 509 # error Not compiling with mingw
 510 #endif
 511     ])], [
 512
 513 dnl Check for broken versions of mingw-runtime compatability library
 514     AC_MSG_CHECKING(for broken mingw-runtime)
 515     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 516 #include <_mingw.h>
 517 #if defined(__MINGW64_VERSION_MAJOR)
 518 # if __MINGW64_VERSION_MAJOR < 3
 519 #  error Attempting to use mingw-runtime with broken vsnprintf support
 520 # endif
 521 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
 522 # error Attempting to use mingw-runtime with broken vsnprintf support
 523 #endif
 524     ])], [
 525         AC_MSG_RESULT([ok])
 526     ], [
 527         AC_MSG_RESULT([present])
 528         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
 529     ])
 530
 531     dnl force use of mingw provided c99 *printf over msvcrt
 532     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 533
 534     dnl Add WinMainCRTStartup entry point to show it's a WinMain application
 535     VLC_ADD_LDFLAGS([vlc],[-mwindows])
 536
 537     dnl Check for the need to include the mingwex lib for mingw32
 538     VLC_SAVE_FLAGS
 539     AC_CHECK_LIB(mingwex,opendir,
 540         AC_CHECK_LIB(mingw32,opendir,,
 541             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 542     )
 543     VLC_RESTORE_FLAGS
 544     ], [
 545         AC_MSG_RESULT([Not compiling with mingw])
 546     ])
 547
 548     dnl Check for fnative-struct or mms-bitfields support for mingw32
 549     VLC_SAVE_FLAGS
 550     CFLAGS="${CFLAGS} -mms-bitfields"
 551     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
 552     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 553         [ac_cv_c_mms_bitfields],
 554         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 555     if test "${ac_cv_c_mms_bitfields}" = "no"; then
 556         VLC_RESTORE_FLAGS
 557         CFLAGS="${CFLAGS} -fnative-struct"
 558         CXXFLAGS="${CXXFLAGS} -fnative-struct"
 559         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 560             [ac_cv_c_fnative_struct],
 561             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 562         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
 563     fi
 564 ])
 565
 566
 567 dnl
 568 dnl Buggy glibc prevention. Purposedly not cached.
 569 dnl See sourceware.org bugs 5058 and 5443.
 570 dnl Ubuntu alone has 20 bug numbers for this...
 571 dnl
 572 AC_MSG_CHECKING(for buggy GNU/libc versions)
 573 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 574 #include <limits.h>
 575 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 576   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 577 # error GNU/libc with dcgettext killer bug!
 578 #endif
 579 ])], [
 580   AC_MSG_RESULT([not present])
 581 ], [
 582   AC_MSG_RESULT([found])
 583   AS_IF([test "x${enable_nls}" != "xno"], [
 584     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 585 work-around for this. Check with your distribution vendor on how to update the
 586 glibc run-time. Alternatively, build with --disable-nls.])
 587   ])
 588 ])
 589
 590 dnl Plugin compilation stuff
 591
 592 VLC_LIBRARY_SUFFIX
 593
 594 dnl Check for system libs needed
 595 need_libc=false
 596
 597 dnl Check for usual libc functions
 598 AC_CHECK_FUNCS([daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime tdestroy uselocale])
 599 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv memrchr nrand48 poll posix_memalign recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tfind timegm timespec_get strverscmp])
 600 AC_REPLACE_FUNCS([gettimeofday])
 601 AC_CHECK_FUNC(fdatasync,,
 602   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 603 ])
 604
 605 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
 606
 607 dnl mingw64 implements those as static inline, not functions with C linkage
 608 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
 609 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
 610 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
 611 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
 612
 613 dnl C11 static_assert()
 614 AC_MSG_CHECKING([for static_assert in assert.h])
 615 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 616 static_assert(1, "The impossible happened.");
 617 ])], [
 618   AC_MSG_RESULT([yes])
 619   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 620 ], [
 621   AC_MSG_RESULT([no])
 622 ])
 623
 624 # Windows CE does not have strcoll()
 625 AC_FUNC_STRCOLL
 626
 627 dnl Check for non-standard system calls
 628 case "$SYS" in
 629   "linux")
 630     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity recvmmsg])
 631     ;;
 632   "mingw32")
 633     AC_CHECK_FUNCS([_lock_file])
 634     ;;
 635 esac
 636
 637 AH_BOTTOM([#include <vlc_fixups.h>])
 638
 639 dnl Check for struct pollfd
 640 AC_CHECK_TYPES([struct pollfd],,,
 641 [#include <sys/types.h>
 642 #if HAVE_POLL
 643 # include <poll.h>
 644 #elif defined (_WIN32)
 645 # include <winsock2.h>
 646 #endif
 647 ])
 648
 649 dnl Check for struct timespec
 650 AC_CHECK_TYPES([struct timespec],,,
 651 [#include <time.h>])
 652
 653 dnl Check for max_align_t
 654 AC_CHECK_TYPES([max_align_t],,,
 655 [#include <stddef.h>])
 656
 657 dnl Checks for socket stuff
 658 VLC_SAVE_FLAGS
 659 SOCKET_LIBS=""
 660 AC_SEARCH_LIBS(connect, [socket], [
 661   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 662     SOCKET_LIBS="$ac_cv_search_connect"
 663   ])
 664 ], [
 665   AS_IF([test "${SYS}" = "mingw32"], [
 666     SOCKET_LIBS="-lws2_32"
 667   ])
 668 ])
 669
 670 AC_SEARCH_LIBS([inet_pton], [nsl], [
 671  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
 672     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
 673   ])
 674 ],, [${SOCKET_LIBS}])
 675
 676 LIBS="${LIBS} ${SOCKET_LIBS}"
 677 AC_LINK_IFELSE([
 678     AC_LANG_PROGRAM([#ifdef _WIN32
 679         # if _WIN32_WINNT < 0x600
 680         #  error Needs vista+
 681         # endif
 682         #include <ws2tcpip.h>
 683         #else
 684         #include <sys/socket.h>
 685         #include <arpa/inet.h>
 686         #endif], [
 687         char dst[[sizeof(struct in_addr)]];
 688         inet_pton(AF_INET, "127.0.0.1", dst);
 689     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 690 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
 691 VLC_RESTORE_FLAGS
 692 AC_SUBST(SOCKET_LIBS)
 693
 694 dnl Check for socklen_t
 695 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 696 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 697 ac_cv_type_socklen_t,
 698 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 699 [#include <sys/types.h>
 700 #ifdef _WIN32
 701 # include <winsock2.h>
 702 # include <ws2tcpip.h>
 703 #else
 704 # include <sys/socket.h>
 705 #endif]], [[socklen_t len; len = 0;]])],
 706 ac_cv_type_socklen_t=yes,
 707 ac_cv_type_socklen_t=no)])
 708 AS_IF([test "$ac_cv_type_socklen_t" = no],
 709  [AC_DEFINE(socklen_t, int)])
 710
 711 dnl Check for struct sockaddr_storage
 712 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 713 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 714 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 715   [AC_TRY_COMPILE(
 716     [#include <sys/types.h>
 717      #if defined( _WIN32 )
 718      # include <winsock2.h>
 719      #else
 720      # include <sys/socket.h>
 721      #endif], [struct sockaddr_storage addr;],
 722      ac_cv_struct_sockaddr_storage=yes,
 723      ac_cv_struct_sockaddr_storage=no)])
 724 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 725   AC_DEFINE(sockaddr_storage, sockaddr)
 726   AC_DEFINE(ss_family, sa_family)
 727 ])
 728
 729 dnl FreeBSD has a gnugetopt library for this:
 730 GNUGETOPT_LIBS=""
 731 AC_CHECK_FUNC(getopt_long,, [
 732   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 733     GNUGETOPT_LIBS="-lgnugetopt"
 734   ])
 735 ])
 736 AC_SUBST(GNUGETOPT_LIBS)
 737
 738 AC_CHECK_LIB(m,cos,[
 739   LIBM="-lm"
 740 ], [
 741   LIBM=""
 742 ])
 743 AC_SUBST(LIBM)
 744
 745 AC_CHECK_LIB(m,lrintf, [
 746   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 747   VLC_ADD_LIBS([skins2],[-lm])
 748 ])
 749 AC_CHECK_LIB(m,nanf,
 750   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 751 )
 752 AC_CHECK_LIB(m,sincos, [
 753   AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
 754 ], [
 755   AC_LIBOBJ([sincos])
 756 ])
 757
 758 dnl Check for dynamic plugins
 759 LIBDL=""
 760 have_dynamic_objects="no"
 761 VLC_SAVE_FLAGS
 762 AC_SEARCH_LIBS(dlsym, [dl svld], [
 763   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 764     LIBDL="$ac_cv_search_dlsym"
 765   ])
 766   have_dynamic_objects="yes"
 767 ])
 768 VLC_RESTORE_FLAGS
 769
 770 # Windows
 771 AS_IF([test "${SYS}" = "mingw32"], [
 772   LIBDL=""
 773   have_dynamic_objects="yes" #assume we can use shared objects
 774 ])
 775
 776 AS_IF([test "${enable_shared}" = "no"], [
 777   have_dynamic_objects=no
 778 ])
 779 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 780
 781 AC_SUBST(LIBDL)
 782
 783 dnl Check for thread library
 784 LIBPTHREAD=""
 785 AS_IF([test "${SYS}" != "mingw32"], [
 786   VLC_SAVE_FLAGS
 787   LIBS=""
 788   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 789     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 790       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 791     ])
 792   ])
 793   VLC_RESTORE_FLAGS
 794 ])
 795 AC_SUBST(LIBPTHREAD)
 796
 797 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
 798   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
 799     LIBRT="$ac_cv_search_clock_nanosleep"
 800   ])
 801 ], [
 802   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
 803     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
 804       LIBRT="$ac_cv_search_nanosleep"
 805     ])
 806   ])
 807 ])
 808 AC_SUBST(LIBRT)
 809
 810 dnl
 811 dnl Check for headers
 812 dnl
 813
 814 dnl  POSIX
 815 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
 816 AC_CHECK_HEADERS([net/if.h], [], [],
 817 [
 818 #include <sys/types.h>
 819 #include <sys/socket.h>
 820 ])
 821 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
 822 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
 823
 824 dnl  BSD
 825 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
 826
 827 dnl  GNU/Linux
 828 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 829
 830 dnl  MacOS
 831 AC_CHECK_HEADERS([xlocale.h])
 832
 833 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 834 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 835 AC_CHECK_TYPE(ssize_t,, [
 836   AC_DEFINE(ssize_t, int)
 837 ])
 838
 839 dnl It seems that autoconf detects pkg-config only during the first
 840 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 841 dnl it is nested within a conditional block, so it was not working right.
 842 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 843 AC_ARG_VAR(PKG_CONFIG_PATH,
 844        [Paths where to find .pc not at the default location])
 845 PKG_PROG_PKG_CONFIG()
 846
 847 dnl On some OS we need static linking
 848 AS_IF([test -n "${PKG_CONFIG}" ],[
 849     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 850         PKG_CONFIG="${PKG_CONFIG} --static"
 851     ])
 852 ])
 853
 854
 855 dnl
 856 dnl Check for zlib.h and -lz along with system -lminizip if available
 857 dnl
 858 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 859 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 860 if test "${have_zlib}" = "yes"
 861 then
 862   VLC_ADD_LIBS([sap],[-lz])
 863   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 864     AC_CHECK_HEADERS([unzip.h], [
 865       have_minizip=yes
 866       MINIZIP_LIBS="-lminizip -lz"
 867     ], [
 868       have_minizip=no
 869     ])
 870   ])
 871 fi
 872 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 873
 874
 875 dnl
 876 dnl Domain name i18n support via GNU libidn
 877 dnl
 878 PKG_CHECK_MODULES([IDN], [libidn], [
 879   have_libidn="yes"
 880   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 881 ], [
 882   have_libidn="no"
 883 ])
 884
 885
 886 dnl Check for dbus
 887 AC_ARG_ENABLE(dbus,
 888   [AS_HELP_STRING([--enable-dbus],
 889     [compile D-Bus message bus support (default enabled)])])
 890 have_dbus="no"
 891 AS_IF([test "${enable_dbus}" != "no"], [
 892   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 893     have_dbus="yes"
 894   ], [
 895     AS_IF([test -n "${enable_dbus}"], [
 896       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 897     ], [
 898       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 899     ])
 900   ])
 901 ])
 902 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 903
 904
 905 dnl Check for systemd
 906 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
 907   have_systemd="yes"
 908 ], [
 909   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
 910 ])
 911 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
 912
 913
 914 dnl Check for ntohl, etc.
 915 VLC_SAVE_FLAGS
 916 CFLAGS="${CFLAGS} -Wall -Werror"
 917 AC_CACHE_CHECK([for ntohl in sys/param.h],
 918     [ac_cv_c_ntohl_sys_param_h],
 919     [     AC_TRY_COMPILE([#include <sys/param.h>],
 920         [int meuh; ntohl(meuh);],
 921         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
 922 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
 923     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
 924 fi
 925 VLC_RESTORE_FLAGS
 926
 927 EXTEND_HELP_STRING([Optimization options:])
 928 dnl
 929 dnl  Compiler warnings
 930 dnl
 931
 932 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration init-self logical-op format-security])
 933 RDC_PROG_CC_FLAGS([-pipe])
 934 AC_LANG_PUSH([C++])
 935 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var format-security])
 936 AC_LANG_POP([C++])
 937
 938 dnl
 939 dnl  Debugging mode
 940 dnl
 941 AC_ARG_ENABLE(debug,
 942   [AS_HELP_STRING([--enable-debug],
 943     [build with run-time assertions (default disabled)])],,
 944   [enable_debug="no"])
 945 AH_TEMPLATE(NDEBUG,
 946             [Define to 1 if debug code should NOT be compiled])
 947 AS_IF([test "${enable_debug}" != "no"], [
 948   AC_CHECK_HEADERS([valgrind/valgrind.h])
 949 ], [
 950   AC_DEFINE(NDEBUG)
 951 ])
 952
 953 dnl
 954 dnl  Profiling
 955 dnl
 956 AC_ARG_ENABLE(gprof,
 957   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 958   [enable_gprof="no"])
 959 AS_IF([test "${enable_gprof}" != "no"], [
 960   CFLAGS="${CFLAGS} -pg"
 961   CXXFLAGS="${CXXFLAGS} -pg"
 962   OBJCFLAGS="${OBJCFLAGS} -pg"
 963   LDFLAGS="${LDFLAGS} -pg"
 964 ])
 965
 966 AC_ARG_ENABLE(cprof,
 967   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 968   [enable_cprof="no"])
 969 AS_IF([test "${enable_gprof}" != "no"], [
 970   CFLAGS="${CFLAGS} -finstrument-functions"
 971   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 972   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 973   LDFLAGS="${LDFLAGS} -finstrument-functions"
 974 ])
 975
 976 dnl
 977 dnl  Test coverage
 978 dnl
 979 AC_ARG_ENABLE(coverage,
 980   [AS_HELP_STRING([--enable-coverage],
 981     [build for test coverage (default disabled)])],,
 982   [enable_coverage="no"])
 983 AS_IF([test "${enable_coverage}" != "no"], [
 984   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 985   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 986   LDFLAGS="-lgcov ${LDFLAGS}"
 987 ])
 988
 989 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
 990   VLC_SAVE_FLAGS
 991   CFLAGS="${CFLAGS} -fvisibility=hidden"
 992   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
 993   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
 994   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
 995                  [ac_cv_c_visibility_hidden], [
 996     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 997       ac_cv_c_visibility_hidden=yes
 998     ], [
 999       ac_cv_c_visibility_hidden=no
1000     ])
1001   ])
1002   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1003 ])
1004
1005
1006 dnl
1007 dnl  Enable/disable optimizations
1008 dnl
1009 AC_ARG_ENABLE(optimizations,
1010   [AS_HELP_STRING([--disable-optimizations],
1011     [disable compiler optimizations (default enabled)])],,
1012   [enable_optimizations="yes"])
1013
1014 dnl Check for various optimization flags
1015 AS_IF([test "${enable_optimizations}" != "no"], [
1016
1017   dnl -O3 only in production builds
1018   AS_IF([test "${enable_debug}" = "no"], [
1019     VLC_SAVE_FLAGS
1020     CFLAGS="${CFLAGS} -O3"
1021     CXXFLAGS="${CXXFLAGS} -O3"
1022     OBJCFLAGS="${OBJCFLAGS} -O3"
1023     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1024       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1025         ac_cv_c_o3=yes
1026       ], [
1027         ac_cv_c_o3=no
1028       ])
1029     ])
1030     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1031   ])
1032
1033   dnl Check for fast maths
1034   RDC_PROG_CC_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1035   AC_LANG_PUSH(C++)
1036   RDC_PROG_CXX_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1037   AC_LANG_POP
1038
1039 AH_BOTTOM([
1040 #if defined(_MSC_VER) && !defined(__clang__)
1041 # pragma fenv_access(off)
1042 # pragma fp_contract(on)
1043 #elif defined(__GNUC__)
1044 /* Not supported so far */
1045 #else
1046 # pragma STDC FENV_ACCESS OFF
1047 # pragma STDC FP_CONTRACT ON
1048 #endif
1049 ])
1050
1051   dnl Check for -funroll-loops
1052   VLC_SAVE_FLAGS
1053   CFLAGS="${CFLAGS} -funroll-loops"
1054   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1055   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1056   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1057     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1058       ac_cv_c_unroll_loops=yes
1059     ], [
1060       ac_cv_c_unroll_loops=no
1061     ])
1062   ])
1063   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1064
1065   AS_IF([test "$enable_debug" = "no"], [
1066     dnl Check for -fomit-frame-pointer
1067     VLC_SAVE_FLAGS
1068     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1069     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1070     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1071     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1072       [ac_cv_c_omit_frame_pointer], [
1073       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1074         ac_cv_c_omit_frame_pointer=yes
1075       ], [
1076         ac_cv_c_omit_frame_pointer=no
1077       ])
1078     ])
1079     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1080   ])
1081 ])
1082
1083 VLC_SAVE_FLAGS
1084 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1085 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1086   AC_TRY_LINK([],, [
1087     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1088   ], [
1089     ac_cv_ld_bsymbolic=""
1090   ])
1091 ])
1092 VLC_RESTORE_FLAGS
1093 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1094 AC_SUBST(SYMBOLIC_LDFLAGS)
1095
1096 VLC_SAVE_FLAGS
1097 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1098 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1099   AC_TRY_LINK([],, [
1100     ac_cv_ld_z_defs="yes"
1101   ], [
1102     ac_cv_ld_z_defs="no"
1103   ])
1104 ])
1105 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1106
1107 dnl Check for __attribute__((packed))
1108 AC_CACHE_CHECK([for __attribute__((packed))],
1109   [ac_cv_c_attribute_packed],
1110   [ac_cv_c_attribute_packed=no
1111    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1112                     [ac_cv_c_attribute_packed=yes])])
1113 if test "${ac_cv_c_attribute_packed}" != "no"; then
1114   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1115 fi
1116
1117 dnl
1118 dnl  Check the CPU
1119 dnl
1120 case "${host_cpu}" in
1121   "")
1122     ARCH=unknown
1123     ;;
1124   *)
1125     ARCH="${host_cpu}"
1126     ;;
1127 esac
1128
1129 dnl Check for backtrace() support
1130 AC_CHECK_HEADERS(execinfo.h)
1131 AC_CHECK_FUNCS(backtrace)
1132
1133 dnl
1134 dnl  default modules
1135 dnl
1136 ALIASES="${ALIASES} cvlc rvlc"
1137
1138 dnl
1139 dnl  Accelerated modules
1140 dnl
1141
1142 dnl  Check for fully working MMX intrinsics
1143 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1144 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1145 AC_ARG_ENABLE(mmx,
1146   [AS_HELP_STRING([--disable-mmx],
1147     [disable MMX optimizations (default auto)])],,[
1148   case "${host_cpu}" in
1149     i?86|x86_64)
1150       enable_mmx="yes"
1151       ;;
1152     *)
1153       enable_mmx="no"
1154       ;;
1155   esac
1156 ])
1157 have_mmx="no"
1158 have_mmxext="no"
1159 AS_IF([test "${enable_mmx}" != "no"], [
1160   ARCH="${ARCH} mmx"
1161   VLC_SAVE_FLAGS
1162   CFLAGS="${CFLAGS} -mmmx"
1163   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1164     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1165 [#include <mmintrin.h>
1166 #include <stdint.h>
1167 uint64_t frobzor;]], [
1168 [__m64 a, b, c;
1169 a = b = c = (__m64)frobzor;
1170 a = _mm_slli_pi16(a, 3);
1171 a = _mm_adds_pi16(a, b);
1172 c = _mm_srli_pi16(c, 8);
1173 c = _mm_slli_pi16(c, 3);
1174 b = _mm_adds_pi16(b, c);
1175 a = _mm_unpacklo_pi8(a, b);
1176 frobzor = (uint64_t)a;]])], [
1177       ac_cv_c_mmx_intrinsics=yes
1178     ], [
1179       ac_cv_c_mmx_intrinsics=no
1180     ])
1181   ])
1182   VLC_RESTORE_FLAGS
1183   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1184     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1185   ])
1186
1187   VLC_SAVE_FLAGS
1188   CFLAGS="${CFLAGS} -mmmx"
1189   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1190     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1191 void *p;
1192 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1193 ]])
1194     ], [
1195       ac_cv_mmx_inline=yes
1196     ], [
1197       ac_cv_mmx_inline=no
1198     ])
1199   ])
1200   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1201     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1202     have_mmx="yes"
1203   ])
1204
1205   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1206                  [ac_cv_mmxext_inline], [
1207     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1208 void *p;
1209 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1210 ]])
1211     ], [
1212       ac_cv_mmxext_inline=yes
1213     ], [
1214       ac_cv_mmxext_inline=no
1215     ])
1216   ])
1217   VLC_RESTORE_FLAGS
1218   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1219     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1220     have_mmxext="yes"
1221   ])
1222 ])
1223 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1224 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1225
1226 dnl  Check for fully workin SSE2 intrinsics
1227 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1228 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1229 AC_ARG_ENABLE(sse,
1230   [AS_HELP_STRING([--disable-sse],
1231     [disable SSE (1-4) optimizations (default auto)])],, [
1232   case "${host_cpu}" in
1233     i?86|x86_64)
1234       enable_sse=yes
1235       ;;
1236     *)
1237       enable_sse=no
1238       ;;
1239   esac
1240 ])
1241 have_sse2="no"
1242 AS_IF([test "${enable_sse}" != "no"], [
1243   ARCH="${ARCH} sse sse2"
1244
1245   VLC_SAVE_FLAGS
1246   CFLAGS="${CFLAGS} -msse2"
1247   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1248     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1249 [#include <emmintrin.h>
1250 #include <stdint.h>
1251 uint64_t frobzor;]], [
1252 [__m128i a, b, c;
1253 a = b = c = _mm_set1_epi64((__m64)frobzor);
1254 a = _mm_slli_epi16(a, 3);
1255 a = _mm_adds_epi16(a, b);
1256 c = _mm_srli_epi16(c, 8);
1257 c = _mm_slli_epi16(c, 3);
1258 b = _mm_adds_epi16(b, c);
1259 a = _mm_unpacklo_epi8(a, b);
1260 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1261       ac_cv_c_sse2_intrinsics=yes
1262     ], [
1263       ac_cv_c_sse2_intrinsics=no
1264     ])
1265   ])
1266   VLC_RESTORE_FLAGS
1267   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1268     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1269   ])
1270
1271   VLC_SAVE_FLAGS
1272   CFLAGS="${CFLAGS} -msse"
1273   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1274     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1275 void *p;
1276 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1277 ]])
1278     ], [
1279       ac_cv_sse_inline=yes
1280     ], [
1281       ac_cv_sse_inline=no
1282     ])
1283   ])
1284
1285   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1286     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1287   ])
1288
1289   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1290     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1291 void *p;
1292 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1293 ]])
1294     ], [
1295       ac_cv_sse2_inline=yes
1296     ], [
1297       ac_cv_sse2_inline=no
1298     ])
1299   ])
1300   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1301     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1302     have_sse2="yes"
1303   ])
1304
1305   # SSE3
1306   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1307     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1308 void *p;
1309 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1310 ]])
1311     ], [
1312       ac_cv_sse3_inline=yes
1313     ], [
1314       ac_cv_sse3_inline=no
1315     ])
1316   ])
1317
1318   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1319     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1320   # SSSE3
1321   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1322     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1323 void *p;
1324 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1325 ]])
1326     ], [
1327       ac_cv_ssse3_inline=yes
1328     ], [
1329       ac_cv_ssse3_inline=no
1330     ])
1331   ])
1332
1333   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1334     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1335
1336   # SSE4.1
1337   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1338                  [ac_cv_sse4_1_inline], [
1339     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1340 void *p;
1341 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1342 ]])
1343     ], [
1344       ac_cv_sse4_1_inline=yes
1345     ], [
1346       ac_cv_sse4_1_inline=no
1347     ])
1348   ])
1349
1350   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1351     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1352
1353   # SSE4.2
1354   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1355                  [ac_cv_sse4_2_inline], [
1356     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1357 void *p;
1358 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1359 ]])
1360     ], [
1361       ac_cv_sse4_2_inline=yes
1362     ], [
1363       ac_cv_sse4_2_inline=no
1364     ])
1365   ])
1366
1367   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1368     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1369
1370   # SSE4A
1371   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1372     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1373 void *p;
1374 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1375 ]])
1376     ], [
1377       ac_cv_sse4a_inline=yes
1378     ], [
1379       ac_cv_sse4a_inline=no
1380     ])
1381   ])
1382   VLC_RESTORE_FLAGS
1383   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1384     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1385 ])
1386 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1387
1388 VLC_SAVE_FLAGS
1389 CFLAGS="${CFLAGS} -mmmx"
1390 have_3dnow="no"
1391 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1392   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1393 void *p;
1394 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1395 ]])
1396   ], [
1397     ac_cv_3dnow_inline=yes
1398   ], [
1399     ac_cv_3dnow_inline=no
1400   ])
1401 ])
1402 VLC_RESTORE_FLAGS
1403 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1404   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1405             [Define to 1 if 3D Now! inline assembly is available.])
1406   have_3dnow="yes"
1407 ])
1408 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1409
1410
1411 AC_ARG_ENABLE(neon,
1412   [AS_HELP_STRING([--disable-neon],
1413     [disable NEON optimizations (default auto)])],, [
1414   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1415 ])
1416 AS_IF([test "${enable_neon}" != "no"], [
1417   VLC_SAVE_FLAGS
1418   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1419   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1420     AC_COMPILE_IFELSE([
1421       AC_LANG_PROGRAM(,[[
1422 asm volatile("vqmovun.s64 d0, q1":::"d0");
1423 ]])
1424     ], [
1425       ac_cv_arm_neon="yes"
1426     ], [
1427       ac_cv_arm_neon="no"
1428     ])
1429   ])
1430   VLC_RESTORE_FLAGS
1431 ])
1432 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1433
1434 AC_ARG_ENABLE(arm64,
1435   [AS_HELP_STRING([--disable-arm64],
1436     [disable arm 64-bit optimizations (default auto)])],, [
1437   AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1438 ])
1439 AS_IF([test "${enable_arm64}" != "no"], [
1440   AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1441     AC_COMPILE_IFELSE([
1442       AC_LANG_PROGRAM(,[[
1443 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1444 ]])
1445     ], [
1446       ac_cv_arm64="yes"
1447     ], [
1448       ac_cv_arm64="no"
1449     ])
1450   ])
1451 ])
1452 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1453
1454
1455 AC_ARG_ENABLE(altivec,
1456   [AS_HELP_STRING([--disable-altivec],
1457     [disable AltiVec optimizations (default auto)])],, [
1458   AS_CASE("${host_cpu}", [powerpc*],
1459         [enable_altivec=yes], [enable_altivec=no])
1460 ])
1461 have_altivec="no"
1462 ALTIVEC_CFLAGS=""
1463 AS_IF([test "${enable_altivec}" = "yes"], [
1464   ARCH="${ARCH} altivec";
1465   VLC_SAVE_FLAGS
1466   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1467     [ac_cv_altivec_inline],
1468     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1469          ac_cv_altivec_inline="yes",
1470          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1471           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1472             [ac_cv_altivec_inline="-Wa,-maltivec"],
1473             ac_cv_altivec_inline=no)
1474          ])])
1475   VLC_RESTORE_FLAGS
1476   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1477     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1478               [Define to 1 if AltiVec inline assembly is available.])
1479     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1480       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1481       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1482     ])
1483     have_altivec="yes"
1484   ])
1485
1486   VLC_SAVE_FLAGS
1487   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1488   [ac_cv_c_altivec], [
1489     CFLAGS="${CFLAGS} -maltivec"
1490     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1491 [#include <altivec.h>]], [
1492 [vec_ld(0, (unsigned char *)0);]])], [
1493       ac_cv_c_altivec="-maltivec"
1494     ], [
1495       ac_cv_c_altivec="no"
1496     ])
1497   ])
1498   VLC_RESTORE_FLAGS
1499   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1500     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1501     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1502     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1503     ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1504     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1505     have_altivec="yes"
1506   ])
1507   AC_CHECK_HEADERS(altivec.h)
1508
1509   VLC_SAVE_FLAGS
1510   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1511   AC_CACHE_CHECK([if linker needs -framework vecLib],
1512     [ac_cv_ld_altivec],
1513     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1514   VLC_RESTORE_FLAGS
1515   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1516     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1517   ])
1518 ])
1519 AC_SUBST(ALTIVEC_CFLAGS)
1520 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1521
1522 dnl
1523 dnl  Memory usage
1524 dnl
1525 AC_ARG_ENABLE(optimize-memory,
1526   [AS_HELP_STRING([--enable-optimize-memory],
1527     [optimize memory usage over performance])])
1528 if test "${enable_optimize_memory}" = "yes"; then
1529   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1530 fi
1531
1532 dnl
1533 dnl Allow running as root (useful for people running on embedded platforms)
1534 dnl
1535 AC_ARG_ENABLE(run-as-root,
1536   [AS_HELP_STRING([--enable-run-as-root],
1537     [allow running VLC as root (default disabled)])])
1538 AS_IF([test "${enable_run_as_root}" = "yes"],[
1539     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1540               [Define to 1 to allow running VLC as root (uid 0).])
1541 ])
1542
1543 dnl
1544 dnl Stream output
1545 dnl
1546 AC_ARG_ENABLE(sout,
1547   [AS_HELP_STRING([--disable-sout],
1548     [disable streaming output (default enabled)])])
1549 AS_IF([test "${enable_sout}" != "no"], [
1550   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1551 ])
1552 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1553
1554 dnl Lua modules
1555 AC_ARG_ENABLE(lua,
1556   [AS_HELP_STRING([--disable-lua],
1557     [disable LUA scripting support (default enabled)])])
1558 if test "${enable_lua}" != "no"
1559 then
1560   PKG_CHECK_MODULES(LUA, lua5.2,
1561     [ have_lua=yes ],
1562     [
1563     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1564
1565     PKG_CHECK_MODULES(LUA, lua5.1,
1566       [ have_lua=yes ],
1567       [
1568       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1569       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1570         [ have_lua=yes ],
1571         [
1572           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1573           have_lua=yes
1574           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1575             [],
1576             [ have_lua=no ] )
1577           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1578             [LUA_LIBS="-llua5.2"],
1579           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1580             [LUA_LIBS="-llua5.1"],
1581             AC_CHECK_LIB( lua51 , luaL_newstate,
1582               [LUA_LIBS="-llua51"],
1583               AC_CHECK_LIB( lua , luaL_newstate,
1584                 [LUA_LIBS="-llua"],
1585                 [ have_lua=no
1586                 ], [-lm])
1587             )))
1588         ])
1589       ])
1590     ])
1591   if test "x${have_lua}" != "xyes" ;  then
1592       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1593   fi
1594   AC_ARG_VAR([LUAC], [LUA byte compiler])
1595   AS_IF([test -z "$LUAC"], [
1596      AC_CHECK_TOOL(LUAC, [luac], [false])
1597   ])
1598   AS_IF([test "${LUAC}" = "false"], [
1599     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1600   ])
1601   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1602     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1603   ])
1604 fi
1605 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1606
1607
1608 dnl
1609 dnl HTTP daemon
1610 dnl
1611 AC_ARG_ENABLE(httpd,
1612   [AS_HELP_STRING([--disable-httpd],
1613     [disable the built-in HTTP server (default enabled)])])
1614 if test "${enable_httpd}" != "no"
1615 then
1616   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1617 fi
1618 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1619
1620
1621 dnl
1622 dnl VideoLAN manager
1623 dnl
1624 AC_ARG_ENABLE(vlm,
1625   [AS_HELP_STRING([--disable-vlm],
1626     [disable the stream manager (default enabled)])],,
1627   [enable_vlm="${enable_sout}"])
1628 AS_IF([test "${enable_vlm}" != "no"], [
1629   AS_IF([test "${enable_sout}" = "no"], [
1630     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1631   ])
1632   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1633 ])
1634 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1635
1636
1637 dnl
1638 dnl Addons manager storage and repositories modules
1639 dnl
1640 AC_ARG_ENABLE(addonmanagermodules,
1641   [AS_HELP_STRING([--disable-addonmanagermodules],
1642     [disable the addons manager modules (default enabled)])])
1643 if test "${enable_addonmanagermodules}" != "no"
1644 then
1645   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1646 fi
1647 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1648
1649
1650 dnl
1651 dnl  Input plugins
1652 dnl
1653
1654 EXTEND_HELP_STRING([Input plugins:])
1655
1656 dnl
1657 dnl  libarchive access module
1658 dnl
1659 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1660
1661 dnl
1662 dnl  live555 input
1663 dnl
1664 AC_ARG_ENABLE(live555,
1665   [AS_HELP_STRING([--enable-live555],
1666     [enable RTSP input through live555 (default enabled)])])
1667
1668 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1669   PKG_CHECK_MODULES(LIVE555, live555, [
1670     VLC_ADD_PLUGIN([live555])
1671     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1672     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1673   ], [
1674     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1675
1676     AC_LANG_PUSH(C++)
1677     VLC_SAVE_FLAGS
1678
1679     dnl detect include paths
1680     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1681       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1682     ], [
1683       AS_IF([test "${SYS}" != "os2"], [
1684         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1685         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1686       ], [
1687         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1688         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1689         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1690       ])
1691     ])
1692
1693     dnl CPP Flags
1694     AS_IF([test "${SYS}" = "solaris"], [
1695       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1696     ])
1697     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1698     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1699
1700     dnl version check
1701     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1702       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1703 [#include <liveMedia_version.hh>
1704 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1705 # error BOOM
1706 #endif]])
1707       ], [
1708         ac_cv_live555="yes"
1709       ], [
1710         ac_cv_live555="no"
1711       ])
1712     ])
1713
1714     AS_IF([test "$ac_cv_live555" = "no"], [
1715       AC_MSG_WARN([live555 is missing or its installed version is too old:
1716 Version 2011.12.23 or later is required to proceed.
1717 You can get an updated one from http://www.live555.com/liveMedia .])
1718       AS_IF([test -n "${enable_live555}"], [
1719         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1720       ])
1721     ], [
1722       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1723       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1724       AS_IF([test "${SYS}" = "mingw32"], [
1725         # add ws2_32 for closesocket, select, recv
1726         other_libs="$other_libs -lws2_32"
1727       ])
1728
1729       dnl We need to check for pic because live555 don't provide shared libs
1730       dnl and we want to build a plugins so we need -fPIC on some arch.
1731       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1732       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1733       AC_CHECK_LIB(liveMedia_pic, main, [
1734         VLC_ADD_PLUGIN([live555])
1735         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1736       ],[
1737         AC_CHECK_LIB(liveMedia, main, [
1738           VLC_ADD_PLUGIN([live555])
1739           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1740         ],[],[${other_libs}])
1741       ],[${other_libs_pic}])
1742     ])
1743     VLC_RESTORE_FLAGS
1744     AC_LANG_POP(C++)
1745   ])
1746 ])
1747
1748 dnl
1749 dnl IIDC and DV FireWire input modules
1750 dnl
1751 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1752 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1753
1754 dnl
1755 dnl - linsys modules: access module check for libzvbi
1756 dnl
1757 AC_ARG_ENABLE(linsys,
1758   [AS_HELP_STRING([--enable-linsys],
1759     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1760 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1761   VLC_ADD_PLUGIN([linsys_hdsdi])
1762   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1763     VLC_ADD_PLUGIN([linsys_sdi])
1764   ], [
1765     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1766   ])
1767 ])
1768
1769 dnl
1770 dnl dvdread module: check for libdvdread
1771 dnl
1772 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1773
1774 dnl
1775 dnl libdvdnav plugin
1776 dnl
1777 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1778 AS_IF([test "${enable_dvdnav}" != "no"], [
1779   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1780     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1781       AC_MSG_RESULT(yes)
1782       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1783       ],[
1784       AC_MSG_RESULT(no)
1785     ])
1786 ])
1787
1788 dnl
1789 dnl  Blu-ray Disc Support with libbluray
1790 dnl
1791 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1792
1793 dnl
1794 dnl  OpenCV wrapper and example filters
1795 dnl
1796 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1797
1798
1799 dnl
1800 dnl  libsmbclient plugin
1801 dnl
1802 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1803 AS_IF([test "${SYS}" = "mingw32" -a "${enable_winstore_app}" != "yes"], [ VLC_ADD_PLUGIN([smb]) ])
1804
1805 dnl
1806 dnl  liBDSM access module
1807 dnl
1808 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1809
1810 dnl
1811 dnl sftp access support
1812 dnl
1813 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1814
1815 dnl
1816 dnl nfs access support
1817 dnl
1818 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1819
1820 dnl
1821 dnl  Video4Linux 2
1822 dnl
1823 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1824   [disable Video4Linux version 2 (default auto)])])
1825 have_v4l2="no"
1826 AS_IF([test "$enable_v4l2" != "no"], [
1827   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1828     have_v4l2="yes"
1829   ])
1830 ])
1831 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1832
1833 dnl
1834 dnl special access module for Blackmagic SDI cards
1835 dnl
1836 AC_ARG_ENABLE(decklink,
1837   [AS_HELP_STRING([--disable-decklink],
1838     [disable Blackmagic DeckLink SDI input (default auto)])])
1839 AC_ARG_WITH(decklink_sdk,
1840   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1841     [                        location of Blackmagic DeckLink SDI SDK])])
1842 have_decklink=no
1843 if test "${enable_decklink}" != "no"
1844 then
1845   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1846   then
1847     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1848   fi
1849   VLC_SAVE_FLAGS
1850   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1851   AC_LANG_PUSH(C++)
1852   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1853       have_decklink=yes
1854   ], [
1855       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1856   ])
1857   AC_LANG_POP(C++)
1858   VLC_RESTORE_FLAGS
1859 fi
1860 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1861
1862
1863 dnl
1864 dnl  Built-in CD-DA and VCD module
1865 dnl
1866 AC_ARG_ENABLE(vcd,
1867   [AS_HELP_STRING([--disable-vcd],
1868     [disable built-in VCD and CD-DA support (default enabled)])])
1869
1870 AC_ARG_ENABLE(libcddb,
1871   [AS_HELP_STRING([--disable-libcddb],
1872     [disable CDDB for Audio CD (default enabled)])])
1873
1874 if test "${enable_vcd}" != "no"
1875 then
1876   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1877   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1878     AC_MSG_RESULT(yes)
1879     VLC_ADD_PLUGIN([vcd cdda])
1880   ],[
1881     AC_MSG_RESULT(no)
1882   ])
1883
1884   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1885   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1886     AC_MSG_RESULT(yes)
1887     VLC_ADD_PLUGIN([vcd cdda])
1888     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1889   ],[
1890     AC_MSG_RESULT(no)
1891   ])
1892
1893   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1894   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1895     AC_MSG_RESULT(yes)
1896     VLC_ADD_PLUGIN([vcd cdda])
1897     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1898   ],[
1899     AC_MSG_RESULT(no)
1900   ])
1901
1902   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1903   then
1904     VLC_ADD_PLUGIN([vcd cdda])
1905   fi
1906
1907   if test "$enable_libcddb" != "no"; then
1908     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1909       HAVE_LIBCDDB=yes
1910       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1911       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1912       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1913       ],:
1914       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1915       HAVE_LIBCDDB=no])
1916   fi
1917 fi
1918
1919 dnl
1920 dnl Linux DVB
1921 dnl
1922 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1923   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1924 [#include <linux/dvb/version.h>
1925 #if (DVB_API_VERSION < 5)
1926 # error Linux DVB API v3.2 and older are not supported.
1927 #endif
1928 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1929 # error Linux DVB API v5.0 is unsupported. Please update.
1930 #endif
1931 ]])], [
1932   ac_cv_linux_dvb_5_1=yes
1933 ], [
1934   ac_cv_linux_dvb_5_1=no
1935 ])])
1936 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1937
1938 dnl
1939 dnl  Screen capture module
1940 dnl
1941 AC_ARG_ENABLE(screen,
1942   [AS_HELP_STRING([--enable-screen],
1943     [disable screen capture (default enabled)])])
1944 if test "${enable_screen}" != "no"; then
1945   if test "${SYS}" = "darwin"; then
1946     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1947       VLC_ADD_PLUGIN([screen])
1948     ])
1949   fi
1950 fi
1951 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1952
1953 dnl
1954 dnl  VNC/RFB access module
1955 dnl
1956 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1957
1958 dnl  RDP/Remote Desktop access module
1959 dnl
1960 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1961
1962 dnl
1963 dnl  Real RTSP plugin
1964 dnl
1965 AC_ARG_ENABLE(realrtsp,
1966   [  --enable-realrtsp       Real RTSP module (default disabled)])
1967 if test "${enable_realrtsp}" = "yes"; then
1968   VLC_ADD_PLUGIN([access_realrtsp])
1969 fi
1970
1971 dnl
1972 dnl QTKit
1973 AC_ARG_ENABLE(macosx-qtkit,
1974   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
1975 if test "x${enable_macosx_qtkit}" != "xno" &&
1976   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1977 then
1978   AC_CHECK_HEADERS(QTKit/QTKit.h, [
1979       VLC_ADD_PLUGIN([qtsound])
1980     ])
1981 fi
1982
1983 dnl
1984 dnl AVFoundation
1985 AC_SUBST(have_avfoundation, ["no"])
1986 AC_ARG_ENABLE(macosx-avfoundation,
1987   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
1988 if test "x${enable_macosx_avfoundation}" != "xno" &&
1989   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
1990 then
1991   SAVED_LIBS="${LIBS}"
1992   LIBS="-framework AVFoundation"
1993   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
1994   LIBS="${SAVED_LIBS}"
1995   if test "${have_avfoundation}" != "no"
1996   then
1997     VLC_ADD_PLUGIN([avcapture])
1998   fi
1999 fi
2000 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2001
2002 dnl
2003 dnl  DCP plugin (using asdcplib)
2004 dnl
2005 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2006 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2007
2008 dnl
2009 dnl  Demux plugins
2010 dnl
2011
2012 EXTEND_HELP_STRING([Mux/Demux plugins:])
2013
2014 dnl
2015 dnl  libdvbpsi check for ts mux/demux
2016 dnl
2017 have_dvbpsi="no"
2018 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2019 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2020
2021
2022 dnl
2023 dnl  GME demux plugin
2024 dnl
2025 AC_ARG_ENABLE(gme,
2026   [AS_HELP_STRING([--enable-gme],
2027     [use Game Music Emu (default auto)])])
2028 AS_IF([test "${enable_gme}" != "no"], [
2029   AC_CHECK_HEADER([gme/gme.h], [
2030     VLC_ADD_LIBS([gme], [-lgme])
2031     VLC_ADD_PLUGIN([gme])
2032   ], [
2033     AS_IF([test "x${enable_gme}" != "x"], [
2034       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2035     ])
2036   ])
2037 ])
2038
2039
2040 dnl
2041 dnl  SIDPlay plugin
2042 dnl
2043 AC_ARG_ENABLE(sid,
2044     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2045 AS_IF([test "${enable_sid}" != "no"], [
2046     PKG_CHECK_MODULES(SID, [libsidplay2], [
2047         AC_LANG_PUSH(C++)
2048         oldCPPFLAGS="$CPPFLAGS"
2049         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2050         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2051             VLC_ADD_PLUGIN([sid])
2052             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2053             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2054         ], [
2055             AS_IF([test -n "${enable_sid}"],
2056                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2057                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2058                 )
2059         ])
2060         CPPFLAGS="$oldCPPFLAGS"
2061         AC_LANG_POP(C++)
2062     ], [
2063         AS_IF([test "x${enable_sid}" = "xyes"],
2064             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2065             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2066             )
2067     ])
2068 ])
2069
2070
2071 dnl
2072 dnl  ogg demux plugin
2073 dnl
2074 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2075 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2076     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2077 ],[true])
2078 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2079 if test "${enable_sout}" != "no"; then
2080 dnl Check for libshout
2081     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2082 fi
2083
2084 dnl
2085 dnl  matroska demux plugin
2086 dnl
2087 PKG_ENABLE_MODULES_VLC([MATROSKA], [mkv], [libebml libmatroska], [MKV format support], [auto])
2088
2089 dnl
2090 dnl  modplug demux plugin
2091 dnl
2092 AC_ARG_ENABLE(mod,
2093   [AS_HELP_STRING([--disable-mod],
2094     [do not use libmodplug (default auto)])])
2095 if test "${enable_mod}" != "no" ; then
2096     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2097           VLC_ADD_PLUGIN([mod])
2098           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2099           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2100           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2101     ],[
2102        AS_IF([test -n "${enable_mod}"],
2103          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2104          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2105     ])
2106 fi
2107
2108 dnl
2109 dnl  mpc demux plugin
2110 dnl
2111 AC_ARG_ENABLE(mpc,
2112   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2113 if test "${enable_mpc}" != "no"
2114 then
2115   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2116     VLC_ADD_PLUGIN([mpc])
2117     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2118     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2119     VLC_ADD_PLUGIN([mpc])
2120     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2121 fi
2122
2123 dnl
2124 dnl  Codec plugins
2125 dnl
2126
2127 EXTEND_HELP_STRING([Codec plugins:])
2128
2129 dnl
2130 dnl wmafixed plugin
2131 dnl
2132 AC_ARG_ENABLE(wma-fixed,
2133   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2134 if test "${enable_wma_fixed}" = "yes"
2135 then
2136   VLC_ADD_PLUGIN([wma_fixed])
2137 fi
2138
2139 dnl
2140 dnl shine encoder plugin
2141 dnl
2142 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2143
2144
2145 dnl
2146 dnl openmax il codec plugin
2147 dnl
2148 AC_ARG_ENABLE(omxil,
2149   [  --enable-omxil          openmax il codec module (default disabled)])
2150 if test "${enable_omxil}" = "yes"
2151 then
2152   VLC_ADD_PLUGIN([omxil])
2153 fi
2154
2155 dnl
2156 dnl openmax il vout plugin
2157 dnl
2158 AC_ARG_ENABLE(omxil-vout,
2159   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2160 if test "${enable_omxil_vout}" = "yes"
2161 then
2162   VLC_ADD_PLUGIN([omxil_vout])
2163 fi
2164
2165 dnl
2166 dnl raspberry pi openmax il configuration
2167 dnl
2168 AC_ARG_ENABLE(rpi-omxil,
2169   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2170 if test "${enable_rpi_omxil}" = "yes"
2171 then
2172   VLC_ADD_PLUGIN([omxil omxil_vout])
2173   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2174 fi
2175
2176 dnl
2177 dnl CrystalHD codec plugin
2178 dnl
2179 AC_ARG_ENABLE(crystalhd,
2180   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2181 if test "${enable_crystalhd}" != "no"; then
2182     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2183       VLC_ADD_PLUGIN([crystalhd])
2184       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2185     ],[
2186       if test "${SYS}" = "mingw32" ; then
2187         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2188           VLC_ADD_PLUGIN([crystalhd])
2189           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2190             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2191             ])
2192         ],[
2193           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2194                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2195                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2196         ],[#define __LINUX_USER__
2197                #include <libcrystalhd/bc_dts_types.h>
2198         ])
2199       fi
2200     ],[
2201        #include <libcrystalhd/bc_dts_types.h>
2202       ])
2203 fi
2204
2205 dnl
2206 dnl  mad plugin
2207 dnl
2208 have_mad="no"
2209 MAD_CFLAGS=""
2210 MAD_LIBS=""
2211
2212 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2213   enable_mad="yes"
2214 ], [
2215   with_mad="no"
2216 ])
2217 AS_IF([test "${with_mad}" != "no"], [
2218   MAD_CFLAGS="-I${with_mad}/include"
2219   MAD_LIBS="-L${with_mad}/lib"
2220 ])
2221
2222 AC_ARG_ENABLE(mad,
2223   [  --enable-mad            libmad module (default enabled)])
2224 AS_IF([test "${enable_mad}" != "no"], [
2225   VLC_SAVE_FLAGS
2226   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2227   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2228   AC_CHECK_HEADERS(mad.h, [
2229     AC_CHECK_LIB(mad, mad_bit_init, [
2230       have_mad="yes"
2231       MAD_LIBS="${MAD_LIBS} -lmad"
2232     ])
2233   ])
2234   VLC_RESTORE_FLAGS
2235   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2236     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2237   ])
2238 ])
2239 AC_SUBST(MAD_CFLAGS)
2240 AC_SUBST(MAD_LIBS)
2241 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2242
2243 dnl  mpg123 plugin
2244 dnl
2245 dnl
2246 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2247
2248 dnl
2249 dnl gstreamer stuff
2250 dnl
2251 AC_ARG_ENABLE(gst-decode,
2252   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2253
2254 have_gst_decode="no"
2255 AS_IF([test "${enable_gst_decode}" != "no"], [
2256   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2257     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2258       have_gst_decode="yes"
2259     ], [
2260       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2261     ])
2262   ], [
2263     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2264   ])
2265 ])
2266 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2267
2268 dnl
2269 dnl  avcodec decoder/encoder plugin
2270 dnl
2271 AC_ARG_ENABLE(merge-ffmpeg,
2272 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2273   enable_merge_ffmpeg="no"
2274 ])
2275 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2276
2277 AC_MSG_CHECKING([for libavutil variant])
2278 PKG_CHECK_EXISTS([libavutil], [
2279   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2280   libavutil_micro="${libavutil_version##*.}"
2281   AS_IF([test ${libavutil_micro} -le 99], [
2282     avfork="libav"
2283   ], [
2284     avfork="ffmpeg"
2285   ])
2286 ], [
2287   avfork="none"
2288 ])
2289 AC_MSG_RESULT([${avfork}])
2290
2291 AC_ARG_ENABLE(avcodec,
2292 [  --enable-avcodec        libavcodec codec (default enabled)])
2293 AS_IF([test "${enable_avcodec}" != "no"], [
2294   dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2295   case "${avfork}" in
2296     libav) av_codec_ver="57.16.0" ;;
2297     ffmpeg) av_codec_ver="57.37.100" ;;
2298     *) AC_MSG_ERROR([Missing libav or FFmpeg])
2299   esac
2300   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2301     VLC_SAVE_FLAGS
2302     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2303     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2304     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2305     AC_CHECK_HEADERS(libavutil/avutil.h)
2306     VLC_RESTORE_FLAGS
2307     have_avcodec="yes"
2308   ],[
2309     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2310   ])
2311 ], [
2312   have_avcodec="no"
2313 ])
2314 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2315
2316 dnl
2317 dnl libva needs avcodec
2318 dnl
2319 AC_ARG_ENABLE(libva,
2320   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2321
2322 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2323   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2324 ])
2325
2326 have_vaapi="no"
2327 have_vaapi_drm="no"
2328 have_vaapi_x11="no"
2329 AS_IF([test "${enable_libva}" != "no"], [
2330   PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2331     have_vaapi="yes"
2332   ], [
2333     AS_IF([test -n "${enable_libva}"], [
2334       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2335     ], [
2336       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2337     ])
2338   ])
2339   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2340     have_vaapi_drm="yes"
2341   ], [
2342     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2343   ])
2344   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2345     have_vaapi_x11="yes"
2346   ], [
2347     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2348   ])
2349 ])
2350 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2351 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2352
2353 have_avcodec_vaapi="no"
2354 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2355   VLC_SAVE_FLAGS
2356   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2357   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2358   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2359     AC_MSG_NOTICE([VA API acceleration activated])
2360     have_avcodec_vaapi="yes"
2361   ],[
2362     AS_IF([test -n "${enable_libva}"], [
2363       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2364     ], [
2365       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2366     ])
2367   ])
2368   VLC_RESTORE_FLAGS
2369 ])
2370 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2371
2372 dnl
2373 dnl dxva2 needs avcodec
2374 dnl
2375 AC_ARG_ENABLE(dxva2,
2376   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2377
2378 have_avcodec_dxva2="no"
2379 AS_IF([test "${enable_dxva2}" != "no"], [
2380   if test "${SYS}" = "mingw32"; then
2381   AS_IF([test "x${have_avcodec}" = "xyes"], [
2382     AC_CHECK_HEADERS(dxva2api.h,
2383       [
2384         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2385            AC_MSG_NOTICE([DxVA2 acceleration activated])
2386            have_avcodec_dxva2="yes"
2387         ],[
2388     AS_IF([test "${enable_dxva2}" = "yes"],
2389           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2390               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2391         ], [#undef _WIN32_WINNT
2392             /* DXVA2 is only available in Vista and above */
2393             #define _WIN32_WINNT 0x600])
2394       ],[
2395     AS_IF([test "${enable_dxva2}" = "yes"],
2396               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2397               [AC_MSG_WARN([dxva2api.h not found])])
2398       ],[#include <d3d9.h>])
2399   ],[
2400     AS_IF([test "x${enable_dxva2}" != "x"], [
2401       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2402     ])
2403   ])
2404   fi
2405 ])
2406 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2407
2408 dnl
2409 dnl d3d11va needs avcodec
2410 dnl
2411 AC_ARG_ENABLE(d3d11va,
2412   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2413
2414 have_avcodec_d3d11va="no"
2415 AS_IF([test "${enable_d3d11va}" != "no"], [
2416   if test "${SYS}" = "mingw32"; then
2417   AS_IF([test "x${have_avcodec}" = "xyes"], [
2418         AC_CHECK_TYPES([ID3D11VideoDecoder],
2419           [
2420             AC_CHECK_HEADERS(dxva2api.h,
2421               [
2422                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2423                    AC_MSG_NOTICE([D3D11 acceleration activated])
2424                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2425                    have_avcodec_d3d11va="yes"
2426                 ],[
2427                   AS_IF([test "${enable_d3d11va}" = "yes"],
2428                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2429                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2430                   ], [#undef _WIN32_WINNT
2431                       /* D3D11 is only available in Vista and above */
2432                       #define _WIN32_WINNT 0x600])
2433                   ],[
2434                     AS_IF([test "${enable_d3d11va}" = "yes"],
2435                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2436                           [AC_MSG_WARN([dxva2api.h not found])])
2437                   ],[#include <d3d9.h>])
2438           ],[
2439             AS_IF([test "${enable_d3d11va}" = "yes"],
2440                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2441                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2442           ], [#include <d3d11.h>])
2443   ],[
2444     AS_IF([test "x${enable_d3d11va}" != "x"], [
2445       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2446     ])
2447   ])
2448   fi
2449 ])
2450 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2451
2452 dnl
2453 dnl DXGI debug
2454 dnl
2455 AC_CHECK_HEADERS(dxgidebug.h)
2456
2457 dnl
2458 dnl  avformat demuxer/muxer plugin
2459 dnl
2460
2461 AC_ARG_ENABLE(avformat,
2462 [  --enable-avformat       libavformat containers (default enabled)],, [
2463   enable_avformat="${have_avcodec}"
2464 ])
2465 have_avformat="no"
2466 AS_IF([test "${enable_avformat}" != "no"], [
2467   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2468       have_avformat="yes"
2469       VLC_SAVE_FLAGS
2470       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2471       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2472       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2473       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2474       AC_CHECK_HEADERS(libavutil/avutil.h)
2475       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2476         have_avformat="no"
2477       ])
2478       VLC_RESTORE_FLAGS
2479     ],[
2480       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2481   ])
2482 ])
2483 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2484
2485 dnl
2486 dnl  swscale image scaling and conversion plugin
2487 dnl
2488
2489 AC_ARG_ENABLE(swscale,
2490   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2491           (default enabled)]))
2492 if test "${enable_swscale}" != "no"
2493 then
2494   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2495     [
2496       VLC_SAVE_FLAGS
2497       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2498       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2499       AC_CHECK_HEADERS(libswscale/swscale.h)
2500       AC_CHECK_HEADERS(libavutil/avutil.h)
2501       VLC_ADD_PLUGIN([swscale])
2502       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2503       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2504       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2505         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2506       ])
2507       VLC_RESTORE_FLAGS
2508     ],[
2509       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2510   ])
2511 fi
2512
2513 dnl
2514 dnl  postproc plugin
2515 dnl
2516
2517 AC_ARG_ENABLE(postproc,
2518 [  --enable-postproc       libpostproc image post-processing (default auto)])
2519 if test "${enable_postproc}" != "no"
2520 then
2521   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2522     [
2523       VLC_SAVE_FLAGS
2524       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2525       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2526       AC_CHECK_HEADERS(postproc/postprocess.h)
2527       VLC_ADD_PLUGIN([postproc])
2528       VLC_RESTORE_FLAGS
2529     ],[
2530       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2531   ])
2532 fi
2533
2534 dnl
2535 dnl  faad decoder plugin
2536 dnl
2537 AC_ARG_ENABLE(faad,
2538 [  --enable-faad           faad codec (default auto)])
2539 have_faad="no"
2540 AS_IF([test "${enable_faad}" != "no"], [
2541   AC_CHECK_HEADERS([neaacdec.h], [
2542     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2543
2544     AS_IF([test "${have_faad}" = "yes"], [
2545       VLC_ADD_PLUGIN([faad])
2546       VLC_ADD_LIBS([faad],[-lfaad])
2547     ], [
2548       AS_IF([test "${enable_faad}" = "yes"], [
2549         AC_MSG_ERROR([cannot find FAAD library])
2550       ], [
2551         AC_MSG_WARN([cannot find FAAD library])
2552       ])
2553     ])
2554   ])
2555 ])
2556
2557 dnl
2558 dnl  AOM decoder plugin
2559 dnl
2560 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec], [disabled])
2561
2562 dnl
2563 dnl libvpx decoder plugin
2564 dnl
2565 AC_ARG_ENABLE(vpx,
2566     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2567 AS_IF([test "${enable_vpx}" != "no"],[
2568     PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2569         VLC_ADD_PLUGIN([vpx])
2570         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2571         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2572         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2573             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2574         ], [], [${VPX_LIBS}])
2575         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2576             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2577         ], [], [${VPX_LIBS}])
2578         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2579             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2580         ], [], [${VPX_LIBS}])
2581         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2582             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2583         ], [], [${VPX_LIBS}])
2584     ], [
2585     AS_IF([test "${enable_vpx}" = "yes"],[
2586         AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2587     ])])
2588 ])
2589
2590 dnl
2591 dnl twolame encoder plugin
2592 dnl
2593 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2594
2595 dnl
2596 dnl fdk-aac encoder plugin
2597 dnl
2598 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2599
2600
2601 dnl
2602 dnl A52/AC3 decoder plugin
2603 dnl
2604 AC_ARG_ENABLE(a52,
2605   [  --enable-a52            A/52 support with liba52 (default enabled)])
2606 if test "${enable_a52}" != "no"
2607 then
2608   AC_ARG_WITH(a52,
2609     [  --with-a52=PATH         a52 headers and libraries])
2610     if test -z "${with_a52}"
2611     then
2612       LDFLAGS_test=""
2613       CPPFLAGS_test=""
2614     else
2615       LDFLAGS_test="-L${with_a52}/lib"
2616       CPPFLAGS_test="-I${with_a52}/include"
2617     fi
2618     VLC_SAVE_FLAGS
2619     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2620     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2621     AC_CHECK_HEADERS(a52dec/a52.h, [
2622       AC_CHECK_LIB(a52, a52_free, [
2623         VLC_ADD_PLUGIN([a52])
2624         VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2625         VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2626       ],[
2627         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2628         ], [$LIBM])
2629     ],[
2630       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2631     ])
2632     VLC_RESTORE_FLAGS
2633 fi
2634
2635 dnl
2636 dnl DTS Coherent Acoustics decoder plugin
2637 dnl
2638 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2639
2640 dnl
2641 dnl  Flac plugin
2642 dnl
2643 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2644
2645 dnl
2646 dnl  Libmpeg2 plugin
2647 dnl
2648 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2649
2650 dnl
2651 dnl  Vorbis plugin
2652 dnl
2653 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2654
2655 dnl
2656 dnl  Tremor plugin
2657 dnl
2658 AC_ARG_ENABLE(tremor,
2659   [  --enable-tremor         Tremor decoder support (default disabled)])
2660 if test "${enable_tremor}" = "yes"
2661 then
2662   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2663     VLC_ADD_PLUGIN([tremor])
2664    ],[])
2665 fi
2666
2667 dnl
2668 dnl  Speex plugins
2669 dnl
2670 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2671 have_speexdsp="no"
2672 AS_IF([test "${enable_speex}" != "no"], [
2673   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2674     have_speexdsp="yes"
2675   ], [
2676     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2677   ])
2678 ])
2679 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2680
2681 dnl
2682 dnl  Opus plugin
2683 dnl
2684 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2685
2686 dnl
2687 dnl  theora decoder plugin
2688 dnl
2689 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2690
2691 dnl
2692 dnl  OggSpots decoder plugin
2693 dnl
2694 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2695
2696 dnl
2697 dnl  Daala decoder plugin
2698 dnl
2699 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2700
2701 dnl
2702 dnl  schroedinger decoder plugin (for dirac format video)
2703 dnl
2704 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2705
2706 dnl
2707 dnl  PNG decoder module
2708 dnl
2709 AC_ARG_ENABLE(png,
2710   [  --enable-png            PNG support (default enabled)])
2711 AS_IF([test "${enable_png}" != "no"], [
2712 AC_CHECK_HEADERS(png.h, [
2713   VLC_SAVE_FLAGS
2714   LDFLAGS="${LDFLAGS} -lz $LIBM"
2715   AC_CHECK_LIB(png, png_set_rows, [
2716     VLC_ADD_PLUGIN([png])
2717   ], [], [-lz $LIBM])
2718   VLC_RESTORE_FLAGS
2719   ])
2720 ])
2721
2722 dnl
2723 dnl  JPEG decoder module
2724 dnl
2725 AC_ARG_ENABLE(jpeg,
2726   [  --enable-jpeg           JPEG support (default enabled)])
2727 AS_IF([test "${enable_jpeg}" != "no"], [
2728 AC_CHECK_HEADERS(jpeglib.h, [
2729   VLC_ADD_PLUGIN([jpeg])
2730   ])
2731 ])
2732
2733 dnl
2734 dnl  BPG decoder module
2735 dnl
2736 AC_ARG_ENABLE(bpg,
2737   [  --enable-bpg           BPG support (default disabled)])
2738 AS_IF([test "${enable_bpg}" != "no"], [
2739 AC_CHECK_HEADERS(libbpg.h, [
2740   VLC_ADD_PLUGIN([bpg])
2741   ])
2742 ])
2743
2744 dnl
2745 dnl H262 encoder plugin (lib262)
2746 dnl
2747 AC_ARG_ENABLE(x262,
2748   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2749 if test "${enable_x262}" != "no"; then
2750     PKG_CHECK_MODULES(X262, x262, [
2751         VLC_ADD_PLUGIN([x262])
2752         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2753         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2754           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2755         ])
2756         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2757         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2758           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2759         fi
2760     ], [
2761        if test "${enable_x262}" = "yes"; then
2762         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2763        fi
2764     ])
2765 fi
2766
2767 dnl x265 encoder
2768 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2769
2770 dnl
2771 dnl H264 encoder plugin (10-bit lib264)
2772 dnl
2773 AC_ARG_ENABLE(x26410b,
2774   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2775 if test "${enable_x26410b}" != "no"; then
2776     PKG_CHECK_MODULES(X26410B, x26410b, [
2777         VLC_ADD_PLUGIN([x26410b])
2778         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2779         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2780           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2781         ])
2782         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2783         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2784           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2785         fi
2786     ], [
2787        if test "${enable_x26410b}" = "yes"; then
2788         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2789        fi
2790     ])
2791 fi
2792
2793
2794 dnl
2795 dnl H264 encoder plugin (using libx264)
2796 dnl
2797 AC_ARG_ENABLE(x264,
2798   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2799 if test "${enable_x264}" != "no"; then
2800       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2801         VLC_ADD_PLUGIN([x264])
2802         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2803
2804         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2805           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2806         ])
2807
2808         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2809         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2810           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2811         fi
2812       ],[
2813         if test "${enable_x264}" = "yes"; then
2814             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2815           fi
2816       ])
2817 fi
2818
2819 dnl
2820 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2821 dnl
2822 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2823
2824 dnl
2825 dnl libfluidsynth (MIDI synthetizer) plugin
2826 dnl
2827 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2828 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2829 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2830
2831 dnl
2832 dnl Teletext Modules
2833 dnl vbi decoder plugin (using libzbvi)
2834 dnl telx module
2835 dnl uncompatible
2836 dnl
2837 AC_ARG_ENABLE(zvbi,
2838   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2839                   libzvbi (default enabled)]))
2840 AC_ARG_ENABLE(telx,
2841   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2842                   zvbi) (default enabled if zvbi is absent)]))
2843
2844 AS_IF( [test "${enable_zvbi}" != "no"],[
2845     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2846         [
2847           VLC_ADD_PLUGIN([zvbi])
2848           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2849           AS_IF( [test "${enable_telx}" = "yes"],[
2850                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2851                   ])
2852         ],[
2853           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2854         ])
2855     ])
2856 AS_IF( [test "${enable_telx}" != "no" ],[
2857   VLC_ADD_PLUGIN([telx])
2858   ])
2859
2860 dnl
2861 dnl libass subtitle rendering module
2862 dnl
2863 AC_ARG_ENABLE(libass,
2864   [  --enable-libass         Subtitle support using libass (default enabled)])
2865 AS_IF( [test "${enable_libass}" != "no"], [
2866   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2867       [
2868         VLC_ADD_PLUGIN([libass])
2869
2870         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2871           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2872            VLC_ADD_LIBS([libass],[-lfontconfig])
2873        ])
2874       ],[
2875         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2876       ])
2877   ])
2878
2879 dnl
2880 dnl ARIB subtitles rendering module
2881 dnl
2882 AC_ARG_ENABLE(aribsub,
2883   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2884 AS_IF( [test "${enable_aribsub}" != "no" ],[
2885   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2886       have_aribb24="yes"
2887       VLC_ADD_PLUGIN([aribsub])
2888       VLC_ADD_LIBS([aribsub],[-laribb24])
2889       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2890     ],[
2891       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2892       have_aribb24="no"
2893   ])
2894 ])
2895 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2896
2897 dnl
2898 dnl ARIB B25
2899 dnl
2900 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2901
2902 dnl
2903 dnl  kate decoder plugin
2904 dnl
2905 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2906
2907 dnl
2908 dnl  tiger rendering for kate decoder plugin
2909 dnl
2910 AC_ARG_ENABLE(tiger,
2911 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2912 AS_IF([test "${enable_tiger}" != "no"], [
2913   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2914       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2915         AS_IF([test -n "${enable_tiger}"], [
2916           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2917         ])
2918   ])
2919 ])
2920
2921
2922 dnl
2923 dnl  Video plugins
2924 dnl
2925
2926 EXTEND_HELP_STRING([Video plugins:])
2927
2928 dnl
2929 dnl  OpenGL
2930 dnl
2931 PKG_CHECK_MODULES([EGL], [egl], [
2932   have_egl="yes"
2933 ], [
2934   have_egl="no"
2935 ])
2936 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
2937
2938 have_gl="no"
2939 PKG_CHECK_MODULES([GL], [gl], [
2940   have_gl="yes"
2941 ], [
2942   AC_MSG_CHECKING([for OpenGL])
2943   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2944 #ifdef _WIN32
2945 # include <GL/glew.h>
2946 #endif
2947 #include <GL/gl.h>
2948 ]], [
2949     [int t0 = GL_TEXTURE0;]])
2950   ], [
2951     GL_CFLAGS=""
2952     have_gl="yes"
2953     AS_IF([test "${SYS}" != "mingw32"], [
2954       GL_LIBS="-lGL"
2955     ], [
2956       GL_LIBS="-lopengl32"
2957     ])
2958   ])
2959   AC_MSG_RESULT([${have_gl}])
2960 ])
2961 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
2962
2963 dnl OpenGL ES 2: depends on EGL 1.1
2964 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
2965
2966 dnl
2967 dnl  Xlib
2968 dnl
2969
2970 AC_PATH_XTRA()
2971 AC_CHECK_HEADERS(X11/Xlib.h)
2972
2973 dnl
2974 dnl  X C Bindings modules
2975 dnl
2976 AC_ARG_ENABLE(xcb,
2977   [  --enable-xcb            X11 support with XCB (default enabled)],, [
2978   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
2979     enable_xcb="yes"
2980   ], [
2981     enable_xcb="no"
2982   ])
2983 ])
2984 AC_ARG_ENABLE(xvideo,
2985   [  --enable-xvideo         XVideo support (default enabled)],, [
2986     enable_xvideo="$enable_xcb"
2987 ])
2988
2989 have_xcb="no"
2990 have_xcb_keysyms="no"
2991 have_xcb_randr="no"
2992 have_xcb_xvideo="no"
2993 AS_IF([test "${enable_xcb}" != "no"], [
2994   dnl libxcb
2995   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
2996   have_xcb="yes"
2997   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
2998   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
2999   PKG_CHECK_MODULES(XPROTO, [xproto])
3000
3001   AS_IF([test "${enable_xvideo}" != "no"], [
3002     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3003   ])
3004
3005   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3006
3007   dnl xcb-utils
3008   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3009     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3010   ])
3011 ])
3012 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3013 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3014 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3015 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3016
3017
3018 dnl
3019 dnl VDPAU needs X11
3020 dnl
3021 AC_ARG_ENABLE(vdpau,
3022   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3023 have_vdpau="no"
3024 AS_IF([test "${enable_vdpau}" != "no"], [
3025   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3026     have_vdpau="yes"
3027     AS_IF([test "${no_x}" = "yes"], [
3028       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3029     ])
3030   ], [
3031     AS_IF([test -n "${enable_vdpau}"], [
3032       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3033     ])
3034   ])
3035 ])
3036 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3037
3038 have_avcodec_vdpau="no"
3039 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3040   case "${avfork}" in
3041     libav) av_vdpau_ver="56.10.0" ;;
3042     ffmpeg) av_vdpau_ver="56.19.100" ;;
3043   esac
3044   PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3045     have_avcodec_vdpau="yes"
3046     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3047   ], [
3048     AS_IF([test -n "${enable_vdpau}"], [
3049       AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3050     ], [
3051       AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3052     ])
3053   ])
3054 ])
3055 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3056
3057
3058 dnl
3059 dnl  Wayland
3060 dnl
3061 AC_ARG_ENABLE(wayland,
3062   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3063 have_wayland="no"
3064 have_wayland_egl="no"
3065
3066 AS_IF([test "${enable_wayland}" != "no"], [
3067   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3068     AC_MSG_CHECKING([for the Wayland protocols])
3069     PKG_CHECK_EXISTS([wayland-protocols >= 1.4], [
3070       WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3071       AC_MSG_RESULT([${WAYLAND_PROTOCOLS}])
3072     ], [
3073       AC_MSG_RESULT([not found])
3074       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors 'wayland-protocols >= 1.4')])
3075     ])
3076
3077     AC_MSG_CHECKING([for the Wayland scanner])
3078     PKG_CHECK_EXISTS([wayland-scanner], [
3079       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3080       AC_MSG_RESULT([${WAYLAND_SCANNER}])
3081     ], [
3082       AC_MSG_RESULT([not found])
3083       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors wayland-scanner)])
3084     ])
3085
3086     have_wayland="yes"
3087
3088     AS_IF([test "${have_egl}" = "yes"], [
3089       PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3090         have_wayland_egl="yes"
3091       ], [
3092         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3093       ])
3094     ])
3095   ], [
3096     AS_IF([test -n "${enable_wayland}"], [
3097       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3098     ])
3099   ])
3100 ])
3101 AC_SUBST([WAYLAND_PROTOCOLS])
3102 AC_SUBST([WAYLAND_SCANNER])
3103 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3104 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3105
3106
3107 dnl
3108 dnl  SDL module
3109 dnl
3110 AC_ARG_ENABLE(sdl,
3111   [  --enable-sdl            SDL support (default enabled)])
3112 AC_ARG_ENABLE(sdl-image,
3113   [  --enable-sdl-image      SDL image support (default enabled)])
3114 if test "${enable_sdl}" != "no"
3115 then
3116    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3117       # SDL on Darwin is heavily patched and can only run SDL_image
3118       if test "${SYS}" != "darwin"; then
3119         VLC_ADD_PLUGIN([vout_sdl])
3120       fi
3121
3122       # SDL_image
3123       AS_IF([ test "${enable_sdl_image}" != "no"],[
3124         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3125           VLC_ADD_PLUGIN([sdl_image])],
3126           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3127           ])
3128       ])
3129    ],[
3130      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3131    ])
3132 fi
3133
3134 dnl
3135 dnl  freetype module
3136 dnl
3137 AC_ARG_ENABLE(freetype,
3138   [  --enable-freetype       freetype support   (default auto)])
3139 AC_ARG_ENABLE(fribidi,
3140   [  --enable-fribidi        fribidi support    (default auto)])
3141 AC_ARG_ENABLE(harfbuzz,
3142   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3143 AC_ARG_ENABLE(fontconfig,
3144   [  --enable-fontconfig     fontconfig support (default auto)])
3145
3146 AC_ARG_WITH([default-font],
3147     AS_HELP_STRING([--with-default-font=PATH],
3148         [Path to the default font]),
3149         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3150             "$withval", [Default font])])
3151 AC_ARG_WITH([default-monospace-font],
3152     AS_HELP_STRING([--with-default-monospace-font=PATH],
3153         [Path to the default font]),
3154         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3155             "$withval", [Default monospace font])])
3156
3157 AC_ARG_WITH([default-font-family],
3158     AS_HELP_STRING([--with-default-font-family=NAME],
3159         [Path to the default font family]),
3160         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3161             "$withval", [Default font family])])
3162 AC_ARG_WITH([default-monospace-font-family],
3163     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3164         [Path to the default font family]),
3165         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3166             "$withval", [Default monospace font family])])
3167
3168 have_freetype="no"
3169 have_fontconfig="no"
3170 have_fribidi="no"
3171 have_harfbuzz="no"
3172
3173 if test "${enable_freetype}" != "no"; then
3174    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3175       have_freetype="yes"
3176       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3177       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3178
3179     dnl fontconfig support
3180     AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3181       PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3182         have_fontconfig="yes"
3183       ], [
3184         AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3185       ])
3186     ])
3187
3188       dnl fribidi support
3189       if test "${enable_fribidi}" != "no"; then
3190         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3191           have_fribidi="yes"
3192           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3193           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3194         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3195       fi
3196
3197       dnl harfbuzz support
3198       if test "${have_fribidi}" != "no"; then
3199         if test "${enable_harfbuzz}" != "no"; then
3200           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3201             have_harfbuzz="yes"
3202             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3203             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3204           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3205         fi
3206       fi
3207   ],[
3208   AS_IF([test -n "${enable_freetype}"],[
3209     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3210     ])
3211   ])
3212 fi
3213
3214 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3215 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3216 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3217 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3218
3219 dnl
3220 dnl SAPI (text to Speech renderer for Windows)
3221 dnl
3222 AC_LANG_PUSH([C++])
3223 AC_CHECK_TYPES([ISpObjectToken],[
3224               have_sapi="yes"
3225             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3226               [#include <windows.h>
3227                #include <sapi.h>
3228                #include <sphelper.h>])
3229 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3230 AC_LANG_POP([C++])
3231
3232 dnl
3233 dnl  SVG module (text rendering and image decoding)
3234 dnl
3235 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3236 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3237
3238 dnl
3239 dnl  Windows DirectX module
3240 dnl
3241
3242 AC_ARG_ENABLE(directx,
3243   [AS_HELP_STRING([--enable-directx],
3244     [Microsoft DirectX support (default enabled on Windows)])],, [
3245   AS_IF([test "${SYS}" = "mingw32"], [
3246     enable_directx="yes"
3247   ], [
3248     enable_directx="no"
3249   ])
3250 ])
3251 AS_IF([test "${enable_directx}" != "no"], [
3252   dnl DirectDraw
3253   AC_CHECK_HEADERS(ddraw.h, [
3254     VLC_ADD_PLUGIN([directdraw])
3255   ])
3256
3257   dnl OpenGL
3258   AC_CHECK_HEADERS(GL/wglew.h, [
3259     VLC_ADD_PLUGIN([glwin32 wgl])
3260   ],, [
3261     #include <windows.h>
3262     #include <GL/gl.h>
3263   ])
3264
3265   dnl Direct3D11
3266   AC_CHECK_HEADERS(d3d11.h, [
3267     VLC_ADD_PLUGIN([direct3d11])
3268   ])
3269
3270   dnl Direct3D9
3271   AC_CHECK_HEADERS(d3d9.h, [
3272     VLC_ADD_PLUGIN([direct3d9])
3273   ])
3274
3275 ])
3276
3277 dnl
3278 dnl  Linux framebuffer module
3279 dnl
3280 AC_CHECK_HEADER([linux/fb.h], [
3281   VLC_ADD_PLUGIN([fb])
3282 ])
3283
3284
3285 dnl
3286 dnl  DirectFB module
3287 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3288 dnl  TODO: support for static linking
3289 dnl
3290 AC_ARG_ENABLE(directfb,
3291   [  --enable-directfb       DirectFB support (default disabled)])
3292 AC_ARG_WITH(directfb,
3293   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3294
3295 if test "${enable_directfb}" = "yes"; then
3296     have_directfb="false"
3297     CPPFLAGS_mydirectfb=
3298     LIBS_mydirectfb=
3299     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3300         dnl Trying the given location
3301         VLC_SAVE_FLAGS
3302
3303         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3304         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3305
3306         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3307         LIBS="${LIBS} ${LIBS_new}"
3308
3309         dnl FIXME: too obscure
3310         AC_CHECK_HEADER([directfb.h], [
3311             AC_CHECK_LIB([direct],[direct_initialize], [
3312                 AC_CHECK_LIB([fusion], [fusion_enter], [
3313                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3314                 ], have_directfb="false")
3315             ], have_directfb="false")
3316         ], have_directfb="false")
3317
3318         VLC_RESTORE_FLAGS
3319
3320         if test "${have_directfb}" = "true"; then
3321             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3322             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3323         fi
3324     else
3325         dnl Look for directfb-config
3326         AC_CHECK_PROG(DIRECTFB_CONFIG, [directfb-config], [false])
3327         AS_IF(["${DIRECTFB_CONFIG}" != "false"], [
3328             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3329             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3330             have_directfb="true"
3331         ], [
3332             dnl Trying with pkg-config
3333             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3334                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3335                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3336                 have_directfb="true"
3337                 ], [have_directfb="false"])
3338         ])
3339     fi
3340     if test "${have_directfb}" = "true"; then
3341         VLC_ADD_PLUGIN([directfb])
3342         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3343         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3344     else
3345         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3346     fi
3347 fi
3348
3349 dnl
3350 dnl  AA plugin
3351 dnl
3352 AC_ARG_ENABLE(aa,
3353   [  --enable-aa             aalib output (default disabled)])
3354 if test "${enable_aa}" = "yes"
3355 then
3356   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3357   if test "${have_aa}" = "true"
3358   then
3359     VLC_ADD_PLUGIN([aa])
3360   fi
3361 fi
3362
3363 dnl
3364 dnl  libcaca plugin
3365 dnl
3366 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3367
3368 dnl
3369 dnl  OS/2 KVA plugin
3370 dnl
3371 AC_ARG_ENABLE(kva,
3372   [AS_HELP_STRING([--enable-kva],
3373     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3374   AS_IF([test "$SYS" = "os2"], [
3375     enable_kva="yes"
3376   ])
3377 ])
3378 have_kva="no"
3379 KVA_LIBS=""
3380 AS_IF([test "$enable_kva" != "no"], [
3381   AC_CHECK_HEADERS([kva.h], [
3382     have_kva="yes"
3383     AC_CHECK_LIB(kva, main, [
3384       KVA_LIBS="-lkva"
3385     ])
3386   ])
3387 ])
3388 AC_SUBST(KVA_LIBS)
3389 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3390
3391 dnl
3392 dnl MMAL plugin
3393 dnl
3394 AC_ARG_ENABLE(mmal,
3395   AS_HELP_STRING([--enable-mmal],
3396     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3397 if test "${enable_mmal}" != "no"; then
3398   VLC_SAVE_FLAGS
3399   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3400   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3401   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3402     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3403         have_mmal="yes"
3404         VLC_ADD_PLUGIN([mmal])
3405         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3406         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3407         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lvchostif ]) ], [
3408           AS_IF([test "${enable_mmal}" = "yes"],
3409             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3410             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3411           ],
3412         [])
3413     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3414       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3415       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3416   VLC_RESTORE_FLAGS
3417 fi
3418 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3419
3420 dnl
3421 dnl evas plugin
3422 dnl
3423 AC_ARG_ENABLE(evas,
3424   [AS_HELP_STRING([--enable-evas],
3425     [use evas output module (default disabled)])])
3426 have_evas="no"
3427 AS_IF([test "${enable_evas}" = "yes"], [
3428   PKG_CHECK_MODULES(EVAS, [evas >= 1.15.99 ecore >= 1.15.99], [
3429       have_evas="yes"
3430       AC_DEFINE([HAVE_EVAS], [1], [Define to 1 if evas is enabled.])
3431     ],[
3432     AS_IF([test "x${enable_evas}" != "x"], [
3433       AC_MSG_ERROR([$EVAS_PKG_ERRORS. libevas and libecore 1.15.99 or later required.])
3434     ])
3435   ])
3436 ])
3437 AM_CONDITIONAL([HAVE_EVAS], [test "${have_evas}" = "yes"])
3438
3439 dnl
3440 dnl  Audio plugins
3441 dnl
3442
3443 EXTEND_HELP_STRING([Audio plugins:])
3444
3445 dnl
3446 dnl  Pulseaudio module
3447 dnl
3448 AC_ARG_ENABLE(pulse,
3449   [AS_HELP_STRING([--enable-pulse],
3450     [use the PulseAudio client library (default auto)])])
3451 have_pulse="no"
3452 AS_IF([test "${enable_pulse}" != "no"], [
3453   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3454     have_pulse="yes"
3455   ], [
3456     AS_IF([test "x${enable_pulse}" != "x"], [
3457       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3458     ])
3459   ])
3460 ])
3461 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3462
3463 dnl
3464 dnl  ALSA module
3465 dnl
3466 AC_ARG_ENABLE(alsa,
3467   [AS_HELP_STRING([--enable-alsa],
3468     [support the Advanced Linux Sound Architecture (default auto)])],, [
3469   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3470     enable_alsa="yes"
3471   ])
3472 ])
3473 have_alsa="no"
3474 AS_IF([test "${enable_alsa}" != "no"], [
3475   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3476     have_alsa="yes"
3477   ], [
3478     AS_IF([test "x${enable_alsa}" != "x"], [
3479       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3480     ])
3481   ])
3482 ])
3483 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3484
3485 dnl
3486 dnl  Open Sound System module
3487 dnl
3488 AC_ARG_ENABLE(oss,
3489   [AS_HELP_STRING([--enable-oss],
3490     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3491   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3492     enable_oss="no"
3493   ])
3494 ])
3495 have_oss="no"
3496 OSS_LIBS=""
3497 AS_IF([test "$enable_oss" != "no"], [
3498   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3499     have_oss="yes"
3500     AC_CHECK_LIB(ossaudio, main, [
3501       OSS_LIBS="-lossaudio"
3502     ])
3503   ])
3504 ])
3505 AC_SUBST(OSS_LIBS)
3506 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3507
3508 dnl
3509 dnl  OpenBSD sndio module
3510 dnl
3511 AC_ARG_ENABLE([sndio],
3512   [AS_HELP_STRING([--disable-sndio],
3513     [support the OpenBSD sndio (default auto)])],, [
3514   AS_IF([test "$SYS" = "openbsd"], [
3515     enable_sndio="yes"
3516   ])
3517 ])
3518 have_sndio="no"
3519 AS_IF([test "$enable_sndio" != "no"], [
3520   AC_CHECK_HEADER([sndio.h], [
3521     have_sndio="yes"
3522   ])
3523 ])
3524 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3525
3526 dnl
3527 dnl  Windows Audio Session plugin
3528 dnl
3529 AC_ARG_ENABLE([wasapi],
3530   [AS_HELP_STRING([--enable-wasapi],
3531     [use the Windows Audio Session API (default auto)])
3532 ])
3533 have_wasapi="no"
3534 AS_IF([test "$enable_wasapi" != "no"], [
3535   AC_CHECK_HEADER([audioclient.h], [
3536     have_wasapi="yes"
3537   ], [
3538     AS_IF([test "x${enable_wasapi}" != "x"], [
3539       AC_MSG_ERROR([Windows Audio Session API not found.])
3540     ])
3541   ])
3542 ])
3543 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3544
3545 dnl
3546 dnl  JACK modules
3547 dnl
3548 AC_ARG_ENABLE(jack,
3549   [AS_HELP_STRING([--disable-jack],
3550     [do not use jack (default auto)])])
3551 have_jack="no"
3552 AS_IF([test "${enable_jack}" != "no"], [
3553     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3554       [ have_jack=yes ],
3555       [
3556       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3557
3558       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3559       [ have_jack=yes ],
3560       [
3561       AS_IF([test -n "${enable_jack}"],
3562          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3563          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3564       ])
3565     ])
3566 ])
3567 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3568
3569 dnl
3570 dnl  OpenSLES Android
3571 dnl
3572 AC_ARG_ENABLE(opensles,
3573   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3574 if test "${HAVE_ANDROID}" = "1"; then
3575   if test "${enable_opensles}" = "yes"; then
3576       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3577         [ VLC_ADD_PLUGIN([opensles_android]) ],
3578         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3579   fi
3580 fi
3581
3582 dnl
3583 dnl  Tizen audio
3584 dnl
3585 AC_ARG_ENABLE(tizen_audio,
3586   [AS_HELP_STRING([--enable-tizen-audio],
3587     [Tizen audio module (default enabled on Tizen)])],, [
3588   AS_IF([test "$HAVE_TIZEN" = "1"], [
3589     enable_tizen_audio="yes"
3590   ])
3591 ])
3592 if test "${enable_tizen_audio}" = "yes"; then
3593   AC_CHECK_HEADERS(audio_io.h,
3594     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3595     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3596 fi
3597
3598 dnl
3599 dnl libsamplerate plugin
3600 dnl
3601 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3602
3603 dnl
3604 dnl  soxr module
3605 dnl
3606 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3607
3608 dnl
3609 dnl  OS/2 KAI plugin
3610 dnl
3611 AC_ARG_ENABLE(kai,
3612   [AS_HELP_STRING([--enable-kai],
3613     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3614   AS_IF([test "$SYS" = "os2"], [
3615     enable_kai="yes"
3616   ])
3617 ])
3618 have_kai="no"
3619 KAI_LIBS=""
3620 AS_IF([test "$enable_kai" != "no"], [
3621   AC_CHECK_HEADERS([kai.h], [
3622     have_kai="yes"
3623     AC_CHECK_LIB(kai, main, [
3624       KAI_LIBS="-lkai"
3625     ])
3626   ])
3627 ])
3628 AC_SUBST(KAI_LIBS)
3629 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3630
3631 dnl
3632 dnl  chromaprint audio track fingerprinter
3633 dnl
3634 m4_pushdef([libchromaprint_version], 0.6.0)
3635 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3636     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3637     AS_IF([test "${enable_chromaprint}" = "yes"],
3638         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3639         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3640          ),
3641     [(Chromaprint based audio fingerprinter)],[auto])
3642 m4_popdef([libchromaprint_version])
3643
3644 dnl
3645 dnl  Chromecast streaming support
3646 dnl
3647 m4_pushdef([protobuf_lite_version], 2.5.0)
3648 AC_ARG_VAR(PROTOC, [protobuf compiler])
3649 AC_CHECK_PROGS(PROTOC, protoc, no)
3650 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3651     AS_IF([test "x${PROTOC}" != "xno"], [
3652         build_chromecast="yes"
3653     ], [
3654     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3655     ])
3656 ], [
3657     AS_IF([test "${enable_chromecast}" = "yes"],
3658         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3659         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3660     )
3661     enable_chromecast="no"
3662 ], [(Chromecast streaming support)], [auto])
3663 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3664 m4_popdef([protobuf_lite_version])
3665
3666 dnl
3667 dnl  Interface plugins
3668 dnl
3669
3670 EXTEND_HELP_STRING([Interface plugins:])
3671
3672 dnl
3673 dnl QT
3674 dnl
3675 AC_ARG_ENABLE(qt, [
3676   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3677   AS_IF([test "${SYS}" = "darwin"], [
3678     enable_qt="no"
3679   ])
3680 ])
3681 have_qt5_x11="no"
3682 AS_IF([test "${enable_qt}" != "no"], [
3683   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.2.0 Qt5Widgets Qt5Gui], [
3684       PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3685           have_qt5_x11="yes"
3686       ],[
3687           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3688       ])
3689       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3690       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3691       QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3692       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3693       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3694       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3695     ], [
3696       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.8.0],, [
3697         AS_IF([test -n "${enable_qt}"],[
3698           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3699         ],[
3700           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3701         ])
3702         enable_qt="no"
3703       ])
3704       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3705       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin"])
3706       AC_PATH_PROG(RCC, rcc, rcc, ["${QT_PATH}/bin"])
3707       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin"])
3708     ])
3709 ])
3710 AS_IF([test "${enable_qt}" != "no"], [
3711   VLC_ADD_PLUGIN([qt])
3712   ALIASES="${ALIASES} qvlc"
3713 ])
3714 AC_SUBST(QT_VERSION)
3715 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3716 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3717
3718 dnl
3719 dnl detect kde4-config patch (used for kde solids).
3720 dnl
3721 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3722 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3723   KDE4_CONFIG="kde4-config"
3724 ])
3725
3726 dnl
3727 dnl Simple test for skins2 dependency
3728 dnl
3729 AS_IF([test "$enable_qt" = "no"], [
3730   AS_IF([test "${enable_skins2}" = "yes"], [
3731     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3732   ], [
3733     enable_skins2="no"
3734     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3735   ])
3736 ])
3737
3738 dnl
3739 dnl Skins2 module
3740 dnl
3741 AC_ARG_ENABLE(skins2,
3742   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3743 AS_IF([test "${enable_skins2}" != "no"], [
3744   have_skins_deps="yes"
3745
3746   dnl Win32
3747   AS_IF([test "${SYS}" = "mingw32"], [
3748     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3749     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3750   dnl OS/2
3751   ], [test "${SYS}" = "os2"], [
3752     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3753   dnl Linux/Unix
3754   ], [
3755     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3756     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3757     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3758     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3759     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3760   ])
3761
3762   dnl we need freetype
3763   AS_IF([test "${have_freetype}" != "yes"], [
3764     have_skins_deps="no"
3765   ])
3766
3767   AS_IF([test "${have_skins_deps}" = "no"], [
3768     AS_IF([test "x${enable_skins2}" = "x"], [
3769       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3770     ], [
3771       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3772     ])
3773     enable_skins2="no"
3774   ], [
3775     ALIASES="${ALIASES} svlc"
3776     enable_skins2="yes"
3777   ])
3778 ])
3779 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3780
3781 AC_ARG_ENABLE(libtar,
3782   [  --enable-libtar         libtar support for skins2 (default auto)])
3783 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3784   AC_CHECK_HEADERS(libtar.h, [
3785     VLC_ADD_LIBS([skins2],[-ltar])
3786   ])
3787 ])
3788
3789 dnl
3790 dnl  MacOS X gui module
3791 dnl
3792 AC_ARG_ENABLE(macosx,
3793   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3794 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3795 then
3796   VLC_ADD_PLUGIN([macosx])
3797   AC_PATH_PROGS(XIB, [ibtool], ibtool, ["/usr/bin"])
3798 fi
3799 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3800
3801 dnl
3802 dnl  MacOS X sparkle update support
3803 dnl
3804 AC_ARG_ENABLE(sparkle,
3805   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3806 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3807 then
3808   if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3809   then
3810     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3811   fi
3812
3813   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3814 fi
3815 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3816
3817 dnl
3818 dnl  MacOS X breakpad creash reporter support
3819 dnl
3820 AC_ARG_ENABLE(breakpad,
3821   [  --enable-breakpad       Breakpad crash reporter support for OS X (default enabled on Mac OS X)])
3822 if test "x${enable_breakpad}" != "xno" -a "${HAVE_OSX}" = "1"
3823 then
3824   if test ! -d ${CONTRIB_DIR}/Breakpad.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework
3825   then
3826     AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3827   fi
3828
3829   AC_DEFINE([HAVE_BREAKPAD], [1], [Define to 1 if breakpad is enabled.])
3830 fi
3831 AM_CONDITIONAL(HAVE_BREAKPAD, [test "$enable_breakpad" != "no"])
3832
3833
3834 dnl
3835 dnl  Minimal Mac OS X module
3836 dnl
3837 AC_ARG_ENABLE(minimal-macosx,
3838   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3839 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3840 then
3841   VLC_ADD_PLUGIN([minimal_macosx])
3842 fi
3843
3844 dnl
3845 dnl Mac OS X fancy dmg build tool
3846 dnl
3847 if test "${HAVE_OSX}" = "1"
3848 then
3849   AC_PATH_PROG(DMGBUILD, dmgbuild, no)
3850   AS_IF([test "x${DMGBUILD}" = "xno"], [
3851     AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
3852   ])
3853 fi
3854 AM_CONDITIONAL(HAVE_DMGBUILD, [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
3855
3856 dnl
3857 dnl  VideoToolbox plugins
3858 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3859     VLC_ADD_PLUGIN([videotoolbox])
3860     VLC_ADD_PLUGIN([cvpx_i420])
3861   ])
3862
3863 dnl
3864 dnl  ncurses module
3865 dnl
3866 AC_ARG_ENABLE(ncurses,
3867 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3868 have_ncurses="no"
3869 AS_IF([test "${enable_ncurses}" != "no"] ,[
3870   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3871     have_ncurses="yes"
3872     ALIASES="${ALIASES} nvlc"
3873   ], [
3874     AS_IF([test -n "${enable_ncurses}"], [
3875       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3876     ])
3877   ])
3878 ])
3879 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3880
3881 dnl
3882 dnl  Lirc plugin
3883 dnl
3884 AC_ARG_ENABLE(lirc,
3885   [  --enable-lirc           lirc support (default disabled)])
3886 have_lirc="no"
3887 AS_IF([test "${enable_lirc}" = "yes"], [
3888   AC_CHECK_HEADER(lirc/lirc_client.h, [
3889     AC_CHECK_LIB(lirc_client, lirc_init, [
3890       have_lirc="yes"
3891     ])
3892   ])
3893 ])
3894 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3895
3896 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3897 dnl
3898 dnl  goom visualization plugin
3899 dnl
3900 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3901
3902 dnl
3903 dnl libprojectM visualization plugin
3904 dnl
3905 AC_ARG_ENABLE(projectm,
3906   [  --enable-projectm       projectM visualization plugin (default enabled)])
3907 AS_IF([test "${enable_projectm}" != "no"],
3908   [
3909     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3910     [
3911       VLC_ADD_PLUGIN([projectm])
3912       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3913         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3914         [ AC_MSG_WARN( [Using libprojectM version 1] )
3915       ])
3916     ],[
3917       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3918     ])
3919   ])
3920
3921 dnl
3922 dnl Vovoid VSXu visualization plugin
3923 dnl
3924 AC_ARG_ENABLE(vsxu,
3925   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3926 AS_IF([test "${enable_vsxu}" != "no"],
3927   [
3928     PKG_CHECK_MODULES(VSXU, libvsxu,
3929     [
3930       VLC_ADD_PLUGIN([vsxu])
3931     ],[
3932       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3933     ])
3934   ])
3935
3936 EXTEND_HELP_STRING([Service Discovery plugins:])
3937 dnl
3938 dnl  Avahi-Zeroconf services discovery
3939 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
3940
3941 dnl
3942 dnl  libudev services discovery
3943 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3944
3945 dnl
3946 dnl MTP devices services discovery
3947 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3948
3949 dnl
3950 dnl UPnP Plugin (Intel SDK)
3951 dnl
3952 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3953
3954 dnl
3955 dnl mDNS using libmicrodns
3956 dnl
3957 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
3958
3959
3960 EXTEND_HELP_STRING([Misc options:])
3961
3962 dnl
3963 dnl  libxml2 module
3964 dnl
3965 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3966
3967
3968 dnl
3969 dnl libgcrypt
3970 dnl
3971 AC_ARG_ENABLE(libgcrypt,
3972   [  --disable-libgcrypt     gcrypt support (default enabled)])
3973 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
3974 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
3975
3976 # require libgcrypt >= 1.6.0
3977 AS_IF([test "${enable_libgcrypt}" != "no"], [
3978   AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
3979     VLC_SAVE_FLAGS
3980     CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
3981     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
3982 [#include <gcrypt.h>
3983 #if GCRYPT_VERSION_NUMBER < 0x010600
3984 #error
3985 #endif]])], [
3986       ac_cv_lib_gcrypt=yes
3987     ], [
3988       ac_cv_lib_gcrypt=no
3989     ])
3990     VLC_RESTORE_FLAGS
3991   ])
3992
3993   AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
3994     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
3995   ], [
3996     AS_IF([test "${enable_libgcrypt}" = "yes"], [
3997       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
3998     ])
3999   ])
4000 ])
4001
4002 AS_IF([test -z "$GCRYPT_LIBS"], [
4003   GCRYPT_LIBS="-lgcrypt -lgpg-error"
4004 ])
4005
4006 AC_SUBST(GCRYPT_CFLAGS)
4007 AC_SUBST(GCRYPT_LIBS)
4008 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4009
4010 dnl
4011 dnl TLS/SSL
4012 dnl
4013 AC_ARG_ENABLE(gnutls,
4014   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4015 AS_IF([test "${enable_gnutls}" != "no"], [
4016   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4017     VLC_ADD_PLUGIN([gnutls])
4018   ], [
4019     AS_IF([test -n "${enable_gnutls}"], [
4020       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4021     ])
4022   ])
4023 ])
4024
4025
4026 dnl
4027 dnl Taglib plugin
4028 dnl
4029 AC_ARG_ENABLE(taglib,
4030   [AS_HELP_STRING([--disable-taglib],
4031     [do not use TagLib (default enabled)])])
4032 AS_IF([test "${enable_taglib}" != "no"], [
4033   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4034     VLC_ADD_PLUGIN([taglib])
4035   ], [
4036     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4037 ])
4038
4039 dnl
4040 dnl  libsecret
4041 dnl
4042 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4043
4044 dnl
4045 dnl  kwallet
4046 dnl
4047 AC_ARG_ENABLE(kwallet,
4048   [AS_HELP_STRING([--enable-kwallet],
4049     [use kwallet (via D-Bus) for keystore (default enabled)])])
4050 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4051   VLC_ADD_PLUGIN([kwallet])
4052 ])
4053
4054 dnl
4055 dnl  Developers helper modules (should be hidden from configure help)
4056 dnl
4057 AC_ARG_ENABLE(devtools, [], [], [enable_devtools="no"])
4058 AS_IF([test "${enable_devtools}" != "no"], [
4059   VLC_ADD_PLUGIN([accesstweaks])
4060 ])
4061
4062 dnl
4063 dnl update checking system
4064 dnl
4065 AC_ARG_ENABLE(update-check,
4066   [  --enable-update-check   update checking system (default disabled)])
4067 if test "${enable_update_check}" = "yes"
4068 then
4069  AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4070     AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4071 fi
4072 AM_CONDITIONAL(UPDATE_CHECK, [test "${enable_update_check}" = "yes"])
4073
4074 dnl
4075 dnl OS X notification plugin
4076 dnl
4077 AC_ARG_ENABLE(osx_notifications,
4078   [  --enable-osx-notifications          osx notification plugin (default disabled)],,
4079   [enable_osx_notifications=no])
4080 AS_IF([test "${enable_osx_notifications}" != "no"], [
4081   if test -d ${CONTRIB_DIR}/Growl.framework -o -d ${CONTRIB_DIR}/Frameworks/Growl.framework
4082   then
4083       VLC_ADD_PLUGIN([osx_notifications])
4084       VLC_ADD_LIBS([osx_notifications], [-Wl,-framework,Growl,-framework,Foundation])
4085       VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4086   fi
4087 ])
4088
4089 dnl
4090 dnl Libnotify notification plugin
4091 dnl
4092 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4093
4094 dnl
4095 dnl  Endianness check
4096 dnl
4097 AC_C_BIGENDIAN
4098 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4099   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4100 ], [
4101   DEFS_BIGENDIAN=""
4102 ])
4103 AC_SUBST(DEFS_BIGENDIAN)
4104
4105 dnl
4106 dnl Where to install KDE solid .desktop
4107 dnl
4108 AC_ARG_WITH(kde-solid,
4109   AS_HELP_STRING([--with-kde-solid=PATH],
4110                  [KDE Solid actions directory (auto)]),, [
4111
4112 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4113   with_kde_solid="yes"
4114 fi
4115 ])
4116 soliddatadir=""
4117 AS_IF([test "${with_kde_solid}" != "no"], [
4118   AS_IF([test "${with_kde_solid}" = "yes"], [
4119     kde4datadir="`${KDE4_CONFIG} --install data`"
4120     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4121     soliddatadir="${kde4datadir}/solid/actions"
4122   ], [
4123     soliddatadir="${with_kde_solid}"
4124   ])
4125 ])
4126 AC_SUBST(soliddatadir)
4127 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4128
4129 dnl
4130 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4131 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4132 dnl
4133 if test "${SYS}" = "mingw32"; then
4134     AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4135 fi
4136
4137 EXTEND_HELP_STRING([Components:])
4138
4139 dnl
4140 dnl  the VLC binary
4141 dnl
4142 AC_ARG_ENABLE(vlc,
4143   [  --enable-vlc            build the VLC media player (default enabled)])
4144 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4145
4146 dnl
4147 dnl  Stuff used by the program
4148 dnl
4149 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4150 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4151 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4152 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4153 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4154 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4155 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4156 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4157 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4158 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4159 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4160 AC_SUBST(COPYRIGHT_MESSAGE)
4161 AC_SUBST(VERSION_MESSAGE)
4162 AC_SUBST(VERSION_MAJOR)
4163 AC_SUBST(VERSION_MINOR)
4164 AC_SUBST(VERSION_REVISION)
4165 AC_SUBST(VERSION_EXTRA)
4166 AC_SUBST(COPYRIGHT_YEARS)
4167 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4168 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4169 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4170 dnl
4171 dnl  Handle substvars that use $(top_srcdir)
4172 dnl
4173 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4174
4175 dnl
4176 dnl  Configuration is finished
4177 dnl
4178 AC_SUBST(SYS)
4179 AC_SUBST(ARCH)
4180 AC_SUBST(ALIASES)
4181 AC_SUBST(ASM)
4182 AC_SUBST(MOC)
4183 AC_SUBST(RCC)
4184 AC_SUBST(UIC)
4185 AC_SUBST(WINDRES)
4186 AC_SUBST(WINE_SDK_PATH)
4187 AC_SUBST(LIBEXT)
4188 AC_SUBST(AM_CPPFLAGS)
4189 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4190 AC_SUBST(FILE_LIBVLCCORE_DLL)
4191 AC_SUBST(FILE_LIBVLC_DLL)
4192
4193 AC_CONFIG_FILES([
4194   Makefile
4195   doc/Makefile
4196   modules/Makefile
4197   m4/Makefile
4198   po/Makefile.in
4199   share/Makefile
4200   compat/Makefile
4201   src/Makefile
4202   lib/Makefile
4203   bin/Makefile
4204   test/Makefile
4205   modules/gui/macosx/Makefile
4206   modules/gui/qt/Makefile
4207   modules/hw/mmal/Makefile
4208   share/vlc.appdata.xml.in
4209 ])
4210
4211 AM_COND_IF([HAVE_WIN32], [
4212   AC_CONFIG_FILES([
4213     extras/package/win32/NSIS/spad.nsi
4214     extras/package/win32/NSIS/vlc.win32.nsi
4215     extras/package/win32/msi/config.wxi
4216   ])
4217 ])
4218
4219 AM_COND_IF([HAVE_DARWIN], [
4220   AC_CONFIG_FILES([
4221     modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4222     share/macosx/Info.plist:share/Info.plist.in
4223   ])
4224 ])
4225
4226 dnl Generate makefiles
4227 AC_OUTPUT
4228
4229 dnl Do we have to use make or gmake ?
4230 if make --version 2>&1|grep -q GNU
4231 then
4232     # GNU make, all seems good
4233     MAKE=make
4234 else
4235     # Known GNU make alias (on BSD)
4236     MAKE=gmake
4237 fi
4238 dnl Shortcut to nice compile message
4239 if test -n $SHELL; then
4240   SHELL=${CONFIG_SHELL-/bin/sh}
4241 fi
4242 rm -f compile
4243 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4244 echo "#! $SHELL
4245 rm -f .error\$\$
4246 ERROR=0
4247 export PATH=\"$PATH\" LANG=C
4248 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4249 test -f .error\$\$ && ERROR=1
4250 rm -f .error\$\$
4251 exit \$ERROR" >compile
4252 chmod a+x compile
4253
4254 echo "
4255 libvlc configuration
4256 --------------------
4257 version               : ${VERSION}
4258 system                : ${SYS}
4259 architecture          : ${ARCH}
4260 optimizations         : ${enable_optimizations}"
4261 if test "${enable_vlc}" != "no"; then
4262 echo "vlc aliases           :${ALIASES}"
4263 else
4264 echo "build vlc executable  : no"
4265 fi
4266 echo "
4267 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."