vlc.win32.nsi

   1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   2 ; NSIS installer script for vlc ;
   3 ; (http://nsis.sourceforge.net) ;
   4 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   5
   6 !define PRODUCT_NAME "VLC media player"
   7 !define PRODUCT_VERSION '${VERSION}'
   8 !define PRODUCT_GROUP "VideoLAN"
   9 !define PRODUCT_PUBLISHER "VideoLAN Team"
  10 !define PRODUCT_WEB_SITE "http://www.videolan.org"
  11 !define PRODUCT_DIR_REGKEY "Software\VideoLAN\VLC"
  12 !define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
  13 !define PRODUCT_UNINST_ROOT_KEY "HKLM"
  14
  15 ;;;;;;;;;;;;;;;;;;;;;;;;;
  16 ; General configuration ;
  17 ;;;;;;;;;;;;;;;;;;;;;;;;;
  18
  19 Name "${PRODUCT_GROUP} ${PRODUCT_NAME} ${PRODUCT_VERSION}"
  20 OutFile ..\vlc-${VERSION}-win32.exe
  21 InstallDir "$PROGRAMFILES\VideoLAN\VLC"
  22 InstallDirRegKey HKLM "${PRODUCT_DIR_REGKEY}" "Install_Dir"
  23 SetCompressor lzma
  24 ShowInstDetails show
  25 ShowUnInstDetails show
  26 SetOverwrite ifnewer
  27 CRCCheck on
  28
  29 InstType "Normal"
  30 InstType "Full"
  31
  32 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  33 ; NSIS Modern User Interface configuration ;
  34 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  35
  36 ; MUI 1.67 compatible ------
  37 !include "MUI.nsh"
  38
  39 ; MUI Settings
  40 !define MUI_ABORTWARNING
  41 !define MUI_ICON "vlc48x48.ico"
  42 !define MUI_UNICON "vlc48x48.ico"
  43 !define MUI_COMPONENTSPAGE_SMALLDESC
  44
  45 ; Welcome page
  46 !insertmacro MUI_PAGE_WELCOME
  47 ; License page
  48 !insertmacro MUI_PAGE_LICENSE "COPYING.txt"
  49 ; Components page
  50 !insertmacro MUI_PAGE_COMPONENTS
  51 ; Directory page
  52 !insertmacro MUI_PAGE_DIRECTORY
  53 ; Instfiles page
  54 !insertmacro MUI_PAGE_INSTFILES
  55 ; Finish page
  56 !define MUI_FINISHPAGE_RUN "$INSTDIR\vlc.exe"
  57 !define MUI_FINISHPAGE_NOREBOOTSUPPORT
  58 !insertmacro MUI_PAGE_FINISH
  59
  60 ; Uninstaller pages
  61 !insertmacro MUI_UNPAGE_INSTFILES
  62
  63 ; Language files
  64 !insertmacro MUI_LANGUAGE "English"
  65
  66 ; Reserve files
  67 !insertmacro MUI_RESERVEFILE_INSTALLOPTIONS
  68
  69 ; MUI end ------
  70
  71 ;;;;;;;;;;;;;;;;;;;;;;;;;;
  72 ; File type associations ;
  73 ;;;;;;;;;;;;;;;;;;;;;;;;;;
  74
  75 Function RegisterExtension
  76   ; back up old value for extension $R0 (eg. ".opt")
  77   ReadRegStr $1 HKCR "$R0" ""
  78   StrCmp $1 "" NoBackup
  79     StrCmp $1 "VLC$R0" "NoBackup"
  80     WriteRegStr HKCR "$R0" "VLC.backup" $1
  81 NoBackup:
  82   WriteRegStr HKCR "$R0" "" "VLC$R0"
  83   ReadRegStr $0 HKCR "VLC$R0" ""
  84   WriteRegStr HKCR "VLC$R0" "" "VLC media file"
  85   WriteRegStr HKCR "VLC$R0\shell" "" "Play"
  86   WriteRegStr HKCR "VLC$R0\shell\Play\command" "" '$INSTDIR\vlc.exe "%1"'
  87   WriteRegStr HKCR "VLC$R0\DefaultIcon" "" "$INSTDIR\vlc.exe,0"
  88 FunctionEnd
  89
  90 Function un.RegisterExtension
  91   ;start of restore script
  92   ReadRegStr $1 HKCR "$R0" ""
  93   StrCmp $1 "VLC$R0" 0 NoOwn ; only do this if we own it
  94     ReadRegStr $1 HKCR "$R0" "VLC.backup"
  95     StrCmp $1 "" 0 Restore ; if backup="" then delete the whole key
  96       DeleteRegKey HKCR "$R0"
  97     Goto NoOwn
  98 Restore:
  99       WriteRegStr HKCR "$R0" "" $1
 100       DeleteRegValue HKCR "$R0" "VLC.backup"
 101 NoOwn:
 102     DeleteRegKey HKCR "VLC$R0" ;Delete key with association settings
 103 FunctionEnd
 104
 105 !macro RegisterExtensionSection EXT
 106   Section /o ${EXT}
 107     Push $R0
 108     StrCpy $R0 ${EXT}
 109     Call RegisterExtension
 110     Pop $R0
 111   SectionEnd
 112 !macroend
 113
 114 !macro UnRegisterExtensionSection EXT
 115   Push $R0
 116   StrCpy $R0 ${EXT}
 117   Call un.RegisterExtension
 118   Pop $R0
 119 !macroend
 120
 121 ;;;;;;;;;;;;;;;;;;;;;;
 122 ; Installer sections ;
 123 ;;;;;;;;;;;;;;;;;;;;;;
 124
 125 Section "Media player (required)" SEC01
 126   SectionIn 1 2 3 RO
 127   SetShellVarContext all
 128   SetOutPath "$INSTDIR"
 129
 130   File  vlc.exe
 131   File  vlc.exe.manifest
 132   File  *.txt
 133
 134   File  /r plugins
 135   File  /r locale
 136   File  /r skins2
 137   File  /r http
 138
 139   WriteRegStr HKCR Applications\vlc.exe "" ""
 140   WriteRegStr HKCR Applications\vlc.exe\shell "" "Play"
 141   WriteRegStr HKCR Applications\vlc.exe\shell\Play\command "" \
 142     '$INSTDIR\vlc.exe "%1"'
 143
 144   WriteRegStr HKCR "AudioCD\shell\PlayWithVLC" "" "Play with VLC media player"
 145   WriteRegStr HKCR "AudioCD\shell\PlayWithVLC\command" "" \
 146     "$INSTDIR\vlc.exe cdda:%1"
 147   WriteRegStr HKCR "DVD\shell\PlayWithVLC" "" "Play with VLC media player"
 148   WriteRegStr HKCR "DVD\shell\PlayWithVLC\command" "" \
 149     "$INSTDIR\vlc.exe dvd:%1"
 150
 151   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Explorer\AutoplayHandlers\EventHandlers\PlayDVDMovieOnArrival" "VLCPlayDVDMovieOnArrival" ""
 152   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Explorer\AutoplayHandlers\Handlers\VLCPlayDVDMovieOnArrival" "Action" "Play DVD movie"
 153   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Explorer\AutoplayHandlers\Handlers\VLCPlayDVDMovieOnArrival" "DefaultIcon" "$INSTDIR\vlc.exe,0"
 154   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Explorer\AutoplayHandlers\Handlers\VLCPlayDVDMovieOnArrival" "Invoke.ProgID" "VLC.MediaFile"
 155   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Explorer\AutoplayHandlers\Handlers\VLCPlayDVDMovieOnArrival" "InvokeVerb" "play"
 156   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Explorer\AutoplayHandlers\Handlers\VLCPlayDVDMovieOnArrival" "Provider" "VideoLAN VLC media player"
 157
 158   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Explorer\AutoplayHandlers\EventHandlers\PlayCDAudioOnArrival" "VLCPlayCDAudioOnArrival" ""
 159   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Explorer\AutoplayHandlers\Handlers\VLCPlayCDAudioOnArrival" "Action" "Play CD audio"
 160   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Explorer\AutoplayHandlers\Handlers\VLCPlayCDAudioOnArrival" "DefaultIcon" "$INSTDIR\vlc.exe,0"
 161   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Explorer\AutoplayHandlers\Handlers\VLCPlayCDAudioOnArrival" "Invoke.ProgID" "VLC.MediaFile"
 162   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Explorer\AutoplayHandlers\Handlers\VLCPlayCDAudioOnArrival" "InvokeVerb" "play"
 163   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Explorer\AutoplayHandlers\Handlers\VLCPlayCDAudioOnArrival" "Provider" "VideoLAN VLC media player"
 164   WriteRegStr HKCR "VLC.MediaFile" "" "VLC media file"
 165   WriteRegStr HKCR "VLC.MediaFile\shell" "" "Play"
 166   WriteRegStr HKCR "VLC.MediaFile\shell\Play\command" "" \
 167     '$INSTDIR\vlc.exe "%1"'
 168   WriteRegStr HKCR "VLC.MediaFile\DefaultIcon" "" "$INSTDIR\vlc.exe,0"
 169
 170 SectionEnd
 171
 172 Section "Start Menu + Desktop Shortcut" SEC02
 173   SectionIn 1 2 3
 174   CreateDirectory "$SMPROGRAMS\VideoLAN"
 175   CreateShortCut "$SMPROGRAMS\VideoLAN\VLC media player.lnk" \
 176     "$INSTDIR\vlc.exe" "--intf wxwin"
 177   CreateShortCut "$SMPROGRAMS\VideoLAN\VLC media player (skins).lnk" \
 178     "$INSTDIR\vlc.exe" "--intf skins2"
 179   CreateShortCut "$DESKTOP\VLC media player.lnk" \
 180     "$INSTDIR\vlc.exe" "--intf wxwin"
 181   WriteIniStr "$INSTDIR\${PRODUCT_NAME}.url" "InternetShortcut" "URL" \
 182     "${PRODUCT_WEB_SITE}"
 183   CreateShortCut "$SMPROGRAMS\VideoLAN\Website.lnk" \
 184     "$INSTDIR\${PRODUCT_NAME}.url"
 185 SectionEnd
 186
 187 Section /o "Mozilla plugin" SEC03
 188   SectionIn 2 3
 189   File  /r mozilla
 190
 191   WriteRegStr HKLM \
 192     SOFTWARE\MozillaPlugins\@videolan.org/vlc,version=${VERSION} \
 193     "Path" '"$INSTDIR\mozilla\npvlc.dll"'
 194 SectionEnd
 195
 196 SubSection "File type associations" SEC04
 197   ; Make sure we have the same list in uninstall
 198   !insertmacro RegisterExtensionSection ".a52"
 199   !insertmacro RegisterExtensionSection ".aac"
 200   !insertmacro RegisterExtensionSection ".ac3"
 201   !insertmacro RegisterExtensionSection ".asf"
 202   !insertmacro RegisterExtensionSection ".asx"
 203   !insertmacro RegisterExtensionSection ".avi"
 204   !insertmacro RegisterExtensionSection ".bin"
 205   !insertmacro RegisterExtensionSection ".cue"
 206   !insertmacro RegisterExtensionSection ".divx"
 207   !insertmacro RegisterExtensionSection ".dts"
 208   !insertmacro RegisterExtensionSection ".dv"
 209   !insertmacro RegisterExtensionSection ".flac"
 210   !insertmacro RegisterExtensionSection ".m1v"
 211   !insertmacro RegisterExtensionSection ".m2v"
 212   !insertmacro RegisterExtensionSection ".m3u"
 213   !insertmacro RegisterExtensionSection ".mka"
 214   !insertmacro RegisterExtensionSection ".mkv"
 215   !insertmacro RegisterExtensionSection ".mov"
 216   !insertmacro RegisterExtensionSection ".mp1"
 217   !insertmacro RegisterExtensionSection ".mp2"
 218   !insertmacro RegisterExtensionSection ".mp3"
 219   !insertmacro RegisterExtensionSection ".mp4"
 220   !insertmacro RegisterExtensionSection ".mpeg"
 221   !insertmacro RegisterExtensionSection ".mpeg1"
 222   !insertmacro RegisterExtensionSection ".mpeg2"
 223   !insertmacro RegisterExtensionSection ".mpeg4"
 224   !insertmacro RegisterExtensionSection ".mpg"
 225   !insertmacro RegisterExtensionSection ".ogg"
 226   !insertmacro RegisterExtensionSection ".ogm"
 227   !insertmacro RegisterExtensionSection ".pls"
 228   !insertmacro RegisterExtensionSection ".spx"
 229   !insertmacro RegisterExtensionSection ".vob"
 230   !insertmacro RegisterExtensionSection ".wav"
 231   !insertmacro RegisterExtensionSection ".wma"
 232   !insertmacro RegisterExtensionSection ".wmv"
 233 SubSectionEnd
 234
 235 Section -Post
 236   WriteUninstaller "$INSTDIR\uninstall.exe"
 237   WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "InstallDir" $INSTDIR
 238   WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "Version" "${VERSION}"
 239   WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "" "$INSTDIR\vlc.exe"
 240
 241   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" \
 242     "DisplayName" "$(^Name)"
 243   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" \
 244     "UninstallString" "$INSTDIR\uninstall.exe"
 245   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" \
 246     "DisplayIcon" "$INSTDIR\vlc.exe"
 247   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" \
 248     "DisplayVersion" "${PRODUCT_VERSION}"
 249   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" \
 250     "URLInfoAbout" "${PRODUCT_WEB_SITE}"
 251   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" \
 252     "Publisher" "${PRODUCT_PUBLISHER}"
 253 SectionEnd
 254
 255 ; Section descriptions
 256 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 257   !insertmacro MUI_DESCRIPTION_TEXT ${SEC01} \
 258     "The media player itself"
 259   !insertmacro MUI_DESCRIPTION_TEXT ${SEC02} \
 260     "Adds icons to your start menu and your desktop for easy access"
 261   !insertmacro MUI_DESCRIPTION_TEXT ${SEC03} \
 262     "The VLC mozilla plugin"
 263   !insertmacro MUI_DESCRIPTION_TEXT ${SEC04} \
 264     "Sets VLC media player as the default application for the specified file type"
 265 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 266
 267
 268 Function un.onUninstSuccess
 269   HideWindow
 270   MessageBox MB_ICONINFORMATION|MB_OK \
 271     "$(^Name) was successfully removed from your computer."
 272 FunctionEnd
 273
 274 Function un.onInit
 275   MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 \
 276     "Are you sure you want to completely remove $(^Name) and all of its components?" IDYES +2
 277   Abort
 278 FunctionEnd
 279
 280 Section Uninstall
 281   SetShellVarContext all
 282
 283   ; Make sure we have the same list in install
 284   !insertmacro UnRegisterExtensionSection ".a52"
 285   !insertmacro UnRegisterExtensionSection ".aac"
 286   !insertmacro UnRegisterExtensionSection ".ac3"
 287   !insertmacro UnRegisterExtensionSection ".asf"
 288   !insertmacro UnRegisterExtensionSection ".asx"
 289   !insertmacro UnRegisterExtensionSection ".avi"
 290   !insertmacro UnRegisterExtensionSection ".bin"
 291   !insertmacro UnRegisterExtensionSection ".cue"
 292   !insertmacro UnRegisterExtensionSection ".divx"
 293   !insertmacro UnRegisterExtensionSection ".dts"
 294   !insertmacro UnRegisterExtensionSection ".dv"
 295   !insertmacro UnRegisterExtensionSection ".flac"
 296   !insertmacro UnRegisterExtensionSection ".m1v"
 297   !insertmacro UnRegisterExtensionSection ".m2v"
 298   !insertmacro UnRegisterExtensionSection ".m3u"
 299   !insertmacro UnRegisterExtensionSection ".mka"
 300   !insertmacro UnRegisterExtensionSection ".mkv"
 301   !insertmacro UnRegisterExtensionSection ".mov"
 302   !insertmacro UnRegisterExtensionSection ".mp1"
 303   !insertmacro UnRegisterExtensionSection ".mp2"
 304   !insertmacro UnRegisterExtensionSection ".mp3"
 305   !insertmacro UnRegisterExtensionSection ".mp4"
 306   !insertmacro UnRegisterExtensionSection ".mpeg"
 307   !insertmacro UnRegisterExtensionSection ".mpeg1"
 308   !insertmacro UnRegisterExtensionSection ".mpeg2"
 309   !insertmacro UnRegisterExtensionSection ".mpeg4"
 310   !insertmacro UnRegisterExtensionSection ".mpg"
 311   !insertmacro UnRegisterExtensionSection ".ogg"
 312   !insertmacro UnRegisterExtensionSection ".ogm"
 313   !insertmacro UnRegisterExtensionSection ".pls"
 314   !insertmacro UnRegisterExtensionSection ".spx"
 315   !insertmacro UnRegisterExtensionSection ".vob"
 316   !insertmacro UnRegisterExtensionSection ".wav"
 317   !insertmacro UnRegisterExtensionSection ".wma"
 318   !insertmacro UnRegisterExtensionSection ".wmv"
 319
 320   RMDir "$SMPROGRAMS\VideoLAN"
 321   RMDir /r $SMPROGRAMS\VideoLAN
 322   RMDir /r $INSTDIR
 323   DeleteRegKey HKLM Software\VideoLAN
 324
 325   DeleteRegKey HKCR Applications\vlc.exe
 326   DeleteRegKey HKCR AudioCD\shell\PlayWithVLC
 327   DeleteRegKey HKCR DVD\shell\PlayWithVLC
 328   DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Explorer\AutoplayHandlers\EventHandlers\PlayDVDMovieOnArrival" "VLCPlayDVDMovieOnArrival"
 329   DeleteRegKey HKLM Software\Microsoft\Windows\CurrentVersion\Explorer\AutoplayHandlers\Handlers\VLCPlayDVDMovieOnArrival
 330   DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Explorer\AutoplayHandlers\EventHandlers\PlayCDAudioOnArrival" "VLCPlayCDAudioOnArrival"
 331   DeleteRegKey HKLM Software\Microsoft\Windows\CurrentVersion\Explorer\AutoplayHandlers\Handlers\VLCPlayCDAudioOnArrival
 332   DeleteRegKey HKCR "VLC.MediaFile"
 333
 334   DeleteRegKey HKLM \
 335     SOFTWARE\MozillaPlugins\@videolan.org/vlc,version=${VERSION}
 336
 337   DeleteRegKey HKLM \
 338     Software\Microsoft\Windows\CurrentVersion\Uninstall\VideoLAN
 339
 340   Delete "$DESKTOP\VLC media player.lnk"
 341
 342   DeleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"
 343   DeleteRegKey HKLM "${PRODUCT_DIR_REGKEY}"
 344   SetAutoClose true
 345 SectionEnd