configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 1999-2016 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 3.0.0-git)
   6 VERSION_MAJOR=3
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=git
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Vetinari"
  17 COPYRIGHT_YEARS="1996-2016"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 AM_SILENT_RULES([yes])
  31 AM_MAINTAINER_MODE([enable])
  32
  33 dnl
  34 dnl Directories
  35 dnl
  36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  37 dnl AC_SUBST(vlcincludedir)
  38 vlcdatadir="\${datadir}/\${PKGDIR}"
  39 AC_SUBST(vlcdatadir)
  40 vlclibdir="\${libdir}/\${PKGDIR}"
  41 AC_SUBST(vlclibdir)
  42
  43 dnl
  44 dnl Check for tools
  45 dnl
  46 AC_PROG_CC_C99
  47 AC_USE_SYSTEM_EXTENSIONS
  48 VLC_PROG_CC_C11
  49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  51 AH_TOP([
  52 #ifndef _REENTRANT
  53 # define _REENTRANT
  54 #endif
  55 ])
  56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  59
  60 AM_PROG_CC_C_O
  61 AC_PROG_CXX
  62 AC_PROG_CPP
  63 AC_PROG_OBJC
  64 _AM_DEPENDENCIES([OBJC])
  65 AC_PROG_EGREP
  66 AC_PROG_MAKE_SET
  67 AC_PROG_INSTALL
  68 AM_PROG_AS
  69
  70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
  73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
  74 AS_IF([test "$BUILDCC" = "false"], [
  75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
  76 ])
  77
  78 dnl Check for compiler properties
  79 AC_C_CONST
  80 AC_C_INLINE
  81 AC_C_RESTRICT
  82 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
  83
  84 dnl Extend the --help string at the current spot.
  85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  86
  87 dnl Allow binary package maintainer to pass a custom string to avoid
  88 dnl cache problem
  89 AC_ARG_WITH(binary-version,
  90     AS_HELP_STRING([--with-binary-version=STRING],
  91          [To avoid plugins cache problem between binary version]),[],[])
  92 AS_IF([test -n "${with_binary_version}"],[
  93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  94          [Binary specific version])
  95 ])
  96
  97 dnl
  98 dnl  Check the operating system
  99 dnl
 100 HAVE_WIN64="0"
 101 HAVE_IOS="0"
 102 HAVE_OSX="0"
 103 HAVE_TVOS="0"
 104
 105 case "${host_os}" in
 106   "")
 107     SYS=unknown
 108     ;;
 109   linux*)
 110     SYS=linux
 111     ;;
 112   bsdi*)
 113     SYS=bsdi
 114     CFLAGS="${CFLAGS} -pthread"
 115     ;;
 116   freebsd*)
 117     SYS=freebsd
 118     CFLAGS="${CFLAGS} -pthread"
 119     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 120     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 121     ac_cv_ld_z_defs=no
 122     ;;
 123   openbsd*)
 124     SYS=openbsd
 125     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 126     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 127     ;;
 128   netbsd*)
 129     SYS=netbsd
 130     ;;
 131   dragonfly*)
 132     SYS=dragonfly
 133     ;;
 134   darwin*)
 135
 136     dnl Force gcc "-arch" flag
 137     ARCH_flag=""
 138     case "${host}" in
 139       i?86*)
 140         ARCH_flag="-arch i386"
 141       ;;
 142       ppc64*)
 143         ARCH_flag="-arch ppc64"
 144       ;;
 145       ppc*)
 146         ARCH_flag="-arch ppc"
 147       ;;
 148       x86_64*)
 149         ARCH_flag="-arch x86_64"
 150       ;;
 151       arm*)
 152         ac_cv_c_bigendian="no"
 153         ac_cv_c_attribute_packed="no"
 154       ;;
 155     esac
 156
 157     SYS=darwin
 158     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 159     CXX="${CXX} -stdlib=libc++ -std=c++11"
 160     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 161     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 162     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 163     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 164     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 165     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 166
 167     AC_EGREP_CPP(yes,
 168             [#import <TargetConditionals.h>
 169              #if TARGET_OS_IPHONE
 170              yes
 171              #endif],
 172              [HAVE_IOS="1"],
 173              [HAVE_OSX="1"])
 174
 175     AC_EGREP_CPP(yes,
 176             [#import <TargetConditionals.h>
 177              #if TARGET_OS_TV
 178              yes
 179              #endif],
 180              [HAVE_TVOS="1"
 181              HAVE_IOS="0"
 182              HAVE_OSX="0"
 183              ],)
 184
 185     dnl Allow binaries created on Lion to run on earlier releases
 186     AC_EGREP_CPP(yes,
 187            [#import <Cocoa/Cocoa.h>
 188             #ifdef MAC_OS_X_VERSION_10_7
 189             yes
 190             #endif],
 191             [AC_MSG_RESULT([yes])
 192             AC_LIBOBJ([getdelim])
 193             AC_LIBOBJ([strndup])
 194             AC_LIBOBJ([strnlen])],)
 195
 196     dnl
 197     dnl  Handle Mac OS X SDK flags
 198     dnl
 199     AC_ARG_WITH(macosx-sdk,
 200       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 201         [compile using the SDK in DIR])])
 202     if test "${with_macosx_sdk}" != "" ; then
 203         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 204         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 205         CC="${CC} -isysroot ${with_macosx_sdk}"
 206         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 207         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 208         LD="${LD} -syslibroot ${with_macosx_sdk}"
 209     fi
 210     AC_ARG_WITH(macosx-version-min,
 211       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 212         [compile for Mac OS X VERSION and above])])
 213     if test "${with_macosx_version_min}" != "" ; then
 214         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 215         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 216         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 217         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 218         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 219     fi
 220     ;;
 221   *mingw32* | *cygwin* | *wince* | *mingwce*)
 222     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
 223     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
 224     CXXFLAGS="${CXXFLAGS} -static-libgcc"
 225     AC_CHECK_TOOL(WINDRES, windres, :)
 226     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 227     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
 228     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
 229     AH_TOP([#endif])
 230     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 231     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 232     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 233     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 234     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 235     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 236     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 237     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 238     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 239     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 240     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 241
 242     case "${host_os}" in
 243       *mingw32*)
 244         SYS=mingw32
 245         ;;
 246       *cygwin*)
 247         dnl Check if we are using the mno-cygwin mode in which case we are
 248         dnl actually dealing with a mingw32 compiler.
 249         AC_EGREP_CPP(yes,
 250             [#ifdef _WIN32
 251              yes
 252              #endif],
 253             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 254         ;;
 255     esac
 256
 257     if test "${SYS}" = "mingw32"; then
 258         # DEP, ASLR, NO SEH
 259         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 260
 261         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 262         ac_default_prefix="`pwd`/_win32"
 263         DESTDIR="`pwd`/_win32/"
 264
 265         dnl
 266         dnl NSIS/MSI Installer prefix and WIN64
 267         dnl
 268         case "${host}" in
 269             amd64*|x86_64*)
 270                 HAVE_WIN64="1"
 271                 WINDOWS_ARCH="x64"
 272                 PROGRAMFILES="PROGRAMFILES64"
 273                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
 274             ;;
 275             *)
 276                 WINDOWS_ARCH="x86"
 277                 PROGRAMFILES="PROGRAMFILES"
 278             ;;
 279         esac
 280         AC_SUBST(WINDOWS_ARCH)
 281         AC_SUBST(PROGRAMFILES)
 282
 283     fi
 284     ;;
 285   *nto*)
 286     SYS=nto
 287     ;;
 288   solaris*)
 289     SYS=solaris
 290     ;;
 291   hpux*)
 292     SYS=hpux
 293     ;;
 294   *os2*)
 295     SYS=os2
 296     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 297     AC_LIBOBJ([freeaddrinfo])
 298     AC_LIBOBJ([gai_strerror])
 299     ;;
 300   *)
 301     SYS="${host_os}"
 302     ;;
 303 esac
 304
 305 dnl WinRT
 306 AC_ARG_ENABLE(winstore_app,
 307      AS_HELP_STRING([--enable-winstore-app],
 308                     [Build targetted for Windows Store apps (default disabled)]))
 309
 310 vlc_winstore_app=0
 311 AS_IF([test "${SYS}" = "mingw32"],[
 312   LIBCOM="-lole32"
 313   AS_IF([test "${enable_winstore_app}" = "yes"], [
 314     vlc_winstore_app=1
 315     LIBCOM=""
 316      VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
 317      AC_LIBOBJ([gai_strerror])
 318     ],[
 319      VLC_ADD_LIBS([libvlccore],[-lwinmm])
 320     ])
 321   AC_SUBST(LIBCOM)
 322   ])
 323 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 324
 325 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 326 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 327
 328 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 329 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
 330 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
 331 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
 332
 333 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 334 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
 335 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 336 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
 337
 338 dnl
 339 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 340 dnl for program foo on win32
 341 case "${build_os}" in
 342     cygwin|msys|mingw32)
 343         ac_executable_extensions=".exe"
 344     ;;
 345     os2*)
 346         BUILDEXEEXT=".exe"
 347     ;;
 348     *)
 349     ;;
 350 esac
 351 AC_SUBST(BUILDEXEEXT)
 352
 353 dnl Android is linux, but a bit different
 354 AS_IF([test "$SYS" = linux],[
 355     AC_MSG_CHECKING([for an Android system])
 356     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 357         [[#ifndef __ANDROID__
 358          # error Not Android
 359          #endif
 360         ]],[[;]])
 361     ],[
 362       HAVE_ANDROID="1"
 363       AC_MSG_RESULT([yes])
 364     ],[
 365       AC_MSG_RESULT([no])
 366     ])
 367 ])
 368 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 369
 370 dnl Tizen (minimum SDK version: 2.3)
 371 AS_IF([test "$SYS" = linux],[
 372     AC_MSG_CHECKING([for Tizen])
 373     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 374         [[#include <tizen.h>
 375         ]],[[;]])
 376     ],[
 377       HAVE_TIZEN="1"
 378       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
 379       AC_MSG_RESULT([yes])
 380     ],[
 381       AC_MSG_RESULT([no])
 382     ])
 383 ])
 384 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
 385
 386 dnl
 387 dnl  Check for the contrib directory
 388 dnl
 389 AC_ARG_WITH(contrib,
 390   [AS_HELP_STRING([--with-contrib[=DIR]],
 391     [search for 3rd party libraries in DIR/include and DIR/lib])
 392 ])
 393 AC_MSG_CHECKING([for 3rd party libraries path])
 394 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 395   CONTRIB_DIR="${srcdir}/contrib/${host}"
 396   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 397     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 398     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 399     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 400       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 401       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
 402       AS_IF([test ! -d "${CONTRIB_DIR}"], [
 403         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 404         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
 405         AS_IF([test ! -d "${CONTRIB_DIR}"], [
 406           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 407           CONTRIB_DIR=""
 408           AC_MSG_RESULT([not found])
 409         ])
 410       ])
 411     ])
 412   ])
 413 ], [
 414   AS_IF([test "${with_contrib}" != "no"], [
 415     CONTRIB_DIR="${with_contrib}"
 416   ], [
 417     CONTRIB_DIR=""
 418     AC_MSG_RESULT([disabled])
 419   ])
 420 ])
 421 AS_IF([test -n "${CONTRIB_DIR}"], [
 422   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 423     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 424   ], [
 425     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 426     CONTRIB_DIR=""
 427     AC_MSG_RESULT([not usable])
 428   ])
 429
 430 ])
 431 AS_IF([test -n "${CONTRIB_DIR}"], [
 432   AC_MSG_RESULT([${CONTRIB_DIR}])
 433   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 434   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 435   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 436   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
 437   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 438   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 439
 440   AS_IF([test -z "$LUAC"], [
 441     dnl Old contribs mixed cross-tools and cross-compiled executables
 442     AS_IF([test -x "${CONTRIB_DIR}/bin/luac"], [
 443       LUAC="${CONTRIB_DIR}/bin/luac"
 444     ])
 445
 446     dnl Newer contribs follow usual name space rules
 447     AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac"], [
 448       LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac"
 449     ])
 450   ])
 451
 452   AS_IF([test "${SYS}" = "darwin"], [
 453     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 454     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 455   ])
 456 ], [
 457   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 458     AC_MSG_ERROR([Third party libraries not found!])
 459   ])
 460 ])
 461 AC_SUBST(CONTRIB_DIR)
 462
 463 dnl Add extras/tools to the PATH
 464 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 465 AS_IF([test -d "${TOOLS_DIR}"], [
 466     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 467     export PATH="${TOOLS_DIR}":$PATH
 468 ])
 469
 470 dnl
 471 dnl  Libtool
 472 dnl  It's very bad, but our former custom system was worst
 473 dnl  -- Courmisch
 474 dnl
 475
 476 dnl override platform specific check for dependent libraries
 477 dnl otherwise libtool linking of shared libraries will
 478 dnl fail on anything other than pass_all.
 479 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 480     [lt_cv_deplibs_check_method=pass_all])
 481
 482 LT_INIT([dlopen win32-dll shared disable-static])
 483 LT_LANG([C++])
 484 LT_LANG([Windows Resource])
 485
 486 DOLT
 487
 488 lt_cv_deplibs_check_method=pass_all
 489
 490 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 491   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 492 ])
 493
 494 dnl
 495 dnl Gettext stuff
 496 dnl
 497 AM_GNU_GETTEXT_VERSION([0.19.8])
 498 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 499
 500 dnl
 501 dnl Iconv stuff
 502 dnl
 503 AM_ICONV
 504
 505 dnl
 506 dnl checks for mingw
 507 AS_IF([test "${SYS}" = "mingw32"], [
 508
 509 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 510 #if !defined(__MINGW32__)
 511 # error Not compiling with mingw
 512 #endif
 513     ])], [
 514
 515 dnl Check for broken versions of mingw-runtime compatability library
 516     AC_MSG_CHECKING(for broken mingw-runtime)
 517     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 518 #include <_mingw.h>
 519 #if defined(__MINGW64_VERSION_MAJOR)
 520 # if __MINGW64_VERSION_MAJOR < 3
 521 #  error Attempting to use mingw-runtime with broken vsnprintf support
 522 # endif
 523 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
 524 # error Attempting to use mingw-runtime with broken vsnprintf support
 525 #endif
 526     ])], [
 527         AC_MSG_RESULT([ok])
 528     ], [
 529         AC_MSG_RESULT([present])
 530         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
 531     ])
 532
 533     dnl force use of mingw provided c99 *printf over msvcrt
 534     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 535
 536     dnl Add WinMainCRTStartup entry point to show it's a WinMain application
 537     VLC_ADD_LDFLAGS([vlc],[-mwindows])
 538
 539     dnl Check for the need to include the mingwex lib for mingw32
 540     VLC_SAVE_FLAGS
 541     AC_CHECK_LIB(mingwex,opendir,
 542         AC_CHECK_LIB(mingw32,opendir,,
 543             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 544     )
 545     VLC_RESTORE_FLAGS
 546     ], [
 547         AC_MSG_RESULT([Not compiling with mingw])
 548     ])
 549
 550     dnl Check for fnative-struct or mms-bitfields support for mingw32
 551     VLC_SAVE_FLAGS
 552     CFLAGS="${CFLAGS} -mms-bitfields"
 553     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
 554     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 555         [ac_cv_c_mms_bitfields],
 556         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 557     if test "${ac_cv_c_mms_bitfields}" = "no"; then
 558         VLC_RESTORE_FLAGS
 559         CFLAGS="${CFLAGS} -fnative-struct"
 560         CXXFLAGS="${CXXFLAGS} -fnative-struct"
 561         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 562             [ac_cv_c_fnative_struct],
 563             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 564         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
 565     fi
 566 ])
 567
 568
 569 dnl
 570 dnl Buggy glibc prevention. Purposedly not cached.
 571 dnl See sourceware.org bugs 5058 and 5443.
 572 dnl Ubuntu alone has 20 bug numbers for this...
 573 dnl
 574 AC_MSG_CHECKING(for buggy GNU/libc versions)
 575 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 576 #include <limits.h>
 577 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 578   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 579 # error GNU/libc with dcgettext killer bug!
 580 #endif
 581 ])], [
 582   AC_MSG_RESULT([not present])
 583 ], [
 584   AC_MSG_RESULT([found])
 585   AS_IF([test "x${enable_nls}" != "xno"], [
 586     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 587 work-around for this. Check with your distribution vendor on how to update the
 588 glibc run-time. Alternatively, build with --disable-nls.])
 589   ])
 590 ])
 591
 592 dnl Plugin compilation stuff
 593
 594 VLC_LIBRARY_SUFFIX
 595
 596 dnl Check for system libs needed
 597 need_libc=false
 598
 599 dnl Check for usual libc functions
 600 AC_CHECK_FUNCS([daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime tdestroy uselocale pthread_cond_timedwait_monotonic_np pthread_condattr_setclock])
 601 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv memrchr nrand48 poll posix_memalign recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tfind timegm timespec_get strverscmp])
 602 AC_REPLACE_FUNCS([gettimeofday])
 603 AC_CHECK_FUNC(fdatasync,,
 604   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 605 ])
 606
 607 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
 608
 609 dnl mingw64 implements those as static inline, not functions with C linkage
 610 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
 611 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
 612 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
 613 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
 614
 615 dnl C11 static_assert()
 616 AC_MSG_CHECKING([for static_assert in assert.h])
 617 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 618 static_assert(1, "The impossible happened.");
 619 ])], [
 620   AC_MSG_RESULT([yes])
 621   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 622 ], [
 623   AC_MSG_RESULT([no])
 624 ])
 625
 626 # Windows CE does not have strcoll()
 627 AC_FUNC_STRCOLL
 628
 629 dnl Check for non-standard system calls
 630 case "$SYS" in
 631   "linux")
 632     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity recvmmsg])
 633     ;;
 634   "mingw32")
 635     AC_CHECK_FUNCS([_lock_file])
 636     ;;
 637 esac
 638
 639 AH_BOTTOM([#include <vlc_fixups.h>])
 640
 641 dnl Check for struct pollfd
 642 AC_CHECK_TYPES([struct pollfd],,,
 643 [#include <sys/types.h>
 644 #if HAVE_POLL
 645 # include <poll.h>
 646 #elif defined (_WIN32)
 647 # include <winsock2.h>
 648 #endif
 649 ])
 650
 651 dnl Check for struct timespec
 652 AC_CHECK_TYPES([struct timespec],,,
 653 [#include <time.h>])
 654
 655 dnl Check for max_align_t
 656 AC_CHECK_TYPES([max_align_t],,,
 657 [#include <stddef.h>])
 658
 659 dnl Checks for socket stuff
 660 VLC_SAVE_FLAGS
 661 SOCKET_LIBS=""
 662 AC_SEARCH_LIBS(connect, [socket], [
 663   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 664     SOCKET_LIBS="$ac_cv_search_connect"
 665   ])
 666 ], [
 667   AS_IF([test "${SYS}" = "mingw32"], [
 668     SOCKET_LIBS="-lws2_32"
 669   ])
 670 ])
 671
 672 AC_SEARCH_LIBS([inet_pton], [nsl], [
 673  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
 674     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
 675   ])
 676 ],, [${SOCKET_LIBS}])
 677
 678 LIBS="${LIBS} ${SOCKET_LIBS}"
 679 AC_LINK_IFELSE([
 680     AC_LANG_PROGRAM([#ifdef _WIN32
 681         # if _WIN32_WINNT < 0x600
 682         #  error Needs vista+
 683         # endif
 684         #include <ws2tcpip.h>
 685         #else
 686         #include <sys/socket.h>
 687         #include <arpa/inet.h>
 688         #endif], [
 689         char dst[[sizeof(struct in_addr)]];
 690         inet_pton(AF_INET, "127.0.0.1", dst);
 691     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 692 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
 693 VLC_RESTORE_FLAGS
 694 AC_SUBST(SOCKET_LIBS)
 695
 696 dnl Check for socklen_t
 697 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 698 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 699 ac_cv_type_socklen_t,
 700 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 701 [#include <sys/types.h>
 702 #ifdef _WIN32
 703 # include <winsock2.h>
 704 # include <ws2tcpip.h>
 705 #else
 706 # include <sys/socket.h>
 707 #endif]], [[socklen_t len; len = 0;]])],
 708 ac_cv_type_socklen_t=yes,
 709 ac_cv_type_socklen_t=no)])
 710 AS_IF([test "$ac_cv_type_socklen_t" = no],
 711  [AC_DEFINE(socklen_t, int)])
 712
 713 dnl Check for struct sockaddr_storage
 714 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 715 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 716 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 717   [AC_TRY_COMPILE(
 718     [#include <sys/types.h>
 719      #if defined( _WIN32 )
 720      # include <winsock2.h>
 721      #else
 722      # include <sys/socket.h>
 723      #endif], [struct sockaddr_storage addr;],
 724      ac_cv_struct_sockaddr_storage=yes,
 725      ac_cv_struct_sockaddr_storage=no)])
 726 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 727   AC_DEFINE(sockaddr_storage, sockaddr)
 728   AC_DEFINE(ss_family, sa_family)
 729 ])
 730
 731 dnl FreeBSD has a gnugetopt library for this:
 732 GNUGETOPT_LIBS=""
 733 AC_CHECK_FUNC(getopt_long,, [
 734   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 735     GNUGETOPT_LIBS="-lgnugetopt"
 736   ])
 737 ])
 738 AC_SUBST(GNUGETOPT_LIBS)
 739
 740 AC_CHECK_LIB(m,cos,[
 741   LIBM="-lm"
 742 ], [
 743   LIBM=""
 744 ])
 745 AC_SUBST(LIBM)
 746
 747 AC_CHECK_LIB(m,lrintf, [
 748   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 749   VLC_ADD_LIBS([skins2],[-lm])
 750 ])
 751 AC_CHECK_LIB(m,nanf,
 752   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 753 )
 754 AC_CHECK_LIB(m,sincos, [
 755   AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
 756 ], [
 757   AC_LIBOBJ([sincos])
 758 ])
 759
 760 dnl Check for dynamic plugins
 761 LIBDL=""
 762 have_dynamic_objects="no"
 763 VLC_SAVE_FLAGS
 764 AC_SEARCH_LIBS(dlsym, [dl svld], [
 765   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 766     LIBDL="$ac_cv_search_dlsym"
 767   ])
 768   have_dynamic_objects="yes"
 769 ])
 770 VLC_RESTORE_FLAGS
 771
 772 # Windows
 773 AS_IF([test "${SYS}" = "mingw32"], [
 774   LIBDL=""
 775   have_dynamic_objects="yes" #assume we can use shared objects
 776 ])
 777
 778 AS_IF([test "${enable_shared}" = "no"], [
 779   have_dynamic_objects=no
 780 ])
 781 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 782
 783 AC_SUBST(LIBDL)
 784
 785 dnl Check for thread library
 786 LIBPTHREAD=""
 787 AS_IF([test "${SYS}" != "mingw32"], [
 788   VLC_SAVE_FLAGS
 789   LIBS=""
 790   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 791     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 792       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 793     ])
 794   ])
 795   VLC_RESTORE_FLAGS
 796 ])
 797 AC_SUBST(LIBPTHREAD)
 798
 799 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
 800   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
 801     LIBRT="$ac_cv_search_clock_nanosleep"
 802   ])
 803 ], [
 804   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
 805     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
 806       LIBRT="$ac_cv_search_nanosleep"
 807     ])
 808   ])
 809 ])
 810 AC_SUBST(LIBRT)
 811
 812 dnl
 813 dnl Check for headers
 814 dnl
 815
 816 dnl  POSIX
 817 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
 818 AC_CHECK_HEADERS([net/if.h], [], [],
 819 [
 820 #include <sys/types.h>
 821 #include <sys/socket.h>
 822 ])
 823 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
 824 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
 825
 826 dnl  BSD
 827 AC_CHECK_HEADERS([netinet/udplite.h sys/param.h sys/mount.h])
 828
 829 dnl  GNU/Linux
 830 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 831
 832 dnl  MacOS
 833 AC_CHECK_HEADERS([xlocale.h])
 834
 835 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 836 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 837 AC_CHECK_TYPE(ssize_t,, [
 838   AC_DEFINE(ssize_t, int)
 839 ])
 840
 841 dnl It seems that autoconf detects pkg-config only during the first
 842 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 843 dnl it is nested within a conditional block, so it was not working right.
 844 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 845 AC_ARG_VAR(PKG_CONFIG_PATH,
 846        [Paths where to find .pc not at the default location])
 847 PKG_PROG_PKG_CONFIG()
 848
 849 dnl On some OS we need static linking
 850 AS_IF([test -n "${PKG_CONFIG}" ],[
 851     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 852         PKG_CONFIG="${PKG_CONFIG} --static"
 853     ])
 854 ])
 855
 856
 857 dnl
 858 dnl Check for zlib.h and -lz along with system -lminizip if available
 859 dnl
 860 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 861 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 862 if test "${have_zlib}" = "yes"
 863 then
 864   VLC_ADD_LIBS([skins2 sap unzip zip],[-lz])
 865   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 866     AC_CHECK_HEADERS([unzip.h], [
 867       have_minizip=yes
 868       MINIZIP_LIBS="-lminizip -lz"
 869     ], [
 870       VLC_ADD_CPPFLAGS([skins2], [-I\\\$(top_srcdir)/modules/access/zip/unzip])
 871       VLC_ADD_LIBS([skins2], [\\\$(top_builddir)/modules/libunzip.la])
 872       have_minizip=no
 873     ])
 874   ])
 875   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
 876   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
 877 fi
 878 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 879
 880
 881 dnl
 882 dnl Domain name i18n support via GNU libidn
 883 dnl
 884 PKG_CHECK_MODULES([IDN], [libidn], [
 885   have_libidn="yes"
 886   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 887 ], [
 888   have_libidn="no"
 889 ])
 890
 891
 892 dnl Check for dbus
 893 AC_ARG_ENABLE(dbus,
 894   [AS_HELP_STRING([--enable-dbus],
 895     [compile D-Bus message bus support (default enabled)])])
 896 have_dbus="no"
 897 AS_IF([test "${enable_dbus}" != "no"], [
 898   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 899     have_dbus="yes"
 900   ], [
 901     AS_IF([test -n "${enable_dbus}"], [
 902       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 903     ], [
 904       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 905     ])
 906   ])
 907 ])
 908 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 909
 910
 911 dnl Check for systemd
 912 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
 913   have_systemd="yes"
 914 ], [
 915   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
 916 ])
 917 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
 918
 919
 920 dnl Check for ntohl, etc.
 921 VLC_SAVE_FLAGS
 922 CFLAGS="${CFLAGS} -Wall -Werror"
 923 AC_CACHE_CHECK([for ntohl in sys/param.h],
 924     [ac_cv_c_ntohl_sys_param_h],
 925     [     AC_TRY_COMPILE([#include <sys/param.h>],
 926         [int meuh; ntohl(meuh);],
 927         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
 928 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
 929     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
 930 fi
 931 VLC_RESTORE_FLAGS
 932
 933 EXTEND_HELP_STRING([Optimization options:])
 934 dnl
 935 dnl  Compiler warnings
 936 dnl
 937
 938 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration init-self logical-op format-security])
 939 RDC_PROG_CC_FLAGS([-pipe])
 940 AC_LANG_PUSH([C++])
 941 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var format-security])
 942 AC_LANG_POP([C++])
 943
 944 dnl
 945 dnl  Debugging mode
 946 dnl
 947 AC_ARG_ENABLE(debug,
 948   [AS_HELP_STRING([--enable-debug],
 949     [build with run-time assertions (default disabled)])],,
 950   [enable_debug="no"])
 951 AH_TEMPLATE(NDEBUG,
 952             [Define to 1 if debug code should NOT be compiled])
 953 AS_IF([test "${enable_debug}" != "no"], [
 954   AC_CHECK_HEADERS([valgrind/valgrind.h])
 955 ], [
 956   AC_DEFINE(NDEBUG)
 957 ])
 958
 959 dnl
 960 dnl  Profiling
 961 dnl
 962 AC_ARG_ENABLE(gprof,
 963   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 964   [enable_gprof="no"])
 965 AS_IF([test "${enable_gprof}" != "no"], [
 966   CFLAGS="${CFLAGS} -pg"
 967   CXXFLAGS="${CXXFLAGS} -pg"
 968   OBJCFLAGS="${OBJCFLAGS} -pg"
 969   LDFLAGS="${LDFLAGS} -pg"
 970 ])
 971
 972 AC_ARG_ENABLE(cprof,
 973   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 974   [enable_cprof="no"])
 975 AS_IF([test "${enable_gprof}" != "no"], [
 976   CFLAGS="${CFLAGS} -finstrument-functions"
 977   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 978   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 979   LDFLAGS="${LDFLAGS} -finstrument-functions"
 980 ])
 981
 982 dnl
 983 dnl  Test coverage
 984 dnl
 985 AC_ARG_ENABLE(coverage,
 986   [AS_HELP_STRING([--enable-coverage],
 987     [build for test coverage (default disabled)])],,
 988   [enable_coverage="no"])
 989 AS_IF([test "${enable_coverage}" != "no"], [
 990   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 991   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 992   LDFLAGS="-lgcov ${LDFLAGS}"
 993 ])
 994
 995 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
 996   VLC_SAVE_FLAGS
 997   CFLAGS="${CFLAGS} -fvisibility=hidden"
 998   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
 999   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
