configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 1999-2018 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 4.0.0-dev)
   6 VERSION_MAJOR=4
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=dev
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Otto Chriek"
  17 COPYRIGHT_YEARS="1996-2018"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 AM_SILENT_RULES([yes])
  31 AM_MAINTAINER_MODE([enable])
  32
  33 dnl
  34 dnl Directories
  35 dnl
  36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  37 dnl AC_SUBST(vlcincludedir)
  38 vlcdatadir="\${datadir}/\${PKGDIR}"
  39 AC_SUBST(vlcdatadir)
  40 vlclibdir="\${libdir}/\${PKGDIR}"
  41 AC_SUBST(vlclibdir)
  42
  43 dnl
  44 dnl Check for tools
  45 dnl
  46 AC_PROG_CC
  47 AC_USE_SYSTEM_EXTENSIONS
  48 VLC_PROG_CC_C11
  49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  51 AH_TOP([
  52 #ifndef _REENTRANT
  53 # define _REENTRANT
  54 #endif
  55 ])
  56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  59
  60 AC_PROG_CXX
  61 AC_PROG_CPP
  62 AC_PROG_OBJC
  63 AC_PROG_EGREP
  64 AC_PROG_MAKE_SET
  65 AC_PROG_INSTALL
  66 AM_PROG_AS
  67 AC_PROG_LEX
  68 AC_PROG_YACC
  69
  70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
  73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
  74 AS_IF([test "$BUILDCC" = "false"], [
  75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
  76 ])
  77
  78 dnl Check for compiler properties
  79 AC_C_CONST
  80 AC_C_INLINE
  81 AC_C_RESTRICT
  82 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
  83
  84 dnl Extend the --help string at the current spot.
  85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  86
  87 dnl Allow binary package maintainer to pass a custom string to avoid
  88 dnl cache problem
  89 AC_ARG_WITH(binary-version,
  90     AS_HELP_STRING([--with-binary-version=STRING],
  91          [To avoid plugins cache problem between binary version]),[],[])
  92 AS_IF([test -n "${with_binary_version}"],[
  93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  94          [Binary specific version])
  95 ])
  96
  97 dnl Prevent clang from accepting unknown flags with a mere warning
  98 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CFLAGS])
  99 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CXXFLAGS])
 100
 101 dnl
 102 dnl  Check the operating system
 103 dnl
 104 HAVE_WIN64="0"
 105 HAVE_IOS="0"
 106 HAVE_OSX="0"
 107 HAVE_TVOS="0"
 108
 109 case "${host_os}" in
 110   "")
 111     SYS=unknown
 112     ;;
 113   linux*)
 114     SYS=linux
 115     ;;
 116   bsdi*)
 117     SYS=bsdi
 118     CFLAGS="${CFLAGS} -pthread"
 119     ;;
 120   freebsd*)
 121     SYS=freebsd
 122     CFLAGS="${CFLAGS} -pthread"
 123     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 124     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 125     ac_cv_ld_z_defs=no
 126     ;;
 127   openbsd*)
 128     SYS=openbsd
 129     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 130     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 131     ;;
 132   netbsd*)
 133     SYS=netbsd
 134     ;;
 135   dragonfly*)
 136     SYS=dragonfly
 137     ;;
 138   darwin*)
 139
 140     dnl Force gcc "-arch" flag
 141     ARCH_flag=""
 142     case "${host}" in
 143       i?86*)
 144         ARCH_flag="-arch i386"
 145       ;;
 146       ppc64*)
 147         ARCH_flag="-arch ppc64"
 148       ;;
 149       ppc*)
 150         ARCH_flag="-arch ppc"
 151       ;;
 152       x86_64*)
 153         ARCH_flag="-arch x86_64"
 154       ;;
 155       arm*)
 156         ac_cv_c_bigendian="no"
 157         ac_cv_c_attribute_packed="no"
 158       ;;
 159     esac
 160
 161     SYS=darwin
 162     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 163     CXX="${CXX} -stdlib=libc++ -std=c++11"
 164     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 165     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 166     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
 167     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 168     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 169     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 170
 171     AC_EGREP_CPP(yes,
 172             [#import <TargetConditionals.h>
 173              #if TARGET_OS_IPHONE
 174              yes
 175              #endif],
 176              [HAVE_IOS="1"],
 177              [HAVE_OSX="1"])
 178
 179     AC_EGREP_CPP(yes,
 180             [#import <TargetConditionals.h>
 181              #if TARGET_OS_TV
 182              yes
 183              #endif],
 184              [HAVE_TVOS="1"
 185              HAVE_IOS="0"
 186              HAVE_OSX="0"
 187              ],)
 188
 189     dnl
 190     dnl  Handle Mac OS X SDK flags
 191     dnl
 192     AC_ARG_WITH(macosx-sdk,
 193       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 194         [compile using the SDK in DIR])])
 195     if test "${with_macosx_sdk}" != "" ; then
 196         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 197         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 198         CC="${CC} -isysroot ${with_macosx_sdk}"
 199         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 200         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 201         LD="${LD} -syslibroot ${with_macosx_sdk}"
 202     fi
 203     AC_ARG_WITH(macosx-version-min,
 204       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 205         [compile for Mac OS X VERSION and above])])
 206     if test "${with_macosx_version_min}" != "" ; then
 207         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 208         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 209         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 210         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 211         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 212     fi
 213     ;;
 214   *mingw32* | *cygwin* | *wince* | *mingwce*)
 215     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
 216     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
 217     CXXFLAGS="${CXXFLAGS} -static-libgcc"
 218     AC_CHECK_TOOL(WINDRES, windres, :)
 219     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 220     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
 221     AH_TOP([# define _WIN32_WINNT 0x0601 /* Windows 7 */])
 222     AH_TOP([#endif])
 223     AC_DEFINE([_WIN32_WINNT], 0x0601, [Define to '0x0601' for Windows 7 APIs.])
 224     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 225     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 226     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 227     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 228     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 229     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 230     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 231     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 232     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 233     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 234     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 235
 236     case "${host_os}" in
 237       *mingw32*)
 238         SYS=mingw32
 239         ;;
 240       *cygwin*)
 241         dnl Check if we are using the mno-cygwin mode in which case we are
 242         dnl actually dealing with a mingw32 compiler.
 243         AC_EGREP_CPP(yes,
 244             [#ifdef _WIN32
 245              yes
 246              #endif],
 247             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 248         ;;
 249     esac
 250
 251     if test "${SYS}" = "mingw32"; then
 252         # DEP, ASLR, NO SEH
 253         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 254
 255         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 256         ac_default_prefix="`pwd`/_win32"
 257         DESTDIR="`pwd`/_win32/"
 258
 259         dnl
 260         dnl NSIS/MSI Installer prefix and WIN64
 261         dnl
 262         case "${host}" in
 263             amd64*|x86_64*)
 264                 HAVE_WIN64="1"
 265                 WINDOWS_ARCH="x64"
 266                 PROGRAMFILES="PROGRAMFILES64"
 267                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
 268             ;;
 269             *)
 270                 WINDOWS_ARCH="x86"
 271                 PROGRAMFILES="PROGRAMFILES"
 272             ;;
 273         esac
 274         AC_SUBST(WINDOWS_ARCH)
 275         AC_SUBST(PROGRAMFILES)
 276
 277     fi
 278     ;;
 279   *nto*)
 280     SYS=nto
 281     ;;
 282   solaris*)
 283     SYS=solaris
 284     ;;
 285   hpux*)
 286     SYS=hpux
 287     ;;
 288   *os2*)
 289     SYS=os2
 290     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 291     AC_LIBOBJ([freeaddrinfo])
 292     AC_LIBOBJ([gai_strerror])
 293     ;;
 294   *nacl*)
 295     SYS=nacl
 296     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 297     AC_LIBOBJ([sigwait])
 298     AC_LIBOBJ([recvmsg])
 299     AC_LIBOBJ([sendmsg])
 300     ;;
 301   *)
 302     SYS="${host_os}"
 303     ;;
 304 esac
 305
 306 dnl WinRT
 307 AC_ARG_ENABLE(winstore_app,
 308      AS_HELP_STRING([--enable-winstore-app],
 309                     [Build targetted for Windows Store apps (default disabled)]))
 310
 311 vlc_winstore_app=0
 312 AS_IF([test "${SYS}" = "mingw32"],[
 313   LIBCOM="-lole32"
 314   AS_IF([test "${enable_winstore_app}" = "yes"], [
 315     vlc_winstore_app=1
 316     LIBCOM=""
 317      VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
 318      AC_LIBOBJ([gai_strerror])
 319     ],[])
 320   AC_SUBST(LIBCOM)
 321   ])
 322 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 323
 324 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 325 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 326
 327 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 328 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
 329 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
 330 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
 331
 332 AM_CONDITIONAL(HAVE_NACL,    test "${SYS}" = "nacl")
 333 AM_CONDITIONAL(HAVE_LIBANL,  test "${HAVE_LIBANL}" = "1")
 334
 335 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 336 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
 337 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 338 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
 339
 340 dnl
 341 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 342 dnl for program foo on win32
 343 case "${build_os}" in
 344     cygwin|msys|mingw32)
 345         ac_executable_extensions=".exe"
 346         BUILDEXEEXT=".exe"
 347     ;;
 348     os2*)
 349         BUILDEXEEXT=".exe"
 350     ;;
 351     *)
 352     ;;
 353 esac
 354 AC_SUBST(BUILDEXEEXT)
 355
 356 dnl Android is linux, but a bit different
 357 AS_IF([test "$SYS" = linux],[
 358     AC_MSG_CHECKING([for an Android system])
 359     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 360         [[#ifndef __ANDROID__
 361          # error Not Android
 362          #endif
 363         ]],[[;]])
 364     ],[
 365       HAVE_ANDROID="1"
 366       AC_MSG_RESULT([yes])
 367     ],[
 368       AC_MSG_RESULT([no])
 369     ])
 370 ])
 371 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 372
 373 dnl Tizen (minimum SDK version: 2.3)
 374 AS_IF([test "$SYS" = linux],[
 375     AC_MSG_CHECKING([for Tizen])
 376     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 377         [[#include <tizen.h>
 378         ]],[[;]])
 379     ],[
 380       HAVE_TIZEN="1"
 381       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
 382       AC_MSG_RESULT([yes])
 383     ],[
 384       AC_MSG_RESULT([no])
 385     ])
 386 ])
 387 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
 388
 389 dnl
 390 dnl  Check for the contrib directory
 391 dnl
 392 AC_ARG_WITH(contrib,
 393   [AS_HELP_STRING([--with-contrib[=DIR]],
 394     [search for 3rd party libraries in DIR/include and DIR/lib])
 395 ])
 396 AC_MSG_CHECKING([for 3rd party libraries path])
 397 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 398   CONTRIB_DIR="${srcdir}/contrib/${host}"
 399   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 400     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 401     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 402     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 403       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 404       CONTRIB_DIR=""
 405       AC_MSG_RESULT([not found])
 406     ])
 407   ])
 408 ], [
 409   AS_IF([test "${with_contrib}" != "no"], [
 410     CONTRIB_DIR="${with_contrib}"
 411   ], [
 412     CONTRIB_DIR=""
 413     AC_MSG_RESULT([disabled])
 414   ])
 415 ])
 416 AS_IF([test -n "${CONTRIB_DIR}"], [
 417   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 418     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 419   ], [
 420     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 421     CONTRIB_DIR=""
 422     AC_MSG_RESULT([not usable])
 423   ])
 424
 425 ])
 426 AS_IF([test -n "${CONTRIB_DIR}"], [
 427   AC_MSG_RESULT([${CONTRIB_DIR}])
 428   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 429   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 430   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 431   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
 432   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 433   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 434
 435   AS_IF([test -z "$LUAC"], [
 436     dnl Old contribs mixed cross-tools and cross-compiled executables
 437     AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
 438       LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
 439     ])
 440
 441     dnl Newer contribs follow usual name space rules
 442     AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
 443       LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
 444     ])
 445   ])
 446
 447   AS_IF([test "${SYS}" = "darwin"], [
 448     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 449     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 450   ])
 451 ], [
 452   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 453     AC_MSG_ERROR([Third party libraries not found!])
 454   ])
 455 ])
 456 AC_SUBST(CONTRIB_DIR)
 457
 458 dnl Add extras/tools to the PATH
 459 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 460 AS_IF([test -d "${TOOLS_DIR}"], [
 461     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 462     export PATH="${TOOLS_DIR}":$PATH
 463 ])
 464
 465 dnl
 466 dnl  Libtool
 467 dnl  It's very bad, but our former custom system was worst
 468 dnl  -- Courmisch
 469 dnl
 470
 471 dnl override platform specific check for dependent libraries
 472 dnl otherwise libtool linking of shared libraries will
 473 dnl fail on anything other than pass_all.
 474 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 475     [lt_cv_deplibs_check_method=pass_all])
 476
 477 LT_INIT([dlopen win32-dll shared disable-static])
 478 LT_LANG([C++])
 479 LT_LANG([Windows Resource])
 480
 481 DOLT
 482
 483 lt_cv_deplibs_check_method=pass_all
 484
 485 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 486   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 487 ])
 488
 489 dnl
 490 dnl Gettext stuff
 491 dnl
 492 AM_GNU_GETTEXT_VERSION([0.19.8])
 493 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 494
 495 dnl
 496 dnl Iconv stuff
 497 dnl
 498 AM_ICONV
 499
 500 dnl
 501 dnl checks for mingw
 502 AS_IF([test "${SYS}" = "mingw32"], [
 503
 504 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 505 #if !defined(__MINGW32__)
 506 # error Not compiling with mingw
 507 #endif
 508     ])], [
 509
 510 dnl Check for broken versions of mingw-runtime compatability library
 511     AC_MSG_CHECKING(for broken mingw-runtime)
 512     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 513 #include <_mingw.h>
 514 #if defined(__MINGW64_VERSION_MAJOR)
 515 # if __MINGW64_VERSION_MAJOR < 5
 516 #  error Update your mingw-w64! This one is too old.
 517 # endif
 518 #else
 519 # error You cannot compile with Mingw. Use Mingw-w64!
 520 #endif
 521     ])], [
 522         AC_MSG_RESULT([ok])
 523     ], [
 524         AC_MSG_RESULT([present])
 525         AC_MSG_ERROR([LibVLC requires Mingw-w64 version 5.0 or higher!])
 526     ])
 527
 528     dnl force use of mingw provided c99 *printf over msvcrt
 529     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 530
 531     dnl Check for the need to include the mingwex lib for mingw32
 532     VLC_SAVE_FLAGS
 533     AC_CHECK_LIB(mingwex,opendir,
 534         AC_CHECK_LIB(mingw32,opendir,,
 535             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 536     )
 537     VLC_RESTORE_FLAGS
 538     ], [
 539         AC_MSG_RESULT([Not compiling with mingw])
 540     ])
 541
 542     dnl Check for fnative-struct or mms-bitfields support for mingw32
 543     VLC_SAVE_FLAGS
 544     CFLAGS="${CFLAGS} -mms-bitfields"
 545     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
 546     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 547         [ac_cv_c_mms_bitfields],
 548         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 549     if test "${ac_cv_c_mms_bitfields}" = "no"; then
 550         VLC_RESTORE_FLAGS
 551         CFLAGS="${CFLAGS} -fnative-struct"
 552         CXXFLAGS="${CXXFLAGS} -fnative-struct"
 553         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 554             [ac_cv_c_fnative_struct],
 555             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 556         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
 557     fi
 558 ])
 559
 560
 561 dnl
 562 dnl Buggy glibc prevention. Purposedly not cached.
 563 dnl See sourceware.org bugs 5058 and 5443.
 564 dnl Ubuntu alone has 20 bug numbers for this...
 565 dnl
 566 AC_MSG_CHECKING(for buggy GNU/libc versions)
 567 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 568 #include <limits.h>
 569 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 570   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 571 # error GNU/libc with dcgettext killer bug!
 572 #endif
 573 ])], [
 574   AC_MSG_RESULT([not present])
 575 ], [
 576   AC_MSG_RESULT([found])
 577   AS_IF([test "x${enable_nls}" != "xno"], [
 578     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 579 work-around for this. Check with your distribution vendor on how to update the
 580 glibc run-time. Alternatively, build with --disable-nls.])
 581   ])
 582 ])
 583
 584 dnl Plugin compilation stuff
 585
 586 VLC_LIBRARY_SUFFIX
 587
 588 dnl Check for system libs needed
 589 need_libc=false
 590
 591 dnl Check for usual libc functions
 592 AC_CHECK_FUNCS([daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp strptime tdestroy uselocale])
 593 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv memrchr nrand48 poll recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tfind timegm timespec_get strverscmp pathconf])
 594 AC_REPLACE_FUNCS([gettimeofday])
 595 AC_CHECK_FUNC(fdatasync,,
 596   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 597 ])
 598
 599 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
 600
 601 dnl mingw64 implements those as static inline, not functions with C linkage
 602 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
 603 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
 604 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
 605 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
 606
 607 dnl C11 static_assert()
 608 AC_MSG_CHECKING([for static_assert in assert.h])
 609 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 610 static_assert(1, "The impossible happened.");
 611 ])], [
 612   AC_MSG_RESULT([yes])
 613   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 614 ], [
 615   AC_MSG_RESULT([no])
 616 ])
 617
 618 # Windows CE does not have strcoll()
 619 AC_FUNC_STRCOLL
 620
 621 dnl Check for non-standard system calls
 622 case "$SYS" in
 623   "linux")
 624     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity recvmmsg])
 625     ;;
 626   "mingw32")
 627     AC_CHECK_FUNCS([_lock_file])
 628     ;;
 629 esac
 630
 631 AH_BOTTOM([#include <vlc_fixups.h>])
 632
 633 dnl Check for struct pollfd
 634 AC_CHECK_TYPES([struct pollfd],,,
 635 [#include <sys/types.h>
 636 #if HAVE_POLL
 637 # include <poll.h>
 638 #elif defined (_WIN32)
 639 # include <winsock2.h>
 640 #endif
 641 ])
 642
 643 dnl Check for struct timespec
 644 AC_CHECK_TYPES([struct timespec],,,
 645 [#include <time.h>])
 646
 647 dnl Check for max_align_t
 648 AC_CHECK_TYPES([max_align_t],,,
 649 [#include <stddef.h>])
 650
 651 dnl Checks for socket stuff
 652 VLC_SAVE_FLAGS
 653 SOCKET_LIBS=""
 654 AC_SEARCH_LIBS(connect, [socket], [
 655   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 656     SOCKET_LIBS="$ac_cv_search_connect"
 657   ])
 658 ], [
 659   AS_IF([test "${SYS}" = "mingw32"], [
 660     SOCKET_LIBS="-lws2_32 -liphlpapi"
 661   ])
 662 ])
 663
 664 AC_SEARCH_LIBS([inet_pton], [nsl], [
 665  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
 666     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
 667   ])
 668 ],, [${SOCKET_LIBS}])
 669
 670 LIBS="${LIBS} ${SOCKET_LIBS}"
 671 AC_LINK_IFELSE([
 672     AC_LANG_PROGRAM([#ifdef _WIN32
 673         # if _WIN32_WINNT < 0x600
 674         #  error Needs vista+
 675         # endif
 676         #include <ws2tcpip.h>
 677         #else
 678         #include <sys/socket.h>
 679         #include <arpa/inet.h>
 680         #endif], [
 681         char dst[[sizeof(struct in_addr)]];
 682         inet_pton(AF_INET, "127.0.0.1", dst);
 683     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 684 AC_CHECK_FUNCS([if_nameindex])
 685 VLC_RESTORE_FLAGS
 686 AC_SUBST(SOCKET_LIBS)
 687
 688 dnl Check for socklen_t
 689 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 690 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 691 ac_cv_type_socklen_t,
 692 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 693 [#include <sys/types.h>
 694 #ifdef _WIN32
 695 # include <winsock2.h>
 696 # include <ws2tcpip.h>
 697 #else
 698 # include <sys/socket.h>
 699 #endif]], [[socklen_t len; len = 0;]])],
 700 ac_cv_type_socklen_t=yes,
 701 ac_cv_type_socklen_t=no)])
 702 AS_IF([test "$ac_cv_type_socklen_t" = no],
 703  [AC_DEFINE(socklen_t, int)])
 704
 705 dnl Check for struct sockaddr_storage
 706 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 707 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 708 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 709   [AC_TRY_COMPILE(
 710     [#include <sys/types.h>
 711      #if defined( _WIN32 )
 712      # include <winsock2.h>
 713      #else
 714      # include <sys/socket.h>
 715      #endif], [struct sockaddr_storage addr;],
 716      ac_cv_struct_sockaddr_storage=yes,
 717      ac_cv_struct_sockaddr_storage=no)])
 718 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 719   AC_DEFINE(sockaddr_storage, sockaddr)
 720   AC_DEFINE(ss_family, sa_family)
 721 ])
 722
 723 dnl FreeBSD has a gnugetopt library for this:
 724 GNUGETOPT_LIBS=""
 725 AC_CHECK_FUNC(getopt_long,, [
 726   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 727     GNUGETOPT_LIBS="-lgnugetopt"
 728   ])
 729 ])
 730 AC_SUBST(GNUGETOPT_LIBS)
 731
 732 AC_CHECK_LIB(m,cos,[
 733   LIBM="-lm"
 734 ], [
 735   LIBM=""
 736 ])
 737 AC_SUBST(LIBM)
 738
 739 AC_CHECK_LIB(m,lrintf, [
 740   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 741   VLC_ADD_LIBS([skins2],[-lm])
 742 ])
 743 AC_CHECK_LIB(m,nanf,
 744   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 745 )
 746 AC_CHECK_LIB(m,sincos, [
 747   AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
 748 ], [
 749   AC_LIBOBJ([sincos])
 750 ])
 751
 752 AC_MSG_CHECKING([_Thread_local support])
 753 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
 754                    int main() {}])], [
 755     AC_MSG_RESULT([ok])
 756     AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
 757 ],[ AC_MSG_RESULT([no])])
 758
 759 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
 760 dnl check for its availability explicitely
 761 AC_CHECK_HEADERS([threads.h])
 762
 763 AC_CHECK_LIB([anl],[getaddrinfo_a],[
 764   AC_DEFINE(HAVE_LIBANL, 1, [Define to 1 if you have the anl library])
 765 ])
 766
 767 dnl Check for dynamic plugins
 768 LIBDL=""
 769 have_dynamic_objects="no"
 770 VLC_SAVE_FLAGS
 771 AC_SEARCH_LIBS(dlsym, [dl svld], [
 772   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 773     LIBDL="$ac_cv_search_dlsym"
 774   ])
 775   have_dynamic_objects="yes"
 776 ])
 777 VLC_RESTORE_FLAGS
 778
 779 # Windows
 780 AS_IF([test "${SYS}" = "mingw32"], [
 781   LIBDL=""
 782   have_dynamic_objects="yes" #assume we can use shared objects
 783 ])
 784
 785 AC_ARG_WITH([libfuzzer],
 786     [AS_HELP_STRING([--with-libfuzzer=DIR],
 787         [use libFuzzer library from DIR and triggers sanitize coverage (default disabled)])],
 788      [],
 789      [with_libfuzzer=no])
 790 AS_VAR_IF(with_libfuzzer, no, [], [
 791     enable_shared=no
 792     enable_static=yes
 793     enable_vlc=no
 794 ])
 795 AM_CONDITIONAL(HAVE_LIBFUZZER, [test "${with_libfuzzer}" != "no"])
 796
 797 AS_IF([test "${enable_shared}" = "no"], [
 798   have_dynamic_objects=no
 799 ])
 800 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 801
 802 AC_SUBST(LIBDL)
 803
 804 dnl Check for thread library
 805 LIBPTHREAD=""
 806 AS_IF([test "${SYS}" != "mingw32"], [
 807   VLC_SAVE_FLAGS
 808   LIBS=""
 809   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 810     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 811       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 812     ])
 813   ])
 814   VLC_RESTORE_FLAGS
 815 ])
 816 AC_SUBST(LIBPTHREAD)
 817
 818 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
 819   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
 820     LIBRT="$ac_cv_search_clock_nanosleep"
 821   ])
 822 ], [
 823   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
 824     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
 825       LIBRT="$ac_cv_search_nanosleep"
 826     ])
 827   ])
 828 ])
 829 AC_SUBST(LIBRT)
 830
 831 dnl
 832 dnl Check for headers
 833 dnl
 834
 835 dnl  POSIX
 836 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
 837 AC_CHECK_HEADERS([net/if.h], [], [],
 838 [
 839 #include <sys/types.h>
 840 #include <sys/socket.h>
 841 ])
 842 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
 843 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
 844
 845 dnl  BSD
 846 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
 847
 848 dnl  GNU/Linux
 849 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 850
 851 dnl  MacOS
 852 AC_CHECK_HEADERS([xlocale.h])
 853
 854 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 855 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 856 AC_CHECK_TYPE(ssize_t,, [
 857   AC_DEFINE(ssize_t, int)
 858 ])
 859
 860 dnl It seems that autoconf detects pkg-config only during the first
 861 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 862 dnl it is nested within a conditional block, so it was not working right.
 863 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 864 AC_ARG_VAR(PKG_CONFIG_PATH,
 865        [Paths where to find .pc not at the default location])
 866 PKG_PROG_PKG_CONFIG()
 867
 868 dnl On some OS we need static linking
 869 AS_IF([test -n "${PKG_CONFIG}" ],[
 870     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 871         PKG_CONFIG="${PKG_CONFIG} --static"
 872     ])
 873 ])
 874
 875
 876 dnl
 877 dnl Check for zlib.h and -lz along with system -lminizip if available
 878 dnl
 879 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 880 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 881 if test "${have_zlib}" = "yes"
 882 then
 883   VLC_ADD_LIBS([sap],[-lz])
 884   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 885     AC_CHECK_HEADERS([unzip.h], [
 886       have_minizip=yes
 887       MINIZIP_LIBS="-lminizip -lz"
 888     ], [
 889       have_minizip=no
 890     ])
 891   ])
 892 fi
 893 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 894
 895
 896 dnl
 897 dnl Domain name i18n support via GNU libidn
 898 dnl
 899 PKG_CHECK_MODULES([IDN], [libidn], [
 900   have_libidn="yes"
 901   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 902 ], [
 903   have_libidn="no"
 904 ])
 905
 906
 907 dnl Check for dbus
 908 AC_ARG_ENABLE(dbus,
 909   [AS_HELP_STRING([--enable-dbus],
 910     [compile D-Bus message bus support (default enabled)])])
 911 have_dbus="no"
 912 AS_IF([test "${enable_dbus}" != "no"], [
 913   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 914     have_dbus="yes"
 915   ], [
 916     AS_IF([test -n "${enable_dbus}"], [
 917       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 918     ], [
 919       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 920     ])
 921   ])
 922 ])
 923 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 924
 925
 926 dnl Check for systemd
 927 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
 928   have_systemd="yes"
 929 ], [
 930   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
 931 ])
 932 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
 933
 934
 935 EXTEND_HELP_STRING([Optimization options:])
 936 dnl
 937 dnl  Compiler warnings
 938 dnl
 939
 940 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CFLAGS])
 941 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CXXFLAGS])
 942
 943 AX_APPEND_COMPILE_FLAGS([-Wbad-function-cast -Wwrite-strings -Wmissing-prototypes -Werror-implicit-function-declaration -Winit-self -Wlogical-op -Wshadow=local], [CFLAGS])
 944 AX_APPEND_COMPILE_FLAGS([-pipe], [CFLAGS])
 945
 946 dnl
 947 dnl  Debugging mode
 948 dnl
 949 AC_ARG_ENABLE(debug,
 950   [AS_HELP_STRING([--enable-debug],
 951     [build with run-time assertions (default disabled)])],,
 952   [enable_debug="no"])
 953 AH_TEMPLATE(NDEBUG,
 954             [Define to 1 if debug code should NOT be compiled])
 955 AS_IF([test "${enable_debug}" != "no"], [
 956   AC_CHECK_HEADERS([valgrind/valgrind.h])
 957 ], [
 958   AC_DEFINE(NDEBUG)
 959 ])
 960
 961 dnl
 962 dnl  Profiling
 963 dnl
 964 AC_ARG_ENABLE(gprof,
 965   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 966   [enable_gprof="no"])
 967 AS_IF([test "${enable_gprof}" != "no"], [
 968   CFLAGS="${CFLAGS} -pg"
 969   CXXFLAGS="${CXXFLAGS} -pg"
 970   OBJCFLAGS="${OBJCFLAGS} -pg"
 971   LDFLAGS="${LDFLAGS} -pg"
 972 ])
 973
 974 AC_ARG_ENABLE(cprof,
 975   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 976   [enable_cprof="no"])
 977 AS_IF([test "${enable_gprof}" != "no"], [
 978   CFLAGS="${CFLAGS} -finstrument-functions"
 979   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 980   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 981   LDFLAGS="${LDFLAGS} -finstrument-functions"
 982 ])
 983
 984 dnl
 985 dnl  Test coverage
 986 dnl
 987 AC_ARG_ENABLE(coverage,
 988   [AS_HELP_STRING([--enable-coverage],
 989     [build for test coverage (default disabled)])],,
 990   [enable_coverage="no"])
 991 AS_IF([test "${enable_coverage}" != "no"], [
 992   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 993   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 994   LDFLAGS="-lgcov ${LDFLAGS}"
 995 ])
 996
 997 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
 998   VLC_SAVE_FLAGS
 999   CFLAGS="${CFLAGS} -fvisibility=hidden"
