configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 1999-2017 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 3.0.0-git)
   6 VERSION_MAJOR=3
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=git
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Vetinari"
  17 COPYRIGHT_YEARS="1996-2017"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 AM_SILENT_RULES([yes])
  31 AM_MAINTAINER_MODE([enable])
  32
  33 dnl
  34 dnl Directories
  35 dnl
  36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  37 dnl AC_SUBST(vlcincludedir)
  38 vlcdatadir="\${datadir}/\${PKGDIR}"
  39 AC_SUBST(vlcdatadir)
  40 vlclibdir="\${libdir}/\${PKGDIR}"
  41 AC_SUBST(vlclibdir)
  42
  43 dnl
  44 dnl Check for tools
  45 dnl
  46 AC_PROG_CC_C99
  47 AC_USE_SYSTEM_EXTENSIONS
  48 VLC_PROG_CC_C11
  49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  51 AH_TOP([
  52 #ifndef _REENTRANT
  53 # define _REENTRANT
  54 #endif
  55 ])
  56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  59
  60 AM_PROG_CC_C_O
  61 AC_PROG_CXX
  62 AC_PROG_CPP
  63 AC_PROG_OBJC
  64 _AM_DEPENDENCIES([OBJC])
  65 AC_PROG_EGREP
  66 AC_PROG_MAKE_SET
  67 AC_PROG_INSTALL
  68 AM_PROG_AS
  69
  70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
  73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
  74 AS_IF([test "$BUILDCC" = "false"], [
  75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
  76 ])
  77
  78 dnl Check for compiler properties
  79 AC_C_CONST
  80 AC_C_INLINE
  81 AC_C_RESTRICT
  82 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
  83
  84 dnl Extend the --help string at the current spot.
  85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  86
  87 dnl Allow binary package maintainer to pass a custom string to avoid
  88 dnl cache problem
  89 AC_ARG_WITH(binary-version,
  90     AS_HELP_STRING([--with-binary-version=STRING],
  91          [To avoid plugins cache problem between binary version]),[],[])
  92 AS_IF([test -n "${with_binary_version}"],[
  93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  94          [Binary specific version])
  95 ])
  96
  97 dnl
  98 dnl  Check the operating system
  99 dnl
 100 HAVE_WIN64="0"
 101 HAVE_IOS="0"
 102 HAVE_OSX="0"
 103 HAVE_TVOS="0"
 104
 105 case "${host_os}" in
 106   "")
 107     SYS=unknown
 108     ;;
 109   linux*)
 110     SYS=linux
 111     ;;
 112   bsdi*)
 113     SYS=bsdi
 114     CFLAGS="${CFLAGS} -pthread"
 115     ;;
 116   freebsd*)
 117     SYS=freebsd
 118     CFLAGS="${CFLAGS} -pthread"
 119     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 120     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 121     ac_cv_ld_z_defs=no
 122     ;;
 123   openbsd*)
 124     SYS=openbsd
 125     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 126     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 127     ;;
 128   netbsd*)
 129     SYS=netbsd
 130     ;;
 131   dragonfly*)
 132     SYS=dragonfly
 133     ;;
 134   darwin*)
 135
 136     dnl Force gcc "-arch" flag
 137     ARCH_flag=""
 138     case "${host}" in
 139       i?86*)
 140         ARCH_flag="-arch i386"
 141       ;;
 142       ppc64*)
 143         ARCH_flag="-arch ppc64"
 144       ;;
 145       ppc*)
 146         ARCH_flag="-arch ppc"
 147       ;;
 148       x86_64*)
 149         ARCH_flag="-arch x86_64"
 150       ;;
 151       arm*)
 152         ac_cv_c_bigendian="no"
 153         ac_cv_c_attribute_packed="no"
 154       ;;
 155     esac
 156
 157     SYS=darwin
 158     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 159     CXX="${CXX} -stdlib=libc++ -std=c++11"
 160     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 161     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 162     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
 163     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 164     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 165     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 166
 167     AC_EGREP_CPP(yes,
 168             [#import <TargetConditionals.h>
 169              #if TARGET_OS_IPHONE
 170              yes
 171              #endif],
 172              [HAVE_IOS="1"],
 173              [HAVE_OSX="1"])
 174
 175     AC_EGREP_CPP(yes,
 176             [#import <TargetConditionals.h>
 177              #if TARGET_OS_TV
 178              yes
 179              #endif],
 180              [HAVE_TVOS="1"
 181              HAVE_IOS="0"
 182              HAVE_OSX="0"
 183              ],)
 184
 185     dnl Allow binaries created on Lion to run on earlier releases
 186     AC_EGREP_CPP(yes,
 187            [#import <Cocoa/Cocoa.h>
 188             #ifdef MAC_OS_X_VERSION_10_7
 189             yes
 190             #endif],
 191             [AC_MSG_RESULT([yes])
 192             AC_LIBOBJ([getdelim])
 193             AC_LIBOBJ([strndup])
 194             AC_LIBOBJ([strnlen])],)
 195
 196     dnl
 197     dnl  Handle Mac OS X SDK flags
 198     dnl
 199     AC_ARG_WITH(macosx-sdk,
 200       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 201         [compile using the SDK in DIR])])
 202     if test "${with_macosx_sdk}" != "" ; then
 203         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 204         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 205         CC="${CC} -isysroot ${with_macosx_sdk}"
 206         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 207         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 208         LD="${LD} -syslibroot ${with_macosx_sdk}"
 209     fi
 210     AC_ARG_WITH(macosx-version-min,
 211       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 212         [compile for Mac OS X VERSION and above])])
 213     if test "${with_macosx_version_min}" != "" ; then
 214         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 215         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 216         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 217         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 218         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 219     fi
 220     ;;
 221   *mingw32* | *cygwin* | *wince* | *mingwce*)
 222     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
 223     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
 224     CXXFLAGS="${CXXFLAGS} -static-libgcc"
 225     AC_CHECK_TOOL(WINDRES, windres, :)
 226     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 227     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
 228     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
 229     AH_TOP([#endif])
 230     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 231     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 232     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 233     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 234     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 235     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 236     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 237     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 238     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 239     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 240     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 241
 242     case "${host_os}" in
 243       *mingw32*)
 244         SYS=mingw32
 245         ;;
 246       *cygwin*)
 247         dnl Check if we are using the mno-cygwin mode in which case we are
 248         dnl actually dealing with a mingw32 compiler.
 249         AC_EGREP_CPP(yes,
 250             [#ifdef _WIN32
 251              yes
 252              #endif],
 253             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 254         ;;
 255     esac
 256
 257     if test "${SYS}" = "mingw32"; then
 258         # DEP, ASLR, NO SEH
 259         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 260
 261         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 262         ac_default_prefix="`pwd`/_win32"
 263         DESTDIR="`pwd`/_win32/"
 264
 265         dnl
 266         dnl NSIS/MSI Installer prefix and WIN64
 267         dnl
 268         case "${host}" in
 269             amd64*|x86_64*)
 270                 HAVE_WIN64="1"
 271                 WINDOWS_ARCH="x64"
 272                 PROGRAMFILES="PROGRAMFILES64"
 273                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
 274             ;;
 275             *)
 276                 WINDOWS_ARCH="x86"
 277                 PROGRAMFILES="PROGRAMFILES"
 278             ;;
 279         esac
 280         AC_SUBST(WINDOWS_ARCH)
 281         AC_SUBST(PROGRAMFILES)
 282
 283     fi
 284     ;;
 285   *nto*)
 286     SYS=nto
 287     ;;
 288   solaris*)
 289     SYS=solaris
 290     ;;
 291   hpux*)
 292     SYS=hpux
 293     ;;
 294   *os2*)
 295     SYS=os2
 296     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 297     AC_LIBOBJ([freeaddrinfo])
 298     AC_LIBOBJ([gai_strerror])
 299     ;;
 300   *)
 301     SYS="${host_os}"
 302     ;;
 303 esac
 304
 305 dnl WinRT
 306 AC_ARG_ENABLE(winstore_app,
 307      AS_HELP_STRING([--enable-winstore-app],
 308                     [Build targetted for Windows Store apps (default disabled)]))
 309
 310 vlc_winstore_app=0
 311 AS_IF([test "${SYS}" = "mingw32"],[
 312   LIBCOM="-lole32"
 313   AS_IF([test "${enable_winstore_app}" = "yes"], [
 314     vlc_winstore_app=1
 315     LIBCOM=""
 316      VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
 317      AC_LIBOBJ([gai_strerror])
 318     ],[
 319      VLC_ADD_LIBS([libvlccore],[-lwinmm])
 320     ])
 321   AC_SUBST(LIBCOM)
 322   ])
 323 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 324
 325 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 326 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 327
 328 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 329 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
 330 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
 331 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
 332
 333 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 334 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
 335 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 336 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
 337
 338 dnl
 339 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 340 dnl for program foo on win32
 341 case "${build_os}" in
 342     cygwin|msys|mingw32)
 343         ac_executable_extensions=".exe"
 344         BUILDEXEEXT=".exe"
 345     ;;
 346     os2*)
 347         BUILDEXEEXT=".exe"
 348     ;;
 349     *)
 350     ;;
 351 esac
 352 AC_SUBST(BUILDEXEEXT)
 353
 354 dnl Android is linux, but a bit different
 355 AS_IF([test "$SYS" = linux],[
 356     AC_MSG_CHECKING([for an Android system])
 357     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 358         [[#ifndef __ANDROID__
 359          # error Not Android
 360          #endif
 361         ]],[[;]])
 362     ],[
 363       HAVE_ANDROID="1"
 364       AC_MSG_RESULT([yes])
 365     ],[
 366       AC_MSG_RESULT([no])
 367     ])
 368 ])
 369 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 370
 371 dnl Tizen (minimum SDK version: 2.3)
 372 AS_IF([test "$SYS" = linux],[
 373     AC_MSG_CHECKING([for Tizen])
 374     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 375         [[#include <tizen.h>
 376         ]],[[;]])
 377     ],[
 378       HAVE_TIZEN="1"
 379       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
 380       AC_MSG_RESULT([yes])
 381     ],[
 382       AC_MSG_RESULT([no])
 383     ])
 384 ])
 385 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
 386
 387 dnl
 388 dnl  Check for the contrib directory
 389 dnl
 390 AC_ARG_WITH(contrib,
 391   [AS_HELP_STRING([--with-contrib[=DIR]],
 392     [search for 3rd party libraries in DIR/include and DIR/lib])
 393 ])
 394 AC_MSG_CHECKING([for 3rd party libraries path])
 395 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 396   CONTRIB_DIR="${srcdir}/contrib/${host}"
 397   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 398     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 399     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 400     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 401       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 402       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
 403       AS_IF([test ! -d "${CONTRIB_DIR}"], [
 404         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 405         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
 406         AS_IF([test ! -d "${CONTRIB_DIR}"], [
 407           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 408           CONTRIB_DIR=""
 409           AC_MSG_RESULT([not found])
 410         ])
 411       ])
 412     ])
 413   ])
 414 ], [
 415   AS_IF([test "${with_contrib}" != "no"], [
 416     CONTRIB_DIR="${with_contrib}"
 417   ], [
 418     CONTRIB_DIR=""
 419     AC_MSG_RESULT([disabled])
 420   ])
 421 ])
 422 AS_IF([test -n "${CONTRIB_DIR}"], [
 423   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 424     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 425   ], [
 426     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 427     CONTRIB_DIR=""
 428     AC_MSG_RESULT([not usable])
 429   ])
 430
 431 ])
 432 AS_IF([test -n "${CONTRIB_DIR}"], [
 433   AC_MSG_RESULT([${CONTRIB_DIR}])
 434   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 435   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 436   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 437   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
 438   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 439   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 440
 441   AS_IF([test -z "$LUAC"], [
 442     dnl Old contribs mixed cross-tools and cross-compiled executables
 443     AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
 444       LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
 445     ])
 446
 447     dnl Newer contribs follow usual name space rules
 448     AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
 449       LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
 450     ])
 451   ])
 452
 453   AS_IF([test "${SYS}" = "darwin"], [
 454     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 455     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 456   ])
 457 ], [
 458   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 459     AC_MSG_ERROR([Third party libraries not found!])
 460   ])
 461 ])
 462 AC_SUBST(CONTRIB_DIR)
 463
 464 dnl Add extras/tools to the PATH
 465 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 466 AS_IF([test -d "${TOOLS_DIR}"], [
 467     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 468     export PATH="${TOOLS_DIR}":$PATH
 469 ])
 470
 471 dnl
 472 dnl  Libtool
 473 dnl  It's very bad, but our former custom system was worst
 474 dnl  -- Courmisch
 475 dnl
 476
 477 dnl override platform specific check for dependent libraries
 478 dnl otherwise libtool linking of shared libraries will
 479 dnl fail on anything other than pass_all.
 480 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 481     [lt_cv_deplibs_check_method=pass_all])
 482
 483 LT_INIT([dlopen win32-dll shared disable-static])
 484 LT_LANG([C++])
 485 LT_LANG([Windows Resource])
 486
 487 DOLT
 488
 489 lt_cv_deplibs_check_method=pass_all
 490
 491 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 492   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 493 ])
 494
 495 dnl
 496 dnl Gettext stuff
 497 dnl
 498 AM_GNU_GETTEXT_VERSION([0.19.8])
 499 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 500
 501 dnl
 502 dnl Iconv stuff
 503 dnl
 504 AM_ICONV
 505
 506 dnl
 507 dnl checks for mingw
 508 AS_IF([test "${SYS}" = "mingw32"], [
 509
 510 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 511 #if !defined(__MINGW32__)
 512 # error Not compiling with mingw
 513 #endif
 514     ])], [
 515
 516 dnl Check for broken versions of mingw-runtime compatability library
 517     AC_MSG_CHECKING(for broken mingw-runtime)
 518     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 519 #include <_mingw.h>
 520 #if defined(__MINGW64_VERSION_MAJOR)
 521 # if __MINGW64_VERSION_MAJOR < 3
 522 #  error Attempting to use mingw-runtime with broken vsnprintf support
 523 # endif
 524 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
 525 # error Attempting to use mingw-runtime with broken vsnprintf support
 526 #endif
 527     ])], [
 528         AC_MSG_RESULT([ok])
 529     ], [
 530         AC_MSG_RESULT([present])
 531         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
 532     ])
 533
 534     dnl force use of mingw provided c99 *printf over msvcrt
 535     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 536
 537     dnl Add WinMainCRTStartup entry point to show it's a WinMain application
 538     VLC_ADD_LDFLAGS([vlc],[-mwindows])
 539
 540     dnl Check for the need to include the mingwex lib for mingw32
 541     VLC_SAVE_FLAGS
 542     AC_CHECK_LIB(mingwex,opendir,
 543         AC_CHECK_LIB(mingw32,opendir,,
 544             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 545     )
 546     VLC_RESTORE_FLAGS
 547     ], [
 548         AC_MSG_RESULT([Not compiling with mingw])
 549     ])
 550
 551     dnl Check for fnative-struct or mms-bitfields support for mingw32
 552     VLC_SAVE_FLAGS
 553     CFLAGS="${CFLAGS} -mms-bitfields"
 554     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
 555     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 556         [ac_cv_c_mms_bitfields],
 557         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 558     if test "${ac_cv_c_mms_bitfields}" = "no"; then
 559         VLC_RESTORE_FLAGS
 560         CFLAGS="${CFLAGS} -fnative-struct"
 561         CXXFLAGS="${CXXFLAGS} -fnative-struct"
 562         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 563             [ac_cv_c_fnative_struct],
 564             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 565         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
 566     fi
 567 ])
 568
 569
 570 dnl
 571 dnl Buggy glibc prevention. Purposedly not cached.
 572 dnl See sourceware.org bugs 5058 and 5443.
 573 dnl Ubuntu alone has 20 bug numbers for this...
 574 dnl
 575 AC_MSG_CHECKING(for buggy GNU/libc versions)
 576 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 577 #include <limits.h>
 578 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 579   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 580 # error GNU/libc with dcgettext killer bug!
 581 #endif
 582 ])], [
 583   AC_MSG_RESULT([not present])
 584 ], [
 585   AC_MSG_RESULT([found])
 586   AS_IF([test "x${enable_nls}" != "xno"], [
 587     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 588 work-around for this. Check with your distribution vendor on how to update the
 589 glibc run-time. Alternatively, build with --disable-nls.])
 590   ])
 591 ])
 592
 593 dnl Plugin compilation stuff
 594
 595 VLC_LIBRARY_SUFFIX
 596
 597 dnl Check for system libs needed
 598 need_libc=false
 599
 600 dnl Check for usual libc functions
 601 AC_CHECK_FUNCS([daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime tdestroy uselocale pthread_cond_timedwait_monotonic_np pthread_condattr_setclock])
 602 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv memrchr nrand48 poll posix_memalign recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tfind timegm timespec_get strverscmp])
 603 AC_REPLACE_FUNCS([gettimeofday])
 604 AC_CHECK_FUNC(fdatasync,,
 605   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 606 ])
 607
 608 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
 609
 610 dnl mingw64 implements those as static inline, not functions with C linkage
 611 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
 612 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
 613 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
 614 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
 615
 616 dnl C11 static_assert()
 617 AC_MSG_CHECKING([for static_assert in assert.h])
 618 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 619 static_assert(1, "The impossible happened.");
 620 ])], [
 621   AC_MSG_RESULT([yes])
 622   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 623 ], [
 624   AC_MSG_RESULT([no])
 625 ])
 626
 627 # Windows CE does not have strcoll()
 628 AC_FUNC_STRCOLL
 629
 630 dnl Check for non-standard system calls
 631 case "$SYS" in
 632   "linux")
 633     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity recvmmsg])
 634     ;;
 635   "mingw32")
 636     AC_CHECK_FUNCS([_lock_file])
 637     ;;
 638 esac
 639
 640 AH_BOTTOM([#include <vlc_fixups.h>])
 641
 642 dnl Check for struct pollfd
 643 AC_CHECK_TYPES([struct pollfd],,,
 644 [#include <sys/types.h>
 645 #if HAVE_POLL
 646 # include <poll.h>
 647 #elif defined (_WIN32)
 648 # include <winsock2.h>
 649 #endif
 650 ])
 651
 652 dnl Check for struct timespec
 653 AC_CHECK_TYPES([struct timespec],,,
 654 [#include <time.h>])
 655
 656 dnl Check for max_align_t
 657 AC_CHECK_TYPES([max_align_t],,,
 658 [#include <stddef.h>])
 659
 660 dnl Checks for socket stuff
 661 VLC_SAVE_FLAGS
 662 SOCKET_LIBS=""
 663 AC_SEARCH_LIBS(connect, [socket], [
 664   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 665     SOCKET_LIBS="$ac_cv_search_connect"
 666   ])
 667 ], [
 668   AS_IF([test "${SYS}" = "mingw32"], [
 669     SOCKET_LIBS="-lws2_32"
 670   ])
 671 ])
 672
 673 AC_SEARCH_LIBS([inet_pton], [nsl], [
 674  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
 675     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
 676   ])
 677 ],, [${SOCKET_LIBS}])
 678
 679 LIBS="${LIBS} ${SOCKET_LIBS}"
 680 AC_LINK_IFELSE([
 681     AC_LANG_PROGRAM([#ifdef _WIN32
 682         # if _WIN32_WINNT < 0x600
 683         #  error Needs vista+
 684         # endif
 685         #include <ws2tcpip.h>
 686         #else
 687         #include <sys/socket.h>
 688         #include <arpa/inet.h>
 689         #endif], [
 690         char dst[[sizeof(struct in_addr)]];
 691         inet_pton(AF_INET, "127.0.0.1", dst);
 692     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 693 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
 694 VLC_RESTORE_FLAGS
 695 AC_SUBST(SOCKET_LIBS)
 696
 697 dnl Check for socklen_t
 698 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 699 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 700 ac_cv_type_socklen_t,
 701 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 702 [#include <sys/types.h>
 703 #ifdef _WIN32
 704 # include <winsock2.h>
 705 # include <ws2tcpip.h>
 706 #else
 707 # include <sys/socket.h>
 708 #endif]], [[socklen_t len; len = 0;]])],
 709 ac_cv_type_socklen_t=yes,
 710 ac_cv_type_socklen_t=no)])
 711 AS_IF([test "$ac_cv_type_socklen_t" = no],
 712  [AC_DEFINE(socklen_t, int)])
 713
 714 dnl Check for struct sockaddr_storage
 715 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 716 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 717 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 718   [AC_TRY_COMPILE(
 719     [#include <sys/types.h>
 720      #if defined( _WIN32 )
 721      # include <winsock2.h>
 722      #else
 723      # include <sys/socket.h>
 724      #endif], [struct sockaddr_storage addr;],
 725      ac_cv_struct_sockaddr_storage=yes,
 726      ac_cv_struct_sockaddr_storage=no)])
 727 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 728   AC_DEFINE(sockaddr_storage, sockaddr)
 729   AC_DEFINE(ss_family, sa_family)
 730 ])
 731
 732 dnl FreeBSD has a gnugetopt library for this:
 733 GNUGETOPT_LIBS=""
 734 AC_CHECK_FUNC(getopt_long,, [
 735   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 736     GNUGETOPT_LIBS="-lgnugetopt"
 737   ])
 738 ])
 739 AC_SUBST(GNUGETOPT_LIBS)
 740
 741 AC_CHECK_LIB(m,cos,[
 742   LIBM="-lm"
 743 ], [
 744   LIBM=""
 745 ])
 746 AC_SUBST(LIBM)
 747
 748 AC_CHECK_LIB(m,lrintf, [
 749   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 750   VLC_ADD_LIBS([skins2],[-lm])
 751 ])
 752 AC_CHECK_LIB(m,nanf,
 753   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 754 )
 755 AC_CHECK_LIB(m,sincos, [
 756   AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
 757 ], [
 758   AC_LIBOBJ([sincos])
 759 ])
 760
 761 dnl Check for dynamic plugins
 762 LIBDL=""
 763 have_dynamic_objects="no"
 764 VLC_SAVE_FLAGS
 765 AC_SEARCH_LIBS(dlsym, [dl svld], [
 766   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 767     LIBDL="$ac_cv_search_dlsym"
 768   ])
 769   have_dynamic_objects="yes"
 770 ])
 771 VLC_RESTORE_FLAGS
 772
 773 # Windows
 774 AS_IF([test "${SYS}" = "mingw32"], [
 775   LIBDL=""
 776   have_dynamic_objects="yes" #assume we can use shared objects
 777 ])
 778
 779 AS_IF([test "${enable_shared}" = "no"], [
 780   have_dynamic_objects=no
 781 ])
 782 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 783
 784 AC_SUBST(LIBDL)
 785
 786 dnl Check for thread library
 787 LIBPTHREAD=""
 788 AS_IF([test "${SYS}" != "mingw32"], [
 789   VLC_SAVE_FLAGS
 790   LIBS=""
 791   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 792     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 793       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 794     ])
 795   ])
 796   VLC_RESTORE_FLAGS
 797 ])
 798 AC_SUBST(LIBPTHREAD)
 799
 800 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
 801   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
 802     LIBRT="$ac_cv_search_clock_nanosleep"
 803   ])
 804 ], [
 805   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
 806     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
 807       LIBRT="$ac_cv_search_nanosleep"
 808     ])
 809   ])
 810 ])
 811 AC_SUBST(LIBRT)
 812
 813 dnl
 814 dnl Check for headers
 815 dnl
 816
 817 dnl  POSIX
 818 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
 819 AC_CHECK_HEADERS([net/if.h], [], [],
 820 [
 821 #include <sys/types.h>
 822 #include <sys/socket.h>
 823 ])
 824 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
 825 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
 826
 827 dnl  BSD
 828 AC_CHECK_HEADERS([netinet/udplite.h sys/param.h sys/mount.h])
 829
 830 dnl  GNU/Linux
 831 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 832
 833 dnl  MacOS
 834 AC_CHECK_HEADERS([xlocale.h])
 835
 836 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 837 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 838 AC_CHECK_TYPE(ssize_t,, [
 839   AC_DEFINE(ssize_t, int)
 840 ])
 841
 842 dnl It seems that autoconf detects pkg-config only during the first
 843 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 844 dnl it is nested within a conditional block, so it was not working right.
 845 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 846 AC_ARG_VAR(PKG_CONFIG_PATH,
 847        [Paths where to find .pc not at the default location])
 848 PKG_PROG_PKG_CONFIG()
 849
 850 dnl On some OS we need static linking
 851 AS_IF([test -n "${PKG_CONFIG}" ],[
 852     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 853         PKG_CONFIG="${PKG_CONFIG} --static"
 854     ])
 855 ])
 856
 857
 858 dnl
 859 dnl Check for zlib.h and -lz along with system -lminizip if available
 860 dnl
 861 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 862 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 863 if test "${have_zlib}" = "yes"
 864 then
 865   VLC_ADD_LIBS([skins2 sap unzip zip],[-lz])
 866   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 867     AC_CHECK_HEADERS([unzip.h], [
 868       have_minizip=yes
 869       MINIZIP_LIBS="-lminizip -lz"
 870     ], [
 871       VLC_ADD_CPPFLAGS([skins2], [-I\\\$(top_srcdir)/modules/access/zip/unzip])
 872       VLC_ADD_LIBS([skins2], [\\\$(top_builddir)/modules/libunzip.la])
 873       have_minizip=no
 874     ])
 875   ])
 876   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
 877   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
 878 fi
 879 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 880
 881
 882 dnl
 883 dnl Domain name i18n support via GNU libidn
 884 dnl
 885 PKG_CHECK_MODULES([IDN], [libidn], [
 886   have_libidn="yes"
 887   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 888 ], [
 889   have_libidn="no"
 890 ])
 891
 892
 893 dnl Check for dbus
 894 AC_ARG_ENABLE(dbus,
 895   [AS_HELP_STRING([--enable-dbus],
 896     [compile D-Bus message bus support (default enabled)])])
 897 have_dbus="no"
 898 AS_IF([test "${enable_dbus}" != "no"], [
 899   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 900     have_dbus="yes"
 901   ], [
 902     AS_IF([test -n "${enable_dbus}"], [
 903       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 904     ], [
 905       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 906     ])
 907   ])
 908 ])
 909 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 910
 911
 912 dnl Check for systemd
 913 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
 914   have_systemd="yes"
 915 ], [
 916   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
 917 ])
 918 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
 919
 920
 921 dnl Check for ntohl, etc.
 922 VLC_SAVE_FLAGS
 923 CFLAGS="${CFLAGS} -Wall -Werror"
 924 AC_CACHE_CHECK([for ntohl in sys/param.h],
 925     [ac_cv_c_ntohl_sys_param_h],
 926     [     AC_TRY_COMPILE([#include <sys/param.h>],
 927         [int meuh; ntohl(meuh);],
 928         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
 929 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
 930     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
 931 fi
 932 VLC_RESTORE_FLAGS
 933
 934 EXTEND_HELP_STRING([Optimization options:])
 935 dnl
 936 dnl  Compiler warnings
 937 dnl
 938
 939 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration init-self logical-op format-security])
 940 RDC_PROG_CC_FLAGS([-pipe])
 941 AC_LANG_PUSH([C++])
 942 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var format-security])
 943 AC_LANG_POP([C++])
 944
 945 dnl
 946 dnl  Debugging mode
 947 dnl
 948 AC_ARG_ENABLE(debug,
 949   [AS_HELP_STRING([--enable-debug],
 950     [build with run-time assertions (default disabled)])],,
 951   [enable_debug="no"])
 952 AH_TEMPLATE(NDEBUG,
 953             [Define to 1 if debug code should NOT be compiled])
 954 AS_IF([test "${enable_debug}" != "no"], [
 955   AC_CHECK_HEADERS([valgrind/valgrind.h])
 956 ], [
 957   AC_DEFINE(NDEBUG)
 958 ])
 959
 960 dnl
 961 dnl  Profiling
 962 dnl
 963 AC_ARG_ENABLE(gprof,
 964   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 965   [enable_gprof="no"])
 966 AS_IF([test "${enable_gprof}" != "no"], [
 967   CFLAGS="${CFLAGS} -pg"
 968   CXXFLAGS="${CXXFLAGS} -pg"
 969   OBJCFLAGS="${OBJCFLAGS} -pg"
 970   LDFLAGS="${LDFLAGS} -pg"
 971 ])
 972
 973 AC_ARG_ENABLE(cprof,
 974   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 975   [enable_cprof="no"])
 976 AS_IF([test "${enable_gprof}" != "no"], [
 977   CFLAGS="${CFLAGS} -finstrument-functions"
 978   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 979   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 980   LDFLAGS="${LDFLAGS} -finstrument-functions"
 981 ])
 982
 983 dnl
 984 dnl  Test coverage
 985 dnl
 986 AC_ARG_ENABLE(coverage,
 987   [AS_HELP_STRING([--enable-coverage],
 988     [build for test coverage (default disabled)])],,
 989   [enable_coverage="no"])
 990 AS_IF([test "${enable_coverage}" != "no"], [
 991   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 992   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 993   LDFLAGS="-lgcov ${LDFLAGS}"
 994 ])
 995
 996 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
 997   VLC_SAVE_FLAGS
 998   CFLAGS="${CFLAGS} -fvisibility=hidden"
 999   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