1000   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
1001                  [ac_cv_c_visibility_hidden], [
1002     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1003       ac_cv_c_visibility_hidden=yes
1004     ], [
1005       ac_cv_c_visibility_hidden=no
1006     ])
1007   ])
1008   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1009 ])
1010
1011
1012 dnl
1013 dnl  Enable/disable optimizations
1014 dnl
1015 AC_ARG_ENABLE(optimizations,
1016   [AS_HELP_STRING([--disable-optimizations],
1017     [disable compiler optimizations (default enabled)])],,
1018   [enable_optimizations="yes"])
1019
1020 dnl Check for various optimization flags
1021 AS_IF([test "${enable_optimizations}" != "no"], [
1022
1023   dnl -O3 only in production builds
1024   AS_IF([test "${enable_debug}" = "no"], [
1025     VLC_SAVE_FLAGS
1026     CFLAGS="${CFLAGS} -O3"
1027     CXXFLAGS="${CXXFLAGS} -O3"
1028     OBJCFLAGS="${OBJCFLAGS} -O3"
1029     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1030       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1031         ac_cv_c_o3=yes
1032       ], [
1033         ac_cv_c_o3=no
1034       ])
1035     ])
1036     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1037   ])
1038
1039   dnl Check for fast maths
1040   RDC_PROG_CC_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1041   AC_LANG_PUSH(C++)
1042   RDC_PROG_CXX_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1043   AC_LANG_POP
1044
1045 AH_BOTTOM([
1046 #if defined(_MSC_VER) && !defined(__clang__)
1047 # pragma fenv_access(off)
1048 # pragma fp_contract(on)
1049 #elif defined(__GNUC__)
1050 /* Not supported so far */
1051 #else
1052 # pragma STDC FENV_ACCESS OFF
1053 # pragma STDC FP_CONTRACT ON
1054 #endif
1055 ])
1056
1057   dnl Check for -funroll-loops
1058   VLC_SAVE_FLAGS
1059   CFLAGS="${CFLAGS} -funroll-loops"
1060   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1061   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1062   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1063     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1064       ac_cv_c_unroll_loops=yes
1065     ], [
1066       ac_cv_c_unroll_loops=no
1067     ])
1068   ])
1069   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1070
1071   AS_IF([test "$enable_debug" = "no"], [
1072     dnl Check for -fomit-frame-pointer
1073     VLC_SAVE_FLAGS
1074     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1075     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1076     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1077     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1078       [ac_cv_c_omit_frame_pointer], [
1079       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1080         ac_cv_c_omit_frame_pointer=yes
1081       ], [
1082         ac_cv_c_omit_frame_pointer=no
1083       ])
1084     ])
1085     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1086   ])
1087 ])
1088
1089 VLC_SAVE_FLAGS
1090 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1091 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1092   AC_TRY_LINK([],, [
1093     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1094   ], [
1095     ac_cv_ld_bsymbolic=""
1096   ])
1097 ])
1098 VLC_RESTORE_FLAGS
1099 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1100 AC_SUBST(SYMBOLIC_LDFLAGS)
1101
1102 VLC_SAVE_FLAGS
1103 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1104 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1105   AC_TRY_LINK([],, [
1106     ac_cv_ld_z_defs="yes"
1107   ], [
1108     ac_cv_ld_z_defs="no"
1109   ])
1110 ])
1111 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1112
1113 dnl Checks for __attribute__(aligned()) directive
1114 VLC_SAVE_FLAGS
1115 CFLAGS="${CFLAGS} -Werror"
1116 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1117     [ac_cv_c_attribute_aligned],
1118     [ac_cv_c_attribute_aligned=0
1119     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1120         AC_TRY_COMPILE([],
1121         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1122         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1123     done])
1124 VLC_RESTORE_FLAGS
1125 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1126     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1127         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1128 fi
1129
1130 dnl Check for __attribute__((packed))
1131 AC_CACHE_CHECK([for __attribute__((packed))],
1132   [ac_cv_c_attribute_packed],
1133   [ac_cv_c_attribute_packed=no
1134    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1135                     [ac_cv_c_attribute_packed=yes])])
1136 if test "${ac_cv_c_attribute_packed}" != "no"; then
1137   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1138 fi
1139
1140 dnl
1141 dnl  Check the CPU
1142 dnl
1143 case "${host_cpu}" in
1144   "")
1145     ARCH=unknown
1146     ;;
1147   *)
1148     ARCH="${host_cpu}"
1149     ;;
1150 esac
1151
1152 dnl Check for backtrace() support
1153 AC_CHECK_HEADERS(execinfo.h)
1154 AC_CHECK_FUNCS(backtrace)
1155
1156 dnl
1157 dnl  default modules
1158 dnl
1159 ALIASES="${ALIASES} cvlc rvlc"
1160
1161 dnl
1162 dnl  Accelerated modules
1163 dnl
1164
1165 dnl  Check for fully working MMX intrinsics
1166 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1167 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1168 AC_ARG_ENABLE(mmx,
1169   [AS_HELP_STRING([--disable-mmx],
1170     [disable MMX optimizations (default auto)])],,[
1171   case "${host_cpu}" in
1172     i?86|x86_64)
1173       enable_mmx="yes"
1174       ;;
1175     *)
1176       enable_mmx="no"
1177       ;;
1178   esac
1179 ])
1180 have_mmx="no"
1181 have_mmxext="no"
1182 AS_IF([test "${enable_mmx}" != "no"], [
1183   ARCH="${ARCH} mmx"
1184   VLC_SAVE_FLAGS
1185   CFLAGS="${CFLAGS} -mmmx"
1186   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1187     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1188 [#include <mmintrin.h>
1189 #include <stdint.h>
1190 uint64_t frobzor;]], [
1191 [__m64 a, b, c;
1192 a = b = c = (__m64)frobzor;
1193 a = _mm_slli_pi16(a, 3);
1194 a = _mm_adds_pi16(a, b);
1195 c = _mm_srli_pi16(c, 8);
1196 c = _mm_slli_pi16(c, 3);
1197 b = _mm_adds_pi16(b, c);
1198 a = _mm_unpacklo_pi8(a, b);
1199 frobzor = (uint64_t)a;]])], [
1200       ac_cv_c_mmx_intrinsics=yes
1201     ], [
1202       ac_cv_c_mmx_intrinsics=no
1203     ])
1204   ])
1205   VLC_RESTORE_FLAGS
1206   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1207     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1208   ])
1209
1210   VLC_SAVE_FLAGS
1211   CFLAGS="${CFLAGS} -mmmx"
1212   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1213     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1214 void *p;
1215 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1216 ]])
1217     ], [
1218       ac_cv_mmx_inline=yes
1219     ], [
1220       ac_cv_mmx_inline=no
1221     ])
1222   ])
1223   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1224     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1225     have_mmx="yes"
1226   ])
1227
1228   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1229                  [ac_cv_mmxext_inline], [
1230     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1231 void *p;
1232 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1233 ]])
1234     ], [
1235       ac_cv_mmxext_inline=yes
1236     ], [
1237       ac_cv_mmxext_inline=no
1238     ])
1239   ])
1240   VLC_RESTORE_FLAGS
1241   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1242     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1243     have_mmxext="yes"
1244   ])
1245 ])
1246 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1247 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1248
1249 dnl  Check for fully workin SSE2 intrinsics
1250 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1251 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1252 AC_ARG_ENABLE(sse,
1253   [AS_HELP_STRING([--disable-sse],
1254     [disable SSE (1-4) optimizations (default auto)])],, [
1255   case "${host_cpu}" in
1256     i?86|x86_64)
1257       enable_sse=yes
1258       ;;
1259     *)
1260       enable_sse=no
1261       ;;
1262   esac
1263 ])
1264 have_sse2="no"
1265 AS_IF([test "${enable_sse}" != "no"], [
1266   ARCH="${ARCH} sse sse2"
1267
1268   VLC_SAVE_FLAGS
1269   CFLAGS="${CFLAGS} -msse2"
1270   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1271     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1272 [#include <emmintrin.h>
1273 #include <stdint.h>
1274 uint64_t frobzor;]], [
1275 [__m128i a, b, c;
1276 a = b = c = _mm_set1_epi64((__m64)frobzor);
1277 a = _mm_slli_epi16(a, 3);
1278 a = _mm_adds_epi16(a, b);
1279 c = _mm_srli_epi16(c, 8);
1280 c = _mm_slli_epi16(c, 3);
1281 b = _mm_adds_epi16(b, c);
1282 a = _mm_unpacklo_epi8(a, b);
1283 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1284       ac_cv_c_sse2_intrinsics=yes
1285     ], [
1286       ac_cv_c_sse2_intrinsics=no
1287     ])
1288   ])
1289   VLC_RESTORE_FLAGS
1290   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1291     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1292   ])
1293
1294   VLC_SAVE_FLAGS
1295   CFLAGS="${CFLAGS} -msse"
1296   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1297     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1298 void *p;
1299 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1300 ]])
1301     ], [
1302       ac_cv_sse_inline=yes
1303     ], [
1304       ac_cv_sse_inline=no
1305     ])
1306   ])
1307
1308   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1309     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1310   ])
1311
1312   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1313     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1314 void *p;
1315 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1316 ]])
1317     ], [
1318       ac_cv_sse2_inline=yes
1319     ], [
1320       ac_cv_sse2_inline=no
1321     ])
1322   ])
1323   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1324     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1325     have_sse2="yes"
1326   ])
1327
1328   # SSE3
1329   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1330     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1331 void *p;
1332 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1333 ]])
1334     ], [
1335       ac_cv_sse3_inline=yes
1336     ], [
1337       ac_cv_sse3_inline=no
1338     ])
1339   ])
1340
1341   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1342     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1343   # SSSE3
1344   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1345     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1346 void *p;
1347 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1348 ]])
1349     ], [
1350       ac_cv_ssse3_inline=yes
1351     ], [
1352       ac_cv_ssse3_inline=no
1353     ])
1354   ])
1355
1356   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1357     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1358
1359   # SSE4.1
1360   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1361                  [ac_cv_sse4_1_inline], [
1362     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1363 void *p;
1364 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1365 ]])
1366     ], [
1367       ac_cv_sse4_1_inline=yes
1368     ], [
1369       ac_cv_sse4_1_inline=no
1370     ])
1371   ])
1372
1373   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1374     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1375
1376   # SSE4.2
1377   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1378                  [ac_cv_sse4_2_inline], [
1379     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1380 void *p;
1381 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1382 ]])
1383     ], [
1384       ac_cv_sse4_2_inline=yes
1385     ], [
1386       ac_cv_sse4_2_inline=no
1387     ])
1388   ])
1389
1390   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1391     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1392
1393   # SSE4A
1394   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1395     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1396 void *p;
1397 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1398 ]])
1399     ], [
1400       ac_cv_sse4a_inline=yes
1401     ], [
1402       ac_cv_sse4a_inline=no
1403     ])
1404   ])
1405   VLC_RESTORE_FLAGS
1406   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1407     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1408 ])
1409 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1410
1411 VLC_SAVE_FLAGS
1412 CFLAGS="${CFLAGS} -mmmx"
1413 have_3dnow="no"
1414 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1415   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1416 void *p;
1417 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1418 ]])
1419   ], [
1420     ac_cv_3dnow_inline=yes
1421   ], [
1422     ac_cv_3dnow_inline=no
1423   ])
1424 ])
1425 VLC_RESTORE_FLAGS
1426 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1427   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1428             [Define to 1 if 3D Now! inline assembly is available.])
1429   have_3dnow="yes"
1430 ])
1431 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1432
1433
1434 AC_ARG_ENABLE(neon,
1435   [AS_HELP_STRING([--disable-neon],
1436     [disable NEON optimizations (default auto)])],, [
1437   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1438 ])
1439 AS_IF([test "${enable_neon}" != "no"], [
1440   VLC_SAVE_FLAGS
1441   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1442   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1443     AC_COMPILE_IFELSE([
1444       AC_LANG_PROGRAM(,[[
1445 asm volatile("vqmovun.s64 d0, q1":::"d0");
1446 ]])
1447     ], [
1448       ac_cv_arm_neon="yes"
1449     ], [
1450       ac_cv_arm_neon="no"
1451     ])
1452   ])
1453   VLC_RESTORE_FLAGS
1454 ])
1455 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1456
1457 AC_ARG_ENABLE(arm64,
1458   [AS_HELP_STRING([--disable-arm64],
1459     [disable arm 64-bit optimizations (default auto)])],, [
1460   AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1461 ])
1462 AS_IF([test "${enable_arm64}" != "no"], [
1463   AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1464     AC_COMPILE_IFELSE([
1465       AC_LANG_PROGRAM(,[[
1466 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1467 ]])
1468     ], [
1469       ac_cv_arm64="yes"
1470     ], [
1471       ac_cv_arm64="no"
1472     ])
1473   ])
1474 ])
1475 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1476
1477
1478 AC_ARG_ENABLE(altivec,
1479   [AS_HELP_STRING([--disable-altivec],
1480     [disable AltiVec optimizations (default auto)])],, [
1481   AS_CASE("${host_cpu}", [powerpc*],
1482         [enable_altivec=yes], [enable_altivec=no])
1483 ])
1484 have_altivec="no"
1485 ALTIVEC_CFLAGS=""
1486 AS_IF([test "${enable_altivec}" = "yes"], [
1487   ARCH="${ARCH} altivec";
1488   VLC_SAVE_FLAGS
1489   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1490     [ac_cv_altivec_inline],
1491     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1492          ac_cv_altivec_inline="yes",
1493          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1494           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1495             [ac_cv_altivec_inline="-Wa,-maltivec"],
1496             ac_cv_altivec_inline=no)
1497          ])])
1498   VLC_RESTORE_FLAGS
1499   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1500     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1501               [Define to 1 if AltiVec inline assembly is available.])
1502     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1503       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1504       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1505     ])
1506     have_altivec="yes"
1507   ])
1508
1509   VLC_SAVE_FLAGS
1510   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1511   [ac_cv_c_altivec], [
1512     CFLAGS="${CFLAGS} -maltivec"
1513     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1514 [#include <altivec.h>]], [
1515 [vec_ld(0, (unsigned char *)0);]])], [
1516       ac_cv_c_altivec="-maltivec"
1517     ], [
1518       ac_cv_c_altivec="no"
1519     ])
1520   ])
1521   VLC_RESTORE_FLAGS
1522   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1523     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1524     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1525     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1526     ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1527     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1528     have_altivec="yes"
1529   ])
1530   AC_CHECK_HEADERS(altivec.h)
1531
1532   VLC_SAVE_FLAGS
1533   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1534   AC_CACHE_CHECK([if linker needs -framework vecLib],
1535     [ac_cv_ld_altivec],
1536     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1537   VLC_RESTORE_FLAGS
1538   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1539     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1540   ])
1541 ])
1542 AC_SUBST(ALTIVEC_CFLAGS)
1543 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1544
1545 dnl
1546 dnl  Memory usage
1547 dnl
1548 AC_ARG_ENABLE(optimize-memory,
1549   [AS_HELP_STRING([--enable-optimize-memory],
1550     [optimize memory usage over performance])])
1551 if test "${enable_optimize_memory}" = "yes"; then
1552   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1553 fi
1554
1555 dnl
1556 dnl Allow running as root (useful for people running on embedded platforms)
1557 dnl
1558 AC_ARG_ENABLE(run-as-root,
1559   [AS_HELP_STRING([--enable-run-as-root],
1560     [allow running VLC as root (default disabled)])])
1561 AS_IF([test "${enable_run_as_root}" = "yes"],[
1562     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1563               [Define to 1 to allow running VLC as root (uid 0).])
1564 ])
1565
1566 dnl
1567 dnl Stream output
1568 dnl
1569 AC_ARG_ENABLE(sout,
1570   [AS_HELP_STRING([--disable-sout],
1571     [disable streaming output (default enabled)])])
1572 AS_IF([test "${enable_sout}" != "no"], [
1573   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1574 ])
1575 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1576
1577 dnl Lua modules
1578 AC_ARG_ENABLE(lua,
1579   [AS_HELP_STRING([--disable-lua],
1580     [disable LUA scripting support (default enabled)])])
1581 if test "${enable_lua}" != "no"
1582 then
1583   PKG_CHECK_MODULES(LUA, lua5.2,
1584     [ have_lua=yes ],
1585     [
1586     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1587
1588     PKG_CHECK_MODULES(LUA, lua5.1,
1589       [ have_lua=yes ],
1590       [
1591       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1592       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1593         [ have_lua=yes ],
1594         [
1595           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1596           have_lua=yes
1597           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1598             [],
1599             [ have_lua=no ] )
1600           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1601             [LUA_LIBS="-llua5.2"],
1602           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1603             [LUA_LIBS="-llua5.1"],
1604             AC_CHECK_LIB( lua51 , luaL_newstate,
1605               [LUA_LIBS="-llua51"],
1606               AC_CHECK_LIB( lua , luaL_newstate,
1607                 [LUA_LIBS="-llua"],
1608                 [ have_lua=no
1609                 ], [-lm])
1610             )))
1611         ])
1612       ])
1613     ])
1614   if test "x${have_lua}" != "xyes" ;  then
1615       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1616   fi
1617   AC_ARG_VAR([LUAC], [LUA byte compiler])
1618   AS_IF([test -z "$LUAC"], [
1619      AC_CHECK_TOOL(LUAC, [luac], [false])
1620   ])
1621   AS_IF([test "${LUAC}" = "false"], [
1622     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1623   ])
1624   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1625     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1626   ])
1627 fi
1628 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1629
1630
1631 dnl
1632 dnl HTTP daemon
1633 dnl
1634 AC_ARG_ENABLE(httpd,
1635   [AS_HELP_STRING([--disable-httpd],
1636     [disable the built-in HTTP server (default enabled)])])
1637 if test "${enable_httpd}" != "no"
1638 then
1639   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1640 fi
1641 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1642
1643
1644 dnl
1645 dnl VideoLAN manager
1646 dnl
1647 AC_ARG_ENABLE(vlm,
1648   [AS_HELP_STRING([--disable-vlm],
1649     [disable the stream manager (default enabled)])],,
1650   [enable_vlm="${enable_sout}"])
1651 AS_IF([test "${enable_vlm}" != "no"], [
1652   AS_IF([test "${enable_sout}" = "no"], [
1653     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1654   ])
1655   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1656 ])
1657 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1658
1659
1660 dnl
1661 dnl Addons manager storage and repositories modules
1662 dnl
1663 AC_ARG_ENABLE(addonmanagermodules,
1664   [AS_HELP_STRING([--disable-addonmanagermodules],
1665     [disable the addons manager modules (default enabled)])])
1666 if test "${enable_addonmanagermodules}" != "no"
1667 then
1668   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1669 fi
1670 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1671
1672
1673 dnl
1674 dnl  Input plugins
1675 dnl
1676
1677 EXTEND_HELP_STRING([Input plugins:])
1678
1679 dnl
1680 dnl  libarchive access module
1681 dnl
1682 PKG_ENABLE_MODULES_VLC([ARCHIVE], [access_archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1683
1684 dnl
1685 dnl  live555 input
1686 dnl
1687 AC_ARG_ENABLE(live555,
1688   [AS_HELP_STRING([--enable-live555],
1689     [enable RTSP input through live555 (default enabled)])])
1690
1691 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1692   PKG_CHECK_MODULES(LIVE555, live555, [
1693     VLC_ADD_PLUGIN([live555])
1694     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1695     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1696   ], [
1697     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1698
1699     AC_LANG_PUSH(C++)
1700     VLC_SAVE_FLAGS
1701
1702     dnl detect include paths
1703     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment.hh"], [
1704       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1705     ], [
1706       AS_IF([test "${SYS}" != "os2"], [
1707         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1708         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1709       ], [
1710         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1711         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1712         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1713       ])
1714     ])
1715
1716     dnl CPP Flags
1717     AS_IF([test "${SYS}" = "solaris"], [
1718       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1719     ])
1720     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1721     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1722
1723     dnl version check
1724     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1725       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1726 [#include <liveMedia_version.hh>
1727 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1728 # error BOOM
1729 #endif]])
1730       ], [
1731         ac_cv_live555="yes"
1732       ], [
1733         ac_cv_live555="no"
1734       ])
1735     ])
1736
1737     AS_IF([test "$ac_cv_live555" = "no"], [
1738       AC_MSG_WARN([live555 is missing or its installed version is too old:
1739 Version 2011.12.23 or later is required to proceed.
1740 You can get an updated one from http://www.live555.com/liveMedia .])
1741       AS_IF([test -n "${enable_live555}"], [
1742         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1743       ])
1744     ], [
1745       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1746       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1747       AS_IF([test "${SYS}" = "mingw32"], [
1748         # add ws2_32 for closesocket, select, recv
1749         other_libs="$other_libs -lws2_32"
1750       ])
1751
1752       dnl We need to check for pic because live555 don't provide shared libs
1753       dnl and we want to build a plugins so we need -fPIC on some arch.
1754       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1755       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1756       AC_CHECK_LIB(liveMedia_pic, main, [
1757         VLC_ADD_PLUGIN([live555])
1758         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1759       ],[
1760         AC_CHECK_LIB(liveMedia, main, [
1761           VLC_ADD_PLUGIN([live555])
1762           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1763         ],[],[${other_libs}])
1764       ],[${other_libs_pic}])
1765     ])
1766     VLC_RESTORE_FLAGS
1767     AC_LANG_POP(C++)
1768   ])
1769 ])
1770
1771 dnl
1772 dnl IIDC and DV FireWire input modules
1773 dnl
1774 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1775 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1776
1777 dnl
1778 dnl - linsys modules: access module check for libzvbi
1779 dnl
1780 AC_ARG_ENABLE(linsys,
1781   [AS_HELP_STRING([--enable-linsys],
1782     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1783 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1784   VLC_ADD_PLUGIN([linsys_hdsdi])
1785   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1786     VLC_ADD_PLUGIN([linsys_sdi])
1787   ], [
1788     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1789   ])
1790 ])
1791
1792 dnl
1793 dnl dvdread module: check for libdvdread
1794 dnl
1795 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1796
1797 dnl
1798 dnl libdvdnav plugin
1799 dnl
1800 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1801 AS_IF([test "${enable_dvdnav}" != "no"], [
1802   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1803     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1804       AC_MSG_RESULT(yes)
1805       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1806       ],[
1807       AC_MSG_RESULT(no)
1808     ])
1809 ])
1810
1811 dnl
1812 dnl  Blu-ray Disc Support with libbluray
1813 dnl
1814 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1815
1816 dnl
1817 dnl  OpenCV wrapper and example filters
1818 dnl
1819 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1820
1821
1822 dnl
1823 dnl  libsmbclient plugin
1824 dnl
1825 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1826 AS_IF([test "${SYS}" = "mingw32" -a "${enable_smbclient}" != "no"], [ VLC_ADD_PLUGIN([smb]) ])
1827
1828 dnl
1829 dnl  liBDSM access module
1830 dnl
1831 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1832
1833 dnl
1834 dnl sftp access support
1835 dnl
1836 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1837
1838 dnl
1839 dnl nfs access support
1840 dnl
1841 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1842
1843 dnl
1844 dnl  Video4Linux 2
1845 dnl
1846 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1847   [disable Video4Linux version 2 (default auto)])])
1848 have_v4l2="no"
1849 AS_IF([test "$enable_v4l2" != "no"], [
1850   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1851     have_v4l2="yes"
1852   ])
1853 ])
1854 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1855
1856 dnl
1857 dnl special access module for Blackmagic SDI cards
1858 dnl
1859 AC_ARG_ENABLE(decklink,
1860   [AS_HELP_STRING([--disable-decklink],
1861     [disable Blackmagic DeckLink SDI input (default auto)])])
1862 AC_ARG_WITH(decklink_sdk,
1863   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1864     [                        location of Blackmagic DeckLink SDI SDK])])
1865 have_decklink=no
1866 if test "${enable_decklink}" != "no"
1867 then
1868   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1869   then
1870     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1871   fi
1872   VLC_SAVE_FLAGS
1873   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1874   AC_LANG_PUSH(C++)
1875   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1876       have_decklink=yes
1877   ], [
1878       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1879   ])
1880   AC_LANG_POP(C++)
1881   VLC_RESTORE_FLAGS
1882 fi
1883 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1884
1885
1886 dnl
1887 dnl  Built-in CD-DA and VCD module
1888 dnl
1889 AC_ARG_ENABLE(vcd,
1890   [AS_HELP_STRING([--disable-vcd],
1891     [disable built-in VCD and CD-DA support (default enabled)])])
1892
1893 AC_ARG_ENABLE(libcddb,
1894   [AS_HELP_STRING([--disable-libcddb],
1895     [disable CDDB for Audio CD (default enabled)])])
1896
1897 if test "${enable_vcd}" != "no"
1898 then
1899   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1900   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1901     AC_MSG_RESULT(yes)
1902     VLC_ADD_PLUGIN([vcd cdda])
1903   ],[
1904     AC_MSG_RESULT(no)
1905   ])
1906
1907   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1908   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1909     AC_MSG_RESULT(yes)
1910     VLC_ADD_PLUGIN([vcd cdda])
1911     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1912   ],[
1913     AC_MSG_RESULT(no)
1914   ])
1915
1916   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1917   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1918     AC_MSG_RESULT(yes)
1919     VLC_ADD_PLUGIN([vcd cdda])
1920     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1921   ],[
1922     AC_MSG_RESULT(no)
1923   ])
1924
1925   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1926   then
1927     VLC_ADD_PLUGIN([vcd cdda])
1928   fi
1929
1930   if test "$enable_libcddb" != "no"; then
1931     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1932       HAVE_LIBCDDB=yes
1933       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1934       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1935       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1936       ],:
1937       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1938       HAVE_LIBCDDB=no])
1939   fi
1940 fi
1941
1942 dnl
1943 dnl Linux DVB
1944 dnl
1945 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1946   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1947 [#include <linux/dvb/version.h>
1948 #if (DVB_API_VERSION < 5)
1949 # error Linux DVB API v3.2 and older are not supported.
1950 #endif
1951 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1952 # error Linux DVB API v5.0 is unsupported. Please update.
1953 #endif
1954 ]])], [
1955   ac_cv_linux_dvb_5_1=yes
1956 ], [
1957   ac_cv_linux_dvb_5_1=no
1958 ])])
1959 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1960
1961 dnl
1962 dnl  Screen capture module
1963 dnl
1964 AC_ARG_ENABLE(screen,
1965   [AS_HELP_STRING([--enable-screen],
1966     [disable screen capture (default enabled)])])
1967 if test "${enable_screen}" != "no"; then
1968   if test "${SYS}" = "darwin"; then
1969     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1970       VLC_ADD_PLUGIN([screen])
1971     ])
1972   fi
1973 fi
1974 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1975
1976 dnl
1977 dnl  VNC/RFB access module
1978 dnl
1979 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1980
1981 dnl  RDP/Remote Desktop access module
1982 dnl
1983 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1984
1985 dnl
1986 dnl  Real RTSP plugin
1987 dnl
1988 AC_ARG_ENABLE(realrtsp,
1989   [  --enable-realrtsp       Real RTSP module (default disabled)])
1990 if test "${enable_realrtsp}" = "yes"; then
1991   VLC_ADD_PLUGIN([access_realrtsp])
1992 fi
1993
1994 dnl
1995 dnl QTKit
1996 AC_ARG_ENABLE(macosx-qtkit,
1997   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
1998 if test "x${enable_macosx_qtkit}" != "xno" &&
1999   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
2000 then
2001   AC_CHECK_HEADERS(QTKit/QTKit.h, [
2002       VLC_ADD_PLUGIN([qtsound])
2003     ])
2004 fi
2005
2006 dnl
2007 dnl AVFoundation
2008 AC_SUBST(have_avfoundation, ["no"])
2009 AC_ARG_ENABLE(macosx-avfoundation,
2010   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
2011 if test "x${enable_macosx_avfoundation}" != "xno" &&
2012   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2013 then
2014   SAVED_LIBS="${LIBS}"
2015   LIBS="-framework AVFoundation"
2016   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2017   LIBS="${SAVED_LIBS}"
2018   if test "${have_avfoundation}" != "no"
2019   then
2020     VLC_ADD_PLUGIN([avcapture])
2021   fi
2022 fi
2023 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2024
2025 dnl
2026 dnl  DCP plugin (using asdcplib)
2027 dnl
2028 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2029 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2030
2031 dnl
2032 dnl  Demux plugins
2033 dnl
2034
2035 EXTEND_HELP_STRING([Mux/Demux plugins:])
2036
2037 dnl
2038 dnl  libdvbpsi check for ts mux/demux
2039 dnl
2040 have_dvbpsi="no"
2041 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2042 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2043
2044
2045 dnl
2046 dnl  GME demux plugin
2047 dnl
2048 AC_ARG_ENABLE(gme,
2049   [AS_HELP_STRING([--enable-gme],
2050     [use Game Music Emu (default auto)])])
2051 AS_IF([test "${enable_gme}" != "no"], [
2052   AC_CHECK_HEADER([gme/gme.h], [
2053     VLC_ADD_LIBS([gme], [-lgme])
2054     VLC_ADD_PLUGIN([gme])
2055   ], [
2056     AS_IF([test "x${enable_gme}" != "x"], [
2057       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2058     ])
2059   ])
2060 ])
2061
2062
2063 dnl
2064 dnl  SIDPlay plugin
2065 dnl
2066 AC_ARG_ENABLE(sid,
2067     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2068 AS_IF([test "${enable_sid}" != "no"], [
2069     PKG_CHECK_MODULES(SID, [libsidplay2], [
2070         AC_LANG_PUSH(C++)
2071         oldCPPFLAGS="$CPPFLAGS"
2072         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2073         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2074             VLC_ADD_PLUGIN([sid])
2075             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2076             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2077         ], [
2078             AS_IF([test -n "${enable_sid}"],
2079                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2080                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2081                 )
2082         ])
2083         CPPFLAGS="$oldCPPFLAGS"
2084         AC_LANG_POP(C++)
2085     ], [
2086         AS_IF([test "x${enable_sid}" = "xyes"],
2087             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2088             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2089             )
2090     ])
2091 ])
2092
2093
2094 dnl
2095 dnl  ogg demux plugin
2096 dnl
2097 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2098 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2099     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2100 ],[true])
2101 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2102 if test "${enable_sout}" != "no"; then
2103 dnl Check for libshout
2104     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2105 fi
2106
2107 dnl
2108 dnl  matroska demux plugin
2109 dnl
2110 PKG_ENABLE_MODULES_VLC([MATROSKA], [mkv], [libebml libmatroska], [MKV format support], [auto])
2111
2112 dnl
2113 dnl  modplug demux plugin
2114 dnl
2115 AC_ARG_ENABLE(mod,
2116   [AS_HELP_STRING([--disable-mod],
2117     [do not use libmodplug (default auto)])])
2118 if test "${enable_mod}" != "no" ; then
2119     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2120           VLC_ADD_PLUGIN([mod])
2121           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2122           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2123           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2124     ],[
2125        AS_IF([test -n "${enable_mod}"],
2126          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2127          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2128     ])
2129 fi
2130
2131 dnl
2132 dnl  mpc demux plugin
2133 dnl
2134 AC_ARG_ENABLE(mpc,
2135   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2136 if test "${enable_mpc}" != "no"
2137 then
2138   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2139     VLC_ADD_PLUGIN([mpc])
2140     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2141     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2142     VLC_ADD_PLUGIN([mpc])
2143     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2144 fi
2145
2146 dnl
2147 dnl  Codec plugins
2148 dnl
2149
2150 EXTEND_HELP_STRING([Codec plugins:])
2151
2152 dnl
2153 dnl wmafixed plugin
2154 dnl
2155 AC_ARG_ENABLE(wma-fixed,
2156   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2157 if test "${enable_wma_fixed}" = "yes"
2158 then
2159   VLC_ADD_PLUGIN([wma_fixed])
2160 fi
2161
2162 dnl
2163 dnl shine encoder plugin
2164 dnl
2165 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2166
2167
2168 dnl
2169 dnl openmax il codec plugin
2170 dnl
2171 AC_ARG_ENABLE(omxil,
2172   [  --enable-omxil          openmax il codec module (default disabled)])
2173 if test "${enable_omxil}" = "yes"
2174 then
2175   VLC_ADD_PLUGIN([omxil])
2176 fi
2177
2178 dnl
2179 dnl openmax il vout plugin
2180 dnl
2181 AC_ARG_ENABLE(omxil-vout,
2182   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2183 if test "${enable_omxil_vout}" = "yes"
2184 then
2185   VLC_ADD_PLUGIN([omxil_vout])
2186 fi
2187
2188 dnl
2189 dnl raspberry pi openmax il configuration
2190 dnl
2191 AC_ARG_ENABLE(rpi-omxil,
2192   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2193 if test "${enable_rpi_omxil}" = "yes"
2194 then
2195   VLC_ADD_PLUGIN([omxil omxil_vout])
2196   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2197 fi
2198
2199 dnl
2200 dnl CrystalHD codec plugin
2201 dnl
2202 AC_ARG_ENABLE(crystalhd,
2203   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2204 if test "${enable_crystalhd}" != "no"; then
2205     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2206       VLC_ADD_PLUGIN([crystalhd])
2207       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2208     ],[
2209       if test "${SYS}" = "mingw32" ; then
2210         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2211           VLC_ADD_PLUGIN([crystalhd])
2212           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2213             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2214             ])
2215         ],[
2216           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2217                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2218                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2219         ],[#define __LINUX_USER__
2220                #include <libcrystalhd/bc_dts_types.h>
2221         ])
2222       fi
2223     ],[
2224        #include <libcrystalhd/bc_dts_types.h>
2225       ])
2226 fi
2227
2228 dnl
2229 dnl  mad plugin
2230 dnl
2231 have_mad="no"
2232 MAD_CFLAGS=""
2233 MAD_LIBS=""
2234
2235 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2236   enable_mad="yes"
2237 ], [
2238   with_mad="no"
2239 ])
2240 AS_IF([test "${with_mad}" != "no"], [
2241   MAD_CFLAGS="-I${with_mad}/include"
2242   MAD_LIBS="-L${with_mad}/lib"
2243 ])
2244
2245 AC_ARG_ENABLE(mad,
2246   [  --enable-mad            libmad module (default enabled)])
2247 AS_IF([test "${enable_mad}" != "no"], [
2248   VLC_SAVE_FLAGS
2249   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2250   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2251   AC_CHECK_HEADERS(mad.h, [
2252     AC_CHECK_LIB(mad, mad_bit_init, [
2253       have_mad="yes"
2254       MAD_LIBS="${MAD_LIBS} -lmad"
2255     ])
2256   ])
2257   VLC_RESTORE_FLAGS
2258   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2259     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2260   ])
2261 ])
2262 AC_SUBST(MAD_CFLAGS)
2263 AC_SUBST(MAD_LIBS)
2264 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2265
2266 dnl  mpg123 plugin
2267 dnl
2268 dnl
2269 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2270
2271
2272 AC_ARG_ENABLE(merge-ffmpeg,
2273 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2274   enable_merge_ffmpeg="no"
2275 ])
2276 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2277
2278 AC_MSG_CHECKING([for libavutil variant])
2279 PKG_CHECK_EXISTS([libavutil], [
2280   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2281   libavutil_micro="${libavutil_version##*.}"
2282   AS_IF([test ${libavutil_micro} -le 99], [
2283     avfork="libav"
2284   ], [
2285     avfork="ffmpeg"
2286   ])
2287 ], [
2288   avfork="none"
2289 ])
2290 AC_MSG_RESULT([${avfork}])
2291
2292 dnl
2293 dnl gstreamer stuff
2294 dnl
2295 AC_ARG_ENABLE(gst-decode,
2296   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2297
2298 have_gst_decode="no"
2299 AS_IF([test "${enable_gst_decode}" != "no"], [
2300   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2301     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2302       have_gst_decode="yes"
2303     ], [
2304       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2305     ])
2306   ], [
2307     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2308   ])
2309 ])
2310 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2311
2312 dnl
2313 dnl  avcodec decoder/encoder plugin
2314 dnl
2315 AC_ARG_ENABLE(avcodec,
2316 [  --enable-avcodec        libavcodec codec (default enabled)])
2317 AS_IF([test "${enable_avcodec}" != "no"], [
2318   dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2319   case "${avfork}" in
2320     libav) av_codec_ver="57.16.0" ;;
2321     ffmpeg) av_codec_ver="57.37.100" ;;
2322     *) AC_MSG_ERROR([Missing libav or FFmpeg])
2323   esac
2324   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2325     VLC_SAVE_FLAGS
2326     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2327     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2328     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2329     AC_CHECK_HEADERS(libavutil/avutil.h)
2330     VLC_RESTORE_FLAGS
2331     have_avcodec="yes"
2332   ],[
2333     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2334   ])
2335 ], [
2336   have_avcodec="no"
2337 ])
2338 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2339
2340 dnl
2341 dnl libva needs avcodec
2342 dnl
2343 AC_ARG_ENABLE(libva,
2344   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2345
2346 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2347   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2348 ])
2349
2350 have_vaapi="no"
2351 have_vaapi_drm="no"
2352 have_vaapi_x11="no"
2353 AS_IF([test "${enable_libva}" != "no"], [
2354   PKG_CHECK_MODULES([LIBVA], [libva >= 0.37], [
2355     have_vaapi="yes"
2356   ], [
2357     AS_IF([test -n "${enable_libva}"], [
2358       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2359     ], [
2360       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2361     ])
2362   ])
2363   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2364     have_vaapi_drm="yes"
2365   ], [
2366     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2367   ])
2368   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2369     have_vaapi_x11="yes"
2370   ], [
2371     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2372   ])
2373 ])
2374 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2375 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2376
2377 have_avcodec_vaapi="no"
2378 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2379   VLC_SAVE_FLAGS
2380   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2381   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2382   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2383     AC_MSG_NOTICE([VA API acceleration activated])
2384     have_avcodec_vaapi="yes"
2385   ],[
2386     AS_IF([test -n "${enable_libva}"], [
2387       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2388     ], [
2389       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2390     ])
2391   ])
2392   VLC_RESTORE_FLAGS
2393 ])
2394 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2395
2396 dnl
2397 dnl dxva2 needs avcodec
2398 dnl
2399 AC_ARG_ENABLE(dxva2,
2400   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2401
2402 have_avcodec_dxva2="no"
2403 AS_IF([test "${enable_dxva2}" != "no"], [
2404   if test "${SYS}" = "mingw32"; then
2405   AS_IF([test "x${have_avcodec}" = "xyes"], [
2406     AC_CHECK_HEADERS(dxva2api.h,
2407       [
2408         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2409            AC_MSG_NOTICE([DxVA2 acceleration activated])
2410            have_avcodec_dxva2="yes"
2411         ],[
2412     AS_IF([test "${enable_dxva2}" = "yes"],
2413           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2414               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2415         ], [#undef _WIN32_WINNT
2416             /* DXVA2 is only available in Vista and above */
2417             #define _WIN32_WINNT 0x600])
2418       ],[
2419     AS_IF([test "${enable_dxva2}" = "yes"],
2420               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2421               [AC_MSG_WARN([dxva2api.h not found])])
2422       ],[#include <d3d9.h>])
2423   ],[
2424     AS_IF([test "x${enable_dxva2}" != "x"], [
2425       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2426     ])
2427   ])
2428   fi
2429 ])
2430 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2431
2432 dnl
2433 dnl d3d11va needs avcodec
2434 dnl
2435 AC_ARG_ENABLE(d3d11va,
2436   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2437
2438 have_avcodec_d3d11va="no"
2439 AS_IF([test "${enable_d3d11va}" != "no"], [
2440   if test "${SYS}" = "mingw32"; then
2441   AS_IF([test "x${have_avcodec}" = "xyes"], [
2442         AC_CHECK_TYPES([ID3D11VideoDecoder],
2443           [
2444             AC_CHECK_HEADERS(dxva2api.h,
2445               [
2446                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2447                    AC_MSG_NOTICE([D3D11 acceleration activated])
2448                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2449                    have_avcodec_d3d11va="yes"
2450                 ],[
2451                   AS_IF([test "${enable_d3d11va}" = "yes"],
2452                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2453                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2454                   ], [#undef _WIN32_WINNT
2455                       /* D3D11 is only available in Vista and above */
2456                       #define _WIN32_WINNT 0x600])
2457                   ],[
2458                     AS_IF([test "${enable_d3d11va}" = "yes"],
2459                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2460                           [AC_MSG_WARN([dxva2api.h not found])])
2461                   ],[#include <d3d9.h>])
2462           ],[
2463             AS_IF([test "${enable_d3d11va}" = "yes"],
2464                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2465                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2466           ], [#include <d3d11.h>])
2467   ],[
2468     AS_IF([test "x${enable_d3d11va}" != "x"], [
2469       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2470     ])
2471   ])
2472   fi
2473 ])
2474 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2475
2476 dnl
2477 dnl DXGI debug
2478 dnl
2479 AC_CHECK_HEADERS(dxgidebug.h)
2480
2481 dnl
2482 dnl vda needs avcodec
2483 dnl
2484 AC_ARG_ENABLE(vda,
2485   [  --enable-vda          VDA  support (default auto)])
2486
2487 have_avcodec_vda="no"
2488 AS_IF([test "${enable_vda}" != "no"], [
2489   if test "${SYS}" = "darwin"; then
2490   AS_IF([test "x${have_avcodec}" = "xyes"], [
2491     AC_CHECK_HEADERS(VideoDecodeAcceleration/VDADecoder.h,
2492       [
2493         AC_CHECK_HEADERS(libavcodec/vda.h, [
2494            have_avcodec_vda="yes"
2495         ],[
2496         AS_IF([test "${enable_vda}" = "yes"],
2497               [AC_MSG_ERROR([vda is present but libavcodec/vda.h is missing])],
2498               [AC_MSG_WARN([vda is present but libavcodec/vda.h is missing ])])
2499         ])
2500   ],[
2501         AS_IF([test "${enable_vda}" = "yes"],
2502               [AC_MSG_ERROR([Could not find required VideoDecodeAcceleration/VDADecoder.h])],
2503               [AC_MSG_WARN([VideoDecodeAcceleration/VDADecoder.h not found])])
2504       ])
2505   ],[
2506     AS_IF([test "x${enable_vda}" != "x"], [
2507       AC_MSG_ERROR([--enable-vda and --disable-avcodec options are mutually exclusive.])
2508     ])
2509  ])
2510  AS_IF([test "${have_avcodec_vda}" = "yes"], [
2511      SAVE_LIBS=$LIBS
2512      LIBS="$LIBS $AVCODEC_LIBS"
2513      AC_CHECK_FUNCS([av_vda_alloc_context])
2514      LIBS=$SAVE_LIBS
2515  ])
2516  fi
2517 ])
2518 AM_CONDITIONAL([HAVE_AVCODEC_VDA], [test "${have_avcodec_vda}" = "yes"])
2519
2520 dnl
2521 dnl  avformat demuxer/muxer plugin
2522 dnl
2523
2524 AC_ARG_ENABLE(avformat,
2525 [  --enable-avformat       libavformat containers (default enabled)],, [
2526   enable_avformat="${have_avcodec}"
2527 ])
2528 have_avformat="no"
2529 AS_IF([test "${enable_avformat}" != "no"], [
2530   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2531       have_avformat="yes"
2532       VLC_SAVE_FLAGS
2533       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2534       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2535       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2536       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2537       AC_CHECK_HEADERS(libavutil/avutil.h)
2538       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2539         have_avformat="no"
2540       ])
2541       VLC_RESTORE_FLAGS
2542     ],[
2543       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2544   ])
2545 ])
2546 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2547
2548 dnl
2549 dnl  swscale image scaling and conversion plugin
2550 dnl
2551
2552 AC_ARG_ENABLE(swscale,
2553   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2554           (default enabled)]))
2555 if test "${enable_swscale}" != "no"
2556 then
2557   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2558     [
2559       VLC_SAVE_FLAGS
2560       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2561       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2562       AC_CHECK_HEADERS(libswscale/swscale.h)
2563       AC_CHECK_HEADERS(libavutil/avutil.h)
2564       VLC_ADD_PLUGIN([swscale])
2565       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2566       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2567       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2568         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2569       ])
2570       VLC_RESTORE_FLAGS
2571     ],[
2572       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2573   ])
2574 fi
2575
2576 dnl
2577 dnl  postproc plugin
2578 dnl
2579
2580 AC_ARG_ENABLE(postproc,
2581 [  --enable-postproc       libpostproc image post-processing (default auto)])
2582 if test "${enable_postproc}" != "no"
2583 then
2584   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2585     [
2586       VLC_SAVE_FLAGS
2587       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2588       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2589       AC_CHECK_HEADERS(postproc/postprocess.h)
2590       VLC_ADD_PLUGIN([postproc])
2591       VLC_RESTORE_FLAGS
2592     ],[
2593       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2594   ])
2595 fi
2596
2597 dnl
2598 dnl  faad decoder plugin
2599 dnl
2600 AC_ARG_ENABLE(faad,
2601 [  --enable-faad           faad codec (default auto)])
2602 have_faad="no"
2603 AS_IF([test "${enable_faad}" != "no"], [
2604   AC_CHECK_HEADERS([neaacdec.h], [
2605     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2606
2607     AS_IF([test "${have_faad}" = "yes"], [
2608       VLC_ADD_PLUGIN([faad])
2609       VLC_ADD_LIBS([faad],[-lfaad])
2610     ], [
2611       AS_IF([test "${enable_faad}" = "yes"], [
2612         AC_MSG_ERROR([cannot find FAAD library])
2613       ], [
2614         AC_MSG_WARN([cannot find FAAD library])
2615       ])
2616     ])
2617   ])
2618 ])
2619
2620 dnl
2621 dnl  AOM decoder plugin
2622 dnl
2623 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec], [disabled])
2624
2625 dnl
2626 dnl libvpx decoder plugin
2627 dnl
2628 AC_ARG_ENABLE(vpx,
2629     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2630 AS_IF([test "${enable_vpx}" != "no"],[
2631     PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2632         VLC_ADD_PLUGIN([vpx])
2633         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2634         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2635         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2636             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2637         ], [], [${VPX_LIBS}])
2638         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2639             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2640         ], [], [${VPX_LIBS}])
2641         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2642             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2643         ], [], [${VPX_LIBS}])
2644         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2645             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2646         ], [], [${VPX_LIBS}])
2647     ], [
2648     AS_IF([test "${enable_vpx}" = "yes"],[
2649         AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2650     ])])
2651 ])
2652
2653 dnl
2654 dnl twolame encoder plugin
2655 dnl
2656 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2657
2658 dnl
2659 dnl fdk-aac encoder plugin
2660 dnl
2661 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2662
2663
2664 dnl
2665 dnl A52/AC3 decoder plugin
2666 dnl
2667 AC_ARG_ENABLE(a52,
2668   [  --enable-a52            A/52 support with liba52 (default enabled)])
2669 if test "${enable_a52}" != "no"
2670 then
2671   AC_ARG_WITH(a52,
2672     [  --with-a52=PATH         a52 headers and libraries])
2673     if test -z "${with_a52}"
2674     then
2675       LDFLAGS_test=""
2676       CPPFLAGS_test=""
2677     else
2678       LDFLAGS_test="-L${with_a52}/lib"
2679       CPPFLAGS_test="-I${with_a52}/include"
2680     fi
2681     VLC_SAVE_FLAGS
2682     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2683     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2684     AC_CHECK_HEADERS(a52dec/a52.h, [
2685       AC_CHECK_LIB(a52, a52_free, [
2686         VLC_ADD_PLUGIN([a52])
2687         VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52])
2688         VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2689       ],[
2690         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2691         ], [$LIBM])
2692     ],[
2693       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2694     ])
2695     VLC_RESTORE_FLAGS
2696 fi
2697
2698 dnl
2699 dnl DTS Coherent Acoustics decoder plugin
2700 dnl
2701 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2702
2703 dnl
2704 dnl  Flac plugin
2705 dnl
2706 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2707
2708 dnl
2709 dnl  Libmpeg2 plugin
2710 dnl
2711 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2712
2713 dnl
2714 dnl  Vorbis plugin
2715 dnl
2716 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2717
2718 dnl
2719 dnl  Tremor plugin
2720 dnl
2721 AC_ARG_ENABLE(tremor,
2722   [  --enable-tremor         Tremor decoder support (default disabled)])
2723 if test "${enable_tremor}" = "yes"
2724 then
2725   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2726     VLC_ADD_PLUGIN([tremor])
2727    ],[])
2728 fi
2729
2730 dnl
2731 dnl  Speex plugins
2732 dnl
2733 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2734 have_speexdsp="no"
2735 AS_IF([test "${enable_speex}" != "no"], [
2736   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2737     have_speexdsp="yes"
2738   ], [
2739     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2740   ])
2741 ])
2742 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2743
2744 dnl
2745 dnl  Opus plugin
2746 dnl
2747 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2748
2749 dnl
2750 dnl  theora decoder plugin
2751 dnl
2752 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2753
2754 dnl
2755 dnl  OggSpots decoder plugin
2756 dnl
2757 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2758
2759 dnl
2760 dnl  Daala decoder plugin
2761 dnl
2762 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2763
2764 dnl
2765 dnl  schroedinger decoder plugin (for dirac format video)
2766 dnl
2767 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2768
2769 dnl
2770 dnl  PNG decoder module
2771 dnl
2772 AC_ARG_ENABLE(png,
2773   [  --enable-png            PNG support (default enabled)])
2774 AS_IF([test "${enable_png}" != "no"], [
2775 AC_CHECK_HEADERS(png.h, [
2776   VLC_SAVE_FLAGS
2777   LDFLAGS="${LDFLAGS} -lz $LIBM"
2778   AC_CHECK_LIB(png, png_set_rows, [
2779     VLC_ADD_PLUGIN([png])
2780   ], [], [-lz $LIBM])
2781   VLC_RESTORE_FLAGS
2782   ])
2783 ])
2784
2785 dnl
2786 dnl  JPEG decoder module
2787 dnl
2788 AC_ARG_ENABLE(jpeg,
2789   [  --enable-jpeg           JPEG support (default enabled)])
2790 AS_IF([test "${enable_jpeg}" != "no"], [
2791 AC_CHECK_HEADERS(jpeglib.h, [
2792   VLC_ADD_PLUGIN([jpeg])
2793   ])
2794 ])
2795
2796 dnl
2797 dnl  BPG decoder module
2798 dnl
2799 AC_ARG_ENABLE(bpg,
2800   [  --enable-bpg           BPG support (default disabled)])
2801 AS_IF([test "${enable_bpg}" != "no"], [
2802 AC_CHECK_HEADERS(libbpg.h, [
2803   VLC_ADD_PLUGIN([bpg])
2804   ])
2805 ])
2806
2807 dnl
2808 dnl H262 encoder plugin (lib262)
2809 dnl
2810 AC_ARG_ENABLE(x262,
2811   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2812 if test "${enable_x262}" != "no"; then
2813     PKG_CHECK_MODULES(X262, x262, [
2814         VLC_ADD_PLUGIN([x262])
2815         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2816         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2817           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2818         ])
2819         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2820         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2821           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2822         fi
2823     ], [
2824        if test "${enable_x262}" = "yes"; then
2825         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2826        fi
2827     ])
2828 fi
2829
2830 dnl x265 encoder
2831 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2832
2833 dnl
2834 dnl H264 encoder plugin (10-bit lib264)
2835 dnl
2836 AC_ARG_ENABLE(x26410b,
2837   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2838 if test "${enable_x26410b}" != "no"; then
2839     PKG_CHECK_MODULES(X26410B, x26410b, [
2840         VLC_ADD_PLUGIN([x26410b])
2841         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2842         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2843           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2844         ])
2845         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2846         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2847           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2848         fi
2849     ], [
2850        if test "${enable_x26410b}" = "yes"; then
2851         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2852        fi
2853     ])
2854 fi
2855
2856
2857 dnl
2858 dnl H264 encoder plugin (using libx264)
2859 dnl
2860 AC_ARG_ENABLE(x264,
2861   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2862 if test "${enable_x264}" != "no"; then
2863       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2864         VLC_ADD_PLUGIN([x264])
2865         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2866
2867         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2868           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2869         ])
2870
2871         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2872         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2873           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2874         fi
2875       ],[
2876         if test "${enable_x264}" = "yes"; then
2877             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2878           fi
2879       ])
2880 fi
2881
2882 dnl
2883 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2884 dnl
2885 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2886
2887 dnl
2888 dnl libfluidsynth (MIDI synthetizer) plugin
2889 dnl
2890 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2891 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2892 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2893
2894 dnl
2895 dnl Teletext Modules
2896 dnl vbi decoder plugin (using libzbvi)
2897 dnl telx module
2898 dnl uncompatible
2899 dnl
2900 AC_ARG_ENABLE(zvbi,
2901   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2902                   libzvbi (default enabled)]))
2903 AC_ARG_ENABLE(telx,
2904   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2905                   zvbi) (default enabled if zvbi is absent)]))
2906
2907 AS_IF( [test "${enable_zvbi}" != "no"],[
2908     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2909         [
2910           VLC_ADD_PLUGIN([zvbi])
2911           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2912           AS_IF( [test "${enable_telx}" = "yes"],[
2913                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2914                   ])
2915         ],[
2916           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2917         ])
2918     ])
2919 AS_IF( [test "${enable_telx}" != "no" ],[
2920   VLC_ADD_PLUGIN([telx])
2921   ])
2922
2923 dnl
2924 dnl libass subtitle rendering module
2925 dnl
2926 AC_ARG_ENABLE(libass,
2927   [  --enable-libass         Subtitle support using libass (default enabled)])
2928 AS_IF( [test "${enable_libass}" != "no"], [
2929   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2930       [
2931         VLC_ADD_PLUGIN([libass])
2932
2933         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2934           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2935            VLC_ADD_LIBS([libass],[-lfontconfig])
2936        ])
2937       ],[
2938         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2939       ])
2940   ])
2941
2942 dnl
2943 dnl ARIB subtitles rendering module
2944 dnl
2945 AC_ARG_ENABLE(aribsub,
2946   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2947 AS_IF( [test "${enable_aribsub}" != "no" ],[
2948   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2949       have_aribb24="yes"
2950       VLC_ADD_PLUGIN([aribsub])
2951       VLC_ADD_LIBS([aribsub],[-laribb24])
2952       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2953     ],[
2954       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2955       have_aribb24="no"
2956   ])
2957 ])
2958 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2959
2960 dnl
2961 dnl ARIB B25
2962 dnl
2963 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2964
2965 dnl
2966 dnl  kate decoder plugin
2967 dnl
2968 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2969
2970 dnl
2971 dnl  tiger rendering for kate decoder plugin
2972 dnl
2973 AC_ARG_ENABLE(tiger,
2974 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2975 AS_IF([test "${enable_tiger}" != "no"], [
2976   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2977       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2978         AS_IF([test -n "${enable_tiger}"], [
2979           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2980         ])
2981   ])
2982 ])
2983
2984
2985 dnl
2986 dnl  Video plugins
2987 dnl
2988
2989 EXTEND_HELP_STRING([Video plugins:])
2990
2991 dnl
2992 dnl  OpenGL
2993 dnl
2994 PKG_CHECK_MODULES([EGL], [egl], [
2995   have_egl="yes"
2996 ], [
2997   have_egl="no"
2998 ])
2999 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3000
3001 have_gl="no"
3002 PKG_CHECK_MODULES([GL], [gl], [
3003   have_gl="yes"
3004 ], [
3005   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3006 #ifdef _WIN32
3007 # include <GL/glew.h>
3008 #endif
3009 #include <GL/gl.h>
3010 ]], [
3011     [int t0 = GL_TEXTURE0;]])
3012   ], [
3013     GL_CFLAGS=""
3014     have_gl="yes"
3015     AS_IF([test "${SYS}" != "mingw32"], [
3016       GL_LIBS="-lGL"
3017     ], [
3018       GL_LIBS="-lopengl32"
3019     ])
3020   ])
3021 ])
3022 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3023
3024 dnl OpenGL ES 2: depends on EGL 1.1
3025 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3026 dnl OpenGL ES 1: depends on EGL 1.0
3027 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [disabled])
3028
3029 dnl
3030 dnl  Xlib
3031 dnl
3032
3033 AC_PATH_XTRA()
3034 AC_CHECK_HEADERS(X11/Xlib.h)
3035
3036 dnl
3037 dnl  X C Bindings modules
3038 dnl
3039 AC_ARG_ENABLE(xcb,
3040   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3041   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3042     enable_xcb="yes"
3043   ], [
3044     enable_xcb="no"
3045   ])
3046 ])
3047 AC_ARG_ENABLE(xvideo,
3048   [  --enable-xvideo         XVideo support (default enabled)],, [
3049     enable_xvideo="$enable_xcb"
3050 ])
3051
3052 have_xcb="no"
3053 have_xcb_keysyms="no"
3054 have_xcb_randr="no"
3055 have_xcb_xvideo="no"
3056 AS_IF([test "${enable_xcb}" != "no"], [
3057   dnl libxcb
3058   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3059   have_xcb="yes"
3060   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3061   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3062   PKG_CHECK_MODULES(XPROTO, [xproto])
3063
3064   AS_IF([test "${enable_xvideo}" != "no"], [
3065     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3066   ])
3067
3068   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3069
3070   dnl xcb-utils
3071   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3072     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3073   ])
3074 ])
3075 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3076 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3077 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3078 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3079
3080
3081 dnl
3082 dnl VDPAU needs X11
3083 dnl
3084 AC_ARG_ENABLE(vdpau,
3085   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3086 have_vdpau="no"
3087 AS_IF([test "${enable_vdpau}" != "no"], [
3088   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3089     have_vdpau="yes"
3090     AS_IF([test "${no_x}" = "yes"], [
3091       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3092     ])
3093   ], [
3094     AS_IF([test -n "${enable_vdpau}"], [
3095       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3096     ])
3097   ])
3098 ])
3099 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3100
3101 have_avcodec_vdpau="no"
3102 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3103   case "${avfork}" in
3104     libav) av_vdpau_ver="56.10.0" ;;
3105     ffmpeg) av_vdpau_ver="56.19.100" ;;
3106   esac
3107   PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3108     have_avcodec_vdpau="yes"
3109     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3110   ], [
3111     AS_IF([test -n "${enable_vdpau}"], [
3112       AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3113     ], [
3114       AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3115     ])
3116   ])
3117 ])
3118 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3119
3120
3121 dnl
3122 dnl  Wayland
3123 dnl
3124 AC_ARG_ENABLE(wayland,
3125   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3126 have_wayland="no"
3127 AC_ARG_VAR([WAYLAND_SCANNER], [Wayland scanner utility])
3128
3129 AS_IF([test "${enable_wayland}" != "no"], [
3130   AC_MSG_CHECKING([for the Wayland scanner])
3131   AS_IF([test -z "$WAYLAND_SCANNER"], [
3132     PKG_CHECK_EXISTS([wayland-scanner], [
3133       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3134     ], [
3135       WAYLAND_SCANNER="wayland-scanner"
3136     ])
3137   ])
3138   AC_MSG_RESULT([$WAYLAND_SCANNER])
3139
3140   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3141     have_wayland="yes"
3142   ], [
3143     AS_IF([test -n "${enable_wayland}"], [
3144       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3145     ])
3146   ])
3147
3148   AS_IF([test "${have_egl}" = "yes"], [
3149     PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3150       have_wayland_egl="yes"
3151     ], [
3152       AS_IF([test -n "${enable_wayland}"], [
3153         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3154       ])
3155     ])
3156   ])
3157 ])
3158 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3159 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3160
3161
3162 dnl
3163 dnl  SDL module
3164 dnl
3165 AC_ARG_ENABLE(sdl,
3166   [  --enable-sdl            SDL support (default enabled)])
3167 AC_ARG_ENABLE(sdl-image,
3168   [  --enable-sdl-image      SDL image support (default enabled)])
3169 if test "${enable_sdl}" != "no"
3170 then
3171    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3172       # SDL on Darwin is heavily patched and can only run SDL_image
3173       if test "${SYS}" != "darwin"; then
3174         VLC_ADD_PLUGIN([vout_sdl])
3175       fi
3176
3177       # SDL_image
3178       AS_IF([ test "${enable_sdl_image}" != "no"],[
3179         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3180           VLC_ADD_PLUGIN([sdl_image])],
3181           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3182           ])
3183       ])
3184    ],[
3185      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3186    ])
3187 fi
3188
3189 dnl
3190 dnl  freetype module
3191 dnl
3192 AC_ARG_ENABLE(freetype,
3193   [  --enable-freetype       freetype support   (default auto)])
3194 AC_ARG_ENABLE(fribidi,
3195   [  --enable-fribidi        fribidi support    (default auto)])
3196 AC_ARG_ENABLE(harfbuzz,
3197   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3198 AC_ARG_ENABLE(fontconfig,
3199   [  --enable-fontconfig     fontconfig support (default auto)])
3200
3201 AC_ARG_WITH([default-font],
3202     AS_HELP_STRING([--with-default-font=PATH],
3203         [Path to the default font]),
3204         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3205             "$withval", [Default font])])
3206 AC_ARG_WITH([default-monospace-font],
3207     AS_HELP_STRING([--with-default-monospace-font=PATH],
3208         [Path to the default font]),
3209         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3210             "$withval", [Default monospace font])])
3211
3212 AC_ARG_WITH([default-font-family],
3213     AS_HELP_STRING([--with-default-font-family=NAME],
3214         [Path to the default font family]),
3215         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3216             "$withval", [Default font family])])
3217 AC_ARG_WITH([default-monospace-font-family],
3218     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3219         [Path to the default font family]),
3220         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3221             "$withval", [Default monospace font family])])
3222
3223 have_freetype="no"
3224 have_fontconfig="no"
3225 have_fribidi="no"
3226 have_harfbuzz="no"
3227
3228 if test "${enable_freetype}" != "no"; then
3229    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3230       have_freetype="yes"
3231       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3232       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3233
3234       dnl fontconfig support
3235       if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
3236           if test "${enable_fontconfig}" != "no"; then
3237             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3238               have_fontconfig="yes"
3239             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3240           fi
3241       fi
3242
3243       dnl fribidi support
3244       if test "${enable_fribidi}" != "no"; then
3245         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3246           have_fribidi="yes"
3247           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3248           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3249         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3250       fi
3251
3252       dnl harfbuzz support
3253       if test "${have_fribidi}" != "no"; then
3254         if test "${enable_harfbuzz}" != "no"; then
3255           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3256             have_harfbuzz="yes"
3257             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3258             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3259           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3260         fi
3261       fi
3262   ],[
3263   AS_IF([test -n "${enable_freetype}"],[
3264     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3265     ])
3266   ])
3267 fi
3268
3269 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3270 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3271 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3272 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3273
3274 dnl
3275 dnl SAPI (text to Speech renderer for Windows)
3276 dnl
3277 AC_LANG_PUSH([C++])
3278 AC_CHECK_TYPES([ISpObjectToken],[
3279               have_sapi="yes"
3280             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3281               [#include <windows.h>
3282                #include <sapi.h>
3283                #include <sphelper.h>])
3284 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3285 AC_LANG_POP([C++])
3286
3287 dnl
3288 dnl  SVG module (text rendering and image decoding)
3289 dnl
3290 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3291 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3292
3293 dnl
3294 dnl  Windows DirectX module
3295 dnl
3296
3297 AC_ARG_ENABLE(directx,
3298   [AS_HELP_STRING([--enable-directx],
3299     [Microsoft DirectX support (default enabled on Windows)])],, [
3300   AS_IF([test "${SYS}" = "mingw32"], [
3301     enable_directx="yes"
3302   ], [
3303     enable_directx="no"
3304   ])
3305 ])
3306 AS_IF([test "${enable_directx}" != "no"], [
3307   dnl DirectDraw
3308   AC_CHECK_HEADERS(ddraw.h, [
3309     VLC_ADD_PLUGIN([directdraw])
3310   ])
3311
3312   dnl OpenGL
3313   AC_CHECK_HEADERS(GL/wglew.h, [
3314     VLC_ADD_PLUGIN([glwin32 wgl])
3315   ],, [
3316     #include <windows.h>
3317     #include <GL/gl.h>
3318   ])
3319
3320   dnl Direct3D11
3321   AC_CHECK_HEADERS(d3d11.h, [
3322     VLC_ADD_PLUGIN([direct3d11])
3323   ])
3324
3325   dnl Direct3D9
3326   AC_CHECK_HEADERS(d3d9.h, [
3327     VLC_ADD_PLUGIN([direct3d9])
3328   ])
3329
3330 ])
3331
3332 dnl
3333 dnl  Linux framebuffer module
3334 dnl
3335 AC_CHECK_HEADER([linux/fb.h], [
3336   VLC_ADD_PLUGIN([fb])
3337 ])
3338
3339
3340 dnl
3341 dnl  DirectFB module
3342 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3343 dnl  TODO: support for static linking
3344 dnl
3345 AC_ARG_ENABLE(directfb,
3346   [  --enable-directfb       DirectFB support (default disabled)])
3347 AC_ARG_WITH(directfb,
3348   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3349
3350 if test "${enable_directfb}" = "yes"; then
3351     have_directfb="false"
3352     CPPFLAGS_mydirectfb=
3353     LIBS_mydirectfb=
3354     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3355         dnl Trying the given location
3356         VLC_SAVE_FLAGS
3357
3358         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3359         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3360
3361         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3362         LIBS="${LIBS} ${LIBS_new}"
3363
3364         dnl FIXME: too obscure
3365         AC_CHECK_HEADER([directfb.h], [
3366             AC_CHECK_LIB([direct],[direct_initialize], [
3367                 AC_CHECK_LIB([fusion], [fusion_enter], [
3368                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3369                 ], have_directfb="false")
3370             ], have_directfb="false")
3371         ], have_directfb="false")
3372
3373         VLC_RESTORE_FLAGS
3374
3375         if test "${have_directfb}" = "true"; then
3376             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3377             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3378         fi
3379     else
3380         dnl Look for directfb-config
3381         AC_CHECK_PROG(DIRECTFB_CONFIG, [directfb-config], [false])
3382         AS_IF(["${DIRECTFB_CONFIG}" != "false"], [
3383             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3384             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3385             have_directfb="true"
3386         ], [
3387             dnl Trying with pkg-config
3388             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3389                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3390                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3391                 have_directfb="true"
3392                 ], [have_directfb="false"])
3393         ])
3394     fi
3395     if test "${have_directfb}" = "true"; then
3396         VLC_ADD_PLUGIN([directfb])
3397         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3398         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3399     else
3400         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3401     fi
3402 fi
3403
3404 dnl
3405 dnl  AA plugin
3406 dnl
3407 AC_ARG_ENABLE(aa,
3408   [  --enable-aa             aalib output (default disabled)])
3409 if test "${enable_aa}" = "yes"
3410 then
3411   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3412   if test "${have_aa}" = "true"
3413   then
3414     VLC_ADD_PLUGIN([aa])
3415   fi
3416 fi
3417
3418 dnl
3419 dnl  libcaca plugin
3420 dnl
3421 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3422
3423 dnl
3424 dnl  OS/2 KVA plugin
3425 dnl
3426 AC_ARG_ENABLE(kva,
3427   [AS_HELP_STRING([--enable-kva],
3428     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3429   AS_IF([test "$SYS" = "os2"], [
3430     enable_kva="yes"
3431   ])
3432 ])
3433 have_kva="no"
3434 KVA_LIBS=""
3435 AS_IF([test "$enable_kva" != "no"], [
3436   AC_CHECK_HEADERS([kva.h], [
3437     have_kva="yes"
3438     AC_CHECK_LIB(kva, main, [
3439       KVA_LIBS="-lkva"
3440     ])
3441   ])
3442 ])
3443 AC_SUBST(KVA_LIBS)
3444 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3445
3446 dnl
3447 dnl MMAL plugin
3448 dnl
3449 AC_ARG_ENABLE(mmal,
3450   AS_HELP_STRING([--enable-mmal],
3451     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3452 if test "${enable_mmal}" != "no"; then
3453   VLC_SAVE_FLAGS
3454   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3455   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3456   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3457     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3458         have_mmal="yes"
3459         VLC_ADD_PLUGIN([mmal])
3460         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3461         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3462         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lvchostif ]) ], [
3463           AS_IF([test "${enable_mmal}" = "yes"],
3464             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3465             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3466           ],
3467         [])
3468     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3469       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3470       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3471   VLC_RESTORE_FLAGS
3472 fi
3473 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3474
3475 dnl
3476 dnl evas plugin
3477 dnl
3478 AC_ARG_ENABLE(evas,
3479   [AS_HELP_STRING([--enable-evas],
3480     [use evas output module (default disabled)])])
3481 have_evas="no"
3482 AS_IF([test "${enable_evas}" = "yes"], [
3483   PKG_CHECK_MODULES(EVAS, [evas >= 1.15.99 ecore >= 1.15.99], [
3484       have_evas="yes"
3485       AC_DEFINE([HAVE_EVAS], [1], [Define to 1 if evas is enabled.])
3486     ],[
3487     AS_IF([test "x${enable_evas}" != "x"], [
3488       AC_MSG_ERROR([$EVAS_PKG_ERRORS. libevas and libecore 1.15.99 or later required.])
3489     ])
3490   ])
3491 ])
3492 AM_CONDITIONAL([HAVE_EVAS], [test "${have_evas}" = "yes"])
3493
3494 dnl
3495 dnl  Audio plugins
3496 dnl
3497
3498 EXTEND_HELP_STRING([Audio plugins:])
3499
3500 dnl
3501 dnl  Pulseaudio module
3502 dnl
3503 AC_ARG_ENABLE(pulse,
3504   [AS_HELP_STRING([--enable-pulse],
3505     [use the PulseAudio client library (default auto)])])
3506 have_pulse="no"
3507 AS_IF([test "${enable_pulse}" != "no"], [
3508   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3509     have_pulse="yes"
3510   ], [
3511     AS_IF([test "x${enable_pulse}" != "x"], [
3512       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3513     ])
3514   ])
3515 ])
3516 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3517
3518 dnl
3519 dnl  ALSA module
3520 dnl
3521 AC_ARG_ENABLE(alsa,
3522   [AS_HELP_STRING([--enable-alsa],
3523     [support the Advanced Linux Sound Architecture (default auto)])],, [
3524   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3525     enable_alsa="yes"
3526   ])
3527 ])
3528 have_alsa="no"
3529 AS_IF([test "${enable_alsa}" != "no"], [
3530   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3531     have_alsa="yes"
3532   ], [
3533     AS_IF([test "x${enable_alsa}" != "x"], [
3534       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3535     ])
3536   ])
3537 ])
3538 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3539
3540 dnl
3541 dnl  Open Sound System module
3542 dnl
3543 AC_ARG_ENABLE(oss,
3544   [AS_HELP_STRING([--enable-oss],
3545     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3546   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3547     enable_oss="no"
3548   ])
3549 ])
3550 have_oss="no"
3551 OSS_LIBS=""
3552 AS_IF([test "$enable_oss" != "no"], [
3553   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3554     have_oss="yes"
3555     AC_CHECK_LIB(ossaudio, main, [
3556       OSS_LIBS="-lossaudio"
3557     ])
3558   ])
3559 ])
3560 AC_SUBST(OSS_LIBS)
3561 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3562
3563 dnl
3564 dnl  OpenBSD sndio module
3565 dnl
3566 AC_ARG_ENABLE([sndio],
3567   [AS_HELP_STRING([--disable-sndio],
3568     [support the OpenBSD sndio (default auto)])],, [
3569   AS_IF([test "$SYS" = "openbsd"], [
3570     enable_sndio="yes"
3571   ])
3572 ])
3573 have_sndio="no"
3574 AS_IF([test "$enable_sndio" != "no"], [
3575   AC_CHECK_HEADER([sndio.h], [
3576     have_sndio="yes"
3577   ])
3578 ])
3579 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3580
3581 dnl
3582 dnl  Windows Audio Session plugin
3583 dnl
3584 AC_ARG_ENABLE([wasapi],
3585   [AS_HELP_STRING([--enable-wasapi],
3586     [use the Windows Audio Session API (default auto)])
3587 ])
3588 have_wasapi="no"
3589 AS_IF([test "$enable_wasapi" != "no"], [
3590   AC_CHECK_HEADER([audioclient.h], [
3591     have_wasapi="yes"
3592   ], [
3593     AS_IF([test "x${enable_wasapi}" != "x"], [
3594       AC_MSG_ERROR([Windows Audio Session API not found.])
3595     ])
3596   ])
3597 ])
3598 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3599
3600 dnl
3601 dnl  AudioQueue plugin
3602 dnl
3603 AC_ARG_ENABLE(audioqueue,
3604   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3605 if test "${enable_audioqueue}" = "yes"
3606 then
3607   VLC_ADD_PLUGIN([audioqueue])
3608 fi
3609
3610 dnl
3611 dnl  JACK modules
3612 dnl
3613 AC_ARG_ENABLE(jack,
3614   [AS_HELP_STRING([--disable-jack],
3615     [do not use jack (default auto)])])
3616 have_jack="no"
3617 AS_IF([test "${enable_jack}" != "no"], [
3618     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3619       [ have_jack=yes ],
3620       [
3621       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3622
3623       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3624       [ have_jack=yes ],
3625       [
3626       AS_IF([test -n "${enable_jack}"],
3627          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3628          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3629       ])
3630     ])
3631 ])
3632 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3633
3634 dnl
3635 dnl  OpenSLES Android
3636 dnl
3637 AC_ARG_ENABLE(opensles,
3638   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3639 if test "${HAVE_ANDROID}" = "1"; then
3640   if test "${enable_opensles}" = "yes"; then
3641       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3642         [ VLC_ADD_PLUGIN([opensles_android]) ],
3643         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3644   fi
3645 fi
3646
3647 dnl
3648 dnl  Tizen audio
3649 dnl
3650 AC_ARG_ENABLE(tizen_audio,
3651   [AS_HELP_STRING([--enable-tizen-audio],
3652     [Tizen audio module (default enabled on Tizen)])],, [
3653   AS_IF([test "$HAVE_TIZEN" = "1"], [
3654     enable_tizen_audio="yes"
3655   ])
3656 ])
3657 if test "${enable_tizen_audio}" = "yes"; then
3658   AC_CHECK_HEADERS(audio_io.h,
3659     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3660     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3661 fi
3662
3663 dnl
3664 dnl libsamplerate plugin
3665 dnl
3666 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3667
3668 dnl
3669 dnl  soxr module
3670 dnl
3671 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3672
3673 dnl
3674 dnl  OS/2 KAI plugin
3675 dnl
3676 AC_ARG_ENABLE(kai,
3677   [AS_HELP_STRING([--enable-kai],
3678     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3679   AS_IF([test "$SYS" = "os2"], [
3680     enable_kai="yes"
3681   ])
3682 ])
3683 have_kai="no"
3684 KAI_LIBS=""
3685 AS_IF([test "$enable_kai" != "no"], [
3686   AC_CHECK_HEADERS([kai.h], [
3687     have_kai="yes"
3688     AC_CHECK_LIB(kai, main, [
3689       KAI_LIBS="-lkai"
3690     ])
3691   ])
3692 ])
3693 AC_SUBST(KAI_LIBS)
3694 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3695
3696 dnl
3697 dnl  chromaprint audio track fingerprinter
3698 dnl
3699 m4_pushdef([libchromaprint_version], 0.6.0)
3700 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3701     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3702     AS_IF([test "${enable_chromaprint}" = "yes"],
3703         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3704         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3705          ),
3706     [(Chromaprint based audio fingerprinter)],[auto])
3707 m4_popdef([libchromaprint_version])
3708
3709 dnl
3710 dnl  Chromecast streaming support
3711 dnl
3712 m4_pushdef([protobuf_lite_version], 2.5.0)
3713 AC_ARG_VAR(PROTOC, [protobuf compiler])
3714 AC_CHECK_PROGS(PROTOC, protoc, no)
3715 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3716     AS_IF([test "x${PROTOC}" != "xno"], [
3717         build_chromecast="yes"
3718     ], [
3719     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3720     ])
3721 ], [
3722     AS_IF([test "${enable_chromecast}" = "yes"],
3723         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3724         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3725     )
3726     enable_chromecast="no"
3727 ], [(Chromecast streaming support)], [auto])
3728 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3729 m4_popdef([protobuf_lite_version])
3730
3731 dnl
3732 dnl  Interface plugins
3733 dnl
3734
3735 EXTEND_HELP_STRING([Interface plugins:])
3736
3737 dnl
3738 dnl QT
3739 dnl
3740 AC_ARG_ENABLE(qt, [
3741   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3742   AS_IF([test "${SYS}" = "darwin"], [
3743     enable_qt="no"
3744   ])
3745 ])
3746 have_qt5_x11="no"
3747 AS_IF([test "${enable_qt}" != "no"], [
3748   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.2.0 Qt5Widgets Qt5Gui], [
3749       PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3750           have_qt5_x11="yes"
3751       ],[
3752           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3753       ])
3754       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3755       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3756       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3757       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3758       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3759     ], [
3760       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.8.0],, [
3761         AS_IF([test -n "${enable_qt}"],[
3762           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3763         ],[
3764           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3765         ])
3766         enable_qt="no"
3767       ])
3768       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3769       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin"])
3770       AC_PATH_PROG(RCC, rcc, rcc, [${QT_PATH}/bin])
3771       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin"])
3772     ])
3773 ])
3774 AS_IF([test "${enable_qt}" != "no"], [
3775   VLC_ADD_PLUGIN([qt])
3776   ALIASES="${ALIASES} qvlc"
3777 ])
3778 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3779 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3780
3781 dnl
3782 dnl detect kde4-config patch (used for kde solids).
3783 dnl
3784 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3785 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3786   KDE4_CONFIG="kde4-config"
3787 ])
3788
3789 dnl
3790 dnl Simple test for skins2 dependency
3791 dnl
3792 AS_IF([test "$enable_qt" = "no"], [
3793   AS_IF([test "${enable_skins2}" = "yes"], [
3794     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3795   ], [
3796     enable_skins2="no"
3797     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3798   ])
3799 ])
3800
3801 dnl
3802 dnl Skins2 module
3803 dnl
3804 AC_ARG_ENABLE(skins2,
3805   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3806 AS_IF([test "${enable_skins2}" != "no"], [
3807   have_skins_deps="yes"
3808
3809   dnl Win32
3810   AS_IF([test "${SYS}" = "mingw32"], [
3811     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3812     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3813   dnl MacOS
3814   ], [test "${SYS}" = "darwin"], [
3815     VLC_ADD_CPPFLAGS([skins2],[ -DMACOSX_SKINS])
3816     VLC_ADD_LIBS([skins2],[-Wl,-framework,Carbon])
3817   dnl OS/2
3818   ], [test "${SYS}" = "os2"], [
3819     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3820   dnl Linux/Unix
3821   ], [
3822     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3823     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3824     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3825     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3826     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3827   ])
3828
3829   dnl for All OSes
3830   VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3831
3832   dnl we need freetype
3833   AS_IF([test "${have_freetype}" != "yes"], [
3834     have_skins_deps="no"
3835   ])
3836
3837   AS_IF([test "${have_skins_deps}" = "no"], [
3838     AS_IF([test "x${enable_skins2}" = "x"], [
3839       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3840     ], [
3841       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3842     ])
3843     enable_skins2="no"
3844   ], [
3845     VLC_ADD_PLUGIN([skins2])
3846     ALIASES="${ALIASES} svlc"
3847     enable_skins2="yes"
3848   ])
3849 ])
3850 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3851
3852 AC_ARG_ENABLE(libtar,
3853   [  --enable-libtar         libtar support for skins2 (default auto)])
3854 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3855   AC_CHECK_HEADERS(libtar.h, [
3856     VLC_ADD_LIBS([skins2],[-ltar])
3857   ])
3858 ])
3859
3860 dnl
3861 dnl  MacOS X gui module
3862 dnl
3863 AC_ARG_ENABLE(macosx,
3864   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3865 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3866 then
3867   VLC_ADD_PLUGIN([macosx])
3868
3869   if test ! -d ${CONTRIB_DIR}/BGHUDAppKit.framework
3870   then
3871     AC_MSG_ERROR([BGHUDAppKit framework is required and was not found in ${CONTRIB_DIR}])
3872   fi
3873 fi
3874 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no"])
3875
3876 dnl
3877 dnl  MacOS X sparkle update support
3878 dnl
3879 AC_ARG_ENABLE(sparkle,
3880   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3881 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3882 then
3883   if test ! -d ${CONTRIB_DIR}/Sparkle.framework
3884   then
3885     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3886   fi
3887
3888   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3889 fi
3890 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3891
3892
3893 dnl
3894 dnl  Minimal Mac OS X module
3895 dnl
3896 AC_ARG_ENABLE(minimal-macosx,
3897   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3898 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3899 then
3900   VLC_ADD_PLUGIN([minimal_macosx])
3901 fi
3902
3903 dnl
3904 dnl  VideoToolbox plugins
3905 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3906     VLC_ADD_PLUGIN([videotoolbox])
3907     VLC_ADD_PLUGIN([cvpx_i420])
3908   ])
3909
3910 dnl
3911 dnl  ncurses module
3912 dnl
3913 AC_ARG_ENABLE(ncurses,
3914 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3915 have_ncurses="no"
3916 AS_IF([test "${enable_ncurses}" != "no"] ,[
3917   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3918     have_ncurses="yes"
3919     ALIASES="${ALIASES} nvlc"
3920   ], [
3921     AS_IF([test -n "${enable_ncurses}"], [
3922       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3923     ])
3924   ])
3925 ])
3926 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3927
3928 dnl
3929 dnl  Lirc plugin
3930 dnl
3931 AC_ARG_ENABLE(lirc,
3932   [  --enable-lirc           lirc support (default disabled)])
3933 have_lirc="no"
3934 AS_IF([test "${enable_lirc}" = "yes"], [
3935   AC_CHECK_HEADER(lirc/lirc_client.h, [
3936     AC_CHECK_LIB(lirc_client, lirc_init, [
3937       have_lirc="true"
3938     ])
3939   ])
3940 ])
3941 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3942
3943 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3944 dnl
3945 dnl  goom visualization plugin
3946 dnl
3947 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3948
3949 dnl
3950 dnl libprojectM visualization plugin
3951 dnl
3952 AC_ARG_ENABLE(projectm,
3953   [  --enable-projectm       projectM visualization plugin (default enabled)])
3954 AS_IF([test "${enable_projectm}" != "no"],
3955   [
3956     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3957     [
3958       VLC_ADD_PLUGIN([projectm])
3959       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3960         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3961         [ AC_MSG_WARN( [Using libprojectM version 1] )
3962       ])
3963     ],[
3964       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3965     ])
3966   ])
3967
3968 dnl
3969 dnl Vovoid VSXu visualization plugin
3970 dnl
3971 AC_ARG_ENABLE(vsxu,
3972   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3973 AS_IF([test "${enable_vsxu}" != "no"],
3974   [
3975     PKG_CHECK_MODULES(VSXU, libvsxu,
3976     [
3977       VLC_ADD_PLUGIN([vsxu])
3978     ],[
3979       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3980     ])
3981   ])
3982
3983 EXTEND_HELP_STRING([Service Discovery plugins:])
3984 dnl
3985 dnl  Avahi-Zeroconf services discovery
3986 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
3987
3988 dnl
3989 dnl  libudev services discovery
3990 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3991
3992 dnl
3993 dnl MTP devices services discovery
3994 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3995
3996 dnl
3997 dnl UPnP Plugin (Intel SDK)
3998 dnl
3999 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
4000
4001 dnl
4002 dnl mDNS using libmicrodns
4003 dnl
4004 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
4005
4006
4007 EXTEND_HELP_STRING([Misc options:])
4008
4009 dnl
4010 dnl  libxml2 module
4011 dnl
4012 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4013
4014
4015 dnl
4016 dnl libgcrypt
4017 dnl
4018 AC_ARG_ENABLE(libgcrypt,
4019   [  --disable-libgcrypt     gcrypt support (default enabled)])
4020 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
4021 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4022
4023 # require libgcrypt >= 1.6.0
4024 AS_IF([test "${enable_libgcrypt}" != "no"], [
4025   AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4026     VLC_SAVE_FLAGS
4027     CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4028     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4029 [#include <gcrypt.h>
4030 #if GCRYPT_VERSION_NUMBER < 0x010600
4031 #error
4032 #endif]])], [
4033       ac_cv_lib_gcrypt=yes
4034     ], [
4035       ac_cv_lib_gcrypt=no
4036     ])
4037     VLC_RESTORE_FLAGS
4038   ])
4039
4040   AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4041     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4042   ], [
4043     AS_IF([test "${enable_libgcrypt}" = "yes"], [
4044       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4045     ])
4046   ])
4047 ])
4048
4049 AS_IF([test -z "$GCRYPT_LIBS"], [
4050   GCRYPT_LIBS="-lgcrypt -lgpg-error"
4051 ])
4052
4053 AC_SUBST(GCRYPT_CFLAGS)
4054 AC_SUBST(GCRYPT_LIBS)
4055 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4056
4057 dnl
4058 dnl TLS/SSL
4059 dnl
4060 AC_ARG_ENABLE(gnutls,
4061   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4062 AS_IF([test "${enable_gnutls}" != "no"], [
4063   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.2.0], [
4064     VLC_ADD_PLUGIN([gnutls])
4065   ], [
4066     AS_IF([test -n "${enable_gnutls}"], [
4067       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4068     ])
4069   ])
4070 ])
4071
4072
4073 dnl
4074 dnl Taglib plugin
4075 dnl
4076 AC_ARG_ENABLE(taglib,
4077   [AS_HELP_STRING([--disable-taglib],
4078     [do not use TagLib (default enabled)])])
4079 AS_IF([test "${enable_taglib}" != "no"], [
4080   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4081     VLC_ADD_PLUGIN([taglib])
4082   ], [
4083     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4084 ])
4085
4086 dnl
4087 dnl  libsecret
4088 dnl
4089 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4090
4091 dnl
4092 dnl  kwallet
4093 dnl
4094 AC_ARG_ENABLE(kwallet,
4095   [AS_HELP_STRING([--enable-kwallet],
4096     [use kwallet (via D-Bus) for keystore (default enabled)])])
4097 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4098   VLC_ADD_PLUGIN([kwallet])
4099 ])
4100
4101 dnl
4102 dnl  Developers helper modules (should be hidden from configure help)
4103 dnl
4104 AC_ARG_ENABLE(devtools, [], [], [enable_devtools="no"])
4105 AS_IF([test "${enable_devtools}" != "no"], [
4106   VLC_ADD_PLUGIN([accesstweaks])
4107 ])
4108
4109 dnl
4110 dnl update checking system
4111 dnl
4112 AC_ARG_ENABLE(update-check,
4113   [  --enable-update-check   update checking system (default disabled)])
4114 if test "${enable_update_check}" = "yes"
4115 then
4116  AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4117     AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4118   VLC_ADD_LIBS([libvlccore], [${GCRYPT_LIBS}])
4119   VLC_ADD_CFLAGS([libvlccore], [${GCRYPT_CFLAGS}])
4120   AC_DEFINE([UPDATE_CHECK], 1, [Define if you want to use the VLC update mechanism])
4121 fi
4122
4123 dnl
4124 dnl OS X notification plugin
4125 dnl
4126 AC_ARG_ENABLE(osx_notifications,
4127   [  --enable-osx-notifications          osx notification plugin (default disabled)],,
4128   [enable_osx_notifications=no])
4129 AS_IF([test "${enable_osx_notifications}" != "no"], [
4130     AC_CHECK_HEADERS(${CONTRIB_DIR}/Growl.framework/Versions/A/Headers/Growl.h, [
4131       VLC_ADD_PLUGIN([osx_notifications])
4132       VLC_ADD_LIBS([osx_notifications], [-F${CONTRIB_DIR} -Wl,-framework,Growl,-framework,Foundation])
4133       VLC_ADD_OBJCFLAGS([osx_notifications], [-F${CONTRIB_DIR}])
4134       VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4135     ])
4136   ]
4137 )
4138
4139 dnl
4140 dnl Libnotify notification plugin
4141 dnl
4142 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4143
4144 dnl
4145 dnl  Endianness check
4146 dnl
4147 AC_C_BIGENDIAN
4148 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4149   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4150 ], [
4151   DEFS_BIGENDIAN=""
4152 ])
4153 AC_SUBST(DEFS_BIGENDIAN)
4154
4155 dnl
4156 dnl Where to install KDE solid .desktop
4157 dnl
4158 AC_ARG_WITH(kde-solid,
4159   AS_HELP_STRING([--with-kde-solid=PATH],
4160                  [KDE Solid actions directory (auto)]),, [
4161
4162 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4163   with_kde_solid="yes"
4164 fi
4165 ])
4166 soliddatadir=""
4167 AS_IF([test "${with_kde_solid}" != "no"], [
4168   AS_IF([test "${with_kde_solid}" = "yes"], [
4169     kde4datadir="`${KDE4_CONFIG} --install data`"
4170     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4171     soliddatadir="${kde4datadir}/solid/actions"
4172   ], [
4173     soliddatadir="${with_kde_solid}"
4174   ])
4175 ])
4176 AC_SUBST(soliddatadir)
4177 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4178
4179 EXTEND_HELP_STRING([Components:])
4180
4181 dnl
4182 dnl  the VLC binary
4183 dnl
4184 AC_ARG_ENABLE(vlc,
4185   [  --enable-vlc            build the VLC media player (default enabled)])
4186 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4187
4188 AC_ARG_ENABLE(macosx-vlc-app,
4189   [  --enable-macosx-vlc-app build the VLC media player (default enabled on Mac OS X)])
4190 AM_CONDITIONAL(BUILD_MACOSX_VLC_APP, [test "${enable_macosx_vlc_app}" != "no" &&
4191     (test "${SYS}" = "darwin" || test "${enable_macosx_vlc_app}" = "yes") ])
4192
4193 dnl
4194 dnl  Stuff used by the program
4195 dnl
4196 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4197 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4198 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4199 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4200 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4201 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4202 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4203 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4204 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4205 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4206 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4207 AC_SUBST(COPYRIGHT_MESSAGE)
4208 AC_SUBST(VERSION_MESSAGE)
4209 AC_SUBST(VERSION_MAJOR)
4210 AC_SUBST(VERSION_MINOR)
4211 AC_SUBST(VERSION_REVISION)
4212 AC_SUBST(VERSION_EXTRA)
4213 AC_SUBST(COPYRIGHT_YEARS)
4214 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4215 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4216 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4217 dnl
4218 dnl  Handle substvars that use $(top_srcdir)
4219 dnl
4220 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4221
4222 dnl
4223 dnl  Configuration is finished
4224 dnl
4225 AC_SUBST(SYS)
4226 AC_SUBST(ARCH)
4227 AC_SUBST(ALIASES)
4228 AC_SUBST(ASM)
4229 AC_SUBST(MOC)
4230 AC_SUBST(RCC)
4231 AC_SUBST(UIC)
4232 AC_SUBST(WINDRES)
4233 AC_SUBST(WINE_SDK_PATH)
4234 AC_SUBST(LIBEXT)
4235 AC_SUBST(AM_CPPFLAGS)
4236 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4237 AC_SUBST(FILE_LIBVLCCORE_DLL)
4238 AC_SUBST(FILE_LIBVLC_DLL)
4239
4240 AC_CONFIG_FILES([
4241   Makefile
4242   doc/Makefile
4243   modules/Makefile
4244   m4/Makefile
4245   po/Makefile.in
4246   share/Makefile
4247   compat/Makefile
4248   src/Makefile
4249   lib/Makefile
4250   bin/Makefile
4251   test/Makefile
4252   modules/gui/macosx/Makefile
4253   modules/gui/qt/Makefile
4254   modules/gui/skins2/Makefile
4255   modules/hw/mmal/Makefile
4256   share/vlc.appdata.xml.in
4257 ])
4258
4259 AM_COND_IF([HAVE_WIN32], [
4260   AC_CONFIG_FILES([
4261     extras/package/win32/NSIS/spad.nsi
4262     extras/package/win32/NSIS/vlc.win32.nsi
4263     extras/package/win32/msi/config.wxi
4264   ])
4265 ])
4266
4267 AM_COND_IF([HAVE_DARWIN], [
4268   AC_CONFIG_FILES([
4269     extras/package/macosx/Info.plist
4270     extras/package/macosx/Resources/English.lproj/InfoPlist.strings
4271   ])
4272 ])
4273
4274 dnl Generate makefiles
4275 AC_OUTPUT
4276
4277 dnl Do we have to use make or gmake ?
4278 if make --version 2>&1|grep -q GNU
4279 then
4280     # GNU make, all seems good
4281     MAKE=make
4282 else
4283     # Known GNU make alias (on BSD)
4284     MAKE=gmake
4285 fi
4286 dnl Shortcut to nice compile message
4287 if test -n $SHELL; then
4288   SHELL=${CONFIG_SHELL-/bin/sh}
4289 fi
4290 rm -f compile
4291 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4292 echo "#! $SHELL
4293 rm -f .error\$\$
4294 ERROR=0
4295 export PATH=\"$PATH\" LANG=C
4296 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4297 test -f .error\$\$ && ERROR=1
4298 rm -f .error\$\$
4299 exit \$ERROR" >compile
4300 chmod a+x compile
4301
4302 echo "
4303 libvlc configuration
4304 --------------------
4305 version               : ${VERSION}
4306 system                : ${SYS}
4307 architecture          : ${ARCH}
4308 optimizations         : ${enable_optimizations}"
4309 if test "${enable_vlc}" != "no"; then
4310 echo "vlc aliases           :${ALIASES}"
4311 else
4312 echo "build vlc executable  : no"
4313 fi
4314 echo "
4315 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."