1000   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
1001   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
1002   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
1003                  [ac_cv_c_visibility_hidden], [
1004     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1005       ac_cv_c_visibility_hidden=yes
1006     ], [
1007       ac_cv_c_visibility_hidden=no
1008     ])
1009   ])
1010   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1011 ])
1012
1013 dnl
1014 dnl Sanitizer flags
1015 dnl
1016 AC_ARG_WITH([sanitizer],
1017     [AS_HELP_STRING([--with-sanitizer=(address/memory/undefined/thread)],
1018         [build with sanitizer flags (default disabled)])],
1019      [],
1020      [with_sanitizer=no])
1021
1022 AS_VAR_IF(with_sanitizer, no, [], [
1023     AX_CHECK_COMPILE_FLAG([-fsanitize=${with_sanitizer}], [
1024         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}])
1025         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [CXXFLAGS])
1026         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [LDFLAGS])
1027     ], [
1028         AC_MSG_ERROR(["-fsanitize=${with_sanitizer} not supported!"])
1029     ])
1030     AX_APPEND_FLAG([-g])
1031     AX_APPEND_FLAG([-g], [CXXFLAGS])
1032
1033     AS_IF([test -z "${with_sanitizer##*address*}" ], [
1034        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer])
1035        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer], [CXXFLAGS])
1036     ])
1037     AS_IF([test -z "${with_sanitizer##*memory*}" ], [
1038         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1039         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1040     ])
1041     AS_IF([test -z "${with_sanitizer##*thread*}" ], [
1042         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1043         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1044     ])
1045 ])
1046
1047 dnl
1048 dnl  Enable/disable optimizations
1049 dnl
1050 AC_ARG_ENABLE(optimizations,
1051   [AS_HELP_STRING([--disable-optimizations],
1052     [disable compiler optimizations (default enabled)])],,
1053   [enable_optimizations="yes"])
1054
1055 dnl Check for various optimization flags
1056 AS_IF([test "${enable_optimizations}" != "no"], [
1057
1058   dnl -O3 only in production builds
1059   AS_IF([test "${enable_debug}" = "no"], [
1060     VLC_SAVE_FLAGS
1061     CFLAGS="${CFLAGS} -O3"
1062     CXXFLAGS="${CXXFLAGS} -O3"
1063     OBJCFLAGS="${OBJCFLAGS} -O3"
1064     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1065       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1066         ac_cv_c_o3=yes
1067       ], [
1068         ac_cv_c_o3=no
1069       ])
1070     ])
1071     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1072   ])
1073
1074   dnl Check for fast maths
1075   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CFLAGS])
1076   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CXXFLAGS])
1077
1078 AH_BOTTOM([
1079 #if defined(_MSC_VER) && !defined(__clang__)
1080 # pragma fenv_access(off)
1081 # pragma fp_contract(on)
1082 #elif defined(__GNUC__)
1083 /* Not supported so far */
1084 #else
1085 # pragma STDC FENV_ACCESS OFF
1086 # pragma STDC FP_CONTRACT ON
1087 #endif
1088 ])
1089
1090   dnl Check for -funroll-loops
1091   VLC_SAVE_FLAGS
1092   CFLAGS="${CFLAGS} -funroll-loops"
1093   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1094   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1095   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1096     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1097       ac_cv_c_unroll_loops=yes
1098     ], [
1099       ac_cv_c_unroll_loops=no
1100     ])
1101   ])
1102   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1103
1104   AS_IF([test "$enable_debug" = "no"], [
1105     dnl Check for -fomit-frame-pointer
1106     VLC_SAVE_FLAGS
1107     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1108     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1109     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1110     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1111       [ac_cv_c_omit_frame_pointer], [
1112       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1113         ac_cv_c_omit_frame_pointer=yes
1114       ], [
1115         ac_cv_c_omit_frame_pointer=no
1116       ])
1117     ])
1118     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1119   ])
1120
1121   AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong])
1122   AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong], [CXXFLAGS])
1123   dnl Win32 requires linking to ssp for stack-protection
1124   AS_IF([test "${SYS}" = "mingw32"], [
1125       LDFLAGS="${LDFLAGS} -lssp"
1126       AS_IF([test "${vlc_winstore_app}" != 1], [LDFLAGS="${LDFLAGS} -ladvapi32"])
1127   ])
1128 ])
1129
1130 VLC_SAVE_FLAGS
1131 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1132 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1133   AC_TRY_LINK([],, [
1134     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1135   ], [
1136     ac_cv_ld_bsymbolic=""
1137   ])
1138 ])
1139 VLC_RESTORE_FLAGS
1140 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1141 AC_SUBST(SYMBOLIC_LDFLAGS)
1142
1143 VLC_SAVE_FLAGS
1144 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1145 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1146   AC_TRY_LINK([],, [
1147     ac_cv_ld_z_defs="yes"
1148   ], [
1149     ac_cv_ld_z_defs="no"
1150   ])
1151 ])
1152 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1153
1154 dnl Check for __attribute__((packed))
1155 AC_CACHE_CHECK([for __attribute__((packed))],
1156   [ac_cv_c_attribute_packed],
1157   [ac_cv_c_attribute_packed=no
1158    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1159                     [ac_cv_c_attribute_packed=yes])])
1160 if test "${ac_cv_c_attribute_packed}" != "no"; then
1161   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1162 fi
1163
1164 dnl
1165 dnl  Check the CPU
1166 dnl
1167 case "${host_cpu}" in
1168   "")
1169     ARCH=unknown
1170     ;;
1171   *)
1172     ARCH="${host_cpu}"
1173     ;;
1174 esac
1175
1176 dnl Check for backtrace() support
1177 AC_CHECK_HEADERS(execinfo.h)
1178 AC_CHECK_FUNCS(backtrace)
1179
1180 dnl
1181 dnl  default modules
1182 dnl
1183 ALIASES="${ALIASES} cvlc rvlc"
1184
1185 dnl
1186 dnl  Accelerated modules
1187 dnl
1188
1189 dnl  Check for fully working MMX intrinsics
1190 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1191 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1192 AC_ARG_ENABLE(mmx,
1193   [AS_HELP_STRING([--disable-mmx],
1194     [disable MMX optimizations (default auto)])],,[
1195   case "${host_cpu}" in
1196     i?86|x86_64)
1197       enable_mmx="yes"
1198       ;;
1199     *)
1200       enable_mmx="no"
1201       ;;
1202   esac
1203 ])
1204 have_mmx="no"
1205 have_mmxext="no"
1206 AS_IF([test "${enable_mmx}" != "no"], [
1207   ARCH="${ARCH} mmx"
1208   VLC_SAVE_FLAGS
1209   CFLAGS="${CFLAGS} -mmmx"
1210   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1211     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1212 [#include <mmintrin.h>
1213 #include <stdint.h>
1214 uint64_t frobzor;]], [
1215 [__m64 a, b, c;
1216 a = b = c = (__m64)frobzor;
1217 a = _mm_slli_pi16(a, 3);
1218 a = _mm_adds_pi16(a, b);
1219 c = _mm_srli_pi16(c, 8);
1220 c = _mm_slli_pi16(c, 3);
1221 b = _mm_adds_pi16(b, c);
1222 a = _mm_unpacklo_pi8(a, b);
1223 frobzor = (uint64_t)a;]])], [
1224       ac_cv_c_mmx_intrinsics=yes
1225     ], [
1226       ac_cv_c_mmx_intrinsics=no
1227     ])
1228   ])
1229   VLC_RESTORE_FLAGS
1230   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1231     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1232   ])
1233
1234   VLC_SAVE_FLAGS
1235   CFLAGS="${CFLAGS} -mmmx"
1236   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1237     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1238 void *p;
1239 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1240 ]])
1241     ], [
1242       ac_cv_mmx_inline=yes
1243     ], [
1244       ac_cv_mmx_inline=no
1245     ])
1246   ])
1247   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1248     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1249     have_mmx="yes"
1250   ])
1251
1252   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1253                  [ac_cv_mmxext_inline], [
1254     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1255 void *p;
1256 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1257 ]])
1258     ], [
1259       ac_cv_mmxext_inline=yes
1260     ], [
1261       ac_cv_mmxext_inline=no
1262     ])
1263   ])
1264   VLC_RESTORE_FLAGS
1265   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1266     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1267     have_mmxext="yes"
1268   ])
1269 ])
1270 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1271 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1272
1273 dnl  Check for fully workin SSE2 intrinsics
1274 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1275 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1276 AC_ARG_ENABLE(sse,
1277   [AS_HELP_STRING([--disable-sse],
1278     [disable SSE (1-4) optimizations (default auto)])],, [
1279   case "${host_cpu}" in
1280     i?86|x86_64)
1281       enable_sse=yes
1282       ;;
1283     *)
1284       enable_sse=no
1285       ;;
1286   esac
1287 ])
1288 have_sse2="no"
1289 AS_IF([test "${enable_sse}" != "no"], [
1290   ARCH="${ARCH} sse sse2"
1291
1292   VLC_SAVE_FLAGS
1293   CFLAGS="${CFLAGS} -msse2"
1294   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1295     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1296 [#include <emmintrin.h>
1297 #include <stdint.h>
1298 uint64_t frobzor;]], [
1299 [__m128i a, b, c;
1300 a = b = c = _mm_set1_epi64((__m64)frobzor);
1301 a = _mm_slli_epi16(a, 3);
1302 a = _mm_adds_epi16(a, b);
1303 c = _mm_srli_epi16(c, 8);
1304 c = _mm_slli_epi16(c, 3);
1305 b = _mm_adds_epi16(b, c);
1306 a = _mm_unpacklo_epi8(a, b);
1307 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1308       ac_cv_c_sse2_intrinsics=yes
1309     ], [
1310       ac_cv_c_sse2_intrinsics=no
1311     ])
1312   ])
1313   VLC_RESTORE_FLAGS
1314   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1315     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1316   ])
1317
1318   VLC_SAVE_FLAGS
1319   CFLAGS="${CFLAGS} -msse"
1320   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1321     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1322 void *p;
1323 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1324 ]])
1325     ], [
1326       ac_cv_sse_inline=yes
1327     ], [
1328       ac_cv_sse_inline=no
1329     ])
1330   ])
1331
1332   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1333     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1334   ])
1335
1336   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1337     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1338 void *p;
1339 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1340 ]])
1341     ], [
1342       ac_cv_sse2_inline=yes
1343     ], [
1344       ac_cv_sse2_inline=no
1345     ])
1346   ])
1347   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1348     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1349     have_sse2="yes"
1350   ])
1351
1352   # SSE3
1353   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1354     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1355 void *p;
1356 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1357 ]])
1358     ], [
1359       ac_cv_sse3_inline=yes
1360     ], [
1361       ac_cv_sse3_inline=no
1362     ])
1363   ])
1364
1365   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1366     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1367   # SSSE3
1368   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1369     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1370 void *p;
1371 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1372 ]])
1373     ], [
1374       ac_cv_ssse3_inline=yes
1375     ], [
1376       ac_cv_ssse3_inline=no
1377     ])
1378   ])
1379
1380   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1381     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1382
1383   # SSE4.1
1384   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1385                  [ac_cv_sse4_1_inline], [
1386     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1387 void *p;
1388 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1389 ]])
1390     ], [
1391       ac_cv_sse4_1_inline=yes
1392     ], [
1393       ac_cv_sse4_1_inline=no
1394     ])
1395   ])
1396
1397   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1398     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1399
1400   # SSE4.2
1401   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1402                  [ac_cv_sse4_2_inline], [
1403     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1404 void *p;
1405 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1406 ]])
1407     ], [
1408       ac_cv_sse4_2_inline=yes
1409     ], [
1410       ac_cv_sse4_2_inline=no
1411     ])
1412   ])
1413
1414   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1415     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1416
1417   # SSE4A
1418   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1419     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1420 void *p;
1421 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1422 ]])
1423     ], [
1424       ac_cv_sse4a_inline=yes
1425     ], [
1426       ac_cv_sse4a_inline=no
1427     ])
1428   ])
1429   VLC_RESTORE_FLAGS
1430   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1431     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1432 ])
1433 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1434
1435 VLC_SAVE_FLAGS
1436 CFLAGS="${CFLAGS} -mmmx"
1437 have_3dnow="no"
1438 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1439   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1440 void *p;
1441 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1442 ]])
1443   ], [
1444     ac_cv_3dnow_inline=yes
1445   ], [
1446     ac_cv_3dnow_inline=no
1447   ])
1448 ])
1449 VLC_RESTORE_FLAGS
1450 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1451   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1452             [Define to 1 if 3D Now! inline assembly is available.])
1453   have_3dnow="yes"
1454 ])
1455 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1456
1457
1458 AC_ARG_ENABLE(neon,
1459   [AS_HELP_STRING([--disable-neon],
1460     [disable NEON optimizations (default auto)])],, [
1461   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1462 ])
1463 AS_IF([test "${enable_neon}" != "no"], [
1464   VLC_SAVE_FLAGS
1465   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1466   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1467     AC_COMPILE_IFELSE([
1468       AC_LANG_PROGRAM(,[[
1469 asm volatile("vqmovun.s64 d0, q1":::"d0");
1470 ]])
1471     ], [
1472       ac_cv_arm_neon="yes"
1473     ], [
1474       ac_cv_arm_neon="no"
1475     ])
1476   ])
1477   VLC_RESTORE_FLAGS
1478 ])
1479 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1480
1481 AC_ARG_ENABLE(arm64,
1482   [AS_HELP_STRING([--disable-arm64],
1483     [disable arm 64-bit optimizations (default auto)])],, [
1484   AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1485 ])
1486 AS_IF([test "${enable_arm64}" != "no"], [
1487   AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1488     AC_COMPILE_IFELSE([
1489       AC_LANG_PROGRAM(,[[
1490 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1491 ]])
1492     ], [
1493       ac_cv_arm64="yes"
1494     ], [
1495       ac_cv_arm64="no"
1496     ])
1497   ])
1498 ])
1499 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1500
1501
1502 AC_ARG_ENABLE(altivec,
1503   [AS_HELP_STRING([--disable-altivec],
1504     [disable AltiVec optimizations (default auto)])],, [
1505   AS_CASE("${host_cpu}", [powerpc*],
1506         [enable_altivec=yes], [enable_altivec=no])
1507 ])
1508 have_altivec="no"
1509 ALTIVEC_CFLAGS=""
1510 AS_IF([test "${enable_altivec}" = "yes"], [
1511   ARCH="${ARCH} altivec";
1512   VLC_SAVE_FLAGS
1513   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1514     [ac_cv_altivec_inline],
1515     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1516          ac_cv_altivec_inline="yes",
1517          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1518           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1519             [ac_cv_altivec_inline="-Wa,-maltivec"],
1520             ac_cv_altivec_inline=no)
1521          ])])
1522   VLC_RESTORE_FLAGS
1523   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1524     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1525               [Define to 1 if AltiVec inline assembly is available.])
1526     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1527       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1528       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1529     ])
1530     have_altivec="yes"
1531   ])
1532
1533   VLC_SAVE_FLAGS
1534   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1535   [ac_cv_c_altivec], [
1536     CFLAGS="${CFLAGS} -maltivec"
1537     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1538 [#include <altivec.h>]], [
1539 [vec_ld(0, (unsigned char *)0);]])], [
1540       ac_cv_c_altivec="-maltivec"
1541     ], [
1542       ac_cv_c_altivec="no"
1543     ])
1544   ])
1545   VLC_RESTORE_FLAGS
1546   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1547     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1548     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1549     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1550     ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1551     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1552     have_altivec="yes"
1553   ])
1554   AC_CHECK_HEADERS(altivec.h)
1555
1556   VLC_SAVE_FLAGS
1557   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1558   AC_CACHE_CHECK([if linker needs -framework vecLib],
1559     [ac_cv_ld_altivec],
1560     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1561   VLC_RESTORE_FLAGS
1562   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1563     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1564   ])
1565 ])
1566 AC_SUBST(ALTIVEC_CFLAGS)
1567 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1568
1569 dnl
1570 dnl  Memory usage
1571 dnl
1572 AC_ARG_ENABLE(optimize-memory,
1573   [AS_HELP_STRING([--enable-optimize-memory],
1574     [optimize memory usage over performance])])
1575 if test "${enable_optimize_memory}" = "yes"; then
1576   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1577 fi
1578
1579 dnl
1580 dnl Allow running as root (useful for people running on embedded platforms)
1581 dnl
1582 AC_ARG_ENABLE(run-as-root,
1583   [AS_HELP_STRING([--enable-run-as-root],
1584     [allow running VLC as root (default disabled)])])
1585 AS_IF([test "${enable_run_as_root}" = "yes"],[
1586     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1587               [Define to 1 to allow running VLC as root (uid 0).])
1588 ])
1589
1590 dnl
1591 dnl Stream output
1592 dnl
1593 AC_ARG_ENABLE(sout,
1594   [AS_HELP_STRING([--disable-sout],
1595     [disable streaming output (default enabled)])])
1596 AS_IF([test "${enable_sout}" != "no"], [
1597   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1598 ])
1599 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1600
1601 dnl Lua modules
1602 AC_ARG_ENABLE(lua,
1603   [AS_HELP_STRING([--disable-lua],
1604     [disable LUA scripting support (default enabled)])])
1605 if test "${enable_lua}" != "no"
1606 then
1607   PKG_CHECK_MODULES(LUA, lua5.2,
1608     [ have_lua=yes ],
1609     [
1610     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1611
1612     PKG_CHECK_MODULES(LUA, lua5.1,
1613       [ have_lua=yes ],
1614       [
1615       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1616       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1617         [ have_lua=yes ],
1618         [
1619           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1620           have_lua=yes
1621           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1622             [],
1623             [ have_lua=no ] )
1624           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1625             [LUA_LIBS="-llua5.2"],
1626           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1627             [LUA_LIBS="-llua5.1"],
1628             AC_CHECK_LIB( lua51 , luaL_newstate,
1629               [LUA_LIBS="-llua51"],
1630               AC_CHECK_LIB( lua , luaL_newstate,
1631                 [LUA_LIBS="-llua"],
1632                 [ have_lua=no
1633                 ], [-lm])
1634             )))
1635         ])
1636       ])
1637     ])
1638   if test "x${have_lua}" != "xyes" ;  then
1639       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1640   fi
1641   AC_ARG_VAR([LUAC], [LUA byte compiler])
1642   AS_IF([test -z "$LUAC"], [
1643      AC_CHECK_TOOL(LUAC, [luac], [false])
1644   ])
1645   AS_IF([test "${LUAC}" = "false"], [
1646     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1647   ])
1648   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1649     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1650   ])
1651 fi
1652 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1653
1654
1655 dnl
1656 dnl VideoLAN manager
1657 dnl
1658 AC_ARG_ENABLE(vlm,
1659   [AS_HELP_STRING([--disable-vlm],
1660     [disable the stream manager (default enabled)])],,
1661   [enable_vlm="${enable_sout}"])
1662 AS_IF([test "${enable_vlm}" != "no"], [
1663   AS_IF([test "${enable_sout}" = "no"], [
1664     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1665   ])
1666   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1667 ])
1668 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1669
1670
1671 dnl
1672 dnl Addons manager storage and repositories modules
1673 dnl
1674 AC_ARG_ENABLE(addonmanagermodules,
1675   [AS_HELP_STRING([--disable-addonmanagermodules],
1676     [disable the addons manager modules (default enabled)])])
1677 if test "${enable_addonmanagermodules}" != "no"
1678 then
1679   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1680 fi
1681 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1682
1683
1684 dnl
1685 dnl  Input plugins
1686 dnl
1687
1688 EXTEND_HELP_STRING([Input plugins:])
1689
1690 dnl
1691 dnl  libarchive access module
1692 dnl
1693 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1694
1695 dnl
1696 dnl  live555 input
1697 dnl
1698 AC_ARG_ENABLE(live555,
1699   [AS_HELP_STRING([--enable-live555],
1700     [enable RTSP input through live555 (default enabled)])])
1701
1702 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1703   PKG_CHECK_MODULES(LIVE555, live555, [
1704     VLC_ADD_PLUGIN([live555])
1705     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1706     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1707   ], [
1708     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1709
1710     AC_LANG_PUSH(C++)
1711     VLC_SAVE_FLAGS
1712
1713     dnl detect include paths
1714     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1715       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1716     ], [
1717       AS_IF([test "${SYS}" != "os2"], [
1718         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1719         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1720       ], [
1721         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1722         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1723         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1724       ])
1725     ])
1726
1727     dnl CPP Flags
1728     AS_IF([test "${SYS}" = "solaris"], [
1729       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1730     ])
1731     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1732     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1733
1734     dnl version check
1735     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1736       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1737 [#include <liveMedia_version.hh>
1738 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1739 # error BOOM
1740 #endif]])
1741       ], [
1742         ac_cv_live555="yes"
1743       ], [
1744         ac_cv_live555="no"
1745       ])
1746     ])
1747
1748     AS_IF([test "$ac_cv_live555" = "no"], [
1749       AC_MSG_WARN([live555 is missing or its installed version is too old:
1750 Version 2011.12.23 or later is required to proceed.
1751 You can get an updated one from http://www.live555.com/liveMedia .])
1752       AS_IF([test -n "${enable_live555}"], [
1753         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1754       ])
1755     ], [
1756       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1757       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1758       AS_IF([test "${SYS}" = "mingw32"], [
1759         # add ws2_32 for closesocket, select, recv
1760         other_libs="$other_libs -lws2_32"
1761       ])
1762
1763       dnl We need to check for pic because live555 don't provide shared libs
1764       dnl and we want to build a plugins so we need -fPIC on some arch.
1765       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1766       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1767       AC_CHECK_LIB(liveMedia_pic, main, [
1768         VLC_ADD_PLUGIN([live555])
1769         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1770       ],[
1771         AC_CHECK_LIB(liveMedia, main, [
1772           VLC_ADD_PLUGIN([live555])
1773           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1774         ],[],[${other_libs}])
1775       ],[${other_libs_pic}])
1776     ])
1777     VLC_RESTORE_FLAGS
1778     AC_LANG_POP(C++)
1779   ])
1780 ])
1781
1782 dnl
1783 dnl IIDC and DV FireWire input modules
1784 dnl
1785 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1786 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1787
1788 dnl
1789 dnl - linsys modules: access module check for libzvbi
1790 dnl
1791 AC_ARG_ENABLE(linsys,
1792   [AS_HELP_STRING([--enable-linsys],
1793     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1794 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1795   VLC_ADD_PLUGIN([linsys_hdsdi])
1796   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1797     VLC_ADD_PLUGIN([linsys_sdi])
1798   ], [
1799     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1800   ])
1801 ])
1802
1803 dnl
1804 dnl dvdread module: check for libdvdread
1805 dnl
1806 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1807
1808 dnl
1809 dnl libdvdnav plugin
1810 dnl
1811 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1812 AS_IF([test "${enable_dvdnav}" != "no"], [
1813   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1814     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1815       AC_MSG_RESULT(yes)
1816       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1817       ],[
1818       AC_MSG_RESULT(no)
1819     ])
1820 ])
1821
1822 dnl
1823 dnl  Blu-ray Disc Support with libbluray
1824 dnl
1825 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1826
1827 dnl
1828 dnl  OpenCV wrapper and example filters
1829 dnl
1830 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1831
1832
1833 dnl
1834 dnl  libsmbclient plugin
1835 dnl
1836 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1837 AS_IF([test "${SYS}" = "mingw32" -a "${enable_winstore_app}" != "yes"], [ VLC_ADD_PLUGIN([smb]) ])
1838
1839 dnl
1840 dnl  liBDSM access module
1841 dnl
1842 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1843
1844 dnl
1845 dnl sftp access support
1846 dnl
1847 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1848
1849 dnl
1850 dnl nfs access support
1851 dnl
1852 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1853
1854 dnl
1855 dnl  Video4Linux 2
1856 dnl
1857 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1858   [disable Video4Linux version 2 (default auto)])])
1859 have_v4l2="no"
1860 AS_IF([test "$enable_v4l2" != "no"], [
1861   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1862     have_v4l2="yes"
1863   ])
1864 ])
1865 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1866
1867 dnl
1868 dnl special access module for Blackmagic SDI cards
1869 dnl
1870 AC_ARG_ENABLE(decklink,
1871   [AS_HELP_STRING([--disable-decklink],
1872     [disable Blackmagic DeckLink SDI input (default auto)])])
1873 AC_ARG_WITH(decklink_sdk,
1874   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1875     [                        location of Blackmagic DeckLink SDI SDK])])
1876 have_decklink=no
1877 if test "${enable_decklink}" != "no"
1878 then
1879   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1880   then
1881     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1882   fi
1883   VLC_SAVE_FLAGS
1884   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1885   AC_LANG_PUSH(C++)
1886   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1887       have_decklink=yes
1888   ], [
1889       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1890   ])
1891   AC_LANG_POP(C++)
1892   VLC_RESTORE_FLAGS
1893 fi
1894 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1895
1896
1897 dnl
1898 dnl  Built-in CD-DA and VCD module
1899 dnl
1900 AC_ARG_ENABLE(vcd,
1901   [AS_HELP_STRING([--disable-vcd],
1902     [disable built-in VCD and CD-DA support (default enabled)])])
1903
1904 AC_ARG_ENABLE(libcddb,
1905   [AS_HELP_STRING([--disable-libcddb],
1906     [disable CDDB for Audio CD (default enabled)])])
1907
1908 if test "${enable_vcd}" != "no"
1909 then
1910   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1911   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1912     AC_MSG_RESULT(yes)
1913     VLC_ADD_PLUGIN([vcd cdda])
1914   ],[
1915     AC_MSG_RESULT(no)
1916   ])
1917
1918   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1919   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1920     AC_MSG_RESULT(yes)
1921     VLC_ADD_PLUGIN([vcd cdda])
1922     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1923   ],[
1924     AC_MSG_RESULT(no)
1925   ])
1926
1927   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1928   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1929     AC_MSG_RESULT(yes)
1930     VLC_ADD_PLUGIN([vcd cdda])
1931     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1932   ],[
1933     AC_MSG_RESULT(no)
1934   ])
1935
1936   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1937   then
1938     VLC_ADD_PLUGIN([vcd cdda])
1939   fi
1940
1941   if test "$enable_libcddb" != "no"; then
1942     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1943       HAVE_LIBCDDB=yes
1944       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1945       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1946       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1947       ],:
1948       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1949       HAVE_LIBCDDB=no])
1950   fi
1951 fi
1952
1953 dnl
1954 dnl Linux DVB
1955 dnl
1956 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1957   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1958 [#include <linux/dvb/version.h>
1959 #if (DVB_API_VERSION < 5)
1960 # error Linux DVB API v3.2 and older are not supported.
1961 #endif
1962 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1963 # error Linux DVB API v5.0 is unsupported. Please update.
1964 #endif
1965 ]])], [
1966   ac_cv_linux_dvb_5_1=yes
1967 ], [
1968   ac_cv_linux_dvb_5_1=no
1969 ])])
1970 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1971
1972 dnl
1973 dnl  Screen capture module
1974 dnl
1975 AC_ARG_ENABLE(screen,
1976   [AS_HELP_STRING([--enable-screen],
1977     [disable screen capture (default enabled)])])
1978 if test "${enable_screen}" != "no"; then
1979   if test "${SYS}" = "darwin"; then
1980     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1981       VLC_ADD_PLUGIN([screen])
1982     ])
1983   fi
1984 fi
1985 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1986
1987 dnl
1988 dnl  VNC/RFB access module
1989 dnl
1990 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1991
1992 dnl  RDP/Remote Desktop access module
1993 dnl
1994 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1995
1996 dnl
1997 dnl  Real RTSP plugin
1998 dnl
1999 AC_ARG_ENABLE(realrtsp,
2000   [  --enable-realrtsp       Real RTSP module (default disabled)])
2001 if test "${enable_realrtsp}" = "yes"; then
2002   VLC_ADD_PLUGIN([access_realrtsp])
2003 fi
2004
2005 dnl
2006 dnl QTKit
2007 AC_ARG_ENABLE(macosx-qtkit,
2008   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
2009 if test "x${enable_macosx_qtkit}" != "xno" &&
2010   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
2011 then
2012   AC_CHECK_HEADERS(QTKit/QTKit.h, [
2013       VLC_ADD_PLUGIN([qtsound])
2014     ])
2015 fi
2016
2017 dnl
2018 dnl AVFoundation
2019 AC_SUBST(have_avfoundation, ["no"])
2020 AC_ARG_ENABLE(macosx-avfoundation,
2021   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
2022 if test "x${enable_macosx_avfoundation}" != "xno" &&
2023   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2024 then
2025   SAVED_LIBS="${LIBS}"
2026   LIBS="-framework AVFoundation"
2027   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2028   LIBS="${SAVED_LIBS}"
2029   if test "${have_avfoundation}" != "no"
2030   then
2031     VLC_ADD_PLUGIN([avcapture])
2032   fi
2033 fi
2034 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2035
2036 dnl
2037 dnl  DCP plugin (using asdcplib)
2038 dnl
2039 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2040 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2041
2042 dnl
2043 dnl  Demux plugins
2044 dnl
2045
2046 EXTEND_HELP_STRING([Mux/Demux plugins:])
2047
2048 dnl
2049 dnl  libdvbpsi check for ts mux/demux
2050 dnl
2051 have_dvbpsi="no"
2052 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2053 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2054
2055
2056 dnl
2057 dnl  GME demux plugin
2058 dnl
2059 AC_ARG_ENABLE(gme,
2060   [AS_HELP_STRING([--enable-gme],
2061     [use Game Music Emu (default auto)])])
2062 AS_IF([test "${enable_gme}" != "no"], [
2063   AC_CHECK_HEADER([gme/gme.h], [
2064     AC_CHECK_LIB([gme], [gme_identify_header], [
2065       VLC_ADD_PLUGIN([gme])
2066     ], [
2067       AC_CHECK_LIB([gme], [gme_identify_extension], [
2068          VLC_ADD_LIBS([gme], [-lstdc++ $LIBM])
2069          VLC_ADD_PLUGIN([gme])
2070       ],, [-lstdc++ $LIBM])
2071     ])
2072     VLC_ADD_LIBS([gme], [-lgme])
2073   ], [
2074     AS_IF([test "x${enable_gme}" != "x"], [
2075       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2076     ])
2077   ])
2078 ])
2079
2080
2081 dnl
2082 dnl  SIDPlay plugin
2083 dnl
2084 AC_ARG_ENABLE(sid,
2085     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2086 AS_IF([test "${enable_sid}" != "no"], [
2087     PKG_CHECK_MODULES(SID, [libsidplay2], [
2088         AC_LANG_PUSH(C++)
2089         oldCPPFLAGS="$CPPFLAGS"
2090         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2091         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2092             VLC_ADD_PLUGIN([sid])
2093             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2094             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2095         ], [
2096             AS_IF([test -n "${enable_sid}"],
2097                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2098                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2099                 )
2100         ])
2101         CPPFLAGS="$oldCPPFLAGS"
2102         AC_LANG_POP(C++)
2103     ], [
2104         AS_IF([test "x${enable_sid}" = "xyes"],
2105             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2106             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2107             )
2108     ])
2109 ])
2110
2111
2112 dnl
2113 dnl  ogg demux plugin
2114 dnl
2115 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2116 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2117     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2118 ],[true])
2119 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2120 if test "${enable_sout}" != "no"; then
2121 dnl Check for libshout
2122     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2123 fi
2124
2125 dnl
2126 dnl  matroska demux plugin
2127 dnl
2128 PKG_ENABLE_MODULES_VLC([MATROSKA], [mkv], [libebml libmatroska], [MKV format support], [auto])
2129
2130 dnl
2131 dnl  modplug demux plugin
2132 dnl
2133 AC_ARG_ENABLE(mod,
2134   [AS_HELP_STRING([--disable-mod],
2135     [do not use libmodplug (default auto)])])
2136 if test "${enable_mod}" != "no" ; then
2137     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2138           VLC_ADD_PLUGIN([mod])
2139           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2140           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2141           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2142     ],[
2143        AS_IF([test -n "${enable_mod}"],
2144          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2145          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2146     ])
2147 fi
2148
2149 dnl
2150 dnl  mpc demux plugin
2151 dnl
2152 AC_ARG_ENABLE(mpc,
2153   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2154 if test "${enable_mpc}" != "no"
2155 then
2156   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2157     VLC_ADD_PLUGIN([mpc])
2158     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2159     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2160     VLC_ADD_PLUGIN([mpc])
2161     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2162 fi
2163
2164 dnl
2165 dnl  Codec plugins
2166 dnl
2167
2168 EXTEND_HELP_STRING([Codec plugins:])
2169
2170 dnl
2171 dnl wmafixed plugin
2172 dnl
2173 AC_ARG_ENABLE(wma-fixed,
2174   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2175 if test "${enable_wma_fixed}" = "yes"
2176 then
2177   VLC_ADD_PLUGIN([wma_fixed])
2178 fi
2179
2180 dnl
2181 dnl shine encoder plugin
2182 dnl
2183 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2184
2185
2186 dnl
2187 dnl openmax il codec plugin
2188 dnl
2189 AC_ARG_ENABLE(omxil,
2190   [  --enable-omxil          openmax il codec module (default disabled)])
2191 if test "${enable_omxil}" = "yes"
2192 then
2193   VLC_ADD_PLUGIN([omxil])
2194 fi
2195
2196 dnl
2197 dnl openmax il vout plugin
2198 dnl
2199 AC_ARG_ENABLE(omxil-vout,
2200   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2201 if test "${enable_omxil_vout}" = "yes"
2202 then
2203   VLC_ADD_PLUGIN([omxil_vout])
2204 fi
2205
2206 dnl
2207 dnl raspberry pi openmax il configuration
2208 dnl
2209 AC_ARG_ENABLE(rpi-omxil,
2210   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2211 if test "${enable_rpi_omxil}" = "yes"
2212 then
2213   VLC_ADD_PLUGIN([omxil omxil_vout])
2214   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2215 fi
2216
2217 dnl
2218 dnl CrystalHD codec plugin
2219 dnl
2220 AC_ARG_ENABLE(crystalhd,
2221   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2222 if test "${enable_crystalhd}" != "no"; then
2223     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2224       VLC_ADD_PLUGIN([crystalhd])
2225       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2226     ],[
2227       if test "${SYS}" = "mingw32" ; then
2228         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2229           VLC_ADD_PLUGIN([crystalhd])
2230           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2231             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2232             ])
2233         ],[
2234           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2235                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2236                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2237         ],[#define __LINUX_USER__
2238                #include <libcrystalhd/bc_dts_types.h>
2239         ])
2240       fi
2241     ],[
2242        #include <libcrystalhd/bc_dts_types.h>
2243       ])
2244 fi
2245
2246 dnl
2247 dnl  mad plugin
2248 dnl
2249 have_mad="no"
2250 MAD_CFLAGS=""
2251 MAD_LIBS=""
2252
2253 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2254   enable_mad="yes"
2255 ], [
2256   with_mad="no"
2257 ])
2258 AS_IF([test "${with_mad}" != "no"], [
2259   MAD_CFLAGS="-I${with_mad}/include"
2260   MAD_LIBS="-L${with_mad}/lib"
2261 ])
2262
2263 AC_ARG_ENABLE(mad,
2264   [  --enable-mad            libmad module (default enabled)])
2265 AS_IF([test "${enable_mad}" != "no"], [
2266   VLC_SAVE_FLAGS
2267   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2268   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2269   AC_CHECK_HEADERS(mad.h, [
2270     AC_CHECK_LIB(mad, mad_bit_init, [
2271       have_mad="yes"
2272       MAD_LIBS="${MAD_LIBS} -lmad"
2273     ])
2274   ])
2275   VLC_RESTORE_FLAGS
2276   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2277     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2278   ])
2279 ])
2280 AC_SUBST(MAD_CFLAGS)
2281 AC_SUBST(MAD_LIBS)
2282 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2283
2284 dnl  mpg123 plugin
2285 dnl
2286 dnl
2287 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2288
2289 dnl
2290 dnl gstreamer stuff
2291 dnl
2292 AC_ARG_ENABLE(gst-decode,
2293   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2294
2295 have_gst_decode="no"
2296 AS_IF([test "${enable_gst_decode}" != "no"], [
2297   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2298     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2299       have_gst_decode="yes"
2300     ], [
2301       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2302     ])
2303   ], [
2304     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2305   ])
2306 ])
2307 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2308
2309 dnl
2310 dnl  avcodec decoder/encoder plugin
2311 dnl
2312 AC_ARG_ENABLE(merge-ffmpeg,
2313 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2314   enable_merge_ffmpeg="no"
2315 ])
2316 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2317
2318 AC_MSG_CHECKING([for libavutil variant])
2319 PKG_CHECK_EXISTS([libavutil], [
2320   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2321   libavutil_micro="${libavutil_version##*.}"
2322   AS_IF([test ${libavutil_micro} -le 99], [
2323     avfork="libav"
2324   ], [
2325     avfork="ffmpeg"
2326   ])
2327 ], [
2328   avfork="none"
2329 ])
2330 AC_MSG_RESULT([${avfork}])
2331
2332 AC_ARG_ENABLE(avcodec,
2333 [  --enable-avcodec        libavcodec codec (default enabled)])
2334 AS_IF([test "${enable_avcodec}" != "no"], [
2335   dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2336   case "${avfork}" in
2337     libav) av_codec_ver="57.16.0" ;;
2338     ffmpeg) av_codec_ver="57.37.100" ;;
2339     *) AC_MSG_ERROR([Missing libav or FFmpeg. Pass --disable-avcodec to ignore this error.])
2340   esac
2341   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2342     VLC_SAVE_FLAGS
2343     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2344     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2345     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2346     AC_CHECK_HEADERS(libavutil/avutil.h)
2347     VLC_RESTORE_FLAGS
2348     have_avcodec="yes"
2349   ],[
2350     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2351   ])
2352 ], [
2353   have_avcodec="no"
2354 ])
2355 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2356
2357 dnl
2358 dnl libva needs avcodec
2359 dnl
2360 AC_ARG_ENABLE(libva,
2361   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2362
2363 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2364   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2365 ])
2366
2367 have_vaapi="no"
2368 have_vaapi_drm="no"
2369 have_vaapi_x11="no"
2370 have_vaapi_wl="no"
2371 AS_IF([test "${enable_libva}" != "no"], [
2372   PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2373     have_vaapi="yes"
2374   ], [
2375     AS_IF([test -n "${enable_libva}"], [
2376       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2377     ], [
2378       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2379     ])
2380   ])
2381   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2382     have_vaapi_drm="yes"
2383   ], [
2384     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2385   ])
2386   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2387     have_vaapi_x11="yes"
2388   ], [
2389     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2390   ])
2391   PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2392     have_vaapi_wl="yes"
2393   ], [
2394     AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2395   ])
2396 ])
2397 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2398 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2399 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2400 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2401
2402 have_avcodec_vaapi="no"
2403 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2404   VLC_SAVE_FLAGS
2405   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2406   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2407   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2408     AC_MSG_NOTICE([VA API acceleration activated])
2409     have_avcodec_vaapi="yes"
2410   ],[
2411     AS_IF([test -n "${enable_libva}"], [
2412       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2413     ], [
2414       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2415     ])
2416   ])
2417   VLC_RESTORE_FLAGS
2418 ])
2419 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2420
2421 dnl
2422 dnl dxva2 needs avcodec
2423 dnl
2424 AC_ARG_ENABLE(dxva2,
2425   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2426
2427 have_avcodec_dxva2="no"
2428 AS_IF([test "${enable_dxva2}" != "no"], [
2429   if test "${SYS}" = "mingw32"; then
2430   AS_IF([test "x${have_avcodec}" = "xyes"], [
2431     AC_CHECK_HEADERS(dxva2api.h,
2432       [
2433         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2434            AC_MSG_NOTICE([DxVA2 acceleration activated])
2435            have_avcodec_dxva2="yes"
2436         ],[
2437     AS_IF([test "${enable_dxva2}" = "yes"],
2438           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2439               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2440         ], [#undef _WIN32_WINNT
2441             /* DXVA2 is only available in Vista and above */
2442             #define _WIN32_WINNT 0x600])
2443       ],[
2444     AS_IF([test "${enable_dxva2}" = "yes"],
2445               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2446               [AC_MSG_WARN([dxva2api.h not found])])
2447       ],[#include <d3d9.h>])
2448   ],[
2449     AS_IF([test "x${enable_dxva2}" != "x"], [
2450       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2451     ])
2452   ])
2453   fi
2454 ])
2455 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2456
2457 dnl
2458 dnl d3d11va needs avcodec
2459 dnl
2460 AC_ARG_ENABLE(d3d11va,
2461   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2462
2463 have_avcodec_d3d11va="no"
2464 AS_IF([test "${enable_d3d11va}" != "no"], [
2465   if test "${SYS}" = "mingw32"; then
2466   AS_IF([test "x${have_avcodec}" = "xyes"], [
2467         AC_CHECK_TYPES([ID3D11VideoDecoder],
2468           [
2469             AC_CHECK_HEADERS(dxva2api.h,
2470               [
2471                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2472                    AC_MSG_NOTICE([D3D11 acceleration activated])
2473                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2474                    have_avcodec_d3d11va="yes"
2475                 ],[
2476                   AS_IF([test "${enable_d3d11va}" = "yes"],
2477                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2478                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2479                   ], [#undef _WIN32_WINNT
2480                       /* D3D11 is only available in Vista and above */
2481                       #define _WIN32_WINNT 0x600])
2482                   ],[
2483                     AS_IF([test "${enable_d3d11va}" = "yes"],
2484                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2485                           [AC_MSG_WARN([dxva2api.h not found])])
2486                   ],[#include <d3d9.h>])
2487           ],[
2488             AS_IF([test "${enable_d3d11va}" = "yes"],
2489                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2490                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2491           ], [#include <d3d11.h>])
2492   ],[
2493     AS_IF([test "x${enable_d3d11va}" != "x"], [
2494       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2495     ])
2496   ])
2497   fi
2498 ])
2499 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2500
2501 dnl
2502 dnl DXGI debug
2503 dnl
2504 AC_CHECK_HEADERS(dxgidebug.h dxgi1_6.h)
2505
2506 dnl
2507 dnl  avformat demuxer/muxer plugin
2508 dnl
2509
2510 AC_ARG_ENABLE(avformat,
2511 [  --enable-avformat       libavformat containers (default enabled)],, [
2512   enable_avformat="${have_avcodec}"
2513 ])
2514 have_avformat="no"
2515 AS_IF([test "${enable_avformat}" != "no"], [
2516   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2517       have_avformat="yes"
2518       VLC_SAVE_FLAGS
2519       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2520       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2521       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2522       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2523       AC_CHECK_HEADERS(libavutil/avutil.h)
2524       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2525         have_avformat="no"
2526       ])
2527       VLC_RESTORE_FLAGS
2528     ],[
2529       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2530   ])
2531 ])
2532 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2533
2534 dnl
2535 dnl  swscale image scaling and conversion plugin
2536 dnl
2537
2538 AC_ARG_ENABLE(swscale,
2539   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2540           (default enabled)]))
2541 if test "${enable_swscale}" != "no"
2542 then
2543   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2544     [
2545       VLC_SAVE_FLAGS
2546       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2547       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2548       AC_CHECK_HEADERS(libswscale/swscale.h)
2549       AC_CHECK_HEADERS(libavutil/avutil.h)
2550       VLC_ADD_PLUGIN([swscale])
2551       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2552       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2553       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2554         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2555       ])
2556       VLC_RESTORE_FLAGS
2557     ],[
2558       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2559   ])
2560 fi
2561
2562 dnl
2563 dnl  postproc plugin
2564 dnl
2565
2566 AC_ARG_ENABLE(postproc,
2567 [  --enable-postproc       libpostproc image post-processing (default auto)])
2568 if test "${enable_postproc}" != "no"
2569 then
2570   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2571     [
2572       VLC_SAVE_FLAGS
2573       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2574       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2575       AC_CHECK_HEADERS(postproc/postprocess.h)
2576       VLC_ADD_PLUGIN([postproc])
2577       VLC_RESTORE_FLAGS
2578     ],[
2579       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2580   ])
2581 fi
2582
2583 dnl
2584 dnl  faad decoder plugin
2585 dnl
2586 AC_ARG_ENABLE(faad,
2587 [  --enable-faad           faad codec (default auto)])
2588 have_faad="no"
2589 AS_IF([test "${enable_faad}" != "no"], [
2590   AC_CHECK_HEADERS([neaacdec.h], [
2591     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2592
2593     AS_IF([test "${have_faad}" = "yes"], [
2594       VLC_ADD_PLUGIN([faad])
2595       VLC_ADD_LIBS([faad],[-lfaad])
2596     ], [
2597       AS_IF([test "${enable_faad}" = "yes"], [
2598         AC_MSG_ERROR([cannot find FAAD library])
2599       ], [
2600         AC_MSG_WARN([cannot find FAAD library])
2601       ])
2602     ])
2603   ])
2604 ])
2605
2606 dnl
2607 dnl  AOM decoder plugin
2608 dnl
2609 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec (default auto)])
2610
2611 dnl
2612 dnl libvpx decoder plugin
2613 dnl
2614 AC_ARG_ENABLE(vpx,
2615     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2616 AS_IF([test "${enable_vpx}" != "no"],[
2617     PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2618         VLC_ADD_PLUGIN([vpx])
2619         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2620         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2621         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2622             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2623         ], [], [${VPX_LIBS}])
2624         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2625             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2626         ], [], [${VPX_LIBS}])
2627         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2628             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2629         ], [], [${VPX_LIBS}])
2630         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2631             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2632         ], [], [${VPX_LIBS}])
2633     ], [
2634     AS_IF([test "${enable_vpx}" = "yes"],[
2635         AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2636     ])])
2637 ])
2638
2639 dnl
2640 dnl twolame encoder plugin
2641 dnl
2642 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2643
2644 dnl
2645 dnl fdk-aac encoder plugin
2646 dnl
2647 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2648
2649
2650 dnl
2651 dnl A52/AC3 decoder plugin
2652 dnl
2653 AC_ARG_ENABLE(a52,
2654   [  --enable-a52            A/52 support with liba52 (default enabled)])
2655 if test "${enable_a52}" != "no"
2656 then
2657   AC_ARG_WITH(a52,
2658     [  --with-a52=PATH         a52 headers and libraries])
2659     if test -z "${with_a52}"
2660     then
2661       LDFLAGS_test=""
2662       CPPFLAGS_test=""
2663     else
2664       LDFLAGS_test="-L${with_a52}/lib"
2665       CPPFLAGS_test="-I${with_a52}/include"
2666     fi
2667     VLC_SAVE_FLAGS
2668     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2669     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2670     AC_CHECK_HEADERS(a52dec/a52.h, [
2671       AC_CHECK_LIB(a52, a52_free, [
2672         VLC_ADD_PLUGIN([a52])
2673         VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2674         VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2675       ],[
2676         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2677         ], [$LIBM])
2678     ],[
2679       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2680     ])
2681     VLC_RESTORE_FLAGS
2682 fi
2683
2684 dnl
2685 dnl DTS Coherent Acoustics decoder plugin
2686 dnl
2687 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2688
2689 dnl
2690 dnl  Flac plugin
2691 dnl
2692 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2693
2694 dnl
2695 dnl  Libmpeg2 plugin
2696 dnl
2697 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2698
2699 dnl
2700 dnl  Vorbis plugin
2701 dnl
2702 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2703
2704 dnl
2705 dnl  Tremor plugin
2706 dnl
2707 AC_ARG_ENABLE(tremor,
2708   [  --enable-tremor         Tremor decoder support (default disabled)])
2709 if test "${enable_tremor}" = "yes"
2710 then
2711   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2712     VLC_ADD_PLUGIN([tremor])
2713    ],[])
2714 fi
2715
2716 dnl
2717 dnl  Speex plugins
2718 dnl
2719 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2720 have_speexdsp="no"
2721 AS_IF([test "${enable_speex}" != "no"], [
2722   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2723     have_speexdsp="yes"
2724   ], [
2725     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2726   ])
2727 ])
2728 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2729
2730 dnl
2731 dnl  Opus plugin
2732 dnl
2733 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2734
2735 dnl
2736 dnl  Ambisonic channel mixer and binauralizer plugin
2737 dnl
2738 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
2739
2740 dnl
2741 dnl  theora decoder plugin
2742 dnl
2743 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2744
2745 dnl
2746 dnl  OggSpots decoder plugin
2747 dnl
2748 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2749
2750 dnl
2751 dnl  Daala decoder plugin
2752 dnl
2753 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2754
2755 dnl
2756 dnl  schroedinger decoder plugin (for dirac format video)
2757 dnl
2758 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2759
2760 dnl
2761 dnl  PNG decoder module
2762 dnl
2763 AC_ARG_ENABLE(png,
2764   [  --enable-png            PNG support (default enabled)])
2765 AS_IF([test "${enable_png}" != "no"], [
2766 AC_CHECK_HEADERS(png.h, [
2767   VLC_SAVE_FLAGS
2768   LDFLAGS="${LDFLAGS} -lz $LIBM"
2769   AC_CHECK_LIB(png, png_set_alpha_mode, [
2770     VLC_ADD_PLUGIN([png])
2771   ], [], [-lz $LIBM])
2772   VLC_RESTORE_FLAGS
2773   ])
2774 ])
2775
2776 dnl
2777 dnl  JPEG decoder module
2778 dnl
2779 AC_ARG_ENABLE(jpeg,
2780   [  --enable-jpeg           JPEG support (default enabled)])
2781 AS_IF([test "${enable_jpeg}" != "no"], [
2782 AC_CHECK_HEADERS(jpeglib.h, [
2783   VLC_ADD_PLUGIN([jpeg])
2784   ])
2785 ])
2786
2787 dnl
2788 dnl  BPG decoder module
2789 dnl
2790 AC_ARG_ENABLE(bpg,
2791   [  --enable-bpg           BPG support (default disabled)])
2792 AS_IF([test "${enable_bpg}" != "no"], [
2793 AC_CHECK_HEADERS(libbpg.h, [
2794   VLC_ADD_PLUGIN([bpg])
2795   ])
2796 ])
2797
2798 dnl
2799 dnl H262 encoder plugin (lib262)
2800 dnl
2801 AC_ARG_ENABLE(x262,
2802   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2803 if test "${enable_x262}" != "no"; then
2804     PKG_CHECK_MODULES(X262, x262, [
2805         VLC_ADD_PLUGIN([x262])
2806         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2807         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2808           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2809         ])
2810         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2811         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2812           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2813         fi
2814     ], [
2815        if test "${enable_x262}" = "yes"; then
2816         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2817        fi
2818     ])
2819 fi
2820
2821 dnl x265 encoder
2822 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2823
2824 dnl
2825 dnl H264 encoder plugin (10-bit lib264)
2826 dnl
2827 AC_ARG_ENABLE(x26410b,
2828   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2829 if test "${enable_x26410b}" != "no"; then
2830     PKG_CHECK_MODULES(X26410B, x26410b, [
2831         VLC_ADD_PLUGIN([x26410b])
2832         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2833         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2834           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2835         ])
2836         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2837         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2838           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2839         fi
2840     ], [
2841        if test "${enable_x26410b}" = "yes"; then
2842         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2843        fi
2844     ])
2845 fi
2846
2847
2848 dnl
2849 dnl H264 encoder plugin (using libx264)
2850 dnl
2851 AC_ARG_ENABLE(x264,
2852   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2853 if test "${enable_x264}" != "no"; then
2854       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2855         VLC_ADD_PLUGIN([x264])
2856         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2857
2858         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2859           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2860         ])
2861
2862         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2863         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2864           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2865         fi
2866       ],[
2867         if test "${enable_x264}" = "yes"; then
2868             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2869           fi
2870       ])
2871 fi
2872
2873 dnl
2874 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2875 dnl
2876 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2877
2878 dnl
2879 dnl libfluidsynth (MIDI synthetizer) plugin
2880 dnl
2881 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2882 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2883 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2884
2885 dnl
2886 dnl Teletext Modules
2887 dnl vbi decoder plugin (using libzbvi)
2888 dnl telx module
2889 dnl uncompatible
2890 dnl
2891 AC_ARG_ENABLE(zvbi,
2892   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2893                   libzvbi (default enabled)]))
2894 AC_ARG_ENABLE(telx,
2895   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2896                   zvbi) (default enabled if zvbi is absent)]))
2897
2898 AS_IF( [test "${enable_zvbi}" != "no"],[
2899     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2900         [
2901           VLC_ADD_PLUGIN([zvbi])
2902           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2903           AS_IF( [test "${enable_telx}" = "yes"],[
2904                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2905                   ])
2906         ],[
2907           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2908         ])
2909     ])
2910 AS_IF( [test "${enable_telx}" != "no" ],[
2911   VLC_ADD_PLUGIN([telx])
2912   ])
2913
2914 dnl
2915 dnl libass subtitle rendering module
2916 dnl
2917 AC_ARG_ENABLE(libass,
2918   [  --enable-libass         Subtitle support using libass (default enabled)])
2919 AS_IF( [test "${enable_libass}" != "no"], [
2920   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2921       [
2922         VLC_ADD_PLUGIN([libass])
2923
2924         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2925           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2926            VLC_ADD_LIBS([libass],[-lfontconfig])
2927        ])
2928       ],[
2929         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2930       ])
2931   ])
2932
2933 dnl
2934 dnl ARIB subtitles rendering module
2935 dnl
2936 AC_ARG_ENABLE(aribsub,
2937   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2938 AS_IF( [test "${enable_aribsub}" != "no" ],[
2939   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2940       have_aribb24="yes"
2941       VLC_ADD_PLUGIN([aribsub])
2942       VLC_ADD_LIBS([aribsub],[-laribb24])
2943       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2944     ],[
2945       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2946       have_aribb24="no"
2947   ])
2948 ])
2949 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2950
2951 dnl
2952 dnl ARIB B25
2953 dnl
2954 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2955
2956 dnl
2957 dnl  kate decoder plugin
2958 dnl
2959 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2960
2961 dnl
2962 dnl  tiger rendering for kate decoder plugin
2963 dnl
2964 AC_ARG_ENABLE(tiger,
2965 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2966 AS_IF([test "${enable_tiger}" != "no"], [
2967   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2968       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2969         AS_IF([test -n "${enable_tiger}"], [
2970           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2971         ])
2972   ])
2973 ])
2974
2975 dnl
2976 dnl  check if we can build the css selector engine
2977 dnl
2978 AC_ARG_ENABLE(css,
2979 [  --enable-css            CSS selector engine (default auto)])
2980 AS_IF([test "${enable_css}" != "no"], [
2981   with_css="yes"
2982   AC_DEFINE(HAVE_CSS, 1, [Define if CSS engine is built])
2983 ])
2984 AM_CONDITIONAL([ENABLE_CSS], [test "${with_css}" = "yes"])
2985
2986
2987 dnl
2988 dnl  Video plugins
2989 dnl
2990
2991 EXTEND_HELP_STRING([Video plugins:])
2992
2993 dnl
2994 dnl  OpenGL
2995 dnl
2996 PKG_CHECK_MODULES([EGL], [egl], [
2997   have_egl="yes"
2998 ], [
2999   have_egl="no"
3000 ])
3001 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3002
3003 have_gl="no"
3004 PKG_CHECK_MODULES([GL], [gl], [
3005   have_gl="yes"
3006 ], [
3007   AC_MSG_CHECKING([for OpenGL])
3008   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3009 #ifdef _WIN32
3010 # include <GL/glew.h>
3011 #endif
3012 #include <GL/gl.h>
3013 ]], [
3014     [int t0 = GL_TEXTURE0;]])
3015   ], [
3016     GL_CFLAGS=""
3017     have_gl="yes"
3018     AS_IF([test "${SYS}" != "mingw32"], [
3019       GL_LIBS="-lGL"
3020     ], [
3021       GL_LIBS="-lopengl32"
3022     ])
3023   ])
3024   AC_MSG_RESULT([${have_gl}])
3025 ])
3026 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3027
3028 dnl OpenGL ES 2: depends on EGL 1.1
3029 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3030
3031 dnl
3032 dnl  Xlib
3033 dnl
3034
3035 AC_PATH_XTRA()
3036 AC_CHECK_HEADERS(X11/Xlib.h)
3037
3038 dnl
3039 dnl  X C Bindings modules
3040 dnl
3041 AC_ARG_ENABLE(xcb,
3042   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3043   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3044     enable_xcb="yes"
3045   ], [
3046     enable_xcb="no"
3047   ])
3048 ])
3049 AC_ARG_ENABLE(xvideo,
3050   [  --enable-xvideo         XVideo support (default enabled)],, [
3051     enable_xvideo="$enable_xcb"
3052 ])
3053
3054 have_xcb="no"
3055 have_xcb_keysyms="no"
3056 have_xcb_randr="no"
3057 have_xcb_xvideo="no"
3058 AS_IF([test "${enable_xcb}" != "no"], [
3059   dnl libxcb
3060   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3061   have_xcb="yes"
3062   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3063   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3064   PKG_CHECK_MODULES(XPROTO, [xproto])
3065
3066   AS_IF([test "${enable_xvideo}" != "no"], [
3067     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3068   ])
3069
3070   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3071
3072   dnl xcb-utils
3073   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3074     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3075   ])
3076 ])
3077 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3078 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3079 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3080 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3081
3082
3083 dnl
3084 dnl VDPAU needs X11
3085 dnl
3086 AC_ARG_ENABLE(vdpau,
3087   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3088 have_vdpau="no"
3089 AS_IF([test "${enable_vdpau}" != "no"], [
3090   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3091     have_vdpau="yes"
3092     AS_IF([test "${no_x}" = "yes"], [
3093       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3094     ])
3095   ], [
3096     AS_IF([test -n "${enable_vdpau}"], [
3097       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3098     ])
3099   ])
3100 ])
3101 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3102
3103 have_avcodec_vdpau="no"
3104 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3105   case "${avfork}" in
3106     libav) av_vdpau_ver="56.10.0" ;;
3107     ffmpeg) av_vdpau_ver="56.19.100" ;;
3108   esac
3109   PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3110     have_avcodec_vdpau="yes"
3111     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3112   ], [
3113     AS_IF([test -n "${enable_vdpau}"], [
3114       AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3115     ], [
3116       AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3117     ])
3118   ])
3119 ])
3120 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3121
3122
3123 dnl
3124 dnl  Wayland
3125 dnl
3126 AC_ARG_ENABLE(wayland,
3127   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3128 have_wayland="no"
3129 have_wayland_egl="no"
3130
3131 AS_IF([test "${enable_wayland}" != "no"], [
3132   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3133     AC_MSG_CHECKING([for the Wayland protocols])
3134     PKG_CHECK_EXISTS([wayland-protocols >= 1.4], [
3135       WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3136       AC_MSG_RESULT([${WAYLAND_PROTOCOLS}])
3137     ], [
3138       AC_MSG_RESULT([not found])
3139       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors 'wayland-protocols >= 1.4')])
3140     ])
3141
3142     AC_MSG_CHECKING([for the Wayland scanner])
3143     PKG_CHECK_EXISTS([wayland-scanner], [
3144       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3145       AC_MSG_RESULT([${WAYLAND_SCANNER}])
3146     ], [
3147       AC_MSG_RESULT([not found])
3148       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors wayland-scanner)])
3149     ])
3150
3151     have_wayland="yes"
3152
3153     AS_IF([test "${have_egl}" = "yes"], [
3154       PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3155         have_wayland_egl="yes"
3156       ], [
3157         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3158       ])
3159     ])
3160   ], [
3161     AS_IF([test -n "${enable_wayland}"], [
3162       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3163     ])
3164   ])
3165 ])
3166 AC_SUBST([WAYLAND_PROTOCOLS])
3167 AC_SUBST([WAYLAND_SCANNER])
3168 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3169 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3170
3171
3172 dnl
3173 dnl  SDL image decoder module
3174 dnl
3175 AC_ARG_ENABLE(sdl-image,
3176   [  --enable-sdl-image      SDL image support (default enabled)])
3177 AS_IF([test "${enable_sdl_image}" != "no"],[
3178   PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3179     VLC_ADD_PLUGIN([sdl_image])
3180   ], [
3181     AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3182   ])
3183 ])
3184
3185 dnl
3186 dnl  freetype module
3187 dnl
3188 AC_ARG_ENABLE(freetype,
3189   [  --enable-freetype       freetype support   (default auto)])
3190 AC_ARG_ENABLE(fribidi,
3191   [  --enable-fribidi        fribidi support    (default auto)])
3192 AC_ARG_ENABLE(harfbuzz,
3193   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3194 AC_ARG_ENABLE(fontconfig,
3195   [  --enable-fontconfig     fontconfig support (default auto)])
3196
3197 AC_ARG_WITH([default-font],
3198     AS_HELP_STRING([--with-default-font=PATH],
3199         [Path to the default font]),
3200         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3201             "$withval", [Default font])])
3202 AC_ARG_WITH([default-monospace-font],
3203     AS_HELP_STRING([--with-default-monospace-font=PATH],
3204         [Path to the default font]),
3205         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3206             "$withval", [Default monospace font])])
3207
3208 AC_ARG_WITH([default-font-family],
3209     AS_HELP_STRING([--with-default-font-family=NAME],
3210         [Path to the default font family]),
3211         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3212             "$withval", [Default font family])])
3213 AC_ARG_WITH([default-monospace-font-family],
3214     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3215         [Path to the default font family]),
3216         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3217             "$withval", [Default monospace font family])])
3218
3219 have_freetype="no"
3220 have_fontconfig="no"
3221 have_fribidi="no"
3222 have_harfbuzz="no"
3223
3224 if test "${enable_freetype}" != "no"; then
3225    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3226       have_freetype="yes"
3227       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3228       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3229
3230     dnl fontconfig support
3231     AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3232       PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3233         have_fontconfig="yes"
3234       ], [
3235         AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3236       ])
3237     ])
3238
3239       dnl fribidi support
3240       if test "${enable_fribidi}" != "no"; then
3241         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3242           have_fribidi="yes"
3243           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3244           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3245         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3246       fi
3247
3248       dnl harfbuzz support
3249       if test "${have_fribidi}" != "no"; then
3250         if test "${enable_harfbuzz}" != "no"; then
3251           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3252             have_harfbuzz="yes"
3253             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3254             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3255           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3256         fi
3257       fi
3258   ],[
3259   AS_IF([test -n "${enable_freetype}"],[
3260     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3261     ])
3262   ])
3263 fi
3264
3265 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3266 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3267 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3268 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3269
3270 dnl
3271 dnl SAPI (text to Speech renderer for Windows)
3272 dnl
3273 AC_LANG_PUSH([C++])
3274 AC_CHECK_TYPES([ISpObjectToken],[
3275               have_sapi="yes"
3276             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3277               [#include <windows.h>
3278                #include <sapi.h>
3279                #include <sphelper.h>])
3280 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3281 AC_LANG_POP([C++])
3282
3283 dnl
3284 dnl  SVG module (text rendering and image decoding)
3285 dnl
3286 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3287 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3288
3289 dnl
3290 dnl  Windows DirectX module
3291 dnl
3292
3293 AC_ARG_ENABLE(directx,
3294   [AS_HELP_STRING([--enable-directx],
3295     [Microsoft DirectX support (default enabled on Windows)])],, [
3296   AS_IF([test "${SYS}" = "mingw32"], [
3297     enable_directx="yes"
3298   ], [
3299     enable_directx="no"
3300   ])
3301 ])
3302 AS_IF([test "${enable_directx}" != "no"], [
3303   dnl DirectDraw
3304   AC_CHECK_HEADERS(ddraw.h, [
3305     VLC_ADD_PLUGIN([directdraw])
3306   ])
3307
3308   dnl OpenGL
3309   AC_CHECK_HEADERS(GL/wglew.h, [
3310     VLC_ADD_PLUGIN([glwin32 wgl])
3311   ],, [
3312     #include <windows.h>
3313     #include <GL/gl.h>
3314   ])
3315
3316   dnl Direct3D11
3317   AC_CHECK_HEADERS(d3d11.h, [
3318     VLC_ADD_PLUGIN([direct3d11 direct3d11_filters])
3319   ])
3320
3321   dnl Direct3D9
3322   AC_CHECK_HEADERS(d3d9.h, [
3323     VLC_ADD_PLUGIN([direct3d9])
3324     AC_CHECK_HEADERS(d3dx9effect.h)
3325
3326     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3327         [[#define COBJMACROS
3328           #include <d3d9.h>
3329           #include <dxva2api.h>
3330           #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3331           # error dxva2 too old
3332           #endif
3333         ]],[[;]])
3334       ],[
3335         VLC_ADD_PLUGIN([direct3d9_filters])
3336       ],
3337       [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3338
3339   ])
3340 ])
3341
3342 dnl
3343 dnl  Linux framebuffer module
3344 dnl
3345 AC_CHECK_HEADER([linux/fb.h], [
3346   VLC_ADD_PLUGIN([fb])
3347 ])
3348
3349
3350 dnl
3351 dnl  AA plugin
3352 dnl
3353 AC_ARG_ENABLE(aa,
3354   [  --enable-aa             aalib output (default disabled)])
3355 if test "${enable_aa}" = "yes"
3356 then
3357   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3358   if test "${have_aa}" = "true"
3359   then
3360     VLC_ADD_PLUGIN([aa])
3361   fi
3362 fi
3363
3364 dnl
3365 dnl  libcaca plugin
3366 dnl
3367 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3368
3369 dnl
3370 dnl  OS/2 KVA plugin
3371 dnl
3372 AC_ARG_ENABLE(kva,
3373   [AS_HELP_STRING([--enable-kva],
3374     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3375   AS_IF([test "$SYS" = "os2"], [
3376     enable_kva="yes"
3377   ])
3378 ])
3379 have_kva="no"
3380 KVA_LIBS=""
3381 AS_IF([test "$enable_kva" != "no"], [
3382   AC_CHECK_HEADERS([kva.h], [
3383     have_kva="yes"
3384     AC_CHECK_LIB(kva, main, [
3385       KVA_LIBS="-lkva"
3386     ])
3387   ])
3388 ])
3389 AC_SUBST(KVA_LIBS)
3390 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3391
3392 dnl
3393 dnl MMAL plugin
3394 dnl
3395 AC_ARG_ENABLE(mmal,
3396   AS_HELP_STRING([--enable-mmal],
3397     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3398 if test "${enable_mmal}" != "no"; then
3399   VLC_SAVE_FLAGS
3400   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3401   CPPFLAGS="${CPPFLAGS} -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux"
3402   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3403     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3404         have_mmal="yes"
3405         VLC_ADD_PLUGIN([mmal])
3406         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3407         VLC_ADD_CFLAGS([mmal],[ -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux ])
3408         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lmmal_core -lmmal_components -lmmal_util -lvchostif ]) ], [
3409           AS_IF([test "${enable_mmal}" = "yes"],
3410             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3411             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3412           ],
3413         [])
3414     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3415       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3416       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3417   VLC_RESTORE_FLAGS
3418 fi
3419 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3420
3421 dnl
3422 dnl evas plugin
3423 dnl
3424 AC_ARG_ENABLE(evas,
3425   [AS_HELP_STRING([--enable-evas],
3426     [use evas output module (default disabled)])])
3427 have_evas="no"
3428 AS_IF([test "${enable_evas}" = "yes"], [
3429   PKG_CHECK_MODULES(EVAS, [evas >= 1.15.99 ecore >= 1.15.99], [
3430       have_evas="yes"
3431       AC_DEFINE([HAVE_EVAS], [1], [Define to 1 if evas is enabled.])
3432     ],[
3433     AS_IF([test "x${enable_evas}" != "x"], [
3434       AC_MSG_ERROR([$EVAS_PKG_ERRORS. libevas and libecore 1.15.99 or later required.])
3435     ])
3436   ])
3437 ])
3438 AM_CONDITIONAL([HAVE_EVAS], [test "${have_evas}" = "yes"])
3439
3440 dnl
3441 dnl  Audio plugins
3442 dnl
3443
3444 EXTEND_HELP_STRING([Audio plugins:])
3445
3446 dnl
3447 dnl  Pulseaudio module
3448 dnl
3449 AC_ARG_ENABLE(pulse,
3450   [AS_HELP_STRING([--enable-pulse],
3451     [use the PulseAudio client library (default auto)])])
3452 have_pulse="no"
3453 AS_IF([test "${enable_pulse}" != "no"], [
3454   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3455     have_pulse="yes"
3456   ], [
3457     AS_IF([test "x${enable_pulse}" != "x"], [
3458       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3459     ])
3460   ])
3461 ])
3462 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3463
3464 dnl
3465 dnl  ALSA module
3466 dnl
3467 AC_ARG_ENABLE(alsa,
3468   [AS_HELP_STRING([--enable-alsa],
3469     [support the Advanced Linux Sound Architecture (default auto)])],, [
3470   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3471     enable_alsa="yes"
3472   ])
3473 ])
3474 have_alsa="no"
3475 AS_IF([test "${enable_alsa}" != "no"], [
3476   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3477     have_alsa="yes"
3478   ], [
3479     AS_IF([test "x${enable_alsa}" != "x"], [
3480       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required. Pass --disable-alsa to ignore this error.])
3481     ])
3482   ])
3483 ])
3484 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3485
3486 dnl
3487 dnl  Open Sound System module
3488 dnl
3489 AC_ARG_ENABLE(oss,
3490   [AS_HELP_STRING([--enable-oss],
3491     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3492   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3493     enable_oss="no"
3494   ])
3495 ])
3496 have_oss="no"
3497 OSS_LIBS=""
3498 AS_IF([test "$enable_oss" != "no"], [
3499   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3500     have_oss="yes"
3501     AC_CHECK_LIB(ossaudio, main, [
3502       OSS_LIBS="-lossaudio"
3503     ])
3504   ])
3505 ])
3506 AC_SUBST(OSS_LIBS)
3507 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3508
3509 dnl
3510 dnl  OpenBSD sndio module
3511 dnl
3512 AC_ARG_ENABLE([sndio],
3513   [AS_HELP_STRING([--disable-sndio],
3514     [support the OpenBSD sndio (default auto)])],, [
3515   AS_IF([test "$SYS" = "openbsd"], [
3516     enable_sndio="yes"
3517   ])
3518 ])
3519 have_sndio="no"
3520 AS_IF([test "$enable_sndio" != "no"], [
3521   AC_CHECK_HEADER([sndio.h], [
3522     have_sndio="yes"
3523   ])
3524 ])
3525 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3526
3527 dnl
3528 dnl  Windows Audio Session plugin
3529 dnl
3530 AC_ARG_ENABLE([wasapi],
3531   [AS_HELP_STRING([--enable-wasapi],
3532     [use the Windows Audio Session API (default auto)])
3533 ])
3534 have_wasapi="no"
3535 AS_IF([test "$enable_wasapi" != "no"], [
3536   AC_CHECK_HEADER([audioclient.h], [
3537     have_wasapi="yes"
3538   ], [
3539     AS_IF([test "x${enable_wasapi}" != "x"], [
3540       AC_MSG_ERROR([Windows Audio Session API not found.])
3541     ])
3542   ])
3543 ])
3544 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3545
3546 dnl
3547 dnl  JACK modules
3548 dnl
3549 AC_ARG_ENABLE(jack,
3550   [AS_HELP_STRING([--disable-jack],
3551     [do not use jack (default auto)])])
3552 have_jack="no"
3553 AS_IF([test "${enable_jack}" != "no"], [
3554     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3555       [ have_jack=yes ],
3556       [
3557       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3558
3559       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3560       [ have_jack=yes ],
3561       [
3562       AS_IF([test -n "${enable_jack}"],
3563          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3564          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3565       ])
3566     ])
3567 ])
3568 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3569
3570 dnl
3571 dnl  OpenSLES Android
3572 dnl
3573 AC_ARG_ENABLE(opensles,
3574   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3575 if test "${HAVE_ANDROID}" = "1"; then
3576   if test "${enable_opensles}" = "yes"; then
3577       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3578         [ VLC_ADD_PLUGIN([opensles_android]) ],
3579         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3580   fi
3581 fi
3582
3583 dnl
3584 dnl  Tizen audio
3585 dnl
3586 AC_ARG_ENABLE(tizen_audio,
3587   [AS_HELP_STRING([--enable-tizen-audio],
3588     [Tizen audio module (default enabled on Tizen)])],, [
3589   AS_IF([test "$HAVE_TIZEN" = "1"], [
3590     enable_tizen_audio="yes"
3591   ])
3592 ])
3593 if test "${enable_tizen_audio}" = "yes"; then
3594   AC_CHECK_HEADERS(audio_io.h,
3595     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3596     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3597 fi
3598
3599 dnl
3600 dnl libsamplerate plugin
3601 dnl
3602 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3603
3604 dnl
3605 dnl  soxr module
3606 dnl
3607 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3608
3609 dnl
3610 dnl  OS/2 KAI plugin
3611 dnl
3612 AC_ARG_ENABLE(kai,
3613   [AS_HELP_STRING([--enable-kai],
3614     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3615   AS_IF([test "$SYS" = "os2"], [
3616     enable_kai="yes"
3617   ])
3618 ])
3619 have_kai="no"
3620 KAI_LIBS=""
3621 AS_IF([test "$enable_kai" != "no"], [
3622   AC_CHECK_HEADERS([kai.h], [
3623     have_kai="yes"
3624     AC_CHECK_LIB(kai, main, [
3625       KAI_LIBS="-lkai"
3626     ])
3627   ])
3628 ])
3629 AC_SUBST(KAI_LIBS)
3630 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3631
3632 dnl
3633 dnl  chromaprint audio track fingerprinter
3634 dnl
3635 m4_pushdef([libchromaprint_version], 0.6.0)
3636 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3637     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3638     AS_IF([test "${enable_chromaprint}" = "yes"],
3639         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3640         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3641          ),
3642     [(Chromaprint based audio fingerprinter)],[auto])
3643 m4_popdef([libchromaprint_version])
3644
3645 dnl
3646 dnl  Chromecast streaming support
3647 dnl
3648 m4_pushdef([protobuf_lite_version], 2.5.0)
3649 AC_ARG_VAR(PROTOC, [protobuf compiler])
3650 AC_CHECK_PROGS(PROTOC, protoc, no)
3651 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3652     AS_IF([test "x${PROTOC}" != "xno"], [
3653         build_chromecast="yes"
3654     ], [
3655     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3656     ])
3657 ], [
3658     AS_IF([test "${enable_chromecast}" = "yes"],
3659         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3660         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3661     )
3662     enable_chromecast="no"
3663 ], [(Chromecast streaming support)], [auto])
3664 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3665 m4_popdef([protobuf_lite_version])
3666
3667 dnl
3668 dnl  Interface plugins
3669 dnl
3670
3671 EXTEND_HELP_STRING([Interface plugins:])
3672
3673 dnl
3674 dnl QT
3675 dnl
3676 AC_ARG_ENABLE(qt, [
3677   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3678   AS_IF([test "${SYS}" = "darwin"], [
3679     enable_qt="no"
3680   ])
3681 ])
3682 have_qt5_x11="no"
3683 AS_IF([test "${enable_qt}" != "no"], [
3684   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.5.0 Qt5Widgets Qt5Gui Qt5Svg], [
3685       PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3686           have_qt5_x11="yes"
3687       ],[
3688           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3689       ])
3690       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3691       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3692       QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3693       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3694       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3695       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3696     ], [
3697       AS_IF([test -n "${enable_qt}"],[
3698         AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3699       ],[
3700         AC_MSG_WARN([${QT_PKG_ERRORS}.])
3701       ])
3702       enable_qt="no"
3703     ])
3704 ])
3705
3706 AS_IF([test "${enable_qt}" != "no"], [
3707   ALIASES="${ALIASES} qvlc"
3708 ])
3709 AC_SUBST(QT_VERSION)
3710 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3711 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3712
3713 dnl
3714 dnl detect kde4-config patch (used for kde solids).
3715 dnl
3716 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3717 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3718   KDE4_CONFIG="kde4-config"
3719 ])
3720
3721 dnl
3722 dnl Simple test for skins2 dependency
3723 dnl
3724 AS_IF([test "$enable_qt" = "no"], [
3725   AS_IF([test "${enable_skins2}" = "yes"], [
3726     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3727   ], [
3728     enable_skins2="no"
3729     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3730   ])
3731 ])
3732
3733 dnl
3734 dnl Skins2 module
3735 dnl
3736 AC_ARG_ENABLE(skins2,
3737   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3738 AS_IF([test "${enable_skins2}" != "no"], [
3739   have_skins_deps="yes"
3740
3741   dnl Win32
3742   AS_IF([test "${SYS}" = "mingw32"], [
3743     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3744     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3745   dnl OS/2
3746   ], [test "${SYS}" = "os2"], [
3747     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3748   dnl Linux/Unix
3749   ], [
3750     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3751     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3752     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3753     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3754     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3755   ])
3756
3757   dnl we need freetype
3758   AS_IF([test "${have_freetype}" != "yes"], [
3759     have_skins_deps="no"
3760   ])
3761
3762   AS_IF([test "${have_skins_deps}" = "no"], [
3763     AS_IF([test "x${enable_skins2}" = "x"], [
3764       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3765     ], [
3766       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3767     ])
3768     enable_skins2="no"
3769   ], [
3770     ALIASES="${ALIASES} svlc"
3771     enable_skins2="yes"
3772   ])
3773 ])
3774 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3775
3776 AC_ARG_ENABLE(libtar,
3777   [  --enable-libtar         libtar support for skins2 (default auto)])
3778 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3779   AC_CHECK_HEADERS(libtar.h, [
3780     VLC_ADD_LIBS([skins2],[-ltar])
3781   ])
3782 ])
3783
3784 dnl
3785 dnl  MacOS X gui module
3786 dnl
3787 AC_ARG_ENABLE(macosx,
3788   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3789 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3790 then
3791
3792   dnl
3793   dnl If possible, use xcrun to find the right ibtool
3794   dnl
3795
3796   AC_PATH_PROG([XCRUN], [xcrun], [no])
3797   AS_IF([test ! "x${XCRUN}" = "xno"], [
3798     AC_MSG_CHECKING([for ibtool (using xcrun)])
3799     XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3800     AC_MSG_RESULT([${XIB}])
3801   ], [
3802     AC_MSG_WARN([Looking for tools without using xcrun])
3803   ])
3804
3805   AS_IF([test "x${XIB}" = "xno"], [
3806     AC_PATH_PROG(XIB, [ibtool], [no])
3807     AS_IF([test "x${XIB}" = "xno"], [
3808       AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3809     ])
3810   ])
3811 fi
3812 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3813
3814 dnl
3815 dnl  MacOS X sparkle update support
3816 dnl
3817 AC_ARG_ENABLE(sparkle,
3818   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3819 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3820 then
3821   if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3822   then
3823     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3824   fi
3825
3826   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3827 fi
3828 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3829
3830 dnl
3831 dnl  MacOS X breakpad creash reporter support
3832 dnl
3833 AC_ARG_WITH([breakpad],
3834   AS_HELP_STRING([--with-breakpad=URL], [Enable Breakpad reporter using given URL]), [], [with_breakpad=no])
3835
3836 AS_IF([test "$with_breakpad" != "no"], [
3837
3838   AS_IF([test "$with_breakpad" = "yes"], [
3839     AC_MSG_ERROR([You need to supply the CrashDragon Server URL as value for --with-breakpad])
3840   ])
3841
3842   AS_IF([test "$HAVE_OSX" = "1"], [
3843     AC_MSG_CHECKING([for Breakpad framework])
3844     AS_IF([test ! -d ${CONTRIB_DIR}/Breakpad.framework -a \
3845                 ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework], [
3846       AC_MSG_RESULT([no])
3847       with_breakpad="no"
3848       AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3849     ], [
3850       AC_MSG_RESULT([yes])
3851     ])
3852   ],[
3853     PKG_CHECK_MODULES([BREAKPAD], [breakpad-client], [
3854       LDFLAGS="${LDFLAGS} -Wl,--build-id"
3855     ], [
3856       AC_MSG_ERROR(["breakpad not found"])
3857     ])
3858   ])
3859 ])
3860
3861 AM_CONDITIONAL(HAVE_BREAKPAD, [test "$with_breakpad" != "no"])
3862 AS_IF([test "$with_breakpad" != "no"], [
3863   AC_SUBST(BREAKPAD_URL, ["${with_breakpad}"])
3864 ])
3865
3866 dnl
3867 dnl  Minimal Mac OS X module
3868 dnl
3869 AC_ARG_ENABLE(minimal-macosx,
3870   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3871 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3872 then
3873   VLC_ADD_PLUGIN([minimal_macosx])
3874 fi
3875
3876 dnl
3877 dnl Mac OS X fancy dmg build tool
3878 dnl
3879 if test "${HAVE_OSX}" = "1"
3880 then
3881   AC_PATH_PROG(DMGBUILD, dmgbuild, no)
3882   AS_IF([test "x${DMGBUILD}" = "xno"], [
3883     AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
3884   ])
3885 fi
3886 AM_CONDITIONAL(HAVE_DMGBUILD, [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
3887
3888 dnl
3889 dnl  VideoToolbox plugins
3890 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3891     VLC_ADD_PLUGIN([videotoolbox])
3892     VLC_ADD_PLUGIN([cvpx])
3893   ])
3894
3895 dnl
3896 dnl  AudioToolbox MIDI plugin
3897 AC_CHECK_HEADERS([AudioToolbox/AudioToolbox.h], [
3898   VLC_ADD_PLUGIN([audiotoolboxmidi])
3899 ])
3900
3901 dnl
3902 dnl  ncurses module
3903 dnl
3904 AC_ARG_ENABLE(ncurses,
3905 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3906 have_ncurses="no"
3907 AS_IF([test "${enable_ncurses}" != "no"] ,[
3908   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3909     have_ncurses="yes"
3910     ALIASES="${ALIASES} nvlc"
3911   ], [
3912     AS_IF([test -n "${enable_ncurses}"], [
3913       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3914     ])
3915   ])
3916 ])
3917 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3918
3919 dnl
3920 dnl  Lirc plugin
3921 dnl
3922 AC_ARG_ENABLE(lirc,
3923   [  --enable-lirc           lirc support (default disabled)])
3924 have_lirc="no"
3925 AS_IF([test "${enable_lirc}" = "yes"], [
3926   AC_CHECK_HEADER(lirc/lirc_client.h, [
3927     AC_CHECK_LIB(lirc_client, lirc_init, [
3928       have_lirc="yes"
3929     ])
3930   ])
3931 ])
3932 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3933
3934 dnl
3935 dnl  SRT plugin
3936 dnl
3937 PKG_ENABLE_MODULES_VLC([SRT], [access_srt access_output_srt], [srt >= 1.2.2], [SRT input/output plugin], [auto], [], [], [-DENABLE_SRT])
3938
3939 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3940 dnl
3941 dnl  goom visualization plugin
3942 dnl
3943 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3944
3945 dnl
3946 dnl libprojectM visualization plugin
3947 dnl
3948 AC_ARG_ENABLE(projectm,
3949   [  --enable-projectm       projectM visualization plugin (default enabled)])
3950 AS_IF([test "${enable_projectm}" != "no"],
3951   [
3952     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3953     [
3954       VLC_ADD_PLUGIN([projectm])
3955       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3956         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3957         [ AC_MSG_WARN( [Using libprojectM version 1] )
3958       ])
3959     ],[
3960       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3961     ])
3962   ])
3963
3964 dnl
3965 dnl Vovoid VSXu visualization plugin
3966 dnl
3967 AC_ARG_ENABLE(vsxu,
3968   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3969 AS_IF([test "${enable_vsxu}" != "no"],
3970   [
3971     PKG_CHECK_MODULES(VSXU, libvsxu,
3972     [
3973       VLC_ADD_PLUGIN([vsxu])
3974     ],[
3975       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3976     ])
3977   ])
3978
3979 EXTEND_HELP_STRING([Service Discovery plugins:])
3980 dnl
3981 dnl  Avahi-Zeroconf services discovery
3982 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
3983
3984 dnl
3985 dnl  libudev services discovery
3986 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3987
3988 dnl
3989 dnl MTP devices services discovery
3990 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3991
3992 dnl
3993 dnl UPnP Plugin (Intel SDK)
3994 dnl
3995 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3996
3997 dnl
3998 dnl mDNS using libmicrodns
3999 dnl
4000 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
4001
4002
4003 EXTEND_HELP_STRING([Misc options:])
4004
4005 dnl
4006 dnl  libxml2 module
4007 dnl
4008 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4009
4010
4011 dnl
4012 dnl libgcrypt
4013 dnl
4014 AC_ARG_ENABLE(libgcrypt,
4015   [  --disable-libgcrypt     gcrypt support (default enabled)])
4016 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
4017 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4018
4019 # require libgcrypt >= 1.6.0
4020 AS_IF([test "${enable_libgcrypt}" != "no"], [
4021   AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4022     VLC_SAVE_FLAGS
4023     CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4024     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4025 [#include <gcrypt.h>
4026 #if GCRYPT_VERSION_NUMBER < 0x010600
4027 #error
4028 #endif]])], [
4029       ac_cv_lib_gcrypt=yes
4030     ], [
4031       ac_cv_lib_gcrypt=no
4032     ])
4033     VLC_RESTORE_FLAGS
4034   ])
4035
4036   AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4037     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4038   ], [
4039     AS_IF([test "${enable_libgcrypt}" = "yes"], [
4040       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4041     ])
4042   ])
4043 ])
4044
4045 AS_IF([test -z "$GCRYPT_LIBS"], [
4046   GCRYPT_LIBS="-lgcrypt -lgpg-error"
4047 ])
4048
4049 AC_SUBST(GCRYPT_CFLAGS)
4050 AC_SUBST(GCRYPT_LIBS)
4051 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4052
4053 dnl
4054 dnl TLS/SSL
4055 dnl
4056 AC_ARG_ENABLE(gnutls,
4057   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4058 AS_IF([test "${enable_gnutls}" != "no"], [
4059   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4060     VLC_ADD_PLUGIN([gnutls])
4061   ], [
4062     AS_IF([test -n "${enable_gnutls}"], [
4063       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4064     ])
4065   ])
4066 ])
4067
4068
4069 dnl
4070 dnl Taglib plugin
4071 dnl
4072 AC_ARG_ENABLE(taglib,
4073   [AS_HELP_STRING([--disable-taglib],
4074     [do not use TagLib (default enabled)])])
4075 AS_IF([test "${enable_taglib}" != "no"], [
4076   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4077     VLC_ADD_PLUGIN([taglib])
4078   ], [
4079     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4080 ])
4081
4082 dnl
4083 dnl  libsecret
4084 dnl
4085 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4086
4087 dnl
4088 dnl  kwallet
4089 dnl
4090 AC_ARG_ENABLE(kwallet,
4091   [AS_HELP_STRING([--enable-kwallet],
4092     [use kwallet (via D-Bus) for keystore (default enabled)])])
4093 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4094   VLC_ADD_PLUGIN([kwallet])
4095 ])
4096
4097 dnl
4098 dnl update checking system
4099 dnl
4100 AC_ARG_ENABLE(update-check,
4101   [  --enable-update-check   update checking system (default disabled)])
4102 if test "${enable_update_check}" = "yes"
4103 then
4104  AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4105     AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4106 fi
4107 AM_CONDITIONAL(UPDATE_CHECK, [test "${enable_update_check}" = "yes"])
4108
4109 dnl
4110 dnl OS X notification plugin
4111 dnl
4112 AC_ARG_ENABLE(osx_notifications,
4113   [  --enable-osx-notifications          osx notification plugin (default disabled)],,
4114   [enable_osx_notifications=no])
4115 AS_IF([test "${enable_osx_notifications}" != "no"], [
4116   if test -d ${CONTRIB_DIR}/Growl.framework -o -d ${CONTRIB_DIR}/Frameworks/Growl.framework
4117   then
4118       VLC_ADD_PLUGIN([osx_notifications])
4119       VLC_ADD_LIBS([osx_notifications], [-Wl,-framework,Growl,-framework,Foundation])
4120       VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4121   fi
4122 ])
4123
4124 dnl
4125 dnl Libnotify notification plugin
4126 dnl
4127 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-3.0], [libnotify notification], [auto])
4128
4129 dnl
4130 dnl  libplacebo support
4131 dnl
4132 AC_ARG_ENABLE(libplacebo,
4133   [AS_HELP_STRING([--disable-libplacebo],
4134       [disable libplacebo support (default auto)])])
4135
4136 AS_IF([test "$enable_libplacebo" != "no"], [
4137   PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 0.1], [
4138     AC_DEFINE([HAVE_LIBPLACEBO], [1], [Define to 1 if libplacebo is enabled.])
4139   ], [
4140     AS_IF([test -n "${enable_libplacebo}"], [
4141       AC_MSG_ERROR([${LIBPLACEBO_PKG_ERRORS}.])
4142     ])
4143     enable_libplacebo="no"
4144   ])
4145 ])
4146 AM_CONDITIONAL(HAVE_LIBPLACEBO, [test "$enable_libplacebo" != "no"])
4147
4148
4149 dnl
4150 dnl  Endianness check
4151 dnl
4152 AC_C_BIGENDIAN
4153 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4154   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4155 ], [
4156   DEFS_BIGENDIAN=""
4157 ])
4158 AC_SUBST(DEFS_BIGENDIAN)
4159
4160 dnl
4161 dnl Where to install KDE solid .desktop
4162 dnl
4163 AC_ARG_WITH(kde-solid,
4164   AS_HELP_STRING([--with-kde-solid=PATH],
4165                  [KDE Solid actions directory (auto)]),, [
4166
4167 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4168   with_kde_solid="yes"
4169 fi
4170 ])
4171 soliddatadir=""
4172 AS_IF([test "${with_kde_solid}" != "no"], [
4173   AS_IF([test "${with_kde_solid}" = "yes"], [
4174     kde4datadir="`${KDE4_CONFIG} --install data`"
4175     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4176     soliddatadir="${kde4datadir}/solid/actions"
4177   ], [
4178     soliddatadir="${with_kde_solid}"
4179   ])
4180 ])
4181 AC_SUBST(soliddatadir)
4182 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4183
4184 dnl
4185 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4186 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4187 dnl
4188 if test "${SYS}" = "mingw32"; then
4189     AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4190 fi
4191
4192 EXTEND_HELP_STRING([Components:])
4193
4194 dnl
4195 dnl  the VLC binary
4196 dnl
4197 AC_ARG_ENABLE(vlc,
4198   [  --enable-vlc            build the VLC media player (default enabled)])
4199 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4200
4201 dnl
4202 dnl Fuzzer (at the end in order to don't mess dependencies FLAGS)
4203 dnl
4204 AS_VAR_IF(with_libfuzzer, no, [], [
4205     LIBS="-lstdc++ ${LIBM} ${LIBPTHREAD} -L${with_libfuzzer} -lFuzzer"
4206     AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc-guard, [
4207         AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard])
4208         AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard], [CXXFLAGS])
4209         AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp])
4210         AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp], [CXXFLAGS])
4211     ], [
4212         AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc, [
4213             AX_APPEND_FLAG([-fsanitize-coverage=trace-pc])
4214             AX_APPEND_FLAG([-fsanitize-coverage=trace-pc], [CXXFLAGS])
4215         ], [
4216             AC_MSG_ERROR([Sanitizer coverage not supported by your compiler])
4217         ])
4218     ])
4219 ])
4220
4221 dnl
4222 dnl  Stuff used by the program
4223 dnl
4224 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4225 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4226 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4227 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4228 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4229 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4230 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4231 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4232 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4233 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4234 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4235 AC_SUBST(COPYRIGHT_MESSAGE)
4236 AC_SUBST(VERSION_MESSAGE)
4237 AC_SUBST(VERSION_MAJOR)
4238 AC_SUBST(VERSION_MINOR)
4239 AC_SUBST(VERSION_REVISION)
4240 AC_SUBST(VERSION_EXTRA)
4241 AC_SUBST(COPYRIGHT_YEARS)
4242 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4243 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4244 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4245 dnl
4246 dnl  Handle substvars that use $(top_srcdir)
4247 dnl
4248 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4249
4250 dnl
4251 dnl  Configuration is finished
4252 dnl
4253 AC_SUBST(SYS)
4254 AC_SUBST(ARCH)
4255 AC_SUBST(ALIASES)
4256 AC_SUBST(ASM)
4257 AC_SUBST(MOC)
4258 AC_SUBST(RCC)
4259 AC_SUBST(UIC)
4260 AC_SUBST(WINDRES)
4261 AC_SUBST(WINE_SDK_PATH)
4262 AC_SUBST(LIBEXT)
4263 AC_SUBST(AM_CPPFLAGS)
4264 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4265 AC_SUBST(FILE_LIBVLCCORE_DLL)
4266 AC_SUBST(FILE_LIBVLC_DLL)
4267
4268 AC_CONFIG_FILES([
4269   Makefile
4270   doc/Makefile
4271   modules/Makefile
4272   m4/Makefile
4273   po/Makefile.in
4274   share/Makefile
4275   compat/Makefile
4276   src/Makefile
4277   lib/Makefile
4278   bin/Makefile
4279   test/Makefile
4280   modules/hw/mmal/Makefile
4281   share/vlc.appdata.xml.in
4282 ])
4283
4284 AM_COND_IF([HAVE_WIN32], [
4285   AC_CONFIG_FILES([
4286     extras/package/win32/NSIS/spad.nsi
4287     extras/package/win32/NSIS/vlc.win32.nsi
4288     extras/package/win32/msi/config.wxi
4289   ])
4290 ])
4291
4292 AM_COND_IF([HAVE_DARWIN], [
4293   AC_CONFIG_FILES([
4294     modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4295     share/macosx/Info.plist:share/Info.plist.in
4296   ])
4297 ])
4298
4299 dnl Generate makefiles
4300 AC_OUTPUT
4301
4302 dnl Do we have to use make or gmake ?
4303 if make --version 2>&1|grep -q GNU
4304 then
4305     # GNU make, all seems good
4306     MAKE=make
4307 else
4308     # Known GNU make alias (on BSD)
4309     MAKE=gmake
4310 fi
4311 dnl Shortcut to nice compile message
4312 if test -n $SHELL; then
4313   SHELL=${CONFIG_SHELL-/bin/sh}
4314 fi
4315 rm -f compile
4316 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4317 echo "#! $SHELL
4318 rm -f .error\$\$
4319 ERROR=0
4320 export PATH=\"$PATH\" LANG=C
4321 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4322 test -f .error\$\$ && ERROR=1
4323 rm -f .error\$\$
4324 exit \$ERROR" >compile
4325 chmod a+x compile
4326
4327 echo "
4328 libvlc configuration
4329 --------------------
4330 version               : ${VERSION}
4331 system                : ${SYS}
4332 architecture          : ${ARCH}
4333 optimizations         : ${enable_optimizations}"
4334 if test "${enable_vlc}" != "no"; then
4335 echo "vlc aliases           :${ALIASES}"
4336 else
4337 echo "build vlc executable  : no"
4338 fi
4339 echo "
4340 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."