1000   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
1001   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
1002                  [ac_cv_c_visibility_hidden], [
1003     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1004       ac_cv_c_visibility_hidden=yes
1005     ], [
1006       ac_cv_c_visibility_hidden=no
1007     ])
1008   ])
1009   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1010 ])
1011
1012
1013 dnl
1014 dnl  Enable/disable optimizations
1015 dnl
1016 AC_ARG_ENABLE(optimizations,
1017   [AS_HELP_STRING([--disable-optimizations],
1018     [disable compiler optimizations (default enabled)])],,
1019   [enable_optimizations="yes"])
1020
1021 dnl Check for various optimization flags
1022 AS_IF([test "${enable_optimizations}" != "no"], [
1023
1024   dnl -O3 only in production builds
1025   AS_IF([test "${enable_debug}" = "no"], [
1026     VLC_SAVE_FLAGS
1027     CFLAGS="${CFLAGS} -O3"
1028     CXXFLAGS="${CXXFLAGS} -O3"
1029     OBJCFLAGS="${OBJCFLAGS} -O3"
1030     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1031       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1032         ac_cv_c_o3=yes
1033       ], [
1034         ac_cv_c_o3=no
1035       ])
1036     ])
1037     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1038   ])
1039
1040   dnl Check for fast maths
1041   RDC_PROG_CC_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1042   AC_LANG_PUSH(C++)
1043   RDC_PROG_CXX_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1044   AC_LANG_POP
1045
1046 AH_BOTTOM([
1047 #if defined(_MSC_VER) && !defined(__clang__)
1048 # pragma fenv_access(off)
1049 # pragma fp_contract(on)
1050 #elif defined(__GNUC__)
1051 /* Not supported so far */
1052 #else
1053 # pragma STDC FENV_ACCESS OFF
1054 # pragma STDC FP_CONTRACT ON
1055 #endif
1056 ])
1057
1058   dnl Check for -funroll-loops
1059   VLC_SAVE_FLAGS
1060   CFLAGS="${CFLAGS} -funroll-loops"
1061   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1062   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1063   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1064     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1065       ac_cv_c_unroll_loops=yes
1066     ], [
1067       ac_cv_c_unroll_loops=no
1068     ])
1069   ])
1070   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1071
1072   AS_IF([test "$enable_debug" = "no"], [
1073     dnl Check for -fomit-frame-pointer
1074     VLC_SAVE_FLAGS
1075     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1076     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1077     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1078     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1079       [ac_cv_c_omit_frame_pointer], [
1080       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1081         ac_cv_c_omit_frame_pointer=yes
1082       ], [
1083         ac_cv_c_omit_frame_pointer=no
1084       ])
1085     ])
1086     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1087   ])
1088 ])
1089
1090 VLC_SAVE_FLAGS
1091 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1092 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1093   AC_TRY_LINK([],, [
1094     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1095   ], [
1096     ac_cv_ld_bsymbolic=""
1097   ])
1098 ])
1099 VLC_RESTORE_FLAGS
1100 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1101 AC_SUBST(SYMBOLIC_LDFLAGS)
1102
1103 VLC_SAVE_FLAGS
1104 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1105 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1106   AC_TRY_LINK([],, [
1107     ac_cv_ld_z_defs="yes"
1108   ], [
1109     ac_cv_ld_z_defs="no"
1110   ])
1111 ])
1112 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1113
1114 dnl Checks for __attribute__(aligned()) directive
1115 VLC_SAVE_FLAGS
1116 CFLAGS="${CFLAGS} -Werror"
1117 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1118     [ac_cv_c_attribute_aligned],
1119     [ac_cv_c_attribute_aligned=0
1120     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1121         AC_TRY_COMPILE([],
1122         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1123         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1124     done])
1125 VLC_RESTORE_FLAGS
1126 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1127     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1128         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1129 fi
1130
1131 dnl Check for __attribute__((packed))
1132 AC_CACHE_CHECK([for __attribute__((packed))],
1133   [ac_cv_c_attribute_packed],
1134   [ac_cv_c_attribute_packed=no
1135    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1136                     [ac_cv_c_attribute_packed=yes])])
1137 if test "${ac_cv_c_attribute_packed}" != "no"; then
1138   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1139 fi
1140
1141 dnl
1142 dnl  Check the CPU
1143 dnl
1144 case "${host_cpu}" in
1145   "")
1146     ARCH=unknown
1147     ;;
1148   *)
1149     ARCH="${host_cpu}"
1150     ;;
1151 esac
1152
1153 dnl Check for backtrace() support
1154 AC_CHECK_HEADERS(execinfo.h)
1155 AC_CHECK_FUNCS(backtrace)
1156
1157 dnl
1158 dnl  default modules
1159 dnl
1160 ALIASES="${ALIASES} cvlc rvlc"
1161
1162 dnl
1163 dnl  Accelerated modules
1164 dnl
1165
1166 dnl  Check for fully working MMX intrinsics
1167 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1168 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1169 AC_ARG_ENABLE(mmx,
1170   [AS_HELP_STRING([--disable-mmx],
1171     [disable MMX optimizations (default auto)])],,[
1172   case "${host_cpu}" in
1173     i?86|x86_64)
1174       enable_mmx="yes"
1175       ;;
1176     *)
1177       enable_mmx="no"
1178       ;;
1179   esac
1180 ])
1181 have_mmx="no"
1182 have_mmxext="no"
1183 AS_IF([test "${enable_mmx}" != "no"], [
1184   ARCH="${ARCH} mmx"
1185   VLC_SAVE_FLAGS
1186   CFLAGS="${CFLAGS} -mmmx"
1187   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1188     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1189 [#include <mmintrin.h>
1190 #include <stdint.h>
1191 uint64_t frobzor;]], [
1192 [__m64 a, b, c;
1193 a = b = c = (__m64)frobzor;
1194 a = _mm_slli_pi16(a, 3);
1195 a = _mm_adds_pi16(a, b);
1196 c = _mm_srli_pi16(c, 8);
1197 c = _mm_slli_pi16(c, 3);
1198 b = _mm_adds_pi16(b, c);
1199 a = _mm_unpacklo_pi8(a, b);
1200 frobzor = (uint64_t)a;]])], [
1201       ac_cv_c_mmx_intrinsics=yes
1202     ], [
1203       ac_cv_c_mmx_intrinsics=no
1204     ])
1205   ])
1206   VLC_RESTORE_FLAGS
1207   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1208     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1209   ])
1210
1211   VLC_SAVE_FLAGS
1212   CFLAGS="${CFLAGS} -mmmx"
1213   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1214     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1215 void *p;
1216 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1217 ]])
1218     ], [
1219       ac_cv_mmx_inline=yes
1220     ], [
1221       ac_cv_mmx_inline=no
1222     ])
1223   ])
1224   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1225     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1226     have_mmx="yes"
1227   ])
1228
1229   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1230                  [ac_cv_mmxext_inline], [
1231     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1232 void *p;
1233 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1234 ]])
1235     ], [
1236       ac_cv_mmxext_inline=yes
1237     ], [
1238       ac_cv_mmxext_inline=no
1239     ])
1240   ])
1241   VLC_RESTORE_FLAGS
1242   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1243     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1244     have_mmxext="yes"
1245   ])
1246 ])
1247 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1248 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1249
1250 dnl  Check for fully workin SSE2 intrinsics
1251 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1252 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1253 AC_ARG_ENABLE(sse,
1254   [AS_HELP_STRING([--disable-sse],
1255     [disable SSE (1-4) optimizations (default auto)])],, [
1256   case "${host_cpu}" in
1257     i?86|x86_64)
1258       enable_sse=yes
1259       ;;
1260     *)
1261       enable_sse=no
1262       ;;
1263   esac
1264 ])
1265 have_sse2="no"
1266 AS_IF([test "${enable_sse}" != "no"], [
1267   ARCH="${ARCH} sse sse2"
1268
1269   VLC_SAVE_FLAGS
1270   CFLAGS="${CFLAGS} -msse2"
1271   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1272     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1273 [#include <emmintrin.h>
1274 #include <stdint.h>
1275 uint64_t frobzor;]], [
1276 [__m128i a, b, c;
1277 a = b = c = _mm_set1_epi64((__m64)frobzor);
1278 a = _mm_slli_epi16(a, 3);
1279 a = _mm_adds_epi16(a, b);
1280 c = _mm_srli_epi16(c, 8);
1281 c = _mm_slli_epi16(c, 3);
1282 b = _mm_adds_epi16(b, c);
1283 a = _mm_unpacklo_epi8(a, b);
1284 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1285       ac_cv_c_sse2_intrinsics=yes
1286     ], [
1287       ac_cv_c_sse2_intrinsics=no
1288     ])
1289   ])
1290   VLC_RESTORE_FLAGS
1291   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1292     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1293   ])
1294
1295   VLC_SAVE_FLAGS
1296   CFLAGS="${CFLAGS} -msse"
1297   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1298     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1299 void *p;
1300 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1301 ]])
1302     ], [
1303       ac_cv_sse_inline=yes
1304     ], [
1305       ac_cv_sse_inline=no
1306     ])
1307   ])
1308
1309   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1310     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1311   ])
1312
1313   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1314     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1315 void *p;
1316 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1317 ]])
1318     ], [
1319       ac_cv_sse2_inline=yes
1320     ], [
1321       ac_cv_sse2_inline=no
1322     ])
1323   ])
1324   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1325     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1326     have_sse2="yes"
1327   ])
1328
1329   # SSE3
1330   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1331     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1332 void *p;
1333 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1334 ]])
1335     ], [
1336       ac_cv_sse3_inline=yes
1337     ], [
1338       ac_cv_sse3_inline=no
1339     ])
1340   ])
1341
1342   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1343     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1344   # SSSE3
1345   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1346     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1347 void *p;
1348 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1349 ]])
1350     ], [
1351       ac_cv_ssse3_inline=yes
1352     ], [
1353       ac_cv_ssse3_inline=no
1354     ])
1355   ])
1356
1357   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1358     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1359
1360   # SSE4.1
1361   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1362                  [ac_cv_sse4_1_inline], [
1363     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1364 void *p;
1365 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1366 ]])
1367     ], [
1368       ac_cv_sse4_1_inline=yes
1369     ], [
1370       ac_cv_sse4_1_inline=no
1371     ])
1372   ])
1373
1374   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1375     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1376
1377   # SSE4.2
1378   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1379                  [ac_cv_sse4_2_inline], [
1380     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1381 void *p;
1382 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1383 ]])
1384     ], [
1385       ac_cv_sse4_2_inline=yes
1386     ], [
1387       ac_cv_sse4_2_inline=no
1388     ])
1389   ])
1390
1391   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1392     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1393
1394   # SSE4A
1395   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1396     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1397 void *p;
1398 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1399 ]])
1400     ], [
1401       ac_cv_sse4a_inline=yes
1402     ], [
1403       ac_cv_sse4a_inline=no
1404     ])
1405   ])
1406   VLC_RESTORE_FLAGS
1407   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1408     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1409 ])
1410 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1411
1412 VLC_SAVE_FLAGS
1413 CFLAGS="${CFLAGS} -mmmx"
1414 have_3dnow="no"
1415 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1416   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1417 void *p;
1418 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1419 ]])
1420   ], [
1421     ac_cv_3dnow_inline=yes
1422   ], [
1423     ac_cv_3dnow_inline=no
1424   ])
1425 ])
1426 VLC_RESTORE_FLAGS
1427 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1428   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1429             [Define to 1 if 3D Now! inline assembly is available.])
1430   have_3dnow="yes"
1431 ])
1432 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1433
1434
1435 AC_ARG_ENABLE(neon,
1436   [AS_HELP_STRING([--disable-neon],
1437     [disable NEON optimizations (default auto)])],, [
1438   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1439 ])
1440 AS_IF([test "${enable_neon}" != "no"], [
1441   VLC_SAVE_FLAGS
1442   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1443   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1444     AC_COMPILE_IFELSE([
1445       AC_LANG_PROGRAM(,[[
1446 asm volatile("vqmovun.s64 d0, q1":::"d0");
1447 ]])
1448     ], [
1449       ac_cv_arm_neon="yes"
1450     ], [
1451       ac_cv_arm_neon="no"
1452     ])
1453   ])
1454   VLC_RESTORE_FLAGS
1455 ])
1456 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1457
1458 AC_ARG_ENABLE(arm64,
1459   [AS_HELP_STRING([--disable-arm64],
1460     [disable arm 64-bit optimizations (default auto)])],, [
1461   AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1462 ])
1463 AS_IF([test "${enable_arm64}" != "no"], [
1464   AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1465     AC_COMPILE_IFELSE([
1466       AC_LANG_PROGRAM(,[[
1467 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1468 ]])
1469     ], [
1470       ac_cv_arm64="yes"
1471     ], [
1472       ac_cv_arm64="no"
1473     ])
1474   ])
1475 ])
1476 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1477
1478
1479 AC_ARG_ENABLE(altivec,
1480   [AS_HELP_STRING([--disable-altivec],
1481     [disable AltiVec optimizations (default auto)])],, [
1482   AS_CASE("${host_cpu}", [powerpc*],
1483         [enable_altivec=yes], [enable_altivec=no])
1484 ])
1485 have_altivec="no"
1486 ALTIVEC_CFLAGS=""
1487 AS_IF([test "${enable_altivec}" = "yes"], [
1488   ARCH="${ARCH} altivec";
1489   VLC_SAVE_FLAGS
1490   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1491     [ac_cv_altivec_inline],
1492     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1493          ac_cv_altivec_inline="yes",
1494          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1495           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1496             [ac_cv_altivec_inline="-Wa,-maltivec"],
1497             ac_cv_altivec_inline=no)
1498          ])])
1499   VLC_RESTORE_FLAGS
1500   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1501     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1502               [Define to 1 if AltiVec inline assembly is available.])
1503     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1504       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1505       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1506     ])
1507     have_altivec="yes"
1508   ])
1509
1510   VLC_SAVE_FLAGS
1511   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1512   [ac_cv_c_altivec], [
1513     CFLAGS="${CFLAGS} -maltivec"
1514     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1515 [#include <altivec.h>]], [
1516 [vec_ld(0, (unsigned char *)0);]])], [
1517       ac_cv_c_altivec="-maltivec"
1518     ], [
1519       ac_cv_c_altivec="no"
1520     ])
1521   ])
1522   VLC_RESTORE_FLAGS
1523   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1524     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1525     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1526     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1527     ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1528     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1529     have_altivec="yes"
1530   ])
1531   AC_CHECK_HEADERS(altivec.h)
1532
1533   VLC_SAVE_FLAGS
1534   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1535   AC_CACHE_CHECK([if linker needs -framework vecLib],
1536     [ac_cv_ld_altivec],
1537     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1538   VLC_RESTORE_FLAGS
1539   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1540     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1541   ])
1542 ])
1543 AC_SUBST(ALTIVEC_CFLAGS)
1544 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1545
1546 dnl
1547 dnl  Memory usage
1548 dnl
1549 AC_ARG_ENABLE(optimize-memory,
1550   [AS_HELP_STRING([--enable-optimize-memory],
1551     [optimize memory usage over performance])])
1552 if test "${enable_optimize_memory}" = "yes"; then
1553   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1554 fi
1555
1556 dnl
1557 dnl Allow running as root (useful for people running on embedded platforms)
1558 dnl
1559 AC_ARG_ENABLE(run-as-root,
1560   [AS_HELP_STRING([--enable-run-as-root],
1561     [allow running VLC as root (default disabled)])])
1562 AS_IF([test "${enable_run_as_root}" = "yes"],[
1563     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1564               [Define to 1 to allow running VLC as root (uid 0).])
1565 ])
1566
1567 dnl
1568 dnl Stream output
1569 dnl
1570 AC_ARG_ENABLE(sout,
1571   [AS_HELP_STRING([--disable-sout],
1572     [disable streaming output (default enabled)])])
1573 AS_IF([test "${enable_sout}" != "no"], [
1574   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1575 ])
1576 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1577
1578 dnl Lua modules
1579 AC_ARG_ENABLE(lua,
1580   [AS_HELP_STRING([--disable-lua],
1581     [disable LUA scripting support (default enabled)])])
1582 if test "${enable_lua}" != "no"
1583 then
1584   PKG_CHECK_MODULES(LUA, lua5.2,
1585     [ have_lua=yes ],
1586     [
1587     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1588
1589     PKG_CHECK_MODULES(LUA, lua5.1,
1590       [ have_lua=yes ],
1591       [
1592       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1593       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1594         [ have_lua=yes ],
1595         [
1596           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1597           have_lua=yes
1598           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1599             [],
1600             [ have_lua=no ] )
1601           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1602             [LUA_LIBS="-llua5.2"],
1603           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1604             [LUA_LIBS="-llua5.1"],
1605             AC_CHECK_LIB( lua51 , luaL_newstate,
1606               [LUA_LIBS="-llua51"],
1607               AC_CHECK_LIB( lua , luaL_newstate,
1608                 [LUA_LIBS="-llua"],
1609                 [ have_lua=no
1610                 ], [-lm])
1611             )))
1612         ])
1613       ])
1614     ])
1615   if test "x${have_lua}" != "xyes" ;  then
1616       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1617   fi
1618   AC_ARG_VAR([LUAC], [LUA byte compiler])
1619   AS_IF([test -z "$LUAC"], [
1620      AC_CHECK_TOOL(LUAC, [luac], [false])
1621   ])
1622   AS_IF([test "${LUAC}" = "false"], [
1623     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1624   ])
1625   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1626     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1627   ])
1628 fi
1629 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1630
1631
1632 dnl
1633 dnl HTTP daemon
1634 dnl
1635 AC_ARG_ENABLE(httpd,
1636   [AS_HELP_STRING([--disable-httpd],
1637     [disable the built-in HTTP server (default enabled)])])
1638 if test "${enable_httpd}" != "no"
1639 then
1640   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1641 fi
1642 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1643
1644
1645 dnl
1646 dnl VideoLAN manager
1647 dnl
1648 AC_ARG_ENABLE(vlm,
1649   [AS_HELP_STRING([--disable-vlm],
1650     [disable the stream manager (default enabled)])],,
1651   [enable_vlm="${enable_sout}"])
1652 AS_IF([test "${enable_vlm}" != "no"], [
1653   AS_IF([test "${enable_sout}" = "no"], [
1654     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1655   ])
1656   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1657 ])
1658 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1659
1660
1661 dnl
1662 dnl Addons manager storage and repositories modules
1663 dnl
1664 AC_ARG_ENABLE(addonmanagermodules,
1665   [AS_HELP_STRING([--disable-addonmanagermodules],
1666     [disable the addons manager modules (default enabled)])])
1667 if test "${enable_addonmanagermodules}" != "no"
1668 then
1669   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1670 fi
1671 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1672
1673
1674 dnl
1675 dnl  Input plugins
1676 dnl
1677
1678 EXTEND_HELP_STRING([Input plugins:])
1679
1680 dnl
1681 dnl  libarchive access module
1682 dnl
1683 PKG_ENABLE_MODULES_VLC([ARCHIVE], [access_archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1684
1685 dnl
1686 dnl  live555 input
1687 dnl
1688 AC_ARG_ENABLE(live555,
1689   [AS_HELP_STRING([--enable-live555],
1690     [enable RTSP input through live555 (default enabled)])])
1691
1692 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1693   PKG_CHECK_MODULES(LIVE555, live555, [
1694     VLC_ADD_PLUGIN([live555])
1695     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1696     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1697   ], [
1698     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1699
1700     AC_LANG_PUSH(C++)
1701     VLC_SAVE_FLAGS
1702
1703     dnl detect include paths
1704     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment.hh"], [
1705       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1706     ], [
1707       AS_IF([test "${SYS}" != "os2"], [
1708         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1709         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1710       ], [
1711         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1712         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1713         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1714       ])
1715     ])
1716
1717     dnl CPP Flags
1718     AS_IF([test "${SYS}" = "solaris"], [
1719       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1720     ])
1721     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1722     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1723
1724     dnl version check
1725     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1726       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1727 [#include <liveMedia_version.hh>
1728 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1729 # error BOOM
1730 #endif]])
1731       ], [
1732         ac_cv_live555="yes"
1733       ], [
1734         ac_cv_live555="no"
1735       ])
1736     ])
1737
1738     AS_IF([test "$ac_cv_live555" = "no"], [
1739       AC_MSG_WARN([live555 is missing or its installed version is too old:
1740 Version 2011.12.23 or later is required to proceed.
1741 You can get an updated one from http://www.live555.com/liveMedia .])
1742       AS_IF([test -n "${enable_live555}"], [
1743         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1744       ])
1745     ], [
1746       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1747       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1748       AS_IF([test "${SYS}" = "mingw32"], [
1749         # add ws2_32 for closesocket, select, recv
1750         other_libs="$other_libs -lws2_32"
1751       ])
1752
1753       dnl We need to check for pic because live555 don't provide shared libs
1754       dnl and we want to build a plugins so we need -fPIC on some arch.
1755       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1756       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1757       AC_CHECK_LIB(liveMedia_pic, main, [
1758         VLC_ADD_PLUGIN([live555])
1759         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1760       ],[
1761         AC_CHECK_LIB(liveMedia, main, [
1762           VLC_ADD_PLUGIN([live555])
1763           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1764         ],[],[${other_libs}])
1765       ],[${other_libs_pic}])
1766     ])
1767     VLC_RESTORE_FLAGS
1768     AC_LANG_POP(C++)
1769   ])
1770 ])
1771
1772 dnl
1773 dnl IIDC and DV FireWire input modules
1774 dnl
1775 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1776 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1777
1778 dnl
1779 dnl - linsys modules: access module check for libzvbi
1780 dnl
1781 AC_ARG_ENABLE(linsys,
1782   [AS_HELP_STRING([--enable-linsys],
1783     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1784 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1785   VLC_ADD_PLUGIN([linsys_hdsdi])
1786   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1787     VLC_ADD_PLUGIN([linsys_sdi])
1788   ], [
1789     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1790   ])
1791 ])
1792
1793 dnl
1794 dnl dvdread module: check for libdvdread
1795 dnl
1796 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1797
1798 dnl
1799 dnl libdvdnav plugin
1800 dnl
1801 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1802 AS_IF([test "${enable_dvdnav}" != "no"], [
1803   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1804     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1805       AC_MSG_RESULT(yes)
1806       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1807       ],[
1808       AC_MSG_RESULT(no)
1809     ])
1810 ])
1811
1812 dnl
1813 dnl  Blu-ray Disc Support with libbluray
1814 dnl
1815 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1816
1817 dnl
1818 dnl  OpenCV wrapper and example filters
1819 dnl
1820 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1821
1822
1823 dnl
1824 dnl  libsmbclient plugin
1825 dnl
1826 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1827 AS_IF([test "${SYS}" = "mingw32" -a "${enable_smbclient}" != "no"], [ VLC_ADD_PLUGIN([smb]) ])
1828
1829 dnl
1830 dnl  liBDSM access module
1831 dnl
1832 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1833
1834 dnl
1835 dnl sftp access support
1836 dnl
1837 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1838
1839 dnl
1840 dnl nfs access support
1841 dnl
1842 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1843
1844 dnl
1845 dnl  Video4Linux 2
1846 dnl
1847 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1848   [disable Video4Linux version 2 (default auto)])])
1849 have_v4l2="no"
1850 AS_IF([test "$enable_v4l2" != "no"], [
1851   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1852     have_v4l2="yes"
1853   ])
1854 ])
1855 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1856
1857 dnl
1858 dnl special access module for Blackmagic SDI cards
1859 dnl
1860 AC_ARG_ENABLE(decklink,
1861   [AS_HELP_STRING([--disable-decklink],
1862     [disable Blackmagic DeckLink SDI input (default auto)])])
1863 AC_ARG_WITH(decklink_sdk,
1864   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1865     [                        location of Blackmagic DeckLink SDI SDK])])
1866 have_decklink=no
1867 if test "${enable_decklink}" != "no"
1868 then
1869   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1870   then
1871     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1872   fi
1873   VLC_SAVE_FLAGS
1874   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1875   AC_LANG_PUSH(C++)
1876   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1877       have_decklink=yes
1878   ], [
1879       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1880   ])
1881   AC_LANG_POP(C++)
1882   VLC_RESTORE_FLAGS
1883 fi
1884 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1885
1886
1887 dnl
1888 dnl  Built-in CD-DA and VCD module
1889 dnl
1890 AC_ARG_ENABLE(vcd,
1891   [AS_HELP_STRING([--disable-vcd],
1892     [disable built-in VCD and CD-DA support (default enabled)])])
1893
1894 AC_ARG_ENABLE(libcddb,
1895   [AS_HELP_STRING([--disable-libcddb],
1896     [disable CDDB for Audio CD (default enabled)])])
1897
1898 if test "${enable_vcd}" != "no"
1899 then
1900   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1901   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1902     AC_MSG_RESULT(yes)
1903     VLC_ADD_PLUGIN([vcd cdda])
1904   ],[
1905     AC_MSG_RESULT(no)
1906   ])
1907
1908   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1909   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1910     AC_MSG_RESULT(yes)
1911     VLC_ADD_PLUGIN([vcd cdda])
1912     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1913   ],[
1914     AC_MSG_RESULT(no)
1915   ])
1916
1917   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1918   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1919     AC_MSG_RESULT(yes)
1920     VLC_ADD_PLUGIN([vcd cdda])
1921     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1922   ],[
1923     AC_MSG_RESULT(no)
1924   ])
1925
1926   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1927   then
1928     VLC_ADD_PLUGIN([vcd cdda])
1929   fi
1930
1931   if test "$enable_libcddb" != "no"; then
1932     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1933       HAVE_LIBCDDB=yes
1934       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1935       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1936       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1937       ],:
1938       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1939       HAVE_LIBCDDB=no])
1940   fi
1941 fi
1942
1943 dnl
1944 dnl Linux DVB
1945 dnl
1946 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1947   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1948 [#include <linux/dvb/version.h>
1949 #if (DVB_API_VERSION < 5)
1950 # error Linux DVB API v3.2 and older are not supported.
1951 #endif
1952 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1953 # error Linux DVB API v5.0 is unsupported. Please update.
1954 #endif
1955 ]])], [
1956   ac_cv_linux_dvb_5_1=yes
1957 ], [
1958   ac_cv_linux_dvb_5_1=no
1959 ])])
1960 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1961
1962 dnl
1963 dnl  Screen capture module
1964 dnl
1965 AC_ARG_ENABLE(screen,
1966   [AS_HELP_STRING([--enable-screen],
1967     [disable screen capture (default enabled)])])
1968 if test "${enable_screen}" != "no"; then
1969   if test "${SYS}" = "darwin"; then
1970     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1971       VLC_ADD_PLUGIN([screen])
1972     ])
1973   fi
1974 fi
1975 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1976
1977 dnl
1978 dnl  VNC/RFB access module
1979 dnl
1980 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1981
1982 dnl  RDP/Remote Desktop access module
1983 dnl
1984 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1985
1986 dnl
1987 dnl  Real RTSP plugin
1988 dnl
1989 AC_ARG_ENABLE(realrtsp,
1990   [  --enable-realrtsp       Real RTSP module (default disabled)])
1991 if test "${enable_realrtsp}" = "yes"; then
1992   VLC_ADD_PLUGIN([access_realrtsp])
1993 fi
1994
1995 dnl
1996 dnl QTKit
1997 AC_ARG_ENABLE(macosx-qtkit,
1998   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
1999 if test "x${enable_macosx_qtkit}" != "xno" &&
2000   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
2001 then
2002   AC_CHECK_HEADERS(QTKit/QTKit.h, [
2003       VLC_ADD_PLUGIN([qtsound])
2004     ])
2005 fi
2006
2007 dnl
2008 dnl AVFoundation
2009 AC_SUBST(have_avfoundation, ["no"])
2010 AC_ARG_ENABLE(macosx-avfoundation,
2011   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
2012 if test "x${enable_macosx_avfoundation}" != "xno" &&
2013   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2014 then
2015   SAVED_LIBS="${LIBS}"
2016   LIBS="-framework AVFoundation"
2017   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2018   LIBS="${SAVED_LIBS}"
2019   if test "${have_avfoundation}" != "no"
2020   then
2021     VLC_ADD_PLUGIN([avcapture])
2022   fi
2023 fi
2024 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2025
2026 dnl
2027 dnl  DCP plugin (using asdcplib)
2028 dnl
2029 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2030 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2031
2032 dnl
2033 dnl  Demux plugins
2034 dnl
2035
2036 EXTEND_HELP_STRING([Mux/Demux plugins:])
2037
2038 dnl
2039 dnl  libdvbpsi check for ts mux/demux
2040 dnl
2041 have_dvbpsi="no"
2042 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2043 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2044
2045
2046 dnl
2047 dnl  GME demux plugin
2048 dnl
2049 AC_ARG_ENABLE(gme,
2050   [AS_HELP_STRING([--enable-gme],
2051     [use Game Music Emu (default auto)])])
2052 AS_IF([test "${enable_gme}" != "no"], [
2053   AC_CHECK_HEADER([gme/gme.h], [
2054     VLC_ADD_LIBS([gme], [-lgme])
2055     VLC_ADD_PLUGIN([gme])
2056   ], [
2057     AS_IF([test "x${enable_gme}" != "x"], [
2058       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2059     ])
2060   ])
2061 ])
2062
2063
2064 dnl
2065 dnl  SIDPlay plugin
2066 dnl
2067 AC_ARG_ENABLE(sid,
2068     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2069 AS_IF([test "${enable_sid}" != "no"], [
2070     PKG_CHECK_MODULES(SID, [libsidplay2], [
2071         AC_LANG_PUSH(C++)
2072         oldCPPFLAGS="$CPPFLAGS"
2073         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2074         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2075             VLC_ADD_PLUGIN([sid])
2076             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2077             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2078         ], [
2079             AS_IF([test -n "${enable_sid}"],
2080                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2081                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2082                 )
2083         ])
2084         CPPFLAGS="$oldCPPFLAGS"
2085         AC_LANG_POP(C++)
2086     ], [
2087         AS_IF([test "x${enable_sid}" = "xyes"],
2088             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2089             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2090             )
2091     ])
2092 ])
2093
2094
2095 dnl
2096 dnl  ogg demux plugin
2097 dnl
2098 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2099 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2100     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2101 ],[true])
2102 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2103 if test "${enable_sout}" != "no"; then
2104 dnl Check for libshout
2105     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2106 fi
2107
2108 dnl
2109 dnl  matroska demux plugin
2110 dnl
2111 PKG_ENABLE_MODULES_VLC([MATROSKA], [mkv], [libebml libmatroska], [MKV format support], [auto])
2112
2113 dnl
2114 dnl  modplug demux plugin
2115 dnl
2116 AC_ARG_ENABLE(mod,
2117   [AS_HELP_STRING([--disable-mod],
2118     [do not use libmodplug (default auto)])])
2119 if test "${enable_mod}" != "no" ; then
2120     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2121           VLC_ADD_PLUGIN([mod])
2122           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2123           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2124           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2125     ],[
2126        AS_IF([test -n "${enable_mod}"],
2127          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2128          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2129     ])
2130 fi
2131
2132 dnl
2133 dnl  mpc demux plugin
2134 dnl
2135 AC_ARG_ENABLE(mpc,
2136   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2137 if test "${enable_mpc}" != "no"
2138 then
2139   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2140     VLC_ADD_PLUGIN([mpc])
2141     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2142     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2143     VLC_ADD_PLUGIN([mpc])
2144     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2145 fi
2146
2147 dnl
2148 dnl  Codec plugins
2149 dnl
2150
2151 EXTEND_HELP_STRING([Codec plugins:])
2152
2153 dnl
2154 dnl wmafixed plugin
2155 dnl
2156 AC_ARG_ENABLE(wma-fixed,
2157   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2158 if test "${enable_wma_fixed}" = "yes"
2159 then
2160   VLC_ADD_PLUGIN([wma_fixed])
2161 fi
2162
2163 dnl
2164 dnl shine encoder plugin
2165 dnl
2166 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2167
2168
2169 dnl
2170 dnl openmax il codec plugin
2171 dnl
2172 AC_ARG_ENABLE(omxil,
2173   [  --enable-omxil          openmax il codec module (default disabled)])
2174 if test "${enable_omxil}" = "yes"
2175 then
2176   VLC_ADD_PLUGIN([omxil])
2177 fi
2178
2179 dnl
2180 dnl openmax il vout plugin
2181 dnl
2182 AC_ARG_ENABLE(omxil-vout,
2183   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2184 if test "${enable_omxil_vout}" = "yes"
2185 then
2186   VLC_ADD_PLUGIN([omxil_vout])
2187 fi
2188
2189 dnl
2190 dnl raspberry pi openmax il configuration
2191 dnl
2192 AC_ARG_ENABLE(rpi-omxil,
2193   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2194 if test "${enable_rpi_omxil}" = "yes"
2195 then
2196   VLC_ADD_PLUGIN([omxil omxil_vout])
2197   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2198 fi
2199
2200 dnl
2201 dnl CrystalHD codec plugin
2202 dnl
2203 AC_ARG_ENABLE(crystalhd,
2204   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2205 if test "${enable_crystalhd}" != "no"; then
2206     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2207       VLC_ADD_PLUGIN([crystalhd])
2208       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2209     ],[
2210       if test "${SYS}" = "mingw32" ; then
2211         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2212           VLC_ADD_PLUGIN([crystalhd])
2213           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2214             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2215             ])
2216         ],[
2217           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2218                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2219                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2220         ],[#define __LINUX_USER__
2221                #include <libcrystalhd/bc_dts_types.h>
2222         ])
2223       fi
2224     ],[
2225        #include <libcrystalhd/bc_dts_types.h>
2226       ])
2227 fi
2228
2229 dnl
2230 dnl  mad plugin
2231 dnl
2232 have_mad="no"
2233 MAD_CFLAGS=""
2234 MAD_LIBS=""
2235
2236 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2237   enable_mad="yes"
2238 ], [
2239   with_mad="no"
2240 ])
2241 AS_IF([test "${with_mad}" != "no"], [
2242   MAD_CFLAGS="-I${with_mad}/include"
2243   MAD_LIBS="-L${with_mad}/lib"
2244 ])
2245
2246 AC_ARG_ENABLE(mad,
2247   [  --enable-mad            libmad module (default enabled)])
2248 AS_IF([test "${enable_mad}" != "no"], [
2249   VLC_SAVE_FLAGS
2250   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2251   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2252   AC_CHECK_HEADERS(mad.h, [
2253     AC_CHECK_LIB(mad, mad_bit_init, [
2254       have_mad="yes"
2255       MAD_LIBS="${MAD_LIBS} -lmad"
2256     ])
2257   ])
2258   VLC_RESTORE_FLAGS
2259   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2260     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2261   ])
2262 ])
2263 AC_SUBST(MAD_CFLAGS)
2264 AC_SUBST(MAD_LIBS)
2265 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2266
2267 dnl  mpg123 plugin
2268 dnl
2269 dnl
2270 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2271
2272
2273 AC_ARG_ENABLE(merge-ffmpeg,
2274 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2275   enable_merge_ffmpeg="no"
2276 ])
2277 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2278
2279 AC_MSG_CHECKING([for libavutil variant])
2280 PKG_CHECK_EXISTS([libavutil], [
2281   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2282   libavutil_micro="${libavutil_version##*.}"
2283   AS_IF([test ${libavutil_micro} -le 99], [
2284     avfork="libav"
2285   ], [
2286     avfork="ffmpeg"
2287   ])
2288 ], [
2289   avfork="none"
2290 ])
2291 AC_MSG_RESULT([${avfork}])
2292
2293 dnl
2294 dnl gstreamer stuff
2295 dnl
2296 AC_ARG_ENABLE(gst-decode,
2297   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2298
2299 have_gst_decode="no"
2300 AS_IF([test "${enable_gst_decode}" != "no"], [
2301   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2302     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2303       have_gst_decode="yes"
2304     ], [
2305       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2306     ])
2307   ], [
2308     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2309   ])
2310 ])
2311 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2312
2313 dnl
2314 dnl  avcodec decoder/encoder plugin
2315 dnl
2316 AC_ARG_ENABLE(avcodec,
2317 [  --enable-avcodec        libavcodec codec (default enabled)])
2318 AS_IF([test "${enable_avcodec}" != "no"], [
2319   dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2320   case "${avfork}" in
2321     libav) av_codec_ver="57.16.0" ;;
2322     ffmpeg) av_codec_ver="57.37.100" ;;
2323     *) AC_MSG_ERROR([Missing libav or FFmpeg])
2324   esac
2325   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2326     VLC_SAVE_FLAGS
2327     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2328     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2329     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2330     AC_CHECK_HEADERS(libavutil/avutil.h)
2331     VLC_RESTORE_FLAGS
2332     have_avcodec="yes"
2333   ],[
2334     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2335   ])
2336 ], [
2337   have_avcodec="no"
2338 ])
2339 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2340
2341 dnl
2342 dnl libva needs avcodec
2343 dnl
2344 AC_ARG_ENABLE(libva,
2345   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2346
2347 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2348   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2349 ])
2350
2351 have_vaapi="no"
2352 have_vaapi_drm="no"
2353 have_vaapi_x11="no"
2354 AS_IF([test "${enable_libva}" != "no"], [
2355   PKG_CHECK_MODULES([LIBVA], [libva >= 0.37], [
2356     have_vaapi="yes"
2357   ], [
2358     AS_IF([test -n "${enable_libva}"], [
2359       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2360     ], [
2361       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2362     ])
2363   ])
2364   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2365     have_vaapi_drm="yes"
2366   ], [
2367     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2368   ])
2369   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2370     have_vaapi_x11="yes"
2371   ], [
2372     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2373   ])
2374 ])
2375 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2376 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2377
2378 have_avcodec_vaapi="no"
2379 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2380   VLC_SAVE_FLAGS
2381   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2382   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2383   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2384     AC_MSG_NOTICE([VA API acceleration activated])
2385     have_avcodec_vaapi="yes"
2386   ],[
2387     AS_IF([test -n "${enable_libva}"], [
2388       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2389     ], [
2390       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2391     ])
2392   ])
2393   VLC_RESTORE_FLAGS
2394 ])
2395 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2396
2397 dnl
2398 dnl dxva2 needs avcodec
2399 dnl
2400 AC_ARG_ENABLE(dxva2,
2401   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2402
2403 have_avcodec_dxva2="no"
2404 AS_IF([test "${enable_dxva2}" != "no"], [
2405   if test "${SYS}" = "mingw32"; then
2406   AS_IF([test "x${have_avcodec}" = "xyes"], [
2407     AC_CHECK_HEADERS(dxva2api.h,
2408       [
2409         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2410            AC_MSG_NOTICE([DxVA2 acceleration activated])
2411            have_avcodec_dxva2="yes"
2412         ],[
2413     AS_IF([test "${enable_dxva2}" = "yes"],
2414           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2415               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2416         ], [#undef _WIN32_WINNT
2417             /* DXVA2 is only available in Vista and above */
2418             #define _WIN32_WINNT 0x600])
2419       ],[
2420     AS_IF([test "${enable_dxva2}" = "yes"],
2421               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2422               [AC_MSG_WARN([dxva2api.h not found])])
2423       ],[#include <d3d9.h>])
2424   ],[
2425     AS_IF([test "x${enable_dxva2}" != "x"], [
2426       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2427     ])
2428   ])
2429   fi
2430 ])
2431 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2432
2433 dnl
2434 dnl d3d11va needs avcodec
2435 dnl
2436 AC_ARG_ENABLE(d3d11va,
2437   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2438
2439 have_avcodec_d3d11va="no"
2440 AS_IF([test "${enable_d3d11va}" != "no"], [
2441   if test "${SYS}" = "mingw32"; then
2442   AS_IF([test "x${have_avcodec}" = "xyes"], [
2443         AC_CHECK_TYPES([ID3D11VideoDecoder],
2444           [
2445             AC_CHECK_HEADERS(dxva2api.h,
2446               [
2447                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2448                    AC_MSG_NOTICE([D3D11 acceleration activated])
2449                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2450                    have_avcodec_d3d11va="yes"
2451                 ],[
2452                   AS_IF([test "${enable_d3d11va}" = "yes"],
2453                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2454                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2455                   ], [#undef _WIN32_WINNT
2456                       /* D3D11 is only available in Vista and above */
2457                       #define _WIN32_WINNT 0x600])
2458                   ],[
2459                     AS_IF([test "${enable_d3d11va}" = "yes"],
2460                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2461                           [AC_MSG_WARN([dxva2api.h not found])])
2462                   ],[#include <d3d9.h>])
2463           ],[
2464             AS_IF([test "${enable_d3d11va}" = "yes"],
2465                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2466                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2467           ], [#include <d3d11.h>])
2468   ],[
2469     AS_IF([test "x${enable_d3d11va}" != "x"], [
2470       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2471     ])
2472   ])
2473   fi
2474 ])
2475 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2476
2477 dnl
2478 dnl DXGI debug
2479 dnl
2480 AC_CHECK_HEADERS(dxgidebug.h)
2481
2482 dnl
2483 dnl vda needs avcodec
2484 dnl
2485 AC_ARG_ENABLE(vda,
2486   [  --enable-vda          VDA  support (default auto)])
2487
2488 have_avcodec_vda="no"
2489 AS_IF([test "${enable_vda}" != "no"], [
2490   if test "${SYS}" = "darwin"; then
2491   AS_IF([test "x${have_avcodec}" = "xyes"], [
2492     AC_CHECK_HEADERS(VideoDecodeAcceleration/VDADecoder.h,
2493       [
2494         AC_CHECK_HEADERS(libavcodec/vda.h, [
2495            have_avcodec_vda="yes"
2496         ],[
2497         AS_IF([test "${enable_vda}" = "yes"],
2498               [AC_MSG_ERROR([vda is present but libavcodec/vda.h is missing])],
2499               [AC_MSG_WARN([vda is present but libavcodec/vda.h is missing ])])
2500         ])
2501   ],[
2502         AS_IF([test "${enable_vda}" = "yes"],
2503               [AC_MSG_ERROR([Could not find required VideoDecodeAcceleration/VDADecoder.h])],
2504               [AC_MSG_WARN([VideoDecodeAcceleration/VDADecoder.h not found])])
2505       ])
2506   ],[
2507     AS_IF([test "x${enable_vda}" != "x"], [
2508       AC_MSG_ERROR([--enable-vda and --disable-avcodec options are mutually exclusive.])
2509     ])
2510  ])
2511  AS_IF([test "${have_avcodec_vda}" = "yes"], [
2512      SAVE_LIBS=$LIBS
2513      LIBS="$LIBS $AVCODEC_LIBS"
2514      AC_CHECK_FUNCS([av_vda_alloc_context])
2515      LIBS=$SAVE_LIBS
2516  ])
2517  fi
2518 ])
2519 AM_CONDITIONAL([HAVE_AVCODEC_VDA], [test "${have_avcodec_vda}" = "yes"])
2520
2521 dnl
2522 dnl  avformat demuxer/muxer plugin
2523 dnl
2524
2525 AC_ARG_ENABLE(avformat,
2526 [  --enable-avformat       libavformat containers (default enabled)],, [
2527   enable_avformat="${have_avcodec}"
2528 ])
2529 have_avformat="no"
2530 AS_IF([test "${enable_avformat}" != "no"], [
2531   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2532       have_avformat="yes"
2533       VLC_SAVE_FLAGS
2534       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2535       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2536       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2537       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2538       AC_CHECK_HEADERS(libavutil/avutil.h)
2539       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2540         have_avformat="no"
2541       ])
2542       VLC_RESTORE_FLAGS
2543     ],[
2544       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2545   ])
2546 ])
2547 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2548
2549 dnl
2550 dnl  swscale image scaling and conversion plugin
2551 dnl
2552
2553 AC_ARG_ENABLE(swscale,
2554   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2555           (default enabled)]))
2556 if test "${enable_swscale}" != "no"
2557 then
2558   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2559     [
2560       VLC_SAVE_FLAGS
2561       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2562       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2563       AC_CHECK_HEADERS(libswscale/swscale.h)
2564       AC_CHECK_HEADERS(libavutil/avutil.h)
2565       VLC_ADD_PLUGIN([swscale])
2566       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2567       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2568       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2569         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2570       ])
2571       VLC_RESTORE_FLAGS
2572     ],[
2573       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2574   ])
2575 fi
2576
2577 dnl
2578 dnl  postproc plugin
2579 dnl
2580
2581 AC_ARG_ENABLE(postproc,
2582 [  --enable-postproc       libpostproc image post-processing (default auto)])
2583 if test "${enable_postproc}" != "no"
2584 then
2585   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2586     [
2587       VLC_SAVE_FLAGS
2588       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2589       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2590       AC_CHECK_HEADERS(postproc/postprocess.h)
2591       VLC_ADD_PLUGIN([postproc])
2592       VLC_RESTORE_FLAGS
2593     ],[
2594       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2595   ])
2596 fi
2597
2598 dnl
2599 dnl  faad decoder plugin
2600 dnl
2601 AC_ARG_ENABLE(faad,
2602 [  --enable-faad           faad codec (default auto)])
2603 have_faad="no"
2604 AS_IF([test "${enable_faad}" != "no"], [
2605   AC_CHECK_HEADERS([neaacdec.h], [
2606     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2607
2608     AS_IF([test "${have_faad}" = "yes"], [
2609       VLC_ADD_PLUGIN([faad])
2610       VLC_ADD_LIBS([faad],[-lfaad])
2611     ], [
2612       AS_IF([test "${enable_faad}" = "yes"], [
2613         AC_MSG_ERROR([cannot find FAAD library])
2614       ], [
2615         AC_MSG_WARN([cannot find FAAD library])
2616       ])
2617     ])
2618   ])
2619 ])
2620
2621 dnl
2622 dnl  AOM decoder plugin
2623 dnl
2624 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec], [disabled])
2625
2626 dnl
2627 dnl libvpx decoder plugin
2628 dnl
2629 AC_ARG_ENABLE(vpx,
2630     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2631 AS_IF([test "${enable_vpx}" != "no"],[
2632     PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2633         VLC_ADD_PLUGIN([vpx])
2634         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2635         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2636         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2637             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2638         ], [], [${VPX_LIBS}])
2639         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2640             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2641         ], [], [${VPX_LIBS}])
2642         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2643             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2644         ], [], [${VPX_LIBS}])
2645         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2646             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2647         ], [], [${VPX_LIBS}])
2648     ], [
2649     AS_IF([test "${enable_vpx}" = "yes"],[
2650         AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2651     ])])
2652 ])
2653
2654 dnl
2655 dnl twolame encoder plugin
2656 dnl
2657 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2658
2659 dnl
2660 dnl fdk-aac encoder plugin
2661 dnl
2662 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2663
2664
2665 dnl
2666 dnl A52/AC3 decoder plugin
2667 dnl
2668 AC_ARG_ENABLE(a52,
2669   [  --enable-a52            A/52 support with liba52 (default enabled)])
2670 if test "${enable_a52}" != "no"
2671 then
2672   AC_ARG_WITH(a52,
2673     [  --with-a52=PATH         a52 headers and libraries])
2674     if test -z "${with_a52}"
2675     then
2676       LDFLAGS_test=""
2677       CPPFLAGS_test=""
2678     else
2679       LDFLAGS_test="-L${with_a52}/lib"
2680       CPPFLAGS_test="-I${with_a52}/include"
2681     fi
2682     VLC_SAVE_FLAGS
2683     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2684     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2685     AC_CHECK_HEADERS(a52dec/a52.h, [
2686       AC_CHECK_LIB(a52, a52_free, [
2687         VLC_ADD_PLUGIN([a52])
2688         VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2689         VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2690       ],[
2691         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2692         ], [$LIBM])
2693     ],[
2694       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2695     ])
2696     VLC_RESTORE_FLAGS
2697 fi
2698
2699 dnl
2700 dnl DTS Coherent Acoustics decoder plugin
2701 dnl
2702 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2703
2704 dnl
2705 dnl  Flac plugin
2706 dnl
2707 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2708
2709 dnl
2710 dnl  Libmpeg2 plugin
2711 dnl
2712 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2713
2714 dnl
2715 dnl  Vorbis plugin
2716 dnl
2717 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2718
2719 dnl
2720 dnl  Tremor plugin
2721 dnl
2722 AC_ARG_ENABLE(tremor,
2723   [  --enable-tremor         Tremor decoder support (default disabled)])
2724 if test "${enable_tremor}" = "yes"
2725 then
2726   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2727     VLC_ADD_PLUGIN([tremor])
2728    ],[])
2729 fi
2730
2731 dnl
2732 dnl  Speex plugins
2733 dnl
2734 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2735 have_speexdsp="no"
2736 AS_IF([test "${enable_speex}" != "no"], [
2737   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2738     have_speexdsp="yes"
2739   ], [
2740     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2741   ])
2742 ])
2743 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2744
2745 dnl
2746 dnl  Opus plugin
2747 dnl
2748 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2749
2750 dnl
2751 dnl  theora decoder plugin
2752 dnl
2753 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2754
2755 dnl
2756 dnl  OggSpots decoder plugin
2757 dnl
2758 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2759
2760 dnl
2761 dnl  Daala decoder plugin
2762 dnl
2763 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2764
2765 dnl
2766 dnl  schroedinger decoder plugin (for dirac format video)
2767 dnl
2768 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2769
2770 dnl
2771 dnl  PNG decoder module
2772 dnl
2773 AC_ARG_ENABLE(png,
2774   [  --enable-png            PNG support (default enabled)])
2775 AS_IF([test "${enable_png}" != "no"], [
2776 AC_CHECK_HEADERS(png.h, [
2777   VLC_SAVE_FLAGS
2778   LDFLAGS="${LDFLAGS} -lz $LIBM"
2779   AC_CHECK_LIB(png, png_set_rows, [
2780     VLC_ADD_PLUGIN([png])
2781   ], [], [-lz $LIBM])
2782   VLC_RESTORE_FLAGS
2783   ])
2784 ])
2785
2786 dnl
2787 dnl  JPEG decoder module
2788 dnl
2789 AC_ARG_ENABLE(jpeg,
2790   [  --enable-jpeg           JPEG support (default enabled)])
2791 AS_IF([test "${enable_jpeg}" != "no"], [
2792 AC_CHECK_HEADERS(jpeglib.h, [
2793   VLC_ADD_PLUGIN([jpeg])
2794   ])
2795 ])
2796
2797 dnl
2798 dnl  BPG decoder module
2799 dnl
2800 AC_ARG_ENABLE(bpg,
2801   [  --enable-bpg           BPG support (default disabled)])
2802 AS_IF([test "${enable_bpg}" != "no"], [
2803 AC_CHECK_HEADERS(libbpg.h, [
2804   VLC_ADD_PLUGIN([bpg])
2805   ])
2806 ])
2807
2808 dnl
2809 dnl H262 encoder plugin (lib262)
2810 dnl
2811 AC_ARG_ENABLE(x262,
2812   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2813 if test "${enable_x262}" != "no"; then
2814     PKG_CHECK_MODULES(X262, x262, [
2815         VLC_ADD_PLUGIN([x262])
2816         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2817         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2818           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2819         ])
2820         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2821         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2822           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2823         fi
2824     ], [
2825        if test "${enable_x262}" = "yes"; then
2826         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2827        fi
2828     ])
2829 fi
2830
2831 dnl x265 encoder
2832 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2833
2834 dnl
2835 dnl H264 encoder plugin (10-bit lib264)
2836 dnl
2837 AC_ARG_ENABLE(x26410b,
2838   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2839 if test "${enable_x26410b}" != "no"; then
2840     PKG_CHECK_MODULES(X26410B, x26410b, [
2841         VLC_ADD_PLUGIN([x26410b])
2842         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2843         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2844           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2845         ])
2846         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2847         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2848           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2849         fi
2850     ], [
2851        if test "${enable_x26410b}" = "yes"; then
2852         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2853        fi
2854     ])
2855 fi
2856
2857
2858 dnl
2859 dnl H264 encoder plugin (using libx264)
2860 dnl
2861 AC_ARG_ENABLE(x264,
2862   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2863 if test "${enable_x264}" != "no"; then
2864       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2865         VLC_ADD_PLUGIN([x264])
2866         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2867
2868         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2869           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2870         ])
2871
2872         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2873         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2874           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2875         fi
2876       ],[
2877         if test "${enable_x264}" = "yes"; then
2878             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2879           fi
2880       ])
2881 fi
2882
2883 dnl
2884 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2885 dnl
2886 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2887
2888 dnl
2889 dnl libfluidsynth (MIDI synthetizer) plugin
2890 dnl
2891 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2892 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2893 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2894
2895 dnl
2896 dnl Teletext Modules
2897 dnl vbi decoder plugin (using libzbvi)
2898 dnl telx module
2899 dnl uncompatible
2900 dnl
2901 AC_ARG_ENABLE(zvbi,
2902   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2903                   libzvbi (default enabled)]))
2904 AC_ARG_ENABLE(telx,
2905   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2906                   zvbi) (default enabled if zvbi is absent)]))
2907
2908 AS_IF( [test "${enable_zvbi}" != "no"],[
2909     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2910         [
2911           VLC_ADD_PLUGIN([zvbi])
2912           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2913           AS_IF( [test "${enable_telx}" = "yes"],[
2914                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2915                   ])
2916         ],[
2917           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2918         ])
2919     ])
2920 AS_IF( [test "${enable_telx}" != "no" ],[
2921   VLC_ADD_PLUGIN([telx])
2922   ])
2923
2924 dnl
2925 dnl libass subtitle rendering module
2926 dnl
2927 AC_ARG_ENABLE(libass,
2928   [  --enable-libass         Subtitle support using libass (default enabled)])
2929 AS_IF( [test "${enable_libass}" != "no"], [
2930   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2931       [
2932         VLC_ADD_PLUGIN([libass])
2933
2934         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2935           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2936            VLC_ADD_LIBS([libass],[-lfontconfig])
2937        ])
2938       ],[
2939         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2940       ])
2941   ])
2942
2943 dnl
2944 dnl ARIB subtitles rendering module
2945 dnl
2946 AC_ARG_ENABLE(aribsub,
2947   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2948 AS_IF( [test "${enable_aribsub}" != "no" ],[
2949   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2950       have_aribb24="yes"
2951       VLC_ADD_PLUGIN([aribsub])
2952       VLC_ADD_LIBS([aribsub],[-laribb24])
2953       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2954     ],[
2955       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2956       have_aribb24="no"
2957   ])
2958 ])
2959 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2960
2961 dnl
2962 dnl ARIB B25
2963 dnl
2964 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2965
2966 dnl
2967 dnl  kate decoder plugin
2968 dnl
2969 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2970
2971 dnl
2972 dnl  tiger rendering for kate decoder plugin
2973 dnl
2974 AC_ARG_ENABLE(tiger,
2975 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2976 AS_IF([test "${enable_tiger}" != "no"], [
2977   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2978       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2979         AS_IF([test -n "${enable_tiger}"], [
2980           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2981         ])
2982   ])
2983 ])
2984
2985
2986 dnl
2987 dnl  Video plugins
2988 dnl
2989
2990 EXTEND_HELP_STRING([Video plugins:])
2991
2992 dnl
2993 dnl  OpenGL
2994 dnl
2995 PKG_CHECK_MODULES([EGL], [egl], [
2996   have_egl="yes"
2997 ], [
2998   have_egl="no"
2999 ])
3000 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3001
3002 have_gl="no"
3003 PKG_CHECK_MODULES([GL], [gl], [
3004   have_gl="yes"
3005 ], [
3006   AC_MSG_CHECKING([for OpenGL])
3007   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3008 #ifdef _WIN32
3009 # include <GL/glew.h>
3010 #endif
3011 #include <GL/gl.h>
3012 ]], [
3013     [int t0 = GL_TEXTURE0;]])
3014   ], [
3015     GL_CFLAGS=""
3016     have_gl="yes"
3017     AS_IF([test "${SYS}" != "mingw32"], [
3018       GL_LIBS="-lGL"
3019     ], [
3020       GL_LIBS="-lopengl32"
3021     ])
3022   ])
3023   AC_MSG_RESULT([${have_gl}])
3024 ])
3025 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3026
3027 dnl OpenGL ES 2: depends on EGL 1.1
3028 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3029
3030 dnl
3031 dnl  Xlib
3032 dnl
3033
3034 AC_PATH_XTRA()
3035 AC_CHECK_HEADERS(X11/Xlib.h)
3036
3037 dnl
3038 dnl  X C Bindings modules
3039 dnl
3040 AC_ARG_ENABLE(xcb,
3041   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3042   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3043     enable_xcb="yes"
3044   ], [
3045     enable_xcb="no"
3046   ])
3047 ])
3048 AC_ARG_ENABLE(xvideo,
3049   [  --enable-xvideo         XVideo support (default enabled)],, [
3050     enable_xvideo="$enable_xcb"
3051 ])
3052
3053 have_xcb="no"
3054 have_xcb_keysyms="no"
3055 have_xcb_randr="no"
3056 have_xcb_xvideo="no"
3057 AS_IF([test "${enable_xcb}" != "no"], [
3058   dnl libxcb
3059   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3060   have_xcb="yes"
3061   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3062   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3063   PKG_CHECK_MODULES(XPROTO, [xproto])
3064
3065   AS_IF([test "${enable_xvideo}" != "no"], [
3066     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3067   ])
3068
3069   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3070
3071   dnl xcb-utils
3072   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3073     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3074   ])
3075 ])
3076 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3077 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3078 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3079 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3080
3081
3082 dnl
3083 dnl VDPAU needs X11
3084 dnl
3085 AC_ARG_ENABLE(vdpau,
3086   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3087 have_vdpau="no"
3088 AS_IF([test "${enable_vdpau}" != "no"], [
3089   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3090     have_vdpau="yes"
3091     AS_IF([test "${no_x}" = "yes"], [
3092       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3093     ])
3094   ], [
3095     AS_IF([test -n "${enable_vdpau}"], [
3096       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3097     ])
3098   ])
3099 ])
3100 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3101
3102 have_avcodec_vdpau="no"
3103 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3104   case "${avfork}" in
3105     libav) av_vdpau_ver="56.10.0" ;;
3106     ffmpeg) av_vdpau_ver="56.19.100" ;;
3107   esac
3108   PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3109     have_avcodec_vdpau="yes"
3110     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3111   ], [
3112     AS_IF([test -n "${enable_vdpau}"], [
3113       AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3114     ], [
3115       AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3116     ])
3117   ])
3118 ])
3119 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3120
3121
3122 dnl
3123 dnl  Wayland
3124 dnl
3125 AC_ARG_ENABLE(wayland,
3126   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3127 have_wayland="no"
3128 AC_ARG_VAR([WAYLAND_SCANNER], [Wayland scanner utility])
3129
3130 AS_IF([test "${enable_wayland}" != "no"], [
3131   AC_MSG_CHECKING([for the Wayland scanner])
3132   AS_IF([test -z "$WAYLAND_SCANNER"], [
3133     PKG_CHECK_EXISTS([wayland-scanner], [
3134       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3135     ], [
3136       WAYLAND_SCANNER="wayland-scanner"
3137     ])
3138   ])
3139   AC_MSG_RESULT([$WAYLAND_SCANNER])
3140
3141   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3142     have_wayland="yes"
3143   ], [
3144     AS_IF([test -n "${enable_wayland}"], [
3145       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3146     ])
3147   ])
3148
3149   AS_IF([test "${have_egl}" = "yes"], [
3150     PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3151       have_wayland_egl="yes"
3152     ], [
3153       AS_IF([test -n "${enable_wayland}"], [
3154         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3155       ])
3156     ])
3157   ])
3158 ])
3159 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3160 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3161
3162
3163 dnl
3164 dnl  SDL module
3165 dnl
3166 AC_ARG_ENABLE(sdl,
3167   [  --enable-sdl            SDL support (default enabled)])
3168 AC_ARG_ENABLE(sdl-image,
3169   [  --enable-sdl-image      SDL image support (default enabled)])
3170 if test "${enable_sdl}" != "no"
3171 then
3172    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3173       # SDL on Darwin is heavily patched and can only run SDL_image
3174       if test "${SYS}" != "darwin"; then
3175         VLC_ADD_PLUGIN([vout_sdl])
3176       fi
3177
3178       # SDL_image
3179       AS_IF([ test "${enable_sdl_image}" != "no"],[
3180         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3181           VLC_ADD_PLUGIN([sdl_image])],
3182           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3183           ])
3184       ])
3185    ],[
3186      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3187    ])
3188 fi
3189
3190 dnl
3191 dnl  freetype module
3192 dnl
3193 AC_ARG_ENABLE(freetype,
3194   [  --enable-freetype       freetype support   (default auto)])
3195 AC_ARG_ENABLE(fribidi,
3196   [  --enable-fribidi        fribidi support    (default auto)])
3197 AC_ARG_ENABLE(harfbuzz,
3198   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3199 AC_ARG_ENABLE(fontconfig,
3200   [  --enable-fontconfig     fontconfig support (default auto)])
3201
3202 AC_ARG_WITH([default-font],
3203     AS_HELP_STRING([--with-default-font=PATH],
3204         [Path to the default font]),
3205         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3206             "$withval", [Default font])])
3207 AC_ARG_WITH([default-monospace-font],
3208     AS_HELP_STRING([--with-default-monospace-font=PATH],
3209         [Path to the default font]),
3210         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3211             "$withval", [Default monospace font])])
3212
3213 AC_ARG_WITH([default-font-family],
3214     AS_HELP_STRING([--with-default-font-family=NAME],
3215         [Path to the default font family]),
3216         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3217             "$withval", [Default font family])])
3218 AC_ARG_WITH([default-monospace-font-family],
3219     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3220         [Path to the default font family]),
3221         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3222             "$withval", [Default monospace font family])])
3223
3224 have_freetype="no"
3225 have_fontconfig="no"
3226 have_fribidi="no"
3227 have_harfbuzz="no"
3228
3229 if test "${enable_freetype}" != "no"; then
3230    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3231       have_freetype="yes"
3232       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3233       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3234
3235       dnl fontconfig support
3236       if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
3237           if test "${enable_fontconfig}" != "no"; then
3238             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3239               have_fontconfig="yes"
3240             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3241           fi
3242       fi
3243
3244       dnl fribidi support
3245       if test "${enable_fribidi}" != "no"; then
3246         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3247           have_fribidi="yes"
3248           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3249           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3250         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3251       fi
3252
3253       dnl harfbuzz support
3254       if test "${have_fribidi}" != "no"; then
3255         if test "${enable_harfbuzz}" != "no"; then
3256           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3257             have_harfbuzz="yes"
3258             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3259             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3260           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3261         fi
3262       fi
3263   ],[
3264   AS_IF([test -n "${enable_freetype}"],[
3265     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3266     ])
3267   ])
3268 fi
3269
3270 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3271 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3272 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3273 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3274
3275 dnl
3276 dnl SAPI (text to Speech renderer for Windows)
3277 dnl
3278 AC_LANG_PUSH([C++])
3279 AC_CHECK_TYPES([ISpObjectToken],[
3280               have_sapi="yes"
3281             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3282               [#include <windows.h>
3283                #include <sapi.h>
3284                #include <sphelper.h>])
3285 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3286 AC_LANG_POP([C++])
3287
3288 dnl
3289 dnl  SVG module (text rendering and image decoding)
3290 dnl
3291 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3292 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3293
3294 dnl
3295 dnl  Windows DirectX module
3296 dnl
3297
3298 AC_ARG_ENABLE(directx,
3299   [AS_HELP_STRING([--enable-directx],
3300     [Microsoft DirectX support (default enabled on Windows)])],, [
3301   AS_IF([test "${SYS}" = "mingw32"], [
3302     enable_directx="yes"
3303   ], [
3304     enable_directx="no"
3305   ])
3306 ])
3307 AS_IF([test "${enable_directx}" != "no"], [
3308   dnl DirectDraw
3309   AC_CHECK_HEADERS(ddraw.h, [
3310     VLC_ADD_PLUGIN([directdraw])
3311   ])
3312
3313   dnl OpenGL
3314   AC_CHECK_HEADERS(GL/wglew.h, [
3315     VLC_ADD_PLUGIN([glwin32 wgl])
3316   ],, [
3317     #include <windows.h>
3318     #include <GL/gl.h>
3319   ])
3320
3321   dnl Direct3D11
3322   AC_CHECK_HEADERS(d3d11.h, [
3323     VLC_ADD_PLUGIN([direct3d11])
3324   ])
3325
3326   dnl Direct3D9
3327   AC_CHECK_HEADERS(d3d9.h, [
3328     VLC_ADD_PLUGIN([direct3d9])
3329   ])
3330
3331 ])
3332
3333 dnl
3334 dnl  Linux framebuffer module
3335 dnl
3336 AC_CHECK_HEADER([linux/fb.h], [
3337   VLC_ADD_PLUGIN([fb])
3338 ])
3339
3340
3341 dnl
3342 dnl  DirectFB module
3343 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3344 dnl  TODO: support for static linking
3345 dnl
3346 AC_ARG_ENABLE(directfb,
3347   [  --enable-directfb       DirectFB support (default disabled)])
3348 AC_ARG_WITH(directfb,
3349   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3350
3351 if test "${enable_directfb}" = "yes"; then
3352     have_directfb="false"
3353     CPPFLAGS_mydirectfb=
3354     LIBS_mydirectfb=
3355     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3356         dnl Trying the given location
3357         VLC_SAVE_FLAGS
3358
3359         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3360         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3361
3362         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3363         LIBS="${LIBS} ${LIBS_new}"
3364
3365         dnl FIXME: too obscure
3366         AC_CHECK_HEADER([directfb.h], [
3367             AC_CHECK_LIB([direct],[direct_initialize], [
3368                 AC_CHECK_LIB([fusion], [fusion_enter], [
3369                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3370                 ], have_directfb="false")
3371             ], have_directfb="false")
3372         ], have_directfb="false")
3373
3374         VLC_RESTORE_FLAGS
3375
3376         if test "${have_directfb}" = "true"; then
3377             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3378             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3379         fi
3380     else
3381         dnl Look for directfb-config
3382         AC_CHECK_PROG(DIRECTFB_CONFIG, [directfb-config], [false])
3383         AS_IF(["${DIRECTFB_CONFIG}" != "false"], [
3384             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3385             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3386             have_directfb="true"
3387         ], [
3388             dnl Trying with pkg-config
3389             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3390                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3391                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3392                 have_directfb="true"
3393                 ], [have_directfb="false"])
3394         ])
3395     fi
3396     if test "${have_directfb}" = "true"; then
3397         VLC_ADD_PLUGIN([directfb])
3398         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3399         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3400     else
3401         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3402     fi
3403 fi
3404
3405 dnl
3406 dnl  AA plugin
3407 dnl
3408 AC_ARG_ENABLE(aa,
3409   [  --enable-aa             aalib output (default disabled)])
3410 if test "${enable_aa}" = "yes"
3411 then
3412   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3413   if test "${have_aa}" = "true"
3414   then
3415     VLC_ADD_PLUGIN([aa])
3416   fi
3417 fi
3418
3419 dnl
3420 dnl  libcaca plugin
3421 dnl
3422 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3423
3424 dnl
3425 dnl  OS/2 KVA plugin
3426 dnl
3427 AC_ARG_ENABLE(kva,
3428   [AS_HELP_STRING([--enable-kva],
3429     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3430   AS_IF([test "$SYS" = "os2"], [
3431     enable_kva="yes"
3432   ])
3433 ])
3434 have_kva="no"
3435 KVA_LIBS=""
3436 AS_IF([test "$enable_kva" != "no"], [
3437   AC_CHECK_HEADERS([kva.h], [
3438     have_kva="yes"
3439     AC_CHECK_LIB(kva, main, [
3440       KVA_LIBS="-lkva"
3441     ])
3442   ])
3443 ])
3444 AC_SUBST(KVA_LIBS)
3445 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3446
3447 dnl
3448 dnl MMAL plugin
3449 dnl
3450 AC_ARG_ENABLE(mmal,
3451   AS_HELP_STRING([--enable-mmal],
3452     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3453 if test "${enable_mmal}" != "no"; then
3454   VLC_SAVE_FLAGS
3455   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3456   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3457   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3458     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3459         have_mmal="yes"
3460         VLC_ADD_PLUGIN([mmal])
3461         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3462         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3463         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lvchostif ]) ], [
3464           AS_IF([test "${enable_mmal}" = "yes"],
3465             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3466             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3467           ],
3468         [])
3469     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3470       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3471       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3472   VLC_RESTORE_FLAGS
3473 fi
3474 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3475
3476 dnl
3477 dnl evas plugin
3478 dnl
3479 AC_ARG_ENABLE(evas,
3480   [AS_HELP_STRING([--enable-evas],
3481     [use evas output module (default disabled)])])
3482 have_evas="no"
3483 AS_IF([test "${enable_evas}" = "yes"], [
3484   PKG_CHECK_MODULES(EVAS, [evas >= 1.15.99 ecore >= 1.15.99], [
3485       have_evas="yes"
3486       AC_DEFINE([HAVE_EVAS], [1], [Define to 1 if evas is enabled.])
3487     ],[
3488     AS_IF([test "x${enable_evas}" != "x"], [
3489       AC_MSG_ERROR([$EVAS_PKG_ERRORS. libevas and libecore 1.15.99 or later required.])
3490     ])
3491   ])
3492 ])
3493 AM_CONDITIONAL([HAVE_EVAS], [test "${have_evas}" = "yes"])
3494
3495 dnl
3496 dnl  Audio plugins
3497 dnl
3498
3499 EXTEND_HELP_STRING([Audio plugins:])
3500
3501 dnl
3502 dnl  Pulseaudio module
3503 dnl
3504 AC_ARG_ENABLE(pulse,
3505   [AS_HELP_STRING([--enable-pulse],
3506     [use the PulseAudio client library (default auto)])])
3507 have_pulse="no"
3508 AS_IF([test "${enable_pulse}" != "no"], [
3509   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3510     have_pulse="yes"
3511   ], [
3512     AS_IF([test "x${enable_pulse}" != "x"], [
3513       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3514     ])
3515   ])
3516 ])
3517 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3518
3519 dnl
3520 dnl  ALSA module
3521 dnl
3522 AC_ARG_ENABLE(alsa,
3523   [AS_HELP_STRING([--enable-alsa],
3524     [support the Advanced Linux Sound Architecture (default auto)])],, [
3525   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3526     enable_alsa="yes"
3527   ])
3528 ])
3529 have_alsa="no"
3530 AS_IF([test "${enable_alsa}" != "no"], [
3531   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3532     have_alsa="yes"
3533   ], [
3534     AS_IF([test "x${enable_alsa}" != "x"], [
3535       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3536     ])
3537   ])
3538 ])
3539 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3540
3541 dnl
3542 dnl  Open Sound System module
3543 dnl
3544 AC_ARG_ENABLE(oss,
3545   [AS_HELP_STRING([--enable-oss],
3546     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3547   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3548     enable_oss="no"
3549   ])
3550 ])
3551 have_oss="no"
3552 OSS_LIBS=""
3553 AS_IF([test "$enable_oss" != "no"], [
3554   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3555     have_oss="yes"
3556     AC_CHECK_LIB(ossaudio, main, [
3557       OSS_LIBS="-lossaudio"
3558     ])
3559   ])
3560 ])
3561 AC_SUBST(OSS_LIBS)
3562 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3563
3564 dnl
3565 dnl  OpenBSD sndio module
3566 dnl
3567 AC_ARG_ENABLE([sndio],
3568   [AS_HELP_STRING([--disable-sndio],
3569     [support the OpenBSD sndio (default auto)])],, [
3570   AS_IF([test "$SYS" = "openbsd"], [
3571     enable_sndio="yes"
3572   ])
3573 ])
3574 have_sndio="no"
3575 AS_IF([test "$enable_sndio" != "no"], [
3576   AC_CHECK_HEADER([sndio.h], [
3577     have_sndio="yes"
3578   ])
3579 ])
3580 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3581
3582 dnl
3583 dnl  Windows Audio Session plugin
3584 dnl
3585 AC_ARG_ENABLE([wasapi],
3586   [AS_HELP_STRING([--enable-wasapi],
3587     [use the Windows Audio Session API (default auto)])
3588 ])
3589 have_wasapi="no"
3590 AS_IF([test "$enable_wasapi" != "no"], [
3591   AC_CHECK_HEADER([audioclient.h], [
3592     have_wasapi="yes"
3593   ], [
3594     AS_IF([test "x${enable_wasapi}" != "x"], [
3595       AC_MSG_ERROR([Windows Audio Session API not found.])
3596     ])
3597   ])
3598 ])
3599 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3600
3601 dnl
3602 dnl  AudioQueue plugin
3603 dnl
3604 AC_ARG_ENABLE(audioqueue,
3605   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3606 if test "${enable_audioqueue}" = "yes"
3607 then
3608   VLC_ADD_PLUGIN([audioqueue])
3609 fi
3610
3611 dnl
3612 dnl  JACK modules
3613 dnl
3614 AC_ARG_ENABLE(jack,
3615   [AS_HELP_STRING([--disable-jack],
3616     [do not use jack (default auto)])])
3617 have_jack="no"
3618 AS_IF([test "${enable_jack}" != "no"], [
3619     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3620       [ have_jack=yes ],
3621       [
3622       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3623
3624       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3625       [ have_jack=yes ],
3626       [
3627       AS_IF([test -n "${enable_jack}"],
3628          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3629          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3630       ])
3631     ])
3632 ])
3633 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3634
3635 dnl
3636 dnl  OpenSLES Android
3637 dnl
3638 AC_ARG_ENABLE(opensles,
3639   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3640 if test "${HAVE_ANDROID}" = "1"; then
3641   if test "${enable_opensles}" = "yes"; then
3642       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3643         [ VLC_ADD_PLUGIN([opensles_android]) ],
3644         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3645   fi
3646 fi
3647
3648 dnl
3649 dnl  Tizen audio
3650 dnl
3651 AC_ARG_ENABLE(tizen_audio,
3652   [AS_HELP_STRING([--enable-tizen-audio],
3653     [Tizen audio module (default enabled on Tizen)])],, [
3654   AS_IF([test "$HAVE_TIZEN" = "1"], [
3655     enable_tizen_audio="yes"
3656   ])
3657 ])
3658 if test "${enable_tizen_audio}" = "yes"; then
3659   AC_CHECK_HEADERS(audio_io.h,
3660     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3661     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3662 fi
3663
3664 dnl
3665 dnl libsamplerate plugin
3666 dnl
3667 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3668
3669 dnl
3670 dnl  soxr module
3671 dnl
3672 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3673
3674 dnl
3675 dnl  OS/2 KAI plugin
3676 dnl
3677 AC_ARG_ENABLE(kai,
3678   [AS_HELP_STRING([--enable-kai],
3679     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3680   AS_IF([test "$SYS" = "os2"], [
3681     enable_kai="yes"
3682   ])
3683 ])
3684 have_kai="no"
3685 KAI_LIBS=""
3686 AS_IF([test "$enable_kai" != "no"], [
3687   AC_CHECK_HEADERS([kai.h], [
3688     have_kai="yes"
3689     AC_CHECK_LIB(kai, main, [
3690       KAI_LIBS="-lkai"
3691     ])
3692   ])
3693 ])
3694 AC_SUBST(KAI_LIBS)
3695 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3696
3697 dnl
3698 dnl  chromaprint audio track fingerprinter
3699 dnl
3700 m4_pushdef([libchromaprint_version], 0.6.0)
3701 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3702     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3703     AS_IF([test "${enable_chromaprint}" = "yes"],
3704         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3705         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3706          ),
3707     [(Chromaprint based audio fingerprinter)],[auto])
3708 m4_popdef([libchromaprint_version])
3709
3710 dnl
3711 dnl  Chromecast streaming support
3712 dnl
3713 m4_pushdef([protobuf_lite_version], 2.5.0)
3714 AC_ARG_VAR(PROTOC, [protobuf compiler])
3715 AC_CHECK_PROGS(PROTOC, protoc, no)
3716 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3717     AS_IF([test "x${PROTOC}" != "xno"], [
3718         build_chromecast="yes"
3719     ], [
3720     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3721     ])
3722 ], [
3723     AS_IF([test "${enable_chromecast}" = "yes"],
3724         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3725         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3726     )
3727     enable_chromecast="no"
3728 ], [(Chromecast streaming support)], [auto])
3729 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3730 m4_popdef([protobuf_lite_version])
3731
3732 dnl
3733 dnl  Interface plugins
3734 dnl
3735
3736 EXTEND_HELP_STRING([Interface plugins:])
3737
3738 dnl
3739 dnl QT
3740 dnl
3741 AC_ARG_ENABLE(qt, [
3742   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3743   AS_IF([test "${SYS}" = "darwin"], [
3744     enable_qt="no"
3745   ])
3746 ])
3747 have_qt5_x11="no"
3748 AS_IF([test "${enable_qt}" != "no"], [
3749   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.2.0 Qt5Widgets Qt5Gui], [
3750       PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3751           have_qt5_x11="yes"
3752       ],[
3753           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3754       ])
3755       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3756       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3757       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3758       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3759       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3760     ], [
3761       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.8.0],, [
3762         AS_IF([test -n "${enable_qt}"],[
3763           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3764         ],[
3765           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3766         ])
3767         enable_qt="no"
3768       ])
3769       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3770       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin"])
3771       AC_PATH_PROG(RCC, rcc, rcc, ["${QT_PATH}/bin"])
3772       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin"])
3773     ])
3774 ])
3775 AS_IF([test "${enable_qt}" != "no"], [
3776   VLC_ADD_PLUGIN([qt])
3777   ALIASES="${ALIASES} qvlc"
3778 ])
3779 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3780 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3781
3782 dnl
3783 dnl detect kde4-config patch (used for kde solids).
3784 dnl
3785 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3786 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3787   KDE4_CONFIG="kde4-config"
3788 ])
3789
3790 dnl
3791 dnl Simple test for skins2 dependency
3792 dnl
3793 AS_IF([test "$enable_qt" = "no"], [
3794   AS_IF([test "${enable_skins2}" = "yes"], [
3795     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3796   ], [
3797     enable_skins2="no"
3798     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3799   ])
3800 ])
3801
3802 dnl
3803 dnl Skins2 module
3804 dnl
3805 AC_ARG_ENABLE(skins2,
3806   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3807 AS_IF([test "${enable_skins2}" != "no"], [
3808   have_skins_deps="yes"
3809
3810   dnl Win32
3811   AS_IF([test "${SYS}" = "mingw32"], [
3812     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3813     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3814   dnl OS/2
3815   ], [test "${SYS}" = "os2"], [
3816     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3817   dnl Linux/Unix
3818   ], [
3819     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3820     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3821     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3822     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3823     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3824   ])
3825
3826   dnl for All OSes
3827   VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3828
3829   dnl we need freetype
3830   AS_IF([test "${have_freetype}" != "yes"], [
3831     have_skins_deps="no"
3832   ])
3833
3834   AS_IF([test "${have_skins_deps}" = "no"], [
3835     AS_IF([test "x${enable_skins2}" = "x"], [
3836       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3837     ], [
3838       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3839     ])
3840     enable_skins2="no"
3841   ], [
3842     VLC_ADD_PLUGIN([skins2])
3843     ALIASES="${ALIASES} svlc"
3844     enable_skins2="yes"
3845   ])
3846 ])
3847 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3848
3849 AC_ARG_ENABLE(libtar,
3850   [  --enable-libtar         libtar support for skins2 (default auto)])
3851 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3852   AC_CHECK_HEADERS(libtar.h, [
3853     VLC_ADD_LIBS([skins2],[-ltar])
3854   ])
3855 ])
3856
3857 dnl
3858 dnl  MacOS X gui module
3859 dnl
3860 AC_ARG_ENABLE(macosx,
3861   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3862 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3863 then
3864   VLC_ADD_PLUGIN([macosx])
3865
3866   if test ! -d ${CONTRIB_DIR}/BGHUDAppKit.framework
3867   then
3868     AC_MSG_ERROR([BGHUDAppKit framework is required and was not found in ${CONTRIB_DIR}])
3869   fi
3870 fi
3871 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no"])
3872
3873 dnl
3874 dnl  MacOS X sparkle update support
3875 dnl
3876 AC_ARG_ENABLE(sparkle,
3877   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3878 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3879 then
3880   if test ! -d ${CONTRIB_DIR}/Sparkle.framework
3881   then
3882     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3883   fi
3884
3885   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3886 fi
3887 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3888
3889
3890 dnl
3891 dnl  Minimal Mac OS X module
3892 dnl
3893 AC_ARG_ENABLE(minimal-macosx,
3894   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3895 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3896 then
3897   VLC_ADD_PLUGIN([minimal_macosx])
3898 fi
3899
3900 dnl
3901 dnl  VideoToolbox plugins
3902 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3903     VLC_ADD_PLUGIN([videotoolbox])
3904     VLC_ADD_PLUGIN([cvpx_i420])
3905   ])
3906
3907 dnl
3908 dnl  ncurses module
3909 dnl
3910 AC_ARG_ENABLE(ncurses,
3911 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3912 have_ncurses="no"
3913 AS_IF([test "${enable_ncurses}" != "no"] ,[
3914   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3915     have_ncurses="yes"
3916     ALIASES="${ALIASES} nvlc"
3917   ], [
3918     AS_IF([test -n "${enable_ncurses}"], [
3919       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3920     ])
3921   ])
3922 ])
3923 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3924
3925 dnl
3926 dnl  Lirc plugin
3927 dnl
3928 AC_ARG_ENABLE(lirc,
3929   [  --enable-lirc           lirc support (default disabled)])
3930 have_lirc="no"
3931 AS_IF([test "${enable_lirc}" = "yes"], [
3932   AC_CHECK_HEADER(lirc/lirc_client.h, [
3933     AC_CHECK_LIB(lirc_client, lirc_init, [
3934       have_lirc="yes"
3935     ])
3936   ])
3937 ])
3938 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3939
3940 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3941 dnl
3942 dnl  goom visualization plugin
3943 dnl
3944 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3945
3946 dnl
3947 dnl libprojectM visualization plugin
3948 dnl
3949 AC_ARG_ENABLE(projectm,
3950   [  --enable-projectm       projectM visualization plugin (default enabled)])
3951 AS_IF([test "${enable_projectm}" != "no"],
3952   [
3953     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3954     [
3955       VLC_ADD_PLUGIN([projectm])
3956       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3957         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3958         [ AC_MSG_WARN( [Using libprojectM version 1] )
3959       ])
3960     ],[
3961       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3962     ])
3963   ])
3964
3965 dnl
3966 dnl Vovoid VSXu visualization plugin
3967 dnl
3968 AC_ARG_ENABLE(vsxu,
3969   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3970 AS_IF([test "${enable_vsxu}" != "no"],
3971   [
3972     PKG_CHECK_MODULES(VSXU, libvsxu,
3973     [
3974       VLC_ADD_PLUGIN([vsxu])
3975     ],[
3976       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3977     ])
3978   ])
3979
3980 EXTEND_HELP_STRING([Service Discovery plugins:])
3981 dnl
3982 dnl  Avahi-Zeroconf services discovery
3983 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
3984
3985 dnl
3986 dnl  libudev services discovery
3987 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3988
3989 dnl
3990 dnl MTP devices services discovery
3991 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3992
3993 dnl
3994 dnl UPnP Plugin (Intel SDK)
3995 dnl
3996 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3997
3998 dnl
3999 dnl mDNS using libmicrodns
4000 dnl
4001 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
4002
4003
4004 EXTEND_HELP_STRING([Misc options:])
4005
4006 dnl
4007 dnl  libxml2 module
4008 dnl
4009 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4010
4011
4012 dnl
4013 dnl libgcrypt
4014 dnl
4015 AC_ARG_ENABLE(libgcrypt,
4016   [  --disable-libgcrypt     gcrypt support (default enabled)])
4017 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
4018 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4019
4020 # require libgcrypt >= 1.6.0
4021 AS_IF([test "${enable_libgcrypt}" != "no"], [
4022   AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4023     VLC_SAVE_FLAGS
4024     CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4025     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4026 [#include <gcrypt.h>
4027 #if GCRYPT_VERSION_NUMBER < 0x010600
4028 #error
4029 #endif]])], [
4030       ac_cv_lib_gcrypt=yes
4031     ], [
4032       ac_cv_lib_gcrypt=no
4033     ])
4034     VLC_RESTORE_FLAGS
4035   ])
4036
4037   AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4038     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4039   ], [
4040     AS_IF([test "${enable_libgcrypt}" = "yes"], [
4041       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4042     ])
4043   ])
4044 ])
4045
4046 AS_IF([test -z "$GCRYPT_LIBS"], [
4047   GCRYPT_LIBS="-lgcrypt -lgpg-error"
4048 ])
4049
4050 AC_SUBST(GCRYPT_CFLAGS)
4051 AC_SUBST(GCRYPT_LIBS)
4052 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4053
4054 dnl
4055 dnl TLS/SSL
4056 dnl
4057 AC_ARG_ENABLE(gnutls,
4058   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4059 AS_IF([test "${enable_gnutls}" != "no"], [
4060   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.2.0], [
4061     VLC_ADD_PLUGIN([gnutls])
4062   ], [
4063     AS_IF([test -n "${enable_gnutls}"], [
4064       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4065     ])
4066   ])
4067 ])
4068
4069
4070 dnl
4071 dnl Taglib plugin
4072 dnl
4073 AC_ARG_ENABLE(taglib,
4074   [AS_HELP_STRING([--disable-taglib],
4075     [do not use TagLib (default enabled)])])
4076 AS_IF([test "${enable_taglib}" != "no"], [
4077   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4078     VLC_ADD_PLUGIN([taglib])
4079   ], [
4080     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4081 ])
4082
4083 dnl
4084 dnl  libsecret
4085 dnl
4086 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4087
4088 dnl
4089 dnl  kwallet
4090 dnl
4091 AC_ARG_ENABLE(kwallet,
4092   [AS_HELP_STRING([--enable-kwallet],
4093     [use kwallet (via D-Bus) for keystore (default enabled)])])
4094 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4095   VLC_ADD_PLUGIN([kwallet])
4096 ])
4097
4098 dnl
4099 dnl  Developers helper modules (should be hidden from configure help)
4100 dnl
4101 AC_ARG_ENABLE(devtools, [], [], [enable_devtools="no"])
4102 AS_IF([test "${enable_devtools}" != "no"], [
4103   VLC_ADD_PLUGIN([accesstweaks])
4104 ])
4105
4106 dnl
4107 dnl update checking system
4108 dnl
4109 AC_ARG_ENABLE(update-check,
4110   [  --enable-update-check   update checking system (default disabled)])
4111 if test "${enable_update_check}" = "yes"
4112 then
4113  AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4114     AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4115   VLC_ADD_LIBS([libvlccore], [${GCRYPT_LIBS}])
4116   VLC_ADD_CFLAGS([libvlccore], [${GCRYPT_CFLAGS}])
4117   AC_DEFINE([UPDATE_CHECK], 1, [Define if you want to use the VLC update mechanism])
4118 fi
4119
4120 dnl
4121 dnl OS X notification plugin
4122 dnl
4123 AC_ARG_ENABLE(osx_notifications,
4124   [  --enable-osx-notifications          osx notification plugin (default disabled)],,
4125   [enable_osx_notifications=no])
4126 AS_IF([test "${enable_osx_notifications}" != "no"], [
4127     AC_CHECK_HEADERS(${CONTRIB_DIR}/Growl.framework/Versions/A/Headers/Growl.h, [
4128       VLC_ADD_PLUGIN([osx_notifications])
4129       VLC_ADD_LIBS([osx_notifications], [-F${CONTRIB_DIR} -Wl,-framework,Growl,-framework,Foundation])
4130       VLC_ADD_OBJCFLAGS([osx_notifications], [-F${CONTRIB_DIR}])
4131       VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4132     ])
4133   ]
4134 )
4135
4136 dnl
4137 dnl Libnotify notification plugin
4138 dnl
4139 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4140
4141 dnl
4142 dnl  Endianness check
4143 dnl
4144 AC_C_BIGENDIAN
4145 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4146   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4147 ], [
4148   DEFS_BIGENDIAN=""
4149 ])
4150 AC_SUBST(DEFS_BIGENDIAN)
4151
4152 dnl
4153 dnl Where to install KDE solid .desktop
4154 dnl
4155 AC_ARG_WITH(kde-solid,
4156   AS_HELP_STRING([--with-kde-solid=PATH],
4157                  [KDE Solid actions directory (auto)]),, [
4158
4159 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4160   with_kde_solid="yes"
4161 fi
4162 ])
4163 soliddatadir=""
4164 AS_IF([test "${with_kde_solid}" != "no"], [
4165   AS_IF([test "${with_kde_solid}" = "yes"], [
4166     kde4datadir="`${KDE4_CONFIG} --install data`"
4167     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4168     soliddatadir="${kde4datadir}/solid/actions"
4169   ], [
4170     soliddatadir="${with_kde_solid}"
4171   ])
4172 ])
4173 AC_SUBST(soliddatadir)
4174 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4175
4176 EXTEND_HELP_STRING([Components:])
4177
4178 dnl
4179 dnl  the VLC binary
4180 dnl
4181 AC_ARG_ENABLE(vlc,
4182   [  --enable-vlc            build the VLC media player (default enabled)])
4183 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4184
4185 AC_ARG_ENABLE(macosx-vlc-app,
4186   [  --enable-macosx-vlc-app build the VLC media player (default enabled on Mac OS X)])
4187 AM_CONDITIONAL(BUILD_MACOSX_VLC_APP, [test "${enable_macosx_vlc_app}" != "no" &&
4188     (test "${SYS}" = "darwin" || test "${enable_macosx_vlc_app}" = "yes") ])
4189
4190 dnl
4191 dnl  Stuff used by the program
4192 dnl
4193 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4194 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4195 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4196 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4197 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4198 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4199 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4200 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4201 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4202 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4203 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4204 AC_SUBST(COPYRIGHT_MESSAGE)
4205 AC_SUBST(VERSION_MESSAGE)
4206 AC_SUBST(VERSION_MAJOR)
4207 AC_SUBST(VERSION_MINOR)
4208 AC_SUBST(VERSION_REVISION)
4209 AC_SUBST(VERSION_EXTRA)
4210 AC_SUBST(COPYRIGHT_YEARS)
4211 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4212 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4213 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4214 dnl
4215 dnl  Handle substvars that use $(top_srcdir)
4216 dnl
4217 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4218
4219 dnl
4220 dnl  Configuration is finished
4221 dnl
4222 AC_SUBST(SYS)
4223 AC_SUBST(ARCH)
4224 AC_SUBST(ALIASES)
4225 AC_SUBST(ASM)
4226 AC_SUBST(MOC)
4227 AC_SUBST(RCC)
4228 AC_SUBST(UIC)
4229 AC_SUBST(WINDRES)
4230 AC_SUBST(WINE_SDK_PATH)
4231 AC_SUBST(LIBEXT)
4232 AC_SUBST(AM_CPPFLAGS)
4233 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4234 AC_SUBST(FILE_LIBVLCCORE_DLL)
4235 AC_SUBST(FILE_LIBVLC_DLL)
4236
4237 AC_CONFIG_FILES([
4238   Makefile
4239   doc/Makefile
4240   modules/Makefile
4241   m4/Makefile
4242   po/Makefile.in
4243   share/Makefile
4244   compat/Makefile
4245   src/Makefile
4246   lib/Makefile
4247   bin/Makefile
4248   test/Makefile
4249   modules/gui/macosx/Makefile
4250   modules/gui/qt/Makefile
4251   modules/gui/skins2/Makefile
4252   modules/hw/mmal/Makefile
4253   share/vlc.appdata.xml.in
4254 ])
4255
4256 AM_COND_IF([HAVE_WIN32], [
4257   AC_CONFIG_FILES([
4258     extras/package/win32/NSIS/spad.nsi
4259     extras/package/win32/NSIS/vlc.win32.nsi
4260     extras/package/win32/msi/config.wxi
4261   ])
4262 ])
4263
4264 AM_COND_IF([HAVE_DARWIN], [
4265   AC_CONFIG_FILES([
4266     extras/package/macosx/Info.plist
4267     extras/package/macosx/Resources/English.lproj/InfoPlist.strings
4268   ])
4269 ])
4270
4271 dnl Generate makefiles
4272 AC_OUTPUT
4273
4274 dnl Do we have to use make or gmake ?
4275 if make --version 2>&1|grep -q GNU
4276 then
4277     # GNU make, all seems good
4278     MAKE=make
4279 else
4280     # Known GNU make alias (on BSD)
4281     MAKE=gmake
4282 fi
4283 dnl Shortcut to nice compile message
4284 if test -n $SHELL; then
4285   SHELL=${CONFIG_SHELL-/bin/sh}
4286 fi
4287 rm -f compile
4288 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4289 echo "#! $SHELL
4290 rm -f .error\$\$
4291 ERROR=0
4292 export PATH=\"$PATH\" LANG=C
4293 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4294 test -f .error\$\$ && ERROR=1
4295 rm -f .error\$\$
4296 exit \$ERROR" >compile
4297 chmod a+x compile
4298
4299 echo "
4300 libvlc configuration
4301 --------------------
4302 version               : ${VERSION}
4303 system                : ${SYS}
4304 architecture          : ${ARCH}
4305 optimizations         : ${enable_optimizations}"
4306 if test "${enable_vlc}" != "no"; then
4307 echo "vlc aliases           :${ALIASES}"
4308 else
4309 echo "build vlc executable  : no"
4310 fi
4311 echo "
4312 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."